commitid.scad.pl

   1 #!/usr/bin/perl -w
   2 use strict;
   3
   4 $SIG{__WARN__} = sub { die @_; };
   5
   6 #  xxx much of the comment below is TODO
   7 #
   8 # Usage:
   9 #
  10 #   .../commitid.scad.pl [OPTION...] [STRING...] >commitid.scad.new \
  11 #     && mv -f commitid.scad.new commitid.scad
  12 #
  13 # Options:
  14 #
  15 #   --git    generate git commit indications, as shown below
  16 #            (this is the default if no strings are requested with -t)
  17 #
  18 #   --git=object
  19 #            generate git commit indication based on commit object only
  20 #            (ie avoid counting commits)
  21 #
  22 #   -i       do not generate `+' if git-untracked files are present
  23 #
  24 #   [-t[FORM]] TEXT
  25 #            generate a form FORM containing TEXT
  26 #            TEXT can contain newlines (final newline usually undesirable)
  27 #            if FORM not specified, generates Arg0 Arg1 Arg2 in sequence
  28 #            character set is SPC 0-9 a-f + * (`*' glyph is `=/=').
  29 #
  30 # We generate a physical indication of which commit was used.
  31 #
  32 # We provide for scaling factors with dynamic variables:
  33 #    $Commitid_pixelsz        if not set, we use 0.8 } multiplied
  34 #    $Commitid_scale          if not set, we use 1.0 }  together
  35 #    $Commitid_depth          if not set, we use xy pixel size from above / 2
  36 #    $Commitid_depth_scale    if not set, we use 1.0 (multiplies depth above)
  37 #
  38 # For each form we have
  39 #
  40 #    module Commitid_Form_2D() { ... }
  41 #    module Commitid_Form() { ... }
  42 #    function Commitid_Form_sz()     => [ x, y ]
  43 #
  44 #  These have their origin in the bottom left corner.  The 3D model
  45 #  is a positive, has its origin halfway through, and is twice the
  46 #  depth in height, so it can be added or subtracted.
  47 #
  48 # And we provide
  49 #
  50 #   function Commitid_pixelsz()    // $Commitid_pixelsz * $Commitid_scale
  51 #   function Commitid_depth()      // see above
  52 #
  53 # We can generate these forms:
  54 #
  55 #   Small3:
  56 #   Small4:
  57 #   Small5:
  58 #   Small6:
  59 #   Small7:
  60 #   Small8:
  61 #   Small9:
  62 #   Small10:
  63 #       git rev-list --first-parent --count HEAD
  64 #       typically 3-4 characters but we allow for up to 6
  65 #       padded with zeroes; if too long we reduce mod 10^n
  66 #       eg
  67 #            Small4    1070
  68 #       If tree is dirty, + or * is suffixed, reducing number of
  69 #       digits by 1.
  70 #
  71 #   Small4S:
  72 #   Small6S:
  73 #   Small8S:
  74 #   Small10S:
  75 #       same but split into two lines eg
  76 #            Small4S  10
  77 #                     70
  78 #
  79 #   Git4   Git4S
  80 #   Git6   Git6S
  81 #   Git8   Git8S
  82 #   Git10  Git10S
  83 #       git-rev-parse HEAD   (prefix of requested length)
  84 #       eg
  85 #            Git6    82f2a2
  86 #       If tree is dirty, + or * is suffixed to commitid,
  87 #       reducing number of hex digits by 1.
  88
  89 #   Full3
  90 #   Full4
  91 #   Full5
  92 #   Full6
  93 #   Full7
  94 #   Full8
  95 #   Full9
  96 #   Full10
  97 #       git-rev-list --first-parent --count HEAD
  98 #       git-rev-parse HEAD
  99 #       eg
 100 #            Full6      1070
 101 #                     82f2a2
 102 #       If tree is dirty, + or * is suffixed to count (but not to
 103 #       commitid) reducing number of digits by 1.
 104 #
 105 #   FontDemo
 106 #
 107 #   Arg0, Arg1, ...
 108 #       Strings passed on command line
 109
 110 sub p { print @_ or die $!; }
 111
 112 p <<'END';
 113 // *** AUTOGENERATED - DO NOT EDIT *** //
 114 function Commitid_pixelsz() =
 115   ($Commitid_pixelsz       ? $Commitid_pixelsz       : 0.8) *
 116   ($Commitid_scale         ? $Commitid_scale         : 1.0);
 117 function Commitid_depth() =
 118   ($Commitid_depth         ? $Commitid_depth         : Commitid_pixelsz()/2) *
 119   ($Commitid_depth_scale   ? $Commitid_depth_scale   : 1.0);
 120 function Commitid__scale() =
 121   Commitid_pixelsz() / 0.2;
 122 END
 123
 124 sub chrmodname ($) {
 125     my ($chr) = @_;
 126     my $chrx = sprintf '%#x', ord $chr;
 127     return "Commitid__chr_$chrx";
 128 }
 129
 130 our $gtm_demo_i = -1;
 131 our $gtm_demo_j;
 132 our @gtm_demo_o;
 133
 134 sub gentextmodule_demo_next_batch(){
 135     $gtm_demo_i++;
 136     $gtm_demo_j = 0;
 137 }
 138 gentextmodule_demo_next_batch();
 139
 140 sub gentextmodule ($@) {
 141     my ($form, @lines) = @_;
 142     my $modb = "Commitid_$form";
 143     p "module ${modb}_2D(){\n";
 144     p " // |$_|\n" foreach @lines;
 145     p " scale(Commitid__scale()){\n";
 146     my $y = @lines;
 147     my $cols = 1;
 148     foreach my $line (@lines) {
 149         $y--;
 150         my $x = 0;
 151         foreach my $chr (split //, $line) {
 152             next if $chr !~ m/\S/;
 153             p sprintf "  translate([%d * 0.8, %d * 1.2]) %s();\n",
 154                 $x, $y, chrmodname $chr;
 155             $x++;
 156         }
 157         $cols = $x if $x > $cols;
 158     }
 159     p " }\n";
 160     p "}\n";
 161     p "module ${modb}(){\n";
 162     p " d=Commitid_depth();\n";
 163     p " translate([0,0,-d]) linear_extrude(height=d*2) ${modb}_2D();\n";
 164     p "}\n";
 165
 166     p sprintf "function %s_sz() = Commitid__scale() * 0.1 * [ %d, %d ];\n",
 167         $modb, 2 * ($cols * 4 - 1), 2 * (@lines * 6 - 1);
 168
 169     push @gtm_demo_o,
 170         " translate([$gtm_demo_i * st[0], $gtm_demo_j * st[1]])".
 171         " ${modb}_2D();\n";
 172     $gtm_demo_j++;
 173 }
 174
 175 our @demo;
 176
 177 sub parsefont () {
 178     my %cellmap;
 179     for (;;) {
 180         $_ = <DATA> // die;
 181         last if %cellmap && !m/\S/;
 182         next unless m/\S/;
 183         chomp;
 184         s{^(.) }{};
 185         $cellmap{$1} = $_;
 186     }
 187     my %chrpolys;
 188     while (<DATA>) {
 189         next unless m/\S/;
 190         chomp;
 191         my @chrs = split / /, $_;
 192         <DATA> !~ m/\S/ or die;
 193         foreach my $row (reverse 0..4) {
 194             $_ = <DATA>;
 195             chomp;
 196             s{^}{ };
 197             $_ .= ' ' x 8;
 198             m{\S/\S} and die;
 199             s{/(?=\s)}{L}g;
 200             s{/(?=\S)}{r}g;
 201             s{\\(?=\s)}{l}g;
 202             s{\\(?=\S)}{R}g;
 203             p "// $_\n";
 204             foreach my $chr (@chrs) {
 205                 s{^ }{} or die "$chr $_ ?";
 206                 foreach my $col (0..2) {
 207                     my @verts;
 208                     if (s{^ }{}) {
 209                     } elsif (s{^\S}{}) {
 210                         my $f = $cellmap{$&};
 211                         die unless $f;
 212                         $f =~ s/\b\d/ sprintf '%05d', $col*2000 + $&*1025 /ge;
 213                         $f =~ s/\d\b/ sprintf '%05d', $row*2000 + $&*1025 /ge;
 214                         push @{ $chrpolys{$chr} }, [ split / /, $f ];
 215                     } else {
 216                         die "$_ ?";
 217                     }
 218                 }
 219             }
 220             die "$_ ?" if m{\S};
 221         }
 222     }
 223
 224     my $demo = '';
 225     my $democols = 6;
 226     foreach my $chr (sort keys %chrpolys) {
 227         my $mod = chrmodname $chr;
 228         p "module $mod () {\n";
 229         foreach my $poly (@{ $chrpolys{$chr} }) {
 230             p " polygon([";
 231             my $delim = "";
 232             foreach my $pt (@$poly) {
 233                 p $delim;
 234                 $pt =~ s{\d{5}}{$&,};
 235                 $pt =~ s{\b\d}{$&.}g;
 236                 p "[$pt]";
 237                 $delim = ',';
 238             }
 239             p "]);\n";
 240         }
 241         p "}\n";
 242         $demo .= $chr;
 243     }
 244     @demo = reverse $demo =~ m{.{1,$democols}}go;
 245 }
 246
 247 parsefont();
 248
 249 our $do_git; # contains may chars 'c' (count) and/or 'o' (object)
 250 our $do_git_untracked = 1;
 251 our $argcounter;
 252
 253 sub rjustt ($$) { # right justify and truncate (ie, pad and truncate at left)
 254     my ($sz, $whole) = @_;
 255     my $lw = length $whole;
 256     return $lw > $sz
 257         ? substr($whole, $lw-$sz)
 258         : sprintf "%${sz}s", $whole;
 259 }
 260
 261 sub ljustt ($$$) { # always includes $suffix
 262     my ($sz, $whole, $suffix) = @_;
 263     $sz -= length $suffix;
 264     return sprintf "%-${sz}.${sz}s%s", $whole, $suffix;
 265 }
 266
 267 sub gentextmodule_plusq ($$) {
 268     my ($form, $s) = @_;
 269     my $l = length $s;
 270     gentextmodule($form, $s);
 271     if (!($l & 1) && $l>=4) {
 272         gentextmodule("${form}S", substr($s,0,$l/2), substr($s,$l/2));
 273     }
 274 }
 275
 276 our @gcmd;
 277
 278 sub gitrun_start () {
 279     open F, "-|", @gcmd or die "$gcmd[0]: start: $!";
 280 }
 281
 282 sub gitrun_done (;$) {
 283     my ($errok) = @_;
 284     $?=0; $!=0;
 285     return if close F;
 286     return if $errok;
 287     die $! if $!;
 288     die "@gcmd failed ($?)\n";
 289 }
 290
 291 sub gitoutput (@) {
 292     (@gcmd) = (qw(git), @_);
 293     gitrun_start;
 294     $_ = <F>;
 295     gitrun_done;
 296     defined or die "@gcmd produced no output";
 297     chomp or die "@gcmd produced no final newline";
 298     $_;
 299 }
 300
 301 sub do_git () {
 302     return unless $do_git;
 303
 304     @gcmd = qw(git status --porcelain);
 305     push @gcmd, qw(--untracked=no) unless $do_git_untracked;
 306
 307     my $git_dirty = '';
 308     gitrun_start;
 309     while (<F>) {
 310         if (m/^\?\?/ && $do_git_untracked) {
 311             $git_dirty = '+';
 312             next;
 313         }
 314         $git_dirty = '*';
 315         last;
 316     }
 317     gitrun_done($git_dirty eq '*');
 318
 319     my $git_count;
 320     my $git_object;
 321
 322     if ($do_git =~ m/c/) {
 323         $git_count = gitoutput qw(rev-list --first-parent --count HEAD);
 324     }
 325     if ($do_git =~ m/o/) {
 326         $git_object = gitoutput qw(rev-parse HEAD);
 327     }
 328
 329     foreach my $sz (3..10) {
 330         gentextmodule_demo_next_batch();
 331
 332         gentextmodule_plusq("Small$sz", rjustt($sz, $git_count.$git_dirty))
 333             if defined $git_count;
 334
 335         gentextmodule_plusq("Git$sz", ljustt($sz, $git_object, $git_dirty))
 336             if defined $git_object;
 337
 338         gentextmodule("Full$sz",
 339                       rjustt($sz, $git_count.$git_dirty),
 340                       ljustt($sz, $git_object, ''))
 341             if defined $git_count && defined $git_object;
 342     }
 343 }
 344
 345 while (@ARGV) {
 346     $_ = shift;
 347     if (m/^--(no)?-git$/) {
 348         $do_git = $1 ? '' : 'co';
 349     } elsif (m/^---git=object$/) {
 350         $do_git = 'o';
 351     } elsif (m/^-i$/) {
 352         $do_git_untracked = 0;
 353     } elsif (m/^-t(.*)$/) {
 354         my $form = $1;
 355         die "bad usage: -t needs string argument\n";
 356         $_ = shift;
 357         gentextmodule($form, split /\n/, $_);
 358         $argcounter //= 0;
 359     } elsif (m/^[^-]/) {
 360         gentextmodule("Arg$argcounter", $_);
 361         $argcounter++;
 362     } else {
 363         die "bad usage: unknown option \`$_'\n";
 364     }
 365 }
 366
 367 $do_git //= defined($argcounter) ? '' : 'co';
 368
 369 gentextmodule('FontDemo', @demo);
 370
 371 do_git();
 372
 373 p "module Commitid_2DDemo(){\n";
 374 p " st = Commitid__scale() * [ 10, 5 ];\n";
 375 p $_ foreach @gtm_demo_o;
 376 p "}\n";
 377
 378 flush STDOUT or die $!;
 379 close STDOUT or die $!;
 380
 381 __DATA__
 382
 383 # 00 20 22 02
 384 l 00 20 02
 385 r 00 20 22
 386 L 00 22 02
 387 R 20 22 02
 388 > 00 20 22 02 11
 389 < 00 20 11 22 02
 390
 391 0 1 2 3 4 5 6 7 8 9
 392
 393 /#\  r  /#\ ##\ # # ### //  ### /#\ /#\
 394 # # /#    #   # # # #   #     # # # # #
 395 # #  #  /#/ ##< \## ##\ ##\  // >#< \##
 396 # #  #  #     #   #   # # #  #  # #   #
 397 \#/ /#\ ### ##/   # ##/ \#/  #  \#/ ##/
 398
 399 a b c d e f
 400
 401     #         #     /##
 402     #   /##   # /#\ #
 403 /## ##\ #   /## #r# ###
 404 # # # # #   # # #/  #
 405 \## ##/ \## \## \#/ #
 406
 407 + *
 408
 409       r
 410  #  ###
 411 ###  #
 412  #  ###
 413     L