man/custom-html.xsl

   1 <?xml version='1.0'?> <!--*-nxml-*-->
   2
   3 <!--
   4   This file is part of systemd.
   5
   6   Copyright 2011 Lennart Poettering
   7
   8   systemd is free software; you can redistribute it and/or modify it
   9   under the terms of the GNU Lesser General Public License as published by
  10   the Free Software Foundation; either version 2.1 of the License, or
  11   (at your option) any later version.
  12
  13   systemd is distributed in the hope that it will be useful, but
  14   WITHOUT ANY WARRANTY; without even the implied warranty of
  15   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
  16   Lesser General Public License for more details.
  17
  18   You should have received a copy of the GNU Lesser General Public License
  19   along with systemd; If not, see <http://www.gnu.org/licenses/>.
  20 -->
  21
  22 <xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
  23
  24 <xsl:import href="http://docbook.sourceforge.net/release/xsl/current/html/docbook.xsl"/>
  25
  26 <!-- translate man page references to links to html pages -->
  27 <xsl:template match="citerefentry[not(@project)]">
  28   <a>
  29     <xsl:attribute name="href">
  30       <xsl:value-of select="refentrytitle"/><xsl:text>.html</xsl:text>
  31     </xsl:attribute>
  32     <xsl:call-template name="inline.charseq"/>
  33   </a>
  34 </xsl:template>
  35
  36 <xsl:template match="citerefentry[@project='man-pages'] | citerefentry[manvolnum='2'] | citerefentry[manvolnum='4']">
  37   <a>
  38     <xsl:attribute name="href">
  39       <xsl:text>http://man7.org/linux/man-pages/man</xsl:text>
  40       <xsl:value-of select="manvolnum"/>
  41       <xsl:text>/</xsl:text>
  42       <xsl:value-of select="refentrytitle"/>
  43       <xsl:text>.</xsl:text>
  44       <xsl:value-of select="manvolnum"/>
  45       <xsl:text>.html</xsl:text>
  46     </xsl:attribute>
  47     <xsl:call-template name="inline.charseq"/>
  48   </a>
  49 </xsl:template>
  50
  51 <xsl:template match="citerefentry[@project='die-net']">
  52   <a>
  53     <xsl:attribute name="href">
  54       <xsl:text>http://linux.die.net/man/</xsl:text>
  55       <xsl:value-of select="manvolnum"/>
  56       <xsl:text>/</xsl:text>
  57       <xsl:value-of select="refentrytitle"/>
  58     </xsl:attribute>
  59     <xsl:call-template name="inline.charseq"/>
  60   </a>
  61 </xsl:template>
  62
  63 <xsl:template match="citerefentry[@project='mankier']">
  64   <a>
  65     <xsl:attribute name="href">
  66       <xsl:text>https://www.mankier.com/</xsl:text>
  67       <xsl:value-of select="manvolnum"/>
  68       <xsl:text>/</xsl:text>
  69       <xsl:value-of select="refentrytitle"/>
  70     </xsl:attribute>
  71     <xsl:call-template name="inline.charseq"/>
  72   </a>
  73 </xsl:template>
  74
  75 <xsl:template match="citerefentry[@project='archlinux']">
  76   <a>
  77     <xsl:attribute name="href">
  78       <xsl:text>https://www.archlinux.org/</xsl:text>
  79       <xsl:value-of select="refentrytitle"/>
  80       <xsl:text>/</xsl:text>
  81       <xsl:value-of select="refentrytitle"/>
  82       <xsl:text>.</xsl:text>
  83       <xsl:value-of select="manvolnum"/>
  84       <xsl:text>.html</xsl:text>
  85     </xsl:attribute>
  86     <xsl:call-template name="inline.charseq"/>
  87   </a>
  88 </xsl:template>
  89
  90 <xsl:template match="citerefentry[@project='freebsd']">
  91   <a>
  92     <xsl:attribute name="href">
  93       <xsl:text>https://www.freebsd.org/cgi/man.cgi?</xsl:text>
  94       <xsl:value-of select="refentrytitle"/>
  95       <xsl:text>(</xsl:text>
  96       <xsl:value-of select="manvolnum"/>
  97       <xsl:text>)</xsl:text>
  98     </xsl:attribute>
  99     <xsl:call-template name="inline.charseq"/>
 100   </a>
 101 </xsl:template>
 102
 103 <xsl:template match="refsect1/title|refsect1/info/title">
 104   <!-- the ID is output in the block.object call for refsect1 -->
 105   <h2>
 106     <xsl:attribute name="id">
 107       <xsl:call-template name="inline.charseq"/>
 108     </xsl:attribute>
 109     <xsl:apply-templates/>
 110     <a>
 111       <xsl:attribute name="class">
 112         <xsl:text>headerlink</xsl:text>
 113       </xsl:attribute>
 114       <xsl:attribute name="title">
 115         <xsl:text>Permalink to this headline</xsl:text>
 116       </xsl:attribute>
 117       <xsl:attribute name="href">
 118         <xsl:text>#</xsl:text>
 119         <xsl:call-template name="inline.charseq"/>
 120       </xsl:attribute>
 121       <xsl:text>¶</xsl:text>
 122     </a>
 123   </h2>
 124 </xsl:template>
 125
 126 <xsl:template match="refsect2/title|refsect2/info/title">
 127   <h3>
 128     <xsl:attribute name="id">
 129       <xsl:call-template name="inline.charseq"/>
 130     </xsl:attribute>
 131     <xsl:apply-templates/>
 132     <a>
 133       <xsl:attribute name="class">
 134         <xsl:text>headerlink</xsl:text>
 135       </xsl:attribute>
 136       <xsl:attribute name="title">
 137         <xsl:text>Permalink to this headline</xsl:text>
 138       </xsl:attribute>
 139       <xsl:attribute name="href">
 140         <xsl:text>#</xsl:text>
 141         <xsl:call-template name="inline.charseq"/>
 142       </xsl:attribute>
 143       <xsl:text>¶</xsl:text>
 144     </a>
 145   </h3>
 146 </xsl:template>
 147
 148 <xsl:template match="varlistentry">
 149   <dt>
 150     <xsl:attribute name="id">
 151       <xsl:call-template name="inline.charseq">
 152         <xsl:with-param name="content">
 153           <xsl:copy-of select="term[position()=1]" />
 154         </xsl:with-param>
 155       </xsl:call-template>
 156     </xsl:attribute>
 157     <xsl:apply-templates select="term"/>
 158     <a>
 159       <xsl:attribute name="class">
 160         <xsl:text>headerlink</xsl:text>
 161       </xsl:attribute>
 162       <xsl:attribute name="title">
 163         <xsl:text>Permalink to this term</xsl:text>
 164       </xsl:attribute>
 165       <xsl:attribute name="href">
 166         <!--        <xsl:call-template name="href.target.uri" /> -->
 167         <xsl:text>#</xsl:text>
 168         <xsl:call-template name="inline.charseq">
 169           <xsl:with-param name="content">
 170             <xsl:copy-of select="term[position()=1]" />
 171           </xsl:with-param>
 172         </xsl:call-template>
 173       </xsl:attribute>
 174       <xsl:text>¶</xsl:text>
 175     </a>
 176   </dt>
 177   <dd>
 178     <xsl:apply-templates select="listitem"/>
 179   </dd>
 180 </xsl:template>
 181
 182
 183 <!-- add Index link at top of page -->
 184 <xsl:template name="user.header.content">
 185   <style>
 186     a.headerlink {
 187       color: #c60f0f;
 188       font-size: 0.8em;
 189       padding: 0 4px 0 4px;
 190       text-decoration: none;
 191       visibility: hidden;
 192     }
 193
 194     a.headerlink:hover {
 195       background-color: #c60f0f;
 196       color: white;
 197     }
 198
 199     h1:hover > a.headerlink, h2:hover > a.headerlink, h3:hover > a.headerlink, dt:hover > a.headerlink {
 200       visibility: visible;
 201     }
 202   </style>
 203
 204   <a>
 205     <xsl:attribute name="href">
 206       <xsl:text>index.html</xsl:text>
 207     </xsl:attribute>
 208     <xsl:text>Index </xsl:text>
 209   </a>·
 210   <a>
 211     <xsl:attribute name="href">
 212       <xsl:text>systemd.directives.html</xsl:text>
 213     </xsl:attribute>
 214     <xsl:text>Directives </xsl:text>
 215   </a>·
 216   <a>
 217     <xsl:attribute name="href">
 218       <xsl:text>../python-systemd/index.html</xsl:text>
 219     </xsl:attribute>
 220     <xsl:text>Python </xsl:text>
 221   </a>·
 222   <a>
 223     <xsl:attribute name="href">
 224       <xsl:text>../libudev/index.html</xsl:text>
 225     </xsl:attribute>
 226     <xsl:text>libudev </xsl:text>
 227   </a>·
 228   <a>
 229     <xsl:attribute name="href">
 230       <xsl:text>../libudev/index.html</xsl:text>
 231     </xsl:attribute>
 232     <xsl:text>gudev </xsl:text>
 233   </a>
 234
 235   <span style="float:right">
 236     <xsl:text>systemd </xsl:text>
 237     <xsl:value-of select="$systemd.version"/>
 238   </span>
 239   <hr/>
 240 </xsl:template>
 241
 242 <xsl:template match="literal">
 243   <xsl:text>"</xsl:text>
 244   <xsl:call-template name="inline.monoseq"/>
 245   <xsl:text>"</xsl:text>
 246 </xsl:template>
 247
 248 <!-- Switch things to UTF-8, ISO-8859-1 is soo yesteryear -->
 249 <xsl:output method="html" encoding="UTF-8" indent="no"/>
 250
 251 </xsl:stylesheet>