git-debrebase

   1 #!/usr/bin/perl -w
   2 # git-debrebase
   3 # Script helping make fast-forwarding histories while still rebasing
   4 # upstream deltas when working on Debian packaging
   5 #
   6 # Copyright (C)2017 Ian Jackson
   7 #
   8 # This program is free software: you can redistribute it and/or modify
   9 # it under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation, either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # This program is distributed in the hope that it will be useful,
  14 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20
  21 # usages:
  22 #    git-debrebase status
  23 #    git-debrebase start       # like ffqrebase start + debrebase launder
  24 #    git-debrebase new-upstream [stuff]  # see below
  25 #    git-debrebase <git-rebase options>  # does debrebase start if necessary
  26 #
  27 #    git-debrebase analyse
  28 #    git-debrebase launder     # prints breakwater tip
  29 #    git-debrebase create-new-upstream-breakwater [-f] <upstreaminfo>...
  30 #
  31 # <upstreaminfo> is
  32 #    [,][<subdir>:][+]<commitid>[,...]
  33 #
  34 # if initial comma is supplied, entries are not positional.  Unspecified
  35 # <subdir> means root (and there may be only one).
  36 # xxx want auto branch names
  37 # xxx too complicated
  38 # how about for now
  39 #    [+]<commit> [<subdir/> [+]<commit>...]
  40 # ?  plus options
  41 #     --new-upstream-different-subtrees
  42 #
  43 #  automatic case
  44 #       git-debrebase new-upstream
  45 #             - previous breakwater merge must be gdr-generated
  46 #             - orig set is the same as before
  47 #             - implicitly uses upstream branches according to orig set
  48 #             - not all upstream branches need be updated
  49 #             - insists on fast-forward of each branch, unless
  50 #                  --force (or --force=<subdir>[/])
  51 #  branch set adjustments
  52 #       git-debrebase new-upstream --add <subdir>/
  53 #       git-debrebase new-upstream --rm <subdir>/
  54 #       git-debrebase new-upstream / [<subdir>/ ...]
  55 #             - orig set is adjusted
  56 #             - otherwise like auto (--add is not checked for ffness, obv)
  57 #             - multiple --add and --rm may be specified
  58 #             - --add makes new upstream the last contributor
  59 #  explicit
  60 #       git-debrebase / [<rootcommitid>] [<subdir>/ [<commitid>] ...]
  61 #             - orig set is precisely as specified now
  62 #             - previous breakwater merge is irrelevant
  63 #             - no fast forward checks
  64 #  for now only explicit with commitids
  65
  66 #         implicitly uses `upstream'
  67 #                                     # (or multiple other branches)
  68 #       git-debrebase new-upstream \
  69 #             [<subdir>/]=<commitid>
  70
  71 #    UPSTREAM[,[[SUBDIR:]SUBUPSTREAM]
  72 #    default for SUBDIR: is from previous upstream merge[xxx terminology]
  73 #
  74 #
  75 #xxx
  76 # when starting must record original start (for ff)
  77 # and new rebase basis
  78 #
  79 #    git-ffqrebase start [BASE]
  80 #                # records previous HEAD so it can be overwritten
  81 #                # records base for future git-ffqrebase
  82 #    git-ffqrebase set-base BASE
  83 #    git-ffqrebase <git-rebase options>
  84 #    git-ffqrebase finish
  85 #    git-ffqrebase status [BRANCH]
  86 #
  87 #  refs/ffqrebase-prev/BRANCH    BRANCH may be refs/...; if not it means
  88 #  refs/ffqrebase-base/BRANCH      refs/heads/BRANCH
  89 #                               zero, one, or both of these may exist
  90 #
  91 # git-debrebase without start, if already started, is willing
  92 # to strip pseudomerges provided that they overwrite exactly
  93 # the previous HEAD
  94 #  xxxx is this right ?  what matters is have we pushed
  95 #    I think in fact the right answer is:
  96 #       git-debrebase always strips out pseudomerges from its branch
  97 #       a pseudomerge is put in at the time we want to push
  98 #       at that time, we make a pseudomerge of the remote tracking
  99 #           branch (if raw git) or the dgit view (if dgit)
 100 #       for raw git git-ffqrebase, do want preciseley to record
 101 #           value of remote tracking branch or our branch, on start, so we
 102 #           overwrite only things we intend to
 103 #  the previous pseudomerge    check for tags and remote branches ?
 104
 105 use strict;
 106
 107 use Debian::Dgit qw(:DEFAULT :playground);
 108 setup_sigwarn();
 109
 110 use Memoize;
 111 use Carp;
 112 use POSIX;
 113 use Data::Dumper;
 114 use Getopt::Long qw(:config posix_default gnu_compat bundling);
 115
 116 sub badusage ($) {
 117     my ($m) = @_;
 118     die "bad usage: $m\n";
 119 }
 120
 121 sub cfg ($) {
 122     my ($k) = @_;
 123     $/ = "\0";
 124     my @cmd = qw(git config -z);
 125     push @cmd, qw(--get-all) if wantarray;
 126     push @cmd, $k;
 127     my $out = cmdoutput @cmd;
 128     return split /\0/, $out;
 129 }
 130
 131 memoize('cfg');
 132
 133 sub get_commit ($) {
 134     my ($objid) = @_;
 135     my $data = git_cat_file $objid, 'commit';
 136     $data =~ m/(?<=\n)\n/ or die "$objid ($data) ?";
 137     return ($`,$');
 138 }
 139
 140 sub D_UPS ()      { 0x02; } # upstream files
 141 sub D_PAT_ADD ()  { 0x04; } # debian/patches/ extra patches at end
 142 sub D_PAT_OTH ()  { 0x08; } # debian/patches other changes
 143 sub D_DEB_CLOG () { 0x10; } # debian/ (not patches/ or changelog)
 144 sub D_DEB_OTH ()  { 0x20; } # debian/changelog
 145 sub DS_DEB ()     { D_DEB_CLOG | D_DEB_OTH; } # debian/ (not patches/)
 146
 147 our $playprefix = 'debrebase';
 148 our $rd;
 149 our $workarea;
 150
 151 our @git = qw(git);
 152
 153 sub in_workarea ($) {
 154     my ($sub) = @_;
 155     changedir $workarea;
 156     my $r = eval { $sub->(); };
 157     { local $@; changedir $maindir; }
 158     die $@ if $@;
 159 }
 160
 161 sub fresh_workarea () {
 162     $workarea = fresh_playground "$playprefix/work";
 163     in_workarea sub { playtree_setup };
 164 }
 165
 166 sub get_differs ($$) {
 167     my ($x,$y) = @_;
 168     # This resembles quiltify_trees_differ, in dgit, a bit.
 169     # But we don't care about modes, or dpkg-source-unrepresentable
 170     # changes, and we don't need the plethora of different modes.
 171     # Conversely we need to distinguish different kinds of changes to
 172     # debian/ and debian/patches/.
 173
 174     my $differs = 0;
 175
 176     my $rundiff = sub {
 177         my ($opts, $limits, $fn) = @_;
 178         my @cmd = (@git, qw(diff-tree -z --no-renames));
 179         push @cmd, @$opts;
 180         push @cmd, "$_:" foreach $x, $y;
 181         push @cmd, @$limits;
 182         my $diffs = cmdoutput @cmd;
 183         foreach (split /\0/, $diffs) { $fn->(); }
 184     };
 185
 186     $rundiff->([qw(--name-only)], [], sub {
 187         $differs |= $_ eq 'debian' ? DS_DEB : D_UPS;
 188     });
 189
 190     if ($differs & DS_DEB) {
 191         $differs &= ~DS_DEB;
 192         $rundiff->([qw(--name-only -r)], [qw(debian)], sub {
 193             $differs |=
 194                 m{^debian/patches/}      ? D_PAT_OTH  :
 195                 $_ eq 'debian/changelog' ? D_DEB_CLOG :
 196                                            D_DEB_OTH;
 197         });
 198         die "mysterious debian changes $x..$y"
 199             unless $differs & (D_PAT_OTH|DS_DEB);
 200     }
 201
 202     if ($differs & D_PAT_OTH) {
 203         my $mode;
 204         $differs &= ~D_PAT_OTH;
 205         my $pat_oth = sub {
 206             $differs |= D_PAT_OTH;
 207             no warnings qw(exiting);  last;
 208         };
 209         $rundiff->([qw(--name-status -r)], [qw(debian/patches/)], sub {
 210             no warnings qw(exiting);
 211             if (!defined $mode) {
 212                 $mode = $_;  next;
 213             }
 214             die unless s{^debian/patches/}{};
 215             my $ok;
 216             if ($mode eq 'A' && !m/\.series$/s) {
 217                 $ok = 1;
 218             } elsif ($mode eq 'M' && $_ eq 'series') {
 219                 my $x_s = git_cat_file "$x:debian/patches/series", 'blob';
 220                 my $y_s = git_cat_file "$y:debian/patches/series", 'blob';
 221                 chomp $x_s;  $x_s .= "\n";
 222                 $ok = $x_s eq substr($y_s, 0, length $x_s);
 223             } else {
 224                 # nope
 225             }
 226             $mode = undef;
 227             $differs |= $ok ? D_PAT_ADD : D_PAT_OTH;
 228         });
 229         die "mysterious debian/patches changes $x..$y"
 230             unless $differs & (D_PAT_ADD|D_PAT_OTH);
 231     }
 232
 233     printdebug sprintf "get_differs %s, %s = %#x\n", $x, $y, $differs;
 234
 235     return $differs;
 236 }
 237
 238 sub commit_pr_info ($) {
 239     my ($r) = @_;
 240     return Data::Dumper->dump([$r], [qw(commit)]);
 241 }
 242
 243 sub calculate_committer_authline () {
 244     my $c = cmdoutput @git, qw(commit-tree --no-gpg-sign -m),
 245         'DUMMY COMMIT (git-debrebase)', "HEAD:";
 246     my ($h,$m) = get_commit $c;
 247     $h =~ m/^committer .*$/m or confess "($h) ?";
 248     return $&;
 249 }
 250
 251 # classify returns an info hash like this
 252 #   CommitId => $objid
 253 #   Hdr => # commit headers, including 1 final newline
 254 #   Msg => # commit message (so one newline is dropped)
 255 #   Tree => $treeobjid
 256 #   Type => (see below)
 257 #   Parents = [ {
 258 #       Ix => $index # ie 0, 1, 2, ...
 259 #       CommitId
 260 #       Differs => return value from get_differs
 261 #       IsOrigin
 262 #       IsDggitImport => 'orig' 'tarball' 'unpatched' 'package' (as from dgit)
 263 #     } ...]
 264 #   NewMsg => # commit message, but with any [dgit import ...] edited
 265 #             # to say "[was: ...]"
 266 #
 267 # Types:
 268 #   Packaging
 269 #   Changelog
 270 #   Upstream
 271 #   AddPatches
 272 #   Mixed
 273 #   Unknown
 274 #
 275 #   Pseudomerge
 276 #     has additional entres in classification result
 277 #       Overwritten = [ subset of Parents ]
 278 #       Contributor = $the_remaining_Parent
 279 #
 280 #   DgitImportUnpatched
 281 #     has additional entry in classification result
 282 #       OrigParents = [ subset of Parents ]
 283 #
 284 #   BreakwaterUpstreamMerge
 285 #     has additional entry in classification result
 286 #       OrigParents = [ subset of Parents ]
 287
 288 sub classify ($) {
 289     my ($objid) = @_;
 290
 291     my ($h,$m) = get_commit $objid;
 292
 293     my ($t) = $h =~ m/^tree (\w+)$/m or die $objid;
 294     my (@ph) = $h =~ m/^parent (\w+)$/mg;
 295     my @p;
 296
 297     my $r = {
 298         CommitId => $objid,
 299         Hdr => $h,
 300         Msg => $m,
 301         Tree => $t,
 302         Parents => \@p,
 303     };
 304
 305     foreach my $ph (@ph) {
 306         push @p, {
 307             Ix => $#p,
 308             CommitId => $ph,
 309             Differs => (get_differs $ph, $t),
 310         };
 311     }
 312
 313     printdebug "classify $objid \$t=$t \@p",
 314         (map { sprintf " %s/%#x", $_->{CommitId}, $_->{Differs} } @p),
 315         "\n";
 316
 317     my $classify = sub {
 318         my ($type, @rest) = @_;
 319         $r = { %$r, Type => $type, @rest };
 320         if ($debuglevel) {
 321             my $dd = new Data::Dumper [ $r ];
 322             Terse $dd 1; Indent $dd 0; Useqq $dd 1;
 323             printdebug " = $type ".(Dump $dd)."\n";
 324         }
 325         return $r;
 326     };
 327     my $unknown = sub {
 328         my ($why) = @_;
 329         $r = { %$r, Type => qw(Unknown) };
 330         printdebug " ** Unknown\n";
 331         return $r;
 332     };
 333
 334     if (@p == 1) {
 335         my $d = $r->{Parents}[0]{Differs};
 336         if ($d == D_PAT_ADD) {
 337             return $classify->(qw(AddPatches));
 338         } elsif ($d & (D_PAT_ADD|D_PAT_OTH)) {
 339             return $unknown->("edits debian/patches");
 340         } elsif ($d & DS_DEB and !($d & ~DS_DEB)) {
 341             my ($ty,$dummy) = git_cat_file "$ph[0]:debian";
 342             if ($ty eq 'tree') {
 343                 if ($d == D_DEB_CLOG) {
 344                     return $classify->(qw(Changelog));
 345                 } else {
 346                     return $classify->(qw(Packaging));
 347                 }
 348             } elsif ($ty eq 'missing') {
 349                 return $classify->(qw(BreakwaterStart));
 350             } else {
 351                 return $unknown->("parent's debian is not a directory");
 352             }
 353         } elsif ($d == D_UPS) {
 354             return $classify->(qw(Upstream));
 355         } elsif ($d & DS_DEB and $d & D_UPS and !($d & ~(DS_DEB|D_UPS))) {
 356             return $classify->(qw(Mixed));
 357         } elsif ($d == 0) {
 358             return $unknown->("no changes");
 359         } else {
 360             confess "internal error $objid ?";
 361         }
 362     }
 363     if (!@p) {
 364         return $unknown->("origin commit");
 365     }
 366
 367     my @identical = grep { !$_->{Differs} } @p;
 368     if (@p == 2 && @identical == 1) {
 369         my @overwritten = grep { $_->{Differs} } @p;
 370         confess "internal error $objid ?" unless @overwritten==1;
 371         return $classify->(qw(Pseudomerge),
 372                            Overwritten => $overwritten[0],
 373                            Contributor => $identical[0]);
 374     }
 375     if (@p == 2 && @identical == 2) {
 376         my @bytime = nsort_by {
 377             my ($ph,$pm) = get_commit $_->{CommitId};
 378             $ph =~ m/^committer .* (\d+) [-+]\d+$/m or die "$_->{CommitId} ?";
 379             $1;
 380         } @p;
 381         return $classify->(qw(Pseudomerge),
 382                            SubType => qw(Ambiguous),
 383                            Overwritten => $bytime[0],
 384                            Contributor => $bytime[1]);
 385     }
 386     foreach my $p (@p) {
 387         my ($p_h, $p_m) = get_commit $p->{CommitId};
 388         $p->{IsOrigin} = $p_h !~ m/^parent \w+$/m;
 389         ($p->{IsDgitImport},) = $p_m =~ m/^\[dgit import ([0-9a-z]+) .*\]$/m;
 390     }
 391     my @orig_ps = grep { ($_->{IsDgitImport}//'X') eq 'orig' } @p;
 392     my $m2 = $m;
 393     if (!(grep { !$_->{IsOrigin} } @p) and
 394         (@orig_ps >= @p - 1) and
 395         $m2 =~ s{^\[(dgit import unpatched .*)\]$}{[was: $1]}m) {
 396         $r->{NewMsg} = $m2;
 397         return $classify->(qw(DgitImportUnpatched),
 398                            OrigParents => \@orig_ps);
 399     }
 400
 401     my ($stype, $series) = git_cat_file "$t:debian/patches/series";
 402     my $haspatches = $stype ne 'missing' && $series =~ m/^\s*[^#\n\t ]/m;
 403
 404     # How to decide about l/r ordering of breakwater merges ?  git
 405     # --topo-order prefers to expand 2nd parent first.  There's
 406     # already an easy rune to look for debian/ history anyway (git log
 407     # debian/) so debian breakwater branch should be 1st parent; that
 408     # way also there's also an easy rune to look for the upstream
 409     # patches (--topo-order).
 410
 411     # The above tells us which way *we* will generate them.  But we
 412     # might encounter ad-hoc breakwater merges generated manually,
 413     # which might be the other way around.  In principle, in some odd
 414     # situations, a breakwater merge might have two identical parents.
 415     # In that case we guess which way round it is (ie, which parent
 416     # has the upstream history).  The order of the 2-iteration loop
 417     # controls which guess we make.
 418
 419     foreach my $prevbrw (qw(0 1)) {
 420         if (@p == 2 &&
 421             !$haspatches &&
 422             !$p[$prevbrw]{IsOrigin} && # breakwater never starts with an origin
 423             !($p[$prevbrw]{Differs} & ~DS_DEB) &&
 424             !($p[!$prevbrw]{Differs} & ~D_UPS)) {
 425             return $classify->(qw(BreakwaterUpstreamMerge),
 426                                OrigParents => [ $p[!$prevbrw] ]);
 427         }
 428         # xxx multi-.orig upstreams
 429     }
 430
 431     return $unknown->("complex merge");
 432 }
 433
 434 sub walk ($;$$);
 435 sub walk ($;$$) {
 436     my ($input,
 437         $nogenerate,$report) = @_;
 438     # => ($tip, $breakwater_tip)
 439     # (or nothing, if $nogenerate)
 440
 441     # go through commits backwards
 442     # we generate two lists of commits to apply:
 443     # breakwater branch and upstream patches
 444     my (@brw_cl, @upp_cl, @processed);
 445     my %found;
 446     my $upp_limit;
 447     my @pseudomerges;
 448
 449     my $cl;
 450     my $xmsg = sub {
 451         my ($appendinfo) = @_;
 452         my $ms = $cl->{Msg};
 453         chomp $ms;
 454         $ms .= "\n\n[git-debrebase $appendinfo]\n";
 455         return (Msg => $ms);
 456     };
 457     my $rewrite_from_here = sub {
 458         my $sp_cl = { SpecialMethod => 'StartRewrite' };
 459         push @brw_cl, $sp_cl;
 460         push @processed, $sp_cl;
 461     };
 462     my $cur = $input;
 463
 464     my $prdelim = "";
 465     my $prprdelim = sub { print $report $prdelim if $report; $prdelim=""; };
 466
 467     my $prline = sub {
 468         return unless $report;
 469         print $report $prdelim, @_;
 470         $prdelim = "\n";
 471     };
 472
 473     my $bomb = sub { # usage: return $bomb->();
 474         print $report " Unprocessable" if $report;
 475         $prprdelim->();
 476         if ($nogenerate) {
 477             return (undef,undef);
 478         }
 479         die "commit $cur: Cannot cope with this commit (d.".
 480             (join ' ', map { sprintf "%#x", $_->{Differs} }
 481              @{ $cl->{Parents} }). ")";
 482     };
 483
 484     my $build;
 485     my $breakwater;
 486
 487     my $build_start = sub {
 488         my ($msg, $parent) = @_;
 489         $prline->(" $msg");
 490         $build = $parent;
 491         no warnings qw(exiting); last;
 492     };
 493
 494     for (;;) {
 495         $cl = classify $cur;
 496         my $ty = $cl->{Type};
 497         my $st = $cl->{SubType};
 498         $prline->("$cl->{CommitId} $cl->{Type}");
 499         $found{$ty. ( defined($st) ? "-$st" : '' )}++;
 500         push @processed, $cl;
 501         my $p0 = @{ $cl->{Parents} }==1 ? $cl->{Parents}[0]{CommitId} : undef;
 502         if ($ty eq 'AddPatches') {
 503             $cur = $p0;
 504             $rewrite_from_here->();
 505             next;
 506         } elsif ($ty eq 'Packaging' or $ty eq 'Changelog') {
 507             push @brw_cl, $cl;
 508             $cur = $p0;
 509             next;
 510         } elsif ($ty eq 'BreakwaterStart') {
 511             $build_start->('FirstPackaging', $cur);
 512         } elsif ($ty eq 'Upstream') {
 513             push @upp_cl, $cl;
 514             $cur = $p0;
 515             next;
 516         } elsif ($ty eq 'Mixed') {
 517             my $queue = sub {
 518                 my ($q, $wh) = @_;
 519                 my $cls = { %$cl, $xmsg->("split mixed commit: $wh part") };
 520                 push @$q, $cls;
 521             };
 522             $queue->(\@brw_cl, "debian");
 523             $queue->(\@upp_cl, "upstream");
 524             $rewrite_from_here->();
 525             $cur = $p0;
 526             next;
 527         } elsif ($ty eq 'Pseudomerge') {
 528             my $contrib = $cl->{Contributor}{CommitId};
 529             print $report " Contributor=$contrib" if $report;
 530             push @pseudomerges, $cl;
 531             $rewrite_from_here->();
 532             $cur = $contrib;
 533             next;
 534         } elsif ($ty eq 'BreakwaterUpstreamMerge') {
 535             $build_start->("PreviousBreakwater", $cur);
 536         } elsif ($ty eq 'DgitImportUnpatched') {
 537             my $pm = $pseudomerges[-1];
 538             if (defined $pm) {
 539                 # To an extent, this is heuristic.  Imports don't have
 540                 # a useful history of the debian/ branch.  We assume
 541                 # that the first pseudomerge after an import has a
 542                 # useful history of debian/, and ignore the histories
 543                 # from later pseudomerges.  Often the first pseudomerge
 544                 # will be the dgit import of the upload to the actual
 545                 # suite intended by the non-dgit NMUer, and later
 546                 # pseudomerges may represent in-archive copies.
 547                 my $ovwrs = $pm->{Overwritten};
 548                 printf $report " PM=%s \@Overwr:%d", $pm, (scalar @$ovwrs)
 549                     if $report;
 550                 if (@$ovwrs != 1) {
 551                     return $bomb->();
 552                 }
 553                 my $ovwr = $ovwrs->[0]{CommitId};
 554                 printf $report " Overwr=%s", $ovwr if $report;
 555                 # This import has a tree which is just like a
 556                 # breakwater tree, but it has the wrong history.  It
 557                 # ought to have the previous breakwater (which the
 558                 # pseudomerge overwrote) as an ancestor.  That will
 559                 # make the history of the debian/ files correct.  As
 560                 # for the upstream version: either it's the same as
 561                 # was ovewritten (ie, same as the previous
 562                 # breakwater), in which case that history is precisely
 563                 # right; or, otherwise, it was a non-gitish upload of a
 564                 # new upstream version.  We can tell these apart by
 565                 # looking at the tree of the supposed upstream.
 566                 push @brw_cl, {
 567                     %$cl,
 568                     SpecialMethod => 'DgitImportDebianUpdate',
 569                     $xmsg->("convert dgit import: debian changes")
 570                 };
 571                 my $differs = (get_differs $ovwr, $cl->{Tree});
 572                 printf $report " Differs=%#x", $differs if $report;
 573                 if ($differs & D_UPS) {
 574                     printf $report " D_UPS" if $report;
 575                     # This will also trigger if a non-dgit git-based NMU
 576                     # deleted .gitignore (which is a thing that some of
 577                     # the existing git tools do if the user doesn't
 578                     # somehow tell them not to).  Ah well.
 579                     push @brw_cl, {
 580                         %$cl,
 581                         SpecialMethod => 'DgitImportUpstreamUpdate',
 582                         $xmsg->("convert dgit import: upstream changes")
 583                     };
 584                 }
 585                 $prline->(" Import");
 586                 $rewrite_from_here->();
 587                 $upp_limit //= $#upp_cl; # further, deeper, patches discarded
 588                 $cur = $ovwr;
 589                 next;
 590             } else {
 591                 # Everything is from this import.  This kind of import
 592                 # is already in valid breakwater format, with the
 593                 # patches as commits.
 594                 printf $report " NoPM" if $report;
 595                 # last thing we processed will have been the first patch,
 596                 # if there is one; which is fine, so no need to rewrite
 597                 # on account of this import
 598                 $build_start->("ImportOrigin", $cur);
 599             }
 600             die "$ty ?";
 601         } else {
 602             return $bomb->();
 603         }
 604     }
 605     $prprdelim->();
 606     return if $nogenerate;
 607
 608     # Now we build it back up again
 609
 610     fresh_workarea();
 611
 612     my $rewriting = 0;
 613
 614     my $rm_tree_cached = sub {
 615         my ($subdir) = @_;
 616         runcmd @git, qw(rm --quiet -rf --cached --ignore-unmatch), $subdir;
 617     };
 618     my $read_tree_debian = sub {
 619         my ($treeish) = @_;
 620         $rm_tree_cached->(qw(debian));
 621         runcmd @git, qw(read-tree --prefix=debian/), "$treeish:debian";
 622     };
 623     my $read_tree_upstream = sub {
 624         my ($treeish) = @_;
 625         runcmd @git, qw(read-tree), $treeish;
 626         $read_tree_debian->($build);
 627     };
 628
 629     my $committer_authline = calculate_committer_authline();
 630
 631     printdebug "WALK REBUILD $build ".(scalar @processed)."\n";
 632
 633     confess "internal error" unless $build eq (pop @processed)->{CommitId};
 634
 635     in_workarea sub {
 636         mkdir $rd or $!==EEXIST or die $!;
 637         my $current_method;
 638         runcmd @git, qw(read-tree), $build;
 639         foreach my $cl (qw(Debian), (reverse @brw_cl),
 640                         { SpecialMethod => 'RecordBreakwaterTip' },
 641                         qw(Upstream), (reverse @upp_cl)) {
 642             if (!ref $cl) {
 643                 $current_method = $cl;
 644                 next;
 645             }
 646             my $method = $cl->{SpecialMethod} // $current_method;
 647             my @parents = ($build);
 648             my $cltree = $cl->{CommitId};
 649             printdebug "WALK BUILD ".($cltree//'undef').
 650                 " $method (rewriting=$rewriting)\n";
 651             if ($method eq 'Debian') {
 652                 $read_tree_debian->($cltree);
 653             } elsif ($method eq 'Upstream') {
 654                 $read_tree_upstream->($cltree);
 655             } elsif ($method eq 'StartRewrite') {
 656                 $rewriting = 1;
 657                 next;
 658             } elsif ($method eq 'RecordBreakwaterTip') {
 659                 $breakwater = $build;
 660                 next;
 661             } elsif ($method eq 'DgitImportDebianUpdate') {
 662                 $read_tree_debian->($cltree);
 663                 $rm_tree_cached->(qw(debian/patches));
 664             } elsif ($method eq 'DgitImportUpstreamUpdate') {
 665                 $read_tree_upstream->($cltree);
 666                 push @parents, map { $_->{CommitId} } @{ $cl->{OrigParents} };
 667             } else {
 668                 confess "$method ?";
 669             }
 670             if (!$rewriting) {
 671                 my $procd = (pop @processed) // 'UNDEF';
 672                 if ($cl ne $procd) {
 673                     $rewriting = 1;
 674                     printdebug "WALK REWRITING NOW cl=$cl procd=$procd\n";
 675                 }
 676             }
 677             my $newtree = cmdoutput @git, qw(write-tree);
 678             my $ch = $cl->{Hdr};
 679             $ch =~ s{^tree .*}{tree $newtree}m or confess "$ch ?";
 680             $ch =~ s{^parent .*\n}{}m;
 681             $ch =~ s{(?=^author)}{
 682                 join '', map { "parent $_\n" } @parents
 683             }me or confess "$ch ?";
 684             if ($rewriting) {
 685                 $ch =~ s{^committer .*$}{$committer_authline}m
 686                     or confess "$ch ?";
 687             }
 688             my $cf = "$rd/m$rewriting";
 689             open CD, ">", $cf or die $!;
 690             print CD $ch, "\n", $cl->{Msg} or die $!;
 691             close CD or die $!;
 692             my @cmd = (@git, qw(hash-object));
 693             push @cmd, qw(-w) if $rewriting;
 694             push @cmd, qw(-t commit), $cf;
 695             my $newcommit = cmdoutput @cmd;
 696             confess "$ch ?" unless $rewriting or $newcommit eq $cl->{CommitId};
 697             $build = $newcommit;
 698         }
 699     };
 700
 701     my $final_check = get_differs $build, $input;
 702     die sprintf "internal error %#x %s %s", $final_check, $build, $input
 703         if $final_check & ~D_PAT_ADD;
 704
 705     return ($build, $breakwater);
 706 }
 707
 708 sub get_head () { return git_rev_parse qw(HEAD); }
 709
 710 sub update_head ($$$) {
 711     my ($old, $new, $mrest) = @_;
 712     runcmd @git, qw(update-ref -m), "debrebase: $mrest", 'HEAD', $new, $old;
 713 }
 714
 715 sub update_head_checkout ($$$) {
 716     my ($old, $new, $mrest) = @_;
 717     my $symref = git_get_symref();
 718     runcmd @git, qw(checkout), $new, qw(.);
 719     update_head $old, $new, $mrest;
 720 }
 721
 722 sub cmd_launder () {
 723     badusage "no arguments to launder allowed" if @ARGV;
 724     my $old = get_head();
 725     my ($tip,$breakwater) = walk $old;
 726     update_head $old, $tip, 'launder';
 727     # no tree changes except debian/patches
 728     runcmd @git, qw(rm --quiet --ignore-unmatch -rf debian/patches);
 729     printf "# breakwater tip\n%s\n", $breakwater;
 730     printf "# working tip\n%s\n", $tip;
 731 }
 732
 733 sub cmd_analyse () {
 734     die if ($ARGV[0]//'') =~ m/^-/;
 735     badusage "too many arguments to analyse" if @ARGV>1;
 736     my ($old) = @ARGV;
 737     if (defined $old) {
 738         $old = git_rev_parse $old;
 739     } else {
 740         $old = get_head();
 741     }
 742     my ($dummy,$breakwater) = walk $old, 1,*STDOUT;
 743     STDOUT->error and die $!;
 744 }
 745
 746 sub cmd_downstream_rebase_launder_v0 () {
 747     badusage "needs 1 argument, the baseline" unless @ARGV==1;
 748     my ($base) = @ARGV;
 749     $base = git_rev_parse $base;
 750     my $old_head = get_head();
 751     my $current = $old_head;
 752     my $topmost_keep;
 753     for (;;) {
 754         if ($current eq $base) {
 755             $topmost_keep //= $current;
 756             print " $current BASE stop\n";
 757             last;
 758         }
 759         my $cl = classify $current;
 760         print " $current $cl->{Type}";
 761         my $keep = 0;
 762         my $p0 = $cl->{Parents}[0]{CommitId};
 763         my $next;
 764         if ($cl->{Type} eq 'Pseudomerge') {
 765             print " ^".($cl->{Contributor}{Ix}+1);
 766             $next = $cl->{Contributor}{CommitId};
 767         } elsif ($cl->{Type} eq 'AddPatches' or
 768                  $cl->{Type} eq 'Changelog') {
 769             print " strip";
 770             $next = $p0;
 771         } else {
 772             print " keep";
 773             $next = $p0;
 774             $keep = 1;
 775         }
 776         print "\n";
 777         if ($keep) {
 778             $topmost_keep //= $current;
 779         } else {
 780             die "to-be stripped changes not on top of the branch\n"
 781                 if $topmost_keep;
 782         }
 783         $current = $next;
 784     }
 785     if ($topmost_keep eq $old_head) {
 786         print "unchanged\n";
 787     } else {
 788         print "updating to $topmost_keep\n";
 789         update_head_checkout
 790             $old_head, $topmost_keep,
 791             'downstream-rebase-launder-v0';
 792     }
 793 }
 794
 795 GetOptions("D+" => \$debuglevel) or die badusage "bad options\n";
 796 initdebug('git-debrebase ');
 797 enabledebug if $debuglevel;
 798
 799 my $toplevel = cmdoutput @git, qw(rev-parse --show-toplevel);
 800 chdir $toplevel or die "chdir $toplevel: $!";
 801
 802 $rd = fresh_playground "$playprefix/misc";
 803
 804 my $cmd = shift @ARGV;
 805 my $cmdfn = $cmd;
 806 $cmdfn =~ y/-/_/;
 807 $cmdfn = ${*::}{"cmd_$cmdfn"};
 808
 809 $cmdfn or badusage "unknown git-debrebase sub-operation $cmd";
 810 $cmdfn->();