dgit

   1 #!/usr/bin/perl -w
   2 # dgit
   3 # Integration between git and Debian-style archives
   4 #
   5 # Copyright (C)2013-2015 Ian Jackson
   6 #
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 use strict;
  21
  22 use Debian::Dgit;
  23 setup_sigwarn();
  24
  25 use IO::Handle;
  26 use Data::Dumper;
  27 use LWP::UserAgent;
  28 use Dpkg::Control::Hash;
  29 use File::Path;
  30 use File::Temp qw(tempdir);
  31 use File::Basename;
  32 use Dpkg::Version;
  33 use POSIX;
  34 use IPC::Open2;
  35 use Digest::SHA;
  36 use Digest::MD5;
  37
  38 use Debian::Dgit;
  39
  40 our $our_version = 'UNRELEASED'; ###substituted###
  41
  42 our @rpushprotovsn_support = qw(3 2);
  43 our $protovsn;
  44
  45 our $isuite = 'unstable';
  46 our $idistro;
  47 our $package;
  48 our @ropts;
  49
  50 our $sign = 1;
  51 our $dryrun_level = 0;
  52 our $changesfile;
  53 our $buildproductsdir = '..';
  54 our $new_package = 0;
  55 our $ignoredirty = 0;
  56 our $rmonerror = 1;
  57 our @deliberatelies;
  58 our %previously;
  59 our $existing_package = 'dpkg';
  60 our $cleanmode = 'dpkg-source';
  61 our $changes_since_version;
  62 our $quilt_mode;
  63 our $quilt_modes_re = 'linear|smash|auto|nofix|nocheck';
  64 our $we_are_responder;
  65 our $initiator_tempdir;
  66
  67 our %format_ok = map { $_=>1 } ("1.0","3.0 (native)","3.0 (quilt)");
  68
  69 our $suite_re = '[-+.0-9a-z]+';
  70
  71 our (@git) = qw(git);
  72 our (@dget) = qw(dget);
  73 our (@curl) = qw(curl -f);
  74 our (@dput) = qw(dput);
  75 our (@debsign) = qw(debsign);
  76 our (@gpg) = qw(gpg);
  77 our (@sbuild) = qw(sbuild -A);
  78 our (@ssh) = 'ssh';
  79 our (@dgit) = qw(dgit);
  80 our (@dpkgbuildpackage) = qw(dpkg-buildpackage -i\.git/ -I.git);
  81 our (@dpkgsource) = qw(dpkg-source -i\.git/ -I.git);
  82 our (@dpkggenchanges) = qw(dpkg-genchanges);
  83 our (@mergechanges) = qw(mergechanges -f);
  84 our (@changesopts) = ('');
  85
  86 our %opts_opt_map = ('dget' => \@dget, # accept for compatibility
  87                      'curl' => \@curl,
  88                      'dput' => \@dput,
  89                      'debsign' => \@debsign,
  90                      'gpg' => \@gpg,
  91                      'sbuild' => \@sbuild,
  92                      'ssh' => \@ssh,
  93                      'dgit' => \@dgit,
  94                      'dpkg-source' => \@dpkgsource,
  95                      'dpkg-buildpackage' => \@dpkgbuildpackage,
  96                      'dpkg-genchanges' => \@dpkggenchanges,
  97                      'ch' => \@changesopts,
  98                      'mergechanges' => \@mergechanges);
  99
 100 our %opts_opt_cmdonly = ('gpg' => 1);
 101 our %opts_cfg_insertpos = map {
 102     $_,
 103     scalar @{ $opts_opt_map{$_} }
 104 } keys %opts_opt_map;
 105
 106 sub finalise_opts_opts();
 107
 108 our $keyid;
 109
 110 autoflush STDOUT 1;
 111
 112 our $supplementary_message = '';
 113
 114 END {
 115     local ($@, $?);
 116     print STDERR "! $_\n" foreach $supplementary_message =~ m/^.+$/mg;
 117 }
 118
 119 our $remotename = 'dgit';
 120 our @ourdscfield = qw(Dgit Vcs-Dgit-Master);
 121 our $csuite;
 122 our $instead_distro;
 123
 124 sub lbranch () { return "$branchprefix/$csuite"; }
 125 my $lbranch_re = '^refs/heads/'.$branchprefix.'/([^/.]+)$';
 126 sub lref () { return "refs/heads/".lbranch(); }
 127 sub lrref () { return "refs/remotes/$remotename/".server_branch($csuite); }
 128 sub rrref () { return server_ref($csuite); }
 129
 130 sub lrfetchrefs () { return "refs/dgit-fetch/$csuite"; }
 131
 132 sub stripepoch ($) {
 133     my ($vsn) = @_;
 134     $vsn =~ s/^\d+\://;
 135     return $vsn;
 136 }
 137
 138 sub srcfn ($$) {
 139     my ($vsn,$sfx) = @_;
 140     return "${package}_".(stripepoch $vsn).$sfx
 141 }
 142
 143 sub dscfn ($) {
 144     my ($vsn) = @_;
 145     return srcfn($vsn,".dsc");
 146 }
 147
 148 our $us = 'dgit';
 149 initdebug('');
 150
 151 our @end;
 152 END {
 153     local ($?);
 154     foreach my $f (@end) {
 155         eval { $f->(); };
 156         warn "$us: cleanup: $@" if length $@;
 157     }
 158 };
 159
 160 sub badcfg { print STDERR "$us: invalid configuration: @_\n"; exit 12; }
 161
 162 sub no_such_package () {
 163     print STDERR "$us: package $package does not exist in suite $isuite\n";
 164     exit 4;
 165 }
 166
 167 sub fetchspec () {
 168     local $csuite = '*';
 169     return  "+".rrref().":".lrref();
 170 }
 171
 172 sub changedir ($) {
 173     my ($newdir) = @_;
 174     printdebug "CD $newdir\n";
 175     chdir $newdir or die "chdir: $newdir: $!";
 176 }
 177
 178 sub deliberately ($) {
 179     my ($enquiry) = @_;
 180     return !!grep { $_ eq "--deliberately-$enquiry" } @deliberatelies;
 181 }
 182
 183 sub deliberately_not_fast_forward () {
 184     foreach (qw(not-fast-forward fresh-repo)) {
 185         return 1 if deliberately($_) || deliberately("TEST-dgit-only-$_");
 186     }
 187 }
 188
 189 #---------- remote protocol support, common ----------
 190
 191 # remote push initiator/responder protocol:
 192 #  $ dgit remote-push-build-host <n-rargs> <rargs>... <push-args>...
 193 #  where <rargs> is <push-host-dir> <supported-proto-vsn>,... ...
 194 #  < dgit-remote-push-ready <actual-proto-vsn>
 195 #
 196 #  > file parsed-changelog
 197 #  [indicates that output of dpkg-parsechangelog follows]
 198 #  > data-block NBYTES
 199 #  > [NBYTES bytes of data (no newline)]
 200 #  [maybe some more blocks]
 201 #  > data-end
 202 #
 203 #  > file dsc
 204 #  [etc]
 205 #
 206 #  > file changes
 207 #  [etc]
 208 #
 209 #  > param head HEAD
 210 #
 211 #  > want signed-tag
 212 #  [indicates that signed tag is wanted]
 213 #  < data-block NBYTES
 214 #  < [NBYTES bytes of data (no newline)]
 215 #  [maybe some more blocks]
 216 #  < data-end
 217 #  < files-end
 218 #
 219 #  > want signed-dsc-changes
 220 #  < data-block NBYTES    [transfer of signed dsc]
 221 #  [etc]
 222 #  < data-block NBYTES    [transfer of signed changes]
 223 #  [etc]
 224 #  < files-end
 225 #
 226 #  > complete
 227
 228 our $i_child_pid;
 229
 230 sub i_child_report () {
 231     # Sees if our child has died, and reap it if so.  Returns a string
 232     # describing how it died if it failed, or undef otherwise.
 233     return undef unless $i_child_pid;
 234     my $got = waitpid $i_child_pid, WNOHANG;
 235     return undef if $got <= 0;
 236     die unless $got == $i_child_pid;
 237     $i_child_pid = undef;
 238     return undef unless $?;
 239     return "build host child ".waitstatusmsg();
 240 }
 241
 242 sub badproto ($$) {
 243     my ($fh, $m) = @_;
 244     fail "connection lost: $!" if $fh->error;
 245     fail "protocol violation; $m not expected";
 246 }
 247
 248 sub badproto_badread ($$) {
 249     my ($fh, $wh) = @_;
 250     fail "connection lost: $!" if $!;
 251     my $report = i_child_report();
 252     fail $report if defined $report;
 253     badproto $fh, "eof (reading $wh)";
 254 }
 255
 256 sub protocol_expect (&$) {
 257     my ($match, $fh) = @_;
 258     local $_;
 259     $_ = <$fh>;
 260     defined && chomp or badproto_badread $fh, "protocol message";
 261     if (wantarray) {
 262         my @r = &$match;
 263         return @r if @r;
 264     } else {
 265         my $r = &$match;
 266         return $r if $r;
 267     }
 268     badproto $fh, "\`$_'";
 269 }
 270
 271 sub protocol_send_file ($$) {
 272     my ($fh, $ourfn) = @_;
 273     open PF, "<", $ourfn or die "$ourfn: $!";
 274     for (;;) {
 275         my $d;
 276         my $got = read PF, $d, 65536;
 277         die "$ourfn: $!" unless defined $got;
 278         last if !$got;
 279         print $fh "data-block ".length($d)."\n" or die $!;
 280         print $fh $d or die $!;
 281     }
 282     PF->error and die "$ourfn $!";
 283     print $fh "data-end\n" or die $!;
 284     close PF;
 285 }
 286
 287 sub protocol_read_bytes ($$) {
 288     my ($fh, $nbytes) = @_;
 289     $nbytes =~ m/^[1-9]\d{0,5}$|^0$/ or badproto \*RO, "bad byte count";
 290     my $d;
 291     my $got = read $fh, $d, $nbytes;
 292     $got==$nbytes or badproto_badread $fh, "data block";
 293     return $d;
 294 }
 295
 296 sub protocol_receive_file ($$) {
 297     my ($fh, $ourfn) = @_;
 298     printdebug "() $ourfn\n";
 299     open PF, ">", $ourfn or die "$ourfn: $!";
 300     for (;;) {
 301         my ($y,$l) = protocol_expect {
 302             m/^data-block (.*)$/ ? (1,$1) :
 303             m/^data-end$/ ? (0,) :
 304             ();
 305         } $fh;
 306         last unless $y;
 307         my $d = protocol_read_bytes $fh, $l;
 308         print PF $d or die $!;
 309     }
 310     close PF or die $!;
 311 }
 312
 313 #---------- remote protocol support, responder ----------
 314
 315 sub responder_send_command ($) {
 316     my ($command) = @_;
 317     return unless $we_are_responder;
 318     # called even without $we_are_responder
 319     printdebug ">> $command\n";
 320     print PO $command, "\n" or die $!;
 321 }
 322
 323 sub responder_send_file ($$) {
 324     my ($keyword, $ourfn) = @_;
 325     return unless $we_are_responder;
 326     printdebug "]] $keyword $ourfn\n";
 327     responder_send_command "file $keyword";
 328     protocol_send_file \*PO, $ourfn;
 329 }
 330
 331 sub responder_receive_files ($@) {
 332     my ($keyword, @ourfns) = @_;
 333     die unless $we_are_responder;
 334     printdebug "[[ $keyword @ourfns\n";
 335     responder_send_command "want $keyword";
 336     foreach my $fn (@ourfns) {
 337         protocol_receive_file \*PI, $fn;
 338     }
 339     printdebug "[[\$\n";
 340     protocol_expect { m/^files-end$/ } \*PI;
 341 }
 342
 343 #---------- remote protocol support, initiator ----------
 344
 345 sub initiator_expect (&) {
 346     my ($match) = @_;
 347     protocol_expect { &$match } \*RO;
 348 }
 349
 350 #---------- end remote code ----------
 351
 352 sub progress {
 353     if ($we_are_responder) {
 354         my $m = join '', @_;
 355         responder_send_command "progress ".length($m) or die $!;
 356         print PO $m or die $!;
 357     } else {
 358         print @_, "\n";
 359     }
 360 }
 361
 362 our $ua;
 363
 364 sub url_get {
 365     if (!$ua) {
 366         $ua = LWP::UserAgent->new();
 367         $ua->env_proxy;
 368     }
 369     my $what = $_[$#_];
 370     progress "downloading $what...";
 371     my $r = $ua->get(@_) or die $!;
 372     return undef if $r->code == 404;
 373     $r->is_success or fail "failed to fetch $what: ".$r->status_line;
 374     return $r->decoded_content(charset => 'none');
 375 }
 376
 377 our ($dscdata,$dscurl,$dsc,$dsc_checked,$skew_warning_vsn);
 378
 379 sub runcmd {
 380     debugcmd "+",@_;
 381     $!=0; $?=0;
 382     failedcmd @_ if system @_;
 383 }
 384
 385 sub act_local () { return $dryrun_level <= 1; }
 386 sub act_scary () { return !$dryrun_level; }
 387
 388 sub printdone {
 389     if (!$dryrun_level) {
 390         progress "dgit ok: @_";
 391     } else {
 392         progress "would be ok: @_ (but dry run only)";
 393     }
 394 }
 395
 396 sub dryrun_report {
 397     printcmd(\*STDERR,$debugprefix."#",@_);
 398 }
 399
 400 sub runcmd_ordryrun {
 401     if (act_scary()) {
 402         runcmd @_;
 403     } else {
 404         dryrun_report @_;
 405     }
 406 }
 407
 408 sub runcmd_ordryrun_local {
 409     if (act_local()) {
 410         runcmd @_;
 411     } else {
 412         dryrun_report @_;
 413     }
 414 }
 415
 416 sub shell_cmd {
 417     my ($first_shell, @cmd) = @_;
 418     return qw(sh -ec), $first_shell.'; exec "$@"', 'x', @cmd;
 419 }
 420
 421 our $helpmsg = <<END;
 422 main usages:
 423   dgit [dgit-opts] clone [dgit-opts] package [suite] [./dir|/dir]
 424   dgit [dgit-opts] fetch|pull [dgit-opts] [suite]
 425   dgit [dgit-opts] build [git-buildpackage-opts|dpkg-buildpackage-opts]
 426   dgit [dgit-opts] push [dgit-opts] [suite]
 427   dgit [dgit-opts] rpush build-host:build-dir ...
 428 important dgit options:
 429   -k<keyid>           sign tag and package with <keyid> instead of default
 430   --dry-run -n        do not change anything, but go through the motions
 431   --damp-run -L       like --dry-run but make local changes, without signing
 432   --new -N            allow introducing a new package
 433   --debug -D          increase debug level
 434   -c<name>=<value>    set git config option (used directly by dgit too)
 435 END
 436
 437 our $later_warning_msg = <<END;
 438 Perhaps the upload is stuck in incoming.  Using the version from git.
 439 END
 440
 441 sub badusage {
 442     print STDERR "$us: @_\n", $helpmsg or die $!;
 443     exit 8;
 444 }
 445
 446 sub nextarg {
 447     @ARGV or badusage "too few arguments";
 448     return scalar shift @ARGV;
 449 }
 450
 451 sub cmd_help () {
 452     print $helpmsg or die $!;
 453     exit 0;
 454 }
 455
 456 our $td = $ENV{DGIT_TEST_DUMMY_DIR} || "DGIT_TEST_DUMMY_DIR-unset";
 457
 458 our %defcfg = ('dgit.default.distro' => 'debian',
 459                'dgit.default.username' => '',
 460                'dgit.default.archive-query-default-component' => 'main',
 461                'dgit.default.ssh' => 'ssh',
 462                'dgit.default.archive-query' => 'madison:',
 463                'dgit.default.sshpsql-dbname' => 'service=projectb',
 464                'dgit-distro.debian.archive-query' => 'ftpmasterapi:',
 465                'dgit-distro.debian.git-check' => 'url',
 466                'dgit-distro.debian.git-check-suffix' => '/info/refs',
 467                'dgit-distro.debian.new-private-pushers' => 't',
 468                'dgit-distro.debian/push.git-url' => '',
 469                'dgit-distro.debian/push.git-host' => 'push.dgit.debian.org',
 470                'dgit-distro.debian/push.git-user-force' => 'dgit',
 471                'dgit-distro.debian/push.git-proto' => 'git+ssh://',
 472                'dgit-distro.debian/push.git-path' => '/dgit/debian/repos',
 473                'dgit-distro.debian/push.git-create' => 'true',
 474                'dgit-distro.debian/push.git-check' => 'ssh-cmd',
 475  'dgit-distro.debian.archive-query-url', 'https://api.ftp-master.debian.org/',
 476 # 'dgit-distro.debian.archive-query-tls-key',
 477 #    '/etc/ssl/certs/%HOST%.pem:/etc/dgit/%HOST%.pem',
 478 # ^ this does not work because curl is broken nowadays
 479 # Fixing #790093 properly will involve providing providing the key
 480 # in some pacagke and maybe updating these paths.
 481 #
 482 # 'dgit-distro.debian.archive-query-tls-curl-args',
 483 #   '--ca-path=/etc/ssl/ca-debian',
 484 # ^ this is a workaround but works (only) on DSA-administered machines
 485                'dgit-distro.debian.git-url' => 'https://git.dgit.debian.org',
 486                'dgit-distro.debian.git-url-suffix' => '',
 487                'dgit-distro.debian.upload-host' => 'ftp-master', # for dput
 488                'dgit-distro.debian.mirror' => 'http://ftp.debian.org/debian/',
 489  'dgit-distro.debian.backports-quirk' => '(squeeze)-backports*',
 490  'dgit-distro.debian-backports.mirror' => 'http://backports.debian.org/debian-backports/',
 491                'dgit-distro.ubuntu.git-check' => 'false',
 492  'dgit-distro.ubuntu.mirror' => 'http://archive.ubuntu.com/ubuntu',
 493                'dgit-distro.test-dummy.ssh' => "$td/ssh",
 494                'dgit-distro.test-dummy.username' => "alice",
 495                'dgit-distro.test-dummy.git-check' => "ssh-cmd",
 496                'dgit-distro.test-dummy.git-create' => "ssh-cmd",
 497                'dgit-distro.test-dummy.git-url' => "$td/git",
 498                'dgit-distro.test-dummy.git-host' => "git",
 499                'dgit-distro.test-dummy.git-path' => "$td/git",
 500                'dgit-distro.test-dummy.archive-query' => "ftpmasterapi:",
 501                'dgit-distro.test-dummy.archive-query-url' => "file://$td/aq/",
 502                'dgit-distro.test-dummy.mirror' => "file://$td/mirror/",
 503                'dgit-distro.test-dummy.upload-host' => 'test-dummy',
 504                );
 505
 506 our %gitcfg;
 507
 508 sub git_slurp_config () {
 509     local ($debuglevel) = $debuglevel-2;
 510     local $/="\0";
 511
 512     my @cmd = (@git, qw(config -z --get-regexp .*));
 513     debugcmd "|",@cmd;
 514
 515     open GITS, "-|", @cmd or failedcmd @cmd;
 516     while (<GITS>) {
 517         chomp or die;
 518         printdebug "=> ", (messagequote $_), "\n";
 519         m/\n/ or die "$_ ?";
 520         push @{ $gitcfg{$`} }, $'; #';
 521     }
 522     $!=0; $?=0;
 523     close GITS
 524         or ($!==0 && $?==256)
 525         or failedcmd @cmd;
 526 }
 527
 528 sub git_get_config ($) {
 529     my ($c) = @_;
 530     my $l = $gitcfg{$c};
 531     printdebug"C $c ".(defined $l ? messagequote "'$l'" : "undef")."\n"
 532         if $debuglevel >= 4;
 533     $l or return undef;
 534     @$l==1 or badcfg "multiple values for $c" if @$l > 1;
 535     return $l->[0];
 536 }
 537
 538 sub cfg {
 539     foreach my $c (@_) {
 540         return undef if $c =~ /RETURN-UNDEF/;
 541         my $v = git_get_config($c);
 542         return $v if defined $v;
 543         my $dv = $defcfg{$c};
 544         return $dv if defined $dv;
 545     }
 546     badcfg "need value for one of: @_\n".
 547         "$us: distro or suite appears not to be (properly) supported";
 548 }
 549
 550 sub access_basedistro () {
 551     if (defined $idistro) {
 552         return $idistro;
 553     } else {
 554         return cfg("dgit-suite.$isuite.distro",
 555                    "dgit.default.distro");
 556     }
 557 }
 558
 559 sub access_quirk () {
 560     # returns (quirk name, distro to use instead or undef, quirk-specific info)
 561     my $basedistro = access_basedistro();
 562     my $backports_quirk = cfg("dgit-distro.$basedistro.backports-quirk",
 563                               'RETURN-UNDEF');
 564     if (defined $backports_quirk) {
 565         my $re = $backports_quirk;
 566         $re =~ s/[^-0-9a-z_\%*()]/\\$&/ig;
 567         $re =~ s/\*/.*/g;
 568         $re =~ s/\%/([-0-9a-z_]+)/
 569             or $re =~ m/[()]/ or badcfg "backports-quirk needs \% or ( )";
 570         if ($isuite =~ m/^$re$/) {
 571             return ('backports',"$basedistro-backports",$1);
 572         }
 573     }
 574     return ('none',undef);
 575 }
 576
 577 our $access_forpush;
 578
 579 sub parse_cfg_bool ($$$) {
 580     my ($what,$def,$v) = @_;
 581     $v //= $def;
 582     return
 583         $v =~ m/^[ty1]/ ? 1 :
 584         $v =~ m/^[fn0]/ ? 0 :
 585         badcfg "$what needs t (true, y, 1) or f (false, n, 0) not \`$v'";
 586 }
 587
 588 sub access_forpush_config () {
 589     my $d = access_basedistro();
 590
 591     return 1 if
 592         $new_package &&
 593         parse_cfg_bool('new-private-pushers', 0,
 594                        cfg("dgit-distro.$d.new-private-pushers",
 595                            'RETURN-UNDEF'));
 596
 597     my $v = cfg("dgit-distro.$d.readonly", 'RETURN-UNDEF');
 598     $v //= 'a';
 599     return
 600         $v =~ m/^[ty1]/ ? 0 : # force readonly,    forpush = 0
 601         $v =~ m/^[fn0]/ ? 1 : # force nonreadonly, forpush = 1
 602         $v =~ m/^[a]/  ? '' : # auto,              forpush = ''
 603         badcfg "readonly needs t (true, y, 1) or f (false, n, 0) or a (auto)";
 604 }
 605
 606 sub access_forpush () {
 607     $access_forpush //= access_forpush_config();
 608     return $access_forpush;
 609 }
 610
 611 sub pushing () {
 612     die "$access_forpush ?" if ($access_forpush // 1) ne 1;
 613     badcfg "pushing but distro is configured readonly"
 614         if access_forpush_config() eq '0';
 615     $access_forpush = 1;
 616     $supplementary_message = <<'END' unless $we_are_responder;
 617 Push failed, before we got started.
 618 You can retry the push, after fixing the problem, if you like.
 619 END
 620     finalise_opts_opts();
 621 }
 622
 623 sub notpushing () {
 624     finalise_opts_opts();
 625 }
 626
 627 sub supplementary_message ($) {
 628     my ($msg) = @_;
 629     if (!$we_are_responder) {
 630         $supplementary_message = $msg;
 631         return;
 632     } elsif ($protovsn >= 3) {
 633         responder_send_command "supplementary-message ".length($msg)
 634             or die $!;
 635         print PO $msg or die $!;
 636     }
 637 }
 638
 639 sub access_distros () {
 640     # Returns list of distros to try, in order
 641     #
 642     # We want to try:
 643     #    0. `instead of' distro name(s) we have been pointed to
 644     #    1. the access_quirk distro, if any
 645     #    2a. the user's specified distro, or failing that  } basedistro
 646     #    2b. the distro calculated from the suite          }
 647     my @l = access_basedistro();
 648
 649     my (undef,$quirkdistro) = access_quirk();
 650     unshift @l, $quirkdistro;
 651     unshift @l, $instead_distro;
 652     @l = grep { defined } @l;
 653
 654     if (access_forpush()) {
 655         @l = map { ("$_/push", $_) } @l;
 656     }
 657     @l;
 658 }
 659
 660 sub access_cfg_cfgs (@) {
 661     my (@keys) = @_;
 662     my @cfgs;
 663     # The nesting of these loops determines the search order.  We put
 664     # the key loop on the outside so that we search all the distros
 665     # for each key, before going on to the next key.  That means that
 666     # if access_cfg is called with a more specific, and then a less
 667     # specific, key, an earlier distro can override the less specific
 668     # without necessarily overriding any more specific keys.  (If the
 669     # distro wants to override the more specific keys it can simply do
 670     # so; whereas if we did the loop the other way around, it would be
 671     # impossible to for an earlier distro to override a less specific
 672     # key but not the more specific ones without restating the unknown
 673     # values of the more specific keys.
 674     my @realkeys;
 675     my @rundef;
 676     # We have to deal with RETURN-UNDEF specially, so that we don't
 677     # terminate the search prematurely.
 678     foreach (@keys) {
 679         if (m/RETURN-UNDEF/) { push @rundef, $_; last; }
 680         push @realkeys, $_
 681     }
 682     foreach my $d (access_distros()) {
 683         push @cfgs, map { "dgit-distro.$d.$_" } @realkeys;
 684     }
 685     push @cfgs, map { "dgit.default.$_" } @realkeys;
 686     push @cfgs, @rundef;
 687     return @cfgs;
 688 }
 689
 690 sub access_cfg (@) {
 691     my (@keys) = @_;
 692     my (@cfgs) = access_cfg_cfgs(@keys);
 693     my $value = cfg(@cfgs);
 694     return $value;
 695 }
 696
 697 sub access_cfg_bool ($$) {
 698     my ($def, @keys) = @_;
 699     parse_cfg_bool($keys[0], $def, access_cfg(@keys, 'RETURN-UNDEF'));
 700 }
 701
 702 sub string_to_ssh ($) {
 703     my ($spec) = @_;
 704     if ($spec =~ m/\s/) {
 705         return qw(sh -ec), 'exec '.$spec.' "$@"', 'x';
 706     } else {
 707         return ($spec);
 708     }
 709 }
 710
 711 sub access_cfg_ssh () {
 712     my $gitssh = access_cfg('ssh', 'RETURN-UNDEF');
 713     if (!defined $gitssh) {
 714         return @ssh;
 715     } else {
 716         return string_to_ssh $gitssh;
 717     }
 718 }
 719
 720 sub access_runeinfo ($) {
 721     my ($info) = @_;
 722     return ": dgit ".access_basedistro()." $info ;";
 723 }
 724
 725 sub access_someuserhost ($) {
 726     my ($some) = @_;
 727     my $user = access_cfg("$some-user-force", 'RETURN-UNDEF');
 728     defined($user) && length($user) or
 729         $user = access_cfg("$some-user",'username');
 730     my $host = access_cfg("$some-host");
 731     return length($user) ? "$user\@$host" : $host;
 732 }
 733
 734 sub access_gituserhost () {
 735     return access_someuserhost('git');
 736 }
 737
 738 sub access_giturl (;$) {
 739     my ($optional) = @_;
 740     my $url = access_cfg('git-url','RETURN-UNDEF');
 741     my $suffix;
 742     if (!length $url) {
 743         my $proto = access_cfg('git-proto', 'RETURN-UNDEF');
 744         return undef unless defined $proto;
 745         $url =
 746             $proto.
 747             access_gituserhost().
 748             access_cfg('git-path');
 749     } else {
 750         $suffix = access_cfg('git-url-suffix','RETURN-UNDEF');
 751     }
 752     $suffix //= '.git';
 753     return "$url/$package$suffix";
 754 }
 755
 756 sub parsecontrolfh ($$;$) {
 757     my ($fh, $desc, $allowsigned) = @_;
 758     our $dpkgcontrolhash_noissigned;
 759     my $c;
 760     for (;;) {
 761         my %opts = ('name' => $desc);
 762         $opts{allow_pgp}= $allowsigned || !$dpkgcontrolhash_noissigned;
 763         $c = Dpkg::Control::Hash->new(%opts);
 764         $c->parse($fh,$desc) or die "parsing of $desc failed";
 765         last if $allowsigned;
 766         last if $dpkgcontrolhash_noissigned;
 767         my $issigned= $c->get_option('is_pgp_signed');
 768         if (!defined $issigned) {
 769             $dpkgcontrolhash_noissigned= 1;
 770             seek $fh, 0,0 or die "seek $desc: $!";
 771         } elsif ($issigned) {
 772             fail "control file $desc is (already) PGP-signed. ".
 773                 " Note that dgit push needs to modify the .dsc and then".
 774                 " do the signature itself";
 775         } else {
 776             last;
 777         }
 778     }
 779     return $c;
 780 }
 781
 782 sub parsecontrol {
 783     my ($file, $desc) = @_;
 784     my $fh = new IO::Handle;
 785     open $fh, '<', $file or die "$file: $!";
 786     my $c = parsecontrolfh($fh,$desc);
 787     $fh->error and die $!;
 788     close $fh;
 789     return $c;
 790 }
 791
 792 sub getfield ($$) {
 793     my ($dctrl,$field) = @_;
 794     my $v = $dctrl->{$field};
 795     return $v if defined $v;
 796     fail "missing field $field in ".$v->get_option('name');
 797 }
 798
 799 sub parsechangelog {
 800     my $c = Dpkg::Control::Hash->new();
 801     my $p = new IO::Handle;
 802     my @cmd = (qw(dpkg-parsechangelog), @_);
 803     open $p, '-|', @cmd or die $!;
 804     $c->parse($p);
 805     $?=0; $!=0; close $p or failedcmd @cmd;
 806     return $c;
 807 }
 808
 809 sub must_getcwd () {
 810     my $d = getcwd();
 811     defined $d or fail "getcwd failed: $!";
 812     return $d;
 813 }
 814
 815 our %rmad;
 816
 817 sub archive_query ($) {
 818     my ($method) = @_;
 819     my $query = access_cfg('archive-query','RETURN-UNDEF');
 820     $query =~ s/^(\w+):// or badcfg "invalid archive-query method \`$query'";
 821     my $proto = $1;
 822     my $data = $'; #';
 823     { no strict qw(refs); &{"${method}_${proto}"}($proto,$data); }
 824 }
 825
 826 sub pool_dsc_subpath ($$) {
 827     my ($vsn,$component) = @_; # $package is implict arg
 828     my $prefix = substr($package, 0, $package =~ m/^l/ ? 4 : 1);
 829     return "/pool/$component/$prefix/$package/".dscfn($vsn);
 830 }
 831
 832 #---------- `ftpmasterapi' archive query method (nascent) ----------
 833
 834 sub archive_api_query_cmd ($) {
 835     my ($subpath) = @_;
 836     my @cmd = qw(curl -sS);
 837     my $url = access_cfg('archive-query-url');
 838     if ($url =~ m#^https://([-.0-9a-z]+)/#) {
 839         my $host = $1;
 840         my $keys = access_cfg('archive-query-tls-key','RETURN-UNDEF') //'';
 841         foreach my $key (split /\:/, $keys) {
 842             $key =~ s/\%HOST\%/$host/g;
 843             if (!stat $key) {
 844                 fail "for $url: stat $key: $!" unless $!==ENOENT;
 845                 next;
 846             }
 847             fail "config requested specific TLS key but do not know".
 848                 " how to get curl to use exactly that EE key ($key)";
 849 #           push @cmd, "--cacert", $key, "--capath", "/dev/enoent";
 850 #           # Sadly the above line does not work because of changes
 851 #           # to gnutls.   The real fix for #790093 may involve
 852 #           # new curl options.
 853             last;
 854         }
 855         # Fixing #790093 properly will involve providing a value
 856         # for this on clients.
 857         my $kargs = access_cfg('archive-query-tls-curl-ca-args','RETURN-UNDEF');
 858         push @cmd, split / /, $kargs if defined $kargs;
 859     }
 860     push @cmd, $url.$subpath;
 861     return @cmd;
 862 }
 863
 864 sub api_query ($$) {
 865     use JSON;
 866     my ($data, $subpath) = @_;
 867     badcfg "ftpmasterapi archive query method takes no data part"
 868         if length $data;
 869     my @cmd = archive_api_query_cmd($subpath);
 870     my $json = cmdoutput @cmd;
 871     return decode_json($json);
 872 }
 873
 874 sub canonicalise_suite_ftpmasterapi () {
 875     my ($proto,$data) = @_;
 876     my $suites = api_query($data, 'suites');
 877     my @matched;
 878     foreach my $entry (@$suites) {
 879         next unless grep {
 880             my $v = $entry->{$_};
 881             defined $v && $v eq $isuite;
 882         } qw(codename name);
 883         push @matched, $entry;
 884     }
 885     fail "unknown suite $isuite" unless @matched;
 886     my $cn;
 887     eval {
 888         @matched==1 or die "multiple matches for suite $isuite\n";
 889         $cn = "$matched[0]{codename}";
 890         defined $cn or die "suite $isuite info has no codename\n";
 891         $cn =~ m/^$suite_re$/ or die "suite $isuite maps to bad codename\n";
 892     };
 893     die "bad ftpmaster api response: $@\n".Dumper(\@matched)
 894         if length $@;
 895     return $cn;
 896 }
 897
 898 sub archive_query_ftpmasterapi () {
 899     my ($proto,$data) = @_;
 900     my $info = api_query($data, "dsc_in_suite/$isuite/$package");
 901     my @rows;
 902     my $digester = Digest::SHA->new(256);
 903     foreach my $entry (@$info) {
 904         eval {
 905             my $vsn = "$entry->{version}";
 906             my ($ok,$msg) = version_check $vsn;
 907             die "bad version: $msg\n" unless $ok;
 908             my $component = "$entry->{component}";
 909             $component =~ m/^$component_re$/ or die "bad component";
 910             my $filename = "$entry->{filename}";
 911             $filename && $filename !~ m#[^-+:._~0-9a-zA-Z/]|^[/.]|/[/.]#
 912                 or die "bad filename";
 913             my $sha256sum = "$entry->{sha256sum}";
 914             $sha256sum =~ m/^[0-9a-f]+$/ or die "bad sha256sum";
 915             push @rows, [ $vsn, "/pool/$component/$filename",
 916                           $digester, $sha256sum ];
 917         };
 918         die "bad ftpmaster api response: $@\n".Dumper($entry)
 919             if length $@;
 920     }
 921     @rows = sort { -version_compare($a->[0],$b->[0]) } @rows;
 922     return @rows;
 923 }
 924
 925 #---------- `madison' archive query method ----------
 926
 927 sub archive_query_madison {
 928     return map { [ @$_[0..1] ] } madison_get_parse(@_);
 929 }
 930
 931 sub madison_get_parse {
 932     my ($proto,$data) = @_;
 933     die unless $proto eq 'madison';
 934     if (!length $data) {
 935         $data= access_cfg('madison-distro','RETURN-UNDEF');
 936         $data //= access_basedistro();
 937     }
 938     $rmad{$proto,$data,$package} ||= cmdoutput
 939         qw(rmadison -asource),"-s$isuite","-u$data",$package;
 940     my $rmad = $rmad{$proto,$data,$package};
 941
 942     my @out;
 943     foreach my $l (split /\n/, $rmad) {
 944         $l =~ m{^ \s*( [^ \t|]+ )\s* \|
 945                   \s*( [^ \t|]+ )\s* \|
 946                   \s*( [^ \t|/]+ )(?:/([^ \t|/]+))? \s* \|
 947                   \s*( [^ \t|]+ )\s* }x or die "$rmad ?";
 948         $1 eq $package or die "$rmad $package ?";
 949         my $vsn = $2;
 950         my $newsuite = $3;
 951         my $component;
 952         if (defined $4) {
 953             $component = $4;
 954         } else {
 955             $component = access_cfg('archive-query-default-component');
 956         }
 957         $5 eq 'source' or die "$rmad ?";
 958         push @out, [$vsn,pool_dsc_subpath($vsn,$component),$newsuite];
 959     }
 960     return sort { -version_compare($a->[0],$b->[0]); } @out;
 961 }
 962
 963 sub canonicalise_suite_madison {
 964     # madison canonicalises for us
 965     my @r = madison_get_parse(@_);
 966     @r or fail
 967         "unable to canonicalise suite using package $package".
 968         " which does not appear to exist in suite $isuite;".
 969         " --existing-package may help";
 970     return $r[0][2];
 971 }
 972
 973 #---------- `sshpsql' archive query method ----------
 974
 975 sub sshpsql ($$$) {
 976     my ($data,$runeinfo,$sql) = @_;
 977     if (!length $data) {
 978         $data= access_someuserhost('sshpsql').':'.
 979             access_cfg('sshpsql-dbname');
 980     }
 981     $data =~ m/:/ or badcfg "invalid sshpsql method string \`$data'";
 982     my ($userhost,$dbname) = ($`,$'); #';
 983     my @rows;
 984     my @cmd = (access_cfg_ssh, $userhost,
 985                access_runeinfo("ssh-psql $runeinfo").
 986                " export LC_MESSAGES=C; export LC_CTYPE=C;".
 987                " ".shellquote qw(psql -A), $dbname, qw(-c), $sql);
 988     debugcmd "|",@cmd;
 989     open P, "-|", @cmd or die $!;
 990     while (<P>) {
 991         chomp or die;
 992         printdebug(">|$_|\n");
 993         push @rows, $_;
 994     }
 995     $!=0; $?=0; close P or failedcmd @cmd;
 996     @rows or die;
 997     my $nrows = pop @rows;
 998     $nrows =~ s/^\((\d+) rows?\)$/$1/ or die "$nrows ?";
 999     @rows == $nrows+1 or die "$nrows ".(scalar @rows)." ?";
1000     @rows = map { [ split /\|/, $_ ] } @rows;
1001     my $ncols = scalar @{ shift @rows };
1002     die if grep { scalar @$_ != $ncols } @rows;
1003     return @rows;
1004 }
1005
1006 sub sql_injection_check {
1007     foreach (@_) { die "$_ $& ?" if m{[^-+=:_.,/0-9a-zA-Z]}; }
1008 }
1009
1010 sub archive_query_sshpsql ($$) {
1011     my ($proto,$data) = @_;
1012     sql_injection_check $isuite, $package;
1013     my @rows = sshpsql($data, "archive-query $isuite $package", <<END);
1014         SELECT source.version, component.name, files.filename, files.sha256sum
1015           FROM source
1016           JOIN src_associations ON source.id = src_associations.source
1017           JOIN suite ON suite.id = src_associations.suite
1018           JOIN dsc_files ON dsc_files.source = source.id
1019           JOIN files_archive_map ON files_archive_map.file_id = dsc_files.file
1020           JOIN component ON component.id = files_archive_map.component_id
1021           JOIN files ON files.id = dsc_files.file
1022          WHERE ( suite.suite_name='$isuite' OR suite.codename='$isuite' )
1023            AND source.source='$package'
1024            AND files.filename LIKE '%.dsc';
1025 END
1026     @rows = sort { -version_compare($a->[0],$b->[0]) } @rows;
1027     my $digester = Digest::SHA->new(256);
1028     @rows = map {
1029         my ($vsn,$component,$filename,$sha256sum) = @$_;
1030         [ $vsn, "/pool/$component/$filename",$digester,$sha256sum ];
1031     } @rows;
1032     return @rows;
1033 }
1034
1035 sub canonicalise_suite_sshpsql ($$) {
1036     my ($proto,$data) = @_;
1037     sql_injection_check $isuite;
1038     my @rows = sshpsql($data, "canonicalise-suite $isuite", <<END);
1039         SELECT suite.codename
1040           FROM suite where suite_name='$isuite' or codename='$isuite';
1041 END
1042     @rows = map { $_->[0] } @rows;
1043     fail "unknown suite $isuite" unless @rows;
1044     die "ambiguous $isuite: @rows ?" if @rows>1;
1045     return $rows[0];
1046 }
1047
1048 #---------- `dummycat' archive query method ----------
1049
1050 sub canonicalise_suite_dummycat ($$) {
1051     my ($proto,$data) = @_;
1052     my $dpath = "$data/suite.$isuite";
1053     if (!open C, "<", $dpath) {
1054         $!==ENOENT or die "$dpath: $!";
1055         printdebug "dummycat canonicalise_suite $isuite $dpath ENOENT\n";
1056         return $isuite;
1057     }
1058     $!=0; $_ = <C>;
1059     chomp or die "$dpath: $!";
1060     close C;
1061     printdebug "dummycat canonicalise_suite $isuite $dpath = $_\n";
1062     return $_;
1063 }
1064
1065 sub archive_query_dummycat ($$) {
1066     my ($proto,$data) = @_;
1067     canonicalise_suite();
1068     my $dpath = "$data/package.$csuite.$package";
1069     if (!open C, "<", $dpath) {
1070         $!==ENOENT or die "$dpath: $!";
1071         printdebug "dummycat query $csuite $package $dpath ENOENT\n";
1072         return ();
1073     }
1074     my @rows;
1075     while (<C>) {
1076         next if m/^\#/;
1077         next unless m/\S/;
1078         die unless chomp;
1079         printdebug "dummycat query $csuite $package $dpath | $_\n";
1080         my @row = split /\s+/, $_;
1081         @row==2 or die "$dpath: $_ ?";
1082         push @rows, \@row;
1083     }
1084     C->error and die "$dpath: $!";
1085     close C;
1086     return sort { -version_compare($a->[0],$b->[0]); } @rows;
1087 }
1088
1089 #---------- archive query entrypoints and rest of program ----------
1090
1091 sub canonicalise_suite () {
1092     return if defined $csuite;
1093     fail "cannot operate on $isuite suite" if $isuite eq 'UNRELEASED';
1094     $csuite = archive_query('canonicalise_suite');
1095     if ($isuite ne $csuite) {
1096         progress "canonical suite name for $isuite is $csuite";
1097     }
1098 }
1099
1100 sub get_archive_dsc () {
1101     canonicalise_suite();
1102     my @vsns = archive_query('archive_query');
1103     foreach my $vinfo (@vsns) {
1104         my ($vsn,$subpath,$digester,$digest) = @$vinfo;
1105         $dscurl = access_cfg('mirror').$subpath;
1106         $dscdata = url_get($dscurl);
1107         if (!$dscdata) {
1108             $skew_warning_vsn = $vsn if !defined $skew_warning_vsn;
1109             next;
1110         }
1111         if ($digester) {
1112             $digester->reset();
1113             $digester->add($dscdata);
1114             my $got = $digester->hexdigest();
1115             $got eq $digest or
1116                 fail "$dscurl has hash $got but".
1117                     " archive told us to expect $digest";
1118         }
1119         my $dscfh = new IO::File \$dscdata, '<' or die $!;
1120         printdebug Dumper($dscdata) if $debuglevel>1;
1121         $dsc = parsecontrolfh($dscfh,$dscurl,1);
1122         printdebug Dumper($dsc) if $debuglevel>1;
1123         my $fmt = getfield $dsc, 'Format';
1124         fail "unsupported source format $fmt, sorry" unless $format_ok{$fmt};
1125         $dsc_checked = !!$digester;
1126         return;
1127     }
1128     $dsc = undef;
1129 }
1130
1131 sub check_for_git ();
1132 sub check_for_git () {
1133     # returns 0 or 1
1134     my $how = access_cfg('git-check');
1135     if ($how eq 'ssh-cmd') {
1136         my @cmd =
1137             (access_cfg_ssh, access_gituserhost(),
1138              access_runeinfo("git-check $package").
1139              " set -e; cd ".access_cfg('git-path').";".
1140              " if test -d $package.git; then echo 1; else echo 0; fi");
1141         my $r= cmdoutput @cmd;
1142         if ($r =~ m/^divert (\w+)$/) {
1143             my $divert=$1;
1144             my ($usedistro,) = access_distros();
1145             # NB that if we are pushing, $usedistro will be $distro/push
1146             $instead_distro= cfg("dgit-distro.$usedistro.diverts.$divert");
1147             $instead_distro =~ s{^/}{ access_basedistro()."/" }e;
1148             progress "diverting to $divert (using config for $instead_distro)";
1149             return check_for_git();
1150         }
1151         failedcmd @cmd unless $r =~ m/^[01]$/;
1152         return $r+0;
1153     } elsif ($how eq 'url') {
1154         my $prefix = access_cfg('git-check-url','git-url');
1155         my $suffix = access_cfg('git-check-suffix','git-suffix',
1156                                 'RETURN-UNDEF') // '.git';
1157         my $url = "$prefix/$package$suffix";
1158         my @cmd = (qw(curl -sS -I), $url);
1159         my $result = cmdoutput @cmd;
1160         $result =~ m/^\S+ (404|200) /s or
1161             fail "unexpected results from git check query - ".
1162                 Dumper($prefix, $result);
1163         my $code = $1;
1164         if ($code eq '404') {
1165             return 0;
1166         } elsif ($code eq '200') {
1167             return 1;
1168         } else {
1169             die;
1170         }
1171     } elsif ($how eq 'true') {
1172         return 1;
1173     } elsif ($how eq 'false') {
1174         return 0;
1175     } else {
1176         badcfg "unknown git-check \`$how'";
1177     }
1178 }
1179
1180 sub create_remote_git_repo () {
1181     my $how = access_cfg('git-create');
1182     if ($how eq 'ssh-cmd') {
1183         runcmd_ordryrun
1184             (access_cfg_ssh, access_gituserhost(),
1185              access_runeinfo("git-create $package").
1186              "set -e; cd ".access_cfg('git-path').";".
1187              " cp -a _template $package.git");
1188     } elsif ($how eq 'true') {
1189         # nothing to do
1190     } else {
1191         badcfg "unknown git-create \`$how'";
1192     }
1193 }
1194
1195 our ($dsc_hash,$lastpush_hash);
1196
1197 our $ud = '.git/dgit/unpack';
1198
1199 sub prep_ud () {
1200     rmtree($ud);
1201     mkpath '.git/dgit';
1202     mkdir $ud or die $!;
1203 }
1204
1205 sub mktree_in_ud_here () {
1206     runcmd qw(git init -q);
1207     rmtree('.git/objects');
1208     symlink '../../../../objects','.git/objects' or die $!;
1209 }
1210
1211 sub git_write_tree () {
1212     my $tree = cmdoutput @git, qw(write-tree);
1213     $tree =~ m/^\w+$/ or die "$tree ?";
1214     return $tree;
1215 }
1216
1217 sub mktree_in_ud_from_only_subdir () {
1218     # changes into the subdir
1219     my (@dirs) = <*/.>;
1220     die unless @dirs==1;
1221     $dirs[0] =~ m#^([^/]+)/\.$# or die;
1222     my $dir = $1;
1223     changedir $dir;
1224
1225     my @gitscmd = qw(find -name .git -prune -print0);
1226     debugcmd "|",@gitscmd;
1227     open GITS, "-|", @gitscmd or failedcmd @gitscmd;
1228     {
1229         local $/="\0";
1230         while (<GITS>) {
1231             chomp or die;
1232             print STDERR "$us: warning: removing from source package: ",
1233                 (messagequote $_), "\n";
1234             rmtree $_;
1235         }
1236     }
1237     $!=0; $?=0; close GITS or failedcmd @gitscmd;
1238
1239     mktree_in_ud_here();
1240     my $format=get_source_format();
1241     if (madformat($format)) {
1242         rmtree '.pc';
1243     }
1244     runcmd @git, qw(add -Af);
1245     my $tree=git_write_tree();
1246     return ($tree,$dir);
1247 }
1248
1249 sub dsc_files_info () {
1250     foreach my $csumi (['Checksums-Sha256','Digest::SHA', 'new(256)'],
1251                        ['Checksums-Sha1',  'Digest::SHA', 'new(1)'],
1252                        ['Files',           'Digest::MD5', 'new()']) {
1253         my ($fname, $module, $method) = @$csumi;
1254         my $field = $dsc->{$fname};
1255         next unless defined $field;
1256         eval "use $module; 1;" or die $@;
1257         my @out;
1258         foreach (split /\n/, $field) {
1259             next unless m/\S/;
1260             m/^(\w+) (\d+) (\S+)$/ or
1261                 fail "could not parse .dsc $fname line \`$_'";
1262             my $digester = eval "$module"."->$method;" or die $@;
1263             push @out, {
1264                 Hash => $1,
1265                 Bytes => $2,
1266                 Filename => $3,
1267                 Digester => $digester,
1268             };
1269         }
1270         return @out;
1271     }
1272     fail "missing any supported Checksums-* or Files field in ".
1273         $dsc->get_option('name');
1274 }
1275
1276 sub dsc_files () {
1277     map { $_->{Filename} } dsc_files_info();
1278 }
1279
1280 sub is_orig_file ($;$) {
1281     local ($_) = $_[0];
1282     my $base = $_[1];
1283     m/\.orig(?:-\w+)?\.tar\.\w+$/ or return 0;
1284     defined $base or return 1;
1285     return $` eq $base;
1286 }
1287
1288 sub make_commit ($) {
1289     my ($file) = @_;
1290     return cmdoutput @git, qw(hash-object -w -t commit), $file;
1291 }
1292
1293 sub clogp_authline ($) {
1294     my ($clogp) = @_;
1295     my $author = getfield $clogp, 'Maintainer';
1296     $author =~ s#,.*##ms;
1297     my $date = cmdoutput qw(date), '+%s %z', qw(-d), getfield($clogp,'Date');
1298     my $authline = "$author $date";
1299     $authline =~ m/^[^<>]+ \<\S+\> \d+ [-+]\d+$/ or
1300         fail "unexpected commit author line format \`$authline'".
1301         " (was generated from changelog Maintainer field)";
1302     return $authline;
1303 }
1304
1305 sub vendor_patches_distro ($$) {
1306     my ($checkdistro, $what) = @_;
1307     return unless defined $checkdistro;
1308
1309     my $series = "debian/patches/\L$checkdistro\E.series";
1310     printdebug "checking for vendor-specific $series ($what)\n";
1311
1312     if (!open SERIES, "<", $series) {
1313         die "$series $!" unless $!==ENOENT;
1314         return;
1315     }
1316     while (<SERIES>) {
1317         next unless m/\S/;
1318         next if m/^\s+\#/;
1319
1320         print STDERR <<END;
1321
1322 Unfortunately, this source package uses a feature of dpkg-source where
1323 the same source package unpacks to different source code on different
1324 distros.  dgit cannot safely operate on such packages on affected
1325 distros, because the meaning of source packages is not stable.
1326
1327 Please ask the distro/maintainer to remove the distro-specific series
1328 files and use a different technique (if necessary, uploading actually
1329 different packages, if different distros are supposed to have
1330 different code).
1331
1332 END
1333         fail "Found active distro-specific series file for".
1334             " $checkdistro ($what): $series, cannot continue";
1335     }
1336     die "$series $!" if SERIES->error;
1337     close SERIES;
1338 }
1339
1340 sub check_for_vendor_patches () {
1341     # This dpkg-source feature doesn't seem to be documented anywhere!
1342     # But it can be found in the changelog (reformatted):
1343
1344     #   commit  4fa01b70df1dc4458daee306cfa1f987b69da58c
1345     #   Author: Raphael Hertzog <hertzog@debian.org>
1346     #   Date: Sun  Oct  3  09:36:48  2010 +0200
1347
1348     #   dpkg-source: correctly create .pc/.quilt_series with alternate
1349     #   series files
1350     #
1351     #   If you have debian/patches/ubuntu.series and you were
1352     #   unpacking the source package on ubuntu, quilt was still
1353     #   directed to debian/patches/series instead of
1354     #   debian/patches/ubuntu.series.
1355     #
1356     #   debian/changelog                        |    3 +++
1357     #   scripts/Dpkg/Source/Package/V3/quilt.pm |    4 +++-
1358     #   2 files changed, 6 insertions(+), 1 deletion(-)
1359
1360     use Dpkg::Vendor;
1361     vendor_patches_distro($ENV{DEB_VENDOR}, "DEB_VENDOR");
1362     vendor_patches_distro(Dpkg::Vendor::get_current_vendor(),
1363                          "Dpkg::Vendor \`current vendor'");
1364     vendor_patches_distro(access_basedistro(),
1365                           "distro being accessed");
1366 }
1367
1368 sub generate_commit_from_dsc () {
1369     prep_ud();
1370     changedir $ud;
1371
1372     foreach my $fi (dsc_files_info()) {
1373         my $f = $fi->{Filename};
1374         die "$f ?" if $f =~ m#/|^\.|\.dsc$|\.tmp$#;
1375
1376         link "../../../$f", $f
1377             or $!==&ENOENT
1378             or die "$f $!";
1379
1380         complete_file_from_dsc('.', $fi);
1381
1382         if (is_orig_file($f)) {
1383             link $f, "../../../../$f"
1384                 or $!==&EEXIST
1385                 or die "$f $!";
1386         }
1387     }
1388
1389     my $dscfn = "$package.dsc";
1390
1391     open D, ">", $dscfn or die "$dscfn: $!";
1392     print D $dscdata or die "$dscfn: $!";
1393     close D or die "$dscfn: $!";
1394     my @cmd = qw(dpkg-source);
1395     push @cmd, '--no-check' if $dsc_checked;
1396     push @cmd, qw(-x --), $dscfn;
1397     runcmd @cmd;
1398
1399     my ($tree,$dir) = mktree_in_ud_from_only_subdir();
1400     check_for_vendor_patches() if madformat($dsc->{format});
1401     runcmd qw(sh -ec), 'dpkg-parsechangelog >../changelog.tmp';
1402     my $clogp = parsecontrol('../changelog.tmp',"commit's changelog");
1403     my $authline = clogp_authline $clogp;
1404     my $changes = getfield $clogp, 'Changes';
1405     open C, ">../commit.tmp" or die $!;
1406     print C <<END or die $!;
1407 tree $tree
1408 author $authline
1409 committer $authline
1410
1411 $changes
1412
1413 # imported from the archive
1414 END
1415     close C or die $!;
1416     my $outputhash = make_commit qw(../commit.tmp);
1417     my $cversion = getfield $clogp, 'Version';
1418     progress "synthesised git commit from .dsc $cversion";
1419     if ($lastpush_hash) {
1420         runcmd @git, qw(reset --hard), $lastpush_hash;
1421         runcmd qw(sh -ec), 'dpkg-parsechangelog >>../changelogold.tmp';
1422         my $oldclogp = parsecontrol('../changelogold.tmp','previous changelog');
1423         my $oversion = getfield $oldclogp, 'Version';
1424         my $vcmp =
1425             version_compare($oversion, $cversion);
1426         if ($vcmp < 0) {
1427             # git upload/ is earlier vsn than archive, use archive
1428             open C, ">../commit2.tmp" or die $!;
1429             print C <<END or die $!;
1430 tree $tree
1431 parent $lastpush_hash
1432 parent $outputhash
1433 author $authline
1434 committer $authline
1435
1436 Record $package ($cversion) in archive suite $csuite
1437 END
1438             $outputhash = make_commit qw(../commit2.tmp);
1439         } elsif ($vcmp > 0) {
1440             print STDERR <<END or die $!;
1441
1442 Version actually in archive:    $cversion (older)
1443 Last allegedly pushed/uploaded: $oversion (newer or same)
1444 $later_warning_msg
1445 END
1446             $outputhash = $lastpush_hash;
1447         } else {
1448             $outputhash = $lastpush_hash;
1449         }
1450     }
1451     changedir '../../../..';
1452     runcmd @git, qw(update-ref -m),"dgit fetch import $cversion",
1453             'DGIT_ARCHIVE', $outputhash;
1454     cmdoutput @git, qw(log -n2), $outputhash;
1455     # ... gives git a chance to complain if our commit is malformed
1456     rmtree($ud);
1457     return $outputhash;
1458 }
1459
1460 sub complete_file_from_dsc ($$) {
1461     our ($dstdir, $fi) = @_;
1462     # Ensures that we have, in $dir, the file $fi, with the correct
1463     # contents.  (Downloading it from alongside $dscurl if necessary.)
1464
1465     my $f = $fi->{Filename};
1466     my $tf = "$dstdir/$f";
1467     my $downloaded = 0;
1468
1469     if (stat_exists $tf) {
1470         progress "using existing $f";
1471     } else {
1472         my $furl = $dscurl;
1473         $furl =~ s{/[^/]+$}{};
1474         $furl .= "/$f";
1475         die "$f ?" unless $f =~ m/^${package}_/;
1476         die "$f ?" if $f =~ m#/#;
1477         runcmd_ordryrun_local @curl,qw(-o),$tf,'--',"$furl";
1478         next if !act_local();
1479         $downloaded = 1;
1480     }
1481
1482     open F, "<", "$tf" or die "$tf: $!";
1483     $fi->{Digester}->reset();
1484     $fi->{Digester}->addfile(*F);
1485     F->error and die $!;
1486     my $got = $fi->{Digester}->hexdigest();
1487     $got eq $fi->{Hash} or
1488         fail "file $f has hash $got but .dsc".
1489             " demands hash $fi->{Hash} ".
1490             ($downloaded ? "(got wrong file from archive!)"
1491              : "(perhaps you should delete this file?)");
1492 }
1493
1494 sub ensure_we_have_orig () {
1495     foreach my $fi (dsc_files_info()) {
1496         my $f = $fi->{Filename};
1497         next unless is_orig_file($f);
1498         complete_file_from_dsc('..', $fi);
1499     }
1500 }
1501
1502 sub git_fetch_us () {
1503     my @specs = (fetchspec());
1504     push @specs,
1505         map { "+refs/$_/*:".lrfetchrefs."/$_/*" }
1506         qw(tags heads);
1507     runcmd_ordryrun_local @git, qw(fetch -p -n -q), access_giturl(), @specs;
1508
1509     my %here;
1510     my $tagpat = debiantag('*',access_basedistro);
1511
1512     git_for_each_ref("refs/tags/".$tagpat, sub {
1513         my ($objid,$objtype,$fullrefname,$reftail) = @_;
1514         printdebug "currently $fullrefname=$objid\n";
1515         $here{$fullrefname} = $objid;
1516     });
1517     git_for_each_ref(lrfetchrefs."/tags/".$tagpat, sub {
1518         my ($objid,$objtype,$fullrefname,$reftail) = @_;
1519         my $lref = "refs".substr($fullrefname, length lrfetchrefs);
1520         printdebug "offered $lref=$objid\n";
1521         if (!defined $here{$lref}) {
1522             my @upd = (@git, qw(update-ref), $lref, $objid, '');
1523             runcmd_ordryrun_local @upd;
1524         } elsif ($here{$lref} eq $objid) {
1525         } else {
1526             print STDERR \
1527                 "Not updateting $lref from $here{$lref} to $objid.\n";
1528         }
1529     });
1530 }
1531
1532 sub fetch_from_archive () {
1533     # ensures that lrref() is what is actually in the archive,
1534     #  one way or another
1535     get_archive_dsc();
1536
1537     if ($dsc) {
1538         foreach my $field (@ourdscfield) {
1539             $dsc_hash = $dsc->{$field};
1540             last if defined $dsc_hash;
1541         }
1542         if (defined $dsc_hash) {
1543             $dsc_hash =~ m/\w+/ or fail "invalid hash in .dsc \`$dsc_hash'";
1544             $dsc_hash = $&;
1545             progress "last upload to archive specified git hash";
1546         } else {
1547             progress "last upload to archive has NO git hash";
1548         }
1549     } else {
1550         progress "no version available from the archive";
1551     }
1552
1553     $lastpush_hash = git_get_ref(lrref());
1554     printdebug "previous reference hash=$lastpush_hash\n";
1555     my $hash;
1556     if (defined $dsc_hash) {
1557         fail "missing remote git history even though dsc has hash -".
1558             " could not find ref ".lrref().
1559             " (should have been fetched from ".access_giturl()."#".rrref().")"
1560             unless $lastpush_hash;
1561         $hash = $dsc_hash;
1562         ensure_we_have_orig();
1563         if ($dsc_hash eq $lastpush_hash) {
1564         } elsif (is_fast_fwd($dsc_hash,$lastpush_hash)) {
1565             print STDERR <<END or die $!;
1566
1567 Git commit in archive is behind the last version allegedly pushed/uploaded.
1568 Commit referred to by archive:  $dsc_hash
1569 Last allegedly pushed/uploaded: $lastpush_hash
1570 $later_warning_msg
1571 END
1572             $hash = $lastpush_hash;
1573         } else {
1574             fail "git head (".lrref()."=$lastpush_hash) is not a ".
1575                 "descendant of archive's .dsc hash ($dsc_hash)";
1576         }
1577     } elsif ($dsc) {
1578         $hash = generate_commit_from_dsc();
1579     } elsif ($lastpush_hash) {
1580         # only in git, not in the archive yet
1581         $hash = $lastpush_hash;
1582         print STDERR <<END or die $!;
1583
1584 Package not found in the archive, but has allegedly been pushed using dgit.
1585 $later_warning_msg
1586 END
1587     } else {
1588         printdebug "nothing found!\n";
1589         if (defined $skew_warning_vsn) {
1590             print STDERR <<END or die $!;
1591
1592 Warning: relevant archive skew detected.
1593 Archive allegedly contains $skew_warning_vsn
1594 But we were not able to obtain any version from the archive or git.
1595
1596 END
1597         }
1598         return 0;
1599     }
1600     printdebug "current hash=$hash\n";
1601     if ($lastpush_hash) {
1602         fail "not fast forward on last upload branch!".
1603             " (archive's version left in DGIT_ARCHIVE)"
1604             unless is_fast_fwd($lastpush_hash, $hash);
1605     }
1606     if (defined $skew_warning_vsn) {
1607         mkpath '.git/dgit';
1608         printdebug "SKEW CHECK WANT $skew_warning_vsn\n";
1609         my $clogf = ".git/dgit/changelog.tmp";
1610         runcmd shell_cmd "exec >$clogf",
1611             @git, qw(cat-file blob), "$hash:debian/changelog";
1612         my $gotclogp = parsechangelog("-l$clogf");
1613         my $got_vsn = getfield $gotclogp, 'Version';
1614         printdebug "SKEW CHECK GOT $got_vsn\n";
1615         if (version_compare($got_vsn, $skew_warning_vsn) < 0) {
1616             print STDERR <<END or die $!;
1617
1618 Warning: archive skew detected.  Using the available version:
1619 Archive allegedly contains    $skew_warning_vsn
1620 We were able to obtain only   $got_vsn
1621
1622 END
1623         }
1624     }
1625     if ($lastpush_hash ne $hash) {
1626         my @upd_cmd = (@git, qw(update-ref -m), 'dgit fetch', lrref(), $hash);
1627         if (act_local()) {
1628             cmdoutput @upd_cmd;
1629         } else {
1630             dryrun_report @upd_cmd;
1631         }
1632     }
1633     return 1;
1634 }
1635
1636 sub set_local_git_config ($$) {
1637     my ($k, $v) = @_;
1638     runcmd @git, qw(config), $k, $v;
1639 }
1640
1641 sub setup_mergechangelogs () {
1642     my $driver = 'dpkg-mergechangelogs';
1643     my $cb = "merge.$driver";
1644     my $attrs = '.git/info/attributes';
1645     ensuredir '.git/info';
1646
1647     open NATTRS, ">", "$attrs.new" or die "$attrs.new $!";
1648     if (!open ATTRS, "<", $attrs) {
1649         $!==ENOENT or die "$attrs: $!";
1650     } else {
1651         while (<ATTRS>) {
1652             chomp;
1653             next if m{^debian/changelog\s};
1654             print NATTRS $_, "\n" or die $!;
1655         }
1656         ATTRS->error and die $!;
1657         close ATTRS;
1658     }
1659     print NATTRS "debian/changelog merge=$driver\n" or die $!;
1660     close NATTRS;
1661
1662     set_local_git_config "$cb.name", 'debian/changelog merge driver';
1663     set_local_git_config "$cb.driver", 'dpkg-mergechangelogs -m %O %A %B %A';
1664
1665     rename "$attrs.new", "$attrs" or die "$attrs: $!";
1666 }
1667
1668 sub clone ($) {
1669     my ($dstdir) = @_;
1670     canonicalise_suite();
1671     badusage "dry run makes no sense with clone" unless act_local();
1672     my $hasgit = check_for_git();
1673     mkdir $dstdir or die "$dstdir $!";
1674     changedir $dstdir;
1675     runcmd @git, qw(init -q);
1676     my $giturl = access_giturl(1);
1677     if (defined $giturl) {
1678         set_local_git_config "remote.$remotename.fetch", fetchspec();
1679         open H, "> .git/HEAD" or die $!;
1680         print H "ref: ".lref()."\n" or die $!;
1681         close H or die $!;
1682         runcmd @git, qw(remote add), 'origin', $giturl;
1683     }
1684     if ($hasgit) {
1685         progress "fetching existing git history";
1686         git_fetch_us();
1687         runcmd_ordryrun_local @git, qw(fetch origin);
1688     } else {
1689         progress "starting new git history";
1690     }
1691     fetch_from_archive() or no_such_package;
1692     my $vcsgiturl = $dsc->{'Vcs-Git'};
1693     if (length $vcsgiturl) {
1694         $vcsgiturl =~ s/\s+-b\s+\S+//g;
1695         runcmd @git, qw(remote add vcs-git), $vcsgiturl;
1696     }
1697     setup_mergechangelogs();
1698     runcmd @git, qw(reset --hard), lrref();
1699     printdone "ready for work in $dstdir";
1700 }
1701
1702 sub fetch () {
1703     if (check_for_git()) {
1704         git_fetch_us();
1705     }
1706     fetch_from_archive() or no_such_package();
1707     printdone "fetched into ".lrref();
1708 }
1709
1710 sub pull () {
1711     fetch();
1712     runcmd_ordryrun_local @git, qw(merge -m),"Merge from $csuite [dgit]",
1713         lrref();
1714     printdone "fetched to ".lrref()." and merged into HEAD";
1715 }
1716
1717 sub check_not_dirty () {
1718     return if $ignoredirty;
1719     my @cmd = (@git, qw(diff --quiet HEAD));
1720     debugcmd "+",@cmd;
1721     $!=0; $?=0; system @cmd;
1722     return if !$! && !$?;
1723     if (!$! && $?==256) {
1724         fail "working tree is dirty (does not match HEAD)";
1725     } else {
1726         failedcmd @cmd;
1727     }
1728 }
1729
1730 sub commit_admin ($) {
1731     my ($m) = @_;
1732     progress "$m";
1733     runcmd_ordryrun_local @git, qw(commit -m), $m;
1734 }
1735
1736 sub commit_quilty_patch () {
1737     my $output = cmdoutput @git, qw(status --porcelain);
1738     my %adds;
1739     foreach my $l (split /\n/, $output) {
1740         next unless $l =~ m/\S/;
1741         if ($l =~ m{^(?:\?\?| M) (.pc|debian/patches)}) {
1742             $adds{$1}++;
1743         }
1744     }
1745     delete $adds{'.pc'}; # if there wasn't one before, don't add it
1746     if (!%adds) {
1747         progress "nothing quilty to commit, ok.";
1748         return;
1749     }
1750     runcmd_ordryrun_local @git, qw(add), sort keys %adds;
1751     commit_admin "Commit Debian 3.0 (quilt) metadata";
1752 }
1753
1754 sub get_source_format () {
1755     if (!open F, "debian/source/format") {
1756         die $! unless $!==&ENOENT;
1757         return '';
1758     }
1759     $_ = <F>;
1760     F->error and die $!;
1761     chomp;
1762     return $_;
1763 }
1764
1765 sub madformat ($) {
1766     my ($format) = @_;
1767     return 0 unless $format eq '3.0 (quilt)';
1768     if ($quilt_mode eq 'nocheck') {
1769         progress "Not doing any fixup of \`$format' due to --no-quilt-fixup";
1770         return 0;
1771     }
1772     progress "Format \`$format', checking/updating patch stack";
1773     return 1;
1774 }
1775
1776 sub push_parse_changelog ($) {
1777     my ($clogpfn) = @_;
1778
1779     my $clogp = Dpkg::Control::Hash->new();
1780     $clogp->load($clogpfn) or die;
1781
1782     $package = getfield $clogp, 'Source';
1783     my $cversion = getfield $clogp, 'Version';
1784     my $tag = debiantag($cversion, access_basedistro);
1785     runcmd @git, qw(check-ref-format), $tag;
1786
1787     my $dscfn = dscfn($cversion);
1788
1789     return ($clogp, $cversion, $tag, $dscfn);
1790 }
1791
1792 sub push_parse_dsc ($$$) {
1793     my ($dscfn,$dscfnwhat, $cversion) = @_;
1794     $dsc = parsecontrol($dscfn,$dscfnwhat);
1795     my $dversion = getfield $dsc, 'Version';
1796     my $dscpackage = getfield $dsc, 'Source';
1797     ($dscpackage eq $package && $dversion eq $cversion) or
1798         fail "$dscfn is for $dscpackage $dversion".
1799             " but debian/changelog is for $package $cversion";
1800 }
1801
1802 sub push_mktag ($$$$$$$) {
1803     my ($head,$clogp,$tag,
1804         $dscfn,
1805         $changesfile,$changesfilewhat,
1806         $tfn) = @_;
1807
1808     $dsc->{$ourdscfield[0]} = $head;
1809     $dsc->save("$dscfn.tmp") or die $!;
1810
1811     my $changes = parsecontrol($changesfile,$changesfilewhat);
1812     foreach my $field (qw(Source Distribution Version)) {
1813         $changes->{$field} eq $clogp->{$field} or
1814             fail "changes field $field \`$changes->{$field}'".
1815                 " does not match changelog \`$clogp->{$field}'";
1816     }
1817
1818     my $cversion = getfield $clogp, 'Version';
1819     my $clogsuite = getfield $clogp, 'Distribution';
1820
1821     # We make the git tag by hand because (a) that makes it easier
1822     # to control the "tagger" (b) we can do remote signing
1823     my $authline = clogp_authline $clogp;
1824     my $delibs = join(" ", "",@deliberatelies);
1825     my $declaredistro = access_basedistro();
1826     open TO, '>', $tfn->('.tmp') or die $!;
1827     print TO <<END or die $!;
1828 object $head
1829 type commit
1830 tag $tag
1831 tagger $authline
1832
1833 $package release $cversion for $clogsuite ($csuite) [dgit]
1834 [dgit distro=$declaredistro$delibs]
1835 END
1836     foreach my $ref (sort keys %previously) {
1837                     print TO <<END or die $!;
1838 [dgit previously:$ref=$previously{$ref}]
1839 END
1840     }
1841
1842     close TO or die $!;
1843
1844     my $tagobjfn = $tfn->('.tmp');
1845     if ($sign) {
1846         if (!defined $keyid) {
1847             $keyid = access_cfg('keyid','RETURN-UNDEF');
1848         }
1849         unlink $tfn->('.tmp.asc') or $!==&ENOENT or die $!;
1850         my @sign_cmd = (@gpg, qw(--detach-sign --armor));
1851         push @sign_cmd, qw(-u),$keyid if defined $keyid;
1852         push @sign_cmd, $tfn->('.tmp');
1853         runcmd_ordryrun @sign_cmd;
1854         if (act_scary()) {
1855             $tagobjfn = $tfn->('.signed.tmp');
1856             runcmd shell_cmd "exec >$tagobjfn", qw(cat --),
1857                 $tfn->('.tmp'), $tfn->('.tmp.asc');
1858         }
1859     }
1860
1861     return ($tagobjfn);
1862 }
1863
1864 sub sign_changes ($) {
1865     my ($changesfile) = @_;
1866     if ($sign) {
1867         my @debsign_cmd = @debsign;
1868         push @debsign_cmd, "-k$keyid" if defined $keyid;
1869         push @debsign_cmd, "-p$gpg[0]" if $gpg[0] ne 'gpg';
1870         push @debsign_cmd, $changesfile;
1871         runcmd_ordryrun @debsign_cmd;
1872     }
1873 }
1874
1875 sub dopush ($) {
1876     my ($forceflag) = @_;
1877     printdebug "actually entering push\n";
1878     supplementary_message(<<'END');
1879 Push failed, while preparing your push.
1880 You can retry the push, after fixing the problem, if you like.
1881 END
1882     prep_ud();
1883
1884     access_giturl(); # check that success is vaguely likely
1885
1886     my $clogpfn = ".git/dgit/changelog.822.tmp";
1887     runcmd shell_cmd "exec >$clogpfn", qw(dpkg-parsechangelog);
1888
1889     responder_send_file('parsed-changelog', $clogpfn);
1890
1891     my ($clogp, $cversion, $tag, $dscfn) =
1892         push_parse_changelog("$clogpfn");
1893
1894     my $dscpath = "$buildproductsdir/$dscfn";
1895     stat_exists $dscpath or
1896         fail "looked for .dsc $dscfn, but $!;".
1897             " maybe you forgot to build";
1898
1899     responder_send_file('dsc', $dscpath);
1900
1901     push_parse_dsc($dscpath, $dscfn, $cversion);
1902
1903     my $format = getfield $dsc, 'Format';
1904     printdebug "format $format\n";
1905     if (madformat($format)) {
1906         commit_quilty_patch();
1907     }
1908     check_not_dirty();
1909     changedir $ud;
1910     progress "checking that $dscfn corresponds to HEAD";
1911     runcmd qw(dpkg-source -x --),
1912         $dscpath =~ m#^/# ? $dscpath : "../../../$dscpath";
1913     my ($tree,$dir) = mktree_in_ud_from_only_subdir();
1914     check_for_vendor_patches() if madformat($dsc->{format});
1915     changedir '../../../..';
1916     my $diffopt = $debuglevel>0 ? '--exit-code' : '--quiet';
1917     my @diffcmd = (@git, qw(diff), $diffopt, $tree);
1918     debugcmd "+",@diffcmd;
1919     $!=0; $?=0;
1920     my $r = system @diffcmd;
1921     if ($r) {
1922         if ($r==256) {
1923             fail "$dscfn specifies a different tree to your HEAD commit;".
1924                 " perhaps you forgot to build".
1925                 ($diffopt eq '--exit-code' ? "" :
1926                  " (run with -D to see full diff output)");
1927         } else {
1928             failedcmd @diffcmd;
1929         }
1930     }
1931     my $head = git_rev_parse('HEAD');
1932     if (!$changesfile) {
1933         my $multi = "$buildproductsdir/".
1934             "${package}_".(stripepoch $cversion)."_multi.changes";
1935         if (stat_exists "$multi") {
1936             $changesfile = $multi;
1937         } else {
1938             my $pat = "${package}_".(stripepoch $cversion)."_*.changes";
1939             my @cs = glob "$buildproductsdir/$pat";
1940             fail "failed to find unique changes file".
1941                 " (looked for $pat in $buildproductsdir, or $multi);".
1942                 " perhaps you need to use dgit -C"
1943                 unless @cs==1;
1944             ($changesfile) = @cs;
1945         }
1946     } else {
1947         $changesfile = "$buildproductsdir/$changesfile";
1948     }
1949
1950     responder_send_file('changes',$changesfile);
1951     responder_send_command("param head $head");
1952     responder_send_command("param csuite $csuite");
1953
1954     if (deliberately_not_fast_forward) {
1955         git_for_each_ref(lrfetchrefs, sub {
1956             my ($objid,$objtype,$lrfetchrefname,$reftail) = @_;
1957             my $rrefname= substr($lrfetchrefname, length(lrfetchrefs) + 1);
1958             responder_send_command("previously $rrefname=$objid");
1959             $previously{$rrefname} = $objid;
1960         });
1961     }
1962
1963     my $tfn = sub { ".git/dgit/tag$_[0]"; };
1964     my $tagobjfn;
1965
1966     supplementary_message(<<'END');
1967 Push failed, while signing the tag.
1968 You can retry the push, after fixing the problem, if you like.
1969 END
1970     # If we manage to sign but fail to record it anywhere, it's fine.
1971     if ($we_are_responder) {
1972         $tagobjfn = $tfn->('.signed.tmp');
1973         responder_receive_files('signed-tag', $tagobjfn);
1974     } else {
1975         $tagobjfn =
1976             push_mktag($head,$clogp,$tag,
1977                        $dscpath,
1978                        $changesfile,$changesfile,
1979                        $tfn);
1980     }
1981     supplementary_message(<<'END');
1982 Push failed, *after* signing the tag.
1983 If you want to try again, you should use a new version number.
1984 END
1985
1986     my $tag_obj_hash = cmdoutput @git, qw(hash-object -w -t tag), $tagobjfn;
1987     runcmd_ordryrun @git, qw(verify-tag), $tag_obj_hash;
1988     runcmd_ordryrun_local @git, qw(update-ref), "refs/tags/$tag", $tag_obj_hash;
1989
1990     supplementary_message(<<'END');
1991 Push failed, while updating the remote git repository - see messages above.
1992 If you want to try again, you should use a new version number.
1993 END
1994     if (!check_for_git()) {
1995         create_remote_git_repo();
1996     }
1997     runcmd_ordryrun @git, qw(push),access_giturl(),
1998         $forceflag."HEAD:".rrref(), $forceflag."refs/tags/$tag";
1999     runcmd_ordryrun @git, qw(update-ref -m), 'dgit push', lrref(), 'HEAD';
2000
2001     supplementary_message(<<'END');
2002 Push failed, after updating the remote git repository.
2003 If you want to try again, you must use a new version number.
2004 END
2005     if ($we_are_responder) {
2006         my $dryrunsuffix = act_local() ? "" : ".tmp";
2007         responder_receive_files('signed-dsc-changes',
2008                                 "$dscpath$dryrunsuffix",
2009                                 "$changesfile$dryrunsuffix");
2010     } else {
2011         if (act_local()) {
2012             rename "$dscpath.tmp",$dscpath or die "$dscfn $!";
2013         } else {
2014             progress "[new .dsc left in $dscpath.tmp]";
2015         }
2016         sign_changes $changesfile;
2017     }
2018
2019     supplementary_message(<<'END');
2020 Push failed, while uploading package(s) to the archive server.
2021 You can retry the upload of exactly these same files with dput of:
2022   $changesfile
2023 If that .changes file is broken, you will need to use a new version
2024 number for your next attempt at the upload.
2025 END
2026     my $host = access_cfg('upload-host','RETURN-UNDEF');
2027     my @hostarg = defined($host) ? ($host,) : ();
2028     runcmd_ordryrun @dput, @hostarg, $changesfile;
2029     printdone "pushed and uploaded $cversion";
2030
2031     supplementary_message('');
2032     responder_send_command("complete");
2033 }
2034
2035 sub cmd_clone {
2036     parseopts();
2037     notpushing();
2038     my $dstdir;
2039     badusage "-p is not allowed with clone; specify as argument instead"
2040         if defined $package;
2041     if (@ARGV==1) {
2042         ($package) = @ARGV;
2043     } elsif (@ARGV==2 && $ARGV[1] =~ m#^\w#) {
2044         ($package,$isuite) = @ARGV;
2045     } elsif (@ARGV==2 && $ARGV[1] =~ m#^[./]#) {
2046         ($package,$dstdir) = @ARGV;
2047     } elsif (@ARGV==3) {
2048         ($package,$isuite,$dstdir) = @ARGV;
2049     } else {
2050         badusage "incorrect arguments to dgit clone";
2051     }
2052     $dstdir ||= "$package";
2053
2054     if (stat_exists $dstdir) {
2055         fail "$dstdir already exists";
2056     }
2057
2058     my $cwd_remove;
2059     if ($rmonerror && !$dryrun_level) {
2060         $cwd_remove= getcwd();
2061         unshift @end, sub {
2062             return unless defined $cwd_remove;
2063             if (!chdir "$cwd_remove") {
2064                 return if $!==&ENOENT;
2065                 die "chdir $cwd_remove: $!";
2066             }
2067             rmtree($dstdir) or die "remove $dstdir: $!\n";
2068         };
2069     }
2070
2071     clone($dstdir);
2072     $cwd_remove = undef;
2073 }
2074
2075 sub branchsuite () {
2076     my $branch = cmdoutput_errok @git, qw(symbolic-ref HEAD);
2077     if ($branch =~ m#$lbranch_re#o) {
2078         return $1;
2079     } else {
2080         return undef;
2081     }
2082 }
2083
2084 sub fetchpullargs () {
2085     notpushing();
2086     if (!defined $package) {
2087         my $sourcep = parsecontrol('debian/control','debian/control');
2088         $package = getfield $sourcep, 'Source';
2089     }
2090     if (@ARGV==0) {
2091 #       $isuite = branchsuite();  # this doesn't work because dak hates canons
2092         if (!$isuite) {
2093             my $clogp = parsechangelog();
2094             $isuite = getfield $clogp, 'Distribution';
2095         }
2096         canonicalise_suite();
2097         progress "fetching from suite $csuite";
2098     } elsif (@ARGV==1) {
2099         ($isuite) = @ARGV;
2100         canonicalise_suite();
2101     } else {
2102         badusage "incorrect arguments to dgit fetch or dgit pull";
2103     }
2104 }
2105
2106 sub cmd_fetch {
2107     parseopts();
2108     fetchpullargs();
2109     fetch();
2110 }
2111
2112 sub cmd_pull {
2113     parseopts();
2114     fetchpullargs();
2115     pull();
2116 }
2117
2118 sub cmd_push {
2119     parseopts();
2120     pushing();
2121     badusage "-p is not allowed with dgit push" if defined $package;
2122     check_not_dirty();
2123     my $clogp = parsechangelog();
2124     $package = getfield $clogp, 'Source';
2125     my $specsuite;
2126     if (@ARGV==0) {
2127     } elsif (@ARGV==1) {
2128         ($specsuite) = (@ARGV);
2129     } else {
2130         badusage "incorrect arguments to dgit push";
2131     }
2132     $isuite = getfield $clogp, 'Distribution';
2133     if ($new_package) {
2134         local ($package) = $existing_package; # this is a hack
2135         canonicalise_suite();
2136     } else {
2137         canonicalise_suite();
2138     }
2139     if (defined $specsuite &&
2140         $specsuite ne $isuite &&
2141         $specsuite ne $csuite) {
2142             fail "dgit push: changelog specifies $isuite ($csuite)".
2143                 " but command line specifies $specsuite";
2144     }
2145     supplementary_message(<<'END');
2146 Push failed, while checking state of the archive.
2147 You can retry the push, after fixing the problem, if you like.
2148 END
2149     if (check_for_git()) {
2150         git_fetch_us();
2151     }
2152     my $forceflag = '';
2153     if (fetch_from_archive()) {
2154         if (is_fast_fwd(lrref(), 'HEAD')) {
2155             # ok
2156         } elsif (deliberately_not_fast_forward) {
2157             $forceflag = '+';
2158         } else {
2159             fail "dgit push: HEAD is not a descendant".
2160                 " of the archive's version.\n".
2161                 "dgit: To overwrite its contents,".
2162                 " use git merge -s ours ".lrref().".\n".
2163                 "dgit: To rewind history, if permitted by the archive,".
2164                 " use --deliberately-not-fast-forward";
2165         }
2166     } else {
2167         $new_package or
2168             fail "package appears to be new in this suite;".
2169                 " if this is intentional, use --new";
2170     }
2171     dopush($forceflag);
2172 }
2173
2174 #---------- remote commands' implementation ----------
2175
2176 sub cmd_remote_push_build_host {
2177     my ($nrargs) = shift @ARGV;
2178     my (@rargs) = @ARGV[0..$nrargs-1];
2179     @ARGV = @ARGV[$nrargs..$#ARGV];
2180     die unless @rargs;
2181     my ($dir,$vsnwant) = @rargs;
2182     # vsnwant is a comma-separated list; we report which we have
2183     # chosen in our ready response (so other end can tell if they
2184     # offered several)
2185     $debugprefix = ' ';
2186     $we_are_responder = 1;
2187     $us .= " (build host)";
2188
2189     pushing();
2190
2191     open PI, "<&STDIN" or die $!;
2192     open STDIN, "/dev/null" or die $!;
2193     open PO, ">&STDOUT" or die $!;
2194     autoflush PO 1;
2195     open STDOUT, ">&STDERR" or die $!;
2196     autoflush STDOUT 1;
2197
2198     $vsnwant //= 1;
2199     ($protovsn) = grep {
2200         $vsnwant =~ m{^(?:.*,)?$_(?:,.*)?$}
2201     } @rpushprotovsn_support;
2202
2203     fail "build host has dgit rpush protocol versions ".
2204         (join ",", @rpushprotovsn_support).
2205         " but invocation host has $vsnwant"
2206         unless defined $protovsn;
2207
2208     responder_send_command("dgit-remote-push-ready $protovsn");
2209
2210     changedir $dir;
2211     &cmd_push;
2212 }
2213
2214 sub cmd_remote_push_responder { cmd_remote_push_build_host(); }
2215 # ... for compatibility with proto vsn.1 dgit (just so that user gets
2216 #     a good error message)
2217
2218 our $i_tmp;
2219
2220 sub i_cleanup {
2221     local ($@, $?);
2222     my $report = i_child_report();
2223     if (defined $report) {
2224         printdebug "($report)\n";
2225     } elsif ($i_child_pid) {
2226         printdebug "(killing build host child $i_child_pid)\n";
2227         kill 15, $i_child_pid;
2228     }
2229     if (defined $i_tmp && !defined $initiator_tempdir) {
2230         changedir "/";
2231         eval { rmtree $i_tmp; };
2232     }
2233 }
2234
2235 END { i_cleanup(); }
2236
2237 sub i_method {
2238     my ($base,$selector,@args) = @_;
2239     $selector =~ s/\-/_/g;
2240     { no strict qw(refs); &{"${base}_${selector}"}(@args); }
2241 }
2242
2243 sub cmd_rpush {
2244     pushing();
2245     my $host = nextarg;
2246     my $dir;
2247     if ($host =~ m/^((?:[^][]|\[[^][]*\])*)\:/) {
2248         $host = $1;
2249         $dir = $'; #';
2250     } else {
2251         $dir = nextarg;
2252     }
2253     $dir =~ s{^-}{./-};
2254     my @rargs = ($dir);
2255     push @rargs, join ",", @rpushprotovsn_support;
2256     my @rdgit;
2257     push @rdgit, @dgit;
2258     push @rdgit, @ropts;
2259     push @rdgit, qw(remote-push-build-host), (scalar @rargs), @rargs;
2260     push @rdgit, @ARGV;
2261     my @cmd = (@ssh, $host, shellquote @rdgit);
2262     debugcmd "+",@cmd;
2263
2264     if (defined $initiator_tempdir) {
2265         rmtree $initiator_tempdir;
2266         mkdir $initiator_tempdir, 0700 or die "$initiator_tempdir: $!";
2267         $i_tmp = $initiator_tempdir;
2268     } else {
2269         $i_tmp = tempdir();
2270     }
2271     $i_child_pid = open2(\*RO, \*RI, @cmd);
2272     changedir $i_tmp;
2273     ($protovsn) = initiator_expect { m/^dgit-remote-push-ready (\S+)/ };
2274     die "$protovsn ?" unless grep { $_ eq $protovsn } @rpushprotovsn_support;
2275     $supplementary_message = '' unless $protovsn >= 3;
2276     for (;;) {
2277         my ($icmd,$iargs) = initiator_expect {
2278             m/^(\S+)(?: (.*))?$/;
2279             ($1,$2);
2280         };
2281         i_method "i_resp", $icmd, $iargs;
2282     }
2283 }
2284
2285 sub i_resp_progress ($) {
2286     my ($rhs) = @_;
2287     my $msg = protocol_read_bytes \*RO, $rhs;
2288     progress $msg;
2289 }
2290
2291 sub i_resp_supplementary_message ($) {
2292     my ($rhs) = @_;
2293     $supplementary_message = protocol_read_bytes \*RO, $rhs;
2294 }
2295
2296 sub i_resp_complete {
2297     my $pid = $i_child_pid;
2298     $i_child_pid = undef; # prevents killing some other process with same pid
2299     printdebug "waiting for build host child $pid...\n";
2300     my $got = waitpid $pid, 0;
2301     die $! unless $got == $pid;
2302     die "build host child failed $?" if $?;
2303
2304     i_cleanup();
2305     printdebug "all done\n";
2306     exit 0;
2307 }
2308
2309 sub i_resp_file ($) {
2310     my ($keyword) = @_;
2311     my $localname = i_method "i_localname", $keyword;
2312     my $localpath = "$i_tmp/$localname";
2313     stat_exists $localpath and
2314         badproto \*RO, "file $keyword ($localpath) twice";
2315     protocol_receive_file \*RO, $localpath;
2316     i_method "i_file", $keyword;
2317 }
2318
2319 our %i_param;
2320
2321 sub i_resp_param ($) {
2322     $_[0] =~ m/^(\S+) (.*)$/ or badproto \*RO, "bad param spec";
2323     $i_param{$1} = $2;
2324 }
2325
2326 sub i_resp_previously ($) {
2327     $_[0] =~ m#^(refs/tags/\S+)=(\w+)$#
2328         or badproto \*RO, "bad previously spec";
2329     my $r = system qw(git check-ref-format), $1;
2330     die "bad previously ref spec ($r)" if $r;
2331     $previously{$1} = $2;
2332 }
2333
2334 our %i_wanted;
2335
2336 sub i_resp_want ($) {
2337     my ($keyword) = @_;
2338     die "$keyword ?" if $i_wanted{$keyword}++;
2339     my @localpaths = i_method "i_want", $keyword;
2340     printdebug "[[  $keyword @localpaths\n";
2341     foreach my $localpath (@localpaths) {
2342         protocol_send_file \*RI, $localpath;
2343     }
2344     print RI "files-end\n" or die $!;
2345 }
2346
2347 our ($i_clogp, $i_version, $i_tag, $i_dscfn, $i_changesfn);
2348
2349 sub i_localname_parsed_changelog {
2350     return "remote-changelog.822";
2351 }
2352 sub i_file_parsed_changelog {
2353     ($i_clogp, $i_version, $i_tag, $i_dscfn) =
2354         push_parse_changelog "$i_tmp/remote-changelog.822";
2355     die if $i_dscfn =~ m#/|^\W#;
2356 }
2357
2358 sub i_localname_dsc {
2359     defined $i_dscfn or badproto \*RO, "dsc (before parsed-changelog)";
2360     return $i_dscfn;
2361 }
2362 sub i_file_dsc { }
2363
2364 sub i_localname_changes {
2365     defined $i_dscfn or badproto \*RO, "dsc (before parsed-changelog)";
2366     $i_changesfn = $i_dscfn;
2367     $i_changesfn =~ s/\.dsc$/_dgit.changes/ or die;
2368     return $i_changesfn;
2369 }
2370 sub i_file_changes { }
2371
2372 sub i_want_signed_tag {
2373     printdebug Dumper(\%i_param, $i_dscfn);
2374     defined $i_param{'head'} && defined $i_dscfn && defined $i_clogp
2375         && defined $i_param{'csuite'}
2376         or badproto \*RO, "premature desire for signed-tag";
2377     my $head = $i_param{'head'};
2378     die if $head =~ m/[^0-9a-f]/ || $head !~ m/^../;
2379
2380     die unless $i_param{'csuite'} =~ m/^$suite_re$/;
2381     $csuite = $&;
2382     push_parse_dsc $i_dscfn, 'remote dsc', $i_version;
2383
2384     my $tagobjfn =
2385         push_mktag $head, $i_clogp, $i_tag,
2386             $i_dscfn,
2387             $i_changesfn, 'remote changes',
2388             sub { "tag$_[0]"; };
2389
2390     return $tagobjfn;
2391 }
2392
2393 sub i_want_signed_dsc_changes {
2394     rename "$i_dscfn.tmp","$i_dscfn" or die "$i_dscfn $!";
2395     sign_changes $i_changesfn;
2396     return ($i_dscfn, $i_changesfn);
2397 }
2398
2399 #---------- building etc. ----------
2400
2401 our $version;
2402 our $sourcechanges;
2403 our $dscfn;
2404
2405 #----- `3.0 (quilt)' handling -----
2406
2407 our $fakeeditorenv = 'DGIT_FAKE_EDITOR_QUILT';
2408
2409 sub quiltify_dpkg_commit ($$$;$) {
2410     my ($patchname,$author,$msg, $xinfo) = @_;
2411     $xinfo //= '';
2412
2413     mkpath '.git/dgit';
2414     my $descfn = ".git/dgit/quilt-description.tmp";
2415     open O, '>', $descfn or die "$descfn: $!";
2416     $msg =~ s/\s+$//g;
2417     $msg =~ s/\n/\n /g;
2418     $msg =~ s/^\s+$/ ./mg;
2419     print O <<END or die $!;
2420 Description: $msg
2421 Author: $author
2422 $xinfo
2423 ---
2424
2425 END
2426     close O or die $!;
2427
2428     {
2429         local $ENV{'EDITOR'} = cmdoutput qw(realpath --), $0;
2430         local $ENV{'VISUAL'} = $ENV{'EDITOR'};
2431         local $ENV{$fakeeditorenv} = cmdoutput qw(realpath --), $descfn;
2432         runcmd_ordryrun_local @dpkgsource, qw(--commit .), $patchname;
2433     }
2434 }
2435
2436 sub quiltify_trees_differ ($$) {
2437     my ($x,$y) = @_;
2438     # returns 1 iff the two tree objects differ other than in debian/
2439     local $/=undef;
2440     my @cmd = (@git, qw(diff-tree --name-only -z), $x, $y);
2441     my $diffs= cmdoutput @cmd;
2442     foreach my $f (split /\0/, $diffs) {
2443         next if $f eq 'debian';
2444         return 1;
2445     }
2446     return 0;
2447 }
2448
2449 sub quiltify_tree_sentinelfiles ($) {
2450     # lists the `sentinel' files present in the tree
2451     my ($x) = @_;
2452     my $r = cmdoutput @git, qw(ls-tree --name-only), $x,
2453         qw(-- debian/rules debian/control);
2454     $r =~ s/\n/,/g;
2455     return $r;
2456 }
2457
2458 sub quiltify ($$) {
2459     my ($clogp,$target) = @_;
2460
2461     # Quilt patchification algorithm
2462     #
2463     # We search backwards through the history of the main tree's HEAD
2464     # (T) looking for a start commit S whose tree object is identical
2465     # to to the patch tip tree (ie the tree corresponding to the
2466     # current dpkg-committed patch series).  For these purposes
2467     # `identical' disregards anything in debian/ - this wrinkle is
2468     # necessary because dpkg-source treates debian/ specially.
2469     #
2470     # We can only traverse edges where at most one of the ancestors'
2471     # trees differs (in changes outside in debian/).  And we cannot
2472     # handle edges which change .pc/ or debian/patches.  To avoid
2473     # going down a rathole we avoid traversing edges which introduce
2474     # debian/rules or debian/control.  And we set a limit on the
2475     # number of edges we are willing to look at.
2476     #
2477     # If we succeed, we walk forwards again.  For each traversed edge
2478     # PC (with P parent, C child) (starting with P=S and ending with
2479     # C=T) to we do this:
2480     #  - git checkout C
2481     #  - dpkg-source --commit with a patch name and message derived from C
2482     # After traversing PT, we git commit the changes which
2483     # should be contained within debian/patches.
2484
2485     changedir '../fake';
2486     mktree_in_ud_here();
2487     rmtree '.pc';
2488     runcmd @git, 'add', '.';
2489     my $oldtiptree=git_write_tree();
2490     changedir '../work';
2491
2492     # The search for the path S..T is breadth-first.  We maintain a
2493     # todo list containing search nodes.  A search node identifies a
2494     # commit, and looks something like this:
2495     #  $p = {
2496     #      Commit => $git_commit_id,
2497     #      Child => $c,                          # or undef if P=T
2498     #      Whynot => $reason_edge_PC_unsuitable, # in @nots only
2499     #      Nontrivial => true iff $p..$c has relevant changes
2500     #  };
2501
2502     my @todo;
2503     my @nots;
2504     my $sref_S;
2505     my $max_work=100;
2506     my %considered; # saves being exponential on some weird graphs
2507
2508     my $t_sentinels = quiltify_tree_sentinelfiles $target;
2509
2510     my $not = sub {
2511         my ($search,$whynot) = @_;
2512         printdebug " search NOT $search->{Commit} $whynot\n";
2513         $search->{Whynot} = $whynot;
2514         push @nots, $search;
2515         no warnings qw(exiting);
2516         next;
2517     };
2518
2519     push @todo, {
2520         Commit => $target,
2521     };
2522
2523     while (@todo) {
2524         my $c = shift @todo;
2525         next if $considered{$c->{Commit}}++;
2526
2527         $not->($c, "maximum search space exceeded") if --$max_work <= 0;
2528
2529         printdebug "quiltify investigate $c->{Commit}\n";
2530
2531         # are we done?
2532         if (!quiltify_trees_differ $c->{Commit}, $oldtiptree) {
2533             printdebug " search finished hooray!\n";
2534             $sref_S = $c;
2535             last;
2536         }
2537
2538         if ($quilt_mode eq 'nofix') {
2539             fail "quilt fixup required but quilt mode is \`nofix'\n".
2540                 "HEAD commit $c->{Commit} differs from tree implied by ".
2541                 " debian/patches (tree object $oldtiptree)";
2542         }
2543         if ($quilt_mode eq 'smash') {
2544             printdebug " search quitting smash\n";
2545             last;
2546         }
2547
2548         my $c_sentinels = quiltify_tree_sentinelfiles $c->{Commit};
2549         $not->($c, "has $c_sentinels not $t_sentinels")
2550             if $c_sentinels ne $t_sentinels;
2551
2552         my $commitdata = cmdoutput @git, qw(cat-file commit), $c->{Commit};
2553         $commitdata =~ m/\n\n/;
2554         $commitdata =~ $`;
2555         my @parents = ($commitdata =~ m/^parent (\w+)$/gm);
2556         @parents = map { { Commit => $_, Child => $c } } @parents;
2557
2558         $not->($c, "root commit") if !@parents;
2559
2560         foreach my $p (@parents) {
2561             $p->{Nontrivial}= quiltify_trees_differ $p->{Commit},$c->{Commit};
2562         }
2563         my $ndiffers = grep { $_->{Nontrivial} } @parents;
2564         $not->($c, "merge ($ndiffers nontrivial parents)") if $ndiffers > 1;
2565
2566         foreach my $p (@parents) {
2567             printdebug "considering C=$c->{Commit} P=$p->{Commit}\n";
2568
2569             my @cmd= (@git, qw(diff-tree -r --name-only),
2570                       $p->{Commit},$c->{Commit}, qw(-- debian/patches .pc));
2571             my $patchstackchange = cmdoutput @cmd;
2572             if (length $patchstackchange) {
2573                 $patchstackchange =~ s/\n/,/g;
2574                 $not->($p, "changed $patchstackchange");
2575             }
2576
2577             printdebug " search queue P=$p->{Commit} ",
2578                 ($p->{Nontrivial} ? "NT" : "triv"),"\n";
2579             push @todo, $p;
2580         }
2581     }
2582
2583     if (!$sref_S) {
2584         printdebug "quiltify want to smash\n";
2585
2586         my $abbrev = sub {
2587             my $x = $_[0]{Commit};
2588             $x =~ s/(.*?[0-9a-z]{8})[0-9a-z]*$/$1/;
2589             return $;
2590         };
2591         my $reportnot = sub {
2592             my ($notp) = @_;
2593             my $s = $abbrev->($notp);
2594             my $c = $notp->{Child};
2595             $s .= "..".$abbrev->($c) if $c;
2596             $s .= ": ".$notp->{Whynot};
2597             return $s;
2598         };
2599         if ($quilt_mode eq 'linear') {
2600             print STDERR "$us: quilt fixup cannot be linear.  Stopped at:\n";
2601             foreach my $notp (@nots) {
2602                 print STDERR "$us:  ", $reportnot->($notp), "\n";
2603             }
2604             fail "quilt fixup naive history linearisation failed.\n".
2605  "Use dpkg-source --commit by hand; or, --quilt=smash for one ugly patch";
2606         } elsif ($quilt_mode eq 'smash') {
2607         } elsif ($quilt_mode eq 'auto') {
2608             progress "quilt fixup cannot be linear, smashing...";
2609         } else {
2610             die "$quilt_mode ?";
2611         }
2612
2613         my $time = time;
2614         my $ncommits = 3;
2615         my $msg = cmdoutput @git, qw(log), "-n$ncommits";
2616
2617         quiltify_dpkg_commit "auto-$version-$target-$time",
2618             (getfield $clogp, 'Maintainer'),
2619             "Automatically generated patch ($clogp->{Version})\n".
2620             "Last (up to) $ncommits git changes, FYI:\n\n". $msg;
2621         return;
2622     }
2623
2624     progress "quiltify linearisation planning successful, executing...";
2625
2626     for (my $p = $sref_S;
2627          my $c = $p->{Child};
2628          $p = $p->{Child}) {
2629         printdebug "quiltify traverse $p->{Commit}..$c->{Commit}\n";
2630         next unless $p->{Nontrivial};
2631
2632         my $cc = $c->{Commit};
2633
2634         my $commitdata = cmdoutput @git, qw(cat-file commit), $cc;
2635         $commitdata =~ m/\n\n/ or die "$c ?";
2636         $commitdata = $`;
2637         my $msg = $'; #';
2638         $commitdata =~ m/^author (.*) \d+ [-+0-9]+$/m or die "$cc ?";
2639         my $author = $1;
2640
2641         $msg =~ s/^(.*)\n*/$1\n/ or die "$cc $msg ?";
2642
2643         my $title = $1;
2644         my $patchname = $title;
2645         $patchname =~ s/[.:]$//;
2646         $patchname =~ y/ A-Z/-a-z/;
2647         $patchname =~ y/-a-z0-9_.+=~//cd;
2648         $patchname =~ s/^\W/x-$&/;
2649         $patchname = substr($patchname,0,40);
2650         my $index;
2651         for ($index='';
2652              stat "debian/patches/$patchname$index";
2653              $index++) { }
2654         $!==ENOENT or die "$patchname$index $!";
2655
2656         runcmd @git, qw(checkout -q), $cc;
2657
2658         # We use the tip's changelog so that dpkg-source doesn't
2659         # produce complaining messages from dpkg-parsechangelog.  None
2660         # of the information dpkg-source gets from the changelog is
2661         # actually relevant - it gets put into the original message
2662         # which dpkg-source provides our stunt editor, and then
2663         # overwritten.
2664         runcmd @git, qw(checkout -q), $target, qw(debian/changelog);
2665
2666         quiltify_dpkg_commit "$patchname$index", $author, $msg,
2667             "X-Dgit-Generated: $clogp->{Version} $cc\n";
2668
2669         runcmd @git, qw(checkout -q), $cc, qw(debian/changelog);
2670     }
2671
2672     runcmd @git, qw(checkout -q master);
2673 }
2674
2675 sub build_maybe_quilt_fixup () {
2676     my $format=get_source_format;
2677     return unless madformat $format;
2678     # sigh
2679
2680     check_for_vendor_patches();
2681
2682     # Our objective is:
2683     #  - honour any existing .pc in case it has any strangeness
2684     #  - determine the git commit corresponding to the tip of
2685     #    the patch stack (if there is one)
2686     #  - if there is such a git commit, convert each subsequent
2687     #    git commit into a quilt patch with dpkg-source --commit
2688     #  - otherwise convert all the differences in the tree into
2689     #    a single git commit
2690     #
2691     # To do this we:
2692
2693     # Our git tree doesn't necessarily contain .pc.  (Some versions of
2694     # dgit would include the .pc in the git tree.)  If there isn't
2695     # one, we need to generate one by unpacking the patches that we
2696     # have.
2697     #
2698     # We first look for a .pc in the git tree.  If there is one, we
2699     # will use it.  (This is not the normal case.)
2700     #
2701     # Otherwise need to regenerate .pc so that dpkg-source --commit
2702     # can work.  We do this as follows:
2703     #     1. Collect all relevant .orig from parent directory
2704     #     2. Generate a debian.tar.gz out of
2705     #         debian/{patches,rules,source/format}
2706     #     3. Generate a fake .dsc containing just these fields:
2707     #          Format Source Version Files
2708     #     4. Extract the fake .dsc
2709     #        Now the fake .dsc has a .pc directory.
2710     # (In fact we do this in every case, because in future we will
2711     # want to search for a good base commit for generating patches.)
2712     #
2713     # Then we can actually do the dpkg-source --commit
2714     #     1. Make a new working tree with the same object
2715     #        store as our main tree and check out the main
2716     #        tree's HEAD.
2717     #     2. Copy .pc from the fake's extraction, if necessary
2718     #     3. Run dpkg-source --commit
2719     #     4. If the result has changes to debian/, then
2720     #          - git-add them them
2721     #          - git-add .pc if we had a .pc in-tree
2722     #          - git-commit
2723     #     5. If we had a .pc in-tree, delete it, and git-commit
2724     #     6. Back in the main tree, fast forward to the new HEAD
2725
2726     my $clogp = parsechangelog();
2727     my $headref = git_rev_parse('HEAD');
2728
2729     prep_ud();
2730     changedir $ud;
2731
2732     my $upstreamversion=$version;
2733     $upstreamversion =~ s/-[^-]*$//;
2734
2735     my $fakeversion="$upstreamversion-~~DGITFAKE";
2736
2737     my $fakedsc=new IO::File 'fake.dsc', '>' or die $!;
2738     print $fakedsc <<END or die $!;
2739 Format: 3.0 (quilt)
2740 Source: $package
2741 Version: $fakeversion
2742 Files:
2743 END
2744
2745     my $dscaddfile=sub {
2746         my ($b) = @_;
2747
2748         my $md = new Digest::MD5;
2749
2750         my $fh = new IO::File $b, '<' or die "$b $!";
2751         stat $fh or die $!;
2752         my $size = -s _;
2753
2754         $md->addfile($fh);
2755         print $fakedsc " ".$md->hexdigest." $size $b\n" or die $!;
2756     };
2757
2758     foreach my $f (<../../../../*>) { #/){
2759         my $b=$f; $b =~ s{.*/}{};
2760         next unless is_orig_file $b, srcfn $upstreamversion,'';
2761         link $f, $b or die "$b $!";
2762         $dscaddfile->($b);
2763     }
2764
2765     my @files=qw(debian/source/format debian/rules);
2766     if (stat_exists '../../../debian/patches') {
2767         push @files, 'debian/patches';
2768     }
2769
2770     my $debtar= srcfn $fakeversion,'.debian.tar.gz';
2771     runcmd qw(env GZIP=-1 tar -zcf), "./$debtar", qw(-C ../../..), @files;
2772
2773     $dscaddfile->($debtar);
2774     close $fakedsc or die $!;
2775
2776     runcmd qw(sh -ec), 'exec dpkg-source --no-check -x fake.dsc >/dev/null';
2777
2778     my $fakexdir= $package.'-'.(stripepoch $upstreamversion);
2779     rename $fakexdir, "fake" or die "$fakexdir $!";
2780
2781     mkdir "work" or die $!;
2782     changedir "work";
2783     mktree_in_ud_here();
2784     runcmd @git, qw(reset --hard), $headref;
2785
2786     my $mustdeletepc=0;
2787     if (stat_exists ".pc") {
2788         -d _ or die;
2789         progress "Tree already contains .pc - will use it then delete it.";
2790         $mustdeletepc=1;
2791     } else {
2792         rename '../fake/.pc','.pc' or die $!;
2793     }
2794
2795     quiltify($clogp,$headref);
2796
2797     if (!open P, '>>', ".pc/applied-patches") {
2798         $!==&ENOENT or die $!;
2799     } else {
2800         close P;
2801     }
2802
2803     commit_quilty_patch();
2804
2805     if ($mustdeletepc) {
2806         runcmd @git, qw(rm -rqf .pc);
2807         commit_admin "Commit removal of .pc (quilt series tracking data)";
2808     }
2809
2810     changedir '../../../..';
2811     runcmd @git, qw(pull --ff-only -q .git/dgit/unpack/work master);
2812 }
2813
2814 sub quilt_fixup_editor () {
2815     my $descfn = $ENV{$fakeeditorenv};
2816     my $editing = $ARGV[$#ARGV];
2817     open I1, '<', $descfn or die "$descfn: $!";
2818     open I2, '<', $editing or die "$editing: $!";
2819     unlink $editing or die "$editing: $!";
2820     open O, '>', $editing or die "$editing: $!";
2821     while (<I1>) { print O or die $!; } I1->error and die $!;
2822     my $copying = 0;
2823     while (<I2>) {
2824         $copying ||= m/^\-\-\- /;
2825         next unless $copying;
2826         print O or die $!;
2827     }
2828     I2->error and die $!;
2829     close O or die $1;
2830     exit 0;
2831 }
2832
2833 #----- other building -----
2834
2835 sub clean_tree () {
2836     if ($cleanmode eq 'dpkg-source') {
2837         runcmd_ordryrun_local @dpkgbuildpackage, qw(-T clean);
2838     } elsif ($cleanmode eq 'dpkg-source-d') {
2839         runcmd_ordryrun_local @dpkgbuildpackage, qw(-d -T clean);
2840     } elsif ($cleanmode eq 'git') {
2841         runcmd_ordryrun_local @git, qw(clean -xdf);
2842     } elsif ($cleanmode eq 'git-ff') {
2843         runcmd_ordryrun_local @git, qw(clean -xdff);
2844     } elsif ($cleanmode eq 'check') {
2845         my $leftovers = cmdoutput @git, qw(clean -xdn);
2846         if (length $leftovers) {
2847             print STDERR $leftovers, "\n" or die $!;
2848             fail "tree contains uncommitted files and --clean=check specified";
2849         }
2850     } elsif ($cleanmode eq 'none') {
2851     } else {
2852         die "$cleanmode ?";
2853     }
2854 }
2855
2856 sub cmd_clean () {
2857     badusage "clean takes no additional arguments" if @ARGV;
2858     notpushing();
2859     clean_tree();
2860 }
2861
2862 sub build_prep () {
2863     notpushing();
2864     badusage "-p is not allowed when building" if defined $package;
2865     check_not_dirty();
2866     clean_tree();
2867     my $clogp = parsechangelog();
2868     $isuite = getfield $clogp, 'Distribution';
2869     $package = getfield $clogp, 'Source';
2870     $version = getfield $clogp, 'Version';
2871     build_maybe_quilt_fixup();
2872 }
2873
2874 sub changesopts () {
2875     my @opts =@changesopts[1..$#changesopts];
2876     if (!defined $changes_since_version) {
2877         my @vsns = archive_query('archive_query');
2878         my @quirk = access_quirk();
2879         if ($quirk[0] eq 'backports') {
2880             local $isuite = $quirk[2];
2881             local $csuite;
2882             canonicalise_suite();
2883             push @vsns, archive_query('archive_query');
2884         }
2885         if (@vsns) {
2886             @vsns = map { $_->[0] } @vsns;
2887             @vsns = sort { -version_compare($a, $b) } @vsns;
2888             $changes_since_version = $vsns[0];
2889             progress "changelog will contain changes since $vsns[0]";
2890         } else {
2891             $changes_since_version = '_';
2892             progress "package seems new, not specifying -v<version>";
2893         }
2894     }
2895     if ($changes_since_version ne '_') {
2896         unshift @opts, "-v$changes_since_version";
2897     }
2898     return @opts;
2899 }
2900
2901 sub massage_dbp_args ($) {
2902     my ($cmd) = @_;
2903     return unless $cleanmode =~ m/git|none/;
2904     debugcmd '#massaging#', @$cmd if $debuglevel>1;
2905     my @newcmd = shift @$cmd;
2906     # -nc has the side effect of specifying -b if nothing else specified
2907     push @newcmd, '-nc';
2908     # and some combinations of -S, -b, et al, are errors, rather than
2909     # later simply overriding earlier
2910     push @newcmd, '-F' unless grep { m/^-[bBASF]$/ } @$cmd;
2911     push @newcmd, @$cmd;
2912     @$cmd = @newcmd;
2913 }
2914
2915 sub cmd_build {
2916     build_prep();
2917     my @dbp = (@dpkgbuildpackage, qw(-us -uc), changesopts(), @ARGV);
2918     massage_dbp_args \@dbp;
2919     runcmd_ordryrun_local @dbp;
2920     printdone "build successful\n";
2921 }
2922
2923 sub cmd_git_build {
2924     build_prep();
2925     my @dbp = @dpkgbuildpackage;
2926     massage_dbp_args \@dbp;
2927     my @cmd =
2928         (qw(git-buildpackage -us -uc --git-no-sign-tags),
2929          "--git-builder=@dbp");
2930     unless (grep { m/^--git-debian-branch|^--git-ignore-branch/ } @ARGV) {
2931         canonicalise_suite();
2932         push @cmd, "--git-debian-branch=".lbranch();
2933     }
2934     push @cmd, changesopts();
2935     runcmd_ordryrun_local @cmd, @ARGV;
2936     printdone "build successful\n";
2937 }
2938
2939 sub build_source {
2940     build_prep();
2941     $sourcechanges = "${package}_".(stripepoch $version)."_source.changes";
2942     $dscfn = dscfn($version);
2943     if ($cleanmode eq 'dpkg-source') {
2944         runcmd_ordryrun_local (@dpkgbuildpackage, qw(-us -uc -S)),
2945             changesopts();
2946     } elsif ($cleanmode eq 'dpkg-source-d') {
2947         runcmd_ordryrun_local (@dpkgbuildpackage, qw(-us -uc -S -d)),
2948             changesopts();
2949     } else {
2950         my $pwd = must_getcwd();
2951         my $leafdir = basename $pwd;
2952         changedir "..";
2953         runcmd_ordryrun_local @dpkgsource, qw(-b --), $leafdir;
2954         changedir $pwd;
2955         runcmd_ordryrun_local qw(sh -ec),
2956             'exec >$1; shift; exec "$@"','x',
2957             "../$sourcechanges",
2958             @dpkggenchanges, qw(-S), changesopts();
2959     }
2960 }
2961
2962 sub cmd_build_source {
2963     badusage "build-source takes no additional arguments" if @ARGV;
2964     build_source();
2965     printdone "source built, results in $dscfn and $sourcechanges";
2966 }
2967
2968 sub cmd_sbuild {
2969     build_source();
2970     changedir "..";
2971     my $pat = "${package}_".(stripepoch $version)."_*.changes";
2972     if (act_local()) {
2973         stat_exists $dscfn or fail "$dscfn (in parent directory): $!";
2974         stat_exists $sourcechanges
2975             or fail "$sourcechanges (in parent directory): $!";
2976         foreach my $cf (glob $pat) {
2977             next if $cf eq $sourcechanges;
2978             unlink $cf or fail "remove $cf: $!";
2979         }
2980     }
2981     runcmd_ordryrun_local @sbuild, @ARGV, qw(-d), $isuite, $dscfn;
2982     my @changesfiles = glob $pat;
2983     @changesfiles = sort {
2984         ($b =~ m/_source\.changes$/ <=> $a =~ m/_source\.changes$/)
2985             or $a cmp $b
2986     } @changesfiles;
2987     fail "wrong number of different changes files (@changesfiles)"
2988         unless @changesfiles;
2989     runcmd_ordryrun_local @mergechanges, @changesfiles;
2990     my $multichanges = "${package}_".(stripepoch $version)."_multi.changes";
2991     if (act_local()) {
2992         stat_exists $multichanges or fail "$multichanges: $!";
2993     }
2994     printdone "build successful, results in $multichanges\n" or die $!;
2995 }
2996
2997 sub cmd_quilt_fixup {
2998     badusage "incorrect arguments to dgit quilt-fixup" if @ARGV;
2999     my $clogp = parsechangelog();
3000     $version = getfield $clogp, 'Version';
3001     $package = getfield $clogp, 'Source';
3002     build_maybe_quilt_fixup();
3003 }
3004
3005 sub cmd_archive_api_query {
3006     badusage "need only 1 subpath argument" unless @ARGV==1;
3007     my ($subpath) = @ARGV;
3008     my @cmd = archive_api_query_cmd($subpath);
3009     debugcmd ">",@cmd;
3010     exec @cmd or fail "exec curl: $!\n";
3011 }
3012
3013 sub cmd_clone_dgit_repos_server {
3014     badusage "need destination argument" unless @ARGV==1;
3015     my ($destdir) = @ARGV;
3016     $package = '_dgit-repos-server';
3017     my @cmd = (@git, qw(clone), access_giturl(), $destdir);
3018     debugcmd ">",@cmd;
3019     exec @cmd or fail "exec git clone: $!\n";
3020 }
3021
3022 sub cmd_setup_mergechangelogs {
3023     badusage "no arguments allowed to dgit setup-mergechangelogs" if @ARGV;
3024     setup_mergechangelogs();
3025 }
3026
3027 #---------- argument parsing and main program ----------
3028
3029 sub cmd_version {
3030     print "dgit version $our_version\n" or die $!;
3031     exit 0;
3032 }
3033
3034 sub parseopts () {
3035     my $om;
3036
3037     if (defined $ENV{'DGIT_SSH'}) {
3038         @ssh = string_to_ssh $ENV{'DGIT_SSH'};
3039     } elsif (defined $ENV{'GIT_SSH'}) {
3040         @ssh = ($ENV{'GIT_SSH'});
3041     }
3042
3043     while (@ARGV) {
3044         last unless $ARGV[0] =~ m/^-/;
3045         $_ = shift @ARGV;
3046         last if m/^--?$/;
3047         if (m/^--/) {
3048             if (m/^--dry-run$/) {
3049                 push @ropts, $_;
3050                 $dryrun_level=2;
3051             } elsif (m/^--damp-run$/) {
3052                 push @ropts, $_;
3053                 $dryrun_level=1;
3054             } elsif (m/^--no-sign$/) {
3055                 push @ropts, $_;
3056                 $sign=0;
3057             } elsif (m/^--help$/) {
3058                 cmd_help();
3059             } elsif (m/^--version$/) {
3060                 cmd_version();
3061             } elsif (m/^--new$/) {
3062                 push @ropts, $_;
3063                 $new_package=1;
3064             } elsif (m/^--since-version=([^_]+|_)$/) {
3065                 push @ropts, $_;
3066                 $changes_since_version = $1;
3067             } elsif (m/^--([-0-9a-z]+)=(.+)/s &&
3068                      ($om = $opts_opt_map{$1}) &&
3069                      length $om->[0]) {
3070                 push @ropts, $_;
3071                 $om->[0] = $2;
3072             } elsif (m/^--([-0-9a-z]+):(.*)/s &&
3073                      !$opts_opt_cmdonly{$1} &&
3074                      ($om = $opts_opt_map{$1})) {
3075                 push @ropts, $_;
3076                 push @$om, $2;
3077             } elsif (m/^--existing-package=(.*)/s) {
3078                 push @ropts, $_;
3079                 $existing_package = $1;
3080             } elsif (m/^--initiator-tempdir=(.*)/s) {
3081                 $initiator_tempdir = $1;
3082                 $initiator_tempdir =~ m#^/# or
3083                     badusage "--initiator-tempdir must be used specify an".
3084                         " absolute, not relative, directory."
3085             } elsif (m/^--distro=(.*)/s) {
3086                 push @ropts, $_;
3087                 $idistro = $1;
3088             } elsif (m/^--build-products-dir=(.*)/s) {
3089                 push @ropts, $_;
3090                 $buildproductsdir = $1;
3091             } elsif (m/^--clean=(dpkg-source(?:-d)?|git|git-ff|check|none)$/s) {
3092                 push @ropts, $_;
3093                 $cleanmode = $1;
3094             } elsif (m/^--clean=(.*)$/s) {
3095                 badusage "unknown cleaning mode \`$1'";
3096             } elsif (m/^--quilt=($quilt_modes_re)$/s) {
3097                 push @ropts, $_;
3098                 $quilt_mode = $1;
3099             } elsif (m/^--quilt=(.*)$/s) {
3100                 badusage "unknown quilt fixup mode \`$1'";
3101             } elsif (m/^--ignore-dirty$/s) {
3102                 push @ropts, $_;
3103                 $ignoredirty = 1;
3104             } elsif (m/^--no-quilt-fixup$/s) {
3105                 push @ropts, $_;
3106                 $quilt_mode = 'nocheck';
3107             } elsif (m/^--no-rm-on-error$/s) {
3108                 push @ropts, $_;
3109                 $rmonerror = 0;
3110             } elsif (m/^--deliberately-($deliberately_re)$/s) {
3111                 push @ropts, $_;
3112                 push @deliberatelies, $&;
3113             } else {
3114                 badusage "unknown long option \`$_'";
3115             }
3116         } else {
3117             while (m/^-./s) {
3118                 if (s/^-n/-/) {
3119                     push @ropts, $&;
3120                     $dryrun_level=2;
3121                 } elsif (s/^-L/-/) {
3122                     push @ropts, $&;
3123                     $dryrun_level=1;
3124                 } elsif (s/^-h/-/) {
3125                     cmd_help();
3126                 } elsif (s/^-D/-/) {
3127                     push @ropts, $&;
3128                     $debuglevel++;
3129                     enabledebug();
3130                 } elsif (s/^-N/-/) {
3131                     push @ropts, $&;
3132                     $new_package=1;
3133                 } elsif (s/^-v([^_]+|_)$//s) {
3134                     push @ropts, $&;
3135                     $changes_since_version = $1;
3136                 } elsif (m/^-m/) {
3137                     push @ropts, $&;
3138                     push @changesopts, $_;
3139                     $_ = '';
3140                 } elsif (s/^-c(.*=.*)//s) {
3141                     push @ropts, $&;
3142                     push @git, '-c', $1;
3143                 } elsif (s/^-d(.+)//s) {
3144                     push @ropts, $&;
3145                     $idistro = $1;
3146                 } elsif (s/^-C(.+)//s) {
3147                     push @ropts, $&;
3148                     $changesfile = $1;
3149                     if ($changesfile =~ s#^(.*)/##) {
3150                         $buildproductsdir = $1;
3151                     }
3152                 } elsif (s/^-k(.+)//s) {
3153                     $keyid=$1;
3154                 } elsif (m/^-[vdCk]$/) {
3155                     badusage
3156  "option \`$_' requires an argument (and no space before the argument)";
3157                 } elsif (s/^-wn$//s) {
3158                     push @ropts, $&;
3159                     $cleanmode = 'none';
3160                 } elsif (s/^-wg$//s) {
3161                     push @ropts, $&;
3162                     $cleanmode = 'git';
3163                 } elsif (s/^-wgf$//s) {
3164                     push @ropts, $&;
3165                     $cleanmode = 'git-ff';
3166                 } elsif (s/^-wd$//s) {
3167                     push @ropts, $&;
3168                     $cleanmode = 'dpkg-source';
3169                 } elsif (s/^-wdd$//s) {
3170                     push @ropts, $&;
3171                     $cleanmode = 'dpkg-source-d';
3172                 } elsif (s/^-wc$//s) {
3173                     push @ropts, $&;
3174                     $cleanmode = 'check';
3175                 } else {
3176                     badusage "unknown short option \`$_'";
3177                 }
3178             }
3179         }
3180     }
3181 }
3182
3183 sub finalise_opts_opts () {
3184     foreach my $k (keys %opts_opt_map) {
3185         my $om = $opts_opt_map{$k};
3186
3187         my $v = access_cfg("cmd-$k", 'RETURN-UNDEF');
3188         if (defined $v) {
3189             badcfg "cannot set command for $k"
3190                 unless length $om->[0];
3191             $om->[0] = $v;
3192         }
3193
3194         foreach my $c (access_cfg_cfgs("opts-$k")) {
3195             my $vl = $gitcfg{$c};
3196             printdebug "CL $c ",
3197                 ($vl ? join " ", map { shellquote } @$vl : ""),
3198                 "\n" if $debuglevel >= 4;
3199             next unless $vl;
3200             badcfg "cannot configure options for $k"
3201                 if $opts_opt_cmdonly{$k};
3202             my $insertpos = $opts_cfg_insertpos{$k};
3203             @$om = ( @$om[0..$insertpos-1],
3204                      @$vl,
3205                      @$om[$insertpos..$#$om] );
3206         }
3207     }
3208 }
3209
3210 if ($ENV{$fakeeditorenv}) {
3211     git_slurp_config();
3212     quilt_fixup_editor();
3213 }
3214
3215 parseopts();
3216 git_slurp_config();
3217
3218 print STDERR "DRY RUN ONLY\n" if $dryrun_level > 1;
3219 print STDERR "DAMP RUN - WILL MAKE LOCAL (UNSIGNED) CHANGES\n"
3220     if $dryrun_level == 1;
3221 if (!@ARGV) {
3222     print STDERR $helpmsg or die $!;
3223     exit 8;
3224 }
3225 my $cmd = shift @ARGV;
3226 $cmd =~ y/-/_/;
3227
3228 if (!defined $quilt_mode) {
3229     local $access_forpush;
3230     $quilt_mode = cfg('dgit.force.quilt-mode', 'RETURN-UNDEF')
3231         // access_cfg('quilt-mode', 'RETURN-UNDEF')
3232         // 'linear';
3233     $quilt_mode =~ m/^($quilt_modes_re)$/
3234         or badcfg "unknown quilt-mode \`$quilt_mode'";
3235     $quilt_mode = $1;
3236 }
3237
3238 my $fn = ${*::}{"cmd_$cmd"};
3239 $fn or badusage "unknown operation $cmd";
3240 $fn->();