CMakeLists.txt

   1 #==============================================================================
   2 # NLOPT CMake file
   3 #
   4 # NLopt is a free/open-source library for nonlinear optimization, providing
   5 # a common interface for a number of different free optimization routines
   6 # available online as well as original implementations of various other
   7 # algorithms
   8 # WEBSITE: http://ab-initio.mit.edu/wiki/index.php/NLopt
   9 # AUTHOR: Steven G. Johnson
  10 #
  11 # This CMakeLists.txt file was created to compile NLOPT with the CMAKE utility.
  12 # Benoit Scherrer, 2010 CRL, Harvard Medical School
  13 # Copyright (c) 2008-2009 Children's Hospital Boston
  14 #==============================================================================
  15 cmake_minimum_required (VERSION 3.0)
  16
  17 if (NOT DEFINED CMAKE_BUILD_TYPE)
  18   set (CMAKE_BUILD_TYPE Release CACHE STRING "Build type")
  19 endif ()
  20
  21 project (nlopt)
  22
  23 list (APPEND CMAKE_MODULE_PATH ${CMAKE_SOURCE_DIR}/cmake)
  24
  25 option (NLOPT_CXX "enable cxx routines" OFF)
  26 option (BUILD_SHARED_LIBS "Build NLopt as a shared library" ON)
  27 option (NLOPT_PYTHON "build python bindings" ON)
  28 option (NLOPT_OCTAVE "build octave bindings" ON)
  29 option (NLOPT_MATLAB "build matlab bindings" ON)
  30 option (NLOPT_GUILE "build guile bindings" ON)
  31 option (NLOPT_SWIG "use SWIG to build bindings" ON)
  32
  33 set (NLOPT_SUFFIX)
  34 if (NLOPT_CXX)
  35   set (NLOPT_SUFFIX _cxx)
  36 endif ()
  37
  38 include (GNUInstallDirs)
  39
  40 # Offer the user the choice of overriding the installation directories
  41 set (INSTALL_LIB_DIR     ${CMAKE_INSTALL_LIBDIR}        CACHE PATH "Installation directory for libraries")
  42 set (INSTALL_BIN_DIR     ${CMAKE_INSTALL_BINDIR}        CACHE PATH "Installation directory for executables")
  43 set (INSTALL_INCLUDE_DIR ${CMAKE_INSTALL_INCLUDEDIR}    CACHE PATH "Installation directory for header files")
  44 set (INSTALL_DATA_DIR    ${CMAKE_INSTALL_DATADIR}/nlopt CACHE PATH "Installation directory for data files")
  45 set (INSTALL_MAN_DIR     ${CMAKE_INSTALL_MANDIR}        CACHE PATH "Installation directory for man documentation")
  46 set (INSTALL_CMAKE_DIR   ${INSTALL_LIB_DIR}/cmake/nlopt CACHE PATH "Installation directory for cmake config files")
  47
  48 # Make relative paths absolute (needed later on)
  49 foreach (p LIB BIN INCLUDE DATA CMAKE)
  50   set (var INSTALL_${p}_DIR)
  51   set (RELATIVE_INSTALL_${p}_DIR ${INSTALL_${p}_DIR})
  52   if (NOT IS_ABSOLUTE "${${var}}")
  53     set(${var} "${CMAKE_INSTALL_PREFIX}/${${var}}")
  54   endif ()
  55 endforeach ()
  56
  57
  58 set (CMAKE_INSTALL_RPATH ${INSTALL_LIB_DIR})
  59 set (CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
  60 if(POLICY CMP0042)
  61   # Set MACOSX_RPATH to ON
  62   cmake_policy(SET CMP0042 NEW)
  63 endif()
  64
  65 include (CheckIncludeFiles)
  66 include (CheckFunctionExists)
  67 include (CheckTypeSize)
  68 include (CheckCCompilerFlag)
  69 include (CheckCXXSymbolExists)
  70 include (CheckCXXCompilerFlag)
  71 include (CheckLibraryExists)
  72
  73 #==============================================================================
  74 # COMPILATION CHECKINGS and CONFIGURATION GENERATION
  75 #==============================================================================
  76 check_include_file (dlfcn.h HAVE_DLFCN_H)
  77 check_include_file (getopt.h HAVE_GETOPT_H)
  78 check_include_file (unistd.h HAVE_UNISTD_H)
  79 check_include_file (string.h HAVE_STRING_H)
  80 check_include_file (strings.h HAVE_STRINGS_H)
  81 check_include_file (inttypes.h HAVE_INTTYPES_H)
  82 check_include_file (memory.h HAVE_MEMORY_H)
  83 check_include_file (stdlib.h HAVE_STDLIB_H)
  84 check_include_file (stdint.h HAVE_STDINT_H)
  85 check_include_file (time.h HAVE_TIME_H)
  86 check_include_file (sys/types.h HAVE_SYS_TYPES_H)
  87 check_include_file (sys/stat.h HAVE_SYS_STAT_H)
  88 check_include_file (sys/time.h HAVE_SYS_TIME_H)
  89 if (HAVE_TIME_H AND HAVE_SYS_TIME_H)
  90   set (TIME_WITH_SYS_TIME TRUE)
  91 endif ()
  92 check_function_exists (getpid HAVE_GETPID)
  93 check_function_exists (syscall HAVE_GETTID_SYSCALL)
  94 check_function_exists (isinf HAVE_ISINF)
  95 check_function_exists (isnan HAVE_ISNAN)
  96 check_function_exists (gettimeofday HAVE_GETTIMEOFDAY)
  97 check_function_exists (qsort_r HAVE_QSORT_R)
  98 check_function_exists (time HAVE_TIME)
  99 check_function_exists (copysign HAVE_COPYSIGN)
 100 check_type_size ("uint32_t" SIZEOF_UINT32_T)
 101 set (HAVE_UINT32_T ${SIZEOF_UINT32_T})
 102 check_type_size ("unsigned int" SIZEOF_UNSIGNED_INT)
 103 check_type_size ("unsigned long" SIZEOF_UNSIGNED_LONG)
 104
 105 check_library_exists ("m" sqrt "" HAVE_LIBM)
 106 if (HAVE_LIBM)
 107   set (M_LIBRARY m)
 108 endif()
 109
 110 if (NOT DEFINED HAVE_FPCLASSIFY)
 111   message(STATUS "Looking for fpclassify")
 112   file (WRITE ${PROJECT_BINARY_DIR}/fpclassify.c "#include <math.h>\n")
 113   file (APPEND ${PROJECT_BINARY_DIR}/fpclassify.c "int main(void) {\n")
 114   file (APPEND ${PROJECT_BINARY_DIR}/fpclassify.c "if (!fpclassify(3.14159)) fpclassify(2.7183);\n")
 115   file (APPEND ${PROJECT_BINARY_DIR}/fpclassify.c "  return 0; }\n")
 116   try_compile (HAVE_FPCLASSIFY
 117   ${PROJECT_BINARY_DIR}/build_fpclassify
 118   ${PROJECT_BINARY_DIR}/fpclassify.c
 119   CMAKE_FLAGS -DLINK_LIBRARIES=m)
 120   message(STATUS "Looking for fpclassify - ${HAVE_FPCLASSIFY}")
 121 endif ()
 122
 123 option (WITH_THREADLOCAL "check thread local keyword" ON)
 124 if (WITH_THREADLOCAL AND NOT DEFINED HAVE_THREAD_LOCAL_STORAGE)
 125   foreach (_THREADLOCAL_KEY "__thread" "__declspec(thread)")
 126     unset (HAVE_THREAD_LOCAL_STORAGE CACHE)
 127     check_c_source_compiles("
 128     ${_THREADLOCAL_KEY} int tls;
 129
 130     int main(void) {
 131         return 0;
 132     }" HAVE_THREAD_LOCAL_STORAGE)
 133     if (${HAVE_THREAD_LOCAL_STORAGE})
 134       set (THREADLOCAL ${_THREADLOCAL_KEY})
 135     endif ()
 136   endforeach()
 137 endif ()
 138
 139 if (NLOPT_CXX OR NLOPT_PYTHON OR NLOPT_GUILE OR NLOPT_OCTAVE)
 140   check_cxx_symbol_exists (_LIBCPP_VERSION string SYSTEM_HAS_LIBCPP)
 141   if (SYSTEM_HAS_LIBCPP)
 142     check_cxx_compiler_flag ("-std=c++11" SUPPORTS_STDCXX11)
 143     if (SUPPORTS_STDCXX11)
 144       set (CMAKE_CXX_FLAGS "-std=c++11 ${CMAKE_CXX_FLAGS}")
 145     endif ()
 146   endif ()
 147 endif ()
 148
 149 #==============================================================================
 150 # version
 151 #==============================================================================
 152 set (NLOPT_MAJOR_VERSION "2")
 153 set (NLOPT_MINOR_VERSION "5")
 154 set (NLOPT_BUGFIX_VERSION "0")
 155 set (NLOPT_VERSION_STRING ${NLOPT_MAJOR_VERSION}.${NLOPT_MINOR_VERSION}.${NLOPT_BUGFIX_VERSION})
 156 message (STATUS "NLopt version ${NLOPT_VERSION_STRING}")
 157
 158 #==============================================================================
 159 # CREATE nlopt_config.h
 160 #==============================================================================
 161
 162 configure_file (${CMAKE_CURRENT_SOURCE_DIR}/nlopt_config.h.in ${CMAKE_CURRENT_BINARY_DIR}/nlopt_config.h IMMEDIATE)
 163
 164 # pkgconfig file
 165 if (UNIX OR MINGW)
 166   configure_file (${CMAKE_CURRENT_SOURCE_DIR}/nlopt.pc.in ${CMAKE_CURRENT_BINARY_DIR}/nlopt.pc @ONLY)
 167   install (FILES ${CMAKE_CURRENT_BINARY_DIR}/nlopt.pc DESTINATION ${RELATIVE_INSTALL_LIB_DIR}/pkgconfig)
 168 endif ()
 169
 170 #==============================================================================
 171 # nlopt LIBRARY TARGET (SHARED OR STATIC)
 172 #==============================================================================
 173
 174 configure_file (src/api/nlopt.h ${PROJECT_BINARY_DIR}/src/api/nlopt.h COPYONLY)
 175
 176 set (NLOPT_HEADERS
 177   ${PROJECT_BINARY_DIR}/src/api/nlopt.h ${PROJECT_BINARY_DIR}/src/api/nlopt.hpp ${PROJECT_BINARY_DIR}/src/api/nlopt.f
 178 )
 179
 180 set (NLOPT_SOURCES
 181   src/algs/direct/DIRect.c src/algs/direct/direct_wrap.c src/algs/direct/DIRserial.c src/algs/direct/DIRsubrout.c src/algs/direct/direct-internal.h src/algs/direct/direct.h
 182   src/algs/cdirect/cdirect.c src/algs/cdirect/hybrid.c src/algs/cdirect/cdirect.h
 183   src/algs/praxis/praxis.c src/algs/praxis/praxis.h
 184   src/algs/luksan/plis.c src/algs/luksan/plip.c src/algs/luksan/pnet.c src/algs/luksan/mssubs.c src/algs/luksan/pssubs.c src/algs/luksan/luksan.h
 185   src/algs/crs/crs.c src/algs/crs/crs.h
 186   src/algs/mlsl/mlsl.c src/algs/mlsl/mlsl.h
 187   src/algs/mma/mma.c src/algs/mma/mma.h src/algs/mma/ccsa_quadratic.c
 188   src/algs/cobyla/cobyla.c src/algs/cobyla/cobyla.h
 189   src/algs/newuoa/newuoa.c src/algs/newuoa/newuoa.h
 190   src/algs/neldermead/nldrmd.c src/algs/neldermead/neldermead.h src/algs/neldermead/sbplx.c
 191   src/algs/auglag/auglag.c src/algs/auglag/auglag.h
 192   src/algs/bobyqa/bobyqa.c src/algs/bobyqa/bobyqa.h
 193   src/algs/isres/isres.c src/algs/isres/isres.h
 194   src/algs/slsqp/slsqp.c src/algs/slsqp/slsqp.h
 195   src/algs/esch/esch.c src/algs/esch/esch.h
 196   src/api/general.c src/api/options.c src/api/optimize.c src/api/deprecated.c src/api/nlopt-internal.h src/api/nlopt.h src/api/f77api.c src/api/f77funcs.h src/api/f77funcs_.h src/api/nlopt.hpp src/api/nlopt-in.hpp
 197   src/util/mt19937ar.c src/util/sobolseq.c src/util/soboldata.h src/util/timer.c src/util/stop.c src/util/nlopt-util.h src/util/redblack.c src/util/redblack.h src/util/qsort_r.c src/util/rescale.c
 198 )
 199
 200 if (NLOPT_CXX)
 201   list (APPEND NLOPT_SOURCES src/algs/stogo/global.cc src/algs/stogo/linalg.cc src/algs/stogo/local.cc src/algs/stogo/stogo.cc src/algs/stogo/tools.cc
 202         src/algs/stogo/global.h src/algs/stogo/linalg.h src/algs/stogo/local.h src/algs/stogo/stogo_config.h src/algs/stogo/stogo.h src/algs/stogo/tools.h)
 203 endif ()
 204
 205 install (FILES ${NLOPT_HEADERS} DESTINATION ${RELATIVE_INSTALL_INCLUDE_DIR})
 206
 207 set (nlopt_lib nlopt${NLOPT_SUFFIX})
 208 add_library (${nlopt_lib} ${NLOPT_SOURCES})
 209 target_link_libraries (${nlopt_lib} ${M_LIBRARY})
 210
 211 set_target_properties (${nlopt_lib} PROPERTIES SOVERSION 0)
 212 set_target_properties (${nlopt_lib} PROPERTIES VERSION 0.9.0)
 213
 214 #==============================================================================
 215 # INCLUDE DIRECTORIES
 216 #==============================================================================
 217 target_include_directories (${nlopt_lib} PRIVATE
 218   ${PROJECT_BINARY_DIR}/src/api
 219   ${PROJECT_BINARY_DIR}
 220   src/algs/stogo
 221   src/util
 222   src/algs/direct
 223   src/algs/cdirect
 224   src/algs/praxis
 225   src/algs/luksan
 226   src/algs/crs
 227   src/algs/mlsl
 228   src/algs/mma
 229   src/algs/cobyla
 230   src/algs/newuoa
 231   src/algs/neldermead
 232   src/algs/auglag
 233   src/algs/bobyqa
 234   src/algs/isres
 235   src/algs/slsqp
 236   src/algs/esch
 237   src/api)
 238
 239 get_target_property (NLOPT_PRIVATE_INCLUDE_DIRS ${nlopt_lib} INCLUDE_DIRECTORIES)
 240 target_include_directories (${nlopt_lib} INTERFACE "$<BUILD_INTERFACE:${PROJECT_BINARY_DIR}/src/api>" "$<INSTALL_INTERFACE:$<INSTALL_PREFIX>/${CMAKE_INSTALL_INCLUDEDIR}>")
 241
 242 if (BUILD_SHARED_LIBS)
 243   target_compile_definitions (${nlopt_lib} PUBLIC -DNLOPT_DLL)
 244   target_compile_definitions (${nlopt_lib} PRIVATE -DNLOPT_DLL_EXPORT)
 245 endif ()
 246
 247 # pass -fPIC in case swig module is built with static library
 248 if (NOT BUILD_SHARED_LIBS)
 249   check_c_compiler_flag (-fPIC HAS_FPIC)
 250   if (HAS_FPIC)
 251     set (CMAKE_C_FLAGS "-fPIC ${CMAKE_C_FLAGS}")
 252     set (CMAKE_CXX_FLAGS "-fPIC ${CMAKE_CXX_FLAGS}")
 253   endif ()
 254 endif ()
 255
 256 install ( TARGETS ${nlopt_lib}
 257           EXPORT  NLoptLibraryDepends
 258           RUNTIME DESTINATION ${RELATIVE_INSTALL_BIN_DIR}
 259           LIBRARY DESTINATION ${RELATIVE_INSTALL_LIB_DIR}
 260           ARCHIVE DESTINATION ${RELATIVE_INSTALL_LIB_DIR}
 261         )
 262
 263 if (MSVC AND BUILD_SHARED_LIBS AND NOT CMAKE_VERSION VERSION_LESS 3.1)
 264   install (FILES $<TARGET_PDB_FILE:${nlopt_lib}> DESTINATION ${RELATIVE_INSTALL_BIN_DIR} CONFIGURATIONS Debug RelWithDebInfo COMPONENT Debug)
 265 endif ()
 266
 267 add_subdirectory (src/api)
 268
 269 if (NLOPT_PYTHON)
 270   find_package (PythonInterp)
 271   find_package (PythonLibs)
 272   find_package (NumPy)
 273 endif ()
 274
 275 if (NOT DEFINED INSTALL_PYTHON_DIR AND PYTHONINTERP_FOUND)
 276   execute_process ( COMMAND ${PYTHON_EXECUTABLE} -c "from distutils import sysconfig; print(sysconfig.get_python_lib(plat_specific=True, prefix='${CMAKE_INSTALL_PREFIX}'))"
 277                     OUTPUT_VARIABLE _ABS_PYTHON_MODULE_PATH
 278                     OUTPUT_STRIP_TRAILING_WHITESPACE )
 279
 280   get_filename_component (_ABS_PYTHON_MODULE_PATH ${_ABS_PYTHON_MODULE_PATH} ABSOLUTE)
 281   file (RELATIVE_PATH _REL_PYTHON_MODULE_PATH ${CMAKE_INSTALL_PREFIX} ${_ABS_PYTHON_MODULE_PATH})
 282
 283   set (INSTALL_PYTHON_DIR ${_REL_PYTHON_MODULE_PATH})
 284
 285 endif ()
 286
 287 if (NLOPT_GUILE)
 288   find_package (Guile)
 289 endif ()
 290
 291 if (NLOPT_SWIG)
 292   find_package (SWIG)
 293 endif ()
 294
 295 add_subdirectory (src/swig)
 296
 297 if (NLOPT_OCTAVE)
 298   find_package (Octave)
 299 endif ()
 300
 301 if (NLOPT_MATLAB)
 302   find_package (Matlab COMPONENTS MX_LIBRARY)
 303 endif ()
 304
 305 if (OCTAVE_FOUND OR Matlab_FOUND)
 306   add_subdirectory (src/octave)
 307 endif ()
 308
 309 enable_testing ()
 310 add_subdirectory (test)
 311
 312 set (CPACK_PACKAGE_NAME          "${CMAKE_PROJECT_NAME}")
 313 set (CPACK_PACKAGE_VERSION_MAJOR "${NLOPT_MAJOR_VERSION}")
 314 set (CPACK_PACKAGE_VERSION_MINOR "${NLOPT_MINOR_VERSION}")
 315 set (CPACK_PACKAGE_VERSION_PATCH "${NLOPT_BUGFIX_VERSION}")
 316 set (CPACK_SOURCE_GENERATOR      "TBZ2;TGZ"    )
 317 set (CPACK_BINARY_STGZ           "OFF"        )
 318 set (CPACK_BINARY_TBZ2           "ON"         )
 319 set (CPACK_BINARY_TGZ            "ON"         )
 320 set (CPACK_BINARY_TZ             "OFF"        )
 321 set (CPACK_SOURCE_IGNORE_FILES ".git;/build;.*~;${CPACK_SOURCE_IGNORE_FILES}")
 322
 323 set (CPACK_SOURCE_PACKAGE_FILE_NAME ${CPACK_PACKAGE_NAME}-${NLOPT_VERSION_STRING})
 324
 325 include (CPack)
 326
 327 # configuration files
 328 export (TARGETS ${nlopt_lib} NAMESPACE NLopt:: FILE ${PROJECT_BINARY_DIR}/NLoptLibraryDepends.cmake)
 329
 330 # Install the export set for use with the install-tree
 331 install(EXPORT NLoptLibraryDepends
 332         NAMESPACE NLopt::
 333         DESTINATION ${RELATIVE_INSTALL_CMAKE_DIR}
 334         COMPONENT Development)
 335
 336 # Create a NLOPTConfig.cmake file for the use from the install tree
 337 # and install it
 338 set (NLOPT_LIBRARIES "NLopt::${nlopt_lib}")
 339
 340 set (NLOPT_CMAKE_DIR "${INSTALL_CMAKE_DIR}")
 341 file (RELATIVE_PATH rel_include_dir "${NLOPT_CMAKE_DIR}" "${INSTALL_INCLUDE_DIR}")
 342 list (APPEND RELATIVE_NLOPT_INCLUDE_DIRS ${rel_include_dir})
 343
 344 file (RELATIVE_PATH rel_lib_dir "${NLOPT_CMAKE_DIR}" "${INSTALL_LIB_DIR}")
 345 list (APPEND RELATIVE_NLOPT_LIB_DIR ${rel_lib_dir})
 346
 347 configure_file (cmake/NLoptConfig.cmake.in NLoptConfig.cmake @ONLY)
 348 configure_file (cmake/NLoptConfigVersion.cmake.in NLoptConfigVersion.cmake @ONLY)
 349 install (FILES
 350           ${CMAKE_CURRENT_BINARY_DIR}/NLoptConfig.cmake
 351           ${CMAKE_CURRENT_BINARY_DIR}/NLoptConfigVersion.cmake
 352          DESTINATION ${RELATIVE_INSTALL_CMAKE_DIR}
 353          COMPONENT Development)