nailing-cargo

   1 #!/usr/bin/perl -w
   2 # nailing-cargo: wrapper to use unpublished local crates
   3 # SPDX-License-Identifier: AGPL-3.0-or-later
   4
   5 our $self;
   6
   7 use strict;
   8 use POSIX;
   9 use Types::Serialiser;
  10
  11 our %archmap = (
  12     RPI => 'arm-unknown-linux-gnueabihf',
  13 );
  14
  15 BEGIN {
  16   $self = $0;  $self =~ s{^.*/(?=.)}{};
  17   my $deref = $0;
  18   while ($deref =~ m{^/}) {
  19     my $link = readlink $deref;
  20     if (!defined $link) {
  21       $! == EINVAL
  22         or die "$self: checking our script location $deref: $!\n";
  23       $deref =~ s{/[^/]+$}{}
  24         or die "$self: unexpected script path: $deref\n";
  25       unshift @INC, $deref."/TOML-Tiny/lib";
  26       last;
  27     }
  28     last if $link !~ m{^/};
  29     $deref = $link;
  30   }
  31 }
  32
  33 use Fcntl qw(LOCK_EX);
  34 use File::Compare;
  35 use TOML::Tiny::Faithful;
  36
  37 our $src_absdir = getcwd() // die "$self: getcwd failed: $!\n";
  38
  39 our $worksphere = $src_absdir;
  40 $worksphere =~ s{/([^/]+)$}{}
  41   or die "$self: cwd \`$worksphere' unsupported!\n";
  42 our $subdir = $1; # leafname
  43
  44 our $lockfile = "../.nailing-cargo.lock";
  45
  46 our @args_preface;
  47 our $cargo_subcmd;
  48 our $command_is_cargo;
  49 our $alt_cargo_lock;
  50 our $cargo_lock_update;
  51 our $pass_options;
  52 our $online;
  53
  54 #
  55 our %subcmd_props = (
  56 # build (default)  =>[qw(                                        )],
  57 'generate-lockfile'=>[qw( lock-update !target        !target-dir )],
  58  update            =>[qw( lock-update !target online             )],
  59  fetch             =>[qw(                     online !target-dir )],
  60                     );
  61
  62 our @subcmd_xprops = qw(!manifest-path !offline !locked);
  63
  64 our @configs;
  65 our $verbose=1;
  66 our ($noact,$dump);
  67 our $target;
  68
  69 sub read_or_enoent ($) {
  70   my ($fn) = @_;
  71   if (!open R, '<', $fn) {
  72     return undef if $!==ENOENT;
  73     die "$self: open $fn: $!\n";
  74   }
  75   local ($/) = undef;
  76   my ($r) = <R> // die "$self: read $fn: $!\n";
  77   $r;
  78 }
  79
  80 sub stat_exists ($$) {
  81   my ($fn, $what) = @_;
  82   if (stat $fn) { return 1; }
  83   $!==ENOENT or die "$self: stat $what: $fn: $!\n";
  84   return 0;
  85 }
  86
  87 sub subcmd_p ($) {
  88   print STDERR " subcmd_p ".(join ' ', keys %$cargo_subcmd)."   | @_\n"
  89     if $dump;
  90   $cargo_subcmd->{$_[0]}
  91 }
  92
  93 sub toml_or_enoent ($$) {
  94   my ($f,$what) = @_;
  95   my $toml = read_or_enoent($f) // return;
  96   print STDERR "Read TOML from $f\n" if $dump;
  97   my ($v,$e) = from_toml($toml);
  98   if (!defined $v) {
  99     chomp $e;
 100     die "$self: parse TOML: $what: $f: $e\n";
 101   }
 102   die "$e ?" if length $e;
 103   $v;
 104 }
 105
 106 sub load1config ($) {
 107   my ($f) = @_;
 108   my $toml = toml_or_enoent($f, "config file");
 109   push @configs, $toml if defined $toml;
 110 }
 111
 112 sub loadconfigs () {
 113   my $dotfile = ".nailing-cargo.toml";
 114   load1config("../Nailing-Cargo.toml");
 115   load1config($dotfile);
 116   load1config("$ENV{HOME}/$dotfile") if defined $ENV{HOME};
 117   load1config("/etc/nailing-cargo/cfg.toml");
 118 }
 119
 120 sub unlink_or_enoent ($) { unlink $_[0] or $!==ENOENT; }
 121
 122 sub same_file ($$) {
 123   my ($x,$y) = @_;
 124   "@$x[0..5]" eq "@$y[0..5]";
 125 }
 126
 127 sub takelock () {
 128   for (;;) {
 129     open LOCK, ">", $lockfile or die "$self: open/create $lockfile: $!\n";
 130     flock LOCK, LOCK_EX or die "$self: lock $lockfile: $!\n";
 131     my @fstat = stat LOCK or die "$self: fstat: $!\n";
 132     my @stat  = stat $lockfile;
 133     if (!@stat) {
 134       next if $! == ENOENT;
 135       die "$self: stat $lockfile: $!\n";
 136     }
 137     last if same_file(\@fstat,\@stat);
 138   }
 139 }
 140 sub unlock () {
 141   unlink $lockfile or die "$self: removing lockfile: $!\n";
 142 }
 143
 144 our $nail;
 145
 146 sub badcfg {
 147   my $m = pop @_;
 148   $" = '.';
 149   die "$self: config key \`@_': $m\n";
 150 }
 151
 152 sub cfg_uc {
 153   foreach my $cfg (@configs) {
 154     my $v = $cfg;
 155     foreach my $k (@_) {
 156       last unless defined $v;
 157       ref($v) eq 'HASH' or badcfg @_, "parent key \`$k' is not a hash";
 158       $v = $v->{$k};
 159     }
 160     return $v if defined $v;
 161   }
 162   return undef;
 163 }
 164
 165 sub cfge {
 166   my $exp = shift @_;
 167   my $v = cfg_uc @_;
 168   my $got = ref($v) || 'scalar';
 169   return $v if !defined($v) || $got eq $exp;
 170   badcfg @_, "found \L$got\E, expected \L$exp\E";
 171   # ^ toml doesn't make refs to scalars, so this is unambiguous
 172 }
 173
 174 sub cfgn {
 175   my $exp = shift @_;
 176   (cfge $exp, @_) // badcfg @_, "missing";
 177 }
 178
 179 sub cfgs  { cfge 'scalar', @_ }
 180 sub cfgsn { cfgn 'scalar', @_ }
 181
 182 sub cfg_bool {
 183   my $v = cfg_uc @_;
 184   return $v if !defined($v) || Types::Serialiser::is_bool $v;
 185   badcfg @_, "expected boolean";
 186 }
 187
 188 sub cfgn_list {
 189   my $l = cfge 'ARRAY', @_;
 190   foreach my $x (@$l) {
 191     !ref $x or badcfg @_, "list contains non-scalar element";
 192   }
 193   @$l
 194 }
 195
 196 sub readnail () {
 197   my $nailfile = "../Cargo.nail";
 198   open N, '<', $nailfile or die "$self: open $nailfile: $!\n";
 199   local ($/) = undef;
 200   my $toml = <N> // die "$self: read $nailfile: $!";
 201   my $transformed;
 202   if ($toml !~ m{^\s*\[/}m &&
 203       $toml !~ m{^[^\n\#]*\=}m &&
 204       # old non-toml syntax
 205       $toml =~ s{^[ \t]*([-_0-9a-z]+)[ \t]+(\S+)[ \t]*$}{$1 = \"$2\"}mig) {
 206     $toml =~ s{^}{[packages\]\n};
 207     my @sd;
 208     $toml =~ s{^[ \t]*\-[ \t]*\=[ \t]*(\"[-_0-9a-z]+\"\n?)$}{
 209       push @sd, $1; '';
 210     }mige;
 211     $toml = "subdirs = [\n".(join '', map { "$_\n" } @sd)."]\n".$toml;
 212     $transformed = 1;
 213   }
 214   my $e;
 215   ($nail,$e) = from_toml($toml);
 216   if (!defined $nail) {
 217     if ($transformed) {
 218       $toml =~ s/^/    /mg;
 219       print STDERR "$self: $nailfile transformed into TOML:\n$toml\n";
 220     }
 221     $/="\n"; chomp $e;
 222     die "$self: parse $nailfile: $e\n";
 223   }
 224   die "$e ?" if length $e;
 225
 226   $nail->{subdirs} //= [ ];
 227
 228   if (!ref $nail->{subdirs}) {
 229     $nail->{subdirs} = [
 230       grep /^[^\#]/,
 231       map { s/^\s+//; s/\s+$//; $_; }
 232       split m{\n},
 233       $nail->{subdirs}
 234     ];
 235   }
 236
 237   unshift @configs, $nail;
 238 }
 239
 240 our @alt_cargo_lock_stat;
 241
 242 sub consider_alt_cargo_lock () {
 243   my @ck = qw(alt_cargo_lock);
 244   # User should *either* have Cargo.lock in .gitignore,
 245   # or expect to commit Cargo.lock.example ($alt_cargo_lock)
 246
 247   $alt_cargo_lock = (cfg_uc @ck);
 248
 249   my $force = 0;
 250   if (defined($alt_cargo_lock) && ref($alt_cargo_lock) eq 'HASH') {
 251     $force = cfg_bool qw(alt_cargo_lock force);
 252     my @ck = qw(alt_cargo_lock file);
 253     $alt_cargo_lock = cfg_uc @ck;
 254   }
 255   $alt_cargo_lock //= Types::Serialiser::true;
 256
 257   if (Types::Serialiser::is_bool $alt_cargo_lock) {
 258     if (!$alt_cargo_lock) { $alt_cargo_lock = undef; return; }
 259     $alt_cargo_lock = 'Cargo.lock.example';
 260   }
 261
 262   if (ref($alt_cargo_lock) || $alt_cargo_lock =~ m{/}) {
 263     badcfg @ck, "expected boolean, or leafname";
 264   }
 265
 266   if (!stat_exists $alt_cargo_lock, "alt_cargo_lock") {
 267     $alt_cargo_lock = undef unless $force;
 268     return;
 269   }
 270
 271   @alt_cargo_lock_stat = stat _;
 272 }
 273
 274 our $oot_dir;      # oot.dir or "Build"
 275
 276 sub consider_oot () {
 277   $oot_dir = cfgs qw(oot dir);
 278   my $use = cfgs qw(oot use);
 279   unless (defined($oot_dir) || defined($use) ||
 280           defined(cfg_uc qw(oot user))) {
 281     return;
 282   }
 283   if (($use//'') eq 'disable') {
 284     $oot_dir = undef;
 285     return;
 286   }
 287   $oot_dir //= 'Build';
 288 }
 289
 290 our %manifests;
 291 our %packagemap;
 292
 293 sub read_manifest ($$$) {
 294   my ($subdir, $org_subdir, $why) = @_;
 295   my $manifest = "../$subdir/Cargo.toml";
 296   print STDERR "$self: reading $manifest...\n" if $verbose>=4;
 297   if (defined $manifests{$manifest}) {
 298     print STDERR
 299  "$self: warning: $subdir: specified more than once!".
 300  " (ignoring $why)\n";
 301     return undef;
 302   }
 303   foreach my $try ("$manifest.unnailed", "$manifest") {
 304     my $toml = toml_or_enoent($try, "manifest, in $why") // next;
 305     my $p = $toml->{package}{name};
 306     if (!defined $p) {
 307       print STDERR
 308  "$self: warning: $subdir, $why: missing package.name in $try, ignoring\n";
 309       next;
 310     }
 311     $manifests{$manifest} = $toml;
 312     return $p;
 313   }
 314   return undef;
 315 }
 316
 317 sub readorigs () {
 318   foreach my $p (keys %{ $nail->{packages} }) {
 319     my $v = $nail->{packages}{$p};
 320     my $subdir = ref($v) ? $v->{subdir} : $v;
 321     my $gotpackage = read_manifest($subdir, $subdir, "from [packages]") // '<nothing!>';
 322     if ($gotpackage ne $p) {
 323       print STDERR
 324  "$self: warning: honouring Cargo.nail packages.$subdir=$p even though $subdir contains package $gotpackage!\n";
 325     }
 326     die if defined $packagemap{$p};
 327     $packagemap{$p} = $subdir;
 328   }
 329   foreach my $subdir (@{ $nail->{subdirs} }) {
 330     my $gotpackage = read_manifest($subdir, $subdir, "from [subdirs]");
 331     if (!defined $gotpackage) {
 332       print STDERR
 333  "$self: warning: ignoring subdir $subdir which has no (suitable) Cargo.toml\n";
 334       next;
 335     }
 336     $packagemap{$gotpackage} //= $subdir;
 337   }
 338 }
 339
 340 sub calculate () {
 341   foreach my $p (sort keys %packagemap) {
 342     print STDERR "$self: package $p in $packagemap{$p}\n" if $verbose>=2;
 343   }
 344   foreach my $mf (keys %manifests) {
 345     my $toml = $manifests{$mf};
 346     foreach my $k (qw(dependencies build-dependencies dev-dependencies)) {
 347       my $deps = $toml->{$k};
 348       next unless $deps;
 349       foreach my $p (keys %packagemap) {
 350         my $info = $deps->{$p};
 351         next unless defined $info;
 352         $deps->{$p} = $info = { } unless ref $info;
 353         delete $info->{version};
 354         $info->{path} = $worksphere.'/'.$packagemap{$p};
 355       }
 356     }
 357     my $nailing = "$mf.nailing~";
 358     unlink_or_enoent $nailing or die "$self: remove old $nailing: $!\n";
 359     open N, '>', $nailing or die "$self: create new $nailing: $!\n";
 360     print N to_toml($toml) or die "$self: write new $nailing: $!\n";
 361     close N or die "$self: close new $nailing: $!\n";
 362   }
 363 }
 364
 365 sub addargs () {
 366   if (!defined $online) {
 367     $_ = cfg_uc qw(misc online);
 368     if (!defined $_) {
 369     } elsif (Types::Serialiser::is_bool $_) {
 370       $online = $_;
 371     } elsif (ref $_) {
 372     } elsif (m/^a/) {
 373       $online = undef;
 374     } elsif (m/^[1ty]/) { # allow booleanish strings
 375       $online = 1;        # for less user frustration
 376     } elsif (m/^[0fn]/) {
 377       $online = 0;
 378     } else {
 379       badcfg qw(misc online), "expected boolean or 'auto', found '$_'";
 380     }
 381   }
 382   $online //= 1 if subcmd_p('online');
 383   $online //= 0;
 384
 385   $cargo_lock_update //= subcmd_p('lock-update');
 386
 387   our @add;
 388
 389   if (!$cargo_lock_update) {
 390     push @add, qw(--locked) unless subcmd_p('!locked');
 391     if (defined($oot_dir) && !subcmd_p('!manifest-path')) {
 392       my $cargotoml = "${src_absdir}/Cargo.toml";
 393       push @args_preface, "--manifest-path=$cargotoml" if $pass_options;
 394       push @add, qw(--target-dir=target) unless subcmd_p('!target-dir');
 395     }
 396   }
 397
 398   if (defined($target) && !subcmd_p('!target')) {
 399     if ($target =~ m{^[A-Z]}) {
 400       $target = (cfgs 'arch', $target) // $archmap{$target}
 401         // die "$self: --target=$target alias specified; not in cfg or map\n";
 402     }
 403     push @add, "--target=$target";
 404   }
 405
 406   push @add, "--offline" unless $online || subcmd_p('!offline');
 407
 408   push @args_preface, @add if $pass_options;
 409   die if grep { m/ / } @add;
 410   $ENV{NAILINGCARGO_CARGO_OPTIONS} = "@add";
 411
 412   unshift @ARGV, @args_preface;
 413 }
 414
 415 our $oot_absdir;
 416 our $build_absdir; # .../Build/<subdir>
 417
 418 sub oot_massage_cmdline () {
 419   return unless defined $oot_dir;
 420
 421   my $use = cfgs qw(oot use);
 422   $use // die "$self: out-of-tree build, but \`oot.use' not configured\n";
 423   $oot_absdir = ($oot_dir !~ m{^/} ? "$worksphere/" : ""). $oot_dir;
 424   $build_absdir = "$oot_absdir/$subdir";
 425
 426   my ($pre,$post);
 427   my @xargs;
 428   if (!$cargo_lock_update) {
 429     push @xargs, $build_absdir;
 430     ($pre, $post) = ('cd "$1"; shift; ', '');
 431   } else {
 432     push @xargs, $oot_absdir, $subdir, $src_absdir;
 433     $pre =  <<'END';
 434         cd "$1"; shift;
 435         mkdir -p -- "$1"; cd "$1"; shift;
 436         cp -- "$1"/Cargo.toml
 437 END
 438     $pre .= <<'ENDLK' if stat_exists 'Cargo.lock', 'working cargo lockfile';
 439               "$1"/Cargo.lock
 440 ENDLK
 441     $pre .= <<'ENDCP';
 442                               .;
 443 ENDCP
 444     $pre .= <<'ENDPRE';
 445         shift;
 446         mkdir -p src; >src/lib.rs; >build.rs
 447 ENDPRE
 448     $post = <<'ENDPOST';
 449         rm -r src Cargo.toml build.rs;
 450 ENDPOST
 451   }
 452   my $addpath = (cfg_uc qw(oot path_add)) //
 453     $use eq 'really' ? Types::Serialiser::true : Types::Serialiser::false;
 454   $addpath =
 455     !Types::Serialiser::is_bool $addpath ? $addpath           :
 456     $addpath                             ? '$HOME/.cargo/bin' :
 457                                            undef;
 458   if (defined $addpath) {
 459     $pre .= <<END
 460         PATH=$addpath:\${PATH-/usr/local/bin:/bin:/usr/bin};
 461         export PATH;
 462 END
 463   }
 464   $pre  =~ s/^\s+//mg; $pre  =~ s/\s+/ /g;
 465   $post =~ s/^\s+//mg; $post =~ s/\s+/ /g;
 466
 467   my $getuser = sub { cfgsn qw(oot user) };
 468   my @command;
 469   my $xe = $verbose >= 2 ? 'xe' : 'e';
 470   my $sh_ec = sub {
 471     if (!length $post) {
 472       @command = (@_, 'sh',"-${xe}c",$pre.'exec "$@"','--',@xargs);
 473     } else {
 474       @command = (@_, 'sh',"-${xe}c",$pre.'"$@"; '.$post,'--',@xargs);
 475     }
 476     push @command, @ARGV;
 477   };
 478   my $command_sh = sub {
 479     my $quoted = join ' ', map {
 480       return $_ if !m/\W/;
 481       s/\'/\'\\'\'/g;
 482       "'$_'"
 483     } @ARGV;
 484     @command = @_, "set -${xe}; $pre $quoted; $post";
 485   };
 486   print STDERR "$self: out-of-tree, building in: \`$build_absdir'\n"
 487     if $verbose;
 488   if ($use eq 'really') {
 489     my $user = $getuser->();
 490     my @pw = getpwnam $user or die "$self: oot.user \`$user' lookup failed\n";
 491     my $homedir = $pw[7];
 492     $sh_ec->('really','-u',$user,'env',"HOME=$homedir");
 493     print STDERR "$self: using really to run as user \`$user'\n" if $verbose;
 494   } elsif ($use eq 'ssh') {
 495     my $user = $getuser->();
 496     $user .= '@localhost' unless $user =~ m/\@/;
 497     $command_sh->('ssh',$user);
 498     print STDERR "$self: using ssh to run as \`$user'\n" if $verbose;
 499   } elsif ($use eq 'command_args') {
 500     my @c = cfgn_list qw(oot command);
 501     $sh_ec->(@c);
 502     print STDERR "$self: out-of-tree, adverbial command: @c\n" if $verbose;
 503   } elsif ($use eq 'command_sh') {
 504     my @c = cfgn_list qw(oot command);
 505     $command_sh->(@c);
 506     print STDERR "$self: out-of-tree, ssh'ish command: @c\n" if $verbose;
 507   } elsif ($use eq 'null') {
 508     $sh_ec->();
 509   } else {
 510     die "$self: oot.use mode $use not recognised\n";
 511   }
 512   die unless @command;
 513   @ARGV = @command;
 514 }
 515
 516 sub setenvs () {
 517   $ENV{CARGO_MANIFEST_DIR} = $src_absdir;
 518   $ENV{NAILINGCARGO_MANIFEST_DIR} = $src_absdir;
 519   $ENV{NAILINGCARGO_WORKSPHERE}   = $worksphere;
 520   $ENV{NAILINGCARGO_BUILDSPHERE}  = $oot_absdir;
 521   delete $ENV{NAILINGCARGO_BUILDSPHERE} unless $oot_absdir;
 522   $ENV{NAILINGCARGO_BUILD_DIR}    = $build_absdir // $src_absdir;
 523 }
 524
 525 our $want_uninstall;
 526
 527 END {
 528   if ($want_uninstall) {
 529     local ($?);
 530     foreach my $mf (keys %manifests) {
 531       eval { uninstall1($mf,1); 1; } or warn "$@";
 532     }
 533     eval { unaltcargolock(1); 1; } or warn "$@";
 534   }
 535 }
 536
 537 sub consider_directories () {
 538   return unless defined $oot_dir;
 539   my $bsubdir = "../$oot_dir/$subdir";
 540   return if stat $bsubdir;
 541   die "$0: build directory $bsubdir inaccessible\n"
 542     unless $!==ENOENT;
 543   return if $cargo_lock_update; # will make it
 544   die "$0: build directory $bsubdir does not exist, and not in Cargo.lock update mode!\n";
 545 }
 546
 547 our $cleanup_cargo_lock;
 548 sub makebackups () {
 549   foreach my $mf (keys %manifests) {
 550     link "$mf", "$mf.unnailed" or $!==EEXIST
 551       or die "$self: make backup link $mf.unnailed: $!\n";
 552   }
 553
 554   if (defined($alt_cargo_lock)) {
 555     if (@alt_cargo_lock_stat) {
 556       print STDERR "$self: using alt_cargo_lock `$alt_cargo_lock'..."
 557         if $verbose>=3;
 558       if (link $alt_cargo_lock, 'Cargo.lock') {
 559         print STDERR " linked\n" if $verbose>=3;
 560       } elsif ($! != EEXIST) {
 561         print STDERR "\n" if $verbose>=3;
 562         die "$self: make \`Cargo.lock' available as \`$alt_cargo_lock': $!\n";
 563       } else {
 564         print STDERR "checking quality." if $verbose>=3;
 565         my @lock_stat = stat 'Cargo.lock'
 566           or die "$self: stat Cargo.lock (for alt check: $!\n";
 567         same_file(\@alt_cargo_lock_stat, \@lock_stat)
 568           or die
 569 "$self: \`Cargo.lock' and alt file \`$alt_cargo_lock' both exist and are not the same file!\n";
 570       }
 571       $cleanup_cargo_lock = 1;
 572     } else {
 573       $cleanup_cargo_lock = 1;
 574       # If Cargo.lock exists and alt doesn't, that means either
 575       # that a previous run was interrupted, or that the user has
 576       # messed up.
 577     }
 578   }
 579 }
 580
 581 sub nailed ($) {
 582   my ($mf) = @_;
 583   my $nailed  = "$mf.nailed~"; $nailed =~ s{/([^/]+)$}{/.$1} or die;
 584   $nailed;
 585 }
 586
 587 sub install () {
 588   my @our_unfound_stab = stat_exists('Cargo.toml', 'local Cargo.toml')
 589     ? (stat _) : ();
 590   foreach my $mf (keys %manifests) {
 591     if (@our_unfound_stab) {
 592       if (stat_exists $mf, "manifest in to-be-nailed directory") {
 593         my @mf_stab = stat _ ;
 594         if ("@mf_stab[0..1]" eq "@our_unfound_stab[0..1]") {
 595           @our_unfound_stab = ();
 596         }
 597       }
 598     }
 599
 600     my $nailing = "$mf.nailing~";
 601     my $nailed = nailed($mf);
 602     my ($use, $rm);
 603     my $diff;
 604     if (open NN, '<', $nailed) {
 605       $diff = compare($nailing, \*NN);
 606       die "$self: compare $nailing and $nailed: $!" if $diff<0;
 607     } else {
 608       $!==ENOENT or die "$self: check previous $nailed: $!\n";
 609       $diff = 1;
 610     }
 611     if ($diff) {
 612       $use = $nailing;
 613       $rm  = $nailed;
 614     } else {
 615       $use = $nailed;
 616       $rm  = $nailing;
 617     }
 618     rename $use, $mf or die "$self: install nailed $use: $!\n";
 619     unlink_or_enoent $rm or die "$self: remove old $rm: $!\n";
 620     print STDERR "$self: nailed $mf\n" if $verbose>=3;
 621   }
 622
 623   if (@our_unfound_stab) {
 624     print STDERR
 625  "$self: *WARNING* cwd is not in Cargo.nail thbough it has Cargo.toml!\n";
 626   }
 627 }
 628
 629 sub invoke () {
 630   my $r = system @ARGV;
 631   if (!$r) {
 632     return 0;
 633   } elsif ($r<0) {
 634     print STDERR "$self: could not execute $ARGV[0]: $!\n";
 635     return 127;
 636   } elsif ($r & 0xff00) {
 637     print STDERR "$self: $ARGV[0] failed (exit status $r)\n";
 638     return $r >> 8;
 639   } else {
 640     print STDERR "$self: $ARGV[0] died due to signal! (wait status $r)\n";
 641     return 125;
 642   }
 643 }
 644
 645 sub cargo_lock_update_after () {
 646   if ($cargo_lock_update) {
 647     # avoids importing File::Copy and the error handling is about as good
 648     $!=0; $?=0;
 649     my $r= system qw(cp --), "$build_absdir/Cargo.lock", "Cargo.lock";
 650     die "$self: run cp: $! $?" if $r<0 || $r & 0xff;
 651     die "$self: failed to update local Cargo.lock (wait status $r)\n" if $r;
 652   }
 653 }
 654
 655 sub uninstall1 ($$) {
 656   my ($mf, $enoentok) = @_;
 657   my $unnailed = "$mf.unnailed";
 658   rename $unnailed, $mf or ($enoentok && $!==ENOENT)
 659     or die "$self: failed to restore: rename $unnailed back to $mf: $!\n";
 660 }
 661
 662 sub unaltcargolock ($) {
 663   my ($enoentok) = @_;
 664   return unless $cleanup_cargo_lock;
 665   die 'internal error!' unless defined $alt_cargo_lock;
 666
 667   # we ignore $enoentok because we don't know if one was supposed to
 668   # have been created.
 669
 670   rename('Cargo.lock', $alt_cargo_lock) or $!==ENOENT or die
 671  "$self: cleanup: rename possibly-updated \`Cargo.lock' to \`$alt_cargo_lock': $!\n";
 672
 673   unlink 'Cargo.lock' or $!==ENOENT or die
 674  "$self: cleanup: remove \`Cargo.lock' in favour of \`$alt_cargo_lock': $!\n";
 675   # ^ this also helps clean up the stupid rename() corner case
 676 }
 677
 678 sub uninstall () {
 679   foreach my $mf (keys %manifests) {
 680     my $nailed = nailed($mf);
 681     link $mf, $nailed or die "$self: preserve (link) $mf as $nailed: $!\n";
 682     uninstall1($mf,0);
 683   }
 684   unaltcargolock(0);
 685 }
 686
 687 sub parse_args () {
 688   my $is_cargo;
 689
 690   # Loop exit condition:
 691   #   $is_cargo is set
 692   #   @ARGV contains
 693   #    $is_cargo==1   <cargo-command> <cargo-opts> [--] <subcmd>...
 694   #    $is_cargo==0   <build-command>...
 695
 696  OPTS: for (;;) {
 697     @ARGV or die "$self: need cargo subcommand\n";
 698
 699     $_ = shift @ARGV;
 700     my $orgopt = $_;
 701
 702     my $not_a_nailing_opt = sub { # usage 1
 703       unshift @ARGV, $orgopt;
 704       unshift @ARGV, 'cargo';
 705       $is_cargo = 1;
 706       no warnings qw(exiting);
 707       last OPTS;
 708     };
 709     $not_a_nailing_opt->() unless m{^-};
 710     $not_a_nailing_opt->() if $_ eq '--';
 711
 712     if ($_ eq '---') { # usage 2 or 3
 713       die "$self: --- must be followed by build command\n" unless @ARGV;
 714       if ($ARGV[0] eq '--') { # usage 3
 715         shift;
 716         $is_cargo = 0;
 717       } elsif (grep { $_ eq '--' } @ARGV) { # usage 2
 718         $is_cargo = 1;
 719       } elsif ($ARGV[0] =~ m{[^/]*cargo[^/]*$}) { # usage 2
 720         $is_cargo = 1;
 721       } else {  # usage 3
 722         $is_cargo = 0;
 723       }
 724       last;
 725     }
 726     if (m{^-[^-]}) {
 727       while (m{^-.}) {
 728         if (s{^-v}{-}) {
 729           $verbose++;
 730         } elsif (s{^-q}{-}) {
 731           $verbose=0;
 732         } elsif (s{^-n}{-}) {
 733           $noact++;
 734         } elsif (s{^-s(.+)}{-}s) {
 735           $cargo_subcmd = $1;
 736         } elsif (s{^-([uU])}{-}) {
 737           $cargo_lock_update = $1=~m/[a-z]/;
 738         } elsif (s{^-([cC])}{-}) {
 739           $pass_options = $1=~m/[a-z]/;
 740         } elsif (s{^-D}{-}) {
 741           $dump++;
 742         } elsif (s{^-T(.+)}{-}s) {
 743           $target = $1;
 744         } elsif (s{^-([oO])}{-}) {
 745           $online = $1=~m/[a-z]/;
 746         } else {
 747           die "$self: unknown short option(s) $_\n" unless $_ eq $orgopt;
 748           $not_a_nailing_opt->();
 749         }
 750       }
 751     } elsif (s{^--target=}{}) {
 752       $target = $_;
 753     } elsif (m{^--(on|off)line$}) {
 754       $online = $1 eq 'on';
 755     } elsif (s{^--subcommand-props=}{}) {
 756       my @props = split /\,/, $_;
 757       our %subcmd_prop_ok;
 758       if (!%subcmd_prop_ok) {
 759         foreach my $v (\@subcmd_xprops, values %subcmd_props) {
 760           $subcmd_prop_ok{$_}=1 foreach @$v;
 761         };
 762       }
 763       $subcmd_prop_ok{$_}
 764         or die "$self: unknown subcommand property \`$_'\n"
 765         foreach @props;
 766       $cargo_subcmd = \@props;
 767     } elsif (m{^--(no-)?cargo-lock-update}) {
 768       $cargo_lock_update= !!$1;
 769     } else {
 770       $not_a_nailing_opt->();
 771     }
 772   }
 773
 774   $is_cargo // die;
 775   @ARGV || die;
 776
 777   if ($is_cargo) {
 778     @args_preface = shift @ARGV;
 779     while (defined($_ = shift @ARGV)) {
 780       if (!m{^-}) { unshift @ARGV, $_; last; }
 781       if ($_ eq '--') { last; }
 782       push @args_preface, $_;
 783     }
 784     @ARGV || die "$self: need cargo subcommand\n";
 785     $cargo_subcmd //= $ARGV[0];
 786     $pass_options //= 1;
 787   } else {
 788     $cargo_subcmd //= '';
 789     $pass_options //= 0;
 790   }
 791   push @args_preface, shift @ARGV;
 792
 793   if (!ref($cargo_subcmd)) {
 794     print STDERR " cargo_subcmd lookup $cargo_subcmd\n" if $dump;
 795     $cargo_subcmd = $subcmd_props{$cargo_subcmd} // [ ];
 796   }
 797
 798   print STDERR " cargo_subcmd props @$cargo_subcmd\n" if $dump;
 799   my %cargo_subcmd;
 800   $cargo_subcmd{$_} = 1 foreach @$cargo_subcmd;
 801   $cargo_subcmd = \%cargo_subcmd;
 802 }
 803
 804 parse_args();
 805 loadconfigs();
 806 takelock();
 807 readnail();
 808 consider_alt_cargo_lock();
 809 consider_oot();
 810 readorigs();
 811 calculate();
 812 addargs();
 813 consider_directories();
 814 our @display_cmd = @ARGV;
 815 oot_massage_cmdline();
 816 setenvs();
 817
 818 if ($dump) {
 819   eval '
 820     use Data::Dumper;
 821     print STDERR Dumper(\%manifests) if $dump>=2;
 822     print STDERR Dumper(\%packagemap, \@ARGV,
 823                         { src_absdir => $src_absdir,
 824                           worksphere => $worksphere,
 825                           subdir => $subdir,
 826                           oot_dir => $oot_dir,
 827                           oot_absdir => $oot_absdir,
 828                           build_absdir => $build_absdir });
 829   ' or die $@;
 830 }
 831
 832 exit 0 if $noact;
 833
 834 $want_uninstall = 1;
 835 makebackups();
 836 install();
 837
 838 printf STDERR "$self: nailed (%s manifests, %s packages)%s\n",
 839   (scalar keys %manifests), (scalar keys %packagemap),
 840   (defined($alt_cargo_lock) and ", using `$alt_cargo_lock'")
 841   if $verbose;
 842
 843 print STDERR "$self: invoking: @display_cmd\n" if $verbose;
 844 my $estatus = invoke();
 845
 846 cargo_lock_update_after();
 847
 848 uninstall();
 849 $want_uninstall = 0;
 850
 851 print STDERR "$self: unnailed.  status $estatus.\n" if $verbose;
 852
 853 exit $estatus;