dgit

   1 #!/usr/bin/perl -w
   2 # dgit
   3 # Integration between git and Debian-style archives
   4 #
   5 # Copyright (C)2013-2016 Ian Jackson
   6 #
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 use strict;
  21
  22 use Debian::Dgit;
  23 setup_sigwarn();
  24
  25 use IO::Handle;
  26 use Data::Dumper;
  27 use LWP::UserAgent;
  28 use Dpkg::Control::Hash;
  29 use File::Path;
  30 use File::Temp qw(tempdir);
  31 use File::Basename;
  32 use Dpkg::Version;
  33 use POSIX;
  34 use IPC::Open2;
  35 use Digest::SHA;
  36 use Digest::MD5;
  37 use List::Util qw(any);
  38 use List::MoreUtils qw(pairwise);
  39 use Text::Glob qw(match_glob);
  40 use Fcntl qw(:DEFAULT :flock);
  41 use Carp;
  42
  43 use Debian::Dgit;
  44
  45 our $our_version = 'UNRELEASED'; ###substituted###
  46 our $absurdity = undef; ###substituted###
  47
  48 our @rpushprotovsn_support = qw(4 3 2); # 4 is new tag format
  49 our $protovsn;
  50
  51 our $isuite = 'unstable';
  52 our $idistro;
  53 our $package;
  54 our @ropts;
  55
  56 our $sign = 1;
  57 our $dryrun_level = 0;
  58 our $changesfile;
  59 our $buildproductsdir = '..';
  60 our $new_package = 0;
  61 our $ignoredirty = 0;
  62 our $rmonerror = 1;
  63 our @deliberatelies;
  64 our %previously;
  65 our $existing_package = 'dpkg';
  66 our $cleanmode;
  67 our $changes_since_version;
  68 our $rmchanges;
  69 our $overwrite_version; # undef: not specified; '': check changelog
  70 our $quilt_mode;
  71 our $quilt_modes_re = 'linear|smash|auto|nofix|nocheck|gbp|dpm|unapplied';
  72 our $dodep14tag;
  73 our $dodep14tag_re = 'want|no|always';
  74 our $split_brain_save;
  75 our $we_are_responder;
  76 our $initiator_tempdir;
  77 our $patches_applied_dirtily = 00;
  78 our $tagformat_want;
  79 our $tagformat;
  80 our $tagformatfn;
  81 our $chase_dsc_distro=1;
  82
  83 our %forceopts = map { $_=>0 }
  84     qw(unrepresentable unsupported-source-format
  85        dsc-changes-mismatch changes-origs-exactly
  86        import-gitapply-absurd
  87        import-gitapply-no-absurd
  88        import-dsc-with-dgit-field);
  89
  90 our %format_ok = map { $_=>1 } ("1.0","3.0 (native)","3.0 (quilt)");
  91
  92 our $suite_re = '[-+.0-9a-z]+';
  93 our $cleanmode_re = 'dpkg-source(?:-d)?|git|git-ff|check|none';
  94 our $orig_f_comp_re = 'orig(?:-[-0-9a-z]+)?';
  95 our $orig_f_sig_re = '\\.(?:asc|gpg|pgp)';
  96 our $orig_f_tail_re = "$orig_f_comp_re\\.tar(?:\\.\\w+)?(?:$orig_f_sig_re)?";
  97
  98 our $git_authline_re = '^([^<>]+) \<(\S+)\> (\d+ [-+]\d+)$';
  99 our $splitbraincache = 'dgit-intern/quilt-cache';
 100 our $rewritemap = 'dgit-rewrite/map';
 101
 102 our (@git) = qw(git);
 103 our (@dget) = qw(dget);
 104 our (@curl) = qw(curl);
 105 our (@dput) = qw(dput);
 106 our (@debsign) = qw(debsign);
 107 our (@gpg) = qw(gpg);
 108 our (@sbuild) = qw(sbuild);
 109 our (@ssh) = 'ssh';
 110 our (@dgit) = qw(dgit);
 111 our (@aptget) = qw(apt-get);
 112 our (@aptcache) = qw(apt-cache);
 113 our (@dpkgbuildpackage) = qw(dpkg-buildpackage -i\.git/ -I.git);
 114 our (@dpkgsource) = qw(dpkg-source -i\.git/ -I.git);
 115 our (@dpkggenchanges) = qw(dpkg-genchanges);
 116 our (@mergechanges) = qw(mergechanges -f);
 117 our (@gbp_build) = ('');
 118 our (@gbp_pq) = ('gbp pq');
 119 our (@changesopts) = ('');
 120
 121 our %opts_opt_map = ('dget' => \@dget, # accept for compatibility
 122                      'curl' => \@curl,
 123                      'dput' => \@dput,
 124                      'debsign' => \@debsign,
 125                      'gpg' => \@gpg,
 126                      'sbuild' => \@sbuild,
 127                      'ssh' => \@ssh,
 128                      'dgit' => \@dgit,
 129                      'git' => \@git,
 130                      'apt-get' => \@aptget,
 131                      'apt-cache' => \@aptcache,
 132                      'dpkg-source' => \@dpkgsource,
 133                      'dpkg-buildpackage' => \@dpkgbuildpackage,
 134                      'dpkg-genchanges' => \@dpkggenchanges,
 135                      'gbp-build' => \@gbp_build,
 136                      'gbp-pq' => \@gbp_pq,
 137                      'ch' => \@changesopts,
 138                      'mergechanges' => \@mergechanges);
 139
 140 our %opts_opt_cmdonly = ('gpg' => 1, 'git' => 1);
 141 our %opts_cfg_insertpos = map {
 142     $_,
 143     scalar @{ $opts_opt_map{$_} }
 144 } keys %opts_opt_map;
 145
 146 sub parseopts_late_defaults();
 147
 148 our $keyid;
 149
 150 autoflush STDOUT 1;
 151
 152 our $supplementary_message = '';
 153 our $need_split_build_invocation = 0;
 154 our $split_brain = 0;
 155
 156 END {
 157     local ($@, $?);
 158     print STDERR "! $_\n" foreach $supplementary_message =~ m/^.+$/mg;
 159 }
 160
 161 our $remotename = 'dgit';
 162 our @ourdscfield = qw(Dgit Vcs-Dgit-Master);
 163 our $csuite;
 164 our $instead_distro;
 165
 166 if (!defined $absurdity) {
 167     $absurdity = $0;
 168     $absurdity =~ s{/[^/]+$}{/absurd} or die;
 169 }
 170
 171 sub debiantag ($$) {
 172     my ($v,$distro) = @_;
 173     return $tagformatfn->($v, $distro);
 174 }
 175
 176 sub debiantag_maintview ($$) {
 177     my ($v,$distro) = @_;
 178     return "$distro/".dep14_version_mangle $v;
 179 }
 180
 181 sub madformat ($) { $_[0] eq '3.0 (quilt)' }
 182
 183 sub lbranch () { return "$branchprefix/$csuite"; }
 184 my $lbranch_re = '^refs/heads/'.$branchprefix.'/([^/.]+)$';
 185 sub lref () { return "refs/heads/".lbranch(); }
 186 sub lrref () { return "refs/remotes/$remotename/".server_branch($csuite); }
 187 sub rrref () { return server_ref($csuite); }
 188
 189 sub stripepoch ($) {
 190     my ($vsn) = @_;
 191     $vsn =~ s/^\d+\://;
 192     return $vsn;
 193 }
 194
 195 sub srcfn ($$) {
 196     my ($vsn,$sfx) = @_;
 197     return "${package}_".(stripepoch $vsn).$sfx
 198 }
 199
 200 sub dscfn ($) {
 201     my ($vsn) = @_;
 202     return srcfn($vsn,".dsc");
 203 }
 204
 205 sub changespat ($;$) {
 206     my ($vsn, $arch) = @_;
 207     return "${package}_".(stripepoch $vsn)."_".($arch//'*').".changes";
 208 }
 209
 210 sub upstreamversion ($) {
 211     my ($vsn) = @_;
 212     $vsn =~ s/-[^-]+$//;
 213     return $vsn;
 214 }
 215
 216 our $us = 'dgit';
 217 initdebug('');
 218
 219 our @end;
 220 END {
 221     local ($?);
 222     foreach my $f (@end) {
 223         eval { $f->(); };
 224         print STDERR "$us: cleanup: $@" if length $@;
 225     }
 226 };
 227
 228 sub badcfg { print STDERR "$us: invalid configuration: @_\n"; exit 12; }
 229
 230 sub forceable_fail ($$) {
 231     my ($forceoptsl, $msg) = @_;
 232     fail $msg unless grep { $forceopts{$_} } @$forceoptsl;
 233     print STDERR "warning: overriding problem due to --force:\n". $msg;
 234 }
 235
 236 sub forceing ($) {
 237     my ($forceoptsl) = @_;
 238     my @got = grep { $forceopts{$_} } @$forceoptsl;
 239     return 0 unless @got;
 240     print STDERR
 241  "warning: skipping checks or functionality due to --force-$got[0]\n";
 242 }
 243
 244 sub no_such_package () {
 245     print STDERR "$us: package $package does not exist in suite $isuite\n";
 246     exit 4;
 247 }
 248
 249 sub changedir ($) {
 250     my ($newdir) = @_;
 251     printdebug "CD $newdir\n";
 252     chdir $newdir or confess "chdir: $newdir: $!";
 253 }
 254
 255 sub deliberately ($) {
 256     my ($enquiry) = @_;
 257     return !!grep { $_ eq "--deliberately-$enquiry" } @deliberatelies;
 258 }
 259
 260 sub deliberately_not_fast_forward () {
 261     foreach (qw(not-fast-forward fresh-repo)) {
 262         return 1 if deliberately($_) || deliberately("TEST-dgit-only-$_");
 263     }
 264 }
 265
 266 sub quiltmode_splitbrain () {
 267     $quilt_mode =~ m/gbp|dpm|unapplied/;
 268 }
 269
 270 sub opts_opt_multi_cmd {
 271     my @cmd;
 272     push @cmd, split /\s+/, shift @_;
 273     push @cmd, @_;
 274     @cmd;
 275 }
 276
 277 sub gbp_pq {
 278     return opts_opt_multi_cmd @gbp_pq;
 279 }
 280
 281 #---------- remote protocol support, common ----------
 282
 283 # remote push initiator/responder protocol:
 284 #  $ dgit remote-push-build-host <n-rargs> <rargs>... <push-args>...
 285 #  where <rargs> is <push-host-dir> <supported-proto-vsn>,... ...
 286 #  < dgit-remote-push-ready <actual-proto-vsn>
 287 #
 288 # occasionally:
 289 #
 290 #  > progress NBYTES
 291 #  [NBYTES message]
 292 #
 293 #  > supplementary-message NBYTES          # $protovsn >= 3
 294 #  [NBYTES message]
 295 #
 296 # main sequence:
 297 #
 298 #  > file parsed-changelog
 299 #  [indicates that output of dpkg-parsechangelog follows]
 300 #  > data-block NBYTES
 301 #  > [NBYTES bytes of data (no newline)]
 302 #  [maybe some more blocks]
 303 #  > data-end
 304 #
 305 #  > file dsc
 306 #  [etc]
 307 #
 308 #  > file changes
 309 #  [etc]
 310 #
 311 #  > param head DGIT-VIEW-HEAD
 312 #  > param csuite SUITE
 313 #  > param tagformat old|new
 314 #  > param maint-view MAINT-VIEW-HEAD
 315 #
 316 #  > previously REFNAME=OBJNAME       # if --deliberately-not-fast-forward
 317 #                                     # goes into tag, for replay prevention
 318 #
 319 #  > want signed-tag
 320 #  [indicates that signed tag is wanted]
 321 #  < data-block NBYTES
 322 #  < [NBYTES bytes of data (no newline)]
 323 #  [maybe some more blocks]
 324 #  < data-end
 325 #  < files-end
 326 #
 327 #  > want signed-dsc-changes
 328 #  < data-block NBYTES    [transfer of signed dsc]
 329 #  [etc]
 330 #  < data-block NBYTES    [transfer of signed changes]
 331 #  [etc]
 332 #  < files-end
 333 #
 334 #  > complete
 335
 336 our $i_child_pid;
 337
 338 sub i_child_report () {
 339     # Sees if our child has died, and reap it if so.  Returns a string
 340     # describing how it died if it failed, or undef otherwise.
 341     return undef unless $i_child_pid;
 342     my $got = waitpid $i_child_pid, WNOHANG;
 343     return undef if $got <= 0;
 344     die unless $got == $i_child_pid;
 345     $i_child_pid = undef;
 346     return undef unless $?;
 347     return "build host child ".waitstatusmsg();
 348 }
 349
 350 sub badproto ($$) {
 351     my ($fh, $m) = @_;
 352     fail "connection lost: $!" if $fh->error;
 353     fail "protocol violation; $m not expected";
 354 }
 355
 356 sub badproto_badread ($$) {
 357     my ($fh, $wh) = @_;
 358     fail "connection lost: $!" if $!;
 359     my $report = i_child_report();
 360     fail $report if defined $report;
 361     badproto $fh, "eof (reading $wh)";
 362 }
 363
 364 sub protocol_expect (&$) {
 365     my ($match, $fh) = @_;
 366     local $_;
 367     $_ = <$fh>;
 368     defined && chomp or badproto_badread $fh, "protocol message";
 369     if (wantarray) {
 370         my @r = &$match;
 371         return @r if @r;
 372     } else {
 373         my $r = &$match;
 374         return $r if $r;
 375     }
 376     badproto $fh, "\`$_'";
 377 }
 378
 379 sub protocol_send_file ($$) {
 380     my ($fh, $ourfn) = @_;
 381     open PF, "<", $ourfn or die "$ourfn: $!";
 382     for (;;) {
 383         my $d;
 384         my $got = read PF, $d, 65536;
 385         die "$ourfn: $!" unless defined $got;
 386         last if !$got;
 387         print $fh "data-block ".length($d)."\n" or die $!;
 388         print $fh $d or die $!;
 389     }
 390     PF->error and die "$ourfn $!";
 391     print $fh "data-end\n" or die $!;
 392     close PF;
 393 }
 394
 395 sub protocol_read_bytes ($$) {
 396     my ($fh, $nbytes) = @_;
 397     $nbytes =~ m/^[1-9]\d{0,5}$|^0$/ or badproto \*RO, "bad byte count";
 398     my $d;
 399     my $got = read $fh, $d, $nbytes;
 400     $got==$nbytes or badproto_badread $fh, "data block";
 401     return $d;
 402 }
 403
 404 sub protocol_receive_file ($$) {
 405     my ($fh, $ourfn) = @_;
 406     printdebug "() $ourfn\n";
 407     open PF, ">", $ourfn or die "$ourfn: $!";
 408     for (;;) {
 409         my ($y,$l) = protocol_expect {
 410             m/^data-block (.*)$/ ? (1,$1) :
 411             m/^data-end$/ ? (0,) :
 412             ();
 413         } $fh;
 414         last unless $y;
 415         my $d = protocol_read_bytes $fh, $l;
 416         print PF $d or die $!;
 417     }
 418     close PF or die $!;
 419 }
 420
 421 #---------- remote protocol support, responder ----------
 422
 423 sub responder_send_command ($) {
 424     my ($command) = @_;
 425     return unless $we_are_responder;
 426     # called even without $we_are_responder
 427     printdebug ">> $command\n";
 428     print PO $command, "\n" or die $!;
 429 }
 430
 431 sub responder_send_file ($$) {
 432     my ($keyword, $ourfn) = @_;
 433     return unless $we_are_responder;
 434     printdebug "]] $keyword $ourfn\n";
 435     responder_send_command "file $keyword";
 436     protocol_send_file \*PO, $ourfn;
 437 }
 438
 439 sub responder_receive_files ($@) {
 440     my ($keyword, @ourfns) = @_;
 441     die unless $we_are_responder;
 442     printdebug "[[ $keyword @ourfns\n";
 443     responder_send_command "want $keyword";
 444     foreach my $fn (@ourfns) {
 445         protocol_receive_file \*PI, $fn;
 446     }
 447     printdebug "[[\$\n";
 448     protocol_expect { m/^files-end$/ } \*PI;
 449 }
 450
 451 #---------- remote protocol support, initiator ----------
 452
 453 sub initiator_expect (&) {
 454     my ($match) = @_;
 455     protocol_expect { &$match } \*RO;
 456 }
 457
 458 #---------- end remote code ----------
 459
 460 sub progress {
 461     if ($we_are_responder) {
 462         my $m = join '', @_;
 463         responder_send_command "progress ".length($m) or die $!;
 464         print PO $m or die $!;
 465     } else {
 466         print @_, "\n";
 467     }
 468 }
 469
 470 our $ua;
 471
 472 sub url_get {
 473     if (!$ua) {
 474         $ua = LWP::UserAgent->new();
 475         $ua->env_proxy;
 476     }
 477     my $what = $_[$#_];
 478     progress "downloading $what...";
 479     my $r = $ua->get(@_) or die $!;
 480     return undef if $r->code == 404;
 481     $r->is_success or fail "failed to fetch $what: ".$r->status_line;
 482     return $r->decoded_content(charset => 'none');
 483 }
 484
 485 our ($dscdata,$dscurl,$dsc,$dsc_checked,$skew_warning_vsn);
 486
 487 sub runcmd {
 488     debugcmd "+",@_;
 489     $!=0; $?=-1;
 490     failedcmd @_ if system @_;
 491 }
 492
 493 sub act_local () { return $dryrun_level <= 1; }
 494 sub act_scary () { return !$dryrun_level; }
 495
 496 sub printdone {
 497     if (!$dryrun_level) {
 498         progress "$us ok: @_";
 499     } else {
 500         progress "would be ok: @_ (but dry run only)";
 501     }
 502 }
 503
 504 sub dryrun_report {
 505     printcmd(\*STDERR,$debugprefix."#",@_);
 506 }
 507
 508 sub runcmd_ordryrun {
 509     if (act_scary()) {
 510         runcmd @_;
 511     } else {
 512         dryrun_report @_;
 513     }
 514 }
 515
 516 sub runcmd_ordryrun_local {
 517     if (act_local()) {
 518         runcmd @_;
 519     } else {
 520         dryrun_report @_;
 521     }
 522 }
 523
 524 sub shell_cmd {
 525     my ($first_shell, @cmd) = @_;
 526     return qw(sh -ec), $first_shell.'; exec "$@"', 'x', @cmd;
 527 }
 528
 529 our $helpmsg = <<END;
 530 main usages:
 531   dgit [dgit-opts] clone [dgit-opts] package [suite] [./dir|/dir]
 532   dgit [dgit-opts] fetch|pull [dgit-opts] [suite]
 533   dgit [dgit-opts] build [dpkg-buildpackage-opts]
 534   dgit [dgit-opts] sbuild [sbuild-opts]
 535   dgit [dgit-opts] push [dgit-opts] [suite]
 536   dgit [dgit-opts] rpush build-host:build-dir ...
 537 important dgit options:
 538   -k<keyid>           sign tag and package with <keyid> instead of default
 539   --dry-run -n        do not change anything, but go through the motions
 540   --damp-run -L       like --dry-run but make local changes, without signing
 541   --new -N            allow introducing a new package
 542   --debug -D          increase debug level
 543   -c<name>=<value>    set git config option (used directly by dgit too)
 544 END
 545
 546 our $later_warning_msg = <<END;
 547 Perhaps the upload is stuck in incoming.  Using the version from git.
 548 END
 549
 550 sub badusage {
 551     print STDERR "$us: @_\n", $helpmsg or die $!;
 552     exit 8;
 553 }
 554
 555 sub nextarg {
 556     @ARGV or badusage "too few arguments";
 557     return scalar shift @ARGV;
 558 }
 559
 560 sub cmd_help () {
 561     print $helpmsg or die $!;
 562     exit 0;
 563 }
 564
 565 our $td = $ENV{DGIT_TEST_DUMMY_DIR} || "DGIT_TEST_DUMMY_DIR-unset";
 566
 567 our %defcfg = ('dgit.default.distro' => 'debian',
 568                'dgit.default.old-dsc-distro' => 'debian',
 569                'dgit-suite.*-security.distro' => 'debian-security',
 570                'dgit.default.username' => '',
 571                'dgit.default.archive-query-default-component' => 'main',
 572                'dgit.default.ssh' => 'ssh',
 573                'dgit.default.archive-query' => 'madison:',
 574                'dgit.default.sshpsql-dbname' => 'service=projectb',
 575                'dgit.default.aptget-components' => 'main',
 576                'dgit.default.dgit-tag-format' => 'new,old,maint',
 577                'dgit.dsc-url-proto-ok.http'    => 'true',
 578                'dgit.dsc-url-proto-ok.https'   => 'true',
 579                'dgit.dsc-url-proto-ok.git'     => 'true',
 580                'dgit.default.dsc-url-proto-ok' => 'false',
 581                # old means "repo server accepts pushes with old dgit tags"
 582                # new means "repo server accepts pushes with new dgit tags"
 583                # maint means "repo server accepts split brain pushes"
 584                # hist means "repo server may have old pushes without new tag"
 585                #   ("hist" is implied by "old")
 586                'dgit-distro.debian.archive-query' => 'ftpmasterapi:',
 587                'dgit-distro.debian.git-check' => 'url',
 588                'dgit-distro.debian.git-check-suffix' => '/info/refs',
 589                'dgit-distro.debian.new-private-pushers' => 't',
 590                'dgit-distro.debian/push.git-url' => '',
 591                'dgit-distro.debian/push.git-host' => 'push.dgit.debian.org',
 592                'dgit-distro.debian/push.git-user-force' => 'dgit',
 593                'dgit-distro.debian/push.git-proto' => 'git+ssh://',
 594                'dgit-distro.debian/push.git-path' => '/dgit/debian/repos',
 595                'dgit-distro.debian/push.git-create' => 'true',
 596                'dgit-distro.debian/push.git-check' => 'ssh-cmd',
 597  'dgit-distro.debian.archive-query-url', 'https://api.ftp-master.debian.org/',
 598 # 'dgit-distro.debian.archive-query-tls-key',
 599 #    '/etc/ssl/certs/%HOST%.pem:/etc/dgit/%HOST%.pem',
 600 # ^ this does not work because curl is broken nowadays
 601 # Fixing #790093 properly will involve providing providing the key
 602 # in some pacagke and maybe updating these paths.
 603 #
 604 # 'dgit-distro.debian.archive-query-tls-curl-args',
 605 #   '--ca-path=/etc/ssl/ca-debian',
 606 # ^ this is a workaround but works (only) on DSA-administered machines
 607                'dgit-distro.debian.git-url' => 'https://git.dgit.debian.org',
 608                'dgit-distro.debian.git-url-suffix' => '',
 609                'dgit-distro.debian.upload-host' => 'ftp-master', # for dput
 610                'dgit-distro.debian.mirror' => 'http://ftp.debian.org/debian/',
 611  'dgit-distro.debian-security.archive-query' => 'aptget:',
 612  'dgit-distro.debian-security.mirror' => 'http://security.debian.org/debian-security/',
 613  'dgit-distro.debian-security.aptget-suite-map' => 's#-security$#/updates#',
 614  'dgit-distro.debian-security.aptget-suite-rmap' => 's#$#-security#',
 615  'dgit-distro.debian-security.nominal-distro' => 'debian',
 616  'dgit-distro.debian.backports-quirk' => '(squeeze)-backports*',
 617  'dgit-distro.debian-backports.mirror' => 'http://backports.debian.org/debian-backports/',
 618                'dgit-distro.ubuntu.git-check' => 'false',
 619  'dgit-distro.ubuntu.mirror' => 'http://archive.ubuntu.com/ubuntu',
 620                'dgit-distro.test-dummy.ssh' => "$td/ssh",
 621                'dgit-distro.test-dummy.username' => "alice",
 622                'dgit-distro.test-dummy.git-check' => "ssh-cmd",
 623                'dgit-distro.test-dummy.git-create' => "ssh-cmd",
 624                'dgit-distro.test-dummy.git-url' => "$td/git",
 625                'dgit-distro.test-dummy.git-host' => "git",
 626                'dgit-distro.test-dummy.git-path' => "$td/git",
 627                'dgit-distro.test-dummy.archive-query' => "dummycatapi:",
 628                'dgit-distro.test-dummy.archive-query-url' => "file://$td/aq/",
 629                'dgit-distro.test-dummy.mirror' => "file://$td/mirror/",
 630                'dgit-distro.test-dummy.upload-host' => 'test-dummy',
 631                );
 632
 633 our %gitcfgs;
 634 our @gitcfgsources = qw(cmdline local global system);
 635
 636 sub git_slurp_config () {
 637     local ($debuglevel) = $debuglevel-2;
 638     local $/="\0";
 639
 640     # This algoritm is a bit subtle, but this is needed so that for
 641     # options which we want to be single-valued, we allow the
 642     # different config sources to override properly.  See #835858.
 643     foreach my $src (@gitcfgsources) {
 644         next if $src eq 'cmdline';
 645         # we do this ourselves since git doesn't handle it
 646
 647         my @cmd = (@git, qw(config -z --get-regexp), "--$src", qw(.*));
 648         debugcmd "|",@cmd;
 649
 650         open GITS, "-|", @cmd or die $!;
 651         while (<GITS>) {
 652             chomp or die;
 653             printdebug "=> ", (messagequote $_), "\n";
 654             m/\n/ or die "$_ ?";
 655             push @{ $gitcfgs{$src}{$`} }, $'; #';
 656         }
 657         $!=0; $?=0;
 658         close GITS
 659             or ($!==0 && $?==256)
 660             or failedcmd @cmd;
 661     }
 662 }
 663
 664 sub git_get_config ($) {
 665     my ($c) = @_;
 666     foreach my $src (@gitcfgsources) {
 667         my $l = $gitcfgs{$src}{$c};
 668         croak "$l $c" if $l && !ref $l;
 669         printdebug"C $c ".(defined $l ?
 670                            join " ", map { messagequote "'$_'" } @$l :
 671                            "undef")."\n"
 672             if $debuglevel >= 4;
 673         $l or next;
 674         @$l==1 or badcfg "multiple values for $c".
 675             " (in $src git config)" if @$l > 1;
 676         return $l->[0];
 677     }
 678     return undef;
 679 }
 680
 681 sub cfg {
 682     foreach my $c (@_) {
 683         return undef if $c =~ /RETURN-UNDEF/;
 684         printdebug "C? $c\n" if $debuglevel >= 5;
 685         my $v = git_get_config($c);
 686         return $v if defined $v;
 687         my $dv = $defcfg{$c};
 688         if (defined $dv) {
 689             printdebug "CD $c $dv\n" if $debuglevel >= 4;
 690             return $dv;
 691         }
 692     }
 693     badcfg "need value for one of: @_\n".
 694         "$us: distro or suite appears not to be (properly) supported";
 695 }
 696
 697 sub access_basedistro__noalias () {
 698     if (defined $idistro) {
 699         return $idistro;
 700     } else {
 701         my $def = cfg("dgit-suite.$isuite.distro", 'RETURN-UNDEF');
 702         return $def if defined $def;
 703         foreach my $src (@gitcfgsources, 'internal') {
 704             my $kl = $src eq 'internal' ? \%defcfg : $gitcfgs{$src};
 705             next unless $kl;
 706             foreach my $k (keys %$kl) {
 707                 next unless $k =~ m#^dgit-suite\.(.*)\.distro$#;
 708                 my $dpat = $1;
 709                 next unless match_glob $dpat, $isuite;
 710                 return $kl->{$k};
 711             }
 712         }
 713         return cfg("dgit.default.distro");
 714     }
 715 }
 716
 717 sub access_basedistro () {
 718     my $noalias = access_basedistro__noalias();
 719     my $canon = cfg("dgit-distro.$noalias.alias-canon",'RETURN-UNDEF');
 720     return $canon // $noalias;
 721 }
 722
 723 sub access_nomdistro () {
 724     my $base = access_basedistro();
 725     my $r = cfg("dgit-distro.$base.nominal-distro",'RETURN-UNDEF') // $base;
 726     $r =~ m/^$distro_re$/ or badcfg
 727  "bad syntax for (nominal) distro \`$r' (does not match /^$distro_re$/)";
 728     return $r;
 729 }
 730
 731 sub access_quirk () {
 732     # returns (quirk name, distro to use instead or undef, quirk-specific info)
 733     my $basedistro = access_basedistro();
 734     my $backports_quirk = cfg("dgit-distro.$basedistro.backports-quirk",
 735                               'RETURN-UNDEF');
 736     if (defined $backports_quirk) {
 737         my $re = $backports_quirk;
 738         $re =~ s/[^-0-9a-z_\%*()]/\\$&/ig;
 739         $re =~ s/\*/.*/g;
 740         $re =~ s/\%/([-0-9a-z_]+)/
 741             or $re =~ m/[()]/ or badcfg "backports-quirk needs \% or ( )";
 742         if ($isuite =~ m/^$re$/) {
 743             return ('backports',"$basedistro-backports",$1);
 744         }
 745     }
 746     return ('none',undef);
 747 }
 748
 749 our $access_forpush;
 750
 751 sub parse_cfg_bool ($$$) {
 752     my ($what,$def,$v) = @_;
 753     $v //= $def;
 754     return
 755         $v =~ m/^[ty1]/ ? 1 :
 756         $v =~ m/^[fn0]/ ? 0 :
 757         badcfg "$what needs t (true, y, 1) or f (false, n, 0) not \`$v'";
 758 }
 759
 760 sub access_forpush_config () {
 761     my $d = access_basedistro();
 762
 763     return 1 if
 764         $new_package &&
 765         parse_cfg_bool('new-private-pushers', 0,
 766                        cfg("dgit-distro.$d.new-private-pushers",
 767                            'RETURN-UNDEF'));
 768
 769     my $v = cfg("dgit-distro.$d.readonly", 'RETURN-UNDEF');
 770     $v //= 'a';
 771     return
 772         $v =~ m/^[ty1]/ ? 0 : # force readonly,    forpush = 0
 773         $v =~ m/^[fn0]/ ? 1 : # force nonreadonly, forpush = 1
 774         $v =~ m/^[a]/  ? '' : # auto,              forpush = ''
 775         badcfg "readonly needs t (true, y, 1) or f (false, n, 0) or a (auto)";
 776 }
 777
 778 sub access_forpush () {
 779     $access_forpush //= access_forpush_config();
 780     return $access_forpush;
 781 }
 782
 783 sub pushing () {
 784     die "$access_forpush ?" if ($access_forpush // 1) ne 1;
 785     badcfg "pushing but distro is configured readonly"
 786         if access_forpush_config() eq '0';
 787     $access_forpush = 1;
 788     $supplementary_message = <<'END' unless $we_are_responder;
 789 Push failed, before we got started.
 790 You can retry the push, after fixing the problem, if you like.
 791 END
 792     parseopts_late_defaults();
 793 }
 794
 795 sub notpushing () {
 796     parseopts_late_defaults();
 797 }
 798
 799 sub supplementary_message ($) {
 800     my ($msg) = @_;
 801     if (!$we_are_responder) {
 802         $supplementary_message = $msg;
 803         return;
 804     } elsif ($protovsn >= 3) {
 805         responder_send_command "supplementary-message ".length($msg)
 806             or die $!;
 807         print PO $msg or die $!;
 808     }
 809 }
 810
 811 sub access_distros () {
 812     # Returns list of distros to try, in order
 813     #
 814     # We want to try:
 815     #    0. `instead of' distro name(s) we have been pointed to
 816     #    1. the access_quirk distro, if any
 817     #    2a. the user's specified distro, or failing that  } basedistro
 818     #    2b. the distro calculated from the suite          }
 819     my @l = access_basedistro();
 820
 821     my (undef,$quirkdistro) = access_quirk();
 822     unshift @l, $quirkdistro;
 823     unshift @l, $instead_distro;
 824     @l = grep { defined } @l;
 825
 826     push @l, access_nomdistro();
 827
 828     if (access_forpush()) {
 829         @l = map { ("$_/push", $_) } @l;
 830     }
 831     @l;
 832 }
 833
 834 sub access_cfg_cfgs (@) {
 835     my (@keys) = @_;
 836     my @cfgs;
 837     # The nesting of these loops determines the search order.  We put
 838     # the key loop on the outside so that we search all the distros
 839     # for each key, before going on to the next key.  That means that
 840     # if access_cfg is called with a more specific, and then a less
 841     # specific, key, an earlier distro can override the less specific
 842     # without necessarily overriding any more specific keys.  (If the
 843     # distro wants to override the more specific keys it can simply do
 844     # so; whereas if we did the loop the other way around, it would be
 845     # impossible to for an earlier distro to override a less specific
 846     # key but not the more specific ones without restating the unknown
 847     # values of the more specific keys.
 848     my @realkeys;
 849     my @rundef;
 850     # We have to deal with RETURN-UNDEF specially, so that we don't
 851     # terminate the search prematurely.
 852     foreach (@keys) {
 853         if (m/RETURN-UNDEF/) { push @rundef, $_; last; }
 854         push @realkeys, $_
 855     }
 856     foreach my $d (access_distros()) {
 857         push @cfgs, map { "dgit-distro.$d.$_" } @realkeys;
 858     }
 859     push @cfgs, map { "dgit.default.$_" } @realkeys;
 860     push @cfgs, @rundef;
 861     return @cfgs;
 862 }
 863
 864 sub access_cfg (@) {
 865     my (@keys) = @_;
 866     my (@cfgs) = access_cfg_cfgs(@keys);
 867     my $value = cfg(@cfgs);
 868     return $value;
 869 }
 870
 871 sub access_cfg_bool ($$) {
 872     my ($def, @keys) = @_;
 873     parse_cfg_bool($keys[0], $def, access_cfg(@keys, 'RETURN-UNDEF'));
 874 }
 875
 876 sub string_to_ssh ($) {
 877     my ($spec) = @_;
 878     if ($spec =~ m/\s/) {
 879         return qw(sh -ec), 'exec '.$spec.' "$@"', 'x';
 880     } else {
 881         return ($spec);
 882     }
 883 }
 884
 885 sub access_cfg_ssh () {
 886     my $gitssh = access_cfg('ssh', 'RETURN-UNDEF');
 887     if (!defined $gitssh) {
 888         return @ssh;
 889     } else {
 890         return string_to_ssh $gitssh;
 891     }
 892 }
 893
 894 sub access_runeinfo ($) {
 895     my ($info) = @_;
 896     return ": dgit ".access_basedistro()." $info ;";
 897 }
 898
 899 sub access_someuserhost ($) {
 900     my ($some) = @_;
 901     my $user = access_cfg("$some-user-force", 'RETURN-UNDEF');
 902     defined($user) && length($user) or
 903         $user = access_cfg("$some-user",'username');
 904     my $host = access_cfg("$some-host");
 905     return length($user) ? "$user\@$host" : $host;
 906 }
 907
 908 sub access_gituserhost () {
 909     return access_someuserhost('git');
 910 }
 911
 912 sub access_giturl (;$) {
 913     my ($optional) = @_;
 914     my $url = access_cfg('git-url','RETURN-UNDEF');
 915     my $suffix;
 916     if (!length $url) {
 917         my $proto = access_cfg('git-proto', 'RETURN-UNDEF');
 918         return undef unless defined $proto;
 919         $url =
 920             $proto.
 921             access_gituserhost().
 922             access_cfg('git-path');
 923     } else {
 924         $suffix = access_cfg('git-url-suffix','RETURN-UNDEF');
 925     }
 926     $suffix //= '.git';
 927     return "$url/$package$suffix";
 928 }
 929
 930 sub parsecontrolfh ($$;$) {
 931     my ($fh, $desc, $allowsigned) = @_;
 932     our $dpkgcontrolhash_noissigned;
 933     my $c;
 934     for (;;) {
 935         my %opts = ('name' => $desc);
 936         $opts{allow_pgp}= $allowsigned || !$dpkgcontrolhash_noissigned;
 937         $c = Dpkg::Control::Hash->new(%opts);
 938         $c->parse($fh,$desc) or die "parsing of $desc failed";
 939         last if $allowsigned;
 940         last if $dpkgcontrolhash_noissigned;
 941         my $issigned= $c->get_option('is_pgp_signed');
 942         if (!defined $issigned) {
 943             $dpkgcontrolhash_noissigned= 1;
 944             seek $fh, 0,0 or die "seek $desc: $!";
 945         } elsif ($issigned) {
 946             fail "control file $desc is (already) PGP-signed. ".
 947                 " Note that dgit push needs to modify the .dsc and then".
 948                 " do the signature itself";
 949         } else {
 950             last;
 951         }
 952     }
 953     return $c;
 954 }
 955
 956 sub parsecontrol {
 957     my ($file, $desc, $allowsigned) = @_;
 958     my $fh = new IO::Handle;
 959     open $fh, '<', $file or die "$file: $!";
 960     my $c = parsecontrolfh($fh,$desc,$allowsigned);
 961     $fh->error and die $!;
 962     close $fh;
 963     return $c;
 964 }
 965
 966 sub getfield ($$) {
 967     my ($dctrl,$field) = @_;
 968     my $v = $dctrl->{$field};
 969     return $v if defined $v;
 970     fail "missing field $field in ".$dctrl->get_option('name');
 971 }
 972
 973 sub parsechangelog {
 974     my $c = Dpkg::Control::Hash->new(name => 'parsed changelog');
 975     my $p = new IO::Handle;
 976     my @cmd = (qw(dpkg-parsechangelog), @_);
 977     open $p, '-|', @cmd or die $!;
 978     $c->parse($p);
 979     $?=0; $!=0; close $p or failedcmd @cmd;
 980     return $c;
 981 }
 982
 983 sub commit_getclogp ($) {
 984     # Returns the parsed changelog hashref for a particular commit
 985     my ($objid) = @_;
 986     our %commit_getclogp_memo;
 987     my $memo = $commit_getclogp_memo{$objid};
 988     return $memo if $memo;
 989     mkpath '.git/dgit';
 990     my $mclog = ".git/dgit/clog-$objid";
 991     runcmd shell_cmd "exec >$mclog", @git, qw(cat-file blob),
 992         "$objid:debian/changelog";
 993     $commit_getclogp_memo{$objid} = parsechangelog("-l$mclog");
 994 }
 995
 996 sub must_getcwd () {
 997     my $d = getcwd();
 998     defined $d or fail "getcwd failed: $!";
 999     return $d;
1000 }
1001
1002 sub parse_dscdata () {
1003     my $dscfh = new IO::File \$dscdata, '<' or die $!;
1004     printdebug Dumper($dscdata) if $debuglevel>1;
1005     $dsc = parsecontrolfh($dscfh,$dscurl,1);
1006     printdebug Dumper($dsc) if $debuglevel>1;
1007 }
1008
1009 our %rmad;
1010
1011 sub archive_query ($;@) {
1012     my ($method) = shift @_;
1013     fail "this operation does not support multiple comma-separated suites"
1014         if $isuite =~ m/,/;
1015     my $query = access_cfg('archive-query','RETURN-UNDEF');
1016     $query =~ s/^(\w+):// or badcfg "invalid archive-query method \`$query'";
1017     my $proto = $1;
1018     my $data = $'; #';
1019     { no strict qw(refs); &{"${method}_${proto}"}($proto,$data,@_); }
1020 }
1021
1022 sub archive_query_prepend_mirror {
1023     my $m = access_cfg('mirror');
1024     return map { [ $_->[0], $m.$_->[1], @$_[2..$#$_] ] } @_;
1025 }
1026
1027 sub pool_dsc_subpath ($$) {
1028     my ($vsn,$component) = @_; # $package is implict arg
1029     my $prefix = substr($package, 0, $package =~ m/^l/ ? 4 : 1);
1030     return "/pool/$component/$prefix/$package/".dscfn($vsn);
1031 }
1032
1033 sub cfg_apply_map ($$$) {
1034     my ($varref, $what, $mapspec) = @_;
1035     return unless $mapspec;
1036
1037     printdebug "config $what EVAL{ $mapspec; }\n";
1038     $_ = $$varref;
1039     eval "package Dgit::Config; $mapspec;";
1040     die $@ if $@;
1041     $$varref = $_;
1042 }
1043
1044 #---------- `ftpmasterapi' archive query method (nascent) ----------
1045
1046 sub archive_api_query_cmd ($) {
1047     my ($subpath) = @_;
1048     my @cmd = (@curl, qw(-sS));
1049     my $url = access_cfg('archive-query-url');
1050     if ($url =~ m#^https://([-.0-9a-z]+)/#) {
1051         my $host = $1;
1052         my $keys = access_cfg('archive-query-tls-key','RETURN-UNDEF') //'';
1053         foreach my $key (split /\:/, $keys) {
1054             $key =~ s/\%HOST\%/$host/g;
1055             if (!stat $key) {
1056                 fail "for $url: stat $key: $!" unless $!==ENOENT;
1057                 next;
1058             }
1059             fail "config requested specific TLS key but do not know".
1060                 " how to get curl to use exactly that EE key ($key)";
1061 #           push @cmd, "--cacert", $key, "--capath", "/dev/enoent";
1062 #           # Sadly the above line does not work because of changes
1063 #           # to gnutls.   The real fix for #790093 may involve
1064 #           # new curl options.
1065             last;
1066         }
1067         # Fixing #790093 properly will involve providing a value
1068         # for this on clients.
1069         my $kargs = access_cfg('archive-query-tls-curl-ca-args','RETURN-UNDEF');
1070         push @cmd, split / /, $kargs if defined $kargs;
1071     }
1072     push @cmd, $url.$subpath;
1073     return @cmd;
1074 }
1075
1076 sub api_query ($$;$) {
1077     use JSON;
1078     my ($data, $subpath, $ok404) = @_;
1079     badcfg "ftpmasterapi archive query method takes no data part"
1080         if length $data;
1081     my @cmd = archive_api_query_cmd($subpath);
1082     my $url = $cmd[$#cmd];
1083     push @cmd, qw(-w %{http_code});
1084     my $json = cmdoutput @cmd;
1085     unless ($json =~ s/\d+\d+\d$//) {
1086         failedcmd_report_cmd undef, @cmd;
1087         fail "curl failed to print 3-digit HTTP code";
1088     }
1089     my $code = $&;
1090     return undef if $code eq '404' && $ok404;
1091     fail "fetch of $url gave HTTP code $code"
1092         unless $url =~ m#^file://# or $code =~ m/^2/;
1093     return decode_json($json);
1094 }
1095
1096 sub canonicalise_suite_ftpmasterapi {
1097     my ($proto,$data) = @_;
1098     my $suites = api_query($data, 'suites');
1099     my @matched;
1100     foreach my $entry (@$suites) {
1101         next unless grep {
1102             my $v = $entry->{$_};
1103             defined $v && $v eq $isuite;
1104         } qw(codename name);
1105         push @matched, $entry;
1106     }
1107     fail "unknown suite $isuite" unless @matched;
1108     my $cn;
1109     eval {
1110         @matched==1 or die "multiple matches for suite $isuite\n";
1111         $cn = "$matched[0]{codename}";
1112         defined $cn or die "suite $isuite info has no codename\n";
1113         $cn =~ m/^$suite_re$/ or die "suite $isuite maps to bad codename\n";
1114     };
1115     die "bad ftpmaster api response: $@\n".Dumper(\@matched)
1116         if length $@;
1117     return $cn;
1118 }
1119
1120 sub archive_query_ftpmasterapi {
1121     my ($proto,$data) = @_;
1122     my $info = api_query($data, "dsc_in_suite/$isuite/$package");
1123     my @rows;
1124     my $digester = Digest::SHA->new(256);
1125     foreach my $entry (@$info) {
1126         eval {
1127             my $vsn = "$entry->{version}";
1128             my ($ok,$msg) = version_check $vsn;
1129             die "bad version: $msg\n" unless $ok;
1130             my $component = "$entry->{component}";
1131             $component =~ m/^$component_re$/ or die "bad component";
1132             my $filename = "$entry->{filename}";
1133             $filename && $filename !~ m#[^-+:._~0-9a-zA-Z/]|^[/.]|/[/.]#
1134                 or die "bad filename";
1135             my $sha256sum = "$entry->{sha256sum}";
1136             $sha256sum =~ m/^[0-9a-f]+$/ or die "bad sha256sum";
1137             push @rows, [ $vsn, "/pool/$component/$filename",
1138                           $digester, $sha256sum ];
1139         };
1140         die "bad ftpmaster api response: $@\n".Dumper($entry)
1141             if length $@;
1142     }
1143     @rows = sort { -version_compare($a->[0],$b->[0]) } @rows;
1144     return archive_query_prepend_mirror @rows;
1145 }
1146
1147 sub file_in_archive_ftpmasterapi {
1148     my ($proto,$data,$filename) = @_;
1149     my $pat = $filename;
1150     $pat =~ s/_/\\_/g;
1151     $pat = "%/$pat";
1152     $pat =~ s#[^-+_.0-9a-z/]# sprintf '%%%02x', ord $& #ge;
1153     my $info = api_query($data, "file_in_archive/$pat", 1);
1154 }
1155
1156 #---------- `aptget' archive query method ----------
1157
1158 our $aptget_base;
1159 our $aptget_releasefile;
1160 our $aptget_configpath;
1161
1162 sub aptget_aptget   () { return @aptget,   qw(-c), $aptget_configpath; }
1163 sub aptget_aptcache () { return @aptcache, qw(-c), $aptget_configpath; }
1164
1165 sub aptget_cache_clean {
1166     runcmd_ordryrun_local qw(sh -ec),
1167         'cd "$1"; find -atime +30 -type f -print0 | xargs -0r rm --',
1168         'x', $aptget_base;
1169 }
1170
1171 sub aptget_lock_acquire () {
1172     my $lockfile = "$aptget_base/lock";
1173     open APTGET_LOCK, '>', $lockfile or die "open $lockfile: $!";
1174     flock APTGET_LOCK, LOCK_EX or die "lock $lockfile: $!";
1175 }
1176
1177 sub aptget_prep ($) {
1178     my ($data) = @_;
1179     return if defined $aptget_base;
1180
1181     badcfg "aptget archive query method takes no data part"
1182         if length $data;
1183
1184     my $cache = $ENV{XDG_CACHE_DIR} // "$ENV{HOME}/.cache";
1185
1186     ensuredir $cache;
1187     ensuredir "$cache/dgit";
1188     my $cachekey =
1189         access_cfg('aptget-cachekey','RETURN-UNDEF')
1190         // access_nomdistro();
1191
1192     $aptget_base = "$cache/dgit/aptget";
1193     ensuredir $aptget_base;
1194
1195     my $quoted_base = $aptget_base;
1196     die "$quoted_base contains bad chars, cannot continue"
1197         if $quoted_base =~ m/["\\]/; # apt.conf(5) says no escaping :-/
1198
1199     ensuredir $aptget_base;
1200
1201     aptget_lock_acquire();
1202
1203     aptget_cache_clean();
1204
1205     $aptget_configpath = "$aptget_base/apt.conf#$cachekey";
1206     my $sourceslist = "source.list#$cachekey";
1207
1208     my $aptsuites = $isuite;
1209     cfg_apply_map(\$aptsuites, 'suite map',
1210                   access_cfg('aptget-suite-map', 'RETURN-UNDEF'));
1211
1212     open SRCS, ">", "$aptget_base/$sourceslist" or die $!;
1213     printf SRCS "deb-src %s %s %s\n",
1214         access_cfg('mirror'),
1215         $aptsuites,
1216         access_cfg('aptget-components')
1217         or die $!;
1218
1219     ensuredir "$aptget_base/cache";
1220     ensuredir "$aptget_base/lists";
1221
1222     open CONF, ">", $aptget_configpath or die $!;
1223     print CONF <<END;
1224 Debug::NoLocking "true";
1225 APT::Get::List-Cleanup "false";
1226 #clear APT::Update::Post-Invoke-Success;
1227 Dir::Etc::SourceList "$quoted_base/$sourceslist";
1228 Dir::State::Lists "$quoted_base/lists";
1229 Dir::Etc::preferences "$quoted_base/preferences";
1230 Dir::Cache::srcpkgcache "$quoted_base/cache/srcs#$cachekey";
1231 Dir::Cache::pkgcache "$quoted_base/cache/pkgs#$cachekey";
1232 END
1233
1234     foreach my $key (qw(
1235                         Dir::Cache
1236                         Dir::State
1237                         Dir::Cache::Archives
1238                         Dir::Etc::SourceParts
1239                         Dir::Etc::preferencesparts
1240                       )) {
1241         ensuredir "$aptget_base/$key";
1242         print CONF "$key \"$quoted_base/$key\";\n" or die $!;
1243     };
1244
1245     my $oldatime = (time // die $!) - 1;
1246     foreach my $oldlist (<$aptget_base/lists/*Release>) {
1247         next unless stat_exists $oldlist;
1248         my ($mtime) = (stat _)[9];
1249         utime $oldatime, $mtime, $oldlist or die "$oldlist $!";
1250     }
1251
1252     runcmd_ordryrun_local aptget_aptget(), qw(update);
1253
1254     my @releasefiles;
1255     foreach my $oldlist (<$aptget_base/lists/*Release>) {
1256         next unless stat_exists $oldlist;
1257         my ($atime) = (stat _)[8];
1258         next if $atime == $oldatime;
1259         push @releasefiles, $oldlist;
1260     }
1261     my @inreleasefiles = grep { m#/InRelease$# } @releasefiles;
1262     @releasefiles = @inreleasefiles if @inreleasefiles;
1263     die "apt updated wrong number of Release files (@releasefiles), erk"
1264         unless @releasefiles == 1;
1265
1266     ($aptget_releasefile) = @releasefiles;
1267 }
1268
1269 sub canonicalise_suite_aptget {
1270     my ($proto,$data) = @_;
1271     aptget_prep($data);
1272
1273     my $release = parsecontrol $aptget_releasefile, "Release file", 1;
1274
1275     foreach my $name (qw(Codename Suite)) {
1276         my $val = $release->{$name};
1277         if (defined $val) {
1278             printdebug "release file $name: $val\n";
1279             $val =~ m/^$suite_re$/o or fail
1280  "Release file ($aptget_releasefile) specifies intolerable $name";
1281             cfg_apply_map(\$val, 'suite rmap',
1282                           access_cfg('aptget-suite-rmap', 'RETURN-UNDEF'));
1283             return $val
1284         }
1285     }
1286     return $isuite;
1287 }
1288
1289 sub archive_query_aptget {
1290     my ($proto,$data) = @_;
1291     aptget_prep($data);
1292
1293     ensuredir "$aptget_base/source";
1294     foreach my $old (<$aptget_base/source/*.dsc>) {
1295         unlink $old or die "$old: $!";
1296     }
1297
1298     my $showsrc = cmdoutput aptget_aptcache(), qw(showsrc), $package;
1299     return () unless $showsrc =~ m/^package:\s*\Q$package\E\s*$/mi;
1300     # avoids apt-get source failing with ambiguous error code
1301
1302     runcmd_ordryrun_local
1303         shell_cmd 'cd "$1"/source; shift', $aptget_base,
1304         aptget_aptget(), qw(--download-only --only-source source), $package;
1305
1306     my @dscs = <$aptget_base/source/*.dsc>;
1307     fail "apt-get source did not produce a .dsc" unless @dscs;
1308     fail "apt-get source produced several .dscs (@dscs)" unless @dscs==1;
1309
1310     my $pre_dsc = parsecontrol $dscs[0], $dscs[0], 1;
1311
1312     use URI::Escape;
1313     my $uri = "file://". uri_escape $dscs[0];
1314     $uri =~ s{\%2f}{/}gi;
1315     return [ (getfield $pre_dsc, 'Version'), $uri ];
1316 }
1317
1318 #---------- `dummyapicat' archive query method ----------
1319
1320 sub archive_query_dummycatapi { archive_query_ftpmasterapi @_; }
1321 sub canonicalise_suite_dummycatapi { canonicalise_suite_ftpmasterapi @_; }
1322
1323 sub file_in_archive_dummycatapi ($$$) {
1324     my ($proto,$data,$filename) = @_;
1325     my $mirror = access_cfg('mirror');
1326     $mirror =~ s#^file://#/# or die "$mirror ?";
1327     my @out;
1328     my @cmd = (qw(sh -ec), '
1329             cd "$1"
1330             find -name "$2" -print0 |
1331             xargs -0r sha256sum
1332         ', qw(x), $mirror, $filename);
1333     debugcmd "-|", @cmd;
1334     open FIA, "-|", @cmd or die $!;
1335     while (<FIA>) {
1336         chomp or die;
1337         printdebug "| $_\n";
1338         m/^(\w+)  (\S+)$/ or die "$_ ?";
1339         push @out, { sha256sum => $1, filename => $2 };
1340     }
1341     close FIA or die failedcmd @cmd;
1342     return \@out;
1343 }
1344
1345 #---------- `madison' archive query method ----------
1346
1347 sub archive_query_madison {
1348     return archive_query_prepend_mirror
1349         map { [ @$_[0..1] ] } madison_get_parse(@_);
1350 }
1351
1352 sub madison_get_parse {
1353     my ($proto,$data) = @_;
1354     die unless $proto eq 'madison';
1355     if (!length $data) {
1356         $data= access_cfg('madison-distro','RETURN-UNDEF');
1357         $data //= access_basedistro();
1358     }
1359     $rmad{$proto,$data,$package} ||= cmdoutput
1360         qw(rmadison -asource),"-s$isuite","-u$data",$package;
1361     my $rmad = $rmad{$proto,$data,$package};
1362
1363     my @out;
1364     foreach my $l (split /\n/, $rmad) {
1365         $l =~ m{^ \s*( [^ \t|]+ )\s* \|
1366                   \s*( [^ \t|]+ )\s* \|
1367                   \s*( [^ \t|/]+ )(?:/([^ \t|/]+))? \s* \|
1368                   \s*( [^ \t|]+ )\s* }x or die "$rmad ?";
1369         $1 eq $package or die "$rmad $package ?";
1370         my $vsn = $2;
1371         my $newsuite = $3;
1372         my $component;
1373         if (defined $4) {
1374             $component = $4;
1375         } else {
1376             $component = access_cfg('archive-query-default-component');
1377         }
1378         $5 eq 'source' or die "$rmad ?";
1379         push @out, [$vsn,pool_dsc_subpath($vsn,$component),$newsuite];
1380     }
1381     return sort { -version_compare($a->[0],$b->[0]); } @out;
1382 }
1383
1384 sub canonicalise_suite_madison {
1385     # madison canonicalises for us
1386     my @r = madison_get_parse(@_);
1387     @r or fail
1388         "unable to canonicalise suite using package $package".
1389         " which does not appear to exist in suite $isuite;".
1390         " --existing-package may help";
1391     return $r[0][2];
1392 }
1393
1394 sub file_in_archive_madison { return undef; }
1395
1396 #---------- `sshpsql' archive query method ----------
1397
1398 sub sshpsql ($$$) {
1399     my ($data,$runeinfo,$sql) = @_;
1400     if (!length $data) {
1401         $data= access_someuserhost('sshpsql').':'.
1402             access_cfg('sshpsql-dbname');
1403     }
1404     $data =~ m/:/ or badcfg "invalid sshpsql method string \`$data'";
1405     my ($userhost,$dbname) = ($`,$'); #';
1406     my @rows;
1407     my @cmd = (access_cfg_ssh, $userhost,
1408                access_runeinfo("ssh-psql $runeinfo").
1409                " export LC_MESSAGES=C; export LC_CTYPE=C;".
1410                " ".shellquote qw(psql -A), $dbname, qw(-c), $sql);
1411     debugcmd "|",@cmd;
1412     open P, "-|", @cmd or die $!;
1413     while (<P>) {
1414         chomp or die;
1415         printdebug(">|$_|\n");
1416         push @rows, $_;
1417     }
1418     $!=0; $?=0; close P or failedcmd @cmd;
1419     @rows or die;
1420     my $nrows = pop @rows;
1421     $nrows =~ s/^\((\d+) rows?\)$/$1/ or die "$nrows ?";
1422     @rows == $nrows+1 or die "$nrows ".(scalar @rows)." ?";
1423     @rows = map { [ split /\|/, $_ ] } @rows;
1424     my $ncols = scalar @{ shift @rows };
1425     die if grep { scalar @$_ != $ncols } @rows;
1426     return @rows;
1427 }
1428
1429 sub sql_injection_check {
1430     foreach (@_) { die "$_ $& ?" if m{[^-+=:_.,/0-9a-zA-Z]}; }
1431 }
1432
1433 sub archive_query_sshpsql ($$) {
1434     my ($proto,$data) = @_;
1435     sql_injection_check $isuite, $package;
1436     my @rows = sshpsql($data, "archive-query $isuite $package", <<END);
1437         SELECT source.version, component.name, files.filename, files.sha256sum
1438           FROM source
1439           JOIN src_associations ON source.id = src_associations.source
1440           JOIN suite ON suite.id = src_associations.suite
1441           JOIN dsc_files ON dsc_files.source = source.id
1442           JOIN files_archive_map ON files_archive_map.file_id = dsc_files.file
1443           JOIN component ON component.id = files_archive_map.component_id
1444           JOIN files ON files.id = dsc_files.file
1445          WHERE ( suite.suite_name='$isuite' OR suite.codename='$isuite' )
1446            AND source.source='$package'
1447            AND files.filename LIKE '%.dsc';
1448 END
1449     @rows = sort { -version_compare($a->[0],$b->[0]) } @rows;
1450     my $digester = Digest::SHA->new(256);
1451     @rows = map {
1452         my ($vsn,$component,$filename,$sha256sum) = @$_;
1453         [ $vsn, "/pool/$component/$filename",$digester,$sha256sum ];
1454     } @rows;
1455     return archive_query_prepend_mirror @rows;
1456 }
1457
1458 sub canonicalise_suite_sshpsql ($$) {
1459     my ($proto,$data) = @_;
1460     sql_injection_check $isuite;
1461     my @rows = sshpsql($data, "canonicalise-suite $isuite", <<END);
1462         SELECT suite.codename
1463           FROM suite where suite_name='$isuite' or codename='$isuite';
1464 END
1465     @rows = map { $_->[0] } @rows;
1466     fail "unknown suite $isuite" unless @rows;
1467     die "ambiguous $isuite: @rows ?" if @rows>1;
1468     return $rows[0];
1469 }
1470
1471 sub file_in_archive_sshpsql ($$$) { return undef; }
1472
1473 #---------- `dummycat' archive query method ----------
1474
1475 sub canonicalise_suite_dummycat ($$) {
1476     my ($proto,$data) = @_;
1477     my $dpath = "$data/suite.$isuite";
1478     if (!open C, "<", $dpath) {
1479         $!==ENOENT or die "$dpath: $!";
1480         printdebug "dummycat canonicalise_suite $isuite $dpath ENOENT\n";
1481         return $isuite;
1482     }
1483     $!=0; $_ = <C>;
1484     chomp or die "$dpath: $!";
1485     close C;
1486     printdebug "dummycat canonicalise_suite $isuite $dpath = $_\n";
1487     return $_;
1488 }
1489
1490 sub archive_query_dummycat ($$) {
1491     my ($proto,$data) = @_;
1492     canonicalise_suite();
1493     my $dpath = "$data/package.$csuite.$package";
1494     if (!open C, "<", $dpath) {
1495         $!==ENOENT or die "$dpath: $!";
1496         printdebug "dummycat query $csuite $package $dpath ENOENT\n";
1497         return ();
1498     }
1499     my @rows;
1500     while (<C>) {
1501         next if m/^\#/;
1502         next unless m/\S/;
1503         die unless chomp;
1504         printdebug "dummycat query $csuite $package $dpath | $_\n";
1505         my @row = split /\s+/, $_;
1506         @row==2 or die "$dpath: $_ ?";
1507         push @rows, \@row;
1508     }
1509     C->error and die "$dpath: $!";
1510     close C;
1511     return archive_query_prepend_mirror
1512         sort { -version_compare($a->[0],$b->[0]); } @rows;
1513 }
1514
1515 sub file_in_archive_dummycat () { return undef; }
1516
1517 #---------- tag format handling ----------
1518
1519 sub access_cfg_tagformats () {
1520     split /\,/, access_cfg('dgit-tag-format');
1521 }
1522
1523 sub access_cfg_tagformats_can_splitbrain () {
1524     my %y = map { $_ => 1 } access_cfg_tagformats;
1525     foreach my $needtf (qw(new maint)) {
1526         next if $y{$needtf};
1527         return 0;
1528     }
1529     return 1;
1530 }
1531
1532 sub need_tagformat ($$) {
1533     my ($fmt, $why) = @_;
1534     fail "need to use tag format $fmt ($why) but also need".
1535         " to use tag format $tagformat_want->[0] ($tagformat_want->[1])".
1536         " - no way to proceed"
1537         if $tagformat_want && $tagformat_want->[0] ne $fmt;
1538     $tagformat_want = [$fmt, $why, $tagformat_want->[2] // 0];
1539 }
1540
1541 sub select_tagformat () {
1542     # sets $tagformatfn
1543     return if $tagformatfn && !$tagformat_want;
1544     die 'bug' if $tagformatfn && $tagformat_want;
1545     # ... $tagformat_want assigned after previous select_tagformat
1546
1547     my (@supported) = grep { $_ =~ m/^(?:old|new)$/ } access_cfg_tagformats();
1548     printdebug "select_tagformat supported @supported\n";
1549
1550     $tagformat_want //= [ $supported[0], "distro access configuration", 0 ];
1551     printdebug "select_tagformat specified @$tagformat_want\n";
1552
1553     my ($fmt,$why,$override) = @$tagformat_want;
1554
1555     fail "target distro supports tag formats @supported".
1556         " but have to use $fmt ($why)"
1557         unless $override
1558             or grep { $_ eq $fmt } @supported;
1559
1560     $tagformat_want = undef;
1561     $tagformat = $fmt;
1562     $tagformatfn = ${*::}{"debiantag_$fmt"};
1563
1564     fail "trying to use unknown tag format \`$fmt' ($why) !"
1565         unless $tagformatfn;
1566 }
1567
1568 #---------- archive query entrypoints and rest of program ----------
1569
1570 sub canonicalise_suite () {
1571     return if defined $csuite;
1572     fail "cannot operate on $isuite suite" if $isuite eq 'UNRELEASED';
1573     $csuite = archive_query('canonicalise_suite');
1574     if ($isuite ne $csuite) {
1575         progress "canonical suite name for $isuite is $csuite";
1576     } else {
1577         progress "canonical suite name is $csuite";
1578     }
1579 }
1580
1581 sub get_archive_dsc () {
1582     canonicalise_suite();
1583     my @vsns = archive_query('archive_query');
1584     foreach my $vinfo (@vsns) {
1585         my ($vsn,$vsn_dscurl,$digester,$digest) = @$vinfo;
1586         $dscurl = $vsn_dscurl;
1587         $dscdata = url_get($dscurl);
1588         if (!$dscdata) {
1589             $skew_warning_vsn = $vsn if !defined $skew_warning_vsn;
1590             next;
1591         }
1592         if ($digester) {
1593             $digester->reset();
1594             $digester->add($dscdata);
1595             my $got = $digester->hexdigest();
1596             $got eq $digest or
1597                 fail "$dscurl has hash $got but".
1598                     " archive told us to expect $digest";
1599         }
1600         parse_dscdata();
1601         my $fmt = getfield $dsc, 'Format';
1602         $format_ok{$fmt} or forceable_fail [qw(unsupported-source-format)],
1603             "unsupported source format $fmt, sorry";
1604
1605         $dsc_checked = !!$digester;
1606         printdebug "get_archive_dsc: Version ".(getfield $dsc, 'Version')."\n";
1607         return;
1608     }
1609     $dsc = undef;
1610     printdebug "get_archive_dsc: nothing in archive, returning undef\n";
1611 }
1612
1613 sub check_for_git ();
1614 sub check_for_git () {
1615     # returns 0 or 1
1616     my $how = access_cfg('git-check');
1617     if ($how eq 'ssh-cmd') {
1618         my @cmd =
1619             (access_cfg_ssh, access_gituserhost(),
1620              access_runeinfo("git-check $package").
1621              " set -e; cd ".access_cfg('git-path').";".
1622              " if test -d $package.git; then echo 1; else echo 0; fi");
1623         my $r= cmdoutput @cmd;
1624         if (defined $r and $r =~ m/^divert (\w+)$/) {
1625             my $divert=$1;
1626             my ($usedistro,) = access_distros();
1627             # NB that if we are pushing, $usedistro will be $distro/push
1628             $instead_distro= cfg("dgit-distro.$usedistro.diverts.$divert");
1629             $instead_distro =~ s{^/}{ access_basedistro()."/" }e;
1630             progress "diverting to $divert (using config for $instead_distro)";
1631             return check_for_git();
1632         }
1633         failedcmd @cmd unless defined $r and $r =~ m/^[01]$/;
1634         return $r+0;
1635     } elsif ($how eq 'url') {
1636         my $prefix = access_cfg('git-check-url','git-url');
1637         my $suffix = access_cfg('git-check-suffix','git-suffix',
1638                                 'RETURN-UNDEF') // '.git';
1639         my $url = "$prefix/$package$suffix";
1640         my @cmd = (@curl, qw(-sS -I), $url);
1641         my $result = cmdoutput @cmd;
1642         $result =~ s/^\S+ 200 .*\n\r?\n//;
1643         # curl -sS -I with https_proxy prints
1644         # HTTP/1.0 200 Connection established
1645         $result =~ m/^\S+ (404|200) /s or
1646             fail "unexpected results from git check query - ".
1647                 Dumper($prefix, $result);
1648         my $code = $1;
1649         if ($code eq '404') {
1650             return 0;
1651         } elsif ($code eq '200') {
1652             return 1;
1653         } else {
1654             die;
1655         }
1656     } elsif ($how eq 'true') {
1657         return 1;
1658     } elsif ($how eq 'false') {
1659         return 0;
1660     } else {
1661         badcfg "unknown git-check \`$how'";
1662     }
1663 }
1664
1665 sub create_remote_git_repo () {
1666     my $how = access_cfg('git-create');
1667     if ($how eq 'ssh-cmd') {
1668         runcmd_ordryrun
1669             (access_cfg_ssh, access_gituserhost(),
1670              access_runeinfo("git-create $package").
1671              "set -e; cd ".access_cfg('git-path').";".
1672              " cp -a _template $package.git");
1673     } elsif ($how eq 'true') {
1674         # nothing to do
1675     } else {
1676         badcfg "unknown git-create \`$how'";
1677     }
1678 }
1679
1680 our ($dsc_hash,$lastpush_mergeinput);
1681 our ($dsc_distro, $dsc_hint_tag, $dsc_hint_url);
1682
1683 our $ud = '.git/dgit/unpack';
1684
1685 sub prep_ud (;$) {
1686     my ($d) = @_;
1687     $d //= $ud;
1688     rmtree($d);
1689     mkpath '.git/dgit';
1690     mkdir $d or die $!;
1691 }
1692
1693 sub mktree_in_ud_here () {
1694     runcmd qw(git init -q);
1695     runcmd qw(git config gc.auto 0);
1696     rmtree('.git/objects');
1697     symlink '../../../../objects','.git/objects' or die $!;
1698 }
1699
1700 sub git_write_tree () {
1701     my $tree = cmdoutput @git, qw(write-tree);
1702     $tree =~ m/^\w+$/ or die "$tree ?";
1703     return $tree;
1704 }
1705
1706 sub git_add_write_tree () {
1707     runcmd @git, qw(add -Af .);
1708     return git_write_tree();
1709 }
1710
1711 sub remove_stray_gits ($) {
1712     my ($what) = @_;
1713     my @gitscmd = qw(find -name .git -prune -print0);
1714     debugcmd "|",@gitscmd;
1715     open GITS, "-|", @gitscmd or die $!;
1716     {
1717         local $/="\0";
1718         while (<GITS>) {
1719             chomp or die;
1720             print STDERR "$us: warning: removing from $what: ",
1721                 (messagequote $_), "\n";
1722             rmtree $_;
1723         }
1724     }
1725     $!=0; $?=0; close GITS or failedcmd @gitscmd;
1726 }
1727
1728 sub mktree_in_ud_from_only_subdir ($;$) {
1729     my ($what,$raw) = @_;
1730
1731     # changes into the subdir
1732     my (@dirs) = <*/.>;
1733     die "expected one subdir but found @dirs ?" unless @dirs==1;
1734     $dirs[0] =~ m#^([^/]+)/\.$# or die;
1735     my $dir = $1;
1736     changedir $dir;
1737
1738     remove_stray_gits($what);
1739     mktree_in_ud_here();
1740     if (!$raw) {
1741         my ($format, $fopts) = get_source_format();
1742         if (madformat($format)) {
1743             rmtree '.pc';
1744         }
1745     }
1746
1747     my $tree=git_add_write_tree();
1748     return ($tree,$dir);
1749 }
1750
1751 our @files_csum_info_fields =
1752     (['Checksums-Sha256','Digest::SHA', 'new(256)', 'sha256sum'],
1753      ['Checksums-Sha1',  'Digest::SHA', 'new(1)',   'sha1sum'],
1754      ['Files',           'Digest::MD5', 'new()',    'md5sum']);
1755
1756 sub dsc_files_info () {
1757     foreach my $csumi (@files_csum_info_fields) {
1758         my ($fname, $module, $method) = @$csumi;
1759         my $field = $dsc->{$fname};
1760         next unless defined $field;
1761         eval "use $module; 1;" or die $@;
1762         my @out;
1763         foreach (split /\n/, $field) {
1764             next unless m/\S/;
1765             m/^(\w+) (\d+) (\S+)$/ or
1766                 fail "could not parse .dsc $fname line \`$_'";
1767             my $digester = eval "$module"."->$method;" or die $@;
1768             push @out, {
1769                 Hash => $1,
1770                 Bytes => $2,
1771                 Filename => $3,
1772                 Digester => $digester,
1773             };
1774         }
1775         return @out;
1776     }
1777     fail "missing any supported Checksums-* or Files field in ".
1778         $dsc->get_option('name');
1779 }
1780
1781 sub dsc_files () {
1782     map { $_->{Filename} } dsc_files_info();
1783 }
1784
1785 sub files_compare_inputs (@) {
1786     my $inputs = \@_;
1787     my %record;
1788     my %fchecked;
1789
1790     my $showinputs = sub {
1791         return join "; ", map { $_->get_option('name') } @$inputs;
1792     };
1793
1794     foreach my $in (@$inputs) {
1795         my $expected_files;
1796         my $in_name = $in->get_option('name');
1797
1798         printdebug "files_compare_inputs $in_name\n";
1799
1800         foreach my $csumi (@files_csum_info_fields) {
1801             my ($fname) = @$csumi;
1802             printdebug "files_compare_inputs $in_name $fname\n";
1803
1804             my $field = $in->{$fname};
1805             next unless defined $field;
1806
1807             my @files;
1808             foreach (split /\n/, $field) {
1809                 next unless m/\S/;
1810
1811                 my ($info, $f) = m/^(\w+ \d+) (?:\S+ \S+ )?(\S+)$/ or
1812                     fail "could not parse $in_name $fname line \`$_'";
1813
1814                 printdebug "files_compare_inputs $in_name $fname $f\n";
1815
1816                 push @files, $f;
1817
1818                 my $re = \ $record{$f}{$fname};
1819                 if (defined $$re) {
1820                     $fchecked{$f}{$in_name} = 1;
1821                     $$re eq $info or
1822                         fail "hash or size of $f varies in $fname fields".
1823                         " (between: ".$showinputs->().")";
1824                 } else {
1825                     $$re = $info;
1826                 }
1827             }
1828             @files = sort @files;
1829             $expected_files //= \@files;
1830             "@$expected_files" eq "@files" or
1831                 fail "file list in $in_name varies between hash fields!";
1832         }
1833         $expected_files or
1834             fail "$in_name has no files list field(s)";
1835     }
1836     printdebug "files_compare_inputs ".Dumper(\%fchecked, \%record)
1837         if $debuglevel>=2;
1838
1839     grep { keys %$_ == @$inputs-1 } values %fchecked
1840         or fail "no file appears in all file lists".
1841         " (looked in: ".$showinputs->().")";
1842 }
1843
1844 sub is_orig_file_in_dsc ($$) {
1845     my ($f, $dsc_files_info) = @_;
1846     return 0 if @$dsc_files_info <= 1;
1847     # One file means no origs, and the filename doesn't have a "what
1848     # part of dsc" component.  (Consider versions ending `.orig'.)
1849     return 0 unless $f =~ m/\.$orig_f_tail_re$/o;
1850     return 1;
1851 }
1852
1853 sub is_orig_file_of_vsn ($$) {
1854     my ($f, $upstreamvsn) = @_;
1855     my $base = srcfn $upstreamvsn, '';
1856     return 0 unless $f =~ m/^\Q$base\E\.$orig_f_tail_re$/;
1857     return 1;
1858 }
1859
1860 sub changes_update_origs_from_dsc ($$$$) {
1861     my ($dsc, $changes, $upstreamvsn, $changesfile) = @_;
1862     my %changes_f;
1863     printdebug "checking origs needed ($upstreamvsn)...\n";
1864     $_ = getfield $changes, 'Files';
1865     m/^\w+ \d+ (\S+ \S+) \S+$/m or
1866         fail "cannot find section/priority from .changes Files field";
1867     my $placementinfo = $1;
1868     my %changed;
1869     printdebug "checking origs needed placement '$placementinfo'...\n";
1870     foreach my $l (split /\n/, getfield $dsc, 'Files') {
1871         $l =~ m/\S+$/ or next;
1872         my $file = $&;
1873         printdebug "origs $file | $l\n";
1874         next unless is_orig_file_of_vsn $file, $upstreamvsn;
1875         printdebug "origs $file is_orig\n";
1876         my $have = archive_query('file_in_archive', $file);
1877         if (!defined $have) {
1878             print STDERR <<END;
1879 archive does not support .orig check; hope you used --ch:--sa/-sd if needed
1880 END
1881             return;
1882         }
1883         my $found_same = 0;
1884         my @found_differ;
1885         printdebug "origs $file \$#\$have=$#$have\n";
1886         foreach my $h (@$have) {
1887             my $same = 0;
1888             my @differ;
1889             foreach my $csumi (@files_csum_info_fields) {
1890                 my ($fname, $module, $method, $archivefield) = @$csumi;
1891                 next unless defined $h->{$archivefield};
1892                 $_ = $dsc->{$fname};
1893                 next unless defined;
1894                 m/^(\w+) .* \Q$file\E$/m or
1895                     fail ".dsc $fname missing entry for $file";
1896                 if ($h->{$archivefield} eq $1) {
1897                     $same++;
1898                 } else {
1899                     push @differ,
1900  "$archivefield: $h->{$archivefield} (archive) != $1 (local .dsc)";
1901                 }
1902             }
1903             die "$file ".Dumper($h)." ?!" if $same && @differ;
1904             $found_same++
1905                 if $same;
1906             push @found_differ, "archive $h->{filename}: ".join "; ", @differ
1907                 if @differ;
1908         }
1909         printdebug "origs $file f.same=$found_same".
1910             " #f._differ=$#found_differ\n";
1911         if (@found_differ && !$found_same) {
1912             fail join "\n",
1913                 "archive contains $file with different checksum",
1914                 @found_differ;
1915         }
1916         # Now we edit the changes file to add or remove it
1917         foreach my $csumi (@files_csum_info_fields) {
1918             my ($fname, $module, $method, $archivefield) = @$csumi;
1919             next unless defined $changes->{$fname};
1920             if ($found_same) {
1921                 # in archive, delete from .changes if it's there
1922                 $changed{$file} = "removed" if
1923                     $changes->{$fname} =~ s/^.* \Q$file\E$(?:)\n//m;
1924             } elsif ($changes->{$fname} =~ m/^.* \Q$file\E$(?:)\n/m) {
1925                 # not in archive, but it's here in the .changes
1926             } else {
1927                 my $dsc_data = getfield $dsc, $fname;
1928                 $dsc_data =~ m/^(.* \Q$file\E$)\n/m or die "$dsc_data $file ?";
1929                 my $extra = $1;
1930                 $extra =~ s/ \d+ /$&$placementinfo /
1931                     or die "$fname $extra >$dsc_data< ?"
1932                     if $fname eq 'Files';
1933                 $changes->{$fname} .= "\n". $extra;
1934                 $changed{$file} = "added";
1935             }
1936         }
1937     }
1938     if (%changed) {
1939         foreach my $file (keys %changed) {
1940             progress sprintf
1941                 "edited .changes for archive .orig contents: %s %s",
1942                 $changed{$file}, $file;
1943         }
1944         my $chtmp = "$changesfile.tmp";
1945         $changes->save($chtmp);
1946         if (act_local()) {
1947             rename $chtmp,$changesfile or die "$changesfile $!";
1948         } else {
1949             progress "[new .changes left in $changesfile]";
1950         }
1951     } else {
1952         progress "$changesfile already has appropriate .orig(s) (if any)";
1953     }
1954 }
1955
1956 sub make_commit ($) {
1957     my ($file) = @_;
1958     return cmdoutput @git, qw(hash-object -w -t commit), $file;
1959 }
1960
1961 sub make_commit_text ($) {
1962     my ($text) = @_;
1963     my ($out, $in);
1964     my @cmd = (@git, qw(hash-object -w -t commit --stdin));
1965     debugcmd "|",@cmd;
1966     print Dumper($text) if $debuglevel > 1;
1967     my $child = open2($out, $in, @cmd) or die $!;
1968     my $h;
1969     eval {
1970         print $in $text or die $!;
1971         close $in or die $!;
1972         $h = <$out>;
1973         $h =~ m/^\w+$/ or die;
1974         $h = $&;
1975         printdebug "=> $h\n";
1976     };
1977     close $out;
1978     waitpid $child, 0 == $child or die "$child $!";
1979     $? and failedcmd @cmd;
1980     return $h;
1981 }
1982
1983 sub clogp_authline ($) {
1984     my ($clogp) = @_;
1985     my $author = getfield $clogp, 'Maintainer';
1986     $author =~ s#,.*##ms;
1987     my $date = cmdoutput qw(date), '+%s %z', qw(-d), getfield($clogp,'Date');
1988     my $authline = "$author $date";
1989     $authline =~ m/$git_authline_re/o or
1990         fail "unexpected commit author line format \`$authline'".
1991         " (was generated from changelog Maintainer field)";
1992     return ($1,$2,$3) if wantarray;
1993     return $authline;
1994 }
1995
1996 sub vendor_patches_distro ($$) {
1997     my ($checkdistro, $what) = @_;
1998     return unless defined $checkdistro;
1999
2000     my $series = "debian/patches/\L$checkdistro\E.series";
2001     printdebug "checking for vendor-specific $series ($what)\n";
2002
2003     if (!open SERIES, "<", $series) {
2004         die "$series $!" unless $!==ENOENT;
2005         return;
2006     }
2007     while (<SERIES>) {
2008         next unless m/\S/;
2009         next if m/^\s+\#/;
2010
2011         print STDERR <<END;
2012
2013 Unfortunately, this source package uses a feature of dpkg-source where
2014 the same source package unpacks to different source code on different
2015 distros.  dgit cannot safely operate on such packages on affected
2016 distros, because the meaning of source packages is not stable.
2017
2018 Please ask the distro/maintainer to remove the distro-specific series
2019 files and use a different technique (if necessary, uploading actually
2020 different packages, if different distros are supposed to have
2021 different code).
2022
2023 END
2024         fail "Found active distro-specific series file for".
2025             " $checkdistro ($what): $series, cannot continue";
2026     }
2027     die "$series $!" if SERIES->error;
2028     close SERIES;
2029 }
2030
2031 sub check_for_vendor_patches () {
2032     # This dpkg-source feature doesn't seem to be documented anywhere!
2033     # But it can be found in the changelog (reformatted):
2034
2035     #   commit  4fa01b70df1dc4458daee306cfa1f987b69da58c
2036     #   Author: Raphael Hertzog <hertzog@debian.org>
2037     #   Date: Sun  Oct  3  09:36:48  2010 +0200
2038
2039     #   dpkg-source: correctly create .pc/.quilt_series with alternate
2040     #   series files
2041     #
2042     #   If you have debian/patches/ubuntu.series and you were
2043     #   unpacking the source package on ubuntu, quilt was still
2044     #   directed to debian/patches/series instead of
2045     #   debian/patches/ubuntu.series.
2046     #
2047     #   debian/changelog                        |    3 +++
2048     #   scripts/Dpkg/Source/Package/V3/quilt.pm |    4 +++-
2049     #   2 files changed, 6 insertions(+), 1 deletion(-)
2050
2051     use Dpkg::Vendor;
2052     vendor_patches_distro($ENV{DEB_VENDOR}, "DEB_VENDOR");
2053     vendor_patches_distro(Dpkg::Vendor::get_current_vendor(),
2054                          "Dpkg::Vendor \`current vendor'");
2055     vendor_patches_distro(access_basedistro(),
2056                           "(base) distro being accessed");
2057     vendor_patches_distro(access_nomdistro(),
2058                           "(nominal) distro being accessed");
2059 }
2060
2061 sub generate_commits_from_dsc () {
2062     # See big comment in fetch_from_archive, below.
2063     # See also README.dsc-import.
2064     prep_ud();
2065     changedir $ud;
2066
2067     my @dfi = dsc_files_info();
2068     foreach my $fi (@dfi) {
2069         my $f = $fi->{Filename};
2070         die "$f ?" if $f =~ m#/|^\.|\.dsc$|\.tmp$#;
2071
2072         printdebug "considering linking $f: ";
2073
2074         link_ltarget "../../../../$f", $f
2075             or ((printdebug "($!) "), 0)
2076             or $!==&ENOENT
2077             or die "$f $!";
2078
2079         printdebug "linked.\n";
2080
2081         complete_file_from_dsc('.', $fi)
2082             or next;
2083
2084         if (is_orig_file_in_dsc($f, \@dfi)) {
2085             link $f, "../../../../$f"
2086                 or $!==&EEXIST
2087                 or die "$f $!";
2088         }
2089     }
2090
2091     # We unpack and record the orig tarballs first, so that we only
2092     # need disk space for one private copy of the unpacked source.
2093     # But we can't make them into commits until we have the metadata
2094     # from the debian/changelog, so we record the tree objects now and
2095     # make them into commits later.
2096     my @tartrees;
2097     my $upstreamv = upstreamversion $dsc->{version};
2098     my $orig_f_base = srcfn $upstreamv, '';
2099
2100     foreach my $fi (@dfi) {
2101         # We actually import, and record as a commit, every tarball
2102         # (unless there is only one file, in which case there seems
2103         # little point.
2104
2105         my $f = $fi->{Filename};
2106         printdebug "import considering $f ";
2107         (printdebug "only one dfi\n"), next if @dfi == 1;
2108         (printdebug "not tar\n"), next unless $f =~ m/\.tar(\.\w+)?$/;
2109         (printdebug "signature\n"), next if $f =~ m/$orig_f_sig_re$/o;
2110         my $compr_ext = $1;
2111
2112         my ($orig_f_part) =
2113             $f =~ m/^\Q$orig_f_base\E\.([^._]+)?\.tar(?:\.\w+)?$/;
2114
2115         printdebug "Y ", (join ' ', map { $_//"(none)" }
2116                           $compr_ext, $orig_f_part
2117                          ), "\n";
2118
2119         my $input = new IO::File $f, '<' or die "$f $!";
2120         my $compr_pid;
2121         my @compr_cmd;
2122
2123         if (defined $compr_ext) {
2124             my $cname =
2125                 Dpkg::Compression::compression_guess_from_filename $f;
2126             fail "Dpkg::Compression cannot handle file $f in source package"
2127                 if defined $compr_ext && !defined $cname;
2128             my $compr_proc =
2129                 new Dpkg::Compression::Process compression => $cname;
2130             my @compr_cmd = $compr_proc->get_uncompress_cmdline();
2131             my $compr_fh = new IO::Handle;
2132             my $compr_pid = open $compr_fh, "-|" // die $!;
2133             if (!$compr_pid) {
2134                 open STDIN, "<&", $input or die $!;
2135                 exec @compr_cmd;
2136                 die "dgit (child): exec $compr_cmd[0]: $!\n";
2137             }
2138             $input = $compr_fh;
2139         }
2140
2141         rmtree "_unpack-tar";
2142         mkdir "_unpack-tar" or die $!;
2143         my @tarcmd = qw(tar -x -f -
2144                         --no-same-owner --no-same-permissions
2145                         --no-acls --no-xattrs --no-selinux);
2146         my $tar_pid = fork // die $!;
2147         if (!$tar_pid) {
2148             chdir "_unpack-tar" or die $!;
2149             open STDIN, "<&", $input or die $!;
2150             exec @tarcmd;
2151             die "dgit (child): exec $tarcmd[0]: $!";
2152         }
2153         $!=0; (waitpid $tar_pid, 0) == $tar_pid or die $!;
2154         !$? or failedcmd @tarcmd;
2155
2156         close $input or
2157             (@compr_cmd ? failedcmd @compr_cmd
2158              : die $!);
2159         # finally, we have the results in "tarball", but maybe
2160         # with the wrong permissions
2161
2162         runcmd qw(chmod -R +rwX _unpack-tar);
2163         changedir "_unpack-tar";
2164         remove_stray_gits($f);
2165         mktree_in_ud_here();
2166
2167         my ($tree) = git_add_write_tree();
2168         my $tentries = cmdoutput @git, qw(ls-tree -z), $tree;
2169         if ($tentries =~ m/^\d+ tree (\w+)\t[^\000]+\000$/s) {
2170             $tree = $1;
2171             printdebug "one subtree $1\n";
2172         } else {
2173             printdebug "multiple subtrees\n";
2174         }
2175         changedir "..";
2176         rmtree "_unpack-tar";
2177
2178         my $ent = [ $f, $tree ];
2179         push @tartrees, {
2180             Orig => !!$orig_f_part,
2181             Sort => (!$orig_f_part         ? 2 :
2182                      $orig_f_part =~ m/-/g ? 1 :
2183                                              0),
2184             F => $f,
2185             Tree => $tree,
2186         };
2187     }
2188
2189     @tartrees = sort {
2190         # put any without "_" first (spec is not clear whether files
2191         # are always in the usual order).  Tarballs without "_" are
2192         # the main orig or the debian tarball.
2193         $a->{Sort} <=> $b->{Sort} or
2194         $a->{F}    cmp $b->{F}
2195     } @tartrees;
2196
2197     my $any_orig = grep { $_->{Orig} } @tartrees;
2198
2199     my $dscfn = "$package.dsc";
2200
2201     my $treeimporthow = 'package';
2202
2203     open D, ">", $dscfn or die "$dscfn: $!";
2204     print D $dscdata or die "$dscfn: $!";
2205     close D or die "$dscfn: $!";
2206     my @cmd = qw(dpkg-source);
2207     push @cmd, '--no-check' if $dsc_checked;
2208     if (madformat $dsc->{format}) {
2209         push @cmd, '--skip-patches';
2210         $treeimporthow = 'unpatched';
2211     }
2212     push @cmd, qw(-x --), $dscfn;
2213     runcmd @cmd;
2214
2215     my ($tree,$dir) = mktree_in_ud_from_only_subdir("source package");
2216     if (madformat $dsc->{format}) {
2217         check_for_vendor_patches();
2218     }
2219
2220     my $dappliedtree;
2221     if (madformat $dsc->{format}) {
2222         my @pcmd = qw(dpkg-source --before-build .);
2223         runcmd shell_cmd 'exec >/dev/null', @pcmd;
2224         rmtree '.pc';
2225         $dappliedtree = git_add_write_tree();
2226     }
2227
2228     my @clogcmd = qw(dpkg-parsechangelog --format rfc822 --all);
2229     debugcmd "|",@clogcmd;
2230     open CLOGS, "-|", @clogcmd or die $!;
2231
2232     my $clogp;
2233     my $r1clogp;
2234
2235     printdebug "import clog search...\n";
2236
2237     for (;;) {
2238         my $stanzatext = do { local $/=""; <CLOGS>; };
2239         printdebug "import clogp ".Dumper($stanzatext) if $debuglevel>1;
2240         last if !defined $stanzatext;
2241
2242         my $desc = "package changelog, entry no.$.";
2243         open my $stanzafh, "<", \$stanzatext or die;
2244         my $thisstanza = parsecontrolfh $stanzafh, $desc, 1;
2245         $clogp //= $thisstanza;
2246
2247         printdebug "import clog $thisstanza->{version} $desc...\n";
2248
2249         last if !$any_orig; # we don't need $r1clogp
2250
2251         # We look for the first (most recent) changelog entry whose
2252         # version number is lower than the upstream version of this
2253         # package.  Then the last (least recent) previous changelog
2254         # entry is treated as the one which introduced this upstream
2255         # version and used for the synthetic commits for the upstream
2256         # tarballs.
2257
2258         # One might think that a more sophisticated algorithm would be
2259         # necessary.  But: we do not want to scan the whole changelog
2260         # file.  Stopping when we see an earlier version, which
2261         # necessarily then is an earlier upstream version, is the only
2262         # realistic way to do that.  Then, either the earliest
2263         # changelog entry we have seen so far is indeed the earliest
2264         # upload of this upstream version; or there are only changelog
2265         # entries relating to later upstream versions (which is not
2266         # possible unless the changelog and .dsc disagree about the
2267         # version).  Then it remains to choose between the physically
2268         # last entry in the file, and the one with the lowest version
2269         # number.  If these are not the same, we guess that the
2270         # versions were created in a non-monotic order rather than
2271         # that the changelog entries have been misordered.
2272
2273         printdebug "import clog $thisstanza->{version} vs $upstreamv...\n";
2274
2275         last if version_compare($thisstanza->{version}, $upstreamv) < 0;
2276         $r1clogp = $thisstanza;
2277
2278         printdebug "import clog $r1clogp->{version} becomes r1\n";
2279     }
2280     die $! if CLOGS->error;
2281     close CLOGS or $?==SIGPIPE or failedcmd @clogcmd;
2282
2283     $clogp or fail "package changelog has no entries!";
2284
2285     my $authline = clogp_authline $clogp;
2286     my $changes = getfield $clogp, 'Changes';
2287     my $cversion = getfield $clogp, 'Version';
2288
2289     if (@tartrees) {
2290         $r1clogp //= $clogp; # maybe there's only one entry;
2291         my $r1authline = clogp_authline $r1clogp;
2292         # Strictly, r1authline might now be wrong if it's going to be
2293         # unused because !$any_orig.  Whatever.
2294
2295         printdebug "import tartrees authline   $authline\n";
2296         printdebug "import tartrees r1authline $r1authline\n";
2297
2298         foreach my $tt (@tartrees) {
2299             printdebug "import tartree $tt->{F} $tt->{Tree}\n";
2300
2301             $tt->{Commit} = make_commit_text($tt->{Orig} ? <<END_O : <<END_T);
2302 tree $tt->{Tree}
2303 author $r1authline
2304 committer $r1authline
2305
2306 Import $tt->{F}
2307
2308 [dgit import orig $tt->{F}]
2309 END_O
2310 tree $tt->{Tree}
2311 author $authline
2312 committer $authline
2313
2314 Import $tt->{F}
2315
2316 [dgit import tarball $package $cversion $tt->{F}]
2317 END_T
2318         }
2319     }
2320
2321     printdebug "import main commit\n";
2322
2323     open C, ">../commit.tmp" or die $!;
2324     print C <<END or die $!;
2325 tree $tree
2326 END
2327     print C <<END or die $! foreach @tartrees;
2328 parent $_->{Commit}
2329 END
2330     print C <<END or die $!;
2331 author $authline
2332 committer $authline
2333
2334 $changes
2335
2336 [dgit import $treeimporthow $package $cversion]
2337 END
2338
2339     close C or die $!;
2340     my $rawimport_hash = make_commit qw(../commit.tmp);
2341
2342     if (madformat $dsc->{format}) {
2343         printdebug "import apply patches...\n";
2344
2345         # regularise the state of the working tree so that
2346         # the checkout of $rawimport_hash works nicely.
2347         my $dappliedcommit = make_commit_text(<<END);
2348 tree $dappliedtree
2349 author $authline
2350 committer $authline
2351
2352 [dgit dummy commit]
2353 END
2354         runcmd @git, qw(checkout -q -b dapplied), $dappliedcommit;
2355
2356         runcmd @git, qw(checkout -q -b unpa), $rawimport_hash;
2357
2358         # We need the answers to be reproducible
2359         my @authline = clogp_authline($clogp);
2360         local $ENV{GIT_COMMITTER_NAME} =  $authline[0];
2361         local $ENV{GIT_COMMITTER_EMAIL} = $authline[1];
2362         local $ENV{GIT_COMMITTER_DATE} =  $authline[2];
2363         local $ENV{GIT_AUTHOR_NAME} =  $authline[0];
2364         local $ENV{GIT_AUTHOR_EMAIL} = $authline[1];
2365         local $ENV{GIT_AUTHOR_DATE} =  $authline[2];
2366
2367         my $path = $ENV{PATH} or die;
2368
2369         foreach my $use_absurd (qw(0 1)) {
2370             runcmd @git, qw(checkout -q unpa);
2371             runcmd @git, qw(update-ref -d refs/heads/patch-queue/unpa);
2372             local $ENV{PATH} = $path;
2373             if ($use_absurd) {
2374                 chomp $@;
2375                 progress "warning: $@";
2376                 $path = "$absurdity:$path";
2377                 progress "$us: trying slow absurd-git-apply...";
2378                 rename "../../gbp-pq-output","../../gbp-pq-output.0"
2379                     or $!==ENOENT
2380                     or die $!;
2381             }
2382             eval {
2383                 die "forbid absurd git-apply\n" if $use_absurd
2384                     && forceing [qw(import-gitapply-no-absurd)];
2385                 die "only absurd git-apply!\n" if !$use_absurd
2386                     && forceing [qw(import-gitapply-absurd)];
2387
2388                 local $ENV{DGIT_ABSURD_DEBUG} = $debuglevel if $use_absurd;
2389                 local $ENV{PATH} = $path                    if $use_absurd;
2390
2391                 my @showcmd = (gbp_pq, qw(import));
2392                 my @realcmd = shell_cmd
2393                     'exec >/dev/null 2>>../../gbp-pq-output', @showcmd;
2394                 debugcmd "+",@realcmd;
2395                 if (system @realcmd) {
2396                     die +(shellquote @showcmd).
2397                         " failed: ".
2398                         failedcmd_waitstatus()."\n";
2399                 }
2400
2401                 my $gapplied = git_rev_parse('HEAD');
2402                 my $gappliedtree = cmdoutput @git, qw(rev-parse HEAD:);
2403                 $gappliedtree eq $dappliedtree or
2404                     fail <<END;
2405 gbp-pq import and dpkg-source disagree!
2406  gbp-pq import gave commit $gapplied
2407  gbp-pq import gave tree $gappliedtree
2408  dpkg-source --before-build gave tree $dappliedtree
2409 END
2410                 $rawimport_hash = $gapplied;
2411             };
2412             last unless $@;
2413         }
2414         if ($@) {
2415             { local $@; eval { runcmd qw(cat ../../gbp-pq-output); }; }
2416             die $@;
2417         }
2418     }
2419
2420     progress "synthesised git commit from .dsc $cversion";
2421
2422     my $rawimport_mergeinput = {
2423         Commit => $rawimport_hash,
2424         Info => "Import of source package",
2425     };
2426     my @output = ($rawimport_mergeinput);
2427
2428     if ($lastpush_mergeinput) {
2429         my $oldclogp = mergeinfo_getclogp($lastpush_mergeinput);
2430         my $oversion = getfield $oldclogp, 'Version';
2431         my $vcmp =
2432             version_compare($oversion, $cversion);
2433         if ($vcmp < 0) {
2434             @output = ($rawimport_mergeinput, $lastpush_mergeinput,
2435                 { Message => <<END, ReverseParents => 1 });
2436 Record $package ($cversion) in archive suite $csuite
2437 END
2438         } elsif ($vcmp > 0) {
2439             print STDERR <<END or die $!;
2440
2441 Version actually in archive:   $cversion (older)
2442 Last version pushed with dgit: $oversion (newer or same)
2443 $later_warning_msg
2444 END
2445             @output = $lastpush_mergeinput;
2446         } else {
2447             # Same version.  Use what's in the server git branch,
2448             # discarding our own import.  (This could happen if the
2449             # server automatically imports all packages into git.)
2450             @output = $lastpush_mergeinput;
2451         }
2452     }
2453     changedir '../../../..';
2454     rmtree($ud);
2455     return @output;
2456 }
2457
2458 sub complete_file_from_dsc ($$) {
2459     our ($dstdir, $fi) = @_;
2460     # Ensures that we have, in $dir, the file $fi, with the correct
2461     # contents.  (Downloading it from alongside $dscurl if necessary.)
2462
2463     my $f = $fi->{Filename};
2464     my $tf = "$dstdir/$f";
2465     my $downloaded = 0;
2466
2467     if (stat_exists $tf) {
2468         progress "using existing $f";
2469     } else {
2470         printdebug "$tf does not exist, need to fetch\n";
2471         my $furl = $dscurl;
2472         $furl =~ s{/[^/]+$}{};
2473         $furl .= "/$f";
2474         die "$f ?" unless $f =~ m/^\Q${package}\E_/;
2475         die "$f ?" if $f =~ m#/#;
2476         runcmd_ordryrun_local @curl,qw(-f -o),$tf,'--',"$furl";
2477         return 0 if !act_local();
2478         $downloaded = 1;
2479     }
2480
2481     open F, "<", "$tf" or die "$tf: $!";
2482     $fi->{Digester}->reset();
2483     $fi->{Digester}->addfile(*F);
2484     F->error and die $!;
2485     my $got = $fi->{Digester}->hexdigest();
2486     $got eq $fi->{Hash} or
2487         fail "file $f has hash $got but .dsc".
2488             " demands hash $fi->{Hash} ".
2489             ($downloaded ? "(got wrong file from archive!)"
2490              : "(perhaps you should delete this file?)");
2491
2492     return 1;
2493 }
2494
2495 sub ensure_we_have_orig () {
2496     my @dfi = dsc_files_info();
2497     foreach my $fi (@dfi) {
2498         my $f = $fi->{Filename};
2499         next unless is_orig_file_in_dsc($f, \@dfi);
2500         complete_file_from_dsc('..', $fi)
2501             or next;
2502     }
2503 }
2504
2505 #---------- git fetch ----------
2506
2507 sub lrfetchrefs () { return "refs/dgit-fetch/".access_basedistro(); }
2508 sub lrfetchref () { return lrfetchrefs.'/'.server_branch($csuite); }
2509
2510 # We fetch some parts of lrfetchrefs/*.  Ideally we delete these
2511 # locally fetched refs because they have unhelpful names and clutter
2512 # up gitk etc.  So we track whether we have "used up" head ref (ie,
2513 # whether we have made another local ref which refers to this object).
2514 #
2515 # (If we deleted them unconditionally, then we might end up
2516 # re-fetching the same git objects each time dgit fetch was run.)
2517 #
2518 # So, leach use of lrfetchrefs needs to be accompanied by arrangements
2519 # in git_fetch_us to fetch the refs in question, and possibly a call
2520 # to lrfetchref_used.
2521
2522 our (%lrfetchrefs_f, %lrfetchrefs_d);
2523 # $lrfetchrefs_X{lrfetchrefs."/heads/whatever"} = $objid
2524
2525 sub lrfetchref_used ($) {
2526     my ($fullrefname) = @_;
2527     my $objid = $lrfetchrefs_f{$fullrefname};
2528     $lrfetchrefs_d{$fullrefname} = $objid if defined $objid;
2529 }
2530
2531 sub git_lrfetch_sane {
2532     my ($supplementary, @specs) = @_;
2533     # Make a 'refs/'.lrfetchrefs.'/*' be just like on server,
2534     # at least as regards @specs.  Also leave the results in
2535     # %lrfetchrefs_f, and arrange for lrfetchref_used to be
2536     # able to clean these up.
2537     #
2538     # With $supplementary==1, @specs must not contain wildcards
2539     # and we add to our previous fetches (non-atomically).
2540
2541     # This is rather miserable:
2542     # When git fetch --prune is passed a fetchspec ending with a *,
2543     # it does a plausible thing.  If there is no * then:
2544     # - it matches subpaths too, even if the supplied refspec
2545     #   starts refs, and behaves completely madly if the source
2546     #   has refs/refs/something.  (See, for example, Debian #NNNN.)
2547     # - if there is no matching remote ref, it bombs out the whole
2548     #   fetch.
2549     # We want to fetch a fixed ref, and we don't know in advance
2550     # if it exists, so this is not suitable.
2551     #
2552     # Our workaround is to use git ls-remote.  git ls-remote has its
2553     # own qairks.  Notably, it has the absurd multi-tail-matching
2554     # behaviour: git ls-remote R refs/foo can report refs/foo AND
2555     # refs/refs/foo etc.
2556     #
2557     # Also, we want an idempotent snapshot, but we have to make two
2558     # calls to the remote: one to git ls-remote and to git fetch.  The
2559     # solution is use git ls-remote to obtain a target state, and
2560     # git fetch to try to generate it.  If we don't manage to generate
2561     # the target state, we try again.
2562
2563     my $url = access_giturl();
2564
2565     printdebug "git_lrfetch_sane suppl=$supplementary specs @specs\n";
2566
2567     my $specre = join '|', map {
2568         my $x = $_;
2569         $x =~ s/\W/\\$&/g;
2570         my $wildcard = $x =~ s/\\\*$/.*/;
2571         die if $wildcard && $supplementary;
2572         "(?:refs/$x)";
2573     } @specs;
2574     printdebug "git_lrfetch_sane specre=$specre\n";
2575     my $wanted_rref = sub {
2576         local ($_) = @_;
2577         return m/^(?:$specre)$/;
2578     };
2579
2580     my $fetch_iteration = 0;
2581     FETCH_ITERATION:
2582     for (;;) {
2583         printdebug "git_lrfetch_sane iteration $fetch_iteration\n";
2584         if (++$fetch_iteration > 10) {
2585             fail "too many iterations trying to get sane fetch!";
2586         }
2587
2588         my @look = map { "refs/$_" } @specs;
2589         my @lcmd = (@git, qw(ls-remote -q --refs), $url, @look);
2590         debugcmd "|",@lcmd;
2591
2592         my %wantr;
2593         open GITLS, "-|", @lcmd or die $!;
2594         while (<GITLS>) {
2595             printdebug "=> ", $_;
2596             m/^(\w+)\s+(\S+)\n/ or die "ls-remote $_ ?";
2597             my ($objid,$rrefname) = ($1,$2);
2598             if (!$wanted_rref->($rrefname)) {
2599                 print STDERR <<END;
2600 warning: git ls-remote @look reported $rrefname; this is silly, ignoring it.
2601 END
2602                 next;
2603             }
2604             $wantr{$rrefname} = $objid;
2605         }
2606         $!=0; $?=0;
2607         close GITLS or failedcmd @lcmd;
2608
2609         # OK, now %want is exactly what we want for refs in @specs
2610         my @fspecs = map {
2611             !m/\*$/ && !exists $wantr{"refs/$_"} ? () :
2612             "+refs/$_:".lrfetchrefs."/$_";
2613         } @specs;
2614
2615         printdebug "git_lrfetch_sane fspecs @fspecs\n";
2616
2617         my @fcmd = (@git, qw(fetch -p -n -q), $url, @fspecs);
2618         runcmd_ordryrun_local @fcmd if @fspecs;
2619
2620         if (!$supplementary) {
2621             %lrfetchrefs_f = ();
2622         }
2623         my %objgot;
2624
2625         git_for_each_ref(lrfetchrefs, sub {
2626             my ($objid,$objtype,$lrefname,$reftail) = @_;
2627             $lrfetchrefs_f{$lrefname} = $objid;
2628             $objgot{$objid} = 1;
2629         });
2630
2631         if ($supplementary) {
2632             last;
2633         }
2634
2635         foreach my $lrefname (sort keys %lrfetchrefs_f) {
2636             my $rrefname = 'refs'.substr($lrefname, length lrfetchrefs);
2637             if (!exists $wantr{$rrefname}) {
2638                 if ($wanted_rref->($rrefname)) {
2639                     printdebug <<END;
2640 git-fetch @fspecs created $lrefname which git ls-remote @look didn't list.
2641 END
2642                 } else {
2643                     print STDERR <<END
2644 warning: git fetch @fspecs created $lrefname; this is silly, deleting it.
2645 END
2646                 }
2647                 runcmd_ordryrun_local @git, qw(update-ref -d), $lrefname;
2648                 delete $lrfetchrefs_f{$lrefname};
2649                 next;
2650             }
2651         }
2652         foreach my $rrefname (sort keys %wantr) {
2653             my $lrefname = lrfetchrefs.substr($rrefname, 4);
2654             my $got = $lrfetchrefs_f{$lrefname} // '<none>';
2655             my $want = $wantr{$rrefname};
2656             next if $got eq $want;
2657             if (!defined $objgot{$want}) {
2658                 print STDERR <<END;
2659 warning: git ls-remote suggests we want $lrefname
2660 warning:  and it should refer to $want
2661 warning:  but git fetch didn't fetch that object to any relevant ref.
2662 warning:  This may be due to a race with someone updating the server.
2663 warning:  Will try again...
2664 END
2665                 next FETCH_ITERATION;
2666             }
2667             printdebug <<END;
2668 git-fetch @fspecs made $lrefname=$got but want git ls-remote @look says $want
2669 END
2670             runcmd_ordryrun_local @git, qw(update-ref -m),
2671                 "dgit fetch git fetch fixup", $lrefname, $want;
2672             $lrfetchrefs_f{$lrefname} = $want;
2673         }
2674         last;
2675     }
2676     printdebug "git_lrfetch_sane: git fetch --no-insane emulation complete\n",
2677         Dumper(\%lrfetchrefs_f);
2678 }
2679
2680 sub git_fetch_us () {
2681     # Want to fetch only what we are going to use, unless
2682     # deliberately-not-ff, in which case we must fetch everything.
2683
2684     my @specs = deliberately_not_fast_forward ? qw(tags/*) :
2685         map { "tags/$_" }
2686         (quiltmode_splitbrain
2687          ? (map { $_->('*',access_nomdistro) }
2688             \&debiantag_new, \&debiantag_maintview)
2689          : debiantags('*',access_nomdistro));
2690     push @specs, server_branch($csuite);
2691     push @specs, $rewritemap;
2692     push @specs, qw(heads/*) if deliberately_not_fast_forward;
2693
2694     git_lrfetch_sane 0, @specs;
2695
2696     my %here;
2697     my @tagpats = debiantags('*',access_nomdistro);
2698
2699     git_for_each_ref([map { "refs/tags/$_" } @tagpats], sub {
2700         my ($objid,$objtype,$fullrefname,$reftail) = @_;
2701         printdebug "currently $fullrefname=$objid\n";
2702         $here{$fullrefname} = $objid;
2703     });
2704     git_for_each_ref([map { lrfetchrefs."/tags/".$_ } @tagpats], sub {
2705         my ($objid,$objtype,$fullrefname,$reftail) = @_;
2706         my $lref = "refs".substr($fullrefname, length(lrfetchrefs));
2707         printdebug "offered $lref=$objid\n";
2708         if (!defined $here{$lref}) {
2709             my @upd = (@git, qw(update-ref), $lref, $objid, '');
2710             runcmd_ordryrun_local @upd;
2711             lrfetchref_used $fullrefname;
2712         } elsif ($here{$lref} eq $objid) {
2713             lrfetchref_used $fullrefname;
2714         } else {
2715             print STDERR \
2716                 "Not updateting $lref from $here{$lref} to $objid.\n";
2717         }
2718     });
2719 }
2720
2721 #---------- dsc and archive handling ----------
2722
2723 sub mergeinfo_getclogp ($) {
2724     # Ensures thit $mi->{Clogp} exists and returns it
2725     my ($mi) = @_;
2726     $mi->{Clogp} = commit_getclogp($mi->{Commit});
2727 }
2728
2729 sub mergeinfo_version ($) {
2730     return getfield( (mergeinfo_getclogp $_[0]), 'Version' );
2731 }
2732
2733 sub fetch_from_archive_record_1 ($) {
2734     my ($hash) = @_;
2735     runcmd @git, qw(update-ref -m), "dgit fetch $csuite",
2736             'DGIT_ARCHIVE', $hash;
2737     cmdoutput @git, qw(log -n2), $hash;
2738     # ... gives git a chance to complain if our commit is malformed
2739 }
2740
2741 sub fetch_from_archive_record_2 ($) {
2742     my ($hash) = @_;
2743     my @upd_cmd = (@git, qw(update-ref -m), 'dgit fetch', lrref(), $hash);
2744     if (act_local()) {
2745         cmdoutput @upd_cmd;
2746     } else {
2747         dryrun_report @upd_cmd;
2748     }
2749 }
2750
2751 sub parse_dsc_field ($$) {
2752     my ($dsc, $what) = @_;
2753     my $f;
2754     foreach my $field (@ourdscfield) {
2755         $f = $dsc->{$field};
2756         last if defined $f;
2757     }
2758     if (!defined $f) {
2759         progress "$what: NO git hash";
2760     } elsif (($dsc_hash, $dsc_distro, $dsc_hint_tag, $dsc_hint_url)
2761              = $f =~ m/^(\w+) ($distro_re) ($versiontag_re) (\S+)(?:\s|$)/) {
2762         progress "$what: specified git info ($dsc_distro)";
2763         $dsc_hint_tag = [ $dsc_hint_tag ];
2764     } elsif ($f =~ m/^\w+\s*$/) {
2765         $dsc_hash = $&;
2766         $dsc_distro //= cfg qw(dgit.default.old-dsc-distro
2767                                dgit.default.distro);
2768         $dsc_hint_tag = [ debiantags +(getfield $dsc, 'Version'),
2769                           $dsc_distro ];
2770         progress "$what: specified git hash";
2771     } else {
2772         fail "$what: invalid Dgit info";
2773     }
2774 }
2775
2776 sub resolve_dsc_field_commit ($$) {
2777     my ($already_distro, $already_mapref) = @_;
2778
2779     return unless defined $dsc_hash;
2780
2781     my $mapref =
2782         defined $already_mapref &&
2783         ($already_distro eq $dsc_distro || !$chase_dsc_distro)
2784         ? $already_mapref : undef;
2785
2786     my $do_fetch;
2787     $do_fetch = sub {
2788         my ($what, @fetch) = @_;
2789
2790         local $idistro = $dsc_distro;
2791         my $lrf = lrfetchrefs;
2792
2793         if (!$chase_dsc_distro) {
2794             progress
2795                 "not chasing .dsc distro $dsc_distro: not fetching $what";
2796             return 0;
2797         }
2798
2799         progress
2800             ".dsc names distro $dsc_distro: fetching $what";
2801
2802         my $url = access_giturl();
2803         if (!defined $url) {
2804             defined $dsc_hint_url or fail <<END;
2805 .dsc Dgit metadata is in context of distro $dsc_distro
2806 for which we have no configured url and .dsc provides no hint
2807 END
2808             my $proto =
2809                 $dsc_hint_url =~ m#^([-+0-9a-zA-Z]+):# ? $1 :
2810                 $dsc_hint_url =~ m#^/# ? 'file' : 'bad-syntax';
2811             parse_cfg_bool "dsc-url-proto-ok", 'false',
2812                 cfg("dgit.dsc-url-proto-ok.$proto",
2813                     "dgit.default.dsc-url-proto-ok")
2814                 or fail <<END;
2815 .dsc Dgit metadata is in context of distro $dsc_distro
2816 for which we have no configured url;
2817 .dsc provices hinted url with protocol $proto which is unsafe.
2818 (can be overridden by config - consult documentation)
2819 END
2820             $url = $dsc_hint_url;
2821         }
2822
2823         git_lrfetch_sane 1, @fetch;
2824
2825         return $lrf;
2826     };
2827
2828     my $rewrite_enable = do {
2829         local $idistro = $dsc_distro;
2830         access_cfg('rewrite-map-enable', 'RETURN-UNDEF');
2831     };
2832
2833     if (parse_cfg_bool 'rewrite-map-enable', 'true', $rewrite_enable) {
2834         my $lrf = $do_fetch->("rewrite map", $rewritemap) or return;
2835         $mapref = $lrf.'/'.$rewritemap;
2836         my $rewritemapdata = git_cat_file $mapref.':map';
2837         if (defined $rewritemapdata
2838             && $rewritemapdata =~ m/^$dsc_hash(?:[ \t](\w+))/m) {
2839             progress
2840                 "server's git history rewrite map contains a relevant entry!";
2841
2842             $dsc_hash = $1;
2843             if (defined $dsc_hash) {
2844                 progress "using rewritten git hash in place of .dsc value";
2845             } else {
2846                 progress "server data says .dsc hash is to be disregarded";
2847             }
2848         }
2849     }
2850
2851     if (!defined git_cat_file $dsc_hash) {
2852         my @tags = map { "tags/".$_ } @$dsc_hint_tag;
2853         my $lrf = $do_fetch->("additional commits", @tags) &&
2854             defined git_cat_file $dsc_hash
2855             or fail <<END;
2856 .dsc Dgit metadata requires commit $dsc_hash
2857 but we could not obtain that object anywhere.
2858 END
2859         foreach my $t (@tags) {
2860             my $fullrefname = $lrf.'/'.$t;
2861             print STDERR "CHK $t $fullrefname ".Dumper(\%lrfetchrefs_f);
2862             next unless $lrfetchrefs_f{$fullrefname};
2863             next unless is_fast_fwd "$fullrefname~0", $dsc_hash;
2864             lrfetchref_used $fullrefname;
2865         }
2866     }
2867 }
2868
2869 sub fetch_from_archive () {
2870     ensure_setup_existing_tree();
2871
2872     # Ensures that lrref() is what is actually in the archive, one way
2873     # or another, according to us - ie this client's
2874     # appropritaely-updated archive view.  Also returns the commit id.
2875     # If there is nothing in the archive, leaves lrref alone and
2876     # returns undef.  git_fetch_us must have already been called.
2877     get_archive_dsc();
2878
2879     if ($dsc) {
2880         parse_dsc_field($dsc, 'last upload to archive');
2881         resolve_dsc_field_commit access_basedistro,
2882             lrfetchrefs."/".$rewritemap
2883     } else {
2884         progress "no version available from the archive";
2885     }
2886
2887     # If the archive's .dsc has a Dgit field, there are three
2888     # relevant git commitids we need to choose between and/or merge
2889     # together:
2890     #   1. $dsc_hash: the Dgit field from the archive
2891     #   2. $lastpush_hash: the suite branch on the dgit git server
2892     #   3. $lastfetch_hash: our local tracking brach for the suite
2893     #
2894     # These may all be distinct and need not be in any fast forward
2895     # relationship:
2896     #
2897     # If the dsc was pushed to this suite, then the server suite
2898     # branch will have been updated; but it might have been pushed to
2899     # a different suite and copied by the archive.  Conversely a more
2900     # recent version may have been pushed with dgit but not appeared
2901     # in the archive (yet).
2902     #
2903     # $lastfetch_hash may be awkward because archive imports
2904     # (particularly, imports of Dgit-less .dscs) are performed only as
2905     # needed on individual clients, so different clients may perform a
2906     # different subset of them - and these imports are only made
2907     # public during push.  So $lastfetch_hash may represent a set of
2908     # imports different to a subsequent upload by a different dgit
2909     # client.
2910     #
2911     # Our approach is as follows:
2912     #
2913     # As between $dsc_hash and $lastpush_hash: if $lastpush_hash is a
2914     # descendant of $dsc_hash, then it was pushed by a dgit user who
2915     # had based their work on $dsc_hash, so we should prefer it.
2916     # Otherwise, $dsc_hash was installed into this suite in the
2917     # archive other than by a dgit push, and (necessarily) after the
2918     # last dgit push into that suite (since a dgit push would have
2919     # been descended from the dgit server git branch); thus, in that
2920     # case, we prefer the archive's version (and produce a
2921     # pseudo-merge to overwrite the dgit server git branch).
2922     #
2923     # (If there is no Dgit field in the archive's .dsc then
2924     # generate_commit_from_dsc uses the version numbers to decide
2925     # whether the suite branch or the archive is newer.  If the suite
2926     # branch is newer it ignores the archive's .dsc; otherwise it
2927     # generates an import of the .dsc, and produces a pseudo-merge to
2928     # overwrite the suite branch with the archive contents.)
2929     #
2930     # The outcome of that part of the algorithm is the `public view',
2931     # and is same for all dgit clients: it does not depend on any
2932     # unpublished history in the local tracking branch.
2933     #
2934     # As between the public view and the local tracking branch: The
2935     # local tracking branch is only updated by dgit fetch, and
2936     # whenever dgit fetch runs it includes the public view in the
2937     # local tracking branch.  Therefore if the public view is not
2938     # descended from the local tracking branch, the local tracking
2939     # branch must contain history which was imported from the archive
2940     # but never pushed; and, its tip is now out of date.  So, we make
2941     # a pseudo-merge to overwrite the old imports and stitch the old
2942     # history in.
2943     #
2944     # Finally: we do not necessarily reify the public view (as
2945     # described above).  This is so that we do not end up stacking two
2946     # pseudo-merges.  So what we actually do is figure out the inputs
2947     # to any public view pseudo-merge and put them in @mergeinputs.
2948
2949     my @mergeinputs;
2950     # $mergeinputs[]{Commit}
2951     # $mergeinputs[]{Info}
2952     # $mergeinputs[0] is the one whose tree we use
2953     # @mergeinputs is in the order we use in the actual commit)
2954     #
2955     # Also:
2956     # $mergeinputs[]{Message} is a commit message to use
2957     # $mergeinputs[]{ReverseParents} if def specifies that parent
2958     #                                list should be in opposite order
2959     # Such an entry has no Commit or Info.  It applies only when found
2960     # in the last entry.  (This ugliness is to support making
2961     # identical imports to previous dgit versions.)
2962
2963     my $lastpush_hash = git_get_ref(lrfetchref());
2964     printdebug "previous reference hash=$lastpush_hash\n";
2965     $lastpush_mergeinput = $lastpush_hash && {
2966         Commit => $lastpush_hash,
2967         Info => "dgit suite branch on dgit git server",
2968     };
2969
2970     my $lastfetch_hash = git_get_ref(lrref());
2971     printdebug "fetch_from_archive: lastfetch=$lastfetch_hash\n";
2972     my $lastfetch_mergeinput = $lastfetch_hash && {
2973         Commit => $lastfetch_hash,
2974         Info => "dgit client's archive history view",
2975     };
2976
2977     my $dsc_mergeinput = $dsc_hash && {
2978         Commit => $dsc_hash,
2979         Info => "Dgit field in .dsc from archive",
2980     };
2981
2982     my $cwd = getcwd();
2983     my $del_lrfetchrefs = sub {
2984         changedir $cwd;
2985         my $gur;
2986         printdebug "del_lrfetchrefs...\n";
2987         foreach my $fullrefname (sort keys %lrfetchrefs_d) {
2988             my $objid = $lrfetchrefs_d{$fullrefname};
2989             printdebug "del_lrfetchrefs: $objid $fullrefname\n";
2990             if (!$gur) {
2991                 $gur ||= new IO::Handle;
2992                 open $gur, "|-", qw(git update-ref --stdin) or die $!;
2993             }
2994             printf $gur "delete %s %s\n", $fullrefname, $objid;
2995         }
2996         if ($gur) {
2997             close $gur or failedcmd "git update-ref delete lrfetchrefs";
2998         }
2999     };
3000
3001     if (defined $dsc_hash) {
3002         ensure_we_have_orig();
3003         if (!$lastpush_hash || $dsc_hash eq $lastpush_hash) {
3004             @mergeinputs = $dsc_mergeinput
3005         } elsif (is_fast_fwd($dsc_hash,$lastpush_hash)) {
3006             print STDERR <<END or die $!;
3007
3008 Git commit in archive is behind the last version allegedly pushed/uploaded.
3009 Commit referred to by archive: $dsc_hash
3010 Last version pushed with dgit: $lastpush_hash
3011 $later_warning_msg
3012 END
3013             @mergeinputs = ($lastpush_mergeinput);
3014         } else {
3015             # Archive has .dsc which is not a descendant of the last dgit
3016             # push.  This can happen if the archive moves .dscs about.
3017             # Just follow its lead.
3018             if (is_fast_fwd($lastpush_hash,$dsc_hash)) {
3019                 progress "archive .dsc names newer git commit";
3020                 @mergeinputs = ($dsc_mergeinput);
3021             } else {
3022                 progress "archive .dsc names other git commit, fixing up";
3023                 @mergeinputs = ($dsc_mergeinput, $lastpush_mergeinput);
3024             }
3025         }
3026     } elsif ($dsc) {
3027         @mergeinputs = generate_commits_from_dsc();
3028         # We have just done an import.  Now, our import algorithm might
3029         # have been improved.  But even so we do not want to generate
3030         # a new different import of the same package.  So if the
3031         # version numbers are the same, just use our existing version.
3032         # If the version numbers are different, the archive has changed
3033         # (perhaps, rewound).
3034         if ($lastfetch_mergeinput &&
3035             !version_compare( (mergeinfo_version $lastfetch_mergeinput),
3036                               (mergeinfo_version $mergeinputs[0]) )) {
3037             @mergeinputs = ($lastfetch_mergeinput);
3038         }
3039     } elsif ($lastpush_hash) {
3040         # only in git, not in the archive yet
3041         @mergeinputs = ($lastpush_mergeinput);
3042         print STDERR <<END or die $!;
3043
3044 Package not found in the archive, but has allegedly been pushed using dgit.
3045 $later_warning_msg
3046 END
3047     } else {
3048         printdebug "nothing found!\n";
3049         if (defined $skew_warning_vsn) {
3050             print STDERR <<END or die $!;
3051
3052 Warning: relevant archive skew detected.
3053 Archive allegedly contains $skew_warning_vsn
3054 But we were not able to obtain any version from the archive or git.
3055
3056 END
3057         }
3058         unshift @end, $del_lrfetchrefs;
3059         return undef;
3060     }
3061
3062     if ($lastfetch_hash &&
3063         !grep {
3064             my $h = $_->{Commit};
3065             $h and is_fast_fwd($lastfetch_hash, $h);
3066             # If true, one of the existing parents of this commit
3067             # is a descendant of the $lastfetch_hash, so we'll
3068             # be ff from that automatically.
3069         } @mergeinputs
3070         ) {
3071         # Otherwise:
3072         push @mergeinputs, $lastfetch_mergeinput;
3073     }
3074
3075     printdebug "fetch mergeinfos:\n";
3076     foreach my $mi (@mergeinputs) {
3077         if ($mi->{Info}) {
3078             printdebug " commit $mi->{Commit} $mi->{Info}\n";
3079         } else {
3080             printdebug sprintf " ReverseParents=%d Message=%s",
3081                 $mi->{ReverseParents}, $mi->{Message};
3082         }
3083     }
3084
3085     my $compat_info= pop @mergeinputs
3086         if $mergeinputs[$#mergeinputs]{Message};
3087
3088     @mergeinputs = grep { defined $_->{Commit} } @mergeinputs;
3089
3090     my $hash;
3091     if (@mergeinputs > 1) {
3092         # here we go, then:
3093         my $tree_commit = $mergeinputs[0]{Commit};
3094
3095         my $tree = cmdoutput @git, qw(cat-file commit), $tree_commit;
3096         $tree =~ m/\n\n/;  $tree = $`;
3097         $tree =~ m/^tree (\w+)$/m or die "$dsc_hash tree ?";
3098         $tree = $1;
3099
3100         # We use the changelog author of the package in question the
3101         # author of this pseudo-merge.  This is (roughly) correct if
3102         # this commit is simply representing aa non-dgit upload.
3103         # (Roughly because it does not record sponsorship - but we
3104         # don't have sponsorship info because that's in the .changes,
3105         # which isn't in the archivw.)
3106         #
3107         # But, it might be that we are representing archive history
3108         # updates (including in-archive copies).  These are not really
3109         # the responsibility of the person who created the .dsc, but
3110         # there is no-one whose name we should better use.  (The
3111         # author of the .dsc-named commit is clearly worse.)
3112
3113         my $useclogp = mergeinfo_getclogp $mergeinputs[0];
3114         my $author = clogp_authline $useclogp;
3115         my $cversion = getfield $useclogp, 'Version';
3116
3117         my $mcf = ".git/dgit/mergecommit";
3118         open MC, ">", $mcf or die "$mcf $!";
3119         print MC <<END or die $!;
3120 tree $tree
3121 END
3122
3123         my @parents = grep { $_->{Commit} } @mergeinputs;
3124         @parents = reverse @parents if $compat_info->{ReverseParents};
3125         print MC <<END or die $! foreach @parents;
3126 parent $_->{Commit}
3127 END
3128
3129         print MC <<END or die $!;
3130 author $author
3131 committer $author
3132
3133 END
3134
3135         if (defined $compat_info->{Message}) {
3136             print MC $compat_info->{Message} or die $!;
3137         } else {
3138             print MC <<END or die $!;
3139 Record $package ($cversion) in archive suite $csuite
3140
3141 Record that
3142 END
3143             my $message_add_info = sub {
3144                 my ($mi) = (@_);
3145                 my $mversion = mergeinfo_version $mi;
3146                 printf MC "  %-20s %s\n", $mversion, $mi->{Info}
3147                     or die $!;
3148             };
3149
3150             $message_add_info->($mergeinputs[0]);
3151             print MC <<END or die $!;
3152 should be treated as descended from
3153 END
3154             $message_add_info->($_) foreach @mergeinputs[1..$#mergeinputs];
3155         }
3156
3157         close MC or die $!;
3158         $hash = make_commit $mcf;
3159     } else {
3160         $hash = $mergeinputs[0]{Commit};
3161     }
3162     printdebug "fetch hash=$hash\n";
3163
3164     my $chkff = sub {
3165         my ($lasth, $what) = @_;
3166         return unless $lasth;
3167         die "$lasth $hash $what ?" unless is_fast_fwd($lasth, $hash);
3168     };
3169
3170     $chkff->($lastpush_hash, 'dgit repo server tip (last push)')
3171         if $lastpush_hash;
3172     $chkff->($lastfetch_hash, 'local tracking tip (last fetch)');
3173
3174     fetch_from_archive_record_1($hash);
3175
3176     if (defined $skew_warning_vsn) {
3177         mkpath '.git/dgit';
3178         printdebug "SKEW CHECK WANT $skew_warning_vsn\n";
3179         my $gotclogp = commit_getclogp($hash);
3180         my $got_vsn = getfield $gotclogp, 'Version';
3181         printdebug "SKEW CHECK GOT $got_vsn\n";
3182         if (version_compare($got_vsn, $skew_warning_vsn) < 0) {
3183             print STDERR <<END or die $!;
3184
3185 Warning: archive skew detected.  Using the available version:
3186 Archive allegedly contains    $skew_warning_vsn
3187 We were able to obtain only   $got_vsn
3188
3189 END
3190         }
3191     }
3192
3193     if ($lastfetch_hash ne $hash) {
3194         fetch_from_archive_record_2($hash);
3195     }
3196
3197     lrfetchref_used lrfetchref();
3198
3199     unshift @end, $del_lrfetchrefs;
3200     return $hash;
3201 }
3202
3203 sub set_local_git_config ($$) {
3204     my ($k, $v) = @_;
3205     runcmd @git, qw(config), $k, $v;
3206 }
3207
3208 sub setup_mergechangelogs (;$) {
3209     my ($always) = @_;
3210     return unless $always || access_cfg_bool(1, 'setup-mergechangelogs');
3211
3212     my $driver = 'dpkg-mergechangelogs';
3213     my $cb = "merge.$driver";
3214     my $attrs = '.git/info/attributes';
3215     ensuredir '.git/info';
3216
3217     open NATTRS, ">", "$attrs.new" or die "$attrs.new $!";
3218     if (!open ATTRS, "<", $attrs) {
3219         $!==ENOENT or die "$attrs: $!";
3220     } else {
3221         while (<ATTRS>) {
3222             chomp;
3223             next if m{^debian/changelog\s};
3224             print NATTRS $_, "\n" or die $!;
3225         }
3226         ATTRS->error and die $!;
3227         close ATTRS;
3228     }
3229     print NATTRS "debian/changelog merge=$driver\n" or die $!;
3230     close NATTRS;
3231
3232     set_local_git_config "$cb.name", 'debian/changelog merge driver';
3233     set_local_git_config "$cb.driver", 'dpkg-mergechangelogs -m %O %A %B %A';
3234
3235     rename "$attrs.new", "$attrs" or die "$attrs: $!";
3236 }
3237
3238 sub setup_useremail (;$) {
3239     my ($always) = @_;
3240     return unless $always || access_cfg_bool(1, 'setup-useremail');
3241
3242     my $setup = sub {
3243         my ($k, $envvar) = @_;
3244         my $v = access_cfg("user-$k", 'RETURN-UNDEF') // $ENV{$envvar};
3245         return unless defined $v;
3246         set_local_git_config "user.$k", $v;
3247     };
3248
3249     $setup->('email', 'DEBEMAIL');
3250     $setup->('name', 'DEBFULLNAME');
3251 }
3252
3253 sub ensure_setup_existing_tree () {
3254     my $k = "remote.$remotename.skipdefaultupdate";
3255     my $c = git_get_config $k;
3256     return if defined $c;
3257     set_local_git_config $k, 'true';
3258 }
3259
3260 sub setup_new_tree () {
3261     setup_mergechangelogs();
3262     setup_useremail();
3263 }
3264
3265 sub multisuite_suite_child ($$$) {
3266     my ($tsuite, $merginputs, $fn) = @_;
3267     # in child, sets things up, calls $fn->(), and returns undef
3268     # in parent, returns canonical suite name for $tsuite
3269     my $canonsuitefh = IO::File::new_tmpfile;
3270     my $pid = fork // die $!;
3271     if (!$pid) {
3272         $isuite = $tsuite;
3273         $us .= " [$isuite]";
3274         $debugprefix .= " ";
3275         progress "fetching $tsuite...";
3276         canonicalise_suite();
3277         print $canonsuitefh $csuite, "\n" or die $!;
3278         close $canonsuitefh or die $!;
3279         $fn->();
3280         return undef;
3281     }
3282     waitpid $pid,0 == $pid or die $!;
3283     fail "failed to obtain $tsuite: ".waitstatusmsg() if $? && $?!=256*4;
3284     seek $canonsuitefh,0,0 or die $!;
3285     local $csuite = <$canonsuitefh>;
3286     die $! unless defined $csuite && chomp $csuite;
3287     if ($? == 256*4) {
3288         printdebug "multisuite $tsuite missing\n";
3289         return $csuite;
3290     }
3291     printdebug "multisuite $tsuite ok (canon=$csuite)\n";
3292     push @$merginputs, {
3293         Ref => lrref,
3294         Info => $csuite,
3295     };
3296     return $csuite;
3297 }
3298
3299 sub fork_for_multisuite ($) {
3300     my ($before_fetch_merge) = @_;
3301     # if nothing unusual, just returns ''
3302     #
3303     # if multisuite:
3304     # returns 0 to caller in child, to do first of the specified suites
3305     # in child, $csuite is not yet set
3306     #
3307     # returns 1 to caller in parent, to finish up anything needed after
3308     # in parent, $csuite is set to canonicalised portmanteau
3309
3310     my $org_isuite = $isuite;
3311     my @suites = split /\,/, $isuite;
3312     return '' unless @suites > 1;
3313     printdebug "fork_for_multisuite: @suites\n";
3314
3315     my @mergeinputs;
3316
3317     my $cbasesuite = multisuite_suite_child($suites[0], \@mergeinputs,
3318                                             sub { });
3319     return 0 unless defined $cbasesuite;
3320
3321     fail "package $package missing in (base suite) $cbasesuite"
3322         unless @mergeinputs;
3323
3324     my @csuites = ($cbasesuite);
3325
3326     $before_fetch_merge->();
3327
3328     foreach my $tsuite (@suites[1..$#suites]) {
3329         my $csubsuite = multisuite_suite_child($tsuite, \@mergeinputs,
3330                                                sub {
3331             @end = ();
3332             fetch();
3333             exit 0;
3334         });
3335         # xxx collecte the ref here
3336
3337         $csubsuite =~ s/^\Q$cbasesuite\E-/-/;
3338         push @csuites, $csubsuite;
3339     }
3340
3341     foreach my $mi (@mergeinputs) {
3342         my $ref = git_get_ref $mi->{Ref};
3343         die "$mi->{Ref} ?" unless length $ref;
3344         $mi->{Commit} = $ref;
3345     }
3346
3347     $csuite = join ",", @csuites;
3348
3349     my $previous = git_get_ref lrref;
3350     if ($previous) {
3351         unshift @mergeinputs, {
3352             Commit => $previous,
3353             Info => "local combined tracking branch",
3354             Warning =>
3355  "archive seems to have rewound: local tracking branch is ahead!",
3356         };
3357     }
3358
3359     foreach my $ix (0..$#mergeinputs) {
3360         $mergeinputs[$ix]{Index} = $ix;
3361     }
3362
3363     @mergeinputs = sort {
3364         -version_compare(mergeinfo_version $a,
3365                          mergeinfo_version $b) # highest version first
3366             or
3367         $a->{Index} <=> $b->{Index}; # earliest in spec first
3368     } @mergeinputs;
3369
3370     my @needed;
3371
3372   NEEDED:
3373     foreach my $mi (@mergeinputs) {
3374         printdebug "multisuite merge check $mi->{Info}\n";
3375         foreach my $previous (@needed) {
3376             next unless is_fast_fwd $mi->{Commit}, $previous->{Commit};
3377             printdebug "multisuite merge un-needed $previous->{Info}\n";
3378             next NEEDED;
3379         }
3380         push @needed, $mi;
3381         printdebug "multisuite merge this-needed\n";
3382         $mi->{Character} = '+';
3383     }
3384
3385     $needed[0]{Character} = '*';
3386
3387     my $output = $needed[0]{Commit};
3388
3389     if (@needed > 1) {
3390         printdebug "multisuite merge nontrivial\n";
3391         my $tree = cmdoutput qw(git rev-parse), $needed[0]{Commit}.':';
3392
3393         my $commit = "tree $tree\n";
3394         my $msg = "Combine archive branches $csuite [dgit]\n\n".
3395             "Input branches:\n";
3396
3397         foreach my $mi (sort { $a->{Index} <=> $b->{Index} } @mergeinputs) {
3398             printdebug "multisuite merge include $mi->{Info}\n";
3399             $mi->{Character} //= ' ';
3400             $commit .= "parent $mi->{Commit}\n";
3401             $msg .= sprintf " %s  %-25s %s\n",
3402                 $mi->{Character},
3403                 (mergeinfo_version $mi),
3404                 $mi->{Info};
3405         }
3406         my $authline = clogp_authline mergeinfo_getclogp $needed[0];
3407         $msg .= "\nKey\n".
3408             " * marks the highest version branch, which choose to use\n".
3409             " + marks each branch which was not already an ancestor\n\n".
3410             "[dgit multi-suite $csuite]\n";
3411         $commit .=
3412             "author $authline\n".
3413             "committer $authline\n\n";
3414         $output = make_commit_text $commit.$msg;
3415         printdebug "multisuite merge generated $output\n";
3416     }
3417
3418     fetch_from_archive_record_1($output);
3419     fetch_from_archive_record_2($output);
3420
3421     progress "calculated combined tracking suite $csuite";
3422
3423     return 1;
3424 }
3425
3426 sub clone_set_head () {
3427     open H, "> .git/HEAD" or die $!;
3428     print H "ref: ".lref()."\n" or die $!;
3429     close H or die $!;
3430 }
3431 sub clone_finish ($) {
3432     my ($dstdir) = @_;
3433     runcmd @git, qw(reset --hard), lrref();
3434     runcmd qw(bash -ec), <<'END';
3435         set -o pipefail
3436         git ls-tree -r --name-only -z HEAD | \
3437         xargs -0r touch -h -r . --
3438 END
3439     printdone "ready for work in $dstdir";
3440 }
3441
3442 sub clone ($) {
3443     my ($dstdir) = @_;
3444     badusage "dry run makes no sense with clone" unless act_local();
3445
3446     my $multi_fetched = fork_for_multisuite(sub {
3447         printdebug "multi clone before fetch merge\n";
3448         changedir $dstdir;
3449     });
3450     if ($multi_fetched) {
3451         printdebug "multi clone after fetch merge\n";
3452         clone_set_head();
3453         clone_finish($dstdir);
3454         exit 0;
3455     }
3456     printdebug "clone main body\n";
3457
3458     canonicalise_suite();
3459     my $hasgit = check_for_git();
3460     mkdir $dstdir or fail "create \`$dstdir': $!";
3461     changedir $dstdir;
3462     runcmd @git, qw(init -q);
3463     clone_set_head();
3464     my $giturl = access_giturl(1);
3465     if (defined $giturl) {
3466         runcmd @git, qw(remote add), 'origin', $giturl;
3467     }
3468     if ($hasgit) {
3469         progress "fetching existing git history";
3470         git_fetch_us();
3471         runcmd_ordryrun_local @git, qw(fetch origin);
3472     } else {
3473         progress "starting new git history";
3474     }
3475     fetch_from_archive() or no_such_package;
3476     my $vcsgiturl = $dsc->{'Vcs-Git'};
3477     if (length $vcsgiturl) {
3478         $vcsgiturl =~ s/\s+-b\s+\S+//g;
3479         runcmd @git, qw(remote add vcs-git), $vcsgiturl;
3480     }
3481     setup_new_tree();
3482     clone_finish($dstdir);
3483 }
3484
3485 sub fetch () {
3486     canonicalise_suite();
3487     if (check_for_git()) {
3488         git_fetch_us();
3489     }
3490     fetch_from_archive() or no_such_package();
3491     printdone "fetched into ".lrref();
3492 }
3493
3494 sub pull () {
3495     my $multi_fetched = fork_for_multisuite(sub { });
3496     fetch() unless $multi_fetched; # parent
3497     return if $multi_fetched eq '0'; # child
3498     runcmd_ordryrun_local @git, qw(merge -m),"Merge from $csuite [dgit]",
3499         lrref();
3500     printdone "fetched to ".lrref()." and merged into HEAD";
3501 }
3502
3503 sub check_not_dirty () {
3504     foreach my $f (qw(local-options local-patch-header)) {
3505         if (stat_exists "debian/source/$f") {
3506             fail "git tree contains debian/source/$f";
3507         }
3508     }
3509
3510     return if $ignoredirty;
3511
3512     my @cmd = (@git, qw(diff --quiet HEAD));
3513     debugcmd "+",@cmd;
3514     $!=0; $?=-1; system @cmd;
3515     return if !$?;
3516     if ($?==256) {
3517         fail "working tree is dirty (does not match HEAD)";
3518     } else {
3519         failedcmd @cmd;
3520     }
3521 }
3522
3523 sub commit_admin ($) {
3524     my ($m) = @_;
3525     progress "$m";
3526     runcmd_ordryrun_local @git, qw(commit -m), $m;
3527 }
3528
3529 sub commit_quilty_patch () {
3530     my $output = cmdoutput @git, qw(status --porcelain);
3531     my %adds;
3532     foreach my $l (split /\n/, $output) {
3533         next unless $l =~ m/\S/;
3534         if ($l =~ m{^(?:\?\?| M) (.pc|debian/patches)}) {
3535             $adds{$1}++;
3536         }
3537     }
3538     delete $adds{'.pc'}; # if there wasn't one before, don't add it
3539     if (!%adds) {
3540         progress "nothing quilty to commit, ok.";
3541         return;
3542     }
3543     my @adds = map { s/[][*?\\]/\\$&/g; $_; } sort keys %adds;
3544     runcmd_ordryrun_local @git, qw(add -f), @adds;
3545     commit_admin <<END
3546 Commit Debian 3.0 (quilt) metadata
3547
3548 [dgit ($our_version) quilt-fixup]
3549 END
3550 }
3551
3552 sub get_source_format () {
3553     my %options;
3554     if (open F, "debian/source/options") {
3555         while (<F>) {
3556             next if m/^\s*\#/;
3557             next unless m/\S/;
3558             s/\s+$//; # ignore missing final newline
3559             if (m/\s*\#\s*/) {
3560                 my ($k, $v) = ($`, $'); #');
3561                 $v =~ s/^"(.*)"$/$1/;
3562                 $options{$k} = $v;
3563             } else {
3564                 $options{$_} = 1;
3565             }
3566         }
3567         F->error and die $!;
3568         close F;
3569     } else {
3570         die $! unless $!==&ENOENT;
3571     }
3572
3573     if (!open F, "debian/source/format") {
3574         die $! unless $!==&ENOENT;
3575         return '';
3576     }
3577     $_ = <F>;
3578     F->error and die $!;
3579     chomp;
3580     return ($_, \%options);
3581 }
3582
3583 sub madformat_wantfixup ($) {
3584     my ($format) = @_;
3585     return 0 unless $format eq '3.0 (quilt)';
3586     our $quilt_mode_warned;
3587     if ($quilt_mode eq 'nocheck') {
3588         progress "Not doing any fixup of \`$format' due to".
3589             " ----no-quilt-fixup or --quilt=nocheck"
3590             unless $quilt_mode_warned++;
3591         return 0;
3592     }
3593     progress "Format \`$format', need to check/update patch stack"
3594         unless $quilt_mode_warned++;
3595     return 1;
3596 }
3597
3598 sub maybe_split_brain_save ($$$) {
3599     my ($headref, $dgitview, $msg) = @_;
3600     # => message fragment "$saved" describing disposition of $dgitview
3601     return "commit id $dgitview" unless defined $split_brain_save;
3602     my @cmd = (shell_cmd "cd ../../../..",
3603                @git, qw(update-ref -m),
3604                "dgit --dgit-view-save $msg HEAD=$headref",
3605                $split_brain_save, $dgitview);
3606     runcmd @cmd;
3607     return "and left in $split_brain_save";
3608 }
3609
3610 # An "infopair" is a tuple [ $thing, $what ]
3611 # (often $thing is a commit hash; $what is a description)
3612
3613 sub infopair_cond_equal ($$) {
3614     my ($x,$y) = @_;
3615     $x->[0] eq $y->[0] or fail <<END;
3616 $x->[1] ($x->[0]) not equal to $y->[1] ($y->[0])
3617 END
3618 };
3619
3620 sub infopair_lrf_tag_lookup ($$) {
3621     my ($tagnames, $what) = @_;
3622     # $tagname may be an array ref
3623     my @tagnames = ref $tagnames ? @$tagnames : ($tagnames);
3624     printdebug "infopair_lrfetchref_tag_lookup $what @tagnames\n";
3625     foreach my $tagname (@tagnames) {
3626         my $lrefname = lrfetchrefs."/tags/$tagname";
3627         my $tagobj = $lrfetchrefs_f{$lrefname};
3628         next unless defined $tagobj;
3629         printdebug "infopair_lrfetchref_tag_lookup $tagobj $tagname $what\n";
3630         return [ git_rev_parse($tagobj), $what ];
3631     }
3632     fail @tagnames==1 ? <<END : <<END;
3633 Wanted tag $what (@tagnames) on dgit server, but not found
3634 END
3635 Wanted tag $what (one of: @tagnames) on dgit server, but not found
3636 END
3637 }
3638
3639 sub infopair_cond_ff ($$) {
3640     my ($anc,$desc) = @_;
3641     is_fast_fwd($anc->[0], $desc->[0]) or fail <<END;
3642 $anc->[1] ($anc->[0]) .. $desc->[1] ($desc->[0]) is not fast forward
3643 END
3644 };
3645
3646 sub pseudomerge_version_check ($$) {
3647     my ($clogp, $archive_hash) = @_;
3648
3649     my $arch_clogp = commit_getclogp $archive_hash;
3650     my $i_arch_v = [ (getfield $arch_clogp, 'Version'),
3651                      'version currently in archive' ];
3652     if (defined $overwrite_version) {
3653         if (length $overwrite_version) {
3654             infopair_cond_equal([ $overwrite_version,
3655                                   '--overwrite= version' ],
3656                                 $i_arch_v);
3657         } else {
3658             my $v = $i_arch_v->[0];
3659             progress "Checking package changelog for archive version $v ...";
3660             eval {
3661                 my @xa = ("-f$v", "-t$v");
3662                 my $vclogp = parsechangelog @xa;
3663                 my $cv = [ (getfield $vclogp, 'Version'),
3664                            "Version field from dpkg-parsechangelog @xa" ];
3665                 infopair_cond_equal($i_arch_v, $cv);
3666             };
3667             if ($@) {
3668                 $@ =~ s/^dgit: //gm;
3669                 fail "$@".
3670                     "Perhaps debian/changelog does not mention $v ?";
3671             }
3672         }
3673     }
3674
3675     printdebug "pseudomerge_version_check i_arch_v @$i_arch_v\n";
3676     return $i_arch_v;
3677 }
3678
3679 sub pseudomerge_make_commit ($$$$ $$) {
3680     my ($clogp, $dgitview, $archive_hash, $i_arch_v,
3681         $msg_cmd, $msg_msg) = @_;
3682     progress "Declaring that HEAD inciudes all changes in $i_arch_v->[0]...";
3683
3684     my $tree = cmdoutput qw(git rev-parse), "${dgitview}:";
3685     my $authline = clogp_authline $clogp;
3686
3687     chomp $msg_msg;
3688     $msg_cmd .=
3689         !defined $overwrite_version ? ""
3690         : !length  $overwrite_version ? " --overwrite"
3691         : " --overwrite=".$overwrite_version;
3692
3693     mkpath '.git/dgit';
3694     my $pmf = ".git/dgit/pseudomerge";
3695     open MC, ">", $pmf or die "$pmf $!";
3696     print MC <<END or die $!;
3697 tree $tree
3698 parent $dgitview
3699 parent $archive_hash
3700 author $authline
3701 committer $authline
3702
3703 $msg_msg
3704
3705 [$msg_cmd]
3706 END
3707     close MC or die $!;
3708
3709     return make_commit($pmf);
3710 }
3711
3712 sub splitbrain_pseudomerge ($$$$) {
3713     my ($clogp, $maintview, $dgitview, $archive_hash) = @_;
3714     # => $merged_dgitview
3715     printdebug "splitbrain_pseudomerge...\n";
3716     #
3717     #     We:      debian/PREVIOUS    HEAD($maintview)
3718     # expect:          o ----------------- o
3719     #                    \                   \
3720     #                     o                   o
3721     #                 a/d/PREVIOUS        $dgitview
3722     #                $archive_hash              \
3723     #  If so,                \                   \
3724     #  we do:                 `------------------ o
3725     #   this:                                   $dgitview'
3726     #
3727
3728     return $dgitview unless defined $archive_hash;
3729
3730     printdebug "splitbrain_pseudomerge...\n";
3731
3732     my $i_arch_v = pseudomerge_version_check($clogp, $archive_hash);
3733
3734     if (!defined $overwrite_version) {
3735         progress "Checking that HEAD inciudes all changes in archive...";
3736     }
3737
3738     return $dgitview if is_fast_fwd $archive_hash, $dgitview;
3739
3740     if (defined $overwrite_version) {
3741     } elsif (!eval {
3742         my $t_dep14 = debiantag_maintview $i_arch_v->[0], access_nomdistro;
3743         my $i_dep14 = infopair_lrf_tag_lookup($t_dep14, "maintainer view tag");
3744         my $t_dgit = debiantag_new $i_arch_v->[0], access_nomdistro;
3745         my $i_dgit = infopair_lrf_tag_lookup($t_dgit, "dgit view tag");
3746         my $i_archive = [ $archive_hash, "current archive contents" ];
3747
3748         printdebug "splitbrain_pseudomerge i_archive @$i_archive\n";
3749
3750         infopair_cond_equal($i_dgit, $i_archive);
3751         infopair_cond_ff($i_dep14, $i_dgit);
3752         infopair_cond_ff($i_dep14, [ $maintview, 'HEAD' ]);
3753         1;
3754     }) {
3755         print STDERR <<END;
3756 $us: check failed (maybe --overwrite is needed, consult documentation)
3757 END
3758         die "$@";
3759     }
3760
3761     my $r = pseudomerge_make_commit
3762         $clogp, $dgitview, $archive_hash, $i_arch_v,
3763         "dgit --quilt=$quilt_mode",
3764         (defined $overwrite_version ? <<END_OVERWR : <<END_MAKEFF);
3765 Declare fast forward from $i_arch_v->[0]
3766 END_OVERWR
3767 Make fast forward from $i_arch_v->[0]
3768 END_MAKEFF
3769
3770     maybe_split_brain_save $maintview, $r, "pseudomerge";
3771
3772     progress "Made pseudo-merge of $i_arch_v->[0] into dgit view.";
3773     return $r;
3774 }
3775
3776 sub plain_overwrite_pseudomerge ($$$) {
3777     my ($clogp, $head, $archive_hash) = @_;
3778
3779     printdebug "plain_overwrite_pseudomerge...";
3780
3781     my $i_arch_v = pseudomerge_version_check($clogp, $archive_hash);
3782
3783     return $head if is_fast_fwd $archive_hash, $head;
3784
3785     my $m = "Declare fast forward from $i_arch_v->[0]";
3786
3787     my $r = pseudomerge_make_commit
3788         $clogp, $head, $archive_hash, $i_arch_v,
3789         "dgit", $m;
3790
3791     runcmd @git, qw(update-ref -m), $m, 'HEAD', $r, $head;
3792
3793     progress "Make pseudo-merge of $i_arch_v->[0] into your HEAD.";
3794     return $r;
3795 }
3796
3797 sub push_parse_changelog ($) {
3798     my ($clogpfn) = @_;
3799
3800     my $clogp = Dpkg::Control::Hash->new();
3801     $clogp->load($clogpfn) or die;
3802
3803     my $clogpackage = getfield $clogp, 'Source';
3804     $package //= $clogpackage;
3805     fail "-p specified $package but changelog specified $clogpackage"
3806         unless $package eq $clogpackage;
3807     my $cversion = getfield $clogp, 'Version';
3808     my $tag = debiantag($cversion, access_nomdistro);
3809     runcmd @git, qw(check-ref-format), $tag;
3810
3811     my $dscfn = dscfn($cversion);
3812
3813     return ($clogp, $cversion, $dscfn);
3814 }
3815
3816 sub push_parse_dsc ($$$) {
3817     my ($dscfn,$dscfnwhat, $cversion) = @_;
3818     $dsc = parsecontrol($dscfn,$dscfnwhat);
3819     my $dversion = getfield $dsc, 'Version';
3820     my $dscpackage = getfield $dsc, 'Source';
3821     ($dscpackage eq $package && $dversion eq $cversion) or
3822         fail "$dscfn is for $dscpackage $dversion".
3823             " but debian/changelog is for $package $cversion";
3824 }
3825
3826 sub push_tagwants ($$$$) {
3827     my ($cversion, $dgithead, $maintviewhead, $tfbase) = @_;
3828     my @tagwants;
3829     push @tagwants, {
3830         TagFn => \&debiantag,
3831         Objid => $dgithead,
3832         TfSuffix => '',
3833         View => 'dgit',
3834     };
3835     if (defined $maintviewhead) {
3836         push @tagwants, {
3837             TagFn => \&debiantag_maintview,
3838             Objid => $maintviewhead,
3839             TfSuffix => '-maintview',
3840             View => 'maint',
3841         };
3842     } elsif ($dodep14tag eq 'no' ? 0
3843              : $dodep14tag eq 'want' ? access_cfg_tagformats_can_splitbrain
3844              : $dodep14tag eq 'always'
3845              ? (access_cfg_tagformats_can_splitbrain or fail <<END)
3846 --dep14tag-always (or equivalent in config) means server must support
3847  both "new" and "maint" tag formats, but config says it doesn't.
3848 END
3849             : die "$dodep14tag ?") {
3850         push @tagwants, {
3851             TagFn => \&debiantag_maintview,
3852             Objid => $dgithead,
3853             TfSuffix => '-dgit',
3854             View => 'dgit',
3855         };
3856     };
3857     foreach my $tw (@tagwants) {
3858         $tw->{Tag} = $tw->{TagFn}($cversion, access_nomdistro);
3859         $tw->{Tfn} = sub { $tfbase.$tw->{TfSuffix}.$_[0]; };
3860     }
3861     printdebug 'push_tagwants: ', Dumper(\@_, \@tagwants);
3862     return @tagwants;
3863 }
3864
3865 sub push_mktags ($$ $$ $) {
3866     my ($clogp,$dscfn,
3867         $changesfile,$changesfilewhat,
3868         $tagwants) = @_;
3869
3870     die unless $tagwants->[0]{View} eq 'dgit';
3871
3872     my $declaredistro = access_nomdistro();
3873     my $reader_giturl = do { local $access_forpush=0; access_giturl(); };
3874     $dsc->{$ourdscfield[0]} = join " ",
3875         $tagwants->[0]{Objid}, $declaredistro, $tagwants->[0]{Tag},
3876         $reader_giturl;
3877     $dsc->save("$dscfn.tmp") or die $!;
3878
3879     my $changes = parsecontrol($changesfile,$changesfilewhat);
3880     foreach my $field (qw(Source Distribution Version)) {
3881         $changes->{$field} eq $clogp->{$field} or
3882             fail "changes field $field \`$changes->{$field}'".
3883                 " does not match changelog \`$clogp->{$field}'";
3884     }
3885
3886     my $cversion = getfield $clogp, 'Version';
3887     my $clogsuite = getfield $clogp, 'Distribution';
3888
3889     # We make the git tag by hand because (a) that makes it easier
3890     # to control the "tagger" (b) we can do remote signing
3891     my $authline = clogp_authline $clogp;
3892     my $delibs = join(" ", "",@deliberatelies);
3893
3894     my $mktag = sub {
3895         my ($tw) = @_;
3896         my $tfn = $tw->{Tfn};
3897         my $head = $tw->{Objid};
3898         my $tag = $tw->{Tag};
3899
3900         open TO, '>', $tfn->('.tmp') or die $!;
3901         print TO <<END or die $!;
3902 object $head
3903 type commit
3904 tag $tag
3905 tagger $authline
3906
3907 END
3908         if ($tw->{View} eq 'dgit') {
3909             print TO <<END or die $!;
3910 $package release $cversion for $clogsuite ($csuite) [dgit]
3911 [dgit distro=$declaredistro$delibs]
3912 END
3913             foreach my $ref (sort keys %previously) {
3914                 print TO <<END or die $!;
3915 [dgit previously:$ref=$previously{$ref}]
3916 END
3917             }
3918         } elsif ($tw->{View} eq 'maint') {
3919             print TO <<END or die $!;
3920 $package release $cversion for $clogsuite ($csuite)
3921 (maintainer view tag generated by dgit --quilt=$quilt_mode)
3922 END
3923         } else {
3924             die Dumper($tw)."?";
3925         }
3926
3927         close TO or die $!;
3928
3929         my $tagobjfn = $tfn->('.tmp');
3930         if ($sign) {
3931             if (!defined $keyid) {
3932                 $keyid = access_cfg('keyid','RETURN-UNDEF');
3933             }
3934             if (!defined $keyid) {
3935                 $keyid = getfield $clogp, 'Maintainer';
3936             }
3937             unlink $tfn->('.tmp.asc') or $!==&ENOENT or die $!;
3938             my @sign_cmd = (@gpg, qw(--detach-sign --armor));
3939             push @sign_cmd, qw(-u),$keyid if defined $keyid;
3940             push @sign_cmd, $tfn->('.tmp');
3941             runcmd_ordryrun @sign_cmd;
3942             if (act_scary()) {
3943                 $tagobjfn = $tfn->('.signed.tmp');
3944                 runcmd shell_cmd "exec >$tagobjfn", qw(cat --),
3945                     $tfn->('.tmp'), $tfn->('.tmp.asc');
3946             }
3947         }
3948         return $tagobjfn;
3949     };
3950
3951     my @r = map { $mktag->($_); } @$tagwants;
3952     return @r;
3953 }
3954
3955 sub sign_changes ($) {
3956     my ($changesfile) = @_;
3957     if ($sign) {
3958         my @debsign_cmd = @debsign;
3959         push @debsign_cmd, "-k$keyid" if defined $keyid;
3960         push @debsign_cmd, "-p$gpg[0]" if $gpg[0] ne 'gpg';
3961         push @debsign_cmd, $changesfile;
3962         runcmd_ordryrun @debsign_cmd;
3963     }
3964 }
3965
3966 sub dopush () {
3967     printdebug "actually entering push\n";
3968
3969     supplementary_message(<<'END');
3970 Push failed, while checking state of the archive.
3971 You can retry the push, after fixing the problem, if you like.
3972 END
3973     if (check_for_git()) {
3974         git_fetch_us();
3975     }
3976     my $archive_hash = fetch_from_archive();
3977     if (!$archive_hash) {
3978         $new_package or
3979             fail "package appears to be new in this suite;".
3980                 " if this is intentional, use --new";
3981     }
3982
3983     supplementary_message(<<'END');
3984 Push failed, while preparing your push.
3985 You can retry the push, after fixing the problem, if you like.
3986 END
3987
3988     need_tagformat 'new', "quilt mode $quilt_mode"
3989         if quiltmode_splitbrain;
3990
3991     prep_ud();
3992
3993     access_giturl(); # check that success is vaguely likely
3994     select_tagformat();
3995
3996     my $clogpfn = ".git/dgit/changelog.822.tmp";
3997     runcmd shell_cmd "exec >$clogpfn", qw(dpkg-parsechangelog);
3998
3999     responder_send_file('parsed-changelog', $clogpfn);
4000
4001     my ($clogp, $cversion, $dscfn) =
4002         push_parse_changelog("$clogpfn");
4003
4004     my $dscpath = "$buildproductsdir/$dscfn";
4005     stat_exists $dscpath or
4006         fail "looked for .dsc $dscpath, but $!;".
4007             " maybe you forgot to build";
4008
4009     responder_send_file('dsc', $dscpath);
4010
4011     push_parse_dsc($dscpath, $dscfn, $cversion);
4012
4013     my $format = getfield $dsc, 'Format';
4014     printdebug "format $format\n";
4015
4016     my $actualhead = git_rev_parse('HEAD');
4017     my $dgithead = $actualhead;
4018     my $maintviewhead = undef;
4019
4020     my $upstreamversion = upstreamversion $clogp->{Version};
4021
4022     if (madformat_wantfixup($format)) {
4023         # user might have not used dgit build, so maybe do this now:
4024         if (quiltmode_splitbrain()) {
4025             changedir $ud;
4026             quilt_make_fake_dsc($upstreamversion);
4027             my $cachekey;
4028             ($dgithead, $cachekey) =
4029                 quilt_check_splitbrain_cache($actualhead, $upstreamversion);
4030             $dgithead or fail
4031  "--quilt=$quilt_mode but no cached dgit view:
4032  perhaps tree changed since dgit build[-source] ?";
4033             $split_brain = 1;
4034             $dgithead = splitbrain_pseudomerge($clogp,
4035                                                $actualhead, $dgithead,
4036                                                $archive_hash);
4037             $maintviewhead = $actualhead;
4038             changedir '../../../..';
4039             prep_ud(); # so _only_subdir() works, below
4040         } else {
4041             commit_quilty_patch();
4042         }
4043     }
4044
4045     if (defined $overwrite_version && !defined $maintviewhead) {
4046         $dgithead = plain_overwrite_pseudomerge($clogp,
4047                                                 $dgithead,
4048                                                 $archive_hash);
4049     }
4050
4051     check_not_dirty();
4052
4053     my $forceflag = '';
4054     if ($archive_hash) {
4055         if (is_fast_fwd($archive_hash, $dgithead)) {
4056             # ok
4057         } elsif (deliberately_not_fast_forward) {
4058             $forceflag = '+';
4059         } else {
4060             fail "dgit push: HEAD is not a descendant".
4061                 " of the archive's version.\n".
4062                 "To overwrite the archive's contents,".
4063                 " pass --overwrite[=VERSION].\n".
4064                 "To rewind history, if permitted by the archive,".
4065                 " use --deliberately-not-fast-forward.";
4066         }
4067     }
4068
4069     changedir $ud;
4070     progress "checking that $dscfn corresponds to HEAD";
4071     runcmd qw(dpkg-source -x --),
4072         $dscpath =~ m#^/# ? $dscpath : "../../../$dscpath";
4073     my ($tree,$dir) = mktree_in_ud_from_only_subdir("source package");
4074     check_for_vendor_patches() if madformat($dsc->{format});
4075     changedir '../../../..';
4076     my @diffcmd = (@git, qw(diff --quiet), $tree, $dgithead);
4077     debugcmd "+",@diffcmd;
4078     $!=0; $?=-1;
4079     my $r = system @diffcmd;
4080     if ($r) {
4081         if ($r==256) {
4082             my $diffs = cmdoutput @git, qw(diff --stat), $tree, $dgithead;
4083             fail <<END
4084 HEAD specifies a different tree to $dscfn:
4085 $diffs
4086 Perhaps you forgot to build.  Or perhaps there is a problem with your
4087  source tree (see dgit(7) for some hints).  To see a full diff, run
4088    git diff $tree HEAD
4089 END
4090         } else {
4091             failedcmd @diffcmd;
4092         }
4093     }
4094     if (!$changesfile) {
4095         my $pat = changespat $cversion;
4096         my @cs = glob "$buildproductsdir/$pat";
4097         fail "failed to find unique changes file".
4098             " (looked for $pat in $buildproductsdir);".
4099             " perhaps you need to use dgit -C"
4100             unless @cs==1;
4101         ($changesfile) = @cs;
4102     } else {
4103         $changesfile = "$buildproductsdir/$changesfile";
4104     }
4105
4106     # Check that changes and .dsc agree enough
4107     $changesfile =~ m{[^/]*$};
4108     my $changes = parsecontrol($changesfile,$&);
4109     files_compare_inputs($dsc, $changes)
4110         unless forceing [qw(dsc-changes-mismatch)];
4111
4112     # Perhaps adjust .dsc to contain right set of origs
4113     changes_update_origs_from_dsc($dsc, $changes, $upstreamversion,
4114                                   $changesfile)
4115         unless forceing [qw(changes-origs-exactly)];
4116
4117     # Checks complete, we're going to try and go ahead:
4118
4119     responder_send_file('changes',$changesfile);
4120     responder_send_command("param head $dgithead");
4121     responder_send_command("param csuite $csuite");
4122     responder_send_command("param tagformat $tagformat");
4123     if (defined $maintviewhead) {
4124         die unless ($protovsn//4) >= 4;
4125         responder_send_command("param maint-view $maintviewhead");
4126     }
4127
4128     if (deliberately_not_fast_forward) {
4129         git_for_each_ref(lrfetchrefs, sub {
4130             my ($objid,$objtype,$lrfetchrefname,$reftail) = @_;
4131             my $rrefname= substr($lrfetchrefname, length(lrfetchrefs) + 1);
4132             responder_send_command("previously $rrefname=$objid");
4133             $previously{$rrefname} = $objid;
4134         });
4135     }
4136
4137     my @tagwants = push_tagwants($cversion, $dgithead, $maintviewhead,
4138                                  ".git/dgit/tag");
4139     my @tagobjfns;
4140
4141     supplementary_message(<<'END');
4142 Push failed, while signing the tag.
4143 You can retry the push, after fixing the problem, if you like.
4144 END
4145     # If we manage to sign but fail to record it anywhere, it's fine.
4146     if ($we_are_responder) {
4147         @tagobjfns = map { $_->{Tfn}('.signed-tmp') } @tagwants;
4148         responder_receive_files('signed-tag', @tagobjfns);
4149     } else {
4150         @tagobjfns = push_mktags($clogp,$dscpath,
4151                               $changesfile,$changesfile,
4152                               \@tagwants);
4153     }
4154     supplementary_message(<<'END');
4155 Push failed, *after* signing the tag.
4156 If you want to try again, you should use a new version number.
4157 END
4158
4159     pairwise { $a->{TagObjFn} = $b } @tagwants, @tagobjfns;
4160
4161     foreach my $tw (@tagwants) {
4162         my $tag = $tw->{Tag};
4163         my $tagobjfn = $tw->{TagObjFn};
4164         my $tag_obj_hash =
4165             cmdoutput @git, qw(hash-object -w -t tag), $tagobjfn;
4166         runcmd_ordryrun @git, qw(verify-tag), $tag_obj_hash;
4167         runcmd_ordryrun_local
4168             @git, qw(update-ref), "refs/tags/$tag", $tag_obj_hash;
4169     }
4170
4171     supplementary_message(<<'END');
4172 Push failed, while updating the remote git repository - see messages above.
4173 If you want to try again, you should use a new version number.
4174 END
4175     if (!check_for_git()) {
4176         create_remote_git_repo();
4177     }
4178
4179     my @pushrefs = $forceflag.$dgithead.":".rrref();
4180     foreach my $tw (@tagwants) {
4181         push @pushrefs, $forceflag."refs/tags/$tw->{Tag}";
4182     }
4183
4184     runcmd_ordryrun @git,
4185         qw(-c push.followTags=false push), access_giturl(), @pushrefs;
4186     runcmd_ordryrun @git, qw(update-ref -m), 'dgit push', lrref(), $dgithead;
4187
4188     supplementary_message(<<'END');
4189 Push failed, while obtaining signatures on the .changes and .dsc.
4190 If it was just that the signature failed, you may try again by using
4191 debsign by hand to sign the changes
4192    $changesfile
4193 and then dput to complete the upload.
4194 If you need to change the package, you must use a new version number.
4195 END
4196     if ($we_are_responder) {
4197         my $dryrunsuffix = act_local() ? "" : ".tmp";
4198         responder_receive_files('signed-dsc-changes',
4199                                 "$dscpath$dryrunsuffix",
4200                                 "$changesfile$dryrunsuffix");
4201     } else {
4202         if (act_local()) {
4203             rename "$dscpath.tmp",$dscpath or die "$dscfn $!";
4204         } else {
4205             progress "[new .dsc left in $dscpath.tmp]";
4206         }
4207         sign_changes $changesfile;
4208     }
4209
4210     supplementary_message(<<END);
4211 Push failed, while uploading package(s) to the archive server.
4212 You can retry the upload of exactly these same files with dput of:
4213   $changesfile
4214 If that .changes file is broken, you will need to use a new version
4215 number for your next attempt at the upload.
4216 END
4217     my $host = access_cfg('upload-host','RETURN-UNDEF');
4218     my @hostarg = defined($host) ? ($host,) : ();
4219     runcmd_ordryrun @dput, @hostarg, $changesfile;
4220     printdone "pushed and uploaded $cversion";
4221
4222     supplementary_message('');
4223     responder_send_command("complete");
4224 }
4225
4226 sub cmd_clone {
4227     parseopts();
4228     my $dstdir;
4229     badusage "-p is not allowed with clone; specify as argument instead"
4230         if defined $package;
4231     if (@ARGV==1) {
4232         ($package) = @ARGV;
4233     } elsif (@ARGV==2 && $ARGV[1] =~ m#^\w#) {
4234         ($package,$isuite) = @ARGV;
4235     } elsif (@ARGV==2 && $ARGV[1] =~ m#^[./]#) {
4236         ($package,$dstdir) = @ARGV;
4237     } elsif (@ARGV==3) {
4238         ($package,$isuite,$dstdir) = @ARGV;
4239     } else {
4240         badusage "incorrect arguments to dgit clone";
4241     }
4242     notpushing();
4243
4244     $dstdir ||= "$package";
4245     if (stat_exists $dstdir) {
4246         fail "$dstdir already exists";
4247     }
4248
4249     my $cwd_remove;
4250     if ($rmonerror && !$dryrun_level) {
4251         $cwd_remove= getcwd();
4252         unshift @end, sub {
4253             return unless defined $cwd_remove;
4254             if (!chdir "$cwd_remove") {
4255                 return if $!==&ENOENT;
4256                 die "chdir $cwd_remove: $!";
4257             }
4258             printdebug "clone rmonerror removing $dstdir\n";
4259             if (stat $dstdir) {
4260                 rmtree($dstdir) or die "remove $dstdir: $!\n";
4261             } elsif (grep { $! == $_ }
4262                      (ENOENT, ENOTDIR, EACCES, EPERM, ELOOP)) {
4263             } else {
4264                 print STDERR "check whether to remove $dstdir: $!\n";
4265             }
4266         };
4267     }
4268
4269     clone($dstdir);
4270     $cwd_remove = undef;
4271 }
4272
4273 sub branchsuite () {
4274     my $branch = cmdoutput_errok @git, qw(symbolic-ref HEAD);
4275     if ($branch =~ m#$lbranch_re#o) {
4276         return $1;
4277     } else {
4278         return undef;
4279     }
4280 }
4281
4282 sub fetchpullargs () {
4283     if (!defined $package) {
4284         my $sourcep = parsecontrol('debian/control','debian/control');
4285         $package = getfield $sourcep, 'Source';
4286     }
4287     if (@ARGV==0) {
4288         $isuite = branchsuite();
4289         if (!$isuite) {
4290             my $clogp = parsechangelog();
4291             $isuite = getfield $clogp, 'Distribution';
4292         }
4293     } elsif (@ARGV==1) {
4294         ($isuite) = @ARGV;
4295     } else {
4296         badusage "incorrect arguments to dgit fetch or dgit pull";
4297     }
4298     notpushing();
4299 }
4300
4301 sub cmd_fetch {
4302     parseopts();
4303     fetchpullargs();
4304     my $multi_fetched = fork_for_multisuite(sub { });
4305     exit 0 if $multi_fetched;
4306     fetch();
4307 }
4308
4309 sub cmd_pull {
4310     parseopts();
4311     fetchpullargs();
4312     if (quiltmode_splitbrain()) {
4313         my ($format, $fopts) = get_source_format();
4314         madformat($format) and fail <<END
4315 dgit pull not yet supported in split view mode (--quilt=$quilt_mode)
4316 END
4317     }
4318     pull();
4319 }
4320
4321 sub cmd_push {
4322     parseopts();
4323     pushing();
4324     badusage "-p is not allowed with dgit push" if defined $package;
4325     check_not_dirty();
4326     my $clogp = parsechangelog();
4327     $package = getfield $clogp, 'Source';
4328     my $specsuite;
4329     if (@ARGV==0) {
4330     } elsif (@ARGV==1) {
4331         ($specsuite) = (@ARGV);
4332     } else {
4333         badusage "incorrect arguments to dgit push";
4334     }
4335     $isuite = getfield $clogp, 'Distribution';
4336     if ($new_package) {
4337         local ($package) = $existing_package; # this is a hack
4338         canonicalise_suite();
4339     } else {
4340         canonicalise_suite();
4341     }
4342     if (defined $specsuite &&
4343         $specsuite ne $isuite &&
4344         $specsuite ne $csuite) {
4345             fail "dgit push: changelog specifies $isuite ($csuite)".
4346                 " but command line specifies $specsuite";
4347     }
4348     dopush();
4349 }
4350
4351 #---------- remote commands' implementation ----------
4352
4353 sub cmd_remote_push_build_host {
4354     my ($nrargs) = shift @ARGV;
4355     my (@rargs) = @ARGV[0..$nrargs-1];
4356     @ARGV = @ARGV[$nrargs..$#ARGV];
4357     die unless @rargs;
4358     my ($dir,$vsnwant) = @rargs;
4359     # vsnwant is a comma-separated list; we report which we have
4360     # chosen in our ready response (so other end can tell if they
4361     # offered several)
4362     $debugprefix = ' ';
4363     $we_are_responder = 1;
4364     $us .= " (build host)";
4365
4366     pushing();
4367
4368     open PI, "<&STDIN" or die $!;
4369     open STDIN, "/dev/null" or die $!;
4370     open PO, ">&STDOUT" or die $!;
4371     autoflush PO 1;
4372     open STDOUT, ">&STDERR" or die $!;
4373     autoflush STDOUT 1;
4374
4375     $vsnwant //= 1;
4376     ($protovsn) = grep {
4377         $vsnwant =~ m{^(?:.*,)?$_(?:,.*)?$}
4378     } @rpushprotovsn_support;
4379
4380     fail "build host has dgit rpush protocol versions ".
4381         (join ",", @rpushprotovsn_support).
4382         " but invocation host has $vsnwant"
4383         unless defined $protovsn;
4384
4385     responder_send_command("dgit-remote-push-ready $protovsn");
4386     rpush_handle_protovsn_bothends();
4387     changedir $dir;
4388     &cmd_push;
4389 }
4390
4391 sub cmd_remote_push_responder { cmd_remote_push_build_host(); }
4392 # ... for compatibility with proto vsn.1 dgit (just so that user gets
4393 #     a good error message)
4394
4395 sub rpush_handle_protovsn_bothends () {
4396     if ($protovsn < 4) {
4397         need_tagformat 'old', "rpush negotiated protocol $protovsn";
4398     }
4399     select_tagformat();
4400 }
4401
4402 our $i_tmp;
4403
4404 sub i_cleanup {
4405     local ($@, $?);
4406     my $report = i_child_report();
4407     if (defined $report) {
4408         printdebug "($report)\n";
4409     } elsif ($i_child_pid) {
4410         printdebug "(killing build host child $i_child_pid)\n";
4411         kill 15, $i_child_pid;
4412     }
4413     if (defined $i_tmp && !defined $initiator_tempdir) {
4414         changedir "/";
4415         eval { rmtree $i_tmp; };
4416     }
4417 }
4418
4419 END { i_cleanup(); }
4420
4421 sub i_method {
4422     my ($base,$selector,@args) = @_;
4423     $selector =~ s/\-/_/g;
4424     { no strict qw(refs); &{"${base}_${selector}"}(@args); }
4425 }
4426
4427 sub cmd_rpush {
4428     pushing();
4429     my $host = nextarg;
4430     my $dir;
4431     if ($host =~ m/^((?:[^][]|\[[^][]*\])*)\:/) {
4432         $host = $1;
4433         $dir = $'; #';
4434     } else {
4435         $dir = nextarg;
4436     }
4437     $dir =~ s{^-}{./-};
4438     my @rargs = ($dir);
4439     push @rargs, join ",", @rpushprotovsn_support;
4440     my @rdgit;
4441     push @rdgit, @dgit;
4442     push @rdgit, @ropts;
4443     push @rdgit, qw(remote-push-build-host), (scalar @rargs), @rargs;
4444     push @rdgit, @ARGV;
4445     my @cmd = (@ssh, $host, shellquote @rdgit);
4446     debugcmd "+",@cmd;
4447
4448     if (defined $initiator_tempdir) {
4449         rmtree $initiator_tempdir;
4450         mkdir $initiator_tempdir, 0700 or die "$initiator_tempdir: $!";
4451         $i_tmp = $initiator_tempdir;
4452     } else {
4453         $i_tmp = tempdir();
4454     }
4455     $i_child_pid = open2(\*RO, \*RI, @cmd);
4456     changedir $i_tmp;
4457     ($protovsn) = initiator_expect { m/^dgit-remote-push-ready (\S+)/ };
4458     die "$protovsn ?" unless grep { $_ eq $protovsn } @rpushprotovsn_support;
4459     $supplementary_message = '' unless $protovsn >= 3;
4460
4461     fail "rpush negotiated protocol version $protovsn".
4462         " which does not support quilt mode $quilt_mode"
4463         if quiltmode_splitbrain;
4464
4465     rpush_handle_protovsn_bothends();
4466     for (;;) {
4467         my ($icmd,$iargs) = initiator_expect {
4468             m/^(\S+)(?: (.*))?$/;
4469             ($1,$2);
4470         };
4471         i_method "i_resp", $icmd, $iargs;
4472     }
4473 }
4474
4475 sub i_resp_progress ($) {
4476     my ($rhs) = @_;
4477     my $msg = protocol_read_bytes \*RO, $rhs;
4478     progress $msg;
4479 }
4480
4481 sub i_resp_supplementary_message ($) {
4482     my ($rhs) = @_;
4483     $supplementary_message = protocol_read_bytes \*RO, $rhs;
4484 }
4485
4486 sub i_resp_complete {
4487     my $pid = $i_child_pid;
4488     $i_child_pid = undef; # prevents killing some other process with same pid
4489     printdebug "waiting for build host child $pid...\n";
4490     my $got = waitpid $pid, 0;
4491     die $! unless $got == $pid;
4492     die "build host child failed $?" if $?;
4493
4494     i_cleanup();
4495     printdebug "all done\n";
4496     exit 0;
4497 }
4498
4499 sub i_resp_file ($) {
4500     my ($keyword) = @_;
4501     my $localname = i_method "i_localname", $keyword;
4502     my $localpath = "$i_tmp/$localname";
4503     stat_exists $localpath and
4504         badproto \*RO, "file $keyword ($localpath) twice";
4505     protocol_receive_file \*RO, $localpath;
4506     i_method "i_file", $keyword;
4507 }
4508
4509 our %i_param;
4510
4511 sub i_resp_param ($) {
4512     $_[0] =~ m/^(\S+) (.*)$/ or badproto \*RO, "bad param spec";
4513     $i_param{$1} = $2;
4514 }
4515
4516 sub i_resp_previously ($) {
4517     $_[0] =~ m#^(refs/tags/\S+)=(\w+)$#
4518         or badproto \*RO, "bad previously spec";
4519     my $r = system qw(git check-ref-format), $1;
4520     die "bad previously ref spec ($r)" if $r;
4521     $previously{$1} = $2;
4522 }
4523
4524 our %i_wanted;
4525
4526 sub i_resp_want ($) {
4527     my ($keyword) = @_;
4528     die "$keyword ?" if $i_wanted{$keyword}++;
4529     my @localpaths = i_method "i_want", $keyword;
4530     printdebug "[[  $keyword @localpaths\n";
4531     foreach my $localpath (@localpaths) {
4532         protocol_send_file \*RI, $localpath;
4533     }
4534     print RI "files-end\n" or die $!;
4535 }
4536
4537 our ($i_clogp, $i_version, $i_dscfn, $i_changesfn);
4538
4539 sub i_localname_parsed_changelog {
4540     return "remote-changelog.822";
4541 }
4542 sub i_file_parsed_changelog {
4543     ($i_clogp, $i_version, $i_dscfn) =
4544         push_parse_changelog "$i_tmp/remote-changelog.822";
4545     die if $i_dscfn =~ m#/|^\W#;
4546 }
4547
4548 sub i_localname_dsc {
4549     defined $i_dscfn or badproto \*RO, "dsc (before parsed-changelog)";
4550     return $i_dscfn;
4551 }
4552 sub i_file_dsc { }
4553
4554 sub i_localname_changes {
4555     defined $i_dscfn or badproto \*RO, "dsc (before parsed-changelog)";
4556     $i_changesfn = $i_dscfn;
4557     $i_changesfn =~ s/\.dsc$/_dgit.changes/ or die;
4558     return $i_changesfn;
4559 }
4560 sub i_file_changes { }
4561
4562 sub i_want_signed_tag {
4563     printdebug Dumper(\%i_param, $i_dscfn);
4564     defined $i_param{'head'} && defined $i_dscfn && defined $i_clogp
4565         && defined $i_param{'csuite'}
4566         or badproto \*RO, "premature desire for signed-tag";
4567     my $head = $i_param{'head'};
4568     die if $head =~ m/[^0-9a-f]/ || $head !~ m/^../;
4569
4570     my $maintview = $i_param{'maint-view'};
4571     die if defined $maintview && $maintview =~ m/[^0-9a-f]/;
4572
4573     select_tagformat();
4574     if ($protovsn >= 4) {
4575         my $p = $i_param{'tagformat'} // '<undef>';
4576         $p eq $tagformat
4577             or badproto \*RO, "tag format mismatch: $p vs. $tagformat";
4578     }
4579
4580     die unless $i_param{'csuite'} =~ m/^$suite_re$/;
4581     $csuite = $&;
4582     push_parse_dsc $i_dscfn, 'remote dsc', $i_version;
4583
4584     my @tagwants = push_tagwants $i_version, $head, $maintview, "tag";
4585
4586     return
4587         push_mktags $i_clogp, $i_dscfn,
4588             $i_changesfn, 'remote changes',
4589             \@tagwants;
4590 }
4591
4592 sub i_want_signed_dsc_changes {
4593     rename "$i_dscfn.tmp","$i_dscfn" or die "$i_dscfn $!";
4594     sign_changes $i_changesfn;
4595     return ($i_dscfn, $i_changesfn);
4596 }
4597
4598 #---------- building etc. ----------
4599
4600 our $version;
4601 our $sourcechanges;
4602 our $dscfn;
4603
4604 #----- `3.0 (quilt)' handling -----
4605
4606 our $fakeeditorenv = 'DGIT_FAKE_EDITOR_QUILT';
4607
4608 sub quiltify_dpkg_commit ($$$;$) {
4609     my ($patchname,$author,$msg, $xinfo) = @_;
4610     $xinfo //= '';
4611
4612     mkpath '.git/dgit';
4613     my $descfn = ".git/dgit/quilt-description.tmp";
4614     open O, '>', $descfn or die "$descfn: $!";
4615     $msg =~ s/\n+/\n\n/;
4616     print O <<END or die $!;
4617 From: $author
4618 ${xinfo}Subject: $msg
4619 ---
4620
4621 END
4622     close O or die $!;
4623
4624     {
4625         local $ENV{'EDITOR'} = cmdoutput qw(realpath --), $0;
4626         local $ENV{'VISUAL'} = $ENV{'EDITOR'};
4627         local $ENV{$fakeeditorenv} = cmdoutput qw(realpath --), $descfn;
4628         runcmd @dpkgsource, qw(--commit --include-removal .), $patchname;
4629     }
4630 }
4631
4632 sub quiltify_trees_differ ($$;$$$) {
4633     my ($x,$y,$finegrained,$ignorenamesr,$unrepres) = @_;
4634     # returns true iff the two tree objects differ other than in debian/
4635     # with $finegrained,
4636     # returns bitmask 01 - differ in upstream files except .gitignore
4637     #                 02 - differ in .gitignore
4638     # if $ignorenamesr is defined, $ingorenamesr->{$fn}
4639     #  is set for each modified .gitignore filename $fn
4640     # if $unrepres is defined, array ref to which is appeneded
4641     #  a list of unrepresentable changes (removals of upstream files
4642     #  (as messages)
4643     local $/=undef;
4644     my @cmd = (@git, qw(diff-tree -z));
4645     push @cmd, qw(--name-only) unless $unrepres;
4646     push @cmd, qw(-r) if $finegrained || $unrepres;
4647     push @cmd, $x, $y;
4648     my $diffs= cmdoutput @cmd;
4649     my $r = 0;
4650     my @lmodes;
4651     foreach my $f (split /\0/, $diffs) {
4652         if ($unrepres && !@lmodes) {
4653             @lmodes = $f =~ m/^\:(\w+) (\w+) \w+ \w+ / or die "$_ ?";
4654             next;
4655         }
4656         my ($oldmode,$newmode) = @lmodes;
4657         @lmodes = ();
4658
4659         next if $f =~ m#^debian(?:/.*)?$#s;
4660
4661         if ($unrepres) {
4662             eval {
4663                 die "not a plain file\n"
4664                     unless $newmode =~ m/^10\d{4}$/ ||
4665                            $oldmode =~ m/^10\d{4}$/;
4666                 if ($oldmode =~ m/[^0]/ &&
4667                     $newmode =~ m/[^0]/) {
4668                     die "mode changed\n" if $oldmode ne $newmode;
4669                 } else {
4670                     die "non-default mode\n"
4671                         unless $newmode =~ m/^100644$/ ||
4672                                $oldmode =~ m/^100644$/;
4673                 }
4674             };
4675             if ($@) {
4676                 local $/="\n"; chomp $@;
4677                 push @$unrepres, [ $f, "$@ ($oldmode->$newmode)" ];
4678             }
4679         }
4680
4681         my $isignore = $f =~ m#^(?:.*/)?.gitignore$#s;
4682         $r |= $isignore ? 02 : 01;
4683         $ignorenamesr->{$f}=1 if $ignorenamesr && $isignore;
4684     }
4685     printdebug "quiltify_trees_differ $x $y => $r\n";
4686     return $r;
4687 }
4688
4689 sub quiltify_tree_sentinelfiles ($) {
4690     # lists the `sentinel' files present in the tree
4691     my ($x) = @_;
4692     my $r = cmdoutput @git, qw(ls-tree --name-only), $x,
4693         qw(-- debian/rules debian/control);
4694     $r =~ s/\n/,/g;
4695     return $r;
4696 }
4697
4698 sub quiltify_splitbrain_needed () {
4699     if (!$split_brain) {
4700         progress "dgit view: changes are required...";
4701         runcmd @git, qw(checkout -q -b dgit-view);
4702         $split_brain = 1;
4703     }
4704 }
4705
4706 sub quiltify_splitbrain ($$$$$$) {
4707     my ($clogp, $unapplied, $headref, $diffbits,
4708         $editedignores, $cachekey) = @_;
4709     if ($quilt_mode !~ m/gbp|dpm/) {
4710         # treat .gitignore just like any other upstream file
4711         $diffbits = { %$diffbits };
4712         $_ = !!$_ foreach values %$diffbits;
4713     }
4714     # We would like any commits we generate to be reproducible
4715     my @authline = clogp_authline($clogp);
4716     local $ENV{GIT_COMMITTER_NAME} =  $authline[0];
4717     local $ENV{GIT_COMMITTER_EMAIL} = $authline[1];
4718     local $ENV{GIT_COMMITTER_DATE} =  $authline[2];
4719     local $ENV{GIT_AUTHOR_NAME} =  $authline[0];
4720     local $ENV{GIT_AUTHOR_EMAIL} = $authline[1];
4721     local $ENV{GIT_AUTHOR_DATE} =  $authline[2];
4722
4723     if ($quilt_mode =~ m/gbp|unapplied/ &&
4724         ($diffbits->{O2H} & 01)) {
4725         my $msg =
4726  "--quilt=$quilt_mode specified, implying patches-unapplied git tree\n".
4727  " but git tree differs from orig in upstream files.";
4728         if (!stat_exists "debian/patches") {
4729             $msg .=
4730  "\n ... debian/patches is missing; perhaps this is a patch queue branch?";
4731         }
4732         fail $msg;
4733     }
4734     if ($quilt_mode =~ m/dpm/ &&
4735         ($diffbits->{H2A} & 01)) {
4736         fail <<END;
4737 --quilt=$quilt_mode specified, implying patches-applied git tree
4738  but git tree differs from result of applying debian/patches to upstream
4739 END
4740     }
4741     if ($quilt_mode =~ m/gbp|unapplied/ &&
4742         ($diffbits->{O2A} & 01)) { # some patches
4743         quiltify_splitbrain_needed();
4744         progress "dgit view: creating patches-applied version using gbp pq";
4745         runcmd shell_cmd 'exec >/dev/null', gbp_pq, qw(import);
4746         # gbp pq import creates a fresh branch; push back to dgit-view
4747         runcmd @git, qw(update-ref refs/heads/dgit-view HEAD);
4748         runcmd @git, qw(checkout -q dgit-view);
4749     }
4750     if ($quilt_mode =~ m/gbp|dpm/ &&
4751         ($diffbits->{O2A} & 02)) {
4752         fail <<END
4753 --quilt=$quilt_mode specified, implying that HEAD is for use with a
4754  tool which does not create patches for changes to upstream
4755  .gitignores: but, such patches exist in debian/patches.
4756 END
4757     }
4758     if (($diffbits->{O2H} & 02) && # user has modified .gitignore
4759         !($diffbits->{O2A} & 02)) { # patches do not change .gitignore
4760         quiltify_splitbrain_needed();
4761         progress "dgit view: creating patch to represent .gitignore changes";
4762         ensuredir "debian/patches";
4763         my $gipatch = "debian/patches/auto-gitignore";
4764         open GIPATCH, ">>", "$gipatch" or die "$gipatch: $!";
4765         stat GIPATCH or die "$gipatch: $!";
4766         fail "$gipatch already exists; but want to create it".
4767             " to record .gitignore changes" if (stat _)[7];
4768         print GIPATCH <<END or die "$gipatch: $!";
4769 Subject: Update .gitignore from Debian packaging branch
4770
4771 The Debian packaging git branch contains these updates to the upstream
4772 .gitignore file(s).  This patch is autogenerated, to provide these
4773 updates to users of the official Debian archive view of the package.
4774
4775 [dgit ($our_version) update-gitignore]
4776 ---
4777 END
4778         close GIPATCH or die "$gipatch: $!";
4779         runcmd shell_cmd "exec >>$gipatch", @git, qw(diff),
4780             $unapplied, $headref, "--", sort keys %$editedignores;
4781         open SERIES, "+>>", "debian/patches/series" or die $!;
4782         defined seek SERIES, -1, 2 or $!==EINVAL or die $!;
4783         my $newline;
4784         defined read SERIES, $newline, 1 or die $!;
4785         print SERIES "\n" or die $! unless $newline eq "\n";
4786         print SERIES "auto-gitignore\n" or die $!;
4787         close SERIES or die  $!;
4788         runcmd @git, qw(add -- debian/patches/series), $gipatch;
4789         commit_admin <<END
4790 Commit patch to update .gitignore
4791
4792 [dgit ($our_version) update-gitignore-quilt-fixup]
4793 END
4794     }
4795
4796     my $dgitview = git_rev_parse 'HEAD';
4797
4798     changedir '../../../..';
4799     # When we no longer need to support squeeze, use --create-reflog
4800     # instead of this:
4801     ensuredir ".git/logs/refs/dgit-intern";
4802     my $makelogfh = new IO::File ".git/logs/refs/$splitbraincache", '>>'
4803       or die $!;
4804
4805     my $oldcache = git_get_ref "refs/$splitbraincache";
4806     if ($oldcache eq $dgitview) {
4807         my $tree = cmdoutput qw(git rev-parse), "$dgitview:";
4808         # git update-ref doesn't always update, in this case.  *sigh*
4809         my $dummy = make_commit_text <<END;
4810 tree $tree
4811 parent $dgitview
4812 author Dgit <dgit\@example.com> 1000000000 +0000
4813 committer Dgit <dgit\@example.com> 1000000000 +0000
4814
4815 Dummy commit - do not use
4816 END
4817         runcmd @git, qw(update-ref -m), "dgit $our_version - dummy",
4818             "refs/$splitbraincache", $dummy;
4819     }
4820     runcmd @git, qw(update-ref -m), $cachekey, "refs/$splitbraincache",
4821         $dgitview;
4822
4823     changedir '.git/dgit/unpack/work';
4824
4825     my $saved = maybe_split_brain_save $headref, $dgitview, "converted";
4826     progress "dgit view: created ($saved)";
4827 }
4828
4829 sub quiltify ($$$$) {
4830     my ($clogp,$target,$oldtiptree,$failsuggestion) = @_;
4831
4832     # Quilt patchification algorithm
4833     #
4834     # We search backwards through the history of the main tree's HEAD
4835     # (T) looking for a start commit S whose tree object is identical
4836     # to to the patch tip tree (ie the tree corresponding to the
4837     # current dpkg-committed patch series).  For these purposes
4838     # `identical' disregards anything in debian/ - this wrinkle is
4839     # necessary because dpkg-source treates debian/ specially.
4840     #
4841     # We can only traverse edges where at most one of the ancestors'
4842     # trees differs (in changes outside in debian/).  And we cannot
4843     # handle edges which change .pc/ or debian/patches.  To avoid
4844     # going down a rathole we avoid traversing edges which introduce
4845     # debian/rules or debian/control.  And we set a limit on the
4846     # number of edges we are willing to look at.
4847     #
4848     # If we succeed, we walk forwards again.  For each traversed edge
4849     # PC (with P parent, C child) (starting with P=S and ending with
4850     # C=T) to we do this:
4851     #  - git checkout C
4852     #  - dpkg-source --commit with a patch name and message derived from C
4853     # After traversing PT, we git commit the changes which
4854     # should be contained within debian/patches.
4855
4856     # The search for the path S..T is breadth-first.  We maintain a
4857     # todo list containing search nodes.  A search node identifies a
4858     # commit, and looks something like this:
4859     #  $p = {
4860     #      Commit => $git_commit_id,
4861     #      Child => $c,                          # or undef if P=T
4862     #      Whynot => $reason_edge_PC_unsuitable, # in @nots only
4863     #      Nontrivial => true iff $p..$c has relevant changes
4864     #  };
4865
4866     my @todo;
4867     my @nots;
4868     my $sref_S;
4869     my $max_work=100;
4870     my %considered; # saves being exponential on some weird graphs
4871
4872     my $t_sentinels = quiltify_tree_sentinelfiles $target;
4873
4874     my $not = sub {
4875         my ($search,$whynot) = @_;
4876         printdebug " search NOT $search->{Commit} $whynot\n";
4877         $search->{Whynot} = $whynot;
4878         push @nots, $search;
4879         no warnings qw(exiting);
4880         next;
4881     };
4882
4883     push @todo, {
4884         Commit => $target,
4885     };
4886
4887     while (@todo) {
4888         my $c = shift @todo;
4889         next if $considered{$c->{Commit}}++;
4890
4891         $not->($c, "maximum search space exceeded") if --$max_work <= 0;
4892
4893         printdebug "quiltify investigate $c->{Commit}\n";
4894
4895         # are we done?
4896         if (!quiltify_trees_differ $c->{Commit}, $oldtiptree) {
4897             printdebug " search finished hooray!\n";
4898             $sref_S = $c;
4899             last;
4900         }
4901
4902         if ($quilt_mode eq 'nofix') {
4903             fail "quilt fixup required but quilt mode is \`nofix'\n".
4904                 "HEAD commit $c->{Commit} differs from tree implied by ".
4905                 " debian/patches (tree object $oldtiptree)";
4906         }
4907         if ($quilt_mode eq 'smash') {
4908             printdebug " search quitting smash\n";
4909             last;
4910         }
4911
4912         my $c_sentinels = quiltify_tree_sentinelfiles $c->{Commit};
4913         $not->($c, "has $c_sentinels not $t_sentinels")
4914             if $c_sentinels ne $t_sentinels;
4915
4916         my $commitdata = cmdoutput @git, qw(cat-file commit), $c->{Commit};
4917         $commitdata =~ m/\n\n/;
4918         $commitdata =~ $`;
4919         my @parents = ($commitdata =~ m/^parent (\w+)$/gm);
4920         @parents = map { { Commit => $_, Child => $c } } @parents;
4921
4922         $not->($c, "root commit") if !@parents;
4923
4924         foreach my $p (@parents) {
4925             $p->{Nontrivial}= quiltify_trees_differ $p->{Commit},$c->{Commit};
4926         }
4927         my $ndiffers = grep { $_->{Nontrivial} } @parents;
4928         $not->($c, "merge ($ndiffers nontrivial parents)") if $ndiffers > 1;
4929
4930         foreach my $p (@parents) {
4931             printdebug "considering C=$c->{Commit} P=$p->{Commit}\n";
4932
4933             my @cmd= (@git, qw(diff-tree -r --name-only),
4934                       $p->{Commit},$c->{Commit}, qw(-- debian/patches .pc));
4935             my $patchstackchange = cmdoutput @cmd;
4936             if (length $patchstackchange) {
4937                 $patchstackchange =~ s/\n/,/g;
4938                 $not->($p, "changed $patchstackchange");
4939             }
4940
4941             printdebug " search queue P=$p->{Commit} ",
4942                 ($p->{Nontrivial} ? "NT" : "triv"),"\n";
4943             push @todo, $p;
4944         }
4945     }
4946
4947     if (!$sref_S) {
4948         printdebug "quiltify want to smash\n";
4949
4950         my $abbrev = sub {
4951             my $x = $_[0]{Commit};
4952             $x =~ s/(.*?[0-9a-z]{8})[0-9a-z]*$/$1/;
4953             return $x;
4954         };
4955         my $reportnot = sub {
4956             my ($notp) = @_;
4957             my $s = $abbrev->($notp);
4958             my $c = $notp->{Child};
4959             $s .= "..".$abbrev->($c) if $c;
4960             $s .= ": ".$notp->{Whynot};
4961             return $s;
4962         };
4963         if ($quilt_mode eq 'linear') {
4964             print STDERR "$us: quilt fixup cannot be linear.  Stopped at:\n";
4965             foreach my $notp (@nots) {
4966                 print STDERR "$us:  ", $reportnot->($notp), "\n";
4967             }
4968             print STDERR "$us: $_\n" foreach @$failsuggestion;
4969             fail "quilt fixup naive history linearisation failed.\n".
4970  "Use dpkg-source --commit by hand; or, --quilt=smash for one ugly patch";
4971         } elsif ($quilt_mode eq 'smash') {
4972         } elsif ($quilt_mode eq 'auto') {
4973             progress "quilt fixup cannot be linear, smashing...";
4974         } else {
4975             die "$quilt_mode ?";
4976         }
4977
4978         my $time = $ENV{'GIT_COMMITTER_DATE'} || time;
4979         $time =~ s/\s.*//; # trim timezone from GIT_COMMITTER_DATE
4980         my $ncommits = 3;
4981         my $msg = cmdoutput @git, qw(log), "-n$ncommits";
4982
4983         quiltify_dpkg_commit "auto-$version-$target-$time",
4984             (getfield $clogp, 'Maintainer'),
4985             "Automatically generated patch ($clogp->{Version})\n".
4986             "Last (up to) $ncommits git changes, FYI:\n\n". $msg;
4987         return;
4988     }
4989
4990     progress "quiltify linearisation planning successful, executing...";
4991
4992     for (my $p = $sref_S;
4993          my $c = $p->{Child};
4994          $p = $p->{Child}) {
4995         printdebug "quiltify traverse $p->{Commit}..$c->{Commit}\n";
4996         next unless $p->{Nontrivial};
4997
4998         my $cc = $c->{Commit};
4999
5000         my $commitdata = cmdoutput @git, qw(cat-file commit), $cc;
5001         $commitdata =~ m/\n\n/ or die "$c ?";
5002         $commitdata = $`;
5003         my $msg = $'; #';
5004         $commitdata =~ m/^author (.*) \d+ [-+0-9]+$/m or die "$cc ?";
5005         my $author = $1;
5006
5007         my $commitdate = cmdoutput
5008             @git, qw(log -n1 --pretty=format:%aD), $cc;
5009
5010         $msg =~ s/^(.*)\n*/$1\n/ or die "$cc $msg ?";
5011
5012         my $strip_nls = sub { $msg =~ s/\n+$//; $msg .= "\n"; };
5013         $strip_nls->();
5014
5015         my $title = $1;
5016         my $patchname;
5017         my $patchdir;
5018
5019         my $gbp_check_suitable = sub {
5020             $_ = shift;
5021             my ($what) = @_;
5022
5023             eval {
5024                 die "contains unexpected slashes\n" if m{//} || m{/$};
5025                 die "contains leading punctuation\n" if m{^\W} || m{/\W};
5026                 die "contains bad character(s)\n" if m{[^-a-z0-9_.+=~/]}i;
5027                 die "too long" if length > 200;
5028             };
5029             return $_ unless $@;
5030             print STDERR "quiltifying commit $cc:".
5031                 " ignoring/dropping Gbp-Pq $what: $@";
5032             return undef;
5033         };
5034
5035         if ($msg =~ s/^ (?: gbp(?:-pq)? : \s* name \s+ |
5036                            gbp-pq-name: \s* )
5037                        (\S+) \s* \n //ixm) {
5038             $patchname = $gbp_check_suitable->($1, 'Name');
5039         }
5040         if ($msg =~ s/^ (?: gbp(?:-pq)? : \s* topic \s+ |
5041                            gbp-pq-topic: \s* )
5042                        (\S+) \s* \n //ixm) {
5043             $patchdir = $gbp_check_suitable->($1, 'Topic');
5044         }
5045
5046         $strip_nls->();
5047
5048         if (!defined $patchname) {
5049             $patchname = $title;
5050             $patchname =~ s/[.:]$//;
5051             use Text::Iconv;
5052             eval {
5053                 my $converter = new Text::Iconv qw(UTF-8 ASCII//TRANSLIT);
5054                 my $translitname = $converter->convert($patchname);
5055                 die unless defined $translitname;
5056                 $patchname = $translitname;
5057             };
5058             print STDERR
5059                 "dgit: patch title transliteration error: $@"
5060                 if $@;
5061             $patchname =~ y/ A-Z/-a-z/;
5062             $patchname =~ y/-a-z0-9_.+=~//cd;
5063             $patchname =~ s/^\W/x-$&/;
5064             $patchname = substr($patchname,0,40);
5065         }
5066         if (!defined $patchdir) {
5067             $patchdir = '';
5068         }
5069         if (length $patchdir) {
5070             $patchname = "$patchdir/$patchname";
5071         }
5072         if ($patchname =~ m{^(.*)/}) {
5073             mkpath "debian/patches/$1";
5074         }
5075
5076         my $index;
5077         for ($index='';
5078              stat "debian/patches/$patchname$index";
5079              $index++) { }
5080         $!==ENOENT or die "$patchname$index $!";
5081
5082         runcmd @git, qw(checkout -q), $cc;
5083
5084         # We use the tip's changelog so that dpkg-source doesn't
5085         # produce complaining messages from dpkg-parsechangelog.  None
5086         # of the information dpkg-source gets from the changelog is
5087         # actually relevant - it gets put into the original message
5088         # which dpkg-source provides our stunt editor, and then
5089         # overwritten.
5090         runcmd @git, qw(checkout -q), $target, qw(debian/changelog);
5091
5092         quiltify_dpkg_commit "$patchname$index", $author, $msg,
5093             "Date: $commitdate\n".
5094             "X-Dgit-Generated: $clogp->{Version} $cc\n";
5095
5096         runcmd @git, qw(checkout -q), $cc, qw(debian/changelog);
5097     }
5098
5099     runcmd @git, qw(checkout -q master);
5100 }
5101
5102 sub build_maybe_quilt_fixup () {
5103     my ($format,$fopts) = get_source_format;
5104     return unless madformat_wantfixup $format;
5105     # sigh
5106
5107     check_for_vendor_patches();
5108
5109     if (quiltmode_splitbrain) {
5110         fail <<END unless access_cfg_tagformats_can_splitbrain;
5111 quilt mode $quilt_mode requires split view so server needs to support
5112  both "new" and "maint" tag formats, but config says it doesn't.
5113 END
5114     }
5115
5116     my $clogp = parsechangelog();
5117     my $headref = git_rev_parse('HEAD');
5118
5119     prep_ud();
5120     changedir $ud;
5121
5122     my $upstreamversion = upstreamversion $version;
5123
5124     if ($fopts->{'single-debian-patch'}) {
5125         quilt_fixup_singlepatch($clogp, $headref, $upstreamversion);
5126     } else {
5127         quilt_fixup_multipatch($clogp, $headref, $upstreamversion);
5128     }
5129
5130     die 'bug' if $split_brain && !$need_split_build_invocation;
5131
5132     changedir '../../../..';
5133     runcmd_ordryrun_local
5134         @git, qw(pull --ff-only -q .git/dgit/unpack/work master);
5135 }
5136
5137 sub quilt_fixup_mkwork ($) {
5138     my ($headref) = @_;
5139
5140     mkdir "work" or die $!;
5141     changedir "work";
5142     mktree_in_ud_here();
5143     runcmd @git, qw(reset -q --hard), $headref;
5144 }
5145
5146 sub quilt_fixup_linkorigs ($$) {
5147     my ($upstreamversion, $fn) = @_;
5148     # calls $fn->($leafname);
5149
5150     foreach my $f (<../../../../*>) { #/){
5151         my $b=$f; $b =~ s{.*/}{};
5152         {
5153             local ($debuglevel) = $debuglevel-1;
5154             printdebug "QF linkorigs $b, $f ?\n";
5155         }
5156         next unless is_orig_file_of_vsn $b, $upstreamversion;
5157         printdebug "QF linkorigs $b, $f Y\n";
5158         link_ltarget $f, $b or die "$b $!";
5159         $fn->($b);
5160     }
5161 }
5162
5163 sub quilt_fixup_delete_pc () {
5164     runcmd @git, qw(rm -rqf .pc);
5165     commit_admin <<END
5166 Commit removal of .pc (quilt series tracking data)
5167
5168 [dgit ($our_version) upgrade quilt-remove-pc]
5169 END
5170 }
5171
5172 sub quilt_fixup_singlepatch ($$$) {
5173     my ($clogp, $headref, $upstreamversion) = @_;
5174
5175     progress "starting quiltify (single-debian-patch)";
5176
5177     # dpkg-source --commit generates new patches even if
5178     # single-debian-patch is in debian/source/options.  In order to
5179     # get it to generate debian/patches/debian-changes, it is
5180     # necessary to build the source package.
5181
5182     quilt_fixup_linkorigs($upstreamversion, sub { });
5183     quilt_fixup_mkwork($headref);
5184
5185     rmtree("debian/patches");
5186
5187     runcmd @dpkgsource, qw(-b .);
5188     changedir "..";
5189     runcmd @dpkgsource, qw(-x), (srcfn $version, ".dsc");
5190     rename srcfn("$upstreamversion", "/debian/patches"),
5191            "work/debian/patches";
5192
5193     changedir "work";
5194     commit_quilty_patch();
5195 }
5196
5197 sub quilt_make_fake_dsc ($) {
5198     my ($upstreamversion) = @_;
5199
5200     my $fakeversion="$upstreamversion-~~DGITFAKE";
5201
5202     my $fakedsc=new IO::File 'fake.dsc', '>' or die $!;
5203     print $fakedsc <<END or die $!;
5204 Format: 3.0 (quilt)
5205 Source: $package
5206 Version: $fakeversion
5207 Files:
5208 END
5209
5210     my $dscaddfile=sub {
5211         my ($b) = @_;
5212
5213         my $md = new Digest::MD5;
5214
5215         my $fh = new IO::File $b, '<' or die "$b $!";
5216         stat $fh or die $!;
5217         my $size = -s _;
5218
5219         $md->addfile($fh);
5220         print $fakedsc " ".$md->hexdigest." $size $b\n" or die $!;
5221     };
5222
5223     quilt_fixup_linkorigs($upstreamversion, $dscaddfile);
5224
5225     my @files=qw(debian/source/format debian/rules
5226                  debian/control debian/changelog);
5227     foreach my $maybe (qw(debian/patches debian/source/options
5228                           debian/tests/control)) {
5229         next unless stat_exists "../../../$maybe";
5230         push @files, $maybe;
5231     }
5232
5233     my $debtar= srcfn $fakeversion,'.debian.tar.gz';
5234     runcmd qw(env GZIP=-1n tar -zcf), "./$debtar", qw(-C ../../..), @files;
5235
5236     $dscaddfile->($debtar);
5237     close $fakedsc or die $!;
5238 }
5239
5240 sub quilt_check_splitbrain_cache ($$) {
5241     my ($headref, $upstreamversion) = @_;
5242     # Called only if we are in (potentially) split brain mode.
5243     # Called in $ud.
5244     # Computes the cache key and looks in the cache.
5245     # Returns ($dgit_view_commitid, $cachekey) or (undef, $cachekey)
5246
5247     my $splitbrain_cachekey;
5248
5249     progress
5250  "dgit: split brain (separate dgit view) may be needed (--quilt=$quilt_mode).";
5251     # we look in the reflog of dgit-intern/quilt-cache
5252     # we look for an entry whose message is the key for the cache lookup
5253     my @cachekey = (qw(dgit), $our_version);
5254     push @cachekey, $upstreamversion;
5255     push @cachekey, $quilt_mode;
5256     push @cachekey, $headref;
5257
5258     push @cachekey, hashfile('fake.dsc');
5259
5260     my $srcshash = Digest::SHA->new(256);
5261     my %sfs = ( %INC, '$0(dgit)' => $0 );
5262     foreach my $sfk (sort keys %sfs) {
5263         next unless $sfk =~ m/^\$0\b/ || $sfk =~ m{^Debian/Dgit\b};
5264         $srcshash->add($sfk,"  ");
5265         $srcshash->add(hashfile($sfs{$sfk}));
5266         $srcshash->add("\n");
5267     }
5268     push @cachekey, $srcshash->hexdigest();
5269     $splitbrain_cachekey = "@cachekey";
5270
5271     my @cmd = (@git, qw(log -g), '--pretty=format:%H %gs',
5272                $splitbraincache);
5273     printdebug "splitbrain cachekey $splitbrain_cachekey\n";
5274     debugcmd "|(probably)",@cmd;
5275     my $child = open GC, "-|";  defined $child or die $!;
5276     if (!$child) {
5277         chdir '../../..' or die $!;
5278         if (!stat ".git/logs/refs/$splitbraincache") {
5279             $! == ENOENT or die $!;
5280             printdebug ">(no reflog)\n";
5281             exit 0;
5282         }
5283         exec @cmd; die $!;
5284     }
5285     while (<GC>) {
5286         chomp;
5287         printdebug ">| ", $_, "\n" if $debuglevel > 1;
5288         next unless m/^(\w+) (\S.*\S)$/ && $2 eq $splitbrain_cachekey;
5289
5290         my $cachehit = $1;
5291         quilt_fixup_mkwork($headref);
5292         my $saved = maybe_split_brain_save $headref, $cachehit, "cache-hit";
5293         if ($cachehit ne $headref) {
5294             progress "dgit view: found cached ($saved)";
5295             runcmd @git, qw(checkout -q -b dgit-view), $cachehit;
5296             $split_brain = 1;
5297             return ($cachehit, $splitbrain_cachekey);
5298         }
5299         progress "dgit view: found cached, no changes required";
5300         return ($headref, $splitbrain_cachekey);
5301     }
5302     die $! if GC->error;
5303     failedcmd unless close GC;
5304
5305     printdebug "splitbrain cache miss\n";
5306     return (undef, $splitbrain_cachekey);
5307 }
5308
5309 sub quilt_fixup_multipatch ($$$) {
5310     my ($clogp, $headref, $upstreamversion) = @_;
5311
5312     progress "examining quilt state (multiple patches, $quilt_mode mode)";
5313
5314     # Our objective is:
5315     #  - honour any existing .pc in case it has any strangeness
5316     #  - determine the git commit corresponding to the tip of
5317     #    the patch stack (if there is one)
5318     #  - if there is such a git commit, convert each subsequent
5319     #    git commit into a quilt patch with dpkg-source --commit
5320     #  - otherwise convert all the differences in the tree into
5321     #    a single git commit
5322     #
5323     # To do this we:
5324
5325     # Our git tree doesn't necessarily contain .pc.  (Some versions of
5326     # dgit would include the .pc in the git tree.)  If there isn't
5327     # one, we need to generate one by unpacking the patches that we
5328     # have.
5329     #
5330     # We first look for a .pc in the git tree.  If there is one, we
5331     # will use it.  (This is not the normal case.)
5332     #
5333     # Otherwise need to regenerate .pc so that dpkg-source --commit
5334     # can work.  We do this as follows:
5335     #     1. Collect all relevant .orig from parent directory
5336     #     2. Generate a debian.tar.gz out of
5337     #         debian/{patches,rules,source/format,source/options}
5338     #     3. Generate a fake .dsc containing just these fields:
5339     #          Format Source Version Files
5340     #     4. Extract the fake .dsc
5341     #        Now the fake .dsc has a .pc directory.
5342     # (In fact we do this in every case, because in future we will
5343     # want to search for a good base commit for generating patches.)
5344     #
5345     # Then we can actually do the dpkg-source --commit
5346     #     1. Make a new working tree with the same object
5347     #        store as our main tree and check out the main
5348     #        tree's HEAD.
5349     #     2. Copy .pc from the fake's extraction, if necessary
5350     #     3. Run dpkg-source --commit
5351     #     4. If the result has changes to debian/, then
5352     #          - git add them them
5353     #          - git add .pc if we had a .pc in-tree
5354     #          - git commit
5355     #     5. If we had a .pc in-tree, delete it, and git commit
5356     #     6. Back in the main tree, fast forward to the new HEAD
5357
5358     # Another situation we may have to cope with is gbp-style
5359     # patches-unapplied trees.
5360     #
5361     # We would want to detect these, so we know to escape into
5362     # quilt_fixup_gbp.  However, this is in general not possible.
5363     # Consider a package with a one patch which the dgit user reverts
5364     # (with git revert or the moral equivalent).
5365     #
5366     # That is indistinguishable in contents from a patches-unapplied
5367     # tree.  And looking at the history to distinguish them is not
5368     # useful because the user might have made a confusing-looking git
5369     # history structure (which ought to produce an error if dgit can't
5370     # cope, not a silent reintroduction of an unwanted patch).
5371     #
5372     # So gbp users will have to pass an option.  But we can usually
5373     # detect their failure to do so: if the tree is not a clean
5374     # patches-applied tree, quilt linearisation fails, but the tree
5375     # _is_ a clean patches-unapplied tree, we can suggest that maybe
5376     # they want --quilt=unapplied.
5377     #
5378     # To help detect this, when we are extracting the fake dsc, we
5379     # first extract it with --skip-patches, and then apply the patches
5380     # afterwards with dpkg-source --before-build.  That lets us save a
5381     # tree object corresponding to .origs.
5382
5383     my $splitbrain_cachekey;
5384
5385     quilt_make_fake_dsc($upstreamversion);
5386
5387     if (quiltmode_splitbrain()) {
5388         my $cachehit;
5389         ($cachehit, $splitbrain_cachekey) =
5390             quilt_check_splitbrain_cache($headref, $upstreamversion);
5391         return if $cachehit;
5392     }
5393
5394     runcmd qw(sh -ec),
5395         'exec dpkg-source --no-check --skip-patches -x fake.dsc >/dev/null';
5396
5397     my $fakexdir= $package.'-'.(stripepoch $upstreamversion);
5398     rename $fakexdir, "fake" or die "$fakexdir $!";
5399
5400     changedir 'fake';
5401
5402     remove_stray_gits("source package");
5403     mktree_in_ud_here();
5404
5405     rmtree '.pc';
5406
5407     my $unapplied=git_add_write_tree();
5408     printdebug "fake orig tree object $unapplied\n";
5409
5410     ensuredir '.pc';
5411
5412     my @bbcmd = (qw(sh -ec), 'exec dpkg-source --before-build . >/dev/null');
5413     $!=0; $?=-1;
5414     if (system @bbcmd) {
5415         failedcmd @bbcmd if $? < 0;
5416         fail <<END;
5417 failed to apply your git tree's patch stack (from debian/patches/) to
5418  the corresponding upstream tarball(s).  Your source tree and .orig
5419  are probably too inconsistent.  dgit can only fix up certain kinds of
5420  anomaly (depending on the quilt mode).  See --quilt= in dgit(1).
5421 END
5422     }
5423
5424     changedir '..';
5425
5426     quilt_fixup_mkwork($headref);
5427
5428     my $mustdeletepc=0;
5429     if (stat_exists ".pc") {
5430         -d _ or die;
5431         progress "Tree already contains .pc - will use it then delete it.";
5432         $mustdeletepc=1;
5433     } else {
5434         rename '../fake/.pc','.pc' or die $!;
5435     }
5436
5437     changedir '../fake';
5438     rmtree '.pc';
5439     my $oldtiptree=git_add_write_tree();
5440     printdebug "fake o+d/p tree object $unapplied\n";
5441     changedir '../work';
5442
5443
5444     # We calculate some guesswork now about what kind of tree this might
5445     # be.  This is mostly for error reporting.
5446
5447     my %editedignores;
5448     my @unrepres;
5449     my $diffbits = {
5450         # H = user's HEAD
5451         # O = orig, without patches applied
5452         # A = "applied", ie orig with H's debian/patches applied
5453         O2H => quiltify_trees_differ($unapplied,$headref,   1,
5454                                      \%editedignores, \@unrepres),
5455         H2A => quiltify_trees_differ($headref,  $oldtiptree,1),
5456         O2A => quiltify_trees_differ($unapplied,$oldtiptree,1),
5457     };
5458
5459     my @dl;
5460     foreach my $b (qw(01 02)) {
5461         foreach my $v (qw(O2H O2A H2A)) {
5462             push @dl, ($diffbits->{$v} & $b) ? '##' : '==';
5463         }
5464     }
5465     printdebug "differences \@dl @dl.\n";
5466
5467     progress sprintf
5468 "$us: base trees orig=%.20s o+d/p=%.20s",
5469               $unapplied, $oldtiptree;
5470     progress sprintf
5471 "$us: quilt differences: src:  %s orig %s     gitignores:  %s orig %s\n".
5472 "$us: quilt differences:      HEAD %s o+d/p               HEAD %s o+d/p",
5473                              $dl[0], $dl[1],              $dl[3], $dl[4],
5474                                  $dl[2],                     $dl[5];
5475
5476     if (@unrepres) {
5477         print STDERR "dgit:  cannot represent change: $_->[1]: $_->[0]\n"
5478             foreach @unrepres;
5479         forceable_fail [qw(unrepresentable)], <<END;
5480 HEAD has changes to .orig[s] which are not representable by `3.0 (quilt)'
5481 END
5482     }
5483
5484     my @failsuggestion;
5485     if (!($diffbits->{O2H} & $diffbits->{O2A})) {
5486         push @failsuggestion, "This might be a patches-unapplied branch.";
5487     }  elsif (!($diffbits->{H2A} & $diffbits->{O2A})) {
5488         push @failsuggestion, "This might be a patches-applied branch.";
5489     }
5490     push @failsuggestion, "Maybe you need to specify one of".
5491         " --[quilt=]gbp --[quilt=]dpm --quilt=unapplied ?";
5492
5493     if (quiltmode_splitbrain()) {
5494         quiltify_splitbrain($clogp, $unapplied, $headref,
5495                             $diffbits, \%editedignores,
5496                             $splitbrain_cachekey);
5497         return;
5498     }
5499
5500     progress "starting quiltify (multiple patches, $quilt_mode mode)";
5501     quiltify($clogp,$headref,$oldtiptree,\@failsuggestion);
5502
5503     if (!open P, '>>', ".pc/applied-patches") {
5504         $!==&ENOENT or die $!;
5505     } else {
5506         close P;
5507     }
5508
5509     commit_quilty_patch();
5510
5511     if ($mustdeletepc) {
5512         quilt_fixup_delete_pc();
5513     }
5514 }
5515
5516 sub quilt_fixup_editor () {
5517     my $descfn = $ENV{$fakeeditorenv};
5518     my $editing = $ARGV[$#ARGV];
5519     open I1, '<', $descfn or die "$descfn: $!";
5520     open I2, '<', $editing or die "$editing: $!";
5521     unlink $editing or die "$editing: $!";
5522     open O, '>', $editing or die "$editing: $!";
5523     while (<I1>) { print O or die $!; } I1->error and die $!;
5524     my $copying = 0;
5525     while (<I2>) {
5526         $copying ||= m/^\-\-\- /;
5527         next unless $copying;
5528         print O or die $!;
5529     }
5530     I2->error and die $!;
5531     close O or die $1;
5532     exit 0;
5533 }
5534
5535 sub maybe_apply_patches_dirtily () {
5536     return unless $quilt_mode =~ m/gbp|unapplied/;
5537     print STDERR <<END or die $!;
5538
5539 dgit: Building, or cleaning with rules target, in patches-unapplied tree.
5540 dgit: Have to apply the patches - making the tree dirty.
5541 dgit: (Consider specifying --clean=git and (or) using dgit sbuild.)
5542
5543 END
5544     $patches_applied_dirtily = 01;
5545     $patches_applied_dirtily |= 02 unless stat_exists '.pc';
5546     runcmd qw(dpkg-source --before-build .);
5547 }
5548
5549 sub maybe_unapply_patches_again () {
5550     progress "dgit: Unapplying patches again to tidy up the tree."
5551         if $patches_applied_dirtily;
5552     runcmd qw(dpkg-source --after-build .)
5553         if $patches_applied_dirtily & 01;
5554     rmtree '.pc'
5555         if $patches_applied_dirtily & 02;
5556     $patches_applied_dirtily = 0;
5557 }
5558
5559 #----- other building -----
5560
5561 our $clean_using_builder;
5562 # ^ tree is to be cleaned by dpkg-source's builtin idea that it should
5563 #   clean the tree before building (perhaps invoked indirectly by
5564 #   whatever we are using to run the build), rather than separately
5565 #   and explicitly by us.
5566
5567 sub clean_tree () {
5568     return if $clean_using_builder;
5569     if ($cleanmode eq 'dpkg-source') {
5570         maybe_apply_patches_dirtily();
5571         runcmd_ordryrun_local @dpkgbuildpackage, qw(-T clean);
5572     } elsif ($cleanmode eq 'dpkg-source-d') {
5573         maybe_apply_patches_dirtily();
5574         runcmd_ordryrun_local @dpkgbuildpackage, qw(-d -T clean);
5575     } elsif ($cleanmode eq 'git') {
5576         runcmd_ordryrun_local @git, qw(clean -xdf);
5577     } elsif ($cleanmode eq 'git-ff') {
5578         runcmd_ordryrun_local @git, qw(clean -xdff);
5579     } elsif ($cleanmode eq 'check') {
5580         my $leftovers = cmdoutput @git, qw(clean -xdn);
5581         if (length $leftovers) {
5582             print STDERR $leftovers, "\n" or die $!;
5583             fail "tree contains uncommitted files and --clean=check specified";
5584         }
5585     } elsif ($cleanmode eq 'none') {
5586     } else {
5587         die "$cleanmode ?";
5588     }
5589 }
5590
5591 sub cmd_clean () {
5592     badusage "clean takes no additional arguments" if @ARGV;
5593     notpushing();
5594     clean_tree();
5595     maybe_unapply_patches_again();
5596 }
5597
5598 sub build_prep_early () {
5599     our $build_prep_early_done //= 0;
5600     return if $build_prep_early_done++;
5601     notpushing();
5602     badusage "-p is not allowed when building" if defined $package;
5603     my $clogp = parsechangelog();
5604     $isuite = getfield $clogp, 'Distribution';
5605     $package = getfield $clogp, 'Source';
5606     $version = getfield $clogp, 'Version';
5607     check_not_dirty();
5608 }
5609
5610 sub build_prep () {
5611     build_prep_early();
5612     clean_tree();
5613     build_maybe_quilt_fixup();
5614     if ($rmchanges) {
5615         my $pat = changespat $version;
5616         foreach my $f (glob "$buildproductsdir/$pat") {
5617             if (act_local()) {
5618                 unlink $f or fail "remove old changes file $f: $!";
5619             } else {
5620                 progress "would remove $f";
5621             }
5622         }
5623     }
5624 }
5625
5626 sub changesopts_initial () {
5627     my @opts =@changesopts[1..$#changesopts];
5628 }
5629
5630 sub changesopts_version () {
5631     if (!defined $changes_since_version) {
5632         my @vsns = archive_query('archive_query');
5633         my @quirk = access_quirk();
5634         if ($quirk[0] eq 'backports') {
5635             local $isuite = $quirk[2];
5636             local $csuite;
5637             canonicalise_suite();
5638             push @vsns, archive_query('archive_query');
5639         }
5640         if (@vsns) {
5641             @vsns = map { $_->[0] } @vsns;
5642             @vsns = sort { -version_compare($a, $b) } @vsns;
5643             $changes_since_version = $vsns[0];
5644             progress "changelog will contain changes since $vsns[0]";
5645         } else {
5646             $changes_since_version = '_';
5647             progress "package seems new, not specifying -v<version>";
5648         }
5649     }
5650     if ($changes_since_version ne '_') {
5651         return ("-v$changes_since_version");
5652     } else {
5653         return ();
5654     }
5655 }
5656
5657 sub changesopts () {
5658     return (changesopts_initial(), changesopts_version());
5659 }
5660
5661 sub massage_dbp_args ($;$) {
5662     my ($cmd,$xargs) = @_;
5663     # We need to:
5664     #
5665     #  - if we're going to split the source build out so we can
5666     #    do strange things to it, massage the arguments to dpkg-buildpackage
5667     #    so that the main build doessn't build source (or add an argument
5668     #    to stop it building source by default).
5669     #
5670     #  - add -nc to stop dpkg-source cleaning the source tree,
5671     #    unless we're not doing a split build and want dpkg-source
5672     #    as cleanmode, in which case we can do nothing
5673     #
5674     # return values:
5675     #    0 - source will NOT need to be built separately by caller
5676     #   +1 - source will need to be built separately by caller
5677     #   +2 - source will need to be built separately by caller AND
5678     #        dpkg-buildpackage should not in fact be run at all!
5679     debugcmd '#massaging#', @$cmd if $debuglevel>1;
5680 #print STDERR "MASS0 ",Dumper($cmd, $xargs, $need_split_build_invocation);
5681     if ($cleanmode eq 'dpkg-source' && !$need_split_build_invocation) {
5682         $clean_using_builder = 1;
5683         return 0;
5684     }
5685     # -nc has the side effect of specifying -b if nothing else specified
5686     # and some combinations of -S, -b, et al, are errors, rather than
5687     # later simply overriding earlie.  So we need to:
5688     #  - search the command line for these options
5689     #  - pick the last one
5690     #  - perhaps add our own as a default
5691     #  - perhaps adjust it to the corresponding non-source-building version
5692     my $dmode = '-F';
5693     foreach my $l ($cmd, $xargs) {
5694         next unless $l;
5695         @$l = grep { !(m/^-[SgGFABb]$/s and $dmode=$_) } @$l;
5696     }
5697     push @$cmd, '-nc';
5698 #print STDERR "MASS1 ",Dumper($cmd, $xargs, $dmode);
5699     my $r = 0;
5700     if ($need_split_build_invocation) {
5701         printdebug "massage split $dmode.\n";
5702         $r = $dmode =~ m/[S]/     ? +2 :
5703              $dmode =~ y/gGF/ABb/ ? +1 :
5704              $dmode =~ m/[ABb]/   ?  0 :
5705              die "$dmode ?";
5706     }
5707     printdebug "massage done $r $dmode.\n";
5708     push @$cmd, $dmode;
5709 #print STDERR "MASS2 ",Dumper($cmd, $xargs, $r);
5710     return $r;
5711 }
5712
5713 sub in_parent (&) {
5714     my ($fn) = @_;
5715     my $wasdir = must_getcwd();
5716     changedir "..";
5717     $fn->();
5718     changedir $wasdir;
5719 }
5720
5721 sub postbuild_mergechanges ($) { # must run with CWD=.. (eg in in_parent)
5722     my ($msg_if_onlyone) = @_;
5723     # If there is only one .changes file, fail with $msg_if_onlyone,
5724     # or if that is undef, be a no-op.
5725     # Returns the changes file to report to the user.
5726     my $pat = changespat $version;
5727     my @changesfiles = glob $pat;
5728     @changesfiles = sort {
5729         ($b =~ m/_source\.changes$/ <=> $a =~ m/_source\.changes$/)
5730             or $a cmp $b
5731     } @changesfiles;
5732     my $result;
5733     if (@changesfiles==1) {
5734         fail <<END.$msg_if_onlyone if defined $msg_if_onlyone;
5735 only one changes file from build (@changesfiles)
5736 END
5737         $result = $changesfiles[0];
5738     } elsif (@changesfiles==2) {
5739         my $binchanges = parsecontrol($changesfiles[1], "binary changes file");
5740         foreach my $l (split /\n/, getfield $binchanges, 'Files') {
5741             fail "$l found in binaries changes file $binchanges"
5742                 if $l =~ m/\.dsc$/;
5743         }
5744         runcmd_ordryrun_local @mergechanges, @changesfiles;
5745         my $multichanges = changespat $version,'multi';
5746         if (act_local()) {
5747             stat_exists $multichanges or fail "$multichanges: $!";
5748             foreach my $cf (glob $pat) {
5749                 next if $cf eq $multichanges;
5750                 rename "$cf", "$cf.inmulti" or fail "$cf\{,.inmulti}: $!";
5751             }
5752         }
5753         $result = $multichanges;
5754     } else {
5755         fail "wrong number of different changes files (@changesfiles)";
5756     }
5757     printdone "build successful, results in $result\n" or die $!;
5758 }
5759
5760 sub midbuild_checkchanges () {
5761     my $pat = changespat $version;
5762     return if $rmchanges;
5763     my @unwanted = map { s#^\.\./##; $_; } glob "../$pat";
5764     @unwanted = grep { $_ ne changespat $version,'source' } @unwanted;
5765     fail <<END
5766 changes files other than source matching $pat already present; building would result in ambiguity about the intended results.
5767 Suggest you delete @unwanted.
5768 END
5769         if @unwanted;
5770 }
5771
5772 sub midbuild_checkchanges_vanilla ($) {
5773     my ($wantsrc) = @_;
5774     midbuild_checkchanges() if $wantsrc == 1;
5775 }
5776
5777 sub postbuild_mergechanges_vanilla ($) {
5778     my ($wantsrc) = @_;
5779     if ($wantsrc == 1) {
5780         in_parent {
5781             postbuild_mergechanges(undef);
5782         };
5783     } else {
5784         printdone "build successful\n";
5785     }
5786 }
5787
5788 sub cmd_build {
5789     build_prep_early();
5790     my @dbp = (@dpkgbuildpackage, qw(-us -uc), changesopts_initial(), @ARGV);
5791     my $wantsrc = massage_dbp_args \@dbp;
5792     if ($wantsrc > 0) {
5793         build_source();
5794         midbuild_checkchanges_vanilla $wantsrc;
5795     } else {
5796         build_prep();
5797     }
5798     if ($wantsrc < 2) {
5799         push @dbp, changesopts_version();
5800         maybe_apply_patches_dirtily();
5801         runcmd_ordryrun_local @dbp;
5802     }
5803     maybe_unapply_patches_again();
5804     postbuild_mergechanges_vanilla $wantsrc;
5805 }
5806
5807 sub pre_gbp_build {
5808     $quilt_mode //= 'gbp';
5809 }
5810
5811 sub cmd_gbp_build {
5812     build_prep_early();
5813
5814     # gbp can make .origs out of thin air.  In my tests it does this
5815     # even for a 1.0 format package, with no origs present.  So I
5816     # guess it keys off just the version number.  We don't know
5817     # exactly what .origs ought to exist, but let's assume that we
5818     # should run gbp if: the version has an upstream part and the main
5819     # orig is absent.
5820     my $upstreamversion = upstreamversion $version;
5821     my $origfnpat = srcfn $upstreamversion, '.orig.tar.*';
5822     my $gbp_make_orig = $version =~ m/-/ && !(() = glob "../$origfnpat");
5823
5824     if ($gbp_make_orig) {
5825         clean_tree();
5826         $cleanmode = 'none'; # don't do it again
5827         $need_split_build_invocation = 1;
5828     }
5829
5830     my @dbp = @dpkgbuildpackage;
5831
5832     my $wantsrc = massage_dbp_args \@dbp, \@ARGV;
5833
5834     if (!length $gbp_build[0]) {
5835         if (length executable_on_path('git-buildpackage')) {
5836             $gbp_build[0] = qw(git-buildpackage);
5837         } else {
5838             $gbp_build[0] = 'gbp buildpackage';
5839         }
5840     }
5841     my @cmd = opts_opt_multi_cmd @gbp_build;
5842
5843     push @cmd, (qw(-us -uc --git-no-sign-tags), "--git-builder=@dbp");
5844
5845     if ($gbp_make_orig) {
5846         ensuredir '.git/dgit';
5847         my $ok = '.git/dgit/origs-gen-ok';
5848         unlink $ok or $!==&ENOENT or die $!;
5849         my @origs_cmd = @cmd;
5850         push @origs_cmd, qw(--git-cleaner=true);
5851         push @origs_cmd, "--git-prebuild=touch $ok .git/dgit/no-such-dir/ok";
5852         push @origs_cmd, @ARGV;
5853         if (act_local()) {
5854             debugcmd @origs_cmd;
5855             system @origs_cmd;
5856             do { local $!; stat_exists $ok; }
5857                 or failedcmd @origs_cmd;
5858         } else {
5859             dryrun_report @origs_cmd;
5860         }
5861     }
5862
5863     if ($wantsrc > 0) {
5864         build_source();
5865         midbuild_checkchanges_vanilla $wantsrc;
5866     } else {
5867         if (!$clean_using_builder) {
5868             push @cmd, '--git-cleaner=true';
5869         }
5870         build_prep();
5871     }
5872     maybe_unapply_patches_again();
5873     if ($wantsrc < 2) {
5874         push @cmd, changesopts();
5875         runcmd_ordryrun_local @cmd, @ARGV;
5876     }
5877     postbuild_mergechanges_vanilla $wantsrc;
5878 }
5879 sub cmd_git_build { cmd_gbp_build(); } # compatibility with <= 1.0
5880
5881 sub build_source {
5882     build_prep_early();
5883     my $our_cleanmode = $cleanmode;
5884     if ($need_split_build_invocation) {
5885         # Pretend that clean is being done some other way.  This
5886         # forces us not to try to use dpkg-buildpackage to clean and
5887         # build source all in one go; and instead we run dpkg-source
5888         # (and build_prep() will do the clean since $clean_using_builder
5889         # is false).
5890         $our_cleanmode = 'ELSEWHERE';
5891     }
5892     if ($our_cleanmode =~ m/^dpkg-source/) {
5893         # dpkg-source invocation (below) will clean, so build_prep shouldn't
5894         $clean_using_builder = 1;
5895     }
5896     build_prep();
5897     $sourcechanges = changespat $version,'source';
5898     if (act_local()) {
5899         unlink "../$sourcechanges" or $!==ENOENT
5900             or fail "remove $sourcechanges: $!";
5901     }
5902     $dscfn = dscfn($version);
5903     if ($our_cleanmode eq 'dpkg-source') {
5904         maybe_apply_patches_dirtily();
5905         runcmd_ordryrun_local @dpkgbuildpackage, qw(-us -uc -S),
5906             changesopts();
5907     } elsif ($our_cleanmode eq 'dpkg-source-d') {
5908         maybe_apply_patches_dirtily();
5909         runcmd_ordryrun_local @dpkgbuildpackage, qw(-us -uc -S -d),
5910             changesopts();
5911     } else {
5912         my @cmd = (@dpkgsource, qw(-b --));
5913         if ($split_brain) {
5914             changedir $ud;
5915             runcmd_ordryrun_local @cmd, "work";
5916             my @udfiles = <${package}_*>;
5917             changedir "../../..";
5918             foreach my $f (@udfiles) {
5919                 printdebug "source copy, found $f\n";
5920                 next unless
5921                     $f eq $dscfn or
5922                     ($f =~ m/\.debian\.tar(?:\.\w+)$/ &&
5923                      $f eq srcfn($version, $&));
5924                 printdebug "source copy, found $f - renaming\n";
5925                 rename "$ud/$f", "../$f" or $!==ENOENT
5926                     or fail "put in place new source file ($f): $!";
5927             }
5928         } else {
5929             my $pwd = must_getcwd();
5930             my $leafdir = basename $pwd;
5931             changedir "..";
5932             runcmd_ordryrun_local @cmd, $leafdir;
5933             changedir $pwd;
5934         }
5935         runcmd_ordryrun_local qw(sh -ec),
5936             'exec >$1; shift; exec "$@"','x',
5937             "../$sourcechanges",
5938             @dpkggenchanges, qw(-S), changesopts();
5939     }
5940 }
5941
5942 sub cmd_build_source {
5943     build_prep_early();
5944     badusage "build-source takes no additional arguments" if @ARGV;
5945     build_source();
5946     maybe_unapply_patches_again();
5947     printdone "source built, results in $dscfn and $sourcechanges";
5948 }
5949
5950 sub cmd_sbuild {
5951     build_source();
5952     midbuild_checkchanges();
5953     in_parent {
5954         if (act_local()) {
5955             stat_exists $dscfn or fail "$dscfn (in parent directory): $!";
5956             stat_exists $sourcechanges
5957                 or fail "$sourcechanges (in parent directory): $!";
5958         }
5959         runcmd_ordryrun_local @sbuild, qw(-d), $isuite, @ARGV, $dscfn;
5960     };
5961     maybe_unapply_patches_again();
5962     in_parent {
5963         postbuild_mergechanges(<<END);
5964 perhaps you need to pass -A ?  (sbuild's default is to build only
5965 arch-specific binaries; dgit 1.4 used to override that.)
5966 END
5967     };
5968 }
5969
5970 sub cmd_quilt_fixup {
5971     badusage "incorrect arguments to dgit quilt-fixup" if @ARGV;
5972     build_prep_early();
5973     clean_tree();
5974     build_maybe_quilt_fixup();
5975 }
5976
5977 sub cmd_import_dsc {
5978     my $needsig = 0;
5979
5980     while (@ARGV) {
5981         last unless $ARGV[0] =~ m/^-/;
5982         $_ = shift @ARGV;
5983         last if m/^--?$/;
5984         if (m/^--require-valid-signature$/) {
5985             $needsig = 1;
5986         } else {
5987             badusage "unknown dgit import-dsc sub-option \`$_'";
5988         }
5989     }
5990
5991     badusage "usage: dgit import-dsc .../PATH/TO/.DSC BRANCH" unless @ARGV==2;
5992     my ($dscfn, $dstbranch) = @ARGV;
5993
5994     badusage "dry run makes no sense with import-dsc" unless act_local();
5995
5996     my $force = $dstbranch =~ s/^\+//   ? +1 :
5997                 $dstbranch =~ s/^\.\.// ? -1 :
5998                                            0;
5999     my $info = $force ? " $&" : '';
6000     $info = "$dscfn$info";
6001
6002     my $specbranch = $dstbranch;
6003     $dstbranch = "refs/heads/$dstbranch" unless $dstbranch =~ m#^refs/#;
6004     $dstbranch = cmdoutput @git, qw(check-ref-format --normalize), $dstbranch;
6005
6006     my @symcmd = (@git, qw(symbolic-ref -q HEAD));
6007     my $chead = cmdoutput_errok @symcmd;
6008     defined $chead or $?==256 or failedcmd @symcmd;
6009
6010     fail "$dstbranch is checked out - will not update it"
6011         if defined $chead and $chead eq $dstbranch;
6012
6013     my $oldhash = git_get_ref $dstbranch;
6014
6015     open D, "<", $dscfn or fail "open import .dsc ($dscfn): $!";
6016     $dscdata = do { local $/ = undef; <D>; };
6017     D->error and fail "read $dscfn: $!";
6018     close C;
6019
6020     # we don't normally need this so import it here
6021     use Dpkg::Source::Package;
6022     my $dp = new Dpkg::Source::Package filename => $dscfn,
6023         require_valid_signature => $needsig;
6024     {
6025         local $SIG{__WARN__} = sub {
6026             print STDERR $_[0];
6027             return unless $needsig;
6028             fail "import-dsc signature check failed";
6029         };
6030         if (!$dp->is_signed()) {
6031             warn "$us: warning: importing unsigned .dsc\n";
6032         } else {
6033             my $r = $dp->check_signature();
6034             die "->check_signature => $r" if $needsig && $r;
6035         }
6036     }
6037
6038     parse_dscdata();
6039
6040     $package = getfield $dsc, 'Source';
6041
6042     parse_dsc_field($dsc, "Dgit metadata in .dsc")
6043         unless forceing [qw(import-dsc-with-dgit-field)];
6044
6045     if (defined $dsc_hash) {
6046         progress "dgit: import-dsc of .dsc with Dgit field, using git hash";
6047         resolve_dsc_field_commit undef, undef;
6048     }
6049     if (defined $dsc_hash) {
6050         my @cmd = (qw(sh -ec),
6051                    "echo $dsc_hash | git cat-file --batch-check");
6052         my $objgot = cmdoutput @cmd;
6053         if ($objgot =~ m#^\w+ missing\b#) {
6054             fail <<END
6055 .dsc contains Dgit field referring to object $dsc_hash
6056 Your git tree does not have that object.  Try `git fetch' from a
6057 plausible server (browse.dgit.d.o? alioth?), and try the import-dsc again.
6058 END
6059         }
6060         if ($oldhash && !is_fast_fwd $oldhash, $dsc_hash) {
6061             if ($force > 0) {
6062                 progress "Not fast forward, forced update.";
6063             } else {
6064                 fail "Not fast forward to $dsc_hash";
6065             }
6066         }
6067         @cmd = (@git, qw(update-ref -m), "dgit import-dsc (Dgit): $info",
6068                 $dstbranch, $dsc_hash);
6069         runcmd @cmd;
6070         progress "dgit: import-dsc updated git ref $dstbranch";
6071         return 0;
6072     }
6073
6074     fail <<END
6075 Branch $dstbranch already exists
6076 Specify ..$specbranch for a pseudo-merge, binding in existing history
6077 Specify  +$specbranch to overwrite, discarding existing history
6078 END
6079         if $oldhash && !$force;
6080
6081     my @dfi = dsc_files_info();
6082     foreach my $fi (@dfi) {
6083         my $f = $fi->{Filename};
6084         my $here = "../$f";
6085         next if lstat $here;
6086         fail "stat $here: $!" unless $! == ENOENT;
6087         my $there = $dscfn;
6088         if ($dscfn =~ m#^(?:\./+)?\.\./+#) {
6089             $there = $';
6090         } elsif ($dscfn =~ m#^/#) {
6091             $there = $dscfn;
6092         } else {
6093             fail "cannot import $dscfn which seems to be inside working tree!";
6094         }
6095         $there =~ s#/+[^/]+$## or
6096             fail "cannot import $dscfn which seems to not have a basename";
6097         $there .= "/$f";
6098         symlink $there, $here or fail "symlink $there to $here: $!";
6099         progress "made symlink $here -> $there";
6100 #       print STDERR Dumper($fi);
6101     }
6102     my @mergeinputs = generate_commits_from_dsc();
6103     die unless @mergeinputs == 1;
6104
6105     my $newhash = $mergeinputs[0]{Commit};
6106
6107     if ($oldhash) {
6108         if ($force > 0) {
6109             progress "Import, forced update - synthetic orphan git history.";
6110         } elsif ($force < 0) {
6111             progress "Import, merging.";
6112             my $tree = cmdoutput @git, qw(rev-parse), "$newhash:";
6113             my $version = getfield $dsc, 'Version';
6114             my $clogp = commit_getclogp $newhash;
6115             my $authline = clogp_authline $clogp;
6116             $newhash = make_commit_text <<END;
6117 tree $tree
6118 parent $newhash
6119 parent $oldhash
6120 author $authline
6121 committer $authline
6122
6123 Merge $package ($version) import into $dstbranch
6124 END
6125         } else {
6126             die; # caught earlier
6127         }
6128     }
6129
6130     my @cmd = (@git, qw(update-ref -m), "dgit import-dsc: $info",
6131                $dstbranch, $newhash);
6132     runcmd @cmd;
6133     progress "dgit: import-dsc results are in in git ref $dstbranch";
6134 }
6135
6136 sub cmd_archive_api_query {
6137     badusage "need only 1 subpath argument" unless @ARGV==1;
6138     my ($subpath) = @ARGV;
6139     my @cmd = archive_api_query_cmd($subpath);
6140     push @cmd, qw(-f);
6141     debugcmd ">",@cmd;
6142     exec @cmd or fail "exec curl: $!\n";
6143 }
6144
6145 sub cmd_clone_dgit_repos_server {
6146     badusage "need destination argument" unless @ARGV==1;
6147     my ($destdir) = @ARGV;
6148     $package = '_dgit-repos-server';
6149     my @cmd = (@git, qw(clone), access_giturl(), $destdir);
6150     debugcmd ">",@cmd;
6151     exec @cmd or fail "exec git clone: $!\n";
6152 }
6153
6154 sub cmd_setup_mergechangelogs {
6155     badusage "no arguments allowed to dgit setup-mergechangelogs" if @ARGV;
6156     setup_mergechangelogs(1);
6157 }
6158
6159 sub cmd_setup_useremail {
6160     badusage "no arguments allowed to dgit setup-mergechangelogs" if @ARGV;
6161     setup_useremail(1);
6162 }
6163
6164 sub cmd_setup_new_tree {
6165     badusage "no arguments allowed to dgit setup-tree" if @ARGV;
6166     setup_new_tree();
6167 }
6168
6169 #---------- argument parsing and main program ----------
6170
6171 sub cmd_version {
6172     print "dgit version $our_version\n" or die $!;
6173     exit 0;
6174 }
6175
6176 our (%valopts_long, %valopts_short);
6177 our @rvalopts;
6178
6179 sub defvalopt ($$$$) {
6180     my ($long,$short,$val_re,$how) = @_;
6181     my $oi = { Long => $long, Short => $short, Re => $val_re, How => $how };
6182     $valopts_long{$long} = $oi;
6183     $valopts_short{$short} = $oi;
6184     # $how subref should:
6185     #   do whatever assignemnt or thing it likes with $_[0]
6186     #   if the option should not be passed on to remote, @rvalopts=()
6187     # or $how can be a scalar ref, meaning simply assign the value
6188 }
6189
6190 defvalopt '--since-version', '-v', '[^_]+|_', \$changes_since_version;
6191 defvalopt '--distro',        '-d', '.+',      \$idistro;
6192 defvalopt '',                '-k', '.+',      \$keyid;
6193 defvalopt '--existing-package','', '.*',      \$existing_package;
6194 defvalopt '--build-products-dir','','.*',     \$buildproductsdir;
6195 defvalopt '--clean',       '', $cleanmode_re, \$cleanmode;
6196 defvalopt '--package',   '-p',   $package_re, \$package;
6197 defvalopt '--quilt',     '', $quilt_modes_re, \$quilt_mode;
6198
6199 defvalopt '', '-C', '.+', sub {
6200     ($changesfile) = (@_);
6201     if ($changesfile =~ s#^(.*)/##) {
6202         $buildproductsdir = $1;
6203     }
6204 };
6205
6206 defvalopt '--initiator-tempdir','','.*', sub {
6207     ($initiator_tempdir) = (@_);
6208     $initiator_tempdir =~ m#^/# or
6209         badusage "--initiator-tempdir must be used specify an".
6210         " absolute, not relative, directory."
6211 };
6212
6213 sub parseopts () {
6214     my $om;
6215
6216     if (defined $ENV{'DGIT_SSH'}) {
6217         @ssh = string_to_ssh $ENV{'DGIT_SSH'};
6218     } elsif (defined $ENV{'GIT_SSH'}) {
6219         @ssh = ($ENV{'GIT_SSH'});
6220     }
6221
6222     my $oi;
6223     my $val;
6224     my $valopt = sub {
6225         my ($what) = @_;
6226         @rvalopts = ($_);
6227         if (!defined $val) {
6228             badusage "$what needs a value" unless @ARGV;
6229             $val = shift @ARGV;
6230             push @rvalopts, $val;
6231         }
6232         badusage "bad value \`$val' for $what" unless
6233             $val =~ m/^$oi->{Re}$(?!\n)/s;
6234         my $how = $oi->{How};
6235         if (ref($how) eq 'SCALAR') {
6236             $$how = $val;
6237         } else {
6238             $how->($val);
6239         }
6240         push @ropts, @rvalopts;
6241     };
6242
6243     while (@ARGV) {
6244         last unless $ARGV[0] =~ m/^-/;
6245         $_ = shift @ARGV;
6246         last if m/^--?$/;
6247         if (m/^--/) {
6248             if (m/^--dry-run$/) {
6249                 push @ropts, $_;
6250                 $dryrun_level=2;
6251             } elsif (m/^--damp-run$/) {
6252                 push @ropts, $_;
6253                 $dryrun_level=1;
6254             } elsif (m/^--no-sign$/) {
6255                 push @ropts, $_;
6256                 $sign=0;
6257             } elsif (m/^--help$/) {
6258                 cmd_help();
6259             } elsif (m/^--version$/) {
6260                 cmd_version();
6261             } elsif (m/^--new$/) {
6262                 push @ropts, $_;
6263                 $new_package=1;
6264             } elsif (m/^--([-0-9a-z]+)=(.+)/s &&
6265                      ($om = $opts_opt_map{$1}) &&
6266                      length $om->[0]) {
6267                 push @ropts, $_;
6268                 $om->[0] = $2;
6269             } elsif (m/^--([-0-9a-z]+):(.*)/s &&
6270                      !$opts_opt_cmdonly{$1} &&
6271                      ($om = $opts_opt_map{$1})) {
6272                 push @ropts, $_;
6273                 push @$om, $2;
6274             } elsif (m/^--(gbp|dpm)$/s) {
6275                 push @ropts, "--quilt=$1";
6276                 $quilt_mode = $1;
6277             } elsif (m/^--ignore-dirty$/s) {
6278                 push @ropts, $_;
6279                 $ignoredirty = 1;
6280             } elsif (m/^--no-quilt-fixup$/s) {
6281                 push @ropts, $_;
6282                 $quilt_mode = 'nocheck';
6283             } elsif (m/^--no-rm-on-error$/s) {
6284                 push @ropts, $_;
6285                 $rmonerror = 0;
6286             } elsif (m/^--no-chase-dsc-distro$/s) {
6287                 push @ropts, $_;
6288                 $chase_dsc_distro = 0;
6289             } elsif (m/^--overwrite$/s) {
6290                 push @ropts, $_;
6291                 $overwrite_version = '';
6292             } elsif (m/^--overwrite=(.+)$/s) {
6293                 push @ropts, $_;
6294                 $overwrite_version = $1;
6295             } elsif (m/^--dep14tag$/s) {
6296                 push @ropts, $_;
6297                 $dodep14tag= 'want';
6298             } elsif (m/^--no-dep14tag$/s) {
6299                 push @ropts, $_;
6300                 $dodep14tag= 'no';
6301             } elsif (m/^--always-dep14tag$/s) {
6302                 push @ropts, $_;
6303                 $dodep14tag= 'always';
6304             } elsif (m/^--delayed=(\d+)$/s) {
6305                 push @ropts, $_;
6306                 push @dput, $_;
6307             } elsif (m/^--dgit-view-save=(.+)$/s) {
6308                 push @ropts, $_;
6309                 $split_brain_save = $1;
6310                 $split_brain_save =~ s#^(?!refs/)#refs/heads/#;
6311             } elsif (m/^--(no-)?rm-old-changes$/s) {
6312                 push @ropts, $_;
6313                 $rmchanges = !$1;
6314             } elsif (m/^--deliberately-($deliberately_re)$/s) {
6315                 push @ropts, $_;
6316                 push @deliberatelies, $&;
6317             } elsif (m/^--force-(.*)/ && defined $forceopts{$1}) {
6318                 push @ropts, $&;
6319                 $forceopts{$1} = 1;
6320                 $_='';
6321             } elsif (m/^--force-/) {
6322                 print STDERR
6323                     "$us: warning: ignoring unknown force option $_\n";
6324                 $_='';
6325             } elsif (m/^--dgit-tag-format=(old|new)$/s) {
6326                 # undocumented, for testing
6327                 push @ropts, $_;
6328                 $tagformat_want = [ $1, 'command line', 1 ];
6329                 # 1 menas overrides distro configuration
6330             } elsif (m/^--always-split-source-build$/s) {
6331                 # undocumented, for testing
6332                 push @ropts, $_;
6333                 $need_split_build_invocation = 1;
6334             } elsif (m/^--config-lookup-explode=(.+)$/s) {
6335                 # undocumented, for testing
6336                 push @ropts, $_;
6337                 $gitcfgs{cmdline}{$1} = 'CONFIG-LOOKUP-EXPLODE';
6338                 # ^ it's supposed to be an array ref
6339             } elsif (m/^(--[-0-9a-z]+)(=|$)/ && ($oi = $valopts_long{$1})) {
6340                 $val = $2 ? $' : undef; #';
6341                 $valopt->($oi->{Long});
6342             } else {
6343                 badusage "unknown long option \`$_'";
6344             }
6345         } else {
6346             while (m/^-./s) {
6347                 if (s/^-n/-/) {
6348                     push @ropts, $&;
6349                     $dryrun_level=2;
6350                 } elsif (s/^-L/-/) {
6351                     push @ropts, $&;
6352                     $dryrun_level=1;
6353                 } elsif (s/^-h/-/) {
6354                     cmd_help();
6355                 } elsif (s/^-D/-/) {
6356                     push @ropts, $&;
6357                     $debuglevel++;
6358                     enabledebug();
6359                 } elsif (s/^-N/-/) {
6360                     push @ropts, $&;
6361                     $new_package=1;
6362                 } elsif (m/^-m/) {
6363                     push @ropts, $&;
6364                     push @changesopts, $_;
6365                     $_ = '';
6366                 } elsif (s/^-wn$//s) {
6367                     push @ropts, $&;
6368                     $cleanmode = 'none';
6369                 } elsif (s/^-wg$//s) {
6370                     push @ropts, $&;
6371                     $cleanmode = 'git';
6372                 } elsif (s/^-wgf$//s) {
6373                     push @ropts, $&;
6374                     $cleanmode = 'git-ff';
6375                 } elsif (s/^-wd$//s) {
6376                     push @ropts, $&;
6377                     $cleanmode = 'dpkg-source';
6378                 } elsif (s/^-wdd$//s) {
6379                     push @ropts, $&;
6380                     $cleanmode = 'dpkg-source-d';
6381                 } elsif (s/^-wc$//s) {
6382                     push @ropts, $&;
6383                     $cleanmode = 'check';
6384                 } elsif (s/^-c([^=]*)\=(.*)$//s) {
6385                     push @git, '-c', $&;
6386                     $gitcfgs{cmdline}{$1} = [ $2 ];
6387                 } elsif (s/^-c([^=]+)$//s) {
6388                     push @git, '-c', $&;
6389                     $gitcfgs{cmdline}{$1} = [ 'true' ];
6390                 } elsif (m/^-[a-zA-Z]/ && ($oi = $valopts_short{$&})) {
6391                     $val = $'; #';
6392                     $val = undef unless length $val;
6393                     $valopt->($oi->{Short});
6394                     $_ = '';
6395                 } else {
6396                     badusage "unknown short option \`$_'";
6397                 }
6398             }
6399         }
6400     }
6401 }
6402
6403 sub check_env_sanity () {
6404     my $blocked = new POSIX::SigSet;
6405     sigprocmask SIG_UNBLOCK, $blocked, $blocked or die $!;
6406
6407     eval {
6408         foreach my $name (qw(PIPE CHLD)) {
6409             my $signame = "SIG$name";
6410             my $signum = eval "POSIX::$signame" // die;
6411             ($SIG{$name} // 'DEFAULT') eq 'DEFAULT' or
6412                 die "$signame is set to something other than SIG_DFL\n";
6413             $blocked->ismember($signum) and
6414                 die "$signame is blocked\n";
6415         }
6416     };
6417     return unless $@;
6418     chomp $@;
6419     fail <<END;
6420 On entry to dgit, $@
6421 This is a bug produced by something in in your execution environment.
6422 Giving up.
6423 END
6424 }
6425
6426
6427 sub parseopts_late_defaults () {
6428     foreach my $k (keys %opts_opt_map) {
6429         my $om = $opts_opt_map{$k};
6430
6431         my $v = access_cfg("cmd-$k", 'RETURN-UNDEF');
6432         if (defined $v) {
6433             badcfg "cannot set command for $k"
6434                 unless length $om->[0];
6435             $om->[0] = $v;
6436         }
6437
6438         foreach my $c (access_cfg_cfgs("opts-$k")) {
6439             my @vl =
6440                 map { $_ ? @$_ : () }
6441                 map { $gitcfgs{$_}{$c} }
6442                 reverse @gitcfgsources;
6443             printdebug "CL $c ", (join " ", map { shellquote } @vl),
6444                 "\n" if $debuglevel >= 4;
6445             next unless @vl;
6446             badcfg "cannot configure options for $k"
6447                 if $opts_opt_cmdonly{$k};
6448             my $insertpos = $opts_cfg_insertpos{$k};
6449             @$om = ( @$om[0..$insertpos-1],
6450                      @vl,
6451                      @$om[$insertpos..$#$om] );
6452         }
6453     }
6454
6455     if (!defined $rmchanges) {
6456         local $access_forpush;
6457         $rmchanges = access_cfg_bool(0, 'rm-old-changes');
6458     }
6459
6460     if (!defined $quilt_mode) {
6461         local $access_forpush;
6462         $quilt_mode = cfg('dgit.force.quilt-mode', 'RETURN-UNDEF')
6463             // access_cfg('quilt-mode', 'RETURN-UNDEF')
6464             // 'linear';
6465         $quilt_mode =~ m/^($quilt_modes_re)$/
6466             or badcfg "unknown quilt-mode \`$quilt_mode'";
6467         $quilt_mode = $1;
6468     }
6469
6470     if (!defined $dodep14tag) {
6471         local $access_forpush;
6472         $dodep14tag = access_cfg('dep14tag', 'RETURN-UNDEF') // 'want';
6473         $dodep14tag =~ m/^($dodep14tag_re)$/
6474             or badcfg "unknown dep14tag setting \`$dodep14tag'";
6475         $dodep14tag = $1;
6476     }
6477
6478     $need_split_build_invocation ||= quiltmode_splitbrain();
6479
6480     if (!defined $cleanmode) {
6481         local $access_forpush;
6482         $cleanmode = access_cfg('clean-mode', 'RETURN-UNDEF');
6483         $cleanmode //= 'dpkg-source';
6484
6485         badcfg "unknown clean-mode \`$cleanmode'" unless
6486             $cleanmode =~ m/^($cleanmode_re)$(?!\n)/s;
6487     }
6488 }
6489
6490 if ($ENV{$fakeeditorenv}) {
6491     git_slurp_config();
6492     quilt_fixup_editor();
6493 }
6494
6495 parseopts();
6496 check_env_sanity();
6497 git_slurp_config();
6498
6499 print STDERR "DRY RUN ONLY\n" if $dryrun_level > 1;
6500 print STDERR "DAMP RUN - WILL MAKE LOCAL (UNSIGNED) CHANGES\n"
6501     if $dryrun_level == 1;
6502 if (!@ARGV) {
6503     print STDERR $helpmsg or die $!;
6504     exit 8;
6505 }
6506 my $cmd = shift @ARGV;
6507 $cmd =~ y/-/_/;
6508
6509 my $pre_fn = ${*::}{"pre_$cmd"};
6510 $pre_fn->() if $pre_fn;
6511
6512 my $fn = ${*::}{"cmd_$cmd"};
6513 $fn or badusage "unknown operation $cmd";
6514 $fn->();