chiark / gitweb /
systemd-analyse: add "critical-chain" command
[elogind.git] / configure.ac
1 #
2 #  This file is part of systemd.
3 #
4 #  Copyright 2010-2012 Lennart Poettering
5 #  Copyright 2010-2012 Kay Sievers
6 #
7 #  systemd is free software; you can redistribute it and/or modify it
8 #  under the terms of the GNU Lesser General Public License as published by
9 #  the Free Software Foundation; either version 2.1 of the License, or
10 #  (at your option) any later version.
11 #
12 #  systemd is distributed in the hope that it will be useful, but
13 #  WITHOUT ANY WARRANTY; without even the implied warranty of
14 #  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
15 #  Lesser General Public License for more details.
16 #
17 #  You should have received a copy of the GNU Lesser General Public License
18 #  along with systemd; If not, see <http://www.gnu.org/licenses/>.
19
20 AC_PREREQ([2.64])
21
22 AC_INIT([systemd],
23         [202],
24         [http://bugs.freedesktop.org/enter_bug.cgi?product=systemd],
25         [systemd],
26         [http://www.freedesktop.org/wiki/Software/systemd])
27
28 AC_CONFIG_SRCDIR([src/core/main.c])
29 AC_CONFIG_MACRO_DIR([m4])
30 AC_CONFIG_HEADERS([config.h])
31 AC_CONFIG_AUX_DIR([build-aux])
32
33 AC_USE_SYSTEM_EXTENSIONS
34 AC_SYS_LARGEFILE
35 AC_PREFIX_DEFAULT([/usr])
36 AM_INIT_AUTOMAKE([foreign 1.11 -Wall -Wno-portability silent-rules tar-pax no-dist-gzip dist-xz subdir-objects check-news])
37 AM_SILENT_RULES([yes])
38 AC_CANONICAL_HOST
39 AC_DEFINE_UNQUOTED([CANONICAL_HOST], "$host", [Canonical host string.])
40 AS_IF([test "x$host_cpu" = "xmips" || test "x$host_cpu" = "xmipsel" ||
41        test "x$host_cpu" = "xmips64" || test "x$host_cpu" = "xmips64el"],
42       [AC_DEFINE(ARCH_MIPS, [], [Whether on mips arch])])
43
44 LT_PREREQ(2.2)
45 LT_INIT([disable-static])
46
47 # i18n stuff for the PolicyKit policy files
48 IT_PROG_INTLTOOL([0.40.0])
49
50 GETTEXT_PACKAGE=systemd
51 AC_SUBST(GETTEXT_PACKAGE)
52
53 AC_PROG_MKDIR_P
54 AC_PROG_LN_S
55 AC_PROG_SED
56 AC_PROG_GREP
57 AC_PROG_AWK
58
59 AC_PROG_CC
60 AC_PROG_CC_C99
61 AM_PROG_CC_C_O
62 AC_PROG_GCC_TRADITIONAL
63
64 AC_PATH_PROG([M4], [m4])
65 AC_PATH_PROG([XSLTPROC], [xsltproc])
66
67 AC_PATH_PROG([QUOTAON], [quotaon], [/usr/sbin/quotaon])
68 AC_PATH_PROG([QUOTACHECK], [quotacheck], [/usr/sbin/quotacheck])
69
70 AC_PATH_PROG([SETCAP], [setcap], [/usr/sbin/setcap])
71
72 AC_PATH_PROG([KILL], [kill], [/usr/bin/kill])
73
74 # gtkdocize greps for '^GTK_DOC_CHECK', so it needs to be on its own line
75 m4_ifdef([GTK_DOC_CHECK], [
76 GTK_DOC_CHECK([1.18],[--flavour no-tmpl])
77 ], [AM_CONDITIONAL([ENABLE_GTK_DOC], [false])])
78
79 AS_IF([test "x$enable_gtk_doc" = "xyes" -a "x$XSLTPROC" = x], [
80         AC_MSG_ERROR([*** GTK doc requested but xsltproc not found])
81 ])
82
83 m4_ifdef([GOBJECT_INTROSPECTION_CHECK], [
84 GOBJECT_INTROSPECTION_CHECK([1.31.1])
85 ], [
86    AM_CONDITIONAL([HAVE_INTROSPECTION], [false])
87    enable_introspection=no])
88
89 AC_CHECK_TOOL(OBJCOPY, objcopy)
90 AC_CHECK_TOOL(STRINGS, strings)
91 AC_CHECK_TOOL(GPERF, gperf)
92 if test -z "$GPERF" ; then
93         AC_MSG_ERROR([*** gperf not found])
94 fi
95
96 CC_CHECK_FLAGS_APPEND([with_cflags], [CFLAGS], [\
97         -pipe \
98         -Wall \
99         -Wextra \
100         -Wno-inline \
101         -Wundef \
102         "-Wformat=2 -Wformat-security -Wformat-nonliteral" \
103         -Wlogical-op \
104         -Wsign-compare \
105         -Wmissing-include-dirs \
106         -Wold-style-definition \
107         -Wpointer-arith \
108         -Winit-self \
109         -Wdeclaration-after-statement \
110         -Wfloat-equal \
111         -Wmissing-prototypes \
112         -Wstrict-prototypes \
113         -Wredundant-decls \
114         -Wmissing-declarations \
115         -Wmissing-noreturn \
116         -Wshadow \
117         -Wendif-labels \
118         -Wcast-align \
119         -Wstrict-aliasing=2 \
120         -Wwrite-strings \
121         -Wno-long-long \
122         -Wno-overlength-strings \
123         -Wno-unused-parameter \
124         -Wno-missing-field-initializers \
125         -Wno-unused-result \
126         -Werror=overflow \
127         -ffast-math \
128         -fno-common \
129         -fdiagnostics-show-option \
130         -fno-strict-aliasing \
131         -fvisibility=hidden \
132         -ffunction-sections \
133         -fdata-sections \
134         -fstack-protector \
135         --param=ssp-buffer-size=4])
136 AC_SUBST([OUR_CFLAGS], $with_cflags)
137
138 AS_CASE([$CFLAGS], [*-O[[12345g\ ]]*], [
139         CC_CHECK_FLAGS_APPEND([with_cppflags], [CPPFLAGS], [\
140                -Wp,-D_FORTIFY_SOURCE=2])], [
141         python_extra_cflags=-Wp,-U_FORTIFY_SOURCE
142         AC_MSG_RESULT([skipping -D_FORTIFY_SOURCE, optimization not enabled])])
143 AC_SUBST([OUR_CPPFLAGS], $with_cppflags)
144
145 CC_CHECK_FLAGS_APPEND([with_ldflags], [LDFLAGS], [\
146         -Wl,--as-needed \
147         -Wl,--no-undefined \
148         -Wl,--gc-sections \
149         -Wl,-z,relro \
150         -Wl,-z,now])
151 AC_SUBST([OUR_LDFLAGS], $with_ldflags)
152
153 # ------------------------------------------------------------------------------
154 # we use python to build the man page index, and for systemd-python
155 have_python=no
156 have_python_devel=no
157
158 AC_ARG_WITH([python],
159         [AS_HELP_STRING([--without-python], [Disable building the man page index and systemd-python (default: test)])])
160
161 AS_IF([test "x$with_python" != "xno"], [
162         AM_PATH_PYTHON(,, [:])
163         AS_IF([test "$PYTHON" != :], [have_python=yes])
164 ])
165 AM_CONDITIONAL([HAVE_PYTHON], [test "x$have_python" = "xyes"])
166 AS_IF([test "x$PYTHON_BINARY" = "x"],
167       [AS_IF([test "x$have_python" = "xyes"],
168              [PYTHON_BINARY="$(which "$PYTHON")"],
169              [PYTHON_BINARY=/usr/bin/python])])
170 AC_ARG_VAR(PYTHON_BINARY, [Python binary used to launch installed scripts])
171
172 AS_IF([test "x$with_python" != "xno"], [
173         AC_PATH_PROG(PYTHON_CONFIG, python${PYTHON_VERSION}-config)
174         AS_IF([test -n "$PYTHON_CONFIG"], [
175               have_python_devel=yes
176               PYTHON_CFLAGS="$($PYTHON_CONFIG --cflags) $python_extra_cflags"
177               PYTHON_LIBS="$($PYTHON_CONFIG --ldflags)"
178               AC_SUBST(PYTHON_CFLAGS)
179               AC_SUBST(PYTHON_LIBS)
180               AC_PATH_PROGS(SPHINX_BUILD, sphinx-build-${PYTHON_VERSION} sphinx-build)
181         ])
182 ])
183 AM_CONDITIONAL([HAVE_PYTHON_DEVEL], [test "$have_python_devel" = "yes"])
184
185 # ------------------------------------------------------------------------------
186
187 AC_SEARCH_LIBS([mq_open], [rt], [], [AC_MSG_ERROR([*** POSIX RT library not found])])
188 AC_SEARCH_LIBS([dlsym], [dl], [], [AC_MSG_ERROR([*** Dynamic linking loader library not found])])
189
190 save_LIBS="$LIBS"
191 LIBS=
192 AC_SEARCH_LIBS([cap_init], [cap], [], [AC_MSG_ERROR([*** POSIX caps library not found])])
193 AC_CHECK_HEADERS([sys/capability.h], [], [AC_MSG_ERROR([*** POSIX caps headers not found])])
194 CAP_LIBS="$LIBS"
195 LIBS="$save_LIBS"
196 AC_SUBST(CAP_LIBS)
197
198 AC_CHECK_FUNCS([fanotify_init fanotify_mark])
199 AC_CHECK_FUNCS([__secure_getenv secure_getenv])
200 AC_CHECK_DECLS([gettid, pivot_root, name_to_handle_at], [], [], [[#include <sys/types.h>
201 #include <unistd.h>
202 #include <sys/mount.h>
203 #include <fcntl.h>]])
204
205 # This makes sure pkg.m4 is available.
206 m4_pattern_forbid([^_?PKG_[A-Z_]+$],[*** pkg.m4 missing, please install pkg-config])
207
208 PKG_CHECK_MODULES(DBUS, [dbus-1 >= 1.3.2])
209
210 # ------------------------------------------------------------------------------
211 have_kmod=no
212 AC_ARG_ENABLE(kmod, AS_HELP_STRING([--disable-kmod], [disable loadable modules support]))
213 if test "x$enable_kmod" != "xno"; then
214         PKG_CHECK_MODULES(KMOD, [ libkmod >= 5 ],
215                 [AC_DEFINE(HAVE_KMOD, 1, [Define if kmod is available]) have_kmod=yes], have_kmod=no)
216         if test "x$have_kmod" = xno -a "x$enable_kmod" = xyes; then
217                 AC_MSG_ERROR([*** kmod support requested but libraries not found])
218         fi
219 fi
220 AM_CONDITIONAL(HAVE_KMOD, [test "$have_kmod" = "yes"])
221
222 # ------------------------------------------------------------------------------
223 have_blkid=no
224 AC_ARG_ENABLE(blkid, AS_HELP_STRING([--disable-blkid], [disable blkid support]))
225 if test "x$enable_blkid" != "xno"; then
226         PKG_CHECK_MODULES(BLKID, [ blkid >= 2.20 ],
227                 [AC_DEFINE(HAVE_BLKID, 1, [Define if blkid is available]) have_blkid=yes], have_blkid=no)
228         if test "x$have_blkid" = xno -a "x$enable_blkid" = xyes; then
229                 AC_MSG_ERROR([*** blkid support requested but libraries not found])
230         fi
231 fi
232 AM_CONDITIONAL(HAVE_BLKID, [test "$have_blkid" = "yes"])
233
234 # ------------------------------------------------------------------------------
235 have_ima=yes
236 AC_ARG_ENABLE([ima], AS_HELP_STRING([--disable-ima],[Disable optional IMA support]),
237                 [case "${enableval}" in
238                         yes) have_ima=yes ;;
239                         no) have_ima=no ;;
240                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-ima) ;;
241                 esac],
242                 [have_ima=yes])
243
244 if test "x${have_ima}" != xno ; then
245         AC_DEFINE(HAVE_IMA, 1, [Define if IMA is available])
246 fi
247
248 # ------------------------------------------------------------------------------
249 have_chkconfig=yes
250 AC_ARG_ENABLE([chkconfig], AS_HELP_STRING([--disable-chkconfig],[Disable optional chkconfig support]),
251                 [case "${enableval}" in
252                         yes) have_chkconfig=yes ;;
253                         no) have_chkconfig=no ;;
254                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-chkconfig) ;;
255                 esac],
256                 [AC_PATH_PROG(CHKCONFIG, chkconfig)
257                 if test -z "$CHKCONFIG"; then
258                         have_chkconfig=no
259                 else
260                         have_chkconfig=yes
261                 fi])
262
263 if test "x${have_chkconfig}" != xno ; then
264         AC_DEFINE(HAVE_CHKCONFIG, 1, [Define if CHKCONFIG is available])
265 fi
266
267 # ------------------------------------------------------------------------------
268 have_selinux=no
269 AC_ARG_ENABLE(selinux, AS_HELP_STRING([--disable-selinux], [Disable optional SELINUX support]))
270 if test "x$enable_selinux" != "xno"; then
271         PKG_CHECK_MODULES([SELINUX], [libselinux >= 2.1.9],
272                 [AC_DEFINE(HAVE_SELINUX, 1, [Define if SELinux is available]) have_selinux=yes], have_selinux=no)
273         if test "x$have_selinux" = xno -a "x$enable_selinux" = xyes; then
274                 AC_MSG_ERROR([*** SELinux support requested but libraries not found])
275         fi
276 fi
277 AM_CONDITIONAL(HAVE_SELINUX, [test "$have_selinux" = "yes"])
278
279 AC_ARG_WITH(debug-shell,
280         AS_HELP_STRING([--with-debug-shell=PATH],
281                 [Path to debug shell binary]),
282         [SUSHELL="$withval"],[
283         AS_IF([test "x${have_selinux}" != "xno"], [SUSHELL="/sbin/sushell"] , [SUSHELL="/bin/sh"])])
284
285 AC_SUBST(SUSHELL)
286
287 AC_ARG_WITH([debug-tty],
288         AS_HELP_STRING([--with-debug-tty=PATH],
289                 [Specify the tty device for debug shell]),
290         [DEBUGTTY="$withval"],
291         [DEBUGTTY=/dev/tty9])
292
293 AC_SUBST(DEBUGTTY)
294
295 # ------------------------------------------------------------------------------
296 have_xz=no
297 AC_ARG_ENABLE(xz, AS_HELP_STRING([--disable-xz], [Disable optional XZ support]))
298 if test "x$enable_xz" != "xno"; then
299         PKG_CHECK_MODULES(XZ, [ liblzma ],
300                 [AC_DEFINE(HAVE_XZ, 1, [Define if XZ is available]) have_xz=yes], have_xz=no)
301         if test "x$have_xz" = xno -a "x$enable_xz" = xyes; then
302                 AC_MSG_ERROR([*** Xz support requested but libraries not found])
303         fi
304 fi
305 AM_CONDITIONAL(HAVE_XZ, [test "$have_xz" = "yes"])
306
307 # ------------------------------------------------------------------------------
308 AC_ARG_ENABLE([tcpwrap],
309         AS_HELP_STRING([--disable-tcpwrap],[Disable optional TCP wrappers support]),
310                 [case "${enableval}" in
311                         yes) have_tcpwrap=yes ;;
312                         no) have_tcpwrap=no ;;
313                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-tcpwrap) ;;
314                 esac],
315                 [have_tcpwrap=auto])
316
317 if test "x${have_tcpwrap}" != xno ; then
318         ACX_LIBWRAP
319         if test "x${LIBWRAP_LIBS}" = x ; then
320                 if test "x$have_tcpwrap" = xyes ; then
321                         AC_MSG_ERROR([*** TCP wrappers support not found.])
322                 fi
323                 have_tcpwrap=no
324         else
325                 have_tcpwrap=yes
326         fi
327 else
328         LIBWRAP_LIBS=
329 fi
330 AC_SUBST(LIBWRAP_LIBS)
331
332 # ------------------------------------------------------------------------------
333 AC_ARG_ENABLE([pam],
334         AS_HELP_STRING([--disable-pam],[Disable optional PAM support]),
335                 [case "${enableval}" in
336                         yes) have_pam=yes ;;
337                         no) have_pam=no ;;
338                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-pam) ;;
339                 esac],
340                 [have_pam=auto])
341
342 if test "x${have_pam}" != xno ; then
343         AC_CHECK_HEADERS(
344                 [security/pam_modules.h security/pam_modutil.h security/pam_ext.h],
345                 [have_pam=yes],
346                 [if test "x$have_pam" = xyes ; then
347                         AC_MSG_ERROR([*** PAM headers not found.])
348                 fi])
349
350         AC_CHECK_LIB(
351                 [pam],
352                 [pam_syslog],
353                 [have_pam=yes],
354                 [if test "x$have_pam" = xyes ; then
355                         AC_MSG_ERROR([*** libpam not found.])
356                 fi])
357
358         if test "x$have_pam" = xyes ; then
359                 PAM_LIBS="-lpam -lpam_misc"
360                 AC_DEFINE(HAVE_PAM, 1, [PAM available])
361         else
362                 have_pam=no
363         fi
364 else
365         PAM_LIBS=
366 fi
367 AC_SUBST(PAM_LIBS)
368 AM_CONDITIONAL([HAVE_PAM], [test "x$have_pam" != xno])
369
370 # ------------------------------------------------------------------------------
371 AC_ARG_ENABLE([acl],
372         AS_HELP_STRING([--disable-acl],[Disable optional ACL support]),
373                 [case "${enableval}" in
374                         yes) have_acl=yes ;;
375                         no) have_acl=no ;;
376                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-acl) ;;
377                 esac],
378                 [have_acl=auto])
379
380 if test "x${have_acl}" != xno ; then
381         AC_CHECK_HEADERS(
382                 [sys/acl.h acl/libacl.h],
383                 [have_acl=yes],
384                 [if test "x$have_acl" = xyes ; then
385                         AC_MSG_ERROR([*** ACL headers not found.])
386                 fi])
387
388         AC_CHECK_LIB(
389                 [acl],
390                 [acl_get_file],
391                 [have_acl=yes],
392                 [if test "x$have_acl" = xyes ; then
393                         AC_MSG_ERROR([*** libacl not found.])
394                 fi])
395
396         if test "x$have_acl" = xyes ; then
397                 ACL_LIBS="-lacl"
398                 AC_DEFINE(HAVE_ACL, 1, [ACL available])
399         else
400                 have_acl=no
401         fi
402 else
403         ACL_LIBS=
404 fi
405 AC_SUBST(ACL_LIBS)
406 AM_CONDITIONAL([HAVE_ACL], [test "x$have_acl" != xno])
407
408 # ------------------------------------------------------------------------------
409 AC_ARG_ENABLE([xattr],
410         AS_HELP_STRING([--disable-xattr],[Disable optional XATTR support]),
411                 [case "${enableval}" in
412                         yes) have_xattr=yes ;;
413                         no) have_xattr=no ;;
414                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-xattr) ;;
415                 esac],
416                 [have_xattr=auto])
417
418 if test "x${have_xattr}" != xno ; then
419         AC_CHECK_HEADERS(
420                 [attr/xattr.h],
421                 [have_xattr=yes],
422                 [if test "x$have_xattr" = xyes ; then
423                         AC_MSG_ERROR([*** XATTR headers not found.])
424                 fi])
425
426         AC_CHECK_LIB(
427                 [attr],
428                 [fsetxattr],
429                 [have_xattr=yes],
430                 [if test "x$have_xattr" = xyes ; then
431                         AC_MSG_ERROR([*** libattr not found.])
432                 fi])
433
434         if test "x$have_xattr" = xyes ; then
435                 XATTR_LIBS="-lattr"
436                 AC_DEFINE(HAVE_XATTR, 1, [XATTR available])
437         else
438                 have_xattr=no
439         fi
440 else
441         XATTR_LIBS=
442 fi
443 AC_SUBST(XATTR_LIBS)
444 AM_CONDITIONAL([HAVE_XATTR], [test "x$have_xattr" != xno])
445
446 # ------------------------------------------------------------------------------
447 AC_ARG_ENABLE([gcrypt],
448         AS_HELP_STRING([--disable-gcrypt],[Disable optional GCRYPT support]),
449                 [case "${enableval}" in
450                         yes) have_gcrypt=yes ;;
451                         no) have_gcrypt=no ;;
452                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-gcrypt) ;;
453                 esac],
454                 [have_gcrypt=auto])
455
456 if test "x${have_gcrypt}" != xno ; then
457         AM_PATH_LIBGCRYPT(
458                 [1.4.5],
459                 [have_gcrypt=yes],
460                 [if test "x$have_gcrypt" = xyes ; then
461                         AC_MSG_ERROR([*** GCRYPT headers not found.])
462                 fi])
463
464         if test "x$have_gcrypt" = xyes ; then
465                 GCRYPT_LIBS="$LIBGCRYPT_LIBS"
466                 GCRYPT_CFLAGS="$LIBGCRYPT_CFLAGS"
467                 AC_DEFINE(HAVE_GCRYPT, 1, [GCRYPT available])
468         else
469                 have_gcrypt=no
470         fi
471 else
472         GCRYPT_LIBS=
473         GCRYPT_CFLAGS=
474 fi
475 AC_SUBST(GCRYPT_LIBS)
476 AC_SUBST(GCRYPT_CFLAGS)
477 AM_CONDITIONAL([HAVE_GCRYPT], [test "x$have_gcrypt" != xno])
478
479 # ------------------------------------------------------------------------------
480 AC_ARG_ENABLE([audit],
481         AS_HELP_STRING([--disable-audit],[Disable optional AUDIT support]),
482                 [case "${enableval}" in
483                         yes) have_audit=yes ;;
484                         no) have_audit=no ;;
485                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-audit) ;;
486                 esac],
487                 [have_audit=auto])
488
489 if test "x${have_audit}" != xno ; then
490         AC_CHECK_HEADERS(
491                 [libaudit.h],
492                 [have_audit=yes],
493                 [if test "x$have_audit" = xyes ; then
494                         AC_MSG_ERROR([*** AUDIT headers not found.])
495                 fi])
496
497         AC_CHECK_LIB(
498                 [audit],
499                 [audit_open],
500                 [have_audit=yes],
501                 [if test "x$have_audit" = xyes ; then
502                         AC_MSG_ERROR([*** libaudit not found.])
503                 fi])
504
505         if test "x$have_audit" = xyes ; then
506                 AUDIT_LIBS="-laudit"
507                 AC_DEFINE(HAVE_AUDIT, 1, [AUDIT available])
508         else
509                 have_audit=no
510         fi
511 else
512         AUDIT_LIBS=
513 fi
514 AC_SUBST(AUDIT_LIBS)
515
516 # ------------------------------------------------------------------------------
517 have_libcryptsetup=no
518 AC_ARG_ENABLE(libcryptsetup, AS_HELP_STRING([--disable-libcryptsetup], [disable libcryptsetup tools]))
519 if test "x$enable_libcryptsetup" != "xno"; then
520         PKG_CHECK_MODULES(LIBCRYPTSETUP, [ libcryptsetup >= 1.4.2 ],
521                 [AC_DEFINE(HAVE_LIBCRYPTSETUP, 1, [Define if libcryptsetup is available]) have_libcryptsetup=yes], have_libcryptsetup=no)
522         if test "x$have_libcryptsetup" = xno -a "x$enable_libcryptsetup" = xyes; then
523                 AC_MSG_ERROR([*** libcryptsetup support requested but libraries not found])
524         fi
525 fi
526 AM_CONDITIONAL(HAVE_LIBCRYPTSETUP, [test "$have_libcryptsetup" = "yes"])
527
528 # ------------------------------------------------------------------------------
529 have_qrencode=no
530 AC_ARG_ENABLE(qrencode, AS_HELP_STRING([--disable-qrencode], [disable qrencode support]))
531 if test "x$enable_qrencode" != "xno"; then
532         PKG_CHECK_MODULES(QRENCODE, [ libqrencode ],
533                 [AC_DEFINE(HAVE_QRENCODE, 1, [Define if qrencode is available]) have_qrencode=yes], have_qrencode=no)
534         if test "x$have_qrencode" = xno -a "x$enable_qrencode" = xyes; then
535                 AC_MSG_ERROR([*** qrencode support requested but libraries not found])
536         fi
537 fi
538 AM_CONDITIONAL(HAVE_QRENCODE, [test "$have_qrencode" = "yes"])
539
540 # ------------------------------------------------------------------------------
541 have_microhttpd=no
542 AC_ARG_ENABLE(microhttpd, AS_HELP_STRING([--disable-microhttpd], [disable microhttpd support]))
543 if test "x$enable_microhttpd" != "xno"; then
544         PKG_CHECK_MODULES(MICROHTTPD, [libmicrohttpd >= 0.9.5],
545                 [AC_DEFINE(HAVE_MICROHTTPD, 1, [Define if microhttpd is available]) have_microhttpd=yes], have_microhttpd=no)
546         if test "x$have_microhttpd" = xno -a "x$enable_microhttpd" = xyes; then
547                 AC_MSG_ERROR([*** microhttpd support requested but libraries not found])
548         fi
549 fi
550 AM_CONDITIONAL(HAVE_MICROHTTPD, [test "$have_microhttpd" = "yes"])
551
552 # ------------------------------------------------------------------------------
553 have_binfmt=no
554 AC_ARG_ENABLE(binfmt, AS_HELP_STRING([--disable-binfmt], [disable binfmt tool]))
555 if test "x$enable_binfmt" != "xno"; then
556         have_binfmt=yes
557 fi
558 AM_CONDITIONAL(ENABLE_BINFMT, [test "$have_binfmt" = "yes"])
559
560 # ------------------------------------------------------------------------------
561 have_vconsole=no
562 AC_ARG_ENABLE(vconsole, AS_HELP_STRING([--disable-vconsole], [disable vconsole tool]))
563 if test "x$enable_vconsole" != "xno"; then
564         have_vconsole=yes
565 fi
566 AM_CONDITIONAL(ENABLE_VCONSOLE, [test "$have_vconsole" = "yes"])
567
568 # ------------------------------------------------------------------------------
569 have_readahead=no
570 AC_ARG_ENABLE(readahead, AS_HELP_STRING([--disable-readahead], [disable readahead tools]))
571 if test "x$enable_readahead" != "xno"; then
572         have_readahead=yes
573 fi
574 AM_CONDITIONAL(ENABLE_READAHEAD, [test "$have_readahead" = "yes"])
575
576 # ------------------------------------------------------------------------------
577 have_bootchart=no
578 AC_ARG_ENABLE(bootchart, AS_HELP_STRING([--disable-bootchart], [disable bootchart tool]))
579 if test "x$enable_bootchart" != "xno"; then
580         have_bootchart=yes
581 fi
582 AM_CONDITIONAL(ENABLE_BOOTCHART, [test "$have_bootchart" = "yes"])
583
584 # ------------------------------------------------------------------------------
585 have_quotacheck=no
586 AC_ARG_ENABLE(quotacheck, AS_HELP_STRING([--disable-quotacheck], [disable quotacheck tools]))
587 if test "x$enable_quotacheck" != "xno"; then
588         have_quotacheck=yes
589 fi
590 AM_CONDITIONAL(ENABLE_QUOTACHECK, [test "$have_quotacheck" = "yes"])
591
592 # ------------------------------------------------------------------------------
593 have_randomseed=no
594 AC_ARG_ENABLE(randomseed, AS_HELP_STRING([--disable-randomseed], [disable randomseed tools]))
595 if test "x$enable_randomseed" != "xno"; then
596         have_randomseed=yes
597 fi
598 AM_CONDITIONAL(ENABLE_RANDOMSEED, [test "$have_randomseed" = "yes"])
599
600 # ------------------------------------------------------------------------------
601 have_logind=no
602 AC_ARG_ENABLE(logind, AS_HELP_STRING([--disable-logind], [disable login daemon]))
603 if test "x$enable_logind" != "xno"; then
604         have_logind=yes
605 fi
606 AM_CONDITIONAL(ENABLE_LOGIND, [test "$have_logind" = "yes"])
607 AS_IF([test "$have_logind" = "yes"], [ AC_DEFINE(HAVE_LOGIND, [1], [Logind support available]) ])
608
609 # ------------------------------------------------------------------------------
610 have_hostnamed=no
611 AC_ARG_ENABLE(hostnamed, AS_HELP_STRING([--disable-hostnamed], [disable hostname daemon]))
612 if test "x$enable_hostnamed" != "xno"; then
613         have_hostnamed=yes
614 fi
615 AM_CONDITIONAL(ENABLE_HOSTNAMED, [test "$have_hostnamed" = "yes"])
616
617 # ------------------------------------------------------------------------------
618 have_timedated=no
619 AC_ARG_ENABLE(timedated, AS_HELP_STRING([--disable-timedated], [disable timedate daemon]))
620 if test "x$enable_timedated" != "xno"; then
621         have_timedated=yes
622 fi
623 AM_CONDITIONAL(ENABLE_TIMEDATED, [test "$have_timedated" = "yes"])
624
625 # ------------------------------------------------------------------------------
626 have_localed=no
627 AC_ARG_ENABLE(localed, AS_HELP_STRING([--disable-localed], [disable locale daemon]))
628 if test "x$enable_localed" != "xno"; then
629         have_localed=yes
630 fi
631 AM_CONDITIONAL(ENABLE_LOCALED, [test "$have_localed" = "yes"])
632
633 # ------------------------------------------------------------------------------
634 have_coredump=no
635 AC_ARG_ENABLE(coredump, AS_HELP_STRING([--disable-coredump], [disable coredump hook]))
636 if test "x$enable_coredump" != "xno"; then
637         have_coredump=yes
638 fi
639 AM_CONDITIONAL(ENABLE_COREDUMP, [test "$have_coredump" = "yes"])
640
641 # ------------------------------------------------------------------------------
642 have_polkit=no
643 AC_ARG_ENABLE(polkit, AS_HELP_STRING([--disable-polkit], [disable PolicyKit support]))
644 if test "x$enable_polkit" != "xno"; then
645         AC_DEFINE(ENABLE_POLKIT, 1, [Define if PolicyKit support is to be enabled])
646         have_polkit=yes
647 fi
648 AM_CONDITIONAL(ENABLE_POLKIT, [test "x$have_polkit" = "xyes"])
649
650 # ------------------------------------------------------------------------------
651 have_efi=no
652 AC_ARG_ENABLE(efi, AS_HELP_STRING([--disable-efi], [disable EFI support]))
653 if test "x$enable_efi" != "xno"; then
654         AC_DEFINE(ENABLE_EFI, 1, [Define if EFI support is to be enabled])
655         have_efi=yes
656 fi
657 AM_CONDITIONAL(ENABLE_EFI, [test "x$have_efi" = "xyes"])
658
659 # ------------------------------------------------------------------------------
660 AC_ARG_WITH(rc-local-script-path-start,
661         AS_HELP_STRING([--with-rc-local-script-path-start=PATH],
662                 [Path to /etc/rc.local]),
663         [RC_LOCAL_SCRIPT_PATH_START="$withval"],
664         [RC_LOCAL_SCRIPT_PATH_START="/etc/rc.local"])
665
666 AC_ARG_WITH(rc-local-script-path-stop,
667         AS_HELP_STRING([--with-rc-local-script-path-stop=PATH],
668                 [Path to /usr/sbin/halt.local]),
669         [RC_LOCAL_SCRIPT_PATH_STOP="$withval"],
670         [RC_LOCAL_SCRIPT_PATH_STOP="/usr/sbin/halt.local"])
671
672 AC_DEFINE_UNQUOTED(RC_LOCAL_SCRIPT_PATH_START, ["$RC_LOCAL_SCRIPT_PATH_START"], [Path of /etc/rc.local script])
673 AC_DEFINE_UNQUOTED(RC_LOCAL_SCRIPT_PATH_STOP, ["$RC_LOCAL_SCRIPT_PATH_STOP"], [Path of /usr/sbin/halt.local script])
674
675 AC_SUBST(RC_LOCAL_SCRIPT_PATH_START)
676 AC_SUBST(RC_LOCAL_SCRIPT_PATH_STOP)
677
678 # ------------------------------------------------------------------------------
679 AC_ARG_WITH(kbd-loadkeys,
680         AS_HELP_STRING([--with-kbd-loadkeys=PATH],
681                 [Path to loadkeys]),
682         [KBD_LOADKEYS="$withval"],
683         [KBD_LOADKEYS="/usr/bin/loadkeys"])
684
685 AC_ARG_WITH(kbd-setfont,
686         AS_HELP_STRING([--with-kbd-setfont=PATH],
687                 [Path to setfont]),
688         [KBD_SETFONT="$withval"],
689         [KBD_SETFONT="/usr/bin/setfont"])
690
691 AC_DEFINE_UNQUOTED(KBD_LOADKEYS, ["$KBD_LOADKEYS"], [Path of loadkeys])
692 AC_DEFINE_UNQUOTED(KBD_SETFONT, ["$KBD_SETFONT"], [Path of setfont])
693
694 AC_SUBST(KBD_LOADKEYS)
695 AC_SUBST(KBD_SETFONT)
696
697 AC_ARG_WITH(telinit,
698         AS_HELP_STRING([--with-telinit=PATH],
699                 [Path to telinit]),
700         [TELINIT="$withval"],
701         [TELINIT="/lib/upstart/telinit"])
702
703 AC_DEFINE_UNQUOTED(TELINIT, ["$TELINIT"], [Path to telinit])
704
705 AC_SUBST(TELINIT)
706
707 AC_CHECK_HEADERS_ONCE([valgrind/memcheck.h])
708
709 # ------------------------------------------------------------------------------
710 have_myhostname=no
711 AC_ARG_ENABLE(myhostname, AS_HELP_STRING([--disable-myhostname], [disable nss-myhostname support]))
712 if test "x$enable_myhostname" != "xno"; then
713         AC_HEADER_STDC
714         AC_CHECK_HEADERS([arpa/inet.h fcntl.h inttypes.h netdb.h netinet/in.h stdlib.h string.h sys/socket.h sys/time.h unistd.h nss.h sys/ioctl.h])
715
716         AC_C_CONST
717         AC_TYPE_SIZE_T
718         AC_HEADER_TIME
719
720         AC_FUNC_MALLOC
721         AC_FUNC_SELECT_ARGTYPES
722         AC_CHECK_FUNCS([gethostbyaddr gethostbyname gettimeofday inet_ntoa memset select socket strcspn strdup strerror strncasecmp strcasecmp strspn])
723
724         have_myhostname=yes
725 fi
726 AM_CONDITIONAL(HAVE_MYHOSTNAME, [test "$have_myhostname" = "yes"])
727
728 # ------------------------------------------------------------------------------
729 AC_ARG_WITH(firmware-path,
730        AS_HELP_STRING([--with-firmware-path=DIR[[[:DIR[...]]]]],
731           [Firmware search path (default="")]),
732        [], [with_firmware_path=""])
733 OLD_IFS=$IFS
734 IFS=:
735 for i in $with_firmware_path; do
736        if test "x${FIRMWARE_PATH}" = "x"; then
737               FIRMWARE_PATH="\\\"${i}/\\\""
738        else
739               FIRMWARE_PATH="${FIRMWARE_PATH}, \\\"${i}/\\\""
740        fi
741 done
742 IFS=$OLD_IFS
743 AC_SUBST(FIRMWARE_PATH)
744 AS_IF([test "x${FIRMWARE_PATH}" != "x"], [ AC_DEFINE(HAVE_FIRMWARE, 1, [Define if FIRMWARE is available]) ])
745 AM_CONDITIONAL(ENABLE_FIRMWARE, [test "x${FIRMWARE_PATH}" != "x"])
746
747 # ------------------------------------------------------------------------------
748 AC_ARG_ENABLE([gudev],
749        AS_HELP_STRING([--disable-gudev], [disable Gobject libudev support @<:@default=enabled@:>@]),
750        [], [enable_gudev=yes])
751 AS_IF([test "x$enable_gudev" = "xyes"], [ PKG_CHECK_MODULES([GLIB], [glib-2.0 >= 2.22.0 gobject-2.0 >= 2.22.0 gio-2.0]) ])
752 AM_CONDITIONAL([ENABLE_GUDEV], [test "x$enable_gudev" = "xyes"])
753 AS_IF([test "x$enable_gudev" = "xyes"], [ AC_DEFINE(HAVE_GLIB, 1, [Define if glib is available]) ])
754
755 # ------------------------------------------------------------------------------
756 AC_ARG_ENABLE([keymap],
757        AS_HELP_STRING([--disable-keymap], [disable keymap fixup support @<:@default=enabled@:>@]),
758        [], [enable_keymap=yes])
759 AS_IF([test "x$enable_keymap" = "xyes"], [
760        AC_PATH_PROG([GPERF], [gperf])
761        if test -z "$GPERF"; then
762               AC_MSG_ERROR([gperf is needed])
763        fi
764
765        AC_CHECK_HEADER([linux/input.h], [:], AC_MSG_ERROR([kernel headers not found]))
766        AC_SUBST([INCLUDE_PREFIX], [$(echo '#include <linux/input.h>' | eval $ac_cpp -E - | sed -n '/linux\/input.h/ {s:.*"\(.*\)/linux/input.h".*:\1:; p; q}')])
767 ])
768 AM_CONDITIONAL([ENABLE_KEYMAP], [test "x$enable_keymap" = "xyes"])
769
770 # ------------------------------------------------------------------------------
771 have_manpages=no
772 AC_ARG_ENABLE(manpages, AS_HELP_STRING([--disable-manpages], [disable manpages]))
773 AS_IF([test "x$enable_manpages" != xno], [
774         AS_IF([test "x$enable_manpages" = xyes -a "x$XSLTPROC" = x], [
775                 AC_MSG_ERROR([*** Manpages requested but xsltproc not found])
776         ])
777         AS_IF([test "x$XSLTPROC" != x], [have_manpages=yes])
778 ])
779 AM_CONDITIONAL(ENABLE_MANPAGES, [test "x$have_manpages" = "xyes"])
780
781 # ------------------------------------------------------------------------------
782
783 # Location of the init scripts as mandated by LSB
784 SYSTEM_SYSVINIT_PATH=/etc/init.d
785 SYSTEM_SYSVRCND_PATH=/etc/rc.d
786 M4_DEFINES=
787
788 AC_ARG_WITH([sysvinit-path],
789         [AS_HELP_STRING([--with-sysvinit-path=PATH],
790                 [Specify the path to where the SysV init scripts are located])],
791         [SYSTEM_SYSVINIT_PATH="$withval"],
792         [])
793
794 AC_ARG_WITH([sysvrcnd-path],
795         [AS_HELP_STRING([--with-sysvrcnd-path=PATH],
796                 [Specify the path to the base directory for the SysV rcN.d directories])],
797         [SYSTEM_SYSVRCND_PATH="$withval"],
798         [])
799
800 if test "x${SYSTEM_SYSVINIT_PATH}" != "x" -a "x${SYSTEM_SYSVRCND_PATH}" != "x"; then
801         AC_DEFINE(HAVE_SYSV_COMPAT, [], [SysV init scripts and rcN.d links are supported.])
802         SYSTEM_SYSV_COMPAT="yes"
803         M4_DEFINES="$M4_DEFINES -DHAVE_SYSV_COMPAT"
804 elif test "x${SYSTEM_SYSVINIT_PATH}" != "x" -o "x${SYSTEM_SYSVRCND_PATH}" != "x"; then
805         AC_MSG_ERROR([*** You need both --with-sysvinit-path=PATH and --with-sysvrcnd-path=PATH to enable SysV compatibility support, or both empty to disable it.])
806 else
807         SYSTEM_SYSV_COMPAT="no"
808 fi
809
810 AC_SUBST(SYSTEM_SYSVINIT_PATH)
811 AC_SUBST(SYSTEM_SYSVRCND_PATH)
812 AC_SUBST(M4_DEFINES)
813
814 AM_CONDITIONAL(HAVE_SYSV_COMPAT, test "$SYSTEM_SYSV_COMPAT" = "yes")
815
816 AC_ARG_WITH([tty-gid],
817         [AS_HELP_STRING([--with-tty-gid=GID],
818                 [Specify the numeric GID of the 'tty' group])],
819         [AC_DEFINE_UNQUOTED(TTY_GID, [$withval], [GID of the 'tty' group])],
820         [])
821
822 AC_ARG_WITH([dbuspolicydir],
823         AS_HELP_STRING([--with-dbuspolicydir=DIR], [D-Bus policy directory]),
824         [],
825         [with_dbuspolicydir=$($PKG_CONFIG --variable=sysconfdir dbus-1)/dbus-1/system.d])
826
827 AC_ARG_WITH([dbussessionservicedir],
828         AS_HELP_STRING([--with-dbussessionservicedir=DIR], [D-Bus session service directory]),
829         [],
830         [with_dbussessionservicedir=$($PKG_CONFIG --variable=session_bus_services_dir dbus-1)])
831
832 AC_ARG_WITH([dbussystemservicedir],
833         AS_HELP_STRING([--with-dbussystemservicedir=DIR], [D-Bus system service directory]),
834         [],
835         [with_dbussystemservicedir=$(readlink -m $($PKG_CONFIG --variable=session_bus_services_dir dbus-1)/../system-services)])
836
837 AC_ARG_WITH([dbusinterfacedir],
838         AS_HELP_STRING([--with-dbusinterfacedir=DIR], [D-Bus interface directory]),
839         [],
840         [with_dbusinterfacedir=$(readlink -m $($PKG_CONFIG --variable=session_bus_services_dir dbus-1)/../interfaces)])
841
842 AC_ARG_WITH([bashcompletiondir],
843         AS_HELP_STRING([--with-bashcompletiondir=DIR], [Bash completions directory]),
844         [],
845         [AS_IF([$($PKG_CONFIG --exists bash-completion)], [
846                 with_bashcompletiondir=$($PKG_CONFIG --variable=completionsdir bash-completion)
847         ] , [
848                 with_bashcompletiondir=${datadir}/bash-completion/completions
849         ])])
850
851 AC_ARG_WITH([rootprefix],
852         AS_HELP_STRING([--with-rootprefix=DIR], [rootfs directory prefix for config files and kernel modules]),
853         [], [with_rootprefix=${ac_default_prefix}])
854
855 AC_ARG_WITH([rootlibdir],
856         AS_HELP_STRING([--with-rootlibdir=DIR], [Root directory for libraries necessary for boot]),
857         [],
858         [with_rootlibdir=${libdir}])
859
860 AC_ARG_WITH([pamlibdir],
861         AS_HELP_STRING([--with-pamlibdir=DIR], [Directory for PAM modules]),
862         [],
863         [with_pamlibdir=${with_rootlibdir}/security])
864
865 AC_ARG_ENABLE([split-usr],
866         AS_HELP_STRING([--enable-split-usr], [Assume that /bin, /sbin aren\'t symlinks into /usr]),
867         [],
868         [AS_IF([test "x${ac_default_prefix}" != "x${with_rootprefix}"], [
869                 enable_split_usr=yes
870         ], [
871                 enable_split_usr=no
872         ])])
873
874 AS_IF([test "x${enable_split_usr}" = "xyes"], [
875         AC_DEFINE(HAVE_SPLIT_USR, 1, [Define if /bin, /sbin aren't symlinks into /usr])
876 ])
877
878 # Work around intltoolize and gtk-doc problems in VPATH builds
879 AM_CONDITIONAL([ENABLE_GTK_DOC_TESTS], [test "x$0" = "x./configure"],
880                                        [Define to do gtk-doc tests])
881 AS_IF([test "x$0" != "x./configure"], [
882         AC_SUBST([INTLTOOL_UPDATE], [/bin/true])
883 ])
884
885 AC_ARG_ENABLE(tests,
886        [AC_HELP_STRING([--disable-tests], [disable tests])],
887        enable_tests=$enableval, enable_tests=yes)
888 AM_CONDITIONAL(ENABLE_TESTS, [test x$enable_tests = xyes])
889
890 AC_SUBST([dbuspolicydir], [$with_dbuspolicydir])
891 AC_SUBST([dbussessionservicedir], [$with_dbussessionservicedir])
892 AC_SUBST([dbussystemservicedir], [$with_dbussystemservicedir])
893 AC_SUBST([dbusinterfacedir], [$with_dbusinterfacedir])
894 AC_SUBST([bashcompletiondir], [$with_bashcompletiondir])
895 AC_SUBST([pamlibdir], [$with_pamlibdir])
896 AC_SUBST([rootprefix], [$with_rootprefix])
897 AC_SUBST([rootlibdir], [$with_rootlibdir])
898
899 AC_CONFIG_FILES([
900         Makefile po/Makefile.in
901         docs/libudev/Makefile
902         docs/libudev/version.xml
903         docs/gudev/Makefile
904         docs/gudev/version.xml
905 ])
906
907 AC_OUTPUT
908 AC_MSG_RESULT([
909         $PACKAGE_NAME $VERSION
910
911         libcryptsetup:           ${have_libcryptsetup}
912         tcpwrap:                 ${have_tcpwrap}
913         PAM:                     ${have_pam}
914         AUDIT:                   ${have_audit}
915         IMA:                     ${have_ima}
916         SELinux:                 ${have_selinux}
917         XZ:                      ${have_xz}
918         ACL:                     ${have_acl}
919         XATTR:                   ${have_xattr}
920         GCRYPT:                  ${have_gcrypt}
921         QRENCODE:                ${have_qrencode}
922         MICROHTTPD:              ${have_microhttpd}
923         CHKCONFIG:               ${have_chkconfig}
924         binfmt:                  ${have_binfmt}
925         vconsole:                ${have_vconsole}
926         readahead:               ${have_readahead}
927         bootchart:               ${have_bootchart}
928         quotacheck:              ${have_quotacheck}
929         randomseed:              ${have_randomseed}
930         logind:                  ${have_logind}
931         hostnamed:               ${have_hostnamed}
932         timedated:               ${have_timedated}
933         localed:                 ${have_localed}
934         coredump:                ${have_coredump}
935         polkit:                  ${have_polkit}
936         efi:                     ${have_efi}
937         kmod:                    ${have_kmod}
938         blkid:                   ${have_blkid}
939         nss-myhostname:          ${have_myhostname}
940         gudev:                   ${enable_gudev}
941         gintrospection:          ${enable_introspection}
942         keymap:                  ${enable_keymap}
943         Python:                  ${have_python}
944         Python Headers:          ${have_python_devel}
945         man pages:               ${have_manpages}
946         gtk-doc:                 ${enable_gtk_doc}
947         Split /usr:              ${enable_split_usr}
948         SysV compatibility:      ${SYSTEM_SYSV_COMPAT}
949
950         prefix:                  ${prefix}
951         rootprefix:              ${with_rootprefix}
952         sysconf dir:             ${sysconfdir}
953         datarootdir:             ${datarootdir}
954         includedir:              ${includedir}
955         include_prefix:          ${INCLUDE_PREFIX}
956         lib dir:                 ${libdir}
957         rootlib dir:             ${with_rootlibdir}
958         SysV init scripts:       ${SYSTEM_SYSVINIT_PATH}
959         SysV rc?.d directories:  ${SYSTEM_SYSVRCND_PATH}
960         Build Python:            ${PYTHON}
961         Installation Python:     ${PYTHON_BINARY}
962         firmware path:           ${FIRMWARE_PATH}
963         PAM modules dir:         ${with_pamlibdir}
964         D-Bus policy dir:        ${with_dbuspolicydir}
965         D-Bus session dir:       ${with_dbussessionservicedir}
966         D-Bus system dir:        ${with_dbussystemservicedir}
967         D-Bus interfaces dir:    ${with_dbusinterfacedir}
968         Bash completions dir:    ${with_bashcompletiondir}
969         Extra start script:      ${RC_LOCAL_SCRIPT_PATH_START}
970         Extra stop script:       ${RC_LOCAL_SCRIPT_PATH_STOP}
971         Debug shell:             ${SUSHELL} @ ${DEBUGTTY}
972
973         CFLAGS:                  ${OUR_CFLAGS} ${CFLAGS}
974         CPPFLAGS:                ${OUR_CPPFLAGS} ${CPPFLAGS}
975         LDFLAGS:                 ${OUR_LDFLAGS} ${LDFLAGS}
976         PYTHON_CFLAGS:           ${PYTHON_CFLAGS}
977         PYTHON_LIBS:             ${PYTHON_LIBS}
978 ])