git-debrebase

   1 #!/usr/bin/perl -w
   2 # git-debrebase
   3 # Script helping make fast-forwarding histories while still rebasing
   4 # upstream deltas when working on Debian packaging
   5 #
   6 # Copyright (C)2017 Ian Jackson
   7 #
   8 # This program is free software: you can redistribute it and/or modify
   9 # it under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation, either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # This program is distributed in the hope that it will be useful,
  14 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20
  21 # usages:
  22 #    git-debrebase status
  23 #    git-debrebase start       # like ffqrebase start + debrebase launder
  24 #    git-debrebase new-upstream [stuff]  # see below
  25 #    git-debrebase <git-rebase options>  # does debrebase start if necessary
  26 #
  27 #    git-debrebase analyse
  28 #    git-debrebase launder     # prints breakwater tip
  29 #    git-debrebase create-new-upstream-breakwater [-f] <upstreaminfo>...
  30 #
  31 # <upstreaminfo> is
  32 #    [,][<subdir>:][+]<commitid>[,...]
  33 #
  34 # if initial comma is supplied, entries are not positional.  Unspecified
  35 # <subdir> means root (and there may be only one).
  36 # xxx want auto branch names
  37 # xxx too complicated
  38 # how about for now
  39 #    [+]<commit> [<subdir/> [+]<commit>...]
  40 # ?  plus options
  41 #     --new-upstream-different-subtrees
  42 #
  43 #  automatic case
  44 #       git-debrebase new-upstream
  45 #             - previous breakwater merge must be gdr-generated
  46 #             - orig set is the same as before
  47 #             - implicitly uses upstream branches according to orig set
  48 #             - not all upstream branches need be updated
  49 #             - insists on fast-forward of each branch, unless
  50 #                  --force (or --force=<subdir>[/])
  51 #  branch set adjustments
  52 #       git-debrebase new-upstream --add <subdir>/
  53 #       git-debrebase new-upstream --rm <subdir>/
  54 #       git-debrebase new-upstream / [<subdir>/ ...]
  55 #             - orig set is adjusted
  56 #             - otherwise like auto (--add is not checked for ffness, obv)
  57 #             - multiple --add and --rm may be specified
  58 #             - --add makes new upstream the last contributor
  59 #  explicit
  60 #       git-debrebase / [<rootcommitid>] [<subdir>/ [<commitid>] ...]
  61 #             - orig set is precisely as specified now
  62 #             - previous breakwater merge is irrelevant
  63 #             - no fast forward checks
  64 #  for now only explicit with commitids
  65
  66 #         implicitly uses `upstream'
  67 #                                     # (or multiple other branches)
  68 #       git-debrebase new-upstream \
  69 #             [<subdir>/]=<commitid>
  70
  71 #    UPSTREAM[,[[SUBDIR:]SUBUPSTREAM]
  72 #    default for SUBDIR: is from previous upstream merge[xxx terminology]
  73 #
  74 #
  75 #xxx
  76 # when starting must record original start (for ff)
  77 # and new rebase basis
  78 #
  79 #    git-ffqrebase start [BASE]
  80 #                # records previous HEAD so it can be overwritten
  81 #                # records base for future git-ffqrebase
  82 #    git-ffqrebase set-base BASE
  83 #    git-ffqrebase <git-rebase options>
  84 #    git-ffqrebase finish
  85 #    git-ffqrebase status [BRANCH]
  86 #
  87 #  refs/ffqrebase-prev/BRANCH    BRANCH may be refs/...; if not it means
  88 #  refs/ffqrebase-base/BRANCH      refs/heads/BRANCH
  89 #                               zero, one, or both of these may exist
  90 #
  91 # git-debrebase without start, if already started, is willing
  92 # to strip pseudomerges provided that they overwrite exactly
  93 # the previous HEAD
  94 #  xxxx is this right ?  what matters is have we pushed
  95 #    I think in fact the right answer is:
  96 #       git-debrebase always strips out pseudomerges from its branch
  97 #       a pseudomerge is put in at the time we want to push
  98 #       at that time, we make a pseudomerge of the remote tracking
  99 #           branch (if raw git) or the dgit view (if dgit)
 100 #       for raw git git-ffqrebase, do want preciseley to record
 101 #           value of remote tracking branch or our branch, on start, so we
 102 #           overwrite only things we intend to
 103 #  the previous pseudomerge    check for tags and remote branches ?
 104
 105 use strict;
 106
 107 use Debian::Dgit qw(:DEFAULT :playground);
 108 setup_sigwarn();
 109
 110 use Memoize;
 111 use Carp;
 112 use POSIX;
 113 use Data::Dumper;
 114 use Getopt::Long qw(:config posix_default gnu_compat bundling);
 115
 116 sub badusage ($) {
 117     my ($m) = @_;
 118     die "bad usage: $m\n";
 119 }
 120
 121 sub cfg ($) {
 122     my ($k) = @_;
 123     $/ = "\0";
 124     my @cmd = qw(git config -z);
 125     push @cmd, qw(--get-all) if wantarray;
 126     push @cmd, $k;
 127     my $out = cmdoutput @cmd;
 128     return split /\0/, $out;
 129 }
 130
 131 memoize('cfg');
 132
 133 sub get_commit ($) {
 134     my ($objid) = @_;
 135     my $data = git_cat_file $objid, 'commit';
 136     $data =~ m/(?<=\n)\n/ or die "$objid ($data) ?";
 137     return ($`,$');
 138 }
 139
 140 sub D_UPS ()      { 0x02; } # upstream files
 141 sub D_PAT_ADD ()  { 0x04; } # debian/patches/ extra patches at end
 142 sub D_PAT_OTH ()  { 0x08; } # debian/patches other changes
 143 sub D_DEB_CLOG () { 0x10; } # debian/ (not patches/ or changelog)
 144 sub D_DEB_OTH ()  { 0x20; } # debian/changelog
 145 sub DS_DEB ()     { D_DEB_CLOG | D_DEB_OTH; } # debian/ (not patches/)
 146
 147 our $playprefix = 'debrebase';
 148 our $rd;
 149 our $workarea;
 150
 151 our @git = qw(git);
 152
 153 sub in_workarea ($) {
 154     my ($sub) = @_;
 155     changedir $workarea;
 156     my $r = eval { $sub->(); };
 157     { local $@; changedir $maindir; }
 158     die $@ if $@;
 159 }
 160
 161 sub fresh_workarea () {
 162     $workarea = fresh_playground "$playprefix/work";
 163     in_workarea sub { playtree_setup };
 164 }
 165
 166 sub get_differs ($$) {
 167     my ($x,$y) = @_;
 168     # This resembles quiltify_trees_differ, in dgit, a bit.
 169     # But we don't care about modes, or dpkg-source-unrepresentable
 170     # changes, and we don't need the plethora of different modes.
 171     # Conversely we need to distinguish different kinds of changes to
 172     # debian/ and debian/patches/.
 173
 174     my $differs = 0;
 175
 176     my $rundiff = sub {
 177         my ($opts, $limits, $fn) = @_;
 178         my @cmd = (@git, qw(diff-tree -z --no-renames));
 179         push @cmd, @$opts;
 180         push @cmd, "$_:" foreach $x, $y;
 181         push @cmd, @$limits;
 182         my $diffs = cmdoutput @cmd;
 183         foreach (split /\0/, $diffs) { $fn->(); }
 184     };
 185
 186     $rundiff->([qw(--name-only)], [], sub {
 187         $differs |= $_ eq 'debian' ? DS_DEB : D_UPS;
 188     });
 189
 190     if ($differs & DS_DEB) {
 191         $differs &= ~DS_DEB;
 192         $rundiff->([qw(--name-only -r)], [qw(debian)], sub {
 193             $differs |=
 194                 m{^debian/patches/}      ? D_PAT_OTH  :
 195                 $_ eq 'debian/changelog' ? D_DEB_CLOG :
 196                                            D_DEB_OTH;
 197         });
 198         die "mysterious debian changes $x..$y"
 199             unless $differs & (D_PAT_OTH|DS_DEB);
 200     }
 201
 202     if ($differs & D_PAT_OTH) {
 203         my $mode;
 204         $differs &= ~D_PAT_OTH;
 205         my $pat_oth = sub {
 206             $differs |= D_PAT_OTH;
 207             no warnings qw(exiting);  last;
 208         };
 209         $rundiff->([qw(--name-status -r)], [qw(debian/patches/)], sub {
 210             no warnings qw(exiting);
 211             if (!defined $mode) {
 212                 $mode = $_;  next;
 213             }
 214             die unless s{^debian/patches/}{};
 215             my $ok;
 216             if ($mode eq 'A' && !m/\.series$/s) {
 217                 $ok = 1;
 218             } elsif ($mode eq 'M' && $_ eq 'series') {
 219                 my $x_s = git_cat_file "$x:debian/patches/series", 'blob';
 220                 my $y_s = git_cat_file "$y:debian/patches/series", 'blob';
 221                 chomp $x_s;  $x_s .= "\n";
 222                 $ok = $x_s eq substr($y_s, 0, length $x_s);
 223             } else {
 224                 # nope
 225             }
 226             $mode = undef;
 227             $differs |= $ok ? D_PAT_ADD : D_PAT_OTH;
 228         });
 229         die "mysterious debian/patches changes $x..$y"
 230             unless $differs & (D_PAT_ADD|D_PAT_OTH);
 231     }
 232
 233     printdebug sprintf "get_differs %s, %s = %#x\n", $x, $y, $differs;
 234
 235     return $differs;
 236 }
 237
 238 sub commit_pr_info ($) {
 239     my ($r) = @_;
 240     return Data::Dumper->dump([$r], [qw(commit)]);
 241 }
 242
 243 sub calculate_committer_authline () {
 244     my $c = cmdoutput @git, qw(commit-tree --no-gpg-sign -m),
 245         'DUMMY COMMIT (git-debrebase)', "HEAD:";
 246     my ($h,$m) = get_commit $c;
 247     $h =~ m/^committer .*$/m or confess "($h) ?";
 248     return $&;
 249 }
 250
 251 # classify returns an info hash like this
 252 #   CommitId => $objid
 253 #   Hdr => # commit headers, including 1 final newline
 254 #   Msg => # commit message (so one newline is dropped)
 255 #   Tree => $treeobjid
 256 #   Type => (see below)
 257 #   Parents = [ {
 258 #       Ix => $index # ie 0, 1, 2, ...
 259 #       CommitId
 260 #       Differs => return value from get_differs
 261 #       IsOrigin
 262 #       IsDggitImport => 'orig' 'tarball' 'unpatched' 'package' (as from dgit)
 263 #     } ...]
 264 #   NewMsg => # commit message, but with any [dgit import ...] edited
 265 #             # to say "[was: ...]"
 266 #
 267 # Types:
 268 #   Packaging
 269 #   Changelog
 270 #   Upstream
 271 #   AddPatches
 272 #   Mixed
 273 #   Unknown
 274 #
 275 #   Pseudomerge
 276 #     has additional entres in classification result
 277 #       Overwritten = [ subset of Parents ]
 278 #       Contributor = $the_remaining_Parent
 279 #
 280 #   DgitImportUnpatched
 281 #     has additional entry in classification result
 282 #       OrigParents = [ subset of Parents ]
 283 #
 284 #   BreakwaterUpstreamMerge
 285 #     has additional entry in classification result
 286 #       OrigParents = [ subset of Parents ]  # singleton list
 287
 288 sub parsecommit ($;$) {
 289     my ($objid, $p_ref) = @_;
 290     # => hash with                   CommitId Hdr Msg Tree Parents
 291     #    Parents entries have only   Ix CommitId
 292     #    $p_ref, if provided, must be [] and is used as a base for Parents
 293
 294     $p_ref //= [];
 295     die if @$p_ref;
 296
 297     my ($h,$m) = get_commit $objid;
 298
 299     my ($t) = $h =~ m/^tree (\w+)$/m or die $objid;
 300     my (@ph) = $h =~ m/^parent (\w+)$/mg;
 301
 302     my $r = {
 303         CommitId => $objid,
 304         Hdr => $h,
 305         Msg => $m,
 306         Tree => $t,
 307         Parents => $p_ref,
 308     };
 309
 310     foreach my $ph (@ph) {
 311         push @$p_ref, {
 312             Ix => $#$p_ref,
 313             CommitId => $ph,
 314         };
 315     }
 316
 317     return $r;
 318 }
 319
 320 sub classify ($) {
 321     my ($objid) = @_;
 322
 323     my @p;
 324     my $r = parsecommit($objid, \@p);
 325     my $t = $r->{Tree};
 326
 327     foreach my $p (@p) {
 328         $p->{Differs} => (get_differs $p->{CommitId}, $t),
 329     }
 330
 331     printdebug "classify $objid \$t=$t \@p",
 332         (map { sprintf " %s/%#x", $_->{CommitId}, $_->{Differs} } @p),
 333         "\n";
 334
 335     my $classify = sub {
 336         my ($type, @rest) = @_;
 337         $r = { %$r, Type => $type, @rest };
 338         if ($debuglevel) {
 339             my $dd = new Data::Dumper [ $r ];
 340             Terse $dd 1; Indent $dd 0; Useqq $dd 1;
 341             printdebug " = $type ".(Dump $dd)."\n";
 342         }
 343         return $r;
 344     };
 345     my $unknown = sub {
 346         my ($why) = @_;
 347         $r = { %$r, Type => qw(Unknown) };
 348         printdebug " ** Unknown\n";
 349         return $r;
 350     };
 351
 352     if (@p == 1) {
 353         my $d = $r->{Parents}[0]{Differs};
 354         if ($d == D_PAT_ADD) {
 355             return $classify->(qw(AddPatches));
 356         } elsif ($d & (D_PAT_ADD|D_PAT_OTH)) {
 357             return $unknown->("edits debian/patches");
 358         } elsif ($d & DS_DEB and !($d & ~DS_DEB)) {
 359             my ($ty,$dummy) = git_cat_file "$ph[0]:debian";
 360             if ($ty eq 'tree') {
 361                 if ($d == D_DEB_CLOG) {
 362                     return $classify->(qw(Changelog));
 363                 } else {
 364                     return $classify->(qw(Packaging));
 365                 }
 366             } elsif ($ty eq 'missing') {
 367                 return $classify->(qw(BreakwaterStart));
 368             } else {
 369                 return $unknown->("parent's debian is not a directory");
 370             }
 371         } elsif ($d == D_UPS) {
 372             return $classify->(qw(Upstream));
 373         } elsif ($d & DS_DEB and $d & D_UPS and !($d & ~(DS_DEB|D_UPS))) {
 374             return $classify->(qw(Mixed));
 375         } elsif ($d == 0) {
 376             return $unknown->("no changes");
 377         } else {
 378             confess "internal error $objid ?";
 379         }
 380     }
 381     if (!@p) {
 382         return $unknown->("origin commit");
 383     }
 384
 385     my @identical = grep { !$_->{Differs} } @p;
 386     if (@p == 2 && @identical == 1) {
 387         my @overwritten = grep { $_->{Differs} } @p;
 388         confess "internal error $objid ?" unless @overwritten==1;
 389         return $classify->(qw(Pseudomerge),
 390                            Overwritten => $overwritten[0],
 391                            Contributor => $identical[0]);
 392     }
 393     if (@p == 2 && @identical == 2) {
 394         my @bytime = nsort_by {
 395             my ($ph,$pm) = get_commit $_->{CommitId};
 396             $ph =~ m/^committer .* (\d+) [-+]\d+$/m or die "$_->{CommitId} ?";
 397             $1;
 398         } @p;
 399         return $classify->(qw(Pseudomerge),
 400                            SubType => qw(Ambiguous),
 401                            Overwritten => $bytime[0],
 402                            Contributor => $bytime[1]);
 403     }
 404     foreach my $p (@p) {
 405         my ($p_h, $p_m) = get_commit $p->{CommitId};
 406         $p->{IsOrigin} = $p_h !~ m/^parent \w+$/m;
 407         ($p->{IsDgitImport},) = $p_m =~ m/^\[dgit import ([0-9a-z]+) .*\]$/m;
 408     }
 409     my @orig_ps = grep { ($_->{IsDgitImport}//'X') eq 'orig' } @p;
 410     my $m2 = $r->{Msg};
 411     if (!(grep { !$_->{IsOrigin} } @p) and
 412         (@orig_ps >= @p - 1) and
 413         $m2 =~ s{^\[(dgit import unpatched .*)\]$}{[was: $1]}m) {
 414         $r->{NewMsg} = $m2;
 415         return $classify->(qw(DgitImportUnpatched),
 416                            OrigParents => \@orig_ps);
 417     }
 418
 419     my ($stype, $series) = git_cat_file "$t:debian/patches/series";
 420     my $haspatches = $stype ne 'missing' && $series =~ m/^\s*[^#\n\t ]/m;
 421
 422     # How to decide about l/r ordering of breakwater merges ?  git
 423     # --topo-order prefers to expand 2nd parent first.  There's
 424     # already an easy rune to look for debian/ history anyway (git log
 425     # debian/) so debian breakwater branch should be 1st parent; that
 426     # way also there's also an easy rune to look for the upstream
 427     # patches (--topo-order).
 428
 429     # The above tells us which way *we* will generate them.  But we
 430     # might encounter ad-hoc breakwater merges generated manually,
 431     # which might be the other way around.  In principle, in some odd
 432     # situations, a breakwater merge might have two identical parents.
 433     # In that case we guess which way round it is (ie, which parent
 434     # has the upstream history).  The order of the 2-iteration loop
 435     # controls which guess we make.
 436
 437     foreach my $prevbrw (qw(0 1)) {
 438         if (@p == 2 &&
 439             !$haspatches &&
 440             !$p[$prevbrw]{IsOrigin} && # breakwater never starts with an origin
 441             !($p[$prevbrw]{Differs} & ~DS_DEB) &&
 442             !($p[!$prevbrw]{Differs} & ~D_UPS)) {
 443             return $classify->(qw(BreakwaterUpstreamMerge),
 444                                OrigParents => [ $p[!$prevbrw] ]);
 445         }
 446         # xxx multi-.orig upstreams
 447     }
 448
 449     return $unknown->("complex merge");
 450 }
 451
 452 sub walk ($;$$);
 453 sub walk ($;$$) {
 454     my ($input,
 455         $nogenerate,$report) = @_;
 456     # => ($tip, $breakwater_tip)
 457     # (or nothing, if $nogenerate)
 458
 459     # go through commits backwards
 460     # we generate two lists of commits to apply:
 461     # breakwater branch and upstream patches
 462     my (@brw_cl, @upp_cl, @processed);
 463     my %found;
 464     my $upp_limit;
 465     my @pseudomerges;
 466
 467     my $cl;
 468     my $xmsg = sub {
 469         my ($appendinfo) = @_;
 470         my $ms = $cl->{Msg};
 471         chomp $ms;
 472         $ms .= "\n\n[git-debrebase $appendinfo]\n";
 473         return (Msg => $ms);
 474     };
 475     my $rewrite_from_here = sub {
 476         my $sp_cl = { SpecialMethod => 'StartRewrite' };
 477         push @brw_cl, $sp_cl;
 478         push @processed, $sp_cl;
 479     };
 480     my $cur = $input;
 481
 482     my $prdelim = "";
 483     my $prprdelim = sub { print $report $prdelim if $report; $prdelim=""; };
 484
 485     my $prline = sub {
 486         return unless $report;
 487         print $report $prdelim, @_;
 488         $prdelim = "\n";
 489     };
 490
 491     my $bomb = sub { # usage: return $bomb->();
 492         print $report " Unprocessable" if $report;
 493         $prprdelim->();
 494         if ($nogenerate) {
 495             return (undef,undef);
 496         }
 497         die "commit $cur: Cannot cope with this commit (d.".
 498             (join ' ', map { sprintf "%#x", $_->{Differs} }
 499              @{ $cl->{Parents} }). ")";
 500     };
 501
 502     my $build;
 503     my $breakwater;
 504
 505     my $build_start = sub {
 506         my ($msg, $parent) = @_;
 507         $prline->(" $msg");
 508         $build = $parent;
 509         no warnings qw(exiting); last;
 510     };
 511
 512     for (;;) {
 513         $cl = classify $cur;
 514         my $ty = $cl->{Type};
 515         my $st = $cl->{SubType};
 516         $prline->("$cl->{CommitId} $cl->{Type}");
 517         $found{$ty. ( defined($st) ? "-$st" : '' )}++;
 518         push @processed, $cl;
 519         my $p0 = @{ $cl->{Parents} }==1 ? $cl->{Parents}[0]{CommitId} : undef;
 520         if ($ty eq 'AddPatches') {
 521             $cur = $p0;
 522             $rewrite_from_here->();
 523             next;
 524         } elsif ($ty eq 'Packaging' or $ty eq 'Changelog') {
 525             push @brw_cl, $cl;
 526             $cur = $p0;
 527             next;
 528         } elsif ($ty eq 'BreakwaterStart') {
 529             $build_start->('FirstPackaging', $cur);
 530         } elsif ($ty eq 'Upstream') {
 531             push @upp_cl, $cl;
 532             $cur = $p0;
 533             next;
 534         } elsif ($ty eq 'Mixed') {
 535             my $queue = sub {
 536                 my ($q, $wh) = @_;
 537                 my $cls = { %$cl, $xmsg->("split mixed commit: $wh part") };
 538                 push @$q, $cls;
 539             };
 540             $queue->(\@brw_cl, "debian");
 541             $queue->(\@upp_cl, "upstream");
 542             $rewrite_from_here->();
 543             $cur = $p0;
 544             next;
 545         } elsif ($ty eq 'Pseudomerge') {
 546             my $contrib = $cl->{Contributor}{CommitId};
 547             print $report " Contributor=$contrib" if $report;
 548             push @pseudomerges, $cl;
 549             $rewrite_from_here->();
 550             $cur = $contrib;
 551             next;
 552         } elsif ($ty eq 'BreakwaterUpstreamMerge') {
 553             $build_start->("PreviousBreakwater", $cur);
 554         } elsif ($ty eq 'DgitImportUnpatched') {
 555             my $pm = $pseudomerges[-1];
 556             if (defined $pm) {
 557                 # To an extent, this is heuristic.  Imports don't have
 558                 # a useful history of the debian/ branch.  We assume
 559                 # that the first pseudomerge after an import has a
 560                 # useful history of debian/, and ignore the histories
 561                 # from later pseudomerges.  Often the first pseudomerge
 562                 # will be the dgit import of the upload to the actual
 563                 # suite intended by the non-dgit NMUer, and later
 564                 # pseudomerges may represent in-archive copies.
 565                 my $ovwrs = $pm->{Overwritten};
 566                 printf $report " PM=%s \@Overwr:%d", $pm, (scalar @$ovwrs)
 567                     if $report;
 568                 if (@$ovwrs != 1) {
 569                     return $bomb->();
 570                 }
 571                 my $ovwr = $ovwrs->[0]{CommitId};
 572                 printf $report " Overwr=%s", $ovwr if $report;
 573                 # This import has a tree which is just like a
 574                 # breakwater tree, but it has the wrong history.  It
 575                 # ought to have the previous breakwater (which the
 576                 # pseudomerge overwrote) as an ancestor.  That will
 577                 # make the history of the debian/ files correct.  As
 578                 # for the upstream version: either it's the same as
 579                 # was ovewritten (ie, same as the previous
 580                 # breakwater), in which case that history is precisely
 581                 # right; or, otherwise, it was a non-gitish upload of a
 582                 # new upstream version.  We can tell these apart by
 583                 # looking at the tree of the supposed upstream.
 584                 push @brw_cl, {
 585                     %$cl,
 586                     SpecialMethod => 'DgitImportDebianUpdate',
 587                     $xmsg->("convert dgit import: debian changes")
 588                 };
 589                 my $differs = (get_differs $ovwr, $cl->{Tree});
 590                 printf $report " Differs=%#x", $differs if $report;
 591                 if ($differs & D_UPS) {
 592                     printf $report " D_UPS" if $report;
 593                     # This will also trigger if a non-dgit git-based NMU
 594                     # deleted .gitignore (which is a thing that some of
 595                     # the existing git tools do if the user doesn't
 596                     # somehow tell them not to).  Ah well.
 597                     push @brw_cl, {
 598                         %$cl,
 599                         SpecialMethod => 'DgitImportUpstreamUpdate',
 600                         $xmsg->("convert dgit import: upstream changes")
 601                     };
 602                 }
 603                 $prline->(" Import");
 604                 $rewrite_from_here->();
 605                 $upp_limit //= $#upp_cl; # further, deeper, patches discarded
 606                 $cur = $ovwr;
 607                 next;
 608             } else {
 609                 # Everything is from this import.  This kind of import
 610                 # is already in valid breakwater format, with the
 611                 # patches as commits.
 612                 printf $report " NoPM" if $report;
 613                 # last thing we processed will have been the first patch,
 614                 # if there is one; which is fine, so no need to rewrite
 615                 # on account of this import
 616                 $build_start->("ImportOrigin", $cur);
 617             }
 618             die "$ty ?";
 619         } else {
 620             return $bomb->();
 621         }
 622     }
 623     $prprdelim->();
 624     return if $nogenerate;
 625
 626     # Now we build it back up again
 627
 628     fresh_workarea();
 629
 630     my $rewriting = 0;
 631
 632     my $rm_tree_cached = sub {
 633         my ($subdir) = @_;
 634         runcmd @git, qw(rm --quiet -rf --cached --ignore-unmatch), $subdir;
 635     };
 636     my $read_tree_debian = sub {
 637         my ($treeish) = @_;
 638         $rm_tree_cached->(qw(debian));
 639         runcmd @git, qw(read-tree --prefix=debian/), "$treeish:debian";
 640     };
 641     my $read_tree_upstream = sub {
 642         my ($treeish) = @_;
 643         runcmd @git, qw(read-tree), $treeish;
 644         $read_tree_debian->($build);
 645     };
 646
 647     my $committer_authline = calculate_committer_authline();
 648
 649     printdebug "WALK REBUILD $build ".(scalar @processed)."\n";
 650
 651     confess "internal error" unless $build eq (pop @processed)->{CommitId};
 652
 653     in_workarea sub {
 654         mkdir $rd or $!==EEXIST or die $!;
 655         my $current_method;
 656         runcmd @git, qw(read-tree), $build;
 657         foreach my $cl (qw(Debian), (reverse @brw_cl),
 658                         { SpecialMethod => 'RecordBreakwaterTip' },
 659                         qw(Upstream), (reverse @upp_cl)) {
 660             if (!ref $cl) {
 661                 $current_method = $cl;
 662                 next;
 663             }
 664             my $method = $cl->{SpecialMethod} // $current_method;
 665             my @parents = ($build);
 666             my $cltree = $cl->{CommitId};
 667             printdebug "WALK BUILD ".($cltree//'undef').
 668                 " $method (rewriting=$rewriting)\n";
 669             if ($method eq 'Debian') {
 670                 $read_tree_debian->($cltree);
 671             } elsif ($method eq 'Upstream') {
 672                 $read_tree_upstream->($cltree);
 673             } elsif ($method eq 'StartRewrite') {
 674                 $rewriting = 1;
 675                 next;
 676             } elsif ($method eq 'RecordBreakwaterTip') {
 677                 $breakwater = $build;
 678                 next;
 679             } elsif ($method eq 'DgitImportDebianUpdate') {
 680                 $read_tree_debian->($cltree);
 681                 $rm_tree_cached->(qw(debian/patches));
 682             } elsif ($method eq 'DgitImportUpstreamUpdate') {
 683                 $read_tree_upstream->($cltree);
 684                 push @parents, map { $_->{CommitId} } @{ $cl->{OrigParents} };
 685             } else {
 686                 confess "$method ?";
 687             }
 688             if (!$rewriting) {
 689                 my $procd = (pop @processed) // 'UNDEF';
 690                 if ($cl ne $procd) {
 691                     $rewriting = 1;
 692                     printdebug "WALK REWRITING NOW cl=$cl procd=$procd\n";
 693                 }
 694             }
 695             my $newtree = cmdoutput @git, qw(write-tree);
 696             my $ch = $cl->{Hdr};
 697             $ch =~ s{^tree .*}{tree $newtree}m or confess "$ch ?";
 698             $ch =~ s{^parent .*\n}{}m;
 699             $ch =~ s{(?=^author)}{
 700                 join '', map { "parent $_\n" } @parents
 701             }me or confess "$ch ?";
 702             if ($rewriting) {
 703                 $ch =~ s{^committer .*$}{$committer_authline}m
 704                     or confess "$ch ?";
 705             }
 706             my $cf = "$rd/m$rewriting";
 707             open CD, ">", $cf or die $!;
 708             print CD $ch, "\n", $cl->{Msg} or die $!;
 709             close CD or die $!;
 710             my @cmd = (@git, qw(hash-object));
 711             push @cmd, qw(-w) if $rewriting;
 712             push @cmd, qw(-t commit), $cf;
 713             my $newcommit = cmdoutput @cmd;
 714             confess "$ch ?" unless $rewriting or $newcommit eq $cl->{CommitId};
 715             $build = $newcommit;
 716         }
 717     };
 718
 719     my $final_check = get_differs $build, $input;
 720     die sprintf "internal error %#x %s %s", $final_check, $build, $input
 721         if $final_check & ~D_PAT_ADD;
 722
 723     return ($build, $breakwater);
 724 }
 725
 726 sub get_head () { return git_rev_parse qw(HEAD); }
 727
 728 sub update_head ($$$) {
 729     my ($old, $new, $mrest) = @_;
 730     runcmd @git, qw(update-ref -m), "debrebase: $mrest", 'HEAD', $new, $old;
 731 }
 732
 733 sub update_head_checkout ($$$) {
 734     my ($old, $new, $mrest) = @_;
 735     my $symref = git_get_symref();
 736     runcmd @git, qw(checkout), $new, qw(.);
 737     update_head $old, $new, $mrest;
 738 }
 739
 740 sub cmd_launder () {
 741     badusage "no arguments to launder allowed" if @ARGV;
 742     my $old = get_head();
 743     my ($tip,$breakwater) = walk $old;
 744     update_head $old, $tip, 'launder';
 745     # no tree changes except debian/patches
 746     runcmd @git, qw(rm --quiet --ignore-unmatch -rf debian/patches);
 747     printf "# breakwater tip\n%s\n", $breakwater;
 748     printf "# working tip\n%s\n", $tip;
 749 }
 750
 751 sub cmd_analyse () {
 752     die if ($ARGV[0]//'') =~ m/^-/;
 753     badusage "too many arguments to analyse" if @ARGV>1;
 754     my ($old) = @ARGV;
 755     if (defined $old) {
 756         $old = git_rev_parse $old;
 757     } else {
 758         $old = get_head();
 759     }
 760     my ($dummy,$breakwater) = walk $old, 1,*STDOUT;
 761     STDOUT->error and die $!;
 762 }
 763
 764 sub cmd_downstream_rebase_launder_v0 () {
 765     badusage "needs 1 argument, the baseline" unless @ARGV==1;
 766     my ($base) = @ARGV;
 767     $base = git_rev_parse $base;
 768     my $old_head = get_head();
 769     my $current = $old_head;
 770     my $topmost_keep;
 771     for (;;) {
 772         if ($current eq $base) {
 773             $topmost_keep //= $current;
 774             print " $current BASE stop\n";
 775             last;
 776         }
 777         my $cl = classify $current;
 778         print " $current $cl->{Type}";
 779         my $keep = 0;
 780         my $p0 = $cl->{Parents}[0]{CommitId};
 781         my $next;
 782         if ($cl->{Type} eq 'Pseudomerge') {
 783             print " ^".($cl->{Contributor}{Ix}+1);
 784             $next = $cl->{Contributor}{CommitId};
 785         } elsif ($cl->{Type} eq 'AddPatches' or
 786                  $cl->{Type} eq 'Changelog') {
 787             print " strip";
 788             $next = $p0;
 789         } else {
 790             print " keep";
 791             $next = $p0;
 792             $keep = 1;
 793         }
 794         print "\n";
 795         if ($keep) {
 796             $topmost_keep //= $current;
 797         } else {
 798             die "to-be stripped changes not on top of the branch\n"
 799                 if $topmost_keep;
 800         }
 801         $current = $next;
 802     }
 803     if ($topmost_keep eq $old_head) {
 804         print "unchanged\n";
 805     } else {
 806         print "updating to $topmost_keep\n";
 807         update_head_checkout
 808             $old_head, $topmost_keep,
 809             'downstream-rebase-launder-v0';
 810     }
 811 }
 812
 813 GetOptions("D+" => \$debuglevel) or die badusage "bad options\n";
 814 initdebug('git-debrebase ');
 815 enabledebug if $debuglevel;
 816
 817 my $toplevel = cmdoutput @git, qw(rev-parse --show-toplevel);
 818 chdir $toplevel or die "chdir $toplevel: $!";
 819
 820 $rd = fresh_playground "$playprefix/misc";
 821
 822 my $cmd = shift @ARGV;
 823 my $cmdfn = $cmd;
 824 $cmdfn =~ y/-/_/;
 825 $cmdfn = ${*::}{"cmd_$cmdfn"};
 826
 827 $cmdfn or badusage "unknown git-debrebase sub-operation $cmd";
 828 $cmdfn->();