chiark / gitweb /
Split brain: Add some debug relating to tagwants
[dgit.git] / dgit
1 #!/usr/bin/perl -w
2 # dgit
3 # Integration between git and Debian-style archives
4 #
5 # Copyright (C)2013-2015 Ian Jackson
6 #
7 # This program is free software: you can redistribute it and/or modify
8 # it under the terms of the GNU General Public License as published by
9 # the Free Software Foundation, either version 3 of the License, or
10 # (at your option) any later version.
11 #
12 # This program is distributed in the hope that it will be useful,
13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
15 # GNU General Public License for more details.
16 #
17 # You should have received a copy of the GNU General Public License
18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
19
20 use strict;
21
22 use Debian::Dgit;
23 setup_sigwarn();
24
25 use IO::Handle;
26 use Data::Dumper;
27 use LWP::UserAgent;
28 use Dpkg::Control::Hash;
29 use File::Path;
30 use File::Temp qw(tempdir);
31 use File::Basename;
32 use Dpkg::Version;
33 use POSIX;
34 use IPC::Open2;
35 use Digest::SHA;
36 use Digest::MD5;
37 use List::Util qw(any);
38 use List::MoreUtils qw(pairwise);
39 use Carp;
40
41 use Debian::Dgit;
42
43 our $our_version = 'UNRELEASED'; ###substituted###
44
45 our @rpushprotovsn_support = qw(4 3 2); # 4 is new tag format
46 our $protovsn;
47
48 our $isuite = 'unstable';
49 our $idistro;
50 our $package;
51 our @ropts;
52
53 our $sign = 1;
54 our $dryrun_level = 0;
55 our $changesfile;
56 our $buildproductsdir = '..';
57 our $new_package = 0;
58 our $ignoredirty = 0;
59 our $rmonerror = 1;
60 our @deliberatelies;
61 our %previously;
62 our $existing_package = 'dpkg';
63 our $cleanmode;
64 our $changes_since_version;
65 our $rmchanges;
66 our $quilt_mode;
67 our $quilt_modes_re = 'linear|smash|auto|nofix|nocheck|gbp|unapplied';
68 our $we_are_responder;
69 our $initiator_tempdir;
70 our $patches_applied_dirtily = 00;
71 our $tagformat_want;
72 our $tagformat;
73 our $tagformatfn;
74
75 our %format_ok = map { $_=>1 } ("1.0","3.0 (native)","3.0 (quilt)");
76
77 our $suite_re = '[-+.0-9a-z]+';
78 our $cleanmode_re = 'dpkg-source(?:-d)?|git|git-ff|check|none';
79
80 our $git_authline_re = '^([^<>]+) \<(\S+)\> (\d+ [-+]\d+)$';
81 our $splitbraincache = 'dgit-intern/quilt-cache';
82
83 our (@git) = qw(git);
84 our (@dget) = qw(dget);
85 our (@curl) = qw(curl -f);
86 our (@dput) = qw(dput);
87 our (@debsign) = qw(debsign);
88 our (@gpg) = qw(gpg);
89 our (@sbuild) = qw(sbuild);
90 our (@ssh) = 'ssh';
91 our (@dgit) = qw(dgit);
92 our (@dpkgbuildpackage) = qw(dpkg-buildpackage -i\.git/ -I.git);
93 our (@dpkgsource) = qw(dpkg-source -i\.git/ -I.git);
94 our (@dpkggenchanges) = qw(dpkg-genchanges);
95 our (@mergechanges) = qw(mergechanges -f);
96 our (@gbp) = qw(gbp);
97 our (@changesopts) = ('');
98
99 our %opts_opt_map = ('dget' => \@dget, # accept for compatibility
100                      'curl' => \@curl,
101                      'dput' => \@dput,
102                      'debsign' => \@debsign,
103                      'gpg' => \@gpg,
104                      'sbuild' => \@sbuild,
105                      'ssh' => \@ssh,
106                      'dgit' => \@dgit,
107                      'git' => \@git,
108                      'dpkg-source' => \@dpkgsource,
109                      'dpkg-buildpackage' => \@dpkgbuildpackage,
110                      'dpkg-genchanges' => \@dpkggenchanges,
111                      'gbp' => \@gbp,
112                      'ch' => \@changesopts,
113                      'mergechanges' => \@mergechanges);
114
115 our %opts_opt_cmdonly = ('gpg' => 1, 'git' => 1);
116 our %opts_cfg_insertpos = map {
117     $_,
118     scalar @{ $opts_opt_map{$_} }
119 } keys %opts_opt_map;
120
121 sub finalise_opts_opts();
122
123 our $keyid;
124
125 autoflush STDOUT 1;
126
127 our $supplementary_message = '';
128 our $need_split_build_invocation = 0;
129 our $split_brain = 0;
130
131 END {
132     local ($@, $?);
133     print STDERR "! $_\n" foreach $supplementary_message =~ m/^.+$/mg;
134 }
135
136 our $remotename = 'dgit';
137 our @ourdscfield = qw(Dgit Vcs-Dgit-Master);
138 our $csuite;
139 our $instead_distro;
140
141 sub debiantag ($$) {
142     my ($v,$distro) = @_;
143     return $tagformatfn->($v, $distro);
144 }
145
146 sub debiantag_maintview ($$) { 
147     my ($v,$distro) = @_;
148     $v =~ y/~:/_%/;
149     return "$distro/$v";
150 }
151
152 sub lbranch () { return "$branchprefix/$csuite"; }
153 my $lbranch_re = '^refs/heads/'.$branchprefix.'/([^/.]+)$';
154 sub lref () { return "refs/heads/".lbranch(); }
155 sub lrref () { return "refs/remotes/$remotename/".server_branch($csuite); }
156 sub rrref () { return server_ref($csuite); }
157
158 sub lrfetchrefs () { return "refs/dgit-fetch/$csuite"; }
159 sub lrfetchref () { return lrfetchrefs.'/'.server_branch($csuite); }
160
161 # We fetch some parts of lrfetchrefs/*.  Ideally we delete these
162 # locally fetched refs because they have unhelpful names and clutter
163 # up gitk etc.  So we track whether we have "used up" head ref (ie,
164 # whether we have made another local ref which refers to this object).
165 #
166 # (If we deleted them unconditionally, then we might end up
167 # re-fetching the same git objects each time dgit fetch was run.)
168 #
169 # So, leach use of lrfetchrefs needs to be accompanied by arrangements
170 # in git_fetch_us to fetch the refs in question, and possibly a call
171 # to lrfetchref_used.
172
173 our (%lrfetchrefs_f, %lrfetchrefs_d);
174 # $lrfetchrefs_X{lrfetchrefs."/heads/whatever"} = $objid
175
176 sub lrfetchref_used ($) {
177     my ($fullrefname) = @_;
178     my $objid = $lrfetchrefs_f{$fullrefname};
179     $lrfetchrefs_d{$fullrefname} = $objid if defined $objid;
180 }
181
182 sub stripepoch ($) {
183     my ($vsn) = @_;
184     $vsn =~ s/^\d+\://;
185     return $vsn;
186 }
187
188 sub srcfn ($$) {
189     my ($vsn,$sfx) = @_;
190     return "${package}_".(stripepoch $vsn).$sfx
191 }
192
193 sub dscfn ($) {
194     my ($vsn) = @_;
195     return srcfn($vsn,".dsc");
196 }
197
198 sub changespat ($;$) {
199     my ($vsn, $arch) = @_;
200     return "${package}_".(stripepoch $vsn)."_".($arch//'*').".changes";
201 }
202
203 our $us = 'dgit';
204 initdebug('');
205
206 our @end;
207 END { 
208     local ($?);
209     foreach my $f (@end) {
210         eval { $f->(); };
211         print STDERR "$us: cleanup: $@" if length $@;
212     }
213 };
214
215 sub badcfg { print STDERR "$us: invalid configuration: @_\n"; exit 12; }
216
217 sub no_such_package () {
218     print STDERR "$us: package $package does not exist in suite $isuite\n";
219     exit 4;
220 }
221
222 sub changedir ($) {
223     my ($newdir) = @_;
224     printdebug "CD $newdir\n";
225     chdir $newdir or confess "chdir: $newdir: $!";
226 }
227
228 sub deliberately ($) {
229     my ($enquiry) = @_;
230     return !!grep { $_ eq "--deliberately-$enquiry" } @deliberatelies;
231 }
232
233 sub deliberately_not_fast_forward () {
234     foreach (qw(not-fast-forward fresh-repo)) {
235         return 1 if deliberately($_) || deliberately("TEST-dgit-only-$_");
236     }
237 }
238
239 sub quiltmode_splitbrain () {
240     $quilt_mode =~ m/gbp|dpm|unapplied/;
241 }
242
243 #---------- remote protocol support, common ----------
244
245 # remote push initiator/responder protocol:
246 #  $ dgit remote-push-build-host <n-rargs> <rargs>... <push-args>...
247 #  where <rargs> is <push-host-dir> <supported-proto-vsn>,... ...
248 #  < dgit-remote-push-ready <actual-proto-vsn>
249 #
250 # occasionally:
251 #
252 #  > progress NBYTES
253 #  [NBYTES message]
254 #
255 #  > supplementary-message NBYTES          # $protovsn >= 3
256 #  [NBYTES message]
257 #
258 # main sequence:
259 #
260 #  > file parsed-changelog
261 #  [indicates that output of dpkg-parsechangelog follows]
262 #  > data-block NBYTES
263 #  > [NBYTES bytes of data (no newline)]
264 #  [maybe some more blocks]
265 #  > data-end
266 #
267 #  > file dsc
268 #  [etc]
269 #
270 #  > file changes
271 #  [etc]
272 #
273 #  > param head DGIT-VIEW-HEAD
274 #  > param csuite SUITE
275 #  > param tagformat old|new
276 #  > param maint-view MAINT-VIEW-HEAD
277 #
278 #  > previously REFNAME=OBJNAME       # if --deliberately-not-fast-forward
279 #                                     # goes into tag, for replay prevention
280 #
281 #  > want signed-tag
282 #  [indicates that signed tag is wanted]
283 #  < data-block NBYTES
284 #  < [NBYTES bytes of data (no newline)]
285 #  [maybe some more blocks]
286 #  < data-end
287 #  < files-end
288 #
289 #  > want signed-dsc-changes
290 #  < data-block NBYTES    [transfer of signed dsc]
291 #  [etc]
292 #  < data-block NBYTES    [transfer of signed changes]
293 #  [etc]
294 #  < files-end
295 #
296 #  > complete
297
298 our $i_child_pid;
299
300 sub i_child_report () {
301     # Sees if our child has died, and reap it if so.  Returns a string
302     # describing how it died if it failed, or undef otherwise.
303     return undef unless $i_child_pid;
304     my $got = waitpid $i_child_pid, WNOHANG;
305     return undef if $got <= 0;
306     die unless $got == $i_child_pid;
307     $i_child_pid = undef;
308     return undef unless $?;
309     return "build host child ".waitstatusmsg();
310 }
311
312 sub badproto ($$) {
313     my ($fh, $m) = @_;
314     fail "connection lost: $!" if $fh->error;
315     fail "protocol violation; $m not expected";
316 }
317
318 sub badproto_badread ($$) {
319     my ($fh, $wh) = @_;
320     fail "connection lost: $!" if $!;
321     my $report = i_child_report();
322     fail $report if defined $report;
323     badproto $fh, "eof (reading $wh)";
324 }
325
326 sub protocol_expect (&$) {
327     my ($match, $fh) = @_;
328     local $_;
329     $_ = <$fh>;
330     defined && chomp or badproto_badread $fh, "protocol message";
331     if (wantarray) {
332         my @r = &$match;
333         return @r if @r;
334     } else {
335         my $r = &$match;
336         return $r if $r;
337     }
338     badproto $fh, "\`$_'";
339 }
340
341 sub protocol_send_file ($$) {
342     my ($fh, $ourfn) = @_;
343     open PF, "<", $ourfn or die "$ourfn: $!";
344     for (;;) {
345         my $d;
346         my $got = read PF, $d, 65536;
347         die "$ourfn: $!" unless defined $got;
348         last if !$got;
349         print $fh "data-block ".length($d)."\n" or die $!;
350         print $fh $d or die $!;
351     }
352     PF->error and die "$ourfn $!";
353     print $fh "data-end\n" or die $!;
354     close PF;
355 }
356
357 sub protocol_read_bytes ($$) {
358     my ($fh, $nbytes) = @_;
359     $nbytes =~ m/^[1-9]\d{0,5}$|^0$/ or badproto \*RO, "bad byte count";
360     my $d;
361     my $got = read $fh, $d, $nbytes;
362     $got==$nbytes or badproto_badread $fh, "data block";
363     return $d;
364 }
365
366 sub protocol_receive_file ($$) {
367     my ($fh, $ourfn) = @_;
368     printdebug "() $ourfn\n";
369     open PF, ">", $ourfn or die "$ourfn: $!";
370     for (;;) {
371         my ($y,$l) = protocol_expect {
372             m/^data-block (.*)$/ ? (1,$1) :
373             m/^data-end$/ ? (0,) :
374             ();
375         } $fh;
376         last unless $y;
377         my $d = protocol_read_bytes $fh, $l;
378         print PF $d or die $!;
379     }
380     close PF or die $!;
381 }
382
383 #---------- remote protocol support, responder ----------
384
385 sub responder_send_command ($) {
386     my ($command) = @_;
387     return unless $we_are_responder;
388     # called even without $we_are_responder
389     printdebug ">> $command\n";
390     print PO $command, "\n" or die $!;
391 }    
392
393 sub responder_send_file ($$) {
394     my ($keyword, $ourfn) = @_;
395     return unless $we_are_responder;
396     printdebug "]] $keyword $ourfn\n";
397     responder_send_command "file $keyword";
398     protocol_send_file \*PO, $ourfn;
399 }
400
401 sub responder_receive_files ($@) {
402     my ($keyword, @ourfns) = @_;
403     die unless $we_are_responder;
404     printdebug "[[ $keyword @ourfns\n";
405     responder_send_command "want $keyword";
406     foreach my $fn (@ourfns) {
407         protocol_receive_file \*PI, $fn;
408     }
409     printdebug "[[\$\n";
410     protocol_expect { m/^files-end$/ } \*PI;
411 }
412
413 #---------- remote protocol support, initiator ----------
414
415 sub initiator_expect (&) {
416     my ($match) = @_;
417     protocol_expect { &$match } \*RO;
418 }
419
420 #---------- end remote code ----------
421
422 sub progress {
423     if ($we_are_responder) {
424         my $m = join '', @_;
425         responder_send_command "progress ".length($m) or die $!;
426         print PO $m or die $!;
427     } else {
428         print @_, "\n";
429     }
430 }
431
432 our $ua;
433
434 sub url_get {
435     if (!$ua) {
436         $ua = LWP::UserAgent->new();
437         $ua->env_proxy;
438     }
439     my $what = $_[$#_];
440     progress "downloading $what...";
441     my $r = $ua->get(@_) or die $!;
442     return undef if $r->code == 404;
443     $r->is_success or fail "failed to fetch $what: ".$r->status_line;
444     return $r->decoded_content(charset => 'none');
445 }
446
447 our ($dscdata,$dscurl,$dsc,$dsc_checked,$skew_warning_vsn);
448
449 sub runcmd {
450     debugcmd "+",@_;
451     $!=0; $?=-1;
452     failedcmd @_ if system @_;
453 }
454
455 sub act_local () { return $dryrun_level <= 1; }
456 sub act_scary () { return !$dryrun_level; }
457
458 sub printdone {
459     if (!$dryrun_level) {
460         progress "dgit ok: @_";
461     } else {
462         progress "would be ok: @_ (but dry run only)";
463     }
464 }
465
466 sub dryrun_report {
467     printcmd(\*STDERR,$debugprefix."#",@_);
468 }
469
470 sub runcmd_ordryrun {
471     if (act_scary()) {
472         runcmd @_;
473     } else {
474         dryrun_report @_;
475     }
476 }
477
478 sub runcmd_ordryrun_local {
479     if (act_local()) {
480         runcmd @_;
481     } else {
482         dryrun_report @_;
483     }
484 }
485
486 sub shell_cmd {
487     my ($first_shell, @cmd) = @_;
488     return qw(sh -ec), $first_shell.'; exec "$@"', 'x', @cmd;
489 }
490
491 our $helpmsg = <<END;
492 main usages:
493   dgit [dgit-opts] clone [dgit-opts] package [suite] [./dir|/dir]
494   dgit [dgit-opts] fetch|pull [dgit-opts] [suite]
495   dgit [dgit-opts] build [dpkg-buildpackage-opts]
496   dgit [dgit-opts] sbuild [sbuild-opts]
497   dgit [dgit-opts] push [dgit-opts] [suite]
498   dgit [dgit-opts] rpush build-host:build-dir ...
499 important dgit options:
500   -k<keyid>           sign tag and package with <keyid> instead of default
501   --dry-run -n        do not change anything, but go through the motions
502   --damp-run -L       like --dry-run but make local changes, without signing
503   --new -N            allow introducing a new package
504   --debug -D          increase debug level
505   -c<name>=<value>    set git config option (used directly by dgit too)
506 END
507
508 our $later_warning_msg = <<END;
509 Perhaps the upload is stuck in incoming.  Using the version from git.
510 END
511
512 sub badusage {
513     print STDERR "$us: @_\n", $helpmsg or die $!;
514     exit 8;
515 }
516
517 sub nextarg {
518     @ARGV or badusage "too few arguments";
519     return scalar shift @ARGV;
520 }
521
522 sub cmd_help () {
523     print $helpmsg or die $!;
524     exit 0;
525 }
526
527 our $td = $ENV{DGIT_TEST_DUMMY_DIR} || "DGIT_TEST_DUMMY_DIR-unset";
528
529 our %defcfg = ('dgit.default.distro' => 'debian',
530                'dgit.default.username' => '',
531                'dgit.default.archive-query-default-component' => 'main',
532                'dgit.default.ssh' => 'ssh',
533                'dgit.default.archive-query' => 'madison:',
534                'dgit.default.sshpsql-dbname' => 'service=projectb',
535                'dgit.default.dgit-tag-format' => 'old,new,maint',
536                'dgit-distro.debian.archive-query' => 'ftpmasterapi:',
537                'dgit-distro.debian.git-check' => 'url',
538                'dgit-distro.debian.git-check-suffix' => '/info/refs',
539                'dgit-distro.debian.new-private-pushers' => 't',
540                'dgit-distro.debian.dgit-tag-format' => 'old',
541                'dgit-distro.debian/push.git-url' => '',
542                'dgit-distro.debian/push.git-host' => 'push.dgit.debian.org',
543                'dgit-distro.debian/push.git-user-force' => 'dgit',
544                'dgit-distro.debian/push.git-proto' => 'git+ssh://',
545                'dgit-distro.debian/push.git-path' => '/dgit/debian/repos',
546                'dgit-distro.debian/push.git-create' => 'true',
547                'dgit-distro.debian/push.git-check' => 'ssh-cmd',
548  'dgit-distro.debian.archive-query-url', 'https://api.ftp-master.debian.org/',
549 # 'dgit-distro.debian.archive-query-tls-key',
550 #    '/etc/ssl/certs/%HOST%.pem:/etc/dgit/%HOST%.pem',
551 # ^ this does not work because curl is broken nowadays
552 # Fixing #790093 properly will involve providing providing the key
553 # in some pacagke and maybe updating these paths.
554 #
555 # 'dgit-distro.debian.archive-query-tls-curl-args',
556 #   '--ca-path=/etc/ssl/ca-debian',
557 # ^ this is a workaround but works (only) on DSA-administered machines
558                'dgit-distro.debian.git-url' => 'https://git.dgit.debian.org',
559                'dgit-distro.debian.git-url-suffix' => '',
560                'dgit-distro.debian.upload-host' => 'ftp-master', # for dput
561                'dgit-distro.debian.mirror' => 'http://ftp.debian.org/debian/',
562  'dgit-distro.debian.backports-quirk' => '(squeeze)-backports*',
563  'dgit-distro.debian-backports.mirror' => 'http://backports.debian.org/debian-backports/',
564                'dgit-distro.ubuntu.git-check' => 'false',
565  'dgit-distro.ubuntu.mirror' => 'http://archive.ubuntu.com/ubuntu',
566                'dgit-distro.test-dummy.ssh' => "$td/ssh",
567                'dgit-distro.test-dummy.username' => "alice",
568                'dgit-distro.test-dummy.git-check' => "ssh-cmd",
569                'dgit-distro.test-dummy.git-create' => "ssh-cmd",
570                'dgit-distro.test-dummy.git-url' => "$td/git",
571                'dgit-distro.test-dummy.git-host' => "git",
572                'dgit-distro.test-dummy.git-path' => "$td/git",
573                'dgit-distro.test-dummy.archive-query' => "ftpmasterapi:",
574                'dgit-distro.test-dummy.archive-query-url' => "file://$td/aq/",
575                'dgit-distro.test-dummy.mirror' => "file://$td/mirror/",
576                'dgit-distro.test-dummy.upload-host' => 'test-dummy',
577                );
578
579 our %gitcfg;
580
581 sub git_slurp_config () {
582     local ($debuglevel) = $debuglevel-2;
583     local $/="\0";
584
585     my @cmd = (@git, qw(config -z --get-regexp .*));
586     debugcmd "|",@cmd;
587
588     open GITS, "-|", @cmd or die $!;
589     while (<GITS>) {
590         chomp or die;
591         printdebug "=> ", (messagequote $_), "\n";
592         m/\n/ or die "$_ ?";
593         push @{ $gitcfg{$`} }, $'; #';
594     }
595     $!=0; $?=0;
596     close GITS
597         or ($!==0 && $?==256)
598         or failedcmd @cmd;
599 }
600
601 sub git_get_config ($) {
602     my ($c) = @_;
603     my $l = $gitcfg{$c};
604     printdebug"C $c ".(defined $l ? messagequote "'$l'" : "undef")."\n"
605         if $debuglevel >= 4;
606     $l or return undef;
607     @$l==1 or badcfg "multiple values for $c" if @$l > 1;
608     return $l->[0];
609 }
610
611 sub cfg {
612     foreach my $c (@_) {
613         return undef if $c =~ /RETURN-UNDEF/;
614         my $v = git_get_config($c);
615         return $v if defined $v;
616         my $dv = $defcfg{$c};
617         return $dv if defined $dv;
618     }
619     badcfg "need value for one of: @_\n".
620         "$us: distro or suite appears not to be (properly) supported";
621 }
622
623 sub access_basedistro () {
624     if (defined $idistro) {
625         return $idistro;
626     } else {    
627         return cfg("dgit-suite.$isuite.distro",
628                    "dgit.default.distro");
629     }
630 }
631
632 sub access_quirk () {
633     # returns (quirk name, distro to use instead or undef, quirk-specific info)
634     my $basedistro = access_basedistro();
635     my $backports_quirk = cfg("dgit-distro.$basedistro.backports-quirk",
636                               'RETURN-UNDEF');
637     if (defined $backports_quirk) {
638         my $re = $backports_quirk;
639         $re =~ s/[^-0-9a-z_\%*()]/\\$&/ig;
640         $re =~ s/\*/.*/g;
641         $re =~ s/\%/([-0-9a-z_]+)/
642             or $re =~ m/[()]/ or badcfg "backports-quirk needs \% or ( )";
643         if ($isuite =~ m/^$re$/) {
644             return ('backports',"$basedistro-backports",$1);
645         }
646     }
647     return ('none',undef);
648 }
649
650 our $access_forpush;
651
652 sub parse_cfg_bool ($$$) {
653     my ($what,$def,$v) = @_;
654     $v //= $def;
655     return
656         $v =~ m/^[ty1]/ ? 1 :
657         $v =~ m/^[fn0]/ ? 0 :
658         badcfg "$what needs t (true, y, 1) or f (false, n, 0) not \`$v'";
659 }       
660
661 sub access_forpush_config () {
662     my $d = access_basedistro();
663
664     return 1 if
665         $new_package &&
666         parse_cfg_bool('new-private-pushers', 0,
667                        cfg("dgit-distro.$d.new-private-pushers",
668                            'RETURN-UNDEF'));
669
670     my $v = cfg("dgit-distro.$d.readonly", 'RETURN-UNDEF');
671     $v //= 'a';
672     return
673         $v =~ m/^[ty1]/ ? 0 : # force readonly,    forpush = 0
674         $v =~ m/^[fn0]/ ? 1 : # force nonreadonly, forpush = 1
675         $v =~ m/^[a]/  ? '' : # auto,              forpush = ''
676         badcfg "readonly needs t (true, y, 1) or f (false, n, 0) or a (auto)";
677 }
678
679 sub access_forpush () {
680     $access_forpush //= access_forpush_config();
681     return $access_forpush;
682 }
683
684 sub pushing () {
685     die "$access_forpush ?" if ($access_forpush // 1) ne 1;
686     badcfg "pushing but distro is configured readonly"
687         if access_forpush_config() eq '0';
688     $access_forpush = 1;
689     $supplementary_message = <<'END' unless $we_are_responder;
690 Push failed, before we got started.
691 You can retry the push, after fixing the problem, if you like.
692 END
693     finalise_opts_opts();
694 }
695
696 sub notpushing () {
697     finalise_opts_opts();
698 }
699
700 sub supplementary_message ($) {
701     my ($msg) = @_;
702     if (!$we_are_responder) {
703         $supplementary_message = $msg;
704         return;
705     } elsif ($protovsn >= 3) {
706         responder_send_command "supplementary-message ".length($msg)
707             or die $!;
708         print PO $msg or die $!;
709     }
710 }
711
712 sub access_distros () {
713     # Returns list of distros to try, in order
714     #
715     # We want to try:
716     #    0. `instead of' distro name(s) we have been pointed to
717     #    1. the access_quirk distro, if any
718     #    2a. the user's specified distro, or failing that  } basedistro
719     #    2b. the distro calculated from the suite          }
720     my @l = access_basedistro();
721
722     my (undef,$quirkdistro) = access_quirk();
723     unshift @l, $quirkdistro;
724     unshift @l, $instead_distro;
725     @l = grep { defined } @l;
726
727     if (access_forpush()) {
728         @l = map { ("$_/push", $_) } @l;
729     }
730     @l;
731 }
732
733 sub access_cfg_cfgs (@) {
734     my (@keys) = @_;
735     my @cfgs;
736     # The nesting of these loops determines the search order.  We put
737     # the key loop on the outside so that we search all the distros
738     # for each key, before going on to the next key.  That means that
739     # if access_cfg is called with a more specific, and then a less
740     # specific, key, an earlier distro can override the less specific
741     # without necessarily overriding any more specific keys.  (If the
742     # distro wants to override the more specific keys it can simply do
743     # so; whereas if we did the loop the other way around, it would be
744     # impossible to for an earlier distro to override a less specific
745     # key but not the more specific ones without restating the unknown
746     # values of the more specific keys.
747     my @realkeys;
748     my @rundef;
749     # We have to deal with RETURN-UNDEF specially, so that we don't
750     # terminate the search prematurely.
751     foreach (@keys) {
752         if (m/RETURN-UNDEF/) { push @rundef, $_; last; }
753         push @realkeys, $_
754     }
755     foreach my $d (access_distros()) {
756         push @cfgs, map { "dgit-distro.$d.$_" } @realkeys;
757     }
758     push @cfgs, map { "dgit.default.$_" } @realkeys;
759     push @cfgs, @rundef;
760     return @cfgs;
761 }
762
763 sub access_cfg (@) {
764     my (@keys) = @_;
765     my (@cfgs) = access_cfg_cfgs(@keys);
766     my $value = cfg(@cfgs);
767     return $value;
768 }
769
770 sub access_cfg_bool ($$) {
771     my ($def, @keys) = @_;
772     parse_cfg_bool($keys[0], $def, access_cfg(@keys, 'RETURN-UNDEF'));
773 }
774
775 sub string_to_ssh ($) {
776     my ($spec) = @_;
777     if ($spec =~ m/\s/) {
778         return qw(sh -ec), 'exec '.$spec.' "$@"', 'x';
779     } else {
780         return ($spec);
781     }
782 }
783
784 sub access_cfg_ssh () {
785     my $gitssh = access_cfg('ssh', 'RETURN-UNDEF');
786     if (!defined $gitssh) {
787         return @ssh;
788     } else {
789         return string_to_ssh $gitssh;
790     }
791 }
792
793 sub access_runeinfo ($) {
794     my ($info) = @_;
795     return ": dgit ".access_basedistro()." $info ;";
796 }
797
798 sub access_someuserhost ($) {
799     my ($some) = @_;
800     my $user = access_cfg("$some-user-force", 'RETURN-UNDEF');
801     defined($user) && length($user) or
802         $user = access_cfg("$some-user",'username');
803     my $host = access_cfg("$some-host");
804     return length($user) ? "$user\@$host" : $host;
805 }
806
807 sub access_gituserhost () {
808     return access_someuserhost('git');
809 }
810
811 sub access_giturl (;$) {
812     my ($optional) = @_;
813     my $url = access_cfg('git-url','RETURN-UNDEF');
814     my $suffix;
815     if (!length $url) {
816         my $proto = access_cfg('git-proto', 'RETURN-UNDEF');
817         return undef unless defined $proto;
818         $url =
819             $proto.
820             access_gituserhost().
821             access_cfg('git-path');
822     } else {
823         $suffix = access_cfg('git-url-suffix','RETURN-UNDEF');
824     }
825     $suffix //= '.git';
826     return "$url/$package$suffix";
827 }              
828
829 sub parsecontrolfh ($$;$) {
830     my ($fh, $desc, $allowsigned) = @_;
831     our $dpkgcontrolhash_noissigned;
832     my $c;
833     for (;;) {
834         my %opts = ('name' => $desc);
835         $opts{allow_pgp}= $allowsigned || !$dpkgcontrolhash_noissigned;
836         $c = Dpkg::Control::Hash->new(%opts);
837         $c->parse($fh,$desc) or die "parsing of $desc failed";
838         last if $allowsigned;
839         last if $dpkgcontrolhash_noissigned;
840         my $issigned= $c->get_option('is_pgp_signed');
841         if (!defined $issigned) {
842             $dpkgcontrolhash_noissigned= 1;
843             seek $fh, 0,0 or die "seek $desc: $!";
844         } elsif ($issigned) {
845             fail "control file $desc is (already) PGP-signed. ".
846                 " Note that dgit push needs to modify the .dsc and then".
847                 " do the signature itself";
848         } else {
849             last;
850         }
851     }
852     return $c;
853 }
854
855 sub parsecontrol {
856     my ($file, $desc) = @_;
857     my $fh = new IO::Handle;
858     open $fh, '<', $file or die "$file: $!";
859     my $c = parsecontrolfh($fh,$desc);
860     $fh->error and die $!;
861     close $fh;
862     return $c;
863 }
864
865 sub getfield ($$) {
866     my ($dctrl,$field) = @_;
867     my $v = $dctrl->{$field};
868     return $v if defined $v;
869     fail "missing field $field in ".$v->get_option('name');
870 }
871
872 sub parsechangelog {
873     my $c = Dpkg::Control::Hash->new();
874     my $p = new IO::Handle;
875     my @cmd = (qw(dpkg-parsechangelog), @_);
876     open $p, '-|', @cmd or die $!;
877     $c->parse($p);
878     $?=0; $!=0; close $p or failedcmd @cmd;
879     return $c;
880 }
881
882 sub commit_getclogp ($) {
883     # Returns the parsed changelog hashref for a particular commit
884     my ($objid) = @_;
885     our %commit_getclogp_memo;
886     my $memo = $commit_getclogp_memo{$objid};
887     return $memo if $memo;
888     mkpath '.git/dgit';
889     my $mclog = ".git/dgit/clog-$objid";
890     runcmd shell_cmd "exec >$mclog", @git, qw(cat-file blob),
891         "$objid:debian/changelog";
892     $commit_getclogp_memo{$objid} = parsechangelog("-l$mclog");
893 }
894
895 sub must_getcwd () {
896     my $d = getcwd();
897     defined $d or fail "getcwd failed: $!";
898     return $d;
899 }
900
901 our %rmad;
902
903 sub archive_query ($) {
904     my ($method) = @_;
905     my $query = access_cfg('archive-query','RETURN-UNDEF');
906     $query =~ s/^(\w+):// or badcfg "invalid archive-query method \`$query'";
907     my $proto = $1;
908     my $data = $'; #';
909     { no strict qw(refs); &{"${method}_${proto}"}($proto,$data); }
910 }
911
912 sub pool_dsc_subpath ($$) {
913     my ($vsn,$component) = @_; # $package is implict arg
914     my $prefix = substr($package, 0, $package =~ m/^l/ ? 4 : 1);
915     return "/pool/$component/$prefix/$package/".dscfn($vsn);
916 }
917
918 #---------- `ftpmasterapi' archive query method (nascent) ----------
919
920 sub archive_api_query_cmd ($) {
921     my ($subpath) = @_;
922     my @cmd = qw(curl -sS);
923     my $url = access_cfg('archive-query-url');
924     if ($url =~ m#^https://([-.0-9a-z]+)/#) {
925         my $host = $1;
926         my $keys = access_cfg('archive-query-tls-key','RETURN-UNDEF') //'';
927         foreach my $key (split /\:/, $keys) {
928             $key =~ s/\%HOST\%/$host/g;
929             if (!stat $key) {
930                 fail "for $url: stat $key: $!" unless $!==ENOENT;
931                 next;
932             }
933             fail "config requested specific TLS key but do not know".
934                 " how to get curl to use exactly that EE key ($key)";
935 #           push @cmd, "--cacert", $key, "--capath", "/dev/enoent";
936 #           # Sadly the above line does not work because of changes
937 #           # to gnutls.   The real fix for #790093 may involve
938 #           # new curl options.
939             last;
940         }
941         # Fixing #790093 properly will involve providing a value
942         # for this on clients.
943         my $kargs = access_cfg('archive-query-tls-curl-ca-args','RETURN-UNDEF');
944         push @cmd, split / /, $kargs if defined $kargs;
945     }
946     push @cmd, $url.$subpath;
947     return @cmd;
948 }
949
950 sub api_query ($$) {
951     use JSON;
952     my ($data, $subpath) = @_;
953     badcfg "ftpmasterapi archive query method takes no data part"
954         if length $data;
955     my @cmd = archive_api_query_cmd($subpath);
956     my $json = cmdoutput @cmd;
957     return decode_json($json);
958 }
959
960 sub canonicalise_suite_ftpmasterapi () {
961     my ($proto,$data) = @_;
962     my $suites = api_query($data, 'suites');
963     my @matched;
964     foreach my $entry (@$suites) {
965         next unless grep { 
966             my $v = $entry->{$_};
967             defined $v && $v eq $isuite;
968         } qw(codename name);
969         push @matched, $entry;
970     }
971     fail "unknown suite $isuite" unless @matched;
972     my $cn;
973     eval {
974         @matched==1 or die "multiple matches for suite $isuite\n";
975         $cn = "$matched[0]{codename}";
976         defined $cn or die "suite $isuite info has no codename\n";
977         $cn =~ m/^$suite_re$/ or die "suite $isuite maps to bad codename\n";
978     };
979     die "bad ftpmaster api response: $@\n".Dumper(\@matched)
980         if length $@;
981     return $cn;
982 }
983
984 sub archive_query_ftpmasterapi () {
985     my ($proto,$data) = @_;
986     my $info = api_query($data, "dsc_in_suite/$isuite/$package");
987     my @rows;
988     my $digester = Digest::SHA->new(256);
989     foreach my $entry (@$info) {
990         eval {
991             my $vsn = "$entry->{version}";
992             my ($ok,$msg) = version_check $vsn;
993             die "bad version: $msg\n" unless $ok;
994             my $component = "$entry->{component}";
995             $component =~ m/^$component_re$/ or die "bad component";
996             my $filename = "$entry->{filename}";
997             $filename && $filename !~ m#[^-+:._~0-9a-zA-Z/]|^[/.]|/[/.]#
998                 or die "bad filename";
999             my $sha256sum = "$entry->{sha256sum}";
1000             $sha256sum =~ m/^[0-9a-f]+$/ or die "bad sha256sum";
1001             push @rows, [ $vsn, "/pool/$component/$filename",
1002                           $digester, $sha256sum ];
1003         };
1004         die "bad ftpmaster api response: $@\n".Dumper($entry)
1005             if length $@;
1006     }
1007     @rows = sort { -version_compare($a->[0],$b->[0]) } @rows;
1008     return @rows;
1009 }
1010
1011 #---------- `madison' archive query method ----------
1012
1013 sub archive_query_madison {
1014     return map { [ @$_[0..1] ] } madison_get_parse(@_);
1015 }
1016
1017 sub madison_get_parse {
1018     my ($proto,$data) = @_;
1019     die unless $proto eq 'madison';
1020     if (!length $data) {
1021         $data= access_cfg('madison-distro','RETURN-UNDEF');
1022         $data //= access_basedistro();
1023     }
1024     $rmad{$proto,$data,$package} ||= cmdoutput
1025         qw(rmadison -asource),"-s$isuite","-u$data",$package;
1026     my $rmad = $rmad{$proto,$data,$package};
1027
1028     my @out;
1029     foreach my $l (split /\n/, $rmad) {
1030         $l =~ m{^ \s*( [^ \t|]+ )\s* \|
1031                   \s*( [^ \t|]+ )\s* \|
1032                   \s*( [^ \t|/]+ )(?:/([^ \t|/]+))? \s* \|
1033                   \s*( [^ \t|]+ )\s* }x or die "$rmad ?";
1034         $1 eq $package or die "$rmad $package ?";
1035         my $vsn = $2;
1036         my $newsuite = $3;
1037         my $component;
1038         if (defined $4) {
1039             $component = $4;
1040         } else {
1041             $component = access_cfg('archive-query-default-component');
1042         }
1043         $5 eq 'source' or die "$rmad ?";
1044         push @out, [$vsn,pool_dsc_subpath($vsn,$component),$newsuite];
1045     }
1046     return sort { -version_compare($a->[0],$b->[0]); } @out;
1047 }
1048
1049 sub canonicalise_suite_madison {
1050     # madison canonicalises for us
1051     my @r = madison_get_parse(@_);
1052     @r or fail
1053         "unable to canonicalise suite using package $package".
1054         " which does not appear to exist in suite $isuite;".
1055         " --existing-package may help";
1056     return $r[0][2];
1057 }
1058
1059 #---------- `sshpsql' archive query method ----------
1060
1061 sub sshpsql ($$$) {
1062     my ($data,$runeinfo,$sql) = @_;
1063     if (!length $data) {
1064         $data= access_someuserhost('sshpsql').':'.
1065             access_cfg('sshpsql-dbname');
1066     }
1067     $data =~ m/:/ or badcfg "invalid sshpsql method string \`$data'";
1068     my ($userhost,$dbname) = ($`,$'); #';
1069     my @rows;
1070     my @cmd = (access_cfg_ssh, $userhost,
1071                access_runeinfo("ssh-psql $runeinfo").
1072                " export LC_MESSAGES=C; export LC_CTYPE=C;".
1073                " ".shellquote qw(psql -A), $dbname, qw(-c), $sql);
1074     debugcmd "|",@cmd;
1075     open P, "-|", @cmd or die $!;
1076     while (<P>) {
1077         chomp or die;
1078         printdebug(">|$_|\n");
1079         push @rows, $_;
1080     }
1081     $!=0; $?=0; close P or failedcmd @cmd;
1082     @rows or die;
1083     my $nrows = pop @rows;
1084     $nrows =~ s/^\((\d+) rows?\)$/$1/ or die "$nrows ?";
1085     @rows == $nrows+1 or die "$nrows ".(scalar @rows)." ?";
1086     @rows = map { [ split /\|/, $_ ] } @rows;
1087     my $ncols = scalar @{ shift @rows };
1088     die if grep { scalar @$_ != $ncols } @rows;
1089     return @rows;
1090 }
1091
1092 sub sql_injection_check {
1093     foreach (@_) { die "$_ $& ?" if m{[^-+=:_.,/0-9a-zA-Z]}; }
1094 }
1095
1096 sub archive_query_sshpsql ($$) {
1097     my ($proto,$data) = @_;
1098     sql_injection_check $isuite, $package;
1099     my @rows = sshpsql($data, "archive-query $isuite $package", <<END);
1100         SELECT source.version, component.name, files.filename, files.sha256sum
1101           FROM source
1102           JOIN src_associations ON source.id = src_associations.source
1103           JOIN suite ON suite.id = src_associations.suite
1104           JOIN dsc_files ON dsc_files.source = source.id
1105           JOIN files_archive_map ON files_archive_map.file_id = dsc_files.file
1106           JOIN component ON component.id = files_archive_map.component_id
1107           JOIN files ON files.id = dsc_files.file
1108          WHERE ( suite.suite_name='$isuite' OR suite.codename='$isuite' )
1109            AND source.source='$package'
1110            AND files.filename LIKE '%.dsc';
1111 END
1112     @rows = sort { -version_compare($a->[0],$b->[0]) } @rows;
1113     my $digester = Digest::SHA->new(256);
1114     @rows = map {
1115         my ($vsn,$component,$filename,$sha256sum) = @$_;
1116         [ $vsn, "/pool/$component/$filename",$digester,$sha256sum ];
1117     } @rows;
1118     return @rows;
1119 }
1120
1121 sub canonicalise_suite_sshpsql ($$) {
1122     my ($proto,$data) = @_;
1123     sql_injection_check $isuite;
1124     my @rows = sshpsql($data, "canonicalise-suite $isuite", <<END);
1125         SELECT suite.codename
1126           FROM suite where suite_name='$isuite' or codename='$isuite';
1127 END
1128     @rows = map { $_->[0] } @rows;
1129     fail "unknown suite $isuite" unless @rows;
1130     die "ambiguous $isuite: @rows ?" if @rows>1;
1131     return $rows[0];
1132 }
1133
1134 #---------- `dummycat' archive query method ----------
1135
1136 sub canonicalise_suite_dummycat ($$) {
1137     my ($proto,$data) = @_;
1138     my $dpath = "$data/suite.$isuite";
1139     if (!open C, "<", $dpath) {
1140         $!==ENOENT or die "$dpath: $!";
1141         printdebug "dummycat canonicalise_suite $isuite $dpath ENOENT\n";
1142         return $isuite;
1143     }
1144     $!=0; $_ = <C>;
1145     chomp or die "$dpath: $!";
1146     close C;
1147     printdebug "dummycat canonicalise_suite $isuite $dpath = $_\n";
1148     return $_;
1149 }
1150
1151 sub archive_query_dummycat ($$) {
1152     my ($proto,$data) = @_;
1153     canonicalise_suite();
1154     my $dpath = "$data/package.$csuite.$package";
1155     if (!open C, "<", $dpath) {
1156         $!==ENOENT or die "$dpath: $!";
1157         printdebug "dummycat query $csuite $package $dpath ENOENT\n";
1158         return ();
1159     }
1160     my @rows;
1161     while (<C>) {
1162         next if m/^\#/;
1163         next unless m/\S/;
1164         die unless chomp;
1165         printdebug "dummycat query $csuite $package $dpath | $_\n";
1166         my @row = split /\s+/, $_;
1167         @row==2 or die "$dpath: $_ ?";
1168         push @rows, \@row;
1169     }
1170     C->error and die "$dpath: $!";
1171     close C;
1172     return sort { -version_compare($a->[0],$b->[0]); } @rows;
1173 }
1174
1175 #---------- tag format handling ----------
1176
1177 sub access_cfg_tagformats () {
1178     split /\,/, access_cfg('dgit-tag-format');
1179 }
1180
1181 sub need_tagformat ($$) {
1182     my ($fmt, $why) = @_;
1183     fail "need to use tag format $fmt ($why) but also need".
1184         " to use tag format $tagformat_want->[0] ($tagformat_want->[1])".
1185         " - no way to proceed"
1186         if $tagformat_want && $tagformat_want->[0] ne $fmt;
1187     $tagformat_want = [$fmt, $why, $tagformat_want->[2] // 0];
1188 }
1189
1190 sub select_tagformat () {
1191     # sets $tagformatfn
1192     return if $tagformatfn && !$tagformat_want;
1193     die 'bug' if $tagformatfn && $tagformat_want;
1194     # ... $tagformat_want assigned after previous select_tagformat
1195
1196     my (@supported) = grep { $_ ne 'maint' } access_cfg_tagformats();
1197     printdebug "select_tagformat supported @supported\n";
1198
1199     $tagformat_want //= [ $supported[0], "distro access configuration", 0 ];
1200     printdebug "select_tagformat specified @$tagformat_want\n";
1201
1202     my ($fmt,$why,$override) = @$tagformat_want;
1203
1204     fail "target distro supports tag formats @supported".
1205         " but have to use $fmt ($why)"
1206         unless $override
1207             or grep { $_ eq $fmt } @supported;
1208
1209     $tagformat_want = undef;
1210     $tagformat = $fmt;
1211     $tagformatfn = ${*::}{"debiantag_$fmt"};
1212
1213     fail "trying to use unknown tag format \`$fmt' ($why) !"
1214         unless $tagformatfn;
1215 }
1216
1217 #---------- archive query entrypoints and rest of program ----------
1218
1219 sub canonicalise_suite () {
1220     return if defined $csuite;
1221     fail "cannot operate on $isuite suite" if $isuite eq 'UNRELEASED';
1222     $csuite = archive_query('canonicalise_suite');
1223     if ($isuite ne $csuite) {
1224         progress "canonical suite name for $isuite is $csuite";
1225     }
1226 }
1227
1228 sub get_archive_dsc () {
1229     canonicalise_suite();
1230     my @vsns = archive_query('archive_query');
1231     foreach my $vinfo (@vsns) {
1232         my ($vsn,$subpath,$digester,$digest) = @$vinfo;
1233         $dscurl = access_cfg('mirror').$subpath;
1234         $dscdata = url_get($dscurl);
1235         if (!$dscdata) {
1236             $skew_warning_vsn = $vsn if !defined $skew_warning_vsn;
1237             next;
1238         }
1239         if ($digester) {
1240             $digester->reset();
1241             $digester->add($dscdata);
1242             my $got = $digester->hexdigest();
1243             $got eq $digest or
1244                 fail "$dscurl has hash $got but".
1245                     " archive told us to expect $digest";
1246         }
1247         my $dscfh = new IO::File \$dscdata, '<' or die $!;
1248         printdebug Dumper($dscdata) if $debuglevel>1;
1249         $dsc = parsecontrolfh($dscfh,$dscurl,1);
1250         printdebug Dumper($dsc) if $debuglevel>1;
1251         my $fmt = getfield $dsc, 'Format';
1252         fail "unsupported source format $fmt, sorry" unless $format_ok{$fmt};
1253         $dsc_checked = !!$digester;
1254         printdebug "get_archive_dsc: Version ".(getfield $dsc, 'Version')."\n";
1255         return;
1256     }
1257     $dsc = undef;
1258     printdebug "get_archive_dsc: nothing in archive, returning undef\n";
1259 }
1260
1261 sub check_for_git ();
1262 sub check_for_git () {
1263     # returns 0 or 1
1264     my $how = access_cfg('git-check');
1265     if ($how eq 'ssh-cmd') {
1266         my @cmd =
1267             (access_cfg_ssh, access_gituserhost(),
1268              access_runeinfo("git-check $package").
1269              " set -e; cd ".access_cfg('git-path').";".
1270              " if test -d $package.git; then echo 1; else echo 0; fi");
1271         my $r= cmdoutput @cmd;
1272         if (defined $r and $r =~ m/^divert (\w+)$/) {
1273             my $divert=$1;
1274             my ($usedistro,) = access_distros();
1275             # NB that if we are pushing, $usedistro will be $distro/push
1276             $instead_distro= cfg("dgit-distro.$usedistro.diverts.$divert");
1277             $instead_distro =~ s{^/}{ access_basedistro()."/" }e;
1278             progress "diverting to $divert (using config for $instead_distro)";
1279             return check_for_git();
1280         }
1281         failedcmd @cmd unless defined $r and $r =~ m/^[01]$/;
1282         return $r+0;
1283     } elsif ($how eq 'url') {
1284         my $prefix = access_cfg('git-check-url','git-url');
1285         my $suffix = access_cfg('git-check-suffix','git-suffix',
1286                                 'RETURN-UNDEF') // '.git';
1287         my $url = "$prefix/$package$suffix";
1288         my @cmd = (qw(curl -sS -I), $url);
1289         my $result = cmdoutput @cmd;
1290         $result =~ s/^\S+ 200 .*\n\r?\n//;
1291         # curl -sS -I with https_proxy prints
1292         # HTTP/1.0 200 Connection established
1293         $result =~ m/^\S+ (404|200) /s or
1294             fail "unexpected results from git check query - ".
1295                 Dumper($prefix, $result);
1296         my $code = $1;
1297         if ($code eq '404') {
1298             return 0;
1299         } elsif ($code eq '200') {
1300             return 1;
1301         } else {
1302             die;
1303         }
1304     } elsif ($how eq 'true') {
1305         return 1;
1306     } elsif ($how eq 'false') {
1307         return 0;
1308     } else {
1309         badcfg "unknown git-check \`$how'";
1310     }
1311 }
1312
1313 sub create_remote_git_repo () {
1314     my $how = access_cfg('git-create');
1315     if ($how eq 'ssh-cmd') {
1316         runcmd_ordryrun
1317             (access_cfg_ssh, access_gituserhost(),
1318              access_runeinfo("git-create $package").
1319              "set -e; cd ".access_cfg('git-path').";".
1320              " cp -a _template $package.git");
1321     } elsif ($how eq 'true') {
1322         # nothing to do
1323     } else {
1324         badcfg "unknown git-create \`$how'";
1325     }
1326 }
1327
1328 our ($dsc_hash,$lastpush_mergeinput);
1329
1330 our $ud = '.git/dgit/unpack';
1331
1332 sub prep_ud (;$) {
1333     my ($d) = @_;
1334     $d //= $ud;
1335     rmtree($d);
1336     mkpath '.git/dgit';
1337     mkdir $d or die $!;
1338 }
1339
1340 sub mktree_in_ud_here () {
1341     runcmd qw(git init -q);
1342     rmtree('.git/objects');
1343     symlink '../../../../objects','.git/objects' or die $!;
1344 }
1345
1346 sub git_write_tree () {
1347     my $tree = cmdoutput @git, qw(write-tree);
1348     $tree =~ m/^\w+$/ or die "$tree ?";
1349     return $tree;
1350 }
1351
1352 sub remove_stray_gits () {
1353     my @gitscmd = qw(find -name .git -prune -print0);
1354     debugcmd "|",@gitscmd;
1355     open GITS, "-|", @gitscmd or die $!;
1356     {
1357         local $/="\0";
1358         while (<GITS>) {
1359             chomp or die;
1360             print STDERR "$us: warning: removing from source package: ",
1361                 (messagequote $_), "\n";
1362             rmtree $_;
1363         }
1364     }
1365     $!=0; $?=0; close GITS or failedcmd @gitscmd;
1366 }
1367
1368 sub mktree_in_ud_from_only_subdir () {
1369     # changes into the subdir
1370     my (@dirs) = <*/.>;
1371     die "@dirs ?" unless @dirs==1;
1372     $dirs[0] =~ m#^([^/]+)/\.$# or die;
1373     my $dir = $1;
1374     changedir $dir;
1375
1376     remove_stray_gits();
1377     mktree_in_ud_here();
1378     my ($format, $fopts) = get_source_format();
1379     if (madformat($format)) {
1380         rmtree '.pc';
1381     }
1382     runcmd @git, qw(add -Af);
1383     my $tree=git_write_tree();
1384     return ($tree,$dir);
1385 }
1386
1387 sub dsc_files_info () {
1388     foreach my $csumi (['Checksums-Sha256','Digest::SHA', 'new(256)'],
1389                        ['Checksums-Sha1',  'Digest::SHA', 'new(1)'],
1390                        ['Files',           'Digest::MD5', 'new()']) {
1391         my ($fname, $module, $method) = @$csumi;
1392         my $field = $dsc->{$fname};
1393         next unless defined $field;
1394         eval "use $module; 1;" or die $@;
1395         my @out;
1396         foreach (split /\n/, $field) {
1397             next unless m/\S/;
1398             m/^(\w+) (\d+) (\S+)$/ or
1399                 fail "could not parse .dsc $fname line \`$_'";
1400             my $digester = eval "$module"."->$method;" or die $@;
1401             push @out, {
1402                 Hash => $1,
1403                 Bytes => $2,
1404                 Filename => $3,
1405                 Digester => $digester,
1406             };
1407         }
1408         return @out;
1409     }
1410     fail "missing any supported Checksums-* or Files field in ".
1411         $dsc->get_option('name');
1412 }
1413
1414 sub dsc_files () {
1415     map { $_->{Filename} } dsc_files_info();
1416 }
1417
1418 sub is_orig_file ($;$) {
1419     local ($_) = $_[0];
1420     my $base = $_[1];
1421     m/\.orig(?:-\w+)?\.tar\.\w+$/ or return 0;
1422     defined $base or return 1;
1423     return $` eq $base;
1424 }
1425
1426 sub make_commit ($) {
1427     my ($file) = @_;
1428     return cmdoutput @git, qw(hash-object -w -t commit), $file;
1429 }
1430
1431 sub clogp_authline ($) {
1432     my ($clogp) = @_;
1433     my $author = getfield $clogp, 'Maintainer';
1434     $author =~ s#,.*##ms;
1435     my $date = cmdoutput qw(date), '+%s %z', qw(-d), getfield($clogp,'Date');
1436     my $authline = "$author $date";
1437     $authline =~ m/$git_authline_re/o or
1438         fail "unexpected commit author line format \`$authline'".
1439         " (was generated from changelog Maintainer field)";
1440     return ($1,$2,$3) if wantarray;
1441     return $authline;
1442 }
1443
1444 sub vendor_patches_distro ($$) {
1445     my ($checkdistro, $what) = @_;
1446     return unless defined $checkdistro;
1447
1448     my $series = "debian/patches/\L$checkdistro\E.series";
1449     printdebug "checking for vendor-specific $series ($what)\n";
1450
1451     if (!open SERIES, "<", $series) {
1452         die "$series $!" unless $!==ENOENT;
1453         return;
1454     }
1455     while (<SERIES>) {
1456         next unless m/\S/;
1457         next if m/^\s+\#/;
1458
1459         print STDERR <<END;
1460
1461 Unfortunately, this source package uses a feature of dpkg-source where
1462 the same source package unpacks to different source code on different
1463 distros.  dgit cannot safely operate on such packages on affected
1464 distros, because the meaning of source packages is not stable.
1465
1466 Please ask the distro/maintainer to remove the distro-specific series
1467 files and use a different technique (if necessary, uploading actually
1468 different packages, if different distros are supposed to have
1469 different code).
1470
1471 END
1472         fail "Found active distro-specific series file for".
1473             " $checkdistro ($what): $series, cannot continue";
1474     }
1475     die "$series $!" if SERIES->error;
1476     close SERIES;
1477 }
1478
1479 sub check_for_vendor_patches () {
1480     # This dpkg-source feature doesn't seem to be documented anywhere!
1481     # But it can be found in the changelog (reformatted):
1482
1483     #   commit  4fa01b70df1dc4458daee306cfa1f987b69da58c
1484     #   Author: Raphael Hertzog <hertzog@debian.org>
1485     #   Date: Sun  Oct  3  09:36:48  2010 +0200
1486
1487     #   dpkg-source: correctly create .pc/.quilt_series with alternate
1488     #   series files
1489     #   
1490     #   If you have debian/patches/ubuntu.series and you were
1491     #   unpacking the source package on ubuntu, quilt was still
1492     #   directed to debian/patches/series instead of
1493     #   debian/patches/ubuntu.series.
1494     #   
1495     #   debian/changelog                        |    3 +++
1496     #   scripts/Dpkg/Source/Package/V3/quilt.pm |    4 +++-
1497     #   2 files changed, 6 insertions(+), 1 deletion(-)
1498
1499     use Dpkg::Vendor;
1500     vendor_patches_distro($ENV{DEB_VENDOR}, "DEB_VENDOR");
1501     vendor_patches_distro(Dpkg::Vendor::get_current_vendor(),
1502                          "Dpkg::Vendor \`current vendor'");
1503     vendor_patches_distro(access_basedistro(),
1504                           "distro being accessed");
1505 }
1506
1507 sub generate_commits_from_dsc () {
1508     # See big comment in fetch_from_archive, below.
1509     prep_ud();
1510     changedir $ud;
1511
1512     foreach my $fi (dsc_files_info()) {
1513         my $f = $fi->{Filename};
1514         die "$f ?" if $f =~ m#/|^\.|\.dsc$|\.tmp$#;
1515
1516         link_ltarget "../../../$f", $f
1517             or $!==&ENOENT
1518             or die "$f $!";
1519
1520         complete_file_from_dsc('.', $fi)
1521             or next;
1522
1523         if (is_orig_file($f)) {
1524             link $f, "../../../../$f"
1525                 or $!==&EEXIST
1526                 or die "$f $!";
1527         }
1528     }
1529
1530     my $dscfn = "$package.dsc";
1531
1532     open D, ">", $dscfn or die "$dscfn: $!";
1533     print D $dscdata or die "$dscfn: $!";
1534     close D or die "$dscfn: $!";
1535     my @cmd = qw(dpkg-source);
1536     push @cmd, '--no-check' if $dsc_checked;
1537     push @cmd, qw(-x --), $dscfn;
1538     runcmd @cmd;
1539
1540     my ($tree,$dir) = mktree_in_ud_from_only_subdir();
1541     check_for_vendor_patches() if madformat($dsc->{format});
1542     runcmd qw(sh -ec), 'dpkg-parsechangelog >../changelog.tmp';
1543     my $clogp = parsecontrol('../changelog.tmp',"commit's changelog");
1544     my $authline = clogp_authline $clogp;
1545     my $changes = getfield $clogp, 'Changes';
1546     open C, ">../commit.tmp" or die $!;
1547     print C <<END or die $!;
1548 tree $tree
1549 author $authline
1550 committer $authline
1551
1552 $changes
1553
1554 # imported from the archive
1555 END
1556     close C or die $!;
1557     my $rawimport_hash = make_commit qw(../commit.tmp);
1558     my $cversion = getfield $clogp, 'Version';
1559     my $rawimport_mergeinput = {
1560         Commit => $rawimport_hash,
1561         Info => "Import of source package",
1562     };
1563     my @output = ($rawimport_mergeinput);
1564     progress "synthesised git commit from .dsc $cversion";
1565     if ($lastpush_mergeinput) {
1566         my $oldclogp = mergeinfo_getclogp($lastpush_mergeinput);
1567         my $oversion = getfield $oldclogp, 'Version';
1568         my $vcmp =
1569             version_compare($oversion, $cversion);
1570         if ($vcmp < 0) {
1571             @output = ($rawimport_mergeinput, $lastpush_mergeinput,
1572                 { Message => <<END, ReverseParents => 1 });
1573 Record $package ($cversion) in archive suite $csuite
1574 END
1575         } elsif ($vcmp > 0) {
1576             print STDERR <<END or die $!;
1577
1578 Version actually in archive:   $cversion (older)
1579 Last version pushed with dgit: $oversion (newer or same)
1580 $later_warning_msg
1581 END
1582             @output = $lastpush_mergeinput;
1583         } else {
1584             # Same version.  Use what's in the server git branch,
1585             # discarding our own import.  (This could happen if the
1586             # server automatically imports all packages into git.)
1587             @output = $lastpush_mergeinput;
1588         }
1589     }
1590     changedir '../../../..';
1591     rmtree($ud);
1592     return @output;
1593 }
1594
1595 sub complete_file_from_dsc ($$) {
1596     our ($dstdir, $fi) = @_;
1597     # Ensures that we have, in $dir, the file $fi, with the correct
1598     # contents.  (Downloading it from alongside $dscurl if necessary.)
1599
1600     my $f = $fi->{Filename};
1601     my $tf = "$dstdir/$f";
1602     my $downloaded = 0;
1603
1604     if (stat_exists $tf) {
1605         progress "using existing $f";
1606     } else {
1607         my $furl = $dscurl;
1608         $furl =~ s{/[^/]+$}{};
1609         $furl .= "/$f";
1610         die "$f ?" unless $f =~ m/^\Q${package}\E_/;
1611         die "$f ?" if $f =~ m#/#;
1612         runcmd_ordryrun_local @curl,qw(-o),$tf,'--',"$furl";
1613         return 0 if !act_local();
1614         $downloaded = 1;
1615     }
1616
1617     open F, "<", "$tf" or die "$tf: $!";
1618     $fi->{Digester}->reset();
1619     $fi->{Digester}->addfile(*F);
1620     F->error and die $!;
1621     my $got = $fi->{Digester}->hexdigest();
1622     $got eq $fi->{Hash} or
1623         fail "file $f has hash $got but .dsc".
1624             " demands hash $fi->{Hash} ".
1625             ($downloaded ? "(got wrong file from archive!)"
1626              : "(perhaps you should delete this file?)");
1627
1628     return 1;
1629 }
1630
1631 sub ensure_we_have_orig () {
1632     foreach my $fi (dsc_files_info()) {
1633         my $f = $fi->{Filename};
1634         next unless is_orig_file($f);
1635         complete_file_from_dsc('..', $fi)
1636             or next;
1637     }
1638 }
1639
1640 sub git_fetch_us () {
1641     # Want to fetch only what we are going to use, unless
1642     # deliberately-not-ff, in which case we must fetch everything.
1643
1644     my @specs = deliberately_not_fast_forward ? qw(tags/*) :
1645         map { "tags/$_" } debiantags('*',access_basedistro);
1646     push @specs, server_branch($csuite);
1647     push @specs, qw(heads/*) if deliberately_not_fast_forward;
1648
1649     # This is rather miserable:
1650     # When git-fetch --prune is passed a fetchspec ending with a *,
1651     # it does a plausible thing.  If there is no * then:
1652     # - it matches subpaths too, even if the supplied refspec
1653     #   starts refs, and behaves completely madly if the source
1654     #   has refs/refs/something.  (See, for example, Debian #NNNN.)
1655     # - if there is no matching remote ref, it bombs out the whole
1656     #   fetch.
1657     # We want to fetch a fixed ref, and we don't know in advance
1658     # if it exists, so this is not suitable.
1659     #
1660     # Our workaround is to use git-ls-remote.  git-ls-remote has its
1661     # own qairks.  Notably, it has the absurd multi-tail-matching
1662     # behaviour: git-ls-remote R refs/foo can report refs/foo AND
1663     # refs/refs/foo etc.
1664     #
1665     # Also, we want an idempotent snapshot, but we have to make two
1666     # calls to the remote: one to git-ls-remote and to git-fetch.  The
1667     # solution is use git-ls-remote to obtain a target state, and
1668     # git-fetch to try to generate it.  If we don't manage to generate
1669     # the target state, we try again.
1670
1671     my $specre = join '|', map {
1672         my $x = $_;
1673         $x =~ s/\W/\\$&/g;
1674         $x =~ s/\\\*$/.*/;
1675         "(?:refs/$x)";
1676     } @specs;
1677     printdebug "git_fetch_us specre=$specre\n";
1678     my $wanted_rref = sub {
1679         local ($_) = @_;
1680         return m/^(?:$specre)$/o;
1681     };
1682
1683     my $fetch_iteration = 0;
1684     FETCH_ITERATION:
1685     for (;;) {
1686         if (++$fetch_iteration > 10) {
1687             fail "too many iterations trying to get sane fetch!";
1688         }
1689
1690         my @look = map { "refs/$_" } @specs;
1691         my @lcmd = (@git, qw(ls-remote -q --refs), access_giturl(), @look);
1692         debugcmd "|",@lcmd;
1693
1694         my %wantr;
1695         open GITLS, "-|", @lcmd or die $!;
1696         while (<GITLS>) {
1697             printdebug "=> ", $_;
1698             m/^(\w+)\s+(\S+)\n/ or die "ls-remote $_ ?";
1699             my ($objid,$rrefname) = ($1,$2);
1700             if (!$wanted_rref->($rrefname)) {
1701                 print STDERR <<END;
1702 warning: git-ls-remote @look reported $rrefname; this is silly, ignoring it.
1703 END
1704                 next;
1705             }
1706             $wantr{$rrefname} = $objid;
1707         }
1708         $!=0; $?=0;
1709         close GITLS or failedcmd @lcmd;
1710
1711         # OK, now %want is exactly what we want for refs in @specs
1712         my @fspecs = map {
1713             return () if !m/\*$/ && !exists $wantr{"refs/$_"};
1714             "+refs/$_:".lrfetchrefs."/$_";
1715         } @specs;
1716
1717         my @fcmd = (@git, qw(fetch -p -n -q), access_giturl(), @fspecs);
1718         runcmd_ordryrun_local @git, qw(fetch -p -n -q), access_giturl(),
1719             @fspecs;
1720
1721         %lrfetchrefs_f = ();
1722         my %objgot;
1723
1724         git_for_each_ref(lrfetchrefs, sub {
1725             my ($objid,$objtype,$lrefname,$reftail) = @_;
1726             $lrfetchrefs_f{$lrefname} = $objid;
1727             $objgot{$objid} = 1;
1728         });
1729
1730         foreach my $lrefname (sort keys %lrfetchrefs_f) {
1731             my $rrefname = 'refs'.substr($lrefname, length lrfetchrefs);
1732             if (!exists $wantr{$rrefname}) {
1733                 if ($wanted_rref->($rrefname)) {
1734                     printdebug <<END;
1735 git-fetch @fspecs created $lrefname which git-ls-remote @look didn't list.
1736 END
1737                 } else {
1738                     print STDERR <<END
1739 warning: git-fetch @fspecs created $lrefname; this is silly, deleting it.
1740 END
1741                 }
1742                 runcmd_ordryrun_local @git, qw(update-ref -d), $lrefname;
1743                 delete $lrfetchrefs_f{$lrefname};
1744                 next;
1745             }
1746         }
1747         foreach my $rrefname (sort keys %wantr) {
1748             my $lrefname = lrfetchrefs.substr($rrefname, 4);
1749             my $got = $lrfetchrefs_f{$lrefname} // '<none>';
1750             my $want = $wantr{$rrefname};
1751             next if $got eq $want;
1752             if (!defined $objgot{$want}) {
1753                 print STDERR <<END;
1754 warning: git-ls-remote suggests we want $lrefname
1755 warning:  and it should refer to $want
1756 warning:  but git-fetch didn't fetch that object to any relevant ref.
1757 warning:  This may be due to a race with someone updating the server.
1758 warning:  Will try again...
1759 END
1760                 next FETCH_ITERATION;
1761             }
1762             printdebug <<END;
1763 git-fetch @fspecs made $lrefname=$got but want git-ls-remote @look says $want
1764 END
1765             runcmd_ordryrun_local @git, qw(update-ref -m),
1766                 "dgit fetch git-fetch fixup", $lrefname, $want;
1767             $lrfetchrefs_f{$lrefname} = $want;
1768         }
1769         last;
1770     }
1771     printdebug "git_fetch_us: git-fetch --no-insane emulation complete\n",
1772         Dumper(\%lrfetchrefs_f);
1773
1774     my %here;
1775     my @tagpats = debiantags('*',access_basedistro);
1776
1777     git_for_each_ref([map { "refs/tags/$_" } @tagpats], sub {
1778         my ($objid,$objtype,$fullrefname,$reftail) = @_;
1779         printdebug "currently $fullrefname=$objid\n";
1780         $here{$fullrefname} = $objid;
1781     });
1782     git_for_each_ref([map { lrfetchrefs."/tags/".$_ } @tagpats], sub {
1783         my ($objid,$objtype,$fullrefname,$reftail) = @_;
1784         my $lref = "refs".substr($fullrefname, length(lrfetchrefs));
1785         printdebug "offered $lref=$objid\n";
1786         if (!defined $here{$lref}) {
1787             my @upd = (@git, qw(update-ref), $lref, $objid, '');
1788             runcmd_ordryrun_local @upd;
1789             lrfetchref_used $fullrefname;
1790         } elsif ($here{$lref} eq $objid) {
1791             lrfetchref_used $fullrefname;
1792         } else {
1793             print STDERR \
1794                 "Not updateting $lref from $here{$lref} to $objid.\n";
1795         }
1796     });
1797 }
1798
1799 sub mergeinfo_getclogp ($) {
1800     # Ensures thit $mi->{Clogp} exists and returns it
1801     my ($mi) = @_;
1802     $mi->{Clogp} = commit_getclogp($mi->{Commit});
1803 }
1804
1805 sub mergeinfo_version ($) {
1806     return getfield( (mergeinfo_getclogp $_[0]), 'Version' );
1807 }
1808
1809 sub fetch_from_archive () {
1810     # Ensures that lrref() is what is actually in the archive, one way
1811     # or another, according to us - ie this client's
1812     # appropritaely-updated archive view.  Also returns the commit id.
1813     # If there is nothing in the archive, leaves lrref alone and
1814     # returns undef.  git_fetch_us must have already been called.
1815     get_archive_dsc();
1816
1817     if ($dsc) {
1818         foreach my $field (@ourdscfield) {
1819             $dsc_hash = $dsc->{$field};
1820             last if defined $dsc_hash;
1821         }
1822         if (defined $dsc_hash) {
1823             $dsc_hash =~ m/\w+/ or fail "invalid hash in .dsc \`$dsc_hash'";
1824             $dsc_hash = $&;
1825             progress "last upload to archive specified git hash";
1826         } else {
1827             progress "last upload to archive has NO git hash";
1828         }
1829     } else {
1830         progress "no version available from the archive";
1831     }
1832
1833     # If the archive's .dsc has a Dgit field, there are three
1834     # relevant git commitids we need to choose between and/or merge
1835     # together:
1836     #   1. $dsc_hash: the Dgit field from the archive
1837     #   2. $lastpush_hash: the suite branch on the dgit git server
1838     #   3. $lastfetch_hash: our local tracking brach for the suite
1839     #
1840     # These may all be distinct and need not be in any fast forward
1841     # relationship:
1842     #
1843     # If the dsc was pushed to this suite, then the server suite
1844     # branch will have been updated; but it might have been pushed to
1845     # a different suite and copied by the archive.  Conversely a more
1846     # recent version may have been pushed with dgit but not appeared
1847     # in the archive (yet).
1848     #
1849     # $lastfetch_hash may be awkward because archive imports
1850     # (particularly, imports of Dgit-less .dscs) are performed only as
1851     # needed on individual clients, so different clients may perform a
1852     # different subset of them - and these imports are only made
1853     # public during push.  So $lastfetch_hash may represent a set of
1854     # imports different to a subsequent upload by a different dgit
1855     # client.
1856     #
1857     # Our approach is as follows:
1858     #
1859     # As between $dsc_hash and $lastpush_hash: if $lastpush_hash is a
1860     # descendant of $dsc_hash, then it was pushed by a dgit user who
1861     # had based their work on $dsc_hash, so we should prefer it.
1862     # Otherwise, $dsc_hash was installed into this suite in the
1863     # archive other than by a dgit push, and (necessarily) after the
1864     # last dgit push into that suite (since a dgit push would have
1865     # been descended from the dgit server git branch); thus, in that
1866     # case, we prefer the archive's version (and produce a
1867     # pseudo-merge to overwrite the dgit server git branch).
1868     #
1869     # (If there is no Dgit field in the archive's .dsc then
1870     # generate_commit_from_dsc uses the version numbers to decide
1871     # whether the suite branch or the archive is newer.  If the suite
1872     # branch is newer it ignores the archive's .dsc; otherwise it
1873     # generates an import of the .dsc, and produces a pseudo-merge to
1874     # overwrite the suite branch with the archive contents.)
1875     #
1876     # The outcome of that part of the algorithm is the `public view',
1877     # and is same for all dgit clients: it does not depend on any
1878     # unpublished history in the local tracking branch.
1879     #
1880     # As between the public view and the local tracking branch: The
1881     # local tracking branch is only updated by dgit fetch, and
1882     # whenever dgit fetch runs it includes the public view in the
1883     # local tracking branch.  Therefore if the public view is not
1884     # descended from the local tracking branch, the local tracking
1885     # branch must contain history which was imported from the archive
1886     # but never pushed; and, its tip is now out of date.  So, we make
1887     # a pseudo-merge to overwrite the old imports and stitch the old
1888     # history in.
1889     #
1890     # Finally: we do not necessarily reify the public view (as
1891     # described above).  This is so that we do not end up stacking two
1892     # pseudo-merges.  So what we actually do is figure out the inputs
1893     # to any public view psuedo-merge and put them in @mergeinputs.
1894
1895     my @mergeinputs;
1896     # $mergeinputs[]{Commit}
1897     # $mergeinputs[]{Info}
1898     # $mergeinputs[0] is the one whose tree we use
1899     # @mergeinputs is in the order we use in the actual commit)
1900     #
1901     # Also:
1902     # $mergeinputs[]{Message} is a commit message to use
1903     # $mergeinputs[]{ReverseParents} if def specifies that parent
1904     #                                list should be in opposite order
1905     # Such an entry has no Commit or Info.  It applies only when found
1906     # in the last entry.  (This ugliness is to support making
1907     # identical imports to previous dgit versions.)
1908
1909     my $lastpush_hash = git_get_ref(lrfetchref());
1910     printdebug "previous reference hash=$lastpush_hash\n";
1911     $lastpush_mergeinput = $lastpush_hash && {
1912         Commit => $lastpush_hash,
1913         Info => "dgit suite branch on dgit git server",
1914     };
1915
1916     my $lastfetch_hash = git_get_ref(lrref());
1917     printdebug "fetch_from_archive: lastfetch=$lastfetch_hash\n";
1918     my $lastfetch_mergeinput = $lastfetch_hash && {
1919         Commit => $lastfetch_hash,
1920         Info => "dgit client's archive history view",
1921     };
1922
1923     my $dsc_mergeinput = $dsc_hash && {
1924         Commit => $dsc_hash,
1925         Info => "Dgit field in .dsc from archive",
1926     };
1927
1928     my $cwd = getcwd();
1929     my $del_lrfetchrefs = sub {
1930         changedir $cwd;
1931         my $gur;
1932         printdebug "del_lrfetchrefs...\n";
1933         foreach my $fullrefname (sort keys %lrfetchrefs_d) {
1934             my $objid = $lrfetchrefs_d{$fullrefname};
1935             printdebug "del_lrfetchrefs: $objid $fullrefname\n";
1936             if (!$gur) {
1937                 $gur ||= new IO::Handle;
1938                 open $gur, "|-", qw(git update-ref --stdin) or die $!;
1939             }
1940             printf $gur "delete %s %s\n", $fullrefname, $objid;
1941         }
1942         if ($gur) {
1943             close $gur or failedcmd "git update-ref delete lrfetchrefs";
1944         }
1945     };
1946
1947     if (defined $dsc_hash) {
1948         fail "missing remote git history even though dsc has hash -".
1949             " could not find ref ".rref()." at ".access_giturl()
1950             unless $lastpush_hash;
1951         ensure_we_have_orig();
1952         if ($dsc_hash eq $lastpush_hash) {
1953             @mergeinputs = $dsc_mergeinput
1954         } elsif (is_fast_fwd($dsc_hash,$lastpush_hash)) {
1955             print STDERR <<END or die $!;
1956
1957 Git commit in archive is behind the last version allegedly pushed/uploaded.
1958 Commit referred to by archive: $dsc_hash
1959 Last version pushed with dgit: $lastpush_hash
1960 $later_warning_msg
1961 END
1962             @mergeinputs = ($lastpush_mergeinput);
1963         } else {
1964             # Archive has .dsc which is not a descendant of the last dgit
1965             # push.  This can happen if the archive moves .dscs about.
1966             # Just follow its lead.
1967             if (is_fast_fwd($lastpush_hash,$dsc_hash)) {
1968                 progress "archive .dsc names newer git commit";
1969                 @mergeinputs = ($dsc_mergeinput);
1970             } else {
1971                 progress "archive .dsc names other git commit, fixing up";
1972                 @mergeinputs = ($dsc_mergeinput, $lastpush_mergeinput);
1973             }
1974         }
1975     } elsif ($dsc) {
1976         @mergeinputs = generate_commits_from_dsc();
1977         # We have just done an import.  Now, our import algorithm might
1978         # have been improved.  But even so we do not want to generate
1979         # a new different import of the same package.  So if the
1980         # version numbers are the same, just use our existing version.
1981         # If the version numbers are different, the archive has changed
1982         # (perhaps, rewound).
1983         if ($lastfetch_mergeinput &&
1984             !version_compare( (mergeinfo_version $lastfetch_mergeinput),
1985                               (mergeinfo_version $mergeinputs[0]) )) {
1986             @mergeinputs = ($lastfetch_mergeinput);
1987         }
1988     } elsif ($lastpush_hash) {
1989         # only in git, not in the archive yet
1990         @mergeinputs = ($lastpush_mergeinput);
1991         print STDERR <<END or die $!;
1992
1993 Package not found in the archive, but has allegedly been pushed using dgit.
1994 $later_warning_msg
1995 END
1996     } else {
1997         printdebug "nothing found!\n";
1998         if (defined $skew_warning_vsn) {
1999             print STDERR <<END or die $!;
2000
2001 Warning: relevant archive skew detected.
2002 Archive allegedly contains $skew_warning_vsn
2003 But we were not able to obtain any version from the archive or git.
2004
2005 END
2006         }
2007         unshift @end, $del_lrfetchrefs;
2008         return undef;
2009     }
2010
2011     if ($lastfetch_hash &&
2012         !grep {
2013             my $h = $_->{Commit};
2014             $h and is_fast_fwd($lastfetch_hash, $h);
2015             # If true, one of the existing parents of this commit
2016             # is a descendant of the $lastfetch_hash, so we'll
2017             # be ff from that automatically.
2018         } @mergeinputs
2019         ) {
2020         # Otherwise:
2021         push @mergeinputs, $lastfetch_mergeinput;
2022     }
2023
2024     printdebug "fetch mergeinfos:\n";
2025     foreach my $mi (@mergeinputs) {
2026         if ($mi->{Info}) {
2027             printdebug " commit $mi->{Commit} $mi->{Info}\n";
2028         } else {
2029             printdebug sprintf " ReverseParents=%d Message=%s",
2030                 $mi->{ReverseParents}, $mi->{Message};
2031         }
2032     }
2033
2034     my $compat_info= pop @mergeinputs
2035         if $mergeinputs[$#mergeinputs]{Message};
2036
2037     @mergeinputs = grep { defined $_->{Commit} } @mergeinputs;
2038
2039     my $hash;
2040     if (@mergeinputs > 1) {
2041         # here we go, then:
2042         my $tree_commit = $mergeinputs[0]{Commit};
2043
2044         my $tree = cmdoutput @git, qw(cat-file commit), $tree_commit;
2045         $tree =~ m/\n\n/;  $tree = $`;
2046         $tree =~ m/^tree (\w+)$/m or die "$dsc_hash tree ?";
2047         $tree = $1;
2048
2049         # We use the changelog author of the package in question the
2050         # author of this pseudo-merge.  This is (roughly) correct if
2051         # this commit is simply representing aa non-dgit upload.
2052         # (Roughly because it does not record sponsorship - but we
2053         # don't have sponsorship info because that's in the .changes,
2054         # which isn't in the archivw.)
2055         #
2056         # But, it might be that we are representing archive history
2057         # updates (including in-archive copies).  These are not really
2058         # the responsibility of the person who created the .dsc, but
2059         # there is no-one whose name we should better use.  (The
2060         # author of the .dsc-named commit is clearly worse.)
2061
2062         my $useclogp = mergeinfo_getclogp $mergeinputs[0];
2063         my $author = clogp_authline $useclogp;
2064         my $cversion = getfield $useclogp, 'Version';
2065
2066         my $mcf = ".git/dgit/mergecommit";
2067         open MC, ">", $mcf or die "$mcf $!";
2068         print MC <<END or die $!;
2069 tree $tree
2070 END
2071
2072         my @parents = grep { $_->{Commit} } @mergeinputs;
2073         @parents = reverse @parents if $compat_info->{ReverseParents};
2074         print MC <<END or die $! foreach @parents;
2075 parent $_->{Commit}
2076 END
2077
2078         print MC <<END or die $!;
2079 author $author
2080 committer $author
2081
2082 END
2083
2084         if (defined $compat_info->{Message}) {
2085             print MC $compat_info->{Message} or die $!;
2086         } else {
2087             print MC <<END or die $!;
2088 Record $package ($cversion) in archive suite $csuite
2089
2090 Record that
2091 END
2092             my $message_add_info = sub {
2093                 my ($mi) = (@_);
2094                 my $mversion = mergeinfo_version $mi;
2095                 printf MC "  %-20s %s\n", $mversion, $mi->{Info}
2096                     or die $!;
2097             };
2098
2099             $message_add_info->($mergeinputs[0]);
2100             print MC <<END or die $!;
2101 should be treated as descended from
2102 END
2103             $message_add_info->($_) foreach @mergeinputs[1..$#mergeinputs];
2104         }
2105
2106         close MC or die $!;
2107         $hash = make_commit $mcf;
2108     } else {
2109         $hash = $mergeinputs[0]{Commit};
2110     }
2111     progress "fetch hash=$hash\n";
2112
2113     my $chkff = sub {
2114         my ($lasth, $what) = @_;
2115         return unless $lasth;
2116         die "$lasth $hash $what ?" unless is_fast_fwd($lasth, $hash);
2117     };
2118
2119     $chkff->($lastpush_hash, 'dgit repo server tip (last push)');
2120     $chkff->($lastfetch_hash, 'local tracking tip (last fetch)');
2121
2122     runcmd @git, qw(update-ref -m), "dgit fetch $csuite",
2123             'DGIT_ARCHIVE', $hash;
2124     cmdoutput @git, qw(log -n2), $hash;
2125     # ... gives git a chance to complain if our commit is malformed
2126
2127     if (defined $skew_warning_vsn) {
2128         mkpath '.git/dgit';
2129         printdebug "SKEW CHECK WANT $skew_warning_vsn\n";
2130         my $gotclogp = commit_getclogp($hash);
2131         my $got_vsn = getfield $gotclogp, 'Version';
2132         printdebug "SKEW CHECK GOT $got_vsn\n";
2133         if (version_compare($got_vsn, $skew_warning_vsn) < 0) {
2134             print STDERR <<END or die $!;
2135
2136 Warning: archive skew detected.  Using the available version:
2137 Archive allegedly contains    $skew_warning_vsn
2138 We were able to obtain only   $got_vsn
2139
2140 END
2141         }
2142     }
2143
2144     if ($lastfetch_hash ne $hash) {
2145         my @upd_cmd = (@git, qw(update-ref -m), 'dgit fetch', lrref(), $hash);
2146         if (act_local()) {
2147             cmdoutput @upd_cmd;
2148         } else {
2149             dryrun_report @upd_cmd;
2150         }
2151     }
2152
2153     lrfetchref_used lrfetchref();
2154
2155     unshift @end, $del_lrfetchrefs;
2156     return $hash;
2157 }
2158
2159 sub set_local_git_config ($$) {
2160     my ($k, $v) = @_;
2161     runcmd @git, qw(config), $k, $v;
2162 }
2163
2164 sub setup_mergechangelogs (;$) {
2165     my ($always) = @_;
2166     return unless $always || access_cfg_bool(1, 'setup-mergechangelogs');
2167
2168     my $driver = 'dpkg-mergechangelogs';
2169     my $cb = "merge.$driver";
2170     my $attrs = '.git/info/attributes';
2171     ensuredir '.git/info';
2172
2173     open NATTRS, ">", "$attrs.new" or die "$attrs.new $!";
2174     if (!open ATTRS, "<", $attrs) {
2175         $!==ENOENT or die "$attrs: $!";
2176     } else {
2177         while (<ATTRS>) {
2178             chomp;
2179             next if m{^debian/changelog\s};
2180             print NATTRS $_, "\n" or die $!;
2181         }
2182         ATTRS->error and die $!;
2183         close ATTRS;
2184     }
2185     print NATTRS "debian/changelog merge=$driver\n" or die $!;
2186     close NATTRS;
2187
2188     set_local_git_config "$cb.name", 'debian/changelog merge driver';
2189     set_local_git_config "$cb.driver", 'dpkg-mergechangelogs -m %O %A %B %A';
2190
2191     rename "$attrs.new", "$attrs" or die "$attrs: $!";
2192 }
2193
2194 sub setup_useremail (;$) {
2195     my ($always) = @_;
2196     return unless $always || access_cfg_bool(1, 'setup-useremail');
2197
2198     my $setup = sub {
2199         my ($k, $envvar) = @_;
2200         my $v = access_cfg("user-$k", 'RETURN-UNDEF') // $ENV{$envvar};
2201         return unless defined $v;
2202         set_local_git_config "user.$k", $v;
2203     };
2204
2205     $setup->('email', 'DEBEMAIL');
2206     $setup->('name', 'DEBFULLNAME');
2207 }
2208
2209 sub setup_new_tree () {
2210     setup_mergechangelogs();
2211     setup_useremail();
2212 }
2213
2214 sub clone ($) {
2215     my ($dstdir) = @_;
2216     canonicalise_suite();
2217     badusage "dry run makes no sense with clone" unless act_local();
2218     my $hasgit = check_for_git();
2219     mkdir $dstdir or fail "create \`$dstdir': $!";
2220     changedir $dstdir;
2221     runcmd @git, qw(init -q);
2222     my $giturl = access_giturl(1);
2223     if (defined $giturl) {
2224         open H, "> .git/HEAD" or die $!;
2225         print H "ref: ".lref()."\n" or die $!;
2226         close H or die $!;
2227         runcmd @git, qw(remote add), 'origin', $giturl;
2228     }
2229     if ($hasgit) {
2230         progress "fetching existing git history";
2231         git_fetch_us();
2232         runcmd_ordryrun_local @git, qw(fetch origin);
2233     } else {
2234         progress "starting new git history";
2235     }
2236     fetch_from_archive() or no_such_package;
2237     my $vcsgiturl = $dsc->{'Vcs-Git'};
2238     if (length $vcsgiturl) {
2239         $vcsgiturl =~ s/\s+-b\s+\S+//g;
2240         runcmd @git, qw(remote add vcs-git), $vcsgiturl;
2241     }
2242     setup_new_tree();
2243     runcmd @git, qw(reset --hard), lrref();
2244     printdone "ready for work in $dstdir";
2245 }
2246
2247 sub fetch () {
2248     if (check_for_git()) {
2249         git_fetch_us();
2250     }
2251     fetch_from_archive() or no_such_package();
2252     printdone "fetched into ".lrref();
2253 }
2254
2255 sub pull () {
2256     fetch();
2257     runcmd_ordryrun_local @git, qw(merge -m),"Merge from $csuite [dgit]",
2258         lrref();
2259     printdone "fetched to ".lrref()." and merged into HEAD";
2260 }
2261
2262 sub check_not_dirty () {
2263     foreach my $f (qw(local-options local-patch-header)) {
2264         if (stat_exists "debian/source/$f") {
2265             fail "git tree contains debian/source/$f";
2266         }
2267     }
2268
2269     return if $ignoredirty;
2270
2271     my @cmd = (@git, qw(diff --quiet HEAD));
2272     debugcmd "+",@cmd;
2273     $!=0; $?=-1; system @cmd;
2274     return if !$?;
2275     if ($?==256) {
2276         fail "working tree is dirty (does not match HEAD)";
2277     } else {
2278         failedcmd @cmd;
2279     }
2280 }
2281
2282 sub commit_admin ($) {
2283     my ($m) = @_;
2284     progress "$m";
2285     runcmd_ordryrun_local @git, qw(commit -m), $m;
2286 }
2287
2288 sub commit_quilty_patch () {
2289     my $output = cmdoutput @git, qw(status --porcelain);
2290     my %adds;
2291     foreach my $l (split /\n/, $output) {
2292         next unless $l =~ m/\S/;
2293         if ($l =~ m{^(?:\?\?| M) (.pc|debian/patches)}) {
2294             $adds{$1}++;
2295         }
2296     }
2297     delete $adds{'.pc'}; # if there wasn't one before, don't add it
2298     if (!%adds) {
2299         progress "nothing quilty to commit, ok.";
2300         return;
2301     }
2302     my @adds = map { s/[][*?\\]/\\$&/g; $_; } sort keys %adds;
2303     runcmd_ordryrun_local @git, qw(add -f), @adds;
2304     commit_admin "Commit Debian 3.0 (quilt) metadata";
2305 }
2306
2307 sub get_source_format () {
2308     my %options;
2309     if (open F, "debian/source/options") {
2310         while (<F>) {
2311             next if m/^\s*\#/;
2312             next unless m/\S/;
2313             s/\s+$//; # ignore missing final newline
2314             if (m/\s*\#\s*/) {
2315                 my ($k, $v) = ($`, $'); #');
2316                 $v =~ s/^"(.*)"$/$1/;
2317                 $options{$k} = $v;
2318             } else {
2319                 $options{$_} = 1;
2320             }
2321         }
2322         F->error and die $!;
2323         close F;
2324     } else {
2325         die $! unless $!==&ENOENT;
2326     }
2327
2328     if (!open F, "debian/source/format") {
2329         die $! unless $!==&ENOENT;
2330         return '';
2331     }
2332     $_ = <F>;
2333     F->error and die $!;
2334     chomp;
2335     return ($_, \%options);
2336 }
2337
2338 sub madformat ($) {
2339     my ($format) = @_;
2340     return 0 unless $format eq '3.0 (quilt)';
2341     our $quilt_mode_warned;
2342     if ($quilt_mode eq 'nocheck') {
2343         progress "Not doing any fixup of \`$format' due to".
2344             " ----no-quilt-fixup or --quilt=nocheck"
2345             unless $quilt_mode_warned++;
2346         return 0;
2347     }
2348     progress "Format \`$format', need to check/update patch stack"
2349         unless $quilt_mode_warned++;
2350     return 1;
2351 }
2352
2353 sub push_parse_changelog ($) {
2354     my ($clogpfn) = @_;
2355
2356     my $clogp = Dpkg::Control::Hash->new();
2357     $clogp->load($clogpfn) or die;
2358
2359     $package = getfield $clogp, 'Source';
2360     my $cversion = getfield $clogp, 'Version';
2361     my $tag = debiantag($cversion, access_basedistro);
2362     runcmd @git, qw(check-ref-format), $tag;
2363
2364     my $dscfn = dscfn($cversion);
2365
2366     return ($clogp, $cversion, $dscfn);
2367 }
2368
2369 sub push_parse_dsc ($$$) {
2370     my ($dscfn,$dscfnwhat, $cversion) = @_;
2371     $dsc = parsecontrol($dscfn,$dscfnwhat);
2372     my $dversion = getfield $dsc, 'Version';
2373     my $dscpackage = getfield $dsc, 'Source';
2374     ($dscpackage eq $package && $dversion eq $cversion) or
2375         fail "$dscfn is for $dscpackage $dversion".
2376             " but debian/changelog is for $package $cversion";
2377 }
2378
2379 sub push_tagwants ($$$$) {
2380     my ($cversion, $dgithead, $maintviewhead, $tfbase) = @_;
2381     my @tagwants;
2382     push @tagwants, {
2383         TagFn => \&debiantag,
2384         Objid => $dgithead,
2385         TfSuffix => '',
2386         View => 'dgit',
2387     };
2388     if (defined $maintviewhead) {
2389         push @tagwants, {
2390             TagFn => \&debiantag_maintview,
2391             Objid => $maintviewhead,
2392             TfSuffix => '-maintview',
2393             View => 'maint',
2394         };
2395     }
2396     foreach my $tw (@tagwants) {
2397         $tw->{Tag} = $tw->{TagFn}($cversion, access_basedistro);
2398         $tw->{Tfn} = sub { $tfbase.$tw->{TfSuffix}.$_[0]; };
2399     }
2400     printdebug 'push_tagwants: ', Dumper(\@_, \@tagwants);
2401     return @tagwants;
2402 }
2403
2404 sub push_mktags ($$ $$ $) {
2405     my ($clogp,$dscfn,
2406         $changesfile,$changesfilewhat,
2407         $tagwants) = @_;
2408
2409     die unless $tagwants->[0]{View} eq 'dgit';
2410
2411     $dsc->{$ourdscfield[0]} = $tagwants->[0]{Objid};
2412     $dsc->save("$dscfn.tmp") or die $!;
2413
2414     my $changes = parsecontrol($changesfile,$changesfilewhat);
2415     foreach my $field (qw(Source Distribution Version)) {
2416         $changes->{$field} eq $clogp->{$field} or
2417             fail "changes field $field \`$changes->{$field}'".
2418                 " does not match changelog \`$clogp->{$field}'";
2419     }
2420
2421     my $cversion = getfield $clogp, 'Version';
2422     my $clogsuite = getfield $clogp, 'Distribution';
2423
2424     # We make the git tag by hand because (a) that makes it easier
2425     # to control the "tagger" (b) we can do remote signing
2426     my $authline = clogp_authline $clogp;
2427     my $delibs = join(" ", "",@deliberatelies);
2428     my $declaredistro = access_basedistro();
2429
2430     my $mktag = sub {
2431         my ($tw) = @_;
2432         my $tfn = $tw->{Tfn};
2433         my $head = $tw->{Objid};
2434         my $tag = $tw->{Tag};
2435
2436         open TO, '>', $tfn->('.tmp') or die $!;
2437         print TO <<END or die $!;
2438 object $head
2439 type commit
2440 tag $tag
2441 tagger $authline
2442
2443 END
2444         if ($tw->{View} eq 'dgit') {
2445             print TO <<END or die $!;
2446 $package release $cversion for $clogsuite ($csuite) [dgit]
2447 [dgit distro=$declaredistro$delibs]
2448 END
2449             foreach my $ref (sort keys %previously) {
2450                 print TO <<END or die $!;
2451 [dgit previously:$ref=$previously{$ref}]
2452 END
2453             }
2454         } elsif ($tw->{View} eq 'maint') {
2455             print TO <<END or die $!;
2456 $package release $cversion for $clogsuite ($csuite)
2457 (maintainer view tag generated by dgit --quilt=$quilt_mode)
2458 END
2459         } else {
2460             die Dumper($tw)."?";
2461         }
2462
2463         close TO or die $!;
2464
2465         my $tagobjfn = $tfn->('.tmp');
2466         if ($sign) {
2467             if (!defined $keyid) {
2468                 $keyid = access_cfg('keyid','RETURN-UNDEF');
2469             }
2470             if (!defined $keyid) {
2471                 $keyid = getfield $clogp, 'Maintainer';
2472             }
2473             unlink $tfn->('.tmp.asc') or $!==&ENOENT or die $!;
2474             my @sign_cmd = (@gpg, qw(--detach-sign --armor));
2475             push @sign_cmd, qw(-u),$keyid if defined $keyid;
2476             push @sign_cmd, $tfn->('.tmp');
2477             runcmd_ordryrun @sign_cmd;
2478             if (act_scary()) {
2479                 $tagobjfn = $tfn->('.signed.tmp');
2480                 runcmd shell_cmd "exec >$tagobjfn", qw(cat --),
2481                     $tfn->('.tmp'), $tfn->('.tmp.asc');
2482             }
2483         }
2484         return $tagobjfn;
2485     };
2486
2487     my @r = map { $mktag->($_); } @$tagwants;
2488     return @r;
2489 }
2490
2491 sub sign_changes ($) {
2492     my ($changesfile) = @_;
2493     if ($sign) {
2494         my @debsign_cmd = @debsign;
2495         push @debsign_cmd, "-k$keyid" if defined $keyid;
2496         push @debsign_cmd, "-p$gpg[0]" if $gpg[0] ne 'gpg';
2497         push @debsign_cmd, $changesfile;
2498         runcmd_ordryrun @debsign_cmd;
2499     }
2500 }
2501
2502 sub dopush () {
2503     printdebug "actually entering push\n";
2504
2505     supplementary_message(<<'END');
2506 Push failed, while checking state of the archive.
2507 You can retry the push, after fixing the problem, if you like.
2508 END
2509     if (check_for_git()) {
2510         git_fetch_us();
2511     }
2512     my $archive_hash = fetch_from_archive();
2513     if (!$archive_hash) {
2514         $new_package or
2515             fail "package appears to be new in this suite;".
2516                 " if this is intentional, use --new";
2517     }
2518
2519     supplementary_message(<<'END');
2520 Push failed, while preparing your push.
2521 You can retry the push, after fixing the problem, if you like.
2522 END
2523
2524     need_tagformat 'new', "quilt mode $quilt_mode"
2525         if quiltmode_splitbrain;
2526
2527     prep_ud();
2528
2529     access_giturl(); # check that success is vaguely likely
2530     select_tagformat();
2531
2532     my $clogpfn = ".git/dgit/changelog.822.tmp";
2533     runcmd shell_cmd "exec >$clogpfn", qw(dpkg-parsechangelog);
2534
2535     responder_send_file('parsed-changelog', $clogpfn);
2536
2537     my ($clogp, $cversion, $dscfn) =
2538         push_parse_changelog("$clogpfn");
2539
2540     my $dscpath = "$buildproductsdir/$dscfn";
2541     stat_exists $dscpath or
2542         fail "looked for .dsc $dscfn, but $!;".
2543             " maybe you forgot to build";
2544
2545     responder_send_file('dsc', $dscpath);
2546
2547     push_parse_dsc($dscpath, $dscfn, $cversion);
2548
2549     my $format = getfield $dsc, 'Format';
2550     printdebug "format $format\n";
2551
2552     my $actualhead = git_rev_parse('HEAD');
2553     my $dgithead = $actualhead;
2554     my $maintviewhead = undef;
2555
2556     if (madformat($format)) {
2557         # user might have not used dgit build, so maybe do this now:
2558         if (quiltmode_splitbrain()) {
2559             my $upstreamversion = $clogp->{Version};
2560             $upstreamversion =~ s/-[^-]*$//;
2561             changedir $ud;
2562             quilt_make_fake_dsc($upstreamversion);
2563             my ($dgitview, $cachekey) =
2564                 quilt_check_splitbrain_cache($actualhead, $upstreamversion);
2565             $dgitview or fail
2566  "--quilt=$quilt_mode but no cached dgit view:
2567  perhaps tree changed since dgit build[-source] ?";
2568             $split_brain = 1;
2569             $dgithead = $dgitview;
2570             $maintviewhead = $actualhead;
2571             changedir '../../../..';
2572             prep_ud(); # so _only_subdir() works, below
2573         } else {
2574             commit_quilty_patch();
2575         }
2576     }
2577
2578     check_not_dirty();
2579
2580     my $forceflag = '';
2581     if ($archive_hash) {
2582         if (is_fast_fwd($archive_hash, $dgithead)) {
2583             # ok
2584         } elsif (deliberately_not_fast_forward) {
2585             $forceflag = '+';
2586         } else {
2587             fail "dgit push: HEAD is not a descendant".
2588                 " of the archive's version.\n".
2589                 "dgit: To overwrite its contents,".
2590                 " use git merge -s ours ".lrref().".\n".
2591                 "dgit: To rewind history, if permitted by the archive,".
2592                 " use --deliberately-not-fast-forward";
2593         }
2594     }
2595
2596     changedir $ud;
2597     progress "checking that $dscfn corresponds to HEAD";
2598     runcmd qw(dpkg-source -x --),
2599         $dscpath =~ m#^/# ? $dscpath : "../../../$dscpath";
2600     my ($tree,$dir) = mktree_in_ud_from_only_subdir();
2601     check_for_vendor_patches() if madformat($dsc->{format});
2602     changedir '../../../..';
2603     my $diffopt = $debuglevel>0 ? '--exit-code' : '--quiet';
2604     my @diffcmd = (@git, qw(diff), $diffopt, $tree, $dgithead);
2605     debugcmd "+",@diffcmd;
2606     $!=0; $?=-1;
2607     my $r = system @diffcmd;
2608     if ($r) {
2609         if ($r==256) {
2610             fail "$dscfn specifies a different tree to your HEAD commit;".
2611                 " perhaps you forgot to build".
2612                 ($diffopt eq '--exit-code' ? "" :
2613                  " (run with -D to see full diff output)");
2614         } else {
2615             failedcmd @diffcmd;
2616         }
2617     }
2618     if (!$changesfile) {
2619         my $pat = changespat $cversion;
2620         my @cs = glob "$buildproductsdir/$pat";
2621         fail "failed to find unique changes file".
2622             " (looked for $pat in $buildproductsdir);".
2623             " perhaps you need to use dgit -C"
2624             unless @cs==1;
2625         ($changesfile) = @cs;
2626     } else {
2627         $changesfile = "$buildproductsdir/$changesfile";
2628     }
2629
2630     # Checks complete, we're going to try and go ahead:
2631
2632     responder_send_file('changes',$changesfile);
2633     responder_send_command("param head $dgithead");
2634     responder_send_command("param csuite $csuite");
2635     responder_send_command("param tagformat $tagformat");
2636     if (quiltmode_splitbrain) {
2637         die unless ($protovsn//4) >= 4;
2638         responder_send_command("param maint-view $maintviewhead");
2639     }
2640
2641     if (deliberately_not_fast_forward) {
2642         git_for_each_ref(lrfetchrefs, sub {
2643             my ($objid,$objtype,$lrfetchrefname,$reftail) = @_;
2644             my $rrefname= substr($lrfetchrefname, length(lrfetchrefs) + 1);
2645             responder_send_command("previously $rrefname=$objid");
2646             $previously{$rrefname} = $objid;
2647         });
2648     }
2649
2650     my @tagwants = push_tagwants($cversion, $dgithead, $maintviewhead,
2651                                  ".git/dgit/tag");
2652     my @tagobjfns;
2653
2654     supplementary_message(<<'END');
2655 Push failed, while signing the tag.
2656 You can retry the push, after fixing the problem, if you like.
2657 END
2658     # If we manage to sign but fail to record it anywhere, it's fine.
2659     if ($we_are_responder) {
2660         @tagobjfns = map { $_->{Tfn}('.signed-tmp') } @tagwants;
2661         responder_receive_files('signed-tag', @tagobjfns);
2662     } else {
2663         @tagobjfns = push_mktags($clogp,$dscpath,
2664                               $changesfile,$changesfile,
2665                               \@tagwants);
2666     }
2667     supplementary_message(<<'END');
2668 Push failed, *after* signing the tag.
2669 If you want to try again, you should use a new version number.
2670 END
2671
2672     pairwise { $a->{TagObjFn} = $b } @tagwants, @tagobjfns;
2673
2674     foreach my $tw (@tagwants) {
2675         my $tag = $tw->{Tag};
2676         my $tagobjfn = $tw->{TagObjFn};
2677         my $tag_obj_hash =
2678             cmdoutput @git, qw(hash-object -w -t tag), $tagobjfn;
2679         runcmd_ordryrun @git, qw(verify-tag), $tag_obj_hash;
2680         runcmd_ordryrun_local
2681             @git, qw(update-ref), "refs/tags/$tag", $tag_obj_hash;
2682     }
2683
2684     supplementary_message(<<'END');
2685 Push failed, while updating the remote git repository - see messages above.
2686 If you want to try again, you should use a new version number.
2687 END
2688     if (!check_for_git()) {
2689         create_remote_git_repo();
2690     }
2691
2692     my @pushrefs = $forceflag.$dgithead.":".rrref();
2693     foreach my $tw (@tagwants) {
2694         my $view = $tw->{View};
2695         next unless $view eq 'dgit'
2696             or any { $_ eq $view } access_cfg_tagformats();
2697             # ^ $view is "dgit" or "maint" so this looks for "maint"
2698             # in archive supported tagformats.
2699         push @pushrefs, $forceflag."refs/tags/$tw->{Tag}";
2700     }
2701
2702     runcmd_ordryrun @git, qw(push),access_giturl(), @pushrefs;
2703     runcmd_ordryrun @git, qw(update-ref -m), 'dgit push', lrref(), $dgithead;
2704
2705     supplementary_message(<<'END');
2706 Push failed, after updating the remote git repository.
2707 If you want to try again, you must use a new version number.
2708 END
2709     if ($we_are_responder) {
2710         my $dryrunsuffix = act_local() ? "" : ".tmp";
2711         responder_receive_files('signed-dsc-changes',
2712                                 "$dscpath$dryrunsuffix",
2713                                 "$changesfile$dryrunsuffix");
2714     } else {
2715         if (act_local()) {
2716             rename "$dscpath.tmp",$dscpath or die "$dscfn $!";
2717         } else {
2718             progress "[new .dsc left in $dscpath.tmp]";
2719         }
2720         sign_changes $changesfile;
2721     }
2722
2723     supplementary_message(<<END);
2724 Push failed, while uploading package(s) to the archive server.
2725 You can retry the upload of exactly these same files with dput of:
2726   $changesfile
2727 If that .changes file is broken, you will need to use a new version
2728 number for your next attempt at the upload.
2729 END
2730     my $host = access_cfg('upload-host','RETURN-UNDEF');
2731     my @hostarg = defined($host) ? ($host,) : ();
2732     runcmd_ordryrun @dput, @hostarg, $changesfile;
2733     printdone "pushed and uploaded $cversion";
2734
2735     supplementary_message('');
2736     responder_send_command("complete");
2737 }
2738
2739 sub cmd_clone {
2740     parseopts();
2741     notpushing();
2742     my $dstdir;
2743     badusage "-p is not allowed with clone; specify as argument instead"
2744         if defined $package;
2745     if (@ARGV==1) {
2746         ($package) = @ARGV;
2747     } elsif (@ARGV==2 && $ARGV[1] =~ m#^\w#) {
2748         ($package,$isuite) = @ARGV;
2749     } elsif (@ARGV==2 && $ARGV[1] =~ m#^[./]#) {
2750         ($package,$dstdir) = @ARGV;
2751     } elsif (@ARGV==3) {
2752         ($package,$isuite,$dstdir) = @ARGV;
2753     } else {
2754         badusage "incorrect arguments to dgit clone";
2755     }
2756     $dstdir ||= "$package";
2757
2758     if (stat_exists $dstdir) {
2759         fail "$dstdir already exists";
2760     }
2761
2762     my $cwd_remove;
2763     if ($rmonerror && !$dryrun_level) {
2764         $cwd_remove= getcwd();
2765         unshift @end, sub { 
2766             return unless defined $cwd_remove;
2767             if (!chdir "$cwd_remove") {
2768                 return if $!==&ENOENT;
2769                 die "chdir $cwd_remove: $!";
2770             }
2771             if (stat $dstdir) {
2772                 rmtree($dstdir) or die "remove $dstdir: $!\n";
2773             } elsif (!grep { $! == $_ }
2774                      (ENOENT, ENOTDIR, EACCES, EPERM, ELOOP)) {
2775             } else {
2776                 print STDERR "check whether to remove $dstdir: $!\n";
2777             }
2778         };
2779     }
2780
2781     clone($dstdir);
2782     $cwd_remove = undef;
2783 }
2784
2785 sub branchsuite () {
2786     my $branch = cmdoutput_errok @git, qw(symbolic-ref HEAD);
2787     if ($branch =~ m#$lbranch_re#o) {
2788         return $1;
2789     } else {
2790         return undef;
2791     }
2792 }
2793
2794 sub fetchpullargs () {
2795     notpushing();
2796     if (!defined $package) {
2797         my $sourcep = parsecontrol('debian/control','debian/control');
2798         $package = getfield $sourcep, 'Source';
2799     }
2800     if (@ARGV==0) {
2801 #       $isuite = branchsuite();  # this doesn't work because dak hates canons
2802         if (!$isuite) {
2803             my $clogp = parsechangelog();
2804             $isuite = getfield $clogp, 'Distribution';
2805         }
2806         canonicalise_suite();
2807         progress "fetching from suite $csuite";
2808     } elsif (@ARGV==1) {
2809         ($isuite) = @ARGV;
2810         canonicalise_suite();
2811     } else {
2812         badusage "incorrect arguments to dgit fetch or dgit pull";
2813     }
2814 }
2815
2816 sub cmd_fetch {
2817     parseopts();
2818     fetchpullargs();
2819     fetch();
2820 }
2821
2822 sub cmd_pull {
2823     parseopts();
2824     fetchpullargs();
2825     pull();
2826 }
2827
2828 sub cmd_push {
2829     parseopts();
2830     pushing();
2831     badusage "-p is not allowed with dgit push" if defined $package;
2832     check_not_dirty();
2833     my $clogp = parsechangelog();
2834     $package = getfield $clogp, 'Source';
2835     my $specsuite;
2836     if (@ARGV==0) {
2837     } elsif (@ARGV==1) {
2838         ($specsuite) = (@ARGV);
2839     } else {
2840         badusage "incorrect arguments to dgit push";
2841     }
2842     $isuite = getfield $clogp, 'Distribution';
2843     if ($new_package) {
2844         local ($package) = $existing_package; # this is a hack
2845         canonicalise_suite();
2846     } else {
2847         canonicalise_suite();
2848     }
2849     if (defined $specsuite &&
2850         $specsuite ne $isuite &&
2851         $specsuite ne $csuite) {
2852             fail "dgit push: changelog specifies $isuite ($csuite)".
2853                 " but command line specifies $specsuite";
2854     }
2855     dopush();
2856 }
2857
2858 #---------- remote commands' implementation ----------
2859
2860 sub cmd_remote_push_build_host {
2861     my ($nrargs) = shift @ARGV;
2862     my (@rargs) = @ARGV[0..$nrargs-1];
2863     @ARGV = @ARGV[$nrargs..$#ARGV];
2864     die unless @rargs;
2865     my ($dir,$vsnwant) = @rargs;
2866     # vsnwant is a comma-separated list; we report which we have
2867     # chosen in our ready response (so other end can tell if they
2868     # offered several)
2869     $debugprefix = ' ';
2870     $we_are_responder = 1;
2871     $us .= " (build host)";
2872
2873     pushing();
2874
2875     open PI, "<&STDIN" or die $!;
2876     open STDIN, "/dev/null" or die $!;
2877     open PO, ">&STDOUT" or die $!;
2878     autoflush PO 1;
2879     open STDOUT, ">&STDERR" or die $!;
2880     autoflush STDOUT 1;
2881
2882     $vsnwant //= 1;
2883     ($protovsn) = grep {
2884         $vsnwant =~ m{^(?:.*,)?$_(?:,.*)?$}
2885     } @rpushprotovsn_support;
2886
2887     fail "build host has dgit rpush protocol versions ".
2888         (join ",", @rpushprotovsn_support).
2889         " but invocation host has $vsnwant"
2890         unless defined $protovsn;
2891
2892     responder_send_command("dgit-remote-push-ready $protovsn");
2893     rpush_handle_protovsn_bothends();
2894     changedir $dir;
2895     &cmd_push;
2896 }
2897
2898 sub cmd_remote_push_responder { cmd_remote_push_build_host(); }
2899 # ... for compatibility with proto vsn.1 dgit (just so that user gets
2900 #     a good error message)
2901
2902 sub rpush_handle_protovsn_bothends () {
2903     if ($protovsn < 4) {
2904         need_tagformat 'old', "rpush negotiated protocol $protovsn";
2905     }
2906     select_tagformat();
2907 }
2908
2909 our $i_tmp;
2910
2911 sub i_cleanup {
2912     local ($@, $?);
2913     my $report = i_child_report();
2914     if (defined $report) {
2915         printdebug "($report)\n";
2916     } elsif ($i_child_pid) {
2917         printdebug "(killing build host child $i_child_pid)\n";
2918         kill 15, $i_child_pid;
2919     }
2920     if (defined $i_tmp && !defined $initiator_tempdir) {
2921         changedir "/";
2922         eval { rmtree $i_tmp; };
2923     }
2924 }
2925
2926 END { i_cleanup(); }
2927
2928 sub i_method {
2929     my ($base,$selector,@args) = @_;
2930     $selector =~ s/\-/_/g;
2931     { no strict qw(refs); &{"${base}_${selector}"}(@args); }
2932 }
2933
2934 sub cmd_rpush {
2935     pushing();
2936     my $host = nextarg;
2937     my $dir;
2938     if ($host =~ m/^((?:[^][]|\[[^][]*\])*)\:/) {
2939         $host = $1;
2940         $dir = $'; #';
2941     } else {
2942         $dir = nextarg;
2943     }
2944     $dir =~ s{^-}{./-};
2945     my @rargs = ($dir);
2946     push @rargs, join ",", @rpushprotovsn_support;
2947     my @rdgit;
2948     push @rdgit, @dgit;
2949     push @rdgit, @ropts;
2950     push @rdgit, qw(remote-push-build-host), (scalar @rargs), @rargs;
2951     push @rdgit, @ARGV;
2952     my @cmd = (@ssh, $host, shellquote @rdgit);
2953     debugcmd "+",@cmd;
2954
2955     if (defined $initiator_tempdir) {
2956         rmtree $initiator_tempdir;
2957         mkdir $initiator_tempdir, 0700 or die "$initiator_tempdir: $!";
2958         $i_tmp = $initiator_tempdir;
2959     } else {
2960         $i_tmp = tempdir();
2961     }
2962     $i_child_pid = open2(\*RO, \*RI, @cmd);
2963     changedir $i_tmp;
2964     ($protovsn) = initiator_expect { m/^dgit-remote-push-ready (\S+)/ };
2965     die "$protovsn ?" unless grep { $_ eq $protovsn } @rpushprotovsn_support;
2966     $supplementary_message = '' unless $protovsn >= 3;
2967
2968     fail "rpush negotiated protocol version $protovsn".
2969         " which does not support quilt mode $quilt_mode"
2970         if quiltmode_splitbrain;
2971
2972     rpush_handle_protovsn_bothends();
2973     for (;;) {
2974         my ($icmd,$iargs) = initiator_expect {
2975             m/^(\S+)(?: (.*))?$/;
2976             ($1,$2);
2977         };
2978         i_method "i_resp", $icmd, $iargs;
2979     }
2980 }
2981
2982 sub i_resp_progress ($) {
2983     my ($rhs) = @_;
2984     my $msg = protocol_read_bytes \*RO, $rhs;
2985     progress $msg;
2986 }
2987
2988 sub i_resp_supplementary_message ($) {
2989     my ($rhs) = @_;
2990     $supplementary_message = protocol_read_bytes \*RO, $rhs;
2991 }
2992
2993 sub i_resp_complete {
2994     my $pid = $i_child_pid;
2995     $i_child_pid = undef; # prevents killing some other process with same pid
2996     printdebug "waiting for build host child $pid...\n";
2997     my $got = waitpid $pid, 0;
2998     die $! unless $got == $pid;
2999     die "build host child failed $?" if $?;
3000
3001     i_cleanup();
3002     printdebug "all done\n";
3003     exit 0;
3004 }
3005
3006 sub i_resp_file ($) {
3007     my ($keyword) = @_;
3008     my $localname = i_method "i_localname", $keyword;
3009     my $localpath = "$i_tmp/$localname";
3010     stat_exists $localpath and
3011         badproto \*RO, "file $keyword ($localpath) twice";
3012     protocol_receive_file \*RO, $localpath;
3013     i_method "i_file", $keyword;
3014 }
3015
3016 our %i_param;
3017
3018 sub i_resp_param ($) {
3019     $_[0] =~ m/^(\S+) (.*)$/ or badproto \*RO, "bad param spec";
3020     $i_param{$1} = $2;
3021 }
3022
3023 sub i_resp_previously ($) {
3024     $_[0] =~ m#^(refs/tags/\S+)=(\w+)$#
3025         or badproto \*RO, "bad previously spec";
3026     my $r = system qw(git check-ref-format), $1;
3027     die "bad previously ref spec ($r)" if $r;
3028     $previously{$1} = $2;
3029 }
3030
3031 our %i_wanted;
3032
3033 sub i_resp_want ($) {
3034     my ($keyword) = @_;
3035     die "$keyword ?" if $i_wanted{$keyword}++;
3036     my @localpaths = i_method "i_want", $keyword;
3037     printdebug "[[  $keyword @localpaths\n";
3038     foreach my $localpath (@localpaths) {
3039         protocol_send_file \*RI, $localpath;
3040     }
3041     print RI "files-end\n" or die $!;
3042 }
3043
3044 our ($i_clogp, $i_version, $i_dscfn, $i_changesfn);
3045
3046 sub i_localname_parsed_changelog {
3047     return "remote-changelog.822";
3048 }
3049 sub i_file_parsed_changelog {
3050     ($i_clogp, $i_version, $i_dscfn) =
3051         push_parse_changelog "$i_tmp/remote-changelog.822";
3052     die if $i_dscfn =~ m#/|^\W#;
3053 }
3054
3055 sub i_localname_dsc {
3056     defined $i_dscfn or badproto \*RO, "dsc (before parsed-changelog)";
3057     return $i_dscfn;
3058 }
3059 sub i_file_dsc { }
3060
3061 sub i_localname_changes {
3062     defined $i_dscfn or badproto \*RO, "dsc (before parsed-changelog)";
3063     $i_changesfn = $i_dscfn;
3064     $i_changesfn =~ s/\.dsc$/_dgit.changes/ or die;
3065     return $i_changesfn;
3066 }
3067 sub i_file_changes { }
3068
3069 sub i_want_signed_tag {
3070     printdebug Dumper(\%i_param, $i_dscfn);
3071     defined $i_param{'head'} && defined $i_dscfn && defined $i_clogp
3072         && defined $i_param{'csuite'}
3073         or badproto \*RO, "premature desire for signed-tag";
3074     my $head = $i_param{'head'};
3075     die if $head =~ m/[^0-9a-f]/ || $head !~ m/^../;
3076
3077     my $maintview = $i_param{'maint-view'};
3078     die if defined $maintview && $maintview =~ m/[^0-9a-f]/;
3079
3080     select_tagformat();
3081     if ($protovsn >= 4) {
3082         my $p = $i_param{'tagformat'} // '<undef>';
3083         $p eq $tagformat
3084             or badproto \*RO, "tag format mismatch: $p vs. $tagformat";
3085     }
3086
3087     die unless $i_param{'csuite'} =~ m/^$suite_re$/;
3088     $csuite = $&;
3089     push_parse_dsc $i_dscfn, 'remote dsc', $i_version;
3090
3091     my @tagwants = push_tagwants $i_version, $head, $maintview, "tag";
3092
3093     return
3094         push_mktags $i_clogp, $i_dscfn,
3095             $i_changesfn, 'remote changes',
3096             \@tagwants;
3097 }
3098
3099 sub i_want_signed_dsc_changes {
3100     rename "$i_dscfn.tmp","$i_dscfn" or die "$i_dscfn $!";
3101     sign_changes $i_changesfn;
3102     return ($i_dscfn, $i_changesfn);
3103 }
3104
3105 #---------- building etc. ----------
3106
3107 our $version;
3108 our $sourcechanges;
3109 our $dscfn;
3110
3111 #----- `3.0 (quilt)' handling -----
3112
3113 our $fakeeditorenv = 'DGIT_FAKE_EDITOR_QUILT';
3114
3115 sub quiltify_dpkg_commit ($$$;$) {
3116     my ($patchname,$author,$msg, $xinfo) = @_;
3117     $xinfo //= '';
3118
3119     mkpath '.git/dgit';
3120     my $descfn = ".git/dgit/quilt-description.tmp";
3121     open O, '>', $descfn or die "$descfn: $!";
3122     $msg =~ s/\s+$//g;
3123     $msg =~ s/\n/\n /g;
3124     $msg =~ s/^\s+$/ ./mg;
3125     print O <<END or die $!;
3126 Description: $msg
3127 Author: $author
3128 $xinfo
3129 ---
3130
3131 END
3132     close O or die $!;
3133
3134     {
3135         local $ENV{'EDITOR'} = cmdoutput qw(realpath --), $0;
3136         local $ENV{'VISUAL'} = $ENV{'EDITOR'};
3137         local $ENV{$fakeeditorenv} = cmdoutput qw(realpath --), $descfn;
3138         runcmd @dpkgsource, qw(--commit .), $patchname;
3139     }
3140 }
3141
3142 sub quiltify_trees_differ ($$;$$) {
3143     my ($x,$y,$finegrained,$ignorenamesr) = @_;
3144     # returns true iff the two tree objects differ other than in debian/
3145     # with $finegrained,
3146     # returns bitmask 01 - differ in upstream files except .gitignore
3147     #                 02 - differ in .gitignore
3148     # if $ignorenamesr is defined, $ingorenamesr->{$fn}
3149     #  is set for each modified .gitignore filename $fn
3150     local $/=undef;
3151     my @cmd = (@git, qw(diff-tree --name-only -z));
3152     push @cmd, qw(-r) if $finegrained;
3153     push @cmd, $x, $y;
3154     my $diffs= cmdoutput @cmd;
3155     my $r = 0;
3156     foreach my $f (split /\0/, $diffs) {
3157         next if $f =~ m#^debian(?:/.*)?$#s;
3158         my $isignore = $f =~ m#^(?:.*/)?.gitignore$#s;
3159         $r |= $isignore ? 02 : 01;
3160         $ignorenamesr->{$f}=1 if $ignorenamesr && $isignore;
3161     }
3162     printdebug "quiltify_trees_differ $x $y => $r\n";
3163     return $r;
3164 }
3165
3166 sub quiltify_tree_sentinelfiles ($) {
3167     # lists the `sentinel' files present in the tree
3168     my ($x) = @_;
3169     my $r = cmdoutput @git, qw(ls-tree --name-only), $x,
3170         qw(-- debian/rules debian/control);
3171     $r =~ s/\n/,/g;
3172     return $r;
3173 }
3174
3175 sub quiltify_splitbrain_needed () {
3176     if (!$split_brain) {
3177         progress "dgit view: changes are required...";
3178         runcmd @git, qw(checkout -q -b dgit-view);
3179         $split_brain = 1;
3180     }
3181 }
3182
3183 sub quiltify_splitbrain ($$$$$$) {
3184     my ($clogp, $unapplied, $headref, $diffbits,
3185         $editedignores, $cachekey) = @_;
3186     if ($quilt_mode !~ m/gbp|dpm/) {
3187         # treat .gitignore just like any other upstream file
3188         $diffbits = { %$diffbits };
3189         $_ = !!$_ foreach values %$diffbits;
3190     }
3191     # We would like any commits we generate to be reproducible
3192     my @authline = clogp_authline($clogp);
3193     local $ENV{GIT_COMMITTER_NAME} =  $authline[0];
3194     local $ENV{GIT_COMMITTER_EMAIL} = $authline[1];
3195     local $ENV{GIT_COMMITTER_DATE} =  $authline[2];
3196         
3197     if ($quilt_mode =~ m/gbp|unapplied/ &&
3198         ($diffbits->{H2O} & 01)) {
3199         my $msg =
3200  "--quilt=$quilt_mode specified, implying patches-unapplied git tree\n".
3201  " but git tree differs from orig in upstream files.";
3202         if (!stat_exists "debian/patches") {
3203             $msg .=
3204  "\n ... debian/patches is missing; perhaps this is a patch queue branch?";
3205         }  
3206         fail $msg;
3207     }
3208     if ($quilt_mode =~ m/gbp|unapplied/ &&
3209         ($diffbits->{O2A} & 01)) { # some patches
3210         quiltify_splitbrain_needed();
3211         progress "dgit view: creating patches-applied version using gbp pq";
3212         runcmd shell_cmd 'exec >/dev/null', @gbp, qw(pq import);
3213         # gbp pq import creates a fresh branch; push back to dgit-view
3214         runcmd @git, qw(update-ref refs/heads/dgit-view HEAD);
3215         runcmd @git, qw(checkout -q dgit-view);
3216     }
3217     if (($diffbits->{H2O} & 02) && # user has modified .gitignore
3218         !($diffbits->{O2A} & 02)) { # patches do not change .gitignore
3219         quiltify_splitbrain_needed();
3220         progress "dgit view: creating patch to represent .gitignore changes";
3221         ensuredir "debian/patches";
3222         my $gipatch = "debian/patches/auto-gitignore";
3223         open GIPATCH, ">>", "$gipatch" or die "$gipatch: $!";
3224         stat GIPATCH or die "$gipatch: $!";
3225         fail "$gipatch already exists; but want to create it".
3226             " to record .gitignore changes" if (stat _)[7];
3227         print GIPATCH <<END or die "$gipatch: $!";
3228 Subject: Update .gitignore from Debian packaging branch
3229
3230 The Debian packaging git branch contains these updates to the upstream
3231 .gitignore file(s).  This patch is autogenerated, to provide these
3232 updates to users of the official Debian archive view of the package.
3233
3234 [dgit version $our_version]
3235 ---
3236 END
3237         close GIPATCH or die "$gipatch: $!";
3238         runcmd shell_cmd "exec >>$gipatch", @git, qw(diff),
3239             $unapplied, $headref, "--", sort keys %$editedignores;
3240         open SERIES, "+>>", "debian/patches/series" or die $!;
3241         defined seek SERIES, -1, 2 or $!==EINVAL or die $!;
3242         my $newline;
3243         defined read SERIES, $newline, 1 or die $!;
3244         print SERIES "\n" or die $! unless $newline eq "\n";
3245         print SERIES "auto-gitignore\n" or die $!;
3246         close SERIES or die  $!;
3247         runcmd @git, qw(add -- debian/patches/series), $gipatch;
3248         commit_admin "Commit patch to update .gitignore";
3249     }
3250
3251     my $dgitview = git_rev_parse 'refs/heads/dgit-view';
3252
3253     changedir '../../../..';
3254     ensuredir ".git/logs/refs/dgit-intern";
3255     my $makelogfh = new IO::File ".git/logs/refs/$splitbraincache", '>>'
3256       or die $!;
3257     runcmd @git, qw(update-ref -m), $cachekey, "refs/$splitbraincache",
3258         $dgitview;
3259
3260     progress "dgit view: created (commit id $dgitview)";
3261
3262     changedir '.git/dgit/unpack/work';
3263 }
3264
3265 sub quiltify ($$$$) {
3266     my ($clogp,$target,$oldtiptree,$failsuggestion) = @_;
3267
3268     # Quilt patchification algorithm
3269     #
3270     # We search backwards through the history of the main tree's HEAD
3271     # (T) looking for a start commit S whose tree object is identical
3272     # to to the patch tip tree (ie the tree corresponding to the
3273     # current dpkg-committed patch series).  For these purposes
3274     # `identical' disregards anything in debian/ - this wrinkle is
3275     # necessary because dpkg-source treates debian/ specially.
3276     #
3277     # We can only traverse edges where at most one of the ancestors'
3278     # trees differs (in changes outside in debian/).  And we cannot
3279     # handle edges which change .pc/ or debian/patches.  To avoid
3280     # going down a rathole we avoid traversing edges which introduce
3281     # debian/rules or debian/control.  And we set a limit on the
3282     # number of edges we are willing to look at.
3283     #
3284     # If we succeed, we walk forwards again.  For each traversed edge
3285     # PC (with P parent, C child) (starting with P=S and ending with
3286     # C=T) to we do this:
3287     #  - git checkout C
3288     #  - dpkg-source --commit with a patch name and message derived from C
3289     # After traversing PT, we git commit the changes which
3290     # should be contained within debian/patches.
3291
3292     # The search for the path S..T is breadth-first.  We maintain a
3293     # todo list containing search nodes.  A search node identifies a
3294     # commit, and looks something like this:
3295     #  $p = {
3296     #      Commit => $git_commit_id,
3297     #      Child => $c,                          # or undef if P=T
3298     #      Whynot => $reason_edge_PC_unsuitable, # in @nots only
3299     #      Nontrivial => true iff $p..$c has relevant changes
3300     #  };
3301
3302     my @todo;
3303     my @nots;
3304     my $sref_S;
3305     my $max_work=100;
3306     my %considered; # saves being exponential on some weird graphs
3307
3308     my $t_sentinels = quiltify_tree_sentinelfiles $target;
3309
3310     my $not = sub {
3311         my ($search,$whynot) = @_;
3312         printdebug " search NOT $search->{Commit} $whynot\n";
3313         $search->{Whynot} = $whynot;
3314         push @nots, $search;
3315         no warnings qw(exiting);
3316         next;
3317     };
3318
3319     push @todo, {
3320         Commit => $target,
3321     };
3322
3323     while (@todo) {
3324         my $c = shift @todo;
3325         next if $considered{$c->{Commit}}++;
3326
3327         $not->($c, "maximum search space exceeded") if --$max_work <= 0;
3328
3329         printdebug "quiltify investigate $c->{Commit}\n";
3330
3331         # are we done?
3332         if (!quiltify_trees_differ $c->{Commit}, $oldtiptree) {
3333             printdebug " search finished hooray!\n";
3334             $sref_S = $c;
3335             last;
3336         }
3337
3338         if ($quilt_mode eq 'nofix') {
3339             fail "quilt fixup required but quilt mode is \`nofix'\n".
3340                 "HEAD commit $c->{Commit} differs from tree implied by ".
3341                 " debian/patches (tree object $oldtiptree)";
3342         }
3343         if ($quilt_mode eq 'smash') {
3344             printdebug " search quitting smash\n";
3345             last;
3346         }
3347
3348         my $c_sentinels = quiltify_tree_sentinelfiles $c->{Commit};
3349         $not->($c, "has $c_sentinels not $t_sentinels")
3350             if $c_sentinels ne $t_sentinels;
3351
3352         my $commitdata = cmdoutput @git, qw(cat-file commit), $c->{Commit};
3353         $commitdata =~ m/\n\n/;
3354         $commitdata =~ $`;
3355         my @parents = ($commitdata =~ m/^parent (\w+)$/gm);
3356         @parents = map { { Commit => $_, Child => $c } } @parents;
3357
3358         $not->($c, "root commit") if !@parents;
3359
3360         foreach my $p (@parents) {
3361             $p->{Nontrivial}= quiltify_trees_differ $p->{Commit},$c->{Commit};
3362         }
3363         my $ndiffers = grep { $_->{Nontrivial} } @parents;
3364         $not->($c, "merge ($ndiffers nontrivial parents)") if $ndiffers > 1;
3365
3366         foreach my $p (@parents) {
3367             printdebug "considering C=$c->{Commit} P=$p->{Commit}\n";
3368
3369             my @cmd= (@git, qw(diff-tree -r --name-only),
3370                       $p->{Commit},$c->{Commit}, qw(-- debian/patches .pc));
3371             my $patchstackchange = cmdoutput @cmd;
3372             if (length $patchstackchange) {
3373                 $patchstackchange =~ s/\n/,/g;
3374                 $not->($p, "changed $patchstackchange");
3375             }
3376
3377             printdebug " search queue P=$p->{Commit} ",
3378                 ($p->{Nontrivial} ? "NT" : "triv"),"\n";
3379             push @todo, $p;
3380         }
3381     }
3382
3383     if (!$sref_S) {
3384         printdebug "quiltify want to smash\n";
3385
3386         my $abbrev = sub {
3387             my $x = $_[0]{Commit};
3388             $x =~ s/(.*?[0-9a-z]{8})[0-9a-z]*$/$1/;
3389             return $x;
3390         };
3391         my $reportnot = sub {
3392             my ($notp) = @_;
3393             my $s = $abbrev->($notp);
3394             my $c = $notp->{Child};
3395             $s .= "..".$abbrev->($c) if $c;
3396             $s .= ": ".$notp->{Whynot};
3397             return $s;
3398         };
3399         if ($quilt_mode eq 'linear') {
3400             print STDERR "$us: quilt fixup cannot be linear.  Stopped at:\n";
3401             foreach my $notp (@nots) {
3402                 print STDERR "$us:  ", $reportnot->($notp), "\n";
3403             }
3404             print STDERR "$us: $_\n" foreach @$failsuggestion;
3405             fail "quilt fixup naive history linearisation failed.\n".
3406  "Use dpkg-source --commit by hand; or, --quilt=smash for one ugly patch";
3407         } elsif ($quilt_mode eq 'smash') {
3408         } elsif ($quilt_mode eq 'auto') {
3409             progress "quilt fixup cannot be linear, smashing...";
3410         } else {
3411             die "$quilt_mode ?";
3412         }
3413
3414         my $time = $ENV{'GIT_COMMITTER_DATE'} || time;
3415         $time =~ s/\s.*//; # trim timezone from GIT_COMMITTER_DATE
3416         my $ncommits = 3;
3417         my $msg = cmdoutput @git, qw(log), "-n$ncommits";
3418
3419         quiltify_dpkg_commit "auto-$version-$target-$time",
3420             (getfield $clogp, 'Maintainer'),
3421             "Automatically generated patch ($clogp->{Version})\n".
3422             "Last (up to) $ncommits git changes, FYI:\n\n". $msg;
3423         return;
3424     }
3425
3426     progress "quiltify linearisation planning successful, executing...";
3427
3428     for (my $p = $sref_S;
3429          my $c = $p->{Child};
3430          $p = $p->{Child}) {
3431         printdebug "quiltify traverse $p->{Commit}..$c->{Commit}\n";
3432         next unless $p->{Nontrivial};
3433
3434         my $cc = $c->{Commit};
3435
3436         my $commitdata = cmdoutput @git, qw(cat-file commit), $cc;
3437         $commitdata =~ m/\n\n/ or die "$c ?";
3438         $commitdata = $`;
3439         my $msg = $'; #';
3440         $commitdata =~ m/^author (.*) \d+ [-+0-9]+$/m or die "$cc ?";
3441         my $author = $1;
3442
3443         $msg =~ s/^(.*)\n*/$1\n/ or die "$cc $msg ?";
3444
3445         my $title = $1;
3446         my $patchname = $title;
3447         $patchname =~ s/[.:]$//;
3448         $patchname =~ y/ A-Z/-a-z/;
3449         $patchname =~ y/-a-z0-9_.+=~//cd;
3450         $patchname =~ s/^\W/x-$&/;
3451         $patchname = substr($patchname,0,40);
3452         my $index;
3453         for ($index='';
3454              stat "debian/patches/$patchname$index";
3455              $index++) { }
3456         $!==ENOENT or die "$patchname$index $!";
3457
3458         runcmd @git, qw(checkout -q), $cc;
3459
3460         # We use the tip's changelog so that dpkg-source doesn't
3461         # produce complaining messages from dpkg-parsechangelog.  None
3462         # of the information dpkg-source gets from the changelog is
3463         # actually relevant - it gets put into the original message
3464         # which dpkg-source provides our stunt editor, and then
3465         # overwritten.
3466         runcmd @git, qw(checkout -q), $target, qw(debian/changelog);
3467
3468         quiltify_dpkg_commit "$patchname$index", $author, $msg,
3469             "X-Dgit-Generated: $clogp->{Version} $cc\n";
3470
3471         runcmd @git, qw(checkout -q), $cc, qw(debian/changelog);
3472     }
3473
3474     runcmd @git, qw(checkout -q master);
3475 }
3476
3477 sub build_maybe_quilt_fixup () {
3478     my ($format,$fopts) = get_source_format;
3479     return unless madformat $format;
3480     # sigh
3481
3482     check_for_vendor_patches();
3483
3484     my $clogp = parsechangelog();
3485     my $headref = git_rev_parse('HEAD');
3486
3487     prep_ud();
3488     changedir $ud;
3489
3490     my $upstreamversion=$version;
3491     $upstreamversion =~ s/-[^-]*$//;
3492
3493     if ($fopts->{'single-debian-patch'}) {
3494         quilt_fixup_singlepatch($clogp, $headref, $upstreamversion);
3495     } else {
3496         quilt_fixup_multipatch($clogp, $headref, $upstreamversion);
3497     }
3498
3499     die 'bug' if $split_brain && !$need_split_build_invocation;
3500
3501     changedir '../../../..';
3502     runcmd_ordryrun_local
3503         @git, qw(pull --ff-only -q .git/dgit/unpack/work master);
3504 }
3505
3506 sub quilt_fixup_mkwork ($) {
3507     my ($headref) = @_;
3508
3509     mkdir "work" or die $!;
3510     changedir "work";
3511     mktree_in_ud_here();
3512     runcmd @git, qw(reset -q --hard), $headref;
3513 }
3514
3515 sub quilt_fixup_linkorigs ($$) {
3516     my ($upstreamversion, $fn) = @_;
3517     # calls $fn->($leafname);
3518
3519     foreach my $f (<../../../../*>) { #/){
3520         my $b=$f; $b =~ s{.*/}{};
3521         {
3522             local ($debuglevel) = $debuglevel-1;
3523             printdebug "QF linkorigs $b, $f ?\n";
3524         }
3525         next unless is_orig_file $b, srcfn $upstreamversion,'';
3526         printdebug "QF linkorigs $b, $f Y\n";
3527         link_ltarget $f, $b or die "$b $!";
3528         $fn->($b);
3529     }
3530 }
3531
3532 sub quilt_fixup_delete_pc () {
3533     runcmd @git, qw(rm -rqf .pc);
3534     commit_admin "Commit removal of .pc (quilt series tracking data)";
3535 }
3536
3537 sub quilt_fixup_singlepatch ($$$) {
3538     my ($clogp, $headref, $upstreamversion) = @_;
3539
3540     progress "starting quiltify (single-debian-patch)";
3541
3542     # dpkg-source --commit generates new patches even if
3543     # single-debian-patch is in debian/source/options.  In order to
3544     # get it to generate debian/patches/debian-changes, it is
3545     # necessary to build the source package.
3546
3547     quilt_fixup_linkorigs($upstreamversion, sub { });
3548     quilt_fixup_mkwork($headref);
3549
3550     rmtree("debian/patches");
3551
3552     runcmd @dpkgsource, qw(-b .);
3553     chdir "..";
3554     runcmd @dpkgsource, qw(-x), (srcfn $version, ".dsc");
3555     rename srcfn("$upstreamversion", "/debian/patches"), 
3556            "work/debian/patches";
3557
3558     chdir "work";
3559     commit_quilty_patch();
3560 }
3561
3562 sub quilt_make_fake_dsc ($) {
3563     my ($upstreamversion) = @_;
3564
3565     my $fakeversion="$upstreamversion-~~DGITFAKE";
3566
3567     my $fakedsc=new IO::File 'fake.dsc', '>' or die $!;
3568     print $fakedsc <<END or die $!;
3569 Format: 3.0 (quilt)
3570 Source: $package
3571 Version: $fakeversion
3572 Files:
3573 END
3574
3575     my $dscaddfile=sub {
3576         my ($b) = @_;
3577         
3578         my $md = new Digest::MD5;
3579
3580         my $fh = new IO::File $b, '<' or die "$b $!";
3581         stat $fh or die $!;
3582         my $size = -s _;
3583
3584         $md->addfile($fh);
3585         print $fakedsc " ".$md->hexdigest." $size $b\n" or die $!;
3586     };
3587
3588     quilt_fixup_linkorigs($upstreamversion, $dscaddfile);
3589
3590     my @files=qw(debian/source/format debian/rules
3591                  debian/control debian/changelog);
3592     foreach my $maybe (qw(debian/patches debian/source/options
3593                           debian/tests/control)) {
3594         next unless stat_exists "../../../$maybe";
3595         push @files, $maybe;
3596     }
3597
3598     my $debtar= srcfn $fakeversion,'.debian.tar.gz';
3599     runcmd qw(env GZIP=-1n tar -zcf), "./$debtar", qw(-C ../../..), @files;
3600
3601     $dscaddfile->($debtar);
3602     close $fakedsc or die $!;
3603 }
3604
3605 sub quilt_check_splitbrain_cache ($$) {
3606     my ($headref, $upstreamversion) = @_;
3607     # Called only if we are in (potentially) split brain mode.
3608     # Called in $ud.
3609     # Computes the cache key and looks in the cache.
3610     # Returns ($dgit_view_commitid, $cachekey) or (undef, $cachekey)
3611
3612     my $splitbrain_cachekey;
3613     
3614     progress
3615  "dgit: split brain (separate dgit view) may be needed (--quilt=$quilt_mode).";
3616     # we look in the reflog of dgit-intern/quilt-cache
3617     # we look for an entry whose message is the key for the cache lookup
3618     my @cachekey = (qw(dgit), $our_version);
3619     push @cachekey, $upstreamversion;
3620     push @cachekey, $quilt_mode;
3621     push @cachekey, $headref;
3622
3623     push @cachekey, hashfile('fake.dsc');
3624
3625     my $srcshash = Digest::SHA->new(256);
3626     my %sfs = ( %INC, '$0(dgit)' => $0 );
3627     foreach my $sfk (sort keys %sfs) {
3628         next unless m/^\$0\b/ || m{^Debian/Dgit\b};
3629         $srcshash->add($sfk,"  ");
3630         $srcshash->add(hashfile($sfs{$sfk}));
3631         $srcshash->add("\n");
3632     }
3633     push @cachekey, $srcshash->hexdigest();
3634     $splitbrain_cachekey = "@cachekey";
3635
3636     my @cmd = (@git, qw(reflog), '--pretty=format:%H %gs',
3637                $splitbraincache);
3638     printdebug "splitbrain cachekey $splitbrain_cachekey\n";
3639     debugcmd "|(probably)",@cmd;
3640     my $child = open GC, "-|";  defined $child or die $!;
3641     if (!$child) {
3642         chdir '../../..' or die $!;
3643         if (!stat ".git/logs/refs/$splitbraincache") {
3644             $! == ENOENT or die $!;
3645             printdebug ">(no reflog)\n";
3646             exit 0;
3647         }
3648         exec @cmd; die $!;
3649     }
3650     while (<GC>) {
3651         chomp;
3652         printdebug ">| ", $_, "\n" if $debuglevel > 1;
3653         next unless m/^(\w+) (\S.*\S)$/ && $2 eq $splitbrain_cachekey;
3654             
3655         my $cachehit = $1;
3656         quilt_fixup_mkwork($headref);
3657         if ($cachehit ne $headref) {
3658             progress "dgit view: found cached (commit id $cachehit)";
3659             runcmd @git, qw(checkout -q -b dgit-view), $cachehit;
3660             $split_brain = 1;
3661             return ($cachehit, $splitbrain_cachekey);
3662         }
3663         progress "dgit view: found cached, no changes required";
3664         return ($headref, $splitbrain_cachekey);
3665     }
3666     die $! if GC->error;
3667     failedcmd unless close GC;
3668
3669     printdebug "splitbrain cache miss\n";
3670     return (undef, $splitbrain_cachekey);
3671 }
3672
3673 sub quilt_fixup_multipatch ($$$) {
3674     my ($clogp, $headref, $upstreamversion) = @_;
3675
3676     progress "examining quilt state (multiple patches, $quilt_mode mode)";
3677
3678     # Our objective is:
3679     #  - honour any existing .pc in case it has any strangeness
3680     #  - determine the git commit corresponding to the tip of
3681     #    the patch stack (if there is one)
3682     #  - if there is such a git commit, convert each subsequent
3683     #    git commit into a quilt patch with dpkg-source --commit
3684     #  - otherwise convert all the differences in the tree into
3685     #    a single git commit
3686     #
3687     # To do this we:
3688
3689     # Our git tree doesn't necessarily contain .pc.  (Some versions of
3690     # dgit would include the .pc in the git tree.)  If there isn't
3691     # one, we need to generate one by unpacking the patches that we
3692     # have.
3693     #
3694     # We first look for a .pc in the git tree.  If there is one, we
3695     # will use it.  (This is not the normal case.)
3696     #
3697     # Otherwise need to regenerate .pc so that dpkg-source --commit
3698     # can work.  We do this as follows:
3699     #     1. Collect all relevant .orig from parent directory
3700     #     2. Generate a debian.tar.gz out of
3701     #         debian/{patches,rules,source/format,source/options}
3702     #     3. Generate a fake .dsc containing just these fields:
3703     #          Format Source Version Files
3704     #     4. Extract the fake .dsc
3705     #        Now the fake .dsc has a .pc directory.
3706     # (In fact we do this in every case, because in future we will
3707     # want to search for a good base commit for generating patches.)
3708     #
3709     # Then we can actually do the dpkg-source --commit
3710     #     1. Make a new working tree with the same object
3711     #        store as our main tree and check out the main
3712     #        tree's HEAD.
3713     #     2. Copy .pc from the fake's extraction, if necessary
3714     #     3. Run dpkg-source --commit
3715     #     4. If the result has changes to debian/, then
3716     #          - git-add them them
3717     #          - git-add .pc if we had a .pc in-tree
3718     #          - git-commit
3719     #     5. If we had a .pc in-tree, delete it, and git-commit
3720     #     6. Back in the main tree, fast forward to the new HEAD
3721
3722     # Another situation we may have to cope with is gbp-style
3723     # patches-unapplied trees.
3724     #
3725     # We would want to detect these, so we know to escape into
3726     # quilt_fixup_gbp.  However, this is in general not possible.
3727     # Consider a package with a one patch which the dgit user reverts
3728     # (with git-revert or the moral equivalent).
3729     #
3730     # That is indistinguishable in contents from a patches-unapplied
3731     # tree.  And looking at the history to distinguish them is not
3732     # useful because the user might have made a confusing-looking git
3733     # history structure (which ought to produce an error if dgit can't
3734     # cope, not a silent reintroduction of an unwanted patch).
3735     #
3736     # So gbp users will have to pass an option.  But we can usually
3737     # detect their failure to do so: if the tree is not a clean
3738     # patches-applied tree, quilt linearisation fails, but the tree
3739     # _is_ a clean patches-unapplied tree, we can suggest that maybe
3740     # they want --quilt=unapplied.
3741     #
3742     # To help detect this, when we are extracting the fake dsc, we
3743     # first extract it with --skip-patches, and then apply the patches
3744     # afterwards with dpkg-source --before-build.  That lets us save a