fairphone-case.scad

   1 // -*- C -*-
   2
   3 include <utils.scad>
   4
   5 phone = [ 75.0, 145.0 ];
   6
   7 prop_buildout_less = 3;
   8
   9 prop_angles = [ 15, 30, 45, 60 ];
  10
  11 bumper = [ 0.250, -0.025 ];
  12 // ^ One side.  Overall size is increased by twice this.
  13 // If no bumpers, is the gap around the phone.
  14
  15 enable_support = 1;
  16
  17 phone_cnr_rad = 6.0;
  18
  19 button_cutout_depth = 9;
  20
  21 phone_edge_thick = 9.0;
  22 phone_total_thick = 12.0;
  23 phone_backside_slope_inner = 1.5; // larger means shallower
  24 phone_backside_slope_outer = 1.0; // larger means shallower
  25
  26 camera_pos_tl = [  6.450, 12.750 ]; // measured from tl corner
  27 camera_pos_br = [ 22.300, 37.600 ]; // tl/br as seen from back
  28
  29 jack_pos = [ 13.83, 8.485 ];
  30 jack_dia = 10.64 + .5; // some jack I had lying around
  31
  32 noisecancelmic_pos = [ 19.54, 7.37 ];   // from rhs
  33 noisecancelmic_dia = 4.00;
  34
  35 //fingerpushhole_dias = [ 15, 18 ];
  36 fingerpushhole_dias = [];
  37
  38 rearspeaker_pos_bl = [ 12.64, 18.72 ];
  39 rearspeaker_size   = [  3.76,  7.36 ];
  40
  41 microusb_above = 3.27 - 0.25;
  42 microusb_below = 0.0;
  43 microusb_width = 16.12 + 1.25;
  44
  45 case_th_bottom = 2.5;
  46 case_th_lid = 2.5;
  47 case_th_side = 2;
  48 case_th_lip = 1.2;
  49
  50 case_struts_count = 6;
  51 case_struts_solid_below = 1.00;
  52 case_struts_solid_above = 0.75;
  53 case_struts_width = 0.10;
  54
  55 keeper_th_z = 0.75;
  56 keeper_th_x = 0.75;
  57 keeper_inner_width = 2.75;
  58 keeper_inner_height = 2.75;
  59 keeper_slant_slope = 2; // larger means steeper
  60
  61 keeper_gap_z_top = 0.25;
  62 keeper_gap_z_bot = 0.75;
  63 keeper_gap_x     = 0.25;
  64 keeper_gap_x_holes = 0.75;
  65
  66 keeper_side = 0; // 0 = lhs; 1 = rhs
  67
  68 case_lip = 1.25;
  69
  70 lid_gap_x = 0.25;
  71 lid_gap_z = 0.25;
  72 lid_lip = 1.75;
  73
  74 catch_slop = 0.50;
  75
  76 foldover_gap = 0.50;
  77 foldover_lever_gap = 0.50;
  78
  79 hingescrew_shaft_dia = 2.0 + 0.25; // M2 x 12mm machine screw
  80 hingescrew_shaft_len = 12;
  81 hingescrew_nut_thick = 1.93 + 0.20; // incl. washer
  82 hingescrew_nut_dia = 4.72 + 0.50; // washer, actually
  83 hingescrew_head_th = 1.38 + 0.75;
  84 hingescrew_head_dia = 3.92;
  85 lever_cover_th = 0.75;
  86 hingemount_th = 2.5;
  87
  88 $fa = 5;
  89 $fs = 0.1;
  90
  91 button_l_fudge = 4.4;
  92 buttonishleg_default_l_is_fudge = 10;
  93
  94 hinge_base_slope = 1.5; // bigger is steeper
  95
  96 strut_min_at_end = 1.5;
  97
  98 hinge_x_gap = 0.125;
  99 hinge_x_postscrew_gap = 0.75;
 100 hinge_x_arms_gap = 0.35;
 101 hinge_r_arms_gap = 0.55;
 102
 103 rearspeaker_gap    = [ 2.0, 2.0 ]; // each side
 104
 105 catch_len = 7.5;
 106 catch_width = 15;
 107 catch_thickness = 1.0;
 108 catch_side_gap = 0.75; // each side
 109
 110 catch_depth = 0.75;
 111 catch_height = 0.35;
 112 catch_finger_height = 1.5;
 113 catch_finger_depth = 2.5;
 114
 115 prop_recess_under = 0.50;
 116 prop_recess_slop = 0.200; // each side
 117 prop_end_dia = 0.5;
 118 prop_main_th = 3;
 119 prop_taper_len = 6;
 120 prop_main_width = 4;
 121 prop_side_gap = 0.75; // each side
 122 prop_lidrecess_behind = 0.75;
 123 prop_caserecess_behind = 0.75;
 124 prop_caserecess_taper = 0.45; // one side only
 125 prop_prop_gap = 0.5;
 126 prop_prong_heel_slope = 0.5;
 127
 128 // ---------- calculated ----------
 129
 130 phone_width =  (phone + bumper*2)[0];
 131 phone_height = (phone + bumper*2)[1];
 132
 133 inside_br = [phone_width, -phone_height];
 134
 135 prop_prong_h = prop_main_th;
 136
 137 //echo(camera_pos_tl + bumper,
 138 //     camera_pos_br + bumper);
 139
 140 // ----- could be changed -----
 141 lid_buttoncover_gap = lid_gap_x;
 142 lid_buttoncover_overlap = case_th_lip + keeper_gap_z_top;
 143
 144 phone_backside_slope_thick = phone_total_thick - phone_edge_thick;
 145
 146 //prop_lidrecess_depth = case_th_lid - prop_recess_under;
 147
 148 //prop_nose_len = case_th_lid - prop_recess_under;
 149 //prop_recess_slope = tan(prop_max_angle); // bigger means steeper
 150 //prop_recess_width = prop_main_th / cos(prop_max_angle) + prop_backfwd_gap;
 151
 152
 153 //lid_lip_overlap_width xxx bad name = ;
 154 //lid_lip_inner_slope = [ 5, 5 ]; // xxx
 155
 156 epp0 = [0,0];
 157 epp1 = [0, -phone_edge_thick];
 158 epp2i = epp1 + phone_backside_slope_thick * [ phone_backside_slope_inner, -1 ];
 159 epp2o = epp1 + phone_backside_slope_thick * [ phone_backside_slope_outer, -1 ];
 160 epp3 = epp2i + [10, 0];
 161 epp5 = epp0 + [0,1] * (keeper_th_z + keeper_gap_z_top + case_lip);
 162 epp4 = epp5 + [-1,0] * case_th_side;
 163
 164 kppe = [0,0];
 165 kppd = kppe + [1,0] * keeper_inner_width;
 166 kppc = kppd + [0,1] * keeper_th_z;
 167 kppb = [ kppe[0] - keeper_th_x, kppc[1] ];
 168 kppf = kppe - [0,1] * keeper_inner_height;
 169 kppa = [ kppb[0], kppf[1] ];
 170
 171 lpp10 = [ epp5[0] + lid_gap_x, kppc[1] + lid_gap_z ];
 172 lpp11 = [ lpp10[0],            epp5[1] + lid_gap_z ];
 173
 174 lp_r12 = case_th_lid - (lpp11[1] - lpp10[1]);
 175
 176 lpp12 = [ epp4[0] + lp_r12,    lpp11[1] ];
 177 lpp13 = [ lpp12[0],            lpp12[1] + lp_r12 ];
 178
 179 case_bottom_z = epp2o[1] - case_th_bottom;
 180
 181 // button profile
 182 bppM = epp4 + [0,5];
 183 bppN = [ 0.5 * (epp0[0] + epp4[0]), bppM[1] ];
 184 bppR = [ bppN[0] + lid_buttoncover_gap, -button_cutout_depth ];
 185 bppS = [ epp1[0], bppR[1] ];
 186 bppQ = [ bppM[0], bppR[1] - lid_buttoncover_overlap ];
 187 bppP = bppQ + [0,1] * lid_buttoncover_gap;
 188 bppO = [ bppN[0], bppP[1] ];
 189 bppL = lpp10 + [5,0];
 190 bppK = [ bppL[0], bppN[1] ];
 191 bppJ = [ bppN[0], bppL[1] ];
 192 bppU = [ bppJ[0], lpp12[1] ];
 193 bppV = lpp11;
 194 bppW = lpp10;
 195
 196 // hinge plan
 197 hp_rn = hingescrew_nut_dia/2;
 198 hp_r2_min = hp_rn + lever_cover_th;
 199 hp_rs = hingescrew_shaft_dia/2;
 200 hp_r1_min = hp_rs + hingemount_th;
 201
 202 hp_r1 = max(hp_r1_min, hp_r2_min);
 203 hp_r2 = hp_r1;
 204
 205 hppU = lpp13;
 206 hppS = epp2o + [0,-1] * case_th_bottom;
 207 hp_k = 0.5 * (hppU[1] - hppS[1] + foldover_gap);
 208
 209 hppM = [ epp4[0] - foldover_lever_gap - hp_r2,
 210          0.5 * (hppU + hppS)[1] ];
 211 hppT = [ hppM[0], hppU[1] - hp_r1 ];
 212 hppB = hppT + [0,-1] * hp_k;
 213
 214 hppE_y = epp2o[1] - case_th_bottom + hp_r1;
 215 hppE_x = hppB[0] + (hppB[1] - hppE_y) * hinge_base_slope;
 216 hppE = [ hppE_x, hppE_y ];
 217
 218 // hinge elevation x coords
 219
 220 hingescrew_portion_len =
 221   0.5* (hingescrew_shaft_len - hingescrew_nut_thick - hinge_x_gap);
 222
 223 hex20 = max(epp2o[0],
 224             phone_cnr_rad,
 225             kppd[0] + hingescrew_head_th + keeper_gap_x_holes);
 226 hex21 = hex20 + hingescrew_portion_len;
 227 hex22 = hex21 + hinge_x_gap;
 228 hex23 = hex22 + hingescrew_portion_len
 229   - hingescrew_nut_thick; // bodge, need to divvy this up more sensibly
 230 hex24 = hex20 + hingescrew_shaft_len + hinge_x_postscrew_gap;
 231 //echo(hex20, hex21, hex22, hex23, hex24);
 232 //echo(hingescrew_portion_len);
 233
 234 // catch
 235
 236 cppJ = [ epp4[0] + catch_thickness, lpp10[1] ];
 237 cppA = cppJ + [lid_gap_x, -lid_gap_z];
 238 cppB = [ epp0[0], cppA[1] ];
 239 cppP = [ epp4[0], cppJ[1] ];
 240
 241 cppS = cppJ + [0,-1] * catch_len;
 242 cppD = [ cppA[0], cppS[1] + catch_slop ];
 243 cppC = [ cppB[0], cppD[1] ];
 244 cppT = cppS + [1,0] * catch_depth;
 245 cppU = cppT + [0,-1] * catch_height;
 246 cppV = [ cppS[0], cppU[1] - catch_depth ];
 247
 248 cppR = 0.5*(cppP + cppJ);
 249
 250 cp_rQ = 0.5 * (cppJ[0] - cppP[0]);
 251 cppQ = [ cppR[0],
 252          cppV[1] - (catch_finger_height - cp_rQ) ];
 253 cppF = [ cppV[0] + catch_finger_depth, cppC[1] ];
 254
 255 // prop recess in case
 256
 257 prop_x_pos = phone_width/2;
 258
 259 prop_recess_hw = 0.5 * prop_main_width + prop_side_gap;
 260
 261 prc_r1 = prop_end_dia/2;
 262 prc_r3 = prc_r1 + prop_recess_slop;
 263
 264 prcp2 = [ epp4[0] + prop_buildout_less,
 265           case_bottom_z ];
 266
 267 prop_caserecess_buildout_r = -1; // prcp2[0] - epp2o[0];
 268
 269 prcp1 = [ epp2o[0] + prc_r3 + prop_caserecess_behind,
 270           epp2i[1] - prc_r3 - prop_recess_under];
 271
 272 // prop recess in lid
 273
 274 prl_r10 = prop_end_dia/2;
 275 prl_r10o = prl_r10 + prop_recess_slop;
 276
 277 prlp10 = lpp10 + [1,1] * prl_r10o
 278   + [1,0] * prop_lidrecess_behind
 279   + [0,1] * prop_recess_under;
 280
 281 // prop
 282
 283 $prpp10 = [0,0];
 284 $prpp11 = [0, prop_taper_len];
 285
 286 $prp_r10 = prl_r10;
 287
 288 // ---------- modules ----------
 289
 290 module KeeperProfile(slant=0){
 291   use_e = kppe + [0,-1] * slant * keeper_inner_width / keeper_slant_slope;
 292   polygon([use_e, kppd, kppc, kppb, kppa, kppf]);
 293 }
 294
 295 module EdgeProfile(){
 296   difference(){
 297     hull(){
 298       translate(epp3) square(case_th_bottom*2, center=true);
 299       circleat(epp2o, r=case_th_bottom);
 300       circleat(epp1, r=case_th_side);
 301       rectfromto(epp0, epp4);
 302     }
 303     polygon([ epp5 + [0,10],
 304               epp1,
 305               epp2i,
 306               epp3 + [10,0] ]);
 307   }
 308 }
 309
 310 module LidEdgeProfile(){
 311   polygon([ lpp10,
 312             lpp11,
 313             lpp12,
 314             lpp13,
 315             lpp13 + [10, 0],
 316             lpp10 + [10, 0]
 317             ]);
 318   intersection(){
 319     circleat(lpp12, r=lp_r12);
 320     rectfromto( lpp12 + [-10,   0],
 321                 lpp12 + [+10, +10] );
 322   }
 323 }
 324
 325 module ButtonCoverProfile(){
 326   intersection(){
 327     polygon(concat([ bppM, bppP, bppO, bppJ ],
 328                    (enable_support ? [ bppU, bppV, bppW ] : []),
 329                    [ bppL, bppK ]));
 330     hull(){
 331       EdgeProfile();
 332       LidEdgeProfile();
 333     }
 334   }
 335 }
 336
 337 module ButtonPlan(l, deep, cut){
 338   epsilon =
 339     (cut  ? 0 : lid_buttoncover_gap);
 340
 341   delta =
 342     (deep ? lid_buttoncover_overlap : 0);
 343
 344   C = [0,0]; // by definition
 345   T = [ 0, epp4[1] ];
 346   G = T + [0,10];
 347
 348   B0 = C + [0,-1] * button_cutout_depth;
 349   B1 = B0 + [0,1] * epsilon;
 350
 351   r0 = 0.5 * (T[1] - B0[1]);
 352   A = [  -(l + button_l_fudge)/2 + r0, 0.5 * (T[1] + B0[1]) ];
 353   H = A + [0,-1] * delta;
 354
 355   D = A + [-2,0] * r0;
 356   F = D + [0,10];
 357
 358   E0 = 0.5 * (D + A);
 359   E1 = E0 + [1,0] * epsilon;
 360
 361   I0 = [ E0[0], H[1] ];
 362   I1 = [ E1[0], H[1] ];
 363
 364   hull(){
 365     for (m=[0,1]) mirror([m,0])
 366       circleat(H, r0 - epsilon);
 367   }
 368   for (m=[0,1]) mirror([m,0]) {
 369     difference(){
 370       polygon([ E1,
 371                 I1,
 372                 H,
 373                 B1,
 374                 G,
 375                 F,
 376                 D
 377                 ]);
 378       circleat(D, r0 + epsilon);
 379     }
 380   }
 381 }
 382
 383 module CatchCatchProfile(){
 384   hull(){
 385     for (c=[ cppR, cppQ ])
 386       circleat(c, cp_rQ);
 387   }
 388   hull(){
 389     circleat(lpp12, lp_r12);
 390     circleat(lpp12 + [5,0], lp_r12);
 391     rectfromto(cppP, cppP + [5,0.1]);
 392   }
 393   polygon([cppJ, cppS, cppT, cppU, cppV, cppQ, cppR]);
 394 }
 395
 396 module CatchCutProfile(){
 397   polygon([ cppB,
 398             cppA,
 399             cppD,
 400             cppF,
 401             cppF + [0,-10],
 402             cppF + [-10,-10],
 403             lpp12 + [-10,0],
 404             lpp12 + [10,0]
 405             ]);
 406 }
 407
 408 module Flip_rhs(yn=[0,1]) {
 409   for ($rhsflip=yn) {
 410     translate([phone_width/2, 0, 0])
 411       mirror([$rhsflip,0,0])
 412       translate([-phone_width/2, 0, 0])
 413       children();
 414   }
 415 }
 416
 417 module Flip_bot(yn=[0,1]) {
 418   for ($botflip=yn) {
 419     translate([0, -phone_height/2, 0])
 420       mirror([0, $botflip, 0])
 421       translate([0, phone_height/2, 0])
 422       children();
 423   }
 424 }
 425
 426 module AroundEdges(fill_zstart, fill_th, fill_downwards=0){
 427   // sides
 428   Flip_rhs(){
 429     translate([0, -phone_cnr_rad, 0])
 430       rotate([90,0,0])
 431       linear_extrude(height = phone_height - phone_cnr_rad*2)
 432       children(0);
 433   }
 434   // corners
 435   Flip_rhs() Flip_bot() {
 436     translate([+1,-1] * phone_cnr_rad)
 437       intersection(){
 438         rotate_extrude()
 439           intersection(){
 440             mirror([1,0,0])
 441               translate([-1,0] * phone_cnr_rad)
 442               children(0);
 443             rectfromto([0,-20],[10,20]);
 444           }
 445         translate([-10, 0, -20] + 0.01 * [+1,-1, 0] )
 446           cube([10,10,40]);
 447       }
 448   }
 449   // top and bottom
 450   Flip_bot(){
 451     translate([ phone_width - phone_cnr_rad, 0,0 ])
 452       rotate([90,0,-90])
 453       linear_extrude(height = phone_width - phone_cnr_rad*2)
 454       children(0);
 455   }
 456   // fill
 457   translate([0,0, fill_zstart])
 458     mirror([0,0, fill_downwards])
 459     linear_extrude(height = fill_th)
 460     rectfromto([+1,-1] * phone_cnr_rad,
 461                [phone_width, -phone_height] + [-1,+1] * phone_cnr_rad);
 462 }
 463
 464 module CaseAperture(pos, dia, $fn) {
 465   theta = 180/$fn;
 466   translate([ pos[0] + bumper[0],
 467               -epp2i[0],
 468               -pos[1] ])
 469     rotate([-90, theta, 0])
 470     cylinder(r = dia/2 / cos(theta),
 471              h = 60);
 472 }
 473
 474 module SideButton(y, y_ref_sign, l){
 475   // y_ref_sign:
 476   //   +1  measured from top    of actual phone to top    of button
 477   //   -1  measured from bottom of actual phone to bottom of button
 478   //    0  y is centre of button in coordinate system
 479   $button_l= l;
 480   eff_y = y_ref_sign > 0 ?         -bumper [1] -y -l/2 :
 481           y_ref_sign < 0 ? (-phone -bumper)[1] +y +l/2 :
 482           y;
 483   //echo(eff_y);
 484   translate([0, eff_y, 0])
 485     children();
 486 }
 487
 488 module LidButtonishLeg(y, y_ref_sign, l=buttonishleg_default_l_is_fudge) {
 489   $button_leg_only = true;
 490   SideButton(y, y_ref_sign, l) children();
 491 }
 492
 493 module Buttons(){
 494   Flip_rhs(1) SideButton(15.580, +1, 8.9) children(); // power
 495   Flip_rhs(1) SideButton(48.700, -1, 8.920) children(); // camera
 496   Flip_rhs(0) SideButton(30.800, +1, 21.96) children(); // volume
 497   Flip_rhs(   ) LidButtonishLeg(14, -1) children();
 498 //  Flip_rhs(0) LidButtonishLeg(20, +1, 20) children();
 499 }
 500
 501 module Struts(x_start, z_min, th){
 502   // if th is negative, starts at z_min and works towards -ve z
 503   // and object should then be printed other way up
 504   for (i= [1 : 1 : case_struts_count]) {
 505     translate([0,
 506                0,
 507                z_min])
 508       mirror([0,0, th<0 ? 1 : 0])
 509       translate([0,
 510                  -phone_height * i / (case_struts_count+1),
 511                  case_struts_solid_below])
 512       linear_extrude(height= abs(th)
 513                      -(case_struts_solid_below+case_struts_solid_above))
 514       rectfromto([               x_start, -0.5 * case_struts_width ],
 515                  [ phone_width - x_start, +0.5 * case_struts_width ]);
 516   }
 517 }
 518
 519 module OrdinaryRearAperture(rhs,bot, pos){
 520   Flip_rhs(rhs) Flip_bot(bot)
 521     linextr(-20, 20)
 522     mirror([0,1])
 523     translate(pos + bumper)
 524     children();
 525 }
 526
 527 module MicroUSB(){
 528   Flip_bot(1){
 529     rotate([90,0,0])
 530       mirror([0,0,1])
 531       linextr(-epp2i[0], 60)
 532       translate([0.5 * phone_width, 0, 0])
 533       rectfromto([-microusb_width/2, epp2i[1] + microusb_below],
 534                  [+microusb_width/2, epp0[1] + -microusb_above]);
 535   }
 536 }
 537
 538 module OrdinaryRearApertures(){
 539   // rear speaker
 540   OrdinaryRearAperture(1,1, rearspeaker_pos_bl)
 541     rectfromto(-rearspeaker_gap,
 542                rearspeaker_size + rearspeaker_gap);
 543
 544   // finger hole to remove phone
 545   if (len(fingerpushhole_dias))
 546     OrdinaryRearAperture(1,0, [ fingerpushhole_dias[0]/2 + epp2i[0],
 547                                 phone[1]/2 ])
 548     scale(fingerpushhole_dias)
 549     circle(r= 0.5 );
 550 }
 551
 552 module RearCameraAperture(){
 553   Flip_rhs(1)
 554     mirror([0, 0, 1])
 555     linear_extrude(height = 20)
 556     mirror([0, 1, 0])
 557     translate(bumper)
 558     rectfromto(camera_pos_tl, camera_pos_br);
 559 }
 560
 561 module HingeLidProfile(){
 562   hull(){
 563     circleat(hppT, hp_r1);
 564     circleat(lpp12, lp_r12);
 565     polygon([lpp10,
 566              lpp13 + [2,0],
 567              lpp12,
 568              hppT]);
 569   }
 570 }
 571
 572 module HingeBaseProfile(){
 573   difference(){
 574     hull(){
 575       circleat(hppB, hp_r1);
 576       circleat(hppE, hp_r1);
 577       circleat(epp2o, case_th_bottom);
 578       circleat(hppB + [10,0], hp_r1);
 579     }
 580     polygon([epp5, epp1, epp2i, epp3, bppL]);
 581   }
 582 }
 583
 584 module HingeLeverOuterProfile(){
 585   hull(){
 586     circleat(hppT, hp_r2);
 587     circleat(hppB, hp_r2);
 588   }
 589 }
 590
 591 module HingeLeverInnerProfile(){
 592   for (s = [-1,+1]) {
 593     c = s > 0 ? hppT : hppB;
 594     translate(c)
 595       mirror([0,0,s>0])
 596       hull()
 597       for (x=[-20,20])
 598         for (y=[0, s * 10])
 599           translate([x,y])
 600             circle(hp_rn);
 601   }
 602 }
 603
 604 module Flip_hinge(){
 605   hinge_origin = [0, -(phone_height - hppB[0]), hppB[1]];
 606   translate(hinge_origin)
 607     rotate([180,0,0])
 608     translate(-hinge_origin)
 609     children();
 610 }
 611
 612 module HingePortion(x0,x1){
 613   Flip_rhs() Flip_bot(1)
 614     translate([x0,0,0])
 615     mirror([1,0,0])
 616     rotate([90,0,-90])
 617     linear_extrude(height=x1-x0)
 618     children(0);
 619 }
 620
 621 module CatchPortion(width){
 622   translate([phone_width/2, 0,0])
 623     rotate([90,0,-90])
 624     linextr(-width/2, width/2)
 625     children(0);
 626 }
 627
 628 module CaseBase(){
 629   AroundEdges(epp3[1], case_th_bottom, 1)
 630     EdgeProfile();
 631 }
 632
 633 function prop_x(gamma) = hp_k / (2 * sin(gamma/2)) - hppT[0];
 634
 635 module PropProfileAssignments(gamma){
 636   // https://en.wikipedia.org/wiki/Solution_of_triangles#Two_sides_and_the_included_angle_given_(SAS)
 637   x = prop_x(gamma);
 638   p = phone_height + prlp10[0] - hppB[0];
 639   b = p + x;
 640
 641   q = phone_height - hppT[0] - prcp1[0]; // $prpp7[0] is 0 by definition
 642   a = q + x;
 643   c = sqrt(a*a + b*b - 2*a*b*cos(gamma));
 644   $prp_alpha = acos( (b*b + c*c - a*a) / (2*b*c) );
 645
 646   $prp_theta = 90 - $prp_alpha;
 647   beta = 180 - $prp_alpha - gamma;
 648   psi = 90 - beta;
 649
 650   //echo("abc", a,b,c);
 651
 652   v1 = [ [ cos(psi), -sin(psi) ],    // x
 653          [ sin(psi),  cos(psi) ] ];  // y
 654
 655   $prpp7 = [0, c + (lpp13[1] - $prpp10[1] - hp_k) ];
 656
 657   $prp_r1 = prc_r1;
 658   $prp_r11 = prop_main_th/2;
 659
 660   $prpp1 = $prpp7 + [1,0] *
 661     // this is approximate, but will do
 662     (prop_main_th/2 + prop_prop_gap + prcp1[0] - cppA[0]);
 663   $prpp3 = $prpp1 +
 664     v1[0] * -$prp_r1 +
 665     v1[1] * ((prcp2[1] - prcp1[1]) - prop_prop_gap);
 666   $prpp12 = $prpp3 + v1[0] *
 667     (prop_end_dia + prop_caserecess_taper * ($prpp1[1] - $prpp3[1]));
 668   $prp_r8 = prop_main_th;
 669   $prpp4 = [ prop_main_th/2, $prpp3[1] ];
 670   $prp_r5 = $prp_r8;
 671   $prpp5 = [ $prpp12[0] - $prp_r5,
 672             $prpp3[1] - prop_prong_h + $prp_r5 ];
 673   $prpp6 = $prpp4 + [0,-1] * (prop_prong_h +
 674          prop_prong_heel_slope * ($prpp5[0] - $prpp4[0]));
 675   $prpp8 = $prpp4 + [0,-1] * $prp_r8;
 676   $prpp9 = $prpp8 + [-1,0] * $prp_r8;
 677
 678   children();
 679 }
 680
 681 module PropProfile(gamma, cut=0, rot=0){ ////toplevel
 682   PropProfileAssignments(gamma){
 683
 684     //#circleat($prpp3,1);
 685     //#circleat($prpp12,1);
 686
 687     if (!cut) {
 688       hull(){
 689         translate($prpp8)
 690           intersection(){
 691             circle($prp_r8);
 692             polygon([[-20,-0], [20,20], [0,0]]);
 693           }
 694         rectfromto($prpp6, $prpp9);
 695         translate($prpp5) intersection(){
 696           circle($prp_r5);
 697           polygon([[-10,-10], [0,0], [10,0]]);
 698         }
 699         rectfromto($prpp12 + [0,-0.1], $prpp3);
 700       }
 701       hull(){
 702         circleat($prpp1, $prp_r1);
 703         rectfromto($prpp12 + [0,-0.1], $prpp3);
 704       }
 705     }
 706     // main shaft
 707     rotate([0,0, rot*-$prp_theta]){
 708       hull(){
 709         extra = cut ? prop_recess_slop : 0;
 710         rectfromto($prpp6, $prpp9);
 711         circleat($prpp11, $prp_r11 + extra);
 712         circleat($prpp10, $prp_r10 + extra);
 713       }
 714     }
 715   }
 716 }
 717
 718 module PropAggregateProfile(){
 719   for (angle = prop_angles)
 720     PropProfile(angle, 0,0);
 721 }
 722
 723 module Prop(){ ////toplevel
 724   hw = prop_main_width/2;
 725   linextr(-hw, +hw)
 726     PropAggregateProfile();
 727 }
 728
 729 module Case(){ ////toplevel
 730   difference(){
 731     union(){
 732       CaseBase();
 733
 734       // ledge (fixed keeper)
 735       Flip_rhs(1-keeper_side) intersection(){
 736         rotate([90, 0, 0])
 737           linear_extrude(height = phone_height + phone_cnr_rad * 2)
 738           KeeperProfile(1);
 739
 740         // outline of the whole case, to stop it protruding
 741         translate([0,0, -25])
 742           linear_extrude(height = 50)
 743           hull()
 744           Flip_bot()
 745           circleat([+1,-1] * phone_cnr_rad, phone_cnr_rad + case_th_side/2);
 746       }
 747
 748       // hinge
 749       HingePortion(hex20, hex21) HingeBaseProfile();
 750
 751       // buildout for prop recess
 752       if (prop_caserecess_buildout_r > 0) Flip_rhs(1)
 753         linextr(case_bottom_z, epp2i[1])
 754         hull() {
 755           for (dxs = [-1,+1])
 756             circleat([ prop_x_pos + dxs * prop_caserecess_buildout_r,
 757                        -epp2o[0] ],
 758                      r = epp2o[0] - prcp2[0]);
 759         }
 760     }
 761
 762     // slot for keeper
 763     Flip_rhs(keeper_side)
 764       translate([0, -phone_cnr_rad, 0])
 765       rotate([90, 0, 0])
 766       linear_extrude(height = phone_height + phone_cnr_rad * 2)
 767       minkowski(){
 768         KeeperProfile();
 769         rectfromto([ -keeper_gap_x,    -keeper_gap_z_bot ],
 770                    [ keeper_gap_x_holes,    +keeper_gap_z_top ]);
 771       }
 772
 773     // front camera
 774     RearCameraAperture();
 775
 776     // struts (invisible, because they're buried in the case)
 777     Struts(epp2i[0], epp2i[1] - case_th_bottom, case_th_bottom);
 778
 779     Buttons(){
 780       mirror([1,0,0])
 781         rotate([90,0,90]) {
 782           if (!($button_leg_only && enable_support))
 783           intersection(){
 784             translate([0,0,-10])
 785               linear_extrude(height= 20)
 786               ButtonPlan($button_l, 0,1);
 787             if ($button_leg_only)
 788               rotate([-90,90,0])
 789                 translate([phone_width/2, -400, kppe[1]])
 790                 mirror([1-abs($rhsflip - keeper_side),0,0])
 791                 cube([400, 800, 50]);
 792             if (enable_support)
 793               rotate([-90,90,0])
 794               translate([-400, -400, kppd[1]])
 795                 mirror([0,0,1])
 796                 cube([800,800,100]);
 797           }
 798           translate([0,0, -bppR[0]])
 799             linear_extrude(height= 20)
 800             ButtonPlan($button_l, 1,1);
 801         }
 802
 803     }
 804
 805     // apertures along top edge
 806     CaseAperture(jack_pos, jack_dia, 8);
 807     Flip_rhs(1)
 808       CaseAperture(noisecancelmic_pos, noisecancelmic_dia, 8);
 809
 810     OrdinaryRearApertures();
 811
 812     MicroUSB();
 813
 814     // gaps for the lid's hinge arms
 815     HingePortion(hex20 - hinge_x_arms_gap,
 816                  hex21 + hinge_x_arms_gap)
 817       minkowski(){
 818         HingeLidProfile();
 819         circle(r= hinge_r_arms_gap, $fn= 8);
 820       }
 821
 822     // screw holes in the hinge arms
 823     HingeScrews();
 824
 825     // catch striker
 826     CatchPortion(catch_width + catch_side_gap*2)
 827       CatchCutProfile();
 828
 829     // prop recess
 830     Flip_rhs(1)
 831       translate([prop_x_pos,0,0])
 832       mirror([0,1,0])
 833       rotate([90,0,90])
 834       linextr(-prop_recess_hw, +prop_recess_hw)
 835       hull(){
 836         for (d=[ [0,0], [0,-1], [+1,-1/prop_caserecess_taper] ])
 837           circleat(prcp1 + 20*d,
 838                    prc_r3);
 839       }
 840   }
 841 }
 842
 843 module Lid(){ ////toplevel
 844   difference(){
 845     union(){
 846       AroundEdges(lpp10[1], lpp13[1] - lpp10[1], 0)
 847         LidEdgeProfile();
 848
 849       // button covers
 850       Buttons(){
 851         intersection(){
 852           rotate([90,0,90])
 853             translate([0,0,-10])
 854             linear_extrude(height= 20)
 855             ButtonPlan($button_l, 1,0);
 856           rotate([90,0,0])
 857              translate([0,0,-100])
 858             linear_extrude(height= 200)
 859             ButtonCoverProfile();
 860         }
 861       }
 862
 863       // hinge arms
 864       HingePortion(hex20, hex21) HingeLidProfile();
 865
 866       // catch
 867       CatchPortion(catch_width)
 868         CatchCatchProfile();
 869     }
 870     Struts(lpp10[0] + strut_min_at_end, lpp13[1], -case_th_lid);
 871
 872     // screw holes in the hinge arms
 873     HingeScrews();
 874
 875     // prop recess
 876     translate([prop_x_pos, -prlp10[0], prlp10[1]])
 877       mirror([0,1,0])
 878       rotate([90,0,90])
 879       linextr(-prop_recess_hw, +prop_recess_hw)
 880       hull()
 881       for (pa = prop_angles)
 882         PropProfile(pa, 1,1);
 883   }
 884 }
 885
 886 module HingeLever(){ ////toplevel
 887   difference() {
 888     // outer body, positive
 889     HingePortion(hex22, hex22 + phone_width/2)
 890       HingeLeverOuterProfile();
 891
 892     // space for the screws
 893     HingePortion(hex23, hex24)
 894       HingeLeverInnerProfile();
 895
 896     // bores for the screws
 897     HingeScrews();
 898
 899     // space for the charging cable
 900     MicroUSB();
 901     Flip_hinge() MicroUSB();
 902   }
 903 }
 904
 905 module HingeLeverPrint(){ ////toplevel
 906   rotate([90,0,0])
 907     HingeLever();
 908 }
 909
 910 module TestSelectLength(){
 911   translate([-30, -200, -20])
 912     cube([30 + 15, 250, 40]);
 913 }
 914
 915 module TestLength(){ ////toplevel
 916   intersection(){
 917     Case();
 918     TestSelectLength();
 919   }
 920 }
 921
 922 module TestLengthRight(){ ////toplevel
 923   intersection(){
 924     Case();
 925     Flip_rhs(1)
 926       TestSelectLength();
 927   }
 928 }
 929
 930 module TestSelectWidth(){
 931   translate([-30, -(phone_height - 25), -20])
 932     mirror([0, 1, 0])
 933     cube([200, 50, 40]);
 934 }
 935
 936 module TestWidth(){ ////toplevel
 937   intersection(){
 938     Case();
 939     TestSelectWidth();
 940   }
 941 }
 942
 943 module TestLidWidthPrint(){ ////toplevel
 944   rotate([0,180.0]) intersection(){
 945     Lid();
 946     TestSelectWidth();
 947   }
 948 }
 949
 950 module TestSelectRearAperture(){
 951   minkowski(){
 952     union() children();
 953     translate([20, 0,0])
 954       cube([42, 2, 1], center=true);
 955   }
 956 }
 957
 958 module TestSelectCamera(){
 959   minkowski(){
 960     TestSelectRearAperture()
 961       RearCameraAperture();
 962     cube([0.1, 50, 0.1]);
 963   }
 964 }
 965
 966 module TestSelectOrdinaryRearApertures(){
 967   TestSelectRearAperture()
 968     OrdinaryRearApertures();
 969 }
 970
 971 module TestCamera(){ ////toplevel
 972   intersection(){
 973     Case();
 974     TestSelectCamera();
 975   }
 976 }
 977
 978 module TestLidByCamera(){ ////toplevel
 979   intersection(){
 980     Lid();
 981     TestSelectCamera();
 982   }
 983 }
 984
 985 module TestLidByCameraPrint(){ ////toplevel
 986   rotate([180,0,0]) TestLidByCamera();
 987 }
 988
 989 module DemoByCamera(){ ////toplevel
 990   color("blue") TestLidByCamera();
 991   color("red")  TestCamera();
 992 }
 993
 994 module OneKeeper(){ ////toplevel
 995   translate([0, -phone_cnr_rad, 0])
 996     rotate([90, 0, 0])
 997     linear_extrude(height = phone_height - phone_cnr_rad * 2)
 998     KeeperProfile();
 999 }
