git-debrebase

   1 #!/usr/bin/perl -w
   2 # git-debrebase
   3 # Script helping make fast-forwarding histories while still rebasing
   4 # upstream deltas when working on Debian packaging
   5 #
   6 # Copyright (C)2017,2018 Ian Jackson
   7 #
   8 # This program is free software: you can redistribute it and/or modify
   9 # it under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation, either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # This program is distributed in the hope that it will be useful,
  14 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20
  21 END { $? = $Debian::Dgit::ExitStatus::desired // -1; };
  22 use Debian::Dgit::GDR;
  23 use Debian::Dgit::ExitStatus;
  24
  25 use strict;
  26
  27 use Debian::Dgit qw(:DEFAULT :playground);
  28 setup_sigwarn();
  29
  30 use Memoize;
  31 use Carp;
  32 use POSIX;
  33 use Data::Dumper;
  34 use Getopt::Long qw(:config posix_default gnu_compat bundling);
  35 use Dpkg::Version;
  36 use File::FnMatch qw(:fnmatch);
  37 use File::Copy;
  38
  39 $debugcmd_when_debuglevel = 2;
  40
  41 our ($usage_message) = <<'END';
  42 usages:
  43   git-debrebase [<options>] [--|-i <git rebase options...>]
  44   git-debrebase [<options>] status
  45   git-debrebase [<options>] prepush [--prose=...]
  46   git-debrebase [<options>] quick|conclude
  47   git-debrebase [<options>] new-upstream <new-version> [<details ...>]
  48   git-debrebase [<options>] convert-from-gbp [<upstream-commitish>]
  49   ...
  50 See git-debrebase(1), git-debrebase(5), dgit-maint-debrebase(7) (in dgit).
  51 END
  52
  53 our ($opt_force, $opt_noop_ok, $opt_merges, @opt_anchors);
  54 our ($opt_defaultcmd_interactive);
  55
  56 our $us = qw(git-debrebase);
  57
  58 our $wrecknoteprefix = 'refs/debrebase/wreckage';
  59 our $merge_cache_ref = 'refs/debrebase/merge-resolutions';
  60
  61 $|=1;
  62
  63 sub badusage ($) {
  64     my ($m) = @_;
  65     print STDERR "$us: bad usage: $m\n";
  66     finish 8;
  67 }
  68
  69 sub getoptions_main {
  70     my $m = shift;
  71     local $SIG{__WARN__}; # GetOptions calls `warn' to print messages
  72     GetOptions @_ or badusage $m;
  73 }
  74 sub getoptions {
  75     my $sc = shift;
  76     getoptions_main "bad options follow \`git-debrebase $sc'", @_;
  77 }
  78
  79 sub cfg ($;$) {
  80     my ($k, $optional) = @_;
  81     local $/ = "\0";
  82     my @cmd = qw(git config -z);
  83     push @cmd, qw(--get-all) if wantarray;
  84     push @cmd, $k;
  85     my $out = cmdoutput_errok @cmd;
  86     if (!defined $out) {
  87         fail "missing required git config $k" unless $optional;
  88         return ();
  89     }
  90     my @l = split /\0/, $out;
  91     return wantarray ? @l : $l[0];
  92 }
  93
  94 memoize('cfg');
  95
  96 sub dd ($) {
  97     my ($v) = @_;
  98     my $dd = new Data::Dumper [ $v ];
  99     Terse $dd 1; Indent $dd 0; Useqq $dd 1;
 100     return Dump $dd;
 101 }
 102
 103 sub get_commit ($) {
 104     my ($objid) = @_;
 105     my $data = (git_cat_file $objid, 'commit');
 106     $data =~ m/(?<=\n)\n/ or die "$objid ($data) ?";
 107     return ($`,$');
 108 }
 109
 110 sub D_UPS ()      { 0x02; } # upstream files
 111 sub D_PAT_ADD ()  { 0x04; } # debian/patches/ extra patches at end
 112 sub D_PAT_OTH ()  { 0x08; } # debian/patches other changes
 113 sub D_DEB_CLOG () { 0x10; } # debian/changelog
 114 sub D_DEB_OTH ()  { 0x20; } # debian/ (not patches/ or changelog)
 115 sub DS_DEB ()     { D_DEB_CLOG | D_DEB_OTH; } # debian/ (not patches/)
 116
 117 our $playprefix = 'debrebase';
 118 our $rd;
 119 our $workarea;
 120
 121 our @git = qw(git);
 122 our @dgit = qw(dgit);
 123
 124 sub in_workarea ($) {
 125     my ($sub) = @_;
 126     changedir $workarea;
 127     my $r = eval { $sub->(); };
 128     { local $@; changedir $maindir; }
 129     die $@ if $@;
 130 }
 131
 132 sub fresh_workarea (;$) {
 133     my ($subdir) = @_;
 134     $subdir //= 'work';
 135     $workarea = fresh_playground "$playprefix/$subdir";
 136     in_workarea sub { playtree_setup };
 137 }
 138
 139 sub run_ref_updates_now ($$) {
 140     my ($mrest, $updates) = @_;
 141     # @$updates is a list of lines for git-update-ref, without \ns
 142
 143     my @upd_cmd = (git_update_ref_cmd "debrebase: $mrest", qw(--stdin));
 144     debugcmd '>|', @upd_cmd;
 145     open U, "|-", @upd_cmd or die $!;
 146     foreach (@$updates) {
 147         printdebug ">= ", $_, "\n";
 148         print U $_, "\n" or die $!;
 149     }
 150     printdebug ">\$\n";
 151     close U or failedcmd @upd_cmd;
 152 }
 153
 154 our $snags_forced = 0;
 155 our $snags_tripped = 0;
 156 our $snags_summarised = 0;
 157 our @deferred_updates;
 158 our @deferred_update_messages;
 159
 160 sub merge_wreckage_cleaning ($) {
 161     my ($updates) = @_;
 162     git_for_each_ref("$wrecknoteprefix/*", sub {
 163         my ($objid,$objtype,$fullrefname,$reftail) = @_;
 164         push @$updates, "delete $fullrefname";
 165     });
 166 }
 167
 168 sub all_snags_summarised () {
 169     $snags_forced + $snags_tripped == $snags_summarised;
 170 }
 171 sub run_deferred_updates ($) {
 172     my ($mrest) = @_;
 173
 174     confess 'dangerous internal error' unless all_snags_summarised();
 175
 176     merge_wreckage_cleaning \@deferred_updates;
 177     run_ref_updates_now $mrest, \@deferred_updates;
 178     print $_, "\n" foreach @deferred_update_messages;
 179
 180     @deferred_updates = ();
 181     @deferred_update_messages = ();
 182 }
 183
 184 sub get_tree ($;$$) {
 185     # tree object name => ([ $name, $info ], ...)
 186     # where $name is the sort key, ie has / at end for subtrees
 187     # $info is the LHS from git-ls-tree (<mode> <type> <hash>)
 188     # without $precheck, will crash if $x does not exist, so don't do that;
 189     # instead pass '' to get ().
 190     my ($x, $precheck, $recurse) = @_;
 191
 192     return () if !length $x;
 193
 194     if ($precheck) {
 195         my ($type, $dummy) = git_cat_file $x, [qw(tree missing)];
 196         return () if $type eq 'missing';
 197     }
 198
 199     $recurse = !!$recurse;
 200
 201     confess "get_tree needs object not $x ?" unless $x =~ m{^[0-9a-f]+\:};
 202
 203     our (@get_tree_memo, %get_tree_memo);
 204     my $memo = $get_tree_memo{$recurse,$x};
 205     return @$memo if $memo;
 206
 207     local $Debian::Dgit::debugcmd_when_debuglevel = 3;
 208     my @l;
 209     my @cmd = (qw(git ls-tree -z --full-tree));
 210     push @cmd, qw(-r) if $recurse;
 211     push @cmd, qw(--), $x;
 212     my $o = cmdoutput @cmd;
 213     $o =~ s/\0$//s;
 214     my $last = '';
 215     foreach my $l (split /\0/, $o) {
 216         my ($i, $n) = split /\t/, $l, 2;
 217         $n .= '/' if $i =~ m/^\d+ tree /;
 218         push @l, [ $n, $i ];
 219         confess "$x need $last < $n ?" unless $last lt $n;
 220     }
 221     $get_tree_memo{$recurse,$x} = \@l;
 222     push @get_tree_memo, $x;
 223     if (@get_tree_memo > 10) {
 224         delete $get_tree_memo{ shift @get_tree_memo };
 225     }
 226     return @l;
 227 }
 228
 229 sub trees_diff_walk ($$$;$) {
 230     # trees_diff_walk [{..opts...},] $x, $y, sub {... }
 231     # calls sub->($name, $ix, $iy) for each difference
 232     # $x and $y are as for get_tree
 233     # where $name, $ix, $iy are $name and $info from get_tree
 234     # opts are   all       call even for names same in both
 235     #            recurse   call even for names same in both
 236     my $opts = shift @_ if @_>=4;
 237     my ($x,$y,$call) = @_;
 238     my $all = $opts->{all};
 239     return if !$all and $x eq $y;
 240     my @x = get_tree $x, 0, $opts->{recurse};
 241     my @y = get_tree $y, 0, $opts->{recurse};
 242     printdebug "trees_diff_walk(..$x,$y..) ".Dumper(\@x,\@y)
 243         if $debuglevel >= 3;
 244     while (@x || @y) {
 245         my $cmp = !@x       <=> !@y          # eg @y empty? $cmp=-1, use x
 246              ||    $x[0][0] cmp  $y[0][0];   # eg, x lt y ? $cmp=-1, use x
 247         my ($n, $ix, $iy);                   # all same? $cmp=0, use both
 248         $ix=$iy='';
 249         printdebug "trees_diff_walk $cmp : @{ $x[0]//[] } | @{ $y[0]//[] }\n"
 250             if $debuglevel >= 3;
 251         ($n, $ix) = @{ shift @x } if $cmp <= 0;
 252         ($n, $iy) = @{ shift @y } if $cmp >= 0;
 253         next if !$all and $ix eq $iy;
 254         printdebug sprintf
 255             "trees_diff_walk(%d,'%s','%s') call('%s','%s','%s')\n",
 256             !!$all,$x,$y, $n,$ix,$iy
 257             if $debuglevel >= 2;
 258         $call->($n, $ix, $iy);
 259     }
 260 }
 261
 262 sub get_differs ($$) {
 263     my ($x,$y) = @_;
 264     # This does a similar job to quiltify_trees_differ, in dgit, a bit.
 265     # But we don't care about modes, or dpkg-source-unrepresentable
 266     # changes, and we don't need the plethora of different modes.
 267     # Conversely we need to distinguish different kinds of changes to
 268     # debian/ and debian/patches/.
 269     # Also, here we have, and want to use, trees_diff_walk, because
 270     # we may be calling this an awful lot and we want it to be fast.
 271
 272     my $differs = 0;
 273     my @debian_info;
 274
 275     no warnings qw(exiting);
 276
 277     my $plain = sub { $_[0] =~ m{^(100|0*)644 blob }s; };
 278
 279     trees_diff_walk "$x:", "$y:", sub {
 280         my ($n,$ix,$iy) = @_;
 281
 282         # analyse difference at the toplevel
 283
 284         if ($n ne 'debian/') {
 285             $differs |= D_UPS;
 286             next;
 287         }
 288         if ($n eq 'debian') {
 289             # one side has a non-tree for ./debian !
 290             $differs |= D_DEB_OTH;
 291             next;
 292         }
 293
 294         my $xd = $ix && "$x:debian";
 295         my $yd = $iy && "$y:debian";
 296         trees_diff_walk $xd, $yd, sub {
 297             my ($n,$ix,$iy) = @_;
 298
 299             # analyse difference in debian/
 300
 301             if ($n eq 'changelog' && (!$ix || $plain->($ix))
 302                                   &&          $plain->($iy) ) {
 303                 $differs |= D_DEB_CLOG;
 304                 next;
 305             }
 306             if ($n ne 'patches/') {
 307                 $differs |= D_DEB_OTH;
 308                 next;
 309             }
 310
 311             my $xp = $ix && "$xd/patches";
 312             my $yp = $iy && "$yd/patches";
 313             trees_diff_walk { recurse=>1 }, $xp, $yp, sub {
 314                 my ($n,$ix,$iy) = @_;
 315
 316                 # analyse difference in debian/patches
 317
 318                 my $ok;
 319                 if ($n =~ m{/$}s) {
 320                     # we are recursing; directories may appear and disappear
 321                     $ok = 1;
 322                 } elsif ($n !~ m/\.series$/s && !$ix && $plain->($iy)) {
 323                     $ok = 1;
 324                 } elsif ($n eq 'series' && $plain->($ix) && $plain->($iy)) {
 325                     my $x_s = (git_cat_file "$xp/series", 'blob');
 326                     my $y_s = (git_cat_file "$yp/series", 'blob');
 327                     chomp $x_s;  $x_s .= "\n";
 328                     $ok = $x_s eq substr($y_s, 0, length $x_s);
 329                 } else {
 330                     # nope
 331                 }
 332                 $differs |= $ok ? D_PAT_ADD : D_PAT_OTH;
 333             };
 334         };
 335     };
 336
 337     printdebug sprintf "get_differs %s %s = %#x\n", $x, $y, $differs;
 338
 339     return $differs;
 340 }
 341
 342 sub commit_pr_info ($) {
 343     my ($r) = @_;
 344     return Data::Dumper->dump([$r], [qw(commit)]);
 345 }
 346
 347 sub calculate_committer_authline () {
 348     my $c = cmdoutput @git, qw(commit-tree --no-gpg-sign -m),
 349         'DUMMY COMMIT (git-debrebase)', "HEAD:";
 350     my ($h,$m) = get_commit $c;
 351     $h =~ m/^committer .*$/m or confess "($h) ?";
 352     return $&;
 353 }
 354
 355 sub rm_subdir_cached ($) {
 356     my ($subdir) = @_;
 357     runcmd @git, qw(rm --quiet -rf --cached --ignore-unmatch), $subdir;
 358 }
 359
 360 sub read_tree_subdir ($$) {
 361     my ($subdir, $new_tree_object) = @_;
 362     rm_subdir_cached $subdir;
 363     runcmd @git, qw(read-tree), "--prefix=$subdir/", $new_tree_object;
 364 }
 365
 366 sub read_tree_debian ($) {
 367     my ($treeish) = @_;
 368     read_tree_subdir 'debian', "$treeish:debian";
 369     rm_subdir_cached 'debian/patches';
 370 }
 371
 372 sub read_tree_upstream ($;$$) {
 373     my ($treeish, $keep_patches, $tree_with_debian) = @_;
 374     # if $tree_with_debian is supplied, will use that for debian/
 375     # otherwise will save and restore it.
 376     my $debian =
 377         $tree_with_debian ? "$tree_with_debian:debian"
 378         : cmdoutput @git, qw(write-tree --prefix=debian/);
 379     runcmd @git, qw(read-tree), $treeish;
 380     read_tree_subdir 'debian', $debian;
 381     rm_subdir_cached 'debian/patches' unless $keep_patches;
 382 };
 383
 384 sub make_commit ($$) {
 385     my ($parents, $message_paras) = @_;
 386     my $tree = cmdoutput @git, qw(write-tree);
 387     my @cmd = (@git, qw(commit-tree), $tree);
 388     push @cmd, qw(-p), $_ foreach @$parents;
 389     push @cmd, qw(-m), $_ foreach @$message_paras;
 390     return cmdoutput @cmd;
 391 }
 392
 393 our @snag_force_opts;
 394 sub snag ($$;@) {
 395     my ($tag,$msg) = @_; # ignores extra args, for benefit of keycommits
 396     if (grep { $_ eq $tag } @snag_force_opts) {
 397         $snags_forced++;
 398         print STDERR "git-debrebase: snag ignored (-f$tag): $msg\n";
 399     } else {
 400         $snags_tripped++;
 401         print STDERR "git-debrebase: snag detected (-f$tag): $msg\n";
 402     }
 403 }
 404
 405 # Important: all mainline code must call snags_maybe_bail after
 406 # any point where snag might be called, but before making changes
 407 # (eg before any call to run_deferred_updates).  snags_maybe_bail
 408 # may be called more than once if necessary (but this is not ideal
 409 # because then the messages about number of snags may be confusing).
 410 sub snags_maybe_bail () {
 411     return if all_snags_summarised();
 412     if ($snags_forced) {
 413         printf STDERR
 414             "%s: snags: %d overriden by individual -f options\n",
 415             $us, $snags_forced;
 416     }
 417     if ($snags_tripped) {
 418         if ($opt_force) {
 419             printf STDERR
 420                 "%s: snags: %d overriden by global --force\n",
 421                 $us, $snags_tripped;
 422         } else {
 423             fail sprintf
 424   "%s: snags: %d blocker(s) (you could -f<tag>, or --force)",
 425                 $us, $snags_tripped;
 426         }
 427     }
 428     $snags_summarised = $snags_forced + $snags_tripped;
 429 }
 430 sub snags_maybe_bail_early () {
 431     # useful to bail out early without doing a lot of work;
 432     # not a substitute for snags_maybe_bail.
 433     snags_maybe_bail() if $snags_tripped && !$opt_force;
 434 }
 435 sub any_snags () {
 436     return $snags_forced || $snags_tripped;
 437 }
 438
 439 sub ffq_prev_branchinfo () {
 440     my $current = git_get_symref();
 441     return gdr_ffq_prev_branchinfo($current);
 442 }
 443
 444 sub record_gdrlast ($$;$) {
 445     my ($gdrlast, $newvalue, $oldvalue) = @_;
 446     $oldvalue ||= $git_null_obj;
 447     push @deferred_updates, "update $gdrlast $newvalue $oldvalue";
 448 }
 449
 450 sub fail_unprocessable ($) {
 451     my ($msg) = @_;
 452     changedir $maindir;
 453     my ($ffqs, $ffqm, $symref, $ffq_prev, $gdrlast) = ffq_prev_branchinfo();
 454
 455     my $mangled = <<END;
 456 Branch/history seems mangled - no longer in gdr format.
 457 See ILLEGAL OPERATIONS in git-debrebase(5).
 458 END
 459     chomp $mangled;
 460
 461     if (defined $ffqm) {
 462         fail <<END;
 463 $msg
 464 Is this meant to be a gdr branch?  $ffqm
 465 END
 466     } elsif (git_get_ref $ffq_prev) {
 467         fail <<END;
 468 $msg
 469 $mangled
 470 Consider git-debrebase scrap, to throw away your recent work.
 471 END
 472     } elsif (!git_get_ref $gdrlast) {
 473         fail <<END;
 474 $msg
 475 Branch does not seem to be meant to be a git-debrebase branch?
 476 Wrong branch, or maybe you needed git-debrebase convert-from-*.
 477 END
 478     } elsif (is_fast_fwd $gdrlast, git_rev_parse 'HEAD') {
 479         fail <<END;
 480 $msg
 481 $mangled
 482 END
 483     } else {
 484         fail <<END;
 485 $msg
 486 Branch/history mangled, and diverged since last git-debrebase.
 487 Maybe you reset to, or rebased from, somewhere inappropriate.
 488 END
 489     }
 490 };
 491
 492 sub gbp_pq_export ($$$) {
 493     my ($bname, $base, $tip) = @_;
 494     # must be run in a workarea.  $bname and patch-queue/$bname
 495     # ought not to exist.  Leaves you on patch-queue/$bname with
 496     # the patches staged but not committed.
 497     # returns 1 if there were any patches
 498     printdebug "gbp_pq_export $bname $base $tip\n";
 499     runcmd @git, qw(checkout -q -b), $bname, $base;
 500     runcmd @git, qw(checkout -q -b), "patch-queue/$bname", $tip;
 501     my @gbp_cmd = (qw(gbp pq export));
 502     my $r = system shell_cmd 'exec >../gbp-pq-err 2>&1', @gbp_cmd;
 503     if ($r) {
 504         { local ($!,$?); copy('../gbp-pq-err', \*STDERR); }
 505         failedcmd @gbp_cmd;
 506     }
 507     return 0 unless stat_exists 'debian/patches';
 508     runcmd @git, qw(add -f debian/patches);
 509     return 1;
 510 }
 511
 512
 513 # MERGE-TODO allow merge resolution separately from laundering, before git merge
 514
 515 # later/rework?
 516 #  use git-format-patch?
 517 #  our own patch identification algorithm?
 518 #  this is an alternative strategy
 519
 520 sub merge_failed ($$;@) {
 521     my ($wrecknotes, $emsg, @xmsgs) = @_;
 522     my @m;
 523     push @m, "Merge resolution failed: $emsg";
 524     push @m, @xmsgs;
 525
 526     changedir $maindir;
 527
 528     my @updates;
 529     merge_wreckage_cleaning \@updates;
 530     run_ref_updates_now "merge failed", \@updates;
 531
 532     @updates = ();
 533     keys %$wrecknotes;
 534     while (my ($k,$v) = each %$wrecknotes) {
 535         push @updates, "create $wrecknoteprefix/$k $v";
 536     }
 537     run_ref_updates_now "merge failed", \@updates;
 538     push @m, "Wreckage left in $wrecknoteprefix/*.";
 539
 540     push @m, "See git-debrebase(1) section FAILED MERGES for suggestions.";
 541
 542     # use finish rather than fail, in case we are within an eval
 543     # (that can happen inside walk!)
 544     print STDERR "\n";
 545     print STDERR "$us: $_\n" foreach @m;
 546     finish 15;
 547 }
 548
 549 sub mwrecknote ($$$) {
 550     my ($wrecknotes, $reftail, $commitish) = @_;
 551     confess unless defined $commitish;
 552     printdebug "mwrecknote $reftail $commitish\n";
 553     $wrecknotes->{$reftail} = $commitish;
 554 }
 555
 556 sub merge_attempt_cmd {
 557     my $wrecknotes = shift @_;
 558     debugcmd '+', @_;
 559     $!=0; $?=-1;
 560     if (system @_) {
 561         merge_failed $wrecknotes,
 562             failedcmd_waitstatus(),
 563             "failed command: @_";
 564     }
 565 }
 566
 567 sub merge_series_patchqueue_convert ($$$);
 568
 569 sub merge_series ($$$;@) {
 570     my ($newbase, $wrecknotes, $base_q, @input_qs) = @_;
 571     # $base_q{SeriesBase}  $input_qs[]{SeriesBase}
 572     # $base_q{SeriesTip}   $input_qs[]{SeriesTip}
 573     # ^ specifies several patch series (currently we only support exactly 2)
 574     # return value is a commit which is the result of
 575     # merging the two versions of the same topic branch
 576     #   $input_q[0] and $input_q[1]
 577     # with respect to the old version
 578     #   $base_q
 579     # all onto $newbase.
 580
 581     # Creates, in *_q, a key MR for its private use
 582
 583     printdebug "merge_series newbase=$newbase\n";
 584
 585     $input_qs[$_]{MR}{S} = $_ foreach (0..$#input_qs);
 586     $base_q->{MR}{S} = 'base';
 587
 588     my %prereq;
 589     # $prereq{<patch filename>}{<possible prereq}{<S>} = 1 or absent
 590     # $prereq{<patch filename>}{<possible prereq}  exists or not (later)
 591     # $prereq{<patch filename>}               exists or not (even later)
 592
 593     my $merged_pq;
 594
 595     my $mwrecknote = sub { &mwrecknote($wrecknotes, @_); };
 596
 597     my $attempt_cmd = sub { &merge_attempt_cmd($wrecknotes, @_); };
 598
 599     local $workarea;
 600     fresh_workarea "merge";
 601     my $seriesfile = "debian/patches/series";
 602     in_workarea sub {
 603         playtree_setup();
 604         foreach my $q ($base_q, reverse @input_qs) {
 605             my $s = $q->{MR}{S};
 606             gbp_pq_export "p-$s", $q->{SeriesBase}, $q->{SeriesTip};
 607             my @earlier;
 608             if (open S, $seriesfile) {
 609                 while (my $patch = <S>) {
 610                     chomp $patch or die $!;
 611                     $prereq{$patch} //= {};
 612                     foreach my $earlier (@earlier) {
 613                         $prereq{$patch}{$earlier}{$s}++ and die;
 614                     }
 615                     push @earlier, $patch;
 616                     stat "debian/patches/$patch" or die "$patch ?";
 617                 }
 618                 S->error and die "$seriesfile $!";
 619                 close S;
 620             } else {
 621                 die "$seriesfile $!" unless $!==ENOENT;
 622             }
 623             read_tree_upstream $newbase, 1;
 624             my $pec = make_commit [ grep { defined } $base_q->{MR}{PEC} ], [
 625                 "Convert $s to patch queue for merging",
 626                 "[git-debrebase merge-innards patch-queue import:".
 627                 " $q->{SeriesTip}]"
 628             ];
 629             printdebug "merge_series  pec $pec ";
 630             runcmd @git, qw(rm -q --ignore-unmatch --cached), $seriesfile;
 631             $pec = make_commit [ $pec ], [
 632                 "Drop series file from $s to avoid merge trouble",
 633                 "[git-debrebase merge-innards patch-queue prep:".
 634                 " $q->{SeriesTip}]"
 635             ];
 636
 637             read_tree_debian $newbase;
 638             if (@earlier) {
 639                 read_tree_subdir 'debian/patches', "$pec:debian/patches";
 640             } else {
 641                 rm_subdir_cached 'debian/patches';
 642             }
 643             $pec = make_commit [ $pec ], [
 644  "Update debian/ (excluding patches) to final to avoid re-merging",
 645  "debian/ was already merged and we need to just take that.",
 646                 "[git-debrebase merge-innards patch-queue packaging:".
 647                 " $q->{SeriesTip}]"
 648             ];
 649
 650             printdebug "pec' $pec\n";
 651             runcmd @git, qw(reset -q --hard), $pec;
 652             $q->{MR}{PEC} = $pec;
 653             $mwrecknote->("$q->{LeftRight}-patchqueue", $pec);
 654         }
 655         # now, because of reverse, we are on $input_q->{MR}{OQC}
 656         runcmd @git, qw(checkout -q -b merge);
 657         printdebug "merge_series merging...\n";
 658         my @mergecmd = (@git, qw(merge --quiet --no-edit), "p-1");
 659
 660         $attempt_cmd->(@mergecmd);
 661
 662         printdebug "merge_series merge ok, series...\n";
 663         # We need to construct a new series file
 664         # Firstly, resolve prereq
 665         foreach my $f (sort keys %prereq) {
 666             printdebug "merge_series  patch\t$f\t";
 667             if (!stat_exists "debian/patches/$f") {
 668                 print DEBUG " drop\n" if $debuglevel;
 669                 # git merge deleted it; that's how we tell it's not wanted
 670                 delete $prereq{$f};
 671                 next;
 672             }
 673             print DEBUG " keep\n" if $debuglevel;
 674             foreach my $g (sort keys %{ $prereq{$f} }) {
 675                 my $gfp = $prereq{$f}{$g};
 676                 printdebug "merge_series  prereq\t$f\t-> $g\t";
 677                 if (!!$gfp->{0} == !!$gfp->{1}
 678                     ? $gfp->{0}
 679                     : !$gfp->{base}) {
 680                     print DEBUG "\tkeep\n" if $debuglevel;
 681                 } else {
 682                     print DEBUG "\tdrop\n" if $debuglevel;
 683                     delete $prereq{$f}{$g};
 684                 }
 685             }
 686         }
 687
 688         my $unsat = sub {
 689             my ($f) = @_;
 690             return scalar keys %{ $prereq{$f} };
 691         };
 692
 693         my $nodate = time + 1;
 694         my %authordate;
 695         # $authordate{<patch filename>};
 696         my $authordate = sub {
 697             my ($f) = @_;
 698             $authordate{$f} //= do {
 699                 open PF, "<", "debian/patches/$f" or die "$f $!";
 700                 while (<PF>) {
 701                     return $nodate if m/^$/;
 702                     last if s{^Date: }{};
 703                 }
 704                 chomp;
 705                 return cmdoutput qw(date +%s -d), $_;
 706             };
 707         };
 708
 709         open NS, '>', $seriesfile or die $!;
 710
 711         while (keys %prereq) {
 712             my $best;
 713             foreach my $try (sort keys %prereq) {
 714                 if ($best) {
 715                     next if (
 716                              $unsat->($try) <=> $unsat->($best) or
 717                              $authordate->($try) <=> $authordate->($best) or
 718                              $try cmp $best
 719                             ) >= 0;
 720                 }
 721                 $best = $try;
 722             }
 723             printdebug "merge_series series next $best\n";
 724             print NS "$best\n" or die $!;
 725             delete $prereq{$best};
 726             foreach my $gp (values %prereq) {
 727                 delete $gp->{$best};
 728             }
 729         }
 730
 731         runcmd @git, qw(add), $seriesfile;
 732         runcmd @git, qw(commit --quiet -m), 'Merged patch queue form';
 733         $merged_pq = git_rev_parse 'HEAD';
 734         $mwrecknote->('merged-patchqueue', $merged_pq);
 735     };
 736     return merge_series_patchqueue_convert
 737             $wrecknotes, $newbase, $merged_pq;
 738 }
 739
 740 sub merge_series_patchqueue_convert ($$$) {
 741     my ($wrecknotes, $newbase, $merged_pq) = @_;
 742
 743     my $result;
 744     in_workarea sub {
 745         playtree_setup();
 746         printdebug "merge_series series gbp pq import\n";
 747         runcmd @git, qw(checkout -q -b mergec), $merged_pq;
 748
 749         merge_attempt_cmd($wrecknotes, qw(gbp pq import));
 750         # MERGE-TODO consider git-format-patch etc. instead,
 751         # since gbp pq doesn't always round-trip :-/
 752
 753         # OK now we are on patch-queue/merge, and we need to rebase
 754         # onto the intended parent and drop the patches from each one
 755
 756         printdebug "merge_series series ok, building...\n";
 757         my $build = $newbase;
 758         my @lcmd = (@git, qw(rev-list --reverse mergec..patch-queue/mergec));
 759         foreach my $c (grep /./, split /\n/, cmdoutput @lcmd) {
 760             my $commit = git_cat_file $c, 'commit';
 761             printdebug "merge_series series ok, building $c\n";
 762             read_tree_upstream $c, 0, $newbase;
 763             my $tree = cmdoutput @git, qw(write-tree);
 764             $commit =~ s{^parent (\S+)$}{parent $build}m or confess;
 765             $commit =~ s{^tree (\S+)$}{tree $tree}m      or confess;
 766             open C, ">", "../mcommit" or die $!;
 767             print C $commit or die $!;
 768             close C or die $!;
 769             $build = cmdoutput @git, qw(hash-object -w -t commit ../mcommit);
 770         }
 771         $result = $build;
 772         mwrecknote($wrecknotes, 'merged-result', $result);
 773
 774         runcmd @git, qw(update-ref refs/heads/result), $result;
 775
 776         runcmd @git, qw(checkout -q -b debug);
 777         runcmd @git, qw(commit --allow-empty -q -m M-INDEX);
 778         runcmd @git, qw(add .);
 779         runcmd @git, qw(commit --allow-empty -q -m M-WORKTREE);
 780         my $mdebug = git_rev_parse 'HEAD';
 781         printdebug sprintf "merge_series done debug=%s\n", $mdebug;
 782         mwrecknote($wrecknotes, 'merged-debug', $mdebug);
 783     };
 784     printdebug "merge_series returns $result\n";
 785     return $result;
 786 }
 787
 788 # classify returns an info hash like this
 789 #   CommitId => $objid
 790 #   Hdr => # commit headers, including 1 final newline
 791 #   Msg => # commit message (so one newline is dropped)
 792 #   Tree => $treeobjid
 793 #   Type => (see below)
 794 #   Parents = [ {
 795 #       Ix => $index # ie 0, 1, 2, ...
 796 #       CommitId
 797 #       Differs => return value from get_differs
 798 #       IsOrigin
 799 #       IsDggitImport => 'orig' 'tarball' 'unpatched' 'package' (as from dgit)
 800 #     } ...]
 801 #   NewMsg => # commit message, but with any [dgit import ...] edited
 802 #             # to say "[was: ...]"
 803 #
 804 # Types:
 805 #   Packaging
 806 #   Changelog
 807 #   Upstream
 808 #   AddPatches
 809 #   Mixed
 810 #
 811 #   Pseudomerge
 812 #     has additional entres in classification result
 813 #       Overwritten = [ subset of Parents ]
 814 #       Contributor = $the_remaining_Parent
 815 #
 816 #   DgitImportUnpatched
 817 #     has additional entry in classification result
 818 #       OrigParents = [ subset of Parents ]
 819 #
 820 #   Anchor
 821 #     has additional entry in classification result
 822 #       OrigParents = [ subset of Parents ]  # singleton list
 823 #
 824 #   TreatAsAnchor
 825 #
 826 #   BreakwaterStart
 827 #
 828 #   Unknown
 829 #     has additional entry in classification result
 830 #       Why => "prose"
 831
 832 sub parsecommit ($;$) {
 833     my ($objid, $p_ref) = @_;
 834     # => hash with                   CommitId Hdr Msg Tree Parents
 835     #    Parents entries have only   Ix CommitId
 836     #    $p_ref, if provided, must be [] and is used as a base for Parents
 837
 838     $p_ref //= [];
 839     die if @$p_ref;
 840
 841     my ($h,$m) = get_commit $objid;
 842
 843     my ($t) = $h =~ m/^tree (\w+)$/m or die $objid;
 844     my (@ph) = $h =~ m/^parent (\w+)$/mg;
 845
 846     my $r = {
 847         CommitId => $objid,
 848         Hdr => $h,
 849         Msg => $m,
 850         Tree => $t,
 851         Parents => $p_ref,
 852     };
 853
 854     foreach my $ph (@ph) {
 855         push @$p_ref, {
 856             Ix => scalar @$p_ref,
 857             CommitId => $ph,
 858         };
 859     }
 860
 861     return $r;
 862 }
 863
 864 sub classify ($) {
 865     my ($objid) = @_;
 866
 867     my @p;
 868     my $r = parsecommit($objid, \@p);
 869     my $t = $r->{Tree};
 870
 871     foreach my $p (@p) {
 872         $p->{Differs} = (get_differs $p->{CommitId}, $t),
 873     }
 874
 875     printdebug "classify $objid \$t=$t \@p",
 876         (map { sprintf " %s/%#x", $_->{CommitId}, $_->{Differs} } @p),
 877         "\n";
 878
 879     my $classify = sub {
 880         my ($type, @rest) = @_;
 881         $r = { %$r, Type => $type, @rest };
 882         if ($debuglevel) {
 883             printdebug " = $type ".(dd $r)."\n";
 884         }
 885         return $r;
 886     };
 887     my $unknown = sub {
 888         my ($why) = @_;
 889         $r = { %$r, Type => qw(Unknown), Why => $why };
 890         printdebug " ** Unknown\n";
 891         return $r;
 892     };
 893
 894     if (grep { $_ eq $objid } @opt_anchors) {
 895         return $classify->('TreatAsAnchor');
 896     }
 897
 898     my @identical = grep { !$_->{Differs} } @p;
 899     my ($stype, $series) = git_cat_file "$t:debian/patches/series";
 900     my $haspatches = $stype ne 'missing' && $series =~ m/^\s*[^#\n\t ]/m;
 901
 902     if ($r->{Msg} =~ m{^\[git-debrebase anchor.*\]$}m) {
 903         # multi-orig upstreams are represented with an anchor merge
 904         # from a single upstream commit which combines the orig tarballs
 905
 906         # Every anchor tagged this way must be a merge.
 907         # We are relying on the
 908         #     [git-debrebase anchor: ...]
 909         # commit message annotation in "declare" anchor merges (which
 910         # do not have any upstream changes), to distinguish those
 911         # anchor merges from ordinary pseudomerges (which we might
 912         # just try to strip).
 913         #
 914         # However, the user is going to be doing git-rebase a lot.  We
 915         # really don't want them to rewrite an anchor commit.
 916         # git-rebase trips up on merges, so that is a useful safety
 917         # catch.
 918         #
 919         # BreakwaterStart commits are also anchors in the terminology
 920         # of git-debrebase(5), but they are untagged (and always
 921         # manually generated).
 922         #
 923         # We cannot not tolerate any tagged linear commit (ie,
 924         # BreakwaterStart commits tagged `[anchor:') because such a
 925         # thing could result from an erroneous linearising raw git
 926         # rebase of a merge anchor.  That would represent a corruption
 927         # of the branch. and we want to detect and reject the results
 928         # of such corruption before it makes it out anywhere.  If we
 929         # reject it here then we avoid making the pseudomerge which
 930         # would be needed to push it.
 931
 932         my $badanchor = sub { $unknown->("git-debrebase \`anchor' but @_"); };
 933         @p == 2 or return $badanchor->("has other than two parents");
 934         $haspatches and return $badanchor->("contains debian/patches");
 935
 936         # How to decide about l/r ordering of anchors ?  git
 937         # --topo-order prefers to expand 2nd parent first.  There's
 938         # already an easy rune to look for debian/ history anyway (git log
 939         # debian/) so debian breakwater branch should be 1st parent; that
 940         # way also there's also an easy rune to look for the upstream
 941         # patches (--topo-order).
 942
 943         # Also this makes --first-parent be slightly more likely to
 944         # be useful - it makes it provide a linearised breakwater history.
 945
 946         # Of course one can say somthing like
 947         #  gitk -- ':/' ':!/debian'
 948         # to get _just_ the commits touching upstream files, and by
 949         # the TREESAME logic in git-rev-list this will leave the
 950         # breakwater into upstream at the first anchor.  But that
 951         # doesn't report debian/ changes at all.
 952
 953         # Other observations about gitk: by default, gitk seems to
 954         # produce output in a different order to git-rev-list.  I
 955         # can't seem to find this documented anywhere.  gitk
 956         # --date-order DTRT.  But, gitk always seems to put the
 957         # parents from left to right, in order, so it's easy to see
 958         # which way round a pseudomerge is.
 959
 960         $p[0]{IsOrigin} and $badanchor->("is an origin commit");
 961         $p[1]{Differs} & ~DS_DEB and
 962             $badanchor->("upstream files differ from left parent");
 963         $p[0]{Differs} & ~D_UPS and
 964             $badanchor->("debian/ differs from right parent");
 965
 966         return $classify->(qw(Anchor),
 967                            OrigParents => [ $p[1] ]);
 968     }
 969
 970     if (@p == 1) {
 971         my $d = $r->{Parents}[0]{Differs};
 972         if ($d == D_PAT_ADD) {
 973             return $classify->(qw(AddPatches));
 974         } elsif ($d & (D_PAT_ADD|D_PAT_OTH)) {
 975             return $unknown->("edits debian/patches");
 976         } elsif ($d & DS_DEB and !($d & ~DS_DEB)) {
 977             my ($ty,$dummy) = git_cat_file "$p[0]{CommitId}:debian";
 978             if ($ty eq 'tree') {
 979                 if ($d == D_DEB_CLOG) {
 980                     return $classify->(qw(Changelog));
 981                 } else {
 982                     return $classify->(qw(Packaging));
 983                 }
 984             } elsif ($ty eq 'missing') {
 985                 return $classify->(qw(BreakwaterStart));
 986             } else {
 987                 return $unknown->("parent's debian is not a directory");
 988             }
 989         } elsif ($d == D_UPS) {
 990             return $classify->(qw(Upstream));
 991         } elsif ($d & DS_DEB and $d & D_UPS and !($d & ~(DS_DEB|D_UPS))) {
 992             return $classify->(qw(Mixed));
 993         } elsif ($d == 0) {
 994             return $unknown->("no changes");
 995         } else {
 996             confess "internal error $objid ?";
 997         }
 998     }
 999     if (!@p) {
1000         return $unknown->("origin commit");
1001     }
1002
1003     if (@p == 2 && @identical == 1) {
1004         my @overwritten = grep { $_->{Differs} } @p;
1005         confess "internal error $objid ?" unless @overwritten==1;
1006         return $classify->(qw(Pseudomerge),
1007                            Overwritten => [ $overwritten[0] ],
1008                            Contributor => $identical[0]);
1009     }
1010     if (@p == 2 && @identical == 2) {
1011         my $get_t = sub {
1012             my ($ph,$pm) = get_commit $_[0]{CommitId};
1013             $ph =~ m/^committer .* (\d+) [-+]\d+$/m or die "$_->{CommitId} ?";
1014             $1;
1015         };
1016         my @bytime = @p;
1017         my $order = $get_t->($bytime[0]) <=> $get_t->($bytime[1]);
1018         if ($order > 0) { # newer first
1019         } elsif ($order < 0) {
1020             @bytime = reverse @bytime;
1021         } else {
1022             # same age, default to order made by -s ours
1023             # that is, commit was made by someone who preferred L
1024         }
1025         return $classify->(qw(Pseudomerge),
1026                            SubType => qw(Ambiguous),
1027                            Contributor => $bytime[0],
1028                            Overwritten => [ $bytime[1] ]);
1029     }
1030     foreach my $p (@p) {
1031         my ($p_h, $p_m) = get_commit $p->{CommitId};
1032         $p->{IsOrigin} = $p_h !~ m/^parent \w+$/m;
1033         ($p->{IsDgitImport},) = $p_m =~ m/^\[dgit import ([0-9a-z]+) .*\]$/m;
1034     }
1035     my @orig_ps = grep { ($_->{IsDgitImport}//'X') eq 'orig' } @p;
1036     my $m2 = $r->{Msg};
1037     if (!(grep { !$_->{IsOrigin} } @p) and
1038         (@orig_ps >= @p - 1) and
1039         $m2 =~ s{^\[(dgit import unpatched .*)\]$}{[was: $1]}m) {
1040         $r->{NewMsg} = $m2;
1041         return $classify->(qw(DgitImportUnpatched),
1042                            OrigParents => \@orig_ps);
1043     }
1044
1045     if (@p == 2 and
1046         $r->{Msg} =~ m{^\[git-debrebase merged-breakwater.*\]$}m) {
1047         return $classify->("MergedBreakwaters");
1048     }
1049     if ($r->{Msg} =~ m{^\[(git-debrebase|dgit)[: ].*\]$}m) {
1050         return $unknown->("unknown kind of merge from $1");
1051     }
1052     if (@p > 2) {
1053         return $unknown->("octopus merge");
1054     }
1055
1056     if (!$opt_merges) {
1057         return $unknown->("general two-parent merge");
1058     }
1059
1060     return $classify->("VanillaMerge");
1061 }
1062
1063 sub keycommits ($;$$$$$);
1064
1065 sub mergedbreakwaters_anchor ($) {
1066     my ($cl) = @_;
1067     my $best_anchor;
1068     foreach my $p (@{ $cl->{Parents} }) {
1069         my ($panchor, $pbw) = keycommits $p->{CommitId},
1070             undef,undef,undef,undef, 1;
1071         $best_anchor = $panchor
1072             if !defined $best_anchor
1073             or is_fast_fwd $best_anchor, $panchor;
1074         fail "inconsistent anchors in merged-breakwaters $p->{CommitId}"
1075             unless is_fast_fwd $panchor, $best_anchor;
1076     }
1077     return $best_anchor;
1078 }
1079
1080 sub keycommits ($;$$$$$) {
1081     my ($head, $furniture, $unclean, $trouble, $fatal, $claimed_bw) = @_;
1082     # => ($anchor, $breakwater)
1083
1084     # $unclean->("unclean-$tagsfx", $msg, $cl)
1085     # $furniture->("unclean-$tagsfx", $msg, $cl)
1086     # $dgitimport->("unclean-$tagsfx", $msg, $cl))
1087     #   is callled for each situation or commit that
1088     #   wouldn't be found in a laundered branch
1089     # $furniture is for furniture commits such as might be found on an
1090     #   interchange branch (pseudomerge, d/patches, changelog)
1091     # $trouble is for things whnich prevent the return of
1092     #   anchor and breakwater information; if that is ignored,
1093     #   then keycommits returns (undef, undef) instead.
1094     # $fatal is for unprocessable commits, and should normally cause
1095     #    a failure.  If ignored, agaion, (undef, undef) is returned.
1096     #
1097     # If $claimed_bw, this is supposed to be a breakwater commit.
1098     #
1099     # If a callback is undef, fail is called instead.
1100     # If a callback is defined but false, the situation is ignored.
1101     # Callbacks may say:
1102     #   no warnings qw(exiting); last;
1103     # if the answer is no longer wanted.
1104
1105     my ($anchor, $breakwater);
1106     $breakwater = $head if $claimed_bw;
1107     my $clogonly;
1108     my $cl;
1109     my $found_pm;
1110     $fatal //= sub { fail_unprocessable $_[1]; };
1111     my $x = sub {
1112         my ($cb, $tagsfx, $mainwhy, $xwhy) = @_;
1113         my $why = $mainwhy.$xwhy;
1114         my $m = "branch needs laundering (run git-debrebase): $why";
1115         fail $m unless defined $cb;
1116         return unless $cb;
1117         $cb->("unclean-$tagsfx", $why, $cl, $mainwhy);
1118     };
1119     my $found_anchor = sub {
1120         ($anchor) = @_;
1121         $breakwater //= $clogonly;
1122         $breakwater //= $head;
1123         no warnings qw(exiting);
1124         last;
1125     };
1126     for (;;) {
1127         $cl = classify $head;
1128         my $ty = $cl->{Type};
1129         if ($ty eq 'Packaging') {
1130             $breakwater //= $clogonly;
1131             $breakwater //= $head;
1132         } elsif ($ty eq 'Changelog') {
1133             # this is going to count as the tip of the breakwater
1134             # only if it has no upstream stuff before it
1135             $clogonly //= $head;
1136         } elsif ($ty eq 'Anchor' or
1137                  $ty eq 'TreatAsAnchor' or
1138                  $ty eq 'BreakwaterStart') {
1139             $found_anchor->($head);
1140         } elsif ($ty eq 'Upstream') {
1141             $x->($unclean, 'ordering',
1142  "packaging change ($breakwater) follows upstream change"," (eg $head)")
1143                 if defined $breakwater;
1144             $clogonly = undef;
1145             $breakwater = undef;
1146         } elsif ($ty eq 'Mixed') {
1147             $x->($unclean, 'mixed',
1148                  "found mixed upstream/packaging commit"," ($head)");
1149             $clogonly = undef;
1150             $breakwater = undef;
1151         } elsif ($ty eq 'Pseudomerge' or
1152                  $ty eq 'AddPatches') {
1153             my $found_pm = 1;
1154             $x->($furniture, (lc $ty),
1155                  "found interchange bureaucracy commit ($ty)"," ($head)");
1156         } elsif ($ty eq 'DgitImportUnpatched') {
1157             if ($found_pm) {
1158                 $x->($trouble, 'dgitimport',
1159                      "found dgit dsc import"," ($head)");
1160                 return (undef,undef);
1161             } else {
1162                 $x->($fatal, 'unprocessable',
1163                      "found bare dgit dsc import with no prior history",
1164                      " ($head)");
1165                 return (undef,undef);
1166             }
1167         } elsif ($ty eq 'VanillaMerge') {
1168             $x->($trouble, 'vanillamerge',
1169                  "found vanilla merge"," ($head)");
1170             return (undef,undef);
1171         } elsif ($ty eq 'MergedBreakwaters') {
1172             $found_anchor->(mergedbreakwaters_anchor $cl);
1173         } else {
1174             $x->($fatal, 'unprocessable',
1175                  "found unprocessable commit, cannot cope: $cl->{Why}",
1176                  " ($head)");
1177             return (undef,undef);
1178         }
1179         $head = $cl->{Parents}[0]{CommitId};
1180     }
1181     return ($anchor, $breakwater);
1182 }
1183
1184 sub walk ($;$$$);
1185 sub walk ($;$$$) {
1186     my ($input,
1187         $nogenerate,$report, $report_lprefix) = @_;
1188     # => ($tip, $breakwater_tip, $last_anchor)
1189     # (or nothing, if $nogenerate)
1190
1191     printdebug "*** WALK $input ".($nogenerate//0)." ".($report//'-')."\n";
1192     $report_lprefix //= '';
1193
1194     # go through commits backwards
1195     # we generate two lists of commits to apply:
1196     # breakwater branch and upstream patches
1197     my (@brw_cl, @upp_cl, @processed);
1198     my %found;
1199     my $upp_limit;
1200     my @pseudomerges;
1201
1202     my $cl;
1203     my $xmsg = sub {
1204         my ($prose, $info) = @_;
1205         my $ms = $cl->{Msg};
1206         chomp $ms;
1207         confess unless defined $info;
1208         $ms .= "\n\n[git-debrebase $info: $prose]\n";
1209         return (Msg => $ms);
1210     };
1211     my $rewrite_from_here = sub {
1212         my ($cl) = @_;
1213         my $sp_cl = { SpecialMethod => 'StartRewrite' };
1214         push @$cl, $sp_cl;
1215         push @processed, $sp_cl;
1216     };
1217     my $cur = $input;
1218
1219     my $prdelim = "";
1220     my $prprdelim = sub { print $report $prdelim if $report; $prdelim=""; };
1221
1222     my $prline = sub {
1223         return unless $report;
1224         print $report $prdelim, $report_lprefix, @_;
1225         $prdelim = "\n";
1226     };
1227
1228     my $bomb = sub { # usage: return $bomb->();
1229         print $report " Unprocessable" if $report;
1230         print $report " ($cl->{Why})" if $report && defined $cl->{Why};
1231         $prprdelim->();
1232         if ($nogenerate) {
1233             return (undef,undef);
1234         }
1235         fail_unprocessable "found unprocessable commit, cannot cope".
1236             (defined $cl->{Why} ? "; $cl->{Why}:": ':').
1237             " (commit $cur) (d.".
1238             (join ' ', map { sprintf "%#x", $_->{Differs} }
1239              @{ $cl->{Parents} }).
1240                  ")";
1241     };
1242
1243     my $build;
1244     my $breakwater;
1245
1246     my $build_start = sub {
1247         my ($msg, $parent) = @_;
1248         $prline->(" $msg");
1249         $build = $parent;
1250         no warnings qw(exiting); last;
1251     };
1252
1253     my $nomerge = sub {
1254         my ($emsg) = @_;
1255         merge_failed $cl->{MergeWreckNotes}, $emsg;
1256     };
1257
1258     my $mwrecknote = sub { &mwrecknote($cl->{MergeWreckNotes}, @_); };
1259
1260     my $last_anchor;
1261
1262     for (;;) {
1263         $cl = classify $cur;
1264         $cl->{MergeWreckNotes} //= {};
1265         my $ty = $cl->{Type};
1266         my $st = $cl->{SubType};
1267         $prline->("$cl->{CommitId} $cl->{Type}");
1268         $found{$ty. ( defined($st) ? "-$st" : '' )}++;
1269         push @processed, $cl;
1270         my $p0 = @{ $cl->{Parents} }==1 ? $cl->{Parents}[0]{CommitId} : undef;
1271         if ($ty eq 'AddPatches') {
1272             $cur = $p0;
1273             $rewrite_from_here->(\@upp_cl);
1274             next;
1275         } elsif ($ty eq 'Packaging' or $ty eq 'Changelog') {
1276             push @brw_cl, $cl;
1277             $cur = $p0;
1278             next;
1279         } elsif ($ty eq 'BreakwaterStart') {
1280             $last_anchor = $cur;
1281             $build_start->('FirstPackaging', $cur);
1282         } elsif ($ty eq 'Upstream') {
1283             push @upp_cl, $cl;
1284             $cur = $p0;
1285             next;
1286         } elsif ($ty eq 'Mixed') {
1287             my $queue = sub {
1288                 my ($q, $wh) = @_;
1289                 my $cls = { %$cl, $xmsg->("mixed commit: $wh part",'split') };
1290                 push @$q, $cls;
1291             };
1292             $queue->(\@brw_cl, "debian");
1293             $queue->(\@upp_cl, "upstream");
1294             $rewrite_from_here->(\@brw_cl);
1295             $cur = $p0;
1296             next;
1297         } elsif ($ty eq 'Pseudomerge') {
1298             my $contrib = $cl->{Contributor}{CommitId};
1299             print $report " Contributor=$contrib" if $report;
1300             push @pseudomerges, $cl;
1301             $rewrite_from_here->(\@upp_cl);
1302             $cur = $contrib;
1303             next;
1304         } elsif ($ty eq 'Anchor' or $ty eq 'TreatAsAnchor') {
1305             $last_anchor = $cur;
1306             $build_start->("Anchor", $cur);
1307         } elsif ($ty eq 'DgitImportUnpatched') {
1308             my $pm = $pseudomerges[-1];
1309             if (defined $pm) {
1310                 # To an extent, this is heuristic.  Imports don't have
1311                 # a useful history of the debian/ branch.  We assume
1312                 # that the first pseudomerge after an import has a
1313                 # useful history of debian/, and ignore the histories
1314                 # from later pseudomerges.  Often the first pseudomerge
1315                 # will be the dgit import of the upload to the actual
1316                 # suite intended by the non-dgit NMUer, and later
1317                 # pseudomerges may represent in-archive copies.
1318                 my $ovwrs = $pm->{Overwritten};
1319                 printf $report " PM=%s \@Overwr:%d",
1320                     $pm->{CommitId}, (scalar @$ovwrs)
1321                     if $report;
1322                 if (@$ovwrs != 1) {
1323                     printdebug "*** WALK BOMB DgitImportUnpatched\n";
1324                     return $bomb->();
1325                 }
1326                 my $ovwr = $ovwrs->[0]{CommitId};
1327                 printf $report " Overwr=%s", $ovwr if $report;
1328                 # This import has a tree which is just like a
1329                 # breakwater tree, but it has the wrong history.  It
1330                 # ought to have the previous breakwater (which the
1331                 # pseudomerge overwrote) as an ancestor.  That will
1332                 # make the history of the debian/ files correct.  As
1333                 # for the upstream version: either it's the same as
1334                 # was ovewritten (ie, same as the previous
1335                 # breakwater), in which case that history is precisely
1336                 # right; or, otherwise, it was a non-gitish upload of a
1337                 # new upstream version.  We can tell these apart by
1338                 # looking at the tree of the supposed upstream.
1339                 push @brw_cl, {
1340                     %$cl,
1341                     SpecialMethod => 'DgitImportDebianUpdate',
1342                     $xmsg->("debian changes", 'convert dgit import')
1343                 }, {
1344                     %$cl,
1345                     SpecialMethod => 'DgitImportUpstreamUpdate',
1346                     $xmsg->("convert dgit import: upstream update",
1347                             "anchor")
1348                 };
1349                 $prline->(" Import");
1350                 $rewrite_from_here->(\@brw_cl);
1351                 $upp_limit //= $#upp_cl; # further, deeper, patches discarded
1352                 $cur = $ovwr;
1353                 next;
1354             } else {
1355                 # Everything is from this import.  This kind of import
1356                 # is already nearly in valid breakwater format, with the
1357                 # patches as commits.  Unfortunately it contains
1358                 # debian/patches/.
1359                 printdebug "*** WALK BOMB bare dgit import\n";
1360                 $cl->{Why} = "bare dgit dsc import";
1361                 return $bomb->();
1362             }
1363             die "$ty ?";
1364         } elsif ($ty eq 'MergedBreakwaters') {
1365             $last_anchor = mergedbreakwaters_anchor $cl;
1366             $build_start->(' MergedBreakwaters', $cur);
1367             last;
1368         } elsif ($ty eq 'VanillaMerge') {
1369             # User may have merged unstitched branch(es).  We will
1370             # have now lost what ffq-prev was then (since the later
1371             # pseudomerge may introduce further changes).  The effect
1372             # of resolving such a merge is that we may have to go back
1373             # further in history to find a merge base, since the one
1374             # which was reachable via ffq-prev is no longer findable.
1375             # This is suboptimal, but if it all works we'll have done
1376             # the right thing.
1377             # MERGE-TODO we should warn the user in the docs about this
1378
1379             my $ok=1;
1380             my $best_anchor;
1381             # We expect to find a dominating anchor amongst the
1382             # inputs' anchors.  That will be the new anchor.
1383             #
1384             # More complicated is finding a merge base for the
1385             # breakwaters.  We need a merge base that is a breakwater
1386             # commit.  The ancestors of breakwater commits are more
1387             # breakwater commits and possibly upstream commits and the
1388             # ancestors of those upstream.  Upstreams might have
1389             # arbitrary ancestors.  But any upstream commit U is
1390             # either included in both anchors, in which case the
1391             # earlier anchor is a better merge base than any of U's
1392             # ancestors; or U is not included in the older anchor, in
1393             # which case U is not an ancestor of the vanilla merge at
1394             # all.  So no upstream commit, nor any ancestor thereof,
1395             # is a best merge base.  As for non-breakwater Debian
1396             # commits: these are never ancestors of any breakwater.
1397             #
1398             # So any best merge base as found by git-merge-base
1399             # is a suitable breakwater anchor.  Usually there will
1400             # be only one.
1401
1402             printdebug "*** MERGE\n";
1403
1404             my @bwbcmd = (@git, qw(merge-base));
1405             my @ibcmd = (@git, qw(merge-base --all));
1406             my $might_be_in_bw = 1;
1407
1408             my $ps = $cl->{Parents};
1409
1410             $mwrecknote->('vanilla-merge', $cl->{CommitId});
1411
1412             foreach my $p (@$ps) {
1413                 $prline->(" VanillaMerge ".$p->{Ix});
1414                 $prprdelim->();
1415                 my ($ptip, $pbw, $panchor) =
1416                     walk $p->{CommitId}, 0, $report,
1417                          $report_lprefix.'  ';
1418                 $p->{Laundered} = $p->{SeriesTip} = $ptip;
1419                 $p->{Breakwater} = $p->{SeriesBase} = $pbw;
1420                 $p->{Anchor} = $panchor;
1421
1422                 my $lr = $p->{LeftRight} = (qw(left right))[$p->{Ix}];
1423                 $mwrecknote->("$lr-input", $p->{CommitId});
1424
1425                 my $mwrecknote_parent = sub {
1426                     my ($which) = @_;
1427                     $mwrecknote->("$lr-".(lc $which), $p->{$which});
1428                 };
1429                 $mwrecknote_parent->('Laundered');
1430                 $mwrecknote_parent->('Breakwater');
1431                 $mwrecknote_parent->('Anchor');
1432
1433                 $best_anchor = $panchor if
1434                     !defined $best_anchor or
1435                     is_fast_fwd $best_anchor, $panchor;
1436
1437                 printdebug " MERGE BA best=".($best_anchor//'-').
1438                     " p=$panchor\n";
1439             }
1440
1441             $mwrecknote->('result-anchor', $best_anchor);
1442
1443             foreach my $p (@$ps) {
1444                 $prline->(" VanillaMerge ".$p->{Ix});
1445                 if (!is_fast_fwd $p->{Anchor}, $best_anchor) {
1446                     $nomerge->('divergent anchors');
1447                 } elsif ($p->{Anchor} eq $best_anchor) {
1448                     print $report " SameAnchor" if $report;
1449                 } else {
1450                     print $report " SupersededAnchor" if $report;
1451                 }
1452                 if ($p->{Breakwater} eq $p->{CommitId}) {
1453                     # this parent commit was its own breakwater,
1454                     # ie it is part of the breakwater
1455                     print $report " Breakwater" if $report;
1456                 } else {
1457                     $might_be_in_bw = 0;
1458                 }
1459                 push @bwbcmd, $p->{Breakwater};
1460                 push @ibcmd, $p->{CommitId};
1461             }
1462
1463             if ($ok && $might_be_in_bw) {
1464                 # We could rewrite this to contaion the metadata
1465                 # declaring it to be MergedBreakwaters, but
1466                 # unnecessarily rewriting a merge seems unhelpful.
1467                 $prline->(" VanillaMerge MergedBreakwaters");
1468                 $last_anchor = $best_anchor;
1469                 $build_start->('MergedBreakwaters', $cur);
1470             }
1471
1472             my $bwb = cmdoutput @bwbcmd;
1473
1474             # OK, now we have a breakwater base, but we need the merge
1475             # base for the interchange branch because we need the delta
1476             # queue.
1477             #
1478             # This a the best merge base of our inputs which has the
1479             # breakwater merge base as an ancestor.
1480
1481             my @ibs =
1482                 grep /./,
1483                 split /\n/,
1484                 cmdoutput @ibcmd;
1485
1486             @ibs or confess 'internal error, expected anchor at least ?';
1487
1488             my $ib;
1489             my $ibleaf;
1490             foreach my $tibix (0..$#ibs) {
1491                 my $tib = $ibs[$tibix];
1492                 my $ff = is_fast_fwd $bwb, $tib;
1493                 my $ok = !$ff ? 'rej' : $ib ? 'extra' : 'ok';
1494                 my $tibleaf = "interchange-mbcand-$ok-$tibix";
1495                 $mwrecknote->($tibleaf, $tib);
1496                 next unless $ff;
1497                 next if $ib;
1498                 $ib = $tib;
1499                 $ibleaf = $tibleaf;
1500             }
1501
1502             $ib or $nomerge->("no suitable interchange merge base");
1503
1504             $prline->("  VanillaMerge Base");
1505             $prprdelim->();
1506             my ($btip, $bbw, $banchor) = eval {
1507                 walk $ib, 0, $report, $report_lprefix.'  ';
1508             };
1509             $nomerge->("walking interchange branch merge base ($ibleaf):\n".
1510                        $@)
1511                 if length $@;
1512
1513             $mwrecknote->("mergebase-laundered", $btip);
1514             $mwrecknote->("mergebase-breakwater", $bbw);
1515             $mwrecknote->("mergebase-anchor", $banchor);
1516
1517             my $ibinfo = { SeriesTip => $btip,
1518                            SeriesBase => $bbw,
1519                            Anchor => $banchor,
1520                            LeftRight => 'mergebase' };
1521
1522             $bbw eq $bwb
1523                 or $nomerge->("interchange merge-base ($ib)'s".
1524                               " breakwater ($bbw)".
1525                               " != breakwaters' merge-base ($bwb)");
1526
1527             grep { $_->{Anchor} eq $ibinfo->{Anchor} } @$ps
1528                  or $nomerge->("interchange merge-base ($ib)'s".
1529                                " anchor ($ibinfo->{SeriesBase})".
1530                                " != any merge input's anchor (".
1531                                (join ' ', map { $_->{Anchor} } @$ps).
1532                                ")");
1533
1534             $cl->{MergeInterchangeBaseInfo} = $ibinfo;
1535             $cl->{MergeBestAnchor} = $best_anchor;
1536             push @brw_cl, {
1537                 %$cl,
1538                 SpecialMethod => 'MergeCreateMergedBreakwaters',
1539                 $xmsg->('constructed from vanilla merge',
1540                         'merged-breakwater'),
1541             };
1542             push @upp_cl, {
1543                 %$cl,
1544                 SpecialMethod => 'MergeMergeSeries',
1545             };
1546             $build_start->('MergeBreakwaters', $cur);
1547         } else {
1548             printdebug "*** WALK BOMB unrecognised\n";
1549             return $bomb->();
1550         }
1551     }
1552     $prprdelim->();
1553
1554     printdebug "*** WALK prep done cur=$cur".
1555         " brw $#brw_cl upp $#upp_cl proc $#processed pm $#pseudomerges\n";
1556
1557     return if $nogenerate;
1558
1559     # Now we build it back up again
1560
1561     fresh_workarea();
1562
1563     my $rewriting = 0;
1564
1565     $#upp_cl = $upp_limit if defined $upp_limit;
1566
1567     my $committer_authline = calculate_committer_authline();
1568
1569     printdebug "WALK REBUILD $build ".(scalar @processed)."\n";
1570
1571     confess "internal error" unless $build eq (pop @processed)->{CommitId};
1572
1573     in_workarea sub {
1574         mkdir $rd or $!==EEXIST or die $!;
1575         my $current_method;
1576         my $want_debian = $build;
1577         my $want_upstream = $build;
1578
1579         my $read_tree_upstream = sub { ($want_upstream) = @_; };
1580         my $read_tree_debian = sub { ($want_debian) = @_; };
1581
1582         foreach my $cl (qw(Debian), (reverse @brw_cl),
1583                         { SpecialMethod => 'RecordBreakwaterTip' },
1584                         qw(Upstream), (reverse @upp_cl)) {
1585             if (!ref $cl) {
1586                 $current_method = $cl;
1587                 next;
1588             }
1589             my $method = $cl->{SpecialMethod} // $current_method;
1590             my @parents = ($build);
1591             my $cltree = $cl->{CommitId};
1592             printdebug "WALK BUILD ".($cltree//'undef').
1593                 " $method (rewriting=$rewriting)\n";
1594             if ($method eq 'Debian') {
1595                 $read_tree_debian->($cltree);
1596             } elsif ($method eq 'Upstream') {
1597                 $read_tree_upstream->($cltree);
1598             } elsif ($method eq 'StartRewrite') {
1599                 $rewriting = 1;
1600                 next;
1601             } elsif ($method eq 'RecordBreakwaterTip') {
1602                 $breakwater = $build;
1603                 next;
1604             } elsif ($method eq 'DgitImportDebianUpdate') {
1605                 $read_tree_debian->($cltree);
1606             } elsif ($method eq 'DgitImportUpstreamUpdate') {
1607                 confess unless $rewriting;
1608                 my $differs = (get_differs $build, $cltree);
1609                 next unless $differs & D_UPS;
1610                 $read_tree_upstream->($cltree);
1611                 push @parents, map { $_->{CommitId} } @{ $cl->{OrigParents} };
1612             } elsif ($method eq 'MergeCreateMergedBreakwaters') {
1613                 print "Found a general merge, will try to tidy it up.\n";
1614                 $rewriting = 1;
1615                 $read_tree_upstream->($cl->{MergeBestAnchor});
1616                 $read_tree_debian->($cltree);
1617                 @parents = map { $_->{Breakwater} } @{ $cl->{Parents} };
1618             } elsif ($method eq 'MergeMergeSeries') {
1619                 my $cachehit = reflog_cache_lookup
1620                     $merge_cache_ref, "vanilla-merge $cl->{CommitId}";
1621                 if ($cachehit) {
1622                     print "Using supplied resolution for $cl->{CommitId}...\n";
1623                     $build = $cachehit;
1624                     $mwrecknote->('cached-resolution', $build);
1625                 } else {
1626                     print "Running merge resolution for $cl->{CommitId}...\n";
1627                     $mwrecknote->('new-base', $build);
1628                     $build = merge_series
1629                         $build, $cl->{MergeWreckNotes},
1630                         $cl->{MergeInterchangeBaseInfo},
1631                         @{ $cl->{Parents} };
1632                 }
1633                 $last_anchor = $cl->{MergeBestAnchor};
1634
1635                 # Check for mismerges:
1636                 my $check = sub {
1637                     my ($against, $allow, $what) = @_;
1638                     my $differs = get_differs $build, $against;
1639                     $nomerge->(sprintf
1640        "merge misresolved: %s are not the same (%s %s d.%#x)",
1641                                $what, $against, $build, $differs)
1642                         if $differs & ~($allow | D_PAT_ADD);
1643                 };
1644
1645                 # Breakwater changes which were in each side of the
1646                 # merge will have been incorporated into the
1647                 # MergeCreateMergedBreakwaters output.  Because the
1648                 # upstream series was rebased onto the new breakwater,
1649                 # so should all of the packaging changes which were in
1650                 # the input.
1651                 $check->($input, D_UPS, 'debian files');
1652
1653                 # Upstream files are merge_series, which ought to
1654                 # have been identical to the original merge.
1655                 $check->($cl->{CommitId}, DS_DEB, 'upstream files');
1656
1657                 print "Merge resolution successful.\n";
1658                 next;
1659             } else {
1660                 confess "$method ?";
1661             }
1662             if (!$rewriting) {
1663                 my $procd = (pop @processed) // 'UNDEF';
1664                 if ($cl ne $procd) {
1665                     $rewriting = 1;
1666                     printdebug "WALK REWRITING NOW cl=$cl procd=$procd\n";
1667                 }
1668             }
1669             if ($rewriting) {
1670                 read_tree_upstream $want_upstream, 0, $want_debian;
1671
1672                 my $newtree = cmdoutput @git, qw(write-tree);
1673                 my $ch = $cl->{Hdr};
1674                 $ch =~ s{^tree .*}{tree $newtree}m or confess "$ch ?";
1675                 $ch =~ s{^parent .*\n}{}mg;
1676                 $ch =~ s{(?=^author)}{
1677                     join '', map { "parent $_\n" } @parents
1678                 }me or confess "$ch ?";
1679                 if ($rewriting) {
1680                     $ch =~ s{^committer .*$}{$committer_authline}m
1681                         or confess "$ch ?";
1682                 }
1683                 my $cf = "$rd/m$rewriting";
1684                 open CD, ">", $cf or die $!;
1685                 print CD $ch, "\n", $cl->{Msg} or die $!;
1686                 close CD or die $!;
1687                 my @cmd = (@git, qw(hash-object));
1688                 push @cmd, qw(-w) if $rewriting;
1689                 push @cmd, qw(-t commit), $cf;
1690                 my $newcommit = cmdoutput @cmd;
1691                 confess "$ch ?" unless $rewriting
1692                     or $newcommit eq $cl->{CommitId};
1693                 $build = $newcommit;
1694             } else {
1695                 $build = $cl->{CommitId};
1696                 trees_diff_walk "$want_upstream:", "$build:", sub {
1697                     my ($n) = @_;
1698                     no warnings qw(exiting);
1699                     next if $n eq 'debian/';
1700                     confess "mismatch @_ ?";
1701                 };
1702                 trees_diff_walk "$want_debian:debian", "$build:debian", sub {
1703                     confess "mismatch @_ ?";
1704                 };
1705                 my @old_parents = map { $_->{CommitId} } @{ $cl->{Parents} };
1706                 confess "mismatch @parents != @old_parents ?"
1707                     unless "@parents" eq "@old_parents";
1708             }
1709             if (grep { $method eq $_ } qw(DgitImportUpstreamUpdate)) {
1710                 $last_anchor = $cur;
1711             }
1712         }
1713     };
1714
1715     my $final_check = get_differs $build, $input;
1716     die sprintf "internal error %#x %s %s", $final_check, $input, $build
1717         if $final_check & ~D_PAT_ADD;
1718
1719     my @r = ($build, $breakwater, $last_anchor);
1720     printdebug "*** WALK RETURN @r\n";
1721     return @r
1722 }
1723
1724 sub get_head () {
1725     git_check_unmodified();
1726     return git_rev_parse qw(HEAD);
1727 }
1728
1729 sub update_head ($$$) {
1730     my ($old, $new, $mrest) = @_;
1731     push @deferred_updates, "update HEAD $new $old";
1732     run_deferred_updates $mrest;
1733 }
1734
1735 sub update_head_checkout ($$$) {
1736     my ($old, $new, $mrest) = @_;
1737     update_head $old, $new, $mrest;
1738     runcmd @git, qw(reset --hard);
1739 }
1740
1741 sub update_head_postlaunder ($$$) {
1742     my ($old, $tip, $reflogmsg) = @_;
1743     return if $tip eq $old && !@deferred_updates;
1744     print "git-debrebase: laundered (head was $old)\n";
1745     update_head $old, $tip, $reflogmsg;
1746     # no tree changes except debian/patches
1747     runcmd @git, qw(rm --quiet --ignore-unmatch -rf debian/patches);
1748 }
1749
1750 sub currently_rebasing() {
1751     foreach (qw(rebase-merge rebase-apply)) {
1752         return 1 if stat_exists "$maindir_gitdir/$_";
1753     }
1754     return 0;
1755 }
1756
1757 sub bail_if_rebasing() {
1758     fail "you are in the middle of a git-rebase already"
1759         if currently_rebasing();
1760 }
1761
1762 sub do_launder_head ($) {
1763     my ($reflogmsg) = @_;
1764     my $old = get_head();
1765     record_ffq_auto();
1766     my ($tip,$breakwater) = walk $old;
1767     snags_maybe_bail();
1768     update_head_postlaunder $old, $tip, $reflogmsg;
1769     return ($tip,$breakwater);
1770 }
1771
1772 sub cmd_launder_v0 () {
1773     badusage "no arguments to launder-v0 allowed" if @ARGV;
1774     my $old = get_head();
1775     my ($tip,$breakwater,$last_anchor) = walk $old;
1776     update_head_postlaunder $old, $tip, 'launder';
1777     printf "# breakwater tip\n%s\n", $breakwater;
1778     printf "# working tip\n%s\n", $tip;
1779     printf "# last anchor\n%s\n", $last_anchor;
1780 }
1781
1782 sub defaultcmd_rebase () {
1783     push @ARGV, @{ $opt_defaultcmd_interactive // [] };
1784     my ($tip,$breakwater) = do_launder_head 'launder for rebase';
1785     runcmd @git, qw(rebase), @ARGV, $breakwater if @ARGV;
1786 }
1787
1788 sub cmd_analyse () {
1789     badusage "analyse does not support any options"
1790         if @ARGV and $ARGV[0] =~ m/^-/;
1791     badusage "too many arguments to analyse" if @ARGV>1;
1792     my ($old) = @ARGV;
1793     if (defined $old) {
1794         $old = git_rev_parse $old;
1795     } else {
1796         $old = git_rev_parse 'HEAD';
1797     }
1798     my ($dummy,$breakwater) = walk $old, 1,*STDOUT;
1799     STDOUT->error and die $!;
1800 }
1801
1802 sub ffq_check ($;$$) {
1803     # calls $ff and/or $notff zero or more times
1804     # then returns either (status,message) where status is
1805     #    exists
1806     #    detached
1807     #    weird-symref
1808     #    notbranch
1809     # or (undef,undef, $ffq_prev,$gdrlast)
1810     # $ff and $notff are called like this:
1811     #   $ff->("message for stdout\n");
1812     #   $notff->('snag-name', $message);
1813     # normally $currentval should be HEAD
1814     my ($currentval, $ff, $notff) =@_;
1815
1816     $ff //= sub { print $_[0] or die $!; };
1817     $notff //= \&snag;
1818
1819     my ($status, $message, $current, $ffq_prev, $gdrlast)
1820         = ffq_prev_branchinfo();
1821     return ($status, $message) unless $status eq 'branch';
1822
1823     my $exists = git_get_ref $ffq_prev;
1824     return ('exists',"$ffq_prev already exists") if $exists;
1825
1826     return ('not-branch', 'HEAD symref is not to refs/heads/')
1827         unless $current =~ m{^refs/heads/};
1828     my $branch = $';
1829
1830     my @check_specs = split /\;/, (cfg "branch.$branch.ffq-ffrefs",1) // '*';
1831     my %checked;
1832
1833     printdebug "ffq check_specs @check_specs\n";
1834
1835     my $check = sub {
1836         my ($lrref, $desc) = @_;
1837         printdebug "ffq might check $lrref ($desc)\n";
1838         my $invert;
1839         for my $chk (@check_specs) {
1840             my $glob = $chk;
1841             $invert = $glob =~ s{^[!^]}{};
1842             last if fnmatch $glob, $lrref;
1843         }
1844         return if $invert;
1845         my $lrval = git_get_ref $lrref;
1846         return unless length $lrval;
1847
1848         if (is_fast_fwd $lrval, $currentval) {
1849             $ff->("OK, you are ahead of $lrref\n");
1850             $checked{$lrref} = 1;
1851         } elsif (is_fast_fwd $currentval, $lrval) {
1852             $checked{$lrref} = -1;
1853             $notff->('behind', "you are behind $lrref, divergence risk");
1854         } else {
1855             $checked{$lrref} = -1;
1856             $notff->('diverged', "you have diverged from $lrref");
1857         }
1858     };
1859
1860     my $merge = cfg "branch.$branch.merge",1;
1861     if (defined $merge and $merge =~ m{^refs/heads/}) {
1862         my $rhs = $';
1863         printdebug "ffq merge $rhs\n";
1864         my $check_remote = sub {
1865             my ($remote, $desc) = @_;
1866             printdebug "ffq check_remote ".($remote//'undef')." $desc\n";
1867             return unless defined $remote;
1868             $check->("refs/remotes/$remote/$rhs", $desc);
1869         };
1870         $check_remote->((scalar cfg "branch.$branch.remote",1),
1871                         'remote fetch/merge branch');
1872         $check_remote->((scalar cfg "branch.$branch.pushRemote",1) //
1873                         (scalar cfg "branch.$branch.pushDefault",1),
1874                         'remote push branch');
1875     }
1876     if ($branch =~ m{^dgit/}) {
1877         $check->("refs/remotes/dgit/$branch", 'remote dgit branch');
1878     } elsif ($branch =~ m{^master$}) {
1879         $check->("refs/remotes/dgit/dgit/sid", 'remote dgit branch for sid');
1880     }
1881     return (undef, undef, $ffq_prev, $gdrlast);
1882 }
1883
1884 sub record_ffq_prev_deferred () {
1885     # => ('status', "message")
1886     # 'status' may be
1887     #    deferred          message is undef
1888     #    exists
1889     #    detached
1890     #    weird-symref
1891     #    notbranch
1892     # if not ff from some branch we should be ff from, is an snag
1893     # if "deferred", will have added something about that to
1894     #   @deferred_update_messages, and also maybe printed (already)
1895     #   some messages about ff checks
1896     bail_if_rebasing();
1897     my $currentval = get_head();
1898
1899     my ($status,$message, $ffq_prev,$gdrlast) = ffq_check $currentval;
1900     return ($status,$message) if defined $status;
1901
1902     snags_maybe_bail();
1903
1904     push @deferred_updates, "update $ffq_prev $currentval $git_null_obj";
1905     push @deferred_updates, "delete $gdrlast";
1906     push @deferred_update_messages, "Recorded previous head for preservation";
1907     return ('deferred', undef);
1908 }
1909
1910 sub record_ffq_auto () {
1911     my ($status, $message) = record_ffq_prev_deferred();
1912     if ($status eq 'deferred' || $status eq 'exists') {
1913     } else {
1914         snag $status, "could not record ffq-prev: $message";
1915         snags_maybe_bail();
1916     }
1917 }
1918
1919 sub ffq_prev_info () {
1920     bail_if_rebasing();
1921     # => ($ffq_prev, $gdrlast, $ffq_prev_commitish)
1922     my ($status, $message, $current, $ffq_prev, $gdrlast)
1923         = ffq_prev_branchinfo();
1924     if ($status ne 'branch') {
1925         snag $status, "could not check ffq-prev: $message";
1926         snags_maybe_bail();
1927     }
1928     my $ffq_prev_commitish = $ffq_prev && git_get_ref $ffq_prev;
1929     return ($ffq_prev, $gdrlast, $ffq_prev_commitish);
1930 }
1931
1932 sub stitch ($$$$$) {
1933     my ($old_head, $ffq_prev, $gdrlast, $ffq_prev_commitish, $prose) = @_;
1934
1935     push @deferred_updates, "delete $ffq_prev $ffq_prev_commitish";
1936
1937     if (is_fast_fwd $old_head, $ffq_prev_commitish) {
1938         my $differs = get_differs $old_head, $ffq_prev_commitish;
1939         unless ($differs & ~D_PAT_ADD) {
1940             # ffq-prev is ahead of us, and the only tree changes it has
1941             # are possibly addition of things in debian/patches/.
1942             # Just wind forwards rather than making a pointless pseudomerge.
1943             record_gdrlast $gdrlast, $ffq_prev_commitish;
1944             update_head_checkout $old_head, $ffq_prev_commitish,
1945                 "stitch (fast forward)";
1946             return;
1947         }
1948     }
1949     fresh_workarea();
1950     # We make pseudomerges with L as the contributing parent.
1951     # This makes git rev-list --first-parent work properly.
1952     my $new_head = make_commit [ $old_head, $ffq_prev ], [
1953         'Declare fast forward / record previous work',
1954         "[git-debrebase pseudomerge: $prose]",
1955     ];
1956     record_gdrlast $gdrlast, $new_head;
1957     update_head $old_head, $new_head, "stitch: $prose";
1958 }
1959
1960 sub do_stitch ($;$) {
1961     my ($prose, $unclean) = @_;
1962
1963     my ($ffq_prev, $gdrlast, $ffq_prev_commitish) = ffq_prev_info();
1964     if (!$ffq_prev_commitish) {
1965         fail "No ffq-prev to stitch." unless $opt_noop_ok;
1966         return;
1967     }
1968     my $dangling_head = get_head();
1969
1970     keycommits $dangling_head, $unclean,$unclean,$unclean;
1971     snags_maybe_bail();
1972
1973     stitch($dangling_head, $ffq_prev, $gdrlast, $ffq_prev_commitish, $prose);
1974 }
1975
1976 sub upstream_commitish_search ($$) {
1977     my ($upstream_version, $tried) = @_;
1978     # todo: at some point maybe use git-deborig to do this
1979     foreach my $tagpfx ('', 'v', 'upstream/') {
1980         my $tag = $tagpfx.(dep14_version_mangle $upstream_version);
1981         my $new_upstream = git_get_ref "refs/tags/$tag";
1982         push @$tried, $tag;
1983         return $new_upstream if length $new_upstream;
1984     }
1985 }
1986
1987 sub resolve_upstream_version ($$) {
1988     my ($new_upstream, $upstream_version) = @_;
1989
1990     if (!defined $new_upstream) {
1991         my @tried;
1992         $new_upstream = upstream_commitish_search $upstream_version, \@tried;
1993         if (!length $new_upstream) {
1994             fail "Could not determine appropriate upstream commitish.\n".
1995                 " (Tried these tags: @tried)\n".
1996                 " Check version, and specify upstream commitish explicitly.";
1997         }
1998     }
1999     $new_upstream = git_rev_parse $new_upstream;
2000
2001     return $new_upstream;
2002 }
2003
2004 sub cmd_new_upstream () {
2005     # automatically and unconditionally launders before rebasing
2006     # if rebase --abort is used, laundering has still been done
2007
2008     my %pieces;
2009
2010     badusage "need NEW-VERSION [UPS-COMMITTISH]" unless @ARGV >= 1;
2011
2012     # parse args - low commitment
2013     my $spec_version = shift @ARGV;
2014     my $new_version = (new Dpkg::Version $spec_version, check => 1);
2015     fail "bad version number \`$spec_version'" unless defined $new_version;
2016     if ($new_version->is_native()) {
2017         $new_version = (new Dpkg::Version "$spec_version-1", check => 1);
2018     }
2019
2020     my $new_upstream = shift @ARGV;
2021     my $new_upstream_version = upstreamversion  $new_version;
2022     $new_upstream =
2023         resolve_upstream_version $new_upstream, $new_upstream_version;
2024
2025     record_ffq_auto();
2026
2027     my $piece = sub {
2028         my ($n, @x) = @_; # may be ''
2029         my $pc = $pieces{$n} //= {
2030             Name => $n,
2031             Desc => ($n ? "upstream piece \`$n'" : "upstream (main piece"),
2032         };
2033         while (my $k = shift @x) { $pc->{$k} = shift @x; }
2034         $pc;
2035     };
2036
2037     my @newpieces;
2038     my $newpiece = sub {
2039         my ($n, @x) = @_; # may be ''
2040         my $pc = $piece->($n, @x, NewIx => (scalar @newpieces));
2041         push @newpieces, $pc;
2042     };
2043
2044     $newpiece->('',
2045         OldIx => 0,
2046         New => $new_upstream,
2047     );
2048     while (@ARGV && $ARGV[0] !~ m{^-}) {
2049         my $n = shift @ARGV;
2050
2051         badusage "for each EXTRA-UPS-NAME need EXTRA-UPS-COMMITISH"
2052             unless @ARGV && $ARGV[0] !~ m{^-};
2053
2054         my $c = git_rev_parse shift @ARGV;
2055         die unless $n =~ m/^$extra_orig_namepart_re$/;
2056         $newpiece->($n, New => $c);
2057     }
2058
2059     # now we need to investigate the branch this generates the
2060     # laundered version but we don't switch to it yet
2061     my $old_head = get_head();
2062     my ($old_laundered_tip,$old_bw,$old_anchor) = walk $old_head;
2063
2064     my $old_bw_cl = classify $old_bw;
2065     my $old_anchor_cl = classify $old_anchor;
2066     my $old_upstream;
2067     if (!$old_anchor_cl->{OrigParents}) {
2068         snag 'anchor-treated',
2069             'old anchor is recognised due to --anchor, cannot check upstream';
2070     } else {
2071         $old_upstream = parsecommit
2072             $old_anchor_cl->{OrigParents}[0]{CommitId};
2073         $piece->('', Old => $old_upstream->{CommitId});
2074     }
2075
2076     if ($old_upstream && $old_upstream->{Msg} =~ m{^\[git-debrebase }m) {
2077         if ($old_upstream->{Msg} =~
2078  m{^\[git-debrebase upstream-combine (\.(?: $extra_orig_namepart_re)+)\:.*\]$}m
2079            ) {
2080             my @oldpieces = (split / /, $1);
2081             my $old_n_parents = scalar @{ $old_upstream->{Parents} };
2082             if ($old_n_parents != @oldpieces &&
2083                 $old_n_parents != @oldpieces + 1) {
2084                 snag 'upstream-confusing', sprintf
2085                     "previous upstream combine %s".
2086                     " mentions %d pieces (each implying one parent)".
2087                     " but has %d parents".
2088                     " (one per piece plus maybe a previous combine)",
2089                     $old_upstream->{CommitId},
2090                     (scalar @oldpieces),
2091                     $old_n_parents;
2092             } elsif ($oldpieces[0] ne '.') {
2093                 snag 'upstream-confusing', sprintf
2094                     "previous upstream combine %s".
2095                     " first piece is not \`.'",
2096                     $oldpieces[0];
2097             } else {
2098                 $oldpieces[0] = '';
2099                 foreach my $i (0..$#oldpieces) {
2100                     my $n = $oldpieces[$i];
2101                     my $hat = 1 + $i + ($old_n_parents - @oldpieces);
2102                     $piece->($n, Old => $old_upstream->{CommitId}.'^'.$hat);
2103                 }
2104             }
2105         } else {
2106             snag 'upstream-confusing',
2107                 "previous upstream $old_upstream->{CommitId} is from".
2108                " git-debrebase but not an \`upstream-combine' commit";
2109         }
2110     }
2111
2112     foreach my $pc (values %pieces) {
2113         if (!$old_upstream) {
2114             # we have complained already
2115         } elsif (!$pc->{Old}) {
2116             snag 'upstream-new-piece',
2117                 "introducing upstream piece \`$pc->{Name}'";
2118         } elsif (!$pc->{New}) {
2119             snag 'upstream-rm-piece',
2120                 "dropping upstream piece \`$pc->{Name}'";
2121         } elsif (!is_fast_fwd $pc->{Old}, $pc->{New}) {
2122             snag 'upstream-not-ff',
2123                 "not fast forward: $pc->{Name} $pc->{Old}..$pc->{New}";
2124         }
2125     }
2126
2127     printdebug "%pieces = ", (dd \%pieces), "\n";
2128     printdebug "\@newpieces = ", (dd \@newpieces), "\n";
2129
2130     snags_maybe_bail();
2131
2132     my $new_bw;
2133
2134     fresh_workarea();
2135     in_workarea sub {
2136         my @upstream_merge_parents;
2137
2138         if (!any_snags()) {
2139             push @upstream_merge_parents, $old_upstream->{CommitId};
2140         }
2141
2142         foreach my $pc (@newpieces) { # always has '' first
2143             if ($pc->{Name}) {
2144                 read_tree_subdir $pc->{Name}, $pc->{New};
2145             } else {
2146                 runcmd @git, qw(read-tree), $pc->{New};
2147             }
2148             push @upstream_merge_parents, $pc->{New};
2149         }
2150
2151         # index now contains the new upstream
2152
2153         if (@newpieces > 1) {
2154             # need to make the upstream subtree merge commit
2155             $new_upstream = make_commit \@upstream_merge_parents,
2156                 [ "Combine upstreams for $new_upstream_version",
2157  ("[git-debrebase upstream-combine . ".
2158  (join " ", map { $_->{Name} } @newpieces[1..$#newpieces]).
2159  ": new upstream]"),
2160                 ];
2161         }
2162
2163         # $new_upstream is either the single upstream commit, or the
2164         # combined commit we just made.  Either way it will be the
2165         # "upstream" parent of the anchor merge.
2166
2167         read_tree_subdir 'debian', "$old_bw:debian";
2168
2169         # index now contains the anchor merge contents
2170         $new_bw = make_commit [ $old_bw, $new_upstream ],
2171             [ "Update to upstream $new_upstream_version",
2172  "[git-debrebase anchor: new upstream $new_upstream_version, merge]",
2173             ];
2174
2175         my $clogsignoff = cmdoutput qw(git show),
2176             '--pretty=format:%an <%ae>  %aD',
2177             $new_bw;
2178
2179         # Now we have to add a changelog stanza so the Debian version
2180         # is right.
2181         die if unlink "debian";
2182         die $! unless $!==ENOENT or $!==ENOTEMPTY;
2183         unlink "debian/changelog" or $!==ENOENT or die $!;
2184         mkdir "debian" or die $!;
2185         open CN, ">", "debian/changelog" or die $!;
2186         my $oldclog = git_cat_file ":debian/changelog";
2187         $oldclog =~ m/^($package_re) \(\S+\) / or
2188             fail "cannot parse old changelog to get package name";
2189         my $p = $1;
2190         print CN <<END, $oldclog or die $!;
2191 $p ($new_version) UNRELEASED; urgency=medium
2192
2193   * Update to new upstream version $new_upstream_version.
2194
2195  -- $clogsignoff
2196
2197 END
2198         close CN or die $!;
2199         runcmd @git, qw(update-index --add --replace), 'debian/changelog';
2200
2201         # Now we have the final new breakwater branch in the index
2202         $new_bw = make_commit [ $new_bw ],
2203             [ "Update changelog for new upstream $new_upstream_version",
2204               "[git-debrebase changelog: new upstream $new_upstream_version]",
2205             ];
2206     };
2207
2208     # we have constructed the new breakwater. we now need to commit to
2209     # the laundering output, because git-rebase can't easily be made
2210     # to make a replay list which is based on some other branch
2211
2212     update_head_postlaunder $old_head, $old_laundered_tip,
2213         'launder for new upstream';
2214
2215     my @cmd = (@git, qw(rebase --onto), $new_bw, $old_bw, @ARGV);
2216     local $ENV{GIT_REFLOG_ACTION} = git_reflog_action_msg
2217         "debrebase new-upstream $new_version: rebase";
2218     runcmd @cmd;
2219     # now it's for the user to sort out
2220 }
2221
2222 sub cmd_record_ffq_prev () {
2223     badusage "no arguments allowed" if @ARGV;
2224     my ($status, $msg) = record_ffq_prev_deferred();
2225     if ($status eq 'exists' && $opt_noop_ok) {
2226         print "Previous head already recorded\n" or die $!;
2227     } elsif ($status eq 'deferred') {
2228         run_deferred_updates 'record-ffq-prev';
2229     } else {
2230         fail "Could not preserve: $msg";
2231     }
2232 }
2233
2234 sub cmd_anchor () {
2235     badusage "no arguments allowed" if @ARGV;
2236     my ($anchor, $bw) = keycommits +(git_rev_parse 'HEAD'), 0,0;
2237     print "$bw\n" or die $!;
2238 }
2239
2240 sub cmd_breakwater () {
2241     badusage "no arguments allowed" if @ARGV;
2242     my ($anchor, $bw) = keycommits +(git_rev_parse 'HEAD'), 0,0;
2243     print "$bw\n" or die $!;
2244 }
2245
2246 sub cmd_status () {
2247     badusage "no arguments allowed" if @ARGV;
2248
2249     # todo: gdr status should print divergence info
2250     # todo: gdr status should print upstream component(s) info
2251     # todo: gdr should leave/maintain some refs with this kind of info ?
2252
2253     my $oldest = { Badness => 0 };
2254     my $newest;
2255     my $note = sub {
2256         my ($badness, $ourmsg, $snagname, $dummy, $cl, $kcmsg) = @_;
2257         if ($oldest->{Badness} < $badness) {
2258             $oldest = $newest = undef;
2259         }
2260         $oldest = {
2261                    Badness => $badness,
2262                    CommitId => $cl->{CommitId},
2263                    OurMsg => $ourmsg,
2264                    KcMsg => $kcmsg,
2265                   };
2266         $newest //= $oldest;
2267     };
2268     my ($anchor, $bw) = keycommits +(git_rev_parse 'HEAD'),
2269         sub { $note->(1, 'branch contains furniture (not laundered)', @_); },
2270         sub { $note->(2, 'branch is unlaundered', @_); },
2271         sub { $note->(3, 'branch needs laundering', @_); },
2272         sub { $note->(4, 'branch not in git-debrebase form', @_); };
2273
2274     my $prcommitinfo = sub {
2275         my ($cid) = @_;
2276         flush STDOUT or die $!;
2277         runcmd @git, qw(--no-pager log -n1),
2278             '--pretty=format:    %h %s%n',
2279             $cid;
2280     };
2281
2282     print "current branch contents, in git-debrebase terms:\n";
2283     if (!$oldest->{Badness}) {
2284         print "  branch is laundered\n";
2285     } else {
2286         print "  $oldest->{OurMsg}\n";
2287         my $printed = '';
2288         foreach my $info ($oldest, $newest) {
2289             my $cid = $info->{CommitId};
2290             next if $cid eq $printed;
2291             $printed = $cid;
2292             print "  $info->{KcMsg}\n";
2293             $prcommitinfo->($cid);
2294         }
2295     }
2296
2297     my $prab = sub {
2298         my ($cid, $what) = @_;
2299         if (!defined $cid) {
2300             print "  $what is not well-defined\n";
2301         } else {
2302             print "  $what\n";
2303             $prcommitinfo->($cid);
2304         }
2305     };
2306     print "key git-debrebase commits:\n";
2307     $prab->($anchor, 'anchor');
2308     $prab->($bw, 'breakwater');
2309
2310     my ($ffqstatus, $ffq_msg, $current, $ffq_prev, $gdrlast) =
2311         ffq_prev_branchinfo();
2312
2313     print "branch and ref status, in git-debrebase terms:\n";
2314     if ($ffq_msg) {
2315         print "  $ffq_msg\n";
2316     } else {
2317         $ffq_prev = git_get_ref $ffq_prev;
2318         $gdrlast = git_get_ref $gdrlast;
2319         if ($ffq_prev) {
2320             print "  unstitched; previous tip was:\n";
2321             $prcommitinfo->($ffq_prev);
2322         } elsif (!$gdrlast) {
2323             print "  stitched? (no record of git-debrebase work)\n";
2324         } elsif (is_fast_fwd $gdrlast, 'HEAD') {
2325             print "  stitched\n";
2326         } else {
2327             print "  not git-debrebase (diverged since last stitch)\n"
2328         }
2329     }
2330     print "you are currently rebasing\n" if currently_rebasing();
2331 }
2332
2333 sub cmd_stitch () {
2334     my $prose = 'stitch';
2335     getoptions("stitch",
2336                'prose=s', \$prose);
2337     badusage "no arguments allowed" if @ARGV;
2338     do_stitch $prose, 0;
2339 }
2340 sub cmd_prepush () {
2341     $opt_noop_ok = 1;
2342     cmd_stitch();
2343 }
2344
2345 sub cmd_quick () {
2346     badusage "no arguments allowed" if @ARGV;
2347     do_launder_head 'launder for git-debrebase quick';
2348     do_stitch 'quick';
2349 }
2350
2351 sub cmd_conclude () {
2352     my ($ffq_prev, $gdrlast, $ffq_prev_commitish) = ffq_prev_info();
2353     if (!$ffq_prev_commitish) {
2354         fail "No ongoing git-debrebase session." unless $opt_noop_ok;
2355         return;
2356     }
2357     my $dangling_head = get_head();
2358
2359     badusage "no arguments allowed" if @ARGV;
2360     do_launder_head 'launder for git-debrebase quick';
2361     do_stitch 'quick';
2362 }
2363
2364 sub cmd_scrap () {
2365     if (currently_rebasing()) {
2366         runcmd @git, qw(rebase --abort);
2367         push @deferred_updates, 'verify HEAD HEAD';
2368         # noop, but stops us complaining that scrap was a noop
2369     }
2370     badusage "no arguments allowed" if @ARGV;
2371     my ($ffq_prev, $gdrlast, $ffq_prev_commitish) = ffq_prev_info();
2372     my $scrapping_head;
2373     if ($ffq_prev_commitish) {
2374         $scrapping_head = get_head();
2375         push @deferred_updates,
2376             "update $gdrlast $ffq_prev_commitish $git_null_obj",
2377             "update $ffq_prev $git_null_obj $ffq_prev_commitish";
2378     }
2379     if (git_get_ref $merge_cache_ref) {
2380         push @deferred_updates,
2381             "delete $merge_cache_ref";
2382     }
2383     if (!@deferred_updates) {
2384         fail "No ongoing git-debrebase session." unless $opt_noop_ok;
2385         finish 0;
2386     }
2387     snags_maybe_bail();
2388     if ($scrapping_head) {
2389         update_head_checkout $scrapping_head, $ffq_prev_commitish, "scrap";
2390     } else {
2391         run_deferred_updates "scrap";
2392     }
2393 }
2394
2395 sub make_patches_staged ($) {
2396     my ($head) = @_;
2397     # Produces the patches that would result from $head if it were
2398     # laundered.
2399     my ($secret_head, $secret_bw, $last_anchor) = walk $head;
2400     fresh_workarea();
2401     my $any;
2402     in_workarea sub {
2403         $any = gbp_pq_export 'bw', $secret_bw, $secret_head;
2404     };
2405     return $any;
2406 }
2407
2408 sub make_patches ($) {
2409     my ($head) = @_;
2410     keycommits $head, 0, \&snag;
2411     make_patches_staged $head;
2412     my $out;
2413     in_workarea sub {
2414         my $ptree = cmdoutput @git, qw(write-tree --prefix=debian/patches/);
2415         runcmd @git, qw(read-tree), $head;
2416         read_tree_subdir 'debian/patches', $ptree;
2417         $out = make_commit [$head], [
2418             'Commit patch queue (exported by git-debrebase)',
2419             '[git-debrebase make-patches: export and commit patches]',
2420         ];
2421     };
2422     return $out;
2423 }
2424
2425 sub cmd_make_patches () {
2426     my $opt_quiet_would_amend;
2427     getoptions("make-patches",
2428                'quiet-would-amend!', \$opt_quiet_would_amend);
2429     badusage "no arguments allowed" if @ARGV;
2430     bail_if_rebasing();
2431     my $old_head = get_head();
2432     my $new = make_patches $old_head;
2433     my $d = get_differs $old_head, $new;
2434     if ($d == 0) {
2435         fail "No (more) patches to export." unless $opt_noop_ok;
2436         return;
2437     } elsif ($d == D_PAT_ADD) {
2438         snags_maybe_bail();
2439         update_head_checkout $old_head, $new, 'make-patches';
2440     } else {
2441         print STDERR failmsg
2442             "Patch export produced patch amendments".
2443             " (abandoned output commit $new).".
2444             "  Try laundering first."
2445             unless $opt_quiet_would_amend;
2446         finish 7;
2447     }
2448 }
2449
2450 sub check_series_has_all_patches ($) {
2451     my ($head) = @_;
2452     my $seriesfn = 'debian/patches/series';
2453     my ($dummy, $series) = git_cat_file "$head:$seriesfn",
2454         [qw(blob missing)];
2455     $series //= '';
2456     my %series;
2457     our $comments_snagged;
2458     foreach my $f (grep /\S/, grep {!m/^\s\#/} split /\n/, $series) {
2459         if ($f =~ m/^\s*\#/) {
2460             snag 'series-comments',
2461                 "$seriesfn contains comments, which will be discarded"
2462                 unless $comments_snagged++;
2463             next;
2464         }
2465         fail "patch $f repeated in $seriesfn !" if $series{$f}++;
2466     }
2467     foreach my $patchfile (get_tree "$head:debian/patches", 1,1) {
2468         my ($f,$i) = @$patchfile;
2469         next if $series{$f};
2470         next if $f eq 'series';
2471         snag 'unused-patches', "Unused patch file $f will be discarded";
2472     }
2473 }
2474
2475 sub begin_convert_from () {
2476     my $head = get_head();
2477     my ($ffqs, $ffqm, $symref, $ffq_prev, $gdrlast) = ffq_prev_branchinfo();
2478
2479     fail "ffq-prev exists, this is already managed by git-debrebase!"
2480         if $ffq_prev && git_get_ref $ffq_prev;
2481
2482     my $gdrlast_obj = $gdrlast && git_get_ref $gdrlast;
2483     snag 'already-converted',
2484         "ahead of debrebase-last, this is already managed by git-debrebase!"
2485         if $gdrlast_obj && is_fast_fwd $gdrlast_obj, $head;
2486     return ($head, { LastRef => $gdrlast, LastObj => $gdrlast_obj });
2487 }
2488
2489 sub complete_convert_from ($$$$) {
2490     my ($old_head, $new_head, $gi, $mrest) = @_;
2491     ffq_check $new_head;
2492     record_gdrlast $gi->{LastRef}, $new_head, $gi->{LastObj}
2493         if $gi->{LastRef};
2494     snags_maybe_bail();
2495     update_head_checkout $old_head, $new_head, $mrest;
2496 }
2497
2498 sub cmd_convert_from_gbp () {
2499     badusage "want only 1 optional argument, the upstream git commitish"
2500         unless @ARGV<=1;
2501
2502     my $clogp = parsechangelog();
2503     my $version = $clogp->{'Version'}
2504         // die "missing Version from changelog";
2505
2506     my ($upstream_spec) = @ARGV;
2507
2508     my $upstream_version = upstreamversion $version;
2509     my $upstream =
2510         resolve_upstream_version($upstream_spec, $upstream_version);
2511
2512     my ($old_head, $gdrlastinfo) = begin_convert_from();
2513
2514     my $upsdiff = get_differs $upstream, $old_head;
2515     if ($upsdiff & D_UPS) {
2516         runcmd @git, qw(--no-pager diff --stat),
2517             $upstream, $old_head,
2518             qw( -- :!/debian :/);
2519         fail <<END;
2520 upstream ($upstream_spec) and HEAD are not
2521 identical in upstream files.  See diffstat above, or run
2522   git diff $upstream_spec HEAD -- :!/debian :/
2523 END
2524     }
2525
2526     if (!is_fast_fwd $upstream, $old_head) {
2527         snag 'upstream-not-ancestor',
2528             "upstream ($upstream) is not an ancestor of HEAD";
2529     } else {
2530         my $wrong = cmdoutput
2531             (@git, qw(rev-list --ancestry-path), "$upstream..HEAD",
2532              qw(-- :/ :!/debian));
2533         if (length $wrong) {
2534             snag 'unexpected-upstream-changes',
2535                 "history between upstream ($upstream) and HEAD contains direct changes to upstream files - are you sure this is a gbp (patches-unapplied) branch?";
2536             print STDERR "list expected changes with:  git log --stat --ancestry-path $upstream_spec..HEAD -- :/ ':!/debian'\n";
2537         }
2538     }
2539
2540     if ((git_cat_file "$upstream:debian")[0] ne 'missing') {
2541         snag 'upstream-has-debian',
2542             "upstream ($upstream) contains debian/ directory";
2543     }
2544
2545     check_series_has_all_patches $old_head;
2546
2547     my $previous_dgit_view = eval {
2548         my @clogcmd = qw(dpkg-parsechangelog --format rfc822 -n2);
2549         my ($lvsn, $suite);
2550         parsechangelog_loop \@clogcmd, 'debian/changelog', sub {
2551             my ($stz, $desc) = @_;
2552             no warnings qw(exiting);
2553             printdebug 'CHANGELOG ', Dumper($desc, $stz);
2554             next unless $stz->{Date};
2555             next unless $stz->{Distribution} ne 'UNRELEASED';
2556             $lvsn = $stz->{Version};
2557             $suite = $stz->{Distribution};
2558             last;
2559         };
2560         die "neither of the first two changelog entries are released\n"
2561             unless defined $lvsn;
2562         print "last finished-looking changelog entry: ($lvsn) $suite\n";
2563         my $mtag_pat = debiantag_maintview $lvsn, '*';
2564         my $mtag = cmdoutput @git, qw(describe --always --abbrev=0 --match),
2565             $mtag_pat;
2566         die "could not find suitable maintainer view tag $mtag_pat\n"
2567             unless $mtag =~ m{/};
2568         is_fast_fwd $mtag, 'HEAD' or
2569             die "HEAD is not FF from maintainer tag $mtag!";
2570         my $dtag = "archive/$mtag";
2571         git_get_ref "refs/tags/$dtag" or
2572             die "dgit view tag $dtag not found\n";
2573         is_fast_fwd $mtag, $dtag or
2574             die "dgit view tag $dtag is not FF from maintainer tag $mtag\n";
2575         print "will stitch in dgit view, $dtag\n";
2576         git_rev_parse $dtag;
2577     };
2578     if (!$previous_dgit_view) {
2579         $@ =~ s/^\n+//;
2580         chomp $@;
2581         print STDERR <<END;
2582 Cannot confirm dgit view: $@
2583 Failed to stitch in dgit view (see messages above).
2584 dgit --overwrite will be needed on the first dgit push after conversion.
2585 END
2586     }
2587
2588     snags_maybe_bail_early();
2589
2590     my $work;
2591
2592     fresh_workarea();
2593     in_workarea sub {
2594         runcmd @git, qw(checkout -q -b gdr-internal), $old_head;
2595         # make a branch out of the patch queue - we'll want this in a mo
2596         runcmd qw(gbp pq import);
2597         # strip the patches out
2598         runcmd @git, qw(checkout -q gdr-internal~0);
2599         rm_subdir_cached 'debian/patches';
2600         $work = make_commit ['HEAD'], [
2601  'git-debrebase convert-from-gbp: drop patches from tree',
2602  'Delete debian/patches, as part of converting to git-debrebase format.',
2603  '[git-debrebase convert-from-gbp: drop patches from tree]'
2604                               ];
2605         # make the anchor merge
2606         # the tree is already exactly right
2607         $work = make_commit [$work, $upstream], [
2608  'git-debrebase import: declare upstream',
2609  'First breakwater merge.',
2610  '[git-debrebase anchor: declare upstream]'
2611                               ];
2612
2613         # rebase the patch queue onto the new breakwater
2614         runcmd @git, qw(reset --quiet --hard patch-queue/gdr-internal);
2615         runcmd @git, qw(rebase --quiet --onto), $work, qw(gdr-internal);
2616         $work = git_rev_parse 'HEAD';
2617
2618         if ($previous_dgit_view) {
2619             $work = make_commit [$work, $previous_dgit_view], [
2620  'git-debrebase import: declare ff from dgit archive view',
2621  '[git-debrebase pseudomerge: import-from-gbp]',
2622             ];
2623         }
2624     };
2625
2626     complete_convert_from $old_head, $work, $gdrlastinfo, 'convert-from-gbp';
2627     print <<END or die $!;
2628 git-debrebase: converted from patched-unapplied (gbp) branch format, OK
2629 END
2630 }
2631
2632 sub cmd_convert_to_gbp () {
2633     badusage "no arguments allowed" if @ARGV;
2634     my $head = get_head();
2635     my (undef, undef, undef, $ffq, $gdrlast) = ffq_prev_branchinfo();
2636     my ($anchor, $breakwater) = keycommits $head, 0;
2637     my $out = $breakwater;
2638     make_patches_staged $head;
2639     in_workarea sub {
2640         $out = make_commit [$out], [
2641             'Commit patch queue (converted from git-debrebase format)',
2642             '[git-debrebase convert-to-gbp: commit patches]',
2643         ];
2644     };
2645     if (defined $ffq) {
2646         push @deferred_updates, "delete $ffq";
2647         push @deferred_updates, "delete $gdrlast";
2648     }
2649     snags_maybe_bail();
2650     update_head_checkout $head, $out, "convert to gbp (v0)";
2651     print <<END or die $!;
2652 git-debrebase: converted to git-buildpackage branch format
2653 git-debrebase: WARNING: do not now run "git-debrebase" any more
2654 git-debrebase: WARNING: doing so would drop all upstream patches!
2655 END
2656 }
2657
2658 sub cmd_convert_from_dgit_view () {
2659     my $clogp = parsechangelog();
2660
2661     my $bpd = (cfg 'dgit.default.build-products-dir',1) // '..';
2662     my $do_origs = 1;
2663     my $do_tags = 1;
2664     my $always = 0;
2665     my $diagnose = 0;
2666
2667     getoptions("convert-from-dgit-view",
2668                'diagnose!', \$diagnose,
2669                'build-products-dir:s', \$bpd,
2670                'origs!', \$do_origs,
2671                'tags!', \$do_tags,
2672                'always-convert-anyway!', \$always);
2673     fail "takes 1 optional argument, the upstream commitish" if @ARGV>1;
2674
2675     my @upstreams;
2676
2677     if (@ARGV) {
2678         my $spec = shift @ARGV;
2679         my $commit = git_rev_parse "$spec^{commit}";
2680         push @upstreams, { Commit => $commit,
2681                            Source => "$ARGV[0], from command line",
2682                            Only => 1,
2683                          };
2684     }
2685
2686     my ($head, $gdrlastinfo) = begin_convert_from();
2687
2688     if (!$always) {
2689         my $troubles = 0;
2690         my $trouble = sub { $troubles++; };
2691         keycommits $head, sub{}, sub{}, $trouble, $trouble;
2692         printdebug "troubles=$troubles\n";
2693         if (!$troubles) {
2694             print STDERR <<END;
2695 $us: Branch already seems to be in git-debrebase format!
2696 $us: --always-convert-anyway would do the conversion operation anyway
2697 $us: but is probably a bad idea.  Probably, you wanted to do nothing.
2698 END
2699             fail "Branch already in git-debrebase format." unless $opt_noop_ok;
2700             finish 0;
2701         }
2702     }
2703
2704     check_series_has_all_patches $head;
2705
2706     snags_maybe_bail_early();
2707
2708     my $version = upstreamversion $clogp->{Version};
2709     print STDERR "Considering possible commits corresponding to upstream:\n";
2710
2711     if (!@upstreams) {
2712         if ($do_tags) {
2713             my @tried;
2714             my $ups_tag = upstream_commitish_search $version, \@tried;
2715             if ($ups_tag) {
2716                 my $this = "git tag $tried[-1]";
2717                 push @upstreams, { Commit => $ups_tag,
2718                                    Source => $this,
2719                                  };
2720             } else {
2721                 printf STDERR
2722                     " git tag: no suitable tag found (tried %s)\n",
2723                     "@tried";
2724             }
2725         }
2726         if ($do_origs) {
2727             my $p = $clogp->{'Source'};
2728             # we do a quick check to see if there are plausible origs
2729             my $something=0;
2730             if (!opendir BPD, $bpd) {
2731                 die "$bpd: opendir: $!" unless $!==ENOENT;
2732             } else {
2733                 while ($!=0, my $f = readdir BPD) {
2734                     next unless is_orig_file_of_p_v $f, $p, $version;
2735                     printf STDERR
2736                         " orig: found what looks like a .orig, %s\n",
2737                         "$bpd/$f";
2738                     $something=1;
2739                     last;
2740                 }
2741                 die "read $bpd: $!" if $!;
2742                 closedir BPD;
2743             }
2744             if ($something) {
2745                 my $tree = cmdoutput
2746                     @dgit, qw(--build-products-dir), $bpd,
2747                     qw(print-unapplied-treeish);
2748                 fresh_workarea();
2749                 in_workarea sub {
2750                     runcmd @git, qw(reset --quiet), $tree, qw(-- .);
2751                     rm_subdir_cached 'debian';
2752                     $tree = cmdoutput @git, qw(write-tree);
2753                     my $ups_synth = make_commit [], [ <<END, <<END,
2754 Import effective orig tree for upstream version $version
2755 END
2756 This includes the contents of the .orig(s), minus any debian/ directory.
2757
2758 [git-debrebase convert-from-dgit-view upstream-import-convert: $version]
2759 END
2760                                                     ];
2761                     push @upstreams, { Commit => $ups_synth,
2762                                        Source => "orig(s) imported via dgit",
2763                                      };
2764                 }
2765             } else {
2766                 printf STDERR
2767                     " orig: no suitable origs found (looked for %s in %s)\n",
2768                     "${p}_".(stripeoch $version)."...", $bpd;
2769             }
2770         }
2771     }
2772
2773     my $some_patches = stat_exists 'debian/patches/series';
2774
2775     print STDERR "Evaluating possible commits corresponding to upstream:\n";
2776
2777     my $result;
2778     foreach my $u (@upstreams) {
2779         my $work = $head;
2780         fresh_workarea();
2781         in_workarea sub {
2782             runcmd @git, qw(reset --quiet), $u->{Commit}, qw(-- .);
2783             runcmd @git, qw(checkout), $u->{Commit}, qw(-- .);
2784             runcmd @git, qw(clean -xdff);
2785             runcmd @git, qw(checkout), $head, qw(-- debian);
2786             if ($some_patches) {
2787                 rm_subdir_cached 'debian/patches';
2788                 $work = make_commit [ $work ], [
2789  'git-debrebase convert-from-dgit-view: drop upstream changes from breakwater',
2790  "Drop upstream changes, and delete debian/patches, as part of converting\n".
2791  "to git-debrebase format.  Upstream changes will appear as commits.",
2792  '[git-debrebase convert-from-dgit-view drop-patches]'
2793                                            ];
2794             }
2795             $work = make_commit [ $work, $u->{Commit} ], [
2796  'git-debrebase convert-from-dgit-view: declare upstream',
2797  '(Re)constructed breakwater merge.',
2798  '[git-debrebase anchor: declare upstream]'
2799                                                          ];
2800             runcmd @git, qw(checkout --quiet -b mk), $work;
2801             if ($some_patches) {
2802                 runcmd @git, qw(checkout), $head, qw(-- debian/patches);
2803                 runcmd @git, qw(reset --quiet);
2804                 my @gbp_cmd = (qw(gbp pq import));
2805                 if (!$diagnose) {
2806                     my $gbp_err = "../gbp-pq-err";
2807                     @gbp_cmd = shell_cmd "exec >$gbp_err 2>&1", @gbp_cmd;
2808                 }
2809                 my $r = system @gbp_cmd;
2810                 if ($r) {
2811                     printf STDERR
2812                         " %s: couldn't apply patches: gbp pq %s",
2813                         $u->{Source}, waitstatusmsg();
2814                     return;
2815                 }
2816             }
2817             my $work = git_rev_parse qw(HEAD);
2818             my $diffout = cmdoutput @git, qw(diff-tree --stat HEAD), $work;
2819             if (length $diffout) {
2820                 print STDERR
2821                     " $u->{Source}: applying patches gives different tree\n";
2822                 print STDERR $diffout if $diagnose;
2823                 return;
2824             }
2825             # OMG!
2826             $u->{Result} = $work;
2827             $result = $u;
2828         };
2829         last if $result;
2830     }
2831
2832     if (!$result) {
2833         fail <<END;
2834 Could not find or construct a suitable upstream commit.
2835 Rerun adding --diagnose after convert-from-dgit-view, or pass a
2836 upstream commmit explicitly or provide suitable origs.
2837 END
2838     }
2839
2840     printf STDERR "Yes, will base new branch on %s\n", $result->{Source};
2841
2842     complete_convert_from $head, $result->{Result}, $gdrlastinfo,
2843         'convert-from-dgit-view';
2844 }
2845
2846 sub cmd_forget_was_ever_debrebase () {
2847     badusage "forget-was-ever-debrebase takes no further arguments" if @ARGV;
2848     my ($ffqstatus, $ffq_msg, $current, $ffq_prev, $gdrlast) =
2849         ffq_prev_branchinfo();
2850     fail "Not suitable for recording git-debrebaseness anyway: $ffq_msg"
2851         if defined $ffq_msg;
2852     push @deferred_updates, "delete $ffq_prev";
2853     push @deferred_updates, "delete $gdrlast";
2854     snags_maybe_bail();
2855     run_deferred_updates "forget-was-ever-debrebase";
2856 }
2857
2858 sub cmd_record_resolved_merge () {
2859     badusage "record-resolved-merge takes no further arguments" if @ARGV;
2860     # MERGE-TODO needs documentation
2861     my $new = get_head();
2862     my $method;
2863
2864     print "Checking how you have resolved the merge problem\n";
2865     my $nope = sub { print "Not $method: @_"; 0; };
2866
2867     my $maybe = sub { print "Seems to be $method.\n"; };
2868     my $yes = sub {
2869         my ($key, $ref) = @_;
2870         reflog_cache_insert $merge_cache_ref, $key, $ref;
2871         print "OK.  You can switch branches and try git-debrebase again.\n";
2872         1;
2873     };
2874
2875     fresh_workarea 'merge';
2876     sub {
2877         $method = 'vanilla-merge patchqueue';
2878         my $vanilla = git_get_ref "$wrecknoteprefix/vanilla-merge";
2879         $vanilla or return $nope->("wreckage was not of vanilla-merge");
2880         foreach my $lr (qw(left right)) {
2881             my $n = "$wrecknoteprefix/$lr-patchqueue";
2882             my $lrpq = git_get_ref $n;
2883             $lrpq or return $nope->("wreckage did not contain patchqueues");
2884             is_fast_fwd $lrpq, $new or return $nope->("HEAD not ff of $n");
2885         }
2886         $maybe->();
2887         my $newbase = git_get_ref "$wrecknoteprefix/new-base"
2888             or die "wreckage element $wrecknoteprefix/new-base missing";
2889         my $result = merge_series_patchqueue_convert
2890             {}, $newbase, $new;
2891         $yes->("vanilla-merge $vanilla", $result);
2892         1;
2893     }->() or sub {
2894         fail "No resolved merge method seems applicable.\n";
2895     }->();
2896 }
2897
2898 sub cmd_downstream_rebase_launder_v0 () {
2899     badusage "needs 1 argument, the baseline" unless @ARGV==1;
2900     my ($base) = @ARGV;
2901     $base = git_rev_parse $base;
2902     my $old_head = get_head();
2903     my $current = $old_head;
2904     my $topmost_keep;
2905     for (;;) {
2906         if ($current eq $base) {
2907             $topmost_keep //= $current;
2908             print " $current BASE stop\n";
2909             last;
2910         }
2911         my $cl = classify $current;
2912         print " $current $cl->{Type}";
2913         my $keep = 0;
2914         my $p0 = $cl->{Parents}[0]{CommitId};
2915         my $next;
2916         if ($cl->{Type} eq 'Pseudomerge') {
2917             print " ^".($cl->{Contributor}{Ix}+1);
2918             $next = $cl->{Contributor}{CommitId};
2919         } elsif ($cl->{Type} eq 'AddPatches' or
2920                  $cl->{Type} eq 'Changelog') {
2921             print " strip";
2922             $next = $p0;
2923         } else {
2924             print " keep";
2925             $next = $p0;
2926             $keep = 1;
2927         }
2928         print "\n";
2929         if ($keep) {
2930             $topmost_keep //= $current;
2931         } else {
2932             die "to-be stripped changes not on top of the branch\n"
2933                 if $topmost_keep;
2934         }
2935         $current = $next;
2936     }
2937     if ($topmost_keep eq $old_head) {
2938         print "unchanged\n";
2939     } else {
2940         print "updating to $topmost_keep\n";
2941         update_head_checkout
2942             $old_head, $topmost_keep,
2943             'downstream-rebase-launder-v0';
2944     }
2945 }
2946
2947 getoptions_main
2948           ("bad options\n",
2949            "D+" => \$debuglevel,
2950            'noop-ok', => \$opt_noop_ok,
2951            'f=s' => \@snag_force_opts,
2952            'anchor=s' => \@opt_anchors,
2953            '--dgit=s' => \($dgit[0]),
2954            'force!',
2955            'experimental-merge-resolution!', \$opt_merges,
2956            '-i:s' => sub {
2957                my ($opt,$val) = @_;
2958                badusage "git-debrebase: no cuddling to -i for git-rebase"
2959                    if length $val;
2960                die if $opt_defaultcmd_interactive; # should not happen
2961                $opt_defaultcmd_interactive = [ qw(-i) ];
2962                # This access to @ARGV is excessive familiarity with
2963                # Getopt::Long, but there isn't another sensible
2964                # approach.  '-i=s{0,}' does not work with bundling.
2965                push @$opt_defaultcmd_interactive, @ARGV;
2966                @ARGV=();
2967            },
2968            'help' => sub { print $usage_message or die $!; finish 0; },
2969            );
2970
2971 initdebug('git-debrebase ');
2972 enabledebug if $debuglevel;
2973
2974 my $toplevel = cmdoutput @git, qw(rev-parse --show-toplevel);
2975 chdir $toplevel or die "chdir $toplevel: $!";
2976
2977 $rd = fresh_playground "$playprefix/misc";
2978
2979 @opt_anchors = map { git_rev_parse $_ } @opt_anchors;
2980
2981 if (!@ARGV || $opt_defaultcmd_interactive || $ARGV[0] =~ m{^-}) {
2982     defaultcmd_rebase();
2983 } else {
2984     my $cmd = shift @ARGV;
2985     my $cmdfn = $cmd;
2986     $cmdfn =~ y/-/_/;
2987     $cmdfn = ${*::}{"cmd_$cmdfn"};
2988
2989     $cmdfn or badusage "unknown git-debrebase sub-operation $cmd";
2990     $cmdfn->();
2991 }
2992
2993 finish 0;