belt-slot-cut-jig.scad

   1 // -*- C -*-
   2
   3 // todo
   4 //  various registration marks
   5 //   protrustions at ends at strap width and middle
   6 //   grooves on top face at 1/4,1/2,3/4 length and 1/2 width
   7
   8 crewpunch_slop = 0.3;
   9
  10 holder_min_wall = 2;
  11 holder_attach_near_wall = 3;
  12
  13 holder_attach_xsz = 5;
  14 holder_ctie_width = 4.0 + 0.5;
  15 holder_ctie_thick = 3.0 + 0.5;
  16 holder_attach_walls = 3;
  17 holder_attach_roof = 2.5;
  18
  19 jig_interval = 25;
  20 strap_width = 26.75 + 0.7;
  21 strap_thick = 3;
  22 edgewall_width = 3;
  23
  24 punch_travel = 8;
  25
  26 main_slop = 0.5;
  27
  28 jig_max_len = 160; // print diagonally
  29 //jig_max_len = 30;
  30
  31 registrationgroove_width = 0.8;
  32 registrationgroove_depth = 1.2;
  33
  34 registrationprotrusion_poke = 3;
  35 registrationprotrusion_slope = 0.75;
  36
  37 jig_overlap = 1;
  38
  39 // from careful measurement
  40
  41 crewpunch_shape =
  42   [[  6, [0.6, 6.0], [1.6, 12.3] ],
  43    [  8, [1.1, 6.2], [1.9, 12.5] ],
  44    [ 10, [1.6, 6.5], [2.1, 12.8] ],
  45    [ 12, [1.8, 6.6], [2.3, 12.7] ],
  46    [ 14, [2.1, 6.8], [2.6, 13.0] ],
  47    [ 16, [2.4, 6.9], [2.7, 13.2] ],
  48    [ 18, [2.5, 7.0], [2.9, 13.3] ],
  49    [ 22, [3.1, 7.1], [3.2, 13.4] ],
  50    [ 26, [3.3, 7.2], [3.5, 13.6] ],
  51    ];
  52
  53 crewpunch_shaft_max_y = 3.5;
  54
  55 crewpunch_systematic_size_error = +0.36;
  56
  57 crewpunch_smallest_shape = crewpunch_shape[0];
  58 crewpunch_biggest_shape = crewpunch_shape[len(crewpunch_shape)-1];
  59
  60 crewpunch_skew_angle = 3.5; //degrees
  61 crewpunch_skew_yoff_broken = 0; //mm
  62 crewpunch_skew_yoff = -1.1; //mm
  63
  64 // computed
  65
  66 attach_ysz = holder_attach_walls*2 + holder_ctie_width;
  67
  68 holder_block_zsz = crewpunch_biggest_shape[0] - crewpunch_smallest_shape[0];
  69 holder_xsz = crewpunch_biggest_shape[2][0] + crewpunch_biggest_shape[2][1] +
  70   holder_min_wall*2;
  71
  72 holder_skewangle_yextra = holder_xsz/2 * sin(abs(crewpunch_skew_angle));
  73
  74 holder_front_all = crewpunch_shaft_max_y - crewpunch_biggest_shape[1][0]
  75   + attach_ysz + crewpunch_systematic_size_error + crewpunch_skew_yoff_broken
  76   + holder_skewangle_yextra;
  77
  78 crewpunch_biggest_y =
  79   crewpunch_biggest_shape[1][0] + crewpunch_biggest_shape[1][1];
  80 holder_ysz = crewpunch_biggest_y + holder_min_wall + holder_front_all
  81   + max(0, -crewpunch_skew_yoff_broken);
  82
  83 attach_offset = 0.5 * (holder_front_all - holder_attach_near_wall);
  84
  85 jig_main_zsz = holder_block_zsz + punch_travel;
  86
  87 jig_ends_extra = 2;
  88
  89 //jig_iters = (jig_max_len - jig_ends_extra) / jig_interval;
  90 jig_iters=2;
  91 echo(jig_iters);
  92
  93 // objects
  94
  95 module CrewPunch(){
  96   ourslop = crewpunch_slop - crewpunch_systematic_size_error;
  97   hull(){
  98     for(layer=crewpunch_shape){
  99       translate([0,0, layer[0]]){
 100         for(xind=[0,1]) //translate([xind?0:1,0,0])
 101           for(yind=[0,1]) //translate([0,yind?0.5:0,0])
 102             mirror([xind?1:0,0,0]) mirror([0,yind?0:1,0]){
 103               translate([-0.1,-0.1,-0.1])
 104                 cube([0.1 + layer[2][xind] + ourslop,
 105                       0.1 + layer[1][1-yind] + ourslop,
 106                       0.2]);
 107             }
 108       }
 109     }
 110   }
 111 }
 112
 113 module PunchHolder(cutouts=true){
 114   translations=[-holder_xsz/2,
 115                 -holder_ysz + holder_min_wall + crewpunch_biggest_y/2,
 116                 0];
 117   translate(translations){
 118     difference(){
 119       translate([0,attach_offset,0])
 120         cube([holder_xsz, holder_ysz - attach_offset, holder_block_zsz]);
 121       if (cutouts)
 122         translate([0,-crewpunch_skew_yoff_broken])
 123         translate(-translations)
 124         rotate([0,0,-crewpunch_skew_angle])
 125         translate(translations)
 126         translate([crewpunch_biggest_shape[2][1] + holder_min_wall,
 127                    crewpunch_biggest_shape[1][1] + holder_front_all,
 128                    -crewpunch_smallest_shape[0]])
 129           CrewPunch();
 130     }
 131     difference(){
 132       translate([holder_xsz/2 - holder_attach_xsz/2, 0, 0])
 133         cube([holder_attach_xsz,
 134               attach_ysz,
 135               holder_block_zsz + punch_travel
 136               + holder_ctie_thick + holder_attach_roof + 1]);
 137       if (cutouts)
 138         translate([-30,
 139                    holder_attach_walls,
 140                    holder_block_zsz + punch_travel])
 141           cube([60, holder_ctie_width, holder_ctie_thick]);
 142     }
 143   }
 144 }
 145
 146 module RegistrationGroove(l){
 147   // runs along the +ve X axis for length l but at correct z pos
 148   translate([0, 0, jig_main_zsz + 0.1]) {
 149     rotate([90,0,90])
 150       linear_extrude(height=l)
 151       polygon([[-registrationgroove_width/2, 0],
 152                [ +registrationgroove_width/2, 0],
 153                [ 0, -registrationgroove_depth ]]);
 154   }
 155 }
 156
 157 module OneJig(){
 158   difference(){
 159     translate([-(jig_interval/2 + jig_overlap),
 160                -(strap_width/2 + edgewall_width) - attach_offset,
 161                -strap_thick])
 162       cube([jig_interval + 2,
 163             strap_width + edgewall_width*2 + attach_offset,
 164             jig_main_zsz + strap_thick]);
 165     minkowski(){
 166       cube([main_slop*2, main_slop*2, 50], center=true);
 167       PunchHolder(false);
 168     }
 169     translate([-100, -strap_width/2, -10])
 170       cube([200, strap_width, 10]);
 171    translate([-100,0,0])
 172      RegistrationGroove(200);
 173    for (xfrac=[-1/4,0,+1/4])
 174      translate([jig_interval * xfrac, -100, 0])
 175        rotate([0,0,90])
 176        RegistrationGroove(200);
 177   }
 178 }
 179
 180 module RegistrationProtrusion(){
 181   // points towards the positive x axis
 182   xsz = registrationprotrusion_poke;
 183   ysz = registrationprotrusion_poke;
 184   diag_sz = xsz * sqrt(2);
 185   zsz = diag_sz / registrationprotrusion_slope;
 186   hull(){
 187     translate([0, 0, 0.1]){
 188       linear_extrude(height=0.1)
 189         polygon([[   0, -ysz ],
 190                  [ xsz,    0 ],
 191                  [   0,  ysz ]]);
 192       translate([-0.1, 0, zsz ])
 193         rotate([0,0,45])
 194         cube(0.1);
 195     }
 196   }
 197 }
 198
 199 module Jig(){
 200   for(end=[0,1]){
 201     for(yfrac=[-1/2, 0, 1/2]){
 202       translate([ end
 203                   ? jig_interval * (jig_iters - 0.5)
 204                   : -jig_interval/2,
 205                  yfrac * strap_width,
 206                  0])
 207         rotate([0,0, end ? 0 : 180])
 208         translate([ jig_overlap, 0, 0 ])
 209         RegistrationProtrusion();
 210     }
 211   }
 212   for (i=[0:jig_iters-1]) {
 213     translate([jig_interval * i, 0, 0])
 214       OneJig();
 215   }
 216 }
 217
 218 module JigT(){ ////toplevel
 219   translate([0,0,jig_main_zsz])
 220     rotate([180,0,0])
 221     Jig();
 222 }
 223
 224 module PunchHolderT(){ ////toplevel
 225   PunchHolder(true);
 226 }
 227
 228 module Demo(){ ////toplevel
 229   %PunchHolder();
 230   Jig();
 231 }
 232
 233 module Kit(){ ////toplevel
 234   rotate([0,0,-45]){
 235     JigT();
 236     translate([(jig_iters-1)*jig_interval/2,
 237                -strap_width,
 238                0])
 239       PunchHolder();
 240   }
 241 }
 242
 243 //CrewPunch();
 244 //PunchHolder();
 245 //PunchHolder(false);
 246 //OneJig();
 247 //Jig();
 248 Demo();
 249 //JigT();
 250 //RegistrationProtrusion();
 251 //PunchHolderT();
 252 //Kit();