git-debrebase

   1 #!/usr/bin/perl -w
   2 # git-debrebase
   3 # Script helping make fast-forwarding histories while still rebasing
   4 # upstream deltas when working on Debian packaging
   5 #
   6 # Copyright (C)2017,2018 Ian Jackson
   7 #
   8 # This program is free software: you can redistribute it and/or modify
   9 # it under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation, either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # This program is distributed in the hope that it will be useful,
  14 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20
  21 END { $? = $Debian::Dgit::ExitStatus::desired // -1; };
  22 use Debian::Dgit::GDR;
  23 use Debian::Dgit::ExitStatus;
  24 use Debian::Dgit::I18n;
  25
  26 use strict;
  27
  28 use Debian::Dgit qw(:DEFAULT :playground);
  29 setup_sigwarn();
  30
  31 use Memoize;
  32 use Carp;
  33 use POSIX;
  34 use Locale::gettext;
  35 use Data::Dumper;
  36 use Getopt::Long qw(:config posix_default gnu_compat bundling);
  37 use Dpkg::Version;
  38 use File::FnMatch qw(:fnmatch);
  39 use File::Copy;
  40
  41 $debugcmd_when_debuglevel = 2;
  42
  43 our ($usage_message) = i_ <<'END';
  44 usages:
  45   git-debrebase [<options>] [--|-i <git rebase options...>]
  46   git-debrebase [<options>] status
  47   git-debrebase [<options>] prepush [--prose=...]
  48   git-debrebase [<options>] quick|conclude
  49   git-debrebase [<options>] new-upstream <new-version> [<details ...>]
  50   git-debrebase [<options>] convert-from-* ...
  51   ...
  52 See git-debrebase(1), git-debrebase(5), dgit-maint-debrebase(7) (in dgit).
  53 END
  54
  55 our ($opt_force, $opt_noop_ok, $opt_merges, @opt_anchors);
  56 our ($opt_defaultcmd_interactive);
  57
  58 our $us = qw(git-debrebase);
  59
  60 our $wrecknoteprefix = 'refs/debrebase/wreckage';
  61 our $merge_cache_ref = 'refs/debrebase/merge-resolutions';
  62
  63 $|=1;
  64
  65 sub badusage ($) {
  66     my ($m) = @_;
  67     print STDERR f_ "%s: bad usage: %s\n", $us, $m;
  68     finish 8;
  69 }
  70
  71 sub getoptions_main {
  72     my $m = shift;
  73     local $SIG{__WARN__}; # GetOptions calls `warn' to print messages
  74     GetOptions @_ or badusage $m;
  75 }
  76 sub getoptions {
  77     my $sc = shift;
  78     getoptions_main +(f_ "bad options follow \`git-debrebase %s'", $sc), @_;
  79 }
  80
  81 sub cfg ($;$) {
  82     my ($k, $optional) = @_;
  83     local $/ = "\0";
  84     my @cmd = qw(git config -z);
  85     push @cmd, qw(--get-all) if wantarray;
  86     push @cmd, $k;
  87     my $out = cmdoutput_errok @cmd;
  88     if (!defined $out) {
  89         fail f_ "missing required git config %s", $k unless $optional;
  90         return ();
  91     }
  92     my @l = split /\0/, $out;
  93     return wantarray ? @l : $l[0];
  94 }
  95
  96 memoize('cfg');
  97
  98 sub dd ($) {
  99     my ($v) = @_;
 100     my $dd = new Data::Dumper [ $v ];
 101     Terse $dd 1; Indent $dd 0; Useqq $dd 1;
 102     return Dump $dd;
 103 }
 104
 105 sub get_commit ($) {
 106     my ($objid) = @_;
 107     my $data = (git_cat_file $objid, 'commit');
 108     $data =~ m/(?<=\n)\n/ or confess "$objid ($data) ?";
 109     return ($`,$');
 110 }
 111
 112 sub D_UPS ()      { 0x02; } # upstream files
 113 sub D_PAT_ADD ()  { 0x04; } # debian/patches/ extra patches at end
 114 sub D_PAT_OTH ()  { 0x08; } # debian/patches other changes
 115 sub D_DEB_CLOG () { 0x10; } # debian/changelog
 116 sub D_DEB_OTH ()  { 0x20; } # debian/ (not patches/ or changelog)
 117 sub DS_DEB ()     { D_DEB_CLOG | D_DEB_OTH; } # debian/ (not patches/)
 118
 119 our $playprefix = 'debrebase';
 120 our $rd;
 121 our $workarea;
 122
 123 our @git = qw(git);
 124 our @dgit = qw(dgit);
 125
 126 sub in_workarea ($) {
 127     my ($sub) = @_;
 128     changedir $workarea;
 129     my $r = eval { $sub->(); };
 130     { local $@; changedir $maindir; }
 131     die $@ if $@;
 132 }
 133
 134 sub fresh_workarea (;$) {
 135     my ($subdir) = @_;
 136     $subdir //= 'work';
 137     $workarea = fresh_playground "$playprefix/$subdir";
 138     in_workarea sub { playtree_setup };
 139 }
 140
 141 sub run_ref_updates_now ($$) {
 142     my ($mrest, $updates) = @_;
 143     # @$updates is a list of lines for git-update-ref, without \ns
 144
 145     my @upd_cmd = (git_update_ref_cmd "debrebase: $mrest", qw(--stdin));
 146     debugcmd '>|', @upd_cmd;
 147     open U, "|-", @upd_cmd or confess "$!";
 148     foreach (@$updates) {
 149         printdebug ">= ", $_, "\n";
 150         print U $_, "\n" or confess "$!";
 151     }
 152     printdebug ">\$\n";
 153     close U or failedcmd @upd_cmd;
 154 }
 155
 156 our $snags_forced = 0;
 157 our $snags_tripped = 0;
 158 our $snags_summarised = 0;
 159 our @deferred_updates;
 160 our @deferred_update_messages;
 161
 162 sub merge_wreckage_cleaning ($) {
 163     my ($updates) = @_;
 164     git_for_each_ref("$wrecknoteprefix/*", sub {
 165         my ($objid,$objtype,$fullrefname,$reftail) = @_;
 166         push @$updates, "delete $fullrefname";
 167     });
 168 }
 169
 170 sub all_snags_summarised () {
 171     $snags_forced + $snags_tripped == $snags_summarised;
 172 }
 173 sub run_deferred_updates ($) {
 174     my ($mrest) = @_;
 175
 176     my $m = 'dangerous internal error';
 177     confess $m.' - '.__ $m unless all_snags_summarised();
 178
 179     merge_wreckage_cleaning \@deferred_updates;
 180     run_ref_updates_now $mrest, \@deferred_updates;
 181     print $_, "\n" foreach @deferred_update_messages;
 182
 183     @deferred_updates = ();
 184     @deferred_update_messages = ();
 185 }
 186
 187 sub get_tree ($;$$) {
 188     # tree object name => ([ $name, $info ], ...)
 189     # where $name is the sort key, ie has / at end for subtrees
 190     # $info is the LHS from git-ls-tree (<mode> <type> <hash>)
 191     # without $precheck, will crash if $x does not exist, so don't do that;
 192     # instead pass '' to get ().
 193     my ($x, $precheck, $recurse) = @_;
 194
 195     return () if !length $x;
 196
 197     if ($precheck) {
 198         my ($type, $dummy) = git_cat_file $x, [qw(tree missing)];
 199         return () if $type eq 'missing';
 200     }
 201
 202     $recurse = !!$recurse;
 203
 204     confess "get_tree needs object not $x ?" unless $x =~ m{^[0-9a-f]+\:};
 205
 206     our (@get_tree_memo, %get_tree_memo);
 207     my $memo = $get_tree_memo{$recurse,$x};
 208     return @$memo if $memo;
 209
 210     local $Debian::Dgit::debugcmd_when_debuglevel = 3;
 211     my @l;
 212     my @cmd = (qw(git ls-tree -z --full-tree));
 213     push @cmd, qw(-r) if $recurse;
 214     push @cmd, qw(--), $x;
 215     my $o = cmdoutput @cmd;
 216     $o =~ s/\0$//s;
 217     my $last = '';
 218     foreach my $l (split /\0/, $o) {
 219         my ($i, $n) = split /\t/, $l, 2;
 220         $n .= '/' if $i =~ m/^\d+ tree /;
 221         push @l, [ $n, $i ];
 222         confess "$x need $last < $n ?" unless $last lt $n;
 223     }
 224     $get_tree_memo{$recurse,$x} = \@l;
 225     push @get_tree_memo, $x;
 226     if (@get_tree_memo > 10) {
 227         delete $get_tree_memo{ shift @get_tree_memo };
 228     }
 229     return @l;
 230 }
 231
 232 sub trees_diff_walk ($$$;$) {
 233     # trees_diff_walk [{..opts...},] $x, $y, sub {... }
 234     # calls sub->($name, $ix, $iy) for each difference
 235     # $x and $y are as for get_tree
 236     # where $name, $ix, $iy are $name and $info from get_tree
 237     # opts are   all       call even for names same in both
 238     #            recurse   call even for names same in both
 239     my $opts = shift @_ if @_>=4;
 240     my ($x,$y,$call) = @_;
 241     my $all = $opts->{all};
 242     return if !$all and $x eq $y;
 243     my @x = get_tree $x, 0, $opts->{recurse};
 244     my @y = get_tree $y, 0, $opts->{recurse};
 245     printdebug "trees_diff_walk(..$x,$y..) ".Dumper(\@x,\@y)
 246         if $debuglevel >= 3;
 247     while (@x || @y) {
 248         my $cmp = !@x       <=> !@y          # eg @y empty? $cmp=-1, use x
 249              ||    $x[0][0] cmp  $y[0][0];   # eg, x lt y ? $cmp=-1, use x
 250         my ($n, $ix, $iy);                   # all same? $cmp=0, use both
 251         $ix=$iy='';
 252         printdebug "trees_diff_walk $cmp : @{ $x[0]//[] } | @{ $y[0]//[] }\n"
 253             if $debuglevel >= 3;
 254         ($n, $ix) = @{ shift @x } if $cmp <= 0;
 255         ($n, $iy) = @{ shift @y } if $cmp >= 0;
 256         next if !$all and $ix eq $iy;
 257         printdebug sprintf
 258             "trees_diff_walk(%d,'%s','%s') call('%s','%s','%s')\n",
 259             !!$all,$x,$y, $n,$ix,$iy
 260             if $debuglevel >= 2;
 261         $call->($n, $ix, $iy);
 262     }
 263 }
 264
 265 sub get_differs ($$) {
 266     my ($x,$y) = @_;
 267     # This does a similar job to quiltify_trees_differ, in dgit, a bit.
 268     # But we don't care about modes, or dpkg-source-unrepresentable
 269     # changes, and we don't need the plethora of different modes.
 270     # Conversely we need to distinguish different kinds of changes to
 271     # debian/ and debian/patches/.
 272     # Also, here we have, and want to use, trees_diff_walk, because
 273     # we may be calling this an awful lot and we want it to be fast.
 274
 275     my $differs = 0;
 276     my @debian_info;
 277
 278     no warnings qw(exiting);
 279
 280     my $plain = sub { $_[0] =~ m{^(100|0*)644 blob }s; };
 281
 282     trees_diff_walk "$x:", "$y:", sub {
 283         my ($n,$ix,$iy) = @_;
 284
 285         # analyse difference at the toplevel
 286
 287         if ($n ne 'debian/') {
 288             $differs |= D_UPS;
 289             next;
 290         }
 291         if ($n eq 'debian') {
 292             # one side has a non-tree for ./debian !
 293             $differs |= D_DEB_OTH;
 294             next;
 295         }
 296
 297         my $xd = $ix && "$x:debian";
 298         my $yd = $iy && "$y:debian";
 299         trees_diff_walk $xd, $yd, sub {
 300             my ($n,$ix,$iy) = @_;
 301
 302             # analyse difference in debian/
 303
 304             if ($n eq 'changelog' && (!$ix || $plain->($ix))
 305                                   &&          $plain->($iy) ) {
 306                 $differs |= D_DEB_CLOG;
 307                 next;
 308             }
 309             if ($n ne 'patches/') {
 310                 $differs |= D_DEB_OTH;
 311                 next;
 312             }
 313
 314             my $xp = $ix && "$xd/patches";
 315             my $yp = $iy && "$yd/patches";
 316             trees_diff_walk { recurse=>1 }, $xp, $yp, sub {
 317                 my ($n,$ix,$iy) = @_;
 318
 319                 # analyse difference in debian/patches
 320
 321                 my $ok;
 322                 if ($n =~ m{/$}s) {
 323                     # we are recursing; directories may appear and disappear
 324                     $ok = 1;
 325                 } elsif ($n !~ m/\.series$/s && !$ix && $plain->($iy)) {
 326                     $ok = 1;
 327                 } elsif ($n eq 'series' && $plain->($ix) && $plain->($iy)) {
 328                     my $x_s = (git_cat_file "$xp/series", 'blob');
 329                     my $y_s = (git_cat_file "$yp/series", 'blob');
 330                     chomp $x_s;  $x_s .= "\n";
 331                     $ok = $x_s eq substr($y_s, 0, length $x_s);
 332                 } else {
 333                     # nope
 334                 }
 335                 $differs |= $ok ? D_PAT_ADD : D_PAT_OTH;
 336             };
 337         };
 338     };
 339
 340     printdebug sprintf "get_differs %s %s = %#x\n", $x, $y, $differs;
 341
 342     return $differs;
 343 }
 344
 345 sub commit_pr_info ($) {
 346     my ($r) = @_;
 347     return Data::Dumper->dump([$r], [qw(commit)]);
 348 }
 349
 350 sub calculate_committer_authline () {
 351     my $c = cmdoutput @git, qw(commit-tree --no-gpg-sign -m),
 352         'DUMMY COMMIT (git-debrebase)', "HEAD:";
 353     my ($h,$m) = get_commit $c;
 354     $h =~ m/^committer .*$/m or confess "($h) ?";
 355     return $&;
 356 }
 357
 358 sub rm_subdir_cached ($) {
 359     my ($subdir) = @_;
 360     runcmd @git, qw(rm --quiet -rf --cached --ignore-unmatch), $subdir;
 361 }
 362
 363 sub read_tree_subdir ($$) {
 364     my ($subdir, $new_tree_object) = @_;
 365     rm_subdir_cached $subdir;
 366     runcmd @git, qw(read-tree), "--prefix=$subdir/", $new_tree_object;
 367 }
 368
 369 sub read_tree_debian ($) {
 370     my ($treeish) = @_;
 371     read_tree_subdir 'debian', "$treeish:debian";
 372     rm_subdir_cached 'debian/patches';
 373 }
 374
 375 sub read_tree_upstream ($;$$) {
 376     my ($treeish, $keep_patches, $tree_with_debian) = @_;
 377     # if $tree_with_debian is supplied, will use that for debian/
 378     # otherwise will save and restore it.
 379     my $debian =
 380         $tree_with_debian ? "$tree_with_debian:debian"
 381         : cmdoutput @git, qw(write-tree --prefix=debian/);
 382     runcmd @git, qw(read-tree), $treeish;
 383     read_tree_subdir 'debian', $debian;
 384     rm_subdir_cached 'debian/patches' unless $keep_patches;
 385 };
 386
 387 sub make_commit ($$) {
 388     my ($parents, $message_paras) = @_;
 389     my $tree = cmdoutput @git, qw(write-tree);
 390     my @cmd = (@git, qw(commit-tree), $tree);
 391     push @cmd, qw(-p), $_ foreach @$parents;
 392     push @cmd, qw(-m), $_ foreach @$message_paras;
 393     return cmdoutput @cmd;
 394 }
 395
 396 our @snag_force_opts;
 397 sub snag ($$;@) {
 398     my ($tag,$msg) = @_; # ignores extra args, for benefit of keycommits
 399     if (grep { $_ eq $tag } @snag_force_opts) {
 400         $snags_forced++;
 401         print STDERR f_ "%s: snag ignored (-f%s): %s\n", $us, $tag, $msg;
 402     } else {
 403         $snags_tripped++;
 404         print STDERR f_ "%s: snag detected (-f%s): %s\n", $us, $tag, $msg;
 405     }
 406 }
 407
 408 # Important: all mainline code must call snags_maybe_bail after
 409 # any point where snag might be called, but before making changes
 410 # (eg before any call to run_deferred_updates).  snags_maybe_bail
 411 # may be called more than once if necessary (but this is not ideal
 412 # because then the messages about number of snags may be confusing).
 413 sub snags_maybe_bail () {
 414     return if all_snags_summarised();
 415     if ($snags_forced) {
 416         print STDERR f_
 417             "%s: snags: %d overriden by individual -f options\n",
 418             $us, $snags_forced;
 419     }
 420     if ($snags_tripped) {
 421         if ($opt_force) {
 422             print STDERR f_
 423                 "%s: snags: %d overriden by global --force\n",
 424                 $us, $snags_tripped;
 425         } else {
 426             fail f_
 427   "%s: snags: %d blocker(s) (you could -f<tag>, or --force)",
 428                 $us, $snags_tripped;
 429         }
 430     }
 431     $snags_summarised = $snags_forced + $snags_tripped;
 432 }
 433 sub snags_maybe_bail_early () {
 434     # useful to bail out early without doing a lot of work;
 435     # not a substitute for snags_maybe_bail.
 436     snags_maybe_bail() if $snags_tripped && !$opt_force;
 437 }
 438 sub any_snags () {
 439     return $snags_forced || $snags_tripped;
 440 }
 441
 442 sub ffq_prev_branchinfo () {
 443     my $current = git_get_symref();
 444     return gdr_ffq_prev_branchinfo($current);
 445 }
 446
 447 sub record_gdrlast ($$;$) {
 448     my ($gdrlast, $newvalue, $oldvalue) = @_;
 449     $oldvalue ||= $git_null_obj;
 450     push @deferred_updates, "update $gdrlast $newvalue $oldvalue";
 451 }
 452
 453 sub fail_unprocessable ($) {
 454     my ($msg) = @_;
 455     changedir $maindir;
 456     my ($ffqs, $ffqm, $symref, $ffq_prev, $gdrlast) = ffq_prev_branchinfo();
 457
 458     my $mangled = __ <<END;
 459 Branch/history seems mangled - no longer in gdr format.
 460 See ILLEGAL OPERATIONS in git-debrebase(5).
 461 END
 462     chomp $mangled;
 463
 464     if (defined $ffqm) {
 465         fail f_ <<END, $msg, $ffqm;
 466 %s
 467 Is this meant to be a gdr branch?  %s
 468 END
 469     } elsif (git_get_ref $ffq_prev) {
 470         fail f_ <<END, $msg, $mangled;
 471 %s
 472 %s
 473 Consider git-debrebase scrap, to throw away your recent work.
 474 END
 475     } elsif (!git_get_ref $gdrlast) {
 476         fail f_ <<END, $msg;
 477 %s
 478 Branch does not seem to be meant to be a git-debrebase branch?
 479 Wrong branch, or maybe you needed git-debrebase convert-from-*.
 480 END
 481     } elsif (is_fast_fwd $gdrlast, git_rev_parse 'HEAD') {
 482         fail <<END;
 483 $msg
 484 $mangled
 485 END
 486     } else {
 487         fail f_ <<END, $msg;
 488 %s
 489 Branch/history mangled, and diverged since last git-debrebase.
 490 Maybe you reset to, or rebased from, somewhere inappropriate.
 491 END
 492     }
 493 };
 494
 495 sub gbp_pq_export ($$$) {
 496     my ($bname, $base, $tip) = @_;
 497     # must be run in a workarea.  $bname and patch-queue/$bname
 498     # ought not to exist.  Leaves you on patch-queue/$bname with
 499     # the patches staged but not committed.
 500     # returns 1 if there were any patches
 501     printdebug "gbp_pq_export $bname $base $tip\n";
 502     runcmd @git, qw(checkout -q -b), $bname, $base;
 503     runcmd @git, qw(checkout -q -b), "patch-queue/$bname", $tip;
 504     my @gbp_cmd = (qw(gbp pq export));
 505     my $r = system shell_cmd 'exec >../gbp-pq-err 2>&1', @gbp_cmd;
 506     if ($r) {
 507         { local ($!,$?); copy('../gbp-pq-err', \*STDERR); }
 508         failedcmd @gbp_cmd;
 509     }
 510     return 0 unless stat_exists 'debian/patches';
 511     runcmd @git, qw(add -f debian/patches);
 512     return 1;
 513 }
 514
 515
 516 # MERGE-TODO allow merge resolution separately from laundering, before git merge
 517
 518 # later/rework?
 519 #  use git-format-patch?
 520 #  our own patch identification algorithm?
 521 #  this is an alternative strategy
 522
 523 sub merge_failed ($$;@) {
 524     my ($wrecknotes, $emsg, @xmsgs) = @_;
 525     my @m;
 526     push @m, "Merge resolution failed: $emsg";
 527     push @m, @xmsgs;
 528
 529     changedir $maindir;
 530
 531     my @updates;
 532     merge_wreckage_cleaning \@updates;
 533     run_ref_updates_now "merge failed", \@updates;
 534
 535     @updates = ();
 536     keys %$wrecknotes;
 537     while (my ($k,$v) = each %$wrecknotes) {
 538         push @updates, "create $wrecknoteprefix/$k $v";
 539     }
 540     run_ref_updates_now "merge failed", \@updates;
 541     push @m, "Wreckage left in $wrecknoteprefix/*.";
 542
 543     push @m, "See git-debrebase(1) section FAILED MERGES for suggestions.";
 544
 545     # use finish rather than fail, in case we are within an eval
 546     # (that can happen inside walk!)
 547     print STDERR "\n";
 548     print STDERR "$us: $_\n" foreach @m;
 549     finish 15;
 550 }
 551
 552 sub mwrecknote ($$$) {
 553     my ($wrecknotes, $reftail, $commitish) = @_;
 554     confess unless defined $commitish;
 555     printdebug "mwrecknote $reftail $commitish\n";
 556     $wrecknotes->{$reftail} = $commitish;
 557 }
 558
 559 sub merge_attempt_cmd {
 560     my $wrecknotes = shift @_;
 561     debugcmd '+', @_;
 562     $!=0; $?=-1;
 563     if (system @_) {
 564         merge_failed $wrecknotes,
 565             failedcmd_waitstatus(),
 566             "failed command: @_";
 567     }
 568 }
 569
 570 sub merge_series_patchqueue_convert ($$$);
 571
 572 sub merge_series ($$$;@) {
 573     my ($newbase, $wrecknotes, $base_q, @input_qs) = @_;
 574     # $base_q{SeriesBase}  $input_qs[]{SeriesBase}
 575     # $base_q{SeriesTip}   $input_qs[]{SeriesTip}
 576     # ^ specifies several patch series (currently we only support exactly 2)
 577     # return value is a commit which is the result of
 578     # merging the two versions of the same topic branch
 579     #   $input_q[0] and $input_q[1]
 580     # with respect to the old version
 581     #   $base_q
 582     # all onto $newbase.
 583
 584     # Creates, in *_q, a key MR for its private use
 585
 586     printdebug "merge_series newbase=$newbase\n";
 587
 588     $input_qs[$_]{MR}{S} = $_ foreach (0..$#input_qs);
 589     $base_q->{MR}{S} = 'base';
 590
 591     my %prereq;
 592     # $prereq{<patch filename>}{<possible prereq}{<S>} = 1 or absent
 593     # $prereq{<patch filename>}{<possible prereq}  exists or not (later)
 594     # $prereq{<patch filename>}               exists or not (even later)
 595
 596     my $merged_pq;
 597
 598     my $mwrecknote = sub { &mwrecknote($wrecknotes, @_); };
 599
 600     my $attempt_cmd = sub { &merge_attempt_cmd($wrecknotes, @_); };
 601
 602     local $workarea;
 603     fresh_workarea "merge";
 604     my $seriesfile = "debian/patches/series";
 605     in_workarea sub {
 606         playtree_setup();
 607         foreach my $q ($base_q, reverse @input_qs) {
 608             my $s = $q->{MR}{S};
 609             my $any = gbp_pq_export "p-$s", $q->{SeriesBase}, $q->{SeriesTip};
 610             my @earlier;
 611             if ($any) {
 612                 open S, $seriesfile or confess "$seriesfile $!";
 613                 while (my $patch = <S>) {
 614                     chomp $patch or confess "$!";
 615                     $prereq{$patch} //= {};
 616                     foreach my $earlier (@earlier) {
 617                         $prereq{$patch}{$earlier}{$s}++ and confess;
 618                     }
 619                     push @earlier, $patch;
 620                     stat "debian/patches/$patch" or confess "$patch ?";
 621                 }
 622                 S->error and confess "$seriesfile $!";
 623                 close S;
 624             }
 625             read_tree_upstream $newbase, 1;
 626             my $pec = make_commit [ grep { defined } $base_q->{MR}{PEC} ], [
 627                 "Convert $s to patch queue for merging",
 628                 "[git-debrebase merge-innards patch-queue import:".
 629                 " $q->{SeriesTip}]"
 630             ];
 631             printdebug "merge_series  pec $pec ";
 632             runcmd @git, qw(rm -q --ignore-unmatch --cached), $seriesfile;
 633             $pec = make_commit [ $pec ], [
 634                 "Drop series file from $s to avoid merge trouble",
 635                 "[git-debrebase merge-innards patch-queue prep:".
 636                 " $q->{SeriesTip}]"
 637             ];
 638
 639             read_tree_debian $newbase;
 640             if (@earlier) {
 641                 read_tree_subdir 'debian/patches', "$pec:debian/patches";
 642             } else {
 643                 rm_subdir_cached 'debian/patches';
 644             }
 645             $pec = make_commit [ $pec ], [
 646  "Update debian/ (excluding patches) to final to avoid re-merging",
 647  "debian/ was already merged and we need to just take that.",
 648                 "[git-debrebase merge-innards patch-queue packaging:".
 649                 " $q->{SeriesTip}]"
 650             ];
 651
 652             printdebug "pec' $pec\n";
 653             runcmd @git, qw(reset -q --hard), $pec;
 654             $q->{MR}{PEC} = $pec;
 655             $mwrecknote->("$q->{LeftRight}-patchqueue", $pec);
 656         }
 657         # now, because of reverse, we are on $input_q->{MR}{OQC}
 658         runcmd @git, qw(checkout -q -b merge);
 659         printdebug "merge_series merging...\n";
 660         my @mergecmd = (@git, qw(merge --quiet --no-edit), "p-1");
 661
 662         $attempt_cmd->(@mergecmd);
 663
 664         printdebug "merge_series merge ok, series...\n";
 665         # We need to construct a new series file
 666         # Firstly, resolve prereq
 667         foreach my $f (sort keys %prereq) {
 668             printdebug "merge_series  patch\t$f\t";
 669             if (!stat_exists "debian/patches/$f") {
 670                 print DEBUG " drop\n" if $debuglevel;
 671                 # git merge deleted it; that's how we tell it's not wanted
 672                 delete $prereq{$f};
 673                 next;
 674             }
 675             print DEBUG " keep\n" if $debuglevel;
 676             foreach my $g (sort keys %{ $prereq{$f} }) {
 677                 my $gfp = $prereq{$f}{$g};
 678                 printdebug "merge_series  prereq\t$f\t-> $g\t";
 679                 if (!!$gfp->{0} == !!$gfp->{1}
 680                     ? $gfp->{0}
 681                     : !$gfp->{base}) {
 682                     print DEBUG "\tkeep\n" if $debuglevel;
 683                 } else {
 684                     print DEBUG "\tdrop\n" if $debuglevel;
 685                     delete $prereq{$f}{$g};
 686                 }
 687             }
 688         }
 689
 690         my $unsat = sub {
 691             my ($f) = @_;
 692             return scalar keys %{ $prereq{$f} };
 693         };
 694
 695         my $nodate = time + 1;
 696         my %authordate;
 697         # $authordate{<patch filename>};
 698         my $authordate = sub {
 699             my ($f) = @_;
 700             $authordate{$f} //= do {
 701                 open PF, "<", "debian/patches/$f" or confess "$f $!";
 702                 while (<PF>) {
 703                     return $nodate if m/^$/;
 704                     last if s{^Date: }{};
 705                 }
 706                 chomp;
 707                 return cmdoutput qw(date +%s -d), $_;
 708             };
 709         };
 710
 711         open NS, '>', $seriesfile or confess "$!";
 712
 713         while (keys %prereq) {
 714             my $best;
 715             foreach my $try (sort keys %prereq) {
 716                 if ($best) {
 717                     next if (
 718                              $unsat->($try) <=> $unsat->($best) or
 719                              $authordate->($try) <=> $authordate->($best) or
 720                              $try cmp $best
 721                             ) >= 0;
 722                 }
 723                 $best = $try;
 724             }
 725             printdebug "merge_series series next $best\n";
 726             print NS "$best\n" or confess "$!";
 727             delete $prereq{$best};
 728             foreach my $gp (values %prereq) {
 729                 delete $gp->{$best};
 730             }
 731         }
 732
 733         runcmd @git, qw(add), $seriesfile;
 734         runcmd @git, qw(commit --quiet -m), 'Merged patch queue form';
 735         $merged_pq = git_rev_parse 'HEAD';
 736         $mwrecknote->('merged-patchqueue', $merged_pq);
 737     };
 738     return merge_series_patchqueue_convert
 739             $wrecknotes, $newbase, $merged_pq;
 740 }
 741
 742 sub merge_series_patchqueue_convert ($$$) {
 743     my ($wrecknotes, $newbase, $merged_pq) = @_;
 744
 745     my $result;
 746     in_workarea sub {
 747         playtree_setup();
 748         printdebug "merge_series series gbp pq import\n";
 749         runcmd @git, qw(checkout -q -b mergec), $merged_pq;
 750
 751         merge_attempt_cmd($wrecknotes, qw(gbp pq import));
 752         # MERGE-TODO consider git-format-patch etc. instead,
 753         # since gbp pq doesn't always round-trip :-/
 754
 755         # OK now we are on patch-queue/merge, and we need to rebase
 756         # onto the intended parent and drop the patches from each one
 757
 758         printdebug "merge_series series ok, building...\n";
 759         my $build = $newbase;
 760         my @lcmd = (@git, qw(rev-list --reverse mergec..patch-queue/mergec));
 761         foreach my $c (grep /./, split /\n/, cmdoutput @lcmd) {
 762             my $commit = git_cat_file $c, 'commit';
 763             printdebug "merge_series series ok, building $c\n";
 764             read_tree_upstream $c, 0, $newbase;
 765             my $tree = cmdoutput @git, qw(write-tree);
 766             $commit =~ s{^parent (\S+)$}{parent $build}m or confess;
 767             $commit =~ s{^tree (\S+)$}{tree $tree}m      or confess;
 768             open C, ">", "../mcommit" or confess "$!";
 769             print C $commit or confess "$!";
 770             close C or confess "$!";
 771             $build = cmdoutput @git, qw(hash-object -w -t commit ../mcommit);
 772         }
 773         $result = $build;
 774         mwrecknote($wrecknotes, 'merged-result', $result);
 775
 776         runcmd @git, qw(update-ref refs/heads/result), $result;
 777
 778         runcmd @git, qw(checkout -q -b debug);
 779         runcmd @git, qw(commit --allow-empty -q -m M-INDEX);
 780         runcmd @git, qw(add .);
 781         runcmd @git, qw(commit --allow-empty -q -m M-WORKTREE);
 782         my $mdebug = git_rev_parse 'HEAD';
 783         printdebug sprintf "merge_series done debug=%s\n", $mdebug;
 784         mwrecknote($wrecknotes, 'merged-debug', $mdebug);
 785     };
 786     printdebug "merge_series returns $result\n";
 787     return $result;
 788 }
 789
 790 # classify returns an info hash like this
 791 #   CommitId => $objid
 792 #   Hdr => # commit headers, including 1 final newline
 793 #   Msg => # commit message (so one newline is dropped)
 794 #   Tree => $treeobjid
 795 #   Type => (see below)
 796 #   Parents = [ {
 797 #       Ix => $index # ie 0, 1, 2, ...
 798 #       CommitId
 799 #       Differs => return value from get_differs
 800 #       IsOrigin
 801 #       IsDggitImport => 'orig' 'tarball' 'unpatched' 'package' (as from dgit)
 802 #     } ...]
 803 #   NewMsg => # commit message, but with any [dgit import ...] edited
 804 #             # to say "[was: ...]"
 805 #
 806 # Types:
 807 #   Packaging
 808 #   Changelog
 809 #   Upstream
 810 #   AddPatches
 811 #   Mixed
 812 #
 813 #   Pseudomerge
 814 #     has additional entres in classification result
 815 #       Overwritten = [ subset of Parents ]
 816 #       Contributor = $the_remaining_Parent
 817 #
 818 #   DgitImportUnpatched
 819 #     has additional entry in classification result
 820 #       OrigParents = [ subset of Parents ]
 821 #
 822 #   Anchor
 823 #     has additional entry in classification result
 824 #       OrigParents = [ subset of Parents ]  # singleton list
 825 #
 826 #   TreatAsAnchor
 827 #
 828 #   BreakwaterStart
 829 #
 830 #   Unknown
 831 #     has additional entry in classification result
 832 #       Why => "prose"
 833
 834 sub parsecommit ($;$) {
 835     my ($objid, $p_ref) = @_;
 836     # => hash with                   CommitId Hdr Msg Tree Parents
 837     #    Parents entries have only   Ix CommitId
 838     #    $p_ref, if provided, must be [] and is used as a base for Parents
 839
 840     $p_ref //= [];
 841     confess if @$p_ref;
 842
 843     my ($h,$m) = get_commit $objid;
 844
 845     my ($t) = $h =~ m/^tree (\w+)$/m or confess $objid;
 846     my (@ph) = $h =~ m/^parent (\w+)$/mg;
 847
 848     my $r = {
 849         CommitId => $objid,
 850         Hdr => $h,
 851         Msg => $m,
 852         Tree => $t,
 853         Parents => $p_ref,
 854     };
 855
 856     foreach my $ph (@ph) {
 857         push @$p_ref, {
 858             Ix => scalar @$p_ref,
 859             CommitId => $ph,
 860         };
 861     }
 862
 863     return $r;
 864 }
 865
 866 sub classify ($) {
 867     my ($objid) = @_;
 868
 869     my @p;
 870     my $r = parsecommit($objid, \@p);
 871     my $t = $r->{Tree};
 872
 873     foreach my $p (@p) {
 874         $p->{Differs} = (get_differs $p->{CommitId}, $t),
 875     }
 876
 877     printdebug "classify $objid \$t=$t \@p",
 878         (map { sprintf " %s/%#x", $_->{CommitId}, $_->{Differs} } @p),
 879         "\n";
 880
 881     my $classify = sub {
 882         my ($type, @rest) = @_;
 883         $r = { %$r, Type => $type, @rest };
 884         if ($debuglevel) {
 885             printdebug " = $type ".(dd $r)."\n";
 886         }
 887         return $r;
 888     };
 889     my $unknown = sub {
 890         my ($why) = @_;
 891         $r = { %$r, Type => qw(Unknown), Why => $why };
 892         printdebug " ** Unknown\n";
 893         return $r;
 894     };
 895
 896     if (grep { $_ eq $objid } @opt_anchors) {
 897         return $classify->('TreatAsAnchor');
 898     }
 899
 900     my @identical = grep { !$_->{Differs} } @p;
 901     my ($stype, $series) = git_cat_file "$t:debian/patches/series";
 902     my $haspatches = $stype ne 'missing' && $series =~ m/^\s*[^#\n\t ]/m;
 903
 904     if ($r->{Msg} =~ m{^\[git-debrebase anchor.*\]$}m) {
 905         # multi-orig upstreams are represented with an anchor merge
 906         # from a single upstream commit which combines the orig tarballs
 907
 908         # Every anchor tagged this way must be a merge.
 909         # We are relying on the
 910         #     [git-debrebase anchor: ...]
 911         # commit message annotation in "declare" anchor merges (which
 912         # do not have any upstream changes), to distinguish those
 913         # anchor merges from ordinary pseudomerges (which we might
 914         # just try to strip).
 915         #
 916         # However, the user is going to be doing git-rebase a lot.  We
 917         # really don't want them to rewrite an anchor commit.
 918         # git-rebase trips up on merges, so that is a useful safety
 919         # catch.
 920         #
 921         # BreakwaterStart commits are also anchors in the terminology
 922         # of git-debrebase(5), but they are untagged (and always
 923         # manually generated).
 924         #
 925         # We cannot not tolerate any tagged linear commit (ie,
 926         # BreakwaterStart commits tagged `[anchor:') because such a
 927         # thing could result from an erroneous linearising raw git
 928         # rebase of a merge anchor.  That would represent a corruption
 929         # of the branch. and we want to detect and reject the results
 930         # of such corruption before it makes it out anywhere.  If we
 931         # reject it here then we avoid making the pseudomerge which
 932         # would be needed to push it.
 933
 934         my $badanchor = sub {
 935             $unknown->(f_ "git-debrebase \`anchor' but %s", "@_");
 936         };
 937         @p == 2 or return $badanchor->(__ "has other than two parents");
 938         $haspatches and return $badanchor->(__ "contains debian/patches");
 939
 940         # How to decide about l/r ordering of anchors ?  git
 941         # --topo-order prefers to expand 2nd parent first.  There's
 942         # already an easy rune to look for debian/ history anyway (git log
 943         # debian/) so debian breakwater branch should be 1st parent; that
 944         # way also there's also an easy rune to look for the upstream
 945         # patches (--topo-order).
 946
 947         # Also this makes --first-parent be slightly more likely to
 948         # be useful - it makes it provide a linearised breakwater history.
 949
 950         # Of course one can say somthing like
 951         #  gitk -- ':/' ':!/debian'
 952         # to get _just_ the commits touching upstream files, and by
 953         # the TREESAME logic in git-rev-list this will leave the
 954         # breakwater into upstream at the first anchor.  But that
 955         # doesn't report debian/ changes at all.
 956
 957         # Other observations about gitk: by default, gitk seems to
 958         # produce output in a different order to git-rev-list.  I
 959         # can't seem to find this documented anywhere.  gitk
 960         # --date-order DTRT.  But, gitk always seems to put the
 961         # parents from left to right, in order, so it's easy to see
 962         # which way round a pseudomerge is.
 963
 964         $p[0]{IsOrigin} and $badanchor->(__ "is an origin commit");
 965         $p[1]{Differs} & ~DS_DEB and
 966             $badanchor->(__ "upstream files differ from left parent");
 967         $p[0]{Differs} & ~D_UPS and
 968             $badanchor->(__ "debian/ differs from right parent");
 969
 970         return $classify->(qw(Anchor),
 971                            OrigParents => [ $p[1] ]);
 972     }
 973
 974     if (@p == 1) {
 975         my $d = $r->{Parents}[0]{Differs};
 976         if ($d == D_PAT_ADD) {
 977             return $classify->(qw(AddPatches));
 978         } elsif ($d & (D_PAT_ADD|D_PAT_OTH)) {
 979             return $unknown->(__ "edits debian/patches");
 980         } elsif ($d & DS_DEB and !($d & ~DS_DEB)) {
 981             my ($ty,$dummy) = git_cat_file "$p[0]{CommitId}:debian";
 982             if ($ty eq 'tree') {
 983                 if ($d == D_DEB_CLOG) {
 984                     return $classify->(qw(Changelog));
 985                 } else {
 986                     return $classify->(qw(Packaging));
 987                 }
 988             } elsif ($ty eq 'missing') {
 989                 return $classify->(qw(BreakwaterStart));
 990             } else {
 991                 return $unknown->(__ "parent's debian is not a directory");
 992             }
 993         } elsif ($d == D_UPS) {
 994             return $classify->(qw(Upstream));
 995         } elsif ($d & DS_DEB and $d & D_UPS and !($d & ~(DS_DEB|D_UPS))) {
 996             return $classify->(qw(Mixed));
 997         } elsif ($d == 0) {
 998             return $unknown->(__ "no changes");
 999         } else {
1000             confess "internal error $objid ?";
1001         }
1002     }
1003     if (!@p) {
1004         return $unknown->(__ "origin commit");
1005     }
1006
1007     if (@p == 2 && @identical == 1) {
1008         my @overwritten = grep { $_->{Differs} } @p;
1009         confess "internal error $objid ?" unless @overwritten==1;
1010         return $classify->(qw(Pseudomerge),
1011                            Overwritten => [ $overwritten[0] ],
1012                            Contributor => $identical[0]);
1013     }
1014     if (@p == 2 && @identical == 2) {
1015         my $get_t = sub {
1016             my ($ph,$pm) = get_commit $_[0]{CommitId};
1017             $ph =~ m/^committer .* (\d+) [-+]\d+$/m
1018                 or confess "$_->{CommitId} ?";
1019             $1;
1020         };
1021         my @bytime = @p;
1022         my $order = $get_t->($bytime[0]) <=> $get_t->($bytime[1]);
1023         if ($order > 0) { # newer first
1024         } elsif ($order < 0) {
1025             @bytime = reverse @bytime;
1026         } else {
1027             # same age, default to order made by -s ours
1028             # that is, commit was made by someone who preferred L
1029         }
1030         return $classify->(qw(Pseudomerge),
1031                            SubType => qw(Ambiguous),
1032                            Contributor => $bytime[0],
1033                            Overwritten => [ $bytime[1] ]);
1034     }
1035     foreach my $p (@p) {
1036         my ($p_h, $p_m) = get_commit $p->{CommitId};
1037         $p->{IsOrigin} = $p_h !~ m/^parent \w+$/m;
1038         ($p->{IsDgitImport},) = $p_m =~ m/^\[dgit import ([0-9a-z]+) .*\]$/m;
1039     }
1040     my @orig_ps = grep { ($_->{IsDgitImport}//'X') eq 'orig' } @p;
1041     my $m2 = $r->{Msg};
1042     if (!(grep { !$_->{IsOrigin} } @p) and
1043         (@orig_ps >= @p - 1) and
1044         $m2 =~ s{^\[(dgit import unpatched .*)\]$}{[was: $1]}m) {
1045         $r->{NewMsg} = $m2;
1046         return $classify->(qw(DgitImportUnpatched),
1047                            OrigParents => \@orig_ps);
1048     }
1049
1050     if (@p == 2 and
1051         $r->{Msg} =~ m{^\[git-debrebase merged-breakwater.*\]$}m) {
1052         return $classify->("MergedBreakwaters");
1053     }
1054     if ($r->{Msg} =~ m{^\[(git-debrebase|dgit)[: ].*\]$}m) {
1055         return $unknown->(f_ "unknown kind of merge from %s", $1);
1056     }
1057     if (@p > 2) {
1058         return $unknown->(__ "octopus merge");
1059     }
1060
1061     if (!$opt_merges) {
1062         return $unknown->(__ "general two-parent merge");
1063     }
1064
1065     return $classify->("VanillaMerge");
1066 }
1067
1068 sub keycommits ($;$$$$$);
1069
1070 sub mergedbreakwaters_anchor ($) {
1071     my ($cl) = @_;
1072     my $best_anchor;
1073     foreach my $p (@{ $cl->{Parents} }) {
1074         my ($panchor, $pbw) = keycommits $p->{CommitId},
1075             undef,undef,undef,undef, 1;
1076         $best_anchor = $panchor
1077             if !defined $best_anchor
1078             or is_fast_fwd $best_anchor, $panchor;
1079         fail f_ "inconsistent anchors in merged-breakwaters %s",
1080             $p->{CommitId}
1081             unless is_fast_fwd $panchor, $best_anchor;
1082     }
1083     return $best_anchor;
1084 }
1085
1086 sub keycommits ($;$$$$$) {
1087     my ($head, $furniture, $unclean, $trouble, $fatal, $claimed_bw) = @_;
1088     # => ($anchor, $breakwater)
1089
1090     # $furniture->("unclean-$tagsfx", $msg, $cl)
1091     # $unclean->("unclean-$tagsfx", $msg, $cl)
1092     #   is callled for each situation or commit that
1093     #   wouldn't be found in a laundered branch
1094     # $furniture is for furniture commits such as might be found on an
1095     #   interchange branch (pseudomerge, d/patches, changelog)
1096     # $trouble is for things whnich prevent the return of
1097     #   anchor and breakwater information; if that is ignored,
1098     #   then keycommits returns (undef, undef) instead.
1099     # $fatal is for unprocessable commits, and should normally cause
1100     #    a failure.  If ignored, agaion, (undef, undef) is returned.
1101     #
1102     # If $claimed_bw, this is supposed to be a breakwater commit.
1103     #
1104     # If a callback is undef, fail is called instead.
1105     # If a callback is defined but false, the situation is ignored.
1106     # Callbacks may say:
1107     #   no warnings qw(exiting); last;
1108     # if the answer is no longer wanted.
1109
1110     my ($anchor, $breakwater);
1111     $breakwater = $head if $claimed_bw;
1112     my $clogonly;
1113     my $cl;
1114     my $found_pm;
1115     $fatal //= sub { fail_unprocessable $_[1]; };
1116     my $x = sub {
1117         my ($cb, $tagsfx, $mainwhy, $xwhy) = @_;
1118         my $why = $mainwhy.$xwhy;
1119         my $m = f_ "branch needs laundering (run git-debrebase): %s", $why;
1120         fail $m unless defined $cb;
1121         return unless $cb;
1122         $cb->("unclean-$tagsfx", $why, $cl, $mainwhy);
1123     };
1124     my $found_anchor = sub {
1125         ($anchor) = @_;
1126         $breakwater //= $clogonly;
1127         $breakwater //= $head;
1128         no warnings qw(exiting);
1129         last;
1130     };
1131     for (;;) {
1132         $cl = classify $head;
1133         my $ty = $cl->{Type};
1134         if ($ty eq 'Packaging') {
1135             $breakwater //= $clogonly;
1136             $breakwater //= $head;
1137         } elsif ($ty eq 'Changelog') {
1138             # this is going to count as the tip of the breakwater
1139             # only if it has no upstream stuff before it
1140             $clogonly //= $head;
1141         } elsif ($ty eq 'Anchor' or
1142                  $ty eq 'TreatAsAnchor' or
1143                  $ty eq 'BreakwaterStart') {
1144             $found_anchor->($head);
1145         } elsif ($ty eq 'Upstream') {
1146             $x->($unclean, 'ordering',
1147  (f_ "packaging change (%s) follows upstream change", $breakwater),
1148                  (f_ " (eg %s)", $head))
1149                 if defined $breakwater;
1150             $clogonly = undef;
1151             $breakwater = undef;
1152         } elsif ($ty eq 'Mixed') {
1153             $x->($unclean, 'mixed',
1154                  (__ "found mixed upstream/packaging commit"),
1155                  (f_ " (%s)", $head));
1156             $clogonly = undef;
1157             $breakwater = undef;
1158         } elsif ($ty eq 'Pseudomerge' or
1159                  $ty eq 'AddPatches') {
1160             my $found_pm = 1;
1161             $x->($furniture, (lc $ty),
1162                  (f_ "found interchange bureaucracy commit (%s)", $ty),
1163                  (f_ " (%s)", $head));
1164         } elsif ($ty eq 'DgitImportUnpatched') {
1165             if ($found_pm) {
1166                 $x->($trouble, 'dgitimport',
1167                      (__ "found dgit dsc import"),
1168                      (f_ " (%s)", $head));
1169                 return (undef,undef);
1170             } else {
1171                 $x->($fatal, 'unprocessable',
1172                      (__ "found bare dgit dsc import with no prior history"),
1173                      (f_ " (%s)", $head));
1174                 return (undef,undef);
1175             }
1176         } elsif ($ty eq 'VanillaMerge') {
1177             $x->($trouble, 'vanillamerge',
1178                  (__ "found vanilla merge"),
1179                  (f_ " (%s)", $head));
1180             return (undef,undef);
1181         } elsif ($ty eq 'MergedBreakwaters') {
1182             $found_anchor->(mergedbreakwaters_anchor $cl);
1183         } else {
1184             $x->($fatal, 'unprocessable',
1185                  (f_ "found unprocessable commit, cannot cope: %s",
1186                      $cl->{Why}),
1187                  (f_ " (%s)", $head));
1188             return (undef,undef);
1189         }
1190         $head = $cl->{Parents}[0]{CommitId};
1191     }
1192     return ($anchor, $breakwater);
1193 }
1194
1195 sub walk ($;$$$);
1196 sub walk ($;$$$) {
1197     my ($input,
1198         $nogenerate,$report, $report_lprefix) = @_;
1199     # => ($tip, $breakwater_tip, $last_anchor)
1200     # (or nothing, if $nogenerate)
1201
1202     printdebug "*** WALK $input ".($nogenerate//0)." ".($report//'-')."\n";
1203     $report_lprefix //= '';
1204
1205     # go through commits backwards
1206     # we generate two lists of commits to apply:
1207     # breakwater branch and upstream patches
1208     my (@brw_cl, @upp_cl, @processed);
1209     my %found;
1210     my $upp_limit;
1211     my @pseudomerges;
1212
1213     my $cl;
1214     my $xmsg = sub {
1215         my ($prose, $info) = @_;
1216         # We deliberately do not translate $prose, since this mostly
1217         # appears in commits in Debian and they should be in English.
1218         my $ms = $cl->{Msg};
1219         chomp $ms;
1220         confess unless defined $info;
1221         $ms .= "\n\n[git-debrebase $info: $prose]\n";
1222         return (Msg => $ms);
1223     };
1224     my $rewrite_from_here = sub {
1225         my ($cl) = @_;
1226         my $sp_cl = { SpecialMethod => 'StartRewrite' };
1227         push @$cl, $sp_cl;
1228         push @processed, $sp_cl;
1229     };
1230     my $cur = $input;
1231
1232     my $prdelim = "";
1233     my $prprdelim = sub { print $report $prdelim if $report; $prdelim=""; };
1234
1235     my $prline = sub {
1236         return unless $report;
1237         print $report $prdelim, $report_lprefix, @_;
1238         $prdelim = "\n";
1239     };
1240
1241     my $bomb = sub { # usage: return $bomb->();
1242         print $report " Unprocessable" if $report;
1243         print $report " ($cl->{Why})" if $report && defined $cl->{Why};
1244         $prprdelim->();
1245         if ($nogenerate) {
1246             return (undef,undef);
1247         }
1248         my $d =
1249             join ' ',
1250             map { sprintf "%#x", $_->{Differs} }
1251             @{ $cl->{Parents} };
1252         fail_unprocessable f_ +(defined $cl->{Why}
1253  ? i_ 'found unprocessable commit, cannot cope; %3$s: (commit %1$s) (d.%2$s)'
1254  : i_ 'found unprocessable commit, cannot cope: (commit %1$s) (d.%2$s)'),
1255                                    $cur, $d, $cl->{Why};
1256     };
1257
1258     my $build;
1259     my $breakwater;
1260
1261     my $build_start = sub {
1262         my ($msg, $parent) = @_;
1263         $prline->(" $msg");
1264         $build = $parent;
1265         no warnings qw(exiting); last;
1266     };
1267
1268     my $nomerge = sub {
1269         my ($emsg) = @_;
1270         merge_failed $cl->{MergeWreckNotes}, $emsg;
1271     };
1272
1273     my $mwrecknote = sub { &mwrecknote($cl->{MergeWreckNotes}, @_); };
1274
1275     my $last_anchor;
1276
1277     for (;;) {
1278         $cl = classify $cur;
1279         $cl->{MergeWreckNotes} //= {};
1280         my $ty = $cl->{Type};
1281         my $st = $cl->{SubType};
1282         $prline->("$cl->{CommitId} $cl->{Type}");
1283         $found{$ty. ( defined($st) ? "-$st" : '' )}++;
1284         push @processed, $cl;
1285         my $p0 = @{ $cl->{Parents} }==1 ? $cl->{Parents}[0]{CommitId} : undef;
1286         if ($ty eq 'AddPatches') {
1287             $cur = $p0;
1288             $rewrite_from_here->(\@upp_cl);
1289             next;
1290         } elsif ($ty eq 'Packaging' or $ty eq 'Changelog') {
1291             push @brw_cl, $cl;
1292             $cur = $p0;
1293             next;
1294         } elsif ($ty eq 'BreakwaterStart') {
1295             $last_anchor = $cur;
1296             $build_start->('FirstPackaging', $cur);
1297         } elsif ($ty eq 'Upstream') {
1298             push @upp_cl, $cl;
1299             $cur = $p0;
1300             next;
1301         } elsif ($ty eq 'Mixed') {
1302             my $queue = sub {
1303                 my ($q, $wh) = @_;
1304                 my $cls = { %$cl, $xmsg->("mixed commit: $wh part",'split') };
1305                 push @$q, $cls;
1306             };
1307             $queue->(\@brw_cl, "debian");
1308             $queue->(\@upp_cl, "upstream");
1309             $rewrite_from_here->(\@brw_cl);
1310             $cur = $p0;
1311             next;
1312         } elsif ($ty eq 'Pseudomerge') {
1313             my $contrib = $cl->{Contributor}{CommitId};
1314             print $report " Contributor=$contrib" if $report;
1315             push @pseudomerges, $cl;
1316             $rewrite_from_here->(\@upp_cl);
1317             $cur = $contrib;
1318             next;
1319         } elsif ($ty eq 'Anchor' or $ty eq 'TreatAsAnchor') {
1320             $last_anchor = $cur;
1321             $build_start->("Anchor", $cur);
1322         } elsif ($ty eq 'DgitImportUnpatched') {
1323             my $pm = $pseudomerges[-1];
1324             if (defined $pm) {
1325                 # To an extent, this is heuristic.  Imports don't have
1326                 # a useful history of the debian/ branch.  We assume
1327                 # that the first pseudomerge after an import has a
1328                 # useful history of debian/, and ignore the histories
1329                 # from later pseudomerges.  Often the first pseudomerge
1330                 # will be the dgit import of the upload to the actual
1331                 # suite intended by the non-dgit NMUer, and later
1332                 # pseudomerges may represent in-archive copies.
1333                 my $ovwrs = $pm->{Overwritten};
1334                 printf $report " PM=%s \@Overwr:%d",
1335                     $pm->{CommitId}, (scalar @$ovwrs)
1336                     if $report;
1337                 if (@$ovwrs != 1) {
1338                     printdebug "*** WALK BOMB DgitImportUnpatched\n";
1339                     return $bomb->();
1340                 }
1341                 my $ovwr = $ovwrs->[0]{CommitId};
1342                 printf $report " Overwr=%s", $ovwr if $report;
1343                 # This import has a tree which is just like a
1344                 # breakwater tree, but it has the wrong history.  It
1345                 # ought to have the previous breakwater (which the
1346                 # pseudomerge overwrote) as an ancestor.  That will
1347                 # make the history of the debian/ files correct.  As
1348                 # for the upstream version: either it's the same as
1349                 # was ovewritten (ie, same as the previous
1350                 # breakwater), in which case that history is precisely
1351                 # right; or, otherwise, it was a non-gitish upload of a
1352                 # new upstream version.  We can tell these apart by
1353                 # looking at the tree of the supposed upstream.
1354                 push @brw_cl, {
1355                     %$cl,
1356                     SpecialMethod => 'DgitImportDebianUpdate',
1357                     $xmsg->("debian changes", 'convert dgit import')
1358                 }, {
1359                     %$cl,
1360                     SpecialMethod => 'DgitImportUpstreamUpdate',
1361                     $xmsg->("convert dgit import: upstream update",
1362                             "anchor")
1363                 };
1364                 $prline->(" Import");
1365                 $rewrite_from_here->(\@brw_cl);
1366                 $upp_limit //= $#upp_cl; # further, deeper, patches discarded
1367                 $cur = $ovwr;
1368                 next;
1369             } else {
1370                 # Everything is from this import.  This kind of import
1371                 # is already nearly in valid breakwater format, with the
1372                 # patches as commits.  Unfortunately it contains
1373                 # debian/patches/.
1374                 printdebug "*** WALK BOMB bare dgit import\n";
1375                 $cl->{Why} = __ "bare dgit dsc import";
1376                 return $bomb->();
1377             }
1378             confess "$ty ?";
1379         } elsif ($ty eq 'MergedBreakwaters') {
1380             $last_anchor = mergedbreakwaters_anchor $cl;
1381             $build_start->(' MergedBreakwaters', $cur);
1382             last;
1383         } elsif ($ty eq 'VanillaMerge') {
1384             # User may have merged unstitched branch(es).  We will
1385             # have now lost what ffq-prev was then (since the later
1386             # pseudomerge may introduce further changes).  The effect
1387             # of resolving such a merge is that we may have to go back
1388             # further in history to find a merge base, since the one
1389             # which was reachable via ffq-prev is no longer findable.
1390             # This is suboptimal, but if it all works we'll have done
1391             # the right thing.
1392             # MERGE-TODO we should warn the user in the docs about this
1393
1394             my $ok=1;
1395             my $best_anchor;
1396             # We expect to find a dominating anchor amongst the
1397             # inputs' anchors.  That will be the new anchor.
1398             #
1399             # More complicated is finding a merge base for the
1400             # breakwaters.  We need a merge base that is a breakwater
1401             # commit.  The ancestors of breakwater commits are more
1402             # breakwater commits and possibly upstream commits and the
1403             # ancestors of those upstream.  Upstreams might have
1404             # arbitrary ancestors.  But any upstream commit U is
1405             # either included in both anchors, in which case the
1406             # earlier anchor is a better merge base than any of U's
1407             # ancestors; or U is not included in the older anchor, in
1408             # which case U is not an ancestor of the vanilla merge at
1409             # all.  So no upstream commit, nor any ancestor thereof,
1410             # is a best merge base.  As for non-breakwater Debian
1411             # commits: these are never ancestors of any breakwater.
1412             #
1413             # So any best merge base as found by git-merge-base
1414             # is a suitable breakwater anchor.  Usually there will
1415             # be only one.
1416
1417             printdebug "*** MERGE\n";
1418
1419             my @bwbcmd = (@git, qw(merge-base));
1420             my @ibcmd = (@git, qw(merge-base --all));
1421             my $might_be_in_bw = 1;
1422
1423             my $ps = $cl->{Parents};
1424
1425             $mwrecknote->('vanilla-merge', $cl->{CommitId});
1426
1427             foreach my $p (@$ps) {
1428                 $prline->(" VanillaMerge ".$p->{Ix});
1429                 $prprdelim->();
1430                 my ($ptip, $pbw, $panchor) =
1431                     walk $p->{CommitId}, 0, $report,
1432                          $report_lprefix.'  ';
1433                 $p->{Laundered} = $p->{SeriesTip} = $ptip;
1434                 $p->{Breakwater} = $p->{SeriesBase} = $pbw;
1435                 $p->{Anchor} = $panchor;
1436
1437                 my $lr = $p->{LeftRight} = (qw(left right))[$p->{Ix}];
1438                 $mwrecknote->("$lr-input", $p->{CommitId});
1439
1440                 my $mwrecknote_parent = sub {
1441                     my ($which) = @_;
1442                     $mwrecknote->("$lr-".(lc $which), $p->{$which});
1443                 };
1444                 $mwrecknote_parent->('Laundered');
1445                 $mwrecknote_parent->('Breakwater');
1446                 $mwrecknote_parent->('Anchor');
1447
1448                 $best_anchor = $panchor if
1449                     !defined $best_anchor or
1450                     is_fast_fwd $best_anchor, $panchor;
1451
1452                 printdebug " MERGE BA best=".($best_anchor//'-').
1453                     " p=$panchor\n";
1454             }
1455
1456             $mwrecknote->('result-anchor', $best_anchor);
1457
1458             foreach my $p (@$ps) {
1459                 $prline->(" VanillaMerge ".$p->{Ix});
1460                 if (!is_fast_fwd $p->{Anchor}, $best_anchor) {
1461                     $nomerge->('divergent anchors');
1462                 } elsif ($p->{Anchor} eq $best_anchor) {
1463                     print $report " SameAnchor" if $report;
1464                 } else {
1465                     print $report " SupersededAnchor" if $report;
1466                 }
1467                 if ($p->{Breakwater} eq $p->{CommitId}) {
1468                     # this parent commit was its own breakwater,
1469                     # ie it is part of the breakwater
1470                     print $report " Breakwater" if $report;
1471                 } else {
1472                     $might_be_in_bw = 0;
1473                 }
1474                 push @bwbcmd, $p->{Breakwater};
1475                 push @ibcmd, $p->{CommitId};
1476             }
1477
1478             if ($ok && $might_be_in_bw) {
1479                 # We could rewrite this to contaion the metadata
1480                 # declaring it to be MergedBreakwaters, but
1481                 # unnecessarily rewriting a merge seems unhelpful.
1482                 $prline->(" VanillaMerge MergedBreakwaters");
1483                 $last_anchor = $best_anchor;
1484                 $build_start->('MergedBreakwaters', $cur);
1485             }
1486
1487             my $bwb = cmdoutput @bwbcmd;
1488
1489             # OK, now we have a breakwater base, but we need the merge
1490             # base for the interchange branch because we need the delta
1491             # queue.
1492             #
1493             # This a the best merge base of our inputs which has the
1494             # breakwater merge base as an ancestor.
1495
1496             my @ibs =
1497                 grep /./,
1498                 split /\n/,
1499                 cmdoutput @ibcmd;
1500
1501             @ibs or confess 'internal error, expected anchor at least ?';
1502
1503             my $ib;
1504             my $ibleaf;
1505             foreach my $tibix (0..$#ibs) {
1506                 my $tib = $ibs[$tibix];
1507                 my $ff = is_fast_fwd $bwb, $tib;
1508                 my $ok = !$ff ? 'rej' : $ib ? 'extra' : 'ok';
1509                 my $tibleaf = "interchange-mbcand-$ok-$tibix";
1510                 $mwrecknote->($tibleaf, $tib);
1511                 next unless $ff;
1512                 next if $ib;
1513                 $ib = $tib;
1514                 $ibleaf = $tibleaf;
1515             }
1516
1517             $ib or $nomerge->("no suitable interchange merge base");
1518
1519             $prline->("  VanillaMerge Base");
1520             $prprdelim->();
1521             my ($btip, $bbw, $banchor) = eval {
1522                 walk $ib, 0, $report, $report_lprefix.'  ';
1523             };
1524             $nomerge->("walking interchange branch merge base ($ibleaf):\n".
1525                        $@)
1526                 if length $@;
1527
1528             $mwrecknote->("mergebase-laundered", $btip);
1529             $mwrecknote->("mergebase-breakwater", $bbw);
1530             $mwrecknote->("mergebase-anchor", $banchor);
1531
1532             my $ibinfo = { SeriesTip => $btip,
1533                            SeriesBase => $bbw,
1534                            Anchor => $banchor,
1535                            LeftRight => 'mergebase' };
1536
1537             $bbw eq $bwb
1538                 or $nomerge->("interchange merge-base ($ib)'s".
1539                               " breakwater ($bbw)".
1540                               " != breakwaters' merge-base ($bwb)");
1541
1542             grep { $_->{Anchor} eq $ibinfo->{Anchor} } @$ps
1543                  or $nomerge->("interchange merge-base ($ib)'s".
1544                                " anchor ($ibinfo->{SeriesBase})".
1545                                " != any merge input's anchor (".
1546                                (join ' ', map { $_->{Anchor} } @$ps).
1547                                ")");
1548
1549             $cl->{MergeInterchangeBaseInfo} = $ibinfo;
1550             $cl->{MergeBestAnchor} = $best_anchor;
1551             push @brw_cl, {
1552                 %$cl,
1553                 SpecialMethod => 'MergeCreateMergedBreakwaters',
1554                 $xmsg->('constructed from vanilla merge',
1555                         'merged-breakwater'),
1556             };
1557             push @upp_cl, {
1558                 %$cl,
1559                 SpecialMethod => 'MergeMergeSeries',
1560             };
1561             $build_start->('MergeBreakwaters', $cur);
1562         } else {
1563             printdebug "*** WALK BOMB unrecognised\n";
1564             return $bomb->();
1565         }
1566     }
1567     $prprdelim->();
1568
1569     printdebug "*** WALK prep done cur=$cur".
1570         " brw $#brw_cl upp $#upp_cl proc $#processed pm $#pseudomerges\n";
1571
1572     return if $nogenerate;
1573
1574     # Now we build it back up again
1575
1576     fresh_workarea();
1577
1578     my $rewriting = 0;
1579
1580     $#upp_cl = $upp_limit if defined $upp_limit;
1581
1582     my $committer_authline = calculate_committer_authline();
1583
1584     printdebug "WALK REBUILD $build ".(scalar @processed)."\n";
1585
1586     confess __ "internal error" unless $build eq (pop @processed)->{CommitId};
1587
1588     in_workarea sub {
1589         mkdir $rd or $!==EEXIST or confess "$!";
1590         my $current_method;
1591         my $want_debian = $build;
1592         my $want_upstream = $build;
1593
1594         my $read_tree_upstream = sub { ($want_upstream) = @_; };
1595         my $read_tree_debian = sub { ($want_debian) = @_; };
1596
1597         foreach my $cl (qw(Debian), (reverse @brw_cl),
1598                         { SpecialMethod => 'RecordBreakwaterTip' },
1599                         qw(Upstream), (reverse @upp_cl)) {
1600             if (!ref $cl) {
1601                 $current_method = $cl;
1602                 next;
1603             }
1604             my $method = $cl->{SpecialMethod} // $current_method;
1605             my @parents = ($build);
1606             my $cltree = $cl->{CommitId};
1607             printdebug "WALK BUILD ".($cltree//'undef').
1608                 " $method (rewriting=$rewriting)\n";
1609             if ($method eq 'Debian') {
1610                 $read_tree_debian->($cltree);
1611             } elsif ($method eq 'Upstream') {
1612                 $read_tree_upstream->($cltree);
1613             } elsif ($method eq 'StartRewrite') {
1614                 $rewriting = 1;
1615                 next;
1616             } elsif ($method eq 'RecordBreakwaterTip') {
1617                 $breakwater = $build;
1618                 next;
1619             } elsif ($method eq 'DgitImportDebianUpdate') {
1620                 $read_tree_debian->($cltree);
1621             } elsif ($method eq 'DgitImportUpstreamUpdate') {
1622                 confess unless $rewriting;
1623                 my $differs = (get_differs $build, $cltree);
1624                 next unless $differs & D_UPS;
1625                 $read_tree_upstream->($cltree);
1626                 push @parents, map { $_->{CommitId} } @{ $cl->{OrigParents} };
1627             } elsif ($method eq 'MergeCreateMergedBreakwaters') {
1628                 print "Found a general merge, will try to tidy it up.\n";
1629                 $rewriting = 1;
1630                 $read_tree_upstream->($cl->{MergeBestAnchor});
1631                 $read_tree_debian->($cltree);
1632                 @parents = map { $_->{Breakwater} } @{ $cl->{Parents} };
1633             } elsif ($method eq 'MergeMergeSeries') {
1634                 my $cachehit = reflog_cache_lookup
1635                     $merge_cache_ref, "vanilla-merge $cl->{CommitId}";
1636                 if ($cachehit) {
1637                     print "Using supplied resolution for $cl->{CommitId}...\n";
1638                     $build = $cachehit;
1639                     $mwrecknote->('cached-resolution', $build);
1640                 } else {
1641                     print "Running merge resolution for $cl->{CommitId}...\n";
1642                     $mwrecknote->('new-base', $build);
1643                     $build = merge_series
1644                         $build, $cl->{MergeWreckNotes},
1645                         $cl->{MergeInterchangeBaseInfo},
1646                         @{ $cl->{Parents} };
1647                 }
1648                 $last_anchor = $cl->{MergeBestAnchor};
1649
1650                 # Check for mismerges:
1651                 my $check = sub {
1652                     my ($against, $allow, $what) = @_;
1653                     my $differs = get_differs $build, $against;
1654                     $nomerge->(sprintf
1655        "merge misresolved: %s are not the same (%s %s d.%#x)",
1656                                $what, $against, $build, $differs)
1657                         if $differs & ~($allow | D_PAT_ADD);
1658                 };
1659
1660                 # Breakwater changes which were in each side of the
1661                 # merge will have been incorporated into the
1662                 # MergeCreateMergedBreakwaters output.  Because the
1663                 # upstream series was rebased onto the new breakwater,
1664                 # so should all of the packaging changes which were in
1665                 # the input.
1666                 $check->($input, D_UPS, 'debian files');
1667
1668                 # Upstream files are merge_series, which ought to
1669                 # have been identical to the original merge.
1670                 $check->($cl->{CommitId}, DS_DEB, 'upstream files');
1671
1672                 print "Merge resolution successful.\n";
1673                 next;
1674             } else {
1675                 confess "$method ?";
1676             }
1677             if (!$rewriting) {
1678                 my $procd = (pop @processed) // 'UNDEF';
1679                 if ($cl ne $procd) {
1680                     $rewriting = 1;
1681                     printdebug "WALK REWRITING NOW cl=$cl procd=$procd\n";
1682                 }
1683             }
1684             if ($rewriting) {
1685                 read_tree_upstream $want_upstream, 0, $want_debian;
1686
1687                 my $newtree = cmdoutput @git, qw(write-tree);
1688                 my $ch = $cl->{Hdr};
1689                 $ch =~ s{^tree .*}{tree $newtree}m or confess "$ch ?";
1690                 $ch =~ s{^parent .*\n}{}mg;
1691                 $ch =~ s{(?=^author)}{
1692                     join '', map { "parent $_\n" } @parents
1693                 }me or confess "$ch ?";
1694                 if ($rewriting) {
1695                     $ch =~ s{^committer .*$}{$committer_authline}m
1696                         or confess "$ch ?";
1697                 }
1698                 my $cf = "$rd/m$rewriting";
1699                 open CD, ">", $cf or confess "$!";
1700                 print CD $ch, "\n", $cl->{Msg} or confess "$!";
1701                 close CD or confess "$!";
1702                 my @cmd = (@git, qw(hash-object));
1703                 push @cmd, qw(-w) if $rewriting;
1704                 push @cmd, qw(-t commit), $cf;
1705                 my $newcommit = cmdoutput @cmd;
1706                 confess "$ch ?" unless $rewriting
1707                     or $newcommit eq $cl->{CommitId};
1708                 $build = $newcommit;
1709             } else {
1710                 $build = $cl->{CommitId};
1711                 trees_diff_walk "$want_upstream:", "$build:", sub {
1712                     my ($n) = @_;
1713                     no warnings qw(exiting);
1714                     next if $n eq 'debian/';
1715                     confess f_ "mismatch %s ?", "@_";
1716                 };
1717                 trees_diff_walk "$want_debian:debian", "$build:debian", sub {
1718                     confess f_ "mismatch %s ?", "@_";
1719                 };
1720                 my @old_parents = map { $_->{CommitId} } @{ $cl->{Parents} };
1721                 confess f_ "mismatch %s != %s ?", "@parents", "@old_parents"
1722                     unless "@parents" eq "@old_parents";
1723             }
1724             if (grep { $method eq $_ } qw(DgitImportUpstreamUpdate)) {
1725                 $last_anchor = $cur;
1726             }
1727         }
1728     };
1729
1730     my $final_check = get_differs $build, $input;
1731     confess f_ "internal error %#x %s %s", $final_check, $input, $build
1732         if $final_check & ~D_PAT_ADD;
1733
1734     my @r = ($build, $breakwater, $last_anchor);
1735     printdebug "*** WALK RETURN @r\n";
1736     return @r
1737 }
1738
1739 sub get_head () {
1740     git_check_unmodified();
1741     return git_rev_parse qw(HEAD);
1742 }
1743
1744 sub update_head ($$$) {
1745     my ($old, $new, $mrest) = @_;
1746     push @deferred_updates, "update HEAD $new $old";
1747     run_deferred_updates $mrest;
1748 }
1749
1750 sub update_head_checkout ($$$) {
1751     my ($old, $new, $mrest) = @_;
1752     update_head $old, $new, $mrest;
1753     runcmd @git, qw(reset --hard);
1754 }
1755
1756 sub update_head_postlaunder ($$$) {
1757     my ($old, $tip, $reflogmsg) = @_;
1758     return if $tip eq $old && !@deferred_updates;
1759     print f_ "%s: laundered (head was %s)\n", $us, $old;
1760     update_head $old, $tip, $reflogmsg;
1761     # no tree changes except debian/patches
1762     runcmd @git, qw(rm --quiet --ignore-unmatch -rf debian/patches);
1763 }
1764
1765 sub currently_rebasing() {
1766     foreach (qw(rebase-merge rebase-apply)) {
1767         return 1 if stat_exists "$maindir_gitdir/$_";
1768     }
1769     return 0;
1770 }
1771
1772 sub bail_if_rebasing() {
1773     fail __ "you are in the middle of a git-rebase already"
1774         if currently_rebasing();
1775 }
1776
1777 sub do_launder_head ($) {
1778     my ($reflogmsg) = @_;
1779     my $old = get_head();
1780     record_ffq_auto();
1781     my ($tip,$breakwater) = walk $old;
1782     snags_maybe_bail();
1783     update_head_postlaunder $old, $tip, $reflogmsg;
1784     return ($tip,$breakwater);
1785 }
1786
1787 sub cmd_launder_v0 () {
1788     badusage "no arguments to launder-v0 allowed" if @ARGV;
1789     my $old = get_head();
1790     my ($tip,$breakwater,$last_anchor) = walk $old;
1791     update_head_postlaunder $old, $tip, 'launder';
1792     printf "# breakwater tip\n%s\n", $breakwater;
1793     printf "# working tip\n%s\n", $tip;
1794     printf "# last anchor\n%s\n", $last_anchor;
1795 }
1796
1797 sub defaultcmd_rebase () {
1798     push @ARGV, @{ $opt_defaultcmd_interactive // [] };
1799     my ($tip,$breakwater) = do_launder_head __ 'launder for rebase';
1800     runcmd @git, qw(rebase), @ARGV, $breakwater if @ARGV;
1801 }
1802
1803 sub cmd_analyse () {
1804     badusage __ "analyse does not support any options"
1805         if @ARGV and $ARGV[0] =~ m/^-/;
1806     badusage __ "too many arguments to analyse" if @ARGV>1;
1807     my ($old) = @ARGV;
1808     if (defined $old) {
1809         $old = git_rev_parse $old;
1810     } else {
1811         $old = git_rev_parse 'HEAD';
1812     }
1813     my ($dummy,$breakwater) = walk $old, 1,*STDOUT;
1814     STDOUT->error and confess "$!";
1815 }
1816
1817 sub ffq_check ($;$$) {
1818     # calls $ff and/or $notff zero or more times
1819     # then returns either (status,message) where status is
1820     #    exists
1821     #    detached
1822     #    weird-symref
1823     #    notbranch
1824     # or (undef,undef, $ffq_prev,$gdrlast)
1825     # $ff and $notff are called like this:
1826     #   $ff->("message for stdout\n");
1827     #   $notff->('snag-name', $message);
1828     # normally $currentval should be HEAD
1829     my ($currentval, $ff, $notff) =@_;
1830
1831     $ff //= sub { print $_[0] or confess "$!"; };
1832     $notff //= \&snag;
1833
1834     my ($status, $message, $current, $ffq_prev, $gdrlast)
1835         = ffq_prev_branchinfo();
1836     return ($status, $message) unless $status eq 'branch';
1837
1838     my $exists = git_get_ref $ffq_prev;
1839     return ('exists', f_ "%s already exists", $ffq_prev) if $exists;
1840
1841     return ('not-branch', __ 'HEAD symref is not to refs/heads/')
1842         unless $current =~ m{^refs/heads/};
1843     my $branch = $';
1844
1845     my @check_specs = split /\;/, (cfg "branch.$branch.ffq-ffrefs",1) // '*';
1846     my %checked;
1847
1848     printdebug "ffq check_specs @check_specs\n";
1849
1850     my $check = sub {
1851         my ($lrref, $desc) = @_;
1852         printdebug "ffq might check $lrref ($desc)\n";
1853         my $invert;
1854         for my $chk (@check_specs) {
1855             my $glob = $chk;
1856             $invert = $glob =~ s{^[!^]}{};
1857             last if fnmatch $glob, $lrref;
1858         }
1859         return if $invert;
1860         my $lrval = git_get_ref $lrref;
1861         return unless length $lrval;
1862
1863         if (is_fast_fwd $lrval, $currentval) {
1864             $ff->(f_ "OK, you are ahead of %s\n", $lrref);
1865             $checked{$lrref} = 1;
1866         } elsif (is_fast_fwd $currentval, $lrval) {
1867             $checked{$lrref} = -1;
1868             $notff->('behind', f_ "you are behind %s, divergence risk",
1869                                   $lrref);
1870         } else {
1871             $checked{$lrref} = -1;
1872             $notff->('diverged', f_ "you have diverged from %s", $lrref);
1873         }
1874     };
1875
1876     my $merge = cfg "branch.$branch.merge",1;
1877     if (defined $merge and $merge =~ m{^refs/heads/}) {
1878         my $rhs = $';
1879         printdebug "ffq merge $rhs\n";
1880         my $check_remote = sub {
1881             my ($remote, $desc) = @_;
1882             printdebug "ffq check_remote ".($remote//'undef')." $desc\n";
1883             return unless defined $remote;
1884             $check->("refs/remotes/$remote/$rhs", $desc);
1885         };
1886         $check_remote->((scalar cfg "branch.$branch.remote",1),
1887                         'remote fetch/merge branch');
1888         $check_remote->((scalar cfg "branch.$branch.pushRemote",1) //
1889                         (scalar cfg "branch.$branch.pushDefault",1),
1890                         'remote push branch');
1891     }
1892     if ($branch =~ m{^dgit/}) {
1893         $check->("refs/remotes/dgit/$branch",
1894                  __ 'remote dgit branch');
1895     } elsif ($branch =~ m{^master$}) {
1896         $check->("refs/remotes/dgit/dgit/sid",
1897                  __ 'remote dgit branch for sid');
1898     }
1899     return (undef, undef, $ffq_prev, $gdrlast);
1900 }
1901
1902 sub record_ffq_prev_deferred () {
1903     # => ('status', "message")
1904     # 'status' may be
1905     #    deferred          message is undef
1906     #    exists
1907     #    detached
1908     #    weird-symref
1909     #    notbranch
1910     # if not ff from some branch we should be ff from, is an snag
1911     # if "deferred", will have added something about that to
1912     #   @deferred_update_messages, and also maybe printed (already)
1913     #   some messages about ff checks
1914     bail_if_rebasing();
1915     my $currentval = get_head();
1916
1917     my ($status,$message, $ffq_prev,$gdrlast) = ffq_check $currentval;
1918     return ($status,$message) if defined $status;
1919
1920     snags_maybe_bail();
1921
1922     push @deferred_updates, "update $ffq_prev $currentval $git_null_obj";
1923     push @deferred_updates, "delete $gdrlast";
1924     push @deferred_update_messages,
1925         __ "Recorded previous head for preservation";
1926     return ('deferred', undef);
1927 }
1928
1929 sub record_ffq_auto () {
1930     my ($status, $message) = record_ffq_prev_deferred();
1931     if ($status eq 'deferred' || $status eq 'exists') {
1932     } else {
1933         snag $status, f_ "could not record ffq-prev: %s", $message;
1934         snags_maybe_bail();
1935     }
1936 }
1937
1938 sub ffq_prev_info () {
1939     bail_if_rebasing();
1940     # => ($ffq_prev, $gdrlast, $ffq_prev_commitish)
1941     my ($status, $message, $current, $ffq_prev, $gdrlast)
1942         = ffq_prev_branchinfo();
1943     if ($status ne 'branch') {
1944         snag $status, f_ "could not check ffq-prev: %s", $message;
1945         snags_maybe_bail();
1946     }
1947     my $ffq_prev_commitish = $ffq_prev && git_get_ref $ffq_prev;
1948     return ($ffq_prev, $gdrlast, $ffq_prev_commitish);
1949 }
1950
1951 sub stitch ($$$$$) {
1952     my ($old_head, $ffq_prev, $gdrlast, $ffq_prev_commitish, $prose) = @_;
1953
1954     push @deferred_updates, "delete $ffq_prev $ffq_prev_commitish";
1955
1956     if (is_fast_fwd $old_head, $ffq_prev_commitish) {
1957         my $differs = get_differs $old_head, $ffq_prev_commitish;
1958         unless ($differs & ~D_PAT_ADD) {
1959             # ffq-prev is ahead of us, and the only tree changes it has
1960             # are possibly addition of things in debian/patches/.
1961             # Just wind forwards rather than making a pointless pseudomerge.
1962             record_gdrlast $gdrlast, $ffq_prev_commitish;
1963             update_head_checkout $old_head, $ffq_prev_commitish,
1964                 sprintf "stitch (%s)", __ 'fast forward';
1965             return;
1966         }
1967     }
1968     fresh_workarea();
1969     # We make pseudomerges with L as the contributing parent.
1970     # This makes git rev-list --first-parent work properly.
1971     my $new_head = make_commit [ $old_head, $ffq_prev ], [
1972         # we translate this against the time when this same code is
1973         # used outside Debian, for downstreams and users
1974         (__ 'Declare fast forward / record previous work'),
1975         "[git-debrebase pseudomerge: $prose]",
1976     ];
1977     record_gdrlast $gdrlast, $new_head;
1978     update_head $old_head, $new_head, "stitch: $prose";
1979 }
1980
1981 sub do_stitch ($;$) {
1982     my ($prose, $unclean) = @_;
1983
1984     my ($ffq_prev, $gdrlast, $ffq_prev_commitish) = ffq_prev_info();
1985     if (!$ffq_prev_commitish) {
1986         fail __ "No ffq-prev to stitch." unless $opt_noop_ok;
1987         return;
1988     }
1989     my $dangling_head = get_head();
1990
1991     keycommits $dangling_head, $unclean,$unclean,$unclean;
1992     snags_maybe_bail();
1993
1994     stitch($dangling_head, $ffq_prev, $gdrlast, $ffq_prev_commitish, $prose);
1995 }
1996
1997 sub cmd_new_upstream () {
1998     # automatically and unconditionally launders before rebasing
1999     # if rebase --abort is used, laundering has still been done
2000
2001     my %pieces;
2002
2003     badusage __ "need NEW-VERSION [UPS-COMMITTISH]" unless @ARGV >= 1;
2004
2005     # parse args - low commitment
2006     my $spec_version = shift @ARGV;
2007     my $new_version = (new Dpkg::Version $spec_version, check => 1);
2008     fail f_ "bad version number \`%s'", $spec_version
2009         unless defined $new_version;
2010     if ($new_version->is_native()) {
2011         $new_version = (new Dpkg::Version "$spec_version-1", check => 1);
2012     }
2013
2014     my $new_upstream = shift @ARGV;
2015     my $new_upstream_version = upstreamversion  $new_version;
2016     my $new_upstream_used;
2017     ($new_upstream, $new_upstream_used) =
2018         resolve_upstream_version $new_upstream, $new_upstream_version;
2019
2020     record_ffq_auto();
2021
2022     my $piece = sub {
2023         my ($n, @x) = @_; # may be ''
2024         my $pc = $pieces{$n} //= {
2025             Name => $n,
2026             Desc => ($n ? (f_ "upstream piece \`%s'", $n)
2027                         : (__ "upstream (main piece")),
2028         };
2029         while (my $k = shift @x) { $pc->{$k} = shift @x; }
2030         $pc;
2031     };
2032
2033     my @newpieces;
2034     my $newpiece = sub {
2035         my ($n, @x) = @_; # may be ''
2036         my $pc = $piece->($n, @x, NewIx => (scalar @newpieces));
2037         push @newpieces, $pc;
2038     };
2039
2040     $newpiece->('',
2041         OldIx => 0,
2042         New => $new_upstream,
2043     );
2044     while (@ARGV && $ARGV[0] !~ m{^-}) {
2045         my $n = shift @ARGV;
2046
2047         badusage __ "for each EXTRA-UPS-NAME need EXTRA-UPS-COMMITISH"
2048             unless @ARGV && $ARGV[0] !~ m{^-};
2049
2050         my $c = git_rev_parse shift @ARGV;
2051         confess unless $n =~ m/^$extra_orig_namepart_re$/;
2052         $newpiece->($n, New => $c);
2053     }
2054
2055     # now we need to investigate the branch this generates the
2056     # laundered version but we don't switch to it yet
2057     my $old_head = get_head();
2058     my ($old_laundered_tip,$old_bw,$old_anchor) = walk $old_head;
2059
2060     my $old_bw_cl = classify $old_bw;
2061     my $old_anchor_cl = classify $old_anchor;
2062     my $old_upstream;
2063     if (!$old_anchor_cl->{OrigParents}) {
2064         snag 'anchor-treated',
2065  __ 'old anchor is recognised due to --anchor, cannot check upstream';
2066     } else {
2067         $old_upstream = parsecommit
2068             $old_anchor_cl->{OrigParents}[0]{CommitId};
2069         $piece->('', Old => $old_upstream->{CommitId});
2070     }
2071
2072     if ($old_upstream && $old_upstream->{Msg} =~ m{^\[git-debrebase }m) {
2073         if ($old_upstream->{Msg} =~
2074  m{^\[git-debrebase upstream-combine (\.(?: $extra_orig_namepart_re)+)\:.*\]$}m
2075            ) {
2076             my @oldpieces = (split / /, $1);
2077             my $old_n_parents = scalar @{ $old_upstream->{Parents} };
2078             if ($old_n_parents != @oldpieces &&
2079                 $old_n_parents != @oldpieces + 1) {
2080                 snag 'upstream-confusing', f_
2081                     "previous upstream combine %s".
2082                     " mentions %d pieces (each implying one parent)".
2083                     " but has %d parents".
2084                     " (one per piece plus maybe a previous combine)",
2085                     $old_upstream->{CommitId},
2086                     (scalar @oldpieces),
2087                     $old_n_parents;
2088             } elsif ($oldpieces[0] ne '.') {
2089                 snag 'upstream-confusing', f_
2090                     "previous upstream combine %s".
2091                     " first piece is not \`.'",
2092                     $oldpieces[0];
2093             } else {
2094                 $oldpieces[0] = '';
2095                 foreach my $i (0..$#oldpieces) {
2096                     my $n = $oldpieces[$i];
2097                     my $hat = 1 + $i + ($old_n_parents - @oldpieces);
2098                     $piece->($n, Old => $old_upstream->{CommitId}.'^'.$hat);
2099                 }
2100             }
2101         } else {
2102             snag 'upstream-confusing', f_
2103                 "previous upstream %s is from".
2104                " git-debrebase but not an \`upstream-combine' commit",
2105                $old_upstream->{CommitId};
2106         }
2107     }
2108
2109     foreach my $pc (values %pieces) {
2110         if (!$old_upstream) {
2111             # we have complained already
2112         } elsif (!$pc->{Old}) {
2113             snag 'upstream-new-piece',
2114                 f_ "introducing upstream piece \`%s'", $pc->{Name};
2115         } elsif (!$pc->{New}) {
2116             snag 'upstream-rm-piece',
2117                 f_ "dropping upstream piece \`%s'", $pc->{Name};
2118         } elsif (!is_fast_fwd $pc->{Old}, $pc->{New}) {
2119             snag 'upstream-not-ff',
2120                 f_ "not fast forward: %s %s",
2121                    $pc->{Name}, "$pc->{Old}..$pc->{New}";
2122         }
2123     }
2124
2125     printdebug "%pieces = ", (dd \%pieces), "\n";
2126     printdebug "\@newpieces = ", (dd \@newpieces), "\n";
2127
2128     snags_maybe_bail();
2129
2130     my $new_bw;
2131
2132     fresh_workarea();
2133     in_workarea sub {
2134         my @upstream_merge_parents;
2135
2136         if (!any_snags()) {
2137             push @upstream_merge_parents, $old_upstream->{CommitId};
2138         }
2139
2140         foreach my $pc (@newpieces) { # always has '' first
2141             if ($pc->{Name}) {
2142                 read_tree_subdir $pc->{Name}, $pc->{New};
2143             } else {
2144                 runcmd @git, qw(read-tree), $pc->{New};
2145             }
2146             push @upstream_merge_parents, $pc->{New};
2147         }
2148
2149         # index now contains the new upstream
2150
2151         if (@newpieces > 1) {
2152             # need to make the upstream subtree merge commit
2153             $new_upstream = make_commit \@upstream_merge_parents,
2154                 [ "Combine upstreams for $new_upstream_version",
2155  ("[git-debrebase upstream-combine . ".
2156  (join " ", map { $_->{Name} } @newpieces[1..$#newpieces]).
2157  ": new upstream]"),
2158                 ];
2159         }
2160
2161         # $new_upstream is either the single upstream commit, or the
2162         # combined commit we just made.  Either way it will be the
2163         # "upstream" parent of the anchor merge.
2164
2165         read_tree_subdir 'debian', "$old_bw:debian";
2166
2167         # index now contains the anchor merge contents
2168         $new_bw = make_commit [ $old_bw, $new_upstream ],
2169             [ "Update to upstream $new_upstream_version",
2170  "[git-debrebase anchor: new upstream $new_upstream_version, merge]",
2171             ];
2172
2173         # Now we have to add a changelog stanza so the Debian version
2174         # is right.  We use debchange to do this.  Invoking debchange
2175         # here is a bit fiddly because it has a lot of optional
2176         # exciting behaviours, some of which will break stuff, and
2177         # some of which won't work in a playtree.
2178
2179         # Make debchange use git's idea of the user's identity.
2180         # That way, if the user never uses debchange et al, configuring
2181         # git is enough.
2182         my $usetup = sub {
2183             my ($e, $k) = @_;
2184             my $v = cfg $k, 1;
2185             defined $v or return;
2186             $ENV{$e} = $v;
2187         };
2188         $usetup->('DEBEMAIL',    'user.email');
2189         $usetup->('DEBFULLNAME', 'user.name');
2190
2191         my @dch = (qw(debchange
2192                       --allow-lower-version .*
2193                       --no-auto-nmu
2194                       --preserve
2195                       --vendor=Unknown-Vendor
2196                       --changelog debian/changelog
2197                       --check-dirname-level 0
2198                       --release-heuristic=changelog
2199                       -v), $new_version,
2200                    "Update to new upstream version $new_upstream_version.");
2201
2202         runcmd @git, qw(checkout -q debian/changelog);
2203         runcmd @dch;
2204         runcmd @git, qw(update-index --add --replace), 'debian/changelog';
2205
2206         # Now we have the final new breakwater branch in the index
2207         $new_bw = make_commit [ $new_bw ],
2208             [ "Update changelog for new upstream $new_upstream_version",
2209               "[git-debrebase changelog: new upstream $new_upstream_version]",
2210             ];
2211     };
2212
2213     # we have constructed the new breakwater. we now need to commit to
2214     # the laundering output, because git-rebase can't easily be made
2215     # to make a replay list which is based on some other branch
2216
2217     update_head_postlaunder $old_head, $old_laundered_tip,
2218         'launder for new upstream';
2219
2220     my @cmd = (@git, qw(rebase --onto), $new_bw, $old_bw, @ARGV);
2221     local $ENV{GIT_REFLOG_ACTION} = git_reflog_action_msg
2222         "debrebase new-upstream $new_version: rebase";
2223     runcmd @cmd;
2224     # now it's for the user to sort out
2225 }
2226
2227 sub cmd_record_ffq_prev () {
2228     badusage "no arguments allowed" if @ARGV;
2229     my ($status, $msg) = record_ffq_prev_deferred();
2230     if ($status eq 'exists' && $opt_noop_ok) {
2231         print __ "Previous head already recorded\n" or confess "$!";
2232     } elsif ($status eq 'deferred') {
2233         run_deferred_updates 'record-ffq-prev';
2234     } else {
2235         fail f_ "Could not preserve: %s", $msg;
2236     }
2237 }
2238
2239 sub cmd_anchor () {
2240     badusage __ "no arguments allowed" if @ARGV;
2241     my ($anchor, $bw) = keycommits +(git_rev_parse 'HEAD'), 0,0;
2242     print "$anchor\n" or confess "$!";
2243 }
2244
2245 sub cmd_breakwater () {
2246     badusage __ "no arguments allowed" if @ARGV;
2247     my ($anchor, $bw) = keycommits +(git_rev_parse 'HEAD'), 0,0;
2248     print "$bw\n" or confess "$!";
2249 }
2250
2251 sub cmd_status () {
2252     badusage __ "no arguments allowed" if @ARGV;
2253
2254     # todo: gdr status should print divergence info
2255     # todo: gdr status should print upstream component(s) info
2256     # todo: gdr should leave/maintain some refs with this kind of info ?
2257
2258     my $oldest = { Badness => 0 };
2259     my $newest;
2260     my $note = sub {
2261         my ($badness, $ourmsg, $snagname, $dummy, $cl, $kcmsg) = @_;
2262         if ($oldest->{Badness} < $badness) {
2263             $oldest = $newest = undef;
2264         }
2265         $oldest = {
2266                    Badness => $badness,
2267                    CommitId => $cl->{CommitId},
2268                    OurMsg => $ourmsg,
2269                    KcMsg => $kcmsg,
2270                   };
2271         $newest //= $oldest;
2272     };
2273     my ($anchor, $bw) = keycommits +(git_rev_parse 'HEAD'),
2274         sub { $note->(1, __ 'branch contains furniture (not laundered)',@_); },
2275         sub { $note->(2, __ 'branch is unlaundered', @_); },
2276         sub { $note->(3, __ 'branch needs laundering', @_); },
2277         sub { $note->(4, __ 'branch not in git-debrebase form', @_); };
2278
2279     my $prcommitinfo = sub {
2280         my ($cid) = @_;
2281         flush STDOUT or confess "$!";
2282         runcmd @git, qw(--no-pager log -n1),
2283             '--pretty=format:    %h %s%n',
2284             $cid;
2285     };
2286
2287     print __ "current branch contents, in git-debrebase terms:\n";
2288     if (!$oldest->{Badness}) {
2289         print __ "  branch is laundered\n";
2290     } else {
2291         print "  $oldest->{OurMsg}\n";
2292         my $printed = '';
2293         foreach my $info ($oldest, $newest) {
2294             my $cid = $info->{CommitId};
2295             next if $cid eq $printed;
2296             $printed = $cid;
2297             print "  $info->{KcMsg}\n";
2298             $prcommitinfo->($cid);
2299         }
2300     }
2301
2302     my $prab = sub {
2303         my ($cid, $what) = @_;
2304         if (!defined $cid) {
2305             print f_ "  %s is not well-defined\n", $what;
2306         } else {
2307             print "  $what\n";
2308             $prcommitinfo->($cid);
2309         }
2310     };
2311     print __ "key git-debrebase commits:\n";
2312     $prab->($anchor, __ 'anchor');
2313     $prab->($bw, __ 'breakwater');
2314
2315     my ($ffqstatus, $ffq_msg, $current, $ffq_prev, $gdrlast) =
2316         ffq_prev_branchinfo();
2317
2318     print __ "branch and ref status, in git-debrebase terms:\n";
2319     if ($ffq_msg) {
2320         print "  $ffq_msg\n";
2321     } else {
2322         $ffq_prev = git_get_ref $ffq_prev;
2323         $gdrlast = git_get_ref $gdrlast;
2324         if ($ffq_prev) {
2325             print __ "  unstitched; previous tip was:\n";
2326             $prcommitinfo->($ffq_prev);
2327         } elsif (!$gdrlast) {
2328             print __ "  stitched? (no record of git-debrebase work)\n";
2329         } elsif (is_fast_fwd $gdrlast, 'HEAD') {
2330             print __ "  stitched\n";
2331         } else {
2332             print __ "  not git-debrebase (diverged since last stitch)\n"
2333         }
2334     }
2335     print __ "you are currently rebasing\n" if currently_rebasing();
2336 }
2337
2338 sub cmd_stitch () {
2339     my $prose = 'stitch';
2340     getoptions("stitch",
2341                'prose=s', \$prose);
2342     badusage __ "no arguments allowed" if @ARGV;
2343     do_stitch $prose, 0;
2344 }
2345 sub cmd_prepush () {
2346     $opt_noop_ok = 1;
2347     cmd_stitch();
2348 }
2349
2350 sub cmd_quick () {
2351     badusage __ "no arguments allowed" if @ARGV;
2352     do_launder_head __ 'launder for git-debrebase quick';
2353     do_stitch 'quick';
2354 }
2355
2356 sub cmd_conclude () {
2357     my ($ffq_prev, $gdrlast, $ffq_prev_commitish) = ffq_prev_info();
2358     if (!$ffq_prev_commitish) {
2359         fail __ "No ongoing git-debrebase session." unless $opt_noop_ok;
2360         return;
2361     }
2362     my $dangling_head = get_head();
2363
2364     badusage "no arguments allowed" if @ARGV;
2365     do_launder_head __ 'launder for git-debrebase quick';
2366     do_stitch 'quick';
2367 }
2368
2369 sub cmd_scrap () {
2370     if (currently_rebasing()) {
2371         runcmd @git, qw(rebase --abort);
2372         push @deferred_updates, 'verify HEAD HEAD';
2373         # noop, but stops us complaining that scrap was a noop
2374     }
2375     badusage __ "no arguments allowed" if @ARGV;
2376     my ($ffq_prev, $gdrlast, $ffq_prev_commitish) = ffq_prev_info();
2377     my $scrapping_head;
2378     if ($ffq_prev_commitish) {
2379         $scrapping_head = get_head();
2380         push @deferred_updates,
2381             "update $gdrlast $ffq_prev_commitish $git_null_obj",
2382             "update $ffq_prev $git_null_obj $ffq_prev_commitish";
2383     }
2384     if (git_get_ref $merge_cache_ref) {
2385         push @deferred_updates,
2386             "delete $merge_cache_ref";
2387     }
2388     if (!@deferred_updates) {
2389         fail __ "No ongoing git-debrebase session." unless $opt_noop_ok;
2390         finish 0;
2391     }
2392     snags_maybe_bail();
2393     if ($scrapping_head) {
2394         update_head_checkout $scrapping_head, $ffq_prev_commitish, "scrap";
2395     } else {
2396         run_deferred_updates "scrap";
2397     }
2398 }
2399
2400 sub make_patches_staged ($) {
2401     my ($head) = @_;
2402     # Produces the patches that would result from $head if it were
2403     # laundered.
2404     my ($secret_head, $secret_bw, $last_anchor) = walk $head;
2405     fresh_workarea();
2406     my $any;
2407     in_workarea sub {
2408         $any = gbp_pq_export 'bw', $secret_bw, $secret_head;
2409     };
2410     return $any;
2411 }
2412
2413 sub make_patches ($) {
2414     my ($head) = @_;
2415     keycommits $head, 0, \&snag;
2416     my $any = make_patches_staged $head;
2417     my $out;
2418     in_workarea sub {
2419         my $ptree = !$any ? undef :
2420             cmdoutput @git, qw(write-tree --prefix=debian/patches/);
2421         runcmd @git, qw(read-tree), $head;
2422         if ($ptree) {
2423             read_tree_subdir 'debian/patches', $ptree;
2424         } else {
2425             rm_subdir_cached 'debian/patches';
2426         }
2427         $out = make_commit [$head], [
2428             (__ 'Commit patch queue (exported by git-debrebase)'),
2429             '[git-debrebase make-patches: export and commit patches]',
2430         ];
2431     };
2432     return $out;
2433 }
2434
2435 sub cmd_make_patches () {
2436     my $opt_quiet_would_amend;
2437     getoptions("make-patches",
2438                'quiet-would-amend!', \$opt_quiet_would_amend);
2439     badusage __ "no arguments allowed" if @ARGV;
2440     bail_if_rebasing();
2441     my $old_head = get_head();
2442     my $new = make_patches $old_head;
2443     my $d = get_differs $old_head, $new;
2444     if ($d == 0) {
2445         fail __ "No (more) patches to export." unless $opt_noop_ok;
2446         return;
2447     } elsif ($d == D_PAT_ADD) {
2448         snags_maybe_bail();
2449         update_head_checkout $old_head, $new, 'make-patches';
2450     } else {
2451         print STDERR failmsg f_
2452             "Patch export produced patch amendments".
2453             " (abandoned output commit %s).".
2454             "  Try laundering first.",
2455             $new
2456             unless $opt_quiet_would_amend;
2457         finish 7;
2458     }
2459 }
2460
2461 sub check_series_has_all_patches ($) {
2462     my ($head) = @_;
2463     my $seriesfn = 'debian/patches/series';
2464     my ($dummy, $series) = git_cat_file "$head:$seriesfn",
2465         [qw(blob missing)];
2466     $series //= '';
2467     my %series;
2468     our $comments_snagged;
2469     foreach my $f (grep /\S/, grep {!m/^\s\#/} split /\n/, $series) {
2470         if ($f =~ m/^\s*\#/) {
2471             snag 'series-comments', f_
2472                 "%s contains comments, which will be discarded",
2473                 $seriesfn
2474                 unless $comments_snagged++;
2475             next;
2476         }
2477         fail f_ "patch %s repeated in %s !", $f, $seriesfn if $series{$f}++;
2478     }
2479     foreach my $patchfile (get_tree "$head:debian/patches", 1,1) {
2480         my ($f,$i) = @$patchfile;
2481         next if $series{$f};
2482         next if $f eq 'series';
2483         snag 'unused-patches', f_
2484             "Unused patch file %s will be discarded", $f;
2485     }
2486 }
2487
2488 sub begin_convert_from () {
2489     my $head = get_head();
2490     my ($ffqs, $ffqm, $symref, $ffq_prev, $gdrlast) = ffq_prev_branchinfo();
2491
2492     fail __ "ffq-prev exists, this is already managed by git-debrebase!"
2493         if $ffq_prev && git_get_ref $ffq_prev;
2494
2495     my $gdrlast_obj = $gdrlast && git_get_ref $gdrlast;
2496     snag 'already-converted', __
2497         "ahead of debrebase-last, this is already managed by git-debrebase!"
2498         if $gdrlast_obj && is_fast_fwd $gdrlast_obj, $head;
2499     return ($head, { LastRef => $gdrlast, LastObj => $gdrlast_obj });
2500 }
2501
2502 sub complete_convert_from ($$$$) {
2503     my ($old_head, $new_head, $gi, $mrest) = @_;
2504     ffq_check $new_head;
2505     record_gdrlast $gi->{LastRef}, $new_head, $gi->{LastObj}
2506         if $gi->{LastRef};
2507     snags_maybe_bail();
2508     update_head_checkout $old_head, $new_head, $mrest;
2509 }
2510
2511 sub cmd_convert_from_unapplied () { cmd_convert_from_gbp(); }
2512 sub cmd_convert_from_gbp () {
2513     badusage __ "want only 1 optional argument, the upstream git commitish"
2514         unless @ARGV<=1;
2515
2516     my $clogp = parsechangelog();
2517     my $version = $clogp->{'Version'}
2518         // fail __ "missing Version from changelog\n";
2519
2520     my ($upstream_spec) = @ARGV;
2521
2522     my $upstream_version = upstreamversion $version;
2523     my ($upstream, $upstream_used) =
2524         resolve_upstream_version($upstream_spec, $upstream_version);
2525
2526     my ($old_head, $gdrlastinfo) = begin_convert_from();
2527
2528     my $upsdiff = get_differs $upstream, $old_head;
2529     if ($upsdiff & D_UPS) {
2530         runcmd @git, qw(--no-pager diff --stat),
2531             $upstream, $old_head,
2532             qw( -- :!/debian :/);
2533         fail f_ <<END, $upstream_used, $upstream;
2534 upstream (%s) and HEAD are not
2535 identical in upstream files.  See diffstat above, or run
2536   git diff %s HEAD -- :!/debian :/
2537 END
2538     }
2539
2540     if (!is_fast_fwd $upstream, $old_head) {
2541         snag 'upstream-not-ancestor',
2542             f_ "upstream (%s) is not an ancestor of HEAD", $upstream;
2543     } else {
2544         my $wrong = cmdoutput
2545             (@git, qw(rev-list --ancestry-path), "$upstream..HEAD",
2546              qw(-- :/ :!/debian));
2547         if (length $wrong) {
2548             snag 'unexpected-upstream-changes', f_
2549                 "history between upstream (%s) and HEAD contains direct changes to upstream files - are you sure this is a gbp (patches-unapplied) branch?",
2550                 $upstream_used;
2551             print STDERR f_ "list expected changes with:  %s\n",
2552  "git log --stat --ancestry-path $upstream..HEAD -- :/ ':!/debian'";
2553         }
2554     }
2555
2556     if ((git_cat_file "$upstream:debian")[0] ne 'missing') {
2557         snag 'upstream-has-debian',
2558             f_ "upstream (%s) contains debian/ directory", $upstream;
2559     }
2560
2561     check_series_has_all_patches $old_head;
2562
2563     my $previous_dgit_view = eval {
2564         my @clogcmd = qw(dpkg-parsechangelog --format rfc822 -n2);
2565         my ($lvsn, $suite);
2566         parsechangelog_loop \@clogcmd, 'debian/changelog', sub {
2567             my ($stz, $desc) = @_;
2568             no warnings qw(exiting);
2569             printdebug 'CHANGELOG ', Dumper($desc, $stz);
2570             next unless $stz->{Date};
2571             next unless $stz->{Distribution} ne 'UNRELEASED';
2572             $lvsn = $stz->{Version};
2573             $suite = $stz->{Distribution};
2574             last;
2575         };
2576         die __ "neither of the first two changelog entries are released\n"
2577             unless defined $lvsn;
2578         print "last finished-looking changelog entry: ($lvsn) $suite\n";
2579         my $mtag_pat = debiantag_maintview $lvsn, '*';
2580         my $mtag = cmdoutput @git, qw(describe --always --abbrev=0 --match),
2581             $mtag_pat;
2582         die f_ "could not find suitable maintainer view tag %s\n", $mtag_pat
2583             unless $mtag =~ m{/};
2584         is_fast_fwd $mtag, 'HEAD' or
2585             die f_ "HEAD is not FF from maintainer tag %s!", $mtag;
2586         my $dtag = "archive/$mtag";
2587         git_get_ref "refs/tags/$dtag" or
2588             die f_ "dgit view tag %s not found\n", $dtag;
2589         is_fast_fwd $mtag, $dtag or
2590             die f_ "dgit view tag %s is not FF from maintainer tag %s\n",
2591                    $dtag, $mtag;
2592         print f_ "will stitch in dgit view, %s\n", $dtag;
2593         git_rev_parse $dtag;
2594     };
2595     if (!$previous_dgit_view) {
2596         $@ =~ s/^\n+//;
2597         chomp $@;
2598         print STDERR f_ <<END, "$@";
2599 Cannot confirm dgit view: %s
2600 Failed to stitch in dgit view (see messages above).
2601 dgit --overwrite will be needed on the first dgit push after conversion.
2602 END
2603     }
2604
2605     snags_maybe_bail_early();
2606
2607     my $work;
2608
2609     fresh_workarea();
2610     in_workarea sub {
2611         runcmd @git, qw(checkout -q -b gdr-internal), $old_head;
2612         # make a branch out of the patch queue - we'll want this in a mo
2613         runcmd qw(gbp pq import);
2614         # strip the patches out
2615         runcmd @git, qw(checkout -q gdr-internal~0);
2616         rm_subdir_cached 'debian/patches';
2617         $work = make_commit ['HEAD'], [
2618  'git-debrebase convert-from-gbp: drop patches from tree',
2619  'Delete debian/patches, as part of converting to git-debrebase format.',
2620  '[git-debrebase convert-from-gbp: drop patches from tree]'
2621                               ];
2622         # make the anchor merge
2623         # the tree is already exactly right
2624         $work = make_commit [$work, $upstream], [
2625  'git-debrebase import: declare upstream',
2626  'First breakwater merge.',
2627  '[git-debrebase anchor: declare upstream]'
2628                               ];
2629
2630         # rebase the patch queue onto the new breakwater
2631         runcmd @git, qw(reset --quiet --hard patch-queue/gdr-internal);
2632         runcmd @git, qw(rebase --quiet --onto), $work, qw(gdr-internal);
2633         $work = git_rev_parse 'HEAD';
2634
2635         if ($previous_dgit_view) {
2636             $work = make_commit [$work, $previous_dgit_view], [
2637  'git-debrebase import: declare ff from dgit archive view',
2638  '[git-debrebase pseudomerge: import-from-gbp]',
2639             ];
2640         }
2641     };
2642
2643     complete_convert_from $old_head, $work, $gdrlastinfo, 'convert-from-gbp';
2644     print f_ <<END, $us or confess "$!";
2645 %s: converted from patched-unapplied (gbp) branch format, OK
2646 END
2647 }
2648
2649 sub cmd_convert_to_gbp () {
2650     badusage "no arguments allowed" if @ARGV;
2651     my $head = get_head();
2652     my (undef, undef, undef, $ffq, $gdrlast) = ffq_prev_branchinfo();
2653     my ($anchor, $breakwater) = keycommits $head, 0;
2654     my $out = $breakwater;
2655     my $any = make_patches_staged $head;
2656     if ($any) {
2657         in_workarea sub {
2658             $out = make_commit [$out], [
2659                 'Commit patch queue (converted from git-debrebase format)',
2660                 '[git-debrebase convert-to-gbp: commit patches]',
2661             ];
2662         };
2663     } else {
2664         # in this case, it can be fast forward
2665         $out = $head;
2666     }
2667     if (defined $ffq) {
2668         push @deferred_updates, "delete $ffq";
2669         push @deferred_updates, "delete $gdrlast";
2670     }
2671     snags_maybe_bail();
2672     update_head_checkout $head, $out, "convert to gbp (v0)";
2673     print f_ <<END, $us,$us,$us or confess "$!";
2674 %s: converted to git-buildpackage branch format
2675 %s: WARNING: do not now run "git-debrebase" any more
2676 %s: WARNING: doing so would drop all upstream patches!
2677 END
2678 }
2679
2680 sub cmd_convert_from_dgit_view () {
2681     my $clogp = parsechangelog();
2682
2683     my $bpd = (cfg 'dgit.default.build-products-dir',1) // '..';
2684     my $do_origs = 1;
2685     my $do_tags = 1;
2686     my $always = 0;
2687     my $diagnose = 0;
2688
2689     getoptions("convert-from-dgit-view",
2690                'diagnose!', \$diagnose,
2691                'build-products-dir:s', \$bpd,
2692                'origs!', \$do_origs,
2693                'tags!', \$do_tags,
2694                'always-convert-anyway!', \$always);
2695     fail __ "takes 1 optional argument, the upstream commitish" if @ARGV>1;
2696
2697     my @upstreams;
2698
2699     if (@ARGV) {
2700         my $spec = shift @ARGV;
2701         my $commit = git_rev_parse "$spec^{commit}";
2702         push @upstreams, { Commit => $commit,
2703                            Source => (f_ "%s, from command line", $ARGV[0]),
2704                            Only => 1,
2705                          };
2706     }
2707
2708     my ($head, $gdrlastinfo) = begin_convert_from();
2709
2710     if (!$always) {
2711         my $troubles = 0;
2712         my $trouble = sub { $troubles++; };
2713         keycommits $head, sub{}, sub{}, $trouble, $trouble;
2714         printdebug "troubles=$troubles\n";
2715         if (!$troubles) {
2716             print STDERR f_ <<END, $us,$us,$us;
2717 %s: Branch already seems to be in git-debrebase format!
2718 %s: --always-convert-anyway would do the conversion operation anyway
2719 %s: but is probably a bad idea.  Probably, you wanted to do nothing.
2720 END
2721             fail __ "Branch already in git-debrebase format."
2722                 unless $opt_noop_ok;
2723             finish 0;
2724         }
2725     }
2726
2727     check_series_has_all_patches $head;
2728
2729     snags_maybe_bail_early();
2730
2731     my $version = upstreamversion $clogp->{Version};
2732     print STDERR __
2733         "Considering possible commits corresponding to upstream:\n";
2734
2735     if (!@upstreams) {
2736         if ($do_tags) {
2737             my @tried;
2738             my $ups_tag = upstream_commitish_search $version, \@tried;
2739             if ($ups_tag) {
2740                 my $this = f_ "git tag %s", $tried[-1];
2741                 push @upstreams, { Commit => $ups_tag,
2742                                    Source => $this,
2743                                  };
2744             } else {
2745                 print STDERR f_
2746                     " git tag: no suitable tag found (tried %s)\n",
2747                     "@tried";
2748             }
2749         }
2750         if ($do_origs) {
2751             my $p = $clogp->{'Source'};
2752             # we do a quick check to see if there are plausible origs
2753             my $something=0;
2754             if (!opendir BPD, $bpd) {
2755                 die f_ "opendir build-products-dir %s: %s", $bpd, $!
2756                     unless $!==ENOENT;
2757             } else {
2758                 while ($!=0, my $f = readdir BPD) {
2759                     next unless is_orig_file_of_p_v $f, $p, $version;
2760                     print STDERR f_
2761                         " orig: found what looks like a .orig, %s\n",
2762                         "$bpd/$f";
2763                     $something=1;
2764                     last;
2765                 }
2766                 confess "read $bpd: $!" if $!;
2767                 closedir BPD;
2768             }
2769             if ($something) {
2770                 my $tree = cmdoutput
2771                     @dgit, qw(--build-products-dir), $bpd,
2772                     qw(print-unapplied-treeish);
2773                 fresh_workarea();
2774                 in_workarea sub {
2775                     runcmd @git, qw(reset --quiet), $tree, qw(-- .);
2776                     rm_subdir_cached 'debian';
2777                     $tree = cmdoutput @git, qw(write-tree);
2778                     my $ups_synth = make_commit [], [ <<END, <<END,
2779 Import effective orig tree for upstream version $version
2780 END
2781 This includes the contents of the .orig(s), minus any debian/ directory.
2782
2783 [git-debrebase convert-from-dgit-view upstream-import-convert: $version]
2784 END
2785                                                     ];
2786                     push @upstreams, { Commit => $ups_synth,
2787                                        Source => "orig(s) imported via dgit",
2788                                      };
2789                 }
2790             } else {
2791                 print STDERR f_
2792                     " orig: no suitable origs found (looked for %s in %s)\n",
2793                     "${p}_".(stripeoch $version)."...", $bpd;
2794             }
2795         }
2796     }
2797
2798     my $some_patches = stat_exists 'debian/patches/series';
2799
2800     print STDERR __
2801         "Evaluating possible commits corresponding to upstream:\n";
2802
2803     my $result;
2804     foreach my $u (@upstreams) {
2805         my $work = $head;
2806         fresh_workarea();
2807         in_workarea sub {
2808             runcmd @git, qw(reset --quiet), $u->{Commit}, qw(-- .);
2809             runcmd @git, qw(checkout), $u->{Commit}, qw(-- .);
2810             runcmd @git, qw(clean -xdff);
2811             runcmd @git, qw(checkout), $head, qw(-- debian);
2812             if ($some_patches) {
2813                 rm_subdir_cached 'debian/patches';
2814                 $work = make_commit [ $work ], [
2815  'git-debrebase convert-from-dgit-view: drop upstream changes from breakwater',
2816  "Drop upstream changes, and delete debian/patches, as part of converting\n".
2817  "to git-debrebase format.  Upstream changes will appear as commits.",
2818  '[git-debrebase convert-from-dgit-view drop-patches]'
2819                                            ];
2820             }
2821             $work = make_commit [ $work, $u->{Commit} ], [
2822  'git-debrebase convert-from-dgit-view: declare upstream',
2823  '(Re)constructed breakwater merge.',
2824  '[git-debrebase anchor: declare upstream]'
2825                                                          ];
2826             runcmd @git, qw(checkout --quiet -b mk), $work;
2827             if ($some_patches) {
2828                 runcmd @git, qw(checkout), $head, qw(-- debian/patches);
2829                 runcmd @git, qw(reset --quiet);
2830                 my @gbp_cmd = (qw(gbp pq import));
2831                 if (!$diagnose) {
2832                     my $gbp_err = "../gbp-pq-err";
2833                     @gbp_cmd = shell_cmd "exec >$gbp_err 2>&1", @gbp_cmd;
2834                 }
2835                 my $r = system @gbp_cmd;
2836                 if ($r) {
2837                     print STDERR f_
2838                         " %s: couldn't apply patches: gbp pq %s",
2839                         $u->{Source}, waitstatusmsg();
2840                     return;
2841                 }
2842             }
2843             my $work = git_rev_parse qw(HEAD);
2844             my $diffout = cmdoutput @git, qw(diff-tree --stat HEAD), $work;
2845             if (length $diffout) {
2846                 print STDERR f_
2847                     " %s: applying patches gives different tree\n",
2848                     $u->{Source};
2849                 print STDERR $diffout if $diagnose;
2850                 return;
2851             }
2852             # OMG!
2853             $u->{Result} = $work;
2854             $result = $u;
2855         };
2856         last if $result;
2857     }
2858
2859     if (!$result) {
2860         fail __ <<END;
2861 Could not find or construct a suitable upstream commit.
2862 Rerun adding --diagnose after convert-from-dgit-view, or pass a
2863 upstream commmit explicitly or provide suitable origs.
2864 END
2865     }
2866
2867     print STDERR f_ "Yes, will base new branch on %s\n", $result->{Source};
2868
2869     complete_convert_from $head, $result->{Result}, $gdrlastinfo,
2870         'convert-from-dgit-view';
2871 }
2872
2873 sub cmd_forget_was_ever_debrebase () {
2874     badusage __ "forget-was-ever-debrebase takes no further arguments"
2875         if @ARGV;
2876     my ($ffqstatus, $ffq_msg, $current, $ffq_prev, $gdrlast) =
2877         ffq_prev_branchinfo();
2878     fail f_ "Not suitable for recording git-debrebaseness anyway: %s",
2879             $ffq_msg
2880         if defined $ffq_msg;
2881     push @deferred_updates, "delete $ffq_prev";
2882     push @deferred_updates, "delete $gdrlast";
2883     snags_maybe_bail();
2884     run_deferred_updates "forget-was-ever-debrebase";
2885 }
2886
2887 sub cmd_record_resolved_merge () {
2888     badusage "record-resolved-merge takes no further arguments" if @ARGV;
2889     # MERGE-TODO needs documentation
2890     my $new = get_head();
2891     my $method;
2892
2893     print "Checking how you have resolved the merge problem\n";
2894     my $nope = sub { print "Not $method: @_"; 0; };
2895
2896     my $maybe = sub { print "Seems to be $method.\n"; };
2897     my $yes = sub {
2898         my ($key, $ref) = @_;
2899         reflog_cache_insert $merge_cache_ref, $key, $ref;
2900         print "OK.  You can switch branches and try git-debrebase again.\n";
2901         1;
2902     };
2903
2904     fresh_workarea 'merge';
2905     sub {
2906         $method = 'vanilla-merge patchqueue';
2907         my $vanilla = git_get_ref "$wrecknoteprefix/vanilla-merge";
2908         $vanilla or return $nope->("wreckage was not of vanilla-merge");
2909         foreach my $lr (qw(left right)) {
2910             my $n = "$wrecknoteprefix/$lr-patchqueue";
2911             my $lrpq = git_get_ref $n;
2912             $lrpq or return $nope->("wreckage did not contain patchqueues");
2913             is_fast_fwd $lrpq, $new or return $nope->("HEAD not ff of $n");
2914         }
2915         $maybe->();
2916         my $newbase = git_get_ref "$wrecknoteprefix/new-base"
2917             or die "wreckage element $wrecknoteprefix/new-base missing";
2918         my $result = merge_series_patchqueue_convert
2919             {}, $newbase, $new;
2920         $yes->("vanilla-merge $vanilla", $result);
2921         1;
2922     }->() or sub {
2923         fail "No resolved merge method seems applicable.\n";
2924     }->();
2925 }
2926
2927 sub cmd_downstream_rebase_launder_v0 () {
2928     badusage "needs 1 argument, the baseline" unless @ARGV==1;
2929     my ($base) = @ARGV;
2930     $base = git_rev_parse $base;
2931     my $old_head = get_head();
2932     my $current = $old_head;
2933     my $topmost_keep;
2934     for (;;) {
2935         if ($current eq $base) {
2936             $topmost_keep //= $current;
2937             print " $current BASE stop\n";
2938             last;
2939         }
2940         my $cl = classify $current;
2941         print " $current $cl->{Type}";
2942         my $keep = 0;
2943         my $p0 = $cl->{Parents}[0]{CommitId};
2944         my $next;
2945         if ($cl->{Type} eq 'Pseudomerge') {
2946             print " ^".($cl->{Contributor}{Ix}+1);
2947             $next = $cl->{Contributor}{CommitId};
2948         } elsif ($cl->{Type} eq 'AddPatches' or
2949                  $cl->{Type} eq 'Changelog') {
2950             print " strip";
2951             $next = $p0;
2952         } else {
2953             print " keep";
2954             $next = $p0;
2955             $keep = 1;
2956         }
2957         print "\n";
2958         if ($keep) {
2959             $topmost_keep //= $current;
2960         } else {
2961             die "to-be stripped changes not on top of the branch\n"
2962                 if $topmost_keep;
2963         }
2964         $current = $next;
2965     }
2966     if ($topmost_keep eq $old_head) {
2967         print "unchanged\n";
2968     } else {
2969         print "updating to $topmost_keep\n";
2970         update_head_checkout
2971             $old_head, $topmost_keep,
2972             'downstream-rebase-launder-v0';
2973     }
2974 }
2975
2976 setlocale(LC_MESSAGES, "");
2977 textdomain("git-debrebase");
2978
2979 getoptions_main
2980           (__ "bad options\n",
2981            "D+" => \$debuglevel,
2982            'noop-ok', => \$opt_noop_ok,
2983            'f=s' => \@snag_force_opts,
2984            'anchor=s' => \@opt_anchors,
2985            '--dgit=s' => \($dgit[0]),
2986            'force!',
2987            'experimental-merge-resolution!', \$opt_merges,
2988            '-i:s' => sub {
2989                my ($opt,$val) = @_;
2990                badusage f_ "%s: no cuddling to -i for git-rebase", $us
2991                    if length $val;
2992                confess if $opt_defaultcmd_interactive; # should not happen
2993                $opt_defaultcmd_interactive = [ qw(-i) ];
2994                # This access to @ARGV is excessive familiarity with
2995                # Getopt::Long, but there isn't another sensible
2996                # approach.  '-i=s{0,}' does not work with bundling.
2997                push @$opt_defaultcmd_interactive, @ARGV;
2998                @ARGV=();
2999            },
3000            'help' => sub { print __ $usage_message or confess "$!"; finish 0; },
3001            );
3002
3003 initdebug('git-debrebase ');
3004 enabledebug if $debuglevel;
3005
3006 changedir_git_toplevel();
3007
3008 $rd = fresh_playground "$playprefix/misc";
3009
3010 @opt_anchors = map { git_rev_parse $_ } @opt_anchors;
3011
3012 if (!@ARGV || $opt_defaultcmd_interactive || $ARGV[0] =~ m{^-}) {
3013     defaultcmd_rebase();
3014 } else {
3015     my $cmd = shift @ARGV;
3016     my $cmdfn = $cmd;
3017     $cmdfn =~ y/-/_/;
3018     $cmdfn = ${*::}{"cmd_$cmdfn"};
3019
3020     $cmdfn or badusage f_ "unknown git-debrebase sub-operation %s", $cmd;
3021     $cmdfn->();
3022 }
3023
3024 finish 0;