dgit

   1 #!/usr/bin/perl -w
   2 # dgit
   3 # Integration between git and Debian-style archives
   4 #
   5 # Copyright (C)2013-2016 Ian Jackson
   6 #
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 use strict;
  21
  22 use Debian::Dgit qw(:DEFAULT :playground);
  23 setup_sigwarn();
  24
  25 use IO::Handle;
  26 use Data::Dumper;
  27 use LWP::UserAgent;
  28 use Dpkg::Control::Hash;
  29 use File::Path;
  30 use File::Temp qw(tempdir);
  31 use File::Basename;
  32 use Dpkg::Version;
  33 use POSIX;
  34 use IPC::Open2;
  35 use Digest::SHA;
  36 use Digest::MD5;
  37 use List::MoreUtils qw(pairwise);
  38 use Text::Glob qw(match_glob);
  39 use Fcntl qw(:DEFAULT :flock);
  40 use Carp;
  41
  42 use Debian::Dgit;
  43
  44 our $our_version = 'UNRELEASED'; ###substituted###
  45 our $absurdity = undef; ###substituted###
  46
  47 our @rpushprotovsn_support = qw(4 3 2); # 4 is new tag format
  48 our $protovsn;
  49
  50 our $cmd;
  51 our $subcommand;
  52 our $isuite;
  53 our $idistro;
  54 our $package;
  55 our @ropts;
  56
  57 our $sign = 1;
  58 our $dryrun_level = 0;
  59 our $changesfile;
  60 our $buildproductsdir = '..';
  61 our $new_package = 0;
  62 our $ignoredirty = 0;
  63 our $rmonerror = 1;
  64 our @deliberatelies;
  65 our %previously;
  66 our $existing_package = 'dpkg';
  67 our $cleanmode;
  68 our $changes_since_version;
  69 our $rmchanges;
  70 our $overwrite_version; # undef: not specified; '': check changelog
  71 our $quilt_mode;
  72 our $quilt_modes_re = 'linear|smash|auto|nofix|nocheck|gbp|dpm|unapplied';
  73 our $dodep14tag;
  74 our $split_brain_save;
  75 our $we_are_responder;
  76 our $we_are_initiator;
  77 our $initiator_tempdir;
  78 our $patches_applied_dirtily = 00;
  79 our $tagformat_want;
  80 our $tagformat;
  81 our $tagformatfn;
  82 our $chase_dsc_distro=1;
  83
  84 our %forceopts = map { $_=>0 }
  85     qw(unrepresentable unsupported-source-format
  86        dsc-changes-mismatch changes-origs-exactly
  87        import-gitapply-absurd
  88        import-gitapply-no-absurd
  89        import-dsc-with-dgit-field);
  90
  91 our %format_ok = map { $_=>1 } ("1.0","3.0 (native)","3.0 (quilt)");
  92
  93 our $suite_re = '[-+.0-9a-z]+';
  94 our $cleanmode_re = 'dpkg-source(?:-d)?|git|git-ff|check|none';
  95 our $orig_f_comp_re = 'orig(?:-[-0-9a-z]+)?';
  96 our $orig_f_sig_re = '\\.(?:asc|gpg|pgp)';
  97 our $orig_f_tail_re = "$orig_f_comp_re\\.tar(?:\\.\\w+)?(?:$orig_f_sig_re)?";
  98
  99 our $git_authline_re = '^([^<>]+) \<(\S+)\> (\d+ [-+]\d+)$';
 100 our $splitbraincache = 'dgit-intern/quilt-cache';
 101 our $rewritemap = 'dgit-rewrite/map';
 102
 103 our (@git) = qw(git);
 104 our (@dget) = qw(dget);
 105 our (@curl) = (qw(curl --proto-redir), '-all,http,https', qw(-L));
 106 our (@dput) = qw(dput);
 107 our (@debsign) = qw(debsign);
 108 our (@gpg) = qw(gpg);
 109 our (@sbuild) = qw(sbuild);
 110 our (@ssh) = 'ssh';
 111 our (@dgit) = qw(dgit);
 112 our (@aptget) = qw(apt-get);
 113 our (@aptcache) = qw(apt-cache);
 114 our (@dpkgbuildpackage) = qw(dpkg-buildpackage -i\.git/ -I.git);
 115 our (@dpkgsource) = qw(dpkg-source -i\.git/ -I.git);
 116 our (@dpkggenchanges) = qw(dpkg-genchanges);
 117 our (@mergechanges) = qw(mergechanges -f);
 118 our (@gbp_build) = ('');
 119 our (@gbp_pq) = ('gbp pq');
 120 our (@changesopts) = ('');
 121
 122 our %opts_opt_map = ('dget' => \@dget, # accept for compatibility
 123                      'curl' => \@curl,
 124                      'dput' => \@dput,
 125                      'debsign' => \@debsign,
 126                      'gpg' => \@gpg,
 127                      'sbuild' => \@sbuild,
 128                      'ssh' => \@ssh,
 129                      'dgit' => \@dgit,
 130                      'git' => \@git,
 131                      'apt-get' => \@aptget,
 132                      'apt-cache' => \@aptcache,
 133                      'dpkg-source' => \@dpkgsource,
 134                      'dpkg-buildpackage' => \@dpkgbuildpackage,
 135                      'dpkg-genchanges' => \@dpkggenchanges,
 136                      'gbp-build' => \@gbp_build,
 137                      'gbp-pq' => \@gbp_pq,
 138                      'ch' => \@changesopts,
 139                      'mergechanges' => \@mergechanges);
 140
 141 our %opts_opt_cmdonly = ('gpg' => 1, 'git' => 1);
 142 our %opts_cfg_insertpos = map {
 143     $_,
 144     scalar @{ $opts_opt_map{$_} }
 145 } keys %opts_opt_map;
 146
 147 sub parseopts_late_defaults();
 148 sub setup_gitattrs(;$);
 149 sub check_gitattrs($$);
 150
 151 our $keyid;
 152
 153 autoflush STDOUT 1;
 154
 155 our $supplementary_message = '';
 156 our $need_split_build_invocation = 0;
 157 our $split_brain = 0;
 158
 159 END {
 160     local ($@, $?);
 161     return unless forkcheck_mainprocess();
 162     print STDERR "! $_\n" foreach $supplementary_message =~ m/^.+$/mg;
 163 }
 164
 165 our $remotename = 'dgit';
 166 our @ourdscfield = qw(Dgit Vcs-Dgit-Master);
 167 our $csuite;
 168 our $instead_distro;
 169
 170 if (!defined $absurdity) {
 171     $absurdity = $0;
 172     $absurdity =~ s{/[^/]+$}{/absurd} or die;
 173 }
 174
 175 sub debiantag ($$) {
 176     my ($v,$distro) = @_;
 177     return $tagformatfn->($v, $distro);
 178 }
 179
 180 sub debiantag_maintview ($$) {
 181     my ($v,$distro) = @_;
 182     return "$distro/".dep14_version_mangle $v;
 183 }
 184
 185 sub madformat ($) { $_[0] eq '3.0 (quilt)' }
 186
 187 sub lbranch () { return "$branchprefix/$csuite"; }
 188 my $lbranch_re = '^refs/heads/'.$branchprefix.'/([^/.]+)$';
 189 sub lref () { return "refs/heads/".lbranch(); }
 190 sub lrref () { return "refs/remotes/$remotename/".server_branch($csuite); }
 191 sub rrref () { return server_ref($csuite); }
 192
 193 sub stripepoch ($) {
 194     my ($vsn) = @_;
 195     $vsn =~ s/^\d+\://;
 196     return $vsn;
 197 }
 198
 199 sub srcfn ($$) {
 200     my ($vsn,$sfx) = @_;
 201     return "${package}_".(stripepoch $vsn).$sfx
 202 }
 203
 204 sub dscfn ($) {
 205     my ($vsn) = @_;
 206     return srcfn($vsn,".dsc");
 207 }
 208
 209 sub changespat ($;$) {
 210     my ($vsn, $arch) = @_;
 211     return "${package}_".(stripepoch $vsn)."_".($arch//'*').".changes";
 212 }
 213
 214 sub upstreamversion ($) {
 215     my ($vsn) = @_;
 216     $vsn =~ s/-[^-]+$//;
 217     return $vsn;
 218 }
 219
 220 our $us = 'dgit';
 221 initdebug('');
 222
 223 our @end;
 224 END {
 225     local ($?);
 226     return unless forkcheck_mainprocess();
 227     foreach my $f (@end) {
 228         eval { $f->(); };
 229         print STDERR "$us: cleanup: $@" if length $@;
 230     }
 231 };
 232
 233 sub badcfg { print STDERR "$us: invalid configuration: @_\n"; exit 12; }
 234
 235 sub forceable_fail ($$) {
 236     my ($forceoptsl, $msg) = @_;
 237     fail $msg unless grep { $forceopts{$_} } @$forceoptsl;
 238     print STDERR "warning: overriding problem due to --force:\n". $msg;
 239 }
 240
 241 sub forceing ($) {
 242     my ($forceoptsl) = @_;
 243     my @got = grep { $forceopts{$_} } @$forceoptsl;
 244     return 0 unless @got;
 245     print STDERR
 246  "warning: skipping checks or functionality due to --force-$got[0]\n";
 247 }
 248
 249 sub no_such_package () {
 250     print STDERR "$us: package $package does not exist in suite $isuite\n";
 251     exit 4;
 252 }
 253
 254 sub deliberately ($) {
 255     my ($enquiry) = @_;
 256     return !!grep { $_ eq "--deliberately-$enquiry" } @deliberatelies;
 257 }
 258
 259 sub deliberately_not_fast_forward () {
 260     foreach (qw(not-fast-forward fresh-repo)) {
 261         return 1 if deliberately($_) || deliberately("TEST-dgit-only-$_");
 262     }
 263 }
 264
 265 sub quiltmode_splitbrain () {
 266     $quilt_mode =~ m/gbp|dpm|unapplied/;
 267 }
 268
 269 sub opts_opt_multi_cmd {
 270     my @cmd;
 271     push @cmd, split /\s+/, shift @_;
 272     push @cmd, @_;
 273     @cmd;
 274 }
 275
 276 sub gbp_pq {
 277     return opts_opt_multi_cmd @gbp_pq;
 278 }
 279
 280 #---------- remote protocol support, common ----------
 281
 282 # remote push initiator/responder protocol:
 283 #  $ dgit remote-push-build-host <n-rargs> <rargs>... <push-args>...
 284 #  where <rargs> is <push-host-dir> <supported-proto-vsn>,... ...
 285 #  < dgit-remote-push-ready <actual-proto-vsn>
 286 #
 287 # occasionally:
 288 #
 289 #  > progress NBYTES
 290 #  [NBYTES message]
 291 #
 292 #  > supplementary-message NBYTES          # $protovsn >= 3
 293 #  [NBYTES message]
 294 #
 295 # main sequence:
 296 #
 297 #  > file parsed-changelog
 298 #  [indicates that output of dpkg-parsechangelog follows]
 299 #  > data-block NBYTES
 300 #  > [NBYTES bytes of data (no newline)]
 301 #  [maybe some more blocks]
 302 #  > data-end
 303 #
 304 #  > file dsc
 305 #  [etc]
 306 #
 307 #  > file changes
 308 #  [etc]
 309 #
 310 #  > param head DGIT-VIEW-HEAD
 311 #  > param csuite SUITE
 312 #  > param tagformat old|new
 313 #  > param maint-view MAINT-VIEW-HEAD
 314 #
 315 #  > param buildinfo-filename P_V_X.buildinfo   # zero or more times
 316 #  > file buildinfo                             # for buildinfos to sign
 317 #
 318 #  > previously REFNAME=OBJNAME       # if --deliberately-not-fast-forward
 319 #                                     # goes into tag, for replay prevention
 320 #
 321 #  > want signed-tag
 322 #  [indicates that signed tag is wanted]
 323 #  < data-block NBYTES
 324 #  < [NBYTES bytes of data (no newline)]
 325 #  [maybe some more blocks]
 326 #  < data-end
 327 #  < files-end
 328 #
 329 #  > want signed-dsc-changes
 330 #  < data-block NBYTES    [transfer of signed dsc]
 331 #  [etc]
 332 #  < data-block NBYTES    [transfer of signed changes]
 333 #  [etc]
 334 #  < data-block NBYTES    [transfer of each signed buildinfo
 335 #  [etc]                   same number and order as "file buildinfo"]
 336 #  ...
 337 #  < files-end
 338 #
 339 #  > complete
 340
 341 our $i_child_pid;
 342
 343 sub i_child_report () {
 344     # Sees if our child has died, and reap it if so.  Returns a string
 345     # describing how it died if it failed, or undef otherwise.
 346     return undef unless $i_child_pid;
 347     my $got = waitpid $i_child_pid, WNOHANG;
 348     return undef if $got <= 0;
 349     die unless $got == $i_child_pid;
 350     $i_child_pid = undef;
 351     return undef unless $?;
 352     return "build host child ".waitstatusmsg();
 353 }
 354
 355 sub badproto ($$) {
 356     my ($fh, $m) = @_;
 357     fail "connection lost: $!" if $fh->error;
 358     fail "protocol violation; $m not expected";
 359 }
 360
 361 sub badproto_badread ($$) {
 362     my ($fh, $wh) = @_;
 363     fail "connection lost: $!" if $!;
 364     my $report = i_child_report();
 365     fail $report if defined $report;
 366     badproto $fh, "eof (reading $wh)";
 367 }
 368
 369 sub protocol_expect (&$) {
 370     my ($match, $fh) = @_;
 371     local $_;
 372     $_ = <$fh>;
 373     defined && chomp or badproto_badread $fh, "protocol message";
 374     if (wantarray) {
 375         my @r = &$match;
 376         return @r if @r;
 377     } else {
 378         my $r = &$match;
 379         return $r if $r;
 380     }
 381     badproto $fh, "\`$_'";
 382 }
 383
 384 sub protocol_send_file ($$) {
 385     my ($fh, $ourfn) = @_;
 386     open PF, "<", $ourfn or die "$ourfn: $!";
 387     for (;;) {
 388         my $d;
 389         my $got = read PF, $d, 65536;
 390         die "$ourfn: $!" unless defined $got;
 391         last if !$got;
 392         print $fh "data-block ".length($d)."\n" or die $!;
 393         print $fh $d or die $!;
 394     }
 395     PF->error and die "$ourfn $!";
 396     print $fh "data-end\n" or die $!;
 397     close PF;
 398 }
 399
 400 sub protocol_read_bytes ($$) {
 401     my ($fh, $nbytes) = @_;
 402     $nbytes =~ m/^[1-9]\d{0,5}$|^0$/ or badproto \*RO, "bad byte count";
 403     my $d;
 404     my $got = read $fh, $d, $nbytes;
 405     $got==$nbytes or badproto_badread $fh, "data block";
 406     return $d;
 407 }
 408
 409 sub protocol_receive_file ($$) {
 410     my ($fh, $ourfn) = @_;
 411     printdebug "() $ourfn\n";
 412     open PF, ">", $ourfn or die "$ourfn: $!";
 413     for (;;) {
 414         my ($y,$l) = protocol_expect {
 415             m/^data-block (.*)$/ ? (1,$1) :
 416             m/^data-end$/ ? (0,) :
 417             ();
 418         } $fh;
 419         last unless $y;
 420         my $d = protocol_read_bytes $fh, $l;
 421         print PF $d or die $!;
 422     }
 423     close PF or die $!;
 424 }
 425
 426 #---------- remote protocol support, responder ----------
 427
 428 sub responder_send_command ($) {
 429     my ($command) = @_;
 430     return unless $we_are_responder;
 431     # called even without $we_are_responder
 432     printdebug ">> $command\n";
 433     print PO $command, "\n" or die $!;
 434 }
 435
 436 sub responder_send_file ($$) {
 437     my ($keyword, $ourfn) = @_;
 438     return unless $we_are_responder;
 439     printdebug "]] $keyword $ourfn\n";
 440     responder_send_command "file $keyword";
 441     protocol_send_file \*PO, $ourfn;
 442 }
 443
 444 sub responder_receive_files ($@) {
 445     my ($keyword, @ourfns) = @_;
 446     die unless $we_are_responder;
 447     printdebug "[[ $keyword @ourfns\n";
 448     responder_send_command "want $keyword";
 449     foreach my $fn (@ourfns) {
 450         protocol_receive_file \*PI, $fn;
 451     }
 452     printdebug "[[\$\n";
 453     protocol_expect { m/^files-end$/ } \*PI;
 454 }
 455
 456 #---------- remote protocol support, initiator ----------
 457
 458 sub initiator_expect (&) {
 459     my ($match) = @_;
 460     protocol_expect { &$match } \*RO;
 461 }
 462
 463 #---------- end remote code ----------
 464
 465 sub progress {
 466     if ($we_are_responder) {
 467         my $m = join '', @_;
 468         responder_send_command "progress ".length($m) or die $!;
 469         print PO $m or die $!;
 470     } else {
 471         print @_, "\n";
 472     }
 473 }
 474
 475 our $ua;
 476
 477 sub url_get {
 478     if (!$ua) {
 479         $ua = LWP::UserAgent->new();
 480         $ua->env_proxy;
 481     }
 482     my $what = $_[$#_];
 483     progress "downloading $what...";
 484     my $r = $ua->get(@_) or die $!;
 485     return undef if $r->code == 404;
 486     $r->is_success or fail "failed to fetch $what: ".$r->status_line;
 487     return $r->decoded_content(charset => 'none');
 488 }
 489
 490 our ($dscdata,$dscurl,$dsc,$dsc_checked,$skew_warning_vsn);
 491
 492 sub act_local () { return $dryrun_level <= 1; }
 493 sub act_scary () { return !$dryrun_level; }
 494
 495 sub printdone {
 496     if (!$dryrun_level) {
 497         progress "$us ok: @_";
 498     } else {
 499         progress "would be ok: @_ (but dry run only)";
 500     }
 501 }
 502
 503 sub dryrun_report {
 504     printcmd(\*STDERR,$debugprefix."#",@_);
 505 }
 506
 507 sub runcmd_ordryrun {
 508     if (act_scary()) {
 509         runcmd @_;
 510     } else {
 511         dryrun_report @_;
 512     }
 513 }
 514
 515 sub runcmd_ordryrun_local {
 516     if (act_local()) {
 517         runcmd @_;
 518     } else {
 519         dryrun_report @_;
 520     }
 521 }
 522
 523 sub shell_cmd {
 524     my ($first_shell, @cmd) = @_;
 525     return qw(sh -ec), $first_shell.'; exec "$@"', 'x', @cmd;
 526 }
 527
 528 our $helpmsg = <<END;
 529 main usages:
 530   dgit [dgit-opts] clone [dgit-opts] package [suite] [./dir|/dir]
 531   dgit [dgit-opts] fetch|pull [dgit-opts] [suite]
 532   dgit [dgit-opts] build [dpkg-buildpackage-opts]
 533   dgit [dgit-opts] sbuild [sbuild-opts]
 534   dgit [dgit-opts] push [dgit-opts] [suite]
 535   dgit [dgit-opts] rpush build-host:build-dir ...
 536 important dgit options:
 537   -k<keyid>           sign tag and package with <keyid> instead of default
 538   --dry-run -n        do not change anything, but go through the motions
 539   --damp-run -L       like --dry-run but make local changes, without signing
 540   --new -N            allow introducing a new package
 541   --debug -D          increase debug level
 542   -c<name>=<value>    set git config option (used directly by dgit too)
 543 END
 544
 545 our $later_warning_msg = <<END;
 546 Perhaps the upload is stuck in incoming.  Using the version from git.
 547 END
 548
 549 sub badusage {
 550     print STDERR "$us: @_\n", $helpmsg or die $!;
 551     exit 8;
 552 }
 553
 554 sub nextarg {
 555     @ARGV or badusage "too few arguments";
 556     return scalar shift @ARGV;
 557 }
 558
 559 sub pre_help () {
 560     no_local_git_cfg();
 561 }
 562 sub cmd_help () {
 563     print $helpmsg or die $!;
 564     exit 0;
 565 }
 566
 567 our $td = $ENV{DGIT_TEST_DUMMY_DIR} || "DGIT_TEST_DUMMY_DIR-unset";
 568
 569 our %defcfg = ('dgit.default.distro' => 'debian',
 570                'dgit.default.default-suite' => 'unstable',
 571                'dgit.default.old-dsc-distro' => 'debian',
 572                'dgit-suite.*-security.distro' => 'debian-security',
 573                'dgit.default.username' => '',
 574                'dgit.default.archive-query-default-component' => 'main',
 575                'dgit.default.ssh' => 'ssh',
 576                'dgit.default.archive-query' => 'madison:',
 577                'dgit.default.sshpsql-dbname' => 'service=projectb',
 578                'dgit.default.aptget-components' => 'main',
 579                'dgit.default.dgit-tag-format' => 'new,old,maint',
 580                'dgit.dsc-url-proto-ok.http'    => 'true',
 581                'dgit.dsc-url-proto-ok.https'   => 'true',
 582                'dgit.dsc-url-proto-ok.git'     => 'true',
 583                'dgit.default.dsc-url-proto-ok' => 'false',
 584                # old means "repo server accepts pushes with old dgit tags"
 585                # new means "repo server accepts pushes with new dgit tags"
 586                # maint means "repo server accepts split brain pushes"
 587                # hist means "repo server may have old pushes without new tag"
 588                #   ("hist" is implied by "old")
 589                'dgit-distro.debian.archive-query' => 'ftpmasterapi:',
 590                'dgit-distro.debian.git-check' => 'url',
 591                'dgit-distro.debian.git-check-suffix' => '/info/refs',
 592                'dgit-distro.debian.new-private-pushers' => 't',
 593                'dgit-distro.debian/push.git-url' => '',
 594                'dgit-distro.debian/push.git-host' => 'push.dgit.debian.org',
 595                'dgit-distro.debian/push.git-user-force' => 'dgit',
 596                'dgit-distro.debian/push.git-proto' => 'git+ssh://',
 597                'dgit-distro.debian/push.git-path' => '/dgit/debian/repos',
 598                'dgit-distro.debian/push.git-create' => 'true',
 599                'dgit-distro.debian/push.git-check' => 'ssh-cmd',
 600  'dgit-distro.debian.archive-query-url', 'https://api.ftp-master.debian.org/',
 601 # 'dgit-distro.debian.archive-query-tls-key',
 602 #    '/etc/ssl/certs/%HOST%.pem:/etc/dgit/%HOST%.pem',
 603 # ^ this does not work because curl is broken nowadays
 604 # Fixing #790093 properly will involve providing providing the key
 605 # in some pacagke and maybe updating these paths.
 606 #
 607 # 'dgit-distro.debian.archive-query-tls-curl-args',
 608 #   '--ca-path=/etc/ssl/ca-debian',
 609 # ^ this is a workaround but works (only) on DSA-administered machines
 610                'dgit-distro.debian.git-url' => 'https://git.dgit.debian.org',
 611                'dgit-distro.debian.git-url-suffix' => '',
 612                'dgit-distro.debian.upload-host' => 'ftp-master', # for dput
 613                'dgit-distro.debian.mirror' => 'http://ftp.debian.org/debian/',
 614  'dgit-distro.debian-security.archive-query' => 'aptget:',
 615  'dgit-distro.debian-security.mirror' => 'http://security.debian.org/debian-security/',
 616  'dgit-distro.debian-security.aptget-suite-map' => 's#-security$#/updates#',
 617  'dgit-distro.debian-security.aptget-suite-rmap' => 's#$#-security#',
 618  'dgit-distro.debian-security.nominal-distro' => 'debian',
 619  'dgit-distro.debian.backports-quirk' => '(squeeze)-backports*',
 620  'dgit-distro.debian-backports.mirror' => 'http://backports.debian.org/debian-backports/',
 621                'dgit-distro.ubuntu.git-check' => 'false',
 622  'dgit-distro.ubuntu.mirror' => 'http://archive.ubuntu.com/ubuntu',
 623                'dgit-distro.test-dummy.ssh' => "$td/ssh",
 624                'dgit-distro.test-dummy.username' => "alice",
 625                'dgit-distro.test-dummy.git-check' => "ssh-cmd",
 626                'dgit-distro.test-dummy.git-create' => "ssh-cmd",
 627                'dgit-distro.test-dummy.git-url' => "$td/git",
 628                'dgit-distro.test-dummy.git-host' => "git",
 629                'dgit-distro.test-dummy.git-path' => "$td/git",
 630                'dgit-distro.test-dummy.archive-query' => "dummycatapi:",
 631                'dgit-distro.test-dummy.archive-query-url' => "file://$td/aq/",
 632                'dgit-distro.test-dummy.mirror' => "file://$td/mirror/",
 633                'dgit-distro.test-dummy.upload-host' => 'test-dummy',
 634                );
 635
 636 our %gitcfgs;
 637 our @gitcfgsources = qw(cmdline local global system);
 638
 639 sub git_slurp_config () {
 640     # This algoritm is a bit subtle, but this is needed so that for
 641     # options which we want to be single-valued, we allow the
 642     # different config sources to override properly.  See #835858.
 643     foreach my $src (@gitcfgsources) {
 644         next if $src eq 'cmdline';
 645         # we do this ourselves since git doesn't handle it
 646
 647         $gitcfgs{$src} = git_slurp_config_src $src;
 648     }
 649 }
 650
 651 sub git_get_config ($) {
 652     my ($c) = @_;
 653     foreach my $src (@gitcfgsources) {
 654         my $l = $gitcfgs{$src}{$c};
 655         confess "internal error ($l $c)" if $l && !ref $l;
 656         printdebug"C $c ".(defined $l ?
 657                            join " ", map { messagequote "'$_'" } @$l :
 658                            "undef")."\n"
 659             if $debuglevel >= 4;
 660         $l or next;
 661         @$l==1 or badcfg "multiple values for $c".
 662             " (in $src git config)" if @$l > 1;
 663         return $l->[0];
 664     }
 665     return undef;
 666 }
 667
 668 sub cfg {
 669     foreach my $c (@_) {
 670         return undef if $c =~ /RETURN-UNDEF/;
 671         printdebug "C? $c\n" if $debuglevel >= 5;
 672         my $v = git_get_config($c);
 673         return $v if defined $v;
 674         my $dv = $defcfg{$c};
 675         if (defined $dv) {
 676             printdebug "CD $c $dv\n" if $debuglevel >= 4;
 677             return $dv;
 678         }
 679     }
 680     badcfg "need value for one of: @_\n".
 681         "$us: distro or suite appears not to be (properly) supported";
 682 }
 683
 684 sub no_local_git_cfg () {
 685     # needs to be called from pre_*
 686     @gitcfgsources = grep { $_ ne 'local' } @gitcfgsources;
 687 }
 688
 689 sub access_basedistro__noalias () {
 690     if (defined $idistro) {
 691         return $idistro;
 692     } else {
 693         my $def = cfg("dgit-suite.$isuite.distro", 'RETURN-UNDEF');
 694         return $def if defined $def;
 695         foreach my $src (@gitcfgsources, 'internal') {
 696             my $kl = $src eq 'internal' ? \%defcfg : $gitcfgs{$src};
 697             next unless $kl;
 698             foreach my $k (keys %$kl) {
 699                 next unless $k =~ m#^dgit-suite\.(.*)\.distro$#;
 700                 my $dpat = $1;
 701                 next unless match_glob $dpat, $isuite;
 702                 return $kl->{$k};
 703             }
 704         }
 705         return cfg("dgit.default.distro");
 706     }
 707 }
 708
 709 sub access_basedistro () {
 710     my $noalias = access_basedistro__noalias();
 711     my $canon = cfg("dgit-distro.$noalias.alias-canon",'RETURN-UNDEF');
 712     return $canon // $noalias;
 713 }
 714
 715 sub access_nomdistro () {
 716     my $base = access_basedistro();
 717     my $r = cfg("dgit-distro.$base.nominal-distro",'RETURN-UNDEF') // $base;
 718     $r =~ m/^$distro_re$/ or badcfg
 719  "bad syntax for (nominal) distro \`$r' (does not match /^$distro_re$/)";
 720     return $r;
 721 }
 722
 723 sub access_quirk () {
 724     # returns (quirk name, distro to use instead or undef, quirk-specific info)
 725     my $basedistro = access_basedistro();
 726     my $backports_quirk = cfg("dgit-distro.$basedistro.backports-quirk",
 727                               'RETURN-UNDEF');
 728     if (defined $backports_quirk) {
 729         my $re = $backports_quirk;
 730         $re =~ s/[^-0-9a-z_\%*()]/\\$&/ig;
 731         $re =~ s/\*/.*/g;
 732         $re =~ s/\%/([-0-9a-z_]+)/
 733             or $re =~ m/[()]/ or badcfg "backports-quirk needs \% or ( )";
 734         if ($isuite =~ m/^$re$/) {
 735             return ('backports',"$basedistro-backports",$1);
 736         }
 737     }
 738     return ('none',undef);
 739 }
 740
 741 our $access_forpush;
 742
 743 sub parse_cfg_bool ($$$) {
 744     my ($what,$def,$v) = @_;
 745     $v //= $def;
 746     return
 747         $v =~ m/^[ty1]/ ? 1 :
 748         $v =~ m/^[fn0]/ ? 0 :
 749         badcfg "$what needs t (true, y, 1) or f (false, n, 0) not \`$v'";
 750 }
 751
 752 sub access_forpush_config () {
 753     my $d = access_basedistro();
 754
 755     return 1 if
 756         $new_package &&
 757         parse_cfg_bool('new-private-pushers', 0,
 758                        cfg("dgit-distro.$d.new-private-pushers",
 759                            'RETURN-UNDEF'));
 760
 761     my $v = cfg("dgit-distro.$d.readonly", 'RETURN-UNDEF');
 762     $v //= 'a';
 763     return
 764         $v =~ m/^[ty1]/ ? 0 : # force readonly,    forpush = 0
 765         $v =~ m/^[fn0]/ ? 1 : # force nonreadonly, forpush = 1
 766         $v =~ m/^[a]/  ? '' : # auto,              forpush = ''
 767         badcfg "readonly needs t (true, y, 1) or f (false, n, 0) or a (auto)";
 768 }
 769
 770 sub access_forpush () {
 771     $access_forpush //= access_forpush_config();
 772     return $access_forpush;
 773 }
 774
 775 sub pushing () {
 776     die "$access_forpush ?" if ($access_forpush // 1) ne 1;
 777     badcfg "pushing but distro is configured readonly"
 778         if access_forpush_config() eq '0';
 779     $access_forpush = 1;
 780     $supplementary_message = <<'END' unless $we_are_responder;
 781 Push failed, before we got started.
 782 You can retry the push, after fixing the problem, if you like.
 783 END
 784     parseopts_late_defaults();
 785 }
 786
 787 sub notpushing () {
 788     parseopts_late_defaults();
 789 }
 790
 791 sub supplementary_message ($) {
 792     my ($msg) = @_;
 793     if (!$we_are_responder) {
 794         $supplementary_message = $msg;
 795         return;
 796     } elsif ($protovsn >= 3) {
 797         responder_send_command "supplementary-message ".length($msg)
 798             or die $!;
 799         print PO $msg or die $!;
 800     }
 801 }
 802
 803 sub access_distros () {
 804     # Returns list of distros to try, in order
 805     #
 806     # We want to try:
 807     #    0. `instead of' distro name(s) we have been pointed to
 808     #    1. the access_quirk distro, if any
 809     #    2a. the user's specified distro, or failing that  } basedistro
 810     #    2b. the distro calculated from the suite          }
 811     my @l = access_basedistro();
 812
 813     my (undef,$quirkdistro) = access_quirk();
 814     unshift @l, $quirkdistro;
 815     unshift @l, $instead_distro;
 816     @l = grep { defined } @l;
 817
 818     push @l, access_nomdistro();
 819
 820     if (access_forpush()) {
 821         @l = map { ("$_/push", $_) } @l;
 822     }
 823     @l;
 824 }
 825
 826 sub access_cfg_cfgs (@) {
 827     my (@keys) = @_;
 828     my @cfgs;
 829     # The nesting of these loops determines the search order.  We put
 830     # the key loop on the outside so that we search all the distros
 831     # for each key, before going on to the next key.  That means that
 832     # if access_cfg is called with a more specific, and then a less
 833     # specific, key, an earlier distro can override the less specific
 834     # without necessarily overriding any more specific keys.  (If the
 835     # distro wants to override the more specific keys it can simply do
 836     # so; whereas if we did the loop the other way around, it would be
 837     # impossible to for an earlier distro to override a less specific
 838     # key but not the more specific ones without restating the unknown
 839     # values of the more specific keys.
 840     my @realkeys;
 841     my @rundef;
 842     # We have to deal with RETURN-UNDEF specially, so that we don't
 843     # terminate the search prematurely.
 844     foreach (@keys) {
 845         if (m/RETURN-UNDEF/) { push @rundef, $_; last; }
 846         push @realkeys, $_
 847     }
 848     foreach my $d (access_distros()) {
 849         push @cfgs, map { "dgit-distro.$d.$_" } @realkeys;
 850     }
 851     push @cfgs, map { "dgit.default.$_" } @realkeys;
 852     push @cfgs, @rundef;
 853     return @cfgs;
 854 }
 855
 856 sub access_cfg (@) {
 857     my (@keys) = @_;
 858     my (@cfgs) = access_cfg_cfgs(@keys);
 859     my $value = cfg(@cfgs);
 860     return $value;
 861 }
 862
 863 sub access_cfg_bool ($$) {
 864     my ($def, @keys) = @_;
 865     parse_cfg_bool($keys[0], $def, access_cfg(@keys, 'RETURN-UNDEF'));
 866 }
 867
 868 sub string_to_ssh ($) {
 869     my ($spec) = @_;
 870     if ($spec =~ m/\s/) {
 871         return qw(sh -ec), 'exec '.$spec.' "$@"', 'x';
 872     } else {
 873         return ($spec);
 874     }
 875 }
 876
 877 sub access_cfg_ssh () {
 878     my $gitssh = access_cfg('ssh', 'RETURN-UNDEF');
 879     if (!defined $gitssh) {
 880         return @ssh;
 881     } else {
 882         return string_to_ssh $gitssh;
 883     }
 884 }
 885
 886 sub access_runeinfo ($) {
 887     my ($info) = @_;
 888     return ": dgit ".access_basedistro()." $info ;";
 889 }
 890
 891 sub access_someuserhost ($) {
 892     my ($some) = @_;
 893     my $user = access_cfg("$some-user-force", 'RETURN-UNDEF');
 894     defined($user) && length($user) or
 895         $user = access_cfg("$some-user",'username');
 896     my $host = access_cfg("$some-host");
 897     return length($user) ? "$user\@$host" : $host;
 898 }
 899
 900 sub access_gituserhost () {
 901     return access_someuserhost('git');
 902 }
 903
 904 sub access_giturl (;$) {
 905     my ($optional) = @_;
 906     my $url = access_cfg('git-url','RETURN-UNDEF');
 907     my $suffix;
 908     if (!length $url) {
 909         my $proto = access_cfg('git-proto', 'RETURN-UNDEF');
 910         return undef unless defined $proto;
 911         $url =
 912             $proto.
 913             access_gituserhost().
 914             access_cfg('git-path');
 915     } else {
 916         $suffix = access_cfg('git-url-suffix','RETURN-UNDEF');
 917     }
 918     $suffix //= '.git';
 919     return "$url/$package$suffix";
 920 }
 921
 922 sub parsecontrolfh ($$;$) {
 923     my ($fh, $desc, $allowsigned) = @_;
 924     our $dpkgcontrolhash_noissigned;
 925     my $c;
 926     for (;;) {
 927         my %opts = ('name' => $desc);
 928         $opts{allow_pgp}= $allowsigned || !$dpkgcontrolhash_noissigned;
 929         $c = Dpkg::Control::Hash->new(%opts);
 930         $c->parse($fh,$desc) or die "parsing of $desc failed";
 931         last if $allowsigned;
 932         last if $dpkgcontrolhash_noissigned;
 933         my $issigned= $c->get_option('is_pgp_signed');
 934         if (!defined $issigned) {
 935             $dpkgcontrolhash_noissigned= 1;
 936             seek $fh, 0,0 or die "seek $desc: $!";
 937         } elsif ($issigned) {
 938             fail "control file $desc is (already) PGP-signed. ".
 939                 " Note that dgit push needs to modify the .dsc and then".
 940                 " do the signature itself";
 941         } else {
 942             last;
 943         }
 944     }
 945     return $c;
 946 }
 947
 948 sub parsecontrol {
 949     my ($file, $desc, $allowsigned) = @_;
 950     my $fh = new IO::Handle;
 951     open $fh, '<', $file or die "$file: $!";
 952     my $c = parsecontrolfh($fh,$desc,$allowsigned);
 953     $fh->error and die $!;
 954     close $fh;
 955     return $c;
 956 }
 957
 958 sub getfield ($$) {
 959     my ($dctrl,$field) = @_;
 960     my $v = $dctrl->{$field};
 961     return $v if defined $v;
 962     fail "missing field $field in ".$dctrl->get_option('name');
 963 }
 964
 965 sub parsechangelog {
 966     my $c = Dpkg::Control::Hash->new(name => 'parsed changelog');
 967     my $p = new IO::Handle;
 968     my @cmd = (qw(dpkg-parsechangelog), @_);
 969     open $p, '-|', @cmd or die $!;
 970     $c->parse($p);
 971     $?=0; $!=0; close $p or failedcmd @cmd;
 972     return $c;
 973 }
 974
 975 sub commit_getclogp ($) {
 976     # Returns the parsed changelog hashref for a particular commit
 977     my ($objid) = @_;
 978     our %commit_getclogp_memo;
 979     my $memo = $commit_getclogp_memo{$objid};
 980     return $memo if $memo;
 981     mkpath '.git/dgit';
 982     my $mclog = ".git/dgit/clog-$objid";
 983     runcmd shell_cmd "exec >$mclog", @git, qw(cat-file blob),
 984         "$objid:debian/changelog";
 985     $commit_getclogp_memo{$objid} = parsechangelog("-l$mclog");
 986 }
 987
 988 sub parse_dscdata () {
 989     my $dscfh = new IO::File \$dscdata, '<' or die $!;
 990     printdebug Dumper($dscdata) if $debuglevel>1;
 991     $dsc = parsecontrolfh($dscfh,$dscurl,1);
 992     printdebug Dumper($dsc) if $debuglevel>1;
 993 }
 994
 995 our %rmad;
 996
 997 sub archive_query ($;@) {
 998     my ($method) = shift @_;
 999     fail "this operation does not support multiple comma-separated suites"
1000         if $isuite =~ m/,/;
1001     my $query = access_cfg('archive-query','RETURN-UNDEF');
1002     $query =~ s/^(\w+):// or badcfg "invalid archive-query method \`$query'";
1003     my $proto = $1;
1004     my $data = $'; #';
1005     { no strict qw(refs); &{"${method}_${proto}"}($proto,$data,@_); }
1006 }
1007
1008 sub archive_query_prepend_mirror {
1009     my $m = access_cfg('mirror');
1010     return map { [ $_->[0], $m.$_->[1], @$_[2..$#$_] ] } @_;
1011 }
1012
1013 sub pool_dsc_subpath ($$) {
1014     my ($vsn,$component) = @_; # $package is implict arg
1015     my $prefix = substr($package, 0, $package =~ m/^l/ ? 4 : 1);
1016     return "/pool/$component/$prefix/$package/".dscfn($vsn);
1017 }
1018
1019 sub cfg_apply_map ($$$) {
1020     my ($varref, $what, $mapspec) = @_;
1021     return unless $mapspec;
1022
1023     printdebug "config $what EVAL{ $mapspec; }\n";
1024     $_ = $$varref;
1025     eval "package Dgit::Config; $mapspec;";
1026     die $@ if $@;
1027     $$varref = $_;
1028 }
1029
1030 #---------- `ftpmasterapi' archive query method (nascent) ----------
1031
1032 sub archive_api_query_cmd ($) {
1033     my ($subpath) = @_;
1034     my @cmd = (@curl, qw(-sS));
1035     my $url = access_cfg('archive-query-url');
1036     if ($url =~ m#^https://([-.0-9a-z]+)/#) {
1037         my $host = $1;
1038         my $keys = access_cfg('archive-query-tls-key','RETURN-UNDEF') //'';
1039         foreach my $key (split /\:/, $keys) {
1040             $key =~ s/\%HOST\%/$host/g;
1041             if (!stat $key) {
1042                 fail "for $url: stat $key: $!" unless $!==ENOENT;
1043                 next;
1044             }
1045             fail "config requested specific TLS key but do not know".
1046                 " how to get curl to use exactly that EE key ($key)";
1047 #           push @cmd, "--cacert", $key, "--capath", "/dev/enoent";
1048 #           # Sadly the above line does not work because of changes
1049 #           # to gnutls.   The real fix for #790093 may involve
1050 #           # new curl options.
1051             last;
1052         }
1053         # Fixing #790093 properly will involve providing a value
1054         # for this on clients.
1055         my $kargs = access_cfg('archive-query-tls-curl-ca-args','RETURN-UNDEF');
1056         push @cmd, split / /, $kargs if defined $kargs;
1057     }
1058     push @cmd, $url.$subpath;
1059     return @cmd;
1060 }
1061
1062 sub api_query ($$;$) {
1063     use JSON;
1064     my ($data, $subpath, $ok404) = @_;
1065     badcfg "ftpmasterapi archive query method takes no data part"
1066         if length $data;
1067     my @cmd = archive_api_query_cmd($subpath);
1068     my $url = $cmd[$#cmd];
1069     push @cmd, qw(-w %{http_code});
1070     my $json = cmdoutput @cmd;
1071     unless ($json =~ s/\d+\d+\d$//) {
1072         failedcmd_report_cmd undef, @cmd;
1073         fail "curl failed to print 3-digit HTTP code";
1074     }
1075     my $code = $&;
1076     return undef if $code eq '404' && $ok404;
1077     fail "fetch of $url gave HTTP code $code"
1078         unless $url =~ m#^file://# or $code =~ m/^2/;
1079     return decode_json($json);
1080 }
1081
1082 sub canonicalise_suite_ftpmasterapi {
1083     my ($proto,$data) = @_;
1084     my $suites = api_query($data, 'suites');
1085     my @matched;
1086     foreach my $entry (@$suites) {
1087         next unless grep {
1088             my $v = $entry->{$_};
1089             defined $v && $v eq $isuite;
1090         } qw(codename name);
1091         push @matched, $entry;
1092     }
1093     fail "unknown suite $isuite" unless @matched;
1094     my $cn;
1095     eval {
1096         @matched==1 or die "multiple matches for suite $isuite\n";
1097         $cn = "$matched[0]{codename}";
1098         defined $cn or die "suite $isuite info has no codename\n";
1099         $cn =~ m/^$suite_re$/ or die "suite $isuite maps to bad codename\n";
1100     };
1101     die "bad ftpmaster api response: $@\n".Dumper(\@matched)
1102         if length $@;
1103     return $cn;
1104 }
1105
1106 sub archive_query_ftpmasterapi {
1107     my ($proto,$data) = @_;
1108     my $info = api_query($data, "dsc_in_suite/$isuite/$package");
1109     my @rows;
1110     my $digester = Digest::SHA->new(256);
1111     foreach my $entry (@$info) {
1112         eval {
1113             my $vsn = "$entry->{version}";
1114             my ($ok,$msg) = version_check $vsn;
1115             die "bad version: $msg\n" unless $ok;
1116             my $component = "$entry->{component}";
1117             $component =~ m/^$component_re$/ or die "bad component";
1118             my $filename = "$entry->{filename}";
1119             $filename && $filename !~ m#[^-+:._~0-9a-zA-Z/]|^[/.]|/[/.]#
1120                 or die "bad filename";
1121             my $sha256sum = "$entry->{sha256sum}";
1122             $sha256sum =~ m/^[0-9a-f]+$/ or die "bad sha256sum";
1123             push @rows, [ $vsn, "/pool/$component/$filename",
1124                           $digester, $sha256sum ];
1125         };
1126         die "bad ftpmaster api response: $@\n".Dumper($entry)
1127             if length $@;
1128     }
1129     @rows = sort { -version_compare($a->[0],$b->[0]) } @rows;
1130     return archive_query_prepend_mirror @rows;
1131 }
1132
1133 sub file_in_archive_ftpmasterapi {
1134     my ($proto,$data,$filename) = @_;
1135     my $pat = $filename;
1136     $pat =~ s/_/\\_/g;
1137     $pat = "%/$pat";
1138     $pat =~ s#[^-+_.0-9a-z/]# sprintf '%%%02x', ord $& #ge;
1139     my $info = api_query($data, "file_in_archive/$pat", 1);
1140 }
1141
1142 #---------- `aptget' archive query method ----------
1143
1144 our $aptget_base;
1145 our $aptget_releasefile;
1146 our $aptget_configpath;
1147
1148 sub aptget_aptget   () { return @aptget,   qw(-c), $aptget_configpath; }
1149 sub aptget_aptcache () { return @aptcache, qw(-c), $aptget_configpath; }
1150
1151 sub aptget_cache_clean {
1152     runcmd_ordryrun_local qw(sh -ec),
1153         'cd "$1"; find -atime +30 -type f -print0 | xargs -0r rm --',
1154         'x', $aptget_base;
1155 }
1156
1157 sub aptget_lock_acquire () {
1158     my $lockfile = "$aptget_base/lock";
1159     open APTGET_LOCK, '>', $lockfile or die "open $lockfile: $!";
1160     flock APTGET_LOCK, LOCK_EX or die "lock $lockfile: $!";
1161 }
1162
1163 sub aptget_prep ($) {
1164     my ($data) = @_;
1165     return if defined $aptget_base;
1166
1167     badcfg "aptget archive query method takes no data part"
1168         if length $data;
1169
1170     my $cache = $ENV{XDG_CACHE_DIR} // "$ENV{HOME}/.cache";
1171
1172     ensuredir $cache;
1173     ensuredir "$cache/dgit";
1174     my $cachekey =
1175         access_cfg('aptget-cachekey','RETURN-UNDEF')
1176         // access_nomdistro();
1177
1178     $aptget_base = "$cache/dgit/aptget";
1179     ensuredir $aptget_base;
1180
1181     my $quoted_base = $aptget_base;
1182     die "$quoted_base contains bad chars, cannot continue"
1183         if $quoted_base =~ m/["\\]/; # apt.conf(5) says no escaping :-/
1184
1185     ensuredir $aptget_base;
1186
1187     aptget_lock_acquire();
1188
1189     aptget_cache_clean();
1190
1191     $aptget_configpath = "$aptget_base/apt.conf#$cachekey";
1192     my $sourceslist = "source.list#$cachekey";
1193
1194     my $aptsuites = $isuite;
1195     cfg_apply_map(\$aptsuites, 'suite map',
1196                   access_cfg('aptget-suite-map', 'RETURN-UNDEF'));
1197
1198     open SRCS, ">", "$aptget_base/$sourceslist" or die $!;
1199     printf SRCS "deb-src %s %s %s\n",
1200         access_cfg('mirror'),
1201         $aptsuites,
1202         access_cfg('aptget-components')
1203         or die $!;
1204
1205     ensuredir "$aptget_base/cache";
1206     ensuredir "$aptget_base/lists";
1207
1208     open CONF, ">", $aptget_configpath or die $!;
1209     print CONF <<END;
1210 Debug::NoLocking "true";
1211 APT::Get::List-Cleanup "false";
1212 #clear APT::Update::Post-Invoke-Success;
1213 Dir::Etc::SourceList "$quoted_base/$sourceslist";
1214 Dir::State::Lists "$quoted_base/lists";
1215 Dir::Etc::preferences "$quoted_base/preferences";
1216 Dir::Cache::srcpkgcache "$quoted_base/cache/srcs#$cachekey";
1217 Dir::Cache::pkgcache "$quoted_base/cache/pkgs#$cachekey";
1218 END
1219
1220     foreach my $key (qw(
1221                         Dir::Cache
1222                         Dir::State
1223                         Dir::Cache::Archives
1224                         Dir::Etc::SourceParts
1225                         Dir::Etc::preferencesparts
1226                       )) {
1227         ensuredir "$aptget_base/$key";
1228         print CONF "$key \"$quoted_base/$key\";\n" or die $!;
1229     };
1230
1231     my $oldatime = (time // die $!) - 1;
1232     foreach my $oldlist (<$aptget_base/lists/*Release>) {
1233         next unless stat_exists $oldlist;
1234         my ($mtime) = (stat _)[9];
1235         utime $oldatime, $mtime, $oldlist or die "$oldlist $!";
1236     }
1237
1238     runcmd_ordryrun_local aptget_aptget(), qw(update);
1239
1240     my @releasefiles;
1241     foreach my $oldlist (<$aptget_base/lists/*Release>) {
1242         next unless stat_exists $oldlist;
1243         my ($atime) = (stat _)[8];
1244         next if $atime == $oldatime;
1245         push @releasefiles, $oldlist;
1246     }
1247     my @inreleasefiles = grep { m#/InRelease$# } @releasefiles;
1248     @releasefiles = @inreleasefiles if @inreleasefiles;
1249     die "apt updated wrong number of Release files (@releasefiles), erk"
1250         unless @releasefiles == 1;
1251
1252     ($aptget_releasefile) = @releasefiles;
1253 }
1254
1255 sub canonicalise_suite_aptget {
1256     my ($proto,$data) = @_;
1257     aptget_prep($data);
1258
1259     my $release = parsecontrol $aptget_releasefile, "Release file", 1;
1260
1261     foreach my $name (qw(Codename Suite)) {
1262         my $val = $release->{$name};
1263         if (defined $val) {
1264             printdebug "release file $name: $val\n";
1265             $val =~ m/^$suite_re$/o or fail
1266  "Release file ($aptget_releasefile) specifies intolerable $name";
1267             cfg_apply_map(\$val, 'suite rmap',
1268                           access_cfg('aptget-suite-rmap', 'RETURN-UNDEF'));
1269             return $val
1270         }
1271     }
1272     return $isuite;
1273 }
1274
1275 sub archive_query_aptget {
1276     my ($proto,$data) = @_;
1277     aptget_prep($data);
1278
1279     ensuredir "$aptget_base/source";
1280     foreach my $old (<$aptget_base/source/*.dsc>) {
1281         unlink $old or die "$old: $!";
1282     }
1283
1284     my $showsrc = cmdoutput aptget_aptcache(), qw(showsrc), $package;
1285     return () unless $showsrc =~ m/^package:\s*\Q$package\E\s*$/mi;
1286     # avoids apt-get source failing with ambiguous error code
1287
1288     runcmd_ordryrun_local
1289         shell_cmd 'cd "$1"/source; shift', $aptget_base,
1290         aptget_aptget(), qw(--download-only --only-source source), $package;
1291
1292     my @dscs = <$aptget_base/source/*.dsc>;
1293     fail "apt-get source did not produce a .dsc" unless @dscs;
1294     fail "apt-get source produced several .dscs (@dscs)" unless @dscs==1;
1295
1296     my $pre_dsc = parsecontrol $dscs[0], $dscs[0], 1;
1297
1298     use URI::Escape;
1299     my $uri = "file://". uri_escape $dscs[0];
1300     $uri =~ s{\%2f}{/}gi;
1301     return [ (getfield $pre_dsc, 'Version'), $uri ];
1302 }
1303
1304 sub file_in_archive_aptget () { return undef; }
1305
1306 #---------- `dummyapicat' archive query method ----------
1307
1308 sub archive_query_dummycatapi { archive_query_ftpmasterapi @_; }
1309 sub canonicalise_suite_dummycatapi { canonicalise_suite_ftpmasterapi @_; }
1310
1311 sub file_in_archive_dummycatapi ($$$) {
1312     my ($proto,$data,$filename) = @_;
1313     my $mirror = access_cfg('mirror');
1314     $mirror =~ s#^file://#/# or die "$mirror ?";
1315     my @out;
1316     my @cmd = (qw(sh -ec), '
1317             cd "$1"
1318             find -name "$2" -print0 |
1319             xargs -0r sha256sum
1320         ', qw(x), $mirror, $filename);
1321     debugcmd "-|", @cmd;
1322     open FIA, "-|", @cmd or die $!;
1323     while (<FIA>) {
1324         chomp or die;
1325         printdebug "| $_\n";
1326         m/^(\w+)  (\S+)$/ or die "$_ ?";
1327         push @out, { sha256sum => $1, filename => $2 };
1328     }
1329     close FIA or die failedcmd @cmd;
1330     return \@out;
1331 }
1332
1333 #---------- `madison' archive query method ----------
1334
1335 sub archive_query_madison {
1336     return archive_query_prepend_mirror
1337         map { [ @$_[0..1] ] } madison_get_parse(@_);
1338 }
1339
1340 sub madison_get_parse {
1341     my ($proto,$data) = @_;
1342     die unless $proto eq 'madison';
1343     if (!length $data) {
1344         $data= access_cfg('madison-distro','RETURN-UNDEF');
1345         $data //= access_basedistro();
1346     }
1347     $rmad{$proto,$data,$package} ||= cmdoutput
1348         qw(rmadison -asource),"-s$isuite","-u$data",$package;
1349     my $rmad = $rmad{$proto,$data,$package};
1350
1351     my @out;
1352     foreach my $l (split /\n/, $rmad) {
1353         $l =~ m{^ \s*( [^ \t|]+ )\s* \|
1354                   \s*( [^ \t|]+ )\s* \|
1355                   \s*( [^ \t|/]+ )(?:/([^ \t|/]+))? \s* \|
1356                   \s*( [^ \t|]+ )\s* }x or die "$rmad ?";
1357         $1 eq $package or die "$rmad $package ?";
1358         my $vsn = $2;
1359         my $newsuite = $3;
1360         my $component;
1361         if (defined $4) {
1362             $component = $4;
1363         } else {
1364             $component = access_cfg('archive-query-default-component');
1365         }
1366         $5 eq 'source' or die "$rmad ?";
1367         push @out, [$vsn,pool_dsc_subpath($vsn,$component),$newsuite];
1368     }
1369     return sort { -version_compare($a->[0],$b->[0]); } @out;
1370 }
1371
1372 sub canonicalise_suite_madison {
1373     # madison canonicalises for us
1374     my @r = madison_get_parse(@_);
1375     @r or fail
1376         "unable to canonicalise suite using package $package".
1377         " which does not appear to exist in suite $isuite;".
1378         " --existing-package may help";
1379     return $r[0][2];
1380 }
1381
1382 sub file_in_archive_madison { return undef; }
1383
1384 #---------- `sshpsql' archive query method ----------
1385
1386 sub sshpsql ($$$) {
1387     my ($data,$runeinfo,$sql) = @_;
1388     if (!length $data) {
1389         $data= access_someuserhost('sshpsql').':'.
1390             access_cfg('sshpsql-dbname');
1391     }
1392     $data =~ m/:/ or badcfg "invalid sshpsql method string \`$data'";
1393     my ($userhost,$dbname) = ($`,$'); #';
1394     my @rows;
1395     my @cmd = (access_cfg_ssh, $userhost,
1396                access_runeinfo("ssh-psql $runeinfo").
1397                " export LC_MESSAGES=C; export LC_CTYPE=C;".
1398                " ".shellquote qw(psql -A), $dbname, qw(-c), $sql);
1399     debugcmd "|",@cmd;
1400     open P, "-|", @cmd or die $!;
1401     while (<P>) {
1402         chomp or die;
1403         printdebug(">|$_|\n");
1404         push @rows, $_;
1405     }
1406     $!=0; $?=0; close P or failedcmd @cmd;
1407     @rows or die;
1408     my $nrows = pop @rows;
1409     $nrows =~ s/^\((\d+) rows?\)$/$1/ or die "$nrows ?";
1410     @rows == $nrows+1 or die "$nrows ".(scalar @rows)." ?";
1411     @rows = map { [ split /\|/, $_ ] } @rows;
1412     my $ncols = scalar @{ shift @rows };
1413     die if grep { scalar @$_ != $ncols } @rows;
1414     return @rows;
1415 }
1416
1417 sub sql_injection_check {
1418     foreach (@_) { die "$_ $& ?" if m{[^-+=:_.,/0-9a-zA-Z]}; }
1419 }
1420
1421 sub archive_query_sshpsql ($$) {
1422     my ($proto,$data) = @_;
1423     sql_injection_check $isuite, $package;
1424     my @rows = sshpsql($data, "archive-query $isuite $package", <<END);
1425         SELECT source.version, component.name, files.filename, files.sha256sum
1426           FROM source
1427           JOIN src_associations ON source.id = src_associations.source
1428           JOIN suite ON suite.id = src_associations.suite
1429           JOIN dsc_files ON dsc_files.source = source.id
1430           JOIN files_archive_map ON files_archive_map.file_id = dsc_files.file
1431           JOIN component ON component.id = files_archive_map.component_id
1432           JOIN files ON files.id = dsc_files.file
1433          WHERE ( suite.suite_name='$isuite' OR suite.codename='$isuite' )
1434            AND source.source='$package'
1435            AND files.filename LIKE '%.dsc';
1436 END
1437     @rows = sort { -version_compare($a->[0],$b->[0]) } @rows;
1438     my $digester = Digest::SHA->new(256);
1439     @rows = map {
1440         my ($vsn,$component,$filename,$sha256sum) = @$_;
1441         [ $vsn, "/pool/$component/$filename",$digester,$sha256sum ];
1442     } @rows;
1443     return archive_query_prepend_mirror @rows;
1444 }
1445
1446 sub canonicalise_suite_sshpsql ($$) {
1447     my ($proto,$data) = @_;
1448     sql_injection_check $isuite;
1449     my @rows = sshpsql($data, "canonicalise-suite $isuite", <<END);
1450         SELECT suite.codename
1451           FROM suite where suite_name='$isuite' or codename='$isuite';
1452 END
1453     @rows = map { $_->[0] } @rows;
1454     fail "unknown suite $isuite" unless @rows;
1455     die "ambiguous $isuite: @rows ?" if @rows>1;
1456     return $rows[0];
1457 }
1458
1459 sub file_in_archive_sshpsql ($$$) { return undef; }
1460
1461 #---------- `dummycat' archive query method ----------
1462
1463 sub canonicalise_suite_dummycat ($$) {
1464     my ($proto,$data) = @_;
1465     my $dpath = "$data/suite.$isuite";
1466     if (!open C, "<", $dpath) {
1467         $!==ENOENT or die "$dpath: $!";
1468         printdebug "dummycat canonicalise_suite $isuite $dpath ENOENT\n";
1469         return $isuite;
1470     }
1471     $!=0; $_ = <C>;
1472     chomp or die "$dpath: $!";
1473     close C;
1474     printdebug "dummycat canonicalise_suite $isuite $dpath = $_\n";
1475     return $_;
1476 }
1477
1478 sub archive_query_dummycat ($$) {
1479     my ($proto,$data) = @_;
1480     canonicalise_suite();
1481     my $dpath = "$data/package.$csuite.$package";
1482     if (!open C, "<", $dpath) {
1483         $!==ENOENT or die "$dpath: $!";
1484         printdebug "dummycat query $csuite $package $dpath ENOENT\n";
1485         return ();
1486     }
1487     my @rows;
1488     while (<C>) {
1489         next if m/^\#/;
1490         next unless m/\S/;
1491         die unless chomp;
1492         printdebug "dummycat query $csuite $package $dpath | $_\n";
1493         my @row = split /\s+/, $_;
1494         @row==2 or die "$dpath: $_ ?";
1495         push @rows, \@row;
1496     }
1497     C->error and die "$dpath: $!";
1498     close C;
1499     return archive_query_prepend_mirror
1500         sort { -version_compare($a->[0],$b->[0]); } @rows;
1501 }
1502
1503 sub file_in_archive_dummycat () { return undef; }
1504
1505 #---------- tag format handling ----------
1506
1507 sub access_cfg_tagformats () {
1508     split /\,/, access_cfg('dgit-tag-format');
1509 }
1510
1511 sub access_cfg_tagformats_can_splitbrain () {
1512     my %y = map { $_ => 1 } access_cfg_tagformats;
1513     foreach my $needtf (qw(new maint)) {
1514         next if $y{$needtf};
1515         return 0;
1516     }
1517     return 1;
1518 }
1519
1520 sub need_tagformat ($$) {
1521     my ($fmt, $why) = @_;
1522     fail "need to use tag format $fmt ($why) but also need".
1523         " to use tag format $tagformat_want->[0] ($tagformat_want->[1])".
1524         " - no way to proceed"
1525         if $tagformat_want && $tagformat_want->[0] ne $fmt;
1526     $tagformat_want = [$fmt, $why, $tagformat_want->[2] // 0];
1527 }
1528
1529 sub select_tagformat () {
1530     # sets $tagformatfn
1531     return if $tagformatfn && !$tagformat_want;
1532     die 'bug' if $tagformatfn && $tagformat_want;
1533     # ... $tagformat_want assigned after previous select_tagformat
1534
1535     my (@supported) = grep { $_ =~ m/^(?:old|new)$/ } access_cfg_tagformats();
1536     printdebug "select_tagformat supported @supported\n";
1537
1538     $tagformat_want //= [ $supported[0], "distro access configuration", 0 ];
1539     printdebug "select_tagformat specified @$tagformat_want\n";
1540
1541     my ($fmt,$why,$override) = @$tagformat_want;
1542
1543     fail "target distro supports tag formats @supported".
1544         " but have to use $fmt ($why)"
1545         unless $override
1546             or grep { $_ eq $fmt } @supported;
1547
1548     $tagformat_want = undef;
1549     $tagformat = $fmt;
1550     $tagformatfn = ${*::}{"debiantag_$fmt"};
1551
1552     fail "trying to use unknown tag format \`$fmt' ($why) !"
1553         unless $tagformatfn;
1554 }
1555
1556 #---------- archive query entrypoints and rest of program ----------
1557
1558 sub canonicalise_suite () {
1559     return if defined $csuite;
1560     fail "cannot operate on $isuite suite" if $isuite eq 'UNRELEASED';
1561     $csuite = archive_query('canonicalise_suite');
1562     if ($isuite ne $csuite) {
1563         progress "canonical suite name for $isuite is $csuite";
1564     } else {
1565         progress "canonical suite name is $csuite";
1566     }
1567 }
1568
1569 sub get_archive_dsc () {
1570     canonicalise_suite();
1571     my @vsns = archive_query('archive_query');
1572     foreach my $vinfo (@vsns) {
1573         my ($vsn,$vsn_dscurl,$digester,$digest) = @$vinfo;
1574         $dscurl = $vsn_dscurl;
1575         $dscdata = url_get($dscurl);
1576         if (!$dscdata) {
1577             $skew_warning_vsn = $vsn if !defined $skew_warning_vsn;
1578             next;
1579         }
1580         if ($digester) {
1581             $digester->reset();
1582             $digester->add($dscdata);
1583             my $got = $digester->hexdigest();
1584             $got eq $digest or
1585                 fail "$dscurl has hash $got but".
1586                     " archive told us to expect $digest";
1587         }
1588         parse_dscdata();
1589         my $fmt = getfield $dsc, 'Format';
1590         $format_ok{$fmt} or forceable_fail [qw(unsupported-source-format)],
1591             "unsupported source format $fmt, sorry";
1592
1593         $dsc_checked = !!$digester;
1594         printdebug "get_archive_dsc: Version ".(getfield $dsc, 'Version')."\n";
1595         return;
1596     }
1597     $dsc = undef;
1598     printdebug "get_archive_dsc: nothing in archive, returning undef\n";
1599 }
1600
1601 sub check_for_git ();
1602 sub check_for_git () {
1603     # returns 0 or 1
1604     my $how = access_cfg('git-check');
1605     if ($how eq 'ssh-cmd') {
1606         my @cmd =
1607             (access_cfg_ssh, access_gituserhost(),
1608              access_runeinfo("git-check $package").
1609              " set -e; cd ".access_cfg('git-path').";".
1610              " if test -d $package.git; then echo 1; else echo 0; fi");
1611         my $r= cmdoutput @cmd;
1612         if (defined $r and $r =~ m/^divert (\w+)$/) {
1613             my $divert=$1;
1614             my ($usedistro,) = access_distros();
1615             # NB that if we are pushing, $usedistro will be $distro/push
1616             $instead_distro= cfg("dgit-distro.$usedistro.diverts.$divert");
1617             $instead_distro =~ s{^/}{ access_basedistro()."/" }e;
1618             progress "diverting to $divert (using config for $instead_distro)";
1619             return check_for_git();
1620         }
1621         failedcmd @cmd unless defined $r and $r =~ m/^[01]$/;
1622         return $r+0;
1623     } elsif ($how eq 'url') {
1624         my $prefix = access_cfg('git-check-url','git-url');
1625         my $suffix = access_cfg('git-check-suffix','git-suffix',
1626                                 'RETURN-UNDEF') // '.git';
1627         my $url = "$prefix/$package$suffix";
1628         my @cmd = (@curl, qw(-sS -I), $url);
1629         my $result = cmdoutput @cmd;
1630         $result =~ s/^\S+ 200 .*\n\r?\n//;
1631         # curl -sS -I with https_proxy prints
1632         # HTTP/1.0 200 Connection established
1633         $result =~ m/^\S+ (404|200) /s or
1634             fail "unexpected results from git check query - ".
1635                 Dumper($prefix, $result);
1636         my $code = $1;
1637         if ($code eq '404') {
1638             return 0;
1639         } elsif ($code eq '200') {
1640             return 1;
1641         } else {
1642             die;
1643         }
1644     } elsif ($how eq 'true') {
1645         return 1;
1646     } elsif ($how eq 'false') {
1647         return 0;
1648     } else {
1649         badcfg "unknown git-check \`$how'";
1650     }
1651 }
1652
1653 sub create_remote_git_repo () {
1654     my $how = access_cfg('git-create');
1655     if ($how eq 'ssh-cmd') {
1656         runcmd_ordryrun
1657             (access_cfg_ssh, access_gituserhost(),
1658              access_runeinfo("git-create $package").
1659              "set -e; cd ".access_cfg('git-path').";".
1660              " cp -a _template $package.git");
1661     } elsif ($how eq 'true') {
1662         # nothing to do
1663     } else {
1664         badcfg "unknown git-create \`$how'";
1665     }
1666 }
1667
1668 our ($dsc_hash,$lastpush_mergeinput);
1669 our ($dsc_distro, $dsc_hint_tag, $dsc_hint_url);
1670
1671
1672 sub prep_ud () {
1673     fresh_playground 'dgit/unpack';
1674 }
1675
1676 sub mktree_in_ud_here () {
1677     playtree_setup $gitcfgs{local};
1678 }
1679
1680 sub git_write_tree () {
1681     my $tree = cmdoutput @git, qw(write-tree);
1682     $tree =~ m/^\w+$/ or die "$tree ?";
1683     return $tree;
1684 }
1685
1686 sub git_add_write_tree () {
1687     runcmd @git, qw(add -Af .);
1688     return git_write_tree();
1689 }
1690
1691 sub remove_stray_gits ($) {
1692     my ($what) = @_;
1693     my @gitscmd = qw(find -name .git -prune -print0);
1694     debugcmd "|",@gitscmd;
1695     open GITS, "-|", @gitscmd or die $!;
1696     {
1697         local $/="\0";
1698         while (<GITS>) {
1699             chomp or die;
1700             print STDERR "$us: warning: removing from $what: ",
1701                 (messagequote $_), "\n";
1702             rmtree $_;
1703         }
1704     }
1705     $!=0; $?=0; close GITS or failedcmd @gitscmd;
1706 }
1707
1708 sub mktree_in_ud_from_only_subdir ($;$) {
1709     my ($what,$raw) = @_;
1710
1711     # changes into the subdir
1712     my (@dirs) = <*/.>;
1713     die "expected one subdir but found @dirs ?" unless @dirs==1;
1714     $dirs[0] =~ m#^([^/]+)/\.$# or die;
1715     my $dir = $1;
1716     changedir $dir;
1717
1718     remove_stray_gits($what);
1719     mktree_in_ud_here();
1720     if (!$raw) {
1721         my ($format, $fopts) = get_source_format();
1722         if (madformat($format)) {
1723             rmtree '.pc';
1724         }
1725     }
1726
1727     my $tree=git_add_write_tree();
1728     return ($tree,$dir);
1729 }
1730
1731 our @files_csum_info_fields =
1732     (['Checksums-Sha256','Digest::SHA', 'new(256)', 'sha256sum'],
1733      ['Checksums-Sha1',  'Digest::SHA', 'new(1)',   'sha1sum'],
1734      ['Files',           'Digest::MD5', 'new()',    'md5sum']);
1735
1736 sub dsc_files_info () {
1737     foreach my $csumi (@files_csum_info_fields) {
1738         my ($fname, $module, $method) = @$csumi;
1739         my $field = $dsc->{$fname};
1740         next unless defined $field;
1741         eval "use $module; 1;" or die $@;
1742         my @out;
1743         foreach (split /\n/, $field) {
1744             next unless m/\S/;
1745             m/^(\w+) (\d+) (\S+)$/ or
1746                 fail "could not parse .dsc $fname line \`$_'";
1747             my $digester = eval "$module"."->$method;" or die $@;
1748             push @out, {
1749                 Hash => $1,
1750                 Bytes => $2,
1751                 Filename => $3,
1752                 Digester => $digester,
1753             };
1754         }
1755         return @out;
1756     }
1757     fail "missing any supported Checksums-* or Files field in ".
1758         $dsc->get_option('name');
1759 }
1760
1761 sub dsc_files () {
1762     map { $_->{Filename} } dsc_files_info();
1763 }
1764
1765 sub files_compare_inputs (@) {
1766     my $inputs = \@_;
1767     my %record;
1768     my %fchecked;
1769
1770     my $showinputs = sub {
1771         return join "; ", map { $_->get_option('name') } @$inputs;
1772     };
1773
1774     foreach my $in (@$inputs) {
1775         my $expected_files;
1776         my $in_name = $in->get_option('name');
1777
1778         printdebug "files_compare_inputs $in_name\n";
1779
1780         foreach my $csumi (@files_csum_info_fields) {
1781             my ($fname) = @$csumi;
1782             printdebug "files_compare_inputs $in_name $fname\n";
1783
1784             my $field = $in->{$fname};
1785             next unless defined $field;
1786
1787             my @files;
1788             foreach (split /\n/, $field) {
1789                 next unless m/\S/;
1790
1791                 my ($info, $f) = m/^(\w+ \d+) (?:\S+ \S+ )?(\S+)$/ or
1792                     fail "could not parse $in_name $fname line \`$_'";
1793
1794                 printdebug "files_compare_inputs $in_name $fname $f\n";
1795
1796                 push @files, $f;
1797
1798                 my $re = \ $record{$f}{$fname};
1799                 if (defined $$re) {
1800                     $fchecked{$f}{$in_name} = 1;
1801                     $$re eq $info or
1802                         fail "hash or size of $f varies in $fname fields".
1803                         " (between: ".$showinputs->().")";
1804                 } else {
1805                     $$re = $info;
1806                 }
1807             }
1808             @files = sort @files;
1809             $expected_files //= \@files;
1810             "@$expected_files" eq "@files" or
1811                 fail "file list in $in_name varies between hash fields!";
1812         }
1813         $expected_files or
1814             fail "$in_name has no files list field(s)";
1815     }
1816     printdebug "files_compare_inputs ".Dumper(\%fchecked, \%record)
1817         if $debuglevel>=2;
1818
1819     grep { keys %$_ == @$inputs-1 } values %fchecked
1820         or fail "no file appears in all file lists".
1821         " (looked in: ".$showinputs->().")";
1822 }
1823
1824 sub is_orig_file_in_dsc ($$) {
1825     my ($f, $dsc_files_info) = @_;
1826     return 0 if @$dsc_files_info <= 1;
1827     # One file means no origs, and the filename doesn't have a "what
1828     # part of dsc" component.  (Consider versions ending `.orig'.)
1829     return 0 unless $f =~ m/\.$orig_f_tail_re$/o;
1830     return 1;
1831 }
1832
1833 sub is_orig_file_of_vsn ($$) {
1834     my ($f, $upstreamvsn) = @_;
1835     my $base = srcfn $upstreamvsn, '';
1836     return 0 unless $f =~ m/^\Q$base\E\.$orig_f_tail_re$/;
1837     return 1;
1838 }
1839
1840 sub changes_update_origs_from_dsc ($$$$) {
1841     my ($dsc, $changes, $upstreamvsn, $changesfile) = @_;
1842     my %changes_f;
1843     printdebug "checking origs needed ($upstreamvsn)...\n";
1844     $_ = getfield $changes, 'Files';
1845     m/^\w+ \d+ (\S+ \S+) \S+$/m or
1846         fail "cannot find section/priority from .changes Files field";
1847     my $placementinfo = $1;
1848     my %changed;
1849     printdebug "checking origs needed placement '$placementinfo'...\n";
1850     foreach my $l (split /\n/, getfield $dsc, 'Files') {
1851         $l =~ m/\S+$/ or next;
1852         my $file = $&;
1853         printdebug "origs $file | $l\n";
1854         next unless is_orig_file_of_vsn $file, $upstreamvsn;
1855         printdebug "origs $file is_orig\n";
1856         my $have = archive_query('file_in_archive', $file);
1857         if (!defined $have) {
1858             print STDERR <<END;
1859 archive does not support .orig check; hope you used --ch:--sa/-sd if needed
1860 END
1861             return;
1862         }
1863         my $found_same = 0;
1864         my @found_differ;
1865         printdebug "origs $file \$#\$have=$#$have\n";
1866         foreach my $h (@$have) {
1867             my $same = 0;
1868             my @differ;
1869             foreach my $csumi (@files_csum_info_fields) {
1870                 my ($fname, $module, $method, $archivefield) = @$csumi;
1871                 next unless defined $h->{$archivefield};
1872                 $_ = $dsc->{$fname};
1873                 next unless defined;
1874                 m/^(\w+) .* \Q$file\E$/m or
1875                     fail ".dsc $fname missing entry for $file";
1876                 if ($h->{$archivefield} eq $1) {
1877                     $same++;
1878                 } else {
1879                     push @differ,
1880  "$archivefield: $h->{$archivefield} (archive) != $1 (local .dsc)";
1881                 }
1882             }
1883             die "$file ".Dumper($h)." ?!" if $same && @differ;
1884             $found_same++
1885                 if $same;
1886             push @found_differ, "archive $h->{filename}: ".join "; ", @differ
1887                 if @differ;
1888         }
1889         printdebug "origs $file f.same=$found_same".
1890             " #f._differ=$#found_differ\n";
1891         if (@found_differ && !$found_same) {
1892             fail join "\n",
1893                 "archive contains $file with different checksum",
1894                 @found_differ;
1895         }
1896         # Now we edit the changes file to add or remove it
1897         foreach my $csumi (@files_csum_info_fields) {
1898             my ($fname, $module, $method, $archivefield) = @$csumi;
1899             next unless defined $changes->{$fname};
1900             if ($found_same) {
1901                 # in archive, delete from .changes if it's there
1902                 $changed{$file} = "removed" if
1903                     $changes->{$fname} =~ s/^.* \Q$file\E$(?:)\n//m;
1904             } elsif ($changes->{$fname} =~ m/^.* \Q$file\E$(?:)\n/m) {
1905                 # not in archive, but it's here in the .changes
1906             } else {
1907                 my $dsc_data = getfield $dsc, $fname;
1908                 $dsc_data =~ m/^(.* \Q$file\E$)\n/m or die "$dsc_data $file ?";
1909                 my $extra = $1;
1910                 $extra =~ s/ \d+ /$&$placementinfo /
1911                     or die "$fname $extra >$dsc_data< ?"
1912                     if $fname eq 'Files';
1913                 $changes->{$fname} .= "\n". $extra;
1914                 $changed{$file} = "added";
1915             }
1916         }
1917     }
1918     if (%changed) {
1919         foreach my $file (keys %changed) {
1920             progress sprintf
1921                 "edited .changes for archive .orig contents: %s %s",
1922                 $changed{$file}, $file;
1923         }
1924         my $chtmp = "$changesfile.tmp";
1925         $changes->save($chtmp);
1926         if (act_local()) {
1927             rename $chtmp,$changesfile or die "$changesfile $!";
1928         } else {
1929             progress "[new .changes left in $changesfile]";
1930         }
1931     } else {
1932         progress "$changesfile already has appropriate .orig(s) (if any)";
1933     }
1934 }
1935
1936 sub make_commit ($) {
1937     my ($file) = @_;
1938     return cmdoutput @git, qw(hash-object -w -t commit), $file;
1939 }
1940
1941 sub make_commit_text ($) {
1942     my ($text) = @_;
1943     my ($out, $in);
1944     my @cmd = (@git, qw(hash-object -w -t commit --stdin));
1945     debugcmd "|",@cmd;
1946     print Dumper($text) if $debuglevel > 1;
1947     my $child = open2($out, $in, @cmd) or die $!;
1948     my $h;
1949     eval {
1950         print $in $text or die $!;
1951         close $in or die $!;
1952         $h = <$out>;
1953         $h =~ m/^\w+$/ or die;
1954         $h = $&;
1955         printdebug "=> $h\n";
1956     };
1957     close $out;
1958     waitpid $child, 0 == $child or die "$child $!";
1959     $? and failedcmd @cmd;
1960     return $h;
1961 }
1962
1963 sub clogp_authline ($) {
1964     my ($clogp) = @_;
1965     my $author = getfield $clogp, 'Maintainer';
1966     if ($author =~ m/^[^"\@]+\,/) {
1967         # single entry Maintainer field with unquoted comma
1968         $author = ($& =~ y/,//rd).$'; # strip the comma
1969     }
1970     # git wants a single author; any remaining commas in $author
1971     # are by now preceded by @ (or ").  It seems safer to punt on
1972     # "..." for now rather than attempting to dequote or something.
1973     $author =~ s#,.*##ms unless $author =~ m/"/;
1974     my $date = cmdoutput qw(date), '+%s %z', qw(-d), getfield($clogp,'Date');
1975     my $authline = "$author $date";
1976     $authline =~ m/$git_authline_re/o or
1977         fail "unexpected commit author line format \`$authline'".
1978         " (was generated from changelog Maintainer field)";
1979     return ($1,$2,$3) if wantarray;
1980     return $authline;
1981 }
1982
1983 sub vendor_patches_distro ($$) {
1984     my ($checkdistro, $what) = @_;
1985     return unless defined $checkdistro;
1986
1987     my $series = "debian/patches/\L$checkdistro\E.series";
1988     printdebug "checking for vendor-specific $series ($what)\n";
1989
1990     if (!open SERIES, "<", $series) {
1991         die "$series $!" unless $!==ENOENT;
1992         return;
1993     }
1994     while (<SERIES>) {
1995         next unless m/\S/;
1996         next if m/^\s+\#/;
1997
1998         print STDERR <<END;
1999
2000 Unfortunately, this source package uses a feature of dpkg-source where
2001 the same source package unpacks to different source code on different
2002 distros.  dgit cannot safely operate on such packages on affected
2003 distros, because the meaning of source packages is not stable.
2004
2005 Please ask the distro/maintainer to remove the distro-specific series
2006 files and use a different technique (if necessary, uploading actually
2007 different packages, if different distros are supposed to have
2008 different code).
2009
2010 END
2011         fail "Found active distro-specific series file for".
2012             " $checkdistro ($what): $series, cannot continue";
2013     }
2014     die "$series $!" if SERIES->error;
2015     close SERIES;
2016 }
2017
2018 sub check_for_vendor_patches () {
2019     # This dpkg-source feature doesn't seem to be documented anywhere!
2020     # But it can be found in the changelog (reformatted):
2021
2022     #   commit  4fa01b70df1dc4458daee306cfa1f987b69da58c
2023     #   Author: Raphael Hertzog <hertzog@debian.org>
2024     #   Date: Sun  Oct  3  09:36:48  2010 +0200
2025
2026     #   dpkg-source: correctly create .pc/.quilt_series with alternate
2027     #   series files
2028     #
2029     #   If you have debian/patches/ubuntu.series and you were
2030     #   unpacking the source package on ubuntu, quilt was still
2031     #   directed to debian/patches/series instead of
2032     #   debian/patches/ubuntu.series.
2033     #
2034     #   debian/changelog                        |    3 +++
2035     #   scripts/Dpkg/Source/Package/V3/quilt.pm |    4 +++-
2036     #   2 files changed, 6 insertions(+), 1 deletion(-)
2037
2038     use Dpkg::Vendor;
2039     vendor_patches_distro($ENV{DEB_VENDOR}, "DEB_VENDOR");
2040     vendor_patches_distro(Dpkg::Vendor::get_current_vendor(),
2041                          "Dpkg::Vendor \`current vendor'");
2042     vendor_patches_distro(access_basedistro(),
2043                           "(base) distro being accessed");
2044     vendor_patches_distro(access_nomdistro(),
2045                           "(nominal) distro being accessed");
2046 }
2047
2048 sub generate_commits_from_dsc () {
2049     # See big comment in fetch_from_archive, below.
2050     # See also README.dsc-import.
2051     prep_ud();
2052     changedir $playground;
2053
2054     my @dfi = dsc_files_info();
2055     foreach my $fi (@dfi) {
2056         my $f = $fi->{Filename};
2057         die "$f ?" if $f =~ m#/|^\.|\.dsc$|\.tmp$#;
2058         my $upper_f = "../../../../$f";
2059
2060         printdebug "considering reusing $f: ";
2061
2062         if (link_ltarget "$upper_f,fetch", $f) {
2063             printdebug "linked (using ...,fetch).\n";
2064         } elsif ((printdebug "($!) "),
2065                  $! != ENOENT) {
2066             fail "accessing ../$f,fetch: $!";
2067         } elsif (link_ltarget $upper_f, $f) {
2068             printdebug "linked.\n";
2069         } elsif ((printdebug "($!) "),
2070                  $! != ENOENT) {
2071             fail "accessing ../$f: $!";
2072         } else {
2073             printdebug "absent.\n";
2074         }
2075
2076         my $refetched;
2077         complete_file_from_dsc('.', $fi, \$refetched)
2078             or next;
2079
2080         printdebug "considering saving $f: ";
2081
2082         if (link $f, $upper_f) {
2083             printdebug "linked.\n";
2084         } elsif ((printdebug "($!) "),
2085                  $! != EEXIST) {
2086             fail "saving ../$f: $!";
2087         } elsif (!$refetched) {
2088             printdebug "no need.\n";
2089         } elsif (link $f, "$upper_f,fetch") {
2090             printdebug "linked (using ...,fetch).\n";
2091         } elsif ((printdebug "($!) "),
2092                  $! != EEXIST) {
2093             fail "saving ../$f,fetch: $!";
2094         } else {
2095             printdebug "cannot.\n";
2096         }
2097     }
2098
2099     # We unpack and record the orig tarballs first, so that we only
2100     # need disk space for one private copy of the unpacked source.
2101     # But we can't make them into commits until we have the metadata
2102     # from the debian/changelog, so we record the tree objects now and
2103     # make them into commits later.
2104     my @tartrees;
2105     my $upstreamv = upstreamversion $dsc->{version};
2106     my $orig_f_base = srcfn $upstreamv, '';
2107
2108     foreach my $fi (@dfi) {
2109         # We actually import, and record as a commit, every tarball
2110         # (unless there is only one file, in which case there seems
2111         # little point.
2112
2113         my $f = $fi->{Filename};
2114         printdebug "import considering $f ";
2115         (printdebug "only one dfi\n"), next if @dfi == 1;
2116         (printdebug "not tar\n"), next unless $f =~ m/\.tar(\.\w+)?$/;
2117         (printdebug "signature\n"), next if $f =~ m/$orig_f_sig_re$/o;
2118         my $compr_ext = $1;
2119
2120         my ($orig_f_part) =
2121             $f =~ m/^\Q$orig_f_base\E\.([^._]+)?\.tar(?:\.\w+)?$/;
2122
2123         printdebug "Y ", (join ' ', map { $_//"(none)" }
2124                           $compr_ext, $orig_f_part
2125                          ), "\n";
2126
2127         my $input = new IO::File $f, '<' or die "$f $!";
2128         my $compr_pid;
2129         my @compr_cmd;
2130
2131         if (defined $compr_ext) {
2132             my $cname =
2133                 Dpkg::Compression::compression_guess_from_filename $f;
2134             fail "Dpkg::Compression cannot handle file $f in source package"
2135                 if defined $compr_ext && !defined $cname;
2136             my $compr_proc =
2137                 new Dpkg::Compression::Process compression => $cname;
2138             @compr_cmd = $compr_proc->get_uncompress_cmdline();
2139             my $compr_fh = new IO::Handle;
2140             my $compr_pid = open $compr_fh, "-|" // die $!;
2141             if (!$compr_pid) {
2142                 open STDIN, "<&", $input or die $!;
2143                 exec @compr_cmd;
2144                 die "dgit (child): exec $compr_cmd[0]: $!\n";
2145             }
2146             $input = $compr_fh;
2147         }
2148
2149         rmtree "_unpack-tar";
2150         mkdir "_unpack-tar" or die $!;
2151         my @tarcmd = qw(tar -x -f -
2152                         --no-same-owner --no-same-permissions
2153                         --no-acls --no-xattrs --no-selinux);
2154         my $tar_pid = fork // die $!;
2155         if (!$tar_pid) {
2156             chdir "_unpack-tar" or die $!;
2157             open STDIN, "<&", $input or die $!;
2158             exec @tarcmd;
2159             die "dgit (child): exec $tarcmd[0]: $!";
2160         }
2161         $!=0; (waitpid $tar_pid, 0) == $tar_pid or die $!;
2162         !$? or failedcmd @tarcmd;
2163
2164         close $input or
2165             (@compr_cmd ? ($?==SIGPIPE || failedcmd @compr_cmd)
2166              : die $!);
2167         # finally, we have the results in "tarball", but maybe
2168         # with the wrong permissions
2169
2170         runcmd qw(chmod -R +rwX _unpack-tar);
2171         changedir "_unpack-tar";
2172         remove_stray_gits($f);
2173         mktree_in_ud_here();
2174
2175         my ($tree) = git_add_write_tree();
2176         my $tentries = cmdoutput @git, qw(ls-tree -z), $tree;
2177         if ($tentries =~ m/^\d+ tree (\w+)\t[^\000]+\000$/s) {
2178             $tree = $1;
2179             printdebug "one subtree $1\n";
2180         } else {
2181             printdebug "multiple subtrees\n";
2182         }
2183         changedir "..";
2184         rmtree "_unpack-tar";
2185
2186         my $ent = [ $f, $tree ];
2187         push @tartrees, {
2188             Orig => !!$orig_f_part,
2189             Sort => (!$orig_f_part         ? 2 :
2190                      $orig_f_part =~ m/-/g ? 1 :
2191                                              0),
2192             F => $f,
2193             Tree => $tree,
2194         };
2195     }
2196
2197     @tartrees = sort {
2198         # put any without "_" first (spec is not clear whether files
2199         # are always in the usual order).  Tarballs without "_" are
2200         # the main orig or the debian tarball.
2201         $a->{Sort} <=> $b->{Sort} or
2202         $a->{F}    cmp $b->{F}
2203     } @tartrees;
2204
2205     my $any_orig = grep { $_->{Orig} } @tartrees;
2206
2207     my $dscfn = "$package.dsc";
2208
2209     my $treeimporthow = 'package';
2210
2211     open D, ">", $dscfn or die "$dscfn: $!";
2212     print D $dscdata or die "$dscfn: $!";
2213     close D or die "$dscfn: $!";
2214     my @cmd = qw(dpkg-source);
2215     push @cmd, '--no-check' if $dsc_checked;
2216     if (madformat $dsc->{format}) {
2217         push @cmd, '--skip-patches';
2218         $treeimporthow = 'unpatched';
2219     }
2220     push @cmd, qw(-x --), $dscfn;
2221     runcmd @cmd;
2222
2223     my ($tree,$dir) = mktree_in_ud_from_only_subdir("source package");
2224     if (madformat $dsc->{format}) {
2225         check_for_vendor_patches();
2226     }
2227
2228     my $dappliedtree;
2229     if (madformat $dsc->{format}) {
2230         my @pcmd = qw(dpkg-source --before-build .);
2231         runcmd shell_cmd 'exec >/dev/null', @pcmd;
2232         rmtree '.pc';
2233         $dappliedtree = git_add_write_tree();
2234     }
2235
2236     my @clogcmd = qw(dpkg-parsechangelog --format rfc822 --all);
2237     debugcmd "|",@clogcmd;
2238     open CLOGS, "-|", @clogcmd or die $!;
2239
2240     my $clogp;
2241     my $r1clogp;
2242
2243     printdebug "import clog search...\n";
2244
2245     for (;;) {
2246         my $stanzatext = do { local $/=""; <CLOGS>; };
2247         printdebug "import clogp ".Dumper($stanzatext) if $debuglevel>1;
2248         last if !defined $stanzatext;
2249
2250         my $desc = "package changelog, entry no.$.";
2251         open my $stanzafh, "<", \$stanzatext or die;
2252         my $thisstanza = parsecontrolfh $stanzafh, $desc, 1;
2253         $clogp //= $thisstanza;
2254
2255         printdebug "import clog $thisstanza->{version} $desc...\n";
2256
2257         last if !$any_orig; # we don't need $r1clogp
2258
2259         # We look for the first (most recent) changelog entry whose
2260         # version number is lower than the upstream version of this
2261         # package.  Then the last (least recent) previous changelog
2262         # entry is treated as the one which introduced this upstream
2263         # version and used for the synthetic commits for the upstream
2264         # tarballs.
2265
2266         # One might think that a more sophisticated algorithm would be
2267         # necessary.  But: we do not want to scan the whole changelog
2268         # file.  Stopping when we see an earlier version, which
2269         # necessarily then is an earlier upstream version, is the only
2270         # realistic way to do that.  Then, either the earliest
2271         # changelog entry we have seen so far is indeed the earliest
2272         # upload of this upstream version; or there are only changelog
2273         # entries relating to later upstream versions (which is not
2274         # possible unless the changelog and .dsc disagree about the
2275         # version).  Then it remains to choose between the physically
2276         # last entry in the file, and the one with the lowest version
2277         # number.  If these are not the same, we guess that the
2278         # versions were created in a non-monotic order rather than
2279         # that the changelog entries have been misordered.
2280
2281         printdebug "import clog $thisstanza->{version} vs $upstreamv...\n";
2282
2283         last if version_compare($thisstanza->{version}, $upstreamv) < 0;
2284         $r1clogp = $thisstanza;
2285
2286         printdebug "import clog $r1clogp->{version} becomes r1\n";
2287     }
2288     die $! if CLOGS->error;
2289     close CLOGS or $?==SIGPIPE or failedcmd @clogcmd;
2290
2291     $clogp or fail "package changelog has no entries!";
2292
2293     my $authline = clogp_authline $clogp;
2294     my $changes = getfield $clogp, 'Changes';
2295     $changes =~ s/^\n//; # Changes: \n
2296     my $cversion = getfield $clogp, 'Version';
2297
2298     if (@tartrees) {
2299         $r1clogp //= $clogp; # maybe there's only one entry;
2300         my $r1authline = clogp_authline $r1clogp;
2301         # Strictly, r1authline might now be wrong if it's going to be
2302         # unused because !$any_orig.  Whatever.
2303
2304         printdebug "import tartrees authline   $authline\n";
2305         printdebug "import tartrees r1authline $r1authline\n";
2306
2307         foreach my $tt (@tartrees) {
2308             printdebug "import tartree $tt->{F} $tt->{Tree}\n";
2309
2310             $tt->{Commit} = make_commit_text($tt->{Orig} ? <<END_O : <<END_T);
2311 tree $tt->{Tree}
2312 author $r1authline
2313 committer $r1authline
2314
2315 Import $tt->{F}
2316
2317 [dgit import orig $tt->{F}]
2318 END_O
2319 tree $tt->{Tree}
2320 author $authline
2321 committer $authline
2322
2323 Import $tt->{F}
2324
2325 [dgit import tarball $package $cversion $tt->{F}]
2326 END_T
2327         }
2328     }
2329
2330     printdebug "import main commit\n";
2331
2332     open C, ">../commit.tmp" or die $!;
2333     print C <<END or die $!;
2334 tree $tree
2335 END
2336     print C <<END or die $! foreach @tartrees;
2337 parent $_->{Commit}
2338 END
2339     print C <<END or die $!;
2340 author $authline
2341 committer $authline
2342
2343 $changes
2344
2345 [dgit import $treeimporthow $package $cversion]
2346 END
2347
2348     close C or die $!;
2349     my $rawimport_hash = make_commit qw(../commit.tmp);
2350
2351     if (madformat $dsc->{format}) {
2352         printdebug "import apply patches...\n";
2353
2354         # regularise the state of the working tree so that
2355         # the checkout of $rawimport_hash works nicely.
2356         my $dappliedcommit = make_commit_text(<<END);
2357 tree $dappliedtree
2358 author $authline
2359 committer $authline
2360
2361 [dgit dummy commit]
2362 END
2363         runcmd @git, qw(checkout -q -b dapplied), $dappliedcommit;
2364
2365         runcmd @git, qw(checkout -q -b unpa), $rawimport_hash;
2366
2367         # We need the answers to be reproducible
2368         my @authline = clogp_authline($clogp);
2369         local $ENV{GIT_COMMITTER_NAME} =  $authline[0];
2370         local $ENV{GIT_COMMITTER_EMAIL} = $authline[1];
2371         local $ENV{GIT_COMMITTER_DATE} =  $authline[2];
2372         local $ENV{GIT_AUTHOR_NAME} =  $authline[0];
2373         local $ENV{GIT_AUTHOR_EMAIL} = $authline[1];
2374         local $ENV{GIT_AUTHOR_DATE} =  $authline[2];
2375
2376         my $path = $ENV{PATH} or die;
2377
2378         foreach my $use_absurd (qw(0 1)) {
2379             runcmd @git, qw(checkout -q unpa);
2380             runcmd @git, qw(update-ref -d refs/heads/patch-queue/unpa);
2381             local $ENV{PATH} = $path;
2382             if ($use_absurd) {
2383                 chomp $@;
2384                 progress "warning: $@";
2385                 $path = "$absurdity:$path";
2386                 progress "$us: trying slow absurd-git-apply...";
2387                 rename "../../gbp-pq-output","../../gbp-pq-output.0"
2388                     or $!==ENOENT
2389                     or die $!;
2390             }
2391             eval {
2392                 die "forbid absurd git-apply\n" if $use_absurd
2393                     && forceing [qw(import-gitapply-no-absurd)];
2394                 die "only absurd git-apply!\n" if !$use_absurd
2395                     && forceing [qw(import-gitapply-absurd)];
2396
2397                 local $ENV{DGIT_ABSURD_DEBUG} = $debuglevel if $use_absurd;
2398                 local $ENV{PATH} = $path                    if $use_absurd;
2399
2400                 my @showcmd = (gbp_pq, qw(import));
2401                 my @realcmd = shell_cmd
2402                     'exec >/dev/null 2>>../../gbp-pq-output', @showcmd;
2403                 debugcmd "+",@realcmd;
2404                 if (system @realcmd) {
2405                     die +(shellquote @showcmd).
2406                         " failed: ".
2407                         failedcmd_waitstatus()."\n";
2408                 }
2409
2410                 my $gapplied = git_rev_parse('HEAD');
2411                 my $gappliedtree = cmdoutput @git, qw(rev-parse HEAD:);
2412                 $gappliedtree eq $dappliedtree or
2413                     fail <<END;
2414 gbp-pq import and dpkg-source disagree!
2415  gbp-pq import gave commit $gapplied
2416  gbp-pq import gave tree $gappliedtree
2417  dpkg-source --before-build gave tree $dappliedtree
2418 END
2419                 $rawimport_hash = $gapplied;
2420             };
2421             last unless $@;
2422         }
2423         if ($@) {
2424             { local $@; eval { runcmd qw(cat ../../gbp-pq-output); }; }
2425             die $@;
2426         }
2427     }
2428
2429     progress "synthesised git commit from .dsc $cversion";
2430
2431     my $rawimport_mergeinput = {
2432         Commit => $rawimport_hash,
2433         Info => "Import of source package",
2434     };
2435     my @output = ($rawimport_mergeinput);
2436
2437     if ($lastpush_mergeinput) {
2438         my $oldclogp = mergeinfo_getclogp($lastpush_mergeinput);
2439         my $oversion = getfield $oldclogp, 'Version';
2440         my $vcmp =
2441             version_compare($oversion, $cversion);
2442         if ($vcmp < 0) {
2443             @output = ($rawimport_mergeinput, $lastpush_mergeinput,
2444                 { Message => <<END, ReverseParents => 1 });
2445 Record $package ($cversion) in archive suite $csuite
2446 END
2447         } elsif ($vcmp > 0) {
2448             print STDERR <<END or die $!;
2449
2450 Version actually in archive:   $cversion (older)
2451 Last version pushed with dgit: $oversion (newer or same)
2452 $later_warning_msg
2453 END
2454             @output = $lastpush_mergeinput;
2455         } else {
2456             # Same version.  Use what's in the server git branch,
2457             # discarding our own import.  (This could happen if the
2458             # server automatically imports all packages into git.)
2459             @output = $lastpush_mergeinput;
2460         }
2461     }
2462     changedir $maindir;
2463     rmtree $playground;
2464     return @output;
2465 }
2466
2467 sub complete_file_from_dsc ($$;$) {
2468     our ($dstdir, $fi, $refetched) = @_;
2469     # Ensures that we have, in $dstdir, the file $fi, with the correct
2470     # contents.  (Downloading it from alongside $dscurl if necessary.)
2471     # If $refetched is defined, can overwrite "$dstdir/$fi->{Filename}"
2472     # and will set $$refetched=1 if it did so (or tried to).
2473
2474     my $f = $fi->{Filename};
2475     my $tf = "$dstdir/$f";
2476     my $downloaded = 0;
2477
2478     my $got;
2479     my $checkhash = sub {
2480         open F, "<", "$tf" or die "$tf: $!";
2481         $fi->{Digester}->reset();
2482         $fi->{Digester}->addfile(*F);
2483         F->error and die $!;
2484         $got = $fi->{Digester}->hexdigest();
2485         return $got eq $fi->{Hash};
2486     };
2487
2488     if (stat_exists $tf) {
2489         if ($checkhash->()) {
2490             progress "using existing $f";
2491             return 1;
2492         }
2493         if (!$refetched) {
2494             fail "file $f has hash $got but .dsc".
2495                 " demands hash $fi->{Hash} ".
2496                 "(perhaps you should delete this file?)";
2497         }
2498         progress "need to fetch correct version of $f";
2499         unlink $tf or die "$tf $!";
2500         $$refetched = 1;
2501     } else {
2502         printdebug "$tf does not exist, need to fetch\n";
2503     }
2504
2505     my $furl = $dscurl;
2506     $furl =~ s{/[^/]+$}{};
2507     $furl .= "/$f";
2508     die "$f ?" unless $f =~ m/^\Q${package}\E_/;
2509     die "$f ?" if $f =~ m#/#;
2510     runcmd_ordryrun_local @curl,qw(-f -o),$tf,'--',"$furl";
2511     return 0 if !act_local();
2512
2513     $checkhash->() or
2514         fail "file $f has hash $got but .dsc".
2515             " demands hash $fi->{Hash} ".
2516             "(got wrong file from archive!)";
2517
2518     return 1;
2519 }
2520
2521 sub ensure_we_have_orig () {
2522     my @dfi = dsc_files_info();
2523     foreach my $fi (@dfi) {
2524         my $f = $fi->{Filename};
2525         next unless is_orig_file_in_dsc($f, \@dfi);
2526         complete_file_from_dsc('..', $fi)
2527             or next;
2528     }
2529 }
2530
2531 #---------- git fetch ----------
2532
2533 sub lrfetchrefs () { return "refs/dgit-fetch/".access_basedistro(); }
2534 sub lrfetchref () { return lrfetchrefs.'/'.server_branch($csuite); }
2535
2536 # We fetch some parts of lrfetchrefs/*.  Ideally we delete these
2537 # locally fetched refs because they have unhelpful names and clutter
2538 # up gitk etc.  So we track whether we have "used up" head ref (ie,
2539 # whether we have made another local ref which refers to this object).
2540 #
2541 # (If we deleted them unconditionally, then we might end up
2542 # re-fetching the same git objects each time dgit fetch was run.)
2543 #
2544 # So, each use of lrfetchrefs needs to be accompanied by arrangements
2545 # in git_fetch_us to fetch the refs in question, and possibly a call
2546 # to lrfetchref_used.
2547
2548 our (%lrfetchrefs_f, %lrfetchrefs_d);
2549 # $lrfetchrefs_X{lrfetchrefs."/heads/whatever"} = $objid
2550
2551 sub lrfetchref_used ($) {
2552     my ($fullrefname) = @_;
2553     my $objid = $lrfetchrefs_f{$fullrefname};
2554     $lrfetchrefs_d{$fullrefname} = $objid if defined $objid;
2555 }
2556
2557 sub git_lrfetch_sane {
2558     my ($url, $supplementary, @specs) = @_;
2559     # Make a 'refs/'.lrfetchrefs.'/*' be just like on server,
2560     # at least as regards @specs.  Also leave the results in
2561     # %lrfetchrefs_f, and arrange for lrfetchref_used to be
2562     # able to clean these up.
2563     #
2564     # With $supplementary==1, @specs must not contain wildcards
2565     # and we add to our previous fetches (non-atomically).
2566
2567     # This is rather miserable:
2568     # When git fetch --prune is passed a fetchspec ending with a *,
2569     # it does a plausible thing.  If there is no * then:
2570     # - it matches subpaths too, even if the supplied refspec
2571     #   starts refs, and behaves completely madly if the source
2572     #   has refs/refs/something.  (See, for example, Debian #NNNN.)
2573     # - if there is no matching remote ref, it bombs out the whole
2574     #   fetch.
2575     # We want to fetch a fixed ref, and we don't know in advance
2576     # if it exists, so this is not suitable.
2577     #
2578     # Our workaround is to use git ls-remote.  git ls-remote has its
2579     # own qairks.  Notably, it has the absurd multi-tail-matching
2580     # behaviour: git ls-remote R refs/foo can report refs/foo AND
2581     # refs/refs/foo etc.
2582     #
2583     # Also, we want an idempotent snapshot, but we have to make two
2584     # calls to the remote: one to git ls-remote and to git fetch.  The
2585     # solution is use git ls-remote to obtain a target state, and
2586     # git fetch to try to generate it.  If we don't manage to generate
2587     # the target state, we try again.
2588
2589     printdebug "git_lrfetch_sane suppl=$supplementary specs @specs\n";
2590
2591     my $specre = join '|', map {
2592         my $x = $_;
2593         $x =~ s/\W/\\$&/g;
2594         my $wildcard = $x =~ s/\\\*$/.*/;
2595         die if $wildcard && $supplementary;
2596         "(?:refs/$x)";
2597     } @specs;
2598     printdebug "git_lrfetch_sane specre=$specre\n";
2599     my $wanted_rref = sub {
2600         local ($_) = @_;
2601         return m/^(?:$specre)$/;
2602     };
2603
2604     my $fetch_iteration = 0;
2605     FETCH_ITERATION:
2606     for (;;) {
2607         printdebug "git_lrfetch_sane iteration $fetch_iteration\n";
2608         if (++$fetch_iteration > 10) {
2609             fail "too many iterations trying to get sane fetch!";
2610         }
2611
2612         my @look = map { "refs/$_" } @specs;
2613         my @lcmd = (@git, qw(ls-remote -q --refs), $url, @look);
2614         debugcmd "|",@lcmd;
2615
2616         my %wantr;
2617         open GITLS, "-|", @lcmd or die $!;
2618         while (<GITLS>) {
2619             printdebug "=> ", $_;
2620             m/^(\w+)\s+(\S+)\n/ or die "ls-remote $_ ?";
2621             my ($objid,$rrefname) = ($1,$2);
2622             if (!$wanted_rref->($rrefname)) {
2623                 print STDERR <<END;
2624 warning: git ls-remote @look reported $rrefname; this is silly, ignoring it.
2625 END
2626                 next;
2627             }
2628             $wantr{$rrefname} = $objid;
2629         }
2630         $!=0; $?=0;
2631         close GITLS or failedcmd @lcmd;
2632
2633         # OK, now %want is exactly what we want for refs in @specs
2634         my @fspecs = map {
2635             !m/\*$/ && !exists $wantr{"refs/$_"} ? () :
2636             "+refs/$_:".lrfetchrefs."/$_";
2637         } @specs;
2638
2639         printdebug "git_lrfetch_sane fspecs @fspecs\n";
2640
2641         my @fcmd = (@git, qw(fetch -p -n -q), $url, @fspecs);
2642         runcmd_ordryrun_local @fcmd if @fspecs;
2643
2644         if (!$supplementary) {
2645             %lrfetchrefs_f = ();
2646         }
2647         my %objgot;
2648
2649         git_for_each_ref(lrfetchrefs, sub {
2650             my ($objid,$objtype,$lrefname,$reftail) = @_;
2651             $lrfetchrefs_f{$lrefname} = $objid;
2652             $objgot{$objid} = 1;
2653         });
2654
2655         if ($supplementary) {
2656             last;
2657         }
2658
2659         foreach my $lrefname (sort keys %lrfetchrefs_f) {
2660             my $rrefname = 'refs'.substr($lrefname, length lrfetchrefs);
2661             if (!exists $wantr{$rrefname}) {
2662                 if ($wanted_rref->($rrefname)) {
2663                     printdebug <<END;
2664 git-fetch @fspecs created $lrefname which git ls-remote @look didn't list.
2665 END
2666                 } else {
2667                     print STDERR <<END
2668 warning: git fetch @fspecs created $lrefname; this is silly, deleting it.
2669 END
2670                 }
2671                 runcmd_ordryrun_local @git, qw(update-ref -d), $lrefname;
2672                 delete $lrfetchrefs_f{$lrefname};
2673                 next;
2674             }
2675         }
2676         foreach my $rrefname (sort keys %wantr) {
2677             my $lrefname = lrfetchrefs.substr($rrefname, 4);
2678             my $got = $lrfetchrefs_f{$lrefname} // '<none>';
2679             my $want = $wantr{$rrefname};
2680             next if $got eq $want;
2681             if (!defined $objgot{$want}) {
2682                 print STDERR <<END;
2683 warning: git ls-remote suggests we want $lrefname
2684 warning:  and it should refer to $want
2685 warning:  but git fetch didn't fetch that object to any relevant ref.
2686 warning:  This may be due to a race with someone updating the server.
2687 warning:  Will try again...
2688 END
2689                 next FETCH_ITERATION;
2690             }
2691             printdebug <<END;
2692 git-fetch @fspecs made $lrefname=$got but want git ls-remote @look says $want
2693 END
2694             runcmd_ordryrun_local @git, qw(update-ref -m),
2695                 "dgit fetch git fetch fixup", $lrefname, $want;
2696             $lrfetchrefs_f{$lrefname} = $want;
2697         }
2698         last;
2699     }
2700
2701     if (defined $csuite) {
2702         printdebug "git_lrfetch_sane: tidying any old suite lrfetchrefs\n";
2703         git_for_each_ref("refs/dgit-fetch/$csuite", sub {
2704             my ($objid,$objtype,$lrefname,$reftail) = @_;
2705             next if $lrfetchrefs_f{$lrefname}; # $csuite eq $distro ?
2706             runcmd_ordryrun_local @git, qw(update-ref -d), $lrefname;
2707         });
2708     }
2709
2710     printdebug "git_lrfetch_sane: git fetch --no-insane emulation complete\n",
2711         Dumper(\%lrfetchrefs_f);
2712 }
2713
2714 sub git_fetch_us () {
2715     # Want to fetch only what we are going to use, unless
2716     # deliberately-not-ff, in which case we must fetch everything.
2717
2718     my @specs = deliberately_not_fast_forward ? qw(tags/*) :
2719         map { "tags/$_" }
2720         (quiltmode_splitbrain
2721          ? (map { $_->('*',access_nomdistro) }
2722             \&debiantag_new, \&debiantag_maintview)
2723          : debiantags('*',access_nomdistro));
2724     push @specs, server_branch($csuite);
2725     push @specs, $rewritemap;
2726     push @specs, qw(heads/*) if deliberately_not_fast_forward;
2727
2728     my $url = access_giturl();
2729     git_lrfetch_sane $url, 0, @specs;
2730
2731     my %here;
2732     my @tagpats = debiantags('*',access_nomdistro);
2733
2734     git_for_each_ref([map { "refs/tags/$_" } @tagpats], sub {
2735         my ($objid,$objtype,$fullrefname,$reftail) = @_;
2736         printdebug "currently $fullrefname=$objid\n";
2737         $here{$fullrefname} = $objid;
2738     });
2739     git_for_each_ref([map { lrfetchrefs."/tags/".$_ } @tagpats], sub {
2740         my ($objid,$objtype,$fullrefname,$reftail) = @_;
2741         my $lref = "refs".substr($fullrefname, length(lrfetchrefs));
2742         printdebug "offered $lref=$objid\n";
2743         if (!defined $here{$lref}) {
2744             my @upd = (@git, qw(update-ref), $lref, $objid, '');
2745             runcmd_ordryrun_local @upd;
2746             lrfetchref_used $fullrefname;
2747         } elsif ($here{$lref} eq $objid) {
2748             lrfetchref_used $fullrefname;
2749         } else {
2750             print STDERR
2751                 "Not updating $lref from $here{$lref} to $objid.\n";
2752         }
2753     });
2754 }
2755
2756 #---------- dsc and archive handling ----------
2757
2758 sub mergeinfo_getclogp ($) {
2759     # Ensures thit $mi->{Clogp} exists and returns it
2760     my ($mi) = @_;
2761     $mi->{Clogp} = commit_getclogp($mi->{Commit});
2762 }
2763
2764 sub mergeinfo_version ($) {
2765     return getfield( (mergeinfo_getclogp $_[0]), 'Version' );
2766 }
2767
2768 sub fetch_from_archive_record_1 ($) {
2769     my ($hash) = @_;
2770     runcmd @git, qw(update-ref -m), "dgit fetch $csuite",
2771             'DGIT_ARCHIVE', $hash;
2772     cmdoutput @git, qw(log -n2), $hash;
2773     # ... gives git a chance to complain if our commit is malformed
2774 }
2775
2776 sub fetch_from_archive_record_2 ($) {
2777     my ($hash) = @_;
2778     my @upd_cmd = (@git, qw(update-ref -m), 'dgit fetch', lrref(), $hash);
2779     if (act_local()) {
2780         cmdoutput @upd_cmd;
2781     } else {
2782         dryrun_report @upd_cmd;
2783     }
2784 }
2785
2786 sub parse_dsc_field_def_dsc_distro () {
2787     $dsc_distro //= cfg qw(dgit.default.old-dsc-distro
2788                            dgit.default.distro);
2789 }
2790
2791 sub parse_dsc_field ($$) {
2792     my ($dsc, $what) = @_;
2793     my $f;
2794     foreach my $field (@ourdscfield) {
2795         $f = $dsc->{$field};
2796         last if defined $f;
2797     }
2798
2799     if (!defined $f) {
2800         progress "$what: NO git hash";
2801         parse_dsc_field_def_dsc_distro();
2802     } elsif (($dsc_hash, $dsc_distro, $dsc_hint_tag, $dsc_hint_url)
2803              = $f =~ m/^(\w+)\s+($distro_re)\s+($versiontag_re)\s+(\S+)(?:\s|$)/) {
2804         progress "$what: specified git info ($dsc_distro)";
2805         $dsc_hint_tag = [ $dsc_hint_tag ];
2806     } elsif ($f =~ m/^\w+\s*$/) {
2807         $dsc_hash = $&;
2808         parse_dsc_field_def_dsc_distro();
2809         $dsc_hint_tag = [ debiantags +(getfield $dsc, 'Version'),
2810                           $dsc_distro ];
2811         progress "$what: specified git hash";
2812     } else {
2813         fail "$what: invalid Dgit info";
2814     }
2815 }
2816
2817 sub resolve_dsc_field_commit ($$) {
2818     my ($already_distro, $already_mapref) = @_;
2819
2820     return unless defined $dsc_hash;
2821
2822     my $mapref =
2823         defined $already_mapref &&
2824         ($already_distro eq $dsc_distro || !$chase_dsc_distro)
2825         ? $already_mapref : undef;
2826
2827     my $do_fetch;
2828     $do_fetch = sub {
2829         my ($what, @fetch) = @_;
2830
2831         local $idistro = $dsc_distro;
2832         my $lrf = lrfetchrefs;
2833
2834         if (!$chase_dsc_distro) {
2835             progress
2836                 "not chasing .dsc distro $dsc_distro: not fetching $what";
2837             return 0;
2838         }
2839
2840         progress
2841             ".dsc names distro $dsc_distro: fetching $what";
2842
2843         my $url = access_giturl();
2844         if (!defined $url) {
2845             defined $dsc_hint_url or fail <<END;
2846 .dsc Dgit metadata is in context of distro $dsc_distro
2847 for which we have no configured url and .dsc provides no hint
2848 END
2849             my $proto =
2850                 $dsc_hint_url =~ m#^([-+0-9a-zA-Z]+):# ? $1 :
2851                 $dsc_hint_url =~ m#^/# ? 'file' : 'bad-syntax';
2852             parse_cfg_bool "dsc-url-proto-ok", 'false',
2853                 cfg("dgit.dsc-url-proto-ok.$proto",
2854                     "dgit.default.dsc-url-proto-ok")
2855                 or fail <<END;
2856 .dsc Dgit metadata is in context of distro $dsc_distro
2857 for which we have no configured url;
2858 .dsc provides hinted url with protocol $proto which is unsafe.
2859 (can be overridden by config - consult documentation)
2860 END
2861             $url = $dsc_hint_url;
2862         }
2863
2864         git_lrfetch_sane $url, 1, @fetch;
2865
2866         return $lrf;
2867     };
2868
2869     my $rewrite_enable = do {
2870         local $idistro = $dsc_distro;
2871         access_cfg('rewrite-map-enable', 'RETURN-UNDEF');
2872     };
2873
2874     if (parse_cfg_bool 'rewrite-map-enable', 'true', $rewrite_enable) {
2875         if (!defined $mapref) {
2876             my $lrf = $do_fetch->("rewrite map", $rewritemap) or return;
2877             $mapref = $lrf.'/'.$rewritemap;
2878         }
2879         my $rewritemapdata = git_cat_file $mapref.':map';
2880         if (defined $rewritemapdata
2881             && $rewritemapdata =~ m/^$dsc_hash(?:[ \t](\w+))/m) {
2882             progress
2883                 "server's git history rewrite map contains a relevant entry!";
2884
2885             $dsc_hash = $1;
2886             if (defined $dsc_hash) {
2887                 progress "using rewritten git hash in place of .dsc value";
2888             } else {
2889                 progress "server data says .dsc hash is to be disregarded";
2890             }
2891         }
2892     }
2893
2894     if (!defined git_cat_file $dsc_hash) {
2895         my @tags = map { "tags/".$_ } @$dsc_hint_tag;
2896         my $lrf = $do_fetch->("additional commits", @tags) &&
2897             defined git_cat_file $dsc_hash
2898             or fail <<END;
2899 .dsc Dgit metadata requires commit $dsc_hash
2900 but we could not obtain that object anywhere.
2901 END
2902         foreach my $t (@tags) {
2903             my $fullrefname = $lrf.'/'.$t;
2904 #           print STDERR "CHK $t $fullrefname ".Dumper(\%lrfetchrefs_f);
2905             next unless $lrfetchrefs_f{$fullrefname};
2906             next unless is_fast_fwd "$fullrefname~0", $dsc_hash;
2907             lrfetchref_used $fullrefname;
2908         }
2909     }
2910 }
2911
2912 sub fetch_from_archive () {
2913     ensure_setup_existing_tree();
2914
2915     # Ensures that lrref() is what is actually in the archive, one way
2916     # or another, according to us - ie this client's
2917     # appropritaely-updated archive view.  Also returns the commit id.
2918     # If there is nothing in the archive, leaves lrref alone and
2919     # returns undef.  git_fetch_us must have already been called.
2920     get_archive_dsc();
2921
2922     if ($dsc) {
2923         parse_dsc_field($dsc, 'last upload to archive');
2924         resolve_dsc_field_commit access_basedistro,
2925             lrfetchrefs."/".$rewritemap
2926     } else {
2927         progress "no version available from the archive";
2928     }
2929
2930     # If the archive's .dsc has a Dgit field, there are three
2931     # relevant git commitids we need to choose between and/or merge
2932     # together:
2933     #   1. $dsc_hash: the Dgit field from the archive
2934     #   2. $lastpush_hash: the suite branch on the dgit git server
2935     #   3. $lastfetch_hash: our local tracking brach for the suite
2936     #
2937     # These may all be distinct and need not be in any fast forward
2938     # relationship:
2939     #
2940     # If the dsc was pushed to this suite, then the server suite
2941     # branch will have been updated; but it might have been pushed to
2942     # a different suite and copied by the archive.  Conversely a more
2943     # recent version may have been pushed with dgit but not appeared
2944     # in the archive (yet).
2945     #
2946     # $lastfetch_hash may be awkward because archive imports
2947     # (particularly, imports of Dgit-less .dscs) are performed only as
2948     # needed on individual clients, so different clients may perform a
2949     # different subset of them - and these imports are only made
2950     # public during push.  So $lastfetch_hash may represent a set of
2951     # imports different to a subsequent upload by a different dgit
2952     # client.
2953     #
2954     # Our approach is as follows:
2955     #
2956     # As between $dsc_hash and $lastpush_hash: if $lastpush_hash is a
2957     # descendant of $dsc_hash, then it was pushed by a dgit user who
2958     # had based their work on $dsc_hash, so we should prefer it.
2959     # Otherwise, $dsc_hash was installed into this suite in the
2960     # archive other than by a dgit push, and (necessarily) after the
2961     # last dgit push into that suite (since a dgit push would have
2962     # been descended from the dgit server git branch); thus, in that
2963     # case, we prefer the archive's version (and produce a
2964     # pseudo-merge to overwrite the dgit server git branch).
2965     #
2966     # (If there is no Dgit field in the archive's .dsc then
2967     # generate_commit_from_dsc uses the version numbers to decide
2968     # whether the suite branch or the archive is newer.  If the suite
2969     # branch is newer it ignores the archive's .dsc; otherwise it
2970     # generates an import of the .dsc, and produces a pseudo-merge to
2971     # overwrite the suite branch with the archive contents.)
2972     #
2973     # The outcome of that part of the algorithm is the `public view',
2974     # and is same for all dgit clients: it does not depend on any
2975     # unpublished history in the local tracking branch.
2976     #
2977     # As between the public view and the local tracking branch: The
2978     # local tracking branch is only updated by dgit fetch, and
2979     # whenever dgit fetch runs it includes the public view in the
2980     # local tracking branch.  Therefore if the public view is not
2981     # descended from the local tracking branch, the local tracking
2982     # branch must contain history which was imported from the archive
2983     # but never pushed; and, its tip is now out of date.  So, we make
2984     # a pseudo-merge to overwrite the old imports and stitch the old
2985     # history in.
2986     #
2987     # Finally: we do not necessarily reify the public view (as
2988     # described above).  This is so that we do not end up stacking two
2989     # pseudo-merges.  So what we actually do is figure out the inputs
2990     # to any public view pseudo-merge and put them in @mergeinputs.
2991
2992     my @mergeinputs;
2993     # $mergeinputs[]{Commit}
2994     # $mergeinputs[]{Info}
2995     # $mergeinputs[0] is the one whose tree we use
2996     # @mergeinputs is in the order we use in the actual commit)
2997     #
2998     # Also:
2999     # $mergeinputs[]{Message} is a commit message to use
3000     # $mergeinputs[]{ReverseParents} if def specifies that parent
3001     #                                list should be in opposite order
3002     # Such an entry has no Commit or Info.  It applies only when found
3003     # in the last entry.  (This ugliness is to support making
3004     # identical imports to previous dgit versions.)
3005
3006     my $lastpush_hash = git_get_ref(lrfetchref());
3007     printdebug "previous reference hash=$lastpush_hash\n";
3008     $lastpush_mergeinput = $lastpush_hash && {
3009         Commit => $lastpush_hash,
3010         Info => "dgit suite branch on dgit git server",
3011     };
3012
3013     my $lastfetch_hash = git_get_ref(lrref());
3014     printdebug "fetch_from_archive: lastfetch=$lastfetch_hash\n";
3015     my $lastfetch_mergeinput = $lastfetch_hash && {
3016         Commit => $lastfetch_hash,
3017         Info => "dgit client's archive history view",
3018     };
3019
3020     my $dsc_mergeinput = $dsc_hash && {
3021         Commit => $dsc_hash,
3022         Info => "Dgit field in .dsc from archive",
3023     };
3024
3025     my $cwd = getcwd();
3026     my $del_lrfetchrefs = sub {
3027         changedir $cwd;
3028         my $gur;
3029         printdebug "del_lrfetchrefs...\n";
3030         foreach my $fullrefname (sort keys %lrfetchrefs_d) {
3031             my $objid = $lrfetchrefs_d{$fullrefname};
3032             printdebug "del_lrfetchrefs: $objid $fullrefname\n";
3033             if (!$gur) {
3034                 $gur ||= new IO::Handle;
3035                 open $gur, "|-", qw(git update-ref --stdin) or die $!;
3036             }
3037             printf $gur "delete %s %s\n", $fullrefname, $objid;
3038         }
3039         if ($gur) {
3040             close $gur or failedcmd "git update-ref delete lrfetchrefs";
3041         }
3042     };
3043
3044     if (defined $dsc_hash) {
3045         ensure_we_have_orig();
3046         if (!$lastpush_hash || $dsc_hash eq $lastpush_hash) {
3047             @mergeinputs = $dsc_mergeinput
3048         } elsif (is_fast_fwd($dsc_hash,$lastpush_hash)) {
3049             print STDERR <<END or die $!;
3050
3051 Git commit in archive is behind the last version allegedly pushed/uploaded.
3052 Commit referred to by archive: $dsc_hash
3053 Last version pushed with dgit: $lastpush_hash
3054 $later_warning_msg
3055 END
3056             @mergeinputs = ($lastpush_mergeinput);
3057         } else {
3058             # Archive has .dsc which is not a descendant of the last dgit
3059             # push.  This can happen if the archive moves .dscs about.
3060             # Just follow its lead.
3061             if (is_fast_fwd($lastpush_hash,$dsc_hash)) {
3062                 progress "archive .dsc names newer git commit";
3063                 @mergeinputs = ($dsc_mergeinput);
3064             } else {
3065                 progress "archive .dsc names other git commit, fixing up";
3066                 @mergeinputs = ($dsc_mergeinput, $lastpush_mergeinput);
3067             }
3068         }
3069     } elsif ($dsc) {
3070         @mergeinputs = generate_commits_from_dsc();
3071         # We have just done an import.  Now, our import algorithm might
3072         # have been improved.  But even so we do not want to generate
3073         # a new different import of the same package.  So if the
3074         # version numbers are the same, just use our existing version.
3075         # If the version numbers are different, the archive has changed
3076         # (perhaps, rewound).
3077         if ($lastfetch_mergeinput &&
3078             !version_compare( (mergeinfo_version $lastfetch_mergeinput),
3079                               (mergeinfo_version $mergeinputs[0]) )) {
3080             @mergeinputs = ($lastfetch_mergeinput);
3081         }
3082     } elsif ($lastpush_hash) {
3083         # only in git, not in the archive yet
3084         @mergeinputs = ($lastpush_mergeinput);
3085         print STDERR <<END or die $!;
3086
3087 Package not found in the archive, but has allegedly been pushed using dgit.
3088 $later_warning_msg
3089 END
3090     } else {
3091         printdebug "nothing found!\n";
3092         if (defined $skew_warning_vsn) {
3093             print STDERR <<END or die $!;
3094
3095 Warning: relevant archive skew detected.
3096 Archive allegedly contains $skew_warning_vsn
3097 But we were not able to obtain any version from the archive or git.
3098
3099 END
3100         }
3101         unshift @end, $del_lrfetchrefs;
3102         return undef;
3103     }
3104
3105     if ($lastfetch_hash &&
3106         !grep {
3107             my $h = $_->{Commit};
3108             $h and is_fast_fwd($lastfetch_hash, $h);
3109             # If true, one of the existing parents of this commit
3110             # is a descendant of the $lastfetch_hash, so we'll
3111             # be ff from that automatically.
3112         } @mergeinputs
3113         ) {
3114         # Otherwise:
3115         push @mergeinputs, $lastfetch_mergeinput;
3116     }
3117
3118     printdebug "fetch mergeinfos:\n";
3119     foreach my $mi (@mergeinputs) {
3120         if ($mi->{Info}) {
3121             printdebug " commit $mi->{Commit} $mi->{Info}\n";
3122         } else {
3123             printdebug sprintf " ReverseParents=%d Message=%s",
3124                 $mi->{ReverseParents}, $mi->{Message};
3125         }
3126     }
3127
3128     my $compat_info= pop @mergeinputs
3129         if $mergeinputs[$#mergeinputs]{Message};
3130
3131     @mergeinputs = grep { defined $_->{Commit} } @mergeinputs;
3132
3133     my $hash;
3134     if (@mergeinputs > 1) {
3135         # here we go, then:
3136         my $tree_commit = $mergeinputs[0]{Commit};
3137
3138         my $tree = cmdoutput @git, qw(cat-file commit), $tree_commit;
3139         $tree =~ m/\n\n/;  $tree = $`;
3140         $tree =~ m/^tree (\w+)$/m or die "$dsc_hash tree ?";
3141         $tree = $1;
3142
3143         # We use the changelog author of the package in question the
3144         # author of this pseudo-merge.  This is (roughly) correct if
3145         # this commit is simply representing aa non-dgit upload.
3146         # (Roughly because it does not record sponsorship - but we
3147         # don't have sponsorship info because that's in the .changes,
3148         # which isn't in the archivw.)
3149         #
3150         # But, it might be that we are representing archive history
3151         # updates (including in-archive copies).  These are not really
3152         # the responsibility of the person who created the .dsc, but
3153         # there is no-one whose name we should better use.  (The
3154         # author of the .dsc-named commit is clearly worse.)
3155
3156         my $useclogp = mergeinfo_getclogp $mergeinputs[0];
3157         my $author = clogp_authline $useclogp;
3158         my $cversion = getfield $useclogp, 'Version';
3159
3160         my $mcf = ".git/dgit/mergecommit";
3161         open MC, ">", $mcf or die "$mcf $!";
3162         print MC <<END or die $!;
3163 tree $tree
3164 END
3165
3166         my @parents = grep { $_->{Commit} } @mergeinputs;
3167         @parents = reverse @parents if $compat_info->{ReverseParents};
3168         print MC <<END or die $! foreach @parents;
3169 parent $_->{Commit}
3170 END
3171
3172         print MC <<END or die $!;
3173 author $author
3174 committer $author
3175
3176 END
3177
3178         if (defined $compat_info->{Message}) {
3179             print MC $compat_info->{Message} or die $!;
3180         } else {
3181             print MC <<END or die $!;
3182 Record $package ($cversion) in archive suite $csuite
3183
3184 Record that
3185 END
3186             my $message_add_info = sub {
3187                 my ($mi) = (@_);
3188                 my $mversion = mergeinfo_version $mi;
3189                 printf MC "  %-20s %s\n", $mversion, $mi->{Info}
3190                     or die $!;
3191             };
3192
3193             $message_add_info->($mergeinputs[0]);
3194             print MC <<END or die $!;
3195 should be treated as descended from
3196 END
3197             $message_add_info->($_) foreach @mergeinputs[1..$#mergeinputs];
3198         }
3199
3200         close MC or die $!;
3201         $hash = make_commit $mcf;
3202     } else {
3203         $hash = $mergeinputs[0]{Commit};
3204     }
3205     printdebug "fetch hash=$hash\n";
3206
3207     my $chkff = sub {
3208         my ($lasth, $what) = @_;
3209         return unless $lasth;
3210         die "$lasth $hash $what ?" unless is_fast_fwd($lasth, $hash);
3211     };
3212
3213     $chkff->($lastpush_hash, 'dgit repo server tip (last push)')
3214         if $lastpush_hash;
3215     $chkff->($lastfetch_hash, 'local tracking tip (last fetch)');
3216
3217     fetch_from_archive_record_1($hash);
3218
3219     if (defined $skew_warning_vsn) {
3220         mkpath '.git/dgit';
3221         printdebug "SKEW CHECK WANT $skew_warning_vsn\n";
3222         my $gotclogp = commit_getclogp($hash);
3223         my $got_vsn = getfield $gotclogp, 'Version';
3224         printdebug "SKEW CHECK GOT $got_vsn\n";
3225         if (version_compare($got_vsn, $skew_warning_vsn) < 0) {
3226             print STDERR <<END or die $!;
3227
3228 Warning: archive skew detected.  Using the available version:
3229 Archive allegedly contains    $skew_warning_vsn
3230 We were able to obtain only   $got_vsn
3231
3232 END
3233         }
3234     }
3235
3236     if ($lastfetch_hash ne $hash) {
3237         fetch_from_archive_record_2($hash);
3238     }
3239
3240     lrfetchref_used lrfetchref();
3241
3242     check_gitattrs($hash, "fetched source tree");
3243
3244     unshift @end, $del_lrfetchrefs;
3245     return $hash;
3246 }
3247
3248 sub set_local_git_config ($$) {
3249     my ($k, $v) = @_;
3250     runcmd @git, qw(config), $k, $v;
3251 }
3252
3253 sub setup_mergechangelogs (;$) {
3254     my ($always) = @_;
3255     return unless $always || access_cfg_bool(1, 'setup-mergechangelogs');
3256
3257     my $driver = 'dpkg-mergechangelogs';
3258     my $cb = "merge.$driver";
3259     my $attrs = '.git/info/attributes';
3260     ensuredir '.git/info';
3261
3262     open NATTRS, ">", "$attrs.new" or die "$attrs.new $!";
3263     if (!open ATTRS, "<", $attrs) {
3264         $!==ENOENT or die "$attrs: $!";
3265     } else {
3266         while (<ATTRS>) {
3267             chomp;
3268             next if m{^debian/changelog\s};
3269             print NATTRS $_, "\n" or die $!;
3270         }
3271         ATTRS->error and die $!;
3272         close ATTRS;
3273     }
3274     print NATTRS "debian/changelog merge=$driver\n" or die $!;
3275     close NATTRS;
3276
3277     set_local_git_config "$cb.name", 'debian/changelog merge driver';
3278     set_local_git_config "$cb.driver", 'dpkg-mergechangelogs -m %O %A %B %A';
3279
3280     rename "$attrs.new", "$attrs" or die "$attrs: $!";
3281 }
3282
3283 sub setup_useremail (;$) {
3284     my ($always) = @_;
3285     return unless $always || access_cfg_bool(1, 'setup-useremail');
3286
3287     my $setup = sub {
3288         my ($k, $envvar) = @_;
3289         my $v = access_cfg("user-$k", 'RETURN-UNDEF') // $ENV{$envvar};
3290         return unless defined $v;
3291         set_local_git_config "user.$k", $v;
3292     };
3293
3294     $setup->('email', 'DEBEMAIL');
3295     $setup->('name', 'DEBFULLNAME');
3296 }
3297
3298 sub ensure_setup_existing_tree () {
3299     my $k = "remote.$remotename.skipdefaultupdate";
3300     my $c = git_get_config $k;
3301     return if defined $c;
3302     set_local_git_config $k, 'true';
3303 }
3304
3305 sub open_gitattrs () {
3306     my $gai = new IO::File ".git/info/attributes"
3307         or $!==ENOENT
3308         or die "open .git/info/attributes: $!";
3309     return $gai;
3310 }
3311
3312 sub is_gitattrs_setup () {
3313     my $gai = open_gitattrs();
3314     return 0 unless $gai;
3315     while (<$gai>) {
3316         return 1 if m{^\[attr\]dgit-defuse-attrs\s};
3317     }
3318     $gai->error and die $!;
3319     return 0;
3320 }
3321
3322 sub setup_gitattrs (;$) {
3323     my ($always) = @_;
3324     return unless $always || access_cfg_bool(1, 'setup-gitattributes');
3325
3326     if (is_gitattrs_setup()) {
3327         progress <<END;
3328 [attr]dgit-defuse-attrs already found in .git/info/attributes
3329  not doing further gitattributes setup
3330 END
3331         return;
3332     }
3333     my $af = ".git/info/attributes";
3334     ensuredir '.git/info';
3335     open GAO, "> $af.new" or die $!;
3336     print GAO <<END or die $!;
3337 *       dgit-defuse-attrs
3338 [attr]dgit-defuse-attrs $negate_harmful_gitattrs
3339 # ^ see GITATTRIBUTES in dgit(7) and dgit setup-new-tree in dgit(1)
3340 END
3341     my $gai = open_gitattrs();
3342     if ($gai) {
3343         while (<$gai>) {
3344             chomp;
3345             print GAO $_, "\n" or die $!;
3346         }
3347         $gai->error and die $!;
3348     }
3349     close GAO or die $!;
3350     rename "$af.new", "$af" or die "install $af: $!";
3351 }
3352
3353 sub setup_new_tree () {
3354     setup_mergechangelogs();
3355     setup_useremail();
3356     setup_gitattrs();
3357 }
3358
3359 sub check_gitattrs ($$) {
3360     my ($treeish, $what) = @_;
3361
3362     return if is_gitattrs_setup;
3363
3364     local $/="\0";
3365     my @cmd = (@git, qw(ls-tree -lrz --), "${treeish}:");
3366     debugcmd "|",@cmd;
3367     my $gafl = new IO::File;
3368     open $gafl, "-|", @cmd or die $!;
3369     while (<$gafl>) {
3370         chomp or die;
3371         s/^\d+\s+\w+\s+\w+\s+(\d+)\t// or die;
3372         next if $1 == 0;
3373         next unless m{(?:^|/)\.gitattributes$};
3374
3375         # oh dear, found one
3376         print STDERR <<END;
3377 dgit: warning: $what contains .gitattributes
3378 dgit: .gitattributes have not been defused.  Recommended: dgit setup-new-tree.
3379 END
3380         close $gafl;
3381         return;
3382     }
3383     # tree contains no .gitattributes files
3384     $?=0; $!=0; close $gafl or failedcmd @cmd;
3385 }
3386
3387
3388 sub multisuite_suite_child ($$$) {
3389     my ($tsuite, $merginputs, $fn) = @_;
3390     # in child, sets things up, calls $fn->(), and returns undef
3391     # in parent, returns canonical suite name for $tsuite
3392     my $canonsuitefh = IO::File::new_tmpfile;
3393     my $pid = fork // die $!;
3394     if (!$pid) {
3395         forkcheck_setup();
3396         $isuite = $tsuite;
3397         $us .= " [$isuite]";
3398         $debugprefix .= " ";
3399         progress "fetching $tsuite...";
3400         canonicalise_suite();
3401         print $canonsuitefh $csuite, "\n" or die $!;
3402         close $canonsuitefh or die $!;
3403         $fn->();
3404         return undef;
3405     }
3406     waitpid $pid,0 == $pid or die $!;
3407     fail "failed to obtain $tsuite: ".waitstatusmsg() if $? && $?!=256*4;
3408     seek $canonsuitefh,0,0 or die $!;
3409     local $csuite = <$canonsuitefh>;
3410     die $! unless defined $csuite && chomp $csuite;
3411     if ($? == 256*4) {
3412         printdebug "multisuite $tsuite missing\n";
3413         return $csuite;
3414     }
3415     printdebug "multisuite $tsuite ok (canon=$csuite)\n";
3416     push @$merginputs, {
3417         Ref => lrref,
3418         Info => $csuite,
3419     };
3420     return $csuite;
3421 }
3422
3423 sub fork_for_multisuite ($) {
3424     my ($before_fetch_merge) = @_;
3425     # if nothing unusual, just returns ''
3426     #
3427     # if multisuite:
3428     # returns 0 to caller in child, to do first of the specified suites
3429     # in child, $csuite is not yet set
3430     #
3431     # returns 1 to caller in parent, to finish up anything needed after
3432     # in parent, $csuite is set to canonicalised portmanteau
3433
3434     my $org_isuite = $isuite;
3435     my @suites = split /\,/, $isuite;
3436     return '' unless @suites > 1;
3437     printdebug "fork_for_multisuite: @suites\n";
3438
3439     my @mergeinputs;
3440
3441     my $cbasesuite = multisuite_suite_child($suites[0], \@mergeinputs,
3442                                             sub { });
3443     return 0 unless defined $cbasesuite;
3444
3445     fail "package $package missing in (base suite) $cbasesuite"
3446         unless @mergeinputs;
3447
3448     my @csuites = ($cbasesuite);
3449
3450     $before_fetch_merge->();
3451
3452     foreach my $tsuite (@suites[1..$#suites]) {
3453         $tsuite =~ s/^-/$cbasesuite-/;
3454         my $csubsuite = multisuite_suite_child($tsuite, \@mergeinputs,
3455                                                sub {
3456             @end = ();
3457             fetch();
3458             exit 0;
3459         });
3460         # xxx collecte the ref here
3461
3462         $csubsuite =~ s/^\Q$cbasesuite\E-/-/;
3463         push @csuites, $csubsuite;
3464     }
3465
3466     foreach my $mi (@mergeinputs) {
3467         my $ref = git_get_ref $mi->{Ref};
3468         die "$mi->{Ref} ?" unless length $ref;
3469         $mi->{Commit} = $ref;
3470     }
3471
3472     $csuite = join ",", @csuites;
3473
3474     my $previous = git_get_ref lrref;
3475     if ($previous) {
3476         unshift @mergeinputs, {
3477             Commit => $previous,
3478             Info => "local combined tracking branch",
3479             Warning =>
3480  "archive seems to have rewound: local tracking branch is ahead!",
3481         };
3482     }
3483
3484     foreach my $ix (0..$#mergeinputs) {
3485         $mergeinputs[$ix]{Index} = $ix;
3486     }
3487
3488     @mergeinputs = sort {
3489         -version_compare(mergeinfo_version $a,
3490                          mergeinfo_version $b) # highest version first
3491             or
3492         $a->{Index} <=> $b->{Index}; # earliest in spec first
3493     } @mergeinputs;
3494
3495     my @needed;
3496
3497   NEEDED:
3498     foreach my $mi (@mergeinputs) {
3499         printdebug "multisuite merge check $mi->{Info}\n";
3500         foreach my $previous (@needed) {
3501             next unless is_fast_fwd $mi->{Commit}, $previous->{Commit};
3502             printdebug "multisuite merge un-needed $previous->{Info}\n";
3503             next NEEDED;
3504         }
3505         push @needed, $mi;
3506         printdebug "multisuite merge this-needed\n";
3507         $mi->{Character} = '+';
3508     }
3509
3510     $needed[0]{Character} = '*';
3511
3512     my $output = $needed[0]{Commit};
3513
3514     if (@needed > 1) {
3515         printdebug "multisuite merge nontrivial\n";
3516         my $tree = cmdoutput qw(git rev-parse), $needed[0]{Commit}.':';
3517
3518         my $commit = "tree $tree\n";
3519         my $msg = "Combine archive branches $csuite [dgit]\n\n".
3520             "Input branches:\n";
3521
3522         foreach my $mi (sort { $a->{Index} <=> $b->{Index} } @mergeinputs) {
3523             printdebug "multisuite merge include $mi->{Info}\n";
3524             $mi->{Character} //= ' ';
3525             $commit .= "parent $mi->{Commit}\n";
3526             $msg .= sprintf " %s  %-25s %s\n",
3527                 $mi->{Character},
3528                 (mergeinfo_version $mi),
3529                 $mi->{Info};
3530         }
3531         my $authline = clogp_authline mergeinfo_getclogp $needed[0];
3532         $msg .= "\nKey\n".
3533             " * marks the highest version branch, which choose to use\n".
3534             " + marks each branch which was not already an ancestor\n\n".
3535             "[dgit multi-suite $csuite]\n";
3536         $commit .=
3537             "author $authline\n".
3538             "committer $authline\n\n";
3539         $output = make_commit_text $commit.$msg;
3540         printdebug "multisuite merge generated $output\n";
3541     }
3542
3543     fetch_from_archive_record_1($output);
3544     fetch_from_archive_record_2($output);
3545
3546     progress "calculated combined tracking suite $csuite";
3547
3548     return 1;
3549 }
3550
3551 sub clone_set_head () {
3552     open H, "> .git/HEAD" or die $!;
3553     print H "ref: ".lref()."\n" or die $!;
3554     close H or die $!;
3555 }
3556 sub clone_finish ($) {
3557     my ($dstdir) = @_;
3558     runcmd @git, qw(reset --hard), lrref();
3559     runcmd qw(bash -ec), <<'END';
3560         set -o pipefail
3561         git ls-tree -r --name-only -z HEAD | \
3562         xargs -0r touch -h -r . --
3563 END
3564     printdone "ready for work in $dstdir";
3565 }
3566
3567 sub clone ($) {
3568     # in multisuite, returns twice!
3569     # once in parent after first suite fetched,
3570     # and then again in child after everything is finished
3571     my ($dstdir) = @_;
3572     badusage "dry run makes no sense with clone" unless act_local();
3573
3574     my $multi_fetched = fork_for_multisuite(sub {
3575         printdebug "multi clone before fetch merge\n";
3576         changedir $dstdir;
3577     });
3578     if ($multi_fetched) {
3579         printdebug "multi clone after fetch merge\n";
3580         clone_set_head();
3581         clone_finish($dstdir);
3582         return;
3583     }
3584     printdebug "clone main body\n";
3585
3586     canonicalise_suite();
3587     my $hasgit = check_for_git();
3588     mkdir $dstdir or fail "create \`$dstdir': $!";
3589     changedir $dstdir;
3590     runcmd @git, qw(init -q);
3591     setup_new_tree();
3592     clone_set_head();
3593     my $giturl = access_giturl(1);
3594     if (defined $giturl) {
3595         runcmd @git, qw(remote add), 'origin', $giturl;
3596     }
3597     if ($hasgit) {
3598         progress "fetching existing git history";
3599         git_fetch_us();
3600         runcmd_ordryrun_local @git, qw(fetch origin);
3601     } else {
3602         progress "starting new git history";
3603     }
3604     fetch_from_archive() or no_such_package;
3605     my $vcsgiturl = $dsc->{'Vcs-Git'};
3606     if (length $vcsgiturl) {
3607         $vcsgiturl =~ s/\s+-b\s+\S+//g;
3608         runcmd @git, qw(remote add vcs-git), $vcsgiturl;
3609     }
3610     clone_finish($dstdir);
3611 }
3612
3613 sub fetch () {
3614     canonicalise_suite();
3615     if (check_for_git()) {
3616         git_fetch_us();
3617     }
3618     fetch_from_archive() or no_such_package();
3619     printdone "fetched into ".lrref();
3620 }
3621
3622 sub pull () {
3623     my $multi_fetched = fork_for_multisuite(sub { });
3624     fetch() unless $multi_fetched; # parent
3625     return if $multi_fetched eq '0'; # child
3626     runcmd_ordryrun_local @git, qw(merge -m),"Merge from $csuite [dgit]",
3627         lrref();
3628     printdone "fetched to ".lrref()." and merged into HEAD";
3629 }
3630
3631 sub check_not_dirty () {
3632     foreach my $f (qw(local-options local-patch-header)) {
3633         if (stat_exists "debian/source/$f") {
3634             fail "git tree contains debian/source/$f";
3635         }
3636     }
3637
3638     return if $ignoredirty;
3639
3640     my @cmd = (@git, qw(diff --quiet HEAD));
3641     debugcmd "+",@cmd;
3642     $!=0; $?=-1; system @cmd;
3643     return if !$?;
3644     if ($?==256) {
3645         fail "working tree is dirty (does not match HEAD)";
3646     } else {
3647         failedcmd @cmd;
3648     }
3649 }
3650
3651 sub commit_admin ($) {
3652     my ($m) = @_;
3653     progress "$m";
3654     runcmd_ordryrun_local @git, qw(commit -m), $m;
3655 }
3656
3657 sub commit_quilty_patch () {
3658     my $output = cmdoutput @git, qw(status --porcelain);
3659     my %adds;
3660     foreach my $l (split /\n/, $output) {
3661         next unless $l =~ m/\S/;
3662         if ($l =~ m{^(?:\?\?| M) (.pc|debian/patches)}) {
3663             $adds{$1}++;
3664         }
3665     }
3666     delete $adds{'.pc'}; # if there wasn't one before, don't add it
3667     if (!%adds) {
3668         progress "nothing quilty to commit, ok.";
3669         return;
3670     }
3671     my @adds = map { s/[][*?\\]/\\$&/g; $_; } sort keys %adds;
3672     runcmd_ordryrun_local @git, qw(add -f), @adds;
3673     commit_admin <<END
3674 Commit Debian 3.0 (quilt) metadata
3675
3676 [dgit ($our_version) quilt-fixup]
3677 END
3678 }
3679
3680 sub get_source_format () {
3681     my %options;
3682     if (open F, "debian/source/options") {
3683         while (<F>) {
3684             next if m/^\s*\#/;
3685             next unless m/\S/;
3686             s/\s+$//; # ignore missing final newline
3687             if (m/\s*\#\s*/) {
3688                 my ($k, $v) = ($`, $'); #');
3689                 $v =~ s/^"(.*)"$/$1/;
3690                 $options{$k} = $v;
3691             } else {
3692                 $options{$_} = 1;
3693             }
3694         }
3695         F->error and die $!;
3696         close F;
3697     } else {
3698         die $! unless $!==&ENOENT;
3699     }
3700
3701     if (!open F, "debian/source/format") {
3702         die $! unless $!==&ENOENT;
3703         return '';
3704     }
3705     $_ = <F>;
3706     F->error and die $!;
3707     chomp;
3708     return ($_, \%options);
3709 }
3710
3711 sub madformat_wantfixup ($) {
3712     my ($format) = @_;
3713     return 0 unless $format eq '3.0 (quilt)';
3714     our $quilt_mode_warned;
3715     if ($quilt_mode eq 'nocheck') {
3716         progress "Not doing any fixup of \`$format' due to".
3717             " ----no-quilt-fixup or --quilt=nocheck"
3718             unless $quilt_mode_warned++;
3719         return 0;
3720     }
3721     progress "Format \`$format', need to check/update patch stack"
3722         unless $quilt_mode_warned++;
3723     return 1;
3724 }
3725
3726 sub maybe_split_brain_save ($$$) {
3727     my ($headref, $dgitview, $msg) = @_;
3728     # => message fragment "$saved" describing disposition of $dgitview
3729     return "commit id $dgitview" unless defined $split_brain_save;
3730     my @cmd = (shell_cmd "cd ../../../..",
3731                @git, qw(update-ref -m),
3732                "dgit --dgit-view-save $msg HEAD=$headref",
3733                $split_brain_save, $dgitview);
3734     runcmd @cmd;
3735     return "and left in $split_brain_save";
3736 }
3737
3738 # An "infopair" is a tuple [ $thing, $what ]
3739 # (often $thing is a commit hash; $what is a description)
3740
3741 sub infopair_cond_equal ($$) {
3742     my ($x,$y) = @_;
3743     $x->[0] eq $y->[0] or fail <<END;
3744 $x->[1] ($x->[0]) not equal to $y->[1] ($y->[0])
3745 END
3746 };
3747
3748 sub infopair_lrf_tag_lookup ($$) {
3749     my ($tagnames, $what) = @_;
3750     # $tagname may be an array ref
3751     my @tagnames = ref $tagnames ? @$tagnames : ($tagnames);
3752     printdebug "infopair_lrfetchref_tag_lookup $what @tagnames\n";
3753     foreach my $tagname (@tagnames) {
3754         my $lrefname = lrfetchrefs."/tags/$tagname";
3755         my $tagobj = $lrfetchrefs_f{$lrefname};
3756         next unless defined $tagobj;
3757         printdebug "infopair_lrfetchref_tag_lookup $tagobj $tagname $what\n";
3758         return [ git_rev_parse($tagobj), $what ];
3759     }
3760     fail @tagnames==1 ? <<END : <<END;
3761 Wanted tag $what (@tagnames) on dgit server, but not found
3762 END
3763 Wanted tag $what (one of: @tagnames) on dgit server, but not found
3764 END
3765 }
3766
3767 sub infopair_cond_ff ($$) {
3768     my ($anc,$desc) = @_;
3769     is_fast_fwd($anc->[0], $desc->[0]) or fail <<END;
3770 $anc->[1] ($anc->[0]) .. $desc->[1] ($desc->[0]) is not fast forward
3771 END
3772 };
3773
3774 sub pseudomerge_version_check ($$) {
3775     my ($clogp, $archive_hash) = @_;
3776
3777     my $arch_clogp = commit_getclogp $archive_hash;
3778     my $i_arch_v = [ (getfield $arch_clogp, 'Version'),
3779                      'version currently in archive' ];
3780     if (defined $overwrite_version) {
3781         if (length $overwrite_version) {
3782             infopair_cond_equal([ $overwrite_version,
3783                                   '--overwrite= version' ],
3784                                 $i_arch_v);
3785         } else {
3786             my $v = $i_arch_v->[0];
3787             progress "Checking package changelog for archive version $v ...";
3788             my $cd;
3789             eval {
3790                 my @xa = ("-f$v", "-t$v");
3791                 my $vclogp = parsechangelog @xa;
3792                 my $gf = sub {
3793                     my ($fn) = @_;
3794                     [ (getfield $vclogp, $fn),
3795                       "$fn field from dpkg-parsechangelog @xa" ];
3796                 };
3797                 my $cv = $gf->('Version');
3798                 infopair_cond_equal($i_arch_v, $cv);
3799                 $cd = $gf->('Distribution');
3800             };
3801             if ($@) {
3802                 $@ =~ s/^dgit: //gm;
3803                 fail "$@".
3804                     "Perhaps debian/changelog does not mention $v ?";
3805             }
3806             fail <<END if $cd->[0] =~ m/UNRELEASED/;
3807 $cd->[1] is $cd->[0]
3808 Your tree seems to based on earlier (not uploaded) $v.
3809 END
3810         }
3811     }
3812
3813     printdebug "pseudomerge_version_check i_arch_v @$i_arch_v\n";
3814     return $i_arch_v;
3815 }
3816
3817 sub pseudomerge_make_commit ($$$$ $$) {
3818     my ($clogp, $dgitview, $archive_hash, $i_arch_v,
3819         $msg_cmd, $msg_msg) = @_;
3820     progress "Declaring that HEAD inciudes all changes in $i_arch_v->[0]...";
3821
3822     my $tree = cmdoutput qw(git rev-parse), "${dgitview}:";
3823     my $authline = clogp_authline $clogp;
3824
3825     chomp $msg_msg;
3826     $msg_cmd .=
3827         !defined $overwrite_version ? ""
3828         : !length  $overwrite_version ? " --overwrite"
3829         : " --overwrite=".$overwrite_version;
3830
3831     mkpath '.git/dgit';
3832     my $pmf = ".git/dgit/pseudomerge";
3833     open MC, ">", $pmf or die "$pmf $!";
3834     print MC <<END or die $!;
3835 tree $tree
3836 parent $dgitview
3837 parent $archive_hash
3838 author $authline
3839 committer $authline
3840
3841 $msg_msg
3842
3843 [$msg_cmd]
3844 END
3845     close MC or die $!;
3846
3847     return make_commit($pmf);
3848 }
3849
3850 sub splitbrain_pseudomerge ($$$$) {
3851     my ($clogp, $maintview, $dgitview, $archive_hash) = @_;
3852     # => $merged_dgitview
3853     printdebug "splitbrain_pseudomerge...\n";
3854     #
3855     #     We:      debian/PREVIOUS    HEAD($maintview)
3856     # expect:          o ----------------- o
3857     #                    \                   \
3858     #                     o                   o
3859     #                 a/d/PREVIOUS        $dgitview
3860     #                $archive_hash              \
3861     #  If so,                \                   \
3862     #  we do:                 `------------------ o
3863     #   this:                                   $dgitview'
3864     #
3865
3866     return $dgitview unless defined $archive_hash;
3867     return $dgitview if deliberately_not_fast_forward();
3868
3869     printdebug "splitbrain_pseudomerge...\n";
3870
3871     my $i_arch_v = pseudomerge_version_check($clogp, $archive_hash);
3872
3873     if (!defined $overwrite_version) {
3874         progress "Checking that HEAD inciudes all changes in archive...";
3875     }
3876
3877     return $dgitview if is_fast_fwd $archive_hash, $dgitview;
3878
3879     if (defined $overwrite_version) {
3880     } elsif (!eval {
3881         my $t_dep14 = debiantag_maintview $i_arch_v->[0], access_nomdistro;
3882         my $i_dep14 = infopair_lrf_tag_lookup($t_dep14, "maintainer view tag");
3883         my $t_dgit = debiantag_new $i_arch_v->[0], access_nomdistro;
3884         my $i_dgit = infopair_lrf_tag_lookup($t_dgit, "dgit view tag");
3885         my $i_archive = [ $archive_hash, "current archive contents" ];
3886
3887         printdebug "splitbrain_pseudomerge i_archive @$i_archive\n";
3888
3889         infopair_cond_equal($i_dgit, $i_archive);
3890         infopair_cond_ff($i_dep14, $i_dgit);
3891         infopair_cond_ff($i_dep14, [ $maintview, 'HEAD' ]);
3892         1;
3893     }) {
3894         print STDERR <<END;
3895 $us: check failed (maybe --overwrite is needed, consult documentation)
3896 END
3897         die "$@";
3898     }
3899
3900     my $r = pseudomerge_make_commit
3901         $clogp, $dgitview, $archive_hash, $i_arch_v,
3902         "dgit --quilt=$quilt_mode",
3903         (defined $overwrite_version ? <<END_OVERWR : <<END_MAKEFF);
3904 Declare fast forward from $i_arch_v->[0]
3905 END_OVERWR
3906 Make fast forward from $i_arch_v->[0]
3907 END_MAKEFF
3908
3909     maybe_split_brain_save $maintview, $r, "pseudomerge";
3910
3911     progress "Made pseudo-merge of $i_arch_v->[0] into dgit view.";
3912     return $r;
3913 }
3914
3915 sub plain_overwrite_pseudomerge ($$$) {
3916     my ($clogp, $head, $archive_hash) = @_;
3917
3918     printdebug "plain_overwrite_pseudomerge...";
3919
3920     my $i_arch_v = pseudomerge_version_check($clogp, $archive_hash);
3921
3922     return $head if is_fast_fwd $archive_hash, $head;
3923
3924     my $m = "Declare fast forward from $i_arch_v->[0]";
3925
3926     my $r = pseudomerge_make_commit
3927         $clogp, $head, $archive_hash, $i_arch_v,
3928         "dgit", $m;
3929
3930     runcmd @git, qw(update-ref -m), $m, 'HEAD', $r, $head;
3931
3932     progress "Make pseudo-merge of $i_arch_v->[0] into your HEAD.";
3933     return $r;
3934 }
3935
3936 sub push_parse_changelog ($) {
3937     my ($clogpfn) = @_;
3938
3939     my $clogp = Dpkg::Control::Hash->new();
3940     $clogp->load($clogpfn) or die;
3941
3942     my $clogpackage = getfield $clogp, 'Source';
3943     $package //= $clogpackage;
3944     fail "-p specified $package but changelog specified $clogpackage"
3945         unless $package eq $clogpackage;
3946     my $cversion = getfield $clogp, 'Version';
3947
3948     if (!$we_are_initiator) {
3949         # rpush initiator can't do this because it doesn't have $isuite yet
3950         my $tag = debiantag($cversion, access_nomdistro);
3951         runcmd @git, qw(check-ref-format), $tag;
3952     }
3953
3954     my $dscfn = dscfn($cversion);
3955
3956     return ($clogp, $cversion, $dscfn);
3957 }
3958
3959 sub push_parse_dsc ($$$) {
3960     my ($dscfn,$dscfnwhat, $cversion) = @_;
3961     $dsc = parsecontrol($dscfn,$dscfnwhat);
3962     my $dversion = getfield $dsc, 'Version';
3963     my $dscpackage = getfield $dsc, 'Source';
3964     ($dscpackage eq $package && $dversion eq $cversion) or
3965         fail "$dscfn is for $dscpackage $dversion".
3966             " but debian/changelog is for $package $cversion";
3967 }
3968
3969 sub push_tagwants ($$$$) {
3970     my ($cversion, $dgithead, $maintviewhead, $tfbase) = @_;
3971     my @tagwants;
3972     push @tagwants, {
3973         TagFn => \&debiantag,
3974         Objid => $dgithead,
3975         TfSuffix => '',
3976         View => 'dgit',
3977     };
3978     if (defined $maintviewhead) {
3979         push @tagwants, {
3980             TagFn => \&debiantag_maintview,
3981             Objid => $maintviewhead,
3982             TfSuffix => '-maintview',
3983             View => 'maint',
3984         };
3985     } elsif ($dodep14tag eq 'no' ? 0
3986              : $dodep14tag eq 'want' ? access_cfg_tagformats_can_splitbrain
3987              : $dodep14tag eq 'always'
3988              ? (access_cfg_tagformats_can_splitbrain or fail <<END)
3989 --dep14tag-always (or equivalent in config) means server must support
3990  both "new" and "maint" tag formats, but config says it doesn't.
3991 END
3992             : die "$dodep14tag ?") {
3993         push @tagwants, {
3994             TagFn => \&debiantag_maintview,
3995             Objid => $dgithead,
3996             TfSuffix => '-dgit',
3997             View => 'dgit',
3998         };
3999     };
4000     foreach my $tw (@tagwants) {
4001         $tw->{Tag} = $tw->{TagFn}($cversion, access_nomdistro);
4002         $tw->{Tfn} = sub { $tfbase.$tw->{TfSuffix}.$_[0]; };
4003     }
4004     printdebug 'push_tagwants: ', Dumper(\@_, \@tagwants);
4005     return @tagwants;
4006 }
4007
4008 sub push_mktags ($$ $$ $) {
4009     my ($clogp,$dscfn,
4010         $changesfile,$changesfilewhat,
4011         $tagwants) = @_;
4012
4013     die unless $tagwants->[0]{View} eq 'dgit';
4014
4015     my $declaredistro = access_nomdistro();
4016     my $reader_giturl = do { local $access_forpush=0; access_giturl(); };
4017     $dsc->{$ourdscfield[0]} = join " ",
4018         $tagwants->[0]{Objid}, $declaredistro, $tagwants->[0]{Tag},
4019         $reader_giturl;
4020     $dsc->save("$dscfn.tmp") or die $!;
4021
4022     my $changes = parsecontrol($changesfile,$changesfilewhat);
4023     foreach my $field (qw(Source Distribution Version)) {
4024         $changes->{$field} eq $clogp->{$field} or
4025             fail "changes field $field \`$changes->{$field}'".
4026                 " does not match changelog \`$clogp->{$field}'";
4027     }
4028
4029     my $cversion = getfield $clogp, 'Version';
4030     my $clogsuite = getfield $clogp, 'Distribution';
4031
4032     # We make the git tag by hand because (a) that makes it easier
4033     # to control the "tagger" (b) we can do remote signing
4034     my $authline = clogp_authline $clogp;
4035     my $delibs = join(" ", "",@deliberatelies);
4036
4037     my $mktag = sub {
4038         my ($tw) = @_;
4039         my $tfn = $tw->{Tfn};
4040         my $head = $tw->{Objid};
4041         my $tag = $tw->{Tag};
4042
4043         open TO, '>', $tfn->('.tmp') or die $!;
4044         print TO <<END or die $!;
4045 object $head
4046 type commit
4047 tag $tag
4048 tagger $authline
4049
4050 END
4051         if ($tw->{View} eq 'dgit') {
4052             print TO <<END or die $!;
4053 $package release $cversion for $clogsuite ($csuite) [dgit]
4054 [dgit distro=$declaredistro$delibs]
4055 END
4056             foreach my $ref (sort keys %previously) {
4057                 print TO <<END or die $!;
4058 [dgit previously:$ref=$previously{$ref}]
4059 END
4060             }
4061         } elsif ($tw->{View} eq 'maint') {
4062             print TO <<END or die $!;
4063 $package release $cversion for $clogsuite ($csuite)
4064 (maintainer view tag generated by dgit --quilt=$quilt_mode)
4065 END
4066         } else {
4067             die Dumper($tw)."?";
4068         }
4069
4070         close TO or die $!;
4071
4072         my $tagobjfn = $tfn->('.tmp');
4073         if ($sign) {
4074             if (!defined $keyid) {
4075                 $keyid = access_cfg('keyid','RETURN-UNDEF');
4076             }
4077             if (!defined $keyid) {
4078                 $keyid = getfield $clogp, 'Maintainer';
4079             }
4080             unlink $tfn->('.tmp.asc') or $!==&ENOENT or die $!;
4081             my @sign_cmd = (@gpg, qw(--detach-sign --armor));
4082             push @sign_cmd, qw(-u),$keyid if defined $keyid;
4083             push @sign_cmd, $tfn->('.tmp');
4084             runcmd_ordryrun @sign_cmd;
4085             if (act_scary()) {
4086                 $tagobjfn = $tfn->('.signed.tmp');
4087                 runcmd shell_cmd "exec >$tagobjfn", qw(cat --),
4088                     $tfn->('.tmp'), $tfn->('.tmp.asc');
4089             }
4090         }
4091         return $tagobjfn;
4092     };
4093
4094     my @r = map { $mktag->($_); } @$tagwants;
4095     return @r;
4096 }
4097
4098 sub sign_changes ($) {
4099     my ($changesfile) = @_;
4100     if ($sign) {
4101         my @debsign_cmd = @debsign;
4102         push @debsign_cmd, "-k$keyid" if defined $keyid;
4103         push @debsign_cmd, "-p$gpg[0]" if $gpg[0] ne 'gpg';
4104         push @debsign_cmd, $changesfile;
4105         runcmd_ordryrun @debsign_cmd;
4106     }
4107 }
4108
4109 sub dopush () {
4110     printdebug "actually entering push\n";
4111
4112     supplementary_message(<<'END');
4113 Push failed, while checking state of the archive.
4114 You can retry the push, after fixing the problem, if you like.
4115 END
4116     if (check_for_git()) {
4117         git_fetch_us();
4118     }
4119     my $archive_hash = fetch_from_archive();
4120     if (!$archive_hash) {
4121         $new_package or
4122             fail "package appears to be new in this suite;".
4123                 " if this is intentional, use --new";
4124     }
4125
4126     supplementary_message(<<'END');
4127 Push failed, while preparing your push.
4128 You can retry the push, after fixing the problem, if you like.
4129 END
4130
4131     need_tagformat 'new', "quilt mode $quilt_mode"
4132         if quiltmode_splitbrain;
4133
4134     prep_ud();
4135
4136     access_giturl(); # check that success is vaguely likely
4137     rpush_handle_protovsn_bothends() if $we_are_initiator;
4138     select_tagformat();
4139
4140     my $clogpfn = ".git/dgit/changelog.822.tmp";
4141     runcmd shell_cmd "exec >$clogpfn", qw(dpkg-parsechangelog);
4142
4143     responder_send_file('parsed-changelog', $clogpfn);
4144
4145     my ($clogp, $cversion, $dscfn) =
4146         push_parse_changelog("$clogpfn");
4147
4148     my $dscpath = "$buildproductsdir/$dscfn";
4149     stat_exists $dscpath or
4150         fail "looked for .dsc $dscpath, but $!;".
4151             " maybe you forgot to build";
4152
4153     responder_send_file('dsc', $dscpath);
4154
4155     push_parse_dsc($dscpath, $dscfn, $cversion);
4156
4157     my $format = getfield $dsc, 'Format';
4158     printdebug "format $format\n";
4159
4160     my $actualhead = git_rev_parse('HEAD');
4161     my $dgithead = $actualhead;
4162     my $maintviewhead = undef;
4163
4164     my $upstreamversion = upstreamversion $clogp->{Version};
4165
4166     if (madformat_wantfixup($format)) {
4167         # user might have not used dgit build, so maybe do this now:
4168         if (quiltmode_splitbrain()) {
4169             changedir $playground;
4170             quilt_make_fake_dsc($upstreamversion);
4171             my $cachekey;
4172             ($dgithead, $cachekey) =
4173                 quilt_check_splitbrain_cache($actualhead, $upstreamversion);
4174             $dgithead or fail
4175  "--quilt=$quilt_mode but no cached dgit view:
4176  perhaps tree changed since dgit build[-source] ?";
4177             $split_brain = 1;
4178             $dgithead = splitbrain_pseudomerge($clogp,
4179                                                $actualhead, $dgithead,
4180                                                $archive_hash);
4181             $maintviewhead = $actualhead;
4182             changedir $maindir;
4183             prep_ud(); # so _only_subdir() works, below
4184         } else {
4185             commit_quilty_patch();
4186         }
4187     }
4188
4189     if (defined $overwrite_version && !defined $maintviewhead) {
4190         $dgithead = plain_overwrite_pseudomerge($clogp,
4191                                                 $dgithead,
4192                                                 $archive_hash);
4193     }
4194
4195     check_not_dirty();
4196
4197     my $forceflag = '';
4198     if ($archive_hash) {
4199         if (is_fast_fwd($archive_hash, $dgithead)) {
4200             # ok
4201         } elsif (deliberately_not_fast_forward) {
4202             $forceflag = '+';
4203         } else {
4204             fail "dgit push: HEAD is not a descendant".
4205                 " of the archive's version.\n".
4206                 "To overwrite the archive's contents,".
4207                 " pass --overwrite[=VERSION].\n".
4208                 "To rewind history, if permitted by the archive,".
4209                 " use --deliberately-not-fast-forward.";
4210         }
4211     }
4212
4213     changedir $playground;
4214     progress "checking that $dscfn corresponds to HEAD";
4215     runcmd qw(dpkg-source -x --),
4216         $dscpath =~ m#^/# ? $dscpath : "../../../$dscpath";
4217     my ($tree,$dir) = mktree_in_ud_from_only_subdir("source package");
4218     check_for_vendor_patches() if madformat($dsc->{format});
4219     changedir $maindir;
4220     my @diffcmd = (@git, qw(diff --quiet), $tree, $dgithead);
4221     debugcmd "+",@diffcmd;
4222     $!=0; $?=-1;
4223     my $r = system @diffcmd;
4224     if ($r) {
4225         if ($r==256) {
4226             my $diffs = cmdoutput @git, qw(diff --stat), $tree, $dgithead;
4227             fail <<END
4228 HEAD specifies a different tree to $dscfn:
4229 $diffs
4230 Perhaps you forgot to build.  Or perhaps there is a problem with your
4231  source tree (see dgit(7) for some hints).  To see a full diff, run
4232    git diff $tree HEAD
4233 END
4234         } else {
4235             failedcmd @diffcmd;
4236         }
4237     }
4238     if (!$changesfile) {
4239         my $pat = changespat $cversion;
4240         my @cs = glob "$buildproductsdir/$pat";
4241         fail "failed to find unique changes file".
4242             " (looked for $pat in $buildproductsdir);".
4243             " perhaps you need to use dgit -C"
4244             unless @cs==1;
4245         ($changesfile) = @cs;
4246     } else {
4247         $changesfile = "$buildproductsdir/$changesfile";
4248     }
4249
4250     # Check that changes and .dsc agree enough
4251     $changesfile =~ m{[^/]*$};
4252     my $changes = parsecontrol($changesfile,$&);
4253     files_compare_inputs($dsc, $changes)
4254         unless forceing [qw(dsc-changes-mismatch)];
4255
4256     # Perhaps adjust .dsc to contain right set of origs
4257     changes_update_origs_from_dsc($dsc, $changes, $upstreamversion,
4258                                   $changesfile)
4259         unless forceing [qw(changes-origs-exactly)];
4260
4261     # Checks complete, we're going to try and go ahead:
4262
4263     responder_send_file('changes',$changesfile);
4264     responder_send_command("param head $dgithead");
4265     responder_send_command("param csuite $csuite");
4266     responder_send_command("param isuite $isuite");
4267     responder_send_command("param tagformat $tagformat");
4268     if (defined $maintviewhead) {
4269         die unless ($protovsn//4) >= 4;
4270         responder_send_command("param maint-view $maintviewhead");
4271     }
4272
4273     # Perhaps send buildinfo(s) for signing
4274     my $changes_files = getfield $changes, 'Files';
4275     my @buildinfos = ($changes_files =~ m/ .* (\S+\.buildinfo)$/mg);
4276     foreach my $bi (@buildinfos) {
4277         responder_send_command("param buildinfo-filename $bi");
4278         responder_send_file('buildinfo', "$buildproductsdir/$bi");
4279     }
4280
4281     if (deliberately_not_fast_forward) {
4282         git_for_each_ref(lrfetchrefs, sub {
4283             my ($objid,$objtype,$lrfetchrefname,$reftail) = @_;
4284             my $rrefname= substr($lrfetchrefname, length(lrfetchrefs) + 1);
4285             responder_send_command("previously $rrefname=$objid");
4286             $previously{$rrefname} = $objid;
4287         });
4288     }
4289
4290     my @tagwants = push_tagwants($cversion, $dgithead, $maintviewhead,
4291                                  ".git/dgit/tag");
4292     my @tagobjfns;
4293
4294     supplementary_message(<<'END');
4295 Push failed, while signing the tag.
4296 You can retry the push, after fixing the problem, if you like.
4297 END
4298     # If we manage to sign but fail to record it anywhere, it's fine.
4299     if ($we_are_responder) {
4300         @tagobjfns = map { $_->{Tfn}('.signed-tmp') } @tagwants;
4301         responder_receive_files('signed-tag', @tagobjfns);
4302     } else {
4303         @tagobjfns = push_mktags($clogp,$dscpath,
4304                               $changesfile,$changesfile,
4305                               \@tagwants);
4306     }
4307     supplementary_message(<<'END');
4308 Push failed, *after* signing the tag.
4309 If you want to try again, you should use a new version number.
4310 END
4311
4312     pairwise { $a->{TagObjFn} = $b } @tagwants, @tagobjfns;
4313
4314     foreach my $tw (@tagwants) {
4315         my $tag = $tw->{Tag};
4316         my $tagobjfn = $tw->{TagObjFn};
4317         my $tag_obj_hash =
4318             cmdoutput @git, qw(hash-object -w -t tag), $tagobjfn;
4319         runcmd_ordryrun @git, qw(verify-tag), $tag_obj_hash;
4320         runcmd_ordryrun_local
4321             @git, qw(update-ref), "refs/tags/$tag", $tag_obj_hash;
4322     }
4323
4324     supplementary_message(<<'END');
4325 Push failed, while updating the remote git repository - see messages above.
4326 If you want to try again, you should use a new version number.
4327 END
4328     if (!check_for_git()) {
4329         create_remote_git_repo();
4330     }
4331
4332     my @pushrefs = $forceflag.$dgithead.":".rrref();
4333     foreach my $tw (@tagwants) {
4334         push @pushrefs, $forceflag."refs/tags/$tw->{Tag}";
4335     }
4336
4337     runcmd_ordryrun @git,
4338         qw(-c push.followTags=false push), access_giturl(), @pushrefs;
4339     runcmd_ordryrun @git, qw(update-ref -m), 'dgit push', lrref(), $dgithead;
4340
4341     supplementary_message(<<'END');
4342 Push failed, while obtaining signatures on the .changes and .dsc.
4343 If it was just that the signature failed, you may try again by using
4344 debsign by hand to sign the changes
4345    $changesfile
4346 and then dput to complete the upload.
4347 If you need to change the package, you must use a new version number.
4348 END
4349     if ($we_are_responder) {
4350         my $dryrunsuffix = act_local() ? "" : ".tmp";
4351         my @rfiles = ($dscpath, $changesfile);
4352         push @rfiles, map { "$buildproductsdir/$_" } @buildinfos;
4353         responder_receive_files('signed-dsc-changes',
4354                                 map { "$_$dryrunsuffix" } @rfiles);
4355     } else {
4356         if (act_local()) {
4357             rename "$dscpath.tmp",$dscpath or die "$dscfn $!";
4358         } else {
4359             progress "[new .dsc left in $dscpath.tmp]";
4360         }
4361         sign_changes $changesfile;
4362     }
4363
4364     supplementary_message(<<END);
4365 Push failed, while uploading package(s) to the archive server.
4366 You can retry the upload of exactly these same files with dput of:
4367   $changesfile
4368 If that .changes file is broken, you will need to use a new version
4369 number for your next attempt at the upload.
4370 END
4371     my $host = access_cfg('upload-host','RETURN-UNDEF');
4372     my @hostarg = defined($host) ? ($host,) : ();
4373     runcmd_ordryrun @dput, @hostarg, $changesfile;
4374     printdone "pushed and uploaded $cversion";
4375
4376     supplementary_message('');
4377     responder_send_command("complete");
4378 }
4379
4380 sub pre_clone () {
4381     no_local_git_cfg();
4382 }
4383 sub cmd_clone {
4384     parseopts();
4385     my $dstdir;
4386     badusage "-p is not allowed with clone; specify as argument instead"
4387         if defined $package;
4388     if (@ARGV==1) {
4389         ($package) = @ARGV;
4390     } elsif (@ARGV==2 && $ARGV[1] =~ m#^\w#) {
4391         ($package,$isuite) = @ARGV;
4392     } elsif (@ARGV==2 && $ARGV[1] =~ m#^[./]#) {
4393         ($package,$dstdir) = @ARGV;
4394     } elsif (@ARGV==3) {
4395         ($package,$isuite,$dstdir) = @ARGV;
4396     } else {
4397         badusage "incorrect arguments to dgit clone";
4398     }
4399     notpushing();
4400
4401     $dstdir ||= "$package";
4402     if (stat_exists $dstdir) {
4403         fail "$dstdir already exists";
4404     }
4405
4406     my $cwd_remove;
4407     if ($rmonerror && !$dryrun_level) {
4408         $cwd_remove= getcwd();
4409         unshift @end, sub {
4410             return unless defined $cwd_remove;
4411             if (!chdir "$cwd_remove") {
4412                 return if $!==&ENOENT;
4413                 die "chdir $cwd_remove: $!";
4414             }
4415             printdebug "clone rmonerror removing $dstdir\n";
4416             if (stat $dstdir) {
4417                 rmtree($dstdir) or die "remove $dstdir: $!\n";
4418             } elsif (grep { $! == $_ }
4419                      (ENOENT, ENOTDIR, EACCES, EPERM, ELOOP)) {
4420             } else {
4421                 print STDERR "check whether to remove $dstdir: $!\n";
4422             }
4423         };
4424     }
4425
4426     clone($dstdir);
4427     $cwd_remove = undef;
4428 }
4429
4430 sub branchsuite () {
4431     my @cmd = (@git, qw(symbolic-ref -q HEAD));
4432     my $branch = cmdoutput_errok @cmd;
4433     if (!defined $branch) {
4434         $?==256 or failedcmd @cmd;
4435         return undef;
4436     }
4437     if ($branch =~ m#$lbranch_re#o) {
4438         return $1;
4439     } else {
4440         return undef;
4441     }
4442 }
4443
4444 sub fetchpullargs () {
4445     if (!defined $package) {
4446         my $sourcep = parsecontrol('debian/control','debian/control');
4447         $package = getfield $sourcep, 'Source';
4448     }
4449     if (@ARGV==0) {
4450         $isuite = branchsuite();
4451         if (!$isuite) {
4452             my $clogp = parsechangelog();
4453             my $clogsuite = getfield $clogp, 'Distribution';
4454             $isuite= $clogsuite if $clogsuite ne 'UNRELEASED';
4455         }
4456     } elsif (@ARGV==1) {
4457         ($isuite) = @ARGV;
4458     } else {
4459         badusage "incorrect arguments to dgit fetch or dgit pull";
4460     }
4461     notpushing();
4462 }
4463
4464 sub cmd_fetch {
4465     parseopts();
4466     fetchpullargs();
4467     my $multi_fetched = fork_for_multisuite(sub { });
4468     exit 0 if $multi_fetched;
4469     fetch();
4470 }
4471
4472 sub cmd_pull {
4473     parseopts();
4474     fetchpullargs();
4475     if (quiltmode_splitbrain()) {
4476         my ($format, $fopts) = get_source_format();
4477         madformat($format) and fail <<END
4478 dgit pull not yet supported in split view mode (--quilt=$quilt_mode)
4479 END
4480     }
4481     pull();
4482 }
4483
4484 sub prep_push () {
4485     parseopts();
4486     build_or_push_prep_early();
4487     pushing();
4488     check_not_dirty();
4489     my $specsuite;
4490     if (@ARGV==0) {
4491     } elsif (@ARGV==1) {
4492         ($specsuite) = (@ARGV);
4493     } else {
4494         badusage "incorrect arguments to dgit $subcommand";
4495     }
4496     if ($new_package) {
4497         local ($package) = $existing_package; # this is a hack
4498         canonicalise_suite();
4499     } else {
4500         canonicalise_suite();
4501     }
4502     if (defined $specsuite &&
4503         $specsuite ne $isuite &&
4504         $specsuite ne $csuite) {
4505             fail "dgit $subcommand: changelog specifies $isuite ($csuite)".
4506                 " but command line specifies $specsuite";
4507     }
4508 }
4509
4510 sub cmd_push {
4511     prep_push();
4512     dopush();
4513 }
4514
4515 #---------- remote commands' implementation ----------
4516
4517 sub pre_remote_push_build_host {
4518     my ($nrargs) = shift @ARGV;
4519     my (@rargs) = @ARGV[0..$nrargs-1];
4520     @ARGV = @ARGV[$nrargs..$#ARGV];
4521     die unless @rargs;
4522     my ($dir,$vsnwant) = @rargs;
4523     # vsnwant is a comma-separated list; we report which we have
4524     # chosen in our ready response (so other end can tell if they
4525     # offered several)
4526     $debugprefix = ' ';
4527     $we_are_responder = 1;
4528     $us .= " (build host)";
4529
4530     open PI, "<&STDIN" or die $!;
4531     open STDIN, "/dev/null" or die $!;
4532     open PO, ">&STDOUT" or die $!;
4533     autoflush PO 1;
4534     open STDOUT, ">&STDERR" or die $!;
4535     autoflush STDOUT 1;
4536
4537     $vsnwant //= 1;
4538     ($protovsn) = grep {
4539         $vsnwant =~ m{^(?:.*,)?$_(?:,.*)?$}
4540     } @rpushprotovsn_support;
4541
4542     fail "build host has dgit rpush protocol versions ".
4543         (join ",", @rpushprotovsn_support).
4544         " but invocation host has $vsnwant"
4545         unless defined $protovsn;
4546
4547     changedir $dir;
4548 }
4549 sub cmd_remote_push_build_host {
4550     responder_send_command("dgit-remote-push-ready $protovsn");
4551     &cmd_push;
4552 }
4553
4554 sub pre_remote_push_responder { pre_remote_push_build_host(); }
4555 sub cmd_remote_push_responder { cmd_remote_push_build_host(); }
4556 # ... for compatibility with proto vsn.1 dgit (just so that user gets
4557 #     a good error message)
4558
4559 sub rpush_handle_protovsn_bothends () {
4560     if ($protovsn < 4) {
4561         need_tagformat 'old', "rpush negotiated protocol $protovsn";
4562     }
4563     select_tagformat();
4564 }
4565
4566 our $i_tmp;
4567
4568 sub i_cleanup {
4569     local ($@, $?);
4570     my $report = i_child_report();
4571     if (defined $report) {
4572         printdebug "($report)\n";
4573     } elsif ($i_child_pid) {
4574         printdebug "(killing build host child $i_child_pid)\n";
4575         kill 15, $i_child_pid;
4576     }
4577     if (defined $i_tmp && !defined $initiator_tempdir) {
4578         changedir "/";
4579         eval { rmtree $i_tmp; };
4580     }
4581 }
4582
4583 END {
4584     return unless forkcheck_mainprocess();
4585     i_cleanup();
4586 }
4587
4588 sub i_method {
4589     my ($base,$selector,@args) = @_;
4590     $selector =~ s/\-/_/g;
4591     { no strict qw(refs); &{"${base}_${selector}"}(@args); }
4592 }
4593
4594 sub pre_rpush () {
4595     no_local_git_cfg();
4596 }
4597 sub cmd_rpush {
4598     my $host = nextarg;
4599     my $dir;
4600     if ($host =~ m/^((?:[^][]|\[[^][]*\])*)\:/) {
4601         $host = $1;
4602         $dir = $'; #';
4603     } else {
4604         $dir = nextarg;
4605     }
4606     $dir =~ s{^-}{./-};
4607     my @rargs = ($dir);
4608     push @rargs, join ",", @rpushprotovsn_support;
4609     my @rdgit;
4610     push @rdgit, @dgit;
4611     push @rdgit, @ropts;
4612     push @rdgit, qw(remote-push-build-host), (scalar @rargs), @rargs;
4613     push @rdgit, @ARGV;
4614     my @cmd = (@ssh, $host, shellquote @rdgit);
4615     debugcmd "+",@cmd;
4616
4617     $we_are_initiator=1;
4618
4619     if (defined $initiator_tempdir) {
4620         rmtree $initiator_tempdir;
4621         mkdir $initiator_tempdir, 0700 or die "$initiator_tempdir: $!";
4622         $i_tmp = $initiator_tempdir;
4623     } else {
4624         $i_tmp = tempdir();
4625     }
4626     $i_child_pid = open2(\*RO, \*RI, @cmd);
4627     changedir $i_tmp;
4628     ($protovsn) = initiator_expect { m/^dgit-remote-push-ready (\S+)/ };
4629     die "$protovsn ?" unless grep { $_ eq $protovsn } @rpushprotovsn_support;
4630     $supplementary_message = '' unless $protovsn >= 3;
4631
4632     for (;;) {
4633         my ($icmd,$iargs) = initiator_expect {
4634             m/^(\S+)(?: (.*))?$/;
4635             ($1,$2);
4636         };
4637         i_method "i_resp", $icmd, $iargs;
4638     }
4639 }
4640
4641 sub i_resp_progress ($) {
4642     my ($rhs) = @_;
4643     my $msg = protocol_read_bytes \*RO, $rhs;
4644     progress $msg;
4645 }
4646
4647 sub i_resp_supplementary_message ($) {
4648     my ($rhs) = @_;
4649     $supplementary_message = protocol_read_bytes \*RO, $rhs;
4650 }
4651
4652 sub i_resp_complete {
4653     my $pid = $i_child_pid;
4654     $i_child_pid = undef; # prevents killing some other process with same pid
4655     printdebug "waiting for build host child $pid...\n";
4656     my $got = waitpid $pid, 0;
4657     die $! unless $got == $pid;
4658     die "build host child failed $?" if $?;
4659
4660     i_cleanup();
4661     printdebug "all done\n";
4662     exit 0;
4663 }
4664
4665 sub i_resp_file ($) {
4666     my ($keyword) = @_;
4667     my $localname = i_method "i_localname", $keyword;
4668     my $localpath = "$i_tmp/$localname";
4669     stat_exists $localpath and
4670         badproto \*RO, "file $keyword ($localpath) twice";
4671     protocol_receive_file \*RO, $localpath;
4672     i_method "i_file", $keyword;
4673 }
4674
4675 our %i_param;
4676
4677 sub i_resp_param ($) {
4678     $_[0] =~ m/^(\S+) (.*)$/ or badproto \*RO, "bad param spec";
4679     $i_param{$1} = $2;
4680 }
4681
4682 sub i_resp_previously ($) {
4683     $_[0] =~ m#^(refs/tags/\S+)=(\w+)$#
4684         or badproto \*RO, "bad previously spec";
4685     my $r = system qw(git check-ref-format), $1;
4686     die "bad previously ref spec ($r)" if $r;
4687     $previously{$1} = $2;
4688 }
4689
4690 our %i_wanted;
4691
4692 sub i_resp_want ($) {
4693     my ($keyword) = @_;
4694     die "$keyword ?" if $i_wanted{$keyword}++;
4695
4696     defined $i_param{'csuite'} or badproto \*RO, "premature desire, no csuite";
4697     $isuite = $i_param{'isuite'} // $i_param{'csuite'};
4698     die unless $isuite =~ m/^$suite_re$/;
4699
4700     pushing();
4701     rpush_handle_protovsn_bothends();
4702
4703     fail "rpush negotiated protocol version $protovsn".
4704         " which does not support quilt mode $quilt_mode"
4705         if quiltmode_splitbrain;
4706
4707     my @localpaths = i_method "i_want", $keyword;
4708     printdebug "[[  $keyword @localpaths\n";
4709     foreach my $localpath (@localpaths) {
4710         protocol_send_file \*RI, $localpath;
4711     }
4712     print RI "files-end\n" or die $!;
4713 }
4714
4715 our ($i_clogp, $i_version, $i_dscfn, $i_changesfn, @i_buildinfos);
4716
4717 sub i_localname_parsed_changelog {
4718     return "remote-changelog.822";
4719 }
4720 sub i_file_parsed_changelog {
4721     ($i_clogp, $i_version, $i_dscfn) =
4722         push_parse_changelog "$i_tmp/remote-changelog.822";
4723     die if $i_dscfn =~ m#/|^\W#;
4724 }
4725
4726 sub i_localname_dsc {
4727     defined $i_dscfn or badproto \*RO, "dsc (before parsed-changelog)";
4728     return $i_dscfn;
4729 }
4730 sub i_file_dsc { }
4731
4732 sub i_localname_buildinfo ($) {
4733     my $bi = $i_param{'buildinfo-filename'};
4734     defined $bi or badproto \*RO, "buildinfo before filename";
4735     defined $i_changesfn or badproto \*RO, "buildinfo before changes";
4736     $bi =~ m{^\Q$package\E_[!-.0-~]*\.buildinfo$}s
4737         or badproto \*RO, "improper buildinfo filename";
4738     return $&;
4739 }
4740 sub i_file_buildinfo {
4741     my $bi = $i_param{'buildinfo-filename'};
4742     my $bd = parsecontrol "$i_tmp/$bi", $bi;
4743     my $ch = parsecontrol "$i_tmp/$i_changesfn", 'changes';
4744     if (!forceing [qw(buildinfo-changes-mismatch)]) {
4745         files_compare_inputs($bd, $ch);
4746         (getfield $bd, $_) eq (getfield $ch, $_) or
4747             fail "buildinfo mismatch $_"
4748             foreach qw(Source Version);
4749         !defined $bd->{$_} or
4750             fail "buildinfo contains $_"
4751             foreach qw(Changes Changed-by Distribution);
4752     }
4753     push @i_buildinfos, $bi;
4754     delete $i_param{'buildinfo-filename'};
4755 }
4756
4757 sub i_localname_changes {
4758     defined $i_dscfn or badproto \*RO, "dsc (before parsed-changelog)";
4759     $i_changesfn = $i_dscfn;
4760     $i_changesfn =~ s/\.dsc$/_dgit.changes/ or die;
4761     return $i_changesfn;
4762 }
4763 sub i_file_changes { }
4764
4765 sub i_want_signed_tag {
4766     printdebug Dumper(\%i_param, $i_dscfn);
4767     defined $i_param{'head'} && defined $i_dscfn && defined $i_clogp
4768         && defined $i_param{'csuite'}
4769         or badproto \*RO, "premature desire for signed-tag";
4770     my $head = $i_param{'head'};
4771     die if $head =~ m/[^0-9a-f]/ || $head !~ m/^../;
4772
4773     my $maintview = $i_param{'maint-view'};
4774     die if defined $maintview && $maintview =~ m/[^0-9a-f]/;
4775
4776     select_tagformat();
4777     if ($protovsn >= 4) {
4778         my $p = $i_param{'tagformat'} // '<undef>';
4779         $p eq $tagformat
4780             or badproto \*RO, "tag format mismatch: $p vs. $tagformat";
4781     }
4782
4783     die unless $i_param{'csuite'} =~ m/^$suite_re$/;
4784     $csuite = $&;
4785     push_parse_dsc $i_dscfn, 'remote dsc', $i_version;
4786
4787     my @tagwants = push_tagwants $i_version, $head, $maintview, "tag";
4788
4789     return
4790         push_mktags $i_clogp, $i_dscfn,
4791             $i_changesfn, 'remote changes',
4792             \@tagwants;
4793 }
4794
4795 sub i_want_signed_dsc_changes {
4796     rename "$i_dscfn.tmp","$i_dscfn" or die "$i_dscfn $!";
4797     sign_changes $i_changesfn;
4798     return ($i_dscfn, $i_changesfn, @i_buildinfos);
4799 }
4800
4801 #---------- building etc. ----------
4802
4803 our $version;
4804 our $sourcechanges;
4805 our $dscfn;
4806
4807 #----- `3.0 (quilt)' handling -----
4808
4809 our $fakeeditorenv = 'DGIT_FAKE_EDITOR_QUILT';
4810
4811 sub quiltify_dpkg_commit ($$$;$) {
4812     my ($patchname,$author,$msg, $xinfo) = @_;
4813     $xinfo //= '';
4814
4815     mkpath '.git/dgit';
4816     my $descfn = ".git/dgit/quilt-description.tmp";
4817     open O, '>', $descfn or die "$descfn: $!";
4818     $msg =~ s/\n+/\n\n/;
4819     print O <<END or die $!;
4820 From: $author
4821 ${xinfo}Subject: $msg
4822 ---
4823
4824 END
4825     close O or die $!;
4826
4827     {
4828         local $ENV{'EDITOR'} = cmdoutput qw(realpath --), $0;
4829         local $ENV{'VISUAL'} = $ENV{'EDITOR'};
4830         local $ENV{$fakeeditorenv} = cmdoutput qw(realpath --), $descfn;
4831         runcmd @dpkgsource, qw(--commit --include-removal .), $patchname;
4832     }
4833 }
4834
4835 sub quiltify_trees_differ ($$;$$$) {
4836     my ($x,$y,$finegrained,$ignorenamesr,$unrepres) = @_;
4837     # returns true iff the two tree objects differ other than in debian/
4838     # with $finegrained,
4839     # returns bitmask 01 - differ in upstream files except .gitignore
4840     #                 02 - differ in .gitignore
4841     # if $ignorenamesr is defined, $ingorenamesr->{$fn}
4842     #  is set for each modified .gitignore filename $fn
4843     # if $unrepres is defined, array ref to which is appeneded
4844     #  a list of unrepresentable changes (removals of upstream files
4845     #  (as messages)
4846     local $/=undef;
4847     my @cmd = (@git, qw(diff-tree -z --no-renames));
4848     push @cmd, qw(--name-only) unless $unrepres;
4849     push @cmd, qw(-r) if $finegrained || $unrepres;
4850     push @cmd, $x, $y;
4851     my $diffs= cmdoutput @cmd;
4852     my $r = 0;
4853     my @lmodes;
4854     foreach my $f (split /\0/, $diffs) {
4855         if ($unrepres && !@lmodes) {
4856             @lmodes = $f =~ m/^\:(\w+) (\w+) \w+ \w+ / or die "$_ ?";
4857             next;
4858         }
4859         my ($oldmode,$newmode) = @lmodes;
4860         @lmodes = ();
4861
4862         next if $f =~ m#^debian(?:/.*)?$#s;
4863
4864         if ($unrepres) {
4865             eval {
4866                 die "not a plain file or symlink\n"
4867                     unless $newmode =~ m/^(?:10|12)\d{4}$/ ||
4868                            $oldmode =~ m/^(?:10|12)\d{4}$/;
4869                 if ($oldmode =~ m/[^0]/ &&
4870                     $newmode =~ m/[^0]/) {
4871                     # both old and new files exist
4872                     die "mode or type changed\n" if $oldmode ne $newmode;
4873                     die "modified symlink\n" unless $newmode =~ m/^10/;
4874                 } elsif ($oldmode =~ m/[^0]/) {
4875                     # deletion
4876                     die "deletion of symlink\n"
4877                         unless $oldmode =~ m/^10/;
4878                 } else {
4879                     # creation
4880                     die "creation with non-default mode\n"
4881                         unless $newmode =~ m/^100644$/ or
4882                                $newmode =~ m/^120000$/;
4883                 }
4884             };
4885             if ($@) {
4886                 local $/="\n"; chomp $@;
4887                 push @$unrepres, [ $f, "$@ ($oldmode->$newmode)" ];
4888             }
4889         }
4890
4891         my $isignore = $f =~ m#^(?:.*/)?.gitignore$#s;
4892         $r |= $isignore ? 02 : 01;
4893         $ignorenamesr->{$f}=1 if $ignorenamesr && $isignore;
4894     }
4895     printdebug "quiltify_trees_differ $x $y => $r\n";
4896     return $r;
4897 }
4898
4899 sub quiltify_tree_sentinelfiles ($) {
4900     # lists the `sentinel' files present in the tree
4901     my ($x) = @_;
4902     my $r = cmdoutput @git, qw(ls-tree --name-only), $x,
4903         qw(-- debian/rules debian/control);
4904     $r =~ s/\n/,/g;
4905     return $r;
4906 }
4907
4908 sub quiltify_splitbrain_needed () {
4909     if (!$split_brain) {
4910         progress "dgit view: changes are required...";
4911         runcmd @git, qw(checkout -q -b dgit-view);
4912         $split_brain = 1;
4913     }
4914 }
4915
4916 sub quiltify_splitbrain ($$$$$$) {
4917     my ($clogp, $unapplied, $headref, $diffbits,
4918         $editedignores, $cachekey) = @_;
4919     if ($quilt_mode !~ m/gbp|dpm/) {
4920         # treat .gitignore just like any other upstream file
4921         $diffbits = { %$diffbits };
4922         $_ = !!$_ foreach values %$diffbits;
4923     }
4924     # We would like any commits we generate to be reproducible
4925     my @authline = clogp_authline($clogp);
4926     local $ENV{GIT_COMMITTER_NAME} =  $authline[0];
4927     local $ENV{GIT_COMMITTER_EMAIL} = $authline[1];
4928     local $ENV{GIT_COMMITTER_DATE} =  $authline[2];
4929     local $ENV{GIT_AUTHOR_NAME} =  $authline[0];
4930     local $ENV{GIT_AUTHOR_EMAIL} = $authline[1];
4931     local $ENV{GIT_AUTHOR_DATE} =  $authline[2];
4932
4933     if ($quilt_mode =~ m/gbp|unapplied/ &&
4934         ($diffbits->{O2H} & 01)) {
4935         my $msg =
4936  "--quilt=$quilt_mode specified, implying patches-unapplied git tree\n".
4937  " but git tree differs from orig in upstream files.";
4938         if (!stat_exists "debian/patches") {
4939             $msg .=
4940  "\n ... debian/patches is missing; perhaps this is a patch queue branch?";
4941         }
4942         fail $msg;
4943     }
4944     if ($quilt_mode =~ m/dpm/ &&
4945         ($diffbits->{H2A} & 01)) {
4946         fail <<END;
4947 --quilt=$quilt_mode specified, implying patches-applied git tree
4948  but git tree differs from result of applying debian/patches to upstream
4949 END
4950     }
4951     if ($quilt_mode =~ m/gbp|unapplied/ &&
4952         ($diffbits->{O2A} & 01)) { # some patches
4953         quiltify_splitbrain_needed();
4954         progress "dgit view: creating patches-applied version using gbp pq";
4955         runcmd shell_cmd 'exec >/dev/null', gbp_pq, qw(import);
4956         # gbp pq import creates a fresh branch; push back to dgit-view
4957         runcmd @git, qw(update-ref refs/heads/dgit-view HEAD);
4958         runcmd @git, qw(checkout -q dgit-view);
4959     }
4960     if ($quilt_mode =~ m/gbp|dpm/ &&
4961         ($diffbits->{O2A} & 02)) {
4962         fail <<END
4963 --quilt=$quilt_mode specified, implying that HEAD is for use with a
4964  tool which does not create patches for changes to upstream
4965  .gitignores: but, such patches exist in debian/patches.
4966 END
4967     }
4968     if (($diffbits->{O2H} & 02) && # user has modified .gitignore
4969         !($diffbits->{O2A} & 02)) { # patches do not change .gitignore
4970         quiltify_splitbrain_needed();
4971         progress "dgit view: creating patch to represent .gitignore changes";
4972         ensuredir "debian/patches";
4973         my $gipatch = "debian/patches/auto-gitignore";
4974         open GIPATCH, ">>", "$gipatch" or die "$gipatch: $!";
4975         stat GIPATCH or die "$gipatch: $!";
4976         fail "$gipatch already exists; but want to create it".
4977             " to record .gitignore changes" if (stat _)[7];
4978         print GIPATCH <<END or die "$gipatch: $!";
4979 Subject: Update .gitignore from Debian packaging branch
4980
4981 The Debian packaging git branch contains these updates to the upstream
4982 .gitignore file(s).  This patch is autogenerated, to provide these
4983 updates to users of the official Debian archive view of the package.
4984
4985 [dgit ($our_version) update-gitignore]
4986 ---
4987 END
4988         close GIPATCH or die "$gipatch: $!";
4989         runcmd shell_cmd "exec >>$gipatch", @git, qw(diff),
4990             $unapplied, $headref, "--", sort keys %$editedignores;
4991         open SERIES, "+>>", "debian/patches/series" or die $!;
4992         defined seek SERIES, -1, 2 or $!==EINVAL or die $!;
4993         my $newline;
4994         defined read SERIES, $newline, 1 or die $!;
4995         print SERIES "\n" or die $! unless $newline eq "\n";
4996         print SERIES "auto-gitignore\n" or die $!;
4997         close SERIES or die  $!;
4998         runcmd @git, qw(add -- debian/patches/series), $gipatch;
4999         commit_admin <<END
5000 Commit patch to update .gitignore
5001
5002 [dgit ($our_version) update-gitignore-quilt-fixup]
5003 END
5004     }
5005
5006     my $dgitview = git_rev_parse 'HEAD';
5007
5008     changedir $maindir;
5009     # When we no longer need to support squeeze, use --create-reflog
5010     # instead of this:
5011     ensuredir ".git/logs/refs/dgit-intern";
5012     my $makelogfh = new IO::File ".git/logs/refs/$splitbraincache", '>>'
5013       or die $!;
5014
5015     my $oldcache = git_get_ref "refs/$splitbraincache";
5016     if ($oldcache eq $dgitview) {
5017         my $tree = cmdoutput qw(git rev-parse), "$dgitview:";
5018         # git update-ref doesn't always update, in this case.  *sigh*
5019         my $dummy = make_commit_text <<END;
5020 tree $tree
5021 parent $dgitview
5022 author Dgit <dgit\@example.com> 1000000000 +0000
5023 committer Dgit <dgit\@example.com> 1000000000 +0000
5024
5025 Dummy commit - do not use
5026 END
5027         runcmd @git, qw(update-ref -m), "dgit $our_version - dummy",
5028             "refs/$splitbraincache", $dummy;
5029     }
5030     runcmd @git, qw(update-ref -m), $cachekey, "refs/$splitbraincache",
5031         $dgitview;
5032
5033     changedir "$playground/work";
5034
5035     my $saved = maybe_split_brain_save $headref, $dgitview, "converted";
5036     progress "dgit view: created ($saved)";
5037 }
5038
5039 sub quiltify ($$$$) {
5040     my ($clogp,$target,$oldtiptree,$failsuggestion) = @_;
5041
5042     # Quilt patchification algorithm
5043     #
5044     # We search backwards through the history of the main tree's HEAD
5045     # (T) looking for a start commit S whose tree object is identical
5046     # to to the patch tip tree (ie the tree corresponding to the
5047     # current dpkg-committed patch series).  For these purposes
5048     # `identical' disregards anything in debian/ - this wrinkle is
5049     # necessary because dpkg-source treates debian/ specially.
5050     #
5051     # We can only traverse edges where at most one of the ancestors'
5052     # trees differs (in changes outside in debian/).  And we cannot
5053     # handle edges which change .pc/ or debian/patches.  To avoid
5054     # going down a rathole we avoid traversing edges which introduce
5055     # debian/rules or debian/control.  And we set a limit on the
5056     # number of edges we are willing to look at.
5057     #
5058     # If we succeed, we walk forwards again.  For each traversed edge
5059     # PC (with P parent, C child) (starting with P=S and ending with
5060     # C=T) to we do this:
5061     #  - git checkout C
5062     #  - dpkg-source --commit with a patch name and message derived from C
5063     # After traversing PT, we git commit the changes which
5064     # should be contained within debian/patches.
5065
5066     # The search for the path S..T is breadth-first.  We maintain a
5067     # todo list containing search nodes.  A search node identifies a
5068     # commit, and looks something like this:
5069     #  $p = {
5070     #      Commit => $git_commit_id,
5071     #      Child => $c,                          # or undef if P=T
5072     #      Whynot => $reason_edge_PC_unsuitable, # in @nots only
5073     #      Nontrivial => true iff $p..$c has relevant changes
5074     #  };
5075
5076     my @todo;
5077     my @nots;
5078     my $sref_S;
5079     my $max_work=100;
5080     my %considered; # saves being exponential on some weird graphs
5081
5082     my $t_sentinels = quiltify_tree_sentinelfiles $target;
5083
5084     my $not = sub {
5085         my ($search,$whynot) = @_;
5086         printdebug " search NOT $search->{Commit} $whynot\n";
5087         $search->{Whynot} = $whynot;
5088         push @nots, $search;
5089         no warnings qw(exiting);
5090         next;
5091     };
5092
5093     push @todo, {
5094         Commit => $target,
5095     };
5096
5097     while (@todo) {
5098         my $c = shift @todo;
5099         next if $considered{$c->{Commit}}++;
5100
5101         $not->($c, "maximum search space exceeded") if --$max_work <= 0;
5102
5103         printdebug "quiltify investigate $c->{Commit}\n";
5104
5105         # are we done?
5106         if (!quiltify_trees_differ $c->{Commit}, $oldtiptree) {
5107             printdebug " search finished hooray!\n";
5108             $sref_S = $c;
5109             last;
5110         }
5111
5112         if ($quilt_mode eq 'nofix') {
5113             fail "quilt fixup required but quilt mode is \`nofix'\n".
5114                 "HEAD commit $c->{Commit} differs from tree implied by ".
5115                 " debian/patches (tree object $oldtiptree)";
5116         }
5117         if ($quilt_mode eq 'smash') {
5118             printdebug " search quitting smash\n";
5119             last;
5120         }
5121
5122         my $c_sentinels = quiltify_tree_sentinelfiles $c->{Commit};
5123         $not->($c, "has $c_sentinels not $t_sentinels")
5124             if $c_sentinels ne $t_sentinels;
5125
5126         my $commitdata = cmdoutput @git, qw(cat-file commit), $c->{Commit};
5127         $commitdata =~ m/\n\n/;
5128         $commitdata =~ $`;
5129         my @parents = ($commitdata =~ m/^parent (\w+)$/gm);
5130         @parents = map { { Commit => $_, Child => $c } } @parents;
5131
5132         $not->($c, "root commit") if !@parents;
5133
5134         foreach my $p (@parents) {
5135             $p->{Nontrivial}= quiltify_trees_differ $p->{Commit},$c->{Commit};
5136         }
5137         my $ndiffers = grep { $_->{Nontrivial} } @parents;
5138         $not->($c, "merge ($ndiffers nontrivial parents)") if $ndiffers > 1;
5139
5140         foreach my $p (@parents) {
5141             printdebug "considering C=$c->{Commit} P=$p->{Commit}\n";
5142
5143             my @cmd= (@git, qw(diff-tree -r --name-only),
5144                       $p->{Commit},$c->{Commit}, qw(-- debian/patches .pc));
5145             my $patchstackchange = cmdoutput @cmd;
5146             if (length $patchstackchange) {
5147                 $patchstackchange =~ s/\n/,/g;
5148                 $not->($p, "changed $patchstackchange");
5149             }
5150
5151             printdebug " search queue P=$p->{Commit} ",
5152                 ($p->{Nontrivial} ? "NT" : "triv"),"\n";
5153             push @todo, $p;
5154         }
5155     }
5156
5157     if (!$sref_S) {
5158         printdebug "quiltify want to smash\n";
5159
5160         my $abbrev = sub {
5161             my $x = $_[0]{Commit};
5162             $x =~ s/(.*?[0-9a-z]{8})[0-9a-z]*$/$1/;
5163             return $x;
5164         };
5165         my $reportnot = sub {
5166             my ($notp) = @_;
5167             my $s = $abbrev->($notp);
5168             my $c = $notp->{Child};
5169             $s .= "..".$abbrev->($c) if $c;
5170             $s .= ": ".$notp->{Whynot};
5171             return $s;
5172         };
5173         if ($quilt_mode eq 'linear') {
5174             print STDERR "$us: quilt fixup cannot be linear.  Stopped at:\n";
5175             foreach my $notp (@nots) {
5176                 print STDERR "$us:  ", $reportnot->($notp), "\n";
5177             }
5178             print STDERR "$us: $_\n" foreach @$failsuggestion;
5179             fail "quilt fixup naive history linearisation failed.\n".
5180  "Use dpkg-source --commit by hand; or, --quilt=smash for one ugly patch";
5181         } elsif ($quilt_mode eq 'smash') {
5182         } elsif ($quilt_mode eq 'auto') {
5183             progress "quilt fixup cannot be linear, smashing...";
5184         } else {
5185             die "$quilt_mode ?";
5186         }
5187
5188         my $time = $ENV{'GIT_COMMITTER_DATE'} || time;
5189         $time =~ s/\s.*//; # trim timezone from GIT_COMMITTER_DATE
5190         my $ncommits = 3;
5191         my $msg = cmdoutput @git, qw(log), "-n$ncommits";
5192
5193         quiltify_dpkg_commit "auto-$version-$target-$time",
5194             (getfield $clogp, 'Maintainer'),
5195             "Automatically generated patch ($clogp->{Version})\n".
5196             "Last (up to) $ncommits git changes, FYI:\n\n". $msg;
5197         return;
5198     }
5199
5200     progress "quiltify linearisation planning successful, executing...";
5201
5202     for (my $p = $sref_S;
5203          my $c = $p->{Child};
5204          $p = $p->{Child}) {
5205         printdebug "quiltify traverse $p->{Commit}..$c->{Commit}\n";
5206         next unless $p->{Nontrivial};
5207
5208         my $cc = $c->{Commit};
5209
5210         my $commitdata = cmdoutput @git, qw(cat-file commit), $cc;
5211         $commitdata =~ m/\n\n/ or die "$c ?";
5212         $commitdata = $`;
5213         my $msg = $'; #';
5214         $commitdata =~ m/^author (.*) \d+ [-+0-9]+$/m or die "$cc ?";
5215         my $author = $1;
5216
5217         my $commitdate = cmdoutput
5218             @git, qw(log -n1 --pretty=format:%aD), $cc;
5219
5220         $msg =~ s/^(.*)\n*/$1\n/ or die "$cc $msg ?";
5221
5222         my $strip_nls = sub { $msg =~ s/\n+$//; $msg .= "\n"; };
5223         $strip_nls->();
5224
5225         my $title = $1;
5226         my $patchname;
5227         my $patchdir;
5228
5229         my $gbp_check_suitable = sub {
5230             $_ = shift;
5231             my ($what) = @_;
5232
5233             eval {
5234                 die "contains unexpected slashes\n" if m{//} || m{/$};
5235                 die "contains leading punctuation\n" if m{^\W} || m{/\W};
5236                 die "contains bad character(s)\n" if m{[^-a-z0-9_.+=~/]}i;
5237                 die "is series file\n" if m{$series_filename_re}o;
5238                 die "too long" if length > 200;
5239             };
5240             return $_ unless $@;
5241             print STDERR "quiltifying commit $cc:".
5242                 " ignoring/dropping Gbp-Pq $what: $@";
5243             return undef;
5244         };
5245
5246         if ($msg =~ s/^ (?: gbp(?:-pq)? : \s* name \s+ |
5247                            gbp-pq-name: \s* )
5248                        (\S+) \s* \n //ixm) {
5249             $patchname = $gbp_check_suitable->($1, 'Name');
5250         }
5251         if ($msg =~ s/^ (?: gbp(?:-pq)? : \s* topic \s+ |
5252                            gbp-pq-topic: \s* )
5253                        (\S+) \s* \n //ixm) {
5254             $patchdir = $gbp_check_suitable->($1, 'Topic');
5255         }
5256
5257         $strip_nls->();
5258
5259         if (!defined $patchname) {
5260             $patchname = $title;
5261             $patchname =~ s/[.:]$//;
5262             use Text::Iconv;
5263             eval {
5264                 my $converter = new Text::Iconv qw(UTF-8 ASCII//TRANSLIT);
5265                 my $translitname = $converter->convert($patchname);
5266                 die unless defined $translitname;
5267                 $patchname = $translitname;
5268             };
5269             print STDERR
5270                 "dgit: patch title transliteration error: $@"
5271                 if $@;
5272             $patchname =~ y/ A-Z/-a-z/;
5273             $patchname =~ y/-a-z0-9_.+=~//cd;
5274             $patchname =~ s/^\W/x-$&/;
5275             $patchname = substr($patchname,0,40);
5276             $patchname .= ".patch";
5277         }
5278         if (!defined $patchdir) {
5279             $patchdir = '';
5280         }
5281         if (length $patchdir) {
5282             $patchname = "$patchdir/$patchname";
5283         }
5284         if ($patchname =~ m{^(.*)/}) {
5285             mkpath "debian/patches/$1";
5286         }
5287
5288         my $index;
5289         for ($index='';
5290              stat "debian/patches/$patchname$index";
5291              $index++) { }
5292         $!==ENOENT or die "$patchname$index $!";
5293
5294         runcmd @git, qw(checkout -q), $cc;
5295
5296         # We use the tip's changelog so that dpkg-source doesn't
5297         # produce complaining messages from dpkg-parsechangelog.  None
5298         # of the information dpkg-source gets from the changelog is
5299         # actually relevant - it gets put into the original message
5300         # which dpkg-source provides our stunt editor, and then
5301         # overwritten.
5302         runcmd @git, qw(checkout -q), $target, qw(debian/changelog);
5303
5304         quiltify_dpkg_commit "$patchname$index", $author, $msg,
5305             "Date: $commitdate\n".
5306             "X-Dgit-Generated: $clogp->{Version} $cc\n";
5307
5308         runcmd @git, qw(checkout -q), $cc, qw(debian/changelog);
5309     }
5310
5311     runcmd @git, qw(checkout -q master);
5312 }
5313
5314 sub build_maybe_quilt_fixup () {
5315     my ($format,$fopts) = get_source_format;
5316     return unless madformat_wantfixup $format;
5317     # sigh
5318
5319     check_for_vendor_patches();
5320
5321     if (quiltmode_splitbrain) {
5322         fail <<END unless access_cfg_tagformats_can_splitbrain;
5323 quilt mode $quilt_mode requires split view so server needs to support
5324  both "new" and "maint" tag formats, but config says it doesn't.
5325 END
5326     }
5327
5328     my $clogp = parsechangelog();
5329     my $headref = git_rev_parse('HEAD');
5330
5331     prep_ud();
5332     changedir $playground;
5333
5334     my $upstreamversion = upstreamversion $version;
5335
5336     if ($fopts->{'single-debian-patch'}) {
5337         quilt_fixup_singlepatch($clogp, $headref, $upstreamversion);
5338     } else {
5339         quilt_fixup_multipatch($clogp, $headref, $upstreamversion);
5340     }
5341
5342     die 'bug' if $split_brain && !$need_split_build_invocation;
5343
5344     changedir $maindir;
5345     runcmd_ordryrun_local
5346         @git, qw(pull --ff-only -q .git/dgit/unpack/work master);
5347 }
5348
5349 sub quilt_fixup_mkwork ($) {
5350     my ($headref) = @_;
5351
5352     mkdir "work" or die $!;
5353     changedir "work";
5354     mktree_in_ud_here();
5355     runcmd @git, qw(reset -q --hard), $headref;
5356 }
5357
5358 sub quilt_fixup_linkorigs ($$) {
5359     my ($upstreamversion, $fn) = @_;
5360     # calls $fn->($leafname);
5361
5362     foreach my $f (<../../../../*>) { #/){
5363         my $b=$f; $b =~ s{.*/}{};
5364         {
5365             local ($debuglevel) = $debuglevel-1;
5366             printdebug "QF linkorigs $b, $f ?\n";
5367         }
5368         next unless is_orig_file_of_vsn $b, $upstreamversion;
5369         printdebug "QF linkorigs $b, $f Y\n";
5370         link_ltarget $f, $b or die "$b $!";
5371         $fn->($b);
5372     }
5373 }
5374
5375 sub quilt_fixup_delete_pc () {
5376     runcmd @git, qw(rm -rqf .pc);
5377     commit_admin <<END
5378 Commit removal of .pc (quilt series tracking data)
5379
5380 [dgit ($our_version) upgrade quilt-remove-pc]
5381 END
5382 }
5383
5384 sub quilt_fixup_singlepatch ($$$) {
5385     my ($clogp, $headref, $upstreamversion) = @_;
5386
5387     progress "starting quiltify (single-debian-patch)";
5388
5389     # dpkg-source --commit generates new patches even if
5390     # single-debian-patch is in debian/source/options.  In order to
5391     # get it to generate debian/patches/debian-changes, it is
5392     # necessary to build the source package.
5393
5394     quilt_fixup_linkorigs($upstreamversion, sub { });
5395     quilt_fixup_mkwork($headref);
5396
5397     rmtree("debian/patches");
5398
5399     runcmd @dpkgsource, qw(-b .);
5400     changedir "..";
5401     runcmd @dpkgsource, qw(-x), (srcfn $version, ".dsc");
5402     rename srcfn("$upstreamversion", "/debian/patches"),
5403            "work/debian/patches";
5404
5405     changedir "work";
5406     commit_quilty_patch();
5407 }
5408
5409 sub quilt_make_fake_dsc ($) {
5410     my ($upstreamversion) = @_;
5411
5412     my $fakeversion="$upstreamversion-~~DGITFAKE";
5413
5414     my $fakedsc=new IO::File 'fake.dsc', '>' or die $!;
5415     print $fakedsc <<END or die $!;
5416 Format: 3.0 (quilt)
5417 Source: $package
5418 Version: $fakeversion
5419 Files:
5420 END
5421
5422     my $dscaddfile=sub {
5423         my ($b) = @_;
5424
5425         my $md = new Digest::MD5;
5426
5427         my $fh = new IO::File $b, '<' or die "$b $!";
5428         stat $fh or die $!;
5429         my $size = -s _;
5430
5431         $md->addfile($fh);
5432         print $fakedsc " ".$md->hexdigest." $size $b\n" or die $!;
5433     };
5434
5435     quilt_fixup_linkorigs($upstreamversion, $dscaddfile);
5436
5437     my @files=qw(debian/source/format debian/rules
5438                  debian/control debian/changelog);
5439     foreach my $maybe (qw(debian/patches debian/source/options
5440                           debian/tests/control)) {
5441         next unless stat_exists "../../../$maybe";
5442         push @files, $maybe;
5443     }
5444
5445     my $debtar= srcfn $fakeversion,'.debian.tar.gz';
5446     runcmd qw(env GZIP=-1n tar -zcf), "./$debtar", qw(-C ../../..), @files;
5447
5448     $dscaddfile->($debtar);
5449     close $fakedsc or die $!;
5450 }
5451
5452 sub quilt_check_splitbrain_cache ($$) {
5453     my ($headref, $upstreamversion) = @_;
5454     # Called only if we are in (potentially) split brain mode.
5455     # Called in playground.
5456     # Computes the cache key and looks in the cache.
5457     # Returns ($dgit_view_commitid, $cachekey) or (undef, $cachekey)
5458
5459     my $splitbrain_cachekey;
5460
5461     progress
5462  "dgit: split brain (separate dgit view) may be needed (--quilt=$quilt_mode).";
5463     # we look in the reflog of dgit-intern/quilt-cache
5464     # we look for an entry whose message is the key for the cache lookup
5465     my @cachekey = (qw(dgit), $our_version);
5466     push @cachekey, $upstreamversion;
5467     push @cachekey, $quilt_mode;
5468     push @cachekey, $headref;
5469
5470     push @cachekey, hashfile('fake.dsc');
5471
5472     my $srcshash = Digest::SHA->new(256);
5473     my %sfs = ( %INC, '$0(dgit)' => $0 );
5474     foreach my $sfk (sort keys %sfs) {
5475         next unless $sfk =~ m/^\$0\b/ || $sfk =~ m{^Debian/Dgit\b};
5476         $srcshash->add($sfk,"  ");
5477         $srcshash->add(hashfile($sfs{$sfk}));
5478         $srcshash->add("\n");
5479     }
5480     push @cachekey, $srcshash->hexdigest();
5481     $splitbrain_cachekey = "@cachekey";
5482
5483     my @cmd = (@git, qw(log -g), '--pretty=format:%H %gs',
5484                $splitbraincache);
5485     printdebug "splitbrain cachekey $splitbrain_cachekey\n";
5486     debugcmd "|(probably)",@cmd;
5487     my $child = open GC, "-|";  defined $child or die $!;
5488     if (!$child) {
5489         chdir '../../..' or die $!;
5490         if (!stat ".git/logs/refs/$splitbraincache") {
5491             $! == ENOENT or die $!;
5492             printdebug ">(no reflog)\n";
5493             exit 0;
5494         }
5495         exec @cmd; die $!;
5496     }
5497     while (<GC>) {
5498         chomp;
5499         printdebug ">| ", $_, "\n" if $debuglevel > 1;
5500         next unless m/^(\w+) (\S.*\S)$/ && $2 eq $splitbrain_cachekey;
5501
5502         my $cachehit = $1;
5503         quilt_fixup_mkwork($headref);
5504         my $saved = maybe_split_brain_save $headref, $cachehit, "cache-hit";
5505         if ($cachehit ne $headref) {
5506             progress "dgit view: found cached ($saved)";
5507             runcmd @git, qw(checkout -q -b dgit-view), $cachehit;
5508             $split_brain = 1;
5509             return ($cachehit, $splitbrain_cachekey);
5510         }
5511         progress "dgit view: found cached, no changes required";
5512         return ($headref, $splitbrain_cachekey);
5513     }
5514     die $! if GC->error;
5515     failedcmd unless close GC;
5516
5517     printdebug "splitbrain cache miss\n";
5518     return (undef, $splitbrain_cachekey);
5519 }
5520
5521 sub quilt_fixup_multipatch ($$$) {
5522     my ($clogp, $headref, $upstreamversion) = @_;
5523
5524     progress "examining quilt state (multiple patches, $quilt_mode mode)";
5525
5526     # Our objective is:
5527     #  - honour any existing .pc in case it has any strangeness
5528     #  - determine the git commit corresponding to the tip of
5529     #    the patch stack (if there is one)
5530     #  - if there is such a git commit, convert each subsequent
5531     #    git commit into a quilt patch with dpkg-source --commit
5532     #  - otherwise convert all the differences in the tree into
5533     #    a single git commit
5534     #
5535     # To do this we:
5536
5537     # Our git tree doesn't necessarily contain .pc.  (Some versions of
5538     # dgit would include the .pc in the git tree.)  If there isn't
5539     # one, we need to generate one by unpacking the patches that we
5540     # have.
5541     #
5542     # We first look for a .pc in the git tree.  If there is one, we
5543     # will use it.  (This is not the normal case.)
5544     #
5545     # Otherwise need to regenerate .pc so that dpkg-source --commit
5546     # can work.  We do this as follows:
5547     #     1. Collect all relevant .orig from parent directory
5548     #     2. Generate a debian.tar.gz out of
5549     #         debian/{patches,rules,source/format,source/options}
5550     #     3. Generate a fake .dsc containing just these fields:
5551     #          Format Source Version Files
5552     #     4. Extract the fake .dsc
5553     #        Now the fake .dsc has a .pc directory.
5554     # (In fact we do this in every case, because in future we will
5555     # want to search for a good base commit for generating patches.)
5556     #
5557     # Then we can actually do the dpkg-source --commit
5558     #     1. Make a new working tree with the same object
5559     #        store as our main tree and check out the main
5560     #        tree's HEAD.
5561     #     2. Copy .pc from the fake's extraction, if necessary
5562     #     3. Run dpkg-source --commit
5563     #     4. If the result has changes to debian/, then
5564     #          - git add them them
5565     #          - git add .pc if we had a .pc in-tree
5566     #          - git commit
5567     #     5. If we had a .pc in-tree, delete it, and git commit
5568     #     6. Back in the main tree, fast forward to the new HEAD
5569
5570     # Another situation we may have to cope with is gbp-style
5571     # patches-unapplied trees.
5572     #
5573     # We would want to detect these, so we know to escape into
5574     # quilt_fixup_gbp.  However, this is in general not possible.
5575     # Consider a package with a one patch which the dgit user reverts
5576     # (with git revert or the moral equivalent).
5577     #
5578     # That is indistinguishable in contents from a patches-unapplied
5579     # tree.  And looking at the history to distinguish them is not
5580     # useful because the user might have made a confusing-looking git
5581     # history structure (which ought to produce an error if dgit can't
5582     # cope, not a silent reintroduction of an unwanted patch).
5583     #
5584     # So gbp users will have to pass an option.  But we can usually
5585     # detect their failure to do so: if the tree is not a clean
5586     # patches-applied tree, quilt linearisation fails, but the tree
5587     # _is_ a clean patches-unapplied tree, we can suggest that maybe
5588     # they want --quilt=unapplied.
5589     #
5590     # To help detect this, when we are extracting the fake dsc, we
5591     # first extract it with --skip-patches, and then apply the patches
5592     # afterwards with dpkg-source --before-build.  That lets us save a
5593     # tree object corresponding to .origs.
5594
5595     my $splitbrain_cachekey;
5596
5597     quilt_make_fake_dsc($upstreamversion);
5598
5599     if (quiltmode_splitbrain()) {
5600         my $cachehit;
5601         ($cachehit, $splitbrain_cachekey) =
5602             quilt_check_splitbrain_cache($headref, $upstreamversion);
5603         return if $cachehit;
5604     }
5605
5606     runcmd qw(sh -ec),
5607         'exec dpkg-source --no-check --skip-patches -x fake.dsc >/dev/null';
5608
5609     my $fakexdir= $package.'-'.(stripepoch $upstreamversion);
5610     rename $fakexdir, "fake" or die "$fakexdir $!";
5611
5612     changedir 'fake';
5613
5614     remove_stray_gits("source package");
5615     mktree_in_ud_here();
5616
5617     rmtree '.pc';
5618
5619     runcmd @git, qw(checkout -f), $headref, qw(-- debian);
5620     my $unapplied=git_add_write_tree();
5621     printdebug "fake orig tree object $unapplied\n";
5622
5623     ensuredir '.pc';
5624
5625     my @bbcmd = (qw(sh -ec), 'exec dpkg-source --before-build . >/dev/null');
5626     $!=0; $?=-1;
5627     if (system @bbcmd) {
5628         failedcmd @bbcmd if $? < 0;
5629         fail <<END;
5630 failed to apply your git tree's patch stack (from debian/patches/) to
5631  the corresponding upstream tarball(s).  Your source tree and .orig
5632  are probably too inconsistent.  dgit can only fix up certain kinds of
5633  anomaly (depending on the quilt mode).  See --quilt= in dgit(1).
5634 END
5635     }
5636
5637     changedir '..';
5638
5639     quilt_fixup_mkwork($headref);
5640
5641     my $mustdeletepc=0;
5642     if (stat_exists ".pc") {
5643         -d _ or die;
5644         progress "Tree already contains .pc - will use it then delete it.";
5645         $mustdeletepc=1;
5646     } else {
5647         rename '../fake/.pc','.pc' or die $!;
5648     }
5649
5650     changedir '../fake';
5651     rmtree '.pc';
5652     my $oldtiptree=git_add_write_tree();
5653     printdebug "fake o+d/p tree object $unapplied\n";
5654     changedir '../work';
5655
5656
5657     # We calculate some guesswork now about what kind of tree this might
5658     # be.  This is mostly for error reporting.
5659
5660     my %editedignores;
5661     my @unrepres;
5662     my $diffbits = {
5663         # H = user's HEAD
5664         # O = orig, without patches applied
5665         # A = "applied", ie orig with H's debian/patches applied
5666         O2H => quiltify_trees_differ($unapplied,$headref,   1,
5667                                      \%editedignores, \@unrepres),
5668         H2A => quiltify_trees_differ($headref,  $oldtiptree,1),
5669         O2A => quiltify_trees_differ($unapplied,$oldtiptree,1),
5670     };
5671
5672     my @dl;
5673     foreach my $b (qw(01 02)) {
5674         foreach my $v (qw(O2H O2A H2A)) {
5675             push @dl, ($diffbits->{$v} & $b) ? '##' : '==';
5676         }
5677     }
5678     printdebug "differences \@dl @dl.\n";
5679
5680     progress sprintf
5681 "$us: base trees orig=%.20s o+d/p=%.20s",
5682               $unapplied, $oldtiptree;
5683     progress sprintf
5684 "$us: quilt differences: src:  %s orig %s     gitignores:  %s orig %s\n".
5685 "$us: quilt differences:      HEAD %s o+d/p               HEAD %s o+d/p",
5686                              $dl[0], $dl[1],              $dl[3], $dl[4],
5687                                  $dl[2],                     $dl[5];
5688
5689     if (@unrepres) {
5690         print STDERR "dgit:  cannot represent change: $_->[1]: $_->[0]\n"
5691             foreach @unrepres;
5692         forceable_fail [qw(unrepresentable)], <<END;
5693 HEAD has changes to .orig[s] which are not representable by `3.0 (quilt)'
5694 END
5695     }
5696
5697     my @failsuggestion;
5698     if (!($diffbits->{O2H} & $diffbits->{O2A})) {
5699         push @failsuggestion, "This might be a patches-unapplied branch.";
5700     }  elsif (!($diffbits->{H2A} & $diffbits->{O2A})) {
5701         push @failsuggestion, "This might be a patches-applied branch.";
5702     }
5703     push @failsuggestion, "Maybe you need to specify one of".
5704         " --[quilt=]gbp --[quilt=]dpm --quilt=unapplied ?";
5705
5706     if (quiltmode_splitbrain()) {
5707         quiltify_splitbrain($clogp, $unapplied, $headref,
5708                             $diffbits, \%editedignores,
5709                             $splitbrain_cachekey);
5710         return;
5711     }
5712
5713     progress "starting quiltify (multiple patches, $quilt_mode mode)";
5714     quiltify($clogp,$headref,$oldtiptree,\@failsuggestion);
5715
5716     if (!open P, '>>', ".pc/applied-patches") {
5717         $!==&ENOENT or die $!;
5718     } else {
5719         close P;
5720     }
5721
5722     commit_quilty_patch();
5723
5724     if ($mustdeletepc) {
5725         quilt_fixup_delete_pc();
5726     }
5727 }
5728
5729 sub quilt_fixup_editor () {
5730     my $descfn = $ENV{$fakeeditorenv};
5731     my $editing = $ARGV[$#ARGV];
5732     open I1, '<', $descfn or die "$descfn: $!";
5733     open I2, '<', $editing or die "$editing: $!";
5734     unlink $editing or die "$editing: $!";
5735     open O, '>', $editing or die "$editing: $!";
5736     while (<I1>) { print O or die $!; } I1->error and die $!;
5737     my $copying = 0;
5738     while (<I2>) {
5739         $copying ||= m/^\-\-\- /;
5740         next unless $copying;
5741         print O or die $!;
5742     }
5743     I2->error and die $!;
5744     close O or die $1;
5745     exit 0;
5746 }
5747
5748 sub maybe_apply_patches_dirtily () {
5749     return unless $quilt_mode =~ m/gbp|unapplied/;
5750     print STDERR <<END or die $!;
5751
5752 dgit: Building, or cleaning with rules target, in patches-unapplied tree.
5753 dgit: Have to apply the patches - making the tree dirty.
5754 dgit: (Consider specifying --clean=git and (or) using dgit sbuild.)
5755
5756 END
5757     $patches_applied_dirtily = 01;
5758     $patches_applied_dirtily |= 02 unless stat_exists '.pc';
5759     runcmd qw(dpkg-source --before-build .);
5760 }
5761
5762 sub maybe_unapply_patches_again () {
5763     progress "dgit: Unapplying patches again to tidy up the tree."
5764         if $patches_applied_dirtily;
5765     runcmd qw(dpkg-source --after-build .)
5766         if $patches_applied_dirtily & 01;
5767     rmtree '.pc'
5768         if $patches_applied_dirtily & 02;
5769     $patches_applied_dirtily = 0;
5770 }
5771
5772 #----- other building -----
5773
5774 our $clean_using_builder;
5775 # ^ tree is to be cleaned by dpkg-source's builtin idea that it should
5776 #   clean the tree before building (perhaps invoked indirectly by
5777 #   whatever we are using to run the build), rather than separately
5778 #   and explicitly by us.
5779
5780 sub clean_tree () {
5781     return if $clean_using_builder;
5782     if ($cleanmode eq 'dpkg-source') {
5783         maybe_apply_patches_dirtily();
5784         runcmd_ordryrun_local @dpkgbuildpackage, qw(-T clean);
5785     } elsif ($cleanmode eq 'dpkg-source-d') {
5786         maybe_apply_patches_dirtily();
5787         runcmd_ordryrun_local @dpkgbuildpackage, qw(-d -T clean);
5788     } elsif ($cleanmode eq 'git') {
5789         runcmd_ordryrun_local @git, qw(clean -xdf);
5790     } elsif ($cleanmode eq 'git-ff') {
5791         runcmd_ordryrun_local @git, qw(clean -xdff);
5792     } elsif ($cleanmode eq 'check') {
5793         my $leftovers = cmdoutput @git, qw(clean -xdn);
5794         if (length $leftovers) {
5795             print STDERR $leftovers, "\n" or die $!;
5796             fail "tree contains uncommitted files and --clean=check specified";
5797         }
5798     } elsif ($cleanmode eq 'none') {
5799     } else {
5800         die "$cleanmode ?";
5801     }
5802 }
5803
5804 sub cmd_clean () {
5805     badusage "clean takes no additional arguments" if @ARGV;
5806     notpushing();
5807     clean_tree();
5808     maybe_unapply_patches_again();
5809 }
5810
5811 sub build_or_push_prep_early () {
5812     our $build_or_push_prep_early_done //= 0;
5813     return if $build_or_push_prep_early_done++;
5814     badusage "-p is not allowed with dgit $subcommand" if defined $package;
5815     my $clogp = parsechangelog();
5816     $isuite = getfield $clogp, 'Distribution';
5817     $package = getfield $clogp, 'Source';
5818     $version = getfield $clogp, 'Version';
5819 }
5820
5821 sub build_prep_early () {
5822     build_or_push_prep_early();
5823     notpushing();
5824     check_not_dirty();
5825 }
5826
5827 sub build_prep () {
5828     build_prep_early();
5829     clean_tree();
5830     build_maybe_quilt_fixup();
5831     if ($rmchanges) {
5832         my $pat = changespat $version;
5833         foreach my $f (glob "$buildproductsdir/$pat") {
5834             if (act_local()) {
5835                 unlink $f or fail "remove old changes file $f: $!";
5836             } else {
5837                 progress "would remove $f";
5838             }
5839         }
5840     }
5841 }
5842
5843 sub changesopts_initial () {
5844     my @opts =@changesopts[1..$#changesopts];
5845 }
5846
5847 sub changesopts_version () {
5848     if (!defined $changes_since_version) {
5849         my @vsns = archive_query('archive_query');
5850         my @quirk = access_quirk();
5851         if ($quirk[0] eq 'backports') {
5852             local $isuite = $quirk[2];
5853             local $csuite;
5854             canonicalise_suite();
5855             push @vsns, archive_query('archive_query');
5856         }
5857         if (@vsns) {
5858             @vsns = map { $_->[0] } @vsns;
5859             @vsns = sort { -version_compare($a, $b) } @vsns;
5860             $changes_since_version = $vsns[0];
5861             progress "changelog will contain changes since $vsns[0]";
5862         } else {
5863             $changes_since_version = '_';
5864             progress "package seems new, not specifying -v<version>";
5865         }
5866     }
5867     if ($changes_since_version ne '_') {
5868         return ("-v$changes_since_version");
5869     } else {
5870         return ();
5871     }
5872 }
5873
5874 sub changesopts () {
5875     return (changesopts_initial(), changesopts_version());
5876 }
5877
5878 sub massage_dbp_args ($;$) {
5879     my ($cmd,$xargs) = @_;
5880     # We need to:
5881     #
5882     #  - if we're going to split the source build out so we can
5883     #    do strange things to it, massage the arguments to dpkg-buildpackage
5884     #    so that the main build doessn't build source (or add an argument
5885     #    to stop it building source by default).
5886     #
5887     #  - add -nc to stop dpkg-source cleaning the source tree,
5888     #    unless we're not doing a split build and want dpkg-source
5889     #    as cleanmode, in which case we can do nothing
5890     #
5891     # return values:
5892     #    0 - source will NOT need to be built separately by caller
5893     #   +1 - source will need to be built separately by caller
5894     #   +2 - source will need to be built separately by caller AND
5895     #        dpkg-buildpackage should not in fact be run at all!
5896     debugcmd '#massaging#', @$cmd if $debuglevel>1;
5897 #print STDERR "MASS0 ",Dumper($cmd, $xargs, $need_split_build_invocation);
5898     if ($cleanmode eq 'dpkg-source' && !$need_split_build_invocation) {
5899         $clean_using_builder = 1;
5900         return 0;
5901     }
5902     # -nc has the side effect of specifying -b if nothing else specified
5903     # and some combinations of -S, -b, et al, are errors, rather than
5904     # later simply overriding earlie.  So we need to:
5905     #  - search the command line for these options
5906     #  - pick the last one
5907     #  - perhaps add our own as a default
5908     #  - perhaps adjust it to the corresponding non-source-building version
5909     my $dmode = '-F';
5910     foreach my $l ($cmd, $xargs) {
5911         next unless $l;
5912         @$l = grep { !(m/^-[SgGFABb]$/s and $dmode=$_) } @$l;
5913     }
5914     push @$cmd, '-nc';
5915 #print STDERR "MASS1 ",Dumper($cmd, $xargs, $dmode);
5916     my $r = 0;
5917     if ($need_split_build_invocation) {
5918         printdebug "massage split $dmode.\n";
5919         $r = $dmode =~ m/[S]/     ? +2 :
5920              $dmode =~ y/gGF/ABb/ ? +1 :
5921              $dmode =~ m/[ABb]/   ?  0 :
5922              die "$dmode ?";
5923     }
5924     printdebug "massage done $r $dmode.\n";
5925     push @$cmd, $dmode;
5926 #print STDERR "MASS2 ",Dumper($cmd, $xargs, $r);
5927     return $r;
5928 }
5929
5930 sub in_parent (&) {
5931     my ($fn) = @_;
5932     my $wasdir = must_getcwd();
5933     changedir "..";
5934     $fn->();
5935     changedir $wasdir;
5936 }
5937
5938 sub postbuild_mergechanges ($) { # must run with CWD=.. (eg in in_parent)
5939     my ($msg_if_onlyone) = @_;
5940     # If there is only one .changes file, fail with $msg_if_onlyone,
5941     # or if that is undef, be a no-op.
5942     # Returns the changes file to report to the user.
5943     my $pat = changespat $version;
5944     my @changesfiles = glob $pat;
5945     @changesfiles = sort {
5946         ($b =~ m/_source\.changes$/ <=> $a =~ m/_source\.changes$/)
5947             or $a cmp $b
5948     } @changesfiles;
5949     my $result;
5950     if (@changesfiles==1) {
5951         fail <<END.$msg_if_onlyone if defined $msg_if_onlyone;
5952 only one changes file from build (@changesfiles)
5953 END
5954         $result = $changesfiles[0];
5955     } elsif (@changesfiles==2) {
5956         my $binchanges = parsecontrol($changesfiles[1], "binary changes file");
5957         foreach my $l (split /\n/, getfield $binchanges, 'Files') {
5958             fail "$l found in binaries changes file $binchanges"
5959                 if $l =~ m/\.dsc$/;
5960         }
5961         runcmd_ordryrun_local @mergechanges, @changesfiles;
5962         my $multichanges = changespat $version,'multi';
5963         if (act_local()) {
5964             stat_exists $multichanges or fail "$multichanges: $!";
5965             foreach my $cf (glob $pat) {
5966                 next if $cf eq $multichanges;
5967                 rename "$cf", "$cf.inmulti" or fail "$cf\{,.inmulti}: $!";
5968             }
5969         }
5970         $result = $multichanges;
5971     } else {
5972         fail "wrong number of different changes files (@changesfiles)";
5973     }
5974     printdone "build successful, results in $result\n" or die $!;
5975 }
5976
5977 sub midbuild_checkchanges () {
5978     my $pat = changespat $version;
5979     return if $rmchanges;
5980     my @unwanted = map { s#^\.\./##; $_; } glob "../$pat";
5981     @unwanted = grep { $_ ne changespat $version,'source' } @unwanted;
5982     fail <<END
5983 changes files other than source matching $pat already present; building would result in ambiguity about the intended results.
5984 Suggest you delete @unwanted.
5985 END
5986         if @unwanted;
5987 }
5988
5989 sub midbuild_checkchanges_vanilla ($) {
5990     my ($wantsrc) = @_;
5991     midbuild_checkchanges() if $wantsrc == 1;
5992 }
5993
5994 sub postbuild_mergechanges_vanilla ($) {
5995     my ($wantsrc) = @_;
5996     if ($wantsrc == 1) {
5997         in_parent {
5998             postbuild_mergechanges(undef);
5999         };
6000     } else {
6001         printdone "build successful\n";
6002     }
6003 }
6004
6005 sub cmd_build {
6006     build_prep_early();
6007     my @dbp = (@dpkgbuildpackage, qw(-us -uc), changesopts_initial(), @ARGV);
6008     my $wantsrc = massage_dbp_args \@dbp;
6009     if ($wantsrc > 0) {
6010         build_source();
6011         midbuild_checkchanges_vanilla $wantsrc;
6012     } else {
6013         build_prep();
6014     }
6015     if ($wantsrc < 2) {
6016         push @dbp, changesopts_version();
6017         maybe_apply_patches_dirtily();
6018         runcmd_ordryrun_local @dbp;
6019     }
6020     maybe_unapply_patches_again();
6021     postbuild_mergechanges_vanilla $wantsrc;
6022 }
6023
6024 sub pre_gbp_build {
6025     $quilt_mode //= 'gbp';
6026 }
6027
6028 sub cmd_gbp_build {
6029     build_prep_early();
6030
6031     # gbp can make .origs out of thin air.  In my tests it does this
6032     # even for a 1.0 format package, with no origs present.  So I
6033     # guess it keys off just the version number.  We don't know
6034     # exactly what .origs ought to exist, but let's assume that we
6035     # should run gbp if: the version has an upstream part and the main
6036     # orig is absent.
6037     my $upstreamversion = upstreamversion $version;
6038     my $origfnpat = srcfn $upstreamversion, '.orig.tar.*';
6039     my $gbp_make_orig = $version =~ m/-/ && !(() = glob "../$origfnpat");
6040
6041     if ($gbp_make_orig) {
6042         clean_tree();
6043         $cleanmode = 'none'; # don't do it again
6044         $need_split_build_invocation = 1;
6045     }
6046
6047     my @dbp = @dpkgbuildpackage;
6048
6049     my $wantsrc = massage_dbp_args \@dbp, \@ARGV;
6050
6051     if (!length $gbp_build[0]) {
6052         if (length executable_on_path('git-buildpackage')) {
6053             $gbp_build[0] = qw(git-buildpackage);
6054         } else {
6055             $gbp_build[0] = 'gbp buildpackage';
6056         }
6057     }
6058     my @cmd = opts_opt_multi_cmd @gbp_build;
6059
6060     push @cmd, (qw(-us -uc --git-no-sign-tags), "--git-builder=@dbp");
6061
6062     if ($gbp_make_orig) {
6063         ensuredir '.git/dgit';
6064         my $ok = '.git/dgit/origs-gen-ok';
6065         unlink $ok or $!==&ENOENT or die $!;
6066         my @origs_cmd = @cmd;
6067         push @origs_cmd, qw(--git-cleaner=true);
6068         push @origs_cmd, "--git-prebuild=touch $ok .git/dgit/no-such-dir/ok";
6069         push @origs_cmd, @ARGV;
6070         if (act_local()) {
6071             debugcmd @origs_cmd;
6072             system @origs_cmd;
6073             do { local $!; stat_exists $ok; }
6074                 or failedcmd @origs_cmd;
6075         } else {
6076             dryrun_report @origs_cmd;
6077         }
6078     }
6079
6080     if ($wantsrc > 0) {
6081         build_source();
6082         midbuild_checkchanges_vanilla $wantsrc;
6083     } else {
6084         if (!$clean_using_builder) {
6085             push @cmd, '--git-cleaner=true';
6086         }
6087         build_prep();
6088     }
6089     maybe_unapply_patches_again();
6090     if ($wantsrc < 2) {
6091         push @cmd, changesopts();
6092         runcmd_ordryrun_local @cmd, @ARGV;
6093     }
6094     postbuild_mergechanges_vanilla $wantsrc;
6095 }
6096 sub cmd_git_build { cmd_gbp_build(); } # compatibility with <= 1.0
6097
6098 sub build_source {
6099     build_prep_early();
6100     my $our_cleanmode = $cleanmode;
6101     if ($need_split_build_invocation) {
6102         # Pretend that clean is being done some other way.  This
6103         # forces us not to try to use dpkg-buildpackage to clean and
6104         # build source all in one go; and instead we run dpkg-source
6105         # (and build_prep() will do the clean since $clean_using_builder
6106         # is false).
6107         $our_cleanmode = 'ELSEWHERE';
6108     }
6109     if ($our_cleanmode =~ m/^dpkg-source/) {
6110         # dpkg-source invocation (below) will clean, so build_prep shouldn't
6111         $clean_using_builder = 1;
6112     }
6113     build_prep();
6114     $sourcechanges = changespat $version,'source';
6115     if (act_local()) {
6116         unlink "../$sourcechanges" or $!==ENOENT
6117             or fail "remove $sourcechanges: $!";
6118     }
6119     $dscfn = dscfn($version);
6120     if ($our_cleanmode eq 'dpkg-source') {
6121         maybe_apply_patches_dirtily();
6122         runcmd_ordryrun_local @dpkgbuildpackage, qw(-us -uc -S),
6123             changesopts();
6124     } elsif ($our_cleanmode eq 'dpkg-source-d') {
6125         maybe_apply_patches_dirtily();
6126         runcmd_ordryrun_local @dpkgbuildpackage, qw(-us -uc -S -d),
6127             changesopts();
6128     } else {
6129         my @cmd = (@dpkgsource, qw(-b --));
6130         if ($split_brain) {
6131             changedir $playground;
6132             runcmd_ordryrun_local @cmd, "work";
6133             my @udfiles = <${package}_*>;
6134             changedir $maindir;
6135             foreach my $f (@udfiles) {
6136                 printdebug "source copy, found $f\n";
6137                 next unless
6138                     $f eq $dscfn or
6139                     ($f =~ m/\.debian\.tar(?:\.\w+)$/ &&
6140                      $f eq srcfn($version, $&));
6141                 printdebug "source copy, found $f - renaming\n";
6142                 rename "$playground/$f", "../$f" or $!==ENOENT
6143                     or fail "put in place new source file ($f): $!";
6144             }
6145         } else {
6146             my $pwd = must_getcwd();
6147             my $leafdir = basename $pwd;
6148             changedir "..";
6149             runcmd_ordryrun_local @cmd, $leafdir;
6150             changedir $pwd;
6151         }
6152         runcmd_ordryrun_local qw(sh -ec),
6153             'exec >$1; shift; exec "$@"','x',
6154             "../$sourcechanges",
6155             @dpkggenchanges, qw(-S), changesopts();
6156     }
6157 }
6158
6159 sub cmd_build_source {
6160     build_prep_early();
6161     badusage "build-source takes no additional arguments" if @ARGV;
6162     build_source();
6163     maybe_unapply_patches_again();
6164     printdone "source built, results in $dscfn and $sourcechanges";
6165 }
6166
6167 sub cmd_sbuild {
6168     build_source();
6169     midbuild_checkchanges();
6170     in_parent {
6171         if (act_local()) {
6172             stat_exists $dscfn or fail "$dscfn (in parent directory): $!";
6173             stat_exists $sourcechanges
6174                 or fail "$sourcechanges (in parent directory): $!";
6175         }
6176         runcmd_ordryrun_local @sbuild, qw(-d), $isuite, @ARGV, $dscfn;
6177     };
6178     maybe_unapply_patches_again();
6179     in_parent {
6180         postbuild_mergechanges(<<END);
6181 perhaps you need to pass -A ?  (sbuild's default is to build only
6182 arch-specific binaries; dgit 1.4 used to override that.)
6183 END
6184     };
6185 }
6186
6187 sub cmd_quilt_fixup {
6188     badusage "incorrect arguments to dgit quilt-fixup" if @ARGV;
6189     build_prep_early();
6190     clean_tree();
6191     build_maybe_quilt_fixup();
6192 }
6193
6194 sub import_dsc_result {
6195     my ($dstref, $newhash, $what_log, $what_msg) = @_;
6196     my @cmd = (@git, qw(update-ref -m), $what_log, $dstref, $newhash);
6197     runcmd @cmd;
6198     check_gitattrs($newhash, "source tree");
6199
6200     progress "dgit: import-dsc: $what_msg";
6201 }
6202
6203 sub cmd_import_dsc {
6204     my $needsig = 0;
6205
6206     while (@ARGV) {
6207         last unless $ARGV[0] =~ m/^-/;
6208         $_ = shift @ARGV;
6209         last if m/^--?$/;
6210         if (m/^--require-valid-signature$/) {
6211             $needsig = 1;
6212         } else {
6213             badusage "unknown dgit import-dsc sub-option \`$_'";
6214         }
6215     }
6216
6217     badusage "usage: dgit import-dsc .../PATH/TO/.DSC BRANCH" unless @ARGV==2;
6218     my ($dscfn, $dstbranch) = @ARGV;
6219
6220     badusage "dry run makes no sense with import-dsc" unless act_local();
6221
6222     my $force = $dstbranch =~ s/^\+//   ? +1 :
6223                 $dstbranch =~ s/^\.\.// ? -1 :
6224                                            0;
6225     my $info = $force ? " $&" : '';
6226     $info = "$dscfn$info";
6227
6228     my $specbranch = $dstbranch;
6229     $dstbranch = "refs/heads/$dstbranch" unless $dstbranch =~ m#^refs/#;
6230     $dstbranch = cmdoutput @git, qw(check-ref-format --normalize), $dstbranch;
6231
6232     my @symcmd = (@git, qw(symbolic-ref -q HEAD));
6233     my $chead = cmdoutput_errok @symcmd;
6234     defined $chead or $?==256 or failedcmd @symcmd;
6235
6236     fail "$dstbranch is checked out - will not update it"
6237         if defined $chead and $chead eq $dstbranch;
6238
6239     my $oldhash = git_get_ref $dstbranch;
6240
6241     open D, "<", $dscfn or fail "open import .dsc ($dscfn): $!";
6242     $dscdata = do { local $/ = undef; <D>; };
6243     D->error and fail "read $dscfn: $!";
6244     close C;
6245
6246     # we don't normally need this so import it here
6247     use Dpkg::Source::Package;
6248     my $dp = new Dpkg::Source::Package filename => $dscfn,
6249         require_valid_signature => $needsig;
6250     {
6251         local $SIG{__WARN__} = sub {
6252             print STDERR $_[0];
6253             return unless $needsig;
6254             fail "import-dsc signature check failed";
6255         };
6256         if (!$dp->is_signed()) {
6257             warn "$us: warning: importing unsigned .dsc\n";
6258         } else {
6259             my $r = $dp->check_signature();
6260             die "->check_signature => $r" if $needsig && $r;
6261         }
6262     }
6263
6264     parse_dscdata();
6265
6266     $package = getfield $dsc, 'Source';
6267
6268     parse_dsc_field($dsc, "Dgit metadata in .dsc")
6269         unless forceing [qw(import-dsc-with-dgit-field)];
6270     parse_dsc_field_def_dsc_distro();
6271
6272     $isuite = 'DGIT-IMPORT-DSC';
6273     $idistro //= $dsc_distro;
6274
6275     notpushing();
6276
6277     if (defined $dsc_hash) {
6278         progress "dgit: import-dsc of .dsc with Dgit field, using git hash";
6279         resolve_dsc_field_commit undef, undef;
6280     }
6281     if (defined $dsc_hash) {
6282         my @cmd = (qw(sh -ec),
6283                    "echo $dsc_hash | git cat-file --batch-check");
6284         my $objgot = cmdoutput @cmd;
6285         if ($objgot =~ m#^\w+ missing\b#) {
6286             fail <<END
6287 .dsc contains Dgit field referring to object $dsc_hash
6288 Your git tree does not have that object.  Try `git fetch' from a
6289 plausible server (browse.dgit.d.o? alioth?), and try the import-dsc again.
6290 END
6291         }
6292         if ($oldhash && !is_fast_fwd $oldhash, $dsc_hash) {
6293             if ($force > 0) {
6294                 progress "Not fast forward, forced update.";
6295             } else {
6296                 fail "Not fast forward to $dsc_hash";
6297             }
6298         }
6299         import_dsc_result $dstbranch, $dsc_hash,
6300             "dgit import-dsc (Dgit): $info",
6301             "updated git ref $dstbranch";
6302         return 0;
6303     }
6304
6305     fail <<END
6306 Branch $dstbranch already exists
6307 Specify ..$specbranch for a pseudo-merge, binding in existing history
6308 Specify  +$specbranch to overwrite, discarding existing history
6309 END
6310         if $oldhash && !$force;
6311
6312     my @dfi = dsc_files_info();
6313     foreach my $fi (@dfi) {
6314         my $f = $fi->{Filename};
6315         my $here = "../$f";
6316         if (lstat $here) {
6317             next if stat $here;
6318             fail "lstat $here works but stat gives $! !";
6319         }
6320         fail "stat $here: $!" unless $! == ENOENT;
6321         my $there = $dscfn;
6322         if ($dscfn =~ m#^(?:\./+)?\.\./+#) {
6323             $there = $';
6324         } elsif ($dscfn =~ m#^/#) {
6325             $there = $dscfn;
6326         } else {
6327             fail "cannot import $dscfn which seems to be inside working tree!";
6328         }
6329         $there =~ s#/+[^/]+$## or
6330             fail "import $dscfn requires ../$f, but it does not exist";
6331         $there .= "/$f";
6332         my $test = $there =~ m{^/} ? $there : "../$there";
6333         stat $test or fail "import $dscfn requires $test, but: $!";
6334         symlink $there, $here or fail "symlink $there to $here: $!";
6335         progress "made symlink $here -> $there";
6336 #       print STDERR Dumper($fi);
6337     }
6338     my @mergeinputs = generate_commits_from_dsc();
6339     die unless @mergeinputs == 1;
6340
6341     my $newhash = $mergeinputs[0]{Commit};
6342
6343     if ($oldhash) {
6344         if ($force > 0) {
6345             progress "Import, forced update - synthetic orphan git history.";
6346         } elsif ($force < 0) {
6347             progress "Import, merging.";
6348             my $tree = cmdoutput @git, qw(rev-parse), "$newhash:";
6349             my $version = getfield $dsc, 'Version';
6350             my $clogp = commit_getclogp $newhash;
6351             my $authline = clogp_authline $clogp;
6352             $newhash = make_commit_text <<END;
6353 tree $tree
6354 parent $newhash
6355 parent $oldhash
6356 author $authline
6357 committer $authline
6358
6359 Merge $package ($version) import into $dstbranch
6360 END
6361         } else {
6362             die; # caught earlier
6363         }
6364     }
6365
6366     import_dsc_result $dstbranch, $newhash,
6367         "dgit import-dsc: $info",
6368         "results are in in git ref $dstbranch";
6369 }
6370
6371 sub pre_archive_api_query () {
6372     no_local_git_cfg();
6373 }
6374 sub cmd_archive_api_query {
6375     badusage "need only 1 subpath argument" unless @ARGV==1;
6376     my ($subpath) = @ARGV;
6377     my @cmd = archive_api_query_cmd($subpath);
6378     push @cmd, qw(-f);
6379     debugcmd ">",@cmd;
6380     exec @cmd or fail "exec curl: $!\n";
6381 }
6382
6383 sub repos_server_url () {
6384     $package = '_dgit-repos-server';
6385     local $access_forpush = 1;
6386     local $isuite = 'DGIT-REPOS-SERVER';
6387     my $url = access_giturl();
6388 }
6389
6390 sub pre_clone_dgit_repos_server () {
6391     no_local_git_cfg();
6392 }
6393 sub cmd_clone_dgit_repos_server {
6394     badusage "need destination argument" unless @ARGV==1;
6395     my ($destdir) = @ARGV;
6396     my $url = repos_server_url();
6397     my @cmd = (@git, qw(clone), $url, $destdir);
6398     debugcmd ">",@cmd;
6399     exec @cmd or fail "exec git clone: $!\n";
6400 }
6401
6402 sub pre_print_dgit_repos_server_source_url () {
6403     no_local_git_cfg();
6404 }
6405 sub cmd_print_dgit_repos_server_source_url {
6406     badusage "no arguments allowed to dgit print-dgit-repos-server-source-url"
6407         if @ARGV;
6408     my $url = repos_server_url();
6409     print $url, "\n" or die $!;
6410 }
6411
6412 sub cmd_setup_mergechangelogs {
6413     badusage "no arguments allowed to dgit setup-mergechangelogs" if @ARGV;
6414     local $isuite = 'DGIT-SETUP-TREE';
6415     setup_mergechangelogs(1);
6416 }
6417
6418 sub cmd_setup_useremail {
6419     badusage "no arguments allowed to dgit setup-useremail" if @ARGV;
6420     local $isuite = 'DGIT-SETUP-TREE';
6421     setup_useremail(1);
6422 }
6423
6424 sub cmd_setup_gitattributes {
6425     badusage "no arguments allowed to dgit setup-useremail" if @ARGV;
6426     local $isuite = 'DGIT-SETUP-TREE';
6427     setup_gitattrs(1);
6428 }
6429
6430 sub cmd_setup_new_tree {
6431     badusage "no arguments allowed to dgit setup-tree" if @ARGV;
6432     local $isuite = 'DGIT-SETUP-TREE';
6433     setup_new_tree();
6434 }
6435
6436 #---------- argument parsing and main program ----------
6437
6438 sub cmd_version {
6439     print "dgit version $our_version\n" or die $!;
6440     exit 0;
6441 }
6442
6443 our (%valopts_long, %valopts_short);
6444 our (%funcopts_long);
6445 our @rvalopts;
6446 our (@modeopt_cfgs);
6447
6448 sub defvalopt ($$$$) {
6449     my ($long,$short,$val_re,$how) = @_;
6450     my $oi = { Long => $long, Short => $short, Re => $val_re, How => $how };
6451     $valopts_long{$long} = $oi;
6452     $valopts_short{$short} = $oi;
6453     # $how subref should:
6454     #   do whatever assignemnt or thing it likes with $_[0]
6455     #   if the option should not be passed on to remote, @rvalopts=()
6456     # or $how can be a scalar ref, meaning simply assign the value
6457 }
6458
6459 defvalopt '--since-version', '-v', '[^_]+|_', \$changes_since_version;
6460 defvalopt '--distro',        '-d', '.+',      \$idistro;
6461 defvalopt '',                '-k', '.+',      \$keyid;
6462 defvalopt '--existing-package','', '.*',      \$existing_package;
6463 defvalopt '--build-products-dir','','.*',     \$buildproductsdir;
6464 defvalopt '--clean',       '', $cleanmode_re, \$cleanmode;
6465 defvalopt '--package',   '-p',   $package_re, \$package;
6466 defvalopt '--quilt',     '', $quilt_modes_re, \$quilt_mode;
6467
6468 defvalopt '', '-C', '.+', sub {
6469     ($changesfile) = (@_);
6470     if ($changesfile =~ s#^(.*)/##) {
6471         $buildproductsdir = $1;
6472     }
6473 };
6474
6475 defvalopt '--initiator-tempdir','','.*', sub {
6476     ($initiator_tempdir) = (@_);
6477     $initiator_tempdir =~ m#^/# or
6478         badusage "--initiator-tempdir must be used specify an".
6479         " absolute, not relative, directory."
6480 };
6481
6482 sub defoptmodes ($@) {
6483     my ($varref, $cfgkey, $default, %optmap) = @_;
6484     my %permit;
6485     while (my ($opt,$val) = each %optmap) {
6486         $funcopts_long{$opt} = sub { $$varref = $val; };
6487         $permit{$val} = $val;
6488     }
6489     push @modeopt_cfgs, {
6490         Var => $varref,
6491         Key => $cfgkey,
6492         Default => $default,
6493         Vals => \%permit
6494     };
6495 }
6496
6497 defoptmodes \$dodep14tag, qw( dep14tag          want
6498                               --dep14tag        want
6499                               --no-dep14tag     no
6500                               --always-dep14tag always );
6501
6502 sub parseopts () {
6503     my $om;
6504
6505     if (defined $ENV{'DGIT_SSH'}) {
6506         @ssh = string_to_ssh $ENV{'DGIT_SSH'};
6507     } elsif (defined $ENV{'GIT_SSH'}) {
6508         @ssh = ($ENV{'GIT_SSH'});
6509     }
6510
6511     my $oi;
6512     my $val;
6513     my $valopt = sub {
6514         my ($what) = @_;
6515         @rvalopts = ($_);
6516         if (!defined $val) {
6517             badusage "$what needs a value" unless @ARGV;
6518             $val = shift @ARGV;
6519             push @rvalopts, $val;
6520         }
6521         badusage "bad value \`$val' for $what" unless
6522             $val =~ m/^$oi->{Re}$(?!\n)/s;
6523         my $how = $oi->{How};
6524         if (ref($how) eq 'SCALAR') {
6525             $$how = $val;
6526         } else {
6527             $how->($val);
6528         }
6529         push @ropts, @rvalopts;
6530     };
6531
6532     while (@ARGV) {
6533         last unless $ARGV[0] =~ m/^-/;
6534         $_ = shift @ARGV;
6535         last if m/^--?$/;
6536         if (m/^--/) {
6537             if (m/^--dry-run$/) {
6538                 push @ropts, $_;
6539                 $dryrun_level=2;
6540             } elsif (m/^--damp-run$/) {
6541                 push @ropts, $_;
6542                 $dryrun_level=1;
6543             } elsif (m/^--no-sign$/) {
6544                 push @ropts, $_;
6545                 $sign=0;
6546             } elsif (m/^--help$/) {
6547                 cmd_help();
6548             } elsif (m/^--version$/) {
6549                 cmd_version();
6550             } elsif (m/^--new$/) {
6551                 push @ropts, $_;
6552                 $new_package=1;
6553             } elsif (m/^--([-0-9a-z]+)=(.+)/s &&
6554                      ($om = $opts_opt_map{$1}) &&
6555                      length $om->[0]) {
6556                 push @ropts, $_;
6557                 $om->[0] = $2;
6558             } elsif (m/^--([-0-9a-z]+):(.*)/s &&
6559                      !$opts_opt_cmdonly{$1} &&
6560                      ($om = $opts_opt_map{$1})) {
6561                 push @ropts, $_;
6562                 push @$om, $2;
6563             } elsif (m/^--(gbp|dpm)$/s) {
6564                 push @ropts, "--quilt=$1";
6565                 $quilt_mode = $1;
6566             } elsif (m/^--ignore-dirty$/s) {
6567                 push @ropts, $_;
6568                 $ignoredirty = 1;
6569             } elsif (m/^--no-quilt-fixup$/s) {
6570                 push @ropts, $_;
6571                 $quilt_mode = 'nocheck';
6572             } elsif (m/^--no-rm-on-error$/s) {
6573                 push @ropts, $_;
6574                 $rmonerror = 0;
6575             } elsif (m/^--no-chase-dsc-distro$/s) {
6576                 push @ropts, $_;
6577                 $chase_dsc_distro = 0;
6578             } elsif (m/^--overwrite$/s) {
6579                 push @ropts, $_;
6580                 $overwrite_version = '';
6581             } elsif (m/^--overwrite=(.+)$/s) {
6582                 push @ropts, $_;
6583                 $overwrite_version = $1;
6584             } elsif (m/^--delayed=(\d+)$/s) {
6585                 push @ropts, $_;
6586                 push @dput, $_;
6587             } elsif (m/^--dgit-view-save=(.+)$/s) {
6588                 push @ropts, $_;
6589                 $split_brain_save = $1;
6590                 $split_brain_save =~ s#^(?!refs/)#refs/heads/#;
6591             } elsif (m/^--(no-)?rm-old-changes$/s) {
6592                 push @ropts, $_;
6593                 $rmchanges = !$1;
6594             } elsif (m/^--deliberately-($deliberately_re)$/s) {
6595                 push @ropts, $_;
6596                 push @deliberatelies, $&;
6597             } elsif (m/^--force-(.*)/ && defined $forceopts{$1}) {
6598                 push @ropts, $&;
6599                 $forceopts{$1} = 1;
6600                 $_='';
6601             } elsif (m/^--force-/) {
6602                 print STDERR
6603                     "$us: warning: ignoring unknown force option $_\n";
6604                 $_='';
6605             } elsif (m/^--dgit-tag-format=(old|new)$/s) {
6606                 # undocumented, for testing
6607                 push @ropts, $_;
6608                 $tagformat_want = [ $1, 'command line', 1 ];
6609                 # 1 menas overrides distro configuration
6610             } elsif (m/^--always-split-source-build$/s) {
6611                 # undocumented, for testing
6612                 push @ropts, $_;
6613                 $need_split_build_invocation = 1;
6614             } elsif (m/^--config-lookup-explode=(.+)$/s) {
6615                 # undocumented, for testing
6616                 push @ropts, $_;
6617                 $gitcfgs{cmdline}{$1} = 'CONFIG-LOOKUP-EXPLODE';
6618                 # ^ it's supposed to be an array ref
6619             } elsif (m/^(--[-0-9a-z]+)(=|$)/ && ($oi = $valopts_long{$1})) {
6620                 $val = $2 ? $' : undef; #';
6621                 $valopt->($oi->{Long});
6622             } elsif ($funcopts_long{$_}) {
6623                 push @ropts, $_;
6624                 $funcopts_long{$_}();
6625             } else {
6626                 badusage "unknown long option \`$_'";
6627             }
6628         } else {
6629             while (m/^-./s) {
6630                 if (s/^-n/-/) {
6631                     push @ropts, $&;
6632                     $dryrun_level=2;
6633                 } elsif (s/^-L/-/) {
6634                     push @ropts, $&;
6635                     $dryrun_level=1;
6636                 } elsif (s/^-h/-/) {
6637                     cmd_help();
6638                 } elsif (s/^-D/-/) {
6639                     push @ropts, $&;
6640                     $debuglevel++;
6641                     enabledebug();
6642                 } elsif (s/^-N/-/) {
6643                     push @ropts, $&;
6644                     $new_package=1;
6645                 } elsif (m/^-m/) {
6646                     push @ropts, $&;
6647                     push @changesopts, $_;
6648                     $_ = '';
6649                 } elsif (s/^-wn$//s) {
6650                     push @ropts, $&;
6651                     $cleanmode = 'none';
6652                 } elsif (s/^-wg$//s) {
6653                     push @ropts, $&;
6654                     $cleanmode = 'git';
6655                 } elsif (s/^-wgf$//s) {
6656                     push @ropts, $&;
6657                     $cleanmode = 'git-ff';
6658                 } elsif (s/^-wd$//s) {
6659                     push @ropts, $&;
6660                     $cleanmode = 'dpkg-source';
6661                 } elsif (s/^-wdd$//s) {
6662                     push @ropts, $&;
6663                     $cleanmode = 'dpkg-source-d';
6664                 } elsif (s/^-wc$//s) {
6665                     push @ropts, $&;
6666                     $cleanmode = 'check';
6667                 } elsif (s/^-c([^=]*)\=(.*)$//s) {
6668                     push @git, '-c', $&;
6669                     $gitcfgs{cmdline}{$1} = [ $2 ];
6670                 } elsif (s/^-c([^=]+)$//s) {
6671                     push @git, '-c', $&;
6672                     $gitcfgs{cmdline}{$1} = [ 'true' ];
6673                 } elsif (m/^-[a-zA-Z]/ && ($oi = $valopts_short{$&})) {
6674                     $val = $'; #';
6675                     $val = undef unless length $val;
6676                     $valopt->($oi->{Short});
6677                     $_ = '';
6678                 } else {
6679                     badusage "unknown short option \`$_'";
6680                 }
6681             }
6682         }
6683     }
6684 }
6685
6686 sub check_env_sanity () {
6687     my $blocked = new POSIX::SigSet;
6688     sigprocmask SIG_UNBLOCK, $blocked, $blocked or die $!;
6689
6690     eval {
6691         foreach my $name (qw(PIPE CHLD)) {
6692             my $signame = "SIG$name";
6693             my $signum = eval "POSIX::$signame" // die;
6694             ($SIG{$name} // 'DEFAULT') eq 'DEFAULT' or
6695                 die "$signame is set to something other than SIG_DFL\n";
6696             $blocked->ismember($signum) and
6697                 die "$signame is blocked\n";
6698         }
6699     };
6700     return unless $@;
6701     chomp $@;
6702     fail <<END;
6703 On entry to dgit, $@
6704 This is a bug produced by something in in your execution environment.
6705 Giving up.
6706 END
6707 }
6708
6709
6710 sub parseopts_late_defaults () {
6711     $isuite //= cfg("dgit-distro.$idistro.default-suite", 'RETURN-UNDEF')
6712         if defined $idistro;
6713     $isuite //= cfg('dgit.default.default-suite');
6714
6715     foreach my $k (keys %opts_opt_map) {
6716         my $om = $opts_opt_map{$k};
6717
6718         my $v = access_cfg("cmd-$k", 'RETURN-UNDEF');
6719         if (defined $v) {
6720             badcfg "cannot set command for $k"
6721                 unless length $om->[0];
6722             $om->[0] = $v;
6723         }
6724
6725         foreach my $c (access_cfg_cfgs("opts-$k")) {
6726             my @vl =
6727                 map { $_ ? @$_ : () }
6728                 map { $gitcfgs{$_}{$c} }
6729                 reverse @gitcfgsources;
6730             printdebug "CL $c ", (join " ", map { shellquote } @vl),
6731                 "\n" if $debuglevel >= 4;
6732             next unless @vl;
6733             badcfg "cannot configure options for $k"
6734                 if $opts_opt_cmdonly{$k};
6735             my $insertpos = $opts_cfg_insertpos{$k};
6736             @$om = ( @$om[0..$insertpos-1],
6737                      @vl,
6738                      @$om[$insertpos..$#$om] );
6739         }
6740     }
6741
6742     if (!defined $rmchanges) {
6743         local $access_forpush;
6744         $rmchanges = access_cfg_bool(0, 'rm-old-changes');
6745     }
6746
6747     if (!defined $quilt_mode) {
6748         local $access_forpush;
6749         $quilt_mode = cfg('dgit.force.quilt-mode', 'RETURN-UNDEF')
6750             // access_cfg('quilt-mode', 'RETURN-UNDEF')
6751             // 'linear';
6752         $quilt_mode =~ m/^($quilt_modes_re)$/
6753             or badcfg "unknown quilt-mode \`$quilt_mode'";
6754         $quilt_mode = $1;
6755     }
6756
6757     foreach my $moc (@modeopt_cfgs) {
6758         local $access_forpush;
6759         my $vr = $moc->{Var};
6760         next if defined $$vr;
6761         $$vr = access_cfg($moc->{Key}, 'RETURN-UNDEF') // $moc->{Default};
6762         my $v = $moc->{Vals}{$$vr};
6763         badcfg "unknown $moc->{Key} setting \`$$vr'" unless defined $v;
6764         $$vr = $v;
6765     }
6766
6767     $need_split_build_invocation ||= quiltmode_splitbrain();
6768
6769     if (!defined $cleanmode) {
6770         local $access_forpush;
6771         $cleanmode = access_cfg('clean-mode', 'RETURN-UNDEF');
6772         $cleanmode //= 'dpkg-source';
6773
6774         badcfg "unknown clean-mode \`$cleanmode'" unless
6775             $cleanmode =~ m/^($cleanmode_re)$(?!\n)/s;
6776     }
6777 }
6778
6779 if ($ENV{$fakeeditorenv}) {
6780     git_slurp_config();
6781     quilt_fixup_editor();
6782 }
6783
6784 parseopts();
6785 check_env_sanity();
6786
6787 print STDERR "DRY RUN ONLY\n" if $dryrun_level > 1;
6788 print STDERR "DAMP RUN - WILL MAKE LOCAL (UNSIGNED) CHANGES\n"
6789     if $dryrun_level == 1;
6790 if (!@ARGV) {
6791     print STDERR $helpmsg or die $!;
6792     exit 8;
6793 }
6794 $cmd = $subcommand = shift @ARGV;
6795 $cmd =~ y/-/_/;
6796
6797 my $pre_fn = ${*::}{"pre_$cmd"};
6798 $pre_fn->() if $pre_fn;
6799
6800 git_slurp_config();
6801
6802 my $fn = ${*::}{"cmd_$cmd"};
6803 $fn or badusage "unknown operation $cmd";
6804 $fn->();