test/CMakeLists.txt

   1 add_custom_target (tests)
   2
   3 # have to add timer.c and mt19937ar.c as symbols are declared extern
   4 add_executable (testopt testfuncs.c testfuncs.h testopt.c
   5   ${PROJECT_SOURCE_DIR}/util/timer.c ${PROJECT_SOURCE_DIR}/util/mt19937ar.c ${CMAKE_SOURCE_DIR}/util/nlopt-getopt.c)
   6 target_link_libraries (testopt ${nlopt_lib})
   7 target_include_directories (testopt PRIVATE ${NLOPT_PRIVATE_INCLUDE_DIRS})
   8 add_dependencies (tests testopt)
   9
  10 foreach (algo_index RANGE 29)# 42
  11   foreach (obj_index RANGE 1)# 21
  12     set (enable_ TRUE)
  13     # cxx stogo
  14     if (NOT WITH_CXX)
  15       if (algo_index STREQUAL 8 OR algo_index STREQUAL 9)
  16         set (enable_ FALSE)
  17       endif ()
  18     endif ()
  19     # L-BFGS
  20     if (algo_index STREQUAL 10)
  21       set (enable_ FALSE)
  22     endif ()
  23     # LN_NEWUOA_BOUND timeouts on msvc
  24     if (algo_index STREQUAL 27)
  25       set (enable_ FALSE)
  26     endif ()
  27     if (enable_)
  28       add_test (NAME testopt_algo${algo_index}_obj${obj_index} COMMAND testopt -a ${algo_index} -o ${obj_index})
  29     endif ()
  30   endforeach ()
  31 endforeach ()
  32
  33 if (NUMPY_FOUND AND PYTHONLIBS_FOUND AND (SWIG_FOUND OR (EXISTS ${PROJECT_SOURCE_DIR}/swig/nlopt-python.cpp)))
  34   set (PYINSTALLCHECK_ENVIRONMENT "LD_LIBRARY_PATH=${PROJECT_BINARY_DIR}/swig"
  35                                   "PYTHONPATH=${PROJECT_BINARY_DIR}/swig"
  36     )
  37   add_test (NAME test_python COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/t_python.py)
  38   set_tests_properties (test_python PROPERTIES ENVIRONMENT "${PYINSTALLCHECK_ENVIRONMENT}")
  39 endif ()
  40
  41 if (OCTAVE_FOUND)
  42   add_test (NAME test_octave COMMAND ${OCTAVE_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/t_octave.m ${PROJECT_SOURCE_DIR}/octave ${PROJECT_BINARY_DIR}/octave)
  43 endif ()
  44
  45 if (GUILE_FOUND AND ((SWIG_FOUND AND SWIG_VERSION VERSION_GREATER 2.0.9) OR (EXISTS ${CMAKE_CURRENT_SOURCE_DIR}/nlopt-guile.cpp)))
  46   set (GUILECHECK_ENVIRONMENT "LD_LIBRARY_PATH=${PROJECT_BINARY_DIR}/swig"
  47                               "GUILE_LOAD_PATH=${PROJECT_BINARY_DIR}/swig"
  48     )
  49   add_test (NAME test_guile COMMAND ${GUILE_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/t_guile.scm)
  50   set_tests_properties (test_guile PROPERTIES ENVIRONMENT "${GUILECHECK_ENVIRONMENT}")
  51 endif ()