configure.ac

   1 #
   2 #  This file is part of elogind.
   3 #
   4 #  Copyright 2010-2012 Lennart Poettering
   5 #  Copyright 2010-2012 Kay Sievers
   6 #
   7 #  elogind is free software; you can redistribute it and/or modify it
   8 #  under the terms of the GNU Lesser General Public License as published by
   9 #  the Free Software Foundation; either version 2.1 of the License, or
  10 #  (at your option) any later version.
  11 #
  12 #  elogind is distributed in the hope that it will be useful, but
  13 #  WITHOUT ANY WARRANTY; without even the implied warranty of
  14 #  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
  15 #  Lesser General Public License for more details.
  16 #
  17 #  You should have received a copy of the GNU Lesser General Public License
  18 #  along with systemd; If not, see <http://www.gnu.org/licenses/>.
  19
  20 AC_PREREQ([2.64])
  21
  22 AC_INIT([elogind],
  23         [221],
  24         [https://github.com/elogind/elogind/issues],
  25         [elogind],
  26         [https://github.com/elogind/elogind])
  27
  28 AC_CONFIG_SRCDIR([src/login/logind.c])
  29 AC_CONFIG_MACRO_DIR([m4])
  30 AC_CONFIG_HEADERS([config.h])
  31 AC_CONFIG_AUX_DIR([build-aux])
  32
  33 AC_USE_SYSTEM_EXTENSIONS
  34 AC_SYS_LARGEFILE
  35 AC_PREFIX_DEFAULT([/usr])
  36 AM_MAINTAINER_MODE([enable])
  37 AM_INIT_AUTOMAKE([foreign 1.11 -Wall -Wno-portability silent-rules tar-pax no-dist-gzip dist-xz subdir-objects parallel-tests])
  38 AM_SILENT_RULES([yes])
  39 AC_CANONICAL_HOST
  40 AC_DEFINE_UNQUOTED([CANONICAL_HOST], "$host", [Canonical host string.])
  41 LT_PREREQ(2.2)
  42 LT_INIT([disable-static])
  43
  44 AS_IF([test "x$enable_static" = "xyes"], [AC_MSG_ERROR([--enable-static is not supported by elogind])])
  45 AS_IF([test "x$enable_largefile" = "xno"], [AC_MSG_ERROR([--disable-largefile is not supported by elogind])])
  46
  47 SET_ARCH(X86_64, x86_64*)
  48 SET_ARCH(IA32, i*86*)
  49 SET_ARCH(MIPS, mips*)
  50 SET_ARCH(AARCH64, aarch64*)
  51
  52 # i18n stuff for the PolicyKit policy files, heck whether intltool can be found, disable NLS otherwise
  53 AC_CHECK_PROG(intltool_found, [intltool-merge], [yes], [no])
  54 AS_IF([test x"$intltool_found" != xyes],
  55       [AS_IF([test x"$enable_nls" = xyes],
  56              [AC_MSG_ERROR([--enable-nls requested but intltool not found])],
  57              [AS_IF([test x"$enable_nls" != xno],
  58                     [AC_MSG_WARN([*** Disabling NLS support because intltool was not found])
  59                      enable_nls=no])
  60              ])
  61       ])
  62
  63 AM_NLS
  64 AS_IF([test x"$enable_nls" != xno -o "x$enable_polkit" != xno], [
  65     # intltoolize greps for '^(AC|IT)_PROG_INTLTOOL', so it needs to be on its own line
  66 IT_PROG_INTLTOOL([0.40.0])
  67 ])
  68
  69 AS_IF([test -z "$INTLTOOL_POLICY_RULE"], [
  70     # If intltool is not available, provide a dummy rule to fail generation of %.policy files with a meaningful error message
  71     INTLTOOL_POLICY_RULE='%.policy: %.policy.in ; @echo "  ITMRG   " $@ && echo "*** intltool support required to build target $@" && false'
  72     AC_SUBST(INTLTOOL_POLICY_RULE)
  73 ])
  74
  75 GETTEXT_PACKAGE=elogind
  76 AC_SUBST(GETTEXT_PACKAGE)
  77 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, "$GETTEXT_PACKAGE", [elogind])
  78
  79 AC_PROG_MKDIR_P
  80 AC_PROG_LN_S
  81 AC_PROG_SED
  82 AC_PROG_GREP
  83 AC_PROG_AWK
  84
  85 AC_PROG_CC_C99
  86
  87 AC_PATH_PROG([M4], [m4])
  88 AC_PATH_PROG([XSLTPROC], [xsltproc])
  89
  90 AC_PATH_PROG([HALT], [halt], [halt])
  91 AC_PATH_PROG([REBOOT], [reboot], [reboot])
  92 AC_PATH_PROG([KEXEC], [kexec], [/usr/sbin/kexec], [$PATH:/usr/sbin:/sbin])
  93
  94 AS_IF([! ln --relative --help > /dev/null 2>&1], [AC_MSG_ERROR([*** ln doesn't support --relative ***])])
  95
  96 M4_DEFINES=
  97
  98 # gtkdocize greps for '^GTK_DOC_CHECK', so it needs to be on its own line
  99 m4_ifdef([GTK_DOC_CHECK], [
 100 GTK_DOC_CHECK([1.18],[--flavour no-tmpl])],
 101          [AM_CONDITIONAL([ENABLE_GTK_DOC], [false])
 102           enable_gtk_doc=no])
 103
 104 AS_IF([test "x$enable_gtk_doc" = "xyes" -a "x$XSLTPROC" = x], [
 105         AC_MSG_ERROR([*** GTK doc requested but xsltproc not found])
 106 ])
 107
 108 AC_CHECK_TOOL(GPERF, gperf)
 109 if test -z "$GPERF" ; then
 110         AC_MSG_ERROR([*** gperf not found])
 111 fi
 112
 113 # ------------------------------------------------------------------------------
 114 address_sanitizer_cflags=
 115 address_sanitizer_cppflags=
 116 address_sanitizer_ldflags=
 117 AC_ARG_ENABLE(address-sanitizer, AS_HELP_STRING([--enable-address-sanitizer], [enable -fsanitize=address]))
 118 AS_IF([test "x$enable_address_sanitizer" = "xyes"], [
 119             CC_CHECK_FLAG_APPEND([with_as_cflags], [CFLAGS], [-fsanitize=address])
 120             AS_IF([test -z "$with_as_cflags"],
 121                   [AC_MSG_ERROR([*** -fsanitize=address is not supported])])
 122             address_sanitizer_cflags="$with_as_cflags -fno-omit-frame-pointer -DVALGRIND=1"
 123             address_sanitizer_cppflags="-DVALGRIND=1"
 124             address_sanitizer_ldflags="-Wc,-fsanitize=address"
 125       ])
 126
 127 undefined_sanitizer_cflags=
 128 undefined_sanitizer_cppflags=
 129 undefined_sanitizer_ldflags=
 130 AC_ARG_ENABLE(undefined-sanitizer, AS_HELP_STRING([--enable-undefined-sanitizer], [enable -fsanitize=undefined]))
 131 AS_IF([test "x$enable_undefined_sanitizer" = "xyes"], [
 132             CC_CHECK_FLAG_APPEND([with_us_cflags], [CFLAGS], [-fsanitize=undefined])
 133             AS_IF([test -z "$with_us_cflags"],
 134                   [AC_MSG_ERROR([*** -fsanitize=undefined is not supported])])
 135             undefined_sanitizer_cflags="$with_us_cflags -fno-omit-frame-pointer -DVALGRIND=1"
 136             undefined_sanitizer_cppflags="-DVALGRIND=1"
 137             undefined_sanitizer_ldflags="-Wc,-fsanitize=undefined"
 138       ])
 139
 140 sanitizer_cflags="$address_sanitizer_cflags $undefined_sanitizer_cflags"
 141 sanitizer_cppflags="$address_sanitizer_cppflags $undefined_sanitizer_cppflags"
 142 sanitizer_ldflags="$address_sanitizer_ldflags $undefined_sanitizer_ldflags"
 143
 144 CC_CHECK_FLAGS_APPEND([with_cflags], [CFLAGS], [\
 145         -pipe \
 146         -Wall \
 147         -Wextra \
 148         -Wundef \
 149         "-Wformat=2 -Wformat-security -Wformat-nonliteral" \
 150         -Wlogical-op \
 151         -Wmissing-include-dirs \
 152         -Wold-style-definition \
 153         -Wpointer-arith \
 154         -Winit-self \
 155         -Wdeclaration-after-statement \
 156         -Wfloat-equal \
 157         -Wsuggest-attribute=noreturn \
 158         -Werror=missing-prototypes \
 159         -Werror=implicit-function-declaration \
 160         -Werror=missing-declarations \
 161         -Werror=return-type \
 162         -Werror=shadow \
 163         -Wstrict-prototypes \
 164         -Wredundant-decls \
 165         -Wmissing-noreturn \
 166         -Wshadow \
 167         -Wendif-labels \
 168         -Wstrict-aliasing=2 \
 169         -Wwrite-strings \
 170         -Wno-unused-parameter \
 171         -Wno-missing-field-initializers \
 172         -Wno-unused-result \
 173         -Wno-format-signedness \
 174         -Werror=overflow \
 175         -Wdate-time \
 176         -Wnested-externs \
 177         -ffast-math \
 178         -fno-common \
 179         -fdiagnostics-show-option \
 180         -fno-strict-aliasing \
 181         -fvisibility=hidden \
 182         -fstack-protector \
 183         -fstack-protector-strong \
 184         -fPIE \
 185         --param=ssp-buffer-size=4])
 186
 187 AS_CASE([$CC], [*clang*],
 188         [CC_CHECK_FLAGS_APPEND([with_cppflags], [CPPFLAGS], [\
 189                -Wno-typedef-redefinition \
 190                -Wno-gnu-variable-sized-type-not-at-end \
 191         ])])
 192
 193 dnl AS_CASE([$CFLAGS], [*-O[[12345sz\ ]]*],
 194 dnl         [CC_CHECK_FLAGS_APPEND([with_cflags], [CFLAGS], [\
 195 dnl                -flto -ffat-lto-objects])],
 196 dnl         [AC_MSG_RESULT([skipping -flto, optimization not enabled])])
 197 AC_SUBST([OUR_CFLAGS], "$with_cflags $sanitizer_cflags")
 198
 199 AS_CASE([$CFLAGS], [*-O[[12345sz\ ]]*],
 200         [CC_CHECK_FLAGS_APPEND([with_cppflags], [CPPFLAGS], [\
 201                -Wp,-D_FORTIFY_SOURCE=2])],
 202         [AC_MSG_RESULT([skipping -D_FORTIFY_SOURCE, optimization not enabled])])
 203 AC_SUBST([OUR_CPPFLAGS], "$with_cppflags $sanitizer_cppflags")
 204
 205 AS_CASE([$CFLAGS], [*-O[[12345sz\ ]]*],
 206         [CC_CHECK_FLAGS_APPEND([with_ldflags], [LDFLAGS], [\
 207                -Wl,--gc-sections])],
 208         [AC_MSG_RESULT([skipping --gc-sections, optimization not enabled])])
 209 AC_SUBST([OUR_CFLAGS], "$with_ldflags $sanitizer_cflags")
 210
 211 AS_CASE([$CFLAGS], [*-O[[12345sz\ ]]*],
 212         [CC_CHECK_FLAGS_APPEND([with_cflags], [CFLAGS], [\
 213                -ffunction-sections -fdata-sections])],
 214         [AC_MSG_RESULT([skipping -ffunction/data-section, optimization not enabled])])
 215 AC_SUBST([OUR_CFLAGS], "$with_cflags $sanitizer_cflags")
 216
 217 CC_CHECK_FLAGS_APPEND([with_ldflags], [LDFLAGS], [\
 218         -Wl,--as-needed \
 219         -Wl,--no-undefined \
 220         -Wl,-z,relro \
 221         -Wl,-z,now \
 222         -pie \
 223         -Wl,-fuse-ld=gold])
 224 AC_SUBST([OUR_LDFLAGS], "$with_ldflags $sanitizer_ldflags")
 225
 226 AC_CHECK_SIZEOF(pid_t)
 227 AC_CHECK_SIZEOF(uid_t)
 228 AC_CHECK_SIZEOF(gid_t)
 229 AC_CHECK_SIZEOF(time_t)
 230 AC_CHECK_SIZEOF(dev_t)
 231 AC_CHECK_SIZEOF(rlim_t,,[
 232        #include <sys/time.h>
 233        #include <sys/resource.h>
 234 ])
 235
 236 # ------------------------------------------------------------------------------
 237
 238 AC_CHECK_HEADERS([sys/capability.h], [], [AC_MSG_ERROR([*** POSIX caps headers not found])])
 239 AC_CHECK_HEADERS([linux/btrfs.h], [], [])
 240 AC_CHECK_HEADERS([linux/memfd.h], [], [])
 241
 242 # unconditionally pull-in librt with old glibc versions
 243 AC_SEARCH_LIBS([clock_gettime], [rt], [], [])
 244 AC_SEARCH_LIBS([mq_unlink], [rt], [], [])
 245
 246 AC_ARG_WITH([libcap],
 247             AS_HELP_STRING([--with-libcap=DIR], [Prefix for libcap]),
 248             [CAP_LDFLAGS="-L$with_libcap/lib"],
 249             [CAP_LDFLAGS=""])
 250 save_LIBS="$LIBS"
 251 save_LDFLAGS="$LDFLAGS"
 252 LIBS=
 253 LDFLAGS="$LDFLAGS $CAP_LDFLAGS"
 254 AC_SEARCH_LIBS([cap_init], [cap], [], [AC_MSG_ERROR([*** POSIX caps library not found])])
 255 CAP_LIBS="$LIBS"
 256 AC_SUBST(CAP_LIBS)
 257 AC_SUBST(CAP_LDFLAGS)
 258 LIBS="$save_LIBS"
 259 LDFLAGS="$save_LDFLAGS"
 260
 261 AC_CHECK_FUNCS([memfd_create])
 262 AC_CHECK_FUNCS([__secure_getenv secure_getenv])
 263 AC_CHECK_DECLS([gettid, pivot_root, name_to_handle_at, setns, getrandom, renameat2, kcmp, LO_FLAGS_PARTSCAN],
 264                [], [], [[
 265 #include <sys/types.h>
 266 #include <unistd.h>
 267 #include <sys/mount.h>
 268 #include <fcntl.h>
 269 #include <sched.h>
 270 #include <linux/loop.h>
 271 #include <linux/random.h>
 272 ]])
 273
 274 AC_CHECK_DECLS([IFLA_INET6_ADDR_GEN_MODE,
 275                 IFLA_MACVLAN_FLAGS,
 276                 IFLA_IPVLAN_MODE,
 277                 IFLA_VTI_REMOTE,
 278                 IFLA_PHYS_PORT_ID,
 279                 IFLA_BOND_AD_INFO,
 280                 IFLA_VLAN_PROTOCOL,
 281                 IFLA_VXLAN_REMCSUM_NOPARTIAL,
 282                 IFLA_VXLAN_LOCAL6,
 283                 IFLA_IPTUN_6RD_RELAY_PREFIXLEN,
 284                 IFLA_BRIDGE_VLAN_INFO,
 285                 IFLA_BRPORT_UNICAST_FLOOD,
 286                 NDA_IFINDEX,
 287                 IFA_FLAGS],
 288 [], [], [[
 289 #include <inttypes.h>
 290 #include <netinet/in.h>
 291 #include <netinet/ether.h>
 292 #include <linux/rtnetlink.h>
 293 #include <net/if.h>
 294 #include <linux/ip.h>
 295 #include <linux/if_tunnel.h>
 296 #include <linux/if_link.h>
 297 #include <linux/if_bridge.h>
 298 #include <linux/if_addr.h>
 299 #include <linux/neighbour.h>
 300 ]])
 301
 302 # This makes sure pkg.m4 is available.
 303 m4_pattern_forbid([^_?PKG_[A-Z_]+$],[*** pkg.m4 missing, please install pkg-config])
 304
 305 # ------------------------------------------------------------------------------
 306 have_dbus=no
 307 AC_ARG_ENABLE(dbus, AS_HELP_STRING([--disable-dbus], [disable usage of dbus-1 in tests]))
 308 AS_IF([test "x$enable_dbus" != "xno"], [
 309         PKG_CHECK_MODULES(DBUS, [dbus-1 >= 1.3.2],
 310                 [AC_DEFINE(HAVE_DBUS, 1, [Define if dbus-1 library is available]) have_dbus=yes],
 311                 [have_dbus=no])
 312         AS_IF([test "x$have_dbus" = "xno" -a "x$enable_dbus" = "xyes"],
 313                 [AC_MSG_ERROR([*** dbus-1 support requested but libraries not found])])])
 314 AM_CONDITIONAL(HAVE_DBUS, [test "$have_dbus" = "yes"])
 315
 316 # ------------------------------------------------------------------------------
 317 PKG_CHECK_MODULES(UDEV, [libudev])
 318 dnl
 319 AC_ARG_WITH([udevrulesdir],
 320             AS_HELP_STRING([--with-udevrulesdir=DIR], [Directory for udev rules files]),
 321             [],
 322             [with_udevrulesdir=$($PKG_CONFIG --variable=udevdir udev)/rules.d])
 323 AC_SUBST([udevrulesdir], [$with_udevrulesdir])
 324
 325 AC_ARG_WITH([udevbindir],
 326             AS_HELP_STRING([--with-udevbindir=DIR], [Directory for udev binary files]),
 327             [],
 328             [with_udevbindir=$($PKG_CONFIG --variable=udevdir udev)])
 329 AC_SUBST([udevbindir], [$with_udevbindir])
 330
 331 # ------------------------------------------------------------------------------
 332 have_coverage=no
 333 AC_ARG_ENABLE(coverage, AS_HELP_STRING([--enable-coverage], [enable test coverage]))
 334 if test "x$enable_coverage" = "xyes" ; then
 335         AC_CHECK_PROG(lcov_found, [lcov], [yes], [no])
 336         if test "x$lcov_found" = xno ; then
 337                 AC_MSG_ERROR([*** lcov support requested but the program was not found])
 338         else
 339                 lcov_version_major="`lcov --version | cut -d ' ' -f 4 | cut -d '.' -f 1`"
 340                 lcov_version_minor="`lcov --version | cut -d ' ' -f 4 | cut -d '.' -f 2`"
 341                 if test "$lcov_version_major" -eq 1 -a "$lcov_version_minor" -lt 10; then
 342                         AC_MSG_ERROR([*** lcov version is too old. 1.10 required])
 343                 else
 344                         have_coverage=yes
 345                         CC_CHECK_FLAGS_APPEND([with_coverage_cflags], [CFLAGS], [\
 346                         -fprofile-arcs \
 347                         -ftest-coverage])
 348                         AC_SUBST([OUR_CFLAGS], "$with_cflags $with_coverage_cflags")
 349                 fi
 350         fi
 351 fi
 352 AM_CONDITIONAL(ENABLE_COVERAGE, [test "$have_coverage" = "yes"])
 353
 354 # ------------------------------------------------------------------------------
 355 have_blkid=no
 356 AC_ARG_ENABLE(blkid, AS_HELP_STRING([--disable-blkid], [disable blkid support]))
 357 if test "x$enable_blkid" != "xno"; then
 358         PKG_CHECK_MODULES(BLKID, [ blkid >= 2.24 ],
 359                 [AC_DEFINE(HAVE_BLKID, 1, [Define if blkid is available]) have_blkid=yes], have_blkid=no)
 360         if test "x$have_blkid" = xno -a "x$enable_blkid" = xyes; then
 361                 AC_MSG_ERROR([*** blkid support requested but libraries not found])
 362         fi
 363 fi
 364 AM_CONDITIONAL(HAVE_BLKID, [test "$have_blkid" = "yes"])
 365
 366 # ------------------------------------------------------------------------------
 367 have_seccomp=no
 368 AC_ARG_ENABLE(seccomp, AS_HELP_STRING([--disable-seccomp], [Disable optional SECCOMP support]))
 369 if test "x$enable_seccomp" != "xno"; then
 370         PKG_CHECK_MODULES(SECCOMP, [libseccomp >= 1.0.0],
 371                [AC_DEFINE(HAVE_SECCOMP, 1, [Define if seccomp is available])
 372                 have_seccomp=yes
 373                 M4_DEFINES="$M4_DEFINES -DHAVE_SECCOMP"],
 374                [have_seccomp=no])
 375         if test "x$have_seccomp" = "xno" -a "x$enable_seccomp" = "xyes"; then
 376                 AC_MSG_ERROR([*** seccomp support requested but libraries not found])
 377         fi
 378 fi
 379 AM_CONDITIONAL(HAVE_SECCOMP, [test "$have_seccomp" = "yes"])
 380
 381 # ------------------------------------------------------------------------------
 382 have_selinux=no
 383 AC_ARG_ENABLE(selinux, AS_HELP_STRING([--disable-selinux], [Disable optional SELINUX support]))
 384 if test "x$enable_selinux" != "xno"; then
 385         PKG_CHECK_MODULES([SELINUX], [libselinux >= 2.1.9],
 386                 [AC_DEFINE(HAVE_SELINUX, 1, [Define if SELinux is available])
 387                  have_selinux=yes
 388                  M4_DEFINES="$M4_DEFINES -DHAVE_SELINUX"],
 389                 [have_selinux=no])
 390         if test "x$have_selinux" = xno -a "x$enable_selinux" = xyes; then
 391                 AC_MSG_ERROR([*** SELinux support requested but libraries not found])
 392         fi
 393 fi
 394 AM_CONDITIONAL(HAVE_SELINUX, [test "$have_selinux" = "yes"])
 395
 396 have_apparmor=no
 397 AC_ARG_ENABLE(apparmor, AS_HELP_STRING([--disable-apparmor], [Disable optional AppArmor support]))
 398 if test "x$enable_apparmor" != "xno"; then
 399         PKG_CHECK_MODULES([APPARMOR], [libapparmor],
 400                 [AC_DEFINE(HAVE_APPARMOR, 1, [Define if AppArmor is available])
 401                  have_apparmor=yes
 402                  M4_DEFINES="$M4_DEFINES -DHAVE_APPARMOR"],
 403                 [have_apparmor=no])
 404         if test "x$have_apparmor" = xno -a "x$enable_apparmor" = xyes; then
 405                 AC_MSG_ERROR([*** AppArmor support requested but libraries not found])
 406         fi
 407 fi
 408 AM_CONDITIONAL(HAVE_APPARMOR, [test "$have_apparmor" = "yes"])
 409
 410 # ------------------------------------------------------------------------------
 411 AC_ARG_ENABLE([pam],
 412         AS_HELP_STRING([--disable-pam],[Disable optional PAM support]),
 413                 [case "${enableval}" in
 414                         yes) have_pam=yes ;;
 415                         no) have_pam=no ;;
 416                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-pam) ;;
 417                 esac],
 418                 [have_pam=auto])
 419
 420 if test "x${have_pam}" != xno ; then
 421         AC_CHECK_HEADERS(
 422                 [security/pam_modules.h security/pam_modutil.h security/pam_ext.h],
 423                 [have_pam=yes],
 424                 [if test "x$have_pam" = xyes ; then
 425                         AC_MSG_ERROR([*** PAM headers not found.])
 426                 fi])
 427
 428         AC_CHECK_LIB(
 429                 [pam],
 430                 [pam_syslog],
 431                 [have_pam=yes],
 432                 [if test "x$have_pam" = xyes ; then
 433                         AC_MSG_ERROR([*** libpam not found.])
 434                 fi])
 435
 436         if test "x$have_pam" = xyes ; then
 437                 PAM_LIBS="-lpam -lpam_misc"
 438                 AC_DEFINE(HAVE_PAM, 1, [PAM available])
 439                 M4_DEFINES="$M4_DEFINES -DHAVE_PAM"
 440         else
 441                 have_pam=no
 442         fi
 443 else
 444         PAM_LIBS=
 445 fi
 446 AC_SUBST(PAM_LIBS)
 447 AM_CONDITIONAL([HAVE_PAM], [test "x$have_pam" != xno])
 448
 449 # ------------------------------------------------------------------------------
 450 AC_ARG_ENABLE([acl],
 451         AS_HELP_STRING([--disable-acl],[Disable optional ACL support]),
 452                 [case "${enableval}" in
 453                         yes) have_acl=yes ;;
 454                         no) have_acl=no ;;
 455                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-acl) ;;
 456                 esac],
 457                 [have_acl=auto])
 458
 459 if test "x${have_acl}" != xno ; then
 460         AC_CHECK_HEADERS(
 461                 [sys/acl.h acl/libacl.h],
 462                 [have_acl=yes],
 463                 [if test "x$have_acl" = xyes ; then
 464                         AC_MSG_ERROR([*** ACL headers not found.])
 465                 fi])
 466
 467         AC_CHECK_LIB(
 468                 [acl],
 469                 [acl_get_file],
 470                 [have_acl=yes],
 471                 [if test "x$have_acl" = xyes ; then
 472                         AC_MSG_ERROR([*** libacl not found.])
 473                 fi])
 474
 475         if test "x$have_acl" = xyes ; then
 476                 ACL_LIBS="-lacl"
 477                 AC_DEFINE(HAVE_ACL, 1, [ACL available])
 478                 M4_DEFINES="$M4_DEFINES -DHAVE_ACL"
 479         else
 480                 have_acl=no
 481         fi
 482 else
 483         ACL_LIBS=
 484 fi
 485 AC_SUBST(ACL_LIBS)
 486 AM_CONDITIONAL([HAVE_ACL], [test "x$have_acl" != xno])
 487
 488 # ------------------------------------------------------------------------------
 489 AC_ARG_ENABLE([smack], AS_HELP_STRING([--disable-smack],[Disable optional SMACK support]),
 490                 [case "${enableval}" in
 491                         yes) have_smack=yes ;;
 492                         no) have_smack=no ;;
 493                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-smack) ;;
 494                 esac],
 495                 [have_smack=auto])
 496
 497 if test "x${have_smack}" = xauto; then
 498         M4_DEFINES="$M4_DEFINES -DHAVE_SMACK"
 499         have_smack=yes
 500 fi
 501
 502 AC_ARG_WITH(smack-run-label,
 503 AS_HELP_STRING([--with-smack-run-label=STRING],
 504         [run elogind --system with a specific SMACK label]),
 505         [AC_DEFINE_UNQUOTED(SMACK_RUN_LABEL, ["$withval"], [Run with a smack label])],
 506         [])
 507
 508 if test "x${have_smack}" = xyes ; then
 509         AC_DEFINE(HAVE_SMACK, 1, [Define if SMACK is available])
 510 fi
 511
 512 AM_CONDITIONAL([HAVE_SMACK], [test "x$have_smack" = "xyes"])
 513
 514 # ------------------------------------------------------------------------------
 515 AC_ARG_WITH(system-uid-max,
 516         AS_HELP_STRING([--with-system-uid-max=UID]
 517                 [Maximum UID for system users]),
 518         [SYSTEM_UID_MAX="$withval"],
 519         [SYSTEM_UID_MAX="`awk 'BEGIN { uid=999 } /^\s*SYS_UID_MAX\s+/ { uid=$2 } END { print uid }' /etc/login.defs 2>/dev/null || echo 999`"])
 520
 521 AC_DEFINE_UNQUOTED(SYSTEM_UID_MAX, [$SYSTEM_UID_MAX], [Maximum System UID])
 522 AC_SUBST(SYSTEM_UID_MAX)
 523
 524 # ------------------------------------------------------------------------------
 525 AC_ARG_WITH(system-gid-max,
 526         AS_HELP_STRING([--with-system-gid-max=GID]
 527                 [Maximum GID for system groups]),
 528         [SYSTEM_GID_MAX="$withval"],
 529         [SYSTEM_GID_MAX="`awk 'BEGIN { gid=999 } /^\s*SYS_GID_MAX\s+/ { gid=$2 } END { print gid }' /etc/login.defs 2>/dev/null || echo 999`"])
 530
 531 AC_DEFINE_UNQUOTED(SYSTEM_GID_MAX, [$SYSTEM_GID_MAX], [Maximum System GID])
 532 AC_SUBST(SYSTEM_GID_MAX)
 533
 534 # ------------------------------------------------------------------------------
 535 have_polkit=no
 536 AC_ARG_ENABLE(polkit, AS_HELP_STRING([--disable-polkit], [disable PolicyKit support]))
 537 if test "x$enable_polkit" != "xno"; then
 538         AC_DEFINE(ENABLE_POLKIT, 1, [Define if PolicyKit support is to be enabled])
 539         have_polkit=yes
 540 fi
 541 AM_CONDITIONAL(ENABLE_POLKIT, [test "x$have_polkit" = "xyes"])
 542
 543 # ------------------------------------------------------------------------------
 544 have_kdbus=no
 545 AC_ARG_ENABLE(kdbus, AS_HELP_STRING([--disable-kdbus], [do not connect to kdbus by default]))
 546 if test "x$enable_kdbus" != "xno"; then
 547         AC_DEFINE(ENABLE_KDBUS, 1, [Define if kdbus is to be connected to by default])
 548         have_kdbus=yes
 549         M4_DEFINES="$M4_DEFINES -DENABLE_KDBUS"
 550 fi
 551 AM_CONDITIONAL(ENABLE_KDBUS, [test "$have_kdbus" = "yes"])
 552
 553 # ------------------------------------------------------------------------------
 554 AC_CHECK_HEADERS_ONCE([valgrind/memcheck.h valgrind/valgrind.h])
 555
 556 # ------------------------------------------------------------------------------
 557 PKG_CHECK_MODULES([GLIB], [glib-2.0 >= 2.22.0 gobject-2.0 >= 2.22.0 gio-2.0],
 558                   [have_glib=yes], [have_glib=no])
 559 AS_IF([test "x$have_glib" = "xyes"], [ AC_DEFINE(HAVE_GLIB, 1, [Define if glib is available]) ])
 560
 561 # ------------------------------------------------------------------------------
 562 have_manpages=no
 563 AC_ARG_ENABLE(manpages, AS_HELP_STRING([--disable-manpages], [disable manpages]))
 564 AS_IF([test "x$enable_manpages" != xno], [have_manpages=yes])
 565 AM_CONDITIONAL(ENABLE_MANPAGES, [test "x$have_manpages" = "xyes"])
 566
 567 # ------------------------------------------------------------------------------
 568 AC_SUBST(M4_DEFINES)
 569
 570 AC_ARG_WITH([dbuspolicydir],
 571         AS_HELP_STRING([--with-dbuspolicydir=DIR], [D-Bus policy directory]),
 572         [],
 573         [with_dbuspolicydir=${sysconfdir}/dbus-1/system.d])
 574 AX_NORMALIZE_PATH([with_dbuspolicydir])
 575
 576 AC_ARG_WITH([dbussystemservicedir],
 577         AS_HELP_STRING([--with-dbussystemservicedir=DIR], [D-Bus system service directory]),
 578         [],
 579         [with_dbussystemservicedir=${datadir}/dbus-1/system-services])
 580 AX_NORMALIZE_PATH([with_dbussystemservicedir])
 581
 582 AC_ARG_WITH([bashcompletiondir],
 583         AS_HELP_STRING([--with-bashcompletiondir=DIR], [Bash completions directory]),
 584         [],
 585         [AS_IF([$($PKG_CONFIG --exists bash-completion)], [
 586                 with_bashcompletiondir=$($PKG_CONFIG --variable=completionsdir bash-completion)
 587         ] , [
 588                 with_bashcompletiondir=${datadir}/bash-completion/completions
 589         ])])
 590 AX_NORMALIZE_PATH([with_bashcompletiondir])
 591
 592 AC_ARG_WITH([zshcompletiondir],
 593         AS_HELP_STRING([--with-zshcompletiondir=DIR], [Zsh completions directory]),
 594         [], [with_zshcompletiondir=${datadir}/zsh/site-functions])
 595 AX_NORMALIZE_PATH([with_zshcompletiondir])
 596
 597 AC_ARG_WITH([rootprefix],
 598         AS_HELP_STRING([--with-rootprefix=DIR], [rootfs directory prefix for config files and kernel modules]),
 599         [], [with_rootprefix=${ac_default_prefix}])
 600 # --with-rootprefix= (empty) should default to "/" but AX_NORMALIZE_PATH
 601 # defaults those to ".", solve that here for now until we can find a suitable
 602 # fix for AX_NORMALIZE_PATH upstream at autoconf-archive.
 603 # See: https://github.com/systemd/systemd/issues/54
 604 if test "x${with_rootprefix}" = "x"; then
 605         with_rootprefix="/"
 606 fi
 607 AX_NORMALIZE_PATH([with_rootprefix])
 608
 609 AC_ARG_WITH([rootlibdir],
 610         AS_HELP_STRING([--with-rootlibdir=DIR], [Root directory for libraries necessary for boot]),
 611         [],
 612         [with_rootlibdir=${libdir}])
 613 AX_NORMALIZE_PATH([with_rootlibdir])
 614
 615 AC_ARG_WITH([pamlibdir],
 616         AS_HELP_STRING([--with-pamlibdir=DIR], [Directory for PAM modules]),
 617         [],
 618         [with_pamlibdir=${with_rootlibdir}/security])
 619 AX_NORMALIZE_PATH([with_pamlibdir])
 620
 621 AC_ARG_WITH([pamconfdir],
 622         AS_HELP_STRING([--with-pamconfdir=DIR], [Directory for PAM configuration]),
 623         [],
 624         [with_pamconfdir=${sysconfdir}/pam.d])
 625 AX_NORMALIZE_PATH([with_pamconfdir])
 626
 627 AC_ARG_ENABLE([split-usr],
 628         AS_HELP_STRING([--enable-split-usr], [Assume that /bin, /sbin aren\'t symlinks into /usr]),
 629         [],
 630         [AS_IF([test "x${ac_default_prefix}" != "x${with_rootprefix}"], [
 631                 enable_split_usr=yes
 632         ], [
 633                 enable_split_usr=no
 634         ])])
 635
 636 AS_IF([test "x${enable_split_usr}" = "xyes"], [
 637         AC_DEFINE(HAVE_SPLIT_USR, 1, [Define if /bin, /sbin aren't symlinks into /usr])
 638 ])
 639 AM_CONDITIONAL(ENABLE_SPLIT_USR, [test "x${enable_split_usr}" = "xyes"])
 640
 641 # work around intltool-update issues during 'make distcheck'
 642 AS_IF([test "x$0" != "x./configure"], [
 643         AC_SUBST([INTLTOOL_UPDATE], [/usr/bin/env true])
 644 ])
 645
 646 AC_ARG_ENABLE(tests,
 647         [AC_HELP_STRING([--disable-tests], [disable tests])],
 648         enable_tests=$enableval, enable_tests=yes)
 649 AM_CONDITIONAL(ENABLE_TESTS, [test x$enable_tests = xyes])
 650
 651 AC_ARG_ENABLE(debug,
 652         [AC_HELP_STRING([--enable-debug@<:@=LIST@:>@], [enable extra debugging (hashmap,mmap-cache)])],
 653         [if test "x$enableval" = "xyes"; then
 654                 enableval="hashmap,mmap-cache"
 655         fi
 656         saved_ifs="$IFS"
 657         IFS="$IFS$PATH_SEPARATOR,"
 658         for name in $enableval; do
 659                 case $name in
 660                 hashmap)
 661                         enable_debug_hashmap=yes
 662                         ;;
 663                 mmap-cache)
 664                         enable_debug_mmap_cache=yes
 665                         ;;
 666                 esac
 667         done
 668         IFS="$saved_ifs"],[])
 669
 670 enable_debug=""
 671 AS_IF([test x$enable_debug_hashmap = xyes], [
 672         AC_DEFINE(ENABLE_DEBUG_HASHMAP, 1, [Define if hashmap debugging is to be enabled])
 673         enable_debug="hashmap $enable_debug"
 674 ])
 675 AS_IF([test x$enable_debug_mmap_cache = xyes], [
 676         AC_DEFINE(ENABLE_DEBUG_MMAP_CACHE, 1, [Define if mmap cache debugging is to be enabled])
 677         enable_debug="mmap-cache $enable_debug"
 678 ])
 679 test -z "$enable_debug" && enable_debug="none"
 680
 681 AC_SUBST([dbuspolicydir], [$with_dbuspolicydir])
 682 AC_SUBST([dbussystemservicedir], [$with_dbussystemservicedir])
 683 AC_SUBST([bashcompletiondir], [$with_bashcompletiondir])
 684 AC_SUBST([zshcompletiondir], [$with_zshcompletiondir])
 685 AC_SUBST([pamlibdir], [$with_pamlibdir])
 686 AC_SUBST([pamconfdir], [$with_pamconfdir])
 687 AC_SUBST([rootprefix], [$with_rootprefix])
 688 AC_SUBST([rootlibdir], [$with_rootlibdir])
 689
 690 AC_CONFIG_FILES([
 691         Makefile
 692         po/Makefile.in
 693 ])
 694
 695 AC_OUTPUT
 696 AC_MSG_RESULT([
 697         $PACKAGE_NAME $VERSION
 698
 699         PAM:                     ${have_pam}
 700         AppArmor:                ${have_apparmor}
 701         SELinux:                 ${have_selinux}
 702         SECCOMP:                 ${have_seccomp}
 703         SMACK:                   ${have_smack}
 704         ACL:                     ${have_acl}
 705         polkit:                  ${have_polkit}
 706         blkid:                   ${have_blkid}
 707         dbus:                    ${have_dbus}
 708         kdbus:                   ${have_kdbus}
 709         man pages:               ${have_manpages}
 710         test coverage:           ${have_coverage}
 711         Split /usr:              ${enable_split_usr}
 712         extra debugging:         ${enable_debug}
 713
 714         prefix:                  ${prefix}
 715         rootprefix:              ${with_rootprefix}
 716         sysconf dir:             ${sysconfdir}
 717         datarootdir:             ${datarootdir}
 718         includedir:              ${includedir}
 719         lib dir:                 ${libdir}
 720         rootlib dir:             ${with_rootlibdir}
 721         PAM modules dir:         ${with_pamlibdir}
 722         PAM configuration dir:   ${with_pamconfdir}
 723         D-Bus policy dir:        ${with_dbuspolicydir}
 724         D-Bus system dir:        ${with_dbussystemservicedir}
 725         Bash completions dir:    ${with_bashcompletiondir}
 726         Zsh completions dir:     ${with_zshcompletiondir}
 727         Maximum System UID:      ${SYSTEM_UID_MAX}
 728         Maximum System GID:      ${SYSTEM_GID_MAX}
 729
 730         CFLAGS:                  ${OUR_CFLAGS} ${CFLAGS}
 731         CPPFLAGS:                ${OUR_CPPFLAGS} ${CPPFLAGS}
 732         LDFLAGS:                 ${OUR_LDFLAGS} ${LDFLAGS}
 733 ])