nailing-cargo

   1 #!/usr/bin/perl -w
   2 # nailing-cargo: wrapper to use unpublished local crates
   3 # SPDX-License-Identifier: AGPL-3.0-or-later
   4
   5 our $self;
   6
   7 use strict;
   8 use POSIX;
   9 use Types::Serialiser;
  10
  11 our %archmap = (
  12     RPI => 'arm-unknown-linux-gnueabihf',
  13 );
  14
  15 BEGIN {
  16   $self = $0;  $self =~ s{^.*/(?=.)}{};
  17   my $deref = $0;
  18   while ($deref =~ m{^/}) {
  19     my $link = readlink $deref;
  20     if (!defined $link) {
  21       $! == EINVAL
  22         or die "$self: checking our script location $deref: $!\n";
  23       $deref =~ s{/[^/]+$}{}
  24         or die "$self: unexpected script path: $deref\n";
  25       unshift @INC, $deref."/TOML-Tiny/lib";
  26       last;
  27     }
  28     last if $link !~ m{^/};
  29     $deref = $link;
  30   }
  31 }
  32
  33 use Fcntl qw(LOCK_EX);
  34 use File::Compare;
  35 use TOML::Tiny::Faithful;
  36
  37 our $src_absdir = getcwd() // die "$self: getcwd failed: $!\n";
  38
  39 our $worksphere = $src_absdir;
  40 $worksphere =~ s{/([^/]+)$}{}
  41   or die "$self: cwd \`$worksphere' unsupported!\n";
  42 our $subdir = $1; # leafname
  43
  44 our $lockfile = "../.nailing-cargo.lock";
  45
  46 our @args_preface;
  47 our $cargo_subcmd;
  48 our $command_is_cargo;
  49 our $alt_cargo_lock;
  50 our $cargo_lock_update;
  51 our $pass_options;
  52 our $online;
  53
  54 #
  55 our %subcmd_props = (
  56 # build (default)  =>[qw(                                        )],
  57 'generate-lockfile'=>[qw( lock-update !target        !target-dir )],
  58  update            =>[qw( lock-update !target online             )],
  59  fetch             =>[qw(                     online !target-dir )],
  60                     );
  61
  62 our @subcmd_xprops = qw(!manifest-path !offline !locked);
  63
  64 our @configs;
  65 our $verbose=1;
  66 our ($noact,$dump);
  67 our $target;
  68
  69 sub read_or_enoent ($) {
  70   my ($fn) = @_;
  71   if (!open R, '<', $fn) {
  72     return undef if $!==ENOENT;
  73     die "$self: open $fn: $!\n";
  74   }
  75   local ($/) = undef;
  76   my ($r) = <R> // die "$self: read $fn: $!\n";
  77   $r;
  78 }
  79
  80 sub stat_exists ($$) {
  81   my ($fn, $what) = @_;
  82   if (stat $fn) { return 1; }
  83   $!==ENOENT or die "$self: stat $what: $fn: $!\n";
  84   return 0;
  85 }
  86
  87 sub subcmd_p ($) {
  88   print STDERR " subcmd_p ".(join ' ', keys %$cargo_subcmd)."   | @_\n"
  89     if $dump;
  90   $cargo_subcmd->{$_[0]}
  91 }
  92
  93 sub toml_or_enoent ($$) {
  94   my ($f,$what) = @_;
  95   my $toml = read_or_enoent($f) // return;
  96   print STDERR "Read TOML from $f\n" if $dump;
  97   my ($v,$e) = from_toml($toml);
  98   if (!defined $v) {
  99     chomp $e;
 100     die "$self: parse TOML: $what: $f: $e\n";
 101   }
 102   die "$e ?" if length $e;
 103   $v;
 104 }
 105
 106 sub load1config ($) {
 107   my ($f) = @_;
 108   my $toml = toml_or_enoent($f, "config file");
 109   push @configs, $toml if defined $toml;
 110 }
 111
 112 sub loadconfigs () {
 113   my $dotfile = ".nailing-cargo.toml";
 114   load1config("../Nailing-Cargo.toml");
 115   load1config($dotfile);
 116   load1config("$ENV{HOME}/$dotfile") if defined $ENV{HOME};
 117   load1config("/etc/nailing-cargo/cfg.toml");
 118 }
 119
 120 sub unlink_or_enoent ($) { unlink $_[0] or $!==ENOENT; }
 121
 122 sub same_file ($$) {
 123   my ($x,$y) = @_;
 124   "@$x[0..5]" eq "@$y[0..5]";
 125 }
 126
 127 sub takelock () {
 128   for (;;) {
 129     open LOCK, ">", $lockfile or die "$self: open/create $lockfile: $!\n";
 130     flock LOCK, LOCK_EX or die "$self: lock $lockfile: $!\n";
 131     my @fstat = stat LOCK or die "$self: fstat: $!\n";
 132     my @stat  = stat $lockfile;
 133     if (!@stat) {
 134       next if $! == ENOENT;
 135       die "$self: stat $lockfile: $!\n";
 136     }
 137     last if same_file(\@fstat,\@stat);
 138   }
 139 }
 140 sub unlock () {
 141   unlink $lockfile or die "$self: removing lockfile: $!\n";
 142 }
 143
 144 our $nail;
 145
 146 sub badcfg {
 147   my $m = pop @_;
 148   $" = '.';
 149   die "$self: config key \`@_': $m\n";
 150 }
 151
 152 sub cfg_uc {
 153   foreach my $cfg (@configs) {
 154     my $v = $cfg;
 155     foreach my $k (@_) {
 156       last unless defined $v;
 157       ref($v) eq 'HASH' or badcfg @_, "parent key \`$k' is not a hash";
 158       $v = $v->{$k};
 159     }
 160     return $v if defined $v;
 161   }
 162   return undef;
 163 }
 164
 165 sub cfge {
 166   my $exp = shift @_;
 167   my $v = cfg_uc @_;
 168   my $got = ref($v) || 'scalar';
 169   return $v if !defined($v) || $got eq $exp;
 170   badcfg @_, "found \L$got\E, expected \L$exp\E";
 171   # ^ toml doesn't make refs to scalars, so this is unambiguous
 172 }
 173
 174 sub cfgn {
 175   my $exp = shift @_;
 176   (cfge $exp, @_) // badcfg @_, "missing";
 177 }
 178
 179 sub cfgs  { cfge 'scalar', @_ }
 180 sub cfgsn { cfgn 'scalar', @_ }
 181
 182 sub cfg_bool {
 183   my $v = cfg_uc @_;
 184   return $v if !defined($v) || Types::Serialiser::is_bool $v;
 185   badcfg @_, "expected boolean";
 186 }
 187
 188 sub cfgn_list {
 189   my $l = cfge 'ARRAY', @_;
 190   foreach my $x (@$l) {
 191     !ref $x or badcfg @_, "list contains non-scalar element";
 192   }
 193   @$l
 194 }
 195
 196 sub readnail () {
 197   my $nailfile = "../Cargo.nail";
 198   open N, '<', $nailfile or die "$self: open $nailfile: $!\n";
 199   local ($/) = undef;
 200   my $toml = <N> // die "$self: read $nailfile: $!";
 201   my $transformed;
 202   if ($toml !~ m{^\s*\[/}m &&
 203       $toml !~ m{^[^\n\#]*\=}m &&
 204       # old non-toml syntax
 205       $toml =~ s{^[ \t]*([-_0-9a-z]+)[ \t]+(\S+)[ \t]*$}{$1 = \"$2\"}mig) {
 206     $toml =~ s{^}{[packages\]\n};
 207     my @sd;
 208     $toml =~ s{^[ \t]*\-[ \t]*\=[ \t]*(\"[-_0-9a-z]+\"\n?)$}{
 209       push @sd, $1; '';
 210     }mige;
 211     $toml = "subdirs = [\n".(join '', map { "$_\n" } @sd)."]\n".$toml;
 212     $transformed = 1;
 213   }
 214   my $e;
 215   ($nail,$e) = from_toml($toml);
 216   if (!defined $nail) {
 217     if ($transformed) {
 218       $toml =~ s/^/    /mg;
 219       print STDERR "$self: $nailfile transformed into TOML:\n$toml\n";
 220     }
 221     $/="\n"; chomp $e;
 222     die "$self: parse $nailfile: $e\n";
 223   }
 224   die "$e ?" if length $e;
 225
 226   $nail->{subdirs} //= [ ];
 227
 228   if (!ref $nail->{subdirs}) {
 229     $nail->{subdirs} = [
 230       grep /^[^\#]/,
 231       map { s/^\s+//; s/\s+$//; $_; }
 232       split m{\n},
 233       $nail->{subdirs}
 234     ];
 235   }
 236
 237   unshift @configs, $nail;
 238 }
 239
 240 our @alt_cargo_lock_stat;
 241
 242 sub consider_alt_cargo_lock () {
 243   my @ck = qw(alt_cargo_lock);
 244   # User should *either* have Cargo.lock in .gitignore,
 245   # or expect to commit Cargo.lock.example ($alt_cargo_lock)
 246
 247   $alt_cargo_lock = (cfg_uc @ck);
 248
 249   my $force = 0;
 250   if (defined($alt_cargo_lock) && ref($alt_cargo_lock) eq 'HASH') {
 251     $force = cfg_bool qw(alt_cargo_lock force);
 252     my @ck = qw(alt_cargo_lock file);
 253     $alt_cargo_lock = cfg_uc @ck;
 254   }
 255   $alt_cargo_lock //= Types::Serialiser::true;
 256
 257   if (Types::Serialiser::is_bool $alt_cargo_lock) {
 258     if (!$alt_cargo_lock) { $alt_cargo_lock = undef; return; }
 259     $alt_cargo_lock = 'Cargo.lock.example';
 260   }
 261
 262   if (ref($alt_cargo_lock) || $alt_cargo_lock =~ m{/}) {
 263     badcfg @ck, "expected boolean, or leafname";
 264   }
 265
 266   if (!stat_exists $alt_cargo_lock, "alt_cargo_lock") {
 267     $alt_cargo_lock = undef unless $force;
 268     return;
 269   }
 270
 271   @alt_cargo_lock_stat = stat _;
 272 }
 273
 274 our $oot_dir;      # oot.dir or "Build"
 275
 276 sub consider_oot () {
 277   $oot_dir = cfgs qw(oot dir);
 278   my $use = cfgs qw(oot use);
 279   unless (defined($oot_dir) || defined($use) ||
 280           defined(cfg_uc qw(oot user))) {
 281     die "$self: specified --cargo-lock-update but not out-of-tree build!\n"
 282       if $cargo_lock_update;
 283     $cargo_lock_update=0;
 284     return;
 285   }
 286   if ($use eq 'disable') {
 287     $oot_dir = undef;
 288     return;
 289   }
 290   $oot_dir //= 'Build';
 291 }
 292
 293 our %manifests;
 294 our %packagemap;
 295
 296 sub read_manifest ($) {
 297   my ($subdir) = @_;
 298   my $manifest = "../$subdir/Cargo.toml";
 299   print STDERR "$self: reading $manifest...\n" if $verbose>=4;
 300   if (defined $manifests{$manifest}) {
 301     print STDERR
 302  "$self: warning: $subdir: specified more than once!\n";
 303     return undef;
 304   }
 305   foreach my $try ("$manifest.unnailed", "$manifest") {
 306     my $toml = toml_or_enoent($try, "package manifest") // next;
 307     my $p = $toml->{package}{name};
 308     if (!defined $p) {
 309       print STDERR
 310  "$self: warning: $subdir: missing package.name in $try, ignoring\n";
 311       next;
 312     }
 313     $manifests{$manifest} = $toml;
 314     return $p;
 315   }
 316   return undef;
 317 }
 318
 319 sub readorigs () {
 320   foreach my $p (keys %{ $nail->{packages} }) {
 321     my $v = $nail->{packages}{$p};
 322     my $subdir = ref($v) ? $v->{subdir} : $v;
 323     my $gotpackage = read_manifest($subdir) // '<nothing!>';
 324     if ($gotpackage ne $p) {
 325       print STDERR
 326  "$self: warning: honouring Cargo.nail packages.$subdir=$p even though $subdir contains package $gotpackage!\n";
 327     }
 328     die if defined $packagemap{$p};
 329     $packagemap{$p} = $subdir;
 330   }
 331   foreach my $subdir (@{ $nail->{subdirs} }) {
 332     my $gotpackage = read_manifest($subdir);
 333     if (!defined $gotpackage) {
 334       print STDERR
 335  "$self: warning: ignoring subdir $subdir which has no Cargo.toml\n";
 336       next;
 337     }
 338     $packagemap{$gotpackage} //= $subdir;
 339   }
 340 }
 341
 342 sub calculate () {
 343   foreach my $p (sort keys %packagemap) {
 344     print STDERR "$self: package $p in $packagemap{$p}\n" if $verbose>=2;
 345   }
 346   foreach my $mf (keys %manifests) {
 347     my $toml = $manifests{$mf};
 348     foreach my $k (qw(dependencies build-dependencies dev-dependencies)) {
 349       my $deps = $toml->{$k};
 350       next unless $deps;
 351       foreach my $p (keys %packagemap) {
 352         my $info = $deps->{$p};
 353         next unless defined $info;
 354         $deps->{$p} = $info = { } unless ref $info;
 355         delete $info->{version};
 356         $info->{path} = $worksphere.'/'.$packagemap{$p};
 357       }
 358     }
 359     my $nailing = "$mf.nailing~";
 360     unlink_or_enoent $nailing or die "$self: remove old $nailing: $!\n";
 361     open N, '>', $nailing or die "$self: create new $nailing: $!\n";
 362     print N to_toml($toml) or die "$self: write new $nailing: $!\n";
 363     close N or die "$self: close new $nailing: $!\n";
 364   }
 365 }
 366
 367 sub addargs () {
 368   $online = 1 if subcmd_p('online');
 369   $online //= cfg_bool qw(misc online);
 370   $online //= 0;
 371
 372   $cargo_lock_update //= subcmd_p('lock-update');
 373
 374   our @add;
 375
 376   if (!$cargo_lock_update) {
 377     push @add, qw(--locked) unless subcmd_p('!locked');
 378     if (defined($oot_dir) && !subcmd_p('!manifest-path')) {
 379       my $cargotoml = "${src_absdir}/Cargo.toml";
 380       push @args_preface, "--manifest-path=$cargotoml" if $pass_options;
 381       push @add, qw(--target-dir=target) unless subcmd_p('!target-dir');
 382     }
 383   }
 384
 385   if (defined($target) && !subcmd_p('!target')) {
 386     if ($target =~ m{^[A-Z]}) {
 387       $target = (cfgs 'arch', $target) // $archmap{$target}
 388         // die "$self: --target=$target alias specified; not in cfg or map\n";
 389     }
 390     push @add, "--target=$target";
 391   }
 392
 393   push @add, "--offline" unless $online || subcmd_p('!offline');
 394
 395   push @args_preface, @add if $pass_options;
 396   die if grep { m/ / } @add;
 397   $ENV{NAILINGCARGO_CARGO_OPTIONS} = "@add";
 398
 399   unshift @ARGV, @args_preface;
 400 }
 401
 402 our $oot_absdir;
 403 our $build_absdir; # .../Build/<subdir>
 404
 405 sub oot_massage_cmdline () {
 406   return unless defined $oot_dir;
 407
 408   my $use = cfgs qw(oot use);
 409   $oot_absdir = ($oot_dir !~ m{^/} ? "$worksphere/" : ""). $oot_dir;
 410   $build_absdir = "$oot_absdir/$subdir";
 411
 412   my ($pre,$post);
 413   my @xargs;
 414   if (!$cargo_lock_update) {
 415     push @xargs, $build_absdir;
 416     ($pre, $post) = ('cd "$1"; shift; ', '');
 417   } else {
 418     push @xargs, $oot_absdir, $subdir, $src_absdir;
 419     $pre =  <<'END';
 420         cd "$1"; shift;
 421         mkdir -p -- "$1"; cd "$1"; shift;
 422         cp -- "$1"/Cargo.toml
 423 END
 424     $pre .= <<'ENDLK' if stat_exists 'Cargo.lock', 'working cargo lockfile';
 425               "$1"/Cargo.lock
 426 ENDLK
 427     $pre .= <<'ENDCP';
 428                               .;
 429 ENDCP
 430     $pre .= <<'ENDPRE';
 431         shift;
 432         mkdir -p src; >src/lib.rs; >build.rs
 433 ENDPRE
 434     $post = <<'ENDPOST';
 435         rm -r src Cargo.toml build.rs;
 436 ENDPOST
 437   }
 438   my $addpath = (cfg_uc qw(oot path_add)) //
 439     $use eq 'really' ? Types::Serialiser::true : Types::Serialiser::false;
 440   $addpath =
 441     !Types::Serialiser::is_bool $addpath ? $addpath           :
 442     $addpath                             ? '$HOME/.cargo/bin' :
 443                                            undef;
 444   if (defined $addpath) {
 445     $pre .= <<END
 446         PATH=$addpath:\${PATH-/usr/local/bin:/bin:/usr/bin};
 447         export PATH;
 448 END
 449   }
 450   $pre  =~ s/^\s+//mg; $pre  =~ s/\s+/ /g;
 451   $post =~ s/^\s+//mg; $post =~ s/\s+/ /g;
 452
 453   my $getuser = sub { cfgsn qw(oot user) };
 454   my @command;
 455   my $xe = $verbose >= 2 ? 'xe' : 'e';
 456   my $sh_ec = sub {
 457     if (!length $post) {
 458       @command = (@_, 'sh',"-${xe}c",$pre.'exec "$@"','--',@xargs);
 459     } else {
 460       @command = (@_, 'sh',"-${xe}c",$pre.'"$@"; '.$post,'--',@xargs);
 461     }
 462     push @command, @ARGV;
 463   };
 464   my $command_sh = sub {
 465     my $quoted = join ' ', map {
 466       return $_ if !m/\W/;
 467       s/\'/\'\\'\'/g;
 468       "'$_'"
 469     } @ARGV;
 470     @command = @_, "set -${xe}; $pre $quoted; $post";
 471   };
 472   print STDERR "$self: out-of-tree, building in: \`$build_absdir'\n"
 473     if $verbose;
 474   if ($use eq 'really') {
 475     my $user = $getuser->();
 476     my @pw = getpwnam $user or die "$self: oot.user \`$user' lookup failed\n";
 477     my $homedir = $pw[7];
 478     $sh_ec->('really','-u',$user,'env',"HOME=$homedir");
 479     print STDERR "$self: using really to run as user \`$user'\n" if $verbose;
 480   } elsif ($use eq 'ssh') {
 481     my $user = $getuser->();
 482     $user .= '@localhost' unless $user =~ m/\@/;
 483     $command_sh->('ssh',$user);
 484     print STDERR "$self: using ssh to run as \`$user'\n" if $verbose;
 485   } elsif ($use eq 'command_args') {
 486     my @c = cfgn_list qw(oot command);
 487     $sh_ec->(@c);
 488     print STDERR "$self: out-of-tree, adverbial command: @c\n" if $verbose;
 489   } elsif ($use eq 'command_sh') {
 490     my @c = cfgn_list qw(oot command);
 491     $command_sh->(@c);
 492     print STDERR "$self: out-of-tree, ssh'ish command: @c\n" if $verbose;
 493   } elsif ($use eq 'null') {
 494     $sh_ec->();
 495   } else {
 496     die "$self: oot.use mode $use not recognised\n";
 497   }
 498   die unless @command;
 499   @ARGV = @command;
 500 }
 501
 502 sub setenvs () {
 503   $ENV{CARGO_MANIFEST_DIR} = $src_absdir;
 504   $ENV{NAILINGCARGO_MANIFEST_DIR} = $src_absdir;
 505   $ENV{NAILINGCARGO_WORKSPHERE}   = $worksphere;
 506   $ENV{NAILINGCARGO_BUILDSPHERE}  = $oot_absdir;
 507   delete $ENV{NAILINGCARGO_BUILDSPHERE} unless $oot_absdir;
 508   $ENV{NAILINGCARGO_BUILD_DIR}    = $build_absdir // $src_absdir;
 509 }
 510
 511 our $want_uninstall;
 512
 513 END {
 514   if ($want_uninstall) {
 515     local ($?);
 516     foreach my $mf (keys %manifests) {
 517       eval { uninstall1($mf,1); 1; } or warn "$@";
 518     }
 519     eval { unaltcargolock(1); 1; } or warn "$@";
 520   }
 521 }
 522
 523 our $cleanup_cargo_lock;
 524 sub makebackups () {
 525   foreach my $mf (keys %manifests) {
 526     link "$mf", "$mf.unnailed" or $!==EEXIST
 527       or die "$self: make backup link $mf.unnailed: $!\n";
 528   }
 529
 530   if (defined($alt_cargo_lock)) {
 531     if (@alt_cargo_lock_stat) {
 532       print STDERR "$self: using alt_cargo_lock `$alt_cargo_lock'..."
 533         if $verbose>=3;
 534       if (link $alt_cargo_lock, 'Cargo.lock') {
 535         print STDERR " linked\n" if $verbose>=3;
 536       } elsif ($! != EEXIST) {
 537         print STDERR "\n" if $verbose>=3;
 538         die "$self: make \`Cargo.lock' available as \`$alt_cargo_lock': $!\n";
 539       } else {
 540         print STDERR "checking quality." if $verbose>=3;
 541         my @lock_stat = stat 'Cargo.lock'
 542           or die "$self: stat Cargo.lock (for alt check: $!\n";
 543         same_file(\@alt_cargo_lock_stat, \@lock_stat)
 544           or die
 545 "$self: \`Cargo.lock' and alt file \`$alt_cargo_lock' both exist and are not the same file!\n";
 546       }
 547       $cleanup_cargo_lock = 1;
 548     } else {
 549       $cleanup_cargo_lock = 1;
 550       # If Cargo.lock exists and alt doesn't, that means either
 551       # that a previous run was interrupted, or that the user has
 552       # messed up.
 553     }
 554   }
 555 }
 556
 557 sub nailed ($) {
 558   my ($mf) = @_;
 559   my $nailed  = "$mf.nailed~"; $nailed =~ s{/([^/]+)$}{/.$1} or die;
 560   $nailed;
 561 }
 562
 563 sub install () {
 564   my @our_unfound_stab = stat_exists('Cargo.toml', 'local Cargo.toml')
 565     ? (stat _) : ();
 566   foreach my $mf (keys %manifests) {
 567     if (@our_unfound_stab) {
 568       if (stat_exists $mf, "manifest in to-be-nailed directory") {
 569         my @mf_stab = stat _ ;
 570         if ("@mf_stab[0..1]" eq "@our_unfound_stab[0..1]") {
 571           @our_unfound_stab = ();
 572         }
 573       }
 574     }
 575
 576     my $nailing = "$mf.nailing~";
 577     my $nailed = nailed($mf);
 578     my ($use, $rm);
 579     my $diff;
 580     if (open NN, '<', $nailed) {
 581       $diff = compare($nailing, \*NN);
 582       die "$self: compare $nailing and $nailed: $!" if $diff<0;
 583     } else {
 584       $!==ENOENT or die "$self: check previous $nailed: $!\n";
 585       $diff = 1;
 586     }
 587     if ($diff) {
 588       $use = $nailing;
 589       $rm  = $nailed;
 590     } else {
 591       $use = $nailed;
 592       $rm  = $nailing;
 593     }
 594     rename $use, $mf or die "$self: install nailed $use: $!\n";
 595     unlink_or_enoent $rm or die "$self: remove old $rm: $!\n";
 596     print STDERR "$self: nailed $mf\n" if $verbose>=3;
 597   }
 598
 599   if (@our_unfound_stab) {
 600     print STDERR
 601  "$self: *WARNING* cwd is not in Cargo.nail thbough it has Cargo.toml!\n";
 602   }
 603 }
 604
 605 sub invoke () {
 606   my $r = system @ARGV;
 607   if (!$r) {
 608     return 0;
 609   } elsif ($r<0) {
 610     print STDERR "$self: could not execute $ARGV[0]: $!\n";
 611     return 127;
 612   } elsif ($r & 0xff00) {
 613     print STDERR "$self: $ARGV[0] failed (exit status $r)\n";
 614     return $r >> 8;
 615   } else {
 616     print STDERR "$self: $ARGV[0] died due to signal! (wait status $r)\n";
 617     return 125;
 618   }
 619 }
 620
 621 sub cargo_lock_update_after () {
 622   if ($cargo_lock_update) {
 623     # avoids importing File::Copy and the error handling is about as good
 624     $!=0; $?=0;
 625     my $r= system qw(cp --), "$build_absdir/Cargo.lock", "Cargo.lock";
 626     die "$self: run cp: $! $?" if $r<0 || $r & 0xff;
 627     die "$self: failed to update local Cargo.lock (wait status $r)\n" if $r;
 628   }
 629 }
 630
 631 sub uninstall1 ($$) {
 632   my ($mf, $enoentok) = @_;
 633   my $unnailed = "$mf.unnailed";
 634   rename $unnailed, $mf or ($enoentok && $!==ENOENT)
 635     or die "$self: failed to restore: rename $unnailed back to $mf: $!\n";
 636 }
 637
 638 sub unaltcargolock ($) {
 639   my ($enoentok) = @_;
 640   return unless $cleanup_cargo_lock;
 641   die 'internal error!' unless defined $alt_cargo_lock;
 642
 643   # we ignore $enoentok because we don't know if one was supposed to
 644   # have been created.
 645
 646   rename('Cargo.lock', $alt_cargo_lock) or $!==ENOENT or die
 647  "$self: cleanup: rename possibly-updated \`Cargo.lock' to \`$alt_cargo_lock': $!\n";
 648
 649   unlink 'Cargo.lock' or $!==ENOENT or die
 650  "$self: cleanup: remove \`Cargo.lock' in favour of \`$alt_cargo_lock': $!\n";
 651   # ^ this also helps clean up the stupid rename() corner case
 652 }
 653
 654 sub uninstall () {
 655   foreach my $mf (keys %manifests) {
 656     my $nailed = nailed($mf);
 657     link $mf, $nailed or die "$self: preserve (link) $mf as $nailed: $!\n";
 658     uninstall1($mf,0);
 659   }
 660   unaltcargolock(0);
 661 }
 662
 663 sub parse_args () {
 664   my $is_cargo;
 665
 666   # Loop exit condition:
 667   #   $is_cargo is set
 668   #   @ARGV contains
 669   #    $is_cargo==1   <cargo-command> <cargo-opts> [--] <subcmd>...
 670   #    $is_cargo==0   <build-command>...
 671
 672   for (;;) {
 673     @ARGV or die "$self: need cargo subcommand\n";
 674
 675     $_ = shift @ARGV;
 676     my $orgopt = $_;
 677
 678     my $not_a_nailing_opt = sub { # usage 1
 679       unshift @ARGV, $orgopt;
 680       unshift @ARGV, 'cargo';
 681       $is_cargo = 1;
 682       no warnings qw(exiting);
 683       last;
 684     };
 685     $not_a_nailing_opt->() unless m{^-};
 686     $not_a_nailing_opt->() if $_ eq '--';
 687
 688     if ($_ eq '---') { # usage 2 or 3
 689       die "$self: --- must be followed by build command\n" unless @ARGV;
 690       if ($ARGV[0] eq '--') { # usage 3
 691         shift;
 692         $is_cargo = 0;
 693       } elsif (grep { $_ eq '--' } @ARGV) { # usage 2
 694         $is_cargo = 1;
 695       } elsif ($ARGV[0] =~ m{[^/]*cargo[^/]*$}) { # usage 2
 696         $is_cargo = 1;
 697       } else {  # usage 3
 698         $is_cargo = 0;
 699       }
 700       last;
 701     }
 702     if (m{^-[^-]}) {
 703       while (m{^-.}) {
 704         if (s{^-v}{-}) {
 705           $verbose++;
 706         } elsif (s{^-q}{-}) {
 707           $verbose=0;
 708         } elsif (s{^-n}{-}) {
 709           $noact++;
 710         } elsif (s{^-s(.+)}{-}s) {
 711           $cargo_subcmd = $1;
 712         } elsif (s{^-([cC])}{-}) {
 713           $pass_options = $1=~m/[a-z]/;
 714         } elsif (s{^-D}{-}) {
 715           $dump++;
 716         } elsif (s{^-T(.+)}{-}s) {
 717           $target = $1;
 718         } elsif (s{^-([oO])}{-}) {
 719           $online = $1=~m/[a-z]/;
 720         } else {
 721           die "$self: unknown short option(s) $_\n" unless $_ eq $orgopt;
 722           $not_a_nailing_opt->();
 723         }
 724       }
 725     } elsif (s{^--target=}{}) {
 726       $target = $_;
 727     } elsif (m{^--(on|off)line$}) {
 728       $online = $1 eq 'on';
 729     } elsif (s{^--subcommand-props=}{}) {
 730       my @props = split /\,/, $_;
 731       our %subcmd_prop_ok;
 732       if (!%subcmd_prop_ok) {
 733         foreach my $v (\@subcmd_xprops, values %subcmd_props) {
 734           $subcmd_prop_ok{$_}=1 foreach @$v;
 735         };
 736       }
 737       $subcmd_prop_ok{$_}
 738         or die "$self: unknown subcommand property \`$_'\n"
 739         foreach @props;
 740       $cargo_subcmd = \@props;
 741     } elsif (m{^--(no-)?cargo-lock-update}) {
 742       $cargo_lock_update= !!$1;
 743     } else {
 744       $not_a_nailing_opt->();
 745     }
 746   }
 747
 748   $is_cargo // die;
 749   @ARGV || die;
 750
 751   if ($is_cargo) {
 752     @args_preface = shift @ARGV;
 753     while (defined($_ = shift @ARGV)) {
 754       if (!m{^-}) { unshift @ARGV, $_; last; }
 755       if ($_ eq '--') { last; }
 756       push @args_preface, $_;
 757     }
 758     @ARGV || die "$self: need cargo subcommand\n";
 759     $cargo_subcmd //= $ARGV[0];
 760     $pass_options //= 1;
 761   } else {
 762     $cargo_subcmd //= '';
 763     $pass_options //= 0;
 764   }
 765   push @args_preface, shift @ARGV;
 766
 767   if (!ref($cargo_subcmd)) {
 768     print STDERR " cargo_subcmd lookup $cargo_subcmd\n" if $dump;
 769     $cargo_subcmd = $subcmd_props{$cargo_subcmd} // [ ];
 770   }
 771
 772   print STDERR " cargo_subcmd props @$cargo_subcmd\n" if $dump;
 773   my %cargo_subcmd;
 774   $cargo_subcmd{$_} = 1 foreach @$cargo_subcmd;
 775   $cargo_subcmd = \%cargo_subcmd;
 776 }
 777
 778 parse_args();
 779 loadconfigs();
 780 takelock();
 781 readnail();
 782 consider_alt_cargo_lock();
 783 consider_oot();
 784 readorigs();
 785 calculate();
 786 addargs();
 787 our @display_cmd = @ARGV;
 788 oot_massage_cmdline();
 789 setenvs();
 790
 791 if ($dump) {
 792   eval '
 793     use Data::Dumper;
 794     print STDERR Dumper(\%manifests) if $dump>=2;
 795     print STDERR Dumper(\%packagemap, \@ARGV,
 796                         { src_absdir => $src_absdir,
 797                           worksphere => $worksphere,
 798                           subdir => $subdir,
 799                           oot_dir => $oot_dir,
 800                           oot_absdir => $oot_absdir,
 801                           build_absdir => $build_absdir });
 802   ' or die $@;
 803 }
 804
 805 exit 0 if $noact;
 806
 807 $want_uninstall = 1;
 808 makebackups();
 809 install();
 810
 811 printf STDERR "$self: nailed (%s manifests, %s packages)%s\n",
 812   (scalar keys %manifests), (scalar keys %packagemap),
 813   (defined($alt_cargo_lock) and ", using `$alt_cargo_lock'")
 814   if $verbose;
 815
 816 print STDERR "$self: invoking: @display_cmd\n" if $verbose;
 817 my $estatus = invoke();
 818
 819 cargo_lock_update_after();
 820
 821 uninstall();
 822 $want_uninstall = 0;
 823
 824 print STDERR "$self: unnailed.  status $estatus.\n" if $verbose;
 825
 826 exit $estatus;