chiark / gitweb /
634f91edab17ee52103433f1e1790f3f92b14dba
[dgit.git] / infra / dgit-repos-server
1 #!/usr/bin/perl -w
2 # dgit-repos-server
3 #
4 # usages:
5 #   dgit-repos-server DISTRO DISTRO-DIR AUTH-SPEC [<settings>] --ssh
6 #   dgit-repos-server DISTRO DISTRO-DIR AUTH-SPEC [<settings>] --cron
7 # settings
8 #   --repos=GIT-REPOS-DIR      default DISTRO-DIR/repos/
9 #   --suites=SUITES-FILE       default DISTRO-DIR/suites
10 #   --policy-hook=POLICY-HOOK  default DISTRO-DIR/policy-hook
11 #   --dgit-live=DGIT-LIVE-DIR  default DISTRO-DIR/dgit-live
12 # (DISTRO-DIR is not used other than as default)
13 # internal usage:
14 #  .../dgit-repos-server --pre-receive-hook PACKAGE
15 #
16 # Invoked as the ssh restricted command
17 #
18 # Works like git-receive-pack
19 #
20 # SUITES is the name of a file which lists the permissible suites
21 # one per line (#-comments and blank lines ignored)
22 #
23 # AUTH-SPEC is a :-separated list of
24 #   KEYRING.GPG,AUTH-SPEC
25 # where AUTH-SPEC is one of
26 #   a
27 #   mDM.TXT
28 # (With --cron AUTH-SPEC is not used and may be the empty string.)
29
30 use strict;
31 $SIG{__WARN__} = sub { die $_[0]; };
32
33 # DGIT-REPOS-DIR contains:
34 # git tree (or other object)      lock (in acquisition order, outer first)
35 #
36 #  _tmp/PACKAGE_prospective       ! } SAME.lock, held during receive-pack
37 #
38 #  _tmp/PACKAGE_incoming$$        ! } SAME.lock, held during receive-pack
39 #  _tmp/PACKAGE_incoming$$_fresh  ! }
40 #
41 #  PACKAGE.git                      } PACKAGE.git.lock
42 #  PACKAGE_garbage                  }   (also covers executions of
43 #  PACKAGE_garbage-old              }    policy hook script for PACKAGE)
44 #  PACKAGE_garbage-tmp              }
45 #  policy*                          } (for policy hook script, covered by
46 #                                   }  lock only when invoked for a package)
47 #
48 # leaf locks, held during brief operaton only:
49 #
50 #  _empty                           } SAME.lock
51 #  _empty.new                       }
52 #
53 #  _template                        } SAME.lock
54 #
55 # locks marked ! may be held during client data transfer
56
57 # What we do on push is this:
58 #  - extract the destination repo name
59 #  - make a hardlink clone of the destination repo
60 #  - provide the destination with a stunt pre-receive hook
61 #  - run actual git-receive-pack with that new destination
62 #   as a result of this the stunt pre-receive hook runs; it does this:
63 #    + understand what refs we are allegedly updating and
64 #      check some correspondences:
65 #        * we are updating only refs/tags/debian/* and refs/dgit/*
66 #        * and only one of each
67 #        * and the tag does not already exist
68 #      and
69 #        * recover the suite name from the destination refs/dgit/ ref
70 #    + disassemble the signed tag into its various fields and signature
71 #      including:
72 #        * parsing the first line of the tag message to recover
73 #          the package name, version and suite
74 #        * checking that the package name corresponds to the dest repo name
75 #        * checking that the suite name is as recovered above
76 #    + verify the signature on the signed tag
77 #      and if necessary check that the keyid and package are listed in dm.txt
78 #    + check various correspondences:
79 #        * the signed tag must refer to a commit
80 #        * the signed tag commit must be the refs/dgit value
81 #        * the name in the signed tag must correspond to its ref name
82 #        * the tag name must be debian/<version> (massaged as needed)
83 #        * the suite is one of those permitted
84 #        * the signed tag has a suitable name
85 #        * run the "push" policy hook
86 #        * replay prevention for --deliberately-not-fast-forward
87 #        * check the commit is a fast forward
88 #        * handle a request from the policy hook for a fresh repo
89 #    + push the signed tag and new dgit branch to the actual repo
90 #
91 # If the destination repo does not already exist, we need to make
92 # sure that we create it reasonably atomically, and also that
93 # we don't every have a destination repo containing no refs at all
94 # (because such a thing causes git-fetch-pack to barf).  So then we
95 # do as above, except:
96 #  - before starting, we take out our own lock for the destination repo
97 #  - we create a prospective new destination repo by making a copy
98 #    of _template
99 #  - we use the prospective new destination repo instead of the
100 #    actual new destination repo (since the latter doesn't exist)
101 #  - after git-receive-pack exits, we
102 #    + check that the prospective repo contains a tag and head
103 #    + rename the prospective destination repo into place
104 #
105 # Cleanup strategy:
106 #  - We are crash-only
107 #  - Temporary working trees and their locks are cleaned up
108 #    opportunistically by a program which tries to take each lock and
109 #    if successful deletes both the tree and the lockfile
110 #  - Prospective working trees and their locks are cleaned up by
111 #    a program which tries to take each lock and if successful
112 #    deletes any prospective working tree and the lock (but not
113 #    of course any actual tree)
114 #  - It is forbidden to _remove_ the lockfile without removing
115 #    the corresponding temporary tree, as the lockfile is also
116 #    a stampfile whose presence indicates that there may be
117 #    cleanup to do
118 #
119 # Policy hook script is invoked like this:
120 #   POLICY-HOOK-SCRIPT DISTRO DGIT-REPOS-DIR DGIT-LIVE-DIR ACTION...
121 # ie.
122 #   POLICY-HOOK-SCRIPT ... check-list [...]
123 #   POLICY-HOOK-SCRIPT ... check-package PACKAGE [...]
124 #   POLICY-HOOK-SCRIPT ... push PACKAGE \
125 #         VERSION SUITE TAGNAME DELIBERATELIES [...]
126 #   POLICY-HOOK-SCRIPT ... push-confirm PACKAGE \
127 #         VERSION SUITE TAGNAME DELIBERATELIES FRESH-REPO|'' [...]
128 #
129 # Exit status is a bitmask.  Bit weight constants are defined in Dgit.pm.
130 #    NOFFCHECK   (2)
131 #         suppress dgit-repos-server's fast-forward check ("push" only)
132 #    FRESHREPO   (4)
133 #         blow away repo right away (ie, as if before push or fetch)
134 #         ("check-package" and "push" only)
135 # any unexpected bits mean failure, and then known set bits are ignored
136 # if no unexpected bits set, operation continues (subject to meaning
137 # of any expected bits set).  So, eg, exit 0 means "continue normally"
138 # and would be appropriate for an unknown action.
139 #
140 # cwd for push and push-confirm is a temporary repo where the
141 # to-be-pushed objects have been received; TAGNAME is the
142 # version-based tag
143 #
144 # FRESH-REPO is '' iff the repo for this package already existed, or
145 # the pathname of the newly-created repo which will be renamed into
146 # place if everything goes well.  (NB that this is generally not the
147 # same repo as the cwd, because the objects are first received into a
148 # temporary repo so they can be examined.)
149
150 # if push requested FRESHREPO, push-confirm happens in said fresh repo
151 # and FRESH-REPO is guaranteed not to be ''.
152 #
153 # policy hook for a particular package will be invoked only once at
154 # a time - (see comments about DGIT-REPOS-DIR, above)
155 #
156 # check-list and check-package are invoked via the --cron option.
157 # First, without any locking, check-list is called.  It should produce
158 # a list of package names (one per line).  Then check-package will be
159 # invoked for each named package, in each case after taking an
160 # appropriate lock.
161 #
162 # If policy hook wants to run dgit (or something else in the dgit
163 # package), it should use DGIT-LIVE-DIR/dgit (etc.)
164
165
166 use POSIX;
167 use Fcntl qw(:flock);
168 use File::Path qw(rmtree);
169 use File::Temp qw(tempfile);
170
171 use Debian::Dgit qw(:DEFAULT :policyflags);
172
173 initdebug('');
174
175 our $func;
176 our $dgitrepos;
177 our $package;
178 our $distro;
179 our $suitesfile;
180 our $policyhook;
181 our $dgitlive;
182 our $destrepo;
183 our $workrepo;
184 our $keyrings;
185 our @lockfhs;
186
187 our @deliberatelies;
188 our %supersedes;
189 our $policy;
190
191 #----- utilities -----
192
193 sub realdestrepo () { "$dgitrepos/$package.git"; }
194
195 sub acquirelock ($$) {
196     my ($lock, $must) = @_;
197     my $fh;
198     printdebug sprintf "locking %s %d\n", $lock, $must;
199     for (;;) {
200         close $fh if $fh;
201         $fh = new IO::File $lock, ">" or die "open $lock: $!";
202         my $ok = flock $fh, $must ? LOCK_EX : (LOCK_EX|LOCK_NB);
203         if (!$ok) {
204             die "flock $lock: $!" if $must;
205             printdebug " locking $lock failed\n";
206             return undef;
207         }
208         next unless stat_exists $lock;
209         my $want = (stat _)[1];
210         stat $fh or die $!;
211         my $got = (stat _)[1];
212         last if $got == $want;
213     }
214     return $fh;
215 }
216
217 sub acquirermtree ($$) {
218     my ($tree, $must) = @_;
219     my $fh = acquirelock("$tree.lock", $must);
220     if ($fh) {
221         push @lockfhs, $fh;
222         rmtree $tree;
223     }
224     return $fh;
225 }
226
227 sub locksometree ($) {
228     my ($tree) = @_;
229     acquirelock("$tree.lock", 1);
230 }
231
232 sub lockrealtree () {
233     locksometree(realdestrepo);
234 }
235
236 sub mkrepotmp () {
237     my $tmpdir = "$dgitrepos/_tmp";
238     return if mkdir $tmpdir;
239     return if $! == EEXIST;
240     die $!;
241 }
242
243 sub recorderror ($) {
244     my ($why) = @_;
245     my $w = $ENV{'DGIT_DRS_WORK'}; # we are in stunthook
246     if (defined $w) {
247         chomp $why;
248         open ERR, ">", "$w/drs-error" or die $!;
249         print ERR $why, "\n" or die $!;
250         close ERR or die $!;
251         return 1;
252     }
253     return 0;
254 }
255
256 sub reject ($) {
257     my ($why) = @_;
258     recorderror "reject: $why";
259     die "dgit-repos-server: reject: $why\n";
260 }
261
262 sub runcmd {
263     debugcmd '+',@_;
264     $!=0; $?=0;
265     my $r = system @_;
266     die (shellquote @_)." $? $!" if $r;
267 }
268
269 sub policyhook {
270     my ($policyallowbits, @polargs) = @_;
271     # => ($exitstatuspolicybitmap);
272     die if $policyallowbits & ~0x3e;
273     my @cmd = ($policyhook,$distro,$dgitrepos,$dgitlive,@polargs);
274     debugcmd '+',@cmd;
275     my $r = system @cmd;
276     die "system: $!" if $r < 0;
277     die "hook (".(shellquote @cmd).") failed ($?)"
278         if $r & ~($policyallowbits << 8);
279     printdebug sprintf "hook => %#x\n", $r;
280     return $r >> 8;
281 }
282
283 sub mkemptyrepo ($$) {
284     my ($dir,$sharedperm) = @_;
285     runcmd qw(git init --bare --quiet), "--shared=$sharedperm", $dir;
286 }
287
288 sub mkrepo_fromtemplate ($) {
289     my ($dir) = @_;
290     my $template = "$dgitrepos/_template";
291     locksometree($template);
292     printdebug "copy template $template -> $dir\n";
293     my $r = system qw(cp -a --), $template, $dir;
294     !$r or die "create new repo $dir failed: $r $!";
295 }
296
297 sub movetogarbage () {
298     # realdestrepo must have been locked
299     my $garbagerepo = "$dgitrepos/${package}_garbage";
300     # We arrange to always keep at least one old tree, for anti-rewind
301     # purposes (and, I guess, recovery from mistakes).  This is either
302     # $garbage or $garbage-old.
303     if (stat_exists "$garbagerepo") {
304         printdebug "movetogarbage: rmtree $garbagerepo-tmp\n";
305         rmtree "$garbagerepo-tmp";
306         if (rename "$garbagerepo-old", "$garbagerepo-tmp") {
307             printdebug "movetogarbage: $garbagerepo-old -> -tmp, rmtree\n";
308             rmtree "$garbagerepo-tmp";
309         } else {
310             die "$garbagerepo $!" unless $!==ENOENT;
311             printdebug "movetogarbage: $garbagerepo-old -> -tmp\n";
312         }
313         printdebug "movetogarbage: $garbagerepo -> -old\n";
314         rename "$garbagerepo", "$garbagerepo-old" or die "$garbagerepo $!";
315     }
316     my $real = realdestrepo;
317     printdebug "movetogarbage: $real -> $garbagerepo\n";
318     rename $real, $garbagerepo
319         or $! == ENOENT
320         or die "$garbagerepo $!";
321 }
322
323 sub policy_checkpackage () {
324     my $lfh = lockrealtree();
325
326     $policy = policyhook(FRESHREPO,'check-package',$package);
327     if ($policy & FRESHREPO) {
328         movetogarbage();
329     }
330
331     close $lfh;
332 }
333
334 #----- git-receive-pack -----
335
336 sub fixmissing__git_receive_pack () {
337     mkrepotmp();
338     $destrepo = "$dgitrepos/_tmp/${package}_prospective";
339     acquirermtree($destrepo, 1);
340     mkrepo_fromtemplate($destrepo);
341 }
342
343 sub makeworkingclone () {
344     mkrepotmp();
345     $workrepo = "$dgitrepos/_tmp/${package}_incoming$$";
346     acquirermtree($workrepo, 1);
347     my $lfh = lockrealtree();
348     runcmd qw(git clone -l -q --mirror), $destrepo, $workrepo;
349     close $lfh;
350     rmtree "${workrepo}_fresh";
351 }
352
353 sub setupstunthook () {
354     my $prerecv = "$workrepo/hooks/pre-receive";
355     my $fh = new IO::File $prerecv, O_WRONLY|O_CREAT|O_TRUNC, 0777
356         or die "$prerecv: $!";
357     print $fh <<END or die "$prerecv: $!";
358 #!/bin/sh
359 set -e
360 exec $0 --pre-receive-hook $package
361 END
362     close $fh or die "$prerecv: $!";
363     $ENV{'DGIT_DRS_WORK'}= $workrepo;
364     $ENV{'DGIT_DRS_DEST'}= $destrepo;
365     printdebug " stunt hook set up $prerecv\n";
366 }
367
368 sub dealwithfreshrepo () {
369     my $freshrepo = "${workrepo}_fresh";
370     return unless stat_exists $freshrepo;
371     $destrepo = $freshrepo;
372 }
373
374 sub maybeinstallprospective () {
375     return if $destrepo eq realdestrepo;
376
377     if (open REJ, "<", "$workrepo/drs-error") {
378         local $/ = undef;
379         my $msg = <REJ>;
380         REJ->error and die $!;
381         print STDERR $msg;
382         exit 1;
383     } else {
384         $!==&ENOENT or die $!;
385     }
386
387     printdebug " show-ref ($destrepo) ...\n";
388
389     my $child = open SR, "-|";
390     defined $child or die $!;
391     if (!$child) {
392         chdir $destrepo or die $!;
393         exec qw(git show-ref);
394         die $!;
395     }
396     my %got = qw(tag 0 head 0);
397     while (<SR>) {
398         chomp or die;
399         printdebug " show-refs| $_\n";
400         s/^\S*[1-9a-f]\S* (\S+)$/$1/ or die;
401         my $wh =
402             m{^refs/tags/} ? 'tag' :
403             m{^refs/dgit/} ? 'head' :
404             die;
405         die if $got{$wh}++;
406     }
407     $!=0; $?=0; close SR or $?==256 or die "$? $!";
408
409     printdebug "installprospective ?\n";
410     die Dumper(\%got)." -- missing refs in new repo"
411         if grep { !$_ } values %got;
412
413     lockrealtree();
414
415     if ($destrepo eq "${workrepo}_fresh") {
416         movetogarbage;
417     }
418
419     printdebug "install $destrepo => ".realdestrepo."\n";
420     rename $destrepo, realdestrepo or die $!;
421     remove "$destrepo.lock" or die $!;
422 }
423
424 sub main__git_receive_pack () {
425     makeworkingclone();
426     setupstunthook();
427     runcmd qw(git receive-pack), $workrepo;
428     dealwithfreshrepo();
429     maybeinstallprospective();
430 }
431
432 #----- stunt post-receive hook -----
433
434 our ($tagname, $tagval, $suite, $oldcommit, $commit);
435 our ($version, %tagh);
436
437 sub readupdates () {
438     printdebug " updates ...\n";
439     while (<STDIN>) {
440         chomp or die;
441         printdebug " upd.| $_\n";
442         m/^(\S+) (\S+) (\S+)$/ or die "$_ ?";
443         my ($old, $sha1, $refname) = ($1, $2, $3);
444         if ($refname =~ m{^refs/tags/(?=debian/)}) {
445             reject "pushing multiple tags!" if defined $tagname;
446             $tagname = $'; #';
447             $tagval = $sha1;
448             reject "tag $tagname already exists -".
449                 " not replacing previously-pushed version"
450                 if $old =~ m/[^0]/;
451         } elsif ($refname =~ m{^refs/dgit/}) {
452             reject "pushing multiple heads!" if defined $suite;
453             $suite = $'; #';
454             $oldcommit = $old;
455             $commit = $sha1;
456         } else {
457             reject "pushing unexpected ref!";
458         }
459     }
460     STDIN->error and die $!;
461
462     reject "push is missing tag ref update" unless defined $tagname;
463     reject "push is missing head ref update" unless defined $suite;
464     printdebug " updates ok.\n";
465 }
466
467 sub parsetag () {
468     printdebug " parsetag...\n";
469     open PT, ">dgit-tmp/plaintext" or die $!;
470     open DS, ">dgit-tmp/plaintext.asc" or die $!;
471     open T, "-|", qw(git cat-file tag), $tagval or die $!;
472     for (;;) {
473         $!=0; $_=<T>; defined or die $!;
474         print PT or die $!;
475         if (m/^(\S+) (.*)/) {
476             push @{ $tagh{$1} }, $2;
477         } elsif (!m/\S/) {
478             last;
479         } else {
480             die;
481         }
482     }
483     $!=0; $_=<T>; defined or die $!;
484     m/^($package_re) release (\S+) for \S+ \((\S+)\) \[dgit\]$/ or
485         reject "tag message not in expected format";
486
487     die unless $1 eq $package;
488     $version = $2;
489     die "$3 != $suite " unless $3 eq $suite;
490
491     my $copyl = $_;
492     for (;;) {
493         print PT $copyl or die $!;
494         $!=0; $_=<T>; defined or die "missing signature? $!";
495         $copyl = $_;
496         if (m/^\[dgit ([^"].*)\]$/) { # [dgit "something"] is for future
497             $_ = $1." ";
498             while (length) {
499                 if (s/^distro\=(\S+) //) {
500                     die "$1 != $distro" unless $1 eq $distro;
501                 } elsif (s/^(--deliberately-$package_re) //) {
502                     push @deliberatelies, $1;
503                 } elsif (s/^supersede:(\S+)=(\w+) //) {
504                     die "supersede $1 twice" if defined $supersedes{$1};
505                     $supersedes{$1} = $2;
506                 } elsif (s/^[-+.=0-9a-z]\S* //) {
507                 } else {
508                     die "unknown dgit info in tag ($_)";
509                 }
510             }
511             next;
512         }
513         last if m/^-----BEGIN PGP/;
514     }
515     $_ = $copyl;
516     for (;;) {
517         print DS or die $!;
518         $!=0; $_=<T>;
519         last if !defined;
520     }
521     T->error and die $!;
522     close PT or die $!;
523     close DS or die $!;
524     printdebug " parsetag ok.\n";
525 }
526
527 sub checksig_keyring ($) {
528     my ($keyringfile) = @_;
529     # returns primary-keyid if signed by a key in this keyring
530     # or undef if not
531     # or dies on other errors
532
533     my $ok = undef;
534
535     printdebug " checksig keyring $keyringfile...\n";
536
537     our @cmd = (qw(gpgv --status-fd=1 --keyring),
538                    $keyringfile,
539                    qw(dgit-tmp/plaintext.asc dgit-tmp/plaintext));
540     debugcmd '|',@cmd;
541
542     open P, "-|", @cmd
543         or die $!;
544
545     while (<P>) {
546         next unless s/^\[GNUPG:\] //;
547         chomp or die;
548         printdebug " checksig| $_\n";
549         my @l = split / /, $_;
550         if ($l[0] eq 'NO_PUBKEY') {
551             last;
552         } elsif ($l[0] eq 'VALIDSIG') {
553             my $sigtype = $l[9];
554             $sigtype eq '00' or reject "signature is not of type 00!";
555             $ok = $l[10];
556             die unless defined $ok;
557             last;
558         }
559     }
560     close P;
561
562     printdebug sprintf " checksig ok=%d\n", !!$ok;
563
564     return $ok;
565 }
566
567 sub dm_txt_check ($$) {
568     my ($keyid, $dmtxtfn) = @_;
569     printdebug " dm_txt_check $keyid $dmtxtfn\n";
570     open DT, '<', $dmtxtfn or die "$dmtxtfn $!";
571     while (<DT>) {
572         m/^fingerprint:\s+$keyid$/oi
573             ..0 or next;
574         if (s/^allow:/ /i..0) {
575         } else {
576             m/^./
577                 or reject "key $keyid missing Allow section in permissions!";
578             next;
579         }
580         # in right stanza...
581         s/^[ \t]+//
582             or reject "package $package not allowed for key $keyid";
583         # in allow field...
584         s/\([^()]+\)//;
585         s/\,//;
586         chomp or die;
587         printdebug " dm_txt_check allow| $_\n";
588         foreach my $p (split /\s+/) {
589             if ($p eq $package) {
590                 # yay!
591                 printdebug " dm_txt_check ok\n";
592                 return;
593             }
594         }
595     }
596     DT->error and die $!;
597     close DT or die $!;
598     reject "key $keyid not in permissions list although in keyring!";
599 }
600
601 sub verifytag () {
602     foreach my $kas (split /:/, $keyrings) {
603         printdebug "verifytag $kas...\n";
604         $kas =~ s/^([^,]+),// or die;
605         my $keyid = checksig_keyring $1;
606         if (defined $keyid) {
607             if ($kas =~ m/^a$/) {
608                 printdebug "verifytag a ok\n";
609                 return; # yay
610             } elsif ($kas =~ m/^m([^,]+)$/) {
611                 dm_txt_check($keyid, $1);
612                 printdebug "verifytag m ok\n";
613                 return;
614             } else {
615                 die;
616             }
617         }   
618     }
619     reject "key not found in keyrings";
620 }
621
622 sub checksuite () {
623     printdebug "checksuite ($suitesfile)\n";
624     open SUITES, "<", $suitesfile or die $!;
625     while (<SUITES>) {
626         chomp;
627         next unless m/\S/;
628         next if m/^\#/;
629         s/\s+$//;
630         return if $_ eq $suite;
631     }
632     die $! if SUITES->error;
633     reject "unknown suite";
634 }
635
636 sub checktagnoreplay () {
637     # We check that the signed tag mentions the name and value of
638     # (a) in the case of FRESHREPO all tags in the repo;
639     # (b) in the case of just NOFFCHECK all tags referring to
640     # the current head for the suite (there must be at least one).
641     # This prevents a replay attack using an earlier signed tag.
642     return unless $policy & (FRESHREPO|NOFFCHECK);
643
644     my $garbagerepo = "$dgitrepos/${package}_garbage";
645     lockrealtree();
646
647     local $ENV{GIT_DIR};
648     foreach my $garb ("$garbagerepo", "$garbagerepo-old") {
649         if (stat_exists $garb) {
650             $ENV{GIT_DIR} = $garb;
651             last;
652         }
653     }
654     if (!defined $ENV{GIT_DIR}) {
655         # Nothing to overwrite so the FRESHREPO and NOFFCHECK were
656         # pointless.  Oh well.
657         printdebug "checktagnoreplay - no garbage, ok\n";
658         return;
659     }
660
661     my $onlyreferring;
662     if (!($policy & FRESHREPO)) {
663         my $branch = server_branch($suite);
664         $!=0; $?=0; $_ =
665             `git for-each-ref --format='%(objectname)' '[r]efs/$branch'`;
666         defined or die "$branch $? $!";
667         $? and die "$branch $?";
668         if (!length) {
669             # No such branch - NOFFCHECK was unnecessary.  Oh well.
670             printdebug "checktagnoreplay - not FRESHREPO, new branch, ok\n";
671             return;
672         }
673         m/^(\w+)\n$/ or die "$branch $_ ?";
674         $onlyreferring = $1;
675         printdebug "checktagnoreplay - not FRESHREPO,".
676             " checking for overwriting refs/$branch=$onlyreferring\n";
677     }
678
679     my @problems;
680
681     git_for_each_tag_referring($onlyreferring, sub {
682         my ($objid,$fullrefname,$tagname) = @_;
683         printdebug "checktagnoreplay - overwriting $fullrefname=$objid\n";
684         my $supers = $supersedes{$fullrefname};
685         if (!defined $supers) {
686             push @problems, "does not supersede $fullrefname";
687         } elsif ($supers ne $objid) {
688             push @problems,
689  "supersedes $fullrefname=$supers but previously $fullrefname=$objid";
690         } else {
691             # ok;
692         }
693     });
694
695     if (@problems) {
696         reject "replay attack prevention check failed:".
697             " signed tag for $version: ".
698             join("; ", @problems).
699             "\n";
700     }
701     printdebug "checktagnoreply - all ok\n"
702 }
703
704 sub tagh1 ($) {
705     my ($tag) = @_;
706     my $vals = $tagh{$tag};
707     reject "missing header $tag in signed tag object" unless $vals;
708     reject "multiple headers $tag in signed tag object" unless @$vals == 1;
709     return $vals->[0];
710 }
711
712 sub checks () {
713     printdebug "checks\n";
714
715     tagh1('type') eq 'commit' or reject "tag refers to wrong kind of object";
716     tagh1('object') eq $commit or reject "tag refers to wrong commit";
717     tagh1('tag') eq $tagname or reject "tag name in tag is wrong";
718
719     my $v = $version;
720     $v =~ y/~:/_%/;
721
722     printdebug "translated version $v\n";
723     $tagname eq "debian/$v" or die;
724
725     lockrealtree();
726
727     my @policy_args = ($package,$version,$suite,$tagname,
728                        join(",",@deliberatelies));
729     $policy = policyhook(NOFFCHECK|FRESHREPO, 'push', @policy_args);
730
731     checktagnoreplay();
732     checksuite();
733
734     # check that our ref is being fast-forwarded
735     printdebug "oldcommit $oldcommit\n";
736     if (!($policy & NOFFCHECK) && $oldcommit =~ m/[^0]/) {
737         $?=0; $!=0; my $mb = `git merge-base $commit $oldcommit`;
738         chomp $mb;
739         $mb eq $oldcommit or reject "not fast forward on dgit branch";
740     }
741
742     if ($policy & FRESHREPO) {
743         # This is troublesome.  We have been asked by the policy hook
744         # to receive the push into a fresh repo.  But of course we
745         # have actually already mostly received the push into the working
746         # repo.  (This is unavoidable because the instruction to use a new
747         # repo comes ultimately from the signed tag for the dgit push,
748         # which has to have been received into some repo.)
749         #
750         # So what we do is generate a fresh working repo right now and
751         # push the head and tag into it.  The presence of this fresh
752         # working repo is detected by the parent, which responds by
753         # making a fresh master repo from the template.
754
755         $destrepo = "${workrepo}_fresh"; # workrepo lock covers
756         mkrepo_fromtemplate $destrepo;
757     }
758
759     my $willinstall = ($destrepo eq realdestrepo ? '' : $destrepo);
760     policyhook(0, 'push-confirm', @policy_args, $willinstall);
761 }
762
763 sub onwardpush () {
764     my @cmd = (qw(git send-pack), $destrepo);
765     push @cmd, qw(--force) if $policy & NOFFCHECK;
766     push @cmd, "$commit:refs/dgit/$suite",
767                "$tagval:refs/tags/$tagname";
768     debugcmd '+',@cmd;
769     $!=0;
770     my $r = system @cmd;
771     !$r or die "onward push to $destrepo failed: $r $!";
772 }
773
774 sub stunthook () {
775     printdebug "stunthook in $workrepo\n";
776     chdir $workrepo or die "chdir $workrepo: $!";
777     mkdir "dgit-tmp" or $!==EEXIST or die $!;
778     readupdates();
779     parsetag();
780     verifytag();
781     checks();
782     onwardpush();
783     printdebug "stunthook done.\n";
784 }
785
786 #----- git-upload-pack -----
787
788 sub fixmissing__git_upload_pack () {
789     $destrepo = "$dgitrepos/_empty";
790     my $lfh = locksometree($destrepo);
791     return if stat_exists $destrepo;
792     rmtree "$destrepo.new";
793     mkemptyrepo "$destrepo.new", "0644";
794     rename "$destrepo.new", $destrepo or die $!;
795     unlink "$destrepo.lock" or die $!;
796     close $lfh;
797 }
798
799 sub main__git_upload_pack () {
800     my $lfh = locksometree($destrepo);
801     printdebug "git-upload-pack in $destrepo\n";
802     chdir $destrepo or die "$destrepo: $!";
803     close $lfh;
804     runcmd qw(git upload-pack), ".";
805 }
806
807 #----- arg parsing and main program -----
808
809 sub argval () {
810     die unless @ARGV;
811     my $v = shift @ARGV;
812     die if $v =~ m/^-/;
813     return $v;
814 }
815
816 our %indistrodir = (
817     # keys are used for DGIT_DRS_XXX too
818     'repos' => \$dgitrepos,
819     'suites' => \$suitesfile,
820     'policy-hook' => \$policyhook,
821     'dgit-live' => \$dgitlive,
822     );
823
824 our @hookenvs = qw(distro suitesfile policyhook dgitlive keyrings dgitrepos);
825
826 # workrepo and destrepo handled ad-hoc
827
828 sub mode_ssh () {
829     die if @ARGV;
830
831     my $cmd = $ENV{'SSH_ORIGINAL_COMMAND'};
832     $cmd =~ m{
833         ^
834         (?: \S* / )?
835         ( [-0-9a-z]+ )
836         \s+
837         '? (?: \S* / )?
838         ($package_re) \.git
839         '?$
840     }ox 
841     or reject "command string not understood";
842     my $method = $1;
843     $package = $2;
844
845     my $funcn = $method;
846     $funcn =~ y/-/_/;
847     my $mainfunc = $main::{"main__$funcn"};
848
849     reject "unknown method" unless $mainfunc;
850
851     policy_checkpackage();
852
853     if (stat_exists realdestrepo) {
854         $destrepo = realdestrepo;
855     } else {
856         printdebug " fixmissing $funcn\n";
857         my $fixfunc = $main::{"fixmissing__$funcn"};
858         &$fixfunc;
859     }
860
861     printdebug " running main $funcn\n";
862     &$mainfunc;
863 }
864
865 sub mode_cron () {
866     die if @ARGV;
867
868     my $listfh = tempfile();
869     open STDOUT, ">&", $listfh or die $!;
870     policyhook(0,'check-list');
871     open STDOUT, ">&STDERR" or die $!;
872
873     seek $listfh, 0, 0 or die $!;
874     while (<$listfh>) {
875         chomp or die;
876         next if m/^\s*\#/;
877         next unless m/\S/;
878         die unless m/^($package_re)$/;
879         
880         $package = $1;
881         policy_checkpackage();
882     }
883     die $! if $listfh->error;
884 }    
885
886 sub parseargsdispatch () {
887     die unless @ARGV;
888
889     delete $ENV{'GIT_DIR'}; # if not run via ssh, our parent git process
890     delete $ENV{'GIT_PREFIX'}; # sets these and they mess things up
891
892     if ($ENV{'DGIT_DRS_DEBUG'}) {
893         enabledebug();
894     }
895
896     if ($ARGV[0] eq '--pre-receive-hook') {
897         if ($debuglevel) {
898             $debugprefix.="=";
899             printdebug "in stunthook ".(shellquote @ARGV)."\n";
900             foreach my $k (sort keys %ENV) {
901                 printdebug "$k=$ENV{$k}\n" if $k =~  m/^DGIT/;
902             }
903         }
904         shift @ARGV;
905         @ARGV == 1 or die;
906         $package = shift @ARGV;
907         ${ $main::{$_} } = $ENV{"DGIT_DRS_\U$_"} foreach @hookenvs;
908         defined($workrepo = $ENV{'DGIT_DRS_WORK'}) or die;
909         defined($destrepo = $ENV{'DGIT_DRS_DEST'}) or die;
910         open STDOUT, ">&STDERR" or die $!;
911         eval {
912             stunthook();
913         };
914         if ($@) {
915             recorderror "$@" or die;
916             die $@;
917         }
918         exit 0;
919     }
920
921     $distro = $ENV{'DGIT_DRS_DISTRO'}     = argval();
922     my $distrodir                         = argval();
923     $keyrings = $ENV{'DGIT_DRS_KEYRINGS'} = argval();
924
925     foreach my $dk (keys %indistrodir) {
926         ${ $indistrodir{$dk} } = "$distrodir/$dk";
927     }
928
929     while (@ARGV && $ARGV[0] =~ m/^--([-0-9a-z]+)=/ && $indistrodir{$1}) {
930         ${ $indistrodir{$1} } = $'; #';
931         shift @ARGV;
932     }
933
934     $ENV{"DGIT_DRS_\U$_"} = ${ $main::{$_} } foreach @hookenvs;
935
936     die unless @ARGV==1;
937
938     my $mode = shift @ARGV;
939     die unless $mode =~ m/^--(\w+)$/;
940     my $fn = ${*::}{"mode_$1"};
941     die unless $fn;
942     $fn->();
943 }
944
945 sub unlockall () {
946     while (my $fh = pop @lockfhs) { close $fh; }
947 }
948
949 sub cleanup () {
950     unlockall();
951     if (!chdir "$dgitrepos/_tmp") {
952         $!==ENOENT or die $!;
953         return;
954     }
955     foreach my $lf (<*.lock>) {
956         my $tree = $lf;
957         $tree =~ s/\.lock$//;
958         next unless acquirermtree($tree, 0);
959         remove $lf or warn $!;
960         unlockall();
961     }
962 }
963
964 parseargsdispatch();
965 cleanup();