belt-slot-cut-jig.scad

   1 // -*- C -*-
   2
   3 crewpunch_slop = 0.3;
   4
   5 holder_min_wall = 2;
   6
   7 holder_attach_xsz = 5;
   8 holder_ctie_width = 4.0 + 0.5;
   9 holder_ctie_thick = 2.0 + 0.5;
  10 holder_attach_walls = 3;
  11 holder_attach_roof = 2.5;
  12
  13 jig_interval = 25;
  14 strap_width = 25;
  15 edgewall_width = 3;
  16
  17 main_slop = 0.5;
  18
  19 // from careful measurement
  20
  21 crewpunch_shape =
  22   [[  6, [0.6, 6.0], [1.6, 12.3] ],
  23    [  8, [1.1, 6.2], [1.9, 12.5] ],
  24    [ 10, [1.6, 6.5], [2.1, 12.8] ],
  25    [ 12, [1.8, 6.6], [2.3, 12.7] ],
  26    [ 14, [2.1, 6.8], [2.6, 13.0] ],
  27    [ 16, [2.4, 6.9], [2.7, 13.2] ]];
  28
  29 crewpunch_shaft_max_y = 7.5;
  30
  31 crewpunch_systematic_size_error = +0.36;
  32
  33 crewpunch_min_y = 4.7 - crewpunch_systematic_size_error;
  34
  35 crewpunch_smallest_shape = crewpunch_shape[0];
  36 crewpunch_biggest_shape = crewpunch_shape[len(crewpunch_shape)-1];
  37
  38 // computed
  39
  40 attach_ysz = holder_attach_walls*2 + holder_ctie_width;
  41 holder_front_wall = crewpunch_shaft_max_y - crewpunch_biggest_shape[1][1]
  42   + attach_ysz;
  43
  44 holder_block_zsz = crewpunch_biggest_shape[0] - crewpunch_smallest_shape[0];
  45 holder_xsz = crewpunch_biggest_shape[2][0] + crewpunch_biggest_shape[2][1] +
  46   holder_min_wall*2;
  47 crewpunch_biggest_y =
  48   crewpunch_biggest_shape[1][0] + crewpunch_biggest_shape[1][1];
  49 holder_ysz = crewpunch_biggest_y + holder_min_wall + holder_front_wall;
  50
  51 attach_offset = holder_attach_xsz + holder_min_wall;
  52
  53 // objects
  54
  55 module CrewPunch(){
  56   ourslop = crewpunch_slop - crewpunch_systematic_size_error;
  57   hull(){
  58     for(layer=crewpunch_shape){
  59       translate([0,0, layer[0]]){
  60         for(xind=[0,1]) //translate([xind?0:1,0,0])
  61           for(yind=[0,1]) //translate([0,yind?0.5:0,0])
  62             mirror([xind?1:0,0,0]) mirror([0,yind?0:1,0]){
  63               translate([-0.1,-0.1,-0.1])
  64                 cube([0.1 + layer[2][xind] + ourslop,
  65                       0.1 + layer[1][yind] + ourslop,
  66                       0.2]);
  67             }
  68       }
  69     }
  70   }
  71 }
  72
  73 module PunchHolder(cutouts=true){
  74   translate([-holder_xsz/2,
  75              -holder_ysz + holder_min_wall + crewpunch_biggest_y/2,
  76              0]){
  77     difference(){
  78       translate([0,attach_offset,0])
  79         cube([holder_xsz, holder_ysz - attach_offset, holder_block_zsz]);
  80       if (cutouts)
  81         translate([crewpunch_biggest_shape[2][1] + holder_min_wall,
  82                    crewpunch_biggest_shape[1][0] + holder_front_wall,
  83                    -crewpunch_smallest_shape[0]])
  84           CrewPunch();
  85     }
  86     difference(){
  87       translate([holder_xsz/2 - holder_attach_xsz/2, 0, 0])
  88         cube([holder_attach_xsz,
  89               attach_ysz,
  90               holder_block_zsz + holder_ctie_thick + holder_attach_roof + 1]);
  91       if (cutouts)
  92         translate([-30, holder_attach_walls, holder_block_zsz + 0.1])
  93           cube([60, holder_ctie_width, holder_ctie_thick]);
  94     }
  95   }
  96 }
  97
  98 module OneJig(){
  99   difference(){
 100     translate([-(jig_interval/2 + 1),
 101                -(strap_width/2 + edgewall_width) - attach_offset,
 102                0])
 103       cube([jig_interval + 2,
 104             strap_width + edgewall_width*2 + attach_offset,
 105             holder_ysz]);
 106     minkowski(){
 107       cube([main_slop*2, main_slop*2, 50], center=true);
 108       PunchHolder(false);
 109     }
 110   }
 111 }
 112
 113 //CrewPunch();
 114 //PunchHolder();
 115 //PunchHolder(false);
 116 OneJig();