i18n-diff-auditor

   1 #!/usr/bin/perl -w
   2 use strict;
   3 use Carp;
   4 use Data::Dumper;
   5 use Getopt::Long;
   6
   7 our $debug = 0;
   8 GetOptions("debug|D+" => \$debug
   9            );
  10
  11 our @debug;
  12 sub debug ($$) {
  13     my ($i,$s) = @_;
  14     push @{ $debug[$i] }, $s if $debug;
  15 }
  16
  17 my @d = <>;
  18 unshift @d, "# dummy line to make line 1 index 1 in \@d\n";
  19
  20 our $i_last_l_ok = -1;
  21 our $count_i_last_l_ok;
  22
  23 sub l_ok ($) {
  24     my ($i) = @_;
  25
  26     if ($i == $i_last_l_ok) {
  27         confess $i if $count_i_last_l_ok++ > 50;
  28     } else {
  29         $count_i_last_l_ok = 0;
  30         $i_last_l_ok = $i;
  31     }
  32
  33     return unless $i < @d;
  34     $_ = $d[$i];
  35     #print STDERR "L $i\n";
  36     1;
  37 }
  38
  39 sub l ($) {
  40     my ($i) = @_;
  41     confess $i unless l_ok $i;
  42 };
  43
  44 our $perlop_text = <<'END'; # c&p from man perlop
  45            left        terms and list operators (leftward)
  46            left        ->
  47            nonassoc    ++ --
  48            right       **
  49            right       ! ~ \ and unary + and -
  50            left        =~ !~
  51            left        * / % x
  52            left        + - .
  53            left        << >>
  54            nonassoc    named unary operators
  55            nonassoc    < > <= >= lt gt le ge
  56            nonassoc    == != <=> eq ne cmp ~~
  57            left        &
  58            left        | ^
  59            left        &&
  60            left        || //
  61            nonassoc    ..  ...
  62            right       ?:
  63            right       = += -= *= etc. goto last next redo dump
  64            left        , =>
  65            nonassoc    list operators (rightward)
  66            right       not
  67            left        and
  68            left        or xor
  69
  70            **=    +=    *=    &=    &.=    <<=    &&=
  71                   -=    /=    |=    |.=    >>=    ||=
  72                   .=    %=    ^=    ^.=           //=
  73                         x=
  74 END
  75
  76 our $perlop_re;
  77
  78 sub prep_perlop () {
  79     my @ops;
  80     foreach (split /\n/, $perlop_text) {
  81         next unless m{\S};
  82         s{\s+$}{};
  83         s{^\s+}{};
  84         s{^(?: left | right | nonassoc ) \s+}{}x;
  85         next if m{^terms and list operators};
  86         next if m{^named unary};
  87         next if m{^list operators};
  88         s{ and unary.*}{};
  89         s{ etc\. }{ };
  90         s{\?\:}{ ? : };
  91         foreach my $op (split /\s+/) {
  92             next unless length $op;
  93             next if $op =~ m{^\w+$};
  94             $op =~ s/\W/\\$&/g;
  95             push @ops, $op;
  96         }
  97     }
  98     $perlop_re = '(?: '.(join ' | ', @ops).' )';
  99     $perlop_re = qr{$perlop_re}x;
 100     #print STDERR "$perlop_re\n";
 101 }
 102
 103 prep_perlop();
 104
 105 our ($ifilehead, $ifirsthunkhead);
 106 our ($ihunkhead, $ihunkend);
 107 our ($ichunkstart, $ichunkend);
 108 our ($before, $after);
 109
 110 sub is_string ($) { $_[0]{T} =~ m/heredoc|string/; };
 111
 112 sub semiparse ($) {
 113     ($_) = @_;
 114     my @o;
 115     # entries contain
 116     #   T     type
 117     #   E     exact input text (does not contain here doc contents)
 118     #   P     something to print in messages
 119     #   V     value, only for: heredoc string
 120     #   Q     quote characcter, only for: heredoc string
 121     for (;;) {
 122         s{^\s+}{};
 123         if (s{^[\$\@\%]?[_0-9a-zA-Z]+}{}) {
 124             push @o, { T => 'ident', E => $&, P => $& };
 125         } elsif (s{^\<\<(['"]?)([A-Z_]+)\1}{}) {
 126             my ($q,$d) = ($1,$2);
 127             $q ||= '"';
 128             push @o, { T => 'heredoc', Q => $q, Delim => $d,
 129                        E => $&, P => "<<$q$d$q" };
 130             s{^
 131                 (             .* \n    )
 132                 ( (?: (?! $d) .* \n )* )
 133                           $d     \n
 134               }{ $1 }x or die "missing end of here doc $d\n";
 135             $o[$#o]{V} = $2;
 136         } elsif (s{^ (["'])( (?: [^\\'"]
 137                                | \\ [^"']
 138                                | (?! \1 ) [^"]
 139                               )*
 140                        ) \1 }{}x) {
 141             my ($q,$v) = ($1,$2);
 142             push @o, { T => 'string', E => $&, P => "$q-string",
 143                        Q => $q, V => $v};
 144         } elsif (s{^$perlop_re|^\;}{}) {
 145             push @o, { T => 'op', E => $&, P => $& };
 146         } elsif (s/[[{(]//) {
 147             push @o, { T => 'bra', E => $&, P => $& };
 148         } elsif (s/[]})]//) {
 149             push @o, { T => 'ket', E => $&, P => $& };
 150         } elsif (s/^( [\$\@\%] )( \{ )//x) {
 151             push @o, { T => 'deref', E => $1, P => $1 },
 152                      { T => 'bra',   E => $2, P => $2 };
 153         } elsif (s/^ [\$\@\%] [^[^{] //x) {
 154             push @o, { T => 'specvar', E => $&, P => $& };
 155         } elsif (!length) {
 156             last;
 157         } else {
 158             m{^.{0,10}};
 159             die "cannot tokenise \`$&'";
 160         }
 161     }
 162     for (my $i=@o-2; $i>0; --$i) {
 163         next unless $o[$i+1]{E} eq '.';
 164         my @inputs = @o[$i, $i+2];
 165         next if grep { !is_string($_) } @inputs;
 166         my $q = $inputs[0]{Q};
 167         next if grep { $_->{Q} ne $q } @inputs;
 168         my $new = { T => 'joinedstrings',
 169                     E => (join '.', map { $_->{E} } @inputs),
 170                     P => (join '.', map { $_->{P} } @inputs),
 171                     V => (join '',  map { $_->{V} } @inputs),
 172                     Q => $q,
 173                   };
 174         @o = (@o[0..$i-1], $new, @o[$i+3..$#o]);
 175         print STDERR Dumper(\@o);
 176     }
 177     debug $ichunkstart, "semiparsed: ".join ' ', map { $_->{P} } @o;
 178     return @o;
 179 }
 180
 181 our @analysed_x;
 182 our @analysed_y;
 183
 184 sub analyse_chunk_core () {
 185     die "plain deletion\n" unless defined $after;
 186     die "plain insertion\n" unless defined $before;
 187     my @xs = semiparse $before;
 188     my @ys = semiparse $after;
 189     @analysed_x = @analysed_y = ();
 190     my $next_something = sub {
 191         my ($ary,$anal,$var,$what) = @_;
 192         die "ran out of $what\n" unless @$ary;
 193         my $r = shift @$ary;
 194         push @$anal, $r->{P};
 195         $$var = $r;
 196     };
 197     my ($x,$y);
 198     my $next_x = sub { $next_something->(\@xs, \@analysed_x, \$x, 'before'); };
 199     my $next_y = sub { $next_something->(\@ys, \@analysed_y, \$y, 'after' ); };
 200     for (;;) {
 201         last unless @xs or @ys;
 202         $next_x->();
 203         $next_y->();
 204         next if $x->{E} eq $y->{E};
 205         my $string_changed;
 206         my $ye = $y->{E};
 207         if ($ye eq '__' or $ye eq 'f_') {
 208             $next_y->();
 209             die "__ on non-string $y->{P}\n"     unless is_string($y);
 210             die "__ on was non-string $y->{P}\n" unless is_string($x);
 211             if ($y->{Q} ne "'") {
 212                 die "var subst in new string\n"
 213                     if $y->{V} =~ m{(?<!\\) [\$\@]};
 214             }
 215             eval {
 216                 die "__ string changed\n"       unless $y->{V} eq $x->{V};
 217                 die "__ string quote changed\n" unless $y->{Q} eq $x->{Q};
 218             };
 219             $string_changed = $@;
 220         }
 221         if ($ye eq '__') {
 222             $_ = $y->{V};
 223             die "percent $& in __ ' string\n" if m{\%};
 224             die $string_changed if length $string_changed;
 225             next;
 226         }
 227         if ($ye eq 'f_') {
 228             my $fmt = $y->{V};
 229             die "no percent in _f string\n" unless $fmt =~ m{\%};
 230             next unless $string_changed;
 231             die "f_ old string '-quoted\n" if $x->{Q} ne '"';
 232             my $xs = $x->{V};
 233             my $exactly = sub {
 234                 my ($lit, $what) = @_;
 235                 my $xl = substr($xs, 0, length($lit));
 236                 if ($xl ne $lit) {
 237                     debug $ichunkstart, "not exactly x: $xs";
 238                     debug $ichunkstart, "not exactly y: $lit";
 239                     my $next = @ys ? $ys[0]{P} : '(end)';
 240                     die "string contents mismatch near $what before $next\n";
 241                 }
 242                 $xs = substr($xs, length($lit));
 243             };
 244             for (;;) {
 245                 if ($fmt !~ m{\%[^\%]}) {
 246                     $exactly->($fmt, '(tail)');
 247                     $fmt = '';
 248                     last;
 249                 }
 250                 $exactly->($`, '(literal)');
 251                 $fmt = $';
 252                 if ($& eq '%%') { $exactly->('%', '%%'); next; }
 253                 elsif ($& ne '%s') { die "unhandled %-subst $&\n"; }
 254                 $next_y->();
 255                 die "expected comma, got $y->{P}\n" unless $y->{E} eq ',';
 256                 if ($xs =~ m{^\@}) {
 257                     $next_y->();
 258                     die "\@... => not string" unless is_string($y);
 259                     die "\@... => $y->{P}" if $y->{Q} ne '"';
 260                     $exactly->($y->{V}, $y->{P});
 261                     next;
 262                 }
 263                 my $bras = 0;
 264                 for (;;) {
 265                     if (!$bras and !@ys) {
 266                         last;
 267                     }
 268                     $next_y->();
 269                     if (!$bras and
 270                         (grep { $y->{E} eq $_ } qw( or xor and not ; : , )
 271                          or $y->{T} eq 'ket'
 272                         )) {
 273                         # lookahead shows close of containing scope
 274                         # or lower precedence operator
 275                         unshift @ys, $y;
 276                         last;
 277                     }
 278                     $xs =~ s{^\s+}{};
 279                     #debug $ichunkstart, "TOKEN $y->{P}\n";
 280                     $exactly->($y->{E}, $y->{P});
 281                     if ($y->{T} eq 'bra' or $y->{E} eq '?') {
 282                         $bras++;
 283                     } elsif ($y->{T} eq 'ket' or $y->{E} eq ':') {
 284                         die "too many kets at $y->{E}\n" unless $bras;
 285                         $bras--;
 286                     }
 287                 }
 288             }
 289             next;
 290         }
 291         die "mismatch $x->{P} => $y->{P}\n";
 292     }
 293 }
 294
 295 sub analyse_chunk () {
 296     for (;;) {
 297         eval { analyse_chunk_core(); };
 298         return unless length $@;
 299         if ($@ =~ m{^missing end of here doc (\S+)\n}) {
 300             # fudge this
 301             $before .= "\n$1\n";
 302             $after .= "\n$1\n";
 303             next;
 304         } else {
 305             die $@;
 306         }
 307     }
 308 }
 309
 310 our @report;
 311 our $last_filehead = -1;
 312
 313 sub report_on_hunk () {
 314     return unless @report;
 315     if ($last_filehead != $ifilehead) {
 316         foreach (my $i=$ifilehead; $i<$ifirsthunkhead; $i++) {
 317             print $d[$i];
 318         }
 319         $last_filehead = $ifilehead;
 320     }
 321     my $dummy_r = { S => (scalar @d)+1, E => (scalar @d)+1 };
 322     my $r;
 323     for (my $i=$ihunkhead; ; $i++) {
 324         for (;;) {
 325             $r //= shift @report;
 326             $r //= $dummy_r;
 327             last if $i < $r->{E};
 328             confess unless $r->{Done} == 03;
 329             $r = undef;
 330         }
 331
 332         last unless $i<$ihunkend;
 333
 334         foreach my $ds (@{ $debug[$i] }) {
 335             print "# $ds\n";
 336         }
 337
 338         if ($i == $r->{S}) {
 339             print "!! $r->{M}";
 340             $r->{Done} |= 01;
 341         }
 342         if ($i >= $r->{S}) {
 343             print "!";
 344             $r->{Done} |= 02;
 345         } else {
 346             print " ";
 347         }
 348         print $d[$i];
 349     }
 350     confess unless $r = $dummy_r;
 351 }
 352
 353 for ($ifilehead = 0; l_ok $ifilehead; $ifilehead++) {
 354     m{^diff} or next;
 355     $ifirsthunkhead = $ifilehead;
 356     while (l_ok $ifirsthunkhead and
 357            m{^diff|^index|^---|^\Q+++\E}) {
 358         $ifirsthunkhead++
 359     }
 360     $ihunkhead = $ifirsthunkhead;
 361     while (l_ok $ihunkhead) {
 362         m{^\@\@} or confess "$ihunkhead $_ ?";
 363         my $i = $ihunkhead + 1;
 364         for (; ; $i++) {
 365             if (!l_ok $i or m{^ } or m{^\@\@}) {
 366                 if (defined $ichunkstart) {
 367                     $ichunkend = $i;
 368                     eval { analyse_chunk(); 1; };
 369                     if (length $@) {
 370                         debug $ichunkstart, "done x: @analysed_x";
 371                         debug $ichunkstart, "done y: @analysed_y";
 372                         push @report, { M => $@,
 373                                         S => $ichunkstart,
 374                                         E => $ichunkend };
 375                     }
 376                     $ichunkstart = $ichunkend = $before = $after = undef;
 377                 }
 378                 l_ok $i or last;
 379                 m{^\@\@} and last;
 380             } elsif (m{^[-+]}) {
 381                 my $which = $& eq '-' ? \$before : \$after;
 382                 $ichunkstart //= $i;
 383                 $$which //= '';
 384                 $$which .= $';
 385             } else {
 386                 confess "$i $_ ?";
 387             }
 388         }
 389         $ihunkend = $i;
 390         report_on_hunk();
 391         $ichunkend = $i;
 392         $ihunkhead = $i;
 393     }
 394 }