belt-slot-cut-jig.scad

   1 // -*- C -*-
   2
   3 // todo
   4 //  various registration marks
   5 //   protrustions at ends at strap width and middle
   6 //   grooves on top face at 1/4,1/2,3/4 length and 1/2 width
   7
   8 crewpunch_slop = 0.3;
   9
  10 holder_min_wall = 2;
  11 holder_attach_near_wall = 3;
  12
  13 holder_attach_xsz = 5;
  14 holder_ctie_width = 4.0 + 0.5;
  15 holder_ctie_thick = 2.0 + 0.5;
  16 holder_attach_walls = 3;
  17 holder_attach_roof = 2.5;
  18
  19 jig_interval = 25;
  20 strap_width = 25;
  21 strap_thick = 3;
  22 edgewall_width = 3;
  23
  24 punch_travel = 8;
  25
  26 main_slop = 0.5;
  27
  28 jig_max_len = 160; // print diagonally
  29 //jig_max_len = 30;
  30
  31 registrationgroove_width = 0.8;
  32 registrationgroove_depth = 1.2;
  33
  34 // from careful measurement
  35
  36 crewpunch_shape =
  37   [[  6, [0.6, 6.0], [1.6, 12.3] ],
  38    [  8, [1.1, 6.2], [1.9, 12.5] ],
  39    [ 10, [1.6, 6.5], [2.1, 12.8] ],
  40    [ 12, [1.8, 6.6], [2.3, 12.7] ],
  41    [ 14, [2.1, 6.8], [2.6, 13.0] ],
  42    [ 16, [2.4, 6.9], [2.7, 13.2] ]];
  43
  44 crewpunch_shaft_max_y = 7.5;
  45
  46 crewpunch_systematic_size_error = +0.36;
  47
  48 crewpunch_min_y = 4.7 - crewpunch_systematic_size_error;
  49
  50 crewpunch_smallest_shape = crewpunch_shape[0];
  51 crewpunch_biggest_shape = crewpunch_shape[len(crewpunch_shape)-1];
  52
  53 // computed
  54
  55 attach_ysz = holder_attach_walls*2 + holder_ctie_width;
  56 holder_front_all = crewpunch_shaft_max_y - crewpunch_biggest_shape[1][1]
  57   + attach_ysz;
  58
  59 holder_block_zsz = crewpunch_biggest_shape[0] - crewpunch_smallest_shape[0];
  60 holder_xsz = crewpunch_biggest_shape[2][0] + crewpunch_biggest_shape[2][1] +
  61   holder_min_wall*2;
  62 crewpunch_biggest_y =
  63   crewpunch_biggest_shape[1][0] + crewpunch_biggest_shape[1][1];
  64 holder_ysz = crewpunch_biggest_y + holder_min_wall + holder_front_all;
  65
  66 attach_offset = 0.5 * (holder_front_all - holder_attach_near_wall);
  67
  68 jig_main_zsz = holder_block_zsz + punch_travel;
  69
  70 jig_ends_extra = 2;
  71
  72 jig_iters = (jig_max_len - jig_ends_extra) / jig_interval;
  73 echo(jig_iters);
  74
  75 // objects
  76
  77 module CrewPunch(){
  78   ourslop = crewpunch_slop - crewpunch_systematic_size_error;
  79   hull(){
  80     for(layer=crewpunch_shape){
  81       translate([0,0, layer[0]]){
  82         for(xind=[0,1]) //translate([xind?0:1,0,0])
  83           for(yind=[0,1]) //translate([0,yind?0.5:0,0])
  84             mirror([xind?1:0,0,0]) mirror([0,yind?0:1,0]){
  85               translate([-0.1,-0.1,-0.1])
  86                 cube([0.1 + layer[2][xind] + ourslop,
  87                       0.1 + layer[1][yind] + ourslop,
  88                       0.2]);
  89             }
  90       }
  91     }
  92   }
  93 }
  94
  95 module PunchHolder(cutouts=true){
  96   translate([-holder_xsz/2,
  97              -holder_ysz + holder_min_wall + crewpunch_biggest_y/2,
  98              0]){
  99     difference(){
 100       translate([0,attach_offset,0])
 101         cube([holder_xsz, holder_ysz - attach_offset, holder_block_zsz]);
 102       if (cutouts)
 103         translate([crewpunch_biggest_shape[2][1] + holder_min_wall,
 104                    crewpunch_biggest_shape[1][0] + holder_front_all,
 105                    -crewpunch_smallest_shape[0]])
 106           CrewPunch();
 107     }
 108     difference(){
 109       translate([holder_xsz/2 - holder_attach_xsz/2, 0, 0])
 110         cube([holder_attach_xsz,
 111               attach_ysz,
 112               holder_block_zsz + punch_travel
 113               + holder_ctie_thick + holder_attach_roof + 1]);
 114       if (cutouts)
 115         translate([-30,
 116                    holder_attach_walls,
 117                    holder_block_zsz + punch_travel])
 118           cube([60, holder_ctie_width, holder_ctie_thick]);
 119     }
 120   }
 121 }
 122
 123 module RegistrationGroove(l){
 124   // runs along the +ve X axis for length l but at correct z pos
 125   translate([0, 0, jig_main_zsz + 0.1]) {
 126     rotate([90,0,90])
 127       linear_extrude(height=l)
 128       polygon([[-registrationgroove_width/2, 0],
 129                [ +registrationgroove_width/2, 0],
 130                [ 0, -registrationgroove_depth ]]);
 131   }
 132 }
 133
 134 module OneJig(){
 135   difference(){
 136     translate([-(jig_interval/2 + 1),
 137                -(strap_width/2 + edgewall_width) - attach_offset,
 138                -strap_thick])
 139       cube([jig_interval + 2,
 140             strap_width + edgewall_width*2 + attach_offset,
 141             jig_main_zsz + strap_thick]);
 142     minkowski(){
 143       cube([main_slop*2, main_slop*2, 50], center=true);
 144       PunchHolder(false);
 145     }
 146     translate([-100, -strap_width/2, -10])
 147       cube([200, strap_width, 10]);
 148    translate([-100,0,0])
 149      RegistrationGroove(200);
 150    for (xfrac=[-1/4,0,+1/4])
 151      translate([jig_interval * xfrac, -100, 0])
 152        rotate([0,0,90])
 153        RegistrationGroove(200);
 154   }
 155 }
 156
 157 module Jig(){
 158   for (i=[0:jig_iters-1]) {
 159     translate([jig_interval * i, 0, 0])
 160       OneJig();
 161   }
 162 }
 163
 164 module Demo(){
 165   %PunchHolder();
 166   Jig();
 167 }
 168
 169 //CrewPunch();
 170 //PunchHolder();
 171 //PunchHolder(false);
 172 //OneJig();
 173 //Jig();
 174 Demo();