configure.ac

   1 #  This file is part of systemd.
   2 #
   3 #  Copyright 2010 Lennart Poettering
   4 #
   5 #  systemd is free software; you can redistribute it and/or modify it
   6 #  under the terms of the GNU General Public License as published by
   7 #  the Free Software Foundation; either version 2 of the License, or
   8 #  (at your option) any later version.
   9 #
  10 #  systemd is distributed in the hope that it will be useful, but
  11 #  WITHOUT ANY WARRANTY; without even the implied warranty of
  12 #  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
  13 #  General Public License for more details.
  14 #
  15 #  You should have received a copy of the GNU General Public License
  16 #  along with systemd; If not, see <http://www.gnu.org/licenses/>.
  17
  18 AC_PREREQ(2.63)
  19
  20 AC_INIT([systemd],[17],[systemd-devel@lists.freedesktop.org])
  21 AC_CONFIG_SRCDIR([src/main.c])
  22 AC_CONFIG_MACRO_DIR([m4])
  23 AC_CONFIG_HEADERS([config.h])
  24
  25 AM_INIT_AUTOMAKE([foreign 1.11 -Wall -Wno-portability silent-rules tar-pax subdir-objects dist-bzip2])
  26
  27 AC_SUBST(PACKAGE_URL, [http://www.freedesktop.org/wiki/Software/systemd])
  28
  29 AC_CANONICAL_HOST
  30 AC_DEFINE_UNQUOTED([CANONICAL_HOST], "$host", [Canonical host string.])
  31
  32 AM_SILENT_RULES([yes])
  33
  34 AC_CHECK_PROG([STOW], [stow], [yes], [no])
  35
  36 AS_IF([test "x$STOW" = "xyes" && test -d /usr/local/stow], [
  37         AC_MSG_NOTICE([*** Found /usr/local/stow: default install prefix set to /usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION} ***])
  38         ac_default_prefix="/usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION}"
  39 ])
  40
  41 AC_PROG_MKDIR_P
  42 AC_PROG_LN_S
  43 AC_PROG_SED
  44
  45 AC_PROG_CC
  46 AC_PROG_CC_C99
  47 AM_PROG_CC_C_O
  48 AC_PROG_GCC_TRADITIONAL
  49 AC_USE_SYSTEM_EXTENSIONS
  50
  51 AC_CHECK_TOOL(OBJCOPY, objcopy)
  52 AC_CHECK_TOOL(STRINGS, strings)
  53
  54 CC_CHECK_CFLAGS_APPEND([ \
  55         -pipe \
  56         -Wall \
  57         -W \
  58         -Wextra \
  59         -Wno-inline \
  60         -Wvla \
  61         -Wundef \
  62         -Wformat=2 \
  63         -Wlogical-op \
  64         -Wsign-compare \
  65         -Wformat-security \
  66         -Wmissing-include-dirs \
  67         -Wformat-nonliteral \
  68         -Wold-style-definition \
  69         -Wpointer-arith \
  70         -Winit-self \
  71         -Wdeclaration-after-statement \
  72         -Wfloat-equal \
  73         -Wmissing-prototypes \
  74         -Wstrict-prototypes \
  75         -Wredundant-decls \
  76         -Wmissing-declarations \
  77         -Wmissing-noreturn \
  78         -Wshadow \
  79         -Wendif-labels \
  80         -Wcast-align \
  81         -Wstrict-aliasing=2 \
  82         -Wwrite-strings \
  83         -Wno-long-long \
  84         -Wno-overlength-strings \
  85         -Wno-unused-parameter \
  86         -Wno-missing-field-initializers \
  87         -Wno-unused-result \
  88         -Wp,-D_FORTIFY_SOURCE=2 \
  89         -ffast-math \
  90         -fno-common \
  91         -fdiagnostics-show-option \
  92         -fno-strict-aliasing \
  93         -fvisibility=hidden \
  94         -ffunction-sections \
  95         -fdata-sections \
  96         -Wl,--as-needed \
  97         -Wl,--gc-sections])
  98
  99 LT_PREREQ(2.2)
 100 LT_INIT
 101
 102 AC_SEARCH_LIBS([clock_gettime], [rt], [], [AC_MSG_ERROR([*** POSIX RT library not found])])
 103 AC_SEARCH_LIBS([dlsym], [dl], [], [AC_MSG_ERROR([*** Dynamic linking loader library not found])])
 104 AC_SEARCH_LIBS([cap_init], [cap], [], [AC_MSG_ERROR([*** POSIX caps library not found])])
 105 AC_CHECK_HEADERS([sys/capability.h], [], [AC_MSG_ERROR([*** POSIX caps headers not found])])
 106
 107 # This makes sure pkg.m4 is available.
 108 m4_pattern_forbid([^_?PKG_[A-Z_]+$],[*** pkg.m4 missing, please install pkg-config])
 109
 110 PKG_CHECK_MODULES(UDEV, [ libudev >= 160 ])
 111 AC_SUBST(UDEV_CFLAGS)
 112 AC_SUBST(UDEV_LIBS)
 113
 114 PKG_CHECK_MODULES(DBUS, [ dbus-1 >= 1.3.2 ])
 115 AC_SUBST(DBUS_CFLAGS)
 116 AC_SUBST(DBUS_LIBS)
 117
 118 PKG_CHECK_MODULES(SELINUX, libselinux,
 119         have_selinux=yes,
 120         have_selinux=no)
 121 if test "x$have_selinux" = "xyes" ; then
 122         AC_DEFINE(HAVE_SELINUX, [], [Define if SELINUX is available])
 123 fi
 124 AM_CONDITIONAL(HAVE_SELINUX, test x$have_selinux = xyes)
 125 AC_SUBST(SELINUX_CFLAGS)
 126 AC_SUBST(SELINUX_LIBS)
 127
 128 AC_ARG_ENABLE([tcpwrap],
 129         AS_HELP_STRING([--disable-tcpwrap],[Disable optional TCP wrappers support]),
 130                 [case "${enableval}" in
 131                         yes) have_tcpwrap=yes ;;
 132                         no) have_tcpwrap=no ;;
 133                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-tcpwrap) ;;
 134                 esac],
 135                 [have_tcpwrap=auto])
 136
 137 if test "x${have_tcpwrap}" != xno ; then
 138         ACX_LIBWRAP
 139         if test "x${LIBWRAP_LIBS}" = x ; then
 140                 if test "x$have_tcpwrap" = xyes ; then
 141                         AC_MSG_ERROR([*** TCP wrappers support not found.])
 142                 fi
 143                 have_tcpwrap=no
 144         else
 145                 have_tcpwrap=yes
 146         fi
 147 else
 148         LIBWRAP_LIBS=
 149 fi
 150 AC_SUBST(LIBWRAP_LIBS)
 151
 152 AC_ARG_ENABLE([pam],
 153         AS_HELP_STRING([--disable-pam],[Disable optional PAM support]),
 154                 [case "${enableval}" in
 155                         yes) have_pam=yes ;;
 156                         no) have_pam=no ;;
 157                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-pam) ;;
 158                 esac],
 159                 [have_pam=auto])
 160
 161 if test "x${have_pam}" != xno ; then
 162         AC_CHECK_HEADERS(
 163                 [security/pam_modules.h security/pam_modutil.h security/pam_ext.h],
 164                 [have_pam=yes],
 165                 [if test "x$have_pam" = xyes ; then
 166                         AC_MSG_ERROR([*** PAM headers not found.])
 167                 fi])
 168
 169         AC_CHECK_LIB(
 170                 [pam],
 171                 [pam_syslog],
 172                 [have_pam=yes],
 173                 [if test "x$have_pam" = xyes ; then
 174                         AC_MSG_ERROR([*** libpam not found.])
 175                 fi])
 176
 177         if test "x$have_pam" = xyes ; then
 178                 PAM_LIBS="-lpam -lpam_misc"
 179                 AC_DEFINE(HAVE_PAM, 1, [PAM available])
 180         else
 181                 have_pam=no
 182         fi
 183 else
 184         PAM_LIBS=
 185 fi
 186 AC_SUBST(PAM_LIBS)
 187 AM_CONDITIONAL([HAVE_PAM], [test "x$have_pam" != xno])
 188
 189 AC_ARG_ENABLE([audit],
 190         AS_HELP_STRING([--disable-audit],[Disable optional AUDIT support]),
 191                 [case "${enableval}" in
 192                         yes) have_audit=yes ;;
 193                         no) have_audit=no ;;
 194                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-audit) ;;
 195                 esac],
 196                 [have_audit=auto])
 197
 198 if test "x${have_audit}" != xno ; then
 199         AC_CHECK_HEADERS(
 200                 [libaudit.h],
 201                 [have_audit=yes],
 202                 [if test "x$have_audit" = xyes ; then
 203                         AC_MSG_ERROR([*** AUDIT headers not found.])
 204                 fi])
 205
 206         AC_CHECK_LIB(
 207                 [audit],
 208                 [audit_open],
 209                 [have_audit=yes],
 210                 [if test "x$have_audit" = xyes ; then
 211                         AC_MSG_ERROR([*** libaudit not found.])
 212                 fi])
 213
 214         if test "x$have_audit" = xyes ; then
 215                 AUDIT_LIBS="-laudit"
 216                 AC_DEFINE(HAVE_AUDIT, 1, [AUDIT available])
 217         else
 218                 have_audit=no
 219         fi
 220 else
 221         AUDIT_LIBS=
 222 fi
 223 AC_SUBST(AUDIT_LIBS)
 224
 225 have_libcryptsetup=no
 226 AC_ARG_ENABLE(libcryptsetup, AS_HELP_STRING([--disable-libcryptsetup], [disable libcryptsetup tools]))
 227 if test "x$enable_libcryptsetup" != "xno"; then
 228         PKG_CHECK_MODULES(LIBCRYPTSETUP, [ libcryptsetup ],
 229                 [AC_DEFINE(HAVE_LIBCRYPTSETUP, 1, [Define if libcryptsetup is available]) have_libcryptsetup=yes], have_libcryptsetup=no)
 230         AC_SUBST(LIBCRYPTSETUP_CFLAGS)
 231         AC_SUBST(LIBCRYPTSETUP_LIBS)
 232         if test "x$have_libcryptsetup" = xno -a "x$enable_libcryptsetup" = xyes; then
 233              AC_MSG_ERROR([*** libcryptsetup support requested but libraries not found])
 234         fi
 235 fi
 236 AM_CONDITIONAL(HAVE_LIBCRYPTSETUP, [test "$have_libcryptsetup" = "yes"])
 237
 238 have_gtk=no
 239 AC_ARG_ENABLE(gtk, AS_HELP_STRING([--disable-gtk], [disable GTK tools]))
 240 if test "x$enable_gtk" != "xno"; then
 241         PKG_CHECK_MODULES(GTK, [ gtk+-2.0 glib-2.0 > 2.26 gio-unix-2.0 ],
 242                 [AC_DEFINE(HAVE_GTK, 1, [Define if GTK is available]) have_gtk=yes], have_gtk=no)
 243         AC_SUBST(GTK_CFLAGS)
 244         AC_SUBST(GTK_LIBS)
 245         if test "x$have_gtk" = xno -a "x$enable_gtk" = xyes; then
 246                 AC_MSG_ERROR([*** gtk support requested but libraries not found])
 247         fi
 248 fi
 249 AM_CONDITIONAL(HAVE_GTK, [test "$have_gtk" = "yes"])
 250
 251 if test "$have_gtk" = "yes"; then
 252         PKG_CHECK_MODULES(LIBNOTIFY, [ libnotify ])
 253         PKG_CHECK_EXISTS([ libnotify >= 0.7.0 ], [ libnotify07=yes ])
 254
 255         AC_SUBST(LIBNOTIFY_CFLAGS)
 256         AC_SUBST(LIBNOTIFY_LIBS)
 257 fi
 258 AM_CONDITIONAL(LIBNOTIFY07, [ test "$libnotify07" = "yes" ])
 259
 260 AM_PROG_VALAC([0.10])
 261 AC_SUBST(VAPIDIR)
 262 AM_CONDITIONAL(HAVE_VALAC, test x"$VALAC" != x)
 263
 264 AC_PATH_PROG([XSLTPROC], [xsltproc])
 265 AM_CONDITIONAL(HAVE_XSLTPROC, test x"$XSLTPROC" != x)
 266
 267 AC_PATH_PROG([M4], [m4])
 268
 269 AC_ARG_WITH(distro, AS_HELP_STRING([--with-distro=DISTRO],[Specify the distribution to target: One of fedora, suse, debian, ubuntu, arch, gentoo, slackware or other]))
 270 if test "z$with_distro" = "z"; then
 271         if test "$cross_compiling" = yes; then
 272                 AC_MSG_WARN([Target distribution cannot be reliably detected when cross-compiling. You should specify it with --with-distro (see $0 --help for recognized distros)])
 273         else
 274                 AC_CHECK_FILE(/etc/redhat-release,with_distro="fedora")
 275                 AC_CHECK_FILE(/etc/SuSE-release,with_distro="suse")
 276                 AC_CHECK_FILE(/etc/debian_version,with_distro="debian")
 277                 if test "x`lsb_release -is 2>/dev/null`" = "xUbuntu"; then
 278                         with_distro="ubuntu"
 279                 fi
 280                 AC_CHECK_FILE(/etc/arch-release,with_distro="arch")
 281                 AC_CHECK_FILE(/etc/gentoo-release,with_distro="gentoo")
 282                 AC_CHECK_FILE(/etc/slackware-version,with_distro="slackware")
 283                 AC_CHECK_FILE(/etc/frugalware-release,with_distro="frugalware")
 284         fi
 285         if test "z$with_distro" = "z"; then
 286                 with_distro=`uname -s`
 287         fi
 288 fi
 289 with_distro=`echo ${with_distro} | tr '[[:upper:]]' '[[:lower:]]' `
 290 AC_DEFINE_UNQUOTED(DISTRIBUTION, ["${with_distro}"], [Target Distribution])
 291
 292 # Default generic names
 293 SPECIAL_SYSLOG_SERVICE=syslog.service
 294
 295 # Location of the init scripts as mandated by LSB
 296 SYSTEM_SYSVINIT_PATH=/etc/init.d
 297
 298 M4_DISTRO_FLAG=
 299
 300 case $with_distro in
 301         fedora)
 302                 SYSTEM_SYSVINIT_PATH=/etc/rc.d/init.d
 303                 SYSTEM_SYSVRCND_PATH=/etc/rc.d
 304
 305                 # A little background why we define this special unit
 306                 # names here in configure.ac: SysV services currently
 307                 # cannot have aliases. As long as syslog is started
 308                 # via a SysV init script we hence define this name to
 309                 # the actual SysV name here. Later on when SysV init
 310                 # scripts are not used anymore it is advisable to use
 311                 # the generic name instead and use symlinks in the
 312                 # unit directories to point to the right native unit
 313                 # file.
 314
 315                 SPECIAL_SYSLOG_SERVICE=rsyslog.service
 316                 AC_DEFINE(TARGET_FEDORA, [], [Target is Fedora/RHEL])
 317                 M4_DISTRO_FLAG=-DTARGET_FEDORA=1
 318                 ;;
 319         suse)
 320                 SYSTEM_SYSVRCND_PATH=/etc/init.d
 321                 AC_DEFINE(TARGET_SUSE, [], [Target is openSUSE/SLE])
 322                 M4_DISTRO_FLAG=-DTARGET_SUSE=1
 323                 ;;
 324         debian)
 325                 SYSTEM_SYSVRCND_PATH=/etc
 326                 SPECIAL_SYSLOG_SERVICE=rsyslog.service
 327                 AC_DEFINE(TARGET_DEBIAN, [], [Target is Debian])
 328                 M4_DISTRO_FLAG=-DTARGET_DEBIAN=1
 329                 ;;
 330         ubuntu)
 331                 SYSTEM_SYSVRCND_PATH=/etc
 332                 SPECIAL_SYSLOG_SERVICE=rsyslog.service
 333                 AC_DEFINE(TARGET_UBUNTU, [], [Target is Ubuntu])
 334                 M4_DISTRO_FLAG=-DTARGET_UBUNTU=1
 335                 ;;
 336         arch)
 337                 SYSTEM_SYSVINIT_PATH=/etc/rc.d
 338                 SYSTEM_SYSVRCND_PATH=/etc
 339                 SPECIAL_SYSLOG_SERVICE=syslog-ng.service
 340                 AC_DEFINE(TARGET_ARCH, [], [Target is ArchLinux])
 341                 M4_DISTRO_FLAG=-DTARGET_ARCH=1
 342                 ;;
 343         gentoo)
 344                 SYSTEM_SYSVINIT_PATH=
 345                 SYSTEM_SYSVRCND_PATH=
 346                 SPECIAL_SYSLOG_SERVICE=syslog-ng.service
 347                 AC_DEFINE(TARGET_GENTOO, [], [Target is Gentoo])
 348                 M4_DISTRO_FLAG=-DTARGET_GENTOO=1
 349                 ;;
 350         slackware)
 351                 SYSTEM_SYSVINIT_PATH=/etc/rc.d/init.d
 352                 SYSTEM_SYSVRCND_PATH=/etc/rc.d
 353                 AC_DEFINE(TARGET_SLACKWARE, [], [Target is Slackware])
 354                 M4_DISTRO_FLAG=-DTARGET_SLACKWARE=1
 355                 ;;
 356         frugalware)
 357                 SYSTEM_SYSVINIT_PATH=/etc/rc.d
 358                 SYSTEM_SYSVRCND_PATH=/etc/rc.d
 359                 AC_DEFINE(TARGET_FRUGALWARE, [], [Target is Frugalware])
 360                 M4_DISTRO_FLAG=-DTARGET_FRUGALWARE=1
 361                 ;;
 362         other)
 363                 AS_IF([test "x$with_syslog_service" = "x"],
 364                         [AC_MSG_ERROR([With --distro=other, you must pass --with-syslog-service= to configure])])
 365                 ;;
 366         *)
 367                 AC_MSG_ERROR([Your distribution (${with_distro}) is not yet supported, SysV init scripts could not be found! (patches welcome); you can specify --with-distro=other to skip this check])
 368                 ;;
 369 esac
 370
 371 AC_ARG_WITH([sysvinit-path],
 372         [AS_HELP_STRING([--with-sysvinit-path=PATH],
 373                 [Specify the path to where the SysV init scripts are located @<:@default=based on distro@:>@])],
 374         [SYSTEM_SYSVINIT_PATH="$withval"],
 375         [])
 376
 377 AC_ARG_WITH([sysvrcd-path],
 378         [AS_HELP_STRING([--with-sysvrcd-path=PATH],
 379                 [Specify the path to the base directory for the SysV rcN.d directories @<:@default=based on distro@:>@])],
 380         [SYSTEM_SYSVRCND_PATH="$withval"],
 381         [])
 382
 383 AC_ARG_WITH([syslog-service],
 384         [AS_HELP_STRING([--with-syslog-service=UNIT],
 385                 [Specify the name of the special syslog service @<:@default=based on distro@:>@])],
 386         [SPECIAL_SYSLOG_SERVICE="$withval"],
 387         [])
 388
 389 AC_SUBST(SYSTEM_SYSVINIT_PATH)
 390 AC_SUBST(SYSTEM_SYSVRCND_PATH)
 391 AC_SUBST(SPECIAL_SYSLOG_SERVICE)
 392 AC_SUBST(M4_DISTRO_FLAG)
 393
 394 if test "x${SYSTEM_SYSVINIT_PATH}" != "x" -a "x${SYSTEM_SYSVRCND_PATH}" != "x"; then
 395         AC_DEFINE(HAVE_SYSV_COMPAT, [], [SysV init scripts and rcN.d links are supported.])
 396         SYSTEM_SYSV_COMPAT="yes"
 397 elif test "x${SYSTEM_SYSVINIT_PATH}" != "x" -o "x${SYSTEM_SYSVRCND_PATH}" != "x"; then
 398         AC_MSG_ERROR([*** You need both --with-sysvinit-path=PATH and --with-sysvrcd-path=PATH to enable SysV compatibility support, or both empty to disable it.])
 399 else
 400         SYSTEM_SYSV_COMPAT="no"
 401 fi
 402
 403 AC_ARG_WITH([tty-gid],
 404         [AS_HELP_STRING([--with-tty-gid=GID],
 405                 [Specify the numeric GID of the 'tty' group])],
 406         [AC_DEFINE_UNQUOTED(TTY_GID, [$withval], [GID of the 'tty' group])],
 407         [])
 408
 409 AM_CONDITIONAL(TARGET_FEDORA, test x"$with_distro" = xfedora)
 410 AM_CONDITIONAL(TARGET_SUSE, test x"$with_distro" = xsuse)
 411 AM_CONDITIONAL(TARGET_DEBIAN, test x"$with_distro" = xdebian)
 412 AM_CONDITIONAL(TARGET_UBUNTU, test x"$with_distro" = xubuntu)
 413 AM_CONDITIONAL(TARGET_DEBIAN_OR_UBUNTU, test x"$with_distro" = xdebian -o x"$with_distro" = xubuntu)
 414 AM_CONDITIONAL(TARGET_ARCH, test x"$with_distro" = xarch)
 415 AM_CONDITIONAL(TARGET_GENTOO, test x"$with_distro" = xgentoo)
 416 AM_CONDITIONAL(TARGET_SLACKWARE, test x"$with_distro" = xslackware)
 417 AM_CONDITIONAL(TARGET_FRUGALWARE, test x"$with_distro" = xfrugalware)
 418
 419 AC_DEFINE_UNQUOTED(SPECIAL_SYSLOG_SERVICE, ["$SPECIAL_SYSLOG_SERVICE"], [Syslog service name])
 420
 421 AC_ARG_WITH([dbuspolicydir],
 422         AS_HELP_STRING([--with-dbuspolicydir=DIR], [D-Bus policy directory]),
 423         [],
 424         [with_dbuspolicydir=`pkg-config --variable=sysconfdir dbus-1`/dbus-1/system.d])
 425
 426 AC_ARG_WITH([dbussessionservicedir],
 427         AS_HELP_STRING([--with-dbussessionservicedir=DIR], [D-Bus session service directory]),
 428         [],
 429         [with_dbussessionservicedir=`pkg-config --variable=session_bus_services_dir dbus-1`])
 430
 431 AC_ARG_WITH([dbussystemservicedir],
 432         AS_HELP_STRING([--with-dbussystemservicedir=DIR], [D-Bus system service directory]),
 433         [],
 434         [with_dbussystemservicedir=`pkg-config --variable=session_bus_services_dir dbus-1`/../system-services])
 435
 436 AC_ARG_WITH([dbusinterfacedir],
 437         AS_HELP_STRING([--with-dbusinterfacedir=DIR], [D-Bus interface directory]),
 438         [],
 439         [with_dbusinterfacedir=`pkg-config --variable=session_bus_services_dir dbus-1`/../interfaces])
 440
 441 AC_ARG_WITH([udevrulesdir],
 442         AS_HELP_STRING([--with-udevrulesdir=DIR], [Diectory for udev rules]),
 443         [],
 444         [with_udevrulesdir=`pkg-config --variable=udevdir udev`/rules.d])
 445
 446 AC_ARG_WITH([pamlibdir],
 447         AS_HELP_STRING([--with-pamlibdir=DIR], [Diectory for PAM modules]),
 448         [],
 449         [with_pamlibdir=/lib/`$CC -print-multi-os-directory`/security])
 450
 451 AC_ARG_WITH([rootdir],
 452         AS_HELP_STRING([--with-rootdir=DIR], [Root directory for files necessary for boot]),
 453         [],
 454         [with_rootdir=${ac_default_prefix}])
 455
 456 AC_SUBST([dbuspolicydir], [$with_dbuspolicydir])
 457 AC_SUBST([dbussessionservicedir], [$with_dbussessionservicedir])
 458 AC_SUBST([dbussystemservicedir], [$with_dbussystemservicedir])
 459 AC_SUBST([dbusinterfacedir], [$with_dbusinterfacedir])
 460 AC_SUBST([udevrulesdir], [$with_udevrulesdir])
 461 AC_SUBST([pamlibdir], [$with_pamlibdir])
 462 AC_SUBST([rootdir], [$with_rootdir])
 463
 464 AC_CONFIG_FILES([Makefile])
 465 AC_OUTPUT
 466
 467 echo "
 468         $PACKAGE_NAME $VERSION
 469
 470         Distribution:            ${with_distro}
 471         SysV compatibility:      ${SYSTEM_SYSV_COMPAT}
 472         SysV init scripts:       ${SYSTEM_SYSVINIT_PATH}
 473         SysV rc?.d directories:  ${SYSTEM_SYSVRCND_PATH}
 474         Syslog service:          ${SPECIAL_SYSLOG_SERVICE}
 475         Gtk:                     ${have_gtk}
 476         libcryptsetup:           ${have_libcryptsetup}
 477         tcpwrap:                 ${have_tcpwrap}
 478         PAM:                     ${have_pam}
 479         AUDIT:                   ${have_audit}
 480         SELinux:                 ${have_selinux}
 481         prefix:                  ${prefix}
 482         root dir:                ${with_rootdir}
 483         udev rules dir:          ${with_udevrulesdir}
 484         pam modules dir:         ${with_pamlibdir}
 485         dbus policy dir:         ${with_dbuspolicydir}
 486         dbus session dir:        ${with_dbussessionservicedir}
 487         dbus system dir:         ${with_dbussystemservicedir}
 488         dbus interfaces dir:     ${with_dbusinterfacedir}
 489 "