dgit

   1 #!/usr/bin/perl -w
   2 # dgit
   3 # Integration between git and Debian-style archives
   4 #
   5 # Copyright (C)2013 Ian Jackson
   6 #
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 use strict;
  21
  22 use IO::Handle;
  23 use Data::Dumper;
  24 use LWP::UserAgent;
  25 use Dpkg::Control::Hash;
  26 use File::Path;
  27 use File::Temp qw(tempdir);
  28 use File::Basename;
  29 use Dpkg::Version;
  30 use POSIX;
  31 use IPC::Open2;
  32 use Digest::SHA;
  33 use Digest::MD5;
  34 use Config;
  35
  36 our $our_version = 'UNRELEASED'; ###substituted###
  37
  38 our $rpushprotovsn = 2;
  39
  40 our $isuite = 'unstable';
  41 our $idistro;
  42 our $package;
  43 our @ropts;
  44
  45 our $sign = 1;
  46 our $dryrun_level = 0;
  47 our $changesfile;
  48 our $buildproductsdir = '..';
  49 our $new_package = 0;
  50 our $ignoredirty = 0;
  51 our $noquilt = 0;
  52 our $rmonerror = 1;
  53 our $existing_package = 'dpkg';
  54 our $cleanmode = 'dpkg-source';
  55 our $changes_since_version;
  56 our $we_are_responder;
  57 our $initiator_tempdir;
  58
  59 our %format_ok = map { $_=>1 } ("1.0","3.0 (native)","3.0 (quilt)");
  60
  61 our $suite_re = '[-+.0-9a-z]+';
  62
  63 our (@git) = qw(git);
  64 our (@dget) = qw(dget);
  65 our (@curl) = qw(curl -f);
  66 our (@dput) = qw(dput);
  67 our (@debsign) = qw(debsign);
  68 our (@gpg) = qw(gpg);
  69 our (@sbuild) = qw(sbuild -A);
  70 our (@ssh) = 'ssh';
  71 our (@dgit) = qw(dgit);
  72 our (@dpkgbuildpackage) = qw(dpkg-buildpackage -i\.git/ -I.git);
  73 our (@dpkgsource) = qw(dpkg-source -i\.git/ -I.git);
  74 our (@dpkggenchanges) = qw(dpkg-genchanges);
  75 our (@mergechanges) = qw(mergechanges -f);
  76 our (@changesopts) = ('');
  77
  78 our %opts_opt_map = ('dget' => \@dget, # accept for compatibility
  79                      'curl' => \@curl,
  80                      'dput' => \@dput,
  81                      'debsign' => \@debsign,
  82                      'gpg' => \@gpg,
  83                      'sbuild' => \@sbuild,
  84                      'ssh' => \@ssh,
  85                      'dgit' => \@dgit,
  86                      'dpkg-source' => \@dpkgsource,
  87                      'dpkg-buildpackage' => \@dpkgbuildpackage,
  88                      'dpkg-genchanges' => \@dpkggenchanges,
  89                      'ch' => \@changesopts,
  90                      'mergechanges' => \@mergechanges);
  91
  92 our %opts_opt_cmdonly = ('gpg' => 1);
  93
  94 our $keyid;
  95
  96 our $debug = 0;
  97 open DEBUG, ">/dev/null" or die $!;
  98
  99 autoflush STDOUT 1;
 100
 101 our $remotename = 'dgit';
 102 our @ourdscfield = qw(Dgit Vcs-Dgit-Master);
 103 our $branchprefix = 'dgit';
 104 our $csuite;
 105
 106 sub lbranch () { return "$branchprefix/$csuite"; }
 107 my $lbranch_re = '^refs/heads/'.$branchprefix.'/([^/.]+)$';
 108 sub lref () { return "refs/heads/".lbranch(); }
 109 sub lrref () { return "refs/remotes/$remotename/$branchprefix/$csuite"; }
 110 sub rrref () { return "refs/$branchprefix/$csuite"; }
 111 sub debiantag ($) {
 112     my ($v) = @_;
 113     $v =~ y/~:/_%/;
 114     return "debian/$v";
 115 }
 116
 117 sub stripepoch ($) {
 118     my ($vsn) = @_;
 119     $vsn =~ s/^\d+\://;
 120     return $vsn;
 121 }
 122
 123 sub srcfn ($$) {
 124     my ($vsn,$sfx) = @_;
 125     return "${package}_".(stripepoch $vsn).$sfx
 126 }
 127
 128 sub dscfn ($) {
 129     my ($vsn) = @_;
 130     return srcfn($vsn,".dsc");
 131 }
 132
 133 our $us = 'dgit';
 134 our $debugprefix = '';
 135
 136 our @end;
 137 END {
 138     local ($?);
 139     foreach my $f (@end) {
 140         eval { $f->(); };
 141         warn "$us: cleanup: $@" if length $@;
 142     }
 143 };
 144
 145 our @signames = split / /, $Config{sig_name};
 146
 147 sub waitstatusmsg () {
 148     if (!$?) {
 149         return "terminated, reporting successful completion";
 150     } elsif (!($? & 255)) {
 151         return "failed with error exit status ".WEXITSTATUS($?);
 152     } elsif (WIFSIGNALED($?)) {
 153         my $signum=WTERMSIG($?);
 154         return "died due to fatal signal ".
 155             ($signames[$signum] // "number $signum").
 156             ($? & 128 ? " (core dumped)" : ""); # POSIX(3pm) has no WCOREDUMP
 157     } else {
 158         return "failed with unknown wait status ".$?;
 159     }
 160 }
 161
 162 sub printdebug { print DEBUG $debugprefix, @_ or die $!; }
 163
 164 sub fail {
 165     die $us.($we_are_responder ? " (build host)" : "").": @_\n";
 166 }
 167
 168 sub badcfg { print STDERR "$us: invalid configuration: @_\n"; exit 12; }
 169
 170 sub no_such_package () {
 171     print STDERR "$us: package $package does not exist in suite $isuite\n";
 172     exit 4;
 173 }
 174
 175 sub fetchspec () {
 176     local $csuite = '*';
 177     return  "+".rrref().":".lrref();
 178 }
 179
 180 sub changedir ($) {
 181     my ($newdir) = @_;
 182     printdebug "CD $newdir\n";
 183     chdir $newdir or die "chdir: $newdir: $!";
 184 }
 185
 186 sub stat_exists ($) {
 187     my ($f) = @_;
 188     return 1 if stat $f;
 189     return 0 if $!==&ENOENT;
 190     die "stat $f: $!";
 191 }
 192
 193 #---------- remote protocol support, common ----------
 194
 195 # remote push initiator/responder protocol:
 196 #  < dgit-remote-push-ready [optional extra info ignored by old initiators]
 197 #
 198 #  > file parsed-changelog
 199 #  [indicates that output of dpkg-parsechangelog follows]
 200 #  > data-block NBYTES
 201 #  > [NBYTES bytes of data (no newline)]
 202 #  [maybe some more blocks]
 203 #  > data-end
 204 #
 205 #  > file dsc
 206 #  [etc]
 207 #
 208 #  > file changes
 209 #  [etc]
 210 #
 211 #  > param head HEAD
 212 #
 213 #  > want signed-tag
 214 #  [indicates that signed tag is wanted]
 215 #  < data-block NBYTES
 216 #  < [NBYTES bytes of data (no newline)]
 217 #  [maybe some more blocks]
 218 #  < data-end
 219 #  < files-end
 220 #
 221 #  > want signed-dsc-changes
 222 #  < data-block NBYTES    [transfer of signed dsc]
 223 #  [etc]
 224 #  < data-block NBYTES    [transfer of signed changes]
 225 #  [etc]
 226 #  < files-end
 227 #
 228 #  > complete
 229
 230 our $i_child_pid;
 231
 232 sub i_child_report () {
 233     # Sees if our child has died, and reap it if so.  Returns a string
 234     # describing how it died if it failed, or undef otherwise.
 235     return undef unless $i_child_pid;
 236     my $got = waitpid $i_child_pid, WNOHANG;
 237     return undef if $got <= 0;
 238     die unless $got == $i_child_pid;
 239     $i_child_pid = undef;
 240     return undef unless $?;
 241     return "build host child ".waitstatusmsg();
 242 }
 243
 244 sub badproto ($$) {
 245     my ($fh, $m) = @_;
 246     fail "connection lost: $!" if $fh->error;
 247     fail "protocol violation; $m not expected";
 248 }
 249
 250 sub badproto_badread ($$) {
 251     my ($fh, $wh) = @_;
 252     fail "connection lost: $!" if $!;
 253     my $report = i_child_report();
 254     fail $report if defined $report;
 255     badproto $fh, "eof (reading $wh)";
 256 }
 257
 258 sub protocol_expect (&$) {
 259     my ($match, $fh) = @_;
 260     local $_;
 261     $_ = <$fh>;
 262     defined && chomp or badproto_badread $fh, "protocol message";
 263     if (wantarray) {
 264         my @r = &$match;
 265         return @r if @r;
 266     } else {
 267         my $r = &$match;
 268         return $r if $r;
 269     }
 270     badproto $fh, "\`$_'";
 271 }
 272
 273 sub protocol_send_file ($$) {
 274     my ($fh, $ourfn) = @_;
 275     open PF, "<", $ourfn or die "$ourfn: $!";
 276     for (;;) {
 277         my $d;
 278         my $got = read PF, $d, 65536;
 279         die "$ourfn: $!" unless defined $got;
 280         last if !$got;
 281         print $fh "data-block ".length($d)."\n" or die $!;
 282         print $fh $d or die $!;
 283     }
 284     PF->error and die "$ourfn $!";
 285     print $fh "data-end\n" or die $!;
 286     close PF;
 287 }
 288
 289 sub protocol_read_bytes ($$) {
 290     my ($fh, $nbytes) = @_;
 291     $nbytes =~ m/^[1-9]\d{0,5}$/ or badproto \*RO, "bad byte count";
 292     my $d;
 293     my $got = read $fh, $d, $nbytes;
 294     $got==$nbytes or badproto_badread $fh, "data block";
 295     return $d;
 296 }
 297
 298 sub protocol_receive_file ($$) {
 299     my ($fh, $ourfn) = @_;
 300     printdebug "() $ourfn\n";
 301     open PF, ">", $ourfn or die "$ourfn: $!";
 302     for (;;) {
 303         my ($y,$l) = protocol_expect {
 304             m/^data-block (.*)$/ ? (1,$1) :
 305             m/^data-end$/ ? (0,) :
 306             ();
 307         } $fh;
 308         last unless $y;
 309         my $d = protocol_read_bytes $fh, $l;
 310         print PF $d or die $!;
 311     }
 312     close PF or die $!;
 313 }
 314
 315 #---------- remote protocol support, responder ----------
 316
 317 sub responder_send_command ($) {
 318     my ($command) = @_;
 319     return unless $we_are_responder;
 320     # called even without $we_are_responder
 321     printdebug ">> $command\n";
 322     print PO $command, "\n" or die $!;
 323 }
 324
 325 sub responder_send_file ($$) {
 326     my ($keyword, $ourfn) = @_;
 327     return unless $we_are_responder;
 328     printdebug "]] $keyword $ourfn\n";
 329     responder_send_command "file $keyword";
 330     protocol_send_file \*PO, $ourfn;
 331 }
 332
 333 sub responder_receive_files ($@) {
 334     my ($keyword, @ourfns) = @_;
 335     die unless $we_are_responder;
 336     printdebug "[[ $keyword @ourfns\n";
 337     responder_send_command "want $keyword";
 338     foreach my $fn (@ourfns) {
 339         protocol_receive_file \*PI, $fn;
 340     }
 341     printdebug "[[\$\n";
 342     protocol_expect { m/^files-end$/ } \*PI;
 343 }
 344
 345 #---------- remote protocol support, initiator ----------
 346
 347 sub initiator_expect (&) {
 348     my ($match) = @_;
 349     protocol_expect { &$match } \*RO;
 350 }
 351
 352 #---------- end remote code ----------
 353
 354 sub progress {
 355     if ($we_are_responder) {
 356         my $m = join '', @_;
 357         responder_send_command "progress ".length($m) or die $!;
 358         print PO $m or die $!;
 359     } else {
 360         print @_, "\n";
 361     }
 362 }
 363
 364 our $ua;
 365
 366 sub url_get {
 367     if (!$ua) {
 368         $ua = LWP::UserAgent->new();
 369         $ua->env_proxy;
 370     }
 371     my $what = $_[$#_];
 372     progress "downloading $what...";
 373     my $r = $ua->get(@_) or die $!;
 374     return undef if $r->code == 404;
 375     $r->is_success or fail "failed to fetch $what: ".$r->status_line;
 376     return $r->decoded_content(charset => 'none');
 377 }
 378
 379 our ($dscdata,$dscurl,$dsc,$dsc_checked,$skew_warning_vsn);
 380
 381 sub shellquote {
 382     my @out;
 383     local $_;
 384     foreach my $a (@_) {
 385         $_ = $a;
 386         if (m{[^-=_./0-9a-z]}i) {
 387             s{['\\]}{'\\$&'}g;
 388             push @out, "'$_'";
 389         } else {
 390             push @out, $_;
 391         }
 392     }
 393     return join ' ', @out;
 394 }
 395
 396 sub printcmd {
 397     my $fh = shift @_;
 398     my $intro = shift @_;
 399     print $fh $intro," " or die $!;
 400     print $fh shellquote @_ or die $!;
 401     print $fh "\n" or die $!;
 402 }
 403
 404 sub failedcmd {
 405     { local ($!); printcmd \*STDERR, "$us: failed command:", @_ or die $!; };
 406     if ($!) {
 407         fail "failed to fork/exec: $!";
 408     } elsif ($?) {
 409         fail "subprocess ".waitstatusmsg();
 410     } else {
 411         fail "subprocess produced invalid output";
 412     }
 413 }
 414
 415 sub runcmd {
 416     printcmd(\*DEBUG,$debugprefix."+",@_) if $debug>0;
 417     $!=0; $?=0;
 418     failedcmd @_ if system @_;
 419 }
 420
 421 sub act_local () { return $dryrun_level <= 1; }
 422 sub act_scary () { return !$dryrun_level; }
 423
 424 sub printdone {
 425     if (!$dryrun_level) {
 426         progress "dgit ok: @_";
 427     } else {
 428         progress "would be ok: @_ (but dry run only)";
 429     }
 430 }
 431
 432 sub cmdoutput_errok {
 433     die Dumper(\@_)." ?" if grep { !defined } @_;
 434     printcmd(\*DEBUG,$debugprefix."|",@_) if $debug>0;
 435     open P, "-|", @_ or die $!;
 436     my $d;
 437     $!=0; $?=0;
 438     { local $/ = undef; $d = <P>; }
 439     die $! if P->error;
 440     if (!close P) { printdebug "=>!$?\n" if $debug>0; return undef; }
 441     chomp $d;
 442     $d =~ m/^.*/;
 443     printdebug "=> \`$&'",(length $' ? '...' : ''),"\n" if $debug>0; #';
 444     return $d;
 445 }
 446
 447 sub cmdoutput {
 448     my $d = cmdoutput_errok @_;
 449     defined $d or failedcmd @_;
 450     return $d;
 451 }
 452
 453 sub dryrun_report {
 454     printcmd(\*STDERR,$debugprefix."#",@_);
 455 }
 456
 457 sub runcmd_ordryrun {
 458     if (act_scary()) {
 459         runcmd @_;
 460     } else {
 461         dryrun_report @_;
 462     }
 463 }
 464
 465 sub runcmd_ordryrun_local {
 466     if (act_local()) {
 467         runcmd @_;
 468     } else {
 469         dryrun_report @_;
 470     }
 471 }
 472
 473 sub shell_cmd {
 474     my ($first_shell, @cmd) = @_;
 475     return qw(sh -ec), $first_shell.'; exec "$@"', 'x', @cmd;
 476 }
 477
 478 our $helpmsg = <<END;
 479 main usages:
 480   dgit [dgit-opts] clone [dgit-opts] package [suite] [./dir|/dir]
 481   dgit [dgit-opts] fetch|pull [dgit-opts] [suite]
 482   dgit [dgit-opts] build [git-buildpackage-opts|dpkg-buildpackage-opts]
 483   dgit [dgit-opts] push [dgit-opts] [suite]
 484   dgit [dgit-opts] rpush build-host:build-dir ...
 485 important dgit options:
 486   -k<keyid>           sign tag and package with <keyid> instead of default
 487   --dry-run -n        do not change anything, but go through the motions
 488   --damp-run -L       like --dry-run but make local changes, without signing
 489   --new -N            allow introducing a new package
 490   --debug -D          increase debug level
 491   -c<name>=<value>    set git config option (used directly by dgit too)
 492 END
 493
 494 our $later_warning_msg = <<END;
 495 Perhaps the upload is stuck in incoming.  Using the version from git.
 496 END
 497
 498 sub badusage {
 499     print STDERR "$us: @_\n", $helpmsg or die $!;
 500     exit 8;
 501 }
 502
 503 sub nextarg {
 504     @ARGV or badusage "too few arguments";
 505     return scalar shift @ARGV;
 506 }
 507
 508 sub cmd_help () {
 509     print $helpmsg or die $!;
 510     exit 0;
 511 }
 512
 513 our $td = $ENV{DGIT_TEST_DUMMY_DIR} || "DGIT_TEST_DUMMY_DIR-unset";
 514
 515 our %defcfg = ('dgit.default.distro' => 'debian',
 516                'dgit.default.username' => '',
 517                'dgit.default.archive-query-default-component' => 'main',
 518                'dgit.default.ssh' => 'ssh',
 519                'dgit.default.archive-query' => 'madison:',
 520                'dgit.default.sshpsql-dbname' => 'service=projectb',
 521                'dgit-distro.debian.archive-query' => 'sshpsql:',
 522                'dgit-distro.debian.git-host' => 'git.debian.org',
 523                'dgit-distro.debian.git-proto' => 'git+ssh://',
 524                'dgit-distro.debian.git-path' => '/git/dgit-repos/repos',
 525                'dgit-distro.debian.git-check' => 'ssh-cmd',
 526                'dgit-distro.debian.git-create' => 'ssh-cmd',
 527                'dgit-distro.debian.sshpsql-host' => 'mirror.ftp-master.debian.org',
 528                'dgit-distro.debian.upload-host' => 'ftp-master', # for dput
 529                'dgit-distro.debian.mirror' => 'http://ftp.debian.org/debian/',
 530  'dgit-distro.debian.backports-quirk' => '(squeeze)-backports*',
 531  'dgit-distro.debian-backports.mirror' => 'http://backports.debian.org/debian-backports/',
 532                'dgit-distro.ubuntu.git-check' => 'false',
 533  'dgit-distro.ubuntu.mirror' => 'http://archive.ubuntu.com/ubuntu',
 534                'dgit-distro.test-dummy.ssh' => "$td/ssh",
 535                'dgit-distro.test-dummy.username' => "alice",
 536                'dgit-distro.test-dummy.git-check' => "ssh-cmd",
 537                'dgit-distro.test-dummy.git-create' => "ssh-cmd",
 538                'dgit-distro.test-dummy.git-url' => "$td/git",
 539                'dgit-distro.test-dummy.git-host' => "git",
 540                'dgit-distro.test-dummy.git-path' => "$td/git",
 541                'dgit-distro.test-dummy.archive-query' => "dummycat:$td/aq",
 542                'dgit-distro.test-dummy.mirror' => "file://$td/mirror/",
 543                'dgit-distro.test-dummy.upload-host' => 'test-dummy',
 544                );
 545
 546 sub cfg {
 547     foreach my $c (@_) {
 548         return undef if $c =~ /RETURN-UNDEF/;
 549         my @cmd = (@git, qw(config --), $c);
 550         my $v;
 551         {
 552             local ($debug) = $debug-1;
 553             $v = cmdoutput_errok @cmd;
 554         };
 555         if ($?==0) {
 556             return $v;
 557         } elsif ($?!=256) {
 558             failedcmd @cmd;
 559         }
 560         my $dv = $defcfg{$c};
 561         return $dv if defined $dv;
 562     }
 563     badcfg "need value for one of: @_\n".
 564         "$us: distro or suite appears not to be (properly) supported";
 565 }
 566
 567 sub access_basedistro () {
 568     if (defined $idistro) {
 569         return $idistro;
 570     } else {
 571         return cfg("dgit-suite.$isuite.distro",
 572                    "dgit.default.distro");
 573     }
 574 }
 575
 576 sub access_quirk () {
 577     # returns (quirk name, distro to use instead or undef, quirk-specific info)
 578     my $basedistro = access_basedistro();
 579     my $backports_quirk = cfg("dgit-distro.$basedistro.backports-quirk",
 580                               'RETURN-UNDEF');
 581     if (defined $backports_quirk) {
 582         my $re = $backports_quirk;
 583         $re =~ s/[^-0-9a-z_\%*()]/\\$&/ig;
 584         $re =~ s/\*/.*/g;
 585         $re =~ s/\%/([-0-9a-z_]+)/
 586             or $re =~ m/[()]/ or badcfg "backports-quirk needs \% or ( )";
 587         if ($isuite =~ m/^$re$/) {
 588             return ('backports',"$basedistro-backports",$1);
 589         }
 590     }
 591     return ('none',undef);
 592 }
 593
 594 sub access_distros () {
 595     # Returns list of distros to try, in order
 596     #
 597     # We want to try:
 598     #    1. the access_quirk distro, if any
 599     #    2a. the user's specified distro, or failing that  } basedistro
 600     #    2b. the distro calculated from the suite          }
 601     my @l = access_basedistro();
 602
 603     my (undef,$quirkdistro) = access_quirk();
 604     unshift @l, $quirkdistro if defined $quirkdistro;
 605
 606     return @l;
 607 }
 608
 609 sub access_cfg (@) {
 610     my (@keys) = @_;
 611     my @cfgs;
 612     # The nesting of these loops determines the search order.  We put
 613     # the key loop on the outside so that we search all the distros
 614     # for each key, before going on to the next key.  That means that
 615     # if access_cfg is called with a more specific, and then a less
 616     # specific, key, an earlier distro can override the less specific
 617     # without necessarily overriding any more specific keys.  (If the
 618     # distro wants to override the more specific keys it can simply do
 619     # so; whereas if we did the loop the other way around, it would be
 620     # impossible to for an earlier distro to override a less specific
 621     # key but not the more specific ones without restating the unknown
 622     # values of the more specific keys.
 623     my @realkeys;
 624     my @rundef;
 625     # We have to deal with RETURN-UNDEF specially, so that we don't
 626     # terminate the search prematurely.
 627     foreach (@keys) {
 628         if (m/RETURN-UNDEF/) { push @rundef, $_; last; }
 629         push @realkeys, $_
 630     }
 631     foreach my $d (access_distros()) {
 632         push @cfgs, map { "dgit-distro.$d.$_" } @realkeys;
 633     }
 634     push @cfgs, map { "dgit.default.$_" } @realkeys;
 635     push @cfgs, @rundef;
 636     my $value = cfg(@cfgs);
 637     return $value;
 638 }
 639
 640 sub string_to_ssh ($) {
 641     my ($spec) = @_;
 642     if ($spec =~ m/\s/) {
 643         return qw(sh -ec), 'exec '.$spec.' "$@"', 'x';
 644     } else {
 645         return ($spec);
 646     }
 647 }
 648
 649 sub access_cfg_ssh () {
 650     my $gitssh = access_cfg('ssh', 'RETURN-UNDEF');
 651     if (!defined $gitssh) {
 652         return @ssh;
 653     } else {
 654         return string_to_ssh $gitssh;
 655     }
 656 }
 657
 658 sub access_someuserhost ($) {
 659     my ($some) = @_;
 660     my $user = access_cfg("$some-user",'username');
 661     my $host = access_cfg("$some-host");
 662     return length($user) ? "$user\@$host" : $host;
 663 }
 664
 665 sub access_gituserhost () {
 666     return access_someuserhost('git');
 667 }
 668
 669 sub access_giturl (;$) {
 670     my ($optional) = @_;
 671     my $url = access_cfg('git-url','RETURN-UNDEF');
 672     if (!defined $url) {
 673         my $proto = access_cfg('git-proto', 'RETURN-UNDEF');
 674         return undef unless defined $proto;
 675         $url =
 676             $proto.
 677             access_gituserhost().
 678             access_cfg('git-path');
 679     }
 680     return "$url/$package.git";
 681 }
 682
 683 sub parsecontrolfh ($$;$) {
 684     my ($fh, $desc, $allowsigned) = @_;
 685     our $dpkgcontrolhash_noissigned;
 686     my $c;
 687     for (;;) {
 688         my %opts = ('name' => $desc);
 689         $opts{allow_pgp}= $allowsigned || !$dpkgcontrolhash_noissigned;
 690         $c = Dpkg::Control::Hash->new(%opts);
 691         $c->parse($fh,$desc) or die "parsing of $desc failed";
 692         last if $allowsigned;
 693         last if $dpkgcontrolhash_noissigned;
 694         my $issigned= $c->get_option('is_pgp_signed');
 695         if (!defined $issigned) {
 696             $dpkgcontrolhash_noissigned= 1;
 697             seek $fh, 0,0 or die "seek $desc: $!";
 698         } elsif ($issigned) {
 699             fail "control file $desc is (already) PGP-signed. ".
 700                 " Note that dgit push needs to modify the .dsc and then".
 701                 " do the signature itself";
 702         } else {
 703             last;
 704         }
 705     }
 706     return $c;
 707 }
 708
 709 sub parsecontrol {
 710     my ($file, $desc) = @_;
 711     my $fh = new IO::Handle;
 712     open $fh, '<', $file or die "$file: $!";
 713     my $c = parsecontrolfh($fh,$desc);
 714     $fh->error and die $!;
 715     close $fh;
 716     return $c;
 717 }
 718
 719 sub getfield ($$) {
 720     my ($dctrl,$field) = @_;
 721     my $v = $dctrl->{$field};
 722     return $v if defined $v;
 723     fail "missing field $field in ".$v->get_option('name');
 724 }
 725
 726 sub parsechangelog {
 727     my $c = Dpkg::Control::Hash->new();
 728     my $p = new IO::Handle;
 729     my @cmd = (qw(dpkg-parsechangelog), @_);
 730     open $p, '-|', @cmd or die $!;
 731     $c->parse($p);
 732     $?=0; $!=0; close $p or failedcmd @cmd;
 733     return $c;
 734 }
 735
 736 sub git_get_ref ($) {
 737     my ($refname) = @_;
 738     my $got = cmdoutput_errok @git, qw(show-ref --), $refname;
 739     if (!defined $got) {
 740         $?==256 or fail "git show-ref failed (status $?)";
 741         printdebug "ref $refname= [show-ref exited 1]\n";
 742         return '';
 743     }
 744     if ($got =~ m/^(\w+) \Q$refname\E$/m) {
 745         printdebug "ref $refname=$1\n";
 746         return $1;
 747     } else {
 748         printdebug "ref $refname= [no match]\n";
 749         return '';
 750     }
 751 }
 752
 753 sub must_getcwd () {
 754     my $d = getcwd();
 755     defined $d or fail "getcwd failed: $!";
 756     return $d;
 757 }
 758
 759 our %rmad;
 760
 761 sub archive_query ($) {
 762     my ($method) = @_;
 763     my $query = access_cfg('archive-query','RETURN-UNDEF');
 764     $query =~ s/^(\w+):// or badcfg "invalid archive-query method \`$query'";
 765     my $proto = $1;
 766     my $data = $'; #';
 767     { no strict qw(refs); &{"${method}_${proto}"}($proto,$data); }
 768 }
 769
 770 sub pool_dsc_subpath ($$) {
 771     my ($vsn,$component) = @_; # $package is implict arg
 772     my $prefix = substr($package, 0, $package =~ m/^l/ ? 4 : 1);
 773     return "/pool/$component/$prefix/$package/".dscfn($vsn);
 774 }
 775
 776 sub archive_query_madison {
 777     return map { [ @$_[0..1] ] } madison_get_parse(@_);
 778 }
 779
 780 sub madison_get_parse {
 781     my ($proto,$data) = @_;
 782     die unless $proto eq 'madison';
 783     if (!length $data) {
 784         $data= access_cfg('madison-distro','RETURN-UNDEF');
 785         $data //= access_basedistro();
 786     }
 787     $rmad{$proto,$data,$package} ||= cmdoutput
 788         qw(rmadison -asource),"-s$isuite","-u$data",$package;
 789     my $rmad = $rmad{$proto,$data,$package};
 790
 791     my @out;
 792     foreach my $l (split /\n/, $rmad) {
 793         $l =~ m{^ \s*( [^ \t|]+ )\s* \|
 794                   \s*( [^ \t|]+ )\s* \|
 795                   \s*( [^ \t|/]+ )(?:/([^ \t|/]+))? \s* \|
 796                   \s*( [^ \t|]+ )\s* }x or die "$rmad ?";
 797         $1 eq $package or die "$rmad $package ?";
 798         my $vsn = $2;
 799         my $newsuite = $3;
 800         my $component;
 801         if (defined $4) {
 802             $component = $4;
 803         } else {
 804             $component = access_cfg('archive-query-default-component');
 805         }
 806         $5 eq 'source' or die "$rmad ?";
 807         push @out, [$vsn,pool_dsc_subpath($vsn,$component),$newsuite];
 808     }
 809     return sort { -version_compare($a->[0],$b->[0]); } @out;
 810 }
 811
 812 sub canonicalise_suite_madison {
 813     # madison canonicalises for us
 814     my @r = madison_get_parse(@_);
 815     @r or fail
 816         "unable to canonicalise suite using package $package".
 817         " which does not appear to exist in suite $isuite;".
 818         " --existing-package may help";
 819     return $r[0][2];
 820 }
 821
 822 sub sshpsql ($$$) {
 823     my ($data,$runeinfo,$sql) = @_;
 824     if (!length $data) {
 825         $data= access_someuserhost('sshpsql').':'.
 826             access_cfg('sshpsql-dbname');
 827     }
 828     $data =~ m/:/ or badcfg "invalid sshpsql method string \`$data'";
 829     my ($userhost,$dbname) = ($`,$'); #';
 830     my @rows;
 831     my @cmd = (access_cfg_ssh, $userhost,
 832                ": dgit ssh-psql $runeinfo ;".
 833                " export LANG=C;".
 834                " ".shellquote qw(psql -A), $dbname, qw(-c), $sql);
 835     printcmd(\*DEBUG,$debugprefix."|",@cmd) if $debug>0;
 836     open P, "-|", @cmd or die $!;
 837     while (<P>) {
 838         chomp or die;
 839         printdebug("$debugprefix>|$_|\n");
 840         push @rows, $_;
 841     }
 842     $!=0; $?=0; close P or failedcmd @cmd;
 843     @rows or die;
 844     my $nrows = pop @rows;
 845     $nrows =~ s/^\((\d+) rows?\)$/$1/ or die "$nrows ?";
 846     @rows == $nrows+1 or die "$nrows ".(scalar @rows)." ?";
 847     @rows = map { [ split /\|/, $_ ] } @rows;
 848     my $ncols = scalar @{ shift @rows };
 849     die if grep { scalar @$_ != $ncols } @rows;
 850     return @rows;
 851 }
 852
 853 sub sql_injection_check {
 854     foreach (@_) { die "$_ $& ?" if m{[^-+=:_.,/0-9a-zA-Z]}; }
 855 }
 856
 857 sub archive_query_sshpsql ($$) {
 858     my ($proto,$data) = @_;
 859     sql_injection_check $isuite, $package;
 860     my @rows = sshpsql($data, "archive-query $isuite $package", <<END);
 861         SELECT source.version, component.name, files.filename, files.sha256sum
 862           FROM source
 863           JOIN src_associations ON source.id = src_associations.source
 864           JOIN suite ON suite.id = src_associations.suite
 865           JOIN dsc_files ON dsc_files.source = source.id
 866           JOIN files_archive_map ON files_archive_map.file_id = dsc_files.file
 867           JOIN component ON component.id = files_archive_map.component_id
 868           JOIN files ON files.id = dsc_files.file
 869          WHERE ( suite.suite_name='$isuite' OR suite.codename='$isuite' )
 870            AND source.source='$package'
 871            AND files.filename LIKE '%.dsc';
 872 END
 873     @rows = sort { -version_compare($a->[0],$b->[0]) } @rows;
 874     my $digester = Digest::SHA->new(256);
 875     @rows = map {
 876         my ($vsn,$component,$filename,$sha256sum) = @$_;
 877         [ $vsn, "/pool/$component/$filename",$digester,$sha256sum ];
 878     } @rows;
 879     return @rows;
 880 }
 881
 882 sub canonicalise_suite_sshpsql ($$) {
 883     my ($proto,$data) = @_;
 884     sql_injection_check $isuite;
 885     my @rows = sshpsql($data, "canonicalise-suite $isuite", <<END);
 886         SELECT suite.codename
 887           FROM suite where suite_name='$isuite' or codename='$isuite';
 888 END
 889     @rows = map { $_->[0] } @rows;
 890     fail "unknown suite $isuite" unless @rows;
 891     die "ambiguous $isuite: @rows ?" if @rows>1;
 892     return $rows[0];
 893 }
 894
 895 sub canonicalise_suite_dummycat ($$) {
 896     my ($proto,$data) = @_;
 897     my $dpath = "$data/suite.$isuite";
 898     if (!open C, "<", $dpath) {
 899         $!==ENOENT or die "$dpath: $!";
 900         printdebug "dummycat canonicalise_suite $isuite $dpath ENOENT\n";
 901         return $isuite;
 902     }
 903     $!=0; $_ = <C>;
 904     chomp or die "$dpath: $!";
 905     close C;
 906     printdebug "dummycat canonicalise_suite $isuite $dpath = $_\n";
 907     return $_;
 908 }
 909
 910 sub archive_query_dummycat ($$) {
 911     my ($proto,$data) = @_;
 912     canonicalise_suite();
 913     my $dpath = "$data/package.$csuite.$package";
 914     if (!open C, "<", $dpath) {
 915         $!==ENOENT or die "$dpath: $!";
 916         printdebug "dummycat query $csuite $package $dpath ENOENT\n";
 917         return ();
 918     }
 919     my @rows;
 920     while (<C>) {
 921         next if m/^\#/;
 922         next unless m/\S/;
 923         die unless chomp;
 924         printdebug "dummycat query $csuite $package $dpath | $_\n";
 925         my @row = split /\s+/, $_;
 926         @row==2 or die "$dpath: $_ ?";
 927         push @rows, \@row;
 928     }
 929     C->error and die "$dpath: $!";
 930     close C;
 931     return sort { -version_compare($a->[0],$b->[0]); } @rows;
 932 }
 933
 934 sub canonicalise_suite () {
 935     return if defined $csuite;
 936     fail "cannot operate on $isuite suite" if $isuite eq 'UNRELEASED';
 937     $csuite = archive_query('canonicalise_suite');
 938     if ($isuite ne $csuite) {
 939         progress "canonical suite name for $isuite is $csuite";
 940     }
 941 }
 942
 943 sub get_archive_dsc () {
 944     canonicalise_suite();
 945     my @vsns = archive_query('archive_query');
 946     foreach my $vinfo (@vsns) {
 947         my ($vsn,$subpath,$digester,$digest) = @$vinfo;
 948         $dscurl = access_cfg('mirror').$subpath;
 949         $dscdata = url_get($dscurl);
 950         if (!$dscdata) {
 951             $skew_warning_vsn = $vsn if !defined $skew_warning_vsn;
 952             next;
 953         }
 954         if ($digester) {
 955             $digester->reset();
 956             $digester->add($dscdata);
 957             my $got = $digester->hexdigest();
 958             $got eq $digest or
 959                 fail "$dscurl has hash $got but".
 960                     " archive told us to expect $digest";
 961         }
 962         my $dscfh = new IO::File \$dscdata, '<' or die $!;
 963         printdebug Dumper($dscdata) if $debug>1;
 964         $dsc = parsecontrolfh($dscfh,$dscurl,1);
 965         printdebug Dumper($dsc) if $debug>1;
 966         my $fmt = getfield $dsc, 'Format';
 967         fail "unsupported source format $fmt, sorry" unless $format_ok{$fmt};
 968         $dsc_checked = !!$digester;
 969         return;
 970     }
 971     $dsc = undef;
 972 }
 973
 974 sub check_for_git () {
 975     # returns 0 or 1
 976     my $how = access_cfg('git-check');
 977     if ($how eq 'ssh-cmd') {
 978         my @cmd =
 979             (access_cfg_ssh, access_gituserhost(),
 980              ": dgit git-check $package ;".
 981              " set -e; cd ".access_cfg('git-path').";".
 982              " if test -d $package.git; then echo 1; else echo 0; fi");
 983         my $r= cmdoutput @cmd;
 984         failedcmd @cmd unless $r =~ m/^[01]$/;
 985         return $r+0;
 986     } elsif ($how eq 'true') {
 987         return 1;
 988     } elsif ($how eq 'false') {
 989         return 0;
 990     } else {
 991         badcfg "unknown git-check \`$how'";
 992     }
 993 }
 994
 995 sub create_remote_git_repo () {
 996     my $how = access_cfg('git-create');
 997     if ($how eq 'ssh-cmd') {
 998         runcmd_ordryrun
 999             (access_cfg_ssh, access_gituserhost(),
1000              " : dgit git-create $package ; ".
1001              "set -e; cd ".access_cfg('git-path').";".
1002              " cp -a _template $package.git");
1003     } elsif ($how eq 'true') {
1004         # nothing to do
1005     } else {
1006         badcfg "unknown git-create \`$how'";
1007     }
1008 }
1009
1010 our ($dsc_hash,$lastpush_hash);
1011
1012 our $ud = '.git/dgit/unpack';
1013
1014 sub prep_ud () {
1015     rmtree($ud);
1016     mkpath '.git/dgit';
1017     mkdir $ud or die $!;
1018 }
1019
1020 sub mktree_in_ud_here () {
1021     runcmd qw(git init -q);
1022     rmtree('.git/objects');
1023     symlink '../../../../objects','.git/objects' or die $!;
1024 }
1025
1026 sub mktree_in_ud_from_only_subdir () {
1027     # changes into the subdir
1028     my (@dirs) = <*/.>;
1029     die unless @dirs==1;
1030     $dirs[0] =~ m#^([^/]+)/\.$# or die;
1031     my $dir = $1;
1032     changedir $dir;
1033     fail "source package contains .git directory" if stat_exists '.git';
1034     mktree_in_ud_here();
1035     my $format=get_source_format();
1036     if (madformat($format)) {
1037         rmtree '.pc';
1038     }
1039     runcmd @git, qw(add -Af);
1040     my $tree = cmdoutput @git, qw(write-tree);
1041     $tree =~ m/^\w+$/ or die "$tree ?";
1042     return ($tree,$dir);
1043 }
1044
1045 sub dsc_files_info () {
1046     foreach my $csumi (['Checksums-Sha256','Digest::SHA', 'new(256)'],
1047                        ['Checksums-Sha1',  'Digest::SHA', 'new(1)'],
1048                        ['Files',           'Digest::MD5', 'new()']) {
1049         my ($fname, $module, $method) = @$csumi;
1050         my $field = $dsc->{$fname};
1051         next unless defined $field;
1052         eval "use $module; 1;" or die $@;
1053         my @out;
1054         foreach (split /\n/, $field) {
1055             next unless m/\S/;
1056             m/^(\w+) (\d+) (\S+)$/ or
1057                 fail "could not parse .dsc $fname line \`$_'";
1058             my $digester = eval "$module"."->$method;" or die $@;
1059             push @out, {
1060                 Hash => $1,
1061                 Bytes => $2,
1062                 Filename => $3,
1063                 Digester => $digester,
1064             };
1065         }
1066         return @out;
1067     }
1068     fail "missing any supported Checksums-* or Files field in ".
1069         $dsc->get_option('name');
1070 }
1071
1072 sub dsc_files () {
1073     map { $_->{Filename} } dsc_files_info();
1074 }
1075
1076 sub is_orig_file ($;$) {
1077     local ($_) = $_[0];
1078     my $base = $_[1];
1079     m/\.orig(?:-\w+)?\.tar\.\w+$/ or return 0;
1080     defined $base or return 1;
1081     return $` eq $base;
1082 }
1083
1084 sub make_commit ($) {
1085     my ($file) = @_;
1086     return cmdoutput @git, qw(hash-object -w -t commit), $file;
1087 }
1088
1089 sub clogp_authline ($) {
1090     my ($clogp) = @_;
1091     my $author = getfield $clogp, 'Maintainer';
1092     $author =~ s#,.*##ms;
1093     my $date = cmdoutput qw(date), '+%s %z', qw(-d), getfield($clogp,'Date');
1094     my $authline = "$author $date";
1095     $authline =~ m/^[^<>]+ \<\S+\> \d+ [-+]\d+$/ or
1096         fail "unexpected commit author line format \`$authline'".
1097         " (was generated from changelog Maintainer field)";
1098     return $authline;
1099 }
1100
1101 sub generate_commit_from_dsc () {
1102     prep_ud();
1103     changedir $ud;
1104
1105     foreach my $fi (dsc_files_info()) {
1106         my $f = $fi->{Filename};
1107         die "$f ?" if $f =~ m#/|^\.|\.dsc$|\.tmp$#;
1108
1109         link "../../../$f", $f
1110             or $!==&ENOENT
1111             or die "$f $!";
1112
1113         complete_file_from_dsc('.', $fi);
1114
1115         if (is_orig_file($f)) {
1116             link $f, "../../../../$f"
1117                 or $!==&EEXIST
1118                 or die "$f $!";
1119         }
1120     }
1121
1122     my $dscfn = "$package.dsc";
1123
1124     open D, ">", $dscfn or die "$dscfn: $!";
1125     print D $dscdata or die "$dscfn: $!";
1126     close D or die "$dscfn: $!";
1127     my @cmd = qw(dpkg-source);
1128     push @cmd, '--no-check' if $dsc_checked;
1129     push @cmd, qw(-x --), $dscfn;
1130     runcmd @cmd;
1131
1132     my ($tree,$dir) = mktree_in_ud_from_only_subdir();
1133     runcmd qw(sh -ec), 'dpkg-parsechangelog >../changelog.tmp';
1134     my $clogp = parsecontrol('../changelog.tmp',"commit's changelog");
1135     my $authline = clogp_authline $clogp;
1136     my $changes = getfield $clogp, 'Changes';
1137     open C, ">../commit.tmp" or die $!;
1138     print C <<END or die $!;
1139 tree $tree
1140 author $authline
1141 committer $authline
1142
1143 $changes
1144
1145 # imported from the archive
1146 END
1147     close C or die $!;
1148     my $outputhash = make_commit qw(../commit.tmp);
1149     my $cversion = getfield $clogp, 'Version';
1150     progress "synthesised git commit from .dsc $cversion";
1151     if ($lastpush_hash) {
1152         runcmd @git, qw(reset --hard), $lastpush_hash;
1153         runcmd qw(sh -ec), 'dpkg-parsechangelog >>../changelogold.tmp';
1154         my $oldclogp = parsecontrol('../changelogold.tmp','previous changelog');
1155         my $oversion = getfield $oldclogp, 'Version';
1156         my $vcmp =
1157             version_compare($oversion, $cversion);
1158         if ($vcmp < 0) {
1159             # git upload/ is earlier vsn than archive, use archive
1160             open C, ">../commit2.tmp" or die $!;
1161             print C <<END or die $!;
1162 tree $tree
1163 parent $lastpush_hash
1164 parent $outputhash
1165 author $authline
1166 committer $authline
1167
1168 Record $package ($cversion) in archive suite $csuite
1169 END
1170             $outputhash = make_commit qw(../commit2.tmp);
1171         } elsif ($vcmp > 0) {
1172             print STDERR <<END or die $!;
1173
1174 Version actually in archive:    $cversion (older)
1175 Last allegedly pushed/uploaded: $oversion (newer or same)
1176 $later_warning_msg
1177 END
1178             $outputhash = $lastpush_hash;
1179         } else {
1180             $outputhash = $lastpush_hash;
1181         }
1182     }
1183     changedir '../../../..';
1184     runcmd @git, qw(update-ref -m),"dgit fetch import $cversion",
1185             'DGIT_ARCHIVE', $outputhash;
1186     cmdoutput @git, qw(log -n2), $outputhash;
1187     # ... gives git a chance to complain if our commit is malformed
1188     rmtree($ud);
1189     return $outputhash;
1190 }
1191
1192 sub complete_file_from_dsc ($$) {
1193     our ($dstdir, $fi) = @_;
1194     # Ensures that we have, in $dir, the file $fi, with the correct
1195     # contents.  (Downloading it from alongside $dscurl if necessary.)
1196
1197     my $f = $fi->{Filename};
1198     my $tf = "$dstdir/$f";
1199     my $downloaded = 0;
1200
1201     if (stat_exists $tf) {
1202         progress "using existing $f";
1203     } else {
1204         my $furl = $dscurl;
1205         $furl =~ s{/[^/]+$}{};
1206         $furl .= "/$f";
1207         die "$f ?" unless $f =~ m/^${package}_/;
1208         die "$f ?" if $f =~ m#/#;
1209         runcmd_ordryrun_local @curl,qw(-o),$tf,'--',"$furl";
1210         next if !act_local();
1211         $downloaded = 1;
1212     }
1213
1214     open F, "<", "$tf" or die "$tf: $!";
1215     $fi->{Digester}->reset();
1216     $fi->{Digester}->addfile(*F);
1217     F->error and die $!;
1218     my $got = $fi->{Digester}->hexdigest();
1219     $got eq $fi->{Hash} or
1220         fail "file $f has hash $got but .dsc".
1221             " demands hash $fi->{Hash} ".
1222             ($downloaded ? "(got wrong file from archive!)"
1223              : "(perhaps you should delete this file?)");
1224 }
1225
1226 sub ensure_we_have_orig () {
1227     foreach my $fi (dsc_files_info()) {
1228         my $f = $fi->{Filename};
1229         next unless is_orig_file($f);
1230         complete_file_from_dsc('..', $fi);
1231     }
1232 }
1233
1234 sub rev_parse ($) {
1235     return cmdoutput @git, qw(rev-parse), "$_[0]~0";
1236 }
1237
1238 sub is_fast_fwd ($$) {
1239     my ($ancestor,$child) = @_;
1240     my @cmd = (@git, qw(merge-base), $ancestor, $child);
1241     my $mb = cmdoutput_errok @cmd;
1242     if (defined $mb) {
1243         return rev_parse($mb) eq rev_parse($ancestor);
1244     } else {
1245         $?==256 or failedcmd @cmd;
1246         return 0;
1247     }
1248 }
1249
1250 sub git_fetch_us () {
1251     runcmd_ordryrun_local @git, qw(fetch),access_giturl(),fetchspec();
1252 }
1253
1254 sub fetch_from_archive () {
1255     # ensures that lrref() is what is actually in the archive,
1256     #  one way or another
1257     get_archive_dsc();
1258
1259     if ($dsc) {
1260         foreach my $field (@ourdscfield) {
1261             $dsc_hash = $dsc->{$field};
1262             last if defined $dsc_hash;
1263         }
1264         if (defined $dsc_hash) {
1265             $dsc_hash =~ m/\w+/ or fail "invalid hash in .dsc \`$dsc_hash'";
1266             $dsc_hash = $&;
1267             progress "last upload to archive specified git hash";
1268         } else {
1269             progress "last upload to archive has NO git hash";
1270         }
1271     } else {
1272         progress "no version available from the archive";
1273     }
1274
1275     $lastpush_hash = git_get_ref(lrref());
1276     printdebug "previous reference hash=$lastpush_hash\n";
1277     my $hash;
1278     if (defined $dsc_hash) {
1279         fail "missing remote git history even though dsc has hash -".
1280             " could not find ref ".lrref().
1281             " (should have been fetched from ".access_giturl()."#".rrref().")"
1282             unless $lastpush_hash;
1283         $hash = $dsc_hash;
1284         ensure_we_have_orig();
1285         if ($dsc_hash eq $lastpush_hash) {
1286         } elsif (is_fast_fwd($dsc_hash,$lastpush_hash)) {
1287             print STDERR <<END or die $!;
1288
1289 Git commit in archive is behind the last version allegedly pushed/uploaded.
1290 Commit referred to by archive:  $dsc_hash
1291 Last allegedly pushed/uploaded: $lastpush_hash
1292 $later_warning_msg
1293 END
1294             $hash = $lastpush_hash;
1295         } else {
1296             fail "archive's .dsc refers to ".$dsc_hash.
1297                 " but this is an ancestor of ".$lastpush_hash;
1298         }
1299     } elsif ($dsc) {
1300         $hash = generate_commit_from_dsc();
1301     } elsif ($lastpush_hash) {
1302         # only in git, not in the archive yet
1303         $hash = $lastpush_hash;
1304         print STDERR <<END or die $!;
1305
1306 Package not found in the archive, but has allegedly been pushed using dgit.
1307 $later_warning_msg
1308 END
1309     } else {
1310         printdebug "nothing found!\n";
1311         if (defined $skew_warning_vsn) {
1312             print STDERR <<END or die $!;
1313
1314 Warning: relevant archive skew detected.
1315 Archive allegedly contains $skew_warning_vsn
1316 But we were not able to obtain any version from the archive or git.
1317
1318 END
1319         }
1320         return 0;
1321     }
1322     printdebug "current hash=$hash\n";
1323     if ($lastpush_hash) {
1324         fail "not fast forward on last upload branch!".
1325             " (archive's version left in DGIT_ARCHIVE)"
1326             unless is_fast_fwd($lastpush_hash, $hash);
1327     }
1328     if (defined $skew_warning_vsn) {
1329         mkpath '.git/dgit';
1330         printdebug "SKEW CHECK WANT $skew_warning_vsn\n";
1331         my $clogf = ".git/dgit/changelog.tmp";
1332         runcmd shell_cmd "exec >$clogf",
1333             @git, qw(cat-file blob), "$hash:debian/changelog";
1334         my $gotclogp = parsechangelog("-l$clogf");
1335         my $got_vsn = getfield $gotclogp, 'Version';
1336         printdebug "SKEW CHECK GOT $got_vsn\n";
1337         if (version_compare($got_vsn, $skew_warning_vsn) < 0) {
1338             print STDERR <<END or die $!;
1339
1340 Warning: archive skew detected.  Using the available version:
1341 Archive allegedly contains    $skew_warning_vsn
1342 We were able to obtain only   $got_vsn
1343
1344 END
1345         }
1346     }
1347     if ($lastpush_hash ne $hash) {
1348         my @upd_cmd = (@git, qw(update-ref -m), 'dgit fetch', lrref(), $hash);
1349         if (act_local()) {
1350             cmdoutput @upd_cmd;
1351         } else {
1352             dryrun_report @upd_cmd;
1353         }
1354     }
1355     return 1;
1356 }
1357
1358 sub clone ($) {
1359     my ($dstdir) = @_;
1360     canonicalise_suite();
1361     badusage "dry run makes no sense with clone" unless act_local();
1362     mkdir $dstdir or die "$dstdir $!";
1363     changedir $dstdir;
1364     runcmd @git, qw(init -q);
1365     my $giturl = access_giturl(1);
1366     if (defined $giturl) {
1367         runcmd @git, qw(config), "remote.$remotename.fetch", fetchspec();
1368         open H, "> .git/HEAD" or die $!;
1369         print H "ref: ".lref()."\n" or die $!;
1370         close H or die $!;
1371         runcmd @git, qw(remote add), 'origin', $giturl;
1372     }
1373     if (check_for_git()) {
1374         progress "fetching existing git history";
1375         git_fetch_us();
1376         runcmd_ordryrun_local @git, qw(fetch origin);
1377     } else {
1378         progress "starting new git history";
1379     }
1380     fetch_from_archive() or no_such_package;
1381     my $vcsgiturl = $dsc->{'Vcs-Git'};
1382     if (length $vcsgiturl) {
1383         runcmd @git, qw(remote add vcs-git), $vcsgiturl;
1384     }
1385     runcmd @git, qw(reset --hard), lrref();
1386     printdone "ready for work in $dstdir";
1387 }
1388
1389 sub fetch () {
1390     if (check_for_git()) {
1391         git_fetch_us();
1392     }
1393     fetch_from_archive() or no_such_package();
1394     printdone "fetched into ".lrref();
1395 }
1396
1397 sub pull () {
1398     fetch();
1399     runcmd_ordryrun_local @git, qw(merge -m),"Merge from $csuite [dgit]",
1400         lrref();
1401     printdone "fetched to ".lrref()." and merged into HEAD";
1402 }
1403
1404 sub check_not_dirty () {
1405     return if $ignoredirty;
1406     my @cmd = (@git, qw(diff --quiet HEAD));
1407     printcmd(\*DEBUG,$debugprefix."+",@cmd) if $debug>0;
1408     $!=0; $?=0; system @cmd;
1409     return if !$! && !$?;
1410     if (!$! && $?==256) {
1411         fail "working tree is dirty (does not match HEAD)";
1412     } else {
1413         failedcmd @cmd;
1414     }
1415 }
1416
1417 sub commit_admin ($) {
1418     my ($m) = @_;
1419     progress "$m";
1420     runcmd_ordryrun_local @git, qw(commit -m), $m;
1421 }
1422
1423 sub commit_quilty_patch () {
1424     my $output = cmdoutput @git, qw(status --porcelain);
1425     my %adds;
1426     foreach my $l (split /\n/, $output) {
1427         next unless $l =~ m/\S/;
1428         if ($l =~ m{^(?:\?\?| M) (.pc|debian/patches)}) {
1429             $adds{$1}++;
1430         }
1431     }
1432     delete $adds{'.pc'}; # if there wasn't one before, don't add it
1433     if (!%adds) {
1434         progress "nothing quilty to commit, ok.";
1435         return;
1436     }
1437     runcmd_ordryrun_local @git, qw(add), sort keys %adds;
1438     commit_admin "Commit Debian 3.0 (quilt) metadata";
1439 }
1440
1441 sub get_source_format () {
1442     if (!open F, "debian/source/format") {
1443         die $! unless $!==&ENOENT;
1444         return '';
1445     }
1446     $_ = <F>;
1447     F->error and die $!;
1448     chomp;
1449     return $_;
1450 }
1451
1452 sub madformat ($) {
1453     my ($format) = @_;
1454     return 0 unless $format eq '3.0 (quilt)';
1455     if ($noquilt) {
1456         progress "Not doing any fixup of \`$format' due to --no-quilt-fixup";
1457         return 0;
1458     }
1459     progress "Format \`$format', checking/updating patch stack";
1460     return 1;
1461 }
1462
1463 sub push_parse_changelog ($) {
1464     my ($clogpfn) = @_;
1465
1466     my $clogp = Dpkg::Control::Hash->new();
1467     $clogp->load($clogpfn) or die;
1468
1469     $package = getfield $clogp, 'Source';
1470     my $cversion = getfield $clogp, 'Version';
1471     my $tag = debiantag($cversion);
1472     runcmd @git, qw(check-ref-format), $tag;
1473
1474     my $dscfn = dscfn($cversion);
1475
1476     return ($clogp, $cversion, $tag, $dscfn);
1477 }
1478
1479 sub push_parse_dsc ($$$) {
1480     my ($dscfn,$dscfnwhat, $cversion) = @_;
1481     $dsc = parsecontrol($dscfn,$dscfnwhat);
1482     my $dversion = getfield $dsc, 'Version';
1483     my $dscpackage = getfield $dsc, 'Source';
1484     ($dscpackage eq $package && $dversion eq $cversion) or
1485         fail "$dscfn is for $dscpackage $dversion".
1486             " but debian/changelog is for $package $cversion";
1487 }
1488
1489 sub push_mktag ($$$$$$$) {
1490     my ($head,$clogp,$tag,
1491         $dscfn,
1492         $changesfile,$changesfilewhat,
1493         $tfn) = @_;
1494
1495     $dsc->{$ourdscfield[0]} = $head;
1496     $dsc->save("$dscfn.tmp") or die $!;
1497
1498     my $changes = parsecontrol($changesfile,$changesfilewhat);
1499     foreach my $field (qw(Source Distribution Version)) {
1500         $changes->{$field} eq $clogp->{$field} or
1501             fail "changes field $field \`$changes->{$field}'".
1502                 " does not match changelog \`$clogp->{$field}'";
1503     }
1504
1505     my $cversion = getfield $clogp, 'Version';
1506     my $clogsuite = getfield $clogp, 'Distribution';
1507
1508     # We make the git tag by hand because (a) that makes it easier
1509     # to control the "tagger" (b) we can do remote signing
1510     my $authline = clogp_authline $clogp;
1511     open TO, '>', $tfn->('.tmp') or die $!;
1512     print TO <<END or die $!;
1513 object $head
1514 type commit
1515 tag $tag
1516 tagger $authline
1517
1518 $package release $cversion for $clogsuite ($csuite) [dgit]
1519 END
1520     close TO or die $!;
1521
1522     my $tagobjfn = $tfn->('.tmp');
1523     if ($sign) {
1524         if (!defined $keyid) {
1525             $keyid = access_cfg('keyid','RETURN-UNDEF');
1526         }
1527         unlink $tfn->('.tmp.asc') or $!==&ENOENT or die $!;
1528         my @sign_cmd = (@gpg, qw(--detach-sign --armor));
1529         push @sign_cmd, qw(-u),$keyid if defined $keyid;
1530         push @sign_cmd, $tfn->('.tmp');
1531         runcmd_ordryrun @sign_cmd;
1532         if (act_scary()) {
1533             $tagobjfn = $tfn->('.signed.tmp');
1534             runcmd shell_cmd "exec >$tagobjfn", qw(cat --),
1535                 $tfn->('.tmp'), $tfn->('.tmp.asc');
1536         }
1537     }
1538
1539     return ($tagobjfn);
1540 }
1541
1542 sub sign_changes ($) {
1543     my ($changesfile) = @_;
1544     if ($sign) {
1545         my @debsign_cmd = @debsign;
1546         push @debsign_cmd, "-k$keyid" if defined $keyid;
1547         push @debsign_cmd, "-p$gpg[0]" if $gpg[0] ne 'gpg';
1548         push @debsign_cmd, $changesfile;
1549         runcmd_ordryrun @debsign_cmd;
1550     }
1551 }
1552
1553 sub dopush () {
1554     printdebug "actually entering push\n";
1555     prep_ud();
1556
1557     access_giturl(); # check that success is vaguely likely
1558
1559     my $clogpfn = ".git/dgit/changelog.822.tmp";
1560     runcmd shell_cmd "exec >$clogpfn", qw(dpkg-parsechangelog);
1561
1562     responder_send_file('parsed-changelog', $clogpfn);
1563
1564     my ($clogp, $cversion, $tag, $dscfn) =
1565         push_parse_changelog("$clogpfn");
1566
1567     my $dscpath = "$buildproductsdir/$dscfn";
1568     stat_exists $dscpath or
1569         fail "looked for .dsc $dscfn, but $!;".
1570             " maybe you forgot to build";
1571
1572     responder_send_file('dsc', $dscpath);
1573
1574     push_parse_dsc($dscpath, $dscfn, $cversion);
1575
1576     my $format = getfield $dsc, 'Format';
1577     printdebug "format $format\n";
1578     if (madformat($format)) {
1579         commit_quilty_patch();
1580     }
1581     check_not_dirty();
1582     changedir $ud;
1583     progress "checking that $dscfn corresponds to HEAD";
1584     runcmd qw(dpkg-source -x --),
1585         $dscpath =~ m#^/# ? $dscpath : "../../../$dscpath";
1586     my ($tree,$dir) = mktree_in_ud_from_only_subdir();
1587     changedir '../../../..';
1588     my $diffopt = $debug>0 ? '--exit-code' : '--quiet';
1589     my @diffcmd = (@git, qw(diff), $diffopt, $tree);
1590     printcmd \*DEBUG,$debugprefix."+",@diffcmd;
1591     $!=0; $?=0;
1592     my $r = system @diffcmd;
1593     if ($r) {
1594         if ($r==256) {
1595             fail "$dscfn specifies a different tree to your HEAD commit;".
1596                 " perhaps you forgot to build".
1597                 ($diffopt eq '--exit-code' ? "" :
1598                  " (run with -D to see full diff output)");
1599         } else {
1600             failedcmd @diffcmd;
1601         }
1602     }
1603 #fetch from alioth
1604 #do fast forward check and maybe fake merge
1605 #    if (!is_fast_fwd(mainbranch
1606 #    runcmd @git, qw(fetch -p ), "$alioth_git/$package.git",
1607 #        map { lref($_).":".rref($_) }
1608 #        (uploadbranch());
1609     my $head = rev_parse('HEAD');
1610     if (!$changesfile) {
1611         my $multi = "$buildproductsdir/".
1612             "${package}_".(stripepoch $cversion)."_multi.changes";
1613         if (stat_exists "$multi") {
1614             $changesfile = $multi;
1615         } else {
1616             my $pat = "${package}_".(stripepoch $cversion)."_*.changes";
1617             my @cs = glob "$buildproductsdir/$pat";
1618             fail "failed to find unique changes file".
1619                 " (looked for $pat in $buildproductsdir, or $multi);".
1620                 " perhaps you need to use dgit -C"
1621                 unless @cs==1;
1622             ($changesfile) = @cs;
1623         }
1624     } else {
1625         $changesfile = "$buildproductsdir/$changesfile";
1626     }
1627
1628     responder_send_file('changes',$changesfile);
1629     responder_send_command("param head $head");
1630     responder_send_command("param csuite $csuite");
1631
1632     my $tfn = sub { ".git/dgit/tag$_[0]"; };
1633     my $tagobjfn;
1634
1635     if ($we_are_responder) {
1636         $tagobjfn = $tfn->('.signed.tmp');
1637         responder_receive_files('signed-tag', $tagobjfn);
1638     } else {
1639         $tagobjfn =
1640             push_mktag($head,$clogp,$tag,
1641                        $dscpath,
1642                        $changesfile,$changesfile,
1643                        $tfn);
1644     }
1645
1646     my $tag_obj_hash = cmdoutput @git, qw(hash-object -w -t tag), $tagobjfn;
1647     runcmd_ordryrun @git, qw(verify-tag), $tag_obj_hash;
1648     runcmd_ordryrun_local @git, qw(update-ref), "refs/tags/$tag", $tag_obj_hash;
1649     runcmd_ordryrun @git, qw(tag -v --), $tag;
1650
1651     if (!check_for_git()) {
1652         create_remote_git_repo();
1653     }
1654     runcmd_ordryrun @git, qw(push),access_giturl(),
1655         "HEAD:".rrref(), "refs/tags/$tag";
1656     runcmd_ordryrun @git, qw(update-ref -m), 'dgit push', lrref(), 'HEAD';
1657
1658     if ($we_are_responder) {
1659         my $dryrunsuffix = act_local() ? "" : ".tmp";
1660         responder_receive_files('signed-dsc-changes',
1661                                 "$dscpath$dryrunsuffix",
1662                                 "$changesfile$dryrunsuffix");
1663     } else {
1664         if (act_local()) {
1665             rename "$dscpath.tmp",$dscpath or die "$dscfn $!";
1666         } else {
1667             progress "[new .dsc left in $dscpath.tmp]";
1668         }
1669         sign_changes $changesfile;
1670     }
1671
1672     my $host = access_cfg('upload-host','RETURN-UNDEF');
1673     my @hostarg = defined($host) ? ($host,) : ();
1674     runcmd_ordryrun @dput, @hostarg, $changesfile;
1675     printdone "pushed and uploaded $cversion";
1676
1677     responder_send_command("complete");
1678 }
1679
1680 sub cmd_clone {
1681     parseopts();
1682     my $dstdir;
1683     badusage "-p is not allowed with clone; specify as argument instead"
1684         if defined $package;
1685     if (@ARGV==1) {
1686         ($package) = @ARGV;
1687     } elsif (@ARGV==2 && $ARGV[1] =~ m#^\w#) {
1688         ($package,$isuite) = @ARGV;
1689     } elsif (@ARGV==2 && $ARGV[1] =~ m#^[./]#) {
1690         ($package,$dstdir) = @ARGV;
1691     } elsif (@ARGV==3) {
1692         ($package,$isuite,$dstdir) = @ARGV;
1693     } else {
1694         badusage "incorrect arguments to dgit clone";
1695     }
1696     $dstdir ||= "$package";
1697
1698     if (stat_exists $dstdir) {
1699         fail "$dstdir already exists";
1700     }
1701
1702     my $cwd_remove;
1703     if ($rmonerror && !$dryrun_level) {
1704         $cwd_remove= getcwd();
1705         unshift @end, sub {
1706             return unless defined $cwd_remove;
1707             if (!chdir "$cwd_remove") {
1708                 return if $!==&ENOENT;
1709                 die "chdir $cwd_remove: $!";
1710             }
1711             rmtree($dstdir) or die "remove $dstdir: $!\n";
1712         };
1713     }
1714
1715     clone($dstdir);
1716     $cwd_remove = undef;
1717 }
1718
1719 sub branchsuite () {
1720     my $branch = cmdoutput_errok @git, qw(symbolic-ref HEAD);
1721     if ($branch =~ m#$lbranch_re#o) {
1722         return $1;
1723     } else {
1724         return undef;
1725     }
1726 }
1727
1728 sub fetchpullargs () {
1729     if (!defined $package) {
1730         my $sourcep = parsecontrol('debian/control','debian/control');
1731         $package = getfield $sourcep, 'Source';
1732     }
1733     if (@ARGV==0) {
1734 #       $isuite = branchsuite();  # this doesn't work because dak hates canons
1735         if (!$isuite) {
1736             my $clogp = parsechangelog();
1737             $isuite = getfield $clogp, 'Distribution';
1738         }
1739         canonicalise_suite();
1740         progress "fetching from suite $csuite";
1741     } elsif (@ARGV==1) {
1742         ($isuite) = @ARGV;
1743         canonicalise_suite();
1744     } else {
1745         badusage "incorrect arguments to dgit fetch or dgit pull";
1746     }
1747 }
1748
1749 sub cmd_fetch {
1750     parseopts();
1751     fetchpullargs();
1752     fetch();
1753 }
1754
1755 sub cmd_pull {
1756     parseopts();
1757     fetchpullargs();
1758     pull();
1759 }
1760
1761 sub cmd_push {
1762     parseopts();
1763     badusage "-p is not allowed with dgit push" if defined $package;
1764     check_not_dirty();
1765     my $clogp = parsechangelog();
1766     $package = getfield $clogp, 'Source';
1767     my $specsuite;
1768     if (@ARGV==0) {
1769     } elsif (@ARGV==1) {
1770         ($specsuite) = (@ARGV);
1771     } else {
1772         badusage "incorrect arguments to dgit push";
1773     }
1774     $isuite = getfield $clogp, 'Distribution';
1775     if ($new_package) {
1776         local ($package) = $existing_package; # this is a hack
1777         canonicalise_suite();
1778     }
1779     if (defined $specsuite && $specsuite ne $isuite) {
1780         canonicalise_suite();
1781         $csuite eq $specsuite or
1782             fail "dgit push: changelog specifies $isuite ($csuite)".
1783                 " but command line specifies $specsuite";
1784     }
1785     if (check_for_git()) {
1786         git_fetch_us();
1787     }
1788     if (fetch_from_archive()) {
1789         is_fast_fwd(lrref(), 'HEAD') or
1790             fail "dgit push: HEAD is not a descendant".
1791                 " of the archive's version.\n".
1792                 "$us: To overwrite it, use git merge -s ours ".lrref().".";
1793     } else {
1794         $new_package or
1795             fail "package appears to be new in this suite;".
1796                 " if this is intentional, use --new";
1797     }
1798     dopush();
1799 }
1800
1801 #---------- remote commands' implementation ----------
1802
1803 sub cmd_remote_push_build_host {
1804     my ($nrargs) = shift @ARGV;
1805     my (@rargs) = @ARGV[0..$nrargs-1];
1806     @ARGV = @ARGV[$nrargs..$#ARGV];
1807     die unless @rargs;
1808     my ($dir,$vsnwant) = @rargs;
1809     # vsnwant is a comma-separated list; we report which we have
1810     # chosen in our ready response (so other end can tell if they
1811     # offered several)
1812     $debugprefix = ' ';
1813     $we_are_responder = 1;
1814
1815     open PI, "<&STDIN" or die $!;
1816     open STDIN, "/dev/null" or die $!;
1817     open PO, ">&STDOUT" or die $!;
1818     autoflush PO 1;
1819     open STDOUT, ">&STDERR" or die $!;
1820     autoflush STDOUT 1;
1821
1822     $vsnwant //= 1;
1823     fail "build host has dgit rpush protocol version".
1824         " $rpushprotovsn but invocation host has $vsnwant"
1825         unless grep { $rpushprotovsn eq $_ } split /,/, $vsnwant;
1826
1827     responder_send_command("dgit-remote-push-ready $rpushprotovsn");
1828
1829     changedir $dir;
1830     &cmd_push;
1831 }
1832
1833 sub cmd_remote_push_responder { cmd_remote_push_build_host(); }
1834 # ... for compatibility with proto vsn.1 dgit (just so that user gets
1835 #     a good error message)
1836
1837 our $i_tmp;
1838
1839 sub i_cleanup {
1840     local ($@, $?);
1841     my $report = i_child_report();
1842     if (defined $report) {
1843         printdebug "($report)\n";
1844     } elsif ($i_child_pid) {
1845         printdebug "(killing build host child $i_child_pid)\n";
1846         kill 15, $i_child_pid;
1847     }
1848     if (defined $i_tmp && !defined $initiator_tempdir) {
1849         changedir "/";
1850         eval { rmtree $i_tmp; };
1851     }
1852 }
1853
1854 END { i_cleanup(); }
1855
1856 sub i_method {
1857     my ($base,$selector,@args) = @_;
1858     $selector =~ s/\-/_/g;
1859     { no strict qw(refs); &{"${base}_${selector}"}(@args); }
1860 }
1861
1862 sub cmd_rpush {
1863     my $host = nextarg;
1864     my $dir;
1865     if ($host =~ m/^((?:[^][]|\[[^][]*\])*)\:/) {
1866         $host = $1;
1867         $dir = $'; #';
1868     } else {
1869         $dir = nextarg;
1870     }
1871     $dir =~ s{^-}{./-};
1872     my @rargs = ($dir,$rpushprotovsn);
1873     my @rdgit;
1874     push @rdgit, @dgit;
1875     push @rdgit, @ropts;
1876     push @rdgit, qw(remote-push-build-host), (scalar @rargs), @rargs;
1877     push @rdgit, @ARGV;
1878     my @cmd = (@ssh, $host, shellquote @rdgit);
1879     printcmd \*DEBUG,$debugprefix."+",@cmd;
1880
1881     if (defined $initiator_tempdir) {
1882         rmtree $initiator_tempdir;
1883         mkdir $initiator_tempdir, 0700 or die "$initiator_tempdir: $!";
1884         $i_tmp = $initiator_tempdir;
1885     } else {
1886         $i_tmp = tempdir();
1887     }
1888     $i_child_pid = open2(\*RO, \*RI, @cmd);
1889     changedir $i_tmp;
1890     initiator_expect { m/^dgit-remote-push-ready/ };
1891     for (;;) {
1892         my ($icmd,$iargs) = initiator_expect {
1893             m/^(\S+)(?: (.*))?$/;
1894             ($1,$2);
1895         };
1896         i_method "i_resp", $icmd, $iargs;
1897     }
1898 }
1899
1900 sub i_resp_progress ($) {
1901     my ($rhs) = @_;
1902     my $msg = protocol_read_bytes \*RO, $rhs;
1903     progress $msg;
1904 }
1905
1906 sub i_resp_complete {
1907     my $pid = $i_child_pid;
1908     $i_child_pid = undef; # prevents killing some other process with same pid
1909     printdebug "waiting for build host child $pid...\n";
1910     my $got = waitpid $pid, 0;
1911     die $! unless $got == $pid;
1912     die "build host child failed $?" if $?;
1913
1914     i_cleanup();
1915     printdebug "all done\n";
1916     exit 0;
1917 }
1918
1919 sub i_resp_file ($) {
1920     my ($keyword) = @_;
1921     my $localname = i_method "i_localname", $keyword;
1922     my $localpath = "$i_tmp/$localname";
1923     stat_exists $localpath and
1924         badproto \*RO, "file $keyword ($localpath) twice";
1925     protocol_receive_file \*RO, $localpath;
1926     i_method "i_file", $keyword;
1927 }
1928
1929 our %i_param;
1930
1931 sub i_resp_param ($) {
1932     $_[0] =~ m/^(\S+) (.*)$/ or badproto \*RO, "bad param spec";
1933     $i_param{$1} = $2;
1934 }
1935
1936 our %i_wanted;
1937
1938 sub i_resp_want ($) {
1939     my ($keyword) = @_;
1940     die "$keyword ?" if $i_wanted{$keyword}++;
1941     my @localpaths = i_method "i_want", $keyword;
1942     printdebug "[[  $keyword @localpaths\n";
1943     foreach my $localpath (@localpaths) {
1944         protocol_send_file \*RI, $localpath;
1945     }
1946     print RI "files-end\n" or die $!;
1947 }
1948
1949 our ($i_clogp, $i_version, $i_tag, $i_dscfn, $i_changesfn);
1950
1951 sub i_localname_parsed_changelog {
1952     return "remote-changelog.822";
1953 }
1954 sub i_file_parsed_changelog {
1955     ($i_clogp, $i_version, $i_tag, $i_dscfn) =
1956         push_parse_changelog "$i_tmp/remote-changelog.822";
1957     die if $i_dscfn =~ m#/|^\W#;
1958 }
1959
1960 sub i_localname_dsc {
1961     defined $i_dscfn or badproto \*RO, "dsc (before parsed-changelog)";
1962     return $i_dscfn;
1963 }
1964 sub i_file_dsc { }
1965
1966 sub i_localname_changes {
1967     defined $i_dscfn or badproto \*RO, "dsc (before parsed-changelog)";
1968     $i_changesfn = $i_dscfn;
1969     $i_changesfn =~ s/\.dsc$/_dgit.changes/ or die;
1970     return $i_changesfn;
1971 }
1972 sub i_file_changes { }
1973
1974 sub i_want_signed_tag {
1975     printdebug Dumper(\%i_param, $i_dscfn);
1976     defined $i_param{'head'} && defined $i_dscfn && defined $i_clogp
1977         && defined $i_param{'csuite'}
1978         or badproto \*RO, "premature desire for signed-tag";
1979     my $head = $i_param{'head'};
1980     die if $head =~ m/[^0-9a-f]/ || $head !~ m/^../;
1981
1982     die unless $i_param{'csuite'} =~ m/^$suite_re$/;
1983     $csuite = $&;
1984     push_parse_dsc $i_dscfn, 'remote dsc', $i_version;
1985
1986     my $tagobjfn =
1987         push_mktag $head, $i_clogp, $i_tag,
1988             $i_dscfn,
1989             $i_changesfn, 'remote changes',
1990             sub { "tag$_[0]"; };
1991
1992     return $tagobjfn;
1993 }
1994
1995 sub i_want_signed_dsc_changes {
1996     rename "$i_dscfn.tmp","$i_dscfn" or die "$i_dscfn $!";
1997     sign_changes $i_changesfn;
1998     return ($i_dscfn, $i_changesfn);
1999 }
2000
2001 #---------- building etc. ----------
2002
2003 our $version;
2004 our $sourcechanges;
2005 our $dscfn;
2006
2007 our $fakeeditorenv = 'DGIT_FAKE_EDITOR_QUILT';
2008
2009 sub build_maybe_quilt_fixup () {
2010     my $format=get_source_format;
2011     return unless madformat $format;
2012     # sigh
2013
2014     # Our objective is:
2015     #  - honour any existing .pc in case it has any strangeness
2016     #  - determine the git commit corresponding to the tip of
2017     #    the patch stack (if there is one)
2018     #  - if there is such a git commit, convert each subsequent
2019     #    git commit into a quilt patch with dpkg-source --commit
2020     #  - otherwise convert all the differences in the tree into
2021     #    a single git commit
2022     #
2023     # To do this we:
2024
2025     # Our git tree doesn't necessarily contain .pc.  (Some versions of
2026     # dgit would include the .pc in the git tree.)  If there isn't
2027     # one, we need to generate one by unpacking the patches that we
2028     # have.
2029     #
2030     # We first look for a .pc in the git tree.  If there is one, we
2031     # will use it.  (This is not the normal case.)
2032     #
2033     # Otherwise need to regenerate .pc so that dpkg-source --commit
2034     # can work.  We do this as follows:
2035     #     1. Collect all relevant .orig from parent directory
2036     #     2. Generate a debian.tar.gz out of
2037     #         debian/{patches,rules,source/format}
2038     #     3. Generate a fake .dsc containing just these fields:
2039     #          Format Source Version Files
2040     #     4. Extract the fake .dsc
2041     #        Now the fake .dsc has a .pc directory.
2042     # (In fact we do this in every case, because in future we will
2043     # want to search for a good base commit for generating patches.)
2044     #
2045     # Then we can actually do the dpkg-source --commit
2046     #     1. Make a new working tree with the same object
2047     #        store as our main tree and check out the main
2048     #        tree's HEAD.
2049     #     2. Copy .pc from the fake's extraction, if necessary
2050     #     3. Run dpkg-source --commit
2051     #     4. If the result has changes to debian/, then
2052     #          - git-add them them
2053     #          - git-add .pc if we had a .pc in-tree
2054     #          - git-commit
2055     #     5. If we had a .pc in-tree, delete it, and git-commit
2056     #     6. Back in the main tree, fast forward to the new HEAD
2057
2058     my $clogp = parsechangelog();
2059     my $headref = rev_parse('HEAD');
2060
2061     prep_ud();
2062     changedir $ud;
2063
2064     my $upstreamversion=$version;
2065     $upstreamversion =~ s/-[^-]*$//;
2066
2067     my $fakeversion="$upstreamversion-~~DGITFAKE";
2068
2069     my $fakedsc=new IO::File 'fake.dsc', '>' or die $!;
2070     print $fakedsc <<END or die $!;
2071 Format: 3.0 (quilt)
2072 Source: $package
2073 Version: $fakeversion
2074 Files:
2075 END
2076
2077     my $dscaddfile=sub {
2078         my ($b) = @_;
2079
2080         my $md = new Digest::MD5;
2081
2082         my $fh = new IO::File $b, '<' or die "$b $!";
2083         stat $fh or die $!;
2084         my $size = -s _;
2085
2086         $md->addfile($fh);
2087         print $fakedsc " ".$md->hexdigest." $size $b\n" or die $!;
2088     };
2089
2090     foreach my $f (<../../../../*>) { #/){
2091         my $b=$f; $b =~ s{.*/}{};
2092         next unless is_orig_file $b, srcfn $upstreamversion,'';
2093         link $f, $b or die "$b $!";
2094         $dscaddfile->($b);
2095     }
2096
2097     my @files=qw(debian/source/format debian/rules);
2098     if (stat_exists '../../../debian/patches') {
2099         push @files, 'debian/patches';
2100     }
2101
2102     my $debtar= srcfn $fakeversion,'.debian.tar.gz';
2103     runcmd qw(env GZIP=-1 tar -zcf), "./$debtar", qw(-C ../../..), @files;
2104
2105     $dscaddfile->($debtar);
2106     close $fakedsc or die $!;
2107
2108     runcmd qw(sh -ec), 'exec dpkg-source --no-check -x fake.dsc >/dev/null';
2109
2110     my $fakexdir= $package.'-'.(stripepoch $upstreamversion);
2111     rename $fakexdir, "fake" or die "$fakexdir $!";
2112
2113     mkdir "work" or die $!;
2114     changedir "work";
2115     mktree_in_ud_here();
2116     runcmd @git, qw(reset --hard), $headref;
2117
2118     my $mustdeletepc=0;
2119     if (stat_exists ".pc") {
2120         -d _ or die;
2121         progress "Tree already contains .pc - will use it then delete it.";
2122         $mustdeletepc=1;
2123     } else {
2124         rename '../fake/.pc','.pc' or die $!;
2125     }
2126
2127     my $author = getfield $clogp, 'Maintainer';
2128     my $time = time;
2129     my $ncommits = 3;
2130     my $patchname = "auto-$version-$headref-$time";
2131     my $msg = cmdoutput @git, qw(log), "-n$ncommits";
2132     mkpath '.git/dgit';
2133     my $descfn = ".git/dgit/quilt-description.tmp";
2134     open O, '>', $descfn or die "$descfn: $!";
2135     $msg =~ s/\n/\n /g;
2136     $msg =~ s/^\s+$/ ./mg;
2137     print O <<END or die $!;
2138 Description: Automatically generated patch ($clogp->{Version})
2139  Last (up to) $ncommits git changes, FYI:
2140  .
2141  $msg
2142 Author: $author
2143
2144 ---
2145
2146 END
2147     close O or die $!;
2148     {
2149         local $ENV{'EDITOR'} = cmdoutput qw(realpath --), $0;
2150         local $ENV{'VISUAL'} = $ENV{'EDITOR'};
2151         local $ENV{$fakeeditorenv} = cmdoutput qw(realpath --), $descfn;
2152         runcmd_ordryrun_local @dpkgsource, qw(--commit .), $patchname;
2153     }
2154
2155     if (!open P, '>>', ".pc/applied-patches") {
2156         $!==&ENOENT or die $!;
2157     } else {
2158         close P;
2159     }
2160
2161     commit_quilty_patch();
2162
2163     if ($mustdeletepc) {
2164         runcmd @git, qw(rm -rq .pc);
2165         commit_admin "Commit removal of .pc (quilt series tracking data)";
2166     }
2167
2168     changedir '../../../..';
2169     runcmd @git, qw(pull --ff-only -q .git/dgit/unpack/work master);
2170 }
2171
2172 sub quilt_fixup_editor () {
2173     my $descfn = $ENV{$fakeeditorenv};
2174     my $editing = $ARGV[$#ARGV];
2175     open I1, '<', $descfn or die "$descfn: $!";
2176     open I2, '<', $editing or die "$editing: $!";
2177     unlink $editing or die "$editing: $!";
2178     open O, '>', $editing or die "$editing: $!";
2179     while (<I1>) { print O or die $!; } I1->error and die $!;
2180     my $copying = 0;
2181     while (<I2>) {
2182         $copying ||= m/^\-\-\- /;
2183         next unless $copying;
2184         print O or die $!;
2185     }
2186     I2->error and die $!;
2187     close O or die $1;
2188     exit 0;
2189 }
2190
2191 sub clean_tree () {
2192     if ($cleanmode eq 'dpkg-source') {
2193         runcmd_ordryrun_local @dpkgbuildpackage, qw(-T clean);
2194     } elsif ($cleanmode eq 'git') {
2195         runcmd_ordryrun_local @git, qw(clean -xdf);
2196     } elsif ($cleanmode eq 'none') {
2197     } else {
2198         die "$cleanmode ?";
2199     }
2200 }
2201
2202 sub cmd_clean () {
2203     badusage "clean takes no additional arguments" if @ARGV;
2204     clean_tree();
2205 }
2206
2207 sub build_prep () {
2208     badusage "-p is not allowed when building" if defined $package;
2209     check_not_dirty();
2210     clean_tree();
2211     my $clogp = parsechangelog();
2212     $isuite = getfield $clogp, 'Distribution';
2213     $package = getfield $clogp, 'Source';
2214     $version = getfield $clogp, 'Version';
2215     build_maybe_quilt_fixup();
2216 }
2217
2218 sub changesopts () {
2219     my @opts =@changesopts[1..$#changesopts];
2220     if (!defined $changes_since_version) {
2221         my @vsns = archive_query('archive_query');
2222         my @quirk = access_quirk();
2223         if ($quirk[0] eq 'backports') {
2224             local $isuite = $quirk[2];
2225             local $csuite;
2226             canonicalise_suite();
2227             push @vsns, archive_query('archive_query');
2228         }
2229         if (@vsns) {
2230             @vsns = map { $_->[0] } @vsns;
2231             @vsns = sort { -version_compare($a, $b) } @vsns;
2232             $changes_since_version = $vsns[0];
2233             progress "changelog will contain changes since $vsns[0]";
2234         } else {
2235             $changes_since_version = '_';
2236             progress "package seems new, not specifying -v<version>";
2237         }
2238     }
2239     if ($changes_since_version ne '_') {
2240         unshift @opts, "-v$changes_since_version";
2241     }
2242     return @opts;
2243 }
2244
2245 sub cmd_build {
2246     build_prep();
2247     runcmd_ordryrun_local @dpkgbuildpackage, qw(-us -uc), changesopts(), @ARGV;
2248     printdone "build successful\n";
2249 }
2250
2251 sub cmd_git_build {
2252     build_prep();
2253     my @cmd =
2254         (qw(git-buildpackage -us -uc --git-no-sign-tags),
2255          "--git-builder=@dpkgbuildpackage");
2256     unless (grep { m/^--git-debian-branch|^--git-ignore-branch/ } @ARGV) {
2257         canonicalise_suite();
2258         push @cmd, "--git-debian-branch=".lbranch();
2259     }
2260     push @cmd, changesopts();
2261     runcmd_ordryrun_local @cmd, @ARGV;
2262     printdone "build successful\n";
2263 }
2264
2265 sub build_source {
2266     build_prep();
2267     $sourcechanges = "${package}_".(stripepoch $version)."_source.changes";
2268     $dscfn = dscfn($version);
2269     if ($cleanmode eq 'dpkg-source') {
2270         runcmd_ordryrun_local (@dpkgbuildpackage, qw(-us -uc -S)),
2271             changesopts();
2272     } else {
2273         my $pwd = must_getcwd();
2274         my $leafdir = basename $pwd;
2275         changedir "..";
2276         runcmd_ordryrun_local @dpkgsource, qw(-b --), $leafdir;
2277         changedir $pwd;
2278         runcmd_ordryrun_local qw(sh -ec),
2279             'exec >$1; shift; exec "$@"','x',
2280             "../$sourcechanges",
2281             @dpkggenchanges, qw(-S), changesopts();
2282     }
2283 }
2284
2285 sub cmd_build_source {
2286     badusage "build-source takes no additional arguments" if @ARGV;
2287     build_source();
2288     printdone "source built, results in $dscfn and $sourcechanges";
2289 }
2290
2291 sub cmd_sbuild {
2292     build_source();
2293     changedir "..";
2294     my $pat = "${package}_".(stripepoch $version)."_*.changes";
2295     if (act_local()) {
2296         stat_exist $dscfn or fail "$dscfn (in parent directory): $!";
2297         stat_exists $sourcechanges
2298             or fail "$sourcechanges (in parent directory): $!";
2299         foreach my $cf (glob $pat) {
2300             next if $cf eq $sourcechanges;
2301             unlink $cf or fail "remove $cf: $!";
2302         }
2303     }
2304     runcmd_ordryrun_local @sbuild, @ARGV, qw(-d), $isuite, $dscfn;
2305     my @changesfiles = glob $pat;
2306     @changesfiles = sort {
2307         ($b =~ m/_source\.changes$/ <=> $a =~ m/_source\.changes$/)
2308             or $a cmp $b
2309     } @changesfiles;
2310     fail "wrong number of different changes files (@changesfiles)"
2311         unless @changesfiles;
2312     runcmd_ordryrun_local @mergechanges, @changesfiles;
2313     my $multichanges = "${package}_".(stripepoch $version)."_multi.changes";
2314     if (act_local()) {
2315         stat_exists $multichanges or fail "$multichanges: $!";
2316     }
2317     printdone "build successful, results in $multichanges\n" or die $!;
2318 }
2319
2320 sub cmd_quilt_fixup {
2321     badusage "incorrect arguments to dgit quilt-fixup" if @ARGV;
2322     my $clogp = parsechangelog();
2323     $version = getfield $clogp, 'Version';
2324     $package = getfield $clogp, 'Source';
2325     build_maybe_quilt_fixup();
2326 }
2327
2328 #---------- argument parsing and main program ----------
2329
2330 sub cmd_version {
2331     print "dgit version $our_version\n" or die $!;
2332     exit 0;
2333 }
2334
2335 sub parseopts () {
2336     my $om;
2337
2338     if (defined $ENV{'DGIT_SSH'}) {
2339         @ssh = string_to_ssh $ENV{'DGIT_SSH'};
2340     } elsif (defined $ENV{'GIT_SSH'}) {
2341         @ssh = ($ENV{'GIT_SSH'});
2342     }
2343
2344     while (@ARGV) {
2345         last unless $ARGV[0] =~ m/^-/;
2346         $_ = shift @ARGV;
2347         last if m/^--?$/;
2348         if (m/^--/) {
2349             if (m/^--dry-run$/) {
2350                 push @ropts, $_;
2351                 $dryrun_level=2;
2352             } elsif (m/^--damp-run$/) {
2353                 push @ropts, $_;
2354                 $dryrun_level=1;
2355             } elsif (m/^--no-sign$/) {
2356                 push @ropts, $_;
2357                 $sign=0;
2358             } elsif (m/^--help$/) {
2359                 cmd_help();
2360             } elsif (m/^--version$/) {
2361                 cmd_version();
2362             } elsif (m/^--new$/) {
2363                 push @ropts, $_;
2364                 $new_package=1;
2365             } elsif (m/^--since-version=([^_]+|_)$/) {
2366                 push @ropts, $_;
2367                 $changes_since_version = $1;
2368             } elsif (m/^--([-0-9a-z]+)=(.*)/s &&
2369                      ($om = $opts_opt_map{$1}) &&
2370                      length $om->[0]) {
2371                 push @ropts, $_;
2372                 $om->[0] = $2;
2373             } elsif (m/^--([-0-9a-z]+):(.*)/s &&
2374                      !$opts_opt_cmdonly{$1} &&
2375                      ($om = $opts_opt_map{$1})) {
2376                 push @ropts, $_;
2377                 push @$om, $2;
2378             } elsif (m/^--existing-package=(.*)/s) {
2379                 push @ropts, $_;
2380                 $existing_package = $1;
2381             } elsif (m/^--initiator-tempdir=(.*)/s) {
2382                 $initiator_tempdir = $1;
2383                 $initiator_tempdir =~ m#^/# or
2384                     badusage "--initiator-tempdir must be used specify an".
2385                         " absolute, not relative, directory."
2386             } elsif (m/^--distro=(.*)/s) {
2387                 push @ropts, $_;
2388                 $idistro = $1;
2389             } elsif (m/^--build-products-dir=(.*)/s) {
2390                 push @ropts, $_;
2391                 $buildproductsdir = $1;
2392             } elsif (m/^--clean=(dpkg-source|git|none)$/s) {
2393                 push @ropts, $_;
2394                 $cleanmode = $1;
2395             } elsif (m/^--clean=(.*)$/s) {
2396                 badusage "unknown cleaning mode \`$1'";
2397             } elsif (m/^--ignore-dirty$/s) {
2398                 push @ropts, $_;
2399                 $ignoredirty = 1;
2400             } elsif (m/^--no-quilt-fixup$/s) {
2401                 push @ropts, $_;
2402                 $noquilt = 1;
2403             } elsif (m/^--no-rm-on-error$/s) {
2404                 push @ropts, $_;
2405                 $rmonerror = 0;
2406             } else {
2407                 badusage "unknown long option \`$_'";
2408             }
2409         } else {
2410             while (m/^-./s) {
2411                 if (s/^-n/-/) {
2412                     push @ropts, $&;
2413                     $dryrun_level=2;
2414                 } elsif (s/^-L/-/) {
2415                     push @ropts, $&;
2416                     $dryrun_level=1;
2417                 } elsif (s/^-h/-/) {
2418                     cmd_help();
2419                 } elsif (s/^-D/-/) {
2420                     push @ropts, $&;
2421                     open DEBUG, ">&STDERR" or die $!;
2422                     autoflush DEBUG 1;
2423                     $debug++;
2424                 } elsif (s/^-N/-/) {
2425                     push @ropts, $&;
2426                     $new_package=1;
2427                 } elsif (s/^-v([^_]+|_)$//s) {
2428                     push @ropts, $&;
2429                     $changes_since_version = $1;
2430                 } elsif (m/^-m/) {
2431                     push @ropts, $&;
2432                     push @changesopts, $_;
2433                     $_ = '';
2434                 } elsif (s/^-c(.*=.*)//s) {
2435                     push @ropts, $&;
2436                     push @git, '-c', $1;
2437                 } elsif (s/^-d(.*)//s) {
2438                     push @ropts, $&;
2439                     $idistro = $1;
2440                 } elsif (s/^-C(.*)//s) {
2441                     push @ropts, $&;
2442                     $changesfile = $1;
2443                     if ($changesfile =~ s#^(.*)/##) {
2444                         $buildproductsdir = $1;
2445                     }
2446                 } elsif (s/^-k(.*)//s) {
2447                     $keyid=$1;
2448                 } elsif (s/^-wn//s) {
2449                     push @ropts, $&;
2450                     $cleanmode = 'none';
2451                 } elsif (s/^-wg//s) {
2452                     push @ropts, $&;
2453                     $cleanmode = 'git';
2454                 } elsif (s/^-wd//s) {
2455                     push @ropts, $&;
2456                     $cleanmode = 'dpkg-source';
2457                 } else {
2458                     badusage "unknown short option \`$_'";
2459                 }
2460             }
2461         }
2462     }
2463 }
2464
2465 if ($ENV{$fakeeditorenv}) {
2466     quilt_fixup_editor();
2467 }
2468
2469 parseopts();
2470 print STDERR "DRY RUN ONLY\n" if $dryrun_level > 1;
2471 print STDERR "DAMP RUN - WILL MAKE LOCAL (UNSIGNED) CHANGES\n"
2472     if $dryrun_level == 1;
2473 if (!@ARGV) {
2474     print STDERR $helpmsg or die $!;
2475     exit 8;
2476 }
2477 my $cmd = shift @ARGV;
2478 $cmd =~ y/-/_/;
2479
2480 my $fn = ${*::}{"cmd_$cmd"};
2481 $fn or badusage "unknown operation $cmd";
2482 $fn->();