dgit

   1 #!/usr/bin/perl -w
   2 # dgit
   3 # Integration between git and Debian-style archives
   4 #
   5 # Copyright (C)2013 Ian Jackson
   6 #
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 use strict;
  21
  22 use IO::Handle;
  23 use Data::Dumper;
  24 use LWP::UserAgent;
  25 use Dpkg::Control::Hash;
  26 use File::Path;
  27 use File::Temp qw(tempdir);
  28 use File::Basename;
  29 use Dpkg::Version;
  30 use POSIX;
  31 use IPC::Open2;
  32 use Digest::SHA;
  33 use Digest::MD5;
  34 use Config;
  35
  36 our $our_version = 'UNRELEASED'; ###substituted###
  37
  38 our $rpushprotovsn = 2;
  39
  40 our $isuite = 'unstable';
  41 our $idistro;
  42 our $package;
  43 our @ropts;
  44
  45 our $sign = 1;
  46 our $dryrun_level = 0;
  47 our $changesfile;
  48 our $buildproductsdir = '..';
  49 our $new_package = 0;
  50 our $ignoredirty = 0;
  51 our $noquilt = 0;
  52 our $rmonerror = 1;
  53 our $existing_package = 'dpkg';
  54 our $cleanmode = 'dpkg-source';
  55 our $changes_since_version;
  56 our $we_are_responder;
  57 our $initiator_tempdir;
  58
  59 our %format_ok = map { $_=>1 } ("1.0","3.0 (native)","3.0 (quilt)");
  60
  61 our $suite_re = '[-+.0-9a-z]+';
  62
  63 our (@git) = qw(git);
  64 our (@dget) = qw(dget);
  65 our (@curl) = qw(curl -f);
  66 our (@dput) = qw(dput);
  67 our (@debsign) = qw(debsign);
  68 our (@gpg) = qw(gpg);
  69 our (@sbuild) = qw(sbuild -A);
  70 our (@ssh) = 'ssh';
  71 our (@dgit) = qw(dgit);
  72 our (@dpkgbuildpackage) = qw(dpkg-buildpackage -i\.git/ -I.git);
  73 our (@dpkgsource) = qw(dpkg-source -i\.git/ -I.git);
  74 our (@dpkggenchanges) = qw(dpkg-genchanges);
  75 our (@mergechanges) = qw(mergechanges -f);
  76 our (@changesopts) = ('');
  77
  78 our %opts_opt_map = ('dget' => \@dget, # accept for compatibility
  79                      'curl' => \@curl,
  80                      'dput' => \@dput,
  81                      'debsign' => \@debsign,
  82                      'gpg' => \@gpg,
  83                      'sbuild' => \@sbuild,
  84                      'ssh' => \@ssh,
  85                      'dgit' => \@dgit,
  86                      'dpkg-source' => \@dpkgsource,
  87                      'dpkg-buildpackage' => \@dpkgbuildpackage,
  88                      'dpkg-genchanges' => \@dpkggenchanges,
  89                      'ch' => \@changesopts,
  90                      'mergechanges' => \@mergechanges);
  91
  92 our %opts_opt_cmdonly = ('gpg' => 1);
  93
  94 our $keyid;
  95
  96 our $debug = 0;
  97 open DEBUG, ">/dev/null" or die $!;
  98
  99 autoflush STDOUT 1;
 100
 101 our $remotename = 'dgit';
 102 our @ourdscfield = qw(Dgit Vcs-Dgit-Master);
 103 our $branchprefix = 'dgit';
 104 our $csuite;
 105
 106 sub lbranch () { return "$branchprefix/$csuite"; }
 107 my $lbranch_re = '^refs/heads/'.$branchprefix.'/([^/.]+)$';
 108 sub lref () { return "refs/heads/".lbranch(); }
 109 sub lrref () { return "refs/remotes/$remotename/$branchprefix/$csuite"; }
 110 sub rrref () { return "refs/$branchprefix/$csuite"; }
 111 sub debiantag ($) {
 112     my ($v) = @_;
 113     $v =~ y/~:/_%/;
 114     return "debian/$v";
 115 }
 116
 117 sub stripepoch ($) {
 118     my ($vsn) = @_;
 119     $vsn =~ s/^\d+\://;
 120     return $vsn;
 121 }
 122
 123 sub srcfn ($$) {
 124     my ($vsn,$sfx) = @_;
 125     return "${package}_".(stripepoch $vsn).$sfx
 126 }
 127
 128 sub dscfn ($) {
 129     my ($vsn) = @_;
 130     return srcfn($vsn,".dsc");
 131 }
 132
 133 our $us = 'dgit';
 134 our $debugprefix = '';
 135
 136 our @end;
 137 END {
 138     local ($?);
 139     foreach my $f (@end) {
 140         eval { $f->(); };
 141         warn "$us: cleanup: $@" if length $@;
 142     }
 143 };
 144
 145 our @signames = split / /, $Config{sig_name};
 146
 147 sub waitstatusmsg () {
 148     if (!$?) {
 149         return "terminated, reporting successful completion";
 150     } elsif (!($? & 255)) {
 151         return "failed with error exit status ".WEXITSTATUS($?);
 152     } elsif (WIFSIGNALED($?)) {
 153         my $signum=WTERMSIG($?);
 154         return "died due to fatal signal ".
 155             ($signames[$signum] // "number $signum").
 156             ($? & 128 ? " (core dumped)" : ""); # POSIX(3pm) has no WCOREDUMP
 157     } else {
 158         return "failed with unknown wait status ".$?;
 159     }
 160 }
 161
 162 sub printdebug { print DEBUG $debugprefix, @_ or die $!; }
 163
 164 sub fail {
 165     die $us.($we_are_responder ? " (build host)" : "").": @_\n";
 166 }
 167
 168 sub badcfg { print STDERR "$us: invalid configuration: @_\n"; exit 12; }
 169
 170 sub no_such_package () {
 171     print STDERR "$us: package $package does not exist in suite $isuite\n";
 172     exit 4;
 173 }
 174
 175 sub fetchspec () {
 176     local $csuite = '*';
 177     return  "+".rrref().":".lrref();
 178 }
 179
 180 sub changedir ($) {
 181     my ($newdir) = @_;
 182     printdebug "CD $newdir\n";
 183     chdir $newdir or die "chdir: $newdir: $!";
 184 }
 185
 186 sub stat_exists ($) {
 187     my ($f) = @_;
 188     return 1 if stat $f;
 189     return 0 if $!==&ENOENT;
 190     die "stat $f: $!";
 191 }
 192
 193 #---------- remote protocol support, common ----------
 194
 195 # remote push initiator/responder protocol:
 196 #  < dgit-remote-push-ready [optional extra info ignored by old initiators]
 197 #
 198 #  > file parsed-changelog
 199 #  [indicates that output of dpkg-parsechangelog follows]
 200 #  > data-block NBYTES
 201 #  > [NBYTES bytes of data (no newline)]
 202 #  [maybe some more blocks]
 203 #  > data-end
 204 #
 205 #  > file dsc
 206 #  [etc]
 207 #
 208 #  > file changes
 209 #  [etc]
 210 #
 211 #  > param head HEAD
 212 #
 213 #  > want signed-tag
 214 #  [indicates that signed tag is wanted]
 215 #  < data-block NBYTES
 216 #  < [NBYTES bytes of data (no newline)]
 217 #  [maybe some more blocks]
 218 #  < data-end
 219 #  < files-end
 220 #
 221 #  > want signed-dsc-changes
 222 #  < data-block NBYTES    [transfer of signed dsc]
 223 #  [etc]
 224 #  < data-block NBYTES    [transfer of signed changes]
 225 #  [etc]
 226 #  < files-end
 227 #
 228 #  > complete
 229
 230 our $i_child_pid;
 231
 232 sub i_child_report () {
 233     # Sees if our child has died, and reap it if so.  Returns a string
 234     # describing how it died if it failed, or undef otherwise.
 235     return undef unless $i_child_pid;
 236     my $got = waitpid $i_child_pid, WNOHANG;
 237     return undef if $got <= 0;
 238     die unless $got == $i_child_pid;
 239     $i_child_pid = undef;
 240     return undef unless $?;
 241     return "build host child ".waitstatusmsg();
 242 }
 243
 244 sub badproto ($$) {
 245     my ($fh, $m) = @_;
 246     fail "connection lost: $!" if $fh->error;
 247     fail "protocol violation; $m not expected";
 248 }
 249
 250 sub badproto_badread ($$) {
 251     my ($fh, $wh) = @_;
 252     fail "connection lost: $!" if $!;
 253     my $report = i_child_report();
 254     fail $report if defined $report;
 255     badproto $fh, "eof (reading $wh)";
 256 }
 257
 258 sub protocol_expect (&$) {
 259     my ($match, $fh) = @_;
 260     local $_;
 261     $_ = <$fh>;
 262     defined && chomp or badproto_badread $fh, "protocol message";
 263     if (wantarray) {
 264         my @r = &$match;
 265         return @r if @r;
 266     } else {
 267         my $r = &$match;
 268         return $r if $r;
 269     }
 270     badproto $fh, "\`$_'";
 271 }
 272
 273 sub protocol_send_file ($$) {
 274     my ($fh, $ourfn) = @_;
 275     open PF, "<", $ourfn or die "$ourfn: $!";
 276     for (;;) {
 277         my $d;
 278         my $got = read PF, $d, 65536;
 279         die "$ourfn: $!" unless defined $got;
 280         last if !$got;
 281         print $fh "data-block ".length($d)."\n" or die $!;
 282         print $fh $d or die $!;
 283     }
 284     PF->error and die "$ourfn $!";
 285     print $fh "data-end\n" or die $!;
 286     close PF;
 287 }
 288
 289 sub protocol_read_bytes ($$) {
 290     my ($fh, $nbytes) = @_;
 291     $nbytes =~ m/^[1-9]\d{0,5}$/ or badproto \*RO, "bad byte count";
 292     my $d;
 293     my $got = read $fh, $d, $nbytes;
 294     $got==$nbytes or badproto_badread $fh, "data block";
 295     return $d;
 296 }
 297
 298 sub protocol_receive_file ($$) {
 299     my ($fh, $ourfn) = @_;
 300     printdebug "() $ourfn\n";
 301     open PF, ">", $ourfn or die "$ourfn: $!";
 302     for (;;) {
 303         my ($y,$l) = protocol_expect {
 304             m/^data-block (.*)$/ ? (1,$1) :
 305             m/^data-end$/ ? (0,) :
 306             ();
 307         } $fh;
 308         last unless $y;
 309         my $d = protocol_read_bytes $fh, $l;
 310         print PF $d or die $!;
 311     }
 312     close PF or die $!;
 313 }
 314
 315 #---------- remote protocol support, responder ----------
 316
 317 sub responder_send_command ($) {
 318     my ($command) = @_;
 319     return unless $we_are_responder;
 320     # called even without $we_are_responder
 321     printdebug ">> $command\n";
 322     print PO $command, "\n" or die $!;
 323 }
 324
 325 sub responder_send_file ($$) {
 326     my ($keyword, $ourfn) = @_;
 327     return unless $we_are_responder;
 328     printdebug "]] $keyword $ourfn\n";
 329     responder_send_command "file $keyword";
 330     protocol_send_file \*PO, $ourfn;
 331 }
 332
 333 sub responder_receive_files ($@) {
 334     my ($keyword, @ourfns) = @_;
 335     die unless $we_are_responder;
 336     printdebug "[[ $keyword @ourfns\n";
 337     responder_send_command "want $keyword";
 338     foreach my $fn (@ourfns) {
 339         protocol_receive_file \*PI, $fn;
 340     }
 341     printdebug "[[\$\n";
 342     protocol_expect { m/^files-end$/ } \*PI;
 343 }
 344
 345 #---------- remote protocol support, initiator ----------
 346
 347 sub initiator_expect (&) {
 348     my ($match) = @_;
 349     protocol_expect { &$match } \*RO;
 350 }
 351
 352 #---------- end remote code ----------
 353
 354 sub progress {
 355     if ($we_are_responder) {
 356         my $m = join '', @_;
 357         responder_send_command "progress ".length($m) or die $!;
 358         print PO $m or die $!;
 359     } else {
 360         print @_, "\n";
 361     }
 362 }
 363
 364 our $ua;
 365
 366 sub url_get {
 367     if (!$ua) {
 368         $ua = LWP::UserAgent->new();
 369         $ua->env_proxy;
 370     }
 371     my $what = $_[$#_];
 372     progress "downloading $what...";
 373     my $r = $ua->get(@_) or die $!;
 374     return undef if $r->code == 404;
 375     $r->is_success or fail "failed to fetch $what: ".$r->status_line;
 376     return $r->decoded_content(charset => 'none');
 377 }
 378
 379 our ($dscdata,$dscurl,$dsc,$dsc_checked,$skew_warning_vsn);
 380
 381 sub shellquote {
 382     my @out;
 383     local $_;
 384     foreach my $a (@_) {
 385         $_ = $a;
 386         if (m{[^-=_./0-9a-z]}i) {
 387             s{['\\]}{'\\$&'}g;
 388             push @out, "'$_'";
 389         } else {
 390             push @out, $_;
 391         }
 392     }
 393     return join ' ', @out;
 394 }
 395
 396 sub printcmd {
 397     my $fh = shift @_;
 398     my $intro = shift @_;
 399     print $fh $intro," " or die $!;
 400     print $fh shellquote @_ or die $!;
 401     print $fh "\n" or die $!;
 402 }
 403
 404 sub failedcmd {
 405     { local ($!); printcmd \*STDERR, "$us: failed command:", @_ or die $!; };
 406     if ($!) {
 407         fail "failed to fork/exec: $!";
 408     } elsif ($?) {
 409         fail "subprocess ".waitstatusmsg();
 410     } else {
 411         fail "subprocess produced invalid output";
 412     }
 413 }
 414
 415 sub runcmd {
 416     printcmd(\*DEBUG,$debugprefix."+",@_) if $debug>0;
 417     $!=0; $?=0;
 418     failedcmd @_ if system @_;
 419 }
 420
 421 sub act_local () { return $dryrun_level <= 1; }
 422 sub act_scary () { return !$dryrun_level; }
 423
 424 sub printdone {
 425     if (!$dryrun_level) {
 426         progress "dgit ok: @_";
 427     } else {
 428         progress "would be ok: @_ (but dry run only)";
 429     }
 430 }
 431
 432 sub cmdoutput_errok {
 433     die Dumper(\@_)." ?" if grep { !defined } @_;
 434     printcmd(\*DEBUG,$debugprefix."|",@_) if $debug>0;
 435     open P, "-|", @_ or die $!;
 436     my $d;
 437     $!=0; $?=0;
 438     { local $/ = undef; $d = <P>; }
 439     die $! if P->error;
 440     if (!close P) { printdebug "=>!$?\n" if $debug>0; return undef; }
 441     chomp $d;
 442     $d =~ m/^.*/;
 443     printdebug "=> \`$&'",(length $' ? '...' : ''),"\n" if $debug>0; #';
 444     return $d;
 445 }
 446
 447 sub cmdoutput {
 448     my $d = cmdoutput_errok @_;
 449     defined $d or failedcmd @_;
 450     return $d;
 451 }
 452
 453 sub dryrun_report {
 454     printcmd(\*STDERR,$debugprefix."#",@_);
 455 }
 456
 457 sub runcmd_ordryrun {
 458     if (act_scary()) {
 459         runcmd @_;
 460     } else {
 461         dryrun_report @_;
 462     }
 463 }
 464
 465 sub runcmd_ordryrun_local {
 466     if (act_local()) {
 467         runcmd @_;
 468     } else {
 469         dryrun_report @_;
 470     }
 471 }
 472
 473 sub shell_cmd {
 474     my ($first_shell, @cmd) = @_;
 475     return qw(sh -ec), $first_shell.'; exec "$@"', 'x', @cmd;
 476 }
 477
 478 our $helpmsg = <<END;
 479 main usages:
 480   dgit [dgit-opts] clone [dgit-opts] package [suite] [./dir|/dir]
 481   dgit [dgit-opts] fetch|pull [dgit-opts] [suite]
 482   dgit [dgit-opts] build [git-buildpackage-opts|dpkg-buildpackage-opts]
 483   dgit [dgit-opts] push [dgit-opts] [suite]
 484   dgit [dgit-opts] rpush build-host:build-dir ...
 485 important dgit options:
 486   -k<keyid>           sign tag and package with <keyid> instead of default
 487   --dry-run -n        do not change anything, but go through the motions
 488   --damp-run -L       like --dry-run but make local changes, without signing
 489   --new -N            allow introducing a new package
 490   --debug -D          increase debug level
 491   -c<name>=<value>    set git config option (used directly by dgit too)
 492 END
 493
 494 our $later_warning_msg = <<END;
 495 Perhaps the upload is stuck in incoming.  Using the version from git.
 496 END
 497
 498 sub badusage {
 499     print STDERR "$us: @_\n", $helpmsg or die $!;
 500     exit 8;
 501 }
 502
 503 sub nextarg {
 504     @ARGV or badusage "too few arguments";
 505     return scalar shift @ARGV;
 506 }
 507
 508 sub cmd_help () {
 509     print $helpmsg or die $!;
 510     exit 0;
 511 }
 512
 513 our $td = $ENV{DGIT_TEST_DUMMY_DIR} || "DGIT_TEST_DUMMY_DIR-unset";
 514
 515 our %defcfg = ('dgit.default.distro' => 'debian',
 516                'dgit.default.username' => '',
 517                'dgit.default.archive-query-default-component' => 'main',
 518                'dgit.default.ssh' => 'ssh',
 519                'dgit.default.archive-query' => 'madison:',
 520                'dgit.default.sshpsql-dbname' => 'service=projectb',
 521                'dgit-distro.debian.archive-query' => 'sshpsql:',
 522                'dgit-distro.debian.git-host' => 'git.debian.org',
 523                'dgit-distro.debian.git-proto' => 'git+ssh://',
 524                'dgit-distro.debian.git-path' => '/git/dgit-repos/repos',
 525                'dgit-distro.debian.git-check' => 'ssh-cmd',
 526                'dgit-distro.debian.git-create' => 'ssh-cmd',
 527                'dgit-distro.debian.sshpsql-host' => 'mirror.ftp-master.debian.org',
 528                'dgit-distro.debian.upload-host' => 'ftp-master', # for dput
 529                'dgit-distro.debian.mirror' => 'http://ftp.debian.org/debian/',
 530  'dgit-distro.debian.backports-quirk' => '(squeeze)-backports*',
 531  'dgit-distro.debian-backports.mirror' => 'http://backports.debian.org/debian-backports/',
 532                'dgit-distro.ubuntu.git-check' => 'false',
 533  'dgit-distro.ubuntu.mirror' => 'http://archive.ubuntu.com/ubuntu',
 534                'dgit-distro.test-dummy.ssh' => "$td/ssh",
 535                'dgit-distro.test-dummy.username' => "alice",
 536                'dgit-distro.test-dummy.git-check' => "ssh-cmd",
 537                'dgit-distro.test-dummy.git-create' => "ssh-cmd",
 538                'dgit-distro.test-dummy.git-url' => "$td/git",
 539                'dgit-distro.test-dummy.git-host' => "git",
 540                'dgit-distro.test-dummy.git-path' => "$td/git",
 541                'dgit-distro.test-dummy.archive-query' => "dummycat:$td/aq",
 542                'dgit-distro.test-dummy.mirror' => "file://$td/mirror/",
 543                'dgit-distro.test-dummy.upload-host' => 'test-dummy',
 544                );
 545
 546 sub cfg {
 547     foreach my $c (@_) {
 548         return undef if $c =~ /RETURN-UNDEF/;
 549         my @cmd = (@git, qw(config --), $c);
 550         my $v;
 551         {
 552             local ($debug) = $debug-1;
 553             $v = cmdoutput_errok @cmd;
 554         };
 555         if ($?==0) {
 556             return $v;
 557         } elsif ($?!=256) {
 558             failedcmd @cmd;
 559         }
 560         my $dv = $defcfg{$c};
 561         return $dv if defined $dv;
 562     }
 563     badcfg "need value for one of: @_\n".
 564         "$us: distro or suite appears not to be (properly) supported";
 565 }
 566
 567 sub access_basedistro () {
 568     if (defined $idistro) {
 569         return cfg("dgit-distro.basedistro.distro",
 570                    "dgit-suite.$isuite.distro",
 571                    'RETURN-UNDEF') // $idistro;
 572     } else {
 573         return cfg("dgit-suite.$isuite.distro",
 574                    "dgit.default.distro");
 575     }
 576 }
 577
 578 sub access_quirk () {
 579     # returns (quirk name, distro to use instead, quirk-specific info)
 580     my $basedistro = access_basedistro();
 581     my $backports_quirk = cfg("dgit-distro.$basedistro.backports-quirk",
 582                               'RETURN-UNDEF');
 583     if (defined $backports_quirk) {
 584         my $re = $backports_quirk;
 585         $re =~ s/[^-0-9a-z_\%*()]/\\$&/ig;
 586         $re =~ s/\*/.*/g;
 587         $re =~ s/\%/([-0-9a-z_]+)/
 588             or $re =~ m/[()]/ or badcfg "backports-quirk needs \% or ( )";
 589         if ($isuite =~ m/^$re$/) {
 590             return ('backports',"$basedistro-backports",$1);
 591         }
 592     }
 593     return ('none',$basedistro);
 594 }
 595
 596 sub access_distro () {
 597     return (access_quirk())[1];
 598 }
 599
 600 sub access_cfg (@) {
 601     my (@keys) = @_;
 602     my $basedistro = access_basedistro();
 603     my $distro = $idistro || access_distro();
 604     my $value = cfg(map {
 605         ("dgit-distro.$distro.$_",
 606          "dgit-distro.$basedistro.$_",
 607          "dgit.default.$_")
 608                     } @keys);
 609     return $value;
 610 }
 611
 612 sub string_to_ssh ($) {
 613     my ($spec) = @_;
 614     if ($spec =~ m/\s/) {
 615         return qw(sh -ec), 'exec '.$spec.' "$@"', 'x';
 616     } else {
 617         return ($spec);
 618     }
 619 }
 620
 621 sub access_cfg_ssh () {
 622     my $gitssh = access_cfg('ssh', 'RETURN-UNDEF');
 623     if (!defined $gitssh) {
 624         return @ssh;
 625     } else {
 626         return string_to_ssh $gitssh;
 627     }
 628 }
 629
 630 sub access_someuserhost ($) {
 631     my ($some) = @_;
 632     my $user = access_cfg("$some-user",'username');
 633     my $host = access_cfg("$some-host");
 634     return length($user) ? "$user\@$host" : $host;
 635 }
 636
 637 sub access_gituserhost () {
 638     return access_someuserhost('git');
 639 }
 640
 641 sub access_giturl () {
 642     my $url = access_cfg('git-url','RETURN-UNDEF');
 643     if (!defined $url) {
 644         $url =
 645             access_cfg('git-proto').
 646             access_gituserhost().
 647             access_cfg('git-path');
 648     }
 649     return "$url/$package.git";
 650 }
 651
 652 sub parsecontrolfh ($$;$) {
 653     my ($fh, $desc, $allowsigned) = @_;
 654     our $dpkgcontrolhash_noissigned;
 655     my $c;
 656     for (;;) {
 657         my %opts = ('name' => $desc);
 658         $opts{allow_pgp}= $allowsigned || !$dpkgcontrolhash_noissigned;
 659         $c = Dpkg::Control::Hash->new(%opts);
 660         $c->parse($fh,$desc) or die "parsing of $desc failed";
 661         last if $allowsigned;
 662         last if $dpkgcontrolhash_noissigned;
 663         my $issigned= $c->get_option('is_pgp_signed');
 664         if (!defined $issigned) {
 665             $dpkgcontrolhash_noissigned= 1;
 666             seek $fh, 0,0 or die "seek $desc: $!";
 667         } elsif ($issigned) {
 668             fail "control file $desc is (already) PGP-signed. ".
 669                 " Note that dgit push needs to modify the .dsc and then".
 670                 " do the signature itself";
 671         } else {
 672             last;
 673         }
 674     }
 675     return $c;
 676 }
 677
 678 sub parsecontrol {
 679     my ($file, $desc) = @_;
 680     my $fh = new IO::Handle;
 681     open $fh, '<', $file or die "$file: $!";
 682     my $c = parsecontrolfh($fh,$desc);
 683     $fh->error and die $!;
 684     close $fh;
 685     return $c;
 686 }
 687
 688 sub getfield ($$) {
 689     my ($dctrl,$field) = @_;
 690     my $v = $dctrl->{$field};
 691     return $v if defined $v;
 692     fail "missing field $field in ".$v->get_option('name');
 693 }
 694
 695 sub parsechangelog {
 696     my $c = Dpkg::Control::Hash->new();
 697     my $p = new IO::Handle;
 698     my @cmd = (qw(dpkg-parsechangelog), @_);
 699     open $p, '-|', @cmd or die $!;
 700     $c->parse($p);
 701     $?=0; $!=0; close $p or failedcmd @cmd;
 702     return $c;
 703 }
 704
 705 sub git_get_ref ($) {
 706     my ($refname) = @_;
 707     my $got = cmdoutput_errok @git, qw(show-ref --), $refname;
 708     if (!defined $got) {
 709         $?==256 or fail "git show-ref failed (status $?)";
 710         printdebug "ref $refname= [show-ref exited 1]\n";
 711         return '';
 712     }
 713     if ($got =~ m/^(\w+) \Q$refname\E$/m) {
 714         printdebug "ref $refname=$1\n";
 715         return $1;
 716     } else {
 717         printdebug "ref $refname= [no match]\n";
 718         return '';
 719     }
 720 }
 721
 722 sub must_getcwd () {
 723     my $d = getcwd();
 724     defined $d or fail "getcwd failed: $!";
 725     return $d;
 726 }
 727
 728 our %rmad;
 729
 730 sub archive_query ($) {
 731     my ($method) = @_;
 732     my $query = access_cfg('archive-query','RETURN-UNDEF');
 733     $query =~ s/^(\w+):// or badcfg "invalid archive-query method \`$query'";
 734     my $proto = $1;
 735     my $data = $'; #';
 736     { no strict qw(refs); &{"${method}_${proto}"}($proto,$data); }
 737 }
 738
 739 sub pool_dsc_subpath ($$) {
 740     my ($vsn,$component) = @_; # $package is implict arg
 741     my $prefix = substr($package, 0, $package =~ m/^l/ ? 4 : 1);
 742     return "/pool/$component/$prefix/$package/".dscfn($vsn);
 743 }
 744
 745 sub archive_query_madison ($$) {
 746     my ($proto,$data) = @_;
 747     die unless $proto eq 'madison';
 748     if (!length $data) {
 749         $data= access_cfg('madison-distro',access_basedistro());
 750     }
 751     $rmad{$package} ||= cmdoutput
 752         qw(rmadison -asource),"-s$isuite","-u$data",$package;
 753     my $rmad = $rmad{$package};
 754     return madison_parse($rmad);
 755 }
 756
 757 sub madison_parse ($) {
 758     my ($rmad) = @_;
 759     my @out;
 760     foreach my $l (split /\n/, $rmad) {
 761         $l =~ m{^ \s*( [^ \t|]+ )\s* \|
 762                   \s*( [^ \t|]+ )\s* \|
 763                   \s*( [^ \t|/]+ )(?:/([^ \t|/]+))? \s* \|
 764                   \s*( [^ \t|]+ )\s* }x or die "$rmad ?";
 765         $1 eq $package or die "$rmad $package ?";
 766         my $vsn = $2;
 767         my $newsuite = $3;
 768         my $component;
 769         if (defined $4) {
 770             $component = $4;
 771         } else {
 772             $component = access_cfg('archive-query-default-component');
 773         }
 774         $5 eq 'source' or die "$rmad ?";
 775         push @out, [$vsn,pool_dsc_subpath($vsn,$component),$newsuite];
 776     }
 777     return sort { -version_compare($a->[0],$b->[0]); } @out;
 778 }
 779
 780 sub canonicalise_suite_madison ($$) {
 781     # madison canonicalises for us
 782     my @r = archive_query_madison($_[0],$_[1]);
 783     @r or fail
 784         "unable to canonicalise suite using package $package".
 785         " which does not appear to exist in suite $isuite;".
 786         " --existing-package may help";
 787     return $r[0][2];
 788 }
 789
 790 sub sshpsql ($$) {
 791     my ($data,$sql) = @_;
 792     if (!length $data) {
 793         $data= access_someuserhost('sshpsql').':'.
 794             access_cfg('sshpsql-dbname');
 795     }
 796     $data =~ m/:/ or badcfg "invalid sshpsql method string \`$data'";
 797     my ($userhost,$dbname) = ($`,$'); #';
 798     my @rows;
 799     my @cmd = (access_cfg_ssh, $userhost,
 800                "export LANG=C; ".shellquote qw(psql -A), $dbname, qw(-c), $sql);
 801     printcmd(\*DEBUG,$debugprefix."|",@cmd) if $debug>0;
 802     open P, "-|", @cmd or die $!;
 803     while (<P>) {
 804         chomp or die;
 805         printdebug("$debugprefix>|$_|\n");
 806         push @rows, $_;
 807     }
 808     $!=0; $?=0; close P or failedcmd @cmd;
 809     @rows or die;
 810     my $nrows = pop @rows;
 811     $nrows =~ s/^\((\d+) rows?\)$/$1/ or die "$nrows ?";
 812     @rows == $nrows+1 or die "$nrows ".(scalar @rows)." ?";
 813     @rows = map { [ split /\|/, $_ ] } @rows;
 814     my $ncols = scalar @{ shift @rows };
 815     die if grep { scalar @$_ != $ncols } @rows;
 816     return @rows;
 817 }
 818
 819 sub sql_injection_check {
 820     foreach (@_) { die "$_ $& ?" if m/[']/; }
 821 }
 822
 823 sub archive_query_sshpsql ($$) {
 824     my ($proto,$data) = @_;
 825     sql_injection_check $isuite, $package;
 826     my @rows = sshpsql($data, <<END);
 827         SELECT source.version, component.name, files.filename, files.sha256sum
 828           FROM source
 829           JOIN src_associations ON source.id = src_associations.source
 830           JOIN suite ON suite.id = src_associations.suite
 831           JOIN dsc_files ON dsc_files.source = source.id
 832           JOIN files_archive_map ON files_archive_map.file_id = dsc_files.file
 833           JOIN component ON component.id = files_archive_map.component_id
 834           JOIN files ON files.id = dsc_files.file
 835          WHERE ( suite.suite_name='$isuite' OR suite.codename='$isuite' )
 836            AND source.source='$package'
 837            AND files.filename LIKE '%.dsc';
 838 END
 839     @rows = sort { -version_compare($a->[0],$b->[0]) } @rows;
 840     my $digester = Digest::SHA->new(256);
 841     @rows = map {
 842         my ($vsn,$component,$filename,$sha256sum) = @$_;
 843         [ $vsn, "/pool/$component/$filename",$digester,$sha256sum ];
 844     } @rows;
 845     return @rows;
 846 }
 847
 848 sub canonicalise_suite_sshpsql ($$) {
 849     my ($proto,$data) = @_;
 850     sql_injection_check $isuite;
 851     my @rows = sshpsql($data, <<END);
 852         SELECT suite.codename
 853           FROM suite where suite_name='$isuite' or codename='$isuite';
 854 END
 855     @rows = map { $_->[0] } @rows;
 856     fail "unknown suite $isuite" unless @rows;
 857     die "ambiguous $isuite: @rows ?" if @rows>1;
 858     return $rows[0];
 859 }
 860
 861 sub canonicalise_suite_dummycat ($$) {
 862     my ($proto,$data) = @_;
 863     my $dpath = "$data/suite.$isuite";
 864     if (!open C, "<", $dpath) {
 865         $!==ENOENT or die "$dpath: $!";
 866         printdebug "dummycat canonicalise_suite $isuite $dpath ENOENT\n";
 867         return $isuite;
 868     }
 869     $!=0; $_ = <C>;
 870     chomp or die "$dpath: $!";
 871     close C;
 872     printdebug "dummycat canonicalise_suite $isuite $dpath = $_\n";
 873     return $_;
 874 }
 875
 876 sub archive_query_dummycat ($$) {
 877     my ($proto,$data) = @_;
 878     canonicalise_suite();
 879     my $dpath = "$data/package.$csuite.$package";
 880     if (!open C, "<", $dpath) {
 881         $!==ENOENT or die "$dpath: $!";
 882         printdebug "dummycat query $csuite $package $dpath ENOENT\n";
 883         return ();
 884     }
 885     my @rows;
 886     while (<C>) {
 887         next if m/^\#/;
 888         next unless m/\S/;
 889         die unless chomp;
 890         printdebug "dummycat query $csuite $package $dpath | $_\n";
 891         my @row = split /\s+/, $_;
 892         @row==2 or die "$dpath: $_ ?";
 893         push @rows, \@row;
 894     }
 895     C->error and die "$dpath: $!";
 896     close C;
 897     return sort { -version_compare($a->[0],$b->[0]); } @rows;
 898 }
 899
 900 sub canonicalise_suite () {
 901     return if defined $csuite;
 902     fail "cannot operate on $isuite suite" if $isuite eq 'UNRELEASED';
 903     $csuite = archive_query('canonicalise_suite');
 904     if ($isuite ne $csuite) {
 905         progress "canonical suite name for $isuite is $csuite";
 906     }
 907 }
 908
 909 sub get_archive_dsc () {
 910     canonicalise_suite();
 911     my @vsns = archive_query('archive_query');
 912     foreach my $vinfo (@vsns) {
 913         my ($vsn,$subpath,$digester,$digest) = @$vinfo;
 914         $dscurl = access_cfg('mirror').$subpath;
 915         $dscdata = url_get($dscurl);
 916         if (!$dscdata) {
 917             $skew_warning_vsn = $vsn if !defined $skew_warning_vsn;
 918             next;
 919         }
 920         if ($digester) {
 921             $digester->reset();
 922             $digester->add($dscdata);
 923             my $got = $digester->hexdigest();
 924             $got eq $digest or
 925                 fail "$dscurl has hash $got but".
 926                     " archive told us to expect $digest";
 927         }
 928         my $dscfh = new IO::File \$dscdata, '<' or die $!;
 929         printdebug Dumper($dscdata) if $debug>1;
 930         $dsc = parsecontrolfh($dscfh,$dscurl,1);
 931         printdebug Dumper($dsc) if $debug>1;
 932         my $fmt = getfield $dsc, 'Format';
 933         fail "unsupported source format $fmt, sorry" unless $format_ok{$fmt};
 934         $dsc_checked = !!$digester;
 935         return;
 936     }
 937     $dsc = undef;
 938 }
 939
 940 sub check_for_git () {
 941     # returns 0 or 1
 942     my $how = access_cfg('git-check');
 943     if ($how eq 'ssh-cmd') {
 944         my @cmd =
 945             (access_cfg_ssh, access_gituserhost(),
 946              " set -e; cd ".access_cfg('git-path').";".
 947              " if test -d $package.git; then echo 1; else echo 0; fi");
 948         my $r= cmdoutput @cmd;
 949         failedcmd @cmd unless $r =~ m/^[01]$/;
 950         return $r+0;
 951     } elsif ($how eq 'true') {
 952         return 1;
 953     } elsif ($how eq 'false') {
 954         return 0;
 955     } else {
 956         badcfg "unknown git-check \`$how'";
 957     }
 958 }
 959
 960 sub create_remote_git_repo () {
 961     my $how = access_cfg('git-create');
 962     if ($how eq 'ssh-cmd') {
 963         runcmd_ordryrun
 964             (access_cfg_ssh, access_gituserhost(),
 965              "set -e; cd ".access_cfg('git-path').";".
 966              " cp -a _template $package.git");
 967     } elsif ($how eq 'true') {
 968         # nothing to do
 969     } else {
 970         badcfg "unknown git-create \`$how'";
 971     }
 972 }
 973
 974 our ($dsc_hash,$lastpush_hash);
 975
 976 our $ud = '.git/dgit/unpack';
 977
 978 sub prep_ud () {
 979     rmtree($ud);
 980     mkpath '.git/dgit';
 981     mkdir $ud or die $!;
 982 }
 983
 984 sub mktree_in_ud_here () {
 985     runcmd qw(git init -q);
 986     rmtree('.git/objects');
 987     symlink '../../../../objects','.git/objects' or die $!;
 988 }
 989
 990 sub mktree_in_ud_from_only_subdir () {
 991     # changes into the subdir
 992     my (@dirs) = <*/.>;
 993     die unless @dirs==1;
 994     $dirs[0] =~ m#^([^/]+)/\.$# or die;
 995     my $dir = $1;
 996     changedir $dir;
 997     fail "source package contains .git directory" if stat_exists '.git';
 998     mktree_in_ud_here();
 999     my $format=get_source_format();
1000     if (madformat($format)) {
1001         rmtree '.pc';
1002     }
1003     runcmd @git, qw(add -Af);
1004     my $tree = cmdoutput @git, qw(write-tree);
1005     $tree =~ m/^\w+$/ or die "$tree ?";
1006     return ($tree,$dir);
1007 }
1008
1009 sub dsc_files_info () {
1010     foreach my $csumi (['Checksums-Sha256','Digest::SHA', 'new(256)'],
1011                        ['Checksums-Sha1',  'Digest::SHA', 'new(1)'],
1012                        ['Files',           'Digest::MD5', 'new()']) {
1013         my ($fname, $module, $method) = @$csumi;
1014         my $field = $dsc->{$fname};
1015         next unless defined $field;
1016         eval "use $module; 1;" or die $@;
1017         my @out;
1018         foreach (split /\n/, $field) {
1019             next unless m/\S/;
1020             m/^(\w+) (\d+) (\S+)$/ or
1021                 fail "could not parse .dsc $fname line \`$_'";
1022             my $digester = eval "$module"."->$method;" or die $@;
1023             push @out, {
1024                 Hash => $1,
1025                 Bytes => $2,
1026                 Filename => $3,
1027                 Digester => $digester,
1028             };
1029         }
1030         return @out;
1031     }
1032     fail "missing any supported Checksums-* or Files field in ".
1033         $dsc->get_option('name');
1034 }
1035
1036 sub dsc_files () {
1037     map { $_->{Filename} } dsc_files_info();
1038 }
1039
1040 sub is_orig_file ($;$) {
1041     local ($_) = $_[0];
1042     my $base = $_[1];
1043     m/\.orig(?:-\w+)?\.tar\.\w+$/ or return 0;
1044     defined $base or return 1;
1045     return $` eq $base;
1046 }
1047
1048 sub make_commit ($) {
1049     my ($file) = @_;
1050     return cmdoutput @git, qw(hash-object -w -t commit), $file;
1051 }
1052
1053 sub clogp_authline ($) {
1054     my ($clogp) = @_;
1055     my $author = getfield $clogp, 'Maintainer';
1056     $author =~ s#,.*##ms;
1057     my $date = cmdoutput qw(date), '+%s %z', qw(-d), getfield($clogp,'Date');
1058     my $authline = "$author $date";
1059     $authline =~ m/^[^<>]+ \<\S+\> \d+ [-+]\d+$/ or
1060         fail "unexpected commit author line format \`$authline'".
1061         " (was generated from changelog Maintainer field)";
1062     return $authline;
1063 }
1064
1065 sub generate_commit_from_dsc () {
1066     prep_ud();
1067     changedir $ud;
1068
1069     foreach my $fi (dsc_files_info()) {
1070         my $f = $fi->{Filename};
1071         die "$f ?" if $f =~ m#/|^\.|\.dsc$|\.tmp$#;
1072
1073         link "../../../$f", $f
1074             or $!==&ENOENT
1075             or die "$f $!";
1076
1077         complete_file_from_dsc('.', $fi);
1078
1079         if (is_orig_file($f)) {
1080             link $f, "../../../../$f"
1081                 or $!==&EEXIST
1082                 or die "$f $!";
1083         }
1084     }
1085
1086     my $dscfn = "$package.dsc";
1087
1088     open D, ">", $dscfn or die "$dscfn: $!";
1089     print D $dscdata or die "$dscfn: $!";
1090     close D or die "$dscfn: $!";
1091     my @cmd = qw(dpkg-source);
1092     push @cmd, '--no-check' if $dsc_checked;
1093     push @cmd, qw(-x --), $dscfn;
1094     runcmd @cmd;
1095
1096     my ($tree,$dir) = mktree_in_ud_from_only_subdir();
1097     runcmd qw(sh -ec), 'dpkg-parsechangelog >../changelog.tmp';
1098     my $clogp = parsecontrol('../changelog.tmp',"commit's changelog");
1099     my $authline = clogp_authline $clogp;
1100     my $changes = getfield $clogp, 'Changes';
1101     open C, ">../commit.tmp" or die $!;
1102     print C <<END or die $!;
1103 tree $tree
1104 author $authline
1105 committer $authline
1106
1107 $changes
1108
1109 # imported from the archive
1110 END
1111     close C or die $!;
1112     my $outputhash = make_commit qw(../commit.tmp);
1113     my $cversion = getfield $clogp, 'Version';
1114     progress "synthesised git commit from .dsc $cversion";
1115     if ($lastpush_hash) {
1116         runcmd @git, qw(reset --hard), $lastpush_hash;
1117         runcmd qw(sh -ec), 'dpkg-parsechangelog >>../changelogold.tmp';
1118         my $oldclogp = parsecontrol('../changelogold.tmp','previous changelog');
1119         my $oversion = getfield $oldclogp, 'Version';
1120         my $vcmp =
1121             version_compare($oversion, $cversion);
1122         if ($vcmp < 0) {
1123             # git upload/ is earlier vsn than archive, use archive
1124             open C, ">../commit2.tmp" or die $!;
1125             print C <<END or die $!;
1126 tree $tree
1127 parent $lastpush_hash
1128 parent $outputhash
1129 author $authline
1130 committer $authline
1131
1132 Record $package ($cversion) in archive suite $csuite
1133 END
1134             $outputhash = make_commit qw(../commit2.tmp);
1135         } elsif ($vcmp > 0) {
1136             print STDERR <<END or die $!;
1137
1138 Version actually in archive:    $cversion (older)
1139 Last allegedly pushed/uploaded: $oversion (newer or same)
1140 $later_warning_msg
1141 END
1142             $outputhash = $lastpush_hash;
1143         } else {
1144             $outputhash = $lastpush_hash;
1145         }
1146     }
1147     changedir '../../../..';
1148     runcmd @git, qw(update-ref -m),"dgit fetch import $cversion",
1149             'DGIT_ARCHIVE', $outputhash;
1150     cmdoutput @git, qw(log -n2), $outputhash;
1151     # ... gives git a chance to complain if our commit is malformed
1152     rmtree($ud);
1153     return $outputhash;
1154 }
1155
1156 sub complete_file_from_dsc ($$) {
1157     our ($dstdir, $fi) = @_;
1158     # Ensures that we have, in $dir, the file $fi, with the correct
1159     # contents.  (Downloading it from alongside $dscurl if necessary.)
1160
1161     my $f = $fi->{Filename};
1162     my $tf = "$dstdir/$f";
1163     my $downloaded = 0;
1164
1165     if (stat_exists $tf) {
1166         progress "using existing $f";
1167     } else {
1168         my $furl = $dscurl;
1169         $furl =~ s{/[^/]+$}{};
1170         $furl .= "/$f";
1171         die "$f ?" unless $f =~ m/^${package}_/;
1172         die "$f ?" if $f =~ m#/#;
1173         runcmd_ordryrun_local @curl,qw(-o),$tf,'--',"$furl";
1174         next if !act_local();
1175         $downloaded = 1;
1176     }
1177
1178     open F, "<", "$tf" or die "$tf: $!";
1179     $fi->{Digester}->reset();
1180     $fi->{Digester}->addfile(*F);
1181     F->error and die $!;
1182     my $got = $fi->{Digester}->hexdigest();
1183     $got eq $fi->{Hash} or
1184         fail "file $f has hash $got but .dsc".
1185             " demands hash $fi->{Hash} ".
1186             ($downloaded ? "(got wrong file from archive!)"
1187              : "(perhaps you should delete this file?)");
1188 }
1189
1190 sub ensure_we_have_orig () {
1191     foreach my $fi (dsc_files_info()) {
1192         my $f = $fi->{Filename};
1193         next unless is_orig_file($f);
1194         complete_file_from_dsc('..', $fi);
1195     }
1196 }
1197
1198 sub rev_parse ($) {
1199     return cmdoutput @git, qw(rev-parse), "$_[0]~0";
1200 }
1201
1202 sub is_fast_fwd ($$) {
1203     my ($ancestor,$child) = @_;
1204     my @cmd = (@git, qw(merge-base), $ancestor, $child);
1205     my $mb = cmdoutput_errok @cmd;
1206     if (defined $mb) {
1207         return rev_parse($mb) eq rev_parse($ancestor);
1208     } else {
1209         $?==256 or failedcmd @cmd;
1210         return 0;
1211     }
1212 }
1213
1214 sub git_fetch_us () {
1215     runcmd_ordryrun_local @git, qw(fetch),access_giturl(),fetchspec();
1216 }
1217
1218 sub fetch_from_archive () {
1219     # ensures that lrref() is what is actually in the archive,
1220     #  one way or another
1221     get_archive_dsc();
1222
1223     if ($dsc) {
1224         foreach my $field (@ourdscfield) {
1225             $dsc_hash = $dsc->{$field};
1226             last if defined $dsc_hash;
1227         }
1228         if (defined $dsc_hash) {
1229             $dsc_hash =~ m/\w+/ or fail "invalid hash in .dsc \`$dsc_hash'";
1230             $dsc_hash = $&;
1231             progress "last upload to archive specified git hash";
1232         } else {
1233             progress "last upload to archive has NO git hash";
1234         }
1235     } else {
1236         progress "no version available from the archive";
1237     }
1238
1239     $lastpush_hash = git_get_ref(lrref());
1240     printdebug "previous reference hash=$lastpush_hash\n";
1241     my $hash;
1242     if (defined $dsc_hash) {
1243         fail "missing remote git history even though dsc has hash -".
1244             " could not find ref ".lrref().
1245             " (should have been fetched from ".access_giturl()."#".rrref().")"
1246             unless $lastpush_hash;
1247         $hash = $dsc_hash;
1248         ensure_we_have_orig();
1249         if ($dsc_hash eq $lastpush_hash) {
1250         } elsif (is_fast_fwd($dsc_hash,$lastpush_hash)) {
1251             print STDERR <<END or die $!;
1252
1253 Git commit in archive is behind the last version allegedly pushed/uploaded.
1254 Commit referred to by archive:  $dsc_hash
1255 Last allegedly pushed/uploaded: $lastpush_hash
1256 $later_warning_msg
1257 END
1258             $hash = $lastpush_hash;
1259         } else {
1260             fail "archive's .dsc refers to ".$dsc_hash.
1261                 " but this is an ancestor of ".$lastpush_hash;
1262         }
1263     } elsif ($dsc) {
1264         $hash = generate_commit_from_dsc();
1265     } elsif ($lastpush_hash) {
1266         # only in git, not in the archive yet
1267         $hash = $lastpush_hash;
1268         print STDERR <<END or die $!;
1269
1270 Package not found in the archive, but has allegedly been pushed using dgit.
1271 $later_warning_msg
1272 END
1273     } else {
1274         printdebug "nothing found!\n";
1275         if (defined $skew_warning_vsn) {
1276             print STDERR <<END or die $!;
1277
1278 Warning: relevant archive skew detected.
1279 Archive allegedly contains $skew_warning_vsn
1280 But we were not able to obtain any version from the archive or git.
1281
1282 END
1283         }
1284         return 0;
1285     }
1286     printdebug "current hash=$hash\n";
1287     if ($lastpush_hash) {
1288         fail "not fast forward on last upload branch!".
1289             " (archive's version left in DGIT_ARCHIVE)"
1290             unless is_fast_fwd($lastpush_hash, $hash);
1291     }
1292     if (defined $skew_warning_vsn) {
1293         mkpath '.git/dgit';
1294         printdebug "SKEW CHECK WANT $skew_warning_vsn\n";
1295         my $clogf = ".git/dgit/changelog.tmp";
1296         runcmd shell_cmd "exec >$clogf",
1297             @git, qw(cat-file blob), "$hash:debian/changelog";
1298         my $gotclogp = parsechangelog("-l$clogf");
1299         my $got_vsn = getfield $gotclogp, 'Version';
1300         printdebug "SKEW CHECK GOT $got_vsn\n";
1301         if (version_compare($got_vsn, $skew_warning_vsn) < 0) {
1302             print STDERR <<END or die $!;
1303
1304 Warning: archive skew detected.  Using the available version:
1305 Archive allegedly contains    $skew_warning_vsn
1306 We were able to obtain only   $got_vsn
1307
1308 END
1309         }
1310     }
1311     if ($lastpush_hash ne $hash) {
1312         my @upd_cmd = (@git, qw(update-ref -m), 'dgit fetch', lrref(), $hash);
1313         if (act_local()) {
1314             cmdoutput @upd_cmd;
1315         } else {
1316             dryrun_report @upd_cmd;
1317         }
1318     }
1319     return 1;
1320 }
1321
1322 sub clone ($) {
1323     my ($dstdir) = @_;
1324     canonicalise_suite();
1325     badusage "dry run makes no sense with clone" unless act_local();
1326     mkdir $dstdir or die "$dstdir $!";
1327     changedir $dstdir;
1328     runcmd @git, qw(init -q);
1329     runcmd @git, qw(config), "remote.$remotename.fetch", fetchspec();
1330     open H, "> .git/HEAD" or die $!;
1331     print H "ref: ".lref()."\n" or die $!;
1332     close H or die $!;
1333     runcmd @git, qw(remote add), 'origin', access_giturl();
1334     if (check_for_git()) {
1335         progress "fetching existing git history";
1336         git_fetch_us();
1337         runcmd_ordryrun_local @git, qw(fetch origin);
1338     } else {
1339         progress "starting new git history";
1340     }
1341     fetch_from_archive() or no_such_package;
1342     my $vcsgiturl = $dsc->{'Vcs-Git'};
1343     if (length $vcsgiturl) {
1344         runcmd @git, qw(remote add vcs-git), $vcsgiturl;
1345     }
1346     runcmd @git, qw(reset --hard), lrref();
1347     printdone "ready for work in $dstdir";
1348 }
1349
1350 sub fetch () {
1351     if (check_for_git()) {
1352         git_fetch_us();
1353     }
1354     fetch_from_archive() or no_such_package();
1355     printdone "fetched into ".lrref();
1356 }
1357
1358 sub pull () {
1359     fetch();
1360     runcmd_ordryrun_local @git, qw(merge -m),"Merge from $csuite [dgit]",
1361         lrref();
1362     printdone "fetched to ".lrref()." and merged into HEAD";
1363 }
1364
1365 sub check_not_dirty () {
1366     return if $ignoredirty;
1367     my @cmd = (@git, qw(diff --quiet HEAD));
1368     printcmd(\*DEBUG,$debugprefix."+",@cmd) if $debug>0;
1369     $!=0; $?=0; system @cmd;
1370     return if !$! && !$?;
1371     if (!$! && $?==256) {
1372         fail "working tree is dirty (does not match HEAD)";
1373     } else {
1374         failedcmd @cmd;
1375     }
1376 }
1377
1378 sub commit_admin ($) {
1379     my ($m) = @_;
1380     progress "$m";
1381     runcmd_ordryrun_local @git, qw(commit -m), $m;
1382 }
1383
1384 sub commit_quilty_patch () {
1385     my $output = cmdoutput @git, qw(status --porcelain);
1386     my %adds;
1387     foreach my $l (split /\n/, $output) {
1388         next unless $l =~ m/\S/;
1389         if ($l =~ m{^(?:\?\?| M) (.pc|debian/patches)}) {
1390             $adds{$1}++;
1391         }
1392     }
1393     delete $adds{'.pc'}; # if there wasn't one before, don't add it
1394     if (!%adds) {
1395         progress "nothing quilty to commit, ok.";
1396         return;
1397     }
1398     runcmd_ordryrun_local @git, qw(add), sort keys %adds;
1399     commit_admin "Commit Debian 3.0 (quilt) metadata";
1400 }
1401
1402 sub get_source_format () {
1403     if (!open F, "debian/source/format") {
1404         die $! unless $!==&ENOENT;
1405         return '';
1406     }
1407     $_ = <F>;
1408     F->error and die $!;
1409     chomp;
1410     return $_;
1411 }
1412
1413 sub madformat ($) {
1414     my ($format) = @_;
1415     return 0 unless $format eq '3.0 (quilt)';
1416     if ($noquilt) {
1417         progress "Not doing any fixup of \`$format' due to --no-quilt-fixup";
1418         return 0;
1419     }
1420     progress "Format \`$format', checking/updating patch stack";
1421     return 1;
1422 }
1423
1424 sub push_parse_changelog ($) {
1425     my ($clogpfn) = @_;
1426
1427     my $clogp = Dpkg::Control::Hash->new();
1428     $clogp->load($clogpfn) or die;
1429
1430     $package = getfield $clogp, 'Source';
1431     my $cversion = getfield $clogp, 'Version';
1432     my $tag = debiantag($cversion);
1433     runcmd @git, qw(check-ref-format), $tag;
1434
1435     my $dscfn = dscfn($cversion);
1436
1437     return ($clogp, $cversion, $tag, $dscfn);
1438 }
1439
1440 sub push_parse_dsc ($$$) {
1441     my ($dscfn,$dscfnwhat, $cversion) = @_;
1442     $dsc = parsecontrol($dscfn,$dscfnwhat);
1443     my $dversion = getfield $dsc, 'Version';
1444     my $dscpackage = getfield $dsc, 'Source';
1445     ($dscpackage eq $package && $dversion eq $cversion) or
1446         fail "$dscfn is for $dscpackage $dversion".
1447             " but debian/changelog is for $package $cversion";
1448 }
1449
1450 sub push_mktag ($$$$$$$) {
1451     my ($head,$clogp,$tag,
1452         $dscfn,
1453         $changesfile,$changesfilewhat,
1454         $tfn) = @_;
1455
1456     $dsc->{$ourdscfield[0]} = $head;
1457     $dsc->save("$dscfn.tmp") or die $!;
1458
1459     my $changes = parsecontrol($changesfile,$changesfilewhat);
1460     foreach my $field (qw(Source Distribution Version)) {
1461         $changes->{$field} eq $clogp->{$field} or
1462             fail "changes field $field \`$changes->{$field}'".
1463                 " does not match changelog \`$clogp->{$field}'";
1464     }
1465
1466     my $cversion = getfield $clogp, 'Version';
1467     my $clogsuite = getfield $clogp, 'Distribution';
1468
1469     # We make the git tag by hand because (a) that makes it easier
1470     # to control the "tagger" (b) we can do remote signing
1471     my $authline = clogp_authline $clogp;
1472     open TO, '>', $tfn->('.tmp') or die $!;
1473     print TO <<END or die $!;
1474 object $head
1475 type commit
1476 tag $tag
1477 tagger $authline
1478
1479 $package release $cversion for $clogsuite ($csuite) [dgit]
1480 END
1481     close TO or die $!;
1482
1483     my $tagobjfn = $tfn->('.tmp');
1484     if ($sign) {
1485         if (!defined $keyid) {
1486             $keyid = access_cfg('keyid','RETURN-UNDEF');
1487         }
1488         unlink $tfn->('.tmp.asc') or $!==&ENOENT or die $!;
1489         my @sign_cmd = (@gpg, qw(--detach-sign --armor));
1490         push @sign_cmd, qw(-u),$keyid if defined $keyid;
1491         push @sign_cmd, $tfn->('.tmp');
1492         runcmd_ordryrun @sign_cmd;
1493         if (act_scary()) {
1494             $tagobjfn = $tfn->('.signed.tmp');
1495             runcmd shell_cmd "exec >$tagobjfn", qw(cat --),
1496                 $tfn->('.tmp'), $tfn->('.tmp.asc');
1497         }
1498     }
1499
1500     return ($tagobjfn);
1501 }
1502
1503 sub sign_changes ($) {
1504     my ($changesfile) = @_;
1505     if ($sign) {
1506         my @debsign_cmd = @debsign;
1507         push @debsign_cmd, "-k$keyid" if defined $keyid;
1508         push @debsign_cmd, "-p$gpg[0]" if $gpg[0] ne 'gpg';
1509         push @debsign_cmd, $changesfile;
1510         runcmd_ordryrun @debsign_cmd;
1511     }
1512 }
1513
1514 sub dopush () {
1515     printdebug "actually entering push\n";
1516     prep_ud();
1517
1518     access_giturl(); # check that success is vaguely likely
1519
1520     my $clogpfn = ".git/dgit/changelog.822.tmp";
1521     runcmd shell_cmd "exec >$clogpfn", qw(dpkg-parsechangelog);
1522
1523     responder_send_file('parsed-changelog', $clogpfn);
1524
1525     my ($clogp, $cversion, $tag, $dscfn) =
1526         push_parse_changelog("$clogpfn");
1527
1528     my $dscpath = "$buildproductsdir/$dscfn";
1529     stat_exists $dscpath or
1530         fail "looked for .dsc $dscfn, but $!;".
1531             " maybe you forgot to build";
1532
1533     responder_send_file('dsc', $dscpath);
1534
1535     push_parse_dsc($dscpath, $dscfn, $cversion);
1536
1537     my $format = getfield $dsc, 'Format';
1538     printdebug "format $format\n";
1539     if (madformat($format)) {
1540         commit_quilty_patch();
1541     }
1542     check_not_dirty();
1543     changedir $ud;
1544     progress "checking that $dscfn corresponds to HEAD";
1545     runcmd qw(dpkg-source -x --),
1546         $dscpath =~ m#^/# ? $dscpath : "../../../$dscpath";
1547     my ($tree,$dir) = mktree_in_ud_from_only_subdir();
1548     changedir '../../../..';
1549     my $diffopt = $debug>0 ? '--exit-code' : '--quiet';
1550     my @diffcmd = (@git, qw(diff), $diffopt, $tree);
1551     printcmd \*DEBUG,$debugprefix."+",@diffcmd;
1552     $!=0; $?=0;
1553     my $r = system @diffcmd;
1554     if ($r) {
1555         if ($r==256) {
1556             fail "$dscfn specifies a different tree to your HEAD commit;".
1557                 " perhaps you forgot to build".
1558                 ($diffopt eq '--exit-code' ? "" :
1559                  " (run with -D to see full diff output)");
1560         } else {
1561             failedcmd @diffcmd;
1562         }
1563     }
1564 #fetch from alioth
1565 #do fast forward check and maybe fake merge
1566 #    if (!is_fast_fwd(mainbranch
1567 #    runcmd @git, qw(fetch -p ), "$alioth_git/$package.git",
1568 #        map { lref($_).":".rref($_) }
1569 #        (uploadbranch());
1570     my $head = rev_parse('HEAD');
1571     if (!$changesfile) {
1572         my $multi = "$buildproductsdir/".
1573             "${package}_".(stripepoch $cversion)."_multi.changes";
1574         if (stat_exists "$multi") {
1575             $changesfile = $multi;
1576         } else {
1577             my $pat = "${package}_".(stripepoch $cversion)."_*.changes";
1578             my @cs = glob "$buildproductsdir/$pat";
1579             fail "failed to find unique changes file".
1580                 " (looked for $pat in $buildproductsdir, or $multi);".
1581                 " perhaps you need to use dgit -C"
1582                 unless @cs==1;
1583             ($changesfile) = @cs;
1584         }
1585     } else {
1586         $changesfile = "$buildproductsdir/$changesfile";
1587     }
1588
1589     responder_send_file('changes',$changesfile);
1590     responder_send_command("param head $head");
1591     responder_send_command("param csuite $csuite");
1592
1593     my $tfn = sub { ".git/dgit/tag$_[0]"; };
1594     my $tagobjfn;
1595
1596     if ($we_are_responder) {
1597         $tagobjfn = $tfn->('.signed.tmp');
1598         responder_receive_files('signed-tag', $tagobjfn);
1599     } else {
1600         $tagobjfn =
1601             push_mktag($head,$clogp,$tag,
1602                        $dscpath,
1603                        $changesfile,$changesfile,
1604                        $tfn);
1605     }
1606
1607     my $tag_obj_hash = cmdoutput @git, qw(hash-object -w -t tag), $tagobjfn;
1608     runcmd_ordryrun @git, qw(verify-tag), $tag_obj_hash;
1609     runcmd_ordryrun_local @git, qw(update-ref), "refs/tags/$tag", $tag_obj_hash;
1610     runcmd_ordryrun @git, qw(tag -v --), $tag;
1611
1612     if (!check_for_git()) {
1613         create_remote_git_repo();
1614     }
1615     runcmd_ordryrun @git, qw(push),access_giturl(),
1616         "HEAD:".rrref(), "refs/tags/$tag";
1617     runcmd_ordryrun @git, qw(update-ref -m), 'dgit push', lrref(), 'HEAD';
1618
1619     if ($we_are_responder) {
1620         my $dryrunsuffix = act_local() ? "" : ".tmp";
1621         responder_receive_files('signed-dsc-changes',
1622                                 "$dscpath$dryrunsuffix",
1623                                 "$changesfile$dryrunsuffix");
1624     } else {
1625         if (act_local()) {
1626             rename "$dscpath.tmp",$dscpath or die "$dscfn $!";
1627         } else {
1628             progress "[new .dsc left in $dscpath.tmp]";
1629         }
1630         sign_changes $changesfile;
1631     }
1632
1633     my $host = access_cfg('upload-host','RETURN-UNDEF');
1634     my @hostarg = defined($host) ? ($host,) : ();
1635     runcmd_ordryrun @dput, @hostarg, $changesfile;
1636     printdone "pushed and uploaded $cversion";
1637
1638     responder_send_command("complete");
1639 }
1640
1641 sub cmd_clone {
1642     parseopts();
1643     my $dstdir;
1644     badusage "-p is not allowed with clone; specify as argument instead"
1645         if defined $package;
1646     if (@ARGV==1) {
1647         ($package) = @ARGV;
1648     } elsif (@ARGV==2 && $ARGV[1] =~ m#^\w#) {
1649         ($package,$isuite) = @ARGV;
1650     } elsif (@ARGV==2 && $ARGV[1] =~ m#^[./]#) {
1651         ($package,$dstdir) = @ARGV;
1652     } elsif (@ARGV==3) {
1653         ($package,$isuite,$dstdir) = @ARGV;
1654     } else {
1655         badusage "incorrect arguments to dgit clone";
1656     }
1657     $dstdir ||= "$package";
1658
1659     if (stat_exists $dstdir) {
1660         fail "$dstdir already exists";
1661     }
1662
1663     my $cwd_remove;
1664     if ($rmonerror && !$dryrun_level) {
1665         $cwd_remove= getcwd();
1666         unshift @end, sub {
1667             return unless defined $cwd_remove;
1668             if (!chdir "$cwd_remove") {
1669                 return if $!==&ENOENT;
1670                 die "chdir $cwd_remove: $!";
1671             }
1672             rmtree($dstdir) or die "remove $dstdir: $!\n";
1673         };
1674     }
1675
1676     clone($dstdir);
1677     $cwd_remove = undef;
1678 }
1679
1680 sub branchsuite () {
1681     my $branch = cmdoutput_errok @git, qw(symbolic-ref HEAD);
1682     if ($branch =~ m#$lbranch_re#o) {
1683         return $1;
1684     } else {
1685         return undef;
1686     }
1687 }
1688
1689 sub fetchpullargs () {
1690     if (!defined $package) {
1691         my $sourcep = parsecontrol('debian/control','debian/control');
1692         $package = getfield $sourcep, 'Source';
1693     }
1694     if (@ARGV==0) {
1695 #       $isuite = branchsuite();  # this doesn't work because dak hates canons
1696         if (!$isuite) {
1697             my $clogp = parsechangelog();
1698             $isuite = getfield $clogp, 'Distribution';
1699         }
1700         canonicalise_suite();
1701         progress "fetching from suite $csuite";
1702     } elsif (@ARGV==1) {
1703         ($isuite) = @ARGV;
1704         canonicalise_suite();
1705     } else {
1706         badusage "incorrect arguments to dgit fetch or dgit pull";
1707     }
1708 }
1709
1710 sub cmd_fetch {
1711     parseopts();
1712     fetchpullargs();
1713     fetch();
1714 }
1715
1716 sub cmd_pull {
1717     parseopts();
1718     fetchpullargs();
1719     pull();
1720 }
1721
1722 sub cmd_push {
1723     parseopts();
1724     badusage "-p is not allowed with dgit push" if defined $package;
1725     check_not_dirty();
1726     my $clogp = parsechangelog();
1727     $package = getfield $clogp, 'Source';
1728     my $specsuite;
1729     if (@ARGV==0) {
1730     } elsif (@ARGV==1) {
1731         ($specsuite) = (@ARGV);
1732     } else {
1733         badusage "incorrect arguments to dgit push";
1734     }
1735     $isuite = getfield $clogp, 'Distribution';
1736     if ($new_package) {
1737         local ($package) = $existing_package; # this is a hack
1738         canonicalise_suite();
1739     }
1740     if (defined $specsuite && $specsuite ne $isuite) {
1741         canonicalise_suite();
1742         $csuite eq $specsuite or
1743             fail "dgit push: changelog specifies $isuite ($csuite)".
1744                 " but command line specifies $specsuite";
1745     }
1746     if (check_for_git()) {
1747         git_fetch_us();
1748     }
1749     if (fetch_from_archive()) {
1750         is_fast_fwd(lrref(), 'HEAD') or
1751             fail "dgit push: HEAD is not a descendant".
1752                 " of the archive's version.\n".
1753                 "$us: To overwrite it, use git merge -s ours ".lrref().".";
1754     } else {
1755         $new_package or
1756             fail "package appears to be new in this suite;".
1757                 " if this is intentional, use --new";
1758     }
1759     dopush();
1760 }
1761
1762 #---------- remote commands' implementation ----------
1763
1764 sub cmd_remote_push_build_host {
1765     my ($nrargs) = shift @ARGV;
1766     my (@rargs) = @ARGV[0..$nrargs-1];
1767     @ARGV = @ARGV[$nrargs..$#ARGV];
1768     die unless @rargs;
1769     my ($dir,$vsnwant) = @rargs;
1770     # vsnwant is a comma-separated list; we report which we have
1771     # chosen in our ready response (so other end can tell if they
1772     # offered several)
1773     $debugprefix = ' ';
1774     $we_are_responder = 1;
1775
1776     open PI, "<&STDIN" or die $!;
1777     open STDIN, "/dev/null" or die $!;
1778     open PO, ">&STDOUT" or die $!;
1779     autoflush PO 1;
1780     open STDOUT, ">&STDERR" or die $!;
1781     autoflush STDOUT 1;
1782
1783     $vsnwant //= 1;
1784     fail "build host has dgit rpush protocol version".
1785         " $rpushprotovsn but invocation host has $vsnwant"
1786         unless grep { $rpushprotovsn eq $_ } split /,/, $vsnwant;
1787
1788     responder_send_command("dgit-remote-push-ready $rpushprotovsn");
1789
1790     changedir $dir;
1791     &cmd_push;
1792 }
1793
1794 sub cmd_remote_push_responder { cmd_remote_push_build_host(); }
1795 # ... for compatibility with proto vsn.1 dgit (just so that user gets
1796 #     a good error message)
1797
1798 our $i_tmp;
1799
1800 sub i_cleanup {
1801     local ($@, $?);
1802     my $report = i_child_report();
1803     if (defined $report) {
1804         printdebug "($report)\n";
1805     } elsif ($i_child_pid) {
1806         printdebug "(killing build host child $i_child_pid)\n";
1807         kill 15, $i_child_pid;
1808     }
1809     if (defined $i_tmp && !defined $initiator_tempdir) {
1810         changedir "/";
1811         eval { rmtree $i_tmp; };
1812     }
1813 }
1814
1815 END { i_cleanup(); }
1816
1817 sub i_method {
1818     my ($base,$selector,@args) = @_;
1819     $selector =~ s/\-/_/g;
1820     { no strict qw(refs); &{"${base}_${selector}"}(@args); }
1821 }
1822
1823 sub cmd_rpush {
1824     my $host = nextarg;
1825     my $dir;
1826     if ($host =~ m/^((?:[^][]|\[[^][]*\])*)\:/) {
1827         $host = $1;
1828         $dir = $'; #';
1829     } else {
1830         $dir = nextarg;
1831     }
1832     $dir =~ s{^-}{./-};
1833     my @rargs = ($dir,$rpushprotovsn);
1834     my @rdgit;
1835     push @rdgit, @dgit;
1836     push @rdgit, @ropts;
1837     push @rdgit, qw(remote-push-build-host), (scalar @rargs), @rargs;
1838     push @rdgit, @ARGV;
1839     my @cmd = (@ssh, $host, shellquote @rdgit);
1840     printcmd \*DEBUG,$debugprefix."+",@cmd;
1841
1842     if (defined $initiator_tempdir) {
1843         rmtree $initiator_tempdir;
1844         mkdir $initiator_tempdir, 0700 or die "$initiator_tempdir: $!";
1845         $i_tmp = $initiator_tempdir;
1846     } else {
1847         $i_tmp = tempdir();
1848     }
1849     $i_child_pid = open2(\*RO, \*RI, @cmd);
1850     changedir $i_tmp;
1851     initiator_expect { m/^dgit-remote-push-ready/ };
1852     for (;;) {
1853         my ($icmd,$iargs) = initiator_expect {
1854             m/^(\S+)(?: (.*))?$/;
1855             ($1,$2);
1856         };
1857         i_method "i_resp", $icmd, $iargs;
1858     }
1859 }
1860
1861 sub i_resp_progress ($) {
1862     my ($rhs) = @_;
1863     my $msg = protocol_read_bytes \*RO, $rhs;
1864     progress $msg;
1865 }
1866
1867 sub i_resp_complete {
1868     my $pid = $i_child_pid;
1869     $i_child_pid = undef; # prevents killing some other process with same pid
1870     printdebug "waiting for build host child $pid...\n";
1871     my $got = waitpid $pid, 0;
1872     die $! unless $got == $pid;
1873     die "build host child failed $?" if $?;
1874
1875     i_cleanup();
1876     printdebug "all done\n";
1877     exit 0;
1878 }
1879
1880 sub i_resp_file ($) {
1881     my ($keyword) = @_;
1882     my $localname = i_method "i_localname", $keyword;
1883     my $localpath = "$i_tmp/$localname";
1884     stat_exists $localpath and
1885         badproto \*RO, "file $keyword ($localpath) twice";
1886     protocol_receive_file \*RO, $localpath;
1887     i_method "i_file", $keyword;
1888 }
1889
1890 our %i_param;
1891
1892 sub i_resp_param ($) {
1893     $_[0] =~ m/^(\S+) (.*)$/ or badproto \*RO, "bad param spec";
1894     $i_param{$1} = $2;
1895 }
1896
1897 our %i_wanted;
1898
1899 sub i_resp_want ($) {
1900     my ($keyword) = @_;
1901     die "$keyword ?" if $i_wanted{$keyword}++;
1902     my @localpaths = i_method "i_want", $keyword;
1903     printdebug "[[  $keyword @localpaths\n";
1904     foreach my $localpath (@localpaths) {
1905         protocol_send_file \*RI, $localpath;
1906     }
1907     print RI "files-end\n" or die $!;
1908 }
1909
1910 our ($i_clogp, $i_version, $i_tag, $i_dscfn, $i_changesfn);
1911
1912 sub i_localname_parsed_changelog {
1913     return "remote-changelog.822";
1914 }
1915 sub i_file_parsed_changelog {
1916     ($i_clogp, $i_version, $i_tag, $i_dscfn) =
1917         push_parse_changelog "$i_tmp/remote-changelog.822";
1918     die if $i_dscfn =~ m#/|^\W#;
1919 }
1920
1921 sub i_localname_dsc {
1922     defined $i_dscfn or badproto \*RO, "dsc (before parsed-changelog)";
1923     return $i_dscfn;
1924 }
1925 sub i_file_dsc { }
1926
1927 sub i_localname_changes {
1928     defined $i_dscfn or badproto \*RO, "dsc (before parsed-changelog)";
1929     $i_changesfn = $i_dscfn;
1930     $i_changesfn =~ s/\.dsc$/_dgit.changes/ or die;
1931     return $i_changesfn;
1932 }
1933 sub i_file_changes { }
1934
1935 sub i_want_signed_tag {
1936     printdebug Dumper(\%i_param, $i_dscfn);
1937     defined $i_param{'head'} && defined $i_dscfn && defined $i_clogp
1938         && defined $i_param{'csuite'}
1939         or badproto \*RO, "premature desire for signed-tag";
1940     my $head = $i_param{'head'};
1941     die if $head =~ m/[^0-9a-f]/ || $head !~ m/^../;
1942
1943     die unless $i_param{'csuite'} =~ m/^$suite_re$/;
1944     $csuite = $&;
1945     push_parse_dsc $i_dscfn, 'remote dsc', $i_version;
1946
1947     my $tagobjfn =
1948         push_mktag $head, $i_clogp, $i_tag,
1949             $i_dscfn,
1950             $i_changesfn, 'remote changes',
1951             sub { "tag$_[0]"; };
1952
1953     return $tagobjfn;
1954 }
1955
1956 sub i_want_signed_dsc_changes {
1957     rename "$i_dscfn.tmp","$i_dscfn" or die "$i_dscfn $!";
1958     sign_changes $i_changesfn;
1959     return ($i_dscfn, $i_changesfn);
1960 }
1961
1962 #---------- building etc. ----------
1963
1964 our $version;
1965 our $sourcechanges;
1966 our $dscfn;
1967
1968 our $fakeeditorenv = 'DGIT_FAKE_EDITOR_QUILT';
1969
1970 sub build_maybe_quilt_fixup () {
1971     my $format=get_source_format;
1972     return unless madformat $format;
1973     # sigh
1974
1975     # Our objective is:
1976     #  - honour any existing .pc in case it has any strangeness
1977     #  - determine the git commit corresponding to the tip of
1978     #    the patch stack (if there is one)
1979     #  - if there is such a git commit, convert each subsequent
1980     #    git commit into a quilt patch with dpkg-source --commit
1981     #  - otherwise convert all the differences in the tree into
1982     #    a single git commit
1983     #
1984     # To do this we:
1985
1986     # Our git tree doesn't necessarily contain .pc.  (Some versions of
1987     # dgit would include the .pc in the git tree.)  If there isn't
1988     # one, we need to generate one by unpacking the patches that we
1989     # have.
1990     #
1991     # We first look for a .pc in the git tree.  If there is one, we
1992     # will use it.  (This is not the normal case.)
1993     #
1994     # Otherwise need to regenerate .pc so that dpkg-source --commit
1995     # can work.  We do this as follows:
1996     #     1. Collect all relevant .orig from parent directory
1997     #     2. Generate a debian.tar.gz out of
1998     #         debian/{patches,rules,source/format}
1999     #     3. Generate a fake .dsc containing just these fields:
2000     #          Format Source Version Files
2001     #     4. Extract the fake .dsc
2002     #        Now the fake .dsc has a .pc directory.
2003     # (In fact we do this in every case, because in future we will
2004     # want to search for a good base commit for generating patches.)
2005     #
2006     # Then we can actually do the dpkg-source --commit
2007     #     1. Make a new working tree with the same object
2008     #        store as our main tree and check out the main
2009     #        tree's HEAD.
2010     #     2. Copy .pc from the fake's extraction, if necessary
2011     #     3. Run dpkg-source --commit
2012     #     4. If the result has changes to debian/, then
2013     #          - git-add them them
2014     #          - git-add .pc if we had a .pc in-tree
2015     #          - git-commit
2016     #     5. If we had a .pc in-tree, delete it, and git-commit
2017     #     6. Back in the main tree, fast forward to the new HEAD
2018
2019     my $clogp = parsechangelog();
2020     my $headref = rev_parse('HEAD');
2021
2022     prep_ud();
2023     changedir $ud;
2024
2025     my $upstreamversion=$version;
2026     $upstreamversion =~ s/-[^-]*$//;
2027
2028     my $fakeversion="$upstreamversion-~~DGITFAKE";
2029
2030     my $fakedsc=new IO::File 'fake.dsc', '>' or die $!;
2031     print $fakedsc <<END or die $!;
2032 Format: 3.0 (quilt)
2033 Source: $package
2034 Version: $fakeversion
2035 Files:
2036 END
2037
2038     my $dscaddfile=sub {
2039         my ($b) = @_;
2040
2041         my $md = new Digest::MD5;
2042
2043         my $fh = new IO::File $b, '<' or die "$b $!";
2044         stat $fh or die $!;
2045         my $size = -s _;
2046
2047         $md->addfile($fh);
2048         print $fakedsc " ".$md->hexdigest." $size $b\n" or die $!;
2049     };
2050
2051     foreach my $f (<../../../../*>) { #/){
2052         my $b=$f; $b =~ s{.*/}{};
2053         next unless is_orig_file $b, srcfn $upstreamversion,'';
2054         link $f, $b or die "$b $!";
2055         $dscaddfile->($b);
2056     }
2057
2058     my @files=qw(debian/source/format debian/rules);
2059     if (stat_exists '../../../debian/patches') {
2060         push @files, 'debian/patches';
2061     }
2062
2063     my $debtar= srcfn $fakeversion,'.debian.tar.gz';
2064     runcmd qw(env GZIP=-1 tar -zcf), "./$debtar", qw(-C ../../..), @files;
2065
2066     $dscaddfile->($debtar);
2067     close $fakedsc or die $!;
2068
2069     runcmd qw(sh -ec), 'exec dpkg-source --no-check -x fake.dsc >/dev/null';
2070
2071     my $fakexdir= $package.'-'.(stripepoch $upstreamversion);
2072     rename $fakexdir, "fake" or die "$fakexdir $!";
2073
2074     mkdir "work" or die $!;
2075     changedir "work";
2076     mktree_in_ud_here();
2077     runcmd @git, qw(reset --hard), $headref;
2078
2079     my $mustdeletepc=0;
2080     if (stat_exists ".pc") {
2081         -d _ or die;
2082         progress "Tree already contains .pc - will use it then delete it.";
2083         $mustdeletepc=1;
2084     } else {
2085         rename '../fake/.pc','.pc' or die $!;
2086     }
2087
2088     my $author = getfield $clogp, 'Maintainer';
2089     my $time = time;
2090     my $ncommits = 3;
2091     my $patchname = "auto-$version-$headref-$time";
2092     my $msg = cmdoutput @git, qw(log), "-n$ncommits";
2093     mkpath '.git/dgit';
2094     my $descfn = ".git/dgit/quilt-description.tmp";
2095     open O, '>', $descfn or die "$descfn: $!";
2096     $msg =~ s/\n/\n /g;
2097     $msg =~ s/^\s+$/ ./mg;
2098     print O <<END or die $!;
2099 Description: Automatically generated patch ($clogp->{Version})
2100  Last (up to) $ncommits git changes, FYI:
2101  .
2102  $msg
2103 Author: $author
2104
2105 ---
2106
2107 END
2108     close O or die $!;
2109     {
2110         local $ENV{'EDITOR'} = cmdoutput qw(realpath --), $0;
2111         local $ENV{'VISUAL'} = $ENV{'EDITOR'};
2112         local $ENV{$fakeeditorenv} = cmdoutput qw(realpath --), $descfn;
2113         runcmd_ordryrun_local @dpkgsource, qw(--commit .), $patchname;
2114     }
2115
2116     if (!open P, '>>', ".pc/applied-patches") {
2117         $!==&ENOENT or die $!;
2118     } else {
2119         close P;
2120     }
2121
2122     commit_quilty_patch();
2123
2124     if ($mustdeletepc) {
2125         runcmd @git, qw(rm -rq .pc);
2126         commit_admin "Commit removal of .pc (quilt series tracking data)";
2127     }
2128
2129     changedir '../../../..';
2130     runcmd @git, qw(pull --ff-only -q .git/dgit/unpack/work master);
2131 }
2132
2133 sub quilt_fixup_editor () {
2134     my $descfn = $ENV{$fakeeditorenv};
2135     my $editing = $ARGV[$#ARGV];
2136     open I1, '<', $descfn or die "$descfn: $!";
2137     open I2, '<', $editing or die "$editing: $!";
2138     unlink $editing or die "$editing: $!";
2139     open O, '>', $editing or die "$editing: $!";
2140     while (<I1>) { print O or die $!; } I1->error and die $!;
2141     my $copying = 0;
2142     while (<I2>) {
2143         $copying ||= m/^\-\-\- /;
2144         next unless $copying;
2145         print O or die $!;
2146     }
2147     I2->error and die $!;
2148     close O or die $1;
2149     exit 0;
2150 }
2151
2152 sub clean_tree () {
2153     if ($cleanmode eq 'dpkg-source') {
2154         runcmd_ordryrun_local @dpkgbuildpackage, qw(-T clean);
2155     } elsif ($cleanmode eq 'git') {
2156         runcmd_ordryrun_local @git, qw(clean -xdf);
2157     } elsif ($cleanmode eq 'none') {
2158     } else {
2159         die "$cleanmode ?";
2160     }
2161 }
2162
2163 sub cmd_clean () {
2164     badusage "clean takes no additional arguments" if @ARGV;
2165     clean_tree();
2166 }
2167
2168 sub build_prep () {
2169     badusage "-p is not allowed when building" if defined $package;
2170     check_not_dirty();
2171     clean_tree();
2172     my $clogp = parsechangelog();
2173     $isuite = getfield $clogp, 'Distribution';
2174     $package = getfield $clogp, 'Source';
2175     $version = getfield $clogp, 'Version';
2176     build_maybe_quilt_fixup();
2177 }
2178
2179 sub changesopts () {
2180     my @opts =@changesopts[1..$#changesopts];
2181     if (!defined $changes_since_version) {
2182         my @vsns = archive_query('archive_query');
2183         my @quirk = access_quirk();
2184         if ($quirk[0] eq 'backports') {
2185             local $isuite = $quirk[2];
2186             local $csuite;
2187             canonicalise_suite();
2188             push @vsns, archive_query('archive_query');
2189         }
2190         if (@vsns) {
2191             @vsns = map { $_->[0] } @vsns;
2192             @vsns = sort { -version_compare($a, $b) } @vsns;
2193             $changes_since_version = $vsns[0];
2194             progress "changelog will contain changes since $vsns[0]";
2195         } else {
2196             $changes_since_version = '_';
2197             progress "package seems new, not specifying -v<version>";
2198         }
2199     }
2200     if ($changes_since_version ne '_') {
2201         unshift @opts, "-v$changes_since_version";
2202     }
2203     return @opts;
2204 }
2205
2206 sub cmd_build {
2207     build_prep();
2208     runcmd_ordryrun_local @dpkgbuildpackage, qw(-us -uc), changesopts(), @ARGV;
2209     printdone "build successful\n";
2210 }
2211
2212 sub cmd_git_build {
2213     build_prep();
2214     my @cmd =
2215         (qw(git-buildpackage -us -uc --git-no-sign-tags),
2216          "--git-builder=@dpkgbuildpackage");
2217     unless (grep { m/^--git-debian-branch|^--git-ignore-branch/ } @ARGV) {
2218         canonicalise_suite();
2219         push @cmd, "--git-debian-branch=".lbranch();
2220     }
2221     push @cmd, changesopts();
2222     runcmd_ordryrun_local @cmd, @ARGV;
2223     printdone "build successful\n";
2224 }
2225
2226 sub build_source {
2227     build_prep();
2228     $sourcechanges = "${package}_".(stripepoch $version)."_source.changes";
2229     $dscfn = dscfn($version);
2230     if ($cleanmode eq 'dpkg-source') {
2231         runcmd_ordryrun_local (@dpkgbuildpackage, qw(-us -uc -S)),
2232             changesopts();
2233     } else {
2234         my $pwd = must_getcwd();
2235         my $leafdir = basename $pwd;
2236         changedir "..";
2237         runcmd_ordryrun_local @dpkgsource, qw(-b --), $leafdir;
2238         changedir $pwd;
2239         runcmd_ordryrun_local qw(sh -ec),
2240             'exec >$1; shift; exec "$@"','x',
2241             "../$sourcechanges",
2242             @dpkggenchanges, qw(-S), changesopts();
2243     }
2244 }
2245
2246 sub cmd_build_source {
2247     badusage "build-source takes no additional arguments" if @ARGV;
2248     build_source();
2249     printdone "source built, results in $dscfn and $sourcechanges";
2250 }
2251
2252 sub cmd_sbuild {
2253     build_source();
2254     changedir "..";
2255     my $pat = "${package}_".(stripepoch $version)."_*.changes";
2256     if (act_local()) {
2257         stat_exist $dscfn or fail "$dscfn (in parent directory): $!";
2258         stat_exists $sourcechanges
2259             or fail "$sourcechanges (in parent directory): $!";
2260         foreach my $cf (glob $pat) {
2261             next if $cf eq $sourcechanges;
2262             unlink $cf or fail "remove $cf: $!";
2263         }
2264     }
2265     runcmd_ordryrun_local @sbuild, @ARGV, qw(-d), $isuite, $dscfn;
2266     my @changesfiles = glob $pat;
2267     @changesfiles = sort {
2268         ($b =~ m/_source\.changes$/ <=> $a =~ m/_source\.changes$/)
2269             or $a cmp $b
2270     } @changesfiles;
2271     fail "wrong number of different changes files (@changesfiles)"
2272         unless @changesfiles;
2273     runcmd_ordryrun_local @mergechanges, @changesfiles;
2274     my $multichanges = "${package}_".(stripepoch $version)."_multi.changes";
2275     if (act_local()) {
2276         stat_exists $multichanges or fail "$multichanges: $!";
2277     }
2278     printdone "build successful, results in $multichanges\n" or die $!;
2279 }
2280
2281 sub cmd_quilt_fixup {
2282     badusage "incorrect arguments to dgit quilt-fixup" if @ARGV;
2283     my $clogp = parsechangelog();
2284     $version = getfield $clogp, 'Version';
2285     $package = getfield $clogp, 'Source';
2286     build_maybe_quilt_fixup();
2287 }
2288
2289 #---------- argument parsing and main program ----------
2290
2291 sub cmd_version {
2292     print "dgit version $our_version\n" or die $!;
2293     exit 0;
2294 }
2295
2296 sub parseopts () {
2297     my $om;
2298
2299     if (defined $ENV{'DGIT_SSH'}) {
2300         @ssh = string_to_ssh $ENV{'DGIT_SSH'};
2301     } elsif (defined $ENV{'GIT_SSH'}) {
2302         @ssh = ($ENV{'GIT_SSH'});
2303     }
2304
2305     while (@ARGV) {
2306         last unless $ARGV[0] =~ m/^-/;
2307         $_ = shift @ARGV;
2308         last if m/^--?$/;
2309         if (m/^--/) {
2310             if (m/^--dry-run$/) {
2311                 push @ropts, $_;
2312                 $dryrun_level=2;
2313             } elsif (m/^--damp-run$/) {
2314                 push @ropts, $_;
2315                 $dryrun_level=1;
2316             } elsif (m/^--no-sign$/) {
2317                 push @ropts, $_;
2318                 $sign=0;
2319             } elsif (m/^--help$/) {
2320                 cmd_help();
2321             } elsif (m/^--version$/) {
2322                 cmd_version();
2323             } elsif (m/^--new$/) {
2324                 push @ropts, $_;
2325                 $new_package=1;
2326             } elsif (m/^--since-version=([^_]+|_)$/) {
2327                 push @ropts, $_;
2328                 $changes_since_version = $1;
2329             } elsif (m/^--([-0-9a-z]+)=(.*)/s &&
2330                      ($om = $opts_opt_map{$1}) &&
2331                      length $om->[0]) {
2332                 push @ropts, $_;
2333                 $om->[0] = $2;
2334             } elsif (m/^--([-0-9a-z]+):(.*)/s &&
2335                      !$opts_opt_cmdonly{$1} &&
2336                      ($om = $opts_opt_map{$1})) {
2337                 push @ropts, $_;
2338                 push @$om, $2;
2339             } elsif (m/^--existing-package=(.*)/s) {
2340                 push @ropts, $_;
2341                 $existing_package = $1;
2342             } elsif (m/^--initiator-tempdir=(.*)/s) {
2343                 $initiator_tempdir = $1;
2344                 $initiator_tempdir =~ m#^/# or
2345                     badusage "--initiator-tempdir must be used specify an".
2346                         " absolute, not relative, directory."
2347             } elsif (m/^--distro=(.*)/s) {
2348                 push @ropts, $_;
2349                 $idistro = $1;
2350             } elsif (m/^--build-products-dir=(.*)/s) {
2351                 push @ropts, $_;
2352                 $buildproductsdir = $1;
2353             } elsif (m/^--clean=(dpkg-source|git|none)$/s) {
2354                 push @ropts, $_;
2355                 $cleanmode = $1;
2356             } elsif (m/^--clean=(.*)$/s) {
2357                 badusage "unknown cleaning mode \`$1'";
2358             } elsif (m/^--ignore-dirty$/s) {
2359                 push @ropts, $_;
2360                 $ignoredirty = 1;
2361             } elsif (m/^--no-quilt-fixup$/s) {
2362                 push @ropts, $_;
2363                 $noquilt = 1;
2364             } elsif (m/^--no-rm-on-error$/s) {
2365                 push @ropts, $_;
2366                 $rmonerror = 0;
2367             } else {
2368                 badusage "unknown long option \`$_'";
2369             }
2370         } else {
2371             while (m/^-./s) {
2372                 if (s/^-n/-/) {
2373                     push @ropts, $&;
2374                     $dryrun_level=2;
2375                 } elsif (s/^-L/-/) {
2376                     push @ropts, $&;
2377                     $dryrun_level=1;
2378                 } elsif (s/^-h/-/) {
2379                     cmd_help();
2380                 } elsif (s/^-D/-/) {
2381                     push @ropts, $&;
2382                     open DEBUG, ">&STDERR" or die $!;
2383                     autoflush DEBUG 1;
2384                     $debug++;
2385                 } elsif (s/^-N/-/) {
2386                     push @ropts, $&;
2387                     $new_package=1;
2388                 } elsif (s/^-v([^_]+|_)$//s) {
2389                     push @ropts, $&;
2390                     $changes_since_version = $1;
2391                 } elsif (m/^-m/) {
2392                     push @ropts, $&;
2393                     push @changesopts, $_;
2394                     $_ = '';
2395                 } elsif (s/^-c(.*=.*)//s) {
2396                     push @ropts, $&;
2397                     push @git, '-c', $1;
2398                 } elsif (s/^-d(.*)//s) {
2399                     push @ropts, $&;
2400                     $idistro = $1;
2401                 } elsif (s/^-C(.*)//s) {
2402                     push @ropts, $&;
2403                     $changesfile = $1;
2404                     if ($changesfile =~ s#^(.*)/##) {
2405                         $buildproductsdir = $1;
2406                     }
2407                 } elsif (s/^-k(.*)//s) {
2408                     $keyid=$1;
2409                 } elsif (s/^-wn//s) {
2410                     push @ropts, $&;
2411                     $cleanmode = 'none';
2412                 } elsif (s/^-wg//s) {
2413                     push @ropts, $&;
2414                     $cleanmode = 'git';
2415                 } elsif (s/^-wd//s) {
2416                     push @ropts, $&;
2417                     $cleanmode = 'dpkg-source';
2418                 } else {
2419                     badusage "unknown short option \`$_'";
2420                 }
2421             }
2422         }
2423     }
2424 }
2425
2426 if ($ENV{$fakeeditorenv}) {
2427     quilt_fixup_editor();
2428 }
2429
2430 parseopts();
2431 print STDERR "DRY RUN ONLY\n" if $dryrun_level > 1;
2432 print STDERR "DAMP RUN - WILL MAKE LOCAL (UNSIGNED) CHANGES\n"
2433     if $dryrun_level == 1;
2434 if (!@ARGV) {
2435     print STDERR $helpmsg or die $!;
2436     exit 8;
2437 }
2438 my $cmd = shift @ARGV;
2439 $cmd =~ y/-/_/;
2440
2441 my $fn = ${*::}{"cmd_$cmd"};
2442 $fn or badusage "unknown operation $cmd";
2443 $fn->();