git-debrebase

   1 #!/usr/bin/perl -w
   2 # git-debrebase
   3 # Script helping make fast-forwarding histories while still rebasing
   4 # upstream deltas when working on Debian packaging
   5 #
   6 # Copyright (C)2017,2018 Ian Jackson
   7 #
   8 # This program is free software: you can redistribute it and/or modify
   9 # it under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation, either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # This program is distributed in the hope that it will be useful,
  14 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20
  21 END { $? = $Debian::Dgit::ExitStatus::desired // -1; };
  22 use Debian::Dgit::GDR;
  23 use Debian::Dgit::ExitStatus;
  24 use Debian::Dgit::I18n;
  25
  26 use strict;
  27
  28 use Debian::Dgit qw(:DEFAULT :playground);
  29 setup_sigwarn();
  30
  31 use Memoize;
  32 use Carp;
  33 use POSIX;
  34 use Locale::gettext;
  35 use Data::Dumper;
  36 use Getopt::Long qw(:config posix_default gnu_compat bundling);
  37 use Dpkg::Version;
  38 use File::FnMatch qw(:fnmatch);
  39 use File::Copy;
  40
  41 $debugcmd_when_debuglevel = 2;
  42
  43 our ($usage_message) = i_ <<'END';
  44 usages:
  45   git-debrebase [<options>] [--|-i <git rebase options...>]
  46   git-debrebase [<options>] status
  47   git-debrebase [<options>] prepush [--prose=...]
  48   git-debrebase [<options>] quick|conclude
  49   git-debrebase [<options>] new-upstream <new-version> [<details ...>]
  50   git-debrebase [<options>] convert-from-gbp [<upstream-commitish>]
  51   ...
  52 See git-debrebase(1), git-debrebase(5), dgit-maint-debrebase(7) (in dgit).
  53 END
  54
  55 our ($opt_force, $opt_noop_ok, $opt_merges, @opt_anchors);
  56 our ($opt_defaultcmd_interactive);
  57
  58 our $us = qw(git-debrebase);
  59
  60 our $wrecknoteprefix = 'refs/debrebase/wreckage';
  61 our $merge_cache_ref = 'refs/debrebase/merge-resolutions';
  62
  63 $|=1;
  64
  65 sub badusage ($) {
  66     my ($m) = @_;
  67     print STDERR f_ "%s: bad usage: %s\n", $us, $m;
  68     finish 8;
  69 }
  70
  71 sub getoptions_main {
  72     my $m = shift;
  73     local $SIG{__WARN__}; # GetOptions calls `warn' to print messages
  74     GetOptions @_ or badusage $m;
  75 }
  76 sub getoptions {
  77     my $sc = shift;
  78     getoptions_main +(f_ "bad options follow \`git-debrebase %s'", $sc), @_;
  79 }
  80
  81 sub cfg ($;$) {
  82     my ($k, $optional) = @_;
  83     local $/ = "\0";
  84     my @cmd = qw(git config -z);
  85     push @cmd, qw(--get-all) if wantarray;
  86     push @cmd, $k;
  87     my $out = cmdoutput_errok @cmd;
  88     if (!defined $out) {
  89         fail f_ "missing required git config %s", $k unless $optional;
  90         return ();
  91     }
  92     my @l = split /\0/, $out;
  93     return wantarray ? @l : $l[0];
  94 }
  95
  96 memoize('cfg');
  97
  98 sub dd ($) {
  99     my ($v) = @_;
 100     my $dd = new Data::Dumper [ $v ];
 101     Terse $dd 1; Indent $dd 0; Useqq $dd 1;
 102     return Dump $dd;
 103 }
 104
 105 sub get_commit ($) {
 106     my ($objid) = @_;
 107     my $data = (git_cat_file $objid, 'commit');
 108     $data =~ m/(?<=\n)\n/ or confess "$objid ($data) ?";
 109     return ($`,$');
 110 }
 111
 112 sub D_UPS ()      { 0x02; } # upstream files
 113 sub D_PAT_ADD ()  { 0x04; } # debian/patches/ extra patches at end
 114 sub D_PAT_OTH ()  { 0x08; } # debian/patches other changes
 115 sub D_DEB_CLOG () { 0x10; } # debian/changelog
 116 sub D_DEB_OTH ()  { 0x20; } # debian/ (not patches/ or changelog)
 117 sub DS_DEB ()     { D_DEB_CLOG | D_DEB_OTH; } # debian/ (not patches/)
 118
 119 our $playprefix = 'debrebase';
 120 our $rd;
 121 our $workarea;
 122
 123 our @git = qw(git);
 124 our @dgit = qw(dgit);
 125
 126 sub in_workarea ($) {
 127     my ($sub) = @_;
 128     changedir $workarea;
 129     my $r = eval { $sub->(); };
 130     { local $@; changedir $maindir; }
 131     die $@ if $@;
 132 }
 133
 134 sub fresh_workarea (;$) {
 135     my ($subdir) = @_;
 136     $subdir //= 'work';
 137     $workarea = fresh_playground "$playprefix/$subdir";
 138     in_workarea sub { playtree_setup };
 139 }
 140
 141 sub run_ref_updates_now ($$) {
 142     my ($mrest, $updates) = @_;
 143     # @$updates is a list of lines for git-update-ref, without \ns
 144
 145     my @upd_cmd = (git_update_ref_cmd "debrebase: $mrest", qw(--stdin));
 146     debugcmd '>|', @upd_cmd;
 147     open U, "|-", @upd_cmd or confess $!;
 148     foreach (@$updates) {
 149         printdebug ">= ", $_, "\n";
 150         print U $_, "\n" or confess $!;
 151     }
 152     printdebug ">\$\n";
 153     close U or failedcmd @upd_cmd;
 154 }
 155
 156 our $snags_forced = 0;
 157 our $snags_tripped = 0;
 158 our $snags_summarised = 0;
 159 our @deferred_updates;
 160 our @deferred_update_messages;
 161
 162 sub merge_wreckage_cleaning ($) {
 163     my ($updates) = @_;
 164     git_for_each_ref("$wrecknoteprefix/*", sub {
 165         my ($objid,$objtype,$fullrefname,$reftail) = @_;
 166         push @$updates, "delete $fullrefname";
 167     });
 168 }
 169
 170 sub all_snags_summarised () {
 171     $snags_forced + $snags_tripped == $snags_summarised;
 172 }
 173 sub run_deferred_updates ($) {
 174     my ($mrest) = @_;
 175
 176     my $m = 'dangerous internal error';
 177     confess $m.' - '.__ $m unless all_snags_summarised();
 178
 179     merge_wreckage_cleaning \@deferred_updates;
 180     run_ref_updates_now $mrest, \@deferred_updates;
 181     print $_, "\n" foreach @deferred_update_messages;
 182
 183     @deferred_updates = ();
 184     @deferred_update_messages = ();
 185 }
 186
 187 sub get_tree ($;$$) {
 188     # tree object name => ([ $name, $info ], ...)
 189     # where $name is the sort key, ie has / at end for subtrees
 190     # $info is the LHS from git-ls-tree (<mode> <type> <hash>)
 191     # without $precheck, will crash if $x does not exist, so don't do that;
 192     # instead pass '' to get ().
 193     my ($x, $precheck, $recurse) = @_;
 194
 195     return () if !length $x;
 196
 197     if ($precheck) {
 198         my ($type, $dummy) = git_cat_file $x, [qw(tree missing)];
 199         return () if $type eq 'missing';
 200     }
 201
 202     $recurse = !!$recurse;
 203
 204     confess "get_tree needs object not $x ?" unless $x =~ m{^[0-9a-f]+\:};
 205
 206     our (@get_tree_memo, %get_tree_memo);
 207     my $memo = $get_tree_memo{$recurse,$x};
 208     return @$memo if $memo;
 209
 210     local $Debian::Dgit::debugcmd_when_debuglevel = 3;
 211     my @l;
 212     my @cmd = (qw(git ls-tree -z --full-tree));
 213     push @cmd, qw(-r) if $recurse;
 214     push @cmd, qw(--), $x;
 215     my $o = cmdoutput @cmd;
 216     $o =~ s/\0$//s;
 217     my $last = '';
 218     foreach my $l (split /\0/, $o) {
 219         my ($i, $n) = split /\t/, $l, 2;
 220         $n .= '/' if $i =~ m/^\d+ tree /;
 221         push @l, [ $n, $i ];
 222         confess "$x need $last < $n ?" unless $last lt $n;
 223     }
 224     $get_tree_memo{$recurse,$x} = \@l;
 225     push @get_tree_memo, $x;
 226     if (@get_tree_memo > 10) {
 227         delete $get_tree_memo{ shift @get_tree_memo };
 228     }
 229     return @l;
 230 }
 231
 232 sub trees_diff_walk ($$$;$) {
 233     # trees_diff_walk [{..opts...},] $x, $y, sub {... }
 234     # calls sub->($name, $ix, $iy) for each difference
 235     # $x and $y are as for get_tree
 236     # where $name, $ix, $iy are $name and $info from get_tree
 237     # opts are   all       call even for names same in both
 238     #            recurse   call even for names same in both
 239     my $opts = shift @_ if @_>=4;
 240     my ($x,$y,$call) = @_;
 241     my $all = $opts->{all};
 242     return if !$all and $x eq $y;
 243     my @x = get_tree $x, 0, $opts->{recurse};
 244     my @y = get_tree $y, 0, $opts->{recurse};
 245     printdebug "trees_diff_walk(..$x,$y..) ".Dumper(\@x,\@y)
 246         if $debuglevel >= 3;
 247     while (@x || @y) {
 248         my $cmp = !@x       <=> !@y          # eg @y empty? $cmp=-1, use x
 249              ||    $x[0][0] cmp  $y[0][0];   # eg, x lt y ? $cmp=-1, use x
 250         my ($n, $ix, $iy);                   # all same? $cmp=0, use both
 251         $ix=$iy='';
 252         printdebug "trees_diff_walk $cmp : @{ $x[0]//[] } | @{ $y[0]//[] }\n"
 253             if $debuglevel >= 3;
 254         ($n, $ix) = @{ shift @x } if $cmp <= 0;
 255         ($n, $iy) = @{ shift @y } if $cmp >= 0;
 256         next if !$all and $ix eq $iy;
 257         printdebug sprintf
 258             "trees_diff_walk(%d,'%s','%s') call('%s','%s','%s')\n",
 259             !!$all,$x,$y, $n,$ix,$iy
 260             if $debuglevel >= 2;
 261         $call->($n, $ix, $iy);
 262     }
 263 }
 264
 265 sub get_differs ($$) {
 266     my ($x,$y) = @_;
 267     # This does a similar job to quiltify_trees_differ, in dgit, a bit.
 268     # But we don't care about modes, or dpkg-source-unrepresentable
 269     # changes, and we don't need the plethora of different modes.
 270     # Conversely we need to distinguish different kinds of changes to
 271     # debian/ and debian/patches/.
 272     # Also, here we have, and want to use, trees_diff_walk, because
 273     # we may be calling this an awful lot and we want it to be fast.
 274
 275     my $differs = 0;
 276     my @debian_info;
 277
 278     no warnings qw(exiting);
 279
 280     my $plain = sub { $_[0] =~ m{^(100|0*)644 blob }s; };
 281
 282     trees_diff_walk "$x:", "$y:", sub {
 283         my ($n,$ix,$iy) = @_;
 284
 285         # analyse difference at the toplevel
 286
 287         if ($n ne 'debian/') {
 288             $differs |= D_UPS;
 289             next;
 290         }
 291         if ($n eq 'debian') {
 292             # one side has a non-tree for ./debian !
 293             $differs |= D_DEB_OTH;
 294             next;
 295         }
 296
 297         my $xd = $ix && "$x:debian";
 298         my $yd = $iy && "$y:debian";
 299         trees_diff_walk $xd, $yd, sub {
 300             my ($n,$ix,$iy) = @_;
 301
 302             # analyse difference in debian/
 303
 304             if ($n eq 'changelog' && (!$ix || $plain->($ix))
 305                                   &&          $plain->($iy) ) {
 306                 $differs |= D_DEB_CLOG;
 307                 next;
 308             }
 309             if ($n ne 'patches/') {
 310                 $differs |= D_DEB_OTH;
 311                 next;
 312             }
 313
 314             my $xp = $ix && "$xd/patches";
 315             my $yp = $iy && "$yd/patches";
 316             trees_diff_walk { recurse=>1 }, $xp, $yp, sub {
 317                 my ($n,$ix,$iy) = @_;
 318
 319                 # analyse difference in debian/patches
 320
 321                 my $ok;
 322                 if ($n =~ m{/$}s) {
 323                     # we are recursing; directories may appear and disappear
 324                     $ok = 1;
 325                 } elsif ($n !~ m/\.series$/s && !$ix && $plain->($iy)) {
 326                     $ok = 1;
 327                 } elsif ($n eq 'series' && $plain->($ix) && $plain->($iy)) {
 328                     my $x_s = (git_cat_file "$xp/series", 'blob');
 329                     my $y_s = (git_cat_file "$yp/series", 'blob');
 330                     chomp $x_s;  $x_s .= "\n";
 331                     $ok = $x_s eq substr($y_s, 0, length $x_s);
 332                 } else {
 333                     # nope
 334                 }
 335                 $differs |= $ok ? D_PAT_ADD : D_PAT_OTH;
 336             };
 337         };
 338     };
 339
 340     printdebug sprintf "get_differs %s %s = %#x\n", $x, $y, $differs;
 341
 342     return $differs;
 343 }
 344
 345 sub commit_pr_info ($) {
 346     my ($r) = @_;
 347     return Data::Dumper->dump([$r], [qw(commit)]);
 348 }
 349
 350 sub calculate_committer_authline () {
 351     my $c = cmdoutput @git, qw(commit-tree --no-gpg-sign -m),
 352         'DUMMY COMMIT (git-debrebase)', "HEAD:";
 353     my ($h,$m) = get_commit $c;
 354     $h =~ m/^committer .*$/m or confess "($h) ?";
 355     return $&;
 356 }
 357
 358 sub rm_subdir_cached ($) {
 359     my ($subdir) = @_;
 360     runcmd @git, qw(rm --quiet -rf --cached --ignore-unmatch), $subdir;
 361 }
 362
 363 sub read_tree_subdir ($$) {
 364     my ($subdir, $new_tree_object) = @_;
 365     rm_subdir_cached $subdir;
 366     runcmd @git, qw(read-tree), "--prefix=$subdir/", $new_tree_object;
 367 }
 368
 369 sub read_tree_debian ($) {
 370     my ($treeish) = @_;
 371     read_tree_subdir 'debian', "$treeish:debian";
 372     rm_subdir_cached 'debian/patches';
 373 }
 374
 375 sub read_tree_upstream ($;$$) {
 376     my ($treeish, $keep_patches, $tree_with_debian) = @_;
 377     # if $tree_with_debian is supplied, will use that for debian/
 378     # otherwise will save and restore it.
 379     my $debian =
 380         $tree_with_debian ? "$tree_with_debian:debian"
 381         : cmdoutput @git, qw(write-tree --prefix=debian/);
 382     runcmd @git, qw(read-tree), $treeish;
 383     read_tree_subdir 'debian', $debian;
 384     rm_subdir_cached 'debian/patches' unless $keep_patches;
 385 };
 386
 387 sub make_commit ($$) {
 388     my ($parents, $message_paras) = @_;
 389     my $tree = cmdoutput @git, qw(write-tree);
 390     my @cmd = (@git, qw(commit-tree), $tree);
 391     push @cmd, qw(-p), $_ foreach @$parents;
 392     push @cmd, qw(-m), $_ foreach @$message_paras;
 393     return cmdoutput @cmd;
 394 }
 395
 396 our @snag_force_opts;
 397 sub snag ($$;@) {
 398     my ($tag,$msg) = @_; # ignores extra args, for benefit of keycommits
 399     if (grep { $_ eq $tag } @snag_force_opts) {
 400         $snags_forced++;
 401         print STDERR f_ "%s: snag ignored (-f%s): %s\n", $us, $tag, $msg;
 402     } else {
 403         $snags_tripped++;
 404         print STDERR f_ "%s: snag detected (-f%s): %s\n", $us, $tag, $msg;
 405     }
 406 }
 407
 408 # Important: all mainline code must call snags_maybe_bail after
 409 # any point where snag might be called, but before making changes
 410 # (eg before any call to run_deferred_updates).  snags_maybe_bail
 411 # may be called more than once if necessary (but this is not ideal
 412 # because then the messages about number of snags may be confusing).
 413 sub snags_maybe_bail () {
 414     return if all_snags_summarised();
 415     if ($snags_forced) {
 416         print STDERR f_
 417             "%s: snags: %d overriden by individual -f options\n",
 418             $us, $snags_forced;
 419     }
 420     if ($snags_tripped) {
 421         if ($opt_force) {
 422             print STDERR f_
 423                 "%s: snags: %d overriden by global --force\n",
 424                 $us, $snags_tripped;
 425         } else {
 426             fail f_
 427   "%s: snags: %d blocker(s) (you could -f<tag>, or --force)",
 428                 $us, $snags_tripped;
 429         }
 430     }
 431     $snags_summarised = $snags_forced + $snags_tripped;
 432 }
 433 sub snags_maybe_bail_early () {
 434     # useful to bail out early without doing a lot of work;
 435     # not a substitute for snags_maybe_bail.
 436     snags_maybe_bail() if $snags_tripped && !$opt_force;
 437 }
 438 sub any_snags () {
 439     return $snags_forced || $snags_tripped;
 440 }
 441
 442 sub ffq_prev_branchinfo () {
 443     my $current = git_get_symref();
 444     return gdr_ffq_prev_branchinfo($current);
 445 }
 446
 447 sub record_gdrlast ($$;$) {
 448     my ($gdrlast, $newvalue, $oldvalue) = @_;
 449     $oldvalue ||= $git_null_obj;
 450     push @deferred_updates, "update $gdrlast $newvalue $oldvalue";
 451 }
 452
 453 sub fail_unprocessable ($) {
 454     my ($msg) = @_;
 455     changedir $maindir;
 456     my ($ffqs, $ffqm, $symref, $ffq_prev, $gdrlast) = ffq_prev_branchinfo();
 457
 458     my $mangled = __ <<END;
 459 Branch/history seems mangled - no longer in gdr format.
 460 See ILLEGAL OPERATIONS in git-debrebase(5).
 461 END
 462     chomp $mangled;
 463
 464     if (defined $ffqm) {
 465         fail f_ <<END, $msg, $ffqm;
 466 %s
 467 Is this meant to be a gdr branch?  %s
 468 END
 469     } elsif (git_get_ref $ffq_prev) {
 470         fail f_ <<END, $msg, $mangled;
 471 %s
 472 %s
 473 Consider git-debrebase scrap, to throw away your recent work.
 474 END
 475     } elsif (!git_get_ref $gdrlast) {
 476         fail f_ <<END, $msg;
 477 %s
 478 Branch does not seem to be meant to be a git-debrebase branch?
 479 Wrong branch, or maybe you needed git-debrebase convert-from-*.
 480 END
 481     } elsif (is_fast_fwd $gdrlast, git_rev_parse 'HEAD') {
 482         fail <<END;
 483 $msg
 484 $mangled
 485 END
 486     } else {
 487         fail f_ <<END, $msg;
 488 %s
 489 Branch/history mangled, and diverged since last git-debrebase.
 490 Maybe you reset to, or rebased from, somewhere inappropriate.
 491 END
 492     }
 493 };
 494
 495 sub gbp_pq_export ($$$) {
 496     my ($bname, $base, $tip) = @_;
 497     # must be run in a workarea.  $bname and patch-queue/$bname
 498     # ought not to exist.  Leaves you on patch-queue/$bname with
 499     # the patches staged but not committed.
 500     # returns 1 if there were any patches
 501     printdebug "gbp_pq_export $bname $base $tip\n";
 502     runcmd @git, qw(checkout -q -b), $bname, $base;
 503     runcmd @git, qw(checkout -q -b), "patch-queue/$bname", $tip;
 504     my @gbp_cmd = (qw(gbp pq export));
 505     my $r = system shell_cmd 'exec >../gbp-pq-err 2>&1', @gbp_cmd;
 506     if ($r) {
 507         { local ($!,$?); copy('../gbp-pq-err', \*STDERR); }
 508         failedcmd @gbp_cmd;
 509     }
 510     return 0 unless stat_exists 'debian/patches';
 511     runcmd @git, qw(add -f debian/patches);
 512     return 1;
 513 }
 514
 515
 516 # MERGE-TODO allow merge resolution separately from laundering, before git merge
 517
 518 # later/rework?
 519 #  use git-format-patch?
 520 #  our own patch identification algorithm?
 521 #  this is an alternative strategy
 522
 523 sub merge_failed ($$;@) {
 524     my ($wrecknotes, $emsg, @xmsgs) = @_;
 525     my @m;
 526     push @m, "Merge resolution failed: $emsg";
 527     push @m, @xmsgs;
 528
 529     changedir $maindir;
 530
 531     my @updates;
 532     merge_wreckage_cleaning \@updates;
 533     run_ref_updates_now "merge failed", \@updates;
 534
 535     @updates = ();
 536     keys %$wrecknotes;
 537     while (my ($k,$v) = each %$wrecknotes) {
 538         push @updates, "create $wrecknoteprefix/$k $v";
 539     }
 540     run_ref_updates_now "merge failed", \@updates;
 541     push @m, "Wreckage left in $wrecknoteprefix/*.";
 542
 543     push @m, "See git-debrebase(1) section FAILED MERGES for suggestions.";
 544
 545     # use finish rather than fail, in case we are within an eval
 546     # (that can happen inside walk!)
 547     print STDERR "\n";
 548     print STDERR "$us: $_\n" foreach @m;
 549     finish 15;
 550 }
 551
 552 sub mwrecknote ($$$) {
 553     my ($wrecknotes, $reftail, $commitish) = @_;
 554     confess unless defined $commitish;
 555     printdebug "mwrecknote $reftail $commitish\n";
 556     $wrecknotes->{$reftail} = $commitish;
 557 }
 558
 559 sub merge_attempt_cmd {
 560     my $wrecknotes = shift @_;
 561     debugcmd '+', @_;
 562     $!=0; $?=-1;
 563     if (system @_) {
 564         merge_failed $wrecknotes,
 565             failedcmd_waitstatus(),
 566             "failed command: @_";
 567     }
 568 }
 569
 570 sub merge_series_patchqueue_convert ($$$);
 571
 572 sub merge_series ($$$;@) {
 573     my ($newbase, $wrecknotes, $base_q, @input_qs) = @_;
 574     # $base_q{SeriesBase}  $input_qs[]{SeriesBase}
 575     # $base_q{SeriesTip}   $input_qs[]{SeriesTip}
 576     # ^ specifies several patch series (currently we only support exactly 2)
 577     # return value is a commit which is the result of
 578     # merging the two versions of the same topic branch
 579     #   $input_q[0] and $input_q[1]
 580     # with respect to the old version
 581     #   $base_q
 582     # all onto $newbase.
 583
 584     # Creates, in *_q, a key MR for its private use
 585
 586     printdebug "merge_series newbase=$newbase\n";
 587
 588     $input_qs[$_]{MR}{S} = $_ foreach (0..$#input_qs);
 589     $base_q->{MR}{S} = 'base';
 590
 591     my %prereq;
 592     # $prereq{<patch filename>}{<possible prereq}{<S>} = 1 or absent
 593     # $prereq{<patch filename>}{<possible prereq}  exists or not (later)
 594     # $prereq{<patch filename>}               exists or not (even later)
 595
 596     my $merged_pq;
 597
 598     my $mwrecknote = sub { &mwrecknote($wrecknotes, @_); };
 599
 600     my $attempt_cmd = sub { &merge_attempt_cmd($wrecknotes, @_); };
 601
 602     local $workarea;
 603     fresh_workarea "merge";
 604     my $seriesfile = "debian/patches/series";
 605     in_workarea sub {
 606         playtree_setup();
 607         foreach my $q ($base_q, reverse @input_qs) {
 608             my $s = $q->{MR}{S};
 609             my $any = gbp_pq_export "p-$s", $q->{SeriesBase}, $q->{SeriesTip};
 610             my @earlier;
 611             if ($any) {
 612                 open S, $seriesfile or confess "$seriesfile $!";
 613                 while (my $patch = <S>) {
 614                     chomp $patch or confess $!;
 615                     $prereq{$patch} //= {};
 616                     foreach my $earlier (@earlier) {
 617                         $prereq{$patch}{$earlier}{$s}++ and confess;
 618                     }
 619                     push @earlier, $patch;
 620                     stat "debian/patches/$patch" or confess "$patch ?";
 621                 }
 622                 S->error and confess "$seriesfile $!";
 623                 close S;
 624             }
 625             read_tree_upstream $newbase, 1;
 626             my $pec = make_commit [ grep { defined } $base_q->{MR}{PEC} ], [
 627                 "Convert $s to patch queue for merging",
 628                 "[git-debrebase merge-innards patch-queue import:".
 629                 " $q->{SeriesTip}]"
 630             ];
 631             printdebug "merge_series  pec $pec ";
 632             runcmd @git, qw(rm -q --ignore-unmatch --cached), $seriesfile;
 633             $pec = make_commit [ $pec ], [
 634                 "Drop series file from $s to avoid merge trouble",
 635                 "[git-debrebase merge-innards patch-queue prep:".
 636                 " $q->{SeriesTip}]"
 637             ];
 638
 639             read_tree_debian $newbase;
 640             if (@earlier) {
 641                 read_tree_subdir 'debian/patches', "$pec:debian/patches";
 642             } else {
 643                 rm_subdir_cached 'debian/patches';
 644             }
 645             $pec = make_commit [ $pec ], [
 646  "Update debian/ (excluding patches) to final to avoid re-merging",
 647  "debian/ was already merged and we need to just take that.",
 648                 "[git-debrebase merge-innards patch-queue packaging:".
 649                 " $q->{SeriesTip}]"
 650             ];
 651
 652             printdebug "pec' $pec\n";
 653             runcmd @git, qw(reset -q --hard), $pec;
 654             $q->{MR}{PEC} = $pec;
 655             $mwrecknote->("$q->{LeftRight}-patchqueue", $pec);
 656         }
 657         # now, because of reverse, we are on $input_q->{MR}{OQC}
 658         runcmd @git, qw(checkout -q -b merge);
 659         printdebug "merge_series merging...\n";
 660         my @mergecmd = (@git, qw(merge --quiet --no-edit), "p-1");
 661
 662         $attempt_cmd->(@mergecmd);
 663
 664         printdebug "merge_series merge ok, series...\n";
 665         # We need to construct a new series file
 666         # Firstly, resolve prereq
 667         foreach my $f (sort keys %prereq) {
 668             printdebug "merge_series  patch\t$f\t";
 669             if (!stat_exists "debian/patches/$f") {
 670                 print DEBUG " drop\n" if $debuglevel;
 671                 # git merge deleted it; that's how we tell it's not wanted
 672                 delete $prereq{$f};
 673                 next;
 674             }
 675             print DEBUG " keep\n" if $debuglevel;
 676             foreach my $g (sort keys %{ $prereq{$f} }) {
 677                 my $gfp = $prereq{$f}{$g};
 678                 printdebug "merge_series  prereq\t$f\t-> $g\t";
 679                 if (!!$gfp->{0} == !!$gfp->{1}
 680                     ? $gfp->{0}
 681                     : !$gfp->{base}) {
 682                     print DEBUG "\tkeep\n" if $debuglevel;
 683                 } else {
 684                     print DEBUG "\tdrop\n" if $debuglevel;
 685                     delete $prereq{$f}{$g};
 686                 }
 687             }
 688         }
 689
 690         my $unsat = sub {
 691             my ($f) = @_;
 692             return scalar keys %{ $prereq{$f} };
 693         };
 694
 695         my $nodate = time + 1;
 696         my %authordate;
 697         # $authordate{<patch filename>};
 698         my $authordate = sub {
 699             my ($f) = @_;
 700             $authordate{$f} //= do {
 701                 open PF, "<", "debian/patches/$f" or confess "$f $!";
 702                 while (<PF>) {
 703                     return $nodate if m/^$/;
 704                     last if s{^Date: }{};
 705                 }
 706                 chomp;
 707                 return cmdoutput qw(date +%s -d), $_;
 708             };
 709         };
 710
 711         open NS, '>', $seriesfile or confess $!;
 712
 713         while (keys %prereq) {
 714             my $best;
 715             foreach my $try (sort keys %prereq) {
 716                 if ($best) {
 717                     next if (
 718                              $unsat->($try) <=> $unsat->($best) or
 719                              $authordate->($try) <=> $authordate->($best) or
 720                              $try cmp $best
 721                             ) >= 0;
 722                 }
 723                 $best = $try;
 724             }
 725             printdebug "merge_series series next $best\n";
 726             print NS "$best\n" or confess $!;
 727             delete $prereq{$best};
 728             foreach my $gp (values %prereq) {
 729                 delete $gp->{$best};
 730             }
 731         }
 732
 733         runcmd @git, qw(add), $seriesfile;
 734         runcmd @git, qw(commit --quiet -m), 'Merged patch queue form';
 735         $merged_pq = git_rev_parse 'HEAD';
 736         $mwrecknote->('merged-patchqueue', $merged_pq);
 737     };
 738     return merge_series_patchqueue_convert
 739             $wrecknotes, $newbase, $merged_pq;
 740 }
 741
 742 sub merge_series_patchqueue_convert ($$$) {
 743     my ($wrecknotes, $newbase, $merged_pq) = @_;
 744
 745     my $result;
 746     in_workarea sub {
 747         playtree_setup();
 748         printdebug "merge_series series gbp pq import\n";
 749         runcmd @git, qw(checkout -q -b mergec), $merged_pq;
 750
 751         merge_attempt_cmd($wrecknotes, qw(gbp pq import));
 752         # MERGE-TODO consider git-format-patch etc. instead,
 753         # since gbp pq doesn't always round-trip :-/
 754
 755         # OK now we are on patch-queue/merge, and we need to rebase
 756         # onto the intended parent and drop the patches from each one
 757
 758         printdebug "merge_series series ok, building...\n";
 759         my $build = $newbase;
 760         my @lcmd = (@git, qw(rev-list --reverse mergec..patch-queue/mergec));
 761         foreach my $c (grep /./, split /\n/, cmdoutput @lcmd) {
 762             my $commit = git_cat_file $c, 'commit';
 763             printdebug "merge_series series ok, building $c\n";
 764             read_tree_upstream $c, 0, $newbase;
 765             my $tree = cmdoutput @git, qw(write-tree);
 766             $commit =~ s{^parent (\S+)$}{parent $build}m or confess;
 767             $commit =~ s{^tree (\S+)$}{tree $tree}m      or confess;
 768             open C, ">", "../mcommit" or confess $!;
 769             print C $commit or confess $!;
 770             close C or confess $!;
 771             $build = cmdoutput @git, qw(hash-object -w -t commit ../mcommit);
 772         }
 773         $result = $build;
 774         mwrecknote($wrecknotes, 'merged-result', $result);
 775
 776         runcmd @git, qw(update-ref refs/heads/result), $result;
 777
 778         runcmd @git, qw(checkout -q -b debug);
 779         runcmd @git, qw(commit --allow-empty -q -m M-INDEX);
 780         runcmd @git, qw(add .);
 781         runcmd @git, qw(commit --allow-empty -q -m M-WORKTREE);
 782         my $mdebug = git_rev_parse 'HEAD';
 783         printdebug sprintf "merge_series done debug=%s\n", $mdebug;
 784         mwrecknote($wrecknotes, 'merged-debug', $mdebug);
 785     };
 786     printdebug "merge_series returns $result\n";
 787     return $result;
 788 }
 789
 790 # classify returns an info hash like this
 791 #   CommitId => $objid
 792 #   Hdr => # commit headers, including 1 final newline
 793 #   Msg => # commit message (so one newline is dropped)
 794 #   Tree => $treeobjid
 795 #   Type => (see below)
 796 #   Parents = [ {
 797 #       Ix => $index # ie 0, 1, 2, ...
 798 #       CommitId
 799 #       Differs => return value from get_differs
 800 #       IsOrigin
 801 #       IsDggitImport => 'orig' 'tarball' 'unpatched' 'package' (as from dgit)
 802 #     } ...]
 803 #   NewMsg => # commit message, but with any [dgit import ...] edited
 804 #             # to say "[was: ...]"
 805 #
 806 # Types:
 807 #   Packaging
 808 #   Changelog
 809 #   Upstream
 810 #   AddPatches
 811 #   Mixed
 812 #
 813 #   Pseudomerge
 814 #     has additional entres in classification result
 815 #       Overwritten = [ subset of Parents ]
 816 #       Contributor = $the_remaining_Parent
 817 #
 818 #   DgitImportUnpatched
 819 #     has additional entry in classification result
 820 #       OrigParents = [ subset of Parents ]
 821 #
 822 #   Anchor
 823 #     has additional entry in classification result
 824 #       OrigParents = [ subset of Parents ]  # singleton list
 825 #
 826 #   TreatAsAnchor
 827 #
 828 #   BreakwaterStart
 829 #
 830 #   Unknown
 831 #     has additional entry in classification result
 832 #       Why => "prose"
 833
 834 sub parsecommit ($;$) {
 835     my ($objid, $p_ref) = @_;
 836     # => hash with                   CommitId Hdr Msg Tree Parents
 837     #    Parents entries have only   Ix CommitId
 838     #    $p_ref, if provided, must be [] and is used as a base for Parents
 839
 840     $p_ref //= [];
 841     confess if @$p_ref;
 842
 843     my ($h,$m) = get_commit $objid;
 844
 845     my ($t) = $h =~ m/^tree (\w+)$/m or confess $objid;
 846     my (@ph) = $h =~ m/^parent (\w+)$/mg;
 847
 848     my $r = {
 849         CommitId => $objid,
 850         Hdr => $h,
 851         Msg => $m,
 852         Tree => $t,
 853         Parents => $p_ref,
 854     };
 855
 856     foreach my $ph (@ph) {
 857         push @$p_ref, {
 858             Ix => scalar @$p_ref,
 859             CommitId => $ph,
 860         };
 861     }
 862
 863     return $r;
 864 }
 865
 866 sub classify ($) {
 867     my ($objid) = @_;
 868
 869     my @p;
 870     my $r = parsecommit($objid, \@p);
 871     my $t = $r->{Tree};
 872
 873     foreach my $p (@p) {
 874         $p->{Differs} = (get_differs $p->{CommitId}, $t),
 875     }
 876
 877     printdebug "classify $objid \$t=$t \@p",
 878         (map { sprintf " %s/%#x", $_->{CommitId}, $_->{Differs} } @p),
 879         "\n";
 880
 881     my $classify = sub {
 882         my ($type, @rest) = @_;
 883         $r = { %$r, Type => $type, @rest };
 884         if ($debuglevel) {
 885             printdebug " = $type ".(dd $r)."\n";
 886         }
 887         return $r;
 888     };
 889     my $unknown = sub {
 890         my ($why) = @_;
 891         $r = { %$r, Type => qw(Unknown), Why => $why };
 892         printdebug " ** Unknown\n";
 893         return $r;
 894     };
 895
 896     if (grep { $_ eq $objid } @opt_anchors) {
 897         return $classify->('TreatAsAnchor');
 898     }
 899
 900     my @identical = grep { !$_->{Differs} } @p;
 901     my ($stype, $series) = git_cat_file "$t:debian/patches/series";
 902     my $haspatches = $stype ne 'missing' && $series =~ m/^\s*[^#\n\t ]/m;
 903
 904     if ($r->{Msg} =~ m{^\[git-debrebase anchor.*\]$}m) {
 905         # multi-orig upstreams are represented with an anchor merge
 906         # from a single upstream commit which combines the orig tarballs
 907
 908         # Every anchor tagged this way must be a merge.
 909         # We are relying on the
 910         #     [git-debrebase anchor: ...]
 911         # commit message annotation in "declare" anchor merges (which
 912         # do not have any upstream changes), to distinguish those
 913         # anchor merges from ordinary pseudomerges (which we might
 914         # just try to strip).
 915         #
 916         # However, the user is going to be doing git-rebase a lot.  We
 917         # really don't want them to rewrite an anchor commit.
 918         # git-rebase trips up on merges, so that is a useful safety
 919         # catch.
 920         #
 921         # BreakwaterStart commits are also anchors in the terminology
 922         # of git-debrebase(5), but they are untagged (and always
 923         # manually generated).
 924         #
 925         # We cannot not tolerate any tagged linear commit (ie,
 926         # BreakwaterStart commits tagged `[anchor:') because such a
 927         # thing could result from an erroneous linearising raw git
 928         # rebase of a merge anchor.  That would represent a corruption
 929         # of the branch. and we want to detect and reject the results
 930         # of such corruption before it makes it out anywhere.  If we
 931         # reject it here then we avoid making the pseudomerge which
 932         # would be needed to push it.
 933
 934         my $badanchor = sub {
 935             $unknown->(f_ "git-debrebase \`anchor' but %s", "@_");
 936         };
 937         @p == 2 or return $badanchor->(__ "has other than two parents");
 938         $haspatches and return $badanchor->(__ "contains debian/patches");
 939
 940         # How to decide about l/r ordering of anchors ?  git
 941         # --topo-order prefers to expand 2nd parent first.  There's
 942         # already an easy rune to look for debian/ history anyway (git log
 943         # debian/) so debian breakwater branch should be 1st parent; that
 944         # way also there's also an easy rune to look for the upstream
 945         # patches (--topo-order).
 946
 947         # Also this makes --first-parent be slightly more likely to
 948         # be useful - it makes it provide a linearised breakwater history.
 949
 950         # Of course one can say somthing like
 951         #  gitk -- ':/' ':!/debian'
 952         # to get _just_ the commits touching upstream files, and by
 953         # the TREESAME logic in git-rev-list this will leave the
 954         # breakwater into upstream at the first anchor.  But that
 955         # doesn't report debian/ changes at all.
 956
 957         # Other observations about gitk: by default, gitk seems to
 958         # produce output in a different order to git-rev-list.  I
 959         # can't seem to find this documented anywhere.  gitk
 960         # --date-order DTRT.  But, gitk always seems to put the
 961         # parents from left to right, in order, so it's easy to see
 962         # which way round a pseudomerge is.
 963
 964         $p[0]{IsOrigin} and $badanchor->(__ "is an origin commit");
 965         $p[1]{Differs} & ~DS_DEB and
 966             $badanchor->(__ "upstream files differ from left parent");
 967         $p[0]{Differs} & ~D_UPS and
 968             $badanchor->(__ "debian/ differs from right parent");
 969
 970         return $classify->(qw(Anchor),
 971                            OrigParents => [ $p[1] ]);
 972     }
 973
 974     if (@p == 1) {
 975         my $d = $r->{Parents}[0]{Differs};
 976         if ($d == D_PAT_ADD) {
 977             return $classify->(qw(AddPatches));
 978         } elsif ($d & (D_PAT_ADD|D_PAT_OTH)) {
 979             return $unknown->(__ "edits debian/patches");
 980         } elsif ($d & DS_DEB and !($d & ~DS_DEB)) {
 981             my ($ty,$dummy) = git_cat_file "$p[0]{CommitId}:debian";
 982             if ($ty eq 'tree') {
 983                 if ($d == D_DEB_CLOG) {
 984                     return $classify->(qw(Changelog));
 985                 } else {
 986                     return $classify->(qw(Packaging));
 987                 }
 988             } elsif ($ty eq 'missing') {
 989                 return $classify->(qw(BreakwaterStart));
 990             } else {
 991                 return $unknown->(__ "parent's debian is not a directory");
 992             }
 993         } elsif ($d == D_UPS) {
 994             return $classify->(qw(Upstream));
 995         } elsif ($d & DS_DEB and $d & D_UPS and !($d & ~(DS_DEB|D_UPS))) {
 996             return $classify->(qw(Mixed));
 997         } elsif ($d == 0) {
 998             return $unknown->(__ "no changes");
 999         } else {
1000             confess "internal error $objid ?";
1001         }
1002     }
1003     if (!@p) {
1004         return $unknown->(__ "origin commit");
1005     }
1006
1007     if (@p == 2 && @identical == 1) {
1008         my @overwritten = grep { $_->{Differs} } @p;
1009         confess "internal error $objid ?" unless @overwritten==1;
1010         return $classify->(qw(Pseudomerge),
1011                            Overwritten => [ $overwritten[0] ],
1012                            Contributor => $identical[0]);
1013     }
1014     if (@p == 2 && @identical == 2) {
1015         my $get_t = sub {
1016             my ($ph,$pm) = get_commit $_[0]{CommitId};
1017             $ph =~ m/^committer .* (\d+) [-+]\d+$/m
1018                 or confess "$_->{CommitId} ?";
1019             $1;
1020         };
1021         my @bytime = @p;
1022         my $order = $get_t->($bytime[0]) <=> $get_t->($bytime[1]);
1023         if ($order > 0) { # newer first
1024         } elsif ($order < 0) {
1025             @bytime = reverse @bytime;
1026         } else {
1027             # same age, default to order made by -s ours
1028             # that is, commit was made by someone who preferred L
1029         }
1030         return $classify->(qw(Pseudomerge),
1031                            SubType => qw(Ambiguous),
1032                            Contributor => $bytime[0],
1033                            Overwritten => [ $bytime[1] ]);
1034     }
1035     foreach my $p (@p) {
1036         my ($p_h, $p_m) = get_commit $p->{CommitId};
1037         $p->{IsOrigin} = $p_h !~ m/^parent \w+$/m;
1038         ($p->{IsDgitImport},) = $p_m =~ m/^\[dgit import ([0-9a-z]+) .*\]$/m;
1039     }
1040     my @orig_ps = grep { ($_->{IsDgitImport}//'X') eq 'orig' } @p;
1041     my $m2 = $r->{Msg};
1042     if (!(grep { !$_->{IsOrigin} } @p) and
1043         (@orig_ps >= @p - 1) and
1044         $m2 =~ s{^\[(dgit import unpatched .*)\]$}{[was: $1]}m) {
1045         $r->{NewMsg} = $m2;
1046         return $classify->(qw(DgitImportUnpatched),
1047                            OrigParents => \@orig_ps);
1048     }
1049
1050     if (@p == 2 and
1051         $r->{Msg} =~ m{^\[git-debrebase merged-breakwater.*\]$}m) {
1052         return $classify->("MergedBreakwaters");
1053     }
1054     if ($r->{Msg} =~ m{^\[(git-debrebase|dgit)[: ].*\]$}m) {
1055         return $unknown->(f_ "unknown kind of merge from %s", $1);
1056     }
1057     if (@p > 2) {
1058         return $unknown->(__ "octopus merge");
1059     }
1060
1061     if (!$opt_merges) {
1062         return $unknown->(__ "general two-parent merge");
1063     }
1064
1065     return $classify->("VanillaMerge");
1066 }
1067
1068 sub keycommits ($;$$$$$);
1069
1070 sub mergedbreakwaters_anchor ($) {
1071     my ($cl) = @_;
1072     my $best_anchor;
1073     foreach my $p (@{ $cl->{Parents} }) {
1074         my ($panchor, $pbw) = keycommits $p->{CommitId},
1075             undef,undef,undef,undef, 1;
1076         $best_anchor = $panchor
1077             if !defined $best_anchor
1078             or is_fast_fwd $best_anchor, $panchor;
1079         fail f_ "inconsistent anchors in merged-breakwaters %s",
1080             $p->{CommitId}
1081             unless is_fast_fwd $panchor, $best_anchor;
1082     }
1083     return $best_anchor;
1084 }
1085
1086 sub keycommits ($;$$$$$) {
1087     my ($head, $furniture, $unclean, $trouble, $fatal, $claimed_bw) = @_;
1088     # => ($anchor, $breakwater)
1089
1090     # $furniture->("unclean-$tagsfx", $msg, $cl)
1091     # $unclean->("unclean-$tagsfx", $msg, $cl)
1092     #   is callled for each situation or commit that
1093     #   wouldn't be found in a laundered branch
1094     # $furniture is for furniture commits such as might be found on an
1095     #   interchange branch (pseudomerge, d/patches, changelog)
1096     # $trouble is for things whnich prevent the return of
1097     #   anchor and breakwater information; if that is ignored,
1098     #   then keycommits returns (undef, undef) instead.
1099     # $fatal is for unprocessable commits, and should normally cause
1100     #    a failure.  If ignored, agaion, (undef, undef) is returned.
1101     #
1102     # If $claimed_bw, this is supposed to be a breakwater commit.
1103     #
1104     # If a callback is undef, fail is called instead.
1105     # If a callback is defined but false, the situation is ignored.
1106     # Callbacks may say:
1107     #   no warnings qw(exiting); last;
1108     # if the answer is no longer wanted.
1109
1110     my ($anchor, $breakwater);
1111     $breakwater = $head if $claimed_bw;
1112     my $clogonly;
1113     my $cl;
1114     my $found_pm;
1115     $fatal //= sub { fail_unprocessable $_[1]; };
1116     my $x = sub {
1117         my ($cb, $tagsfx, $mainwhy, $xwhy) = @_;
1118         my $why = $mainwhy.$xwhy;
1119         my $m = f_ "branch needs laundering (run git-debrebase): %s", $why;
1120         fail $m unless defined $cb;
1121         return unless $cb;
1122         $cb->("unclean-$tagsfx", $why, $cl, $mainwhy);
1123     };
1124     my $found_anchor = sub {
1125         ($anchor) = @_;
1126         $breakwater //= $clogonly;
1127         $breakwater //= $head;
1128         no warnings qw(exiting);
1129         last;
1130     };
1131     for (;;) {
1132         $cl = classify $head;
1133         my $ty = $cl->{Type};
1134         if ($ty eq 'Packaging') {
1135             $breakwater //= $clogonly;
1136             $breakwater //= $head;
1137         } elsif ($ty eq 'Changelog') {
1138             # this is going to count as the tip of the breakwater
1139             # only if it has no upstream stuff before it
1140             $clogonly //= $head;
1141         } elsif ($ty eq 'Anchor' or
1142                  $ty eq 'TreatAsAnchor' or
1143                  $ty eq 'BreakwaterStart') {
1144             $found_anchor->($head);
1145         } elsif ($ty eq 'Upstream') {
1146             $x->($unclean, 'ordering',
1147  (f_ "packaging change (%s) follows upstream change", $breakwater),
1148                  (f_ " (eg %s)", $head))
1149                 if defined $breakwater;
1150             $clogonly = undef;
1151             $breakwater = undef;
1152         } elsif ($ty eq 'Mixed') {
1153             $x->($unclean, 'mixed',
1154                  (__ "found mixed upstream/packaging commit"),
1155                  (f_ " (%s)", $head));
1156             $clogonly = undef;
1157             $breakwater = undef;
1158         } elsif ($ty eq 'Pseudomerge' or
1159                  $ty eq 'AddPatches') {
1160             my $found_pm = 1;
1161             $x->($furniture, (lc $ty),
1162                  (f_ "found interchange bureaucracy commit (%s)", $ty),
1163                  (f_ " (%s)", $head));
1164         } elsif ($ty eq 'DgitImportUnpatched') {
1165             if ($found_pm) {
1166                 $x->($trouble, 'dgitimport',
1167                      (__ "found dgit dsc import"),
1168                      (f_ " (%s)", $head));
1169                 return (undef,undef);
1170             } else {
1171                 $x->($fatal, 'unprocessable',
1172                      (__ "found bare dgit dsc import with no prior history"),
1173                      (f_ " (%s)", $head));
1174                 return (undef,undef);
1175             }
1176         } elsif ($ty eq 'VanillaMerge') {
1177             $x->($trouble, 'vanillamerge',
1178                  (__ "found vanilla merge"),
1179                  (f_ " (%s)", $head));
1180             return (undef,undef);
1181         } elsif ($ty eq 'MergedBreakwaters') {
1182             $found_anchor->(mergedbreakwaters_anchor $cl);
1183         } else {
1184             $x->($fatal, 'unprocessable',
1185                  (f_ "found unprocessable commit, cannot cope: %s",
1186                      $cl->{Why}),
1187                  (f_ " (%s)", $head));
1188             return (undef,undef);
1189         }
1190         $head = $cl->{Parents}[0]{CommitId};
1191     }
1192     return ($anchor, $breakwater);
1193 }
1194
1195 sub walk ($;$$$);
1196 sub walk ($;$$$) {
1197     my ($input,
1198         $nogenerate,$report, $report_lprefix) = @_;
1199     # => ($tip, $breakwater_tip, $last_anchor)
1200     # (or nothing, if $nogenerate)
1201
1202     printdebug "*** WALK $input ".($nogenerate//0)." ".($report//'-')."\n";
1203     $report_lprefix //= '';
1204
1205     # go through commits backwards
1206     # we generate two lists of commits to apply:
1207     # breakwater branch and upstream patches
1208     my (@brw_cl, @upp_cl, @processed);
1209     my %found;
1210     my $upp_limit;
1211     my @pseudomerges;
1212
1213     my $cl;
1214     my $xmsg = sub {
1215         my ($prose, $info) = @_;
1216         my $ms = $cl->{Msg};
1217         chomp $ms;
1218         confess unless defined $info;
1219         $ms .= "\n\n[git-debrebase $info: $prose]\n";
1220         return (Msg => $ms);
1221     };
1222     my $rewrite_from_here = sub {
1223         my ($cl) = @_;
1224         my $sp_cl = { SpecialMethod => 'StartRewrite' };
1225         push @$cl, $sp_cl;
1226         push @processed, $sp_cl;
1227     };
1228     my $cur = $input;
1229
1230     my $prdelim = "";
1231     my $prprdelim = sub { print $report $prdelim if $report; $prdelim=""; };
1232
1233     my $prline = sub {
1234         return unless $report;
1235         print $report $prdelim, $report_lprefix, @_;
1236         $prdelim = "\n";
1237     };
1238
1239     my $bomb = sub { # usage: return $bomb->();
1240         print $report " Unprocessable" if $report;
1241         print $report " ($cl->{Why})" if $report && defined $cl->{Why};
1242         $prprdelim->();
1243         if ($nogenerate) {
1244             return (undef,undef);
1245         }
1246         fail_unprocessable "found unprocessable commit, cannot cope".
1247             (defined $cl->{Why} ? "; $cl->{Why}:": ':').
1248             " (commit $cur) (d.".
1249             (join ' ', map { sprintf "%#x", $_->{Differs} }
1250              @{ $cl->{Parents} }).
1251                  ")";
1252     };
1253
1254     my $build;
1255     my $breakwater;
1256
1257     my $build_start = sub {
1258         my ($msg, $parent) = @_;
1259         $prline->(" $msg");
1260         $build = $parent;
1261         no warnings qw(exiting); last;
1262     };
1263
1264     my $nomerge = sub {
1265         my ($emsg) = @_;
1266         merge_failed $cl->{MergeWreckNotes}, $emsg;
1267     };
1268
1269     my $mwrecknote = sub { &mwrecknote($cl->{MergeWreckNotes}, @_); };
1270
1271     my $last_anchor;
1272
1273     for (;;) {
1274         $cl = classify $cur;
1275         $cl->{MergeWreckNotes} //= {};
1276         my $ty = $cl->{Type};
1277         my $st = $cl->{SubType};
1278         $prline->("$cl->{CommitId} $cl->{Type}");
1279         $found{$ty. ( defined($st) ? "-$st" : '' )}++;
1280         push @processed, $cl;
1281         my $p0 = @{ $cl->{Parents} }==1 ? $cl->{Parents}[0]{CommitId} : undef;
1282         if ($ty eq 'AddPatches') {
1283             $cur = $p0;
1284             $rewrite_from_here->(\@upp_cl);
1285             next;
1286         } elsif ($ty eq 'Packaging' or $ty eq 'Changelog') {
1287             push @brw_cl, $cl;
1288             $cur = $p0;
1289             next;
1290         } elsif ($ty eq 'BreakwaterStart') {
1291             $last_anchor = $cur;
1292             $build_start->('FirstPackaging', $cur);
1293         } elsif ($ty eq 'Upstream') {
1294             push @upp_cl, $cl;
1295             $cur = $p0;
1296             next;
1297         } elsif ($ty eq 'Mixed') {
1298             my $queue = sub {
1299                 my ($q, $wh) = @_;
1300                 my $cls = { %$cl, $xmsg->("mixed commit: $wh part",'split') };
1301                 push @$q, $cls;
1302             };
1303             $queue->(\@brw_cl, "debian");
1304             $queue->(\@upp_cl, "upstream");
1305             $rewrite_from_here->(\@brw_cl);
1306             $cur = $p0;
1307             next;
1308         } elsif ($ty eq 'Pseudomerge') {
1309             my $contrib = $cl->{Contributor}{CommitId};
1310             print $report " Contributor=$contrib" if $report;
1311             push @pseudomerges, $cl;
1312             $rewrite_from_here->(\@upp_cl);
1313             $cur = $contrib;
1314             next;
1315         } elsif ($ty eq 'Anchor' or $ty eq 'TreatAsAnchor') {
1316             $last_anchor = $cur;
1317             $build_start->("Anchor", $cur);
1318         } elsif ($ty eq 'DgitImportUnpatched') {
1319             my $pm = $pseudomerges[-1];
1320             if (defined $pm) {
1321                 # To an extent, this is heuristic.  Imports don't have
1322                 # a useful history of the debian/ branch.  We assume
1323                 # that the first pseudomerge after an import has a
1324                 # useful history of debian/, and ignore the histories
1325                 # from later pseudomerges.  Often the first pseudomerge
1326                 # will be the dgit import of the upload to the actual
1327                 # suite intended by the non-dgit NMUer, and later
1328                 # pseudomerges may represent in-archive copies.
1329                 my $ovwrs = $pm->{Overwritten};
1330                 printf $report " PM=%s \@Overwr:%d",
1331                     $pm->{CommitId}, (scalar @$ovwrs)
1332                     if $report;
1333                 if (@$ovwrs != 1) {
1334                     printdebug "*** WALK BOMB DgitImportUnpatched\n";
1335                     return $bomb->();
1336                 }
1337                 my $ovwr = $ovwrs->[0]{CommitId};
1338                 printf $report " Overwr=%s", $ovwr if $report;
1339                 # This import has a tree which is just like a
1340                 # breakwater tree, but it has the wrong history.  It
1341                 # ought to have the previous breakwater (which the
1342                 # pseudomerge overwrote) as an ancestor.  That will
1343                 # make the history of the debian/ files correct.  As
1344                 # for the upstream version: either it's the same as
1345                 # was ovewritten (ie, same as the previous
1346                 # breakwater), in which case that history is precisely
1347                 # right; or, otherwise, it was a non-gitish upload of a
1348                 # new upstream version.  We can tell these apart by
1349                 # looking at the tree of the supposed upstream.
1350                 push @brw_cl, {
1351                     %$cl,
1352                     SpecialMethod => 'DgitImportDebianUpdate',
1353                     $xmsg->("debian changes", 'convert dgit import')
1354                 }, {
1355                     %$cl,
1356                     SpecialMethod => 'DgitImportUpstreamUpdate',
1357                     $xmsg->("convert dgit import: upstream update",
1358                             "anchor")
1359                 };
1360                 $prline->(" Import");
1361                 $rewrite_from_here->(\@brw_cl);
1362                 $upp_limit //= $#upp_cl; # further, deeper, patches discarded
1363                 $cur = $ovwr;
1364                 next;
1365             } else {
1366                 # Everything is from this import.  This kind of import
1367                 # is already nearly in valid breakwater format, with the
1368                 # patches as commits.  Unfortunately it contains
1369                 # debian/patches/.
1370                 printdebug "*** WALK BOMB bare dgit import\n";
1371                 $cl->{Why} = "bare dgit dsc import";
1372                 return $bomb->();
1373             }
1374             confess "$ty ?";
1375         } elsif ($ty eq 'MergedBreakwaters') {
1376             $last_anchor = mergedbreakwaters_anchor $cl;
1377             $build_start->(' MergedBreakwaters', $cur);
1378             last;
1379         } elsif ($ty eq 'VanillaMerge') {
1380             # User may have merged unstitched branch(es).  We will
1381             # have now lost what ffq-prev was then (since the later
1382             # pseudomerge may introduce further changes).  The effect
1383             # of resolving such a merge is that we may have to go back
1384             # further in history to find a merge base, since the one
1385             # which was reachable via ffq-prev is no longer findable.
1386             # This is suboptimal, but if it all works we'll have done
1387             # the right thing.
1388             # MERGE-TODO we should warn the user in the docs about this
1389
1390             my $ok=1;
1391             my $best_anchor;
1392             # We expect to find a dominating anchor amongst the
1393             # inputs' anchors.  That will be the new anchor.
1394             #
1395             # More complicated is finding a merge base for the
1396             # breakwaters.  We need a merge base that is a breakwater
1397             # commit.  The ancestors of breakwater commits are more
1398             # breakwater commits and possibly upstream commits and the
1399             # ancestors of those upstream.  Upstreams might have
1400             # arbitrary ancestors.  But any upstream commit U is
1401             # either included in both anchors, in which case the
1402             # earlier anchor is a better merge base than any of U's
1403             # ancestors; or U is not included in the older anchor, in
1404             # which case U is not an ancestor of the vanilla merge at
1405             # all.  So no upstream commit, nor any ancestor thereof,
1406             # is a best merge base.  As for non-breakwater Debian
1407             # commits: these are never ancestors of any breakwater.
1408             #
1409             # So any best merge base as found by git-merge-base
1410             # is a suitable breakwater anchor.  Usually there will
1411             # be only one.
1412
1413             printdebug "*** MERGE\n";
1414
1415             my @bwbcmd = (@git, qw(merge-base));
1416             my @ibcmd = (@git, qw(merge-base --all));
1417             my $might_be_in_bw = 1;
1418
1419             my $ps = $cl->{Parents};
1420
1421             $mwrecknote->('vanilla-merge', $cl->{CommitId});
1422
1423             foreach my $p (@$ps) {
1424                 $prline->(" VanillaMerge ".$p->{Ix});
1425                 $prprdelim->();
1426                 my ($ptip, $pbw, $panchor) =
1427                     walk $p->{CommitId}, 0, $report,
1428                          $report_lprefix.'  ';
1429                 $p->{Laundered} = $p->{SeriesTip} = $ptip;
1430                 $p->{Breakwater} = $p->{SeriesBase} = $pbw;
1431                 $p->{Anchor} = $panchor;
1432
1433                 my $lr = $p->{LeftRight} = (qw(left right))[$p->{Ix}];
1434                 $mwrecknote->("$lr-input", $p->{CommitId});
1435
1436                 my $mwrecknote_parent = sub {
1437                     my ($which) = @_;
1438                     $mwrecknote->("$lr-".(lc $which), $p->{$which});
1439                 };
1440                 $mwrecknote_parent->('Laundered');
1441                 $mwrecknote_parent->('Breakwater');
1442                 $mwrecknote_parent->('Anchor');
1443
1444                 $best_anchor = $panchor if
1445                     !defined $best_anchor or
1446                     is_fast_fwd $best_anchor, $panchor;
1447
1448                 printdebug " MERGE BA best=".($best_anchor//'-').
1449                     " p=$panchor\n";
1450             }
1451
1452             $mwrecknote->('result-anchor', $best_anchor);
1453
1454             foreach my $p (@$ps) {
1455                 $prline->(" VanillaMerge ".$p->{Ix});
1456                 if (!is_fast_fwd $p->{Anchor}, $best_anchor) {
1457                     $nomerge->('divergent anchors');
1458                 } elsif ($p->{Anchor} eq $best_anchor) {
1459                     print $report " SameAnchor" if $report;
1460                 } else {
1461                     print $report " SupersededAnchor" if $report;
1462                 }
1463                 if ($p->{Breakwater} eq $p->{CommitId}) {
1464                     # this parent commit was its own breakwater,
1465                     # ie it is part of the breakwater
1466                     print $report " Breakwater" if $report;
1467                 } else {
1468                     $might_be_in_bw = 0;
1469                 }
1470                 push @bwbcmd, $p->{Breakwater};
1471                 push @ibcmd, $p->{CommitId};
1472             }
1473
1474             if ($ok && $might_be_in_bw) {
1475                 # We could rewrite this to contaion the metadata
1476                 # declaring it to be MergedBreakwaters, but
1477                 # unnecessarily rewriting a merge seems unhelpful.
1478                 $prline->(" VanillaMerge MergedBreakwaters");
1479                 $last_anchor = $best_anchor;
1480                 $build_start->('MergedBreakwaters', $cur);
1481             }
1482
1483             my $bwb = cmdoutput @bwbcmd;
1484
1485             # OK, now we have a breakwater base, but we need the merge
1486             # base for the interchange branch because we need the delta
1487             # queue.
1488             #
1489             # This a the best merge base of our inputs which has the
1490             # breakwater merge base as an ancestor.
1491
1492             my @ibs =
1493                 grep /./,
1494                 split /\n/,
1495                 cmdoutput @ibcmd;
1496
1497             @ibs or confess 'internal error, expected anchor at least ?';
1498
1499             my $ib;
1500             my $ibleaf;
1501             foreach my $tibix (0..$#ibs) {
1502                 my $tib = $ibs[$tibix];
1503                 my $ff = is_fast_fwd $bwb, $tib;
1504                 my $ok = !$ff ? 'rej' : $ib ? 'extra' : 'ok';
1505                 my $tibleaf = "interchange-mbcand-$ok-$tibix";
1506                 $mwrecknote->($tibleaf, $tib);
1507                 next unless $ff;
1508                 next if $ib;
1509                 $ib = $tib;
1510                 $ibleaf = $tibleaf;
1511             }
1512
1513             $ib or $nomerge->("no suitable interchange merge base");
1514
1515             $prline->("  VanillaMerge Base");
1516             $prprdelim->();
1517             my ($btip, $bbw, $banchor) = eval {
1518                 walk $ib, 0, $report, $report_lprefix.'  ';
1519             };
1520             $nomerge->("walking interchange branch merge base ($ibleaf):\n".
1521                        $@)
1522                 if length $@;
1523
1524             $mwrecknote->("mergebase-laundered", $btip);
1525             $mwrecknote->("mergebase-breakwater", $bbw);
1526             $mwrecknote->("mergebase-anchor", $banchor);
1527
1528             my $ibinfo = { SeriesTip => $btip,
1529                            SeriesBase => $bbw,
1530                            Anchor => $banchor,
1531                            LeftRight => 'mergebase' };
1532
1533             $bbw eq $bwb
1534                 or $nomerge->("interchange merge-base ($ib)'s".
1535                               " breakwater ($bbw)".
1536                               " != breakwaters' merge-base ($bwb)");
1537
1538             grep { $_->{Anchor} eq $ibinfo->{Anchor} } @$ps
1539                  or $nomerge->("interchange merge-base ($ib)'s".
1540                                " anchor ($ibinfo->{SeriesBase})".
1541                                " != any merge input's anchor (".
1542                                (join ' ', map { $_->{Anchor} } @$ps).
1543                                ")");
1544
1545             $cl->{MergeInterchangeBaseInfo} = $ibinfo;
1546             $cl->{MergeBestAnchor} = $best_anchor;
1547             push @brw_cl, {
1548                 %$cl,
1549                 SpecialMethod => 'MergeCreateMergedBreakwaters',
1550                 $xmsg->('constructed from vanilla merge',
1551                         'merged-breakwater'),
1552             };
1553             push @upp_cl, {
1554                 %$cl,
1555                 SpecialMethod => 'MergeMergeSeries',
1556             };
1557             $build_start->('MergeBreakwaters', $cur);
1558         } else {
1559             printdebug "*** WALK BOMB unrecognised\n";
1560             return $bomb->();
1561         }
1562     }
1563     $prprdelim->();
1564
1565     printdebug "*** WALK prep done cur=$cur".
1566         " brw $#brw_cl upp $#upp_cl proc $#processed pm $#pseudomerges\n";
1567
1568     return if $nogenerate;
1569
1570     # Now we build it back up again
1571
1572     fresh_workarea();
1573
1574     my $rewriting = 0;
1575
1576     $#upp_cl = $upp_limit if defined $upp_limit;
1577
1578     my $committer_authline = calculate_committer_authline();
1579
1580     printdebug "WALK REBUILD $build ".(scalar @processed)."\n";
1581
1582     confess "internal error" unless $build eq (pop @processed)->{CommitId};
1583
1584     in_workarea sub {
1585         mkdir $rd or $!==EEXIST or confess $!;
1586         my $current_method;
1587         my $want_debian = $build;
1588         my $want_upstream = $build;
1589
1590         my $read_tree_upstream = sub { ($want_upstream) = @_; };
1591         my $read_tree_debian = sub { ($want_debian) = @_; };
1592
1593         foreach my $cl (qw(Debian), (reverse @brw_cl),
1594                         { SpecialMethod => 'RecordBreakwaterTip' },
1595                         qw(Upstream), (reverse @upp_cl)) {
1596             if (!ref $cl) {
1597                 $current_method = $cl;
1598                 next;
1599             }
1600             my $method = $cl->{SpecialMethod} // $current_method;
1601             my @parents = ($build);
1602             my $cltree = $cl->{CommitId};
1603             printdebug "WALK BUILD ".($cltree//'undef').
1604                 " $method (rewriting=$rewriting)\n";
1605             if ($method eq 'Debian') {
1606                 $read_tree_debian->($cltree);
1607             } elsif ($method eq 'Upstream') {
1608                 $read_tree_upstream->($cltree);
1609             } elsif ($method eq 'StartRewrite') {
1610                 $rewriting = 1;
1611                 next;
1612             } elsif ($method eq 'RecordBreakwaterTip') {
1613                 $breakwater = $build;
1614                 next;
1615             } elsif ($method eq 'DgitImportDebianUpdate') {
1616                 $read_tree_debian->($cltree);
1617             } elsif ($method eq 'DgitImportUpstreamUpdate') {
1618                 confess unless $rewriting;
1619                 my $differs = (get_differs $build, $cltree);
1620                 next unless $differs & D_UPS;
1621                 $read_tree_upstream->($cltree);
1622                 push @parents, map { $_->{CommitId} } @{ $cl->{OrigParents} };
1623             } elsif ($method eq 'MergeCreateMergedBreakwaters') {
1624                 print "Found a general merge, will try to tidy it up.\n";
1625                 $rewriting = 1;
1626                 $read_tree_upstream->($cl->{MergeBestAnchor});
1627                 $read_tree_debian->($cltree);
1628                 @parents = map { $_->{Breakwater} } @{ $cl->{Parents} };
1629             } elsif ($method eq 'MergeMergeSeries') {
1630                 my $cachehit = reflog_cache_lookup
1631                     $merge_cache_ref, "vanilla-merge $cl->{CommitId}";
1632                 if ($cachehit) {
1633                     print "Using supplied resolution for $cl->{CommitId}...\n";
1634                     $build = $cachehit;
1635                     $mwrecknote->('cached-resolution', $build);
1636                 } else {
1637                     print "Running merge resolution for $cl->{CommitId}...\n";
1638                     $mwrecknote->('new-base', $build);
1639                     $build = merge_series
1640                         $build, $cl->{MergeWreckNotes},
1641                         $cl->{MergeInterchangeBaseInfo},
1642                         @{ $cl->{Parents} };
1643                 }
1644                 $last_anchor = $cl->{MergeBestAnchor};
1645
1646                 # Check for mismerges:
1647                 my $check = sub {
1648                     my ($against, $allow, $what) = @_;
1649                     my $differs = get_differs $build, $against;
1650                     $nomerge->(sprintf
1651        "merge misresolved: %s are not the same (%s %s d.%#x)",
1652                                $what, $against, $build, $differs)
1653                         if $differs & ~($allow | D_PAT_ADD);
1654                 };
1655
1656                 # Breakwater changes which were in each side of the
1657                 # merge will have been incorporated into the
1658                 # MergeCreateMergedBreakwaters output.  Because the
1659                 # upstream series was rebased onto the new breakwater,
1660                 # so should all of the packaging changes which were in
1661                 # the input.
1662                 $check->($input, D_UPS, 'debian files');
1663
1664                 # Upstream files are merge_series, which ought to
1665                 # have been identical to the original merge.
1666                 $check->($cl->{CommitId}, DS_DEB, 'upstream files');
1667
1668                 print "Merge resolution successful.\n";
1669                 next;
1670             } else {
1671                 confess "$method ?";
1672             }
1673             if (!$rewriting) {
1674                 my $procd = (pop @processed) // 'UNDEF';
1675                 if ($cl ne $procd) {
1676                     $rewriting = 1;
1677                     printdebug "WALK REWRITING NOW cl=$cl procd=$procd\n";
1678                 }
1679             }
1680             if ($rewriting) {
1681                 read_tree_upstream $want_upstream, 0, $want_debian;
1682
1683                 my $newtree = cmdoutput @git, qw(write-tree);
1684                 my $ch = $cl->{Hdr};
1685                 $ch =~ s{^tree .*}{tree $newtree}m or confess "$ch ?";
1686                 $ch =~ s{^parent .*\n}{}mg;
1687                 $ch =~ s{(?=^author)}{
1688                     join '', map { "parent $_\n" } @parents
1689                 }me or confess "$ch ?";
1690                 if ($rewriting) {
1691                     $ch =~ s{^committer .*$}{$committer_authline}m
1692                         or confess "$ch ?";
1693                 }
1694                 my $cf = "$rd/m$rewriting";
1695                 open CD, ">", $cf or confess $!;
1696                 print CD $ch, "\n", $cl->{Msg} or confess $!;
1697                 close CD or confess $!;
1698                 my @cmd = (@git, qw(hash-object));
1699                 push @cmd, qw(-w) if $rewriting;
1700                 push @cmd, qw(-t commit), $cf;
1701                 my $newcommit = cmdoutput @cmd;
1702                 confess "$ch ?" unless $rewriting
1703                     or $newcommit eq $cl->{CommitId};
1704                 $build = $newcommit;
1705             } else {
1706                 $build = $cl->{CommitId};
1707                 trees_diff_walk "$want_upstream:", "$build:", sub {
1708                     my ($n) = @_;
1709                     no warnings qw(exiting);
1710                     next if $n eq 'debian/';
1711                     confess "mismatch @_ ?";
1712                 };
1713                 trees_diff_walk "$want_debian:debian", "$build:debian", sub {
1714                     confess "mismatch @_ ?";
1715                 };
1716                 my @old_parents = map { $_->{CommitId} } @{ $cl->{Parents} };
1717                 confess "mismatch @parents != @old_parents ?"
1718                     unless "@parents" eq "@old_parents";
1719             }
1720             if (grep { $method eq $_ } qw(DgitImportUpstreamUpdate)) {
1721                 $last_anchor = $cur;
1722             }
1723         }
1724     };
1725
1726     my $final_check = get_differs $build, $input;
1727     confess sprintf "internal error %#x %s %s", $final_check, $input, $build
1728         if $final_check & ~D_PAT_ADD;
1729
1730     my @r = ($build, $breakwater, $last_anchor);
1731     printdebug "*** WALK RETURN @r\n";
1732     return @r
1733 }
1734
1735 sub get_head () {
1736     git_check_unmodified();
1737     return git_rev_parse qw(HEAD);
1738 }
1739
1740 sub update_head ($$$) {
1741     my ($old, $new, $mrest) = @_;
1742     push @deferred_updates, "update HEAD $new $old";
1743     run_deferred_updates $mrest;
1744 }
1745
1746 sub update_head_checkout ($$$) {
1747     my ($old, $new, $mrest) = @_;
1748     update_head $old, $new, $mrest;
1749     runcmd @git, qw(reset --hard);
1750 }
1751
1752 sub update_head_postlaunder ($$$) {
1753     my ($old, $tip, $reflogmsg) = @_;
1754     return if $tip eq $old && !@deferred_updates;
1755     print "$us: laundered (head was $old)\n";
1756     update_head $old, $tip, $reflogmsg;
1757     # no tree changes except debian/patches
1758     runcmd @git, qw(rm --quiet --ignore-unmatch -rf debian/patches);
1759 }
1760
1761 sub currently_rebasing() {
1762     foreach (qw(rebase-merge rebase-apply)) {
1763         return 1 if stat_exists "$maindir_gitdir/$_";
1764     }
1765     return 0;
1766 }
1767
1768 sub bail_if_rebasing() {
1769     fail "you are in the middle of a git-rebase already"
1770         if currently_rebasing();
1771 }
1772
1773 sub do_launder_head ($) {
1774     my ($reflogmsg) = @_;
1775     my $old = get_head();
1776     record_ffq_auto();
1777     my ($tip,$breakwater) = walk $old;
1778     snags_maybe_bail();
1779     update_head_postlaunder $old, $tip, $reflogmsg;
1780     return ($tip,$breakwater);
1781 }
1782
1783 sub cmd_launder_v0 () {
1784     badusage "no arguments to launder-v0 allowed" if @ARGV;
1785     my $old = get_head();
1786     my ($tip,$breakwater,$last_anchor) = walk $old;
1787     update_head_postlaunder $old, $tip, 'launder';
1788     printf "# breakwater tip\n%s\n", $breakwater;
1789     printf "# working tip\n%s\n", $tip;
1790     printf "# last anchor\n%s\n", $last_anchor;
1791 }
1792
1793 sub defaultcmd_rebase () {
1794     push @ARGV, @{ $opt_defaultcmd_interactive // [] };
1795     my ($tip,$breakwater) = do_launder_head 'launder for rebase';
1796     runcmd @git, qw(rebase), @ARGV, $breakwater if @ARGV;
1797 }
1798
1799 sub cmd_analyse () {
1800     badusage "analyse does not support any options"
1801         if @ARGV and $ARGV[0] =~ m/^-/;
1802     badusage "too many arguments to analyse" if @ARGV>1;
1803     my ($old) = @ARGV;
1804     if (defined $old) {
1805         $old = git_rev_parse $old;
1806     } else {
1807         $old = git_rev_parse 'HEAD';
1808     }
1809     my ($dummy,$breakwater) = walk $old, 1,*STDOUT;
1810     STDOUT->error and confess $!;
1811 }
1812
1813 sub ffq_check ($;$$) {
1814     # calls $ff and/or $notff zero or more times
1815     # then returns either (status,message) where status is
1816     #    exists
1817     #    detached
1818     #    weird-symref
1819     #    notbranch
1820     # or (undef,undef, $ffq_prev,$gdrlast)
1821     # $ff and $notff are called like this:
1822     #   $ff->("message for stdout\n");
1823     #   $notff->('snag-name', $message);
1824     # normally $currentval should be HEAD
1825     my ($currentval, $ff, $notff) =@_;
1826
1827     $ff //= sub { print $_[0] or confess $!; };
1828     $notff //= \&snag;
1829
1830     my ($status, $message, $current, $ffq_prev, $gdrlast)
1831         = ffq_prev_branchinfo();
1832     return ($status, $message) unless $status eq 'branch';
1833
1834     my $exists = git_get_ref $ffq_prev;
1835     return ('exists',"$ffq_prev already exists") if $exists;
1836
1837     return ('not-branch', 'HEAD symref is not to refs/heads/')
1838         unless $current =~ m{^refs/heads/};
1839     my $branch = $';
1840
1841     my @check_specs = split /\;/, (cfg "branch.$branch.ffq-ffrefs",1) // '*';
1842     my %checked;
1843
1844     printdebug "ffq check_specs @check_specs\n";
1845
1846     my $check = sub {
1847         my ($lrref, $desc) = @_;
1848         printdebug "ffq might check $lrref ($desc)\n";
1849         my $invert;
1850         for my $chk (@check_specs) {
1851             my $glob = $chk;
1852             $invert = $glob =~ s{^[!^]}{};
1853             last if fnmatch $glob, $lrref;
1854         }
1855         return if $invert;
1856         my $lrval = git_get_ref $lrref;
1857         return unless length $lrval;
1858
1859         if (is_fast_fwd $lrval, $currentval) {
1860             $ff->("OK, you are ahead of $lrref\n");
1861             $checked{$lrref} = 1;
1862         } elsif (is_fast_fwd $currentval, $lrval) {
1863             $checked{$lrref} = -1;
1864             $notff->('behind', "you are behind $lrref, divergence risk");
1865         } else {
1866             $checked{$lrref} = -1;
1867             $notff->('diverged', "you have diverged from $lrref");
1868         }
1869     };
1870
1871     my $merge = cfg "branch.$branch.merge",1;
1872     if (defined $merge and $merge =~ m{^refs/heads/}) {
1873         my $rhs = $';
1874         printdebug "ffq merge $rhs\n";
1875         my $check_remote = sub {
1876             my ($remote, $desc) = @_;
1877             printdebug "ffq check_remote ".($remote//'undef')." $desc\n";
1878             return unless defined $remote;
1879             $check->("refs/remotes/$remote/$rhs", $desc);
1880         };
1881         $check_remote->((scalar cfg "branch.$branch.remote",1),
1882                         'remote fetch/merge branch');
1883         $check_remote->((scalar cfg "branch.$branch.pushRemote",1) //
1884                         (scalar cfg "branch.$branch.pushDefault",1),
1885                         'remote push branch');
1886     }
1887     if ($branch =~ m{^dgit/}) {
1888         $check->("refs/remotes/dgit/$branch", 'remote dgit branch');
1889     } elsif ($branch =~ m{^master$}) {
1890         $check->("refs/remotes/dgit/dgit/sid", 'remote dgit branch for sid');
1891     }
1892     return (undef, undef, $ffq_prev, $gdrlast);
1893 }
1894
1895 sub record_ffq_prev_deferred () {
1896     # => ('status', "message")
1897     # 'status' may be
1898     #    deferred          message is undef
1899     #    exists
1900     #    detached
1901     #    weird-symref
1902     #    notbranch
1903     # if not ff from some branch we should be ff from, is an snag
1904     # if "deferred", will have added something about that to
1905     #   @deferred_update_messages, and also maybe printed (already)
1906     #   some messages about ff checks
1907     bail_if_rebasing();
1908     my $currentval = get_head();
1909
1910     my ($status,$message, $ffq_prev,$gdrlast) = ffq_check $currentval;
1911     return ($status,$message) if defined $status;
1912
1913     snags_maybe_bail();
1914
1915     push @deferred_updates, "update $ffq_prev $currentval $git_null_obj";
1916     push @deferred_updates, "delete $gdrlast";
1917     push @deferred_update_messages, "Recorded previous head for preservation";
1918     return ('deferred', undef);
1919 }
1920
1921 sub record_ffq_auto () {
1922     my ($status, $message) = record_ffq_prev_deferred();
1923     if ($status eq 'deferred' || $status eq 'exists') {
1924     } else {
1925         snag $status, "could not record ffq-prev: $message";
1926         snags_maybe_bail();
1927     }
1928 }
1929
1930 sub ffq_prev_info () {
1931     bail_if_rebasing();
1932     # => ($ffq_prev, $gdrlast, $ffq_prev_commitish)
1933     my ($status, $message, $current, $ffq_prev, $gdrlast)
1934         = ffq_prev_branchinfo();
1935     if ($status ne 'branch') {
1936         snag $status, "could not check ffq-prev: $message";
1937         snags_maybe_bail();
1938     }
1939     my $ffq_prev_commitish = $ffq_prev && git_get_ref $ffq_prev;
1940     return ($ffq_prev, $gdrlast, $ffq_prev_commitish);
1941 }
1942
1943 sub stitch ($$$$$) {
1944     my ($old_head, $ffq_prev, $gdrlast, $ffq_prev_commitish, $prose) = @_;
1945
1946     push @deferred_updates, "delete $ffq_prev $ffq_prev_commitish";
1947
1948     if (is_fast_fwd $old_head, $ffq_prev_commitish) {
1949         my $differs = get_differs $old_head, $ffq_prev_commitish;
1950         unless ($differs & ~D_PAT_ADD) {
1951             # ffq-prev is ahead of us, and the only tree changes it has
1952             # are possibly addition of things in debian/patches/.
1953             # Just wind forwards rather than making a pointless pseudomerge.
1954             record_gdrlast $gdrlast, $ffq_prev_commitish;
1955             update_head_checkout $old_head, $ffq_prev_commitish,
1956                 "stitch (fast forward)";
1957             return;
1958         }
1959     }
1960     fresh_workarea();
1961     # We make pseudomerges with L as the contributing parent.
1962     # This makes git rev-list --first-parent work properly.
1963     my $new_head = make_commit [ $old_head, $ffq_prev ], [
1964         'Declare fast forward / record previous work',
1965         "[git-debrebase pseudomerge: $prose]",
1966     ];
1967     record_gdrlast $gdrlast, $new_head;
1968     update_head $old_head, $new_head, "stitch: $prose";
1969 }
1970
1971 sub do_stitch ($;$) {
1972     my ($prose, $unclean) = @_;
1973
1974     my ($ffq_prev, $gdrlast, $ffq_prev_commitish) = ffq_prev_info();
1975     if (!$ffq_prev_commitish) {
1976         fail "No ffq-prev to stitch." unless $opt_noop_ok;
1977         return;
1978     }
1979     my $dangling_head = get_head();
1980
1981     keycommits $dangling_head, $unclean,$unclean,$unclean;
1982     snags_maybe_bail();
1983
1984     stitch($dangling_head, $ffq_prev, $gdrlast, $ffq_prev_commitish, $prose);
1985 }
1986
1987 sub upstream_commitish_search ($$) {
1988     my ($upstream_version, $tried) = @_;
1989     # todo: at some point maybe use git-deborig to do this
1990     foreach my $tagpfx ('', 'v', 'upstream/') {
1991         my $tag = $tagpfx.(dep14_version_mangle $upstream_version);
1992         my $new_upstream = git_get_ref "refs/tags/$tag";
1993         push @$tried, $tag;
1994         return $new_upstream if length $new_upstream;
1995     }
1996 }
1997
1998 sub resolve_upstream_version ($$) {
1999     my ($new_upstream, $upstream_version) = @_;
2000
2001     if (!defined $new_upstream) {
2002         my @tried;
2003         $new_upstream = upstream_commitish_search $upstream_version, \@tried;
2004         if (!length $new_upstream) {
2005             fail "Could not determine appropriate upstream commitish.\n".
2006                 " (Tried these tags: @tried)\n".
2007                 " Check version, and specify upstream commitish explicitly.";
2008         }
2009     }
2010     $new_upstream = git_rev_parse $new_upstream;
2011
2012     return $new_upstream;
2013 }
2014
2015 sub cmd_new_upstream () {
2016     # automatically and unconditionally launders before rebasing
2017     # if rebase --abort is used, laundering has still been done
2018
2019     my %pieces;
2020
2021     badusage "need NEW-VERSION [UPS-COMMITTISH]" unless @ARGV >= 1;
2022
2023     # parse args - low commitment
2024     my $spec_version = shift @ARGV;
2025     my $new_version = (new Dpkg::Version $spec_version, check => 1);
2026     fail "bad version number \`$spec_version'" unless defined $new_version;
2027     if ($new_version->is_native()) {
2028         $new_version = (new Dpkg::Version "$spec_version-1", check => 1);
2029     }
2030
2031     my $new_upstream = shift @ARGV;
2032     my $new_upstream_version = upstreamversion  $new_version;
2033     $new_upstream =
2034         resolve_upstream_version $new_upstream, $new_upstream_version;
2035
2036     record_ffq_auto();
2037
2038     my $piece = sub {
2039         my ($n, @x) = @_; # may be ''
2040         my $pc = $pieces{$n} //= {
2041             Name => $n,
2042             Desc => ($n ? "upstream piece \`$n'" : "upstream (main piece"),
2043         };
2044         while (my $k = shift @x) { $pc->{$k} = shift @x; }
2045         $pc;
2046     };
2047
2048     my @newpieces;
2049     my $newpiece = sub {
2050         my ($n, @x) = @_; # may be ''
2051         my $pc = $piece->($n, @x, NewIx => (scalar @newpieces));
2052         push @newpieces, $pc;
2053     };
2054
2055     $newpiece->('',
2056         OldIx => 0,
2057         New => $new_upstream,
2058     );
2059     while (@ARGV && $ARGV[0] !~ m{^-}) {
2060         my $n = shift @ARGV;
2061
2062         badusage "for each EXTRA-UPS-NAME need EXTRA-UPS-COMMITISH"
2063             unless @ARGV && $ARGV[0] !~ m{^-};
2064
2065         my $c = git_rev_parse shift @ARGV;
2066         confess unless $n =~ m/^$extra_orig_namepart_re$/;
2067         $newpiece->($n, New => $c);
2068     }
2069
2070     # now we need to investigate the branch this generates the
2071     # laundered version but we don't switch to it yet
2072     my $old_head = get_head();
2073     my ($old_laundered_tip,$old_bw,$old_anchor) = walk $old_head;
2074
2075     my $old_bw_cl = classify $old_bw;
2076     my $old_anchor_cl = classify $old_anchor;
2077     my $old_upstream;
2078     if (!$old_anchor_cl->{OrigParents}) {
2079         snag 'anchor-treated',
2080  __ 'old anchor is recognised due to --anchor, cannot check upstream';
2081     } else {
2082         $old_upstream = parsecommit
2083             $old_anchor_cl->{OrigParents}[0]{CommitId};
2084         $piece->('', Old => $old_upstream->{CommitId});
2085     }
2086
2087     if ($old_upstream && $old_upstream->{Msg} =~ m{^\[git-debrebase }m) {
2088         if ($old_upstream->{Msg} =~
2089  m{^\[git-debrebase upstream-combine (\.(?: $extra_orig_namepart_re)+)\:.*\]$}m
2090            ) {
2091             my @oldpieces = (split / /, $1);
2092             my $old_n_parents = scalar @{ $old_upstream->{Parents} };
2093             if ($old_n_parents != @oldpieces &&
2094                 $old_n_parents != @oldpieces + 1) {
2095                 snag 'upstream-confusing', sprintf
2096                     "previous upstream combine %s".
2097                     " mentions %d pieces (each implying one parent)".
2098                     " but has %d parents".
2099                     " (one per piece plus maybe a previous combine)",
2100                     $old_upstream->{CommitId},
2101                     (scalar @oldpieces),
2102                     $old_n_parents;
2103             } elsif ($oldpieces[0] ne '.') {
2104                 snag 'upstream-confusing', sprintf
2105                     "previous upstream combine %s".
2106                     " first piece is not \`.'",
2107                     $oldpieces[0];
2108             } else {
2109                 $oldpieces[0] = '';
2110                 foreach my $i (0..$#oldpieces) {
2111                     my $n = $oldpieces[$i];
2112                     my $hat = 1 + $i + ($old_n_parents - @oldpieces);
2113                     $piece->($n, Old => $old_upstream->{CommitId}.'^'.$hat);
2114                 }
2115             }
2116         } else {
2117             snag 'upstream-confusing',
2118                 "previous upstream $old_upstream->{CommitId} is from".
2119                " git-debrebase but not an \`upstream-combine' commit";
2120         }
2121     }
2122
2123     foreach my $pc (values %pieces) {
2124         if (!$old_upstream) {
2125             # we have complained already
2126         } elsif (!$pc->{Old}) {
2127             snag 'upstream-new-piece',
2128                 "introducing upstream piece \`$pc->{Name}'";
2129         } elsif (!$pc->{New}) {
2130             snag 'upstream-rm-piece',
2131                 "dropping upstream piece \`$pc->{Name}'";
2132         } elsif (!is_fast_fwd $pc->{Old}, $pc->{New}) {
2133             snag 'upstream-not-ff',
2134                 "not fast forward: $pc->{Name} $pc->{Old}..$pc->{New}";
2135         }
2136     }
2137
2138     printdebug "%pieces = ", (dd \%pieces), "\n";
2139     printdebug "\@newpieces = ", (dd \@newpieces), "\n";
2140
2141     snags_maybe_bail();
2142
2143     my $new_bw;
2144
2145     fresh_workarea();
2146     in_workarea sub {
2147         my @upstream_merge_parents;
2148
2149         if (!any_snags()) {
2150             push @upstream_merge_parents, $old_upstream->{CommitId};
2151         }
2152
2153         foreach my $pc (@newpieces) { # always has '' first
2154             if ($pc->{Name}) {
2155                 read_tree_subdir $pc->{Name}, $pc->{New};
2156             } else {
2157                 runcmd @git, qw(read-tree), $pc->{New};
2158             }
2159             push @upstream_merge_parents, $pc->{New};
2160         }
2161
2162         # index now contains the new upstream
2163
2164         if (@newpieces > 1) {
2165             # need to make the upstream subtree merge commit
2166             $new_upstream = make_commit \@upstream_merge_parents,
2167                 [ "Combine upstreams for $new_upstream_version",
2168  ("[git-debrebase upstream-combine . ".
2169  (join " ", map { $_->{Name} } @newpieces[1..$#newpieces]).
2170  ": new upstream]"),
2171                 ];
2172         }
2173
2174         # $new_upstream is either the single upstream commit, or the
2175         # combined commit we just made.  Either way it will be the
2176         # "upstream" parent of the anchor merge.
2177
2178         read_tree_subdir 'debian', "$old_bw:debian";
2179
2180         # index now contains the anchor merge contents
2181         $new_bw = make_commit [ $old_bw, $new_upstream ],
2182             [ "Update to upstream $new_upstream_version",
2183  "[git-debrebase anchor: new upstream $new_upstream_version, merge]",
2184             ];
2185
2186         # Now we have to add a changelog stanza so the Debian version
2187         # is right.  We use debchange to do this.  Invoking debchange
2188         # here is a bit fiddly because it has a lot of optional
2189         # exciting behaviours, some of which will break stuff, and
2190         # some of which won't work in a playtree.
2191
2192         # Make debchange use git's idea of the user's identity.
2193         # That way, if the user never uses debchange et al, configuring
2194         # git is enough.
2195         my $usetup = sub {
2196             my ($e, $k) = @_;
2197             my $v = cfg $k, 1;
2198             defined $v or return;
2199             $ENV{$e} = $v;
2200         };
2201         $usetup->('DEBEMAIL',    'user.email');
2202         $usetup->('DEBFULLNAME', 'user.name');
2203
2204 sleep 2;
2205
2206         my @dch = (qw(debchange
2207                       --allow-lower-version .*
2208                       --no-auto-nmu
2209                       --preserve
2210                       --vendor=Unknown-Vendor
2211                       --changelog debian/changelog
2212                       --check-dirname-level 0
2213                       --release-heuristic=changelog
2214                       -v), $new_version,
2215                    "Update to new upstream version $new_upstream_version.");
2216
2217         runcmd @git, qw(checkout -q debian/changelog);
2218         runcmd @dch;
2219         runcmd @git, qw(update-index --add --replace), 'debian/changelog';
2220
2221         # Now we have the final new breakwater branch in the index
2222         $new_bw = make_commit [ $new_bw ],
2223             [ "Update changelog for new upstream $new_upstream_version",
2224               "[git-debrebase changelog: new upstream $new_upstream_version]",
2225             ];
2226     };
2227
2228     # we have constructed the new breakwater. we now need to commit to
2229     # the laundering output, because git-rebase can't easily be made
2230     # to make a replay list which is based on some other branch
2231
2232     update_head_postlaunder $old_head, $old_laundered_tip,
2233         'launder for new upstream';
2234
2235     my @cmd = (@git, qw(rebase --onto), $new_bw, $old_bw, @ARGV);
2236     local $ENV{GIT_REFLOG_ACTION} = git_reflog_action_msg
2237         "debrebase new-upstream $new_version: rebase";
2238     runcmd @cmd;
2239     # now it's for the user to sort out
2240 }
2241
2242 sub cmd_record_ffq_prev () {
2243     badusage "no arguments allowed" if @ARGV;
2244     my ($status, $msg) = record_ffq_prev_deferred();
2245     if ($status eq 'exists' && $opt_noop_ok) {
2246         print "Previous head already recorded\n" or confess $!;
2247     } elsif ($status eq 'deferred') {
2248         run_deferred_updates 'record-ffq-prev';
2249     } else {
2250         fail "Could not preserve: $msg";
2251     }
2252 }
2253
2254 sub cmd_anchor () {
2255     badusage "no arguments allowed" if @ARGV;
2256     my ($anchor, $bw) = keycommits +(git_rev_parse 'HEAD'), 0,0;
2257     print "$bw\n" or confess $!;
2258 }
2259
2260 sub cmd_breakwater () {
2261     badusage "no arguments allowed" if @ARGV;
2262     my ($anchor, $bw) = keycommits +(git_rev_parse 'HEAD'), 0,0;
2263     print "$bw\n" or confess $!;
2264 }
2265
2266 sub cmd_status () {
2267     badusage "no arguments allowed" if @ARGV;
2268
2269     # todo: gdr status should print divergence info
2270     # todo: gdr status should print upstream component(s) info
2271     # todo: gdr should leave/maintain some refs with this kind of info ?
2272
2273     my $oldest = { Badness => 0 };
2274     my $newest;
2275     my $note = sub {
2276         my ($badness, $ourmsg, $snagname, $dummy, $cl, $kcmsg) = @_;
2277         if ($oldest->{Badness} < $badness) {
2278             $oldest = $newest = undef;
2279         }
2280         $oldest = {
2281                    Badness => $badness,
2282                    CommitId => $cl->{CommitId},
2283                    OurMsg => $ourmsg,
2284                    KcMsg => $kcmsg,
2285                   };
2286         $newest //= $oldest;
2287     };
2288     my ($anchor, $bw) = keycommits +(git_rev_parse 'HEAD'),
2289         sub { $note->(1, 'branch contains furniture (not laundered)', @_); },
2290         sub { $note->(2, 'branch is unlaundered', @_); },
2291         sub { $note->(3, 'branch needs laundering', @_); },
2292         sub { $note->(4, 'branch not in git-debrebase form', @_); };
2293
2294     my $prcommitinfo = sub {
2295         my ($cid) = @_;
2296         flush STDOUT or confess $!;
2297         runcmd @git, qw(--no-pager log -n1),
2298             '--pretty=format:    %h %s%n',
2299             $cid;
2300     };
2301
2302     print "current branch contents, in git-debrebase terms:\n";
2303     if (!$oldest->{Badness}) {
2304         print "  branch is laundered\n";
2305     } else {
2306         print "  $oldest->{OurMsg}\n";
2307         my $printed = '';
2308         foreach my $info ($oldest, $newest) {
2309             my $cid = $info->{CommitId};
2310             next if $cid eq $printed;
2311             $printed = $cid;
2312             print "  $info->{KcMsg}\n";
2313             $prcommitinfo->($cid);
2314         }
2315     }
2316
2317     my $prab = sub {
2318         my ($cid, $what) = @_;
2319         if (!defined $cid) {
2320             print "  $what is not well-defined\n";
2321         } else {
2322             print "  $what\n";
2323             $prcommitinfo->($cid);
2324         }
2325     };
2326     print "key git-debrebase commits:\n";
2327     $prab->($anchor, 'anchor');
2328     $prab->($bw, 'breakwater');
2329
2330     my ($ffqstatus, $ffq_msg, $current, $ffq_prev, $gdrlast) =
2331         ffq_prev_branchinfo();
2332
2333     print "branch and ref status, in git-debrebase terms:\n";
2334     if ($ffq_msg) {
2335         print "  $ffq_msg\n";
2336     } else {
2337         $ffq_prev = git_get_ref $ffq_prev;
2338         $gdrlast = git_get_ref $gdrlast;
2339         if ($ffq_prev) {
2340             print "  unstitched; previous tip was:\n";
2341             $prcommitinfo->($ffq_prev);
2342         } elsif (!$gdrlast) {
2343             print "  stitched? (no record of git-debrebase work)\n";
2344         } elsif (is_fast_fwd $gdrlast, 'HEAD') {
2345             print "  stitched\n";
2346         } else {
2347             print "  not git-debrebase (diverged since last stitch)\n"
2348         }
2349     }
2350     print "you are currently rebasing\n" if currently_rebasing();
2351 }
2352
2353 sub cmd_stitch () {
2354     my $prose = 'stitch';
2355     getoptions("stitch",
2356                'prose=s', \$prose);
2357     badusage "no arguments allowed" if @ARGV;
2358     do_stitch $prose, 0;
2359 }
2360 sub cmd_prepush () {
2361     $opt_noop_ok = 1;
2362     cmd_stitch();
2363 }
2364
2365 sub cmd_quick () {
2366     badusage "no arguments allowed" if @ARGV;
2367     do_launder_head 'launder for git-debrebase quick';
2368     do_stitch 'quick';
2369 }
2370
2371 sub cmd_conclude () {
2372     my ($ffq_prev, $gdrlast, $ffq_prev_commitish) = ffq_prev_info();
2373     if (!$ffq_prev_commitish) {
2374         fail "No ongoing git-debrebase session." unless $opt_noop_ok;
2375         return;
2376     }
2377     my $dangling_head = get_head();
2378
2379     badusage "no arguments allowed" if @ARGV;
2380     do_launder_head 'launder for git-debrebase quick';
2381     do_stitch 'quick';
2382 }
2383
2384 sub cmd_scrap () {
2385     if (currently_rebasing()) {
2386         runcmd @git, qw(rebase --abort);
2387         push @deferred_updates, 'verify HEAD HEAD';
2388         # noop, but stops us complaining that scrap was a noop
2389     }
2390     badusage "no arguments allowed" if @ARGV;
2391     my ($ffq_prev, $gdrlast, $ffq_prev_commitish) = ffq_prev_info();
2392     my $scrapping_head;
2393     if ($ffq_prev_commitish) {
2394         $scrapping_head = get_head();
2395         push @deferred_updates,
2396             "update $gdrlast $ffq_prev_commitish $git_null_obj",
2397             "update $ffq_prev $git_null_obj $ffq_prev_commitish";
2398     }
2399     if (git_get_ref $merge_cache_ref) {
2400         push @deferred_updates,
2401             "delete $merge_cache_ref";
2402     }
2403     if (!@deferred_updates) {
2404         fail "No ongoing git-debrebase session." unless $opt_noop_ok;
2405         finish 0;
2406     }
2407     snags_maybe_bail();
2408     if ($scrapping_head) {
2409         update_head_checkout $scrapping_head, $ffq_prev_commitish, "scrap";
2410     } else {
2411         run_deferred_updates "scrap";
2412     }
2413 }
2414
2415 sub make_patches_staged ($) {
2416     my ($head) = @_;
2417     # Produces the patches that would result from $head if it were
2418     # laundered.
2419     my ($secret_head, $secret_bw, $last_anchor) = walk $head;
2420     fresh_workarea();
2421     my $any;
2422     in_workarea sub {
2423         $any = gbp_pq_export 'bw', $secret_bw, $secret_head;
2424     };
2425     return $any;
2426 }
2427
2428 sub make_patches ($) {
2429     my ($head) = @_;
2430     keycommits $head, 0, \&snag;
2431     my $any = make_patches_staged $head;
2432     my $out;
2433     in_workarea sub {
2434         my $ptree = !$any ? undef :
2435             cmdoutput @git, qw(write-tree --prefix=debian/patches/);
2436         runcmd @git, qw(read-tree), $head;
2437         if ($ptree) {
2438             read_tree_subdir 'debian/patches', $ptree;
2439         } else {
2440             rm_subdir_cached 'debian/patches';
2441         }
2442         $out = make_commit [$head], [
2443             'Commit patch queue (exported by git-debrebase)',
2444             '[git-debrebase make-patches: export and commit patches]',
2445         ];
2446     };
2447     return $out;
2448 }
2449
2450 sub cmd_make_patches () {
2451     my $opt_quiet_would_amend;
2452     getoptions("make-patches",
2453                'quiet-would-amend!', \$opt_quiet_would_amend);
2454     badusage "no arguments allowed" if @ARGV;
2455     bail_if_rebasing();
2456     my $old_head = get_head();
2457     my $new = make_patches $old_head;
2458     my $d = get_differs $old_head, $new;
2459     if ($d == 0) {
2460         fail "No (more) patches to export." unless $opt_noop_ok;
2461         return;
2462     } elsif ($d == D_PAT_ADD) {
2463         snags_maybe_bail();
2464         update_head_checkout $old_head, $new, 'make-patches';
2465     } else {
2466         print STDERR failmsg
2467             "Patch export produced patch amendments".
2468             " (abandoned output commit $new).".
2469             "  Try laundering first."
2470             unless $opt_quiet_would_amend;
2471         finish 7;
2472     }
2473 }
2474
2475 sub check_series_has_all_patches ($) {
2476     my ($head) = @_;
2477     my $seriesfn = 'debian/patches/series';
2478     my ($dummy, $series) = git_cat_file "$head:$seriesfn",
2479         [qw(blob missing)];
2480     $series //= '';
2481     my %series;
2482     our $comments_snagged;
2483     foreach my $f (grep /\S/, grep {!m/^\s\#/} split /\n/, $series) {
2484         if ($f =~ m/^\s*\#/) {
2485             snag 'series-comments',
2486                 "$seriesfn contains comments, which will be discarded"
2487                 unless $comments_snagged++;
2488             next;
2489         }
2490         fail "patch $f repeated in $seriesfn !" if $series{$f}++;
2491     }
2492     foreach my $patchfile (get_tree "$head:debian/patches", 1,1) {
2493         my ($f,$i) = @$patchfile;
2494         next if $series{$f};
2495         next if $f eq 'series';
2496         snag 'unused-patches', "Unused patch file $f will be discarded";
2497     }
2498 }
2499
2500 sub begin_convert_from () {
2501     my $head = get_head();
2502     my ($ffqs, $ffqm, $symref, $ffq_prev, $gdrlast) = ffq_prev_branchinfo();
2503
2504     fail "ffq-prev exists, this is already managed by git-debrebase!"
2505         if $ffq_prev && git_get_ref $ffq_prev;
2506
2507     my $gdrlast_obj = $gdrlast && git_get_ref $gdrlast;
2508     snag 'already-converted',
2509         "ahead of debrebase-last, this is already managed by git-debrebase!"
2510         if $gdrlast_obj && is_fast_fwd $gdrlast_obj, $head;
2511     return ($head, { LastRef => $gdrlast, LastObj => $gdrlast_obj });
2512 }
2513
2514 sub complete_convert_from ($$$$) {
2515     my ($old_head, $new_head, $gi, $mrest) = @_;
2516     ffq_check $new_head;
2517     record_gdrlast $gi->{LastRef}, $new_head, $gi->{LastObj}
2518         if $gi->{LastRef};
2519     snags_maybe_bail();
2520     update_head_checkout $old_head, $new_head, $mrest;
2521 }
2522
2523 sub cmd_convert_from_gbp () {
2524     badusage "want only 1 optional argument, the upstream git commitish"
2525         unless @ARGV<=1;
2526
2527     my $clogp = parsechangelog();
2528     my $version = $clogp->{'Version'}
2529         // die "missing Version from changelog\n";
2530
2531     my ($upstream_spec) = @ARGV;
2532
2533     my $upstream_version = upstreamversion $version;
2534     my $upstream =
2535         resolve_upstream_version($upstream_spec, $upstream_version);
2536
2537     my ($old_head, $gdrlastinfo) = begin_convert_from();
2538
2539     my $upsdiff = get_differs $upstream, $old_head;
2540     if ($upsdiff & D_UPS) {
2541         runcmd @git, qw(--no-pager diff --stat),
2542             $upstream, $old_head,
2543             qw( -- :!/debian :/);
2544         fail <<END;
2545 upstream ($upstream_spec) and HEAD are not
2546 identical in upstream files.  See diffstat above, or run
2547   git diff $upstream_spec HEAD -- :!/debian :/
2548 END
2549     }
2550
2551     if (!is_fast_fwd $upstream, $old_head) {
2552         snag 'upstream-not-ancestor',
2553             "upstream ($upstream) is not an ancestor of HEAD";
2554     } else {
2555         my $wrong = cmdoutput
2556             (@git, qw(rev-list --ancestry-path), "$upstream..HEAD",
2557              qw(-- :/ :!/debian));
2558         if (length $wrong) {
2559             snag 'unexpected-upstream-changes',
2560                 "history between upstream ($upstream) and HEAD contains direct changes to upstream files - are you sure this is a gbp (patches-unapplied) branch?";
2561             print STDERR "list expected changes with:  git log --stat --ancestry-path $upstream_spec..HEAD -- :/ ':!/debian'\n";
2562         }
2563     }
2564
2565     if ((git_cat_file "$upstream:debian")[0] ne 'missing') {
2566         snag 'upstream-has-debian',
2567             "upstream ($upstream) contains debian/ directory";
2568     }
2569
2570     check_series_has_all_patches $old_head;
2571
2572     my $previous_dgit_view = eval {
2573         my @clogcmd = qw(dpkg-parsechangelog --format rfc822 -n2);
2574         my ($lvsn, $suite);
2575         parsechangelog_loop \@clogcmd, 'debian/changelog', sub {
2576             my ($stz, $desc) = @_;
2577             no warnings qw(exiting);
2578             printdebug 'CHANGELOG ', Dumper($desc, $stz);
2579             next unless $stz->{Date};
2580             next unless $stz->{Distribution} ne 'UNRELEASED';
2581             $lvsn = $stz->{Version};
2582             $suite = $stz->{Distribution};
2583             last;
2584         };
2585         die "neither of the first two changelog entries are released\n"
2586             unless defined $lvsn;
2587         print "last finished-looking changelog entry: ($lvsn) $suite\n";
2588         my $mtag_pat = debiantag_maintview $lvsn, '*';
2589         my $mtag = cmdoutput @git, qw(describe --always --abbrev=0 --match),
2590             $mtag_pat;
2591         die "could not find suitable maintainer view tag $mtag_pat\n"
2592             unless $mtag =~ m{/};
2593         is_fast_fwd $mtag, 'HEAD' or
2594             die "HEAD is not FF from maintainer tag $mtag!";
2595         my $dtag = "archive/$mtag";
2596         git_get_ref "refs/tags/$dtag" or
2597             die "dgit view tag $dtag not found\n";
2598         is_fast_fwd $mtag, $dtag or
2599             die "dgit view tag $dtag is not FF from maintainer tag $mtag\n";
2600         print "will stitch in dgit view, $dtag\n";
2601         git_rev_parse $dtag;
2602     };
2603     if (!$previous_dgit_view) {
2604         $@ =~ s/^\n+//;
2605         chomp $@;
2606         print STDERR <<END;
2607 Cannot confirm dgit view: $@
2608 Failed to stitch in dgit view (see messages above).
2609 dgit --overwrite will be needed on the first dgit push after conversion.
2610 END
2611     }
2612
2613     snags_maybe_bail_early();
2614
2615     my $work;
2616
2617     fresh_workarea();
2618     in_workarea sub {
2619         runcmd @git, qw(checkout -q -b gdr-internal), $old_head;
2620         # make a branch out of the patch queue - we'll want this in a mo
2621         runcmd qw(gbp pq import);
2622         # strip the patches out
2623         runcmd @git, qw(checkout -q gdr-internal~0);
2624         rm_subdir_cached 'debian/patches';
2625         $work = make_commit ['HEAD'], [
2626  'git-debrebase convert-from-gbp: drop patches from tree',
2627  'Delete debian/patches, as part of converting to git-debrebase format.',
2628  '[git-debrebase convert-from-gbp: drop patches from tree]'
2629                               ];
2630         # make the anchor merge
2631         # the tree is already exactly right
2632         $work = make_commit [$work, $upstream], [
2633  'git-debrebase import: declare upstream',
2634  'First breakwater merge.',
2635  '[git-debrebase anchor: declare upstream]'
2636                               ];
2637
2638         # rebase the patch queue onto the new breakwater
2639         runcmd @git, qw(reset --quiet --hard patch-queue/gdr-internal);
2640         runcmd @git, qw(rebase --quiet --onto), $work, qw(gdr-internal);
2641         $work = git_rev_parse 'HEAD';
2642
2643         if ($previous_dgit_view) {
2644             $work = make_commit [$work, $previous_dgit_view], [
2645  'git-debrebase import: declare ff from dgit archive view',
2646  '[git-debrebase pseudomerge: import-from-gbp]',
2647             ];
2648         }
2649     };
2650
2651     complete_convert_from $old_head, $work, $gdrlastinfo, 'convert-from-gbp';
2652     print <<END or confess $!;
2653 $us: converted from patched-unapplied (gbp) branch format, OK
2654 END
2655 }
2656
2657 sub cmd_convert_to_gbp () {
2658     badusage "no arguments allowed" if @ARGV;
2659     my $head = get_head();
2660     my (undef, undef, undef, $ffq, $gdrlast) = ffq_prev_branchinfo();
2661     my ($anchor, $breakwater) = keycommits $head, 0;
2662     my $out = $breakwater;
2663     my $any = make_patches_staged $head;
2664     if ($any) {
2665         in_workarea sub {
2666             $out = make_commit [$out], [
2667                 'Commit patch queue (converted from git-debrebase format)',
2668                 '[git-debrebase convert-to-gbp: commit patches]',
2669             ];
2670         };
2671     } else {
2672         # in this case, it can be fast forward
2673         $out = $head;
2674     }
2675     if (defined $ffq) {
2676         push @deferred_updates, "delete $ffq";
2677         push @deferred_updates, "delete $gdrlast";
2678     }
2679     snags_maybe_bail();
2680     update_head_checkout $head, $out, "convert to gbp (v0)";
2681     print <<END or confess $!;
2682 $us: converted to git-buildpackage branch format
2683 $us: WARNING: do not now run "git-debrebase" any more
2684 $us: WARNING: doing so would drop all upstream patches!
2685 END
2686 }
2687
2688 sub cmd_convert_from_dgit_view () {
2689     my $clogp = parsechangelog();
2690
2691     my $bpd = (cfg 'dgit.default.build-products-dir',1) // '..';
2692     my $do_origs = 1;
2693     my $do_tags = 1;
2694     my $always = 0;
2695     my $diagnose = 0;
2696
2697     getoptions("convert-from-dgit-view",
2698                'diagnose!', \$diagnose,
2699                'build-products-dir:s', \$bpd,
2700                'origs!', \$do_origs,
2701                'tags!', \$do_tags,
2702                'always-convert-anyway!', \$always);
2703     fail "takes 1 optional argument, the upstream commitish" if @ARGV>1;
2704
2705     my @upstreams;
2706
2707     if (@ARGV) {
2708         my $spec = shift @ARGV;
2709         my $commit = git_rev_parse "$spec^{commit}";
2710         push @upstreams, { Commit => $commit,
2711                            Source => "$ARGV[0], from command line",
2712                            Only => 1,
2713                          };
2714     }
2715
2716     my ($head, $gdrlastinfo) = begin_convert_from();
2717
2718     if (!$always) {
2719         my $troubles = 0;
2720         my $trouble = sub { $troubles++; };
2721         keycommits $head, sub{}, sub{}, $trouble, $trouble;
2722         printdebug "troubles=$troubles\n";
2723         if (!$troubles) {
2724             print STDERR <<END;
2725 $us: Branch already seems to be in git-debrebase format!
2726 $us: --always-convert-anyway would do the conversion operation anyway
2727 $us: but is probably a bad idea.  Probably, you wanted to do nothing.
2728 END
2729             fail "Branch already in git-debrebase format." unless $opt_noop_ok;
2730             finish 0;
2731         }
2732     }
2733
2734     check_series_has_all_patches $head;
2735
2736     snags_maybe_bail_early();
2737
2738     my $version = upstreamversion $clogp->{Version};
2739     print STDERR "Considering possible commits corresponding to upstream:\n";
2740
2741     if (!@upstreams) {
2742         if ($do_tags) {
2743             my @tried;
2744             my $ups_tag = upstream_commitish_search $version, \@tried;
2745             if ($ups_tag) {
2746                 my $this = "git tag $tried[-1]";
2747                 push @upstreams, { Commit => $ups_tag,
2748                                    Source => $this,
2749                                  };
2750             } else {
2751                 printf STDERR
2752                     " git tag: no suitable tag found (tried %s)\n",
2753                     "@tried";
2754             }
2755         }
2756         if ($do_origs) {
2757             my $p = $clogp->{'Source'};
2758             # we do a quick check to see if there are plausible origs
2759             my $something=0;
2760             if (!opendir BPD, $bpd) {
2761                 die "opendir build-products-dir $bpd: $!" unless $!==ENOENT;
2762             } else {
2763                 while ($!=0, my $f = readdir BPD) {
2764                     next unless is_orig_file_of_p_v $f, $p, $version;
2765                     printf STDERR
2766                         " orig: found what looks like a .orig, %s\n",
2767                         "$bpd/$f";
2768                     $something=1;
2769                     last;
2770                 }
2771                 confess "read $bpd: $!" if $!;
2772                 closedir BPD;
2773             }
2774             if ($something) {
2775                 my $tree = cmdoutput
2776                     @dgit, qw(--build-products-dir), $bpd,
2777                     qw(print-unapplied-treeish);
2778                 fresh_workarea();
2779                 in_workarea sub {
2780                     runcmd @git, qw(reset --quiet), $tree, qw(-- .);
2781                     rm_subdir_cached 'debian';
2782                     $tree = cmdoutput @git, qw(write-tree);
2783                     my $ups_synth = make_commit [], [ <<END, <<END,
2784 Import effective orig tree for upstream version $version
2785 END
2786 This includes the contents of the .orig(s), minus any debian/ directory.
2787
2788 [git-debrebase convert-from-dgit-view upstream-import-convert: $version]
2789 END
2790                                                     ];
2791                     push @upstreams, { Commit => $ups_synth,
2792                                        Source => "orig(s) imported via dgit",
2793                                      };
2794                 }
2795             } else {
2796                 printf STDERR
2797                     " orig: no suitable origs found (looked for %s in %s)\n",
2798                     "${p}_".(stripeoch $version)."...", $bpd;
2799             }
2800         }
2801     }
2802
2803     my $some_patches = stat_exists 'debian/patches/series';
2804
2805     print STDERR "Evaluating possible commits corresponding to upstream:\n";
2806
2807     my $result;
2808     foreach my $u (@upstreams) {
2809         my $work = $head;
2810         fresh_workarea();
2811         in_workarea sub {
2812             runcmd @git, qw(reset --quiet), $u->{Commit}, qw(-- .);
2813             runcmd @git, qw(checkout), $u->{Commit}, qw(-- .);
2814             runcmd @git, qw(clean -xdff);
2815             runcmd @git, qw(checkout), $head, qw(-- debian);
2816             if ($some_patches) {
2817                 rm_subdir_cached 'debian/patches';
2818                 $work = make_commit [ $work ], [
2819  'git-debrebase convert-from-dgit-view: drop upstream changes from breakwater',
2820  "Drop upstream changes, and delete debian/patches, as part of converting\n".
2821  "to git-debrebase format.  Upstream changes will appear as commits.",
2822  '[git-debrebase convert-from-dgit-view drop-patches]'
2823                                            ];
2824             }
2825             $work = make_commit [ $work, $u->{Commit} ], [
2826  'git-debrebase convert-from-dgit-view: declare upstream',
2827  '(Re)constructed breakwater merge.',
2828  '[git-debrebase anchor: declare upstream]'
2829                                                          ];
2830             runcmd @git, qw(checkout --quiet -b mk), $work;
2831             if ($some_patches) {
2832                 runcmd @git, qw(checkout), $head, qw(-- debian/patches);
2833                 runcmd @git, qw(reset --quiet);
2834                 my @gbp_cmd = (qw(gbp pq import));
2835                 if (!$diagnose) {
2836                     my $gbp_err = "../gbp-pq-err";
2837                     @gbp_cmd = shell_cmd "exec >$gbp_err 2>&1", @gbp_cmd;
2838                 }
2839                 my $r = system @gbp_cmd;
2840                 if ($r) {
2841                     printf STDERR
2842                         " %s: couldn't apply patches: gbp pq %s",
2843                         $u->{Source}, waitstatusmsg();
2844                     return;
2845                 }
2846             }
2847             my $work = git_rev_parse qw(HEAD);
2848             my $diffout = cmdoutput @git, qw(diff-tree --stat HEAD), $work;
2849             if (length $diffout) {
2850                 print STDERR
2851                     " $u->{Source}: applying patches gives different tree\n";
2852                 print STDERR $diffout if $diagnose;
2853                 return;
2854             }
2855             # OMG!
2856             $u->{Result} = $work;
2857             $result = $u;
2858         };
2859         last if $result;
2860     }
2861
2862     if (!$result) {
2863         fail <<END;
2864 Could not find or construct a suitable upstream commit.
2865 Rerun adding --diagnose after convert-from-dgit-view, or pass a
2866 upstream commmit explicitly or provide suitable origs.
2867 END
2868     }
2869
2870     printf STDERR "Yes, will base new branch on %s\n", $result->{Source};
2871
2872     complete_convert_from $head, $result->{Result}, $gdrlastinfo,
2873         'convert-from-dgit-view';
2874 }
2875
2876 sub cmd_forget_was_ever_debrebase () {
2877     badusage "forget-was-ever-debrebase takes no further arguments" if @ARGV;
2878     my ($ffqstatus, $ffq_msg, $current, $ffq_prev, $gdrlast) =
2879         ffq_prev_branchinfo();
2880     fail "Not suitable for recording git-debrebaseness anyway: $ffq_msg"
2881         if defined $ffq_msg;
2882     push @deferred_updates, "delete $ffq_prev";
2883     push @deferred_updates, "delete $gdrlast";
2884     snags_maybe_bail();
2885     run_deferred_updates "forget-was-ever-debrebase";
2886 }
2887
2888 sub cmd_record_resolved_merge () {
2889     badusage "record-resolved-merge takes no further arguments" if @ARGV;
2890     # MERGE-TODO needs documentation
2891     my $new = get_head();
2892     my $method;
2893
2894     print "Checking how you have resolved the merge problem\n";
2895     my $nope = sub { print "Not $method: @_"; 0; };
2896
2897     my $maybe = sub { print "Seems to be $method.\n"; };
2898     my $yes = sub {
2899         my ($key, $ref) = @_;
2900         reflog_cache_insert $merge_cache_ref, $key, $ref;
2901         print "OK.  You can switch branches and try git-debrebase again.\n";
2902         1;
2903     };
2904
2905     fresh_workarea 'merge';
2906     sub {
2907         $method = 'vanilla-merge patchqueue';
2908         my $vanilla = git_get_ref "$wrecknoteprefix/vanilla-merge";
2909         $vanilla or return $nope->("wreckage was not of vanilla-merge");
2910         foreach my $lr (qw(left right)) {
2911             my $n = "$wrecknoteprefix/$lr-patchqueue";
2912             my $lrpq = git_get_ref $n;
2913             $lrpq or return $nope->("wreckage did not contain patchqueues");
2914             is_fast_fwd $lrpq, $new or return $nope->("HEAD not ff of $n");
2915         }
2916         $maybe->();
2917         my $newbase = git_get_ref "$wrecknoteprefix/new-base"
2918             or die "wreckage element $wrecknoteprefix/new-base missing";
2919         my $result = merge_series_patchqueue_convert
2920             {}, $newbase, $new;
2921         $yes->("vanilla-merge $vanilla", $result);
2922         1;
2923     }->() or sub {
2924         fail "No resolved merge method seems applicable.\n";
2925     }->();
2926 }
2927
2928 sub cmd_downstream_rebase_launder_v0 () {
2929     badusage "needs 1 argument, the baseline" unless @ARGV==1;
2930     my ($base) = @ARGV;
2931     $base = git_rev_parse $base;
2932     my $old_head = get_head();
2933     my $current = $old_head;
2934     my $topmost_keep;
2935     for (;;) {
2936         if ($current eq $base) {
2937             $topmost_keep //= $current;
2938             print " $current BASE stop\n";
2939             last;
2940         }
2941         my $cl = classify $current;
2942         print " $current $cl->{Type}";
2943         my $keep = 0;
2944         my $p0 = $cl->{Parents}[0]{CommitId};
2945         my $next;
2946         if ($cl->{Type} eq 'Pseudomerge') {
2947             print " ^".($cl->{Contributor}{Ix}+1);
2948             $next = $cl->{Contributor}{CommitId};
2949         } elsif ($cl->{Type} eq 'AddPatches' or
2950                  $cl->{Type} eq 'Changelog') {
2951             print " strip";
2952             $next = $p0;
2953         } else {
2954             print " keep";
2955             $next = $p0;
2956             $keep = 1;
2957         }
2958         print "\n";
2959         if ($keep) {
2960             $topmost_keep //= $current;
2961         } else {
2962             die "to-be stripped changes not on top of the branch\n"
2963                 if $topmost_keep;
2964         }
2965         $current = $next;
2966     }
2967     if ($topmost_keep eq $old_head) {
2968         print "unchanged\n";
2969     } else {
2970         print "updating to $topmost_keep\n";
2971         update_head_checkout
2972             $old_head, $topmost_keep,
2973             'downstream-rebase-launder-v0';
2974     }
2975 }
2976
2977 setlocale(LC_MESSAGES, "");
2978 textdomain("git-debrebase");
2979
2980 getoptions_main
2981           ("bad options\n",
2982            "D+" => \$debuglevel,
2983            'noop-ok', => \$opt_noop_ok,
2984            'f=s' => \@snag_force_opts,
2985            'anchor=s' => \@opt_anchors,
2986            '--dgit=s' => \($dgit[0]),
2987            'force!',
2988            'experimental-merge-resolution!', \$opt_merges,
2989            '-i:s' => sub {
2990                my ($opt,$val) = @_;
2991                badusage f_ "%s: no cuddling to -i for git-rebase", $us
2992                    if length $val;
2993                confess if $opt_defaultcmd_interactive; # should not happen
2994                $opt_defaultcmd_interactive = [ qw(-i) ];
2995                # This access to @ARGV is excessive familiarity with
2996                # Getopt::Long, but there isn't another sensible
2997                # approach.  '-i=s{0,}' does not work with bundling.
2998                push @$opt_defaultcmd_interactive, @ARGV;
2999                @ARGV=();
3000            },
3001            'help' => sub { print __ $usage_message or confess $!; finish 0; },
3002            );
3003
3004 initdebug('git-debrebase ');
3005 enabledebug if $debuglevel;
3006
3007 my $toplevel = cmdoutput @git, qw(rev-parse --show-toplevel);
3008 chdir $toplevel or fail "chdir toplevel $toplevel: $!\n";
3009
3010 $rd = fresh_playground "$playprefix/misc";
3011
3012 @opt_anchors = map { git_rev_parse $_ } @opt_anchors;
3013
3014 if (!@ARGV || $opt_defaultcmd_interactive || $ARGV[0] =~ m{^-}) {
3015     defaultcmd_rebase();
3016 } else {
3017     my $cmd = shift @ARGV;
3018     my $cmdfn = $cmd;
3019     $cmdfn =~ y/-/_/;
3020     $cmdfn = ${*::}{"cmd_$cmdfn"};
3021
3022     $cmdfn or badusage f_ "unknown git-debrebase sub-operation %s", $cmd;
3023     $cmdfn->();
3024 }
3025
3026 finish 0;