configure.ac

   1 #
   2 #  This file is part of elogind.
   3 #
   4 #  Copyright 2010-2012 Lennart Poettering
   5 #  Copyright 2010-2012 Kay Sievers
   6 #
   7 #  elogind is free software; you can redistribute it and/or modify it
   8 #  under the terms of the GNU Lesser General Public License as published by
   9 #  the Free Software Foundation; either version 2.1 of the License, or
  10 #  (at your option) any later version.
  11 #
  12 #  elogind is distributed in the hope that it will be useful, but
  13 #  WITHOUT ANY WARRANTY; without even the implied warranty of
  14 #  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
  15 #  Lesser General Public License for more details.
  16 #
  17 #  You should have received a copy of the GNU Lesser General Public License
  18 #  along with systemd; If not, see <http://www.gnu.org/licenses/>.
  19
  20 AC_PREREQ([2.64])
  21
  22 AC_INIT([elogind],
  23         [226],
  24         [https://github.com/elogind/elogind/issues],
  25         [elogind],
  26         [https://github.com/elogind/elogind])
  27
  28 AC_CONFIG_SRCDIR([src/login/logind.c])
  29 AC_CONFIG_MACRO_DIR([m4])
  30 AC_CONFIG_HEADERS([config.h])
  31 AC_CONFIG_AUX_DIR([build-aux])
  32
  33 AC_USE_SYSTEM_EXTENSIONS
  34 AC_SYS_LARGEFILE
  35 AC_PREFIX_DEFAULT([/usr])
  36 AM_MAINTAINER_MODE([enable])
  37 AM_INIT_AUTOMAKE([foreign 1.11 -Wall -Wno-portability silent-rules tar-pax no-dist-gzip dist-xz subdir-objects parallel-tests])
  38 AM_SILENT_RULES([yes])
  39 AC_CANONICAL_HOST
  40 AC_DEFINE_UNQUOTED([CANONICAL_HOST], "$host", [Canonical host string.])
  41
  42 AC_PROG_CC_C99
  43
  44 AX_COMPILER_VENDOR
  45 AS_IF([test "x$ax_cv_c_compiler_vendor" = "xgnu"], [
  46       AC_CHECK_TOOLS([AR], [gcc-ar ar], [:])
  47       AC_CHECK_TOOLS([NM], [gcc-nm nm], [:])
  48       AC_CHECK_TOOLS([RANLIB], [gcc-ranlib ranlib], [:])
  49 ])
  50
  51 LT_PREREQ(2.2)
  52 LT_INIT([disable-static])
  53
  54 AS_IF([test "x$enable_static" = "xyes"], [AC_MSG_ERROR([--enable-static is not supported by elogind])])
  55 AS_IF([test "x$enable_largefile" = "xno"], [AC_MSG_ERROR([--disable-largefile is not supported by elogind])])
  56
  57 SET_ARCH(X86_64, x86_64*)
  58 SET_ARCH(IA32, i*86*)
  59 SET_ARCH(MIPS, mips*)
  60 SET_ARCH(AARCH64, aarch64*)
  61
  62 # i18n stuff for the PolicyKit policy files, heck whether intltool can be found, disable NLS otherwise
  63 AC_CHECK_PROG(intltool_found, [intltool-merge], [yes], [no])
  64 AS_IF([test x"$intltool_found" != xyes],
  65       [AS_IF([test x"$enable_nls" = xyes],
  66              [AC_MSG_ERROR([--enable-nls requested but intltool not found])],
  67              [AS_IF([test x"$enable_nls" != xno],
  68                     [AC_MSG_WARN([*** Disabling NLS support because intltool was not found])
  69                      enable_nls=no])
  70              ])
  71       ])
  72
  73 AM_NLS
  74 AS_IF([test x"$enable_nls" != xno -o "x$enable_polkit" != xno], [
  75     # intltoolize greps for '^(AC|IT)_PROG_INTLTOOL', so it needs to be on its own line
  76 IT_PROG_INTLTOOL([0.40.0])
  77 ])
  78
  79 AS_IF([test -z "$INTLTOOL_POLICY_RULE"], [
  80     # If intltool is not available, provide a dummy rule to fail generation of %.policy files with a meaningful error message
  81     INTLTOOL_POLICY_RULE='%.policy: %.policy.in ; @echo "  ITMRG   " $@ && echo "*** intltool support required to build target $@" && false'
  82     AC_SUBST(INTLTOOL_POLICY_RULE)
  83 ])
  84
  85 GETTEXT_PACKAGE=elogind
  86 AC_SUBST(GETTEXT_PACKAGE)
  87 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, "$GETTEXT_PACKAGE", [elogind])
  88
  89 AC_PROG_MKDIR_P
  90 AC_PROG_LN_S
  91 AC_PROG_SED
  92 AC_PROG_GREP
  93 AC_PROG_AWK
  94
  95 AC_PATH_PROG([M4], [m4])
  96 AC_PATH_PROG([XSLTPROC], [xsltproc])
  97
  98 AC_PATH_PROG([HALT], [halt], [halt])
  99 AC_PATH_PROG([REBOOT], [reboot], [reboot])
 100 AC_PATH_PROG([KEXEC], [kexec], [/usr/sbin/kexec], [$PATH:/usr/sbin:/sbin])
 101
 102 AS_IF([! ln --relative --help > /dev/null 2>&1], [AC_MSG_ERROR([*** ln doesn't support --relative ***])])
 103
 104 M4_DEFINES=
 105
 106 AC_CHECK_TOOL(OBJCOPY, objcopy)
 107 AC_CHECK_TOOL(GPERF, gperf)
 108 if test -z "$GPERF" ; then
 109         AC_MSG_ERROR([*** gperf not found])
 110 fi
 111
 112 # ------------------------------------------------------------------------------
 113 address_sanitizer_cflags=
 114 address_sanitizer_cppflags=
 115 address_sanitizer_ldflags=
 116 AC_ARG_ENABLE(address-sanitizer, AS_HELP_STRING([--enable-address-sanitizer], [enable -fsanitize=address]))
 117 AS_IF([test "x$enable_address_sanitizer" = "xyes"], [
 118             CC_CHECK_FLAG_APPEND([with_as_cflags], [CFLAGS], [-fsanitize=address])
 119             AS_IF([test -z "$with_as_cflags"],
 120                   [AC_MSG_ERROR([*** -fsanitize=address is not supported])])
 121             address_sanitizer_cflags="$with_as_cflags -fno-omit-frame-pointer -DVALGRIND=1"
 122             address_sanitizer_cppflags="-DVALGRIND=1"
 123             address_sanitizer_ldflags="-Wc,-fsanitize=address"
 124       ])
 125
 126 undefined_sanitizer_cflags=
 127 undefined_sanitizer_cppflags=
 128 undefined_sanitizer_ldflags=
 129 AC_ARG_ENABLE(undefined-sanitizer, AS_HELP_STRING([--enable-undefined-sanitizer], [enable -fsanitize=undefined]))
 130 AS_IF([test "x$enable_undefined_sanitizer" = "xyes"], [
 131             CC_CHECK_FLAG_APPEND([with_us_cflags], [CFLAGS], [-fsanitize=undefined])
 132             AS_IF([test -z "$with_us_cflags"],
 133                   [AC_MSG_ERROR([*** -fsanitize=undefined is not supported])])
 134             undefined_sanitizer_cflags="$with_us_cflags -fno-omit-frame-pointer -DVALGRIND=1"
 135             undefined_sanitizer_cppflags="-DVALGRIND=1"
 136             undefined_sanitizer_ldflags="-Wc,-fsanitize=undefined"
 137       ])
 138
 139 sanitizer_cflags="$address_sanitizer_cflags $undefined_sanitizer_cflags"
 140 sanitizer_cppflags="$address_sanitizer_cppflags $undefined_sanitizer_cppflags"
 141 sanitizer_ldflags="$address_sanitizer_ldflags $undefined_sanitizer_ldflags"
 142
 143 CC_CHECK_FLAGS_APPEND([with_cflags], [CFLAGS], [\
 144         -pipe \
 145         -Wall \
 146         -Wextra \
 147         -Wundef \
 148         "-Wformat=2 -Wformat-security -Wformat-nonliteral" \
 149         -Wlogical-op \
 150         -Wmissing-include-dirs \
 151         -Wold-style-definition \
 152         -Wpointer-arith \
 153         -Winit-self \
 154         -Wdeclaration-after-statement \
 155         -Wfloat-equal \
 156         -Wsuggest-attribute=noreturn \
 157         -Werror=missing-prototypes \
 158         -Werror=implicit-function-declaration \
 159         -Werror=missing-declarations \
 160         -Werror=return-type \
 161         -Werror=shadow \
 162         -Wstrict-prototypes \
 163         -Wredundant-decls \
 164         -Wmissing-noreturn \
 165         -Wshadow \
 166         -Wendif-labels \
 167         -Wstrict-aliasing=2 \
 168         -Wwrite-strings \
 169         -Wno-unused-parameter \
 170         -Wno-missing-field-initializers \
 171         -Wno-unused-result \
 172         -Wno-format-signedness \
 173         -Werror=overflow \
 174         -Wdate-time \
 175         -Wnested-externs \
 176         -ffast-math \
 177         -fno-common \
 178         -fdiagnostics-show-option \
 179         -fno-strict-aliasing \
 180         -fvisibility=hidden \
 181         -fstack-protector \
 182         -fstack-protector-strong \
 183         -fPIE \
 184         --param=ssp-buffer-size=4])
 185
 186 AS_CASE([$CC], [*clang*],
 187         [CC_CHECK_FLAGS_APPEND([with_cppflags], [CPPFLAGS], [\
 188                -Wno-typedef-redefinition \
 189                -Wno-gnu-variable-sized-type-not-at-end \
 190         ])])
 191
 192 dnl AS_CASE([$CFLAGS], [*-O[[12345sz\ ]]*],
 193 dnl         [CC_CHECK_FLAGS_APPEND([with_cflags], [CFLAGS], [\
 194 dnl                -flto])],
 195 dnl         [AC_MSG_RESULT([skipping -flto, optimization not enabled])])
 196 dnl AC_SUBST([OUR_CFLAGS], "$with_cflags $sanitizer_cflags")
 197
 198 AS_CASE([$CFLAGS], [*-O[[12345sz\ ]]*],
 199         [CC_CHECK_FLAGS_APPEND([with_cppflags], [CPPFLAGS], [\
 200                -Wp,-D_FORTIFY_SOURCE=2])],
 201         [AC_MSG_RESULT([skipping -D_FORTIFY_SOURCE, optimization not enabled])])
 202 AC_SUBST([OUR_CPPFLAGS], "$with_cppflags $sanitizer_cppflags")
 203
 204 AS_CASE([$CFLAGS], [*-O[[12345sz\ ]]*],
 205         [CC_CHECK_FLAGS_APPEND([with_ldflags], [LDFLAGS], [\
 206                -Wl,--gc-sections])],
 207         [AC_MSG_RESULT([skipping --gc-sections, optimization not enabled])])
 208 AC_SUBST([OUR_CFLAGS], "$with_ldflags $sanitizer_cflags")
 209
 210 AS_CASE([$CFLAGS], [*-O[[12345sz\ ]]*],
 211         [CC_CHECK_FLAGS_APPEND([with_cflags], [CFLAGS], [\
 212                -ffunction-sections -fdata-sections])],
 213         [AC_MSG_RESULT([skipping -ffunction/data-section, optimization not enabled])])
 214 AC_SUBST([OUR_CFLAGS], "$with_cflags $sanitizer_cflags")
 215
 216 CC_CHECK_FLAGS_APPEND([with_ldflags], [LDFLAGS], [\
 217         -Wl,--as-needed \
 218         -Wl,--no-undefined \
 219         -Wl,-z,relro \
 220         -Wl,-z,now \
 221         -pie \
 222         -Wl,-fuse-ld=gold])
 223 AC_SUBST([OUR_LDFLAGS], "$with_ldflags $sanitizer_ldflags")
 224
 225 AC_CHECK_SIZEOF(pid_t)
 226 AC_CHECK_SIZEOF(uid_t)
 227 AC_CHECK_SIZEOF(gid_t)
 228 AC_CHECK_SIZEOF(time_t)
 229 AC_CHECK_SIZEOF(dev_t)
 230 AC_CHECK_SIZEOF(rlim_t,,[
 231        #include <sys/time.h>
 232        #include <sys/resource.h>
 233 ])
 234
 235 GPERF_TEST="$(echo foo,bar | ${GPERF} -L ANSI-C)"
 236
 237 AC_COMPILE_IFELSE(
 238         [AC_LANG_PROGRAM([
 239                 #include <string.h>
 240                 const char * in_word_set(const char *, size_t);
 241                 $GPERF_TEST]
 242         )],
 243         [GPERF_LEN_TYPE=size_t],
 244         [AC_COMPILE_IFELSE(
 245                 [AC_LANG_PROGRAM([
 246                         #include <string.h>
 247                         const char * in_word_set(const char *, unsigned);
 248                         $GPERF_TEST]
 249                 )],
 250                 [GPERF_LEN_TYPE=unsigned],
 251                 [AC_MSG_ERROR([** unable to determine gperf len type])]
 252         )]
 253 )
 254
 255 AC_DEFINE_UNQUOTED([GPERF_LEN_TYPE], [$GPERF_LEN_TYPE], [gperf len type])
 256
 257 # ------------------------------------------------------------------------------
 258 # we use python to build the man page index
 259 have_python=no
 260 AC_ARG_WITH([python],
 261         [AS_HELP_STRING([--without-python], [Disable building the man page index (default: test)])])
 262
 263 have_lxml=no
 264 AS_IF([test "x$with_python" != "xno"], [
 265         AM_PATH_PYTHON(,, [:])
 266         AS_IF([test "x$PYTHON" != "x:"], [
 267                 AC_MSG_CHECKING([for python lxml module])
 268                 AS_IF(["$PYTHON" -c 'import lxml' 2>/dev/null], [have_lxml=yes])
 269                 AC_MSG_RESULT([$have_lxml])
 270                 AS_IF([test "x$have_lxml" = "xyes"], [have_python=yes],
 271                       [AC_MSG_WARN([*** python support requires python-lxml module installed])])
 272         ])
 273 ])
 274 AS_IF([test "$have_python" != "yes"], [
 275       AS_IF([test "$with_python" = "yes"],
 276             [AC_MSG_ERROR([*** python support requested but python support not found])])
 277       AS_IF([test "$with_python" != "no"],
 278             [AC_MSG_WARN([*** python support not found, some documentation cannot be built])])
 279 ])
 280
 281 AM_CONDITIONAL([HAVE_PYTHON], [test "x$have_python" = "xyes"])
 282
 283 # ------------------------------------------------------------------------------
 284
 285 AC_CHECK_HEADERS([sys/capability.h], [], [AC_MSG_ERROR([*** POSIX caps headers not found])])
 286 AC_CHECK_HEADERS([linux/btrfs.h], [], [])
 287 AC_CHECK_HEADERS([linux/memfd.h], [], [])
 288
 289 # unconditionally pull-in librt with old glibc versions
 290 AC_SEARCH_LIBS([clock_gettime], [rt], [], [])
 291 AC_SEARCH_LIBS([mq_unlink], [rt], [], [])
 292
 293 AC_ARG_WITH([libcap],
 294             AS_HELP_STRING([--with-libcap=DIR], [Prefix for libcap]),
 295             [CAP_LDFLAGS="-L$with_libcap/lib"],
 296             [CAP_LDFLAGS=""])
 297 save_LIBS="$LIBS"
 298 save_LDFLAGS="$LDFLAGS"
 299 LIBS=
 300 LDFLAGS="$LDFLAGS $CAP_LDFLAGS"
 301 AC_SEARCH_LIBS([cap_init], [cap], [], [AC_MSG_ERROR([*** POSIX caps library not found])])
 302 CAP_LIBS="$LIBS"
 303 AC_SUBST(CAP_LIBS)
 304 AC_SUBST(CAP_LDFLAGS)
 305 LIBS="$save_LIBS"
 306 LDFLAGS="$save_LDFLAGS"
 307
 308 AC_CHECK_FUNCS([memfd_create])
 309 AC_CHECK_FUNCS([__secure_getenv secure_getenv])
 310 AC_CHECK_DECLS([gettid, pivot_root, name_to_handle_at, setns, getrandom, renameat2, kcmp, LO_FLAGS_PARTSCAN],
 311                [], [], [[
 312 #include <sys/types.h>
 313 #include <unistd.h>
 314 #include <sys/mount.h>
 315 #include <fcntl.h>
 316 #include <sched.h>
 317 #include <linux/loop.h>
 318 #include <linux/random.h>
 319 ]])
 320
 321 AC_CHECK_DECLS([IFLA_INET6_ADDR_GEN_MODE,
 322                 IFLA_MACVLAN_FLAGS,
 323                 IFLA_IPVLAN_MODE,
 324                 IFLA_VTI_REMOTE,
 325                 IFLA_PHYS_PORT_ID,
 326                 IFLA_BOND_AD_INFO,
 327                 IFLA_VLAN_PROTOCOL,
 328                 IFLA_VXLAN_REMCSUM_NOPARTIAL,
 329                 IFLA_VXLAN_LOCAL6,
 330                 IFLA_IPTUN_ENCAP_DPORT,
 331                 IFLA_GRE_ENCAP_DPORT,
 332                 IFLA_BRIDGE_VLAN_INFO,
 333                 IFLA_BRPORT_LEARNING_SYNC,
 334                 NDA_IFINDEX,
 335                 IFA_FLAGS],
 336 [], [], [[
 337 #include <inttypes.h>
 338 #include <netinet/in.h>
 339 #include <netinet/ether.h>
 340 #include <linux/rtnetlink.h>
 341 #include <net/if.h>
 342 #include <linux/ip.h>
 343 #include <linux/if_tunnel.h>
 344 #include <linux/if_link.h>
 345 #include <linux/if_bridge.h>
 346 #include <linux/if_addr.h>
 347 #include <linux/neighbour.h>
 348 ]])
 349
 350 # This makes sure pkg.m4 is available.
 351 m4_pattern_forbid([^_?PKG_[A-Z_]+$],[*** pkg.m4 missing, please install pkg-config])
 352
 353
 354 # ------------------------------------------------------------------------------
 355 PKG_CHECK_MODULES(UDEV, [libudev])
 356 dnl
 357 AC_ARG_WITH([udevrulesdir],
 358             AS_HELP_STRING([--with-udevrulesdir=DIR], [Directory for udev rules files]),
 359             [],
 360             [with_udevrulesdir=$($PKG_CONFIG --variable=udevdir udev)/rules.d])
 361 AC_SUBST([udevrulesdir], [$with_udevrulesdir])
 362
 363 AC_ARG_WITH([udevbindir],
 364             AS_HELP_STRING([--with-udevbindir=DIR], [Directory for udev binary files]),
 365             [],
 366             [with_udevbindir=$($PKG_CONFIG --variable=udevdir udev)])
 367 AC_SUBST([udevbindir], [$with_udevbindir])
 368
 369 # ------------------------------------------------------------------------------
 370 have_coverage=no
 371 AC_ARG_ENABLE(coverage, AS_HELP_STRING([--enable-coverage], [enable test coverage]))
 372 if test "x$enable_coverage" = "xyes" ; then
 373         AC_CHECK_PROG(lcov_found, [lcov], [yes], [no])
 374         if test "x$lcov_found" = xno ; then
 375                 AC_MSG_ERROR([*** lcov support requested but the program was not found])
 376         else
 377                 lcov_version_major="`lcov --version | cut -d ' ' -f 4 | cut -d '.' -f 1`"
 378                 lcov_version_minor="`lcov --version | cut -d ' ' -f 4 | cut -d '.' -f 2`"
 379                 if test "$lcov_version_major" -eq 1 -a "$lcov_version_minor" -lt 10; then
 380                         AC_MSG_ERROR([*** lcov version is too old. 1.10 required])
 381                 else
 382                         have_coverage=yes
 383                         CC_CHECK_FLAGS_APPEND([with_coverage_cflags], [CFLAGS], [\
 384                         -fprofile-arcs \
 385                         -ftest-coverage])
 386                         AC_SUBST([OUR_CFLAGS], "$with_cflags $with_coverage_cflags")
 387                 fi
 388         fi
 389 fi
 390 AM_CONDITIONAL(ENABLE_COVERAGE, [test "$have_coverage" = "yes"])
 391
 392 # ------------------------------------------------------------------------------
 393 have_blkid=no
 394 AC_ARG_ENABLE(blkid, AS_HELP_STRING([--disable-blkid], [disable blkid support]))
 395 if test "x$enable_blkid" != "xno"; then
 396         PKG_CHECK_MODULES(BLKID, [ blkid >= 2.24 ],
 397                 [AC_DEFINE(HAVE_BLKID, 1, [Define if blkid is available]) have_blkid=yes], have_blkid=no)
 398         if test "x$have_blkid" = xno -a "x$enable_blkid" = xyes; then
 399                 AC_MSG_ERROR([*** blkid support requested but libraries not found])
 400         fi
 401 fi
 402 AM_CONDITIONAL(HAVE_BLKID, [test "$have_blkid" = "yes"])
 403
 404 # ------------------------------------------------------------------------------
 405 have_seccomp=no
 406 AC_ARG_ENABLE(seccomp, AS_HELP_STRING([--disable-seccomp], [Disable optional SECCOMP support]))
 407 if test "x$enable_seccomp" != "xno"; then
 408         PKG_CHECK_MODULES(SECCOMP, [libseccomp >= 1.0.0],
 409                [AC_DEFINE(HAVE_SECCOMP, 1, [Define if seccomp is available])
 410                 have_seccomp=yes
 411                 M4_DEFINES="$M4_DEFINES -DHAVE_SECCOMP"],
 412                [have_seccomp=no])
 413         if test "x$have_seccomp" = "xno" -a "x$enable_seccomp" = "xyes"; then
 414                 AC_MSG_ERROR([*** seccomp support requested but libraries not found])
 415         fi
 416 fi
 417 AM_CONDITIONAL(HAVE_SECCOMP, [test "$have_seccomp" = "yes"])
 418
 419 # ------------------------------------------------------------------------------
 420 have_selinux=no
 421 AC_ARG_ENABLE(selinux, AS_HELP_STRING([--disable-selinux], [Disable optional SELINUX support]))
 422 if test "x$enable_selinux" != "xno"; then
 423         PKG_CHECK_MODULES([SELINUX], [libselinux >= 2.1.9],
 424                 [AC_DEFINE(HAVE_SELINUX, 1, [Define if SELinux is available])
 425                  have_selinux=yes
 426                  M4_DEFINES="$M4_DEFINES -DHAVE_SELINUX"],
 427                 [have_selinux=no])
 428         if test "x$have_selinux" = xno -a "x$enable_selinux" = xyes; then
 429                 AC_MSG_ERROR([*** SELinux support requested but libraries not found])
 430         fi
 431 fi
 432 AM_CONDITIONAL(HAVE_SELINUX, [test "$have_selinux" = "yes"])
 433
 434 have_apparmor=no
 435 AC_ARG_ENABLE(apparmor, AS_HELP_STRING([--disable-apparmor], [Disable optional AppArmor support]))
 436 if test "x$enable_apparmor" != "xno"; then
 437         PKG_CHECK_MODULES([APPARMOR], [libapparmor],
 438                 [AC_DEFINE(HAVE_APPARMOR, 1, [Define if AppArmor is available])
 439                  have_apparmor=yes
 440                  M4_DEFINES="$M4_DEFINES -DHAVE_APPARMOR"],
 441                 [have_apparmor=no])
 442         if test "x$have_apparmor" = xno -a "x$enable_apparmor" = xyes; then
 443                 AC_MSG_ERROR([*** AppArmor support requested but libraries not found])
 444         fi
 445 fi
 446 AM_CONDITIONAL(HAVE_APPARMOR, [test "$have_apparmor" = "yes"])
 447
 448 # ------------------------------------------------------------------------------
 449 AC_ARG_ENABLE([pam],
 450         AS_HELP_STRING([--disable-pam],[Disable optional PAM support]),
 451                 [case "${enableval}" in
 452                         yes) have_pam=yes ;;
 453                         no) have_pam=no ;;
 454                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-pam) ;;
 455                 esac],
 456                 [have_pam=auto])
 457
 458 if test "x${have_pam}" != xno ; then
 459         AC_CHECK_HEADERS(
 460                 [security/pam_modules.h security/pam_modutil.h security/pam_ext.h],
 461                 [have_pam=yes],
 462                 [if test "x$have_pam" = xyes ; then
 463                         AC_MSG_ERROR([*** PAM headers not found.])
 464                 fi])
 465
 466         AC_CHECK_LIB(
 467                 [pam],
 468                 [pam_syslog],
 469                 [have_pam=yes],
 470                 [if test "x$have_pam" = xyes ; then
 471                         AC_MSG_ERROR([*** libpam not found.])
 472                 fi])
 473
 474         if test "x$have_pam" = xyes ; then
 475                 PAM_LIBS="-lpam -lpam_misc"
 476                 AC_DEFINE(HAVE_PAM, 1, [PAM available])
 477                 M4_DEFINES="$M4_DEFINES -DHAVE_PAM"
 478         else
 479                 have_pam=no
 480         fi
 481 else
 482         PAM_LIBS=
 483 fi
 484 AC_SUBST(PAM_LIBS)
 485 AM_CONDITIONAL([HAVE_PAM], [test "x$have_pam" != xno])
 486
 487 # ------------------------------------------------------------------------------
 488 AC_ARG_ENABLE([acl],
 489         AS_HELP_STRING([--disable-acl],[Disable optional ACL support]),
 490                 [case "${enableval}" in
 491                         yes) have_acl=yes ;;
 492                         no) have_acl=no ;;
 493                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-acl) ;;
 494                 esac],
 495                 [have_acl=auto])
 496
 497 if test "x${have_acl}" != xno ; then
 498         AC_CHECK_HEADERS(
 499                 [sys/acl.h acl/libacl.h],
 500                 [have_acl=yes],
 501                 [if test "x$have_acl" = xyes ; then
 502                         AC_MSG_ERROR([*** ACL headers not found.])
 503                 fi])
 504
 505         AC_CHECK_LIB(
 506                 [acl],
 507                 [acl_get_file],
 508                 [have_acl=yes],
 509                 [if test "x$have_acl" = xyes ; then
 510                         AC_MSG_ERROR([*** libacl not found.])
 511                 fi])
 512
 513         if test "x$have_acl" = xyes ; then
 514                 ACL_LIBS="-lacl"
 515                 AC_DEFINE(HAVE_ACL, 1, [ACL available])
 516                 M4_DEFINES="$M4_DEFINES -DHAVE_ACL"
 517         else
 518                 have_acl=no
 519         fi
 520 else
 521         ACL_LIBS=
 522 fi
 523 AC_SUBST(ACL_LIBS)
 524 AM_CONDITIONAL([HAVE_ACL], [test "x$have_acl" != xno])
 525
 526 # ------------------------------------------------------------------------------
 527 AC_ARG_ENABLE([smack], AS_HELP_STRING([--disable-smack],[Disable optional SMACK support]),
 528                 [case "${enableval}" in
 529                         yes) have_smack=yes ;;
 530                         no) have_smack=no ;;
 531                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-smack) ;;
 532                 esac],
 533                 [have_smack=auto])
 534
 535 if test "x${have_smack}" = xauto; then
 536         M4_DEFINES="$M4_DEFINES -DHAVE_SMACK"
 537         have_smack=yes
 538 fi
 539
 540 AC_ARG_WITH(smack-run-label,
 541 AS_HELP_STRING([--with-smack-run-label=STRING],
 542         [run elogind --system itself with a specific SMACK label]),
 543         [AC_DEFINE_UNQUOTED(SMACK_RUN_LABEL, ["$withval"], [Run elogind itself with SMACK label])],
 544         [])
 545
 546 AC_ARG_WITH(smack-default-process-label,
 547 AS_HELP_STRING([--with-smack-default-process-label=STRING],
 548         [default SMACK label for executed processes]),
 549         [AC_DEFINE_UNQUOTED(SMACK_DEFAULT_PROCESS_LABEL, ["$withval"], [Default SMACK label for executed processes])],
 550         [])
 551
 552 if test "x${have_smack}" = xyes ; then
 553         AC_DEFINE(HAVE_SMACK, 1, [Define if SMACK is available])
 554 fi
 555
 556 AM_CONDITIONAL([HAVE_SMACK], [test "x$have_smack" = "xyes"])
 557
 558 # ------------------------------------------------------------------------------
 559 have_logind=yes
 560 #AC_ARG_ENABLE(logind, AS_HELP_STRING([--disable-logind], [disable login daemon]))
 561 #if test "x$enable_logind" != "xno"; then
 562 #        have_logind=yes
 563 #fi
 564 AM_CONDITIONAL(ENABLE_LOGIND, [test "$have_logind" = "yes"])
 565 AS_IF([test "$have_logind" = "yes"], [ AC_DEFINE(HAVE_LOGIND, [1], [Logind support available]) ])
 566
 567 # ------------------------------------------------------------------------------
 568 AC_ARG_WITH(system-uid-max,
 569         AS_HELP_STRING([--with-system-uid-max=UID]
 570                 [Maximum UID for system users]),
 571         [SYSTEM_UID_MAX="$withval"],
 572         [SYSTEM_UID_MAX="`awk 'BEGIN { uid=999 } /^\s*SYS_UID_MAX\s+/ { uid=$2 } END { print uid }' /etc/login.defs 2>/dev/null || echo 999`"])
 573
 574 AC_DEFINE_UNQUOTED(SYSTEM_UID_MAX, [$SYSTEM_UID_MAX], [Maximum System UID])
 575 AC_SUBST(SYSTEM_UID_MAX)
 576
 577 # ------------------------------------------------------------------------------
 578 AC_ARG_WITH(system-gid-max,
 579         AS_HELP_STRING([--with-system-gid-max=GID]
 580                 [Maximum GID for system groups]),
 581         [SYSTEM_GID_MAX="$withval"],
 582         [SYSTEM_GID_MAX="`awk 'BEGIN { gid=999 } /^\s*SYS_GID_MAX\s+/ { gid=$2 } END { print gid }' /etc/login.defs 2>/dev/null || echo 999`"])
 583
 584 AC_DEFINE_UNQUOTED(SYSTEM_GID_MAX, [$SYSTEM_GID_MAX], [Maximum System GID])
 585 AC_SUBST(SYSTEM_GID_MAX)
 586
 587 # ------------------------------------------------------------------------------
 588 have_polkit=no
 589 AC_ARG_ENABLE(polkit, AS_HELP_STRING([--disable-polkit], [disable PolicyKit support]))
 590 if test "x$enable_polkit" != "xno"; then
 591         AC_DEFINE(ENABLE_POLKIT, 1, [Define if PolicyKit support is to be enabled])
 592         have_polkit=yes
 593 fi
 594 AM_CONDITIONAL(ENABLE_POLKIT, [test "x$have_polkit" = "xyes"])
 595
 596 # ------------------------------------------------------------------------------
 597 have_kdbus=no
 598 AC_ARG_ENABLE(kdbus, AS_HELP_STRING([--disable-kdbus], [do not connect to kdbus by default]))
 599 if test "x$enable_kdbus" != "xno"; then
 600         AC_DEFINE(ENABLE_KDBUS, 1, [Define if kdbus is to be connected to by default])
 601         have_kdbus=yes
 602         M4_DEFINES="$M4_DEFINES -DENABLE_KDBUS"
 603 fi
 604 AM_CONDITIONAL(ENABLE_KDBUS, [test "$have_kdbus" = "yes"])
 605
 606 # ------------------------------------------------------------------------------
 607 AC_CHECK_HEADERS_ONCE([valgrind/memcheck.h valgrind/valgrind.h])
 608
 609 # ------------------------------------------------------------------------------
 610 PKG_CHECK_MODULES([GLIB], [glib-2.0 >= 2.22.0 gobject-2.0 >= 2.22.0 gio-2.0],
 611                   [have_glib=yes], [have_glib=no])
 612 AS_IF([test "x$have_glib" = "xyes"], [ AC_DEFINE(HAVE_GLIB, 1, [Define if glib is available]) ])
 613
 614 # ------------------------------------------------------------------------------
 615 have_manpages=no
 616 AC_ARG_ENABLE(manpages, AS_HELP_STRING([--disable-manpages], [disable manpages]))
 617 AS_IF([test "x$enable_manpages" != xno], [have_manpages=yes])
 618 AM_CONDITIONAL(ENABLE_MANPAGES, [test "x$have_manpages" = "xyes"])
 619
 620 # ------------------------------------------------------------------------------
 621 AC_SUBST(M4_DEFINES)
 622
 623 AC_ARG_WITH([dbuspolicydir],
 624         AS_HELP_STRING([--with-dbuspolicydir=DIR], [D-Bus policy directory]),
 625         [],
 626         [with_dbuspolicydir=${sysconfdir}/dbus-1/system.d])
 627 AX_NORMALIZE_PATH([with_dbuspolicydir])
 628
 629 AC_ARG_WITH([dbussystemservicedir],
 630         AS_HELP_STRING([--with-dbussystemservicedir=DIR], [D-Bus system service directory]),
 631         [],
 632         [with_dbussystemservicedir=${datadir}/dbus-1/system-services])
 633 AX_NORMALIZE_PATH([with_dbussystemservicedir])
 634
 635 AC_ARG_WITH([bashcompletiondir],
 636         AS_HELP_STRING([--with-bashcompletiondir=DIR], [Bash completions directory]),
 637         [],
 638         [AS_IF([$($PKG_CONFIG --exists bash-completion)], [
 639                 with_bashcompletiondir=$($PKG_CONFIG --variable=completionsdir bash-completion)
 640         ] , [
 641                 with_bashcompletiondir=${datadir}/bash-completion/completions
 642         ])])
 643 AM_CONDITIONAL(ENABLE_BASH_COMPLETION, [test "$with_bashcompletiondir" != "no"])
 644 AX_NORMALIZE_PATH([with_bashcompletiondir])
 645
 646 AC_ARG_WITH([zshcompletiondir],
 647         AS_HELP_STRING([--with-zshcompletiondir=DIR], [Zsh completions directory]),
 648         [], [with_zshcompletiondir=${datadir}/zsh/site-functions])
 649 AM_CONDITIONAL(ENABLE_ZSH_COMPLETION, [test "$with_zshcompletiondir" != "no"])
 650 AX_NORMALIZE_PATH([with_zshcompletiondir])
 651
 652 AC_ARG_WITH([rootprefix],
 653         AS_HELP_STRING([--with-rootprefix=DIR], [rootfs directory prefix for config files and kernel modules]),
 654         [], [with_rootprefix=${ac_default_prefix}])
 655 # --with-rootprefix= (empty) should default to "/" but AX_NORMALIZE_PATH
 656 # defaults those to ".", solve that here for now until we can find a suitable
 657 # fix for AX_NORMALIZE_PATH upstream at autoconf-archive.
 658 # See: https://github.com/systemd/systemd/issues/54
 659 if test "x${with_rootprefix}" = "x"; then
 660         with_rootprefix="/"
 661 fi
 662 AX_NORMALIZE_PATH([with_rootprefix])
 663
 664 AC_ARG_WITH([rootlibdir],
 665         AS_HELP_STRING([--with-rootlibdir=DIR], [Root directory for libraries necessary for boot]),
 666         [],
 667         [with_rootlibdir=${libdir}])
 668 AX_NORMALIZE_PATH([with_rootlibdir])
 669
 670 AC_ARG_WITH([pamlibdir],
 671         AS_HELP_STRING([--with-pamlibdir=DIR], [Directory for PAM modules]),
 672         [],
 673         [with_pamlibdir=${with_rootlibdir}/security])
 674 AX_NORMALIZE_PATH([with_pamlibdir])
 675
 676 AC_ARG_WITH([pamconfdir],
 677         AS_HELP_STRING([--with-pamconfdir=DIR], [Directory for PAM configuration]),
 678         [],
 679         [with_pamconfdir=${sysconfdir}/pam.d])
 680 AX_NORMALIZE_PATH([with_pamconfdir])
 681
 682 AC_ARG_ENABLE([split-usr],
 683         AS_HELP_STRING([--enable-split-usr], [Assume that /bin, /sbin aren\'t symlinks into /usr]),
 684         [],
 685         [AS_IF([test "x${ac_default_prefix}" != "x${with_rootprefix}"], [
 686                 enable_split_usr=yes
 687         ], [
 688                 enable_split_usr=no
 689         ])])
 690
 691 AS_IF([test "x${enable_split_usr}" = "xyes"], [
 692         AC_DEFINE(HAVE_SPLIT_USR, 1, [Define if /bin, /sbin aren't symlinks into /usr])
 693 ])
 694 AM_CONDITIONAL(ENABLE_SPLIT_USR, [test "x${enable_split_usr}" = "xyes"])
 695
 696 # work around intltool-update issues during 'make distcheck'
 697 AS_IF([test "x$0" != "x./configure"], [
 698         AC_SUBST([INTLTOOL_UPDATE], [/usr/bin/env true])
 699 ])
 700
 701 AC_ARG_ENABLE(tests,
 702         [AC_HELP_STRING([--disable-tests], [disable tests])],
 703         enable_tests=$enableval, enable_tests=yes)
 704 AM_CONDITIONAL(ENABLE_TESTS, [test x$enable_tests = xyes])
 705
 706 AC_ARG_ENABLE(debug,
 707         [AC_HELP_STRING([--enable-debug@<:@=LIST@:>@], [enable extra debugging (hashmap,mmap-cache)])],
 708         [if test "x$enableval" = "xyes"; then
 709                 enableval="hashmap,mmap-cache"
 710         fi
 711         saved_ifs="$IFS"
 712         IFS="$IFS$PATH_SEPARATOR,"
 713         for name in $enableval; do
 714                 case $name in
 715                 hashmap)
 716                         enable_debug_hashmap=yes
 717                         ;;
 718                 mmap-cache)
 719                         enable_debug_mmap_cache=yes
 720                         ;;
 721                 esac
 722         done
 723         IFS="$saved_ifs"],[])
 724
 725 enable_debug=""
 726 AS_IF([test x$enable_debug_hashmap = xyes], [
 727         AC_DEFINE(ENABLE_DEBUG_HASHMAP, 1, [Define if hashmap debugging is to be enabled])
 728         enable_debug="hashmap $enable_debug"
 729 ])
 730 AS_IF([test x$enable_debug_mmap_cache = xyes], [
 731         AC_DEFINE(ENABLE_DEBUG_MMAP_CACHE, 1, [Define if mmap cache debugging is to be enabled])
 732         enable_debug="mmap-cache $enable_debug"
 733 ])
 734 test -z "$enable_debug" && enable_debug="none"
 735
 736 AC_SUBST([dbuspolicydir], [$with_dbuspolicydir])
 737 AC_SUBST([dbussystemservicedir], [$with_dbussystemservicedir])
 738 AC_SUBST([bashcompletiondir], [$with_bashcompletiondir])
 739 AC_SUBST([zshcompletiondir], [$with_zshcompletiondir])
 740 AC_SUBST([pamlibdir], [$with_pamlibdir])
 741 AC_SUBST([pamconfdir], [$with_pamconfdir])
 742 AC_SUBST([rootprefix], [$with_rootprefix])
 743 AC_SUBST([rootlibdir], [$with_rootlibdir])
 744
 745 AC_CONFIG_FILES([
 746         Makefile
 747         po/Makefile.in
 748 ])
 749
 750 AC_OUTPUT
 751 AC_MSG_RESULT([
 752         $PACKAGE_NAME $VERSION
 753
 754         PAM:                     ${have_pam}
 755         AppArmor:                ${have_apparmor}
 756         SELinux:                 ${have_selinux}
 757         SECCOMP:                 ${have_seccomp}
 758         SMACK:                   ${have_smack}
 759         ACL:                     ${have_acl}
 760         polkit:                  ${have_polkit}
 761         blkid:                   ${have_blkid}
 762         kdbus:                   ${have_kdbus}
 763         Python:                  ${have_python}
 764         man pages:               ${have_manpages}
 765         test coverage:           ${have_coverage}
 766         Split /usr:              ${enable_split_usr}
 767         extra debugging:         ${enable_debug}
 768
 769         prefix:                  ${prefix}
 770         rootprefix:              ${with_rootprefix}
 771         sysconf dir:             ${sysconfdir}
 772         datarootdir:             ${datarootdir}
 773         includedir:              ${includedir}
 774         lib dir:                 ${libdir}
 775         rootlib dir:             ${with_rootlibdir}
 776         PAM modules dir:         ${with_pamlibdir}
 777         PAM configuration dir:   ${with_pamconfdir}
 778         D-Bus policy dir:        ${with_dbuspolicydir}
 779         D-Bus system dir:        ${with_dbussystemservicedir}
 780         Bash completions dir:    ${with_bashcompletiondir}
 781         Zsh completions dir:     ${with_zshcompletiondir}
 782         Maximum System UID:      ${SYSTEM_UID_MAX}
 783         Maximum System GID:      ${SYSTEM_GID_MAX}
 784
 785         CFLAGS:                  ${OUR_CFLAGS} ${CFLAGS}
 786         CPPFLAGS:                ${OUR_CPPFLAGS} ${CPPFLAGS}
 787         LDFLAGS:                 ${OUR_LDFLAGS} ${LDFLAGS}
 788 ])