nailing-cargo

   1 #!/usr/bin/perl -w
   2 # nailing-cargo: wrapper to use unpublished local crates
   3 # SPDX-License-Identifier: AGPL-3.0-or-later
   4
   5 our $self;
   6
   7 use strict;
   8 use POSIX;
   9 use Types::Serialiser;
  10 use File::Glob qw(bsd_glob GLOB_ERR GLOB_BRACE GLOB_NOMAGIC);
  11 use Cwd qw(realpath);
  12
  13 our %archmap = (
  14     RPI => 'arm-unknown-linux-gnueabihf',
  15 );
  16
  17 BEGIN {
  18   $self = $0;  $self =~ s{^.*/(?=.)}{};
  19   my $deref = $0;
  20   while ($deref =~ m{^/}) {
  21     my $link = readlink $deref;
  22     if (!defined $link) {
  23       $! == EINVAL
  24         or die "$self: checking our script location $deref: $!\n";
  25       $deref =~ s{/[^/]+$}{}
  26         or die "$self: unexpected script path: $deref\n";
  27       unshift @INC, $deref."/TOML-Tiny/lib";
  28       last;
  29     }
  30     last if $link !~ m{^/};
  31     $deref = $link;
  32   }
  33 }
  34
  35 use Fcntl qw(LOCK_EX);
  36 use File::Compare;
  37 use TOML::Tiny::Faithful;
  38
  39 our $src_absdir = getcwd() // die "$self: getcwd failed: $!\n";
  40
  41 our $worksphere = $src_absdir;
  42 $worksphere =~ s{/([^/]+)$}{}
  43   or die "$self: cwd \`$worksphere' unsupported!\n";
  44 our $subdir = $1; # leafname
  45
  46 our $lockfile = "../.nailing-cargo.lock";
  47
  48 our @args_preface;
  49 our $cargo_subcmd;
  50 our $command_is_cargo;
  51 our $alt_cargo_lock;
  52 our $cargo_lock_update;
  53 our $pass_options;
  54 our $online;
  55
  56 #
  57 our %subcmd_props = (
  58 # build (default)  =>[qw(                                        )],
  59 'generate-lockfile'=>[qw( lock-update !target        !target-dir )],
  60  update            =>[qw( lock-update !target online             )],
  61  fetch             =>[qw(                     online !target-dir )],
  62                     );
  63
  64 our @subcmd_xprops = qw(!manifest-path !offline !locked);
  65
  66 our @configs;
  67 our $verbose=1;
  68 our ($noact,$dump);
  69 our $target;
  70
  71 sub read_or_enoent ($) {
  72   my ($fn) = @_;
  73   if (!open R, '<', $fn) {
  74     return undef if $!==ENOENT;
  75     die "$self: open $fn: $!\n";
  76   }
  77   local ($/) = undef;
  78   my ($r) = <R> // die "$self: read $fn: $!\n";
  79   $r;
  80 }
  81
  82 sub stat_exists ($$) {
  83   my ($fn, $what) = @_;
  84   if (stat $fn) { return 1; }
  85   $!==ENOENT or die "$self: stat $what: $fn: $!\n";
  86   return 0;
  87 }
  88
  89 sub subcmd_p ($) {
  90   print STDERR " subcmd_p ".(join ' ', keys %$cargo_subcmd)."   | @_\n"
  91     if $dump;
  92   $cargo_subcmd->{$_[0]}
  93 }
  94
  95 sub toml_or_enoent ($$) {
  96   my ($f,$what) = @_;
  97   my $toml = read_or_enoent($f) // return;
  98   print STDERR "Read TOML from $f\n" if $dump;
  99   my ($v,$e) = from_toml($toml);
 100   if (!defined $v) {
 101     chomp $e;
 102     die "$self: parse TOML: $what: $f: $e\n";
 103   }
 104   die "$e ?" if length $e;
 105   $v;
 106 }
 107
 108 sub load1config ($) {
 109   my ($f) = @_;
 110   my $toml = toml_or_enoent($f, "config file");
 111   push @configs, $toml if defined $toml;
 112 }
 113
 114 sub loadconfigs () {
 115   my $dotfile = ".nailing-cargo.toml";
 116   load1config("../Nailing-Cargo.toml");
 117   load1config($dotfile);
 118   load1config("$ENV{HOME}/$dotfile") if defined $ENV{HOME};
 119   load1config("/etc/nailing-cargo/cfg.toml");
 120 }
 121
 122 sub unlink_or_enoent ($) { unlink $_[0] or $!==ENOENT; }
 123
 124 sub same_file ($$) {
 125   my ($x,$y) = @_;
 126   "@$x[0..5]" eq "@$y[0..5]";
 127 }
 128
 129 sub takelock () {
 130   for (;;) {
 131     open LOCK, ">", $lockfile or die "$self: open/create $lockfile: $!\n";
 132     flock LOCK, LOCK_EX or die "$self: lock $lockfile: $!\n";
 133     my @fstat = stat LOCK or die "$self: fstat: $!\n";
 134     my @stat  = stat $lockfile;
 135     if (!@stat) {
 136       next if $! == ENOENT;
 137       die "$self: stat $lockfile: $!\n";
 138     }
 139     last if same_file(\@fstat,\@stat);
 140   }
 141 }
 142 sub unlock () {
 143   unlink $lockfile or die "$self: removing lockfile: $!\n";
 144 }
 145
 146 our $nail;
 147
 148 sub badcfg {
 149   my $m = pop @_;
 150   $" = '.';
 151   die "$self: config key \`@_': $m\n";
 152 }
 153
 154 sub cfg_uc {
 155   foreach my $cfg (@configs) {
 156     my $v = $cfg;
 157     foreach my $k (@_) {
 158       last unless defined $v;
 159       ref($v) eq 'HASH' or badcfg @_, "parent key \`$k' is not a hash";
 160       $v = $v->{$k};
 161     }
 162     return $v if defined $v;
 163   }
 164   return undef;
 165 }
 166
 167 sub cfge {
 168   my $exp = shift @_;
 169   my $v = cfg_uc @_;
 170   my $got = ref($v) || 'scalar';
 171   return $v if !defined($v) || $got eq $exp;
 172   badcfg @_, "found \L$got\E, expected \L$exp\E";
 173   # ^ toml doesn't make refs to scalars, so this is unambiguous
 174 }
 175
 176 sub cfgn {
 177   my $exp = shift @_;
 178   (cfge $exp, @_) // badcfg @_, "missing";
 179 }
 180
 181 sub cfgs  { cfge 'scalar', @_ }
 182 sub cfgsn { cfgn 'scalar', @_ }
 183
 184 sub cfg_bool {
 185   my $v = cfg_uc @_;
 186   return $v if !defined($v) || Types::Serialiser::is_bool $v;
 187   badcfg @_, "expected boolean";
 188 }
 189
 190 sub cfgn_list {
 191   my $l = cfge 'ARRAY', @_;
 192   foreach my $x (@$l) {
 193     !ref $x or badcfg @_, "list contains non-scalar element";
 194   }
 195   @$l
 196 }
 197
 198 sub readnail () {
 199   my $nailfile = "../Cargo.nail";
 200   open N, '<', $nailfile or die "$self: open $nailfile: $!\n";
 201   local ($/) = undef;
 202   my $toml = <N> // die "$self: read $nailfile: $!";
 203   my $transformed;
 204   if ($toml !~ m{^\s*\[/}m &&
 205       $toml !~ m{^[^\n\#]*\=}m &&
 206       # old non-toml syntax
 207       $toml =~ s{^[ \t]*([-_0-9a-z]+)[ \t]+(\S+)[ \t]*$}{$1 = \"$2\"}mig) {
 208     $toml =~ s{^}{[packages\]\n};
 209     my @sd;
 210     $toml =~ s{^[ \t]*\-[ \t]*\=[ \t]*(\"[-_0-9a-z]+\"\n?)$}{
 211       push @sd, $1; '';
 212     }mige;
 213     $toml = "subdirs = [\n".(join '', map { "$_\n" } @sd)."]\n".$toml;
 214     $transformed = 1;
 215   }
 216   my $e;
 217   ($nail,$e) = from_toml($toml);
 218   if (!defined $nail) {
 219     if ($transformed) {
 220       $toml =~ s/^/    /mg;
 221       print STDERR "$self: $nailfile transformed into TOML:\n$toml\n";
 222     }
 223     $/="\n"; chomp $e;
 224     die "$self: parse $nailfile: $e\n";
 225   }
 226   die "$e ?" if length $e;
 227
 228   $nail->{subdirs} //= [ ];
 229
 230   if (!ref $nail->{subdirs}) {
 231     $nail->{subdirs} = [
 232       grep /^[^\#]/,
 233       map { s/^\s+//; s/\s+$//; $_; }
 234       split m{\n},
 235       $nail->{subdirs}
 236     ];
 237   }
 238
 239   unshift @configs, $nail;
 240 }
 241
 242 sub get_dependency_tables ($) {
 243   my ($toml) = @_;
 244   my @keys = qw(dependencies build-dependencies dev-dependencies);
 245   my @r;
 246   my $process = sub {
 247     my ($node) = @_;
 248     foreach my $k (@keys) {
 249       my $deps = $node->{$k};
 250       push @r, $deps if $deps;
 251     }
 252   };
 253   $process->($toml);
 254   foreach my $target_node (values %{ $toml->{target} // { } }) {
 255     $process->($target_node);
 256   }
 257   @r;
 258 }
 259
 260 our @alt_cargo_lock_stat;
 261
 262 sub consider_alt_cargo_lock () {
 263   my @ck = qw(alt_cargo_lock);
 264   # User should *either* have Cargo.lock in .gitignore,
 265   # or expect to commit Cargo.lock.example ($alt_cargo_lock)
 266
 267   $alt_cargo_lock = (cfg_uc @ck);
 268
 269   my $force = 0;
 270   if (defined($alt_cargo_lock) && ref($alt_cargo_lock) eq 'HASH') {
 271     $force = cfg_bool qw(alt_cargo_lock force);
 272     my @ck = qw(alt_cargo_lock file);
 273     $alt_cargo_lock = cfg_uc @ck;
 274   }
 275   $alt_cargo_lock //= Types::Serialiser::true;
 276
 277   if (Types::Serialiser::is_bool $alt_cargo_lock) {
 278     if (!$alt_cargo_lock) { $alt_cargo_lock = undef; return; }
 279     $alt_cargo_lock = 'Cargo.lock.example';
 280   }
 281
 282   if (ref($alt_cargo_lock) || $alt_cargo_lock =~ m{/}) {
 283     badcfg @ck, "expected boolean, or leafname";
 284   }
 285
 286   if (!stat_exists $alt_cargo_lock, "alt_cargo_lock") {
 287     $alt_cargo_lock = undef unless $force;
 288     return;
 289   }
 290
 291   @alt_cargo_lock_stat = stat _;
 292 }
 293
 294 our $oot_dir;      # oot.dir or "Build"
 295 our $oot_absdir;
 296
 297 sub consider_oot () {
 298   $oot_dir = cfgs qw(oot dir);
 299   my $use = cfgs qw(oot use);
 300   unless (defined($oot_dir) || defined($use) ||
 301           defined(cfg_uc qw(oot user))) {
 302     return;
 303   }
 304   if (($use//'') eq 'disable') {
 305     $oot_dir = undef;
 306     return;
 307   }
 308   $oot_dir //= 'Build';
 309   $oot_absdir = ($oot_dir !~ m{^/} ? "$worksphere/" : ""). $oot_dir;
 310 }
 311
 312 our %manifests;
 313 our %packagemap;
 314 our %workspaces;
 315 our @queued_paths;
 316
 317 sub read_manifest ($$$) {
 318   my ($subdir, $org_subdir, $why) = @_;
 319   my $manifest = "../$subdir/Cargo.toml";
 320   print STDERR "$self: reading $manifest...\n" if $verbose>=4;
 321   if (defined $manifests{$manifest}) {
 322     print STDERR
 323  "$self: warning: $subdir: specified more than once!".
 324  " (ignoring $why)\n";
 325     return undef;
 326   }
 327   foreach my $try ("$manifest.unnailed", "$manifest") {
 328     my $toml = toml_or_enoent($try, "manifest, in $why") // next;
 329     my $ws = $toml->{workspace};
 330     if ($ws) {
 331       queue_workspace_members($subdir, $org_subdir, $ws, "$subdir, $why");
 332     }
 333     my $p = $toml->{package}{name};
 334     if (!defined $p and !defined $ws) {
 335       print STDERR
 336  "$self: warning: $subdir, $why: missing package.name in $try, ignoring\n";
 337       next;
 338     }
 339     $manifests{$manifest} = [ $toml, $org_subdir ] if $p;
 340     return ($p, $ws);
 341   }
 342   return undef;
 343 }
 344
 345 sub queue_workspace_members ($$) {
 346   my ($subdir, $org_subdir, $ws_toml, $what) = @_;
 347   # We need to (more or less) reimplement the cargo workspace
 348   # membership algorithm (see the "workspaces" section of the cargo
 349   # reference).  How tiresome.
 350   #
 351   # It's not quite the same for us because we aren't interested in
 352   # whether cargo thinks things are "in the workspace".  But we do
 353   # need to do the automatic discover.
 354
 355   my @include = @{ $ws_toml->{members} // [ ] };
 356   my $exclude = $ws_toml->{exclude} // [ ];
 357
 358   my @exclude = map {
 359     s/[^*?0-9a-zA-Z_]/\\$&/g;
 360     s/\?/./g;
 361     s/\*/.*/g;
 362   } @$exclude;
 363
 364   foreach my $spec (@include) {
 365     if ($spec =~ m{^/}) {
 366       print STDERR
 367         "$self: warning: absolute workspace member $spec in $what (not nailing, but cargo will probably use it)\n";
 368       next;
 369     }
 370     my $spec_glob = "../$subdir/$spec";
 371     my $globflags = GLOB_ERR|GLOB_BRACE|GLOB_NOMAGIC;
 372     foreach my $globent (bsd_glob($spec_glob, $globflags)) {
 373       next if grep { $globent =~ m{^$_$} } @exclude;
 374       queue_referenced_path($globent, $org_subdir,
 375                             "member of workspace $what");
 376     }
 377   }
 378 }
 379
 380 sub queue_referenced_path ($$$) {
 381   my ($spec_path, $org_subdir, $why) = @_;
 382   open REALPATH, "-|",
 383     qw(realpath), "--relative-to=../$org_subdir", "--", $spec_path
 384     or die "$self: fork/pipe/exec for realpath(1)\n";
 385   my $rel_path = do { local $/=undef; <REALPATH>; };
 386   $?=0; $!=0;
 387   my $r = close(REALPATH);
 388   die "$self: reap realpath: $!\n" if $!;
 389   if (!chomp($rel_path) or $?) {
 390     print STDERR
 391  "$self: warning: failed to determine realpath for $spec_path in $org_subdir (exit code $?)\n";
 392     return;
 393   }
 394   if ($rel_path =~ m{^\.\./} or $rel_path eq '..') {
 395     print STDERR
 396       "$self: warning: $spec_path ($why) points outside $org_subdir, not following so not nailing (although cargo probably will follow it)\n";
 397     return;
 398   }
 399
 400   my $q_subdir = "$org_subdir/$rel_path";
 401   print STDERR "$self: making a note to look at $q_subdir, $why)\n"
 402     if $verbose >= 4;
 403
 404   push @queued_paths, [ "$q_subdir", $org_subdir, $why ];
 405 }
 406
 407 sub readorigs () {
 408   foreach my $p (keys %{ $nail->{packages} }) {
 409     my $v = $nail->{packages}{$p};
 410     my $subdir = ref($v) ? $v->{subdir} : $v;
 411     my ($gotpackage, $ws) = read_manifest($subdir, $subdir, "from [packages]");
 412     $gotpackage //= '<nothing!>';
 413     if ($gotpackage ne $p) {
 414       print STDERR
 415  "$self: warning: honouring Cargo.nail packages.$subdir=$p even though $subdir contains package $gotpackage!\n";
 416     }
 417     die if defined $packagemap{$p};
 418     $packagemap{$p} = [ $subdir, $subdir ];
 419   }
 420   foreach my $subdir (@{ $nail->{subdirs} }) {
 421     my ($gotpackage,$ws) = read_manifest($subdir, $subdir, "from [subdirs]");
 422     if (!defined $gotpackage) {
 423       print STDERR
 424  "$self: warning: ignoring subdir $subdir which has no (suitable) Cargo.toml\n"
 425         unless $ws;
 426       next;
 427     }
 428     $packagemap{$gotpackage} //= [ $subdir, $subdir ];
 429   }
 430   while (my ($subdir, $org_subdir, $why) = @{ shift @queued_paths or [] }) {
 431     next if $manifests{"../$subdir/Cargo.toml"};
 432     my ($gotpackage, $ws) = read_manifest($subdir, $org_subdir, $why);
 433     next unless $gotpackage;
 434     $packagemap{$gotpackage} //= [ $subdir, $org_subdir ];
 435   }
 436 }
 437
 438 sub calculate () {
 439   foreach my $p (sort keys %packagemap) {
 440     print STDERR "$self: package $p in $packagemap{$p}[0]\n" if $verbose>=2;
 441   }
 442   foreach my $mf (keys %manifests) {
 443     my ($toml, $mf_org_subdir) = @{ $manifests{$mf} };
 444     foreach my $deps (get_dependency_tables $toml) {
 445       next unless $deps;
 446       foreach my $p (keys %packagemap) {
 447         my $info = $deps->{$p};
 448         next unless defined $info;
 449         $deps->{$p} = $info = { } unless ref $info;
 450         my $oldpath = $info->{path};
 451         delete $info->{version};
 452         my $newpath = $worksphere.'/'.$packagemap{$p}[0];
 453         if ($cargo_lock_update and defined $oot_dir and
 454             $newpath =~ m{^\Q$src_absdir\E(?=$|/)}) {
 455           our $oot_subdir_realpath;
 456           $oot_subdir_realpath //= Cwd::realpath "$oot_absdir/$subdir"
 457             // die "$self: cannot resolve $oot_absdir/$subdir: $!";
 458           $newpath = $oot_subdir_realpath.$';
 459         }
 460         print STDERR "in $mf set $p path=$newpath (was ".
 461           ($oldpath // '<unset>').")\n"
 462           if $verbose >= 4;
 463         $info->{path} = $newpath;
 464       }
 465     }
 466     my $nailing = "$mf.nailing~";
 467     unlink_or_enoent $nailing or die "$self: remove old $nailing: $!\n";
 468     open N, '>', $nailing or die "$self: create new $nailing: $!\n";
 469     print N to_toml($toml) or die "$self: write new $nailing: $!\n";
 470     close N or die "$self: close new $nailing: $!\n";
 471   }
 472 }
 473
 474 sub addargs () {
 475   if (!defined $online) {
 476     $_ = cfg_uc qw(misc online);
 477     if (!defined $_) {
 478     } elsif (Types::Serialiser::is_bool $_) {
 479       $online = $_;
 480     } elsif (ref $_) {
 481     } elsif (m/^a/) {
 482       $online = undef;
 483     } elsif (m/^[1ty]/) { # allow booleanish strings
 484       $online = 1;        # for less user frustration
 485     } elsif (m/^[0fn]/) {
 486       $online = 0;
 487     } else {
 488       badcfg qw(misc online), "expected boolean or 'auto', found '$_'";
 489     }
 490   }
 491   $online //= 1 if subcmd_p('online');
 492   $online //= 0;
 493
 494   $cargo_lock_update //= subcmd_p('lock-update');
 495
 496   our @add;
 497
 498   if (!$cargo_lock_update) {
 499     push @add, qw(--locked) unless subcmd_p('!locked');
 500     if (defined($oot_dir) && !subcmd_p('!manifest-path')) {
 501       my $cargotoml = "${src_absdir}/Cargo.toml";
 502       push @args_preface, "--manifest-path=$cargotoml" if $pass_options;
 503       push @add, qw(--target-dir=target) unless subcmd_p('!target-dir');
 504     }
 505   }
 506
 507   if (defined($target) && !subcmd_p('!target')) {
 508     if ($target =~ m{^[A-Z]}) {
 509       $target = (cfgs 'arch', $target) // $archmap{$target}
 510         // die "$self: --target=$target alias specified; not in cfg or map\n";
 511     }
 512     push @add, "--target=$target";
 513   }
 514
 515   push @add, "--offline" unless $online || subcmd_p('!offline');
 516
 517   push @args_preface, @add if $pass_options;
 518   die if grep { m/ / } @add;
 519   $ENV{NAILINGCARGO_CARGO_OPTIONS} = "@add";
 520
 521   unshift @ARGV, @args_preface;
 522 }
 523
 524 our $build_absdir; # .../Build/<subdir>
 525
 526 sub oot_massage_cmdline () {
 527   return unless defined $oot_dir;
 528
 529   my $use = cfgs qw(oot use);
 530   $use // die "$self: out-of-tree build, but \`oot.use' not configured\n";
 531   $build_absdir = "$oot_absdir/$subdir";
 532
 533   my ($pre,$post) = ('','');
 534   my @xargs;
 535   if (!$cargo_lock_update) {
 536     push @xargs, $build_absdir;
 537     ($pre, $post) = ('cd "$1"; shift; ', '');
 538   } else {
 539     push @xargs, $oot_absdir, $subdir, $src_absdir;
 540     $pre =  <<'END';
 541         cd "$1"; shift;
 542         mkdir -p -- "$1"; cd "$1"; shift;
 543         clean () { find -lname "$1/*" -print0 | xargs -0r rm --; }; clean;
 544         find "$1" -maxdepth 1 \! -name Cargo.lock -print0 | xargs -0r -I_ ln -sf -- _ .;
 545 END
 546     $pre .= <<'ENDLK' if stat_exists 'Cargo.lock', 'working cargo lockfile';
 547         rm -f Cargo.lock;
 548         cp -- "$1"/Cargo.lock .;
 549 ENDLK
 550     $pre .= <<'ENDPRE';
 551         shift;
 552 ENDPRE
 553 #    $post = <<'ENDCLEAN';
 554 #        clean;
 555 #ENDCLEAN
 556   }
 557   my $addpath = (cfg_uc qw(oot path_add)) //
 558     $use eq 'really' ? Types::Serialiser::true : Types::Serialiser::false;
 559   $addpath =
 560     !Types::Serialiser::is_bool $addpath ? $addpath           :
 561     $addpath                             ? '$HOME/.cargo/bin' :
 562                                            undef;
 563   if (defined $addpath) {
 564     $pre .= <<END
 565         PATH=$addpath:\${PATH-/usr/local/bin:/bin:/usr/bin};
 566         export PATH;
 567 END
 568   }
 569   $pre  =~ s/^\s+//mg; $pre  =~ s/\s+/ /g;
 570   $post =~ s/^\s+//mg; $post =~ s/\s+/ /g;
 571
 572   my $getuser = sub { cfgsn qw(oot user) };
 573   my @command;
 574   my $xe = $verbose >= 2 ? 'xe' : 'e';
 575   my $sh_ec = sub {
 576     if (!length $post) {
 577       @command = (@_, 'sh',"-${xe}c",$pre.'exec "$@"','--',@xargs);
 578     } else {
 579       @command = (@_, 'sh',"-${xe}c",$pre.'"$@"; '.$post,'--',@xargs);
 580     }
 581     push @command, @ARGV;
 582   };
 583   my $command_sh = sub {
 584     my $quoted = join ' ', map {
 585       return $_ if !m/\W/;
 586       s/\'/\'\\'\'/g;
 587       "'$_'"
 588     } @ARGV;
 589     @command = @_, "set -${xe}; $pre $quoted; $post";
 590   };
 591   print STDERR "$self: out-of-tree, building in: \`$build_absdir'\n"
 592     if $verbose;
 593   if ($use eq 'really') {
 594     my $user = $getuser->();
 595     my @pw = getpwnam $user or die "$self: oot.user \`$user' lookup failed\n";
 596     my $homedir = $pw[7];
 597     $sh_ec->('really','-u',$user,'env',"HOME=$homedir");
 598     print STDERR "$self: using really to run as user \`$user'\n" if $verbose;
 599   } elsif ($use eq 'ssh') {
 600     my $user = $getuser->();
 601     $user .= '@localhost' unless $user =~ m/\@/;
 602     $command_sh->('ssh',$user);
 603     print STDERR "$self: using ssh to run as \`$user'\n" if $verbose;
 604   } elsif ($use eq 'command_args') {
 605     my @c = cfgn_list qw(oot command);
 606     $sh_ec->(@c);
 607     print STDERR "$self: out-of-tree, adverbial command: @c\n" if $verbose;
 608   } elsif ($use eq 'command_sh') {
 609     my @c = cfgn_list qw(oot command);
 610     $command_sh->(@c);
 611     print STDERR "$self: out-of-tree, ssh'ish command: @c\n" if $verbose;
 612   } elsif ($use eq 'null') {
 613     $sh_ec->();
 614   } else {
 615     die "$self: oot.use mode $use not recognised\n";
 616   }
 617   die unless @command;
 618   @ARGV = @command;
 619 }
 620
 621 sub setenvs () {
 622   $ENV{CARGO_MANIFEST_DIR} = $src_absdir;
 623   $ENV{NAILINGCARGO_MANIFEST_DIR} = $src_absdir;
 624   $ENV{NAILINGCARGO_WORKSPHERE}   = $worksphere;
 625   $ENV{NAILINGCARGO_BUILDSPHERE}  = $oot_absdir;
 626   delete $ENV{NAILINGCARGO_BUILDSPHERE} unless $oot_absdir;
 627   $ENV{NAILINGCARGO_BUILD_DIR}    = $build_absdir // $src_absdir;
 628 }
 629
 630 our $want_uninstall;
 631
 632 END {
 633   if ($want_uninstall) {
 634     local ($?);
 635     foreach my $mf (keys %manifests) {
 636       eval { uninstall1($mf,1); 1; } or warn "$@";
 637     }
 638     eval { unaltcargolock(1); 1; } or warn "$@";
 639   }
 640 }
 641
 642 sub consider_directories () {
 643   return unless defined $oot_dir;
 644   my $bsubdir = "../$oot_dir/$subdir";
 645   return if stat $bsubdir;
 646   die "$0: build directory $bsubdir inaccessible\n"
 647     unless $!==ENOENT;
 648   return if $cargo_lock_update; # will make it
 649   die "$0: build directory $bsubdir does not exist, and not in Cargo.lock update mode!\n";
 650 }
 651
 652 our $cleanup_cargo_lock;
 653 sub makebackups () {
 654   foreach my $mf (keys %manifests) {
 655     link "$mf", "$mf.unnailed" or $!==EEXIST
 656       or die "$self: make backup link $mf.unnailed: $!\n";
 657   }
 658
 659   if (defined($alt_cargo_lock)) {
 660     if (@alt_cargo_lock_stat) {
 661       print STDERR "$self: using alt_cargo_lock `$alt_cargo_lock'..."
 662         if $verbose>=3;
 663       if (link $alt_cargo_lock, 'Cargo.lock') {
 664         print STDERR " linked\n" if $verbose>=3;
 665       } elsif ($! != EEXIST) {
 666         print STDERR "\n" if $verbose>=3;
 667         die "$self: make \`Cargo.lock' available as \`$alt_cargo_lock': $!\n";
 668       } else {
 669         print STDERR "checking quality." if $verbose>=3;
 670         my @lock_stat = stat 'Cargo.lock'
 671           or die "$self: stat Cargo.lock (for alt check: $!\n";
 672         same_file(\@alt_cargo_lock_stat, \@lock_stat)
 673           or die
 674 "$self: \`Cargo.lock' and alt file \`$alt_cargo_lock' both exist and are not the same file!\n";
 675       }
 676       $cleanup_cargo_lock = 1;
 677     } else {
 678       $cleanup_cargo_lock = 1;
 679       # If Cargo.lock exists and alt doesn't, that means either
 680       # that a previous run was interrupted, or that the user has
 681       # messed up.
 682     }
 683   }
 684 }
 685
 686 sub nailed ($) {
 687   my ($mf) = @_;
 688   my $nailed  = "$mf.nailed~"; $nailed =~ s{/([^/]+)$}{/.$1} or die;
 689   $nailed;
 690 }
 691
 692 sub install () {
 693   my @our_unfound_stab = stat_exists('Cargo.toml', 'local Cargo.toml')
 694     ? (stat _) : ();
 695   foreach my $mf (keys %manifests) {
 696     if (@our_unfound_stab) {
 697       if (stat_exists $mf, "manifest in to-be-nailed directory") {
 698         my @mf_stab = stat _ ;
 699         if ("@mf_stab[0..1]" eq "@our_unfound_stab[0..1]") {
 700           @our_unfound_stab = ();
 701         }
 702       }
 703     }
 704
 705     my $nailing = "$mf.nailing~";
 706     my $nailed = nailed($mf);
 707     my ($use, $rm);
 708     my $diff;
 709     if (open NN, '<', $nailed) {
 710       $diff = compare($nailing, \*NN);
 711       die "$self: compare $nailing and $nailed: $!" if $diff<0;
 712     } else {
 713       $!==ENOENT or die "$self: check previous $nailed: $!\n";
 714       $diff = 1;
 715     }
 716     if ($diff) {
 717       $use = $nailing;
 718       $rm  = $nailed;
 719     } else {
 720       $use = $nailed;
 721       $rm  = $nailing;
 722     }
 723     rename $use, $mf or die "$self: install nailed $use: $!\n";
 724     unlink_or_enoent $rm or die "$self: remove old $rm: $!\n";
 725     print STDERR "$self: nailed $mf\n" if $verbose>=3;
 726   }
 727
 728   if (@our_unfound_stab) {
 729     print STDERR
 730  "$self: *WARNING* cwd is not in Cargo.nail thbough it has Cargo.toml!\n";
 731   }
 732 }
 733
 734 sub invoke () {
 735   my $r = system @ARGV;
 736   if (!$r) {
 737     return 0;
 738   } elsif ($r<0) {
 739     print STDERR "$self: could not execute $ARGV[0]: $!\n";
 740     return 127;
 741   } elsif ($r & 0xff00) {
 742     print STDERR "$self: $ARGV[0] failed (exit status $r)\n";
 743     return $r >> 8;
 744   } else {
 745     print STDERR "$self: $ARGV[0] died due to signal! (wait status $r)\n";
 746     return 125;
 747   }
 748 }
 749
 750 sub cargo_lock_update_after () {
 751   if ($cargo_lock_update) {
 752     # avoids importing File::Copy and the error handling is about as good
 753     $!=0; $?=0;
 754     my $r= system qw(cp --), "$build_absdir/Cargo.lock", "Cargo.lock";
 755     die "$self: run cp: $! $?" if $r<0 || $r & 0xff;
 756     die "$self: failed to update local Cargo.lock (wait status $r)\n" if $r;
 757   }
 758 }
 759
 760 sub uninstall1 ($$) {
 761   my ($mf, $enoentok) = @_;
 762   my $unnailed = "$mf.unnailed";
 763   rename $unnailed, $mf or ($enoentok && $!==ENOENT)
 764     or die "$self: failed to restore: rename $unnailed back to $mf: $!\n";
 765 }
 766
 767 sub unaltcargolock ($) {
 768   my ($enoentok) = @_;
 769   return unless $cleanup_cargo_lock;
 770   die 'internal error!' unless defined $alt_cargo_lock;
 771
 772   # we ignore $enoentok because we don't know if one was supposed to
 773   # have been created.
 774
 775   rename('Cargo.lock', $alt_cargo_lock) or $!==ENOENT or die
 776  "$self: cleanup: rename possibly-updated \`Cargo.lock' to \`$alt_cargo_lock': $!\n";
 777
 778   unlink 'Cargo.lock' or $!==ENOENT or die
 779  "$self: cleanup: remove \`Cargo.lock' in favour of \`$alt_cargo_lock': $!\n";
 780   # ^ this also helps clean up the stupid rename() corner case
 781 }
 782
 783 sub uninstall () {
 784   foreach my $mf (keys %manifests) {
 785     my $nailed = nailed($mf);
 786     link $mf, $nailed or die "$self: preserve (link) $mf as $nailed: $!\n";
 787     uninstall1($mf,0);
 788   }
 789   unaltcargolock(0);
 790 }
 791
 792 sub parse_args () {
 793   my $is_cargo;
 794
 795   # Loop exit condition:
 796   #   $is_cargo is set
 797   #   @ARGV contains
 798   #    $is_cargo==1   <cargo-command> <cargo-opts> [--] <subcmd>...
 799   #    $is_cargo==0   <build-command>...
 800
 801  OPTS: for (;;) {
 802     @ARGV or die "$self: need cargo subcommand\n";
 803
 804     $_ = shift @ARGV;
 805     my $orgopt = $_;
 806
 807     my $not_a_nailing_opt = sub { # usage 1
 808       unshift @ARGV, $orgopt;
 809       unshift @ARGV, 'cargo';
 810       $is_cargo = 1;
 811       no warnings qw(exiting);
 812       last OPTS;
 813     };
 814     $not_a_nailing_opt->() unless m{^-};
 815     $not_a_nailing_opt->() if $_ eq '--';
 816
 817     if ($_ eq '---') { # usage 2 or 3
 818       die "$self: --- must be followed by build command\n" unless @ARGV;
 819       if ($ARGV[0] eq '--') { # usage 3
 820         shift;
 821         $is_cargo = 0;
 822       } elsif (grep { $_ eq '--' } @ARGV) { # usage 2
 823         $is_cargo = 1;
 824       } elsif ($ARGV[0] =~ m{[^/]*cargo[^/]*$}) { # usage 2
 825         $is_cargo = 1;
 826       } else {  # usage 3
 827         $is_cargo = 0;
 828       }
 829       last;
 830     }
 831     if (m{^-[^-]}) {
 832       while (m{^-.}) {
 833         if (s{^-v}{-}) {
 834           $verbose++;
 835         } elsif (s{^-q}{-}) {
 836           $verbose=0;
 837         } elsif (s{^-n}{-}) {
 838           $noact++;
 839         } elsif (s{^-s(.+)}{-}s) {
 840           $cargo_subcmd = $1;
 841         } elsif (s{^-([uU])}{-}) {
 842           $cargo_lock_update = $1=~m/[a-z]/;
 843         } elsif (s{^-([cC])}{-}) {
 844           $pass_options = $1=~m/[a-z]/;
 845         } elsif (s{^-D}{-}) {
 846           $dump++;
 847         } elsif (s{^-T(.+)}{-}s) {
 848           $target = $1;
 849         } elsif (s{^-([oO])}{-}) {
 850           $online = $1=~m/[a-z]/;
 851         } else {
 852           die "$self: unknown short option(s) $_\n" unless $_ eq $orgopt;
 853           $not_a_nailing_opt->();
 854         }
 855       }
 856     } elsif (s{^--target=}{}) {
 857       $target = $_;
 858     } elsif (m{^--(on|off)line$}) {
 859       $online = $1 eq 'on';
 860     } elsif (s{^--subcommand-props=}{}) {
 861       my @props = split /\,/, $_;
 862       our %subcmd_prop_ok;
 863       if (!%subcmd_prop_ok) {
 864         foreach my $v (\@subcmd_xprops, values %subcmd_props) {
 865           $subcmd_prop_ok{$_}=1 foreach @$v;
 866         };
 867       }
 868       $subcmd_prop_ok{$_}
 869         or die "$self: unknown subcommand property \`$_'\n"
 870         foreach @props;
 871       $cargo_subcmd = \@props;
 872     } elsif (m{^--(no-)?cargo-lock-update}) {
 873       $cargo_lock_update= !!$1;
 874     } else {
 875       $not_a_nailing_opt->();
 876     }
 877   }
 878
 879   $is_cargo // die;
 880   @ARGV || die;
 881
 882   if ($is_cargo) {
 883     @args_preface = shift @ARGV;
 884     while (defined($_ = shift @ARGV)) {
 885       if (!m{^-}) { unshift @ARGV, $_; last; }
 886       if ($_ eq '--') { last; }
 887       push @args_preface, $_;
 888     }
 889     @ARGV || die "$self: need cargo subcommand\n";
 890     $cargo_subcmd //= $ARGV[0];
 891     $pass_options //= 1;
 892   } else {
 893     $cargo_subcmd //= '';
 894     $pass_options //= 0;
 895   }
 896   push @args_preface, shift @ARGV;
 897
 898   if (!ref($cargo_subcmd)) {
 899     print STDERR " cargo_subcmd lookup $cargo_subcmd\n" if $dump;
 900     $cargo_subcmd = $subcmd_props{$cargo_subcmd} // [ ];
 901   }
 902
 903   print STDERR " cargo_subcmd props @$cargo_subcmd\n" if $dump;
 904   my %cargo_subcmd;
 905   $cargo_subcmd{$_} = 1 foreach @$cargo_subcmd;
 906   $cargo_subcmd = \%cargo_subcmd;
 907 }
 908
 909 parse_args();
 910 loadconfigs();
 911 takelock();
 912 readnail();
 913 consider_alt_cargo_lock();
 914 consider_oot();
 915 readorigs();
 916 calculate();
 917 addargs();
 918 consider_directories();
 919 our @display_cmd = @ARGV;
 920 oot_massage_cmdline();
 921 setenvs();
 922
 923 if ($dump) {
 924   eval '
 925     use Data::Dumper;
 926     print STDERR Dumper(\%manifests) if $dump>=2;
 927     print STDERR Dumper(\%packagemap, \@ARGV,
 928                         { src_absdir => $src_absdir,
 929                           worksphere => $worksphere,
 930                           subdir => $subdir,
 931                           oot_dir => $oot_dir,
 932                           oot_absdir => $oot_absdir,
 933                           build_absdir => $build_absdir });
 934   ' or die $@;
 935 }
 936
 937 exit 0 if $noact;
 938
 939 $want_uninstall = 1;
 940 makebackups();
 941 install();
 942
 943 printf STDERR "$self: nailed (%s manifests, %s packages)%s\n",
 944   (scalar keys %manifests), (scalar keys %packagemap),
 945   (defined($alt_cargo_lock) and ", using `$alt_cargo_lock'")
 946   if $verbose;
 947
 948 print STDERR "$self: invoking: @display_cmd\n" if $verbose;
 949 my $estatus = invoke();
 950
 951 cargo_lock_update_after();
 952
 953 uninstall();
 954 $want_uninstall = 0;
 955
 956 print STDERR "$self: unnailed.  status $estatus.\n" if $verbose;
 957
 958 exit $estatus;