git-debrebase

   1 #!/usr/bin/perl -w
   2 # git-debrebase
   3 # Script helping make fast-forwarding histories while still rebasing
   4 # upstream deltas when working on Debian packaging
   5 #
   6 # Copyright (C)2017,2018 Ian Jackson
   7 #
   8 # This program is free software: you can redistribute it and/or modify
   9 # it under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation, either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # This program is distributed in the hope that it will be useful,
  14 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20
  21 END { $? = $Debian::Dgit::ExitStatus::desired // -1; };
  22 use Debian::Dgit::GDR;
  23 use Debian::Dgit::ExitStatus;
  24
  25 use strict;
  26
  27 use Debian::Dgit qw(:DEFAULT :playground);
  28 setup_sigwarn();
  29
  30 use Memoize;
  31 use Carp;
  32 use POSIX;
  33 use Data::Dumper;
  34 use Getopt::Long qw(:config posix_default gnu_compat bundling);
  35 use Dpkg::Version;
  36 use File::FnMatch qw(:fnmatch);
  37 use File::Copy;
  38
  39 $debugcmd_when_debuglevel = 2;
  40
  41 our ($usage_message) = <<'END';
  42 usages:
  43   git-debrebase [<options>] [--|-i <git rebase options...>]
  44   git-debrebase [<options>] status
  45   git-debrebase [<options>] prepush [--prose=...]
  46   git-debrebase [<options>] quick|conclude
  47   git-debrebase [<options>] new-upstream <new-version> [<details ...>]
  48   git-debrebase [<options>] convert-from-gbp [<upstream-commitish>]
  49   ...
  50 See git-debrebase(1), git-debrebase(5), dgit-maint-debrebase(7) (in dgit).
  51 END
  52
  53 our ($opt_force, $opt_noop_ok, @opt_anchors);
  54 our ($opt_defaultcmd_interactive);
  55
  56 our $us = qw(git-debrebase);
  57
  58 our $wrecknoteprefix = 'refs/debrebase-wreckage';
  59
  60 $|=1;
  61
  62 sub badusage ($) {
  63     my ($m) = @_;
  64     print STDERR "$us: bad usage: $m\n";
  65     finish 8;
  66 }
  67
  68 sub getoptions_main {
  69     my $m = shift;
  70     local $SIG{__WARN__}; # GetOptions calls `warn' to print messages
  71     GetOptions @_ or badusage $m;
  72 }
  73 sub getoptions {
  74     my $sc = shift;
  75     getoptions_main "bad options follow \`git-debrebase $sc'", @_;
  76 }
  77
  78 sub cfg ($;$) {
  79     my ($k, $optional) = @_;
  80     local $/ = "\0";
  81     my @cmd = qw(git config -z);
  82     push @cmd, qw(--get-all) if wantarray;
  83     push @cmd, $k;
  84     my $out = cmdoutput_errok @cmd;
  85     if (!defined $out) {
  86         fail "missing required git config $k" unless $optional;
  87         return ();
  88     }
  89     my @l = split /\0/, $out;
  90     return wantarray ? @l : $l[0];
  91 }
  92
  93 memoize('cfg');
  94
  95 sub dd ($) {
  96     my ($v) = @_;
  97     my $dd = new Data::Dumper [ $v ];
  98     Terse $dd 1; Indent $dd 0; Useqq $dd 1;
  99     return Dump $dd;
 100 }
 101
 102 sub get_commit ($) {
 103     my ($objid) = @_;
 104     my $data = (git_cat_file $objid, 'commit');
 105     $data =~ m/(?<=\n)\n/ or die "$objid ($data) ?";
 106     return ($`,$');
 107 }
 108
 109 sub D_UPS ()      { 0x02; } # upstream files
 110 sub D_PAT_ADD ()  { 0x04; } # debian/patches/ extra patches at end
 111 sub D_PAT_OTH ()  { 0x08; } # debian/patches other changes
 112 sub D_DEB_CLOG () { 0x10; } # debian/ (not patches/ or changelog)
 113 sub D_DEB_OTH ()  { 0x20; } # debian/changelog
 114 sub DS_DEB ()     { D_DEB_CLOG | D_DEB_OTH; } # debian/ (not patches/)
 115
 116 our $playprefix = 'debrebase';
 117 our $rd;
 118 our $workarea;
 119
 120 our @git = qw(git);
 121 our @dgit = qw(dgit);
 122
 123 sub in_workarea ($) {
 124     my ($sub) = @_;
 125     changedir $workarea;
 126     my $r = eval { $sub->(); };
 127     { local $@; changedir $maindir; }
 128     die $@ if $@;
 129 }
 130
 131 sub fresh_workarea () {
 132     $workarea = fresh_playground "$playprefix/work";
 133     in_workarea sub { playtree_setup };
 134 }
 135
 136 sub run_ref_updates_now ($$) {
 137     my ($mrest, $updates) = @_;
 138     # @$updates is a list of lines for git-update-ref, without \ns
 139
 140     my @upd_cmd = (git_update_ref_cmd "debrebase: $mrest", qw(--stdin));
 141     debugcmd '>|', @upd_cmd;
 142     open U, "|-", @upd_cmd or die $!;
 143     foreach (@$updates) {
 144         printdebug ">= ", $_, "\n";
 145         print U $_, "\n" or die $!;
 146     }
 147     printdebug ">\$\n";
 148     close U or failedcmd @upd_cmd;
 149 }
 150
 151 our $snags_forced = 0;
 152 our $snags_tripped = 0;
 153 our $snags_summarised = 0;
 154 our @deferred_updates;
 155 our @deferred_update_messages;
 156
 157 sub merge_wreckage_cleaning ($) {
 158     my ($updates) = @_;
 159     git_for_each_ref("$wrecknoteprefix/*", sub {
 160         my ($objid,$objtype,$fullrefname,$reftail) = @_;
 161         push @$updates, "delete $fullrefname";
 162     });
 163 }
 164
 165 sub all_snags_summarised () {
 166     $snags_forced + $snags_tripped == $snags_summarised;
 167 }
 168 sub run_deferred_updates ($) {
 169     my ($mrest) = @_;
 170
 171     confess 'dangerous internal error' unless all_snags_summarised();
 172
 173     merge_wreckage_cleaning \@deferred_updates;
 174     run_ref_updates_now $mrest, \@deferred_updates;
 175     print $_, "\n" foreach @deferred_update_messages;
 176
 177     @deferred_updates = ();
 178     @deferred_update_messages = ();
 179 }
 180
 181 sub get_differs ($$) {
 182     my ($x,$y) = @_;
 183     # This resembles quiltify_trees_differ, in dgit, a bit.
 184     # But we don't care about modes, or dpkg-source-unrepresentable
 185     # changes, and we don't need the plethora of different modes.
 186     # Conversely we need to distinguish different kinds of changes to
 187     # debian/ and debian/patches/.
 188
 189     my $differs = 0;
 190
 191     my $rundiff = sub {
 192         my ($opts, $limits, $fn) = @_;
 193         my @cmd = (@git, qw(diff-tree -z --no-renames));
 194         push @cmd, @$opts;
 195         push @cmd, "$_:" foreach $x, $y;
 196         push @cmd, '--', @$limits;
 197         my $diffs = cmdoutput @cmd;
 198         foreach (split /\0/, $diffs) { $fn->(); }
 199     };
 200
 201     $rundiff->([qw(--name-only)], [], sub {
 202         $differs |= $_ eq 'debian' ? DS_DEB : D_UPS;
 203     });
 204
 205     if ($differs & DS_DEB) {
 206         $differs &= ~DS_DEB;
 207         $rundiff->([qw(--name-only -r)], [qw(debian)], sub {
 208             $differs |=
 209                 m{^debian/patches/}      ? D_PAT_OTH  :
 210                 $_ eq 'debian/changelog' ? D_DEB_CLOG :
 211                                            D_DEB_OTH;
 212         });
 213         die "mysterious debian changes $x..$y"
 214             unless $differs & (D_PAT_OTH|DS_DEB);
 215     }
 216
 217     if ($differs & D_PAT_OTH) {
 218         my $mode;
 219         $differs &= ~D_PAT_OTH;
 220         my $pat_oth = sub {
 221             $differs |= D_PAT_OTH;
 222             no warnings qw(exiting);  last;
 223         };
 224         $rundiff->([qw(--name-status -r)], [qw(debian/patches/)], sub {
 225             no warnings qw(exiting);
 226             if (!defined $mode) {
 227                 $mode = $_;  next;
 228             }
 229             die unless s{^debian/patches/}{};
 230             my $ok;
 231             if ($mode eq 'A' && !m/\.series$/s) {
 232                 $ok = 1;
 233             } elsif ($mode eq 'M' && $_ eq 'series') {
 234                 my $x_s = (git_cat_file "$x:debian/patches/series", 'blob');
 235                 my $y_s = (git_cat_file "$y:debian/patches/series", 'blob');
 236                 chomp $x_s;  $x_s .= "\n";
 237                 $ok = $x_s eq substr($y_s, 0, length $x_s);
 238             } else {
 239                 # nope
 240             }
 241             $mode = undef;
 242             $differs |= $ok ? D_PAT_ADD : D_PAT_OTH;
 243         });
 244         die "mysterious debian/patches changes $x..$y"
 245             unless $differs & (D_PAT_ADD|D_PAT_OTH);
 246     }
 247
 248     printdebug sprintf "get_differs %s %s = %#x\n", $x, $y, $differs;
 249
 250     return $differs;
 251 }
 252
 253 sub commit_pr_info ($) {
 254     my ($r) = @_;
 255     return Data::Dumper->dump([$r], [qw(commit)]);
 256 }
 257
 258 sub calculate_committer_authline () {
 259     my $c = cmdoutput @git, qw(commit-tree --no-gpg-sign -m),
 260         'DUMMY COMMIT (git-debrebase)', "HEAD:";
 261     my ($h,$m) = get_commit $c;
 262     $h =~ m/^committer .*$/m or confess "($h) ?";
 263     return $&;
 264 }
 265
 266 sub rm_subdir_cached ($) {
 267     my ($subdir) = @_;
 268     runcmd @git, qw(rm --quiet -rf --cached --ignore-unmatch), $subdir;
 269 }
 270
 271 sub read_tree_subdir ($$) {
 272     my ($subdir, $new_tree_object) = @_;
 273     rm_subdir_cached $subdir;
 274     runcmd @git, qw(read-tree), "--prefix=$subdir/", $new_tree_object;
 275 }
 276
 277 sub read_tree_debian ($) {
 278     my ($treeish) = @_;
 279     read_tree_subdir 'debian', "$treeish:debian";
 280     rm_subdir_cached 'debian/patches';
 281 }
 282
 283 sub read_tree_upstream ($;$$) {
 284     my ($treeish, $keep_patches, $tree_with_debian) = @_;
 285     # if $tree_with_debian is supplied, will use that for debian/
 286     # otherwise will save and restore it.
 287     my $debian =
 288         $tree_with_debian ? "$tree_with_debian:debian"
 289         : cmdoutput @git, qw(write-tree --prefix=debian/);
 290     runcmd @git, qw(read-tree), $treeish;
 291     read_tree_subdir 'debian', $debian;
 292     rm_subdir_cached 'debian/patches' unless $keep_patches;
 293 };
 294
 295 sub make_commit ($$) {
 296     my ($parents, $message_paras) = @_;
 297     my $tree = cmdoutput @git, qw(write-tree);
 298     my @cmd = (@git, qw(commit-tree), $tree);
 299     push @cmd, qw(-p), $_ foreach @$parents;
 300     push @cmd, qw(-m), $_ foreach @$message_paras;
 301     return cmdoutput @cmd;
 302 }
 303
 304 our @snag_force_opts;
 305 sub snag ($$;@) {
 306     my ($tag,$msg) = @_; # ignores extra args, for benefit of keycommits
 307     if (grep { $_ eq $tag } @snag_force_opts) {
 308         $snags_forced++;
 309         print STDERR "git-debrebase: snag ignored (-f$tag): $msg\n";
 310     } else {
 311         $snags_tripped++;
 312         print STDERR "git-debrebase: snag detected (-f$tag): $msg\n";
 313     }
 314 }
 315
 316 # Important: all mainline code must call snags_maybe_bail after
 317 # any point where snag might be called, but before making changes
 318 # (eg before any call to run_deferred_updates).  snags_maybe_bail
 319 # may be called more than once if necessary (but this is not ideal
 320 # because then the messages about number of snags may be confusing).
 321 sub snags_maybe_bail () {
 322     return if all_snags_summarised();
 323     if ($snags_forced) {
 324         printf STDERR
 325             "%s: snags: %d overriden by individual -f options\n",
 326             $us, $snags_forced;
 327     }
 328     if ($snags_tripped) {
 329         if ($opt_force) {
 330             printf STDERR
 331                 "%s: snags: %d overriden by global --force\n",
 332                 $us, $snags_tripped;
 333         } else {
 334             fail sprintf
 335   "%s: snags: %d blocker(s) (you could -f<tag>, or --force)",
 336                 $us, $snags_tripped;
 337         }
 338     }
 339     $snags_summarised = $snags_forced + $snags_tripped;
 340 }
 341 sub snags_maybe_bail_early () {
 342     # useful to bail out early without doing a lot of work;
 343     # not a substitute for snags_maybe_bail.
 344     snags_maybe_bail() if $snags_tripped && !$opt_force;
 345 }
 346 sub any_snags () {
 347     return $snags_forced || $snags_tripped;
 348 }
 349
 350 sub gbp_pq_export ($$$) {
 351     my ($bname, $base, $tip) = @_;
 352     # must be run in a workarea.  $bname and patch-queue/$bname
 353     # ought not to exist.  Leaves you on patch-queue/$bname with
 354     # the patches staged but not committed.
 355     printdebug "gbp_pq_export $bname $base $tip\n";
 356     runcmd @git, qw(checkout -q -b), $bname, $base;
 357     runcmd @git, qw(checkout -q -b), "patch-queue/$bname", $tip;
 358     my @gbp_cmd = (qw(gbp pq export));
 359     my $r = system shell_cmd 'exec >../gbp-pq-err 2>&1', @gbp_cmd;
 360     if ($r) {
 361         { local ($!,$?); copy('../gbp-pq-err', \*STDERR); }
 362         failedcmd @gbp_cmd;
 363     }
 364     runcmd @git, qw(add -f debian/patches) if stat_exists 'debian/patches';
 365 }
 366
 367
 368 # xxx allow merge resolution separately from laundering, before git merge
 369 #
 370 # xxx general gdr docs highlight forbidden things
 371 # xxx general gdr docs list allowable things ?
 372 # xxx general gdr docs explicitly forbid some rebase
 373 #
 374 # xxx provide a way for the user to help
 375 # xxx (eg, provide wreckage provide way to continue)
 376
 377 # later/rework?
 378 #  use git-format-patch?
 379 #  our own patch identification algorithm?
 380 #  this is an alternative strategy
 381
 382 sub merge_failed ($$) {
 383     my ($wrecknotes, $emsg) = @_;
 384     my @m;
 385     push @m, "Merge resolution failed: $emsg";
 386
 387     changedir $maindir;
 388
 389     my @updates;
 390     merge_wreckage_cleaning \@updates;
 391     keys %$wrecknotes;
 392     while (my ($k,$v) = each %$wrecknotes) {
 393         push @updates, "create $wrecknoteprefix/$k $v";
 394     }
 395     run_ref_updates_now "merge failed", \@updates;
 396     push @m, "Wreckage left in $wrecknoteprefix/*.";
 397
 398     push @m, "See git-debrebase(1) section FAILED MERGES for suggestions.";
 399
 400     # use finish rather than fail, in case we are within an eval
 401     # (that can happen inside walk!)
 402     print STDERR "\n";
 403     print STDERR "$us: $_\n" foreach @m;
 404     finish 15;
 405 }
 406
 407 sub mwrecknote ($$$) {
 408     my ($wrecknotes, $reftail, $commitish) = @_;
 409     confess unless defined $commitish;
 410     printdebug "mwrecknote $reftail $commitish\n";
 411     $wrecknotes->{$reftail} = $commitish;
 412 }
 413
 414 sub merge_series ($$$;@) {
 415     my ($newbase, $wrecknotes, $base_q, @input_qs) = @_;
 416     # $base_q{SeriesBase}  $input_qs[]{SeriesBase}
 417     # $base_q{SeriesTip}   $input_qs[]{SeriesTip}
 418     # ^ specifies several patch series (currently we only support exactly 2)
 419     # return value is a commit which is the result of
 420     # merging the two versions of the same topic branch
 421     #   $input_q[0] and $input_q[1]
 422     # with respect to the old version
 423     #   $base_q
 424     # all onto $newbase.
 425
 426     # Creates, in *_q, a key MR for its private use
 427
 428     printdebug "merge_series newbase=$newbase\n";
 429
 430     $input_qs[$_]{MR}{S} = $_ foreach (0..$#input_qs);
 431     $base_q->{MR}{S} = 'base';
 432
 433     my %prereq;
 434     # $prereq{<patch filename>}{<possible prereq}{<S>} = 1 or absent
 435     # $prereq{<patch filename>}{<possible prereq}  exists or not (later)
 436     # $prereq{<patch filename>}               exists or not (even later)
 437
 438     my $result;
 439
 440     my $mwrecknote = sub { &mwrecknote($wrecknotes, @_); };
 441
 442     my $attempt_cmd = sub {
 443         debugcmd '+', @_;
 444         $!=0; $?=-1;
 445         if (system @_) {
 446             failedcmd_report_cmd undef, @_;
 447             merge_failed $wrecknotes, failedcmd_waitstatus();
 448         }
 449     };
 450
 451     local $workarea = fresh_playground "$playprefix/merge";
 452     my $seriesfile = "debian/patches/series";
 453     in_workarea sub {
 454         playtree_setup();
 455         foreach my $q ($base_q, reverse @input_qs) {
 456             my $s = $q->{MR}{S};
 457             gbp_pq_export "p-$s", $q->{SeriesBase}, $q->{SeriesTip};
 458             my @earlier;
 459             if (open S, $seriesfile) {
 460                 while (my $patch = <S>) {
 461                     chomp $patch or die $!;
 462                     $prereq{$patch} //= {};
 463                     foreach my $earlier (@earlier) {
 464                         $prereq{$patch}{$earlier}{$s}++ and die;
 465                     }
 466                     push @earlier, $patch;
 467                     stat "debian/patches/$patch" or die "$patch ?";
 468                 }
 469                 S->error and die "$seriesfile $!";
 470                 close S;
 471             } else {
 472                 die "$seriesfile $!" unless $!==ENOENT;
 473             }
 474             read_tree_upstream $newbase, 1;
 475             my $pec = make_commit [ grep { defined } $base_q->{MR}{PEC} ], [
 476                 "Convert $s to patch queue for merging",
 477                 "[git-debrebase merge-innards patch-queue import:".
 478                 " $q->{SeriesTip}]"
 479             ];
 480             printdebug "merge_series  pec $pec ";
 481             runcmd @git, qw(rm -q --ignore-unmatch --cached), $seriesfile;
 482             $pec = make_commit [ $pec ], [
 483                 "Drop series file from $s to avoid merge trouble",
 484                 "[git-debrebase merge-innards patch-queue prep:".
 485                 " $q->{SeriesTip}]"
 486             ];
 487
 488             read_tree_debian $newbase;
 489             if (@earlier) {
 490                 read_tree_subdir 'debian/patches', "$pec:debian/patches";
 491             } else {
 492                 rm_subdir_cached 'debian/patches';
 493             }
 494             $pec = make_commit [ $pec ], [
 495  "Update debian/ (excluding patches) to final to avoid re-merging",
 496  "debian/ was already merged and we need to just take that.",
 497                 "[git-debrebase merge-innards patch-queue packaging:".
 498                 " $q->{SeriesTip}]"
 499             ];
 500
 501             printdebug "pec' $pec\n";
 502             runcmd @git, qw(reset -q --hard), $pec;
 503             $q->{MR}{PEC} = $pec;
 504             $mwrecknote->("$q->{LeftRight}-patchqueue", $pec);
 505         }
 506         # now, because of reverse, we are on $input_q->{MR}{OQC}
 507         runcmd @git, qw(checkout -q -b merge);
 508         printdebug "merge_series merging...\n";
 509         my @mergecmd = (@git, qw(merge --quiet --no-edit), "p-1");
 510
 511         $attempt_cmd->(@mergecmd);
 512
 513         printdebug "merge_series merge ok, series...\n";
 514         # We need to construct a new series file
 515         # Firstly, resolve prereq
 516         foreach my $f (sort keys %prereq) {
 517             printdebug "merge_series  patch\t$f\t";
 518             if (!stat_exists "debian/patches/$f") {
 519                 print DEBUG " drop\n" if $debuglevel;
 520                 # git merge deleted it; that's how we tell it's not wanted
 521                 delete $prereq{$f};
 522                 next;
 523             }
 524             print DEBUG " keep\n" if $debuglevel;
 525             foreach my $g (sort keys %{ $prereq{$f} }) {
 526                 my $gfp = $prereq{$f}{$g};
 527                 printdebug "merge_series  prereq\t$f\t-> $g\t";
 528                 if (!!$gfp->{0} == !!$gfp->{1}
 529                     ? $gfp->{0}
 530                     : !$gfp->{base}) {
 531                     print DEBUG "\tkeep\n" if $debuglevel;
 532                 } else {
 533                     print DEBUG "\tdrop\n" if $debuglevel;
 534                     delete $prereq{$f}{$g};
 535                 }
 536             }
 537         }
 538
 539         my $unsat = sub {
 540             my ($f) = @_;
 541             return scalar keys %{ $prereq{$f} };
 542         };
 543
 544         my $nodate = time + 1;
 545         my %authordate;
 546         # $authordate{<patch filename>};
 547         my $authordate = sub {
 548             my ($f) = @_;
 549             $authordate{$f} //= do {
 550                 open PF, "<", "debian/patches/$f" or die "$f $!";
 551                 while (<PF>) {
 552                     return $nodate if m/^$/;
 553                     last if s{^Date: }{};
 554                 }
 555                 chomp;
 556                 return cmdoutput qw(date +%s -d), $_;
 557             };
 558         };
 559
 560         open NS, '>', $seriesfile or die $!;
 561
 562         while (keys %prereq) {
 563             my $best;
 564             foreach my $try (sort keys %prereq) {
 565                 if ($best) {
 566                     next if (
 567                              $unsat->($try) <=> $unsat->($best) or
 568                              $authordate->($try) <=> $authordate->($best) or
 569                              $try cmp $best
 570                             ) >= 0;
 571                 }
 572                 $best = $try;
 573             }
 574             printdebug "merge_series series next $best\n";
 575             print NS "$best\n" or die $!;
 576             delete $prereq{$best};
 577             foreach my $gp (values %prereq) {
 578                 delete $gp->{$best};
 579             }
 580         }
 581
 582         runcmd @git, qw(add), $seriesfile;
 583         runcmd @git, qw(commit --quiet -m), 'Merged patch queue form';
 584         $mwrecknote->('merged-patchqueue', git_rev_parse 'HEAD');
 585
 586         printdebug "merge_series series gbp pq import\n";
 587
 588         $attempt_cmd->(qw(gbp pq import));
 589
 590         # OK now we are on patch-queue/merge, and we need to rebase
 591         # onto the intended parent and drop the patches from each one
 592
 593         printdebug "merge_series series ok, building...\n";
 594         my $build = $newbase;
 595         my @lcmd = (@git, qw(rev-list --reverse merge..patch-queue/merge));
 596         foreach my $c (grep /./, split /\n/, cmdoutput @lcmd) {
 597             my $commit = git_cat_file $c, 'commit';
 598             printdebug "merge_series series ok, building $c\n";
 599             read_tree_upstream $c, 0, $newbase;
 600             my $tree = cmdoutput @git, qw(write-tree);
 601             $commit =~ s{^parent (\S+)$}{parent $build}m or confess;
 602             $commit =~ s{^tree (\S+)$}{tree $tree}m      or confess;
 603             open C, ">", "../mcommit" or die $!;
 604             print C $commit or die $!;
 605             close C or die $!;
 606             $build = cmdoutput @git, qw(hash-object -w -t commit ../mcommit);
 607         }
 608         $result = $build;
 609         $mwrecknote->('merged-result', $result);
 610
 611         runcmd @git, qw(update-ref refs/heads/result), $result;
 612
 613         runcmd @git, qw(checkout -q -b debug);
 614         runcmd @git, qw(commit --allow-empty -q -m M-INDEX);
 615         runcmd @git, qw(add .);
 616         runcmd @git, qw(commit --allow-empty -q -m M-WORKTREE);
 617         my $mdebug = git_rev_parse 'HEAD';
 618         printdebug sprintf "merge_series done debug=%s\n", $mdebug;
 619         $mwrecknote->('merged-debug', $mdebug);
 620     };
 621     printdebug "merge_series returns $result\n";
 622     return $result;
 623 }
 624
 625 # classify returns an info hash like this
 626 #   CommitId => $objid
 627 #   Hdr => # commit headers, including 1 final newline
 628 #   Msg => # commit message (so one newline is dropped)
 629 #   Tree => $treeobjid
 630 #   Type => (see below)
 631 #   Parents = [ {
 632 #       Ix => $index # ie 0, 1, 2, ...
 633 #       CommitId
 634 #       Differs => return value from get_differs
 635 #       IsOrigin
 636 #       IsDggitImport => 'orig' 'tarball' 'unpatched' 'package' (as from dgit)
 637 #     } ...]
 638 #   NewMsg => # commit message, but with any [dgit import ...] edited
 639 #             # to say "[was: ...]"
 640 #
 641 # Types:
 642 #   Packaging
 643 #   Changelog
 644 #   Upstream
 645 #   AddPatches
 646 #   Mixed
 647 #
 648 #   Pseudomerge
 649 #     has additional entres in classification result
 650 #       Overwritten = [ subset of Parents ]
 651 #       Contributor = $the_remaining_Parent
 652 #
 653 #   DgitImportUnpatched
 654 #     has additional entry in classification result
 655 #       OrigParents = [ subset of Parents ]
 656 #
 657 #   Anchor
 658 #     has additional entry in classification result
 659 #       OrigParents = [ subset of Parents ]  # singleton list
 660 #
 661 #   TreatAsAnchor
 662 #
 663 #   BreakwaterStart
 664 #
 665 #   Unknown
 666 #     has additional entry in classification result
 667 #       Why => "prose"
 668
 669 sub parsecommit ($;$) {
 670     my ($objid, $p_ref) = @_;
 671     # => hash with                   CommitId Hdr Msg Tree Parents
 672     #    Parents entries have only   Ix CommitId
 673     #    $p_ref, if provided, must be [] and is used as a base for Parents
 674
 675     $p_ref //= [];
 676     die if @$p_ref;
 677
 678     my ($h,$m) = get_commit $objid;
 679
 680     my ($t) = $h =~ m/^tree (\w+)$/m or die $objid;
 681     my (@ph) = $h =~ m/^parent (\w+)$/mg;
 682
 683     my $r = {
 684         CommitId => $objid,
 685         Hdr => $h,
 686         Msg => $m,
 687         Tree => $t,
 688         Parents => $p_ref,
 689     };
 690
 691     foreach my $ph (@ph) {
 692         push @$p_ref, {
 693             Ix => scalar @$p_ref,
 694             CommitId => $ph,
 695         };
 696     }
 697
 698     return $r;
 699 }
 700
 701 sub classify ($) {
 702     my ($objid) = @_;
 703
 704     my @p;
 705     my $r = parsecommit($objid, \@p);
 706     my $t = $r->{Tree};
 707
 708     foreach my $p (@p) {
 709         $p->{Differs} = (get_differs $p->{CommitId}, $t),
 710     }
 711
 712     printdebug "classify $objid \$t=$t \@p",
 713         (map { sprintf " %s/%#x", $_->{CommitId}, $_->{Differs} } @p),
 714         "\n";
 715
 716     my $classify = sub {
 717         my ($type, @rest) = @_;
 718         $r = { %$r, Type => $type, @rest };
 719         if ($debuglevel) {
 720             printdebug " = $type ".(dd $r)."\n";
 721         }
 722         return $r;
 723     };
 724     my $unknown = sub {
 725         my ($why) = @_;
 726         $r = { %$r, Type => qw(Unknown), Why => $why };
 727         printdebug " ** Unknown\n";
 728         return $r;
 729     };
 730
 731     if (grep { $_ eq $objid } @opt_anchors) {
 732         return $classify->('TreatAsAnchor');
 733     }
 734
 735     my @identical = grep { !$_->{Differs} } @p;
 736     my ($stype, $series) = git_cat_file "$t:debian/patches/series";
 737     my $haspatches = $stype ne 'missing' && $series =~ m/^\s*[^#\n\t ]/m;
 738
 739     if ($r->{Msg} =~ m{^\[git-debrebase anchor.*\]$}m) {
 740         # multi-orig upstreams are represented with an anchor merge
 741         # from a single upstream commit which combines the orig tarballs
 742
 743         # Every anchor tagged this way must be a merge.
 744         # We are relying on the
 745         #     [git-debrebase anchor: ...]
 746         # commit message annotation in "declare" anchor merges (which
 747         # do not have any upstream changes), to distinguish those
 748         # anchor merges from ordinary pseudomerges (which we might
 749         # just try to strip).
 750         #
 751         # However, the user is going to be doing git-rebase a lot.  We
 752         # really don't want them to rewrite an anchor commit.
 753         # git-rebase trips up on merges, so that is a useful safety
 754         # catch.
 755         #
 756         # BreakwaterStart commits are also anchors in the terminology
 757         # of git-debrebase(5), but they are untagged (and always
 758         # manually generated).
 759         #
 760         # We cannot not tolerate any tagged linear commit (ie,
 761         # BreakwaterStart commits tagged `[anchor:') because such a
 762         # thing could result from an erroneous linearising raw git
 763         # rebase of a merge anchor.  That would represent a corruption
 764         # of the branch. and we want to detect and reject the results
 765         # of such corruption before it makes it out anywhere.  If we
 766         # reject it here then we avoid making the pseudomerge which
 767         # would be needed to push it.
 768
 769         my $badanchor = sub { $unknown->("git-debrebase \`anchor' but @_"); };
 770         @p == 2 or return $badanchor->("has other than two parents");
 771         $haspatches and return $badanchor->("contains debian/patches");
 772
 773         # How to decide about l/r ordering of anchors ?  git
 774         # --topo-order prefers to expand 2nd parent first.  There's
 775         # already an easy rune to look for debian/ history anyway (git log
 776         # debian/) so debian breakwater branch should be 1st parent; that
 777         # way also there's also an easy rune to look for the upstream
 778         # patches (--topo-order).
 779
 780         # Also this makes --first-parent be slightly more likely to
 781         # be useful - it makes it provide a linearised breakwater history.
 782
 783         # Of course one can say somthing like
 784         #  gitk -- ':/' ':!/debian'
 785         # to get _just_ the commits touching upstream files, and by
 786         # the TREESAME logic in git-rev-list this will leave the
 787         # breakwater into upstream at the first anchor.  But that
 788         # doesn't report debian/ changes at all.
 789
 790         # Other observations about gitk: by default, gitk seems to
 791         # produce output in a different order to git-rev-list.  I
 792         # can't seem to find this documented anywhere.  gitk
 793         # --date-order DTRT.  But, gitk always seems to put the
 794         # parents from left to right, in order, so it's easy to see
 795         # which way round a pseudomerge is.
 796
 797         $p[0]{IsOrigin} and $badanchor->("is an origin commit");
 798         $p[1]{Differs} & ~DS_DEB and
 799             $badanchor->("upstream files differ from left parent");
 800         $p[0]{Differs} & ~D_UPS and
 801             $badanchor->("debian/ differs from right parent");
 802
 803         return $classify->(qw(Anchor),
 804                            OrigParents => [ $p[1] ]);
 805     }
 806
 807     if (@p == 1) {
 808         my $d = $r->{Parents}[0]{Differs};
 809         if ($d == D_PAT_ADD) {
 810             return $classify->(qw(AddPatches));
 811         } elsif ($d & (D_PAT_ADD|D_PAT_OTH)) {
 812             return $unknown->("edits debian/patches");
 813         } elsif ($d & DS_DEB and !($d & ~DS_DEB)) {
 814             my ($ty,$dummy) = git_cat_file "$p[0]{CommitId}:debian";
 815             if ($ty eq 'tree') {
 816                 if ($d == D_DEB_CLOG) {
 817                     return $classify->(qw(Changelog));
 818                 } else {
 819                     return $classify->(qw(Packaging));
 820                 }
 821             } elsif ($ty eq 'missing') {
 822                 return $classify->(qw(BreakwaterStart));
 823             } else {
 824                 return $unknown->("parent's debian is not a directory");
 825             }
 826         } elsif ($d == D_UPS) {
 827             return $classify->(qw(Upstream));
 828         } elsif ($d & DS_DEB and $d & D_UPS and !($d & ~(DS_DEB|D_UPS))) {
 829             return $classify->(qw(Mixed));
 830         } elsif ($d == 0) {
 831             return $unknown->("no changes");
 832         } else {
 833             confess "internal error $objid ?";
 834         }
 835     }
 836     if (!@p) {
 837         return $unknown->("origin commit");
 838     }
 839
 840     if (@p == 2 && @identical == 1) {
 841         my @overwritten = grep { $_->{Differs} } @p;
 842         confess "internal error $objid ?" unless @overwritten==1;
 843         return $classify->(qw(Pseudomerge),
 844                            Overwritten => [ $overwritten[0] ],
 845                            Contributor => $identical[0]);
 846     }
 847     if (@p == 2 && @identical == 2) {
 848         my $get_t = sub {
 849             my ($ph,$pm) = get_commit $_[0]{CommitId};
 850             $ph =~ m/^committer .* (\d+) [-+]\d+$/m or die "$_->{CommitId} ?";
 851             $1;
 852         };
 853         my @bytime = @p;
 854         my $order = $get_t->($bytime[0]) <=> $get_t->($bytime[1]);
 855         if ($order > 0) { # newer first
 856         } elsif ($order < 0) {
 857             @bytime = reverse @bytime;
 858         } else {
 859             # same age, default to order made by -s ours
 860             # that is, commit was made by someone who preferred L
 861         }
 862         return $classify->(qw(Pseudomerge),
 863                            SubType => qw(Ambiguous),
 864                            Contributor => $bytime[0],
 865                            Overwritten => [ $bytime[1] ]);
 866     }
 867     foreach my $p (@p) {
 868         my ($p_h, $p_m) = get_commit $p->{CommitId};
 869         $p->{IsOrigin} = $p_h !~ m/^parent \w+$/m;
 870         ($p->{IsDgitImport},) = $p_m =~ m/^\[dgit import ([0-9a-z]+) .*\]$/m;
 871     }
 872     my @orig_ps = grep { ($_->{IsDgitImport}//'X') eq 'orig' } @p;
 873     my $m2 = $r->{Msg};
 874     if (!(grep { !$_->{IsOrigin} } @p) and
 875         (@orig_ps >= @p - 1) and
 876         $m2 =~ s{^\[(dgit import unpatched .*)\]$}{[was: $1]}m) {
 877         $r->{NewMsg} = $m2;
 878         return $classify->(qw(DgitImportUnpatched),
 879                            OrigParents => \@orig_ps);
 880     }
 881
 882     if (@p == 2 and
 883         $r->{Msg} =~ m{^\[git-debrebase merged-breakwater.*\]$}m) {
 884         # xxx ^ metadata tag needs adding to (5)
 885         return $classify->("MergedBreakwaters");
 886     }
 887     if ($r->{Msg} =~ m{^\[(git-debrebase|dgit)[: ].*\]$}m) {
 888         return $unknown->("unknown kind of merge from $1");
 889     }
 890     if (@p > 2) {
 891         return $unknown->("octopus merge");
 892     }
 893
 894     if (!$ENV{GIT_DEBREBASE_EXPERIMENTAL_MERGE}) {
 895         return $unknown->("general two-parent merge");
 896     }
 897
 898     return $classify->("VanillaMerge");
 899 }
 900
 901 sub keycommits ($;$$$$$);
 902
 903 sub mergedbreakwaters_anchor ($) {
 904     my ($cl) = @_;
 905     my $best_anchor;
 906     foreach my $p (@{ $cl->{Parents} }) {
 907         my ($panchor, $pbw) = keycommits $p->{CommitId},
 908             undef,undef,undef,undef, 1;
 909         $best_anchor = $panchor
 910             if !defined $best_anchor
 911             or is_fast_fwd $best_anchor, $panchor;
 912         fail "inconsistent anchors in merged-breakwaters $p->{CommitId}"
 913             unless is_fast_fwd $panchor, $best_anchor;
 914     }
 915     return $best_anchor;
 916 }
 917
 918 sub keycommits ($;$$$$$) {
 919     my ($head, $furniture, $unclean, $trouble, $fatal, $claimed_bw) = @_;
 920     # => ($anchor, $breakwater)
 921
 922     # $unclean->("unclean-$tagsfx", $msg, $cl)
 923     # $furniture->("unclean-$tagsfx", $msg, $cl)
 924     # $dgitimport->("unclean-$tagsfx", $msg, $cl))
 925     #   is callled for each situation or commit that
 926     #   wouldn't be found in a laundered branch
 927     # $furniture is for furniture commits such as might be found on an
 928     #   interchange branch (pseudomerge, d/patches, changelog)
 929     # $trouble is for things whnich prevent the return of
 930     #   anchor and breakwater information; if that is ignored,
 931     #   then keycommits returns (undef, undef) instead.
 932     # $fatal is for unprocessable commits, and should normally cause
 933     #    a failure.  If ignored, agaion, (undef, undef) is returned.
 934     #
 935     # If $claimed_bw, this is supposed to be a breakwater commit.
 936     #
 937     # If a callback is undef, fail is called instead.
 938     # If a callback is defined but false, the situation is ignored.
 939     # Callbacks may say:
 940     #   no warnings qw(exiting); last;
 941     # if the answer is no longer wanted.
 942
 943     my ($anchor, $breakwater);
 944     $breakwater = $head if $claimed_bw;
 945     my $clogonly;
 946     my $cl;
 947     my $found_pm;
 948     $fatal //= sub { fail $_[1]; };
 949     my $x = sub {
 950         my ($cb, $tagsfx, $mainwhy, $xwhy) = @_;
 951         my $why = $mainwhy.$xwhy;
 952         my $m = "branch needs laundering (run git-debrebase): $why";
 953         fail $m unless defined $cb;
 954         return unless $cb;
 955         $cb->("unclean-$tagsfx", $why, $cl, $mainwhy);
 956     };
 957     my $found_anchor = sub {
 958         ($anchor) = @_;
 959         $breakwater //= $clogonly;
 960         $breakwater //= $head;
 961         no warnings qw(exiting);
 962         last;
 963     };
 964     for (;;) {
 965         $cl = classify $head;
 966         my $ty = $cl->{Type};
 967         if ($ty eq 'Packaging') {
 968             $breakwater //= $clogonly;
 969             $breakwater //= $head;
 970         } elsif ($ty eq 'Changelog') {
 971             # this is going to count as the tip of the breakwater
 972             # only if it has no upstream stuff before it
 973             $clogonly //= $head;
 974         } elsif ($ty eq 'Anchor' or
 975                  $ty eq 'TreatAsAnchor' or
 976                  $ty eq 'BreakwaterStart') {
 977             $found_anchor->($head);
 978         } elsif ($ty eq 'Upstream') {
 979             $x->($unclean, 'ordering',
 980  "packaging change ($breakwater) follows upstream change"," (eg $head)")
 981                 if defined $breakwater;
 982             $clogonly = undef;
 983             $breakwater = undef;
 984         } elsif ($ty eq 'Mixed') {
 985             $x->($unclean, 'mixed',
 986                  "found mixed upstream/packaging commit"," ($head)");
 987             $clogonly = undef;
 988             $breakwater = undef;
 989         } elsif ($ty eq 'Pseudomerge' or
 990                  $ty eq 'AddPatches') {
 991             my $found_pm = 1;
 992             $x->($furniture, (lc $ty),
 993                  "found interchange bureaucracy commit ($ty)"," ($head)");
 994         } elsif ($ty eq 'DgitImportUnpatched') {
 995             if ($found_pm) {
 996                 $x->($trouble, 'dgitimport',
 997                      "found dgit dsc import"," ($head)");
 998                 return (undef,undef);
 999             } else {
1000                 $x->($fatal, 'unprocessable',
1001                      "found bare dgit dsc import with no prior history",
1002                      " ($head)");
1003                 return (undef,undef);
1004             }
1005         } elsif ($ty eq 'VanillaMerge') {
1006             $x->($trouble, 'vanillamerge',
1007                  "found vanilla merge"," ($head)");
1008             return (undef,undef);
1009         } elsif ($ty eq 'MergedBreakwaters') {
1010             $found_anchor->(mergedbreakwaters_anchor $cl);
1011         } else {
1012             $x->($fatal, 'unprocessable',
1013                  "found unprocessable commit, cannot cope: $cl->{Why}",
1014                  " ($head)");
1015             return (undef,undef);
1016         }
1017         $head = $cl->{Parents}[0]{CommitId};
1018     }
1019     return ($anchor, $breakwater);
1020 }
1021
1022 sub walk ($;$$$);
1023 sub walk ($;$$$) {
1024     my ($input,
1025         $nogenerate,$report, $report_lprefix) = @_;
1026     # => ($tip, $breakwater_tip, $last_anchor)
1027     # (or nothing, if $nogenerate)
1028
1029     printdebug "*** WALK $input ".($nogenerate//0)." ".($report//'-')."\n";
1030     $report_lprefix //= '';
1031
1032     # go through commits backwards
1033     # we generate two lists of commits to apply:
1034     # breakwater branch and upstream patches
1035     my (@brw_cl, @upp_cl, @processed);
1036     my %found;
1037     my $upp_limit;
1038     my @pseudomerges;
1039
1040     my $cl;
1041     my $xmsg = sub {
1042         my ($prose, $info) = @_;
1043         my $ms = $cl->{Msg};
1044         chomp $ms;
1045         $info //= '';
1046         $ms .= "\n\n[git-debrebase$info: $prose]\n";
1047         return (Msg => $ms);
1048     };
1049     my $rewrite_from_here = sub {
1050         my ($cl) = @_;
1051         my $sp_cl = { SpecialMethod => 'StartRewrite' };
1052         push @$cl, $sp_cl;
1053         push @processed, $sp_cl;
1054     };
1055     my $cur = $input;
1056
1057     my $prdelim = "";
1058     my $prprdelim = sub { print $report $prdelim if $report; $prdelim=""; };
1059
1060     my $prline = sub {
1061         return unless $report;
1062         print $report $prdelim, $report_lprefix, @_;
1063         $prdelim = "\n";
1064     };
1065
1066     my $bomb = sub { # usage: return $bomb->();
1067         print $report " Unprocessable" if $report;
1068         print $report " ($cl->{Why})" if $report && defined $cl->{Why};
1069         $prprdelim->();
1070         if ($nogenerate) {
1071             return (undef,undef);
1072         }
1073         fail "found unprocessable commit, cannot cope".
1074             (defined $cl->{Why} ? "; $cl->{Why}:": ':').
1075             " (commit $cur) (d.".
1076             (join ' ', map { sprintf "%#x", $_->{Differs} }
1077              @{ $cl->{Parents} }).
1078                  ")";
1079     };
1080
1081     my $build;
1082     my $breakwater;
1083
1084     my $build_start = sub {
1085         my ($msg, $parent) = @_;
1086         $prline->(" $msg");
1087         $build = $parent;
1088         no warnings qw(exiting); last;
1089     };
1090
1091     my $nomerge = sub {
1092         my ($emsg) = @_;
1093         merge_failed $cl->{MergeWreckNotes}, $emsg;
1094     };
1095
1096     my $mwrecknote = sub { &mwrecknote($cl->{MergeWreckNotes}, @_); };
1097
1098     my $last_anchor;
1099
1100     for (;;) {
1101         $cl = classify $cur;
1102         $cl->{MergeWreckNotes} //= {};
1103         my $ty = $cl->{Type};
1104         my $st = $cl->{SubType};
1105         $prline->("$cl->{CommitId} $cl->{Type}");
1106         $found{$ty. ( defined($st) ? "-$st" : '' )}++;
1107         push @processed, $cl;
1108         my $p0 = @{ $cl->{Parents} }==1 ? $cl->{Parents}[0]{CommitId} : undef;
1109         if ($ty eq 'AddPatches') {
1110             $cur = $p0;
1111             $rewrite_from_here->(\@upp_cl);
1112             next;
1113         } elsif ($ty eq 'Packaging' or $ty eq 'Changelog') {
1114             push @brw_cl, $cl;
1115             $cur = $p0;
1116             next;
1117         } elsif ($ty eq 'BreakwaterStart') {
1118             $last_anchor = $cur;
1119             $build_start->('FirstPackaging', $cur);
1120         } elsif ($ty eq 'Upstream') {
1121             push @upp_cl, $cl;
1122             $cur = $p0;
1123             next;
1124         } elsif ($ty eq 'Mixed') {
1125             my $queue = sub {
1126                 my ($q, $wh) = @_;
1127                 my $cls = { %$cl, $xmsg->("split mixed commit: $wh part") };
1128                 push @$q, $cls;
1129             };
1130             $queue->(\@brw_cl, "debian");
1131             $queue->(\@upp_cl, "upstream");
1132             $rewrite_from_here->(\@brw_cl);
1133             $cur = $p0;
1134             next;
1135         } elsif ($ty eq 'Pseudomerge') {
1136             my $contrib = $cl->{Contributor}{CommitId};
1137             print $report " Contributor=$contrib" if $report;
1138             push @pseudomerges, $cl;
1139             $rewrite_from_here->(\@upp_cl);
1140             $cur = $contrib;
1141             next;
1142         } elsif ($ty eq 'Anchor' or $ty eq 'TreatAsAnchor') {
1143             $last_anchor = $cur;
1144             $build_start->("Anchor", $cur);
1145         } elsif ($ty eq 'DgitImportUnpatched') {
1146             my $pm = $pseudomerges[-1];
1147             if (defined $pm) {
1148                 # To an extent, this is heuristic.  Imports don't have
1149                 # a useful history of the debian/ branch.  We assume
1150                 # that the first pseudomerge after an import has a
1151                 # useful history of debian/, and ignore the histories
1152                 # from later pseudomerges.  Often the first pseudomerge
1153                 # will be the dgit import of the upload to the actual
1154                 # suite intended by the non-dgit NMUer, and later
1155                 # pseudomerges may represent in-archive copies.
1156                 my $ovwrs = $pm->{Overwritten};
1157                 printf $report " PM=%s \@Overwr:%d",
1158                     $pm->{CommitId}, (scalar @$ovwrs)
1159                     if $report;
1160                 if (@$ovwrs != 1) {
1161                     printdebug "*** WALK BOMB DgitImportUnpatched\n";
1162                     return $bomb->();
1163                 }
1164                 my $ovwr = $ovwrs->[0]{CommitId};
1165                 printf $report " Overwr=%s", $ovwr if $report;
1166                 # This import has a tree which is just like a
1167                 # breakwater tree, but it has the wrong history.  It
1168                 # ought to have the previous breakwater (which the
1169                 # pseudomerge overwrote) as an ancestor.  That will
1170                 # make the history of the debian/ files correct.  As
1171                 # for the upstream version: either it's the same as
1172                 # was ovewritten (ie, same as the previous
1173                 # breakwater), in which case that history is precisely
1174                 # right; or, otherwise, it was a non-gitish upload of a
1175                 # new upstream version.  We can tell these apart by
1176                 # looking at the tree of the supposed upstream.
1177                 push @brw_cl, {
1178                     %$cl,
1179                     SpecialMethod => 'DgitImportDebianUpdate',
1180                     $xmsg->("convert dgit import: debian changes")
1181                 }, {
1182                     %$cl,
1183                     SpecialMethod => 'DgitImportUpstreamUpdate',
1184                     $xmsg->("convert dgit import: upstream update",
1185                             " anchor")
1186                 };
1187                 $prline->(" Import");
1188                 $rewrite_from_here->(\@brw_cl);
1189                 $upp_limit //= $#upp_cl; # further, deeper, patches discarded
1190                 $cur = $ovwr;
1191                 next;
1192             } else {
1193                 # Everything is from this import.  This kind of import
1194                 # is already nearly in valid breakwater format, with the
1195                 # patches as commits.  Unfortunately it contains
1196                 # debian/patches/.
1197                 printdebug "*** WALK BOMB bare dgit import\n";
1198                 $cl->{Why} = "bare dgit dsc import";
1199                 return $bomb->();
1200             }
1201             die "$ty ?";
1202         } elsif ($ty eq 'MergedBreakwaters') {
1203             $last_anchor = mergedbreakwaters_anchor $cl;
1204             $build_start->(' MergedBreakwaters', $cur);
1205             last;
1206         } elsif ($ty eq 'VanillaMerge') {
1207             # User may have merged unstitched branch(es).  We will
1208             # have now lost what ffq-prev was then (since the later
1209             # pseudomerge may introduce further changes).  The effect
1210             # of resolving such a merge is that we may have to go back
1211             # further in history to find a merge base, since the one
1212             # which was reachable via ffq-prev is no longer findable.
1213             # This is suboptimal, but if it all works we'll have done
1214             # the right thing.
1215             # xxx we should warn the user in the docs about this
1216
1217             my $ok=1;
1218             my $best_anchor;
1219             # We expect to find a dominating anchor amongst the
1220             # inputs' anchors.  That will be the new anchor.
1221             #
1222             # More complicated is finding a merge base for the
1223             # breakwaters.  We need a merge base that is a breakwater
1224             # commit.  The ancestors of breakwater commits are more
1225             # breakwater commits and possibly upstream commits and the
1226             # ancestors of those upstream.  Upstreams might have
1227             # arbitrary ancestors.  But any upstream commit U is
1228             # either included in both anchors, in which case the
1229             # earlier anchor is a better merge base than any of U's
1230             # ancestors; or U is not included in the older anchor, in
1231             # which case U is not an ancestor of the vanilla merge at
1232             # all.  So no upstream commit, nor any ancestor thereof,
1233             # is a best merge base.  As for non-breakwater Debian
1234             # commits: these are never ancestors of any breakwater.
1235             #
1236             # So any best merge base as found by git-merge-base
1237             # is a suitable breakwater anchor.  Usually there will
1238             # be only one.
1239
1240             printdebug "*** MERGE\n";
1241
1242             my @bwbcmd = (@git, qw(merge-base));
1243             my @ibcmd = (@git, qw(merge-base --all));
1244             my $might_be_in_bw = 1;
1245
1246             my $ps = $cl->{Parents};
1247
1248             $mwrecknote->('vanilla-merge', $cl->{CommitId});
1249
1250             foreach my $p (@$ps) {
1251                 $prline->(" VanillaMerge ".$p->{Ix});
1252                 $prprdelim->();
1253                 my ($ptip, $pbw, $panchor) =
1254                     walk $p->{CommitId}, 0, $report,
1255                          $report_lprefix.'  ';
1256                 $p->{Laundered} = $p->{SeriesTip} = $ptip;
1257                 $p->{Breakwater} = $p->{SeriesBase} = $pbw;
1258                 $p->{Anchor} = $panchor;
1259
1260                 my $lr = $p->{LeftRight} = (qw(left right))[$p->{Ix}];
1261                 $mwrecknote->("$lr-input", $p->{CommitId});
1262
1263                 my $mwrecknote_parent = sub {
1264                     my ($which) = @_;
1265                     $mwrecknote->("$lr-".(lc $which), $p->{$which});
1266                 };
1267                 $mwrecknote_parent->('Laundered');
1268                 $mwrecknote_parent->('Breakwater');
1269                 $mwrecknote_parent->('Anchor');
1270
1271                 $best_anchor = $panchor if
1272                     !defined $best_anchor or
1273                     is_fast_fwd $best_anchor, $panchor;
1274
1275                 printdebug " MERGE BA best=".($best_anchor//'-').
1276                     " p=$panchor\n";
1277             }
1278
1279             $mwrecknote->('result-anchor', $best_anchor);
1280
1281             foreach my $p (@$ps) {
1282                 $prline->(" VanillaMerge ".$p->{Ix});
1283                 if (!is_fast_fwd $p->{Anchor}, $best_anchor) {
1284                     $nomerge->('divergent anchors');
1285                 } elsif ($p->{Anchor} eq $best_anchor) {
1286                     print $report " SameAnchor" if $report;
1287                 } else {
1288                     print $report " SupersededAnchor" if $report;
1289                 }
1290                 if ($p->{Breakwater} eq $p->{CommitId}) {
1291                     # this parent commit was its own breakwater,
1292                     # ie it is part of the breakwater
1293                     print $report " Breakwater" if $report;
1294                 } else {
1295                     $might_be_in_bw = 0;
1296                 }
1297                 push @bwbcmd, $p->{Breakwater};
1298                 push @ibcmd, $p->{CommitId};
1299             }
1300
1301             if ($ok && $might_be_in_bw) {
1302                 # We could rewrite this to contaion the metadata
1303                 # declaring it to be MergedBreakwaters, but
1304                 # unnecessarily rewriting a merge seems unhelpful.
1305                 $prline->(" VanillaMerge MergedBreakwaters");
1306                 $last_anchor = $best_anchor;
1307                 $build_start->('MergedBreakwaters', $cur);
1308             }
1309
1310             my $bwb = cmdoutput @bwbcmd;
1311
1312             # OK, now we have a breakwater base, but we need the merge
1313             # base for the interchange branch because we need the delta
1314             # queue.
1315             #
1316             # This a the best merge base of our inputs which has the
1317             # breakwater merge base as an ancestor.
1318
1319             my @ibs =
1320                 grep /./,
1321                 split /\n/,
1322                 cmdoutput @ibcmd;
1323
1324             @ibs or confess 'internal error, expected anchor at least ?';
1325
1326             my $ib;
1327             my $ibleaf;
1328             foreach my $tibix (0..$#ibs) {
1329                 my $tib = $ibs[$tibix];
1330                 my $ff = is_fast_fwd $bwb, $tib;
1331                 my $ok = !$ff ? 'rej' : $ib ? 'extra' : 'ok';
1332                 my $tibleaf = "interchange-mbcand-$ok-$tibix";
1333                 $mwrecknote->($tibleaf, $tib);
1334                 next unless $ff;
1335                 next if $ib;
1336                 $ib = $tib;
1337                 $ibleaf = $tibleaf;
1338             }
1339
1340             $ib or $nomerge->("no suitable interchange merge base");
1341
1342             $prline->("  VanillaMerge Base");
1343             $prprdelim->();
1344             my ($btip, $bbw, $banchor) = eval {
1345                 walk $ib, 0, $report, $report_lprefix.'  ';
1346             };
1347             $nomerge->("walking interchange branch merge base ($ibleaf): ".
1348                        $@) if length $@;
1349
1350             $mwrecknote->("mergebase-laundered", $btip);
1351             $mwrecknote->("mergebase-breakwater", $bbw);
1352             $mwrecknote->("mergebase-anchor", $banchor);
1353
1354             my $ibinfo = { SeriesTip => $btip,
1355                            SeriesBase => $bbw,
1356                            Anchor => $banchor,
1357                            LeftRight => 'mergebase' };
1358
1359             $bbw eq $bwb
1360                 or $nomerge->("interchange merge-base ($ib)'s".
1361                               " breakwater ($bbw)".
1362                               " != breakwaters' merge-base ($bwb)");
1363
1364             grep { $_->{Anchor} eq $ibinfo->{Anchor} } @$ps
1365                  or $nomerge->("interchange merge-base ($ib)'s".
1366                                " anchor ($ibinfo->{SeriesBase})".
1367                                " != any merge input's anchor (".
1368                                (join ' ', map { $_->{Anchor} } @$ps).
1369                                ")");
1370
1371             $cl->{MergeInterchangeBaseInfo} = $ibinfo;
1372             $cl->{MergeBestAnchor} = $best_anchor;
1373             push @brw_cl, {
1374                 %$cl,
1375                 SpecialMethod => 'MergeCreateMergedBreakwaters',
1376                 $xmsg->('constructed from vanilla merge',
1377                         ' merged-breakwater'),
1378             };
1379             push @upp_cl, {
1380                 %$cl,
1381                 SpecialMethod => 'MergeMergeSeries',
1382             };
1383             $build_start->('MergeBreakwaters', $cur);
1384         } else {
1385             printdebug "*** WALK BOMB unrecognised\n";
1386             return $bomb->();
1387         }
1388     }
1389     $prprdelim->();
1390
1391     printdebug "*** WALK prep done cur=$cur".
1392         " brw $#brw_cl upp $#upp_cl proc $#processed pm $#pseudomerges\n";
1393
1394     return if $nogenerate;
1395
1396     # Now we build it back up again
1397
1398     fresh_workarea();
1399
1400     my $rewriting = 0;
1401
1402     my $read_tree_upstream = sub {
1403         my ($treeish) = @_;
1404         read_tree_upstream $treeish, 0, $build;
1405     };
1406
1407     $#upp_cl = $upp_limit if defined $upp_limit;
1408
1409     my $committer_authline = calculate_committer_authline();
1410
1411     printdebug "WALK REBUILD $build ".(scalar @processed)."\n";
1412
1413     confess "internal error" unless $build eq (pop @processed)->{CommitId};
1414
1415     in_workarea sub {
1416         mkdir $rd or $!==EEXIST or die $!;
1417         my $current_method;
1418         runcmd @git, qw(read-tree), $build;
1419         foreach my $cl (qw(Debian), (reverse @brw_cl),
1420                         { SpecialMethod => 'RecordBreakwaterTip' },
1421                         qw(Upstream), (reverse @upp_cl)) {
1422             if (!ref $cl) {
1423                 $current_method = $cl;
1424                 next;
1425             }
1426             my $method = $cl->{SpecialMethod} // $current_method;
1427             my @parents = ($build);
1428             my $cltree = $cl->{CommitId};
1429             printdebug "WALK BUILD ".($cltree//'undef').
1430                 " $method (rewriting=$rewriting)\n";
1431             if ($method eq 'Debian') {
1432                 read_tree_debian($cltree);
1433             } elsif ($method eq 'Upstream') {
1434                 $read_tree_upstream->($cltree);
1435             } elsif ($method eq 'StartRewrite') {
1436                 $rewriting = 1;
1437                 next;
1438             } elsif ($method eq 'RecordBreakwaterTip') {
1439                 $breakwater = $build;
1440                 next;
1441             } elsif ($method eq 'DgitImportDebianUpdate') {
1442                 read_tree_debian($cltree);
1443             } elsif ($method eq 'DgitImportUpstreamUpdate') {
1444                 confess unless $rewriting;
1445                 my $differs = (get_differs $build, $cltree);
1446                 next unless $differs & D_UPS;
1447                 $read_tree_upstream->($cltree);
1448                 push @parents, map { $_->{CommitId} } @{ $cl->{OrigParents} };
1449             } elsif ($method eq 'MergeCreateMergedBreakwaters') {
1450                 print "Found a general merge, will try to tidy it up.\n";
1451                 $rewriting = 1;
1452                 $read_tree_upstream->($cl->{MergeBestAnchor});
1453                 $read_tree_upstream->($cl->{MergeBestAnchor});
1454                 read_tree_debian($cltree);
1455                 @parents = map { $_->{Breakwater} } @{ $cl->{Parents} };
1456             } elsif ($method eq 'MergeMergeSeries') {
1457                 print "Running merge resolution for $cl->{CommitId}...\n";
1458                 $build = merge_series
1459                     $build, $cl->{MergeWreckNotes},
1460                     $cl->{MergeInterchangeBaseInfo},
1461                     @{ $cl->{Parents} };
1462                 $last_anchor = $cl->{MergeBestAnchor};
1463
1464                 # Check for mismerges:
1465                 my $check = sub {
1466                     my ($against, $allow, $what) = @_;
1467                     my $differs = get_differs $build, $against;
1468                     $nomerge->(sprintf
1469        "merge misresolved: %s are not the same (%s %s d.%#x)",
1470                                $what, $against, $build, $differs)
1471                         if $differs & ~($allow | D_PAT_ADD);
1472                 };
1473
1474                 # Breakwater changes which were in each side of the
1475                 # merge will have been incorporated into the
1476                 # MergeCreateMergedBreakwaters output.  Because the
1477                 # upstream series was rebased onto the new breakwater,
1478                 # so should all of the packaging changes which were in
1479                 # the input.
1480                 $check->($input, D_UPS, 'debian files');
1481
1482                 # Upstream files are merge_series, which ought to
1483                 # have been identical to the original merge.
1484                 $check->($cl->{CommitId}, DS_DEB, 'upstream files');
1485
1486                 print "Merge resolution successful.\n";
1487                 next;
1488             } else {
1489                 confess "$method ?";
1490             }
1491             if (!$rewriting) {
1492                 my $procd = (pop @processed) // 'UNDEF';
1493                 if ($cl ne $procd) {
1494                     $rewriting = 1;
1495                     printdebug "WALK REWRITING NOW cl=$cl procd=$procd\n";
1496                 }
1497             }
1498             my $newtree = cmdoutput @git, qw(write-tree);
1499             my $ch = $cl->{Hdr};
1500             $ch =~ s{^tree .*}{tree $newtree}m or confess "$ch ?";
1501             $ch =~ s{^parent .*\n}{}mg;
1502             $ch =~ s{(?=^author)}{
1503                 join '', map { "parent $_\n" } @parents
1504             }me or confess "$ch ?";
1505             if ($rewriting) {
1506                 $ch =~ s{^committer .*$}{$committer_authline}m
1507                     or confess "$ch ?";
1508             }
1509             my $cf = "$rd/m$rewriting";
1510             open CD, ">", $cf or die $!;
1511             print CD $ch, "\n", $cl->{Msg} or die $!;
1512             close CD or die $!;
1513             my @cmd = (@git, qw(hash-object));
1514             push @cmd, qw(-w) if $rewriting;
1515             push @cmd, qw(-t commit), $cf;
1516             my $newcommit = cmdoutput @cmd;
1517             confess "$ch ?" unless $rewriting or $newcommit eq $cl->{CommitId};
1518             $build = $newcommit;
1519             if (grep { $method eq $_ } qw(DgitImportUpstreamUpdate)) {
1520                 $last_anchor = $cur;
1521             }
1522         }
1523     };
1524
1525     my $final_check = get_differs $build, $input;
1526     die sprintf "internal error %#x %s %s", $final_check, $input, $build
1527         if $final_check & ~D_PAT_ADD;
1528
1529     my @r = ($build, $breakwater, $last_anchor);
1530     printdebug "*** WALK RETURN @r\n";
1531     return @r
1532 }
1533
1534 sub get_head () {
1535     git_check_unmodified();
1536     return git_rev_parse qw(HEAD);
1537 }
1538
1539 sub update_head ($$$) {
1540     my ($old, $new, $mrest) = @_;
1541     push @deferred_updates, "update HEAD $new $old";
1542     run_deferred_updates $mrest;
1543 }
1544
1545 sub update_head_checkout ($$$) {
1546     my ($old, $new, $mrest) = @_;
1547     update_head $old, $new, $mrest;
1548     runcmd @git, qw(reset --hard);
1549 }
1550
1551 sub update_head_postlaunder ($$$) {
1552     my ($old, $tip, $reflogmsg) = @_;
1553     return if $tip eq $old;
1554     print "git-debrebase: laundered (head was $old)\n";
1555     update_head $old, $tip, $reflogmsg;
1556     # no tree changes except debian/patches
1557     runcmd @git, qw(rm --quiet --ignore-unmatch -rf debian/patches);
1558 }
1559
1560 sub currently_rebasing() {
1561     foreach (qw(rebase-merge rebase-apply)) {
1562         return 1 if stat_exists "$maindir_gitdir/$_";
1563     }
1564     return 0;
1565 }
1566
1567 sub bail_if_rebasing() {
1568     fail "you are in the middle of a git-rebase already"
1569         if currently_rebasing();
1570 }
1571
1572 sub do_launder_head ($) {
1573     my ($reflogmsg) = @_;
1574     my $old = get_head();
1575     record_ffq_auto();
1576     my ($tip,$breakwater) = walk $old;
1577     snags_maybe_bail();
1578     update_head_postlaunder $old, $tip, $reflogmsg;
1579     return ($tip,$breakwater);
1580 }
1581
1582 sub cmd_launder_v0 () {
1583     badusage "no arguments to launder-v0 allowed" if @ARGV;
1584     my $old = get_head();
1585     my ($tip,$breakwater,$last_anchor) = walk $old;
1586     update_head_postlaunder $old, $tip, 'launder';
1587     printf "# breakwater tip\n%s\n", $breakwater;
1588     printf "# working tip\n%s\n", $tip;
1589     printf "# last anchor\n%s\n", $last_anchor;
1590 }
1591
1592 sub defaultcmd_rebase () {
1593     push @ARGV, @{ $opt_defaultcmd_interactive // [] };
1594     my ($tip,$breakwater) = do_launder_head 'launder for rebase';
1595     runcmd @git, qw(rebase), @ARGV, $breakwater if @ARGV;
1596 }
1597
1598 sub cmd_analyse () {
1599     badusage "analyse does not support any options"
1600         if @ARGV and $ARGV[0] =~ m/^-/;
1601     badusage "too many arguments to analyse" if @ARGV>1;
1602     my ($old) = @ARGV;
1603     if (defined $old) {
1604         $old = git_rev_parse $old;
1605     } else {
1606         $old = git_rev_parse 'HEAD';
1607     }
1608     my ($dummy,$breakwater) = walk $old, 1,*STDOUT;
1609     STDOUT->error and die $!;
1610 }
1611
1612 sub ffq_prev_branchinfo () {
1613     my $current = git_get_symref();
1614     return gdr_ffq_prev_branchinfo($current);
1615 }
1616
1617 sub ffq_check ($;$$) {
1618     # calls $ff and/or $notff zero or more times
1619     # then returns either (status,message) where status is
1620     #    exists
1621     #    detached
1622     #    weird-symref
1623     #    notbranch
1624     # or (undef,undef, $ffq_prev,$gdrlast)
1625     # $ff and $notff are called like this:
1626     #   $ff->("message for stdout\n");
1627     #   $notff->('snag-name', $message);
1628     # normally $currentval should be HEAD
1629     my ($currentval, $ff, $notff) =@_;
1630
1631     $ff //= sub { print $_[0] or die $!; };
1632     $notff //= \&snag;
1633
1634     my ($status, $message, $current, $ffq_prev, $gdrlast)
1635         = ffq_prev_branchinfo();
1636     return ($status, $message) unless $status eq 'branch';
1637
1638     my $exists = git_get_ref $ffq_prev;
1639     return ('exists',"$ffq_prev already exists") if $exists;
1640
1641     return ('not-branch', 'HEAD symref is not to refs/heads/')
1642         unless $current =~ m{^refs/heads/};
1643     my $branch = $';
1644
1645     my @check_specs = split /\;/, (cfg "branch.$branch.ffq-ffrefs",1) // '*';
1646     my %checked;
1647
1648     printdebug "ffq check_specs @check_specs\n";
1649
1650     my $check = sub {
1651         my ($lrref, $desc) = @_;
1652         printdebug "ffq might check $lrref ($desc)\n";
1653         my $invert;
1654         for my $chk (@check_specs) {
1655             my $glob = $chk;
1656             $invert = $glob =~ s{^[!^]}{};
1657             last if fnmatch $glob, $lrref;
1658         }
1659         return if $invert;
1660         my $lrval = git_get_ref $lrref;
1661         return unless length $lrval;
1662
1663         if (is_fast_fwd $lrval, $currentval) {
1664             $ff->("OK, you are ahead of $lrref\n");
1665             $checked{$lrref} = 1;
1666         } elsif (is_fast_fwd $currentval, $lrval) {
1667             $checked{$lrref} = -1;
1668             $notff->('behind', "you are behind $lrref, divergence risk");
1669         } else {
1670             $checked{$lrref} = -1;
1671             $notff->('diverged', "you have diverged from $lrref");
1672         }
1673     };
1674
1675     my $merge = cfg "branch.$branch.merge",1;
1676     if (defined $merge and $merge =~ m{^refs/heads/}) {
1677         my $rhs = $';
1678         printdebug "ffq merge $rhs\n";
1679         my $check_remote = sub {
1680             my ($remote, $desc) = @_;
1681             printdebug "ffq check_remote ".($remote//'undef')." $desc\n";
1682             return unless defined $remote;
1683             $check->("refs/remotes/$remote/$rhs", $desc);
1684         };
1685         $check_remote->((scalar cfg "branch.$branch.remote",1),
1686                         'remote fetch/merge branch');
1687         $check_remote->((scalar cfg "branch.$branch.pushRemote",1) //
1688                         (scalar cfg "branch.$branch.pushDefault",1),
1689                         'remote push branch');
1690     }
1691     if ($branch =~ m{^dgit/}) {
1692         $check->("refs/remotes/dgit/$branch", 'remote dgit branch');
1693     } elsif ($branch =~ m{^master$}) {
1694         $check->("refs/remotes/dgit/dgit/sid", 'remote dgit branch for sid');
1695     }
1696     return (undef, undef, $ffq_prev, $gdrlast);
1697 }
1698
1699 sub record_ffq_prev_deferred () {
1700     # => ('status', "message")
1701     # 'status' may be
1702     #    deferred          message is undef
1703     #    exists
1704     #    detached
1705     #    weird-symref
1706     #    notbranch
1707     # if not ff from some branch we should be ff from, is an snag
1708     # if "deferred", will have added something about that to
1709     #   @deferred_update_messages, and also maybe printed (already)
1710     #   some messages about ff checks
1711     bail_if_rebasing();
1712     my $currentval = get_head();
1713
1714     my ($status,$message, $ffq_prev,$gdrlast) = ffq_check $currentval;
1715     return ($status,$message) if defined $status;
1716
1717     snags_maybe_bail();
1718
1719     push @deferred_updates, "update $ffq_prev $currentval $git_null_obj";
1720     push @deferred_updates, "delete $gdrlast";
1721     push @deferred_update_messages, "Recorded previous head for preservation";
1722     return ('deferred', undef);
1723 }
1724
1725 sub record_ffq_auto () {
1726     my ($status, $message) = record_ffq_prev_deferred();
1727     if ($status eq 'deferred' || $status eq 'exists') {
1728     } else {
1729         snag $status, "could not record ffq-prev: $message";
1730         snags_maybe_bail();
1731     }
1732 }
1733
1734 sub ffq_prev_info () {
1735     bail_if_rebasing();
1736     # => ($ffq_prev, $gdrlast, $ffq_prev_commitish)
1737     my ($status, $message, $current, $ffq_prev, $gdrlast)
1738         = ffq_prev_branchinfo();
1739     if ($status ne 'branch') {
1740         snag $status, "could not check ffq-prev: $message";
1741         snags_maybe_bail();
1742     }
1743     my $ffq_prev_commitish = $ffq_prev && git_get_ref $ffq_prev;
1744     return ($ffq_prev, $gdrlast, $ffq_prev_commitish);
1745 }
1746
1747 sub stitch ($$$$$) {
1748     my ($old_head, $ffq_prev, $gdrlast, $ffq_prev_commitish, $prose) = @_;
1749
1750     push @deferred_updates, "delete $ffq_prev $ffq_prev_commitish";
1751
1752     if (is_fast_fwd $old_head, $ffq_prev_commitish) {
1753         my $differs = get_differs $old_head, $ffq_prev_commitish;
1754         unless ($differs & ~D_PAT_ADD) {
1755             # ffq-prev is ahead of us, and the only tree changes it has
1756             # are possibly addition of things in debian/patches/.
1757             # Just wind forwards rather than making a pointless pseudomerge.
1758             push @deferred_updates,
1759                 "update $gdrlast $ffq_prev_commitish $git_null_obj";
1760             update_head_checkout $old_head, $ffq_prev_commitish,
1761                 "stitch (fast forward)";
1762             return;
1763         }
1764     }
1765     fresh_workarea();
1766     # We make pseudomerges with L as the contributing parent.
1767     # This makes git rev-list --first-parent work properly.
1768     my $new_head = make_commit [ $old_head, $ffq_prev ], [
1769         'Declare fast forward / record previous work',
1770         "[git-debrebase pseudomerge: $prose]",
1771     ];
1772     push @deferred_updates, "update $gdrlast $new_head $git_null_obj";
1773     update_head $old_head, $new_head, "stitch: $prose";
1774 }
1775
1776 sub do_stitch ($;$) {
1777     my ($prose, $unclean) = @_;
1778
1779     my ($ffq_prev, $gdrlast, $ffq_prev_commitish) = ffq_prev_info();
1780     if (!$ffq_prev_commitish) {
1781         fail "No ffq-prev to stitch." unless $opt_noop_ok;
1782         return;
1783     }
1784     my $dangling_head = get_head();
1785
1786     keycommits $dangling_head, $unclean,$unclean,$unclean;
1787     snags_maybe_bail();
1788
1789     stitch($dangling_head, $ffq_prev, $gdrlast, $ffq_prev_commitish, $prose);
1790 }
1791
1792 sub upstream_commitish_search ($$) {
1793     my ($upstream_version, $tried) = @_;
1794     # todo: at some point maybe use git-deborig to do this
1795     foreach my $tagpfx ('', 'v', 'upstream/') {
1796         my $tag = $tagpfx.(dep14_version_mangle $upstream_version);
1797         my $new_upstream = git_get_ref "refs/tags/$tag";
1798         push @$tried, $tag;
1799         return $new_upstream if length $new_upstream;
1800     }
1801 }
1802
1803 sub resolve_upstream_version ($$) {
1804     my ($new_upstream, $upstream_version) = @_;
1805
1806     if (!defined $new_upstream) {
1807         my @tried;
1808         $new_upstream = upstream_commitish_search $upstream_version, \@tried;
1809         if (!length $new_upstream) {
1810             fail "Could not determine appropriate upstream commitish.\n".
1811                 " (Tried these tags: @tried)\n".
1812                 " Check version, and specify upstream commitish explicitly.";
1813         }
1814     }
1815     $new_upstream = git_rev_parse $new_upstream;
1816
1817     return $new_upstream;
1818 }
1819
1820 sub cmd_new_upstream () {
1821     # automatically and unconditionally launders before rebasing
1822     # if rebase --abort is used, laundering has still been done
1823
1824     my %pieces;
1825
1826     badusage "need NEW-VERSION [UPS-COMMITTISH]" unless @ARGV >= 1;
1827
1828     # parse args - low commitment
1829     my $spec_version = shift @ARGV;
1830     my $new_version = (new Dpkg::Version $spec_version, check => 1);
1831     fail "bad version number \`$spec_version'" unless defined $new_version;
1832     if ($new_version->is_native()) {
1833         $new_version = (new Dpkg::Version "$spec_version-1", check => 1);
1834     }
1835
1836     my $new_upstream = shift @ARGV;
1837     my $new_upstream_version = upstreamversion  $new_version;
1838     $new_upstream =
1839         resolve_upstream_version $new_upstream, $new_upstream_version;
1840
1841     record_ffq_auto();
1842
1843     my $piece = sub {
1844         my ($n, @x) = @_; # may be ''
1845         my $pc = $pieces{$n} //= {
1846             Name => $n,
1847             Desc => ($n ? "upstream piece \`$n'" : "upstream (main piece"),
1848         };
1849         while (my $k = shift @x) { $pc->{$k} = shift @x; }
1850         $pc;
1851     };
1852
1853     my @newpieces;
1854     my $newpiece = sub {
1855         my ($n, @x) = @_; # may be ''
1856         my $pc = $piece->($n, @x, NewIx => (scalar @newpieces));
1857         push @newpieces, $pc;
1858     };
1859
1860     $newpiece->('',
1861         OldIx => 0,
1862         New => $new_upstream,
1863     );
1864     while (@ARGV && $ARGV[0] !~ m{^-}) {
1865         my $n = shift @ARGV;
1866
1867         badusage "for each EXTRA-UPS-NAME need EXTRA-UPS-COMMITISH"
1868             unless @ARGV && $ARGV[0] !~ m{^-};
1869
1870         my $c = git_rev_parse shift @ARGV;
1871         die unless $n =~ m/^$extra_orig_namepart_re$/;
1872         $newpiece->($n, New => $c);
1873     }
1874
1875     # now we need to investigate the branch this generates the
1876     # laundered version but we don't switch to it yet
1877     my $old_head = get_head();
1878     my ($old_laundered_tip,$old_bw,$old_anchor) = walk $old_head;
1879
1880     my $old_bw_cl = classify $old_bw;
1881     my $old_anchor_cl = classify $old_anchor;
1882     my $old_upstream;
1883     if (!$old_anchor_cl->{OrigParents}) {
1884         snag 'anchor-treated',
1885             'old anchor is recognised due to --anchor, cannot check upstream';
1886     } else {
1887         $old_upstream = parsecommit
1888             $old_anchor_cl->{OrigParents}[0]{CommitId};
1889         $piece->('', Old => $old_upstream->{CommitId});
1890     }
1891
1892     if ($old_upstream && $old_upstream->{Msg} =~ m{^\[git-debrebase }m) {
1893         if ($old_upstream->{Msg} =~
1894  m{^\[git-debrebase upstream-combine (\.(?: $extra_orig_namepart_re)+)\:.*\]$}m
1895            ) {
1896             my @oldpieces = (split / /, $1);
1897             my $old_n_parents = scalar @{ $old_upstream->{Parents} };
1898             if ($old_n_parents != @oldpieces &&
1899                 $old_n_parents != @oldpieces + 1) {
1900                 snag 'upstream-confusing', sprintf
1901                     "previous upstream combine %s".
1902                     " mentions %d pieces (each implying one parent)".
1903                     " but has %d parents".
1904                     " (one per piece plus maybe a previous combine)",
1905                     $old_upstream->{CommitId},
1906                     (scalar @oldpieces),
1907                     $old_n_parents;
1908             } elsif ($oldpieces[0] ne '.') {
1909                 snag 'upstream-confusing', sprintf
1910                     "previous upstream combine %s".
1911                     " first piece is not \`.'",
1912                     $oldpieces[0];
1913             } else {
1914                 $oldpieces[0] = '';
1915                 foreach my $i (0..$#oldpieces) {
1916                     my $n = $oldpieces[$i];
1917                     my $hat = 1 + $i + ($old_n_parents - @oldpieces);
1918                     $piece->($n, Old => $old_upstream->{CommitId}.'^'.$hat);
1919                 }
1920             }
1921         } else {
1922             snag 'upstream-confusing',
1923                 "previous upstream $old_upstream->{CommitId} is from".
1924                " git-debrebase but not an \`upstream-combine' commit";
1925         }
1926     }
1927
1928     foreach my $pc (values %pieces) {
1929         if (!$old_upstream) {
1930             # we have complained already
1931         } elsif (!$pc->{Old}) {
1932             snag 'upstream-new-piece',
1933                 "introducing upstream piece \`$pc->{Name}'";
1934         } elsif (!$pc->{New}) {
1935             snag 'upstream-rm-piece',
1936                 "dropping upstream piece \`$pc->{Name}'";
1937         } elsif (!is_fast_fwd $pc->{Old}, $pc->{New}) {
1938             snag 'upstream-not-ff',
1939                 "not fast forward: $pc->{Name} $pc->{Old}..$pc->{New}";
1940         }
1941     }
1942
1943     printdebug "%pieces = ", (dd \%pieces), "\n";
1944     printdebug "\@newpieces = ", (dd \@newpieces), "\n";
1945
1946     snags_maybe_bail();
1947
1948     my $new_bw;
1949
1950     fresh_workarea();
1951     in_workarea sub {
1952         my @upstream_merge_parents;
1953
1954         if (!any_snags()) {
1955             push @upstream_merge_parents, $old_upstream->{CommitId};
1956         }
1957
1958         foreach my $pc (@newpieces) { # always has '' first
1959             if ($pc->{Name}) {
1960                 read_tree_subdir $pc->{Name}, $pc->{New};
1961             } else {
1962                 runcmd @git, qw(read-tree), $pc->{New};
1963             }
1964             push @upstream_merge_parents, $pc->{New};
1965         }
1966
1967         # index now contains the new upstream
1968
1969         if (@newpieces > 1) {
1970             # need to make the upstream subtree merge commit
1971             $new_upstream = make_commit \@upstream_merge_parents,
1972                 [ "Combine upstreams for $new_upstream_version",
1973  ("[git-debrebase upstream-combine . ".
1974  (join " ", map { $_->{Name} } @newpieces[1..$#newpieces]).
1975  ": new upstream]"),
1976                 ];
1977         }
1978
1979         # $new_upstream is either the single upstream commit, or the
1980         # combined commit we just made.  Either way it will be the
1981         # "upstream" parent of the anchor merge.
1982
1983         read_tree_subdir 'debian', "$old_bw:debian";
1984
1985         # index now contains the anchor merge contents
1986         $new_bw = make_commit [ $old_bw, $new_upstream ],
1987             [ "Update to upstream $new_upstream_version",
1988  "[git-debrebase anchor: new upstream $new_upstream_version, merge]",
1989             ];
1990
1991         my $clogsignoff = cmdoutput qw(git show),
1992             '--pretty=format:%an <%ae>  %aD',
1993             $new_bw;
1994
1995         # Now we have to add a changelog stanza so the Debian version
1996         # is right.
1997         die if unlink "debian";
1998         die $! unless $!==ENOENT or $!==ENOTEMPTY;
1999         unlink "debian/changelog" or $!==ENOENT or die $!;
2000         mkdir "debian" or die $!;
2001         open CN, ">", "debian/changelog" or die $!;
2002         my $oldclog = git_cat_file ":debian/changelog";
2003         $oldclog =~ m/^($package_re) \(\S+\) / or
2004             fail "cannot parse old changelog to get package name";
2005         my $p = $1;
2006         print CN <<END, $oldclog or die $!;
2007 $p ($new_version) UNRELEASED; urgency=medium
2008
2009   * Update to new upstream version $new_upstream_version.
2010
2011  -- $clogsignoff
2012
2013 END
2014         close CN or die $!;
2015         runcmd @git, qw(update-index --add --replace), 'debian/changelog';
2016
2017         # Now we have the final new breakwater branch in the index
2018         $new_bw = make_commit [ $new_bw ],
2019             [ "Update changelog for new upstream $new_upstream_version",
2020               "[git-debrebase: new upstream $new_upstream_version, changelog]",
2021             ];
2022     };
2023
2024     # we have constructed the new breakwater. we now need to commit to
2025     # the laundering output, because git-rebase can't easily be made
2026     # to make a replay list which is based on some other branch
2027
2028     update_head_postlaunder $old_head, $old_laundered_tip,
2029         'launder for new upstream';
2030
2031     my @cmd = (@git, qw(rebase --onto), $new_bw, $old_bw, @ARGV);
2032     local $ENV{GIT_REFLOG_ACTION} = git_reflog_action_msg
2033         "debrebase new-upstream $new_version: rebase";
2034     runcmd @cmd;
2035     # now it's for the user to sort out
2036 }
2037
2038 sub cmd_record_ffq_prev () {
2039     badusage "no arguments allowed" if @ARGV;
2040     my ($status, $msg) = record_ffq_prev_deferred();
2041     if ($status eq 'exists' && $opt_noop_ok) {
2042         print "Previous head already recorded\n" or die $!;
2043     } elsif ($status eq 'deferred') {
2044         run_deferred_updates 'record-ffq-prev';
2045     } else {
2046         fail "Could not preserve: $msg";
2047     }
2048 }
2049
2050 sub cmd_anchor () {
2051     badusage "no arguments allowed" if @ARGV;
2052     my ($anchor, $bw) = keycommits +(git_rev_parse 'HEAD'), 0,0;
2053     print "$bw\n" or die $!;
2054 }
2055
2056 sub cmd_breakwater () {
2057     badusage "no arguments allowed" if @ARGV;
2058     my ($anchor, $bw) = keycommits +(git_rev_parse 'HEAD'), 0,0;
2059     print "$bw\n" or die $!;
2060 }
2061
2062 sub cmd_status () {
2063     badusage "no arguments allowed" if @ARGV;
2064
2065     # todo: gdr status should print divergence info
2066     # todo: gdr status should print upstream component(s) info
2067     # todo: gdr should leave/maintain some refs with this kind of info ?
2068
2069     my $oldest = { Badness => 0 };
2070     my $newest;
2071     my $note = sub {
2072         my ($badness, $ourmsg, $snagname, $dummy, $cl, $kcmsg) = @_;
2073         if ($oldest->{Badness} < $badness) {
2074             $oldest = $newest = undef;
2075         }
2076         $oldest = {
2077                    Badness => $badness,
2078                    CommitId => $cl->{CommitId},
2079                    OurMsg => $ourmsg,
2080                    KcMsg => $kcmsg,
2081                   };
2082         $newest //= $oldest;
2083     };
2084     my ($anchor, $bw) = keycommits +(git_rev_parse 'HEAD'),
2085         sub { $note->(1, 'branch contains furniture (not laundered)', @_); },
2086         sub { $note->(2, 'branch is unlaundered', @_); },
2087         sub { $note->(3, 'branch needs laundering', @_); },
2088         sub { $note->(4, 'branch not in git-debrebase form', @_); };
2089
2090     my $prcommitinfo = sub {
2091         my ($cid) = @_;
2092         flush STDOUT or die $!;
2093         runcmd @git, qw(--no-pager log -n1),
2094             '--pretty=format:    %h %s%n',
2095             $cid;
2096     };
2097
2098     print "current branch contents, in git-debrebase terms:\n";
2099     if (!$oldest->{Badness}) {
2100         print "  branch is laundered\n";
2101     } else {
2102         print "  $oldest->{OurMsg}\n";
2103         my $printed = '';
2104         foreach my $info ($oldest, $newest) {
2105             my $cid = $info->{CommitId};
2106             next if $cid eq $printed;
2107             $printed = $cid;
2108             print "  $info->{KcMsg}\n";
2109             $prcommitinfo->($cid);
2110         }
2111     }
2112
2113     my $prab = sub {
2114         my ($cid, $what) = @_;
2115         if (!defined $cid) {
2116             print "  $what is not well-defined\n";
2117         } else {
2118             print "  $what\n";
2119             $prcommitinfo->($cid);
2120         }
2121     };
2122     print "key git-debrebase commits:\n";
2123     $prab->($anchor, 'anchor');
2124     $prab->($bw, 'breakwater');
2125
2126     my ($ffqstatus, $ffq_msg, $current, $ffq_prev, $gdrlast) =
2127         ffq_prev_branchinfo();
2128
2129     print "branch and ref status, in git-debrebase terms:\n";
2130     if ($ffq_msg) {
2131         print "  $ffq_msg\n";
2132     } else {
2133         $ffq_prev = git_get_ref $ffq_prev;
2134         $gdrlast = git_get_ref $gdrlast;
2135         if ($ffq_prev) {
2136             print "  unstitched; previous tip was:\n";
2137             $prcommitinfo->($ffq_prev);
2138         } elsif (!$gdrlast) {
2139             print "  stitched? (no record of git-debrebase work)\n";
2140         } elsif (is_fast_fwd $gdrlast, 'HEAD') {
2141             print "  stitched\n";
2142         } else {
2143             print "  not git-debrebase (diverged since last stitch)\n"
2144         }
2145     }
2146     print "you are currently rebasing\n" if currently_rebasing();
2147 }
2148
2149 sub cmd_stitch () {
2150     my $prose = 'stitch';
2151     getoptions("stitch",
2152                'prose=s', \$prose);
2153     badusage "no arguments allowed" if @ARGV;
2154     do_stitch $prose, 0;
2155 }
2156 sub cmd_prepush () { cmd_stitch(); }
2157
2158 sub cmd_quick () {
2159     badusage "no arguments allowed" if @ARGV;
2160     do_launder_head 'launder for git-debrebase quick';
2161     do_stitch 'quick';
2162 }
2163
2164 sub cmd_conclude () {
2165     my ($ffq_prev, $gdrlast, $ffq_prev_commitish) = ffq_prev_info();
2166     if (!$ffq_prev_commitish) {
2167         fail "No ongoing git-debrebase session." unless $opt_noop_ok;
2168         return;
2169     }
2170     my $dangling_head = get_head();
2171
2172     badusage "no arguments allowed" if @ARGV;
2173     do_launder_head 'launder for git-debrebase quick';
2174     do_stitch 'quick';
2175 }
2176
2177 sub cmd_scrap () {
2178     if (currently_rebasing()) {
2179         runcmd @git, qw(rebase --abort);
2180     }
2181     my ($ffq_prev, $gdrlast, $ffq_prev_commitish) = ffq_prev_info();
2182     if (!$ffq_prev_commitish) {
2183         fail "No ongoing git-debrebase session." unless $opt_noop_ok;
2184         finish 0;
2185     }
2186     my $scrapping_head = get_head();
2187     badusage "no arguments allowed" if @ARGV;
2188     push @deferred_updates,
2189         "update $gdrlast $ffq_prev_commitish $git_null_obj",
2190         "update $ffq_prev $git_null_obj $ffq_prev_commitish";
2191     snags_maybe_bail();
2192     update_head_checkout $scrapping_head, $ffq_prev_commitish, "scrap";
2193 }
2194
2195 sub make_patches_staged ($) {
2196     my ($head) = @_;
2197     # Produces the patches that would result from $head if it were
2198     # laundered.
2199     my ($secret_head, $secret_bw, $last_anchor) = walk $head;
2200     fresh_workarea();
2201     in_workarea sub {
2202         gbp_pq_export 'bw', $secret_bw, $secret_head;
2203     };
2204 }
2205
2206 sub make_patches ($) {
2207     my ($head) = @_;
2208     keycommits $head, 0, \&snag;
2209     make_patches_staged $head;
2210     my $out;
2211     in_workarea sub {
2212         my $ptree = cmdoutput @git, qw(write-tree --prefix=debian/patches/);
2213         runcmd @git, qw(read-tree), $head;
2214         read_tree_subdir 'debian/patches', $ptree;
2215         $out = make_commit [$head], [
2216             'Commit patch queue (exported by git-debrebase)',
2217             '[git-debrebase: export and commit patches]',
2218         ];
2219     };
2220     return $out;
2221 }
2222
2223 sub cmd_make_patches () {
2224     my $opt_quiet_would_amend;
2225     getoptions("make-patches",
2226                'quiet-would-amend!', \$opt_quiet_would_amend);
2227     badusage "no arguments allowed" if @ARGV;
2228     bail_if_rebasing();
2229     my $old_head = get_head();
2230     my $new = make_patches $old_head;
2231     my $d = get_differs $old_head, $new;
2232     if ($d == 0) {
2233         fail "No (more) patches to export." unless $opt_noop_ok;
2234         return;
2235     } elsif ($d == D_PAT_ADD) {
2236         snags_maybe_bail();
2237         update_head_checkout $old_head, $new, 'make-patches';
2238     } else {
2239         print STDERR failmsg
2240             "Patch export produced patch amendments".
2241             " (abandoned output commit $new).".
2242             "  Try laundering first."
2243             unless $opt_quiet_would_amend;
2244         finish 7;
2245     }
2246 }
2247
2248 sub cmd_convert_from_gbp () {
2249     badusage "want only 1 optional argument, the upstream git commitish"
2250         unless @ARGV<=1;
2251
2252     my $clogp = parsechangelog();
2253     my $version = $clogp->{'Version'}
2254         // die "missing Version from changelog";
2255
2256     my ($upstream_spec) = @ARGV;
2257
2258     my $upstream_version = upstreamversion $version;
2259     my $upstream =
2260         resolve_upstream_version($upstream_spec, $upstream_version);
2261
2262     my $old_head = get_head();
2263
2264     my $upsdiff = get_differs $upstream, $old_head;
2265     if ($upsdiff & D_UPS) {
2266         runcmd @git, qw(--no-pager diff --stat),
2267             $upstream, $old_head,
2268             qw( -- :!/debian :/);
2269         fail <<END;
2270 upstream ($upstream_spec) and HEAD are not
2271 identical in upstream files.  See diffstat above, or run
2272   git diff $upstream_spec HEAD -- :!/debian :/
2273 END
2274     }
2275
2276     if (!is_fast_fwd $upstream, $old_head) {
2277         snag 'upstream-not-ancestor',
2278             "upstream ($upstream) is not an ancestor of HEAD";
2279     } else {
2280         my $wrong = cmdoutput
2281             (@git, qw(rev-list --ancestry-path), "$upstream..HEAD",
2282              qw(-- :/ :!/debian));
2283         if (length $wrong) {
2284             snag 'unexpected-upstream-changes',
2285                 "history between upstream ($upstream) and HEAD contains direct changes to upstream files - are you sure this is a gbp (patches-unapplied) branch?";
2286             print STDERR "list expected changes with:  git log --stat --ancestry-path $upstream_spec..HEAD -- :/ ':!/debian'\n";
2287         }
2288     }
2289
2290     if ((git_cat_file "$upstream:debian")[0] ne 'missing') {
2291         snag 'upstream-has-debian',
2292             "upstream ($upstream) contains debian/ directory";
2293     }
2294
2295     my $previous_dgit_view = eval {
2296         my @clogcmd = qw(dpkg-parsechangelog --format rfc822 -n2);
2297         my ($lvsn, $suite);
2298         parsechangelog_loop \@clogcmd, 'debian/changelog', sub {
2299             my ($stz, $desc) = @_;
2300             no warnings qw(exiting);
2301             printdebug 'CHANGELOG ', Dumper($desc, $stz);
2302             next unless $stz->{Date};
2303             next unless $stz->{Distribution} ne 'UNRELEASED';
2304             $lvsn = $stz->{Version};
2305             $suite = $stz->{Distribution};
2306             last;
2307         };
2308         die "neither of the first two changelog entries are released\n"
2309             unless defined $lvsn;
2310         print "last finished-looking changelog entry: ($lvsn) $suite\n";
2311         my $mtag_pat = debiantag_maintview $lvsn, '*';
2312         my $mtag = cmdoutput @git, qw(describe --always --abbrev=0 --match),
2313             $mtag_pat;
2314         die "could not find suitable maintainer view tag $mtag_pat\n"
2315             unless $mtag_pat =~ m{/};
2316         is_fast_fwd $mtag, 'HEAD' or
2317             die "HEAD is not FF from maintainer tag $mtag!";
2318         my $dtag = "archive/$mtag";
2319         is_fast_fwd $mtag, $dtag or
2320             die "dgit view tag $dtag is not FF from maintainer tag $mtag";
2321         print "will stitch in dgit view, $dtag\n";
2322         git_rev_parse $dtag;
2323     };
2324     if (!$previous_dgit_view) {
2325         $@ =~ s/^\n+//;
2326         chomp $@;
2327         print STDERR "cannot stitch in dgit view: $@\n";
2328     }
2329
2330     snags_maybe_bail_early();
2331
2332     my $work;
2333
2334     fresh_workarea();
2335     in_workarea sub {
2336         runcmd @git, qw(checkout -q -b gdr-internal), $old_head;
2337         # make a branch out of the patch queue - we'll want this in a mo
2338         runcmd qw(gbp pq import);
2339         # strip the patches out
2340         runcmd @git, qw(checkout -q gdr-internal~0);
2341         rm_subdir_cached 'debian/patches';
2342         $work = make_commit ['HEAD'], [
2343  'git-debrebase convert-from-gbp: drop patches from tree',
2344  'Delete debian/patches, as part of converting to git-debrebase format.',
2345  '[git-debrebase convert-from-gbp: drop patches from tree]'
2346                               ];
2347         # make the anchor merge
2348         # the tree is already exactly right
2349         $work = make_commit [$work, $upstream], [
2350  'git-debrebase import: declare upstream',
2351  'First breakwater merge.',
2352  '[git-debrebase anchor: declare upstream]'
2353                               ];
2354
2355         # rebase the patch queue onto the new breakwater
2356         runcmd @git, qw(reset --quiet --hard patch-queue/gdr-internal);
2357         runcmd @git, qw(rebase --quiet --onto), $work, qw(gdr-internal);
2358         $work = git_rev_parse 'HEAD';
2359
2360         if ($previous_dgit_view) {
2361             $work = make_commit [$work, $previous_dgit_view], [
2362  'git-debrebase import: declare ff from dgit archive view',
2363  '[git-debrebase pseudomerge: import-from-gbp]',
2364             ];
2365         }
2366     };
2367
2368     ffq_check $work;
2369     snags_maybe_bail();
2370     update_head_checkout $old_head, $work, 'convert-from-gbp';
2371 }
2372
2373 sub cmd_convert_to_gbp () {
2374     badusage "no arguments allowed" if @ARGV;
2375     my $head = get_head();
2376     my (undef, undef, undef, $ffq, $gdrlast) = ffq_prev_branchinfo();
2377     keycommits $head, 0;
2378     my $out;
2379     make_patches_staged $head;
2380     in_workarea sub {
2381         $out = make_commit ['HEAD'], [
2382             'Commit patch queue (converted from git-debrebase format)',
2383             '[git-debrebase convert-to-gbp: commit patches]',
2384         ];
2385     };
2386     if (defined $ffq) {
2387         push @deferred_updates, "delete $ffq";
2388         push @deferred_updates, "delete $gdrlast";
2389     }
2390     snags_maybe_bail();
2391     update_head_checkout $head, $out, "convert to gbp (v0)";
2392     print <<END or die $!;
2393 git-debrebase: converted to git-buildpackage branch format
2394 git-debrebase: WARNING: do not now run "git-debrebase" any more
2395 git-debrebase: WARNING: doing so would drop all upstream patches!
2396 END
2397 }
2398
2399 sub cmd_convert_from_dgit_view () {
2400     my $clogp = parsechangelog();
2401
2402     my $bpd = (cfg 'dgit.default.build-products-dir',1) // '..';
2403     my $do_origs = 1;
2404     my $do_tags = 1;
2405     my $always = 0;
2406     my $diagnose = 0;
2407
2408     getoptions("convert-from-dgit-view",
2409                'diagnose!', \$diagnose,
2410                'build-products-dir:s', \$bpd,
2411                'origs!', \$do_origs,
2412                'tags!', \$do_tags,
2413                'always-convert-anyway!', \$always);
2414     fail "takes 1 optional argument, the upstream commitish" if @ARGV>1;
2415
2416     my @upstreams;
2417
2418     if (@ARGV) {
2419         my $spec = shift @ARGV;
2420         my $commit = git_rev_parse "$spec^{commit}";
2421         push @upstreams, { Commit => $commit,
2422                            Source => "$ARGV[0], from command line",
2423                            Only => 1,
2424                          };
2425     }
2426
2427     my $head = get_head();
2428
2429     if (!$always) {
2430         my $troubles = 0;
2431         my $trouble = sub { $troubles++; };
2432         keycommits $head, sub{}, sub{}, $trouble, $trouble;
2433         printdebug "troubles=$troubles\n";
2434         if (!$troubles) {
2435             print STDERR <<END;
2436 $us: Branch already seems to be in git-debrebase format!
2437 $us: --always-convert-anyway would do the conversion operation anyway
2438 $us: but is probably a bad idea.  Probably, you wanted to do nothing.
2439 END
2440             fail "Branch already in git-debrebase format." unless $opt_noop_ok;
2441             finish 0;
2442         }
2443     }
2444
2445     snags_maybe_bail_early();
2446
2447     my $version = upstreamversion $clogp->{Version};
2448     print STDERR "Considering possible commits corresponding to upstream:\n";
2449
2450     if (!@upstreams) {
2451         if ($do_tags) {
2452             my @tried;
2453             my $ups_tag = upstream_commitish_search $version, \@tried;
2454             if ($ups_tag) {
2455                 my $this = "git tag $tried[-1]";
2456                 push @upstreams, { Commit => $ups_tag,
2457                                    Source => $this,
2458                                  };
2459             } else {
2460                 printf STDERR
2461                     " git tag: no suitable tag found (tried %s)\n",
2462                     "@tried";
2463             }
2464         }
2465         if ($do_origs) {
2466             my $p = $clogp->{'Source'};
2467             # we do a quick check to see if there are plausible origs
2468             my $something=0;
2469             if (!opendir BPD, $bpd) {
2470                 die "$bpd: opendir: $!" unless $!==ENOENT;
2471             } else {
2472                 while ($!=0, my $f = readdir BPD) {
2473                     next unless is_orig_file_of_p_v $f, $p, $version;
2474                     printf STDERR
2475                         " orig: found what looks like a .orig, %s\n",
2476                         "$bpd/$f";
2477                     $something=1;
2478                     last;
2479                 }
2480                 die "read $bpd: $!" if $!;
2481                 closedir BPD;
2482             }
2483             if ($something) {
2484                 my $tree = cmdoutput
2485                     @dgit, qw(--build-products-dir), $bpd,
2486                     qw(print-unapplied-treeish);
2487                 fresh_workarea();
2488                 in_workarea sub {
2489                     runcmd @git, qw(reset --quiet), $tree, qw(-- .);
2490                     rm_subdir_cached 'debian';
2491                     $tree = cmdoutput @git, qw(write-tree);
2492                     my $ups_synth = make_commit [], [ <<END, <<END,
2493 Import effective orig tree for upstream version $version
2494 END
2495 This includes the contents of the .orig(s), minus any debian/ directory.
2496
2497 [git-debrebase import-from-dgit-view upstream-import-convert: $version]
2498 END
2499                                                     ];
2500                     push @upstreams, { Commit => $ups_synth,
2501                                        Source => "orig(s) imported via dgit",
2502                                      };
2503                 }
2504             } else {
2505                 printf STDERR
2506                     " orig: no suitable origs found (looked for %s in %s)\n",
2507                     "${p}_".(stripeoch $version)."...", $bpd;
2508             }
2509         }
2510     }
2511
2512     my $some_patches = stat_exists 'debian/patches/series';
2513
2514     print STDERR "Evaluating possible commits corresponding to upstream:\n";
2515
2516     my $result;
2517     foreach my $u (@upstreams) {
2518         my $work = $head;
2519         fresh_workarea();
2520         in_workarea sub {
2521             runcmd @git, qw(reset --quiet), $u->{Commit}, qw(-- .);
2522             runcmd @git, qw(checkout), $u->{Commit}, qw(-- .);
2523             runcmd @git, qw(clean -xdff);
2524             runcmd @git, qw(checkout), $head, qw(-- debian);
2525             if ($some_patches) {
2526                 rm_subdir_cached 'debian/patches';
2527                 $work = make_commit [ $work ], [
2528  'git-debrebase convert-from-dgit-view: drop upstream changes from breakwater',
2529  "Drop upstream changes, and delete debian/patches, as part of converting\n".
2530  "to git-debrebase format.  Upstream changes will appear as commits.",
2531  '[git-debrebase convert-from-dgit-view: drop patches from tree]'
2532                                            ];
2533             }
2534             $work = make_commit [ $work, $u->{Commit} ], [
2535  'git-debrebase convert-from-dgit-view: declare upstream',
2536  '(Re)constructed breakwater merge.',
2537  '[git-debrebase anchor: declare upstream]'
2538                                                          ];
2539             runcmd @git, qw(checkout --quiet -b mk), $work;
2540             if ($some_patches) {
2541                 runcmd @git, qw(checkout), $head, qw(-- debian/patches);
2542                 runcmd @git, qw(reset --quiet);
2543                 my @gbp_cmd = (qw(gbp pq import));
2544                 if (!$diagnose) {
2545                     my $gbp_err = "../gbp-pq-err";
2546                     @gbp_cmd = shell_cmd "exec >$gbp_err 2>&1", @gbp_cmd;
2547                 }
2548                 my $r = system @gbp_cmd;
2549                 if ($r) {
2550                     printf STDERR
2551                         " %s: couldn't apply patches: gbp pq %s",
2552                         $u->{Source}, waitstatusmsg();
2553                     return;
2554                 }
2555             }
2556             my $work = git_rev_parse qw(HEAD);
2557             my $diffout = cmdoutput @git, qw(diff-tree --stat HEAD), $work;
2558             if (length $diffout) {
2559                 print STDERR
2560                     " $u->{Source}: applying patches gives different tree\n";
2561                 print STDERR $diffout if $diagnose;
2562                 return;
2563             }
2564             # OMG!
2565             $u->{Result} = $work;
2566             $result = $u;
2567         };
2568         last if $result;
2569     }
2570
2571     if (!$result) {
2572         fail <<END;
2573 Could not find or construct a suitable upstream commit.
2574 Rerun adding --diagnose after convert-from-dgit-view, or pass a
2575 upstream commmit explicitly or provide suitable origs.
2576 END
2577     }
2578
2579     printf STDERR "Yes, will base new branch on %s\n", $result->{Source};
2580
2581     ffq_check $result->{Result};
2582     snags_maybe_bail();
2583     update_head_checkout $head, $result->{Result},
2584         'convert-from-dgit-view';
2585 }
2586
2587 sub cmd_downstream_rebase_launder_v0 () {
2588     badusage "needs 1 argument, the baseline" unless @ARGV==1;
2589     my ($base) = @ARGV;
2590     $base = git_rev_parse $base;
2591     my $old_head = get_head();
2592     my $current = $old_head;
2593     my $topmost_keep;
2594     for (;;) {
2595         if ($current eq $base) {
2596             $topmost_keep //= $current;
2597             print " $current BASE stop\n";
2598             last;
2599         }
2600         my $cl = classify $current;
2601         print " $current $cl->{Type}";
2602         my $keep = 0;
2603         my $p0 = $cl->{Parents}[0]{CommitId};
2604         my $next;
2605         if ($cl->{Type} eq 'Pseudomerge') {
2606             print " ^".($cl->{Contributor}{Ix}+1);
2607             $next = $cl->{Contributor}{CommitId};
2608         } elsif ($cl->{Type} eq 'AddPatches' or
2609                  $cl->{Type} eq 'Changelog') {
2610             print " strip";
2611             $next = $p0;
2612         } else {
2613             print " keep";
2614             $next = $p0;
2615             $keep = 1;
2616         }
2617         print "\n";
2618         if ($keep) {
2619             $topmost_keep //= $current;
2620         } else {
2621             die "to-be stripped changes not on top of the branch\n"
2622                 if $topmost_keep;
2623         }
2624         $current = $next;
2625     }
2626     if ($topmost_keep eq $old_head) {
2627         print "unchanged\n";
2628     } else {
2629         print "updating to $topmost_keep\n";
2630         update_head_checkout
2631             $old_head, $topmost_keep,
2632             'downstream-rebase-launder-v0';
2633     }
2634 }
2635
2636 getoptions_main
2637           ("bad options\n",
2638            "D+" => \$debuglevel,
2639            'noop-ok', => \$opt_noop_ok,
2640            'f=s' => \@snag_force_opts,
2641            'anchor=s' => \@opt_anchors,
2642            '--dgit=s' => \($dgit[0]),
2643            'force!',
2644            '-i:s' => sub {
2645                my ($opt,$val) = @_;
2646                badusage "git-debrebase: no cuddling to -i for git-rebase"
2647                    if length $val;
2648                die if $opt_defaultcmd_interactive; # should not happen
2649                $opt_defaultcmd_interactive = [ qw(-i) ];
2650                # This access to @ARGV is excessive familiarity with
2651                # Getopt::Long, but there isn't another sensible
2652                # approach.  '-i=s{0,}' does not work with bundling.
2653                push @$opt_defaultcmd_interactive, @ARGV;
2654                @ARGV=();
2655            },
2656            'help' => sub { print $usage_message or die $!; finish 0; },
2657            );
2658
2659 initdebug('git-debrebase ');
2660 enabledebug if $debuglevel;
2661
2662 my $toplevel = cmdoutput @git, qw(rev-parse --show-toplevel);
2663 chdir $toplevel or die "chdir $toplevel: $!";
2664
2665 $rd = fresh_playground "$playprefix/misc";
2666
2667 @opt_anchors = map { git_rev_parse $_ } @opt_anchors;
2668
2669 if (!@ARGV || $opt_defaultcmd_interactive || $ARGV[0] =~ m{^-}) {
2670     defaultcmd_rebase();
2671 } else {
2672     my $cmd = shift @ARGV;
2673     my $cmdfn = $cmd;
2674     $cmdfn =~ y/-/_/;
2675     $cmdfn = ${*::}{"cmd_$cmdfn"};
2676
2677     $cmdfn or badusage "unknown git-debrebase sub-operation $cmd";
2678     $cmdfn->();
2679 }
2680
2681 finish 0;