git-debrebase

   1 #!/usr/bin/perl -w
   2 # git-debrebase
   3 # Script helping make fast-forwarding histories while still rebasing
   4 # upstream deltas when working on Debian packaging
   5 #
   6 # Copyright (C)2017,2018 Ian Jackson
   7 #
   8 # This program is free software: you can redistribute it and/or modify
   9 # it under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation, either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # This program is distributed in the hope that it will be useful,
  14 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20
  21 END { $? = $Debian::Dgit::ExitStatus::desired // -1; };
  22 use Debian::Dgit::GDR;
  23 use Debian::Dgit::ExitStatus;
  24
  25 use strict;
  26
  27 use Debian::Dgit qw(:DEFAULT :playground);
  28 setup_sigwarn();
  29
  30 use Memoize;
  31 use Carp;
  32 use POSIX;
  33 use Data::Dumper;
  34 use Getopt::Long qw(:config posix_default gnu_compat bundling);
  35 use Dpkg::Version;
  36 use File::FnMatch qw(:fnmatch);
  37 use File::Copy;
  38
  39 $debugcmd_when_debuglevel = 2;
  40
  41 our ($usage_message) = <<'END';
  42 usages:
  43   git-debrebase [<options>] [--|-i <git rebase options...>]
  44   git-debrebase [<options>] status
  45   git-debrebase [<options>] prepush [--prose=...]
  46   git-debrebase [<options>] quick|conclude
  47   git-debrebase [<options>] new-upstream <new-version> [<details ...>]
  48   git-debrebase [<options>] convert-from-gbp [<upstream-commitish>]
  49   ...
  50 See git-debrebase(1), git-debrebase(5), dgit-maint-debrebase(7) (in dgit).
  51 END
  52
  53 our ($opt_force, $opt_noop_ok, @opt_anchors);
  54 our ($opt_defaultcmd_interactive);
  55
  56 our $us = qw(git-debrebase);
  57
  58 $|=1;
  59
  60 sub badusage ($) {
  61     my ($m) = @_;
  62     print STDERR "$us: bad usage: $m\n";
  63     finish 8;
  64 }
  65
  66 sub getoptions_main {
  67     my $m = shift;
  68     local $SIG{__WARN__}; # GetOptions calls `warn' to print messages
  69     GetOptions @_ or badusage $m;
  70 }
  71 sub getoptions {
  72     my $sc = shift;
  73     getoptions_main "bad options follow \`git-debrebase $sc'", @_;
  74 }
  75
  76 sub cfg ($;$) {
  77     my ($k, $optional) = @_;
  78     local $/ = "\0";
  79     my @cmd = qw(git config -z);
  80     push @cmd, qw(--get-all) if wantarray;
  81     push @cmd, $k;
  82     my $out = cmdoutput_errok @cmd;
  83     if (!defined $out) {
  84         fail "missing required git config $k" unless $optional;
  85         return ();
  86     }
  87     my @l = split /\0/, $out;
  88     return wantarray ? @l : $l[0];
  89 }
  90
  91 memoize('cfg');
  92
  93 sub dd ($) {
  94     my ($v) = @_;
  95     my $dd = new Data::Dumper [ $v ];
  96     Terse $dd 1; Indent $dd 0; Useqq $dd 1;
  97     return Dump $dd;
  98 }
  99
 100 sub get_commit ($) {
 101     my ($objid) = @_;
 102     my $data = (git_cat_file $objid, 'commit');
 103     $data =~ m/(?<=\n)\n/ or die "$objid ($data) ?";
 104     return ($`,$');
 105 }
 106
 107 sub D_UPS ()      { 0x02; } # upstream files
 108 sub D_PAT_ADD ()  { 0x04; } # debian/patches/ extra patches at end
 109 sub D_PAT_OTH ()  { 0x08; } # debian/patches other changes
 110 sub D_DEB_CLOG () { 0x10; } # debian/ (not patches/ or changelog)
 111 sub D_DEB_OTH ()  { 0x20; } # debian/changelog
 112 sub DS_DEB ()     { D_DEB_CLOG | D_DEB_OTH; } # debian/ (not patches/)
 113
 114 our $playprefix = 'debrebase';
 115 our $rd;
 116 our $workarea;
 117
 118 our @git = qw(git);
 119 our @dgit = qw(dgit);
 120
 121 sub in_workarea ($) {
 122     my ($sub) = @_;
 123     changedir $workarea;
 124     my $r = eval { $sub->(); };
 125     { local $@; changedir $maindir; }
 126     die $@ if $@;
 127 }
 128
 129 sub fresh_workarea () {
 130     $workarea = fresh_playground "$playprefix/work";
 131     in_workarea sub { playtree_setup };
 132 }
 133
 134 our $snags_forced = 0;
 135 our $snags_tripped = 0;
 136 our $snags_summarised = 0;
 137 our @deferred_updates;
 138 our @deferred_update_messages;
 139
 140 sub all_snags_summarised () {
 141     $snags_forced + $snags_tripped == $snags_summarised;
 142 }
 143 sub run_deferred_updates ($) {
 144     my ($mrest) = @_;
 145
 146     confess 'dangerous internal error' unless all_snags_summarised();
 147
 148     my @upd_cmd = (git_update_ref_cmd "debrebase: $mrest", qw(--stdin));
 149     debugcmd '>|', @upd_cmd;
 150     open U, "|-", @upd_cmd or die $!;
 151     foreach (@deferred_updates) {
 152         printdebug ">= ", $_, "\n";
 153         print U $_, "\n" or die $!;
 154     }
 155     printdebug ">\$\n";
 156     close U or failedcmd @upd_cmd;
 157
 158     print $_, "\n" foreach @deferred_update_messages;
 159
 160     @deferred_updates = ();
 161     @deferred_update_messages = ();
 162 }
 163
 164 sub get_differs ($$) {
 165     my ($x,$y) = @_;
 166     # This resembles quiltify_trees_differ, in dgit, a bit.
 167     # But we don't care about modes, or dpkg-source-unrepresentable
 168     # changes, and we don't need the plethora of different modes.
 169     # Conversely we need to distinguish different kinds of changes to
 170     # debian/ and debian/patches/.
 171
 172     my $differs = 0;
 173
 174     my $rundiff = sub {
 175         my ($opts, $limits, $fn) = @_;
 176         my @cmd = (@git, qw(diff-tree -z --no-renames));
 177         push @cmd, @$opts;
 178         push @cmd, "$_:" foreach $x, $y;
 179         push @cmd, '--', @$limits;
 180         my $diffs = cmdoutput @cmd;
 181         foreach (split /\0/, $diffs) { $fn->(); }
 182     };
 183
 184     $rundiff->([qw(--name-only)], [], sub {
 185         $differs |= $_ eq 'debian' ? DS_DEB : D_UPS;
 186     });
 187
 188     if ($differs & DS_DEB) {
 189         $differs &= ~DS_DEB;
 190         $rundiff->([qw(--name-only -r)], [qw(debian)], sub {
 191             $differs |=
 192                 m{^debian/patches/}      ? D_PAT_OTH  :
 193                 $_ eq 'debian/changelog' ? D_DEB_CLOG :
 194                                            D_DEB_OTH;
 195         });
 196         die "mysterious debian changes $x..$y"
 197             unless $differs & (D_PAT_OTH|DS_DEB);
 198     }
 199
 200     if ($differs & D_PAT_OTH) {
 201         my $mode;
 202         $differs &= ~D_PAT_OTH;
 203         my $pat_oth = sub {
 204             $differs |= D_PAT_OTH;
 205             no warnings qw(exiting);  last;
 206         };
 207         $rundiff->([qw(--name-status -r)], [qw(debian/patches/)], sub {
 208             no warnings qw(exiting);
 209             if (!defined $mode) {
 210                 $mode = $_;  next;
 211             }
 212             die unless s{^debian/patches/}{};
 213             my $ok;
 214             if ($mode eq 'A' && !m/\.series$/s) {
 215                 $ok = 1;
 216             } elsif ($mode eq 'M' && $_ eq 'series') {
 217                 my $x_s = (git_cat_file "$x:debian/patches/series", 'blob');
 218                 my $y_s = (git_cat_file "$y:debian/patches/series", 'blob');
 219                 chomp $x_s;  $x_s .= "\n";
 220                 $ok = $x_s eq substr($y_s, 0, length $x_s);
 221             } else {
 222                 # nope
 223             }
 224             $mode = undef;
 225             $differs |= $ok ? D_PAT_ADD : D_PAT_OTH;
 226         });
 227         die "mysterious debian/patches changes $x..$y"
 228             unless $differs & (D_PAT_ADD|D_PAT_OTH);
 229     }
 230
 231     printdebug sprintf "get_differs %s %s = %#x\n", $x, $y, $differs;
 232
 233     return $differs;
 234 }
 235
 236 sub commit_pr_info ($) {
 237     my ($r) = @_;
 238     return Data::Dumper->dump([$r], [qw(commit)]);
 239 }
 240
 241 sub calculate_committer_authline () {
 242     my $c = cmdoutput @git, qw(commit-tree --no-gpg-sign -m),
 243         'DUMMY COMMIT (git-debrebase)', "HEAD:";
 244     my ($h,$m) = get_commit $c;
 245     $h =~ m/^committer .*$/m or confess "($h) ?";
 246     return $&;
 247 }
 248
 249 sub rm_subdir_cached ($) {
 250     my ($subdir) = @_;
 251     runcmd @git, qw(rm --quiet -rf --cached --ignore-unmatch), $subdir;
 252 }
 253
 254 sub read_tree_subdir ($$) {
 255     my ($subdir, $new_tree_object) = @_;
 256     rm_subdir_cached $subdir;
 257     runcmd @git, qw(read-tree), "--prefix=$subdir/", $new_tree_object;
 258 }
 259
 260 sub read_tree_debian ($) {
 261     my ($treeish) = @_;
 262     read_tree_subdir 'debian', "$treeish:debian";
 263     rm_subdir_cached 'debian/patches';
 264 }
 265
 266 sub read_tree_upstream ($;$$) {
 267     my ($treeish, $keep_patches, $tree_with_debian) = @_;
 268     # if $tree_with_debian is supplied, will use that for debian/
 269     # otherwise will save and restore it.
 270     my $debian =
 271         $tree_with_debian ? "$tree_with_debian:debian"
 272         : cmdoutput @git, qw(write-tree --prefix=debian/);
 273     runcmd @git, qw(read-tree), $treeish;
 274     read_tree_subdir 'debian', $debian;
 275     rm_subdir_cached 'debian/patches' unless $keep_patches;
 276 };
 277
 278 sub make_commit ($$) {
 279     my ($parents, $message_paras) = @_;
 280     my $tree = cmdoutput @git, qw(write-tree);
 281     my @cmd = (@git, qw(commit-tree), $tree);
 282     push @cmd, qw(-p), $_ foreach @$parents;
 283     push @cmd, qw(-m), $_ foreach @$message_paras;
 284     return cmdoutput @cmd;
 285 }
 286
 287 our @snag_force_opts;
 288 sub snag ($$;@) {
 289     my ($tag,$msg) = @_; # ignores extra args, for benefit of keycommits
 290     if (grep { $_ eq $tag } @snag_force_opts) {
 291         $snags_forced++;
 292         print STDERR "git-debrebase: snag ignored (-f$tag): $msg\n";
 293     } else {
 294         $snags_tripped++;
 295         print STDERR "git-debrebase: snag detected (-f$tag): $msg\n";
 296     }
 297 }
 298
 299 # Important: all mainline code must call snags_maybe_bail after
 300 # any point where snag might be called, but before making changes
 301 # (eg before any call to run_deferred_updates).  snags_maybe_bail
 302 # may be called more than once if necessary (but this is not ideal
 303 # because then the messages about number of snags may be confusing).
 304 sub snags_maybe_bail () {
 305     return if all_snags_summarised();
 306     if ($snags_forced) {
 307         printf STDERR
 308             "%s: snags: %d overriden by individual -f options\n",
 309             $us, $snags_forced;
 310     }
 311     if ($snags_tripped) {
 312         if ($opt_force) {
 313             printf STDERR
 314                 "%s: snags: %d overriden by global --force\n",
 315                 $us, $snags_tripped;
 316         } else {
 317             fail sprintf
 318   "%s: snags: %d blocker(s) (you could -f<tag>, or --force)",
 319                 $us, $snags_tripped;
 320         }
 321     }
 322     $snags_summarised = $snags_forced + $snags_tripped;
 323 }
 324 sub snags_maybe_bail_early () {
 325     # useful to bail out early without doing a lot of work;
 326     # not a substitute for snags_maybe_bail.
 327     snags_maybe_bail() if $snags_tripped && !$opt_force;
 328 }
 329 sub any_snags () {
 330     return $snags_forced || $snags_tripped;
 331 }
 332
 333 sub gbp_pq_export ($$$) {
 334     my ($bname, $base, $tip) = @_;
 335     # must be run in a workarea.  $bname and patch-queue/$bname
 336     # ought not to exist.  Leaves you on patch-queue/$bname with
 337     # the patches staged but not committed.
 338     printdebug "gbp_pq_export $bname $base $tip\n";
 339     runcmd @git, qw(checkout -q -b), $bname, $base;
 340     runcmd @git, qw(checkout -q -b), "patch-queue/$bname", $tip;
 341     my @gbp_cmd = (qw(gbp pq export));
 342     my $r = system shell_cmd 'exec >../gbp-pq-err 2>&1', @gbp_cmd;
 343     if ($r) {
 344         { local ($!,$?); copy('../gbp-pq-err', \*STDERR); }
 345         failedcmd @gbp_cmd;
 346     }
 347     runcmd @git, qw(add -f debian/patches);
 348 }
 349
 350
 351 # xxx allow merge resolution separately from laundering, before git merge
 352 #
 353 # xxx general gdr docs highlight forbidden things
 354 # xxx general gdr docs list allowable things ?
 355 # xxx general gdr docs explicitly forbid some rebase
 356 #
 357 # xxx provide a way for the user to help
 358 # xxx (eg, provide wreckage provide way to continue)
 359
 360 # later/rework?
 361 #  use git-format-patch?
 362 #  our own patch identification algorithm?
 363 #  this is an alternative strategy
 364
 365 sub merge_series ($$;@) {
 366     my ($newbase, $base_q, @input_qs) = @_;
 367     # $base_q{SeriesBase}  $input_qs[]{SeriesBase}
 368     # $base_q{SeriesTip}   $input_qs[]{SeriesTip}
 369     # ^ specifies several patch series (currently we only support exactly 2)
 370     # return value is a commit which is the result of
 371     # merging the two versions of the same topic branch
 372     #   $input_q[0] and $input_q[1]
 373     # with respect to the old version
 374     #   $base_q
 375     # all onto $newbase.
 376
 377     # Creates, in *_q, a key MR for its private use
 378
 379     printdebug "merge_series newbase=$newbase\n";
 380
 381     $input_qs[$_]{MR}{S} = $_ foreach (0..$#input_qs);
 382     $base_q->{MR}{S} = 'base';
 383
 384     my %prereq;
 385     # $prereq{<patch filename>}{<possible prereq}{<S>} = 1 or absent
 386     # $prereq{<patch filename>}{<possible prereq}  exists or not (later)
 387     # $prereq{<patch filename>}               exists or not (even later)
 388
 389     my $result;
 390
 391     local $workarea = fresh_playground "$playprefix/merge";
 392     my $seriesfile = "debian/patches/series";
 393     in_workarea sub {
 394         playtree_setup();
 395         foreach my $q ($base_q, reverse @input_qs) {
 396             my $s = $q->{MR}{S};
 397             gbp_pq_export "p-$s", $q->{SeriesBase}, $q->{SeriesTip};
 398             my @earlier;
 399             if (open S, $seriesfile) {
 400                 while (my $patch = <S>) {
 401                     chomp $patch or die $!;
 402                     $prereq{$patch} //= {};
 403                     foreach my $earlier (@earlier) {
 404                         $prereq{$patch}{$earlier}{$s}++ and die;
 405                     }
 406                     push @earlier, $patch;
 407                     stat "debian/patches/$patch" or die "$patch ?";
 408                 }
 409                 S->error and die "$seriesfile $!";
 410                 close S;
 411             } else {
 412                 die "$seriesfile $!" unless $!==ENOENT;
 413             }
 414             read_tree_upstream $newbase, 1;
 415             my $pec = make_commit [ grep { defined } $base_q->{MR}{PEC} ], [
 416                 "Convert $s to patch queue for merging",
 417                 "[git-debrebase merge-innards patch-queue import:".
 418                 " $q->{SeriesTip}]"
 419             ];
 420             printdebug "merge_series  pec $pec ";
 421             runcmd @git, qw(rm -q --cached), $seriesfile;
 422             $pec = make_commit [ $pec ], [
 423                 "Drop series file from $s to avoid merge trouble",
 424                 "[git-debrebase merge-innards patch-queue prep:".
 425                 " $q->{SeriesTip}]"
 426             ];
 427
 428             read_tree_debian $newbase;
 429             if (@earlier) {
 430                 read_tree_subdir 'debian/patches', "$pec:debian/patches";
 431             } else {
 432                 rm_subdir_cached 'debian/patches';
 433             }
 434             $pec = make_commit [ $pec ], [
 435  "Update debian/ (excluding patches) to final to avoid re-merging",
 436  "debian/ was already merged and we need to just take that.",
 437                 "[git-debrebase merge-innards patch-queue packaging:".
 438                 " $q->{SeriesTip}]"
 439             ];
 440
 441             printdebug "pec' $pec\n";
 442             runcmd @git, qw(reset -q --hard), $pec;
 443             $q->{MR}{PEC} = $pec;
 444         }
 445         # now, because of reverse, we are on $input_q->{MR}{OQC}
 446         runcmd @git, qw(checkout -q -b merge);
 447         printdebug "merge_series merging...\n";
 448         my @mergecmd = (@git, qw(merge --quiet --no-edit), "p-1");
 449         debugcmd '+', @mergecmd;
 450         $!=0; $?=-1;
 451         if (system @mergecmd) {
 452             failedcmd @mergecmd;
 453         }
 454
 455         printdebug "merge_series merge ok, series...\n";
 456         # We need to construct a new series file
 457         # Firstly, resolve prereq
 458         foreach my $f (sort keys %prereq) {
 459             printdebug "merge_series  patch\t$f\t";
 460             if (!stat_exists "debian/patches/$f") {
 461                 print DEBUG " drop\n" if $debuglevel;
 462                 # git merge deleted it; that's how we tell it's not wanted
 463                 delete $prereq{$f};
 464                 next;
 465             }
 466             print DEBUG " keep\n" if $debuglevel;
 467             foreach my $g (sort keys %{ $prereq{$f} }) {
 468                 my $gfp = $prereq{$f}{$g};
 469                 printdebug "merge_series  prereq\t$f\t-> $g\t";
 470                 if (!!$gfp->{0} == !!$gfp->{1}
 471                     ? $gfp->{0}
 472                     : !$gfp->{base}) {
 473                     print DEBUG "\tkeep\n" if $debuglevel;
 474                 } else {
 475                     print DEBUG "\tdrop\n" if $debuglevel;
 476                     delete $prereq{$f}{$g};
 477                 }
 478             }
 479         }
 480
 481         my $unsat = sub {
 482             my ($f) = @_;
 483             return scalar keys %{ $prereq{$f} };
 484         };
 485
 486         my $nodate = time + 1;
 487         my %authordate;
 488         # $authordate{<patch filename>};
 489         my $authordate = sub {
 490             my ($f) = @_;
 491             $authordate{$f} //= do {
 492                 open PF, "<", "debian/patches/$f" or die "$f $!";
 493                 while (<PF>) {
 494                     return $nodate if m/^$/;
 495                     last if s{^Date: }{};
 496                 }
 497                 chomp;
 498                 return cmdoutput qw(date +%s -d), $_;
 499             };
 500         };
 501
 502         open NS, '>', $seriesfile or die $!;
 503
 504         while (keys %prereq) {
 505             my $best;
 506             foreach my $try (sort keys %prereq) {
 507                 if ($best) {
 508                     next if (
 509                              $unsat->($try) <=> $unsat->($best) or
 510                              $authordate->($try) <=> $authordate->($best) or
 511                              $try cmp $best
 512                             ) >= 0;
 513                 }
 514                 $best = $try;
 515             }
 516             printdebug "merge_series series next $best\n";
 517             print NS "$best\n" or die $!;
 518             delete $prereq{$best};
 519             foreach my $gp (values %prereq) {
 520                 delete $gp->{$best};
 521             }
 522         }
 523
 524         runcmd @git, qw(add), $seriesfile;
 525         runcmd @git, qw(commit --quiet -m), 'Merged series';
 526
 527         printdebug "merge_series series gbp pq import\n";
 528         runcmd qw(gbp pq import);
 529
 530         # OK now we are on patch-queue/merge, and we need to rebase
 531         # onto the intended parent and drop the patches from each one
 532
 533         printdebug "merge_series series ok, building...\n";
 534         my $build = $newbase;
 535         my @lcmd = (@git, qw(rev-list --reverse merge..patch-queue/merge));
 536         foreach my $c (grep /./, split /\n/, cmdoutput @lcmd) {
 537             my $commit = git_cat_file $c, 'commit';
 538             printdebug "merge_series series ok, building $c\n";
 539             read_tree_upstream $c, 0, $newbase;
 540             my $tree = cmdoutput @git, qw(write-tree);
 541             $commit =~ s{^parent (\S+)$}{parent $build}m or confess;
 542             $commit =~ s{^tree (\S+)$}{tree $tree}m      or confess;
 543             open C, ">", "../mcommit" or die $!;
 544             print C $commit or die $!;
 545             close C or die $!;
 546             $build = cmdoutput @git, qw(hash-object -w -t commit ../mcommit);
 547         }
 548         $result = $build;
 549         runcmd @git, qw(update-ref refs/heads/result), $result;
 550
 551         runcmd @git, qw(checkout -q -b debug);
 552         runcmd @git, qw(commit --allow-empty -q -m M-INDEX);
 553         runcmd @git, qw(add .);
 554         runcmd @git, qw(commit --allow-empty -q -m M-WORKTREE);
 555         printdebug sprintf "merge_series done debug=%s\n",
 556             git_rev_parse 'HEAD';
 557     };
 558     printdebug "merge_series returns $result\n";
 559     return $result;
 560 }
 561
 562 # classify returns an info hash like this
 563 #   CommitId => $objid
 564 #   Hdr => # commit headers, including 1 final newline
 565 #   Msg => # commit message (so one newline is dropped)
 566 #   Tree => $treeobjid
 567 #   Type => (see below)
 568 #   Parents = [ {
 569 #       Ix => $index # ie 0, 1, 2, ...
 570 #       CommitId
 571 #       Differs => return value from get_differs
 572 #       IsOrigin
 573 #       IsDggitImport => 'orig' 'tarball' 'unpatched' 'package' (as from dgit)
 574 #     } ...]
 575 #   NewMsg => # commit message, but with any [dgit import ...] edited
 576 #             # to say "[was: ...]"
 577 #
 578 # Types:
 579 #   Packaging
 580 #   Changelog
 581 #   Upstream
 582 #   AddPatches
 583 #   Mixed
 584 #
 585 #   Pseudomerge
 586 #     has additional entres in classification result
 587 #       Overwritten = [ subset of Parents ]
 588 #       Contributor = $the_remaining_Parent
 589 #
 590 #   DgitImportUnpatched
 591 #     has additional entry in classification result
 592 #       OrigParents = [ subset of Parents ]
 593 #
 594 #   Anchor
 595 #     has additional entry in classification result
 596 #       OrigParents = [ subset of Parents ]  # singleton list
 597 #
 598 #   TreatAsAnchor
 599 #
 600 #   BreakwaterStart
 601 #
 602 #   Unknown
 603 #     has additional entry in classification result
 604 #       Why => "prose"
 605
 606 sub parsecommit ($;$) {
 607     my ($objid, $p_ref) = @_;
 608     # => hash with                   CommitId Hdr Msg Tree Parents
 609     #    Parents entries have only   Ix CommitId
 610     #    $p_ref, if provided, must be [] and is used as a base for Parents
 611
 612     $p_ref //= [];
 613     die if @$p_ref;
 614
 615     my ($h,$m) = get_commit $objid;
 616
 617     my ($t) = $h =~ m/^tree (\w+)$/m or die $objid;
 618     my (@ph) = $h =~ m/^parent (\w+)$/mg;
 619
 620     my $r = {
 621         CommitId => $objid,
 622         Hdr => $h,
 623         Msg => $m,
 624         Tree => $t,
 625         Parents => $p_ref,
 626     };
 627
 628     foreach my $ph (@ph) {
 629         push @$p_ref, {
 630             Ix => scalar @$p_ref,
 631             CommitId => $ph,
 632         };
 633     }
 634
 635     return $r;
 636 }
 637
 638 sub classify ($) {
 639     my ($objid) = @_;
 640
 641     my @p;
 642     my $r = parsecommit($objid, \@p);
 643     my $t = $r->{Tree};
 644
 645     foreach my $p (@p) {
 646         $p->{Differs} = (get_differs $p->{CommitId}, $t),
 647     }
 648
 649     printdebug "classify $objid \$t=$t \@p",
 650         (map { sprintf " %s/%#x", $_->{CommitId}, $_->{Differs} } @p),
 651         "\n";
 652
 653     my $classify = sub {
 654         my ($type, @rest) = @_;
 655         $r = { %$r, Type => $type, @rest };
 656         if ($debuglevel) {
 657             printdebug " = $type ".(dd $r)."\n";
 658         }
 659         return $r;
 660     };
 661     my $unknown = sub {
 662         my ($why) = @_;
 663         $r = { %$r, Type => qw(Unknown), Why => $why };
 664         printdebug " ** Unknown\n";
 665         return $r;
 666     };
 667
 668     if (grep { $_ eq $objid } @opt_anchors) {
 669         return $classify->('TreatAsAnchor');
 670     }
 671
 672     my @identical = grep { !$_->{Differs} } @p;
 673     my ($stype, $series) = git_cat_file "$t:debian/patches/series";
 674     my $haspatches = $stype ne 'missing' && $series =~ m/^\s*[^#\n\t ]/m;
 675
 676     if ($r->{Msg} =~ m{^\[git-debrebase anchor.*\]$}m) {
 677         # multi-orig upstreams are represented with an anchor merge
 678         # from a single upstream commit which combines the orig tarballs
 679
 680         # Every anchor tagged this way must be a merge.
 681         # We are relying on the
 682         #     [git-debrebase anchor: ...]
 683         # commit message annotation in "declare" anchor merges (which
 684         # do not have any upstream changes), to distinguish those
 685         # anchor merges from ordinary pseudomerges (which we might
 686         # just try to strip).
 687         #
 688         # However, the user is going to be doing git-rebase a lot.  We
 689         # really don't want them to rewrite an anchor commit.
 690         # git-rebase trips up on merges, so that is a useful safety
 691         # catch.
 692         #
 693         # BreakwaterStart commits are also anchors in the terminology
 694         # of git-debrebase(5), but they are untagged (and always
 695         # manually generated).
 696         #
 697         # We cannot not tolerate any tagged linear commit (ie,
 698         # BreakwaterStart commits tagged `[anchor:') because such a
 699         # thing could result from an erroneous linearising raw git
 700         # rebase of a merge anchor.  That would represent a corruption
 701         # of the branch. and we want to detect and reject the results
 702         # of such corruption before it makes it out anywhere.  If we
 703         # reject it here then we avoid making the pseudomerge which
 704         # would be needed to push it.
 705
 706         my $badanchor = sub { $unknown->("git-debrebase \`anchor' but @_"); };
 707         @p == 2 or return $badanchor->("has other than two parents");
 708         $haspatches and return $badanchor->("contains debian/patches");
 709
 710         # How to decide about l/r ordering of anchors ?  git
 711         # --topo-order prefers to expand 2nd parent first.  There's
 712         # already an easy rune to look for debian/ history anyway (git log
 713         # debian/) so debian breakwater branch should be 1st parent; that
 714         # way also there's also an easy rune to look for the upstream
 715         # patches (--topo-order).
 716
 717         # Also this makes --first-parent be slightly more likely to
 718         # be useful - it makes it provide a linearised breakwater history.
 719
 720         # Of course one can say somthing like
 721         #  gitk -- ':/' ':!/debian'
 722         # to get _just_ the commits touching upstream files, and by
 723         # the TREESAME logic in git-rev-list this will leave the
 724         # breakwater into upstream at the first anchor.  But that
 725         # doesn't report debian/ changes at all.
 726
 727         # Other observations about gitk: by default, gitk seems to
 728         # produce output in a different order to git-rev-list.  I
 729         # can't seem to find this documented anywhere.  gitk
 730         # --date-order DTRT.  But, gitk always seems to put the
 731         # parents from left to right, in order, so it's easy to see
 732         # which way round a pseudomerge is.
 733
 734         $p[0]{IsOrigin} and $badanchor->("is an origin commit");
 735         $p[1]{Differs} & ~DS_DEB and
 736             $badanchor->("upstream files differ from left parent");
 737         $p[0]{Differs} & ~D_UPS and
 738             $badanchor->("debian/ differs from right parent");
 739
 740         return $classify->(qw(Anchor),
 741                            OrigParents => [ $p[1] ]);
 742     }
 743
 744     if (@p == 1) {
 745         my $d = $r->{Parents}[0]{Differs};
 746         if ($d == D_PAT_ADD) {
 747             return $classify->(qw(AddPatches));
 748         } elsif ($d & (D_PAT_ADD|D_PAT_OTH)) {
 749             return $unknown->("edits debian/patches");
 750         } elsif ($d & DS_DEB and !($d & ~DS_DEB)) {
 751             my ($ty,$dummy) = git_cat_file "$p[0]{CommitId}:debian";
 752             if ($ty eq 'tree') {
 753                 if ($d == D_DEB_CLOG) {
 754                     return $classify->(qw(Changelog));
 755                 } else {
 756                     return $classify->(qw(Packaging));
 757                 }
 758             } elsif ($ty eq 'missing') {
 759                 return $classify->(qw(BreakwaterStart));
 760             } else {
 761                 return $unknown->("parent's debian is not a directory");
 762             }
 763         } elsif ($d == D_UPS) {
 764             return $classify->(qw(Upstream));
 765         } elsif ($d & DS_DEB and $d & D_UPS and !($d & ~(DS_DEB|D_UPS))) {
 766             return $classify->(qw(Mixed));
 767         } elsif ($d == 0) {
 768             return $unknown->("no changes");
 769         } else {
 770             confess "internal error $objid ?";
 771         }
 772     }
 773     if (!@p) {
 774         return $unknown->("origin commit");
 775     }
 776
 777     if (@p == 2 && @identical == 1) {
 778         my @overwritten = grep { $_->{Differs} } @p;
 779         confess "internal error $objid ?" unless @overwritten==1;
 780         return $classify->(qw(Pseudomerge),
 781                            Overwritten => [ $overwritten[0] ],
 782                            Contributor => $identical[0]);
 783     }
 784     if (@p == 2 && @identical == 2) {
 785         my $get_t = sub {
 786             my ($ph,$pm) = get_commit $_[0]{CommitId};
 787             $ph =~ m/^committer .* (\d+) [-+]\d+$/m or die "$_->{CommitId} ?";
 788             $1;
 789         };
 790         my @bytime = @p;
 791         my $order = $get_t->($bytime[0]) <=> $get_t->($bytime[1]);
 792         if ($order > 0) { # newer first
 793         } elsif ($order < 0) {
 794             @bytime = reverse @bytime;
 795         } else {
 796             # same age, default to order made by -s ours
 797             # that is, commit was made by someone who preferred L
 798         }
 799         return $classify->(qw(Pseudomerge),
 800                            SubType => qw(Ambiguous),
 801                            Contributor => $bytime[0],
 802                            Overwritten => [ $bytime[1] ]);
 803     }
 804     foreach my $p (@p) {
 805         my ($p_h, $p_m) = get_commit $p->{CommitId};
 806         $p->{IsOrigin} = $p_h !~ m/^parent \w+$/m;
 807         ($p->{IsDgitImport},) = $p_m =~ m/^\[dgit import ([0-9a-z]+) .*\]$/m;
 808     }
 809     my @orig_ps = grep { ($_->{IsDgitImport}//'X') eq 'orig' } @p;
 810     my $m2 = $r->{Msg};
 811     if (!(grep { !$_->{IsOrigin} } @p) and
 812         (@orig_ps >= @p - 1) and
 813         $m2 =~ s{^\[(dgit import unpatched .*)\]$}{[was: $1]}m) {
 814         $r->{NewMsg} = $m2;
 815         return $classify->(qw(DgitImportUnpatched),
 816                            OrigParents => \@orig_ps);
 817     }
 818
 819     if (@p == 2 and
 820         $r->{Msg} =~ m{^\[git-debrebase merged-breakwater.*\]$}m) {
 821         # xxx ^ metadata tag needs adding to (5)
 822         return $classify->("MergedBreakwaters");
 823     }
 824     if ($r->{Msg} =~ m{^\[(git-debrebase|dgit)[: ].*\]$}m) {
 825         return $unknown->("unknown kind of merge from $1");
 826     }
 827     if (@p > 2) {
 828         return $unknown->("octopus merge");
 829     }
 830
 831     if (!$ENV{GIT_DEBREBASE_EXPERIMENTAL_MERGE}) {
 832         return $unknown->("general two-parent merge");
 833     }
 834
 835     return $classify->("VanillaMerge");
 836 }
 837
 838 sub keycommits ($;$$$$$);
 839
 840 sub mergedbreakwaters_anchor ($) {
 841     my ($cl) = @_;
 842     my $best_anchor;
 843     foreach my $p (@{ $cl->{Parents} }) {
 844         my ($panchor, $pbw) = keycommits $p->{CommitId},
 845             undef,undef,undef,undef, 1;
 846         $best_anchor = $panchor
 847             if !defined $best_anchor
 848             or is_fast_fwd $best_anchor, $panchor;
 849         fail "inconsistent anchors in merged-breakwaters $p->{CommitId}"
 850             unless is_fast_fwd $panchor, $best_anchor;
 851     }
 852     return $best_anchor;
 853 }
 854
 855 sub keycommits ($;$$$$$) {
 856     my ($head, $furniture, $unclean, $trouble, $fatal, $claimed_bw) = @_;
 857     # => ($anchor, $breakwater)
 858
 859     # $unclean->("unclean-$tagsfx", $msg, $cl)
 860     # $furniture->("unclean-$tagsfx", $msg, $cl)
 861     # $dgitimport->("unclean-$tagsfx", $msg, $cl))
 862     #   is callled for each situation or commit that
 863     #   wouldn't be found in a laundered branch
 864     # $furniture is for furniture commits such as might be found on an
 865     #   interchange branch (pseudomerge, d/patches, changelog)
 866     # $trouble is for things whnich prevent the return of
 867     #   anchor and breakwater information; if that is ignored,
 868     #   then keycommits returns (undef, undef) instead.
 869     # $fatal is for unprocessable commits, and should normally cause
 870     #    a failure.  If ignored, agaion, (undef, undef) is returned.
 871     #
 872     # If $claimed_bw, this is supposed to be a breakwater commit.
 873     #
 874     # If a callback is undef, fail is called instead.
 875     # If a callback is defined but false, the situation is ignored.
 876     # Callbacks may say:
 877     #   no warnings qw(exiting); last;
 878     # if the answer is no longer wanted.
 879
 880     my ($anchor, $breakwater);
 881     $breakwater = $head if $claimed_bw;
 882     my $clogonly;
 883     my $cl;
 884     my $found_pm;
 885     $fatal //= sub { fail $_[1]; };
 886     my $x = sub {
 887         my ($cb, $tagsfx, $mainwhy, $xwhy) = @_;
 888         my $why = $mainwhy.$xwhy;
 889         my $m = "branch needs laundering (run git-debrebase): $why";
 890         fail $m unless defined $cb;
 891         return unless $cb;
 892         $cb->("unclean-$tagsfx", $why, $cl, $mainwhy);
 893     };
 894     my $found_anchor = sub {
 895         ($anchor) = @_;
 896         $breakwater //= $clogonly;
 897         $breakwater //= $head;
 898         no warnings qw(exiting);
 899         last;
 900     };
 901     for (;;) {
 902         $cl = classify $head;
 903         my $ty = $cl->{Type};
 904         if ($ty eq 'Packaging') {
 905             $breakwater //= $clogonly;
 906             $breakwater //= $head;
 907         } elsif ($ty eq 'Changelog') {
 908             # this is going to count as the tip of the breakwater
 909             # only if it has no upstream stuff before it
 910             $clogonly //= $head;
 911         } elsif ($ty eq 'Anchor' or
 912                  $ty eq 'TreatAsAnchor' or
 913                  $ty eq 'BreakwaterStart') {
 914             $found_anchor->($head);
 915         } elsif ($ty eq 'Upstream') {
 916             $x->($unclean, 'ordering',
 917  "packaging change ($breakwater) follows upstream change"," (eg $head)")
 918                 if defined $breakwater;
 919             $clogonly = undef;
 920             $breakwater = undef;
 921         } elsif ($ty eq 'Mixed') {
 922             $x->($unclean, 'mixed',
 923                  "found mixed upstream/packaging commit"," ($head)");
 924             $clogonly = undef;
 925             $breakwater = undef;
 926         } elsif ($ty eq 'Pseudomerge' or
 927                  $ty eq 'AddPatches') {
 928             my $found_pm = 1;
 929             $x->($furniture, (lc $ty),
 930                  "found interchange bureaucracy commit ($ty)"," ($head)");
 931         } elsif ($ty eq 'DgitImportUnpatched') {
 932             if ($found_pm) {
 933                 $x->($trouble, 'dgitimport',
 934                      "found dgit dsc import"," ($head)");
 935                 return (undef,undef);
 936             } else {
 937                 $x->($fatal, 'unprocessable',
 938                      "found bare dgit dsc import with no prior history",
 939                      " ($head)");
 940                 return (undef,undef);
 941             }
 942         } elsif ($ty eq 'VanillaMerge') {
 943             $x->($trouble, 'vanillamerge',
 944                  "found vanilla merge"," ($head)");
 945             return (undef,undef);
 946         } elsif ($ty eq 'MergedBreakwaters') {
 947             $found_anchor->(mergedbreakwaters_anchor $cl);
 948         } else {
 949             $x->($fatal, 'unprocessable',
 950                  "found unprocessable commit, cannot cope: $cl->{Why}",
 951                  " ($head)");
 952             return (undef,undef);
 953         }
 954         $head = $cl->{Parents}[0]{CommitId};
 955     }
 956     return ($anchor, $breakwater);
 957 }
 958
 959 sub walk ($;$$$);
 960 sub walk ($;$$$) {
 961     my ($input,
 962         $nogenerate,$report, $report_lprefix) = @_;
 963     # => ($tip, $breakwater_tip, $last_anchor)
 964     # (or nothing, if $nogenerate)
 965
 966     printdebug "*** WALK $input ".($nogenerate//0)." ".($report//'-')."\n";
 967     $report_lprefix //= '';
 968
 969     # go through commits backwards
 970     # we generate two lists of commits to apply:
 971     # breakwater branch and upstream patches
 972     my (@brw_cl, @upp_cl, @processed);
 973     my %found;
 974     my $upp_limit;
 975     my @pseudomerges;
 976
 977     my $cl;
 978     my $xmsg = sub {
 979         my ($prose, $info) = @_;
 980         my $ms = $cl->{Msg};
 981         chomp $ms;
 982         $info //= '';
 983         $ms .= "\n\n[git-debrebase$info: $prose]\n";
 984         return (Msg => $ms);
 985     };
 986     my $rewrite_from_here = sub {
 987         my ($cl) = @_;
 988         my $sp_cl = { SpecialMethod => 'StartRewrite' };
 989         push @$cl, $sp_cl;
 990         push @processed, $sp_cl;
 991     };
 992     my $cur = $input;
 993
 994     my $prdelim = "";
 995     my $prprdelim = sub { print $report $prdelim if $report; $prdelim=""; };
 996
 997     my $prline = sub {
 998         return unless $report;
 999         print $report $prdelim, $report_lprefix, @_;
1000         $prdelim = "\n";
1001     };
1002
1003     my $bomb = sub { # usage: return $bomb->();
1004         print $report " Unprocessable" if $report;
1005         print $report " ($cl->{Why})" if $report && defined $cl->{Why};
1006         $prprdelim->();
1007         if ($nogenerate) {
1008             return (undef,undef);
1009         }
1010         fail "found unprocessable commit, cannot cope".
1011             (defined $cl->{Why} ? "; $cl->{Why}:": ':').
1012             " (commit $cur) (d.".
1013             (join ' ', map { sprintf "%#x", $_->{Differs} }
1014              @{ $cl->{Parents} }).
1015                  ")";
1016     };
1017
1018     my $build;
1019     my $breakwater;
1020
1021     my $build_start = sub {
1022         my ($msg, $parent) = @_;
1023         $prline->(" $msg");
1024         $build = $parent;
1025         no warnings qw(exiting); last;
1026     };
1027
1028     my $nomerge = sub {
1029         fail "something useful about failed merge attempt @_ xxx".Dumper($cl);
1030     };
1031
1032     my $last_anchor;
1033
1034     for (;;) {
1035         $cl = classify $cur;
1036         my $ty = $cl->{Type};
1037         my $st = $cl->{SubType};
1038         $prline->("$cl->{CommitId} $cl->{Type}");
1039         $found{$ty. ( defined($st) ? "-$st" : '' )}++;
1040         push @processed, $cl;
1041         my $p0 = @{ $cl->{Parents} }==1 ? $cl->{Parents}[0]{CommitId} : undef;
1042         if ($ty eq 'AddPatches') {
1043             $cur = $p0;
1044             $rewrite_from_here->(\@upp_cl);
1045             next;
1046         } elsif ($ty eq 'Packaging' or $ty eq 'Changelog') {
1047             push @brw_cl, $cl;
1048             $cur = $p0;
1049             next;
1050         } elsif ($ty eq 'BreakwaterStart') {
1051             $last_anchor = $cur;
1052             $build_start->('FirstPackaging', $cur);
1053         } elsif ($ty eq 'Upstream') {
1054             push @upp_cl, $cl;
1055             $cur = $p0;
1056             next;
1057         } elsif ($ty eq 'Mixed') {
1058             my $queue = sub {
1059                 my ($q, $wh) = @_;
1060                 my $cls = { %$cl, $xmsg->("split mixed commit: $wh part") };
1061                 push @$q, $cls;
1062             };
1063             $queue->(\@brw_cl, "debian");
1064             $queue->(\@upp_cl, "upstream");
1065             $rewrite_from_here->(\@brw_cl);
1066             $cur = $p0;
1067             next;
1068         } elsif ($ty eq 'Pseudomerge') {
1069             my $contrib = $cl->{Contributor}{CommitId};
1070             print $report " Contributor=$contrib" if $report;
1071             push @pseudomerges, $cl;
1072             $rewrite_from_here->(\@upp_cl);
1073             $cur = $contrib;
1074             next;
1075         } elsif ($ty eq 'Anchor' or $ty eq 'TreatAsAnchor') {
1076             $last_anchor = $cur;
1077             $build_start->("Anchor", $cur);
1078         } elsif ($ty eq 'DgitImportUnpatched') {
1079             my $pm = $pseudomerges[-1];
1080             if (defined $pm) {
1081                 # To an extent, this is heuristic.  Imports don't have
1082                 # a useful history of the debian/ branch.  We assume
1083                 # that the first pseudomerge after an import has a
1084                 # useful history of debian/, and ignore the histories
1085                 # from later pseudomerges.  Often the first pseudomerge
1086                 # will be the dgit import of the upload to the actual
1087                 # suite intended by the non-dgit NMUer, and later
1088                 # pseudomerges may represent in-archive copies.
1089                 my $ovwrs = $pm->{Overwritten};
1090                 printf $report " PM=%s \@Overwr:%d",
1091                     $pm->{CommitId}, (scalar @$ovwrs)
1092                     if $report;
1093                 if (@$ovwrs != 1) {
1094                     printdebug "*** WALK BOMB DgitImportUnpatched\n";
1095                     return $bomb->();
1096                 }
1097                 my $ovwr = $ovwrs->[0]{CommitId};
1098                 printf $report " Overwr=%s", $ovwr if $report;
1099                 # This import has a tree which is just like a
1100                 # breakwater tree, but it has the wrong history.  It
1101                 # ought to have the previous breakwater (which the
1102                 # pseudomerge overwrote) as an ancestor.  That will
1103                 # make the history of the debian/ files correct.  As
1104                 # for the upstream version: either it's the same as
1105                 # was ovewritten (ie, same as the previous
1106                 # breakwater), in which case that history is precisely
1107                 # right; or, otherwise, it was a non-gitish upload of a
1108                 # new upstream version.  We can tell these apart by
1109                 # looking at the tree of the supposed upstream.
1110                 push @brw_cl, {
1111                     %$cl,
1112                     SpecialMethod => 'DgitImportDebianUpdate',
1113                     $xmsg->("convert dgit import: debian changes")
1114                 }, {
1115                     %$cl,
1116                     SpecialMethod => 'DgitImportUpstreamUpdate',
1117                     $xmsg->("convert dgit import: upstream update",
1118                             " anchor")
1119                 };
1120                 $prline->(" Import");
1121                 $rewrite_from_here->(\@brw_cl);
1122                 $upp_limit //= $#upp_cl; # further, deeper, patches discarded
1123                 $cur = $ovwr;
1124                 next;
1125             } else {
1126                 # Everything is from this import.  This kind of import
1127                 # is already nearly in valid breakwater format, with the
1128                 # patches as commits.  Unfortunately it contains
1129                 # debian/patches/.
1130                 printdebug "*** WALK BOMB bare dgit import\n";
1131                 $cl->{Why} = "bare dgit dsc import";
1132                 return $bomb->();
1133             }
1134             die "$ty ?";
1135         } elsif ($ty eq 'MergedBreakwaters') {
1136             $last_anchor = mergedbreakwaters_anchor $cl;
1137             $build_start->(' MergedBreakwaters', $cur);
1138             last;
1139         } elsif ($ty eq 'VanillaMerge') {
1140             # User may have merged unstitched branch(es).  We will
1141             # have now lost what ffq-prev was then (since the later
1142             # pseudomerge may introduce further changes).  The effect
1143             # of resolving such a merge is that we may have to go back
1144             # further in history to find a merge base, since the one
1145             # which was reachable via ffq-prev is no longer findable.
1146             # This is suboptimal, but if it all works we'll have done
1147             # the right thing.
1148             # xxx we should warn the user in the docs about this
1149
1150             my $ok=1;
1151             my $best_anchor;
1152             # We expect to find a dominating anchor amongst the
1153             # inputs' anchors.  That will be the new anchor.
1154             #
1155             # More complicated is finding a merge base for the
1156             # breakwaters.  We need a merge base that is a breakwater
1157             # commit.  The ancestors of breakwater commits are more
1158             # breakwater commits and possibly upstream commits and the
1159             # ancestors of those upstream.  Upstreams might have
1160             # arbitrary ancestors.  But any upstream commit U is
1161             # either included in both anchors, in which case the
1162             # earlier anchor is a better merge base than any of U's
1163             # ancestors; or U is not included in the older anchor, in
1164             # which case U is not an ancestor of the vanilla merge at
1165             # all.  So no upstream commit, nor any ancestor thereof,
1166             # is a best merge base.  As for non-breakwater Debian
1167             # commits: these are never ancestors of any breakwater.
1168             #
1169             # So any best merge base as found by git-merge-base
1170             # is a suitable breakwater anchor.  Usually there will
1171             # be only one.
1172
1173             printdebug "*** MERGE\n";
1174
1175             my @bwbcmd = (@git, qw(merge-base));
1176             my @ibcmd = (@git, qw(merge-base --all));
1177             my $might_be_in_bw = 1;
1178
1179             my $ps = $cl->{Parents};
1180
1181             foreach my $p (@$ps) {
1182                 $prline->(" VanillaMerge ".$p->{Ix});
1183                 $prprdelim->();
1184                 my ($ptip, $pbw, $panchor) =
1185                     walk $p->{CommitId}, 0, $report,
1186                          $report_lprefix.'  ';
1187                 $p->{Laundered} = $p->{SeriesTip} = $ptip;
1188                 $p->{Breakwater} = $p->{SeriesBase} = $pbw;
1189                 $p->{Anchor} = $panchor;
1190
1191                 $best_anchor = $panchor if
1192                     !defined $best_anchor or
1193                     is_fast_fwd $best_anchor, $panchor;
1194
1195                 printdebug " MERGE BA best=".($best_anchor//'-').
1196                     " p=$panchor\n";
1197             }
1198
1199             foreach my $p (@$ps) {
1200                 $prline->(" VanillaMerge ".$p->{Ix});
1201                 if (!is_fast_fwd $p->{Anchor}, $best_anchor) {
1202                     $nomerge->('DivergentAnchor');
1203                 } elsif ($p->{Anchor} eq $best_anchor) {
1204                     print $report " SameAnchor" if $report;
1205                 } else {
1206                     print $report " SupersededAnchor" if $report;
1207                 }
1208                 if ($p->{Breakwater} eq $p->{CommitId}) {
1209                     # this parent commit was its own breakwater,
1210                     # ie it is part of the breakwater
1211                     print $report " Breakwater" if $report;
1212                 } else {
1213                     $might_be_in_bw = 0;
1214                 }
1215                 push @bwbcmd, $p->{Breakwater};
1216                 push @ibcmd, $p->{CommitId};
1217             }
1218
1219             if ($ok && $might_be_in_bw) {
1220                 # We could rewrite this to contaion the metadata
1221                 # declaring it to be MergedBreakwaters, but
1222                 # unnecessarily rewriting a merge seems unhelpful.
1223                 $prline->(" VanillaMerge MergedBreakwaters");
1224                 $last_anchor = $best_anchor;
1225                 $build_start->('MergedBreakwaters', $cur);
1226             }
1227
1228             my $bwb = cmdoutput @bwbcmd;
1229
1230             # OK, now we have a breakwater base, but we need the merge
1231             # base for the interchange branch because we need the delta
1232             # queue.
1233             #
1234             # This a the best merge base of our inputs which has the
1235             # breakwater merge base as an ancestor.
1236
1237             my @ibs =
1238                 grep { is_fast_fwd $bwb, $_ }
1239                 grep /./,
1240                 split /\n/,
1241                 cmdoutput @ibcmd;
1242             my ($ib) = @ibs
1243                 or $nomerge->("no suitable interchange merge base");
1244
1245             $prline->("  VanillaMerge Base");
1246             $prprdelim->();
1247             my ($btip, $bbw, $banchor) =
1248                 walk $ib, 0, $report, $report_lprefix.'  ';
1249
1250             my $ibinfo = { SeriesTip => $btip,
1251                            SeriesBase => $bbw,
1252                            Anchor => $banchor };
1253             $bbw eq $bwb
1254                 or $nomerge->("interchange merge-base ($ib)'s".
1255                               " breakwater ($bbw)".
1256                               " != breakwaters' merge-base ($bwb)");
1257             grep { $_->{Anchor} eq $ibinfo->{Anchor} } @$ps
1258                  or $nomerge->("interchange merge-base ($ib)'s".
1259                                " anchor ($ibinfo->{SeriesBase})".
1260                                " != any merge input's anchor (".
1261                                (join ' ', map { $_->{Anchor} } @$ps).
1262                                ")");
1263
1264
1265             $cl->{MergeInterchangeBaseInfo} = $ibinfo;
1266             $cl->{MergeBestAnchor} = $best_anchor;
1267             push @brw_cl, {
1268                 %$cl,
1269                 SpecialMethod => 'MergeCreateMergedBreakwaters',
1270                 $xmsg->('constructed from vanilla merge',
1271                         ' merged-breakwater'),
1272             };
1273             push @upp_cl, {
1274                 %$cl,
1275                 SpecialMethod => 'MergeMergeSeries',
1276             };
1277             $build_start->('MergeBreakwaters', $cur);
1278         } else {
1279             printdebug "*** WALK BOMB unrecognised\n";
1280             return $bomb->();
1281         }
1282     }
1283     $prprdelim->();
1284
1285     printdebug "*** WALK prep done cur=$cur".
1286         " brw $#brw_cl upp $#upp_cl proc $#processed pm $#pseudomerges\n";
1287
1288     return if $nogenerate;
1289
1290     # Now we build it back up again
1291
1292     fresh_workarea();
1293
1294     my $rewriting = 0;
1295
1296     my $read_tree_upstream = sub {
1297         my ($treeish) = @_;
1298         read_tree_upstream $treeish, 0, $build;
1299     };
1300
1301     $#upp_cl = $upp_limit if defined $upp_limit;
1302
1303     my $committer_authline = calculate_committer_authline();
1304
1305     printdebug "WALK REBUILD $build ".(scalar @processed)."\n";
1306
1307     confess "internal error" unless $build eq (pop @processed)->{CommitId};
1308
1309     in_workarea sub {
1310         mkdir $rd or $!==EEXIST or die $!;
1311         my $current_method;
1312         runcmd @git, qw(read-tree), $build;
1313         foreach my $cl (qw(Debian), (reverse @brw_cl),
1314                         { SpecialMethod => 'RecordBreakwaterTip' },
1315                         qw(Upstream), (reverse @upp_cl)) {
1316             if (!ref $cl) {
1317                 $current_method = $cl;
1318                 next;
1319             }
1320             my $method = $cl->{SpecialMethod} // $current_method;
1321             my @parents = ($build);
1322             my $cltree = $cl->{CommitId};
1323             printdebug "WALK BUILD ".($cltree//'undef').
1324                 " $method (rewriting=$rewriting)\n";
1325             if ($method eq 'Debian') {
1326                 read_tree_debian($cltree);
1327             } elsif ($method eq 'Upstream') {
1328                 $read_tree_upstream->($cltree);
1329             } elsif ($method eq 'StartRewrite') {
1330                 $rewriting = 1;
1331                 next;
1332             } elsif ($method eq 'RecordBreakwaterTip') {
1333                 $breakwater = $build;
1334                 next;
1335             } elsif ($method eq 'DgitImportDebianUpdate') {
1336                 read_tree_debian($cltree);
1337             } elsif ($method eq 'DgitImportUpstreamUpdate') {
1338                 confess unless $rewriting;
1339                 my $differs = (get_differs $build, $cltree);
1340                 next unless $differs & D_UPS;
1341                 $read_tree_upstream->($cltree);
1342                 push @parents, map { $_->{CommitId} } @{ $cl->{OrigParents} };
1343             } elsif ($method eq 'MergeCreateMergedBreakwaters') {
1344                 print "Found a general merge, will try to tidy it up.\n";
1345                 $rewriting = 1;
1346                 $read_tree_upstream->($cl->{MergeBestAnchor});
1347                 $read_tree_upstream->($cl->{MergeBestAnchor});
1348                 read_tree_debian($cltree);
1349                 @parents = map { $_->{Breakwater} } @{ $cl->{Parents} };
1350             } elsif ($method eq 'MergeMergeSeries') {
1351                 print "Running merge resolution for $cl->{CommitId}...\n";
1352                 $build = merge_series
1353                     $build,
1354                     $cl->{MergeInterchangeBaseInfo},
1355                     @{ $cl->{Parents} };
1356                 $last_anchor = $cl->{MergeBestAnchor};
1357
1358                 # Check for mismerges:
1359                 my $check = sub {
1360                     my ($against, $allow, $what) = @_;
1361                     my $differs = get_differs $build, $against;
1362                     $nomerge->(sprintf
1363        "merge misresolved: %s are not the same (%s %s d.%#x)",
1364                                $what, $against, $build, $differs)
1365                         if $differs & ~($allow | D_PAT_ADD);
1366                 };
1367
1368                 # Breakwater changes which were in each side of the
1369                 # merge will have been incorporated into the
1370                 # MergeCreateMergedBreakwaters output.  Because the
1371                 # upstream series was rebased onto the new breakwater,
1372                 # so should all of the packaging changes which were in
1373                 # the input.
1374                 $check->($input, D_UPS, 'debian files');
1375
1376                 # Upstream files are merge_series, which ought to
1377                 # have been identical to the original merge.
1378                 $check->($cl->{CommitId}, DS_DEB, 'upstream files');
1379
1380                 print "Merge resolution successful.\n";
1381                 next;
1382             } else {
1383                 confess "$method ?";
1384             }
1385             if (!$rewriting) {
1386                 my $procd = (pop @processed) // 'UNDEF';
1387                 if ($cl ne $procd) {
1388                     $rewriting = 1;
1389                     printdebug "WALK REWRITING NOW cl=$cl procd=$procd\n";
1390                 }
1391             }
1392             my $newtree = cmdoutput @git, qw(write-tree);
1393             my $ch = $cl->{Hdr};
1394             $ch =~ s{^tree .*}{tree $newtree}m or confess "$ch ?";
1395             $ch =~ s{^parent .*\n}{}mg;
1396             $ch =~ s{(?=^author)}{
1397                 join '', map { "parent $_\n" } @parents
1398             }me or confess "$ch ?";
1399             if ($rewriting) {
1400                 $ch =~ s{^committer .*$}{$committer_authline}m
1401                     or confess "$ch ?";
1402             }
1403             my $cf = "$rd/m$rewriting";
1404             open CD, ">", $cf or die $!;
1405             print CD $ch, "\n", $cl->{Msg} or die $!;
1406             close CD or die $!;
1407             my @cmd = (@git, qw(hash-object));
1408             push @cmd, qw(-w) if $rewriting;
1409             push @cmd, qw(-t commit), $cf;
1410             my $newcommit = cmdoutput @cmd;
1411             confess "$ch ?" unless $rewriting or $newcommit eq $cl->{CommitId};
1412             $build = $newcommit;
1413             if (grep { $method eq $_ } qw(DgitImportUpstreamUpdate)) {
1414                 $last_anchor = $cur;
1415             }
1416         }
1417     };
1418
1419     my $final_check = get_differs $build, $input;
1420     die sprintf "internal error %#x %s %s", $final_check, $input, $build
1421         if $final_check & ~D_PAT_ADD;
1422
1423     my @r = ($build, $breakwater, $last_anchor);
1424     printdebug "*** WALK RETURN @r\n";
1425     return @r
1426 }
1427
1428 sub get_head () {
1429     git_check_unmodified();
1430     return git_rev_parse qw(HEAD);
1431 }
1432
1433 sub update_head ($$$) {
1434     my ($old, $new, $mrest) = @_;
1435     push @deferred_updates, "update HEAD $new $old";
1436     run_deferred_updates $mrest;
1437 }
1438
1439 sub update_head_checkout ($$$) {
1440     my ($old, $new, $mrest) = @_;
1441     update_head $old, $new, $mrest;
1442     runcmd @git, qw(reset --hard);
1443 }
1444
1445 sub update_head_postlaunder ($$$) {
1446     my ($old, $tip, $reflogmsg) = @_;
1447     return if $tip eq $old;
1448     print "git-debrebase: laundered (head was $old)\n";
1449     update_head $old, $tip, $reflogmsg;
1450     # no tree changes except debian/patches
1451     runcmd @git, qw(rm --quiet --ignore-unmatch -rf debian/patches);
1452 }
1453
1454 sub currently_rebasing() {
1455     foreach (qw(rebase-merge rebase-apply)) {
1456         return 1 if stat_exists "$maindir_gitdir/$_";
1457     }
1458     return 0;
1459 }
1460
1461 sub bail_if_rebasing() {
1462     fail "you are in the middle of a git-rebase already"
1463         if currently_rebasing();
1464 }
1465
1466 sub do_launder_head ($) {
1467     my ($reflogmsg) = @_;
1468     my $old = get_head();
1469     record_ffq_auto();
1470     my ($tip,$breakwater) = walk $old;
1471     snags_maybe_bail();
1472     update_head_postlaunder $old, $tip, $reflogmsg;
1473     return ($tip,$breakwater);
1474 }
1475
1476 sub cmd_launder_v0 () {
1477     badusage "no arguments to launder-v0 allowed" if @ARGV;
1478     my $old = get_head();
1479     my ($tip,$breakwater,$last_anchor) = walk $old;
1480     update_head_postlaunder $old, $tip, 'launder';
1481     printf "# breakwater tip\n%s\n", $breakwater;
1482     printf "# working tip\n%s\n", $tip;
1483     printf "# last anchor\n%s\n", $last_anchor;
1484 }
1485
1486 sub defaultcmd_rebase () {
1487     push @ARGV, @{ $opt_defaultcmd_interactive // [] };
1488     my ($tip,$breakwater) = do_launder_head 'launder for rebase';
1489     runcmd @git, qw(rebase), @ARGV, $breakwater if @ARGV;
1490 }
1491
1492 sub cmd_analyse () {
1493     badusage "analyse does not support any options"
1494         if @ARGV and $ARGV[0] =~ m/^-/;
1495     badusage "too many arguments to analyse" if @ARGV>1;
1496     my ($old) = @ARGV;
1497     if (defined $old) {
1498         $old = git_rev_parse $old;
1499     } else {
1500         $old = git_rev_parse 'HEAD';
1501     }
1502     my ($dummy,$breakwater) = walk $old, 1,*STDOUT;
1503     STDOUT->error and die $!;
1504 }
1505
1506 sub ffq_prev_branchinfo () {
1507     my $current = git_get_symref();
1508     return gdr_ffq_prev_branchinfo($current);
1509 }
1510
1511 sub ffq_check ($;$$) {
1512     # calls $ff and/or $notff zero or more times
1513     # then returns either (status,message) where status is
1514     #    exists
1515     #    detached
1516     #    weird-symref
1517     #    notbranch
1518     # or (undef,undef, $ffq_prev,$gdrlast)
1519     # $ff and $notff are called like this:
1520     #   $ff->("message for stdout\n");
1521     #   $notff->('snag-name', $message);
1522     # normally $currentval should be HEAD
1523     my ($currentval, $ff, $notff) =@_;
1524
1525     $ff //= sub { print $_[0] or die $!; };
1526     $notff //= \&snag;
1527
1528     my ($status, $message, $current, $ffq_prev, $gdrlast)
1529         = ffq_prev_branchinfo();
1530     return ($status, $message) unless $status eq 'branch';
1531
1532     my $exists = git_get_ref $ffq_prev;
1533     return ('exists',"$ffq_prev already exists") if $exists;
1534
1535     return ('not-branch', 'HEAD symref is not to refs/heads/')
1536         unless $current =~ m{^refs/heads/};
1537     my $branch = $';
1538
1539     my @check_specs = split /\;/, (cfg "branch.$branch.ffq-ffrefs",1) // '*';
1540     my %checked;
1541
1542     printdebug "ffq check_specs @check_specs\n";
1543
1544     my $check = sub {
1545         my ($lrref, $desc) = @_;
1546         printdebug "ffq might check $lrref ($desc)\n";
1547         my $invert;
1548         for my $chk (@check_specs) {
1549             my $glob = $chk;
1550             $invert = $glob =~ s{^[!^]}{};
1551             last if fnmatch $glob, $lrref;
1552         }
1553         return if $invert;
1554         my $lrval = git_get_ref $lrref;
1555         return unless length $lrval;
1556
1557         if (is_fast_fwd $lrval, $currentval) {
1558             $ff->("OK, you are ahead of $lrref\n");
1559             $checked{$lrref} = 1;
1560         } elsif (is_fast_fwd $currentval, $lrval) {
1561             $checked{$lrref} = -1;
1562             $notff->('behind', "you are behind $lrref, divergence risk");
1563         } else {
1564             $checked{$lrref} = -1;
1565             $notff->('diverged', "you have diverged from $lrref");
1566         }
1567     };
1568
1569     my $merge = cfg "branch.$branch.merge",1;
1570     if (defined $merge and $merge =~ m{^refs/heads/}) {
1571         my $rhs = $';
1572         printdebug "ffq merge $rhs\n";
1573         my $check_remote = sub {
1574             my ($remote, $desc) = @_;
1575             printdebug "ffq check_remote ".($remote//'undef')." $desc\n";
1576             return unless defined $remote;
1577             $check->("refs/remotes/$remote/$rhs", $desc);
1578         };
1579         $check_remote->((scalar cfg "branch.$branch.remote",1),
1580                         'remote fetch/merge branch');
1581         $check_remote->((scalar cfg "branch.$branch.pushRemote",1) //
1582                         (scalar cfg "branch.$branch.pushDefault",1),
1583                         'remote push branch');
1584     }
1585     if ($branch =~ m{^dgit/}) {
1586         $check->("refs/remotes/dgit/$branch", 'remote dgit branch');
1587     } elsif ($branch =~ m{^master$}) {
1588         $check->("refs/remotes/dgit/dgit/sid", 'remote dgit branch for sid');
1589     }
1590     return (undef, undef, $ffq_prev, $gdrlast);
1591 }
1592
1593 sub record_ffq_prev_deferred () {
1594     # => ('status', "message")
1595     # 'status' may be
1596     #    deferred          message is undef
1597     #    exists
1598     #    detached
1599     #    weird-symref
1600     #    notbranch
1601     # if not ff from some branch we should be ff from, is an snag
1602     # if "deferred", will have added something about that to
1603     #   @deferred_update_messages, and also maybe printed (already)
1604     #   some messages about ff checks
1605     bail_if_rebasing();
1606     my $currentval = get_head();
1607
1608     my ($status,$message, $ffq_prev,$gdrlast) = ffq_check $currentval;
1609     return ($status,$message) if defined $status;
1610
1611     snags_maybe_bail();
1612
1613     push @deferred_updates, "update $ffq_prev $currentval $git_null_obj";
1614     push @deferred_updates, "delete $gdrlast";
1615     push @deferred_update_messages, "Recorded previous head for preservation";
1616     return ('deferred', undef);
1617 }
1618
1619 sub record_ffq_auto () {
1620     my ($status, $message) = record_ffq_prev_deferred();
1621     if ($status eq 'deferred' || $status eq 'exists') {
1622     } else {
1623         snag $status, "could not record ffq-prev: $message";
1624         snags_maybe_bail();
1625     }
1626 }
1627
1628 sub ffq_prev_info () {
1629     bail_if_rebasing();
1630     # => ($ffq_prev, $gdrlast, $ffq_prev_commitish)
1631     my ($status, $message, $current, $ffq_prev, $gdrlast)
1632         = ffq_prev_branchinfo();
1633     if ($status ne 'branch') {
1634         snag $status, "could not check ffq-prev: $message";
1635         snags_maybe_bail();
1636     }
1637     my $ffq_prev_commitish = $ffq_prev && git_get_ref $ffq_prev;
1638     return ($ffq_prev, $gdrlast, $ffq_prev_commitish);
1639 }
1640
1641 sub stitch ($$$$$) {
1642     my ($old_head, $ffq_prev, $gdrlast, $ffq_prev_commitish, $prose) = @_;
1643
1644     push @deferred_updates, "delete $ffq_prev $ffq_prev_commitish";
1645
1646     if (is_fast_fwd $old_head, $ffq_prev_commitish) {
1647         my $differs = get_differs $old_head, $ffq_prev_commitish;
1648         unless ($differs & ~D_PAT_ADD) {
1649             # ffq-prev is ahead of us, and the only tree changes it has
1650             # are possibly addition of things in debian/patches/.
1651             # Just wind forwards rather than making a pointless pseudomerge.
1652             push @deferred_updates,
1653                 "update $gdrlast $ffq_prev_commitish $git_null_obj";
1654             update_head_checkout $old_head, $ffq_prev_commitish,
1655                 "stitch (fast forward)";
1656             return;
1657         }
1658     }
1659     fresh_workarea();
1660     # We make pseudomerges with L as the contributing parent.
1661     # This makes git rev-list --first-parent work properly.
1662     my $new_head = make_commit [ $old_head, $ffq_prev ], [
1663         'Declare fast forward / record previous work',
1664         "[git-debrebase pseudomerge: $prose]",
1665     ];
1666     push @deferred_updates, "update $gdrlast $new_head $git_null_obj";
1667     update_head $old_head, $new_head, "stitch: $prose";
1668 }
1669
1670 sub do_stitch ($;$) {
1671     my ($prose, $unclean) = @_;
1672
1673     my ($ffq_prev, $gdrlast, $ffq_prev_commitish) = ffq_prev_info();
1674     if (!$ffq_prev_commitish) {
1675         fail "No ffq-prev to stitch." unless $opt_noop_ok;
1676         return;
1677     }
1678     my $dangling_head = get_head();
1679
1680     keycommits $dangling_head, $unclean,$unclean,$unclean;
1681     snags_maybe_bail();
1682
1683     stitch($dangling_head, $ffq_prev, $gdrlast, $ffq_prev_commitish, $prose);
1684 }
1685
1686 sub upstream_commitish_search ($$) {
1687     my ($upstream_version, $tried) = @_;
1688     # todo: at some point maybe use git-deborig to do this
1689     foreach my $tagpfx ('', 'v', 'upstream/') {
1690         my $tag = $tagpfx.(dep14_version_mangle $upstream_version);
1691         my $new_upstream = git_get_ref "refs/tags/$tag";
1692         push @$tried, $tag;
1693         return $new_upstream if length $new_upstream;
1694     }
1695 }
1696
1697 sub resolve_upstream_version ($$) {
1698     my ($new_upstream, $upstream_version) = @_;
1699
1700     if (!defined $new_upstream) {
1701         my @tried;
1702         $new_upstream = upstream_commitish_search $upstream_version, \@tried;
1703         if (!length $new_upstream) {
1704             fail "Could not determine appropriate upstream commitish.\n".
1705                 " (Tried these tags: @tried)\n".
1706                 " Check version, and specify upstream commitish explicitly.";
1707         }
1708     }
1709     $new_upstream = git_rev_parse $new_upstream;
1710
1711     return $new_upstream;
1712 }
1713
1714 sub cmd_new_upstream () {
1715     # automatically and unconditionally launders before rebasing
1716     # if rebase --abort is used, laundering has still been done
1717
1718     my %pieces;
1719
1720     badusage "need NEW-VERSION [UPS-COMMITTISH]" unless @ARGV >= 1;
1721
1722     # parse args - low commitment
1723     my $spec_version = shift @ARGV;
1724     my $new_version = (new Dpkg::Version $spec_version, check => 1);
1725     fail "bad version number \`$spec_version'" unless defined $new_version;
1726     if ($new_version->is_native()) {
1727         $new_version = (new Dpkg::Version "$spec_version-1", check => 1);
1728     }
1729
1730     my $new_upstream = shift @ARGV;
1731     my $new_upstream_version = upstreamversion  $new_version;
1732     $new_upstream =
1733         resolve_upstream_version $new_upstream, $new_upstream_version;
1734
1735     record_ffq_auto();
1736
1737     my $piece = sub {
1738         my ($n, @x) = @_; # may be ''
1739         my $pc = $pieces{$n} //= {
1740             Name => $n,
1741             Desc => ($n ? "upstream piece \`$n'" : "upstream (main piece"),
1742         };
1743         while (my $k = shift @x) { $pc->{$k} = shift @x; }
1744         $pc;
1745     };
1746
1747     my @newpieces;
1748     my $newpiece = sub {
1749         my ($n, @x) = @_; # may be ''
1750         my $pc = $piece->($n, @x, NewIx => (scalar @newpieces));
1751         push @newpieces, $pc;
1752     };
1753
1754     $newpiece->('',
1755         OldIx => 0,
1756         New => $new_upstream,
1757     );
1758     while (@ARGV && $ARGV[0] !~ m{^-}) {
1759         my $n = shift @ARGV;
1760
1761         badusage "for each EXTRA-UPS-NAME need EXTRA-UPS-COMMITISH"
1762             unless @ARGV && $ARGV[0] !~ m{^-};
1763
1764         my $c = git_rev_parse shift @ARGV;
1765         die unless $n =~ m/^$extra_orig_namepart_re$/;
1766         $newpiece->($n, New => $c);
1767     }
1768
1769     # now we need to investigate the branch this generates the
1770     # laundered version but we don't switch to it yet
1771     my $old_head = get_head();
1772     my ($old_laundered_tip,$old_bw,$old_anchor) = walk $old_head;
1773
1774     my $old_bw_cl = classify $old_bw;
1775     my $old_anchor_cl = classify $old_anchor;
1776     my $old_upstream;
1777     if (!$old_anchor_cl->{OrigParents}) {
1778         snag 'anchor-treated',
1779             'old anchor is recognised due to --anchor, cannot check upstream';
1780     } else {
1781         $old_upstream = parsecommit
1782             $old_anchor_cl->{OrigParents}[0]{CommitId};
1783         $piece->('', Old => $old_upstream->{CommitId});
1784     }
1785
1786     if ($old_upstream && $old_upstream->{Msg} =~ m{^\[git-debrebase }m) {
1787         if ($old_upstream->{Msg} =~
1788  m{^\[git-debrebase upstream-combine (\.(?: $extra_orig_namepart_re)+)\:.*\]$}m
1789            ) {
1790             my @oldpieces = (split / /, $1);
1791             my $old_n_parents = scalar @{ $old_upstream->{Parents} };
1792             if ($old_n_parents != @oldpieces &&
1793                 $old_n_parents != @oldpieces + 1) {
1794                 snag 'upstream-confusing', sprintf
1795                     "previous upstream combine %s".
1796                     " mentions %d pieces (each implying one parent)".
1797                     " but has %d parents".
1798                     " (one per piece plus maybe a previous combine)",
1799                     $old_upstream->{CommitId},
1800                     (scalar @oldpieces),
1801                     $old_n_parents;
1802             } elsif ($oldpieces[0] ne '.') {
1803                 snag 'upstream-confusing', sprintf
1804                     "previous upstream combine %s".
1805                     " first piece is not \`.'",
1806                     $oldpieces[0];
1807             } else {
1808                 $oldpieces[0] = '';
1809                 foreach my $i (0..$#oldpieces) {
1810                     my $n = $oldpieces[$i];
1811                     my $hat = 1 + $i + ($old_n_parents - @oldpieces);
1812                     $piece->($n, Old => $old_upstream->{CommitId}.'^'.$hat);
1813                 }
1814             }
1815         } else {
1816             snag 'upstream-confusing',
1817                 "previous upstream $old_upstream->{CommitId} is from".
1818                " git-debrebase but not an \`upstream-combine' commit";
1819         }
1820     }
1821
1822     foreach my $pc (values %pieces) {
1823         if (!$old_upstream) {
1824             # we have complained already
1825         } elsif (!$pc->{Old}) {
1826             snag 'upstream-new-piece',
1827                 "introducing upstream piece \`$pc->{Name}'";
1828         } elsif (!$pc->{New}) {
1829             snag 'upstream-rm-piece',
1830                 "dropping upstream piece \`$pc->{Name}'";
1831         } elsif (!is_fast_fwd $pc->{Old}, $pc->{New}) {
1832             snag 'upstream-not-ff',
1833                 "not fast forward: $pc->{Name} $pc->{Old}..$pc->{New}";
1834         }
1835     }
1836
1837     printdebug "%pieces = ", (dd \%pieces), "\n";
1838     printdebug "\@newpieces = ", (dd \@newpieces), "\n";
1839
1840     snags_maybe_bail();
1841
1842     my $new_bw;
1843
1844     fresh_workarea();
1845     in_workarea sub {
1846         my @upstream_merge_parents;
1847
1848         if (!any_snags()) {
1849             push @upstream_merge_parents, $old_upstream->{CommitId};
1850         }
1851
1852         foreach my $pc (@newpieces) { # always has '' first
1853             if ($pc->{Name}) {
1854                 read_tree_subdir $pc->{Name}, $pc->{New};
1855             } else {
1856                 runcmd @git, qw(read-tree), $pc->{New};
1857             }
1858             push @upstream_merge_parents, $pc->{New};
1859         }
1860
1861         # index now contains the new upstream
1862
1863         if (@newpieces > 1) {
1864             # need to make the upstream subtree merge commit
1865             $new_upstream = make_commit \@upstream_merge_parents,
1866                 [ "Combine upstreams for $new_upstream_version",
1867  ("[git-debrebase upstream-combine . ".
1868  (join " ", map { $_->{Name} } @newpieces[1..$#newpieces]).
1869  ": new upstream]"),
1870                 ];
1871         }
1872
1873         # $new_upstream is either the single upstream commit, or the
1874         # combined commit we just made.  Either way it will be the
1875         # "upstream" parent of the anchor merge.
1876
1877         read_tree_subdir 'debian', "$old_bw:debian";
1878
1879         # index now contains the anchor merge contents
1880         $new_bw = make_commit [ $old_bw, $new_upstream ],
1881             [ "Update to upstream $new_upstream_version",
1882  "[git-debrebase anchor: new upstream $new_upstream_version, merge]",
1883             ];
1884
1885         my $clogsignoff = cmdoutput qw(git show),
1886             '--pretty=format:%an <%ae>  %aD',
1887             $new_bw;
1888
1889         # Now we have to add a changelog stanza so the Debian version
1890         # is right.
1891         die if unlink "debian";
1892         die $! unless $!==ENOENT or $!==ENOTEMPTY;
1893         unlink "debian/changelog" or $!==ENOENT or die $!;
1894         mkdir "debian" or die $!;
1895         open CN, ">", "debian/changelog" or die $!;
1896         my $oldclog = git_cat_file ":debian/changelog";
1897         $oldclog =~ m/^($package_re) \(\S+\) / or
1898             fail "cannot parse old changelog to get package name";
1899         my $p = $1;
1900         print CN <<END, $oldclog or die $!;
1901 $p ($new_version) UNRELEASED; urgency=medium
1902
1903   * Update to new upstream version $new_upstream_version.
1904
1905  -- $clogsignoff
1906
1907 END
1908         close CN or die $!;
1909         runcmd @git, qw(update-index --add --replace), 'debian/changelog';
1910
1911         # Now we have the final new breakwater branch in the index
1912         $new_bw = make_commit [ $new_bw ],
1913             [ "Update changelog for new upstream $new_upstream_version",
1914               "[git-debrebase: new upstream $new_upstream_version, changelog]",
1915             ];
1916     };
1917
1918     # we have constructed the new breakwater. we now need to commit to
1919     # the laundering output, because git-rebase can't easily be made
1920     # to make a replay list which is based on some other branch
1921
1922     update_head_postlaunder $old_head, $old_laundered_tip,
1923         'launder for new upstream';
1924
1925     my @cmd = (@git, qw(rebase --onto), $new_bw, $old_bw, @ARGV);
1926     local $ENV{GIT_REFLOG_ACTION} = git_reflog_action_msg
1927         "debrebase new-upstream $new_version: rebase";
1928     runcmd @cmd;
1929     # now it's for the user to sort out
1930 }
1931
1932 sub cmd_record_ffq_prev () {
1933     badusage "no arguments allowed" if @ARGV;
1934     my ($status, $msg) = record_ffq_prev_deferred();
1935     if ($status eq 'exists' && $opt_noop_ok) {
1936         print "Previous head already recorded\n" or die $!;
1937     } elsif ($status eq 'deferred') {
1938         run_deferred_updates 'record-ffq-prev';
1939     } else {
1940         fail "Could not preserve: $msg";
1941     }
1942 }
1943
1944 sub cmd_anchor () {
1945     badusage "no arguments allowed" if @ARGV;
1946     my ($anchor, $bw) = keycommits +(git_rev_parse 'HEAD'), 0,0;
1947     print "$bw\n" or die $!;
1948 }
1949
1950 sub cmd_breakwater () {
1951     badusage "no arguments allowed" if @ARGV;
1952     my ($anchor, $bw) = keycommits +(git_rev_parse 'HEAD'), 0,0;
1953     print "$bw\n" or die $!;
1954 }
1955
1956 sub cmd_status () {
1957     badusage "no arguments allowed" if @ARGV;
1958
1959     # todo: gdr status should print divergence info
1960     # todo: gdr status should print upstream component(s) info
1961     # todo: gdr should leave/maintain some refs with this kind of info ?
1962
1963     my $oldest = { Badness => 0 };
1964     my $newest;
1965     my $note = sub {
1966         my ($badness, $ourmsg, $snagname, $dummy, $cl, $kcmsg) = @_;
1967         if ($oldest->{Badness} < $badness) {
1968             $oldest = $newest = undef;
1969         }
1970         $oldest = {
1971                    Badness => $badness,
1972                    CommitId => $cl->{CommitId},
1973                    OurMsg => $ourmsg,
1974                    KcMsg => $kcmsg,
1975                   };
1976         $newest //= $oldest;
1977     };
1978     my ($anchor, $bw) = keycommits +(git_rev_parse 'HEAD'),
1979         sub { $note->(1, 'branch contains furniture (not laundered)', @_); },
1980         sub { $note->(2, 'branch is unlaundered', @_); },
1981         sub { $note->(3, 'branch needs laundering', @_); },
1982         sub { $note->(4, 'branch not in git-debrebase form', @_); };
1983
1984     my $prcommitinfo = sub {
1985         my ($cid) = @_;
1986         flush STDOUT or die $!;
1987         runcmd @git, qw(--no-pager log -n1),
1988             '--pretty=format:    %h %s%n',
1989             $cid;
1990     };
1991
1992     print "current branch contents, in git-debrebase terms:\n";
1993     if (!$oldest->{Badness}) {
1994         print "  branch is laundered\n";
1995     } else {
1996         print "  $oldest->{OurMsg}\n";
1997         my $printed = '';
1998         foreach my $info ($oldest, $newest) {
1999             my $cid = $info->{CommitId};
2000             next if $cid eq $printed;
2001             $printed = $cid;
2002             print "  $info->{KcMsg}\n";
2003             $prcommitinfo->($cid);
2004         }
2005     }
2006
2007     my $prab = sub {
2008         my ($cid, $what) = @_;
2009         if (!defined $cid) {
2010             print "  $what is not well-defined\n";
2011         } else {
2012             print "  $what\n";
2013             $prcommitinfo->($cid);
2014         }
2015     };
2016     print "key git-debrebase commits:\n";
2017     $prab->($anchor, 'anchor');
2018     $prab->($bw, 'breakwater');
2019
2020     my ($ffqstatus, $ffq_msg, $current, $ffq_prev, $gdrlast) =
2021         ffq_prev_branchinfo();
2022
2023     print "branch and ref status, in git-debrebase terms:\n";
2024     if ($ffq_msg) {
2025         print "  $ffq_msg\n";
2026     } else {
2027         $ffq_prev = git_get_ref $ffq_prev;
2028         $gdrlast = git_get_ref $gdrlast;
2029         if ($ffq_prev) {
2030             print "  unstitched; previous tip was:\n";
2031             $prcommitinfo->($ffq_prev);
2032         } elsif (!$gdrlast) {
2033             print "  stitched? (no record of git-debrebase work)\n";
2034         } elsif (is_fast_fwd $gdrlast, 'HEAD') {
2035             print "  stitched\n";
2036         } else {
2037             print "  not git-debrebase (diverged since last stitch)\n"
2038         }
2039     }
2040     print "you are currently rebasing\n" if currently_rebasing();
2041 }
2042
2043 sub cmd_stitch () {
2044     my $prose = 'stitch';
2045     getoptions("stitch",
2046                'prose=s', \$prose);
2047     badusage "no arguments allowed" if @ARGV;
2048     do_stitch $prose, 0;
2049 }
2050 sub cmd_prepush () { cmd_stitch(); }
2051
2052 sub cmd_quick () {
2053     badusage "no arguments allowed" if @ARGV;
2054     do_launder_head 'launder for git-debrebase quick';
2055     do_stitch 'quick';
2056 }
2057
2058 sub cmd_conclude () {
2059     my ($ffq_prev, $gdrlast, $ffq_prev_commitish) = ffq_prev_info();
2060     if (!$ffq_prev_commitish) {
2061         fail "No ongoing git-debrebase session." unless $opt_noop_ok;
2062         return;
2063     }
2064     my $dangling_head = get_head();
2065
2066     badusage "no arguments allowed" if @ARGV;
2067     do_launder_head 'launder for git-debrebase quick';
2068     do_stitch 'quick';
2069 }
2070
2071 sub cmd_scrap () {
2072     if (currently_rebasing()) {
2073         runcmd @git, qw(rebase --abort);
2074     }
2075     my ($ffq_prev, $gdrlast, $ffq_prev_commitish) = ffq_prev_info();
2076     if (!$ffq_prev_commitish) {
2077         fail "No ongoing git-debrebase session." unless $opt_noop_ok;
2078         finish 0;
2079     }
2080     my $scrapping_head = get_head();
2081     badusage "no arguments allowed" if @ARGV;
2082     push @deferred_updates,
2083         "update $gdrlast $ffq_prev_commitish $git_null_obj",
2084         "update $ffq_prev $git_null_obj $ffq_prev_commitish";
2085     snags_maybe_bail();
2086     update_head_checkout $scrapping_head, $ffq_prev_commitish, "scrap";
2087 }
2088
2089 sub make_patches_staged ($) {
2090     my ($head) = @_;
2091     # Produces the patches that would result from $head if it were
2092     # laundered.
2093     my ($secret_head, $secret_bw, $last_anchor) = walk $head;
2094     fresh_workarea();
2095     in_workarea sub {
2096         gbp_pq_export 'bw', $secret_bw, $secret_head;
2097     };
2098 }
2099
2100 sub make_patches ($) {
2101     my ($head) = @_;
2102     keycommits $head, 0, \&snag;
2103     make_patches_staged $head;
2104     my $out;
2105     in_workarea sub {
2106         my $ptree = cmdoutput @git, qw(write-tree --prefix=debian/patches/);
2107         runcmd @git, qw(read-tree), $head;
2108         read_tree_subdir 'debian/patches', $ptree;
2109         $out = make_commit [$head], [
2110             'Commit patch queue (exported by git-debrebase)',
2111             '[git-debrebase: export and commit patches]',
2112         ];
2113     };
2114     return $out;
2115 }
2116
2117 sub cmd_make_patches () {
2118     my $opt_quiet_would_amend;
2119     getoptions("make-patches",
2120                'quiet-would-amend!', \$opt_quiet_would_amend);
2121     badusage "no arguments allowed" if @ARGV;
2122     bail_if_rebasing();
2123     my $old_head = get_head();
2124     my $new = make_patches $old_head;
2125     my $d = get_differs $old_head, $new;
2126     if ($d == 0) {
2127         fail "No (more) patches to export." unless $opt_noop_ok;
2128         return;
2129     } elsif ($d == D_PAT_ADD) {
2130         snags_maybe_bail();
2131         update_head_checkout $old_head, $new, 'make-patches';
2132     } else {
2133         print STDERR failmsg
2134             "Patch export produced patch amendments".
2135             " (abandoned output commit $new).".
2136             "  Try laundering first."
2137             unless $opt_quiet_would_amend;
2138         finish 7;
2139     }
2140 }
2141
2142 sub cmd_convert_from_gbp () {
2143     badusage "want only 1 optional argument, the upstream git commitish"
2144         unless @ARGV<=1;
2145
2146     my $clogp = parsechangelog();
2147     my $version = $clogp->{'Version'}
2148         // die "missing Version from changelog";
2149
2150     my ($upstream_spec) = @ARGV;
2151
2152     my $upstream_version = upstreamversion $version;
2153     my $upstream =
2154         resolve_upstream_version($upstream_spec, $upstream_version);
2155
2156     my $old_head = get_head();
2157
2158     my $upsdiff = get_differs $upstream, $old_head;
2159     if ($upsdiff & D_UPS) {
2160         runcmd @git, qw(--no-pager diff --stat),
2161             $upstream, $old_head,
2162             qw( -- :!/debian :/);
2163         fail <<END;
2164 upstream ($upstream_spec) and HEAD are not
2165 identical in upstream files.  See diffstat above, or run
2166   git diff $upstream_spec HEAD -- :!/debian :/
2167 END
2168     }
2169
2170     if (!is_fast_fwd $upstream, $old_head) {
2171         snag 'upstream-not-ancestor',
2172             "upstream ($upstream) is not an ancestor of HEAD";
2173     } else {
2174         my $wrong = cmdoutput
2175             (@git, qw(rev-list --ancestry-path), "$upstream..HEAD",
2176              qw(-- :/ :!/debian));
2177         if (length $wrong) {
2178             snag 'unexpected-upstream-changes',
2179                 "history between upstream ($upstream) and HEAD contains direct changes to upstream files - are you sure this is a gbp (patches-unapplied) branch?";
2180             print STDERR "list expected changes with:  git log --stat --ancestry-path $upstream_spec..HEAD -- :/ ':!/debian'\n";
2181         }
2182     }
2183
2184     if ((git_cat_file "$upstream:debian")[0] ne 'missing') {
2185         snag 'upstream-has-debian',
2186             "upstream ($upstream) contains debian/ directory";
2187     }
2188
2189     my $previous_dgit_view = eval {
2190         my @clogcmd = qw(dpkg-parsechangelog --format rfc822 -n2);
2191         my ($lvsn, $suite);
2192         parsechangelog_loop \@clogcmd, 'debian/changelog', sub {
2193             my ($stz, $desc) = @_;
2194             no warnings qw(exiting);
2195             printdebug 'CHANGELOG ', Dumper($desc, $stz);
2196             next unless $stz->{Date};
2197             next unless $stz->{Distribution} ne 'UNRELEASED';
2198             $lvsn = $stz->{Version};
2199             $suite = $stz->{Distribution};
2200             last;
2201         };
2202         die "neither of the first two changelog entries are released\n"
2203             unless defined $lvsn;
2204         print "last finished-looking changelog entry: ($lvsn) $suite\n";
2205         my $mtag_pat = debiantag_maintview $lvsn, '*';
2206         my $mtag = cmdoutput @git, qw(describe --always --abbrev=0 --match),
2207             $mtag_pat;
2208         die "could not find suitable maintainer view tag $mtag_pat\n"
2209             unless $mtag_pat =~ m{/};
2210         is_fast_fwd $mtag, 'HEAD' or
2211             die "HEAD is not FF from maintainer tag $mtag!";
2212         my $dtag = "archive/$mtag";
2213         is_fast_fwd $mtag, $dtag or
2214             die "dgit view tag $dtag is not FF from maintainer tag $mtag";
2215         print "will stitch in dgit view, $dtag\n";
2216         git_rev_parse $dtag;
2217     };
2218     if (!$previous_dgit_view) {
2219         $@ =~ s/^\n+//;
2220         chomp $@;
2221         print STDERR "cannot stitch in dgit view: $@\n";
2222     }
2223
2224     snags_maybe_bail_early();
2225
2226     my $work;
2227
2228     fresh_workarea();
2229     in_workarea sub {
2230         runcmd @git, qw(checkout -q -b gdr-internal), $old_head;
2231         # make a branch out of the patch queue - we'll want this in a mo
2232         runcmd qw(gbp pq import);
2233         # strip the patches out
2234         runcmd @git, qw(checkout -q gdr-internal~0);
2235         rm_subdir_cached 'debian/patches';
2236         $work = make_commit ['HEAD'], [
2237  'git-debrebase convert-from-gbp: drop patches from tree',
2238  'Delete debian/patches, as part of converting to git-debrebase format.',
2239  '[git-debrebase convert-from-gbp: drop patches from tree]'
2240                               ];
2241         # make the anchor merge
2242         # the tree is already exactly right
2243         $work = make_commit [$work, $upstream], [
2244  'git-debrebase import: declare upstream',
2245  'First breakwater merge.',
2246  '[git-debrebase anchor: declare upstream]'
2247                               ];
2248
2249         # rebase the patch queue onto the new breakwater
2250         runcmd @git, qw(reset --quiet --hard patch-queue/gdr-internal);
2251         runcmd @git, qw(rebase --quiet --onto), $work, qw(gdr-internal);
2252         $work = git_rev_parse 'HEAD';
2253
2254         if ($previous_dgit_view) {
2255             $work = make_commit [$work, $previous_dgit_view], [
2256  'git-debrebase import: declare ff from dgit archive view',
2257  '[git-debrebase pseudomerge: import-from-gbp]',
2258             ];
2259         }
2260     };
2261
2262     ffq_check $work;
2263     snags_maybe_bail();
2264     update_head_checkout $old_head, $work, 'convert-from-gbp';
2265 }
2266
2267 sub cmd_convert_to_gbp () {
2268     badusage "no arguments allowed" if @ARGV;
2269     my $head = get_head();
2270     my (undef, undef, undef, $ffq, $gdrlast) = ffq_prev_branchinfo();
2271     keycommits $head, 0;
2272     my $out;
2273     make_patches_staged $head;
2274     in_workarea sub {
2275         $out = make_commit ['HEAD'], [
2276             'Commit patch queue (converted from git-debrebase format)',
2277             '[git-debrebase convert-to-gbp: commit patches]',
2278         ];
2279     };
2280     if (defined $ffq) {
2281         push @deferred_updates, "delete $ffq";
2282         push @deferred_updates, "delete $gdrlast";
2283     }
2284     snags_maybe_bail();
2285     update_head_checkout $head, $out, "convert to gbp (v0)";
2286     print <<END or die $!;
2287 git-debrebase: converted to git-buildpackage branch format
2288 git-debrebase: WARNING: do not now run "git-debrebase" any more
2289 git-debrebase: WARNING: doing so would drop all upstream patches!
2290 END
2291 }
2292
2293 sub cmd_convert_from_dgit_view () {
2294     my $clogp = parsechangelog();
2295
2296     my $bpd = (cfg 'dgit.default.build-products-dir',1) // '..';
2297     my $do_origs = 1;
2298     my $do_tags = 1;
2299     my $always = 0;
2300     my $diagnose = 0;
2301
2302     getoptions("convert-from-dgit-view",
2303                'diagnose!', \$diagnose,
2304                'build-products-dir:s', \$bpd,
2305                'origs!', \$do_origs,
2306                'tags!', \$do_tags,
2307                'always-convert-anyway!', \$always);
2308     fail "takes 1 optional argument, the upstream commitish" if @ARGV>1;
2309
2310     my @upstreams;
2311
2312     if (@ARGV) {
2313         my $spec = shift @ARGV;
2314         my $commit = git_rev_parse "$spec^{commit}";
2315         push @upstreams, { Commit => $commit,
2316                            Source => "$ARGV[0], from command line",
2317                            Only => 1,
2318                          };
2319     }
2320
2321     my $head = get_head();
2322
2323     if (!$always) {
2324         my $troubles = 0;
2325         my $trouble = sub { $troubles++; };
2326         keycommits $head, sub{}, sub{}, $trouble, $trouble;
2327         printdebug "troubles=$troubles\n";
2328         if (!$troubles) {
2329             print STDERR <<END;
2330 $us: Branch already seems to be in git-debrebase format!
2331 $us: --always-convert-anyway would do the conversion operation anyway
2332 $us: but is probably a bad idea.  Probably, you wanted to do nothing.
2333 END
2334             fail "Branch already in git-debrebase format." unless $opt_noop_ok;
2335             finish 0;
2336         }
2337     }
2338
2339     snags_maybe_bail_early();
2340
2341     my $version = upstreamversion $clogp->{Version};
2342     print STDERR "Considering possible commits corresponding to upstream:\n";
2343
2344     if (!@upstreams) {
2345         if ($do_tags) {
2346             my @tried;
2347             my $ups_tag = upstream_commitish_search $version, \@tried;
2348             if ($ups_tag) {
2349                 my $this = "git tag $tried[-1]";
2350                 push @upstreams, { Commit => $ups_tag,
2351                                    Source => $this,
2352                                  };
2353             } else {
2354                 printf STDERR
2355                     " git tag: no suitable tag found (tried %s)\n",
2356                     "@tried";
2357             }
2358         }
2359         if ($do_origs) {
2360             my $p = $clogp->{'Source'};
2361             # we do a quick check to see if there are plausible origs
2362             my $something=0;
2363             if (!opendir BPD, $bpd) {
2364                 die "$bpd: opendir: $!" unless $!==ENOENT;
2365             } else {
2366                 while ($!=0, my $f = readdir BPD) {
2367                     next unless is_orig_file_of_p_v $f, $p, $version;
2368                     printf STDERR
2369                         " orig: found what looks like a .orig, %s\n",
2370                         "$bpd/$f";
2371                     $something=1;
2372                     last;
2373                 }
2374                 die "read $bpd: $!" if $!;
2375                 closedir BPD;
2376             }
2377             if ($something) {
2378                 my $tree = cmdoutput
2379                     @dgit, qw(--build-products-dir), $bpd,
2380                     qw(print-unapplied-treeish);
2381                 fresh_workarea();
2382                 in_workarea sub {
2383                     runcmd @git, qw(reset --quiet), $tree, qw(-- .);
2384                     rm_subdir_cached 'debian';
2385                     $tree = cmdoutput @git, qw(write-tree);
2386                     my $ups_synth = make_commit [], [ <<END, <<END,
2387 Import effective orig tree for upstream version $version
2388 END
2389 This includes the contents of the .orig(s), minus any debian/ directory.
2390
2391 [git-debrebase import-from-dgit-view upstream-import-convert: $version]
2392 END
2393                                                     ];
2394                     push @upstreams, { Commit => $ups_synth,
2395                                        Source => "orig(s) imported via dgit",
2396                                      };
2397                 }
2398             } else {
2399                 printf STDERR
2400                     " orig: no suitable origs found (looked for %s in %s)\n",
2401                     "${p}_".(stripeoch $version)."...", $bpd;
2402             }
2403         }
2404     }
2405
2406     my $some_patches = stat_exists 'debian/patches/series';
2407
2408     print STDERR "Evaluating possible commits corresponding to upstream:\n";
2409
2410     my $result;
2411     foreach my $u (@upstreams) {
2412         my $work = $head;
2413         fresh_workarea();
2414         in_workarea sub {
2415             runcmd @git, qw(reset --quiet), $u->{Commit}, qw(-- .);
2416             runcmd @git, qw(checkout), $u->{Commit}, qw(-- .);
2417             runcmd @git, qw(clean -xdff);
2418             runcmd @git, qw(checkout), $head, qw(-- debian);
2419             if ($some_patches) {
2420                 rm_subdir_cached 'debian/patches';
2421                 $work = make_commit [ $work ], [
2422  'git-debrebase convert-from-dgit-view: drop upstream changes from breakwater',
2423  "Drop upstream changes, and delete debian/patches, as part of converting\n".
2424  "to git-debrebase format.  Upstream changes will appear as commits.",
2425  '[git-debrebase convert-from-dgit-view: drop patches from tree]'
2426                                            ];
2427             }
2428             $work = make_commit [ $work, $u->{Commit} ], [
2429  'git-debrebase convert-from-dgit-view: declare upstream',
2430  '(Re)constructed breakwater merge.',
2431  '[git-debrebase anchor: declare upstream]'
2432                                                          ];
2433             runcmd @git, qw(checkout --quiet -b mk), $work;
2434             if ($some_patches) {
2435                 runcmd @git, qw(checkout), $head, qw(-- debian/patches);
2436                 runcmd @git, qw(reset --quiet);
2437                 my @gbp_cmd = (qw(gbp pq import));
2438                 if (!$diagnose) {
2439                     my $gbp_err = "../gbp-pq-err";
2440                     @gbp_cmd = shell_cmd "exec >$gbp_err 2>&1", @gbp_cmd;
2441                 }
2442                 my $r = system @gbp_cmd;
2443                 if ($r) {
2444                     printf STDERR
2445                         " %s: couldn't apply patches: gbp pq %s",
2446                         $u->{Source}, waitstatusmsg();
2447                     return;
2448                 }
2449             }
2450             my $work = git_rev_parse qw(HEAD);
2451             my $diffout = cmdoutput @git, qw(diff-tree --stat HEAD), $work;
2452             if (length $diffout) {
2453                 print STDERR
2454                     " $u->{Source}: applying patches gives different tree\n";
2455                 print STDERR $diffout if $diagnose;
2456                 return;
2457             }
2458             # OMG!
2459             $u->{Result} = $work;
2460             $result = $u;
2461         };
2462         last if $result;
2463     }
2464
2465     if (!$result) {
2466         fail <<END;
2467 Could not find or construct a suitable upstream commit.
2468 Rerun adding --diagnose after convert-from-dgit-view, or pass a
2469 upstream commmit explicitly or provide suitable origs.
2470 END
2471     }
2472
2473     printf STDERR "Yes, will base new branch on %s\n", $result->{Source};
2474
2475     ffq_check $result->{Result};
2476     snags_maybe_bail();
2477     update_head_checkout $head, $result->{Result},
2478         'convert-from-dgit-view';
2479 }
2480
2481 sub cmd_downstream_rebase_launder_v0 () {
2482     badusage "needs 1 argument, the baseline" unless @ARGV==1;
2483     my ($base) = @ARGV;
2484     $base = git_rev_parse $base;
2485     my $old_head = get_head();
2486     my $current = $old_head;
2487     my $topmost_keep;
2488     for (;;) {
2489         if ($current eq $base) {
2490             $topmost_keep //= $current;
2491             print " $current BASE stop\n";
2492             last;
2493         }
2494         my $cl = classify $current;
2495         print " $current $cl->{Type}";
2496         my $keep = 0;
2497         my $p0 = $cl->{Parents}[0]{CommitId};
2498         my $next;
2499         if ($cl->{Type} eq 'Pseudomerge') {
2500             print " ^".($cl->{Contributor}{Ix}+1);
2501             $next = $cl->{Contributor}{CommitId};
2502         } elsif ($cl->{Type} eq 'AddPatches' or
2503                  $cl->{Type} eq 'Changelog') {
2504             print " strip";
2505             $next = $p0;
2506         } else {
2507             print " keep";
2508             $next = $p0;
2509             $keep = 1;
2510         }
2511         print "\n";
2512         if ($keep) {
2513             $topmost_keep //= $current;
2514         } else {
2515             die "to-be stripped changes not on top of the branch\n"
2516                 if $topmost_keep;
2517         }
2518         $current = $next;
2519     }
2520     if ($topmost_keep eq $old_head) {
2521         print "unchanged\n";
2522     } else {
2523         print "updating to $topmost_keep\n";
2524         update_head_checkout
2525             $old_head, $topmost_keep,
2526             'downstream-rebase-launder-v0';
2527     }
2528 }
2529
2530 getoptions_main
2531           ("bad options\n",
2532            "D+" => \$debuglevel,
2533            'noop-ok', => \$opt_noop_ok,
2534            'f=s' => \@snag_force_opts,
2535            'anchor=s' => \@opt_anchors,
2536            '--dgit=s' => \($dgit[0]),
2537            'force!',
2538            '-i:s' => sub {
2539                my ($opt,$val) = @_;
2540                badusage "git-debrebase: no cuddling to -i for git-rebase"
2541                    if length $val;
2542                die if $opt_defaultcmd_interactive; # should not happen
2543                $opt_defaultcmd_interactive = [ qw(-i) ];
2544                # This access to @ARGV is excessive familiarity with
2545                # Getopt::Long, but there isn't another sensible
2546                # approach.  '-i=s{0,}' does not work with bundling.
2547                push @$opt_defaultcmd_interactive, @ARGV;
2548                @ARGV=();
2549            },
2550            'help' => sub { print $usage_message or die $!; finish 0; },
2551            );
2552
2553 initdebug('git-debrebase ');
2554 enabledebug if $debuglevel;
2555
2556 my $toplevel = cmdoutput @git, qw(rev-parse --show-toplevel);
2557 chdir $toplevel or die "chdir $toplevel: $!";
2558
2559 $rd = fresh_playground "$playprefix/misc";
2560
2561 @opt_anchors = map { git_rev_parse $_ } @opt_anchors;
2562
2563 if (!@ARGV || $opt_defaultcmd_interactive || $ARGV[0] =~ m{^-}) {
2564     defaultcmd_rebase();
2565 } else {
2566     my $cmd = shift @ARGV;
2567     my $cmdfn = $cmd;
2568     $cmdfn =~ y/-/_/;
2569     $cmdfn = ${*::}{"cmd_$cmdfn"};
2570
2571     $cmdfn or badusage "unknown git-debrebase sub-operation $cmd";
2572     $cmdfn->();
2573 }
2574
2575 finish 0;