nailing-cargo

   1 #!/usr/bin/perl -w
   2 # nailing-cargo: wrapper to use unpublished local crates
   3 # SPDX-License-Identifier: AGPL-3.0-or-later
   4 our $usage = <<'END';
   5
   6 usages:
   7
   8   nailing-cargo <nailing-opts> <cargo-opts> [--] <subcmd>...
   9   nailing-cargo <nailing-opts> --- <cargo> <cargo-opts> [--] <subcmd>...
  10   nailing-cargo <nailing-opts> --- [--] <build-command>...
  11
  12 options:
  13
  14   -v  Increase verbosity.  (Default is 1)
  15   -q  Set verbosity to 0
  16   -D  Increase amount of debugging dump.
  17   -n  "No action": stop after writing Cargo.toml.nailing~
  18       everywhere, and do not run any build command
  19
  20   -c  Do add cargo command line options      } default is add if
  21   -C  Do not add cargo command line options  }  command is cargo
  22
  23   -o --online                     -O --offline
  24   -u --cargo-lock-update          -U --no-cargo-lock-update
  25
  26   -T<arch>  --target=<arch>       Specify target architecture
  27   -h --help                       Print this message
  28   --doc --man --manual            Display complete manual (in w3m)
  29   --leave-nailed                  Leave the nailed Cargo.toml in place
  30   -E | --edits-sources            Allow source edits (repeat: file creation)
  31   -f | --force                    Override some warnings
  32   --linkfarm[=no|shallow|git|full]        (default varies, usually "no")
  33   --just-linkfarm | --clean-linkfarm | --keep-linkfarm (default is keep)
  34   --[no-]preclean-build[=no|src|full]               (default is no)
  35   --just-run                      Run the command, don't do cargo stuff
  36   --no-nail                       Do not nail, just run the command.
  37   --no-cargo-lock-manip           Do not manipulate Cargo.lock.
  38   --no-concurrency-lock           Do not take the concurrency lock.
  39
  40   -s<subcommand>                  Treat command as `cargo <subcommand>`
  41   --subcommand-props=<prop>,...   Override command props (see docs)
  42
  43 END
  44
  45 our $self;
  46
  47 use strict;
  48 use POSIX;
  49 use Types::Serialiser;
  50 use File::Glob qw(bsd_glob GLOB_ERR GLOB_BRACE GLOB_NOMAGIC);
  51 use Cwd qw(realpath);
  52
  53 our $base_path;
  54 our %archmap = (
  55     RPI => 'arm-unknown-linux-gnueabihf',
  56     WASM => 'wasm32-unknown-unknown',
  57 );
  58
  59 BEGIN {
  60   $self = $0;  $self =~ s{^.*/(?=.)}{};
  61   my $deref = $0;
  62   our $base_path;
  63   while ($deref =~ m{^/}) {
  64     my $link = readlink $deref;
  65     if (!defined $link) {
  66       $! == EINVAL
  67         or die "$self: checking our script location $deref: $!\n";
  68       $deref =~ s{/[^/]+$}{}
  69         or die "$self: unexpected script path: $deref\n";
  70       $base_path = $deref;
  71       unshift @INC, $deref."/TOML-Tiny/lib";
  72       last;
  73     }
  74     last if $link !~ m{^/};
  75     $deref = $link;
  76   }
  77 }
  78
  79 use Fcntl qw(LOCK_EX);
  80 use File::Compare;
  81 use TOML::Tiny::Faithful;
  82
  83 our $src_absdir = getcwd() // die "$self: getcwd failed: $!\n";
  84
  85 our $worksphere = $src_absdir;
  86 $worksphere =~ s{/([^/]+)$}{}
  87   or die "$self: cwd \`$worksphere' unsupported!\n";
  88 our $subdir = $1; # leafname
  89
  90 our $lockfile = "../.nailing-cargo.lock";
  91
  92 our @args_preface;
  93 our $cargo_subcmd;
  94 our $command_is_cargo;
  95 our $alt_cargo_lock;
  96 our $cargo_lock_update;
  97 our $pass_options;
  98 our $online;
  99 our $just_linkfarm;
 100 our $leave_nailed;
 101 our $oot_clean;
 102 our $oot_preclean;
 103 our $do_nail=1;
 104 our $do_cargo_lock=1;
 105 our $do_lock=1;
 106 our $linkfarm_depth;
 107
 108 #
 109 our %subcmd_props = (
 110 # build (default)  =>[qw(                                                )],
 111 'generate-lockfile'=>[qw( lock-update !target          !target-dir       )],
 112  update            =>[qw( lock-update !target online                     )],
 113  fetch             =>[qw(                     online   !target-dir       )],
 114  fmt               =>[qw( !locked     !target !offline !target-dir edits )],
 115  init              =>[qw(                                        creates )],
 116  metadata          =>[qw(                              !target-dir       )],
 117  miri              =>[qw( !locked             !offline  linkfarm-shallow )],
 118  publish           =>[qw(                     !offline  linkfarm-gitclean )],
 119  upgrades          =>[qw( !locked                      !target-dir       )],
 120                     );
 121
 122 our @subcmd_xprops = qw(!manifest-path);
 123
 124 our @configs;
 125 our $verbose=1;
 126 our $force=0;
 127 our $forced=0;
 128 our ($noact,$dump);
 129 our $target;
 130
 131 sub print_usage () {
 132   print $usage or die $!;
 133   exit 0;
 134 }
 135
 136 sub show_manual () {
 137   my $manual = ($base_path // '.').'/README.md';
 138   stat $manual or die "$self: manual not found at $manual: $!\n";;
 139   exec 'sh','-ec', 'pandoc -- "$1" 2>&1 | w3m -T text/html', '--', $manual;
 140   die "$self: exec sh failed: $!";
 141 }
 142
 143 sub forceable_warning ($) {
 144   my ($m) = @_;
 145   print STDERR "$self: *WARNING*: $m\n";
 146   if ($force) {
 147     print STDERR "$self: continuing because of --force...\n" unless $forced++;
 148     return;
 149   } else {
 150     die "$self: Stopping due to warning (override with -f | --force)\n";
 151   }
 152 }
 153
 154 sub read_or_enoent ($) {
 155   my ($fn) = @_;
 156   if (!open R, '<', $fn) {
 157     return undef if $!==ENOENT;
 158     die "$self: open $fn: $!\n";
 159   }
 160   local ($/) = undef;
 161   my ($r) = <R> // die "$self: read $fn: $!\n";
 162   $r;
 163 }
 164
 165 sub stat_exists ($$) {
 166   my ($fn, $what) = @_;
 167   if (stat $fn) { return 1; }
 168   $!==ENOENT or die "$self: stat $what: $fn: $!\n";
 169   return 0;
 170 }
 171
 172 sub subcmd_p ($) {
 173   print STDERR " subcmd_p ".(join ' ', keys %$cargo_subcmd)."   | @_\n"
 174     if $dump;
 175   $cargo_subcmd->{$_[0]}
 176 }
 177
 178 sub toml_or_enoent ($$) {
 179   my ($f,$what) = @_;
 180   my $toml = read_or_enoent($f) // return;
 181   print STDERR "Read TOML from $f\n" if $dump;
 182   my ($v,$e) = from_toml($toml);
 183   if (!defined $v) {
 184     chomp $e;
 185     die "$self: parse TOML: $what: $f: $e\n";
 186   }
 187   die "$e ?" if length $e;
 188   $v;
 189 }
 190
 191 sub load1config ($) {
 192   my ($f) = @_;
 193   my $toml = toml_or_enoent($f, "config file");
 194   push @configs, $toml if defined $toml;
 195 }
 196
 197 sub loadconfigs () {
 198   my $dotfile = ".nailing-cargo.toml";
 199   load1config("../Nailing-Cargo.toml");
 200   load1config($dotfile);
 201   load1config("$ENV{HOME}/$dotfile") if defined $ENV{HOME};
 202   load1config("/etc/nailing-cargo/cfg.toml");
 203 }
 204
 205 sub unlink_or_enoent ($) { unlink $_[0] or $!==ENOENT; }
 206
 207 sub same_file ($$) {
 208   my ($x,$y) = @_;
 209   "@$x[0..5]" eq "@$y[0..5]";
 210 }
 211
 212 sub takelock () {
 213   return unless $do_lock;
 214
 215   for (;;) {
 216     open LOCK, ">", $lockfile or die "$self: open/create $lockfile: $!\n";
 217     flock LOCK, LOCK_EX or die "$self: lock $lockfile: $!\n";
 218     my @fstat = stat LOCK or die "$self: fstat: $!\n";
 219     my @stat  = stat $lockfile;
 220     if (!@stat) {
 221       next if $! == ENOENT;
 222       die "$self: stat $lockfile: $!\n";
 223     }
 224     last if same_file(\@fstat,\@stat);
 225   }
 226 }
 227 sub unlock () {
 228   unlink $lockfile or die "$self: removing lockfile: $!\n";
 229 }
 230
 231 our $nail;
 232
 233 sub badcfg {
 234   my $m = pop @_;
 235   $" = '.';
 236   die "$self: config key \`@_': $m\n";
 237 }
 238
 239 sub cfg_uc {
 240   foreach my $cfg (@configs) {
 241     my $v = $cfg;
 242     foreach my $k (@_) {
 243       last unless defined $v;
 244       ref($v) eq 'HASH' or badcfg @_, "parent key \`$k' is not a hash";
 245       $v = $v->{$k};
 246     }
 247     return $v if defined $v;
 248   }
 249   return undef;
 250 }
 251
 252 sub cfge {
 253   my $exp = shift @_;
 254   my $v = cfg_uc @_;
 255   my $got = ref($v) || 'scalar';
 256   return $v if !defined($v) || $got eq $exp;
 257   badcfg @_, "found \L$got\E, expected \L$exp\E";
 258   # ^ toml doesn't make refs to scalars, so this is unambiguous
 259 }
 260
 261 sub cfgn {
 262   my $exp = shift @_;
 263   (cfge $exp, @_) // badcfg @_, "missing";
 264 }
 265
 266 sub cfgs  { cfge 'scalar', @_ }
 267 sub cfgsn { cfgn 'scalar', @_ }
 268
 269 sub cfg_bool {
 270   my $v = cfg_uc @_;
 271   return $v if !defined($v) || Types::Serialiser::is_bool $v;
 272   badcfg @_, "expected boolean";
 273 }
 274
 275 sub cfgn_list {
 276   my $l = cfge 'ARRAY', @_;
 277   foreach my $x (@$l) {
 278     !ref $x or badcfg @_, "list contains non-scalar element";
 279   }
 280   @$l
 281 }
 282
 283 sub readnail () {
 284   my $nailfile = "../Cargo.nail";
 285   open N, '<', $nailfile or die "$self: open $nailfile: $!\n";
 286   local ($/) = undef;
 287   my $toml = <N> // die "$self: read $nailfile: $!";
 288   my $transformed;
 289   if ($toml !~ m{^\s*\[/}m &&
 290       $toml !~ m{^[^\n\#]*\=}m &&
 291       # old non-toml syntax
 292       $toml =~ s{^[ \t]*([-_0-9a-z]+)[ \t]+(\S+)[ \t]*$}{$1 = \"$2\"}mig) {
 293     $toml =~ s{^}{[packages\]\n};
 294     my @sd;
 295     $toml =~ s{^[ \t]*\-[ \t]*\=[ \t]*(\"[-_0-9a-z]+\"\n?)$}{
 296       push @sd, $1; '';
 297     }mige;
 298     $toml = "subdirs = [\n".(join '', map { "$_\n" } @sd)."]\n".$toml;
 299     $transformed = 1;
 300   }
 301   my $e;
 302   ($nail,$e) = from_toml($toml);
 303   if (!defined $nail) {
 304     if ($transformed) {
 305       $toml =~ s/^/    /mg;
 306       print STDERR "$self: $nailfile transformed into TOML:\n$toml\n";
 307     }
 308     $/="\n"; chomp $e;
 309     die "$self: parse $nailfile: $e\n";
 310   }
 311   die "$e ?" if length $e;
 312
 313   $nail->{subdirs} //= [ ];
 314
 315   if (!ref $nail->{subdirs}) {
 316     $nail->{subdirs} = [
 317       grep /^[^\#]/,
 318       map { s/^\s+//; s/\s+$//; $_; }
 319       split m{\n},
 320       $nail->{subdirs}
 321     ];
 322   }
 323
 324   unshift @configs, $nail;
 325 }
 326
 327 sub get_dependency_tables ($) {
 328   my ($toml) = @_;
 329   my @keys = qw(dependencies build-dependencies dev-dependencies);
 330   my @r;
 331   my $process = sub {
 332     my ($node) = @_;
 333     foreach my $k (@keys) {
 334       my $deps = $node->{$k};
 335       push @r, $deps if $deps;
 336     }
 337   };
 338   $process->($toml);
 339   foreach my $target_node (values %{ $toml->{target} // { } }) {
 340     $process->($target_node);
 341   }
 342   @r;
 343 }
 344
 345 our @alt_cargo_lock_stat;
 346
 347 sub consider_alt_cargo_lock () {
 348   my @ck = qw(alt_cargo_lock);
 349   # User should *either* have Cargo.lock in .gitignore,
 350   # or expect to commit Cargo.lock.example ($alt_cargo_lock)
 351
 352   return unless $do_cargo_lock;
 353
 354   $alt_cargo_lock = (cfg_uc @ck);
 355
 356   my $force = 0;
 357   if (defined($alt_cargo_lock) && ref($alt_cargo_lock) eq 'HASH') {
 358     $force = cfg_bool qw(alt_cargo_lock force);
 359     my @ck = qw(alt_cargo_lock file);
 360     $alt_cargo_lock = cfg_uc @ck;
 361   }
 362   $alt_cargo_lock //= Types::Serialiser::true;
 363
 364   if (Types::Serialiser::is_bool $alt_cargo_lock) {
 365     if (!$alt_cargo_lock) { $alt_cargo_lock = undef; return; }
 366     $alt_cargo_lock = 'Cargo.lock.example';
 367   }
 368
 369   if (ref($alt_cargo_lock) || $alt_cargo_lock =~ m{/}) {
 370     badcfg @ck, "expected boolean, or leafname";
 371   }
 372
 373   if (!stat_exists $alt_cargo_lock, "alt_cargo_lock") {
 374     $alt_cargo_lock = undef unless $force;
 375     return;
 376   }
 377
 378   @alt_cargo_lock_stat = stat _;
 379 }
 380
 381 our $oot_dir;      # oot.dir or "Build"
 382 our $oot_absdir;
 383
 384 sub consider_oot () {
 385   $oot_dir = cfgs qw(oot dir);
 386   my $use = cfgs qw(oot use);
 387   unless (defined($oot_dir) || defined($use) ||
 388           defined(cfg_uc qw(oot user))) {
 389     return;
 390   }
 391   if (($use//'') eq 'disable') {
 392     $oot_dir = undef;
 393     return;
 394   }
 395   $oot_clean //= cfg_bool qw(oot clean);
 396   $oot_dir //= 'Build';
 397   $oot_absdir = ($oot_dir !~ m{^/} ? "$worksphere/" : ""). $oot_dir;
 398 }
 399
 400 our %manifests;
 401 our %packagemap;
 402 our %workspaces;
 403 our @queued_paths;
 404
 405 sub read_manifest ($$$) {
 406   my ($subdir, $org_subdir, $why) = @_;
 407   my $manifest = "../$subdir/Cargo.toml";
 408   print STDERR "$self: reading $manifest...\n" if $verbose>=4;
 409   if (defined $manifests{$manifest}) {
 410     print STDERR
 411  "$self: warning: $subdir: specified more than once!".
 412  " (ignoring $why)\n";
 413     return undef;
 414   }
 415   foreach my $try ("$manifest.unnailed", "$manifest") {
 416     my $toml = toml_or_enoent($try, "manifest, in $why") // next;
 417     my $ws = $toml->{workspace};
 418     if ($ws) {
 419       queue_workspace_members($subdir, $org_subdir, $ws, "$subdir, $why");
 420     }
 421     my $p = $toml->{package}{name};
 422     if (!defined $p and !defined $ws) {
 423       print STDERR
 424  "$self: warning: $subdir, $why: missing package.name in $try, ignoring\n";
 425       next;
 426     }
 427     $manifests{$manifest} = [ $toml, $org_subdir ] if $p;
 428     foreach my $dep (get_dependency_tables $toml) {
 429       next unless defined $dep->{path};
 430       queue_referenced_path($dep->{path}, $org_subdir,
 431                             "dependency of $subdir, $why");
 432     }
 433     return ($p, $ws);
 434   }
 435   return undef;
 436 }
 437
 438 sub queue_workspace_members ($$) {
 439   my ($subdir, $org_subdir, $ws_toml, $what) = @_;
 440   # We need to (more or less) reimplement the cargo workspace
 441   # membership algorithm (see the "workspaces" section of the cargo
 442   # reference).  How tiresome.
 443   #
 444   # It's not quite the same for us because we aren't interested in
 445   # whether cargo thinks things are "in the workspace".  But we do
 446   # need to do the automatic discover.
 447
 448   my @include = @{ $ws_toml->{members} // [ ] };
 449   my $exclude = $ws_toml->{exclude} // [ ];
 450
 451   my @exclude = map {
 452     s/[^*?0-9a-zA-Z_]/\\$&/g;
 453     s/\?/./g;
 454     s/\*/.*/g;
 455   } @$exclude;
 456
 457   foreach my $spec (@include) {
 458     if ($spec =~ m{^/}) {
 459       print STDERR
 460         "$self: warning: absolute workspace member $spec in $what (not nailing, but cargo will probably use it)\n";
 461       next;
 462     }
 463     my $spec_glob = "../$subdir/$spec";
 464     my $globflags = GLOB_ERR|GLOB_BRACE|GLOB_NOMAGIC;
 465     foreach my $globent (bsd_glob($spec_glob, $globflags)) {
 466       next if grep { $globent =~ m{^$_$} } @exclude;
 467       queue_referenced_path($globent, $org_subdir,
 468                             "member of workspace $what");
 469     }
 470   }
 471 }
 472
 473 sub queue_referenced_path ($$$) {
 474   my ($spec_path, $org_subdir, $why) = @_;
 475   open REALPATH, "-|",
 476     qw(realpath), "--relative-to=../$org_subdir", "--", $spec_path
 477     or die "$self: fork/pipe/exec for realpath(1)\n";
 478   my $rel_path = do { local $/=undef; <REALPATH>; };
 479   $?=0; $!=0;
 480   my $r = close(REALPATH);
 481   die "$self: reap realpath: $!\n" if $!;
 482   if (!chomp($rel_path) or $?) {
 483     print STDERR
 484  "$self: warning: failed to determine realpath for $spec_path in $org_subdir (exit code $?)\n";
 485     return;
 486   }
 487   if ($rel_path =~ m{^\.\./} or $rel_path eq '..') {
 488     print STDERR
 489       "$self: warning: $spec_path ($why) points outside $org_subdir, not following so not nailing (although cargo probably will follow it)\n";
 490     return;
 491   }
 492
 493   my $q_subdir = "$org_subdir/$rel_path";
 494   print STDERR "$self: making a note to look at $q_subdir, $why)\n"
 495     if $verbose >= 4;
 496
 497   push @queued_paths, [ "$q_subdir", $org_subdir, $why ];
 498 }
 499
 500 sub readorigs () {
 501   # We (and our callees) populate %packagemap and %manifest, so if we
 502   # don't run, they remain empty and nothing is nailed.
 503   return unless $do_nail;
 504
 505   foreach my $p (keys %{ $nail->{packages} }) {
 506     my $v = $nail->{packages}{$p};
 507     my $subdir = ref($v) ? $v->{subdir} : $v;
 508     my ($gotpackage, $ws) = read_manifest($subdir, $subdir, "from [packages]");
 509     $gotpackage //= '<nothing!>';
 510     if ($gotpackage ne $p) {
 511       print STDERR
 512  "$self: warning: honouring Cargo.nail packages.$subdir=$p even though $subdir contains package $gotpackage!\n";
 513     }
 514     die if defined $packagemap{$p};
 515     $packagemap{$p} = [ $subdir, $subdir ];
 516   }
 517   foreach my $subdir (@{ $nail->{subdirs} }) {
 518     my ($gotpackage,$ws) = read_manifest($subdir, $subdir, "from [subdirs]");
 519     if (!defined $gotpackage) {
 520       print STDERR
 521  "$self: warning: ignoring subdir $subdir which has no (suitable) Cargo.toml\n"
 522         unless $ws;
 523       next;
 524     }
 525     $packagemap{$gotpackage} //= [ $subdir, $subdir ];
 526   }
 527   while (my ($subdir, $org_subdir, $why) = @{ shift @queued_paths or [] }) {
 528     next if $manifests{"../$subdir/Cargo.toml"};
 529     my ($gotpackage, $ws) = read_manifest($subdir, $org_subdir, $why);
 530     next unless $gotpackage;
 531     $packagemap{$gotpackage} //= [ $subdir, $org_subdir ];
 532   }
 533 }
 534
 535 sub calculate () {
 536   foreach my $p (sort keys %packagemap) {
 537     print STDERR "$self: package $p in $packagemap{$p}[0]\n" if $verbose>=2;
 538   }
 539   foreach my $mf (keys %manifests) {
 540     die "internal error" unless $do_nail; # belt and braces
 541
 542     my ($toml, $mf_org_subdir) = @{ $manifests{$mf} };
 543     foreach my $deps (get_dependency_tables $toml) {
 544       next unless $deps;
 545       foreach my $p (keys %packagemap) {
 546         my $info = $deps->{$p};
 547         next unless defined $info;
 548         next if $packagemap{$p}[1] eq $mf_org_subdir;
 549         $deps->{$p} = $info = { } unless ref $info; # was just version
 550         my $oldpath = $info->{path};
 551         delete $info->{version};
 552         my $newpath = $worksphere.'/'.$packagemap{$p}[0];
 553         print STDERR "in $mf set $p path=$newpath (was ".
 554           ($oldpath // '<unset>').")\n"
 555           if $verbose >= 4;
 556         $info->{path} = $newpath;
 557         delete $info->{git};
 558         delete $info->{branch};
 559       }
 560     }
 561     my $nailing = "$mf.nailing~";
 562     unlink_or_enoent $nailing or die "$self: remove old $nailing: $!\n";
 563     open N, '>', $nailing or die "$self: create new $nailing: $!\n";
 564     print N to_toml($toml) or die "$self: write new $nailing: $!\n";
 565     close N or die "$self: close new $nailing: $!\n";
 566   }
 567 }
 568
 569 sub addargs () {
 570   if ($just_linkfarm) {
 571     die "$self: --just-linkfarm but not doing out-of-tree builds!\n"
 572       unless defined $oot_dir;
 573     @ARGV = ();
 574     return;
 575   }
 576
 577   if (!defined $online) {
 578     $_ = cfg_uc qw(misc online);
 579     if (!defined $_) {
 580     } elsif (Types::Serialiser::is_bool $_) {
 581       $online = $_;
 582     } elsif (ref $_) {
 583     } elsif (m/^a/) {
 584       $online = undef;
 585     } elsif (m/^[1ty]/) { # allow booleanish strings
 586       $online = 1;        # for less user frustration
 587     } elsif (m/^[0fn]/) {
 588       $online = 0;
 589     } else {
 590       badcfg qw(misc online), "expected boolean or 'auto', found '$_'";
 591     }
 592   }
 593   $online //= 1 if subcmd_p('online');
 594   $online //= 0;
 595
 596   if (($linkfarm_depth//'') eq 'copy-edit-all') {
 597     $oot_preclean //= 'src';
 598     if ($oot_preclean !~ m/^(?:src|full)$/) {
 599       forceable_warning
 600  "-EE specified, but also --preclean=no; will probably leave your source tree full of junk";
 601     }
 602   }
 603
 604   if (subcmd_p('linkfarm-gitclean')) {
 605     $linkfarm_depth //= 'git';
 606     $oot_preclean //= 'src';
 607   }
 608
 609   $cargo_lock_update //= subcmd_p('lock-update');
 610   $linkfarm_depth //=
 611     subcmd_p('linkfarm-shallow') ? 'shallow' :
 612     $cargo_lock_update           ? 'shallow' :
 613     '';
 614
 615   $oot_preclean //= 'no';
 616
 617   our @add;
 618
 619   if (!$cargo_lock_update) {
 620     push @add, qw(--locked) unless subcmd_p('!locked');
 621   }
 622   if ($linkfarm_depth eq '') {
 623     if (defined($oot_dir) && !subcmd_p('!manifest-path')) {
 624       my $cargotoml = "${src_absdir}/Cargo.toml";
 625       push @args_preface, "--manifest-path=$cargotoml" if $pass_options;
 626       push @add, qw(--target-dir=target) unless subcmd_p('!target-dir');
 627     }
 628   }
 629
 630   if (defined($target) && !subcmd_p('!target')) {
 631     if ($target =~ m{^[A-Z]}) {
 632       $target = (cfgs 'arch', $target) // $archmap{$target}
 633         // die "$self: --target=$target alias specified; not in cfg or map\n";
 634     }
 635     push @add, "--target=$target";
 636   }
 637
 638   push @add, "--offline" unless $online || subcmd_p('!offline');
 639
 640   if (subcmd_p('creates') && $linkfarm_depth !~ m/^copy-edit-all/) {
 641     forceable_warning
 642  "this subcommand expects to create new source files; you probably want to specify --edits-sources twice aka -EE (which is not the default even now, for safety reasons)";
 643   } elsif (subcmd_p('edits') && $linkfarm_depth !~ m/^copy-edit/) {
 644     forceable_warning
 645  "this subcommand expects to edit the source code; you probably want to specify --edits-sources aka -E (which is not the default even now, for safety reasons)";
 646   }
 647
 648   push @args_preface, @add if $pass_options;
 649   die if grep { m/ / } @add;
 650   $ENV{NAILINGCARGO_CARGO_OPTIONS} = "@add";
 651
 652   unshift @ARGV, @args_preface;
 653 }
 654
 655 our $build_absdir; # .../Build/<subdir>
 656
 657 sub oot_massage_cmdline () {
 658   return unless defined $oot_dir;
 659
 660   my $use = cfgs qw(oot use);
 661   $use // die "$self: out-of-tree build, but \`oot.use' not configured\n";
 662   $build_absdir = "$oot_absdir/$subdir";
 663
 664   my ($pre,$post) = ('','');
 665   my @xargs;
 666   if ($linkfarm_depth eq '') {
 667     push @xargs, $build_absdir;
 668     ($pre, $post) = ('cd "$1"; shift; ', '');
 669   } else {
 670     push @xargs, $oot_absdir, $subdir, $src_absdir;
 671     $pre = <<'END_BOTH';
 672         bld="$1"; shift; sd="$1"; shift; src="$1"; shift;
 673         cd "$bld"; mkdir -p -- "$sd"; cd "$sd";
 674 END_BOTH
 675     if ($oot_preclean ne 'no') {
 676       $pre.= "find . -maxdepth 1 ! -path .";
 677       $pre.= " ! -path ./target" if $oot_preclean ne 'full';
 678       $pre.= " -print0 | xargs -0r rm -r --;"
 679     }
 680     if ($linkfarm_depth eq 'shallow') {
 681       $pre.= <<'END_SHALLOW';
 682         clean () { find -lname "$src/*" -print0 | xargs -0r rm --; }; clean;
 683         find "$src" -maxdepth 1 \! -name Cargo.lock -print0 |
 684         xargs -0r sh -ec 'for f in "$@"; do
 685                 rm -rf "${f##*/}";
 686                 ln -sf -- "$f" .;
 687         done';
 688 END_SHALLOW
 689     } elsif ($linkfarm_depth =~ /full|git/) {
 690       $pre .= <<'END_EITHER_DEEP_DIRS';
 691         clean () { find -follow -lname "$src/*" -print0 | xargs -0r rm --; };
 692         (set -e; cd "$src"; find . \! -name Cargo.lock \! \( -name .git -prune \) \! -path . \! -name .git -type d -print0) |
 693         xargs -0r sh -ec 'for f in "$@"; do
 694                 rm -f "$f" 2>/dev/null ||:;
 695                 mkdir -p "$f";
 696         done' x;
 697 END_EITHER_DEEP_DIRS
 698       if ($linkfarm_depth eq 'git') {
 699         $pre .= <<'END_FILES_GIT'
 700         (set -e; cd "$src"; git ls-files --exclude-standard -co -z) |
 701 END_FILES_GIT
 702       } elsif ($linkfarm_depth eq 'full') {
 703         $pre .= <<'END_FILES_FULL'
 704         (set -e; cd "$src"; find . \! -name Cargo.lock \! \( -name .git -prune \) \! -type d -print0) |
 705 END_FILES_FULL
 706       }
 707       $pre .= <<'END_DEEP';
 708         perl -0 -ne '
 709                 BEGIN { $src=shift @ARGV; }
 710                 next if (readlink "$_"//"") eq "$src/$_";
 711                 unlink "$_";
 712                 symlink "$src/$_", "$_" or die "$_ $!";
 713         ' "$src";
 714 END_DEEP
 715     } elsif ($linkfarm_depth =~ m/^copy-edit/) {
 716       $pre .= <<'END_COPY_EDIT';
 717         find -lname "$src/*" -print0 | xargs -0r rm --;
 718         (set -e; cd "$src"; git ls-files -c -z |
 719         cpio --quiet -p0m --no-preserve-owner -u --make-directories "$bld/$sd");
 720         clean () {
 721           (set -e; cd "$src"; git ls-files -c -z) | xargs -0r rm -f --;
 722         };
 723 END_COPY_EDIT
 724       if ($linkfarm_depth eq 'copy-edit-all') {
 725         $post .= <<'END_COPY_EDIT_GENFILES_ALL';
 726         find -xdev \( \( -name .git -o -path ./target -o -path ./nailing-cargo-update.tar \) -prune \) -o
 727               \( -type l -o -type f \) -print0 |
 728 END_COPY_EDIT_GENFILES_ALL
 729       } else {
 730         $post .= <<'END_COPY_EDIT_GENFILES_GIT';
 731         (set -e; cd "$src"; git ls-files -c -z) |
 732 END_COPY_EDIT_GENFILES_GIT
 733       }
 734       $post .= <<'END_COPY_EDIT_BUNDLE';
 735         cpio -Hustar -o0 --quiet >"nailing-cargo-update.tar";
 736 END_COPY_EDIT_BUNDLE
 737     } else {
 738        die "$linkfarm_depth ?";
 739     }
 740     $pre .= <<'ENDLK' if $do_cargo_lock;
 741         if test -e Cargo.lock; then
 742           rm -f Cargo.lock;
 743           cp -- "$src"/Cargo.lock .;
 744         fi;
 745 ENDLK
 746     $post .= <<'ENDCLEAN' if $oot_clean && !$just_linkfarm;
 747         clean;
 748 ENDCLEAN
 749   }
 750   my $addpath = (cfg_uc qw(oot path_add)) //
 751     $use eq 'really' ? Types::Serialiser::true : Types::Serialiser::false;
 752   $addpath =
 753     !Types::Serialiser::is_bool $addpath ? $addpath           :
 754     $addpath                             ? '$HOME/.cargo/bin' :
 755                                            undef;
 756   if (defined $addpath) {
 757     $pre .= <<END
 758         PATH=$addpath:\${PATH-/usr/local/bin:/bin:/usr/bin};
 759         export PATH;
 760 END
 761   }
 762   $pre  =~ s/^\s+//mg; $pre  =~ s/\s+/ /g;
 763   $post =~ s/^\s+//mg; $post =~ s/\s+/ /g;
 764
 765   my $getuser = sub { cfgsn qw(oot user) };
 766   my @command;
 767   my $xe = $verbose >= 2 ? 'xe' : 'e';
 768   my $sh_ec = sub {
 769     if (!length $post) {
 770       @command = (@_, 'sh',"-${xe}c",$pre.'exec "$@"','--',@xargs);
 771     } else {
 772       @command = (@_, 'sh',"-${xe}c",$pre.'"$@"; '.$post,'--',@xargs);
 773     }
 774     push @command, @ARGV;
 775   };
 776   my $command_sh = sub {
 777     my $quoted = join ' ', map {
 778       return $_ if !m/\W/;
 779       s/\'/\'\\'\'/g;
 780       "'$_'"
 781     } @ARGV;
 782     @command = @_, "set -${xe}; $pre $quoted; $post";
 783   };
 784   print STDERR "$self: out-of-tree, building in: \`$build_absdir'\n"
 785     if $verbose;
 786   if ($use eq 'really') {
 787     my $user = $getuser->();
 788     my @pw = getpwnam $user or die "$self: oot.user \`$user' lookup failed\n";
 789     my $homedir = $pw[7];
 790     $sh_ec->('really','-u',$user,'env',"HOME=$homedir");
 791     print STDERR "$self: using really to run as user \`$user'\n" if $verbose;
 792   } elsif ($use eq 'ssh') {
 793     my $user = $getuser->();
 794     $user .= '@localhost' unless $user =~ m/\@/;
 795     $command_sh->('ssh',$user);
 796     print STDERR "$self: using ssh to run as \`$user'\n" if $verbose;
 797   } elsif ($use eq 'command_args') {
 798     my @c = cfgn_list qw(oot command);
 799     $sh_ec->(@c);
 800     print STDERR "$self: out-of-tree, adverbial command: @c\n" if $verbose;
 801   } elsif ($use eq 'command_sh') {
 802     my @c = cfgn_list qw(oot command);
 803     $command_sh->(@c);
 804     print STDERR "$self: out-of-tree, ssh'ish command: @c\n" if $verbose;
 805   } elsif ($use eq 'null') {
 806     $sh_ec->();
 807   } else {
 808     die "$self: oot.use mode $use not recognised\n";
 809   }
 810   die unless @command;
 811   @ARGV = @command;
 812 }
 813
 814 sub setenvs () {
 815   $ENV{CARGO_MANIFEST_DIR} = $src_absdir unless $linkfarm_depth;
 816   $ENV{NAILINGCARGO_MANIFEST_DIR} = $src_absdir;
 817   $ENV{NAILINGCARGO_WORKSPHERE}   = $worksphere;
 818   $ENV{NAILINGCARGO_BUILDSPHERE}  = $oot_absdir;
 819   delete $ENV{NAILINGCARGO_BUILDSPHERE} unless $oot_absdir;
 820   $ENV{NAILINGCARGO_BUILD_DIR}    = $build_absdir // $src_absdir;
 821 }
 822
 823 our $want_uninstall;
 824
 825 END {
 826   if ($want_uninstall) {
 827     local ($?);
 828     foreach my $mf (keys %manifests) {
 829       eval { uninstall1($mf,1); 1; } or warn "$@";
 830     }
 831     eval { unaltcargolock(1); 1; } or warn "$@";
 832   }
 833 }
 834
 835 sub consider_directories () {
 836   return unless defined $oot_dir;
 837   my $bsubdir = "../$oot_dir/$subdir";
 838   return if stat $bsubdir;
 839   die "$0: build directory $bsubdir inaccessible\n"
 840     unless $!==ENOENT;
 841   return if $cargo_lock_update; # will make it
 842   die "$0: build directory $bsubdir does not exist, and not in Cargo.lock update mode!\n";
 843 }
 844
 845 our $cleanup_cargo_lock;
 846 sub makebackups () {
 847   foreach my $mf (keys %manifests) {
 848     link "$mf", "$mf.unnailed" or $!==EEXIST
 849       or die "$self: make backup link $mf.unnailed: $!\n";
 850   }
 851
 852   if (defined($alt_cargo_lock)) {
 853     die 'internal error' unless $do_cargo_lock;
 854     if (@alt_cargo_lock_stat) {
 855       print STDERR "$self: using alt_cargo_lock `$alt_cargo_lock'..."
 856         if $verbose>=3;
 857       if (link $alt_cargo_lock, 'Cargo.lock') {
 858         print STDERR " linked\n" if $verbose>=3;
 859       } elsif ($! != EEXIST) {
 860         print STDERR "\n" if $verbose>=3;
 861         die "$self: make \`Cargo.lock' available as \`$alt_cargo_lock': $!\n";
 862       } else {
 863         print STDERR "checking quality." if $verbose>=3;
 864         my @lock_stat = stat 'Cargo.lock'
 865           or die "$self: stat Cargo.lock (for alt check: $!\n";
 866         same_file(\@alt_cargo_lock_stat, \@lock_stat)
 867           or die
 868 "$self: \`Cargo.lock' and alt file \`$alt_cargo_lock' both exist and are not the same file!\n";
 869       }
 870       $cleanup_cargo_lock = 1;
 871     } else {
 872       $cleanup_cargo_lock = 1;
 873       # If Cargo.lock exists and alt doesn't, that means either
 874       # that a previous run was interrupted, or that the user has
 875       # messed up.
 876     }
 877   }
 878 }
 879
 880 sub nailed ($) {
 881   my ($mf) = @_;
 882   my $nailed  = "$mf.nailed~"; $nailed =~ s{/([^/]+)$}{/.$1} or die;
 883   $nailed;
 884 }
 885
 886 sub install () {
 887   my @our_unfound_stab = stat_exists('Cargo.toml', 'local Cargo.toml')
 888     ? (stat _) : ();
 889   foreach my $mf (keys %manifests) {
 890     if (@our_unfound_stab) {
 891       if (stat_exists $mf, "manifest in to-be-nailed directory") {
 892         my @mf_stab = stat _ ;
 893         if ("@mf_stab[0..1]" eq "@our_unfound_stab[0..1]") {
 894           @our_unfound_stab = ();
 895         }
 896       }
 897     }
 898
 899     my $nailing = "$mf.nailing~";
 900     my $nailed = nailed($mf);
 901     my ($use, $rm);
 902     my $diff;
 903     if (open NN, '<', $nailed) {
 904       $diff = compare($nailing, \*NN);
 905       die "$self: compare $nailing and $nailed: $!" if $diff<0;
 906     } else {
 907       $!==ENOENT or die "$self: check previous $nailed: $!\n";
 908       $diff = 1;
 909     }
 910     if ($diff) {
 911       $use = $nailing;
 912       $rm  = $nailed;
 913     } else {
 914       $use = $nailed;
 915       $rm  = $nailing;
 916     }
 917     rename $use, $mf or die "$self: install nailed $use: $!\n";
 918     unlink_or_enoent $rm or die "$self: remove old $rm: $!\n";
 919     print STDERR "$self: nailed $mf\n" if $verbose>=3;
 920   }
 921
 922   if (@our_unfound_stab && $do_nail) {
 923     print STDERR
 924  "$self: *WARNING* cwd is not in Cargo.nail thbough it has Cargo.toml!\n";
 925   }
 926 }
 927
 928 sub invoke () {
 929   my $r = system @ARGV;
 930   if (!$r) {
 931     return 0;
 932   } elsif ($r<0) {
 933     print STDERR "$self: could not execute $ARGV[0]: $!\n";
 934     return 127;
 935   } elsif ($r & 0xff00) {
 936     print STDERR "$self: $ARGV[0] failed (exit status $r)\n";
 937     return $r >> 8;
 938   } else {
 939     print STDERR "$self: $ARGV[0] died due to signal! (wait status $r)\n";
 940     return 125;
 941   }
 942 }
 943
 944 sub files_return_after_update () {
 945   if ($linkfarm_depth =~ m/^copy-edit/) {
 946     my $tar_source_opts;
 947     my $tar_stdin;
 948     if ($linkfarm_depth eq 'copy-edit-all') {
 949       $tar_source_opts = '--null --files-from=-';
 950       $tar_stdin = <<'END_GIT_FILES';
 951       git ls-files -c -z | \
 952 END_GIT_FILES
 953     } else {
 954       $tar_source_opts = '--anchored --exclude=.git --exclude="*/.git" --exclude=target --exclude=nailing-cargo-update.tar';
 955       $tar_stdin = '';
 956     }
 957     system qw(sh -ec), $tar_stdin . <<'END', 'x', "$build_absdir";
 958       tar -x --keep-newer-files --no-same-permissions --no-same-owner \
 959         --no-acls --no-selinux --no-xattrs --warning=no-ignore-newer \
 960         -Hustar $tar_source_opts --force-local \
 961         -f "$1/nailing-cargo-update.tar"
 962 END
 963   } elsif ($do_cargo_lock && $cargo_lock_update && !$just_linkfarm) {
 964     # avoids importing File::Copy and the error handling is about as good
 965     $!=0; $?=0;
 966     my $r= system qw(cp --), "$build_absdir/Cargo.lock", "Cargo.lock";
 967     die "$self: run cp: $! $?" if $r<0 || $r & 0xff;
 968     die "$self: failed to update local Cargo.lock (wait status $r)\n" if $r;
 969   }
 970 }
 971
 972 sub uninstall1 ($$) {
 973   my ($mf, $enoentok) = @_;
 974   my $unnailed = "$mf.unnailed";
 975   rename $unnailed, $mf or ($enoentok && $!==ENOENT)
 976     or die "$self: failed to restore: rename $unnailed back to $mf: $!\n";
 977 }
 978
 979 sub unaltcargolock ($) {
 980   my ($enoentok) = @_;
 981   return unless $cleanup_cargo_lock;
 982   die 'internal error!' unless $do_cargo_lock && defined $alt_cargo_lock;
 983
 984   # we ignore $enoentok because we don't know if one was supposed to
 985   # have been created.
 986
 987   rename('Cargo.lock', $alt_cargo_lock) or $!==ENOENT or die
 988  "$self: cleanup: rename possibly-updated \`Cargo.lock' to \`$alt_cargo_lock': $!\n";
 989
 990   unlink 'Cargo.lock' or $!==ENOENT or die
 991  "$self: cleanup: remove \`Cargo.lock' in favour of \`$alt_cargo_lock': $!\n";
 992   # ^ this also helps clean up the stupid rename() corner case
 993 }
 994
 995 sub uninstall () {
 996   foreach my $mf (keys %manifests) {
 997     my $nailed = nailed($mf);
 998     link $mf, $nailed or die "$self: preserve (link) $mf as $nailed: $!\n";
 999     uninstall1($mf,0);
1000   }
1001   unaltcargolock(0);
1002 }
1003
1004 sub parse_args () {
1005   my $is_cargo;
1006
1007   # Loop exit condition:
1008   #   $is_cargo is set
1009   #   @ARGV contains
1010   #    $is_cargo==1   <cargo-command> <cargo-opts> [--] <subcmd>...
1011   #    $is_cargo==0   <build-command>...
1012
1013  OPTS: for (;;) {
1014     if (!@ARGV) {
1015       die "$self: need cargo subcommand\n"
1016         unless $noact || $just_linkfarm;;
1017       push @ARGV, "CARGO-SUBCOMMAND"; # dummy, user may see it
1018     }
1019
1020     $_ = shift @ARGV;
1021     my $orgopt = $_;
1022
1023     my $not_a_nailing_opt = sub { # usage 1
1024       unshift @ARGV, $orgopt;
1025       unshift @ARGV, 'cargo';
1026       $is_cargo = 1;
1027       no warnings qw(exiting);
1028       last OPTS;
1029     };
1030     $not_a_nailing_opt->() unless m{^-};
1031     $not_a_nailing_opt->() if $_ eq '--';
1032
1033     my $edits_sources = sub {
1034       $linkfarm_depth =
1035         ($linkfarm_depth//'') eq 'copy-edit' ? 'copy-edit-all' : 'copy-edit';
1036     };
1037
1038     if ($_ eq '---') { # usage 2 or 3
1039       if (!@ARGV) {
1040         die "$self: --- must be followed by build command\n" unless $noact;
1041         push @ARGV, 'BUILD-COMMAND';
1042       }
1043       if ($ARGV[0] eq '--') { # usage 3
1044         shift;
1045         $is_cargo = 0;
1046       } elsif (grep { $_ eq '--' } @ARGV) { # usage 2
1047         $is_cargo = 1;
1048       } elsif ($ARGV[0] =~ m{[^/]*cargo[^/]*$}) { # usage 2
1049         $is_cargo = 1;
1050       } else {  # usage 3
1051         $is_cargo = 0;
1052       }
1053       last;
1054     }
1055     if (m{^-[^-]}) {
1056       while (m{^-.}) {
1057         if (s{^-h}{-}) {
1058           print_usage();
1059         } elsif (s{^-v}{-}) {
1060           $verbose++;
1061         } elsif (s{^-q}{-}) {
1062           $verbose=0;
1063         } elsif (s{^-n}{-}) {
1064           $noact++;
1065         } elsif (s{^-f}{-}) {
1066           $force++;
1067         } elsif (s{^-s(.+)}{-}s) {
1068           $cargo_subcmd = $1;
1069         } elsif (s{^-([uU])}{-}) {
1070           $cargo_lock_update = $1=~m/[a-z]/;
1071         } elsif (s{^-([cC])}{-}) {
1072           $pass_options = $1=~m/[a-z]/;
1073         } elsif (s{^-D}{-}) {
1074           $dump++;
1075         } elsif (s{^-E}{-}) {
1076           $edits_sources->();
1077         } elsif (s{^-T(.+)}{-}s) {
1078           $target = $1;
1079         } elsif (s{^-([oO])}{-}) {
1080           $online = $1=~m/[a-z]/;
1081         } else {
1082           die "$self: unknown short option(s) $_\n" unless $_ eq $orgopt;
1083           $not_a_nailing_opt->();
1084         }
1085       }
1086     } elsif (s{^--help$}{}) {
1087       print_usage();
1088     } elsif (s{^--(?:doc|man|manual)?$}{}) {
1089       show_manual();
1090     } elsif (s{^--target=}{}) {
1091       $target = $_;
1092     } elsif (m{^--(on|off)line$}) {
1093       $online = $1 eq 'on';
1094     } elsif (m{^--just-linkfarm(?:=(shallow|git|full))?$}) {
1095       $just_linkfarm = 1;
1096       $linkfarm_depth = $1 if $1;
1097       $cargo_lock_update= 1; # will set $linkfarm_detph to 1 by default
1098     } elsif (m{^--linkfarm(?:=(no|shallow|git|full))?$}) {
1099       $linkfarm_depth = $1 || 'git';
1100     } elsif (m{^--edits?-sources?$}) {
1101       $edits_sources->();
1102     } elsif (m{^--force$}) {
1103       $force++;
1104     } elsif (m{^--just-run$}) {
1105       $do_nail = $do_cargo_lock = $do_lock = 0;
1106     } elsif (m{^--(clean|keep)-linkfarm$}) {
1107       $oot_clean = $1 eq 'clean';
1108     } elsif (m{^--(no-)?preclean-build$}) {
1109       $oot_preclean = $1 ? 'no' : 'src';
1110     } elsif (m{^--preclean-build=(no|src|full)$}) {
1111       $oot_preclean = $1;
1112     } elsif (m{^--(no-)?nail$}) {
1113       $do_nail = !$1;
1114     } elsif (m{^--(no-)?cargo-lock-manip$}) {
1115       $do_cargo_lock = !$1;
1116     } elsif (m{^--(no-)?concurrency-lock$}) {
1117       $do_lock = !$1;
1118     } elsif (m{^--leave-nailed$}) {
1119       $leave_nailed = 1;
1120     } elsif (s{^--subcommand-props=}{}) {
1121       my @props = split /\,/, $_;
1122       our %subcmd_prop_ok;
1123       if (!%subcmd_prop_ok) {
1124         foreach my $v (\@subcmd_xprops, values %subcmd_props) {
1125           $subcmd_prop_ok{$_}=1 foreach @$v;
1126         };
1127       }
1128       $subcmd_prop_ok{$_}
1129         or die "$self: unknown subcommand property \`$_'\n"
1130         foreach @props;
1131       $cargo_subcmd = \@props;
1132     } elsif (m{^--(no-)?cargo-lock-update}) {
1133       $cargo_lock_update= !!$1;
1134     } else {
1135       $not_a_nailing_opt->();
1136     }
1137   }
1138
1139   $is_cargo // die;
1140   @ARGV || die;
1141
1142   if ($is_cargo) {
1143     @args_preface = shift @ARGV;
1144     while (defined($_ = shift @ARGV)) {
1145       if (!m{^-|^\+}) { unshift @ARGV, $_; last; }
1146       if ($_ eq '--') { last; }
1147       push @args_preface, $_;
1148     }
1149     @ARGV || die "$self: need cargo subcommand\n";
1150     $cargo_subcmd //= $ARGV[0];
1151     $pass_options //= 1;
1152   } else {
1153     $cargo_subcmd //= '';
1154     $pass_options //= 0;
1155   }
1156   push @args_preface, shift @ARGV;
1157
1158   if (!ref($cargo_subcmd)) {
1159     print STDERR " cargo_subcmd lookup $cargo_subcmd\n" if $dump;
1160     $cargo_subcmd = $subcmd_props{$cargo_subcmd} // [ ];
1161   }
1162
1163   print STDERR " cargo_subcmd props @$cargo_subcmd\n" if $dump;
1164   my %cargo_subcmd;
1165   $cargo_subcmd{$_} = 1 foreach @$cargo_subcmd;
1166   $cargo_subcmd = \%cargo_subcmd;
1167 }
1168
1169 parse_args();
1170 loadconfigs();
1171 readnail();
1172 takelock();
1173 consider_alt_cargo_lock();
1174 consider_oot();
1175 readorigs();
1176 calculate();
1177 addargs();
1178 consider_directories();
1179 our @display_cmd = @ARGV;
1180 oot_massage_cmdline();
1181 setenvs();
1182
1183 if ($dump) {
1184   eval '
1185     use Data::Dumper;
1186     print STDERR Dumper(\%manifests) if $dump>=2;
1187     print STDERR Dumper(\%packagemap, \@ARGV,
1188                         { src_absdir => $src_absdir,
1189                           worksphere => $worksphere,
1190                           subdir => $subdir,
1191                           oot_dir => $oot_dir,
1192                           oot_absdir => $oot_absdir,
1193                           build_absdir => $build_absdir,
1194                           linkfarm_depth => $linkfarm_depth,
1195                           oot_preclean => $oot_preclean,
1196                           force => $force,,
1197                           forced => $forced,});
1198   ' or die $@;
1199 }
1200
1201 exit 0 if $noact;
1202
1203 $want_uninstall = !$leave_nailed;
1204 makebackups();
1205 install();
1206
1207 printf STDERR "$self: nailed (%s manifests, %s packages)%s\n",
1208   (scalar keys %manifests), (scalar keys %packagemap),
1209   (defined($alt_cargo_lock) and ", using `$alt_cargo_lock'")
1210   if $verbose && $do_nail;
1211
1212 print STDERR "$self: invoking: @display_cmd\n" if $verbose;
1213 my $estatus = invoke();
1214
1215 files_return_after_update();
1216
1217 uninstall() unless $leave_nailed;
1218 $want_uninstall = 0;
1219
1220 print STDERR "$self: ".($do_nail ? "unnailed" : "finished")
1221              .".  status $estatus.\n" if $verbose;
1222
1223 exit $estatus;