belt-slot-cut-jig.scad

   1 // -*- C -*-
   2
   3 // todo
   4 //  various registration marks
   5 //   protrustions at ends at strap width and middle
   6 //   grooves on top face at 1/4,1/2,3/4 length and 1/2 width
   7
   8 crewpunch_slop = 0.3;
   9
  10 holder_min_wall = 2;
  11 holder_attach_near_wall = 3;
  12
  13 holder_attach_xsz = 5;
  14 holder_ctie_width = 4.0 + 0.5;
  15 holder_ctie_thick = 3.0 + 0.5;
  16 holder_attach_walls = 3;
  17 holder_attach_roof = 2.5;
  18
  19 jig_interval = 25;
  20 strap_width = 26.75 + 0.7;
  21 strap_thick = 3;
  22 edgewall_width = 3;
  23
  24 punch_travel = 8;
  25
  26 main_slop = 0.5;
  27
  28 jig_max_len = 160; // print diagonally
  29 //jig_max_len = 30;
  30
  31 registrationgroove_width = 0.8;
  32 registrationgroove_depth = 1.2;
  33
  34 registrationprotrusion_poke = 3;
  35 registrationprotrusion_slope = 0.75;
  36
  37 jig_overlap = 1;
  38
  39 // from careful measurement
  40
  41 crewpunch_shape =
  42   [[  6, [0.6, 6.0], [1.6, 12.3] ],
  43    [  8, [1.1, 6.2], [1.9, 12.5] ],
  44    [ 10, [1.6, 6.5], [2.1, 12.8] ],
  45    [ 12, [1.8, 6.6], [2.3, 12.7] ],
  46    [ 14, [2.1, 6.8], [2.6, 13.0] ],
  47    [ 16, [2.4, 6.9], [2.7, 13.2] ],
  48    [ 18, [2.5, 7.0], [2.9, 13.3] ],
  49    [ 22, [3.1, 7.1], [3.2, 13.4] ],
  50    [ 26, [3.3, 7.2], [3.5, 13.6] ],
  51    ];
  52
  53 crewpunch_shaft_max_y = 7.5;
  54
  55 crewpunch_systematic_size_error = +0.36;
  56
  57 crewpunch_min_y = 4.7 - crewpunch_systematic_size_error;
  58
  59 crewpunch_smallest_shape = crewpunch_shape[0];
  60 crewpunch_biggest_shape = crewpunch_shape[len(crewpunch_shape)-1];
  61
  62 crewpunch_skew_angle = 2.0; //degrees
  63
  64 // computed
  65
  66 attach_ysz = holder_attach_walls*2 + holder_ctie_width;
  67 holder_front_all = crewpunch_shaft_max_y - crewpunch_biggest_shape[1][1]
  68   + attach_ysz;
  69
  70 holder_block_zsz = crewpunch_biggest_shape[0] - crewpunch_smallest_shape[0];
  71 holder_xsz = crewpunch_biggest_shape[2][1] + crewpunch_biggest_shape[2][0] +
  72   holder_min_wall*2;
  73 crewpunch_biggest_y =
  74   crewpunch_biggest_shape[1][0] + crewpunch_biggest_shape[1][1];
  75 holder_ysz = crewpunch_biggest_y + holder_min_wall + holder_front_all;
  76
  77 attach_offset = 0.5 * (holder_front_all - holder_attach_near_wall);
  78
  79 jig_main_zsz = holder_block_zsz + punch_travel;
  80
  81 jig_ends_extra = 2;
  82
  83 //jig_iters = (jig_max_len - jig_ends_extra) / jig_interval;
  84 jig_iters=2;
  85 echo(jig_iters);
  86
  87 // objects
  88
  89 module CrewPunch(){
  90   ourslop = crewpunch_slop - crewpunch_systematic_size_error;
  91   hull(){
  92     for(layer=crewpunch_shape){
  93       translate([0,0, layer[0]]){
  94         for(xind=[0,1]) //translate([xind?0:1,0,0])
  95           for(yind=[0,1]) //translate([0,yind?0.5:0,0])
  96             mirror([xind?1:0,0,0]) mirror([0,yind?0:1,0]){
  97               translate([-0.1,-0.1,-0.1])
  98                 cube([0.1 + layer[2][1-xind] + ourslop,
  99                       0.1 + layer[1][yind] + ourslop,
 100                       0.2]);
 101             }
 102       }
 103     }
 104   }
 105 }
 106
 107 module PunchHolder(cutouts=true){
 108   translations=[-holder_xsz/2,
 109                 -holder_ysz + holder_min_wall + crewpunch_biggest_y/2,
 110                 0];
 111   translate(translations){
 112     difference(){
 113       translate([0,attach_offset,0])
 114         cube([holder_xsz, holder_ysz - attach_offset, holder_block_zsz]);
 115       if (cutouts)
 116         translate(-translations)
 117         rotate([0,0,-crewpunch_skew_angle])
 118         translate(translations)
 119         translate([crewpunch_biggest_shape[2][0] + holder_min_wall,
 120                    crewpunch_biggest_shape[1][0] + holder_front_all,
 121                    -crewpunch_smallest_shape[0]])
 122           CrewPunch();
 123     }
 124     difference(){
 125       translate([holder_xsz/2 - holder_attach_xsz/2, 0, 0])
 126         cube([holder_attach_xsz,
 127               attach_ysz,
 128               holder_block_zsz + punch_travel
 129               + holder_ctie_thick + holder_attach_roof + 1]);
 130       if (cutouts)
 131         translate([-30,
 132                    holder_attach_walls,
 133                    holder_block_zsz + punch_travel])
 134           cube([60, holder_ctie_width, holder_ctie_thick]);
 135     }
 136   }
 137 }
 138
 139 module RegistrationGroove(l){
 140   // runs along the +ve X axis for length l but at correct z pos
 141   translate([0, 0, jig_main_zsz + 0.1]) {
 142     rotate([90,0,90])
 143       linear_extrude(height=l)
 144       polygon([[-registrationgroove_width/2, 0],
 145                [ +registrationgroove_width/2, 0],
 146                [ 0, -registrationgroove_depth ]]);
 147   }
 148 }
 149
 150 module OneJig(){
 151   difference(){
 152     translate([-(jig_interval/2 + jig_overlap),
 153                -(strap_width/2 + edgewall_width) - attach_offset,
 154                -strap_thick])
 155       cube([jig_interval + 2,
 156             strap_width + edgewall_width*2 + attach_offset,
 157             jig_main_zsz + strap_thick]);
 158     minkowski(){
 159       cube([main_slop*2, main_slop*2, 50], center=true);
 160       PunchHolder(false);
 161     }
 162     translate([-100, -strap_width/2, -10])
 163       cube([200, strap_width, 10]);
 164    translate([-100,0,0])
 165      RegistrationGroove(200);
 166    for (xfrac=[-1/4,0,+1/4])
 167      translate([jig_interval * xfrac, -100, 0])
 168        rotate([0,0,90])
 169        RegistrationGroove(200);
 170   }
 171 }
 172
 173 module RegistrationProtrusion(){
 174   // points towards the positive x axis
 175   xsz = registrationprotrusion_poke;
 176   ysz = registrationprotrusion_poke;
 177   diag_sz = xsz * sqrt(2);
 178   zsz = diag_sz / registrationprotrusion_slope;
 179   hull(){
 180     translate([0, 0, 0.1]){
 181       linear_extrude(height=0.1)
 182         polygon([[   0, -ysz ],
 183                  [ xsz,    0 ],
 184                  [   0,  ysz ]]);
 185       translate([-0.1, 0, zsz ])
 186         rotate([0,0,45])
 187         cube(0.1);
 188     }
 189   }
 190 }
 191
 192 module Jig(){
 193   for(end=[0,1]){
 194     for(yfrac=[-1/2, 0, 1/2]){
 195       translate([ end
 196                   ? jig_interval * (jig_iters - 0.5)
 197                   : -jig_interval/2,
 198                  yfrac * strap_width,
 199                  0])
 200         rotate([0,0, end ? 0 : 180])
 201         translate([ jig_overlap, 0, 0 ])
 202         RegistrationProtrusion();
 203     }
 204   }
 205   for (i=[0:jig_iters-1]) {
 206     translate([jig_interval * i, 0, 0])
 207       OneJig();
 208   }
 209 }
 210
 211 module JigT(){ ////toplevel
 212   rotate([180,0,0])
 213     Jig();
 214 }
 215
 216 module PunchHolderT(){ ////toplevel
 217   PunchHolder(true);
 218 }
 219
 220 module Demo(){
 221   %PunchHolder();
 222   Jig();
 223 }
 224
 225 //CrewPunch();
 226 //PunchHolder();
 227 //PunchHolder(false);
 228 //OneJig();
 229 //Jig();
 230 //Demo();
 231 //JigT();
 232 //RegistrationProtrusion();
 233 //PunchHolderT();