1000
1001 module OneKeeperPrint(){ ////toplevel
1002   rotate([0,180,0])
1003     OneKeeper();
1004 }
1005
1006 module LidPrint(){ ////toplevel
1007   rotate([0,180,0])
1008     Lid();
1009 }
1010
1011 module TestSelectFrame(){
1012   include = [1,-1] * (epp2i[0] + 4);
1013
1014   difference(){
1015     cube(1000, center=true);
1016     translate([0,0, -100])
1017       linear_extrude(height=200)
1018       rectfromto(include,  inside_br - include);
1019   }
1020 }
1021
1022 module TestSelectLidFrame(){
1023   TestSelectFrame();
1024 }
1025
1026 module TestFrameCase(){ ////toplevel
1027   intersection(){
1028     Case();
1029     union(){
1030       TestSelectFrame();
1031       TestSelectCamera();
1032       TestSelectOrdinaryRearApertures();
1033     }
1034   }
1035 }
1036
1037 module TestTopApertures(){ ////toplevel
1038   intersection(){
1039     Case();
1040     TestSelectFrame();
1041     translate([-100, -35, -100])
1042       cube([400, 100, 200]);
1043   }
1044 }
1045
1046 module TestFrameLidPrint(){ ////toplevel
1047   rotate([0,180,0]) intersection(){
1048     Lid();
1049     TestSelectLidFrame();
1050   }
1051 }
1052
1053 module ButtonPlanForDemo(z, deep, cut){
1054   translate([0,0,z])
1055     ButtonPlan(8, deep, cut);
1056 }
1057
1058 module HingeScrews(){
1059   Flip_rhs() Flip_bot(1){
1060     for (c= [ hppT, hppB ])
1061       translate([ hex20,
1062                   -c[0],
1063                   c[1] ]){
1064         rotate([0,90,0])
1065           translate([0,0,-.2])
1066           cylinder( r= hingescrew_shaft_dia/2,
1067                     h = hingescrew_shaft_len+0.2 );
1068         rotate([0,-90,0])
1069           translate([0,0,+.1])
1070           cylinder( r= hingescrew_head_dia/2, h = hingescrew_head_th );
1071       }
1072   }
1073 }
1074
1075 module DemoPropAngleSelect(c){
1076   color(c) difference(){
1077     union(){ children(); }
1078     translate([ prop_x_pos, -400, -200 ])
1079       cube([ 400,800,400 ]);
1080   }
1081 }
1082
1083 module DemoPropAngle(ang){
1084   hL = [0, -(phone_height - hppT[0]), hppT[1] - hp_k*2];
1085   hC = [0, -(phone_height - hppB[0]), hppB[1]];
1086
1087   translate(hL)
1088     rotate([ang/2,0,0])
1089     translate(-hL)
1090     translate(hC)
1091     rotate([ang/2,0,0])
1092     translate(-hC) {
1093       DemoPropAngleSelect("red") Case();
1094
1095       color("orange")
1096         translate([prop_x_pos, -prcp1[0], prcp1[1]])
1097         PropProfileAssignments(ang) {
1098           echo($prpp1);
1099           rotate([-$prp_theta, 0, 0])
1100           translate([0, $prpp1[0], -$prpp1[1]])
1101           rotate([90,0,-90])
1102           Prop();
1103         }
1104     }
1105
1106   translate([0,0, -hp_k*2])
1107     DemoPropAngleSelect("blue")
1108     Lid();
1109 }
1110
1111 module DemoPropAngles(){ ////toplevel
1112   for (i=[0 : len(prop_angles)-1])
1113     translate(i * [0, -100, 100])
1114     DemoPropAngle(prop_angles[i]);
1115 }
1116
1117 module DemoFrame(){ ////toplevel
1118   color("red") TestFrameCase();
1119   color("blue") intersection(){ Lid(); TestSelectLidFrame(); }
1120   color("black") HingeScrews();
1121   %HingeLever();
1122 }
1123
1124 module DemoHingedFrame(){ ///toplevel
1125   color("red") TestFrameCase();
1126   translate([0,0, -2*hp_k])
1127   color("blue") intersection(){ Lid(); TestSelectLidFrame(); }
1128
1129   Flip_hinge(){
1130     color("orange") HingeLever();
1131     color("black") HingeScrews();
1132   }
1133 }
1134
1135 module DemoHinge(){ ////toplevel
1136   DemoFrame();
1137   translate([0,0, -hp_k*3])
1138     DemoHingedFrame();
1139 }
1140
1141 module DemoProfiles(){ ////toplevel
1142   LidEdgeProfile();
1143   %EdgeProfile();
1144   KeeperProfile();
1145   translate([0,0,-1]) color("black") KeeperProfile(1);
1146
1147   translate([20,0]) {
1148     LidEdgeProfile();
1149     %EdgeProfile();
1150
1151     demopoint_QR = [ bppS[0], bppQ[1] - 0.1];
1152
1153     color("blue") ButtonCoverProfile();
1154     color("red") {
1155       rectfromto(bppQ, demopoint_QR);
1156       rectfromto(bppR, demopoint_QR);
1157     }
1158   }
1159
1160   translate([-20,0]) {
1161     color("black") ButtonPlanForDemo(-2, 0,1);
1162     color("red" )  ButtonPlanForDemo(-4, 1,1);
1163     color("blue")  ButtonPlanForDemo(-6, 1,0);
1164   }
1165
1166   translate([0, -30]) {
1167     %LidEdgeProfile();
1168     %EdgeProfile();
1169     color("blue") HingeLidProfile();
1170     color("red")  HingeBaseProfile();
1171     color("black") translate([0,0,-2]) HingeLeverOuterProfile();
1172     color("orange") translate([0,0,-1]) HingeLeverInnerProfile();
1173   }
1174
1175   translate([20,-30]) {
1176     %EdgeProfile();
1177     %LidEdgeProfile();
1178     //translate([0,0,1]) CatchCutProfile();
1179     color("blue") CatchCatchProfile();
1180     color("red") difference(){ EdgeProfile(); CatchCutProfile(); }
1181   }
1182
1183   translate([40,-30]) {
1184     difference(){
1185       LidEdgeProfile();
1186       translate(prlp10)
1187         PropProfile(10, 1, 0);
1188     }
1189     translate(prlp10)
1190       PropProfile(15, 0);
1191   }
1192   translate([60,-30]) {
1193     PropAggregateProfile();
1194   }
1195 }
1196
1197 //EdgeProfile();
1198 //KeeperProfile();
1199 //CaseBase();
1200 //%Case();
1201 //Keeper();
1202 //LidEdgeProfile();
1203 //KeeperProfile();
1204 //DemoProfiles();
1205 //PropRecess();