CMakeLists.txt

   1 #==============================================================================
   2 # NLOPT CMake file
   3 #
   4 # NLopt is a free/open-source library for nonlinear optimization, providing
   5 # a common interface for a number of different free optimization routines
   6 # available online as well as original implementations of various other
   7 # algorithms
   8 # WEBSITE: http://ab-initio.mit.edu/wiki/index.php/NLopt
   9 # AUTHOR: Steven G. Johnson
  10 #
  11 # This CMakeLists.txt file was created to compile NLOPT with the CMAKE utility.
  12 # Benoit Scherrer, 2010 CRL, Harvard Medical School
  13 # Copyright (c) 2008-2009 Children's Hospital Boston
  14 #==============================================================================
  15 cmake_minimum_required (VERSION 2.8.11)
  16
  17 if (NOT DEFINED CMAKE_BUILD_TYPE)
  18   set (CMAKE_BUILD_TYPE Release CACHE STRING "Build type")
  19 endif ()
  20
  21 project (nlopt)
  22
  23 #==============================================================================
  24 # version
  25 set (NLOPT_MAJOR_VERSION "2")
  26 set (NLOPT_MINOR_VERSION "5")
  27 set (NLOPT_BUGFIX_VERSION "0")
  28 set (NLOPT_VERSION_STRING ${NLOPT_MAJOR_VERSION}.${NLOPT_MINOR_VERSION}.${NLOPT_BUGFIX_VERSION})
  29 message (STATUS "NLopt version ${NLOPT_VERSION_STRING}")
  30
  31 # This is the ABI version number, which differes from the API version above
  32 # (it indicates ABI compatibility), but they are typically incremented together.
  33 set(SO_MAJOR 0)
  34 set(SO_MINOR 9)
  35 set(SO_PATCH 0)
  36 #==============================================================================
  37
  38 list (APPEND CMAKE_MODULE_PATH ${CMAKE_SOURCE_DIR}/cmake)
  39
  40 option (NLOPT_CXX "enable cxx routines" OFF)
  41 option (BUILD_SHARED_LIBS "Build NLopt as a shared library" ON)
  42 option (NLOPT_PYTHON "build python bindings" ON)
  43 option (NLOPT_OCTAVE "build octave bindings" ON)
  44 option (NLOPT_MATLAB "build matlab bindings" ON)
  45 option (NLOPT_GUILE "build guile bindings" ON)
  46 option (NLOPT_SWIG "use SWIG to build bindings" ON)
  47 option (NLOPT_LINK_PYTHON "link Python libs" ON)
  48
  49 if (CMAKE_SOURCE_DIR STREQUAL PROJECT_SOURCE_DIR)
  50   option (NLOPT_TESTS "build unit tests" ON)
  51 else ()
  52   option (NLOPT_TESTS "build unit tests" OFF)
  53 endif ()
  54
  55 set (NLOPT_SUFFIX)
  56 if (NLOPT_CXX)
  57   set (NLOPT_SUFFIX _cxx)
  58 endif ()
  59
  60 include (GNUInstallDirs)
  61
  62 # Offer the user the choice of overriding the installation directories
  63 set (INSTALL_LIB_DIR     ${CMAKE_INSTALL_LIBDIR}        CACHE PATH "Installation directory for libraries")
  64 set (INSTALL_BIN_DIR     ${CMAKE_INSTALL_BINDIR}        CACHE PATH "Installation directory for executables")
  65 set (INSTALL_INCLUDE_DIR ${CMAKE_INSTALL_INCLUDEDIR}    CACHE PATH "Installation directory for header files")
  66 set (INSTALL_DATA_DIR    ${CMAKE_INSTALL_DATADIR}/nlopt CACHE PATH "Installation directory for data files")
  67 set (INSTALL_MAN_DIR     ${CMAKE_INSTALL_MANDIR}        CACHE PATH "Installation directory for man documentation")
  68 set (INSTALL_CMAKE_DIR   ${INSTALL_LIB_DIR}/cmake/nlopt CACHE PATH "Installation directory for cmake config files")
  69
  70 # Make relative paths absolute (needed later on)
  71 foreach (p LIB BIN INCLUDE DATA CMAKE)
  72   set (var INSTALL_${p}_DIR)
  73   set (RELATIVE_INSTALL_${p}_DIR ${INSTALL_${p}_DIR})
  74   if (NOT IS_ABSOLUTE "${${var}}")
  75     set(${var} "${CMAKE_INSTALL_PREFIX}/${${var}}")
  76   endif ()
  77 endforeach ()
  78
  79
  80 set (CMAKE_INSTALL_RPATH ${INSTALL_LIB_DIR})
  81 set (CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
  82 if(POLICY CMP0042)
  83   # Set MACOSX_RPATH to ON
  84   cmake_policy(SET CMP0042 NEW)
  85 endif()
  86
  87 include (CheckIncludeFiles)
  88 include (CheckFunctionExists)
  89 include (CheckTypeSize)
  90 include (CheckCCompilerFlag)
  91 include (CheckCXXSymbolExists)
  92 include (CheckCXXCompilerFlag)
  93 include (CheckLibraryExists)
  94
  95 #==============================================================================
  96 # COMPILATION CHECKINGS and CONFIGURATION GENERATION
  97 #==============================================================================
  98 check_include_file (dlfcn.h HAVE_DLFCN_H)
  99 check_include_file (getopt.h HAVE_GETOPT_H)
 100 check_include_file (unistd.h HAVE_UNISTD_H)
 101 check_include_file (string.h HAVE_STRING_H)
 102 check_include_file (strings.h HAVE_STRINGS_H)
 103 check_include_file (inttypes.h HAVE_INTTYPES_H)
 104 check_include_file (memory.h HAVE_MEMORY_H)
 105 check_include_file (stdlib.h HAVE_STDLIB_H)
 106 check_include_file (stdint.h HAVE_STDINT_H)
 107 check_include_file (time.h HAVE_TIME_H)
 108 check_include_file (sys/types.h HAVE_SYS_TYPES_H)
 109 check_include_file (sys/stat.h HAVE_SYS_STAT_H)
 110 check_include_file (sys/time.h HAVE_SYS_TIME_H)
 111 if (HAVE_TIME_H AND HAVE_SYS_TIME_H)
 112   set (TIME_WITH_SYS_TIME TRUE)
 113 endif ()
 114 check_function_exists (getpid HAVE_GETPID)
 115 check_function_exists (syscall HAVE_GETTID_SYSCALL)
 116 check_function_exists (isinf HAVE_ISINF)
 117 check_function_exists (isnan HAVE_ISNAN)
 118 check_function_exists (gettimeofday HAVE_GETTIMEOFDAY)
 119 check_function_exists (qsort_r HAVE_QSORT_R)
 120 check_function_exists (time HAVE_TIME)
 121 check_function_exists (copysign HAVE_COPYSIGN)
 122 check_type_size ("uint32_t" SIZEOF_UINT32_T)
 123 set (HAVE_UINT32_T ${SIZEOF_UINT32_T})
 124 check_type_size ("unsigned int" SIZEOF_UNSIGNED_INT)
 125 check_type_size ("unsigned long" SIZEOF_UNSIGNED_LONG)
 126
 127 check_library_exists ("m" sqrt "" HAVE_LIBM)
 128 if (HAVE_LIBM)
 129   set (M_LIBRARY m)
 130 endif()
 131
 132 if (NOT DEFINED HAVE_FPCLASSIFY)
 133   message(STATUS "Looking for fpclassify")
 134   file (WRITE ${PROJECT_BINARY_DIR}/fpclassify.c "#include <math.h>\n")
 135   file (APPEND ${PROJECT_BINARY_DIR}/fpclassify.c "int main(void) {\n")
 136   file (APPEND ${PROJECT_BINARY_DIR}/fpclassify.c "if (!fpclassify(3.14159)) fpclassify(2.7183);\n")
 137   file (APPEND ${PROJECT_BINARY_DIR}/fpclassify.c "  return 0; }\n")
 138   try_compile (HAVE_FPCLASSIFY
 139   ${PROJECT_BINARY_DIR}/build_fpclassify
 140   ${PROJECT_BINARY_DIR}/fpclassify.c
 141   CMAKE_FLAGS -DLINK_LIBRARIES=m)
 142   message(STATUS "Looking for fpclassify - ${HAVE_FPCLASSIFY}")
 143 endif ()
 144
 145 option (WITH_THREADLOCAL "check thread local keyword" ON)
 146 if (WITH_THREADLOCAL AND NOT DEFINED HAVE_THREAD_LOCAL_STORAGE)
 147   foreach (_THREADLOCAL_KEY "__thread" "__declspec(thread)")
 148     unset (HAVE_THREAD_LOCAL_STORAGE CACHE)
 149     check_c_source_compiles("
 150     ${_THREADLOCAL_KEY} int tls;
 151
 152     int main(void) {
 153         return 0;
 154     }" HAVE_THREAD_LOCAL_STORAGE)
 155     if (${HAVE_THREAD_LOCAL_STORAGE})
 156       set (THREADLOCAL ${_THREADLOCAL_KEY})
 157     endif ()
 158   endforeach()
 159 endif ()
 160
 161 if (NLOPT_CXX OR NLOPT_PYTHON OR NLOPT_GUILE OR NLOPT_OCTAVE)
 162   check_cxx_symbol_exists (__cplusplus ciso646 SYSTEM_HAS_CXX)
 163   if (SYSTEM_HAS_CXX)
 164     check_cxx_compiler_flag ("-std=c++11" SUPPORTS_STDCXX11)
 165     if (SUPPORTS_STDCXX11)
 166       set (CMAKE_CXX_FLAGS "-std=c++11 ${CMAKE_CXX_FLAGS}")
 167       if (NLOPT_CXX)
 168         set (NLOPT_CXX11 ON)
 169       endif ()
 170     endif ()
 171   else()
 172     message (FATAL_ERROR "The compiler doesn't support CXX.")
 173   endif ()
 174 endif ()
 175
 176 #==============================================================================
 177 # CREATE nlopt_config.h
 178 #==============================================================================
 179
 180 configure_file (${CMAKE_CURRENT_SOURCE_DIR}/nlopt_config.h.in ${CMAKE_CURRENT_BINARY_DIR}/nlopt_config.h IMMEDIATE)
 181
 182 # pkgconfig file
 183 if (UNIX OR MINGW)
 184   configure_file (${CMAKE_CURRENT_SOURCE_DIR}/nlopt.pc.in ${CMAKE_CURRENT_BINARY_DIR}/nlopt.pc @ONLY)
 185   install (FILES ${CMAKE_CURRENT_BINARY_DIR}/nlopt.pc DESTINATION ${RELATIVE_INSTALL_LIB_DIR}/pkgconfig)
 186 endif ()
 187
 188 #==============================================================================
 189 # nlopt LIBRARY TARGET (SHARED OR STATIC)
 190 #==============================================================================
 191
 192 configure_file (src/api/nlopt.h ${PROJECT_BINARY_DIR}/src/api/nlopt.h COPYONLY)
 193
 194 set (NLOPT_HEADERS
 195   ${PROJECT_BINARY_DIR}/src/api/nlopt.h ${PROJECT_BINARY_DIR}/src/api/nlopt.hpp ${PROJECT_BINARY_DIR}/src/api/nlopt.f
 196 )
 197
 198 set (NLOPT_SOURCES
 199   src/algs/direct/DIRect.c src/algs/direct/direct_wrap.c src/algs/direct/DIRserial.c src/algs/direct/DIRsubrout.c src/algs/direct/direct-internal.h src/algs/direct/direct.h
 200   src/algs/cdirect/cdirect.c src/algs/cdirect/hybrid.c src/algs/cdirect/cdirect.h
 201   src/algs/praxis/praxis.c src/algs/praxis/praxis.h
 202   src/algs/luksan/plis.c src/algs/luksan/plip.c src/algs/luksan/pnet.c src/algs/luksan/mssubs.c src/algs/luksan/pssubs.c src/algs/luksan/luksan.h
 203   src/algs/crs/crs.c src/algs/crs/crs.h
 204   src/algs/mlsl/mlsl.c src/algs/mlsl/mlsl.h
 205   src/algs/mma/mma.c src/algs/mma/mma.h src/algs/mma/ccsa_quadratic.c
 206   src/algs/cobyla/cobyla.c src/algs/cobyla/cobyla.h
 207   src/algs/newuoa/newuoa.c src/algs/newuoa/newuoa.h
 208   src/algs/neldermead/nldrmd.c src/algs/neldermead/neldermead.h src/algs/neldermead/sbplx.c
 209   src/algs/auglag/auglag.c src/algs/auglag/auglag.h
 210   src/algs/bobyqa/bobyqa.c src/algs/bobyqa/bobyqa.h
 211   src/algs/isres/isres.c src/algs/isres/isres.h
 212   src/algs/slsqp/slsqp.c src/algs/slsqp/slsqp.h
 213   src/algs/esch/esch.c src/algs/esch/esch.h
 214   src/api/general.c src/api/options.c src/api/optimize.c src/api/deprecated.c src/api/nlopt-internal.h src/api/nlopt.h src/api/f77api.c src/api/f77funcs.h src/api/f77funcs_.h src/api/nlopt.hpp src/api/nlopt-in.hpp
 215   src/util/mt19937ar.c src/util/sobolseq.c src/util/soboldata.h src/util/timer.c src/util/stop.c src/util/nlopt-util.h src/util/redblack.c src/util/redblack.h src/util/qsort_r.c src/util/rescale.c
 216 )
 217
 218 if (NLOPT_CXX)
 219   list (APPEND NLOPT_SOURCES src/algs/stogo/global.cc src/algs/stogo/linalg.cc src/algs/stogo/local.cc src/algs/stogo/stogo.cc src/algs/stogo/tools.cc
 220         src/algs/stogo/global.h src/algs/stogo/linalg.h src/algs/stogo/local.h src/algs/stogo/stogo_config.h src/algs/stogo/stogo.h src/algs/stogo/tools.h)
 221 endif ()
 222 if (NLOPT_CXX11)
 223   list (APPEND NLOPT_SOURCES src/algs/ags/data_types.hpp src/algs/ags/evolvent.hpp src/algs/ags/evolvent.cc src/algs/ags/solver.hpp src/algs/ags/solver.cc
 224   src/algs/ags/local_optimizer.hpp src/algs/ags/local_optimizer.cc src/algs/ags/ags.h src/algs/ags/ags.cc)
 225 endif ()
 226
 227 install (FILES ${NLOPT_HEADERS} DESTINATION ${RELATIVE_INSTALL_INCLUDE_DIR})
 228
 229 set (nlopt_lib nlopt${NLOPT_SUFFIX})
 230 add_library (${nlopt_lib} ${NLOPT_SOURCES})
 231 target_link_libraries (${nlopt_lib} ${M_LIBRARY})
 232
 233 set_target_properties (${nlopt_lib} PROPERTIES SOVERSION ${SO_MAJOR})
 234 set_target_properties (${nlopt_lib} PROPERTIES VERSION "${SO_MAJOR}.${SO_MINOR}.${SO_PATCH}")
 235
 236 #==============================================================================
 237 # INCLUDE DIRECTORIES
 238 #==============================================================================
 239 target_include_directories (${nlopt_lib} PRIVATE
 240   ${PROJECT_BINARY_DIR}/src/api
 241   ${PROJECT_BINARY_DIR}
 242   src/algs/stogo
 243   src/algs/ags
 244   src/util
 245   src/algs/direct
 246   src/algs/cdirect
 247   src/algs/praxis
 248   src/algs/luksan
 249   src/algs/crs
 250   src/algs/mlsl
 251   src/algs/mma
 252   src/algs/cobyla
 253   src/algs/newuoa
 254   src/algs/neldermead
 255   src/algs/auglag
 256   src/algs/bobyqa
 257   src/algs/isres
 258   src/algs/slsqp
 259   src/algs/esch
 260   src/api)
 261
 262 get_target_property (NLOPT_PRIVATE_INCLUDE_DIRS ${nlopt_lib} INCLUDE_DIRECTORIES)
 263 target_include_directories (${nlopt_lib} INTERFACE "$<BUILD_INTERFACE:${PROJECT_BINARY_DIR}/src/api>" "$<INSTALL_INTERFACE:$<INSTALL_PREFIX>/${CMAKE_INSTALL_INCLUDEDIR}>")
 264
 265 if (BUILD_SHARED_LIBS)
 266   target_compile_definitions (${nlopt_lib} PUBLIC -DNLOPT_DLL)
 267   target_compile_definitions (${nlopt_lib} PRIVATE -DNLOPT_DLL_EXPORT)
 268 endif ()
 269
 270 # pass -fPIC in case swig module is built with static library
 271 if (NOT BUILD_SHARED_LIBS)
 272   check_c_compiler_flag (-fPIC HAS_FPIC)
 273   if (HAS_FPIC)
 274     set (CMAKE_C_FLAGS "-fPIC ${CMAKE_C_FLAGS}")
 275     set (CMAKE_CXX_FLAGS "-fPIC ${CMAKE_CXX_FLAGS}")
 276   endif ()
 277 endif ()
 278
 279 install ( TARGETS ${nlopt_lib}
 280           EXPORT  NLoptLibraryDepends
 281           RUNTIME DESTINATION ${RELATIVE_INSTALL_BIN_DIR}
 282           LIBRARY DESTINATION ${RELATIVE_INSTALL_LIB_DIR}
 283           ARCHIVE DESTINATION ${RELATIVE_INSTALL_LIB_DIR}
 284         )
 285
 286 if (MSVC AND BUILD_SHARED_LIBS AND NOT CMAKE_VERSION VERSION_LESS 3.1)
 287   install (FILES $<TARGET_PDB_FILE:${nlopt_lib}> DESTINATION ${RELATIVE_INSTALL_BIN_DIR} CONFIGURATIONS Debug RelWithDebInfo COMPONENT Debug)
 288 endif ()
 289
 290 add_subdirectory (src/api)
 291
 292 if (NLOPT_PYTHON)
 293   find_package (PythonInterp)
 294   find_package (PythonLibs)
 295   find_package (NumPy)
 296 endif ()
 297
 298 if (NOT DEFINED INSTALL_PYTHON_DIR AND PYTHONINTERP_FOUND)
 299   execute_process ( COMMAND ${PYTHON_EXECUTABLE} -c "from distutils import sysconfig; print(sysconfig.get_python_lib(plat_specific=True, prefix='${CMAKE_INSTALL_PREFIX}'))"
 300                     OUTPUT_VARIABLE _ABS_PYTHON_MODULE_PATH
 301                     OUTPUT_STRIP_TRAILING_WHITESPACE )
 302
 303   get_filename_component (_ABS_PYTHON_MODULE_PATH ${_ABS_PYTHON_MODULE_PATH} ABSOLUTE)
 304   file (RELATIVE_PATH _REL_PYTHON_MODULE_PATH ${CMAKE_INSTALL_PREFIX} ${_ABS_PYTHON_MODULE_PATH})
 305
 306   set (INSTALL_PYTHON_DIR ${_REL_PYTHON_MODULE_PATH})
 307
 308 endif ()
 309
 310 if (NLOPT_GUILE)
 311   find_package (Guile)
 312 endif ()
 313
 314 if (NLOPT_SWIG)
 315   find_package (SWIG)
 316   if (SWIG_FOUND)
 317     add_subdirectory (src/swig)
 318   endif ()
 319 endif ()
 320
 321 if (NLOPT_OCTAVE)
 322   find_package (Octave)
 323 endif ()
 324
 325 if (NLOPT_MATLAB)
 326   find_package (Matlab COMPONENTS MX_LIBRARY)
 327 endif ()
 328
 329 if (OCTAVE_FOUND OR Matlab_FOUND)
 330   add_subdirectory (src/octave)
 331 endif ()
 332
 333 if (NLOPT_TESTS)
 334   enable_testing ()
 335   add_subdirectory (test)
 336 endif ()
 337
 338 set (CPACK_PACKAGE_NAME          "${CMAKE_PROJECT_NAME}")
 339 set (CPACK_PACKAGE_VERSION_MAJOR "${NLOPT_MAJOR_VERSION}")
 340 set (CPACK_PACKAGE_VERSION_MINOR "${NLOPT_MINOR_VERSION}")
 341 set (CPACK_PACKAGE_VERSION_PATCH "${NLOPT_BUGFIX_VERSION}")
 342 set (CPACK_SOURCE_GENERATOR      "TBZ2;TGZ"    )
 343 set (CPACK_BINARY_STGZ           "OFF"        )
 344 set (CPACK_BINARY_TBZ2           "ON"         )
 345 set (CPACK_BINARY_TGZ            "ON"         )
 346 set (CPACK_BINARY_TZ             "OFF"        )
 347 set (CPACK_SOURCE_IGNORE_FILES ".git;/build;.*~;${CPACK_SOURCE_IGNORE_FILES}")
 348
 349 set (CPACK_SOURCE_PACKAGE_FILE_NAME ${CPACK_PACKAGE_NAME}-${NLOPT_VERSION_STRING})
 350
 351 include (CPack)
 352
 353 # configuration files
 354 export (TARGETS ${nlopt_lib} NAMESPACE NLopt:: FILE ${PROJECT_BINARY_DIR}/NLoptLibraryDepends.cmake)
 355
 356 # Install the export set for use with the install-tree
 357 install(EXPORT NLoptLibraryDepends
 358         NAMESPACE NLopt::
 359         DESTINATION ${RELATIVE_INSTALL_CMAKE_DIR}
 360         COMPONENT Development)
 361
 362 # Create a NLOPTConfig.cmake file for the use from the install tree
 363 # and install it
 364 set (NLOPT_LIBRARIES "NLopt::${nlopt_lib}")
 365
 366 set (NLOPT_CMAKE_DIR "${INSTALL_CMAKE_DIR}")
 367 file (RELATIVE_PATH rel_include_dir "${NLOPT_CMAKE_DIR}" "${INSTALL_INCLUDE_DIR}")
 368 list (APPEND RELATIVE_NLOPT_INCLUDE_DIRS ${rel_include_dir})
 369
 370 file (RELATIVE_PATH rel_lib_dir "${NLOPT_CMAKE_DIR}" "${INSTALL_LIB_DIR}")
 371 list (APPEND RELATIVE_NLOPT_LIB_DIR ${rel_lib_dir})
 372
 373 configure_file (cmake/NLoptConfig.cmake.in NLoptConfig.cmake @ONLY)
 374 configure_file (cmake/NLoptConfigVersion.cmake.in NLoptConfigVersion.cmake @ONLY)
 375 install (FILES
 376           ${CMAKE_CURRENT_BINARY_DIR}/NLoptConfig.cmake
 377           ${CMAKE_CURRENT_BINARY_DIR}/NLoptConfigVersion.cmake
 378          DESTINATION ${RELATIVE_INSTALL_CMAKE_DIR}
 379          COMPONENT Development)