dgit

   1 #!/usr/bin/perl -w
   2 # dgit
   3 # Integration between git and Debian-style archives
   4 #
   5 # Copyright (C)2013-2016 Ian Jackson
   6 #
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 use strict;
  21
  22 use Debian::Dgit;
  23 setup_sigwarn();
  24
  25 use IO::Handle;
  26 use Data::Dumper;
  27 use LWP::UserAgent;
  28 use Dpkg::Control::Hash;
  29 use File::Path;
  30 use File::Temp qw(tempdir);
  31 use File::Basename;
  32 use Dpkg::Version;
  33 use POSIX;
  34 use IPC::Open2;
  35 use Digest::SHA;
  36 use Digest::MD5;
  37 use List::Util qw(any);
  38 use List::MoreUtils qw(pairwise);
  39 use Text::Glob qw(match_glob);
  40 use Fcntl qw(:DEFAULT :flock);
  41 use Carp;
  42
  43 use Debian::Dgit;
  44
  45 our $our_version = 'UNRELEASED'; ###substituted###
  46 our $absurdity = undef; ###substituted###
  47
  48 our @rpushprotovsn_support = qw(4 3 2); # 4 is new tag format
  49 our $protovsn;
  50
  51 our $isuite;
  52 our $idistro;
  53 our $package;
  54 our @ropts;
  55
  56 our $sign = 1;
  57 our $dryrun_level = 0;
  58 our $changesfile;
  59 our $buildproductsdir = '..';
  60 our $new_package = 0;
  61 our $ignoredirty = 0;
  62 our $rmonerror = 1;
  63 our @deliberatelies;
  64 our %previously;
  65 our $existing_package = 'dpkg';
  66 our $cleanmode;
  67 our $changes_since_version;
  68 our $rmchanges;
  69 our $overwrite_version; # undef: not specified; '': check changelog
  70 our $quilt_mode;
  71 our $quilt_modes_re = 'linear|smash|auto|nofix|nocheck|gbp|dpm|unapplied';
  72 our $dodep14tag;
  73 our $dodep14tag_re = 'want|no|always';
  74 our $split_brain_save;
  75 our $we_are_responder;
  76 our $we_are_initiator;
  77 our $initiator_tempdir;
  78 our $patches_applied_dirtily = 00;
  79 our $tagformat_want;
  80 our $tagformat;
  81 our $tagformatfn;
  82 our $chase_dsc_distro=1;
  83
  84 our %forceopts = map { $_=>0 }
  85     qw(unrepresentable unsupported-source-format
  86        dsc-changes-mismatch changes-origs-exactly
  87        import-gitapply-absurd
  88        import-gitapply-no-absurd
  89        import-dsc-with-dgit-field);
  90
  91 our %format_ok = map { $_=>1 } ("1.0","3.0 (native)","3.0 (quilt)");
  92
  93 our $suite_re = '[-+.0-9a-z]+';
  94 our $cleanmode_re = 'dpkg-source(?:-d)?|git|git-ff|check|none';
  95 our $orig_f_comp_re = 'orig(?:-[-0-9a-z]+)?';
  96 our $orig_f_sig_re = '\\.(?:asc|gpg|pgp)';
  97 our $orig_f_tail_re = "$orig_f_comp_re\\.tar(?:\\.\\w+)?(?:$orig_f_sig_re)?";
  98
  99 our $git_authline_re = '^([^<>]+) \<(\S+)\> (\d+ [-+]\d+)$';
 100 our $splitbraincache = 'dgit-intern/quilt-cache';
 101 our $rewritemap = 'dgit-rewrite/map';
 102
 103 our (@git) = qw(git);
 104 our (@dget) = qw(dget);
 105 our (@curl) = qw(curl);
 106 our (@dput) = qw(dput);
 107 our (@debsign) = qw(debsign);
 108 our (@gpg) = qw(gpg);
 109 our (@sbuild) = qw(sbuild);
 110 our (@ssh) = 'ssh';
 111 our (@dgit) = qw(dgit);
 112 our (@aptget) = qw(apt-get);
 113 our (@aptcache) = qw(apt-cache);
 114 our (@dpkgbuildpackage) = qw(dpkg-buildpackage -i\.git/ -I.git);
 115 our (@dpkgsource) = qw(dpkg-source -i\.git/ -I.git);
 116 our (@dpkggenchanges) = qw(dpkg-genchanges);
 117 our (@mergechanges) = qw(mergechanges -f);
 118 our (@gbp_build) = ('');
 119 our (@gbp_pq) = ('gbp pq');
 120 our (@changesopts) = ('');
 121
 122 our %opts_opt_map = ('dget' => \@dget, # accept for compatibility
 123                      'curl' => \@curl,
 124                      'dput' => \@dput,
 125                      'debsign' => \@debsign,
 126                      'gpg' => \@gpg,
 127                      'sbuild' => \@sbuild,
 128                      'ssh' => \@ssh,
 129                      'dgit' => \@dgit,
 130                      'git' => \@git,
 131                      'apt-get' => \@aptget,
 132                      'apt-cache' => \@aptcache,
 133                      'dpkg-source' => \@dpkgsource,
 134                      'dpkg-buildpackage' => \@dpkgbuildpackage,
 135                      'dpkg-genchanges' => \@dpkggenchanges,
 136                      'gbp-build' => \@gbp_build,
 137                      'gbp-pq' => \@gbp_pq,
 138                      'ch' => \@changesopts,
 139                      'mergechanges' => \@mergechanges);
 140
 141 our %opts_opt_cmdonly = ('gpg' => 1, 'git' => 1);
 142 our %opts_cfg_insertpos = map {
 143     $_,
 144     scalar @{ $opts_opt_map{$_} }
 145 } keys %opts_opt_map;
 146
 147 sub parseopts_late_defaults();
 148
 149 our $keyid;
 150
 151 autoflush STDOUT 1;
 152
 153 our $supplementary_message = '';
 154 our $need_split_build_invocation = 0;
 155 our $split_brain = 0;
 156
 157 END {
 158     local ($@, $?);
 159     print STDERR "! $_\n" foreach $supplementary_message =~ m/^.+$/mg;
 160 }
 161
 162 our $remotename = 'dgit';
 163 our @ourdscfield = qw(Dgit Vcs-Dgit-Master);
 164 our $csuite;
 165 our $instead_distro;
 166
 167 if (!defined $absurdity) {
 168     $absurdity = $0;
 169     $absurdity =~ s{/[^/]+$}{/absurd} or die;
 170 }
 171
 172 sub debiantag ($$) {
 173     my ($v,$distro) = @_;
 174     return $tagformatfn->($v, $distro);
 175 }
 176
 177 sub debiantag_maintview ($$) {
 178     my ($v,$distro) = @_;
 179     return "$distro/".dep14_version_mangle $v;
 180 }
 181
 182 sub madformat ($) { $_[0] eq '3.0 (quilt)' }
 183
 184 sub lbranch () { return "$branchprefix/$csuite"; }
 185 my $lbranch_re = '^refs/heads/'.$branchprefix.'/([^/.]+)$';
 186 sub lref () { return "refs/heads/".lbranch(); }
 187 sub lrref () { return "refs/remotes/$remotename/".server_branch($csuite); }
 188 sub rrref () { return server_ref($csuite); }
 189
 190 sub stripepoch ($) {
 191     my ($vsn) = @_;
 192     $vsn =~ s/^\d+\://;
 193     return $vsn;
 194 }
 195
 196 sub srcfn ($$) {
 197     my ($vsn,$sfx) = @_;
 198     return "${package}_".(stripepoch $vsn).$sfx
 199 }
 200
 201 sub dscfn ($) {
 202     my ($vsn) = @_;
 203     return srcfn($vsn,".dsc");
 204 }
 205
 206 sub changespat ($;$) {
 207     my ($vsn, $arch) = @_;
 208     return "${package}_".(stripepoch $vsn)."_".($arch//'*').".changes";
 209 }
 210
 211 sub upstreamversion ($) {
 212     my ($vsn) = @_;
 213     $vsn =~ s/-[^-]+$//;
 214     return $vsn;
 215 }
 216
 217 our $us = 'dgit';
 218 initdebug('');
 219
 220 our @end;
 221 END {
 222     local ($?);
 223     foreach my $f (@end) {
 224         eval { $f->(); };
 225         print STDERR "$us: cleanup: $@" if length $@;
 226     }
 227 };
 228
 229 sub badcfg { print STDERR "$us: invalid configuration: @_\n"; exit 12; }
 230
 231 sub forceable_fail ($$) {
 232     my ($forceoptsl, $msg) = @_;
 233     fail $msg unless grep { $forceopts{$_} } @$forceoptsl;
 234     print STDERR "warning: overriding problem due to --force:\n". $msg;
 235 }
 236
 237 sub forceing ($) {
 238     my ($forceoptsl) = @_;
 239     my @got = grep { $forceopts{$_} } @$forceoptsl;
 240     return 0 unless @got;
 241     print STDERR
 242  "warning: skipping checks or functionality due to --force-$got[0]\n";
 243 }
 244
 245 sub no_such_package () {
 246     print STDERR "$us: package $package does not exist in suite $isuite\n";
 247     exit 4;
 248 }
 249
 250 sub changedir ($) {
 251     my ($newdir) = @_;
 252     printdebug "CD $newdir\n";
 253     chdir $newdir or confess "chdir: $newdir: $!";
 254 }
 255
 256 sub deliberately ($) {
 257     my ($enquiry) = @_;
 258     return !!grep { $_ eq "--deliberately-$enquiry" } @deliberatelies;
 259 }
 260
 261 sub deliberately_not_fast_forward () {
 262     foreach (qw(not-fast-forward fresh-repo)) {
 263         return 1 if deliberately($_) || deliberately("TEST-dgit-only-$_");
 264     }
 265 }
 266
 267 sub quiltmode_splitbrain () {
 268     $quilt_mode =~ m/gbp|dpm|unapplied/;
 269 }
 270
 271 sub opts_opt_multi_cmd {
 272     my @cmd;
 273     push @cmd, split /\s+/, shift @_;
 274     push @cmd, @_;
 275     @cmd;
 276 }
 277
 278 sub gbp_pq {
 279     return opts_opt_multi_cmd @gbp_pq;
 280 }
 281
 282 #---------- remote protocol support, common ----------
 283
 284 # remote push initiator/responder protocol:
 285 #  $ dgit remote-push-build-host <n-rargs> <rargs>... <push-args>...
 286 #  where <rargs> is <push-host-dir> <supported-proto-vsn>,... ...
 287 #  < dgit-remote-push-ready <actual-proto-vsn>
 288 #
 289 # occasionally:
 290 #
 291 #  > progress NBYTES
 292 #  [NBYTES message]
 293 #
 294 #  > supplementary-message NBYTES          # $protovsn >= 3
 295 #  [NBYTES message]
 296 #
 297 # main sequence:
 298 #
 299 #  > file parsed-changelog
 300 #  [indicates that output of dpkg-parsechangelog follows]
 301 #  > data-block NBYTES
 302 #  > [NBYTES bytes of data (no newline)]
 303 #  [maybe some more blocks]
 304 #  > data-end
 305 #
 306 #  > file dsc
 307 #  [etc]
 308 #
 309 #  > file changes
 310 #  [etc]
 311 #
 312 #  > param head DGIT-VIEW-HEAD
 313 #  > param csuite SUITE
 314 #  > param tagformat old|new
 315 #  > param maint-view MAINT-VIEW-HEAD
 316 #
 317 #  > previously REFNAME=OBJNAME       # if --deliberately-not-fast-forward
 318 #                                     # goes into tag, for replay prevention
 319 #
 320 #  > want signed-tag
 321 #  [indicates that signed tag is wanted]
 322 #  < data-block NBYTES
 323 #  < [NBYTES bytes of data (no newline)]
 324 #  [maybe some more blocks]
 325 #  < data-end
 326 #  < files-end
 327 #
 328 #  > want signed-dsc-changes
 329 #  < data-block NBYTES    [transfer of signed dsc]
 330 #  [etc]
 331 #  < data-block NBYTES    [transfer of signed changes]
 332 #  [etc]
 333 #  < files-end
 334 #
 335 #  > complete
 336
 337 our $i_child_pid;
 338
 339 sub i_child_report () {
 340     # Sees if our child has died, and reap it if so.  Returns a string
 341     # describing how it died if it failed, or undef otherwise.
 342     return undef unless $i_child_pid;
 343     my $got = waitpid $i_child_pid, WNOHANG;
 344     return undef if $got <= 0;
 345     die unless $got == $i_child_pid;
 346     $i_child_pid = undef;
 347     return undef unless $?;
 348     return "build host child ".waitstatusmsg();
 349 }
 350
 351 sub badproto ($$) {
 352     my ($fh, $m) = @_;
 353     fail "connection lost: $!" if $fh->error;
 354     fail "protocol violation; $m not expected";
 355 }
 356
 357 sub badproto_badread ($$) {
 358     my ($fh, $wh) = @_;
 359     fail "connection lost: $!" if $!;
 360     my $report = i_child_report();
 361     fail $report if defined $report;
 362     badproto $fh, "eof (reading $wh)";
 363 }
 364
 365 sub protocol_expect (&$) {
 366     my ($match, $fh) = @_;
 367     local $_;
 368     $_ = <$fh>;
 369     defined && chomp or badproto_badread $fh, "protocol message";
 370     if (wantarray) {
 371         my @r = &$match;
 372         return @r if @r;
 373     } else {
 374         my $r = &$match;
 375         return $r if $r;
 376     }
 377     badproto $fh, "\`$_'";
 378 }
 379
 380 sub protocol_send_file ($$) {
 381     my ($fh, $ourfn) = @_;
 382     open PF, "<", $ourfn or die "$ourfn: $!";
 383     for (;;) {
 384         my $d;
 385         my $got = read PF, $d, 65536;
 386         die "$ourfn: $!" unless defined $got;
 387         last if !$got;
 388         print $fh "data-block ".length($d)."\n" or die $!;
 389         print $fh $d or die $!;
 390     }
 391     PF->error and die "$ourfn $!";
 392     print $fh "data-end\n" or die $!;
 393     close PF;
 394 }
 395
 396 sub protocol_read_bytes ($$) {
 397     my ($fh, $nbytes) = @_;
 398     $nbytes =~ m/^[1-9]\d{0,5}$|^0$/ or badproto \*RO, "bad byte count";
 399     my $d;
 400     my $got = read $fh, $d, $nbytes;
 401     $got==$nbytes or badproto_badread $fh, "data block";
 402     return $d;
 403 }
 404
 405 sub protocol_receive_file ($$) {
 406     my ($fh, $ourfn) = @_;
 407     printdebug "() $ourfn\n";
 408     open PF, ">", $ourfn or die "$ourfn: $!";
 409     for (;;) {
 410         my ($y,$l) = protocol_expect {
 411             m/^data-block (.*)$/ ? (1,$1) :
 412             m/^data-end$/ ? (0,) :
 413             ();
 414         } $fh;
 415         last unless $y;
 416         my $d = protocol_read_bytes $fh, $l;
 417         print PF $d or die $!;
 418     }
 419     close PF or die $!;
 420 }
 421
 422 #---------- remote protocol support, responder ----------
 423
 424 sub responder_send_command ($) {
 425     my ($command) = @_;
 426     return unless $we_are_responder;
 427     # called even without $we_are_responder
 428     printdebug ">> $command\n";
 429     print PO $command, "\n" or die $!;
 430 }
 431
 432 sub responder_send_file ($$) {
 433     my ($keyword, $ourfn) = @_;
 434     return unless $we_are_responder;
 435     printdebug "]] $keyword $ourfn\n";
 436     responder_send_command "file $keyword";
 437     protocol_send_file \*PO, $ourfn;
 438 }
 439
 440 sub responder_receive_files ($@) {
 441     my ($keyword, @ourfns) = @_;
 442     die unless $we_are_responder;
 443     printdebug "[[ $keyword @ourfns\n";
 444     responder_send_command "want $keyword";
 445     foreach my $fn (@ourfns) {
 446         protocol_receive_file \*PI, $fn;
 447     }
 448     printdebug "[[\$\n";
 449     protocol_expect { m/^files-end$/ } \*PI;
 450 }
 451
 452 #---------- remote protocol support, initiator ----------
 453
 454 sub initiator_expect (&) {
 455     my ($match) = @_;
 456     protocol_expect { &$match } \*RO;
 457 }
 458
 459 #---------- end remote code ----------
 460
 461 sub progress {
 462     if ($we_are_responder) {
 463         my $m = join '', @_;
 464         responder_send_command "progress ".length($m) or die $!;
 465         print PO $m or die $!;
 466     } else {
 467         print @_, "\n";
 468     }
 469 }
 470
 471 our $ua;
 472
 473 sub url_get {
 474     if (!$ua) {
 475         $ua = LWP::UserAgent->new();
 476         $ua->env_proxy;
 477     }
 478     my $what = $_[$#_];
 479     progress "downloading $what...";
 480     my $r = $ua->get(@_) or die $!;
 481     return undef if $r->code == 404;
 482     $r->is_success or fail "failed to fetch $what: ".$r->status_line;
 483     return $r->decoded_content(charset => 'none');
 484 }
 485
 486 our ($dscdata,$dscurl,$dsc,$dsc_checked,$skew_warning_vsn);
 487
 488 sub runcmd {
 489     debugcmd "+",@_;
 490     $!=0; $?=-1;
 491     failedcmd @_ if system @_;
 492 }
 493
 494 sub act_local () { return $dryrun_level <= 1; }
 495 sub act_scary () { return !$dryrun_level; }
 496
 497 sub printdone {
 498     if (!$dryrun_level) {
 499         progress "$us ok: @_";
 500     } else {
 501         progress "would be ok: @_ (but dry run only)";
 502     }
 503 }
 504
 505 sub dryrun_report {
 506     printcmd(\*STDERR,$debugprefix."#",@_);
 507 }
 508
 509 sub runcmd_ordryrun {
 510     if (act_scary()) {
 511         runcmd @_;
 512     } else {
 513         dryrun_report @_;
 514     }
 515 }
 516
 517 sub runcmd_ordryrun_local {
 518     if (act_local()) {
 519         runcmd @_;
 520     } else {
 521         dryrun_report @_;
 522     }
 523 }
 524
 525 sub shell_cmd {
 526     my ($first_shell, @cmd) = @_;
 527     return qw(sh -ec), $first_shell.'; exec "$@"', 'x', @cmd;
 528 }
 529
 530 our $helpmsg = <<END;
 531 main usages:
 532   dgit [dgit-opts] clone [dgit-opts] package [suite] [./dir|/dir]
 533   dgit [dgit-opts] fetch|pull [dgit-opts] [suite]
 534   dgit [dgit-opts] build [dpkg-buildpackage-opts]
 535   dgit [dgit-opts] sbuild [sbuild-opts]
 536   dgit [dgit-opts] push [dgit-opts] [suite]
 537   dgit [dgit-opts] rpush build-host:build-dir ...
 538 important dgit options:
 539   -k<keyid>           sign tag and package with <keyid> instead of default
 540   --dry-run -n        do not change anything, but go through the motions
 541   --damp-run -L       like --dry-run but make local changes, without signing
 542   --new -N            allow introducing a new package
 543   --debug -D          increase debug level
 544   -c<name>=<value>    set git config option (used directly by dgit too)
 545 END
 546
 547 our $later_warning_msg = <<END;
 548 Perhaps the upload is stuck in incoming.  Using the version from git.
 549 END
 550
 551 sub badusage {
 552     print STDERR "$us: @_\n", $helpmsg or die $!;
 553     exit 8;
 554 }
 555
 556 sub nextarg {
 557     @ARGV or badusage "too few arguments";
 558     return scalar shift @ARGV;
 559 }
 560
 561 sub cmd_help () {
 562     print $helpmsg or die $!;
 563     exit 0;
 564 }
 565
 566 our $td = $ENV{DGIT_TEST_DUMMY_DIR} || "DGIT_TEST_DUMMY_DIR-unset";
 567
 568 our %defcfg = ('dgit.default.distro' => 'debian',
 569                'dgit.default.default-suite' => 'unstable',
 570                'dgit.default.old-dsc-distro' => 'debian',
 571                'dgit-suite.*-security.distro' => 'debian-security',
 572                'dgit.default.username' => '',
 573                'dgit.default.archive-query-default-component' => 'main',
 574                'dgit.default.ssh' => 'ssh',
 575                'dgit.default.archive-query' => 'madison:',
 576                'dgit.default.sshpsql-dbname' => 'service=projectb',
 577                'dgit.default.aptget-components' => 'main',
 578                'dgit.default.dgit-tag-format' => 'new,old,maint',
 579                'dgit.dsc-url-proto-ok.http'    => 'true',
 580                'dgit.dsc-url-proto-ok.https'   => 'true',
 581                'dgit.dsc-url-proto-ok.git'     => 'true',
 582                'dgit.default.dsc-url-proto-ok' => 'false',
 583                # old means "repo server accepts pushes with old dgit tags"
 584                # new means "repo server accepts pushes with new dgit tags"
 585                # maint means "repo server accepts split brain pushes"
 586                # hist means "repo server may have old pushes without new tag"
 587                #   ("hist" is implied by "old")
 588                'dgit-distro.debian.archive-query' => 'ftpmasterapi:',
 589                'dgit-distro.debian.git-check' => 'url',
 590                'dgit-distro.debian.git-check-suffix' => '/info/refs',
 591                'dgit-distro.debian.new-private-pushers' => 't',
 592                'dgit-distro.debian/push.git-url' => '',
 593                'dgit-distro.debian/push.git-host' => 'push.dgit.debian.org',
 594                'dgit-distro.debian/push.git-user-force' => 'dgit',
 595                'dgit-distro.debian/push.git-proto' => 'git+ssh://',
 596                'dgit-distro.debian/push.git-path' => '/dgit/debian/repos',
 597                'dgit-distro.debian/push.git-create' => 'true',
 598                'dgit-distro.debian/push.git-check' => 'ssh-cmd',
 599  'dgit-distro.debian.archive-query-url', 'https://api.ftp-master.debian.org/',
 600 # 'dgit-distro.debian.archive-query-tls-key',
 601 #    '/etc/ssl/certs/%HOST%.pem:/etc/dgit/%HOST%.pem',
 602 # ^ this does not work because curl is broken nowadays
 603 # Fixing #790093 properly will involve providing providing the key
 604 # in some pacagke and maybe updating these paths.
 605 #
 606 # 'dgit-distro.debian.archive-query-tls-curl-args',
 607 #   '--ca-path=/etc/ssl/ca-debian',
 608 # ^ this is a workaround but works (only) on DSA-administered machines
 609                'dgit-distro.debian.git-url' => 'https://git.dgit.debian.org',
 610                'dgit-distro.debian.git-url-suffix' => '',
 611                'dgit-distro.debian.upload-host' => 'ftp-master', # for dput
 612                'dgit-distro.debian.mirror' => 'http://ftp.debian.org/debian/',
 613  'dgit-distro.debian-security.archive-query' => 'aptget:',
 614  'dgit-distro.debian-security.mirror' => 'http://security.debian.org/debian-security/',
 615  'dgit-distro.debian-security.aptget-suite-map' => 's#-security$#/updates#',
 616  'dgit-distro.debian-security.aptget-suite-rmap' => 's#$#-security#',
 617  'dgit-distro.debian-security.nominal-distro' => 'debian',
 618  'dgit-distro.debian.backports-quirk' => '(squeeze)-backports*',
 619  'dgit-distro.debian-backports.mirror' => 'http://backports.debian.org/debian-backports/',
 620                'dgit-distro.ubuntu.git-check' => 'false',
 621  'dgit-distro.ubuntu.mirror' => 'http://archive.ubuntu.com/ubuntu',
 622                'dgit-distro.test-dummy.ssh' => "$td/ssh",
 623                'dgit-distro.test-dummy.username' => "alice",
 624                'dgit-distro.test-dummy.git-check' => "ssh-cmd",
 625                'dgit-distro.test-dummy.git-create' => "ssh-cmd",
 626                'dgit-distro.test-dummy.git-url' => "$td/git",
 627                'dgit-distro.test-dummy.git-host' => "git",
 628                'dgit-distro.test-dummy.git-path' => "$td/git",
 629                'dgit-distro.test-dummy.archive-query' => "dummycatapi:",
 630                'dgit-distro.test-dummy.archive-query-url' => "file://$td/aq/",
 631                'dgit-distro.test-dummy.mirror' => "file://$td/mirror/",
 632                'dgit-distro.test-dummy.upload-host' => 'test-dummy',
 633                );
 634
 635 our %gitcfgs;
 636 our @gitcfgsources = qw(cmdline local global system);
 637
 638 sub git_slurp_config () {
 639     local ($debuglevel) = $debuglevel-2;
 640     local $/="\0";
 641
 642     # This algoritm is a bit subtle, but this is needed so that for
 643     # options which we want to be single-valued, we allow the
 644     # different config sources to override properly.  See #835858.
 645     foreach my $src (@gitcfgsources) {
 646         next if $src eq 'cmdline';
 647         # we do this ourselves since git doesn't handle it
 648
 649         my @cmd = (@git, qw(config -z --get-regexp), "--$src", qw(.*));
 650         debugcmd "|",@cmd;
 651
 652         open GITS, "-|", @cmd or die $!;
 653         while (<GITS>) {
 654             chomp or die;
 655             printdebug "=> ", (messagequote $_), "\n";
 656             m/\n/ or die "$_ ?";
 657             push @{ $gitcfgs{$src}{$`} }, $'; #';
 658         }
 659         $!=0; $?=0;
 660         close GITS
 661             or ($!==0 && $?==256)
 662             or failedcmd @cmd;
 663     }
 664 }
 665
 666 sub git_get_config ($) {
 667     my ($c) = @_;
 668     foreach my $src (@gitcfgsources) {
 669         my $l = $gitcfgs{$src}{$c};
 670         croak "$l $c" if $l && !ref $l;
 671         printdebug"C $c ".(defined $l ?
 672                            join " ", map { messagequote "'$_'" } @$l :
 673                            "undef")."\n"
 674             if $debuglevel >= 4;
 675         $l or next;
 676         @$l==1 or badcfg "multiple values for $c".
 677             " (in $src git config)" if @$l > 1;
 678         return $l->[0];
 679     }
 680     return undef;
 681 }
 682
 683 sub cfg {
 684     foreach my $c (@_) {
 685         return undef if $c =~ /RETURN-UNDEF/;
 686         printdebug "C? $c\n" if $debuglevel >= 5;
 687         my $v = git_get_config($c);
 688         return $v if defined $v;
 689         my $dv = $defcfg{$c};
 690         if (defined $dv) {
 691             printdebug "CD $c $dv\n" if $debuglevel >= 4;
 692             return $dv;
 693         }
 694     }
 695     badcfg "need value for one of: @_\n".
 696         "$us: distro or suite appears not to be (properly) supported";
 697 }
 698
 699 sub access_basedistro__noalias () {
 700     if (defined $idistro) {
 701         return $idistro;
 702     } else {
 703         my $def = cfg("dgit-suite.$isuite.distro", 'RETURN-UNDEF');
 704         return $def if defined $def;
 705         foreach my $src (@gitcfgsources, 'internal') {
 706             my $kl = $src eq 'internal' ? \%defcfg : $gitcfgs{$src};
 707             next unless $kl;
 708             foreach my $k (keys %$kl) {
 709                 next unless $k =~ m#^dgit-suite\.(.*)\.distro$#;
 710                 my $dpat = $1;
 711                 next unless match_glob $dpat, $isuite;
 712                 return $kl->{$k};
 713             }
 714         }
 715         return cfg("dgit.default.distro");
 716     }
 717 }
 718
 719 sub access_basedistro () {
 720     my $noalias = access_basedistro__noalias();
 721     my $canon = cfg("dgit-distro.$noalias.alias-canon",'RETURN-UNDEF');
 722     return $canon // $noalias;
 723 }
 724
 725 sub access_nomdistro () {
 726     my $base = access_basedistro();
 727     my $r = cfg("dgit-distro.$base.nominal-distro",'RETURN-UNDEF') // $base;
 728     $r =~ m/^$distro_re$/ or badcfg
 729  "bad syntax for (nominal) distro \`$r' (does not match /^$distro_re$/)";
 730     return $r;
 731 }
 732
 733 sub access_quirk () {
 734     # returns (quirk name, distro to use instead or undef, quirk-specific info)
 735     my $basedistro = access_basedistro();
 736     my $backports_quirk = cfg("dgit-distro.$basedistro.backports-quirk",
 737                               'RETURN-UNDEF');
 738     if (defined $backports_quirk) {
 739         my $re = $backports_quirk;
 740         $re =~ s/[^-0-9a-z_\%*()]/\\$&/ig;
 741         $re =~ s/\*/.*/g;
 742         $re =~ s/\%/([-0-9a-z_]+)/
 743             or $re =~ m/[()]/ or badcfg "backports-quirk needs \% or ( )";
 744         if ($isuite =~ m/^$re$/) {
 745             return ('backports',"$basedistro-backports",$1);
 746         }
 747     }
 748     return ('none',undef);
 749 }
 750
 751 our $access_forpush;
 752
 753 sub parse_cfg_bool ($$$) {
 754     my ($what,$def,$v) = @_;
 755     $v //= $def;
 756     return
 757         $v =~ m/^[ty1]/ ? 1 :
 758         $v =~ m/^[fn0]/ ? 0 :
 759         badcfg "$what needs t (true, y, 1) or f (false, n, 0) not \`$v'";
 760 }
 761
 762 sub access_forpush_config () {
 763     my $d = access_basedistro();
 764
 765     return 1 if
 766         $new_package &&
 767         parse_cfg_bool('new-private-pushers', 0,
 768                        cfg("dgit-distro.$d.new-private-pushers",
 769                            'RETURN-UNDEF'));
 770
 771     my $v = cfg("dgit-distro.$d.readonly", 'RETURN-UNDEF');
 772     $v //= 'a';
 773     return
 774         $v =~ m/^[ty1]/ ? 0 : # force readonly,    forpush = 0
 775         $v =~ m/^[fn0]/ ? 1 : # force nonreadonly, forpush = 1
 776         $v =~ m/^[a]/  ? '' : # auto,              forpush = ''
 777         badcfg "readonly needs t (true, y, 1) or f (false, n, 0) or a (auto)";
 778 }
 779
 780 sub access_forpush () {
 781     $access_forpush //= access_forpush_config();
 782     return $access_forpush;
 783 }
 784
 785 sub pushing () {
 786     die "$access_forpush ?" if ($access_forpush // 1) ne 1;
 787     badcfg "pushing but distro is configured readonly"
 788         if access_forpush_config() eq '0';
 789     $access_forpush = 1;
 790     $supplementary_message = <<'END' unless $we_are_responder;
 791 Push failed, before we got started.
 792 You can retry the push, after fixing the problem, if you like.
 793 END
 794     parseopts_late_defaults();
 795 }
 796
 797 sub notpushing () {
 798     parseopts_late_defaults();
 799 }
 800
 801 sub supplementary_message ($) {
 802     my ($msg) = @_;
 803     if (!$we_are_responder) {
 804         $supplementary_message = $msg;
 805         return;
 806     } elsif ($protovsn >= 3) {
 807         responder_send_command "supplementary-message ".length($msg)
 808             or die $!;
 809         print PO $msg or die $!;
 810     }
 811 }
 812
 813 sub access_distros () {
 814     # Returns list of distros to try, in order
 815     #
 816     # We want to try:
 817     #    0. `instead of' distro name(s) we have been pointed to
 818     #    1. the access_quirk distro, if any
 819     #    2a. the user's specified distro, or failing that  } basedistro
 820     #    2b. the distro calculated from the suite          }
 821     my @l = access_basedistro();
 822
 823     my (undef,$quirkdistro) = access_quirk();
 824     unshift @l, $quirkdistro;
 825     unshift @l, $instead_distro;
 826     @l = grep { defined } @l;
 827
 828     push @l, access_nomdistro();
 829
 830     if (access_forpush()) {
 831         @l = map { ("$_/push", $_) } @l;
 832     }
 833     @l;
 834 }
 835
 836 sub access_cfg_cfgs (@) {
 837     my (@keys) = @_;
 838     my @cfgs;
 839     # The nesting of these loops determines the search order.  We put
 840     # the key loop on the outside so that we search all the distros
 841     # for each key, before going on to the next key.  That means that
 842     # if access_cfg is called with a more specific, and then a less
 843     # specific, key, an earlier distro can override the less specific
 844     # without necessarily overriding any more specific keys.  (If the
 845     # distro wants to override the more specific keys it can simply do
 846     # so; whereas if we did the loop the other way around, it would be
 847     # impossible to for an earlier distro to override a less specific
 848     # key but not the more specific ones without restating the unknown
 849     # values of the more specific keys.
 850     my @realkeys;
 851     my @rundef;
 852     # We have to deal with RETURN-UNDEF specially, so that we don't
 853     # terminate the search prematurely.
 854     foreach (@keys) {
 855         if (m/RETURN-UNDEF/) { push @rundef, $_; last; }
 856         push @realkeys, $_
 857     }
 858     foreach my $d (access_distros()) {
 859         push @cfgs, map { "dgit-distro.$d.$_" } @realkeys;
 860     }
 861     push @cfgs, map { "dgit.default.$_" } @realkeys;
 862     push @cfgs, @rundef;
 863     return @cfgs;
 864 }
 865
 866 sub access_cfg (@) {
 867     my (@keys) = @_;
 868     my (@cfgs) = access_cfg_cfgs(@keys);
 869     my $value = cfg(@cfgs);
 870     return $value;
 871 }
 872
 873 sub access_cfg_bool ($$) {
 874     my ($def, @keys) = @_;
 875     parse_cfg_bool($keys[0], $def, access_cfg(@keys, 'RETURN-UNDEF'));
 876 }
 877
 878 sub string_to_ssh ($) {
 879     my ($spec) = @_;
 880     if ($spec =~ m/\s/) {
 881         return qw(sh -ec), 'exec '.$spec.' "$@"', 'x';
 882     } else {
 883         return ($spec);
 884     }
 885 }
 886
 887 sub access_cfg_ssh () {
 888     my $gitssh = access_cfg('ssh', 'RETURN-UNDEF');
 889     if (!defined $gitssh) {
 890         return @ssh;
 891     } else {
 892         return string_to_ssh $gitssh;
 893     }
 894 }
 895
 896 sub access_runeinfo ($) {
 897     my ($info) = @_;
 898     return ": dgit ".access_basedistro()." $info ;";
 899 }
 900
 901 sub access_someuserhost ($) {
 902     my ($some) = @_;
 903     my $user = access_cfg("$some-user-force", 'RETURN-UNDEF');
 904     defined($user) && length($user) or
 905         $user = access_cfg("$some-user",'username');
 906     my $host = access_cfg("$some-host");
 907     return length($user) ? "$user\@$host" : $host;
 908 }
 909
 910 sub access_gituserhost () {
 911     return access_someuserhost('git');
 912 }
 913
 914 sub access_giturl (;$) {
 915     my ($optional) = @_;
 916     my $url = access_cfg('git-url','RETURN-UNDEF');
 917     my $suffix;
 918     if (!length $url) {
 919         my $proto = access_cfg('git-proto', 'RETURN-UNDEF');
 920         return undef unless defined $proto;
 921         $url =
 922             $proto.
 923             access_gituserhost().
 924             access_cfg('git-path');
 925     } else {
 926         $suffix = access_cfg('git-url-suffix','RETURN-UNDEF');
 927     }
 928     $suffix //= '.git';
 929     return "$url/$package$suffix";
 930 }
 931
 932 sub parsecontrolfh ($$;$) {
 933     my ($fh, $desc, $allowsigned) = @_;
 934     our $dpkgcontrolhash_noissigned;
 935     my $c;
 936     for (;;) {
 937         my %opts = ('name' => $desc);
 938         $opts{allow_pgp}= $allowsigned || !$dpkgcontrolhash_noissigned;
 939         $c = Dpkg::Control::Hash->new(%opts);
 940         $c->parse($fh,$desc) or die "parsing of $desc failed";
 941         last if $allowsigned;
 942         last if $dpkgcontrolhash_noissigned;
 943         my $issigned= $c->get_option('is_pgp_signed');
 944         if (!defined $issigned) {
 945             $dpkgcontrolhash_noissigned= 1;
 946             seek $fh, 0,0 or die "seek $desc: $!";
 947         } elsif ($issigned) {
 948             fail "control file $desc is (already) PGP-signed. ".
 949                 " Note that dgit push needs to modify the .dsc and then".
 950                 " do the signature itself";
 951         } else {
 952             last;
 953         }
 954     }
 955     return $c;
 956 }
 957
 958 sub parsecontrol {
 959     my ($file, $desc, $allowsigned) = @_;
 960     my $fh = new IO::Handle;
 961     open $fh, '<', $file or die "$file: $!";
 962     my $c = parsecontrolfh($fh,$desc,$allowsigned);
 963     $fh->error and die $!;
 964     close $fh;
 965     return $c;
 966 }
 967
 968 sub getfield ($$) {
 969     my ($dctrl,$field) = @_;
 970     my $v = $dctrl->{$field};
 971     return $v if defined $v;
 972     fail "missing field $field in ".$dctrl->get_option('name');
 973 }
 974
 975 sub parsechangelog {
 976     my $c = Dpkg::Control::Hash->new(name => 'parsed changelog');
 977     my $p = new IO::Handle;
 978     my @cmd = (qw(dpkg-parsechangelog), @_);
 979     open $p, '-|', @cmd or die $!;
 980     $c->parse($p);
 981     $?=0; $!=0; close $p or failedcmd @cmd;
 982     return $c;
 983 }
 984
 985 sub commit_getclogp ($) {
 986     # Returns the parsed changelog hashref for a particular commit
 987     my ($objid) = @_;
 988     our %commit_getclogp_memo;
 989     my $memo = $commit_getclogp_memo{$objid};
 990     return $memo if $memo;
 991     mkpath '.git/dgit';
 992     my $mclog = ".git/dgit/clog-$objid";
 993     runcmd shell_cmd "exec >$mclog", @git, qw(cat-file blob),
 994         "$objid:debian/changelog";
 995     $commit_getclogp_memo{$objid} = parsechangelog("-l$mclog");
 996 }
 997
 998 sub must_getcwd () {
 999     my $d = getcwd();
1000     defined $d or fail "getcwd failed: $!";
1001     return $d;
1002 }
1003
1004 sub parse_dscdata () {
1005     my $dscfh = new IO::File \$dscdata, '<' or die $!;
1006     printdebug Dumper($dscdata) if $debuglevel>1;
1007     $dsc = parsecontrolfh($dscfh,$dscurl,1);
1008     printdebug Dumper($dsc) if $debuglevel>1;
1009 }
1010
1011 our %rmad;
1012
1013 sub archive_query ($;@) {
1014     my ($method) = shift @_;
1015     fail "this operation does not support multiple comma-separated suites"
1016         if $isuite =~ m/,/;
1017     my $query = access_cfg('archive-query','RETURN-UNDEF');
1018     $query =~ s/^(\w+):// or badcfg "invalid archive-query method \`$query'";
1019     my $proto = $1;
1020     my $data = $'; #';
1021     { no strict qw(refs); &{"${method}_${proto}"}($proto,$data,@_); }
1022 }
1023
1024 sub archive_query_prepend_mirror {
1025     my $m = access_cfg('mirror');
1026     return map { [ $_->[0], $m.$_->[1], @$_[2..$#$_] ] } @_;
1027 }
1028
1029 sub pool_dsc_subpath ($$) {
1030     my ($vsn,$component) = @_; # $package is implict arg
1031     my $prefix = substr($package, 0, $package =~ m/^l/ ? 4 : 1);
1032     return "/pool/$component/$prefix/$package/".dscfn($vsn);
1033 }
1034
1035 sub cfg_apply_map ($$$) {
1036     my ($varref, $what, $mapspec) = @_;
1037     return unless $mapspec;
1038
1039     printdebug "config $what EVAL{ $mapspec; }\n";
1040     $_ = $$varref;
1041     eval "package Dgit::Config; $mapspec;";
1042     die $@ if $@;
1043     $$varref = $_;
1044 }
1045
1046 #---------- `ftpmasterapi' archive query method (nascent) ----------
1047
1048 sub archive_api_query_cmd ($) {
1049     my ($subpath) = @_;
1050     my @cmd = (@curl, qw(-sS));
1051     my $url = access_cfg('archive-query-url');
1052     if ($url =~ m#^https://([-.0-9a-z]+)/#) {
1053         my $host = $1;
1054         my $keys = access_cfg('archive-query-tls-key','RETURN-UNDEF') //'';
1055         foreach my $key (split /\:/, $keys) {
1056             $key =~ s/\%HOST\%/$host/g;
1057             if (!stat $key) {
1058                 fail "for $url: stat $key: $!" unless $!==ENOENT;
1059                 next;
1060             }
1061             fail "config requested specific TLS key but do not know".
1062                 " how to get curl to use exactly that EE key ($key)";
1063 #           push @cmd, "--cacert", $key, "--capath", "/dev/enoent";
1064 #           # Sadly the above line does not work because of changes
1065 #           # to gnutls.   The real fix for #790093 may involve
1066 #           # new curl options.
1067             last;
1068         }
1069         # Fixing #790093 properly will involve providing a value
1070         # for this on clients.
1071         my $kargs = access_cfg('archive-query-tls-curl-ca-args','RETURN-UNDEF');
1072         push @cmd, split / /, $kargs if defined $kargs;
1073     }
1074     push @cmd, $url.$subpath;
1075     return @cmd;
1076 }
1077
1078 sub api_query ($$;$) {
1079     use JSON;
1080     my ($data, $subpath, $ok404) = @_;
1081     badcfg "ftpmasterapi archive query method takes no data part"
1082         if length $data;
1083     my @cmd = archive_api_query_cmd($subpath);
1084     my $url = $cmd[$#cmd];
1085     push @cmd, qw(-w %{http_code});
1086     my $json = cmdoutput @cmd;
1087     unless ($json =~ s/\d+\d+\d$//) {
1088         failedcmd_report_cmd undef, @cmd;
1089         fail "curl failed to print 3-digit HTTP code";
1090     }
1091     my $code = $&;
1092     return undef if $code eq '404' && $ok404;
1093     fail "fetch of $url gave HTTP code $code"
1094         unless $url =~ m#^file://# or $code =~ m/^2/;
1095     return decode_json($json);
1096 }
1097
1098 sub canonicalise_suite_ftpmasterapi {
1099     my ($proto,$data) = @_;
1100     my $suites = api_query($data, 'suites');
1101     my @matched;
1102     foreach my $entry (@$suites) {
1103         next unless grep {
1104             my $v = $entry->{$_};
1105             defined $v && $v eq $isuite;
1106         } qw(codename name);
1107         push @matched, $entry;
1108     }
1109     fail "unknown suite $isuite" unless @matched;
1110     my $cn;
1111     eval {
1112         @matched==1 or die "multiple matches for suite $isuite\n";
1113         $cn = "$matched[0]{codename}";
1114         defined $cn or die "suite $isuite info has no codename\n";
1115         $cn =~ m/^$suite_re$/ or die "suite $isuite maps to bad codename\n";
1116     };
1117     die "bad ftpmaster api response: $@\n".Dumper(\@matched)
1118         if length $@;
1119     return $cn;
1120 }
1121
1122 sub archive_query_ftpmasterapi {
1123     my ($proto,$data) = @_;
1124     my $info = api_query($data, "dsc_in_suite/$isuite/$package");
1125     my @rows;
1126     my $digester = Digest::SHA->new(256);
1127     foreach my $entry (@$info) {
1128         eval {
1129             my $vsn = "$entry->{version}";
1130             my ($ok,$msg) = version_check $vsn;
1131             die "bad version: $msg\n" unless $ok;
1132             my $component = "$entry->{component}";
1133             $component =~ m/^$component_re$/ or die "bad component";
1134             my $filename = "$entry->{filename}";
1135             $filename && $filename !~ m#[^-+:._~0-9a-zA-Z/]|^[/.]|/[/.]#
1136                 or die "bad filename";
1137             my $sha256sum = "$entry->{sha256sum}";
1138             $sha256sum =~ m/^[0-9a-f]+$/ or die "bad sha256sum";
1139             push @rows, [ $vsn, "/pool/$component/$filename",
1140                           $digester, $sha256sum ];
1141         };
1142         die "bad ftpmaster api response: $@\n".Dumper($entry)
1143             if length $@;
1144     }
1145     @rows = sort { -version_compare($a->[0],$b->[0]) } @rows;
1146     return archive_query_prepend_mirror @rows;
1147 }
1148
1149 sub file_in_archive_ftpmasterapi {
1150     my ($proto,$data,$filename) = @_;
1151     my $pat = $filename;
1152     $pat =~ s/_/\\_/g;
1153     $pat = "%/$pat";
1154     $pat =~ s#[^-+_.0-9a-z/]# sprintf '%%%02x', ord $& #ge;
1155     my $info = api_query($data, "file_in_archive/$pat", 1);
1156 }
1157
1158 #---------- `aptget' archive query method ----------
1159
1160 our $aptget_base;
1161 our $aptget_releasefile;
1162 our $aptget_configpath;
1163
1164 sub aptget_aptget   () { return @aptget,   qw(-c), $aptget_configpath; }
1165 sub aptget_aptcache () { return @aptcache, qw(-c), $aptget_configpath; }
1166
1167 sub aptget_cache_clean {
1168     runcmd_ordryrun_local qw(sh -ec),
1169         'cd "$1"; find -atime +30 -type f -print0 | xargs -0r rm --',
1170         'x', $aptget_base;
1171 }
1172
1173 sub aptget_lock_acquire () {
1174     my $lockfile = "$aptget_base/lock";
1175     open APTGET_LOCK, '>', $lockfile or die "open $lockfile: $!";
1176     flock APTGET_LOCK, LOCK_EX or die "lock $lockfile: $!";
1177 }
1178
1179 sub aptget_prep ($) {
1180     my ($data) = @_;
1181     return if defined $aptget_base;
1182
1183     badcfg "aptget archive query method takes no data part"
1184         if length $data;
1185
1186     my $cache = $ENV{XDG_CACHE_DIR} // "$ENV{HOME}/.cache";
1187
1188     ensuredir $cache;
1189     ensuredir "$cache/dgit";
1190     my $cachekey =
1191         access_cfg('aptget-cachekey','RETURN-UNDEF')
1192         // access_nomdistro();
1193
1194     $aptget_base = "$cache/dgit/aptget";
1195     ensuredir $aptget_base;
1196
1197     my $quoted_base = $aptget_base;
1198     die "$quoted_base contains bad chars, cannot continue"
1199         if $quoted_base =~ m/["\\]/; # apt.conf(5) says no escaping :-/
1200
1201     ensuredir $aptget_base;
1202
1203     aptget_lock_acquire();
1204
1205     aptget_cache_clean();
1206
1207     $aptget_configpath = "$aptget_base/apt.conf#$cachekey";
1208     my $sourceslist = "source.list#$cachekey";
1209
1210     my $aptsuites = $isuite;
1211     cfg_apply_map(\$aptsuites, 'suite map',
1212                   access_cfg('aptget-suite-map', 'RETURN-UNDEF'));
1213
1214     open SRCS, ">", "$aptget_base/$sourceslist" or die $!;
1215     printf SRCS "deb-src %s %s %s\n",
1216         access_cfg('mirror'),
1217         $aptsuites,
1218         access_cfg('aptget-components')
1219         or die $!;
1220
1221     ensuredir "$aptget_base/cache";
1222     ensuredir "$aptget_base/lists";
1223
1224     open CONF, ">", $aptget_configpath or die $!;
1225     print CONF <<END;
1226 Debug::NoLocking "true";
1227 APT::Get::List-Cleanup "false";
1228 #clear APT::Update::Post-Invoke-Success;
1229 Dir::Etc::SourceList "$quoted_base/$sourceslist";
1230 Dir::State::Lists "$quoted_base/lists";
1231 Dir::Etc::preferences "$quoted_base/preferences";
1232 Dir::Cache::srcpkgcache "$quoted_base/cache/srcs#$cachekey";
1233 Dir::Cache::pkgcache "$quoted_base/cache/pkgs#$cachekey";
1234 END
1235
1236     foreach my $key (qw(
1237                         Dir::Cache
1238                         Dir::State
1239                         Dir::Cache::Archives
1240                         Dir::Etc::SourceParts
1241                         Dir::Etc::preferencesparts
1242                       )) {
1243         ensuredir "$aptget_base/$key";
1244         print CONF "$key \"$quoted_base/$key\";\n" or die $!;
1245     };
1246
1247     my $oldatime = (time // die $!) - 1;
1248     foreach my $oldlist (<$aptget_base/lists/*Release>) {
1249         next unless stat_exists $oldlist;
1250         my ($mtime) = (stat _)[9];
1251         utime $oldatime, $mtime, $oldlist or die "$oldlist $!";
1252     }
1253
1254     runcmd_ordryrun_local aptget_aptget(), qw(update);
1255
1256     my @releasefiles;
1257     foreach my $oldlist (<$aptget_base/lists/*Release>) {
1258         next unless stat_exists $oldlist;
1259         my ($atime) = (stat _)[8];
1260         next if $atime == $oldatime;
1261         push @releasefiles, $oldlist;
1262     }
1263     my @inreleasefiles = grep { m#/InRelease$# } @releasefiles;
1264     @releasefiles = @inreleasefiles if @inreleasefiles;
1265     die "apt updated wrong number of Release files (@releasefiles), erk"
1266         unless @releasefiles == 1;
1267
1268     ($aptget_releasefile) = @releasefiles;
1269 }
1270
1271 sub canonicalise_suite_aptget {
1272     my ($proto,$data) = @_;
1273     aptget_prep($data);
1274
1275     my $release = parsecontrol $aptget_releasefile, "Release file", 1;
1276
1277     foreach my $name (qw(Codename Suite)) {
1278         my $val = $release->{$name};
1279         if (defined $val) {
1280             printdebug "release file $name: $val\n";
1281             $val =~ m/^$suite_re$/o or fail
1282  "Release file ($aptget_releasefile) specifies intolerable $name";
1283             cfg_apply_map(\$val, 'suite rmap',
1284                           access_cfg('aptget-suite-rmap', 'RETURN-UNDEF'));
1285             return $val
1286         }
1287     }
1288     return $isuite;
1289 }
1290
1291 sub archive_query_aptget {
1292     my ($proto,$data) = @_;
1293     aptget_prep($data);
1294
1295     ensuredir "$aptget_base/source";
1296     foreach my $old (<$aptget_base/source/*.dsc>) {
1297         unlink $old or die "$old: $!";
1298     }
1299
1300     my $showsrc = cmdoutput aptget_aptcache(), qw(showsrc), $package;
1301     return () unless $showsrc =~ m/^package:\s*\Q$package\E\s*$/mi;
1302     # avoids apt-get source failing with ambiguous error code
1303
1304     runcmd_ordryrun_local
1305         shell_cmd 'cd "$1"/source; shift', $aptget_base,
1306         aptget_aptget(), qw(--download-only --only-source source), $package;
1307
1308     my @dscs = <$aptget_base/source/*.dsc>;
1309     fail "apt-get source did not produce a .dsc" unless @dscs;
1310     fail "apt-get source produced several .dscs (@dscs)" unless @dscs==1;
1311
1312     my $pre_dsc = parsecontrol $dscs[0], $dscs[0], 1;
1313
1314     use URI::Escape;
1315     my $uri = "file://". uri_escape $dscs[0];
1316     $uri =~ s{\%2f}{/}gi;
1317     return [ (getfield $pre_dsc, 'Version'), $uri ];
1318 }
1319
1320 #---------- `dummyapicat' archive query method ----------
1321
1322 sub archive_query_dummycatapi { archive_query_ftpmasterapi @_; }
1323 sub canonicalise_suite_dummycatapi { canonicalise_suite_ftpmasterapi @_; }
1324
1325 sub file_in_archive_dummycatapi ($$$) {
1326     my ($proto,$data,$filename) = @_;
1327     my $mirror = access_cfg('mirror');
1328     $mirror =~ s#^file://#/# or die "$mirror ?";
1329     my @out;
1330     my @cmd = (qw(sh -ec), '
1331             cd "$1"
1332             find -name "$2" -print0 |
1333             xargs -0r sha256sum
1334         ', qw(x), $mirror, $filename);
1335     debugcmd "-|", @cmd;
1336     open FIA, "-|", @cmd or die $!;
1337     while (<FIA>) {
1338         chomp or die;
1339         printdebug "| $_\n";
1340         m/^(\w+)  (\S+)$/ or die "$_ ?";
1341         push @out, { sha256sum => $1, filename => $2 };
1342     }
1343     close FIA or die failedcmd @cmd;
1344     return \@out;
1345 }
1346
1347 #---------- `madison' archive query method ----------
1348
1349 sub archive_query_madison {
1350     return archive_query_prepend_mirror
1351         map { [ @$_[0..1] ] } madison_get_parse(@_);
1352 }
1353
1354 sub madison_get_parse {
1355     my ($proto,$data) = @_;
1356     die unless $proto eq 'madison';
1357     if (!length $data) {
1358         $data= access_cfg('madison-distro','RETURN-UNDEF');
1359         $data //= access_basedistro();
1360     }
1361     $rmad{$proto,$data,$package} ||= cmdoutput
1362         qw(rmadison -asource),"-s$isuite","-u$data",$package;
1363     my $rmad = $rmad{$proto,$data,$package};
1364
1365     my @out;
1366     foreach my $l (split /\n/, $rmad) {
1367         $l =~ m{^ \s*( [^ \t|]+ )\s* \|
1368                   \s*( [^ \t|]+ )\s* \|
1369                   \s*( [^ \t|/]+ )(?:/([^ \t|/]+))? \s* \|
1370                   \s*( [^ \t|]+ )\s* }x or die "$rmad ?";
1371         $1 eq $package or die "$rmad $package ?";
1372         my $vsn = $2;
1373         my $newsuite = $3;
1374         my $component;
1375         if (defined $4) {
1376             $component = $4;
1377         } else {
1378             $component = access_cfg('archive-query-default-component');
1379         }
1380         $5 eq 'source' or die "$rmad ?";
1381         push @out, [$vsn,pool_dsc_subpath($vsn,$component),$newsuite];
1382     }
1383     return sort { -version_compare($a->[0],$b->[0]); } @out;
1384 }
1385
1386 sub canonicalise_suite_madison {
1387     # madison canonicalises for us
1388     my @r = madison_get_parse(@_);
1389     @r or fail
1390         "unable to canonicalise suite using package $package".
1391         " which does not appear to exist in suite $isuite;".
1392         " --existing-package may help";
1393     return $r[0][2];
1394 }
1395
1396 sub file_in_archive_madison { return undef; }
1397
1398 #---------- `sshpsql' archive query method ----------
1399
1400 sub sshpsql ($$$) {
1401     my ($data,$runeinfo,$sql) = @_;
1402     if (!length $data) {
1403         $data= access_someuserhost('sshpsql').':'.
1404             access_cfg('sshpsql-dbname');
1405     }
1406     $data =~ m/:/ or badcfg "invalid sshpsql method string \`$data'";
1407     my ($userhost,$dbname) = ($`,$'); #';
1408     my @rows;
1409     my @cmd = (access_cfg_ssh, $userhost,
1410                access_runeinfo("ssh-psql $runeinfo").
1411                " export LC_MESSAGES=C; export LC_CTYPE=C;".
1412                " ".shellquote qw(psql -A), $dbname, qw(-c), $sql);
1413     debugcmd "|",@cmd;
1414     open P, "-|", @cmd or die $!;
1415     while (<P>) {
1416         chomp or die;
1417         printdebug(">|$_|\n");
1418         push @rows, $_;
1419     }
1420     $!=0; $?=0; close P or failedcmd @cmd;
1421     @rows or die;
1422     my $nrows = pop @rows;
1423     $nrows =~ s/^\((\d+) rows?\)$/$1/ or die "$nrows ?";
1424     @rows == $nrows+1 or die "$nrows ".(scalar @rows)." ?";
1425     @rows = map { [ split /\|/, $_ ] } @rows;
1426     my $ncols = scalar @{ shift @rows };
1427     die if grep { scalar @$_ != $ncols } @rows;
1428     return @rows;
1429 }
1430
1431 sub sql_injection_check {
1432     foreach (@_) { die "$_ $& ?" if m{[^-+=:_.,/0-9a-zA-Z]}; }
1433 }
1434
1435 sub archive_query_sshpsql ($$) {
1436     my ($proto,$data) = @_;
1437     sql_injection_check $isuite, $package;
1438     my @rows = sshpsql($data, "archive-query $isuite $package", <<END);
1439         SELECT source.version, component.name, files.filename, files.sha256sum
1440           FROM source
1441           JOIN src_associations ON source.id = src_associations.source
1442           JOIN suite ON suite.id = src_associations.suite
1443           JOIN dsc_files ON dsc_files.source = source.id
1444           JOIN files_archive_map ON files_archive_map.file_id = dsc_files.file
1445           JOIN component ON component.id = files_archive_map.component_id
1446           JOIN files ON files.id = dsc_files.file
1447          WHERE ( suite.suite_name='$isuite' OR suite.codename='$isuite' )
1448            AND source.source='$package'
1449            AND files.filename LIKE '%.dsc';
1450 END
1451     @rows = sort { -version_compare($a->[0],$b->[0]) } @rows;
1452     my $digester = Digest::SHA->new(256);
1453     @rows = map {
1454         my ($vsn,$component,$filename,$sha256sum) = @$_;
1455         [ $vsn, "/pool/$component/$filename",$digester,$sha256sum ];
1456     } @rows;
1457     return archive_query_prepend_mirror @rows;
1458 }
1459
1460 sub canonicalise_suite_sshpsql ($$) {
1461     my ($proto,$data) = @_;
1462     sql_injection_check $isuite;
1463     my @rows = sshpsql($data, "canonicalise-suite $isuite", <<END);
1464         SELECT suite.codename
1465           FROM suite where suite_name='$isuite' or codename='$isuite';
1466 END
1467     @rows = map { $_->[0] } @rows;
1468     fail "unknown suite $isuite" unless @rows;
1469     die "ambiguous $isuite: @rows ?" if @rows>1;
1470     return $rows[0];
1471 }
1472
1473 sub file_in_archive_sshpsql ($$$) { return undef; }
1474
1475 #---------- `dummycat' archive query method ----------
1476
1477 sub canonicalise_suite_dummycat ($$) {
1478     my ($proto,$data) = @_;
1479     my $dpath = "$data/suite.$isuite";
1480     if (!open C, "<", $dpath) {
1481         $!==ENOENT or die "$dpath: $!";
1482         printdebug "dummycat canonicalise_suite $isuite $dpath ENOENT\n";
1483         return $isuite;
1484     }
1485     $!=0; $_ = <C>;
1486     chomp or die "$dpath: $!";
1487     close C;
1488     printdebug "dummycat canonicalise_suite $isuite $dpath = $_\n";
1489     return $_;
1490 }
1491
1492 sub archive_query_dummycat ($$) {
1493     my ($proto,$data) = @_;
1494     canonicalise_suite();
1495     my $dpath = "$data/package.$csuite.$package";
1496     if (!open C, "<", $dpath) {
1497         $!==ENOENT or die "$dpath: $!";
1498         printdebug "dummycat query $csuite $package $dpath ENOENT\n";
1499         return ();
1500     }
1501     my @rows;
1502     while (<C>) {
1503         next if m/^\#/;
1504         next unless m/\S/;
1505         die unless chomp;
1506         printdebug "dummycat query $csuite $package $dpath | $_\n";
1507         my @row = split /\s+/, $_;
1508         @row==2 or die "$dpath: $_ ?";
1509         push @rows, \@row;
1510     }
1511     C->error and die "$dpath: $!";
1512     close C;
1513     return archive_query_prepend_mirror
1514         sort { -version_compare($a->[0],$b->[0]); } @rows;
1515 }
1516
1517 sub file_in_archive_dummycat () { return undef; }
1518
1519 #---------- tag format handling ----------
1520
1521 sub access_cfg_tagformats () {
1522     split /\,/, access_cfg('dgit-tag-format');
1523 }
1524
1525 sub access_cfg_tagformats_can_splitbrain () {
1526     my %y = map { $_ => 1 } access_cfg_tagformats;
1527     foreach my $needtf (qw(new maint)) {
1528         next if $y{$needtf};
1529         return 0;
1530     }
1531     return 1;
1532 }
1533
1534 sub need_tagformat ($$) {
1535     my ($fmt, $why) = @_;
1536     fail "need to use tag format $fmt ($why) but also need".
1537         " to use tag format $tagformat_want->[0] ($tagformat_want->[1])".
1538         " - no way to proceed"
1539         if $tagformat_want && $tagformat_want->[0] ne $fmt;
1540     $tagformat_want = [$fmt, $why, $tagformat_want->[2] // 0];
1541 }
1542
1543 sub select_tagformat () {
1544     # sets $tagformatfn
1545     return if $tagformatfn && !$tagformat_want;
1546     die 'bug' if $tagformatfn && $tagformat_want;
1547     # ... $tagformat_want assigned after previous select_tagformat
1548
1549     my (@supported) = grep { $_ =~ m/^(?:old|new)$/ } access_cfg_tagformats();
1550     printdebug "select_tagformat supported @supported\n";
1551
1552     $tagformat_want //= [ $supported[0], "distro access configuration", 0 ];
1553     printdebug "select_tagformat specified @$tagformat_want\n";
1554
1555     my ($fmt,$why,$override) = @$tagformat_want;
1556
1557     fail "target distro supports tag formats @supported".
1558         " but have to use $fmt ($why)"
1559         unless $override
1560             or grep { $_ eq $fmt } @supported;
1561
1562     $tagformat_want = undef;
1563     $tagformat = $fmt;
1564     $tagformatfn = ${*::}{"debiantag_$fmt"};
1565
1566     fail "trying to use unknown tag format \`$fmt' ($why) !"
1567         unless $tagformatfn;
1568 }
1569
1570 #---------- archive query entrypoints and rest of program ----------
1571
1572 sub canonicalise_suite () {
1573     return if defined $csuite;
1574     fail "cannot operate on $isuite suite" if $isuite eq 'UNRELEASED';
1575     $csuite = archive_query('canonicalise_suite');
1576     if ($isuite ne $csuite) {
1577         progress "canonical suite name for $isuite is $csuite";
1578     } else {
1579         progress "canonical suite name is $csuite";
1580     }
1581 }
1582
1583 sub get_archive_dsc () {
1584     canonicalise_suite();
1585     my @vsns = archive_query('archive_query');
1586     foreach my $vinfo (@vsns) {
1587         my ($vsn,$vsn_dscurl,$digester,$digest) = @$vinfo;
1588         $dscurl = $vsn_dscurl;
1589         $dscdata = url_get($dscurl);
1590         if (!$dscdata) {
1591             $skew_warning_vsn = $vsn if !defined $skew_warning_vsn;
1592             next;
1593         }
1594         if ($digester) {
1595             $digester->reset();
1596             $digester->add($dscdata);
1597             my $got = $digester->hexdigest();
1598             $got eq $digest or
1599                 fail "$dscurl has hash $got but".
1600                     " archive told us to expect $digest";
1601         }
1602         parse_dscdata();
1603         my $fmt = getfield $dsc, 'Format';
1604         $format_ok{$fmt} or forceable_fail [qw(unsupported-source-format)],
1605             "unsupported source format $fmt, sorry";
1606
1607         $dsc_checked = !!$digester;
1608         printdebug "get_archive_dsc: Version ".(getfield $dsc, 'Version')."\n";
1609         return;
1610     }
1611     $dsc = undef;
1612     printdebug "get_archive_dsc: nothing in archive, returning undef\n";
1613 }
1614
1615 sub check_for_git ();
1616 sub check_for_git () {
1617     # returns 0 or 1
1618     my $how = access_cfg('git-check');
1619     if ($how eq 'ssh-cmd') {
1620         my @cmd =
1621             (access_cfg_ssh, access_gituserhost(),
1622              access_runeinfo("git-check $package").
1623              " set -e; cd ".access_cfg('git-path').";".
1624              " if test -d $package.git; then echo 1; else echo 0; fi");
1625         my $r= cmdoutput @cmd;
1626         if (defined $r and $r =~ m/^divert (\w+)$/) {
1627             my $divert=$1;
1628             my ($usedistro,) = access_distros();
1629             # NB that if we are pushing, $usedistro will be $distro/push
1630             $instead_distro= cfg("dgit-distro.$usedistro.diverts.$divert");
1631             $instead_distro =~ s{^/}{ access_basedistro()."/" }e;
1632             progress "diverting to $divert (using config for $instead_distro)";
1633             return check_for_git();
1634         }
1635         failedcmd @cmd unless defined $r and $r =~ m/^[01]$/;
1636         return $r+0;
1637     } elsif ($how eq 'url') {
1638         my $prefix = access_cfg('git-check-url','git-url');
1639         my $suffix = access_cfg('git-check-suffix','git-suffix',
1640                                 'RETURN-UNDEF') // '.git';
1641         my $url = "$prefix/$package$suffix";
1642         my @cmd = (@curl, qw(-sS -I), $url);
1643         my $result = cmdoutput @cmd;
1644         $result =~ s/^\S+ 200 .*\n\r?\n//;
1645         # curl -sS -I with https_proxy prints
1646         # HTTP/1.0 200 Connection established
1647         $result =~ m/^\S+ (404|200) /s or
1648             fail "unexpected results from git check query - ".
1649                 Dumper($prefix, $result);
1650         my $code = $1;
1651         if ($code eq '404') {
1652             return 0;
1653         } elsif ($code eq '200') {
1654             return 1;
1655         } else {
1656             die;
1657         }
1658     } elsif ($how eq 'true') {
1659         return 1;
1660     } elsif ($how eq 'false') {
1661         return 0;
1662     } else {
1663         badcfg "unknown git-check \`$how'";
1664     }
1665 }
1666
1667 sub create_remote_git_repo () {
1668     my $how = access_cfg('git-create');
1669     if ($how eq 'ssh-cmd') {
1670         runcmd_ordryrun
1671             (access_cfg_ssh, access_gituserhost(),
1672              access_runeinfo("git-create $package").
1673              "set -e; cd ".access_cfg('git-path').";".
1674              " cp -a _template $package.git");
1675     } elsif ($how eq 'true') {
1676         # nothing to do
1677     } else {
1678         badcfg "unknown git-create \`$how'";
1679     }
1680 }
1681
1682 our ($dsc_hash,$lastpush_mergeinput);
1683 our ($dsc_distro, $dsc_hint_tag, $dsc_hint_url);
1684
1685 our $ud = '.git/dgit/unpack';
1686
1687 sub prep_ud (;$) {
1688     my ($d) = @_;
1689     $d //= $ud;
1690     rmtree($d);
1691     mkpath '.git/dgit';
1692     mkdir $d or die $!;
1693 }
1694
1695 sub mktree_in_ud_here () {
1696     runcmd qw(git init -q);
1697     runcmd qw(git config gc.auto 0);
1698     rmtree('.git/objects');
1699     symlink '../../../../objects','.git/objects' or die $!;
1700 }
1701
1702 sub git_write_tree () {
1703     my $tree = cmdoutput @git, qw(write-tree);
1704     $tree =~ m/^\w+$/ or die "$tree ?";
1705     return $tree;
1706 }
1707
1708 sub git_add_write_tree () {
1709     runcmd @git, qw(add -Af .);
1710     return git_write_tree();
1711 }
1712
1713 sub remove_stray_gits ($) {
1714     my ($what) = @_;
1715     my @gitscmd = qw(find -name .git -prune -print0);
1716     debugcmd "|",@gitscmd;
1717     open GITS, "-|", @gitscmd or die $!;
1718     {
1719         local $/="\0";
1720         while (<GITS>) {
1721             chomp or die;
1722             print STDERR "$us: warning: removing from $what: ",
1723                 (messagequote $_), "\n";
1724             rmtree $_;
1725         }
1726     }
1727     $!=0; $?=0; close GITS or failedcmd @gitscmd;
1728 }
1729
1730 sub mktree_in_ud_from_only_subdir ($;$) {
1731     my ($what,$raw) = @_;
1732
1733     # changes into the subdir
1734     my (@dirs) = <*/.>;
1735     die "expected one subdir but found @dirs ?" unless @dirs==1;
1736     $dirs[0] =~ m#^([^/]+)/\.$# or die;
1737     my $dir = $1;
1738     changedir $dir;
1739
1740     remove_stray_gits($what);
1741     mktree_in_ud_here();
1742     if (!$raw) {
1743         my ($format, $fopts) = get_source_format();
1744         if (madformat($format)) {
1745             rmtree '.pc';
1746         }
1747     }
1748
1749     my $tree=git_add_write_tree();
1750     return ($tree,$dir);
1751 }
1752
1753 our @files_csum_info_fields =
1754     (['Checksums-Sha256','Digest::SHA', 'new(256)', 'sha256sum'],
1755      ['Checksums-Sha1',  'Digest::SHA', 'new(1)',   'sha1sum'],
1756      ['Files',           'Digest::MD5', 'new()',    'md5sum']);
1757
1758 sub dsc_files_info () {
1759     foreach my $csumi (@files_csum_info_fields) {
1760         my ($fname, $module, $method) = @$csumi;
1761         my $field = $dsc->{$fname};
1762         next unless defined $field;
1763         eval "use $module; 1;" or die $@;
1764         my @out;
1765         foreach (split /\n/, $field) {
1766             next unless m/\S/;
1767             m/^(\w+) (\d+) (\S+)$/ or
1768                 fail "could not parse .dsc $fname line \`$_'";
1769             my $digester = eval "$module"."->$method;" or die $@;
1770             push @out, {
1771                 Hash => $1,
1772                 Bytes => $2,
1773                 Filename => $3,
1774                 Digester => $digester,
1775             };
1776         }
1777         return @out;
1778     }
1779     fail "missing any supported Checksums-* or Files field in ".
1780         $dsc->get_option('name');
1781 }
1782
1783 sub dsc_files () {
1784     map { $_->{Filename} } dsc_files_info();
1785 }
1786
1787 sub files_compare_inputs (@) {
1788     my $inputs = \@_;
1789     my %record;
1790     my %fchecked;
1791
1792     my $showinputs = sub {
1793         return join "; ", map { $_->get_option('name') } @$inputs;
1794     };
1795
1796     foreach my $in (@$inputs) {
1797         my $expected_files;
1798         my $in_name = $in->get_option('name');
1799
1800         printdebug "files_compare_inputs $in_name\n";
1801
1802         foreach my $csumi (@files_csum_info_fields) {
1803             my ($fname) = @$csumi;
1804             printdebug "files_compare_inputs $in_name $fname\n";
1805
1806             my $field = $in->{$fname};
1807             next unless defined $field;
1808
1809             my @files;
1810             foreach (split /\n/, $field) {
1811                 next unless m/\S/;
1812
1813                 my ($info, $f) = m/^(\w+ \d+) (?:\S+ \S+ )?(\S+)$/ or
1814                     fail "could not parse $in_name $fname line \`$_'";
1815
1816                 printdebug "files_compare_inputs $in_name $fname $f\n";
1817
1818                 push @files, $f;
1819
1820                 my $re = \ $record{$f}{$fname};
1821                 if (defined $$re) {
1822                     $fchecked{$f}{$in_name} = 1;
1823                     $$re eq $info or
1824                         fail "hash or size of $f varies in $fname fields".
1825                         " (between: ".$showinputs->().")";
1826                 } else {
1827                     $$re = $info;
1828                 }
1829             }
1830             @files = sort @files;
1831             $expected_files //= \@files;
1832             "@$expected_files" eq "@files" or
1833                 fail "file list in $in_name varies between hash fields!";
1834         }
1835         $expected_files or
1836             fail "$in_name has no files list field(s)";
1837     }
1838     printdebug "files_compare_inputs ".Dumper(\%fchecked, \%record)
1839         if $debuglevel>=2;
1840
1841     grep { keys %$_ == @$inputs-1 } values %fchecked
1842         or fail "no file appears in all file lists".
1843         " (looked in: ".$showinputs->().")";
1844 }
1845
1846 sub is_orig_file_in_dsc ($$) {
1847     my ($f, $dsc_files_info) = @_;
1848     return 0 if @$dsc_files_info <= 1;
1849     # One file means no origs, and the filename doesn't have a "what
1850     # part of dsc" component.  (Consider versions ending `.orig'.)
1851     return 0 unless $f =~ m/\.$orig_f_tail_re$/o;
1852     return 1;
1853 }
1854
1855 sub is_orig_file_of_vsn ($$) {
1856     my ($f, $upstreamvsn) = @_;
1857     my $base = srcfn $upstreamvsn, '';
1858     return 0 unless $f =~ m/^\Q$base\E\.$orig_f_tail_re$/;
1859     return 1;
1860 }
1861
1862 sub changes_update_origs_from_dsc ($$$$) {
1863     my ($dsc, $changes, $upstreamvsn, $changesfile) = @_;
1864     my %changes_f;
1865     printdebug "checking origs needed ($upstreamvsn)...\n";
1866     $_ = getfield $changes, 'Files';
1867     m/^\w+ \d+ (\S+ \S+) \S+$/m or
1868         fail "cannot find section/priority from .changes Files field";
1869     my $placementinfo = $1;
1870     my %changed;
1871     printdebug "checking origs needed placement '$placementinfo'...\n";
1872     foreach my $l (split /\n/, getfield $dsc, 'Files') {
1873         $l =~ m/\S+$/ or next;
1874         my $file = $&;
1875         printdebug "origs $file | $l\n";
1876         next unless is_orig_file_of_vsn $file, $upstreamvsn;
1877         printdebug "origs $file is_orig\n";
1878         my $have = archive_query('file_in_archive', $file);
1879         if (!defined $have) {
1880             print STDERR <<END;
1881 archive does not support .orig check; hope you used --ch:--sa/-sd if needed
1882 END
1883             return;
1884         }
1885         my $found_same = 0;
1886         my @found_differ;
1887         printdebug "origs $file \$#\$have=$#$have\n";
1888         foreach my $h (@$have) {
1889             my $same = 0;
1890             my @differ;
1891             foreach my $csumi (@files_csum_info_fields) {
1892                 my ($fname, $module, $method, $archivefield) = @$csumi;
1893                 next unless defined $h->{$archivefield};
1894                 $_ = $dsc->{$fname};
1895                 next unless defined;
1896                 m/^(\w+) .* \Q$file\E$/m or
1897                     fail ".dsc $fname missing entry for $file";
1898                 if ($h->{$archivefield} eq $1) {
1899                     $same++;
1900                 } else {
1901                     push @differ,
1902  "$archivefield: $h->{$archivefield} (archive) != $1 (local .dsc)";
1903                 }
1904             }
1905             die "$file ".Dumper($h)." ?!" if $same && @differ;
1906             $found_same++
1907                 if $same;
1908             push @found_differ, "archive $h->{filename}: ".join "; ", @differ
1909                 if @differ;
1910         }
1911         printdebug "origs $file f.same=$found_same".
1912             " #f._differ=$#found_differ\n";
1913         if (@found_differ && !$found_same) {
1914             fail join "\n",
1915                 "archive contains $file with different checksum",
1916                 @found_differ;
1917         }
1918         # Now we edit the changes file to add or remove it
1919         foreach my $csumi (@files_csum_info_fields) {
1920             my ($fname, $module, $method, $archivefield) = @$csumi;
1921             next unless defined $changes->{$fname};
1922             if ($found_same) {
1923                 # in archive, delete from .changes if it's there
1924                 $changed{$file} = "removed" if
1925                     $changes->{$fname} =~ s/^.* \Q$file\E$(?:)\n//m;
1926             } elsif ($changes->{$fname} =~ m/^.* \Q$file\E$(?:)\n/m) {
1927                 # not in archive, but it's here in the .changes
1928             } else {
1929                 my $dsc_data = getfield $dsc, $fname;
1930                 $dsc_data =~ m/^(.* \Q$file\E$)\n/m or die "$dsc_data $file ?";
1931                 my $extra = $1;
1932                 $extra =~ s/ \d+ /$&$placementinfo /
1933                     or die "$fname $extra >$dsc_data< ?"
1934                     if $fname eq 'Files';
1935                 $changes->{$fname} .= "\n". $extra;
1936                 $changed{$file} = "added";
1937             }
1938         }
1939     }
1940     if (%changed) {
1941         foreach my $file (keys %changed) {
1942             progress sprintf
1943                 "edited .changes for archive .orig contents: %s %s",
1944                 $changed{$file}, $file;
1945         }
1946         my $chtmp = "$changesfile.tmp";
1947         $changes->save($chtmp);
1948         if (act_local()) {
1949             rename $chtmp,$changesfile or die "$changesfile $!";
1950         } else {
1951             progress "[new .changes left in $changesfile]";
1952         }
1953     } else {
1954         progress "$changesfile already has appropriate .orig(s) (if any)";
1955     }
1956 }
1957
1958 sub make_commit ($) {
1959     my ($file) = @_;
1960     return cmdoutput @git, qw(hash-object -w -t commit), $file;
1961 }
1962
1963 sub make_commit_text ($) {
1964     my ($text) = @_;
1965     my ($out, $in);
1966     my @cmd = (@git, qw(hash-object -w -t commit --stdin));
1967     debugcmd "|",@cmd;
1968     print Dumper($text) if $debuglevel > 1;
1969     my $child = open2($out, $in, @cmd) or die $!;
1970     my $h;
1971     eval {
1972         print $in $text or die $!;
1973         close $in or die $!;
1974         $h = <$out>;
1975         $h =~ m/^\w+$/ or die;
1976         $h = $&;
1977         printdebug "=> $h\n";
1978     };
1979     close $out;
1980     waitpid $child, 0 == $child or die "$child $!";
1981     $? and failedcmd @cmd;
1982     return $h;
1983 }
1984
1985 sub clogp_authline ($) {
1986     my ($clogp) = @_;
1987     my $author = getfield $clogp, 'Maintainer';
1988     $author =~ s#,.*##ms;
1989     my $date = cmdoutput qw(date), '+%s %z', qw(-d), getfield($clogp,'Date');
1990     my $authline = "$author $date";
1991     $authline =~ m/$git_authline_re/o or
1992         fail "unexpected commit author line format \`$authline'".
1993         " (was generated from changelog Maintainer field)";
1994     return ($1,$2,$3) if wantarray;
1995     return $authline;
1996 }
1997
1998 sub vendor_patches_distro ($$) {
1999     my ($checkdistro, $what) = @_;
2000     return unless defined $checkdistro;
2001
2002     my $series = "debian/patches/\L$checkdistro\E.series";
2003     printdebug "checking for vendor-specific $series ($what)\n";
2004
2005     if (!open SERIES, "<", $series) {
2006         die "$series $!" unless $!==ENOENT;
2007         return;
2008     }
2009     while (<SERIES>) {
2010         next unless m/\S/;
2011         next if m/^\s+\#/;
2012
2013         print STDERR <<END;
2014
2015 Unfortunately, this source package uses a feature of dpkg-source where
2016 the same source package unpacks to different source code on different
2017 distros.  dgit cannot safely operate on such packages on affected
2018 distros, because the meaning of source packages is not stable.
2019
2020 Please ask the distro/maintainer to remove the distro-specific series
2021 files and use a different technique (if necessary, uploading actually
2022 different packages, if different distros are supposed to have
2023 different code).
2024
2025 END
2026         fail "Found active distro-specific series file for".
2027             " $checkdistro ($what): $series, cannot continue";
2028     }
2029     die "$series $!" if SERIES->error;
2030     close SERIES;
2031 }
2032
2033 sub check_for_vendor_patches () {
2034     # This dpkg-source feature doesn't seem to be documented anywhere!
2035     # But it can be found in the changelog (reformatted):
2036
2037     #   commit  4fa01b70df1dc4458daee306cfa1f987b69da58c
2038     #   Author: Raphael Hertzog <hertzog@debian.org>
2039     #   Date: Sun  Oct  3  09:36:48  2010 +0200
2040
2041     #   dpkg-source: correctly create .pc/.quilt_series with alternate
2042     #   series files
2043     #
2044     #   If you have debian/patches/ubuntu.series and you were
2045     #   unpacking the source package on ubuntu, quilt was still
2046     #   directed to debian/patches/series instead of
2047     #   debian/patches/ubuntu.series.
2048     #
2049     #   debian/changelog                        |    3 +++
2050     #   scripts/Dpkg/Source/Package/V3/quilt.pm |    4 +++-
2051     #   2 files changed, 6 insertions(+), 1 deletion(-)
2052
2053     use Dpkg::Vendor;
2054     vendor_patches_distro($ENV{DEB_VENDOR}, "DEB_VENDOR");
2055     vendor_patches_distro(Dpkg::Vendor::get_current_vendor(),
2056                          "Dpkg::Vendor \`current vendor'");
2057     vendor_patches_distro(access_basedistro(),
2058                           "(base) distro being accessed");
2059     vendor_patches_distro(access_nomdistro(),
2060                           "(nominal) distro being accessed");
2061 }
2062
2063 sub generate_commits_from_dsc () {
2064     # See big comment in fetch_from_archive, below.
2065     # See also README.dsc-import.
2066     prep_ud();
2067     changedir $ud;
2068
2069     my @dfi = dsc_files_info();
2070     foreach my $fi (@dfi) {
2071         my $f = $fi->{Filename};
2072         die "$f ?" if $f =~ m#/|^\.|\.dsc$|\.tmp$#;
2073
2074         printdebug "considering linking $f: ";
2075
2076         link_ltarget "../../../../$f", $f
2077             or ((printdebug "($!) "), 0)
2078             or $!==&ENOENT
2079             or die "$f $!";
2080
2081         printdebug "linked.\n";
2082
2083         complete_file_from_dsc('.', $fi)
2084             or next;
2085
2086         link $f, "../../../../$f"
2087             or $!==&EEXIST
2088             or die "$f $!";
2089     }
2090
2091     # We unpack and record the orig tarballs first, so that we only
2092     # need disk space for one private copy of the unpacked source.
2093     # But we can't make them into commits until we have the metadata
2094     # from the debian/changelog, so we record the tree objects now and
2095     # make them into commits later.
2096     my @tartrees;
2097     my $upstreamv = upstreamversion $dsc->{version};
2098     my $orig_f_base = srcfn $upstreamv, '';
2099
2100     foreach my $fi (@dfi) {
2101         # We actually import, and record as a commit, every tarball
2102         # (unless there is only one file, in which case there seems
2103         # little point.
2104
2105         my $f = $fi->{Filename};
2106         printdebug "import considering $f ";
2107         (printdebug "only one dfi\n"), next if @dfi == 1;
2108         (printdebug "not tar\n"), next unless $f =~ m/\.tar(\.\w+)?$/;
2109         (printdebug "signature\n"), next if $f =~ m/$orig_f_sig_re$/o;
2110         my $compr_ext = $1;
2111
2112         my ($orig_f_part) =
2113             $f =~ m/^\Q$orig_f_base\E\.([^._]+)?\.tar(?:\.\w+)?$/;
2114
2115         printdebug "Y ", (join ' ', map { $_//"(none)" }
2116                           $compr_ext, $orig_f_part
2117                          ), "\n";
2118
2119         my $input = new IO::File $f, '<' or die "$f $!";
2120         my $compr_pid;
2121         my @compr_cmd;
2122
2123         if (defined $compr_ext) {
2124             my $cname =
2125                 Dpkg::Compression::compression_guess_from_filename $f;
2126             fail "Dpkg::Compression cannot handle file $f in source package"
2127                 if defined $compr_ext && !defined $cname;
2128             my $compr_proc =
2129                 new Dpkg::Compression::Process compression => $cname;
2130             my @compr_cmd = $compr_proc->get_uncompress_cmdline();
2131             my $compr_fh = new IO::Handle;
2132             my $compr_pid = open $compr_fh, "-|" // die $!;
2133             if (!$compr_pid) {
2134                 open STDIN, "<&", $input or die $!;
2135                 exec @compr_cmd;
2136                 die "dgit (child): exec $compr_cmd[0]: $!\n";
2137             }
2138             $input = $compr_fh;
2139         }
2140
2141         rmtree "_unpack-tar";
2142         mkdir "_unpack-tar" or die $!;
2143         my @tarcmd = qw(tar -x -f -
2144                         --no-same-owner --no-same-permissions
2145                         --no-acls --no-xattrs --no-selinux);
2146         my $tar_pid = fork // die $!;
2147         if (!$tar_pid) {
2148             chdir "_unpack-tar" or die $!;
2149             open STDIN, "<&", $input or die $!;
2150             exec @tarcmd;
2151             die "dgit (child): exec $tarcmd[0]: $!";
2152         }
2153         $!=0; (waitpid $tar_pid, 0) == $tar_pid or die $!;
2154         !$? or failedcmd @tarcmd;
2155
2156         close $input or
2157             (@compr_cmd ? failedcmd @compr_cmd
2158              : die $!);
2159         # finally, we have the results in "tarball", but maybe
2160         # with the wrong permissions
2161
2162         runcmd qw(chmod -R +rwX _unpack-tar);
2163         changedir "_unpack-tar";
2164         remove_stray_gits($f);
2165         mktree_in_ud_here();
2166
2167         my ($tree) = git_add_write_tree();
2168         my $tentries = cmdoutput @git, qw(ls-tree -z), $tree;
2169         if ($tentries =~ m/^\d+ tree (\w+)\t[^\000]+\000$/s) {
2170             $tree = $1;
2171             printdebug "one subtree $1\n";
2172         } else {
2173             printdebug "multiple subtrees\n";
2174         }
2175         changedir "..";
2176         rmtree "_unpack-tar";
2177
2178         my $ent = [ $f, $tree ];
2179         push @tartrees, {
2180             Orig => !!$orig_f_part,
2181             Sort => (!$orig_f_part         ? 2 :
2182                      $orig_f_part =~ m/-/g ? 1 :
2183                                              0),
2184             F => $f,
2185             Tree => $tree,
2186         };
2187     }
2188
2189     @tartrees = sort {
2190         # put any without "_" first (spec is not clear whether files
2191         # are always in the usual order).  Tarballs without "_" are
2192         # the main orig or the debian tarball.
2193         $a->{Sort} <=> $b->{Sort} or
2194         $a->{F}    cmp $b->{F}
2195     } @tartrees;
2196
2197     my $any_orig = grep { $_->{Orig} } @tartrees;
2198
2199     my $dscfn = "$package.dsc";
2200
2201     my $treeimporthow = 'package';
2202
2203     open D, ">", $dscfn or die "$dscfn: $!";
2204     print D $dscdata or die "$dscfn: $!";
2205     close D or die "$dscfn: $!";
2206     my @cmd = qw(dpkg-source);
2207     push @cmd, '--no-check' if $dsc_checked;
2208     if (madformat $dsc->{format}) {
2209         push @cmd, '--skip-patches';
2210         $treeimporthow = 'unpatched';
2211     }
2212     push @cmd, qw(-x --), $dscfn;
2213     runcmd @cmd;
2214
2215     my ($tree,$dir) = mktree_in_ud_from_only_subdir("source package");
2216     if (madformat $dsc->{format}) {
2217         check_for_vendor_patches();
2218     }
2219
2220     my $dappliedtree;
2221     if (madformat $dsc->{format}) {
2222         my @pcmd = qw(dpkg-source --before-build .);
2223         runcmd shell_cmd 'exec >/dev/null', @pcmd;
2224         rmtree '.pc';
2225         $dappliedtree = git_add_write_tree();
2226     }
2227
2228     my @clogcmd = qw(dpkg-parsechangelog --format rfc822 --all);
2229     debugcmd "|",@clogcmd;
2230     open CLOGS, "-|", @clogcmd or die $!;
2231
2232     my $clogp;
2233     my $r1clogp;
2234
2235     printdebug "import clog search...\n";
2236
2237     for (;;) {
2238         my $stanzatext = do { local $/=""; <CLOGS>; };
2239         printdebug "import clogp ".Dumper($stanzatext) if $debuglevel>1;
2240         last if !defined $stanzatext;
2241
2242         my $desc = "package changelog, entry no.$.";
2243         open my $stanzafh, "<", \$stanzatext or die;
2244         my $thisstanza = parsecontrolfh $stanzafh, $desc, 1;
2245         $clogp //= $thisstanza;
2246
2247         printdebug "import clog $thisstanza->{version} $desc...\n";
2248
2249         last if !$any_orig; # we don't need $r1clogp
2250
2251         # We look for the first (most recent) changelog entry whose
2252         # version number is lower than the upstream version of this
2253         # package.  Then the last (least recent) previous changelog
2254         # entry is treated as the one which introduced this upstream
2255         # version and used for the synthetic commits for the upstream
2256         # tarballs.
2257
2258         # One might think that a more sophisticated algorithm would be
2259         # necessary.  But: we do not want to scan the whole changelog
2260         # file.  Stopping when we see an earlier version, which
2261         # necessarily then is an earlier upstream version, is the only
2262         # realistic way to do that.  Then, either the earliest
2263         # changelog entry we have seen so far is indeed the earliest
2264         # upload of this upstream version; or there are only changelog
2265         # entries relating to later upstream versions (which is not
2266         # possible unless the changelog and .dsc disagree about the
2267         # version).  Then it remains to choose between the physically
2268         # last entry in the file, and the one with the lowest version
2269         # number.  If these are not the same, we guess that the
2270         # versions were created in a non-monotic order rather than
2271         # that the changelog entries have been misordered.
2272
2273         printdebug "import clog $thisstanza->{version} vs $upstreamv...\n";
2274
2275         last if version_compare($thisstanza->{version}, $upstreamv) < 0;
2276         $r1clogp = $thisstanza;
2277
2278         printdebug "import clog $r1clogp->{version} becomes r1\n";
2279     }
2280     die $! if CLOGS->error;
2281     close CLOGS or $?==SIGPIPE or failedcmd @clogcmd;
2282
2283     $clogp or fail "package changelog has no entries!";
2284
2285     my $authline = clogp_authline $clogp;
2286     my $changes = getfield $clogp, 'Changes';
2287     my $cversion = getfield $clogp, 'Version';
2288
2289     if (@tartrees) {
2290         $r1clogp //= $clogp; # maybe there's only one entry;
2291         my $r1authline = clogp_authline $r1clogp;
2292         # Strictly, r1authline might now be wrong if it's going to be
2293         # unused because !$any_orig.  Whatever.
2294
2295         printdebug "import tartrees authline   $authline\n";
2296         printdebug "import tartrees r1authline $r1authline\n";
2297
2298         foreach my $tt (@tartrees) {
2299             printdebug "import tartree $tt->{F} $tt->{Tree}\n";
2300
2301             $tt->{Commit} = make_commit_text($tt->{Orig} ? <<END_O : <<END_T);
2302 tree $tt->{Tree}
2303 author $r1authline
2304 committer $r1authline
2305
2306 Import $tt->{F}
2307
2308 [dgit import orig $tt->{F}]
2309 END_O
2310 tree $tt->{Tree}
2311 author $authline
2312 committer $authline
2313
2314 Import $tt->{F}
2315
2316 [dgit import tarball $package $cversion $tt->{F}]
2317 END_T
2318         }
2319     }
2320
2321     printdebug "import main commit\n";
2322
2323     open C, ">../commit.tmp" or die $!;
2324     print C <<END or die $!;
2325 tree $tree
2326 END
2327     print C <<END or die $! foreach @tartrees;
2328 parent $_->{Commit}
2329 END
2330     print C <<END or die $!;
2331 author $authline
2332 committer $authline
2333
2334 $changes
2335
2336 [dgit import $treeimporthow $package $cversion]
2337 END
2338
2339     close C or die $!;
2340     my $rawimport_hash = make_commit qw(../commit.tmp);
2341
2342     if (madformat $dsc->{format}) {
2343         printdebug "import apply patches...\n";
2344
2345         # regularise the state of the working tree so that
2346         # the checkout of $rawimport_hash works nicely.
2347         my $dappliedcommit = make_commit_text(<<END);
2348 tree $dappliedtree
2349 author $authline
2350 committer $authline
2351
2352 [dgit dummy commit]
2353 END
2354         runcmd @git, qw(checkout -q -b dapplied), $dappliedcommit;
2355
2356         runcmd @git, qw(checkout -q -b unpa), $rawimport_hash;
2357
2358         # We need the answers to be reproducible
2359         my @authline = clogp_authline($clogp);
2360         local $ENV{GIT_COMMITTER_NAME} =  $authline[0];
2361         local $ENV{GIT_COMMITTER_EMAIL} = $authline[1];
2362         local $ENV{GIT_COMMITTER_DATE} =  $authline[2];
2363         local $ENV{GIT_AUTHOR_NAME} =  $authline[0];
2364         local $ENV{GIT_AUTHOR_EMAIL} = $authline[1];
2365         local $ENV{GIT_AUTHOR_DATE} =  $authline[2];
2366
2367         my $path = $ENV{PATH} or die;
2368
2369         foreach my $use_absurd (qw(0 1)) {
2370             runcmd @git, qw(checkout -q unpa);
2371             runcmd @git, qw(update-ref -d refs/heads/patch-queue/unpa);
2372             local $ENV{PATH} = $path;
2373             if ($use_absurd) {
2374                 chomp $@;
2375                 progress "warning: $@";
2376                 $path = "$absurdity:$path";
2377                 progress "$us: trying slow absurd-git-apply...";
2378                 rename "../../gbp-pq-output","../../gbp-pq-output.0"
2379                     or $!==ENOENT
2380                     or die $!;
2381             }
2382             eval {
2383                 die "forbid absurd git-apply\n" if $use_absurd
2384                     && forceing [qw(import-gitapply-no-absurd)];
2385                 die "only absurd git-apply!\n" if !$use_absurd
2386                     && forceing [qw(import-gitapply-absurd)];
2387
2388                 local $ENV{DGIT_ABSURD_DEBUG} = $debuglevel if $use_absurd;
2389                 local $ENV{PATH} = $path                    if $use_absurd;
2390
2391                 my @showcmd = (gbp_pq, qw(import));
2392                 my @realcmd = shell_cmd
2393                     'exec >/dev/null 2>>../../gbp-pq-output', @showcmd;
2394                 debugcmd "+",@realcmd;
2395                 if (system @realcmd) {
2396                     die +(shellquote @showcmd).
2397                         " failed: ".
2398                         failedcmd_waitstatus()."\n";
2399                 }
2400
2401                 my $gapplied = git_rev_parse('HEAD');
2402                 my $gappliedtree = cmdoutput @git, qw(rev-parse HEAD:);
2403                 $gappliedtree eq $dappliedtree or
2404                     fail <<END;
2405 gbp-pq import and dpkg-source disagree!
2406  gbp-pq import gave commit $gapplied
2407  gbp-pq import gave tree $gappliedtree
2408  dpkg-source --before-build gave tree $dappliedtree
2409 END
2410                 $rawimport_hash = $gapplied;
2411             };
2412             last unless $@;
2413         }
2414         if ($@) {
2415             { local $@; eval { runcmd qw(cat ../../gbp-pq-output); }; }
2416             die $@;
2417         }
2418     }
2419
2420     progress "synthesised git commit from .dsc $cversion";
2421
2422     my $rawimport_mergeinput = {
2423         Commit => $rawimport_hash,
2424         Info => "Import of source package",
2425     };
2426     my @output = ($rawimport_mergeinput);
2427
2428     if ($lastpush_mergeinput) {
2429         my $oldclogp = mergeinfo_getclogp($lastpush_mergeinput);
2430         my $oversion = getfield $oldclogp, 'Version';
2431         my $vcmp =
2432             version_compare($oversion, $cversion);
2433         if ($vcmp < 0) {
2434             @output = ($rawimport_mergeinput, $lastpush_mergeinput,
2435                 { Message => <<END, ReverseParents => 1 });
2436 Record $package ($cversion) in archive suite $csuite
2437 END
2438         } elsif ($vcmp > 0) {
2439             print STDERR <<END or die $!;
2440
2441 Version actually in archive:   $cversion (older)
2442 Last version pushed with dgit: $oversion (newer or same)
2443 $later_warning_msg
2444 END
2445             @output = $lastpush_mergeinput;
2446         } else {
2447             # Same version.  Use what's in the server git branch,
2448             # discarding our own import.  (This could happen if the
2449             # server automatically imports all packages into git.)
2450             @output = $lastpush_mergeinput;
2451         }
2452     }
2453     changedir '../../../..';
2454     rmtree($ud);
2455     return @output;
2456 }
2457
2458 sub complete_file_from_dsc ($$) {
2459     our ($dstdir, $fi) = @_;
2460     # Ensures that we have, in $dir, the file $fi, with the correct
2461     # contents.  (Downloading it from alongside $dscurl if necessary.)
2462
2463     my $f = $fi->{Filename};
2464     my $tf = "$dstdir/$f";
2465     my $downloaded = 0;
2466
2467     if (stat_exists $tf) {
2468         progress "using existing $f";
2469     } else {
2470         printdebug "$tf does not exist, need to fetch\n";
2471         my $furl = $dscurl;
2472         $furl =~ s{/[^/]+$}{};
2473         $furl .= "/$f";
2474         die "$f ?" unless $f =~ m/^\Q${package}\E_/;
2475         die "$f ?" if $f =~ m#/#;
2476         runcmd_ordryrun_local @curl,qw(-f -o),$tf,'--',"$furl";
2477         return 0 if !act_local();
2478         $downloaded = 1;
2479     }
2480
2481     open F, "<", "$tf" or die "$tf: $!";
2482     $fi->{Digester}->reset();
2483     $fi->{Digester}->addfile(*F);
2484     F->error and die $!;
2485     my $got = $fi->{Digester}->hexdigest();
2486     $got eq $fi->{Hash} or
2487         fail "file $f has hash $got but .dsc".
2488             " demands hash $fi->{Hash} ".
2489             ($downloaded ? "(got wrong file from archive!)"
2490              : "(perhaps you should delete this file?)");
2491
2492     return 1;
2493 }
2494
2495 sub ensure_we_have_orig () {
2496     my @dfi = dsc_files_info();
2497     foreach my $fi (@dfi) {
2498         my $f = $fi->{Filename};
2499         next unless is_orig_file_in_dsc($f, \@dfi);
2500         complete_file_from_dsc('..', $fi)
2501             or next;
2502     }
2503 }
2504
2505 #---------- git fetch ----------
2506
2507 sub lrfetchrefs () { return "refs/dgit-fetch/".access_basedistro(); }
2508 sub lrfetchref () { return lrfetchrefs.'/'.server_branch($csuite); }
2509
2510 # We fetch some parts of lrfetchrefs/*.  Ideally we delete these
2511 # locally fetched refs because they have unhelpful names and clutter
2512 # up gitk etc.  So we track whether we have "used up" head ref (ie,
2513 # whether we have made another local ref which refers to this object).
2514 #
2515 # (If we deleted them unconditionally, then we might end up
2516 # re-fetching the same git objects each time dgit fetch was run.)
2517 #
2518 # So, leach use of lrfetchrefs needs to be accompanied by arrangements
2519 # in git_fetch_us to fetch the refs in question, and possibly a call
2520 # to lrfetchref_used.
2521
2522 our (%lrfetchrefs_f, %lrfetchrefs_d);
2523 # $lrfetchrefs_X{lrfetchrefs."/heads/whatever"} = $objid
2524
2525 sub lrfetchref_used ($) {
2526     my ($fullrefname) = @_;
2527     my $objid = $lrfetchrefs_f{$fullrefname};
2528     $lrfetchrefs_d{$fullrefname} = $objid if defined $objid;
2529 }
2530
2531 sub git_lrfetch_sane {
2532     my ($supplementary, @specs) = @_;
2533     # Make a 'refs/'.lrfetchrefs.'/*' be just like on server,
2534     # at least as regards @specs.  Also leave the results in
2535     # %lrfetchrefs_f, and arrange for lrfetchref_used to be
2536     # able to clean these up.
2537     #
2538     # With $supplementary==1, @specs must not contain wildcards
2539     # and we add to our previous fetches (non-atomically).
2540
2541     # This is rather miserable:
2542     # When git fetch --prune is passed a fetchspec ending with a *,
2543     # it does a plausible thing.  If there is no * then:
2544     # - it matches subpaths too, even if the supplied refspec
2545     #   starts refs, and behaves completely madly if the source
2546     #   has refs/refs/something.  (See, for example, Debian #NNNN.)
2547     # - if there is no matching remote ref, it bombs out the whole
2548     #   fetch.
2549     # We want to fetch a fixed ref, and we don't know in advance
2550     # if it exists, so this is not suitable.
2551     #
2552     # Our workaround is to use git ls-remote.  git ls-remote has its
2553     # own qairks.  Notably, it has the absurd multi-tail-matching
2554     # behaviour: git ls-remote R refs/foo can report refs/foo AND
2555     # refs/refs/foo etc.
2556     #
2557     # Also, we want an idempotent snapshot, but we have to make two
2558     # calls to the remote: one to git ls-remote and to git fetch.  The
2559     # solution is use git ls-remote to obtain a target state, and
2560     # git fetch to try to generate it.  If we don't manage to generate
2561     # the target state, we try again.
2562
2563     my $url = access_giturl();
2564
2565     printdebug "git_lrfetch_sane suppl=$supplementary specs @specs\n";
2566
2567     my $specre = join '|', map {
2568         my $x = $_;
2569         $x =~ s/\W/\\$&/g;
2570         my $wildcard = $x =~ s/\\\*$/.*/;
2571         die if $wildcard && $supplementary;
2572         "(?:refs/$x)";
2573     } @specs;
2574     printdebug "git_lrfetch_sane specre=$specre\n";
2575     my $wanted_rref = sub {
2576         local ($_) = @_;
2577         return m/^(?:$specre)$/;
2578     };
2579
2580     my $fetch_iteration = 0;
2581     FETCH_ITERATION:
2582     for (;;) {
2583         printdebug "git_lrfetch_sane iteration $fetch_iteration\n";
2584         if (++$fetch_iteration > 10) {
2585             fail "too many iterations trying to get sane fetch!";
2586         }
2587
2588         my @look = map { "refs/$_" } @specs;
2589         my @lcmd = (@git, qw(ls-remote -q --refs), $url, @look);
2590         debugcmd "|",@lcmd;
2591
2592         my %wantr;
2593         open GITLS, "-|", @lcmd or die $!;
2594         while (<GITLS>) {
2595             printdebug "=> ", $_;
2596             m/^(\w+)\s+(\S+)\n/ or die "ls-remote $_ ?";
2597             my ($objid,$rrefname) = ($1,$2);
2598             if (!$wanted_rref->($rrefname)) {
2599                 print STDERR <<END;
2600 warning: git ls-remote @look reported $rrefname; this is silly, ignoring it.
2601 END
2602                 next;
2603             }
2604             $wantr{$rrefname} = $objid;
2605         }
2606         $!=0; $?=0;
2607         close GITLS or failedcmd @lcmd;
2608
2609         # OK, now %want is exactly what we want for refs in @specs
2610         my @fspecs = map {
2611             !m/\*$/ && !exists $wantr{"refs/$_"} ? () :
2612             "+refs/$_:".lrfetchrefs."/$_";
2613         } @specs;
2614
2615         printdebug "git_lrfetch_sane fspecs @fspecs\n";
2616
2617         my @fcmd = (@git, qw(fetch -p -n -q), $url, @fspecs);
2618         runcmd_ordryrun_local @fcmd if @fspecs;
2619
2620         if (!$supplementary) {
2621             %lrfetchrefs_f = ();
2622         }
2623         my %objgot;
2624
2625         git_for_each_ref(lrfetchrefs, sub {
2626             my ($objid,$objtype,$lrefname,$reftail) = @_;
2627             $lrfetchrefs_f{$lrefname} = $objid;
2628             $objgot{$objid} = 1;
2629         });
2630
2631         if ($supplementary) {
2632             last;
2633         }
2634
2635         foreach my $lrefname (sort keys %lrfetchrefs_f) {
2636             my $rrefname = 'refs'.substr($lrefname, length lrfetchrefs);
2637             if (!exists $wantr{$rrefname}) {
2638                 if ($wanted_rref->($rrefname)) {
2639                     printdebug <<END;
2640 git-fetch @fspecs created $lrefname which git ls-remote @look didn't list.
2641 END
2642                 } else {
2643                     print STDERR <<END
2644 warning: git fetch @fspecs created $lrefname; this is silly, deleting it.
2645 END
2646                 }
2647                 runcmd_ordryrun_local @git, qw(update-ref -d), $lrefname;
2648                 delete $lrfetchrefs_f{$lrefname};
2649                 next;
2650             }
2651         }
2652         foreach my $rrefname (sort keys %wantr) {
2653             my $lrefname = lrfetchrefs.substr($rrefname, 4);
2654             my $got = $lrfetchrefs_f{$lrefname} // '<none>';
2655             my $want = $wantr{$rrefname};
2656             next if $got eq $want;
2657             if (!defined $objgot{$want}) {
2658                 print STDERR <<END;
2659 warning: git ls-remote suggests we want $lrefname
2660 warning:  and it should refer to $want
2661 warning:  but git fetch didn't fetch that object to any relevant ref.
2662 warning:  This may be due to a race with someone updating the server.
2663 warning:  Will try again...
2664 END
2665                 next FETCH_ITERATION;
2666             }
2667             printdebug <<END;
2668 git-fetch @fspecs made $lrefname=$got but want git ls-remote @look says $want
2669 END
2670             runcmd_ordryrun_local @git, qw(update-ref -m),
2671                 "dgit fetch git fetch fixup", $lrefname, $want;
2672             $lrfetchrefs_f{$lrefname} = $want;
2673         }
2674         last;
2675     }
2676
2677     if (defined $csuite) {
2678         printdebug "git_lrfetch_sane: tidying any old suite lrfetchrefs\n";
2679         git_for_each_ref("refs/dgit-fetch/$csuite", sub {
2680             my ($objid,$objtype,$lrefname,$reftail) = @_;
2681             next if $lrfetchrefs_f{$lrefname}; # $csuite eq $distro ?
2682             runcmd_ordryrun_local @git, qw(update-ref -d), $lrefname;
2683         });
2684     }
2685
2686     printdebug "git_lrfetch_sane: git fetch --no-insane emulation complete\n",
2687         Dumper(\%lrfetchrefs_f);
2688 }
2689
2690 sub git_fetch_us () {
2691     # Want to fetch only what we are going to use, unless
2692     # deliberately-not-ff, in which case we must fetch everything.
2693
2694     my @specs = deliberately_not_fast_forward ? qw(tags/*) :
2695         map { "tags/$_" }
2696         (quiltmode_splitbrain
2697          ? (map { $_->('*',access_nomdistro) }
2698             \&debiantag_new, \&debiantag_maintview)
2699          : debiantags('*',access_nomdistro));
2700     push @specs, server_branch($csuite);
2701     push @specs, $rewritemap;
2702     push @specs, qw(heads/*) if deliberately_not_fast_forward;
2703
2704     git_lrfetch_sane 0, @specs;
2705
2706     my %here;
2707     my @tagpats = debiantags('*',access_nomdistro);
2708
2709     git_for_each_ref([map { "refs/tags/$_" } @tagpats], sub {
2710         my ($objid,$objtype,$fullrefname,$reftail) = @_;
2711         printdebug "currently $fullrefname=$objid\n";
2712         $here{$fullrefname} = $objid;
2713     });
2714     git_for_each_ref([map { lrfetchrefs."/tags/".$_ } @tagpats], sub {
2715         my ($objid,$objtype,$fullrefname,$reftail) = @_;
2716         my $lref = "refs".substr($fullrefname, length(lrfetchrefs));
2717         printdebug "offered $lref=$objid\n";
2718         if (!defined $here{$lref}) {
2719             my @upd = (@git, qw(update-ref), $lref, $objid, '');
2720             runcmd_ordryrun_local @upd;
2721             lrfetchref_used $fullrefname;
2722         } elsif ($here{$lref} eq $objid) {
2723             lrfetchref_used $fullrefname;
2724         } else {
2725             print STDERR \
2726                 "Not updateting $lref from $here{$lref} to $objid.\n";
2727         }
2728     });
2729 }
2730
2731 #---------- dsc and archive handling ----------
2732
2733 sub mergeinfo_getclogp ($) {
2734     # Ensures thit $mi->{Clogp} exists and returns it
2735     my ($mi) = @_;
2736     $mi->{Clogp} = commit_getclogp($mi->{Commit});
2737 }
2738
2739 sub mergeinfo_version ($) {
2740     return getfield( (mergeinfo_getclogp $_[0]), 'Version' );
2741 }
2742
2743 sub fetch_from_archive_record_1 ($) {
2744     my ($hash) = @_;
2745     runcmd @git, qw(update-ref -m), "dgit fetch $csuite",
2746             'DGIT_ARCHIVE', $hash;
2747     cmdoutput @git, qw(log -n2), $hash;
2748     # ... gives git a chance to complain if our commit is malformed
2749 }
2750
2751 sub fetch_from_archive_record_2 ($) {
2752     my ($hash) = @_;
2753     my @upd_cmd = (@git, qw(update-ref -m), 'dgit fetch', lrref(), $hash);
2754     if (act_local()) {
2755         cmdoutput @upd_cmd;
2756     } else {
2757         dryrun_report @upd_cmd;
2758     }
2759 }
2760
2761 sub parse_dsc_field ($$) {
2762     my ($dsc, $what) = @_;
2763     my $f;
2764     foreach my $field (@ourdscfield) {
2765         $f = $dsc->{$field};
2766         last if defined $f;
2767     }
2768     if (!defined $f) {
2769         progress "$what: NO git hash";
2770     } elsif (($dsc_hash, $dsc_distro, $dsc_hint_tag, $dsc_hint_url)
2771              = $f =~ m/^(\w+)\s+($distro_re)\s+($versiontag_re)\s+(\S+)(?:\s|$)/) {
2772         progress "$what: specified git info ($dsc_distro)";
2773         $dsc_hint_tag = [ $dsc_hint_tag ];
2774     } elsif ($f =~ m/^\w+\s*$/) {
2775         $dsc_hash = $&;
2776         $dsc_distro //= cfg qw(dgit.default.old-dsc-distro
2777                                dgit.default.distro);
2778         $dsc_hint_tag = [ debiantags +(getfield $dsc, 'Version'),
2779                           $dsc_distro ];
2780         progress "$what: specified git hash";
2781     } else {
2782         fail "$what: invalid Dgit info";
2783     }
2784 }
2785
2786 sub resolve_dsc_field_commit ($$) {
2787     my ($already_distro, $already_mapref) = @_;
2788
2789     return unless defined $dsc_hash;
2790
2791     my $mapref =
2792         defined $already_mapref &&
2793         ($already_distro eq $dsc_distro || !$chase_dsc_distro)
2794         ? $already_mapref : undef;
2795
2796     my $do_fetch;
2797     $do_fetch = sub {
2798         my ($what, @fetch) = @_;
2799
2800         local $idistro = $dsc_distro;
2801         my $lrf = lrfetchrefs;
2802
2803         if (!$chase_dsc_distro) {
2804             progress
2805                 "not chasing .dsc distro $dsc_distro: not fetching $what";
2806             return 0;
2807         }
2808
2809         progress
2810             ".dsc names distro $dsc_distro: fetching $what";
2811
2812         my $url = access_giturl();
2813         if (!defined $url) {
2814             defined $dsc_hint_url or fail <<END;
2815 .dsc Dgit metadata is in context of distro $dsc_distro
2816 for which we have no configured url and .dsc provides no hint
2817 END
2818             my $proto =
2819                 $dsc_hint_url =~ m#^([-+0-9a-zA-Z]+):# ? $1 :
2820                 $dsc_hint_url =~ m#^/# ? 'file' : 'bad-syntax';
2821             parse_cfg_bool "dsc-url-proto-ok", 'false',
2822                 cfg("dgit.dsc-url-proto-ok.$proto",
2823                     "dgit.default.dsc-url-proto-ok")
2824                 or fail <<END;
2825 .dsc Dgit metadata is in context of distro $dsc_distro
2826 for which we have no configured url;
2827 .dsc provices hinted url with protocol $proto which is unsafe.
2828 (can be overridden by config - consult documentation)
2829 END
2830             $url = $dsc_hint_url;
2831         }
2832
2833         git_lrfetch_sane 1, @fetch;
2834
2835         return $lrf;
2836     };
2837
2838     my $rewrite_enable = do {
2839         local $idistro = $dsc_distro;
2840         access_cfg('rewrite-map-enable', 'RETURN-UNDEF');
2841     };
2842
2843     if (parse_cfg_bool 'rewrite-map-enable', 'true', $rewrite_enable) {
2844         if (!defined $mapref) {
2845             my $lrf = $do_fetch->("rewrite map", $rewritemap) or return;
2846             $mapref = $lrf.'/'.$rewritemap;
2847         }
2848         my $rewritemapdata = git_cat_file $mapref.':map';
2849         if (defined $rewritemapdata
2850             && $rewritemapdata =~ m/^$dsc_hash(?:[ \t](\w+))/m) {
2851             progress
2852                 "server's git history rewrite map contains a relevant entry!";
2853
2854             $dsc_hash = $1;
2855             if (defined $dsc_hash) {
2856                 progress "using rewritten git hash in place of .dsc value";
2857             } else {
2858                 progress "server data says .dsc hash is to be disregarded";
2859             }
2860         }
2861     }
2862
2863     if (!defined git_cat_file $dsc_hash) {
2864         my @tags = map { "tags/".$_ } @$dsc_hint_tag;
2865         my $lrf = $do_fetch->("additional commits", @tags) &&
2866             defined git_cat_file $dsc_hash
2867             or fail <<END;
2868 .dsc Dgit metadata requires commit $dsc_hash
2869 but we could not obtain that object anywhere.
2870 END
2871         foreach my $t (@tags) {
2872             my $fullrefname = $lrf.'/'.$t;
2873             print STDERR "CHK $t $fullrefname ".Dumper(\%lrfetchrefs_f);
2874             next unless $lrfetchrefs_f{$fullrefname};
2875             next unless is_fast_fwd "$fullrefname~0", $dsc_hash;
2876             lrfetchref_used $fullrefname;
2877         }
2878     }
2879 }
2880
2881 sub fetch_from_archive () {
2882     ensure_setup_existing_tree();
2883
2884     # Ensures that lrref() is what is actually in the archive, one way
2885     # or another, according to us - ie this client's
2886     # appropritaely-updated archive view.  Also returns the commit id.
2887     # If there is nothing in the archive, leaves lrref alone and
2888     # returns undef.  git_fetch_us must have already been called.
2889     get_archive_dsc();
2890
2891     if ($dsc) {
2892         parse_dsc_field($dsc, 'last upload to archive');
2893         resolve_dsc_field_commit access_basedistro,
2894             lrfetchrefs."/".$rewritemap
2895     } else {
2896         progress "no version available from the archive";
2897     }
2898
2899     # If the archive's .dsc has a Dgit field, there are three
2900     # relevant git commitids we need to choose between and/or merge
2901     # together:
2902     #   1. $dsc_hash: the Dgit field from the archive
2903     #   2. $lastpush_hash: the suite branch on the dgit git server
2904     #   3. $lastfetch_hash: our local tracking brach for the suite
2905     #
2906     # These may all be distinct and need not be in any fast forward
2907     # relationship:
2908     #
2909     # If the dsc was pushed to this suite, then the server suite
2910     # branch will have been updated; but it might have been pushed to
2911     # a different suite and copied by the archive.  Conversely a more
2912     # recent version may have been pushed with dgit but not appeared
2913     # in the archive (yet).
2914     #
2915     # $lastfetch_hash may be awkward because archive imports
2916     # (particularly, imports of Dgit-less .dscs) are performed only as
2917     # needed on individual clients, so different clients may perform a
2918     # different subset of them - and these imports are only made
2919     # public during push.  So $lastfetch_hash may represent a set of
2920     # imports different to a subsequent upload by a different dgit
2921     # client.
2922     #
2923     # Our approach is as follows:
2924     #
2925     # As between $dsc_hash and $lastpush_hash: if $lastpush_hash is a
2926     # descendant of $dsc_hash, then it was pushed by a dgit user who
2927     # had based their work on $dsc_hash, so we should prefer it.
2928     # Otherwise, $dsc_hash was installed into this suite in the
2929     # archive other than by a dgit push, and (necessarily) after the
2930     # last dgit push into that suite (since a dgit push would have
2931     # been descended from the dgit server git branch); thus, in that
2932     # case, we prefer the archive's version (and produce a
2933     # pseudo-merge to overwrite the dgit server git branch).
2934     #
2935     # (If there is no Dgit field in the archive's .dsc then
2936     # generate_commit_from_dsc uses the version numbers to decide
2937     # whether the suite branch or the archive is newer.  If the suite
2938     # branch is newer it ignores the archive's .dsc; otherwise it
2939     # generates an import of the .dsc, and produces a pseudo-merge to
2940     # overwrite the suite branch with the archive contents.)
2941     #
2942     # The outcome of that part of the algorithm is the `public view',
2943     # and is same for all dgit clients: it does not depend on any
2944     # unpublished history in the local tracking branch.
2945     #
2946     # As between the public view and the local tracking branch: The
2947     # local tracking branch is only updated by dgit fetch, and
2948     # whenever dgit fetch runs it includes the public view in the
2949     # local tracking branch.  Therefore if the public view is not
2950     # descended from the local tracking branch, the local tracking
2951     # branch must contain history which was imported from the archive
2952     # but never pushed; and, its tip is now out of date.  So, we make
2953     # a pseudo-merge to overwrite the old imports and stitch the old
2954     # history in.
2955     #
2956     # Finally: we do not necessarily reify the public view (as
2957     # described above).  This is so that we do not end up stacking two
2958     # pseudo-merges.  So what we actually do is figure out the inputs
2959     # to any public view pseudo-merge and put them in @mergeinputs.
2960
2961     my @mergeinputs;
2962     # $mergeinputs[]{Commit}
2963     # $mergeinputs[]{Info}
2964     # $mergeinputs[0] is the one whose tree we use
2965     # @mergeinputs is in the order we use in the actual commit)
2966     #
2967     # Also:
2968     # $mergeinputs[]{Message} is a commit message to use
2969     # $mergeinputs[]{ReverseParents} if def specifies that parent
2970     #                                list should be in opposite order
2971     # Such an entry has no Commit or Info.  It applies only when found
2972     # in the last entry.  (This ugliness is to support making
2973     # identical imports to previous dgit versions.)
2974
2975     my $lastpush_hash = git_get_ref(lrfetchref());
2976     printdebug "previous reference hash=$lastpush_hash\n";
2977     $lastpush_mergeinput = $lastpush_hash && {
2978         Commit => $lastpush_hash,
2979         Info => "dgit suite branch on dgit git server",
2980     };
2981
2982     my $lastfetch_hash = git_get_ref(lrref());
2983     printdebug "fetch_from_archive: lastfetch=$lastfetch_hash\n";
2984     my $lastfetch_mergeinput = $lastfetch_hash && {
2985         Commit => $lastfetch_hash,
2986         Info => "dgit client's archive history view",
2987     };
2988
2989     my $dsc_mergeinput = $dsc_hash && {
2990         Commit => $dsc_hash,
2991         Info => "Dgit field in .dsc from archive",
2992     };
2993
2994     my $cwd = getcwd();
2995     my $del_lrfetchrefs = sub {
2996         changedir $cwd;
2997         my $gur;
2998         printdebug "del_lrfetchrefs...\n";
2999         foreach my $fullrefname (sort keys %lrfetchrefs_d) {
3000             my $objid = $lrfetchrefs_d{$fullrefname};
3001             printdebug "del_lrfetchrefs: $objid $fullrefname\n";
3002             if (!$gur) {
3003                 $gur ||= new IO::Handle;
3004                 open $gur, "|-", qw(git update-ref --stdin) or die $!;
3005             }
3006             printf $gur "delete %s %s\n", $fullrefname, $objid;
3007         }
3008         if ($gur) {
3009             close $gur or failedcmd "git update-ref delete lrfetchrefs";
3010         }
3011     };
3012
3013     if (defined $dsc_hash) {
3014         ensure_we_have_orig();
3015         if (!$lastpush_hash || $dsc_hash eq $lastpush_hash) {
3016             @mergeinputs = $dsc_mergeinput
3017         } elsif (is_fast_fwd($dsc_hash,$lastpush_hash)) {
3018             print STDERR <<END or die $!;
3019
3020 Git commit in archive is behind the last version allegedly pushed/uploaded.
3021 Commit referred to by archive: $dsc_hash
3022 Last version pushed with dgit: $lastpush_hash
3023 $later_warning_msg
3024 END
3025             @mergeinputs = ($lastpush_mergeinput);
3026         } else {
3027             # Archive has .dsc which is not a descendant of the last dgit
3028             # push.  This can happen if the archive moves .dscs about.
3029             # Just follow its lead.
3030             if (is_fast_fwd($lastpush_hash,$dsc_hash)) {
3031                 progress "archive .dsc names newer git commit";
3032                 @mergeinputs = ($dsc_mergeinput);
3033             } else {
3034                 progress "archive .dsc names other git commit, fixing up";
3035                 @mergeinputs = ($dsc_mergeinput, $lastpush_mergeinput);
3036             }
3037         }
3038     } elsif ($dsc) {
3039         @mergeinputs = generate_commits_from_dsc();
3040         # We have just done an import.  Now, our import algorithm might
3041         # have been improved.  But even so we do not want to generate
3042         # a new different import of the same package.  So if the
3043         # version numbers are the same, just use our existing version.
3044         # If the version numbers are different, the archive has changed
3045         # (perhaps, rewound).
3046         if ($lastfetch_mergeinput &&
3047             !version_compare( (mergeinfo_version $lastfetch_mergeinput),
3048                               (mergeinfo_version $mergeinputs[0]) )) {
3049             @mergeinputs = ($lastfetch_mergeinput);
3050         }
3051     } elsif ($lastpush_hash) {
3052         # only in git, not in the archive yet
3053         @mergeinputs = ($lastpush_mergeinput);
3054         print STDERR <<END or die $!;
3055
3056 Package not found in the archive, but has allegedly been pushed using dgit.
3057 $later_warning_msg
3058 END
3059     } else {
3060         printdebug "nothing found!\n";
3061         if (defined $skew_warning_vsn) {
3062             print STDERR <<END or die $!;
3063
3064 Warning: relevant archive skew detected.
3065 Archive allegedly contains $skew_warning_vsn
3066 But we were not able to obtain any version from the archive or git.
3067
3068 END
3069         }
3070         unshift @end, $del_lrfetchrefs;
3071         return undef;
3072     }
3073
3074     if ($lastfetch_hash &&
3075         !grep {
3076             my $h = $_->{Commit};
3077             $h and is_fast_fwd($lastfetch_hash, $h);
3078             # If true, one of the existing parents of this commit
3079             # is a descendant of the $lastfetch_hash, so we'll
3080             # be ff from that automatically.
3081         } @mergeinputs
3082         ) {
3083         # Otherwise:
3084         push @mergeinputs, $lastfetch_mergeinput;
3085     }
3086
3087     printdebug "fetch mergeinfos:\n";
3088     foreach my $mi (@mergeinputs) {
3089         if ($mi->{Info}) {
3090             printdebug " commit $mi->{Commit} $mi->{Info}\n";
3091         } else {
3092             printdebug sprintf " ReverseParents=%d Message=%s",
3093                 $mi->{ReverseParents}, $mi->{Message};
3094         }
3095     }
3096
3097     my $compat_info= pop @mergeinputs
3098         if $mergeinputs[$#mergeinputs]{Message};
3099
3100     @mergeinputs = grep { defined $_->{Commit} } @mergeinputs;
3101
3102     my $hash;
3103     if (@mergeinputs > 1) {
3104         # here we go, then:
3105         my $tree_commit = $mergeinputs[0]{Commit};
3106
3107         my $tree = cmdoutput @git, qw(cat-file commit), $tree_commit;
3108         $tree =~ m/\n\n/;  $tree = $`;
3109         $tree =~ m/^tree (\w+)$/m or die "$dsc_hash tree ?";
3110         $tree = $1;
3111
3112         # We use the changelog author of the package in question the
3113         # author of this pseudo-merge.  This is (roughly) correct if
3114         # this commit is simply representing aa non-dgit upload.
3115         # (Roughly because it does not record sponsorship - but we
3116         # don't have sponsorship info because that's in the .changes,
3117         # which isn't in the archivw.)
3118         #
3119         # But, it might be that we are representing archive history
3120         # updates (including in-archive copies).  These are not really
3121         # the responsibility of the person who created the .dsc, but
3122         # there is no-one whose name we should better use.  (The
3123         # author of the .dsc-named commit is clearly worse.)
3124
3125         my $useclogp = mergeinfo_getclogp $mergeinputs[0];
3126         my $author = clogp_authline $useclogp;
3127         my $cversion = getfield $useclogp, 'Version';
3128
3129         my $mcf = ".git/dgit/mergecommit";
3130         open MC, ">", $mcf or die "$mcf $!";
3131         print MC <<END or die $!;
3132 tree $tree
3133 END
3134
3135         my @parents = grep { $_->{Commit} } @mergeinputs;
3136         @parents = reverse @parents if $compat_info->{ReverseParents};
3137         print MC <<END or die $! foreach @parents;
3138 parent $_->{Commit}
3139 END
3140
3141         print MC <<END or die $!;
3142 author $author
3143 committer $author
3144
3145 END
3146
3147         if (defined $compat_info->{Message}) {
3148             print MC $compat_info->{Message} or die $!;
3149         } else {
3150             print MC <<END or die $!;
3151 Record $package ($cversion) in archive suite $csuite
3152
3153 Record that
3154 END
3155             my $message_add_info = sub {
3156                 my ($mi) = (@_);
3157                 my $mversion = mergeinfo_version $mi;
3158                 printf MC "  %-20s %s\n", $mversion, $mi->{Info}
3159                     or die $!;
3160             };
3161
3162             $message_add_info->($mergeinputs[0]);
3163             print MC <<END or die $!;
3164 should be treated as descended from
3165 END
3166             $message_add_info->($_) foreach @mergeinputs[1..$#mergeinputs];
3167         }
3168
3169         close MC or die $!;
3170         $hash = make_commit $mcf;
3171     } else {
3172         $hash = $mergeinputs[0]{Commit};
3173     }
3174     printdebug "fetch hash=$hash\n";
3175
3176     my $chkff = sub {
3177         my ($lasth, $what) = @_;
3178         return unless $lasth;
3179         die "$lasth $hash $what ?" unless is_fast_fwd($lasth, $hash);
3180     };
3181
3182     $chkff->($lastpush_hash, 'dgit repo server tip (last push)')
3183         if $lastpush_hash;
3184     $chkff->($lastfetch_hash, 'local tracking tip (last fetch)');
3185
3186     fetch_from_archive_record_1($hash);
3187
3188     if (defined $skew_warning_vsn) {
3189         mkpath '.git/dgit';
3190         printdebug "SKEW CHECK WANT $skew_warning_vsn\n";
3191         my $gotclogp = commit_getclogp($hash);
3192         my $got_vsn = getfield $gotclogp, 'Version';
3193         printdebug "SKEW CHECK GOT $got_vsn\n";
3194         if (version_compare($got_vsn, $skew_warning_vsn) < 0) {
3195             print STDERR <<END or die $!;
3196
3197 Warning: archive skew detected.  Using the available version:
3198 Archive allegedly contains    $skew_warning_vsn
3199 We were able to obtain only   $got_vsn
3200
3201 END
3202         }
3203     }
3204
3205     if ($lastfetch_hash ne $hash) {
3206         fetch_from_archive_record_2($hash);
3207     }
3208
3209     lrfetchref_used lrfetchref();
3210
3211     unshift @end, $del_lrfetchrefs;
3212     return $hash;
3213 }
3214
3215 sub set_local_git_config ($$) {
3216     my ($k, $v) = @_;
3217     runcmd @git, qw(config), $k, $v;
3218 }
3219
3220 sub setup_mergechangelogs (;$) {
3221     my ($always) = @_;
3222     return unless $always || access_cfg_bool(1, 'setup-mergechangelogs');
3223
3224     my $driver = 'dpkg-mergechangelogs';
3225     my $cb = "merge.$driver";
3226     my $attrs = '.git/info/attributes';
3227     ensuredir '.git/info';
3228
3229     open NATTRS, ">", "$attrs.new" or die "$attrs.new $!";
3230     if (!open ATTRS, "<", $attrs) {
3231         $!==ENOENT or die "$attrs: $!";
3232     } else {
3233         while (<ATTRS>) {
3234             chomp;
3235             next if m{^debian/changelog\s};
3236             print NATTRS $_, "\n" or die $!;
3237         }
3238         ATTRS->error and die $!;
3239         close ATTRS;
3240     }
3241     print NATTRS "debian/changelog merge=$driver\n" or die $!;
3242     close NATTRS;
3243
3244     set_local_git_config "$cb.name", 'debian/changelog merge driver';
3245     set_local_git_config "$cb.driver", 'dpkg-mergechangelogs -m %O %A %B %A';
3246
3247     rename "$attrs.new", "$attrs" or die "$attrs: $!";
3248 }
3249
3250 sub setup_useremail (;$) {
3251     my ($always) = @_;
3252     return unless $always || access_cfg_bool(1, 'setup-useremail');
3253
3254     my $setup = sub {
3255         my ($k, $envvar) = @_;
3256         my $v = access_cfg("user-$k", 'RETURN-UNDEF') // $ENV{$envvar};
3257         return unless defined $v;
3258         set_local_git_config "user.$k", $v;
3259     };
3260
3261     $setup->('email', 'DEBEMAIL');
3262     $setup->('name', 'DEBFULLNAME');
3263 }
3264
3265 sub ensure_setup_existing_tree () {
3266     my $k = "remote.$remotename.skipdefaultupdate";
3267     my $c = git_get_config $k;
3268     return if defined $c;
3269     set_local_git_config $k, 'true';
3270 }
3271
3272 sub setup_new_tree () {
3273     setup_mergechangelogs();
3274     setup_useremail();
3275 }
3276
3277 sub multisuite_suite_child ($$$) {
3278     my ($tsuite, $merginputs, $fn) = @_;
3279     # in child, sets things up, calls $fn->(), and returns undef
3280     # in parent, returns canonical suite name for $tsuite
3281     my $canonsuitefh = IO::File::new_tmpfile;
3282     my $pid = fork // die $!;
3283     if (!$pid) {
3284         $isuite = $tsuite;
3285         $us .= " [$isuite]";
3286         $debugprefix .= " ";
3287         progress "fetching $tsuite...";
3288         canonicalise_suite();
3289         print $canonsuitefh $csuite, "\n" or die $!;
3290         close $canonsuitefh or die $!;
3291         $fn->();
3292         return undef;
3293     }
3294     waitpid $pid,0 == $pid or die $!;
3295     fail "failed to obtain $tsuite: ".waitstatusmsg() if $? && $?!=256*4;
3296     seek $canonsuitefh,0,0 or die $!;
3297     local $csuite = <$canonsuitefh>;
3298     die $! unless defined $csuite && chomp $csuite;
3299     if ($? == 256*4) {
3300         printdebug "multisuite $tsuite missing\n";
3301         return $csuite;
3302     }
3303     printdebug "multisuite $tsuite ok (canon=$csuite)\n";
3304     push @$merginputs, {
3305         Ref => lrref,
3306         Info => $csuite,
3307     };
3308     return $csuite;
3309 }
3310
3311 sub fork_for_multisuite ($) {
3312     my ($before_fetch_merge) = @_;
3313     # if nothing unusual, just returns ''
3314     #
3315     # if multisuite:
3316     # returns 0 to caller in child, to do first of the specified suites
3317     # in child, $csuite is not yet set
3318     #
3319     # returns 1 to caller in parent, to finish up anything needed after
3320     # in parent, $csuite is set to canonicalised portmanteau
3321
3322     my $org_isuite = $isuite;
3323     my @suites = split /\,/, $isuite;
3324     return '' unless @suites > 1;
3325     printdebug "fork_for_multisuite: @suites\n";
3326
3327     my @mergeinputs;
3328
3329     my $cbasesuite = multisuite_suite_child($suites[0], \@mergeinputs,
3330                                             sub { });
3331     return 0 unless defined $cbasesuite;
3332
3333     fail "package $package missing in (base suite) $cbasesuite"
3334         unless @mergeinputs;
3335
3336     my @csuites = ($cbasesuite);
3337
3338     $before_fetch_merge->();
3339
3340     foreach my $tsuite (@suites[1..$#suites]) {
3341         my $csubsuite = multisuite_suite_child($tsuite, \@mergeinputs,
3342                                                sub {
3343             @end = ();
3344             fetch();
3345             exit 0;
3346         });
3347         # xxx collecte the ref here
3348
3349         $csubsuite =~ s/^\Q$cbasesuite\E-/-/;
3350         push @csuites, $csubsuite;
3351     }
3352
3353     foreach my $mi (@mergeinputs) {
3354         my $ref = git_get_ref $mi->{Ref};
3355         die "$mi->{Ref} ?" unless length $ref;
3356         $mi->{Commit} = $ref;
3357     }
3358
3359     $csuite = join ",", @csuites;
3360
3361     my $previous = git_get_ref lrref;
3362     if ($previous) {
3363         unshift @mergeinputs, {
3364             Commit => $previous,
3365             Info => "local combined tracking branch",
3366             Warning =>
3367  "archive seems to have rewound: local tracking branch is ahead!",
3368         };
3369     }
3370
3371     foreach my $ix (0..$#mergeinputs) {
3372         $mergeinputs[$ix]{Index} = $ix;
3373     }
3374
3375     @mergeinputs = sort {
3376         -version_compare(mergeinfo_version $a,
3377                          mergeinfo_version $b) # highest version first
3378             or
3379         $a->{Index} <=> $b->{Index}; # earliest in spec first
3380     } @mergeinputs;
3381
3382     my @needed;
3383
3384   NEEDED:
3385     foreach my $mi (@mergeinputs) {
3386         printdebug "multisuite merge check $mi->{Info}\n";
3387         foreach my $previous (@needed) {
3388             next unless is_fast_fwd $mi->{Commit}, $previous->{Commit};
3389             printdebug "multisuite merge un-needed $previous->{Info}\n";
3390             next NEEDED;
3391         }
3392         push @needed, $mi;
3393         printdebug "multisuite merge this-needed\n";
3394         $mi->{Character} = '+';
3395     }
3396
3397     $needed[0]{Character} = '*';
3398
3399     my $output = $needed[0]{Commit};
3400
3401     if (@needed > 1) {
3402         printdebug "multisuite merge nontrivial\n";
3403         my $tree = cmdoutput qw(git rev-parse), $needed[0]{Commit}.':';
3404
3405         my $commit = "tree $tree\n";
3406         my $msg = "Combine archive branches $csuite [dgit]\n\n".
3407             "Input branches:\n";
3408
3409         foreach my $mi (sort { $a->{Index} <=> $b->{Index} } @mergeinputs) {
3410             printdebug "multisuite merge include $mi->{Info}\n";
3411             $mi->{Character} //= ' ';
3412             $commit .= "parent $mi->{Commit}\n";
3413             $msg .= sprintf " %s  %-25s %s\n",
3414                 $mi->{Character},
3415                 (mergeinfo_version $mi),
3416                 $mi->{Info};
3417         }
3418         my $authline = clogp_authline mergeinfo_getclogp $needed[0];
3419         $msg .= "\nKey\n".
3420             " * marks the highest version branch, which choose to use\n".
3421             " + marks each branch which was not already an ancestor\n\n".
3422             "[dgit multi-suite $csuite]\n";
3423         $commit .=
3424             "author $authline\n".
3425             "committer $authline\n\n";
3426         $output = make_commit_text $commit.$msg;
3427         printdebug "multisuite merge generated $output\n";
3428     }
3429
3430     fetch_from_archive_record_1($output);
3431     fetch_from_archive_record_2($output);
3432
3433     progress "calculated combined tracking suite $csuite";
3434
3435     return 1;
3436 }
3437
3438 sub clone_set_head () {
3439     open H, "> .git/HEAD" or die $!;
3440     print H "ref: ".lref()."\n" or die $!;
3441     close H or die $!;
3442 }
3443 sub clone_finish ($) {
3444     my ($dstdir) = @_;
3445     runcmd @git, qw(reset --hard), lrref();
3446     runcmd qw(bash -ec), <<'END';
3447         set -o pipefail
3448         git ls-tree -r --name-only -z HEAD | \
3449         xargs -0r touch -h -r . --
3450 END
3451     printdone "ready for work in $dstdir";
3452 }
3453
3454 sub clone ($) {
3455     my ($dstdir) = @_;
3456     badusage "dry run makes no sense with clone" unless act_local();
3457
3458     my $multi_fetched = fork_for_multisuite(sub {
3459         printdebug "multi clone before fetch merge\n";
3460         changedir $dstdir;
3461     });
3462     if ($multi_fetched) {
3463         printdebug "multi clone after fetch merge\n";
3464         clone_set_head();
3465         clone_finish($dstdir);
3466         exit 0;
3467     }
3468     printdebug "clone main body\n";
3469
3470     canonicalise_suite();
3471     my $hasgit = check_for_git();
3472     mkdir $dstdir or fail "create \`$dstdir': $!";
3473     changedir $dstdir;
3474     runcmd @git, qw(init -q);
3475     clone_set_head();
3476     my $giturl = access_giturl(1);
3477     if (defined $giturl) {
3478         runcmd @git, qw(remote add), 'origin', $giturl;
3479     }
3480     if ($hasgit) {
3481         progress "fetching existing git history";
3482         git_fetch_us();
3483         runcmd_ordryrun_local @git, qw(fetch origin);
3484     } else {
3485         progress "starting new git history";
3486     }
3487     fetch_from_archive() or no_such_package;
3488     my $vcsgiturl = $dsc->{'Vcs-Git'};
3489     if (length $vcsgiturl) {
3490         $vcsgiturl =~ s/\s+-b\s+\S+//g;
3491         runcmd @git, qw(remote add vcs-git), $vcsgiturl;
3492     }
3493     setup_new_tree();
3494     clone_finish($dstdir);
3495 }
3496
3497 sub fetch () {
3498     canonicalise_suite();
3499     if (check_for_git()) {
3500         git_fetch_us();
3501     }
3502     fetch_from_archive() or no_such_package();
3503     printdone "fetched into ".lrref();
3504 }
3505
3506 sub pull () {
3507     my $multi_fetched = fork_for_multisuite(sub { });
3508     fetch() unless $multi_fetched; # parent
3509     return if $multi_fetched eq '0'; # child
3510     runcmd_ordryrun_local @git, qw(merge -m),"Merge from $csuite [dgit]",
3511         lrref();
3512     printdone "fetched to ".lrref()." and merged into HEAD";
3513 }
3514
3515 sub check_not_dirty () {
3516     foreach my $f (qw(local-options local-patch-header)) {
3517         if (stat_exists "debian/source/$f") {
3518             fail "git tree contains debian/source/$f";
3519         }
3520     }
3521
3522     return if $ignoredirty;
3523
3524     my @cmd = (@git, qw(diff --quiet HEAD));
3525     debugcmd "+",@cmd;
3526     $!=0; $?=-1; system @cmd;
3527     return if !$?;
3528     if ($?==256) {
3529         fail "working tree is dirty (does not match HEAD)";
3530     } else {
3531         failedcmd @cmd;
3532     }
3533 }
3534
3535 sub commit_admin ($) {
3536     my ($m) = @_;
3537     progress "$m";
3538     runcmd_ordryrun_local @git, qw(commit -m), $m;
3539 }
3540
3541 sub commit_quilty_patch () {
3542     my $output = cmdoutput @git, qw(status --porcelain);
3543     my %adds;
3544     foreach my $l (split /\n/, $output) {
3545         next unless $l =~ m/\S/;
3546         if ($l =~ m{^(?:\?\?| M) (.pc|debian/patches)}) {
3547             $adds{$1}++;
3548         }
3549     }
3550     delete $adds{'.pc'}; # if there wasn't one before, don't add it
3551     if (!%adds) {
3552         progress "nothing quilty to commit, ok.";
3553         return;
3554     }
3555     my @adds = map { s/[][*?\\]/\\$&/g; $_; } sort keys %adds;
3556     runcmd_ordryrun_local @git, qw(add -f), @adds;
3557     commit_admin <<END
3558 Commit Debian 3.0 (quilt) metadata
3559
3560 [dgit ($our_version) quilt-fixup]
3561 END
3562 }
3563
3564 sub get_source_format () {
3565     my %options;
3566     if (open F, "debian/source/options") {
3567         while (<F>) {
3568             next if m/^\s*\#/;
3569             next unless m/\S/;
3570             s/\s+$//; # ignore missing final newline
3571             if (m/\s*\#\s*/) {
3572                 my ($k, $v) = ($`, $'); #');
3573                 $v =~ s/^"(.*)"$/$1/;
3574                 $options{$k} = $v;
3575             } else {
3576                 $options{$_} = 1;
3577             }
3578         }
3579         F->error and die $!;
3580         close F;
3581     } else {
3582         die $! unless $!==&ENOENT;
3583     }
3584
3585     if (!open F, "debian/source/format") {
3586         die $! unless $!==&ENOENT;
3587         return '';
3588     }
3589     $_ = <F>;
3590     F->error and die $!;
3591     chomp;
3592     return ($_, \%options);
3593 }
3594
3595 sub madformat_wantfixup ($) {
3596     my ($format) = @_;
3597     return 0 unless $format eq '3.0 (quilt)';
3598     our $quilt_mode_warned;
3599     if ($quilt_mode eq 'nocheck') {
3600         progress "Not doing any fixup of \`$format' due to".
3601             " ----no-quilt-fixup or --quilt=nocheck"
3602             unless $quilt_mode_warned++;
3603         return 0;
3604     }
3605     progress "Format \`$format', need to check/update patch stack"
3606         unless $quilt_mode_warned++;
3607     return 1;
3608 }
3609
3610 sub maybe_split_brain_save ($$$) {
3611     my ($headref, $dgitview, $msg) = @_;
3612     # => message fragment "$saved" describing disposition of $dgitview
3613     return "commit id $dgitview" unless defined $split_brain_save;
3614     my @cmd = (shell_cmd "cd ../../../..",
3615                @git, qw(update-ref -m),
3616                "dgit --dgit-view-save $msg HEAD=$headref",
3617                $split_brain_save, $dgitview);
3618     runcmd @cmd;
3619     return "and left in $split_brain_save";
3620 }
3621
3622 # An "infopair" is a tuple [ $thing, $what ]
3623 # (often $thing is a commit hash; $what is a description)
3624
3625 sub infopair_cond_equal ($$) {
3626     my ($x,$y) = @_;
3627     $x->[0] eq $y->[0] or fail <<END;
3628 $x->[1] ($x->[0]) not equal to $y->[1] ($y->[0])
3629 END
3630 };
3631
3632 sub infopair_lrf_tag_lookup ($$) {
3633     my ($tagnames, $what) = @_;
3634     # $tagname may be an array ref
3635     my @tagnames = ref $tagnames ? @$tagnames : ($tagnames);
3636     printdebug "infopair_lrfetchref_tag_lookup $what @tagnames\n";
3637     foreach my $tagname (@tagnames) {
3638         my $lrefname = lrfetchrefs."/tags/$tagname";
3639         my $tagobj = $lrfetchrefs_f{$lrefname};
3640         next unless defined $tagobj;
3641         printdebug "infopair_lrfetchref_tag_lookup $tagobj $tagname $what\n";
3642         return [ git_rev_parse($tagobj), $what ];
3643     }
3644     fail @tagnames==1 ? <<END : <<END;
3645 Wanted tag $what (@tagnames) on dgit server, but not found
3646 END
3647 Wanted tag $what (one of: @tagnames) on dgit server, but not found
3648 END
3649 }
3650
3651 sub infopair_cond_ff ($$) {
3652     my ($anc,$desc) = @_;
3653     is_fast_fwd($anc->[0], $desc->[0]) or fail <<END;
3654 $anc->[1] ($anc->[0]) .. $desc->[1] ($desc->[0]) is not fast forward
3655 END
3656 };
3657
3658 sub pseudomerge_version_check ($$) {
3659     my ($clogp, $archive_hash) = @_;
3660
3661     my $arch_clogp = commit_getclogp $archive_hash;
3662     my $i_arch_v = [ (getfield $arch_clogp, 'Version'),
3663                      'version currently in archive' ];
3664     if (defined $overwrite_version) {
3665         if (length $overwrite_version) {
3666             infopair_cond_equal([ $overwrite_version,
3667                                   '--overwrite= version' ],
3668                                 $i_arch_v);
3669         } else {
3670             my $v = $i_arch_v->[0];
3671             progress "Checking package changelog for archive version $v ...";
3672             eval {
3673                 my @xa = ("-f$v", "-t$v");
3674                 my $vclogp = parsechangelog @xa;
3675                 my $cv = [ (getfield $vclogp, 'Version'),
3676                            "Version field from dpkg-parsechangelog @xa" ];
3677                 infopair_cond_equal($i_arch_v, $cv);
3678             };
3679             if ($@) {
3680                 $@ =~ s/^dgit: //gm;
3681                 fail "$@".
3682                     "Perhaps debian/changelog does not mention $v ?";
3683             }
3684         }
3685     }
3686
3687     printdebug "pseudomerge_version_check i_arch_v @$i_arch_v\n";
3688     return $i_arch_v;
3689 }
3690
3691 sub pseudomerge_make_commit ($$$$ $$) {
3692     my ($clogp, $dgitview, $archive_hash, $i_arch_v,
3693         $msg_cmd, $msg_msg) = @_;
3694     progress "Declaring that HEAD inciudes all changes in $i_arch_v->[0]...";
3695
3696     my $tree = cmdoutput qw(git rev-parse), "${dgitview}:";
3697     my $authline = clogp_authline $clogp;
3698
3699     chomp $msg_msg;
3700     $msg_cmd .=
3701         !defined $overwrite_version ? ""
3702         : !length  $overwrite_version ? " --overwrite"
3703         : " --overwrite=".$overwrite_version;
3704
3705     mkpath '.git/dgit';
3706     my $pmf = ".git/dgit/pseudomerge";
3707     open MC, ">", $pmf or die "$pmf $!";
3708     print MC <<END or die $!;
3709 tree $tree
3710 parent $dgitview
3711 parent $archive_hash
3712 author $authline
3713 committer $authline
3714
3715 $msg_msg
3716
3717 [$msg_cmd]
3718 END
3719     close MC or die $!;
3720
3721     return make_commit($pmf);
3722 }
3723
3724 sub splitbrain_pseudomerge ($$$$) {
3725     my ($clogp, $maintview, $dgitview, $archive_hash) = @_;
3726     # => $merged_dgitview
3727     printdebug "splitbrain_pseudomerge...\n";
3728     #
3729     #     We:      debian/PREVIOUS    HEAD($maintview)
3730     # expect:          o ----------------- o
3731     #                    \                   \
3732     #                     o                   o
3733     #                 a/d/PREVIOUS        $dgitview
3734     #                $archive_hash              \
3735     #  If so,                \                   \
3736     #  we do:                 `------------------ o
3737     #   this:                                   $dgitview'
3738     #
3739
3740     return $dgitview unless defined $archive_hash;
3741
3742     printdebug "splitbrain_pseudomerge...\n";
3743
3744     my $i_arch_v = pseudomerge_version_check($clogp, $archive_hash);
3745
3746     if (!defined $overwrite_version) {
3747         progress "Checking that HEAD inciudes all changes in archive...";
3748     }
3749
3750     return $dgitview if is_fast_fwd $archive_hash, $dgitview;
3751
3752     if (defined $overwrite_version) {
3753     } elsif (!eval {
3754         my $t_dep14 = debiantag_maintview $i_arch_v->[0], access_nomdistro;
3755         my $i_dep14 = infopair_lrf_tag_lookup($t_dep14, "maintainer view tag");
3756         my $t_dgit = debiantag_new $i_arch_v->[0], access_nomdistro;
3757         my $i_dgit = infopair_lrf_tag_lookup($t_dgit, "dgit view tag");
3758         my $i_archive = [ $archive_hash, "current archive contents" ];
3759
3760         printdebug "splitbrain_pseudomerge i_archive @$i_archive\n";
3761
3762         infopair_cond_equal($i_dgit, $i_archive);
3763         infopair_cond_ff($i_dep14, $i_dgit);
3764         infopair_cond_ff($i_dep14, [ $maintview, 'HEAD' ]);
3765         1;
3766     }) {
3767         print STDERR <<END;
3768 $us: check failed (maybe --overwrite is needed, consult documentation)
3769 END
3770         die "$@";
3771     }
3772
3773     my $r = pseudomerge_make_commit
3774         $clogp, $dgitview, $archive_hash, $i_arch_v,
3775         "dgit --quilt=$quilt_mode",
3776         (defined $overwrite_version ? <<END_OVERWR : <<END_MAKEFF);
3777 Declare fast forward from $i_arch_v->[0]
3778 END_OVERWR
3779 Make fast forward from $i_arch_v->[0]
3780 END_MAKEFF
3781
3782     maybe_split_brain_save $maintview, $r, "pseudomerge";
3783
3784     progress "Made pseudo-merge of $i_arch_v->[0] into dgit view.";
3785     return $r;
3786 }
3787
3788 sub plain_overwrite_pseudomerge ($$$) {
3789     my ($clogp, $head, $archive_hash) = @_;
3790
3791     printdebug "plain_overwrite_pseudomerge...";
3792
3793     my $i_arch_v = pseudomerge_version_check($clogp, $archive_hash);
3794
3795     return $head if is_fast_fwd $archive_hash, $head;
3796
3797     my $m = "Declare fast forward from $i_arch_v->[0]";
3798
3799     my $r = pseudomerge_make_commit
3800         $clogp, $head, $archive_hash, $i_arch_v,
3801         "dgit", $m;
3802
3803     runcmd @git, qw(update-ref -m), $m, 'HEAD', $r, $head;
3804
3805     progress "Make pseudo-merge of $i_arch_v->[0] into your HEAD.";
3806     return $r;
3807 }
3808
3809 sub push_parse_changelog ($) {
3810     my ($clogpfn) = @_;
3811
3812     my $clogp = Dpkg::Control::Hash->new();
3813     $clogp->load($clogpfn) or die;
3814
3815     my $clogpackage = getfield $clogp, 'Source';
3816     $package //= $clogpackage;
3817     fail "-p specified $package but changelog specified $clogpackage"
3818         unless $package eq $clogpackage;
3819     my $cversion = getfield $clogp, 'Version';
3820
3821     if (!$we_are_initiator) {
3822         # rpush initiator can't do this because it doesn't have $isuite yet
3823         my $tag = debiantag($cversion, access_nomdistro);
3824         runcmd @git, qw(check-ref-format), $tag;
3825     }
3826
3827     my $dscfn = dscfn($cversion);
3828
3829     return ($clogp, $cversion, $dscfn);
3830 }
3831
3832 sub push_parse_dsc ($$$) {
3833     my ($dscfn,$dscfnwhat, $cversion) = @_;
3834     $dsc = parsecontrol($dscfn,$dscfnwhat);
3835     my $dversion = getfield $dsc, 'Version';
3836     my $dscpackage = getfield $dsc, 'Source';
3837     ($dscpackage eq $package && $dversion eq $cversion) or
3838         fail "$dscfn is for $dscpackage $dversion".
3839             " but debian/changelog is for $package $cversion";
3840 }
3841
3842 sub push_tagwants ($$$$) {
3843     my ($cversion, $dgithead, $maintviewhead, $tfbase) = @_;
3844     my @tagwants;
3845     push @tagwants, {
3846         TagFn => \&debiantag,
3847         Objid => $dgithead,
3848         TfSuffix => '',
3849         View => 'dgit',
3850     };
3851     if (defined $maintviewhead) {
3852         push @tagwants, {
3853             TagFn => \&debiantag_maintview,
3854             Objid => $maintviewhead,
3855             TfSuffix => '-maintview',
3856             View => 'maint',
3857         };
3858     } elsif ($dodep14tag eq 'no' ? 0
3859              : $dodep14tag eq 'want' ? access_cfg_tagformats_can_splitbrain
3860              : $dodep14tag eq 'always'
3861              ? (access_cfg_tagformats_can_splitbrain or fail <<END)
3862 --dep14tag-always (or equivalent in config) means server must support
3863  both "new" and "maint" tag formats, but config says it doesn't.
3864 END
3865             : die "$dodep14tag ?") {
3866         push @tagwants, {
3867             TagFn => \&debiantag_maintview,
3868             Objid => $dgithead,
3869             TfSuffix => '-dgit',
3870             View => 'dgit',
3871         };
3872     };
3873     foreach my $tw (@tagwants) {
3874         $tw->{Tag} = $tw->{TagFn}($cversion, access_nomdistro);
3875         $tw->{Tfn} = sub { $tfbase.$tw->{TfSuffix}.$_[0]; };
3876     }
3877     printdebug 'push_tagwants: ', Dumper(\@_, \@tagwants);
3878     return @tagwants;
3879 }
3880
3881 sub push_mktags ($$ $$ $) {
3882     my ($clogp,$dscfn,
3883         $changesfile,$changesfilewhat,
3884         $tagwants) = @_;
3885
3886     die unless $tagwants->[0]{View} eq 'dgit';
3887
3888     my $declaredistro = access_nomdistro();
3889     my $reader_giturl = do { local $access_forpush=0; access_giturl(); };
3890     $dsc->{$ourdscfield[0]} = join " ",
3891         $tagwants->[0]{Objid}, $declaredistro, $tagwants->[0]{Tag},
3892         $reader_giturl;
3893     $dsc->save("$dscfn.tmp") or die $!;
3894
3895     my $changes = parsecontrol($changesfile,$changesfilewhat);
3896     foreach my $field (qw(Source Distribution Version)) {
3897         $changes->{$field} eq $clogp->{$field} or
3898             fail "changes field $field \`$changes->{$field}'".
3899                 " does not match changelog \`$clogp->{$field}'";
3900     }
3901
3902     my $cversion = getfield $clogp, 'Version';
3903     my $clogsuite = getfield $clogp, 'Distribution';
3904
3905     # We make the git tag by hand because (a) that makes it easier
3906     # to control the "tagger" (b) we can do remote signing
3907     my $authline = clogp_authline $clogp;
3908     my $delibs = join(" ", "",@deliberatelies);
3909
3910     my $mktag = sub {
3911         my ($tw) = @_;
3912         my $tfn = $tw->{Tfn};
3913         my $head = $tw->{Objid};
3914         my $tag = $tw->{Tag};
3915
3916         open TO, '>', $tfn->('.tmp') or die $!;
3917         print TO <<END or die $!;
3918 object $head
3919 type commit
3920 tag $tag
3921 tagger $authline
3922
3923 END
3924         if ($tw->{View} eq 'dgit') {
3925             print TO <<END or die $!;
3926 $package release $cversion for $clogsuite ($csuite) [dgit]
3927 [dgit distro=$declaredistro$delibs]
3928 END
3929             foreach my $ref (sort keys %previously) {
3930                 print TO <<END or die $!;
3931 [dgit previously:$ref=$previously{$ref}]
3932 END
3933             }
3934         } elsif ($tw->{View} eq 'maint') {
3935             print TO <<END or die $!;
3936 $package release $cversion for $clogsuite ($csuite)
3937 (maintainer view tag generated by dgit --quilt=$quilt_mode)
3938 END
3939         } else {
3940             die Dumper($tw)."?";
3941         }
3942
3943         close TO or die $!;
3944
3945         my $tagobjfn = $tfn->('.tmp');
3946         if ($sign) {
3947             if (!defined $keyid) {
3948                 $keyid = access_cfg('keyid','RETURN-UNDEF');
3949             }
3950             if (!defined $keyid) {
3951                 $keyid = getfield $clogp, 'Maintainer';
3952             }
3953             unlink $tfn->('.tmp.asc') or $!==&ENOENT or die $!;
3954             my @sign_cmd = (@gpg, qw(--detach-sign --armor));
3955             push @sign_cmd, qw(-u),$keyid if defined $keyid;
3956             push @sign_cmd, $tfn->('.tmp');
3957             runcmd_ordryrun @sign_cmd;
3958             if (act_scary()) {
3959                 $tagobjfn = $tfn->('.signed.tmp');
3960                 runcmd shell_cmd "exec >$tagobjfn", qw(cat --),
3961                     $tfn->('.tmp'), $tfn->('.tmp.asc');
3962             }
3963         }
3964         return $tagobjfn;
3965     };
3966
3967     my @r = map { $mktag->($_); } @$tagwants;
3968     return @r;
3969 }
3970
3971 sub sign_changes ($) {
3972     my ($changesfile) = @_;
3973     if ($sign) {
3974         my @debsign_cmd = @debsign;
3975         push @debsign_cmd, "-k$keyid" if defined $keyid;
3976         push @debsign_cmd, "-p$gpg[0]" if $gpg[0] ne 'gpg';
3977         push @debsign_cmd, $changesfile;
3978         runcmd_ordryrun @debsign_cmd;
3979     }
3980 }
3981
3982 sub dopush () {
3983     printdebug "actually entering push\n";
3984
3985     supplementary_message(<<'END');
3986 Push failed, while checking state of the archive.
3987 You can retry the push, after fixing the problem, if you like.
3988 END
3989     if (check_for_git()) {
3990         git_fetch_us();
3991     }
3992     my $archive_hash = fetch_from_archive();
3993     if (!$archive_hash) {
3994         $new_package or
3995             fail "package appears to be new in this suite;".
3996                 " if this is intentional, use --new";
3997     }
3998
3999     supplementary_message(<<'END');
4000 Push failed, while preparing your push.
4001 You can retry the push, after fixing the problem, if you like.
4002 END
4003
4004     need_tagformat 'new', "quilt mode $quilt_mode"
4005         if quiltmode_splitbrain;
4006
4007     prep_ud();
4008
4009     access_giturl(); # check that success is vaguely likely
4010     rpush_handle_protovsn_bothends() if $we_are_initiator;
4011     select_tagformat();
4012
4013     my $clogpfn = ".git/dgit/changelog.822.tmp";
4014     runcmd shell_cmd "exec >$clogpfn", qw(dpkg-parsechangelog);
4015
4016     responder_send_file('parsed-changelog', $clogpfn);
4017
4018     my ($clogp, $cversion, $dscfn) =
4019         push_parse_changelog("$clogpfn");
4020
4021     my $dscpath = "$buildproductsdir/$dscfn";
4022     stat_exists $dscpath or
4023         fail "looked for .dsc $dscpath, but $!;".
4024             " maybe you forgot to build";
4025
4026     responder_send_file('dsc', $dscpath);
4027
4028     push_parse_dsc($dscpath, $dscfn, $cversion);
4029
4030     my $format = getfield $dsc, 'Format';
4031     printdebug "format $format\n";
4032
4033     my $actualhead = git_rev_parse('HEAD');
4034     my $dgithead = $actualhead;
4035     my $maintviewhead = undef;
4036
4037     my $upstreamversion = upstreamversion $clogp->{Version};
4038
4039     if (madformat_wantfixup($format)) {
4040         # user might have not used dgit build, so maybe do this now:
4041         if (quiltmode_splitbrain()) {
4042             changedir $ud;
4043             quilt_make_fake_dsc($upstreamversion);
4044             my $cachekey;
4045             ($dgithead, $cachekey) =
4046                 quilt_check_splitbrain_cache($actualhead, $upstreamversion);
4047             $dgithead or fail
4048  "--quilt=$quilt_mode but no cached dgit view:
4049  perhaps tree changed since dgit build[-source] ?";
4050             $split_brain = 1;
4051             $dgithead = splitbrain_pseudomerge($clogp,
4052                                                $actualhead, $dgithead,
4053                                                $archive_hash);
4054             $maintviewhead = $actualhead;
4055             changedir '../../../..';
4056             prep_ud(); # so _only_subdir() works, below
4057         } else {
4058             commit_quilty_patch();
4059         }
4060     }
4061
4062     if (defined $overwrite_version && !defined $maintviewhead) {
4063         $dgithead = plain_overwrite_pseudomerge($clogp,
4064                                                 $dgithead,
4065                                                 $archive_hash);
4066     }
4067
4068     check_not_dirty();
4069
4070     my $forceflag = '';
4071     if ($archive_hash) {
4072         if (is_fast_fwd($archive_hash, $dgithead)) {
4073             # ok
4074         } elsif (deliberately_not_fast_forward) {
4075             $forceflag = '+';
4076         } else {
4077             fail "dgit push: HEAD is not a descendant".
4078                 " of the archive's version.\n".
4079                 "To overwrite the archive's contents,".
4080                 " pass --overwrite[=VERSION].\n".
4081                 "To rewind history, if permitted by the archive,".
4082                 " use --deliberately-not-fast-forward.";
4083         }
4084     }
4085
4086     changedir $ud;
4087     progress "checking that $dscfn corresponds to HEAD";
4088     runcmd qw(dpkg-source -x --),
4089         $dscpath =~ m#^/# ? $dscpath : "../../../$dscpath";
4090     my ($tree,$dir) = mktree_in_ud_from_only_subdir("source package");
4091     check_for_vendor_patches() if madformat($dsc->{format});
4092     changedir '../../../..';
4093     my @diffcmd = (@git, qw(diff --quiet), $tree, $dgithead);
4094     debugcmd "+",@diffcmd;
4095     $!=0; $?=-1;
4096     my $r = system @diffcmd;
4097     if ($r) {
4098         if ($r==256) {
4099             my $diffs = cmdoutput @git, qw(diff --stat), $tree, $dgithead;
4100             fail <<END
4101 HEAD specifies a different tree to $dscfn:
4102 $diffs
4103 Perhaps you forgot to build.  Or perhaps there is a problem with your
4104  source tree (see dgit(7) for some hints).  To see a full diff, run
4105    git diff $tree HEAD
4106 END
4107         } else {
4108             failedcmd @diffcmd;
4109         }
4110     }
4111     if (!$changesfile) {
4112         my $pat = changespat $cversion;
4113         my @cs = glob "$buildproductsdir/$pat";
4114         fail "failed to find unique changes file".
4115             " (looked for $pat in $buildproductsdir);".
4116             " perhaps you need to use dgit -C"
4117             unless @cs==1;
4118         ($changesfile) = @cs;
4119     } else {
4120         $changesfile = "$buildproductsdir/$changesfile";
4121     }
4122
4123     # Check that changes and .dsc agree enough
4124     $changesfile =~ m{[^/]*$};
4125     my $changes = parsecontrol($changesfile,$&);
4126     files_compare_inputs($dsc, $changes)
4127         unless forceing [qw(dsc-changes-mismatch)];
4128
4129     # Perhaps adjust .dsc to contain right set of origs
4130     changes_update_origs_from_dsc($dsc, $changes, $upstreamversion,
4131                                   $changesfile)
4132         unless forceing [qw(changes-origs-exactly)];
4133
4134     # Checks complete, we're going to try and go ahead:
4135
4136     responder_send_file('changes',$changesfile);
4137     responder_send_command("param head $dgithead");
4138     responder_send_command("param csuite $csuite");
4139     responder_send_command("param isuite $isuite");
4140     responder_send_command("param tagformat $tagformat");
4141     if (defined $maintviewhead) {
4142         die unless ($protovsn//4) >= 4;
4143         responder_send_command("param maint-view $maintviewhead");
4144     }
4145
4146     if (deliberately_not_fast_forward) {
4147         git_for_each_ref(lrfetchrefs, sub {
4148             my ($objid,$objtype,$lrfetchrefname,$reftail) = @_;
4149             my $rrefname= substr($lrfetchrefname, length(lrfetchrefs) + 1);
4150             responder_send_command("previously $rrefname=$objid");
4151             $previously{$rrefname} = $objid;
4152         });
4153     }
4154
4155     my @tagwants = push_tagwants($cversion, $dgithead, $maintviewhead,
4156                                  ".git/dgit/tag");
4157     my @tagobjfns;
4158
4159     supplementary_message(<<'END');
4160 Push failed, while signing the tag.
4161 You can retry the push, after fixing the problem, if you like.
4162 END
4163     # If we manage to sign but fail to record it anywhere, it's fine.
4164     if ($we_are_responder) {
4165         @tagobjfns = map { $_->{Tfn}('.signed-tmp') } @tagwants;
4166         responder_receive_files('signed-tag', @tagobjfns);
4167     } else {
4168         @tagobjfns = push_mktags($clogp,$dscpath,
4169                               $changesfile,$changesfile,
4170                               \@tagwants);
4171     }
4172     supplementary_message(<<'END');
4173 Push failed, *after* signing the tag.
4174 If you want to try again, you should use a new version number.
4175 END
4176
4177     pairwise { $a->{TagObjFn} = $b } @tagwants, @tagobjfns;
4178
4179     foreach my $tw (@tagwants) {
4180         my $tag = $tw->{Tag};
4181         my $tagobjfn = $tw->{TagObjFn};
4182         my $tag_obj_hash =
4183             cmdoutput @git, qw(hash-object -w -t tag), $tagobjfn;
4184         runcmd_ordryrun @git, qw(verify-tag), $tag_obj_hash;
4185         runcmd_ordryrun_local
4186             @git, qw(update-ref), "refs/tags/$tag", $tag_obj_hash;
4187     }
4188
4189     supplementary_message(<<'END');
4190 Push failed, while updating the remote git repository - see messages above.
4191 If you want to try again, you should use a new version number.
4192 END
4193     if (!check_for_git()) {
4194         create_remote_git_repo();
4195     }
4196
4197     my @pushrefs = $forceflag.$dgithead.":".rrref();
4198     foreach my $tw (@tagwants) {
4199         push @pushrefs, $forceflag."refs/tags/$tw->{Tag}";
4200     }
4201
4202     runcmd_ordryrun @git,
4203         qw(-c push.followTags=false push), access_giturl(), @pushrefs;
4204     runcmd_ordryrun @git, qw(update-ref -m), 'dgit push', lrref(), $dgithead;
4205
4206     supplementary_message(<<'END');
4207 Push failed, while obtaining signatures on the .changes and .dsc.
4208 If it was just that the signature failed, you may try again by using
4209 debsign by hand to sign the changes
4210    $changesfile
4211 and then dput to complete the upload.
4212 If you need to change the package, you must use a new version number.
4213 END
4214     if ($we_are_responder) {
4215         my $dryrunsuffix = act_local() ? "" : ".tmp";
4216         responder_receive_files('signed-dsc-changes',
4217                                 "$dscpath$dryrunsuffix",
4218                                 "$changesfile$dryrunsuffix");
4219     } else {
4220         if (act_local()) {
4221             rename "$dscpath.tmp",$dscpath or die "$dscfn $!";
4222         } else {
4223             progress "[new .dsc left in $dscpath.tmp]";
4224         }
4225         sign_changes $changesfile;
4226     }
4227
4228     supplementary_message(<<END);
4229 Push failed, while uploading package(s) to the archive server.
4230 You can retry the upload of exactly these same files with dput of:
4231   $changesfile
4232 If that .changes file is broken, you will need to use a new version
4233 number for your next attempt at the upload.
4234 END
4235     my $host = access_cfg('upload-host','RETURN-UNDEF');
4236     my @hostarg = defined($host) ? ($host,) : ();
4237     runcmd_ordryrun @dput, @hostarg, $changesfile;
4238     printdone "pushed and uploaded $cversion";
4239
4240     supplementary_message('');
4241     responder_send_command("complete");
4242 }
4243
4244 sub cmd_clone {
4245     parseopts();
4246     my $dstdir;
4247     badusage "-p is not allowed with clone; specify as argument instead"
4248         if defined $package;
4249     if (@ARGV==1) {
4250         ($package) = @ARGV;
4251     } elsif (@ARGV==2 && $ARGV[1] =~ m#^\w#) {
4252         ($package,$isuite) = @ARGV;
4253     } elsif (@ARGV==2 && $ARGV[1] =~ m#^[./]#) {
4254         ($package,$dstdir) = @ARGV;
4255     } elsif (@ARGV==3) {
4256         ($package,$isuite,$dstdir) = @ARGV;
4257     } else {
4258         badusage "incorrect arguments to dgit clone";
4259     }
4260     notpushing();
4261
4262     $dstdir ||= "$package";
4263     if (stat_exists $dstdir) {
4264         fail "$dstdir already exists";
4265     }
4266
4267     my $cwd_remove;
4268     if ($rmonerror && !$dryrun_level) {
4269         $cwd_remove= getcwd();
4270         unshift @end, sub {
4271             return unless defined $cwd_remove;
4272             if (!chdir "$cwd_remove") {
4273                 return if $!==&ENOENT;
4274                 die "chdir $cwd_remove: $!";
4275             }
4276             printdebug "clone rmonerror removing $dstdir\n";
4277             if (stat $dstdir) {
4278                 rmtree($dstdir) or die "remove $dstdir: $!\n";
4279             } elsif (grep { $! == $_ }
4280                      (ENOENT, ENOTDIR, EACCES, EPERM, ELOOP)) {
4281             } else {
4282                 print STDERR "check whether to remove $dstdir: $!\n";
4283             }
4284         };
4285     }
4286
4287     clone($dstdir);
4288     $cwd_remove = undef;
4289 }
4290
4291 sub branchsuite () {
4292     my $branch = cmdoutput_errok @git, qw(symbolic-ref HEAD);
4293     if ($branch =~ m#$lbranch_re#o) {
4294         return $1;
4295     } else {
4296         return undef;
4297     }
4298 }
4299
4300 sub fetchpullargs () {
4301     if (!defined $package) {
4302         my $sourcep = parsecontrol('debian/control','debian/control');
4303         $package = getfield $sourcep, 'Source';
4304     }
4305     if (@ARGV==0) {
4306         $isuite = branchsuite();
4307         if (!$isuite) {
4308             my $clogp = parsechangelog();
4309             my $clogsuite = getfield $clogp, 'Distribution';
4310             $isuite= $clogsuite if $clogsuite ne 'UNRELEASED';
4311         }
4312     } elsif (@ARGV==1) {
4313         ($isuite) = @ARGV;
4314     } else {
4315         badusage "incorrect arguments to dgit fetch or dgit pull";
4316     }
4317     notpushing();
4318 }
4319
4320 sub cmd_fetch {
4321     parseopts();
4322     fetchpullargs();
4323     my $multi_fetched = fork_for_multisuite(sub { });
4324     exit 0 if $multi_fetched;
4325     fetch();
4326 }
4327
4328 sub cmd_pull {
4329     parseopts();
4330     fetchpullargs();
4331     if (quiltmode_splitbrain()) {
4332         my ($format, $fopts) = get_source_format();
4333         madformat($format) and fail <<END
4334 dgit pull not yet supported in split view mode (--quilt=$quilt_mode)
4335 END
4336     }
4337     pull();
4338 }
4339
4340 sub cmd_push {
4341     parseopts();
4342     badusage "-p is not allowed with dgit push" if defined $package;
4343     check_not_dirty();
4344     my $clogp = parsechangelog();
4345     $package = getfield $clogp, 'Source';
4346     my $specsuite;
4347     if (@ARGV==0) {
4348     } elsif (@ARGV==1) {
4349         ($specsuite) = (@ARGV);
4350     } else {
4351         badusage "incorrect arguments to dgit push";
4352     }
4353     $isuite = getfield $clogp, 'Distribution';
4354     pushing();
4355     if ($new_package) {
4356         local ($package) = $existing_package; # this is a hack
4357         canonicalise_suite();
4358     } else {
4359         canonicalise_suite();
4360     }
4361     if (defined $specsuite &&
4362         $specsuite ne $isuite &&
4363         $specsuite ne $csuite) {
4364             fail "dgit push: changelog specifies $isuite ($csuite)".
4365                 " but command line specifies $specsuite";
4366     }
4367     dopush();
4368 }
4369
4370 #---------- remote commands' implementation ----------
4371
4372 sub cmd_remote_push_build_host {
4373     my ($nrargs) = shift @ARGV;
4374     my (@rargs) = @ARGV[0..$nrargs-1];
4375     @ARGV = @ARGV[$nrargs..$#ARGV];
4376     die unless @rargs;
4377     my ($dir,$vsnwant) = @rargs;
4378     # vsnwant is a comma-separated list; we report which we have
4379     # chosen in our ready response (so other end can tell if they
4380     # offered several)
4381     $debugprefix = ' ';
4382     $we_are_responder = 1;
4383     $us .= " (build host)";
4384
4385     open PI, "<&STDIN" or die $!;
4386     open STDIN, "/dev/null" or die $!;
4387     open PO, ">&STDOUT" or die $!;
4388     autoflush PO 1;
4389     open STDOUT, ">&STDERR" or die $!;
4390     autoflush STDOUT 1;
4391
4392     $vsnwant //= 1;
4393     ($protovsn) = grep {
4394         $vsnwant =~ m{^(?:.*,)?$_(?:,.*)?$}
4395     } @rpushprotovsn_support;
4396
4397     fail "build host has dgit rpush protocol versions ".
4398         (join ",", @rpushprotovsn_support).
4399         " but invocation host has $vsnwant"
4400         unless defined $protovsn;
4401
4402     responder_send_command("dgit-remote-push-ready $protovsn");
4403     changedir $dir;
4404     &cmd_push;
4405 }
4406
4407 sub cmd_remote_push_responder { cmd_remote_push_build_host(); }
4408 # ... for compatibility with proto vsn.1 dgit (just so that user gets
4409 #     a good error message)
4410
4411 sub rpush_handle_protovsn_bothends () {
4412     if ($protovsn < 4) {
4413         need_tagformat 'old', "rpush negotiated protocol $protovsn";
4414     }
4415     select_tagformat();
4416 }
4417
4418 our $i_tmp;
4419
4420 sub i_cleanup {
4421     local ($@, $?);
4422     my $report = i_child_report();
4423     if (defined $report) {
4424         printdebug "($report)\n";
4425     } elsif ($i_child_pid) {
4426         printdebug "(killing build host child $i_child_pid)\n";
4427         kill 15, $i_child_pid;
4428     }
4429     if (defined $i_tmp && !defined $initiator_tempdir) {
4430         changedir "/";
4431         eval { rmtree $i_tmp; };
4432     }
4433 }
4434
4435 END { i_cleanup(); }
4436
4437 sub i_method {
4438     my ($base,$selector,@args) = @_;
4439     $selector =~ s/\-/_/g;
4440     { no strict qw(refs); &{"${base}_${selector}"}(@args); }
4441 }
4442
4443 sub cmd_rpush {
4444     my $host = nextarg;
4445     my $dir;
4446     if ($host =~ m/^((?:[^][]|\[[^][]*\])*)\:/) {
4447         $host = $1;
4448         $dir = $'; #';
4449     } else {
4450         $dir = nextarg;
4451     }
4452     $dir =~ s{^-}{./-};
4453     my @rargs = ($dir);
4454     push @rargs, join ",", @rpushprotovsn_support;
4455     my @rdgit;
4456     push @rdgit, @dgit;
4457     push @rdgit, @ropts;
4458     push @rdgit, qw(remote-push-build-host), (scalar @rargs), @rargs;
4459     push @rdgit, @ARGV;
4460     my @cmd = (@ssh, $host, shellquote @rdgit);
4461     debugcmd "+",@cmd;
4462
4463     $we_are_initiator=1;
4464
4465     if (defined $initiator_tempdir) {
4466         rmtree $initiator_tempdir;
4467         mkdir $initiator_tempdir, 0700 or die "$initiator_tempdir: $!";
4468         $i_tmp = $initiator_tempdir;
4469     } else {
4470         $i_tmp = tempdir();
4471     }
4472     $i_child_pid = open2(\*RO, \*RI, @cmd);
4473     changedir $i_tmp;
4474     ($protovsn) = initiator_expect { m/^dgit-remote-push-ready (\S+)/ };
4475     die "$protovsn ?" unless grep { $_ eq $protovsn } @rpushprotovsn_support;
4476     $supplementary_message = '' unless $protovsn >= 3;
4477
4478     for (;;) {
4479         my ($icmd,$iargs) = initiator_expect {
4480             m/^(\S+)(?: (.*))?$/;
4481             ($1,$2);
4482         };
4483         i_method "i_resp", $icmd, $iargs;
4484     }
4485 }
4486
4487 sub i_resp_progress ($) {
4488     my ($rhs) = @_;
4489     my $msg = protocol_read_bytes \*RO, $rhs;
4490     progress $msg;
4491 }
4492
4493 sub i_resp_supplementary_message ($) {
4494     my ($rhs) = @_;
4495     $supplementary_message = protocol_read_bytes \*RO, $rhs;
4496 }
4497
4498 sub i_resp_complete {
4499     my $pid = $i_child_pid;
4500     $i_child_pid = undef; # prevents killing some other process with same pid
4501     printdebug "waiting for build host child $pid...\n";
4502     my $got = waitpid $pid, 0;
4503     die $! unless $got == $pid;
4504     die "build host child failed $?" if $?;
4505
4506     i_cleanup();
4507     printdebug "all done\n";
4508     exit 0;
4509 }
4510
4511 sub i_resp_file ($) {
4512     my ($keyword) = @_;
4513     my $localname = i_method "i_localname", $keyword;
4514     my $localpath = "$i_tmp/$localname";
4515     stat_exists $localpath and
4516         badproto \*RO, "file $keyword ($localpath) twice";
4517     protocol_receive_file \*RO, $localpath;
4518     i_method "i_file", $keyword;
4519 }
4520
4521 our %i_param;
4522
4523 sub i_resp_param ($) {
4524     $_[0] =~ m/^(\S+) (.*)$/ or badproto \*RO, "bad param spec";
4525     $i_param{$1} = $2;
4526 }
4527
4528 sub i_resp_previously ($) {
4529     $_[0] =~ m#^(refs/tags/\S+)=(\w+)$#
4530         or badproto \*RO, "bad previously spec";
4531     my $r = system qw(git check-ref-format), $1;
4532     die "bad previously ref spec ($r)" if $r;
4533     $previously{$1} = $2;
4534 }
4535
4536 our %i_wanted;
4537
4538 sub i_resp_want ($) {
4539     my ($keyword) = @_;
4540     die "$keyword ?" if $i_wanted{$keyword}++;
4541
4542     defined $i_param{'csuite'} or badproto \*RO, "premature desire, no csuite";
4543     $isuite = $i_param{'isuite'} // $i_param{'csuite'};
4544     die unless $isuite =~ m/^$suite_re$/;
4545
4546     pushing();
4547     rpush_handle_protovsn_bothends();
4548
4549     fail "rpush negotiated protocol version $protovsn".
4550         " which does not support quilt mode $quilt_mode"
4551         if quiltmode_splitbrain;
4552
4553     my @localpaths = i_method "i_want", $keyword;
4554     printdebug "[[  $keyword @localpaths\n";
4555     foreach my $localpath (@localpaths) {
4556         protocol_send_file \*RI, $localpath;
4557     }
4558     print RI "files-end\n" or die $!;
4559 }
4560
4561 our ($i_clogp, $i_version, $i_dscfn, $i_changesfn);
4562
4563 sub i_localname_parsed_changelog {
4564     return "remote-changelog.822";
4565 }
4566 sub i_file_parsed_changelog {
4567     ($i_clogp, $i_version, $i_dscfn) =
4568         push_parse_changelog "$i_tmp/remote-changelog.822";
4569     die if $i_dscfn =~ m#/|^\W#;
4570 }
4571
4572 sub i_localname_dsc {
4573     defined $i_dscfn or badproto \*RO, "dsc (before parsed-changelog)";
4574     return $i_dscfn;
4575 }
4576 sub i_file_dsc { }
4577
4578 sub i_localname_changes {
4579     defined $i_dscfn or badproto \*RO, "dsc (before parsed-changelog)";
4580     $i_changesfn = $i_dscfn;
4581     $i_changesfn =~ s/\.dsc$/_dgit.changes/ or die;
4582     return $i_changesfn;
4583 }
4584 sub i_file_changes { }
4585
4586 sub i_want_signed_tag {
4587     printdebug Dumper(\%i_param, $i_dscfn);
4588     defined $i_param{'head'} && defined $i_dscfn && defined $i_clogp
4589         && defined $i_param{'csuite'}
4590         or badproto \*RO, "premature desire for signed-tag";
4591     my $head = $i_param{'head'};
4592     die if $head =~ m/[^0-9a-f]/ || $head !~ m/^../;
4593
4594     my $maintview = $i_param{'maint-view'};
4595     die if defined $maintview && $maintview =~ m/[^0-9a-f]/;
4596
4597     select_tagformat();
4598     if ($protovsn >= 4) {
4599         my $p = $i_param{'tagformat'} // '<undef>';
4600         $p eq $tagformat
4601             or badproto \*RO, "tag format mismatch: $p vs. $tagformat";
4602     }
4603
4604     die unless $i_param{'csuite'} =~ m/^$suite_re$/;
4605     $csuite = $&;
4606     push_parse_dsc $i_dscfn, 'remote dsc', $i_version;
4607
4608     my @tagwants = push_tagwants $i_version, $head, $maintview, "tag";
4609
4610     return
4611         push_mktags $i_clogp, $i_dscfn,
4612             $i_changesfn, 'remote changes',
4613             \@tagwants;
4614 }
4615
4616 sub i_want_signed_dsc_changes {
4617     rename "$i_dscfn.tmp","$i_dscfn" or die "$i_dscfn $!";
4618     sign_changes $i_changesfn;
4619     return ($i_dscfn, $i_changesfn);
4620 }
4621
4622 #---------- building etc. ----------
4623
4624 our $version;
4625 our $sourcechanges;
4626 our $dscfn;
4627
4628 #----- `3.0 (quilt)' handling -----
4629
4630 our $fakeeditorenv = 'DGIT_FAKE_EDITOR_QUILT';
4631
4632 sub quiltify_dpkg_commit ($$$;$) {
4633     my ($patchname,$author,$msg, $xinfo) = @_;
4634     $xinfo //= '';
4635
4636     mkpath '.git/dgit';
4637     my $descfn = ".git/dgit/quilt-description.tmp";
4638     open O, '>', $descfn or die "$descfn: $!";
4639     $msg =~ s/\n+/\n\n/;
4640     print O <<END or die $!;
4641 From: $author
4642 ${xinfo}Subject: $msg
4643 ---
4644
4645 END
4646     close O or die $!;
4647
4648     {
4649         local $ENV{'EDITOR'} = cmdoutput qw(realpath --), $0;
4650         local $ENV{'VISUAL'} = $ENV{'EDITOR'};
4651         local $ENV{$fakeeditorenv} = cmdoutput qw(realpath --), $descfn;
4652         runcmd @dpkgsource, qw(--commit --include-removal .), $patchname;
4653     }
4654 }
4655
4656 sub quiltify_trees_differ ($$;$$$) {
4657     my ($x,$y,$finegrained,$ignorenamesr,$unrepres) = @_;
4658     # returns true iff the two tree objects differ other than in debian/
4659     # with $finegrained,
4660     # returns bitmask 01 - differ in upstream files except .gitignore
4661     #                 02 - differ in .gitignore
4662     # if $ignorenamesr is defined, $ingorenamesr->{$fn}
4663     #  is set for each modified .gitignore filename $fn
4664     # if $unrepres is defined, array ref to which is appeneded
4665     #  a list of unrepresentable changes (removals of upstream files
4666     #  (as messages)
4667     local $/=undef;
4668     my @cmd = (@git, qw(diff-tree -z));
4669     push @cmd, qw(--name-only) unless $unrepres;
4670     push @cmd, qw(-r) if $finegrained || $unrepres;
4671     push @cmd, $x, $y;
4672     my $diffs= cmdoutput @cmd;
4673     my $r = 0;
4674     my @lmodes;
4675     foreach my $f (split /\0/, $diffs) {
4676         if ($unrepres && !@lmodes) {
4677             @lmodes = $f =~ m/^\:(\w+) (\w+) \w+ \w+ / or die "$_ ?";
4678             next;
4679         }
4680         my ($oldmode,$newmode) = @lmodes;
4681         @lmodes = ();
4682
4683         next if $f =~ m#^debian(?:/.*)?$#s;
4684
4685         if ($unrepres) {
4686             eval {
4687                 die "not a plain file\n"
4688                     unless $newmode =~ m/^10\d{4}$/ ||
4689                            $oldmode =~ m/^10\d{4}$/;
4690                 if ($oldmode =~ m/[^0]/ &&
4691                     $newmode =~ m/[^0]/) {
4692                     die "mode changed\n" if $oldmode ne $newmode;
4693                 } else {
4694                     die "non-default mode\n"
4695                         unless $newmode =~ m/^100644$/ ||
4696                                $oldmode =~ m/^100644$/;
4697                 }
4698             };
4699             if ($@) {
4700                 local $/="\n"; chomp $@;
4701                 push @$unrepres, [ $f, "$@ ($oldmode->$newmode)" ];
4702             }
4703         }
4704
4705         my $isignore = $f =~ m#^(?:.*/)?.gitignore$#s;
4706         $r |= $isignore ? 02 : 01;
4707         $ignorenamesr->{$f}=1 if $ignorenamesr && $isignore;
4708     }
4709     printdebug "quiltify_trees_differ $x $y => $r\n";
4710     return $r;
4711 }
4712
4713 sub quiltify_tree_sentinelfiles ($) {
4714     # lists the `sentinel' files present in the tree
4715     my ($x) = @_;
4716     my $r = cmdoutput @git, qw(ls-tree --name-only), $x,
4717         qw(-- debian/rules debian/control);
4718     $r =~ s/\n/,/g;
4719     return $r;
4720 }
4721
4722 sub quiltify_splitbrain_needed () {
4723     if (!$split_brain) {
4724         progress "dgit view: changes are required...";
4725         runcmd @git, qw(checkout -q -b dgit-view);
4726         $split_brain = 1;
4727     }
4728 }
4729
4730 sub quiltify_splitbrain ($$$$$$) {
4731     my ($clogp, $unapplied, $headref, $diffbits,
4732         $editedignores, $cachekey) = @_;
4733     if ($quilt_mode !~ m/gbp|dpm/) {
4734         # treat .gitignore just like any other upstream file
4735         $diffbits = { %$diffbits };
4736         $_ = !!$_ foreach values %$diffbits;
4737     }
4738     # We would like any commits we generate to be reproducible
4739     my @authline = clogp_authline($clogp);
4740     local $ENV{GIT_COMMITTER_NAME} =  $authline[0];
4741     local $ENV{GIT_COMMITTER_EMAIL} = $authline[1];
4742     local $ENV{GIT_COMMITTER_DATE} =  $authline[2];
4743     local $ENV{GIT_AUTHOR_NAME} =  $authline[0];
4744     local $ENV{GIT_AUTHOR_EMAIL} = $authline[1];
4745     local $ENV{GIT_AUTHOR_DATE} =  $authline[2];
4746
4747     if ($quilt_mode =~ m/gbp|unapplied/ &&
4748         ($diffbits->{O2H} & 01)) {
4749         my $msg =
4750  "--quilt=$quilt_mode specified, implying patches-unapplied git tree\n".
4751  " but git tree differs from orig in upstream files.";
4752         if (!stat_exists "debian/patches") {
4753             $msg .=
4754  "\n ... debian/patches is missing; perhaps this is a patch queue branch?";
4755         }
4756         fail $msg;
4757     }
4758     if ($quilt_mode =~ m/dpm/ &&
4759         ($diffbits->{H2A} & 01)) {
4760         fail <<END;
4761 --quilt=$quilt_mode specified, implying patches-applied git tree
4762  but git tree differs from result of applying debian/patches to upstream
4763 END
4764     }
4765     if ($quilt_mode =~ m/gbp|unapplied/ &&
4766         ($diffbits->{O2A} & 01)) { # some patches
4767         quiltify_splitbrain_needed();
4768         progress "dgit view: creating patches-applied version using gbp pq";
4769         runcmd shell_cmd 'exec >/dev/null', gbp_pq, qw(import);
4770         # gbp pq import creates a fresh branch; push back to dgit-view
4771         runcmd @git, qw(update-ref refs/heads/dgit-view HEAD);
4772         runcmd @git, qw(checkout -q dgit-view);
4773     }
4774     if ($quilt_mode =~ m/gbp|dpm/ &&
4775         ($diffbits->{O2A} & 02)) {
4776         fail <<END
4777 --quilt=$quilt_mode specified, implying that HEAD is for use with a
4778  tool which does not create patches for changes to upstream
4779  .gitignores: but, such patches exist in debian/patches.
4780 END
4781     }
4782     if (($diffbits->{O2H} & 02) && # user has modified .gitignore
4783         !($diffbits->{O2A} & 02)) { # patches do not change .gitignore
4784         quiltify_splitbrain_needed();
4785         progress "dgit view: creating patch to represent .gitignore changes";
4786         ensuredir "debian/patches";
4787         my $gipatch = "debian/patches/auto-gitignore";
4788         open GIPATCH, ">>", "$gipatch" or die "$gipatch: $!";
4789         stat GIPATCH or die "$gipatch: $!";
4790         fail "$gipatch already exists; but want to create it".
4791             " to record .gitignore changes" if (stat _)[7];
4792         print GIPATCH <<END or die "$gipatch: $!";
4793 Subject: Update .gitignore from Debian packaging branch
4794
4795 The Debian packaging git branch contains these updates to the upstream
4796 .gitignore file(s).  This patch is autogenerated, to provide these
4797 updates to users of the official Debian archive view of the package.
4798
4799 [dgit ($our_version) update-gitignore]
4800 ---
4801 END
4802         close GIPATCH or die "$gipatch: $!";
4803         runcmd shell_cmd "exec >>$gipatch", @git, qw(diff),
4804             $unapplied, $headref, "--", sort keys %$editedignores;
4805         open SERIES, "+>>", "debian/patches/series" or die $!;
4806         defined seek SERIES, -1, 2 or $!==EINVAL or die $!;
4807         my $newline;
4808         defined read SERIES, $newline, 1 or die $!;
4809         print SERIES "\n" or die $! unless $newline eq "\n";
4810         print SERIES "auto-gitignore\n" or die $!;
4811         close SERIES or die  $!;
4812         runcmd @git, qw(add -- debian/patches/series), $gipatch;
4813         commit_admin <<END
4814 Commit patch to update .gitignore
4815
4816 [dgit ($our_version) update-gitignore-quilt-fixup]
4817 END
4818     }
4819
4820     my $dgitview = git_rev_parse 'HEAD';
4821
4822     changedir '../../../..';
4823     # When we no longer need to support squeeze, use --create-reflog
4824     # instead of this:
4825     ensuredir ".git/logs/refs/dgit-intern";
4826     my $makelogfh = new IO::File ".git/logs/refs/$splitbraincache", '>>'
4827       or die $!;
4828
4829     my $oldcache = git_get_ref "refs/$splitbraincache";
4830     if ($oldcache eq $dgitview) {
4831         my $tree = cmdoutput qw(git rev-parse), "$dgitview:";
4832         # git update-ref doesn't always update, in this case.  *sigh*
4833         my $dummy = make_commit_text <<END;
4834 tree $tree
4835 parent $dgitview
4836 author Dgit <dgit\@example.com> 1000000000 +0000
4837 committer Dgit <dgit\@example.com> 1000000000 +0000
4838
4839 Dummy commit - do not use
4840 END
4841         runcmd @git, qw(update-ref -m), "dgit $our_version - dummy",
4842             "refs/$splitbraincache", $dummy;
4843     }
4844     runcmd @git, qw(update-ref -m), $cachekey, "refs/$splitbraincache",
4845         $dgitview;
4846
4847     changedir '.git/dgit/unpack/work';
4848
4849     my $saved = maybe_split_brain_save $headref, $dgitview, "converted";
4850     progress "dgit view: created ($saved)";
4851 }
4852
4853 sub quiltify ($$$$) {
4854     my ($clogp,$target,$oldtiptree,$failsuggestion) = @_;
4855
4856     # Quilt patchification algorithm
4857     #
4858     # We search backwards through the history of the main tree's HEAD
4859     # (T) looking for a start commit S whose tree object is identical
4860     # to to the patch tip tree (ie the tree corresponding to the
4861     # current dpkg-committed patch series).  For these purposes
4862     # `identical' disregards anything in debian/ - this wrinkle is
4863     # necessary because dpkg-source treates debian/ specially.
4864     #
4865     # We can only traverse edges where at most one of the ancestors'
4866     # trees differs (in changes outside in debian/).  And we cannot
4867     # handle edges which change .pc/ or debian/patches.  To avoid
4868     # going down a rathole we avoid traversing edges which introduce
4869     # debian/rules or debian/control.  And we set a limit on the
4870     # number of edges we are willing to look at.
4871     #
4872     # If we succeed, we walk forwards again.  For each traversed edge
4873     # PC (with P parent, C child) (starting with P=S and ending with
4874     # C=T) to we do this:
4875     #  - git checkout C
4876     #  - dpkg-source --commit with a patch name and message derived from C
4877     # After traversing PT, we git commit the changes which
4878     # should be contained within debian/patches.
4879
4880     # The search for the path S..T is breadth-first.  We maintain a
4881     # todo list containing search nodes.  A search node identifies a
4882     # commit, and looks something like this:
4883     #  $p = {
4884     #      Commit => $git_commit_id,
4885     #      Child => $c,                          # or undef if P=T
4886     #      Whynot => $reason_edge_PC_unsuitable, # in @nots only
4887     #      Nontrivial => true iff $p..$c has relevant changes
4888     #  };
4889
4890     my @todo;
4891     my @nots;
4892     my $sref_S;
4893     my $max_work=100;
4894     my %considered; # saves being exponential on some weird graphs
4895
4896     my $t_sentinels = quiltify_tree_sentinelfiles $target;
4897
4898     my $not = sub {
4899         my ($search,$whynot) = @_;
4900         printdebug " search NOT $search->{Commit} $whynot\n";
4901         $search->{Whynot} = $whynot;
4902         push @nots, $search;
4903         no warnings qw(exiting);
4904         next;
4905     };
4906
4907     push @todo, {
4908         Commit => $target,
4909     };
4910
4911     while (@todo) {
4912         my $c = shift @todo;
4913         next if $considered{$c->{Commit}}++;
4914
4915         $not->($c, "maximum search space exceeded") if --$max_work <= 0;
4916
4917         printdebug "quiltify investigate $c->{Commit}\n";
4918
4919         # are we done?
4920         if (!quiltify_trees_differ $c->{Commit}, $oldtiptree) {
4921             printdebug " search finished hooray!\n";
4922             $sref_S = $c;
4923             last;
4924         }
4925
4926         if ($quilt_mode eq 'nofix') {
4927             fail "quilt fixup required but quilt mode is \`nofix'\n".
4928                 "HEAD commit $c->{Commit} differs from tree implied by ".
4929                 " debian/patches (tree object $oldtiptree)";
4930         }
4931         if ($quilt_mode eq 'smash') {
4932             printdebug " search quitting smash\n";
4933             last;
4934         }
4935
4936         my $c_sentinels = quiltify_tree_sentinelfiles $c->{Commit};
4937         $not->($c, "has $c_sentinels not $t_sentinels")
4938             if $c_sentinels ne $t_sentinels;
4939
4940         my $commitdata = cmdoutput @git, qw(cat-file commit), $c->{Commit};
4941         $commitdata =~ m/\n\n/;
4942         $commitdata =~ $`;
4943         my @parents = ($commitdata =~ m/^parent (\w+)$/gm);
4944         @parents = map { { Commit => $_, Child => $c } } @parents;
4945
4946         $not->($c, "root commit") if !@parents;
4947
4948         foreach my $p (@parents) {
4949             $p->{Nontrivial}= quiltify_trees_differ $p->{Commit},$c->{Commit};
4950         }
4951         my $ndiffers = grep { $_->{Nontrivial} } @parents;
4952         $not->($c, "merge ($ndiffers nontrivial parents)") if $ndiffers > 1;
4953
4954         foreach my $p (@parents) {
4955             printdebug "considering C=$c->{Commit} P=$p->{Commit}\n";
4956
4957             my @cmd= (@git, qw(diff-tree -r --name-only),
4958                       $p->{Commit},$c->{Commit}, qw(-- debian/patches .pc));
4959             my $patchstackchange = cmdoutput @cmd;
4960             if (length $patchstackchange) {
4961                 $patchstackchange =~ s/\n/,/g;
4962                 $not->($p, "changed $patchstackchange");
4963             }
4964
4965             printdebug " search queue P=$p->{Commit} ",
4966                 ($p->{Nontrivial} ? "NT" : "triv"),"\n";
4967             push @todo, $p;
4968         }
4969     }
4970
4971     if (!$sref_S) {
4972         printdebug "quiltify want to smash\n";
4973
4974         my $abbrev = sub {
4975             my $x = $_[0]{Commit};
4976             $x =~ s/(.*?[0-9a-z]{8})[0-9a-z]*$/$1/;
4977             return $x;
4978         };
4979         my $reportnot = sub {
4980             my ($notp) = @_;
4981             my $s = $abbrev->($notp);
4982             my $c = $notp->{Child};
4983             $s .= "..".$abbrev->($c) if $c;
4984             $s .= ": ".$notp->{Whynot};
4985             return $s;
4986         };
4987         if ($quilt_mode eq 'linear') {
4988             print STDERR "$us: quilt fixup cannot be linear.  Stopped at:\n";
4989             foreach my $notp (@nots) {
4990                 print STDERR "$us:  ", $reportnot->($notp), "\n";
4991             }
4992             print STDERR "$us: $_\n" foreach @$failsuggestion;
4993             fail "quilt fixup naive history linearisation failed.\n".
4994  "Use dpkg-source --commit by hand; or, --quilt=smash for one ugly patch";
4995         } elsif ($quilt_mode eq 'smash') {
4996         } elsif ($quilt_mode eq 'auto') {
4997             progress "quilt fixup cannot be linear, smashing...";
4998         } else {
4999             die "$quilt_mode ?";
5000         }
5001
5002         my $time = $ENV{'GIT_COMMITTER_DATE'} || time;
5003         $time =~ s/\s.*//; # trim timezone from GIT_COMMITTER_DATE
5004         my $ncommits = 3;
5005         my $msg = cmdoutput @git, qw(log), "-n$ncommits";
5006
5007         quiltify_dpkg_commit "auto-$version-$target-$time",
5008             (getfield $clogp, 'Maintainer'),
5009             "Automatically generated patch ($clogp->{Version})\n".
5010             "Last (up to) $ncommits git changes, FYI:\n\n". $msg;
5011         return;
5012     }
5013
5014     progress "quiltify linearisation planning successful, executing...";
5015
5016     for (my $p = $sref_S;
5017          my $c = $p->{Child};
5018          $p = $p->{Child}) {
5019         printdebug "quiltify traverse $p->{Commit}..$c->{Commit}\n";
5020         next unless $p->{Nontrivial};
5021
5022         my $cc = $c->{Commit};
5023
5024         my $commitdata = cmdoutput @git, qw(cat-file commit), $cc;
5025         $commitdata =~ m/\n\n/ or die "$c ?";
5026         $commitdata = $`;
5027         my $msg = $'; #';
5028         $commitdata =~ m/^author (.*) \d+ [-+0-9]+$/m or die "$cc ?";
5029         my $author = $1;
5030
5031         my $commitdate = cmdoutput
5032             @git, qw(log -n1 --pretty=format:%aD), $cc;
5033
5034         $msg =~ s/^(.*)\n*/$1\n/ or die "$cc $msg ?";
5035
5036         my $strip_nls = sub { $msg =~ s/\n+$//; $msg .= "\n"; };
5037         $strip_nls->();
5038
5039         my $title = $1;
5040         my $patchname;
5041         my $patchdir;
5042
5043         my $gbp_check_suitable = sub {
5044             $_ = shift;
5045             my ($what) = @_;
5046
5047             eval {
5048                 die "contains unexpected slashes\n" if m{//} || m{/$};
5049                 die "contains leading punctuation\n" if m{^\W} || m{/\W};
5050                 die "contains bad character(s)\n" if m{[^-a-z0-9_.+=~/]}i;
5051                 die "too long" if length > 200;
5052             };
5053             return $_ unless $@;
5054             print STDERR "quiltifying commit $cc:".
5055                 " ignoring/dropping Gbp-Pq $what: $@";
5056             return undef;
5057         };
5058
5059         if ($msg =~ s/^ (?: gbp(?:-pq)? : \s* name \s+ |
5060                            gbp-pq-name: \s* )
5061                        (\S+) \s* \n //ixm) {
5062             $patchname = $gbp_check_suitable->($1, 'Name');
5063         }
5064         if ($msg =~ s/^ (?: gbp(?:-pq)? : \s* topic \s+ |
5065                            gbp-pq-topic: \s* )
5066                        (\S+) \s* \n //ixm) {
5067             $patchdir = $gbp_check_suitable->($1, 'Topic');
5068         }
5069
5070         $strip_nls->();
5071
5072         if (!defined $patchname) {
5073             $patchname = $title;
5074             $patchname =~ s/[.:]$//;
5075             use Text::Iconv;
5076             eval {
5077                 my $converter = new Text::Iconv qw(UTF-8 ASCII//TRANSLIT);
5078                 my $translitname = $converter->convert($patchname);
5079                 die unless defined $translitname;
5080                 $patchname = $translitname;
5081             };
5082             print STDERR
5083                 "dgit: patch title transliteration error: $@"
5084                 if $@;
5085             $patchname =~ y/ A-Z/-a-z/;
5086             $patchname =~ y/-a-z0-9_.+=~//cd;
5087             $patchname =~ s/^\W/x-$&/;
5088             $patchname = substr($patchname,0,40);
5089         }
5090         if (!defined $patchdir) {
5091             $patchdir = '';
5092         }
5093         if (length $patchdir) {
5094             $patchname = "$patchdir/$patchname";
5095         }
5096         if ($patchname =~ m{^(.*)/}) {
5097             mkpath "debian/patches/$1";
5098         }
5099
5100         my $index;
5101         for ($index='';
5102              stat "debian/patches/$patchname$index";
5103              $index++) { }
5104         $!==ENOENT or die "$patchname$index $!";
5105
5106         runcmd @git, qw(checkout -q), $cc;
5107
5108         # We use the tip's changelog so that dpkg-source doesn't
5109         # produce complaining messages from dpkg-parsechangelog.  None
5110         # of the information dpkg-source gets from the changelog is
5111         # actually relevant - it gets put into the original message
5112         # which dpkg-source provides our stunt editor, and then
5113         # overwritten.
5114         runcmd @git, qw(checkout -q), $target, qw(debian/changelog);
5115
5116         quiltify_dpkg_commit "$patchname$index", $author, $msg,
5117             "Date: $commitdate\n".
5118             "X-Dgit-Generated: $clogp->{Version} $cc\n";
5119
5120         runcmd @git, qw(checkout -q), $cc, qw(debian/changelog);
5121     }
5122
5123     runcmd @git, qw(checkout -q master);
5124 }
5125
5126 sub build_maybe_quilt_fixup () {
5127     my ($format,$fopts) = get_source_format;
5128     return unless madformat_wantfixup $format;
5129     # sigh
5130
5131     check_for_vendor_patches();
5132
5133     if (quiltmode_splitbrain) {
5134         fail <<END unless access_cfg_tagformats_can_splitbrain;
5135 quilt mode $quilt_mode requires split view so server needs to support
5136  both "new" and "maint" tag formats, but config says it doesn't.
5137 END
5138     }
5139
5140     my $clogp = parsechangelog();
5141     my $headref = git_rev_parse('HEAD');
5142
5143     prep_ud();
5144     changedir $ud;
5145
5146     my $upstreamversion = upstreamversion $version;
5147
5148     if ($fopts->{'single-debian-patch'}) {
5149         quilt_fixup_singlepatch($clogp, $headref, $upstreamversion);
5150     } else {
5151         quilt_fixup_multipatch($clogp, $headref, $upstreamversion);
5152     }
5153
5154     die 'bug' if $split_brain && !$need_split_build_invocation;
5155
5156     changedir '../../../..';
5157     runcmd_ordryrun_local
5158         @git, qw(pull --ff-only -q .git/dgit/unpack/work master);
5159 }
5160
5161 sub quilt_fixup_mkwork ($) {
5162     my ($headref) = @_;
5163
5164     mkdir "work" or die $!;
5165     changedir "work";
5166     mktree_in_ud_here();
5167     runcmd @git, qw(reset -q --hard), $headref;
5168 }
5169
5170 sub quilt_fixup_linkorigs ($$) {
5171     my ($upstreamversion, $fn) = @_;
5172     # calls $fn->($leafname);
5173
5174     foreach my $f (<../../../../*>) { #/){
5175         my $b=$f; $b =~ s{.*/}{};
5176         {
5177             local ($debuglevel) = $debuglevel-1;
5178             printdebug "QF linkorigs $b, $f ?\n";
5179         }
5180         next unless is_orig_file_of_vsn $b, $upstreamversion;
5181         printdebug "QF linkorigs $b, $f Y\n";
5182         link_ltarget $f, $b or die "$b $!";
5183         $fn->($b);
5184     }
5185 }
5186
5187 sub quilt_fixup_delete_pc () {
5188     runcmd @git, qw(rm -rqf .pc);
5189     commit_admin <<END
5190 Commit removal of .pc (quilt series tracking data)
5191
5192 [dgit ($our_version) upgrade quilt-remove-pc]
5193 END
5194 }
5195
5196 sub quilt_fixup_singlepatch ($$$) {
5197     my ($clogp, $headref, $upstreamversion) = @_;
5198
5199     progress "starting quiltify (single-debian-patch)";
5200
5201     # dpkg-source --commit generates new patches even if
5202     # single-debian-patch is in debian/source/options.  In order to
5203     # get it to generate debian/patches/debian-changes, it is
5204     # necessary to build the source package.
5205
5206     quilt_fixup_linkorigs($upstreamversion, sub { });
5207     quilt_fixup_mkwork($headref);
5208
5209     rmtree("debian/patches");
5210
5211     runcmd @dpkgsource, qw(-b .);
5212     changedir "..";
5213     runcmd @dpkgsource, qw(-x), (srcfn $version, ".dsc");
5214     rename srcfn("$upstreamversion", "/debian/patches"),
5215            "work/debian/patches";
5216
5217     changedir "work";
5218     commit_quilty_patch();
5219 }
5220
5221 sub quilt_make_fake_dsc ($) {
5222     my ($upstreamversion) = @_;
5223
5224     my $fakeversion="$upstreamversion-~~DGITFAKE";
5225
5226     my $fakedsc=new IO::File 'fake.dsc', '>' or die $!;
5227     print $fakedsc <<END or die $!;
5228 Format: 3.0 (quilt)
5229 Source: $package
5230 Version: $fakeversion
5231 Files:
5232 END
5233
5234     my $dscaddfile=sub {
5235         my ($b) = @_;
5236
5237         my $md = new Digest::MD5;
5238
5239         my $fh = new IO::File $b, '<' or die "$b $!";
5240         stat $fh or die $!;
5241         my $size = -s _;
5242
5243         $md->addfile($fh);
5244         print $fakedsc " ".$md->hexdigest." $size $b\n" or die $!;
5245     };
5246
5247     quilt_fixup_linkorigs($upstreamversion, $dscaddfile);
5248
5249     my @files=qw(debian/source/format debian/rules
5250                  debian/control debian/changelog);
5251     foreach my $maybe (qw(debian/patches debian/source/options
5252                           debian/tests/control)) {
5253         next unless stat_exists "../../../$maybe";
5254         push @files, $maybe;
5255     }
5256
5257     my $debtar= srcfn $fakeversion,'.debian.tar.gz';
5258     runcmd qw(env GZIP=-1n tar -zcf), "./$debtar", qw(-C ../../..), @files;
5259
5260     $dscaddfile->($debtar);
5261     close $fakedsc or die $!;
5262 }
5263
5264 sub quilt_check_splitbrain_cache ($$) {
5265     my ($headref, $upstreamversion) = @_;
5266     # Called only if we are in (potentially) split brain mode.
5267     # Called in $ud.
5268     # Computes the cache key and looks in the cache.
5269     # Returns ($dgit_view_commitid, $cachekey) or (undef, $cachekey)
5270
5271     my $splitbrain_cachekey;
5272
5273     progress
5274  "dgit: split brain (separate dgit view) may be needed (--quilt=$quilt_mode).";
5275     # we look in the reflog of dgit-intern/quilt-cache
5276     # we look for an entry whose message is the key for the cache lookup
5277     my @cachekey = (qw(dgit), $our_version);
5278     push @cachekey, $upstreamversion;
5279     push @cachekey, $quilt_mode;
5280     push @cachekey, $headref;
5281
5282     push @cachekey, hashfile('fake.dsc');
5283
5284     my $srcshash = Digest::SHA->new(256);
5285     my %sfs = ( %INC, '$0(dgit)' => $0 );
5286     foreach my $sfk (sort keys %sfs) {
5287         next unless $sfk =~ m/^\$0\b/ || $sfk =~ m{^Debian/Dgit\b};
5288         $srcshash->add($sfk,"  ");
5289         $srcshash->add(hashfile($sfs{$sfk}));
5290         $srcshash->add("\n");
5291     }
5292     push @cachekey, $srcshash->hexdigest();
5293     $splitbrain_cachekey = "@cachekey";
5294
5295     my @cmd = (@git, qw(log -g), '--pretty=format:%H %gs',
5296                $splitbraincache);
5297     printdebug "splitbrain cachekey $splitbrain_cachekey\n";
5298     debugcmd "|(probably)",@cmd;
5299     my $child = open GC, "-|";  defined $child or die $!;
5300     if (!$child) {
5301         chdir '../../..' or die $!;
5302         if (!stat ".git/logs/refs/$splitbraincache") {
5303             $! == ENOENT or die $!;
5304             printdebug ">(no reflog)\n";
5305             exit 0;
5306         }
5307         exec @cmd; die $!;
5308     }
5309     while (<GC>) {
5310         chomp;
5311         printdebug ">| ", $_, "\n" if $debuglevel > 1;
5312         next unless m/^(\w+) (\S.*\S)$/ && $2 eq $splitbrain_cachekey;
5313
5314         my $cachehit = $1;
5315         quilt_fixup_mkwork($headref);
5316         my $saved = maybe_split_brain_save $headref, $cachehit, "cache-hit";
5317         if ($cachehit ne $headref) {
5318             progress "dgit view: found cached ($saved)";
5319             runcmd @git, qw(checkout -q -b dgit-view), $cachehit;
5320             $split_brain = 1;
5321             return ($cachehit, $splitbrain_cachekey);
5322         }
5323         progress "dgit view: found cached, no changes required";
5324         return ($headref, $splitbrain_cachekey);
5325     }
5326     die $! if GC->error;
5327     failedcmd unless close GC;
5328
5329     printdebug "splitbrain cache miss\n";
5330     return (undef, $splitbrain_cachekey);
5331 }
5332
5333 sub quilt_fixup_multipatch ($$$) {
5334     my ($clogp, $headref, $upstreamversion) = @_;
5335
5336     progress "examining quilt state (multiple patches, $quilt_mode mode)";
5337
5338     # Our objective is:
5339     #  - honour any existing .pc in case it has any strangeness
5340     #  - determine the git commit corresponding to the tip of
5341     #    the patch stack (if there is one)
5342     #  - if there is such a git commit, convert each subsequent
5343     #    git commit into a quilt patch with dpkg-source --commit
5344     #  - otherwise convert all the differences in the tree into
5345     #    a single git commit
5346     #
5347     # To do this we:
5348
5349     # Our git tree doesn't necessarily contain .pc.  (Some versions of
5350     # dgit would include the .pc in the git tree.)  If there isn't
5351     # one, we need to generate one by unpacking the patches that we
5352     # have.
5353     #
5354     # We first look for a .pc in the git tree.  If there is one, we
5355     # will use it.  (This is not the normal case.)
5356     #
5357     # Otherwise need to regenerate .pc so that dpkg-source --commit
5358     # can work.  We do this as follows:
5359     #     1. Collect all relevant .orig from parent directory
5360     #     2. Generate a debian.tar.gz out of
5361     #         debian/{patches,rules,source/format,source/options}
5362     #     3. Generate a fake .dsc containing just these fields:
5363     #          Format Source Version Files
5364     #     4. Extract the fake .dsc
5365     #        Now the fake .dsc has a .pc directory.
5366     # (In fact we do this in every case, because in future we will
5367     # want to search for a good base commit for generating patches.)
5368     #
5369     # Then we can actually do the dpkg-source --commit
5370     #     1. Make a new working tree with the same object
5371     #        store as our main tree and check out the main
5372     #        tree's HEAD.
5373     #     2. Copy .pc from the fake's extraction, if necessary
5374     #     3. Run dpkg-source --commit
5375     #     4. If the result has changes to debian/, then
5376     #          - git add them them
5377     #          - git add .pc if we had a .pc in-tree
5378     #          - git commit
5379     #     5. If we had a .pc in-tree, delete it, and git commit
5380     #     6. Back in the main tree, fast forward to the new HEAD
5381
5382     # Another situation we may have to cope with is gbp-style
5383     # patches-unapplied trees.
5384     #
5385     # We would want to detect these, so we know to escape into
5386     # quilt_fixup_gbp.  However, this is in general not possible.
5387     # Consider a package with a one patch which the dgit user reverts
5388     # (with git revert or the moral equivalent).
5389     #
5390     # That is indistinguishable in contents from a patches-unapplied
5391     # tree.  And looking at the history to distinguish them is not
5392     # useful because the user might have made a confusing-looking git
5393     # history structure (which ought to produce an error if dgit can't
5394     # cope, not a silent reintroduction of an unwanted patch).
5395     #
5396     # So gbp users will have to pass an option.  But we can usually
5397     # detect their failure to do so: if the tree is not a clean
5398     # patches-applied tree, quilt linearisation fails, but the tree
5399     # _is_ a clean patches-unapplied tree, we can suggest that maybe
5400     # they want --quilt=unapplied.
5401     #
5402     # To help detect this, when we are extracting the fake dsc, we
5403     # first extract it with --skip-patches, and then apply the patches
5404     # afterwards with dpkg-source --before-build.  That lets us save a
5405     # tree object corresponding to .origs.
5406
5407     my $splitbrain_cachekey;
5408
5409     quilt_make_fake_dsc($upstreamversion);
5410
5411     if (quiltmode_splitbrain()) {
5412         my $cachehit;
5413         ($cachehit, $splitbrain_cachekey) =
5414             quilt_check_splitbrain_cache($headref, $upstreamversion);
5415         return if $cachehit;
5416     }
5417
5418     runcmd qw(sh -ec),
5419         'exec dpkg-source --no-check --skip-patches -x fake.dsc >/dev/null';
5420
5421     my $fakexdir= $package.'-'.(stripepoch $upstreamversion);
5422     rename $fakexdir, "fake" or die "$fakexdir $!";
5423
5424     changedir 'fake';
5425
5426     remove_stray_gits("source package");
5427     mktree_in_ud_here();
5428
5429     rmtree '.pc';
5430
5431     runcmd @git, qw(checkout -f), $headref, qw(-- debian);
5432     my $unapplied=git_add_write_tree();
5433     printdebug "fake orig tree object $unapplied\n";
5434
5435     ensuredir '.pc';
5436
5437     my @bbcmd = (qw(sh -ec), 'exec dpkg-source --before-build . >/dev/null');
5438     $!=0; $?=-1;
5439     if (system @bbcmd) {
5440         failedcmd @bbcmd if $? < 0;
5441         fail <<END;
5442 failed to apply your git tree's patch stack (from debian/patches/) to
5443  the corresponding upstream tarball(s).  Your source tree and .orig
5444  are probably too inconsistent.  dgit can only fix up certain kinds of
5445  anomaly (depending on the quilt mode).  See --quilt= in dgit(1).
5446 END
5447     }
5448
5449     changedir '..';
5450
5451     quilt_fixup_mkwork($headref);
5452
5453     my $mustdeletepc=0;
5454     if (stat_exists ".pc") {
5455         -d _ or die;
5456         progress "Tree already contains .pc - will use it then delete it.";
5457         $mustdeletepc=1;
5458     } else {
5459         rename '../fake/.pc','.pc' or die $!;
5460     }
5461
5462     changedir '../fake';
5463     rmtree '.pc';
5464     my $oldtiptree=git_add_write_tree();
5465     printdebug "fake o+d/p tree object $unapplied\n";
5466     changedir '../work';
5467
5468
5469     # We calculate some guesswork now about what kind of tree this might
5470     # be.  This is mostly for error reporting.
5471
5472     my %editedignores;
5473     my @unrepres;
5474     my $diffbits = {
5475         # H = user's HEAD
5476         # O = orig, without patches applied
5477         # A = "applied", ie orig with H's debian/patches applied
5478         O2H => quiltify_trees_differ($unapplied,$headref,   1,
5479                                      \%editedignores, \@unrepres),
5480         H2A => quiltify_trees_differ($headref,  $oldtiptree,1),
5481         O2A => quiltify_trees_differ($unapplied,$oldtiptree,1),
5482     };
5483
5484     my @dl;
5485     foreach my $b (qw(01 02)) {
5486         foreach my $v (qw(O2H O2A H2A)) {
5487             push @dl, ($diffbits->{$v} & $b) ? '##' : '==';
5488         }
5489     }
5490     printdebug "differences \@dl @dl.\n";
5491
5492     progress sprintf
5493 "$us: base trees orig=%.20s o+d/p=%.20s",
5494               $unapplied, $oldtiptree;
5495     progress sprintf
5496 "$us: quilt differences: src:  %s orig %s     gitignores:  %s orig %s\n".
5497 "$us: quilt differences:      HEAD %s o+d/p               HEAD %s o+d/p",
5498                              $dl[0], $dl[1],              $dl[3], $dl[4],
5499                                  $dl[2],                     $dl[5];
5500
5501     if (@unrepres) {
5502         print STDERR "dgit:  cannot represent change: $_->[1]: $_->[0]\n"
5503             foreach @unrepres;
5504         forceable_fail [qw(unrepresentable)], <<END;
5505 HEAD has changes to .orig[s] which are not representable by `3.0 (quilt)'
5506 END
5507     }
5508
5509     my @failsuggestion;
5510     if (!($diffbits->{O2H} & $diffbits->{O2A})) {
5511         push @failsuggestion, "This might be a patches-unapplied branch.";
5512     }  elsif (!($diffbits->{H2A} & $diffbits->{O2A})) {
5513         push @failsuggestion, "This might be a patches-applied branch.";
5514     }
5515     push @failsuggestion, "Maybe you need to specify one of".
5516         " --[quilt=]gbp --[quilt=]dpm --quilt=unapplied ?";
5517
5518     if (quiltmode_splitbrain()) {
5519         quiltify_splitbrain($clogp, $unapplied, $headref,
5520                             $diffbits, \%editedignores,
5521                             $splitbrain_cachekey);
5522         return;
5523     }
5524
5525     progress "starting quiltify (multiple patches, $quilt_mode mode)";
5526     quiltify($clogp,$headref,$oldtiptree,\@failsuggestion);
5527
5528     if (!open P, '>>', ".pc/applied-patches") {
5529         $!==&ENOENT or die $!;
5530     } else {
5531         close P;
5532     }
5533
5534     commit_quilty_patch();
5535
5536     if ($mustdeletepc) {
5537         quilt_fixup_delete_pc();
5538     }
5539 }
5540
5541 sub quilt_fixup_editor () {
5542     my $descfn = $ENV{$fakeeditorenv};
5543     my $editing = $ARGV[$#ARGV];
5544     open I1, '<', $descfn or die "$descfn: $!";
5545     open I2, '<', $editing or die "$editing: $!";
5546     unlink $editing or die "$editing: $!";
5547     open O, '>', $editing or die "$editing: $!";
5548     while (<I1>) { print O or die $!; } I1->error and die $!;
5549     my $copying = 0;
5550     while (<I2>) {
5551         $copying ||= m/^\-\-\- /;
5552         next unless $copying;
5553         print O or die $!;
5554     }
5555     I2->error and die $!;
5556     close O or die $1;
5557     exit 0;
5558 }
5559
5560 sub maybe_apply_patches_dirtily () {
5561     return unless $quilt_mode =~ m/gbp|unapplied/;
5562     print STDERR <<END or die $!;
5563
5564 dgit: Building, or cleaning with rules target, in patches-unapplied tree.
5565 dgit: Have to apply the patches - making the tree dirty.
5566 dgit: (Consider specifying --clean=git and (or) using dgit sbuild.)
5567
5568 END
5569     $patches_applied_dirtily = 01;
5570     $patches_applied_dirtily |= 02 unless stat_exists '.pc';
5571     runcmd qw(dpkg-source --before-build .);
5572 }
5573
5574 sub maybe_unapply_patches_again () {
5575     progress "dgit: Unapplying patches again to tidy up the tree."
5576         if $patches_applied_dirtily;
5577     runcmd qw(dpkg-source --after-build .)
5578         if $patches_applied_dirtily & 01;
5579     rmtree '.pc'
5580         if $patches_applied_dirtily & 02;
5581     $patches_applied_dirtily = 0;
5582 }
5583
5584 #----- other building -----
5585
5586 our $clean_using_builder;
5587 # ^ tree is to be cleaned by dpkg-source's builtin idea that it should
5588 #   clean the tree before building (perhaps invoked indirectly by
5589 #   whatever we are using to run the build), rather than separately
5590 #   and explicitly by us.
5591
5592 sub clean_tree () {
5593     return if $clean_using_builder;
5594     if ($cleanmode eq 'dpkg-source') {
5595         maybe_apply_patches_dirtily();
5596         runcmd_ordryrun_local @dpkgbuildpackage, qw(-T clean);
5597     } elsif ($cleanmode eq 'dpkg-source-d') {
5598         maybe_apply_patches_dirtily();
5599         runcmd_ordryrun_local @dpkgbuildpackage, qw(-d -T clean);
5600     } elsif ($cleanmode eq 'git') {
5601         runcmd_ordryrun_local @git, qw(clean -xdf);
5602     } elsif ($cleanmode eq 'git-ff') {
5603         runcmd_ordryrun_local @git, qw(clean -xdff);
5604     } elsif ($cleanmode eq 'check') {
5605         my $leftovers = cmdoutput @git, qw(clean -xdn);
5606         if (length $leftovers) {
5607             print STDERR $leftovers, "\n" or die $!;
5608             fail "tree contains uncommitted files and --clean=check specified";
5609         }
5610     } elsif ($cleanmode eq 'none') {
5611     } else {
5612         die "$cleanmode ?";
5613     }
5614 }
5615
5616 sub cmd_clean () {
5617     badusage "clean takes no additional arguments" if @ARGV;
5618     notpushing();
5619     clean_tree();
5620     maybe_unapply_patches_again();
5621 }
5622
5623 sub build_prep_early () {
5624     our $build_prep_early_done //= 0;
5625     return if $build_prep_early_done++;
5626     notpushing();
5627     badusage "-p is not allowed when building" if defined $package;
5628     my $clogp = parsechangelog();
5629     $isuite = getfield $clogp, 'Distribution';
5630     $package = getfield $clogp, 'Source';
5631     $version = getfield $clogp, 'Version';
5632     check_not_dirty();
5633 }
5634
5635 sub build_prep () {
5636     build_prep_early();
5637     clean_tree();
5638     build_maybe_quilt_fixup();
5639     if ($rmchanges) {
5640         my $pat = changespat $version;
5641         foreach my $f (glob "$buildproductsdir/$pat") {
5642             if (act_local()) {
5643                 unlink $f or fail "remove old changes file $f: $!";
5644             } else {
5645                 progress "would remove $f";
5646             }
5647         }
5648     }
5649 }
5650
5651 sub changesopts_initial () {
5652     my @opts =@changesopts[1..$#changesopts];
5653 }
5654
5655 sub changesopts_version () {
5656     if (!defined $changes_since_version) {
5657         my @vsns = archive_query('archive_query');
5658         my @quirk = access_quirk();
5659         if ($quirk[0] eq 'backports') {
5660             local $isuite = $quirk[2];
5661             local $csuite;
5662             canonicalise_suite();
5663             push @vsns, archive_query('archive_query');
5664         }
5665         if (@vsns) {
5666             @vsns = map { $_->[0] } @vsns;
5667             @vsns = sort { -version_compare($a, $b) } @vsns;
5668             $changes_since_version = $vsns[0];
5669             progress "changelog will contain changes since $vsns[0]";
5670         } else {
5671             $changes_since_version = '_';
5672             progress "package seems new, not specifying -v<version>";
5673         }
5674     }
5675     if ($changes_since_version ne '_') {
5676         return ("-v$changes_since_version");
5677     } else {
5678         return ();
5679     }
5680 }
5681
5682 sub changesopts () {
5683     return (changesopts_initial(), changesopts_version());
5684 }
5685
5686 sub massage_dbp_args ($;$) {
5687     my ($cmd,$xargs) = @_;
5688     # We need to:
5689     #
5690     #  - if we're going to split the source build out so we can
5691     #    do strange things to it, massage the arguments to dpkg-buildpackage
5692     #    so that the main build doessn't build source (or add an argument
5693     #    to stop it building source by default).
5694     #
5695     #  - add -nc to stop dpkg-source cleaning the source tree,
5696     #    unless we're not doing a split build and want dpkg-source
5697     #    as cleanmode, in which case we can do nothing
5698     #
5699     # return values:
5700     #    0 - source will NOT need to be built separately by caller
5701     #   +1 - source will need to be built separately by caller
5702     #   +2 - source will need to be built separately by caller AND
5703     #        dpkg-buildpackage should not in fact be run at all!
5704     debugcmd '#massaging#', @$cmd if $debuglevel>1;
5705 #print STDERR "MASS0 ",Dumper($cmd, $xargs, $need_split_build_invocation);
5706     if ($cleanmode eq 'dpkg-source' && !$need_split_build_invocation) {
5707         $clean_using_builder = 1;
5708         return 0;
5709     }
5710     # -nc has the side effect of specifying -b if nothing else specified
5711     # and some combinations of -S, -b, et al, are errors, rather than
5712     # later simply overriding earlie.  So we need to:
5713     #  - search the command line for these options
5714     #  - pick the last one
5715     #  - perhaps add our own as a default
5716     #  - perhaps adjust it to the corresponding non-source-building version
5717     my $dmode = '-F';
5718     foreach my $l ($cmd, $xargs) {
5719         next unless $l;
5720         @$l = grep { !(m/^-[SgGFABb]$/s and $dmode=$_) } @$l;
5721     }
5722     push @$cmd, '-nc';
5723 #print STDERR "MASS1 ",Dumper($cmd, $xargs, $dmode);
5724     my $r = 0;
5725     if ($need_split_build_invocation) {
5726         printdebug "massage split $dmode.\n";
5727         $r = $dmode =~ m/[S]/     ? +2 :
5728              $dmode =~ y/gGF/ABb/ ? +1 :
5729              $dmode =~ m/[ABb]/   ?  0 :
5730              die "$dmode ?";
5731     }
5732     printdebug "massage done $r $dmode.\n";
5733     push @$cmd, $dmode;
5734 #print STDERR "MASS2 ",Dumper($cmd, $xargs, $r);
5735     return $r;
5736 }
5737
5738 sub in_parent (&) {
5739     my ($fn) = @_;
5740     my $wasdir = must_getcwd();
5741     changedir "..";
5742     $fn->();
5743     changedir $wasdir;
5744 }
5745
5746 sub postbuild_mergechanges ($) { # must run with CWD=.. (eg in in_parent)
5747     my ($msg_if_onlyone) = @_;
5748     # If there is only one .changes file, fail with $msg_if_onlyone,
5749     # or if that is undef, be a no-op.
5750     # Returns the changes file to report to the user.
5751     my $pat = changespat $version;
5752     my @changesfiles = glob $pat;
5753     @changesfiles = sort {
5754         ($b =~ m/_source\.changes$/ <=> $a =~ m/_source\.changes$/)
5755             or $a cmp $b
5756     } @changesfiles;
5757     my $result;
5758     if (@changesfiles==1) {
5759         fail <<END.$msg_if_onlyone if defined $msg_if_onlyone;
5760 only one changes file from build (@changesfiles)
5761 END
5762         $result = $changesfiles[0];
5763     } elsif (@changesfiles==2) {
5764         my $binchanges = parsecontrol($changesfiles[1], "binary changes file");
5765         foreach my $l (split /\n/, getfield $binchanges, 'Files') {
5766             fail "$l found in binaries changes file $binchanges"
5767                 if $l =~ m/\.dsc$/;
5768         }
5769         runcmd_ordryrun_local @mergechanges, @changesfiles;
5770         my $multichanges = changespat $version,'multi';
5771         if (act_local()) {
5772             stat_exists $multichanges or fail "$multichanges: $!";
5773             foreach my $cf (glob $pat) {
5774                 next if $cf eq $multichanges;
5775                 rename "$cf", "$cf.inmulti" or fail "$cf\{,.inmulti}: $!";
5776             }
5777         }
5778         $result = $multichanges;
5779     } else {
5780         fail "wrong number of different changes files (@changesfiles)";
5781     }
5782     printdone "build successful, results in $result\n" or die $!;
5783 }
5784
5785 sub midbuild_checkchanges () {
5786     my $pat = changespat $version;
5787     return if $rmchanges;
5788     my @unwanted = map { s#^\.\./##; $_; } glob "../$pat";
5789     @unwanted = grep { $_ ne changespat $version,'source' } @unwanted;
5790     fail <<END
5791 changes files other than source matching $pat already present; building would result in ambiguity about the intended results.
5792 Suggest you delete @unwanted.
5793 END
5794         if @unwanted;
5795 }
5796
5797 sub midbuild_checkchanges_vanilla ($) {
5798     my ($wantsrc) = @_;
5799     midbuild_checkchanges() if $wantsrc == 1;
5800 }
5801
5802 sub postbuild_mergechanges_vanilla ($) {
5803     my ($wantsrc) = @_;
5804     if ($wantsrc == 1) {
5805         in_parent {
5806             postbuild_mergechanges(undef);
5807         };
5808     } else {
5809         printdone "build successful\n";
5810     }
5811 }
5812
5813 sub cmd_build {
5814     build_prep_early();
5815     my @dbp = (@dpkgbuildpackage, qw(-us -uc), changesopts_initial(), @ARGV);
5816     my $wantsrc = massage_dbp_args \@dbp;
5817     if ($wantsrc > 0) {
5818         build_source();
5819         midbuild_checkchanges_vanilla $wantsrc;
5820     } else {
5821         build_prep();
5822     }
5823     if ($wantsrc < 2) {
5824         push @dbp, changesopts_version();
5825         maybe_apply_patches_dirtily();
5826         runcmd_ordryrun_local @dbp;
5827     }
5828     maybe_unapply_patches_again();
5829     postbuild_mergechanges_vanilla $wantsrc;
5830 }
5831
5832 sub pre_gbp_build {
5833     $quilt_mode //= 'gbp';
5834 }
5835
5836 sub cmd_gbp_build {
5837     build_prep_early();
5838
5839     # gbp can make .origs out of thin air.  In my tests it does this
5840     # even for a 1.0 format package, with no origs present.  So I
5841     # guess it keys off just the version number.  We don't know
5842     # exactly what .origs ought to exist, but let's assume that we
5843     # should run gbp if: the version has an upstream part and the main
5844     # orig is absent.
5845     my $upstreamversion = upstreamversion $version;
5846     my $origfnpat = srcfn $upstreamversion, '.orig.tar.*';
5847     my $gbp_make_orig = $version =~ m/-/ && !(() = glob "../$origfnpat");
5848
5849     if ($gbp_make_orig) {
5850         clean_tree();
5851         $cleanmode = 'none'; # don't do it again
5852         $need_split_build_invocation = 1;
5853     }
5854
5855     my @dbp = @dpkgbuildpackage;
5856
5857     my $wantsrc = massage_dbp_args \@dbp, \@ARGV;
5858
5859     if (!length $gbp_build[0]) {
5860         if (length executable_on_path('git-buildpackage')) {
5861             $gbp_build[0] = qw(git-buildpackage);
5862         } else {
5863             $gbp_build[0] = 'gbp buildpackage';
5864         }
5865     }
5866     my @cmd = opts_opt_multi_cmd @gbp_build;
5867
5868     push @cmd, (qw(-us -uc --git-no-sign-tags), "--git-builder=@dbp");
5869
5870     if ($gbp_make_orig) {
5871         ensuredir '.git/dgit';
5872         my $ok = '.git/dgit/origs-gen-ok';
5873         unlink $ok or $!==&ENOENT or die $!;
5874         my @origs_cmd = @cmd;
5875         push @origs_cmd, qw(--git-cleaner=true);
5876         push @origs_cmd, "--git-prebuild=touch $ok .git/dgit/no-such-dir/ok";
5877         push @origs_cmd, @ARGV;
5878         if (act_local()) {
5879             debugcmd @origs_cmd;
5880             system @origs_cmd;
5881             do { local $!; stat_exists $ok; }
5882                 or failedcmd @origs_cmd;
5883         } else {
5884             dryrun_report @origs_cmd;
5885         }
5886     }
5887
5888     if ($wantsrc > 0) {
5889         build_source();
5890         midbuild_checkchanges_vanilla $wantsrc;
5891     } else {
5892         if (!$clean_using_builder) {
5893             push @cmd, '--git-cleaner=true';
5894         }
5895         build_prep();
5896     }
5897     maybe_unapply_patches_again();
5898     if ($wantsrc < 2) {
5899         push @cmd, changesopts();
5900         runcmd_ordryrun_local @cmd, @ARGV;
5901     }
5902     postbuild_mergechanges_vanilla $wantsrc;
5903 }
5904 sub cmd_git_build { cmd_gbp_build(); } # compatibility with <= 1.0
5905
5906 sub build_source {
5907     build_prep_early();
5908     my $our_cleanmode = $cleanmode;
5909     if ($need_split_build_invocation) {
5910         # Pretend that clean is being done some other way.  This
5911         # forces us not to try to use dpkg-buildpackage to clean and
5912         # build source all in one go; and instead we run dpkg-source
5913         # (and build_prep() will do the clean since $clean_using_builder
5914         # is false).
5915         $our_cleanmode = 'ELSEWHERE';
5916     }
5917     if ($our_cleanmode =~ m/^dpkg-source/) {
5918         # dpkg-source invocation (below) will clean, so build_prep shouldn't
5919         $clean_using_builder = 1;
5920     }
5921     build_prep();
5922     $sourcechanges = changespat $version,'source';
5923     if (act_local()) {
5924         unlink "../$sourcechanges" or $!==ENOENT
5925             or fail "remove $sourcechanges: $!";
5926     }
5927     $dscfn = dscfn($version);
5928     if ($our_cleanmode eq 'dpkg-source') {
5929         maybe_apply_patches_dirtily();
5930         runcmd_ordryrun_local @dpkgbuildpackage, qw(-us -uc -S),
5931             changesopts();
5932     } elsif ($our_cleanmode eq 'dpkg-source-d') {
5933         maybe_apply_patches_dirtily();
5934         runcmd_ordryrun_local @dpkgbuildpackage, qw(-us -uc -S -d),
5935             changesopts();
5936     } else {
5937         my @cmd = (@dpkgsource, qw(-b --));
5938         if ($split_brain) {
5939             changedir $ud;
5940             runcmd_ordryrun_local @cmd, "work";
5941             my @udfiles = <${package}_*>;
5942             changedir "../../..";
5943             foreach my $f (@udfiles) {
5944                 printdebug "source copy, found $f\n";
5945                 next unless
5946                     $f eq $dscfn or
5947                     ($f =~ m/\.debian\.tar(?:\.\w+)$/ &&
5948                      $f eq srcfn($version, $&));
5949                 printdebug "source copy, found $f - renaming\n";
5950                 rename "$ud/$f", "../$f" or $!==ENOENT
5951                     or fail "put in place new source file ($f): $!";
5952             }
5953         } else {
5954             my $pwd = must_getcwd();
5955             my $leafdir = basename $pwd;
5956             changedir "..";
5957             runcmd_ordryrun_local @cmd, $leafdir;
5958             changedir $pwd;
5959         }
5960         runcmd_ordryrun_local qw(sh -ec),
5961             'exec >$1; shift; exec "$@"','x',
5962             "../$sourcechanges",
5963             @dpkggenchanges, qw(-S), changesopts();
5964     }
5965 }
5966
5967 sub cmd_build_source {
5968     build_prep_early();
5969     badusage "build-source takes no additional arguments" if @ARGV;
5970     build_source();
5971     maybe_unapply_patches_again();
5972     printdone "source built, results in $dscfn and $sourcechanges";
5973 }
5974
5975 sub cmd_sbuild {
5976     build_source();
5977     midbuild_checkchanges();
5978     in_parent {
5979         if (act_local()) {
5980             stat_exists $dscfn or fail "$dscfn (in parent directory): $!";
5981             stat_exists $sourcechanges
5982                 or fail "$sourcechanges (in parent directory): $!";
5983         }
5984         runcmd_ordryrun_local @sbuild, qw(-d), $isuite, @ARGV, $dscfn;
5985     };
5986     maybe_unapply_patches_again();
5987     in_parent {
5988         postbuild_mergechanges(<<END);
5989 perhaps you need to pass -A ?  (sbuild's default is to build only
5990 arch-specific binaries; dgit 1.4 used to override that.)
5991 END
5992     };
5993 }
5994
5995 sub cmd_quilt_fixup {
5996     badusage "incorrect arguments to dgit quilt-fixup" if @ARGV;
5997     build_prep_early();
5998     clean_tree();
5999     build_maybe_quilt_fixup();
6000 }
6001
6002 sub cmd_import_dsc {
6003     my $needsig = 0;
6004
6005     while (@ARGV) {
6006         last unless $ARGV[0] =~ m/^-/;
6007         $_ = shift @ARGV;
6008         last if m/^--?$/;
6009         if (m/^--require-valid-signature$/) {
6010             $needsig = 1;
6011         } else {
6012             badusage "unknown dgit import-dsc sub-option \`$_'";
6013         }
6014     }
6015
6016     badusage "usage: dgit import-dsc .../PATH/TO/.DSC BRANCH" unless @ARGV==2;
6017     my ($dscfn, $dstbranch) = @ARGV;
6018
6019     badusage "dry run makes no sense with import-dsc" unless act_local();
6020
6021     my $force = $dstbranch =~ s/^\+//   ? +1 :
6022                 $dstbranch =~ s/^\.\.// ? -1 :
6023                                            0;
6024     my $info = $force ? " $&" : '';
6025     $info = "$dscfn$info";
6026
6027     my $specbranch = $dstbranch;
6028     $dstbranch = "refs/heads/$dstbranch" unless $dstbranch =~ m#^refs/#;
6029     $dstbranch = cmdoutput @git, qw(check-ref-format --normalize), $dstbranch;
6030
6031     my @symcmd = (@git, qw(symbolic-ref -q HEAD));
6032     my $chead = cmdoutput_errok @symcmd;
6033     defined $chead or $?==256 or failedcmd @symcmd;
6034
6035     fail "$dstbranch is checked out - will not update it"
6036         if defined $chead and $chead eq $dstbranch;
6037
6038     my $oldhash = git_get_ref $dstbranch;
6039
6040     open D, "<", $dscfn or fail "open import .dsc ($dscfn): $!";
6041     $dscdata = do { local $/ = undef; <D>; };
6042     D->error and fail "read $dscfn: $!";
6043     close C;
6044
6045     # we don't normally need this so import it here
6046     use Dpkg::Source::Package;
6047     my $dp = new Dpkg::Source::Package filename => $dscfn,
6048         require_valid_signature => $needsig;
6049     {
6050         local $SIG{__WARN__} = sub {
6051             print STDERR $_[0];
6052             return unless $needsig;
6053             fail "import-dsc signature check failed";
6054         };
6055         if (!$dp->is_signed()) {
6056             warn "$us: warning: importing unsigned .dsc\n";
6057         } else {
6058             my $r = $dp->check_signature();
6059             die "->check_signature => $r" if $needsig && $r;
6060         }
6061     }
6062
6063     parse_dscdata();
6064
6065     $package = getfield $dsc, 'Source';
6066
6067     parse_dsc_field($dsc, "Dgit metadata in .dsc")
6068         unless forceing [qw(import-dsc-with-dgit-field)];
6069
6070     if (defined $dsc_hash) {
6071         progress "dgit: import-dsc of .dsc with Dgit field, using git hash";
6072         resolve_dsc_field_commit undef, undef;
6073     }
6074     if (defined $dsc_hash) {
6075         my @cmd = (qw(sh -ec),
6076                    "echo $dsc_hash | git cat-file --batch-check");
6077         my $objgot = cmdoutput @cmd;
6078         if ($objgot =~ m#^\w+ missing\b#) {
6079             fail <<END
6080 .dsc contains Dgit field referring to object $dsc_hash
6081 Your git tree does not have that object.  Try `git fetch' from a
6082 plausible server (browse.dgit.d.o? alioth?), and try the import-dsc again.
6083 END
6084         }
6085         if ($oldhash && !is_fast_fwd $oldhash, $dsc_hash) {
6086             if ($force > 0) {
6087                 progress "Not fast forward, forced update.";
6088             } else {
6089                 fail "Not fast forward to $dsc_hash";
6090             }
6091         }
6092         @cmd = (@git, qw(update-ref -m), "dgit import-dsc (Dgit): $info",
6093                 $dstbranch, $dsc_hash);
6094         runcmd @cmd;
6095         progress "dgit: import-dsc updated git ref $dstbranch";
6096         return 0;
6097     }
6098
6099     fail <<END
6100 Branch $dstbranch already exists
6101 Specify ..$specbranch for a pseudo-merge, binding in existing history
6102 Specify  +$specbranch to overwrite, discarding existing history
6103 END
6104         if $oldhash && !$force;
6105
6106     notpushing();
6107
6108     my @dfi = dsc_files_info();
6109     foreach my $fi (@dfi) {
6110         my $f = $fi->{Filename};
6111         my $here = "../$f";
6112         next if lstat $here;
6113         fail "stat $here: $!" unless $! == ENOENT;
6114         my $there = $dscfn;
6115         if ($dscfn =~ m#^(?:\./+)?\.\./+#) {
6116             $there = $';
6117         } elsif ($dscfn =~ m#^/#) {
6118             $there = $dscfn;
6119         } else {
6120             fail "cannot import $dscfn which seems to be inside working tree!";
6121         }
6122         $there =~ s#/+[^/]+$## or
6123             fail "cannot import $dscfn which seems to not have a basename";
6124         $there .= "/$f";
6125         symlink $there, $here or fail "symlink $there to $here: $!";
6126         progress "made symlink $here -> $there";
6127 #       print STDERR Dumper($fi);
6128     }
6129     my @mergeinputs = generate_commits_from_dsc();
6130     die unless @mergeinputs == 1;
6131
6132     my $newhash = $mergeinputs[0]{Commit};
6133
6134     if ($oldhash) {
6135         if ($force > 0) {
6136             progress "Import, forced update - synthetic orphan git history.";
6137         } elsif ($force < 0) {
6138             progress "Import, merging.";
6139             my $tree = cmdoutput @git, qw(rev-parse), "$newhash:";
6140             my $version = getfield $dsc, 'Version';
6141             my $clogp = commit_getclogp $newhash;
6142             my $authline = clogp_authline $clogp;
6143             $newhash = make_commit_text <<END;
6144 tree $tree
6145 parent $newhash
6146 parent $oldhash
6147 author $authline
6148 committer $authline
6149
6150 Merge $package ($version) import into $dstbranch
6151 END
6152         } else {
6153             die; # caught earlier
6154         }
6155     }
6156
6157     my @cmd = (@git, qw(update-ref -m), "dgit import-dsc: $info",
6158                $dstbranch, $newhash);
6159     runcmd @cmd;
6160     progress "dgit: import-dsc results are in in git ref $dstbranch";
6161 }
6162
6163 sub cmd_archive_api_query {
6164     badusage "need only 1 subpath argument" unless @ARGV==1;
6165     my ($subpath) = @ARGV;
6166     my @cmd = archive_api_query_cmd($subpath);
6167     push @cmd, qw(-f);
6168     debugcmd ">",@cmd;
6169     exec @cmd or fail "exec curl: $!\n";
6170 }
6171
6172 sub cmd_clone_dgit_repos_server {
6173     badusage "need destination argument" unless @ARGV==1;
6174     my ($destdir) = @ARGV;
6175     $package = '_dgit-repos-server';
6176     local $access_forpush = 0;
6177     my @cmd = (@git, qw(clone), access_giturl(), $destdir);
6178     debugcmd ">",@cmd;
6179     exec @cmd or fail "exec git clone: $!\n";
6180 }
6181
6182 sub cmd_print_dgit_repos_server_source_url {
6183     badusage "no arguments allowed to dgit print-dgit-repos-server-source-url"
6184         if @ARGV;
6185     $package = '_dgit-repos-server';
6186     local $access_forpush = 0;
6187     my $url = access_giturl();
6188     print $url, "\n" or die $!;
6189 }
6190
6191 sub cmd_setup_mergechangelogs {
6192     badusage "no arguments allowed to dgit setup-mergechangelogs" if @ARGV;
6193     setup_mergechangelogs(1);
6194 }
6195
6196 sub cmd_setup_useremail {
6197     badusage "no arguments allowed to dgit setup-useremail" if @ARGV;
6198     setup_useremail(1);
6199 }
6200
6201 sub cmd_setup_new_tree {
6202     badusage "no arguments allowed to dgit setup-tree" if @ARGV;
6203     setup_new_tree();
6204 }
6205
6206 #---------- argument parsing and main program ----------
6207
6208 sub cmd_version {
6209     print "dgit version $our_version\n" or die $!;
6210     exit 0;
6211 }
6212
6213 our (%valopts_long, %valopts_short);
6214 our @rvalopts;
6215
6216 sub defvalopt ($$$$) {
6217     my ($long,$short,$val_re,$how) = @_;
6218     my $oi = { Long => $long, Short => $short, Re => $val_re, How => $how };
6219     $valopts_long{$long} = $oi;
6220     $valopts_short{$short} = $oi;
6221     # $how subref should:
6222     #   do whatever assignemnt or thing it likes with $_[0]
6223     #   if the option should not be passed on to remote, @rvalopts=()
6224     # or $how can be a scalar ref, meaning simply assign the value
6225 }
6226
6227 defvalopt '--since-version', '-v', '[^_]+|_', \$changes_since_version;
6228 defvalopt '--distro',        '-d', '.+',      \$idistro;
6229 defvalopt '',                '-k', '.+',      \$keyid;
6230 defvalopt '--existing-package','', '.*',      \$existing_package;
6231 defvalopt '--build-products-dir','','.*',     \$buildproductsdir;
6232 defvalopt '--clean',       '', $cleanmode_re, \$cleanmode;
6233 defvalopt '--package',   '-p',   $package_re, \$package;
6234 defvalopt '--quilt',     '', $quilt_modes_re, \$quilt_mode;
6235
6236 defvalopt '', '-C', '.+', sub {
6237     ($changesfile) = (@_);
6238     if ($changesfile =~ s#^(.*)/##) {
6239         $buildproductsdir = $1;
6240     }
6241 };
6242
6243 defvalopt '--initiator-tempdir','','.*', sub {
6244     ($initiator_tempdir) = (@_);
6245     $initiator_tempdir =~ m#^/# or
6246         badusage "--initiator-tempdir must be used specify an".
6247         " absolute, not relative, directory."
6248 };
6249
6250 sub parseopts () {
6251     my $om;
6252
6253     if (defined $ENV{'DGIT_SSH'}) {
6254         @ssh = string_to_ssh $ENV{'DGIT_SSH'};
6255     } elsif (defined $ENV{'GIT_SSH'}) {
6256         @ssh = ($ENV{'GIT_SSH'});
6257     }
6258
6259     my $oi;
6260     my $val;
6261     my $valopt = sub {
6262         my ($what) = @_;
6263         @rvalopts = ($_);
6264         if (!defined $val) {
6265             badusage "$what needs a value" unless @ARGV;
6266             $val = shift @ARGV;
6267             push @rvalopts, $val;
6268         }
6269         badusage "bad value \`$val' for $what" unless
6270             $val =~ m/^$oi->{Re}$(?!\n)/s;
6271         my $how = $oi->{How};
6272         if (ref($how) eq 'SCALAR') {
6273             $$how = $val;
6274         } else {
6275             $how->($val);
6276         }
6277         push @ropts, @rvalopts;
6278     };
6279
6280     while (@ARGV) {
6281         last unless $ARGV[0] =~ m/^-/;
6282         $_ = shift @ARGV;
6283         last if m/^--?$/;
6284         if (m/^--/) {
6285             if (m/^--dry-run$/) {
6286                 push @ropts, $_;
6287                 $dryrun_level=2;
6288             } elsif (m/^--damp-run$/) {
6289                 push @ropts, $_;
6290                 $dryrun_level=1;
6291             } elsif (m/^--no-sign$/) {
6292                 push @ropts, $_;
6293                 $sign=0;
6294             } elsif (m/^--help$/) {
6295                 cmd_help();
6296             } elsif (m/^--version$/) {
6297                 cmd_version();
6298             } elsif (m/^--new$/) {
6299                 push @ropts, $_;
6300                 $new_package=1;
6301             } elsif (m/^--([-0-9a-z]+)=(.+)/s &&
6302                      ($om = $opts_opt_map{$1}) &&
6303                      length $om->[0]) {
6304                 push @ropts, $_;
6305                 $om->[0] = $2;
6306             } elsif (m/^--([-0-9a-z]+):(.*)/s &&
6307                      !$opts_opt_cmdonly{$1} &&
6308                      ($om = $opts_opt_map{$1})) {
6309                 push @ropts, $_;
6310                 push @$om, $2;
6311             } elsif (m/^--(gbp|dpm)$/s) {
6312                 push @ropts, "--quilt=$1";
6313                 $quilt_mode = $1;
6314             } elsif (m/^--ignore-dirty$/s) {
6315                 push @ropts, $_;
6316                 $ignoredirty = 1;
6317             } elsif (m/^--no-quilt-fixup$/s) {
6318                 push @ropts, $_;
6319                 $quilt_mode = 'nocheck';
6320             } elsif (m/^--no-rm-on-error$/s) {
6321                 push @ropts, $_;
6322                 $rmonerror = 0;
6323             } elsif (m/^--no-chase-dsc-distro$/s) {
6324                 push @ropts, $_;
6325                 $chase_dsc_distro = 0;
6326             } elsif (m/^--overwrite$/s) {
6327                 push @ropts, $_;
6328                 $overwrite_version = '';
6329             } elsif (m/^--overwrite=(.+)$/s) {
6330                 push @ropts, $_;
6331                 $overwrite_version = $1;
6332             } elsif (m/^--dep14tag$/s) {
6333                 push @ropts, $_;
6334                 $dodep14tag= 'want';
6335             } elsif (m/^--no-dep14tag$/s) {
6336                 push @ropts, $_;
6337                 $dodep14tag= 'no';
6338             } elsif (m/^--always-dep14tag$/s) {
6339                 push @ropts, $_;
6340                 $dodep14tag= 'always';
6341             } elsif (m/^--delayed=(\d+)$/s) {
6342                 push @ropts, $_;
6343                 push @dput, $_;
6344             } elsif (m/^--dgit-view-save=(.+)$/s) {
6345                 push @ropts, $_;
6346                 $split_brain_save = $1;
6347                 $split_brain_save =~ s#^(?!refs/)#refs/heads/#;
6348             } elsif (m/^--(no-)?rm-old-changes$/s) {
6349                 push @ropts, $_;
6350                 $rmchanges = !$1;
6351             } elsif (m/^--deliberately-($deliberately_re)$/s) {
6352                 push @ropts, $_;
6353                 push @deliberatelies, $&;
6354             } elsif (m/^--force-(.*)/ && defined $forceopts{$1}) {
6355                 push @ropts, $&;
6356                 $forceopts{$1} = 1;
6357                 $_='';
6358             } elsif (m/^--force-/) {
6359                 print STDERR
6360                     "$us: warning: ignoring unknown force option $_\n";
6361                 $_='';
6362             } elsif (m/^--dgit-tag-format=(old|new)$/s) {
6363                 # undocumented, for testing
6364                 push @ropts, $_;
6365                 $tagformat_want = [ $1, 'command line', 1 ];
6366                 # 1 menas overrides distro configuration
6367             } elsif (m/^--always-split-source-build$/s) {
6368                 # undocumented, for testing
6369                 push @ropts, $_;
6370                 $need_split_build_invocation = 1;
6371             } elsif (m/^--config-lookup-explode=(.+)$/s) {
6372                 # undocumented, for testing
6373                 push @ropts, $_;
6374                 $gitcfgs{cmdline}{$1} = 'CONFIG-LOOKUP-EXPLODE';
6375                 # ^ it's supposed to be an array ref
6376             } elsif (m/^(--[-0-9a-z]+)(=|$)/ && ($oi = $valopts_long{$1})) {
6377                 $val = $2 ? $' : undef; #';
6378                 $valopt->($oi->{Long});
6379             } else {
6380                 badusage "unknown long option \`$_'";
6381             }
6382         } else {
6383             while (m/^-./s) {
6384                 if (s/^-n/-/) {
6385                     push @ropts, $&;
6386                     $dryrun_level=2;
6387                 } elsif (s/^-L/-/) {
6388                     push @ropts, $&;
6389                     $dryrun_level=1;
6390                 } elsif (s/^-h/-/) {
6391                     cmd_help();
6392                 } elsif (s/^-D/-/) {
6393                     push @ropts, $&;
6394                     $debuglevel++;
6395                     enabledebug();
6396                 } elsif (s/^-N/-/) {
6397                     push @ropts, $&;
6398                     $new_package=1;
6399                 } elsif (m/^-m/) {
6400                     push @ropts, $&;
6401                     push @changesopts, $_;
6402                     $_ = '';
6403                 } elsif (s/^-wn$//s) {
6404                     push @ropts, $&;
6405                     $cleanmode = 'none';
6406                 } elsif (s/^-wg$//s) {
6407                     push @ropts, $&;
6408                     $cleanmode = 'git';
6409                 } elsif (s/^-wgf$//s) {
6410                     push @ropts, $&;
6411                     $cleanmode = 'git-ff';
6412                 } elsif (s/^-wd$//s) {
6413                     push @ropts, $&;
6414                     $cleanmode = 'dpkg-source';
6415                 } elsif (s/^-wdd$//s) {
6416                     push @ropts, $&;
6417                     $cleanmode = 'dpkg-source-d';
6418                 } elsif (s/^-wc$//s) {
6419                     push @ropts, $&;
6420                     $cleanmode = 'check';
6421                 } elsif (s/^-c([^=]*)\=(.*)$//s) {
6422                     push @git, '-c', $&;
6423                     $gitcfgs{cmdline}{$1} = [ $2 ];
6424                 } elsif (s/^-c([^=]+)$//s) {
6425                     push @git, '-c', $&;
6426                     $gitcfgs{cmdline}{$1} = [ 'true' ];
6427                 } elsif (m/^-[a-zA-Z]/ && ($oi = $valopts_short{$&})) {
6428                     $val = $'; #';
6429                     $val = undef unless length $val;
6430                     $valopt->($oi->{Short});
6431                     $_ = '';
6432                 } else {
6433                     badusage "unknown short option \`$_'";
6434                 }
6435             }
6436         }
6437     }
6438 }
6439
6440 sub check_env_sanity () {
6441     my $blocked = new POSIX::SigSet;
6442     sigprocmask SIG_UNBLOCK, $blocked, $blocked or die $!;
6443
6444     eval {
6445         foreach my $name (qw(PIPE CHLD)) {
6446             my $signame = "SIG$name";
6447             my $signum = eval "POSIX::$signame" // die;
6448             ($SIG{$name} // 'DEFAULT') eq 'DEFAULT' or
6449                 die "$signame is set to something other than SIG_DFL\n";
6450             $blocked->ismember($signum) and
6451                 die "$signame is blocked\n";
6452         }
6453     };
6454     return unless $@;
6455     chomp $@;
6456     fail <<END;
6457 On entry to dgit, $@
6458 This is a bug produced by something in in your execution environment.
6459 Giving up.
6460 END
6461 }
6462
6463
6464 sub parseopts_late_defaults () {
6465     $isuite //= cfg("dgit-distro.$idistro.default-suite", 'RETURN-UNDEF')
6466         if defined $idistro;
6467     $isuite //= cfg('dgit.default.default-suite');
6468
6469     foreach my $k (keys %opts_opt_map) {
6470         my $om = $opts_opt_map{$k};
6471
6472         my $v = access_cfg("cmd-$k", 'RETURN-UNDEF');
6473         if (defined $v) {
6474             badcfg "cannot set command for $k"
6475                 unless length $om->[0];
6476             $om->[0] = $v;
6477         }
6478
6479         foreach my $c (access_cfg_cfgs("opts-$k")) {
6480             my @vl =
6481                 map { $_ ? @$_ : () }
6482                 map { $gitcfgs{$_}{$c} }
6483                 reverse @gitcfgsources;
6484             printdebug "CL $c ", (join " ", map { shellquote } @vl),
6485                 "\n" if $debuglevel >= 4;
6486             next unless @vl;
6487             badcfg "cannot configure options for $k"
6488                 if $opts_opt_cmdonly{$k};
6489             my $insertpos = $opts_cfg_insertpos{$k};
6490             @$om = ( @$om[0..$insertpos-1],
6491                      @vl,
6492                      @$om[$insertpos..$#$om] );
6493         }
6494     }
6495
6496     if (!defined $rmchanges) {
6497         local $access_forpush;
6498         $rmchanges = access_cfg_bool(0, 'rm-old-changes');
6499     }
6500
6501     if (!defined $quilt_mode) {
6502         local $access_forpush;
6503         $quilt_mode = cfg('dgit.force.quilt-mode', 'RETURN-UNDEF')
6504             // access_cfg('quilt-mode', 'RETURN-UNDEF')
6505             // 'linear';
6506         $quilt_mode =~ m/^($quilt_modes_re)$/
6507             or badcfg "unknown quilt-mode \`$quilt_mode'";
6508         $quilt_mode = $1;
6509     }
6510
6511     if (!defined $dodep14tag) {
6512         local $access_forpush;
6513         $dodep14tag = access_cfg('dep14tag', 'RETURN-UNDEF') // 'want';
6514         $dodep14tag =~ m/^($dodep14tag_re)$/
6515             or badcfg "unknown dep14tag setting \`$dodep14tag'";
6516         $dodep14tag = $1;
6517     }
6518
6519     $need_split_build_invocation ||= quiltmode_splitbrain();
6520
6521     if (!defined $cleanmode) {
6522         local $access_forpush;
6523         $cleanmode = access_cfg('clean-mode', 'RETURN-UNDEF');
6524         $cleanmode //= 'dpkg-source';
6525
6526         badcfg "unknown clean-mode \`$cleanmode'" unless
6527             $cleanmode =~ m/^($cleanmode_re)$(?!\n)/s;
6528     }
6529 }
6530
6531 if ($ENV{$fakeeditorenv}) {
6532     git_slurp_config();
6533     quilt_fixup_editor();
6534 }
6535
6536 parseopts();
6537 check_env_sanity();
6538 git_slurp_config();
6539
6540 print STDERR "DRY RUN ONLY\n" if $dryrun_level > 1;
6541 print STDERR "DAMP RUN - WILL MAKE LOCAL (UNSIGNED) CHANGES\n"
6542     if $dryrun_level == 1;
6543 if (!@ARGV) {
6544     print STDERR $helpmsg or die $!;
6545     exit 8;
6546 }
6547 my $cmd = shift @ARGV;
6548 $cmd =~ y/-/_/;
6549
6550 my $pre_fn = ${*::}{"pre_$cmd"};
6551 $pre_fn->() if $pre_fn;
6552
6553 my $fn = ${*::}{"cmd_$cmd"};
6554 $fn or badusage "unknown operation $cmd";
6555 $fn->();