CMakeLists.txt

   1 #==============================================================================
   2 # NLOPT CMake file
   3 #
   4 # NLopt is a free/open-source library for nonlinear optimization, providing
   5 # a common interface for a number of different free optimization routines
   6 # available online as well as original implementations of various other
   7 # algorithms
   8 # WEBSITE: http://ab-initio.mit.edu/wiki/index.php/NLopt
   9 # AUTHOR: Steven G. Johnson
  10 #
  11 # This CMakeLists.txt file was created to compile NLOPT with the CMAKE utility.
  12 # Benoit Scherrer, 2010 CRL, Harvard Medical School
  13 # Copyright (c) 2008-2009 Children's Hospital Boston
  14 #==============================================================================
  15 cmake_minimum_required (VERSION 2.8.11)
  16
  17 if (NOT DEFINED CMAKE_BUILD_TYPE)
  18   set (CMAKE_BUILD_TYPE Release CACHE STRING "Build type")
  19 endif ()
  20
  21 project (nlopt)
  22
  23 #==============================================================================
  24 # version
  25 set (NLOPT_MAJOR_VERSION "2")
  26 set (NLOPT_MINOR_VERSION "5")
  27 set (NLOPT_BUGFIX_VERSION "0")
  28 set (NLOPT_VERSION_STRING ${NLOPT_MAJOR_VERSION}.${NLOPT_MINOR_VERSION}.${NLOPT_BUGFIX_VERSION})
  29 message (STATUS "NLopt version ${NLOPT_VERSION_STRING}")
  30
  31 # This is the ABI version number, which differes from the API version above
  32 # (it indicates ABI compatibility), but they are typically incremented together.
  33 set(SO_MAJOR 0)
  34 set(SO_MINOR 9)
  35 set(SO_PATCH 0)
  36 #==============================================================================
  37
  38 list (APPEND CMAKE_MODULE_PATH ${CMAKE_SOURCE_DIR}/cmake)
  39
  40 option (NLOPT_CXX "enable cxx routines" ON)
  41 option (BUILD_SHARED_LIBS "Build NLopt as a shared library" ON)
  42 option (NLOPT_PYTHON "build python bindings" ON)
  43 option (NLOPT_OCTAVE "build octave bindings" ON)
  44 option (NLOPT_MATLAB "build matlab bindings" ON)
  45 option (NLOPT_GUILE "build guile bindings" ON)
  46 option (NLOPT_SWIG "use SWIG to build bindings" ON)
  47
  48 if (CMAKE_SOURCE_DIR STREQUAL PROJECT_SOURCE_DIR)
  49   option (NLOPT_TESTS "build unit tests" ON)
  50 else ()
  51   option (NLOPT_TESTS "build unit tests" OFF)
  52 endif ()
  53
  54 include (GNUInstallDirs)
  55
  56 # Offer the user the choice of overriding the installation directories
  57 set (INSTALL_LIB_DIR     ${CMAKE_INSTALL_LIBDIR}        CACHE PATH "Installation directory for libraries")
  58 set (INSTALL_BIN_DIR     ${CMAKE_INSTALL_BINDIR}        CACHE PATH "Installation directory for executables")
  59 set (INSTALL_INCLUDE_DIR ${CMAKE_INSTALL_INCLUDEDIR}    CACHE PATH "Installation directory for header files")
  60 set (INSTALL_DATA_DIR    ${CMAKE_INSTALL_DATADIR}/nlopt CACHE PATH "Installation directory for data files")
  61 set (INSTALL_MAN_DIR     ${CMAKE_INSTALL_MANDIR}        CACHE PATH "Installation directory for man documentation")
  62 set (INSTALL_CMAKE_DIR   ${INSTALL_LIB_DIR}/cmake/nlopt CACHE PATH "Installation directory for cmake config files")
  63
  64 # Make relative paths absolute (needed later on)
  65 foreach (p LIB BIN INCLUDE DATA CMAKE)
  66   set (var INSTALL_${p}_DIR)
  67   set (RELATIVE_INSTALL_${p}_DIR ${INSTALL_${p}_DIR})
  68   if (NOT IS_ABSOLUTE "${${var}}")
  69     set(${var} "${CMAKE_INSTALL_PREFIX}/${${var}}")
  70   endif ()
  71 endforeach ()
  72
  73
  74 set (CMAKE_INSTALL_RPATH ${INSTALL_LIB_DIR})
  75 set (CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
  76 if(POLICY CMP0042)
  77   # Set MACOSX_RPATH to ON
  78   cmake_policy(SET CMP0042 NEW)
  79 endif()
  80
  81 include (CheckIncludeFiles)
  82 include (CheckFunctionExists)
  83 include (CheckTypeSize)
  84 include (CheckCCompilerFlag)
  85 include (CheckCXXSymbolExists)
  86 include (CheckCXXCompilerFlag)
  87 include (CheckLibraryExists)
  88
  89 #==============================================================================
  90 # COMPILATION CHECKINGS and CONFIGURATION GENERATION
  91 #==============================================================================
  92 check_include_file (dlfcn.h HAVE_DLFCN_H)
  93 check_include_file (getopt.h HAVE_GETOPT_H)
  94 check_include_file (unistd.h HAVE_UNISTD_H)
  95 check_include_file (string.h HAVE_STRING_H)
  96 check_include_file (strings.h HAVE_STRINGS_H)
  97 check_include_file (inttypes.h HAVE_INTTYPES_H)
  98 check_include_file (memory.h HAVE_MEMORY_H)
  99 check_include_file (stdlib.h HAVE_STDLIB_H)
 100 check_include_file (stdint.h HAVE_STDINT_H)
 101 check_include_file (time.h HAVE_TIME_H)
 102 check_include_file (sys/types.h HAVE_SYS_TYPES_H)
 103 check_include_file (sys/stat.h HAVE_SYS_STAT_H)
 104 check_include_file (sys/time.h HAVE_SYS_TIME_H)
 105 if (HAVE_TIME_H AND HAVE_SYS_TIME_H)
 106   set (TIME_WITH_SYS_TIME TRUE)
 107 endif ()
 108 check_function_exists (getpid HAVE_GETPID)
 109 check_function_exists (syscall HAVE_GETTID_SYSCALL)
 110 check_function_exists (isinf HAVE_ISINF)
 111 check_function_exists (isnan HAVE_ISNAN)
 112 check_function_exists (gettimeofday HAVE_GETTIMEOFDAY)
 113 check_function_exists (qsort_r HAVE_QSORT_R)
 114 check_function_exists (time HAVE_TIME)
 115 check_function_exists (copysign HAVE_COPYSIGN)
 116 check_type_size ("uint32_t" SIZEOF_UINT32_T)
 117 set (HAVE_UINT32_T ${SIZEOF_UINT32_T})
 118 check_type_size ("unsigned int" SIZEOF_UNSIGNED_INT)
 119 check_type_size ("unsigned long" SIZEOF_UNSIGNED_LONG)
 120
 121 check_library_exists ("m" sqrt "" HAVE_LIBM)
 122 if (HAVE_LIBM)
 123   set (M_LIBRARY m)
 124 endif()
 125
 126 if (NOT DEFINED HAVE_FPCLASSIFY)
 127   message(STATUS "Looking for fpclassify")
 128   file (WRITE ${PROJECT_BINARY_DIR}/fpclassify.c "#include <math.h>\n")
 129   file (APPEND ${PROJECT_BINARY_DIR}/fpclassify.c "int main(void) {\n")
 130   file (APPEND ${PROJECT_BINARY_DIR}/fpclassify.c "if (!fpclassify(3.14159)) fpclassify(2.7183);\n")
 131   file (APPEND ${PROJECT_BINARY_DIR}/fpclassify.c "  return 0; }\n")
 132   try_compile (HAVE_FPCLASSIFY
 133   ${PROJECT_BINARY_DIR}/build_fpclassify
 134   ${PROJECT_BINARY_DIR}/fpclassify.c
 135   CMAKE_FLAGS -DLINK_LIBRARIES=m)
 136   message(STATUS "Looking for fpclassify - ${HAVE_FPCLASSIFY}")
 137 endif ()
 138
 139 option (WITH_THREADLOCAL "check thread local keyword" ON)
 140 if (WITH_THREADLOCAL AND NOT DEFINED THREADLOCAL)
 141   foreach (_THREADLOCAL_KEY "__thread" "__declspec(thread)")
 142     unset (HAVE_THREAD_LOCAL_STORAGE CACHE)
 143     check_c_source_compiles("
 144     ${_THREADLOCAL_KEY} int tls;
 145
 146     int main(void) {
 147         return 0;
 148     }" HAVE_THREAD_LOCAL_STORAGE)
 149     if (HAVE_THREAD_LOCAL_STORAGE)
 150       set (THREADLOCAL ${_THREADLOCAL_KEY} CACHE STRING "Thread local keyword")
 151     endif ()
 152   endforeach()
 153 endif ()
 154
 155
 156 if (NLOPT_CXX OR NLOPT_PYTHON OR NLOPT_GUILE OR NLOPT_OCTAVE)
 157   check_cxx_symbol_exists (__cplusplus ciso646 SYSTEM_HAS_CXX)
 158   if (SYSTEM_HAS_CXX)
 159     check_cxx_compiler_flag ("-std=c++11" SUPPORTS_STDCXX11)
 160     if (SUPPORTS_STDCXX11)
 161       set (CMAKE_CXX_FLAGS "-std=c++11 ${CMAKE_CXX_FLAGS}")
 162       if (NLOPT_CXX)
 163         set (NLOPT_CXX11 ON)
 164       endif ()
 165     endif ()
 166   else()
 167     message (FATAL_ERROR "The compiler doesn't support CXX.")
 168   endif ()
 169 endif ()
 170
 171 #==============================================================================
 172 # CREATE nlopt_config.h
 173 #==============================================================================
 174
 175 configure_file (${CMAKE_CURRENT_SOURCE_DIR}/nlopt_config.h.in ${CMAKE_CURRENT_BINARY_DIR}/nlopt_config.h IMMEDIATE)
 176
 177 # pkgconfig file
 178 if (UNIX OR MINGW)
 179   configure_file (${CMAKE_CURRENT_SOURCE_DIR}/nlopt.pc.in ${CMAKE_CURRENT_BINARY_DIR}/nlopt.pc @ONLY)
 180   install (FILES ${CMAKE_CURRENT_BINARY_DIR}/nlopt.pc DESTINATION ${RELATIVE_INSTALL_LIB_DIR}/pkgconfig)
 181 endif ()
 182
 183 #==============================================================================
 184 # nlopt LIBRARY TARGET (SHARED OR STATIC)
 185 #==============================================================================
 186
 187 configure_file (src/api/nlopt.h ${PROJECT_BINARY_DIR}/src/api/nlopt.h COPYONLY)
 188
 189 set (NLOPT_HEADERS
 190   ${PROJECT_BINARY_DIR}/src/api/nlopt.h ${PROJECT_BINARY_DIR}/src/api/nlopt.hpp ${PROJECT_BINARY_DIR}/src/api/nlopt.f
 191 )
 192
 193 set (NLOPT_SOURCES
 194   src/algs/direct/DIRect.c src/algs/direct/direct_wrap.c src/algs/direct/DIRserial.c src/algs/direct/DIRsubrout.c src/algs/direct/direct-internal.h src/algs/direct/direct.h
 195   src/algs/cdirect/cdirect.c src/algs/cdirect/hybrid.c src/algs/cdirect/cdirect.h
 196   src/algs/praxis/praxis.c src/algs/praxis/praxis.h
 197   src/algs/luksan/plis.c src/algs/luksan/plip.c src/algs/luksan/pnet.c src/algs/luksan/mssubs.c src/algs/luksan/pssubs.c src/algs/luksan/luksan.h
 198   src/algs/crs/crs.c src/algs/crs/crs.h
 199   src/algs/mlsl/mlsl.c src/algs/mlsl/mlsl.h
 200   src/algs/mma/mma.c src/algs/mma/mma.h src/algs/mma/ccsa_quadratic.c
 201   src/algs/cobyla/cobyla.c src/algs/cobyla/cobyla.h
 202   src/algs/newuoa/newuoa.c src/algs/newuoa/newuoa.h
 203   src/algs/neldermead/nldrmd.c src/algs/neldermead/neldermead.h src/algs/neldermead/sbplx.c
 204   src/algs/auglag/auglag.c src/algs/auglag/auglag.h
 205   src/algs/bobyqa/bobyqa.c src/algs/bobyqa/bobyqa.h
 206   src/algs/isres/isres.c src/algs/isres/isres.h
 207   src/algs/slsqp/slsqp.c src/algs/slsqp/slsqp.h
 208   src/algs/esch/esch.c src/algs/esch/esch.h
 209   src/api/general.c src/api/options.c src/api/optimize.c src/api/deprecated.c src/api/nlopt-internal.h src/api/nlopt.h src/api/f77api.c src/api/f77funcs.h src/api/f77funcs_.h src/api/nlopt.hpp src/api/nlopt-in.hpp
 210   src/util/mt19937ar.c src/util/sobolseq.c src/util/soboldata.h src/util/timer.c src/util/stop.c src/util/nlopt-util.h src/util/redblack.c src/util/redblack.h src/util/qsort_r.c src/util/rescale.c
 211 )
 212
 213 if (NLOPT_CXX)
 214   list (APPEND NLOPT_SOURCES src/algs/stogo/global.cc src/algs/stogo/linalg.cc src/algs/stogo/local.cc src/algs/stogo/stogo.cc src/algs/stogo/tools.cc
 215         src/algs/stogo/global.h src/algs/stogo/linalg.h src/algs/stogo/local.h src/algs/stogo/stogo_config.h src/algs/stogo/stogo.h src/algs/stogo/tools.h)
 216 endif ()
 217 if (NLOPT_CXX11)
 218   list (APPEND NLOPT_SOURCES src/algs/ags/data_types.hpp src/algs/ags/evolvent.hpp src/algs/ags/evolvent.cc src/algs/ags/solver.hpp src/algs/ags/solver.cc
 219   src/algs/ags/local_optimizer.hpp src/algs/ags/local_optimizer.cc src/algs/ags/ags.h src/algs/ags/ags.cc)
 220 endif ()
 221
 222 install (FILES ${NLOPT_HEADERS} DESTINATION ${RELATIVE_INSTALL_INCLUDE_DIR})
 223
 224 set (nlopt_lib nlopt)
 225 add_library (${nlopt_lib} ${NLOPT_SOURCES})
 226 target_link_libraries (${nlopt_lib} ${M_LIBRARY})
 227
 228 set_target_properties (${nlopt_lib} PROPERTIES SOVERSION ${SO_MAJOR})
 229 set_target_properties (${nlopt_lib} PROPERTIES VERSION "${SO_MAJOR}.${SO_MINOR}.${SO_PATCH}")
 230
 231 #==============================================================================
 232 # INCLUDE DIRECTORIES
 233 #==============================================================================
 234 target_include_directories (${nlopt_lib} PRIVATE
 235   ${PROJECT_BINARY_DIR}/src/api
 236   ${PROJECT_BINARY_DIR}
 237   src/algs/stogo
 238   src/algs/ags
 239   src/util
 240   src/algs/direct
 241   src/algs/cdirect
 242   src/algs/praxis
 243   src/algs/luksan
 244   src/algs/crs
 245   src/algs/mlsl
 246   src/algs/mma
 247   src/algs/cobyla
 248   src/algs/newuoa
 249   src/algs/neldermead
 250   src/algs/auglag
 251   src/algs/bobyqa
 252   src/algs/isres
 253   src/algs/slsqp
 254   src/algs/esch
 255   src/api)
 256
 257 get_target_property (NLOPT_PRIVATE_INCLUDE_DIRS ${nlopt_lib} INCLUDE_DIRECTORIES)
 258 target_include_directories (${nlopt_lib} INTERFACE "$<BUILD_INTERFACE:${PROJECT_BINARY_DIR}/src/api>" "$<INSTALL_INTERFACE:$<INSTALL_PREFIX>/${CMAKE_INSTALL_INCLUDEDIR}>")
 259
 260 if (BUILD_SHARED_LIBS)
 261   target_compile_definitions (${nlopt_lib} PUBLIC -DNLOPT_DLL)
 262   target_compile_definitions (${nlopt_lib} PRIVATE -DNLOPT_DLL_EXPORT)
 263 endif ()
 264
 265 # pass -fPIC in case swig module is built with static library
 266 if (NOT BUILD_SHARED_LIBS)
 267   check_c_compiler_flag (-fPIC HAS_FPIC)
 268   if (HAS_FPIC)
 269     set (CMAKE_C_FLAGS "-fPIC ${CMAKE_C_FLAGS}")
 270     set (CMAKE_CXX_FLAGS "-fPIC ${CMAKE_CXX_FLAGS}")
 271   endif ()
 272 endif ()
 273
 274 install ( TARGETS ${nlopt_lib}
 275           EXPORT  NLoptLibraryDepends
 276           RUNTIME DESTINATION ${RELATIVE_INSTALL_BIN_DIR}
 277           LIBRARY DESTINATION ${RELATIVE_INSTALL_LIB_DIR}
 278           ARCHIVE DESTINATION ${RELATIVE_INSTALL_LIB_DIR}
 279         )
 280
 281 if (MSVC AND BUILD_SHARED_LIBS AND NOT CMAKE_VERSION VERSION_LESS 3.1)
 282   install (FILES $<TARGET_PDB_FILE:${nlopt_lib}> DESTINATION ${RELATIVE_INSTALL_BIN_DIR} CONFIGURATIONS Debug RelWithDebInfo COMPONENT Debug)
 283 endif ()
 284
 285 add_subdirectory (src/api)
 286
 287 if (NLOPT_PYTHON)
 288   find_package (PythonInterp)
 289   find_package (PythonLibs)
 290   find_package (NumPy)
 291 endif ()
 292
 293 if (NOT DEFINED INSTALL_PYTHON_DIR AND PYTHONINTERP_FOUND)
 294   execute_process ( COMMAND ${PYTHON_EXECUTABLE} -c "from distutils import sysconfig; print(sysconfig.get_python_lib(plat_specific=True, prefix='${CMAKE_INSTALL_PREFIX}'))"
 295                     OUTPUT_VARIABLE _ABS_PYTHON_MODULE_PATH
 296                     OUTPUT_STRIP_TRAILING_WHITESPACE )
 297
 298   get_filename_component (_ABS_PYTHON_MODULE_PATH ${_ABS_PYTHON_MODULE_PATH} ABSOLUTE)
 299   file (RELATIVE_PATH _REL_PYTHON_MODULE_PATH ${CMAKE_INSTALL_PREFIX} ${_ABS_PYTHON_MODULE_PATH})
 300
 301   set (INSTALL_PYTHON_DIR ${_REL_PYTHON_MODULE_PATH})
 302
 303 endif ()
 304
 305 if (NLOPT_GUILE)
 306   find_package (Guile)
 307 endif ()
 308
 309 if (NLOPT_SWIG)
 310   find_package (SWIG)
 311   if (SWIG_FOUND)
 312     add_subdirectory (src/swig)
 313   endif ()
 314 endif ()
 315
 316 if (NLOPT_OCTAVE)
 317   find_package (Octave)
 318 endif ()
 319
 320 if (NLOPT_MATLAB)
 321   find_package (Matlab COMPONENTS MX_LIBRARY)
 322 endif ()
 323
 324 if (OCTAVE_FOUND OR Matlab_FOUND)
 325   add_subdirectory (src/octave)
 326 endif ()
 327
 328 if (NLOPT_TESTS)
 329   enable_testing ()
 330   add_subdirectory (test)
 331 endif ()
 332
 333 set (CPACK_PACKAGE_NAME          "${CMAKE_PROJECT_NAME}")
 334 set (CPACK_PACKAGE_VERSION_MAJOR "${NLOPT_MAJOR_VERSION}")
 335 set (CPACK_PACKAGE_VERSION_MINOR "${NLOPT_MINOR_VERSION}")
 336 set (CPACK_PACKAGE_VERSION_PATCH "${NLOPT_BUGFIX_VERSION}")
 337 set (CPACK_SOURCE_GENERATOR      "TBZ2;TGZ"    )
 338 set (CPACK_BINARY_STGZ           "OFF"        )
 339 set (CPACK_BINARY_TBZ2           "ON"         )
 340 set (CPACK_BINARY_TGZ            "ON"         )
 341 set (CPACK_BINARY_TZ             "OFF"        )
 342 set (CPACK_SOURCE_IGNORE_FILES ".git;/build;.*~;${CPACK_SOURCE_IGNORE_FILES}")
 343
 344 set (CPACK_SOURCE_PACKAGE_FILE_NAME ${CPACK_PACKAGE_NAME}-${NLOPT_VERSION_STRING})
 345
 346 include (CPack)
 347
 348 # configuration files
 349 export (TARGETS ${nlopt_lib} NAMESPACE NLopt:: FILE ${PROJECT_BINARY_DIR}/NLoptLibraryDepends.cmake)
 350
 351 # Install the export set for use with the install-tree
 352 install(EXPORT NLoptLibraryDepends
 353         NAMESPACE NLopt::
 354         DESTINATION ${RELATIVE_INSTALL_CMAKE_DIR}
 355         COMPONENT Development)
 356
 357 # Create a NLOPTConfig.cmake file for the use from the install tree
 358 # and install it
 359 set (NLOPT_LIBRARIES "NLopt::${nlopt_lib}")
 360
 361 set (NLOPT_CMAKE_DIR "${INSTALL_CMAKE_DIR}")
 362 file (RELATIVE_PATH rel_include_dir "${NLOPT_CMAKE_DIR}" "${INSTALL_INCLUDE_DIR}")
 363 list (APPEND RELATIVE_NLOPT_INCLUDE_DIRS ${rel_include_dir})
 364
 365 file (RELATIVE_PATH rel_lib_dir "${NLOPT_CMAKE_DIR}" "${INSTALL_LIB_DIR}")
 366 list (APPEND RELATIVE_NLOPT_LIB_DIR ${rel_lib_dir})
 367
 368 configure_file (cmake/NLoptConfig.cmake.in NLoptConfig.cmake @ONLY)
 369 configure_file (cmake/NLoptConfigVersion.cmake.in NLoptConfigVersion.cmake @ONLY)
 370 install (FILES
 371           ${CMAKE_CURRENT_BINARY_DIR}/NLoptConfig.cmake
 372           ${CMAKE_CURRENT_BINARY_DIR}/NLoptConfigVersion.cmake
 373          DESTINATION ${RELATIVE_INSTALL_CMAKE_DIR}
 374          COMPONENT Development)