dgit

   1 #!/usr/bin/perl -w
   2 # dgit
   3 # Integration between git and Debian-style archives
   4 #
   5 # Copyright (C)2013-2016 Ian Jackson
   6 #
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 use strict;
  21
  22 use Debian::Dgit;
  23 setup_sigwarn();
  24
  25 use IO::Handle;
  26 use Data::Dumper;
  27 use LWP::UserAgent;
  28 use Dpkg::Control::Hash;
  29 use File::Path;
  30 use File::Temp qw(tempdir);
  31 use File::Basename;
  32 use Dpkg::Version;
  33 use POSIX;
  34 use IPC::Open2;
  35 use Digest::SHA;
  36 use Digest::MD5;
  37 use List::Util qw(any);
  38 use List::MoreUtils qw(pairwise);
  39 use Text::Glob qw(match_glob);
  40 use Fcntl qw(:DEFAULT :flock);
  41 use Carp;
  42
  43 use Debian::Dgit;
  44
  45 our $our_version = 'UNRELEASED'; ###substituted###
  46 our $absurdity = undef; ###substituted###
  47
  48 our @rpushprotovsn_support = qw(4 3 2); # 4 is new tag format
  49 our $protovsn;
  50
  51 our $isuite = 'unstable';
  52 our $idistro;
  53 our $package;
  54 our @ropts;
  55
  56 our $sign = 1;
  57 our $dryrun_level = 0;
  58 our $changesfile;
  59 our $buildproductsdir = '..';
  60 our $new_package = 0;
  61 our $ignoredirty = 0;
  62 our $rmonerror = 1;
  63 our @deliberatelies;
  64 our %previously;
  65 our $existing_package = 'dpkg';
  66 our $cleanmode;
  67 our $changes_since_version;
  68 our $rmchanges;
  69 our $overwrite_version; # undef: not specified; '': check changelog
  70 our $quilt_mode;
  71 our $quilt_modes_re = 'linear|smash|auto|nofix|nocheck|gbp|dpm|unapplied';
  72 our $dodep14tag;
  73 our $dodep14tag_re = 'want|no|always';
  74 our $split_brain_save;
  75 our $we_are_responder;
  76 our $initiator_tempdir;
  77 our $patches_applied_dirtily = 00;
  78 our $tagformat_want;
  79 our $tagformat;
  80 our $tagformatfn;
  81 our $chase_dsc_distro=1;
  82
  83 our %forceopts = map { $_=>0 }
  84     qw(unrepresentable unsupported-source-format
  85        dsc-changes-mismatch changes-origs-exactly
  86        import-gitapply-absurd
  87        import-gitapply-no-absurd
  88        import-dsc-with-dgit-field);
  89
  90 our %format_ok = map { $_=>1 } ("1.0","3.0 (native)","3.0 (quilt)");
  91
  92 our $suite_re = '[-+.0-9a-z]+';
  93 our $cleanmode_re = 'dpkg-source(?:-d)?|git|git-ff|check|none';
  94 our $orig_f_comp_re = 'orig(?:-[-0-9a-z]+)?';
  95 our $orig_f_sig_re = '\\.(?:asc|gpg|pgp)';
  96 our $orig_f_tail_re = "$orig_f_comp_re\\.tar(?:\\.\\w+)?(?:$orig_f_sig_re)?";
  97
  98 our $git_authline_re = '^([^<>]+) \<(\S+)\> (\d+ [-+]\d+)$';
  99 our $splitbraincache = 'dgit-intern/quilt-cache';
 100 our $rewritemap = 'dgit-rewrite/map';
 101
 102 our (@git) = qw(git);
 103 our (@dget) = qw(dget);
 104 our (@curl) = qw(curl);
 105 our (@dput) = qw(dput);
 106 our (@debsign) = qw(debsign);
 107 our (@gpg) = qw(gpg);
 108 our (@sbuild) = qw(sbuild);
 109 our (@ssh) = 'ssh';
 110 our (@dgit) = qw(dgit);
 111 our (@aptget) = qw(apt-get);
 112 our (@aptcache) = qw(apt-cache);
 113 our (@dpkgbuildpackage) = qw(dpkg-buildpackage -i\.git/ -I.git);
 114 our (@dpkgsource) = qw(dpkg-source -i\.git/ -I.git);
 115 our (@dpkggenchanges) = qw(dpkg-genchanges);
 116 our (@mergechanges) = qw(mergechanges -f);
 117 our (@gbp_build) = ('');
 118 our (@gbp_pq) = ('gbp pq');
 119 our (@changesopts) = ('');
 120
 121 our %opts_opt_map = ('dget' => \@dget, # accept for compatibility
 122                      'curl' => \@curl,
 123                      'dput' => \@dput,
 124                      'debsign' => \@debsign,
 125                      'gpg' => \@gpg,
 126                      'sbuild' => \@sbuild,
 127                      'ssh' => \@ssh,
 128                      'dgit' => \@dgit,
 129                      'git' => \@git,
 130                      'apt-get' => \@aptget,
 131                      'apt-cache' => \@aptcache,
 132                      'dpkg-source' => \@dpkgsource,
 133                      'dpkg-buildpackage' => \@dpkgbuildpackage,
 134                      'dpkg-genchanges' => \@dpkggenchanges,
 135                      'gbp-build' => \@gbp_build,
 136                      'gbp-pq' => \@gbp_pq,
 137                      'ch' => \@changesopts,
 138                      'mergechanges' => \@mergechanges);
 139
 140 our %opts_opt_cmdonly = ('gpg' => 1, 'git' => 1);
 141 our %opts_cfg_insertpos = map {
 142     $_,
 143     scalar @{ $opts_opt_map{$_} }
 144 } keys %opts_opt_map;
 145
 146 sub parseopts_late_defaults();
 147
 148 our $keyid;
 149
 150 autoflush STDOUT 1;
 151
 152 our $supplementary_message = '';
 153 our $need_split_build_invocation = 0;
 154 our $split_brain = 0;
 155
 156 END {
 157     local ($@, $?);
 158     print STDERR "! $_\n" foreach $supplementary_message =~ m/^.+$/mg;
 159 }
 160
 161 our $remotename = 'dgit';
 162 our @ourdscfield = qw(Dgit Vcs-Dgit-Master);
 163 our $csuite;
 164 our $instead_distro;
 165
 166 if (!defined $absurdity) {
 167     $absurdity = $0;
 168     $absurdity =~ s{/[^/]+$}{/absurd} or die;
 169 }
 170
 171 sub debiantag ($$) {
 172     my ($v,$distro) = @_;
 173     return $tagformatfn->($v, $distro);
 174 }
 175
 176 sub debiantag_maintview ($$) {
 177     my ($v,$distro) = @_;
 178     return "$distro/".dep14_version_mangle $v;
 179 }
 180
 181 sub madformat ($) { $_[0] eq '3.0 (quilt)' }
 182
 183 sub lbranch () { return "$branchprefix/$csuite"; }
 184 my $lbranch_re = '^refs/heads/'.$branchprefix.'/([^/.]+)$';
 185 sub lref () { return "refs/heads/".lbranch(); }
 186 sub lrref () { return "refs/remotes/$remotename/".server_branch($csuite); }
 187 sub rrref () { return server_ref($csuite); }
 188
 189 sub stripepoch ($) {
 190     my ($vsn) = @_;
 191     $vsn =~ s/^\d+\://;
 192     return $vsn;
 193 }
 194
 195 sub srcfn ($$) {
 196     my ($vsn,$sfx) = @_;
 197     return "${package}_".(stripepoch $vsn).$sfx
 198 }
 199
 200 sub dscfn ($) {
 201     my ($vsn) = @_;
 202     return srcfn($vsn,".dsc");
 203 }
 204
 205 sub changespat ($;$) {
 206     my ($vsn, $arch) = @_;
 207     return "${package}_".(stripepoch $vsn)."_".($arch//'*').".changes";
 208 }
 209
 210 sub upstreamversion ($) {
 211     my ($vsn) = @_;
 212     $vsn =~ s/-[^-]+$//;
 213     return $vsn;
 214 }
 215
 216 our $us = 'dgit';
 217 initdebug('');
 218
 219 our @end;
 220 END {
 221     local ($?);
 222     foreach my $f (@end) {
 223         eval { $f->(); };
 224         print STDERR "$us: cleanup: $@" if length $@;
 225     }
 226 };
 227
 228 sub badcfg { print STDERR "$us: invalid configuration: @_\n"; exit 12; }
 229
 230 sub forceable_fail ($$) {
 231     my ($forceoptsl, $msg) = @_;
 232     fail $msg unless grep { $forceopts{$_} } @$forceoptsl;
 233     print STDERR "warning: overriding problem due to --force:\n". $msg;
 234 }
 235
 236 sub forceing ($) {
 237     my ($forceoptsl) = @_;
 238     my @got = grep { $forceopts{$_} } @$forceoptsl;
 239     return 0 unless @got;
 240     print STDERR
 241  "warning: skipping checks or functionality due to --force-$got[0]\n";
 242 }
 243
 244 sub no_such_package () {
 245     print STDERR "$us: package $package does not exist in suite $isuite\n";
 246     exit 4;
 247 }
 248
 249 sub changedir ($) {
 250     my ($newdir) = @_;
 251     printdebug "CD $newdir\n";
 252     chdir $newdir or confess "chdir: $newdir: $!";
 253 }
 254
 255 sub deliberately ($) {
 256     my ($enquiry) = @_;
 257     return !!grep { $_ eq "--deliberately-$enquiry" } @deliberatelies;
 258 }
 259
 260 sub deliberately_not_fast_forward () {
 261     foreach (qw(not-fast-forward fresh-repo)) {
 262         return 1 if deliberately($_) || deliberately("TEST-dgit-only-$_");
 263     }
 264 }
 265
 266 sub quiltmode_splitbrain () {
 267     $quilt_mode =~ m/gbp|dpm|unapplied/;
 268 }
 269
 270 sub opts_opt_multi_cmd {
 271     my @cmd;
 272     push @cmd, split /\s+/, shift @_;
 273     push @cmd, @_;
 274     @cmd;
 275 }
 276
 277 sub gbp_pq {
 278     return opts_opt_multi_cmd @gbp_pq;
 279 }
 280
 281 #---------- remote protocol support, common ----------
 282
 283 # remote push initiator/responder protocol:
 284 #  $ dgit remote-push-build-host <n-rargs> <rargs>... <push-args>...
 285 #  where <rargs> is <push-host-dir> <supported-proto-vsn>,... ...
 286 #  < dgit-remote-push-ready <actual-proto-vsn>
 287 #
 288 # occasionally:
 289 #
 290 #  > progress NBYTES
 291 #  [NBYTES message]
 292 #
 293 #  > supplementary-message NBYTES          # $protovsn >= 3
 294 #  [NBYTES message]
 295 #
 296 # main sequence:
 297 #
 298 #  > file parsed-changelog
 299 #  [indicates that output of dpkg-parsechangelog follows]
 300 #  > data-block NBYTES
 301 #  > [NBYTES bytes of data (no newline)]
 302 #  [maybe some more blocks]
 303 #  > data-end
 304 #
 305 #  > file dsc
 306 #  [etc]
 307 #
 308 #  > file changes
 309 #  [etc]
 310 #
 311 #  > param head DGIT-VIEW-HEAD
 312 #  > param csuite SUITE
 313 #  > param tagformat old|new
 314 #  > param maint-view MAINT-VIEW-HEAD
 315 #
 316 #  > previously REFNAME=OBJNAME       # if --deliberately-not-fast-forward
 317 #                                     # goes into tag, for replay prevention
 318 #
 319 #  > want signed-tag
 320 #  [indicates that signed tag is wanted]
 321 #  < data-block NBYTES
 322 #  < [NBYTES bytes of data (no newline)]
 323 #  [maybe some more blocks]
 324 #  < data-end
 325 #  < files-end
 326 #
 327 #  > want signed-dsc-changes
 328 #  < data-block NBYTES    [transfer of signed dsc]
 329 #  [etc]
 330 #  < data-block NBYTES    [transfer of signed changes]
 331 #  [etc]
 332 #  < files-end
 333 #
 334 #  > complete
 335
 336 our $i_child_pid;
 337
 338 sub i_child_report () {
 339     # Sees if our child has died, and reap it if so.  Returns a string
 340     # describing how it died if it failed, or undef otherwise.
 341     return undef unless $i_child_pid;
 342     my $got = waitpid $i_child_pid, WNOHANG;
 343     return undef if $got <= 0;
 344     die unless $got == $i_child_pid;
 345     $i_child_pid = undef;
 346     return undef unless $?;
 347     return "build host child ".waitstatusmsg();
 348 }
 349
 350 sub badproto ($$) {
 351     my ($fh, $m) = @_;
 352     fail "connection lost: $!" if $fh->error;
 353     fail "protocol violation; $m not expected";
 354 }
 355
 356 sub badproto_badread ($$) {
 357     my ($fh, $wh) = @_;
 358     fail "connection lost: $!" if $!;
 359     my $report = i_child_report();
 360     fail $report if defined $report;
 361     badproto $fh, "eof (reading $wh)";
 362 }
 363
 364 sub protocol_expect (&$) {
 365     my ($match, $fh) = @_;
 366     local $_;
 367     $_ = <$fh>;
 368     defined && chomp or badproto_badread $fh, "protocol message";
 369     if (wantarray) {
 370         my @r = &$match;
 371         return @r if @r;
 372     } else {
 373         my $r = &$match;
 374         return $r if $r;
 375     }
 376     badproto $fh, "\`$_'";
 377 }
 378
 379 sub protocol_send_file ($$) {
 380     my ($fh, $ourfn) = @_;
 381     open PF, "<", $ourfn or die "$ourfn: $!";
 382     for (;;) {
 383         my $d;
 384         my $got = read PF, $d, 65536;
 385         die "$ourfn: $!" unless defined $got;
 386         last if !$got;
 387         print $fh "data-block ".length($d)."\n" or die $!;
 388         print $fh $d or die $!;
 389     }
 390     PF->error and die "$ourfn $!";
 391     print $fh "data-end\n" or die $!;
 392     close PF;
 393 }
 394
 395 sub protocol_read_bytes ($$) {
 396     my ($fh, $nbytes) = @_;
 397     $nbytes =~ m/^[1-9]\d{0,5}$|^0$/ or badproto \*RO, "bad byte count";
 398     my $d;
 399     my $got = read $fh, $d, $nbytes;
 400     $got==$nbytes or badproto_badread $fh, "data block";
 401     return $d;
 402 }
 403
 404 sub protocol_receive_file ($$) {
 405     my ($fh, $ourfn) = @_;
 406     printdebug "() $ourfn\n";
 407     open PF, ">", $ourfn or die "$ourfn: $!";
 408     for (;;) {
 409         my ($y,$l) = protocol_expect {
 410             m/^data-block (.*)$/ ? (1,$1) :
 411             m/^data-end$/ ? (0,) :
 412             ();
 413         } $fh;
 414         last unless $y;
 415         my $d = protocol_read_bytes $fh, $l;
 416         print PF $d or die $!;
 417     }
 418     close PF or die $!;
 419 }
 420
 421 #---------- remote protocol support, responder ----------
 422
 423 sub responder_send_command ($) {
 424     my ($command) = @_;
 425     return unless $we_are_responder;
 426     # called even without $we_are_responder
 427     printdebug ">> $command\n";
 428     print PO $command, "\n" or die $!;
 429 }
 430
 431 sub responder_send_file ($$) {
 432     my ($keyword, $ourfn) = @_;
 433     return unless $we_are_responder;
 434     printdebug "]] $keyword $ourfn\n";
 435     responder_send_command "file $keyword";
 436     protocol_send_file \*PO, $ourfn;
 437 }
 438
 439 sub responder_receive_files ($@) {
 440     my ($keyword, @ourfns) = @_;
 441     die unless $we_are_responder;
 442     printdebug "[[ $keyword @ourfns\n";
 443     responder_send_command "want $keyword";
 444     foreach my $fn (@ourfns) {
 445         protocol_receive_file \*PI, $fn;
 446     }
 447     printdebug "[[\$\n";
 448     protocol_expect { m/^files-end$/ } \*PI;
 449 }
 450
 451 #---------- remote protocol support, initiator ----------
 452
 453 sub initiator_expect (&) {
 454     my ($match) = @_;
 455     protocol_expect { &$match } \*RO;
 456 }
 457
 458 #---------- end remote code ----------
 459
 460 sub progress {
 461     if ($we_are_responder) {
 462         my $m = join '', @_;
 463         responder_send_command "progress ".length($m) or die $!;
 464         print PO $m or die $!;
 465     } else {
 466         print @_, "\n";
 467     }
 468 }
 469
 470 our $ua;
 471
 472 sub url_get {
 473     if (!$ua) {
 474         $ua = LWP::UserAgent->new();
 475         $ua->env_proxy;
 476     }
 477     my $what = $_[$#_];
 478     progress "downloading $what...";
 479     my $r = $ua->get(@_) or die $!;
 480     return undef if $r->code == 404;
 481     $r->is_success or fail "failed to fetch $what: ".$r->status_line;
 482     return $r->decoded_content(charset => 'none');
 483 }
 484
 485 our ($dscdata,$dscurl,$dsc,$dsc_checked,$skew_warning_vsn);
 486
 487 sub runcmd {
 488     debugcmd "+",@_;
 489     $!=0; $?=-1;
 490     failedcmd @_ if system @_;
 491 }
 492
 493 sub act_local () { return $dryrun_level <= 1; }
 494 sub act_scary () { return !$dryrun_level; }
 495
 496 sub printdone {
 497     if (!$dryrun_level) {
 498         progress "$us ok: @_";
 499     } else {
 500         progress "would be ok: @_ (but dry run only)";
 501     }
 502 }
 503
 504 sub dryrun_report {
 505     printcmd(\*STDERR,$debugprefix."#",@_);
 506 }
 507
 508 sub runcmd_ordryrun {
 509     if (act_scary()) {
 510         runcmd @_;
 511     } else {
 512         dryrun_report @_;
 513     }
 514 }
 515
 516 sub runcmd_ordryrun_local {
 517     if (act_local()) {
 518         runcmd @_;
 519     } else {
 520         dryrun_report @_;
 521     }
 522 }
 523
 524 sub shell_cmd {
 525     my ($first_shell, @cmd) = @_;
 526     return qw(sh -ec), $first_shell.'; exec "$@"', 'x', @cmd;
 527 }
 528
 529 our $helpmsg = <<END;
 530 main usages:
 531   dgit [dgit-opts] clone [dgit-opts] package [suite] [./dir|/dir]
 532   dgit [dgit-opts] fetch|pull [dgit-opts] [suite]
 533   dgit [dgit-opts] build [dpkg-buildpackage-opts]
 534   dgit [dgit-opts] sbuild [sbuild-opts]
 535   dgit [dgit-opts] push [dgit-opts] [suite]
 536   dgit [dgit-opts] rpush build-host:build-dir ...
 537 important dgit options:
 538   -k<keyid>           sign tag and package with <keyid> instead of default
 539   --dry-run -n        do not change anything, but go through the motions
 540   --damp-run -L       like --dry-run but make local changes, without signing
 541   --new -N            allow introducing a new package
 542   --debug -D          increase debug level
 543   -c<name>=<value>    set git config option (used directly by dgit too)
 544 END
 545
 546 our $later_warning_msg = <<END;
 547 Perhaps the upload is stuck in incoming.  Using the version from git.
 548 END
 549
 550 sub badusage {
 551     print STDERR "$us: @_\n", $helpmsg or die $!;
 552     exit 8;
 553 }
 554
 555 sub nextarg {
 556     @ARGV or badusage "too few arguments";
 557     return scalar shift @ARGV;
 558 }
 559
 560 sub cmd_help () {
 561     print $helpmsg or die $!;
 562     exit 0;
 563 }
 564
 565 our $td = $ENV{DGIT_TEST_DUMMY_DIR} || "DGIT_TEST_DUMMY_DIR-unset";
 566
 567 our %defcfg = ('dgit.default.distro' => 'debian',
 568                'dgit-suite.*-security.distro' => 'debian-security',
 569                'dgit.default.username' => '',
 570                'dgit.default.archive-query-default-component' => 'main',
 571                'dgit.default.ssh' => 'ssh',
 572                'dgit.default.archive-query' => 'madison:',
 573                'dgit.default.sshpsql-dbname' => 'service=projectb',
 574                'dgit.default.aptget-components' => 'main',
 575                'dgit.default.dgit-tag-format' => 'new,old,maint',
 576                'dgit.dsc-url-proto-ok.http'    => 'true',
 577                'dgit.dsc-url-proto-ok.https'   => 'true',
 578                'dgit.dsc-url-proto-ok.git'     => 'true',
 579                'dgit.default.dsc-url-proto-ok' => 'false',
 580                # old means "repo server accepts pushes with old dgit tags"
 581                # new means "repo server accepts pushes with new dgit tags"
 582                # maint means "repo server accepts split brain pushes"
 583                # hist means "repo server may have old pushes without new tag"
 584                #   ("hist" is implied by "old")
 585                'dgit-distro.debian.archive-query' => 'ftpmasterapi:',
 586                'dgit-distro.debian.git-check' => 'url',
 587                'dgit-distro.debian.git-check-suffix' => '/info/refs',
 588                'dgit-distro.debian.new-private-pushers' => 't',
 589                'dgit-distro.debian/push.git-url' => '',
 590                'dgit-distro.debian/push.git-host' => 'push.dgit.debian.org',
 591                'dgit-distro.debian/push.git-user-force' => 'dgit',
 592                'dgit-distro.debian/push.git-proto' => 'git+ssh://',
 593                'dgit-distro.debian/push.git-path' => '/dgit/debian/repos',
 594                'dgit-distro.debian/push.git-create' => 'true',
 595                'dgit-distro.debian/push.git-check' => 'ssh-cmd',
 596  'dgit-distro.debian.archive-query-url', 'https://api.ftp-master.debian.org/',
 597 # 'dgit-distro.debian.archive-query-tls-key',
 598 #    '/etc/ssl/certs/%HOST%.pem:/etc/dgit/%HOST%.pem',
 599 # ^ this does not work because curl is broken nowadays
 600 # Fixing #790093 properly will involve providing providing the key
 601 # in some pacagke and maybe updating these paths.
 602 #
 603 # 'dgit-distro.debian.archive-query-tls-curl-args',
 604 #   '--ca-path=/etc/ssl/ca-debian',
 605 # ^ this is a workaround but works (only) on DSA-administered machines
 606                'dgit-distro.debian.git-url' => 'https://git.dgit.debian.org',
 607                'dgit-distro.debian.git-url-suffix' => '',
 608                'dgit-distro.debian.upload-host' => 'ftp-master', # for dput
 609                'dgit-distro.debian.mirror' => 'http://ftp.debian.org/debian/',
 610  'dgit-distro.debian-security.archive-query' => 'aptget:',
 611  'dgit-distro.debian-security.mirror' => 'http://security.debian.org/debian-security/',
 612  'dgit-distro.debian-security.aptget-suite-map' => 's#-security$#/updates#',
 613  'dgit-distro.debian-security.aptget-suite-rmap' => 's#$#-security#',
 614  'dgit-distro.debian-security.nominal-distro' => 'debian',
 615  'dgit-distro.debian.backports-quirk' => '(squeeze)-backports*',
 616  'dgit-distro.debian-backports.mirror' => 'http://backports.debian.org/debian-backports/',
 617                'dgit-distro.ubuntu.git-check' => 'false',
 618  'dgit-distro.ubuntu.mirror' => 'http://archive.ubuntu.com/ubuntu',
 619                'dgit-distro.test-dummy.ssh' => "$td/ssh",
 620                'dgit-distro.test-dummy.username' => "alice",
 621                'dgit-distro.test-dummy.git-check' => "ssh-cmd",
 622                'dgit-distro.test-dummy.git-create' => "ssh-cmd",
 623                'dgit-distro.test-dummy.git-url' => "$td/git",
 624                'dgit-distro.test-dummy.git-host' => "git",
 625                'dgit-distro.test-dummy.git-path' => "$td/git",
 626                'dgit-distro.test-dummy.archive-query' => "dummycatapi:",
 627                'dgit-distro.test-dummy.archive-query-url' => "file://$td/aq/",
 628                'dgit-distro.test-dummy.mirror' => "file://$td/mirror/",
 629                'dgit-distro.test-dummy.upload-host' => 'test-dummy',
 630                );
 631
 632 our %gitcfgs;
 633 our @gitcfgsources = qw(cmdline local global system);
 634
 635 sub git_slurp_config () {
 636     local ($debuglevel) = $debuglevel-2;
 637     local $/="\0";
 638
 639     # This algoritm is a bit subtle, but this is needed so that for
 640     # options which we want to be single-valued, we allow the
 641     # different config sources to override properly.  See #835858.
 642     foreach my $src (@gitcfgsources) {
 643         next if $src eq 'cmdline';
 644         # we do this ourselves since git doesn't handle it
 645
 646         my @cmd = (@git, qw(config -z --get-regexp), "--$src", qw(.*));
 647         debugcmd "|",@cmd;
 648
 649         open GITS, "-|", @cmd or die $!;
 650         while (<GITS>) {
 651             chomp or die;
 652             printdebug "=> ", (messagequote $_), "\n";
 653             m/\n/ or die "$_ ?";
 654             push @{ $gitcfgs{$src}{$`} }, $'; #';
 655         }
 656         $!=0; $?=0;
 657         close GITS
 658             or ($!==0 && $?==256)
 659             or failedcmd @cmd;
 660     }
 661 }
 662
 663 sub git_get_config ($) {
 664     my ($c) = @_;
 665     foreach my $src (@gitcfgsources) {
 666         my $l = $gitcfgs{$src}{$c};
 667         croak "$l $c" if $l && !ref $l;
 668         printdebug"C $c ".(defined $l ?
 669                            join " ", map { messagequote "'$_'" } @$l :
 670                            "undef")."\n"
 671             if $debuglevel >= 4;
 672         $l or next;
 673         @$l==1 or badcfg "multiple values for $c".
 674             " (in $src git config)" if @$l > 1;
 675         return $l->[0];
 676     }
 677     return undef;
 678 }
 679
 680 sub cfg {
 681     foreach my $c (@_) {
 682         return undef if $c =~ /RETURN-UNDEF/;
 683         printdebug "C? $c\n" if $debuglevel >= 5;
 684         my $v = git_get_config($c);
 685         return $v if defined $v;
 686         my $dv = $defcfg{$c};
 687         if (defined $dv) {
 688             printdebug "CD $c $dv\n" if $debuglevel >= 4;
 689             return $dv;
 690         }
 691     }
 692     badcfg "need value for one of: @_\n".
 693         "$us: distro or suite appears not to be (properly) supported";
 694 }
 695
 696 sub access_basedistro__noalias () {
 697     if (defined $idistro) {
 698         return $idistro;
 699     } else {
 700         my $def = cfg("dgit-suite.$isuite.distro", 'RETURN-UNDEF');
 701         return $def if defined $def;
 702         foreach my $src (@gitcfgsources, 'internal') {
 703             my $kl = $src eq 'internal' ? \%defcfg : $gitcfgs{$src};
 704             next unless $kl;
 705             foreach my $k (keys %$kl) {
 706                 next unless $k =~ m#^dgit-suite\.(.*)\.distro$#;
 707                 my $dpat = $1;
 708                 next unless match_glob $dpat, $isuite;
 709                 return $kl->{$k};
 710             }
 711         }
 712         return cfg("dgit.default.distro");
 713     }
 714 }
 715
 716 sub access_basedistro () {
 717     my $noalias = access_basedistro__noalias();
 718     my $canon = cfg("dgit-distro.$noalias.alias-canon",'RETURN-UNDEF');
 719     return $canon // $noalias;
 720 }
 721
 722 sub access_nomdistro () {
 723     my $base = access_basedistro();
 724     my $r = cfg("dgit-distro.$base.nominal-distro",'RETURN-UNDEF') // $base;
 725     $r =~ m/^$distro_re$/ or badcfg
 726  "bad syntax for (nominal) distro \`$r' (does not match /^$distro_re$/)";
 727     return $r;
 728 }
 729
 730 sub access_quirk () {
 731     # returns (quirk name, distro to use instead or undef, quirk-specific info)
 732     my $basedistro = access_basedistro();
 733     my $backports_quirk = cfg("dgit-distro.$basedistro.backports-quirk",
 734                               'RETURN-UNDEF');
 735     if (defined $backports_quirk) {
 736         my $re = $backports_quirk;
 737         $re =~ s/[^-0-9a-z_\%*()]/\\$&/ig;
 738         $re =~ s/\*/.*/g;
 739         $re =~ s/\%/([-0-9a-z_]+)/
 740             or $re =~ m/[()]/ or badcfg "backports-quirk needs \% or ( )";
 741         if ($isuite =~ m/^$re$/) {
 742             return ('backports',"$basedistro-backports",$1);
 743         }
 744     }
 745     return ('none',undef);
 746 }
 747
 748 our $access_forpush;
 749
 750 sub parse_cfg_bool ($$$) {
 751     my ($what,$def,$v) = @_;
 752     $v //= $def;
 753     return
 754         $v =~ m/^[ty1]/ ? 1 :
 755         $v =~ m/^[fn0]/ ? 0 :
 756         badcfg "$what needs t (true, y, 1) or f (false, n, 0) not \`$v'";
 757 }
 758
 759 sub access_forpush_config () {
 760     my $d = access_basedistro();
 761
 762     return 1 if
 763         $new_package &&
 764         parse_cfg_bool('new-private-pushers', 0,
 765                        cfg("dgit-distro.$d.new-private-pushers",
 766                            'RETURN-UNDEF'));
 767
 768     my $v = cfg("dgit-distro.$d.readonly", 'RETURN-UNDEF');
 769     $v //= 'a';
 770     return
 771         $v =~ m/^[ty1]/ ? 0 : # force readonly,    forpush = 0
 772         $v =~ m/^[fn0]/ ? 1 : # force nonreadonly, forpush = 1
 773         $v =~ m/^[a]/  ? '' : # auto,              forpush = ''
 774         badcfg "readonly needs t (true, y, 1) or f (false, n, 0) or a (auto)";
 775 }
 776
 777 sub access_forpush () {
 778     $access_forpush //= access_forpush_config();
 779     return $access_forpush;
 780 }
 781
 782 sub pushing () {
 783     die "$access_forpush ?" if ($access_forpush // 1) ne 1;
 784     badcfg "pushing but distro is configured readonly"
 785         if access_forpush_config() eq '0';
 786     $access_forpush = 1;
 787     $supplementary_message = <<'END' unless $we_are_responder;
 788 Push failed, before we got started.
 789 You can retry the push, after fixing the problem, if you like.
 790 END
 791     parseopts_late_defaults();
 792 }
 793
 794 sub notpushing () {
 795     parseopts_late_defaults();
 796 }
 797
 798 sub supplementary_message ($) {
 799     my ($msg) = @_;
 800     if (!$we_are_responder) {
 801         $supplementary_message = $msg;
 802         return;
 803     } elsif ($protovsn >= 3) {
 804         responder_send_command "supplementary-message ".length($msg)
 805             or die $!;
 806         print PO $msg or die $!;
 807     }
 808 }
 809
 810 sub access_distros () {
 811     # Returns list of distros to try, in order
 812     #
 813     # We want to try:
 814     #    0. `instead of' distro name(s) we have been pointed to
 815     #    1. the access_quirk distro, if any
 816     #    2a. the user's specified distro, or failing that  } basedistro
 817     #    2b. the distro calculated from the suite          }
 818     my @l = access_basedistro();
 819
 820     my (undef,$quirkdistro) = access_quirk();
 821     unshift @l, $quirkdistro;
 822     unshift @l, $instead_distro;
 823     @l = grep { defined } @l;
 824
 825     push @l, access_nomdistro();
 826
 827     if (access_forpush()) {
 828         @l = map { ("$_/push", $_) } @l;
 829     }
 830     @l;
 831 }
 832
 833 sub access_cfg_cfgs (@) {
 834     my (@keys) = @_;
 835     my @cfgs;
 836     # The nesting of these loops determines the search order.  We put
 837     # the key loop on the outside so that we search all the distros
 838     # for each key, before going on to the next key.  That means that
 839     # if access_cfg is called with a more specific, and then a less
 840     # specific, key, an earlier distro can override the less specific
 841     # without necessarily overriding any more specific keys.  (If the
 842     # distro wants to override the more specific keys it can simply do
 843     # so; whereas if we did the loop the other way around, it would be
 844     # impossible to for an earlier distro to override a less specific
 845     # key but not the more specific ones without restating the unknown
 846     # values of the more specific keys.
 847     my @realkeys;
 848     my @rundef;
 849     # We have to deal with RETURN-UNDEF specially, so that we don't
 850     # terminate the search prematurely.
 851     foreach (@keys) {
 852         if (m/RETURN-UNDEF/) { push @rundef, $_; last; }
 853         push @realkeys, $_
 854     }
 855     foreach my $d (access_distros()) {
 856         push @cfgs, map { "dgit-distro.$d.$_" } @realkeys;
 857     }
 858     push @cfgs, map { "dgit.default.$_" } @realkeys;
 859     push @cfgs, @rundef;
 860     return @cfgs;
 861 }
 862
 863 sub access_cfg (@) {
 864     my (@keys) = @_;
 865     my (@cfgs) = access_cfg_cfgs(@keys);
 866     my $value = cfg(@cfgs);
 867     return $value;
 868 }
 869
 870 sub access_cfg_bool ($$) {
 871     my ($def, @keys) = @_;
 872     parse_cfg_bool($keys[0], $def, access_cfg(@keys, 'RETURN-UNDEF'));
 873 }
 874
 875 sub string_to_ssh ($) {
 876     my ($spec) = @_;
 877     if ($spec =~ m/\s/) {
 878         return qw(sh -ec), 'exec '.$spec.' "$@"', 'x';
 879     } else {
 880         return ($spec);
 881     }
 882 }
 883
 884 sub access_cfg_ssh () {
 885     my $gitssh = access_cfg('ssh', 'RETURN-UNDEF');
 886     if (!defined $gitssh) {
 887         return @ssh;
 888     } else {
 889         return string_to_ssh $gitssh;
 890     }
 891 }
 892
 893 sub access_runeinfo ($) {
 894     my ($info) = @_;
 895     return ": dgit ".access_basedistro()." $info ;";
 896 }
 897
 898 sub access_someuserhost ($) {
 899     my ($some) = @_;
 900     my $user = access_cfg("$some-user-force", 'RETURN-UNDEF');
 901     defined($user) && length($user) or
 902         $user = access_cfg("$some-user",'username');
 903     my $host = access_cfg("$some-host");
 904     return length($user) ? "$user\@$host" : $host;
 905 }
 906
 907 sub access_gituserhost () {
 908     return access_someuserhost('git');
 909 }
 910
 911 sub access_giturl (;$) {
 912     my ($optional) = @_;
 913     my $url = access_cfg('git-url','RETURN-UNDEF');
 914     my $suffix;
 915     if (!length $url) {
 916         my $proto = access_cfg('git-proto', 'RETURN-UNDEF');
 917         return undef unless defined $proto;
 918         $url =
 919             $proto.
 920             access_gituserhost().
 921             access_cfg('git-path');
 922     } else {
 923         $suffix = access_cfg('git-url-suffix','RETURN-UNDEF');
 924     }
 925     $suffix //= '.git';
 926     return "$url/$package$suffix";
 927 }
 928
 929 sub parsecontrolfh ($$;$) {
 930     my ($fh, $desc, $allowsigned) = @_;
 931     our $dpkgcontrolhash_noissigned;
 932     my $c;
 933     for (;;) {
 934         my %opts = ('name' => $desc);
 935         $opts{allow_pgp}= $allowsigned || !$dpkgcontrolhash_noissigned;
 936         $c = Dpkg::Control::Hash->new(%opts);
 937         $c->parse($fh,$desc) or die "parsing of $desc failed";
 938         last if $allowsigned;
 939         last if $dpkgcontrolhash_noissigned;
 940         my $issigned= $c->get_option('is_pgp_signed');
 941         if (!defined $issigned) {
 942             $dpkgcontrolhash_noissigned= 1;
 943             seek $fh, 0,0 or die "seek $desc: $!";
 944         } elsif ($issigned) {
 945             fail "control file $desc is (already) PGP-signed. ".
 946                 " Note that dgit push needs to modify the .dsc and then".
 947                 " do the signature itself";
 948         } else {
 949             last;
 950         }
 951     }
 952     return $c;
 953 }
 954
 955 sub parsecontrol {
 956     my ($file, $desc, $allowsigned) = @_;
 957     my $fh = new IO::Handle;
 958     open $fh, '<', $file or die "$file: $!";
 959     my $c = parsecontrolfh($fh,$desc,$allowsigned);
 960     $fh->error and die $!;
 961     close $fh;
 962     return $c;
 963 }
 964
 965 sub getfield ($$) {
 966     my ($dctrl,$field) = @_;
 967     my $v = $dctrl->{$field};
 968     return $v if defined $v;
 969     fail "missing field $field in ".$dctrl->get_option('name');
 970 }
 971
 972 sub parsechangelog {
 973     my $c = Dpkg::Control::Hash->new(name => 'parsed changelog');
 974     my $p = new IO::Handle;
 975     my @cmd = (qw(dpkg-parsechangelog), @_);
 976     open $p, '-|', @cmd or die $!;
 977     $c->parse($p);
 978     $?=0; $!=0; close $p or failedcmd @cmd;
 979     return $c;
 980 }
 981
 982 sub commit_getclogp ($) {
 983     # Returns the parsed changelog hashref for a particular commit
 984     my ($objid) = @_;
 985     our %commit_getclogp_memo;
 986     my $memo = $commit_getclogp_memo{$objid};
 987     return $memo if $memo;
 988     mkpath '.git/dgit';
 989     my $mclog = ".git/dgit/clog-$objid";
 990     runcmd shell_cmd "exec >$mclog", @git, qw(cat-file blob),
 991         "$objid:debian/changelog";
 992     $commit_getclogp_memo{$objid} = parsechangelog("-l$mclog");
 993 }
 994
 995 sub must_getcwd () {
 996     my $d = getcwd();
 997     defined $d or fail "getcwd failed: $!";
 998     return $d;
 999 }
1000
1001 sub parse_dscdata () {
1002     my $dscfh = new IO::File \$dscdata, '<' or die $!;
1003     printdebug Dumper($dscdata) if $debuglevel>1;
1004     $dsc = parsecontrolfh($dscfh,$dscurl,1);
1005     printdebug Dumper($dsc) if $debuglevel>1;
1006 }
1007
1008 our %rmad;
1009
1010 sub archive_query ($;@) {
1011     my ($method) = shift @_;
1012     fail "this operation does not support multiple comma-separated suites"
1013         if $isuite =~ m/,/;
1014     my $query = access_cfg('archive-query','RETURN-UNDEF');
1015     $query =~ s/^(\w+):// or badcfg "invalid archive-query method \`$query'";
1016     my $proto = $1;
1017     my $data = $'; #';
1018     { no strict qw(refs); &{"${method}_${proto}"}($proto,$data,@_); }
1019 }
1020
1021 sub archive_query_prepend_mirror {
1022     my $m = access_cfg('mirror');
1023     return map { [ $_->[0], $m.$_->[1], @$_[2..$#$_] ] } @_;
1024 }
1025
1026 sub pool_dsc_subpath ($$) {
1027     my ($vsn,$component) = @_; # $package is implict arg
1028     my $prefix = substr($package, 0, $package =~ m/^l/ ? 4 : 1);
1029     return "/pool/$component/$prefix/$package/".dscfn($vsn);
1030 }
1031
1032 sub cfg_apply_map ($$$) {
1033     my ($varref, $what, $mapspec) = @_;
1034     return unless $mapspec;
1035
1036     printdebug "config $what EVAL{ $mapspec; }\n";
1037     $_ = $$varref;
1038     eval "package Dgit::Config; $mapspec;";
1039     die $@ if $@;
1040     $$varref = $_;
1041 }
1042
1043 #---------- `ftpmasterapi' archive query method (nascent) ----------
1044
1045 sub archive_api_query_cmd ($) {
1046     my ($subpath) = @_;
1047     my @cmd = (@curl, qw(-sS));
1048     my $url = access_cfg('archive-query-url');
1049     if ($url =~ m#^https://([-.0-9a-z]+)/#) {
1050         my $host = $1;
1051         my $keys = access_cfg('archive-query-tls-key','RETURN-UNDEF') //'';
1052         foreach my $key (split /\:/, $keys) {
1053             $key =~ s/\%HOST\%/$host/g;
1054             if (!stat $key) {
1055                 fail "for $url: stat $key: $!" unless $!==ENOENT;
1056                 next;
1057             }
1058             fail "config requested specific TLS key but do not know".
1059                 " how to get curl to use exactly that EE key ($key)";
1060 #           push @cmd, "--cacert", $key, "--capath", "/dev/enoent";
1061 #           # Sadly the above line does not work because of changes
1062 #           # to gnutls.   The real fix for #790093 may involve
1063 #           # new curl options.
1064             last;
1065         }
1066         # Fixing #790093 properly will involve providing a value
1067         # for this on clients.
1068         my $kargs = access_cfg('archive-query-tls-curl-ca-args','RETURN-UNDEF');
1069         push @cmd, split / /, $kargs if defined $kargs;
1070     }
1071     push @cmd, $url.$subpath;
1072     return @cmd;
1073 }
1074
1075 sub api_query ($$;$) {
1076     use JSON;
1077     my ($data, $subpath, $ok404) = @_;
1078     badcfg "ftpmasterapi archive query method takes no data part"
1079         if length $data;
1080     my @cmd = archive_api_query_cmd($subpath);
1081     my $url = $cmd[$#cmd];
1082     push @cmd, qw(-w %{http_code});
1083     my $json = cmdoutput @cmd;
1084     unless ($json =~ s/\d+\d+\d$//) {
1085         failedcmd_report_cmd undef, @cmd;
1086         fail "curl failed to print 3-digit HTTP code";
1087     }
1088     my $code = $&;
1089     return undef if $code eq '404' && $ok404;
1090     fail "fetch of $url gave HTTP code $code"
1091         unless $url =~ m#^file://# or $code =~ m/^2/;
1092     return decode_json($json);
1093 }
1094
1095 sub canonicalise_suite_ftpmasterapi {
1096     my ($proto,$data) = @_;
1097     my $suites = api_query($data, 'suites');
1098     my @matched;
1099     foreach my $entry (@$suites) {
1100         next unless grep {
1101             my $v = $entry->{$_};
1102             defined $v && $v eq $isuite;
1103         } qw(codename name);
1104         push @matched, $entry;
1105     }
1106     fail "unknown suite $isuite" unless @matched;
1107     my $cn;
1108     eval {
1109         @matched==1 or die "multiple matches for suite $isuite\n";
1110         $cn = "$matched[0]{codename}";
1111         defined $cn or die "suite $isuite info has no codename\n";
1112         $cn =~ m/^$suite_re$/ or die "suite $isuite maps to bad codename\n";
1113     };
1114     die "bad ftpmaster api response: $@\n".Dumper(\@matched)
1115         if length $@;
1116     return $cn;
1117 }
1118
1119 sub archive_query_ftpmasterapi {
1120     my ($proto,$data) = @_;
1121     my $info = api_query($data, "dsc_in_suite/$isuite/$package");
1122     my @rows;
1123     my $digester = Digest::SHA->new(256);
1124     foreach my $entry (@$info) {
1125         eval {
1126             my $vsn = "$entry->{version}";
1127             my ($ok,$msg) = version_check $vsn;
1128             die "bad version: $msg\n" unless $ok;
1129             my $component = "$entry->{component}";
1130             $component =~ m/^$component_re$/ or die "bad component";
1131             my $filename = "$entry->{filename}";
1132             $filename && $filename !~ m#[^-+:._~0-9a-zA-Z/]|^[/.]|/[/.]#
1133                 or die "bad filename";
1134             my $sha256sum = "$entry->{sha256sum}";
1135             $sha256sum =~ m/^[0-9a-f]+$/ or die "bad sha256sum";
1136             push @rows, [ $vsn, "/pool/$component/$filename",
1137                           $digester, $sha256sum ];
1138         };
1139         die "bad ftpmaster api response: $@\n".Dumper($entry)
1140             if length $@;
1141     }
1142     @rows = sort { -version_compare($a->[0],$b->[0]) } @rows;
1143     return archive_query_prepend_mirror @rows;
1144 }
1145
1146 sub file_in_archive_ftpmasterapi {
1147     my ($proto,$data,$filename) = @_;
1148     my $pat = $filename;
1149     $pat =~ s/_/\\_/g;
1150     $pat = "%/$pat";
1151     $pat =~ s#[^-+_.0-9a-z/]# sprintf '%%%02x', ord $& #ge;
1152     my $info = api_query($data, "file_in_archive/$pat", 1);
1153 }
1154
1155 #---------- `aptget' archive query method ----------
1156
1157 our $aptget_base;
1158 our $aptget_releasefile;
1159 our $aptget_configpath;
1160
1161 sub aptget_aptget   () { return @aptget,   qw(-c), $aptget_configpath; }
1162 sub aptget_aptcache () { return @aptcache, qw(-c), $aptget_configpath; }
1163
1164 sub aptget_cache_clean {
1165     runcmd_ordryrun_local qw(sh -ec),
1166         'cd "$1"; find -atime +30 -type f -print0 | xargs -0r rm --',
1167         'x', $aptget_base;
1168 }
1169
1170 sub aptget_lock_acquire () {
1171     my $lockfile = "$aptget_base/lock";
1172     open APTGET_LOCK, '>', $lockfile or die "open $lockfile: $!";
1173     flock APTGET_LOCK, LOCK_EX or die "lock $lockfile: $!";
1174 }
1175
1176 sub aptget_prep ($) {
1177     my ($data) = @_;
1178     return if defined $aptget_base;
1179
1180     badcfg "aptget archive query method takes no data part"
1181         if length $data;
1182
1183     my $cache = $ENV{XDG_CACHE_DIR} // "$ENV{HOME}/.cache";
1184
1185     ensuredir $cache;
1186     ensuredir "$cache/dgit";
1187     my $cachekey =
1188         access_cfg('aptget-cachekey','RETURN-UNDEF')
1189         // access_nomdistro();
1190
1191     $aptget_base = "$cache/dgit/aptget";
1192     ensuredir $aptget_base;
1193
1194     my $quoted_base = $aptget_base;
1195     die "$quoted_base contains bad chars, cannot continue"
1196         if $quoted_base =~ m/["\\]/; # apt.conf(5) says no escaping :-/
1197
1198     ensuredir $aptget_base;
1199
1200     aptget_lock_acquire();
1201
1202     aptget_cache_clean();
1203
1204     $aptget_configpath = "$aptget_base/apt.conf#$cachekey";
1205     my $sourceslist = "source.list#$cachekey";
1206
1207     my $aptsuites = $isuite;
1208     cfg_apply_map(\$aptsuites, 'suite map',
1209                   access_cfg('aptget-suite-map', 'RETURN-UNDEF'));
1210
1211     open SRCS, ">", "$aptget_base/$sourceslist" or die $!;
1212     printf SRCS "deb-src %s %s %s\n",
1213         access_cfg('mirror'),
1214         $aptsuites,
1215         access_cfg('aptget-components')
1216         or die $!;
1217
1218     ensuredir "$aptget_base/cache";
1219     ensuredir "$aptget_base/lists";
1220
1221     open CONF, ">", $aptget_configpath or die $!;
1222     print CONF <<END;
1223 Debug::NoLocking "true";
1224 APT::Get::List-Cleanup "false";
1225 #clear APT::Update::Post-Invoke-Success;
1226 Dir::Etc::SourceList "$quoted_base/$sourceslist";
1227 Dir::State::Lists "$quoted_base/lists";
1228 Dir::Etc::preferences "$quoted_base/preferences";
1229 Dir::Cache::srcpkgcache "$quoted_base/cache/srcs#$cachekey";
1230 Dir::Cache::pkgcache "$quoted_base/cache/pkgs#$cachekey";
1231 END
1232
1233     foreach my $key (qw(
1234                         Dir::Cache
1235                         Dir::State
1236                         Dir::Cache::Archives
1237                         Dir::Etc::SourceParts
1238                         Dir::Etc::preferencesparts
1239                       )) {
1240         ensuredir "$aptget_base/$key";
1241         print CONF "$key \"$quoted_base/$key\";\n" or die $!;
1242     };
1243
1244     my $oldatime = (time // die $!) - 1;
1245     foreach my $oldlist (<$aptget_base/lists/*Release>) {
1246         next unless stat_exists $oldlist;
1247         my ($mtime) = (stat _)[9];
1248         utime $oldatime, $mtime, $oldlist or die "$oldlist $!";
1249     }
1250
1251     runcmd_ordryrun_local aptget_aptget(), qw(update);
1252
1253     my @releasefiles;
1254     foreach my $oldlist (<$aptget_base/lists/*Release>) {
1255         next unless stat_exists $oldlist;
1256         my ($atime) = (stat _)[8];
1257         next if $atime == $oldatime;
1258         push @releasefiles, $oldlist;
1259     }
1260     my @inreleasefiles = grep { m#/InRelease$# } @releasefiles;
1261     @releasefiles = @inreleasefiles if @inreleasefiles;
1262     die "apt updated wrong number of Release files (@releasefiles), erk"
1263         unless @releasefiles == 1;
1264
1265     ($aptget_releasefile) = @releasefiles;
1266 }
1267
1268 sub canonicalise_suite_aptget {
1269     my ($proto,$data) = @_;
1270     aptget_prep($data);
1271
1272     my $release = parsecontrol $aptget_releasefile, "Release file", 1;
1273
1274     foreach my $name (qw(Codename Suite)) {
1275         my $val = $release->{$name};
1276         if (defined $val) {
1277             printdebug "release file $name: $val\n";
1278             $val =~ m/^$suite_re$/o or fail
1279  "Release file ($aptget_releasefile) specifies intolerable $name";
1280             cfg_apply_map(\$val, 'suite rmap',
1281                           access_cfg('aptget-suite-rmap', 'RETURN-UNDEF'));
1282             return $val
1283         }
1284     }
1285     return $isuite;
1286 }
1287
1288 sub archive_query_aptget {
1289     my ($proto,$data) = @_;
1290     aptget_prep($data);
1291
1292     ensuredir "$aptget_base/source";
1293     foreach my $old (<$aptget_base/source/*.dsc>) {
1294         unlink $old or die "$old: $!";
1295     }
1296
1297     my $showsrc = cmdoutput aptget_aptcache(), qw(showsrc), $package;
1298     return () unless $showsrc =~ m/^package:\s*\Q$package\E\s*$/mi;
1299     # avoids apt-get source failing with ambiguous error code
1300
1301     runcmd_ordryrun_local
1302         shell_cmd 'cd "$1"/source; shift', $aptget_base,
1303         aptget_aptget(), qw(--download-only --only-source source), $package;
1304
1305     my @dscs = <$aptget_base/source/*.dsc>;
1306     fail "apt-get source did not produce a .dsc" unless @dscs;
1307     fail "apt-get source produced several .dscs (@dscs)" unless @dscs==1;
1308
1309     my $pre_dsc = parsecontrol $dscs[0], $dscs[0], 1;
1310
1311     use URI::Escape;
1312     my $uri = "file://". uri_escape $dscs[0];
1313     $uri =~ s{\%2f}{/}gi;
1314     return [ (getfield $pre_dsc, 'Version'), $uri ];
1315 }
1316
1317 #---------- `dummyapicat' archive query method ----------
1318
1319 sub archive_query_dummycatapi { archive_query_ftpmasterapi @_; }
1320 sub canonicalise_suite_dummycatapi { canonicalise_suite_ftpmasterapi @_; }
1321
1322 sub file_in_archive_dummycatapi ($$$) {
1323     my ($proto,$data,$filename) = @_;
1324     my $mirror = access_cfg('mirror');
1325     $mirror =~ s#^file://#/# or die "$mirror ?";
1326     my @out;
1327     my @cmd = (qw(sh -ec), '
1328             cd "$1"
1329             find -name "$2" -print0 |
1330             xargs -0r sha256sum
1331         ', qw(x), $mirror, $filename);
1332     debugcmd "-|", @cmd;
1333     open FIA, "-|", @cmd or die $!;
1334     while (<FIA>) {
1335         chomp or die;
1336         printdebug "| $_\n";
1337         m/^(\w+)  (\S+)$/ or die "$_ ?";
1338         push @out, { sha256sum => $1, filename => $2 };
1339     }
1340     close FIA or die failedcmd @cmd;
1341     return \@out;
1342 }
1343
1344 #---------- `madison' archive query method ----------
1345
1346 sub archive_query_madison {
1347     return archive_query_prepend_mirror
1348         map { [ @$_[0..1] ] } madison_get_parse(@_);
1349 }
1350
1351 sub madison_get_parse {
1352     my ($proto,$data) = @_;
1353     die unless $proto eq 'madison';
1354     if (!length $data) {
1355         $data= access_cfg('madison-distro','RETURN-UNDEF');
1356         $data //= access_basedistro();
1357     }
1358     $rmad{$proto,$data,$package} ||= cmdoutput
1359         qw(rmadison -asource),"-s$isuite","-u$data",$package;
1360     my $rmad = $rmad{$proto,$data,$package};
1361
1362     my @out;
1363     foreach my $l (split /\n/, $rmad) {
1364         $l =~ m{^ \s*( [^ \t|]+ )\s* \|
1365                   \s*( [^ \t|]+ )\s* \|
1366                   \s*( [^ \t|/]+ )(?:/([^ \t|/]+))? \s* \|
1367                   \s*( [^ \t|]+ )\s* }x or die "$rmad ?";
1368         $1 eq $package or die "$rmad $package ?";
1369         my $vsn = $2;
1370         my $newsuite = $3;
1371         my $component;
1372         if (defined $4) {
1373             $component = $4;
1374         } else {
1375             $component = access_cfg('archive-query-default-component');
1376         }
1377         $5 eq 'source' or die "$rmad ?";
1378         push @out, [$vsn,pool_dsc_subpath($vsn,$component),$newsuite];
1379     }
1380     return sort { -version_compare($a->[0],$b->[0]); } @out;
1381 }
1382
1383 sub canonicalise_suite_madison {
1384     # madison canonicalises for us
1385     my @r = madison_get_parse(@_);
1386     @r or fail
1387         "unable to canonicalise suite using package $package".
1388         " which does not appear to exist in suite $isuite;".
1389         " --existing-package may help";
1390     return $r[0][2];
1391 }
1392
1393 sub file_in_archive_madison { return undef; }
1394
1395 #---------- `sshpsql' archive query method ----------
1396
1397 sub sshpsql ($$$) {
1398     my ($data,$runeinfo,$sql) = @_;
1399     if (!length $data) {
1400         $data= access_someuserhost('sshpsql').':'.
1401             access_cfg('sshpsql-dbname');
1402     }
1403     $data =~ m/:/ or badcfg "invalid sshpsql method string \`$data'";
1404     my ($userhost,$dbname) = ($`,$'); #';
1405     my @rows;
1406     my @cmd = (access_cfg_ssh, $userhost,
1407                access_runeinfo("ssh-psql $runeinfo").
1408                " export LC_MESSAGES=C; export LC_CTYPE=C;".
1409                " ".shellquote qw(psql -A), $dbname, qw(-c), $sql);
1410     debugcmd "|",@cmd;
1411     open P, "-|", @cmd or die $!;
1412     while (<P>) {
1413         chomp or die;
1414         printdebug(">|$_|\n");
1415         push @rows, $_;
1416     }
1417     $!=0; $?=0; close P or failedcmd @cmd;
1418     @rows or die;
1419     my $nrows = pop @rows;
1420     $nrows =~ s/^\((\d+) rows?\)$/$1/ or die "$nrows ?";
1421     @rows == $nrows+1 or die "$nrows ".(scalar @rows)." ?";
1422     @rows = map { [ split /\|/, $_ ] } @rows;
1423     my $ncols = scalar @{ shift @rows };
1424     die if grep { scalar @$_ != $ncols } @rows;
1425     return @rows;
1426 }
1427
1428 sub sql_injection_check {
1429     foreach (@_) { die "$_ $& ?" if m{[^-+=:_.,/0-9a-zA-Z]}; }
1430 }
1431
1432 sub archive_query_sshpsql ($$) {
1433     my ($proto,$data) = @_;
1434     sql_injection_check $isuite, $package;
1435     my @rows = sshpsql($data, "archive-query $isuite $package", <<END);
1436         SELECT source.version, component.name, files.filename, files.sha256sum
1437           FROM source
1438           JOIN src_associations ON source.id = src_associations.source
1439           JOIN suite ON suite.id = src_associations.suite
1440           JOIN dsc_files ON dsc_files.source = source.id
1441           JOIN files_archive_map ON files_archive_map.file_id = dsc_files.file
1442           JOIN component ON component.id = files_archive_map.component_id
1443           JOIN files ON files.id = dsc_files.file
1444          WHERE ( suite.suite_name='$isuite' OR suite.codename='$isuite' )
1445            AND source.source='$package'
1446            AND files.filename LIKE '%.dsc';
1447 END
1448     @rows = sort { -version_compare($a->[0],$b->[0]) } @rows;
1449     my $digester = Digest::SHA->new(256);
1450     @rows = map {
1451         my ($vsn,$component,$filename,$sha256sum) = @$_;
1452         [ $vsn, "/pool/$component/$filename",$digester,$sha256sum ];
1453     } @rows;
1454     return archive_query_prepend_mirror @rows;
1455 }
1456
1457 sub canonicalise_suite_sshpsql ($$) {
1458     my ($proto,$data) = @_;
1459     sql_injection_check $isuite;
1460     my @rows = sshpsql($data, "canonicalise-suite $isuite", <<END);
1461         SELECT suite.codename
1462           FROM suite where suite_name='$isuite' or codename='$isuite';
1463 END
1464     @rows = map { $_->[0] } @rows;
1465     fail "unknown suite $isuite" unless @rows;
1466     die "ambiguous $isuite: @rows ?" if @rows>1;
1467     return $rows[0];
1468 }
1469
1470 sub file_in_archive_sshpsql ($$$) { return undef; }
1471
1472 #---------- `dummycat' archive query method ----------
1473
1474 sub canonicalise_suite_dummycat ($$) {
1475     my ($proto,$data) = @_;
1476     my $dpath = "$data/suite.$isuite";
1477     if (!open C, "<", $dpath) {
1478         $!==ENOENT or die "$dpath: $!";
1479         printdebug "dummycat canonicalise_suite $isuite $dpath ENOENT\n";
1480         return $isuite;
1481     }
1482     $!=0; $_ = <C>;
1483     chomp or die "$dpath: $!";
1484     close C;
1485     printdebug "dummycat canonicalise_suite $isuite $dpath = $_\n";
1486     return $_;
1487 }
1488
1489 sub archive_query_dummycat ($$) {
1490     my ($proto,$data) = @_;
1491     canonicalise_suite();
1492     my $dpath = "$data/package.$csuite.$package";
1493     if (!open C, "<", $dpath) {
1494         $!==ENOENT or die "$dpath: $!";
1495         printdebug "dummycat query $csuite $package $dpath ENOENT\n";
1496         return ();
1497     }
1498     my @rows;
1499     while (<C>) {
1500         next if m/^\#/;
1501         next unless m/\S/;
1502         die unless chomp;
1503         printdebug "dummycat query $csuite $package $dpath | $_\n";
1504         my @row = split /\s+/, $_;
1505         @row==2 or die "$dpath: $_ ?";
1506         push @rows, \@row;
1507     }
1508     C->error and die "$dpath: $!";
1509     close C;
1510     return archive_query_prepend_mirror
1511         sort { -version_compare($a->[0],$b->[0]); } @rows;
1512 }
1513
1514 sub file_in_archive_dummycat () { return undef; }
1515
1516 #---------- tag format handling ----------
1517
1518 sub access_cfg_tagformats () {
1519     split /\,/, access_cfg('dgit-tag-format');
1520 }
1521
1522 sub access_cfg_tagformats_can_splitbrain () {
1523     my %y = map { $_ => 1 } access_cfg_tagformats;
1524     foreach my $needtf (qw(new maint)) {
1525         next if $y{$needtf};
1526         return 0;
1527     }
1528     return 1;
1529 }
1530
1531 sub need_tagformat ($$) {
1532     my ($fmt, $why) = @_;
1533     fail "need to use tag format $fmt ($why) but also need".
1534         " to use tag format $tagformat_want->[0] ($tagformat_want->[1])".
1535         " - no way to proceed"
1536         if $tagformat_want && $tagformat_want->[0] ne $fmt;
1537     $tagformat_want = [$fmt, $why, $tagformat_want->[2] // 0];
1538 }
1539
1540 sub select_tagformat () {
1541     # sets $tagformatfn
1542     return if $tagformatfn && !$tagformat_want;
1543     die 'bug' if $tagformatfn && $tagformat_want;
1544     # ... $tagformat_want assigned after previous select_tagformat
1545
1546     my (@supported) = grep { $_ =~ m/^(?:old|new)$/ } access_cfg_tagformats();
1547     printdebug "select_tagformat supported @supported\n";
1548
1549     $tagformat_want //= [ $supported[0], "distro access configuration", 0 ];
1550     printdebug "select_tagformat specified @$tagformat_want\n";
1551
1552     my ($fmt,$why,$override) = @$tagformat_want;
1553
1554     fail "target distro supports tag formats @supported".
1555         " but have to use $fmt ($why)"
1556         unless $override
1557             or grep { $_ eq $fmt } @supported;
1558
1559     $tagformat_want = undef;
1560     $tagformat = $fmt;
1561     $tagformatfn = ${*::}{"debiantag_$fmt"};
1562
1563     fail "trying to use unknown tag format \`$fmt' ($why) !"
1564         unless $tagformatfn;
1565 }
1566
1567 #---------- archive query entrypoints and rest of program ----------
1568
1569 sub canonicalise_suite () {
1570     return if defined $csuite;
1571     fail "cannot operate on $isuite suite" if $isuite eq 'UNRELEASED';
1572     $csuite = archive_query('canonicalise_suite');
1573     if ($isuite ne $csuite) {
1574         progress "canonical suite name for $isuite is $csuite";
1575     } else {
1576         progress "canonical suite name is $csuite";
1577     }
1578 }
1579
1580 sub get_archive_dsc () {
1581     canonicalise_suite();
1582     my @vsns = archive_query('archive_query');
1583     foreach my $vinfo (@vsns) {
1584         my ($vsn,$vsn_dscurl,$digester,$digest) = @$vinfo;
1585         $dscurl = $vsn_dscurl;
1586         $dscdata = url_get($dscurl);
1587         if (!$dscdata) {
1588             $skew_warning_vsn = $vsn if !defined $skew_warning_vsn;
1589             next;
1590         }
1591         if ($digester) {
1592             $digester->reset();
1593             $digester->add($dscdata);
1594             my $got = $digester->hexdigest();
1595             $got eq $digest or
1596                 fail "$dscurl has hash $got but".
1597                     " archive told us to expect $digest";
1598         }
1599         parse_dscdata();
1600         my $fmt = getfield $dsc, 'Format';
1601         $format_ok{$fmt} or forceable_fail [qw(unsupported-source-format)],
1602             "unsupported source format $fmt, sorry";
1603
1604         $dsc_checked = !!$digester;
1605         printdebug "get_archive_dsc: Version ".(getfield $dsc, 'Version')."\n";
1606         return;
1607     }
1608     $dsc = undef;
1609     printdebug "get_archive_dsc: nothing in archive, returning undef\n";
1610 }
1611
1612 sub check_for_git ();
1613 sub check_for_git () {
1614     # returns 0 or 1
1615     my $how = access_cfg('git-check');
1616     if ($how eq 'ssh-cmd') {
1617         my @cmd =
1618             (access_cfg_ssh, access_gituserhost(),
1619              access_runeinfo("git-check $package").
1620              " set -e; cd ".access_cfg('git-path').";".
1621              " if test -d $package.git; then echo 1; else echo 0; fi");
1622         my $r= cmdoutput @cmd;
1623         if (defined $r and $r =~ m/^divert (\w+)$/) {
1624             my $divert=$1;
1625             my ($usedistro,) = access_distros();
1626             # NB that if we are pushing, $usedistro will be $distro/push
1627             $instead_distro= cfg("dgit-distro.$usedistro.diverts.$divert");
1628             $instead_distro =~ s{^/}{ access_basedistro()."/" }e;
1629             progress "diverting to $divert (using config for $instead_distro)";
1630             return check_for_git();
1631         }
1632         failedcmd @cmd unless defined $r and $r =~ m/^[01]$/;
1633         return $r+0;
1634     } elsif ($how eq 'url') {
1635         my $prefix = access_cfg('git-check-url','git-url');
1636         my $suffix = access_cfg('git-check-suffix','git-suffix',
1637                                 'RETURN-UNDEF') // '.git';
1638         my $url = "$prefix/$package$suffix";
1639         my @cmd = (@curl, qw(-sS -I), $url);
1640         my $result = cmdoutput @cmd;
1641         $result =~ s/^\S+ 200 .*\n\r?\n//;
1642         # curl -sS -I with https_proxy prints
1643         # HTTP/1.0 200 Connection established
1644         $result =~ m/^\S+ (404|200) /s or
1645             fail "unexpected results from git check query - ".
1646                 Dumper($prefix, $result);
1647         my $code = $1;
1648         if ($code eq '404') {
1649             return 0;
1650         } elsif ($code eq '200') {
1651             return 1;
1652         } else {
1653             die;
1654         }
1655     } elsif ($how eq 'true') {
1656         return 1;
1657     } elsif ($how eq 'false') {
1658         return 0;
1659     } else {
1660         badcfg "unknown git-check \`$how'";
1661     }
1662 }
1663
1664 sub create_remote_git_repo () {
1665     my $how = access_cfg('git-create');
1666     if ($how eq 'ssh-cmd') {
1667         runcmd_ordryrun
1668             (access_cfg_ssh, access_gituserhost(),
1669              access_runeinfo("git-create $package").
1670              "set -e; cd ".access_cfg('git-path').";".
1671              " cp -a _template $package.git");
1672     } elsif ($how eq 'true') {
1673         # nothing to do
1674     } else {
1675         badcfg "unknown git-create \`$how'";
1676     }
1677 }
1678
1679 our ($dsc_hash,$lastpush_mergeinput);
1680 our ($dsc_distro, $dsc_hint_tag, $dsc_hint_url);
1681
1682 our $ud = '.git/dgit/unpack';
1683
1684 sub prep_ud (;$) {
1685     my ($d) = @_;
1686     $d //= $ud;
1687     rmtree($d);
1688     mkpath '.git/dgit';
1689     mkdir $d or die $!;
1690 }
1691
1692 sub mktree_in_ud_here () {
1693     runcmd qw(git init -q);
1694     runcmd qw(git config gc.auto 0);
1695     rmtree('.git/objects');
1696     symlink '../../../../objects','.git/objects' or die $!;
1697 }
1698
1699 sub git_write_tree () {
1700     my $tree = cmdoutput @git, qw(write-tree);
1701     $tree =~ m/^\w+$/ or die "$tree ?";
1702     return $tree;
1703 }
1704
1705 sub git_add_write_tree () {
1706     runcmd @git, qw(add -Af .);
1707     return git_write_tree();
1708 }
1709
1710 sub remove_stray_gits ($) {
1711     my ($what) = @_;
1712     my @gitscmd = qw(find -name .git -prune -print0);
1713     debugcmd "|",@gitscmd;
1714     open GITS, "-|", @gitscmd or die $!;
1715     {
1716         local $/="\0";
1717         while (<GITS>) {
1718             chomp or die;
1719             print STDERR "$us: warning: removing from $what: ",
1720                 (messagequote $_), "\n";
1721             rmtree $_;
1722         }
1723     }
1724     $!=0; $?=0; close GITS or failedcmd @gitscmd;
1725 }
1726
1727 sub mktree_in_ud_from_only_subdir ($;$) {
1728     my ($what,$raw) = @_;
1729
1730     # changes into the subdir
1731     my (@dirs) = <*/.>;
1732     die "expected one subdir but found @dirs ?" unless @dirs==1;
1733     $dirs[0] =~ m#^([^/]+)/\.$# or die;
1734     my $dir = $1;
1735     changedir $dir;
1736
1737     remove_stray_gits($what);
1738     mktree_in_ud_here();
1739     if (!$raw) {
1740         my ($format, $fopts) = get_source_format();
1741         if (madformat($format)) {
1742             rmtree '.pc';
1743         }
1744     }
1745
1746     my $tree=git_add_write_tree();
1747     return ($tree,$dir);
1748 }
1749
1750 our @files_csum_info_fields =
1751     (['Checksums-Sha256','Digest::SHA', 'new(256)', 'sha256sum'],
1752      ['Checksums-Sha1',  'Digest::SHA', 'new(1)',   'sha1sum'],
1753      ['Files',           'Digest::MD5', 'new()',    'md5sum']);
1754
1755 sub dsc_files_info () {
1756     foreach my $csumi (@files_csum_info_fields) {
1757         my ($fname, $module, $method) = @$csumi;
1758         my $field = $dsc->{$fname};
1759         next unless defined $field;
1760         eval "use $module; 1;" or die $@;
1761         my @out;
1762         foreach (split /\n/, $field) {
1763             next unless m/\S/;
1764             m/^(\w+) (\d+) (\S+)$/ or
1765                 fail "could not parse .dsc $fname line \`$_'";
1766             my $digester = eval "$module"."->$method;" or die $@;
1767             push @out, {
1768                 Hash => $1,
1769                 Bytes => $2,
1770                 Filename => $3,
1771                 Digester => $digester,
1772             };
1773         }
1774         return @out;
1775     }
1776     fail "missing any supported Checksums-* or Files field in ".
1777         $dsc->get_option('name');
1778 }
1779
1780 sub dsc_files () {
1781     map { $_->{Filename} } dsc_files_info();
1782 }
1783
1784 sub files_compare_inputs (@) {
1785     my $inputs = \@_;
1786     my %record;
1787     my %fchecked;
1788
1789     my $showinputs = sub {
1790         return join "; ", map { $_->get_option('name') } @$inputs;
1791     };
1792
1793     foreach my $in (@$inputs) {
1794         my $expected_files;
1795         my $in_name = $in->get_option('name');
1796
1797         printdebug "files_compare_inputs $in_name\n";
1798
1799         foreach my $csumi (@files_csum_info_fields) {
1800             my ($fname) = @$csumi;
1801             printdebug "files_compare_inputs $in_name $fname\n";
1802
1803             my $field = $in->{$fname};
1804             next unless defined $field;
1805
1806             my @files;
1807             foreach (split /\n/, $field) {
1808                 next unless m/\S/;
1809
1810                 my ($info, $f) = m/^(\w+ \d+) (?:\S+ \S+ )?(\S+)$/ or
1811                     fail "could not parse $in_name $fname line \`$_'";
1812
1813                 printdebug "files_compare_inputs $in_name $fname $f\n";
1814
1815                 push @files, $f;
1816
1817                 my $re = \ $record{$f}{$fname};
1818                 if (defined $$re) {
1819                     $fchecked{$f}{$in_name} = 1;
1820                     $$re eq $info or
1821                         fail "hash or size of $f varies in $fname fields".
1822                         " (between: ".$showinputs->().")";
1823                 } else {
1824                     $$re = $info;
1825                 }
1826             }
1827             @files = sort @files;
1828             $expected_files //= \@files;
1829             "@$expected_files" eq "@files" or
1830                 fail "file list in $in_name varies between hash fields!";
1831         }
1832         $expected_files or
1833             fail "$in_name has no files list field(s)";
1834     }
1835     printdebug "files_compare_inputs ".Dumper(\%fchecked, \%record)
1836         if $debuglevel>=2;
1837
1838     grep { keys %$_ == @$inputs-1 } values %fchecked
1839         or fail "no file appears in all file lists".
1840         " (looked in: ".$showinputs->().")";
1841 }
1842
1843 sub is_orig_file_in_dsc ($$) {
1844     my ($f, $dsc_files_info) = @_;
1845     return 0 if @$dsc_files_info <= 1;
1846     # One file means no origs, and the filename doesn't have a "what
1847     # part of dsc" component.  (Consider versions ending `.orig'.)
1848     return 0 unless $f =~ m/\.$orig_f_tail_re$/o;
1849     return 1;
1850 }
1851
1852 sub is_orig_file_of_vsn ($$) {
1853     my ($f, $upstreamvsn) = @_;
1854     my $base = srcfn $upstreamvsn, '';
1855     return 0 unless $f =~ m/^\Q$base\E\.$orig_f_tail_re$/;
1856     return 1;
1857 }
1858
1859 sub changes_update_origs_from_dsc ($$$$) {
1860     my ($dsc, $changes, $upstreamvsn, $changesfile) = @_;
1861     my %changes_f;
1862     printdebug "checking origs needed ($upstreamvsn)...\n";
1863     $_ = getfield $changes, 'Files';
1864     m/^\w+ \d+ (\S+ \S+) \S+$/m or
1865         fail "cannot find section/priority from .changes Files field";
1866     my $placementinfo = $1;
1867     my %changed;
1868     printdebug "checking origs needed placement '$placementinfo'...\n";
1869     foreach my $l (split /\n/, getfield $dsc, 'Files') {
1870         $l =~ m/\S+$/ or next;
1871         my $file = $&;
1872         printdebug "origs $file | $l\n";
1873         next unless is_orig_file_of_vsn $file, $upstreamvsn;
1874         printdebug "origs $file is_orig\n";
1875         my $have = archive_query('file_in_archive', $file);
1876         if (!defined $have) {
1877             print STDERR <<END;
1878 archive does not support .orig check; hope you used --ch:--sa/-sd if needed
1879 END
1880             return;
1881         }
1882         my $found_same = 0;
1883         my @found_differ;
1884         printdebug "origs $file \$#\$have=$#$have\n";
1885         foreach my $h (@$have) {
1886             my $same = 0;
1887             my @differ;
1888             foreach my $csumi (@files_csum_info_fields) {
1889                 my ($fname, $module, $method, $archivefield) = @$csumi;
1890                 next unless defined $h->{$archivefield};
1891                 $_ = $dsc->{$fname};
1892                 next unless defined;
1893                 m/^(\w+) .* \Q$file\E$/m or
1894                     fail ".dsc $fname missing entry for $file";
1895                 if ($h->{$archivefield} eq $1) {
1896                     $same++;
1897                 } else {
1898                     push @differ,
1899  "$archivefield: $h->{$archivefield} (archive) != $1 (local .dsc)";
1900                 }
1901             }
1902             die "$file ".Dumper($h)." ?!" if $same && @differ;
1903             $found_same++
1904                 if $same;
1905             push @found_differ, "archive $h->{filename}: ".join "; ", @differ
1906                 if @differ;
1907         }
1908         printdebug "origs $file f.same=$found_same".
1909             " #f._differ=$#found_differ\n";
1910         if (@found_differ && !$found_same) {
1911             fail join "\n",
1912                 "archive contains $file with different checksum",
1913                 @found_differ;
1914         }
1915         # Now we edit the changes file to add or remove it
1916         foreach my $csumi (@files_csum_info_fields) {
1917             my ($fname, $module, $method, $archivefield) = @$csumi;
1918             next unless defined $changes->{$fname};
1919             if ($found_same) {
1920                 # in archive, delete from .changes if it's there
1921                 $changed{$file} = "removed" if
1922                     $changes->{$fname} =~ s/^.* \Q$file\E$(?:)\n//m;
1923             } elsif ($changes->{$fname} =~ m/^.* \Q$file\E$(?:)\n/m) {
1924                 # not in archive, but it's here in the .changes
1925             } else {
1926                 my $dsc_data = getfield $dsc, $fname;
1927                 $dsc_data =~ m/^(.* \Q$file\E$)\n/m or die "$dsc_data $file ?";
1928                 my $extra = $1;
1929                 $extra =~ s/ \d+ /$&$placementinfo /
1930                     or die "$fname $extra >$dsc_data< ?"
1931                     if $fname eq 'Files';
1932                 $changes->{$fname} .= "\n". $extra;
1933                 $changed{$file} = "added";
1934             }
1935         }
1936     }
1937     if (%changed) {
1938         foreach my $file (keys %changed) {
1939             progress sprintf
1940                 "edited .changes for archive .orig contents: %s %s",
1941                 $changed{$file}, $file;
1942         }
1943         my $chtmp = "$changesfile.tmp";
1944         $changes->save($chtmp);
1945         if (act_local()) {
1946             rename $chtmp,$changesfile or die "$changesfile $!";
1947         } else {
1948             progress "[new .changes left in $changesfile]";
1949         }
1950     } else {
1951         progress "$changesfile already has appropriate .orig(s) (if any)";
1952     }
1953 }
1954
1955 sub make_commit ($) {
1956     my ($file) = @_;
1957     return cmdoutput @git, qw(hash-object -w -t commit), $file;
1958 }
1959
1960 sub make_commit_text ($) {
1961     my ($text) = @_;
1962     my ($out, $in);
1963     my @cmd = (@git, qw(hash-object -w -t commit --stdin));
1964     debugcmd "|",@cmd;
1965     print Dumper($text) if $debuglevel > 1;
1966     my $child = open2($out, $in, @cmd) or die $!;
1967     my $h;
1968     eval {
1969         print $in $text or die $!;
1970         close $in or die $!;
1971         $h = <$out>;
1972         $h =~ m/^\w+$/ or die;
1973         $h = $&;
1974         printdebug "=> $h\n";
1975     };
1976     close $out;
1977     waitpid $child, 0 == $child or die "$child $!";
1978     $? and failedcmd @cmd;
1979     return $h;
1980 }
1981
1982 sub clogp_authline ($) {
1983     my ($clogp) = @_;
1984     my $author = getfield $clogp, 'Maintainer';
1985     $author =~ s#,.*##ms;
1986     my $date = cmdoutput qw(date), '+%s %z', qw(-d), getfield($clogp,'Date');
1987     my $authline = "$author $date";
1988     $authline =~ m/$git_authline_re/o or
1989         fail "unexpected commit author line format \`$authline'".
1990         " (was generated from changelog Maintainer field)";
1991     return ($1,$2,$3) if wantarray;
1992     return $authline;
1993 }
1994
1995 sub vendor_patches_distro ($$) {
1996     my ($checkdistro, $what) = @_;
1997     return unless defined $checkdistro;
1998
1999     my $series = "debian/patches/\L$checkdistro\E.series";
2000     printdebug "checking for vendor-specific $series ($what)\n";
2001
2002     if (!open SERIES, "<", $series) {
2003         die "$series $!" unless $!==ENOENT;
2004         return;
2005     }
2006     while (<SERIES>) {
2007         next unless m/\S/;
2008         next if m/^\s+\#/;
2009
2010         print STDERR <<END;
2011
2012 Unfortunately, this source package uses a feature of dpkg-source where
2013 the same source package unpacks to different source code on different
2014 distros.  dgit cannot safely operate on such packages on affected
2015 distros, because the meaning of source packages is not stable.
2016
2017 Please ask the distro/maintainer to remove the distro-specific series
2018 files and use a different technique (if necessary, uploading actually
2019 different packages, if different distros are supposed to have
2020 different code).
2021
2022 END
2023         fail "Found active distro-specific series file for".
2024             " $checkdistro ($what): $series, cannot continue";
2025     }
2026     die "$series $!" if SERIES->error;
2027     close SERIES;
2028 }
2029
2030 sub check_for_vendor_patches () {
2031     # This dpkg-source feature doesn't seem to be documented anywhere!
2032     # But it can be found in the changelog (reformatted):
2033
2034     #   commit  4fa01b70df1dc4458daee306cfa1f987b69da58c
2035     #   Author: Raphael Hertzog <hertzog@debian.org>
2036     #   Date: Sun  Oct  3  09:36:48  2010 +0200
2037
2038     #   dpkg-source: correctly create .pc/.quilt_series with alternate
2039     #   series files
2040     #
2041     #   If you have debian/patches/ubuntu.series and you were
2042     #   unpacking the source package on ubuntu, quilt was still
2043     #   directed to debian/patches/series instead of
2044     #   debian/patches/ubuntu.series.
2045     #
2046     #   debian/changelog                        |    3 +++
2047     #   scripts/Dpkg/Source/Package/V3/quilt.pm |    4 +++-
2048     #   2 files changed, 6 insertions(+), 1 deletion(-)
2049
2050     use Dpkg::Vendor;
2051     vendor_patches_distro($ENV{DEB_VENDOR}, "DEB_VENDOR");
2052     vendor_patches_distro(Dpkg::Vendor::get_current_vendor(),
2053                          "Dpkg::Vendor \`current vendor'");
2054     vendor_patches_distro(access_basedistro(),
2055                           "(base) distro being accessed");
2056     vendor_patches_distro(access_nomdistro(),
2057                           "(nominal) distro being accessed");
2058 }
2059
2060 sub generate_commits_from_dsc () {
2061     # See big comment in fetch_from_archive, below.
2062     # See also README.dsc-import.
2063     prep_ud();
2064     changedir $ud;
2065
2066     my @dfi = dsc_files_info();
2067     foreach my $fi (@dfi) {
2068         my $f = $fi->{Filename};
2069         die "$f ?" if $f =~ m#/|^\.|\.dsc$|\.tmp$#;
2070
2071         printdebug "considering linking $f: ";
2072
2073         link_ltarget "../../../../$f", $f
2074             or ((printdebug "($!) "), 0)
2075             or $!==&ENOENT
2076             or die "$f $!";
2077
2078         printdebug "linked.\n";
2079
2080         complete_file_from_dsc('.', $fi)
2081             or next;
2082
2083         if (is_orig_file_in_dsc($f, \@dfi)) {
2084             link $f, "../../../../$f"
2085                 or $!==&EEXIST
2086                 or die "$f $!";
2087         }
2088     }
2089
2090     # We unpack and record the orig tarballs first, so that we only
2091     # need disk space for one private copy of the unpacked source.
2092     # But we can't make them into commits until we have the metadata
2093     # from the debian/changelog, so we record the tree objects now and
2094     # make them into commits later.
2095     my @tartrees;
2096     my $upstreamv = upstreamversion $dsc->{version};
2097     my $orig_f_base = srcfn $upstreamv, '';
2098
2099     foreach my $fi (@dfi) {
2100         # We actually import, and record as a commit, every tarball
2101         # (unless there is only one file, in which case there seems
2102         # little point.
2103
2104         my $f = $fi->{Filename};
2105         printdebug "import considering $f ";
2106         (printdebug "only one dfi\n"), next if @dfi == 1;
2107         (printdebug "not tar\n"), next unless $f =~ m/\.tar(\.\w+)?$/;
2108         (printdebug "signature\n"), next if $f =~ m/$orig_f_sig_re$/o;
2109         my $compr_ext = $1;
2110
2111         my ($orig_f_part) =
2112             $f =~ m/^\Q$orig_f_base\E\.([^._]+)?\.tar(?:\.\w+)?$/;
2113
2114         printdebug "Y ", (join ' ', map { $_//"(none)" }
2115                           $compr_ext, $orig_f_part
2116                          ), "\n";
2117
2118         my $input = new IO::File $f, '<' or die "$f $!";
2119         my $compr_pid;
2120         my @compr_cmd;
2121
2122         if (defined $compr_ext) {
2123             my $cname =
2124                 Dpkg::Compression::compression_guess_from_filename $f;
2125             fail "Dpkg::Compression cannot handle file $f in source package"
2126                 if defined $compr_ext && !defined $cname;
2127             my $compr_proc =
2128                 new Dpkg::Compression::Process compression => $cname;
2129             my @compr_cmd = $compr_proc->get_uncompress_cmdline();
2130             my $compr_fh = new IO::Handle;
2131             my $compr_pid = open $compr_fh, "-|" // die $!;
2132             if (!$compr_pid) {
2133                 open STDIN, "<&", $input or die $!;
2134                 exec @compr_cmd;
2135                 die "dgit (child): exec $compr_cmd[0]: $!\n";
2136             }
2137             $input = $compr_fh;
2138         }
2139
2140         rmtree "_unpack-tar";
2141         mkdir "_unpack-tar" or die $!;
2142         my @tarcmd = qw(tar -x -f -
2143                         --no-same-owner --no-same-permissions
2144                         --no-acls --no-xattrs --no-selinux);
2145         my $tar_pid = fork // die $!;
2146         if (!$tar_pid) {
2147             chdir "_unpack-tar" or die $!;
2148             open STDIN, "<&", $input or die $!;
2149             exec @tarcmd;
2150             die "dgit (child): exec $tarcmd[0]: $!";
2151         }
2152         $!=0; (waitpid $tar_pid, 0) == $tar_pid or die $!;
2153         !$? or failedcmd @tarcmd;
2154
2155         close $input or
2156             (@compr_cmd ? failedcmd @compr_cmd
2157              : die $!);
2158         # finally, we have the results in "tarball", but maybe
2159         # with the wrong permissions
2160
2161         runcmd qw(chmod -R +rwX _unpack-tar);
2162         changedir "_unpack-tar";
2163         remove_stray_gits($f);
2164         mktree_in_ud_here();
2165
2166         my ($tree) = git_add_write_tree();
2167         my $tentries = cmdoutput @git, qw(ls-tree -z), $tree;
2168         if ($tentries =~ m/^\d+ tree (\w+)\t[^\000]+\000$/s) {
2169             $tree = $1;
2170             printdebug "one subtree $1\n";
2171         } else {
2172             printdebug "multiple subtrees\n";
2173         }
2174         changedir "..";
2175         rmtree "_unpack-tar";
2176
2177         my $ent = [ $f, $tree ];
2178         push @tartrees, {
2179             Orig => !!$orig_f_part,
2180             Sort => (!$orig_f_part         ? 2 :
2181                      $orig_f_part =~ m/-/g ? 1 :
2182                                              0),
2183             F => $f,
2184             Tree => $tree,
2185         };
2186     }
2187
2188     @tartrees = sort {
2189         # put any without "_" first (spec is not clear whether files
2190         # are always in the usual order).  Tarballs without "_" are
2191         # the main orig or the debian tarball.
2192         $a->{Sort} <=> $b->{Sort} or
2193         $a->{F}    cmp $b->{F}
2194     } @tartrees;
2195
2196     my $any_orig = grep { $_->{Orig} } @tartrees;
2197
2198     my $dscfn = "$package.dsc";
2199
2200     my $treeimporthow = 'package';
2201
2202     open D, ">", $dscfn or die "$dscfn: $!";
2203     print D $dscdata or die "$dscfn: $!";
2204     close D or die "$dscfn: $!";
2205     my @cmd = qw(dpkg-source);
2206     push @cmd, '--no-check' if $dsc_checked;
2207     if (madformat $dsc->{format}) {
2208         push @cmd, '--skip-patches';
2209         $treeimporthow = 'unpatched';
2210     }
2211     push @cmd, qw(-x --), $dscfn;
2212     runcmd @cmd;
2213
2214     my ($tree,$dir) = mktree_in_ud_from_only_subdir("source package");
2215     if (madformat $dsc->{format}) {
2216         check_for_vendor_patches();
2217     }
2218
2219     my $dappliedtree;
2220     if (madformat $dsc->{format}) {
2221         my @pcmd = qw(dpkg-source --before-build .);
2222         runcmd shell_cmd 'exec >/dev/null', @pcmd;
2223         rmtree '.pc';
2224         $dappliedtree = git_add_write_tree();
2225     }
2226
2227     my @clogcmd = qw(dpkg-parsechangelog --format rfc822 --all);
2228     debugcmd "|",@clogcmd;
2229     open CLOGS, "-|", @clogcmd or die $!;
2230
2231     my $clogp;
2232     my $r1clogp;
2233
2234     printdebug "import clog search...\n";
2235
2236     for (;;) {
2237         my $stanzatext = do { local $/=""; <CLOGS>; };
2238         printdebug "import clogp ".Dumper($stanzatext) if $debuglevel>1;
2239         last if !defined $stanzatext;
2240
2241         my $desc = "package changelog, entry no.$.";
2242         open my $stanzafh, "<", \$stanzatext or die;
2243         my $thisstanza = parsecontrolfh $stanzafh, $desc, 1;
2244         $clogp //= $thisstanza;
2245
2246         printdebug "import clog $thisstanza->{version} $desc...\n";
2247
2248         last if !$any_orig; # we don't need $r1clogp
2249
2250         # We look for the first (most recent) changelog entry whose
2251         # version number is lower than the upstream version of this
2252         # package.  Then the last (least recent) previous changelog
2253         # entry is treated as the one which introduced this upstream
2254         # version and used for the synthetic commits for the upstream
2255         # tarballs.
2256
2257         # One might think that a more sophisticated algorithm would be
2258         # necessary.  But: we do not want to scan the whole changelog
2259         # file.  Stopping when we see an earlier version, which
2260         # necessarily then is an earlier upstream version, is the only
2261         # realistic way to do that.  Then, either the earliest
2262         # changelog entry we have seen so far is indeed the earliest
2263         # upload of this upstream version; or there are only changelog
2264         # entries relating to later upstream versions (which is not
2265         # possible unless the changelog and .dsc disagree about the
2266         # version).  Then it remains to choose between the physically
2267         # last entry in the file, and the one with the lowest version
2268         # number.  If these are not the same, we guess that the
2269         # versions were created in a non-monotic order rather than
2270         # that the changelog entries have been misordered.
2271
2272         printdebug "import clog $thisstanza->{version} vs $upstreamv...\n";
2273
2274         last if version_compare($thisstanza->{version}, $upstreamv) < 0;
2275         $r1clogp = $thisstanza;
2276
2277         printdebug "import clog $r1clogp->{version} becomes r1\n";
2278     }
2279     die $! if CLOGS->error;
2280     close CLOGS or $?==SIGPIPE or failedcmd @clogcmd;
2281
2282     $clogp or fail "package changelog has no entries!";
2283
2284     my $authline = clogp_authline $clogp;
2285     my $changes = getfield $clogp, 'Changes';
2286     my $cversion = getfield $clogp, 'Version';
2287
2288     if (@tartrees) {
2289         $r1clogp //= $clogp; # maybe there's only one entry;
2290         my $r1authline = clogp_authline $r1clogp;
2291         # Strictly, r1authline might now be wrong if it's going to be
2292         # unused because !$any_orig.  Whatever.
2293
2294         printdebug "import tartrees authline   $authline\n";
2295         printdebug "import tartrees r1authline $r1authline\n";
2296
2297         foreach my $tt (@tartrees) {
2298             printdebug "import tartree $tt->{F} $tt->{Tree}\n";
2299
2300             $tt->{Commit} = make_commit_text($tt->{Orig} ? <<END_O : <<END_T);
2301 tree $tt->{Tree}
2302 author $r1authline
2303 committer $r1authline
2304
2305 Import $tt->{F}
2306
2307 [dgit import orig $tt->{F}]
2308 END_O
2309 tree $tt->{Tree}
2310 author $authline
2311 committer $authline
2312
2313 Import $tt->{F}
2314
2315 [dgit import tarball $package $cversion $tt->{F}]
2316 END_T
2317         }
2318     }
2319
2320     printdebug "import main commit\n";
2321
2322     open C, ">../commit.tmp" or die $!;
2323     print C <<END or die $!;
2324 tree $tree
2325 END
2326     print C <<END or die $! foreach @tartrees;
2327 parent $_->{Commit}
2328 END
2329     print C <<END or die $!;
2330 author $authline
2331 committer $authline
2332
2333 $changes
2334
2335 [dgit import $treeimporthow $package $cversion]
2336 END
2337
2338     close C or die $!;
2339     my $rawimport_hash = make_commit qw(../commit.tmp);
2340
2341     if (madformat $dsc->{format}) {
2342         printdebug "import apply patches...\n";
2343
2344         # regularise the state of the working tree so that
2345         # the checkout of $rawimport_hash works nicely.
2346         my $dappliedcommit = make_commit_text(<<END);
2347 tree $dappliedtree
2348 author $authline
2349 committer $authline
2350
2351 [dgit dummy commit]
2352 END
2353         runcmd @git, qw(checkout -q -b dapplied), $dappliedcommit;
2354
2355         runcmd @git, qw(checkout -q -b unpa), $rawimport_hash;
2356
2357         # We need the answers to be reproducible
2358         my @authline = clogp_authline($clogp);
2359         local $ENV{GIT_COMMITTER_NAME} =  $authline[0];
2360         local $ENV{GIT_COMMITTER_EMAIL} = $authline[1];
2361         local $ENV{GIT_COMMITTER_DATE} =  $authline[2];
2362         local $ENV{GIT_AUTHOR_NAME} =  $authline[0];
2363         local $ENV{GIT_AUTHOR_EMAIL} = $authline[1];
2364         local $ENV{GIT_AUTHOR_DATE} =  $authline[2];
2365
2366         my $path = $ENV{PATH} or die;
2367
2368         foreach my $use_absurd (qw(0 1)) {
2369             runcmd @git, qw(checkout -q unpa);
2370             runcmd @git, qw(update-ref -d refs/heads/patch-queue/unpa);
2371             local $ENV{PATH} = $path;
2372             if ($use_absurd) {
2373                 chomp $@;
2374                 progress "warning: $@";
2375                 $path = "$absurdity:$path";
2376                 progress "$us: trying slow absurd-git-apply...";
2377                 rename "../../gbp-pq-output","../../gbp-pq-output.0"
2378                     or $!==ENOENT
2379                     or die $!;
2380             }
2381             eval {
2382                 die "forbid absurd git-apply\n" if $use_absurd
2383                     && forceing [qw(import-gitapply-no-absurd)];
2384                 die "only absurd git-apply!\n" if !$use_absurd
2385                     && forceing [qw(import-gitapply-absurd)];
2386
2387                 local $ENV{DGIT_ABSURD_DEBUG} = $debuglevel if $use_absurd;
2388                 local $ENV{PATH} = $path                    if $use_absurd;
2389
2390                 my @showcmd = (gbp_pq, qw(import));
2391                 my @realcmd = shell_cmd
2392                     'exec >/dev/null 2>>../../gbp-pq-output', @showcmd;
2393                 debugcmd "+",@realcmd;
2394                 if (system @realcmd) {
2395                     die +(shellquote @showcmd).
2396                         " failed: ".
2397                         failedcmd_waitstatus()."\n";
2398                 }
2399
2400                 my $gapplied = git_rev_parse('HEAD');
2401                 my $gappliedtree = cmdoutput @git, qw(rev-parse HEAD:);
2402                 $gappliedtree eq $dappliedtree or
2403                     fail <<END;
2404 gbp-pq import and dpkg-source disagree!
2405  gbp-pq import gave commit $gapplied
2406  gbp-pq import gave tree $gappliedtree
2407  dpkg-source --before-build gave tree $dappliedtree
2408 END
2409                 $rawimport_hash = $gapplied;
2410             };
2411             last unless $@;
2412         }
2413         if ($@) {
2414             { local $@; eval { runcmd qw(cat ../../gbp-pq-output); }; }
2415             die $@;
2416         }
2417     }
2418
2419     progress "synthesised git commit from .dsc $cversion";
2420
2421     my $rawimport_mergeinput = {
2422         Commit => $rawimport_hash,
2423         Info => "Import of source package",
2424     };
2425     my @output = ($rawimport_mergeinput);
2426
2427     if ($lastpush_mergeinput) {
2428         my $oldclogp = mergeinfo_getclogp($lastpush_mergeinput);
2429         my $oversion = getfield $oldclogp, 'Version';
2430         my $vcmp =
2431             version_compare($oversion, $cversion);
2432         if ($vcmp < 0) {
2433             @output = ($rawimport_mergeinput, $lastpush_mergeinput,
2434                 { Message => <<END, ReverseParents => 1 });
2435 Record $package ($cversion) in archive suite $csuite
2436 END
2437         } elsif ($vcmp > 0) {
2438             print STDERR <<END or die $!;
2439
2440 Version actually in archive:   $cversion (older)
2441 Last version pushed with dgit: $oversion (newer or same)
2442 $later_warning_msg
2443 END
2444             @output = $lastpush_mergeinput;
2445         } else {
2446             # Same version.  Use what's in the server git branch,
2447             # discarding our own import.  (This could happen if the
2448             # server automatically imports all packages into git.)
2449             @output = $lastpush_mergeinput;
2450         }
2451     }
2452     changedir '../../../..';
2453     rmtree($ud);
2454     return @output;
2455 }
2456
2457 sub complete_file_from_dsc ($$) {
2458     our ($dstdir, $fi) = @_;
2459     # Ensures that we have, in $dir, the file $fi, with the correct
2460     # contents.  (Downloading it from alongside $dscurl if necessary.)
2461
2462     my $f = $fi->{Filename};
2463     my $tf = "$dstdir/$f";
2464     my $downloaded = 0;
2465
2466     if (stat_exists $tf) {
2467         progress "using existing $f";
2468     } else {
2469         printdebug "$tf does not exist, need to fetch\n";
2470         my $furl = $dscurl;
2471         $furl =~ s{/[^/]+$}{};
2472         $furl .= "/$f";
2473         die "$f ?" unless $f =~ m/^\Q${package}\E_/;
2474         die "$f ?" if $f =~ m#/#;
2475         runcmd_ordryrun_local @curl,qw(-f -o),$tf,'--',"$furl";
2476         return 0 if !act_local();
2477         $downloaded = 1;
2478     }
2479
2480     open F, "<", "$tf" or die "$tf: $!";
2481     $fi->{Digester}->reset();
2482     $fi->{Digester}->addfile(*F);
2483     F->error and die $!;
2484     my $got = $fi->{Digester}->hexdigest();
2485     $got eq $fi->{Hash} or
2486         fail "file $f has hash $got but .dsc".
2487             " demands hash $fi->{Hash} ".
2488             ($downloaded ? "(got wrong file from archive!)"
2489              : "(perhaps you should delete this file?)");
2490
2491     return 1;
2492 }
2493
2494 sub ensure_we_have_orig () {
2495     my @dfi = dsc_files_info();
2496     foreach my $fi (@dfi) {
2497         my $f = $fi->{Filename};
2498         next unless is_orig_file_in_dsc($f, \@dfi);
2499         complete_file_from_dsc('..', $fi)
2500             or next;
2501     }
2502 }
2503
2504 #---------- git fetch ----------
2505
2506 sub lrfetchrefs () { return "refs/dgit-fetch/".access_basedistro(); }
2507 sub lrfetchref () { return lrfetchrefs.'/'.server_branch($csuite); }
2508
2509 # We fetch some parts of lrfetchrefs/*.  Ideally we delete these
2510 # locally fetched refs because they have unhelpful names and clutter
2511 # up gitk etc.  So we track whether we have "used up" head ref (ie,
2512 # whether we have made another local ref which refers to this object).
2513 #
2514 # (If we deleted them unconditionally, then we might end up
2515 # re-fetching the same git objects each time dgit fetch was run.)
2516 #
2517 # So, leach use of lrfetchrefs needs to be accompanied by arrangements
2518 # in git_fetch_us to fetch the refs in question, and possibly a call
2519 # to lrfetchref_used.
2520
2521 our (%lrfetchrefs_f, %lrfetchrefs_d);
2522 # $lrfetchrefs_X{lrfetchrefs."/heads/whatever"} = $objid
2523
2524 sub lrfetchref_used ($) {
2525     my ($fullrefname) = @_;
2526     my $objid = $lrfetchrefs_f{$fullrefname};
2527     $lrfetchrefs_d{$fullrefname} = $objid if defined $objid;
2528 }
2529
2530 sub git_lrfetch_sane {
2531     my ($supplementary, @specs) = @_;
2532     # Make a 'refs/'.lrfetchrefs.'/*' be just like on server,
2533     # at least as regards @specs.  Also leave the results in
2534     # %lrfetchrefs_f, and arrange for lrfetchref_used to be
2535     # able to clean these up.
2536     #
2537     # With $supplementary==1, @specs must not contain wildcards
2538     # and we add to our previous fetches (non-atomically).
2539
2540     # This is rather miserable:
2541     # When git fetch --prune is passed a fetchspec ending with a *,
2542     # it does a plausible thing.  If there is no * then:
2543     # - it matches subpaths too, even if the supplied refspec
2544     #   starts refs, and behaves completely madly if the source
2545     #   has refs/refs/something.  (See, for example, Debian #NNNN.)
2546     # - if there is no matching remote ref, it bombs out the whole
2547     #   fetch.
2548     # We want to fetch a fixed ref, and we don't know in advance
2549     # if it exists, so this is not suitable.
2550     #
2551     # Our workaround is to use git ls-remote.  git ls-remote has its
2552     # own qairks.  Notably, it has the absurd multi-tail-matching
2553     # behaviour: git ls-remote R refs/foo can report refs/foo AND
2554     # refs/refs/foo etc.
2555     #
2556     # Also, we want an idempotent snapshot, but we have to make two
2557     # calls to the remote: one to git ls-remote and to git fetch.  The
2558     # solution is use git ls-remote to obtain a target state, and
2559     # git fetch to try to generate it.  If we don't manage to generate
2560     # the target state, we try again.
2561
2562     my $url = access_giturl();
2563
2564     printdebug "git_lrfetch_sane suppl=$supplementary specs @specs\n";
2565
2566     my $specre = join '|', map {
2567         my $x = $_;
2568         $x =~ s/\W/\\$&/g;
2569         my $wildcard = $x =~ s/\\\*$/.*/;
2570         die if $wildcard && $supplementary;
2571         "(?:refs/$x)";
2572     } @specs;
2573     printdebug "git_lrfetch_sane specre=$specre\n";
2574     my $wanted_rref = sub {
2575         local ($_) = @_;
2576         return m/^(?:$specre)$/;
2577     };
2578
2579     my $fetch_iteration = 0;
2580     FETCH_ITERATION:
2581     for (;;) {
2582         printdebug "git_lrfetch_sane iteration $fetch_iteration\n";
2583         if (++$fetch_iteration > 10) {
2584             fail "too many iterations trying to get sane fetch!";
2585         }
2586
2587         my @look = map { "refs/$_" } @specs;
2588         my @lcmd = (@git, qw(ls-remote -q --refs), $url, @look);
2589         debugcmd "|",@lcmd;
2590
2591         my %wantr;
2592         open GITLS, "-|", @lcmd or die $!;
2593         while (<GITLS>) {
2594             printdebug "=> ", $_;
2595             m/^(\w+)\s+(\S+)\n/ or die "ls-remote $_ ?";
2596             my ($objid,$rrefname) = ($1,$2);
2597             if (!$wanted_rref->($rrefname)) {
2598                 print STDERR <<END;
2599 warning: git ls-remote @look reported $rrefname; this is silly, ignoring it.
2600 END
2601                 next;
2602             }
2603             $wantr{$rrefname} = $objid;
2604         }
2605         $!=0; $?=0;
2606         close GITLS or failedcmd @lcmd;
2607
2608         # OK, now %want is exactly what we want for refs in @specs
2609         my @fspecs = map {
2610             !m/\*$/ && !exists $wantr{"refs/$_"} ? () :
2611             "+refs/$_:".lrfetchrefs."/$_";
2612         } @specs;
2613
2614         printdebug "git_lrfetch_sane fspecs @fspecs\n";
2615
2616         my @fcmd = (@git, qw(fetch -p -n -q), $url, @fspecs);
2617         runcmd_ordryrun_local @fcmd if @fspecs;
2618
2619         if (!$supplementary) {
2620             %lrfetchrefs_f = ();
2621         }
2622         my %objgot;
2623
2624         git_for_each_ref(lrfetchrefs, sub {
2625             my ($objid,$objtype,$lrefname,$reftail) = @_;
2626             $lrfetchrefs_f{$lrefname} = $objid;
2627             $objgot{$objid} = 1;
2628         });
2629
2630         if ($supplementary) {
2631             last;
2632         }
2633
2634         foreach my $lrefname (sort keys %lrfetchrefs_f) {
2635             my $rrefname = 'refs'.substr($lrefname, length lrfetchrefs);
2636             if (!exists $wantr{$rrefname}) {
2637                 if ($wanted_rref->($rrefname)) {
2638                     printdebug <<END;
2639 git-fetch @fspecs created $lrefname which git ls-remote @look didn't list.
2640 END
2641                 } else {
2642                     print STDERR <<END
2643 warning: git fetch @fspecs created $lrefname; this is silly, deleting it.
2644 END
2645                 }
2646                 runcmd_ordryrun_local @git, qw(update-ref -d), $lrefname;
2647                 delete $lrfetchrefs_f{$lrefname};
2648                 next;
2649             }
2650         }
2651         foreach my $rrefname (sort keys %wantr) {
2652             my $lrefname = lrfetchrefs.substr($rrefname, 4);
2653             my $got = $lrfetchrefs_f{$lrefname} // '<none>';
2654             my $want = $wantr{$rrefname};
2655             next if $got eq $want;
2656             if (!defined $objgot{$want}) {
2657                 print STDERR <<END;
2658 warning: git ls-remote suggests we want $lrefname
2659 warning:  and it should refer to $want
2660 warning:  but git fetch didn't fetch that object to any relevant ref.
2661 warning:  This may be due to a race with someone updating the server.
2662 warning:  Will try again...
2663 END
2664                 next FETCH_ITERATION;
2665             }
2666             printdebug <<END;
2667 git-fetch @fspecs made $lrefname=$got but want git ls-remote @look says $want
2668 END
2669             runcmd_ordryrun_local @git, qw(update-ref -m),
2670                 "dgit fetch git fetch fixup", $lrefname, $want;
2671             $lrfetchrefs_f{$lrefname} = $want;
2672         }
2673         last;
2674     }
2675     printdebug "git_lrfetch_sane: git fetch --no-insane emulation complete\n",
2676         Dumper(\%lrfetchrefs_f);
2677 }
2678
2679 sub git_fetch_us () {
2680     # Want to fetch only what we are going to use, unless
2681     # deliberately-not-ff, in which case we must fetch everything.
2682
2683     my @specs = deliberately_not_fast_forward ? qw(tags/*) :
2684         map { "tags/$_" }
2685         (quiltmode_splitbrain
2686          ? (map { $_->('*',access_nomdistro) }
2687             \&debiantag_new, \&debiantag_maintview)
2688          : debiantags('*',access_nomdistro));
2689     push @specs, server_branch($csuite);
2690     push @specs, $rewritemap;
2691     push @specs, qw(heads/*) if deliberately_not_fast_forward;
2692
2693     git_lrfetch_sane 0, @specs;
2694
2695     my %here;
2696     my @tagpats = debiantags('*',access_nomdistro);
2697
2698     git_for_each_ref([map { "refs/tags/$_" } @tagpats], sub {
2699         my ($objid,$objtype,$fullrefname,$reftail) = @_;
2700         printdebug "currently $fullrefname=$objid\n";
2701         $here{$fullrefname} = $objid;
2702     });
2703     git_for_each_ref([map { lrfetchrefs."/tags/".$_ } @tagpats], sub {
2704         my ($objid,$objtype,$fullrefname,$reftail) = @_;
2705         my $lref = "refs".substr($fullrefname, length(lrfetchrefs));
2706         printdebug "offered $lref=$objid\n";
2707         if (!defined $here{$lref}) {
2708             my @upd = (@git, qw(update-ref), $lref, $objid, '');
2709             runcmd_ordryrun_local @upd;
2710             lrfetchref_used $fullrefname;
2711         } elsif ($here{$lref} eq $objid) {
2712             lrfetchref_used $fullrefname;
2713         } else {
2714             print STDERR \
2715                 "Not updateting $lref from $here{$lref} to $objid.\n";
2716         }
2717     });
2718 }
2719
2720 #---------- dsc and archive handling ----------
2721
2722 sub mergeinfo_getclogp ($) {
2723     # Ensures thit $mi->{Clogp} exists and returns it
2724     my ($mi) = @_;
2725     $mi->{Clogp} = commit_getclogp($mi->{Commit});
2726 }
2727
2728 sub mergeinfo_version ($) {
2729     return getfield( (mergeinfo_getclogp $_[0]), 'Version' );
2730 }
2731
2732 sub fetch_from_archive_record_1 ($) {
2733     my ($hash) = @_;
2734     runcmd @git, qw(update-ref -m), "dgit fetch $csuite",
2735             'DGIT_ARCHIVE', $hash;
2736     cmdoutput @git, qw(log -n2), $hash;
2737     # ... gives git a chance to complain if our commit is malformed
2738 }
2739
2740 sub fetch_from_archive_record_2 ($) {
2741     my ($hash) = @_;
2742     my @upd_cmd = (@git, qw(update-ref -m), 'dgit fetch', lrref(), $hash);
2743     if (act_local()) {
2744         cmdoutput @upd_cmd;
2745     } else {
2746         dryrun_report @upd_cmd;
2747     }
2748 }
2749
2750 sub parse_dsc_field ($$) {
2751     my ($dsc, $what) = @_;
2752     my $f;
2753     foreach my $field (@ourdscfield) {
2754         $f = $dsc->{$field};
2755         last if defined $f;
2756     }
2757     if (!defined $f) {
2758         progress "$what: NO git hash";
2759     } elsif (($dsc_hash, $dsc_distro, $dsc_hint_tag, $dsc_hint_url)
2760              = $f =~ m/^(\w+) ($distro_re) ($versiontag_re) (\S+)(?:\s|$)/) {
2761         progress "$what: specified git info ($dsc_distro)";
2762         $dsc_hint_tag = [ $dsc_hint_tag ];
2763     } elsif ($f =~ m/^\w+\s*$/) {
2764         $dsc_hash = $&;
2765         $dsc_distro //= 'debian';
2766         $dsc_hint_tag = [ debiantags +(getfield $dsc, 'Version'),
2767                           $dsc_distro ];
2768         progress "$what: specified git hash";
2769     } else {
2770         fail "$what: invalid Dgit info";
2771     }
2772 }
2773
2774 sub resolve_dsc_field_commit ($$) {
2775     my ($already_distro, $already_mapref) = @_;
2776
2777     return unless defined $dsc_hash;
2778
2779     my $mapref =
2780         defined $already_mapref &&
2781         ($already_distro eq $dsc_distro || !$chase_dsc_distro)
2782         ? $already_mapref : undef;
2783
2784     my $do_fetch;
2785     $do_fetch = sub {
2786         my ($what, @fetch) = @_;
2787
2788         local $idistro = $dsc_distro;
2789         my $lrf = lrfetchrefs;
2790
2791         if (!$chase_dsc_distro) {
2792             progress
2793                 "not chasing .dsc distro $dsc_distro: not fetching $what";
2794             return 0;
2795         }
2796
2797         progress
2798             ".dsc names distro $dsc_distro: fetching $what";
2799
2800         my $url = access_giturl();
2801         if (!defined $url) {
2802             defined $dsc_hint_url or fail <<END;
2803 .dsc Dgit metadata is in context of distro $dsc_distro
2804 for which we have no configured url and .dsc provides no hint
2805 END
2806             my $proto =
2807                 $dsc_hint_url =~ m#^([-+0-9a-zA-Z]+):# ? $1 :
2808                 $dsc_hint_url =~ m#^/# ? 'file' : 'bad-syntax';
2809             parse_cfg_bool "dsc-url-proto-ok", 'false',
2810                 cfg("dgit.dsc-url-proto-ok.$proto",
2811                     "dgit.default.dsc-url-proto-ok")
2812                 or fail <<END;
2813 .dsc Dgit metadata is in context of distro $dsc_distro
2814 for which we have no configured url;
2815 .dsc provices hinted url with protocol $proto which is unsafe.
2816 (can be overridden by config - consult documentation)
2817 END
2818             $url = $dsc_hint_url;
2819         }
2820
2821         git_lrfetch_sane 1, @fetch;
2822
2823         return $lrf;
2824     };
2825
2826     if (parse_cfg_bool 'rewrite-map-enable', 'true',
2827             access_cfg('rewrite-map-enable', 'RETURN-UNDEF')) {
2828         my $lrf = $do_fetch->("rewrite map", $rewritemap) or return;
2829         $mapref = $lrf.'/'.$rewritemap;
2830         my $rewritemapdata = git_cat_file $mapref.':map';
2831         if (defined $rewritemapdata
2832             && $rewritemapdata =~ m/^$dsc_hash(?:[ \t](\w+))/m) {
2833             progress
2834                 "server's git history rewrite map contains a relevant entry!";
2835
2836             $dsc_hash = $1;
2837             if (defined $dsc_hash) {
2838                 progress "using rewritten git hash in place of .dsc value";
2839             } else {
2840                 progress "server data says .dsc hash is to be disregarded";
2841             }
2842         }
2843     }
2844
2845     if (!defined git_cat_file $dsc_hash) {
2846         my @tags = map { "tags/".$_ } @$dsc_hint_tag;
2847         my $lrf = $do_fetch->("additional commits", @tags) &&
2848             defined git_cat_file $dsc_hash
2849             or fail <<END;
2850 .dsc Dgit metadata requires commit $dsc_hash
2851 but we could not obtain that object anywhere.
2852 END
2853         foreach my $t (@tags) {
2854             my $fullrefname = $lrf.'/'.$t;
2855             print STDERR "CHK $t $fullrefname ".Dumper(\%lrfetchrefs_f);
2856             next unless $lrfetchrefs_f{$fullrefname};
2857             next unless is_fast_fwd "$fullrefname~0", $dsc_hash;
2858             lrfetchref_used $fullrefname;
2859         }
2860     }
2861 }
2862
2863 sub fetch_from_archive () {
2864     ensure_setup_existing_tree();
2865
2866     # Ensures that lrref() is what is actually in the archive, one way
2867     # or another, according to us - ie this client's
2868     # appropritaely-updated archive view.  Also returns the commit id.
2869     # If there is nothing in the archive, leaves lrref alone and
2870     # returns undef.  git_fetch_us must have already been called.
2871     get_archive_dsc();
2872
2873     if ($dsc) {
2874         parse_dsc_field($dsc, 'last upload to archive');
2875         resolve_dsc_field_commit access_basedistro,
2876             lrfetchrefs."/".$rewritemap
2877     } else {
2878         progress "no version available from the archive";
2879     }
2880
2881     # If the archive's .dsc has a Dgit field, there are three
2882     # relevant git commitids we need to choose between and/or merge
2883     # together:
2884     #   1. $dsc_hash: the Dgit field from the archive
2885     #   2. $lastpush_hash: the suite branch on the dgit git server
2886     #   3. $lastfetch_hash: our local tracking brach for the suite
2887     #
2888     # These may all be distinct and need not be in any fast forward
2889     # relationship:
2890     #
2891     # If the dsc was pushed to this suite, then the server suite
2892     # branch will have been updated; but it might have been pushed to
2893     # a different suite and copied by the archive.  Conversely a more
2894     # recent version may have been pushed with dgit but not appeared
2895     # in the archive (yet).
2896     #
2897     # $lastfetch_hash may be awkward because archive imports
2898     # (particularly, imports of Dgit-less .dscs) are performed only as
2899     # needed on individual clients, so different clients may perform a
2900     # different subset of them - and these imports are only made
2901     # public during push.  So $lastfetch_hash may represent a set of
2902     # imports different to a subsequent upload by a different dgit
2903     # client.
2904     #
2905     # Our approach is as follows:
2906     #
2907     # As between $dsc_hash and $lastpush_hash: if $lastpush_hash is a
2908     # descendant of $dsc_hash, then it was pushed by a dgit user who
2909     # had based their work on $dsc_hash, so we should prefer it.
2910     # Otherwise, $dsc_hash was installed into this suite in the
2911     # archive other than by a dgit push, and (necessarily) after the
2912     # last dgit push into that suite (since a dgit push would have
2913     # been descended from the dgit server git branch); thus, in that
2914     # case, we prefer the archive's version (and produce a
2915     # pseudo-merge to overwrite the dgit server git branch).
2916     #
2917     # (If there is no Dgit field in the archive's .dsc then
2918     # generate_commit_from_dsc uses the version numbers to decide
2919     # whether the suite branch or the archive is newer.  If the suite
2920     # branch is newer it ignores the archive's .dsc; otherwise it
2921     # generates an import of the .dsc, and produces a pseudo-merge to
2922     # overwrite the suite branch with the archive contents.)
2923     #
2924     # The outcome of that part of the algorithm is the `public view',
2925     # and is same for all dgit clients: it does not depend on any
2926     # unpublished history in the local tracking branch.
2927     #
2928     # As between the public view and the local tracking branch: The
2929     # local tracking branch is only updated by dgit fetch, and
2930     # whenever dgit fetch runs it includes the public view in the
2931     # local tracking branch.  Therefore if the public view is not
2932     # descended from the local tracking branch, the local tracking
2933     # branch must contain history which was imported from the archive
2934     # but never pushed; and, its tip is now out of date.  So, we make
2935     # a pseudo-merge to overwrite the old imports and stitch the old
2936     # history in.
2937     #
2938     # Finally: we do not necessarily reify the public view (as
2939     # described above).  This is so that we do not end up stacking two
2940     # pseudo-merges.  So what we actually do is figure out the inputs
2941     # to any public view pseudo-merge and put them in @mergeinputs.
2942
2943     my @mergeinputs;
2944     # $mergeinputs[]{Commit}
2945     # $mergeinputs[]{Info}
2946     # $mergeinputs[0] is the one whose tree we use
2947     # @mergeinputs is in the order we use in the actual commit)
2948     #
2949     # Also:
2950     # $mergeinputs[]{Message} is a commit message to use
2951     # $mergeinputs[]{ReverseParents} if def specifies that parent
2952     #                                list should be in opposite order
2953     # Such an entry has no Commit or Info.  It applies only when found
2954     # in the last entry.  (This ugliness is to support making
2955     # identical imports to previous dgit versions.)
2956
2957     my $lastpush_hash = git_get_ref(lrfetchref());
2958     printdebug "previous reference hash=$lastpush_hash\n";
2959     $lastpush_mergeinput = $lastpush_hash && {
2960         Commit => $lastpush_hash,
2961         Info => "dgit suite branch on dgit git server",
2962     };
2963
2964     my $lastfetch_hash = git_get_ref(lrref());
2965     printdebug "fetch_from_archive: lastfetch=$lastfetch_hash\n";
2966     my $lastfetch_mergeinput = $lastfetch_hash && {
2967         Commit => $lastfetch_hash,
2968         Info => "dgit client's archive history view",
2969     };
2970
2971     my $dsc_mergeinput = $dsc_hash && {
2972         Commit => $dsc_hash,
2973         Info => "Dgit field in .dsc from archive",
2974     };
2975
2976     my $cwd = getcwd();
2977     my $del_lrfetchrefs = sub {
2978         changedir $cwd;
2979         my $gur;
2980         printdebug "del_lrfetchrefs...\n";
2981         foreach my $fullrefname (sort keys %lrfetchrefs_d) {
2982             my $objid = $lrfetchrefs_d{$fullrefname};
2983             printdebug "del_lrfetchrefs: $objid $fullrefname\n";
2984             if (!$gur) {
2985                 $gur ||= new IO::Handle;
2986                 open $gur, "|-", qw(git update-ref --stdin) or die $!;
2987             }
2988             printf $gur "delete %s %s\n", $fullrefname, $objid;
2989         }
2990         if ($gur) {
2991             close $gur or failedcmd "git update-ref delete lrfetchrefs";
2992         }
2993     };
2994
2995     if (defined $dsc_hash) {
2996         ensure_we_have_orig();
2997         if (!$lastpush_hash || $dsc_hash eq $lastpush_hash) {
2998             @mergeinputs = $dsc_mergeinput
2999         } elsif (is_fast_fwd($dsc_hash,$lastpush_hash)) {
3000             print STDERR <<END or die $!;
3001
3002 Git commit in archive is behind the last version allegedly pushed/uploaded.
3003 Commit referred to by archive: $dsc_hash
3004 Last version pushed with dgit: $lastpush_hash
3005 $later_warning_msg
3006 END
3007             @mergeinputs = ($lastpush_mergeinput);
3008         } else {
3009             # Archive has .dsc which is not a descendant of the last dgit
3010             # push.  This can happen if the archive moves .dscs about.
3011             # Just follow its lead.
3012             if (is_fast_fwd($lastpush_hash,$dsc_hash)) {
3013                 progress "archive .dsc names newer git commit";
3014                 @mergeinputs = ($dsc_mergeinput);
3015             } else {
3016                 progress "archive .dsc names other git commit, fixing up";
3017                 @mergeinputs = ($dsc_mergeinput, $lastpush_mergeinput);
3018             }
3019         }
3020     } elsif ($dsc) {
3021         @mergeinputs = generate_commits_from_dsc();
3022         # We have just done an import.  Now, our import algorithm might
3023         # have been improved.  But even so we do not want to generate
3024         # a new different import of the same package.  So if the
3025         # version numbers are the same, just use our existing version.
3026         # If the version numbers are different, the archive has changed
3027         # (perhaps, rewound).
3028         if ($lastfetch_mergeinput &&
3029             !version_compare( (mergeinfo_version $lastfetch_mergeinput),
3030                               (mergeinfo_version $mergeinputs[0]) )) {
3031             @mergeinputs = ($lastfetch_mergeinput);
3032         }
3033     } elsif ($lastpush_hash) {
3034         # only in git, not in the archive yet
3035         @mergeinputs = ($lastpush_mergeinput);
3036         print STDERR <<END or die $!;
3037
3038 Package not found in the archive, but has allegedly been pushed using dgit.
3039 $later_warning_msg
3040 END
3041     } else {
3042         printdebug "nothing found!\n";
3043         if (defined $skew_warning_vsn) {
3044             print STDERR <<END or die $!;
3045
3046 Warning: relevant archive skew detected.
3047 Archive allegedly contains $skew_warning_vsn
3048 But we were not able to obtain any version from the archive or git.
3049
3050 END
3051         }
3052         unshift @end, $del_lrfetchrefs;
3053         return undef;
3054     }
3055
3056     if ($lastfetch_hash &&
3057         !grep {
3058             my $h = $_->{Commit};
3059             $h and is_fast_fwd($lastfetch_hash, $h);
3060             # If true, one of the existing parents of this commit
3061             # is a descendant of the $lastfetch_hash, so we'll
3062             # be ff from that automatically.
3063         } @mergeinputs
3064         ) {
3065         # Otherwise:
3066         push @mergeinputs, $lastfetch_mergeinput;
3067     }
3068
3069     printdebug "fetch mergeinfos:\n";
3070     foreach my $mi (@mergeinputs) {
3071         if ($mi->{Info}) {
3072             printdebug " commit $mi->{Commit} $mi->{Info}\n";
3073         } else {
3074             printdebug sprintf " ReverseParents=%d Message=%s",
3075                 $mi->{ReverseParents}, $mi->{Message};
3076         }
3077     }
3078
3079     my $compat_info= pop @mergeinputs
3080         if $mergeinputs[$#mergeinputs]{Message};
3081
3082     @mergeinputs = grep { defined $_->{Commit} } @mergeinputs;
3083
3084     my $hash;
3085     if (@mergeinputs > 1) {
3086         # here we go, then:
3087         my $tree_commit = $mergeinputs[0]{Commit};
3088
3089         my $tree = cmdoutput @git, qw(cat-file commit), $tree_commit;
3090         $tree =~ m/\n\n/;  $tree = $`;
3091         $tree =~ m/^tree (\w+)$/m or die "$dsc_hash tree ?";
3092         $tree = $1;
3093
3094         # We use the changelog author of the package in question the
3095         # author of this pseudo-merge.  This is (roughly) correct if
3096         # this commit is simply representing aa non-dgit upload.
3097         # (Roughly because it does not record sponsorship - but we
3098         # don't have sponsorship info because that's in the .changes,
3099         # which isn't in the archivw.)
3100         #
3101         # But, it might be that we are representing archive history
3102         # updates (including in-archive copies).  These are not really
3103         # the responsibility of the person who created the .dsc, but
3104         # there is no-one whose name we should better use.  (The
3105         # author of the .dsc-named commit is clearly worse.)
3106
3107         my $useclogp = mergeinfo_getclogp $mergeinputs[0];
3108         my $author = clogp_authline $useclogp;
3109         my $cversion = getfield $useclogp, 'Version';
3110
3111         my $mcf = ".git/dgit/mergecommit";
3112         open MC, ">", $mcf or die "$mcf $!";
3113         print MC <<END or die $!;
3114 tree $tree
3115 END
3116
3117         my @parents = grep { $_->{Commit} } @mergeinputs;
3118         @parents = reverse @parents if $compat_info->{ReverseParents};
3119         print MC <<END or die $! foreach @parents;
3120 parent $_->{Commit}
3121 END
3122
3123         print MC <<END or die $!;
3124 author $author
3125 committer $author
3126
3127 END
3128
3129         if (defined $compat_info->{Message}) {
3130             print MC $compat_info->{Message} or die $!;
3131         } else {
3132             print MC <<END or die $!;
3133 Record $package ($cversion) in archive suite $csuite
3134
3135 Record that
3136 END
3137             my $message_add_info = sub {
3138                 my ($mi) = (@_);
3139                 my $mversion = mergeinfo_version $mi;
3140                 printf MC "  %-20s %s\n", $mversion, $mi->{Info}
3141                     or die $!;
3142             };
3143
3144             $message_add_info->($mergeinputs[0]);
3145             print MC <<END or die $!;
3146 should be treated as descended from
3147 END
3148             $message_add_info->($_) foreach @mergeinputs[1..$#mergeinputs];
3149         }
3150
3151         close MC or die $!;
3152         $hash = make_commit $mcf;
3153     } else {
3154         $hash = $mergeinputs[0]{Commit};
3155     }
3156     printdebug "fetch hash=$hash\n";
3157
3158     my $chkff = sub {
3159         my ($lasth, $what) = @_;
3160         return unless $lasth;
3161         die "$lasth $hash $what ?" unless is_fast_fwd($lasth, $hash);
3162     };
3163
3164     $chkff->($lastpush_hash, 'dgit repo server tip (last push)')
3165         if $lastpush_hash;
3166     $chkff->($lastfetch_hash, 'local tracking tip (last fetch)');
3167
3168     fetch_from_archive_record_1($hash);
3169
3170     if (defined $skew_warning_vsn) {
3171         mkpath '.git/dgit';
3172         printdebug "SKEW CHECK WANT $skew_warning_vsn\n";
3173         my $gotclogp = commit_getclogp($hash);
3174         my $got_vsn = getfield $gotclogp, 'Version';
3175         printdebug "SKEW CHECK GOT $got_vsn\n";
3176         if (version_compare($got_vsn, $skew_warning_vsn) < 0) {
3177             print STDERR <<END or die $!;
3178
3179 Warning: archive skew detected.  Using the available version:
3180 Archive allegedly contains    $skew_warning_vsn
3181 We were able to obtain only   $got_vsn
3182
3183 END
3184         }
3185     }
3186
3187     if ($lastfetch_hash ne $hash) {
3188         fetch_from_archive_record_2($hash);
3189     }
3190
3191     lrfetchref_used lrfetchref();
3192
3193     unshift @end, $del_lrfetchrefs;
3194     return $hash;
3195 }
3196
3197 sub set_local_git_config ($$) {
3198     my ($k, $v) = @_;
3199     runcmd @git, qw(config), $k, $v;
3200 }
3201
3202 sub setup_mergechangelogs (;$) {
3203     my ($always) = @_;
3204     return unless $always || access_cfg_bool(1, 'setup-mergechangelogs');
3205
3206     my $driver = 'dpkg-mergechangelogs';
3207     my $cb = "merge.$driver";
3208     my $attrs = '.git/info/attributes';
3209     ensuredir '.git/info';
3210
3211     open NATTRS, ">", "$attrs.new" or die "$attrs.new $!";
3212     if (!open ATTRS, "<", $attrs) {
3213         $!==ENOENT or die "$attrs: $!";
3214     } else {
3215         while (<ATTRS>) {
3216             chomp;
3217             next if m{^debian/changelog\s};
3218             print NATTRS $_, "\n" or die $!;
3219         }
3220         ATTRS->error and die $!;
3221         close ATTRS;
3222     }
3223     print NATTRS "debian/changelog merge=$driver\n" or die $!;
3224     close NATTRS;
3225
3226     set_local_git_config "$cb.name", 'debian/changelog merge driver';
3227     set_local_git_config "$cb.driver", 'dpkg-mergechangelogs -m %O %A %B %A';
3228
3229     rename "$attrs.new", "$attrs" or die "$attrs: $!";
3230 }
3231
3232 sub setup_useremail (;$) {
3233     my ($always) = @_;
3234     return unless $always || access_cfg_bool(1, 'setup-useremail');
3235
3236     my $setup = sub {
3237         my ($k, $envvar) = @_;
3238         my $v = access_cfg("user-$k", 'RETURN-UNDEF') // $ENV{$envvar};
3239         return unless defined $v;
3240         set_local_git_config "user.$k", $v;
3241     };
3242
3243     $setup->('email', 'DEBEMAIL');
3244     $setup->('name', 'DEBFULLNAME');
3245 }
3246
3247 sub ensure_setup_existing_tree () {
3248     my $k = "remote.$remotename.skipdefaultupdate";
3249     my $c = git_get_config $k;
3250     return if defined $c;
3251     set_local_git_config $k, 'true';
3252 }
3253
3254 sub setup_new_tree () {
3255     setup_mergechangelogs();
3256     setup_useremail();
3257 }
3258
3259 sub multisuite_suite_child ($$$) {
3260     my ($tsuite, $merginputs, $fn) = @_;
3261     # in child, sets things up, calls $fn->(), and returns undef
3262     # in parent, returns canonical suite name for $tsuite
3263     my $canonsuitefh = IO::File::new_tmpfile;
3264     my $pid = fork // die $!;
3265     if (!$pid) {
3266         $isuite = $tsuite;
3267         $us .= " [$isuite]";
3268         $debugprefix .= " ";
3269         progress "fetching $tsuite...";
3270         canonicalise_suite();
3271         print $canonsuitefh $csuite, "\n" or die $!;
3272         close $canonsuitefh or die $!;
3273         $fn->();
3274         return undef;
3275     }
3276     waitpid $pid,0 == $pid or die $!;
3277     fail "failed to obtain $tsuite: ".waitstatusmsg() if $? && $?!=256*4;
3278     seek $canonsuitefh,0,0 or die $!;
3279     local $csuite = <$canonsuitefh>;
3280     die $! unless defined $csuite && chomp $csuite;
3281     if ($? == 256*4) {
3282         printdebug "multisuite $tsuite missing\n";
3283         return $csuite;
3284     }
3285     printdebug "multisuite $tsuite ok (canon=$csuite)\n";
3286     push @$merginputs, {
3287         Ref => lrref,
3288         Info => $csuite,
3289     };
3290     return $csuite;
3291 }
3292
3293 sub fork_for_multisuite ($) {
3294     my ($before_fetch_merge) = @_;
3295     # if nothing unusual, just returns ''
3296     #
3297     # if multisuite:
3298     # returns 0 to caller in child, to do first of the specified suites
3299     # in child, $csuite is not yet set
3300     #
3301     # returns 1 to caller in parent, to finish up anything needed after
3302     # in parent, $csuite is set to canonicalised portmanteau
3303
3304     my $org_isuite = $isuite;
3305     my @suites = split /\,/, $isuite;
3306     return '' unless @suites > 1;
3307     printdebug "fork_for_multisuite: @suites\n";
3308
3309     my @mergeinputs;
3310
3311     my $cbasesuite = multisuite_suite_child($suites[0], \@mergeinputs,
3312                                             sub { });
3313     return 0 unless defined $cbasesuite;
3314
3315     fail "package $package missing in (base suite) $cbasesuite"
3316         unless @mergeinputs;
3317
3318     my @csuites = ($cbasesuite);
3319
3320     $before_fetch_merge->();
3321
3322     foreach my $tsuite (@suites[1..$#suites]) {
3323         my $csubsuite = multisuite_suite_child($tsuite, \@mergeinputs,
3324                                                sub {
3325             @end = ();
3326             fetch();
3327             exit 0;
3328         });
3329         # xxx collecte the ref here
3330
3331         $csubsuite =~ s/^\Q$cbasesuite\E-/-/;
3332         push @csuites, $csubsuite;
3333     }
3334
3335     foreach my $mi (@mergeinputs) {
3336         my $ref = git_get_ref $mi->{Ref};
3337         die "$mi->{Ref} ?" unless length $ref;
3338         $mi->{Commit} = $ref;
3339     }
3340
3341     $csuite = join ",", @csuites;
3342
3343     my $previous = git_get_ref lrref;
3344     if ($previous) {
3345         unshift @mergeinputs, {
3346             Commit => $previous,
3347             Info => "local combined tracking branch",
3348             Warning =>
3349  "archive seems to have rewound: local tracking branch is ahead!",
3350         };
3351     }
3352
3353     foreach my $ix (0..$#mergeinputs) {
3354         $mergeinputs[$ix]{Index} = $ix;
3355     }
3356
3357     @mergeinputs = sort {
3358         -version_compare(mergeinfo_version $a,
3359                          mergeinfo_version $b) # highest version first
3360             or
3361         $a->{Index} <=> $b->{Index}; # earliest in spec first
3362     } @mergeinputs;
3363
3364     my @needed;
3365
3366   NEEDED:
3367     foreach my $mi (@mergeinputs) {
3368         printdebug "multisuite merge check $mi->{Info}\n";
3369         foreach my $previous (@needed) {
3370             next unless is_fast_fwd $mi->{Commit}, $previous->{Commit};
3371             printdebug "multisuite merge un-needed $previous->{Info}\n";
3372             next NEEDED;
3373         }
3374         push @needed, $mi;
3375         printdebug "multisuite merge this-needed\n";
3376         $mi->{Character} = '+';
3377     }
3378
3379     $needed[0]{Character} = '*';
3380
3381     my $output = $needed[0]{Commit};
3382
3383     if (@needed > 1) {
3384         printdebug "multisuite merge nontrivial\n";
3385         my $tree = cmdoutput qw(git rev-parse), $needed[0]{Commit}.':';
3386
3387         my $commit = "tree $tree\n";
3388         my $msg = "Combine archive branches $csuite [dgit]\n\n".
3389             "Input branches:\n";
3390
3391         foreach my $mi (sort { $a->{Index} <=> $b->{Index} } @mergeinputs) {
3392             printdebug "multisuite merge include $mi->{Info}\n";
3393             $mi->{Character} //= ' ';
3394             $commit .= "parent $mi->{Commit}\n";
3395             $msg .= sprintf " %s  %-25s %s\n",
3396                 $mi->{Character},
3397                 (mergeinfo_version $mi),
3398                 $mi->{Info};
3399         }
3400         my $authline = clogp_authline mergeinfo_getclogp $needed[0];
3401         $msg .= "\nKey\n".
3402             " * marks the highest version branch, which choose to use\n".
3403             " + marks each branch which was not already an ancestor\n\n".
3404             "[dgit multi-suite $csuite]\n";
3405         $commit .=
3406             "author $authline\n".
3407             "committer $authline\n\n";
3408         $output = make_commit_text $commit.$msg;
3409         printdebug "multisuite merge generated $output\n";
3410     }
3411
3412     fetch_from_archive_record_1($output);
3413     fetch_from_archive_record_2($output);
3414
3415     progress "calculated combined tracking suite $csuite";
3416
3417     return 1;
3418 }
3419
3420 sub clone_set_head () {
3421     open H, "> .git/HEAD" or die $!;
3422     print H "ref: ".lref()."\n" or die $!;
3423     close H or die $!;
3424 }
3425 sub clone_finish ($) {
3426     my ($dstdir) = @_;
3427     runcmd @git, qw(reset --hard), lrref();
3428     runcmd qw(bash -ec), <<'END';
3429         set -o pipefail
3430         git ls-tree -r --name-only -z HEAD | \
3431         xargs -0r touch -h -r . --
3432 END
3433     printdone "ready for work in $dstdir";
3434 }
3435
3436 sub clone ($) {
3437     my ($dstdir) = @_;
3438     badusage "dry run makes no sense with clone" unless act_local();
3439
3440     my $multi_fetched = fork_for_multisuite(sub {
3441         printdebug "multi clone before fetch merge\n";
3442         changedir $dstdir;
3443     });
3444     if ($multi_fetched) {
3445         printdebug "multi clone after fetch merge\n";
3446         clone_set_head();
3447         clone_finish($dstdir);
3448         exit 0;
3449     }
3450     printdebug "clone main body\n";
3451
3452     canonicalise_suite();
3453     my $hasgit = check_for_git();
3454     mkdir $dstdir or fail "create \`$dstdir': $!";
3455     changedir $dstdir;
3456     runcmd @git, qw(init -q);
3457     clone_set_head();
3458     my $giturl = access_giturl(1);
3459     if (defined $giturl) {
3460         runcmd @git, qw(remote add), 'origin', $giturl;
3461     }
3462     if ($hasgit) {
3463         progress "fetching existing git history";
3464         git_fetch_us();
3465         runcmd_ordryrun_local @git, qw(fetch origin);
3466     } else {
3467         progress "starting new git history";
3468     }
3469     fetch_from_archive() or no_such_package;
3470     my $vcsgiturl = $dsc->{'Vcs-Git'};
3471     if (length $vcsgiturl) {
3472         $vcsgiturl =~ s/\s+-b\s+\S+//g;
3473         runcmd @git, qw(remote add vcs-git), $vcsgiturl;
3474     }
3475     setup_new_tree();
3476     clone_finish($dstdir);
3477 }
3478
3479 sub fetch () {
3480     canonicalise_suite();
3481     if (check_for_git()) {
3482         git_fetch_us();
3483     }
3484     fetch_from_archive() or no_such_package();
3485     printdone "fetched into ".lrref();
3486 }
3487
3488 sub pull () {
3489     my $multi_fetched = fork_for_multisuite(sub { });
3490     fetch() unless $multi_fetched; # parent
3491     return if $multi_fetched eq '0'; # child
3492     runcmd_ordryrun_local @git, qw(merge -m),"Merge from $csuite [dgit]",
3493         lrref();
3494     printdone "fetched to ".lrref()." and merged into HEAD";
3495 }
3496
3497 sub check_not_dirty () {
3498     foreach my $f (qw(local-options local-patch-header)) {
3499         if (stat_exists "debian/source/$f") {
3500             fail "git tree contains debian/source/$f";
3501         }
3502     }
3503
3504     return if $ignoredirty;
3505
3506     my @cmd = (@git, qw(diff --quiet HEAD));
3507     debugcmd "+",@cmd;
3508     $!=0; $?=-1; system @cmd;
3509     return if !$?;
3510     if ($?==256) {
3511         fail "working tree is dirty (does not match HEAD)";
3512     } else {
3513         failedcmd @cmd;
3514     }
3515 }
3516
3517 sub commit_admin ($) {
3518     my ($m) = @_;
3519     progress "$m";
3520     runcmd_ordryrun_local @git, qw(commit -m), $m;
3521 }
3522
3523 sub commit_quilty_patch () {
3524     my $output = cmdoutput @git, qw(status --porcelain);
3525     my %adds;
3526     foreach my $l (split /\n/, $output) {
3527         next unless $l =~ m/\S/;
3528         if ($l =~ m{^(?:\?\?| M) (.pc|debian/patches)}) {
3529             $adds{$1}++;
3530         }
3531     }
3532     delete $adds{'.pc'}; # if there wasn't one before, don't add it
3533     if (!%adds) {
3534         progress "nothing quilty to commit, ok.";
3535         return;
3536     }
3537     my @adds = map { s/[][*?\\]/\\$&/g; $_; } sort keys %adds;
3538     runcmd_ordryrun_local @git, qw(add -f), @adds;
3539     commit_admin <<END
3540 Commit Debian 3.0 (quilt) metadata
3541
3542 [dgit ($our_version) quilt-fixup]
3543 END
3544 }
3545
3546 sub get_source_format () {
3547     my %options;
3548     if (open F, "debian/source/options") {
3549         while (<F>) {
3550             next if m/^\s*\#/;
3551             next unless m/\S/;
3552             s/\s+$//; # ignore missing final newline
3553             if (m/\s*\#\s*/) {
3554                 my ($k, $v) = ($`, $'); #');
3555                 $v =~ s/^"(.*)"$/$1/;
3556                 $options{$k} = $v;
3557             } else {
3558                 $options{$_} = 1;
3559             }
3560         }
3561         F->error and die $!;
3562         close F;
3563     } else {
3564         die $! unless $!==&ENOENT;
3565     }
3566
3567     if (!open F, "debian/source/format") {
3568         die $! unless $!==&ENOENT;
3569         return '';
3570     }
3571     $_ = <F>;
3572     F->error and die $!;
3573     chomp;
3574     return ($_, \%options);
3575 }
3576
3577 sub madformat_wantfixup ($) {
3578     my ($format) = @_;
3579     return 0 unless $format eq '3.0 (quilt)';
3580     our $quilt_mode_warned;
3581     if ($quilt_mode eq 'nocheck') {
3582         progress "Not doing any fixup of \`$format' due to".
3583             " ----no-quilt-fixup or --quilt=nocheck"
3584             unless $quilt_mode_warned++;
3585         return 0;
3586     }
3587     progress "Format \`$format', need to check/update patch stack"
3588         unless $quilt_mode_warned++;
3589     return 1;
3590 }
3591
3592 sub maybe_split_brain_save ($$$) {
3593     my ($headref, $dgitview, $msg) = @_;
3594     # => message fragment "$saved" describing disposition of $dgitview
3595     return "commit id $dgitview" unless defined $split_brain_save;
3596     my @cmd = (shell_cmd "cd ../../../..",
3597                @git, qw(update-ref -m),
3598                "dgit --dgit-view-save $msg HEAD=$headref",
3599                $split_brain_save, $dgitview);
3600     runcmd @cmd;
3601     return "and left in $split_brain_save";
3602 }
3603
3604 # An "infopair" is a tuple [ $thing, $what ]
3605 # (often $thing is a commit hash; $what is a description)
3606
3607 sub infopair_cond_equal ($$) {
3608     my ($x,$y) = @_;
3609     $x->[0] eq $y->[0] or fail <<END;
3610 $x->[1] ($x->[0]) not equal to $y->[1] ($y->[0])
3611 END
3612 };
3613
3614 sub infopair_lrf_tag_lookup ($$) {
3615     my ($tagnames, $what) = @_;
3616     # $tagname may be an array ref
3617     my @tagnames = ref $tagnames ? @$tagnames : ($tagnames);
3618     printdebug "infopair_lrfetchref_tag_lookup $what @tagnames\n";
3619     foreach my $tagname (@tagnames) {
3620         my $lrefname = lrfetchrefs."/tags/$tagname";
3621         my $tagobj = $lrfetchrefs_f{$lrefname};
3622         next unless defined $tagobj;
3623         printdebug "infopair_lrfetchref_tag_lookup $tagobj $tagname $what\n";
3624         return [ git_rev_parse($tagobj), $what ];
3625     }
3626     fail @tagnames==1 ? <<END : <<END;
3627 Wanted tag $what (@tagnames) on dgit server, but not found
3628 END
3629 Wanted tag $what (one of: @tagnames) on dgit server, but not found
3630 END
3631 }
3632
3633 sub infopair_cond_ff ($$) {
3634     my ($anc,$desc) = @_;
3635     is_fast_fwd($anc->[0], $desc->[0]) or fail <<END;
3636 $anc->[1] ($anc->[0]) .. $desc->[1] ($desc->[0]) is not fast forward
3637 END
3638 };
3639
3640 sub pseudomerge_version_check ($$) {
3641     my ($clogp, $archive_hash) = @_;
3642
3643     my $arch_clogp = commit_getclogp $archive_hash;
3644     my $i_arch_v = [ (getfield $arch_clogp, 'Version'),
3645                      'version currently in archive' ];
3646     if (defined $overwrite_version) {
3647         if (length $overwrite_version) {
3648             infopair_cond_equal([ $overwrite_version,
3649                                   '--overwrite= version' ],
3650                                 $i_arch_v);
3651         } else {
3652             my $v = $i_arch_v->[0];
3653             progress "Checking package changelog for archive version $v ...";
3654             eval {
3655                 my @xa = ("-f$v", "-t$v");
3656                 my $vclogp = parsechangelog @xa;
3657                 my $cv = [ (getfield $vclogp, 'Version'),
3658                            "Version field from dpkg-parsechangelog @xa" ];
3659                 infopair_cond_equal($i_arch_v, $cv);
3660             };
3661             if ($@) {
3662                 $@ =~ s/^dgit: //gm;
3663                 fail "$@".
3664                     "Perhaps debian/changelog does not mention $v ?";
3665             }
3666         }
3667     }
3668
3669     printdebug "pseudomerge_version_check i_arch_v @$i_arch_v\n";
3670     return $i_arch_v;
3671 }
3672
3673 sub pseudomerge_make_commit ($$$$ $$) {
3674     my ($clogp, $dgitview, $archive_hash, $i_arch_v,
3675         $msg_cmd, $msg_msg) = @_;
3676     progress "Declaring that HEAD inciudes all changes in $i_arch_v->[0]...";
3677
3678     my $tree = cmdoutput qw(git rev-parse), "${dgitview}:";
3679     my $authline = clogp_authline $clogp;
3680
3681     chomp $msg_msg;
3682     $msg_cmd .=
3683         !defined $overwrite_version ? ""
3684         : !length  $overwrite_version ? " --overwrite"
3685         : " --overwrite=".$overwrite_version;
3686
3687     mkpath '.git/dgit';
3688     my $pmf = ".git/dgit/pseudomerge";
3689     open MC, ">", $pmf or die "$pmf $!";
3690     print MC <<END or die $!;
3691 tree $tree
3692 parent $dgitview
3693 parent $archive_hash
3694 author $authline
3695 committer $authline
3696
3697 $msg_msg
3698
3699 [$msg_cmd]
3700 END
3701     close MC or die $!;
3702
3703     return make_commit($pmf);
3704 }
3705
3706 sub splitbrain_pseudomerge ($$$$) {
3707     my ($clogp, $maintview, $dgitview, $archive_hash) = @_;
3708     # => $merged_dgitview
3709     printdebug "splitbrain_pseudomerge...\n";
3710     #
3711     #     We:      debian/PREVIOUS    HEAD($maintview)
3712     # expect:          o ----------------- o
3713     #                    \                   \
3714     #                     o                   o
3715     #                 a/d/PREVIOUS        $dgitview
3716     #                $archive_hash              \
3717     #  If so,                \                   \
3718     #  we do:                 `------------------ o
3719     #   this:                                   $dgitview'
3720     #
3721
3722     return $dgitview unless defined $archive_hash;
3723
3724     printdebug "splitbrain_pseudomerge...\n";
3725
3726     my $i_arch_v = pseudomerge_version_check($clogp, $archive_hash);
3727
3728     if (!defined $overwrite_version) {
3729         progress "Checking that HEAD inciudes all changes in archive...";
3730     }
3731
3732     return $dgitview if is_fast_fwd $archive_hash, $dgitview;
3733
3734     if (defined $overwrite_version) {
3735     } elsif (!eval {
3736         my $t_dep14 = debiantag_maintview $i_arch_v->[0], access_nomdistro;
3737         my $i_dep14 = infopair_lrf_tag_lookup($t_dep14, "maintainer view tag");
3738         my $t_dgit = debiantag_new $i_arch_v->[0], access_nomdistro;
3739         my $i_dgit = infopair_lrf_tag_lookup($t_dgit, "dgit view tag");
3740         my $i_archive = [ $archive_hash, "current archive contents" ];
3741
3742         printdebug "splitbrain_pseudomerge i_archive @$i_archive\n";
3743
3744         infopair_cond_equal($i_dgit, $i_archive);
3745         infopair_cond_ff($i_dep14, $i_dgit);
3746         infopair_cond_ff($i_dep14, [ $maintview, 'HEAD' ]);
3747         1;
3748     }) {
3749         print STDERR <<END;
3750 $us: check failed (maybe --overwrite is needed, consult documentation)
3751 END
3752         die "$@";
3753     }
3754
3755     my $r = pseudomerge_make_commit
3756         $clogp, $dgitview, $archive_hash, $i_arch_v,
3757         "dgit --quilt=$quilt_mode",
3758         (defined $overwrite_version ? <<END_OVERWR : <<END_MAKEFF);
3759 Declare fast forward from $i_arch_v->[0]
3760 END_OVERWR
3761 Make fast forward from $i_arch_v->[0]
3762 END_MAKEFF
3763
3764     maybe_split_brain_save $maintview, $r, "pseudomerge";
3765
3766     progress "Made pseudo-merge of $i_arch_v->[0] into dgit view.";
3767     return $r;
3768 }
3769
3770 sub plain_overwrite_pseudomerge ($$$) {
3771     my ($clogp, $head, $archive_hash) = @_;
3772
3773     printdebug "plain_overwrite_pseudomerge...";
3774
3775     my $i_arch_v = pseudomerge_version_check($clogp, $archive_hash);
3776
3777     return $head if is_fast_fwd $archive_hash, $head;
3778
3779     my $m = "Declare fast forward from $i_arch_v->[0]";
3780
3781     my $r = pseudomerge_make_commit
3782         $clogp, $head, $archive_hash, $i_arch_v,
3783         "dgit", $m;
3784
3785     runcmd @git, qw(update-ref -m), $m, 'HEAD', $r, $head;
3786
3787     progress "Make pseudo-merge of $i_arch_v->[0] into your HEAD.";
3788     return $r;
3789 }
3790
3791 sub push_parse_changelog ($) {
3792     my ($clogpfn) = @_;
3793
3794     my $clogp = Dpkg::Control::Hash->new();
3795     $clogp->load($clogpfn) or die;
3796
3797     my $clogpackage = getfield $clogp, 'Source';
3798     $package //= $clogpackage;
3799     fail "-p specified $package but changelog specified $clogpackage"
3800         unless $package eq $clogpackage;
3801     my $cversion = getfield $clogp, 'Version';
3802     my $tag = debiantag($cversion, access_nomdistro);
3803     runcmd @git, qw(check-ref-format), $tag;
3804
3805     my $dscfn = dscfn($cversion);
3806
3807     return ($clogp, $cversion, $dscfn);
3808 }
3809
3810 sub push_parse_dsc ($$$) {
3811     my ($dscfn,$dscfnwhat, $cversion) = @_;
3812     $dsc = parsecontrol($dscfn,$dscfnwhat);
3813     my $dversion = getfield $dsc, 'Version';
3814     my $dscpackage = getfield $dsc, 'Source';
3815     ($dscpackage eq $package && $dversion eq $cversion) or
3816         fail "$dscfn is for $dscpackage $dversion".
3817             " but debian/changelog is for $package $cversion";
3818 }
3819
3820 sub push_tagwants ($$$$) {
3821     my ($cversion, $dgithead, $maintviewhead, $tfbase) = @_;
3822     my @tagwants;
3823     push @tagwants, {
3824         TagFn => \&debiantag,
3825         Objid => $dgithead,
3826         TfSuffix => '',
3827         View => 'dgit',
3828     };
3829     if (defined $maintviewhead) {
3830         push @tagwants, {
3831             TagFn => \&debiantag_maintview,
3832             Objid => $maintviewhead,
3833             TfSuffix => '-maintview',
3834             View => 'maint',
3835         };
3836     } elsif ($dodep14tag eq 'no' ? 0
3837              : $dodep14tag eq 'want' ? access_cfg_tagformats_can_splitbrain
3838              : $dodep14tag eq 'always'
3839              ? (access_cfg_tagformats_can_splitbrain or fail <<END)
3840 --dep14tag-always (or equivalent in config) means server must support
3841  both "new" and "maint" tag formats, but config says it doesn't.
3842 END
3843             : die "$dodep14tag ?") {
3844         push @tagwants, {
3845             TagFn => \&debiantag_maintview,
3846             Objid => $dgithead,
3847             TfSuffix => '-dgit',
3848             View => 'dgit',
3849         };
3850     };
3851     foreach my $tw (@tagwants) {
3852         $tw->{Tag} = $tw->{TagFn}($cversion, access_nomdistro);
3853         $tw->{Tfn} = sub { $tfbase.$tw->{TfSuffix}.$_[0]; };
3854     }
3855     printdebug 'push_tagwants: ', Dumper(\@_, \@tagwants);
3856     return @tagwants;
3857 }
3858
3859 sub push_mktags ($$ $$ $) {
3860     my ($clogp,$dscfn,
3861         $changesfile,$changesfilewhat,
3862         $tagwants) = @_;
3863
3864     die unless $tagwants->[0]{View} eq 'dgit';
3865
3866     my $declaredistro = access_nomdistro();
3867     my $reader_giturl = do { local $access_forpush=0; access_giturl(); };
3868     $dsc->{$ourdscfield[0]} = join " ",
3869         $tagwants->[0]{Objid}, $declaredistro, $tagwants->[0]{Tag},
3870         $reader_giturl;
3871     $dsc->save("$dscfn.tmp") or die $!;
3872
3873     my $changes = parsecontrol($changesfile,$changesfilewhat);
3874     foreach my $field (qw(Source Distribution Version)) {
3875         $changes->{$field} eq $clogp->{$field} or
3876             fail "changes field $field \`$changes->{$field}'".
3877                 " does not match changelog \`$clogp->{$field}'";
3878     }
3879
3880     my $cversion = getfield $clogp, 'Version';
3881     my $clogsuite = getfield $clogp, 'Distribution';
3882
3883     # We make the git tag by hand because (a) that makes it easier
3884     # to control the "tagger" (b) we can do remote signing
3885     my $authline = clogp_authline $clogp;
3886     my $delibs = join(" ", "",@deliberatelies);
3887
3888     my $mktag = sub {
3889         my ($tw) = @_;
3890         my $tfn = $tw->{Tfn};
3891         my $head = $tw->{Objid};
3892         my $tag = $tw->{Tag};
3893
3894         open TO, '>', $tfn->('.tmp') or die $!;
3895         print TO <<END or die $!;
3896 object $head
3897 type commit
3898 tag $tag
3899 tagger $authline
3900
3901 END
3902         if ($tw->{View} eq 'dgit') {
3903             print TO <<END or die $!;
3904 $package release $cversion for $clogsuite ($csuite) [dgit]
3905 [dgit distro=$declaredistro$delibs]
3906 END
3907             foreach my $ref (sort keys %previously) {
3908                 print TO <<END or die $!;
3909 [dgit previously:$ref=$previously{$ref}]
3910 END
3911             }
3912         } elsif ($tw->{View} eq 'maint') {
3913             print TO <<END or die $!;
3914 $package release $cversion for $clogsuite ($csuite)
3915 (maintainer view tag generated by dgit --quilt=$quilt_mode)
3916 END
3917         } else {
3918             die Dumper($tw)."?";
3919         }
3920
3921         close TO or die $!;
3922
3923         my $tagobjfn = $tfn->('.tmp');
3924         if ($sign) {
3925             if (!defined $keyid) {
3926                 $keyid = access_cfg('keyid','RETURN-UNDEF');
3927             }
3928             if (!defined $keyid) {
3929                 $keyid = getfield $clogp, 'Maintainer';
3930             }
3931             unlink $tfn->('.tmp.asc') or $!==&ENOENT or die $!;
3932             my @sign_cmd = (@gpg, qw(--detach-sign --armor));
3933             push @sign_cmd, qw(-u),$keyid if defined $keyid;
3934             push @sign_cmd, $tfn->('.tmp');
3935             runcmd_ordryrun @sign_cmd;
3936             if (act_scary()) {
3937                 $tagobjfn = $tfn->('.signed.tmp');
3938                 runcmd shell_cmd "exec >$tagobjfn", qw(cat --),
3939                     $tfn->('.tmp'), $tfn->('.tmp.asc');
3940             }
3941         }
3942         return $tagobjfn;
3943     };
3944
3945     my @r = map { $mktag->($_); } @$tagwants;
3946     return @r;
3947 }
3948
3949 sub sign_changes ($) {
3950     my ($changesfile) = @_;
3951     if ($sign) {
3952         my @debsign_cmd = @debsign;
3953         push @debsign_cmd, "-k$keyid" if defined $keyid;
3954         push @debsign_cmd, "-p$gpg[0]" if $gpg[0] ne 'gpg';
3955         push @debsign_cmd, $changesfile;
3956         runcmd_ordryrun @debsign_cmd;
3957     }
3958 }
3959
3960 sub dopush () {
3961     printdebug "actually entering push\n";
3962
3963     supplementary_message(<<'END');
3964 Push failed, while checking state of the archive.
3965 You can retry the push, after fixing the problem, if you like.
3966 END
3967     if (check_for_git()) {
3968         git_fetch_us();
3969     }
3970     my $archive_hash = fetch_from_archive();
3971     if (!$archive_hash) {
3972         $new_package or
3973             fail "package appears to be new in this suite;".
3974                 " if this is intentional, use --new";
3975     }
3976
3977     supplementary_message(<<'END');
3978 Push failed, while preparing your push.
3979 You can retry the push, after fixing the problem, if you like.
3980 END
3981
3982     need_tagformat 'new', "quilt mode $quilt_mode"
3983         if quiltmode_splitbrain;
3984
3985     prep_ud();
3986
3987     access_giturl(); # check that success is vaguely likely
3988     select_tagformat();
3989
3990     my $clogpfn = ".git/dgit/changelog.822.tmp";
3991     runcmd shell_cmd "exec >$clogpfn", qw(dpkg-parsechangelog);
3992
3993     responder_send_file('parsed-changelog', $clogpfn);
3994
3995     my ($clogp, $cversion, $dscfn) =
3996         push_parse_changelog("$clogpfn");
3997
3998     my $dscpath = "$buildproductsdir/$dscfn";
3999     stat_exists $dscpath or
4000         fail "looked for .dsc $dscpath, but $!;".
4001             " maybe you forgot to build";
4002
4003     responder_send_file('dsc', $dscpath);
4004
4005     push_parse_dsc($dscpath, $dscfn, $cversion);
4006
4007     my $format = getfield $dsc, 'Format';
4008     printdebug "format $format\n";
4009
4010     my $actualhead = git_rev_parse('HEAD');
4011     my $dgithead = $actualhead;
4012     my $maintviewhead = undef;
4013
4014     my $upstreamversion = upstreamversion $clogp->{Version};
4015
4016     if (madformat_wantfixup($format)) {
4017         # user might have not used dgit build, so maybe do this now:
4018         if (quiltmode_splitbrain()) {
4019             changedir $ud;
4020             quilt_make_fake_dsc($upstreamversion);
4021             my $cachekey;
4022             ($dgithead, $cachekey) =
4023                 quilt_check_splitbrain_cache($actualhead, $upstreamversion);
4024             $dgithead or fail
4025  "--quilt=$quilt_mode but no cached dgit view:
4026  perhaps tree changed since dgit build[-source] ?";
4027             $split_brain = 1;
4028             $dgithead = splitbrain_pseudomerge($clogp,
4029                                                $actualhead, $dgithead,
4030                                                $archive_hash);
4031             $maintviewhead = $actualhead;
4032             changedir '../../../..';
4033             prep_ud(); # so _only_subdir() works, below
4034         } else {
4035             commit_quilty_patch();
4036         }
4037     }
4038
4039     if (defined $overwrite_version && !defined $maintviewhead) {
4040         $dgithead = plain_overwrite_pseudomerge($clogp,
4041                                                 $dgithead,
4042                                                 $archive_hash);
4043     }
4044
4045     check_not_dirty();
4046
4047     my $forceflag = '';
4048     if ($archive_hash) {
4049         if (is_fast_fwd($archive_hash, $dgithead)) {
4050             # ok
4051         } elsif (deliberately_not_fast_forward) {
4052             $forceflag = '+';
4053         } else {
4054             fail "dgit push: HEAD is not a descendant".
4055                 " of the archive's version.\n".
4056                 "To overwrite the archive's contents,".
4057                 " pass --overwrite[=VERSION].\n".
4058                 "To rewind history, if permitted by the archive,".
4059                 " use --deliberately-not-fast-forward.";
4060         }
4061     }
4062
4063     changedir $ud;
4064     progress "checking that $dscfn corresponds to HEAD";
4065     runcmd qw(dpkg-source -x --),
4066         $dscpath =~ m#^/# ? $dscpath : "../../../$dscpath";
4067     my ($tree,$dir) = mktree_in_ud_from_only_subdir("source package");
4068     check_for_vendor_patches() if madformat($dsc->{format});
4069     changedir '../../../..';
4070     my @diffcmd = (@git, qw(diff --quiet), $tree, $dgithead);
4071     debugcmd "+",@diffcmd;
4072     $!=0; $?=-1;
4073     my $r = system @diffcmd;
4074     if ($r) {
4075         if ($r==256) {
4076             my $diffs = cmdoutput @git, qw(diff --stat), $tree, $dgithead;
4077             fail <<END
4078 HEAD specifies a different tree to $dscfn:
4079 $diffs
4080 Perhaps you forgot to build.  Or perhaps there is a problem with your
4081  source tree (see dgit(7) for some hints).  To see a full diff, run
4082    git diff $tree HEAD
4083 END
4084         } else {
4085             failedcmd @diffcmd;
4086         }
4087     }
4088     if (!$changesfile) {
4089         my $pat = changespat $cversion;
4090         my @cs = glob "$buildproductsdir/$pat";
4091         fail "failed to find unique changes file".
4092             " (looked for $pat in $buildproductsdir);".
4093             " perhaps you need to use dgit -C"
4094             unless @cs==1;
4095         ($changesfile) = @cs;
4096     } else {
4097         $changesfile = "$buildproductsdir/$changesfile";
4098     }
4099
4100     # Check that changes and .dsc agree enough
4101     $changesfile =~ m{[^/]*$};
4102     my $changes = parsecontrol($changesfile,$&);
4103     files_compare_inputs($dsc, $changes)
4104         unless forceing [qw(dsc-changes-mismatch)];
4105
4106     # Perhaps adjust .dsc to contain right set of origs
4107     changes_update_origs_from_dsc($dsc, $changes, $upstreamversion,
4108                                   $changesfile)
4109         unless forceing [qw(changes-origs-exactly)];
4110
4111     # Checks complete, we're going to try and go ahead:
4112
4113     responder_send_file('changes',$changesfile);
4114     responder_send_command("param head $dgithead");
4115     responder_send_command("param csuite $csuite");
4116     responder_send_command("param tagformat $tagformat");
4117     if (defined $maintviewhead) {
4118         die unless ($protovsn//4) >= 4;
4119         responder_send_command("param maint-view $maintviewhead");
4120     }
4121
4122     if (deliberately_not_fast_forward) {
4123         git_for_each_ref(lrfetchrefs, sub {
4124             my ($objid,$objtype,$lrfetchrefname,$reftail) = @_;
4125             my $rrefname= substr($lrfetchrefname, length(lrfetchrefs) + 1);
4126             responder_send_command("previously $rrefname=$objid");
4127             $previously{$rrefname} = $objid;
4128         });
4129     }
4130
4131     my @tagwants = push_tagwants($cversion, $dgithead, $maintviewhead,
4132                                  ".git/dgit/tag");
4133     my @tagobjfns;
4134
4135     supplementary_message(<<'END');
4136 Push failed, while signing the tag.
4137 You can retry the push, after fixing the problem, if you like.
4138 END
4139     # If we manage to sign but fail to record it anywhere, it's fine.
4140     if ($we_are_responder) {
4141         @tagobjfns = map { $_->{Tfn}('.signed-tmp') } @tagwants;
4142         responder_receive_files('signed-tag', @tagobjfns);
4143     } else {
4144         @tagobjfns = push_mktags($clogp,$dscpath,
4145                               $changesfile,$changesfile,
4146                               \@tagwants);
4147     }
4148     supplementary_message(<<'END');
4149 Push failed, *after* signing the tag.
4150 If you want to try again, you should use a new version number.
4151 END
4152
4153     pairwise { $a->{TagObjFn} = $b } @tagwants, @tagobjfns;
4154
4155     foreach my $tw (@tagwants) {
4156         my $tag = $tw->{Tag};
4157         my $tagobjfn = $tw->{TagObjFn};
4158         my $tag_obj_hash =
4159             cmdoutput @git, qw(hash-object -w -t tag), $tagobjfn;
4160         runcmd_ordryrun @git, qw(verify-tag), $tag_obj_hash;
4161         runcmd_ordryrun_local
4162             @git, qw(update-ref), "refs/tags/$tag", $tag_obj_hash;
4163     }
4164
4165     supplementary_message(<<'END');
4166 Push failed, while updating the remote git repository - see messages above.
4167 If you want to try again, you should use a new version number.
4168 END
4169     if (!check_for_git()) {
4170         create_remote_git_repo();
4171     }
4172
4173     my @pushrefs = $forceflag.$dgithead.":".rrref();
4174     foreach my $tw (@tagwants) {
4175         push @pushrefs, $forceflag."refs/tags/$tw->{Tag}";
4176     }
4177
4178     runcmd_ordryrun @git,
4179         qw(-c push.followTags=false push), access_giturl(), @pushrefs;
4180     runcmd_ordryrun @git, qw(update-ref -m), 'dgit push', lrref(), $dgithead;
4181
4182     supplementary_message(<<'END');
4183 Push failed, while obtaining signatures on the .changes and .dsc.
4184 If it was just that the signature failed, you may try again by using
4185 debsign by hand to sign the changes
4186    $changesfile
4187 and then dput to complete the upload.
4188 If you need to change the package, you must use a new version number.
4189 END
4190     if ($we_are_responder) {
4191         my $dryrunsuffix = act_local() ? "" : ".tmp";
4192         responder_receive_files('signed-dsc-changes',
4193                                 "$dscpath$dryrunsuffix",
4194                                 "$changesfile$dryrunsuffix");
4195     } else {
4196         if (act_local()) {
4197             rename "$dscpath.tmp",$dscpath or die "$dscfn $!";
4198         } else {
4199             progress "[new .dsc left in $dscpath.tmp]";
4200         }
4201         sign_changes $changesfile;
4202     }
4203
4204     supplementary_message(<<END);
4205 Push failed, while uploading package(s) to the archive server.
4206 You can retry the upload of exactly these same files with dput of:
4207   $changesfile
4208 If that .changes file is broken, you will need to use a new version
4209 number for your next attempt at the upload.
4210 END
4211     my $host = access_cfg('upload-host','RETURN-UNDEF');
4212     my @hostarg = defined($host) ? ($host,) : ();
4213     runcmd_ordryrun @dput, @hostarg, $changesfile;
4214     printdone "pushed and uploaded $cversion";
4215
4216     supplementary_message('');
4217     responder_send_command("complete");
4218 }
4219
4220 sub cmd_clone {
4221     parseopts();
4222     my $dstdir;
4223     badusage "-p is not allowed with clone; specify as argument instead"
4224         if defined $package;
4225     if (@ARGV==1) {
4226         ($package) = @ARGV;
4227     } elsif (@ARGV==2 && $ARGV[1] =~ m#^\w#) {
4228         ($package,$isuite) = @ARGV;
4229     } elsif (@ARGV==2 && $ARGV[1] =~ m#^[./]#) {
4230         ($package,$dstdir) = @ARGV;
4231     } elsif (@ARGV==3) {
4232         ($package,$isuite,$dstdir) = @ARGV;
4233     } else {
4234         badusage "incorrect arguments to dgit clone";
4235     }
4236     notpushing();
4237
4238     $dstdir ||= "$package";
4239     if (stat_exists $dstdir) {
4240         fail "$dstdir already exists";
4241     }
4242
4243     my $cwd_remove;
4244     if ($rmonerror && !$dryrun_level) {
4245         $cwd_remove= getcwd();
4246         unshift @end, sub {
4247             return unless defined $cwd_remove;
4248             if (!chdir "$cwd_remove") {
4249                 return if $!==&ENOENT;
4250                 die "chdir $cwd_remove: $!";
4251             }
4252             printdebug "clone rmonerror removing $dstdir\n";
4253             if (stat $dstdir) {
4254                 rmtree($dstdir) or die "remove $dstdir: $!\n";
4255             } elsif (grep { $! == $_ }
4256                      (ENOENT, ENOTDIR, EACCES, EPERM, ELOOP)) {
4257             } else {
4258                 print STDERR "check whether to remove $dstdir: $!\n";
4259             }
4260         };
4261     }
4262
4263     clone($dstdir);
4264     $cwd_remove = undef;
4265 }
4266
4267 sub branchsuite () {
4268     my $branch = cmdoutput_errok @git, qw(symbolic-ref HEAD);
4269     if ($branch =~ m#$lbranch_re#o) {
4270         return $1;
4271     } else {
4272         return undef;
4273     }
4274 }
4275
4276 sub fetchpullargs () {
4277     if (!defined $package) {
4278         my $sourcep = parsecontrol('debian/control','debian/control');
4279         $package = getfield $sourcep, 'Source';
4280     }
4281     if (@ARGV==0) {
4282         $isuite = branchsuite();
4283         if (!$isuite) {
4284             my $clogp = parsechangelog();
4285             $isuite = getfield $clogp, 'Distribution';
4286         }
4287     } elsif (@ARGV==1) {
4288         ($isuite) = @ARGV;
4289     } else {
4290         badusage "incorrect arguments to dgit fetch or dgit pull";
4291     }
4292     notpushing();
4293 }
4294
4295 sub cmd_fetch {
4296     parseopts();
4297     fetchpullargs();
4298     my $multi_fetched = fork_for_multisuite(sub { });
4299     exit 0 if $multi_fetched;
4300     fetch();
4301 }
4302
4303 sub cmd_pull {
4304     parseopts();
4305     fetchpullargs();
4306     if (quiltmode_splitbrain()) {
4307         my ($format, $fopts) = get_source_format();
4308         madformat($format) and fail <<END
4309 dgit pull not yet supported in split view mode (--quilt=$quilt_mode)
4310 END
4311     }
4312     pull();
4313 }
4314
4315 sub cmd_push {
4316     parseopts();
4317     pushing();
4318     badusage "-p is not allowed with dgit push" if defined $package;
4319     check_not_dirty();
4320     my $clogp = parsechangelog();
4321     $package = getfield $clogp, 'Source';
4322     my $specsuite;
4323     if (@ARGV==0) {
4324     } elsif (@ARGV==1) {
4325         ($specsuite) = (@ARGV);
4326     } else {
4327         badusage "incorrect arguments to dgit push";
4328     }
4329     $isuite = getfield $clogp, 'Distribution';
4330     if ($new_package) {
4331         local ($package) = $existing_package; # this is a hack
4332         canonicalise_suite();
4333     } else {
4334         canonicalise_suite();
4335     }
4336     if (defined $specsuite &&
4337         $specsuite ne $isuite &&
4338         $specsuite ne $csuite) {
4339             fail "dgit push: changelog specifies $isuite ($csuite)".
4340                 " but command line specifies $specsuite";
4341     }
4342     dopush();
4343 }
4344
4345 #---------- remote commands' implementation ----------
4346
4347 sub cmd_remote_push_build_host {
4348     my ($nrargs) = shift @ARGV;
4349     my (@rargs) = @ARGV[0..$nrargs-1];
4350     @ARGV = @ARGV[$nrargs..$#ARGV];
4351     die unless @rargs;
4352     my ($dir,$vsnwant) = @rargs;
4353     # vsnwant is a comma-separated list; we report which we have
4354     # chosen in our ready response (so other end can tell if they
4355     # offered several)
4356     $debugprefix = ' ';
4357     $we_are_responder = 1;
4358     $us .= " (build host)";
4359
4360     pushing();
4361
4362     open PI, "<&STDIN" or die $!;
4363     open STDIN, "/dev/null" or die $!;
4364     open PO, ">&STDOUT" or die $!;
4365     autoflush PO 1;
4366     open STDOUT, ">&STDERR" or die $!;
4367     autoflush STDOUT 1;
4368
4369     $vsnwant //= 1;
4370     ($protovsn) = grep {
4371         $vsnwant =~ m{^(?:.*,)?$_(?:,.*)?$}
4372     } @rpushprotovsn_support;
4373
4374     fail "build host has dgit rpush protocol versions ".
4375         (join ",", @rpushprotovsn_support).
4376         " but invocation host has $vsnwant"
4377         unless defined $protovsn;
4378
4379     responder_send_command("dgit-remote-push-ready $protovsn");
4380     rpush_handle_protovsn_bothends();
4381     changedir $dir;
4382     &cmd_push;
4383 }
4384
4385 sub cmd_remote_push_responder { cmd_remote_push_build_host(); }
4386 # ... for compatibility with proto vsn.1 dgit (just so that user gets
4387 #     a good error message)
4388
4389 sub rpush_handle_protovsn_bothends () {
4390     if ($protovsn < 4) {
4391         need_tagformat 'old', "rpush negotiated protocol $protovsn";
4392     }
4393     select_tagformat();
4394 }
4395
4396 our $i_tmp;
4397
4398 sub i_cleanup {
4399     local ($@, $?);
4400     my $report = i_child_report();
4401     if (defined $report) {
4402         printdebug "($report)\n";
4403     } elsif ($i_child_pid) {
4404         printdebug "(killing build host child $i_child_pid)\n";
4405         kill 15, $i_child_pid;
4406     }
4407     if (defined $i_tmp && !defined $initiator_tempdir) {
4408         changedir "/";
4409         eval { rmtree $i_tmp; };
4410     }
4411 }
4412
4413 END { i_cleanup(); }
4414
4415 sub i_method {
4416     my ($base,$selector,@args) = @_;
4417     $selector =~ s/\-/_/g;
4418     { no strict qw(refs); &{"${base}_${selector}"}(@args); }
4419 }
4420
4421 sub cmd_rpush {
4422     pushing();
4423     my $host = nextarg;
4424     my $dir;
4425     if ($host =~ m/^((?:[^][]|\[[^][]*\])*)\:/) {
4426         $host = $1;
4427         $dir = $'; #';
4428     } else {
4429         $dir = nextarg;
4430     }
4431     $dir =~ s{^-}{./-};
4432     my @rargs = ($dir);
4433     push @rargs, join ",", @rpushprotovsn_support;
4434     my @rdgit;
4435     push @rdgit, @dgit;
4436     push @rdgit, @ropts;
4437     push @rdgit, qw(remote-push-build-host), (scalar @rargs), @rargs;
4438     push @rdgit, @ARGV;
4439     my @cmd = (@ssh, $host, shellquote @rdgit);
4440     debugcmd "+",@cmd;
4441
4442     if (defined $initiator_tempdir) {
4443         rmtree $initiator_tempdir;
4444         mkdir $initiator_tempdir, 0700 or die "$initiator_tempdir: $!";
4445         $i_tmp = $initiator_tempdir;
4446     } else {
4447         $i_tmp = tempdir();
4448     }
4449     $i_child_pid = open2(\*RO, \*RI, @cmd);
4450     changedir $i_tmp;
4451     ($protovsn) = initiator_expect { m/^dgit-remote-push-ready (\S+)/ };
4452     die "$protovsn ?" unless grep { $_ eq $protovsn } @rpushprotovsn_support;
4453     $supplementary_message = '' unless $protovsn >= 3;
4454
4455     fail "rpush negotiated protocol version $protovsn".
4456         " which does not support quilt mode $quilt_mode"
4457         if quiltmode_splitbrain;
4458
4459     rpush_handle_protovsn_bothends();
4460     for (;;) {
4461         my ($icmd,$iargs) = initiator_expect {
4462             m/^(\S+)(?: (.*))?$/;
4463             ($1,$2);
4464         };
4465         i_method "i_resp", $icmd, $iargs;
4466     }
4467 }
4468
4469 sub i_resp_progress ($) {
4470     my ($rhs) = @_;
4471     my $msg = protocol_read_bytes \*RO, $rhs;
4472     progress $msg;
4473 }
4474
4475 sub i_resp_supplementary_message ($) {
4476     my ($rhs) = @_;
4477     $supplementary_message = protocol_read_bytes \*RO, $rhs;
4478 }
4479
4480 sub i_resp_complete {
4481     my $pid = $i_child_pid;
4482     $i_child_pid = undef; # prevents killing some other process with same pid
4483     printdebug "waiting for build host child $pid...\n";
4484     my $got = waitpid $pid, 0;
4485     die $! unless $got == $pid;
4486     die "build host child failed $?" if $?;
4487
4488     i_cleanup();
4489     printdebug "all done\n";
4490     exit 0;
4491 }
4492
4493 sub i_resp_file ($) {
4494     my ($keyword) = @_;
4495     my $localname = i_method "i_localname", $keyword;
4496     my $localpath = "$i_tmp/$localname";
4497     stat_exists $localpath and
4498         badproto \*RO, "file $keyword ($localpath) twice";
4499     protocol_receive_file \*RO, $localpath;
4500     i_method "i_file", $keyword;
4501 }
4502
4503 our %i_param;
4504
4505 sub i_resp_param ($) {
4506     $_[0] =~ m/^(\S+) (.*)$/ or badproto \*RO, "bad param spec";
4507     $i_param{$1} = $2;
4508 }
4509
4510 sub i_resp_previously ($) {
4511     $_[0] =~ m#^(refs/tags/\S+)=(\w+)$#
4512         or badproto \*RO, "bad previously spec";
4513     my $r = system qw(git check-ref-format), $1;
4514     die "bad previously ref spec ($r)" if $r;
4515     $previously{$1} = $2;
4516 }
4517
4518 our %i_wanted;
4519
4520 sub i_resp_want ($) {
4521     my ($keyword) = @_;
4522     die "$keyword ?" if $i_wanted{$keyword}++;
4523     my @localpaths = i_method "i_want", $keyword;
4524     printdebug "[[  $keyword @localpaths\n";
4525     foreach my $localpath (@localpaths) {
4526         protocol_send_file \*RI, $localpath;
4527     }
4528     print RI "files-end\n" or die $!;
4529 }
4530
4531 our ($i_clogp, $i_version, $i_dscfn, $i_changesfn);
4532
4533 sub i_localname_parsed_changelog {
4534     return "remote-changelog.822";
4535 }
4536 sub i_file_parsed_changelog {
4537     ($i_clogp, $i_version, $i_dscfn) =
4538         push_parse_changelog "$i_tmp/remote-changelog.822";
4539     die if $i_dscfn =~ m#/|^\W#;
4540 }
4541
4542 sub i_localname_dsc {
4543     defined $i_dscfn or badproto \*RO, "dsc (before parsed-changelog)";
4544     return $i_dscfn;
4545 }
4546 sub i_file_dsc { }
4547
4548 sub i_localname_changes {
4549     defined $i_dscfn or badproto \*RO, "dsc (before parsed-changelog)";
4550     $i_changesfn = $i_dscfn;
4551     $i_changesfn =~ s/\.dsc$/_dgit.changes/ or die;
4552     return $i_changesfn;
4553 }
4554 sub i_file_changes { }
4555
4556 sub i_want_signed_tag {
4557     printdebug Dumper(\%i_param, $i_dscfn);
4558     defined $i_param{'head'} && defined $i_dscfn && defined $i_clogp
4559         && defined $i_param{'csuite'}
4560         or badproto \*RO, "premature desire for signed-tag";
4561     my $head = $i_param{'head'};
4562     die if $head =~ m/[^0-9a-f]/ || $head !~ m/^../;
4563
4564     my $maintview = $i_param{'maint-view'};
4565     die if defined $maintview && $maintview =~ m/[^0-9a-f]/;
4566
4567     select_tagformat();
4568     if ($protovsn >= 4) {
4569         my $p = $i_param{'tagformat'} // '<undef>';
4570         $p eq $tagformat
4571             or badproto \*RO, "tag format mismatch: $p vs. $tagformat";
4572     }
4573
4574     die unless $i_param{'csuite'} =~ m/^$suite_re$/;
4575     $csuite = $&;
4576     push_parse_dsc $i_dscfn, 'remote dsc', $i_version;
4577
4578     my @tagwants = push_tagwants $i_version, $head, $maintview, "tag";
4579
4580     return
4581         push_mktags $i_clogp, $i_dscfn,
4582             $i_changesfn, 'remote changes',
4583             \@tagwants;
4584 }
4585
4586 sub i_want_signed_dsc_changes {
4587     rename "$i_dscfn.tmp","$i_dscfn" or die "$i_dscfn $!";
4588     sign_changes $i_changesfn;
4589     return ($i_dscfn, $i_changesfn);
4590 }
4591
4592 #---------- building etc. ----------
4593
4594 our $version;
4595 our $sourcechanges;
4596 our $dscfn;
4597
4598 #----- `3.0 (quilt)' handling -----
4599
4600 our $fakeeditorenv = 'DGIT_FAKE_EDITOR_QUILT';
4601
4602 sub quiltify_dpkg_commit ($$$;$) {
4603     my ($patchname,$author,$msg, $xinfo) = @_;
4604     $xinfo //= '';
4605
4606     mkpath '.git/dgit';
4607     my $descfn = ".git/dgit/quilt-description.tmp";
4608     open O, '>', $descfn or die "$descfn: $!";
4609     $msg =~ s/\n+/\n\n/;
4610     print O <<END or die $!;
4611 From: $author
4612 ${xinfo}Subject: $msg
4613 ---
4614
4615 END
4616     close O or die $!;
4617
4618     {
4619         local $ENV{'EDITOR'} = cmdoutput qw(realpath --), $0;
4620         local $ENV{'VISUAL'} = $ENV{'EDITOR'};
4621         local $ENV{$fakeeditorenv} = cmdoutput qw(realpath --), $descfn;
4622         runcmd @dpkgsource, qw(--commit --include-removal .), $patchname;
4623     }
4624 }
4625
4626 sub quiltify_trees_differ ($$;$$$) {
4627     my ($x,$y,$finegrained,$ignorenamesr,$unrepres) = @_;
4628     # returns true iff the two tree objects differ other than in debian/
4629     # with $finegrained,
4630     # returns bitmask 01 - differ in upstream files except .gitignore
4631     #                 02 - differ in .gitignore
4632     # if $ignorenamesr is defined, $ingorenamesr->{$fn}
4633     #  is set for each modified .gitignore filename $fn
4634     # if $unrepres is defined, array ref to which is appeneded
4635     #  a list of unrepresentable changes (removals of upstream files
4636     #  (as messages)
4637     local $/=undef;
4638     my @cmd = (@git, qw(diff-tree -z));
4639     push @cmd, qw(--name-only) unless $unrepres;
4640     push @cmd, qw(-r) if $finegrained || $unrepres;
4641     push @cmd, $x, $y;
4642     my $diffs= cmdoutput @cmd;
4643     my $r = 0;
4644     my @lmodes;
4645     foreach my $f (split /\0/, $diffs) {
4646         if ($unrepres && !@lmodes) {
4647             @lmodes = $f =~ m/^\:(\w+) (\w+) \w+ \w+ / or die "$_ ?";
4648             next;
4649         }
4650         my ($oldmode,$newmode) = @lmodes;
4651         @lmodes = ();
4652
4653         next if $f =~ m#^debian(?:/.*)?$#s;
4654
4655         if ($unrepres) {
4656             eval {
4657                 die "not a plain file\n"
4658                     unless $newmode =~ m/^10\d{4}$/ ||
4659                            $oldmode =~ m/^10\d{4}$/;
4660                 if ($oldmode =~ m/[^0]/ &&
4661                     $newmode =~ m/[^0]/) {
4662                     die "mode changed\n" if $oldmode ne $newmode;
4663                 } else {
4664                     die "non-default mode\n"
4665                         unless $newmode =~ m/^100644$/ ||
4666                                $oldmode =~ m/^100644$/;
4667                 }
4668             };
4669             if ($@) {
4670                 local $/="\n"; chomp $@;
4671                 push @$unrepres, [ $f, "$@ ($oldmode->$newmode)" ];
4672             }
4673         }
4674
4675         my $isignore = $f =~ m#^(?:.*/)?.gitignore$#s;
4676         $r |= $isignore ? 02 : 01;
4677         $ignorenamesr->{$f}=1 if $ignorenamesr && $isignore;
4678     }
4679     printdebug "quiltify_trees_differ $x $y => $r\n";
4680     return $r;
4681 }
4682
4683 sub quiltify_tree_sentinelfiles ($) {
4684     # lists the `sentinel' files present in the tree
4685     my ($x) = @_;
4686     my $r = cmdoutput @git, qw(ls-tree --name-only), $x,
4687         qw(-- debian/rules debian/control);
4688     $r =~ s/\n/,/g;
4689     return $r;
4690 }
4691
4692 sub quiltify_splitbrain_needed () {
4693     if (!$split_brain) {
4694         progress "dgit view: changes are required...";
4695         runcmd @git, qw(checkout -q -b dgit-view);
4696         $split_brain = 1;
4697     }
4698 }
4699
4700 sub quiltify_splitbrain ($$$$$$) {
4701     my ($clogp, $unapplied, $headref, $diffbits,
4702         $editedignores, $cachekey) = @_;
4703     if ($quilt_mode !~ m/gbp|dpm/) {
4704         # treat .gitignore just like any other upstream file
4705         $diffbits = { %$diffbits };
4706         $_ = !!$_ foreach values %$diffbits;
4707     }
4708     # We would like any commits we generate to be reproducible
4709     my @authline = clogp_authline($clogp);
4710     local $ENV{GIT_COMMITTER_NAME} =  $authline[0];
4711     local $ENV{GIT_COMMITTER_EMAIL} = $authline[1];
4712     local $ENV{GIT_COMMITTER_DATE} =  $authline[2];
4713     local $ENV{GIT_AUTHOR_NAME} =  $authline[0];
4714     local $ENV{GIT_AUTHOR_EMAIL} = $authline[1];
4715     local $ENV{GIT_AUTHOR_DATE} =  $authline[2];
4716
4717     if ($quilt_mode =~ m/gbp|unapplied/ &&
4718         ($diffbits->{O2H} & 01)) {
4719         my $msg =
4720  "--quilt=$quilt_mode specified, implying patches-unapplied git tree\n".
4721  " but git tree differs from orig in upstream files.";
4722         if (!stat_exists "debian/patches") {
4723             $msg .=
4724  "\n ... debian/patches is missing; perhaps this is a patch queue branch?";
4725         }
4726         fail $msg;
4727     }
4728     if ($quilt_mode =~ m/dpm/ &&
4729         ($diffbits->{H2A} & 01)) {
4730         fail <<END;
4731 --quilt=$quilt_mode specified, implying patches-applied git tree
4732  but git tree differs from result of applying debian/patches to upstream
4733 END
4734     }
4735     if ($quilt_mode =~ m/gbp|unapplied/ &&
4736         ($diffbits->{O2A} & 01)) { # some patches
4737         quiltify_splitbrain_needed();
4738         progress "dgit view: creating patches-applied version using gbp pq";
4739         runcmd shell_cmd 'exec >/dev/null', gbp_pq, qw(import);
4740         # gbp pq import creates a fresh branch; push back to dgit-view
4741         runcmd @git, qw(update-ref refs/heads/dgit-view HEAD);
4742         runcmd @git, qw(checkout -q dgit-view);
4743     }
4744     if ($quilt_mode =~ m/gbp|dpm/ &&
4745         ($diffbits->{O2A} & 02)) {
4746         fail <<END
4747 --quilt=$quilt_mode specified, implying that HEAD is for use with a
4748  tool which does not create patches for changes to upstream
4749  .gitignores: but, such patches exist in debian/patches.
4750 END
4751     }
4752     if (($diffbits->{O2H} & 02) && # user has modified .gitignore
4753         !($diffbits->{O2A} & 02)) { # patches do not change .gitignore
4754         quiltify_splitbrain_needed();
4755         progress "dgit view: creating patch to represent .gitignore changes";
4756         ensuredir "debian/patches";
4757         my $gipatch = "debian/patches/auto-gitignore";
4758         open GIPATCH, ">>", "$gipatch" or die "$gipatch: $!";
4759         stat GIPATCH or die "$gipatch: $!";
4760         fail "$gipatch already exists; but want to create it".
4761             " to record .gitignore changes" if (stat _)[7];
4762         print GIPATCH <<END or die "$gipatch: $!";
4763 Subject: Update .gitignore from Debian packaging branch
4764
4765 The Debian packaging git branch contains these updates to the upstream
4766 .gitignore file(s).  This patch is autogenerated, to provide these
4767 updates to users of the official Debian archive view of the package.
4768
4769 [dgit ($our_version) update-gitignore]
4770 ---
4771 END
4772         close GIPATCH or die "$gipatch: $!";
4773         runcmd shell_cmd "exec >>$gipatch", @git, qw(diff),
4774             $unapplied, $headref, "--", sort keys %$editedignores;
4775         open SERIES, "+>>", "debian/patches/series" or die $!;
4776         defined seek SERIES, -1, 2 or $!==EINVAL or die $!;
4777         my $newline;
4778         defined read SERIES, $newline, 1 or die $!;
4779         print SERIES "\n" or die $! unless $newline eq "\n";
4780         print SERIES "auto-gitignore\n" or die $!;
4781         close SERIES or die  $!;
4782         runcmd @git, qw(add -- debian/patches/series), $gipatch;
4783         commit_admin <<END
4784 Commit patch to update .gitignore
4785
4786 [dgit ($our_version) update-gitignore-quilt-fixup]
4787 END
4788     }
4789
4790     my $dgitview = git_rev_parse 'HEAD';
4791
4792     changedir '../../../..';
4793     # When we no longer need to support squeeze, use --create-reflog
4794     # instead of this:
4795     ensuredir ".git/logs/refs/dgit-intern";
4796     my $makelogfh = new IO::File ".git/logs/refs/$splitbraincache", '>>'
4797       or die $!;
4798
4799     my $oldcache = git_get_ref "refs/$splitbraincache";
4800     if ($oldcache eq $dgitview) {
4801         my $tree = cmdoutput qw(git rev-parse), "$dgitview:";
4802         # git update-ref doesn't always update, in this case.  *sigh*
4803         my $dummy = make_commit_text <<END;
4804 tree $tree
4805 parent $dgitview
4806 author Dgit <dgit\@example.com> 1000000000 +0000
4807 committer Dgit <dgit\@example.com> 1000000000 +0000
4808
4809 Dummy commit - do not use
4810 END
4811         runcmd @git, qw(update-ref -m), "dgit $our_version - dummy",
4812             "refs/$splitbraincache", $dummy;
4813     }
4814     runcmd @git, qw(update-ref -m), $cachekey, "refs/$splitbraincache",
4815         $dgitview;
4816
4817     changedir '.git/dgit/unpack/work';
4818
4819     my $saved = maybe_split_brain_save $headref, $dgitview, "converted";
4820     progress "dgit view: created ($saved)";
4821 }
4822
4823 sub quiltify ($$$$) {
4824     my ($clogp,$target,$oldtiptree,$failsuggestion) = @_;
4825
4826     # Quilt patchification algorithm
4827     #
4828     # We search backwards through the history of the main tree's HEAD
4829     # (T) looking for a start commit S whose tree object is identical
4830     # to to the patch tip tree (ie the tree corresponding to the
4831     # current dpkg-committed patch series).  For these purposes
4832     # `identical' disregards anything in debian/ - this wrinkle is
4833     # necessary because dpkg-source treates debian/ specially.
4834     #
4835     # We can only traverse edges where at most one of the ancestors'
4836     # trees differs (in changes outside in debian/).  And we cannot
4837     # handle edges which change .pc/ or debian/patches.  To avoid
4838     # going down a rathole we avoid traversing edges which introduce
4839     # debian/rules or debian/control.  And we set a limit on the
4840     # number of edges we are willing to look at.
4841     #
4842     # If we succeed, we walk forwards again.  For each traversed edge
4843     # PC (with P parent, C child) (starting with P=S and ending with
4844     # C=T) to we do this:
4845     #  - git checkout C
4846     #  - dpkg-source --commit with a patch name and message derived from C
4847     # After traversing PT, we git commit the changes which
4848     # should be contained within debian/patches.
4849
4850     # The search for the path S..T is breadth-first.  We maintain a
4851     # todo list containing search nodes.  A search node identifies a
4852     # commit, and looks something like this:
4853     #  $p = {
4854     #      Commit => $git_commit_id,
4855     #      Child => $c,                          # or undef if P=T
4856     #      Whynot => $reason_edge_PC_unsuitable, # in @nots only
4857     #      Nontrivial => true iff $p..$c has relevant changes
4858     #  };
4859
4860     my @todo;
4861     my @nots;
4862     my $sref_S;
4863     my $max_work=100;
4864     my %considered; # saves being exponential on some weird graphs
4865
4866     my $t_sentinels = quiltify_tree_sentinelfiles $target;
4867
4868     my $not = sub {
4869         my ($search,$whynot) = @_;
4870         printdebug " search NOT $search->{Commit} $whynot\n";
4871         $search->{Whynot} = $whynot;
4872         push @nots, $search;
4873         no warnings qw(exiting);
4874         next;
4875     };
4876
4877     push @todo, {
4878         Commit => $target,
4879     };
4880
4881     while (@todo) {
4882         my $c = shift @todo;
4883         next if $considered{$c->{Commit}}++;
4884
4885         $not->($c, "maximum search space exceeded") if --$max_work <= 0;
4886
4887         printdebug "quiltify investigate $c->{Commit}\n";
4888
4889         # are we done?
4890         if (!quiltify_trees_differ $c->{Commit}, $oldtiptree) {
4891             printdebug " search finished hooray!\n";
4892             $sref_S = $c;
4893             last;
4894         }
4895
4896         if ($quilt_mode eq 'nofix') {
4897             fail "quilt fixup required but quilt mode is \`nofix'\n".
4898                 "HEAD commit $c->{Commit} differs from tree implied by ".
4899                 " debian/patches (tree object $oldtiptree)";
4900         }
4901         if ($quilt_mode eq 'smash') {
4902             printdebug " search quitting smash\n";
4903             last;
4904         }
4905
4906         my $c_sentinels = quiltify_tree_sentinelfiles $c->{Commit};
4907         $not->($c, "has $c_sentinels not $t_sentinels")
4908             if $c_sentinels ne $t_sentinels;
4909
4910         my $commitdata = cmdoutput @git, qw(cat-file commit), $c->{Commit};
4911         $commitdata =~ m/\n\n/;
4912         $commitdata =~ $`;
4913         my @parents = ($commitdata =~ m/^parent (\w+)$/gm);
4914         @parents = map { { Commit => $_, Child => $c } } @parents;
4915
4916         $not->($c, "root commit") if !@parents;
4917
4918         foreach my $p (@parents) {
4919             $p->{Nontrivial}= quiltify_trees_differ $p->{Commit},$c->{Commit};
4920         }
4921         my $ndiffers = grep { $_->{Nontrivial} } @parents;
4922         $not->($c, "merge ($ndiffers nontrivial parents)") if $ndiffers > 1;
4923
4924         foreach my $p (@parents) {
4925             printdebug "considering C=$c->{Commit} P=$p->{Commit}\n";
4926
4927             my @cmd= (@git, qw(diff-tree -r --name-only),
4928                       $p->{Commit},$c->{Commit}, qw(-- debian/patches .pc));
4929             my $patchstackchange = cmdoutput @cmd;
4930             if (length $patchstackchange) {
4931                 $patchstackchange =~ s/\n/,/g;
4932                 $not->($p, "changed $patchstackchange");
4933             }
4934
4935             printdebug " search queue P=$p->{Commit} ",
4936                 ($p->{Nontrivial} ? "NT" : "triv"),"\n";
4937             push @todo, $p;
4938         }
4939     }
4940
4941     if (!$sref_S) {
4942         printdebug "quiltify want to smash\n";
4943
4944         my $abbrev = sub {
4945             my $x = $_[0]{Commit};
4946             $x =~ s/(.*?[0-9a-z]{8})[0-9a-z]*$/$1/;
4947             return $x;
4948         };
4949         my $reportnot = sub {
4950             my ($notp) = @_;
4951             my $s = $abbrev->($notp);
4952             my $c = $notp->{Child};
4953             $s .= "..".$abbrev->($c) if $c;
4954             $s .= ": ".$notp->{Whynot};
4955             return $s;
4956         };
4957         if ($quilt_mode eq 'linear') {
4958             print STDERR "$us: quilt fixup cannot be linear.  Stopped at:\n";
4959             foreach my $notp (@nots) {
4960                 print STDERR "$us:  ", $reportnot->($notp), "\n";
4961             }
4962             print STDERR "$us: $_\n" foreach @$failsuggestion;
4963             fail "quilt fixup naive history linearisation failed.\n".
4964  "Use dpkg-source --commit by hand; or, --quilt=smash for one ugly patch";
4965         } elsif ($quilt_mode eq 'smash') {
4966         } elsif ($quilt_mode eq 'auto') {
4967             progress "quilt fixup cannot be linear, smashing...";
4968         } else {
4969             die "$quilt_mode ?";
4970         }
4971
4972         my $time = $ENV{'GIT_COMMITTER_DATE'} || time;
4973         $time =~ s/\s.*//; # trim timezone from GIT_COMMITTER_DATE
4974         my $ncommits = 3;
4975         my $msg = cmdoutput @git, qw(log), "-n$ncommits";
4976
4977         quiltify_dpkg_commit "auto-$version-$target-$time",
4978             (getfield $clogp, 'Maintainer'),
4979             "Automatically generated patch ($clogp->{Version})\n".
4980             "Last (up to) $ncommits git changes, FYI:\n\n". $msg;
4981         return;
4982     }
4983
4984     progress "quiltify linearisation planning successful, executing...";
4985
4986     for (my $p = $sref_S;
4987          my $c = $p->{Child};
4988          $p = $p->{Child}) {
4989         printdebug "quiltify traverse $p->{Commit}..$c->{Commit}\n";
4990         next unless $p->{Nontrivial};
4991
4992         my $cc = $c->{Commit};
4993
4994         my $commitdata = cmdoutput @git, qw(cat-file commit), $cc;
4995         $commitdata =~ m/\n\n/ or die "$c ?";
4996         $commitdata = $`;
4997         my $msg = $'; #';
4998         $commitdata =~ m/^author (.*) \d+ [-+0-9]+$/m or die "$cc ?";
4999         my $author = $1;
5000
5001         my $commitdate = cmdoutput
5002             @git, qw(log -n1 --pretty=format:%aD), $cc;
5003
5004         $msg =~ s/^(.*)\n*/$1\n/ or die "$cc $msg ?";
5005
5006         my $strip_nls = sub { $msg =~ s/\n+$//; $msg .= "\n"; };
5007         $strip_nls->();
5008
5009         my $title = $1;
5010         my $patchname;
5011         my $patchdir;
5012
5013         my $gbp_check_suitable = sub {
5014             $_ = shift;
5015             my ($what) = @_;
5016
5017             eval {
5018                 die "contains unexpected slashes\n" if m{//} || m{/$};
5019                 die "contains leading punctuation\n" if m{^\W} || m{/\W};
5020                 die "contains bad character(s)\n" if m{[^-a-z0-9_.+=~/]}i;
5021                 die "too long" if length > 200;
5022             };
5023             return $_ unless $@;
5024             print STDERR "quiltifying commit $cc:".
5025                 " ignoring/dropping Gbp-Pq $what: $@";
5026             return undef;
5027         };
5028
5029         if ($msg =~ s/^ (?: gbp(?:-pq)? : \s* name \s+ |
5030                            gbp-pq-name: \s* )
5031                        (\S+) \s* \n //ixm) {
5032             $patchname = $gbp_check_suitable->($1, 'Name');
5033         }
5034         if ($msg =~ s/^ (?: gbp(?:-pq)? : \s* topic \s+ |
5035                            gbp-pq-topic: \s* )
5036                        (\S+) \s* \n //ixm) {
5037             $patchdir = $gbp_check_suitable->($1, 'Topic');
5038         }
5039
5040         $strip_nls->();
5041
5042         if (!defined $patchname) {
5043             $patchname = $title;
5044             $patchname =~ s/[.:]$//;
5045             use Text::Iconv;
5046             eval {
5047                 my $converter = new Text::Iconv qw(UTF-8 ASCII//TRANSLIT);
5048                 my $translitname = $converter->convert($patchname);
5049                 die unless defined $translitname;
5050                 $patchname = $translitname;
5051             };
5052             print STDERR
5053                 "dgit: patch title transliteration error: $@"
5054                 if $@;
5055             $patchname =~ y/ A-Z/-a-z/;
5056             $patchname =~ y/-a-z0-9_.+=~//cd;
5057             $patchname =~ s/^\W/x-$&/;
5058             $patchname = substr($patchname,0,40);
5059         }
5060         if (!defined $patchdir) {
5061             $patchdir = '';
5062         }
5063         if (length $patchdir) {
5064             $patchname = "$patchdir/$patchname";
5065         }
5066         if ($patchname =~ m{^(.*)/}) {
5067             mkpath "debian/patches/$1";
5068         }
5069
5070         my $index;
5071         for ($index='';
5072              stat "debian/patches/$patchname$index";
5073              $index++) { }
5074         $!==ENOENT or die "$patchname$index $!";
5075
5076         runcmd @git, qw(checkout -q), $cc;
5077
5078         # We use the tip's changelog so that dpkg-source doesn't
5079         # produce complaining messages from dpkg-parsechangelog.  None
5080         # of the information dpkg-source gets from the changelog is
5081         # actually relevant - it gets put into the original message
5082         # which dpkg-source provides our stunt editor, and then
5083         # overwritten.
5084         runcmd @git, qw(checkout -q), $target, qw(debian/changelog);
5085
5086         quiltify_dpkg_commit "$patchname$index", $author, $msg,
5087             "Date: $commitdate\n".
5088             "X-Dgit-Generated: $clogp->{Version} $cc\n";
5089
5090         runcmd @git, qw(checkout -q), $cc, qw(debian/changelog);
5091     }
5092
5093     runcmd @git, qw(checkout -q master);
5094 }
5095
5096 sub build_maybe_quilt_fixup () {
5097     my ($format,$fopts) = get_source_format;
5098     return unless madformat_wantfixup $format;
5099     # sigh
5100
5101     check_for_vendor_patches();
5102
5103     if (quiltmode_splitbrain) {
5104         fail <<END unless access_cfg_tagformats_can_splitbrain;
5105 quilt mode $quilt_mode requires split view so server needs to support
5106  both "new" and "maint" tag formats, but config says it doesn't.
5107 END
5108     }
5109
5110     my $clogp = parsechangelog();
5111     my $headref = git_rev_parse('HEAD');
5112
5113     prep_ud();
5114     changedir $ud;
5115
5116     my $upstreamversion = upstreamversion $version;
5117
5118     if ($fopts->{'single-debian-patch'}) {
5119         quilt_fixup_singlepatch($clogp, $headref, $upstreamversion);
5120     } else {
5121         quilt_fixup_multipatch($clogp, $headref, $upstreamversion);
5122     }
5123
5124     die 'bug' if $split_brain && !$need_split_build_invocation;
5125
5126     changedir '../../../..';
5127     runcmd_ordryrun_local
5128         @git, qw(pull --ff-only -q .git/dgit/unpack/work master);
5129 }
5130
5131 sub quilt_fixup_mkwork ($) {
5132     my ($headref) = @_;
5133
5134     mkdir "work" or die $!;
5135     changedir "work";
5136     mktree_in_ud_here();
5137     runcmd @git, qw(reset -q --hard), $headref;
5138 }
5139
5140 sub quilt_fixup_linkorigs ($$) {
5141     my ($upstreamversion, $fn) = @_;
5142     # calls $fn->($leafname);
5143
5144     foreach my $f (<../../../../*>) { #/){
5145         my $b=$f; $b =~ s{.*/}{};
5146         {
5147             local ($debuglevel) = $debuglevel-1;
5148             printdebug "QF linkorigs $b, $f ?\n";
5149         }
5150         next unless is_orig_file_of_vsn $b, $upstreamversion;
5151         printdebug "QF linkorigs $b, $f Y\n";
5152         link_ltarget $f, $b or die "$b $!";
5153         $fn->($b);
5154     }
5155 }
5156
5157 sub quilt_fixup_delete_pc () {
5158     runcmd @git, qw(rm -rqf .pc);
5159     commit_admin <<END
5160 Commit removal of .pc (quilt series tracking data)
5161
5162 [dgit ($our_version) upgrade quilt-remove-pc]
5163 END
5164 }
5165
5166 sub quilt_fixup_singlepatch ($$$) {
5167     my ($clogp, $headref, $upstreamversion) = @_;
5168
5169     progress "starting quiltify (single-debian-patch)";
5170
5171     # dpkg-source --commit generates new patches even if
5172     # single-debian-patch is in debian/source/options.  In order to
5173     # get it to generate debian/patches/debian-changes, it is
5174     # necessary to build the source package.
5175
5176     quilt_fixup_linkorigs($upstreamversion, sub { });
5177     quilt_fixup_mkwork($headref);
5178
5179     rmtree("debian/patches");
5180
5181     runcmd @dpkgsource, qw(-b .);
5182     changedir "..";
5183     runcmd @dpkgsource, qw(-x), (srcfn $version, ".dsc");
5184     rename srcfn("$upstreamversion", "/debian/patches"),
5185            "work/debian/patches";
5186
5187     changedir "work";
5188     commit_quilty_patch();
5189 }
5190
5191 sub quilt_make_fake_dsc ($) {
5192     my ($upstreamversion) = @_;
5193
5194     my $fakeversion="$upstreamversion-~~DGITFAKE";
5195
5196     my $fakedsc=new IO::File 'fake.dsc', '>' or die $!;
5197     print $fakedsc <<END or die $!;
5198 Format: 3.0 (quilt)
5199 Source: $package
5200 Version: $fakeversion
5201 Files:
5202 END
5203
5204     my $dscaddfile=sub {
5205         my ($b) = @_;
5206
5207         my $md = new Digest::MD5;
5208
5209         my $fh = new IO::File $b, '<' or die "$b $!";
5210         stat $fh or die $!;
5211         my $size = -s _;
5212
5213         $md->addfile($fh);
5214         print $fakedsc " ".$md->hexdigest." $size $b\n" or die $!;
5215     };
5216
5217     quilt_fixup_linkorigs($upstreamversion, $dscaddfile);
5218
5219     my @files=qw(debian/source/format debian/rules
5220                  debian/control debian/changelog);
5221     foreach my $maybe (qw(debian/patches debian/source/options
5222                           debian/tests/control)) {
5223         next unless stat_exists "../../../$maybe";
5224         push @files, $maybe;
5225     }
5226
5227     my $debtar= srcfn $fakeversion,'.debian.tar.gz';
5228     runcmd qw(env GZIP=-1n tar -zcf), "./$debtar", qw(-C ../../..), @files;
5229
5230     $dscaddfile->($debtar);
5231     close $fakedsc or die $!;
5232 }
5233
5234 sub quilt_check_splitbrain_cache ($$) {
5235     my ($headref, $upstreamversion) = @_;
5236     # Called only if we are in (potentially) split brain mode.
5237     # Called in $ud.
5238     # Computes the cache key and looks in the cache.
5239     # Returns ($dgit_view_commitid, $cachekey) or (undef, $cachekey)
5240
5241     my $splitbrain_cachekey;
5242
5243     progress
5244  "dgit: split brain (separate dgit view) may be needed (--quilt=$quilt_mode).";
5245     # we look in the reflog of dgit-intern/quilt-cache
5246     # we look for an entry whose message is the key for the cache lookup
5247     my @cachekey = (qw(dgit), $our_version);
5248     push @cachekey, $upstreamversion;
5249     push @cachekey, $quilt_mode;
5250     push @cachekey, $headref;
5251
5252     push @cachekey, hashfile('fake.dsc');
5253
5254     my $srcshash = Digest::SHA->new(256);
5255     my %sfs = ( %INC, '$0(dgit)' => $0 );
5256     foreach my $sfk (sort keys %sfs) {
5257         next unless $sfk =~ m/^\$0\b/ || $sfk =~ m{^Debian/Dgit\b};
5258         $srcshash->add($sfk,"  ");
5259         $srcshash->add(hashfile($sfs{$sfk}));
5260         $srcshash->add("\n");
5261     }
5262     push @cachekey, $srcshash->hexdigest();
5263     $splitbrain_cachekey = "@cachekey";
5264
5265     my @cmd = (@git, qw(log -g), '--pretty=format:%H %gs',
5266                $splitbraincache);
5267     printdebug "splitbrain cachekey $splitbrain_cachekey\n";
5268     debugcmd "|(probably)",@cmd;
5269     my $child = open GC, "-|";  defined $child or die $!;
5270     if (!$child) {
5271         chdir '../../..' or die $!;
5272         if (!stat ".git/logs/refs/$splitbraincache") {
5273             $! == ENOENT or die $!;
5274             printdebug ">(no reflog)\n";
5275             exit 0;
5276         }
5277         exec @cmd; die $!;
5278     }
5279     while (<GC>) {
5280         chomp;
5281         printdebug ">| ", $_, "\n" if $debuglevel > 1;
5282         next unless m/^(\w+) (\S.*\S)$/ && $2 eq $splitbrain_cachekey;
5283
5284         my $cachehit = $1;
5285         quilt_fixup_mkwork($headref);
5286         my $saved = maybe_split_brain_save $headref, $cachehit, "cache-hit";
5287         if ($cachehit ne $headref) {
5288             progress "dgit view: found cached ($saved)";
5289             runcmd @git, qw(checkout -q -b dgit-view), $cachehit;
5290             $split_brain = 1;
5291             return ($cachehit, $splitbrain_cachekey);
5292         }
5293         progress "dgit view: found cached, no changes required";
5294         return ($headref, $splitbrain_cachekey);
5295     }
5296     die $! if GC->error;
5297     failedcmd unless close GC;
5298
5299     printdebug "splitbrain cache miss\n";
5300     return (undef, $splitbrain_cachekey);
5301 }
5302
5303 sub quilt_fixup_multipatch ($$$) {
5304     my ($clogp, $headref, $upstreamversion) = @_;
5305
5306     progress "examining quilt state (multiple patches, $quilt_mode mode)";
5307
5308     # Our objective is:
5309     #  - honour any existing .pc in case it has any strangeness
5310     #  - determine the git commit corresponding to the tip of
5311     #    the patch stack (if there is one)
5312     #  - if there is such a git commit, convert each subsequent
5313     #    git commit into a quilt patch with dpkg-source --commit
5314     #  - otherwise convert all the differences in the tree into
5315     #    a single git commit
5316     #
5317     # To do this we:
5318
5319     # Our git tree doesn't necessarily contain .pc.  (Some versions of
5320     # dgit would include the .pc in the git tree.)  If there isn't
5321     # one, we need to generate one by unpacking the patches that we
5322     # have.
5323     #
5324     # We first look for a .pc in the git tree.  If there is one, we
5325     # will use it.  (This is not the normal case.)
5326     #
5327     # Otherwise need to regenerate .pc so that dpkg-source --commit
5328     # can work.  We do this as follows:
5329     #     1. Collect all relevant .orig from parent directory
5330     #     2. Generate a debian.tar.gz out of
5331     #         debian/{patches,rules,source/format,source/options}
5332     #     3. Generate a fake .dsc containing just these fields:
5333     #          Format Source Version Files
5334     #     4. Extract the fake .dsc
5335     #        Now the fake .dsc has a .pc directory.
5336     # (In fact we do this in every case, because in future we will
5337     # want to search for a good base commit for generating patches.)
5338     #
5339     # Then we can actually do the dpkg-source --commit
5340     #     1. Make a new working tree with the same object
5341     #        store as our main tree and check out the main
5342     #        tree's HEAD.
5343     #     2. Copy .pc from the fake's extraction, if necessary
5344     #     3. Run dpkg-source --commit
5345     #     4. If the result has changes to debian/, then
5346     #          - git add them them
5347     #          - git add .pc if we had a .pc in-tree
5348     #          - git commit
5349     #     5. If we had a .pc in-tree, delete it, and git commit
5350     #     6. Back in the main tree, fast forward to the new HEAD
5351
5352     # Another situation we may have to cope with is gbp-style
5353     # patches-unapplied trees.
5354     #
5355     # We would want to detect these, so we know to escape into
5356     # quilt_fixup_gbp.  However, this is in general not possible.
5357     # Consider a package with a one patch which the dgit user reverts
5358     # (with git revert or the moral equivalent).
5359     #
5360     # That is indistinguishable in contents from a patches-unapplied
5361     # tree.  And looking at the history to distinguish them is not
5362     # useful because the user might have made a confusing-looking git
5363     # history structure (which ought to produce an error if dgit can't
5364     # cope, not a silent reintroduction of an unwanted patch).
5365     #
5366     # So gbp users will have to pass an option.  But we can usually
5367     # detect their failure to do so: if the tree is not a clean
5368     # patches-applied tree, quilt linearisation fails, but the tree
5369     # _is_ a clean patches-unapplied tree, we can suggest that maybe
5370     # they want --quilt=unapplied.
5371     #
5372     # To help detect this, when we are extracting the fake dsc, we
5373     # first extract it with --skip-patches, and then apply the patches
5374     # afterwards with dpkg-source --before-build.  That lets us save a
5375     # tree object corresponding to .origs.
5376
5377     my $splitbrain_cachekey;
5378
5379     quilt_make_fake_dsc($upstreamversion);
5380
5381     if (quiltmode_splitbrain()) {
5382         my $cachehit;
5383         ($cachehit, $splitbrain_cachekey) =
5384             quilt_check_splitbrain_cache($headref, $upstreamversion);
5385         return if $cachehit;
5386     }
5387
5388     runcmd qw(sh -ec),
5389         'exec dpkg-source --no-check --skip-patches -x fake.dsc >/dev/null';
5390
5391     my $fakexdir= $package.'-'.(stripepoch $upstreamversion);
5392     rename $fakexdir, "fake" or die "$fakexdir $!";
5393
5394     changedir 'fake';
5395
5396     remove_stray_gits("source package");
5397     mktree_in_ud_here();
5398
5399     rmtree '.pc';
5400
5401     my $unapplied=git_add_write_tree();
5402     printdebug "fake orig tree object $unapplied\n";
5403
5404     ensuredir '.pc';
5405
5406     my @bbcmd = (qw(sh -ec), 'exec dpkg-source --before-build . >/dev/null');
5407     $!=0; $?=-1;
5408     if (system @bbcmd) {
5409         failedcmd @bbcmd if $? < 0;
5410         fail <<END;
5411 failed to apply your git tree's patch stack (from debian/patches/) to
5412  the corresponding upstream tarball(s).  Your source tree and .orig
5413  are probably too inconsistent.  dgit can only fix up certain kinds of
5414  anomaly (depending on the quilt mode).  See --quilt= in dgit(1).
5415 END
5416     }
5417
5418     changedir '..';
5419
5420     quilt_fixup_mkwork($headref);
5421
5422     my $mustdeletepc=0;
5423     if (stat_exists ".pc") {
5424         -d _ or die;
5425         progress "Tree already contains .pc - will use it then delete it.";
5426         $mustdeletepc=1;
5427     } else {
5428         rename '../fake/.pc','.pc' or die $!;
5429     }
5430
5431     changedir '../fake';
5432     rmtree '.pc';
5433     my $oldtiptree=git_add_write_tree();
5434     printdebug "fake o+d/p tree object $unapplied\n";
5435     changedir '../work';
5436
5437
5438     # We calculate some guesswork now about what kind of tree this might
5439     # be.  This is mostly for error reporting.
5440
5441     my %editedignores;
5442     my @unrepres;
5443     my $diffbits = {
5444         # H = user's HEAD
5445         # O = orig, without patches applied
5446         # A = "applied", ie orig with H's debian/patches applied
5447         O2H => quiltify_trees_differ($unapplied,$headref,   1,
5448                                      \%editedignores, \@unrepres),
5449         H2A => quiltify_trees_differ($headref,  $oldtiptree,1),
5450         O2A => quiltify_trees_differ($unapplied,$oldtiptree,1),
5451     };
5452
5453     my @dl;
5454     foreach my $b (qw(01 02)) {
5455         foreach my $v (qw(O2H O2A H2A)) {
5456             push @dl, ($diffbits->{$v} & $b) ? '##' : '==';
5457         }
5458     }
5459     printdebug "differences \@dl @dl.\n";
5460
5461     progress sprintf
5462 "$us: base trees orig=%.20s o+d/p=%.20s",
5463               $unapplied, $oldtiptree;
5464     progress sprintf
5465 "$us: quilt differences: src:  %s orig %s     gitignores:  %s orig %s\n".
5466 "$us: quilt differences:      HEAD %s o+d/p               HEAD %s o+d/p",
5467                              $dl[0], $dl[1],              $dl[3], $dl[4],
5468                                  $dl[2],                     $dl[5];
5469
5470     if (@unrepres) {
5471         print STDERR "dgit:  cannot represent change: $_->[1]: $_->[0]\n"
5472             foreach @unrepres;
5473         forceable_fail [qw(unrepresentable)], <<END;
5474 HEAD has changes to .orig[s] which are not representable by `3.0 (quilt)'
5475 END
5476     }
5477
5478     my @failsuggestion;
5479     if (!($diffbits->{O2H} & $diffbits->{O2A})) {
5480         push @failsuggestion, "This might be a patches-unapplied branch.";
5481     }  elsif (!($diffbits->{H2A} & $diffbits->{O2A})) {
5482         push @failsuggestion, "This might be a patches-applied branch.";
5483     }
5484     push @failsuggestion, "Maybe you need to specify one of".
5485         " --[quilt=]gbp --[quilt=]dpm --quilt=unapplied ?";
5486
5487     if (quiltmode_splitbrain()) {
5488         quiltify_splitbrain($clogp, $unapplied, $headref,
5489                             $diffbits, \%editedignores,
5490                             $splitbrain_cachekey);
5491         return;
5492     }
5493
5494     progress "starting quiltify (multiple patches, $quilt_mode mode)";
5495     quiltify($clogp,$headref,$oldtiptree,\@failsuggestion);
5496
5497     if (!open P, '>>', ".pc/applied-patches") {
5498         $!==&ENOENT or die $!;
5499     } else {
5500         close P;
5501     }
5502
5503     commit_quilty_patch();
5504
5505     if ($mustdeletepc) {
5506         quilt_fixup_delete_pc();
5507     }
5508 }
5509
5510 sub quilt_fixup_editor () {
5511     my $descfn = $ENV{$fakeeditorenv};
5512     my $editing = $ARGV[$#ARGV];
5513     open I1, '<', $descfn or die "$descfn: $!";
5514     open I2, '<', $editing or die "$editing: $!";
5515     unlink $editing or die "$editing: $!";
5516     open O, '>', $editing or die "$editing: $!";
5517     while (<I1>) { print O or die $!; } I1->error and die $!;
5518     my $copying = 0;
5519     while (<I2>) {
5520         $copying ||= m/^\-\-\- /;
5521         next unless $copying;
5522         print O or die $!;
5523     }
5524     I2->error and die $!;
5525     close O or die $1;
5526     exit 0;
5527 }
5528
5529 sub maybe_apply_patches_dirtily () {
5530     return unless $quilt_mode =~ m/gbp|unapplied/;
5531     print STDERR <<END or die $!;
5532
5533 dgit: Building, or cleaning with rules target, in patches-unapplied tree.
5534 dgit: Have to apply the patches - making the tree dirty.
5535 dgit: (Consider specifying --clean=git and (or) using dgit sbuild.)
5536
5537 END
5538     $patches_applied_dirtily = 01;
5539     $patches_applied_dirtily |= 02 unless stat_exists '.pc';
5540     runcmd qw(dpkg-source --before-build .);
5541 }
5542
5543 sub maybe_unapply_patches_again () {
5544     progress "dgit: Unapplying patches again to tidy up the tree."
5545         if $patches_applied_dirtily;
5546     runcmd qw(dpkg-source --after-build .)
5547         if $patches_applied_dirtily & 01;
5548     rmtree '.pc'
5549         if $patches_applied_dirtily & 02;
5550     $patches_applied_dirtily = 0;
5551 }
5552
5553 #----- other building -----
5554
5555 our $clean_using_builder;
5556 # ^ tree is to be cleaned by dpkg-source's builtin idea that it should
5557 #   clean the tree before building (perhaps invoked indirectly by
5558 #   whatever we are using to run the build), rather than separately
5559 #   and explicitly by us.
5560
5561 sub clean_tree () {
5562     return if $clean_using_builder;
5563     if ($cleanmode eq 'dpkg-source') {
5564         maybe_apply_patches_dirtily();
5565         runcmd_ordryrun_local @dpkgbuildpackage, qw(-T clean);
5566     } elsif ($cleanmode eq 'dpkg-source-d') {
5567         maybe_apply_patches_dirtily();
5568         runcmd_ordryrun_local @dpkgbuildpackage, qw(-d -T clean);
5569     } elsif ($cleanmode eq 'git') {
5570         runcmd_ordryrun_local @git, qw(clean -xdf);
5571     } elsif ($cleanmode eq 'git-ff') {
5572         runcmd_ordryrun_local @git, qw(clean -xdff);
5573     } elsif ($cleanmode eq 'check') {
5574         my $leftovers = cmdoutput @git, qw(clean -xdn);
5575         if (length $leftovers) {
5576             print STDERR $leftovers, "\n" or die $!;
5577             fail "tree contains uncommitted files and --clean=check specified";
5578         }
5579     } elsif ($cleanmode eq 'none') {
5580     } else {
5581         die "$cleanmode ?";
5582     }
5583 }
5584
5585 sub cmd_clean () {
5586     badusage "clean takes no additional arguments" if @ARGV;
5587     notpushing();
5588     clean_tree();
5589     maybe_unapply_patches_again();
5590 }
5591
5592 sub build_prep_early () {
5593     our $build_prep_early_done //= 0;
5594     return if $build_prep_early_done++;
5595     notpushing();
5596     badusage "-p is not allowed when building" if defined $package;
5597     my $clogp = parsechangelog();
5598     $isuite = getfield $clogp, 'Distribution';
5599     $package = getfield $clogp, 'Source';
5600     $version = getfield $clogp, 'Version';
5601     check_not_dirty();
5602 }
5603
5604 sub build_prep () {
5605     build_prep_early();
5606     clean_tree();
5607     build_maybe_quilt_fixup();
5608     if ($rmchanges) {
5609         my $pat = changespat $version;
5610         foreach my $f (glob "$buildproductsdir/$pat") {
5611             if (act_local()) {
5612                 unlink $f or fail "remove old changes file $f: $!";
5613             } else {
5614                 progress "would remove $f";
5615             }
5616         }
5617     }
5618 }
5619
5620 sub changesopts_initial () {
5621     my @opts =@changesopts[1..$#changesopts];
5622 }
5623
5624 sub changesopts_version () {
5625     if (!defined $changes_since_version) {
5626         my @vsns = archive_query('archive_query');
5627         my @quirk = access_quirk();
5628         if ($quirk[0] eq 'backports') {
5629             local $isuite = $quirk[2];
5630             local $csuite;
5631             canonicalise_suite();
5632             push @vsns, archive_query('archive_query');
5633         }
5634         if (@vsns) {
5635             @vsns = map { $_->[0] } @vsns;
5636             @vsns = sort { -version_compare($a, $b) } @vsns;
5637             $changes_since_version = $vsns[0];
5638             progress "changelog will contain changes since $vsns[0]";
5639         } else {
5640             $changes_since_version = '_';
5641             progress "package seems new, not specifying -v<version>";
5642         }
5643     }
5644     if ($changes_since_version ne '_') {
5645         return ("-v$changes_since_version");
5646     } else {
5647         return ();
5648     }
5649 }
5650
5651 sub changesopts () {
5652     return (changesopts_initial(), changesopts_version());
5653 }
5654
5655 sub massage_dbp_args ($;$) {
5656     my ($cmd,$xargs) = @_;
5657     # We need to:
5658     #
5659     #  - if we're going to split the source build out so we can
5660     #    do strange things to it, massage the arguments to dpkg-buildpackage
5661     #    so that the main build doessn't build source (or add an argument
5662     #    to stop it building source by default).
5663     #
5664     #  - add -nc to stop dpkg-source cleaning the source tree,
5665     #    unless we're not doing a split build and want dpkg-source
5666     #    as cleanmode, in which case we can do nothing
5667     #
5668     # return values:
5669     #    0 - source will NOT need to be built separately by caller
5670     #   +1 - source will need to be built separately by caller
5671     #   +2 - source will need to be built separately by caller AND
5672     #        dpkg-buildpackage should not in fact be run at all!
5673     debugcmd '#massaging#', @$cmd if $debuglevel>1;
5674 #print STDERR "MASS0 ",Dumper($cmd, $xargs, $need_split_build_invocation);
5675     if ($cleanmode eq 'dpkg-source' && !$need_split_build_invocation) {
5676         $clean_using_builder = 1;
5677         return 0;
5678     }
5679     # -nc has the side effect of specifying -b if nothing else specified
5680     # and some combinations of -S, -b, et al, are errors, rather than
5681     # later simply overriding earlie.  So we need to:
5682     #  - search the command line for these options
5683     #  - pick the last one
5684     #  - perhaps add our own as a default
5685     #  - perhaps adjust it to the corresponding non-source-building version
5686     my $dmode = '-F';
5687     foreach my $l ($cmd, $xargs) {
5688         next unless $l;
5689         @$l = grep { !(m/^-[SgGFABb]$/s and $dmode=$_) } @$l;
5690     }
5691     push @$cmd, '-nc';
5692 #print STDERR "MASS1 ",Dumper($cmd, $xargs, $dmode);
5693     my $r = 0;
5694     if ($need_split_build_invocation) {
5695         printdebug "massage split $dmode.\n";
5696         $r = $dmode =~ m/[S]/     ? +2 :
5697              $dmode =~ y/gGF/ABb/ ? +1 :
5698              $dmode =~ m/[ABb]/   ?  0 :
5699              die "$dmode ?";
5700     }
5701     printdebug "massage done $r $dmode.\n";
5702     push @$cmd, $dmode;
5703 #print STDERR "MASS2 ",Dumper($cmd, $xargs, $r);
5704     return $r;
5705 }
5706
5707 sub in_parent (&) {
5708     my ($fn) = @_;
5709     my $wasdir = must_getcwd();
5710     changedir "..";
5711     $fn->();
5712     changedir $wasdir;
5713 }
5714
5715 sub postbuild_mergechanges ($) { # must run with CWD=.. (eg in in_parent)
5716     my ($msg_if_onlyone) = @_;
5717     # If there is only one .changes file, fail with $msg_if_onlyone,
5718     # or if that is undef, be a no-op.
5719     # Returns the changes file to report to the user.
5720     my $pat = changespat $version;
5721     my @changesfiles = glob $pat;
5722     @changesfiles = sort {
5723         ($b =~ m/_source\.changes$/ <=> $a =~ m/_source\.changes$/)
5724             or $a cmp $b
5725     } @changesfiles;
5726     my $result;
5727     if (@changesfiles==1) {
5728         fail <<END.$msg_if_onlyone if defined $msg_if_onlyone;
5729 only one changes file from build (@changesfiles)
5730 END
5731         $result = $changesfiles[0];
5732     } elsif (@changesfiles==2) {
5733         my $binchanges = parsecontrol($changesfiles[1], "binary changes file");
5734         foreach my $l (split /\n/, getfield $binchanges, 'Files') {
5735             fail "$l found in binaries changes file $binchanges"
5736                 if $l =~ m/\.dsc$/;
5737         }
5738         runcmd_ordryrun_local @mergechanges, @changesfiles;
5739         my $multichanges = changespat $version,'multi';
5740         if (act_local()) {
5741             stat_exists $multichanges or fail "$multichanges: $!";
5742             foreach my $cf (glob $pat) {
5743                 next if $cf eq $multichanges;
5744                 rename "$cf", "$cf.inmulti" or fail "$cf\{,.inmulti}: $!";
5745             }
5746         }
5747         $result = $multichanges;
5748     } else {
5749         fail "wrong number of different changes files (@changesfiles)";
5750     }
5751     printdone "build successful, results in $result\n" or die $!;
5752 }
5753
5754 sub midbuild_checkchanges () {
5755     my $pat = changespat $version;
5756     return if $rmchanges;
5757     my @unwanted = map { s#^\.\./##; $_; } glob "../$pat";
5758     @unwanted = grep { $_ ne changespat $version,'source' } @unwanted;
5759     fail <<END
5760 changes files other than source matching $pat already present; building would result in ambiguity about the intended results.
5761 Suggest you delete @unwanted.
5762 END
5763         if @unwanted;
5764 }
5765
5766 sub midbuild_checkchanges_vanilla ($) {
5767     my ($wantsrc) = @_;
5768     midbuild_checkchanges() if $wantsrc == 1;
5769 }
5770
5771 sub postbuild_mergechanges_vanilla ($) {
5772     my ($wantsrc) = @_;
5773     if ($wantsrc == 1) {
5774         in_parent {
5775             postbuild_mergechanges(undef);
5776         };
5777     } else {
5778         printdone "build successful\n";
5779     }
5780 }
5781
5782 sub cmd_build {
5783     build_prep_early();
5784     my @dbp = (@dpkgbuildpackage, qw(-us -uc), changesopts_initial(), @ARGV);
5785     my $wantsrc = massage_dbp_args \@dbp;
5786     if ($wantsrc > 0) {
5787         build_source();
5788         midbuild_checkchanges_vanilla $wantsrc;
5789     } else {
5790         build_prep();
5791     }
5792     if ($wantsrc < 2) {
5793         push @dbp, changesopts_version();
5794         maybe_apply_patches_dirtily();
5795         runcmd_ordryrun_local @dbp;
5796     }
5797     maybe_unapply_patches_again();
5798     postbuild_mergechanges_vanilla $wantsrc;
5799 }
5800
5801 sub pre_gbp_build {
5802     $quilt_mode //= 'gbp';
5803 }
5804
5805 sub cmd_gbp_build {
5806     build_prep_early();
5807
5808     # gbp can make .origs out of thin air.  In my tests it does this
5809     # even for a 1.0 format package, with no origs present.  So I
5810     # guess it keys off just the version number.  We don't know
5811     # exactly what .origs ought to exist, but let's assume that we
5812     # should run gbp if: the version has an upstream part and the main
5813     # orig is absent.
5814     my $upstreamversion = upstreamversion $version;
5815     my $origfnpat = srcfn $upstreamversion, '.orig.tar.*';
5816     my $gbp_make_orig = $version =~ m/-/ && !(() = glob "../$origfnpat");
5817
5818     if ($gbp_make_orig) {
5819         clean_tree();
5820         $cleanmode = 'none'; # don't do it again
5821         $need_split_build_invocation = 1;
5822     }
5823
5824     my @dbp = @dpkgbuildpackage;
5825
5826     my $wantsrc = massage_dbp_args \@dbp, \@ARGV;
5827
5828     if (!length $gbp_build[0]) {
5829         if (length executable_on_path('git-buildpackage')) {
5830             $gbp_build[0] = qw(git-buildpackage);
5831         } else {
5832             $gbp_build[0] = 'gbp buildpackage';
5833         }
5834     }
5835     my @cmd = opts_opt_multi_cmd @gbp_build;
5836
5837     push @cmd, (qw(-us -uc --git-no-sign-tags), "--git-builder=@dbp");
5838
5839     if ($gbp_make_orig) {
5840         ensuredir '.git/dgit';
5841         my $ok = '.git/dgit/origs-gen-ok';
5842         unlink $ok or $!==&ENOENT or die $!;
5843         my @origs_cmd = @cmd;
5844         push @origs_cmd, qw(--git-cleaner=true);
5845         push @origs_cmd, "--git-prebuild=touch $ok .git/dgit/no-such-dir/ok";
5846         push @origs_cmd, @ARGV;
5847         if (act_local()) {
5848             debugcmd @origs_cmd;
5849             system @origs_cmd;
5850             do { local $!; stat_exists $ok; }
5851                 or failedcmd @origs_cmd;
5852         } else {
5853             dryrun_report @origs_cmd;
5854         }
5855     }
5856
5857     if ($wantsrc > 0) {
5858         build_source();
5859         midbuild_checkchanges_vanilla $wantsrc;
5860     } else {
5861         if (!$clean_using_builder) {
5862             push @cmd, '--git-cleaner=true';
5863         }
5864         build_prep();
5865     }
5866     maybe_unapply_patches_again();
5867     if ($wantsrc < 2) {
5868         push @cmd, changesopts();
5869         runcmd_ordryrun_local @cmd, @ARGV;
5870     }
5871     postbuild_mergechanges_vanilla $wantsrc;
5872 }
5873 sub cmd_git_build { cmd_gbp_build(); } # compatibility with <= 1.0
5874
5875 sub build_source {
5876     build_prep_early();
5877     my $our_cleanmode = $cleanmode;
5878     if ($need_split_build_invocation) {
5879         # Pretend that clean is being done some other way.  This
5880         # forces us not to try to use dpkg-buildpackage to clean and
5881         # build source all in one go; and instead we run dpkg-source
5882         # (and build_prep() will do the clean since $clean_using_builder
5883         # is false).
5884         $our_cleanmode = 'ELSEWHERE';
5885     }
5886     if ($our_cleanmode =~ m/^dpkg-source/) {
5887         # dpkg-source invocation (below) will clean, so build_prep shouldn't
5888         $clean_using_builder = 1;
5889     }
5890     build_prep();
5891     $sourcechanges = changespat $version,'source';
5892     if (act_local()) {
5893         unlink "../$sourcechanges" or $!==ENOENT
5894             or fail "remove $sourcechanges: $!";
5895     }
5896     $dscfn = dscfn($version);
5897     if ($our_cleanmode eq 'dpkg-source') {
5898         maybe_apply_patches_dirtily();
5899         runcmd_ordryrun_local @dpkgbuildpackage, qw(-us -uc -S),
5900             changesopts();
5901     } elsif ($our_cleanmode eq 'dpkg-source-d') {
5902         maybe_apply_patches_dirtily();
5903         runcmd_ordryrun_local @dpkgbuildpackage, qw(-us -uc -S -d),
5904             changesopts();
5905     } else {
5906         my @cmd = (@dpkgsource, qw(-b --));
5907         if ($split_brain) {
5908             changedir $ud;
5909             runcmd_ordryrun_local @cmd, "work";
5910             my @udfiles = <${package}_*>;
5911             changedir "../../..";
5912             foreach my $f (@udfiles) {
5913                 printdebug "source copy, found $f\n";
5914                 next unless
5915                     $f eq $dscfn or
5916                     ($f =~ m/\.debian\.tar(?:\.\w+)$/ &&
5917                      $f eq srcfn($version, $&));
5918                 printdebug "source copy, found $f - renaming\n";
5919                 rename "$ud/$f", "../$f" or $!==ENOENT
5920                     or fail "put in place new source file ($f): $!";
5921             }
5922         } else {
5923             my $pwd = must_getcwd();
5924             my $leafdir = basename $pwd;
5925             changedir "..";
5926             runcmd_ordryrun_local @cmd, $leafdir;
5927             changedir $pwd;
5928         }
5929         runcmd_ordryrun_local qw(sh -ec),
5930             'exec >$1; shift; exec "$@"','x',
5931             "../$sourcechanges",
5932             @dpkggenchanges, qw(-S), changesopts();
5933     }
5934 }
5935
5936 sub cmd_build_source {
5937     build_prep_early();
5938     badusage "build-source takes no additional arguments" if @ARGV;
5939     build_source();
5940     maybe_unapply_patches_again();
5941     printdone "source built, results in $dscfn and $sourcechanges";
5942 }
5943
5944 sub cmd_sbuild {
5945     build_source();
5946     midbuild_checkchanges();
5947     in_parent {
5948         if (act_local()) {
5949             stat_exists $dscfn or fail "$dscfn (in parent directory): $!";
5950             stat_exists $sourcechanges
5951                 or fail "$sourcechanges (in parent directory): $!";
5952         }
5953         runcmd_ordryrun_local @sbuild, qw(-d), $isuite, @ARGV, $dscfn;
5954     };
5955     maybe_unapply_patches_again();
5956     in_parent {
5957         postbuild_mergechanges(<<END);
5958 perhaps you need to pass -A ?  (sbuild's default is to build only
5959 arch-specific binaries; dgit 1.4 used to override that.)
5960 END
5961     };
5962 }
5963
5964 sub cmd_quilt_fixup {
5965     badusage "incorrect arguments to dgit quilt-fixup" if @ARGV;
5966     build_prep_early();
5967     clean_tree();
5968     build_maybe_quilt_fixup();
5969 }
5970
5971 sub cmd_import_dsc {
5972     my $needsig = 0;
5973
5974     while (@ARGV) {
5975         last unless $ARGV[0] =~ m/^-/;
5976         $_ = shift @ARGV;
5977         last if m/^--?$/;
5978         if (m/^--require-valid-signature$/) {
5979             $needsig = 1;
5980         } else {
5981             badusage "unknown dgit import-dsc sub-option \`$_'";
5982         }
5983     }
5984
5985     badusage "usage: dgit import-dsc .../PATH/TO/.DSC BRANCH" unless @ARGV==2;
5986     my ($dscfn, $dstbranch) = @ARGV;
5987
5988     badusage "dry run makes no sense with import-dsc" unless act_local();
5989
5990     my $force = $dstbranch =~ s/^\+//   ? +1 :
5991                 $dstbranch =~ s/^\.\.// ? -1 :
5992                                            0;
5993     my $info = $force ? " $&" : '';
5994     $info = "$dscfn$info";
5995
5996     my $specbranch = $dstbranch;
5997     $dstbranch = "refs/heads/$dstbranch" unless $dstbranch =~ m#^refs/#;
5998     $dstbranch = cmdoutput @git, qw(check-ref-format --normalize), $dstbranch;
5999
6000     my @symcmd = (@git, qw(symbolic-ref -q HEAD));
6001     my $chead = cmdoutput_errok @symcmd;
6002     defined $chead or $?==256 or failedcmd @symcmd;
6003
6004     fail "$dstbranch is checked out - will not update it"
6005         if defined $chead and $chead eq $dstbranch;
6006
6007     my $oldhash = git_get_ref $dstbranch;
6008
6009     open D, "<", $dscfn or fail "open import .dsc ($dscfn): $!";
6010     $dscdata = do { local $/ = undef; <D>; };
6011     D->error and fail "read $dscfn: $!";
6012     close C;
6013
6014     # we don't normally need this so import it here
6015     use Dpkg::Source::Package;
6016     my $dp = new Dpkg::Source::Package filename => $dscfn,
6017         require_valid_signature => $needsig;
6018     {
6019         local $SIG{__WARN__} = sub {
6020             print STDERR $_[0];
6021             return unless $needsig;
6022             fail "import-dsc signature check failed";
6023         };
6024         if (!$dp->is_signed()) {
6025             warn "$us: warning: importing unsigned .dsc\n";
6026         } else {
6027             my $r = $dp->check_signature();
6028             die "->check_signature => $r" if $needsig && $r;
6029         }
6030     }
6031
6032     parse_dscdata();
6033
6034     $package = getfield $dsc, 'Source';
6035
6036     parse_dsc_field($dsc, "Dgit metadata in .dsc")
6037         unless forceing [qw(import-dsc-with-dgit-field)];
6038
6039     if (defined $dsc_hash) {
6040         progress "dgit: import-dsc of .dsc with Dgit field, using git hash";
6041         resolve_dsc_field_commit undef, undef;
6042     }
6043     if (defined $dsc_hash) {
6044         my @cmd = (qw(sh -ec),
6045                    "echo $dsc_hash | git cat-file --batch-check");
6046         my $objgot = cmdoutput @cmd;
6047         if ($objgot =~ m#^\w+ missing\b#) {
6048             fail <<END
6049 .dsc contains Dgit field referring to object $dsc_hash
6050 Your git tree does not have that object.  Try `git fetch' from a
6051 plausible server (browse.dgit.d.o? alioth?), and try the import-dsc again.
6052 END
6053         }
6054         if ($oldhash && !is_fast_fwd $oldhash, $dsc_hash) {
6055             if ($force > 0) {
6056                 progress "Not fast forward, forced update.";
6057             } else {
6058                 fail "Not fast forward to $dsc_hash";
6059             }
6060         }
6061         @cmd = (@git, qw(update-ref -m), "dgit import-dsc (Dgit): $info",
6062                 $dstbranch, $dsc_hash);
6063         runcmd @cmd;
6064         progress "dgit: import-dsc updated git ref $dstbranch";
6065         return 0;
6066     }
6067
6068     fail <<END
6069 Branch $dstbranch already exists
6070 Specify ..$specbranch for a pseudo-merge, binding in existing history
6071 Specify  +$specbranch to overwrite, discarding existing history
6072 END
6073         if $oldhash && !$force;
6074
6075     my @dfi = dsc_files_info();
6076     foreach my $fi (@dfi) {
6077         my $f = $fi->{Filename};
6078         my $here = "../$f";
6079         next if lstat $here;
6080         fail "stat $here: $!" unless $! == ENOENT;
6081         my $there = $dscfn;
6082         if ($dscfn =~ m#^(?:\./+)?\.\./+#) {
6083             $there = $';
6084         } elsif ($dscfn =~ m#^/#) {
6085             $there = $dscfn;
6086         } else {
6087             fail "cannot import $dscfn which seems to be inside working tree!";
6088         }
6089         $there =~ s#/+[^/]+$## or
6090             fail "cannot import $dscfn which seems to not have a basename";
6091         $there .= "/$f";
6092         symlink $there, $here or fail "symlink $there to $here: $!";
6093         progress "made symlink $here -> $there";
6094 #       print STDERR Dumper($fi);
6095     }
6096     my @mergeinputs = generate_commits_from_dsc();
6097     die unless @mergeinputs == 1;
6098
6099     my $newhash = $mergeinputs[0]{Commit};
6100
6101     if ($oldhash) {
6102         if ($force > 0) {
6103             progress "Import, forced update - synthetic orphan git history.";
6104         } elsif ($force < 0) {
6105             progress "Import, merging.";
6106             my $tree = cmdoutput @git, qw(rev-parse), "$newhash:";
6107             my $version = getfield $dsc, 'Version';
6108             my $clogp = commit_getclogp $newhash;
6109             my $authline = clogp_authline $clogp;
6110             $newhash = make_commit_text <<END;
6111 tree $tree
6112 parent $newhash
6113 parent $oldhash
6114 author $authline
6115 committer $authline
6116
6117 Merge $package ($version) import into $dstbranch
6118 END
6119         } else {
6120             die; # caught earlier
6121         }
6122     }
6123
6124     my @cmd = (@git, qw(update-ref -m), "dgit import-dsc: $info",
6125                $dstbranch, $newhash);
6126     runcmd @cmd;
6127     progress "dgit: import-dsc results are in in git ref $dstbranch";
6128 }
6129
6130 sub cmd_archive_api_query {
6131     badusage "need only 1 subpath argument" unless @ARGV==1;
6132     my ($subpath) = @ARGV;
6133     my @cmd = archive_api_query_cmd($subpath);
6134     push @cmd, qw(-f);
6135     debugcmd ">",@cmd;
6136     exec @cmd or fail "exec curl: $!\n";
6137 }
6138
6139 sub cmd_clone_dgit_repos_server {
6140     badusage "need destination argument" unless @ARGV==1;
6141     my ($destdir) = @ARGV;
6142     $package = '_dgit-repos-server';
6143     my @cmd = (@git, qw(clone), access_giturl(), $destdir);
6144     debugcmd ">",@cmd;
6145     exec @cmd or fail "exec git clone: $!\n";
6146 }
6147
6148 sub cmd_setup_mergechangelogs {
6149     badusage "no arguments allowed to dgit setup-mergechangelogs" if @ARGV;
6150     setup_mergechangelogs(1);
6151 }
6152
6153 sub cmd_setup_useremail {
6154     badusage "no arguments allowed to dgit setup-mergechangelogs" if @ARGV;
6155     setup_useremail(1);
6156 }
6157
6158 sub cmd_setup_new_tree {
6159     badusage "no arguments allowed to dgit setup-tree" if @ARGV;
6160     setup_new_tree();
6161 }
6162
6163 #---------- argument parsing and main program ----------
6164
6165 sub cmd_version {
6166     print "dgit version $our_version\n" or die $!;
6167     exit 0;
6168 }
6169
6170 our (%valopts_long, %valopts_short);
6171 our @rvalopts;
6172
6173 sub defvalopt ($$$$) {
6174     my ($long,$short,$val_re,$how) = @_;
6175     my $oi = { Long => $long, Short => $short, Re => $val_re, How => $how };
6176     $valopts_long{$long} = $oi;
6177     $valopts_short{$short} = $oi;
6178     # $how subref should:
6179     #   do whatever assignemnt or thing it likes with $_[0]
6180     #   if the option should not be passed on to remote, @rvalopts=()
6181     # or $how can be a scalar ref, meaning simply assign the value
6182 }
6183
6184 defvalopt '--since-version', '-v', '[^_]+|_', \$changes_since_version;
6185 defvalopt '--distro',        '-d', '.+',      \$idistro;
6186 defvalopt '',                '-k', '.+',      \$keyid;
6187 defvalopt '--existing-package','', '.*',      \$existing_package;
6188 defvalopt '--build-products-dir','','.*',     \$buildproductsdir;
6189 defvalopt '--clean',       '', $cleanmode_re, \$cleanmode;
6190 defvalopt '--package',   '-p',   $package_re, \$package;
6191 defvalopt '--quilt',     '', $quilt_modes_re, \$quilt_mode;
6192
6193 defvalopt '', '-C', '.+', sub {
6194     ($changesfile) = (@_);
6195     if ($changesfile =~ s#^(.*)/##) {
6196         $buildproductsdir = $1;
6197     }
6198 };
6199
6200 defvalopt '--initiator-tempdir','','.*', sub {
6201     ($initiator_tempdir) = (@_);
6202     $initiator_tempdir =~ m#^/# or
6203         badusage "--initiator-tempdir must be used specify an".
6204         " absolute, not relative, directory."
6205 };
6206
6207 sub parseopts () {
6208     my $om;
6209
6210     if (defined $ENV{'DGIT_SSH'}) {
6211         @ssh = string_to_ssh $ENV{'DGIT_SSH'};
6212     } elsif (defined $ENV{'GIT_SSH'}) {
6213         @ssh = ($ENV{'GIT_SSH'});
6214     }
6215
6216     my $oi;
6217     my $val;
6218     my $valopt = sub {
6219         my ($what) = @_;
6220         @rvalopts = ($_);
6221         if (!defined $val) {
6222             badusage "$what needs a value" unless @ARGV;
6223             $val = shift @ARGV;
6224             push @rvalopts, $val;
6225         }
6226         badusage "bad value \`$val' for $what" unless
6227             $val =~ m/^$oi->{Re}$(?!\n)/s;
6228         my $how = $oi->{How};
6229         if (ref($how) eq 'SCALAR') {
6230             $$how = $val;
6231         } else {
6232             $how->($val);
6233         }
6234         push @ropts, @rvalopts;
6235     };
6236
6237     while (@ARGV) {
6238         last unless $ARGV[0] =~ m/^-/;
6239         $_ = shift @ARGV;
6240         last if m/^--?$/;
6241         if (m/^--/) {
6242             if (m/^--dry-run$/) {
6243                 push @ropts, $_;
6244                 $dryrun_level=2;
6245             } elsif (m/^--damp-run$/) {
6246                 push @ropts, $_;
6247                 $dryrun_level=1;
6248             } elsif (m/^--no-sign$/) {
6249                 push @ropts, $_;
6250                 $sign=0;
6251             } elsif (m/^--help$/) {
6252                 cmd_help();
6253             } elsif (m/^--version$/) {
6254                 cmd_version();
6255             } elsif (m/^--new$/) {
6256                 push @ropts, $_;
6257                 $new_package=1;
6258             } elsif (m/^--([-0-9a-z]+)=(.+)/s &&
6259                      ($om = $opts_opt_map{$1}) &&
6260                      length $om->[0]) {
6261                 push @ropts, $_;
6262                 $om->[0] = $2;
6263             } elsif (m/^--([-0-9a-z]+):(.*)/s &&
6264                      !$opts_opt_cmdonly{$1} &&
6265                      ($om = $opts_opt_map{$1})) {
6266                 push @ropts, $_;
6267                 push @$om, $2;
6268             } elsif (m/^--(gbp|dpm)$/s) {
6269                 push @ropts, "--quilt=$1";
6270                 $quilt_mode = $1;
6271             } elsif (m/^--ignore-dirty$/s) {
6272                 push @ropts, $_;
6273                 $ignoredirty = 1;
6274             } elsif (m/^--no-quilt-fixup$/s) {
6275                 push @ropts, $_;
6276                 $quilt_mode = 'nocheck';
6277             } elsif (m/^--no-rm-on-error$/s) {
6278                 push @ropts, $_;
6279                 $rmonerror = 0;
6280             } elsif (m/^--no-chase-dsc-distro$/s) {
6281                 push @ropts, $_;
6282                 $chase_dsc_distro = 0;
6283             } elsif (m/^--overwrite$/s) {
6284                 push @ropts, $_;
6285                 $overwrite_version = '';
6286             } elsif (m/^--overwrite=(.+)$/s) {
6287                 push @ropts, $_;
6288                 $overwrite_version = $1;
6289             } elsif (m/^--dep14tag$/s) {
6290                 push @ropts, $_;
6291                 $dodep14tag= 'want';
6292             } elsif (m/^--no-dep14tag$/s) {
6293                 push @ropts, $_;
6294                 $dodep14tag= 'no';
6295             } elsif (m/^--always-dep14tag$/s) {
6296                 push @ropts, $_;
6297                 $dodep14tag= 'always';
6298             } elsif (m/^--delayed=(\d+)$/s) {
6299                 push @ropts, $_;
6300                 push @dput, $_;
6301             } elsif (m/^--dgit-view-save=(.+)$/s) {
6302                 push @ropts, $_;
6303                 $split_brain_save = $1;
6304                 $split_brain_save =~ s#^(?!refs/)#refs/heads/#;
6305             } elsif (m/^--(no-)?rm-old-changes$/s) {
6306                 push @ropts, $_;
6307                 $rmchanges = !$1;
6308             } elsif (m/^--deliberately-($deliberately_re)$/s) {
6309                 push @ropts, $_;
6310                 push @deliberatelies, $&;
6311             } elsif (m/^--force-(.*)/ && defined $forceopts{$1}) {
6312                 push @ropts, $&;
6313                 $forceopts{$1} = 1;
6314                 $_='';
6315             } elsif (m/^--force-/) {
6316                 print STDERR
6317                     "$us: warning: ignoring unknown force option $_\n";
6318                 $_='';
6319             } elsif (m/^--dgit-tag-format=(old|new)$/s) {
6320                 # undocumented, for testing
6321                 push @ropts, $_;
6322                 $tagformat_want = [ $1, 'command line', 1 ];
6323                 # 1 menas overrides distro configuration
6324             } elsif (m/^--always-split-source-build$/s) {
6325                 # undocumented, for testing
6326                 push @ropts, $_;
6327                 $need_split_build_invocation = 1;
6328             } elsif (m/^--config-lookup-explode=(.+)$/s) {
6329                 # undocumented, for testing
6330                 push @ropts, $_;
6331                 $gitcfgs{cmdline}{$1} = 'CONFIG-LOOKUP-EXPLODE';
6332                 # ^ it's supposed to be an array ref
6333             } elsif (m/^(--[-0-9a-z]+)(=|$)/ && ($oi = $valopts_long{$1})) {
6334                 $val = $2 ? $' : undef; #';
6335                 $valopt->($oi->{Long});
6336             } else {
6337                 badusage "unknown long option \`$_'";
6338             }
6339         } else {
6340             while (m/^-./s) {
6341                 if (s/^-n/-/) {
6342                     push @ropts, $&;
6343                     $dryrun_level=2;
6344                 } elsif (s/^-L/-/) {
6345                     push @ropts, $&;
6346                     $dryrun_level=1;
6347                 } elsif (s/^-h/-/) {
6348                     cmd_help();
6349                 } elsif (s/^-D/-/) {
6350                     push @ropts, $&;
6351                     $debuglevel++;
6352                     enabledebug();
6353                 } elsif (s/^-N/-/) {
6354                     push @ropts, $&;
6355                     $new_package=1;
6356                 } elsif (m/^-m/) {
6357                     push @ropts, $&;
6358                     push @changesopts, $_;
6359                     $_ = '';
6360                 } elsif (s/^-wn$//s) {
6361                     push @ropts, $&;
6362                     $cleanmode = 'none';
6363                 } elsif (s/^-wg$//s) {
6364                     push @ropts, $&;
6365                     $cleanmode = 'git';
6366                 } elsif (s/^-wgf$//s) {
6367                     push @ropts, $&;
6368                     $cleanmode = 'git-ff';
6369                 } elsif (s/^-wd$//s) {
6370                     push @ropts, $&;
6371                     $cleanmode = 'dpkg-source';
6372                 } elsif (s/^-wdd$//s) {
6373                     push @ropts, $&;
6374                     $cleanmode = 'dpkg-source-d';
6375                 } elsif (s/^-wc$//s) {
6376                     push @ropts, $&;
6377                     $cleanmode = 'check';
6378                 } elsif (s/^-c([^=]*)\=(.*)$//s) {
6379                     push @git, '-c', $&;
6380                     $gitcfgs{cmdline}{$1} = [ $2 ];
6381                 } elsif (s/^-c([^=]+)$//s) {
6382                     push @git, '-c', $&;
6383                     $gitcfgs{cmdline}{$1} = [ 'true' ];
6384                 } elsif (m/^-[a-zA-Z]/ && ($oi = $valopts_short{$&})) {
6385                     $val = $'; #';
6386                     $val = undef unless length $val;
6387                     $valopt->($oi->{Short});
6388                     $_ = '';
6389                 } else {
6390                     badusage "unknown short option \`$_'";
6391                 }
6392             }
6393         }
6394     }
6395 }
6396
6397 sub check_env_sanity () {
6398     my $blocked = new POSIX::SigSet;
6399     sigprocmask SIG_UNBLOCK, $blocked, $blocked or die $!;
6400
6401     eval {
6402         foreach my $name (qw(PIPE CHLD)) {
6403             my $signame = "SIG$name";
6404             my $signum = eval "POSIX::$signame" // die;
6405             ($SIG{$name} // 'DEFAULT') eq 'DEFAULT' or
6406                 die "$signame is set to something other than SIG_DFL\n";
6407             $blocked->ismember($signum) and
6408                 die "$signame is blocked\n";
6409         }
6410     };
6411     return unless $@;
6412     chomp $@;
6413     fail <<END;
6414 On entry to dgit, $@
6415 This is a bug produced by something in in your execution environment.
6416 Giving up.
6417 END
6418 }
6419
6420
6421 sub parseopts_late_defaults () {
6422     foreach my $k (keys %opts_opt_map) {
6423         my $om = $opts_opt_map{$k};
6424
6425         my $v = access_cfg("cmd-$k", 'RETURN-UNDEF');
6426         if (defined $v) {
6427             badcfg "cannot set command for $k"
6428                 unless length $om->[0];
6429             $om->[0] = $v;
6430         }
6431
6432         foreach my $c (access_cfg_cfgs("opts-$k")) {
6433             my @vl =
6434                 map { $_ ? @$_ : () }
6435                 map { $gitcfgs{$_}{$c} }
6436                 reverse @gitcfgsources;
6437             printdebug "CL $c ", (join " ", map { shellquote } @vl),
6438                 "\n" if $debuglevel >= 4;
6439             next unless @vl;
6440             badcfg "cannot configure options for $k"
6441                 if $opts_opt_cmdonly{$k};
6442             my $insertpos = $opts_cfg_insertpos{$k};
6443             @$om = ( @$om[0..$insertpos-1],
6444                      @vl,
6445                      @$om[$insertpos..$#$om] );
6446         }
6447     }
6448
6449     if (!defined $rmchanges) {
6450         local $access_forpush;
6451         $rmchanges = access_cfg_bool(0, 'rm-old-changes');
6452     }
6453
6454     if (!defined $quilt_mode) {
6455         local $access_forpush;
6456         $quilt_mode = cfg('dgit.force.quilt-mode', 'RETURN-UNDEF')
6457             // access_cfg('quilt-mode', 'RETURN-UNDEF')
6458             // 'linear';
6459         $quilt_mode =~ m/^($quilt_modes_re)$/
6460             or badcfg "unknown quilt-mode \`$quilt_mode'";
6461         $quilt_mode = $1;
6462     }
6463
6464     if (!defined $dodep14tag) {
6465         local $access_forpush;
6466         $dodep14tag = access_cfg('dep14tag', 'RETURN-UNDEF') // 'want';
6467         $dodep14tag =~ m/^($dodep14tag_re)$/
6468             or badcfg "unknown dep14tag setting \`$dodep14tag'";
6469         $dodep14tag = $1;
6470     }
6471
6472     $need_split_build_invocation ||= quiltmode_splitbrain();
6473
6474     if (!defined $cleanmode) {
6475         local $access_forpush;
6476         $cleanmode = access_cfg('clean-mode', 'RETURN-UNDEF');
6477         $cleanmode //= 'dpkg-source';
6478
6479         badcfg "unknown clean-mode \`$cleanmode'" unless
6480             $cleanmode =~ m/^($cleanmode_re)$(?!\n)/s;
6481     }
6482 }
6483
6484 if ($ENV{$fakeeditorenv}) {
6485     git_slurp_config();
6486     quilt_fixup_editor();
6487 }
6488
6489 parseopts();
6490 check_env_sanity();
6491 git_slurp_config();
6492
6493 print STDERR "DRY RUN ONLY\n" if $dryrun_level > 1;
6494 print STDERR "DAMP RUN - WILL MAKE LOCAL (UNSIGNED) CHANGES\n"
6495     if $dryrun_level == 1;
6496 if (!@ARGV) {
6497     print STDERR $helpmsg or die $!;
6498     exit 8;
6499 }
6500 my $cmd = shift @ARGV;
6501 $cmd =~ y/-/_/;
6502
6503 my $pre_fn = ${*::}{"pre_$cmd"};
6504 $pre_fn->() if $pre_fn;
6505
6506 my $fn = ${*::}{"cmd_$cmd"};
6507 $fn or badusage "unknown operation $cmd";
6508 $fn->();