chiark / gitweb /
udevd: use dev_t or netif ifindex as database key
[elogind.git] / configure.ac
1 AC_INIT([udev], [165], [linux-hotplug@vger.kernel.org])
2 AC_PREREQ(2.60)
3 AM_INIT_AUTOMAKE([check-news foreign 1.10 dist-bzip2 subdir-objects])
4 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
5 AC_DISABLE_STATIC
6 AC_USE_SYSTEM_EXTENSIONS
7 AC_SYS_LARGEFILE
8 AC_CONFIG_MACRO_DIR([m4])
9 LT_INIT
10 AC_PROG_AWK
11 GTK_DOC_CHECK(1.10)
12 AC_PREFIX_DEFAULT([/usr])
13 AC_PATH_PROG([XSLTPROC], [xsltproc])
14
15 AC_ARG_WITH([rootlibdir],
16         AS_HELP_STRING([--with-rootlibdir=DIR], [rootfs directory to install shared libraries]),
17         [], [with_rootlibdir=$libdir])
18 AC_SUBST([rootlib_execdir], [$with_rootlibdir])
19
20 AC_ARG_WITH([selinux],
21         AS_HELP_STRING([--with-selinux], [enable SELinux support]),
22         [], [with_selinux=no])
23 if test "x$with_selinux" = xyes; then
24         LIBS_save=$LIBS
25         AC_CHECK_LIB(selinux, getprevcon,
26                 [],
27                 AC_MSG_ERROR([SELinux selected but libselinux not found]))
28         LIBS=$LIBS_save
29         SELINUX_LIBS="-lselinux -lsepol"
30         AC_DEFINE(WITH_SELINUX, [1] ,[SELinux support.])
31 fi
32 AC_SUBST([SELINUX_LIBS])
33 AM_CONDITIONAL(WITH_SELINUX, [test "x$with_selinux" = xyes])
34
35 AC_ARG_ENABLE([debug],
36         AS_HELP_STRING([--enable-debug], [enable debug messages]),
37         [], [enable_debug=no])
38 if test "x$enable_debug" = "xyes"; then
39         AC_DEFINE(ENABLE_DEBUG, [1], [Debug messages.])
40 fi
41
42 AC_ARG_ENABLE([logging],
43         AS_HELP_STRING([--disable-logging], [disable system logging]),
44         [], enable_logging=yes)
45 if test "x$enable_logging" = "xyes"; then
46         AC_DEFINE(ENABLE_LOGGING, [1], [System logging.])
47 fi
48
49 AC_ARG_WITH(firmware-path,
50         AS_HELP_STRING([--with-firmware-path=DIR[[[:DIR[...]]]]],
51            [Firmware search path (default=/lib/firmware/updates:/lib/firmware)]),
52         [], [with_firmware_path="/lib/firmware/updates:/lib/firmware"])
53 OLD_IFS=$IFS
54 IFS=:
55 for i in $with_firmware_path
56 do
57         if test "x${FIRMWARE_PATH}" = "x"; then
58                 FIRMWARE_PATH="\\\"${i}/\\\""
59         else
60                 FIRMWARE_PATH="${FIRMWARE_PATH}, \\\"${i}/\\\""
61         fi
62 done
63 IFS=$OLD_IFS
64 AC_SUBST([FIRMWARE_PATH], [$FIRMWARE_PATH])
65
66 AC_ARG_WITH([systemdsystemunitdir],
67         AS_HELP_STRING([--with-systemdsystemunitdir=DIR], [Directory for systemd service files]),
68         [], [with_systemdsystemunitdir=$($PKG_CONFIG --variable=systemdsystemunitdir systemd)])
69 if test "x$with_systemdsystemunitdir" != xno; then
70     AC_SUBST([systemdsystemunitdir], [$with_systemdsystemunitdir])
71 fi
72 AM_CONDITIONAL(WITH_SYSTEMD, [test -n "$with_systemdsystemunitdir" -a "x$with_systemdsystemunitdir" != xno ])
73
74 AC_ARG_ENABLE([extras],
75         AS_HELP_STRING([--disable-extras], [disable extras with external dependencies]),
76         [], [enable_extras=yes])
77 if test "x$enable_extras" = xyes; then
78         AC_PATH_PROG([GPERF], [gperf])
79         if test -z "$GPERF"; then
80                 AC_MSG_ERROR([gperf is needed])
81         fi
82
83         PKG_CHECK_MODULES([GLIB], [glib-2.0 >= 2.22.0 gobject-2.0 >= 2.22.0])
84         AC_SUBST([GLIB_CFLAGS])
85         AC_SUBST([GLIB_LIBS])
86
87         AC_CHECK_LIB([acl], [acl_init], [:], AC_MSG_ERROR([libacl not found]))
88         AC_CHECK_HEADER([acl/libacl.h], [:], AC_MSG_ERROR([libacl header not found]))
89
90         PKG_CHECK_MODULES(LIBUSB, libusb >= 0.1.12)
91         AC_SUBST(LIBUSB_CFLAGS)
92         AC_SUBST(LIBUSB_LIBS)
93
94         PKG_CHECK_MODULES(USBUTILS, usbutils >= 0.82)
95         AC_SUBST([USB_DATABASE], [$($PKG_CONFIG --variable=usbids usbutils)])
96
97         if test "x$cross_compiling" = "xno" ; then
98                 AC_CHECK_FILES([/usr/share/pci.ids], [pciids=/usr/share/pci.ids])
99                 AC_CHECK_FILES([/usr/share/hwdata/pci.ids], [pciids=/usr/share/hwdata/pci.ids])
100                 AC_CHECK_FILES([/usr/share/misc/pci.ids], [pciids=/usr/share/misc/pci.ids])
101         fi
102         AC_ARG_WITH(pci-ids-path,
103                 [AS_HELP_STRING([--with-pci-ids-path=DIR], [Path to pci.ids file])],
104                 [PCI_DATABASE=${withval}],
105                 [if test -n "$pciids" ; then
106                         PCI_DATABASE="$pciids"
107                 else
108                         AC_MSG_ERROR([pci.ids not found, try --with-pci-ids-path=])
109                 fi])
110         AC_MSG_CHECKING([for PCI database location])
111         AC_MSG_RESULT([$PCI_DATABASE])
112         AC_SUBST(PCI_DATABASE)
113
114         AC_CHECK_HEADER([linux/input.h], [:], AC_MSG_ERROR([kernel headers not found]))
115         AC_SUBST([INCLUDE_PREFIX], [$(echo '#include <linux/input.h>' | eval $ac_cpp -E - | sed -n '/linux\/input.h/ {s:.*"\(.*\)/linux/input.h".*:\1:; p; q}')])
116 fi
117 AM_CONDITIONAL([ENABLE_EXTRAS], [test "x$enable_extras" = xyes])
118
119 AC_ARG_ENABLE([introspection],
120         AS_HELP_STRING([--disable-introspection], [disable GObject introspection]),
121         [], [enable_introspection=yes])
122 if test "x$enable_introspection" = xyes; then
123         PKG_CHECK_MODULES([INTROSPECTION], [gobject-introspection-1.0 >= 0.6.2])
124         AC_DEFINE([ENABLE_INTROSPECTION], [1], [enable GObject introspection support])
125         AC_SUBST([G_IR_SCANNER], [$($PKG_CONFIG --variable=g_ir_scanner gobject-introspection-1.0)])
126         AC_SUBST([G_IR_COMPILER], [$($PKG_CONFIG --variable=g_ir_compiler gobject-introspection-1.0)])
127         AC_SUBST([G_IR_GENERATE], [$($PKG_CONFIG --variable=g_ir_generate gobject-introspection-1.0)])
128         AC_SUBST([GIRDIR], [$($PKG_CONFIG --define-variable=datadir=${datadir} --variable=girdir gobject-introspection-1.0)])
129         AC_SUBST([GIRTYPELIBDIR], [$($PKG_CONFIG --define-variable=libdir=${libdir} --variable=typelibdir gobject-introspection-1.0)])
130 fi
131 AM_CONDITIONAL([ENABLE_INTROSPECTION], [test "x$enable_introspection" = xyes])
132
133 AC_CONFIG_HEADERS(config.h)
134 AC_CONFIG_FILES([
135         Makefile
136         udev/udev.pc
137         init/udev.service
138         init/udev-settle.service
139         init/udev-retry.service
140         libudev/libudev.pc
141         libudev/docs/Makefile
142         libudev/docs/version.xml
143         extras/gudev/gudev-1.0.pc
144         extras/gudev/docs/Makefile
145         extras/gudev/docs/version.xml
146 ])
147
148 AC_OUTPUT
149 AC_MSG_RESULT([
150         udev $VERSION
151         ========
152
153         prefix:                 ${prefix}
154         sysconfdir:             ${sysconfdir}
155         sbindir:                ${sbindir}
156         libdir:                 ${libdir}
157         rootlibdir:             ${rootlib_execdir}
158         libexecdir:             ${libexecdir}
159
160         datarootdir:            ${datarootdir}
161         mandir:                 ${mandir}
162         includedir:             ${includedir}
163
164         include_prefix:         ${INCLUDE_PREFIX}
165
166         systemdsystemunitdir:   ${systemdsystemunitdir}
167
168         logging:                ${enable_logging}
169         debug:                  ${enable_debug}
170         selinux:                ${with_selinux}
171
172         compiler:               ${CC}
173         cflags:                 ${CFLAGS}
174         ldflags:                ${LDFLAGS}
175
176         extras:                 ${enable_extras}
177         gintrospection:         ${enable_introspection}
178
179         usb.ids:                ${USB_DATABASE}
180         pci.ids:                ${PCI_DATABASE}
181         firmware path:          ${FIRMWARE_PATH}
182
183         xsltproc:               ${XSLTPROC}
184         gperf:                  ${GPERF}
185 ])