git-debrebase

   1 #!/usr/bin/perl -w
   2 # git-debrebase
   3 # Script helping make fast-forwarding histories while still rebasing
   4 # upstream deltas when working on Debian packaging
   5 #
   6 # Copyright (C)2017,2018 Ian Jackson
   7 #
   8 # This program is free software: you can redistribute it and/or modify
   9 # it under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation, either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # This program is distributed in the hope that it will be useful,
  14 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20
  21 END { $? = $Debian::Dgit::ExitStatus::desired // -1; };
  22 use Debian::Dgit::GDR;
  23 use Debian::Dgit::ExitStatus;
  24
  25 use strict;
  26
  27 use Debian::Dgit qw(:DEFAULT :playground);
  28 setup_sigwarn();
  29
  30 use Memoize;
  31 use Carp;
  32 use POSIX;
  33 use Data::Dumper;
  34 use Getopt::Long qw(:config posix_default gnu_compat bundling);
  35 use Dpkg::Version;
  36 use File::FnMatch qw(:fnmatch);
  37 use File::Copy;
  38
  39 $debugcmd_when_debuglevel = 2;
  40
  41 our ($usage_message) = <<'END';
  42 usages:
  43   git-debrebase [<options>] [--|-i <git rebase options...>]
  44   git-debrebase [<options>] status
  45   git-debrebase [<options>] prepush [--prose=...]
  46   git-debrebase [<options>] quick|conclude
  47   git-debrebase [<options>] new-upstream <new-version> [<details ...>]
  48   git-debrebase [<options>] convert-from-gbp [<upstream-commitish>]
  49   ...
  50 See git-debrebase(1), git-debrebase(5), dgit-maint-debrebase(7) (in dgit).
  51 END
  52
  53 our ($opt_force, $opt_noop_ok, @opt_anchors);
  54 our ($opt_defaultcmd_interactive);
  55
  56 our $us = qw(git-debrebase);
  57
  58 our $wrecknoteprefix = 'refs/debrebase-wreckage';
  59
  60 $|=1;
  61
  62 sub badusage ($) {
  63     my ($m) = @_;
  64     print STDERR "$us: bad usage: $m\n";
  65     finish 8;
  66 }
  67
  68 sub getoptions_main {
  69     my $m = shift;
  70     local $SIG{__WARN__}; # GetOptions calls `warn' to print messages
  71     GetOptions @_ or badusage $m;
  72 }
  73 sub getoptions {
  74     my $sc = shift;
  75     getoptions_main "bad options follow \`git-debrebase $sc'", @_;
  76 }
  77
  78 sub cfg ($;$) {
  79     my ($k, $optional) = @_;
  80     local $/ = "\0";
  81     my @cmd = qw(git config -z);
  82     push @cmd, qw(--get-all) if wantarray;
  83     push @cmd, $k;
  84     my $out = cmdoutput_errok @cmd;
  85     if (!defined $out) {
  86         fail "missing required git config $k" unless $optional;
  87         return ();
  88     }
  89     my @l = split /\0/, $out;
  90     return wantarray ? @l : $l[0];
  91 }
  92
  93 memoize('cfg');
  94
  95 sub dd ($) {
  96     my ($v) = @_;
  97     my $dd = new Data::Dumper [ $v ];
  98     Terse $dd 1; Indent $dd 0; Useqq $dd 1;
  99     return Dump $dd;
 100 }
 101
 102 sub get_commit ($) {
 103     my ($objid) = @_;
 104     my $data = (git_cat_file $objid, 'commit');
 105     $data =~ m/(?<=\n)\n/ or die "$objid ($data) ?";
 106     return ($`,$');
 107 }
 108
 109 sub D_UPS ()      { 0x02; } # upstream files
 110 sub D_PAT_ADD ()  { 0x04; } # debian/patches/ extra patches at end
 111 sub D_PAT_OTH ()  { 0x08; } # debian/patches other changes
 112 sub D_DEB_CLOG () { 0x10; } # debian/ (not patches/ or changelog)
 113 sub D_DEB_OTH ()  { 0x20; } # debian/changelog
 114 sub DS_DEB ()     { D_DEB_CLOG | D_DEB_OTH; } # debian/ (not patches/)
 115
 116 our $playprefix = 'debrebase';
 117 our $rd;
 118 our $workarea;
 119
 120 our @git = qw(git);
 121 our @dgit = qw(dgit);
 122
 123 sub in_workarea ($) {
 124     my ($sub) = @_;
 125     changedir $workarea;
 126     my $r = eval { $sub->(); };
 127     { local $@; changedir $maindir; }
 128     die $@ if $@;
 129 }
 130
 131 sub fresh_workarea () {
 132     $workarea = fresh_playground "$playprefix/work";
 133     in_workarea sub { playtree_setup };
 134 }
 135
 136 sub run_ref_updates_now ($$) {
 137     my ($mrest, $updates) = @_;
 138     # @$updates is a list of lines for git-update-ref, without \ns
 139
 140     my @upd_cmd = (git_update_ref_cmd "debrebase: $mrest", qw(--stdin));
 141     debugcmd '>|', @upd_cmd;
 142     open U, "|-", @upd_cmd or die $!;
 143     foreach (@$updates) {
 144         printdebug ">= ", $_, "\n";
 145         print U $_, "\n" or die $!;
 146     }
 147     printdebug ">\$\n";
 148     close U or failedcmd @upd_cmd;
 149 }
 150
 151 our $snags_forced = 0;
 152 our $snags_tripped = 0;
 153 our $snags_summarised = 0;
 154 our @deferred_updates;
 155 our @deferred_update_messages;
 156
 157 sub merge_wreckage_cleaning ($) {
 158     my ($updates) = @_;
 159     git_for_each_ref("$wrecknoteprefix/*", sub {
 160         my ($objid,$objtype,$fullrefname,$reftail) = @_;
 161         push @$updates, "delete $fullrefname";
 162     });
 163 }
 164
 165 sub all_snags_summarised () {
 166     $snags_forced + $snags_tripped == $snags_summarised;
 167 }
 168 sub run_deferred_updates ($) {
 169     my ($mrest) = @_;
 170
 171     confess 'dangerous internal error' unless all_snags_summarised();
 172
 173     merge_wreckage_cleaning \@deferred_updates;
 174     run_ref_updates_now $mrest, \@deferred_updates;
 175     print $_, "\n" foreach @deferred_update_messages;
 176
 177     @deferred_updates = ();
 178     @deferred_update_messages = ();
 179 }
 180
 181 sub get_differs ($$) {
 182     my ($x,$y) = @_;
 183     # This resembles quiltify_trees_differ, in dgit, a bit.
 184     # But we don't care about modes, or dpkg-source-unrepresentable
 185     # changes, and we don't need the plethora of different modes.
 186     # Conversely we need to distinguish different kinds of changes to
 187     # debian/ and debian/patches/.
 188
 189     my $differs = 0;
 190
 191     my $rundiff = sub {
 192         my ($opts, $limits, $fn) = @_;
 193         my @cmd = (@git, qw(diff-tree -z --no-renames));
 194         push @cmd, @$opts;
 195         push @cmd, "$_:" foreach $x, $y;
 196         push @cmd, '--', @$limits;
 197         my $diffs = cmdoutput @cmd;
 198         foreach (split /\0/, $diffs) { $fn->(); }
 199     };
 200
 201     $rundiff->([qw(--name-only)], [], sub {
 202         $differs |= $_ eq 'debian' ? DS_DEB : D_UPS;
 203     });
 204
 205     if ($differs & DS_DEB) {
 206         $differs &= ~DS_DEB;
 207         $rundiff->([qw(--name-only -r)], [qw(debian)], sub {
 208             $differs |=
 209                 m{^debian/patches/}      ? D_PAT_OTH  :
 210                 $_ eq 'debian/changelog' ? D_DEB_CLOG :
 211                                            D_DEB_OTH;
 212         });
 213         die "mysterious debian changes $x..$y"
 214             unless $differs & (D_PAT_OTH|DS_DEB);
 215     }
 216
 217     if ($differs & D_PAT_OTH) {
 218         my $mode;
 219         $differs &= ~D_PAT_OTH;
 220         my $pat_oth = sub {
 221             $differs |= D_PAT_OTH;
 222             no warnings qw(exiting);  last;
 223         };
 224         $rundiff->([qw(--name-status -r)], [qw(debian/patches/)], sub {
 225             no warnings qw(exiting);
 226             if (!defined $mode) {
 227                 $mode = $_;  next;
 228             }
 229             die unless s{^debian/patches/}{};
 230             my $ok;
 231             if ($mode eq 'A' && !m/\.series$/s) {
 232                 $ok = 1;
 233             } elsif ($mode eq 'M' && $_ eq 'series') {
 234                 my $x_s = (git_cat_file "$x:debian/patches/series", 'blob');
 235                 my $y_s = (git_cat_file "$y:debian/patches/series", 'blob');
 236                 chomp $x_s;  $x_s .= "\n";
 237                 $ok = $x_s eq substr($y_s, 0, length $x_s);
 238             } else {
 239                 # nope
 240             }
 241             $mode = undef;
 242             $differs |= $ok ? D_PAT_ADD : D_PAT_OTH;
 243         });
 244         die "mysterious debian/patches changes $x..$y"
 245             unless $differs & (D_PAT_ADD|D_PAT_OTH);
 246     }
 247
 248     printdebug sprintf "get_differs %s %s = %#x\n", $x, $y, $differs;
 249
 250     return $differs;
 251 }
 252
 253 sub commit_pr_info ($) {
 254     my ($r) = @_;
 255     return Data::Dumper->dump([$r], [qw(commit)]);
 256 }
 257
 258 sub calculate_committer_authline () {
 259     my $c = cmdoutput @git, qw(commit-tree --no-gpg-sign -m),
 260         'DUMMY COMMIT (git-debrebase)', "HEAD:";
 261     my ($h,$m) = get_commit $c;
 262     $h =~ m/^committer .*$/m or confess "($h) ?";
 263     return $&;
 264 }
 265
 266 sub rm_subdir_cached ($) {
 267     my ($subdir) = @_;
 268     runcmd @git, qw(rm --quiet -rf --cached --ignore-unmatch), $subdir;
 269 }
 270
 271 sub read_tree_subdir ($$) {
 272     my ($subdir, $new_tree_object) = @_;
 273     rm_subdir_cached $subdir;
 274     runcmd @git, qw(read-tree), "--prefix=$subdir/", $new_tree_object;
 275 }
 276
 277 sub read_tree_debian ($) {
 278     my ($treeish) = @_;
 279     read_tree_subdir 'debian', "$treeish:debian";
 280     rm_subdir_cached 'debian/patches';
 281 }
 282
 283 sub read_tree_upstream ($;$$) {
 284     my ($treeish, $keep_patches, $tree_with_debian) = @_;
 285     # if $tree_with_debian is supplied, will use that for debian/
 286     # otherwise will save and restore it.
 287     my $debian =
 288         $tree_with_debian ? "$tree_with_debian:debian"
 289         : cmdoutput @git, qw(write-tree --prefix=debian/);
 290     runcmd @git, qw(read-tree), $treeish;
 291     read_tree_subdir 'debian', $debian;
 292     rm_subdir_cached 'debian/patches' unless $keep_patches;
 293 };
 294
 295 sub make_commit ($$) {
 296     my ($parents, $message_paras) = @_;
 297     my $tree = cmdoutput @git, qw(write-tree);
 298     my @cmd = (@git, qw(commit-tree), $tree);
 299     push @cmd, qw(-p), $_ foreach @$parents;
 300     push @cmd, qw(-m), $_ foreach @$message_paras;
 301     return cmdoutput @cmd;
 302 }
 303
 304 our @snag_force_opts;
 305 sub snag ($$;@) {
 306     my ($tag,$msg) = @_; # ignores extra args, for benefit of keycommits
 307     if (grep { $_ eq $tag } @snag_force_opts) {
 308         $snags_forced++;
 309         print STDERR "git-debrebase: snag ignored (-f$tag): $msg\n";
 310     } else {
 311         $snags_tripped++;
 312         print STDERR "git-debrebase: snag detected (-f$tag): $msg\n";
 313     }
 314 }
 315
 316 # Important: all mainline code must call snags_maybe_bail after
 317 # any point where snag might be called, but before making changes
 318 # (eg before any call to run_deferred_updates).  snags_maybe_bail
 319 # may be called more than once if necessary (but this is not ideal
 320 # because then the messages about number of snags may be confusing).
 321 sub snags_maybe_bail () {
 322     return if all_snags_summarised();
 323     if ($snags_forced) {
 324         printf STDERR
 325             "%s: snags: %d overriden by individual -f options\n",
 326             $us, $snags_forced;
 327     }
 328     if ($snags_tripped) {
 329         if ($opt_force) {
 330             printf STDERR
 331                 "%s: snags: %d overriden by global --force\n",
 332                 $us, $snags_tripped;
 333         } else {
 334             fail sprintf
 335   "%s: snags: %d blocker(s) (you could -f<tag>, or --force)",
 336                 $us, $snags_tripped;
 337         }
 338     }
 339     $snags_summarised = $snags_forced + $snags_tripped;
 340 }
 341 sub snags_maybe_bail_early () {
 342     # useful to bail out early without doing a lot of work;
 343     # not a substitute for snags_maybe_bail.
 344     snags_maybe_bail() if $snags_tripped && !$opt_force;
 345 }
 346 sub any_snags () {
 347     return $snags_forced || $snags_tripped;
 348 }
 349
 350 sub gbp_pq_export ($$$) {
 351     my ($bname, $base, $tip) = @_;
 352     # must be run in a workarea.  $bname and patch-queue/$bname
 353     # ought not to exist.  Leaves you on patch-queue/$bname with
 354     # the patches staged but not committed.
 355     printdebug "gbp_pq_export $bname $base $tip\n";
 356     runcmd @git, qw(checkout -q -b), $bname, $base;
 357     runcmd @git, qw(checkout -q -b), "patch-queue/$bname", $tip;
 358     my @gbp_cmd = (qw(gbp pq export));
 359     my $r = system shell_cmd 'exec >../gbp-pq-err 2>&1', @gbp_cmd;
 360     if ($r) {
 361         { local ($!,$?); copy('../gbp-pq-err', \*STDERR); }
 362         failedcmd @gbp_cmd;
 363     }
 364     runcmd @git, qw(add -f debian/patches) if stat_exists 'debian/patches';
 365 }
 366
 367
 368 # xxx allow merge resolution separately from laundering, before git merge
 369 #
 370 # xxx general gdr docs highlight forbidden things
 371 # xxx general gdr docs list allowable things ?
 372 # xxx general gdr docs explicitly forbid some rebase
 373 #
 374 # xxx provide a way for the user to help
 375 # xxx (eg, provide wreckage provide way to continue)
 376
 377 # later/rework?
 378 #  use git-format-patch?
 379 #  our own patch identification algorithm?
 380 #  this is an alternative strategy
 381
 382 sub merge_failed ($$) {
 383     my ($wrecknotes, $emsg) = @_;
 384     my @m;
 385     push @m, "Merge resolution failed: $emsg";
 386
 387     changedir $maindir;
 388
 389     my @updates;
 390     merge_wreckage_cleaning \@updates;
 391     keys %$wrecknotes;
 392     while (my ($k,$v) = each %$wrecknotes) {
 393         push @updates, "create $wrecknoteprefix/$k $v";
 394     }
 395     run_ref_updates_now "merge failed", \@updates;
 396     push @m, "Wreckage left in $wrecknoteprefix/*.";
 397
 398     push @m, "See git-debrebase(1) section FAILED MERGES for suggestions.";
 399
 400     # use finish rather than fail, in case we are within an eval
 401     # (that can happen inside walk!)
 402     print STDERR "\n";
 403     print STDERR "$us: $_\n" foreach @m;
 404     finish 15;
 405 }
 406
 407 sub mwrecknote ($$$) {
 408     my ($wrecknotes, $reftail, $commitish) = @_;
 409     confess unless defined $commitish;
 410     printdebug "mwrecknote $reftail $commitish\n";
 411     $wrecknotes->{$reftail} = $commitish;
 412 }
 413
 414 sub merge_series ($$$;@) {
 415     my ($newbase, $wrecknotes, $base_q, @input_qs) = @_;
 416     # $base_q{SeriesBase}  $input_qs[]{SeriesBase}
 417     # $base_q{SeriesTip}   $input_qs[]{SeriesTip}
 418     # ^ specifies several patch series (currently we only support exactly 2)
 419     # return value is a commit which is the result of
 420     # merging the two versions of the same topic branch
 421     #   $input_q[0] and $input_q[1]
 422     # with respect to the old version
 423     #   $base_q
 424     # all onto $newbase.
 425
 426     # Creates, in *_q, a key MR for its private use
 427
 428     printdebug "merge_series newbase=$newbase\n";
 429
 430     $input_qs[$_]{MR}{S} = $_ foreach (0..$#input_qs);
 431     $base_q->{MR}{S} = 'base';
 432
 433     my %prereq;
 434     # $prereq{<patch filename>}{<possible prereq}{<S>} = 1 or absent
 435     # $prereq{<patch filename>}{<possible prereq}  exists or not (later)
 436     # $prereq{<patch filename>}               exists or not (even later)
 437
 438     my $result;
 439
 440     my $mwrecknote = sub { &mwrecknote($wrecknotes, @_); };
 441
 442     my $attempt_cmd = sub {
 443         debugcmd '+', @_;
 444         $!=0; $?=-1;
 445         if (system @_) {
 446             failedcmd_report_cmd undef, @_;
 447             merge_failed $wrecknotes, failedcmd_waitstatus();
 448         }
 449     };
 450
 451     local $workarea = fresh_playground "$playprefix/merge";
 452     my $seriesfile = "debian/patches/series";
 453     in_workarea sub {
 454         playtree_setup();
 455         foreach my $q ($base_q, reverse @input_qs) {
 456             my $s = $q->{MR}{S};
 457             gbp_pq_export "p-$s", $q->{SeriesBase}, $q->{SeriesTip};
 458             my @earlier;
 459             if (open S, $seriesfile) {
 460                 while (my $patch = <S>) {
 461                     chomp $patch or die $!;
 462                     $prereq{$patch} //= {};
 463                     foreach my $earlier (@earlier) {
 464                         $prereq{$patch}{$earlier}{$s}++ and die;
 465                     }
 466                     push @earlier, $patch;
 467                     stat "debian/patches/$patch" or die "$patch ?";
 468                 }
 469                 S->error and die "$seriesfile $!";
 470                 close S;
 471             } else {
 472                 die "$seriesfile $!" unless $!==ENOENT;
 473             }
 474             read_tree_upstream $newbase, 1;
 475             my $pec = make_commit [ grep { defined } $base_q->{MR}{PEC} ], [
 476                 "Convert $s to patch queue for merging",
 477                 "[git-debrebase merge-innards patch-queue import:".
 478                 " $q->{SeriesTip}]"
 479             ];
 480             printdebug "merge_series  pec $pec ";
 481             runcmd @git, qw(rm -q --ignore-unmatch --cached), $seriesfile;
 482             $pec = make_commit [ $pec ], [
 483                 "Drop series file from $s to avoid merge trouble",
 484                 "[git-debrebase merge-innards patch-queue prep:".
 485                 " $q->{SeriesTip}]"
 486             ];
 487
 488             read_tree_debian $newbase;
 489             if (@earlier) {
 490                 read_tree_subdir 'debian/patches', "$pec:debian/patches";
 491             } else {
 492                 rm_subdir_cached 'debian/patches';
 493             }
 494             $pec = make_commit [ $pec ], [
 495  "Update debian/ (excluding patches) to final to avoid re-merging",
 496  "debian/ was already merged and we need to just take that.",
 497                 "[git-debrebase merge-innards patch-queue packaging:".
 498                 " $q->{SeriesTip}]"
 499             ];
 500
 501             printdebug "pec' $pec\n";
 502             runcmd @git, qw(reset -q --hard), $pec;
 503             $q->{MR}{PEC} = $pec;
 504             $mwrecknote->("$q->{LeftRight}-patchqueue", $pec);
 505         }
 506         # now, because of reverse, we are on $input_q->{MR}{OQC}
 507         runcmd @git, qw(checkout -q -b merge);
 508         printdebug "merge_series merging...\n";
 509         my @mergecmd = (@git, qw(merge --quiet --no-edit), "p-1");
 510
 511         $attempt_cmd->(@mergecmd);
 512
 513         printdebug "merge_series merge ok, series...\n";
 514         # We need to construct a new series file
 515         # Firstly, resolve prereq
 516         foreach my $f (sort keys %prereq) {
 517             printdebug "merge_series  patch\t$f\t";
 518             if (!stat_exists "debian/patches/$f") {
 519                 print DEBUG " drop\n" if $debuglevel;
 520                 # git merge deleted it; that's how we tell it's not wanted
 521                 delete $prereq{$f};
 522                 next;
 523             }
 524             print DEBUG " keep\n" if $debuglevel;
 525             foreach my $g (sort keys %{ $prereq{$f} }) {
 526                 my $gfp = $prereq{$f}{$g};
 527                 printdebug "merge_series  prereq\t$f\t-> $g\t";
 528                 if (!!$gfp->{0} == !!$gfp->{1}
 529                     ? $gfp->{0}
 530                     : !$gfp->{base}) {
 531                     print DEBUG "\tkeep\n" if $debuglevel;
 532                 } else {
 533                     print DEBUG "\tdrop\n" if $debuglevel;
 534                     delete $prereq{$f}{$g};
 535                 }
 536             }
 537         }
 538
 539         my $unsat = sub {
 540             my ($f) = @_;
 541             return scalar keys %{ $prereq{$f} };
 542         };
 543
 544         my $nodate = time + 1;
 545         my %authordate;
 546         # $authordate{<patch filename>};
 547         my $authordate = sub {
 548             my ($f) = @_;
 549             $authordate{$f} //= do {
 550                 open PF, "<", "debian/patches/$f" or die "$f $!";
 551                 while (<PF>) {
 552                     return $nodate if m/^$/;
 553                     last if s{^Date: }{};
 554                 }
 555                 chomp;
 556                 return cmdoutput qw(date +%s -d), $_;
 557             };
 558         };
 559
 560         open NS, '>', $seriesfile or die $!;
 561
 562         while (keys %prereq) {
 563             my $best;
 564             foreach my $try (sort keys %prereq) {
 565                 if ($best) {
 566                     next if (
 567                              $unsat->($try) <=> $unsat->($best) or
 568                              $authordate->($try) <=> $authordate->($best) or
 569                              $try cmp $best
 570                             ) >= 0;
 571                 }
 572                 $best = $try;
 573             }
 574             printdebug "merge_series series next $best\n";
 575             print NS "$best\n" or die $!;
 576             delete $prereq{$best};
 577             foreach my $gp (values %prereq) {
 578                 delete $gp->{$best};
 579             }
 580         }
 581
 582         runcmd @git, qw(add), $seriesfile;
 583         runcmd @git, qw(commit --quiet -m), 'Merged patch queue form';
 584         $mwrecknote->('merged-patchqueue', git_rev_parse 'HEAD');
 585
 586         printdebug "merge_series series gbp pq import\n";
 587
 588         $attempt_cmd->(qw(gbp pq import));
 589
 590         # OK now we are on patch-queue/merge, and we need to rebase
 591         # onto the intended parent and drop the patches from each one
 592
 593         printdebug "merge_series series ok, building...\n";
 594         my $build = $newbase;
 595         my @lcmd = (@git, qw(rev-list --reverse merge..patch-queue/merge));
 596         foreach my $c (grep /./, split /\n/, cmdoutput @lcmd) {
 597             my $commit = git_cat_file $c, 'commit';
 598             printdebug "merge_series series ok, building $c\n";
 599             read_tree_upstream $c, 0, $newbase;
 600             my $tree = cmdoutput @git, qw(write-tree);
 601             $commit =~ s{^parent (\S+)$}{parent $build}m or confess;
 602             $commit =~ s{^tree (\S+)$}{tree $tree}m      or confess;
 603             open C, ">", "../mcommit" or die $!;
 604             print C $commit or die $!;
 605             close C or die $!;
 606             $build = cmdoutput @git, qw(hash-object -w -t commit ../mcommit);
 607         }
 608         $result = $build;
 609         $mwrecknote->('merged-result', $result);
 610
 611         runcmd @git, qw(update-ref refs/heads/result), $result;
 612
 613         runcmd @git, qw(checkout -q -b debug);
 614         runcmd @git, qw(commit --allow-empty -q -m M-INDEX);
 615         runcmd @git, qw(add .);
 616         runcmd @git, qw(commit --allow-empty -q -m M-WORKTREE);
 617         my $mdebug = git_rev_parse 'HEAD';
 618         printdebug sprintf "merge_series done debug=%s\n", $mdebug;
 619         $mwrecknote->('merged-debug', $mdebug);
 620     };
 621     printdebug "merge_series returns $result\n";
 622     return $result;
 623 }
 624
 625 # classify returns an info hash like this
 626 #   CommitId => $objid
 627 #   Hdr => # commit headers, including 1 final newline
 628 #   Msg => # commit message (so one newline is dropped)
 629 #   Tree => $treeobjid
 630 #   Type => (see below)
 631 #   Parents = [ {
 632 #       Ix => $index # ie 0, 1, 2, ...
 633 #       CommitId
 634 #       Differs => return value from get_differs
 635 #       IsOrigin
 636 #       IsDggitImport => 'orig' 'tarball' 'unpatched' 'package' (as from dgit)
 637 #     } ...]
 638 #   NewMsg => # commit message, but with any [dgit import ...] edited
 639 #             # to say "[was: ...]"
 640 #
 641 # Types:
 642 #   Packaging
 643 #   Changelog
 644 #   Upstream
 645 #   AddPatches
 646 #   Mixed
 647 #
 648 #   Pseudomerge
 649 #     has additional entres in classification result
 650 #       Overwritten = [ subset of Parents ]
 651 #       Contributor = $the_remaining_Parent
 652 #
 653 #   DgitImportUnpatched
 654 #     has additional entry in classification result
 655 #       OrigParents = [ subset of Parents ]
 656 #
 657 #   Anchor
 658 #     has additional entry in classification result
 659 #       OrigParents = [ subset of Parents ]  # singleton list
 660 #
 661 #   TreatAsAnchor
 662 #
 663 #   BreakwaterStart
 664 #
 665 #   Unknown
 666 #     has additional entry in classification result
 667 #       Why => "prose"
 668
 669 sub parsecommit ($;$) {
 670     my ($objid, $p_ref) = @_;
 671     # => hash with                   CommitId Hdr Msg Tree Parents
 672     #    Parents entries have only   Ix CommitId
 673     #    $p_ref, if provided, must be [] and is used as a base for Parents
 674
 675     $p_ref //= [];
 676     die if @$p_ref;
 677
 678     my ($h,$m) = get_commit $objid;
 679
 680     my ($t) = $h =~ m/^tree (\w+)$/m or die $objid;
 681     my (@ph) = $h =~ m/^parent (\w+)$/mg;
 682
 683     my $r = {
 684         CommitId => $objid,
 685         Hdr => $h,
 686         Msg => $m,
 687         Tree => $t,
 688         Parents => $p_ref,
 689     };
 690
 691     foreach my $ph (@ph) {
 692         push @$p_ref, {
 693             Ix => scalar @$p_ref,
 694             CommitId => $ph,
 695         };
 696     }
 697
 698     return $r;
 699 }
 700
 701 sub classify ($) {
 702     my ($objid) = @_;
 703
 704     my @p;
 705     my $r = parsecommit($objid, \@p);
 706     my $t = $r->{Tree};
 707
 708     foreach my $p (@p) {
 709         $p->{Differs} = (get_differs $p->{CommitId}, $t),
 710     }
 711
 712     printdebug "classify $objid \$t=$t \@p",
 713         (map { sprintf " %s/%#x", $_->{CommitId}, $_->{Differs} } @p),
 714         "\n";
 715
 716     my $classify = sub {
 717         my ($type, @rest) = @_;
 718         $r = { %$r, Type => $type, @rest };
 719         if ($debuglevel) {
 720             printdebug " = $type ".(dd $r)."\n";
 721         }
 722         return $r;
 723     };
 724     my $unknown = sub {
 725         my ($why) = @_;
 726         $r = { %$r, Type => qw(Unknown), Why => $why };
 727         printdebug " ** Unknown\n";
 728         return $r;
 729     };
 730
 731     if (grep { $_ eq $objid } @opt_anchors) {
 732         return $classify->('TreatAsAnchor');
 733     }
 734
 735     my @identical = grep { !$_->{Differs} } @p;
 736     my ($stype, $series) = git_cat_file "$t:debian/patches/series";
 737     my $haspatches = $stype ne 'missing' && $series =~ m/^\s*[^#\n\t ]/m;
 738
 739     if ($r->{Msg} =~ m{^\[git-debrebase anchor.*\]$}m) {
 740         # multi-orig upstreams are represented with an anchor merge
 741         # from a single upstream commit which combines the orig tarballs
 742
 743         # Every anchor tagged this way must be a merge.
 744         # We are relying on the
 745         #     [git-debrebase anchor: ...]
 746         # commit message annotation in "declare" anchor merges (which
 747         # do not have any upstream changes), to distinguish those
 748         # anchor merges from ordinary pseudomerges (which we might
 749         # just try to strip).
 750         #
 751         # However, the user is going to be doing git-rebase a lot.  We
 752         # really don't want them to rewrite an anchor commit.
 753         # git-rebase trips up on merges, so that is a useful safety
 754         # catch.
 755         #
 756         # BreakwaterStart commits are also anchors in the terminology
 757         # of git-debrebase(5), but they are untagged (and always
 758         # manually generated).
 759         #
 760         # We cannot not tolerate any tagged linear commit (ie,
 761         # BreakwaterStart commits tagged `[anchor:') because such a
 762         # thing could result from an erroneous linearising raw git
 763         # rebase of a merge anchor.  That would represent a corruption
 764         # of the branch. and we want to detect and reject the results
 765         # of such corruption before it makes it out anywhere.  If we
 766         # reject it here then we avoid making the pseudomerge which
 767         # would be needed to push it.
 768
 769         my $badanchor = sub { $unknown->("git-debrebase \`anchor' but @_"); };
 770         @p == 2 or return $badanchor->("has other than two parents");
 771         $haspatches and return $badanchor->("contains debian/patches");
 772
 773         # How to decide about l/r ordering of anchors ?  git
 774         # --topo-order prefers to expand 2nd parent first.  There's
 775         # already an easy rune to look for debian/ history anyway (git log
 776         # debian/) so debian breakwater branch should be 1st parent; that
 777         # way also there's also an easy rune to look for the upstream
 778         # patches (--topo-order).
 779
 780         # Also this makes --first-parent be slightly more likely to
 781         # be useful - it makes it provide a linearised breakwater history.
 782
 783         # Of course one can say somthing like
 784         #  gitk -- ':/' ':!/debian'
 785         # to get _just_ the commits touching upstream files, and by
 786         # the TREESAME logic in git-rev-list this will leave the
 787         # breakwater into upstream at the first anchor.  But that
 788         # doesn't report debian/ changes at all.
 789
 790         # Other observations about gitk: by default, gitk seems to
 791         # produce output in a different order to git-rev-list.  I
 792         # can't seem to find this documented anywhere.  gitk
 793         # --date-order DTRT.  But, gitk always seems to put the
 794         # parents from left to right, in order, so it's easy to see
 795         # which way round a pseudomerge is.
 796
 797         $p[0]{IsOrigin} and $badanchor->("is an origin commit");
 798         $p[1]{Differs} & ~DS_DEB and
 799             $badanchor->("upstream files differ from left parent");
 800         $p[0]{Differs} & ~D_UPS and
 801             $badanchor->("debian/ differs from right parent");
 802
 803         return $classify->(qw(Anchor),
 804                            OrigParents => [ $p[1] ]);
 805     }
 806
 807     if (@p == 1) {
 808         my $d = $r->{Parents}[0]{Differs};
 809         if ($d == D_PAT_ADD) {
 810             return $classify->(qw(AddPatches));
 811         } elsif ($d & (D_PAT_ADD|D_PAT_OTH)) {
 812             return $unknown->("edits debian/patches");
 813         } elsif ($d & DS_DEB and !($d & ~DS_DEB)) {
 814             my ($ty,$dummy) = git_cat_file "$p[0]{CommitId}:debian";
 815             if ($ty eq 'tree') {
 816                 if ($d == D_DEB_CLOG) {
 817                     return $classify->(qw(Changelog));
 818                 } else {
 819                     return $classify->(qw(Packaging));
 820                 }
 821             } elsif ($ty eq 'missing') {
 822                 return $classify->(qw(BreakwaterStart));
 823             } else {
 824                 return $unknown->("parent's debian is not a directory");
 825             }
 826         } elsif ($d == D_UPS) {
 827             return $classify->(qw(Upstream));
 828         } elsif ($d & DS_DEB and $d & D_UPS and !($d & ~(DS_DEB|D_UPS))) {
 829             return $classify->(qw(Mixed));
 830         } elsif ($d == 0) {
 831             return $unknown->("no changes");
 832         } else {
 833             confess "internal error $objid ?";
 834         }
 835     }
 836     if (!@p) {
 837         return $unknown->("origin commit");
 838     }
 839
 840     if (@p == 2 && @identical == 1) {
 841         my @overwritten = grep { $_->{Differs} } @p;
 842         confess "internal error $objid ?" unless @overwritten==1;
 843         return $classify->(qw(Pseudomerge),
 844                            Overwritten => [ $overwritten[0] ],
 845                            Contributor => $identical[0]);
 846     }
 847     if (@p == 2 && @identical == 2) {
 848         my $get_t = sub {
 849             my ($ph,$pm) = get_commit $_[0]{CommitId};
 850             $ph =~ m/^committer .* (\d+) [-+]\d+$/m or die "$_->{CommitId} ?";
 851             $1;
 852         };
 853         my @bytime = @p;
 854         my $order = $get_t->($bytime[0]) <=> $get_t->($bytime[1]);
 855         if ($order > 0) { # newer first
 856         } elsif ($order < 0) {
 857             @bytime = reverse @bytime;
 858         } else {
 859             # same age, default to order made by -s ours
 860             # that is, commit was made by someone who preferred L
 861         }
 862         return $classify->(qw(Pseudomerge),
 863                            SubType => qw(Ambiguous),
 864                            Contributor => $bytime[0],
 865                            Overwritten => [ $bytime[1] ]);
 866     }
 867     foreach my $p (@p) {
 868         my ($p_h, $p_m) = get_commit $p->{CommitId};
 869         $p->{IsOrigin} = $p_h !~ m/^parent \w+$/m;
 870         ($p->{IsDgitImport},) = $p_m =~ m/^\[dgit import ([0-9a-z]+) .*\]$/m;
 871     }
 872     my @orig_ps = grep { ($_->{IsDgitImport}//'X') eq 'orig' } @p;
 873     my $m2 = $r->{Msg};
 874     if (!(grep { !$_->{IsOrigin} } @p) and
 875         (@orig_ps >= @p - 1) and
 876         $m2 =~ s{^\[(dgit import unpatched .*)\]$}{[was: $1]}m) {
 877         $r->{NewMsg} = $m2;
 878         return $classify->(qw(DgitImportUnpatched),
 879                            OrigParents => \@orig_ps);
 880     }
 881
 882     if (@p == 2 and
 883         $r->{Msg} =~ m{^\[git-debrebase merged-breakwater.*\]$}m) {
 884         # xxx ^ metadata tag needs adding to (5)
 885         return $classify->("MergedBreakwaters");
 886     }
 887     if ($r->{Msg} =~ m{^\[(git-debrebase|dgit)[: ].*\]$}m) {
 888         return $unknown->("unknown kind of merge from $1");
 889     }
 890     if (@p > 2) {
 891         return $unknown->("octopus merge");
 892     }
 893
 894     if (!$ENV{GIT_DEBREBASE_EXPERIMENTAL_MERGE}) {
 895         return $unknown->("general two-parent merge");
 896     }
 897
 898     return $classify->("VanillaMerge");
 899 }
 900
 901 sub keycommits ($;$$$$$);
 902
 903 sub mergedbreakwaters_anchor ($) {
 904     my ($cl) = @_;
 905     my $best_anchor;
 906     foreach my $p (@{ $cl->{Parents} }) {
 907         my ($panchor, $pbw) = keycommits $p->{CommitId},
 908             undef,undef,undef,undef, 1;
 909         $best_anchor = $panchor
 910             if !defined $best_anchor
 911             or is_fast_fwd $best_anchor, $panchor;
 912         fail "inconsistent anchors in merged-breakwaters $p->{CommitId}"
 913             unless is_fast_fwd $panchor, $best_anchor;
 914     }
 915     return $best_anchor;
 916 }
 917
 918 sub keycommits ($;$$$$$) {
 919     my ($head, $furniture, $unclean, $trouble, $fatal, $claimed_bw) = @_;
 920     # => ($anchor, $breakwater)
 921
 922     # $unclean->("unclean-$tagsfx", $msg, $cl)
 923     # $furniture->("unclean-$tagsfx", $msg, $cl)
 924     # $dgitimport->("unclean-$tagsfx", $msg, $cl))
 925     #   is callled for each situation or commit that
 926     #   wouldn't be found in a laundered branch
 927     # $furniture is for furniture commits such as might be found on an
 928     #   interchange branch (pseudomerge, d/patches, changelog)
 929     # $trouble is for things whnich prevent the return of
 930     #   anchor and breakwater information; if that is ignored,
 931     #   then keycommits returns (undef, undef) instead.
 932     # $fatal is for unprocessable commits, and should normally cause
 933     #    a failure.  If ignored, agaion, (undef, undef) is returned.
 934     #
 935     # If $claimed_bw, this is supposed to be a breakwater commit.
 936     #
 937     # If a callback is undef, fail is called instead.
 938     # If a callback is defined but false, the situation is ignored.
 939     # Callbacks may say:
 940     #   no warnings qw(exiting); last;
 941     # if the answer is no longer wanted.
 942
 943     my ($anchor, $breakwater);
 944     $breakwater = $head if $claimed_bw;
 945     my $clogonly;
 946     my $cl;
 947     my $found_pm;
 948     $fatal //= sub { fail $_[1]; };
 949     my $x = sub {
 950         my ($cb, $tagsfx, $mainwhy, $xwhy) = @_;
 951         my $why = $mainwhy.$xwhy;
 952         my $m = "branch needs laundering (run git-debrebase): $why";
 953         fail $m unless defined $cb;
 954         return unless $cb;
 955         $cb->("unclean-$tagsfx", $why, $cl, $mainwhy);
 956     };
 957     my $found_anchor = sub {
 958         ($anchor) = @_;
 959         $breakwater //= $clogonly;
 960         $breakwater //= $head;
 961         no warnings qw(exiting);
 962         last;
 963     };
 964     for (;;) {
 965         $cl = classify $head;
 966         my $ty = $cl->{Type};
 967         if ($ty eq 'Packaging') {
 968             $breakwater //= $clogonly;
 969             $breakwater //= $head;
 970         } elsif ($ty eq 'Changelog') {
 971             # this is going to count as the tip of the breakwater
 972             # only if it has no upstream stuff before it
 973             $clogonly //= $head;
 974         } elsif ($ty eq 'Anchor' or
 975                  $ty eq 'TreatAsAnchor' or
 976                  $ty eq 'BreakwaterStart') {
 977             $found_anchor->($head);
 978         } elsif ($ty eq 'Upstream') {
 979             $x->($unclean, 'ordering',
 980  "packaging change ($breakwater) follows upstream change"," (eg $head)")
 981                 if defined $breakwater;
 982             $clogonly = undef;
 983             $breakwater = undef;
 984         } elsif ($ty eq 'Mixed') {
 985             $x->($unclean, 'mixed',
 986                  "found mixed upstream/packaging commit"," ($head)");
 987             $clogonly = undef;
 988             $breakwater = undef;
 989         } elsif ($ty eq 'Pseudomerge' or
 990                  $ty eq 'AddPatches') {
 991             my $found_pm = 1;
 992             $x->($furniture, (lc $ty),
 993                  "found interchange bureaucracy commit ($ty)"," ($head)");
 994         } elsif ($ty eq 'DgitImportUnpatched') {
 995             if ($found_pm) {
 996                 $x->($trouble, 'dgitimport',
 997                      "found dgit dsc import"," ($head)");
 998                 return (undef,undef);
 999             } else {
1000                 $x->($fatal, 'unprocessable',
1001                      "found bare dgit dsc import with no prior history",
1002                      " ($head)");
1003                 return (undef,undef);
1004             }
1005         } elsif ($ty eq 'VanillaMerge') {
1006             $x->($trouble, 'vanillamerge',
1007                  "found vanilla merge"," ($head)");
1008             return (undef,undef);
1009         } elsif ($ty eq 'MergedBreakwaters') {
1010             $found_anchor->(mergedbreakwaters_anchor $cl);
1011         } else {
1012             $x->($fatal, 'unprocessable',
1013                  "found unprocessable commit, cannot cope: $cl->{Why}",
1014                  " ($head)");
1015             return (undef,undef);
1016         }
1017         $head = $cl->{Parents}[0]{CommitId};
1018     }
1019     return ($anchor, $breakwater);
1020 }
1021
1022 sub walk ($;$$$);
1023 sub walk ($;$$$) {
1024     my ($input,
1025         $nogenerate,$report, $report_lprefix) = @_;
1026     # => ($tip, $breakwater_tip, $last_anchor)
1027     # (or nothing, if $nogenerate)
1028
1029     printdebug "*** WALK $input ".($nogenerate//0)." ".($report//'-')."\n";
1030     $report_lprefix //= '';
1031
1032     # go through commits backwards
1033     # we generate two lists of commits to apply:
1034     # breakwater branch and upstream patches
1035     my (@brw_cl, @upp_cl, @processed);
1036     my %found;
1037     my $upp_limit;
1038     my @pseudomerges;
1039
1040     my $cl;
1041     my $xmsg = sub {
1042         my ($prose, $info) = @_;
1043         my $ms = $cl->{Msg};
1044         chomp $ms;
1045         $info //= '';
1046         $ms .= "\n\n[git-debrebase$info: $prose]\n";
1047         return (Msg => $ms);
1048     };
1049     my $rewrite_from_here = sub {
1050         my ($cl) = @_;
1051         my $sp_cl = { SpecialMethod => 'StartRewrite' };
1052         push @$cl, $sp_cl;
1053         push @processed, $sp_cl;
1054     };
1055     my $cur = $input;
1056
1057     my $prdelim = "";
1058     my $prprdelim = sub { print $report $prdelim if $report; $prdelim=""; };
1059
1060     my $prline = sub {
1061         return unless $report;
1062         print $report $prdelim, $report_lprefix, @_;
1063         $prdelim = "\n";
1064     };
1065
1066     my $bomb = sub { # usage: return $bomb->();
1067         print $report " Unprocessable" if $report;
1068         print $report " ($cl->{Why})" if $report && defined $cl->{Why};
1069         $prprdelim->();
1070         if ($nogenerate) {
1071             return (undef,undef);
1072         }
1073         fail "found unprocessable commit, cannot cope".
1074             (defined $cl->{Why} ? "; $cl->{Why}:": ':').
1075             " (commit $cur) (d.".
1076             (join ' ', map { sprintf "%#x", $_->{Differs} }
1077              @{ $cl->{Parents} }).
1078                  ")";
1079     };
1080
1081     my $build;
1082     my $breakwater;
1083
1084     my $build_start = sub {
1085         my ($msg, $parent) = @_;
1086         $prline->(" $msg");
1087         $build = $parent;
1088         no warnings qw(exiting); last;
1089     };
1090
1091     my $nomerge = sub {
1092         my ($emsg) = @_;
1093         merge_failed $cl->{MergeWreckNotes}, $emsg;
1094     };
1095
1096     my $mwrecknote = sub { &mwrecknote($cl->{MergeWreckNotes}, @_); };
1097
1098     my $last_anchor;
1099
1100     for (;;) {
1101         $cl = classify $cur;
1102         $cl->{MergeWreckNotes} //= {};
1103         my $ty = $cl->{Type};
1104         my $st = $cl->{SubType};
1105         $prline->("$cl->{CommitId} $cl->{Type}");
1106         $found{$ty. ( defined($st) ? "-$st" : '' )}++;
1107         push @processed, $cl;
1108         my $p0 = @{ $cl->{Parents} }==1 ? $cl->{Parents}[0]{CommitId} : undef;
1109         if ($ty eq 'AddPatches') {
1110             $cur = $p0;
1111             $rewrite_from_here->(\@upp_cl);
1112             next;
1113         } elsif ($ty eq 'Packaging' or $ty eq 'Changelog') {
1114             push @brw_cl, $cl;
1115             $cur = $p0;
1116             next;
1117         } elsif ($ty eq 'BreakwaterStart') {
1118             $last_anchor = $cur;
1119             $build_start->('FirstPackaging', $cur);
1120         } elsif ($ty eq 'Upstream') {
1121             push @upp_cl, $cl;
1122             $cur = $p0;
1123             next;
1124         } elsif ($ty eq 'Mixed') {
1125             my $queue = sub {
1126                 my ($q, $wh) = @_;
1127                 my $cls = { %$cl, $xmsg->("split mixed commit: $wh part") };
1128                 push @$q, $cls;
1129             };
1130             $queue->(\@brw_cl, "debian");
1131             $queue->(\@upp_cl, "upstream");
1132             $rewrite_from_here->(\@brw_cl);
1133             $cur = $p0;
1134             next;
1135         } elsif ($ty eq 'Pseudomerge') {
1136             my $contrib = $cl->{Contributor}{CommitId};
1137             print $report " Contributor=$contrib" if $report;
1138             push @pseudomerges, $cl;
1139             $rewrite_from_here->(\@upp_cl);
1140             $cur = $contrib;
1141             next;
1142         } elsif ($ty eq 'Anchor' or $ty eq 'TreatAsAnchor') {
1143             $last_anchor = $cur;
1144             $build_start->("Anchor", $cur);
1145         } elsif ($ty eq 'DgitImportUnpatched') {
1146             my $pm = $pseudomerges[-1];
1147             if (defined $pm) {
1148                 # To an extent, this is heuristic.  Imports don't have
1149                 # a useful history of the debian/ branch.  We assume
1150                 # that the first pseudomerge after an import has a
1151                 # useful history of debian/, and ignore the histories
1152                 # from later pseudomerges.  Often the first pseudomerge
1153                 # will be the dgit import of the upload to the actual
1154                 # suite intended by the non-dgit NMUer, and later
1155                 # pseudomerges may represent in-archive copies.
1156                 my $ovwrs = $pm->{Overwritten};
1157                 printf $report " PM=%s \@Overwr:%d",
1158                     $pm->{CommitId}, (scalar @$ovwrs)
1159                     if $report;
1160                 if (@$ovwrs != 1) {
1161                     printdebug "*** WALK BOMB DgitImportUnpatched\n";
1162                     return $bomb->();
1163                 }
1164                 my $ovwr = $ovwrs->[0]{CommitId};
1165                 printf $report " Overwr=%s", $ovwr if $report;
1166                 # This import has a tree which is just like a
1167                 # breakwater tree, but it has the wrong history.  It
1168                 # ought to have the previous breakwater (which the
1169                 # pseudomerge overwrote) as an ancestor.  That will
1170                 # make the history of the debian/ files correct.  As
1171                 # for the upstream version: either it's the same as
1172                 # was ovewritten (ie, same as the previous
1173                 # breakwater), in which case that history is precisely
1174                 # right; or, otherwise, it was a non-gitish upload of a
1175                 # new upstream version.  We can tell these apart by
1176                 # looking at the tree of the supposed upstream.
1177                 push @brw_cl, {
1178                     %$cl,
1179                     SpecialMethod => 'DgitImportDebianUpdate',
1180                     $xmsg->("convert dgit import: debian changes")
1181                 }, {
1182                     %$cl,
1183                     SpecialMethod => 'DgitImportUpstreamUpdate',
1184                     $xmsg->("convert dgit import: upstream update",
1185                             " anchor")
1186                 };
1187                 $prline->(" Import");
1188                 $rewrite_from_here->(\@brw_cl);
1189                 $upp_limit //= $#upp_cl; # further, deeper, patches discarded
1190                 $cur = $ovwr;
1191                 next;
1192             } else {
1193                 # Everything is from this import.  This kind of import
1194                 # is already nearly in valid breakwater format, with the
1195                 # patches as commits.  Unfortunately it contains
1196                 # debian/patches/.
1197                 printdebug "*** WALK BOMB bare dgit import\n";
1198                 $cl->{Why} = "bare dgit dsc import";
1199                 return $bomb->();
1200             }
1201             die "$ty ?";
1202         } elsif ($ty eq 'MergedBreakwaters') {
1203             $last_anchor = mergedbreakwaters_anchor $cl;
1204             $build_start->(' MergedBreakwaters', $cur);
1205             last;
1206         } elsif ($ty eq 'VanillaMerge') {
1207             # User may have merged unstitched branch(es).  We will
1208             # have now lost what ffq-prev was then (since the later
1209             # pseudomerge may introduce further changes).  The effect
1210             # of resolving such a merge is that we may have to go back
1211             # further in history to find a merge base, since the one
1212             # which was reachable via ffq-prev is no longer findable.
1213             # This is suboptimal, but if it all works we'll have done
1214             # the right thing.
1215             # xxx we should warn the user in the docs about this
1216
1217             my $ok=1;
1218             my $best_anchor;
1219             # We expect to find a dominating anchor amongst the
1220             # inputs' anchors.  That will be the new anchor.
1221             #
1222             # More complicated is finding a merge base for the
1223             # breakwaters.  We need a merge base that is a breakwater
1224             # commit.  The ancestors of breakwater commits are more
1225             # breakwater commits and possibly upstream commits and the
1226             # ancestors of those upstream.  Upstreams might have
1227             # arbitrary ancestors.  But any upstream commit U is
1228             # either included in both anchors, in which case the
1229             # earlier anchor is a better merge base than any of U's
1230             # ancestors; or U is not included in the older anchor, in
1231             # which case U is not an ancestor of the vanilla merge at
1232             # all.  So no upstream commit, nor any ancestor thereof,
1233             # is a best merge base.  As for non-breakwater Debian
1234             # commits: these are never ancestors of any breakwater.
1235             #
1236             # So any best merge base as found by git-merge-base
1237             # is a suitable breakwater anchor.  Usually there will
1238             # be only one.
1239
1240             printdebug "*** MERGE\n";
1241
1242             my @bwbcmd = (@git, qw(merge-base));
1243             my @ibcmd = (@git, qw(merge-base --all));
1244             my $might_be_in_bw = 1;
1245
1246             my $ps = $cl->{Parents};
1247
1248             $mwrecknote->('vanilla-merge', $cl->{CommitId});
1249
1250             foreach my $p (@$ps) {
1251                 $prline->(" VanillaMerge ".$p->{Ix});
1252                 $prprdelim->();
1253                 my ($ptip, $pbw, $panchor) =
1254                     walk $p->{CommitId}, 0, $report,
1255                          $report_lprefix.'  ';
1256                 $p->{Laundered} = $p->{SeriesTip} = $ptip;
1257                 $p->{Breakwater} = $p->{SeriesBase} = $pbw;
1258                 $p->{Anchor} = $panchor;
1259
1260                 my $lr = $p->{LeftRight} = (qw(left right))[$p->{Ix}];
1261                 $mwrecknote->("$lr-input", $p->{CommitId});
1262
1263                 my $mwrecknote_parent = sub {
1264                     my ($which) = @_;
1265                     $mwrecknote->("$lr-".(lc $which), $p->{$which});
1266                 };
1267                 $mwrecknote_parent->('Laundered');
1268                 $mwrecknote_parent->('Breakwater');
1269                 $mwrecknote_parent->('Anchor');
1270
1271                 $best_anchor = $panchor if
1272                     !defined $best_anchor or
1273                     is_fast_fwd $best_anchor, $panchor;
1274
1275                 printdebug " MERGE BA best=".($best_anchor//'-').
1276                     " p=$panchor\n";
1277             }
1278
1279             $mwrecknote->('result-anchor', $best_anchor);
1280
1281             foreach my $p (@$ps) {
1282                 $prline->(" VanillaMerge ".$p->{Ix});
1283                 if (!is_fast_fwd $p->{Anchor}, $best_anchor) {
1284                     $nomerge->('divergent anchors');
1285                 } elsif ($p->{Anchor} eq $best_anchor) {
1286                     print $report " SameAnchor" if $report;
1287                 } else {
1288                     print $report " SupersededAnchor" if $report;
1289                 }
1290                 if ($p->{Breakwater} eq $p->{CommitId}) {
1291                     # this parent commit was its own breakwater,
1292                     # ie it is part of the breakwater
1293                     print $report " Breakwater" if $report;
1294                 } else {
1295                     $might_be_in_bw = 0;
1296                 }
1297                 push @bwbcmd, $p->{Breakwater};
1298                 push @ibcmd, $p->{CommitId};
1299             }
1300
1301             if ($ok && $might_be_in_bw) {
1302                 # We could rewrite this to contaion the metadata
1303                 # declaring it to be MergedBreakwaters, but
1304                 # unnecessarily rewriting a merge seems unhelpful.
1305                 $prline->(" VanillaMerge MergedBreakwaters");
1306                 $last_anchor = $best_anchor;
1307                 $build_start->('MergedBreakwaters', $cur);
1308             }
1309
1310             my $bwb = cmdoutput @bwbcmd;
1311
1312             # OK, now we have a breakwater base, but we need the merge
1313             # base for the interchange branch because we need the delta
1314             # queue.
1315             #
1316             # This a the best merge base of our inputs which has the
1317             # breakwater merge base as an ancestor.
1318
1319             my @ibs =
1320                 grep /./,
1321                 split /\n/,
1322                 cmdoutput @ibcmd;
1323
1324             @ibs or confess 'internal error, expected anchor at least ?';
1325
1326             my $ib;
1327             my $ibleaf;
1328             foreach my $tibix (0..$#ibs) {
1329                 my $tib = $ibs[$tibix];
1330                 my $ff = is_fast_fwd $bwb, $tib;
1331                 my $ok = !$ff ? 'rej' : $ib ? 'extra' : 'ok';
1332                 my $tibleaf = "interchange-mbcand-$ok-$tibix";
1333                 $mwrecknote->($tibleaf, $tib);
1334                 next unless $ff;
1335                 next if $ib;
1336                 $ib = $tib;
1337                 $ibleaf = $tibleaf;
1338             }
1339
1340             $ib or $nomerge->("no suitable interchange merge base");
1341
1342             $prline->("  VanillaMerge Base");
1343             $prprdelim->();
1344             my ($btip, $bbw, $banchor) = eval {
1345                 walk $ib, 0, $report, $report_lprefix.'  ';
1346             };
1347             $nomerge->("walking interchange branch merge base ($ibleaf):\n".
1348                        $@)
1349                 if length $@;
1350
1351             $mwrecknote->("mergebase-laundered", $btip);
1352             $mwrecknote->("mergebase-breakwater", $bbw);
1353             $mwrecknote->("mergebase-anchor", $banchor);
1354
1355             my $ibinfo = { SeriesTip => $btip,
1356                            SeriesBase => $bbw,
1357                            Anchor => $banchor,
1358                            LeftRight => 'mergebase' };
1359
1360             $bbw eq $bwb
1361                 or $nomerge->("interchange merge-base ($ib)'s".
1362                               " breakwater ($bbw)".
1363                               " != breakwaters' merge-base ($bwb)");
1364
1365             grep { $_->{Anchor} eq $ibinfo->{Anchor} } @$ps
1366                  or $nomerge->("interchange merge-base ($ib)'s".
1367                                " anchor ($ibinfo->{SeriesBase})".
1368                                " != any merge input's anchor (".
1369                                (join ' ', map { $_->{Anchor} } @$ps).
1370                                ")");
1371
1372             $cl->{MergeInterchangeBaseInfo} = $ibinfo;
1373             $cl->{MergeBestAnchor} = $best_anchor;
1374             push @brw_cl, {
1375                 %$cl,
1376                 SpecialMethod => 'MergeCreateMergedBreakwaters',
1377                 $xmsg->('constructed from vanilla merge',
1378                         ' merged-breakwater'),
1379             };
1380             push @upp_cl, {
1381                 %$cl,
1382                 SpecialMethod => 'MergeMergeSeries',
1383             };
1384             $build_start->('MergeBreakwaters', $cur);
1385         } else {
1386             printdebug "*** WALK BOMB unrecognised\n";
1387             return $bomb->();
1388         }
1389     }
1390     $prprdelim->();
1391
1392     printdebug "*** WALK prep done cur=$cur".
1393         " brw $#brw_cl upp $#upp_cl proc $#processed pm $#pseudomerges\n";
1394
1395     return if $nogenerate;
1396
1397     # Now we build it back up again
1398
1399     fresh_workarea();
1400
1401     my $rewriting = 0;
1402
1403     my $read_tree_upstream = sub {
1404         my ($treeish) = @_;
1405         read_tree_upstream $treeish, 0, $build;
1406     };
1407
1408     $#upp_cl = $upp_limit if defined $upp_limit;
1409
1410     my $committer_authline = calculate_committer_authline();
1411
1412     printdebug "WALK REBUILD $build ".(scalar @processed)."\n";
1413
1414     confess "internal error" unless $build eq (pop @processed)->{CommitId};
1415
1416     in_workarea sub {
1417         mkdir $rd or $!==EEXIST or die $!;
1418         my $current_method;
1419         runcmd @git, qw(read-tree), $build;
1420         foreach my $cl (qw(Debian), (reverse @brw_cl),
1421                         { SpecialMethod => 'RecordBreakwaterTip' },
1422                         qw(Upstream), (reverse @upp_cl)) {
1423             if (!ref $cl) {
1424                 $current_method = $cl;
1425                 next;
1426             }
1427             my $method = $cl->{SpecialMethod} // $current_method;
1428             my @parents = ($build);
1429             my $cltree = $cl->{CommitId};
1430             printdebug "WALK BUILD ".($cltree//'undef').
1431                 " $method (rewriting=$rewriting)\n";
1432             if ($method eq 'Debian') {
1433                 read_tree_debian($cltree);
1434             } elsif ($method eq 'Upstream') {
1435                 $read_tree_upstream->($cltree);
1436             } elsif ($method eq 'StartRewrite') {
1437                 $rewriting = 1;
1438                 next;
1439             } elsif ($method eq 'RecordBreakwaterTip') {
1440                 $breakwater = $build;
1441                 next;
1442             } elsif ($method eq 'DgitImportDebianUpdate') {
1443                 read_tree_debian($cltree);
1444             } elsif ($method eq 'DgitImportUpstreamUpdate') {
1445                 confess unless $rewriting;
1446                 my $differs = (get_differs $build, $cltree);
1447                 next unless $differs & D_UPS;
1448                 $read_tree_upstream->($cltree);
1449                 push @parents, map { $_->{CommitId} } @{ $cl->{OrigParents} };
1450             } elsif ($method eq 'MergeCreateMergedBreakwaters') {
1451                 print "Found a general merge, will try to tidy it up.\n";
1452                 $rewriting = 1;
1453                 $read_tree_upstream->($cl->{MergeBestAnchor});
1454                 $read_tree_upstream->($cl->{MergeBestAnchor});
1455                 read_tree_debian($cltree);
1456                 @parents = map { $_->{Breakwater} } @{ $cl->{Parents} };
1457             } elsif ($method eq 'MergeMergeSeries') {
1458                 print "Running merge resolution for $cl->{CommitId}...\n";
1459                 $build = merge_series
1460                     $build, $cl->{MergeWreckNotes},
1461                     $cl->{MergeInterchangeBaseInfo},
1462                     @{ $cl->{Parents} };
1463                 $last_anchor = $cl->{MergeBestAnchor};
1464
1465                 # Check for mismerges:
1466                 my $check = sub {
1467                     my ($against, $allow, $what) = @_;
1468                     my $differs = get_differs $build, $against;
1469                     $nomerge->(sprintf
1470        "merge misresolved: %s are not the same (%s %s d.%#x)",
1471                                $what, $against, $build, $differs)
1472                         if $differs & ~($allow | D_PAT_ADD);
1473                 };
1474
1475                 # Breakwater changes which were in each side of the
1476                 # merge will have been incorporated into the
1477                 # MergeCreateMergedBreakwaters output.  Because the
1478                 # upstream series was rebased onto the new breakwater,
1479                 # so should all of the packaging changes which were in
1480                 # the input.
1481                 $check->($input, D_UPS, 'debian files');
1482
1483                 # Upstream files are merge_series, which ought to
1484                 # have been identical to the original merge.
1485                 $check->($cl->{CommitId}, DS_DEB, 'upstream files');
1486
1487                 print "Merge resolution successful.\n";
1488                 next;
1489             } else {
1490                 confess "$method ?";
1491             }
1492             if (!$rewriting) {
1493                 my $procd = (pop @processed) // 'UNDEF';
1494                 if ($cl ne $procd) {
1495                     $rewriting = 1;
1496                     printdebug "WALK REWRITING NOW cl=$cl procd=$procd\n";
1497                 }
1498             }
1499             my $newtree = cmdoutput @git, qw(write-tree);
1500             my $ch = $cl->{Hdr};
1501             $ch =~ s{^tree .*}{tree $newtree}m or confess "$ch ?";
1502             $ch =~ s{^parent .*\n}{}mg;
1503             $ch =~ s{(?=^author)}{
1504                 join '', map { "parent $_\n" } @parents
1505             }me or confess "$ch ?";
1506             if ($rewriting) {
1507                 $ch =~ s{^committer .*$}{$committer_authline}m
1508                     or confess "$ch ?";
1509             }
1510             my $cf = "$rd/m$rewriting";
1511             open CD, ">", $cf or die $!;
1512             print CD $ch, "\n", $cl->{Msg} or die $!;
1513             close CD or die $!;
1514             my @cmd = (@git, qw(hash-object));
1515             push @cmd, qw(-w) if $rewriting;
1516             push @cmd, qw(-t commit), $cf;
1517             my $newcommit = cmdoutput @cmd;
1518             confess "$ch ?" unless $rewriting or $newcommit eq $cl->{CommitId};
1519             $build = $newcommit;
1520             if (grep { $method eq $_ } qw(DgitImportUpstreamUpdate)) {
1521                 $last_anchor = $cur;
1522             }
1523         }
1524     };
1525
1526     my $final_check = get_differs $build, $input;
1527     die sprintf "internal error %#x %s %s", $final_check, $input, $build
1528         if $final_check & ~D_PAT_ADD;
1529
1530     my @r = ($build, $breakwater, $last_anchor);
1531     printdebug "*** WALK RETURN @r\n";
1532     return @r
1533 }
1534
1535 sub get_head () {
1536     git_check_unmodified();
1537     return git_rev_parse qw(HEAD);
1538 }
1539
1540 sub update_head ($$$) {
1541     my ($old, $new, $mrest) = @_;
1542     push @deferred_updates, "update HEAD $new $old";
1543     run_deferred_updates $mrest;
1544 }
1545
1546 sub update_head_checkout ($$$) {
1547     my ($old, $new, $mrest) = @_;
1548     update_head $old, $new, $mrest;
1549     runcmd @git, qw(reset --hard);
1550 }
1551
1552 sub update_head_postlaunder ($$$) {
1553     my ($old, $tip, $reflogmsg) = @_;
1554     return if $tip eq $old;
1555     print "git-debrebase: laundered (head was $old)\n";
1556     update_head $old, $tip, $reflogmsg;
1557     # no tree changes except debian/patches
1558     runcmd @git, qw(rm --quiet --ignore-unmatch -rf debian/patches);
1559 }
1560
1561 sub currently_rebasing() {
1562     foreach (qw(rebase-merge rebase-apply)) {
1563         return 1 if stat_exists "$maindir_gitdir/$_";
1564     }
1565     return 0;
1566 }
1567
1568 sub bail_if_rebasing() {
1569     fail "you are in the middle of a git-rebase already"
1570         if currently_rebasing();
1571 }
1572
1573 sub do_launder_head ($) {
1574     my ($reflogmsg) = @_;
1575     my $old = get_head();
1576     record_ffq_auto();
1577     my ($tip,$breakwater) = walk $old;
1578     snags_maybe_bail();
1579     update_head_postlaunder $old, $tip, $reflogmsg;
1580     return ($tip,$breakwater);
1581 }
1582
1583 sub cmd_launder_v0 () {
1584     badusage "no arguments to launder-v0 allowed" if @ARGV;
1585     my $old = get_head();
1586     my ($tip,$breakwater,$last_anchor) = walk $old;
1587     update_head_postlaunder $old, $tip, 'launder';
1588     printf "# breakwater tip\n%s\n", $breakwater;
1589     printf "# working tip\n%s\n", $tip;
1590     printf "# last anchor\n%s\n", $last_anchor;
1591 }
1592
1593 sub defaultcmd_rebase () {
1594     push @ARGV, @{ $opt_defaultcmd_interactive // [] };
1595     my ($tip,$breakwater) = do_launder_head 'launder for rebase';
1596     runcmd @git, qw(rebase), @ARGV, $breakwater if @ARGV;
1597 }
1598
1599 sub cmd_analyse () {
1600     badusage "analyse does not support any options"
1601         if @ARGV and $ARGV[0] =~ m/^-/;
1602     badusage "too many arguments to analyse" if @ARGV>1;
1603     my ($old) = @ARGV;
1604     if (defined $old) {
1605         $old = git_rev_parse $old;
1606     } else {
1607         $old = git_rev_parse 'HEAD';
1608     }
1609     my ($dummy,$breakwater) = walk $old, 1,*STDOUT;
1610     STDOUT->error and die $!;
1611 }
1612
1613 sub ffq_prev_branchinfo () {
1614     my $current = git_get_symref();
1615     return gdr_ffq_prev_branchinfo($current);
1616 }
1617
1618 sub ffq_check ($;$$) {
1619     # calls $ff and/or $notff zero or more times
1620     # then returns either (status,message) where status is
1621     #    exists
1622     #    detached
1623     #    weird-symref
1624     #    notbranch
1625     # or (undef,undef, $ffq_prev,$gdrlast)
1626     # $ff and $notff are called like this:
1627     #   $ff->("message for stdout\n");
1628     #   $notff->('snag-name', $message);
1629     # normally $currentval should be HEAD
1630     my ($currentval, $ff, $notff) =@_;
1631
1632     $ff //= sub { print $_[0] or die $!; };
1633     $notff //= \&snag;
1634
1635     my ($status, $message, $current, $ffq_prev, $gdrlast)
1636         = ffq_prev_branchinfo();
1637     return ($status, $message) unless $status eq 'branch';
1638
1639     my $exists = git_get_ref $ffq_prev;
1640     return ('exists',"$ffq_prev already exists") if $exists;
1641
1642     return ('not-branch', 'HEAD symref is not to refs/heads/')
1643         unless $current =~ m{^refs/heads/};
1644     my $branch = $';
1645
1646     my @check_specs = split /\;/, (cfg "branch.$branch.ffq-ffrefs",1) // '*';
1647     my %checked;
1648
1649     printdebug "ffq check_specs @check_specs\n";
1650
1651     my $check = sub {
1652         my ($lrref, $desc) = @_;
1653         printdebug "ffq might check $lrref ($desc)\n";
1654         my $invert;
1655         for my $chk (@check_specs) {
1656             my $glob = $chk;
1657             $invert = $glob =~ s{^[!^]}{};
1658             last if fnmatch $glob, $lrref;
1659         }
1660         return if $invert;
1661         my $lrval = git_get_ref $lrref;
1662         return unless length $lrval;
1663
1664         if (is_fast_fwd $lrval, $currentval) {
1665             $ff->("OK, you are ahead of $lrref\n");
1666             $checked{$lrref} = 1;
1667         } elsif (is_fast_fwd $currentval, $lrval) {
1668             $checked{$lrref} = -1;
1669             $notff->('behind', "you are behind $lrref, divergence risk");
1670         } else {
1671             $checked{$lrref} = -1;
1672             $notff->('diverged', "you have diverged from $lrref");
1673         }
1674     };
1675
1676     my $merge = cfg "branch.$branch.merge",1;
1677     if (defined $merge and $merge =~ m{^refs/heads/}) {
1678         my $rhs = $';
1679         printdebug "ffq merge $rhs\n";
1680         my $check_remote = sub {
1681             my ($remote, $desc) = @_;
1682             printdebug "ffq check_remote ".($remote//'undef')." $desc\n";
1683             return unless defined $remote;
1684             $check->("refs/remotes/$remote/$rhs", $desc);
1685         };
1686         $check_remote->((scalar cfg "branch.$branch.remote",1),
1687                         'remote fetch/merge branch');
1688         $check_remote->((scalar cfg "branch.$branch.pushRemote",1) //
1689                         (scalar cfg "branch.$branch.pushDefault",1),
1690                         'remote push branch');
1691     }
1692     if ($branch =~ m{^dgit/}) {
1693         $check->("refs/remotes/dgit/$branch", 'remote dgit branch');
1694     } elsif ($branch =~ m{^master$}) {
1695         $check->("refs/remotes/dgit/dgit/sid", 'remote dgit branch for sid');
1696     }
1697     return (undef, undef, $ffq_prev, $gdrlast);
1698 }
1699
1700 sub record_ffq_prev_deferred () {
1701     # => ('status', "message")
1702     # 'status' may be
1703     #    deferred          message is undef
1704     #    exists
1705     #    detached
1706     #    weird-symref
1707     #    notbranch
1708     # if not ff from some branch we should be ff from, is an snag
1709     # if "deferred", will have added something about that to
1710     #   @deferred_update_messages, and also maybe printed (already)
1711     #   some messages about ff checks
1712     bail_if_rebasing();
1713     my $currentval = get_head();
1714
1715     my ($status,$message, $ffq_prev,$gdrlast) = ffq_check $currentval;
1716     return ($status,$message) if defined $status;
1717
1718     snags_maybe_bail();
1719
1720     push @deferred_updates, "update $ffq_prev $currentval $git_null_obj";
1721     push @deferred_updates, "delete $gdrlast";
1722     push @deferred_update_messages, "Recorded previous head for preservation";
1723     return ('deferred', undef);
1724 }
1725
1726 sub record_ffq_auto () {
1727     my ($status, $message) = record_ffq_prev_deferred();
1728     if ($status eq 'deferred' || $status eq 'exists') {
1729     } else {
1730         snag $status, "could not record ffq-prev: $message";
1731         snags_maybe_bail();
1732     }
1733 }
1734
1735 sub ffq_prev_info () {
1736     bail_if_rebasing();
1737     # => ($ffq_prev, $gdrlast, $ffq_prev_commitish)
1738     my ($status, $message, $current, $ffq_prev, $gdrlast)
1739         = ffq_prev_branchinfo();
1740     if ($status ne 'branch') {
1741         snag $status, "could not check ffq-prev: $message";
1742         snags_maybe_bail();
1743     }
1744     my $ffq_prev_commitish = $ffq_prev && git_get_ref $ffq_prev;
1745     return ($ffq_prev, $gdrlast, $ffq_prev_commitish);
1746 }
1747
1748 sub stitch ($$$$$) {
1749     my ($old_head, $ffq_prev, $gdrlast, $ffq_prev_commitish, $prose) = @_;
1750
1751     push @deferred_updates, "delete $ffq_prev $ffq_prev_commitish";
1752
1753     if (is_fast_fwd $old_head, $ffq_prev_commitish) {
1754         my $differs = get_differs $old_head, $ffq_prev_commitish;
1755         unless ($differs & ~D_PAT_ADD) {
1756             # ffq-prev is ahead of us, and the only tree changes it has
1757             # are possibly addition of things in debian/patches/.
1758             # Just wind forwards rather than making a pointless pseudomerge.
1759             push @deferred_updates,
1760                 "update $gdrlast $ffq_prev_commitish $git_null_obj";
1761             update_head_checkout $old_head, $ffq_prev_commitish,
1762                 "stitch (fast forward)";
1763             return;
1764         }
1765     }
1766     fresh_workarea();
1767     # We make pseudomerges with L as the contributing parent.
1768     # This makes git rev-list --first-parent work properly.
1769     my $new_head = make_commit [ $old_head, $ffq_prev ], [
1770         'Declare fast forward / record previous work',
1771         "[git-debrebase pseudomerge: $prose]",
1772     ];
1773     push @deferred_updates, "update $gdrlast $new_head $git_null_obj";
1774     update_head $old_head, $new_head, "stitch: $prose";
1775 }
1776
1777 sub do_stitch ($;$) {
1778     my ($prose, $unclean) = @_;
1779
1780     my ($ffq_prev, $gdrlast, $ffq_prev_commitish) = ffq_prev_info();
1781     if (!$ffq_prev_commitish) {
1782         fail "No ffq-prev to stitch." unless $opt_noop_ok;
1783         return;
1784     }
1785     my $dangling_head = get_head();
1786
1787     keycommits $dangling_head, $unclean,$unclean,$unclean;
1788     snags_maybe_bail();
1789
1790     stitch($dangling_head, $ffq_prev, $gdrlast, $ffq_prev_commitish, $prose);
1791 }
1792
1793 sub upstream_commitish_search ($$) {
1794     my ($upstream_version, $tried) = @_;
1795     # todo: at some point maybe use git-deborig to do this
1796     foreach my $tagpfx ('', 'v', 'upstream/') {
1797         my $tag = $tagpfx.(dep14_version_mangle $upstream_version);
1798         my $new_upstream = git_get_ref "refs/tags/$tag";
1799         push @$tried, $tag;
1800         return $new_upstream if length $new_upstream;
1801     }
1802 }
1803
1804 sub resolve_upstream_version ($$) {
1805     my ($new_upstream, $upstream_version) = @_;
1806
1807     if (!defined $new_upstream) {
1808         my @tried;
1809         $new_upstream = upstream_commitish_search $upstream_version, \@tried;
1810         if (!length $new_upstream) {
1811             fail "Could not determine appropriate upstream commitish.\n".
1812                 " (Tried these tags: @tried)\n".
1813                 " Check version, and specify upstream commitish explicitly.";
1814         }
1815     }
1816     $new_upstream = git_rev_parse $new_upstream;
1817
1818     return $new_upstream;
1819 }
1820
1821 sub cmd_new_upstream () {
1822     # automatically and unconditionally launders before rebasing
1823     # if rebase --abort is used, laundering has still been done
1824
1825     my %pieces;
1826
1827     badusage "need NEW-VERSION [UPS-COMMITTISH]" unless @ARGV >= 1;
1828
1829     # parse args - low commitment
1830     my $spec_version = shift @ARGV;
1831     my $new_version = (new Dpkg::Version $spec_version, check => 1);
1832     fail "bad version number \`$spec_version'" unless defined $new_version;
1833     if ($new_version->is_native()) {
1834         $new_version = (new Dpkg::Version "$spec_version-1", check => 1);
1835     }
1836
1837     my $new_upstream = shift @ARGV;
1838     my $new_upstream_version = upstreamversion  $new_version;
1839     $new_upstream =
1840         resolve_upstream_version $new_upstream, $new_upstream_version;
1841
1842     record_ffq_auto();
1843
1844     my $piece = sub {
1845         my ($n, @x) = @_; # may be ''
1846         my $pc = $pieces{$n} //= {
1847             Name => $n,
1848             Desc => ($n ? "upstream piece \`$n'" : "upstream (main piece"),
1849         };
1850         while (my $k = shift @x) { $pc->{$k} = shift @x; }
1851         $pc;
1852     };
1853
1854     my @newpieces;
1855     my $newpiece = sub {
1856         my ($n, @x) = @_; # may be ''
1857         my $pc = $piece->($n, @x, NewIx => (scalar @newpieces));
1858         push @newpieces, $pc;
1859     };
1860
1861     $newpiece->('',
1862         OldIx => 0,
1863         New => $new_upstream,
1864     );
1865     while (@ARGV && $ARGV[0] !~ m{^-}) {
1866         my $n = shift @ARGV;
1867
1868         badusage "for each EXTRA-UPS-NAME need EXTRA-UPS-COMMITISH"
1869             unless @ARGV && $ARGV[0] !~ m{^-};
1870
1871         my $c = git_rev_parse shift @ARGV;
1872         die unless $n =~ m/^$extra_orig_namepart_re$/;
1873         $newpiece->($n, New => $c);
1874     }
1875
1876     # now we need to investigate the branch this generates the
1877     # laundered version but we don't switch to it yet
1878     my $old_head = get_head();
1879     my ($old_laundered_tip,$old_bw,$old_anchor) = walk $old_head;
1880
1881     my $old_bw_cl = classify $old_bw;
1882     my $old_anchor_cl = classify $old_anchor;
1883     my $old_upstream;
1884     if (!$old_anchor_cl->{OrigParents}) {
1885         snag 'anchor-treated',
1886             'old anchor is recognised due to --anchor, cannot check upstream';
1887     } else {
1888         $old_upstream = parsecommit
1889             $old_anchor_cl->{OrigParents}[0]{CommitId};
1890         $piece->('', Old => $old_upstream->{CommitId});
1891     }
1892
1893     if ($old_upstream && $old_upstream->{Msg} =~ m{^\[git-debrebase }m) {
1894         if ($old_upstream->{Msg} =~
1895  m{^\[git-debrebase upstream-combine (\.(?: $extra_orig_namepart_re)+)\:.*\]$}m
1896            ) {
1897             my @oldpieces = (split / /, $1);
1898             my $old_n_parents = scalar @{ $old_upstream->{Parents} };
1899             if ($old_n_parents != @oldpieces &&
1900                 $old_n_parents != @oldpieces + 1) {
1901                 snag 'upstream-confusing', sprintf
1902                     "previous upstream combine %s".
1903                     " mentions %d pieces (each implying one parent)".
1904                     " but has %d parents".
1905                     " (one per piece plus maybe a previous combine)",
1906                     $old_upstream->{CommitId},
1907                     (scalar @oldpieces),
1908                     $old_n_parents;
1909             } elsif ($oldpieces[0] ne '.') {
1910                 snag 'upstream-confusing', sprintf
1911                     "previous upstream combine %s".
1912                     " first piece is not \`.'",
1913                     $oldpieces[0];
1914             } else {
1915                 $oldpieces[0] = '';
1916                 foreach my $i (0..$#oldpieces) {
1917                     my $n = $oldpieces[$i];
1918                     my $hat = 1 + $i + ($old_n_parents - @oldpieces);
1919                     $piece->($n, Old => $old_upstream->{CommitId}.'^'.$hat);
1920                 }
1921             }
1922         } else {
1923             snag 'upstream-confusing',
1924                 "previous upstream $old_upstream->{CommitId} is from".
1925                " git-debrebase but not an \`upstream-combine' commit";
1926         }
1927     }
1928
1929     foreach my $pc (values %pieces) {
1930         if (!$old_upstream) {
1931             # we have complained already
1932         } elsif (!$pc->{Old}) {
1933             snag 'upstream-new-piece',
1934                 "introducing upstream piece \`$pc->{Name}'";
1935         } elsif (!$pc->{New}) {
1936             snag 'upstream-rm-piece',
1937                 "dropping upstream piece \`$pc->{Name}'";
1938         } elsif (!is_fast_fwd $pc->{Old}, $pc->{New}) {
1939             snag 'upstream-not-ff',
1940                 "not fast forward: $pc->{Name} $pc->{Old}..$pc->{New}";
1941         }
1942     }
1943
1944     printdebug "%pieces = ", (dd \%pieces), "\n";
1945     printdebug "\@newpieces = ", (dd \@newpieces), "\n";
1946
1947     snags_maybe_bail();
1948
1949     my $new_bw;
1950
1951     fresh_workarea();
1952     in_workarea sub {
1953         my @upstream_merge_parents;
1954
1955         if (!any_snags()) {
1956             push @upstream_merge_parents, $old_upstream->{CommitId};
1957         }
1958
1959         foreach my $pc (@newpieces) { # always has '' first
1960             if ($pc->{Name}) {
1961                 read_tree_subdir $pc->{Name}, $pc->{New};
1962             } else {
1963                 runcmd @git, qw(read-tree), $pc->{New};
1964             }
1965             push @upstream_merge_parents, $pc->{New};
1966         }
1967
1968         # index now contains the new upstream
1969
1970         if (@newpieces > 1) {
1971             # need to make the upstream subtree merge commit
1972             $new_upstream = make_commit \@upstream_merge_parents,
1973                 [ "Combine upstreams for $new_upstream_version",
1974  ("[git-debrebase upstream-combine . ".
1975  (join " ", map { $_->{Name} } @newpieces[1..$#newpieces]).
1976  ": new upstream]"),
1977                 ];
1978         }
1979
1980         # $new_upstream is either the single upstream commit, or the
1981         # combined commit we just made.  Either way it will be the
1982         # "upstream" parent of the anchor merge.
1983
1984         read_tree_subdir 'debian', "$old_bw:debian";
1985
1986         # index now contains the anchor merge contents
1987         $new_bw = make_commit [ $old_bw, $new_upstream ],
1988             [ "Update to upstream $new_upstream_version",
1989  "[git-debrebase anchor: new upstream $new_upstream_version, merge]",
1990             ];
1991
1992         my $clogsignoff = cmdoutput qw(git show),
1993             '--pretty=format:%an <%ae>  %aD',
1994             $new_bw;
1995
1996         # Now we have to add a changelog stanza so the Debian version
1997         # is right.
1998         die if unlink "debian";
1999         die $! unless $!==ENOENT or $!==ENOTEMPTY;
2000         unlink "debian/changelog" or $!==ENOENT or die $!;
2001         mkdir "debian" or die $!;
2002         open CN, ">", "debian/changelog" or die $!;
2003         my $oldclog = git_cat_file ":debian/changelog";
2004         $oldclog =~ m/^($package_re) \(\S+\) / or
2005             fail "cannot parse old changelog to get package name";
2006         my $p = $1;
2007         print CN <<END, $oldclog or die $!;
2008 $p ($new_version) UNRELEASED; urgency=medium
2009
2010   * Update to new upstream version $new_upstream_version.
2011
2012  -- $clogsignoff
2013
2014 END
2015         close CN or die $!;
2016         runcmd @git, qw(update-index --add --replace), 'debian/changelog';
2017
2018         # Now we have the final new breakwater branch in the index
2019         $new_bw = make_commit [ $new_bw ],
2020             [ "Update changelog for new upstream $new_upstream_version",
2021               "[git-debrebase: new upstream $new_upstream_version, changelog]",
2022             ];
2023     };
2024
2025     # we have constructed the new breakwater. we now need to commit to
2026     # the laundering output, because git-rebase can't easily be made
2027     # to make a replay list which is based on some other branch
2028
2029     update_head_postlaunder $old_head, $old_laundered_tip,
2030         'launder for new upstream';
2031
2032     my @cmd = (@git, qw(rebase --onto), $new_bw, $old_bw, @ARGV);
2033     local $ENV{GIT_REFLOG_ACTION} = git_reflog_action_msg
2034         "debrebase new-upstream $new_version: rebase";
2035     runcmd @cmd;
2036     # now it's for the user to sort out
2037 }
2038
2039 sub cmd_record_ffq_prev () {
2040     badusage "no arguments allowed" if @ARGV;
2041     my ($status, $msg) = record_ffq_prev_deferred();
2042     if ($status eq 'exists' && $opt_noop_ok) {
2043         print "Previous head already recorded\n" or die $!;
2044     } elsif ($status eq 'deferred') {
2045         run_deferred_updates 'record-ffq-prev';
2046     } else {
2047         fail "Could not preserve: $msg";
2048     }
2049 }
2050
2051 sub cmd_anchor () {
2052     badusage "no arguments allowed" if @ARGV;
2053     my ($anchor, $bw) = keycommits +(git_rev_parse 'HEAD'), 0,0;
2054     print "$bw\n" or die $!;
2055 }
2056
2057 sub cmd_breakwater () {
2058     badusage "no arguments allowed" if @ARGV;
2059     my ($anchor, $bw) = keycommits +(git_rev_parse 'HEAD'), 0,0;
2060     print "$bw\n" or die $!;
2061 }
2062
2063 sub cmd_status () {
2064     badusage "no arguments allowed" if @ARGV;
2065
2066     # todo: gdr status should print divergence info
2067     # todo: gdr status should print upstream component(s) info
2068     # todo: gdr should leave/maintain some refs with this kind of info ?
2069
2070     my $oldest = { Badness => 0 };
2071     my $newest;
2072     my $note = sub {
2073         my ($badness, $ourmsg, $snagname, $dummy, $cl, $kcmsg) = @_;
2074         if ($oldest->{Badness} < $badness) {
2075             $oldest = $newest = undef;
2076         }
2077         $oldest = {
2078                    Badness => $badness,
2079                    CommitId => $cl->{CommitId},
2080                    OurMsg => $ourmsg,
2081                    KcMsg => $kcmsg,
2082                   };
2083         $newest //= $oldest;
2084     };
2085     my ($anchor, $bw) = keycommits +(git_rev_parse 'HEAD'),
2086         sub { $note->(1, 'branch contains furniture (not laundered)', @_); },
2087         sub { $note->(2, 'branch is unlaundered', @_); },
2088         sub { $note->(3, 'branch needs laundering', @_); },
2089         sub { $note->(4, 'branch not in git-debrebase form', @_); };
2090
2091     my $prcommitinfo = sub {
2092         my ($cid) = @_;
2093         flush STDOUT or die $!;
2094         runcmd @git, qw(--no-pager log -n1),
2095             '--pretty=format:    %h %s%n',
2096             $cid;
2097     };
2098
2099     print "current branch contents, in git-debrebase terms:\n";
2100     if (!$oldest->{Badness}) {
2101         print "  branch is laundered\n";
2102     } else {
2103         print "  $oldest->{OurMsg}\n";
2104         my $printed = '';
2105         foreach my $info ($oldest, $newest) {
2106             my $cid = $info->{CommitId};
2107             next if $cid eq $printed;
2108             $printed = $cid;
2109             print "  $info->{KcMsg}\n";
2110             $prcommitinfo->($cid);
2111         }
2112     }
2113
2114     my $prab = sub {
2115         my ($cid, $what) = @_;
2116         if (!defined $cid) {
2117             print "  $what is not well-defined\n";
2118         } else {
2119             print "  $what\n";
2120             $prcommitinfo->($cid);
2121         }
2122     };
2123     print "key git-debrebase commits:\n";
2124     $prab->($anchor, 'anchor');
2125     $prab->($bw, 'breakwater');
2126
2127     my ($ffqstatus, $ffq_msg, $current, $ffq_prev, $gdrlast) =
2128         ffq_prev_branchinfo();
2129
2130     print "branch and ref status, in git-debrebase terms:\n";
2131     if ($ffq_msg) {
2132         print "  $ffq_msg\n";
2133     } else {
2134         $ffq_prev = git_get_ref $ffq_prev;
2135         $gdrlast = git_get_ref $gdrlast;
2136         if ($ffq_prev) {
2137             print "  unstitched; previous tip was:\n";
2138             $prcommitinfo->($ffq_prev);
2139         } elsif (!$gdrlast) {
2140             print "  stitched? (no record of git-debrebase work)\n";
2141         } elsif (is_fast_fwd $gdrlast, 'HEAD') {
2142             print "  stitched\n";
2143         } else {
2144             print "  not git-debrebase (diverged since last stitch)\n"
2145         }
2146     }
2147     print "you are currently rebasing\n" if currently_rebasing();
2148 }
2149
2150 sub cmd_stitch () {
2151     my $prose = 'stitch';
2152     getoptions("stitch",
2153                'prose=s', \$prose);
2154     badusage "no arguments allowed" if @ARGV;
2155     do_stitch $prose, 0;
2156 }
2157 sub cmd_prepush () { cmd_stitch(); }
2158
2159 sub cmd_quick () {
2160     badusage "no arguments allowed" if @ARGV;
2161     do_launder_head 'launder for git-debrebase quick';
2162     do_stitch 'quick';
2163 }
2164
2165 sub cmd_conclude () {
2166     my ($ffq_prev, $gdrlast, $ffq_prev_commitish) = ffq_prev_info();
2167     if (!$ffq_prev_commitish) {
2168         fail "No ongoing git-debrebase session." unless $opt_noop_ok;
2169         return;
2170     }
2171     my $dangling_head = get_head();
2172
2173     badusage "no arguments allowed" if @ARGV;
2174     do_launder_head 'launder for git-debrebase quick';
2175     do_stitch 'quick';
2176 }
2177
2178 sub cmd_scrap () {
2179     if (currently_rebasing()) {
2180         runcmd @git, qw(rebase --abort);
2181     }
2182     my ($ffq_prev, $gdrlast, $ffq_prev_commitish) = ffq_prev_info();
2183     if (!$ffq_prev_commitish) {
2184         fail "No ongoing git-debrebase session." unless $opt_noop_ok;
2185         finish 0;
2186     }
2187     my $scrapping_head = get_head();
2188     badusage "no arguments allowed" if @ARGV;
2189     push @deferred_updates,
2190         "update $gdrlast $ffq_prev_commitish $git_null_obj",
2191         "update $ffq_prev $git_null_obj $ffq_prev_commitish";
2192     snags_maybe_bail();
2193     update_head_checkout $scrapping_head, $ffq_prev_commitish, "scrap";
2194 }
2195
2196 sub make_patches_staged ($) {
2197     my ($head) = @_;
2198     # Produces the patches that would result from $head if it were
2199     # laundered.
2200     my ($secret_head, $secret_bw, $last_anchor) = walk $head;
2201     fresh_workarea();
2202     in_workarea sub {
2203         gbp_pq_export 'bw', $secret_bw, $secret_head;
2204     };
2205 }
2206
2207 sub make_patches ($) {
2208     my ($head) = @_;
2209     keycommits $head, 0, \&snag;
2210     make_patches_staged $head;
2211     my $out;
2212     in_workarea sub {
2213         my $ptree = cmdoutput @git, qw(write-tree --prefix=debian/patches/);
2214         runcmd @git, qw(read-tree), $head;
2215         read_tree_subdir 'debian/patches', $ptree;
2216         $out = make_commit [$head], [
2217             'Commit patch queue (exported by git-debrebase)',
2218             '[git-debrebase: export and commit patches]',
2219         ];
2220     };
2221     return $out;
2222 }
2223
2224 sub cmd_make_patches () {
2225     my $opt_quiet_would_amend;
2226     getoptions("make-patches",
2227                'quiet-would-amend!', \$opt_quiet_would_amend);
2228     badusage "no arguments allowed" if @ARGV;
2229     bail_if_rebasing();
2230     my $old_head = get_head();
2231     my $new = make_patches $old_head;
2232     my $d = get_differs $old_head, $new;
2233     if ($d == 0) {
2234         fail "No (more) patches to export." unless $opt_noop_ok;
2235         return;
2236     } elsif ($d == D_PAT_ADD) {
2237         snags_maybe_bail();
2238         update_head_checkout $old_head, $new, 'make-patches';
2239     } else {
2240         print STDERR failmsg
2241             "Patch export produced patch amendments".
2242             " (abandoned output commit $new).".
2243             "  Try laundering first."
2244             unless $opt_quiet_would_amend;
2245         finish 7;
2246     }
2247 }
2248
2249 sub cmd_convert_from_gbp () {
2250     badusage "want only 1 optional argument, the upstream git commitish"
2251         unless @ARGV<=1;
2252
2253     my $clogp = parsechangelog();
2254     my $version = $clogp->{'Version'}
2255         // die "missing Version from changelog";
2256
2257     my ($upstream_spec) = @ARGV;
2258
2259     my $upstream_version = upstreamversion $version;
2260     my $upstream =
2261         resolve_upstream_version($upstream_spec, $upstream_version);
2262
2263     my $old_head = get_head();
2264
2265     my $upsdiff = get_differs $upstream, $old_head;
2266     if ($upsdiff & D_UPS) {
2267         runcmd @git, qw(--no-pager diff --stat),
2268             $upstream, $old_head,
2269             qw( -- :!/debian :/);
2270         fail <<END;
2271 upstream ($upstream_spec) and HEAD are not
2272 identical in upstream files.  See diffstat above, or run
2273   git diff $upstream_spec HEAD -- :!/debian :/
2274 END
2275     }
2276
2277     if (!is_fast_fwd $upstream, $old_head) {
2278         snag 'upstream-not-ancestor',
2279             "upstream ($upstream) is not an ancestor of HEAD";
2280     } else {
2281         my $wrong = cmdoutput
2282             (@git, qw(rev-list --ancestry-path), "$upstream..HEAD",
2283              qw(-- :/ :!/debian));
2284         if (length $wrong) {
2285             snag 'unexpected-upstream-changes',
2286                 "history between upstream ($upstream) and HEAD contains direct changes to upstream files - are you sure this is a gbp (patches-unapplied) branch?";
2287             print STDERR "list expected changes with:  git log --stat --ancestry-path $upstream_spec..HEAD -- :/ ':!/debian'\n";
2288         }
2289     }
2290
2291     if ((git_cat_file "$upstream:debian")[0] ne 'missing') {
2292         snag 'upstream-has-debian',
2293             "upstream ($upstream) contains debian/ directory";
2294     }
2295
2296     my $previous_dgit_view = eval {
2297         my @clogcmd = qw(dpkg-parsechangelog --format rfc822 -n2);
2298         my ($lvsn, $suite);
2299         parsechangelog_loop \@clogcmd, 'debian/changelog', sub {
2300             my ($stz, $desc) = @_;
2301             no warnings qw(exiting);
2302             printdebug 'CHANGELOG ', Dumper($desc, $stz);
2303             next unless $stz->{Date};
2304             next unless $stz->{Distribution} ne 'UNRELEASED';
2305             $lvsn = $stz->{Version};
2306             $suite = $stz->{Distribution};
2307             last;
2308         };
2309         die "neither of the first two changelog entries are released\n"
2310             unless defined $lvsn;
2311         print "last finished-looking changelog entry: ($lvsn) $suite\n";
2312         my $mtag_pat = debiantag_maintview $lvsn, '*';
2313         my $mtag = cmdoutput @git, qw(describe --always --abbrev=0 --match),
2314             $mtag_pat;
2315         die "could not find suitable maintainer view tag $mtag_pat\n"
2316             unless $mtag_pat =~ m{/};
2317         is_fast_fwd $mtag, 'HEAD' or
2318             die "HEAD is not FF from maintainer tag $mtag!";
2319         my $dtag = "archive/$mtag";
2320         is_fast_fwd $mtag, $dtag or
2321             die "dgit view tag $dtag is not FF from maintainer tag $mtag";
2322         print "will stitch in dgit view, $dtag\n";
2323         git_rev_parse $dtag;
2324     };
2325     if (!$previous_dgit_view) {
2326         $@ =~ s/^\n+//;
2327         chomp $@;
2328         print STDERR "cannot stitch in dgit view: $@\n";
2329     }
2330
2331     snags_maybe_bail_early();
2332
2333     my $work;
2334
2335     fresh_workarea();
2336     in_workarea sub {
2337         runcmd @git, qw(checkout -q -b gdr-internal), $old_head;
2338         # make a branch out of the patch queue - we'll want this in a mo
2339         runcmd qw(gbp pq import);
2340         # strip the patches out
2341         runcmd @git, qw(checkout -q gdr-internal~0);
2342         rm_subdir_cached 'debian/patches';
2343         $work = make_commit ['HEAD'], [
2344  'git-debrebase convert-from-gbp: drop patches from tree',
2345  'Delete debian/patches, as part of converting to git-debrebase format.',
2346  '[git-debrebase convert-from-gbp: drop patches from tree]'
2347                               ];
2348         # make the anchor merge
2349         # the tree is already exactly right
2350         $work = make_commit [$work, $upstream], [
2351  'git-debrebase import: declare upstream',
2352  'First breakwater merge.',
2353  '[git-debrebase anchor: declare upstream]'
2354                               ];
2355
2356         # rebase the patch queue onto the new breakwater
2357         runcmd @git, qw(reset --quiet --hard patch-queue/gdr-internal);
2358         runcmd @git, qw(rebase --quiet --onto), $work, qw(gdr-internal);
2359         $work = git_rev_parse 'HEAD';
2360
2361         if ($previous_dgit_view) {
2362             $work = make_commit [$work, $previous_dgit_view], [
2363  'git-debrebase import: declare ff from dgit archive view',
2364  '[git-debrebase pseudomerge: import-from-gbp]',
2365             ];
2366         }
2367     };
2368
2369     ffq_check $work;
2370     snags_maybe_bail();
2371     update_head_checkout $old_head, $work, 'convert-from-gbp';
2372 }
2373
2374 sub cmd_convert_to_gbp () {
2375     badusage "no arguments allowed" if @ARGV;
2376     my $head = get_head();
2377     my (undef, undef, undef, $ffq, $gdrlast) = ffq_prev_branchinfo();
2378     keycommits $head, 0;
2379     my $out;
2380     make_patches_staged $head;
2381     in_workarea sub {
2382         $out = make_commit ['HEAD'], [
2383             'Commit patch queue (converted from git-debrebase format)',
2384             '[git-debrebase convert-to-gbp: commit patches]',
2385         ];
2386     };
2387     if (defined $ffq) {
2388         push @deferred_updates, "delete $ffq";
2389         push @deferred_updates, "delete $gdrlast";
2390     }
2391     snags_maybe_bail();
2392     update_head_checkout $head, $out, "convert to gbp (v0)";
2393     print <<END or die $!;
2394 git-debrebase: converted to git-buildpackage branch format
2395 git-debrebase: WARNING: do not now run "git-debrebase" any more
2396 git-debrebase: WARNING: doing so would drop all upstream patches!
2397 END
2398 }
2399
2400 sub cmd_convert_from_dgit_view () {
2401     my $clogp = parsechangelog();
2402
2403     my $bpd = (cfg 'dgit.default.build-products-dir',1) // '..';
2404     my $do_origs = 1;
2405     my $do_tags = 1;
2406     my $always = 0;
2407     my $diagnose = 0;
2408
2409     getoptions("convert-from-dgit-view",
2410                'diagnose!', \$diagnose,
2411                'build-products-dir:s', \$bpd,
2412                'origs!', \$do_origs,
2413                'tags!', \$do_tags,
2414                'always-convert-anyway!', \$always);
2415     fail "takes 1 optional argument, the upstream commitish" if @ARGV>1;
2416
2417     my @upstreams;
2418
2419     if (@ARGV) {
2420         my $spec = shift @ARGV;
2421         my $commit = git_rev_parse "$spec^{commit}";
2422         push @upstreams, { Commit => $commit,
2423                            Source => "$ARGV[0], from command line",
2424                            Only => 1,
2425                          };
2426     }
2427
2428     my $head = get_head();
2429
2430     if (!$always) {
2431         my $troubles = 0;
2432         my $trouble = sub { $troubles++; };
2433         keycommits $head, sub{}, sub{}, $trouble, $trouble;
2434         printdebug "troubles=$troubles\n";
2435         if (!$troubles) {
2436             print STDERR <<END;
2437 $us: Branch already seems to be in git-debrebase format!
2438 $us: --always-convert-anyway would do the conversion operation anyway
2439 $us: but is probably a bad idea.  Probably, you wanted to do nothing.
2440 END
2441             fail "Branch already in git-debrebase format." unless $opt_noop_ok;
2442             finish 0;
2443         }
2444     }
2445
2446     snags_maybe_bail_early();
2447
2448     my $version = upstreamversion $clogp->{Version};
2449     print STDERR "Considering possible commits corresponding to upstream:\n";
2450
2451     if (!@upstreams) {
2452         if ($do_tags) {
2453             my @tried;
2454             my $ups_tag = upstream_commitish_search $version, \@tried;
2455             if ($ups_tag) {
2456                 my $this = "git tag $tried[-1]";
2457                 push @upstreams, { Commit => $ups_tag,
2458                                    Source => $this,
2459                                  };
2460             } else {
2461                 printf STDERR
2462                     " git tag: no suitable tag found (tried %s)\n",
2463                     "@tried";
2464             }
2465         }
2466         if ($do_origs) {
2467             my $p = $clogp->{'Source'};
2468             # we do a quick check to see if there are plausible origs
2469             my $something=0;
2470             if (!opendir BPD, $bpd) {
2471                 die "$bpd: opendir: $!" unless $!==ENOENT;
2472             } else {
2473                 while ($!=0, my $f = readdir BPD) {
2474                     next unless is_orig_file_of_p_v $f, $p, $version;
2475                     printf STDERR
2476                         " orig: found what looks like a .orig, %s\n",
2477                         "$bpd/$f";
2478                     $something=1;
2479                     last;
2480                 }
2481                 die "read $bpd: $!" if $!;
2482                 closedir BPD;
2483             }
2484             if ($something) {
2485                 my $tree = cmdoutput
2486                     @dgit, qw(--build-products-dir), $bpd,
2487                     qw(print-unapplied-treeish);
2488                 fresh_workarea();
2489                 in_workarea sub {
2490                     runcmd @git, qw(reset --quiet), $tree, qw(-- .);
2491                     rm_subdir_cached 'debian';
2492                     $tree = cmdoutput @git, qw(write-tree);
2493                     my $ups_synth = make_commit [], [ <<END, <<END,
2494 Import effective orig tree for upstream version $version
2495 END
2496 This includes the contents of the .orig(s), minus any debian/ directory.
2497
2498 [git-debrebase import-from-dgit-view upstream-import-convert: $version]
2499 END
2500                                                     ];
2501                     push @upstreams, { Commit => $ups_synth,
2502                                        Source => "orig(s) imported via dgit",
2503                                      };
2504                 }
2505             } else {
2506                 printf STDERR
2507                     " orig: no suitable origs found (looked for %s in %s)\n",
2508                     "${p}_".(stripeoch $version)."...", $bpd;
2509             }
2510         }
2511     }
2512
2513     my $some_patches = stat_exists 'debian/patches/series';
2514
2515     print STDERR "Evaluating possible commits corresponding to upstream:\n";
2516
2517     my $result;
2518     foreach my $u (@upstreams) {
2519         my $work = $head;
2520         fresh_workarea();
2521         in_workarea sub {
2522             runcmd @git, qw(reset --quiet), $u->{Commit}, qw(-- .);
2523             runcmd @git, qw(checkout), $u->{Commit}, qw(-- .);
2524             runcmd @git, qw(clean -xdff);
2525             runcmd @git, qw(checkout), $head, qw(-- debian);
2526             if ($some_patches) {
2527                 rm_subdir_cached 'debian/patches';
2528                 $work = make_commit [ $work ], [
2529  'git-debrebase convert-from-dgit-view: drop upstream changes from breakwater',
2530  "Drop upstream changes, and delete debian/patches, as part of converting\n".
2531  "to git-debrebase format.  Upstream changes will appear as commits.",
2532  '[git-debrebase convert-from-dgit-view: drop patches from tree]'
2533                                            ];
2534             }
2535             $work = make_commit [ $work, $u->{Commit} ], [
2536  'git-debrebase convert-from-dgit-view: declare upstream',
2537  '(Re)constructed breakwater merge.',
2538  '[git-debrebase anchor: declare upstream]'
2539                                                          ];
2540             runcmd @git, qw(checkout --quiet -b mk), $work;
2541             if ($some_patches) {
2542                 runcmd @git, qw(checkout), $head, qw(-- debian/patches);
2543                 runcmd @git, qw(reset --quiet);
2544                 my @gbp_cmd = (qw(gbp pq import));
2545                 if (!$diagnose) {
2546                     my $gbp_err = "../gbp-pq-err";
2547                     @gbp_cmd = shell_cmd "exec >$gbp_err 2>&1", @gbp_cmd;
2548                 }
2549                 my $r = system @gbp_cmd;
2550                 if ($r) {
2551                     printf STDERR
2552                         " %s: couldn't apply patches: gbp pq %s",
2553                         $u->{Source}, waitstatusmsg();
2554                     return;
2555                 }
2556             }
2557             my $work = git_rev_parse qw(HEAD);
2558             my $diffout = cmdoutput @git, qw(diff-tree --stat HEAD), $work;
2559             if (length $diffout) {
2560                 print STDERR
2561                     " $u->{Source}: applying patches gives different tree\n";
2562                 print STDERR $diffout if $diagnose;
2563                 return;
2564             }
2565             # OMG!
2566             $u->{Result} = $work;
2567             $result = $u;
2568         };
2569         last if $result;
2570     }
2571
2572     if (!$result) {
2573         fail <<END;
2574 Could not find or construct a suitable upstream commit.
2575 Rerun adding --diagnose after convert-from-dgit-view, or pass a
2576 upstream commmit explicitly or provide suitable origs.
2577 END
2578     }
2579
2580     printf STDERR "Yes, will base new branch on %s\n", $result->{Source};
2581
2582     ffq_check $result->{Result};
2583     snags_maybe_bail();
2584     update_head_checkout $head, $result->{Result},
2585         'convert-from-dgit-view';
2586 }
2587
2588 sub cmd_downstream_rebase_launder_v0 () {
2589     badusage "needs 1 argument, the baseline" unless @ARGV==1;
2590     my ($base) = @ARGV;
2591     $base = git_rev_parse $base;
2592     my $old_head = get_head();
2593     my $current = $old_head;
2594     my $topmost_keep;
2595     for (;;) {
2596         if ($current eq $base) {
2597             $topmost_keep //= $current;
2598             print " $current BASE stop\n";
2599             last;
2600         }
2601         my $cl = classify $current;
2602         print " $current $cl->{Type}";
2603         my $keep = 0;
2604         my $p0 = $cl->{Parents}[0]{CommitId};
2605         my $next;
2606         if ($cl->{Type} eq 'Pseudomerge') {
2607             print " ^".($cl->{Contributor}{Ix}+1);
2608             $next = $cl->{Contributor}{CommitId};
2609         } elsif ($cl->{Type} eq 'AddPatches' or
2610                  $cl->{Type} eq 'Changelog') {
2611             print " strip";
2612             $next = $p0;
2613         } else {
2614             print " keep";
2615             $next = $p0;
2616             $keep = 1;
2617         }
2618         print "\n";
2619         if ($keep) {
2620             $topmost_keep //= $current;
2621         } else {
2622             die "to-be stripped changes not on top of the branch\n"
2623                 if $topmost_keep;
2624         }
2625         $current = $next;
2626     }
2627     if ($topmost_keep eq $old_head) {
2628         print "unchanged\n";
2629     } else {
2630         print "updating to $topmost_keep\n";
2631         update_head_checkout
2632             $old_head, $topmost_keep,
2633             'downstream-rebase-launder-v0';
2634     }
2635 }
2636
2637 getoptions_main
2638           ("bad options\n",
2639            "D+" => \$debuglevel,
2640            'noop-ok', => \$opt_noop_ok,
2641            'f=s' => \@snag_force_opts,
2642            'anchor=s' => \@opt_anchors,
2643            '--dgit=s' => \($dgit[0]),
2644            'force!',
2645            '-i:s' => sub {
2646                my ($opt,$val) = @_;
2647                badusage "git-debrebase: no cuddling to -i for git-rebase"
2648                    if length $val;
2649                die if $opt_defaultcmd_interactive; # should not happen
2650                $opt_defaultcmd_interactive = [ qw(-i) ];
2651                # This access to @ARGV is excessive familiarity with
2652                # Getopt::Long, but there isn't another sensible
2653                # approach.  '-i=s{0,}' does not work with bundling.
2654                push @$opt_defaultcmd_interactive, @ARGV;
2655                @ARGV=();
2656            },
2657            'help' => sub { print $usage_message or die $!; finish 0; },
2658            );
2659
2660 initdebug('git-debrebase ');
2661 enabledebug if $debuglevel;
2662
2663 my $toplevel = cmdoutput @git, qw(rev-parse --show-toplevel);
2664 chdir $toplevel or die "chdir $toplevel: $!";
2665
2666 $rd = fresh_playground "$playprefix/misc";
2667
2668 @opt_anchors = map { git_rev_parse $_ } @opt_anchors;
2669
2670 if (!@ARGV || $opt_defaultcmd_interactive || $ARGV[0] =~ m{^-}) {
2671     defaultcmd_rebase();
2672 } else {
2673     my $cmd = shift @ARGV;
2674     my $cmdfn = $cmd;
2675     $cmdfn =~ y/-/_/;
2676     $cmdfn = ${*::}{"cmd_$cmdfn"};
2677
2678     $cmdfn or badusage "unknown git-debrebase sub-operation $cmd";
2679     $cmdfn->();
2680 }
2681
2682 finish 0;