dgit

   1 #!/usr/bin/perl -w
   2 # dgit
   3 # Integration between git and Debian-style archives
   4 #
   5 # Copyright (C)2013-2016 Ian Jackson
   6 #
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 use strict;
  21
  22 use Debian::Dgit;
  23 setup_sigwarn();
  24
  25 use IO::Handle;
  26 use Data::Dumper;
  27 use LWP::UserAgent;
  28 use Dpkg::Control::Hash;
  29 use File::Path;
  30 use File::Temp qw(tempdir);
  31 use File::Basename;
  32 use Dpkg::Version;
  33 use POSIX;
  34 use IPC::Open2;
  35 use Digest::SHA;
  36 use Digest::MD5;
  37 use List::MoreUtils qw(pairwise);
  38 use Text::Glob qw(match_glob);
  39 use Fcntl qw(:DEFAULT :flock);
  40 use Carp;
  41
  42 use Debian::Dgit;
  43
  44 our $our_version = 'UNRELEASED'; ###substituted###
  45 our $absurdity = undef; ###substituted###
  46
  47 our @rpushprotovsn_support = qw(4 3 2); # 4 is new tag format
  48 our $protovsn;
  49
  50 our $isuite;
  51 our $idistro;
  52 our $package;
  53 our @ropts;
  54
  55 our $sign = 1;
  56 our $dryrun_level = 0;
  57 our $changesfile;
  58 our $buildproductsdir = '..';
  59 our $new_package = 0;
  60 our $ignoredirty = 0;
  61 our $rmonerror = 1;
  62 our @deliberatelies;
  63 our %previously;
  64 our $existing_package = 'dpkg';
  65 our $cleanmode;
  66 our $changes_since_version;
  67 our $rmchanges;
  68 our $overwrite_version; # undef: not specified; '': check changelog
  69 our $quilt_mode;
  70 our $quilt_modes_re = 'linear|smash|auto|nofix|nocheck|gbp|dpm|unapplied';
  71 our $dodep14tag;
  72 our $split_brain_save;
  73 our $we_are_responder;
  74 our $we_are_initiator;
  75 our $initiator_tempdir;
  76 our $patches_applied_dirtily = 00;
  77 our $tagformat_want;
  78 our $tagformat;
  79 our $tagformatfn;
  80 our $chase_dsc_distro=1;
  81
  82 our %forceopts = map { $_=>0 }
  83     qw(unrepresentable unsupported-source-format
  84        dsc-changes-mismatch changes-origs-exactly
  85        import-gitapply-absurd
  86        import-gitapply-no-absurd
  87        import-dsc-with-dgit-field);
  88
  89 our %format_ok = map { $_=>1 } ("1.0","3.0 (native)","3.0 (quilt)");
  90
  91 our $suite_re = '[-+.0-9a-z]+';
  92 our $cleanmode_re = 'dpkg-source(?:-d)?|git|git-ff|check|none';
  93 our $orig_f_comp_re = 'orig(?:-[-0-9a-z]+)?';
  94 our $orig_f_sig_re = '\\.(?:asc|gpg|pgp)';
  95 our $orig_f_tail_re = "$orig_f_comp_re\\.tar(?:\\.\\w+)?(?:$orig_f_sig_re)?";
  96
  97 our $git_authline_re = '^([^<>]+) \<(\S+)\> (\d+ [-+]\d+)$';
  98 our $splitbraincache = 'dgit-intern/quilt-cache';
  99 our $rewritemap = 'dgit-rewrite/map';
 100
 101 our (@git) = qw(git);
 102 our (@dget) = qw(dget);
 103 our (@curl) = qw(curl);
 104 our (@dput) = qw(dput);
 105 our (@debsign) = qw(debsign);
 106 our (@gpg) = qw(gpg);
 107 our (@sbuild) = qw(sbuild);
 108 our (@ssh) = 'ssh';
 109 our (@dgit) = qw(dgit);
 110 our (@aptget) = qw(apt-get);
 111 our (@aptcache) = qw(apt-cache);
 112 our (@dpkgbuildpackage) = qw(dpkg-buildpackage -i\.git/ -I.git);
 113 our (@dpkgsource) = qw(dpkg-source -i\.git/ -I.git);
 114 our (@dpkggenchanges) = qw(dpkg-genchanges);
 115 our (@mergechanges) = qw(mergechanges -f);
 116 our (@gbp_build) = ('');
 117 our (@gbp_pq) = ('gbp pq');
 118 our (@changesopts) = ('');
 119
 120 our %opts_opt_map = ('dget' => \@dget, # accept for compatibility
 121                      'curl' => \@curl,
 122                      'dput' => \@dput,
 123                      'debsign' => \@debsign,
 124                      'gpg' => \@gpg,
 125                      'sbuild' => \@sbuild,
 126                      'ssh' => \@ssh,
 127                      'dgit' => \@dgit,
 128                      'git' => \@git,
 129                      'apt-get' => \@aptget,
 130                      'apt-cache' => \@aptcache,
 131                      'dpkg-source' => \@dpkgsource,
 132                      'dpkg-buildpackage' => \@dpkgbuildpackage,
 133                      'dpkg-genchanges' => \@dpkggenchanges,
 134                      'gbp-build' => \@gbp_build,
 135                      'gbp-pq' => \@gbp_pq,
 136                      'ch' => \@changesopts,
 137                      'mergechanges' => \@mergechanges);
 138
 139 our %opts_opt_cmdonly = ('gpg' => 1, 'git' => 1);
 140 our %opts_cfg_insertpos = map {
 141     $_,
 142     scalar @{ $opts_opt_map{$_} }
 143 } keys %opts_opt_map;
 144
 145 sub parseopts_late_defaults();
 146 sub setup_gitattrs(;$);
 147 sub check_gitattrs($$);
 148
 149 our $keyid;
 150
 151 autoflush STDOUT 1;
 152
 153 our $supplementary_message = '';
 154 our $need_split_build_invocation = 0;
 155 our $split_brain = 0;
 156
 157 END {
 158     local ($@, $?);
 159     return unless forkcheck_mainprocess();
 160     print STDERR "! $_\n" foreach $supplementary_message =~ m/^.+$/mg;
 161 }
 162
 163 our $remotename = 'dgit';
 164 our @ourdscfield = qw(Dgit Vcs-Dgit-Master);
 165 our $csuite;
 166 our $instead_distro;
 167
 168 if (!defined $absurdity) {
 169     $absurdity = $0;
 170     $absurdity =~ s{/[^/]+$}{/absurd} or die;
 171 }
 172
 173 sub debiantag ($$) {
 174     my ($v,$distro) = @_;
 175     return $tagformatfn->($v, $distro);
 176 }
 177
 178 sub debiantag_maintview ($$) {
 179     my ($v,$distro) = @_;
 180     return "$distro/".dep14_version_mangle $v;
 181 }
 182
 183 sub madformat ($) { $_[0] eq '3.0 (quilt)' }
 184
 185 sub lbranch () { return "$branchprefix/$csuite"; }
 186 my $lbranch_re = '^refs/heads/'.$branchprefix.'/([^/.]+)$';
 187 sub lref () { return "refs/heads/".lbranch(); }
 188 sub lrref () { return "refs/remotes/$remotename/".server_branch($csuite); }
 189 sub rrref () { return server_ref($csuite); }
 190
 191 sub stripepoch ($) {
 192     my ($vsn) = @_;
 193     $vsn =~ s/^\d+\://;
 194     return $vsn;
 195 }
 196
 197 sub srcfn ($$) {
 198     my ($vsn,$sfx) = @_;
 199     return "${package}_".(stripepoch $vsn).$sfx
 200 }
 201
 202 sub dscfn ($) {
 203     my ($vsn) = @_;
 204     return srcfn($vsn,".dsc");
 205 }
 206
 207 sub changespat ($;$) {
 208     my ($vsn, $arch) = @_;
 209     return "${package}_".(stripepoch $vsn)."_".($arch//'*').".changes";
 210 }
 211
 212 sub upstreamversion ($) {
 213     my ($vsn) = @_;
 214     $vsn =~ s/-[^-]+$//;
 215     return $vsn;
 216 }
 217
 218 our $us = 'dgit';
 219 initdebug('');
 220
 221 our @end;
 222 END {
 223     local ($?);
 224     return unless forkcheck_mainprocess();
 225     foreach my $f (@end) {
 226         eval { $f->(); };
 227         print STDERR "$us: cleanup: $@" if length $@;
 228     }
 229 };
 230
 231 sub badcfg { print STDERR "$us: invalid configuration: @_\n"; exit 12; }
 232
 233 sub forceable_fail ($$) {
 234     my ($forceoptsl, $msg) = @_;
 235     fail $msg unless grep { $forceopts{$_} } @$forceoptsl;
 236     print STDERR "warning: overriding problem due to --force:\n". $msg;
 237 }
 238
 239 sub forceing ($) {
 240     my ($forceoptsl) = @_;
 241     my @got = grep { $forceopts{$_} } @$forceoptsl;
 242     return 0 unless @got;
 243     print STDERR
 244  "warning: skipping checks or functionality due to --force-$got[0]\n";
 245 }
 246
 247 sub no_such_package () {
 248     print STDERR "$us: package $package does not exist in suite $isuite\n";
 249     exit 4;
 250 }
 251
 252 sub changedir ($) {
 253     my ($newdir) = @_;
 254     printdebug "CD $newdir\n";
 255     chdir $newdir or confess "chdir: $newdir: $!";
 256 }
 257
 258 sub deliberately ($) {
 259     my ($enquiry) = @_;
 260     return !!grep { $_ eq "--deliberately-$enquiry" } @deliberatelies;
 261 }
 262
 263 sub deliberately_not_fast_forward () {
 264     foreach (qw(not-fast-forward fresh-repo)) {
 265         return 1 if deliberately($_) || deliberately("TEST-dgit-only-$_");
 266     }
 267 }
 268
 269 sub quiltmode_splitbrain () {
 270     $quilt_mode =~ m/gbp|dpm|unapplied/;
 271 }
 272
 273 sub opts_opt_multi_cmd {
 274     my @cmd;
 275     push @cmd, split /\s+/, shift @_;
 276     push @cmd, @_;
 277     @cmd;
 278 }
 279
 280 sub gbp_pq {
 281     return opts_opt_multi_cmd @gbp_pq;
 282 }
 283
 284 #---------- remote protocol support, common ----------
 285
 286 # remote push initiator/responder protocol:
 287 #  $ dgit remote-push-build-host <n-rargs> <rargs>... <push-args>...
 288 #  where <rargs> is <push-host-dir> <supported-proto-vsn>,... ...
 289 #  < dgit-remote-push-ready <actual-proto-vsn>
 290 #
 291 # occasionally:
 292 #
 293 #  > progress NBYTES
 294 #  [NBYTES message]
 295 #
 296 #  > supplementary-message NBYTES          # $protovsn >= 3
 297 #  [NBYTES message]
 298 #
 299 # main sequence:
 300 #
 301 #  > file parsed-changelog
 302 #  [indicates that output of dpkg-parsechangelog follows]
 303 #  > data-block NBYTES
 304 #  > [NBYTES bytes of data (no newline)]
 305 #  [maybe some more blocks]
 306 #  > data-end
 307 #
 308 #  > file dsc
 309 #  [etc]
 310 #
 311 #  > file changes
 312 #  [etc]
 313 #
 314 #  > param head DGIT-VIEW-HEAD
 315 #  > param csuite SUITE
 316 #  > param tagformat old|new
 317 #  > param maint-view MAINT-VIEW-HEAD
 318 #
 319 #  > previously REFNAME=OBJNAME       # if --deliberately-not-fast-forward
 320 #                                     # goes into tag, for replay prevention
 321 #
 322 #  > want signed-tag
 323 #  [indicates that signed tag is wanted]
 324 #  < data-block NBYTES
 325 #  < [NBYTES bytes of data (no newline)]
 326 #  [maybe some more blocks]
 327 #  < data-end
 328 #  < files-end
 329 #
 330 #  > want signed-dsc-changes
 331 #  < data-block NBYTES    [transfer of signed dsc]
 332 #  [etc]
 333 #  < data-block NBYTES    [transfer of signed changes]
 334 #  [etc]
 335 #  < files-end
 336 #
 337 #  > complete
 338
 339 our $i_child_pid;
 340
 341 sub i_child_report () {
 342     # Sees if our child has died, and reap it if so.  Returns a string
 343     # describing how it died if it failed, or undef otherwise.
 344     return undef unless $i_child_pid;
 345     my $got = waitpid $i_child_pid, WNOHANG;
 346     return undef if $got <= 0;
 347     die unless $got == $i_child_pid;
 348     $i_child_pid = undef;
 349     return undef unless $?;
 350     return "build host child ".waitstatusmsg();
 351 }
 352
 353 sub badproto ($$) {
 354     my ($fh, $m) = @_;
 355     fail "connection lost: $!" if $fh->error;
 356     fail "protocol violation; $m not expected";
 357 }
 358
 359 sub badproto_badread ($$) {
 360     my ($fh, $wh) = @_;
 361     fail "connection lost: $!" if $!;
 362     my $report = i_child_report();
 363     fail $report if defined $report;
 364     badproto $fh, "eof (reading $wh)";
 365 }
 366
 367 sub protocol_expect (&$) {
 368     my ($match, $fh) = @_;
 369     local $_;
 370     $_ = <$fh>;
 371     defined && chomp or badproto_badread $fh, "protocol message";
 372     if (wantarray) {
 373         my @r = &$match;
 374         return @r if @r;
 375     } else {
 376         my $r = &$match;
 377         return $r if $r;
 378     }
 379     badproto $fh, "\`$_'";
 380 }
 381
 382 sub protocol_send_file ($$) {
 383     my ($fh, $ourfn) = @_;
 384     open PF, "<", $ourfn or die "$ourfn: $!";
 385     for (;;) {
 386         my $d;
 387         my $got = read PF, $d, 65536;
 388         die "$ourfn: $!" unless defined $got;
 389         last if !$got;
 390         print $fh "data-block ".length($d)."\n" or die $!;
 391         print $fh $d or die $!;
 392     }
 393     PF->error and die "$ourfn $!";
 394     print $fh "data-end\n" or die $!;
 395     close PF;
 396 }
 397
 398 sub protocol_read_bytes ($$) {
 399     my ($fh, $nbytes) = @_;
 400     $nbytes =~ m/^[1-9]\d{0,5}$|^0$/ or badproto \*RO, "bad byte count";
 401     my $d;
 402     my $got = read $fh, $d, $nbytes;
 403     $got==$nbytes or badproto_badread $fh, "data block";
 404     return $d;
 405 }
 406
 407 sub protocol_receive_file ($$) {
 408     my ($fh, $ourfn) = @_;
 409     printdebug "() $ourfn\n";
 410     open PF, ">", $ourfn or die "$ourfn: $!";
 411     for (;;) {
 412         my ($y,$l) = protocol_expect {
 413             m/^data-block (.*)$/ ? (1,$1) :
 414             m/^data-end$/ ? (0,) :
 415             ();
 416         } $fh;
 417         last unless $y;
 418         my $d = protocol_read_bytes $fh, $l;
 419         print PF $d or die $!;
 420     }
 421     close PF or die $!;
 422 }
 423
 424 #---------- remote protocol support, responder ----------
 425
 426 sub responder_send_command ($) {
 427     my ($command) = @_;
 428     return unless $we_are_responder;
 429     # called even without $we_are_responder
 430     printdebug ">> $command\n";
 431     print PO $command, "\n" or die $!;
 432 }
 433
 434 sub responder_send_file ($$) {
 435     my ($keyword, $ourfn) = @_;
 436     return unless $we_are_responder;
 437     printdebug "]] $keyword $ourfn\n";
 438     responder_send_command "file $keyword";
 439     protocol_send_file \*PO, $ourfn;
 440 }
 441
 442 sub responder_receive_files ($@) {
 443     my ($keyword, @ourfns) = @_;
 444     die unless $we_are_responder;
 445     printdebug "[[ $keyword @ourfns\n";
 446     responder_send_command "want $keyword";
 447     foreach my $fn (@ourfns) {
 448         protocol_receive_file \*PI, $fn;
 449     }
 450     printdebug "[[\$\n";
 451     protocol_expect { m/^files-end$/ } \*PI;
 452 }
 453
 454 #---------- remote protocol support, initiator ----------
 455
 456 sub initiator_expect (&) {
 457     my ($match) = @_;
 458     protocol_expect { &$match } \*RO;
 459 }
 460
 461 #---------- end remote code ----------
 462
 463 sub progress {
 464     if ($we_are_responder) {
 465         my $m = join '', @_;
 466         responder_send_command "progress ".length($m) or die $!;
 467         print PO $m or die $!;
 468     } else {
 469         print @_, "\n";
 470     }
 471 }
 472
 473 our $ua;
 474
 475 sub url_get {
 476     if (!$ua) {
 477         $ua = LWP::UserAgent->new();
 478         $ua->env_proxy;
 479     }
 480     my $what = $_[$#_];
 481     progress "downloading $what...";
 482     my $r = $ua->get(@_) or die $!;
 483     return undef if $r->code == 404;
 484     $r->is_success or fail "failed to fetch $what: ".$r->status_line;
 485     return $r->decoded_content(charset => 'none');
 486 }
 487
 488 our ($dscdata,$dscurl,$dsc,$dsc_checked,$skew_warning_vsn);
 489
 490 sub runcmd {
 491     debugcmd "+",@_;
 492     $!=0; $?=-1;
 493     failedcmd @_ if system @_;
 494 }
 495
 496 sub act_local () { return $dryrun_level <= 1; }
 497 sub act_scary () { return !$dryrun_level; }
 498
 499 sub printdone {
 500     if (!$dryrun_level) {
 501         progress "$us ok: @_";
 502     } else {
 503         progress "would be ok: @_ (but dry run only)";
 504     }
 505 }
 506
 507 sub dryrun_report {
 508     printcmd(\*STDERR,$debugprefix."#",@_);
 509 }
 510
 511 sub runcmd_ordryrun {
 512     if (act_scary()) {
 513         runcmd @_;
 514     } else {
 515         dryrun_report @_;
 516     }
 517 }
 518
 519 sub runcmd_ordryrun_local {
 520     if (act_local()) {
 521         runcmd @_;
 522     } else {
 523         dryrun_report @_;
 524     }
 525 }
 526
 527 sub shell_cmd {
 528     my ($first_shell, @cmd) = @_;
 529     return qw(sh -ec), $first_shell.'; exec "$@"', 'x', @cmd;
 530 }
 531
 532 our $helpmsg = <<END;
 533 main usages:
 534   dgit [dgit-opts] clone [dgit-opts] package [suite] [./dir|/dir]
 535   dgit [dgit-opts] fetch|pull [dgit-opts] [suite]
 536   dgit [dgit-opts] build [dpkg-buildpackage-opts]
 537   dgit [dgit-opts] sbuild [sbuild-opts]
 538   dgit [dgit-opts] push [dgit-opts] [suite]
 539   dgit [dgit-opts] rpush build-host:build-dir ...
 540 important dgit options:
 541   -k<keyid>           sign tag and package with <keyid> instead of default
 542   --dry-run -n        do not change anything, but go through the motions
 543   --damp-run -L       like --dry-run but make local changes, without signing
 544   --new -N            allow introducing a new package
 545   --debug -D          increase debug level
 546   -c<name>=<value>    set git config option (used directly by dgit too)
 547 END
 548
 549 our $later_warning_msg = <<END;
 550 Perhaps the upload is stuck in incoming.  Using the version from git.
 551 END
 552
 553 sub badusage {
 554     print STDERR "$us: @_\n", $helpmsg or die $!;
 555     exit 8;
 556 }
 557
 558 sub nextarg {
 559     @ARGV or badusage "too few arguments";
 560     return scalar shift @ARGV;
 561 }
 562
 563 sub cmd_help () {
 564     print $helpmsg or die $!;
 565     exit 0;
 566 }
 567
 568 our $td = $ENV{DGIT_TEST_DUMMY_DIR} || "DGIT_TEST_DUMMY_DIR-unset";
 569
 570 our %defcfg = ('dgit.default.distro' => 'debian',
 571                'dgit.default.default-suite' => 'unstable',
 572                'dgit.default.old-dsc-distro' => 'debian',
 573                'dgit-suite.*-security.distro' => 'debian-security',
 574                'dgit.default.username' => '',
 575                'dgit.default.archive-query-default-component' => 'main',
 576                'dgit.default.ssh' => 'ssh',
 577                'dgit.default.archive-query' => 'madison:',
 578                'dgit.default.sshpsql-dbname' => 'service=projectb',
 579                'dgit.default.aptget-components' => 'main',
 580                'dgit.default.dgit-tag-format' => 'new,old,maint',
 581                'dgit.dsc-url-proto-ok.http'    => 'true',
 582                'dgit.dsc-url-proto-ok.https'   => 'true',
 583                'dgit.dsc-url-proto-ok.git'     => 'true',
 584                'dgit.default.dsc-url-proto-ok' => 'false',
 585                # old means "repo server accepts pushes with old dgit tags"
 586                # new means "repo server accepts pushes with new dgit tags"
 587                # maint means "repo server accepts split brain pushes"
 588                # hist means "repo server may have old pushes without new tag"
 589                #   ("hist" is implied by "old")
 590                'dgit-distro.debian.archive-query' => 'ftpmasterapi:',
 591                'dgit-distro.debian.git-check' => 'url',
 592                'dgit-distro.debian.git-check-suffix' => '/info/refs',
 593                'dgit-distro.debian.new-private-pushers' => 't',
 594                'dgit-distro.debian/push.git-url' => '',
 595                'dgit-distro.debian/push.git-host' => 'push.dgit.debian.org',
 596                'dgit-distro.debian/push.git-user-force' => 'dgit',
 597                'dgit-distro.debian/push.git-proto' => 'git+ssh://',
 598                'dgit-distro.debian/push.git-path' => '/dgit/debian/repos',
 599                'dgit-distro.debian/push.git-create' => 'true',
 600                'dgit-distro.debian/push.git-check' => 'ssh-cmd',
 601  'dgit-distro.debian.archive-query-url', 'https://api.ftp-master.debian.org/',
 602 # 'dgit-distro.debian.archive-query-tls-key',
 603 #    '/etc/ssl/certs/%HOST%.pem:/etc/dgit/%HOST%.pem',
 604 # ^ this does not work because curl is broken nowadays
 605 # Fixing #790093 properly will involve providing providing the key
 606 # in some pacagke and maybe updating these paths.
 607 #
 608 # 'dgit-distro.debian.archive-query-tls-curl-args',
 609 #   '--ca-path=/etc/ssl/ca-debian',
 610 # ^ this is a workaround but works (only) on DSA-administered machines
 611                'dgit-distro.debian.git-url' => 'https://git.dgit.debian.org',
 612                'dgit-distro.debian.git-url-suffix' => '',
 613                'dgit-distro.debian.upload-host' => 'ftp-master', # for dput
 614                'dgit-distro.debian.mirror' => 'http://ftp.debian.org/debian/',
 615  'dgit-distro.debian-security.archive-query' => 'aptget:',
 616  'dgit-distro.debian-security.mirror' => 'http://security.debian.org/debian-security/',
 617  'dgit-distro.debian-security.aptget-suite-map' => 's#-security$#/updates#',
 618  'dgit-distro.debian-security.aptget-suite-rmap' => 's#$#-security#',
 619  'dgit-distro.debian-security.nominal-distro' => 'debian',
 620  'dgit-distro.debian.backports-quirk' => '(squeeze)-backports*',
 621  'dgit-distro.debian-backports.mirror' => 'http://backports.debian.org/debian-backports/',
 622                'dgit-distro.ubuntu.git-check' => 'false',
 623  'dgit-distro.ubuntu.mirror' => 'http://archive.ubuntu.com/ubuntu',
 624                'dgit-distro.test-dummy.ssh' => "$td/ssh",
 625                'dgit-distro.test-dummy.username' => "alice",
 626                'dgit-distro.test-dummy.git-check' => "ssh-cmd",
 627                'dgit-distro.test-dummy.git-create' => "ssh-cmd",
 628                'dgit-distro.test-dummy.git-url' => "$td/git",
 629                'dgit-distro.test-dummy.git-host' => "git",
 630                'dgit-distro.test-dummy.git-path' => "$td/git",
 631                'dgit-distro.test-dummy.archive-query' => "dummycatapi:",
 632                'dgit-distro.test-dummy.archive-query-url' => "file://$td/aq/",
 633                'dgit-distro.test-dummy.mirror' => "file://$td/mirror/",
 634                'dgit-distro.test-dummy.upload-host' => 'test-dummy',
 635                );
 636
 637 our %gitcfgs;
 638 our @gitcfgsources = qw(cmdline local global system);
 639
 640 sub git_slurp_config () {
 641     local ($debuglevel) = $debuglevel-2;
 642     local $/="\0";
 643
 644     # This algoritm is a bit subtle, but this is needed so that for
 645     # options which we want to be single-valued, we allow the
 646     # different config sources to override properly.  See #835858.
 647     foreach my $src (@gitcfgsources) {
 648         next if $src eq 'cmdline';
 649         # we do this ourselves since git doesn't handle it
 650
 651         my @cmd = (@git, qw(config -z --get-regexp), "--$src", qw(.*));
 652         debugcmd "|",@cmd;
 653
 654         open GITS, "-|", @cmd or die $!;
 655         while (<GITS>) {
 656             chomp or die;
 657             printdebug "=> ", (messagequote $_), "\n";
 658             m/\n/ or die "$_ ?";
 659             push @{ $gitcfgs{$src}{$`} }, $'; #';
 660         }
 661         $!=0; $?=0;
 662         close GITS
 663             or ($!==0 && $?==256)
 664             or failedcmd @cmd;
 665     }
 666 }
 667
 668 sub git_get_config ($) {
 669     my ($c) = @_;
 670     foreach my $src (@gitcfgsources) {
 671         my $l = $gitcfgs{$src}{$c};
 672         confess "internal error ($l $c)" if $l && !ref $l;
 673         printdebug"C $c ".(defined $l ?
 674                            join " ", map { messagequote "'$_'" } @$l :
 675                            "undef")."\n"
 676             if $debuglevel >= 4;
 677         $l or next;
 678         @$l==1 or badcfg "multiple values for $c".
 679             " (in $src git config)" if @$l > 1;
 680         return $l->[0];
 681     }
 682     return undef;
 683 }
 684
 685 sub cfg {
 686     foreach my $c (@_) {
 687         return undef if $c =~ /RETURN-UNDEF/;
 688         printdebug "C? $c\n" if $debuglevel >= 5;
 689         my $v = git_get_config($c);
 690         return $v if defined $v;
 691         my $dv = $defcfg{$c};
 692         if (defined $dv) {
 693             printdebug "CD $c $dv\n" if $debuglevel >= 4;
 694             return $dv;
 695         }
 696     }
 697     badcfg "need value for one of: @_\n".
 698         "$us: distro or suite appears not to be (properly) supported";
 699 }
 700
 701 sub access_basedistro__noalias () {
 702     if (defined $idistro) {
 703         return $idistro;
 704     } else {
 705         my $def = cfg("dgit-suite.$isuite.distro", 'RETURN-UNDEF');
 706         return $def if defined $def;
 707         foreach my $src (@gitcfgsources, 'internal') {
 708             my $kl = $src eq 'internal' ? \%defcfg : $gitcfgs{$src};
 709             next unless $kl;
 710             foreach my $k (keys %$kl) {
 711                 next unless $k =~ m#^dgit-suite\.(.*)\.distro$#;
 712                 my $dpat = $1;
 713                 next unless match_glob $dpat, $isuite;
 714                 return $kl->{$k};
 715             }
 716         }
 717         return cfg("dgit.default.distro");
 718     }
 719 }
 720
 721 sub access_basedistro () {
 722     my $noalias = access_basedistro__noalias();
 723     my $canon = cfg("dgit-distro.$noalias.alias-canon",'RETURN-UNDEF');
 724     return $canon // $noalias;
 725 }
 726
 727 sub access_nomdistro () {
 728     my $base = access_basedistro();
 729     my $r = cfg("dgit-distro.$base.nominal-distro",'RETURN-UNDEF') // $base;
 730     $r =~ m/^$distro_re$/ or badcfg
 731  "bad syntax for (nominal) distro \`$r' (does not match /^$distro_re$/)";
 732     return $r;
 733 }
 734
 735 sub access_quirk () {
 736     # returns (quirk name, distro to use instead or undef, quirk-specific info)
 737     my $basedistro = access_basedistro();
 738     my $backports_quirk = cfg("dgit-distro.$basedistro.backports-quirk",
 739                               'RETURN-UNDEF');
 740     if (defined $backports_quirk) {
 741         my $re = $backports_quirk;
 742         $re =~ s/[^-0-9a-z_\%*()]/\\$&/ig;
 743         $re =~ s/\*/.*/g;
 744         $re =~ s/\%/([-0-9a-z_]+)/
 745             or $re =~ m/[()]/ or badcfg "backports-quirk needs \% or ( )";
 746         if ($isuite =~ m/^$re$/) {
 747             return ('backports',"$basedistro-backports",$1);
 748         }
 749     }
 750     return ('none',undef);
 751 }
 752
 753 our $access_forpush;
 754
 755 sub parse_cfg_bool ($$$) {
 756     my ($what,$def,$v) = @_;
 757     $v //= $def;
 758     return
 759         $v =~ m/^[ty1]/ ? 1 :
 760         $v =~ m/^[fn0]/ ? 0 :
 761         badcfg "$what needs t (true, y, 1) or f (false, n, 0) not \`$v'";
 762 }
 763
 764 sub access_forpush_config () {
 765     my $d = access_basedistro();
 766
 767     return 1 if
 768         $new_package &&
 769         parse_cfg_bool('new-private-pushers', 0,
 770                        cfg("dgit-distro.$d.new-private-pushers",
 771                            'RETURN-UNDEF'));
 772
 773     my $v = cfg("dgit-distro.$d.readonly", 'RETURN-UNDEF');
 774     $v //= 'a';
 775     return
 776         $v =~ m/^[ty1]/ ? 0 : # force readonly,    forpush = 0
 777         $v =~ m/^[fn0]/ ? 1 : # force nonreadonly, forpush = 1
 778         $v =~ m/^[a]/  ? '' : # auto,              forpush = ''
 779         badcfg "readonly needs t (true, y, 1) or f (false, n, 0) or a (auto)";
 780 }
 781
 782 sub access_forpush () {
 783     $access_forpush //= access_forpush_config();
 784     return $access_forpush;
 785 }
 786
 787 sub pushing () {
 788     die "$access_forpush ?" if ($access_forpush // 1) ne 1;
 789     badcfg "pushing but distro is configured readonly"
 790         if access_forpush_config() eq '0';
 791     $access_forpush = 1;
 792     $supplementary_message = <<'END' unless $we_are_responder;
 793 Push failed, before we got started.
 794 You can retry the push, after fixing the problem, if you like.
 795 END
 796     parseopts_late_defaults();
 797 }
 798
 799 sub notpushing () {
 800     parseopts_late_defaults();
 801 }
 802
 803 sub supplementary_message ($) {
 804     my ($msg) = @_;
 805     if (!$we_are_responder) {
 806         $supplementary_message = $msg;
 807         return;
 808     } elsif ($protovsn >= 3) {
 809         responder_send_command "supplementary-message ".length($msg)
 810             or die $!;
 811         print PO $msg or die $!;
 812     }
 813 }
 814
 815 sub access_distros () {
 816     # Returns list of distros to try, in order
 817     #
 818     # We want to try:
 819     #    0. `instead of' distro name(s) we have been pointed to
 820     #    1. the access_quirk distro, if any
 821     #    2a. the user's specified distro, or failing that  } basedistro
 822     #    2b. the distro calculated from the suite          }
 823     my @l = access_basedistro();
 824
 825     my (undef,$quirkdistro) = access_quirk();
 826     unshift @l, $quirkdistro;
 827     unshift @l, $instead_distro;
 828     @l = grep { defined } @l;
 829
 830     push @l, access_nomdistro();
 831
 832     if (access_forpush()) {
 833         @l = map { ("$_/push", $_) } @l;
 834     }
 835     @l;
 836 }
 837
 838 sub access_cfg_cfgs (@) {
 839     my (@keys) = @_;
 840     my @cfgs;
 841     # The nesting of these loops determines the search order.  We put
 842     # the key loop on the outside so that we search all the distros
 843     # for each key, before going on to the next key.  That means that
 844     # if access_cfg is called with a more specific, and then a less
 845     # specific, key, an earlier distro can override the less specific
 846     # without necessarily overriding any more specific keys.  (If the
 847     # distro wants to override the more specific keys it can simply do
 848     # so; whereas if we did the loop the other way around, it would be
 849     # impossible to for an earlier distro to override a less specific
 850     # key but not the more specific ones without restating the unknown
 851     # values of the more specific keys.
 852     my @realkeys;
 853     my @rundef;
 854     # We have to deal with RETURN-UNDEF specially, so that we don't
 855     # terminate the search prematurely.
 856     foreach (@keys) {
 857         if (m/RETURN-UNDEF/) { push @rundef, $_; last; }
 858         push @realkeys, $_
 859     }
 860     foreach my $d (access_distros()) {
 861         push @cfgs, map { "dgit-distro.$d.$_" } @realkeys;
 862     }
 863     push @cfgs, map { "dgit.default.$_" } @realkeys;
 864     push @cfgs, @rundef;
 865     return @cfgs;
 866 }
 867
 868 sub access_cfg (@) {
 869     my (@keys) = @_;
 870     my (@cfgs) = access_cfg_cfgs(@keys);
 871     my $value = cfg(@cfgs);
 872     return $value;
 873 }
 874
 875 sub access_cfg_bool ($$) {
 876     my ($def, @keys) = @_;
 877     parse_cfg_bool($keys[0], $def, access_cfg(@keys, 'RETURN-UNDEF'));
 878 }
 879
 880 sub string_to_ssh ($) {
 881     my ($spec) = @_;
 882     if ($spec =~ m/\s/) {
 883         return qw(sh -ec), 'exec '.$spec.' "$@"', 'x';
 884     } else {
 885         return ($spec);
 886     }
 887 }
 888
 889 sub access_cfg_ssh () {
 890     my $gitssh = access_cfg('ssh', 'RETURN-UNDEF');
 891     if (!defined $gitssh) {
 892         return @ssh;
 893     } else {
 894         return string_to_ssh $gitssh;
 895     }
 896 }
 897
 898 sub access_runeinfo ($) {
 899     my ($info) = @_;
 900     return ": dgit ".access_basedistro()." $info ;";
 901 }
 902
 903 sub access_someuserhost ($) {
 904     my ($some) = @_;
 905     my $user = access_cfg("$some-user-force", 'RETURN-UNDEF');
 906     defined($user) && length($user) or
 907         $user = access_cfg("$some-user",'username');
 908     my $host = access_cfg("$some-host");
 909     return length($user) ? "$user\@$host" : $host;
 910 }
 911
 912 sub access_gituserhost () {
 913     return access_someuserhost('git');
 914 }
 915
 916 sub access_giturl (;$) {
 917     my ($optional) = @_;
 918     my $url = access_cfg('git-url','RETURN-UNDEF');
 919     my $suffix;
 920     if (!length $url) {
 921         my $proto = access_cfg('git-proto', 'RETURN-UNDEF');
 922         return undef unless defined $proto;
 923         $url =
 924             $proto.
 925             access_gituserhost().
 926             access_cfg('git-path');
 927     } else {
 928         $suffix = access_cfg('git-url-suffix','RETURN-UNDEF');
 929     }
 930     $suffix //= '.git';
 931     return "$url/$package$suffix";
 932 }
 933
 934 sub parsecontrolfh ($$;$) {
 935     my ($fh, $desc, $allowsigned) = @_;
 936     our $dpkgcontrolhash_noissigned;
 937     my $c;
 938     for (;;) {
 939         my %opts = ('name' => $desc);
 940         $opts{allow_pgp}= $allowsigned || !$dpkgcontrolhash_noissigned;
 941         $c = Dpkg::Control::Hash->new(%opts);
 942         $c->parse($fh,$desc) or die "parsing of $desc failed";
 943         last if $allowsigned;
 944         last if $dpkgcontrolhash_noissigned;
 945         my $issigned= $c->get_option('is_pgp_signed');
 946         if (!defined $issigned) {
 947             $dpkgcontrolhash_noissigned= 1;
 948             seek $fh, 0,0 or die "seek $desc: $!";
 949         } elsif ($issigned) {
 950             fail "control file $desc is (already) PGP-signed. ".
 951                 " Note that dgit push needs to modify the .dsc and then".
 952                 " do the signature itself";
 953         } else {
 954             last;
 955         }
 956     }
 957     return $c;
 958 }
 959
 960 sub parsecontrol {
 961     my ($file, $desc, $allowsigned) = @_;
 962     my $fh = new IO::Handle;
 963     open $fh, '<', $file or die "$file: $!";
 964     my $c = parsecontrolfh($fh,$desc,$allowsigned);
 965     $fh->error and die $!;
 966     close $fh;
 967     return $c;
 968 }
 969
 970 sub getfield ($$) {
 971     my ($dctrl,$field) = @_;
 972     my $v = $dctrl->{$field};
 973     return $v if defined $v;
 974     fail "missing field $field in ".$dctrl->get_option('name');
 975 }
 976
 977 sub parsechangelog {
 978     my $c = Dpkg::Control::Hash->new(name => 'parsed changelog');
 979     my $p = new IO::Handle;
 980     my @cmd = (qw(dpkg-parsechangelog), @_);
 981     open $p, '-|', @cmd or die $!;
 982     $c->parse($p);
 983     $?=0; $!=0; close $p or failedcmd @cmd;
 984     return $c;
 985 }
 986
 987 sub commit_getclogp ($) {
 988     # Returns the parsed changelog hashref for a particular commit
 989     my ($objid) = @_;
 990     our %commit_getclogp_memo;
 991     my $memo = $commit_getclogp_memo{$objid};
 992     return $memo if $memo;
 993     mkpath '.git/dgit';
 994     my $mclog = ".git/dgit/clog-$objid";
 995     runcmd shell_cmd "exec >$mclog", @git, qw(cat-file blob),
 996         "$objid:debian/changelog";
 997     $commit_getclogp_memo{$objid} = parsechangelog("-l$mclog");
 998 }
 999
1000 sub must_getcwd () {
1001     my $d = getcwd();
1002     defined $d or fail "getcwd failed: $!";
1003     return $d;
1004 }
1005
1006 sub parse_dscdata () {
1007     my $dscfh = new IO::File \$dscdata, '<' or die $!;
1008     printdebug Dumper($dscdata) if $debuglevel>1;
1009     $dsc = parsecontrolfh($dscfh,$dscurl,1);
1010     printdebug Dumper($dsc) if $debuglevel>1;
1011 }
1012
1013 our %rmad;
1014
1015 sub archive_query ($;@) {
1016     my ($method) = shift @_;
1017     fail "this operation does not support multiple comma-separated suites"
1018         if $isuite =~ m/,/;
1019     my $query = access_cfg('archive-query','RETURN-UNDEF');
1020     $query =~ s/^(\w+):// or badcfg "invalid archive-query method \`$query'";
1021     my $proto = $1;
1022     my $data = $'; #';
1023     { no strict qw(refs); &{"${method}_${proto}"}($proto,$data,@_); }
1024 }
1025
1026 sub archive_query_prepend_mirror {
1027     my $m = access_cfg('mirror');
1028     return map { [ $_->[0], $m.$_->[1], @$_[2..$#$_] ] } @_;
1029 }
1030
1031 sub pool_dsc_subpath ($$) {
1032     my ($vsn,$component) = @_; # $package is implict arg
1033     my $prefix = substr($package, 0, $package =~ m/^l/ ? 4 : 1);
1034     return "/pool/$component/$prefix/$package/".dscfn($vsn);
1035 }
1036
1037 sub cfg_apply_map ($$$) {
1038     my ($varref, $what, $mapspec) = @_;
1039     return unless $mapspec;
1040
1041     printdebug "config $what EVAL{ $mapspec; }\n";
1042     $_ = $$varref;
1043     eval "package Dgit::Config; $mapspec;";
1044     die $@ if $@;
1045     $$varref = $_;
1046 }
1047
1048 #---------- `ftpmasterapi' archive query method (nascent) ----------
1049
1050 sub archive_api_query_cmd ($) {
1051     my ($subpath) = @_;
1052     my @cmd = (@curl, qw(-sS));
1053     my $url = access_cfg('archive-query-url');
1054     if ($url =~ m#^https://([-.0-9a-z]+)/#) {
1055         my $host = $1;
1056         my $keys = access_cfg('archive-query-tls-key','RETURN-UNDEF') //'';
1057         foreach my $key (split /\:/, $keys) {
1058             $key =~ s/\%HOST\%/$host/g;
1059             if (!stat $key) {
1060                 fail "for $url: stat $key: $!" unless $!==ENOENT;
1061                 next;
1062             }
1063             fail "config requested specific TLS key but do not know".
1064                 " how to get curl to use exactly that EE key ($key)";
1065 #           push @cmd, "--cacert", $key, "--capath", "/dev/enoent";
1066 #           # Sadly the above line does not work because of changes
1067 #           # to gnutls.   The real fix for #790093 may involve
1068 #           # new curl options.
1069             last;
1070         }
1071         # Fixing #790093 properly will involve providing a value
1072         # for this on clients.
1073         my $kargs = access_cfg('archive-query-tls-curl-ca-args','RETURN-UNDEF');
1074         push @cmd, split / /, $kargs if defined $kargs;
1075     }
1076     push @cmd, $url.$subpath;
1077     return @cmd;
1078 }
1079
1080 sub api_query ($$;$) {
1081     use JSON;
1082     my ($data, $subpath, $ok404) = @_;
1083     badcfg "ftpmasterapi archive query method takes no data part"
1084         if length $data;
1085     my @cmd = archive_api_query_cmd($subpath);
1086     my $url = $cmd[$#cmd];
1087     push @cmd, qw(-w %{http_code});
1088     my $json = cmdoutput @cmd;
1089     unless ($json =~ s/\d+\d+\d$//) {
1090         failedcmd_report_cmd undef, @cmd;
1091         fail "curl failed to print 3-digit HTTP code";
1092     }
1093     my $code = $&;
1094     return undef if $code eq '404' && $ok404;
1095     fail "fetch of $url gave HTTP code $code"
1096         unless $url =~ m#^file://# or $code =~ m/^2/;
1097     return decode_json($json);
1098 }
1099
1100 sub canonicalise_suite_ftpmasterapi {
1101     my ($proto,$data) = @_;
1102     my $suites = api_query($data, 'suites');
1103     my @matched;
1104     foreach my $entry (@$suites) {
1105         next unless grep {
1106             my $v = $entry->{$_};
1107             defined $v && $v eq $isuite;
1108         } qw(codename name);
1109         push @matched, $entry;
1110     }
1111     fail "unknown suite $isuite" unless @matched;
1112     my $cn;
1113     eval {
1114         @matched==1 or die "multiple matches for suite $isuite\n";
1115         $cn = "$matched[0]{codename}";
1116         defined $cn or die "suite $isuite info has no codename\n";
1117         $cn =~ m/^$suite_re$/ or die "suite $isuite maps to bad codename\n";
1118     };
1119     die "bad ftpmaster api response: $@\n".Dumper(\@matched)
1120         if length $@;
1121     return $cn;
1122 }
1123
1124 sub archive_query_ftpmasterapi {
1125     my ($proto,$data) = @_;
1126     my $info = api_query($data, "dsc_in_suite/$isuite/$package");
1127     my @rows;
1128     my $digester = Digest::SHA->new(256);
1129     foreach my $entry (@$info) {
1130         eval {
1131             my $vsn = "$entry->{version}";
1132             my ($ok,$msg) = version_check $vsn;
1133             die "bad version: $msg\n" unless $ok;
1134             my $component = "$entry->{component}";
1135             $component =~ m/^$component_re$/ or die "bad component";
1136             my $filename = "$entry->{filename}";
1137             $filename && $filename !~ m#[^-+:._~0-9a-zA-Z/]|^[/.]|/[/.]#
1138                 or die "bad filename";
1139             my $sha256sum = "$entry->{sha256sum}";
1140             $sha256sum =~ m/^[0-9a-f]+$/ or die "bad sha256sum";
1141             push @rows, [ $vsn, "/pool/$component/$filename",
1142                           $digester, $sha256sum ];
1143         };
1144         die "bad ftpmaster api response: $@\n".Dumper($entry)
1145             if length $@;
1146     }
1147     @rows = sort { -version_compare($a->[0],$b->[0]) } @rows;
1148     return archive_query_prepend_mirror @rows;
1149 }
1150
1151 sub file_in_archive_ftpmasterapi {
1152     my ($proto,$data,$filename) = @_;
1153     my $pat = $filename;
1154     $pat =~ s/_/\\_/g;
1155     $pat = "%/$pat";
1156     $pat =~ s#[^-+_.0-9a-z/]# sprintf '%%%02x', ord $& #ge;
1157     my $info = api_query($data, "file_in_archive/$pat", 1);
1158 }
1159
1160 #---------- `aptget' archive query method ----------
1161
1162 our $aptget_base;
1163 our $aptget_releasefile;
1164 our $aptget_configpath;
1165
1166 sub aptget_aptget   () { return @aptget,   qw(-c), $aptget_configpath; }
1167 sub aptget_aptcache () { return @aptcache, qw(-c), $aptget_configpath; }
1168
1169 sub aptget_cache_clean {
1170     runcmd_ordryrun_local qw(sh -ec),
1171         'cd "$1"; find -atime +30 -type f -print0 | xargs -0r rm --',
1172         'x', $aptget_base;
1173 }
1174
1175 sub aptget_lock_acquire () {
1176     my $lockfile = "$aptget_base/lock";
1177     open APTGET_LOCK, '>', $lockfile or die "open $lockfile: $!";
1178     flock APTGET_LOCK, LOCK_EX or die "lock $lockfile: $!";
1179 }
1180
1181 sub aptget_prep ($) {
1182     my ($data) = @_;
1183     return if defined $aptget_base;
1184
1185     badcfg "aptget archive query method takes no data part"
1186         if length $data;
1187
1188     my $cache = $ENV{XDG_CACHE_DIR} // "$ENV{HOME}/.cache";
1189
1190     ensuredir $cache;
1191     ensuredir "$cache/dgit";
1192     my $cachekey =
1193         access_cfg('aptget-cachekey','RETURN-UNDEF')
1194         // access_nomdistro();
1195
1196     $aptget_base = "$cache/dgit/aptget";
1197     ensuredir $aptget_base;
1198
1199     my $quoted_base = $aptget_base;
1200     die "$quoted_base contains bad chars, cannot continue"
1201         if $quoted_base =~ m/["\\]/; # apt.conf(5) says no escaping :-/
1202
1203     ensuredir $aptget_base;
1204
1205     aptget_lock_acquire();
1206
1207     aptget_cache_clean();
1208
1209     $aptget_configpath = "$aptget_base/apt.conf#$cachekey";
1210     my $sourceslist = "source.list#$cachekey";
1211
1212     my $aptsuites = $isuite;
1213     cfg_apply_map(\$aptsuites, 'suite map',
1214                   access_cfg('aptget-suite-map', 'RETURN-UNDEF'));
1215
1216     open SRCS, ">", "$aptget_base/$sourceslist" or die $!;
1217     printf SRCS "deb-src %s %s %s\n",
1218         access_cfg('mirror'),
1219         $aptsuites,
1220         access_cfg('aptget-components')
1221         or die $!;
1222
1223     ensuredir "$aptget_base/cache";
1224     ensuredir "$aptget_base/lists";
1225
1226     open CONF, ">", $aptget_configpath or die $!;
1227     print CONF <<END;
1228 Debug::NoLocking "true";
1229 APT::Get::List-Cleanup "false";
1230 #clear APT::Update::Post-Invoke-Success;
1231 Dir::Etc::SourceList "$quoted_base/$sourceslist";
1232 Dir::State::Lists "$quoted_base/lists";
1233 Dir::Etc::preferences "$quoted_base/preferences";
1234 Dir::Cache::srcpkgcache "$quoted_base/cache/srcs#$cachekey";
1235 Dir::Cache::pkgcache "$quoted_base/cache/pkgs#$cachekey";
1236 END
1237
1238     foreach my $key (qw(
1239                         Dir::Cache
1240                         Dir::State
1241                         Dir::Cache::Archives
1242                         Dir::Etc::SourceParts
1243                         Dir::Etc::preferencesparts
1244                       )) {
1245         ensuredir "$aptget_base/$key";
1246         print CONF "$key \"$quoted_base/$key\";\n" or die $!;
1247     };
1248
1249     my $oldatime = (time // die $!) - 1;
1250     foreach my $oldlist (<$aptget_base/lists/*Release>) {
1251         next unless stat_exists $oldlist;
1252         my ($mtime) = (stat _)[9];
1253         utime $oldatime, $mtime, $oldlist or die "$oldlist $!";
1254     }
1255
1256     runcmd_ordryrun_local aptget_aptget(), qw(update);
1257
1258     my @releasefiles;
1259     foreach my $oldlist (<$aptget_base/lists/*Release>) {
1260         next unless stat_exists $oldlist;
1261         my ($atime) = (stat _)[8];
1262         next if $atime == $oldatime;
1263         push @releasefiles, $oldlist;
1264     }
1265     my @inreleasefiles = grep { m#/InRelease$# } @releasefiles;
1266     @releasefiles = @inreleasefiles if @inreleasefiles;
1267     die "apt updated wrong number of Release files (@releasefiles), erk"
1268         unless @releasefiles == 1;
1269
1270     ($aptget_releasefile) = @releasefiles;
1271 }
1272
1273 sub canonicalise_suite_aptget {
1274     my ($proto,$data) = @_;
1275     aptget_prep($data);
1276
1277     my $release = parsecontrol $aptget_releasefile, "Release file", 1;
1278
1279     foreach my $name (qw(Codename Suite)) {
1280         my $val = $release->{$name};
1281         if (defined $val) {
1282             printdebug "release file $name: $val\n";
1283             $val =~ m/^$suite_re$/o or fail
1284  "Release file ($aptget_releasefile) specifies intolerable $name";
1285             cfg_apply_map(\$val, 'suite rmap',
1286                           access_cfg('aptget-suite-rmap', 'RETURN-UNDEF'));
1287             return $val
1288         }
1289     }
1290     return $isuite;
1291 }
1292
1293 sub archive_query_aptget {
1294     my ($proto,$data) = @_;
1295     aptget_prep($data);
1296
1297     ensuredir "$aptget_base/source";
1298     foreach my $old (<$aptget_base/source/*.dsc>) {
1299         unlink $old or die "$old: $!";
1300     }
1301
1302     my $showsrc = cmdoutput aptget_aptcache(), qw(showsrc), $package;
1303     return () unless $showsrc =~ m/^package:\s*\Q$package\E\s*$/mi;
1304     # avoids apt-get source failing with ambiguous error code
1305
1306     runcmd_ordryrun_local
1307         shell_cmd 'cd "$1"/source; shift', $aptget_base,
1308         aptget_aptget(), qw(--download-only --only-source source), $package;
1309
1310     my @dscs = <$aptget_base/source/*.dsc>;
1311     fail "apt-get source did not produce a .dsc" unless @dscs;
1312     fail "apt-get source produced several .dscs (@dscs)" unless @dscs==1;
1313
1314     my $pre_dsc = parsecontrol $dscs[0], $dscs[0], 1;
1315
1316     use URI::Escape;
1317     my $uri = "file://". uri_escape $dscs[0];
1318     $uri =~ s{\%2f}{/}gi;
1319     return [ (getfield $pre_dsc, 'Version'), $uri ];
1320 }
1321
1322 sub file_in_archive_aptget () { return undef; }
1323
1324 #---------- `dummyapicat' archive query method ----------
1325
1326 sub archive_query_dummycatapi { archive_query_ftpmasterapi @_; }
1327 sub canonicalise_suite_dummycatapi { canonicalise_suite_ftpmasterapi @_; }
1328
1329 sub file_in_archive_dummycatapi ($$$) {
1330     my ($proto,$data,$filename) = @_;
1331     my $mirror = access_cfg('mirror');
1332     $mirror =~ s#^file://#/# or die "$mirror ?";
1333     my @out;
1334     my @cmd = (qw(sh -ec), '
1335             cd "$1"
1336             find -name "$2" -print0 |
1337             xargs -0r sha256sum
1338         ', qw(x), $mirror, $filename);
1339     debugcmd "-|", @cmd;
1340     open FIA, "-|", @cmd or die $!;
1341     while (<FIA>) {
1342         chomp or die;
1343         printdebug "| $_\n";
1344         m/^(\w+)  (\S+)$/ or die "$_ ?";
1345         push @out, { sha256sum => $1, filename => $2 };
1346     }
1347     close FIA or die failedcmd @cmd;
1348     return \@out;
1349 }
1350
1351 #---------- `madison' archive query method ----------
1352
1353 sub archive_query_madison {
1354     return archive_query_prepend_mirror
1355         map { [ @$_[0..1] ] } madison_get_parse(@_);
1356 }
1357
1358 sub madison_get_parse {
1359     my ($proto,$data) = @_;
1360     die unless $proto eq 'madison';
1361     if (!length $data) {
1362         $data= access_cfg('madison-distro','RETURN-UNDEF');
1363         $data //= access_basedistro();
1364     }
1365     $rmad{$proto,$data,$package} ||= cmdoutput
1366         qw(rmadison -asource),"-s$isuite","-u$data",$package;
1367     my $rmad = $rmad{$proto,$data,$package};
1368
1369     my @out;
1370     foreach my $l (split /\n/, $rmad) {
1371         $l =~ m{^ \s*( [^ \t|]+ )\s* \|
1372                   \s*( [^ \t|]+ )\s* \|
1373                   \s*( [^ \t|/]+ )(?:/([^ \t|/]+))? \s* \|
1374                   \s*( [^ \t|]+ )\s* }x or die "$rmad ?";
1375         $1 eq $package or die "$rmad $package ?";
1376         my $vsn = $2;
1377         my $newsuite = $3;
1378         my $component;
1379         if (defined $4) {
1380             $component = $4;
1381         } else {
1382             $component = access_cfg('archive-query-default-component');
1383         }
1384         $5 eq 'source' or die "$rmad ?";
1385         push @out, [$vsn,pool_dsc_subpath($vsn,$component),$newsuite];
1386     }
1387     return sort { -version_compare($a->[0],$b->[0]); } @out;
1388 }
1389
1390 sub canonicalise_suite_madison {
1391     # madison canonicalises for us
1392     my @r = madison_get_parse(@_);
1393     @r or fail
1394         "unable to canonicalise suite using package $package".
1395         " which does not appear to exist in suite $isuite;".
1396         " --existing-package may help";
1397     return $r[0][2];
1398 }
1399
1400 sub file_in_archive_madison { return undef; }
1401
1402 #---------- `sshpsql' archive query method ----------
1403
1404 sub sshpsql ($$$) {
1405     my ($data,$runeinfo,$sql) = @_;
1406     if (!length $data) {
1407         $data= access_someuserhost('sshpsql').':'.
1408             access_cfg('sshpsql-dbname');
1409     }
1410     $data =~ m/:/ or badcfg "invalid sshpsql method string \`$data'";
1411     my ($userhost,$dbname) = ($`,$'); #';
1412     my @rows;
1413     my @cmd = (access_cfg_ssh, $userhost,
1414                access_runeinfo("ssh-psql $runeinfo").
1415                " export LC_MESSAGES=C; export LC_CTYPE=C;".
1416                " ".shellquote qw(psql -A), $dbname, qw(-c), $sql);
1417     debugcmd "|",@cmd;
1418     open P, "-|", @cmd or die $!;
1419     while (<P>) {
1420         chomp or die;
1421         printdebug(">|$_|\n");
1422         push @rows, $_;
1423     }
1424     $!=0; $?=0; close P or failedcmd @cmd;
1425     @rows or die;
1426     my $nrows = pop @rows;
1427     $nrows =~ s/^\((\d+) rows?\)$/$1/ or die "$nrows ?";
1428     @rows == $nrows+1 or die "$nrows ".(scalar @rows)." ?";
1429     @rows = map { [ split /\|/, $_ ] } @rows;
1430     my $ncols = scalar @{ shift @rows };
1431     die if grep { scalar @$_ != $ncols } @rows;
1432     return @rows;
1433 }
1434
1435 sub sql_injection_check {
1436     foreach (@_) { die "$_ $& ?" if m{[^-+=:_.,/0-9a-zA-Z]}; }
1437 }
1438
1439 sub archive_query_sshpsql ($$) {
1440     my ($proto,$data) = @_;
1441     sql_injection_check $isuite, $package;
1442     my @rows = sshpsql($data, "archive-query $isuite $package", <<END);
1443         SELECT source.version, component.name, files.filename, files.sha256sum
1444           FROM source
1445           JOIN src_associations ON source.id = src_associations.source
1446           JOIN suite ON suite.id = src_associations.suite
1447           JOIN dsc_files ON dsc_files.source = source.id
1448           JOIN files_archive_map ON files_archive_map.file_id = dsc_files.file
1449           JOIN component ON component.id = files_archive_map.component_id
1450           JOIN files ON files.id = dsc_files.file
1451          WHERE ( suite.suite_name='$isuite' OR suite.codename='$isuite' )
1452            AND source.source='$package'
1453            AND files.filename LIKE '%.dsc';
1454 END
1455     @rows = sort { -version_compare($a->[0],$b->[0]) } @rows;
1456     my $digester = Digest::SHA->new(256);
1457     @rows = map {
1458         my ($vsn,$component,$filename,$sha256sum) = @$_;
1459         [ $vsn, "/pool/$component/$filename",$digester,$sha256sum ];
1460     } @rows;
1461     return archive_query_prepend_mirror @rows;
1462 }
1463
1464 sub canonicalise_suite_sshpsql ($$) {
1465     my ($proto,$data) = @_;
1466     sql_injection_check $isuite;
1467     my @rows = sshpsql($data, "canonicalise-suite $isuite", <<END);
1468         SELECT suite.codename
1469           FROM suite where suite_name='$isuite' or codename='$isuite';
1470 END
1471     @rows = map { $_->[0] } @rows;
1472     fail "unknown suite $isuite" unless @rows;
1473     die "ambiguous $isuite: @rows ?" if @rows>1;
1474     return $rows[0];
1475 }
1476
1477 sub file_in_archive_sshpsql ($$$) { return undef; }
1478
1479 #---------- `dummycat' archive query method ----------
1480
1481 sub canonicalise_suite_dummycat ($$) {
1482     my ($proto,$data) = @_;
1483     my $dpath = "$data/suite.$isuite";
1484     if (!open C, "<", $dpath) {
1485         $!==ENOENT or die "$dpath: $!";
1486         printdebug "dummycat canonicalise_suite $isuite $dpath ENOENT\n";
1487         return $isuite;
1488     }
1489     $!=0; $_ = <C>;
1490     chomp or die "$dpath: $!";
1491     close C;
1492     printdebug "dummycat canonicalise_suite $isuite $dpath = $_\n";
1493     return $_;
1494 }
1495
1496 sub archive_query_dummycat ($$) {
1497     my ($proto,$data) = @_;
1498     canonicalise_suite();
1499     my $dpath = "$data/package.$csuite.$package";
1500     if (!open C, "<", $dpath) {
1501         $!==ENOENT or die "$dpath: $!";
1502         printdebug "dummycat query $csuite $package $dpath ENOENT\n";
1503         return ();
1504     }
1505     my @rows;
1506     while (<C>) {
1507         next if m/^\#/;
1508         next unless m/\S/;
1509         die unless chomp;
1510         printdebug "dummycat query $csuite $package $dpath | $_\n";
1511         my @row = split /\s+/, $_;
1512         @row==2 or die "$dpath: $_ ?";
1513         push @rows, \@row;
1514     }
1515     C->error and die "$dpath: $!";
1516     close C;
1517     return archive_query_prepend_mirror
1518         sort { -version_compare($a->[0],$b->[0]); } @rows;
1519 }
1520
1521 sub file_in_archive_dummycat () { return undef; }
1522
1523 #---------- tag format handling ----------
1524
1525 sub access_cfg_tagformats () {
1526     split /\,/, access_cfg('dgit-tag-format');
1527 }
1528
1529 sub access_cfg_tagformats_can_splitbrain () {
1530     my %y = map { $_ => 1 } access_cfg_tagformats;
1531     foreach my $needtf (qw(new maint)) {
1532         next if $y{$needtf};
1533         return 0;
1534     }
1535     return 1;
1536 }
1537
1538 sub need_tagformat ($$) {
1539     my ($fmt, $why) = @_;
1540     fail "need to use tag format $fmt ($why) but also need".
1541         " to use tag format $tagformat_want->[0] ($tagformat_want->[1])".
1542         " - no way to proceed"
1543         if $tagformat_want && $tagformat_want->[0] ne $fmt;
1544     $tagformat_want = [$fmt, $why, $tagformat_want->[2] // 0];
1545 }
1546
1547 sub select_tagformat () {
1548     # sets $tagformatfn
1549     return if $tagformatfn && !$tagformat_want;
1550     die 'bug' if $tagformatfn && $tagformat_want;
1551     # ... $tagformat_want assigned after previous select_tagformat
1552
1553     my (@supported) = grep { $_ =~ m/^(?:old|new)$/ } access_cfg_tagformats();
1554     printdebug "select_tagformat supported @supported\n";
1555
1556     $tagformat_want //= [ $supported[0], "distro access configuration", 0 ];
1557     printdebug "select_tagformat specified @$tagformat_want\n";
1558
1559     my ($fmt,$why,$override) = @$tagformat_want;
1560
1561     fail "target distro supports tag formats @supported".
1562         " but have to use $fmt ($why)"
1563         unless $override
1564             or grep { $_ eq $fmt } @supported;
1565
1566     $tagformat_want = undef;
1567     $tagformat = $fmt;
1568     $tagformatfn = ${*::}{"debiantag_$fmt"};
1569
1570     fail "trying to use unknown tag format \`$fmt' ($why) !"
1571         unless $tagformatfn;
1572 }
1573
1574 #---------- archive query entrypoints and rest of program ----------
1575
1576 sub canonicalise_suite () {
1577     return if defined $csuite;
1578     fail "cannot operate on $isuite suite" if $isuite eq 'UNRELEASED';
1579     $csuite = archive_query('canonicalise_suite');
1580     if ($isuite ne $csuite) {
1581         progress "canonical suite name for $isuite is $csuite";
1582     } else {
1583         progress "canonical suite name is $csuite";
1584     }
1585 }
1586
1587 sub get_archive_dsc () {
1588     canonicalise_suite();
1589     my @vsns = archive_query('archive_query');
1590     foreach my $vinfo (@vsns) {
1591         my ($vsn,$vsn_dscurl,$digester,$digest) = @$vinfo;
1592         $dscurl = $vsn_dscurl;
1593         $dscdata = url_get($dscurl);
1594         if (!$dscdata) {
1595             $skew_warning_vsn = $vsn if !defined $skew_warning_vsn;
1596             next;
1597         }
1598         if ($digester) {
1599             $digester->reset();
1600             $digester->add($dscdata);
1601             my $got = $digester->hexdigest();
1602             $got eq $digest or
1603                 fail "$dscurl has hash $got but".
1604                     " archive told us to expect $digest";
1605         }
1606         parse_dscdata();
1607         my $fmt = getfield $dsc, 'Format';
1608         $format_ok{$fmt} or forceable_fail [qw(unsupported-source-format)],
1609             "unsupported source format $fmt, sorry";
1610
1611         $dsc_checked = !!$digester;
1612         printdebug "get_archive_dsc: Version ".(getfield $dsc, 'Version')."\n";
1613         return;
1614     }
1615     $dsc = undef;
1616     printdebug "get_archive_dsc: nothing in archive, returning undef\n";
1617 }
1618
1619 sub check_for_git ();
1620 sub check_for_git () {
1621     # returns 0 or 1
1622     my $how = access_cfg('git-check');
1623     if ($how eq 'ssh-cmd') {
1624         my @cmd =
1625             (access_cfg_ssh, access_gituserhost(),
1626              access_runeinfo("git-check $package").
1627              " set -e; cd ".access_cfg('git-path').";".
1628              " if test -d $package.git; then echo 1; else echo 0; fi");
1629         my $r= cmdoutput @cmd;
1630         if (defined $r and $r =~ m/^divert (\w+)$/) {
1631             my $divert=$1;
1632             my ($usedistro,) = access_distros();
1633             # NB that if we are pushing, $usedistro will be $distro/push
1634             $instead_distro= cfg("dgit-distro.$usedistro.diverts.$divert");
1635             $instead_distro =~ s{^/}{ access_basedistro()."/" }e;
1636             progress "diverting to $divert (using config for $instead_distro)";
1637             return check_for_git();
1638         }
1639         failedcmd @cmd unless defined $r and $r =~ m/^[01]$/;
1640         return $r+0;
1641     } elsif ($how eq 'url') {
1642         my $prefix = access_cfg('git-check-url','git-url');
1643         my $suffix = access_cfg('git-check-suffix','git-suffix',
1644                                 'RETURN-UNDEF') // '.git';
1645         my $url = "$prefix/$package$suffix";
1646         my @cmd = (@curl, qw(-sS -I), $url);
1647         my $result = cmdoutput @cmd;
1648         $result =~ s/^\S+ 200 .*\n\r?\n//;
1649         # curl -sS -I with https_proxy prints
1650         # HTTP/1.0 200 Connection established
1651         $result =~ m/^\S+ (404|200) /s or
1652             fail "unexpected results from git check query - ".
1653                 Dumper($prefix, $result);
1654         my $code = $1;
1655         if ($code eq '404') {
1656             return 0;
1657         } elsif ($code eq '200') {
1658             return 1;
1659         } else {
1660             die;
1661         }
1662     } elsif ($how eq 'true') {
1663         return 1;
1664     } elsif ($how eq 'false') {
1665         return 0;
1666     } else {
1667         badcfg "unknown git-check \`$how'";
1668     }
1669 }
1670
1671 sub create_remote_git_repo () {
1672     my $how = access_cfg('git-create');
1673     if ($how eq 'ssh-cmd') {
1674         runcmd_ordryrun
1675             (access_cfg_ssh, access_gituserhost(),
1676              access_runeinfo("git-create $package").
1677              "set -e; cd ".access_cfg('git-path').";".
1678              " cp -a _template $package.git");
1679     } elsif ($how eq 'true') {
1680         # nothing to do
1681     } else {
1682         badcfg "unknown git-create \`$how'";
1683     }
1684 }
1685
1686 our ($dsc_hash,$lastpush_mergeinput);
1687 our ($dsc_distro, $dsc_hint_tag, $dsc_hint_url);
1688
1689 our $ud = '.git/dgit/unpack';
1690
1691 sub prep_ud (;$) {
1692     my ($d) = @_;
1693     $d //= $ud;
1694     rmtree($d);
1695     mkpath '.git/dgit';
1696     mkdir $d or die $!;
1697 }
1698
1699 sub mktree_in_ud_here () {
1700     runcmd qw(git init -q);
1701     runcmd qw(git config gc.auto 0);
1702     rmtree('.git/objects');
1703     symlink '../../../../objects','.git/objects' or die $!;
1704     setup_gitattrs(1);
1705 }
1706
1707 sub git_write_tree () {
1708     my $tree = cmdoutput @git, qw(write-tree);
1709     $tree =~ m/^\w+$/ or die "$tree ?";
1710     return $tree;
1711 }
1712
1713 sub git_add_write_tree () {
1714     runcmd @git, qw(add -Af .);
1715     return git_write_tree();
1716 }
1717
1718 sub remove_stray_gits ($) {
1719     my ($what) = @_;
1720     my @gitscmd = qw(find -name .git -prune -print0);
1721     debugcmd "|",@gitscmd;
1722     open GITS, "-|", @gitscmd or die $!;
1723     {
1724         local $/="\0";
1725         while (<GITS>) {
1726             chomp or die;
1727             print STDERR "$us: warning: removing from $what: ",
1728                 (messagequote $_), "\n";
1729             rmtree $_;
1730         }
1731     }
1732     $!=0; $?=0; close GITS or failedcmd @gitscmd;
1733 }
1734
1735 sub mktree_in_ud_from_only_subdir ($;$) {
1736     my ($what,$raw) = @_;
1737
1738     # changes into the subdir
1739     my (@dirs) = <*/.>;
1740     die "expected one subdir but found @dirs ?" unless @dirs==1;
1741     $dirs[0] =~ m#^([^/]+)/\.$# or die;
1742     my $dir = $1;
1743     changedir $dir;
1744
1745     remove_stray_gits($what);
1746     mktree_in_ud_here();
1747     if (!$raw) {
1748         my ($format, $fopts) = get_source_format();
1749         if (madformat($format)) {
1750             rmtree '.pc';
1751         }
1752     }
1753
1754     my $tree=git_add_write_tree();
1755     return ($tree,$dir);
1756 }
1757
1758 our @files_csum_info_fields =
1759     (['Checksums-Sha256','Digest::SHA', 'new(256)', 'sha256sum'],
1760      ['Checksums-Sha1',  'Digest::SHA', 'new(1)',   'sha1sum'],
1761      ['Files',           'Digest::MD5', 'new()',    'md5sum']);
1762
1763 sub dsc_files_info () {
1764     foreach my $csumi (@files_csum_info_fields) {
1765         my ($fname, $module, $method) = @$csumi;
1766         my $field = $dsc->{$fname};
1767         next unless defined $field;
1768         eval "use $module; 1;" or die $@;
1769         my @out;
1770         foreach (split /\n/, $field) {
1771             next unless m/\S/;
1772             m/^(\w+) (\d+) (\S+)$/ or
1773                 fail "could not parse .dsc $fname line \`$_'";
1774             my $digester = eval "$module"."->$method;" or die $@;
1775             push @out, {
1776                 Hash => $1,
1777                 Bytes => $2,
1778                 Filename => $3,
1779                 Digester => $digester,
1780             };
1781         }
1782         return @out;
1783     }
1784     fail "missing any supported Checksums-* or Files field in ".
1785         $dsc->get_option('name');
1786 }
1787
1788 sub dsc_files () {
1789     map { $_->{Filename} } dsc_files_info();
1790 }
1791
1792 sub files_compare_inputs (@) {
1793     my $inputs = \@_;
1794     my %record;
1795     my %fchecked;
1796
1797     my $showinputs = sub {
1798         return join "; ", map { $_->get_option('name') } @$inputs;
1799     };
1800
1801     foreach my $in (@$inputs) {
1802         my $expected_files;
1803         my $in_name = $in->get_option('name');
1804
1805         printdebug "files_compare_inputs $in_name\n";
1806
1807         foreach my $csumi (@files_csum_info_fields) {
1808             my ($fname) = @$csumi;
1809             printdebug "files_compare_inputs $in_name $fname\n";
1810
1811             my $field = $in->{$fname};
1812             next unless defined $field;
1813
1814             my @files;
1815             foreach (split /\n/, $field) {
1816                 next unless m/\S/;
1817
1818                 my ($info, $f) = m/^(\w+ \d+) (?:\S+ \S+ )?(\S+)$/ or
1819                     fail "could not parse $in_name $fname line \`$_'";
1820
1821                 printdebug "files_compare_inputs $in_name $fname $f\n";
1822
1823                 push @files, $f;
1824
1825                 my $re = \ $record{$f}{$fname};
1826                 if (defined $$re) {
1827                     $fchecked{$f}{$in_name} = 1;
1828                     $$re eq $info or
1829                         fail "hash or size of $f varies in $fname fields".
1830                         " (between: ".$showinputs->().")";
1831                 } else {
1832                     $$re = $info;
1833                 }
1834             }
1835             @files = sort @files;
1836             $expected_files //= \@files;
1837             "@$expected_files" eq "@files" or
1838                 fail "file list in $in_name varies between hash fields!";
1839         }
1840         $expected_files or
1841             fail "$in_name has no files list field(s)";
1842     }
1843     printdebug "files_compare_inputs ".Dumper(\%fchecked, \%record)
1844         if $debuglevel>=2;
1845
1846     grep { keys %$_ == @$inputs-1 } values %fchecked
1847         or fail "no file appears in all file lists".
1848         " (looked in: ".$showinputs->().")";
1849 }
1850
1851 sub is_orig_file_in_dsc ($$) {
1852     my ($f, $dsc_files_info) = @_;
1853     return 0 if @$dsc_files_info <= 1;
1854     # One file means no origs, and the filename doesn't have a "what
1855     # part of dsc" component.  (Consider versions ending `.orig'.)
1856     return 0 unless $f =~ m/\.$orig_f_tail_re$/o;
1857     return 1;
1858 }
1859
1860 sub is_orig_file_of_vsn ($$) {
1861     my ($f, $upstreamvsn) = @_;
1862     my $base = srcfn $upstreamvsn, '';
1863     return 0 unless $f =~ m/^\Q$base\E\.$orig_f_tail_re$/;
1864     return 1;
1865 }
1866
1867 sub changes_update_origs_from_dsc ($$$$) {
1868     my ($dsc, $changes, $upstreamvsn, $changesfile) = @_;
1869     my %changes_f;
1870     printdebug "checking origs needed ($upstreamvsn)...\n";
1871     $_ = getfield $changes, 'Files';
1872     m/^\w+ \d+ (\S+ \S+) \S+$/m or
1873         fail "cannot find section/priority from .changes Files field";
1874     my $placementinfo = $1;
1875     my %changed;
1876     printdebug "checking origs needed placement '$placementinfo'...\n";
1877     foreach my $l (split /\n/, getfield $dsc, 'Files') {
1878         $l =~ m/\S+$/ or next;
1879         my $file = $&;
1880         printdebug "origs $file | $l\n";
1881         next unless is_orig_file_of_vsn $file, $upstreamvsn;
1882         printdebug "origs $file is_orig\n";
1883         my $have = archive_query('file_in_archive', $file);
1884         if (!defined $have) {
1885             print STDERR <<END;
1886 archive does not support .orig check; hope you used --ch:--sa/-sd if needed
1887 END
1888             return;
1889         }
1890         my $found_same = 0;
1891         my @found_differ;
1892         printdebug "origs $file \$#\$have=$#$have\n";
1893         foreach my $h (@$have) {
1894             my $same = 0;
1895             my @differ;
1896             foreach my $csumi (@files_csum_info_fields) {
1897                 my ($fname, $module, $method, $archivefield) = @$csumi;
1898                 next unless defined $h->{$archivefield};
1899                 $_ = $dsc->{$fname};
1900                 next unless defined;
1901                 m/^(\w+) .* \Q$file\E$/m or
1902                     fail ".dsc $fname missing entry for $file";
1903                 if ($h->{$archivefield} eq $1) {
1904                     $same++;
1905                 } else {
1906                     push @differ,
1907  "$archivefield: $h->{$archivefield} (archive) != $1 (local .dsc)";
1908                 }
1909             }
1910             die "$file ".Dumper($h)." ?!" if $same && @differ;
1911             $found_same++
1912                 if $same;
1913             push @found_differ, "archive $h->{filename}: ".join "; ", @differ
1914                 if @differ;
1915         }
1916         printdebug "origs $file f.same=$found_same".
1917             " #f._differ=$#found_differ\n";
1918         if (@found_differ && !$found_same) {
1919             fail join "\n",
1920                 "archive contains $file with different checksum",
1921                 @found_differ;
1922         }
1923         # Now we edit the changes file to add or remove it
1924         foreach my $csumi (@files_csum_info_fields) {
1925             my ($fname, $module, $method, $archivefield) = @$csumi;
1926             next unless defined $changes->{$fname};
1927             if ($found_same) {
1928                 # in archive, delete from .changes if it's there
1929                 $changed{$file} = "removed" if
1930                     $changes->{$fname} =~ s/^.* \Q$file\E$(?:)\n//m;
1931             } elsif ($changes->{$fname} =~ m/^.* \Q$file\E$(?:)\n/m) {
1932                 # not in archive, but it's here in the .changes
1933             } else {
1934                 my $dsc_data = getfield $dsc, $fname;
1935                 $dsc_data =~ m/^(.* \Q$file\E$)\n/m or die "$dsc_data $file ?";
1936                 my $extra = $1;
1937                 $extra =~ s/ \d+ /$&$placementinfo /
1938                     or die "$fname $extra >$dsc_data< ?"
1939                     if $fname eq 'Files';
1940                 $changes->{$fname} .= "\n". $extra;
1941                 $changed{$file} = "added";
1942             }
1943         }
1944     }
1945     if (%changed) {
1946         foreach my $file (keys %changed) {
1947             progress sprintf
1948                 "edited .changes for archive .orig contents: %s %s",
1949                 $changed{$file}, $file;
1950         }
1951         my $chtmp = "$changesfile.tmp";
1952         $changes->save($chtmp);
1953         if (act_local()) {
1954             rename $chtmp,$changesfile or die "$changesfile $!";
1955         } else {
1956             progress "[new .changes left in $changesfile]";
1957         }
1958     } else {
1959         progress "$changesfile already has appropriate .orig(s) (if any)";
1960     }
1961 }
1962
1963 sub make_commit ($) {
1964     my ($file) = @_;
1965     return cmdoutput @git, qw(hash-object -w -t commit), $file;
1966 }
1967
1968 sub make_commit_text ($) {
1969     my ($text) = @_;
1970     my ($out, $in);
1971     my @cmd = (@git, qw(hash-object -w -t commit --stdin));
1972     debugcmd "|",@cmd;
1973     print Dumper($text) if $debuglevel > 1;
1974     my $child = open2($out, $in, @cmd) or die $!;
1975     my $h;
1976     eval {
1977         print $in $text or die $!;
1978         close $in or die $!;
1979         $h = <$out>;
1980         $h =~ m/^\w+$/ or die;
1981         $h = $&;
1982         printdebug "=> $h\n";
1983     };
1984     close $out;
1985     waitpid $child, 0 == $child or die "$child $!";
1986     $? and failedcmd @cmd;
1987     return $h;
1988 }
1989
1990 sub clogp_authline ($) {
1991     my ($clogp) = @_;
1992     my $author = getfield $clogp, 'Maintainer';
1993     $author =~ s#,.*##ms;
1994     my $date = cmdoutput qw(date), '+%s %z', qw(-d), getfield($clogp,'Date');
1995     my $authline = "$author $date";
1996     $authline =~ m/$git_authline_re/o or
1997         fail "unexpected commit author line format \`$authline'".
1998         " (was generated from changelog Maintainer field)";
1999     return ($1,$2,$3) if wantarray;
2000     return $authline;
2001 }
2002
2003 sub vendor_patches_distro ($$) {
2004     my ($checkdistro, $what) = @_;
2005     return unless defined $checkdistro;
2006
2007     my $series = "debian/patches/\L$checkdistro\E.series";
2008     printdebug "checking for vendor-specific $series ($what)\n";
2009
2010     if (!open SERIES, "<", $series) {
2011         die "$series $!" unless $!==ENOENT;
2012         return;
2013     }
2014     while (<SERIES>) {
2015         next unless m/\S/;
2016         next if m/^\s+\#/;
2017
2018         print STDERR <<END;
2019
2020 Unfortunately, this source package uses a feature of dpkg-source where
2021 the same source package unpacks to different source code on different
2022 distros.  dgit cannot safely operate on such packages on affected
2023 distros, because the meaning of source packages is not stable.
2024
2025 Please ask the distro/maintainer to remove the distro-specific series
2026 files and use a different technique (if necessary, uploading actually
2027 different packages, if different distros are supposed to have
2028 different code).
2029
2030 END
2031         fail "Found active distro-specific series file for".
2032             " $checkdistro ($what): $series, cannot continue";
2033     }
2034     die "$series $!" if SERIES->error;
2035     close SERIES;
2036 }
2037
2038 sub check_for_vendor_patches () {
2039     # This dpkg-source feature doesn't seem to be documented anywhere!
2040     # But it can be found in the changelog (reformatted):
2041
2042     #   commit  4fa01b70df1dc4458daee306cfa1f987b69da58c
2043     #   Author: Raphael Hertzog <hertzog@debian.org>
2044     #   Date: Sun  Oct  3  09:36:48  2010 +0200
2045
2046     #   dpkg-source: correctly create .pc/.quilt_series with alternate
2047     #   series files
2048     #
2049     #   If you have debian/patches/ubuntu.series and you were
2050     #   unpacking the source package on ubuntu, quilt was still
2051     #   directed to debian/patches/series instead of
2052     #   debian/patches/ubuntu.series.
2053     #
2054     #   debian/changelog                        |    3 +++
2055     #   scripts/Dpkg/Source/Package/V3/quilt.pm |    4 +++-
2056     #   2 files changed, 6 insertions(+), 1 deletion(-)
2057
2058     use Dpkg::Vendor;
2059     vendor_patches_distro($ENV{DEB_VENDOR}, "DEB_VENDOR");
2060     vendor_patches_distro(Dpkg::Vendor::get_current_vendor(),
2061                          "Dpkg::Vendor \`current vendor'");
2062     vendor_patches_distro(access_basedistro(),
2063                           "(base) distro being accessed");
2064     vendor_patches_distro(access_nomdistro(),
2065                           "(nominal) distro being accessed");
2066 }
2067
2068 sub generate_commits_from_dsc () {
2069     # See big comment in fetch_from_archive, below.
2070     # See also README.dsc-import.
2071     prep_ud();
2072     changedir $ud;
2073
2074     my @dfi = dsc_files_info();
2075     foreach my $fi (@dfi) {
2076         my $f = $fi->{Filename};
2077         die "$f ?" if $f =~ m#/|^\.|\.dsc$|\.tmp$#;
2078         my $upper_f = "../../../../$f";
2079
2080         printdebug "considering reusing $f: ";
2081
2082         if (link_ltarget "$upper_f,fetch", $f) {
2083             printdebug "linked (using ...,fetch).\n";
2084         } elsif ((printdebug "($!) "),
2085                  $! != ENOENT) {
2086             fail "accessing ../$f,fetch: $!";
2087         } elsif (link_ltarget $upper_f, $f) {
2088             printdebug "linked.\n";
2089         } elsif ((printdebug "($!) "),
2090                  $! != ENOENT) {
2091             fail "accessing ../$f: $!";
2092         } else {
2093             printdebug "absent.\n";
2094         }
2095
2096         my $refetched;
2097         complete_file_from_dsc('.', $fi, \$refetched)
2098             or next;
2099
2100         printdebug "considering saving $f: ";
2101
2102         if (link $f, $upper_f) {
2103             printdebug "linked.\n";
2104         } elsif ((printdebug "($!) "),
2105                  $! != EEXIST) {
2106             fail "saving ../$f: $!";
2107         } elsif (!$refetched) {
2108             printdebug "no need.\n";
2109         } elsif (link $f, "$upper_f,fetch") {
2110             printdebug "linked (using ...,fetch).\n";
2111         } elsif ((printdebug "($!) "),
2112                  $! != EEXIST) {
2113             fail "saving ../$f,fetch: $!";
2114         } else {
2115             printdebug "cannot.\n";
2116         }
2117     }
2118
2119     # We unpack and record the orig tarballs first, so that we only
2120     # need disk space for one private copy of the unpacked source.
2121     # But we can't make them into commits until we have the metadata
2122     # from the debian/changelog, so we record the tree objects now and
2123     # make them into commits later.
2124     my @tartrees;
2125     my $upstreamv = upstreamversion $dsc->{version};
2126     my $orig_f_base = srcfn $upstreamv, '';
2127
2128     foreach my $fi (@dfi) {
2129         # We actually import, and record as a commit, every tarball
2130         # (unless there is only one file, in which case there seems
2131         # little point.
2132
2133         my $f = $fi->{Filename};
2134         printdebug "import considering $f ";
2135         (printdebug "only one dfi\n"), next if @dfi == 1;
2136         (printdebug "not tar\n"), next unless $f =~ m/\.tar(\.\w+)?$/;
2137         (printdebug "signature\n"), next if $f =~ m/$orig_f_sig_re$/o;
2138         my $compr_ext = $1;
2139
2140         my ($orig_f_part) =
2141             $f =~ m/^\Q$orig_f_base\E\.([^._]+)?\.tar(?:\.\w+)?$/;
2142
2143         printdebug "Y ", (join ' ', map { $_//"(none)" }
2144                           $compr_ext, $orig_f_part
2145                          ), "\n";
2146
2147         my $input = new IO::File $f, '<' or die "$f $!";
2148         my $compr_pid;
2149         my @compr_cmd;
2150
2151         if (defined $compr_ext) {
2152             my $cname =
2153                 Dpkg::Compression::compression_guess_from_filename $f;
2154             fail "Dpkg::Compression cannot handle file $f in source package"
2155                 if defined $compr_ext && !defined $cname;
2156             my $compr_proc =
2157                 new Dpkg::Compression::Process compression => $cname;
2158             my @compr_cmd = $compr_proc->get_uncompress_cmdline();
2159             my $compr_fh = new IO::Handle;
2160             my $compr_pid = open $compr_fh, "-|" // die $!;
2161             if (!$compr_pid) {
2162                 open STDIN, "<&", $input or die $!;
2163                 exec @compr_cmd;
2164                 die "dgit (child): exec $compr_cmd[0]: $!\n";
2165             }
2166             $input = $compr_fh;
2167         }
2168
2169         rmtree "_unpack-tar";
2170         mkdir "_unpack-tar" or die $!;
2171         my @tarcmd = qw(tar -x -f -
2172                         --no-same-owner --no-same-permissions
2173                         --no-acls --no-xattrs --no-selinux);
2174         my $tar_pid = fork // die $!;
2175         if (!$tar_pid) {
2176             chdir "_unpack-tar" or die $!;
2177             open STDIN, "<&", $input or die $!;
2178             exec @tarcmd;
2179             die "dgit (child): exec $tarcmd[0]: $!";
2180         }
2181         $!=0; (waitpid $tar_pid, 0) == $tar_pid or die $!;
2182         !$? or failedcmd @tarcmd;
2183
2184         close $input or
2185             (@compr_cmd ? failedcmd @compr_cmd
2186              : die $!);
2187         # finally, we have the results in "tarball", but maybe
2188         # with the wrong permissions
2189
2190         runcmd qw(chmod -R +rwX _unpack-tar);
2191         changedir "_unpack-tar";
2192         remove_stray_gits($f);
2193         mktree_in_ud_here();
2194
2195         my ($tree) = git_add_write_tree();
2196         my $tentries = cmdoutput @git, qw(ls-tree -z), $tree;
2197         if ($tentries =~ m/^\d+ tree (\w+)\t[^\000]+\000$/s) {
2198             $tree = $1;
2199             printdebug "one subtree $1\n";
2200         } else {
2201             printdebug "multiple subtrees\n";
2202         }
2203         changedir "..";
2204         rmtree "_unpack-tar";
2205
2206         my $ent = [ $f, $tree ];
2207         push @tartrees, {
2208             Orig => !!$orig_f_part,
2209             Sort => (!$orig_f_part         ? 2 :
2210                      $orig_f_part =~ m/-/g ? 1 :
2211                                              0),
2212             F => $f,
2213             Tree => $tree,
2214         };
2215     }
2216
2217     @tartrees = sort {
2218         # put any without "_" first (spec is not clear whether files
2219         # are always in the usual order).  Tarballs without "_" are
2220         # the main orig or the debian tarball.
2221         $a->{Sort} <=> $b->{Sort} or
2222         $a->{F}    cmp $b->{F}
2223     } @tartrees;
2224
2225     my $any_orig = grep { $_->{Orig} } @tartrees;
2226
2227     my $dscfn = "$package.dsc";
2228
2229     my $treeimporthow = 'package';
2230
2231     open D, ">", $dscfn or die "$dscfn: $!";
2232     print D $dscdata or die "$dscfn: $!";
2233     close D or die "$dscfn: $!";
2234     my @cmd = qw(dpkg-source);
2235     push @cmd, '--no-check' if $dsc_checked;
2236     if (madformat $dsc->{format}) {
2237         push @cmd, '--skip-patches';
2238         $treeimporthow = 'unpatched';
2239     }
2240     push @cmd, qw(-x --), $dscfn;
2241     runcmd @cmd;
2242
2243     my ($tree,$dir) = mktree_in_ud_from_only_subdir("source package");
2244     if (madformat $dsc->{format}) {
2245         check_for_vendor_patches();
2246     }
2247
2248     my $dappliedtree;
2249     if (madformat $dsc->{format}) {
2250         my @pcmd = qw(dpkg-source --before-build .);
2251         runcmd shell_cmd 'exec >/dev/null', @pcmd;
2252         rmtree '.pc';
2253         $dappliedtree = git_add_write_tree();
2254     }
2255
2256     my @clogcmd = qw(dpkg-parsechangelog --format rfc822 --all);
2257     debugcmd "|",@clogcmd;
2258     open CLOGS, "-|", @clogcmd or die $!;
2259
2260     my $clogp;
2261     my $r1clogp;
2262
2263     printdebug "import clog search...\n";
2264
2265     for (;;) {
2266         my $stanzatext = do { local $/=""; <CLOGS>; };
2267         printdebug "import clogp ".Dumper($stanzatext) if $debuglevel>1;
2268         last if !defined $stanzatext;
2269
2270         my $desc = "package changelog, entry no.$.";
2271         open my $stanzafh, "<", \$stanzatext or die;
2272         my $thisstanza = parsecontrolfh $stanzafh, $desc, 1;
2273         $clogp //= $thisstanza;
2274
2275         printdebug "import clog $thisstanza->{version} $desc...\n";
2276
2277         last if !$any_orig; # we don't need $r1clogp
2278
2279         # We look for the first (most recent) changelog entry whose
2280         # version number is lower than the upstream version of this
2281         # package.  Then the last (least recent) previous changelog
2282         # entry is treated as the one which introduced this upstream
2283         # version and used for the synthetic commits for the upstream
2284         # tarballs.
2285
2286         # One might think that a more sophisticated algorithm would be
2287         # necessary.  But: we do not want to scan the whole changelog
2288         # file.  Stopping when we see an earlier version, which
2289         # necessarily then is an earlier upstream version, is the only
2290         # realistic way to do that.  Then, either the earliest
2291         # changelog entry we have seen so far is indeed the earliest
2292         # upload of this upstream version; or there are only changelog
2293         # entries relating to later upstream versions (which is not
2294         # possible unless the changelog and .dsc disagree about the
2295         # version).  Then it remains to choose between the physically
2296         # last entry in the file, and the one with the lowest version
2297         # number.  If these are not the same, we guess that the
2298         # versions were created in a non-monotic order rather than
2299         # that the changelog entries have been misordered.
2300
2301         printdebug "import clog $thisstanza->{version} vs $upstreamv...\n";
2302
2303         last if version_compare($thisstanza->{version}, $upstreamv) < 0;
2304         $r1clogp = $thisstanza;
2305
2306         printdebug "import clog $r1clogp->{version} becomes r1\n";
2307     }
2308     die $! if CLOGS->error;
2309     close CLOGS or $?==SIGPIPE or failedcmd @clogcmd;
2310
2311     $clogp or fail "package changelog has no entries!";
2312
2313     my $authline = clogp_authline $clogp;
2314     my $changes = getfield $clogp, 'Changes';
2315     my $cversion = getfield $clogp, 'Version';
2316
2317     if (@tartrees) {
2318         $r1clogp //= $clogp; # maybe there's only one entry;
2319         my $r1authline = clogp_authline $r1clogp;
2320         # Strictly, r1authline might now be wrong if it's going to be
2321         # unused because !$any_orig.  Whatever.
2322
2323         printdebug "import tartrees authline   $authline\n";
2324         printdebug "import tartrees r1authline $r1authline\n";
2325
2326         foreach my $tt (@tartrees) {
2327             printdebug "import tartree $tt->{F} $tt->{Tree}\n";
2328
2329             $tt->{Commit} = make_commit_text($tt->{Orig} ? <<END_O : <<END_T);
2330 tree $tt->{Tree}
2331 author $r1authline
2332 committer $r1authline
2333
2334 Import $tt->{F}
2335
2336 [dgit import orig $tt->{F}]
2337 END_O
2338 tree $tt->{Tree}
2339 author $authline
2340 committer $authline
2341
2342 Import $tt->{F}
2343
2344 [dgit import tarball $package $cversion $tt->{F}]
2345 END_T
2346         }
2347     }
2348
2349     printdebug "import main commit\n";
2350
2351     open C, ">../commit.tmp" or die $!;
2352     print C <<END or die $!;
2353 tree $tree
2354 END
2355     print C <<END or die $! foreach @tartrees;
2356 parent $_->{Commit}
2357 END
2358     print C <<END or die $!;
2359 author $authline
2360 committer $authline
2361
2362 $changes
2363
2364 [dgit import $treeimporthow $package $cversion]
2365 END
2366
2367     close C or die $!;
2368     my $rawimport_hash = make_commit qw(../commit.tmp);
2369
2370     if (madformat $dsc->{format}) {
2371         printdebug "import apply patches...\n";
2372
2373         # regularise the state of the working tree so that
2374         # the checkout of $rawimport_hash works nicely.
2375         my $dappliedcommit = make_commit_text(<<END);
2376 tree $dappliedtree
2377 author $authline
2378 committer $authline
2379
2380 [dgit dummy commit]
2381 END
2382         runcmd @git, qw(checkout -q -b dapplied), $dappliedcommit;
2383
2384         runcmd @git, qw(checkout -q -b unpa), $rawimport_hash;
2385
2386         # We need the answers to be reproducible
2387         my @authline = clogp_authline($clogp);
2388         local $ENV{GIT_COMMITTER_NAME} =  $authline[0];
2389         local $ENV{GIT_COMMITTER_EMAIL} = $authline[1];
2390         local $ENV{GIT_COMMITTER_DATE} =  $authline[2];
2391         local $ENV{GIT_AUTHOR_NAME} =  $authline[0];
2392         local $ENV{GIT_AUTHOR_EMAIL} = $authline[1];
2393         local $ENV{GIT_AUTHOR_DATE} =  $authline[2];
2394
2395         my $path = $ENV{PATH} or die;
2396
2397         foreach my $use_absurd (qw(0 1)) {
2398             runcmd @git, qw(checkout -q unpa);
2399             runcmd @git, qw(update-ref -d refs/heads/patch-queue/unpa);
2400             local $ENV{PATH} = $path;
2401             if ($use_absurd) {
2402                 chomp $@;
2403                 progress "warning: $@";
2404                 $path = "$absurdity:$path";
2405                 progress "$us: trying slow absurd-git-apply...";
2406                 rename "../../gbp-pq-output","../../gbp-pq-output.0"
2407                     or $!==ENOENT
2408                     or die $!;
2409             }
2410             eval {
2411                 die "forbid absurd git-apply\n" if $use_absurd
2412                     && forceing [qw(import-gitapply-no-absurd)];
2413                 die "only absurd git-apply!\n" if !$use_absurd
2414                     && forceing [qw(import-gitapply-absurd)];
2415
2416                 local $ENV{DGIT_ABSURD_DEBUG} = $debuglevel if $use_absurd;
2417                 local $ENV{PATH} = $path                    if $use_absurd;
2418
2419                 my @showcmd = (gbp_pq, qw(import));
2420                 my @realcmd = shell_cmd
2421                     'exec >/dev/null 2>>../../gbp-pq-output', @showcmd;
2422                 debugcmd "+",@realcmd;
2423                 if (system @realcmd) {
2424                     die +(shellquote @showcmd).
2425                         " failed: ".
2426                         failedcmd_waitstatus()."\n";
2427                 }
2428
2429                 my $gapplied = git_rev_parse('HEAD');
2430                 my $gappliedtree = cmdoutput @git, qw(rev-parse HEAD:);
2431                 $gappliedtree eq $dappliedtree or
2432                     fail <<END;
2433 gbp-pq import and dpkg-source disagree!
2434  gbp-pq import gave commit $gapplied
2435  gbp-pq import gave tree $gappliedtree
2436  dpkg-source --before-build gave tree $dappliedtree
2437 END
2438                 $rawimport_hash = $gapplied;
2439             };
2440             last unless $@;
2441         }
2442         if ($@) {
2443             { local $@; eval { runcmd qw(cat ../../gbp-pq-output); }; }
2444             die $@;
2445         }
2446     }
2447
2448     progress "synthesised git commit from .dsc $cversion";
2449
2450     my $rawimport_mergeinput = {
2451         Commit => $rawimport_hash,
2452         Info => "Import of source package",
2453     };
2454     my @output = ($rawimport_mergeinput);
2455
2456     if ($lastpush_mergeinput) {
2457         my $oldclogp = mergeinfo_getclogp($lastpush_mergeinput);
2458         my $oversion = getfield $oldclogp, 'Version';
2459         my $vcmp =
2460             version_compare($oversion, $cversion);
2461         if ($vcmp < 0) {
2462             @output = ($rawimport_mergeinput, $lastpush_mergeinput,
2463                 { Message => <<END, ReverseParents => 1 });
2464 Record $package ($cversion) in archive suite $csuite
2465 END
2466         } elsif ($vcmp > 0) {
2467             print STDERR <<END or die $!;
2468
2469 Version actually in archive:   $cversion (older)
2470 Last version pushed with dgit: $oversion (newer or same)
2471 $later_warning_msg
2472 END
2473             @output = $lastpush_mergeinput;
2474         } else {
2475             # Same version.  Use what's in the server git branch,
2476             # discarding our own import.  (This could happen if the
2477             # server automatically imports all packages into git.)
2478             @output = $lastpush_mergeinput;
2479         }
2480     }
2481     changedir '../../../..';
2482     rmtree($ud);
2483     return @output;
2484 }
2485
2486 sub complete_file_from_dsc ($$;$) {
2487     our ($dstdir, $fi, $refetched) = @_;
2488     # Ensures that we have, in $dstdir, the file $fi, with the correct
2489     # contents.  (Downloading it from alongside $dscurl if necessary.)
2490     # If $refetched is defined, can overwrite "$dstdir/$fi->{Filename}"
2491     # and will set $$refetched=1 if it did so (or tried to).
2492
2493     my $f = $fi->{Filename};
2494     my $tf = "$dstdir/$f";
2495     my $downloaded = 0;
2496
2497     my $got;
2498     my $checkhash = sub {
2499         open F, "<", "$tf" or die "$tf: $!";
2500         $fi->{Digester}->reset();
2501         $fi->{Digester}->addfile(*F);
2502         F->error and die $!;
2503         my $got = $fi->{Digester}->hexdigest();
2504         return $got eq $fi->{Hash};
2505     };
2506
2507     if (stat_exists $tf) {
2508         if ($checkhash->()) {
2509             progress "using existing $f";
2510             return 1;
2511         }
2512         if (!$refetched) {
2513             fail "file $f has hash $got but .dsc".
2514                 " demands hash $fi->{Hash} ".
2515                 "(perhaps you should delete this file?)";
2516         }
2517         progress "need to fetch correct version of $f";
2518         unlink $tf or die "$tf $!";
2519         $$refetched = 1;
2520     } else {
2521         printdebug "$tf does not exist, need to fetch\n";
2522     }
2523
2524     my $furl = $dscurl;
2525     $furl =~ s{/[^/]+$}{};
2526     $furl .= "/$f";
2527     die "$f ?" unless $f =~ m/^\Q${package}\E_/;
2528     die "$f ?" if $f =~ m#/#;
2529     runcmd_ordryrun_local @curl,qw(-f -o),$tf,'--',"$furl";
2530     return 0 if !act_local();
2531
2532     $checkhash->() or
2533         fail "file $f has hash $got but .dsc".
2534             " demands hash $fi->{Hash} ".
2535             "(got wrong file from archive!)";
2536
2537     return 1;
2538 }
2539
2540 sub ensure_we_have_orig () {
2541     my @dfi = dsc_files_info();
2542     foreach my $fi (@dfi) {
2543         my $f = $fi->{Filename};
2544         next unless is_orig_file_in_dsc($f, \@dfi);
2545         complete_file_from_dsc('..', $fi)
2546             or next;
2547     }
2548 }
2549
2550 #---------- git fetch ----------
2551
2552 sub lrfetchrefs () { return "refs/dgit-fetch/".access_basedistro(); }
2553 sub lrfetchref () { return lrfetchrefs.'/'.server_branch($csuite); }
2554
2555 # We fetch some parts of lrfetchrefs/*.  Ideally we delete these
2556 # locally fetched refs because they have unhelpful names and clutter
2557 # up gitk etc.  So we track whether we have "used up" head ref (ie,
2558 # whether we have made another local ref which refers to this object).
2559 #
2560 # (If we deleted them unconditionally, then we might end up
2561 # re-fetching the same git objects each time dgit fetch was run.)
2562 #
2563 # So, each use of lrfetchrefs needs to be accompanied by arrangements
2564 # in git_fetch_us to fetch the refs in question, and possibly a call
2565 # to lrfetchref_used.
2566
2567 our (%lrfetchrefs_f, %lrfetchrefs_d);
2568 # $lrfetchrefs_X{lrfetchrefs."/heads/whatever"} = $objid
2569
2570 sub lrfetchref_used ($) {
2571     my ($fullrefname) = @_;
2572     my $objid = $lrfetchrefs_f{$fullrefname};
2573     $lrfetchrefs_d{$fullrefname} = $objid if defined $objid;
2574 }
2575
2576 sub git_lrfetch_sane {
2577     my ($url, $supplementary, @specs) = @_;
2578     # Make a 'refs/'.lrfetchrefs.'/*' be just like on server,
2579     # at least as regards @specs.  Also leave the results in
2580     # %lrfetchrefs_f, and arrange for lrfetchref_used to be
2581     # able to clean these up.
2582     #
2583     # With $supplementary==1, @specs must not contain wildcards
2584     # and we add to our previous fetches (non-atomically).
2585
2586     # This is rather miserable:
2587     # When git fetch --prune is passed a fetchspec ending with a *,
2588     # it does a plausible thing.  If there is no * then:
2589     # - it matches subpaths too, even if the supplied refspec
2590     #   starts refs, and behaves completely madly if the source
2591     #   has refs/refs/something.  (See, for example, Debian #NNNN.)
2592     # - if there is no matching remote ref, it bombs out the whole
2593     #   fetch.
2594     # We want to fetch a fixed ref, and we don't know in advance
2595     # if it exists, so this is not suitable.
2596     #
2597     # Our workaround is to use git ls-remote.  git ls-remote has its
2598     # own qairks.  Notably, it has the absurd multi-tail-matching
2599     # behaviour: git ls-remote R refs/foo can report refs/foo AND
2600     # refs/refs/foo etc.
2601     #
2602     # Also, we want an idempotent snapshot, but we have to make two
2603     # calls to the remote: one to git ls-remote and to git fetch.  The
2604     # solution is use git ls-remote to obtain a target state, and
2605     # git fetch to try to generate it.  If we don't manage to generate
2606     # the target state, we try again.
2607
2608     printdebug "git_lrfetch_sane suppl=$supplementary specs @specs\n";
2609
2610     my $specre = join '|', map {
2611         my $x = $_;
2612         $x =~ s/\W/\\$&/g;
2613         my $wildcard = $x =~ s/\\\*$/.*/;
2614         die if $wildcard && $supplementary;
2615         "(?:refs/$x)";
2616     } @specs;
2617     printdebug "git_lrfetch_sane specre=$specre\n";
2618     my $wanted_rref = sub {
2619         local ($_) = @_;
2620         return m/^(?:$specre)$/;
2621     };
2622
2623     my $fetch_iteration = 0;
2624     FETCH_ITERATION:
2625     for (;;) {
2626         printdebug "git_lrfetch_sane iteration $fetch_iteration\n";
2627         if (++$fetch_iteration > 10) {
2628             fail "too many iterations trying to get sane fetch!";
2629         }
2630
2631         my @look = map { "refs/$_" } @specs;
2632         my @lcmd = (@git, qw(ls-remote -q --refs), $url, @look);
2633         debugcmd "|",@lcmd;
2634
2635         my %wantr;
2636         open GITLS, "-|", @lcmd or die $!;
2637         while (<GITLS>) {
2638             printdebug "=> ", $_;
2639             m/^(\w+)\s+(\S+)\n/ or die "ls-remote $_ ?";
2640             my ($objid,$rrefname) = ($1,$2);
2641             if (!$wanted_rref->($rrefname)) {
2642                 print STDERR <<END;
2643 warning: git ls-remote @look reported $rrefname; this is silly, ignoring it.
2644 END
2645                 next;
2646             }
2647             $wantr{$rrefname} = $objid;
2648         }
2649         $!=0; $?=0;
2650         close GITLS or failedcmd @lcmd;
2651
2652         # OK, now %want is exactly what we want for refs in @specs
2653         my @fspecs = map {
2654             !m/\*$/ && !exists $wantr{"refs/$_"} ? () :
2655             "+refs/$_:".lrfetchrefs."/$_";
2656         } @specs;
2657
2658         printdebug "git_lrfetch_sane fspecs @fspecs\n";
2659
2660         my @fcmd = (@git, qw(fetch -p -n -q), $url, @fspecs);
2661         runcmd_ordryrun_local @fcmd if @fspecs;
2662
2663         if (!$supplementary) {
2664             %lrfetchrefs_f = ();
2665         }
2666         my %objgot;
2667
2668         git_for_each_ref(lrfetchrefs, sub {
2669             my ($objid,$objtype,$lrefname,$reftail) = @_;
2670             $lrfetchrefs_f{$lrefname} = $objid;
2671             $objgot{$objid} = 1;
2672         });
2673
2674         if ($supplementary) {
2675             last;
2676         }
2677
2678         foreach my $lrefname (sort keys %lrfetchrefs_f) {
2679             my $rrefname = 'refs'.substr($lrefname, length lrfetchrefs);
2680             if (!exists $wantr{$rrefname}) {
2681                 if ($wanted_rref->($rrefname)) {
2682                     printdebug <<END;
2683 git-fetch @fspecs created $lrefname which git ls-remote @look didn't list.
2684 END
2685                 } else {
2686                     print STDERR <<END
2687 warning: git fetch @fspecs created $lrefname; this is silly, deleting it.
2688 END
2689                 }
2690                 runcmd_ordryrun_local @git, qw(update-ref -d), $lrefname;
2691                 delete $lrfetchrefs_f{$lrefname};
2692                 next;
2693             }
2694         }
2695         foreach my $rrefname (sort keys %wantr) {
2696             my $lrefname = lrfetchrefs.substr($rrefname, 4);
2697             my $got = $lrfetchrefs_f{$lrefname} // '<none>';
2698             my $want = $wantr{$rrefname};
2699             next if $got eq $want;
2700             if (!defined $objgot{$want}) {
2701                 print STDERR <<END;
2702 warning: git ls-remote suggests we want $lrefname
2703 warning:  and it should refer to $want
2704 warning:  but git fetch didn't fetch that object to any relevant ref.
2705 warning:  This may be due to a race with someone updating the server.
2706 warning:  Will try again...
2707 END
2708                 next FETCH_ITERATION;
2709             }
2710             printdebug <<END;
2711 git-fetch @fspecs made $lrefname=$got but want git ls-remote @look says $want
2712 END
2713             runcmd_ordryrun_local @git, qw(update-ref -m),
2714                 "dgit fetch git fetch fixup", $lrefname, $want;
2715             $lrfetchrefs_f{$lrefname} = $want;
2716         }
2717         last;
2718     }
2719
2720     if (defined $csuite) {
2721         printdebug "git_lrfetch_sane: tidying any old suite lrfetchrefs\n";
2722         git_for_each_ref("refs/dgit-fetch/$csuite", sub {
2723             my ($objid,$objtype,$lrefname,$reftail) = @_;
2724             next if $lrfetchrefs_f{$lrefname}; # $csuite eq $distro ?
2725             runcmd_ordryrun_local @git, qw(update-ref -d), $lrefname;
2726         });
2727     }
2728
2729     printdebug "git_lrfetch_sane: git fetch --no-insane emulation complete\n",
2730         Dumper(\%lrfetchrefs_f);
2731 }
2732
2733 sub git_fetch_us () {
2734     # Want to fetch only what we are going to use, unless
2735     # deliberately-not-ff, in which case we must fetch everything.
2736
2737     my @specs = deliberately_not_fast_forward ? qw(tags/*) :
2738         map { "tags/$_" }
2739         (quiltmode_splitbrain
2740          ? (map { $_->('*',access_nomdistro) }
2741             \&debiantag_new, \&debiantag_maintview)
2742          : debiantags('*',access_nomdistro));
2743     push @specs, server_branch($csuite);
2744     push @specs, $rewritemap;
2745     push @specs, qw(heads/*) if deliberately_not_fast_forward;
2746
2747     my $url = access_giturl();
2748     git_lrfetch_sane $url, 0, @specs;
2749
2750     my %here;
2751     my @tagpats = debiantags('*',access_nomdistro);
2752
2753     git_for_each_ref([map { "refs/tags/$_" } @tagpats], sub {
2754         my ($objid,$objtype,$fullrefname,$reftail) = @_;
2755         printdebug "currently $fullrefname=$objid\n";
2756         $here{$fullrefname} = $objid;
2757     });
2758     git_for_each_ref([map { lrfetchrefs."/tags/".$_ } @tagpats], sub {
2759         my ($objid,$objtype,$fullrefname,$reftail) = @_;
2760         my $lref = "refs".substr($fullrefname, length(lrfetchrefs));
2761         printdebug "offered $lref=$objid\n";
2762         if (!defined $here{$lref}) {
2763             my @upd = (@git, qw(update-ref), $lref, $objid, '');
2764             runcmd_ordryrun_local @upd;
2765             lrfetchref_used $fullrefname;
2766         } elsif ($here{$lref} eq $objid) {
2767             lrfetchref_used $fullrefname;
2768         } else {
2769             print STDERR
2770                 "Not updating $lref from $here{$lref} to $objid.\n";
2771         }
2772     });
2773 }
2774
2775 #---------- dsc and archive handling ----------
2776
2777 sub mergeinfo_getclogp ($) {
2778     # Ensures thit $mi->{Clogp} exists and returns it
2779     my ($mi) = @_;
2780     $mi->{Clogp} = commit_getclogp($mi->{Commit});
2781 }
2782
2783 sub mergeinfo_version ($) {
2784     return getfield( (mergeinfo_getclogp $_[0]), 'Version' );
2785 }
2786
2787 sub fetch_from_archive_record_1 ($) {
2788     my ($hash) = @_;
2789     runcmd @git, qw(update-ref -m), "dgit fetch $csuite",
2790             'DGIT_ARCHIVE', $hash;
2791     cmdoutput @git, qw(log -n2), $hash;
2792     # ... gives git a chance to complain if our commit is malformed
2793 }
2794
2795 sub fetch_from_archive_record_2 ($) {
2796     my ($hash) = @_;
2797     my @upd_cmd = (@git, qw(update-ref -m), 'dgit fetch', lrref(), $hash);
2798     if (act_local()) {
2799         cmdoutput @upd_cmd;
2800     } else {
2801         dryrun_report @upd_cmd;
2802     }
2803 }
2804
2805 sub parse_dsc_field_def_dsc_distro () {
2806     $dsc_distro //= cfg qw(dgit.default.old-dsc-distro
2807                            dgit.default.distro);
2808 }
2809
2810 sub parse_dsc_field ($$) {
2811     my ($dsc, $what) = @_;
2812     my $f;
2813     foreach my $field (@ourdscfield) {
2814         $f = $dsc->{$field};
2815         last if defined $f;
2816     }
2817
2818     if (!defined $f) {
2819         progress "$what: NO git hash";
2820         parse_dsc_field_def_dsc_distro();
2821     } elsif (($dsc_hash, $dsc_distro, $dsc_hint_tag, $dsc_hint_url)
2822              = $f =~ m/^(\w+)\s+($distro_re)\s+($versiontag_re)\s+(\S+)(?:\s|$)/) {
2823         progress "$what: specified git info ($dsc_distro)";
2824         $dsc_hint_tag = [ $dsc_hint_tag ];
2825     } elsif ($f =~ m/^\w+\s*$/) {
2826         $dsc_hash = $&;
2827         parse_dsc_field_def_dsc_distro();
2828         $dsc_hint_tag = [ debiantags +(getfield $dsc, 'Version'),
2829                           $dsc_distro ];
2830         progress "$what: specified git hash";
2831     } else {
2832         fail "$what: invalid Dgit info";
2833     }
2834 }
2835
2836 sub resolve_dsc_field_commit ($$) {
2837     my ($already_distro, $already_mapref) = @_;
2838
2839     return unless defined $dsc_hash;
2840
2841     my $mapref =
2842         defined $already_mapref &&
2843         ($already_distro eq $dsc_distro || !$chase_dsc_distro)
2844         ? $already_mapref : undef;
2845
2846     my $do_fetch;
2847     $do_fetch = sub {
2848         my ($what, @fetch) = @_;
2849
2850         local $idistro = $dsc_distro;
2851         my $lrf = lrfetchrefs;
2852
2853         if (!$chase_dsc_distro) {
2854             progress
2855                 "not chasing .dsc distro $dsc_distro: not fetching $what";
2856             return 0;
2857         }
2858
2859         progress
2860             ".dsc names distro $dsc_distro: fetching $what";
2861
2862         my $url = access_giturl();
2863         if (!defined $url) {
2864             defined $dsc_hint_url or fail <<END;
2865 .dsc Dgit metadata is in context of distro $dsc_distro
2866 for which we have no configured url and .dsc provides no hint
2867 END
2868             my $proto =
2869                 $dsc_hint_url =~ m#^([-+0-9a-zA-Z]+):# ? $1 :
2870                 $dsc_hint_url =~ m#^/# ? 'file' : 'bad-syntax';
2871             parse_cfg_bool "dsc-url-proto-ok", 'false',
2872                 cfg("dgit.dsc-url-proto-ok.$proto",
2873                     "dgit.default.dsc-url-proto-ok")
2874                 or fail <<END;
2875 .dsc Dgit metadata is in context of distro $dsc_distro
2876 for which we have no configured url;
2877 .dsc provides hinted url with protocol $proto which is unsafe.
2878 (can be overridden by config - consult documentation)
2879 END
2880             $url = $dsc_hint_url;
2881         }
2882
2883         git_lrfetch_sane $url, 1, @fetch;
2884
2885         return $lrf;
2886     };
2887
2888     my $rewrite_enable = do {
2889         local $idistro = $dsc_distro;
2890         access_cfg('rewrite-map-enable', 'RETURN-UNDEF');
2891     };
2892
2893     if (parse_cfg_bool 'rewrite-map-enable', 'true', $rewrite_enable) {
2894         if (!defined $mapref) {
2895             my $lrf = $do_fetch->("rewrite map", $rewritemap) or return;
2896             $mapref = $lrf.'/'.$rewritemap;
2897         }
2898         my $rewritemapdata = git_cat_file $mapref.':map';
2899         if (defined $rewritemapdata
2900             && $rewritemapdata =~ m/^$dsc_hash(?:[ \t](\w+))/m) {
2901             progress
2902                 "server's git history rewrite map contains a relevant entry!";
2903
2904             $dsc_hash = $1;
2905             if (defined $dsc_hash) {
2906                 progress "using rewritten git hash in place of .dsc value";
2907             } else {
2908                 progress "server data says .dsc hash is to be disregarded";
2909             }
2910         }
2911     }
2912
2913     if (!defined git_cat_file $dsc_hash) {
2914         my @tags = map { "tags/".$_ } @$dsc_hint_tag;
2915         my $lrf = $do_fetch->("additional commits", @tags) &&
2916             defined git_cat_file $dsc_hash
2917             or fail <<END;
2918 .dsc Dgit metadata requires commit $dsc_hash
2919 but we could not obtain that object anywhere.
2920 END
2921         foreach my $t (@tags) {
2922             my $fullrefname = $lrf.'/'.$t;
2923 #           print STDERR "CHK $t $fullrefname ".Dumper(\%lrfetchrefs_f);
2924             next unless $lrfetchrefs_f{$fullrefname};
2925             next unless is_fast_fwd "$fullrefname~0", $dsc_hash;
2926             lrfetchref_used $fullrefname;
2927         }
2928     }
2929 }
2930
2931 sub fetch_from_archive () {
2932     ensure_setup_existing_tree();
2933
2934     # Ensures that lrref() is what is actually in the archive, one way
2935     # or another, according to us - ie this client's
2936     # appropritaely-updated archive view.  Also returns the commit id.
2937     # If there is nothing in the archive, leaves lrref alone and
2938     # returns undef.  git_fetch_us must have already been called.
2939     get_archive_dsc();
2940
2941     if ($dsc) {
2942         parse_dsc_field($dsc, 'last upload to archive');
2943         resolve_dsc_field_commit access_basedistro,
2944             lrfetchrefs."/".$rewritemap
2945     } else {
2946         progress "no version available from the archive";
2947     }
2948
2949     # If the archive's .dsc has a Dgit field, there are three
2950     # relevant git commitids we need to choose between and/or merge
2951     # together:
2952     #   1. $dsc_hash: the Dgit field from the archive
2953     #   2. $lastpush_hash: the suite branch on the dgit git server
2954     #   3. $lastfetch_hash: our local tracking brach for the suite
2955     #
2956     # These may all be distinct and need not be in any fast forward
2957     # relationship:
2958     #
2959     # If the dsc was pushed to this suite, then the server suite
2960     # branch will have been updated; but it might have been pushed to
2961     # a different suite and copied by the archive.  Conversely a more
2962     # recent version may have been pushed with dgit but not appeared
2963     # in the archive (yet).
2964     #
2965     # $lastfetch_hash may be awkward because archive imports
2966     # (particularly, imports of Dgit-less .dscs) are performed only as
2967     # needed on individual clients, so different clients may perform a
2968     # different subset of them - and these imports are only made
2969     # public during push.  So $lastfetch_hash may represent a set of
2970     # imports different to a subsequent upload by a different dgit
2971     # client.
2972     #
2973     # Our approach is as follows:
2974     #
2975     # As between $dsc_hash and $lastpush_hash: if $lastpush_hash is a
2976     # descendant of $dsc_hash, then it was pushed by a dgit user who
2977     # had based their work on $dsc_hash, so we should prefer it.
2978     # Otherwise, $dsc_hash was installed into this suite in the
2979     # archive other than by a dgit push, and (necessarily) after the
2980     # last dgit push into that suite (since a dgit push would have
2981     # been descended from the dgit server git branch); thus, in that
2982     # case, we prefer the archive's version (and produce a
2983     # pseudo-merge to overwrite the dgit server git branch).
2984     #
2985     # (If there is no Dgit field in the archive's .dsc then
2986     # generate_commit_from_dsc uses the version numbers to decide
2987     # whether the suite branch or the archive is newer.  If the suite
2988     # branch is newer it ignores the archive's .dsc; otherwise it
2989     # generates an import of the .dsc, and produces a pseudo-merge to
2990     # overwrite the suite branch with the archive contents.)
2991     #
2992     # The outcome of that part of the algorithm is the `public view',
2993     # and is same for all dgit clients: it does not depend on any
2994     # unpublished history in the local tracking branch.
2995     #
2996     # As between the public view and the local tracking branch: The
2997     # local tracking branch is only updated by dgit fetch, and
2998     # whenever dgit fetch runs it includes the public view in the
2999     # local tracking branch.  Therefore if the public view is not
3000     # descended from the local tracking branch, the local tracking
3001     # branch must contain history which was imported from the archive
3002     # but never pushed; and, its tip is now out of date.  So, we make
3003     # a pseudo-merge to overwrite the old imports and stitch the old
3004     # history in.
3005     #
3006     # Finally: we do not necessarily reify the public view (as
3007     # described above).  This is so that we do not end up stacking two
3008     # pseudo-merges.  So what we actually do is figure out the inputs
3009     # to any public view pseudo-merge and put them in @mergeinputs.
3010
3011     my @mergeinputs;
3012     # $mergeinputs[]{Commit}
3013     # $mergeinputs[]{Info}
3014     # $mergeinputs[0] is the one whose tree we use
3015     # @mergeinputs is in the order we use in the actual commit)
3016     #
3017     # Also:
3018     # $mergeinputs[]{Message} is a commit message to use
3019     # $mergeinputs[]{ReverseParents} if def specifies that parent
3020     #                                list should be in opposite order
3021     # Such an entry has no Commit or Info.  It applies only when found
3022     # in the last entry.  (This ugliness is to support making
3023     # identical imports to previous dgit versions.)
3024
3025     my $lastpush_hash = git_get_ref(lrfetchref());
3026     printdebug "previous reference hash=$lastpush_hash\n";
3027     $lastpush_mergeinput = $lastpush_hash && {
3028         Commit => $lastpush_hash,
3029         Info => "dgit suite branch on dgit git server",
3030     };
3031
3032     my $lastfetch_hash = git_get_ref(lrref());
3033     printdebug "fetch_from_archive: lastfetch=$lastfetch_hash\n";
3034     my $lastfetch_mergeinput = $lastfetch_hash && {
3035         Commit => $lastfetch_hash,
3036         Info => "dgit client's archive history view",
3037     };
3038
3039     my $dsc_mergeinput = $dsc_hash && {
3040         Commit => $dsc_hash,
3041         Info => "Dgit field in .dsc from archive",
3042     };
3043
3044     my $cwd = getcwd();
3045     my $del_lrfetchrefs = sub {
3046         changedir $cwd;
3047         my $gur;
3048         printdebug "del_lrfetchrefs...\n";
3049         foreach my $fullrefname (sort keys %lrfetchrefs_d) {
3050             my $objid = $lrfetchrefs_d{$fullrefname};
3051             printdebug "del_lrfetchrefs: $objid $fullrefname\n";
3052             if (!$gur) {
3053                 $gur ||= new IO::Handle;
3054                 open $gur, "|-", qw(git update-ref --stdin) or die $!;
3055             }
3056             printf $gur "delete %s %s\n", $fullrefname, $objid;
3057         }
3058         if ($gur) {
3059             close $gur or failedcmd "git update-ref delete lrfetchrefs";
3060         }
3061     };
3062
3063     if (defined $dsc_hash) {
3064         ensure_we_have_orig();
3065         if (!$lastpush_hash || $dsc_hash eq $lastpush_hash) {
3066             @mergeinputs = $dsc_mergeinput
3067         } elsif (is_fast_fwd($dsc_hash,$lastpush_hash)) {
3068             print STDERR <<END or die $!;
3069
3070 Git commit in archive is behind the last version allegedly pushed/uploaded.
3071 Commit referred to by archive: $dsc_hash
3072 Last version pushed with dgit: $lastpush_hash
3073 $later_warning_msg
3074 END
3075             @mergeinputs = ($lastpush_mergeinput);
3076         } else {
3077             # Archive has .dsc which is not a descendant of the last dgit
3078             # push.  This can happen if the archive moves .dscs about.
3079             # Just follow its lead.
3080             if (is_fast_fwd($lastpush_hash,$dsc_hash)) {
3081                 progress "archive .dsc names newer git commit";
3082                 @mergeinputs = ($dsc_mergeinput);
3083             } else {
3084                 progress "archive .dsc names other git commit, fixing up";
3085                 @mergeinputs = ($dsc_mergeinput, $lastpush_mergeinput);
3086             }
3087         }
3088     } elsif ($dsc) {
3089         @mergeinputs = generate_commits_from_dsc();
3090         # We have just done an import.  Now, our import algorithm might
3091         # have been improved.  But even so we do not want to generate
3092         # a new different import of the same package.  So if the
3093         # version numbers are the same, just use our existing version.
3094         # If the version numbers are different, the archive has changed
3095         # (perhaps, rewound).
3096         if ($lastfetch_mergeinput &&
3097             !version_compare( (mergeinfo_version $lastfetch_mergeinput),
3098                               (mergeinfo_version $mergeinputs[0]) )) {
3099             @mergeinputs = ($lastfetch_mergeinput);
3100         }
3101     } elsif ($lastpush_hash) {
3102         # only in git, not in the archive yet
3103         @mergeinputs = ($lastpush_mergeinput);
3104         print STDERR <<END or die $!;
3105
3106 Package not found in the archive, but has allegedly been pushed using dgit.
3107 $later_warning_msg
3108 END
3109     } else {
3110         printdebug "nothing found!\n";
3111         if (defined $skew_warning_vsn) {
3112             print STDERR <<END or die $!;
3113
3114 Warning: relevant archive skew detected.
3115 Archive allegedly contains $skew_warning_vsn
3116 But we were not able to obtain any version from the archive or git.
3117
3118 END
3119         }
3120         unshift @end, $del_lrfetchrefs;
3121         return undef;
3122     }
3123
3124     if ($lastfetch_hash &&
3125         !grep {
3126             my $h = $_->{Commit};
3127             $h and is_fast_fwd($lastfetch_hash, $h);
3128             # If true, one of the existing parents of this commit
3129             # is a descendant of the $lastfetch_hash, so we'll
3130             # be ff from that automatically.
3131         } @mergeinputs
3132         ) {
3133         # Otherwise:
3134         push @mergeinputs, $lastfetch_mergeinput;
3135     }
3136
3137     printdebug "fetch mergeinfos:\n";
3138     foreach my $mi (@mergeinputs) {
3139         if ($mi->{Info}) {
3140             printdebug " commit $mi->{Commit} $mi->{Info}\n";
3141         } else {
3142             printdebug sprintf " ReverseParents=%d Message=%s",
3143                 $mi->{ReverseParents}, $mi->{Message};
3144         }
3145     }
3146
3147     my $compat_info= pop @mergeinputs
3148         if $mergeinputs[$#mergeinputs]{Message};
3149
3150     @mergeinputs = grep { defined $_->{Commit} } @mergeinputs;
3151
3152     my $hash;
3153     if (@mergeinputs > 1) {
3154         # here we go, then:
3155         my $tree_commit = $mergeinputs[0]{Commit};
3156
3157         my $tree = cmdoutput @git, qw(cat-file commit), $tree_commit;
3158         $tree =~ m/\n\n/;  $tree = $`;
3159         $tree =~ m/^tree (\w+)$/m or die "$dsc_hash tree ?";
3160         $tree = $1;
3161
3162         # We use the changelog author of the package in question the
3163         # author of this pseudo-merge.  This is (roughly) correct if
3164         # this commit is simply representing aa non-dgit upload.
3165         # (Roughly because it does not record sponsorship - but we
3166         # don't have sponsorship info because that's in the .changes,
3167         # which isn't in the archivw.)
3168         #
3169         # But, it might be that we are representing archive history
3170         # updates (including in-archive copies).  These are not really
3171         # the responsibility of the person who created the .dsc, but
3172         # there is no-one whose name we should better use.  (The
3173         # author of the .dsc-named commit is clearly worse.)
3174
3175         my $useclogp = mergeinfo_getclogp $mergeinputs[0];
3176         my $author = clogp_authline $useclogp;
3177         my $cversion = getfield $useclogp, 'Version';
3178
3179         my $mcf = ".git/dgit/mergecommit";
3180         open MC, ">", $mcf or die "$mcf $!";
3181         print MC <<END or die $!;
3182 tree $tree
3183 END
3184
3185         my @parents = grep { $_->{Commit} } @mergeinputs;
3186         @parents = reverse @parents if $compat_info->{ReverseParents};
3187         print MC <<END or die $! foreach @parents;
3188 parent $_->{Commit}
3189 END
3190
3191         print MC <<END or die $!;
3192 author $author
3193 committer $author
3194
3195 END
3196
3197         if (defined $compat_info->{Message}) {
3198             print MC $compat_info->{Message} or die $!;
3199         } else {
3200             print MC <<END or die $!;
3201 Record $package ($cversion) in archive suite $csuite
3202
3203 Record that
3204 END
3205             my $message_add_info = sub {
3206                 my ($mi) = (@_);
3207                 my $mversion = mergeinfo_version $mi;
3208                 printf MC "  %-20s %s\n", $mversion, $mi->{Info}
3209                     or die $!;
3210             };
3211
3212             $message_add_info->($mergeinputs[0]);
3213             print MC <<END or die $!;
3214 should be treated as descended from
3215 END
3216             $message_add_info->($_) foreach @mergeinputs[1..$#mergeinputs];
3217         }
3218
3219         close MC or die $!;
3220         $hash = make_commit $mcf;
3221     } else {
3222         $hash = $mergeinputs[0]{Commit};
3223     }
3224     printdebug "fetch hash=$hash\n";
3225
3226     my $chkff = sub {
3227         my ($lasth, $what) = @_;
3228         return unless $lasth;
3229         die "$lasth $hash $what ?" unless is_fast_fwd($lasth, $hash);
3230     };
3231
3232     $chkff->($lastpush_hash, 'dgit repo server tip (last push)')
3233         if $lastpush_hash;
3234     $chkff->($lastfetch_hash, 'local tracking tip (last fetch)');
3235
3236     fetch_from_archive_record_1($hash);
3237
3238     if (defined $skew_warning_vsn) {
3239         mkpath '.git/dgit';
3240         printdebug "SKEW CHECK WANT $skew_warning_vsn\n";
3241         my $gotclogp = commit_getclogp($hash);
3242         my $got_vsn = getfield $gotclogp, 'Version';
3243         printdebug "SKEW CHECK GOT $got_vsn\n";
3244         if (version_compare($got_vsn, $skew_warning_vsn) < 0) {
3245             print STDERR <<END or die $!;
3246
3247 Warning: archive skew detected.  Using the available version:
3248 Archive allegedly contains    $skew_warning_vsn
3249 We were able to obtain only   $got_vsn
3250
3251 END
3252         }
3253     }
3254
3255     if ($lastfetch_hash ne $hash) {
3256         fetch_from_archive_record_2($hash);
3257     }
3258
3259     lrfetchref_used lrfetchref();
3260
3261     check_gitattrs($hash, "fetched source tree");
3262
3263     unshift @end, $del_lrfetchrefs;
3264     return $hash;
3265 }
3266
3267 sub set_local_git_config ($$) {
3268     my ($k, $v) = @_;
3269     runcmd @git, qw(config), $k, $v;
3270 }
3271
3272 sub setup_mergechangelogs (;$) {
3273     my ($always) = @_;
3274     return unless $always || access_cfg_bool(1, 'setup-mergechangelogs');
3275
3276     my $driver = 'dpkg-mergechangelogs';
3277     my $cb = "merge.$driver";
3278     my $attrs = '.git/info/attributes';
3279     ensuredir '.git/info';
3280
3281     open NATTRS, ">", "$attrs.new" or die "$attrs.new $!";
3282     if (!open ATTRS, "<", $attrs) {
3283         $!==ENOENT or die "$attrs: $!";
3284     } else {
3285         while (<ATTRS>) {
3286             chomp;
3287             next if m{^debian/changelog\s};
3288             print NATTRS $_, "\n" or die $!;
3289         }
3290         ATTRS->error and die $!;
3291         close ATTRS;
3292     }
3293     print NATTRS "debian/changelog merge=$driver\n" or die $!;
3294     close NATTRS;
3295
3296     set_local_git_config "$cb.name", 'debian/changelog merge driver';
3297     set_local_git_config "$cb.driver", 'dpkg-mergechangelogs -m %O %A %B %A';
3298
3299     rename "$attrs.new", "$attrs" or die "$attrs: $!";
3300 }
3301
3302 sub setup_useremail (;$) {
3303     my ($always) = @_;
3304     return unless $always || access_cfg_bool(1, 'setup-useremail');
3305
3306     my $setup = sub {
3307         my ($k, $envvar) = @_;
3308         my $v = access_cfg("user-$k", 'RETURN-UNDEF') // $ENV{$envvar};
3309         return unless defined $v;
3310         set_local_git_config "user.$k", $v;
3311     };
3312
3313     $setup->('email', 'DEBEMAIL');
3314     $setup->('name', 'DEBFULLNAME');
3315 }
3316
3317 sub ensure_setup_existing_tree () {
3318     my $k = "remote.$remotename.skipdefaultupdate";
3319     my $c = git_get_config $k;
3320     return if defined $c;
3321     set_local_git_config $k, 'true';
3322 }
3323
3324 sub open_gitattrs () {
3325     my $gai = new IO::File ".git/info/attributes"
3326         or $!==ENOENT
3327         or die "open .git/info/attributes: $!";
3328     return $gai;
3329 }
3330
3331 sub is_gitattrs_setup () {
3332     my $gai = open_gitattrs();
3333     return 0 unless $gai;
3334     while (<$gai>) {
3335         return 1 if m{^\[attr\]dgit-defuse-attrs\s};
3336     }
3337     $gai->error and die $!;
3338     return 0;
3339 }
3340
3341 sub setup_gitattrs (;$) {
3342     my ($always) = @_;
3343     return unless $always || access_cfg_bool(1, 'setup-gitattributes');
3344
3345     if (is_gitattrs_setup()) {
3346         progress <<END;
3347 [attr]dgit-defuse-attrs already found in .git/info/attributes
3348  not doing further gitattributes setup
3349 END
3350         return;
3351     }
3352     my $af = ".git/info/attributes";
3353     open GAO, "> $af.new" or die $!;
3354     print GAO <<END or die $!;
3355 *       dgit-defuse-attrs
3356 [attr]dgit-defuse-attrs -text -eol -crlf -ident -filter
3357 # ^ see GITATTRIBUTES in dgit(7) and dgit setup-new-tree in dgit(1)
3358 END
3359     my $gai = open_gitattrs();
3360     if ($gai) {
3361         while (<$gai>) {
3362             chomp;
3363             print GAO $_, "\n" or die $!;
3364         }
3365         $gai->error and die $!;
3366     }
3367     close GAO or die $!;
3368     rename "$af.new", "$af" or die "install $af: $!";
3369 }
3370
3371 sub setup_new_tree () {
3372     setup_mergechangelogs();
3373     setup_useremail();
3374     setup_gitattrs();
3375 }
3376
3377 sub check_gitattrs ($$) {
3378     my ($treeish, $what) = @_;
3379
3380     return if is_gitattrs_setup;
3381
3382     local $/="\0";
3383     my @cmd = (@git, qw(ls-tree -lrz --), "${treeish}:");
3384     debugcmd "|",@cmd;
3385     my $gafl = new IO::File;
3386     open $gafl, "-|", @cmd or die $!;
3387     while (<$gafl>) {
3388         chomp or die;
3389         s/^\d+\s+\w+\s+\w+\s+(\d+)\t// or die;
3390         next if $1 == 0;
3391         next unless m{(?:^|/)\.gitattributes$};
3392
3393         # oh dear, found one
3394         print STDERR <<END;
3395 dgit: warning: $what contains .gitattributes
3396 dgit: .gitattributes have not been defused.  Recommended: dgit setup-new-tree.
3397 END
3398         close $gafl;
3399         return;
3400     }
3401     # tree contains no .gitattributes files
3402     $?=0; $!=0; close $gafl or failedcmd @cmd;
3403 }
3404
3405
3406 sub multisuite_suite_child ($$$) {
3407     my ($tsuite, $merginputs, $fn) = @_;
3408     # in child, sets things up, calls $fn->(), and returns undef
3409     # in parent, returns canonical suite name for $tsuite
3410     my $canonsuitefh = IO::File::new_tmpfile;
3411     my $pid = fork // die $!;
3412     if (!$pid) {
3413         forkcheck_setup();
3414         $isuite = $tsuite;
3415         $us .= " [$isuite]";
3416         $debugprefix .= " ";
3417         progress "fetching $tsuite...";
3418         canonicalise_suite();
3419         print $canonsuitefh $csuite, "\n" or die $!;
3420         close $canonsuitefh or die $!;
3421         $fn->();
3422         return undef;
3423     }
3424     waitpid $pid,0 == $pid or die $!;
3425     fail "failed to obtain $tsuite: ".waitstatusmsg() if $? && $?!=256*4;
3426     seek $canonsuitefh,0,0 or die $!;
3427     local $csuite = <$canonsuitefh>;
3428     die $! unless defined $csuite && chomp $csuite;
3429     if ($? == 256*4) {
3430         printdebug "multisuite $tsuite missing\n";
3431         return $csuite;
3432     }
3433     printdebug "multisuite $tsuite ok (canon=$csuite)\n";
3434     push @$merginputs, {
3435         Ref => lrref,
3436         Info => $csuite,
3437     };
3438     return $csuite;
3439 }
3440
3441 sub fork_for_multisuite ($) {
3442     my ($before_fetch_merge) = @_;
3443     # if nothing unusual, just returns ''
3444     #
3445     # if multisuite:
3446     # returns 0 to caller in child, to do first of the specified suites
3447     # in child, $csuite is not yet set
3448     #
3449     # returns 1 to caller in parent, to finish up anything needed after
3450     # in parent, $csuite is set to canonicalised portmanteau
3451
3452     my $org_isuite = $isuite;
3453     my @suites = split /\,/, $isuite;
3454     return '' unless @suites > 1;
3455     printdebug "fork_for_multisuite: @suites\n";
3456
3457     my @mergeinputs;
3458
3459     my $cbasesuite = multisuite_suite_child($suites[0], \@mergeinputs,
3460                                             sub { });
3461     return 0 unless defined $cbasesuite;
3462
3463     fail "package $package missing in (base suite) $cbasesuite"
3464         unless @mergeinputs;
3465
3466     my @csuites = ($cbasesuite);
3467
3468     $before_fetch_merge->();
3469
3470     foreach my $tsuite (@suites[1..$#suites]) {
3471         my $csubsuite = multisuite_suite_child($tsuite, \@mergeinputs,
3472                                                sub {
3473             @end = ();
3474             fetch();
3475             exit 0;
3476         });
3477         # xxx collecte the ref here
3478
3479         $csubsuite =~ s/^\Q$cbasesuite\E-/-/;
3480         push @csuites, $csubsuite;
3481     }
3482
3483     foreach my $mi (@mergeinputs) {
3484         my $ref = git_get_ref $mi->{Ref};
3485         die "$mi->{Ref} ?" unless length $ref;
3486         $mi->{Commit} = $ref;
3487     }
3488
3489     $csuite = join ",", @csuites;
3490
3491     my $previous = git_get_ref lrref;
3492     if ($previous) {
3493         unshift @mergeinputs, {
3494             Commit => $previous,
3495             Info => "local combined tracking branch",
3496             Warning =>
3497  "archive seems to have rewound: local tracking branch is ahead!",
3498         };
3499     }
3500
3501     foreach my $ix (0..$#mergeinputs) {
3502         $mergeinputs[$ix]{Index} = $ix;
3503     }
3504
3505     @mergeinputs = sort {
3506         -version_compare(mergeinfo_version $a,
3507                          mergeinfo_version $b) # highest version first
3508             or
3509         $a->{Index} <=> $b->{Index}; # earliest in spec first
3510     } @mergeinputs;
3511
3512     my @needed;
3513
3514   NEEDED:
3515     foreach my $mi (@mergeinputs) {
3516         printdebug "multisuite merge check $mi->{Info}\n";
3517         foreach my $previous (@needed) {
3518             next unless is_fast_fwd $mi->{Commit}, $previous->{Commit};
3519             printdebug "multisuite merge un-needed $previous->{Info}\n";
3520             next NEEDED;
3521         }
3522         push @needed, $mi;
3523         printdebug "multisuite merge this-needed\n";
3524         $mi->{Character} = '+';
3525     }
3526
3527     $needed[0]{Character} = '*';
3528
3529     my $output = $needed[0]{Commit};
3530
3531     if (@needed > 1) {
3532         printdebug "multisuite merge nontrivial\n";
3533         my $tree = cmdoutput qw(git rev-parse), $needed[0]{Commit}.':';
3534
3535         my $commit = "tree $tree\n";
3536         my $msg = "Combine archive branches $csuite [dgit]\n\n".
3537             "Input branches:\n";
3538
3539         foreach my $mi (sort { $a->{Index} <=> $b->{Index} } @mergeinputs) {
3540             printdebug "multisuite merge include $mi->{Info}\n";
3541             $mi->{Character} //= ' ';
3542             $commit .= "parent $mi->{Commit}\n";
3543             $msg .= sprintf " %s  %-25s %s\n",
3544                 $mi->{Character},
3545                 (mergeinfo_version $mi),
3546                 $mi->{Info};
3547         }
3548         my $authline = clogp_authline mergeinfo_getclogp $needed[0];
3549         $msg .= "\nKey\n".
3550             " * marks the highest version branch, which choose to use\n".
3551             " + marks each branch which was not already an ancestor\n\n".
3552             "[dgit multi-suite $csuite]\n";
3553         $commit .=
3554             "author $authline\n".
3555             "committer $authline\n\n";
3556         $output = make_commit_text $commit.$msg;
3557         printdebug "multisuite merge generated $output\n";
3558     }
3559
3560     fetch_from_archive_record_1($output);
3561     fetch_from_archive_record_2($output);
3562
3563     progress "calculated combined tracking suite $csuite";
3564
3565     return 1;
3566 }
3567
3568 sub clone_set_head () {
3569     open H, "> .git/HEAD" or die $!;
3570     print H "ref: ".lref()."\n" or die $!;
3571     close H or die $!;
3572 }
3573 sub clone_finish ($) {
3574     my ($dstdir) = @_;
3575     runcmd @git, qw(reset --hard), lrref();
3576     runcmd qw(bash -ec), <<'END';
3577         set -o pipefail
3578         git ls-tree -r --name-only -z HEAD | \
3579         xargs -0r touch -h -r . --
3580 END
3581     printdone "ready for work in $dstdir";
3582 }
3583
3584 sub clone ($) {
3585     my ($dstdir) = @_;
3586     badusage "dry run makes no sense with clone" unless act_local();
3587
3588     my $multi_fetched = fork_for_multisuite(sub {
3589         printdebug "multi clone before fetch merge\n";
3590         changedir $dstdir;
3591     });
3592     if ($multi_fetched) {
3593         printdebug "multi clone after fetch merge\n";
3594         clone_set_head();
3595         clone_finish($dstdir);
3596         exit 0;
3597     }
3598     printdebug "clone main body\n";
3599
3600     canonicalise_suite();
3601     my $hasgit = check_for_git();
3602     mkdir $dstdir or fail "create \`$dstdir': $!";
3603     changedir $dstdir;
3604     runcmd @git, qw(init -q);
3605     setup_new_tree();
3606     clone_set_head();
3607     my $giturl = access_giturl(1);
3608     if (defined $giturl) {
3609         runcmd @git, qw(remote add), 'origin', $giturl;
3610     }
3611     if ($hasgit) {
3612         progress "fetching existing git history";
3613         git_fetch_us();
3614         runcmd_ordryrun_local @git, qw(fetch origin);
3615     } else {
3616         progress "starting new git history";
3617     }
3618     fetch_from_archive() or no_such_package;
3619     my $vcsgiturl = $dsc->{'Vcs-Git'};
3620     if (length $vcsgiturl) {
3621         $vcsgiturl =~ s/\s+-b\s+\S+//g;
3622         runcmd @git, qw(remote add vcs-git), $vcsgiturl;
3623     }
3624     clone_finish($dstdir);
3625 }
3626
3627 sub fetch () {
3628     canonicalise_suite();
3629     if (check_for_git()) {
3630         git_fetch_us();
3631     }
3632     fetch_from_archive() or no_such_package();
3633     printdone "fetched into ".lrref();
3634 }
3635
3636 sub pull () {
3637     my $multi_fetched = fork_for_multisuite(sub { });
3638     fetch() unless $multi_fetched; # parent
3639     return if $multi_fetched eq '0'; # child
3640     runcmd_ordryrun_local @git, qw(merge -m),"Merge from $csuite [dgit]",
3641         lrref();
3642     printdone "fetched to ".lrref()." and merged into HEAD";
3643 }
3644
3645 sub check_not_dirty () {
3646     foreach my $f (qw(local-options local-patch-header)) {
3647         if (stat_exists "debian/source/$f") {
3648             fail "git tree contains debian/source/$f";
3649         }
3650     }
3651
3652     return if $ignoredirty;
3653
3654     my @cmd = (@git, qw(diff --quiet HEAD));
3655     debugcmd "+",@cmd;
3656     $!=0; $?=-1; system @cmd;
3657     return if !$?;
3658     if ($?==256) {
3659         fail "working tree is dirty (does not match HEAD)";
3660     } else {
3661         failedcmd @cmd;
3662     }
3663 }
3664
3665 sub commit_admin ($) {
3666     my ($m) = @_;
3667     progress "$m";
3668     runcmd_ordryrun_local @git, qw(commit -m), $m;
3669 }
3670
3671 sub commit_quilty_patch () {
3672     my $output = cmdoutput @git, qw(status --porcelain);
3673     my %adds;
3674     foreach my $l (split /\n/, $output) {
3675         next unless $l =~ m/\S/;
3676         if ($l =~ m{^(?:\?\?| M) (.pc|debian/patches)}) {
3677             $adds{$1}++;
3678         }
3679     }
3680     delete $adds{'.pc'}; # if there wasn't one before, don't add it
3681     if (!%adds) {
3682         progress "nothing quilty to commit, ok.";
3683         return;
3684     }
3685     my @adds = map { s/[][*?\\]/\\$&/g; $_; } sort keys %adds;
3686     runcmd_ordryrun_local @git, qw(add -f), @adds;
3687     commit_admin <<END
3688 Commit Debian 3.0 (quilt) metadata
3689
3690 [dgit ($our_version) quilt-fixup]
3691 END
3692 }
3693
3694 sub get_source_format () {
3695     my %options;
3696     if (open F, "debian/source/options") {
3697         while (<F>) {
3698             next if m/^\s*\#/;
3699             next unless m/\S/;
3700             s/\s+$//; # ignore missing final newline
3701             if (m/\s*\#\s*/) {
3702                 my ($k, $v) = ($`, $'); #');
3703                 $v =~ s/^"(.*)"$/$1/;
3704                 $options{$k} = $v;
3705             } else {
3706                 $options{$_} = 1;
3707             }
3708         }
3709         F->error and die $!;
3710         close F;
3711     } else {
3712         die $! unless $!==&ENOENT;
3713     }
3714
3715     if (!open F, "debian/source/format") {
3716         die $! unless $!==&ENOENT;
3717         return '';
3718     }
3719     $_ = <F>;
3720     F->error and die $!;
3721     chomp;
3722     return ($_, \%options);
3723 }
3724
3725 sub madformat_wantfixup ($) {
3726     my ($format) = @_;
3727     return 0 unless $format eq '3.0 (quilt)';
3728     our $quilt_mode_warned;
3729     if ($quilt_mode eq 'nocheck') {
3730         progress "Not doing any fixup of \`$format' due to".
3731             " ----no-quilt-fixup or --quilt=nocheck"
3732             unless $quilt_mode_warned++;
3733         return 0;
3734     }
3735     progress "Format \`$format', need to check/update patch stack"
3736         unless $quilt_mode_warned++;
3737     return 1;
3738 }
3739
3740 sub maybe_split_brain_save ($$$) {
3741     my ($headref, $dgitview, $msg) = @_;
3742     # => message fragment "$saved" describing disposition of $dgitview
3743     return "commit id $dgitview" unless defined $split_brain_save;
3744     my @cmd = (shell_cmd "cd ../../../..",
3745                @git, qw(update-ref -m),
3746                "dgit --dgit-view-save $msg HEAD=$headref",
3747                $split_brain_save, $dgitview);
3748     runcmd @cmd;
3749     return "and left in $split_brain_save";
3750 }
3751
3752 # An "infopair" is a tuple [ $thing, $what ]
3753 # (often $thing is a commit hash; $what is a description)
3754
3755 sub infopair_cond_equal ($$) {
3756     my ($x,$y) = @_;
3757     $x->[0] eq $y->[0] or fail <<END;
3758 $x->[1] ($x->[0]) not equal to $y->[1] ($y->[0])
3759 END
3760 };
3761
3762 sub infopair_lrf_tag_lookup ($$) {
3763     my ($tagnames, $what) = @_;
3764     # $tagname may be an array ref
3765     my @tagnames = ref $tagnames ? @$tagnames : ($tagnames);
3766     printdebug "infopair_lrfetchref_tag_lookup $what @tagnames\n";
3767     foreach my $tagname (@tagnames) {
3768         my $lrefname = lrfetchrefs."/tags/$tagname";
3769         my $tagobj = $lrfetchrefs_f{$lrefname};
3770         next unless defined $tagobj;
3771         printdebug "infopair_lrfetchref_tag_lookup $tagobj $tagname $what\n";
3772         return [ git_rev_parse($tagobj), $what ];
3773     }
3774     fail @tagnames==1 ? <<END : <<END;
3775 Wanted tag $what (@tagnames) on dgit server, but not found
3776 END
3777 Wanted tag $what (one of: @tagnames) on dgit server, but not found
3778 END
3779 }
3780
3781 sub infopair_cond_ff ($$) {
3782     my ($anc,$desc) = @_;
3783     is_fast_fwd($anc->[0], $desc->[0]) or fail <<END;
3784 $anc->[1] ($anc->[0]) .. $desc->[1] ($desc->[0]) is not fast forward
3785 END
3786 };
3787
3788 sub pseudomerge_version_check ($$) {
3789     my ($clogp, $archive_hash) = @_;
3790
3791     my $arch_clogp = commit_getclogp $archive_hash;
3792     my $i_arch_v = [ (getfield $arch_clogp, 'Version'),
3793                      'version currently in archive' ];
3794     if (defined $overwrite_version) {
3795         if (length $overwrite_version) {
3796             infopair_cond_equal([ $overwrite_version,
3797                                   '--overwrite= version' ],
3798                                 $i_arch_v);
3799         } else {
3800             my $v = $i_arch_v->[0];
3801             progress "Checking package changelog for archive version $v ...";
3802             eval {
3803                 my @xa = ("-f$v", "-t$v");
3804                 my $vclogp = parsechangelog @xa;
3805                 my $gf = sub {
3806                     my ($fn) = @_;
3807                     [ (getfield $vclogp, $fn),
3808                       "$fn field from dpkg-parsechangelog @xa" ];
3809                 };
3810                 my $cv = $gf->('Version');
3811                 infopair_cond_equal($i_arch_v, $cv);
3812             };
3813             if ($@) {
3814                 $@ =~ s/^dgit: //gm;
3815                 fail "$@".
3816                     "Perhaps debian/changelog does not mention $v ?";
3817             }
3818         }
3819     }
3820
3821     printdebug "pseudomerge_version_check i_arch_v @$i_arch_v\n";
3822     return $i_arch_v;
3823 }
3824
3825 sub pseudomerge_make_commit ($$$$ $$) {
3826     my ($clogp, $dgitview, $archive_hash, $i_arch_v,
3827         $msg_cmd, $msg_msg) = @_;
3828     progress "Declaring that HEAD inciudes all changes in $i_arch_v->[0]...";
3829
3830     my $tree = cmdoutput qw(git rev-parse), "${dgitview}:";
3831     my $authline = clogp_authline $clogp;
3832
3833     chomp $msg_msg;
3834     $msg_cmd .=
3835         !defined $overwrite_version ? ""
3836         : !length  $overwrite_version ? " --overwrite"
3837         : " --overwrite=".$overwrite_version;
3838
3839     mkpath '.git/dgit';
3840     my $pmf = ".git/dgit/pseudomerge";
3841     open MC, ">", $pmf or die "$pmf $!";
3842     print MC <<END or die $!;
3843 tree $tree
3844 parent $dgitview
3845 parent $archive_hash
3846 author $authline
3847 committer $authline
3848
3849 $msg_msg
3850
3851 [$msg_cmd]
3852 END
3853     close MC or die $!;
3854
3855     return make_commit($pmf);
3856 }
3857
3858 sub splitbrain_pseudomerge ($$$$) {
3859     my ($clogp, $maintview, $dgitview, $archive_hash) = @_;
3860     # => $merged_dgitview
3861     printdebug "splitbrain_pseudomerge...\n";
3862     #
3863     #     We:      debian/PREVIOUS    HEAD($maintview)
3864     # expect:          o ----------------- o
3865     #                    \                   \
3866     #                     o                   o
3867     #                 a/d/PREVIOUS        $dgitview
3868     #                $archive_hash              \
3869     #  If so,                \                   \
3870     #  we do:                 `------------------ o
3871     #   this:                                   $dgitview'
3872     #
3873
3874     return $dgitview unless defined $archive_hash;
3875
3876     printdebug "splitbrain_pseudomerge...\n";
3877
3878     my $i_arch_v = pseudomerge_version_check($clogp, $archive_hash);
3879
3880     if (!defined $overwrite_version) {
3881         progress "Checking that HEAD inciudes all changes in archive...";
3882     }
3883
3884     return $dgitview if is_fast_fwd $archive_hash, $dgitview;
3885
3886     if (defined $overwrite_version) {
3887     } elsif (!eval {
3888         my $t_dep14 = debiantag_maintview $i_arch_v->[0], access_nomdistro;
3889         my $i_dep14 = infopair_lrf_tag_lookup($t_dep14, "maintainer view tag");
3890         my $t_dgit = debiantag_new $i_arch_v->[0], access_nomdistro;
3891         my $i_dgit = infopair_lrf_tag_lookup($t_dgit, "dgit view tag");
3892         my $i_archive = [ $archive_hash, "current archive contents" ];
3893
3894         printdebug "splitbrain_pseudomerge i_archive @$i_archive\n";
3895
3896         infopair_cond_equal($i_dgit, $i_archive);
3897         infopair_cond_ff($i_dep14, $i_dgit);
3898         infopair_cond_ff($i_dep14, [ $maintview, 'HEAD' ]);
3899         1;
3900     }) {
3901         print STDERR <<END;
3902 $us: check failed (maybe --overwrite is needed, consult documentation)
3903 END
3904         die "$@";
3905     }
3906
3907     my $r = pseudomerge_make_commit
3908         $clogp, $dgitview, $archive_hash, $i_arch_v,
3909         "dgit --quilt=$quilt_mode",
3910         (defined $overwrite_version ? <<END_OVERWR : <<END_MAKEFF);
3911 Declare fast forward from $i_arch_v->[0]
3912 END_OVERWR
3913 Make fast forward from $i_arch_v->[0]
3914 END_MAKEFF
3915
3916     maybe_split_brain_save $maintview, $r, "pseudomerge";
3917
3918     progress "Made pseudo-merge of $i_arch_v->[0] into dgit view.";
3919     return $r;
3920 }
3921
3922 sub plain_overwrite_pseudomerge ($$$) {
3923     my ($clogp, $head, $archive_hash) = @_;
3924
3925     printdebug "plain_overwrite_pseudomerge...";
3926
3927     my $i_arch_v = pseudomerge_version_check($clogp, $archive_hash);
3928
3929     return $head if is_fast_fwd $archive_hash, $head;
3930
3931     my $m = "Declare fast forward from $i_arch_v->[0]";
3932
3933     my $r = pseudomerge_make_commit
3934         $clogp, $head, $archive_hash, $i_arch_v,
3935         "dgit", $m;
3936
3937     runcmd @git, qw(update-ref -m), $m, 'HEAD', $r, $head;
3938
3939     progress "Make pseudo-merge of $i_arch_v->[0] into your HEAD.";
3940     return $r;
3941 }
3942
3943 sub push_parse_changelog ($) {
3944     my ($clogpfn) = @_;
3945
3946     my $clogp = Dpkg::Control::Hash->new();
3947     $clogp->load($clogpfn) or die;
3948
3949     my $clogpackage = getfield $clogp, 'Source';
3950     $package //= $clogpackage;
3951     fail "-p specified $package but changelog specified $clogpackage"
3952         unless $package eq $clogpackage;
3953     my $cversion = getfield $clogp, 'Version';
3954
3955     if (!$we_are_initiator) {
3956         # rpush initiator can't do this because it doesn't have $isuite yet
3957         my $tag = debiantag($cversion, access_nomdistro);
3958         runcmd @git, qw(check-ref-format), $tag;
3959     }
3960
3961     my $dscfn = dscfn($cversion);
3962
3963     return ($clogp, $cversion, $dscfn);
3964 }
3965
3966 sub push_parse_dsc ($$$) {
3967     my ($dscfn,$dscfnwhat, $cversion) = @_;
3968     $dsc = parsecontrol($dscfn,$dscfnwhat);
3969     my $dversion = getfield $dsc, 'Version';
3970     my $dscpackage = getfield $dsc, 'Source';
3971     ($dscpackage eq $package && $dversion eq $cversion) or
3972         fail "$dscfn is for $dscpackage $dversion".
3973             " but debian/changelog is for $package $cversion";
3974 }
3975
3976 sub push_tagwants ($$$$) {
3977     my ($cversion, $dgithead, $maintviewhead, $tfbase) = @_;
3978     my @tagwants;
3979     push @tagwants, {
3980         TagFn => \&debiantag,
3981         Objid => $dgithead,
3982         TfSuffix => '',
3983         View => 'dgit',
3984     };
3985     if (defined $maintviewhead) {
3986         push @tagwants, {
3987             TagFn => \&debiantag_maintview,
3988             Objid => $maintviewhead,
3989             TfSuffix => '-maintview',
3990             View => 'maint',
3991         };
3992     } elsif ($dodep14tag eq 'no' ? 0
3993              : $dodep14tag eq 'want' ? access_cfg_tagformats_can_splitbrain
3994              : $dodep14tag eq 'always'
3995              ? (access_cfg_tagformats_can_splitbrain or fail <<END)
3996 --dep14tag-always (or equivalent in config) means server must support
3997  both "new" and "maint" tag formats, but config says it doesn't.
3998 END
3999             : die "$dodep14tag ?") {
4000         push @tagwants, {
4001             TagFn => \&debiantag_maintview,
4002             Objid => $dgithead,
4003             TfSuffix => '-dgit',
4004             View => 'dgit',
4005         };
4006     };
4007     foreach my $tw (@tagwants) {
4008         $tw->{Tag} = $tw->{TagFn}($cversion, access_nomdistro);
4009         $tw->{Tfn} = sub { $tfbase.$tw->{TfSuffix}.$_[0]; };
4010     }
4011     printdebug 'push_tagwants: ', Dumper(\@_, \@tagwants);
4012     return @tagwants;
4013 }
4014
4015 sub push_mktags ($$ $$ $) {
4016     my ($clogp,$dscfn,
4017         $changesfile,$changesfilewhat,
4018         $tagwants) = @_;
4019
4020     die unless $tagwants->[0]{View} eq 'dgit';
4021
4022     my $declaredistro = access_nomdistro();
4023     my $reader_giturl = do { local $access_forpush=0; access_giturl(); };
4024     $dsc->{$ourdscfield[0]} = join " ",
4025         $tagwants->[0]{Objid}, $declaredistro, $tagwants->[0]{Tag},
4026         $reader_giturl;
4027     $dsc->save("$dscfn.tmp") or die $!;
4028
4029     my $changes = parsecontrol($changesfile,$changesfilewhat);
4030     foreach my $field (qw(Source Distribution Version)) {
4031         $changes->{$field} eq $clogp->{$field} or
4032             fail "changes field $field \`$changes->{$field}'".
4033                 " does not match changelog \`$clogp->{$field}'";
4034     }
4035
4036     my $cversion = getfield $clogp, 'Version';
4037     my $clogsuite = getfield $clogp, 'Distribution';
4038
4039     # We make the git tag by hand because (a) that makes it easier
4040     # to control the "tagger" (b) we can do remote signing
4041     my $authline = clogp_authline $clogp;
4042     my $delibs = join(" ", "",@deliberatelies);
4043
4044     my $mktag = sub {
4045         my ($tw) = @_;
4046         my $tfn = $tw->{Tfn};
4047         my $head = $tw->{Objid};
4048         my $tag = $tw->{Tag};
4049
4050         open TO, '>', $tfn->('.tmp') or die $!;
4051         print TO <<END or die $!;
4052 object $head
4053 type commit
4054 tag $tag
4055 tagger $authline
4056
4057 END
4058         if ($tw->{View} eq 'dgit') {
4059             print TO <<END or die $!;
4060 $package release $cversion for $clogsuite ($csuite) [dgit]
4061 [dgit distro=$declaredistro$delibs]
4062 END
4063             foreach my $ref (sort keys %previously) {
4064                 print TO <<END or die $!;
4065 [dgit previously:$ref=$previously{$ref}]
4066 END
4067             }
4068         } elsif ($tw->{View} eq 'maint') {
4069             print TO <<END or die $!;
4070 $package release $cversion for $clogsuite ($csuite)
4071 (maintainer view tag generated by dgit --quilt=$quilt_mode)
4072 END
4073         } else {
4074             die Dumper($tw)."?";
4075         }
4076
4077         close TO or die $!;
4078
4079         my $tagobjfn = $tfn->('.tmp');
4080         if ($sign) {
4081             if (!defined $keyid) {
4082                 $keyid = access_cfg('keyid','RETURN-UNDEF');
4083             }
4084             if (!defined $keyid) {
4085                 $keyid = getfield $clogp, 'Maintainer';
4086             }
4087             unlink $tfn->('.tmp.asc') or $!==&ENOENT or die $!;
4088             my @sign_cmd = (@gpg, qw(--detach-sign --armor));
4089             push @sign_cmd, qw(-u),$keyid if defined $keyid;
4090             push @sign_cmd, $tfn->('.tmp');
4091             runcmd_ordryrun @sign_cmd;
4092             if (act_scary()) {
4093                 $tagobjfn = $tfn->('.signed.tmp');
4094                 runcmd shell_cmd "exec >$tagobjfn", qw(cat --),
4095                     $tfn->('.tmp'), $tfn->('.tmp.asc');
4096             }
4097         }
4098         return $tagobjfn;
4099     };
4100
4101     my @r = map { $mktag->($_); } @$tagwants;
4102     return @r;
4103 }
4104
4105 sub sign_changes ($) {
4106     my ($changesfile) = @_;
4107     if ($sign) {
4108         my @debsign_cmd = @debsign;
4109         push @debsign_cmd, "-k$keyid" if defined $keyid;
4110         push @debsign_cmd, "-p$gpg[0]" if $gpg[0] ne 'gpg';
4111         push @debsign_cmd, $changesfile;
4112         runcmd_ordryrun @debsign_cmd;
4113     }
4114 }
4115
4116 sub dopush () {
4117     printdebug "actually entering push\n";
4118
4119     supplementary_message(<<'END');
4120 Push failed, while checking state of the archive.
4121 You can retry the push, after fixing the problem, if you like.
4122 END
4123     if (check_for_git()) {
4124         git_fetch_us();
4125     }
4126     my $archive_hash = fetch_from_archive();
4127     if (!$archive_hash) {
4128         $new_package or
4129             fail "package appears to be new in this suite;".
4130                 " if this is intentional, use --new";
4131     }
4132
4133     supplementary_message(<<'END');
4134 Push failed, while preparing your push.
4135 You can retry the push, after fixing the problem, if you like.
4136 END
4137
4138     need_tagformat 'new', "quilt mode $quilt_mode"
4139         if quiltmode_splitbrain;
4140
4141     prep_ud();
4142
4143     access_giturl(); # check that success is vaguely likely
4144     rpush_handle_protovsn_bothends() if $we_are_initiator;
4145     select_tagformat();
4146
4147     my $clogpfn = ".git/dgit/changelog.822.tmp";
4148     runcmd shell_cmd "exec >$clogpfn", qw(dpkg-parsechangelog);
4149
4150     responder_send_file('parsed-changelog', $clogpfn);
4151
4152     my ($clogp, $cversion, $dscfn) =
4153         push_parse_changelog("$clogpfn");
4154
4155     my $dscpath = "$buildproductsdir/$dscfn";
4156     stat_exists $dscpath or
4157         fail "looked for .dsc $dscpath, but $!;".
4158             " maybe you forgot to build";
4159
4160     responder_send_file('dsc', $dscpath);
4161
4162     push_parse_dsc($dscpath, $dscfn, $cversion);
4163
4164     my $format = getfield $dsc, 'Format';
4165     printdebug "format $format\n";
4166
4167     my $actualhead = git_rev_parse('HEAD');
4168     my $dgithead = $actualhead;
4169     my $maintviewhead = undef;
4170
4171     my $upstreamversion = upstreamversion $clogp->{Version};
4172
4173     if (madformat_wantfixup($format)) {
4174         # user might have not used dgit build, so maybe do this now:
4175         if (quiltmode_splitbrain()) {
4176             changedir $ud;
4177             quilt_make_fake_dsc($upstreamversion);
4178             my $cachekey;
4179             ($dgithead, $cachekey) =
4180                 quilt_check_splitbrain_cache($actualhead, $upstreamversion);
4181             $dgithead or fail
4182  "--quilt=$quilt_mode but no cached dgit view:
4183  perhaps tree changed since dgit build[-source] ?";
4184             $split_brain = 1;
4185             $dgithead = splitbrain_pseudomerge($clogp,
4186                                                $actualhead, $dgithead,
4187                                                $archive_hash);
4188             $maintviewhead = $actualhead;
4189             changedir '../../../..';
4190             prep_ud(); # so _only_subdir() works, below
4191         } else {
4192             commit_quilty_patch();
4193         }
4194     }
4195
4196     if (defined $overwrite_version && !defined $maintviewhead) {
4197         $dgithead = plain_overwrite_pseudomerge($clogp,
4198                                                 $dgithead,
4199                                                 $archive_hash);
4200     }
4201
4202     check_not_dirty();
4203
4204     my $forceflag = '';
4205     if ($archive_hash) {
4206         if (is_fast_fwd($archive_hash, $dgithead)) {
4207             # ok
4208         } elsif (deliberately_not_fast_forward) {
4209             $forceflag = '+';
4210         } else {
4211             fail "dgit push: HEAD is not a descendant".
4212                 " of the archive's version.\n".
4213                 "To overwrite the archive's contents,".
4214                 " pass --overwrite[=VERSION].\n".
4215                 "To rewind history, if permitted by the archive,".
4216                 " use --deliberately-not-fast-forward.";
4217         }
4218     }
4219
4220     changedir $ud;
4221     progress "checking that $dscfn corresponds to HEAD";
4222     runcmd qw(dpkg-source -x --),
4223         $dscpath =~ m#^/# ? $dscpath : "../../../$dscpath";
4224     my ($tree,$dir) = mktree_in_ud_from_only_subdir("source package");
4225     check_for_vendor_patches() if madformat($dsc->{format});
4226     changedir '../../../..';
4227     my @diffcmd = (@git, qw(diff --quiet), $tree, $dgithead);
4228     debugcmd "+",@diffcmd;
4229     $!=0; $?=-1;
4230     my $r = system @diffcmd;
4231     if ($r) {
4232         if ($r==256) {
4233             my $diffs = cmdoutput @git, qw(diff --stat), $tree, $dgithead;
4234             fail <<END
4235 HEAD specifies a different tree to $dscfn:
4236 $diffs
4237 Perhaps you forgot to build.  Or perhaps there is a problem with your
4238  source tree (see dgit(7) for some hints).  To see a full diff, run
4239    git diff $tree HEAD
4240 END
4241         } else {
4242             failedcmd @diffcmd;
4243         }
4244     }
4245     if (!$changesfile) {
4246         my $pat = changespat $cversion;
4247         my @cs = glob "$buildproductsdir/$pat";
4248         fail "failed to find unique changes file".
4249             " (looked for $pat in $buildproductsdir);".
4250             " perhaps you need to use dgit -C"
4251             unless @cs==1;
4252         ($changesfile) = @cs;
4253     } else {
4254         $changesfile = "$buildproductsdir/$changesfile";
4255     }
4256
4257     # Check that changes and .dsc agree enough
4258     $changesfile =~ m{[^/]*$};
4259     my $changes = parsecontrol($changesfile,$&);
4260     files_compare_inputs($dsc, $changes)
4261         unless forceing [qw(dsc-changes-mismatch)];
4262
4263     # Perhaps adjust .dsc to contain right set of origs
4264     changes_update_origs_from_dsc($dsc, $changes, $upstreamversion,
4265                                   $changesfile)
4266         unless forceing [qw(changes-origs-exactly)];
4267
4268     # Checks complete, we're going to try and go ahead:
4269
4270     responder_send_file('changes',$changesfile);
4271     responder_send_command("param head $dgithead");
4272     responder_send_command("param csuite $csuite");
4273     responder_send_command("param isuite $isuite");
4274     responder_send_command("param tagformat $tagformat");
4275     if (defined $maintviewhead) {
4276         die unless ($protovsn//4) >= 4;
4277         responder_send_command("param maint-view $maintviewhead");
4278     }
4279
4280     if (deliberately_not_fast_forward) {
4281         git_for_each_ref(lrfetchrefs, sub {
4282             my ($objid,$objtype,$lrfetchrefname,$reftail) = @_;
4283             my $rrefname= substr($lrfetchrefname, length(lrfetchrefs) + 1);
4284             responder_send_command("previously $rrefname=$objid");
4285             $previously{$rrefname} = $objid;
4286         });
4287     }
4288
4289     my @tagwants = push_tagwants($cversion, $dgithead, $maintviewhead,
4290                                  ".git/dgit/tag");
4291     my @tagobjfns;
4292
4293     supplementary_message(<<'END');
4294 Push failed, while signing the tag.
4295 You can retry the push, after fixing the problem, if you like.
4296 END
4297     # If we manage to sign but fail to record it anywhere, it's fine.
4298     if ($we_are_responder) {
4299         @tagobjfns = map { $_->{Tfn}('.signed-tmp') } @tagwants;
4300         responder_receive_files('signed-tag', @tagobjfns);
4301     } else {
4302         @tagobjfns = push_mktags($clogp,$dscpath,
4303                               $changesfile,$changesfile,
4304                               \@tagwants);
4305     }
4306     supplementary_message(<<'END');
4307 Push failed, *after* signing the tag.
4308 If you want to try again, you should use a new version number.
4309 END
4310
4311     pairwise { $a->{TagObjFn} = $b } @tagwants, @tagobjfns;
4312
4313     foreach my $tw (@tagwants) {
4314         my $tag = $tw->{Tag};
4315         my $tagobjfn = $tw->{TagObjFn};
4316         my $tag_obj_hash =
4317             cmdoutput @git, qw(hash-object -w -t tag), $tagobjfn;
4318         runcmd_ordryrun @git, qw(verify-tag), $tag_obj_hash;
4319         runcmd_ordryrun_local
4320             @git, qw(update-ref), "refs/tags/$tag", $tag_obj_hash;
4321     }
4322
4323     supplementary_message(<<'END');
4324 Push failed, while updating the remote git repository - see messages above.
4325 If you want to try again, you should use a new version number.
4326 END
4327     if (!check_for_git()) {
4328         create_remote_git_repo();
4329     }
4330
4331     my @pushrefs = $forceflag.$dgithead.":".rrref();
4332     foreach my $tw (@tagwants) {
4333         push @pushrefs, $forceflag."refs/tags/$tw->{Tag}";
4334     }
4335
4336     runcmd_ordryrun @git,
4337         qw(-c push.followTags=false push), access_giturl(), @pushrefs;
4338     runcmd_ordryrun @git, qw(update-ref -m), 'dgit push', lrref(), $dgithead;
4339
4340     supplementary_message(<<'END');
4341 Push failed, while obtaining signatures on the .changes and .dsc.
4342 If it was just that the signature failed, you may try again by using
4343 debsign by hand to sign the changes
4344    $changesfile
4345 and then dput to complete the upload.
4346 If you need to change the package, you must use a new version number.
4347 END
4348     if ($we_are_responder) {
4349         my $dryrunsuffix = act_local() ? "" : ".tmp";
4350         responder_receive_files('signed-dsc-changes',
4351                                 "$dscpath$dryrunsuffix",
4352                                 "$changesfile$dryrunsuffix");
4353     } else {
4354         if (act_local()) {
4355             rename "$dscpath.tmp",$dscpath or die "$dscfn $!";
4356         } else {
4357             progress "[new .dsc left in $dscpath.tmp]";
4358         }
4359         sign_changes $changesfile;
4360     }
4361
4362     supplementary_message(<<END);
4363 Push failed, while uploading package(s) to the archive server.
4364 You can retry the upload of exactly these same files with dput of:
4365   $changesfile
4366 If that .changes file is broken, you will need to use a new version
4367 number for your next attempt at the upload.
4368 END
4369     my $host = access_cfg('upload-host','RETURN-UNDEF');
4370     my @hostarg = defined($host) ? ($host,) : ();
4371     runcmd_ordryrun @dput, @hostarg, $changesfile;
4372     printdone "pushed and uploaded $cversion";
4373
4374     supplementary_message('');
4375     responder_send_command("complete");
4376 }
4377
4378 sub cmd_clone {
4379     parseopts();
4380     my $dstdir;
4381     badusage "-p is not allowed with clone; specify as argument instead"
4382         if defined $package;
4383     if (@ARGV==1) {
4384         ($package) = @ARGV;
4385     } elsif (@ARGV==2 && $ARGV[1] =~ m#^\w#) {
4386         ($package,$isuite) = @ARGV;
4387     } elsif (@ARGV==2 && $ARGV[1] =~ m#^[./]#) {
4388         ($package,$dstdir) = @ARGV;
4389     } elsif (@ARGV==3) {
4390         ($package,$isuite,$dstdir) = @ARGV;
4391     } else {
4392         badusage "incorrect arguments to dgit clone";
4393     }
4394     notpushing();
4395
4396     $dstdir ||= "$package";
4397     if (stat_exists $dstdir) {
4398         fail "$dstdir already exists";
4399     }
4400
4401     my $cwd_remove;
4402     if ($rmonerror && !$dryrun_level) {
4403         $cwd_remove= getcwd();
4404         unshift @end, sub {
4405             return unless defined $cwd_remove;
4406             if (!chdir "$cwd_remove") {
4407                 return if $!==&ENOENT;
4408                 die "chdir $cwd_remove: $!";
4409             }
4410             printdebug "clone rmonerror removing $dstdir\n";
4411             if (stat $dstdir) {
4412                 rmtree($dstdir) or die "remove $dstdir: $!\n";
4413             } elsif (grep { $! == $_ }
4414                      (ENOENT, ENOTDIR, EACCES, EPERM, ELOOP)) {
4415             } else {
4416                 print STDERR "check whether to remove $dstdir: $!\n";
4417             }
4418         };
4419     }
4420
4421     clone($dstdir);
4422     $cwd_remove = undef;
4423 }
4424
4425 sub branchsuite () {
4426     my $branch = cmdoutput_errok @git, qw(symbolic-ref HEAD);
4427     if ($branch =~ m#$lbranch_re#o) {
4428         return $1;
4429     } else {
4430         return undef;
4431     }
4432 }
4433
4434 sub fetchpullargs () {
4435     if (!defined $package) {
4436         my $sourcep = parsecontrol('debian/control','debian/control');
4437         $package = getfield $sourcep, 'Source';
4438     }
4439     if (@ARGV==0) {
4440         $isuite = branchsuite();
4441         if (!$isuite) {
4442             my $clogp = parsechangelog();
4443             my $clogsuite = getfield $clogp, 'Distribution';
4444             $isuite= $clogsuite if $clogsuite ne 'UNRELEASED';
4445         }
4446     } elsif (@ARGV==1) {
4447         ($isuite) = @ARGV;
4448     } else {
4449         badusage "incorrect arguments to dgit fetch or dgit pull";
4450     }
4451     notpushing();
4452 }
4453
4454 sub cmd_fetch {
4455     parseopts();
4456     fetchpullargs();
4457     my $multi_fetched = fork_for_multisuite(sub { });
4458     exit 0 if $multi_fetched;
4459     fetch();
4460 }
4461
4462 sub cmd_pull {
4463     parseopts();
4464     fetchpullargs();
4465     if (quiltmode_splitbrain()) {
4466         my ($format, $fopts) = get_source_format();
4467         madformat($format) and fail <<END
4468 dgit pull not yet supported in split view mode (--quilt=$quilt_mode)
4469 END
4470     }
4471     pull();
4472 }
4473
4474 sub cmd_push {
4475     parseopts();
4476     badusage "-p is not allowed with dgit push" if defined $package;
4477     check_not_dirty();
4478     my $clogp = parsechangelog();
4479     $package = getfield $clogp, 'Source';
4480     my $specsuite;
4481     if (@ARGV==0) {
4482     } elsif (@ARGV==1) {
4483         ($specsuite) = (@ARGV);
4484     } else {
4485         badusage "incorrect arguments to dgit push";
4486     }
4487     $isuite = getfield $clogp, 'Distribution';
4488     pushing();
4489     if ($new_package) {
4490         local ($package) = $existing_package; # this is a hack
4491         canonicalise_suite();
4492     } else {
4493         canonicalise_suite();
4494     }
4495     if (defined $specsuite &&
4496         $specsuite ne $isuite &&
4497         $specsuite ne $csuite) {
4498             fail "dgit push: changelog specifies $isuite ($csuite)".
4499                 " but command line specifies $specsuite";
4500     }
4501     dopush();
4502 }
4503
4504 #---------- remote commands' implementation ----------
4505
4506 sub cmd_remote_push_build_host {
4507     my ($nrargs) = shift @ARGV;
4508     my (@rargs) = @ARGV[0..$nrargs-1];
4509     @ARGV = @ARGV[$nrargs..$#ARGV];
4510     die unless @rargs;
4511     my ($dir,$vsnwant) = @rargs;
4512     # vsnwant is a comma-separated list; we report which we have
4513     # chosen in our ready response (so other end can tell if they
4514     # offered several)
4515     $debugprefix = ' ';
4516     $we_are_responder = 1;
4517     $us .= " (build host)";
4518
4519     open PI, "<&STDIN" or die $!;
4520     open STDIN, "/dev/null" or die $!;
4521     open PO, ">&STDOUT" or die $!;
4522     autoflush PO 1;
4523     open STDOUT, ">&STDERR" or die $!;
4524     autoflush STDOUT 1;
4525
4526     $vsnwant //= 1;
4527     ($protovsn) = grep {
4528         $vsnwant =~ m{^(?:.*,)?$_(?:,.*)?$}
4529     } @rpushprotovsn_support;
4530
4531     fail "build host has dgit rpush protocol versions ".
4532         (join ",", @rpushprotovsn_support).
4533         " but invocation host has $vsnwant"
4534         unless defined $protovsn;
4535
4536     responder_send_command("dgit-remote-push-ready $protovsn");
4537     changedir $dir;
4538     &cmd_push;
4539 }
4540
4541 sub cmd_remote_push_responder { cmd_remote_push_build_host(); }
4542 # ... for compatibility with proto vsn.1 dgit (just so that user gets
4543 #     a good error message)
4544
4545 sub rpush_handle_protovsn_bothends () {
4546     if ($protovsn < 4) {
4547         need_tagformat 'old', "rpush negotiated protocol $protovsn";
4548     }
4549     select_tagformat();
4550 }
4551
4552 our $i_tmp;
4553
4554 sub i_cleanup {
4555     local ($@, $?);
4556     my $report = i_child_report();
4557     if (defined $report) {
4558         printdebug "($report)\n";
4559     } elsif ($i_child_pid) {
4560         printdebug "(killing build host child $i_child_pid)\n";
4561         kill 15, $i_child_pid;
4562     }
4563     if (defined $i_tmp && !defined $initiator_tempdir) {
4564         changedir "/";
4565         eval { rmtree $i_tmp; };
4566     }
4567 }
4568
4569 END {
4570     return unless forkcheck_mainprocess();
4571     i_cleanup();
4572 }
4573
4574 sub i_method {
4575     my ($base,$selector,@args) = @_;
4576     $selector =~ s/\-/_/g;
4577     { no strict qw(refs); &{"${base}_${selector}"}(@args); }
4578 }
4579
4580 sub cmd_rpush {
4581     my $host = nextarg;
4582     my $dir;
4583     if ($host =~ m/^((?:[^][]|\[[^][]*\])*)\:/) {
4584         $host = $1;
4585         $dir = $'; #';
4586     } else {
4587         $dir = nextarg;
4588     }
4589     $dir =~ s{^-}{./-};
4590     my @rargs = ($dir);
4591     push @rargs, join ",", @rpushprotovsn_support;
4592     my @rdgit;
4593     push @rdgit, @dgit;
4594     push @rdgit, @ropts;
4595     push @rdgit, qw(remote-push-build-host), (scalar @rargs), @rargs;
4596     push @rdgit, @ARGV;
4597     my @cmd = (@ssh, $host, shellquote @rdgit);
4598     debugcmd "+",@cmd;
4599
4600     $we_are_initiator=1;
4601
4602     if (defined $initiator_tempdir) {
4603         rmtree $initiator_tempdir;
4604         mkdir $initiator_tempdir, 0700 or die "$initiator_tempdir: $!";
4605         $i_tmp = $initiator_tempdir;
4606     } else {
4607         $i_tmp = tempdir();
4608     }
4609     $i_child_pid = open2(\*RO, \*RI, @cmd);
4610     changedir $i_tmp;
4611     ($protovsn) = initiator_expect { m/^dgit-remote-push-ready (\S+)/ };
4612     die "$protovsn ?" unless grep { $_ eq $protovsn } @rpushprotovsn_support;
4613     $supplementary_message = '' unless $protovsn >= 3;
4614
4615     for (;;) {
4616         my ($icmd,$iargs) = initiator_expect {
4617             m/^(\S+)(?: (.*))?$/;
4618             ($1,$2);
4619         };
4620         i_method "i_resp", $icmd, $iargs;
4621     }
4622 }
4623
4624 sub i_resp_progress ($) {
4625     my ($rhs) = @_;
4626     my $msg = protocol_read_bytes \*RO, $rhs;
4627     progress $msg;
4628 }
4629
4630 sub i_resp_supplementary_message ($) {
4631     my ($rhs) = @_;
4632     $supplementary_message = protocol_read_bytes \*RO, $rhs;
4633 }
4634
4635 sub i_resp_complete {
4636     my $pid = $i_child_pid;
4637     $i_child_pid = undef; # prevents killing some other process with same pid
4638     printdebug "waiting for build host child $pid...\n";
4639     my $got = waitpid $pid, 0;
4640     die $! unless $got == $pid;
4641     die "build host child failed $?" if $?;
4642
4643     i_cleanup();
4644     printdebug "all done\n";
4645     exit 0;
4646 }
4647
4648 sub i_resp_file ($) {
4649     my ($keyword) = @_;
4650     my $localname = i_method "i_localname", $keyword;
4651     my $localpath = "$i_tmp/$localname";
4652     stat_exists $localpath and
4653         badproto \*RO, "file $keyword ($localpath) twice";
4654     protocol_receive_file \*RO, $localpath;
4655     i_method "i_file", $keyword;
4656 }
4657
4658 our %i_param;
4659
4660 sub i_resp_param ($) {
4661     $_[0] =~ m/^(\S+) (.*)$/ or badproto \*RO, "bad param spec";
4662     $i_param{$1} = $2;
4663 }
4664
4665 sub i_resp_previously ($) {
4666     $_[0] =~ m#^(refs/tags/\S+)=(\w+)$#
4667         or badproto \*RO, "bad previously spec";
4668     my $r = system qw(git check-ref-format), $1;
4669     die "bad previously ref spec ($r)" if $r;
4670     $previously{$1} = $2;
4671 }
4672
4673 our %i_wanted;
4674
4675 sub i_resp_want ($) {
4676     my ($keyword) = @_;
4677     die "$keyword ?" if $i_wanted{$keyword}++;
4678
4679     defined $i_param{'csuite'} or badproto \*RO, "premature desire, no csuite";
4680     $isuite = $i_param{'isuite'} // $i_param{'csuite'};
4681     die unless $isuite =~ m/^$suite_re$/;
4682
4683     pushing();
4684     rpush_handle_protovsn_bothends();
4685
4686     fail "rpush negotiated protocol version $protovsn".
4687         " which does not support quilt mode $quilt_mode"
4688         if quiltmode_splitbrain;
4689
4690     my @localpaths = i_method "i_want", $keyword;
4691     printdebug "[[  $keyword @localpaths\n";
4692     foreach my $localpath (@localpaths) {
4693         protocol_send_file \*RI, $localpath;
4694     }
4695     print RI "files-end\n" or die $!;
4696 }
4697
4698 our ($i_clogp, $i_version, $i_dscfn, $i_changesfn);
4699
4700 sub i_localname_parsed_changelog {
4701     return "remote-changelog.822";
4702 }
4703 sub i_file_parsed_changelog {
4704     ($i_clogp, $i_version, $i_dscfn) =
4705         push_parse_changelog "$i_tmp/remote-changelog.822";
4706     die if $i_dscfn =~ m#/|^\W#;
4707 }
4708
4709 sub i_localname_dsc {
4710     defined $i_dscfn or badproto \*RO, "dsc (before parsed-changelog)";
4711     return $i_dscfn;
4712 }
4713 sub i_file_dsc { }
4714
4715 sub i_localname_changes {
4716     defined $i_dscfn or badproto \*RO, "dsc (before parsed-changelog)";
4717     $i_changesfn = $i_dscfn;
4718     $i_changesfn =~ s/\.dsc$/_dgit.changes/ or die;
4719     return $i_changesfn;
4720 }
4721 sub i_file_changes { }
4722
4723 sub i_want_signed_tag {
4724     printdebug Dumper(\%i_param, $i_dscfn);
4725     defined $i_param{'head'} && defined $i_dscfn && defined $i_clogp
4726         && defined $i_param{'csuite'}
4727         or badproto \*RO, "premature desire for signed-tag";
4728     my $head = $i_param{'head'};
4729     die if $head =~ m/[^0-9a-f]/ || $head !~ m/^../;
4730
4731     my $maintview = $i_param{'maint-view'};
4732     die if defined $maintview && $maintview =~ m/[^0-9a-f]/;
4733
4734     select_tagformat();
4735     if ($protovsn >= 4) {
4736         my $p = $i_param{'tagformat'} // '<undef>';
4737         $p eq $tagformat
4738             or badproto \*RO, "tag format mismatch: $p vs. $tagformat";
4739     }
4740
4741     die unless $i_param{'csuite'} =~ m/^$suite_re$/;
4742     $csuite = $&;
4743     push_parse_dsc $i_dscfn, 'remote dsc', $i_version;
4744
4745     my @tagwants = push_tagwants $i_version, $head, $maintview, "tag";
4746
4747     return
4748         push_mktags $i_clogp, $i_dscfn,
4749             $i_changesfn, 'remote changes',
4750             \@tagwants;
4751 }
4752
4753 sub i_want_signed_dsc_changes {
4754     rename "$i_dscfn.tmp","$i_dscfn" or die "$i_dscfn $!";
4755     sign_changes $i_changesfn;
4756     return ($i_dscfn, $i_changesfn);
4757 }
4758
4759 #---------- building etc. ----------
4760
4761 our $version;
4762 our $sourcechanges;
4763 our $dscfn;
4764
4765 #----- `3.0 (quilt)' handling -----
4766
4767 our $fakeeditorenv = 'DGIT_FAKE_EDITOR_QUILT';
4768
4769 sub quiltify_dpkg_commit ($$$;$) {
4770     my ($patchname,$author,$msg, $xinfo) = @_;
4771     $xinfo //= '';
4772
4773     mkpath '.git/dgit';
4774     my $descfn = ".git/dgit/quilt-description.tmp";
4775     open O, '>', $descfn or die "$descfn: $!";
4776     $msg =~ s/\n+/\n\n/;
4777     print O <<END or die $!;
4778 From: $author
4779 ${xinfo}Subject: $msg
4780 ---
4781
4782 END
4783     close O or die $!;
4784
4785     {
4786         local $ENV{'EDITOR'} = cmdoutput qw(realpath --), $0;
4787         local $ENV{'VISUAL'} = $ENV{'EDITOR'};
4788         local $ENV{$fakeeditorenv} = cmdoutput qw(realpath --), $descfn;
4789         runcmd @dpkgsource, qw(--commit --include-removal .), $patchname;
4790     }
4791 }
4792
4793 sub quiltify_trees_differ ($$;$$$) {
4794     my ($x,$y,$finegrained,$ignorenamesr,$unrepres) = @_;
4795     # returns true iff the two tree objects differ other than in debian/
4796     # with $finegrained,
4797     # returns bitmask 01 - differ in upstream files except .gitignore
4798     #                 02 - differ in .gitignore
4799     # if $ignorenamesr is defined, $ingorenamesr->{$fn}
4800     #  is set for each modified .gitignore filename $fn
4801     # if $unrepres is defined, array ref to which is appeneded
4802     #  a list of unrepresentable changes (removals of upstream files
4803     #  (as messages)
4804     local $/=undef;
4805     my @cmd = (@git, qw(diff-tree -z));
4806     push @cmd, qw(--name-only) unless $unrepres;
4807     push @cmd, qw(-r) if $finegrained || $unrepres;
4808     push @cmd, $x, $y;
4809     my $diffs= cmdoutput @cmd;
4810     my $r = 0;
4811     my @lmodes;
4812     foreach my $f (split /\0/, $diffs) {
4813         if ($unrepres && !@lmodes) {
4814             @lmodes = $f =~ m/^\:(\w+) (\w+) \w+ \w+ / or die "$_ ?";
4815             next;
4816         }
4817         my ($oldmode,$newmode) = @lmodes;
4818         @lmodes = ();
4819
4820         next if $f =~ m#^debian(?:/.*)?$#s;
4821
4822         if ($unrepres) {
4823             eval {
4824                 die "not a plain file\n"
4825                     unless $newmode =~ m/^10\d{4}$/ ||
4826                            $oldmode =~ m/^10\d{4}$/;
4827                 if ($oldmode =~ m/[^0]/ &&
4828                     $newmode =~ m/[^0]/) {
4829                     die "mode changed\n" if $oldmode ne $newmode;
4830                 } else {
4831                     die "non-default mode\n"
4832                         unless $newmode =~ m/^100644$/ ||
4833                                $oldmode =~ m/^100644$/;
4834                 }
4835             };
4836             if ($@) {
4837                 local $/="\n"; chomp $@;
4838                 push @$unrepres, [ $f, "$@ ($oldmode->$newmode)" ];
4839             }
4840         }
4841
4842         my $isignore = $f =~ m#^(?:.*/)?.gitignore$#s;
4843         $r |= $isignore ? 02 : 01;
4844         $ignorenamesr->{$f}=1 if $ignorenamesr && $isignore;
4845     }
4846     printdebug "quiltify_trees_differ $x $y => $r\n";
4847     return $r;
4848 }
4849
4850 sub quiltify_tree_sentinelfiles ($) {
4851     # lists the `sentinel' files present in the tree
4852     my ($x) = @_;
4853     my $r = cmdoutput @git, qw(ls-tree --name-only), $x,
4854         qw(-- debian/rules debian/control);
4855     $r =~ s/\n/,/g;
4856     return $r;
4857 }
4858
4859 sub quiltify_splitbrain_needed () {
4860     if (!$split_brain) {
4861         progress "dgit view: changes are required...";
4862         runcmd @git, qw(checkout -q -b dgit-view);
4863         $split_brain = 1;
4864     }
4865 }
4866
4867 sub quiltify_splitbrain ($$$$$$) {
4868     my ($clogp, $unapplied, $headref, $diffbits,
4869         $editedignores, $cachekey) = @_;
4870     if ($quilt_mode !~ m/gbp|dpm/) {
4871         # treat .gitignore just like any other upstream file
4872         $diffbits = { %$diffbits };
4873         $_ = !!$_ foreach values %$diffbits;
4874     }
4875     # We would like any commits we generate to be reproducible
4876     my @authline = clogp_authline($clogp);
4877     local $ENV{GIT_COMMITTER_NAME} =  $authline[0];
4878     local $ENV{GIT_COMMITTER_EMAIL} = $authline[1];
4879     local $ENV{GIT_COMMITTER_DATE} =  $authline[2];
4880     local $ENV{GIT_AUTHOR_NAME} =  $authline[0];
4881     local $ENV{GIT_AUTHOR_EMAIL} = $authline[1];
4882     local $ENV{GIT_AUTHOR_DATE} =  $authline[2];
4883
4884     if ($quilt_mode =~ m/gbp|unapplied/ &&
4885         ($diffbits->{O2H} & 01)) {
4886         my $msg =
4887  "--quilt=$quilt_mode specified, implying patches-unapplied git tree\n".
4888  " but git tree differs from orig in upstream files.";
4889         if (!stat_exists "debian/patches") {
4890             $msg .=
4891  "\n ... debian/patches is missing; perhaps this is a patch queue branch?";
4892         }
4893         fail $msg;
4894     }
4895     if ($quilt_mode =~ m/dpm/ &&
4896         ($diffbits->{H2A} & 01)) {
4897         fail <<END;
4898 --quilt=$quilt_mode specified, implying patches-applied git tree
4899  but git tree differs from result of applying debian/patches to upstream
4900 END
4901     }
4902     if ($quilt_mode =~ m/gbp|unapplied/ &&
4903         ($diffbits->{O2A} & 01)) { # some patches
4904         quiltify_splitbrain_needed();
4905         progress "dgit view: creating patches-applied version using gbp pq";
4906         runcmd shell_cmd 'exec >/dev/null', gbp_pq, qw(import);
4907         # gbp pq import creates a fresh branch; push back to dgit-view
4908         runcmd @git, qw(update-ref refs/heads/dgit-view HEAD);
4909         runcmd @git, qw(checkout -q dgit-view);
4910     }
4911     if ($quilt_mode =~ m/gbp|dpm/ &&
4912         ($diffbits->{O2A} & 02)) {
4913         fail <<END
4914 --quilt=$quilt_mode specified, implying that HEAD is for use with a
4915  tool which does not create patches for changes to upstream
4916  .gitignores: but, such patches exist in debian/patches.
4917 END
4918     }
4919     if (($diffbits->{O2H} & 02) && # user has modified .gitignore
4920         !($diffbits->{O2A} & 02)) { # patches do not change .gitignore
4921         quiltify_splitbrain_needed();
4922         progress "dgit view: creating patch to represent .gitignore changes";
4923         ensuredir "debian/patches";
4924         my $gipatch = "debian/patches/auto-gitignore";
4925         open GIPATCH, ">>", "$gipatch" or die "$gipatch: $!";
4926         stat GIPATCH or die "$gipatch: $!";
4927         fail "$gipatch already exists; but want to create it".
4928             " to record .gitignore changes" if (stat _)[7];
4929         print GIPATCH <<END or die "$gipatch: $!";
4930 Subject: Update .gitignore from Debian packaging branch
4931
4932 The Debian packaging git branch contains these updates to the upstream
4933 .gitignore file(s).  This patch is autogenerated, to provide these
4934 updates to users of the official Debian archive view of the package.
4935
4936 [dgit ($our_version) update-gitignore]
4937 ---
4938 END
4939         close GIPATCH or die "$gipatch: $!";
4940         runcmd shell_cmd "exec >>$gipatch", @git, qw(diff),
4941             $unapplied, $headref, "--", sort keys %$editedignores;
4942         open SERIES, "+>>", "debian/patches/series" or die $!;
4943         defined seek SERIES, -1, 2 or $!==EINVAL or die $!;
4944         my $newline;
4945         defined read SERIES, $newline, 1 or die $!;
4946         print SERIES "\n" or die $! unless $newline eq "\n";
4947         print SERIES "auto-gitignore\n" or die $!;
4948         close SERIES or die  $!;
4949         runcmd @git, qw(add -- debian/patches/series), $gipatch;
4950         commit_admin <<END
4951 Commit patch to update .gitignore
4952
4953 [dgit ($our_version) update-gitignore-quilt-fixup]
4954 END
4955     }
4956
4957     my $dgitview = git_rev_parse 'HEAD';
4958
4959     changedir '../../../..';
4960     # When we no longer need to support squeeze, use --create-reflog
4961     # instead of this:
4962     ensuredir ".git/logs/refs/dgit-intern";
4963     my $makelogfh = new IO::File ".git/logs/refs/$splitbraincache", '>>'
4964       or die $!;
4965
4966     my $oldcache = git_get_ref "refs/$splitbraincache";
4967     if ($oldcache eq $dgitview) {
4968         my $tree = cmdoutput qw(git rev-parse), "$dgitview:";
4969         # git update-ref doesn't always update, in this case.  *sigh*
4970         my $dummy = make_commit_text <<END;
4971 tree $tree
4972 parent $dgitview
4973 author Dgit <dgit\@example.com> 1000000000 +0000
4974 committer Dgit <dgit\@example.com> 1000000000 +0000
4975
4976 Dummy commit - do not use
4977 END
4978         runcmd @git, qw(update-ref -m), "dgit $our_version - dummy",
4979             "refs/$splitbraincache", $dummy;
4980     }
4981     runcmd @git, qw(update-ref -m), $cachekey, "refs/$splitbraincache",
4982         $dgitview;
4983
4984     changedir '.git/dgit/unpack/work';
4985
4986     my $saved = maybe_split_brain_save $headref, $dgitview, "converted";
4987     progress "dgit view: created ($saved)";
4988 }
4989
4990 sub quiltify ($$$$) {
4991     my ($clogp,$target,$oldtiptree,$failsuggestion) = @_;
4992
4993     # Quilt patchification algorithm
4994     #
4995     # We search backwards through the history of the main tree's HEAD
4996     # (T) looking for a start commit S whose tree object is identical
4997     # to to the patch tip tree (ie the tree corresponding to the
4998     # current dpkg-committed patch series).  For these purposes
4999     # `identical' disregards anything in debian/ - this wrinkle is
5000     # necessary because dpkg-source treates debian/ specially.
5001     #
5002     # We can only traverse edges where at most one of the ancestors'
5003     # trees differs (in changes outside in debian/).  And we cannot
5004     # handle edges which change .pc/ or debian/patches.  To avoid
5005     # going down a rathole we avoid traversing edges which introduce
5006     # debian/rules or debian/control.  And we set a limit on the
5007     # number of edges we are willing to look at.
5008     #
5009     # If we succeed, we walk forwards again.  For each traversed edge
5010     # PC (with P parent, C child) (starting with P=S and ending with
5011     # C=T) to we do this:
5012     #  - git checkout C
5013     #  - dpkg-source --commit with a patch name and message derived from C
5014     # After traversing PT, we git commit the changes which
5015     # should be contained within debian/patches.
5016
5017     # The search for the path S..T is breadth-first.  We maintain a
5018     # todo list containing search nodes.  A search node identifies a
5019     # commit, and looks something like this:
5020     #  $p = {
5021     #      Commit => $git_commit_id,
5022     #      Child => $c,                          # or undef if P=T
5023     #      Whynot => $reason_edge_PC_unsuitable, # in @nots only
5024     #      Nontrivial => true iff $p..$c has relevant changes
5025     #  };
5026
5027     my @todo;
5028     my @nots;
5029     my $sref_S;
5030     my $max_work=100;
5031     my %considered; # saves being exponential on some weird graphs
5032
5033     my $t_sentinels = quiltify_tree_sentinelfiles $target;
5034
5035     my $not = sub {
5036         my ($search,$whynot) = @_;
5037         printdebug " search NOT $search->{Commit} $whynot\n";
5038         $search->{Whynot} = $whynot;
5039         push @nots, $search;
5040         no warnings qw(exiting);
5041         next;
5042     };
5043
5044     push @todo, {
5045         Commit => $target,
5046     };
5047
5048     while (@todo) {
5049         my $c = shift @todo;
5050         next if $considered{$c->{Commit}}++;
5051
5052         $not->($c, "maximum search space exceeded") if --$max_work <= 0;
5053
5054         printdebug "quiltify investigate $c->{Commit}\n";
5055
5056         # are we done?
5057         if (!quiltify_trees_differ $c->{Commit}, $oldtiptree) {
5058             printdebug " search finished hooray!\n";
5059             $sref_S = $c;
5060             last;
5061         }
5062
5063         if ($quilt_mode eq 'nofix') {
5064             fail "quilt fixup required but quilt mode is \`nofix'\n".
5065                 "HEAD commit $c->{Commit} differs from tree implied by ".
5066                 " debian/patches (tree object $oldtiptree)";
5067         }
5068         if ($quilt_mode eq 'smash') {
5069             printdebug " search quitting smash\n";
5070             last;
5071         }
5072
5073         my $c_sentinels = quiltify_tree_sentinelfiles $c->{Commit};
5074         $not->($c, "has $c_sentinels not $t_sentinels")
5075             if $c_sentinels ne $t_sentinels;
5076
5077         my $commitdata = cmdoutput @git, qw(cat-file commit), $c->{Commit};
5078         $commitdata =~ m/\n\n/;
5079         $commitdata =~ $`;
5080         my @parents = ($commitdata =~ m/^parent (\w+)$/gm);
5081         @parents = map { { Commit => $_, Child => $c } } @parents;
5082
5083         $not->($c, "root commit") if !@parents;
5084
5085         foreach my $p (@parents) {
5086             $p->{Nontrivial}= quiltify_trees_differ $p->{Commit},$c->{Commit};
5087         }
5088         my $ndiffers = grep { $_->{Nontrivial} } @parents;
5089         $not->($c, "merge ($ndiffers nontrivial parents)") if $ndiffers > 1;
5090
5091         foreach my $p (@parents) {
5092             printdebug "considering C=$c->{Commit} P=$p->{Commit}\n";
5093
5094             my @cmd= (@git, qw(diff-tree -r --name-only),
5095                       $p->{Commit},$c->{Commit}, qw(-- debian/patches .pc));
5096             my $patchstackchange = cmdoutput @cmd;
5097             if (length $patchstackchange) {
5098                 $patchstackchange =~ s/\n/,/g;
5099                 $not->($p, "changed $patchstackchange");
5100             }
5101
5102             printdebug " search queue P=$p->{Commit} ",
5103                 ($p->{Nontrivial} ? "NT" : "triv"),"\n";
5104             push @todo, $p;
5105         }
5106     }
5107
5108     if (!$sref_S) {
5109         printdebug "quiltify want to smash\n";
5110
5111         my $abbrev = sub {
5112             my $x = $_[0]{Commit};
5113             $x =~ s/(.*?[0-9a-z]{8})[0-9a-z]*$/$1/;
5114             return $x;
5115         };
5116         my $reportnot = sub {
5117             my ($notp) = @_;
5118             my $s = $abbrev->($notp);
5119             my $c = $notp->{Child};
5120             $s .= "..".$abbrev->($c) if $c;
5121             $s .= ": ".$notp->{Whynot};
5122             return $s;
5123         };
5124         if ($quilt_mode eq 'linear') {
5125             print STDERR "$us: quilt fixup cannot be linear.  Stopped at:\n";
5126             foreach my $notp (@nots) {
5127                 print STDERR "$us:  ", $reportnot->($notp), "\n";
5128             }
5129             print STDERR "$us: $_\n" foreach @$failsuggestion;
5130             fail "quilt fixup naive history linearisation failed.\n".
5131  "Use dpkg-source --commit by hand; or, --quilt=smash for one ugly patch";
5132         } elsif ($quilt_mode eq 'smash') {
5133         } elsif ($quilt_mode eq 'auto') {
5134             progress "quilt fixup cannot be linear, smashing...";
5135         } else {
5136             die "$quilt_mode ?";
5137         }
5138
5139         my $time = $ENV{'GIT_COMMITTER_DATE'} || time;
5140         $time =~ s/\s.*//; # trim timezone from GIT_COMMITTER_DATE
5141         my $ncommits = 3;
5142         my $msg = cmdoutput @git, qw(log), "-n$ncommits";
5143
5144         quiltify_dpkg_commit "auto-$version-$target-$time",
5145             (getfield $clogp, 'Maintainer'),
5146             "Automatically generated patch ($clogp->{Version})\n".
5147             "Last (up to) $ncommits git changes, FYI:\n\n". $msg;
5148         return;
5149     }
5150
5151     progress "quiltify linearisation planning successful, executing...";
5152
5153     for (my $p = $sref_S;
5154          my $c = $p->{Child};
5155          $p = $p->{Child}) {
5156         printdebug "quiltify traverse $p->{Commit}..$c->{Commit}\n";
5157         next unless $p->{Nontrivial};
5158
5159         my $cc = $c->{Commit};
5160
5161         my $commitdata = cmdoutput @git, qw(cat-file commit), $cc;
5162         $commitdata =~ m/\n\n/ or die "$c ?";
5163         $commitdata = $`;
5164         my $msg = $'; #';
5165         $commitdata =~ m/^author (.*) \d+ [-+0-9]+$/m or die "$cc ?";
5166         my $author = $1;
5167
5168         my $commitdate = cmdoutput
5169             @git, qw(log -n1 --pretty=format:%aD), $cc;
5170
5171         $msg =~ s/^(.*)\n*/$1\n/ or die "$cc $msg ?";
5172
5173         my $strip_nls = sub { $msg =~ s/\n+$//; $msg .= "\n"; };
5174         $strip_nls->();
5175
5176         my $title = $1;
5177         my $patchname;
5178         my $patchdir;
5179
5180         my $gbp_check_suitable = sub {
5181             $_ = shift;
5182             my ($what) = @_;
5183
5184             eval {
5185                 die "contains unexpected slashes\n" if m{//} || m{/$};
5186                 die "contains leading punctuation\n" if m{^\W} || m{/\W};
5187                 die "contains bad character(s)\n" if m{[^-a-z0-9_.+=~/]}i;
5188                 die "too long" if length > 200;
5189             };
5190             return $_ unless $@;
5191             print STDERR "quiltifying commit $cc:".
5192                 " ignoring/dropping Gbp-Pq $what: $@";
5193             return undef;
5194         };
5195
5196         if ($msg =~ s/^ (?: gbp(?:-pq)? : \s* name \s+ |
5197                            gbp-pq-name: \s* )
5198                        (\S+) \s* \n //ixm) {
5199             $patchname = $gbp_check_suitable->($1, 'Name');
5200         }
5201         if ($msg =~ s/^ (?: gbp(?:-pq)? : \s* topic \s+ |
5202                            gbp-pq-topic: \s* )
5203                        (\S+) \s* \n //ixm) {
5204             $patchdir = $gbp_check_suitable->($1, 'Topic');
5205         }
5206
5207         $strip_nls->();
5208
5209         if (!defined $patchname) {
5210             $patchname = $title;
5211             $patchname =~ s/[.:]$//;
5212             use Text::Iconv;
5213             eval {
5214                 my $converter = new Text::Iconv qw(UTF-8 ASCII//TRANSLIT);
5215                 my $translitname = $converter->convert($patchname);
5216                 die unless defined $translitname;
5217                 $patchname = $translitname;
5218             };
5219             print STDERR
5220                 "dgit: patch title transliteration error: $@"
5221                 if $@;
5222             $patchname =~ y/ A-Z/-a-z/;
5223             $patchname =~ y/-a-z0-9_.+=~//cd;
5224             $patchname =~ s/^\W/x-$&/;
5225             $patchname = substr($patchname,0,40);
5226         }
5227         if (!defined $patchdir) {
5228             $patchdir = '';
5229         }
5230         if (length $patchdir) {
5231             $patchname = "$patchdir/$patchname";
5232         }
5233         if ($patchname =~ m{^(.*)/}) {
5234             mkpath "debian/patches/$1";
5235         }
5236
5237         my $index;
5238         for ($index='';
5239              stat "debian/patches/$patchname$index";
5240              $index++) { }
5241         $!==ENOENT or die "$patchname$index $!";
5242
5243         runcmd @git, qw(checkout -q), $cc;
5244
5245         # We use the tip's changelog so that dpkg-source doesn't
5246         # produce complaining messages from dpkg-parsechangelog.  None
5247         # of the information dpkg-source gets from the changelog is
5248         # actually relevant - it gets put into the original message
5249         # which dpkg-source provides our stunt editor, and then
5250         # overwritten.
5251         runcmd @git, qw(checkout -q), $target, qw(debian/changelog);
5252
5253         quiltify_dpkg_commit "$patchname$index", $author, $msg,
5254             "Date: $commitdate\n".
5255             "X-Dgit-Generated: $clogp->{Version} $cc\n";
5256
5257         runcmd @git, qw(checkout -q), $cc, qw(debian/changelog);
5258     }
5259
5260     runcmd @git, qw(checkout -q master);
5261 }
5262
5263 sub build_maybe_quilt_fixup () {
5264     my ($format,$fopts) = get_source_format;
5265     return unless madformat_wantfixup $format;
5266     # sigh
5267
5268     check_for_vendor_patches();
5269
5270     if (quiltmode_splitbrain) {
5271         fail <<END unless access_cfg_tagformats_can_splitbrain;
5272 quilt mode $quilt_mode requires split view so server needs to support
5273  both "new" and "maint" tag formats, but config says it doesn't.
5274 END
5275     }
5276
5277     my $clogp = parsechangelog();
5278     my $headref = git_rev_parse('HEAD');
5279
5280     prep_ud();
5281     changedir $ud;
5282
5283     my $upstreamversion = upstreamversion $version;
5284
5285     if ($fopts->{'single-debian-patch'}) {
5286         quilt_fixup_singlepatch($clogp, $headref, $upstreamversion);
5287     } else {
5288         quilt_fixup_multipatch($clogp, $headref, $upstreamversion);
5289     }
5290
5291     die 'bug' if $split_brain && !$need_split_build_invocation;
5292
5293     changedir '../../../..';
5294     runcmd_ordryrun_local
5295         @git, qw(pull --ff-only -q .git/dgit/unpack/work master);
5296 }
5297
5298 sub quilt_fixup_mkwork ($) {
5299     my ($headref) = @_;
5300
5301     mkdir "work" or die $!;
5302     changedir "work";
5303     mktree_in_ud_here();
5304     runcmd @git, qw(reset -q --hard), $headref;
5305 }
5306
5307 sub quilt_fixup_linkorigs ($$) {
5308     my ($upstreamversion, $fn) = @_;
5309     # calls $fn->($leafname);
5310
5311     foreach my $f (<../../../../*>) { #/){
5312         my $b=$f; $b =~ s{.*/}{};
5313         {
5314             local ($debuglevel) = $debuglevel-1;
5315             printdebug "QF linkorigs $b, $f ?\n";
5316         }
5317         next unless is_orig_file_of_vsn $b, $upstreamversion;
5318         printdebug "QF linkorigs $b, $f Y\n";
5319         link_ltarget $f, $b or die "$b $!";
5320         $fn->($b);
5321     }
5322 }
5323
5324 sub quilt_fixup_delete_pc () {
5325     runcmd @git, qw(rm -rqf .pc);
5326     commit_admin <<END
5327 Commit removal of .pc (quilt series tracking data)
5328
5329 [dgit ($our_version) upgrade quilt-remove-pc]
5330 END
5331 }
5332
5333 sub quilt_fixup_singlepatch ($$$) {
5334     my ($clogp, $headref, $upstreamversion) = @_;
5335
5336     progress "starting quiltify (single-debian-patch)";
5337
5338     # dpkg-source --commit generates new patches even if
5339     # single-debian-patch is in debian/source/options.  In order to
5340     # get it to generate debian/patches/debian-changes, it is
5341     # necessary to build the source package.
5342
5343     quilt_fixup_linkorigs($upstreamversion, sub { });
5344     quilt_fixup_mkwork($headref);
5345
5346     rmtree("debian/patches");
5347
5348     runcmd @dpkgsource, qw(-b .);
5349     changedir "..";
5350     runcmd @dpkgsource, qw(-x), (srcfn $version, ".dsc");
5351     rename srcfn("$upstreamversion", "/debian/patches"),
5352            "work/debian/patches";
5353
5354     changedir "work";
5355     commit_quilty_patch();
5356 }
5357
5358 sub quilt_make_fake_dsc ($) {
5359     my ($upstreamversion) = @_;
5360
5361     my $fakeversion="$upstreamversion-~~DGITFAKE";
5362
5363     my $fakedsc=new IO::File 'fake.dsc', '>' or die $!;
5364     print $fakedsc <<END or die $!;
5365 Format: 3.0 (quilt)
5366 Source: $package
5367 Version: $fakeversion
5368 Files:
5369 END
5370
5371     my $dscaddfile=sub {
5372         my ($b) = @_;
5373
5374         my $md = new Digest::MD5;
5375
5376         my $fh = new IO::File $b, '<' or die "$b $!";
5377         stat $fh or die $!;
5378         my $size = -s _;
5379
5380         $md->addfile($fh);
5381         print $fakedsc " ".$md->hexdigest." $size $b\n" or die $!;
5382     };
5383
5384     quilt_fixup_linkorigs($upstreamversion, $dscaddfile);
5385
5386     my @files=qw(debian/source/format debian/rules
5387                  debian/control debian/changelog);
5388     foreach my $maybe (qw(debian/patches debian/source/options
5389                           debian/tests/control)) {
5390         next unless stat_exists "../../../$maybe";
5391         push @files, $maybe;
5392     }
5393
5394     my $debtar= srcfn $fakeversion,'.debian.tar.gz';
5395     runcmd qw(env GZIP=-1n tar -zcf), "./$debtar", qw(-C ../../..), @files;
5396
5397     $dscaddfile->($debtar);
5398     close $fakedsc or die $!;
5399 }
5400
5401 sub quilt_check_splitbrain_cache ($$) {
5402     my ($headref, $upstreamversion) = @_;
5403     # Called only if we are in (potentially) split brain mode.
5404     # Called in $ud.
5405     # Computes the cache key and looks in the cache.
5406     # Returns ($dgit_view_commitid, $cachekey) or (undef, $cachekey)
5407
5408     my $splitbrain_cachekey;
5409
5410     progress
5411  "dgit: split brain (separate dgit view) may be needed (--quilt=$quilt_mode).";
5412     # we look in the reflog of dgit-intern/quilt-cache
5413     # we look for an entry whose message is the key for the cache lookup
5414     my @cachekey = (qw(dgit), $our_version);
5415     push @cachekey, $upstreamversion;
5416     push @cachekey, $quilt_mode;
5417     push @cachekey, $headref;
5418
5419     push @cachekey, hashfile('fake.dsc');
5420
5421     my $srcshash = Digest::SHA->new(256);
5422     my %sfs = ( %INC, '$0(dgit)' => $0 );
5423     foreach my $sfk (sort keys %sfs) {
5424         next unless $sfk =~ m/^\$0\b/ || $sfk =~ m{^Debian/Dgit\b};
5425         $srcshash->add($sfk,"  ");
5426         $srcshash->add(hashfile($sfs{$sfk}));
5427         $srcshash->add("\n");
5428     }
5429     push @cachekey, $srcshash->hexdigest();
5430     $splitbrain_cachekey = "@cachekey";
5431
5432     my @cmd = (@git, qw(log -g), '--pretty=format:%H %gs',
5433                $splitbraincache);
5434     printdebug "splitbrain cachekey $splitbrain_cachekey\n";
5435     debugcmd "|(probably)",@cmd;
5436     my $child = open GC, "-|";  defined $child or die $!;
5437     if (!$child) {
5438         chdir '../../..' or die $!;
5439         if (!stat ".git/logs/refs/$splitbraincache") {
5440             $! == ENOENT or die $!;
5441             printdebug ">(no reflog)\n";
5442             exit 0;
5443         }
5444         exec @cmd; die $!;
5445     }
5446     while (<GC>) {
5447         chomp;
5448         printdebug ">| ", $_, "\n" if $debuglevel > 1;
5449         next unless m/^(\w+) (\S.*\S)$/ && $2 eq $splitbrain_cachekey;
5450
5451         my $cachehit = $1;
5452         quilt_fixup_mkwork($headref);
5453         my $saved = maybe_split_brain_save $headref, $cachehit, "cache-hit";
5454         if ($cachehit ne $headref) {
5455             progress "dgit view: found cached ($saved)";
5456             runcmd @git, qw(checkout -q -b dgit-view), $cachehit;
5457             $split_brain = 1;
5458             return ($cachehit, $splitbrain_cachekey);
5459         }
5460         progress "dgit view: found cached, no changes required";
5461         return ($headref, $splitbrain_cachekey);
5462     }
5463     die $! if GC->error;
5464     failedcmd unless close GC;
5465
5466     printdebug "splitbrain cache miss\n";
5467     return (undef, $splitbrain_cachekey);
5468 }
5469
5470 sub quilt_fixup_multipatch ($$$) {
5471     my ($clogp, $headref, $upstreamversion) = @_;
5472
5473     progress "examining quilt state (multiple patches, $quilt_mode mode)";
5474
5475     # Our objective is:
5476     #  - honour any existing .pc in case it has any strangeness
5477     #  - determine the git commit corresponding to the tip of
5478     #    the patch stack (if there is one)
5479     #  - if there is such a git commit, convert each subsequent
5480     #    git commit into a quilt patch with dpkg-source --commit
5481     #  - otherwise convert all the differences in the tree into
5482     #    a single git commit
5483     #
5484     # To do this we:
5485
5486     # Our git tree doesn't necessarily contain .pc.  (Some versions of
5487     # dgit would include the .pc in the git tree.)  If there isn't
5488     # one, we need to generate one by unpacking the patches that we
5489     # have.
5490     #
5491     # We first look for a .pc in the git tree.  If there is one, we
5492     # will use it.  (This is not the normal case.)
5493     #
5494     # Otherwise need to regenerate .pc so that dpkg-source --commit
5495     # can work.  We do this as follows:
5496     #     1. Collect all relevant .orig from parent directory
5497     #     2. Generate a debian.tar.gz out of
5498     #         debian/{patches,rules,source/format,source/options}
5499     #     3. Generate a fake .dsc containing just these fields:
5500     #          Format Source Version Files
5501     #     4. Extract the fake .dsc
5502     #        Now the fake .dsc has a .pc directory.
5503     # (In fact we do this in every case, because in future we will
5504     # want to search for a good base commit for generating patches.)
5505     #
5506     # Then we can actually do the dpkg-source --commit
5507     #     1. Make a new working tree with the same object
5508     #        store as our main tree and check out the main
5509     #        tree's HEAD.
5510     #     2. Copy .pc from the fake's extraction, if necessary
5511     #     3. Run dpkg-source --commit
5512     #     4. If the result has changes to debian/, then
5513     #          - git add them them
5514     #          - git add .pc if we had a .pc in-tree
5515     #          - git commit
5516     #     5. If we had a .pc in-tree, delete it, and git commit
5517     #     6. Back in the main tree, fast forward to the new HEAD
5518
5519     # Another situation we may have to cope with is gbp-style
5520     # patches-unapplied trees.
5521     #
5522     # We would want to detect these, so we know to escape into
5523     # quilt_fixup_gbp.  However, this is in general not possible.
5524     # Consider a package with a one patch which the dgit user reverts
5525     # (with git revert or the moral equivalent).
5526     #
5527     # That is indistinguishable in contents from a patches-unapplied
5528     # tree.  And looking at the history to distinguish them is not
5529     # useful because the user might have made a confusing-looking git
5530     # history structure (which ought to produce an error if dgit can't
5531     # cope, not a silent reintroduction of an unwanted patch).
5532     #
5533     # So gbp users will have to pass an option.  But we can usually
5534     # detect their failure to do so: if the tree is not a clean
5535     # patches-applied tree, quilt linearisation fails, but the tree
5536     # _is_ a clean patches-unapplied tree, we can suggest that maybe
5537     # they want --quilt=unapplied.
5538     #
5539     # To help detect this, when we are extracting the fake dsc, we
5540     # first extract it with --skip-patches, and then apply the patches
5541     # afterwards with dpkg-source --before-build.  That lets us save a
5542     # tree object corresponding to .origs.
5543
5544     my $splitbrain_cachekey;
5545
5546     quilt_make_fake_dsc($upstreamversion);
5547
5548     if (quiltmode_splitbrain()) {
5549         my $cachehit;
5550         ($cachehit, $splitbrain_cachekey) =
5551             quilt_check_splitbrain_cache($headref, $upstreamversion);
5552         return if $cachehit;
5553     }
5554
5555     runcmd qw(sh -ec),
5556         'exec dpkg-source --no-check --skip-patches -x fake.dsc >/dev/null';
5557
5558     my $fakexdir= $package.'-'.(stripepoch $upstreamversion);
5559     rename $fakexdir, "fake" or die "$fakexdir $!";
5560
5561     changedir 'fake';
5562
5563     remove_stray_gits("source package");
5564     mktree_in_ud_here();
5565
5566     rmtree '.pc';
5567
5568     runcmd @git, qw(checkout -f), $headref, qw(-- debian);
5569     my $unapplied=git_add_write_tree();
5570     printdebug "fake orig tree object $unapplied\n";
5571
5572     ensuredir '.pc';
5573
5574     my @bbcmd = (qw(sh -ec), 'exec dpkg-source --before-build . >/dev/null');
5575     $!=0; $?=-1;
5576     if (system @bbcmd) {
5577         failedcmd @bbcmd if $? < 0;
5578         fail <<END;
5579 failed to apply your git tree's patch stack (from debian/patches/) to
5580  the corresponding upstream tarball(s).  Your source tree and .orig
5581  are probably too inconsistent.  dgit can only fix up certain kinds of
5582  anomaly (depending on the quilt mode).  See --quilt= in dgit(1).
5583 END
5584     }
5585
5586     changedir '..';
5587
5588     quilt_fixup_mkwork($headref);
5589
5590     my $mustdeletepc=0;
5591     if (stat_exists ".pc") {
5592         -d _ or die;
5593         progress "Tree already contains .pc - will use it then delete it.";
5594         $mustdeletepc=1;
5595     } else {
5596         rename '../fake/.pc','.pc' or die $!;
5597     }
5598
5599     changedir '../fake';
5600     rmtree '.pc';
5601     my $oldtiptree=git_add_write_tree();
5602     printdebug "fake o+d/p tree object $unapplied\n";
5603     changedir '../work';
5604
5605
5606     # We calculate some guesswork now about what kind of tree this might
5607     # be.  This is mostly for error reporting.
5608
5609     my %editedignores;
5610     my @unrepres;
5611     my $diffbits = {
5612         # H = user's HEAD
5613         # O = orig, without patches applied
5614         # A = "applied", ie orig with H's debian/patches applied
5615         O2H => quiltify_trees_differ($unapplied,$headref,   1,
5616                                      \%editedignores, \@unrepres),
5617         H2A => quiltify_trees_differ($headref,  $oldtiptree,1),
5618         O2A => quiltify_trees_differ($unapplied,$oldtiptree,1),
5619     };
5620
5621     my @dl;
5622     foreach my $b (qw(01 02)) {
5623         foreach my $v (qw(O2H O2A H2A)) {
5624             push @dl, ($diffbits->{$v} & $b) ? '##' : '==';
5625         }
5626     }
5627     printdebug "differences \@dl @dl.\n";
5628
5629     progress sprintf
5630 "$us: base trees orig=%.20s o+d/p=%.20s",
5631               $unapplied, $oldtiptree;
5632     progress sprintf
5633 "$us: quilt differences: src:  %s orig %s     gitignores:  %s orig %s\n".
5634 "$us: quilt differences:      HEAD %s o+d/p               HEAD %s o+d/p",
5635                              $dl[0], $dl[1],              $dl[3], $dl[4],
5636                                  $dl[2],                     $dl[5];
5637
5638     if (@unrepres) {
5639         print STDERR "dgit:  cannot represent change: $_->[1]: $_->[0]\n"
5640             foreach @unrepres;
5641         forceable_fail [qw(unrepresentable)], <<END;
5642 HEAD has changes to .orig[s] which are not representable by `3.0 (quilt)'
5643 END
5644     }
5645
5646     my @failsuggestion;
5647     if (!($diffbits->{O2H} & $diffbits->{O2A})) {
5648         push @failsuggestion, "This might be a patches-unapplied branch.";
5649     }  elsif (!($diffbits->{H2A} & $diffbits->{O2A})) {
5650         push @failsuggestion, "This might be a patches-applied branch.";
5651     }
5652     push @failsuggestion, "Maybe you need to specify one of".
5653         " --[quilt=]gbp --[quilt=]dpm --quilt=unapplied ?";
5654
5655     if (quiltmode_splitbrain()) {
5656         quiltify_splitbrain($clogp, $unapplied, $headref,
5657                             $diffbits, \%editedignores,
5658                             $splitbrain_cachekey);
5659         return;
5660     }
5661
5662     progress "starting quiltify (multiple patches, $quilt_mode mode)";
5663     quiltify($clogp,$headref,$oldtiptree,\@failsuggestion);
5664
5665     if (!open P, '>>', ".pc/applied-patches") {
5666         $!==&ENOENT or die $!;
5667     } else {
5668         close P;
5669     }
5670
5671     commit_quilty_patch();
5672
5673     if ($mustdeletepc) {
5674         quilt_fixup_delete_pc();
5675     }
5676 }
5677
5678 sub quilt_fixup_editor () {
5679     my $descfn = $ENV{$fakeeditorenv};
5680     my $editing = $ARGV[$#ARGV];
5681     open I1, '<', $descfn or die "$descfn: $!";
5682     open I2, '<', $editing or die "$editing: $!";
5683     unlink $editing or die "$editing: $!";
5684     open O, '>', $editing or die "$editing: $!";
5685     while (<I1>) { print O or die $!; } I1->error and die $!;
5686     my $copying = 0;
5687     while (<I2>) {
5688         $copying ||= m/^\-\-\- /;
5689         next unless $copying;
5690         print O or die $!;
5691     }
5692     I2->error and die $!;
5693     close O or die $1;
5694     exit 0;
5695 }
5696
5697 sub maybe_apply_patches_dirtily () {
5698     return unless $quilt_mode =~ m/gbp|unapplied/;
5699     print STDERR <<END or die $!;
5700
5701 dgit: Building, or cleaning with rules target, in patches-unapplied tree.
5702 dgit: Have to apply the patches - making the tree dirty.
5703 dgit: (Consider specifying --clean=git and (or) using dgit sbuild.)
5704
5705 END
5706     $patches_applied_dirtily = 01;
5707     $patches_applied_dirtily |= 02 unless stat_exists '.pc';
5708     runcmd qw(dpkg-source --before-build .);
5709 }
5710
5711 sub maybe_unapply_patches_again () {
5712     progress "dgit: Unapplying patches again to tidy up the tree."
5713         if $patches_applied_dirtily;
5714     runcmd qw(dpkg-source --after-build .)
5715         if $patches_applied_dirtily & 01;
5716     rmtree '.pc'
5717         if $patches_applied_dirtily & 02;
5718     $patches_applied_dirtily = 0;
5719 }
5720
5721 #----- other building -----
5722
5723 our $clean_using_builder;
5724 # ^ tree is to be cleaned by dpkg-source's builtin idea that it should
5725 #   clean the tree before building (perhaps invoked indirectly by
5726 #   whatever we are using to run the build), rather than separately
5727 #   and explicitly by us.
5728
5729 sub clean_tree () {
5730     return if $clean_using_builder;
5731     if ($cleanmode eq 'dpkg-source') {
5732         maybe_apply_patches_dirtily();
5733         runcmd_ordryrun_local @dpkgbuildpackage, qw(-T clean);
5734     } elsif ($cleanmode eq 'dpkg-source-d') {
5735         maybe_apply_patches_dirtily();
5736         runcmd_ordryrun_local @dpkgbuildpackage, qw(-d -T clean);
5737     } elsif ($cleanmode eq 'git') {
5738         runcmd_ordryrun_local @git, qw(clean -xdf);
5739     } elsif ($cleanmode eq 'git-ff') {
5740         runcmd_ordryrun_local @git, qw(clean -xdff);
5741     } elsif ($cleanmode eq 'check') {
5742         my $leftovers = cmdoutput @git, qw(clean -xdn);
5743         if (length $leftovers) {
5744             print STDERR $leftovers, "\n" or die $!;
5745             fail "tree contains uncommitted files and --clean=check specified";
5746         }
5747     } elsif ($cleanmode eq 'none') {
5748     } else {
5749         die "$cleanmode ?";
5750     }
5751 }
5752
5753 sub cmd_clean () {
5754     badusage "clean takes no additional arguments" if @ARGV;
5755     notpushing();
5756     clean_tree();
5757     maybe_unapply_patches_again();
5758 }
5759
5760 sub build_prep_early () {
5761     our $build_prep_early_done //= 0;
5762     return if $build_prep_early_done++;
5763     badusage "-p is not allowed when building" if defined $package;
5764     my $clogp = parsechangelog();
5765     $isuite = getfield $clogp, 'Distribution';
5766     $package = getfield $clogp, 'Source';
5767     $version = getfield $clogp, 'Version';
5768     notpushing();
5769     check_not_dirty();
5770 }
5771
5772 sub build_prep () {
5773     build_prep_early();
5774     clean_tree();
5775     build_maybe_quilt_fixup();
5776     if ($rmchanges) {
5777         my $pat = changespat $version;
5778         foreach my $f (glob "$buildproductsdir/$pat") {
5779             if (act_local()) {
5780                 unlink $f or fail "remove old changes file $f: $!";
5781             } else {
5782                 progress "would remove $f";
5783             }
5784         }
5785     }
5786 }
5787
5788 sub changesopts_initial () {
5789     my @opts =@changesopts[1..$#changesopts];
5790 }
5791
5792 sub changesopts_version () {
5793     if (!defined $changes_since_version) {
5794         my @vsns = archive_query('archive_query');
5795         my @quirk = access_quirk();
5796         if ($quirk[0] eq 'backports') {
5797             local $isuite = $quirk[2];
5798             local $csuite;
5799             canonicalise_suite();
5800             push @vsns, archive_query('archive_query');
5801         }
5802         if (@vsns) {
5803             @vsns = map { $_->[0] } @vsns;
5804             @vsns = sort { -version_compare($a, $b) } @vsns;
5805             $changes_since_version = $vsns[0];
5806             progress "changelog will contain changes since $vsns[0]";
5807         } else {
5808             $changes_since_version = '_';
5809             progress "package seems new, not specifying -v<version>";
5810         }
5811     }
5812     if ($changes_since_version ne '_') {
5813         return ("-v$changes_since_version");
5814     } else {
5815         return ();
5816     }
5817 }
5818
5819 sub changesopts () {
5820     return (changesopts_initial(), changesopts_version());
5821 }
5822
5823 sub massage_dbp_args ($;$) {
5824     my ($cmd,$xargs) = @_;
5825     # We need to:
5826     #
5827     #  - if we're going to split the source build out so we can
5828     #    do strange things to it, massage the arguments to dpkg-buildpackage
5829     #    so that the main build doessn't build source (or add an argument
5830     #    to stop it building source by default).
5831     #
5832     #  - add -nc to stop dpkg-source cleaning the source tree,
5833     #    unless we're not doing a split build and want dpkg-source
5834     #    as cleanmode, in which case we can do nothing
5835     #
5836     # return values:
5837     #    0 - source will NOT need to be built separately by caller
5838     #   +1 - source will need to be built separately by caller
5839     #   +2 - source will need to be built separately by caller AND
5840     #        dpkg-buildpackage should not in fact be run at all!
5841     debugcmd '#massaging#', @$cmd if $debuglevel>1;
5842 #print STDERR "MASS0 ",Dumper($cmd, $xargs, $need_split_build_invocation);
5843     if ($cleanmode eq 'dpkg-source' && !$need_split_build_invocation) {
5844         $clean_using_builder = 1;
5845         return 0;
5846     }
5847     # -nc has the side effect of specifying -b if nothing else specified
5848     # and some combinations of -S, -b, et al, are errors, rather than
5849     # later simply overriding earlie.  So we need to:
5850     #  - search the command line for these options
5851     #  - pick the last one
5852     #  - perhaps add our own as a default
5853     #  - perhaps adjust it to the corresponding non-source-building version
5854     my $dmode = '-F';
5855     foreach my $l ($cmd, $xargs) {
5856         next unless $l;
5857         @$l = grep { !(m/^-[SgGFABb]$/s and $dmode=$_) } @$l;
5858     }
5859     push @$cmd, '-nc';
5860 #print STDERR "MASS1 ",Dumper($cmd, $xargs, $dmode);
5861     my $r = 0;
5862     if ($need_split_build_invocation) {
5863         printdebug "massage split $dmode.\n";
5864         $r = $dmode =~ m/[S]/     ? +2 :
5865              $dmode =~ y/gGF/ABb/ ? +1 :
5866              $dmode =~ m/[ABb]/   ?  0 :
5867              die "$dmode ?";
5868     }
5869     printdebug "massage done $r $dmode.\n";
5870     push @$cmd, $dmode;
5871 #print STDERR "MASS2 ",Dumper($cmd, $xargs, $r);
5872     return $r;
5873 }
5874
5875 sub in_parent (&) {
5876     my ($fn) = @_;
5877     my $wasdir = must_getcwd();
5878     changedir "..";
5879     $fn->();
5880     changedir $wasdir;
5881 }
5882
5883 sub postbuild_mergechanges ($) { # must run with CWD=.. (eg in in_parent)
5884     my ($msg_if_onlyone) = @_;
5885     # If there is only one .changes file, fail with $msg_if_onlyone,
5886     # or if that is undef, be a no-op.
5887     # Returns the changes file to report to the user.
5888     my $pat = changespat $version;
5889     my @changesfiles = glob $pat;
5890     @changesfiles = sort {
5891         ($b =~ m/_source\.changes$/ <=> $a =~ m/_source\.changes$/)
5892             or $a cmp $b
5893     } @changesfiles;
5894     my $result;
5895     if (@changesfiles==1) {
5896         fail <<END.$msg_if_onlyone if defined $msg_if_onlyone;
5897 only one changes file from build (@changesfiles)
5898 END
5899         $result = $changesfiles[0];
5900     } elsif (@changesfiles==2) {
5901         my $binchanges = parsecontrol($changesfiles[1], "binary changes file");
5902         foreach my $l (split /\n/, getfield $binchanges, 'Files') {
5903             fail "$l found in binaries changes file $binchanges"
5904                 if $l =~ m/\.dsc$/;
5905         }
5906         runcmd_ordryrun_local @mergechanges, @changesfiles;
5907         my $multichanges = changespat $version,'multi';
5908         if (act_local()) {
5909             stat_exists $multichanges or fail "$multichanges: $!";
5910             foreach my $cf (glob $pat) {
5911                 next if $cf eq $multichanges;
5912                 rename "$cf", "$cf.inmulti" or fail "$cf\{,.inmulti}: $!";
5913             }
5914         }
5915         $result = $multichanges;
5916     } else {
5917         fail "wrong number of different changes files (@changesfiles)";
5918     }
5919     printdone "build successful, results in $result\n" or die $!;
5920 }
5921
5922 sub midbuild_checkchanges () {
5923     my $pat = changespat $version;
5924     return if $rmchanges;
5925     my @unwanted = map { s#^\.\./##; $_; } glob "../$pat";
5926     @unwanted = grep { $_ ne changespat $version,'source' } @unwanted;
5927     fail <<END
5928 changes files other than source matching $pat already present; building would result in ambiguity about the intended results.
5929 Suggest you delete @unwanted.
5930 END
5931         if @unwanted;
5932 }
5933
5934 sub midbuild_checkchanges_vanilla ($) {
5935     my ($wantsrc) = @_;
5936     midbuild_checkchanges() if $wantsrc == 1;
5937 }
5938
5939 sub postbuild_mergechanges_vanilla ($) {
5940     my ($wantsrc) = @_;
5941     if ($wantsrc == 1) {
5942         in_parent {
5943             postbuild_mergechanges(undef);
5944         };
5945     } else {
5946         printdone "build successful\n";
5947     }
5948 }
5949
5950 sub cmd_build {
5951     build_prep_early();
5952     my @dbp = (@dpkgbuildpackage, qw(-us -uc), changesopts_initial(), @ARGV);
5953     my $wantsrc = massage_dbp_args \@dbp;
5954     if ($wantsrc > 0) {
5955         build_source();
5956         midbuild_checkchanges_vanilla $wantsrc;
5957     } else {
5958         build_prep();
5959     }
5960     if ($wantsrc < 2) {
5961         push @dbp, changesopts_version();
5962         maybe_apply_patches_dirtily();
5963         runcmd_ordryrun_local @dbp;
5964     }
5965     maybe_unapply_patches_again();
5966     postbuild_mergechanges_vanilla $wantsrc;
5967 }
5968
5969 sub pre_gbp_build {
5970     $quilt_mode //= 'gbp';
5971 }
5972
5973 sub cmd_gbp_build {
5974     build_prep_early();
5975
5976     # gbp can make .origs out of thin air.  In my tests it does this
5977     # even for a 1.0 format package, with no origs present.  So I
5978     # guess it keys off just the version number.  We don't know
5979     # exactly what .origs ought to exist, but let's assume that we
5980     # should run gbp if: the version has an upstream part and the main
5981     # orig is absent.
5982     my $upstreamversion = upstreamversion $version;
5983     my $origfnpat = srcfn $upstreamversion, '.orig.tar.*';
5984     my $gbp_make_orig = $version =~ m/-/ && !(() = glob "../$origfnpat");
5985
5986     if ($gbp_make_orig) {
5987         clean_tree();
5988         $cleanmode = 'none'; # don't do it again
5989         $need_split_build_invocation = 1;
5990     }
5991
5992     my @dbp = @dpkgbuildpackage;
5993
5994     my $wantsrc = massage_dbp_args \@dbp, \@ARGV;
5995
5996     if (!length $gbp_build[0]) {
5997         if (length executable_on_path('git-buildpackage')) {
5998             $gbp_build[0] = qw(git-buildpackage);
5999         } else {
6000             $gbp_build[0] = 'gbp buildpackage';
6001         }
6002     }
6003     my @cmd = opts_opt_multi_cmd @gbp_build;
6004
6005     push @cmd, (qw(-us -uc --git-no-sign-tags), "--git-builder=@dbp");
6006
6007     if ($gbp_make_orig) {
6008         ensuredir '.git/dgit';
6009         my $ok = '.git/dgit/origs-gen-ok';
6010         unlink $ok or $!==&ENOENT or die $!;
6011         my @origs_cmd = @cmd;
6012         push @origs_cmd, qw(--git-cleaner=true);
6013         push @origs_cmd, "--git-prebuild=touch $ok .git/dgit/no-such-dir/ok";
6014         push @origs_cmd, @ARGV;
6015         if (act_local()) {
6016             debugcmd @origs_cmd;
6017             system @origs_cmd;
6018             do { local $!; stat_exists $ok; }
6019                 or failedcmd @origs_cmd;
6020         } else {
6021             dryrun_report @origs_cmd;
6022         }
6023     }
6024
6025     if ($wantsrc > 0) {
6026         build_source();
6027         midbuild_checkchanges_vanilla $wantsrc;
6028     } else {
6029         if (!$clean_using_builder) {
6030             push @cmd, '--git-cleaner=true';
6031         }
6032         build_prep();
6033     }
6034     maybe_unapply_patches_again();
6035     if ($wantsrc < 2) {
6036         push @cmd, changesopts();
6037         runcmd_ordryrun_local @cmd, @ARGV;
6038     }
6039     postbuild_mergechanges_vanilla $wantsrc;
6040 }
6041 sub cmd_git_build { cmd_gbp_build(); } # compatibility with <= 1.0
6042
6043 sub build_source {
6044     build_prep_early();
6045     my $our_cleanmode = $cleanmode;
6046     if ($need_split_build_invocation) {
6047         # Pretend that clean is being done some other way.  This
6048         # forces us not to try to use dpkg-buildpackage to clean and
6049         # build source all in one go; and instead we run dpkg-source
6050         # (and build_prep() will do the clean since $clean_using_builder
6051         # is false).
6052         $our_cleanmode = 'ELSEWHERE';
6053     }
6054     if ($our_cleanmode =~ m/^dpkg-source/) {
6055         # dpkg-source invocation (below) will clean, so build_prep shouldn't
6056         $clean_using_builder = 1;
6057     }
6058     build_prep();
6059     $sourcechanges = changespat $version,'source';
6060     if (act_local()) {
6061         unlink "../$sourcechanges" or $!==ENOENT
6062             or fail "remove $sourcechanges: $!";
6063     }
6064     $dscfn = dscfn($version);
6065     if ($our_cleanmode eq 'dpkg-source') {
6066         maybe_apply_patches_dirtily();
6067         runcmd_ordryrun_local @dpkgbuildpackage, qw(-us -uc -S),
6068             changesopts();
6069     } elsif ($our_cleanmode eq 'dpkg-source-d') {
6070         maybe_apply_patches_dirtily();
6071         runcmd_ordryrun_local @dpkgbuildpackage, qw(-us -uc -S -d),
6072             changesopts();
6073     } else {
6074         my @cmd = (@dpkgsource, qw(-b --));
6075         if ($split_brain) {
6076             changedir $ud;
6077             runcmd_ordryrun_local @cmd, "work";
6078             my @udfiles = <${package}_*>;
6079             changedir "../../..";
6080             foreach my $f (@udfiles) {
6081                 printdebug "source copy, found $f\n";
6082                 next unless
6083                     $f eq $dscfn or
6084                     ($f =~ m/\.debian\.tar(?:\.\w+)$/ &&
6085                      $f eq srcfn($version, $&));
6086                 printdebug "source copy, found $f - renaming\n";
6087                 rename "$ud/$f", "../$f" or $!==ENOENT
6088                     or fail "put in place new source file ($f): $!";
6089             }
6090         } else {
6091             my $pwd = must_getcwd();
6092             my $leafdir = basename $pwd;
6093             changedir "..";
6094             runcmd_ordryrun_local @cmd, $leafdir;
6095             changedir $pwd;
6096         }
6097         runcmd_ordryrun_local qw(sh -ec),
6098             'exec >$1; shift; exec "$@"','x',
6099             "../$sourcechanges",
6100             @dpkggenchanges, qw(-S), changesopts();
6101     }
6102 }
6103
6104 sub cmd_build_source {
6105     build_prep_early();
6106     badusage "build-source takes no additional arguments" if @ARGV;
6107     build_source();
6108     maybe_unapply_patches_again();
6109     printdone "source built, results in $dscfn and $sourcechanges";
6110 }
6111
6112 sub cmd_sbuild {
6113     build_source();
6114     midbuild_checkchanges();
6115     in_parent {
6116         if (act_local()) {
6117             stat_exists $dscfn or fail "$dscfn (in parent directory): $!";
6118             stat_exists $sourcechanges
6119                 or fail "$sourcechanges (in parent directory): $!";
6120         }
6121         runcmd_ordryrun_local @sbuild, qw(-d), $isuite, @ARGV, $dscfn;
6122     };
6123     maybe_unapply_patches_again();
6124     in_parent {
6125         postbuild_mergechanges(<<END);
6126 perhaps you need to pass -A ?  (sbuild's default is to build only
6127 arch-specific binaries; dgit 1.4 used to override that.)
6128 END
6129     };
6130 }
6131
6132 sub cmd_quilt_fixup {
6133     badusage "incorrect arguments to dgit quilt-fixup" if @ARGV;
6134     build_prep_early();
6135     clean_tree();
6136     build_maybe_quilt_fixup();
6137 }
6138
6139 sub import_dsc_result {
6140     my ($dstref, $newhash, $what_log, $what_msg) = @_;
6141     my @cmd = (@git, qw(update-ref -m), $what_log, $dstref, $newhash);
6142     runcmd @cmd;
6143     check_gitattrs($newhash, "source tree");
6144
6145     progress "dgit: import-dsc: $what_msg";
6146 }
6147
6148 sub cmd_import_dsc {
6149     my $needsig = 0;
6150
6151     while (@ARGV) {
6152         last unless $ARGV[0] =~ m/^-/;
6153         $_ = shift @ARGV;
6154         last if m/^--?$/;
6155         if (m/^--require-valid-signature$/) {
6156             $needsig = 1;
6157         } else {
6158             badusage "unknown dgit import-dsc sub-option \`$_'";
6159         }
6160     }
6161
6162     badusage "usage: dgit import-dsc .../PATH/TO/.DSC BRANCH" unless @ARGV==2;
6163     my ($dscfn, $dstbranch) = @ARGV;
6164
6165     badusage "dry run makes no sense with import-dsc" unless act_local();
6166
6167     my $force = $dstbranch =~ s/^\+//   ? +1 :
6168                 $dstbranch =~ s/^\.\.// ? -1 :
6169                                            0;
6170     my $info = $force ? " $&" : '';
6171     $info = "$dscfn$info";
6172
6173     my $specbranch = $dstbranch;
6174     $dstbranch = "refs/heads/$dstbranch" unless $dstbranch =~ m#^refs/#;
6175     $dstbranch = cmdoutput @git, qw(check-ref-format --normalize), $dstbranch;
6176
6177     my @symcmd = (@git, qw(symbolic-ref -q HEAD));
6178     my $chead = cmdoutput_errok @symcmd;
6179     defined $chead or $?==256 or failedcmd @symcmd;
6180
6181     fail "$dstbranch is checked out - will not update it"
6182         if defined $chead and $chead eq $dstbranch;
6183
6184     my $oldhash = git_get_ref $dstbranch;
6185
6186     open D, "<", $dscfn or fail "open import .dsc ($dscfn): $!";
6187     $dscdata = do { local $/ = undef; <D>; };
6188     D->error and fail "read $dscfn: $!";
6189     close C;
6190
6191     # we don't normally need this so import it here
6192     use Dpkg::Source::Package;
6193     my $dp = new Dpkg::Source::Package filename => $dscfn,
6194         require_valid_signature => $needsig;
6195     {
6196         local $SIG{__WARN__} = sub {
6197             print STDERR $_[0];
6198             return unless $needsig;
6199             fail "import-dsc signature check failed";
6200         };
6201         if (!$dp->is_signed()) {
6202             warn "$us: warning: importing unsigned .dsc\n";
6203         } else {
6204             my $r = $dp->check_signature();
6205             die "->check_signature => $r" if $needsig && $r;
6206         }
6207     }
6208
6209     parse_dscdata();
6210
6211     $package = getfield $dsc, 'Source';
6212
6213     parse_dsc_field($dsc, "Dgit metadata in .dsc")
6214         unless forceing [qw(import-dsc-with-dgit-field)];
6215     parse_dsc_field_def_dsc_distro();
6216
6217     $isuite = 'DGIT-IMPORT-DSC';
6218     $idistro //= $dsc_distro;
6219
6220     notpushing();
6221
6222     if (defined $dsc_hash) {
6223         progress "dgit: import-dsc of .dsc with Dgit field, using git hash";
6224         resolve_dsc_field_commit undef, undef;
6225     }
6226     if (defined $dsc_hash) {
6227         my @cmd = (qw(sh -ec),
6228                    "echo $dsc_hash | git cat-file --batch-check");
6229         my $objgot = cmdoutput @cmd;
6230         if ($objgot =~ m#^\w+ missing\b#) {
6231             fail <<END
6232 .dsc contains Dgit field referring to object $dsc_hash
6233 Your git tree does not have that object.  Try `git fetch' from a
6234 plausible server (browse.dgit.d.o? alioth?), and try the import-dsc again.
6235 END
6236         }
6237         if ($oldhash && !is_fast_fwd $oldhash, $dsc_hash) {
6238             if ($force > 0) {
6239                 progress "Not fast forward, forced update.";
6240             } else {
6241                 fail "Not fast forward to $dsc_hash";
6242             }
6243         }
6244         import_dsc_result $dstbranch, $dsc_hash,
6245             "dgit import-dsc (Dgit): $info",
6246             "updated git ref $dstbranch";
6247         return 0;
6248     }
6249
6250     fail <<END
6251 Branch $dstbranch already exists
6252 Specify ..$specbranch for a pseudo-merge, binding in existing history
6253 Specify  +$specbranch to overwrite, discarding existing history
6254 END
6255         if $oldhash && !$force;
6256
6257     my @dfi = dsc_files_info();
6258     foreach my $fi (@dfi) {
6259         my $f = $fi->{Filename};
6260         my $here = "../$f";
6261         next if lstat $here;
6262         fail "stat $here: $!" unless $! == ENOENT;
6263         my $there = $dscfn;
6264         if ($dscfn =~ m#^(?:\./+)?\.\./+#) {
6265             $there = $';
6266         } elsif ($dscfn =~ m#^/#) {
6267             $there = $dscfn;
6268         } else {
6269             fail "cannot import $dscfn which seems to be inside working tree!";
6270         }
6271         $there =~ s#/+[^/]+$## or
6272             fail "cannot import $dscfn which seems to not have a basename";
6273         $there .= "/$f";
6274         symlink $there, $here or fail "symlink $there to $here: $!";
6275         progress "made symlink $here -> $there";
6276 #       print STDERR Dumper($fi);
6277     }
6278     my @mergeinputs = generate_commits_from_dsc();
6279     die unless @mergeinputs == 1;
6280
6281     my $newhash = $mergeinputs[0]{Commit};
6282
6283     if ($oldhash) {
6284         if ($force > 0) {
6285             progress "Import, forced update - synthetic orphan git history.";
6286         } elsif ($force < 0) {
6287             progress "Import, merging.";
6288             my $tree = cmdoutput @git, qw(rev-parse), "$newhash:";
6289             my $version = getfield $dsc, 'Version';
6290             my $clogp = commit_getclogp $newhash;
6291             my $authline = clogp_authline $clogp;
6292             $newhash = make_commit_text <<END;
6293 tree $tree
6294 parent $newhash
6295 parent $oldhash
6296 author $authline
6297 committer $authline
6298
6299 Merge $package ($version) import into $dstbranch
6300 END
6301         } else {
6302             die; # caught earlier
6303         }
6304     }
6305
6306     import_dsc_result $dstbranch, $newhash,
6307         "dgit import-dsc: $info",
6308         "results are in in git ref $dstbranch";
6309 }
6310
6311 sub cmd_archive_api_query {
6312     badusage "need only 1 subpath argument" unless @ARGV==1;
6313     my ($subpath) = @ARGV;
6314     my @cmd = archive_api_query_cmd($subpath);
6315     push @cmd, qw(-f);
6316     debugcmd ">",@cmd;
6317     exec @cmd or fail "exec curl: $!\n";
6318 }
6319
6320 sub repos_server_url () {
6321     $package = '_dgit-repos-server';
6322     local $access_forpush = 1;
6323     local $isuite = 'DGIT-REPOS-SERVER';
6324     my $url = access_giturl();
6325 }
6326
6327 sub cmd_clone_dgit_repos_server {
6328     badusage "need destination argument" unless @ARGV==1;
6329     my ($destdir) = @ARGV;
6330     my $url = repos_server_url();
6331     my @cmd = (@git, qw(clone), $url, $destdir);
6332     debugcmd ">",@cmd;
6333     exec @cmd or fail "exec git clone: $!\n";
6334 }
6335
6336 sub cmd_print_dgit_repos_server_source_url {
6337     badusage "no arguments allowed to dgit print-dgit-repos-server-source-url"
6338         if @ARGV;
6339     my $url = repos_server_url();
6340     print $url, "\n" or die $!;
6341 }
6342
6343 sub cmd_setup_mergechangelogs {
6344     badusage "no arguments allowed to dgit setup-mergechangelogs" if @ARGV;
6345     local $isuite = 'DGIT-SETUP-TREE';
6346     setup_mergechangelogs(1);
6347 }
6348
6349 sub cmd_setup_useremail {
6350     badusage "no arguments allowed to dgit setup-useremail" if @ARGV;
6351     local $isuite = 'DGIT-SETUP-TREE';
6352     setup_useremail(1);
6353 }
6354
6355 sub cmd_setup_gitattributes {
6356     badusage "no arguments allowed to dgit setup-useremail" if @ARGV;
6357     local $isuite = 'DGIT-SETUP-TREE';
6358     setup_gitattrs(1);
6359 }
6360
6361 sub cmd_setup_new_tree {
6362     badusage "no arguments allowed to dgit setup-tree" if @ARGV;
6363     local $isuite = 'DGIT-SETUP-TREE';
6364     setup_new_tree();
6365 }
6366
6367 #---------- argument parsing and main program ----------
6368
6369 sub cmd_version {
6370     print "dgit version $our_version\n" or die $!;
6371     exit 0;
6372 }
6373
6374 our (%valopts_long, %valopts_short);
6375 our (%funcopts_long);
6376 our @rvalopts;
6377 our (@modeopt_cfgs);
6378
6379 sub defvalopt ($$$$) {
6380     my ($long,$short,$val_re,$how) = @_;
6381     my $oi = { Long => $long, Short => $short, Re => $val_re, How => $how };
6382     $valopts_long{$long} = $oi;
6383     $valopts_short{$short} = $oi;
6384     # $how subref should:
6385     #   do whatever assignemnt or thing it likes with $_[0]
6386     #   if the option should not be passed on to remote, @rvalopts=()
6387     # or $how can be a scalar ref, meaning simply assign the value
6388 }
6389
6390 defvalopt '--since-version', '-v', '[^_]+|_', \$changes_since_version;
6391 defvalopt '--distro',        '-d', '.+',      \$idistro;
6392 defvalopt '',                '-k', '.+',      \$keyid;
6393 defvalopt '--existing-package','', '.*',      \$existing_package;
6394 defvalopt '--build-products-dir','','.*',     \$buildproductsdir;
6395 defvalopt '--clean',       '', $cleanmode_re, \$cleanmode;
6396 defvalopt '--package',   '-p',   $package_re, \$package;
6397 defvalopt '--quilt',     '', $quilt_modes_re, \$quilt_mode;
6398
6399 defvalopt '', '-C', '.+', sub {
6400     ($changesfile) = (@_);
6401     if ($changesfile =~ s#^(.*)/##) {
6402         $buildproductsdir = $1;
6403     }
6404 };
6405
6406 defvalopt '--initiator-tempdir','','.*', sub {
6407     ($initiator_tempdir) = (@_);
6408     $initiator_tempdir =~ m#^/# or
6409         badusage "--initiator-tempdir must be used specify an".
6410         " absolute, not relative, directory."
6411 };
6412
6413 sub defoptmodes ($@) {
6414     my ($varref, $cfgkey, $default, %optmap) = @_;
6415     my %permit;
6416     while (my ($opt,$val) = each %optmap) {
6417         $funcopts_long{$opt} = sub { $$varref = $val; };
6418         $permit{$val} = $val;
6419     }
6420     push @modeopt_cfgs, {
6421         Var => $varref,
6422         Key => $cfgkey,
6423         Default => $default,
6424         Vals => \%permit
6425     };
6426 }
6427
6428 defoptmodes \$dodep14tag, qw( dep14tag          want
6429                               --dep14tag        want
6430                               --no-dep14tag     no
6431                               --always-dep14tag always );
6432
6433 sub parseopts () {
6434     my $om;
6435
6436     if (defined $ENV{'DGIT_SSH'}) {
6437         @ssh = string_to_ssh $ENV{'DGIT_SSH'};
6438     } elsif (defined $ENV{'GIT_SSH'}) {
6439         @ssh = ($ENV{'GIT_SSH'});
6440     }
6441
6442     my $oi;
6443     my $val;
6444     my $valopt = sub {
6445         my ($what) = @_;
6446         @rvalopts = ($_);
6447         if (!defined $val) {
6448             badusage "$what needs a value" unless @ARGV;
6449             $val = shift @ARGV;
6450             push @rvalopts, $val;
6451         }
6452         badusage "bad value \`$val' for $what" unless
6453             $val =~ m/^$oi->{Re}$(?!\n)/s;
6454         my $how = $oi->{How};
6455         if (ref($how) eq 'SCALAR') {
6456             $$how = $val;
6457         } else {
6458             $how->($val);
6459         }
6460         push @ropts, @rvalopts;
6461     };
6462
6463     while (@ARGV) {
6464         last unless $ARGV[0] =~ m/^-/;
6465         $_ = shift @ARGV;
6466         last if m/^--?$/;
6467         if (m/^--/) {
6468             if (m/^--dry-run$/) {
6469                 push @ropts, $_;
6470                 $dryrun_level=2;
6471             } elsif (m/^--damp-run$/) {
6472                 push @ropts, $_;
6473                 $dryrun_level=1;
6474             } elsif (m/^--no-sign$/) {
6475                 push @ropts, $_;
6476                 $sign=0;
6477             } elsif (m/^--help$/) {
6478                 cmd_help();
6479             } elsif (m/^--version$/) {
6480                 cmd_version();
6481             } elsif (m/^--new$/) {
6482                 push @ropts, $_;
6483                 $new_package=1;
6484             } elsif (m/^--([-0-9a-z]+)=(.+)/s &&
6485                      ($om = $opts_opt_map{$1}) &&
6486                      length $om->[0]) {
6487                 push @ropts, $_;
6488                 $om->[0] = $2;
6489             } elsif (m/^--([-0-9a-z]+):(.*)/s &&
6490                      !$opts_opt_cmdonly{$1} &&
6491                      ($om = $opts_opt_map{$1})) {
6492                 push @ropts, $_;
6493                 push @$om, $2;
6494             } elsif (m/^--(gbp|dpm)$/s) {
6495                 push @ropts, "--quilt=$1";
6496                 $quilt_mode = $1;
6497             } elsif (m/^--ignore-dirty$/s) {
6498                 push @ropts, $_;
6499                 $ignoredirty = 1;
6500             } elsif (m/^--no-quilt-fixup$/s) {
6501                 push @ropts, $_;
6502                 $quilt_mode = 'nocheck';
6503             } elsif (m/^--no-rm-on-error$/s) {
6504                 push @ropts, $_;
6505                 $rmonerror = 0;
6506             } elsif (m/^--no-chase-dsc-distro$/s) {
6507                 push @ropts, $_;
6508                 $chase_dsc_distro = 0;
6509             } elsif (m/^--overwrite$/s) {
6510                 push @ropts, $_;
6511                 $overwrite_version = '';
6512             } elsif (m/^--overwrite=(.+)$/s) {
6513                 push @ropts, $_;
6514                 $overwrite_version = $1;
6515             } elsif (m/^--delayed=(\d+)$/s) {
6516                 push @ropts, $_;
6517                 push @dput, $_;
6518             } elsif (m/^--dgit-view-save=(.+)$/s) {
6519                 push @ropts, $_;
6520                 $split_brain_save = $1;
6521                 $split_brain_save =~ s#^(?!refs/)#refs/heads/#;
6522             } elsif (m/^--(no-)?rm-old-changes$/s) {
6523                 push @ropts, $_;
6524                 $rmchanges = !$1;
6525             } elsif (m/^--deliberately-($deliberately_re)$/s) {
6526                 push @ropts, $_;
6527                 push @deliberatelies, $&;
6528             } elsif (m/^--force-(.*)/ && defined $forceopts{$1}) {
6529                 push @ropts, $&;
6530                 $forceopts{$1} = 1;
6531                 $_='';
6532             } elsif (m/^--force-/) {
6533                 print STDERR
6534                     "$us: warning: ignoring unknown force option $_\n";
6535                 $_='';
6536             } elsif (m/^--dgit-tag-format=(old|new)$/s) {
6537                 # undocumented, for testing
6538                 push @ropts, $_;
6539                 $tagformat_want = [ $1, 'command line', 1 ];
6540                 # 1 menas overrides distro configuration
6541             } elsif (m/^--always-split-source-build$/s) {
6542                 # undocumented, for testing
6543                 push @ropts, $_;
6544                 $need_split_build_invocation = 1;
6545             } elsif (m/^--config-lookup-explode=(.+)$/s) {
6546                 # undocumented, for testing
6547                 push @ropts, $_;
6548                 $gitcfgs{cmdline}{$1} = 'CONFIG-LOOKUP-EXPLODE';
6549                 # ^ it's supposed to be an array ref
6550             } elsif (m/^(--[-0-9a-z]+)(=|$)/ && ($oi = $valopts_long{$1})) {
6551                 $val = $2 ? $' : undef; #';
6552                 $valopt->($oi->{Long});
6553             } elsif ($funcopts_long{$_}) {
6554                 push @ropts, $_;
6555                 $funcopts_long{$_}();
6556             } else {
6557                 badusage "unknown long option \`$_'";
6558             }
6559         } else {
6560             while (m/^-./s) {
6561                 if (s/^-n/-/) {
6562                     push @ropts, $&;
6563                     $dryrun_level=2;
6564                 } elsif (s/^-L/-/) {
6565                     push @ropts, $&;
6566                     $dryrun_level=1;
6567                 } elsif (s/^-h/-/) {
6568                     cmd_help();
6569                 } elsif (s/^-D/-/) {
6570                     push @ropts, $&;
6571                     $debuglevel++;
6572                     enabledebug();
6573                 } elsif (s/^-N/-/) {
6574                     push @ropts, $&;
6575                     $new_package=1;
6576                 } elsif (m/^-m/) {
6577                     push @ropts, $&;
6578                     push @changesopts, $_;
6579                     $_ = '';
6580                 } elsif (s/^-wn$//s) {
6581                     push @ropts, $&;
6582                     $cleanmode = 'none';
6583                 } elsif (s/^-wg$//s) {
6584                     push @ropts, $&;
6585                     $cleanmode = 'git';
6586                 } elsif (s/^-wgf$//s) {
6587                     push @ropts, $&;
6588                     $cleanmode = 'git-ff';
6589                 } elsif (s/^-wd$//s) {
6590                     push @ropts, $&;
6591                     $cleanmode = 'dpkg-source';
6592                 } elsif (s/^-wdd$//s) {
6593                     push @ropts, $&;
6594                     $cleanmode = 'dpkg-source-d';
6595                 } elsif (s/^-wc$//s) {
6596                     push @ropts, $&;
6597                     $cleanmode = 'check';
6598                 } elsif (s/^-c([^=]*)\=(.*)$//s) {
6599                     push @git, '-c', $&;
6600                     $gitcfgs{cmdline}{$1} = [ $2 ];
6601                 } elsif (s/^-c([^=]+)$//s) {
6602                     push @git, '-c', $&;
6603                     $gitcfgs{cmdline}{$1} = [ 'true' ];
6604                 } elsif (m/^-[a-zA-Z]/ && ($oi = $valopts_short{$&})) {
6605                     $val = $'; #';
6606                     $val = undef unless length $val;
6607                     $valopt->($oi->{Short});
6608                     $_ = '';
6609                 } else {
6610                     badusage "unknown short option \`$_'";
6611                 }
6612             }
6613         }
6614     }
6615 }
6616
6617 sub check_env_sanity () {
6618     my $blocked = new POSIX::SigSet;
6619     sigprocmask SIG_UNBLOCK, $blocked, $blocked or die $!;
6620
6621     eval {
6622         foreach my $name (qw(PIPE CHLD)) {
6623             my $signame = "SIG$name";
6624             my $signum = eval "POSIX::$signame" // die;
6625             ($SIG{$name} // 'DEFAULT') eq 'DEFAULT' or
6626                 die "$signame is set to something other than SIG_DFL\n";
6627             $blocked->ismember($signum) and
6628                 die "$signame is blocked\n";
6629         }
6630     };
6631     return unless $@;
6632     chomp $@;
6633     fail <<END;
6634 On entry to dgit, $@
6635 This is a bug produced by something in in your execution environment.
6636 Giving up.
6637 END
6638 }
6639
6640
6641 sub parseopts_late_defaults () {
6642     $isuite //= cfg("dgit-distro.$idistro.default-suite", 'RETURN-UNDEF')
6643         if defined $idistro;
6644     $isuite //= cfg('dgit.default.default-suite');
6645
6646     foreach my $k (keys %opts_opt_map) {
6647         my $om = $opts_opt_map{$k};
6648
6649         my $v = access_cfg("cmd-$k", 'RETURN-UNDEF');
6650         if (defined $v) {
6651             badcfg "cannot set command for $k"
6652                 unless length $om->[0];
6653             $om->[0] = $v;
6654         }
6655
6656         foreach my $c (access_cfg_cfgs("opts-$k")) {
6657             my @vl =
6658                 map { $_ ? @$_ : () }
6659                 map { $gitcfgs{$_}{$c} }
6660                 reverse @gitcfgsources;
6661             printdebug "CL $c ", (join " ", map { shellquote } @vl),
6662                 "\n" if $debuglevel >= 4;
6663             next unless @vl;
6664             badcfg "cannot configure options for $k"
6665                 if $opts_opt_cmdonly{$k};
6666             my $insertpos = $opts_cfg_insertpos{$k};
6667             @$om = ( @$om[0..$insertpos-1],
6668                      @vl,
6669                      @$om[$insertpos..$#$om] );
6670         }
6671     }
6672
6673     if (!defined $rmchanges) {
6674         local $access_forpush;
6675         $rmchanges = access_cfg_bool(0, 'rm-old-changes');
6676     }
6677
6678     if (!defined $quilt_mode) {
6679         local $access_forpush;
6680         $quilt_mode = cfg('dgit.force.quilt-mode', 'RETURN-UNDEF')
6681             // access_cfg('quilt-mode', 'RETURN-UNDEF')
6682             // 'linear';
6683         $quilt_mode =~ m/^($quilt_modes_re)$/
6684             or badcfg "unknown quilt-mode \`$quilt_mode'";
6685         $quilt_mode = $1;
6686     }
6687
6688     foreach my $moc (@modeopt_cfgs) {
6689         local $access_forpush;
6690         my $vr = $moc->{Var};
6691         next if defined $$vr;
6692         $$vr = access_cfg($moc->{Key}, 'RETURN-UNDEF') // $moc->{Default};
6693         my $v = $moc->{Vals}{$$vr};
6694         badcfg "unknown $moc->{Key} setting \`$$vr'" unless defined $v;
6695         $$vr = $v;
6696     }
6697
6698     $need_split_build_invocation ||= quiltmode_splitbrain();
6699
6700     if (!defined $cleanmode) {
6701         local $access_forpush;
6702         $cleanmode = access_cfg('clean-mode', 'RETURN-UNDEF');
6703         $cleanmode //= 'dpkg-source';
6704
6705         badcfg "unknown clean-mode \`$cleanmode'" unless
6706             $cleanmode =~ m/^($cleanmode_re)$(?!\n)/s;
6707     }
6708 }
6709
6710 if ($ENV{$fakeeditorenv}) {
6711     git_slurp_config();
6712     quilt_fixup_editor();
6713 }
6714
6715 parseopts();
6716 check_env_sanity();
6717 git_slurp_config();
6718
6719 print STDERR "DRY RUN ONLY\n" if $dryrun_level > 1;
6720 print STDERR "DAMP RUN - WILL MAKE LOCAL (UNSIGNED) CHANGES\n"
6721     if $dryrun_level == 1;
6722 if (!@ARGV) {
6723     print STDERR $helpmsg or die $!;
6724     exit 8;
6725 }
6726 my $cmd = shift @ARGV;
6727 $cmd =~ y/-/_/;
6728
6729 my $pre_fn = ${*::}{"pre_$cmd"};
6730 $pre_fn->() if $pre_fn;
6731
6732 my $fn = ${*::}{"cmd_$cmd"};
6733 $fn or badusage "unknown operation $cmd";
6734 $fn->();