configure.ac

   1 #
   2 #  This file is part of systemd.
   3 #
   4 #  Copyright 2010-2012 Lennart Poettering
   5 #  Copyright 2010-2012 Kay Sievers
   6 #
   7 #  systemd is free software; you can redistribute it and/or modify it
   8 #  under the terms of the GNU Lesser General Public License as published by
   9 #  the Free Software Foundation; either version 2.1 of the License, or
  10 #  (at your option) any later version.
  11 #
  12 #  systemd is distributed in the hope that it will be useful, but
  13 #  WITHOUT ANY WARRANTY; without even the implied warranty of
  14 #  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
  15 #  Lesser General Public License for more details.
  16 #
  17 #  You should have received a copy of the GNU Lesser General Public License
  18 #  along with systemd; If not, see <http://www.gnu.org/licenses/>.
  19
  20 AC_PREREQ([2.64])
  21
  22 AC_INIT([systemd],
  23         [206],
  24         [http://bugs.freedesktop.org/enter_bug.cgi?product=systemd],
  25         [systemd],
  26         [http://www.freedesktop.org/wiki/Software/systemd])
  27
  28 AC_CONFIG_SRCDIR([src/core/main.c])
  29 AC_CONFIG_MACRO_DIR([m4])
  30 AC_CONFIG_HEADERS([config.h])
  31 AC_CONFIG_AUX_DIR([build-aux])
  32
  33 AC_USE_SYSTEM_EXTENSIONS
  34 AC_SYS_LARGEFILE
  35 AC_PREFIX_DEFAULT([/usr])
  36 AM_INIT_AUTOMAKE([foreign 1.11 -Wall -Wno-portability silent-rules tar-pax no-dist-gzip dist-xz subdir-objects check-news])
  37 AM_SILENT_RULES([yes])
  38 AC_CANONICAL_HOST
  39 AC_DEFINE_UNQUOTED([CANONICAL_HOST], "$host", [Canonical host string.])
  40 AS_IF([test "x$host_cpu" = "xmips" || test "x$host_cpu" = "xmipsel" ||
  41        test "x$host_cpu" = "xmips64" || test "x$host_cpu" = "xmips64el"],
  42       [AC_DEFINE(ARCH_MIPS, [], [Whether on mips arch])])
  43
  44 LT_PREREQ(2.2)
  45 LT_INIT([disable-static])
  46
  47 AS_IF([test "x$enable_static" = "xyes"], [AC_MSG_ERROR([--enable-static is not supported by systemd])])
  48 AS_IF([test "x$enable_largefile" = "xno"], [AC_MSG_ERROR([--disable-largefile is not supported by systemd])])
  49
  50 # i18n stuff for the PolicyKit policy files
  51 IT_PROG_INTLTOOL([0.40.0])
  52
  53 GETTEXT_PACKAGE=systemd
  54 AC_SUBST(GETTEXT_PACKAGE)
  55
  56 AC_PROG_MKDIR_P
  57 AC_PROG_LN_S
  58 AC_PROG_SED
  59 AC_PROG_GREP
  60 AC_PROG_AWK
  61
  62 AC_PROG_CC
  63 AC_PROG_CC_C99
  64 AM_PROG_CC_C_O
  65 AC_PROG_GCC_TRADITIONAL
  66
  67 AC_PATH_PROG([M4], [m4])
  68 AC_PATH_PROG([XSLTPROC], [xsltproc])
  69
  70 AC_PATH_PROG([QUOTAON], [quotaon], [/usr/sbin/quotaon])
  71 AC_PATH_PROG([QUOTACHECK], [quotacheck], [/usr/sbin/quotacheck])
  72
  73 AC_PATH_PROG([SETCAP], [setcap], [/usr/sbin/setcap])
  74
  75 AC_PATH_PROG([KILL], [kill], [/usr/bin/kill])
  76
  77 AC_PATH_PROG([KMOD], [kmod], [/usr/bin/kmod])
  78
  79 AC_PATH_PROG([KEXEC], [kexec], [/usr/sbin/kexec])
  80
  81 # gtkdocize greps for '^GTK_DOC_CHECK', so it needs to be on its own line
  82 m4_ifdef([GTK_DOC_CHECK], [
  83 GTK_DOC_CHECK([1.18],[--flavour no-tmpl])],
  84          [AM_CONDITIONAL([ENABLE_GTK_DOC], [false])
  85           enable_gtk_doc=no])
  86
  87 AS_IF([test "x$enable_gtk_doc" = "xyes" -a "x$XSLTPROC" = x], [
  88         AC_MSG_ERROR([*** GTK doc requested but xsltproc not found])
  89 ])
  90
  91 m4_ifdef([GOBJECT_INTROSPECTION_CHECK], [
  92 GOBJECT_INTROSPECTION_CHECK([1.31.1])
  93 ], [
  94    AM_CONDITIONAL([HAVE_INTROSPECTION], [false])
  95    enable_introspection=no])
  96
  97 AC_CHECK_TOOL(OBJCOPY, objcopy)
  98 AC_CHECK_TOOL(STRINGS, strings)
  99 AC_CHECK_TOOL(GPERF, gperf)
 100 if test -z "$GPERF" ; then
 101         AC_MSG_ERROR([*** gperf not found])
 102 fi
 103
 104 CC_CHECK_FLAGS_APPEND([with_cflags], [CFLAGS], [\
 105         -pipe \
 106         -Wall \
 107         -Wextra \
 108         -Wno-inline \
 109         -Wundef \
 110         "-Wformat=2 -Wformat-security -Wformat-nonliteral" \
 111         -Wlogical-op \
 112         -Wsign-compare \
 113         -Wmissing-include-dirs \
 114         -Wold-style-definition \
 115         -Wpointer-arith \
 116         -Winit-self \
 117         -Wdeclaration-after-statement \
 118         -Wfloat-equal \
 119         -Wmissing-prototypes \
 120         -Wstrict-prototypes \
 121         -Wredundant-decls \
 122         -Wmissing-declarations \
 123         -Wmissing-noreturn \
 124         -Wshadow \
 125         -Wendif-labels \
 126         -Wcast-align \
 127         -Wstrict-aliasing=2 \
 128         -Wwrite-strings \
 129         -Wno-long-long \
 130         -Wno-overlength-strings \
 131         -Wno-unused-parameter \
 132         -Wno-missing-field-initializers \
 133         -Wno-unused-result \
 134         -Werror=overflow \
 135         -ffast-math \
 136         -fno-common \
 137         -fdiagnostics-show-option \
 138         -fdiagnostics-color \
 139         -fno-strict-aliasing \
 140         -fvisibility=hidden \
 141         -ffunction-sections \
 142         -fdata-sections \
 143         -fstack-protector \
 144         --param=ssp-buffer-size=4])
 145 AC_SUBST([OUR_CFLAGS], $with_cflags)
 146
 147 AS_CASE([$CFLAGS], [*-O[[12345g\ ]]*],
 148         [CC_CHECK_FLAGS_APPEND([with_cppflags], [CPPFLAGS], [\
 149                -Wp,-D_FORTIFY_SOURCE=2])],
 150         [AC_MSG_RESULT([skipping -D_FORTIFY_SOURCE, optimization not enabled])])
 151 AC_SUBST([OUR_CPPFLAGS], $with_cppflags)
 152
 153 CC_CHECK_FLAGS_APPEND([with_ldflags], [LDFLAGS], [\
 154         -Wl,--as-needed \
 155         -Wl,--no-undefined \
 156         -Wl,--gc-sections \
 157         -Wl,-z,relro \
 158         -Wl,-z,now])
 159 AC_SUBST([OUR_LDFLAGS], $with_ldflags)
 160
 161 # ------------------------------------------------------------------------------
 162 # we use python to build the man page index, and for systemd-python
 163 have_python=no
 164 AC_ARG_WITH([python],
 165         [AS_HELP_STRING([--without-python], [Disable building the man page index and systemd-python (default: test)])])
 166
 167 AS_IF([test "x$with_python" != "xno"], [
 168         AM_PATH_PYTHON(,, [:])
 169         AS_IF([test "$PYTHON" != :], [have_python=yes])
 170 ])
 171 AM_CONDITIONAL([HAVE_PYTHON], [test "x$have_python" = "xyes"])
 172 AS_IF([test "x$PYTHON_BINARY" = "x"],
 173       [AS_IF([test "x$have_python" = "xyes"],
 174              [PYTHON_BINARY="$(which "$PYTHON")"],
 175              [PYTHON_BINARY=/usr/bin/python])])
 176 AC_ARG_VAR(PYTHON_BINARY, [Python binary used to launch installed scripts])
 177
 178 have_python_devel=no
 179 AC_ARG_ENABLE(python_devel, AS_HELP_STRING([--disable-python-devel], [Do not build python modules]))
 180 AS_IF([test "x$enable_python_devel" != "xno"], [
 181       PKG_CHECK_MODULES([PYTHON_DEVEL], [python-${PYTHON_VERSION}],
 182             [have_python_devel=yes],
 183             [PKG_CHECK_MODULES([PYTHON_DEVEL], [python],
 184                   [have_python_devel=yes],
 185                   [have_python_devel=no])])
 186       AS_IF([test "x$have_python_devel" = xno -a "x$enable_python_devel" = xyes],
 187             [AC_MSG_ERROR([*** python-devel support requested but libraries not found])])
 188 ])
 189 AM_CONDITIONAL([HAVE_PYTHON_DEVEL], [test "$have_python_devel" = "yes"])
 190
 191 # ------------------------------------------------------------------------------
 192
 193 AC_SEARCH_LIBS([mq_open], [rt], [], [AC_MSG_ERROR([*** POSIX RT library not found])])
 194 AC_SEARCH_LIBS([dlsym], [dl], [], [AC_MSG_ERROR([*** Dynamic linking loader library not found])])
 195
 196 save_LIBS="$LIBS"
 197 LIBS=
 198 AC_SEARCH_LIBS([cap_init], [cap], [], [AC_MSG_ERROR([*** POSIX caps library not found])])
 199 AC_CHECK_HEADERS([sys/capability.h], [], [AC_MSG_ERROR([*** POSIX caps headers not found])])
 200 CAP_LIBS="$LIBS"
 201 LIBS="$save_LIBS"
 202 AC_SUBST(CAP_LIBS)
 203
 204 AC_CHECK_FUNCS([fanotify_init fanotify_mark])
 205 AC_CHECK_FUNCS([__secure_getenv secure_getenv])
 206 AC_CHECK_DECLS([gettid, pivot_root, name_to_handle_at], [], [], [[#include <sys/types.h>
 207 #include <unistd.h>
 208 #include <sys/mount.h>
 209 #include <fcntl.h>]])
 210
 211 # This makes sure pkg.m4 is available.
 212 m4_pattern_forbid([^_?PKG_[A-Z_]+$],[*** pkg.m4 missing, please install pkg-config])
 213
 214 PKG_CHECK_MODULES(DBUS, [dbus-1 >= 1.3.2])
 215
 216 # ------------------------------------------------------------------------------
 217 have_coverage=no
 218 AC_ARG_ENABLE(coverage, AS_HELP_STRING([--enable-coverage], [enable test coverage]))
 219 if test "x$enable_coverage" = "xyes" ; then
 220         AC_CHECK_PROG(lcov_found, [lcov], [yes], [no])
 221         if test "x$lcov_found" = xno ; then
 222                 AC_MSG_ERROR([*** lcov support requested but the program was not found])
 223         else
 224                 lcov_version_major="`lcov --version | cut -d ' ' -f 4 | cut -d '.' -f 1`"
 225                 lcov_version_minor="`lcov --version | cut -d ' ' -f 4 | cut -d '.' -f 2`"
 226                 if test "$lcov_version_major" -eq 1 -a "$lcov_version_minor" -lt 10; then
 227                         AC_MSG_ERROR([*** lcov version is too old. 1.10 required])
 228                 else
 229                         have_coverage=yes
 230                         CC_CHECK_FLAGS_APPEND([with_coverage_cflags], [CFLAGS], [\
 231                         -fprofile-arcs \
 232                         -ftest-coverage])
 233                         AC_SUBST([OUR_CFLAGS], "$with_cflags $with_coverage_cflags")
 234                 fi
 235         fi
 236 fi
 237 AM_CONDITIONAL(ENABLE_COVERAGE, [test "$have_coverage" = "yes"])
 238
 239 # ------------------------------------------------------------------------------
 240 have_kmod=no
 241 AC_ARG_ENABLE(kmod, AS_HELP_STRING([--disable-kmod], [disable loadable modules support]))
 242 if test "x$enable_kmod" != "xno"; then
 243         PKG_CHECK_EXISTS([ libkmod ], have_kmod=yes, have_kmod=no)
 244         if test "x$have_kmod" = "xyes"; then
 245                 PKG_CHECK_MODULES(KMOD, [ libkmod >= 14 ],
 246                         [AC_DEFINE(HAVE_KMOD, 1, [Define if kmod is available])],
 247                         AC_MSG_ERROR([*** kmod version >= 14 not found]))
 248         fi
 249         if test "x$have_kmod" = xno -a "x$enable_kmod" = xyes; then
 250                 AC_MSG_ERROR([*** kmod support requested, but libraries not found])
 251         fi
 252 fi
 253 AM_CONDITIONAL(HAVE_KMOD, [test "$have_kmod" = "yes"])
 254
 255 # ------------------------------------------------------------------------------
 256 have_blkid=no
 257 AC_ARG_ENABLE(blkid, AS_HELP_STRING([--disable-blkid], [disable blkid support]))
 258 if test "x$enable_blkid" != "xno"; then
 259         PKG_CHECK_MODULES(BLKID, [ blkid >= 2.20 ],
 260                 [AC_DEFINE(HAVE_BLKID, 1, [Define if blkid is available]) have_blkid=yes], have_blkid=no)
 261         if test "x$have_blkid" = xno -a "x$enable_blkid" = xyes; then
 262                 AC_MSG_ERROR([*** blkid support requested but libraries not found])
 263         fi
 264 fi
 265 AM_CONDITIONAL(HAVE_BLKID, [test "$have_blkid" = "yes"])
 266
 267 # ------------------------------------------------------------------------------
 268 have_ima=yes
 269 AC_ARG_ENABLE([ima], AS_HELP_STRING([--disable-ima],[Disable optional IMA support]),
 270                 [case "${enableval}" in
 271                         yes) have_ima=yes ;;
 272                         no) have_ima=no ;;
 273                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-ima) ;;
 274                 esac],
 275                 [have_ima=yes])
 276
 277 if test "x${have_ima}" != xno ; then
 278         AC_DEFINE(HAVE_IMA, 1, [Define if IMA is available])
 279 fi
 280
 281 # ------------------------------------------------------------------------------
 282 have_chkconfig=yes
 283 AC_ARG_ENABLE([chkconfig], AS_HELP_STRING([--disable-chkconfig],[Disable optional chkconfig support]),
 284                 [case "${enableval}" in
 285                         yes) have_chkconfig=yes ;;
 286                         no) have_chkconfig=no ;;
 287                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-chkconfig) ;;
 288                 esac],
 289                 [AC_PATH_PROG(CHKCONFIG, chkconfig)
 290                 if test -z "$CHKCONFIG"; then
 291                         have_chkconfig=no
 292                 else
 293                         have_chkconfig=yes
 294                 fi])
 295
 296 if test "x${have_chkconfig}" != xno ; then
 297         AC_DEFINE(HAVE_CHKCONFIG, 1, [Define if CHKCONFIG is available])
 298 fi
 299
 300 # ------------------------------------------------------------------------------
 301 have_selinux=no
 302 AC_ARG_ENABLE(selinux, AS_HELP_STRING([--disable-selinux], [Disable optional SELINUX support]))
 303 if test "x$enable_selinux" != "xno"; then
 304         PKG_CHECK_MODULES([SELINUX], [libselinux >= 2.1.9],
 305                 [AC_DEFINE(HAVE_SELINUX, 1, [Define if SELinux is available]) have_selinux=yes], have_selinux=no)
 306         if test "x$have_selinux" = xno -a "x$enable_selinux" = xyes; then
 307                 AC_MSG_ERROR([*** SELinux support requested but libraries not found])
 308         fi
 309 fi
 310 AM_CONDITIONAL(HAVE_SELINUX, [test "$have_selinux" = "yes"])
 311
 312 AC_ARG_WITH(debug-shell,
 313         AS_HELP_STRING([--with-debug-shell=PATH],
 314                 [Path to debug shell binary]),
 315         [SUSHELL="$withval"],[
 316         AS_IF([test "x${have_selinux}" != "xno"], [SUSHELL="/sbin/sushell"] , [SUSHELL="/bin/sh"])])
 317
 318 AC_SUBST(SUSHELL)
 319
 320 AC_ARG_WITH([debug-tty],
 321         AS_HELP_STRING([--with-debug-tty=PATH],
 322                 [Specify the tty device for debug shell]),
 323         [DEBUGTTY="$withval"],
 324         [DEBUGTTY=/dev/tty9])
 325
 326 AC_SUBST(DEBUGTTY)
 327
 328 # ------------------------------------------------------------------------------
 329 have_xz=no
 330 AC_ARG_ENABLE(xz, AS_HELP_STRING([--disable-xz], [Disable optional XZ support]))
 331 if test "x$enable_xz" != "xno"; then
 332         PKG_CHECK_MODULES(XZ, [ liblzma ],
 333                 [AC_DEFINE(HAVE_XZ, 1, [Define if XZ is available]) have_xz=yes], have_xz=no)
 334         if test "x$have_xz" = xno -a "x$enable_xz" = xyes; then
 335                 AC_MSG_ERROR([*** Xz support requested but libraries not found])
 336         fi
 337 fi
 338 AM_CONDITIONAL(HAVE_XZ, [test "$have_xz" = "yes"])
 339
 340 # ------------------------------------------------------------------------------
 341 AC_ARG_ENABLE([tcpwrap],
 342         AS_HELP_STRING([--disable-tcpwrap],[Disable optional TCP wrappers support]),
 343                 [case "${enableval}" in
 344                         yes) have_tcpwrap=yes ;;
 345                         no) have_tcpwrap=no ;;
 346                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-tcpwrap) ;;
 347                 esac],
 348                 [have_tcpwrap=auto])
 349
 350 if test "x${have_tcpwrap}" != xno ; then
 351         ACX_LIBWRAP
 352         if test "x${LIBWRAP_LIBS}" = x ; then
 353                 if test "x$have_tcpwrap" = xyes ; then
 354                         AC_MSG_ERROR([*** TCP wrappers support not found.])
 355                 fi
 356                 have_tcpwrap=no
 357         else
 358                 have_tcpwrap=yes
 359         fi
 360 else
 361         LIBWRAP_LIBS=
 362 fi
 363 AC_SUBST(LIBWRAP_LIBS)
 364
 365 # ------------------------------------------------------------------------------
 366 AC_ARG_ENABLE([pam],
 367         AS_HELP_STRING([--disable-pam],[Disable optional PAM support]),
 368                 [case "${enableval}" in
 369                         yes) have_pam=yes ;;
 370                         no) have_pam=no ;;
 371                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-pam) ;;
 372                 esac],
 373                 [have_pam=auto])
 374
 375 if test "x${have_pam}" != xno ; then
 376         AC_CHECK_HEADERS(
 377                 [security/pam_modules.h security/pam_modutil.h security/pam_ext.h],
 378                 [have_pam=yes],
 379                 [if test "x$have_pam" = xyes ; then
 380                         AC_MSG_ERROR([*** PAM headers not found.])
 381                 fi])
 382
 383         AC_CHECK_LIB(
 384                 [pam],
 385                 [pam_syslog],
 386                 [have_pam=yes],
 387                 [if test "x$have_pam" = xyes ; then
 388                         AC_MSG_ERROR([*** libpam not found.])
 389                 fi])
 390
 391         if test "x$have_pam" = xyes ; then
 392                 PAM_LIBS="-lpam -lpam_misc"
 393                 AC_DEFINE(HAVE_PAM, 1, [PAM available])
 394         else
 395                 have_pam=no
 396         fi
 397 else
 398         PAM_LIBS=
 399 fi
 400 AC_SUBST(PAM_LIBS)
 401 AM_CONDITIONAL([HAVE_PAM], [test "x$have_pam" != xno])
 402
 403 # ------------------------------------------------------------------------------
 404 AC_ARG_ENABLE([acl],
 405         AS_HELP_STRING([--disable-acl],[Disable optional ACL support]),
 406                 [case "${enableval}" in
 407                         yes) have_acl=yes ;;
 408                         no) have_acl=no ;;
 409                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-acl) ;;
 410                 esac],
 411                 [have_acl=auto])
 412
 413 if test "x${have_acl}" != xno ; then
 414         AC_CHECK_HEADERS(
 415                 [sys/acl.h acl/libacl.h],
 416                 [have_acl=yes],
 417                 [if test "x$have_acl" = xyes ; then
 418                         AC_MSG_ERROR([*** ACL headers not found.])
 419                 fi])
 420
 421         AC_CHECK_LIB(
 422                 [acl],
 423                 [acl_get_file],
 424                 [have_acl=yes],
 425                 [if test "x$have_acl" = xyes ; then
 426                         AC_MSG_ERROR([*** libacl not found.])
 427                 fi])
 428
 429         if test "x$have_acl" = xyes ; then
 430                 ACL_LIBS="-lacl"
 431                 AC_DEFINE(HAVE_ACL, 1, [ACL available])
 432         else
 433                 have_acl=no
 434         fi
 435 else
 436         ACL_LIBS=
 437 fi
 438 AC_SUBST(ACL_LIBS)
 439 AM_CONDITIONAL([HAVE_ACL], [test "x$have_acl" != xno])
 440
 441 # ------------------------------------------------------------------------------
 442 AC_ARG_ENABLE([xattr],
 443         AS_HELP_STRING([--disable-xattr],[Disable optional XATTR support]),
 444                 [case "${enableval}" in
 445                         yes) have_xattr=yes ;;
 446                         no) have_xattr=no ;;
 447                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-xattr) ;;
 448                 esac],
 449                 [have_xattr=auto])
 450
 451 if test "x${have_xattr}" != xno ; then
 452         AC_CHECK_HEADERS(
 453                 [attr/xattr.h],
 454                 [have_xattr=yes],
 455                 [if test "x$have_xattr" = xyes ; then
 456                         AC_MSG_ERROR([*** XATTR headers not found.])
 457                 fi])
 458
 459         AC_CHECK_LIB(
 460                 [attr],
 461                 [fsetxattr],
 462                 [have_xattr=yes],
 463                 [if test "x$have_xattr" = xyes ; then
 464                         AC_MSG_ERROR([*** libattr not found.])
 465                 fi])
 466
 467         if test "x$have_xattr" = xyes ; then
 468                 XATTR_LIBS="-lattr"
 469                 AC_DEFINE(HAVE_XATTR, 1, [XATTR available])
 470         else
 471                 have_xattr=no
 472         fi
 473 else
 474         XATTR_LIBS=
 475 fi
 476 AC_SUBST(XATTR_LIBS)
 477 AM_CONDITIONAL([HAVE_XATTR], [test "x$have_xattr" != xno])
 478
 479 # ------------------------------------------------------------------------------
 480 AC_ARG_ENABLE([smack], AS_HELP_STRING([--disable-smack],[Disable optional SMACK support]),
 481                 [case "${enableval}" in
 482                         yes) have_smack=yes ;;
 483                         no) have_smack=no ;;
 484                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-smack) ;;
 485                 esac],
 486                 [have_smack=auto])
 487
 488 if test "x${have_xattr}" = xno; then
 489         if test "x${have_smack}" = xyes; then
 490                 AC_MSG_ERROR(SMACK requires xattr support)
 491         else
 492                 have_smack=no
 493         fi
 494 else
 495         if test "x${have_smack}" = xauto; then
 496                 have_smack=yes
 497         fi
 498 fi
 499
 500 if test "x${have_smack}" = xyes ; then
 501         AC_DEFINE(HAVE_SMACK, 1, [Define if SMACK is available])
 502 fi
 503
 504 # ------------------------------------------------------------------------------
 505 AC_ARG_ENABLE([gcrypt],
 506         AS_HELP_STRING([--disable-gcrypt],[Disable optional GCRYPT support]),
 507                 [case "${enableval}" in
 508                         yes) have_gcrypt=yes ;;
 509                         no) have_gcrypt=no ;;
 510                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-gcrypt) ;;
 511                 esac],
 512                 [have_gcrypt=auto])
 513
 514 if test "x${have_gcrypt}" != xno ; then
 515         AM_PATH_LIBGCRYPT(
 516                 [1.4.5],
 517                 [have_gcrypt=yes],
 518                 [if test "x$have_gcrypt" = xyes ; then
 519                         AC_MSG_ERROR([*** GCRYPT headers not found.])
 520                 fi])
 521
 522         if test "x$have_gcrypt" = xyes ; then
 523                 GCRYPT_LIBS="$LIBGCRYPT_LIBS"
 524                 GCRYPT_CFLAGS="$LIBGCRYPT_CFLAGS"
 525                 AC_DEFINE(HAVE_GCRYPT, 1, [GCRYPT available])
 526         else
 527                 have_gcrypt=no
 528         fi
 529 else
 530         GCRYPT_LIBS=
 531         GCRYPT_CFLAGS=
 532 fi
 533 AC_SUBST(GCRYPT_LIBS)
 534 AC_SUBST(GCRYPT_CFLAGS)
 535 AM_CONDITIONAL([HAVE_GCRYPT], [test "x$have_gcrypt" != xno])
 536
 537 # ------------------------------------------------------------------------------
 538 AC_ARG_ENABLE([audit],
 539         AS_HELP_STRING([--disable-audit],[Disable optional AUDIT support]),
 540                 [case "${enableval}" in
 541                         yes) have_audit=yes ;;
 542                         no) have_audit=no ;;
 543                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-audit) ;;
 544                 esac],
 545                 [have_audit=auto])
 546
 547 if test "x${have_audit}" != xno ; then
 548         AC_CHECK_HEADERS(
 549                 [libaudit.h],
 550                 [have_audit=yes],
 551                 [if test "x$have_audit" = xyes ; then
 552                         AC_MSG_ERROR([*** AUDIT headers not found.])
 553                 fi])
 554
 555         AC_CHECK_LIB(
 556                 [audit],
 557                 [audit_open],
 558                 [have_audit=yes],
 559                 [if test "x$have_audit" = xyes ; then
 560                         AC_MSG_ERROR([*** libaudit not found.])
 561                 fi])
 562
 563         if test "x$have_audit" = xyes ; then
 564                 AUDIT_LIBS="-laudit"
 565                 AC_DEFINE(HAVE_AUDIT, 1, [AUDIT available])
 566         else
 567                 have_audit=no
 568         fi
 569 else
 570         AUDIT_LIBS=
 571 fi
 572 AC_SUBST(AUDIT_LIBS)
 573
 574 # ------------------------------------------------------------------------------
 575 have_libcryptsetup=no
 576 AC_ARG_ENABLE(libcryptsetup, AS_HELP_STRING([--disable-libcryptsetup], [disable libcryptsetup tools]))
 577 if test "x$enable_libcryptsetup" != "xno"; then
 578         PKG_CHECK_MODULES(LIBCRYPTSETUP, [ libcryptsetup >= 1.6.0 ],
 579                 [AC_DEFINE(HAVE_LIBCRYPTSETUP, 1, [Define if libcryptsetup is available]) have_libcryptsetup=yes], have_libcryptsetup=no)
 580         if test "x$have_libcryptsetup" = xno -a "x$enable_libcryptsetup" = xyes; then
 581                 AC_MSG_ERROR([*** libcryptsetup support requested but libraries not found])
 582         fi
 583 fi
 584 AM_CONDITIONAL(HAVE_LIBCRYPTSETUP, [test "$have_libcryptsetup" = "yes"])
 585
 586 # ------------------------------------------------------------------------------
 587 have_qrencode=no
 588 AC_ARG_ENABLE(qrencode, AS_HELP_STRING([--disable-qrencode], [disable qrencode support]))
 589 if test "x$enable_qrencode" != "xno"; then
 590         PKG_CHECK_MODULES(QRENCODE, [ libqrencode ],
 591                 [AC_DEFINE(HAVE_QRENCODE, 1, [Define if qrencode is available]) have_qrencode=yes], have_qrencode=no)
 592         if test "x$have_qrencode" = xno -a "x$enable_qrencode" = xyes; then
 593                 AC_MSG_ERROR([*** qrencode support requested but libraries not found])
 594         fi
 595 fi
 596 AM_CONDITIONAL(HAVE_QRENCODE, [test "$have_qrencode" = "yes"])
 597
 598 # ------------------------------------------------------------------------------
 599 have_microhttpd=no
 600 AC_ARG_ENABLE(microhttpd, AS_HELP_STRING([--disable-microhttpd], [disable microhttpd support]))
 601 if test "x$enable_microhttpd" != "xno"; then
 602         PKG_CHECK_MODULES(MICROHTTPD, [libmicrohttpd >= 0.9.5],
 603                 [AC_DEFINE(HAVE_MICROHTTPD, 1, [Define if microhttpd is available]) have_microhttpd=yes], have_microhttpd=no)
 604         if test "x$have_microhttpd" = xno -a "x$enable_microhttpd" = xyes; then
 605                 AC_MSG_ERROR([*** microhttpd support requested but libraries not found])
 606         fi
 607 fi
 608 AM_CONDITIONAL(HAVE_MICROHTTPD, [test "$have_microhttpd" = "yes"])
 609
 610 # ------------------------------------------------------------------------------
 611 have_binfmt=no
 612 AC_ARG_ENABLE(binfmt, AS_HELP_STRING([--disable-binfmt], [disable binfmt tool]))
 613 if test "x$enable_binfmt" != "xno"; then
 614         have_binfmt=yes
 615 fi
 616 AM_CONDITIONAL(ENABLE_BINFMT, [test "$have_binfmt" = "yes"])
 617
 618 # ------------------------------------------------------------------------------
 619 have_vconsole=no
 620 AC_ARG_ENABLE(vconsole, AS_HELP_STRING([--disable-vconsole], [disable vconsole tool]))
 621 if test "x$enable_vconsole" != "xno"; then
 622         have_vconsole=yes
 623 fi
 624 AM_CONDITIONAL(ENABLE_VCONSOLE, [test "$have_vconsole" = "yes"])
 625
 626 # ------------------------------------------------------------------------------
 627 have_readahead=no
 628 AC_ARG_ENABLE(readahead, AS_HELP_STRING([--disable-readahead], [disable readahead tools]))
 629 if test "x$enable_readahead" != "xno"; then
 630         have_readahead=yes
 631 fi
 632 AM_CONDITIONAL(ENABLE_READAHEAD, [test "$have_readahead" = "yes"])
 633
 634 # ------------------------------------------------------------------------------
 635 have_bootchart=no
 636 AC_ARG_ENABLE(bootchart, AS_HELP_STRING([--disable-bootchart], [disable bootchart tool]))
 637 if test "x$enable_bootchart" != "xno"; then
 638         have_bootchart=yes
 639 fi
 640 AM_CONDITIONAL(ENABLE_BOOTCHART, [test "$have_bootchart" = "yes"])
 641
 642 # ------------------------------------------------------------------------------
 643 have_quotacheck=no
 644 AC_ARG_ENABLE(quotacheck, AS_HELP_STRING([--disable-quotacheck], [disable quotacheck tools]))
 645 if test "x$enable_quotacheck" != "xno"; then
 646         have_quotacheck=yes
 647 fi
 648 AM_CONDITIONAL(ENABLE_QUOTACHECK, [test "$have_quotacheck" = "yes"])
 649
 650 # ------------------------------------------------------------------------------
 651 have_tmpfiles=no
 652 AC_ARG_ENABLE(tmpfiles, AS_HELP_STRING([--disable-tmpfiles], [disable tmpfiles support]))
 653 if test "x$enable_tmpfiles" != "xno"; then
 654         have_tmpfiles=yes
 655 fi
 656 AM_CONDITIONAL(ENABLE_TMPFILES, [test "$have_tmpfiles" = "yes"])
 657
 658 # ------------------------------------------------------------------------------
 659 have_randomseed=no
 660 AC_ARG_ENABLE(randomseed, AS_HELP_STRING([--disable-randomseed], [disable randomseed tools]))
 661 if test "x$enable_randomseed" != "xno"; then
 662         have_randomseed=yes
 663 fi
 664 AM_CONDITIONAL(ENABLE_RANDOMSEED, [test "$have_randomseed" = "yes"])
 665
 666 # ------------------------------------------------------------------------------
 667 have_logind=no
 668 AC_ARG_ENABLE(logind, AS_HELP_STRING([--disable-logind], [disable login daemon]))
 669 if test "x$enable_logind" != "xno"; then
 670         have_logind=yes
 671 fi
 672 AM_CONDITIONAL(ENABLE_LOGIND, [test "$have_logind" = "yes"])
 673 AS_IF([test "$have_logind" = "yes"], [ AC_DEFINE(HAVE_LOGIND, [1], [Logind support available]) ])
 674
 675 # ------------------------------------------------------------------------------
 676 have_machined=no
 677 AC_ARG_ENABLE(machined, AS_HELP_STRING([--disable-machined], [disable machine daemon]))
 678 if test "x$enable_machined" != "xno"; then
 679         have_machined=yes
 680 fi
 681 AM_CONDITIONAL(ENABLE_MACHINED, [test "$have_machined" = "yes"])
 682 AS_IF([test "$have_machined" = "yes"], [ AC_DEFINE(HAVE_MACHINED, [1], [Machined support available]) ])
 683
 684 # ------------------------------------------------------------------------------
 685 have_hostnamed=no
 686 AC_ARG_ENABLE(hostnamed, AS_HELP_STRING([--disable-hostnamed], [disable hostname daemon]))
 687 if test "x$enable_hostnamed" != "xno"; then
 688         have_hostnamed=yes
 689 fi
 690 AM_CONDITIONAL(ENABLE_HOSTNAMED, [test "$have_hostnamed" = "yes"])
 691
 692 # ------------------------------------------------------------------------------
 693 have_timedated=no
 694 AC_ARG_ENABLE(timedated, AS_HELP_STRING([--disable-timedated], [disable timedate daemon]))
 695 if test "x$enable_timedated" != "xno"; then
 696         have_timedated=yes
 697 fi
 698 AM_CONDITIONAL(ENABLE_TIMEDATED, [test "$have_timedated" = "yes"])
 699
 700 # ------------------------------------------------------------------------------
 701 have_localed=no
 702 AC_ARG_ENABLE(localed, AS_HELP_STRING([--disable-localed], [disable locale daemon]))
 703 if test "x$enable_localed" != "xno"; then
 704         have_localed=yes
 705 fi
 706 AM_CONDITIONAL(ENABLE_LOCALED, [test "$have_localed" = "yes"])
 707
 708 # ------------------------------------------------------------------------------
 709 have_coredump=no
 710 AC_ARG_ENABLE(coredump, AS_HELP_STRING([--disable-coredump], [disable coredump hook]))
 711 if test "x$enable_coredump" != "xno"; then
 712         have_coredump=yes
 713 fi
 714 AM_CONDITIONAL(ENABLE_COREDUMP, [test "$have_coredump" = "yes"])
 715
 716 # ------------------------------------------------------------------------------
 717 have_polkit=no
 718 AC_ARG_ENABLE(polkit, AS_HELP_STRING([--disable-polkit], [disable PolicyKit support]))
 719 if test "x$enable_polkit" != "xno"; then
 720         AC_DEFINE(ENABLE_POLKIT, 1, [Define if PolicyKit support is to be enabled])
 721         have_polkit=yes
 722 fi
 723 AM_CONDITIONAL(ENABLE_POLKIT, [test "x$have_polkit" = "xyes"])
 724
 725 # ------------------------------------------------------------------------------
 726 have_efi=no
 727 AC_ARG_ENABLE(efi, AS_HELP_STRING([--disable-efi], [disable EFI support]))
 728 if test "x$enable_efi" != "xno"; then
 729         AC_DEFINE(ENABLE_EFI, 1, [Define if EFI support is to be enabled])
 730         have_efi=yes
 731 fi
 732 AM_CONDITIONAL(ENABLE_EFI, [test "x$have_efi" = "xyes"])
 733
 734 # ------------------------------------------------------------------------------
 735 AC_ARG_WITH(rc-local-script-path-start,
 736         AS_HELP_STRING([--with-rc-local-script-path-start=PATH],
 737                 [Path to /etc/rc.local]),
 738         [RC_LOCAL_SCRIPT_PATH_START="$withval"],
 739         [RC_LOCAL_SCRIPT_PATH_START="/etc/rc.local"])
 740
 741 AC_ARG_WITH(rc-local-script-path-stop,
 742         AS_HELP_STRING([--with-rc-local-script-path-stop=PATH],
 743                 [Path to /usr/sbin/halt.local]),
 744         [RC_LOCAL_SCRIPT_PATH_STOP="$withval"],
 745         [RC_LOCAL_SCRIPT_PATH_STOP="/usr/sbin/halt.local"])
 746
 747 AC_DEFINE_UNQUOTED(RC_LOCAL_SCRIPT_PATH_START, ["$RC_LOCAL_SCRIPT_PATH_START"], [Path of /etc/rc.local script])
 748 AC_DEFINE_UNQUOTED(RC_LOCAL_SCRIPT_PATH_STOP, ["$RC_LOCAL_SCRIPT_PATH_STOP"], [Path of /usr/sbin/halt.local script])
 749
 750 AC_SUBST(RC_LOCAL_SCRIPT_PATH_START)
 751 AC_SUBST(RC_LOCAL_SCRIPT_PATH_STOP)
 752
 753 # ------------------------------------------------------------------------------
 754 AC_ARG_WITH(kbd-loadkeys,
 755         AS_HELP_STRING([--with-kbd-loadkeys=PATH],
 756                 [Path to loadkeys]),
 757         [KBD_LOADKEYS="$withval"],
 758         [KBD_LOADKEYS="/usr/bin/loadkeys"])
 759
 760 AC_ARG_WITH(kbd-setfont,
 761         AS_HELP_STRING([--with-kbd-setfont=PATH],
 762                 [Path to setfont]),
 763         [KBD_SETFONT="$withval"],
 764         [KBD_SETFONT="/usr/bin/setfont"])
 765
 766 AC_DEFINE_UNQUOTED(KBD_LOADKEYS, ["$KBD_LOADKEYS"], [Path of loadkeys])
 767 AC_DEFINE_UNQUOTED(KBD_SETFONT, ["$KBD_SETFONT"], [Path of setfont])
 768
 769 AC_SUBST(KBD_LOADKEYS)
 770 AC_SUBST(KBD_SETFONT)
 771
 772 AC_ARG_WITH(telinit,
 773         AS_HELP_STRING([--with-telinit=PATH],
 774                 [Path to telinit]),
 775         [TELINIT="$withval"],
 776         [TELINIT="/lib/upstart/telinit"])
 777
 778 AC_DEFINE_UNQUOTED(TELINIT, ["$TELINIT"], [Path to telinit])
 779
 780 AC_SUBST(TELINIT)
 781
 782 AC_CHECK_HEADERS_ONCE([valgrind/memcheck.h])
 783
 784 # ------------------------------------------------------------------------------
 785 have_myhostname=no
 786 AC_ARG_ENABLE(myhostname, AS_HELP_STRING([--disable-myhostname], [disable nss-myhostname support]))
 787 if test "x$enable_myhostname" != "xno"; then
 788         AC_HEADER_STDC
 789         AC_CHECK_HEADERS([arpa/inet.h fcntl.h inttypes.h netdb.h netinet/in.h stdlib.h string.h sys/socket.h sys/time.h unistd.h nss.h sys/ioctl.h])
 790
 791         AC_C_CONST
 792         AC_TYPE_SIZE_T
 793         AC_HEADER_TIME
 794
 795         AC_FUNC_MALLOC
 796         AC_FUNC_SELECT_ARGTYPES
 797         AC_CHECK_FUNCS([gethostbyaddr gethostbyname gettimeofday inet_ntoa memset select socket strcspn strdup strerror strncasecmp strcasecmp strspn])
 798
 799         have_myhostname=yes
 800 fi
 801 AM_CONDITIONAL(HAVE_MYHOSTNAME, [test "$have_myhostname" = "yes"])
 802
 803 # ------------------------------------------------------------------------------
 804 AC_ARG_WITH(firmware-path,
 805        AS_HELP_STRING([--with-firmware-path=DIR[[[:DIR[...]]]]],
 806           [Firmware search path (default="")]),
 807        [], [with_firmware_path=""])
 808 OLD_IFS=$IFS
 809 IFS=:
 810 for i in $with_firmware_path; do
 811        if test "x${FIRMWARE_PATH}" = "x"; then
 812               FIRMWARE_PATH="\\\"${i}/\\\""
 813        else
 814               FIRMWARE_PATH="${FIRMWARE_PATH}, \\\"${i}/\\\""
 815        fi
 816 done
 817 IFS=$OLD_IFS
 818 AC_SUBST(FIRMWARE_PATH)
 819 AS_IF([test "x${FIRMWARE_PATH}" != "x"], [ AC_DEFINE(HAVE_FIRMWARE, 1, [Define if FIRMWARE is available]) ])
 820 AM_CONDITIONAL(ENABLE_FIRMWARE, [test "x${FIRMWARE_PATH}" != "x"])
 821
 822 # ------------------------------------------------------------------------------
 823 AC_ARG_ENABLE([gudev],
 824        AS_HELP_STRING([--disable-gudev], [disable Gobject libudev support @<:@default=enabled@:>@]),
 825        [], [enable_gudev=yes])
 826 AS_IF([test "x$enable_gudev" = "xyes"], [ PKG_CHECK_MODULES([GLIB], [glib-2.0 >= 2.22.0 gobject-2.0 >= 2.22.0 gio-2.0]) ])
 827 AM_CONDITIONAL([ENABLE_GUDEV], [test "x$enable_gudev" = "xyes"])
 828 AS_IF([test "x$enable_gudev" = "xyes"], [ AC_DEFINE(HAVE_GLIB, 1, [Define if glib is available]) ])
 829
 830 # ------------------------------------------------------------------------------
 831 have_manpages=no
 832 AC_ARG_ENABLE(manpages, AS_HELP_STRING([--disable-manpages], [disable manpages]))
 833 AS_IF([test "x$enable_manpages" != xno], [
 834         AS_IF([test "x$enable_manpages" = xyes -a "x$XSLTPROC" = x], [
 835                 AC_MSG_ERROR([*** Manpages requested but xsltproc not found])
 836         ])
 837         AS_IF([test "x$XSLTPROC" != x], [have_manpages=yes])
 838 ])
 839 AM_CONDITIONAL(ENABLE_MANPAGES, [test "x$have_manpages" = "xyes"])
 840
 841 # ------------------------------------------------------------------------------
 842
 843 # Location of the init scripts as mandated by LSB
 844 SYSTEM_SYSVINIT_PATH=/etc/init.d
 845 SYSTEM_SYSVRCND_PATH=/etc/rc.d
 846 M4_DEFINES=
 847
 848 AC_ARG_WITH([sysvinit-path],
 849         [AS_HELP_STRING([--with-sysvinit-path=PATH],
 850                 [Specify the path to where the SysV init scripts are located])],
 851         [SYSTEM_SYSVINIT_PATH="$withval"],
 852         [])
 853
 854 AC_ARG_WITH([sysvrcnd-path],
 855         [AS_HELP_STRING([--with-sysvrcnd-path=PATH],
 856                 [Specify the path to the base directory for the SysV rcN.d directories])],
 857         [SYSTEM_SYSVRCND_PATH="$withval"],
 858         [])
 859
 860 if test "x${SYSTEM_SYSVINIT_PATH}" != "x" -a "x${SYSTEM_SYSVRCND_PATH}" != "x"; then
 861         AC_DEFINE(HAVE_SYSV_COMPAT, [], [SysV init scripts and rcN.d links are supported.])
 862         SYSTEM_SYSV_COMPAT="yes"
 863         M4_DEFINES="$M4_DEFINES -DHAVE_SYSV_COMPAT"
 864 elif test "x${SYSTEM_SYSVINIT_PATH}" != "x" -o "x${SYSTEM_SYSVRCND_PATH}" != "x"; then
 865         AC_MSG_ERROR([*** You need both --with-sysvinit-path=PATH and --with-sysvrcnd-path=PATH to enable SysV compatibility support, or both empty to disable it.])
 866 else
 867         SYSTEM_SYSV_COMPAT="no"
 868 fi
 869
 870 AC_SUBST(SYSTEM_SYSVINIT_PATH)
 871 AC_SUBST(SYSTEM_SYSVRCND_PATH)
 872 AC_SUBST(M4_DEFINES)
 873
 874 AM_CONDITIONAL(HAVE_SYSV_COMPAT, test "$SYSTEM_SYSV_COMPAT" = "yes")
 875
 876 AC_ARG_WITH([tty-gid],
 877         [AS_HELP_STRING([--with-tty-gid=GID],
 878                 [Specify the numeric GID of the 'tty' group])],
 879         [AC_DEFINE_UNQUOTED(TTY_GID, [$withval], [GID of the 'tty' group])],
 880         [])
 881
 882 AC_ARG_WITH([dbuspolicydir],
 883         AS_HELP_STRING([--with-dbuspolicydir=DIR], [D-Bus policy directory]),
 884         [],
 885         [with_dbuspolicydir=$($PKG_CONFIG --variable=sysconfdir dbus-1)/dbus-1/system.d])
 886
 887 AC_ARG_WITH([dbussessionservicedir],
 888         AS_HELP_STRING([--with-dbussessionservicedir=DIR], [D-Bus session service directory]),
 889         [],
 890         [with_dbussessionservicedir=$($PKG_CONFIG --variable=session_bus_services_dir dbus-1)])
 891
 892 AC_ARG_WITH([dbussystemservicedir],
 893         AS_HELP_STRING([--with-dbussystemservicedir=DIR], [D-Bus system service directory]),
 894         [],
 895         [with_dbussystemservicedir=$(readlink -m $($PKG_CONFIG --variable=session_bus_services_dir dbus-1)/../system-services)])
 896
 897 AC_ARG_WITH([dbusinterfacedir],
 898         AS_HELP_STRING([--with-dbusinterfacedir=DIR], [D-Bus interface directory]),
 899         [],
 900         [with_dbusinterfacedir=$(readlink -m $($PKG_CONFIG --variable=session_bus_services_dir dbus-1)/../interfaces)])
 901
 902 AC_ARG_WITH([bashcompletiondir],
 903         AS_HELP_STRING([--with-bashcompletiondir=DIR], [Bash completions directory]),
 904         [],
 905         [AS_IF([$($PKG_CONFIG --exists bash-completion)], [
 906                 with_bashcompletiondir=$($PKG_CONFIG --variable=completionsdir bash-completion)
 907         ] , [
 908                 with_bashcompletiondir=${datadir}/bash-completion/completions
 909         ])])
 910
 911 AC_ARG_WITH([rootprefix],
 912         AS_HELP_STRING([--with-rootprefix=DIR], [rootfs directory prefix for config files and kernel modules]),
 913         [], [with_rootprefix=${ac_default_prefix}])
 914
 915 AC_ARG_WITH([rootlibdir],
 916         AS_HELP_STRING([--with-rootlibdir=DIR], [Root directory for libraries necessary for boot]),
 917         [],
 918         [with_rootlibdir=${libdir}])
 919
 920 AC_ARG_WITH([pamlibdir],
 921         AS_HELP_STRING([--with-pamlibdir=DIR], [Directory for PAM modules]),
 922         [],
 923         [with_pamlibdir=${with_rootlibdir}/security])
 924
 925 AC_ARG_ENABLE([split-usr],
 926         AS_HELP_STRING([--enable-split-usr], [Assume that /bin, /sbin aren\'t symlinks into /usr]),
 927         [],
 928         [AS_IF([test "x${ac_default_prefix}" != "x${with_rootprefix}"], [
 929                 enable_split_usr=yes
 930         ], [
 931                 enable_split_usr=no
 932         ])])
 933
 934 AS_IF([test "x${enable_split_usr}" = "xyes"], [
 935         AC_DEFINE(HAVE_SPLIT_USR, 1, [Define if /bin, /sbin aren't symlinks into /usr])
 936 ])
 937
 938 # Work around intltoolize and gtk-doc problems in VPATH builds
 939 AM_CONDITIONAL([ENABLE_GTK_DOC_TESTS], [test "x$0" = "x./configure"],
 940                                        [Define to do gtk-doc tests])
 941 AS_IF([test "x$0" != "x./configure"], [
 942         AC_SUBST([INTLTOOL_UPDATE], [/bin/true])
 943 ])
 944
 945 AC_ARG_ENABLE(tests,
 946        [AC_HELP_STRING([--disable-tests], [disable tests])],
 947        enable_tests=$enableval, enable_tests=yes)
 948 AM_CONDITIONAL(ENABLE_TESTS, [test x$enable_tests = xyes])
 949
 950 AC_SUBST([dbuspolicydir], [$with_dbuspolicydir])
 951 AC_SUBST([dbussessionservicedir], [$with_dbussessionservicedir])
 952 AC_SUBST([dbussystemservicedir], [$with_dbussystemservicedir])
 953 AC_SUBST([dbusinterfacedir], [$with_dbusinterfacedir])
 954 AC_SUBST([bashcompletiondir], [$with_bashcompletiondir])
 955 AC_SUBST([pamlibdir], [$with_pamlibdir])
 956 AC_SUBST([rootprefix], [$with_rootprefix])
 957 AC_SUBST([rootlibdir], [$with_rootlibdir])
 958
 959 AC_CONFIG_FILES([
 960         Makefile po/Makefile.in
 961         docs/libudev/Makefile
 962         docs/libudev/version.xml
 963         docs/gudev/Makefile
 964         docs/gudev/version.xml
 965 ])
 966
 967 AC_OUTPUT
 968 AC_MSG_RESULT([
 969         $PACKAGE_NAME $VERSION
 970
 971         libcryptsetup:           ${have_libcryptsetup}
 972         tcpwrap:                 ${have_tcpwrap}
 973         PAM:                     ${have_pam}
 974         AUDIT:                   ${have_audit}
 975         IMA:                     ${have_ima}
 976         SELinux:                 ${have_selinux}
 977         SMACK:                   ${have_smack}
 978         XZ:                      ${have_xz}
 979         ACL:                     ${have_acl}
 980         XATTR:                   ${have_xattr}
 981         GCRYPT:                  ${have_gcrypt}
 982         QRENCODE:                ${have_qrencode}
 983         MICROHTTPD:              ${have_microhttpd}
 984         CHKCONFIG:               ${have_chkconfig}
 985         binfmt:                  ${have_binfmt}
 986         vconsole:                ${have_vconsole}
 987         readahead:               ${have_readahead}
 988         bootchart:               ${have_bootchart}
 989         quotacheck:              ${have_quotacheck}
 990         tmpfiles:                ${have_tmpfiles}
 991         randomseed:              ${have_randomseed}
 992         logind:                  ${have_logind}
 993         machined:                ${have_machined}
 994         hostnamed:               ${have_hostnamed}
 995         timedated:               ${have_timedated}
 996         localed:                 ${have_localed}
 997         coredump:                ${have_coredump}
 998         polkit:                  ${have_polkit}
 999         efi:                     ${have_efi}
1000         kmod:                    ${have_kmod}
1001         blkid:                   ${have_blkid}
1002         nss-myhostname:          ${have_myhostname}
1003         gudev:                   ${enable_gudev}
1004         gintrospection:          ${enable_introspection}
1005         Python:                  ${have_python}
1006         Python Headers:          ${have_python_devel}
1007         man pages:               ${have_manpages}
1008         gtk-doc:                 ${enable_gtk_doc}
1009         test coverage:           ${have_coverage}
1010         Split /usr:              ${enable_split_usr}
1011         SysV compatibility:      ${SYSTEM_SYSV_COMPAT}
1012
1013         prefix:                  ${prefix}
1014         rootprefix:              ${with_rootprefix}
1015         sysconf dir:             ${sysconfdir}
1016         datarootdir:             ${datarootdir}
1017         includedir:              ${includedir}
1018         include_prefix:          ${INCLUDE_PREFIX}
1019         lib dir:                 ${libdir}
1020         rootlib dir:             ${with_rootlibdir}
1021         SysV init scripts:       ${SYSTEM_SYSVINIT_PATH}
1022         SysV rc?.d directories:  ${SYSTEM_SYSVRCND_PATH}
1023         Build Python:            ${PYTHON}
1024         Installation Python:     ${PYTHON_BINARY}
1025         firmware path:           ${FIRMWARE_PATH}
1026         PAM modules dir:         ${with_pamlibdir}
1027         D-Bus policy dir:        ${with_dbuspolicydir}
1028         D-Bus session dir:       ${with_dbussessionservicedir}
1029         D-Bus system dir:        ${with_dbussystemservicedir}
1030         D-Bus interfaces dir:    ${with_dbusinterfacedir}
1031         Bash completions dir:    ${with_bashcompletiondir}
1032         Extra start script:      ${RC_LOCAL_SCRIPT_PATH_START}
1033         Extra stop script:       ${RC_LOCAL_SCRIPT_PATH_STOP}
1034         Debug shell:             ${SUSHELL} @ ${DEBUGTTY}
1035
1036         CFLAGS:                  ${OUR_CFLAGS} ${CFLAGS}
1037         CPPFLAGS:                ${OUR_CPPFLAGS} ${CPPFLAGS}
1038         LDFLAGS:                 ${OUR_LDFLAGS} ${LDFLAGS}
1039         PYTHON_CFLAGS:           ${PYTHON_DEVEL_CFLAGS}
1040         PYTHON_LIBS:             ${PYTHON_DEVEL_LIBS}
1041 ])