CMakeLists.txt

   1 #==============================================================================
   2 # NLOPT CMake file
   3 #
   4 # NLopt is a free/open-source library for nonlinear optimization, providing
   5 # a common interface for a number of different free optimization routines
   6 # available online as well as original implementations of various other
   7 # algorithms
   8 # WEBSITE: http://ab-initio.mit.edu/wiki/index.php/NLopt
   9 # AUTHOR: Steven G. Johnson
  10 #
  11 # This CMakeLists.txt file was created to compile NLOPT with the CMAKE utility.
  12 # Benoit Scherrer, 2010 CRL, Harvard Medical School
  13 # Copyright (c) 2008-2009 Children's Hospital Boston
  14 #==============================================================================
  15 cmake_minimum_required (VERSION 2.8.11)
  16
  17 if (NOT DEFINED CMAKE_BUILD_TYPE)
  18   set (CMAKE_BUILD_TYPE Release CACHE STRING "Build type")
  19 endif ()
  20
  21 project (nlopt)
  22
  23 #==============================================================================
  24 # version
  25 set (NLOPT_MAJOR_VERSION "2")
  26 set (NLOPT_MINOR_VERSION "5")
  27 set (NLOPT_BUGFIX_VERSION "0")
  28 set (NLOPT_VERSION_STRING ${NLOPT_MAJOR_VERSION}.${NLOPT_MINOR_VERSION}.${NLOPT_BUGFIX_VERSION})
  29 message (STATUS "NLopt version ${NLOPT_VERSION_STRING}")
  30
  31 # This is the ABI version number, which differes from the API version above
  32 # (it indicates ABI compatibility), but they are typically incremented together.
  33 set(SO_MAJOR 0)
  34 set(SO_MINOR 9)
  35 set(SO_PATCH 0)
  36 #==============================================================================
  37
  38 list (APPEND CMAKE_MODULE_PATH ${CMAKE_SOURCE_DIR}/cmake)
  39
  40 option (NLOPT_CXX "enable cxx routines" ON)
  41 option (BUILD_SHARED_LIBS "Build NLopt as a shared library" ON)
  42 option (NLOPT_PYTHON "build python bindings" ON)
  43 option (NLOPT_OCTAVE "build octave bindings" ON)
  44 option (NLOPT_MATLAB "build matlab bindings" ON)
  45 option (NLOPT_GUILE "build guile bindings" ON)
  46 option (NLOPT_SWIG "use SWIG to build bindings" ON)
  47 option (NLOPT_LINK_PYTHON "link Python libs" ON)
  48
  49 if (CMAKE_SOURCE_DIR STREQUAL PROJECT_SOURCE_DIR)
  50   option (NLOPT_TESTS "build unit tests" ON)
  51 else ()
  52   option (NLOPT_TESTS "build unit tests" OFF)
  53 endif ()
  54
  55 include (GNUInstallDirs)
  56
  57 # Offer the user the choice of overriding the installation directories
  58 set (INSTALL_LIB_DIR     ${CMAKE_INSTALL_LIBDIR}        CACHE PATH "Installation directory for libraries")
  59 set (INSTALL_BIN_DIR     ${CMAKE_INSTALL_BINDIR}        CACHE PATH "Installation directory for executables")
  60 set (INSTALL_INCLUDE_DIR ${CMAKE_INSTALL_INCLUDEDIR}    CACHE PATH "Installation directory for header files")
  61 set (INSTALL_DATA_DIR    ${CMAKE_INSTALL_DATADIR}/nlopt CACHE PATH "Installation directory for data files")
  62 set (INSTALL_MAN_DIR     ${CMAKE_INSTALL_MANDIR}        CACHE PATH "Installation directory for man documentation")
  63 set (INSTALL_CMAKE_DIR   ${INSTALL_LIB_DIR}/cmake/nlopt CACHE PATH "Installation directory for cmake config files")
  64
  65 # Make relative paths absolute (needed later on)
  66 foreach (p LIB BIN INCLUDE DATA CMAKE)
  67   set (var INSTALL_${p}_DIR)
  68   set (RELATIVE_INSTALL_${p}_DIR ${INSTALL_${p}_DIR})
  69   if (NOT IS_ABSOLUTE "${${var}}")
  70     set(${var} "${CMAKE_INSTALL_PREFIX}/${${var}}")
  71   endif ()
  72 endforeach ()
  73
  74
  75 set (CMAKE_INSTALL_RPATH ${INSTALL_LIB_DIR})
  76 set (CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
  77 if(POLICY CMP0042)
  78   # Set MACOSX_RPATH to ON
  79   cmake_policy(SET CMP0042 NEW)
  80 endif()
  81
  82 include (CheckIncludeFiles)
  83 include (CheckFunctionExists)
  84 include (CheckTypeSize)
  85 include (CheckCCompilerFlag)
  86 include (CheckCXXSymbolExists)
  87 include (CheckCXXCompilerFlag)
  88 include (CheckLibraryExists)
  89
  90 #==============================================================================
  91 # COMPILATION CHECKINGS and CONFIGURATION GENERATION
  92 #==============================================================================
  93 check_include_file (dlfcn.h HAVE_DLFCN_H)
  94 check_include_file (getopt.h HAVE_GETOPT_H)
  95 check_include_file (unistd.h HAVE_UNISTD_H)
  96 check_include_file (string.h HAVE_STRING_H)
  97 check_include_file (strings.h HAVE_STRINGS_H)
  98 check_include_file (inttypes.h HAVE_INTTYPES_H)
  99 check_include_file (memory.h HAVE_MEMORY_H)
 100 check_include_file (stdlib.h HAVE_STDLIB_H)
 101 check_include_file (stdint.h HAVE_STDINT_H)
 102 check_include_file (time.h HAVE_TIME_H)
 103 check_include_file (sys/types.h HAVE_SYS_TYPES_H)
 104 check_include_file (sys/stat.h HAVE_SYS_STAT_H)
 105 check_include_file (sys/time.h HAVE_SYS_TIME_H)
 106 if (HAVE_TIME_H AND HAVE_SYS_TIME_H)
 107   set (TIME_WITH_SYS_TIME TRUE)
 108 endif ()
 109 check_function_exists (getpid HAVE_GETPID)
 110 check_function_exists (syscall HAVE_GETTID_SYSCALL)
 111 check_function_exists (isinf HAVE_ISINF)
 112 check_function_exists (isnan HAVE_ISNAN)
 113 check_function_exists (gettimeofday HAVE_GETTIMEOFDAY)
 114 check_function_exists (qsort_r HAVE_QSORT_R)
 115 check_function_exists (time HAVE_TIME)
 116 check_function_exists (copysign HAVE_COPYSIGN)
 117 check_type_size ("uint32_t" SIZEOF_UINT32_T)
 118 set (HAVE_UINT32_T ${SIZEOF_UINT32_T})
 119 check_type_size ("unsigned int" SIZEOF_UNSIGNED_INT)
 120 check_type_size ("unsigned long" SIZEOF_UNSIGNED_LONG)
 121
 122 check_library_exists ("m" sqrt "" HAVE_LIBM)
 123 if (HAVE_LIBM)
 124   set (M_LIBRARY m)
 125 endif()
 126
 127 if (NOT DEFINED HAVE_FPCLASSIFY)
 128   message(STATUS "Looking for fpclassify")
 129   file (WRITE ${PROJECT_BINARY_DIR}/fpclassify.c "#include <math.h>\n")
 130   file (APPEND ${PROJECT_BINARY_DIR}/fpclassify.c "int main(void) {\n")
 131   file (APPEND ${PROJECT_BINARY_DIR}/fpclassify.c "if (!fpclassify(3.14159)) fpclassify(2.7183);\n")
 132   file (APPEND ${PROJECT_BINARY_DIR}/fpclassify.c "  return 0; }\n")
 133   try_compile (HAVE_FPCLASSIFY
 134   ${PROJECT_BINARY_DIR}/build_fpclassify
 135   ${PROJECT_BINARY_DIR}/fpclassify.c
 136   CMAKE_FLAGS -DLINK_LIBRARIES=m)
 137   message(STATUS "Looking for fpclassify - ${HAVE_FPCLASSIFY}")
 138 endif ()
 139
 140 option (WITH_THREADLOCAL "check thread local keyword" ON)
 141 if (WITH_THREADLOCAL AND NOT DEFINED THREADLOCAL)
 142   foreach (_THREADLOCAL_KEY "__thread" "__declspec(thread)")
 143     unset (HAVE_THREAD_LOCAL_STORAGE CACHE)
 144     check_c_source_compiles("
 145     ${_THREADLOCAL_KEY} int tls;
 146
 147     int main(void) {
 148         return 0;
 149     }" HAVE_THREAD_LOCAL_STORAGE)
 150     if (HAVE_THREAD_LOCAL_STORAGE)
 151       set (THREADLOCAL ${_THREADLOCAL_KEY} CACHE STRING "Thread local keyword")
 152     endif ()
 153   endforeach()
 154 endif ()
 155
 156
 157 if (NLOPT_CXX OR NLOPT_PYTHON OR NLOPT_GUILE OR NLOPT_OCTAVE)
 158   check_cxx_symbol_exists (__cplusplus ciso646 SYSTEM_HAS_CXX)
 159   if (SYSTEM_HAS_CXX)
 160     check_cxx_compiler_flag ("-std=c++11" SUPPORTS_STDCXX11)
 161     if (SUPPORTS_STDCXX11)
 162       set (CMAKE_CXX_FLAGS "-std=c++11 ${CMAKE_CXX_FLAGS}")
 163       if (NLOPT_CXX)
 164         set (NLOPT_CXX11 ON)
 165       endif ()
 166     endif ()
 167   else()
 168     message (FATAL_ERROR "The compiler doesn't support CXX.")
 169   endif ()
 170 endif ()
 171
 172 #==============================================================================
 173 # CREATE nlopt_config.h
 174 #==============================================================================
 175
 176 configure_file (${CMAKE_CURRENT_SOURCE_DIR}/nlopt_config.h.in ${CMAKE_CURRENT_BINARY_DIR}/nlopt_config.h IMMEDIATE)
 177
 178 # pkgconfig file
 179 if (UNIX OR MINGW)
 180   configure_file (${CMAKE_CURRENT_SOURCE_DIR}/nlopt.pc.in ${CMAKE_CURRENT_BINARY_DIR}/nlopt.pc @ONLY)
 181   install (FILES ${CMAKE_CURRENT_BINARY_DIR}/nlopt.pc DESTINATION ${RELATIVE_INSTALL_LIB_DIR}/pkgconfig)
 182 endif ()
 183
 184 #==============================================================================
 185 # nlopt LIBRARY TARGET (SHARED OR STATIC)
 186 #==============================================================================
 187
 188 configure_file (src/api/nlopt.h ${PROJECT_BINARY_DIR}/src/api/nlopt.h COPYONLY)
 189
 190 set (NLOPT_HEADERS
 191   ${PROJECT_BINARY_DIR}/src/api/nlopt.h ${PROJECT_BINARY_DIR}/src/api/nlopt.hpp ${PROJECT_BINARY_DIR}/src/api/nlopt.f
 192 )
 193
 194 set (NLOPT_SOURCES
 195   src/algs/direct/DIRect.c src/algs/direct/direct_wrap.c src/algs/direct/DIRserial.c src/algs/direct/DIRsubrout.c src/algs/direct/direct-internal.h src/algs/direct/direct.h
 196   src/algs/cdirect/cdirect.c src/algs/cdirect/hybrid.c src/algs/cdirect/cdirect.h
 197   src/algs/praxis/praxis.c src/algs/praxis/praxis.h
 198   src/algs/luksan/plis.c src/algs/luksan/plip.c src/algs/luksan/pnet.c src/algs/luksan/mssubs.c src/algs/luksan/pssubs.c src/algs/luksan/luksan.h
 199   src/algs/crs/crs.c src/algs/crs/crs.h
 200   src/algs/mlsl/mlsl.c src/algs/mlsl/mlsl.h
 201   src/algs/mma/mma.c src/algs/mma/mma.h src/algs/mma/ccsa_quadratic.c
 202   src/algs/cobyla/cobyla.c src/algs/cobyla/cobyla.h
 203   src/algs/newuoa/newuoa.c src/algs/newuoa/newuoa.h
 204   src/algs/neldermead/nldrmd.c src/algs/neldermead/neldermead.h src/algs/neldermead/sbplx.c
 205   src/algs/auglag/auglag.c src/algs/auglag/auglag.h
 206   src/algs/bobyqa/bobyqa.c src/algs/bobyqa/bobyqa.h
 207   src/algs/isres/isres.c src/algs/isres/isres.h
 208   src/algs/slsqp/slsqp.c src/algs/slsqp/slsqp.h
 209   src/algs/esch/esch.c src/algs/esch/esch.h
 210   src/api/general.c src/api/options.c src/api/optimize.c src/api/deprecated.c src/api/nlopt-internal.h src/api/nlopt.h src/api/f77api.c src/api/f77funcs.h src/api/f77funcs_.h src/api/nlopt.hpp src/api/nlopt-in.hpp
 211   src/util/mt19937ar.c src/util/sobolseq.c src/util/soboldata.h src/util/timer.c src/util/stop.c src/util/nlopt-util.h src/util/redblack.c src/util/redblack.h src/util/qsort_r.c src/util/rescale.c
 212 )
 213
 214 if (NLOPT_CXX)
 215   list (APPEND NLOPT_SOURCES src/algs/stogo/global.cc src/algs/stogo/linalg.cc src/algs/stogo/local.cc src/algs/stogo/stogo.cc src/algs/stogo/tools.cc
 216         src/algs/stogo/global.h src/algs/stogo/linalg.h src/algs/stogo/local.h src/algs/stogo/stogo_config.h src/algs/stogo/stogo.h src/algs/stogo/tools.h)
 217 endif ()
 218 if (NLOPT_CXX11)
 219   list (APPEND NLOPT_SOURCES src/algs/ags/data_types.hpp src/algs/ags/evolvent.hpp src/algs/ags/evolvent.cc src/algs/ags/solver.hpp src/algs/ags/solver.cc
 220   src/algs/ags/local_optimizer.hpp src/algs/ags/local_optimizer.cc src/algs/ags/ags.h src/algs/ags/ags.cc)
 221 endif ()
 222
 223 install (FILES ${NLOPT_HEADERS} DESTINATION ${RELATIVE_INSTALL_INCLUDE_DIR})
 224
 225 set (nlopt_lib nlopt)
 226 add_library (${nlopt_lib} ${NLOPT_SOURCES})
 227 target_link_libraries (${nlopt_lib} ${M_LIBRARY})
 228
 229 set_target_properties (${nlopt_lib} PROPERTIES SOVERSION ${SO_MAJOR})
 230 set_target_properties (${nlopt_lib} PROPERTIES VERSION "${SO_MAJOR}.${SO_MINOR}.${SO_PATCH}")
 231
 232 #==============================================================================
 233 # INCLUDE DIRECTORIES
 234 #==============================================================================
 235 target_include_directories (${nlopt_lib} PRIVATE
 236   ${PROJECT_BINARY_DIR}/src/api
 237   ${PROJECT_BINARY_DIR}
 238   src/algs/stogo
 239   src/algs/ags
 240   src/util
 241   src/algs/direct
 242   src/algs/cdirect
 243   src/algs/praxis
 244   src/algs/luksan
 245   src/algs/crs
 246   src/algs/mlsl
 247   src/algs/mma
 248   src/algs/cobyla
 249   src/algs/newuoa
 250   src/algs/neldermead
 251   src/algs/auglag
 252   src/algs/bobyqa
 253   src/algs/isres
 254   src/algs/slsqp
 255   src/algs/esch
 256   src/api)
 257
 258 get_target_property (NLOPT_PRIVATE_INCLUDE_DIRS ${nlopt_lib} INCLUDE_DIRECTORIES)
 259 target_include_directories (${nlopt_lib} INTERFACE "$<BUILD_INTERFACE:${PROJECT_BINARY_DIR}/src/api>" "$<INSTALL_INTERFACE:$<INSTALL_PREFIX>/${CMAKE_INSTALL_INCLUDEDIR}>")
 260
 261 if (BUILD_SHARED_LIBS)
 262   target_compile_definitions (${nlopt_lib} PUBLIC -DNLOPT_DLL)
 263   target_compile_definitions (${nlopt_lib} PRIVATE -DNLOPT_DLL_EXPORT)
 264 endif ()
 265
 266 # pass -fPIC in case swig module is built with static library
 267 if (NOT BUILD_SHARED_LIBS)
 268   check_c_compiler_flag (-fPIC HAS_FPIC)
 269   if (HAS_FPIC)
 270     set (CMAKE_C_FLAGS "-fPIC ${CMAKE_C_FLAGS}")
 271     set (CMAKE_CXX_FLAGS "-fPIC ${CMAKE_CXX_FLAGS}")
 272   endif ()
 273 endif ()
 274
 275 install ( TARGETS ${nlopt_lib}
 276           EXPORT  NLoptLibraryDepends
 277           RUNTIME DESTINATION ${RELATIVE_INSTALL_BIN_DIR}
 278           LIBRARY DESTINATION ${RELATIVE_INSTALL_LIB_DIR}
 279           ARCHIVE DESTINATION ${RELATIVE_INSTALL_LIB_DIR}
 280         )
 281
 282 if (MSVC AND BUILD_SHARED_LIBS AND NOT CMAKE_VERSION VERSION_LESS 3.1)
 283   install (FILES $<TARGET_PDB_FILE:${nlopt_lib}> DESTINATION ${RELATIVE_INSTALL_BIN_DIR} CONFIGURATIONS Debug RelWithDebInfo COMPONENT Debug)
 284 endif ()
 285
 286 add_subdirectory (src/api)
 287
 288 if (NLOPT_PYTHON)
 289   find_package (PythonInterp)
 290   find_package (PythonLibs)
 291   find_package (NumPy)
 292 endif ()
 293
 294 if (NOT DEFINED INSTALL_PYTHON_DIR AND PYTHONINTERP_FOUND)
 295   execute_process ( COMMAND ${PYTHON_EXECUTABLE} -c "from distutils import sysconfig; print(sysconfig.get_python_lib(plat_specific=True, prefix='${CMAKE_INSTALL_PREFIX}'))"
 296                     OUTPUT_VARIABLE _ABS_PYTHON_MODULE_PATH
 297                     OUTPUT_STRIP_TRAILING_WHITESPACE )
 298
 299   get_filename_component (_ABS_PYTHON_MODULE_PATH ${_ABS_PYTHON_MODULE_PATH} ABSOLUTE)
 300   file (RELATIVE_PATH _REL_PYTHON_MODULE_PATH ${CMAKE_INSTALL_PREFIX} ${_ABS_PYTHON_MODULE_PATH})
 301
 302   set (INSTALL_PYTHON_DIR ${_REL_PYTHON_MODULE_PATH})
 303
 304 endif ()
 305
 306 if (NLOPT_GUILE)
 307   find_package (Guile)
 308 endif ()
 309
 310 if (NLOPT_SWIG)
 311   find_package (SWIG)
 312   if (SWIG_FOUND)
 313     add_subdirectory (src/swig)
 314   endif ()
 315 endif ()
 316
 317 if (NLOPT_OCTAVE)
 318   find_package (Octave)
 319 endif ()
 320
 321 if (NLOPT_MATLAB)
 322   find_package (Matlab COMPONENTS MX_LIBRARY)
 323 endif ()
 324
 325 if (OCTAVE_FOUND OR Matlab_FOUND)
 326   add_subdirectory (src/octave)
 327 endif ()
 328
 329 if (NLOPT_TESTS)
 330   enable_testing ()
 331   add_subdirectory (test)
 332 endif ()
 333
 334 set (CPACK_PACKAGE_NAME          "${CMAKE_PROJECT_NAME}")
 335 set (CPACK_PACKAGE_VERSION_MAJOR "${NLOPT_MAJOR_VERSION}")
 336 set (CPACK_PACKAGE_VERSION_MINOR "${NLOPT_MINOR_VERSION}")
 337 set (CPACK_PACKAGE_VERSION_PATCH "${NLOPT_BUGFIX_VERSION}")
 338 set (CPACK_SOURCE_GENERATOR      "TBZ2;TGZ"    )
 339 set (CPACK_BINARY_STGZ           "OFF"        )
 340 set (CPACK_BINARY_TBZ2           "ON"         )
 341 set (CPACK_BINARY_TGZ            "ON"         )
 342 set (CPACK_BINARY_TZ             "OFF"        )
 343 set (CPACK_SOURCE_IGNORE_FILES ".git;/build;.*~;${CPACK_SOURCE_IGNORE_FILES}")
 344
 345 set (CPACK_SOURCE_PACKAGE_FILE_NAME ${CPACK_PACKAGE_NAME}-${NLOPT_VERSION_STRING})
 346
 347 include (CPack)
 348
 349 # configuration files
 350 export (TARGETS ${nlopt_lib} NAMESPACE NLopt:: FILE ${PROJECT_BINARY_DIR}/NLoptLibraryDepends.cmake)
 351
 352 # Install the export set for use with the install-tree
 353 install(EXPORT NLoptLibraryDepends
 354         NAMESPACE NLopt::
 355         DESTINATION ${RELATIVE_INSTALL_CMAKE_DIR}
 356         COMPONENT Development)
 357
 358 # Create a NLOPTConfig.cmake file for the use from the install tree
 359 # and install it
 360 set (NLOPT_LIBRARIES "NLopt::${nlopt_lib}")
 361
 362 set (NLOPT_CMAKE_DIR "${INSTALL_CMAKE_DIR}")
 363 file (RELATIVE_PATH rel_include_dir "${NLOPT_CMAKE_DIR}" "${INSTALL_INCLUDE_DIR}")
 364 list (APPEND RELATIVE_NLOPT_INCLUDE_DIRS ${rel_include_dir})
 365
 366 file (RELATIVE_PATH rel_lib_dir "${NLOPT_CMAKE_DIR}" "${INSTALL_LIB_DIR}")
 367 list (APPEND RELATIVE_NLOPT_LIB_DIR ${rel_lib_dir})
 368
 369 configure_file (cmake/NLoptConfig.cmake.in NLoptConfig.cmake @ONLY)
 370 configure_file (cmake/NLoptConfigVersion.cmake.in NLoptConfigVersion.cmake @ONLY)
 371 install (FILES
 372           ${CMAKE_CURRENT_BINARY_DIR}/NLoptConfig.cmake
 373           ${CMAKE_CURRENT_BINARY_DIR}/NLoptConfigVersion.cmake
 374          DESTINATION ${RELATIVE_INSTALL_CMAKE_DIR}
 375          COMPONENT Development)