configure.ac

   1 #  This file is part of systemd.
   2 #
   3 #  Copyright 2010 Lennart Poettering
   4 #
   5 #  systemd is free software; you can redistribute it and/or modify it
   6 #  under the terms of the GNU General Public License as published by
   7 #  the Free Software Foundation; either version 2 of the License, or
   8 #  (at your option) any later version.
   9 #
  10 #  systemd is distributed in the hope that it will be useful, but
  11 #  WITHOUT ANY WARRANTY; without even the implied warranty of
  12 #  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
  13 #  General Public License for more details.
  14 #
  15 #  You should have received a copy of the GNU General Public License
  16 #  along with systemd; If not, see <http://www.gnu.org/licenses/>.
  17
  18 AC_PREREQ(2.63)
  19
  20 AC_INIT([systemd],[42],[systemd-devel@lists.freedesktop.org])
  21 AC_CONFIG_SRCDIR([src/main.c])
  22 AC_CONFIG_MACRO_DIR([m4])
  23 AC_CONFIG_HEADERS([config.h])
  24 AC_USE_SYSTEM_EXTENSIONS
  25 AC_SYS_LARGEFILE
  26 AC_PREFIX_DEFAULT([/usr])
  27 AM_INIT_AUTOMAKE([foreign 1.11 -Wall -Wno-portability silent-rules tar-pax no-dist-gzip dist-xz subdir-objects check-news])
  28
  29 AC_SUBST(PACKAGE_URL, [http://www.freedesktop.org/wiki/Software/systemd])
  30
  31 AC_CANONICAL_HOST
  32 AC_DEFINE_UNQUOTED([CANONICAL_HOST], "$host", [Canonical host string.])
  33 AS_IF([test "x$host_cpu" = "xmips" || test "x$host_cpu" = "xmipsel" ||
  34        test "x$host_cpu" = "xmips64" || test "x$host_cpu" = "xmips64el"],
  35       [AC_DEFINE(ARCH_MIPS, [], [Whether on mips arch])])
  36
  37 AM_SILENT_RULES([yes])
  38
  39 # i18n stuff for the PolicyKit policy files
  40 IT_PROG_INTLTOOL([0.40.0])
  41
  42 GETTEXT_PACKAGE=systemd
  43 AC_SUBST(GETTEXT_PACKAGE)
  44
  45 AC_PROG_MKDIR_P
  46 AC_PROG_LN_S
  47 AC_PROG_SED
  48 AC_PROG_GREP
  49 AC_PROG_AWK
  50
  51 AC_PROG_CC
  52 AC_PROG_CC_C99
  53 AM_PROG_CC_C_O
  54 AC_PROG_GCC_TRADITIONAL
  55
  56 AC_CHECK_TOOL(OBJCOPY, objcopy)
  57 AC_CHECK_TOOL(STRINGS, strings)
  58 AC_CHECK_TOOL(GPERF, gperf)
  59 if test -z "$GPERF" ; then
  60         AC_MSG_ERROR([*** gperf not found])
  61 fi
  62
  63 CC_CHECK_CFLAGS_APPEND([ \
  64         -pipe \
  65         -Wall \
  66         -W \
  67         -Wextra \
  68         -Wno-inline \
  69         -Wvla \
  70         -Wundef \
  71         -Wformat=2 \
  72         -Wlogical-op \
  73         -Wsign-compare \
  74         -Wformat-security \
  75         -Wmissing-include-dirs \
  76         -Wformat-nonliteral \
  77         -Wold-style-definition \
  78         -Wpointer-arith \
  79         -Winit-self \
  80         -Wdeclaration-after-statement \
  81         -Wfloat-equal \
  82         -Wmissing-prototypes \
  83         -Wstrict-prototypes \
  84         -Wredundant-decls \
  85         -Wmissing-declarations \
  86         -Wmissing-noreturn \
  87         -Wshadow \
  88         -Wendif-labels \
  89         -Wcast-align \
  90         -Wstrict-aliasing=2 \
  91         -Wwrite-strings \
  92         -Wno-long-long \
  93         -Wno-overlength-strings \
  94         -Wno-unused-parameter \
  95         -Wno-missing-field-initializers \
  96         -Wno-unused-result \
  97         -Werror=overflow \
  98         -Wp,-D_FORTIFY_SOURCE=2 \
  99         -ffast-math \
 100         -fno-common \
 101         -fdiagnostics-show-option \
 102         -fno-strict-aliasing \
 103         -fvisibility=hidden \
 104         -ffunction-sections \
 105         -fdata-sections \
 106         -Wl,--as-needed \
 107         -Wl,--gc-sections])
 108
 109 LT_PREREQ(2.2)
 110 LT_INIT
 111
 112 AC_SEARCH_LIBS([clock_gettime], [rt], [], [AC_MSG_ERROR([*** POSIX RT library not found])])
 113 AC_SEARCH_LIBS([dlsym], [dl], [], [AC_MSG_ERROR([*** Dynamic linking loader library not found])])
 114
 115 save_LIBS="$LIBS"
 116 LIBS=
 117 AC_SEARCH_LIBS([cap_init], [cap], [], [AC_MSG_ERROR([*** POSIX caps library not found])])
 118 AC_CHECK_HEADERS([sys/capability.h], [], [AC_MSG_ERROR([*** POSIX caps headers not found])])
 119 CAP_LIBS="$LIBS"
 120 LIBS="$save_LIBS"
 121 AC_SUBST(CAP_LIBS)
 122
 123 # This makes sure pkg.m4 is available.
 124 m4_pattern_forbid([^_?PKG_[A-Z_]+$],[*** pkg.m4 missing, please install pkg-config])
 125
 126 PKG_CHECK_MODULES(UDEV, [ libudev >= 172 ])
 127 PKG_CHECK_MODULES(DBUS, [ dbus-1 >= 1.3.2 ])
 128 PKG_CHECK_MODULES(KMOD, [ libkmod >= 5 ])
 129
 130 have_selinux=no
 131 AC_ARG_ENABLE(selinux, AS_HELP_STRING([--disable-selinux], [Disable optional SELINUX support]))
 132 if test "x$enable_selinux" != "xno"; then
 133         PKG_CHECK_MODULES(SELINUX, [ libselinux ],
 134                 [AC_DEFINE(HAVE_SELINUX, 1, [Define if SELinux is available]) have_selinux=yes], have_selinux=no)
 135         if test "x$have_selinux" = xno -a "x$enable_selinux" = xyes; then
 136                 AC_MSG_ERROR([*** SELinux support requested but libraries not found])
 137         fi
 138 fi
 139 AM_CONDITIONAL(HAVE_SELINUX, [test "$have_selinux" = "yes"])
 140
 141 have_xz=no
 142 AC_ARG_ENABLE(xz, AS_HELP_STRING([--disable-xz], [Disable optional XZ support]))
 143 if test "x$enable_xz" != "xno"; then
 144         PKG_CHECK_MODULES(XZ, [ liblzma ],
 145                 [AC_DEFINE(HAVE_XZ, 1, [Define if XZ is available]) have_xz=yes], have_xz=no)
 146         if test "x$have_xz" = xno -a "x$enable_xz" = xyes; then
 147                 AC_MSG_ERROR([*** Xz support requested but libraries not found])
 148         fi
 149 fi
 150 AM_CONDITIONAL(HAVE_XZ, [test "$have_xz" = "yes"])
 151
 152 AC_ARG_ENABLE([tcpwrap],
 153         AS_HELP_STRING([--disable-tcpwrap],[Disable optional TCP wrappers support]),
 154                 [case "${enableval}" in
 155                         yes) have_tcpwrap=yes ;;
 156                         no) have_tcpwrap=no ;;
 157                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-tcpwrap) ;;
 158                 esac],
 159                 [have_tcpwrap=auto])
 160
 161 if test "x${have_tcpwrap}" != xno ; then
 162         ACX_LIBWRAP
 163         if test "x${LIBWRAP_LIBS}" = x ; then
 164                 if test "x$have_tcpwrap" = xyes ; then
 165                         AC_MSG_ERROR([*** TCP wrappers support not found.])
 166                 fi
 167                 have_tcpwrap=no
 168         else
 169                 have_tcpwrap=yes
 170         fi
 171 else
 172         LIBWRAP_LIBS=
 173 fi
 174 AC_SUBST(LIBWRAP_LIBS)
 175
 176 AC_ARG_ENABLE([pam],
 177         AS_HELP_STRING([--disable-pam],[Disable optional PAM support]),
 178                 [case "${enableval}" in
 179                         yes) have_pam=yes ;;
 180                         no) have_pam=no ;;
 181                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-pam) ;;
 182                 esac],
 183                 [have_pam=auto])
 184
 185 if test "x${have_pam}" != xno ; then
 186         AC_CHECK_HEADERS(
 187                 [security/pam_modules.h security/pam_modutil.h security/pam_ext.h],
 188                 [have_pam=yes],
 189                 [if test "x$have_pam" = xyes ; then
 190                         AC_MSG_ERROR([*** PAM headers not found.])
 191                 fi])
 192
 193         AC_CHECK_LIB(
 194                 [pam],
 195                 [pam_syslog],
 196                 [have_pam=yes],
 197                 [if test "x$have_pam" = xyes ; then
 198                         AC_MSG_ERROR([*** libpam not found.])
 199                 fi])
 200
 201         if test "x$have_pam" = xyes ; then
 202                 PAM_LIBS="-lpam -lpam_misc"
 203                 AC_DEFINE(HAVE_PAM, 1, [PAM available])
 204         else
 205                 have_pam=no
 206         fi
 207 else
 208         PAM_LIBS=
 209 fi
 210 AC_SUBST(PAM_LIBS)
 211 AM_CONDITIONAL([HAVE_PAM], [test "x$have_pam" != xno])
 212
 213 AC_ARG_ENABLE([acl],
 214         AS_HELP_STRING([--disable-acl],[Disable optional ACL support]),
 215                 [case "${enableval}" in
 216                         yes) have_acl=yes ;;
 217                         no) have_acl=no ;;
 218                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-acl) ;;
 219                 esac],
 220                 [have_acl=auto])
 221
 222 if test "x${have_acl}" != xno ; then
 223         AC_CHECK_HEADERS(
 224                 [sys/acl.h acl/libacl.h],
 225                 [have_acl=yes],
 226                 [if test "x$have_acl" = xyes ; then
 227                         AC_MSG_ERROR([*** ACL headers not found.])
 228                 fi])
 229
 230         AC_CHECK_LIB(
 231                 [acl],
 232                 [acl_get_file],
 233                 [have_acl=yes],
 234                 [if test "x$have_acl" = xyes ; then
 235                         AC_MSG_ERROR([*** libacl not found.])
 236                 fi])
 237
 238         if test "x$have_acl" = xyes ; then
 239                 ACL_LIBS="-lacl"
 240                 AC_DEFINE(HAVE_ACL, 1, [ACL available])
 241         else
 242                 have_acl=no
 243         fi
 244 else
 245         ACL_LIBS=
 246 fi
 247 AC_SUBST(ACL_LIBS)
 248 AM_CONDITIONAL([HAVE_ACL], [test "x$have_acl" != xno])
 249
 250 AC_ARG_ENABLE([audit],
 251         AS_HELP_STRING([--disable-audit],[Disable optional AUDIT support]),
 252                 [case "${enableval}" in
 253                         yes) have_audit=yes ;;
 254                         no) have_audit=no ;;
 255                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-audit) ;;
 256                 esac],
 257                 [have_audit=auto])
 258
 259 if test "x${have_audit}" != xno ; then
 260         AC_CHECK_HEADERS(
 261                 [libaudit.h],
 262                 [have_audit=yes],
 263                 [if test "x$have_audit" = xyes ; then
 264                         AC_MSG_ERROR([*** AUDIT headers not found.])
 265                 fi])
 266
 267         AC_CHECK_LIB(
 268                 [audit],
 269                 [audit_open],
 270                 [have_audit=yes],
 271                 [if test "x$have_audit" = xyes ; then
 272                         AC_MSG_ERROR([*** libaudit not found.])
 273                 fi])
 274
 275         if test "x$have_audit" = xyes ; then
 276                 AUDIT_LIBS="-laudit"
 277                 AC_DEFINE(HAVE_AUDIT, 1, [AUDIT available])
 278         else
 279                 have_audit=no
 280         fi
 281 else
 282         AUDIT_LIBS=
 283 fi
 284 AC_SUBST(AUDIT_LIBS)
 285
 286 have_libcryptsetup=no
 287 AC_ARG_ENABLE(libcryptsetup, AS_HELP_STRING([--disable-libcryptsetup], [disable libcryptsetup tools]))
 288 if test "x$enable_libcryptsetup" != "xno"; then
 289         PKG_CHECK_MODULES(LIBCRYPTSETUP, [ libcryptsetup ],
 290                 [AC_DEFINE(HAVE_LIBCRYPTSETUP, 1, [Define if libcryptsetup is available]) have_libcryptsetup=yes], have_libcryptsetup=no)
 291         if test "x$have_libcryptsetup" = xno -a "x$enable_libcryptsetup" = xyes; then
 292                 AC_MSG_ERROR([*** libcryptsetup support requested but libraries not found])
 293         fi
 294 fi
 295 AM_CONDITIONAL(HAVE_LIBCRYPTSETUP, [test "$have_libcryptsetup" = "yes"])
 296
 297 have_binfmt=no
 298 AC_ARG_ENABLE(binfmt, AS_HELP_STRING([--disable-binfmt], [disable binfmt tool]))
 299 if test "x$enable_binfmt" != "xno"; then
 300         have_binfmt=yes
 301 fi
 302 AM_CONDITIONAL(ENABLE_BINFMT, [test "$have_binfmt" = "yes"])
 303
 304 have_vconsole=no
 305 AC_ARG_ENABLE(vconsole, AS_HELP_STRING([--disable-vconsole], [disable vconsole tool]))
 306 if test "x$enable_vconsole" != "xno"; then
 307         have_vconsole=yes
 308 fi
 309 AM_CONDITIONAL(ENABLE_VCONSOLE, [test "$have_vconsole" = "yes"])
 310
 311 have_readahead=no
 312 AC_ARG_ENABLE(readahead, AS_HELP_STRING([--disable-readahead], [disable readahead tools]))
 313 if test "x$enable_readahead" != "xno"; then
 314         have_readahead=yes
 315 fi
 316 AM_CONDITIONAL(ENABLE_READAHEAD, [test "$have_readahead" = "yes"])
 317
 318 have_quotacheck=no
 319 AC_ARG_ENABLE(quotacheck, AS_HELP_STRING([--disable-quotacheck], [disable quotacheck tools]))
 320 if test "x$enable_quotacheck" != "xno"; then
 321         have_quotacheck=yes
 322 fi
 323 AM_CONDITIONAL(ENABLE_QUOTACHECK, [test "$have_quotacheck" = "yes"])
 324
 325 have_randomseed=no
 326 AC_ARG_ENABLE(randomseed, AS_HELP_STRING([--disable-randomseed], [disable randomseed tools]))
 327 if test "x$enable_randomseed" != "xno"; then
 328         have_randomseed=yes
 329 fi
 330 AM_CONDITIONAL(ENABLE_RANDOMSEED, [test "$have_randomseed" = "yes"])
 331
 332 have_logind=no
 333 AC_ARG_ENABLE(logind, AS_HELP_STRING([--disable-logind], [disable login daemon]))
 334 if test "x$enable_logind" != "xno"; then
 335         have_logind=yes
 336 fi
 337 AM_CONDITIONAL(ENABLE_LOGIND, [test "$have_logind" = "yes"])
 338
 339 have_hostnamed=no
 340 AC_ARG_ENABLE(hostnamed, AS_HELP_STRING([--disable-hostnamed], [disable hostname daemon]))
 341 if test "x$enable_hostnamed" != "xno"; then
 342         have_hostnamed=yes
 343 fi
 344 AM_CONDITIONAL(ENABLE_HOSTNAMED, [test "$have_hostnamed" = "yes"])
 345
 346 have_timedated=no
 347 AC_ARG_ENABLE(timedated, AS_HELP_STRING([--disable-timedated], [disable timedate daemon]))
 348 if test "x$enable_timedated" != "xno"; then
 349         have_timedated=yes
 350 fi
 351 AM_CONDITIONAL(ENABLE_TIMEDATED, [test "$have_timedated" = "yes"])
 352
 353 have_localed=no
 354 AC_ARG_ENABLE(localed, AS_HELP_STRING([--disable-localed], [disable locale daemon]))
 355 if test "x$enable_localed" != "xno"; then
 356         have_localed=yes
 357 fi
 358 AM_CONDITIONAL(ENABLE_LOCALED, [test "$have_localed" = "yes"])
 359
 360 have_coredump=no
 361 AC_ARG_ENABLE(coredump, AS_HELP_STRING([--disable-coredump], [disable coredump hook]))
 362 if test "x$enable_coredump" != "xno"; then
 363         have_coredump=yes
 364 fi
 365 AM_CONDITIONAL(ENABLE_COREDUMP, [test "$have_coredump" = "yes"])
 366
 367 have_manpages=no
 368 AC_ARG_ENABLE(manpages, AS_HELP_STRING([--disable-manpages], [disable manpages]))
 369 if test "x$enable_manpages" != "xno"; then
 370         have_manpages=yes
 371 fi
 372 AM_CONDITIONAL(ENABLE_MANPAGES, [test "$have_manpages" = "yes"])
 373
 374 have_gtk=no
 375 AC_ARG_ENABLE(gtk, AS_HELP_STRING([--disable-gtk], [disable GTK tools]))
 376 if test "x$enable_gtk" != "xno"; then
 377         PKG_CHECK_MODULES(GTK, [ gtk+-2.0 glib-2.0 > 2.26 gio-unix-2.0 gee-1.0],
 378                 [AC_DEFINE(HAVE_GTK, 1, [Define if GTK is available]) have_gtk=yes], have_gtk=no)
 379         if test "x$have_gtk" = xno -a "x$enable_gtk" = xyes; then
 380                 AC_MSG_ERROR([*** gtk support requested but libraries not found])
 381         fi
 382 fi
 383 AM_CONDITIONAL(HAVE_GTK, [test "$have_gtk" = "yes"])
 384
 385 if test "$have_gtk" = "yes"; then
 386         PKG_CHECK_MODULES(LIBNOTIFY, [ libnotify ])
 387 fi
 388
 389 AM_PROG_VALAC([0.10])
 390 AC_SUBST(VAPIDIR)
 391 AM_CONDITIONAL(HAVE_VALAC, test x"$VALAC" != x)
 392
 393 AC_PATH_PROG([XSLTPROC], [xsltproc])
 394 AM_CONDITIONAL(HAVE_XSLTPROC, test x"$XSLTPROC" != x)
 395
 396 AC_PATH_PROG([M4], [m4])
 397
 398 AC_ARG_WITH(distro, AS_HELP_STRING([--with-distro=DISTRO],[Specify the distribution to target: One of fedora, suse, debian, ubuntu, arch, gentoo, slackware, altlinuxi, mandriva, meego, mageia, angstrom or other]))
 399 if test "z$with_distro" = "z"; then
 400         if test "$cross_compiling" = yes; then
 401                 AC_MSG_WARN([Target distribution cannot be reliably detected when cross-compiling. You should specify it with --with-distro (see $0 --help for recognized distros)])
 402         else
 403                 with_distro=$($GREP '^ID=' /etc/os-release | $SED 's/ID=//');
 404         fi
 405         if test "z$with_distro" = "z"; then
 406                 with_distro=other
 407         fi
 408 fi
 409 with_distro=`echo ${with_distro} | tr '[[:upper:]]' '[[:lower:]]' `
 410 AC_DEFINE_UNQUOTED(DISTRIBUTION, ["${with_distro}"], [Target Distribution])
 411
 412 # Location of the init scripts as mandated by LSB
 413 SYSTEM_SYSVINIT_PATH=/etc/init.d
 414 SYSTEM_SYSVRCND_PATH=/etc/rc.d
 415
 416 M4_DEFINES=
 417 have_plymouth=no
 418
 419 case $with_distro in
 420         fedora)
 421                 SYSTEM_SYSVINIT_PATH=/etc/rc.d/init.d
 422                 AC_DEFINE(TARGET_FEDORA, [], [Target is Fedora/RHEL])
 423                 M4_DEFINES=-DTARGET_FEDORA=1
 424                 have_plymouth=yes
 425                 ;;
 426         opensuse|suse)
 427                 SYSTEM_SYSVRCND_PATH=/etc/init.d
 428                 AC_DEFINE(TARGET_SUSE, [], [Target is openSUSE/SLE])
 429                 M4_DEFINES=-DTARGET_SUSE=1
 430                 have_plymouth=yes
 431                 ;;
 432         debian)
 433                 SYSTEM_SYSVRCND_PATH=/etc
 434                 AC_DEFINE(TARGET_DEBIAN, [], [Target is Debian])
 435                 M4_DEFINES=-DTARGET_DEBIAN=1
 436                 ;;
 437         ubuntu)
 438                 SYSTEM_SYSVRCND_PATH=/etc
 439                 AC_DEFINE(TARGET_UBUNTU, [], [Target is Ubuntu])
 440                 M4_DEFINES=-DTARGET_UBUNTU=1
 441                 ;;
 442         arch)
 443                 SYSTEM_SYSVINIT_PATH=/etc/rc.d
 444                 SYSTEM_SYSVRCND_PATH=/etc
 445                 AC_DEFINE(TARGET_ARCH, [], [Target is ArchLinux])
 446                 M4_DEFINES=-DTARGET_ARCH=1
 447                 ;;
 448         gentoo)
 449                 SYSTEM_SYSVINIT_PATH=
 450                 SYSTEM_SYSVRCND_PATH=
 451                 AC_DEFINE(TARGET_GENTOO, [], [Target is Gentoo])
 452                 M4_DEFINES=-DTARGET_GENTOO=1
 453                 ;;
 454         slackware)
 455                 SYSTEM_SYSVINIT_PATH=/etc/rc.d/init.d
 456                 AC_DEFINE(TARGET_SLACKWARE, [], [Target is Slackware])
 457                 M4_DEFINES=-DTARGET_SLACKWARE=1
 458                 ;;
 459         frugalware)
 460                 SYSTEM_SYSVINIT_PATH=/etc/rc.d
 461                 AC_DEFINE(TARGET_FRUGALWARE, [], [Target is Frugalware])
 462                 M4_DEFINES=-DTARGET_FRUGALWARE=1
 463                 have_plymouth=yes
 464                 ;;
 465         altlinux)
 466                 SYSTEM_SYSVINIT_PATH=/etc/rc.d/init.d
 467                 AC_DEFINE(TARGET_ALTLINUX, [], [Target is ALTLinux])
 468                 M4_DEFINES=-DTARGET_ALTLINUX=1
 469                 have_plymouth=yes
 470                 ;;
 471         mandriva)
 472                 SYSTEM_SYSVINIT_PATH=/etc/rc.d/init.d
 473                 AC_DEFINE(TARGET_MANDRIVA, [], [Target is Mandriva])
 474                 M4_DEFINES=-DTARGET_MANDRIVA=1
 475                 have_plymouth=yes
 476                 ;;
 477         meego)
 478                 SYSTEM_SYSVINIT_PATH=
 479                 SYSTEM_SYSVRCND_PATH=
 480                 AC_DEFINE(TARGET_MEEGO, [], [Target is MeeGo])
 481                 M4_DEFINES=-DTARGET_MEEGO=1
 482                 ;;
 483         angstrom)
 484                 SYSTEM_SYSVRCND_PATH=/etc
 485                 AC_DEFINE(TARGET_ANGSTROM, [], [Target is Ångström])
 486                 M4_DEFINES=-DTARGET_ANGSTROM=1
 487                 ;;
 488         mageia)
 489                 SYSTEM_SYSVINIT_PATH=/etc/rc.d/init.d
 490                 AC_DEFINE(TARGET_MAGEIA, [], [Target is Mageia])
 491                 M4_DISTRO_FLAG=-DTARGET_MAGEIA=1
 492                 have_plymouth=yes
 493                 ;;
 494         other)
 495                 ;;
 496         *)
 497                 AC_MSG_ERROR([Your distribution (${with_distro}) is not yet supported, SysV init scripts could not be found! (patches welcome); you can specify --with-distro=other to skip this check])
 498                 ;;
 499 esac
 500
 501 AC_ARG_WITH([sysvinit-path],
 502         [AS_HELP_STRING([--with-sysvinit-path=PATH],
 503                 [Specify the path to where the SysV init scripts are located @<:@default=based on distro@:>@])],
 504         [SYSTEM_SYSVINIT_PATH="$withval"],
 505         [])
 506
 507 AC_ARG_WITH([sysvrcd-path],
 508         [AS_HELP_STRING([--with-sysvrcd-path=PATH],
 509                 [Specify the path to the base directory for the SysV rcN.d directories @<:@default=based on distro@:>@])],
 510         [SYSTEM_SYSVRCND_PATH="$withval"],
 511         [])
 512
 513 AC_SUBST(SYSTEM_SYSVINIT_PATH)
 514 AC_SUBST(SYSTEM_SYSVRCND_PATH)
 515 AC_SUBST(M4_DEFINES)
 516
 517 if test "x${SYSTEM_SYSVINIT_PATH}" != "x" -a "x${SYSTEM_SYSVRCND_PATH}" != "x"; then
 518         AC_DEFINE(HAVE_SYSV_COMPAT, [], [SysV init scripts and rcN.d links are supported.])
 519         SYSTEM_SYSV_COMPAT="yes"
 520         M4_DEFINES="$M4_DEFINES -DHAVE_SYSV_COMPAT"
 521 elif test "x${SYSTEM_SYSVINIT_PATH}" != "x" -o "x${SYSTEM_SYSVRCND_PATH}" != "x"; then
 522         AC_MSG_ERROR([*** You need both --with-sysvinit-path=PATH and --with-sysvrcd-path=PATH to enable SysV compatibility support, or both empty to disable it.])
 523 else
 524         SYSTEM_SYSV_COMPAT="no"
 525 fi
 526
 527 AC_ARG_WITH([tty-gid],
 528         [AS_HELP_STRING([--with-tty-gid=GID],
 529                 [Specify the numeric GID of the 'tty' group])],
 530         [AC_DEFINE_UNQUOTED(TTY_GID, [$withval], [GID of the 'tty' group])],
 531         [])
 532
 533 AC_ARG_ENABLE(plymouth, AS_HELP_STRING([--enable-plymouth], [enable plymouth support]))
 534 if test -n "$enable_plymouth"; then
 535         have_plymouth="$enable_plymouth"
 536 fi
 537
 538 AM_CONDITIONAL(TARGET_FEDORA, test x"$with_distro" = xfedora)
 539 AM_CONDITIONAL(TARGET_SUSE, test x"$with_distro" = xsuse)
 540 AM_CONDITIONAL(TARGET_DEBIAN, test x"$with_distro" = xdebian)
 541 AM_CONDITIONAL(TARGET_UBUNTU, test x"$with_distro" = xubuntu)
 542 AM_CONDITIONAL(TARGET_DEBIAN_OR_UBUNTU, test x"$with_distro" = xdebian -o x"$with_distro" = xubuntu)
 543 AM_CONDITIONAL(TARGET_ARCH, test x"$with_distro" = xarch)
 544 AM_CONDITIONAL(TARGET_GENTOO, test x"$with_distro" = xgentoo)
 545 AM_CONDITIONAL(TARGET_SLACKWARE, test x"$with_distro" = xslackware)
 546 AM_CONDITIONAL(TARGET_FRUGALWARE, test x"$with_distro" = xfrugalware)
 547 AM_CONDITIONAL(TARGET_ALTLINUX, test x"$with_distro" = xaltlinux)
 548 AM_CONDITIONAL(TARGET_MANDRIVA, test x"$with_distro" = xmandriva)
 549 AM_CONDITIONAL(TARGET_MEEGO, test x"$with_distro" = xmeego)
 550 AM_CONDITIONAL(TARGET_ANGSTROM, test x"$with_distro" = xangstrom)
 551 AM_CONDITIONAL(TARGET_MAGEIA, test x"$with_distro" = xmageia)
 552
 553 AM_CONDITIONAL(HAVE_PLYMOUTH, test "$have_plymouth" = "yes")
 554 AM_CONDITIONAL(HAVE_SYSV_COMPAT, test "$SYSTEM_SYSV_COMPAT" = "yes")
 555
 556 AC_ARG_WITH([dbuspolicydir],
 557         AS_HELP_STRING([--with-dbuspolicydir=DIR], [D-Bus policy directory]),
 558         [],
 559         [with_dbuspolicydir=`pkg-config --variable=sysconfdir dbus-1`/dbus-1/system.d])
 560
 561 AC_ARG_WITH([dbussessionservicedir],
 562         AS_HELP_STRING([--with-dbussessionservicedir=DIR], [D-Bus session service directory]),
 563         [],
 564         [with_dbussessionservicedir=`pkg-config --variable=session_bus_services_dir dbus-1`])
 565
 566 AC_ARG_WITH([dbussystemservicedir],
 567         AS_HELP_STRING([--with-dbussystemservicedir=DIR], [D-Bus system service directory]),
 568         [],
 569         [with_dbussystemservicedir=`pkg-config --variable=session_bus_services_dir dbus-1`/../system-services])
 570
 571 AC_ARG_WITH([dbusinterfacedir],
 572         AS_HELP_STRING([--with-dbusinterfacedir=DIR], [D-Bus interface directory]),
 573         [],
 574         [with_dbusinterfacedir=`pkg-config --variable=session_bus_services_dir dbus-1`/../interfaces])
 575
 576 AC_ARG_WITH([udevrulesdir],
 577         AS_HELP_STRING([--with-udevrulesdir=DIR], [Directory for udev rules]),
 578         [],
 579         [with_udevrulesdir=`pkg-config --variable=udevdir udev`/rules.d])
 580
 581 AC_ARG_WITH([rootprefix],
 582         AS_HELP_STRING([--with-rootprefix=DIR], [rootfs directory prefix for config files and kernel modules]),
 583         [], [with_rootprefix=${ac_default_prefix}])
 584
 585 AC_ARG_WITH([rootlibdir],
 586         AS_HELP_STRING([--with-rootlibdir=DIR], [Root directory for libraries necessary for boot]),
 587         [],
 588         [with_rootlibdir=${libdir}])
 589
 590 AC_ARG_WITH([pamlibdir],
 591         AS_HELP_STRING([--with-pamlibdir=DIR], [Directory for PAM modules]),
 592         [],
 593         [with_pamlibdir=${with_rootlibdir}/security])
 594
 595 AC_ARG_ENABLE([split-usr],
 596         AS_HELP_STRING([--enable-split-usr], [Assume that /bin, /sbin aren\'t symlinks into /usr]),
 597         [],
 598         [AS_IF([test "x${ac_default_prefix}" != "x${with_rootprefix}"], [
 599                 enable_split_usr=yes
 600         ], [
 601                 enable_split_usr=no
 602         ])])
 603
 604 AS_IF([test "x${enable_split_usr}" = "xyes"], [
 605         AC_DEFINE(HAVE_SPLIT_USR, 1, [Define if /bin, /sbin aren't symlinks into /usr])
 606 ])
 607
 608 AC_SUBST([dbuspolicydir], [$with_dbuspolicydir])
 609 AC_SUBST([dbussessionservicedir], [$with_dbussessionservicedir])
 610 AC_SUBST([dbussystemservicedir], [$with_dbussystemservicedir])
 611 AC_SUBST([dbusinterfacedir], [$with_dbusinterfacedir])
 612 AC_SUBST([udevrulesdir], [$with_udevrulesdir])
 613 AC_SUBST([pamlibdir], [$with_pamlibdir])
 614 AC_SUBST([rootprefix], [$with_rootprefix])
 615 AC_SUBST([rootlibdir], [$with_rootlibdir])
 616
 617 AC_CONFIG_FILES([Makefile po/Makefile.in])
 618 AC_OUTPUT
 619 AC_MSG_RESULT([
 620         $PACKAGE_NAME $VERSION
 621
 622         Distribution:            ${with_distro}
 623         SysV compatibility:      ${SYSTEM_SYSV_COMPAT}
 624         SysV init scripts:       ${SYSTEM_SYSVINIT_PATH}
 625         SysV rc?.d directories:  ${SYSTEM_SYSVRCND_PATH}
 626         Gtk:                     ${have_gtk}
 627         libcryptsetup:           ${have_libcryptsetup}
 628         tcpwrap:                 ${have_tcpwrap}
 629         PAM:                     ${have_pam}
 630         AUDIT:                   ${have_audit}
 631         SELinux:                 ${have_selinux}
 632         XZ:                      ${have_xz}
 633         ACL:                     ${have_acl}
 634         binfmt:                  ${have_binfmt}
 635         vconsole:                ${have_vconsole}
 636         readahead:               ${have_readahead}
 637         quotacheck:              ${have_quotacheck}
 638         randomseed:              ${have_randomseed}
 639         logind:                  ${have_logind}
 640         hostnamed:               ${have_hostnamed}
 641         timedated:               ${have_timedated}
 642         localed:                 ${have_localed}
 643         coredump:                ${have_coredump}
 644         plymouth:                ${have_plymouth}
 645         prefix:                  ${prefix}
 646         rootprefix:              ${with_rootprefix}
 647         libexec dir:             ${libexecdir}
 648         lib dir:                 ${libdir}
 649         rootlib dir:             ${with_rootlibdir}
 650         PAM modules dir:         ${with_pamlibdir}
 651         udev rules dir:          ${with_udevrulesdir}
 652         D-Bus policy dir:        ${with_dbuspolicydir}
 653         D-Bus session dir:       ${with_dbussessionservicedir}
 654         D-Bus system dir:        ${with_dbussystemservicedir}
 655         D-Bus interfaces dir:    ${with_dbusinterfacedir}
 656         Split /usr:              ${enable_split_usr}
 657         Build man pages:         ${have_manpages}
 658 ])