fairphone-case.scad

   1 // -*- C -*-
   2
   3 // Hard case for Fairphone 2
   4 //
   5 //  Copyright 2018 Ian Jackson.  There is NO WARRANTY.
   6 //  See below for full licensing and disclaimer.
   7 //
   8 // Instructions
   9 //
  10 //  1. You will want to git clone this repository.
  11 //
  12 //  2. Decide about the notification LED aperture. See the variable
  13 //     led_window_style, below.  The default here is "ad-hoc
  14 //     multi-colour", which can produces a translucent (clear-ish)
  15 //     window set into the lid, even on a single-nozzle printer.
  16 //     See "Ad-hoc multi-colour", below.
  17 //
  18 //  3. use "make" to generate the necessary files:
  19 //
  20 //     make -j8 fairphone-case.auto.scads `for f in   \
  21 //        HingePrint        \
  22 //        LidWindowPrint    \
  23 //        LidPrint          \
  24 //        OneKeeperPrint    \
  25 //        Case              \
  26 //     ; do echo fairphone-case,$f.auto.stl; done`
  27 //
  28 //  4. Print them.  Case and OneKeeperPrint should probably be
  29 //     the same colour.
  30 //
  31 //     For Lid and LidWindowPrint, if you are doing ad-hoc
  32 //     multi-colour:
  33 //        i.   Set up for clear filament
  34 //        ii.  Print LidWindowPrint.  Wait for it to finish.
  35 //             It won't take long.  As soon as it finishes, tell
  36 //             your printer to warm up (so that in fact it does
  37 //             not cool down).
  38 //        iii. Leaving the output so far on the printbed, reload
  39 //             your printer with the main lid colour.
  40 //        iv.  Print LidPrint.  You can let this go unattended.
  41 //
  42 //  5. Assemble the hinge.  You will need 4x M2 12mm machine screws
  43 //     and 8x M2 full nuts.
  44 //
  45 //     Make sure you get the hinge the right way round.  If you're not
  46 //     sure, run
  47 //         openscad fairphone-case,DemoHinge.auto.scad
  48 //     to see an assembly diagram.
  49 //
  50 //     The nuts recess into the hinge.  You will want very fine
  51 //     pliers.  As you screw each screw in, add the second nut when
  52 //     the screw thread emerges from the first - this will be a
  53 //     locknut.  Screw each screw to an appropriate tightness for the
  54 //     hinge stiffness.  You want the lid-side hinge to be stiffer as
  55 //     that makes closing the case work better.
  56 //
  57 //     When you have the stiffness right, tighten the locknuts onto
  58 //     each first nut.
  59 //
  60 //  6. In use:
  61 //
  62 //      - To put the phone in, drop its RH side into the RH side of
  63 //        the case.  Then feed the keeper through the small hole.
  64 //        Feed it right through.
  65 //
  66 //      - The optional prop can be used to prop the phone up (in
  67 //        portrait orientation only right now).  See
  68 //            openscad fairphone-case,DemoPropAngles.auto.scad
  69 //
  70 // Ad-hoc multi-colour
  71 //
  72 //  This file is set up to let you make a translucent window using a
  73 //  single-extruder printer, using a "two print run" technique.  This
  74 //  works well with our Lulzbot TAZ 5 and Aleph Objects' version of
  75 //  Cura.  If you are using a different printer, you may need to
  76 //  adjust the parameters or try a different technique.  In particular,
  77 //      initial_layer_thick
  78 //         set so that the window is one layer thick
  79 //      initial_layer_width
  80 //         set so that the slicer draws a rectangle around the whole
  81 //         object, rather than putting a "skirt" or anything inside
  82 //
  83 //  If you have a dual-extruder printer, you can set led_window_style
  84 //  to 2 and do a single print of LidPrint and LidWindowPrint.
  85 //
  86 //  Alternatively you can set it to 1 (just a hole) or 0 (no hole).
  87 //
  88 //  Thanks to Clare Boothby for the ad-hoc multi-colour technique (and
  89 //  the parameters for our Lulzbot TAZ 5 and Aleph Objects's Cura).
  90 //
  91 // Other phones
  92 //
  93 //  It might well be possible to adapt this file for other phones.
  94 //  If you do, let me know how you get on.
  95 //
  96 //
  97 // AUTHORSHIP, COPYRIGHT, LICENCE, AND LACK OF WARRANTY
  98 //
  99 //   Copyright (C)2018 Ian Jackson.
 100 //
 101 //    This program for generating a 3D model is free software: you can
 102 //    redistribute it and/or modify it under the terms of the GNU
 103 //    General Public License as published by the Free Software
 104 //    Foundation, either version 3 of the License, or (at your option)
 105 //    any later version.
 106 //
 107 //    This program is distributed in the hope that it will be useful,
 108 //    but WITHOUT ANY WARRANTY; without even the implied warranty of
 109 //    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 110 //    GNU General Public License for more details.
 111 //
 112 //    You should have received a copy of the GNU General Public
 113 //    License along with this program.  If not, see
 114 //    <http://www.gnu.org/licenses/>.
 115 //
 116 //  In particular DO NOT BLAME ME IF THIS CASE DOES NOT ADEQUATELY
 117 //  PROTECT YOUR PHONE !  It is your responsibility to decide whether
 118 //  this case will meet your needs.
 119
 120 include <utils.scad>
 121 include <funcs.scad>
 122
 123 phone = [ 75.0, 145.0 ];
 124
 125 prop_buildout_less = 3;
 126
 127 prop_angles = [ 15, 30, 45, 60 ];
 128
 129 bumper = [ 0.250, -0.025 ];
 130 // ^ One side.  Overall size is increased by twice this.
 131 // If no bumpers, is the gap around the phone.
 132
 133 enable_support = 1;
 134
 135 led_window_style = 3;
 136 // 0: no window
 137 // 1: simply an opening
 138 // 2: opening with separate cover model, for printing in clear (two colour)
 139 // 3: like 2 but one-layer window for ad-hoc multi-colour
 140
 141 initial_layer_thick = 0.400; // ^ needed for mode 3 only
 142 initial_layer_width = 0.750; // ^ needed for mode 3 only
 143 multicolour_gap = 0.15; // each side
 144
 145 phone_cnr_rad = 6.0;
 146 phone_rim_depth = 0.80; // includes allowance for a screen protector
 147
 148 button_cutout_depth = 9;
 149
 150 phone_edge_thick = 9.0;
 151 phone_total_thick = 12.0;
 152 phone_backside_slope_inner = 1.5; // larger means shallower
 153 phone_backside_slope_outer = 1.0; // larger means shallower
 154
 155 camera_pos_tl = [  6.450, 12.750 ]; // measured from tl corner
 156 camera_pos_br = [ 22.300, 37.600 ]; // tl/br as seen from back
 157
 158 jack_pos = [ 13.83, 8.485 ];
 159 jack_dia = 10.64 + .5; // some jack I had lying around
 160
 161 led_pos = [ 13.98, 10.00 ];
 162 led_aperture = 9;
 163 led_window_ledge = 0.75; // each side
 164
 165 noisecancelmic_pos = [ 19.54, 7.37 ];   // from rhs
 166 noisecancelmic_dia = 4.00;
 167
 168 //fingerpushhole_dias = [ 15, 18 ];
 169 fingerpushhole_dias = [];
 170
 171 lanyard_half_dia = 1.15;
 172
 173 rearspeaker_pos_bl = [ 12.64, 18.72 ];
 174 rearspeaker_size   = [  3.76,  7.36 ];
 175
 176 microusb_above = 3.27 - 0.25;
 177 microusb_below = 0.0;
 178 microusb_width = 16.12 + 1.25;
 179
 180 case_th_bottom = 2.5;
 181 case_th_lid = 3.0;
 182 case_th_side = 2.3;
 183 case_th_lip = 1.2;
 184
 185 lid_screen_gap_extra = .66;
 186
 187 case_struts_count = 6;
 188 case_struts_solid_below = 1.00;
 189 case_struts_solid_above = 0.75;
 190 case_struts_width = 0.10;
 191
 192 keeper_th_z = 0.75;
 193 keeper_th_x = 0.75;
 194 keeper_inner_width = 2.75;
 195 keeper_inner_height = 2.75;
 196 keeper_slant_slope = 2; // larger means steeper
 197
 198 keeper_gap_z_top = 0.25;
 199 keeper_gap_z_bot = 0.75;
 200 keeper_gap_x     = 0.25;
 201 keeper_gap_x_holes = 0.75;
 202
 203 keeper_side = 0; // 0 = lhs; 1 = rhs
 204
 205 case_lip = 1.25;
 206
 207 lid_gap_x = 0.25;
 208 lid_gap_z = 0.25;
 209 lid_lip = 1.75;
 210 lid_edgepart_width = 5.0;
 211 lid_buttoncover_thick = 1.3;
 212
 213 catch_slop = 0.50;
 214
 215 foldover_gap = 0.50;
 216 foldover_lever_gap = 0.50;
 217
 218 // properties of the hinge fasteners
 219 hingescrew_shaft_dia = 2.0 + 0.25; // M2 x 12mm machine screw
 220 hingescrew_shaft_len = 12;
 221 hingescrew_fasteners_extra_thick = 0.40;
 222 // ^ amount of thread protruding if everything was completely nominal
 223 //   and we are using two nuts
 224 hingescrew_nut_access_dia = 4.72 + 0.50;
 225 // ^ washer is 4.72 dia
 226 //   also, want to get pliers or tiny spanner in to do up locknut
 227 hingescrew_nut_across = 3.92 + 0.25; // incl. slop around recess slop
 228 hingescrew_nut_thick = 1.93;
 229 hingescrew_head_th = 1.38 + 0.75;
 230 hingescrew_head_dia = 3.92;
 231
 232 hingescrew_nut_recess_portion = 2/3; // portion of nut in recess
 233
 234 lever_cover_th = 0.75;
 235 hingemount_th = 2.5;
 236 hingemount_wd = 4.8725;
 237
 238 $fa = 5;
 239 $fs = 0.1;
 240
 241 button_l_fudge = 4.4;
 242 buttonishleg_default_l_is_fudge = 10;
 243
 244 hinge_base_slope = 1.5; // bigger is steeper
 245
 246 strut_min_at_end = 1.5;
 247
 248 hinge_x_gap = 0.125;
 249 hinge_x_postscrew_gap = 0.75;
 250 hinge_x_arms_gap = 0.35;
 251 hinge_r_arms_gap = 0.55;
 252
 253 rearspeaker_gap    = [ 2.0, 2.0 ]; // each side
 254
 255 catch_len = 7.5;
 256 catch_width = 15;
 257 catch_thickness = 1.0;
 258 catch_side_gap = 0.75; // each side
 259
 260 catch_depth = 0.75;
 261 catch_height = 0.35;
 262 catch_finger_height = 1.5;
 263 catch_finger_depth = 2.5;
 264
 265 catch_topcurve_r = 5.0;
 266
 267 prop_recess_under = 0.50;
 268 prop_recess_slop = 0.200; // each side
 269 prop_end_dia = 0.5;
 270 prop_main_th = 3;
 271 prop_taper_len = 6;
 272 prop_main_width = 4;
 273 prop_side_gap = 0.75; // each side
 274 prop_lidrecess_behind = 0.75;
 275 prop_caserecess_behind = 0.75;
 276 prop_caserecess_taper = 0.45; // one side only
 277 prop_prop_gap = 0.5;
 278 prop_prong_heel_slope = 0.5;
 279
 280 lid_fold_clearance_antislop = 0.5;
 281
 282 // ---------- calculated ----------
 283
 284 phone_width =  (phone + bumper*2)[0];
 285 phone_height = (phone + bumper*2)[1];
 286
 287 inside_br = [phone_width, -phone_height];
 288
 289 prop_prong_h = prop_main_th;
 290
 291 //echo(camera_pos_tl + bumper,
 292 //     camera_pos_br + bumper);
 293
 294 // ----- could be changed -----
 295 lid_buttoncover_gap = lid_gap_x;
 296 lid_buttoncover_overlap = case_th_lip + keeper_gap_z_top;
 297
 298 phone_backside_slope_thick = phone_total_thick - phone_edge_thick;
 299
 300 //prop_lidrecess_depth = case_th_lid - prop_recess_under;
 301
 302 //prop_nose_len = case_th_lid - prop_recess_under;
 303 //prop_recess_slope = tan(prop_max_angle); // bigger means steeper
 304 //prop_recess_width = prop_main_th / cos(prop_max_angle) + prop_backfwd_gap;
 305
 306
 307 //lid_lip_overlap_width xxx bad name = ;
 308 //lid_lip_inner_slope = [ 5, 5 ]; // xxx
 309
 310 epp0 = [0,0];
 311 epp1 = [0, -phone_edge_thick];
 312 epp2i = epp1 + phone_backside_slope_thick * [ phone_backside_slope_inner, -1 ];
 313 epp2o = epp1 + phone_backside_slope_thick * [ phone_backside_slope_outer, -1 ];
 314 epp3 = epp2i + [10, 0];
 315 epp5 = epp0 + [0,1] * (keeper_th_z + keeper_gap_z_top + case_lip);
 316 epp4 = epp5 + [-1,0] * case_th_side;
 317
 318 kppe = [0,0];
 319 kppd = kppe + [1,0] * keeper_inner_width;
 320 kppc = kppd + [0,1] * keeper_th_z;
 321 kppb = [ kppe[0] - keeper_th_x, kppc[1] ];
 322 kppf = kppe - [0,1] * keeper_inner_height;
 323 kppa = [ kppb[0], kppf[1] ];
 324
 325 lpp10 = [ epp5[0] + lid_gap_x, kppc[1] + lid_gap_z ];
 326 lpp11 = [ lpp10[0],            epp5[1] + lid_gap_z ];
 327
 328 lpp14 = lpp10 + [1,0] * max(keeper_inner_width, lid_edgepart_width);
 329 // exact x posn not very important; must extend past end of keeper
 330
 331 lpp15 = [ lpp14[0],
 332           epp0[1] - phone_rim_depth + 1/2.5 * case_th_lid
 333           + lid_screen_gap_extra ];
 334 // ^ beam theory says to maximise force before contact,
 335 //   the gap below the `beam' (the lid) must be 1/3
 336 //   the thickness (ie the lid thickness) if the beam
 337 //   is solid, or 1/2 if it has a top and bottom only.
 338 //   ours is mostly solid.
 339
 340 lp_r12 = max(case_th_lid - (lpp11[1] - lpp15[1]),
 341              case_th_lip);
 342
 343 lpp12 = [ epp4[0] + lp_r12,    lpp11[1] ];
 344 lpp13 = [ lpp12[0],            lpp12[1] + lp_r12 ];
 345
 346 case_bottom_z = epp2o[1] - case_th_bottom;
 347
 348 // button profile
 349 bppM = epp4 + [0,5];
 350 bppN = [ bppM[0] + lid_buttoncover_thick, bppM[1] ];
 351 bppR = [ bppN[0] + lid_buttoncover_gap, -button_cutout_depth ];
 352 bppS = [ epp1[0], bppR[1] ];
 353 bppQ = [ bppM[0], bppR[1] - lid_buttoncover_overlap ];
 354 bppP = bppQ + [0,1] * lid_buttoncover_gap;
 355 bppO = [ bppN[0], bppP[1] ];
 356 bppL = lpp10 + [5,0];
 357 bppK = [ bppL[0], bppN[1] ];
 358 bppJ = [ bppN[0], bppL[1] ];
 359 bppU = [ bppJ[0], lpp12[1] ];
 360 bppV = lpp11;
 361 bppW = lpp10;
 362
 363 echo("BUTTON COVER TH", bppO[0] - bppP[0]);
 364
 365 // notification led aperture
 366
 367 nla_r0 = led_aperture/2;
 368 nla_r1 = nla_r0 + led_window_ledge;
 369 nla_r2 = nla_r1 + multicolour_gap;
 370 nla_t =
 371   led_window_style >= 3 ? initial_layer_thick :
 372   led_window_style >= 2 ? led_window_ledge : 0;
 373
 374
 375 // hinge plan
 376 hp_rn = hingescrew_nut_access_dia/2;
 377 hp_r2_min = hp_rn + lever_cover_th;
 378 hp_rs = hingescrew_shaft_dia/2;
 379 hp_r1_min = hp_rs + hingemount_th;
 380
 381 hp_r1 = max(hp_r1_min, hp_r2_min);
 382 hp_r2 = hp_r1;
 383
 384 hppU = lpp13;
 385 hppS = epp2o + [0,-1] * case_th_bottom;
 386 hp_k = 0.5 * (hppU[1] - hppS[1] + foldover_gap);
 387
 388 hppM = [ epp4[0] - foldover_lever_gap - hp_r2,
 389          0.5 * (hppU + hppS)[1] ];
 390 hppT = [ hppM[0], hppU[1] - hp_r1 ];
 391 hppB = hppT + [0,-1] * hp_k;
 392
 393 hppE_y = epp2o[1] - case_th_bottom + hp_r1;
 394 hppE_x = hppB[0] + (hppB[1] - hppE_y) * hinge_base_slope;
 395 hppE = [ hppE_x, hppE_y ];
 396
 397 // hinge elevation x coords
 398
 399 hex20 = max(epp2o[0],
 400             phone_cnr_rad,
 401             kppd[0] + hingescrew_head_th + keeper_gap_x_holes);
 402 hex21 = hex20 + hingemount_wd;
 403 hex22 = hex21 + hinge_x_gap;
 404 hex27 = hex20 + hingescrew_shaft_len;
 405 hex24 = hex27 + hinge_x_postscrew_gap;
 406 hex23 = hex27 - (hingescrew_nut_thick*2
 407                  + hingescrew_fasteners_extra_thick);
 408 hex26 = hex23 + hingescrew_nut_thick * 2/3;
 409
 410 echo(hex20, hex21, hex22, hex23, hex24);
 411 //  6, 10.8725, 10.9975, 13.74, 18.75
 412 module chk(act,exp) {
 413   if (abs(act-exp) > 1e-9) echo("WRONG", act, exp);
 414   else echo("ok", act);
 415 }
 416 chk(hex20, 6);
 417 chk(hex21, 10.8725);
 418 chk(hex22, 10.9975);
 419 chk(hex23, 13.74);
 420 chk(hex24, 18.75);
 421
 422 lid_fold_clearance_skew =
 423   (lpp10[1] - hppB[1]) /
 424   (lpp10[0] - hppB[0]);
 425
 426 echo("SK",lid_fold_clearance_skew);
 427
 428 // catch
 429
 430 cppJ = [ epp4[0] + catch_thickness, lpp10[1] ];
 431 cppA = cppJ + [lid_gap_x, -lid_gap_z];
 432 cppB = [ epp0[0], cppA[1] ];
 433 cppP = [ epp4[0], cppJ[1] ];
 434
 435 cppS = cppJ + [0,-1] * catch_len;
 436 cppD = [ cppA[0], cppS[1] + catch_slop ];
 437 cppC = [ cppB[0], cppD[1] ];
 438 cppT = cppS + [1,0] * catch_depth;
 439 cppU = cppT + [0,-1] * catch_height;
 440 cppV = [ cppS[0], cppU[1] - catch_depth ];
 441
 442 cppR = 0.5*(cppP + cppJ);
 443
 444 cp_rQ = 0.5 * (cppJ[0] - cppP[0]);
 445 cppQ = [ cppR[0],
 446          cppV[1] - (catch_finger_height - cp_rQ) ];
 447 cppF = [ cppV[0] + catch_finger_depth, cppC[1] ];
 448
 449 // lanyard
 450
 451 ly_r = lanyard_half_dia / 2;
 452 ly_rc = ly_r * 2 * 5;
 453
 454 // prop recess in case
 455
 456 prop_x_pos = phone_width/2;
 457
 458 prop_recess_hw = 0.5 * prop_main_width + prop_side_gap;
 459
 460 prc_r1 = prop_end_dia/2;
 461 prc_r3 = prc_r1 + prop_recess_slop;
 462
 463 prcp2 = [ epp4[0] + prop_buildout_less,
 464           case_bottom_z ];
 465
 466 prop_caserecess_buildout_r = -1; // prcp2[0] - epp2o[0];
 467
 468 prcp1 = [ epp2o[0] + prc_r3 + prop_caserecess_behind,
 469           epp2i[1] - prc_r3 - prop_recess_under];
 470
 471 // prop recess in lid
 472
 473 prl_r10 = prop_end_dia/2;
 474 prl_r10o = prl_r10 + prop_recess_slop;
 475
 476 prlp10 = lpp10 + [1,1] * prl_r10o
 477   + [1,0] * prop_lidrecess_behind
 478   + [0,1] * prop_recess_under;
 479
 480 // prop
 481
 482 $prpp10 = [0,0];
 483 $prpp11 = [0, prop_taper_len];
 484
 485 $prp_r10 = prl_r10;
 486
 487 // ---------- modules ----------
 488
 489 module AdhocMultiprintFrame(phase, z0, zs) {
 490   // from z0 to z0 + zs*layer
 491   extra = phase * (initial_layer_width + multicolour_gap) + 5;
 492   xextra = extra + -epp4[0];
 493   xrange = [ 0, phone_width ] + [-1,+1] * xextra;
 494   yextra = extra + -epp4[0];
 495   yrange = [ -phone_height + +hppB[0] - hp_r2, 0 ] + [-1,+1] * yextra;
 496   p0 = [ xrange[0], yrange[0] ];
 497   p1 = [ xrange[1], yrange[1] ];
 498   echo(p0, p1);
 499   translate([0,0, z0])
 500     mirror([0,0, zs<0 ? 1 : 0])
 501     linear_extrude(height= initial_layer_thick)
 502     difference(){
 503       rectfromto(p0 - [1,1] * initial_layer_width,
 504                  p1 + [1,1] * initial_layer_width);
 505       rectfromto(p0, p1);
 506     }
 507 }
 508
 509 module KeeperProfile(slant=0){
 510   use_e = kppe + [0,-1] * slant * keeper_inner_width / keeper_slant_slope;
 511   polygon([use_e, kppd, kppc, kppb, kppa, kppf]);
 512 }
 513
 514 module EdgeProfile(){
 515   difference(){
 516     hull(){
 517       translate(epp3) square(case_th_bottom*2, center=true);
 518       circleat(epp2o, r=case_th_bottom);
 519       circleat(epp1, r=case_th_side);
 520       rectfromto(epp0, epp4);
 521     }
 522     polygon([ epp5 + [0,10],
 523               epp1,
 524               epp2i,
 525               epp3 + [10,0] ]);
 526   }
 527 }
 528
 529 module LanyardLanyardProfile(entry=false){
 530   hull(){
 531     for (xs=[-1,+1] * (entry ? 2 : 1))
 532       translate(xs * 0.5 * lanyard_half_dia * [1,0])
 533         circle(r= lanyard_half_dia/2);
 534   }
 535 }
 536
 537 module LanyardCurveChannelProfile(){
 538   translate([0, -ly_r])
 539     LanyardLanyardProfile();
 540 }
 541
 542 module LanyardEntryChannelProfile(){
 543   LanyardLanyardProfile(true);
 544 }
 545
 546 module LanyardMainChannelProfile(){
 547   LanyardCurveChannelProfile();
 548   difference(){
 549     square(center=true, ly_r * [6, 2]);
 550     for (xs=[-1,+1])
 551       translate(ly_r * [3 * xs, -1])
 552         circle(r = ly_r);
 553   }
 554 }
 555
 556 module LanyardEntry(){
 557   q_z = -(ly_rc + ly_r);
 558   d_x = -ly_rc;
 559
 560   translate([d_x, 0, q_z]) {
 561     intersection(){
 562       rotate([90,0,0])
 563         rotate_extrude(convexity=10)
 564         rotate(90)
 565         translate([0, -q_z])
 566         LanyardCurveChannelProfile();
 567       translate([0,-10,0])
 568         cube([20,20,20]);
 569     }
 570   }
 571
 572   mirror([0,0,1])
 573     translate([0,0,-1])
 574     linear_extrude(height=20)
 575     rotate(-90)
 576     LanyardEntryChannelProfile();
 577
 578   translate([0, ly_r*2, 0])
 579     rotate([90,0,0])
 580     linear_extrude(height = ly_r*4){
 581     difference(){
 582       rectfromto([d_x, q_z], [ly_r, 0]);
 583       circleat([d_x, q_z], ly_rc);
 584     }
 585   }
 586 }
 587
 588 module LanyardCutout(l){
 589   rotate([0,-90,0])
 590     linear_extrude(height=l)
 591     rotate(-90)
 592     LanyardMainChannelProfile();
 593
 594   for (ee=[0,1]){
 595     translate(ee * l * [-1,0])
 596       mirror([ee,0,0])
 597       LanyardEntry();
 598   }
 599 }
 600
 601 module LidEdgeProfile(){
 602   polygon([ lpp10,
 603             lpp11,
 604             lpp12,
 605             lpp13,
 606             lpp13 + [10, 0],
 607             lpp15 + [10, 0],
 608             lpp15,
 609             lpp14,
 610             ]);
 611   intersection(){
 612     circleat(lpp12, r=lp_r12);
 613     rectfromto( lpp12 + [-10,   0],
 614                 lpp12 + [+10, +10] );
 615   }
 616 }
 617
 618 module LidEdgeFoldClearanceProfile(){
 619   translate([-lid_fold_clearance_antislop, 0])
 620     polygon([ lpp10,
 621               lpp11,
 622               lpp11 + [-20,  0],
 623               lpp11 + [-20, 20],
 624               lpp11 + [+20, 20],
 625               lpp10 + [+20,  0] ]);
 626 }
 627
 628 module ButtonCoverProfile(){
 629   intersection(){
 630     polygon(concat([ bppM, bppP, bppO, bppJ ],
 631                    (enable_support && !$button_suppress_over_keeper
 632                     ? [ bppU, bppV, bppW ] : []),
 633                    [ bppL, bppK ]));
 634     hull(){
 635       EdgeProfile();
 636       LidEdgeProfile();
 637     }
 638   }
 639 }
 640
 641 module ButtonPlan(l, deep, cut){
 642   epsilon =
 643     (cut  ? 0 : lid_buttoncover_gap);
 644
 645   delta =
 646     (deep ? lid_buttoncover_overlap : 0);
 647
 648   C = [0,0]; // by definition
 649   T = [ 0, epp4[1] ];
 650   G = T + [0,10];
 651
 652   B0 = C + [0,-1] * button_cutout_depth;
 653   B1 = B0 + [0,1] * epsilon;
 654
 655   r0 = 0.5 * (T[1] - B0[1]);
 656   A = [  -(l + button_l_fudge)/2 + r0, 0.5 * (T[1] + B0[1]) ];
 657   H = A + [0,-1] * delta;
 658
 659   D = A + [-2,0] * r0;
 660   F = D + [0,10];
 661
 662   E0 = 0.5 * (D + A);
 663   E1 = E0 + [1,0] * epsilon;
 664
 665   I0 = [ E0[0], H[1] ];
 666   I1 = [ E1[0], H[1] ];
 667
 668   hull(){
 669     for (m=[0,1]) mirror([m,0])
 670       circleat(H, r0 - epsilon);
 671   }
 672   for (m=[0,1]) mirror([m,0]) {
 673     difference(){
 674       polygon([ E1,
 675                 I1,
 676                 H,
 677                 B1,
 678                 G,
 679                 F,
 680                 D
 681                 ]);
 682       circleat(D, r0 + epsilon);
 683     }
 684   }
 685 }
 686
 687 module CatchCatchProfile(){
 688   hull(){
 689     for (c=[ cppR, cppQ ])
 690       circleat(c, cp_rQ);
 691   }
 692   hull(){
 693     circleat(lpp12, lp_r12);
 694     circleat(lpp12 + [5,0], lp_r12);
 695     rectfromto(cppP, cppP + [5,0.1]);
 696   }
 697   polygon([cppJ, cppS, cppT, cppU, cppV, cppQ, cppR]);
 698 }
 699
 700 module CatchCutProfile(){
 701   polygon([ cppB,
 702             cppA,
 703             cppD,
 704             cppF,
 705             cppF + [0,-10],
 706             cppF + [-10,-10],
 707             lpp12 + [-10,0],
 708             lpp12 + [10,0]
 709             ]);
 710 }
 711
 712 module Flip_rhs(yn=[0,1]) {
 713   for ($rhsflip=yn) {
 714     translate([phone_width/2, 0, 0])
 715       mirror([$rhsflip,0,0])
 716       translate([-phone_width/2, 0, 0])
 717       children();
 718   }
 719 }
 720
 721 module Flip_bot(yn=[0,1]) {
 722   for ($botflip=yn) {
 723     translate([0, -phone_height/2, 0])
 724       mirror([0, $botflip, 0])
 725       translate([0, phone_height/2, 0])
 726       children();
 727   }
 728 }
 729
 730 module AroundEdges(fill_zstart, fill_th, fill_downwards=0){
 731   // sides
 732   Flip_rhs(){
 733     translate([0, -phone_cnr_rad, 0])
 734       rotate([90,0,0])
 735       linear_extrude(height = phone_height - phone_cnr_rad*2)
 736       children(0);
 737   }
 738   // corners
 739   Flip_rhs() Flip_bot() {
 740     translate([+1,-1] * phone_cnr_rad)
 741       intersection(){
 742         rotate_extrude()
 743           intersection(){
 744             mirror([1,0,0])
 745               translate([-1,0] * phone_cnr_rad)
 746               children(0);
 747             rectfromto([0,-20],[10,20]);
 748           }
 749         translate([-10, 0, -20] + 0.01 * [+1,-1, 0] )
 750           cube([10,10,40]);
 751       }
 752   }
 753   // top and bottom
 754   Flip_bot(){
 755     translate([ phone_width - phone_cnr_rad, 0,0 ])
 756       rotate([90,0,-90])
 757       linear_extrude(height = phone_width - phone_cnr_rad*2)
 758       children(0);
 759   }
 760   // fill
 761   translate([0,0, fill_zstart])
 762     mirror([0,0, fill_downwards])
 763     linear_extrude(height = fill_th)
 764     rectfromto([+1,-1] * phone_cnr_rad,
 765                [phone_width, -phone_height] + [-1,+1] * phone_cnr_rad);
 766 }
 767
 768 module CaseAperture(pos, dia, $fn) {
 769   theta = 180/$fn;
 770   translate([ pos[0] + bumper[0],
 771               -epp2i[0],
 772               -pos[1] ])
 773     rotate([-90, theta, 0])
 774     cylinder(r = dia/2 / cos(theta),
 775              h = 60);
 776 }
 777
 778 module SideButton(y, y_ref_sign, l, suppress_over_keeper=0){
 779   // y_ref_sign:
 780   //   +1  measured from top    of actual phone to top    of button
 781   //   -1  measured from bottom of actual phone to bottom of button
 782   //    0  y is centre of button in coordinate system
 783   $button_l= l;
 784   $button_suppress_over_keeper= suppress_over_keeper;
 785   eff_y = y_ref_sign > 0 ?         -bumper [1] -y -l/2 :
 786           y_ref_sign < 0 ? (-phone -bumper)[1] +y +l/2 :
 787           y;
 788   //echo(eff_y);
 789   translate([0, eff_y, 0])
 790     children();
 791 }
 792
 793 module LidButtonishLeg(y, y_ref_sign, l=buttonishleg_default_l_is_fudge) {
 794   $button_leg_only = true;
 795   SideButton(y, y_ref_sign, l) children();
 796 }
 797
 798 module Buttons(){
 799   Flip_rhs(1) SideButton(15.580, +1, 8.9     ) children(); // power
 800   Flip_rhs(1) SideButton(48.700, -1, 8.920   ) children(); // camera
 801   Flip_rhs(0) SideButton(30.800, +1, 21.96, 1) children(); // volume
 802   Flip_rhs(   ) LidButtonishLeg(14, -1) children();
 803 //  Flip_rhs(0) LidButtonishLeg(20, +1, 20) children();
 804 }
 805
 806 module Struts(x_start, z_min, th){
 807   // if th is negative, starts at z_min and works towards -ve z
 808   // and object should then be printed other way up
 809   for (i= [1 : 1 : case_struts_count]) {
 810     translate([0,
 811                0,
 812                z_min])
 813       mirror([0,0, th<0 ? 1 : 0])
 814       translate([0,
 815                  -phone_height * i / (case_struts_count+1),
 816                  case_struts_solid_below])
 817       linear_extrude(height= abs(th)
 818                      -(case_struts_solid_below+case_struts_solid_above))
 819       rectfromto([               x_start, -0.5 * case_struts_width ],
 820                  [ phone_width - x_start, +0.5 * case_struts_width ]);
 821   }
 822 }
 823
 824 module OrdinaryRearAperture(rhs,bot, pos){
 825   Flip_rhs(rhs) Flip_bot(bot)
 826     linextr(-20, 20)
 827     mirror([0,1])
 828     translate(pos + bumper)
 829     children();
 830 }
 831
 832 module MicroUSB(){
 833   Flip_bot(1){
 834     rotate([90,0,0])
 835       mirror([0,0,1])
 836       linextr(-epp2i[0], 60)
 837       translate([0.5 * phone_width, 0, 0])
 838       rectfromto([-microusb_width/2, epp2i[1] + microusb_below],
 839                  [+microusb_width/2, epp0[1] + -microusb_above]);
 840   }
 841 }
 842
 843 module OrdinaryRearApertures(){
 844   // rear speaker
 845   OrdinaryRearAperture(1,1, rearspeaker_pos_bl)
 846     rectfromto(-rearspeaker_gap,
 847                rearspeaker_size + rearspeaker_gap);
 848
 849   // finger hole to remove phone
 850   if (len(fingerpushhole_dias))
 851     OrdinaryRearAperture(1,0, [ fingerpushhole_dias[0]/2 + epp2i[0],
 852                                 phone[1]/2 ])
 853     scale(fingerpushhole_dias)
 854     circle(r= 0.5 );
 855 }
 856
 857 module RearCameraAperture(){
 858   Flip_rhs(1)
 859     mirror([0, 0, 1])
 860     linear_extrude(height = 20)
 861     mirror([0, 1, 0])
 862     translate(bumper)
 863     rectfromto(camera_pos_tl, camera_pos_br);
 864 }
 865
 866 module HingeLidProfile(){
 867   hull(){
 868     circleat(hppT, hp_r1);
 869     circleat(lpp12, lp_r12);
 870     polygon([lpp10,
 871              lpp13 + [2,0],
 872              lpp12,
 873              hppT]);
 874   }
 875 }
 876
 877 module HingeBaseProfile(){
 878   difference(){
 879     hull(){
 880       circleat(hppB, hp_r1);
 881       circleat(hppE, hp_r1);
 882       circleat(epp2o, case_th_bottom);
 883       circleat(hppB + [10,0], hp_r1);
 884     }
 885     polygon([epp5, epp1, epp2i, epp3, bppL]);
 886   }
 887 }
 888
 889 module HingeLeverOuterProfile(){
 890   hull(){
 891     circleat(hppT, hp_r2);
 892     circleat(hppB, hp_r2);
 893   }
 894 }
 895
 896 module HingeLeverInnerProfile(){
 897   for (s = [-1,+1]) {
 898     c = s > 0 ? hppT : hppB;
 899     translate(c)
 900       mirror([0,0,s>0])
 901       rotate(s<0 ? -40 : 0)
 902       hull()
 903       for (x=[-20,20])
 904         for (y=[0, s * 10])
 905           translate([x,y])
 906             circle(hp_rn);
 907   }
 908 }
 909
 910 module HingeLeverNutProfile(){
 911   for (c= [hppB, hppT]) {
 912     translate(c)
 913       circle($fn=6, r= 0.5 * hingescrew_nut_across / cos(30));
 914   }
 915 }
 916
 917 module Flip_hinge(doflip=1){
 918   hinge_origin = [0, -(phone_height - hppB[0]), hppB[1]];
 919   translate(hinge_origin)
 920     rotate([doflip*180,0,0])
 921     translate(-hinge_origin)
 922     children();
 923 }
 924
 925 module HingePortion(x0,x1){
 926   Flip_rhs() Flip_bot(1)
 927     translate([x0,0,0])
 928     mirror([1,0,0])
 929     rotate([90,0,-90])
 930     linear_extrude(height=x1-x0)
 931     children();
 932 }
 933
 934 module CatchPortion(xwidth, ztop){
 935   width = catch_width + xwidth;
 936   w = width + catch_topcurve_r*2 + 1;
 937   translate([phone_width/2, 0,0]){
 938     difference(){
 939       rotate([90,0,-90])
 940         linextr(-w/2, w/2)
 941         children(0);
 942       translate([0, 50, 0])
 943         rotate([90,0,0])
 944         linear_extrude(height=100){
 945         for (m=[0,1]) mirror([m,0,0]) {
 946           hull(){
 947             translate([w/2, ztop - catch_topcurve_r])
 948               circle(catch_topcurve_r);
 949             translate([w/2, -50])
 950               square(catch_topcurve_r*2, center=true);
 951           }
 952         }
 953       }
 954     }
 955   }
 956 }
 957
 958 module CaseBase(){
 959   AroundEdges(epp3[1], case_th_bottom, 1)
 960     EdgeProfile();
 961 }
 962
 963 function prop_x(gamma) = hp_k / (2 * sin(gamma/2)) - hppT[0];
 964
 965 module PropProfileAssignments(gamma){
 966   // https://en.wikipedia.org/wiki/Solution_of_triangles#Two_sides_and_the_included_angle_given_(SAS)
 967   x = prop_x(gamma);
 968   p = phone_height + prlp10[0] - hppB[0];
 969   b = p + x;
 970
 971   q = phone_height - hppT[0] - prcp1[0]; // $prpp7[0] is 0 by definition
 972   a = q + x;
 973   c = sqrt(a*a + b*b - 2*a*b*cos(gamma));
 974   $prp_alpha = acos( (b*b + c*c - a*a) / (2*b*c) );
 975
 976   $prp_theta = 90 - $prp_alpha;
 977   beta = 180 - $prp_alpha - gamma;
 978   psi = 90 - beta;
 979
 980   //echo("abc", a,b,c);
 981
 982   v1 = [ [ cos(psi), -sin(psi) ],    // x
 983          [ sin(psi),  cos(psi) ] ];  // y
 984
 985   $prpp7 = [0, c + (lpp13[1] - $prpp10[1] - hp_k) ];
 986
 987   $prp_r1 = prc_r1;
 988   $prp_r11 = prop_main_th/2;
 989
 990   $prpp1 = $prpp7 + [1,0] *
 991     // this is approximate, but will do
 992     (prop_main_th/2 + prop_prop_gap + prcp1[0] - cppA[0]);
 993   $prpp3 = $prpp1 +
 994     v1[0] * -$prp_r1 +
 995     v1[1] * ((prcp2[1] - prcp1[1]) - prop_prop_gap);
 996   $prpp12 = $prpp3 + v1[0] *
 997     (prop_end_dia + prop_caserecess_taper * ($prpp1[1] - $prpp3[1]));
 998   $prp_r8 = prop_main_th;
 999   $prpp4 = [ prop_main_th/2, $prpp3[1] ];
1000   $prp_r5 = $prp_r8;
1001   $prpp5 = [ $prpp12[0] - $prp_r5,
1002             $prpp3[1] - prop_prong_h + $prp_r5 ];
1003   $prpp6 = $prpp4 + [0,-1] * (prop_prong_h +
1004          prop_prong_heel_slope * ($prpp5[0] - $prpp4[0]));
1005   $prpp8 = $prpp4 + [0,-1] * $prp_r8;
1006   $prpp9 = $prpp8 + [-1,0] * $prp_r8;
1007
1008   children();
1009 }
1010
1011 module PropProfile(gamma, cut=0, rot=0){ ////toplevel
1012   PropProfileAssignments(gamma){
1013
1014     //#circleat($prpp3,1);
1015     //#circleat($prpp12,1);
1016
1017     if (!cut) {
1018       hull(){
1019         translate($prpp8)
1020           intersection(){
1021             circle($prp_r8);
1022             polygon([[-20,-0], [20,20], [0,0]]);
1023           }
1024         rectfromto($prpp6, $prpp9);
1025         translate($prpp5) intersection(){
1026           circle($prp_r5);
1027           polygon([[-10,-10], [0,0], [10,0]]);
1028         }
1029         rectfromto($prpp12 + [0,-0.1], $prpp3);
1030       }
1031       hull(){
1032         circleat($prpp1, $prp_r1);
1033         rectfromto($prpp12 + [0,-0.1], $prpp3);
1034       }
1035     }
1036     // main shaft
1037     rotate([0,0, rot*-$prp_theta]){
1038       hull(){
1039         extra = cut ? prop_recess_slop : 0;
1040         rectfromto($prpp6, $prpp9);
1041         circleat($prpp11, $prp_r11 + extra);
1042         circleat($prpp10, $prp_r10 + extra);
1043       }
1044     }
1045   }
1046 }
1047
1048 module PropAggregateProfile(){
1049   for (angle = prop_angles)
1050     PropProfile(angle, 0,0);
1051 }
1052
1053 module Prop(){ ////toplevel
1054   hw = prop_main_width/2;
1055   linextr(-hw, +hw)
1056     PropAggregateProfile();
1057 }
1058
1059 module Case(){ ////toplevel
1060   difference(){
1061     union(){
1062       CaseBase();
1063
1064       // ledge (fixed keeper)
1065       Flip_rhs(1-keeper_side) intersection(){
1066         rotate([90, 0, 0])
1067           linear_extrude(height = phone_height + phone_cnr_rad * 2)
1068           KeeperProfile(1);
1069
1070         // outline of the whole case, to stop it protruding
1071         translate([0,0, -25])
1072           linear_extrude(height = 50)
1073           hull()
1074           Flip_bot()
1075           circleat([+1,-1] * phone_cnr_rad, phone_cnr_rad + case_th_side/2);
1076       }
1077
1078       // hinge
1079       HingePortion(hex20, hex21) HingeBaseProfile();
1080
1081       // buildout for prop recess
1082       if (prop_caserecess_buildout_r > 0) Flip_rhs(1)
1083         linextr(case_bottom_z, epp2i[1])
1084         hull() {
1085           for (dxs = [-1,+1])
1086             circleat([ prop_x_pos + dxs * prop_caserecess_buildout_r,
1087                        -epp2o[0] ],
1088                      r = epp2o[0] - prcp2[0]);
1089         }
1090     }
1091
1092     // slot for keeper
1093     Flip_rhs(keeper_side)
1094       translate([0, -phone_cnr_rad, 0])
1095       rotate([90, 0, 0])
1096       linear_extrude(height = phone_height + phone_cnr_rad * 2)
1097       minkowski(){
1098         KeeperProfile();
1099         rectfromto([ -keeper_gap_x,    -keeper_gap_z_bot ],
1100                    [ keeper_gap_x_holes,    +keeper_gap_z_top ]);
1101       }
1102
1103     // front camera
1104     RearCameraAperture();
1105
1106     // struts (invisible, because they're buried in the case)
1107     Struts(epp2i[0], epp2i[1] - case_th_bottom, case_th_bottom);
1108
1109     Buttons(){
1110       mirror([1,0,0])
1111         rotate([90,0,90]) {
1112           if (!($button_leg_only && enable_support))
1113           intersection(){
1114             translate([0,0,-10])
1115               linear_extrude(height= 20)
1116               ButtonPlan($button_l, 0,1);
1117             if ($button_leg_only)
1118               rotate([-90,90,0])
1119                 translate([phone_width/2, -400, kppe[1]])
1120                 mirror([1-abs($rhsflip - keeper_side),0,0])
1121                 cube([400, 800, 50]);
1122             if (enable_support && !$button_suppress_over_keeper)
1123               rotate([-90,90,0])
1124               translate([-400, -400, kppd[1]])
1125                 mirror([0,0,1])
1126                 cube([800,800,100]);
1127           }
1128           translate([0,0, -bppR[0]])
1129             linear_extrude(height= 20)
1130             ButtonPlan($button_l, 1,1);
1131         }
1132
1133     }
1134
1135     // apertures along top edge
1136     CaseAperture(jack_pos, jack_dia, 8);
1137     Flip_rhs(1)
1138       CaseAperture(noisecancelmic_pos, noisecancelmic_dia, 8);
1139
1140     OrdinaryRearApertures();
1141
1142     MicroUSB();
1143
1144     // gaps for the lid's hinge arms
1145     HingePortion(hex20 - hinge_x_arms_gap,
1146                  hex21 + hinge_x_arms_gap)
1147       minkowski(){
1148         HingeLidProfile();
1149         circle(r= hinge_r_arms_gap, $fn= 8);
1150       }
1151
1152     // screw holes in the hinge arms
1153     HingeScrews();
1154
1155     // catch striker
1156     CatchPortion(catch_side_gap*2, epp4[1])
1157       CatchCutProfile();
1158
1159     // prop recess
1160     Flip_rhs(1)
1161       translate([prop_x_pos,0,0])
1162       mirror([0,1,0])
1163       rotate([90,0,90])
1164       linextr(-prop_recess_hw, +prop_recess_hw)
1165       hull(){
1166         for (d=[ [0,0], [0,-1], [+1,-1/prop_caserecess_taper] ])
1167           circleat(prcp1 + 20*d,
1168                    prc_r3);
1169       }
1170   }
1171 }
1172
1173 module LidAdhocMultiprintFrame(phase){
1174   if (led_window_style >= 3) {
1175     AdhocMultiprintFrame(phase, lpp13[1], -1);
1176   }
1177 }
1178
1179 module LidAroundEdges(){
1180   AroundEdges(lpp15[1], lpp13[1] - lpp15[1], 0)
1181     children();
1182 }
1183
1184 module Lid(){ ////toplevel
1185   skew_centre = [0, lpp11[0], lpp11[1]];
1186   difference(){
1187     union(){
1188       intersection(){
1189         LidAroundEdges()
1190           LidEdgeProfile();
1191
1192         translate(skew_centre)
1193           multmatrix([[ 1, 0, 0, 0 ],
1194                       [ 0, 1, -lid_fold_clearance_skew, 0 ],
1195                       [ 0, 0, 1, 0 ],
1196                       [ 0, 0, 0, 1 ]])
1197           translate(-skew_centre)
1198           LidAroundEdges()
1199           LidEdgeFoldClearanceProfile();
1200       }
1201
1202       // button covers
1203       Buttons(){
1204         intersection(){
1205           rotate([90,0,90])
1206             translate([0,0,-10])
1207             linear_extrude(height= 20)
1208             ButtonPlan($button_l, 1,0);
1209           rotate([90,0,0])
1210              translate([0,0,-100])
1211             linear_extrude(height= 200)
1212             ButtonCoverProfile();
1213         }
1214       }
1215
1216       // hinge arms
1217       HingePortion(hex20, hex21) {
1218         LidEdgeProfile();
1219         HingeLidProfile();
1220       }
1221
1222       // catch
1223       CatchPortion(0, lpp12[1])
1224         CatchCatchProfile();
1225     }
1226     Struts(lpp10[0] + strut_min_at_end, lpp13[1], -case_th_lid);
1227
1228     // screw holes in the hinge arms
1229     HingeScrews();
1230
1231     // prop recess
1232     translate([prop_x_pos, -prlp10[0], prlp10[1]])
1233       mirror([0,1,0])
1234       rotate([90,0,90])
1235       linextr(-prop_recess_hw, +prop_recess_hw)
1236       hull()
1237       for (pa = prop_angles)
1238         PropProfile(pa, 1,1);
1239
1240     // notification led aperture
1241     if (led_window_style)
1242       translate([led_pos[0], -led_pos[1], lpp13[1]]) {
1243         translate([0,0,-10])
1244           cylinder(r=nla_r0, h=20);
1245         if (led_window_style >= 2)
1246           translate([0,0, -nla_t])
1247             cylinder(r=nla_r2, height=20);
1248       }
1249
1250     }
1251
1252   LidAdhocMultiprintFrame(1);
1253 }
1254
1255 module HingeLever(){ ////toplevel
1256   difference() {
1257     // outer body, positive
1258     HingePortion(hex22, hex22 + phone_width/2)
1259       HingeLeverOuterProfile();
1260
1261     // space for the screws
1262     HingePortion(hex26, hex24)
1263       HingeLeverInnerProfile();
1264
1265     // recesses for the nuts
1266     HingePortion(hex23, hex26+1)
1267       HingeLeverNutProfile();
1268
1269     // bores for the screws
1270     HingeScrews();
1271
1272     // space for the charging cable
1273     MicroUSB();
1274     Flip_hinge() MicroUSB();
1275   }
1276 }
1277
1278 module LidWindow(){ ////toplevel
1279   translate([led_pos[0], -led_pos[1], lpp13[1]])
1280     mirror([0,0,1])
1281     cylinder(r= nla_r1, h=nla_t);
1282   LidAdhocMultiprintFrame(0);
1283 }
1284
1285 module LidWindowPrint(){ ////toplevel
1286   rotate([0,180,0])
1287     LidWindow();
1288 }
1289
1290 module DemoLidWindowSelect(){
1291   translate([led_pos[0], led_pos[1], -100]) {
1292     translate([0, -30, 0]) cube([400, 400, 200]);
1293   }
1294 }
1295
1296 module DemoLidWindow(){ ////toplevel
1297   %Lid();
1298   LidWindow();
1299   translate([0,40,0]){
1300     color("blue") intersection(){ Lid(); DemoLidWindowSelect(); }
1301     color("red") intersection(){ LidWindow(); DemoLidWindowSelect(); }
1302   }
1303 }
1304
1305 module HingeLeverPrint(){ ////toplevel
1306   rotate([-90,0,0])
1307     translate([-phone_width/2, phone_height, 0])
1308     HingeLever();
1309 }
1310
1311 module TestSelectLength(){
1312   translate([-30, -200, -20])
1313     cube([30 + 15, 250, 40]);
1314 }
1315
1316 module TestLength(){ ////toplevel
1317   intersection(){
1318     Case();
1319     TestSelectLength();
1320   }
1321 }
1322
1323 module TestLengthRight(){ ////toplevel
1324   intersection(){
1325     Case();
1326     Flip_rhs(1)
1327       TestSelectLength();
1328   }
1329 }
1330
1331 module TestSelectWidth(){
1332   translate([-30, -(phone_height - 25), -20])
1333     mirror([0, 1, 0])
1334     cube([200, 50, 40]);
1335 }
1336
1337 module TestWidth(){ ////toplevel
1338   intersection(){
1339     Case();
1340     TestSelectWidth();
1341   }
1342 }
1343
1344 module TestLidWidthPrint(){ ////toplevel
1345   rotate([0,180.0]) intersection(){
1346     Lid();
1347     TestSelectWidth();
1348   }
1349 }
1350
1351 module TestSelectRearAperture(){
1352   minkowski(){
1353     union() children();
1354     translate([20, 0,0])
1355       cube([42, 2, 1], center=true);
1356   }
1357 }
1358
1359 module TestSelectCamera(){
1360   minkowski(){
1361     TestSelectRearAperture()
1362       RearCameraAperture();
1363     cube([0.1, 50, 0.1]);
1364   }
1365 }
1366
1367 module TestSelectOrdinaryRearApertures(){
1368   TestSelectRearAperture()
1369     OrdinaryRearApertures();
1370 }
1371
1372 module TestCamera(){ ////toplevel
1373   intersection(){
1374     Case();
1375     TestSelectCamera();
1376   }
1377 }
1378
1379 module TestLidByCamera(){ ////toplevel
1380   intersection(){
1381     Lid();
1382     TestSelectCamera();
1383   }
1384 }
1385
1386 module TestLidByCameraPrint(){ ////toplevel
1387   rotate([180,0,0]) TestLidByCamera();
1388 }
1389
1390 module DemoByCamera(){ ////toplevel
1391   color("blue") TestLidByCamera();
1392   color("red")  TestCamera();
1393 }
1394
1395 module OneKeeper(){ ////toplevel
1396   translate([0, -phone_cnr_rad, 0])
1397     rotate([90, 0, 0])
1398     linear_extrude(height = phone_height - phone_cnr_rad * 2)
1399     KeeperProfile();
1400 }
1401
1402 module OneKeeperPrint(){ ////toplevel
1403   rotate([0,180,0])
1404     OneKeeper();
1405 }
1406
1407 module LidPrint(){ ////toplevel
1408   rotate([0,180,0])
1409     Lid();
1410 }
1411
1412 module TestSelectFrame(){
1413   include = [1,-1] * (epp2i[0] + 4);
1414
1415   difference(){
1416     cube(1000, center=true);
1417     translate([0,0, -100])
1418       linear_extrude(height=200)
1419       rectfromto(include,  inside_br - include);
1420   }
1421 }
1422
1423 module TestSelectLidFrame(){
1424   TestSelectFrame();
1425   translate([led_pos[0], -led_pos[1], -50])
1426     cylinder(r= nla_r2+3, h=100);
1427 }
1428
1429 module TestFrameCase(){ ////toplevel
1430   intersection(){
1431     Case();
1432     union(){
1433       TestSelectFrame();
1434       TestSelectCamera();
1435       TestSelectOrdinaryRearApertures();
1436     }
1437   }
1438 }
1439
1440 module TestSelectTopApertures(){
1441   translate([-100, -35, -100])
1442     cube([400, 100, 200]);
1443   LidAdhocMultiprintFrame(0);
1444   LidAdhocMultiprintFrame(1);
1445 }
1446
1447 module TestTopApertures(){ ////toplevel
1448   intersection(){
1449     Case();
1450     TestSelectFrame();
1451     TestSelectTopApertures();
1452   }
1453 }
1454
1455 module TestLidTopAperturesPrint(){ ////toplevel
1456   rotate([0,180,0]) intersection(){
1457     Lid();
1458     TestSelectLidFrame();
1459     TestSelectTopApertures();
1460   }
1461 }
1462
1463 module TestLidWindowTopAperturesPrint(){ ////toplevel
1464   rotate([0,180,0]) intersection(){
1465     LidWindow();
1466     TestSelectTopApertures();
1467   }
1468 }
1469
1470 module TestFrameLidPrint(){ ////toplevel
1471   rotate([0,180,0]) intersection(){
1472     Lid();
1473     TestSelectLidFrame();
1474   }
1475 }
1476
1477 module ButtonPlanForDemo(z, deep, cut){
1478   translate([0,0,z])
1479     ButtonPlan(8, deep, cut);
1480 }
1481
1482 module HingeScrews(){
1483   Flip_rhs() Flip_bot(1){
1484     for (c= [ hppT, hppB ])
1485       translate([ hex20,
1486                   -c[0],
1487                   c[1] ]){
1488         rotate([0,90,0])
1489           translate([0,0,-.2])
1490           cylinder( r= hingescrew_shaft_dia/2,
1491                     h = hingescrew_shaft_len+0.2 );
1492         rotate([0,-90,0])
1493           translate([0,0,+.1])
1494           cylinder( r= hingescrew_head_dia/2, h = hingescrew_head_th );
1495       }
1496   }
1497 }
1498
1499 module DemoPropAngleSelect(c){
1500   color(c) difference(){
1501     union(){ children(); }
1502     translate([ prop_x_pos, -400, -200 ])
1503       cube([ 400,800,400 ]);
1504   }
1505 }
1506
1507 module DemoPropAngle(ang){
1508   hL = [0, -(phone_height - hppT[0]), hppT[1] - hp_k*2];
1509   hC = [0, -(phone_height - hppB[0]), hppB[1]];
1510
1511   translate(hL)
1512     rotate([ang/2,0,0])
1513     translate(-hL)
1514     translate(hC)
1515     rotate([ang/2,0,0])
1516     translate(-hC) {
1517       DemoPropAngleSelect("red") Case();
1518
1519       color("orange")
1520         translate([prop_x_pos, -prcp1[0], prcp1[1]])
1521         PropProfileAssignments(ang) {
1522           echo($prpp1);
1523           rotate([-$prp_theta, 0, 0])
1524           translate([0, $prpp1[0], -$prpp1[1]])
1525           rotate([90,0,-90])
1526           Prop();
1527         }
1528     }
1529
1530   translate([0,0, -hp_k*2])
1531     DemoPropAngleSelect("blue")
1532     Lid();
1533 }
1534
1535 module DemoPropAngles(){ ////toplevel
1536   for (i=[0 : len(prop_angles)-1])
1537     translate(i * [0, -100, 100])
1538     DemoPropAngle(prop_angles[i]);
1539 }
1540
1541 module DemoHingeAngle(ang1,ang2){
1542   hL = [0, -(phone_height - hppT[0]), hppT[1]];
1543   hC = [0, -(phone_height - hppB[0]), hppB[1]];
1544
1545   translate(hL)
1546     rotate([ang2,0,0])
1547     translate(-hL)
1548     translate(hC)
1549     rotate([ang1,0,0])
1550     translate(-hC) {
1551       color("red") Lid();
1552     }
1553
1554   color("blue") intersection(){
1555     Case();
1556     union(){
1557       translate([bppJ[0], -400, -200])
1558         mirror([1,0,0])
1559         cube([400, 800, 400]);
1560       translate([10, -400, -200])
1561         cube([10, 800, 400]);
1562     }
1563   }
1564 }
1565
1566 module DemoHingeAngles(){ ////toplevel
1567   angles = [ 0, 4, 8, 12 ];
1568   echo("angles",angles);
1569   for (i=[0 : len(angles)-1]) {
1570     translate(i * [0, 0, 30]) {
1571       DemoHingeAngle(0,angles[i]);
1572       translate([0, 200, 0])
1573         DemoHingeAngle(angles[i],0);
1574     }
1575   }
1576 }
1577
1578 module DemoSelectAdhocLeftRight(right=0) {
1579   translate([phone_width/2, -400, -100]) // , -15, -100  to cross-section
1580     mirror([1-right, 0,0])
1581     cube([400, 800, 200]);
1582 }
1583
1584 module DemoLeft(){ ////toplevel
1585   color("red")  intersection(){ Case(); DemoSelectAdhocLeftRight(); }
1586   color("blue") intersection(){ Lid();  DemoSelectAdhocLeftRight(); }
1587 }
1588
1589 module DemoFrame(){ ////toplevel
1590   color("red") TestFrameCase();
1591   color("blue") intersection(){ Lid(); TestSelectLidFrame(); }
1592   color("black") HingeScrews();
1593   %HingeLever();
1594 }
1595
1596 module DemoLanyardCutout(){ ////toplevel
1597   LanyardCutout(25);
1598 }
1599
1600 module DemoHingedFrame(){ ///toplevel
1601   color("red") TestFrameCase();
1602   translate([0,0, -2*hp_k])
1603   color("blue") intersection(){ Lid(); TestSelectLidFrame(); }
1604
1605   Flip_hinge(){
1606     color("orange") HingeLever();
1607     color("black") HingeScrews();
1608   }
1609 }
1610
1611 module DemoHinge(){ ////toplevel
1612   translate([ -0.5*phone_width, phone_height, hp_k*3 ]) {
1613     DemoFrame();
1614     translate([0,0, -hp_k*3])
1615       DemoHingedFrame();
1616   }
1617 }
1618
1619 module DemoProfiles(){ ////toplevel
1620   LidEdgeProfile();
1621   %EdgeProfile();
1622   KeeperProfile();
1623   translate([0,0,-1]) color("black") KeeperProfile(1);
1624   color("purple") translate(epp2i)
1625     rotate(atan2vector(epp2i - epp1)) {
1626     translate(lanyard_half_dia * 0.5 * [-3,-1])
1627       LanyardLanyardProfile();
1628     translate(lanyard_half_dia * 0.5 * [-3,+1])
1629       translate([0,-1] * case_th_side)
1630       LanyardLanyardProfile(true);
1631   }
1632
1633   translate([0,20]) {
1634     LanyardMainChannelProfile();
1635     translate([0,0,1]) color("purple") LanyardCurveChannelProfile();
1636     translate([0,0,-1]) color("red") LanyardEntryChannelProfile();
1637   }
1638
1639   translate([20,0]) {
1640     LidEdgeProfile();
1641     %EdgeProfile();
1642
1643     demopoint_QR = [ bppS[0], bppQ[1] - 0.1];
1644
1645     color("blue") ButtonCoverProfile();
1646     color("red") {
1647       rectfromto(bppQ, demopoint_QR);
1648       rectfromto(bppR, demopoint_QR);
1649     }
1650   }
1651
1652   translate([-20,0]) {
1653     color("black") ButtonPlanForDemo(-2, 0,1);
1654     color("red" )  ButtonPlanForDemo(-4, 1,1);
1655     color("blue")  ButtonPlanForDemo(-6, 1,0);
1656   }
1657
1658   translate([0, -30]) {
1659     %LidEdgeProfile();
1660     %EdgeProfile();
1661     color("blue") HingeLidProfile();
1662     color("red")  HingeBaseProfile();
1663     color("black") translate([0,0,-2]) HingeLeverOuterProfile();
1664   }
1665
1666   for (f=[0,1]) {
1667     translate([-30, -60 + 30*f]) {
1668       translate([0,0,-4]) EdgeProfile();
1669       %translate([0,0,-10]) HingeBaseProfile();
1670       translate([0,-2] * f * hp_k) {
1671         translate([0,0,-4]) LidEdgeProfile();
1672         %translate([0,0,-10]) %HingeLidProfile();
1673       }
1674       translate(+hppB) rotate([0,0,180*f]) translate(-hppB) {
1675         translate([0,0,-2]) color("black") HingeLeverOuterProfile();
1676         translate([0,0,0]) color("red") difference(){
1677           HingeLeverOuterProfile();
1678           HingeLeverInnerProfile();
1679         }
1680         translate([0,0,3]) color("yellow") HingeLeverNutProfile();
1681       }
1682     }
1683   }
1684
1685   translate([20,-30]) {
1686     %EdgeProfile();
1687     %LidEdgeProfile();
1688     //translate([0,0,1]) CatchCutProfile();
1689     color("blue") CatchCatchProfile();
1690     color("red") difference(){ EdgeProfile(); CatchCutProfile(); }
1691   }
1692
1693   translate([40,-30]) {
1694     difference(){
1695       LidEdgeProfile();
1696       translate(prlp10)
1697         PropProfile(10, 1, 0);
1698     }
1699     translate(prlp10)
1700       PropProfile(15, 0);
1701   }
1702   translate([60,-30]) {
1703     PropAggregateProfile();
1704   }
1705 }
1706
1707 //EdgeProfile();
1708 //KeeperProfile();
1709 //CaseBase();
1710 //%Case();
1711 //Keeper();
1712 //LidEdgeProfile();
1713 //KeeperProfile();
1714 //DemoProfiles();
1715 //PropRecess();