belt-slot-cut-jig.scad

   1 // -*- C -*-
   2
   3 // todo
   4 //  various registration marks
   5 //   protrustions at ends at strap width and middle
   6 //   grooves on top face at 1/4,1/2,3/4 length and 1/2 width
   7
   8 crewpunch_slop = 0.3;
   9
  10 holder_min_wall = 2;
  11 holder_attach_near_wall = 3;
  12
  13 holder_attach_xsz = 5;
  14 holder_ctie_width = 4.0 + 0.5;
  15 holder_ctie_thick = 2.0 + 0.5;
  16 holder_attach_walls = 3;
  17 holder_attach_roof = 2.5;
  18
  19 jig_interval = 25;
  20 strap_width = 25;
  21 strap_thick = 3;
  22 edgewall_width = 3;
  23
  24 punch_travel = 8;
  25
  26 main_slop = 0.5;
  27
  28 jig_max_len = 160; // print diagonally
  29 //jig_max_len = 30;
  30
  31 registrationgroove_width = 0.8;
  32 registrationgroove_depth = 1.2;
  33
  34 // from careful measurement
  35
  36 crewpunch_shape =
  37   [[  6, [0.6, 6.0], [1.6, 12.3] ],
  38    [  8, [1.1, 6.2], [1.9, 12.5] ],
  39    [ 10, [1.6, 6.5], [2.1, 12.8] ],
  40    [ 12, [1.8, 6.6], [2.3, 12.7] ],
  41    [ 14, [2.1, 6.8], [2.6, 13.0] ],
  42    [ 16, [2.4, 6.9], [2.7, 13.2] ]];
  43
  44 crewpunch_shaft_max_y = 7.5;
  45
  46 crewpunch_systematic_size_error = +0.36;
  47
  48 crewpunch_min_y = 4.7 - crewpunch_systematic_size_error;
  49
  50 crewpunch_smallest_shape = crewpunch_shape[0];
  51 crewpunch_biggest_shape = crewpunch_shape[len(crewpunch_shape)-1];
  52
  53 // computed
  54
  55 attach_ysz = holder_attach_walls*2 + holder_ctie_width;
  56 holder_front_all = crewpunch_shaft_max_y - crewpunch_biggest_shape[1][1]
  57   + attach_ysz;
  58
  59 holder_block_zsz = crewpunch_biggest_shape[0] - crewpunch_smallest_shape[0];
  60 holder_xsz = crewpunch_biggest_shape[2][0] + crewpunch_biggest_shape[2][1] +
  61   holder_min_wall*2;
  62 crewpunch_biggest_y =
  63   crewpunch_biggest_shape[1][0] + crewpunch_biggest_shape[1][1];
  64 holder_ysz = crewpunch_biggest_y + holder_min_wall + holder_front_all;
  65
  66 attach_offset = 0.5 * (holder_front_all - holder_attach_near_wall);
  67
  68 jig_main_zsz = holder_block_zsz + punch_travel;
  69
  70 jig_ends_extra = 2;
  71
  72 //jig_iters = (jig_max_len - jig_ends_extra) / jig_interval;
  73 jig_iters=2;
  74 echo(jig_iters);
  75
  76 // objects
  77
  78 module CrewPunch(){
  79   ourslop = crewpunch_slop - crewpunch_systematic_size_error;
  80   hull(){
  81     for(layer=crewpunch_shape){
  82       translate([0,0, layer[0]]){
  83         for(xind=[0,1]) //translate([xind?0:1,0,0])
  84           for(yind=[0,1]) //translate([0,yind?0.5:0,0])
  85             mirror([xind?1:0,0,0]) mirror([0,yind?0:1,0]){
  86               translate([-0.1,-0.1,-0.1])
  87                 cube([0.1 + layer[2][xind] + ourslop,
  88                       0.1 + layer[1][yind] + ourslop,
  89                       0.2]);
  90             }
  91       }
  92     }
  93   }
  94 }
  95
  96 module PunchHolder(cutouts=true){
  97   translate([-holder_xsz/2,
  98              -holder_ysz + holder_min_wall + crewpunch_biggest_y/2,
  99              0]){
 100     difference(){
 101       translate([0,attach_offset,0])
 102         cube([holder_xsz, holder_ysz - attach_offset, holder_block_zsz]);
 103       if (cutouts)
 104         translate([crewpunch_biggest_shape[2][1] + holder_min_wall,
 105                    crewpunch_biggest_shape[1][0] + holder_front_all,
 106                    -crewpunch_smallest_shape[0]])
 107           CrewPunch();
 108     }
 109     difference(){
 110       translate([holder_xsz/2 - holder_attach_xsz/2, 0, 0])
 111         cube([holder_attach_xsz,
 112               attach_ysz,
 113               holder_block_zsz + punch_travel
 114               + holder_ctie_thick + holder_attach_roof + 1]);
 115       if (cutouts)
 116         translate([-30,
 117                    holder_attach_walls,
 118                    holder_block_zsz + punch_travel])
 119           cube([60, holder_ctie_width, holder_ctie_thick]);
 120     }
 121   }
 122 }
 123
 124 module RegistrationGroove(l){
 125   // runs along the +ve X axis for length l but at correct z pos
 126   translate([0, 0, jig_main_zsz + 0.1]) {
 127     rotate([90,0,90])
 128       linear_extrude(height=l)
 129       polygon([[-registrationgroove_width/2, 0],
 130                [ +registrationgroove_width/2, 0],
 131                [ 0, -registrationgroove_depth ]]);
 132   }
 133 }
 134
 135 module OneJig(){
 136   difference(){
 137     translate([-(jig_interval/2 + 1),
 138                -(strap_width/2 + edgewall_width) - attach_offset,
 139                -strap_thick])
 140       cube([jig_interval + 2,
 141             strap_width + edgewall_width*2 + attach_offset,
 142             jig_main_zsz + strap_thick]);
 143     minkowski(){
 144       cube([main_slop*2, main_slop*2, 50], center=true);
 145       PunchHolder(false);
 146     }
 147     translate([-100, -strap_width/2, -10])
 148       cube([200, strap_width, 10]);
 149    translate([-100,0,0])
 150      RegistrationGroove(200);
 151    for (xfrac=[-1/4,0,+1/4])
 152      translate([jig_interval * xfrac, -100, 0])
 153        rotate([0,0,90])
 154        RegistrationGroove(200);
 155   }
 156 }
 157
 158 module Jig(){
 159   for (i=[0:jig_iters-1]) {
 160     translate([jig_interval * i, 0, 0])
 161       OneJig();
 162   }
 163 }
 164
 165 module JigT(){ ////toplevel
 166   rotate([180,0,0])
 167     Jig();
 168 }
 169
 170 module PunchHolderT(){ ////toplevel
 171   PunchHolder(true);
 172 }
 173
 174 module Demo(){
 175   %PunchHolder();
 176   Jig();
 177 }
 178
 179 //CrewPunch();
 180 //PunchHolder();
 181 //PunchHolder(false);
 182 //OneJig();
 183 //Jig();
 184 //Demo();
 185 //JigT();
 186 //PunchHolderT();