dgit

   1 #!/usr/bin/perl -w
   2 # dgit
   3 # Integration between git and Debian-style archives
   4 #
   5 # Copyright (C)2013-2017 Ian Jackson
   6 # Copyright (C)2017 Sean Whitton
   7 #
   8 # This program is free software: you can redistribute it and/or modify
   9 # it under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation, either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # This program is distributed in the hope that it will be useful,
  14 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20
  21 use strict;
  22
  23 use Debian::Dgit qw(:DEFAULT :playground);
  24 setup_sigwarn();
  25
  26 use IO::Handle;
  27 use Data::Dumper;
  28 use LWP::UserAgent;
  29 use Dpkg::Control::Hash;
  30 use File::Path;
  31 use File::Temp qw(tempdir);
  32 use File::Basename;
  33 use Dpkg::Version;
  34 use Dpkg::Compression;
  35 use Dpkg::Compression::Process;
  36 use POSIX;
  37 use IPC::Open2;
  38 use Digest::SHA;
  39 use Digest::MD5;
  40 use List::MoreUtils qw(pairwise);
  41 use Text::Glob qw(match_glob);
  42 use Fcntl qw(:DEFAULT :flock);
  43 use Carp;
  44
  45 use Debian::Dgit;
  46
  47 our $our_version = 'UNRELEASED'; ###substituted###
  48 our $absurdity = undef; ###substituted###
  49
  50 our @rpushprotovsn_support = qw(4 3 2); # 4 is new tag format
  51 our $protovsn;
  52
  53 our $cmd;
  54 our $subcommand;
  55 our $isuite;
  56 our $idistro;
  57 our $package;
  58 our @ropts;
  59
  60 our $sign = 1;
  61 our $dryrun_level = 0;
  62 our $changesfile;
  63 our $buildproductsdir = '..';
  64 our $new_package = 0;
  65 our $ignoredirty = 0;
  66 our $rmonerror = 1;
  67 our @deliberatelies;
  68 our %previously;
  69 our $existing_package = 'dpkg';
  70 our $cleanmode;
  71 our $changes_since_version;
  72 our $rmchanges;
  73 our $overwrite_version; # undef: not specified; '': check changelog
  74 our $quilt_mode;
  75 our $quilt_modes_re = 'linear|smash|auto|nofix|nocheck|gbp|dpm|unapplied';
  76 our $dodep14tag;
  77 our $split_brain_save;
  78 our $we_are_responder;
  79 our $we_are_initiator;
  80 our $initiator_tempdir;
  81 our $patches_applied_dirtily = 00;
  82 our $tagformat_want;
  83 our $tagformat;
  84 our $tagformatfn;
  85 our $chase_dsc_distro=1;
  86
  87 our %forceopts = map { $_=>0 }
  88     qw(unrepresentable unsupported-source-format
  89        dsc-changes-mismatch changes-origs-exactly
  90        import-gitapply-absurd
  91        import-gitapply-no-absurd
  92        import-dsc-with-dgit-field);
  93
  94 our %format_ok = map { $_=>1 } ("1.0","3.0 (native)","3.0 (quilt)");
  95
  96 our $suite_re = '[-+.0-9a-z]+';
  97 our $cleanmode_re = 'dpkg-source(?:-d)?|git|git-ff|check|none';
  98 our $orig_f_comp_re = 'orig(?:-[-0-9a-z]+)?';
  99 our $orig_f_sig_re = '\\.(?:asc|gpg|pgp)';
 100 our $orig_f_tail_re = "$orig_f_comp_re\\.tar(?:\\.\\w+)?(?:$orig_f_sig_re)?";
 101
 102 our $git_authline_re = '^([^<>]+) \<(\S+)\> (\d+ [-+]\d+)$';
 103 our $splitbraincache = 'dgit-intern/quilt-cache';
 104 our $rewritemap = 'dgit-rewrite/map';
 105
 106 our @dpkg_source_ignores = qw(-i(?:^|/)\.git(?:/|$) -I.git);
 107
 108 our (@git) = qw(git);
 109 our (@dget) = qw(dget);
 110 our (@curl) = (qw(curl --proto-redir), '-all,http,https', qw(-L));
 111 our (@dput) = qw(dput);
 112 our (@debsign) = qw(debsign);
 113 our (@gpg) = qw(gpg);
 114 our (@sbuild) = qw(sbuild);
 115 our (@ssh) = 'ssh';
 116 our (@dgit) = qw(dgit);
 117 our (@aptget) = qw(apt-get);
 118 our (@aptcache) = qw(apt-cache);
 119 our (@dpkgbuildpackage) = (qw(dpkg-buildpackage), @dpkg_source_ignores);
 120 our (@dpkgsource) = (qw(dpkg-source), @dpkg_source_ignores);
 121 our (@dpkggenchanges) = qw(dpkg-genchanges);
 122 our (@mergechanges) = qw(mergechanges -f);
 123 our (@gbp_build) = ('');
 124 our (@gbp_pq) = ('gbp pq');
 125 our (@changesopts) = ('');
 126
 127 our %opts_opt_map = ('dget' => \@dget, # accept for compatibility
 128                      'curl' => \@curl,
 129                      'dput' => \@dput,
 130                      'debsign' => \@debsign,
 131                      'gpg' => \@gpg,
 132                      'sbuild' => \@sbuild,
 133                      'ssh' => \@ssh,
 134                      'dgit' => \@dgit,
 135                      'git' => \@git,
 136                      'apt-get' => \@aptget,
 137                      'apt-cache' => \@aptcache,
 138                      'dpkg-source' => \@dpkgsource,
 139                      'dpkg-buildpackage' => \@dpkgbuildpackage,
 140                      'dpkg-genchanges' => \@dpkggenchanges,
 141                      'gbp-build' => \@gbp_build,
 142                      'gbp-pq' => \@gbp_pq,
 143                      'ch' => \@changesopts,
 144                      'mergechanges' => \@mergechanges);
 145
 146 our %opts_opt_cmdonly = ('gpg' => 1, 'git' => 1);
 147 our %opts_cfg_insertpos = map {
 148     $_,
 149     scalar @{ $opts_opt_map{$_} }
 150 } keys %opts_opt_map;
 151
 152 sub parseopts_late_defaults();
 153 sub setup_gitattrs(;$);
 154 sub check_gitattrs($$);
 155
 156 our $keyid;
 157
 158 autoflush STDOUT 1;
 159
 160 our $supplementary_message = '';
 161 our $need_split_build_invocation = 0;
 162 our $split_brain = 0;
 163
 164 END {
 165     local ($@, $?);
 166     return unless forkcheck_mainprocess();
 167     print STDERR "! $_\n" foreach $supplementary_message =~ m/^.+$/mg;
 168 }
 169
 170 our $remotename = 'dgit';
 171 our @ourdscfield = qw(Dgit Vcs-Dgit-Master);
 172 our $csuite;
 173 our $instead_distro;
 174
 175 if (!defined $absurdity) {
 176     $absurdity = $0;
 177     $absurdity =~ s{/[^/]+$}{/absurd} or die;
 178 }
 179
 180 sub debiantag ($$) {
 181     my ($v,$distro) = @_;
 182     return $tagformatfn->($v, $distro);
 183 }
 184
 185 sub debiantag_maintview ($$) {
 186     my ($v,$distro) = @_;
 187     return "$distro/".dep14_version_mangle $v;
 188 }
 189
 190 sub madformat ($) { $_[0] eq '3.0 (quilt)' }
 191
 192 sub lbranch () { return "$branchprefix/$csuite"; }
 193 my $lbranch_re = '^refs/heads/'.$branchprefix.'/([^/.]+)$';
 194 sub lref () { return "refs/heads/".lbranch(); }
 195 sub lrref () { return "refs/remotes/$remotename/".server_branch($csuite); }
 196 sub rrref () { return server_ref($csuite); }
 197
 198 sub stripepoch ($) {
 199     my ($vsn) = @_;
 200     $vsn =~ s/^\d+\://;
 201     return $vsn;
 202 }
 203
 204 sub srcfn ($$) {
 205     my ($vsn,$sfx) = @_;
 206     return "${package}_".(stripepoch $vsn).$sfx
 207 }
 208
 209 sub dscfn ($) {
 210     my ($vsn) = @_;
 211     return srcfn($vsn,".dsc");
 212 }
 213
 214 sub changespat ($;$) {
 215     my ($vsn, $arch) = @_;
 216     return "${package}_".(stripepoch $vsn)."_".($arch//'*').".changes";
 217 }
 218
 219 sub upstreamversion ($) {
 220     my ($vsn) = @_;
 221     $vsn =~ s/-[^-]+$//;
 222     return $vsn;
 223 }
 224
 225 our $us = 'dgit';
 226 initdebug('');
 227
 228 our @end;
 229 END {
 230     local ($?);
 231     return unless forkcheck_mainprocess();
 232     foreach my $f (@end) {
 233         eval { $f->(); };
 234         print STDERR "$us: cleanup: $@" if length $@;
 235     }
 236 };
 237
 238 sub badcfg { print STDERR "$us: invalid configuration: @_\n"; exit 12; }
 239
 240 sub forceable_fail ($$) {
 241     my ($forceoptsl, $msg) = @_;
 242     fail $msg unless grep { $forceopts{$_} } @$forceoptsl;
 243     print STDERR "warning: overriding problem due to --force:\n". $msg;
 244 }
 245
 246 sub forceing ($) {
 247     my ($forceoptsl) = @_;
 248     my @got = grep { $forceopts{$_} } @$forceoptsl;
 249     return 0 unless @got;
 250     print STDERR
 251  "warning: skipping checks or functionality due to --force-$got[0]\n";
 252 }
 253
 254 sub no_such_package () {
 255     print STDERR "$us: package $package does not exist in suite $isuite\n";
 256     exit 4;
 257 }
 258
 259 sub deliberately ($) {
 260     my ($enquiry) = @_;
 261     return !!grep { $_ eq "--deliberately-$enquiry" } @deliberatelies;
 262 }
 263
 264 sub deliberately_not_fast_forward () {
 265     foreach (qw(not-fast-forward fresh-repo)) {
 266         return 1 if deliberately($_) || deliberately("TEST-dgit-only-$_");
 267     }
 268 }
 269
 270 sub quiltmode_splitbrain () {
 271     $quilt_mode =~ m/gbp|dpm|unapplied/;
 272 }
 273
 274 sub opts_opt_multi_cmd {
 275     my @cmd;
 276     push @cmd, split /\s+/, shift @_;
 277     push @cmd, @_;
 278     @cmd;
 279 }
 280
 281 sub gbp_pq {
 282     return opts_opt_multi_cmd @gbp_pq;
 283 }
 284
 285 sub dgit_privdir () {
 286     our $dgit_privdir_made //= ensure_a_playground 'dgit';
 287 }
 288
 289 #---------- remote protocol support, common ----------
 290
 291 # remote push initiator/responder protocol:
 292 #  $ dgit remote-push-build-host <n-rargs> <rargs>... <push-args>...
 293 #  where <rargs> is <push-host-dir> <supported-proto-vsn>,... ...
 294 #  < dgit-remote-push-ready <actual-proto-vsn>
 295 #
 296 # occasionally:
 297 #
 298 #  > progress NBYTES
 299 #  [NBYTES message]
 300 #
 301 #  > supplementary-message NBYTES          # $protovsn >= 3
 302 #  [NBYTES message]
 303 #
 304 # main sequence:
 305 #
 306 #  > file parsed-changelog
 307 #  [indicates that output of dpkg-parsechangelog follows]
 308 #  > data-block NBYTES
 309 #  > [NBYTES bytes of data (no newline)]
 310 #  [maybe some more blocks]
 311 #  > data-end
 312 #
 313 #  > file dsc
 314 #  [etc]
 315 #
 316 #  > file changes
 317 #  [etc]
 318 #
 319 #  > param head DGIT-VIEW-HEAD
 320 #  > param csuite SUITE
 321 #  > param tagformat old|new
 322 #  > param maint-view MAINT-VIEW-HEAD
 323 #
 324 #  > param buildinfo-filename P_V_X.buildinfo   # zero or more times
 325 #  > file buildinfo                             # for buildinfos to sign
 326 #
 327 #  > previously REFNAME=OBJNAME       # if --deliberately-not-fast-forward
 328 #                                     # goes into tag, for replay prevention
 329 #
 330 #  > want signed-tag
 331 #  [indicates that signed tag is wanted]
 332 #  < data-block NBYTES
 333 #  < [NBYTES bytes of data (no newline)]
 334 #  [maybe some more blocks]
 335 #  < data-end
 336 #  < files-end
 337 #
 338 #  > want signed-dsc-changes
 339 #  < data-block NBYTES    [transfer of signed dsc]
 340 #  [etc]
 341 #  < data-block NBYTES    [transfer of signed changes]
 342 #  [etc]
 343 #  < data-block NBYTES    [transfer of each signed buildinfo
 344 #  [etc]                   same number and order as "file buildinfo"]
 345 #  ...
 346 #  < files-end
 347 #
 348 #  > complete
 349
 350 our $i_child_pid;
 351
 352 sub i_child_report () {
 353     # Sees if our child has died, and reap it if so.  Returns a string
 354     # describing how it died if it failed, or undef otherwise.
 355     return undef unless $i_child_pid;
 356     my $got = waitpid $i_child_pid, WNOHANG;
 357     return undef if $got <= 0;
 358     die unless $got == $i_child_pid;
 359     $i_child_pid = undef;
 360     return undef unless $?;
 361     return "build host child ".waitstatusmsg();
 362 }
 363
 364 sub badproto ($$) {
 365     my ($fh, $m) = @_;
 366     fail "connection lost: $!" if $fh->error;
 367     fail "protocol violation; $m not expected";
 368 }
 369
 370 sub badproto_badread ($$) {
 371     my ($fh, $wh) = @_;
 372     fail "connection lost: $!" if $!;
 373     my $report = i_child_report();
 374     fail $report if defined $report;
 375     badproto $fh, "eof (reading $wh)";
 376 }
 377
 378 sub protocol_expect (&$) {
 379     my ($match, $fh) = @_;
 380     local $_;
 381     $_ = <$fh>;
 382     defined && chomp or badproto_badread $fh, "protocol message";
 383     if (wantarray) {
 384         my @r = &$match;
 385         return @r if @r;
 386     } else {
 387         my $r = &$match;
 388         return $r if $r;
 389     }
 390     badproto $fh, "\`$_'";
 391 }
 392
 393 sub protocol_send_file ($$) {
 394     my ($fh, $ourfn) = @_;
 395     open PF, "<", $ourfn or die "$ourfn: $!";
 396     for (;;) {
 397         my $d;
 398         my $got = read PF, $d, 65536;
 399         die "$ourfn: $!" unless defined $got;
 400         last if !$got;
 401         print $fh "data-block ".length($d)."\n" or die $!;
 402         print $fh $d or die $!;
 403     }
 404     PF->error and die "$ourfn $!";
 405     print $fh "data-end\n" or die $!;
 406     close PF;
 407 }
 408
 409 sub protocol_read_bytes ($$) {
 410     my ($fh, $nbytes) = @_;
 411     $nbytes =~ m/^[1-9]\d{0,5}$|^0$/ or badproto \*RO, "bad byte count";
 412     my $d;
 413     my $got = read $fh, $d, $nbytes;
 414     $got==$nbytes or badproto_badread $fh, "data block";
 415     return $d;
 416 }
 417
 418 sub protocol_receive_file ($$) {
 419     my ($fh, $ourfn) = @_;
 420     printdebug "() $ourfn\n";
 421     open PF, ">", $ourfn or die "$ourfn: $!";
 422     for (;;) {
 423         my ($y,$l) = protocol_expect {
 424             m/^data-block (.*)$/ ? (1,$1) :
 425             m/^data-end$/ ? (0,) :
 426             ();
 427         } $fh;
 428         last unless $y;
 429         my $d = protocol_read_bytes $fh, $l;
 430         print PF $d or die $!;
 431     }
 432     close PF or die $!;
 433 }
 434
 435 #---------- remote protocol support, responder ----------
 436
 437 sub responder_send_command ($) {
 438     my ($command) = @_;
 439     return unless $we_are_responder;
 440     # called even without $we_are_responder
 441     printdebug ">> $command\n";
 442     print PO $command, "\n" or die $!;
 443 }
 444
 445 sub responder_send_file ($$) {
 446     my ($keyword, $ourfn) = @_;
 447     return unless $we_are_responder;
 448     printdebug "]] $keyword $ourfn\n";
 449     responder_send_command "file $keyword";
 450     protocol_send_file \*PO, $ourfn;
 451 }
 452
 453 sub responder_receive_files ($@) {
 454     my ($keyword, @ourfns) = @_;
 455     die unless $we_are_responder;
 456     printdebug "[[ $keyword @ourfns\n";
 457     responder_send_command "want $keyword";
 458     foreach my $fn (@ourfns) {
 459         protocol_receive_file \*PI, $fn;
 460     }
 461     printdebug "[[\$\n";
 462     protocol_expect { m/^files-end$/ } \*PI;
 463 }
 464
 465 #---------- remote protocol support, initiator ----------
 466
 467 sub initiator_expect (&) {
 468     my ($match) = @_;
 469     protocol_expect { &$match } \*RO;
 470 }
 471
 472 #---------- end remote code ----------
 473
 474 sub progress {
 475     if ($we_are_responder) {
 476         my $m = join '', @_;
 477         responder_send_command "progress ".length($m) or die $!;
 478         print PO $m or die $!;
 479     } else {
 480         print @_, "\n";
 481     }
 482 }
 483
 484 our $ua;
 485
 486 sub url_get {
 487     if (!$ua) {
 488         $ua = LWP::UserAgent->new();
 489         $ua->env_proxy;
 490     }
 491     my $what = $_[$#_];
 492     progress "downloading $what...";
 493     my $r = $ua->get(@_) or die $!;
 494     return undef if $r->code == 404;
 495     $r->is_success or fail "failed to fetch $what: ".$r->status_line;
 496     return $r->decoded_content(charset => 'none');
 497 }
 498
 499 our ($dscdata,$dscurl,$dsc,$dsc_checked,$skew_warning_vsn);
 500
 501 sub act_local () { return $dryrun_level <= 1; }
 502 sub act_scary () { return !$dryrun_level; }
 503
 504 sub printdone {
 505     if (!$dryrun_level) {
 506         progress "$us ok: @_";
 507     } else {
 508         progress "would be ok: @_ (but dry run only)";
 509     }
 510 }
 511
 512 sub dryrun_report {
 513     printcmd(\*STDERR,$debugprefix."#",@_);
 514 }
 515
 516 sub runcmd_ordryrun {
 517     if (act_scary()) {
 518         runcmd @_;
 519     } else {
 520         dryrun_report @_;
 521     }
 522 }
 523
 524 sub runcmd_ordryrun_local {
 525     if (act_local()) {
 526         runcmd @_;
 527     } else {
 528         dryrun_report @_;
 529     }
 530 }
 531
 532 sub shell_cmd {
 533     my ($first_shell, @cmd) = @_;
 534     return qw(sh -ec), $first_shell.'; exec "$@"', 'x', @cmd;
 535 }
 536
 537 our $helpmsg = <<END;
 538 main usages:
 539   dgit [dgit-opts] clone [dgit-opts] package [suite] [./dir|/dir]
 540   dgit [dgit-opts] fetch|pull [dgit-opts] [suite]
 541   dgit [dgit-opts] build [dpkg-buildpackage-opts]
 542   dgit [dgit-opts] sbuild [sbuild-opts]
 543   dgit [dgit-opts] push [dgit-opts] [suite]
 544   dgit [dgit-opts] push-source [dgit-opts] [suite]
 545   dgit [dgit-opts] rpush build-host:build-dir ...
 546 important dgit options:
 547   -k<keyid>           sign tag and package with <keyid> instead of default
 548   --dry-run -n        do not change anything, but go through the motions
 549   --damp-run -L       like --dry-run but make local changes, without signing
 550   --new -N            allow introducing a new package
 551   --debug -D          increase debug level
 552   -c<name>=<value>    set git config option (used directly by dgit too)
 553 END
 554
 555 our $later_warning_msg = <<END;
 556 Perhaps the upload is stuck in incoming.  Using the version from git.
 557 END
 558
 559 sub badusage {
 560     print STDERR "$us: @_\n", $helpmsg or die $!;
 561     exit 8;
 562 }
 563
 564 sub nextarg {
 565     @ARGV or badusage "too few arguments";
 566     return scalar shift @ARGV;
 567 }
 568
 569 sub pre_help () {
 570     not_necessarily_a_tree();
 571 }
 572 sub cmd_help () {
 573     print $helpmsg or die $!;
 574     exit 0;
 575 }
 576
 577 our $td = $ENV{DGIT_TEST_DUMMY_DIR} || "DGIT_TEST_DUMMY_DIR-unset";
 578
 579 our %defcfg = ('dgit.default.distro' => 'debian',
 580                'dgit.default.default-suite' => 'unstable',
 581                'dgit.default.old-dsc-distro' => 'debian',
 582                'dgit-suite.*-security.distro' => 'debian-security',
 583                'dgit.default.username' => '',
 584                'dgit.default.archive-query-default-component' => 'main',
 585                'dgit.default.ssh' => 'ssh',
 586                'dgit.default.archive-query' => 'madison:',
 587                'dgit.default.sshpsql-dbname' => 'service=projectb',
 588                'dgit.default.aptget-components' => 'main',
 589                'dgit.default.dgit-tag-format' => 'new,old,maint',
 590                'dgit.dsc-url-proto-ok.http'    => 'true',
 591                'dgit.dsc-url-proto-ok.https'   => 'true',
 592                'dgit.dsc-url-proto-ok.git'     => 'true',
 593                'dgit.default.dsc-url-proto-ok' => 'false',
 594                # old means "repo server accepts pushes with old dgit tags"
 595                # new means "repo server accepts pushes with new dgit tags"
 596                # maint means "repo server accepts split brain pushes"
 597                # hist means "repo server may have old pushes without new tag"
 598                #   ("hist" is implied by "old")
 599                'dgit-distro.debian.archive-query' => 'ftpmasterapi:',
 600                'dgit-distro.debian.git-check' => 'url',
 601                'dgit-distro.debian.git-check-suffix' => '/info/refs',
 602                'dgit-distro.debian.new-private-pushers' => 't',
 603                'dgit-distro.debian/push.git-url' => '',
 604                'dgit-distro.debian/push.git-host' => 'push.dgit.debian.org',
 605                'dgit-distro.debian/push.git-user-force' => 'dgit',
 606                'dgit-distro.debian/push.git-proto' => 'git+ssh://',
 607                'dgit-distro.debian/push.git-path' => '/dgit/debian/repos',
 608                'dgit-distro.debian/push.git-create' => 'true',
 609                'dgit-distro.debian/push.git-check' => 'ssh-cmd',
 610  'dgit-distro.debian.archive-query-url', 'https://api.ftp-master.debian.org/',
 611 # 'dgit-distro.debian.archive-query-tls-key',
 612 #    '/etc/ssl/certs/%HOST%.pem:/etc/dgit/%HOST%.pem',
 613 # ^ this does not work because curl is broken nowadays
 614 # Fixing #790093 properly will involve providing providing the key
 615 # in some pacagke and maybe updating these paths.
 616 #
 617 # 'dgit-distro.debian.archive-query-tls-curl-args',
 618 #   '--ca-path=/etc/ssl/ca-debian',
 619 # ^ this is a workaround but works (only) on DSA-administered machines
 620                'dgit-distro.debian.git-url' => 'https://git.dgit.debian.org',
 621                'dgit-distro.debian.git-url-suffix' => '',
 622                'dgit-distro.debian.upload-host' => 'ftp-master', # for dput
 623                'dgit-distro.debian.mirror' => 'http://ftp.debian.org/debian/',
 624  'dgit-distro.debian-security.archive-query' => 'aptget:',
 625  'dgit-distro.debian-security.mirror' => 'http://security.debian.org/debian-security/',
 626  'dgit-distro.debian-security.aptget-suite-map' => 's#-security$#/updates#',
 627  'dgit-distro.debian-security.aptget-suite-rmap' => 's#$#-security#',
 628  'dgit-distro.debian-security.nominal-distro' => 'debian',
 629  'dgit-distro.debian.backports-quirk' => '(squeeze)-backports*',
 630  'dgit-distro.debian-backports.mirror' => 'http://backports.debian.org/debian-backports/',
 631                'dgit-distro.ubuntu.git-check' => 'false',
 632  'dgit-distro.ubuntu.mirror' => 'http://archive.ubuntu.com/ubuntu',
 633                'dgit-distro.test-dummy.ssh' => "$td/ssh",
 634                'dgit-distro.test-dummy.username' => "alice",
 635                'dgit-distro.test-dummy.git-check' => "ssh-cmd",
 636                'dgit-distro.test-dummy.git-create' => "ssh-cmd",
 637                'dgit-distro.test-dummy.git-url' => "$td/git",
 638                'dgit-distro.test-dummy.git-host' => "git",
 639                'dgit-distro.test-dummy.git-path' => "$td/git",
 640                'dgit-distro.test-dummy.archive-query' => "dummycatapi:",
 641                'dgit-distro.test-dummy.archive-query-url' => "file://$td/aq/",
 642                'dgit-distro.test-dummy.mirror' => "file://$td/mirror/",
 643                'dgit-distro.test-dummy.upload-host' => 'test-dummy',
 644                );
 645
 646 our %gitcfgs;
 647 our @gitcfgsources = qw(cmdline local global system);
 648 our $invoked_in_git_tree = 1;
 649
 650 sub git_slurp_config () {
 651     # This algoritm is a bit subtle, but this is needed so that for
 652     # options which we want to be single-valued, we allow the
 653     # different config sources to override properly.  See #835858.
 654     foreach my $src (@gitcfgsources) {
 655         next if $src eq 'cmdline';
 656         # we do this ourselves since git doesn't handle it
 657
 658         $gitcfgs{$src} = git_slurp_config_src $src;
 659     }
 660 }
 661
 662 sub git_get_config ($) {
 663     my ($c) = @_;
 664     foreach my $src (@gitcfgsources) {
 665         my $l = $gitcfgs{$src}{$c};
 666         confess "internal error ($l $c)" if $l && !ref $l;
 667         printdebug"C $c ".(defined $l ?
 668                            join " ", map { messagequote "'$_'" } @$l :
 669                            "undef")."\n"
 670             if $debuglevel >= 4;
 671         $l or next;
 672         @$l==1 or badcfg "multiple values for $c".
 673             " (in $src git config)" if @$l > 1;
 674         return $l->[0];
 675     }
 676     return undef;
 677 }
 678
 679 sub cfg {
 680     foreach my $c (@_) {
 681         return undef if $c =~ /RETURN-UNDEF/;
 682         printdebug "C? $c\n" if $debuglevel >= 5;
 683         my $v = git_get_config($c);
 684         return $v if defined $v;
 685         my $dv = $defcfg{$c};
 686         if (defined $dv) {
 687             printdebug "CD $c $dv\n" if $debuglevel >= 4;
 688             return $dv;
 689         }
 690     }
 691     badcfg "need value for one of: @_\n".
 692         "$us: distro or suite appears not to be (properly) supported";
 693 }
 694
 695 sub not_necessarily_a_tree () {
 696     # needs to be called from pre_*
 697     @gitcfgsources = grep { $_ ne 'local' } @gitcfgsources;
 698     $invoked_in_git_tree = 0;
 699 }
 700
 701 sub access_basedistro__noalias () {
 702     if (defined $idistro) {
 703         return $idistro;
 704     } else {
 705         my $def = cfg("dgit-suite.$isuite.distro", 'RETURN-UNDEF');
 706         return $def if defined $def;
 707         foreach my $src (@gitcfgsources, 'internal') {
 708             my $kl = $src eq 'internal' ? \%defcfg : $gitcfgs{$src};
 709             next unless $kl;
 710             foreach my $k (keys %$kl) {
 711                 next unless $k =~ m#^dgit-suite\.(.*)\.distro$#;
 712                 my $dpat = $1;
 713                 next unless match_glob $dpat, $isuite;
 714                 return $kl->{$k};
 715             }
 716         }
 717         return cfg("dgit.default.distro");
 718     }
 719 }
 720
 721 sub access_basedistro () {
 722     my $noalias = access_basedistro__noalias();
 723     my $canon = cfg("dgit-distro.$noalias.alias-canon",'RETURN-UNDEF');
 724     return $canon // $noalias;
 725 }
 726
 727 sub access_nomdistro () {
 728     my $base = access_basedistro();
 729     my $r = cfg("dgit-distro.$base.nominal-distro",'RETURN-UNDEF') // $base;
 730     $r =~ m/^$distro_re$/ or badcfg
 731  "bad syntax for (nominal) distro \`$r' (does not match /^$distro_re$/)";
 732     return $r;
 733 }
 734
 735 sub access_quirk () {
 736     # returns (quirk name, distro to use instead or undef, quirk-specific info)
 737     my $basedistro = access_basedistro();
 738     my $backports_quirk = cfg("dgit-distro.$basedistro.backports-quirk",
 739                               'RETURN-UNDEF');
 740     if (defined $backports_quirk) {
 741         my $re = $backports_quirk;
 742         $re =~ s/[^-0-9a-z_\%*()]/\\$&/ig;
 743         $re =~ s/\*/.*/g;
 744         $re =~ s/\%/([-0-9a-z_]+)/
 745             or $re =~ m/[()]/ or badcfg "backports-quirk needs \% or ( )";
 746         if ($isuite =~ m/^$re$/) {
 747             return ('backports',"$basedistro-backports",$1);
 748         }
 749     }
 750     return ('none',undef);
 751 }
 752
 753 our $access_forpush;
 754
 755 sub parse_cfg_bool ($$$) {
 756     my ($what,$def,$v) = @_;
 757     $v //= $def;
 758     return
 759         $v =~ m/^[ty1]/ ? 1 :
 760         $v =~ m/^[fn0]/ ? 0 :
 761         badcfg "$what needs t (true, y, 1) or f (false, n, 0) not \`$v'";
 762 }
 763
 764 sub access_forpush_config () {
 765     my $d = access_basedistro();
 766
 767     return 1 if
 768         $new_package &&
 769         parse_cfg_bool('new-private-pushers', 0,
 770                        cfg("dgit-distro.$d.new-private-pushers",
 771                            'RETURN-UNDEF'));
 772
 773     my $v = cfg("dgit-distro.$d.readonly", 'RETURN-UNDEF');
 774     $v //= 'a';
 775     return
 776         $v =~ m/^[ty1]/ ? 0 : # force readonly,    forpush = 0
 777         $v =~ m/^[fn0]/ ? 1 : # force nonreadonly, forpush = 1
 778         $v =~ m/^[a]/  ? '' : # auto,              forpush = ''
 779         badcfg "readonly needs t (true, y, 1) or f (false, n, 0) or a (auto)";
 780 }
 781
 782 sub access_forpush () {
 783     $access_forpush //= access_forpush_config();
 784     return $access_forpush;
 785 }
 786
 787 sub pushing () {
 788     die "$access_forpush ?" if ($access_forpush // 1) ne 1;
 789     badcfg "pushing but distro is configured readonly"
 790         if access_forpush_config() eq '0';
 791     $access_forpush = 1;
 792     $supplementary_message = <<'END' unless $we_are_responder;
 793 Push failed, before we got started.
 794 You can retry the push, after fixing the problem, if you like.
 795 END
 796     parseopts_late_defaults();
 797 }
 798
 799 sub notpushing () {
 800     parseopts_late_defaults();
 801 }
 802
 803 sub supplementary_message ($) {
 804     my ($msg) = @_;
 805     if (!$we_are_responder) {
 806         $supplementary_message = $msg;
 807         return;
 808     } elsif ($protovsn >= 3) {
 809         responder_send_command "supplementary-message ".length($msg)
 810             or die $!;
 811         print PO $msg or die $!;
 812     }
 813 }
 814
 815 sub access_distros () {
 816     # Returns list of distros to try, in order
 817     #
 818     # We want to try:
 819     #    0. `instead of' distro name(s) we have been pointed to
 820     #    1. the access_quirk distro, if any
 821     #    2a. the user's specified distro, or failing that  } basedistro
 822     #    2b. the distro calculated from the suite          }
 823     my @l = access_basedistro();
 824
 825     my (undef,$quirkdistro) = access_quirk();
 826     unshift @l, $quirkdistro;
 827     unshift @l, $instead_distro;
 828     @l = grep { defined } @l;
 829
 830     push @l, access_nomdistro();
 831
 832     if (access_forpush()) {
 833         @l = map { ("$_/push", $_) } @l;
 834     }
 835     @l;
 836 }
 837
 838 sub access_cfg_cfgs (@) {
 839     my (@keys) = @_;
 840     my @cfgs;
 841     # The nesting of these loops determines the search order.  We put
 842     # the key loop on the outside so that we search all the distros
 843     # for each key, before going on to the next key.  That means that
 844     # if access_cfg is called with a more specific, and then a less
 845     # specific, key, an earlier distro can override the less specific
 846     # without necessarily overriding any more specific keys.  (If the
 847     # distro wants to override the more specific keys it can simply do
 848     # so; whereas if we did the loop the other way around, it would be
 849     # impossible to for an earlier distro to override a less specific
 850     # key but not the more specific ones without restating the unknown
 851     # values of the more specific keys.
 852     my @realkeys;
 853     my @rundef;
 854     # We have to deal with RETURN-UNDEF specially, so that we don't
 855     # terminate the search prematurely.
 856     foreach (@keys) {
 857         if (m/RETURN-UNDEF/) { push @rundef, $_; last; }
 858         push @realkeys, $_
 859     }
 860     foreach my $d (access_distros()) {
 861         push @cfgs, map { "dgit-distro.$d.$_" } @realkeys;
 862     }
 863     push @cfgs, map { "dgit.default.$_" } @realkeys;
 864     push @cfgs, @rundef;
 865     return @cfgs;
 866 }
 867
 868 sub access_cfg (@) {
 869     my (@keys) = @_;
 870     my (@cfgs) = access_cfg_cfgs(@keys);
 871     my $value = cfg(@cfgs);
 872     return $value;
 873 }
 874
 875 sub access_cfg_bool ($$) {
 876     my ($def, @keys) = @_;
 877     parse_cfg_bool($keys[0], $def, access_cfg(@keys, 'RETURN-UNDEF'));
 878 }
 879
 880 sub string_to_ssh ($) {
 881     my ($spec) = @_;
 882     if ($spec =~ m/\s/) {
 883         return qw(sh -ec), 'exec '.$spec.' "$@"', 'x';
 884     } else {
 885         return ($spec);
 886     }
 887 }
 888
 889 sub access_cfg_ssh () {
 890     my $gitssh = access_cfg('ssh', 'RETURN-UNDEF');
 891     if (!defined $gitssh) {
 892         return @ssh;
 893     } else {
 894         return string_to_ssh $gitssh;
 895     }
 896 }
 897
 898 sub access_runeinfo ($) {
 899     my ($info) = @_;
 900     return ": dgit ".access_basedistro()." $info ;";
 901 }
 902
 903 sub access_someuserhost ($) {
 904     my ($some) = @_;
 905     my $user = access_cfg("$some-user-force", 'RETURN-UNDEF');
 906     defined($user) && length($user) or
 907         $user = access_cfg("$some-user",'username');
 908     my $host = access_cfg("$some-host");
 909     return length($user) ? "$user\@$host" : $host;
 910 }
 911
 912 sub access_gituserhost () {
 913     return access_someuserhost('git');
 914 }
 915
 916 sub access_giturl (;$) {
 917     my ($optional) = @_;
 918     my $url = access_cfg('git-url','RETURN-UNDEF');
 919     my $suffix;
 920     if (!length $url) {
 921         my $proto = access_cfg('git-proto', 'RETURN-UNDEF');
 922         return undef unless defined $proto;
 923         $url =
 924             $proto.
 925             access_gituserhost().
 926             access_cfg('git-path');
 927     } else {
 928         $suffix = access_cfg('git-url-suffix','RETURN-UNDEF');
 929     }
 930     $suffix //= '.git';
 931     return "$url/$package$suffix";
 932 }
 933
 934 sub parsecontrolfh ($$;$) {
 935     my ($fh, $desc, $allowsigned) = @_;
 936     our $dpkgcontrolhash_noissigned;
 937     my $c;
 938     for (;;) {
 939         my %opts = ('name' => $desc);
 940         $opts{allow_pgp}= $allowsigned || !$dpkgcontrolhash_noissigned;
 941         $c = Dpkg::Control::Hash->new(%opts);
 942         $c->parse($fh,$desc) or die "parsing of $desc failed";
 943         last if $allowsigned;
 944         last if $dpkgcontrolhash_noissigned;
 945         my $issigned= $c->get_option('is_pgp_signed');
 946         if (!defined $issigned) {
 947             $dpkgcontrolhash_noissigned= 1;
 948             seek $fh, 0,0 or die "seek $desc: $!";
 949         } elsif ($issigned) {
 950             fail "control file $desc is (already) PGP-signed. ".
 951                 " Note that dgit push needs to modify the .dsc and then".
 952                 " do the signature itself";
 953         } else {
 954             last;
 955         }
 956     }
 957     return $c;
 958 }
 959
 960 sub parsecontrol {
 961     my ($file, $desc, $allowsigned) = @_;
 962     my $fh = new IO::Handle;
 963     open $fh, '<', $file or die "$file: $!";
 964     my $c = parsecontrolfh($fh,$desc,$allowsigned);
 965     $fh->error and die $!;
 966     close $fh;
 967     return $c;
 968 }
 969
 970 sub getfield ($$) {
 971     my ($dctrl,$field) = @_;
 972     my $v = $dctrl->{$field};
 973     return $v if defined $v;
 974     fail "missing field $field in ".$dctrl->get_option('name');
 975 }
 976
 977 sub parsechangelog {
 978     my $c = Dpkg::Control::Hash->new(name => 'parsed changelog');
 979     my $p = new IO::Handle;
 980     my @cmd = (qw(dpkg-parsechangelog), @_);
 981     open $p, '-|', @cmd or die $!;
 982     $c->parse($p);
 983     $?=0; $!=0; close $p or failedcmd @cmd;
 984     return $c;
 985 }
 986
 987 sub commit_getclogp ($) {
 988     # Returns the parsed changelog hashref for a particular commit
 989     my ($objid) = @_;
 990     our %commit_getclogp_memo;
 991     my $memo = $commit_getclogp_memo{$objid};
 992     return $memo if $memo;
 993
 994     my $mclog = dgit_privdir()."clog";
 995     runcmd shell_cmd "exec >$mclog", @git, qw(cat-file blob),
 996         "$objid:debian/changelog";
 997     $commit_getclogp_memo{$objid} = parsechangelog("-l$mclog");
 998 }
 999
1000 sub parse_dscdata () {
1001     my $dscfh = new IO::File \$dscdata, '<' or die $!;
1002     printdebug Dumper($dscdata) if $debuglevel>1;
1003     $dsc = parsecontrolfh($dscfh,$dscurl,1);
1004     printdebug Dumper($dsc) if $debuglevel>1;
1005 }
1006
1007 our %rmad;
1008
1009 sub archive_query ($;@) {
1010     my ($method) = shift @_;
1011     fail "this operation does not support multiple comma-separated suites"
1012         if $isuite =~ m/,/;
1013     my $query = access_cfg('archive-query','RETURN-UNDEF');
1014     $query =~ s/^(\w+):// or badcfg "invalid archive-query method \`$query'";
1015     my $proto = $1;
1016     my $data = $'; #';
1017     { no strict qw(refs); &{"${method}_${proto}"}($proto,$data,@_); }
1018 }
1019
1020 sub archive_query_prepend_mirror {
1021     my $m = access_cfg('mirror');
1022     return map { [ $_->[0], $m.$_->[1], @$_[2..$#$_] ] } @_;
1023 }
1024
1025 sub pool_dsc_subpath ($$) {
1026     my ($vsn,$component) = @_; # $package is implict arg
1027     my $prefix = substr($package, 0, $package =~ m/^l/ ? 4 : 1);
1028     return "/pool/$component/$prefix/$package/".dscfn($vsn);
1029 }
1030
1031 sub cfg_apply_map ($$$) {
1032     my ($varref, $what, $mapspec) = @_;
1033     return unless $mapspec;
1034
1035     printdebug "config $what EVAL{ $mapspec; }\n";
1036     $_ = $$varref;
1037     eval "package Dgit::Config; $mapspec;";
1038     die $@ if $@;
1039     $$varref = $_;
1040 }
1041
1042 #---------- `ftpmasterapi' archive query method (nascent) ----------
1043
1044 sub archive_api_query_cmd ($) {
1045     my ($subpath) = @_;
1046     my @cmd = (@curl, qw(-sS));
1047     my $url = access_cfg('archive-query-url');
1048     if ($url =~ m#^https://([-.0-9a-z]+)/#) {
1049         my $host = $1;
1050         my $keys = access_cfg('archive-query-tls-key','RETURN-UNDEF') //'';
1051         foreach my $key (split /\:/, $keys) {
1052             $key =~ s/\%HOST\%/$host/g;
1053             if (!stat $key) {
1054                 fail "for $url: stat $key: $!" unless $!==ENOENT;
1055                 next;
1056             }
1057             fail "config requested specific TLS key but do not know".
1058                 " how to get curl to use exactly that EE key ($key)";
1059 #           push @cmd, "--cacert", $key, "--capath", "/dev/enoent";
1060 #           # Sadly the above line does not work because of changes
1061 #           # to gnutls.   The real fix for #790093 may involve
1062 #           # new curl options.
1063             last;
1064         }
1065         # Fixing #790093 properly will involve providing a value
1066         # for this on clients.
1067         my $kargs = access_cfg('archive-query-tls-curl-ca-args','RETURN-UNDEF');
1068         push @cmd, split / /, $kargs if defined $kargs;
1069     }
1070     push @cmd, $url.$subpath;
1071     return @cmd;
1072 }
1073
1074 sub api_query ($$;$) {
1075     use JSON;
1076     my ($data, $subpath, $ok404) = @_;
1077     badcfg "ftpmasterapi archive query method takes no data part"
1078         if length $data;
1079     my @cmd = archive_api_query_cmd($subpath);
1080     my $url = $cmd[$#cmd];
1081     push @cmd, qw(-w %{http_code});
1082     my $json = cmdoutput @cmd;
1083     unless ($json =~ s/\d+\d+\d$//) {
1084         failedcmd_report_cmd undef, @cmd;
1085         fail "curl failed to print 3-digit HTTP code";
1086     }
1087     my $code = $&;
1088     return undef if $code eq '404' && $ok404;
1089     fail "fetch of $url gave HTTP code $code"
1090         unless $url =~ m#^file://# or $code =~ m/^2/;
1091     return decode_json($json);
1092 }
1093
1094 sub canonicalise_suite_ftpmasterapi {
1095     my ($proto,$data) = @_;
1096     my $suites = api_query($data, 'suites');
1097     my @matched;
1098     foreach my $entry (@$suites) {
1099         next unless grep {
1100             my $v = $entry->{$_};
1101             defined $v && $v eq $isuite;
1102         } qw(codename name);
1103         push @matched, $entry;
1104     }
1105     fail "unknown suite $isuite" unless @matched;
1106     my $cn;
1107     eval {
1108         @matched==1 or die "multiple matches for suite $isuite\n";
1109         $cn = "$matched[0]{codename}";
1110         defined $cn or die "suite $isuite info has no codename\n";
1111         $cn =~ m/^$suite_re$/ or die "suite $isuite maps to bad codename\n";
1112     };
1113     die "bad ftpmaster api response: $@\n".Dumper(\@matched)
1114         if length $@;
1115     return $cn;
1116 }
1117
1118 sub archive_query_ftpmasterapi {
1119     my ($proto,$data) = @_;
1120     my $info = api_query($data, "dsc_in_suite/$isuite/$package");
1121     my @rows;
1122     my $digester = Digest::SHA->new(256);
1123     foreach my $entry (@$info) {
1124         eval {
1125             my $vsn = "$entry->{version}";
1126             my ($ok,$msg) = version_check $vsn;
1127             die "bad version: $msg\n" unless $ok;
1128             my $component = "$entry->{component}";
1129             $component =~ m/^$component_re$/ or die "bad component";
1130             my $filename = "$entry->{filename}";
1131             $filename && $filename !~ m#[^-+:._~0-9a-zA-Z/]|^[/.]|/[/.]#
1132                 or die "bad filename";
1133             my $sha256sum = "$entry->{sha256sum}";
1134             $sha256sum =~ m/^[0-9a-f]+$/ or die "bad sha256sum";
1135             push @rows, [ $vsn, "/pool/$component/$filename",
1136                           $digester, $sha256sum ];
1137         };
1138         die "bad ftpmaster api response: $@\n".Dumper($entry)
1139             if length $@;
1140     }
1141     @rows = sort { -version_compare($a->[0],$b->[0]) } @rows;
1142     return archive_query_prepend_mirror @rows;
1143 }
1144
1145 sub file_in_archive_ftpmasterapi {
1146     my ($proto,$data,$filename) = @_;
1147     my $pat = $filename;
1148     $pat =~ s/_/\\_/g;
1149     $pat = "%/$pat";
1150     $pat =~ s#[^-+_.0-9a-z/]# sprintf '%%%02x', ord $& #ge;
1151     my $info = api_query($data, "file_in_archive/$pat", 1);
1152 }
1153
1154 #---------- `aptget' archive query method ----------
1155
1156 our $aptget_base;
1157 our $aptget_releasefile;
1158 our $aptget_configpath;
1159
1160 sub aptget_aptget   () { return @aptget,   qw(-c), $aptget_configpath; }
1161 sub aptget_aptcache () { return @aptcache, qw(-c), $aptget_configpath; }
1162
1163 sub aptget_cache_clean {
1164     runcmd_ordryrun_local qw(sh -ec),
1165         'cd "$1"; find -atime +30 -type f -print0 | xargs -0r rm --',
1166         'x', $aptget_base;
1167 }
1168
1169 sub aptget_lock_acquire () {
1170     my $lockfile = "$aptget_base/lock";
1171     open APTGET_LOCK, '>', $lockfile or die "open $lockfile: $!";
1172     flock APTGET_LOCK, LOCK_EX or die "lock $lockfile: $!";
1173 }
1174
1175 sub aptget_prep ($) {
1176     my ($data) = @_;
1177     return if defined $aptget_base;
1178
1179     badcfg "aptget archive query method takes no data part"
1180         if length $data;
1181
1182     my $cache = $ENV{XDG_CACHE_DIR} // "$ENV{HOME}/.cache";
1183
1184     ensuredir $cache;
1185     ensuredir "$cache/dgit";
1186     my $cachekey =
1187         access_cfg('aptget-cachekey','RETURN-UNDEF')
1188         // access_nomdistro();
1189
1190     $aptget_base = "$cache/dgit/aptget";
1191     ensuredir $aptget_base;
1192
1193     my $quoted_base = $aptget_base;
1194     die "$quoted_base contains bad chars, cannot continue"
1195         if $quoted_base =~ m/["\\]/; # apt.conf(5) says no escaping :-/
1196
1197     ensuredir $aptget_base;
1198
1199     aptget_lock_acquire();
1200
1201     aptget_cache_clean();
1202
1203     $aptget_configpath = "$aptget_base/apt.conf#$cachekey";
1204     my $sourceslist = "source.list#$cachekey";
1205
1206     my $aptsuites = $isuite;
1207     cfg_apply_map(\$aptsuites, 'suite map',
1208                   access_cfg('aptget-suite-map', 'RETURN-UNDEF'));
1209
1210     open SRCS, ">", "$aptget_base/$sourceslist" or die $!;
1211     printf SRCS "deb-src %s %s %s\n",
1212         access_cfg('mirror'),
1213         $aptsuites,
1214         access_cfg('aptget-components')
1215         or die $!;
1216
1217     ensuredir "$aptget_base/cache";
1218     ensuredir "$aptget_base/lists";
1219
1220     open CONF, ">", $aptget_configpath or die $!;
1221     print CONF <<END;
1222 Debug::NoLocking "true";
1223 APT::Get::List-Cleanup "false";
1224 #clear APT::Update::Post-Invoke-Success;
1225 Dir::Etc::SourceList "$quoted_base/$sourceslist";
1226 Dir::State::Lists "$quoted_base/lists";
1227 Dir::Etc::preferences "$quoted_base/preferences";
1228 Dir::Cache::srcpkgcache "$quoted_base/cache/srcs#$cachekey";
1229 Dir::Cache::pkgcache "$quoted_base/cache/pkgs#$cachekey";
1230 END
1231
1232     foreach my $key (qw(
1233                         Dir::Cache
1234                         Dir::State
1235                         Dir::Cache::Archives
1236                         Dir::Etc::SourceParts
1237                         Dir::Etc::preferencesparts
1238                       )) {
1239         ensuredir "$aptget_base/$key";
1240         print CONF "$key \"$quoted_base/$key\";\n" or die $!;
1241     };
1242
1243     my $oldatime = (time // die $!) - 1;
1244     foreach my $oldlist (<$aptget_base/lists/*Release>) {
1245         next unless stat_exists $oldlist;
1246         my ($mtime) = (stat _)[9];
1247         utime $oldatime, $mtime, $oldlist or die "$oldlist $!";
1248     }
1249
1250     runcmd_ordryrun_local aptget_aptget(), qw(update);
1251
1252     my @releasefiles;
1253     foreach my $oldlist (<$aptget_base/lists/*Release>) {
1254         next unless stat_exists $oldlist;
1255         my ($atime) = (stat _)[8];
1256         next if $atime == $oldatime;
1257         push @releasefiles, $oldlist;
1258     }
1259     my @inreleasefiles = grep { m#/InRelease$# } @releasefiles;
1260     @releasefiles = @inreleasefiles if @inreleasefiles;
1261     die "apt updated wrong number of Release files (@releasefiles), erk"
1262         unless @releasefiles == 1;
1263
1264     ($aptget_releasefile) = @releasefiles;
1265 }
1266
1267 sub canonicalise_suite_aptget {
1268     my ($proto,$data) = @_;
1269     aptget_prep($data);
1270
1271     my $release = parsecontrol $aptget_releasefile, "Release file", 1;
1272
1273     foreach my $name (qw(Codename Suite)) {
1274         my $val = $release->{$name};
1275         if (defined $val) {
1276             printdebug "release file $name: $val\n";
1277             $val =~ m/^$suite_re$/o or fail
1278  "Release file ($aptget_releasefile) specifies intolerable $name";
1279             cfg_apply_map(\$val, 'suite rmap',
1280                           access_cfg('aptget-suite-rmap', 'RETURN-UNDEF'));
1281             return $val
1282         }
1283     }
1284     return $isuite;
1285 }
1286
1287 sub archive_query_aptget {
1288     my ($proto,$data) = @_;
1289     aptget_prep($data);
1290
1291     ensuredir "$aptget_base/source";
1292     foreach my $old (<$aptget_base/source/*.dsc>) {
1293         unlink $old or die "$old: $!";
1294     }
1295
1296     my $showsrc = cmdoutput aptget_aptcache(), qw(showsrc), $package;
1297     return () unless $showsrc =~ m/^package:\s*\Q$package\E\s*$/mi;
1298     # avoids apt-get source failing with ambiguous error code
1299
1300     runcmd_ordryrun_local
1301         shell_cmd 'cd "$1"/source; shift', $aptget_base,
1302         aptget_aptget(), qw(--download-only --only-source source), $package;
1303
1304     my @dscs = <$aptget_base/source/*.dsc>;
1305     fail "apt-get source did not produce a .dsc" unless @dscs;
1306     fail "apt-get source produced several .dscs (@dscs)" unless @dscs==1;
1307
1308     my $pre_dsc = parsecontrol $dscs[0], $dscs[0], 1;
1309
1310     use URI::Escape;
1311     my $uri = "file://". uri_escape $dscs[0];
1312     $uri =~ s{\%2f}{/}gi;
1313     return [ (getfield $pre_dsc, 'Version'), $uri ];
1314 }
1315
1316 sub file_in_archive_aptget () { return undef; }
1317
1318 #---------- `dummyapicat' archive query method ----------
1319
1320 sub archive_query_dummycatapi { archive_query_ftpmasterapi @_; }
1321 sub canonicalise_suite_dummycatapi { canonicalise_suite_ftpmasterapi @_; }
1322
1323 sub file_in_archive_dummycatapi ($$$) {
1324     my ($proto,$data,$filename) = @_;
1325     my $mirror = access_cfg('mirror');
1326     $mirror =~ s#^file://#/# or die "$mirror ?";
1327     my @out;
1328     my @cmd = (qw(sh -ec), '
1329             cd "$1"
1330             find -name "$2" -print0 |
1331             xargs -0r sha256sum
1332         ', qw(x), $mirror, $filename);
1333     debugcmd "-|", @cmd;
1334     open FIA, "-|", @cmd or die $!;
1335     while (<FIA>) {
1336         chomp or die;
1337         printdebug "| $_\n";
1338         m/^(\w+)  (\S+)$/ or die "$_ ?";
1339         push @out, { sha256sum => $1, filename => $2 };
1340     }
1341     close FIA or die failedcmd @cmd;
1342     return \@out;
1343 }
1344
1345 #---------- `madison' archive query method ----------
1346
1347 sub archive_query_madison {
1348     return archive_query_prepend_mirror
1349         map { [ @$_[0..1] ] } madison_get_parse(@_);
1350 }
1351
1352 sub madison_get_parse {
1353     my ($proto,$data) = @_;
1354     die unless $proto eq 'madison';
1355     if (!length $data) {
1356         $data= access_cfg('madison-distro','RETURN-UNDEF');
1357         $data //= access_basedistro();
1358     }
1359     $rmad{$proto,$data,$package} ||= cmdoutput
1360         qw(rmadison -asource),"-s$isuite","-u$data",$package;
1361     my $rmad = $rmad{$proto,$data,$package};
1362
1363     my @out;
1364     foreach my $l (split /\n/, $rmad) {
1365         $l =~ m{^ \s*( [^ \t|]+ )\s* \|
1366                   \s*( [^ \t|]+ )\s* \|
1367                   \s*( [^ \t|/]+ )(?:/([^ \t|/]+))? \s* \|
1368                   \s*( [^ \t|]+ )\s* }x or die "$rmad ?";
1369         $1 eq $package or die "$rmad $package ?";
1370         my $vsn = $2;
1371         my $newsuite = $3;
1372         my $component;
1373         if (defined $4) {
1374             $component = $4;
1375         } else {
1376             $component = access_cfg('archive-query-default-component');
1377         }
1378         $5 eq 'source' or die "$rmad ?";
1379         push @out, [$vsn,pool_dsc_subpath($vsn,$component),$newsuite];
1380     }
1381     return sort { -version_compare($a->[0],$b->[0]); } @out;
1382 }
1383
1384 sub canonicalise_suite_madison {
1385     # madison canonicalises for us
1386     my @r = madison_get_parse(@_);
1387     @r or fail
1388         "unable to canonicalise suite using package $package".
1389         " which does not appear to exist in suite $isuite;".
1390         " --existing-package may help";
1391     return $r[0][2];
1392 }
1393
1394 sub file_in_archive_madison { return undef; }
1395
1396 #---------- `sshpsql' archive query method ----------
1397
1398 sub sshpsql ($$$) {
1399     my ($data,$runeinfo,$sql) = @_;
1400     if (!length $data) {
1401         $data= access_someuserhost('sshpsql').':'.
1402             access_cfg('sshpsql-dbname');
1403     }
1404     $data =~ m/:/ or badcfg "invalid sshpsql method string \`$data'";
1405     my ($userhost,$dbname) = ($`,$'); #';
1406     my @rows;
1407     my @cmd = (access_cfg_ssh, $userhost,
1408                access_runeinfo("ssh-psql $runeinfo").
1409                " export LC_MESSAGES=C; export LC_CTYPE=C;".
1410                " ".shellquote qw(psql -A), $dbname, qw(-c), $sql);
1411     debugcmd "|",@cmd;
1412     open P, "-|", @cmd or die $!;
1413     while (<P>) {
1414         chomp or die;
1415         printdebug(">|$_|\n");
1416         push @rows, $_;
1417     }
1418     $!=0; $?=0; close P or failedcmd @cmd;
1419     @rows or die;
1420     my $nrows = pop @rows;
1421     $nrows =~ s/^\((\d+) rows?\)$/$1/ or die "$nrows ?";
1422     @rows == $nrows+1 or die "$nrows ".(scalar @rows)." ?";
1423     @rows = map { [ split /\|/, $_ ] } @rows;
1424     my $ncols = scalar @{ shift @rows };
1425     die if grep { scalar @$_ != $ncols } @rows;
1426     return @rows;
1427 }
1428
1429 sub sql_injection_check {
1430     foreach (@_) { die "$_ $& ?" if m{[^-+=:_.,/0-9a-zA-Z]}; }
1431 }
1432
1433 sub archive_query_sshpsql ($$) {
1434     my ($proto,$data) = @_;
1435     sql_injection_check $isuite, $package;
1436     my @rows = sshpsql($data, "archive-query $isuite $package", <<END);
1437         SELECT source.version, component.name, files.filename, files.sha256sum
1438           FROM source
1439           JOIN src_associations ON source.id = src_associations.source
1440           JOIN suite ON suite.id = src_associations.suite
1441           JOIN dsc_files ON dsc_files.source = source.id
1442           JOIN files_archive_map ON files_archive_map.file_id = dsc_files.file
1443           JOIN component ON component.id = files_archive_map.component_id
1444           JOIN files ON files.id = dsc_files.file
1445          WHERE ( suite.suite_name='$isuite' OR suite.codename='$isuite' )
1446            AND source.source='$package'
1447            AND files.filename LIKE '%.dsc';
1448 END
1449     @rows = sort { -version_compare($a->[0],$b->[0]) } @rows;
1450     my $digester = Digest::SHA->new(256);
1451     @rows = map {
1452         my ($vsn,$component,$filename,$sha256sum) = @$_;
1453         [ $vsn, "/pool/$component/$filename",$digester,$sha256sum ];
1454     } @rows;
1455     return archive_query_prepend_mirror @rows;
1456 }
1457
1458 sub canonicalise_suite_sshpsql ($$) {
1459     my ($proto,$data) = @_;
1460     sql_injection_check $isuite;
1461     my @rows = sshpsql($data, "canonicalise-suite $isuite", <<END);
1462         SELECT suite.codename
1463           FROM suite where suite_name='$isuite' or codename='$isuite';
1464 END
1465     @rows = map { $_->[0] } @rows;
1466     fail "unknown suite $isuite" unless @rows;
1467     die "ambiguous $isuite: @rows ?" if @rows>1;
1468     return $rows[0];
1469 }
1470
1471 sub file_in_archive_sshpsql ($$$) { return undef; }
1472
1473 #---------- `dummycat' archive query method ----------
1474
1475 sub canonicalise_suite_dummycat ($$) {
1476     my ($proto,$data) = @_;
1477     my $dpath = "$data/suite.$isuite";
1478     if (!open C, "<", $dpath) {
1479         $!==ENOENT or die "$dpath: $!";
1480         printdebug "dummycat canonicalise_suite $isuite $dpath ENOENT\n";
1481         return $isuite;
1482     }
1483     $!=0; $_ = <C>;
1484     chomp or die "$dpath: $!";
1485     close C;
1486     printdebug "dummycat canonicalise_suite $isuite $dpath = $_\n";
1487     return $_;
1488 }
1489
1490 sub archive_query_dummycat ($$) {
1491     my ($proto,$data) = @_;
1492     canonicalise_suite();
1493     my $dpath = "$data/package.$csuite.$package";
1494     if (!open C, "<", $dpath) {
1495         $!==ENOENT or die "$dpath: $!";
1496         printdebug "dummycat query $csuite $package $dpath ENOENT\n";
1497         return ();
1498     }
1499     my @rows;
1500     while (<C>) {
1501         next if m/^\#/;
1502         next unless m/\S/;
1503         die unless chomp;
1504         printdebug "dummycat query $csuite $package $dpath | $_\n";
1505         my @row = split /\s+/, $_;
1506         @row==2 or die "$dpath: $_ ?";
1507         push @rows, \@row;
1508     }
1509     C->error and die "$dpath: $!";
1510     close C;
1511     return archive_query_prepend_mirror
1512         sort { -version_compare($a->[0],$b->[0]); } @rows;
1513 }
1514
1515 sub file_in_archive_dummycat () { return undef; }
1516
1517 #---------- tag format handling ----------
1518
1519 sub access_cfg_tagformats () {
1520     split /\,/, access_cfg('dgit-tag-format');
1521 }
1522
1523 sub access_cfg_tagformats_can_splitbrain () {
1524     my %y = map { $_ => 1 } access_cfg_tagformats;
1525     foreach my $needtf (qw(new maint)) {
1526         next if $y{$needtf};
1527         return 0;
1528     }
1529     return 1;
1530 }
1531
1532 sub need_tagformat ($$) {
1533     my ($fmt, $why) = @_;
1534     fail "need to use tag format $fmt ($why) but also need".
1535         " to use tag format $tagformat_want->[0] ($tagformat_want->[1])".
1536         " - no way to proceed"
1537         if $tagformat_want && $tagformat_want->[0] ne $fmt;
1538     $tagformat_want = [$fmt, $why, $tagformat_want->[2] // 0];
1539 }
1540
1541 sub select_tagformat () {
1542     # sets $tagformatfn
1543     return if $tagformatfn && !$tagformat_want;
1544     die 'bug' if $tagformatfn && $tagformat_want;
1545     # ... $tagformat_want assigned after previous select_tagformat
1546
1547     my (@supported) = grep { $_ =~ m/^(?:old|new)$/ } access_cfg_tagformats();
1548     printdebug "select_tagformat supported @supported\n";
1549
1550     $tagformat_want //= [ $supported[0], "distro access configuration", 0 ];
1551     printdebug "select_tagformat specified @$tagformat_want\n";
1552
1553     my ($fmt,$why,$override) = @$tagformat_want;
1554
1555     fail "target distro supports tag formats @supported".
1556         " but have to use $fmt ($why)"
1557         unless $override
1558             or grep { $_ eq $fmt } @supported;
1559
1560     $tagformat_want = undef;
1561     $tagformat = $fmt;
1562     $tagformatfn = ${*::}{"debiantag_$fmt"};
1563
1564     fail "trying to use unknown tag format \`$fmt' ($why) !"
1565         unless $tagformatfn;
1566 }
1567
1568 #---------- archive query entrypoints and rest of program ----------
1569
1570 sub canonicalise_suite () {
1571     return if defined $csuite;
1572     fail "cannot operate on $isuite suite" if $isuite eq 'UNRELEASED';
1573     $csuite = archive_query('canonicalise_suite');
1574     if ($isuite ne $csuite) {
1575         progress "canonical suite name for $isuite is $csuite";
1576     } else {
1577         progress "canonical suite name is $csuite";
1578     }
1579 }
1580
1581 sub get_archive_dsc () {
1582     canonicalise_suite();
1583     my @vsns = archive_query('archive_query');
1584     foreach my $vinfo (@vsns) {
1585         my ($vsn,$vsn_dscurl,$digester,$digest) = @$vinfo;
1586         $dscurl = $vsn_dscurl;
1587         $dscdata = url_get($dscurl);
1588         if (!$dscdata) {
1589             $skew_warning_vsn = $vsn if !defined $skew_warning_vsn;
1590             next;
1591         }
1592         if ($digester) {
1593             $digester->reset();
1594             $digester->add($dscdata);
1595             my $got = $digester->hexdigest();
1596             $got eq $digest or
1597                 fail "$dscurl has hash $got but".
1598                     " archive told us to expect $digest";
1599         }
1600         parse_dscdata();
1601         my $fmt = getfield $dsc, 'Format';
1602         $format_ok{$fmt} or forceable_fail [qw(unsupported-source-format)],
1603             "unsupported source format $fmt, sorry";
1604
1605         $dsc_checked = !!$digester;
1606         printdebug "get_archive_dsc: Version ".(getfield $dsc, 'Version')."\n";
1607         return;
1608     }
1609     $dsc = undef;
1610     printdebug "get_archive_dsc: nothing in archive, returning undef\n";
1611 }
1612
1613 sub check_for_git ();
1614 sub check_for_git () {
1615     # returns 0 or 1
1616     my $how = access_cfg('git-check');
1617     if ($how eq 'ssh-cmd') {
1618         my @cmd =
1619             (access_cfg_ssh, access_gituserhost(),
1620              access_runeinfo("git-check $package").
1621              " set -e; cd ".access_cfg('git-path').";".
1622              " if test -d $package.git; then echo 1; else echo 0; fi");
1623         my $r= cmdoutput @cmd;
1624         if (defined $r and $r =~ m/^divert (\w+)$/) {
1625             my $divert=$1;
1626             my ($usedistro,) = access_distros();
1627             # NB that if we are pushing, $usedistro will be $distro/push
1628             $instead_distro= cfg("dgit-distro.$usedistro.diverts.$divert");
1629             $instead_distro =~ s{^/}{ access_basedistro()."/" }e;
1630             progress "diverting to $divert (using config for $instead_distro)";
1631             return check_for_git();
1632         }
1633         failedcmd @cmd unless defined $r and $r =~ m/^[01]$/;
1634         return $r+0;
1635     } elsif ($how eq 'url') {
1636         my $prefix = access_cfg('git-check-url','git-url');
1637         my $suffix = access_cfg('git-check-suffix','git-suffix',
1638                                 'RETURN-UNDEF') // '.git';
1639         my $url = "$prefix/$package$suffix";
1640         my @cmd = (@curl, qw(-sS -I), $url);
1641         my $result = cmdoutput @cmd;
1642         $result =~ s/^\S+ 200 .*\n\r?\n//;
1643         # curl -sS -I with https_proxy prints
1644         # HTTP/1.0 200 Connection established
1645         $result =~ m/^\S+ (404|200) /s or
1646             fail "unexpected results from git check query - ".
1647                 Dumper($prefix, $result);
1648         my $code = $1;
1649         if ($code eq '404') {
1650             return 0;
1651         } elsif ($code eq '200') {
1652             return 1;
1653         } else {
1654             die;
1655         }
1656     } elsif ($how eq 'true') {
1657         return 1;
1658     } elsif ($how eq 'false') {
1659         return 0;
1660     } else {
1661         badcfg "unknown git-check \`$how'";
1662     }
1663 }
1664
1665 sub create_remote_git_repo () {
1666     my $how = access_cfg('git-create');
1667     if ($how eq 'ssh-cmd') {
1668         runcmd_ordryrun
1669             (access_cfg_ssh, access_gituserhost(),
1670              access_runeinfo("git-create $package").
1671              "set -e; cd ".access_cfg('git-path').";".
1672              " cp -a _template $package.git");
1673     } elsif ($how eq 'true') {
1674         # nothing to do
1675     } else {
1676         badcfg "unknown git-create \`$how'";
1677     }
1678 }
1679
1680 our ($dsc_hash,$lastpush_mergeinput);
1681 our ($dsc_distro, $dsc_hint_tag, $dsc_hint_url);
1682
1683
1684 sub prep_ud () {
1685     dgit_privdir(); # ensures that $dgit_privdir_made is based on $maindir
1686     fresh_playground 'dgit/unpack';
1687 }
1688
1689 sub mktree_in_ud_here () {
1690     playtree_setup $gitcfgs{local};
1691 }
1692
1693 sub git_write_tree () {
1694     my $tree = cmdoutput @git, qw(write-tree);
1695     $tree =~ m/^\w+$/ or die "$tree ?";
1696     return $tree;
1697 }
1698
1699 sub git_add_write_tree () {
1700     runcmd @git, qw(add -Af .);
1701     return git_write_tree();
1702 }
1703
1704 sub remove_stray_gits ($) {
1705     my ($what) = @_;
1706     my @gitscmd = qw(find -name .git -prune -print0);
1707     debugcmd "|",@gitscmd;
1708     open GITS, "-|", @gitscmd or die $!;
1709     {
1710         local $/="\0";
1711         while (<GITS>) {
1712             chomp or die;
1713             print STDERR "$us: warning: removing from $what: ",
1714                 (messagequote $_), "\n";
1715             rmtree $_;
1716         }
1717     }
1718     $!=0; $?=0; close GITS or failedcmd @gitscmd;
1719 }
1720
1721 sub mktree_in_ud_from_only_subdir ($;$) {
1722     my ($what,$raw) = @_;
1723     # changes into the subdir
1724
1725     my (@dirs) = <*/.>;
1726     die "expected one subdir but found @dirs ?" unless @dirs==1;
1727     $dirs[0] =~ m#^([^/]+)/\.$# or die;
1728     my $dir = $1;
1729     changedir $dir;
1730
1731     remove_stray_gits($what);
1732     mktree_in_ud_here();
1733     if (!$raw) {
1734         my ($format, $fopts) = get_source_format();
1735         if (madformat($format)) {
1736             rmtree '.pc';
1737         }
1738     }
1739
1740     my $tree=git_add_write_tree();
1741     return ($tree,$dir);
1742 }
1743
1744 our @files_csum_info_fields =
1745     (['Checksums-Sha256','Digest::SHA', 'new(256)', 'sha256sum'],
1746      ['Checksums-Sha1',  'Digest::SHA', 'new(1)',   'sha1sum'],
1747      ['Files',           'Digest::MD5', 'new()',    'md5sum']);
1748
1749 sub dsc_files_info () {
1750     foreach my $csumi (@files_csum_info_fields) {
1751         my ($fname, $module, $method) = @$csumi;
1752         my $field = $dsc->{$fname};
1753         next unless defined $field;
1754         eval "use $module; 1;" or die $@;
1755         my @out;
1756         foreach (split /\n/, $field) {
1757             next unless m/\S/;
1758             m/^(\w+) (\d+) (\S+)$/ or
1759                 fail "could not parse .dsc $fname line \`$_'";
1760             my $digester = eval "$module"."->$method;" or die $@;
1761             push @out, {
1762                 Hash => $1,
1763                 Bytes => $2,
1764                 Filename => $3,
1765                 Digester => $digester,
1766             };
1767         }
1768         return @out;
1769     }
1770     fail "missing any supported Checksums-* or Files field in ".
1771         $dsc->get_option('name');
1772 }
1773
1774 sub dsc_files () {
1775     map { $_->{Filename} } dsc_files_info();
1776 }
1777
1778 sub files_compare_inputs (@) {
1779     my $inputs = \@_;
1780     my %record;
1781     my %fchecked;
1782
1783     my $showinputs = sub {
1784         return join "; ", map { $_->get_option('name') } @$inputs;
1785     };
1786
1787     foreach my $in (@$inputs) {
1788         my $expected_files;
1789         my $in_name = $in->get_option('name');
1790
1791         printdebug "files_compare_inputs $in_name\n";
1792
1793         foreach my $csumi (@files_csum_info_fields) {
1794             my ($fname) = @$csumi;
1795             printdebug "files_compare_inputs $in_name $fname\n";
1796
1797             my $field = $in->{$fname};
1798             next unless defined $field;
1799
1800             my @files;
1801             foreach (split /\n/, $field) {
1802                 next unless m/\S/;
1803
1804                 my ($info, $f) = m/^(\w+ \d+) (?:\S+ \S+ )?(\S+)$/ or
1805                     fail "could not parse $in_name $fname line \`$_'";
1806
1807                 printdebug "files_compare_inputs $in_name $fname $f\n";
1808
1809                 push @files, $f;
1810
1811                 my $re = \ $record{$f}{$fname};
1812                 if (defined $$re) {
1813                     $fchecked{$f}{$in_name} = 1;
1814                     $$re eq $info or
1815                         fail "hash or size of $f varies in $fname fields".
1816                         " (between: ".$showinputs->().")";
1817                 } else {
1818                     $$re = $info;
1819                 }
1820             }
1821             @files = sort @files;
1822             $expected_files //= \@files;
1823             "@$expected_files" eq "@files" or
1824                 fail "file list in $in_name varies between hash fields!";
1825         }
1826         $expected_files or
1827             fail "$in_name has no files list field(s)";
1828     }
1829     printdebug "files_compare_inputs ".Dumper(\%fchecked, \%record)
1830         if $debuglevel>=2;
1831
1832     grep { keys %$_ == @$inputs-1 } values %fchecked
1833         or fail "no file appears in all file lists".
1834         " (looked in: ".$showinputs->().")";
1835 }
1836
1837 sub is_orig_file_in_dsc ($$) {
1838     my ($f, $dsc_files_info) = @_;
1839     return 0 if @$dsc_files_info <= 1;
1840     # One file means no origs, and the filename doesn't have a "what
1841     # part of dsc" component.  (Consider versions ending `.orig'.)
1842     return 0 unless $f =~ m/\.$orig_f_tail_re$/o;
1843     return 1;
1844 }
1845
1846 sub is_orig_file_of_vsn ($$) {
1847     my ($f, $upstreamvsn) = @_;
1848     my $base = srcfn $upstreamvsn, '';
1849     return 0 unless $f =~ m/^\Q$base\E\.$orig_f_tail_re$/;
1850     return 1;
1851 }
1852
1853 # This function determines whether a .changes file is source-only from
1854 # the point of view of dak.  Thus, it permits *_source.buildinfo
1855 # files.
1856 #
1857 # It does not, however, permit any other buildinfo files.  After a
1858 # source-only upload, the buildds will try to upload files like
1859 # foo_1.2.3_amd64.buildinfo.  If the package maintainer included files
1860 # named like this in their (otherwise) source-only upload, the uploads
1861 # of the buildd can be rejected by dak.  Fixing the resultant
1862 # situation can require manual intervention.  So we block such
1863 # .buildinfo files when the user tells us to perform a source-only
1864 # upload (such as when using the push-source subcommand with the -C
1865 # option, which calls this function).
1866 #
1867 # Note, though, that when dgit is told to prepare a source-only
1868 # upload, such as when subcommands like build-source and push-source
1869 # without -C are used, dgit has a more restrictive notion of
1870 # source-only .changes than dak: such uploads will never include
1871 # *_source.buildinfo files.  This is because there is no use for such
1872 # files when using a tool like dgit to produce the source package, as
1873 # dgit ensures the source is identical to git HEAD.
1874 sub test_source_only_changes ($) {
1875     my ($changes) = @_;
1876     foreach my $l (split /\n/, getfield $changes, 'Files') {
1877         $l =~ m/\S+$/ or next;
1878         # \.tar\.[a-z0-9]+ covers orig.tar and the tarballs in native packages
1879         unless ($& =~ m/(?:\.dsc|\.diff\.gz|\.tar\.[a-z0-9]+|_source\.buildinfo)$/) {
1880             print "purportedly source-only changes polluted by $&\n";
1881             return 0;
1882         }
1883     }
1884     return 1;
1885 }
1886
1887 sub changes_update_origs_from_dsc ($$$$) {
1888     my ($dsc, $changes, $upstreamvsn, $changesfile) = @_;
1889     my %changes_f;
1890     printdebug "checking origs needed ($upstreamvsn)...\n";
1891     $_ = getfield $changes, 'Files';
1892     m/^\w+ \d+ (\S+ \S+) \S+$/m or
1893         fail "cannot find section/priority from .changes Files field";
1894     my $placementinfo = $1;
1895     my %changed;
1896     printdebug "checking origs needed placement '$placementinfo'...\n";
1897     foreach my $l (split /\n/, getfield $dsc, 'Files') {
1898         $l =~ m/\S+$/ or next;
1899         my $file = $&;
1900         printdebug "origs $file | $l\n";
1901         next unless is_orig_file_of_vsn $file, $upstreamvsn;
1902         printdebug "origs $file is_orig\n";
1903         my $have = archive_query('file_in_archive', $file);
1904         if (!defined $have) {
1905             print STDERR <<END;
1906 archive does not support .orig check; hope you used --ch:--sa/-sd if needed
1907 END
1908             return;
1909         }
1910         my $found_same = 0;
1911         my @found_differ;
1912         printdebug "origs $file \$#\$have=$#$have\n";
1913         foreach my $h (@$have) {
1914             my $same = 0;
1915             my @differ;
1916             foreach my $csumi (@files_csum_info_fields) {
1917                 my ($fname, $module, $method, $archivefield) = @$csumi;
1918                 next unless defined $h->{$archivefield};
1919                 $_ = $dsc->{$fname};
1920                 next unless defined;
1921                 m/^(\w+) .* \Q$file\E$/m or
1922                     fail ".dsc $fname missing entry for $file";
1923                 if ($h->{$archivefield} eq $1) {
1924                     $same++;
1925                 } else {
1926                     push @differ,
1927  "$archivefield: $h->{$archivefield} (archive) != $1 (local .dsc)";
1928                 }
1929             }
1930             die "$file ".Dumper($h)." ?!" if $same && @differ;
1931             $found_same++
1932                 if $same;
1933             push @found_differ, "archive $h->{filename}: ".join "; ", @differ
1934                 if @differ;
1935         }
1936         printdebug "origs $file f.same=$found_same".
1937             " #f._differ=$#found_differ\n";
1938         if (@found_differ && !$found_same) {
1939             fail join "\n",
1940                 "archive contains $file with different checksum",
1941                 @found_differ;
1942         }
1943         # Now we edit the changes file to add or remove it
1944         foreach my $csumi (@files_csum_info_fields) {
1945             my ($fname, $module, $method, $archivefield) = @$csumi;
1946             next unless defined $changes->{$fname};
1947             if ($found_same) {
1948                 # in archive, delete from .changes if it's there
1949                 $changed{$file} = "removed" if
1950                     $changes->{$fname} =~ s/^.* \Q$file\E$(?:)\n//m;
1951             } elsif ($changes->{$fname} =~ m/^.* \Q$file\E$(?:)\n/m) {
1952                 # not in archive, but it's here in the .changes
1953             } else {
1954                 my $dsc_data = getfield $dsc, $fname;
1955                 $dsc_data =~ m/^(.* \Q$file\E$)\n/m or die "$dsc_data $file ?";
1956                 my $extra = $1;
1957                 $extra =~ s/ \d+ /$&$placementinfo /
1958                     or die "$fname $extra >$dsc_data< ?"
1959                     if $fname eq 'Files';
1960                 $changes->{$fname} .= "\n". $extra;
1961                 $changed{$file} = "added";
1962             }
1963         }
1964     }
1965     if (%changed) {
1966         foreach my $file (keys %changed) {
1967             progress sprintf
1968                 "edited .changes for archive .orig contents: %s %s",
1969                 $changed{$file}, $file;
1970         }
1971         my $chtmp = "$changesfile.tmp";
1972         $changes->save($chtmp);
1973         if (act_local()) {
1974             rename $chtmp,$changesfile or die "$changesfile $!";
1975         } else {
1976             progress "[new .changes left in $changesfile]";
1977         }
1978     } else {
1979         progress "$changesfile already has appropriate .orig(s) (if any)";
1980     }
1981 }
1982
1983 sub make_commit ($) {
1984     my ($file) = @_;
1985     return cmdoutput @git, qw(hash-object -w -t commit), $file;
1986 }
1987
1988 sub make_commit_text ($) {
1989     my ($text) = @_;
1990     my ($out, $in);
1991     my @cmd = (@git, qw(hash-object -w -t commit --stdin));
1992     debugcmd "|",@cmd;
1993     print Dumper($text) if $debuglevel > 1;
1994     my $child = open2($out, $in, @cmd) or die $!;
1995     my $h;
1996     eval {
1997         print $in $text or die $!;
1998         close $in or die $!;
1999         $h = <$out>;
2000         $h =~ m/^\w+$/ or die;
2001         $h = $&;
2002         printdebug "=> $h\n";
2003     };
2004     close $out;
2005     waitpid $child, 0 == $child or die "$child $!";
2006     $? and failedcmd @cmd;
2007     return $h;
2008 }
2009
2010 sub clogp_authline ($) {
2011     my ($clogp) = @_;
2012     my $author = getfield $clogp, 'Maintainer';
2013     if ($author =~ m/^[^"\@]+\,/) {
2014         # single entry Maintainer field with unquoted comma
2015         $author = ($& =~ y/,//rd).$'; # strip the comma
2016     }
2017     # git wants a single author; any remaining commas in $author
2018     # are by now preceded by @ (or ").  It seems safer to punt on
2019     # "..." for now rather than attempting to dequote or something.
2020     $author =~ s#,.*##ms unless $author =~ m/"/;
2021     my $date = cmdoutput qw(date), '+%s %z', qw(-d), getfield($clogp,'Date');
2022     my $authline = "$author $date";
2023     $authline =~ m/$git_authline_re/o or
2024         fail "unexpected commit author line format \`$authline'".
2025         " (was generated from changelog Maintainer field)";
2026     return ($1,$2,$3) if wantarray;
2027     return $authline;
2028 }
2029
2030 sub vendor_patches_distro ($$) {
2031     my ($checkdistro, $what) = @_;
2032     return unless defined $checkdistro;
2033
2034     my $series = "debian/patches/\L$checkdistro\E.series";
2035     printdebug "checking for vendor-specific $series ($what)\n";
2036
2037     if (!open SERIES, "<", $series) {
2038         die "$series $!" unless $!==ENOENT;
2039         return;
2040     }
2041     while (<SERIES>) {
2042         next unless m/\S/;
2043         next if m/^\s+\#/;
2044
2045         print STDERR <<END;
2046
2047 Unfortunately, this source package uses a feature of dpkg-source where
2048 the same source package unpacks to different source code on different
2049 distros.  dgit cannot safely operate on such packages on affected
2050 distros, because the meaning of source packages is not stable.
2051
2052 Please ask the distro/maintainer to remove the distro-specific series
2053 files and use a different technique (if necessary, uploading actually
2054 different packages, if different distros are supposed to have
2055 different code).
2056
2057 END
2058         fail "Found active distro-specific series file for".
2059             " $checkdistro ($what): $series, cannot continue";
2060     }
2061     die "$series $!" if SERIES->error;
2062     close SERIES;
2063 }
2064
2065 sub check_for_vendor_patches () {
2066     # This dpkg-source feature doesn't seem to be documented anywhere!
2067     # But it can be found in the changelog (reformatted):
2068
2069     #   commit  4fa01b70df1dc4458daee306cfa1f987b69da58c
2070     #   Author: Raphael Hertzog <hertzog@debian.org>
2071     #   Date: Sun  Oct  3  09:36:48  2010 +0200
2072
2073     #   dpkg-source: correctly create .pc/.quilt_series with alternate
2074     #   series files
2075     #
2076     #   If you have debian/patches/ubuntu.series and you were
2077     #   unpacking the source package on ubuntu, quilt was still
2078     #   directed to debian/patches/series instead of
2079     #   debian/patches/ubuntu.series.
2080     #
2081     #   debian/changelog                        |    3 +++
2082     #   scripts/Dpkg/Source/Package/V3/quilt.pm |    4 +++-
2083     #   2 files changed, 6 insertions(+), 1 deletion(-)
2084
2085     use Dpkg::Vendor;
2086     vendor_patches_distro($ENV{DEB_VENDOR}, "DEB_VENDOR");
2087     vendor_patches_distro(Dpkg::Vendor::get_current_vendor(),
2088                          "Dpkg::Vendor \`current vendor'");
2089     vendor_patches_distro(access_basedistro(),
2090                           "(base) distro being accessed");
2091     vendor_patches_distro(access_nomdistro(),
2092                           "(nominal) distro being accessed");
2093 }
2094
2095 sub generate_commits_from_dsc () {
2096     # See big comment in fetch_from_archive, below.
2097     # See also README.dsc-import.
2098     prep_ud();
2099     changedir $playground;
2100
2101     my @dfi = dsc_files_info();
2102     foreach my $fi (@dfi) {
2103         my $f = $fi->{Filename};
2104         die "$f ?" if $f =~ m#/|^\.|\.dsc$|\.tmp$#;
2105         my $upper_f = "$maindir/../$f";
2106
2107         printdebug "considering reusing $f: ";
2108
2109         if (link_ltarget "$upper_f,fetch", $f) {
2110             printdebug "linked (using ...,fetch).\n";
2111         } elsif ((printdebug "($!) "),
2112                  $! != ENOENT) {
2113             fail "accessing ../$f,fetch: $!";
2114         } elsif (link_ltarget $upper_f, $f) {
2115             printdebug "linked.\n";
2116         } elsif ((printdebug "($!) "),
2117                  $! != ENOENT) {
2118             fail "accessing ../$f: $!";
2119         } else {
2120             printdebug "absent.\n";
2121         }
2122
2123         my $refetched;
2124         complete_file_from_dsc('.', $fi, \$refetched)
2125             or next;
2126
2127         printdebug "considering saving $f: ";
2128
2129         if (link $f, $upper_f) {
2130             printdebug "linked.\n";
2131         } elsif ((printdebug "($!) "),
2132                  $! != EEXIST) {
2133             fail "saving ../$f: $!";
2134         } elsif (!$refetched) {
2135             printdebug "no need.\n";
2136         } elsif (link $f, "$upper_f,fetch") {
2137             printdebug "linked (using ...,fetch).\n";
2138         } elsif ((printdebug "($!) "),
2139                  $! != EEXIST) {
2140             fail "saving ../$f,fetch: $!";
2141         } else {
2142             printdebug "cannot.\n";
2143         }
2144     }
2145
2146     # We unpack and record the orig tarballs first, so that we only
2147     # need disk space for one private copy of the unpacked source.
2148     # But we can't make them into commits until we have the metadata
2149     # from the debian/changelog, so we record the tree objects now and
2150     # make them into commits later.
2151     my @tartrees;
2152     my $upstreamv = upstreamversion $dsc->{version};
2153     my $orig_f_base = srcfn $upstreamv, '';
2154
2155     foreach my $fi (@dfi) {
2156         # We actually import, and record as a commit, every tarball
2157         # (unless there is only one file, in which case there seems
2158         # little point.
2159
2160         my $f = $fi->{Filename};
2161         printdebug "import considering $f ";
2162         (printdebug "only one dfi\n"), next if @dfi == 1;
2163         (printdebug "not tar\n"), next unless $f =~ m/\.tar(\.\w+)?$/;
2164         (printdebug "signature\n"), next if $f =~ m/$orig_f_sig_re$/o;
2165         my $compr_ext = $1;
2166
2167         my ($orig_f_part) =
2168             $f =~ m/^\Q$orig_f_base\E\.([^._]+)?\.tar(?:\.\w+)?$/;
2169
2170         printdebug "Y ", (join ' ', map { $_//"(none)" }
2171                           $compr_ext, $orig_f_part
2172                          ), "\n";
2173
2174         my $input = new IO::File $f, '<' or die "$f $!";
2175         my $compr_pid;
2176         my @compr_cmd;
2177
2178         if (defined $compr_ext) {
2179             my $cname =
2180                 Dpkg::Compression::compression_guess_from_filename $f;
2181             fail "Dpkg::Compression cannot handle file $f in source package"
2182                 if defined $compr_ext && !defined $cname;
2183             my $compr_proc =
2184                 new Dpkg::Compression::Process compression => $cname;
2185             @compr_cmd = $compr_proc->get_uncompress_cmdline();
2186             my $compr_fh = new IO::Handle;
2187             my $compr_pid = open $compr_fh, "-|" // die $!;
2188             if (!$compr_pid) {
2189                 open STDIN, "<&", $input or die $!;
2190                 exec @compr_cmd;
2191                 die "dgit (child): exec $compr_cmd[0]: $!\n";
2192             }
2193             $input = $compr_fh;
2194         }
2195
2196         rmtree "_unpack-tar";
2197         mkdir "_unpack-tar" or die $!;
2198         my @tarcmd = qw(tar -x -f -
2199                         --no-same-owner --no-same-permissions
2200                         --no-acls --no-xattrs --no-selinux);
2201         my $tar_pid = fork // die $!;
2202         if (!$tar_pid) {
2203             chdir "_unpack-tar" or die $!;
2204             open STDIN, "<&", $input or die $!;
2205             exec @tarcmd;
2206             die "dgit (child): exec $tarcmd[0]: $!";
2207         }
2208         $!=0; (waitpid $tar_pid, 0) == $tar_pid or die $!;
2209         !$? or failedcmd @tarcmd;
2210
2211         close $input or
2212             (@compr_cmd ? ($?==SIGPIPE || failedcmd @compr_cmd)
2213              : die $!);
2214         # finally, we have the results in "tarball", but maybe
2215         # with the wrong permissions
2216
2217         runcmd qw(chmod -R +rwX _unpack-tar);
2218         changedir "_unpack-tar";
2219         remove_stray_gits($f);
2220         mktree_in_ud_here();
2221
2222         my ($tree) = git_add_write_tree();
2223         my $tentries = cmdoutput @git, qw(ls-tree -z), $tree;
2224         if ($tentries =~ m/^\d+ tree (\w+)\t[^\000]+\000$/s) {
2225             $tree = $1;
2226             printdebug "one subtree $1\n";
2227         } else {
2228             printdebug "multiple subtrees\n";
2229         }
2230         changedir "..";
2231         rmtree "_unpack-tar";
2232
2233         my $ent = [ $f, $tree ];
2234         push @tartrees, {
2235             Orig => !!$orig_f_part,
2236             Sort => (!$orig_f_part         ? 2 :
2237                      $orig_f_part =~ m/-/g ? 1 :
2238                                              0),
2239             F => $f,
2240             Tree => $tree,
2241         };
2242     }
2243
2244     @tartrees = sort {
2245         # put any without "_" first (spec is not clear whether files
2246         # are always in the usual order).  Tarballs without "_" are
2247         # the main orig or the debian tarball.
2248         $a->{Sort} <=> $b->{Sort} or
2249         $a->{F}    cmp $b->{F}
2250     } @tartrees;
2251
2252     my $any_orig = grep { $_->{Orig} } @tartrees;
2253
2254     my $dscfn = "$package.dsc";
2255
2256     my $treeimporthow = 'package';
2257
2258     open D, ">", $dscfn or die "$dscfn: $!";
2259     print D $dscdata or die "$dscfn: $!";
2260     close D or die "$dscfn: $!";
2261     my @cmd = qw(dpkg-source);
2262     push @cmd, '--no-check' if $dsc_checked;
2263     if (madformat $dsc->{format}) {
2264         push @cmd, '--skip-patches';
2265         $treeimporthow = 'unpatched';
2266     }
2267     push @cmd, qw(-x --), $dscfn;
2268     runcmd @cmd;
2269
2270     my ($tree,$dir) = mktree_in_ud_from_only_subdir("source package");
2271     if (madformat $dsc->{format}) {
2272         check_for_vendor_patches();
2273     }
2274
2275     my $dappliedtree;
2276     if (madformat $dsc->{format}) {
2277         my @pcmd = qw(dpkg-source --before-build .);
2278         runcmd shell_cmd 'exec >/dev/null', @pcmd;
2279         rmtree '.pc';
2280         $dappliedtree = git_add_write_tree();
2281     }
2282
2283     my @clogcmd = qw(dpkg-parsechangelog --format rfc822 --all);
2284     debugcmd "|",@clogcmd;
2285     open CLOGS, "-|", @clogcmd or die $!;
2286
2287     my $clogp;
2288     my $r1clogp;
2289
2290     printdebug "import clog search...\n";
2291
2292     for (;;) {
2293         my $stanzatext = do { local $/=""; <CLOGS>; };
2294         printdebug "import clogp ".Dumper($stanzatext) if $debuglevel>1;
2295         last if !defined $stanzatext;
2296
2297         my $desc = "package changelog, entry no.$.";
2298         open my $stanzafh, "<", \$stanzatext or die;
2299         my $thisstanza = parsecontrolfh $stanzafh, $desc, 1;
2300         $clogp //= $thisstanza;
2301
2302         printdebug "import clog $thisstanza->{version} $desc...\n";
2303
2304         last if !$any_orig; # we don't need $r1clogp
2305
2306         # We look for the first (most recent) changelog entry whose
2307         # version number is lower than the upstream version of this
2308         # package.  Then the last (least recent) previous changelog
2309         # entry is treated as the one which introduced this upstream
2310         # version and used for the synthetic commits for the upstream
2311         # tarballs.
2312
2313         # One might think that a more sophisticated algorithm would be
2314         # necessary.  But: we do not want to scan the whole changelog
2315         # file.  Stopping when we see an earlier version, which
2316         # necessarily then is an earlier upstream version, is the only
2317         # realistic way to do that.  Then, either the earliest
2318         # changelog entry we have seen so far is indeed the earliest
2319         # upload of this upstream version; or there are only changelog
2320         # entries relating to later upstream versions (which is not
2321         # possible unless the changelog and .dsc disagree about the
2322         # version).  Then it remains to choose between the physically
2323         # last entry in the file, and the one with the lowest version
2324         # number.  If these are not the same, we guess that the
2325         # versions were created in a non-monotic order rather than
2326         # that the changelog entries have been misordered.
2327
2328         printdebug "import clog $thisstanza->{version} vs $upstreamv...\n";
2329
2330         last if version_compare($thisstanza->{version}, $upstreamv) < 0;
2331         $r1clogp = $thisstanza;
2332
2333         printdebug "import clog $r1clogp->{version} becomes r1\n";
2334     }
2335     die $! if CLOGS->error;
2336     close CLOGS or $?==SIGPIPE or failedcmd @clogcmd;
2337
2338     $clogp or fail "package changelog has no entries!";
2339
2340     my $authline = clogp_authline $clogp;
2341     my $changes = getfield $clogp, 'Changes';
2342     $changes =~ s/^\n//; # Changes: \n
2343     my $cversion = getfield $clogp, 'Version';
2344
2345     if (@tartrees) {
2346         $r1clogp //= $clogp; # maybe there's only one entry;
2347         my $r1authline = clogp_authline $r1clogp;
2348         # Strictly, r1authline might now be wrong if it's going to be
2349         # unused because !$any_orig.  Whatever.
2350
2351         printdebug "import tartrees authline   $authline\n";
2352         printdebug "import tartrees r1authline $r1authline\n";
2353
2354         foreach my $tt (@tartrees) {
2355             printdebug "import tartree $tt->{F} $tt->{Tree}\n";
2356
2357             $tt->{Commit} = make_commit_text($tt->{Orig} ? <<END_O : <<END_T);
2358 tree $tt->{Tree}
2359 author $r1authline
2360 committer $r1authline
2361
2362 Import $tt->{F}
2363
2364 [dgit import orig $tt->{F}]
2365 END_O
2366 tree $tt->{Tree}
2367 author $authline
2368 committer $authline
2369
2370 Import $tt->{F}
2371
2372 [dgit import tarball $package $cversion $tt->{F}]
2373 END_T
2374         }
2375     }
2376
2377     printdebug "import main commit\n";
2378
2379     open C, ">../commit.tmp" or die $!;
2380     print C <<END or die $!;
2381 tree $tree
2382 END
2383     print C <<END or die $! foreach @tartrees;
2384 parent $_->{Commit}
2385 END
2386     print C <<END or die $!;
2387 author $authline
2388 committer $authline
2389
2390 $changes
2391
2392 [dgit import $treeimporthow $package $cversion]
2393 END
2394
2395     close C or die $!;
2396     my $rawimport_hash = make_commit qw(../commit.tmp);
2397
2398     if (madformat $dsc->{format}) {
2399         printdebug "import apply patches...\n";
2400
2401         # regularise the state of the working tree so that
2402         # the checkout of $rawimport_hash works nicely.
2403         my $dappliedcommit = make_commit_text(<<END);
2404 tree $dappliedtree
2405 author $authline
2406 committer $authline
2407
2408 [dgit dummy commit]
2409 END
2410         runcmd @git, qw(checkout -q -b dapplied), $dappliedcommit;
2411
2412         runcmd @git, qw(checkout -q -b unpa), $rawimport_hash;
2413
2414         # We need the answers to be reproducible
2415         my @authline = clogp_authline($clogp);
2416         local $ENV{GIT_COMMITTER_NAME} =  $authline[0];
2417         local $ENV{GIT_COMMITTER_EMAIL} = $authline[1];
2418         local $ENV{GIT_COMMITTER_DATE} =  $authline[2];
2419         local $ENV{GIT_AUTHOR_NAME} =  $authline[0];
2420         local $ENV{GIT_AUTHOR_EMAIL} = $authline[1];
2421         local $ENV{GIT_AUTHOR_DATE} =  $authline[2];
2422
2423         my $path = $ENV{PATH} or die;
2424
2425         # we use ../../gbp-pq-output, which (given that we are in
2426         # $playground/PLAYTREE, and $playground is .git/dgit/unpack,
2427         # is .git/dgit.
2428
2429         foreach my $use_absurd (qw(0 1)) {
2430             runcmd @git, qw(checkout -q unpa);
2431             runcmd @git, qw(update-ref -d refs/heads/patch-queue/unpa);
2432             local $ENV{PATH} = $path;
2433             if ($use_absurd) {
2434                 chomp $@;
2435                 progress "warning: $@";
2436                 $path = "$absurdity:$path";
2437                 progress "$us: trying slow absurd-git-apply...";
2438                 rename "../../gbp-pq-output","../../gbp-pq-output.0"
2439                     or $!==ENOENT
2440                     or die $!;
2441             }
2442             eval {
2443                 die "forbid absurd git-apply\n" if $use_absurd
2444                     && forceing [qw(import-gitapply-no-absurd)];
2445                 die "only absurd git-apply!\n" if !$use_absurd
2446                     && forceing [qw(import-gitapply-absurd)];
2447
2448                 local $ENV{DGIT_ABSURD_DEBUG} = $debuglevel if $use_absurd;
2449                 local $ENV{PATH} = $path                    if $use_absurd;
2450
2451                 my @showcmd = (gbp_pq, qw(import));
2452                 my @realcmd = shell_cmd
2453                     'exec >/dev/null 2>>../../gbp-pq-output', @showcmd;
2454                 debugcmd "+",@realcmd;
2455                 if (system @realcmd) {
2456                     die +(shellquote @showcmd).
2457                         " failed: ".
2458                         failedcmd_waitstatus()."\n";
2459                 }
2460
2461                 my $gapplied = git_rev_parse('HEAD');
2462                 my $gappliedtree = cmdoutput @git, qw(rev-parse HEAD:);
2463                 $gappliedtree eq $dappliedtree or
2464                     fail <<END;
2465 gbp-pq import and dpkg-source disagree!
2466  gbp-pq import gave commit $gapplied
2467  gbp-pq import gave tree $gappliedtree
2468  dpkg-source --before-build gave tree $dappliedtree
2469 END
2470                 $rawimport_hash = $gapplied;
2471             };
2472             last unless $@;
2473         }
2474         if ($@) {
2475             { local $@; eval { runcmd qw(cat ../../gbp-pq-output); }; }
2476             die $@;
2477         }
2478     }
2479
2480     progress "synthesised git commit from .dsc $cversion";
2481
2482     my $rawimport_mergeinput = {
2483         Commit => $rawimport_hash,
2484         Info => "Import of source package",
2485     };
2486     my @output = ($rawimport_mergeinput);
2487
2488     if ($lastpush_mergeinput) {
2489         my $oldclogp = mergeinfo_getclogp($lastpush_mergeinput);
2490         my $oversion = getfield $oldclogp, 'Version';
2491         my $vcmp =
2492             version_compare($oversion, $cversion);
2493         if ($vcmp < 0) {
2494             @output = ($rawimport_mergeinput, $lastpush_mergeinput,
2495                 { Message => <<END, ReverseParents => 1 });
2496 Record $package ($cversion) in archive suite $csuite
2497 END
2498         } elsif ($vcmp > 0) {
2499             print STDERR <<END or die $!;
2500
2501 Version actually in archive:   $cversion (older)
2502 Last version pushed with dgit: $oversion (newer or same)
2503 $later_warning_msg
2504 END
2505             @output = $lastpush_mergeinput;
2506         } else {
2507             # Same version.  Use what's in the server git branch,
2508             # discarding our own import.  (This could happen if the
2509             # server automatically imports all packages into git.)
2510             @output = $lastpush_mergeinput;
2511         }
2512     }
2513     changedir $maindir;
2514     rmtree $playground;
2515     return @output;
2516 }
2517
2518 sub complete_file_from_dsc ($$;$) {
2519     our ($dstdir, $fi, $refetched) = @_;
2520     # Ensures that we have, in $dstdir, the file $fi, with the correct
2521     # contents.  (Downloading it from alongside $dscurl if necessary.)
2522     # If $refetched is defined, can overwrite "$dstdir/$fi->{Filename}"
2523     # and will set $$refetched=1 if it did so (or tried to).
2524
2525     my $f = $fi->{Filename};
2526     my $tf = "$dstdir/$f";
2527     my $downloaded = 0;
2528
2529     my $got;
2530     my $checkhash = sub {
2531         open F, "<", "$tf" or die "$tf: $!";
2532         $fi->{Digester}->reset();
2533         $fi->{Digester}->addfile(*F);
2534         F->error and die $!;
2535         $got = $fi->{Digester}->hexdigest();
2536         return $got eq $fi->{Hash};
2537     };
2538
2539     if (stat_exists $tf) {
2540         if ($checkhash->()) {
2541             progress "using existing $f";
2542             return 1;
2543         }
2544         if (!$refetched) {
2545             fail "file $f has hash $got but .dsc".
2546                 " demands hash $fi->{Hash} ".
2547                 "(perhaps you should delete this file?)";
2548         }
2549         progress "need to fetch correct version of $f";
2550         unlink $tf or die "$tf $!";
2551         $$refetched = 1;
2552     } else {
2553         printdebug "$tf does not exist, need to fetch\n";
2554     }
2555
2556     my $furl = $dscurl;
2557     $furl =~ s{/[^/]+$}{};
2558     $furl .= "/$f";
2559     die "$f ?" unless $f =~ m/^\Q${package}\E_/;
2560     die "$f ?" if $f =~ m#/#;
2561     runcmd_ordryrun_local @curl,qw(-f -o),$tf,'--',"$furl";
2562     return 0 if !act_local();
2563
2564     $checkhash->() or
2565         fail "file $f has hash $got but .dsc".
2566             " demands hash $fi->{Hash} ".
2567             "(got wrong file from archive!)";
2568
2569     return 1;
2570 }
2571
2572 sub ensure_we_have_orig () {
2573     my @dfi = dsc_files_info();
2574     foreach my $fi (@dfi) {
2575         my $f = $fi->{Filename};
2576         next unless is_orig_file_in_dsc($f, \@dfi);
2577         complete_file_from_dsc('..', $fi)
2578             or next;
2579     }
2580 }
2581
2582 #---------- git fetch ----------
2583
2584 sub lrfetchrefs () { return "refs/dgit-fetch/".access_basedistro(); }
2585 sub lrfetchref () { return lrfetchrefs.'/'.server_branch($csuite); }
2586
2587 # We fetch some parts of lrfetchrefs/*.  Ideally we delete these
2588 # locally fetched refs because they have unhelpful names and clutter
2589 # up gitk etc.  So we track whether we have "used up" head ref (ie,
2590 # whether we have made another local ref which refers to this object).
2591 #
2592 # (If we deleted them unconditionally, then we might end up
2593 # re-fetching the same git objects each time dgit fetch was run.)
2594 #
2595 # So, each use of lrfetchrefs needs to be accompanied by arrangements
2596 # in git_fetch_us to fetch the refs in question, and possibly a call
2597 # to lrfetchref_used.
2598
2599 our (%lrfetchrefs_f, %lrfetchrefs_d);
2600 # $lrfetchrefs_X{lrfetchrefs."/heads/whatever"} = $objid
2601
2602 sub lrfetchref_used ($) {
2603     my ($fullrefname) = @_;
2604     my $objid = $lrfetchrefs_f{$fullrefname};
2605     $lrfetchrefs_d{$fullrefname} = $objid if defined $objid;
2606 }
2607
2608 sub git_lrfetch_sane {
2609     my ($url, $supplementary, @specs) = @_;
2610     # Make a 'refs/'.lrfetchrefs.'/*' be just like on server,
2611     # at least as regards @specs.  Also leave the results in
2612     # %lrfetchrefs_f, and arrange for lrfetchref_used to be
2613     # able to clean these up.
2614     #
2615     # With $supplementary==1, @specs must not contain wildcards
2616     # and we add to our previous fetches (non-atomically).
2617
2618     # This is rather miserable:
2619     # When git fetch --prune is passed a fetchspec ending with a *,
2620     # it does a plausible thing.  If there is no * then:
2621     # - it matches subpaths too, even if the supplied refspec
2622     #   starts refs, and behaves completely madly if the source
2623     #   has refs/refs/something.  (See, for example, Debian #NNNN.)
2624     # - if there is no matching remote ref, it bombs out the whole
2625     #   fetch.
2626     # We want to fetch a fixed ref, and we don't know in advance
2627     # if it exists, so this is not suitable.
2628     #
2629     # Our workaround is to use git ls-remote.  git ls-remote has its
2630     # own qairks.  Notably, it has the absurd multi-tail-matching
2631     # behaviour: git ls-remote R refs/foo can report refs/foo AND
2632     # refs/refs/foo etc.
2633     #
2634     # Also, we want an idempotent snapshot, but we have to make two
2635     # calls to the remote: one to git ls-remote and to git fetch.  The
2636     # solution is use git ls-remote to obtain a target state, and
2637     # git fetch to try to generate it.  If we don't manage to generate
2638     # the target state, we try again.
2639
2640     printdebug "git_lrfetch_sane suppl=$supplementary specs @specs\n";
2641
2642     my $specre = join '|', map {
2643         my $x = $_;
2644         $x =~ s/\W/\\$&/g;
2645         my $wildcard = $x =~ s/\\\*$/.*/;
2646         die if $wildcard && $supplementary;
2647         "(?:refs/$x)";
2648     } @specs;
2649     printdebug "git_lrfetch_sane specre=$specre\n";
2650     my $wanted_rref = sub {
2651         local ($_) = @_;
2652         return m/^(?:$specre)$/;
2653     };
2654
2655     my $fetch_iteration = 0;
2656     FETCH_ITERATION:
2657     for (;;) {
2658         printdebug "git_lrfetch_sane iteration $fetch_iteration\n";
2659         if (++$fetch_iteration > 10) {
2660             fail "too many iterations trying to get sane fetch!";
2661         }
2662
2663         my @look = map { "refs/$_" } @specs;
2664         my @lcmd = (@git, qw(ls-remote -q --refs), $url, @look);
2665         debugcmd "|",@lcmd;
2666
2667         my %wantr;
2668         open GITLS, "-|", @lcmd or die $!;
2669         while (<GITLS>) {
2670             printdebug "=> ", $_;
2671             m/^(\w+)\s+(\S+)\n/ or die "ls-remote $_ ?";
2672             my ($objid,$rrefname) = ($1,$2);
2673             if (!$wanted_rref->($rrefname)) {
2674                 print STDERR <<END;
2675 warning: git ls-remote @look reported $rrefname; this is silly, ignoring it.
2676 END
2677                 next;
2678             }
2679             $wantr{$rrefname} = $objid;
2680         }
2681         $!=0; $?=0;
2682         close GITLS or failedcmd @lcmd;
2683
2684         # OK, now %want is exactly what we want for refs in @specs
2685         my @fspecs = map {
2686             !m/\*$/ && !exists $wantr{"refs/$_"} ? () :
2687             "+refs/$_:".lrfetchrefs."/$_";
2688         } @specs;
2689
2690         printdebug "git_lrfetch_sane fspecs @fspecs\n";
2691
2692         my @fcmd = (@git, qw(fetch -p -n -q), $url, @fspecs);
2693         runcmd_ordryrun_local @fcmd if @fspecs;
2694
2695         if (!$supplementary) {
2696             %lrfetchrefs_f = ();
2697         }
2698         my %objgot;
2699
2700         git_for_each_ref(lrfetchrefs, sub {
2701             my ($objid,$objtype,$lrefname,$reftail) = @_;
2702             $lrfetchrefs_f{$lrefname} = $objid;
2703             $objgot{$objid} = 1;
2704         });
2705
2706         if ($supplementary) {
2707             last;
2708         }
2709
2710         foreach my $lrefname (sort keys %lrfetchrefs_f) {
2711             my $rrefname = 'refs'.substr($lrefname, length lrfetchrefs);
2712             if (!exists $wantr{$rrefname}) {
2713                 if ($wanted_rref->($rrefname)) {
2714                     printdebug <<END;
2715 git-fetch @fspecs created $lrefname which git ls-remote @look didn't list.
2716 END
2717                 } else {
2718                     print STDERR <<END
2719 warning: git fetch @fspecs created $lrefname; this is silly, deleting it.
2720 END
2721                 }
2722                 runcmd_ordryrun_local @git, qw(update-ref -d), $lrefname;
2723                 delete $lrfetchrefs_f{$lrefname};
2724                 next;
2725             }
2726         }
2727         foreach my $rrefname (sort keys %wantr) {
2728             my $lrefname = lrfetchrefs.substr($rrefname, 4);
2729             my $got = $lrfetchrefs_f{$lrefname} // '<none>';
2730             my $want = $wantr{$rrefname};
2731             next if $got eq $want;
2732             if (!defined $objgot{$want}) {
2733                 print STDERR <<END;
2734 warning: git ls-remote suggests we want $lrefname
2735 warning:  and it should refer to $want
2736 warning:  but git fetch didn't fetch that object to any relevant ref.
2737 warning:  This may be due to a race with someone updating the server.
2738 warning:  Will try again...
2739 END
2740                 next FETCH_ITERATION;
2741             }
2742             printdebug <<END;
2743 git-fetch @fspecs made $lrefname=$got but want git ls-remote @look says $want
2744 END
2745             runcmd_ordryrun_local @git, qw(update-ref -m),
2746                 "dgit fetch git fetch fixup", $lrefname, $want;
2747             $lrfetchrefs_f{$lrefname} = $want;
2748         }
2749         last;
2750     }
2751
2752     if (defined $csuite) {
2753         printdebug "git_lrfetch_sane: tidying any old suite lrfetchrefs\n";
2754         git_for_each_ref("refs/dgit-fetch/$csuite", sub {
2755             my ($objid,$objtype,$lrefname,$reftail) = @_;
2756             next if $lrfetchrefs_f{$lrefname}; # $csuite eq $distro ?
2757             runcmd_ordryrun_local @git, qw(update-ref -d), $lrefname;
2758         });
2759     }
2760
2761     printdebug "git_lrfetch_sane: git fetch --no-insane emulation complete\n",
2762         Dumper(\%lrfetchrefs_f);
2763 }
2764
2765 sub git_fetch_us () {
2766     # Want to fetch only what we are going to use, unless
2767     # deliberately-not-ff, in which case we must fetch everything.
2768
2769     my @specs = deliberately_not_fast_forward ? qw(tags/*) :
2770         map { "tags/$_" }
2771         (quiltmode_splitbrain
2772          ? (map { $_->('*',access_nomdistro) }
2773             \&debiantag_new, \&debiantag_maintview)
2774          : debiantags('*',access_nomdistro));
2775     push @specs, server_branch($csuite);
2776     push @specs, $rewritemap;
2777     push @specs, qw(heads/*) if deliberately_not_fast_forward;
2778
2779     my $url = access_giturl();
2780     git_lrfetch_sane $url, 0, @specs;
2781
2782     my %here;
2783     my @tagpats = debiantags('*',access_nomdistro);
2784
2785     git_for_each_ref([map { "refs/tags/$_" } @tagpats], sub {
2786         my ($objid,$objtype,$fullrefname,$reftail) = @_;
2787         printdebug "currently $fullrefname=$objid\n";
2788         $here{$fullrefname} = $objid;
2789     });
2790     git_for_each_ref([map { lrfetchrefs."/tags/".$_ } @tagpats], sub {
2791         my ($objid,$objtype,$fullrefname,$reftail) = @_;
2792         my $lref = "refs".substr($fullrefname, length(lrfetchrefs));
2793         printdebug "offered $lref=$objid\n";
2794         if (!defined $here{$lref}) {
2795             my @upd = (@git, qw(update-ref), $lref, $objid, '');
2796             runcmd_ordryrun_local @upd;
2797             lrfetchref_used $fullrefname;
2798         } elsif ($here{$lref} eq $objid) {
2799             lrfetchref_used $fullrefname;
2800         } else {
2801             print STDERR
2802                 "Not updating $lref from $here{$lref} to $objid.\n";
2803         }
2804     });
2805 }
2806
2807 #---------- dsc and archive handling ----------
2808
2809 sub mergeinfo_getclogp ($) {
2810     # Ensures thit $mi->{Clogp} exists and returns it
2811     my ($mi) = @_;
2812     $mi->{Clogp} = commit_getclogp($mi->{Commit});
2813 }
2814
2815 sub mergeinfo_version ($) {
2816     return getfield( (mergeinfo_getclogp $_[0]), 'Version' );
2817 }
2818
2819 sub fetch_from_archive_record_1 ($) {
2820     my ($hash) = @_;
2821     runcmd @git, qw(update-ref -m), "dgit fetch $csuite",
2822             'DGIT_ARCHIVE', $hash;
2823     cmdoutput @git, qw(log -n2), $hash;
2824     # ... gives git a chance to complain if our commit is malformed
2825 }
2826
2827 sub fetch_from_archive_record_2 ($) {
2828     my ($hash) = @_;
2829     my @upd_cmd = (@git, qw(update-ref -m), 'dgit fetch', lrref(), $hash);
2830     if (act_local()) {
2831         cmdoutput @upd_cmd;
2832     } else {
2833         dryrun_report @upd_cmd;
2834     }
2835 }
2836
2837 sub parse_dsc_field_def_dsc_distro () {
2838     $dsc_distro //= cfg qw(dgit.default.old-dsc-distro
2839                            dgit.default.distro);
2840 }
2841
2842 sub parse_dsc_field ($$) {
2843     my ($dsc, $what) = @_;
2844     my $f;
2845     foreach my $field (@ourdscfield) {
2846         $f = $dsc->{$field};
2847         last if defined $f;
2848     }
2849
2850     if (!defined $f) {
2851         progress "$what: NO git hash";
2852         parse_dsc_field_def_dsc_distro();
2853     } elsif (($dsc_hash, $dsc_distro, $dsc_hint_tag, $dsc_hint_url)
2854              = $f =~ m/^(\w+)\s+($distro_re)\s+($versiontag_re)\s+(\S+)(?:\s|$)/) {
2855         progress "$what: specified git info ($dsc_distro)";
2856         $dsc_hint_tag = [ $dsc_hint_tag ];
2857     } elsif ($f =~ m/^\w+\s*$/) {
2858         $dsc_hash = $&;
2859         parse_dsc_field_def_dsc_distro();
2860         $dsc_hint_tag = [ debiantags +(getfield $dsc, 'Version'),
2861                           $dsc_distro ];
2862         progress "$what: specified git hash";
2863     } else {
2864         fail "$what: invalid Dgit info";
2865     }
2866 }
2867
2868 sub resolve_dsc_field_commit ($$) {
2869     my ($already_distro, $already_mapref) = @_;
2870
2871     return unless defined $dsc_hash;
2872
2873     my $mapref =
2874         defined $already_mapref &&
2875         ($already_distro eq $dsc_distro || !$chase_dsc_distro)
2876         ? $already_mapref : undef;
2877
2878     my $do_fetch;
2879     $do_fetch = sub {
2880         my ($what, @fetch) = @_;
2881
2882         local $idistro = $dsc_distro;
2883         my $lrf = lrfetchrefs;
2884
2885         if (!$chase_dsc_distro) {
2886             progress
2887                 "not chasing .dsc distro $dsc_distro: not fetching $what";
2888             return 0;
2889         }
2890
2891         progress
2892             ".dsc names distro $dsc_distro: fetching $what";
2893
2894         my $url = access_giturl();
2895         if (!defined $url) {
2896             defined $dsc_hint_url or fail <<END;
2897 .dsc Dgit metadata is in context of distro $dsc_distro
2898 for which we have no configured url and .dsc provides no hint
2899 END
2900             my $proto =
2901                 $dsc_hint_url =~ m#^([-+0-9a-zA-Z]+):# ? $1 :
2902                 $dsc_hint_url =~ m#^/# ? 'file' : 'bad-syntax';
2903             parse_cfg_bool "dsc-url-proto-ok", 'false',
2904                 cfg("dgit.dsc-url-proto-ok.$proto",
2905                     "dgit.default.dsc-url-proto-ok")
2906                 or fail <<END;
2907 .dsc Dgit metadata is in context of distro $dsc_distro
2908 for which we have no configured url;
2909 .dsc provides hinted url with protocol $proto which is unsafe.
2910 (can be overridden by config - consult documentation)
2911 END
2912             $url = $dsc_hint_url;
2913         }
2914
2915         git_lrfetch_sane $url, 1, @fetch;
2916
2917         return $lrf;
2918     };
2919
2920     my $rewrite_enable = do {
2921         local $idistro = $dsc_distro;
2922         access_cfg('rewrite-map-enable', 'RETURN-UNDEF');
2923     };
2924
2925     if (parse_cfg_bool 'rewrite-map-enable', 'true', $rewrite_enable) {
2926         if (!defined $mapref) {
2927             my $lrf = $do_fetch->("rewrite map", $rewritemap) or return;
2928             $mapref = $lrf.'/'.$rewritemap;
2929         }
2930         my $rewritemapdata = git_cat_file $mapref.':map';
2931         if (defined $rewritemapdata
2932             && $rewritemapdata =~ m/^$dsc_hash(?:[ \t](\w+))/m) {
2933             progress
2934                 "server's git history rewrite map contains a relevant entry!";
2935
2936             $dsc_hash = $1;
2937             if (defined $dsc_hash) {
2938                 progress "using rewritten git hash in place of .dsc value";
2939             } else {
2940                 progress "server data says .dsc hash is to be disregarded";
2941             }
2942         }
2943     }
2944
2945     if (!defined git_cat_file $dsc_hash) {
2946         my @tags = map { "tags/".$_ } @$dsc_hint_tag;
2947         my $lrf = $do_fetch->("additional commits", @tags) &&
2948             defined git_cat_file $dsc_hash
2949             or fail <<END;
2950 .dsc Dgit metadata requires commit $dsc_hash
2951 but we could not obtain that object anywhere.
2952 END
2953         foreach my $t (@tags) {
2954             my $fullrefname = $lrf.'/'.$t;
2955 #           print STDERR "CHK $t $fullrefname ".Dumper(\%lrfetchrefs_f);
2956             next unless $lrfetchrefs_f{$fullrefname};
2957             next unless is_fast_fwd "$fullrefname~0", $dsc_hash;
2958             lrfetchref_used $fullrefname;
2959         }
2960     }
2961 }
2962
2963 sub fetch_from_archive () {
2964     ensure_setup_existing_tree();
2965
2966     # Ensures that lrref() is what is actually in the archive, one way
2967     # or another, according to us - ie this client's
2968     # appropritaely-updated archive view.  Also returns the commit id.
2969     # If there is nothing in the archive, leaves lrref alone and
2970     # returns undef.  git_fetch_us must have already been called.
2971     get_archive_dsc();
2972
2973     if ($dsc) {
2974         parse_dsc_field($dsc, 'last upload to archive');
2975         resolve_dsc_field_commit access_basedistro,
2976             lrfetchrefs."/".$rewritemap
2977     } else {
2978         progress "no version available from the archive";
2979     }
2980
2981     # If the archive's .dsc has a Dgit field, there are three
2982     # relevant git commitids we need to choose between and/or merge
2983     # together:
2984     #   1. $dsc_hash: the Dgit field from the archive
2985     #   2. $lastpush_hash: the suite branch on the dgit git server
2986     #   3. $lastfetch_hash: our local tracking brach for the suite
2987     #
2988     # These may all be distinct and need not be in any fast forward
2989     # relationship:
2990     #
2991     # If the dsc was pushed to this suite, then the server suite
2992     # branch will have been updated; but it might have been pushed to
2993     # a different suite and copied by the archive.  Conversely a more
2994     # recent version may have been pushed with dgit but not appeared
2995     # in the archive (yet).
2996     #
2997     # $lastfetch_hash may be awkward because archive imports
2998     # (particularly, imports of Dgit-less .dscs) are performed only as
2999     # needed on individual clients, so different clients may perform a
3000     # different subset of them - and these imports are only made
3001     # public during push.  So $lastfetch_hash may represent a set of
3002     # imports different to a subsequent upload by a different dgit
3003     # client.
3004     #
3005     # Our approach is as follows:
3006     #
3007     # As between $dsc_hash and $lastpush_hash: if $lastpush_hash is a
3008     # descendant of $dsc_hash, then it was pushed by a dgit user who
3009     # had based their work on $dsc_hash, so we should prefer it.
3010     # Otherwise, $dsc_hash was installed into this suite in the
3011     # archive other than by a dgit push, and (necessarily) after the
3012     # last dgit push into that suite (since a dgit push would have
3013     # been descended from the dgit server git branch); thus, in that
3014     # case, we prefer the archive's version (and produce a
3015     # pseudo-merge to overwrite the dgit server git branch).
3016     #
3017     # (If there is no Dgit field in the archive's .dsc then
3018     # generate_commit_from_dsc uses the version numbers to decide
3019     # whether the suite branch or the archive is newer.  If the suite
3020     # branch is newer it ignores the archive's .dsc; otherwise it
3021     # generates an import of the .dsc, and produces a pseudo-merge to
3022     # overwrite the suite branch with the archive contents.)
3023     #
3024     # The outcome of that part of the algorithm is the `public view',
3025     # and is same for all dgit clients: it does not depend on any
3026     # unpublished history in the local tracking branch.
3027     #
3028     # As between the public view and the local tracking branch: The
3029     # local tracking branch is only updated by dgit fetch, and
3030     # whenever dgit fetch runs it includes the public view in the
3031     # local tracking branch.  Therefore if the public view is not
3032     # descended from the local tracking branch, the local tracking
3033     # branch must contain history which was imported from the archive
3034     # but never pushed; and, its tip is now out of date.  So, we make
3035     # a pseudo-merge to overwrite the old imports and stitch the old
3036     # history in.
3037     #
3038     # Finally: we do not necessarily reify the public view (as
3039     # described above).  This is so that we do not end up stacking two
3040     # pseudo-merges.  So what we actually do is figure out the inputs
3041     # to any public view pseudo-merge and put them in @mergeinputs.
3042
3043     my @mergeinputs;
3044     # $mergeinputs[]{Commit}
3045     # $mergeinputs[]{Info}
3046     # $mergeinputs[0] is the one whose tree we use
3047     # @mergeinputs is in the order we use in the actual commit)
3048     #
3049     # Also:
3050     # $mergeinputs[]{Message} is a commit message to use
3051     # $mergeinputs[]{ReverseParents} if def specifies that parent
3052     #                                list should be in opposite order
3053     # Such an entry has no Commit or Info.  It applies only when found
3054     # in the last entry.  (This ugliness is to support making
3055     # identical imports to previous dgit versions.)
3056
3057     my $lastpush_hash = git_get_ref(lrfetchref());
3058     printdebug "previous reference hash=$lastpush_hash\n";
3059     $lastpush_mergeinput = $lastpush_hash && {
3060         Commit => $lastpush_hash,
3061         Info => "dgit suite branch on dgit git server",
3062     };
3063
3064     my $lastfetch_hash = git_get_ref(lrref());
3065     printdebug "fetch_from_archive: lastfetch=$lastfetch_hash\n";
3066     my $lastfetch_mergeinput = $lastfetch_hash && {
3067         Commit => $lastfetch_hash,
3068         Info => "dgit client's archive history view",
3069     };
3070
3071     my $dsc_mergeinput = $dsc_hash && {
3072         Commit => $dsc_hash,
3073         Info => "Dgit field in .dsc from archive",
3074     };
3075
3076     my $cwd = getcwd();
3077     my $del_lrfetchrefs = sub {
3078         changedir $cwd;
3079         my $gur;
3080         printdebug "del_lrfetchrefs...\n";
3081         foreach my $fullrefname (sort keys %lrfetchrefs_d) {
3082             my $objid = $lrfetchrefs_d{$fullrefname};
3083             printdebug "del_lrfetchrefs: $objid $fullrefname\n";
3084             if (!$gur) {
3085                 $gur ||= new IO::Handle;
3086                 open $gur, "|-", qw(git update-ref --stdin) or die $!;
3087             }
3088             printf $gur "delete %s %s\n", $fullrefname, $objid;
3089         }
3090         if ($gur) {
3091             close $gur or failedcmd "git update-ref delete lrfetchrefs";
3092         }
3093     };
3094
3095     if (defined $dsc_hash) {
3096         ensure_we_have_orig();
3097         if (!$lastpush_hash || $dsc_hash eq $lastpush_hash) {
3098             @mergeinputs = $dsc_mergeinput
3099         } elsif (is_fast_fwd($dsc_hash,$lastpush_hash)) {
3100             print STDERR <<END or die $!;
3101
3102 Git commit in archive is behind the last version allegedly pushed/uploaded.
3103 Commit referred to by archive: $dsc_hash
3104 Last version pushed with dgit: $lastpush_hash
3105 $later_warning_msg
3106 END
3107             @mergeinputs = ($lastpush_mergeinput);
3108         } else {
3109             # Archive has .dsc which is not a descendant of the last dgit
3110             # push.  This can happen if the archive moves .dscs about.
3111             # Just follow its lead.
3112             if (is_fast_fwd($lastpush_hash,$dsc_hash)) {
3113                 progress "archive .dsc names newer git commit";
3114                 @mergeinputs = ($dsc_mergeinput);
3115             } else {
3116                 progress "archive .dsc names other git commit, fixing up";
3117                 @mergeinputs = ($dsc_mergeinput, $lastpush_mergeinput);
3118             }
3119         }
3120     } elsif ($dsc) {
3121         @mergeinputs = generate_commits_from_dsc();
3122         # We have just done an import.  Now, our import algorithm might
3123         # have been improved.  But even so we do not want to generate
3124         # a new different import of the same package.  So if the
3125         # version numbers are the same, just use our existing version.
3126         # If the version numbers are different, the archive has changed
3127         # (perhaps, rewound).
3128         if ($lastfetch_mergeinput &&
3129             !version_compare( (mergeinfo_version $lastfetch_mergeinput),
3130                               (mergeinfo_version $mergeinputs[0]) )) {
3131             @mergeinputs = ($lastfetch_mergeinput);
3132         }
3133     } elsif ($lastpush_hash) {
3134         # only in git, not in the archive yet
3135         @mergeinputs = ($lastpush_mergeinput);
3136         print STDERR <<END or die $!;
3137
3138 Package not found in the archive, but has allegedly been pushed using dgit.
3139 $later_warning_msg
3140 END
3141     } else {
3142         printdebug "nothing found!\n";
3143         if (defined $skew_warning_vsn) {
3144             print STDERR <<END or die $!;
3145
3146 Warning: relevant archive skew detected.
3147 Archive allegedly contains $skew_warning_vsn
3148 But we were not able to obtain any version from the archive or git.
3149
3150 END
3151         }
3152         unshift @end, $del_lrfetchrefs;
3153         return undef;
3154     }
3155
3156     if ($lastfetch_hash &&
3157         !grep {
3158             my $h = $_->{Commit};
3159             $h and is_fast_fwd($lastfetch_hash, $h);
3160             # If true, one of the existing parents of this commit
3161             # is a descendant of the $lastfetch_hash, so we'll
3162             # be ff from that automatically.
3163         } @mergeinputs
3164         ) {
3165         # Otherwise:
3166         push @mergeinputs, $lastfetch_mergeinput;
3167     }
3168
3169     printdebug "fetch mergeinfos:\n";
3170     foreach my $mi (@mergeinputs) {
3171         if ($mi->{Info}) {
3172             printdebug " commit $mi->{Commit} $mi->{Info}\n";
3173         } else {
3174             printdebug sprintf " ReverseParents=%d Message=%s",
3175                 $mi->{ReverseParents}, $mi->{Message};
3176         }
3177     }
3178
3179     my $compat_info= pop @mergeinputs
3180         if $mergeinputs[$#mergeinputs]{Message};
3181
3182     @mergeinputs = grep { defined $_->{Commit} } @mergeinputs;
3183
3184     my $hash;
3185     if (@mergeinputs > 1) {
3186         # here we go, then:
3187         my $tree_commit = $mergeinputs[0]{Commit};
3188
3189         my $tree = cmdoutput @git, qw(cat-file commit), $tree_commit;
3190         $tree =~ m/\n\n/;  $tree = $`;
3191         $tree =~ m/^tree (\w+)$/m or die "$dsc_hash tree ?";
3192         $tree = $1;
3193
3194         # We use the changelog author of the package in question the
3195         # author of this pseudo-merge.  This is (roughly) correct if
3196         # this commit is simply representing aa non-dgit upload.
3197         # (Roughly because it does not record sponsorship - but we
3198         # don't have sponsorship info because that's in the .changes,
3199         # which isn't in the archivw.)
3200         #
3201         # But, it might be that we are representing archive history
3202         # updates (including in-archive copies).  These are not really
3203         # the responsibility of the person who created the .dsc, but
3204         # there is no-one whose name we should better use.  (The
3205         # author of the .dsc-named commit is clearly worse.)
3206
3207         my $useclogp = mergeinfo_getclogp $mergeinputs[0];
3208         my $author = clogp_authline $useclogp;
3209         my $cversion = getfield $useclogp, 'Version';
3210
3211         my $mcf = dgit_privdir()."/mergecommit";
3212         open MC, ">", $mcf or die "$mcf $!";
3213         print MC <<END or die $!;
3214 tree $tree
3215 END
3216
3217         my @parents = grep { $_->{Commit} } @mergeinputs;
3218         @parents = reverse @parents if $compat_info->{ReverseParents};
3219         print MC <<END or die $! foreach @parents;
3220 parent $_->{Commit}
3221 END
3222
3223         print MC <<END or die $!;
3224 author $author
3225 committer $author
3226
3227 END
3228
3229         if (defined $compat_info->{Message}) {
3230             print MC $compat_info->{Message} or die $!;
3231         } else {
3232             print MC <<END or die $!;
3233 Record $package ($cversion) in archive suite $csuite
3234
3235 Record that
3236 END
3237             my $message_add_info = sub {
3238                 my ($mi) = (@_);
3239                 my $mversion = mergeinfo_version $mi;
3240                 printf MC "  %-20s %s\n", $mversion, $mi->{Info}
3241                     or die $!;
3242             };
3243
3244             $message_add_info->($mergeinputs[0]);
3245             print MC <<END or die $!;
3246 should be treated as descended from
3247 END
3248             $message_add_info->($_) foreach @mergeinputs[1..$#mergeinputs];
3249         }
3250
3251         close MC or die $!;
3252         $hash = make_commit $mcf;
3253     } else {
3254         $hash = $mergeinputs[0]{Commit};
3255     }
3256     printdebug "fetch hash=$hash\n";
3257
3258     my $chkff = sub {
3259         my ($lasth, $what) = @_;
3260         return unless $lasth;
3261         die "$lasth $hash $what ?" unless is_fast_fwd($lasth, $hash);
3262     };
3263
3264     $chkff->($lastpush_hash, 'dgit repo server tip (last push)')
3265         if $lastpush_hash;
3266     $chkff->($lastfetch_hash, 'local tracking tip (last fetch)');
3267
3268     fetch_from_archive_record_1($hash);
3269
3270     if (defined $skew_warning_vsn) {
3271         printdebug "SKEW CHECK WANT $skew_warning_vsn\n";
3272         my $gotclogp = commit_getclogp($hash);
3273         my $got_vsn = getfield $gotclogp, 'Version';
3274         printdebug "SKEW CHECK GOT $got_vsn\n";
3275         if (version_compare($got_vsn, $skew_warning_vsn) < 0) {
3276             print STDERR <<END or die $!;
3277
3278 Warning: archive skew detected.  Using the available version:
3279 Archive allegedly contains    $skew_warning_vsn
3280 We were able to obtain only   $got_vsn
3281
3282 END
3283         }
3284     }
3285
3286     if ($lastfetch_hash ne $hash) {
3287         fetch_from_archive_record_2($hash);
3288     }
3289
3290     lrfetchref_used lrfetchref();
3291
3292     check_gitattrs($hash, "fetched source tree");
3293
3294     unshift @end, $del_lrfetchrefs;
3295     return $hash;
3296 }
3297
3298 sub set_local_git_config ($$) {
3299     my ($k, $v) = @_;
3300     runcmd @git, qw(config), $k, $v;
3301 }
3302
3303 sub setup_mergechangelogs (;$) {
3304     my ($always) = @_;
3305     return unless $always || access_cfg_bool(1, 'setup-mergechangelogs');
3306
3307     my $driver = 'dpkg-mergechangelogs';
3308     my $cb = "merge.$driver";
3309     confess unless defined $maindir;
3310     my $attrs = "$maindir_gitcommon/info/attributes";
3311     ensuredir "$maindir_gitcommon/info";
3312
3313     open NATTRS, ">", "$attrs.new" or die "$attrs.new $!";
3314     if (!open ATTRS, "<", $attrs) {
3315         $!==ENOENT or die "$attrs: $!";
3316     } else {
3317         while (<ATTRS>) {
3318             chomp;
3319             next if m{^debian/changelog\s};
3320             print NATTRS $_, "\n" or die $!;
3321         }
3322         ATTRS->error and die $!;
3323         close ATTRS;
3324     }
3325     print NATTRS "debian/changelog merge=$driver\n" or die $!;
3326     close NATTRS;
3327
3328     set_local_git_config "$cb.name", 'debian/changelog merge driver';
3329     set_local_git_config "$cb.driver", 'dpkg-mergechangelogs -m %O %A %B %A';
3330
3331     rename "$attrs.new", "$attrs" or die "$attrs: $!";
3332 }
3333
3334 sub setup_useremail (;$) {
3335     my ($always) = @_;
3336     return unless $always || access_cfg_bool(1, 'setup-useremail');
3337
3338     my $setup = sub {
3339         my ($k, $envvar) = @_;
3340         my $v = access_cfg("user-$k", 'RETURN-UNDEF') // $ENV{$envvar};
3341         return unless defined $v;
3342         set_local_git_config "user.$k", $v;
3343     };
3344
3345     $setup->('email', 'DEBEMAIL');
3346     $setup->('name', 'DEBFULLNAME');
3347 }
3348
3349 sub ensure_setup_existing_tree () {
3350     my $k = "remote.$remotename.skipdefaultupdate";
3351     my $c = git_get_config $k;
3352     return if defined $c;
3353     set_local_git_config $k, 'true';
3354 }
3355
3356 sub open_main_gitattrs () {
3357     confess 'internal error no maindir' unless defined $maindir;
3358     my $gai = new IO::File "$maindir_gitcommon/info/attributes"
3359         or $!==ENOENT
3360         or die "open $maindir_gitcommon/info/attributes: $!";
3361     return $gai;
3362 }
3363
3364 sub is_gitattrs_setup () {
3365     my $gai = open_main_gitattrs();
3366     return 0 unless $gai;
3367     while (<$gai>) {
3368         return 1 if m{^\[attr\]dgit-defuse-attrs\s};
3369     }
3370     $gai->error and die $!;
3371     return 0;
3372 }
3373
3374 sub setup_gitattrs (;$) {
3375     my ($always) = @_;
3376     return unless $always || access_cfg_bool(1, 'setup-gitattributes');
3377
3378     if (is_gitattrs_setup()) {
3379         progress <<END;
3380 [attr]dgit-defuse-attrs already found in .git/info/attributes
3381  not doing further gitattributes setup
3382 END
3383         return;
3384     }
3385     my $af = "$maindir_gitcommon/info/attributes";
3386     ensuredir "$maindir_gitcommon/info";
3387     open GAO, "> $af.new" or die $!;
3388     print GAO <<END or die $!;
3389 *       dgit-defuse-attrs
3390 [attr]dgit-defuse-attrs $negate_harmful_gitattrs
3391 # ^ see GITATTRIBUTES in dgit(7) and dgit setup-new-tree in dgit(1)
3392 END
3393     my $gai = open_main_gitattrs();
3394     if ($gai) {
3395         while (<$gai>) {
3396             chomp;
3397             print GAO $_, "\n" or die $!;
3398         }
3399         $gai->error and die $!;
3400     }
3401     close GAO or die $!;
3402     rename "$af.new", "$af" or die "install $af: $!";
3403 }
3404
3405 sub setup_new_tree () {
3406     setup_mergechangelogs();
3407     setup_useremail();
3408     setup_gitattrs();
3409 }
3410
3411 sub check_gitattrs ($$) {
3412     my ($treeish, $what) = @_;
3413
3414     return if is_gitattrs_setup;
3415
3416     local $/="\0";
3417     my @cmd = (@git, qw(ls-tree -lrz --), "${treeish}:");
3418     debugcmd "|",@cmd;
3419     my $gafl = new IO::File;
3420     open $gafl, "-|", @cmd or die $!;
3421     while (<$gafl>) {
3422         chomp or die;
3423         s/^\d+\s+\w+\s+\w+\s+(\d+)\t// or die;
3424         next if $1 == 0;
3425         next unless m{(?:^|/)\.gitattributes$};
3426
3427         # oh dear, found one
3428         print STDERR <<END;
3429 dgit: warning: $what contains .gitattributes
3430 dgit: .gitattributes have not been defused.  Recommended: dgit setup-new-tree.
3431 END
3432         close $gafl;
3433         return;
3434     }
3435     # tree contains no .gitattributes files
3436     $?=0; $!=0; close $gafl or failedcmd @cmd;
3437 }
3438
3439
3440 sub multisuite_suite_child ($$$) {
3441     my ($tsuite, $merginputs, $fn) = @_;
3442     # in child, sets things up, calls $fn->(), and returns undef
3443     # in parent, returns canonical suite name for $tsuite
3444     my $canonsuitefh = IO::File::new_tmpfile;
3445     my $pid = fork // die $!;
3446     if (!$pid) {
3447         forkcheck_setup();
3448         $isuite = $tsuite;
3449         $us .= " [$isuite]";
3450         $debugprefix .= " ";
3451         progress "fetching $tsuite...";
3452         canonicalise_suite();
3453         print $canonsuitefh $csuite, "\n" or die $!;
3454         close $canonsuitefh or die $!;
3455         $fn->();
3456         return undef;
3457     }
3458     waitpid $pid,0 == $pid or die $!;
3459     fail "failed to obtain $tsuite: ".waitstatusmsg() if $? && $?!=256*4;
3460     seek $canonsuitefh,0,0 or die $!;
3461     local $csuite = <$canonsuitefh>;
3462     die $! unless defined $csuite && chomp $csuite;
3463     if ($? == 256*4) {
3464         printdebug "multisuite $tsuite missing\n";
3465         return $csuite;
3466     }
3467     printdebug "multisuite $tsuite ok (canon=$csuite)\n";
3468     push @$merginputs, {
3469         Ref => lrref,
3470         Info => $csuite,
3471     };
3472     return $csuite;
3473 }
3474
3475 sub fork_for_multisuite ($) {
3476     my ($before_fetch_merge) = @_;
3477     # if nothing unusual, just returns ''
3478     #
3479     # if multisuite:
3480     # returns 0 to caller in child, to do first of the specified suites
3481     # in child, $csuite is not yet set
3482     #
3483     # returns 1 to caller in parent, to finish up anything needed after
3484     # in parent, $csuite is set to canonicalised portmanteau
3485
3486     my $org_isuite = $isuite;
3487     my @suites = split /\,/, $isuite;
3488     return '' unless @suites > 1;
3489     printdebug "fork_for_multisuite: @suites\n";
3490
3491     my @mergeinputs;
3492
3493     my $cbasesuite = multisuite_suite_child($suites[0], \@mergeinputs,
3494                                             sub { });
3495     return 0 unless defined $cbasesuite;
3496
3497     fail "package $package missing in (base suite) $cbasesuite"
3498         unless @mergeinputs;
3499
3500     my @csuites = ($cbasesuite);
3501
3502     $before_fetch_merge->();
3503
3504     foreach my $tsuite (@suites[1..$#suites]) {
3505         $tsuite =~ s/^-/$cbasesuite-/;
3506         my $csubsuite = multisuite_suite_child($tsuite, \@mergeinputs,
3507                                                sub {
3508             @end = ();
3509             fetch();
3510             exit 0;
3511         });
3512         # xxx collecte the ref here
3513
3514         $csubsuite =~ s/^\Q$cbasesuite\E-/-/;
3515         push @csuites, $csubsuite;
3516     }
3517
3518     foreach my $mi (@mergeinputs) {
3519         my $ref = git_get_ref $mi->{Ref};
3520         die "$mi->{Ref} ?" unless length $ref;
3521         $mi->{Commit} = $ref;
3522     }
3523
3524     $csuite = join ",", @csuites;
3525
3526     my $previous = git_get_ref lrref;
3527     if ($previous) {
3528         unshift @mergeinputs, {
3529             Commit => $previous,
3530             Info => "local combined tracking branch",
3531             Warning =>
3532  "archive seems to have rewound: local tracking branch is ahead!",
3533         };
3534     }
3535
3536     foreach my $ix (0..$#mergeinputs) {
3537         $mergeinputs[$ix]{Index} = $ix;
3538     }
3539
3540     @mergeinputs = sort {
3541         -version_compare(mergeinfo_version $a,
3542                          mergeinfo_version $b) # highest version first
3543             or
3544         $a->{Index} <=> $b->{Index}; # earliest in spec first
3545     } @mergeinputs;
3546
3547     my @needed;
3548
3549   NEEDED:
3550     foreach my $mi (@mergeinputs) {
3551         printdebug "multisuite merge check $mi->{Info}\n";
3552         foreach my $previous (@needed) {
3553             next unless is_fast_fwd $mi->{Commit}, $previous->{Commit};
3554             printdebug "multisuite merge un-needed $previous->{Info}\n";
3555             next NEEDED;
3556         }
3557         push @needed, $mi;
3558         printdebug "multisuite merge this-needed\n";
3559         $mi->{Character} = '+';
3560     }
3561
3562     $needed[0]{Character} = '*';
3563
3564     my $output = $needed[0]{Commit};
3565
3566     if (@needed > 1) {
3567         printdebug "multisuite merge nontrivial\n";
3568         my $tree = cmdoutput qw(git rev-parse), $needed[0]{Commit}.':';
3569
3570         my $commit = "tree $tree\n";
3571         my $msg = "Combine archive branches $csuite [dgit]\n\n".
3572             "Input branches:\n";
3573
3574         foreach my $mi (sort { $a->{Index} <=> $b->{Index} } @mergeinputs) {
3575             printdebug "multisuite merge include $mi->{Info}\n";
3576             $mi->{Character} //= ' ';
3577             $commit .= "parent $mi->{Commit}\n";
3578             $msg .= sprintf " %s  %-25s %s\n",
3579                 $mi->{Character},
3580                 (mergeinfo_version $mi),
3581                 $mi->{Info};
3582         }
3583         my $authline = clogp_authline mergeinfo_getclogp $needed[0];
3584         $msg .= "\nKey\n".
3585             " * marks the highest version branch, which choose to use\n".
3586             " + marks each branch which was not already an ancestor\n\n".
3587             "[dgit multi-suite $csuite]\n";
3588         $commit .=
3589             "author $authline\n".
3590             "committer $authline\n\n";
3591         $output = make_commit_text $commit.$msg;
3592         printdebug "multisuite merge generated $output\n";
3593     }
3594
3595     fetch_from_archive_record_1($output);
3596     fetch_from_archive_record_2($output);
3597
3598     progress "calculated combined tracking suite $csuite";
3599
3600     return 1;
3601 }
3602
3603 sub clone_set_head () {
3604     open H, "> .git/HEAD" or die $!;
3605     print H "ref: ".lref()."\n" or die $!;
3606     close H or die $!;
3607 }
3608 sub clone_finish ($) {
3609     my ($dstdir) = @_;
3610     runcmd @git, qw(reset --hard), lrref();
3611     runcmd qw(bash -ec), <<'END';
3612         set -o pipefail
3613         git ls-tree -r --name-only -z HEAD | \
3614         xargs -0r touch -h -r . --
3615 END
3616     printdone "ready for work in $dstdir";
3617 }
3618
3619 sub clone ($) {
3620     # in multisuite, returns twice!
3621     # once in parent after first suite fetched,
3622     # and then again in child after everything is finished
3623     my ($dstdir) = @_;
3624     badusage "dry run makes no sense with clone" unless act_local();
3625
3626     my $multi_fetched = fork_for_multisuite(sub {
3627         printdebug "multi clone before fetch merge\n";
3628         changedir $dstdir;
3629         record_maindir();
3630     });
3631     if ($multi_fetched) {
3632         printdebug "multi clone after fetch merge\n";
3633         clone_set_head();
3634         clone_finish($dstdir);
3635         return;
3636     }
3637     printdebug "clone main body\n";
3638
3639     canonicalise_suite();
3640     my $hasgit = check_for_git();
3641     mkdir $dstdir or fail "create \`$dstdir': $!";
3642     changedir $dstdir;
3643     runcmd @git, qw(init -q);
3644     record_maindir();
3645     setup_new_tree();
3646     clone_set_head();
3647     my $giturl = access_giturl(1);
3648     if (defined $giturl) {
3649         runcmd @git, qw(remote add), 'origin', $giturl;
3650     }
3651     if ($hasgit) {
3652         progress "fetching existing git history";
3653         git_fetch_us();
3654         runcmd_ordryrun_local @git, qw(fetch origin);
3655     } else {
3656         progress "starting new git history";
3657     }
3658     fetch_from_archive() or no_such_package;
3659     my $vcsgiturl = $dsc->{'Vcs-Git'};
3660     if (length $vcsgiturl) {
3661         $vcsgiturl =~ s/\s+-b\s+\S+//g;
3662         runcmd @git, qw(remote add vcs-git), $vcsgiturl;
3663     }
3664     clone_finish($dstdir);
3665 }
3666
3667 sub fetch () {
3668     canonicalise_suite();
3669     if (check_for_git()) {
3670         git_fetch_us();
3671     }
3672     fetch_from_archive() or no_such_package();
3673     printdone "fetched into ".lrref();
3674 }
3675
3676 sub pull () {
3677     my $multi_fetched = fork_for_multisuite(sub { });
3678     fetch() unless $multi_fetched; # parent
3679     return if $multi_fetched eq '0'; # child
3680     runcmd_ordryrun_local @git, qw(merge -m),"Merge from $csuite [dgit]",
3681         lrref();
3682     printdone "fetched to ".lrref()." and merged into HEAD";
3683 }
3684
3685 sub check_not_dirty () {
3686     foreach my $f (qw(local-options local-patch-header)) {
3687         if (stat_exists "debian/source/$f") {
3688             fail "git tree contains debian/source/$f";
3689         }
3690     }
3691
3692     return if $ignoredirty;
3693
3694     my @cmd = (@git, qw(diff --quiet HEAD));
3695     debugcmd "+",@cmd;
3696     $!=0; $?=-1; system @cmd;
3697     return if !$?;
3698     if ($?==256) {
3699         fail "working tree is dirty (does not match HEAD)";
3700     } else {
3701         failedcmd @cmd;
3702     }
3703 }
3704
3705 sub commit_admin ($) {
3706     my ($m) = @_;
3707     progress "$m";
3708     runcmd_ordryrun_local @git, qw(commit -m), $m;
3709 }
3710
3711 sub commit_quilty_patch () {
3712     my $output = cmdoutput @git, qw(status --porcelain);
3713     my %adds;
3714     foreach my $l (split /\n/, $output) {
3715         next unless $l =~ m/\S/;
3716         if ($l =~ m{^(?:\?\?| M) (.pc|debian/patches)}) {
3717             $adds{$1}++;
3718         }
3719     }
3720     delete $adds{'.pc'}; # if there wasn't one before, don't add it
3721     if (!%adds) {
3722         progress "nothing quilty to commit, ok.";
3723         return;
3724     }
3725     my @adds = map { s/[][*?\\]/\\$&/g; $_; } sort keys %adds;
3726     runcmd_ordryrun_local @git, qw(add -f), @adds;
3727     commit_admin <<END
3728 Commit Debian 3.0 (quilt) metadata
3729
3730 [dgit ($our_version) quilt-fixup]
3731 END
3732 }
3733
3734 sub get_source_format () {
3735     my %options;
3736     if (open F, "debian/source/options") {
3737         while (<F>) {
3738             next if m/^\s*\#/;
3739             next unless m/\S/;
3740             s/\s+$//; # ignore missing final newline
3741             if (m/\s*\#\s*/) {
3742                 my ($k, $v) = ($`, $'); #');
3743                 $v =~ s/^"(.*)"$/$1/;
3744                 $options{$k} = $v;
3745             } else {
3746                 $options{$_} = 1;
3747             }
3748         }
3749         F->error and die $!;
3750         close F;
3751     } else {
3752         die $! unless $!==&ENOENT;
3753     }
3754
3755     if (!open F, "debian/source/format") {
3756         die $! unless $!==&ENOENT;
3757         return '';
3758     }
3759     $_ = <F>;
3760     F->error and die $!;
3761     chomp;
3762     return ($_, \%options);
3763 }
3764
3765 sub madformat_wantfixup ($) {
3766     my ($format) = @_;
3767     return 0 unless $format eq '3.0 (quilt)';
3768     our $quilt_mode_warned;
3769     if ($quilt_mode eq 'nocheck') {
3770         progress "Not doing any fixup of \`$format' due to".
3771             " ----no-quilt-fixup or --quilt=nocheck"
3772             unless $quilt_mode_warned++;
3773         return 0;
3774     }
3775     progress "Format \`$format', need to check/update patch stack"
3776         unless $quilt_mode_warned++;
3777     return 1;
3778 }
3779
3780 sub maybe_split_brain_save ($$$) {
3781     my ($headref, $dgitview, $msg) = @_;
3782     # => message fragment "$saved" describing disposition of $dgitview
3783     return "commit id $dgitview" unless defined $split_brain_save;
3784     my @cmd = (shell_cmd 'cd "$1"; shift', $maindir,
3785                @git, qw(update-ref -m),
3786                "dgit --dgit-view-save $msg HEAD=$headref",
3787                $split_brain_save, $dgitview);
3788     runcmd @cmd;
3789     return "and left in $split_brain_save";
3790 }
3791
3792 # An "infopair" is a tuple [ $thing, $what ]
3793 # (often $thing is a commit hash; $what is a description)
3794
3795 sub infopair_cond_equal ($$) {
3796     my ($x,$y) = @_;
3797     $x->[0] eq $y->[0] or fail <<END;
3798 $x->[1] ($x->[0]) not equal to $y->[1] ($y->[0])
3799 END
3800 };
3801
3802 sub infopair_lrf_tag_lookup ($$) {
3803     my ($tagnames, $what) = @_;
3804     # $tagname may be an array ref
3805     my @tagnames = ref $tagnames ? @$tagnames : ($tagnames);
3806     printdebug "infopair_lrfetchref_tag_lookup $what @tagnames\n";
3807     foreach my $tagname (@tagnames) {
3808         my $lrefname = lrfetchrefs."/tags/$tagname";
3809         my $tagobj = $lrfetchrefs_f{$lrefname};
3810         next unless defined $tagobj;
3811         printdebug "infopair_lrfetchref_tag_lookup $tagobj $tagname $what\n";
3812         return [ git_rev_parse($tagobj), $what ];
3813     }
3814     fail @tagnames==1 ? <<END : <<END;
3815 Wanted tag $what (@tagnames) on dgit server, but not found
3816 END
3817 Wanted tag $what (one of: @tagnames) on dgit server, but not found
3818 END
3819 }
3820
3821 sub infopair_cond_ff ($$) {
3822     my ($anc,$desc) = @_;
3823     is_fast_fwd($anc->[0], $desc->[0]) or fail <<END;
3824 $anc->[1] ($anc->[0]) .. $desc->[1] ($desc->[0]) is not fast forward
3825 END
3826 };
3827
3828 sub pseudomerge_version_check ($$) {
3829     my ($clogp, $archive_hash) = @_;
3830
3831     my $arch_clogp = commit_getclogp $archive_hash;
3832     my $i_arch_v = [ (getfield $arch_clogp, 'Version'),
3833                      'version currently in archive' ];
3834     if (defined $overwrite_version) {
3835         if (length $overwrite_version) {
3836             infopair_cond_equal([ $overwrite_version,
3837                                   '--overwrite= version' ],
3838                                 $i_arch_v);
3839         } else {
3840             my $v = $i_arch_v->[0];
3841             progress "Checking package changelog for archive version $v ...";
3842             my $cd;
3843             eval {
3844                 my @xa = ("-f$v", "-t$v");
3845                 my $vclogp = parsechangelog @xa;
3846                 my $gf = sub {
3847                     my ($fn) = @_;
3848                     [ (getfield $vclogp, $fn),
3849                       "$fn field from dpkg-parsechangelog @xa" ];
3850                 };
3851                 my $cv = $gf->('Version');
3852                 infopair_cond_equal($i_arch_v, $cv);
3853                 $cd = $gf->('Distribution');
3854             };
3855             if ($@) {
3856                 $@ =~ s/^dgit: //gm;
3857                 fail "$@".
3858                     "Perhaps debian/changelog does not mention $v ?";
3859             }
3860             fail <<END if $cd->[0] =~ m/UNRELEASED/;
3861 $cd->[1] is $cd->[0]
3862 Your tree seems to based on earlier (not uploaded) $v.
3863 END
3864         }
3865     }
3866
3867     printdebug "pseudomerge_version_check i_arch_v @$i_arch_v\n";
3868     return $i_arch_v;
3869 }
3870
3871 sub pseudomerge_make_commit ($$$$ $$) {
3872     my ($clogp, $dgitview, $archive_hash, $i_arch_v,
3873         $msg_cmd, $msg_msg) = @_;
3874     progress "Declaring that HEAD inciudes all changes in $i_arch_v->[0]...";
3875
3876     my $tree = cmdoutput qw(git rev-parse), "${dgitview}:";
3877     my $authline = clogp_authline $clogp;
3878
3879     chomp $msg_msg;
3880     $msg_cmd .=
3881         !defined $overwrite_version ? ""
3882         : !length  $overwrite_version ? " --overwrite"
3883         : " --overwrite=".$overwrite_version;
3884
3885     my $pmf = dgit_privdir()."/pseudomerge";
3886     open MC, ">", $pmf or die "$pmf $!";
3887     print MC <<END or die $!;
3888 tree $tree
3889 parent $dgitview
3890 parent $archive_hash
3891 author $authline
3892 committer $authline
3893
3894 $msg_msg
3895
3896 [$msg_cmd]
3897 END
3898     close MC or die $!;
3899
3900     return make_commit($pmf);
3901 }
3902
3903 sub splitbrain_pseudomerge ($$$$) {
3904     my ($clogp, $maintview, $dgitview, $archive_hash) = @_;
3905     # => $merged_dgitview
3906     printdebug "splitbrain_pseudomerge...\n";
3907     #
3908     #     We:      debian/PREVIOUS    HEAD($maintview)
3909     # expect:          o ----------------- o
3910     #                    \                   \
3911     #                     o                   o
3912     #                 a/d/PREVIOUS        $dgitview
3913     #                $archive_hash              \
3914     #  If so,                \                   \
3915     #  we do:                 `------------------ o
3916     #   this:                                   $dgitview'
3917     #
3918
3919     return $dgitview unless defined $archive_hash;
3920     return $dgitview if deliberately_not_fast_forward();
3921
3922     printdebug "splitbrain_pseudomerge...\n";
3923
3924     my $i_arch_v = pseudomerge_version_check($clogp, $archive_hash);
3925
3926     if (!defined $overwrite_version) {
3927         progress "Checking that HEAD inciudes all changes in archive...";
3928     }
3929
3930     return $dgitview if is_fast_fwd $archive_hash, $dgitview;
3931
3932     if (defined $overwrite_version) {
3933     } elsif (!eval {
3934         my $t_dep14 = debiantag_maintview $i_arch_v->[0], access_nomdistro;
3935         my $i_dep14 = infopair_lrf_tag_lookup($t_dep14, "maintainer view tag");
3936         my $t_dgit = debiantag_new $i_arch_v->[0], access_nomdistro;
3937         my $i_dgit = infopair_lrf_tag_lookup($t_dgit, "dgit view tag");
3938         my $i_archive = [ $archive_hash, "current archive contents" ];
3939
3940         printdebug "splitbrain_pseudomerge i_archive @$i_archive\n";
3941
3942         infopair_cond_equal($i_dgit, $i_archive);
3943         infopair_cond_ff($i_dep14, $i_dgit);
3944         infopair_cond_ff($i_dep14, [ $maintview, 'HEAD' ]);
3945         1;
3946     }) {
3947         print STDERR <<END;
3948 $us: check failed (maybe --overwrite is needed, consult documentation)
3949 END
3950         die "$@";
3951     }
3952
3953     my $r = pseudomerge_make_commit
3954         $clogp, $dgitview, $archive_hash, $i_arch_v,
3955         "dgit --quilt=$quilt_mode",
3956         (defined $overwrite_version ? <<END_OVERWR : <<END_MAKEFF);
3957 Declare fast forward from $i_arch_v->[0]
3958 END_OVERWR
3959 Make fast forward from $i_arch_v->[0]
3960 END_MAKEFF
3961
3962     maybe_split_brain_save $maintview, $r, "pseudomerge";
3963
3964     progress "Made pseudo-merge of $i_arch_v->[0] into dgit view.";
3965     return $r;
3966 }
3967
3968 sub plain_overwrite_pseudomerge ($$$) {
3969     my ($clogp, $head, $archive_hash) = @_;
3970
3971     printdebug "plain_overwrite_pseudomerge...";
3972
3973     my $i_arch_v = pseudomerge_version_check($clogp, $archive_hash);
3974
3975     return $head if is_fast_fwd $archive_hash, $head;
3976
3977     my $m = "Declare fast forward from $i_arch_v->[0]";
3978
3979     my $r = pseudomerge_make_commit
3980         $clogp, $head, $archive_hash, $i_arch_v,
3981         "dgit", $m;
3982
3983     runcmd @git, qw(update-ref -m), $m, 'HEAD', $r, $head;
3984
3985     progress "Make pseudo-merge of $i_arch_v->[0] into your HEAD.";
3986     return $r;
3987 }
3988
3989 sub push_parse_changelog ($) {
3990     my ($clogpfn) = @_;
3991
3992     my $clogp = Dpkg::Control::Hash->new();
3993     $clogp->load($clogpfn) or die;
3994
3995     my $clogpackage = getfield $clogp, 'Source';
3996     $package //= $clogpackage;
3997     fail "-p specified $package but changelog specified $clogpackage"
3998         unless $package eq $clogpackage;
3999     my $cversion = getfield $clogp, 'Version';
4000
4001     if (!$we_are_initiator) {
4002         # rpush initiator can't do this because it doesn't have $isuite yet
4003         my $tag = debiantag($cversion, access_nomdistro);
4004         runcmd @git, qw(check-ref-format), $tag;
4005     }
4006
4007     my $dscfn = dscfn($cversion);
4008
4009     return ($clogp, $cversion, $dscfn);
4010 }
4011
4012 sub push_parse_dsc ($$$) {
4013     my ($dscfn,$dscfnwhat, $cversion) = @_;
4014     $dsc = parsecontrol($dscfn,$dscfnwhat);
4015     my $dversion = getfield $dsc, 'Version';
4016     my $dscpackage = getfield $dsc, 'Source';
4017     ($dscpackage eq $package && $dversion eq $cversion) or
4018         fail "$dscfn is for $dscpackage $dversion".
4019             " but debian/changelog is for $package $cversion";
4020 }
4021
4022 sub push_tagwants ($$$$) {
4023     my ($cversion, $dgithead, $maintviewhead, $tfbase) = @_;
4024     my @tagwants;
4025     push @tagwants, {
4026         TagFn => \&debiantag,
4027         Objid => $dgithead,
4028         TfSuffix => '',
4029         View => 'dgit',
4030     };
4031     if (defined $maintviewhead) {
4032         push @tagwants, {
4033             TagFn => \&debiantag_maintview,
4034             Objid => $maintviewhead,
4035             TfSuffix => '-maintview',
4036             View => 'maint',
4037         };
4038     } elsif ($dodep14tag eq 'no' ? 0
4039              : $dodep14tag eq 'want' ? access_cfg_tagformats_can_splitbrain
4040              : $dodep14tag eq 'always'
4041              ? (access_cfg_tagformats_can_splitbrain or fail <<END)
4042 --dep14tag-always (or equivalent in config) means server must support
4043  both "new" and "maint" tag formats, but config says it doesn't.
4044 END
4045             : die "$dodep14tag ?") {
4046         push @tagwants, {
4047             TagFn => \&debiantag_maintview,
4048             Objid => $dgithead,
4049             TfSuffix => '-dgit',
4050             View => 'dgit',
4051         };
4052     };
4053     foreach my $tw (@tagwants) {
4054         $tw->{Tag} = $tw->{TagFn}($cversion, access_nomdistro);
4055         $tw->{Tfn} = sub { $tfbase.$tw->{TfSuffix}.$_[0]; };
4056     }
4057     printdebug 'push_tagwants: ', Dumper(\@_, \@tagwants);
4058     return @tagwants;
4059 }
4060
4061 sub push_mktags ($$ $$ $) {
4062     my ($clogp,$dscfn,
4063         $changesfile,$changesfilewhat,
4064         $tagwants) = @_;
4065
4066     die unless $tagwants->[0]{View} eq 'dgit';
4067
4068     my $declaredistro = access_nomdistro();
4069     my $reader_giturl = do { local $access_forpush=0; access_giturl(); };
4070     $dsc->{$ourdscfield[0]} = join " ",
4071         $tagwants->[0]{Objid}, $declaredistro, $tagwants->[0]{Tag},
4072         $reader_giturl;
4073     $dsc->save("$dscfn.tmp") or die $!;
4074
4075     my $changes = parsecontrol($changesfile,$changesfilewhat);
4076     foreach my $field (qw(Source Distribution Version)) {
4077         $changes->{$field} eq $clogp->{$field} or
4078             fail "changes field $field \`$changes->{$field}'".
4079                 " does not match changelog \`$clogp->{$field}'";
4080     }
4081
4082     my $cversion = getfield $clogp, 'Version';
4083     my $clogsuite = getfield $clogp, 'Distribution';
4084
4085     # We make the git tag by hand because (a) that makes it easier
4086     # to control the "tagger" (b) we can do remote signing
4087     my $authline = clogp_authline $clogp;
4088     my $delibs = join(" ", "",@deliberatelies);
4089
4090     my $mktag = sub {
4091         my ($tw) = @_;
4092         my $tfn = $tw->{Tfn};
4093         my $head = $tw->{Objid};
4094         my $tag = $tw->{Tag};
4095
4096         open TO, '>', $tfn->('.tmp') or die $!;
4097         print TO <<END or die $!;
4098 object $head
4099 type commit
4100 tag $tag
4101 tagger $authline
4102
4103 END
4104         if ($tw->{View} eq 'dgit') {
4105             print TO <<END or die $!;
4106 $package release $cversion for $clogsuite ($csuite) [dgit]
4107 [dgit distro=$declaredistro$delibs]
4108 END
4109             foreach my $ref (sort keys %previously) {
4110                 print TO <<END or die $!;
4111 [dgit previously:$ref=$previously{$ref}]
4112 END
4113             }
4114         } elsif ($tw->{View} eq 'maint') {
4115             print TO <<END or die $!;
4116 $package release $cversion for $clogsuite ($csuite)
4117 (maintainer view tag generated by dgit --quilt=$quilt_mode)
4118 END
4119         } else {
4120             die Dumper($tw)."?";
4121         }
4122
4123         close TO or die $!;
4124
4125         my $tagobjfn = $tfn->('.tmp');
4126         if ($sign) {
4127             if (!defined $keyid) {
4128                 $keyid = access_cfg('keyid','RETURN-UNDEF');
4129             }
4130             if (!defined $keyid) {
4131                 $keyid = getfield $clogp, 'Maintainer';
4132             }
4133             unlink $tfn->('.tmp.asc') or $!==&ENOENT or die $!;
4134             my @sign_cmd = (@gpg, qw(--detach-sign --armor));
4135             push @sign_cmd, qw(-u),$keyid if defined $keyid;
4136             push @sign_cmd, $tfn->('.tmp');
4137             runcmd_ordryrun @sign_cmd;
4138             if (act_scary()) {
4139                 $tagobjfn = $tfn->('.signed.tmp');
4140                 runcmd shell_cmd "exec >$tagobjfn", qw(cat --),
4141                     $tfn->('.tmp'), $tfn->('.tmp.asc');
4142             }
4143         }
4144         return $tagobjfn;
4145     };
4146
4147     my @r = map { $mktag->($_); } @$tagwants;
4148     return @r;
4149 }
4150
4151 sub sign_changes ($) {
4152     my ($changesfile) = @_;
4153     if ($sign) {
4154         my @debsign_cmd = @debsign;
4155         push @debsign_cmd, "-k$keyid" if defined $keyid;
4156         push @debsign_cmd, "-p$gpg[0]" if $gpg[0] ne 'gpg';
4157         push @debsign_cmd, $changesfile;
4158         runcmd_ordryrun @debsign_cmd;
4159     }
4160 }
4161
4162 sub dopush () {
4163     printdebug "actually entering push\n";
4164
4165     supplementary_message(<<'END');
4166 Push failed, while checking state of the archive.
4167 You can retry the push, after fixing the problem, if you like.
4168 END
4169     if (check_for_git()) {
4170         git_fetch_us();
4171     }
4172     my $archive_hash = fetch_from_archive();
4173     if (!$archive_hash) {
4174         $new_package or
4175             fail "package appears to be new in this suite;".
4176                 " if this is intentional, use --new";
4177     }
4178
4179     supplementary_message(<<'END');
4180 Push failed, while preparing your push.
4181 You can retry the push, after fixing the problem, if you like.
4182 END
4183
4184     need_tagformat 'new', "quilt mode $quilt_mode"
4185         if quiltmode_splitbrain;
4186
4187     prep_ud();
4188
4189     access_giturl(); # check that success is vaguely likely
4190     rpush_handle_protovsn_bothends() if $we_are_initiator;
4191     select_tagformat();
4192
4193     my $clogpfn = dgit_privdir()."/changelog.822.tmp";
4194     runcmd shell_cmd "exec >$clogpfn", qw(dpkg-parsechangelog);
4195
4196     responder_send_file('parsed-changelog', $clogpfn);
4197
4198     my ($clogp, $cversion, $dscfn) =
4199         push_parse_changelog("$clogpfn");
4200
4201     my $dscpath = "$buildproductsdir/$dscfn";
4202     stat_exists $dscpath or
4203         fail "looked for .dsc $dscpath, but $!;".
4204             " maybe you forgot to build";
4205
4206     responder_send_file('dsc', $dscpath);
4207
4208     push_parse_dsc($dscpath, $dscfn, $cversion);
4209
4210     my $format = getfield $dsc, 'Format';
4211     printdebug "format $format\n";
4212
4213     my $actualhead = git_rev_parse('HEAD');
4214     my $dgithead = $actualhead;
4215     my $maintviewhead = undef;
4216
4217     my $upstreamversion = upstreamversion $clogp->{Version};
4218
4219     if (madformat_wantfixup($format)) {
4220         # user might have not used dgit build, so maybe do this now:
4221         if (quiltmode_splitbrain()) {
4222             changedir $playground;
4223             quilt_make_fake_dsc($upstreamversion);
4224             my $cachekey;
4225             ($dgithead, $cachekey) =
4226                 quilt_check_splitbrain_cache($actualhead, $upstreamversion);
4227             $dgithead or fail
4228  "--quilt=$quilt_mode but no cached dgit view:
4229  perhaps HEAD changed since dgit build[-source] ?";
4230             $split_brain = 1;
4231             $dgithead = splitbrain_pseudomerge($clogp,
4232                                                $actualhead, $dgithead,
4233                                                $archive_hash);
4234             $maintviewhead = $actualhead;
4235             changedir $maindir;
4236             prep_ud(); # so _only_subdir() works, below
4237         } else {
4238             commit_quilty_patch();
4239         }
4240     }
4241
4242     if (defined $overwrite_version && !defined $maintviewhead) {
4243         $dgithead = plain_overwrite_pseudomerge($clogp,
4244                                                 $dgithead,
4245                                                 $archive_hash);
4246     }
4247
4248     check_not_dirty();
4249
4250     my $forceflag = '';
4251     if ($archive_hash) {
4252         if (is_fast_fwd($archive_hash, $dgithead)) {
4253             # ok
4254         } elsif (deliberately_not_fast_forward) {
4255             $forceflag = '+';
4256         } else {
4257             fail "dgit push: HEAD is not a descendant".
4258                 " of the archive's version.\n".
4259                 "To overwrite the archive's contents,".
4260                 " pass --overwrite[=VERSION].\n".
4261                 "To rewind history, if permitted by the archive,".
4262                 " use --deliberately-not-fast-forward.";
4263         }
4264     }
4265
4266     changedir $playground;
4267     progress "checking that $dscfn corresponds to HEAD";
4268     runcmd qw(dpkg-source -x --),
4269         $dscpath =~ m#^/# ? $dscpath : "$maindir/$dscpath";
4270     my ($tree,$dir) = mktree_in_ud_from_only_subdir("source package");
4271     check_for_vendor_patches() if madformat($dsc->{format});
4272     changedir $maindir;
4273     my @diffcmd = (@git, qw(diff --quiet), $tree, $dgithead);
4274     debugcmd "+",@diffcmd;
4275     $!=0; $?=-1;
4276     my $r = system @diffcmd;
4277     if ($r) {
4278         if ($r==256) {
4279             my $referent = $split_brain ? $dgithead : 'HEAD';
4280             my $diffs = cmdoutput @git, qw(diff --stat), $tree, $dgithead;
4281
4282             my @mode_changes;
4283             my $raw = cmdoutput @git,
4284                 qw(diff --no-renames -z -r --raw), $tree, $dgithead;
4285             my $changed;
4286             foreach (split /\0/, $raw) {
4287                 if (defined $changed) {
4288                     push @mode_changes, "$changed: $_\n" if $changed;
4289                     $changed = undef;
4290                     next;
4291                 } elsif (m/^:0+ 0+ /) {
4292                     $changed = '';
4293                 } elsif (m/^:(?:10*)?(\d+) (?:10*)?(\d+) /) {
4294                     $changed = "Mode change from $1 to $2"
4295                 } else {
4296                     die "$_ ?";
4297                 }
4298             }
4299             if (@mode_changes) {
4300                 fail <<END.(join '', @mode_changes).<<END;
4301 HEAD specifies a different tree to $dscfn:
4302 $diffs
4303 END
4304 There is a problem with your source tree (see dgit(7) for some hints).
4305 To see a full diff, run git diff $tree $referent
4306 END
4307             }
4308
4309             fail <<END;
4310 HEAD specifies a different tree to $dscfn:
4311 $diffs
4312 Perhaps you forgot to build.  Or perhaps there is a problem with your
4313  source tree (see dgit(7) for some hints).  To see a full diff, run
4314    git diff $tree $referent
4315 END
4316         } else {
4317             failedcmd @diffcmd;
4318         }
4319     }
4320     if (!$changesfile) {
4321         my $pat = changespat $cversion;
4322         my @cs = glob "$buildproductsdir/$pat";
4323         fail "failed to find unique changes file".
4324             " (looked for $pat in $buildproductsdir);".
4325             " perhaps you need to use dgit -C"
4326             unless @cs==1;
4327         ($changesfile) = @cs;
4328     } else {
4329         $changesfile = "$buildproductsdir/$changesfile";
4330     }
4331
4332     # Check that changes and .dsc agree enough
4333     $changesfile =~ m{[^/]*$};
4334     my $changes = parsecontrol($changesfile,$&);
4335     files_compare_inputs($dsc, $changes)
4336         unless forceing [qw(dsc-changes-mismatch)];
4337
4338     # Perhaps adjust .dsc to contain right set of origs
4339     changes_update_origs_from_dsc($dsc, $changes, $upstreamversion,
4340                                   $changesfile)
4341         unless forceing [qw(changes-origs-exactly)];
4342
4343     # Checks complete, we're going to try and go ahead:
4344
4345     responder_send_file('changes',$changesfile);
4346     responder_send_command("param head $dgithead");
4347     responder_send_command("param csuite $csuite");
4348     responder_send_command("param isuite $isuite");
4349     responder_send_command("param tagformat $tagformat");
4350     if (defined $maintviewhead) {
4351         die unless ($protovsn//4) >= 4;
4352         responder_send_command("param maint-view $maintviewhead");
4353     }
4354
4355     # Perhaps send buildinfo(s) for signing
4356     my $changes_files = getfield $changes, 'Files';
4357     my @buildinfos = ($changes_files =~ m/ .* (\S+\.buildinfo)$/mg);
4358     foreach my $bi (@buildinfos) {
4359         responder_send_command("param buildinfo-filename $bi");
4360         responder_send_file('buildinfo', "$buildproductsdir/$bi");
4361     }
4362
4363     if (deliberately_not_fast_forward) {
4364         git_for_each_ref(lrfetchrefs, sub {
4365             my ($objid,$objtype,$lrfetchrefname,$reftail) = @_;
4366             my $rrefname= substr($lrfetchrefname, length(lrfetchrefs) + 1);
4367             responder_send_command("previously $rrefname=$objid");
4368             $previously{$rrefname} = $objid;
4369         });
4370     }
4371
4372     my @tagwants = push_tagwants($cversion, $dgithead, $maintviewhead,
4373                                  dgit_privdir()."/tag");
4374     my @tagobjfns;
4375
4376     supplementary_message(<<'END');
4377 Push failed, while signing the tag.
4378 You can retry the push, after fixing the problem, if you like.
4379 END
4380     # If we manage to sign but fail to record it anywhere, it's fine.
4381     if ($we_are_responder) {
4382         @tagobjfns = map { $_->{Tfn}('.signed-tmp') } @tagwants;
4383         responder_receive_files('signed-tag', @tagobjfns);
4384     } else {
4385         @tagobjfns = push_mktags($clogp,$dscpath,
4386                               $changesfile,$changesfile,
4387                               \@tagwants);
4388     }
4389     supplementary_message(<<'END');
4390 Push failed, *after* signing the tag.
4391 If you want to try again, you should use a new version number.
4392 END
4393
4394     pairwise { $a->{TagObjFn} = $b } @tagwants, @tagobjfns;
4395
4396     foreach my $tw (@tagwants) {
4397         my $tag = $tw->{Tag};
4398         my $tagobjfn = $tw->{TagObjFn};
4399         my $tag_obj_hash =
4400             cmdoutput @git, qw(hash-object -w -t tag), $tagobjfn;
4401         runcmd_ordryrun @git, qw(verify-tag), $tag_obj_hash;
4402         runcmd_ordryrun_local
4403             @git, qw(update-ref), "refs/tags/$tag", $tag_obj_hash;
4404     }
4405
4406     supplementary_message(<<'END');
4407 Push failed, while updating the remote git repository - see messages above.
4408 If you want to try again, you should use a new version number.
4409 END
4410     if (!check_for_git()) {
4411         create_remote_git_repo();
4412     }
4413
4414     my @pushrefs = $forceflag.$dgithead.":".rrref();
4415     foreach my $tw (@tagwants) {
4416         push @pushrefs, $forceflag."refs/tags/$tw->{Tag}";
4417     }
4418
4419     runcmd_ordryrun @git,
4420         qw(-c push.followTags=false push), access_giturl(), @pushrefs;
4421     runcmd_ordryrun @git, qw(update-ref -m), 'dgit push', lrref(), $dgithead;
4422
4423     supplementary_message(<<'END');
4424 Push failed, while obtaining signatures on the .changes and .dsc.
4425 If it was just that the signature failed, you may try again by using
4426 debsign by hand to sign the changes
4427    $changesfile
4428 and then dput to complete the upload.
4429 If you need to change the package, you must use a new version number.
4430 END
4431     if ($we_are_responder) {
4432         my $dryrunsuffix = act_local() ? "" : ".tmp";
4433         my @rfiles = ($dscpath, $changesfile);
4434         push @rfiles, map { "$buildproductsdir/$_" } @buildinfos;
4435         responder_receive_files('signed-dsc-changes',
4436                                 map { "$_$dryrunsuffix" } @rfiles);
4437     } else {
4438         if (act_local()) {
4439             rename "$dscpath.tmp",$dscpath or die "$dscfn $!";
4440         } else {
4441             progress "[new .dsc left in $dscpath.tmp]";
4442         }
4443         sign_changes $changesfile;
4444     }
4445
4446     supplementary_message(<<END);
4447 Push failed, while uploading package(s) to the archive server.
4448 You can retry the upload of exactly these same files with dput of:
4449   $changesfile
4450 If that .changes file is broken, you will need to use a new version
4451 number for your next attempt at the upload.
4452 END
4453     my $host = access_cfg('upload-host','RETURN-UNDEF');
4454     my @hostarg = defined($host) ? ($host,) : ();
4455     runcmd_ordryrun @dput, @hostarg, $changesfile;
4456     printdone "pushed and uploaded $cversion";
4457
4458     supplementary_message('');
4459     responder_send_command("complete");
4460 }
4461
4462 sub pre_clone () {
4463     not_necessarily_a_tree();
4464 }
4465 sub cmd_clone {
4466     parseopts();
4467     my $dstdir;
4468     badusage "-p is not allowed with clone; specify as argument instead"
4469         if defined $package;
4470     if (@ARGV==1) {
4471         ($package) = @ARGV;
4472     } elsif (@ARGV==2 && $ARGV[1] =~ m#^\w#) {
4473         ($package,$isuite) = @ARGV;
4474     } elsif (@ARGV==2 && $ARGV[1] =~ m#^[./]#) {
4475         ($package,$dstdir) = @ARGV;
4476     } elsif (@ARGV==3) {
4477         ($package,$isuite,$dstdir) = @ARGV;
4478     } else {
4479         badusage "incorrect arguments to dgit clone";
4480     }
4481     notpushing();
4482
4483     $dstdir ||= "$package";
4484     if (stat_exists $dstdir) {
4485         fail "$dstdir already exists";
4486     }
4487
4488     my $cwd_remove;
4489     if ($rmonerror && !$dryrun_level) {
4490         $cwd_remove= getcwd();
4491         unshift @end, sub {
4492             return unless defined $cwd_remove;
4493             if (!chdir "$cwd_remove") {
4494                 return if $!==&ENOENT;
4495                 die "chdir $cwd_remove: $!";
4496             }
4497             printdebug "clone rmonerror removing $dstdir\n";
4498             if (stat $dstdir) {
4499                 rmtree($dstdir) or die "remove $dstdir: $!\n";
4500             } elsif (grep { $! == $_ }
4501                      (ENOENT, ENOTDIR, EACCES, EPERM, ELOOP)) {
4502             } else {
4503                 print STDERR "check whether to remove $dstdir: $!\n";
4504             }
4505         };
4506     }
4507
4508     clone($dstdir);
4509     $cwd_remove = undef;
4510 }
4511
4512 sub branchsuite () {
4513     my @cmd = (@git, qw(symbolic-ref -q HEAD));
4514     my $branch = cmdoutput_errok @cmd;
4515     if (!defined $branch) {
4516         $?==256 or failedcmd @cmd;
4517         return undef;
4518     }
4519     if ($branch =~ m#$lbranch_re#o) {
4520         return $1;
4521     } else {
4522         return undef;
4523     }
4524 }
4525
4526 sub fetchpullargs () {
4527     if (!defined $package) {
4528         my $sourcep = parsecontrol('debian/control','debian/control');
4529         $package = getfield $sourcep, 'Source';
4530     }
4531     if (@ARGV==0) {
4532         $isuite = branchsuite();
4533         if (!$isuite) {
4534             my $clogp = parsechangelog();
4535             my $clogsuite = getfield $clogp, 'Distribution';
4536             $isuite= $clogsuite if $clogsuite ne 'UNRELEASED';
4537         }
4538     } elsif (@ARGV==1) {
4539         ($isuite) = @ARGV;
4540     } else {
4541         badusage "incorrect arguments to dgit fetch or dgit pull";
4542     }
4543     notpushing();
4544 }
4545
4546 sub cmd_fetch {
4547     parseopts();
4548     fetchpullargs();
4549     my $multi_fetched = fork_for_multisuite(sub { });
4550     exit 0 if $multi_fetched;
4551     fetch();
4552 }
4553
4554 sub cmd_pull {
4555     parseopts();
4556     fetchpullargs();
4557     if (quiltmode_splitbrain()) {
4558         my ($format, $fopts) = get_source_format();
4559         madformat($format) and fail <<END
4560 dgit pull not yet supported in split view mode (--quilt=$quilt_mode)
4561 END
4562     }
4563     pull();
4564 }
4565
4566 sub prep_push () {
4567     parseopts();
4568     build_or_push_prep_early();
4569     pushing();
4570     check_not_dirty();
4571     my $specsuite;
4572     if (@ARGV==0) {
4573     } elsif (@ARGV==1) {
4574         ($specsuite) = (@ARGV);
4575     } else {
4576         badusage "incorrect arguments to dgit $subcommand";
4577     }
4578     if ($new_package) {
4579         local ($package) = $existing_package; # this is a hack
4580         canonicalise_suite();
4581     } else {
4582         canonicalise_suite();
4583     }
4584     if (defined $specsuite &&
4585         $specsuite ne $isuite &&
4586         $specsuite ne $csuite) {
4587             fail "dgit $subcommand: changelog specifies $isuite ($csuite)".
4588                 " but command line specifies $specsuite";
4589     }
4590 }
4591
4592 sub cmd_push {
4593     prep_push();
4594     dopush();
4595 }
4596
4597 sub cmd_push_source {
4598     prep_push();
4599     if ($changesfile) {
4600         my $changes = parsecontrol("$buildproductsdir/$changesfile",
4601                                    "source changes file");
4602         unless (test_source_only_changes($changes)) {
4603             fail "user-specified changes file is not source-only";
4604         }
4605     } else {
4606         # Building a source package is very fast, so just do it
4607         build_source_for_push();
4608     }
4609     dopush();
4610 }
4611
4612 #---------- remote commands' implementation ----------
4613
4614 sub pre_remote_push_build_host {
4615     my ($nrargs) = shift @ARGV;
4616     my (@rargs) = @ARGV[0..$nrargs-1];
4617     @ARGV = @ARGV[$nrargs..$#ARGV];
4618     die unless @rargs;
4619     my ($dir,$vsnwant) = @rargs;
4620     # vsnwant is a comma-separated list; we report which we have
4621     # chosen in our ready response (so other end can tell if they
4622     # offered several)
4623     $debugprefix = ' ';
4624     $we_are_responder = 1;
4625     $us .= " (build host)";
4626
4627     open PI, "<&STDIN" or die $!;
4628     open STDIN, "/dev/null" or die $!;
4629     open PO, ">&STDOUT" or die $!;
4630     autoflush PO 1;
4631     open STDOUT, ">&STDERR" or die $!;
4632     autoflush STDOUT 1;
4633
4634     $vsnwant //= 1;
4635     ($protovsn) = grep {
4636         $vsnwant =~ m{^(?:.*,)?$_(?:,.*)?$}
4637     } @rpushprotovsn_support;
4638
4639     fail "build host has dgit rpush protocol versions ".
4640         (join ",", @rpushprotovsn_support).
4641         " but invocation host has $vsnwant"
4642         unless defined $protovsn;
4643
4644     changedir $dir;
4645 }
4646 sub cmd_remote_push_build_host {
4647     responder_send_command("dgit-remote-push-ready $protovsn");
4648     &cmd_push;
4649 }
4650
4651 sub pre_remote_push_responder { pre_remote_push_build_host(); }
4652 sub cmd_remote_push_responder { cmd_remote_push_build_host(); }
4653 # ... for compatibility with proto vsn.1 dgit (just so that user gets
4654 #     a good error message)
4655
4656 sub rpush_handle_protovsn_bothends () {
4657     if ($protovsn < 4) {
4658         need_tagformat 'old', "rpush negotiated protocol $protovsn";
4659     }
4660     select_tagformat();
4661 }
4662
4663 our $i_tmp;
4664
4665 sub i_cleanup {
4666     local ($@, $?);
4667     my $report = i_child_report();
4668     if (defined $report) {
4669         printdebug "($report)\n";
4670     } elsif ($i_child_pid) {
4671         printdebug "(killing build host child $i_child_pid)\n";
4672         kill 15, $i_child_pid;
4673     }
4674     if (defined $i_tmp && !defined $initiator_tempdir) {
4675         changedir "/";
4676         eval { rmtree $i_tmp; };
4677     }
4678 }
4679
4680 END {
4681     return unless forkcheck_mainprocess();
4682     i_cleanup();
4683 }
4684
4685 sub i_method {
4686     my ($base,$selector,@args) = @_;
4687     $selector =~ s/\-/_/g;
4688     { no strict qw(refs); &{"${base}_${selector}"}(@args); }
4689 }
4690
4691 sub pre_rpush () {
4692     not_necessarily_a_tree();
4693 }
4694 sub cmd_rpush {
4695     my $host = nextarg;
4696     my $dir;
4697     if ($host =~ m/^((?:[^][]|\[[^][]*\])*)\:/) {
4698         $host = $1;
4699         $dir = $'; #';
4700     } else {
4701         $dir = nextarg;
4702     }
4703     $dir =~ s{^-}{./-};
4704     my @rargs = ($dir);
4705     push @rargs, join ",", @rpushprotovsn_support;
4706     my @rdgit;
4707     push @rdgit, @dgit;
4708     push @rdgit, @ropts;
4709     push @rdgit, qw(remote-push-build-host), (scalar @rargs), @rargs;
4710     push @rdgit, @ARGV;
4711     my @cmd = (@ssh, $host, shellquote @rdgit);
4712     debugcmd "+",@cmd;
4713
4714     $we_are_initiator=1;
4715
4716     if (defined $initiator_tempdir) {
4717         rmtree $initiator_tempdir;
4718         mkdir $initiator_tempdir, 0700 or die "$initiator_tempdir: $!";
4719         $i_tmp = $initiator_tempdir;
4720     } else {
4721         $i_tmp = tempdir();
4722     }
4723     $i_child_pid = open2(\*RO, \*RI, @cmd);
4724     changedir $i_tmp;
4725     ($protovsn) = initiator_expect { m/^dgit-remote-push-ready (\S+)/ };
4726     die "$protovsn ?" unless grep { $_ eq $protovsn } @rpushprotovsn_support;
4727     $supplementary_message = '' unless $protovsn >= 3;
4728
4729     for (;;) {
4730         my ($icmd,$iargs) = initiator_expect {
4731             m/^(\S+)(?: (.*))?$/;
4732             ($1,$2);
4733         };
4734         i_method "i_resp", $icmd, $iargs;
4735     }
4736 }
4737
4738 sub i_resp_progress ($) {
4739     my ($rhs) = @_;
4740     my $msg = protocol_read_bytes \*RO, $rhs;
4741     progress $msg;
4742 }
4743
4744 sub i_resp_supplementary_message ($) {
4745     my ($rhs) = @_;
4746     $supplementary_message = protocol_read_bytes \*RO, $rhs;
4747 }
4748
4749 sub i_resp_complete {
4750     my $pid = $i_child_pid;
4751     $i_child_pid = undef; # prevents killing some other process with same pid
4752     printdebug "waiting for build host child $pid...\n";
4753     my $got = waitpid $pid, 0;
4754     die $! unless $got == $pid;
4755     die "build host child failed $?" if $?;
4756
4757     i_cleanup();
4758     printdebug "all done\n";
4759     exit 0;
4760 }
4761
4762 sub i_resp_file ($) {
4763     my ($keyword) = @_;
4764     my $localname = i_method "i_localname", $keyword;
4765     my $localpath = "$i_tmp/$localname";
4766     stat_exists $localpath and
4767         badproto \*RO, "file $keyword ($localpath) twice";
4768     protocol_receive_file \*RO, $localpath;
4769     i_method "i_file", $keyword;
4770 }
4771
4772 our %i_param;
4773
4774 sub i_resp_param ($) {
4775     $_[0] =~ m/^(\S+) (.*)$/ or badproto \*RO, "bad param spec";
4776     $i_param{$1} = $2;
4777 }
4778
4779 sub i_resp_previously ($) {
4780     $_[0] =~ m#^(refs/tags/\S+)=(\w+)$#
4781         or badproto \*RO, "bad previously spec";
4782     my $r = system qw(git check-ref-format), $1;
4783     die "bad previously ref spec ($r)" if $r;
4784     $previously{$1} = $2;
4785 }
4786
4787 our %i_wanted;
4788
4789 sub i_resp_want ($) {
4790     my ($keyword) = @_;
4791     die "$keyword ?" if $i_wanted{$keyword}++;
4792
4793     defined $i_param{'csuite'} or badproto \*RO, "premature desire, no csuite";
4794     $isuite = $i_param{'isuite'} // $i_param{'csuite'};
4795     die unless $isuite =~ m/^$suite_re$/;
4796
4797     pushing();
4798     rpush_handle_protovsn_bothends();
4799
4800     fail "rpush negotiated protocol version $protovsn".
4801         " which does not support quilt mode $quilt_mode"
4802         if quiltmode_splitbrain;
4803
4804     my @localpaths = i_method "i_want", $keyword;
4805     printdebug "[[  $keyword @localpaths\n";
4806     foreach my $localpath (@localpaths) {
4807         protocol_send_file \*RI, $localpath;
4808     }
4809     print RI "files-end\n" or die $!;
4810 }
4811
4812 our ($i_clogp, $i_version, $i_dscfn, $i_changesfn, @i_buildinfos);
4813
4814 sub i_localname_parsed_changelog {
4815     return "remote-changelog.822";
4816 }
4817 sub i_file_parsed_changelog {
4818     ($i_clogp, $i_version, $i_dscfn) =
4819         push_parse_changelog "$i_tmp/remote-changelog.822";
4820     die if $i_dscfn =~ m#/|^\W#;
4821 }
4822
4823 sub i_localname_dsc {
4824     defined $i_dscfn or badproto \*RO, "dsc (before parsed-changelog)";
4825     return $i_dscfn;
4826 }
4827 sub i_file_dsc { }
4828
4829 sub i_localname_buildinfo ($) {
4830     my $bi = $i_param{'buildinfo-filename'};
4831     defined $bi or badproto \*RO, "buildinfo before filename";
4832     defined $i_changesfn or badproto \*RO, "buildinfo before changes";
4833     $bi =~ m{^\Q$package\E_[!-.0-~]*\.buildinfo$}s
4834         or badproto \*RO, "improper buildinfo filename";
4835     return $&;
4836 }
4837 sub i_file_buildinfo {
4838     my $bi = $i_param{'buildinfo-filename'};
4839     my $bd = parsecontrol "$i_tmp/$bi", $bi;
4840     my $ch = parsecontrol "$i_tmp/$i_changesfn", 'changes';
4841     if (!forceing [qw(buildinfo-changes-mismatch)]) {
4842         files_compare_inputs($bd, $ch);
4843         (getfield $bd, $_) eq (getfield $ch, $_) or
4844             fail "buildinfo mismatch $_"
4845             foreach qw(Source Version);
4846         !defined $bd->{$_} or
4847             fail "buildinfo contains $_"
4848             foreach qw(Changes Changed-by Distribution);
4849     }
4850     push @i_buildinfos, $bi;
4851     delete $i_param{'buildinfo-filename'};
4852 }
4853
4854 sub i_localname_changes {
4855     defined $i_dscfn or badproto \*RO, "dsc (before parsed-changelog)";
4856     $i_changesfn = $i_dscfn;
4857     $i_changesfn =~ s/\.dsc$/_dgit.changes/ or die;
4858     return $i_changesfn;
4859 }
4860 sub i_file_changes { }
4861
4862 sub i_want_signed_tag {
4863     printdebug Dumper(\%i_param, $i_dscfn);
4864     defined $i_param{'head'} && defined $i_dscfn && defined $i_clogp
4865         && defined $i_param{'csuite'}
4866         or badproto \*RO, "premature desire for signed-tag";
4867     my $head = $i_param{'head'};
4868     die if $head =~ m/[^0-9a-f]/ || $head !~ m/^../;
4869
4870     my $maintview = $i_param{'maint-view'};
4871     die if defined $maintview && $maintview =~ m/[^0-9a-f]/;
4872
4873     select_tagformat();
4874     if ($protovsn >= 4) {
4875         my $p = $i_param{'tagformat'} // '<undef>';
4876         $p eq $tagformat
4877             or badproto \*RO, "tag format mismatch: $p vs. $tagformat";
4878     }
4879
4880     die unless $i_param{'csuite'} =~ m/^$suite_re$/;
4881     $csuite = $&;
4882     push_parse_dsc $i_dscfn, 'remote dsc', $i_version;
4883
4884     my @tagwants = push_tagwants $i_version, $head, $maintview, "tag";
4885
4886     return
4887         push_mktags $i_clogp, $i_dscfn,
4888             $i_changesfn, 'remote changes',
4889             \@tagwants;
4890 }
4891
4892 sub i_want_signed_dsc_changes {
4893     rename "$i_dscfn.tmp","$i_dscfn" or die "$i_dscfn $!";
4894     sign_changes $i_changesfn;
4895     return ($i_dscfn, $i_changesfn, @i_buildinfos);
4896 }
4897
4898 #---------- building etc. ----------
4899
4900 our $version;
4901 our $sourcechanges;
4902 our $dscfn;
4903
4904 #----- `3.0 (quilt)' handling -----
4905
4906 our $fakeeditorenv = 'DGIT_FAKE_EDITOR_QUILT';
4907
4908 sub quiltify_dpkg_commit ($$$;$) {
4909     my ($patchname,$author,$msg, $xinfo) = @_;
4910     $xinfo //= '';
4911
4912     mkpath '.git/dgit'; # we are in playtree
4913     my $descfn = ".git/dgit/quilt-description.tmp";
4914     open O, '>', $descfn or die "$descfn: $!";
4915     $msg =~ s/\n+/\n\n/;
4916     print O <<END or die $!;
4917 From: $author
4918 ${xinfo}Subject: $msg
4919 ---
4920
4921 END
4922     close O or die $!;
4923
4924     {
4925         local $ENV{'EDITOR'} = cmdoutput qw(realpath --), $0;
4926         local $ENV{'VISUAL'} = $ENV{'EDITOR'};
4927         local $ENV{$fakeeditorenv} = cmdoutput qw(realpath --), $descfn;
4928         runcmd @dpkgsource, qw(--commit --include-removal .), $patchname;
4929     }
4930 }
4931
4932 sub quiltify_trees_differ ($$;$$$) {
4933     my ($x,$y,$finegrained,$ignorenamesr,$unrepres) = @_;
4934     # returns true iff the two tree objects differ other than in debian/
4935     # with $finegrained,
4936     # returns bitmask 01 - differ in upstream files except .gitignore
4937     #                 02 - differ in .gitignore
4938     # if $ignorenamesr is defined, $ingorenamesr->{$fn}
4939     #  is set for each modified .gitignore filename $fn
4940     # if $unrepres is defined, array ref to which is appeneded
4941     #  a list of unrepresentable changes (removals of upstream files
4942     #  (as messages)
4943     local $/=undef;
4944     my @cmd = (@git, qw(diff-tree -z --no-renames));
4945     push @cmd, qw(--name-only) unless $unrepres;
4946     push @cmd, qw(-r) if $finegrained || $unrepres;
4947     push @cmd, $x, $y;
4948     my $diffs= cmdoutput @cmd;
4949     my $r = 0;
4950     my @lmodes;
4951     foreach my $f (split /\0/, $diffs) {
4952         if ($unrepres && !@lmodes) {
4953             @lmodes = $f =~ m/^\:(\w+) (\w+) \w+ \w+ / or die "$_ ?";
4954             next;
4955         }
4956         my ($oldmode,$newmode) = @lmodes;
4957         @lmodes = ();
4958
4959         next if $f =~ m#^debian(?:/.*)?$#s;
4960
4961         if ($unrepres) {
4962             eval {
4963                 die "not a plain file or symlink\n"
4964                     unless $newmode =~ m/^(?:10|12)\d{4}$/ ||
4965                            $oldmode =~ m/^(?:10|12)\d{4}$/;
4966                 if ($oldmode =~ m/[^0]/ &&
4967                     $newmode =~ m/[^0]/) {
4968                     # both old and new files exist
4969                     die "mode or type changed\n" if $oldmode ne $newmode;
4970                     die "modified symlink\n" unless $newmode =~ m/^10/;
4971                 } elsif ($oldmode =~ m/[^0]/) {
4972                     # deletion
4973                     die "deletion of symlink\n"
4974                         unless $oldmode =~ m/^10/;
4975                 } else {
4976                     # creation
4977                     die "creation with non-default mode\n"
4978                         unless $newmode =~ m/^100644$/ or
4979                                $newmode =~ m/^120000$/;
4980                 }
4981             };
4982             if ($@) {
4983                 local $/="\n"; chomp $@;
4984                 push @$unrepres, [ $f, "$@ ($oldmode->$newmode)" ];
4985             }
4986         }
4987
4988         my $isignore = $f =~ m#^(?:.*/)?.gitignore$#s;
4989         $r |= $isignore ? 02 : 01;
4990         $ignorenamesr->{$f}=1 if $ignorenamesr && $isignore;
4991     }
4992     printdebug "quiltify_trees_differ $x $y => $r\n";
4993     return $r;
4994 }
4995
4996 sub quiltify_tree_sentinelfiles ($) {
4997     # lists the `sentinel' files present in the tree
4998     my ($x) = @_;
4999     my $r = cmdoutput @git, qw(ls-tree --name-only), $x,
5000         qw(-- debian/rules debian/control);
5001     $r =~ s/\n/,/g;
5002     return $r;
5003 }
5004
5005 sub quiltify_splitbrain_needed () {
5006     if (!$split_brain) {
5007         progress "dgit view: changes are required...";
5008         runcmd @git, qw(checkout -q -b dgit-view);
5009         $split_brain = 1;
5010     }
5011 }
5012
5013 sub quiltify_splitbrain ($$$$$$) {
5014     my ($clogp, $unapplied, $headref, $diffbits,
5015         $editedignores, $cachekey) = @_;
5016     if ($quilt_mode !~ m/gbp|dpm/) {
5017         # treat .gitignore just like any other upstream file
5018         $diffbits = { %$diffbits };
5019         $_ = !!$_ foreach values %$diffbits;
5020     }
5021     # We would like any commits we generate to be reproducible
5022     my @authline = clogp_authline($clogp);
5023     local $ENV{GIT_COMMITTER_NAME} =  $authline[0];
5024     local $ENV{GIT_COMMITTER_EMAIL} = $authline[1];
5025     local $ENV{GIT_COMMITTER_DATE} =  $authline[2];
5026     local $ENV{GIT_AUTHOR_NAME} =  $authline[0];
5027     local $ENV{GIT_AUTHOR_EMAIL} = $authline[1];
5028     local $ENV{GIT_AUTHOR_DATE} =  $authline[2];
5029
5030     if ($quilt_mode =~ m/gbp|unapplied/ &&
5031         ($diffbits->{O2H} & 01)) {
5032         my $msg =
5033  "--quilt=$quilt_mode specified, implying patches-unapplied git tree\n".
5034  " but git tree differs from orig in upstream files.";
5035         if (!stat_exists "debian/patches") {
5036             $msg .=
5037  "\n ... debian/patches is missing; perhaps this is a patch queue branch?";
5038         }
5039         fail $msg;
5040     }
5041     if ($quilt_mode =~ m/dpm/ &&
5042         ($diffbits->{H2A} & 01)) {
5043         fail <<END;
5044 --quilt=$quilt_mode specified, implying patches-applied git tree
5045  but git tree differs from result of applying debian/patches to upstream
5046 END
5047     }
5048     if ($quilt_mode =~ m/gbp|unapplied/ &&
5049         ($diffbits->{O2A} & 01)) { # some patches
5050         quiltify_splitbrain_needed();
5051         progress "dgit view: creating patches-applied version using gbp pq";
5052         runcmd shell_cmd 'exec >/dev/null', gbp_pq, qw(import);
5053         # gbp pq import creates a fresh branch; push back to dgit-view
5054         runcmd @git, qw(update-ref refs/heads/dgit-view HEAD);
5055         runcmd @git, qw(checkout -q dgit-view);
5056     }
5057     if ($quilt_mode =~ m/gbp|dpm/ &&
5058         ($diffbits->{O2A} & 02)) {
5059         fail <<END
5060 --quilt=$quilt_mode specified, implying that HEAD is for use with a
5061  tool which does not create patches for changes to upstream
5062  .gitignores: but, such patches exist in debian/patches.
5063 END
5064     }
5065     if (($diffbits->{O2H} & 02) && # user has modified .gitignore
5066         !($diffbits->{O2A} & 02)) { # patches do not change .gitignore
5067         quiltify_splitbrain_needed();
5068         progress "dgit view: creating patch to represent .gitignore changes";
5069         ensuredir "debian/patches";
5070         my $gipatch = "debian/patches/auto-gitignore";
5071         open GIPATCH, ">>", "$gipatch" or die "$gipatch: $!";
5072         stat GIPATCH or die "$gipatch: $!";
5073         fail "$gipatch already exists; but want to create it".
5074             " to record .gitignore changes" if (stat _)[7];
5075         print GIPATCH <<END or die "$gipatch: $!";
5076 Subject: Update .gitignore from Debian packaging branch
5077
5078 The Debian packaging git branch contains these updates to the upstream
5079 .gitignore file(s).  This patch is autogenerated, to provide these
5080 updates to users of the official Debian archive view of the package.
5081
5082 [dgit ($our_version) update-gitignore]
5083 ---
5084 END
5085         close GIPATCH or die "$gipatch: $!";
5086         runcmd shell_cmd "exec >>$gipatch", @git, qw(diff),
5087             $unapplied, $headref, "--", sort keys %$editedignores;
5088         open SERIES, "+>>", "debian/patches/series" or die $!;
5089         defined seek SERIES, -1, 2 or $!==EINVAL or die $!;
5090         my $newline;
5091         defined read SERIES, $newline, 1 or die $!;
5092         print SERIES "\n" or die $! unless $newline eq "\n";
5093         print SERIES "auto-gitignore\n" or die $!;
5094         close SERIES or die  $!;
5095         runcmd @git, qw(add -- debian/patches/series), $gipatch;
5096         commit_admin <<END
5097 Commit patch to update .gitignore
5098
5099 [dgit ($our_version) update-gitignore-quilt-fixup]
5100 END
5101     }
5102
5103     my $dgitview = git_rev_parse 'HEAD';
5104
5105     changedir $maindir;
5106     # When we no longer need to support squeeze, use --create-reflog
5107     # instead of this:
5108     ensuredir "$maindir_gitcommon/logs/refs/dgit-intern";
5109     my $makelogfh = new IO::File "$maindir_gitcommon/logs/refs/$splitbraincache", '>>'
5110       or die $!;
5111
5112     my $oldcache = git_get_ref "refs/$splitbraincache";
5113     if ($oldcache eq $dgitview) {
5114         my $tree = cmdoutput qw(git rev-parse), "$dgitview:";
5115         # git update-ref doesn't always update, in this case.  *sigh*
5116         my $dummy = make_commit_text <<END;
5117 tree $tree
5118 parent $dgitview
5119 author Dgit <dgit\@example.com> 1000000000 +0000
5120 committer Dgit <dgit\@example.com> 1000000000 +0000
5121
5122 Dummy commit - do not use
5123 END
5124         runcmd @git, qw(update-ref -m), "dgit $our_version - dummy",
5125             "refs/$splitbraincache", $dummy;
5126     }
5127     runcmd @git, qw(update-ref -m), $cachekey, "refs/$splitbraincache",
5128         $dgitview;
5129
5130     changedir "$playground/work";
5131
5132     my $saved = maybe_split_brain_save $headref, $dgitview, "converted";
5133     progress "dgit view: created ($saved)";
5134 }
5135
5136 sub quiltify ($$$$) {
5137     my ($clogp,$target,$oldtiptree,$failsuggestion) = @_;
5138
5139     # Quilt patchification algorithm
5140     #
5141     # We search backwards through the history of the main tree's HEAD
5142     # (T) looking for a start commit S whose tree object is identical
5143     # to to the patch tip tree (ie the tree corresponding to the
5144     # current dpkg-committed patch series).  For these purposes
5145     # `identical' disregards anything in debian/ - this wrinkle is
5146     # necessary because dpkg-source treates debian/ specially.
5147     #
5148     # We can only traverse edges where at most one of the ancestors'
5149     # trees differs (in changes outside in debian/).  And we cannot
5150     # handle edges which change .pc/ or debian/patches.  To avoid
5151     # going down a rathole we avoid traversing edges which introduce
5152     # debian/rules or debian/control.  And we set a limit on the
5153     # number of edges we are willing to look at.
5154     #
5155     # If we succeed, we walk forwards again.  For each traversed edge
5156     # PC (with P parent, C child) (starting with P=S and ending with
5157     # C=T) to we do this:
5158     #  - git checkout C
5159     #  - dpkg-source --commit with a patch name and message derived from C
5160     # After traversing PT, we git commit the changes which
5161     # should be contained within debian/patches.
5162
5163     # The search for the path S..T is breadth-first.  We maintain a
5164     # todo list containing search nodes.  A search node identifies a
5165     # commit, and looks something like this:
5166     #  $p = {
5167     #      Commit => $git_commit_id,
5168     #      Child => $c,                          # or undef if P=T
5169     #      Whynot => $reason_edge_PC_unsuitable, # in @nots only
5170     #      Nontrivial => true iff $p..$c has relevant changes
5171     #  };
5172
5173     my @todo;
5174     my @nots;
5175     my $sref_S;
5176     my $max_work=100;
5177     my %considered; # saves being exponential on some weird graphs
5178
5179     my $t_sentinels = quiltify_tree_sentinelfiles $target;
5180
5181     my $not = sub {
5182         my ($search,$whynot) = @_;
5183         printdebug " search NOT $search->{Commit} $whynot\n";
5184         $search->{Whynot} = $whynot;
5185         push @nots, $search;
5186         no warnings qw(exiting);
5187         next;
5188     };
5189
5190     push @todo, {
5191         Commit => $target,
5192     };
5193
5194     while (@todo) {
5195         my $c = shift @todo;
5196         next if $considered{$c->{Commit}}++;
5197
5198         $not->($c, "maximum search space exceeded") if --$max_work <= 0;
5199
5200         printdebug "quiltify investigate $c->{Commit}\n";
5201
5202         # are we done?
5203         if (!quiltify_trees_differ $c->{Commit}, $oldtiptree) {
5204             printdebug " search finished hooray!\n";
5205             $sref_S = $c;
5206             last;
5207         }
5208
5209         if ($quilt_mode eq 'nofix') {
5210             fail "quilt fixup required but quilt mode is \`nofix'\n".
5211                 "HEAD commit $c->{Commit} differs from tree implied by ".
5212                 " debian/patches (tree object $oldtiptree)";
5213         }
5214         if ($quilt_mode eq 'smash') {
5215             printdebug " search quitting smash\n";
5216             last;
5217         }
5218
5219         my $c_sentinels = quiltify_tree_sentinelfiles $c->{Commit};
5220         $not->($c, "has $c_sentinels not $t_sentinels")
5221             if $c_sentinels ne $t_sentinels;
5222
5223         my $commitdata = cmdoutput @git, qw(cat-file commit), $c->{Commit};
5224         $commitdata =~ m/\n\n/;
5225         $commitdata =~ $`;
5226         my @parents = ($commitdata =~ m/^parent (\w+)$/gm);
5227         @parents = map { { Commit => $_, Child => $c } } @parents;
5228
5229         $not->($c, "root commit") if !@parents;
5230
5231         foreach my $p (@parents) {
5232             $p->{Nontrivial}= quiltify_trees_differ $p->{Commit},$c->{Commit};
5233         }
5234         my $ndiffers = grep { $_->{Nontrivial} } @parents;
5235         $not->($c, "merge ($ndiffers nontrivial parents)") if $ndiffers > 1;
5236
5237         foreach my $p (@parents) {
5238             printdebug "considering C=$c->{Commit} P=$p->{Commit}\n";
5239
5240             my @cmd= (@git, qw(diff-tree -r --name-only),
5241                       $p->{Commit},$c->{Commit}, qw(-- debian/patches .pc));
5242             my $patchstackchange = cmdoutput @cmd;
5243             if (length $patchstackchange) {
5244                 $patchstackchange =~ s/\n/,/g;
5245                 $not->($p, "changed $patchstackchange");
5246             }
5247
5248             printdebug " search queue P=$p->{Commit} ",
5249                 ($p->{Nontrivial} ? "NT" : "triv"),"\n";
5250             push @todo, $p;
5251         }
5252     }
5253
5254     if (!$sref_S) {
5255         printdebug "quiltify want to smash\n";
5256
5257         my $abbrev = sub {
5258             my $x = $_[0]{Commit};
5259             $x =~ s/(.*?[0-9a-z]{8})[0-9a-z]*$/$1/;
5260             return $x;
5261         };
5262         my $reportnot = sub {
5263             my ($notp) = @_;
5264             my $s = $abbrev->($notp);
5265             my $c = $notp->{Child};
5266             $s .= "..".$abbrev->($c) if $c;
5267             $s .= ": ".$notp->{Whynot};
5268             return $s;
5269         };
5270         if ($quilt_mode eq 'linear') {
5271             print STDERR "$us: quilt fixup cannot be linear.  Stopped at:\n";
5272             foreach my $notp (@nots) {
5273                 print STDERR "$us:  ", $reportnot->($notp), "\n";
5274             }
5275             print STDERR "$us: $_\n" foreach @$failsuggestion;
5276             fail "quilt fixup naive history linearisation failed.\n".
5277  "Use dpkg-source --commit by hand; or, --quilt=smash for one ugly patch";
5278         } elsif ($quilt_mode eq 'smash') {
5279         } elsif ($quilt_mode eq 'auto') {
5280             progress "quilt fixup cannot be linear, smashing...";
5281         } else {
5282             die "$quilt_mode ?";
5283         }
5284
5285         my $time = $ENV{'GIT_COMMITTER_DATE'} || time;
5286         $time =~ s/\s.*//; # trim timezone from GIT_COMMITTER_DATE
5287         my $ncommits = 3;
5288         my $msg = cmdoutput @git, qw(log), "-n$ncommits";
5289
5290         quiltify_dpkg_commit "auto-$version-$target-$time",
5291             (getfield $clogp, 'Maintainer'),
5292             "Automatically generated patch ($clogp->{Version})\n".
5293             "Last (up to) $ncommits git changes, FYI:\n\n". $msg;
5294         return;
5295     }
5296
5297     progress "quiltify linearisation planning successful, executing...";
5298
5299     for (my $p = $sref_S;
5300          my $c = $p->{Child};
5301          $p = $p->{Child}) {
5302         printdebug "quiltify traverse $p->{Commit}..$c->{Commit}\n";
5303         next unless $p->{Nontrivial};
5304
5305         my $cc = $c->{Commit};
5306
5307         my $commitdata = cmdoutput @git, qw(cat-file commit), $cc;
5308         $commitdata =~ m/\n\n/ or die "$c ?";
5309         $commitdata = $`;
5310         my $msg = $'; #';
5311         $commitdata =~ m/^author (.*) \d+ [-+0-9]+$/m or die "$cc ?";
5312         my $author = $1;
5313
5314         my $commitdate = cmdoutput
5315             @git, qw(log -n1 --pretty=format:%aD), $cc;
5316
5317         $msg =~ s/^(.*)\n*/$1\n/ or die "$cc $msg ?";
5318
5319         my $strip_nls = sub { $msg =~ s/\n+$//; $msg .= "\n"; };
5320         $strip_nls->();
5321
5322         my $title = $1;
5323         my $patchname;
5324         my $patchdir;
5325
5326         my $gbp_check_suitable = sub {
5327             $_ = shift;
5328             my ($what) = @_;
5329
5330             eval {
5331                 die "contains unexpected slashes\n" if m{//} || m{/$};
5332                 die "contains leading punctuation\n" if m{^\W} || m{/\W};
5333                 die "contains bad character(s)\n" if m{[^-a-z0-9_.+=~/]}i;
5334                 die "is series file\n" if m{$series_filename_re}o;
5335                 die "too long" if length > 200;
5336             };
5337             return $_ unless $@;
5338             print STDERR "quiltifying commit $cc:".
5339                 " ignoring/dropping Gbp-Pq $what: $@";
5340             return undef;
5341         };
5342
5343         if ($msg =~ s/^ (?: gbp(?:-pq)? : \s* name \s+ |
5344                            gbp-pq-name: \s* )
5345                        (\S+) \s* \n //ixm) {
5346             $patchname = $gbp_check_suitable->($1, 'Name');
5347         }
5348         if ($msg =~ s/^ (?: gbp(?:-pq)? : \s* topic \s+ |
5349                            gbp-pq-topic: \s* )
5350                        (\S+) \s* \n //ixm) {
5351             $patchdir = $gbp_check_suitable->($1, 'Topic');
5352         }
5353
5354         $strip_nls->();
5355
5356         if (!defined $patchname) {
5357             $patchname = $title;
5358             $patchname =~ s/[.:]$//;
5359             use Text::Iconv;
5360             eval {
5361                 my $converter = new Text::Iconv qw(UTF-8 ASCII//TRANSLIT);
5362                 my $translitname = $converter->convert($patchname);
5363                 die unless defined $translitname;
5364                 $patchname = $translitname;
5365             };
5366             print STDERR
5367                 "dgit: patch title transliteration error: $@"
5368                 if $@;
5369             $patchname =~ y/ A-Z/-a-z/;
5370             $patchname =~ y/-a-z0-9_.+=~//cd;
5371             $patchname =~ s/^\W/x-$&/;
5372             $patchname = substr($patchname,0,40);
5373             $patchname .= ".patch";
5374         }
5375         if (!defined $patchdir) {
5376             $patchdir = '';
5377         }
5378         if (length $patchdir) {
5379             $patchname = "$patchdir/$patchname";
5380         }
5381         if ($patchname =~ m{^(.*)/}) {
5382             mkpath "debian/patches/$1";
5383         }
5384
5385         my $index;
5386         for ($index='';
5387              stat "debian/patches/$patchname$index";
5388              $index++) { }
5389         $!==ENOENT or die "$patchname$index $!";
5390
5391         runcmd @git, qw(checkout -q), $cc;
5392
5393         # We use the tip's changelog so that dpkg-source doesn't
5394         # produce complaining messages from dpkg-parsechangelog.  None
5395         # of the information dpkg-source gets from the changelog is
5396         # actually relevant - it gets put into the original message
5397         # which dpkg-source provides our stunt editor, and then
5398         # overwritten.
5399         runcmd @git, qw(checkout -q), $target, qw(debian/changelog);
5400
5401         quiltify_dpkg_commit "$patchname$index", $author, $msg,
5402             "Date: $commitdate\n".
5403             "X-Dgit-Generated: $clogp->{Version} $cc\n";
5404
5405         runcmd @git, qw(checkout -q), $cc, qw(debian/changelog);
5406     }
5407
5408     runcmd @git, qw(checkout -q master);
5409 }
5410
5411 sub build_maybe_quilt_fixup () {
5412     my ($format,$fopts) = get_source_format;
5413     return unless madformat_wantfixup $format;
5414     # sigh
5415
5416     check_for_vendor_patches();
5417
5418     if (quiltmode_splitbrain) {
5419         fail <<END unless access_cfg_tagformats_can_splitbrain;
5420 quilt mode $quilt_mode requires split view so server needs to support
5421  both "new" and "maint" tag formats, but config says it doesn't.
5422 END
5423     }
5424
5425     my $clogp = parsechangelog();
5426     my $headref = git_rev_parse('HEAD');
5427
5428     prep_ud();
5429     changedir $playground;
5430
5431     my $upstreamversion = upstreamversion $version;
5432
5433     if ($fopts->{'single-debian-patch'}) {
5434         quilt_fixup_singlepatch($clogp, $headref, $upstreamversion);
5435     } else {
5436         quilt_fixup_multipatch($clogp, $headref, $upstreamversion);
5437     }
5438
5439     die 'bug' if $split_brain && !$need_split_build_invocation;
5440
5441     changedir $maindir;
5442     runcmd_ordryrun_local
5443         @git, qw(pull --ff-only -q), "$playground/work", qw(master);
5444 }
5445
5446 sub quilt_fixup_mkwork ($) {
5447     my ($headref) = @_;
5448
5449     mkdir "work" or die $!;
5450     changedir "work";
5451     mktree_in_ud_here();
5452     runcmd @git, qw(reset -q --hard), $headref;
5453 }
5454
5455 sub quilt_fixup_linkorigs ($$) {
5456     my ($upstreamversion, $fn) = @_;
5457     # calls $fn->($leafname);
5458
5459     foreach my $f (<$maindir/../*>) { #/){
5460         my $b=$f; $b =~ s{.*/}{};
5461         {
5462             local ($debuglevel) = $debuglevel-1;
5463             printdebug "QF linkorigs $b, $f ?\n";
5464         }
5465         next unless is_orig_file_of_vsn $b, $upstreamversion;
5466         printdebug "QF linkorigs $b, $f Y\n";
5467         link_ltarget $f, $b or die "$b $!";
5468         $fn->($b);
5469     }
5470 }
5471
5472 sub quilt_fixup_delete_pc () {
5473     runcmd @git, qw(rm -rqf .pc);
5474     commit_admin <<END
5475 Commit removal of .pc (quilt series tracking data)
5476
5477 [dgit ($our_version) upgrade quilt-remove-pc]
5478 END
5479 }
5480
5481 sub quilt_fixup_singlepatch ($$$) {
5482     my ($clogp, $headref, $upstreamversion) = @_;
5483
5484     progress "starting quiltify (single-debian-patch)";
5485
5486     # dpkg-source --commit generates new patches even if
5487     # single-debian-patch is in debian/source/options.  In order to
5488     # get it to generate debian/patches/debian-changes, it is
5489     # necessary to build the source package.
5490
5491     quilt_fixup_linkorigs($upstreamversion, sub { });
5492     quilt_fixup_mkwork($headref);
5493
5494     rmtree("debian/patches");
5495
5496     runcmd @dpkgsource, qw(-b .);
5497     changedir "..";
5498     runcmd @dpkgsource, qw(-x), (srcfn $version, ".dsc");
5499     rename srcfn("$upstreamversion", "/debian/patches"),
5500            "work/debian/patches";
5501
5502     changedir "work";
5503     commit_quilty_patch();
5504 }
5505
5506 sub quilt_make_fake_dsc ($) {
5507     my ($upstreamversion) = @_;
5508
5509     my $fakeversion="$upstreamversion-~~DGITFAKE";
5510
5511     my $fakedsc=new IO::File 'fake.dsc', '>' or die $!;
5512     print $fakedsc <<END or die $!;
5513 Format: 3.0 (quilt)
5514 Source: $package
5515 Version: $fakeversion
5516 Files:
5517 END
5518
5519     my $dscaddfile=sub {
5520         my ($b) = @_;
5521
5522         my $md = new Digest::MD5;
5523
5524         my $fh = new IO::File $b, '<' or die "$b $!";
5525         stat $fh or die $!;
5526         my $size = -s _;
5527
5528         $md->addfile($fh);
5529         print $fakedsc " ".$md->hexdigest." $size $b\n" or die $!;
5530     };
5531
5532     quilt_fixup_linkorigs($upstreamversion, $dscaddfile);
5533
5534     my @files=qw(debian/source/format debian/rules
5535                  debian/control debian/changelog);
5536     foreach my $maybe (qw(debian/patches debian/source/options
5537                           debian/tests/control)) {
5538         next unless stat_exists "$maindir/$maybe";
5539         push @files, $maybe;
5540     }
5541
5542     my $debtar= srcfn $fakeversion,'.debian.tar.gz';
5543     runcmd qw(env GZIP=-1n tar -zcf), "./$debtar", qw(-C), $maindir, @files;
5544
5545     $dscaddfile->($debtar);
5546     close $fakedsc or die $!;
5547 }
5548
5549 sub quilt_check_splitbrain_cache ($$) {
5550     my ($headref, $upstreamversion) = @_;
5551     # Called only if we are in (potentially) split brain mode.
5552     # Called in playground.
5553     # Computes the cache key and looks in the cache.
5554     # Returns ($dgit_view_commitid, $cachekey) or (undef, $cachekey)
5555
5556     my $splitbrain_cachekey;
5557
5558     progress
5559  "dgit: split brain (separate dgit view) may be needed (--quilt=$quilt_mode).";
5560     # we look in the reflog of dgit-intern/quilt-cache
5561     # we look for an entry whose message is the key for the cache lookup
5562     my @cachekey = (qw(dgit), $our_version);
5563     push @cachekey, $upstreamversion;
5564     push @cachekey, $quilt_mode;
5565     push @cachekey, $headref;
5566
5567     push @cachekey, hashfile('fake.dsc');
5568
5569     my $srcshash = Digest::SHA->new(256);
5570     my %sfs = ( %INC, '$0(dgit)' => $0 );
5571     foreach my $sfk (sort keys %sfs) {
5572         next unless $sfk =~ m/^\$0\b/ || $sfk =~ m{^Debian/Dgit\b};
5573         $srcshash->add($sfk,"  ");
5574         $srcshash->add(hashfile($sfs{$sfk}));
5575         $srcshash->add("\n");
5576     }
5577     push @cachekey, $srcshash->hexdigest();
5578     $splitbrain_cachekey = "@cachekey";
5579
5580     my @cmd = (@git, qw(log -g), '--pretty=format:%H %gs',
5581                $splitbraincache);
5582     printdebug "splitbrain cachekey $splitbrain_cachekey\n";
5583     debugcmd "|(probably)",@cmd;
5584     my $child = open GC, "-|";  defined $child or die $!;
5585     if (!$child) {
5586         chdir $maindir or die $!;
5587         if (!stat "$maindir_gitcommon/logs/refs/$splitbraincache") {
5588             $! == ENOENT or die $!;
5589             printdebug ">(no reflog)\n";
5590             exit 0;
5591         }
5592         exec @cmd; die $!;
5593     }
5594     while (<GC>) {
5595         chomp;
5596         printdebug ">| ", $_, "\n" if $debuglevel > 1;
5597         next unless m/^(\w+) (\S.*\S)$/ && $2 eq $splitbrain_cachekey;
5598
5599         my $cachehit = $1;
5600         quilt_fixup_mkwork($headref);
5601         my $saved = maybe_split_brain_save $headref, $cachehit, "cache-hit";
5602         if ($cachehit ne $headref) {
5603             progress "dgit view: found cached ($saved)";
5604             runcmd @git, qw(checkout -q -b dgit-view), $cachehit;
5605             $split_brain = 1;
5606             return ($cachehit, $splitbrain_cachekey);
5607         }
5608         progress "dgit view: found cached, no changes required";
5609         return ($headref, $splitbrain_cachekey);
5610     }
5611     die $! if GC->error;
5612     failedcmd unless close GC;
5613
5614     printdebug "splitbrain cache miss\n";
5615     return (undef, $splitbrain_cachekey);
5616 }
5617
5618 sub quilt_fixup_multipatch ($$$) {
5619     my ($clogp, $headref, $upstreamversion) = @_;
5620
5621     progress "examining quilt state (multiple patches, $quilt_mode mode)";
5622
5623     # Our objective is:
5624     #  - honour any existing .pc in case it has any strangeness
5625     #  - determine the git commit corresponding to the tip of
5626     #    the patch stack (if there is one)
5627     #  - if there is such a git commit, convert each subsequent
5628     #    git commit into a quilt patch with dpkg-source --commit
5629     #  - otherwise convert all the differences in the tree into
5630     #    a single git commit
5631     #
5632     # To do this we:
5633
5634     # Our git tree doesn't necessarily contain .pc.  (Some versions of
5635     # dgit would include the .pc in the git tree.)  If there isn't
5636     # one, we need to generate one by unpacking the patches that we
5637     # have.
5638     #
5639     # We first look for a .pc in the git tree.  If there is one, we
5640     # will use it.  (This is not the normal case.)
5641     #
5642     # Otherwise need to regenerate .pc so that dpkg-source --commit
5643     # can work.  We do this as follows:
5644     #     1. Collect all relevant .orig from parent directory
5645     #     2. Generate a debian.tar.gz out of
5646     #         debian/{patches,rules,source/format,source/options}
5647     #     3. Generate a fake .dsc containing just these fields:
5648     #          Format Source Version Files
5649     #     4. Extract the fake .dsc
5650     #        Now the fake .dsc has a .pc directory.
5651     # (In fact we do this in every case, because in future we will
5652     # want to search for a good base commit for generating patches.)
5653     #
5654     # Then we can actually do the dpkg-source --commit
5655     #     1. Make a new working tree with the same object
5656     #        store as our main tree and check out the main
5657     #        tree's HEAD.
5658     #     2. Copy .pc from the fake's extraction, if necessary
5659     #     3. Run dpkg-source --commit
5660     #     4. If the result has changes to debian/, then
5661     #          - git add them them
5662     #          - git add .pc if we had a .pc in-tree
5663     #          - git commit
5664     #     5. If we had a .pc in-tree, delete it, and git commit
5665     #     6. Back in the main tree, fast forward to the new HEAD
5666
5667     # Another situation we may have to cope with is gbp-style
5668     # patches-unapplied trees.
5669     #
5670     # We would want to detect these, so we know to escape into
5671     # quilt_fixup_gbp.  However, this is in general not possible.
5672     # Consider a package with a one patch which the dgit user reverts
5673     # (with git revert or the moral equivalent).
5674     #
5675     # That is indistinguishable in contents from a patches-unapplied
5676     # tree.  And looking at the history to distinguish them is not
5677     # useful because the user might have made a confusing-looking git
5678     # history structure (which ought to produce an error if dgit can't
5679     # cope, not a silent reintroduction of an unwanted patch).
5680     #
5681     # So gbp users will have to pass an option.  But we can usually
5682     # detect their failure to do so: if the tree is not a clean
5683     # patches-applied tree, quilt linearisation fails, but the tree
5684     # _is_ a clean patches-unapplied tree, we can suggest that maybe
5685     # they want --quilt=unapplied.
5686     #
5687     # To help detect this, when we are extracting the fake dsc, we
5688     # first extract it with --skip-patches, and then apply the patches
5689     # afterwards with dpkg-source --before-build.  That lets us save a
5690     # tree object corresponding to .origs.
5691
5692     my $splitbrain_cachekey;
5693
5694     quilt_make_fake_dsc($upstreamversion);
5695
5696     if (quiltmode_splitbrain()) {
5697         my $cachehit;
5698         ($cachehit, $splitbrain_cachekey) =
5699             quilt_check_splitbrain_cache($headref, $upstreamversion);
5700         return if $cachehit;
5701     }
5702
5703     runcmd qw(sh -ec),
5704         'exec dpkg-source --no-check --skip-patches -x fake.dsc >/dev/null';
5705
5706     my $fakexdir= $package.'-'.(stripepoch $upstreamversion);
5707     rename $fakexdir, "fake" or die "$fakexdir $!";
5708
5709     changedir 'fake';
5710
5711     remove_stray_gits("source package");
5712     mktree_in_ud_here();
5713
5714     rmtree '.pc';
5715
5716     runcmd @git, qw(checkout -f), $headref, qw(-- debian);
5717     my $unapplied=git_add_write_tree();
5718     printdebug "fake orig tree object $unapplied\n";
5719
5720     ensuredir '.pc';
5721
5722     my @bbcmd = (qw(sh -ec), 'exec dpkg-source --before-build . >/dev/null');
5723     $!=0; $?=-1;
5724     if (system @bbcmd) {
5725         failedcmd @bbcmd if $? < 0;
5726         fail <<END;
5727 failed to apply your git tree's patch stack (from debian/patches/) to
5728  the corresponding upstream tarball(s).  Your source tree and .orig
5729  are probably too inconsistent.  dgit can only fix up certain kinds of
5730  anomaly (depending on the quilt mode).  See --quilt= in dgit(1).
5731 END
5732     }
5733
5734     changedir '..';
5735
5736     quilt_fixup_mkwork($headref);
5737
5738     my $mustdeletepc=0;
5739     if (stat_exists ".pc") {
5740         -d _ or die;
5741         progress "Tree already contains .pc - will use it then delete it.";
5742         $mustdeletepc=1;
5743     } else {
5744         rename '../fake/.pc','.pc' or die $!;
5745     }
5746
5747     changedir '../fake';
5748     rmtree '.pc';
5749     my $oldtiptree=git_add_write_tree();
5750     printdebug "fake o+d/p tree object $unapplied\n";
5751     changedir '../work';
5752
5753
5754     # We calculate some guesswork now about what kind of tree this might
5755     # be.  This is mostly for error reporting.
5756
5757     my %editedignores;
5758     my @unrepres;
5759     my $diffbits = {
5760         # H = user's HEAD
5761         # O = orig, without patches applied
5762         # A = "applied", ie orig with H's debian/patches applied
5763         O2H => quiltify_trees_differ($unapplied,$headref,   1,
5764                                      \%editedignores, \@unrepres),
5765         H2A => quiltify_trees_differ($headref,  $oldtiptree,1),
5766         O2A => quiltify_trees_differ($unapplied,$oldtiptree,1),
5767     };
5768
5769     my @dl;
5770     foreach my $b (qw(01 02)) {
5771         foreach my $v (qw(O2H O2A H2A)) {
5772             push @dl, ($diffbits->{$v} & $b) ? '##' : '==';
5773         }
5774     }
5775     printdebug "differences \@dl @dl.\n";
5776
5777     progress sprintf
5778 "$us: base trees orig=%.20s o+d/p=%.20s",
5779               $unapplied, $oldtiptree;
5780     progress sprintf
5781 "$us: quilt differences: src:  %s orig %s     gitignores:  %s orig %s\n".
5782 "$us: quilt differences:      HEAD %s o+d/p               HEAD %s o+d/p",
5783                              $dl[0], $dl[1],              $dl[3], $dl[4],
5784                                  $dl[2],                     $dl[5];
5785
5786     if (@unrepres) {
5787         print STDERR "dgit:  cannot represent change: $_->[1]: $_->[0]\n"
5788             foreach @unrepres;
5789         forceable_fail [qw(unrepresentable)], <<END;
5790 HEAD has changes to .orig[s] which are not representable by `3.0 (quilt)'
5791 END
5792     }
5793
5794     my @failsuggestion;
5795     if (!($diffbits->{O2H} & $diffbits->{O2A})) {
5796         push @failsuggestion, "This might be a patches-unapplied branch.";
5797     }  elsif (!($diffbits->{H2A} & $diffbits->{O2A})) {
5798         push @failsuggestion, "This might be a patches-applied branch.";
5799     }
5800     push @failsuggestion, "Maybe you need to specify one of".
5801         " --[quilt=]gbp --[quilt=]dpm --quilt=unapplied ?";
5802
5803     if (quiltmode_splitbrain()) {
5804         quiltify_splitbrain($clogp, $unapplied, $headref,
5805                             $diffbits, \%editedignores,
5806                             $splitbrain_cachekey);
5807         return;
5808     }
5809
5810     progress "starting quiltify (multiple patches, $quilt_mode mode)";
5811     quiltify($clogp,$headref,$oldtiptree,\@failsuggestion);
5812
5813     if (!open P, '>>', ".pc/applied-patches") {
5814         $!==&ENOENT or die $!;
5815     } else {
5816         close P;
5817     }
5818
5819     commit_quilty_patch();
5820
5821     if ($mustdeletepc) {
5822         quilt_fixup_delete_pc();
5823     }
5824 }
5825
5826 sub quilt_fixup_editor () {
5827     my $descfn = $ENV{$fakeeditorenv};
5828     my $editing = $ARGV[$#ARGV];
5829     open I1, '<', $descfn or die "$descfn: $!";
5830     open I2, '<', $editing or die "$editing: $!";
5831     unlink $editing or die "$editing: $!";
5832     open O, '>', $editing or die "$editing: $!";
5833     while (<I1>) { print O or die $!; } I1->error and die $!;
5834     my $copying = 0;
5835     while (<I2>) {
5836         $copying ||= m/^\-\-\- /;
5837         next unless $copying;
5838         print O or die $!;
5839     }
5840     I2->error and die $!;
5841     close O or die $1;
5842     exit 0;
5843 }
5844
5845 sub maybe_apply_patches_dirtily () {
5846     return unless $quilt_mode =~ m/gbp|unapplied/;
5847     print STDERR <<END or die $!;
5848
5849 dgit: Building, or cleaning with rules target, in patches-unapplied tree.
5850 dgit: Have to apply the patches - making the tree dirty.
5851 dgit: (Consider specifying --clean=git and (or) using dgit sbuild.)
5852
5853 END
5854     $patches_applied_dirtily = 01;
5855     $patches_applied_dirtily |= 02 unless stat_exists '.pc';
5856     runcmd qw(dpkg-source --before-build .);
5857 }
5858
5859 sub maybe_unapply_patches_again () {
5860     progress "dgit: Unapplying patches again to tidy up the tree."
5861         if $patches_applied_dirtily;
5862     runcmd qw(dpkg-source --after-build .)
5863         if $patches_applied_dirtily & 01;
5864     rmtree '.pc'
5865         if $patches_applied_dirtily & 02;
5866     $patches_applied_dirtily = 0;
5867 }
5868
5869 #----- other building -----
5870
5871 our $clean_using_builder;
5872 # ^ tree is to be cleaned by dpkg-source's builtin idea that it should
5873 #   clean the tree before building (perhaps invoked indirectly by
5874 #   whatever we are using to run the build), rather than separately
5875 #   and explicitly by us.
5876
5877 sub clean_tree () {
5878     return if $clean_using_builder;
5879     if ($cleanmode eq 'dpkg-source') {
5880         maybe_apply_patches_dirtily();
5881         runcmd_ordryrun_local @dpkgbuildpackage, qw(-T clean);
5882     } elsif ($cleanmode eq 'dpkg-source-d') {
5883         maybe_apply_patches_dirtily();
5884         runcmd_ordryrun_local @dpkgbuildpackage, qw(-d -T clean);
5885     } elsif ($cleanmode eq 'git') {
5886         runcmd_ordryrun_local @git, qw(clean -xdf);
5887     } elsif ($cleanmode eq 'git-ff') {
5888         runcmd_ordryrun_local @git, qw(clean -xdff);
5889     } elsif ($cleanmode eq 'check') {
5890         my $leftovers = cmdoutput @git, qw(clean -xdn);
5891         if (length $leftovers) {
5892             print STDERR $leftovers, "\n" or die $!;
5893             fail "tree contains uncommitted files and --clean=check specified";
5894         }
5895     } elsif ($cleanmode eq 'none') {
5896     } else {
5897         die "$cleanmode ?";
5898     }
5899 }
5900
5901 sub cmd_clean () {
5902     badusage "clean takes no additional arguments" if @ARGV;
5903     notpushing();
5904     clean_tree();
5905     maybe_unapply_patches_again();
5906 }
5907
5908 sub build_or_push_prep_early () {
5909     our $build_or_push_prep_early_done //= 0;
5910     return if $build_or_push_prep_early_done++;
5911     badusage "-p is not allowed with dgit $subcommand" if defined $package;
5912     my $clogp = parsechangelog();
5913     $isuite = getfield $clogp, 'Distribution';
5914     $package = getfield $clogp, 'Source';
5915     $version = getfield $clogp, 'Version';
5916 }
5917
5918 sub build_prep_early () {
5919     build_or_push_prep_early();
5920     notpushing();
5921     check_not_dirty();
5922 }
5923
5924 sub build_prep () {
5925     build_prep_early();
5926     clean_tree();
5927     build_maybe_quilt_fixup();
5928     if ($rmchanges) {
5929         my $pat = changespat $version;
5930         foreach my $f (glob "$buildproductsdir/$pat") {
5931             if (act_local()) {
5932                 unlink $f or fail "remove old changes file $f: $!";
5933             } else {
5934                 progress "would remove $f";
5935             }
5936         }
5937     }
5938 }
5939
5940 sub changesopts_initial () {
5941     my @opts =@changesopts[1..$#changesopts];
5942 }
5943
5944 sub changesopts_version () {
5945     if (!defined $changes_since_version) {
5946         my @vsns = archive_query('archive_query');
5947         my @quirk = access_quirk();
5948         if ($quirk[0] eq 'backports') {
5949             local $isuite = $quirk[2];
5950             local $csuite;
5951             canonicalise_suite();
5952             push @vsns, archive_query('archive_query');
5953         }
5954         if (@vsns) {
5955             @vsns = map { $_->[0] } @vsns;
5956             @vsns = sort { -version_compare($a, $b) } @vsns;
5957             $changes_since_version = $vsns[0];
5958             progress "changelog will contain changes since $vsns[0]";
5959         } else {
5960             $changes_since_version = '_';
5961             progress "package seems new, not specifying -v<version>";
5962         }
5963     }
5964     if ($changes_since_version ne '_') {
5965         return ("-v$changes_since_version");
5966     } else {
5967         return ();
5968     }
5969 }
5970
5971 sub changesopts () {
5972     return (changesopts_initial(), changesopts_version());
5973 }
5974
5975 sub massage_dbp_args ($;$) {
5976     my ($cmd,$xargs) = @_;
5977     # We need to:
5978     #
5979     #  - if we're going to split the source build out so we can
5980     #    do strange things to it, massage the arguments to dpkg-buildpackage
5981     #    so that the main build doessn't build source (or add an argument
5982     #    to stop it building source by default).
5983     #
5984     #  - add -nc to stop dpkg-source cleaning the source tree,
5985     #    unless we're not doing a split build and want dpkg-source
5986     #    as cleanmode, in which case we can do nothing
5987     #
5988     # return values:
5989     #    0 - source will NOT need to be built separately by caller
5990     #   +1 - source will need to be built separately by caller
5991     #   +2 - source will need to be built separately by caller AND
5992     #        dpkg-buildpackage should not in fact be run at all!
5993     debugcmd '#massaging#', @$cmd if $debuglevel>1;
5994 #print STDERR "MASS0 ",Dumper($cmd, $xargs, $need_split_build_invocation);
5995     if ($cleanmode eq 'dpkg-source' && !$need_split_build_invocation) {
5996         $clean_using_builder = 1;
5997         return 0;
5998     }
5999     # -nc has the side effect of specifying -b if nothing else specified
6000     # and some combinations of -S, -b, et al, are errors, rather than
6001     # later simply overriding earlie.  So we need to:
6002     #  - search the command line for these options
6003     #  - pick the last one
6004     #  - perhaps add our own as a default
6005     #  - perhaps adjust it to the corresponding non-source-building version
6006     my $dmode = '-F';
6007     foreach my $l ($cmd, $xargs) {
6008         next unless $l;
6009         @$l = grep { !(m/^-[SgGFABb]$/s and $dmode=$_) } @$l;
6010     }
6011     push @$cmd, '-nc';
6012 #print STDERR "MASS1 ",Dumper($cmd, $xargs, $dmode);
6013     my $r = 0;
6014     if ($need_split_build_invocation) {
6015         printdebug "massage split $dmode.\n";
6016         $r = $dmode =~ m/[S]/     ? +2 :
6017              $dmode =~ y/gGF/ABb/ ? +1 :
6018              $dmode =~ m/[ABb]/   ?  0 :
6019              die "$dmode ?";
6020     }
6021     printdebug "massage done $r $dmode.\n";
6022     push @$cmd, $dmode;
6023 #print STDERR "MASS2 ",Dumper($cmd, $xargs, $r);
6024     return $r;
6025 }
6026
6027 sub in_parent (&) {
6028     my ($fn) = @_;
6029     my $wasdir = must_getcwd();
6030     changedir "..";
6031     $fn->();
6032     changedir $wasdir;
6033 }
6034
6035 sub postbuild_mergechanges ($) { # must run with CWD=.. (eg in in_parent)
6036     my ($msg_if_onlyone) = @_;
6037     # If there is only one .changes file, fail with $msg_if_onlyone,
6038     # or if that is undef, be a no-op.
6039     # Returns the changes file to report to the user.
6040     my $pat = changespat $version;
6041     my @changesfiles = glob $pat;
6042     @changesfiles = sort {
6043         ($b =~ m/_source\.changes$/ <=> $a =~ m/_source\.changes$/)
6044             or $a cmp $b
6045     } @changesfiles;
6046     my $result;
6047     if (@changesfiles==1) {
6048         fail <<END.$msg_if_onlyone if defined $msg_if_onlyone;
6049 only one changes file from build (@changesfiles)
6050 END
6051         $result = $changesfiles[0];
6052     } elsif (@changesfiles==2) {
6053         my $binchanges = parsecontrol($changesfiles[1], "binary changes file");
6054         foreach my $l (split /\n/, getfield $binchanges, 'Files') {
6055             fail "$l found in binaries changes file $binchanges"
6056                 if $l =~ m/\.dsc$/;
6057         }
6058         runcmd_ordryrun_local @mergechanges, @changesfiles;
6059         my $multichanges = changespat $version,'multi';
6060         if (act_local()) {
6061             stat_exists $multichanges or fail "$multichanges: $!";
6062             foreach my $cf (glob $pat) {
6063                 next if $cf eq $multichanges;
6064                 rename "$cf", "$cf.inmulti" or fail "$cf\{,.inmulti}: $!";
6065             }
6066         }
6067         $result = $multichanges;
6068     } else {
6069         fail "wrong number of different changes files (@changesfiles)";
6070     }
6071     printdone "build successful, results in $result\n" or die $!;
6072 }
6073
6074 sub midbuild_checkchanges () {
6075     my $pat = changespat $version;
6076     return if $rmchanges;
6077     my @unwanted = map { s#^\.\./##; $_; } glob "../$pat";
6078     @unwanted = grep { $_ ne changespat $version,'source' } @unwanted;
6079     fail <<END
6080 changes files other than source matching $pat already present; building would result in ambiguity about the intended results.
6081 Suggest you delete @unwanted.
6082 END
6083         if @unwanted;
6084 }
6085
6086 sub midbuild_checkchanges_vanilla ($) {
6087     my ($wantsrc) = @_;
6088     midbuild_checkchanges() if $wantsrc == 1;
6089 }
6090
6091 sub postbuild_mergechanges_vanilla ($) {
6092     my ($wantsrc) = @_;
6093     if ($wantsrc == 1) {
6094         in_parent {
6095             postbuild_mergechanges(undef);
6096         };
6097     } else {
6098         printdone "build successful\n";
6099     }
6100 }
6101
6102 sub cmd_build {
6103     build_prep_early();
6104     my @dbp = (@dpkgbuildpackage, qw(-us -uc), changesopts_initial(), @ARGV);
6105     my $wantsrc = massage_dbp_args \@dbp;
6106     if ($wantsrc > 0) {
6107         build_source();
6108         midbuild_checkchanges_vanilla $wantsrc;
6109     } else {
6110         build_prep();
6111     }
6112     if ($wantsrc < 2) {
6113         push @dbp, changesopts_version();
6114         maybe_apply_patches_dirtily();
6115         runcmd_ordryrun_local @dbp;
6116     }
6117     maybe_unapply_patches_again();
6118     postbuild_mergechanges_vanilla $wantsrc;
6119 }
6120
6121 sub pre_gbp_build {
6122     $quilt_mode //= 'gbp';
6123 }
6124
6125 sub cmd_gbp_build {
6126     build_prep_early();
6127
6128     # gbp can make .origs out of thin air.  In my tests it does this
6129     # even for a 1.0 format package, with no origs present.  So I
6130     # guess it keys off just the version number.  We don't know
6131     # exactly what .origs ought to exist, but let's assume that we
6132     # should run gbp if: the version has an upstream part and the main
6133     # orig is absent.
6134     my $upstreamversion = upstreamversion $version;
6135     my $origfnpat = srcfn $upstreamversion, '.orig.tar.*';
6136     my $gbp_make_orig = $version =~ m/-/ && !(() = glob "../$origfnpat");
6137
6138     if ($gbp_make_orig) {
6139         clean_tree();
6140         $cleanmode = 'none'; # don't do it again
6141         $need_split_build_invocation = 1;
6142     }
6143
6144     my @dbp = @dpkgbuildpackage;
6145
6146     my $wantsrc = massage_dbp_args \@dbp, \@ARGV;
6147
6148     if (!length $gbp_build[0]) {
6149         if (length executable_on_path('git-buildpackage')) {
6150             $gbp_build[0] = qw(git-buildpackage);
6151         } else {
6152             $gbp_build[0] = 'gbp buildpackage';
6153         }
6154     }
6155     my @cmd = opts_opt_multi_cmd @gbp_build;
6156
6157     push @cmd, (qw(-us -uc --git-no-sign-tags),
6158                 "--git-builder=".(shellquote @dbp));
6159
6160     if ($gbp_make_orig) {
6161         my $priv = dgit_privdir();
6162         my $ok = "$priv/origs-gen-ok";
6163         unlink $ok or $!==&ENOENT or die $!;
6164         my @origs_cmd = @cmd;
6165         push @origs_cmd, qw(--git-cleaner=true);
6166         push @origs_cmd, "--git-prebuild=".
6167             "touch ".(shellquote $ok)." ".(shellquote "$priv/no-such-dir/ok");
6168         push @origs_cmd, @ARGV;
6169         if (act_local()) {
6170             debugcmd @origs_cmd;
6171             system @origs_cmd;
6172             do { local $!; stat_exists $ok; }
6173                 or failedcmd @origs_cmd;
6174         } else {
6175             dryrun_report @origs_cmd;
6176         }
6177     }
6178
6179     if ($wantsrc > 0) {
6180         build_source();
6181         midbuild_checkchanges_vanilla $wantsrc;
6182     } else {
6183         if (!$clean_using_builder) {
6184             push @cmd, '--git-cleaner=true';
6185         }
6186         build_prep();
6187     }
6188     maybe_unapply_patches_again();
6189     if ($wantsrc < 2) {
6190         push @cmd, changesopts();
6191         runcmd_ordryrun_local @cmd, @ARGV;
6192     }
6193     postbuild_mergechanges_vanilla $wantsrc;
6194 }
6195 sub cmd_git_build { cmd_gbp_build(); } # compatibility with <= 1.0
6196
6197 sub build_source_for_push {
6198     build_source();
6199     maybe_unapply_patches_again();
6200     $changesfile = $sourcechanges;
6201 }
6202
6203 sub build_source {
6204     build_prep_early();
6205     build_prep();
6206     $sourcechanges = changespat $version,'source';
6207     if (act_local()) {
6208         unlink "../$sourcechanges" or $!==ENOENT
6209             or fail "remove $sourcechanges: $!";
6210     }
6211     $dscfn = dscfn($version);
6212     my @cmd = (@dpkgsource, qw(-b --));
6213     if ($split_brain) {
6214         changedir $playground;
6215         runcmd_ordryrun_local @cmd, "work";
6216         my @udfiles = <${package}_*>;
6217         changedir $maindir;
6218         foreach my $f (@udfiles) {
6219             printdebug "source copy, found $f\n";
6220             next unless
6221               $f eq $dscfn or
6222               ($f =~ m/\.debian\.tar(?:\.\w+)$/ &&
6223                $f eq srcfn($version, $&));
6224             printdebug "source copy, found $f - renaming\n";
6225             rename "$playground/$f", "../$f" or $!==ENOENT
6226               or fail "put in place new source file ($f): $!";
6227         }
6228     } else {
6229         my $pwd = must_getcwd();
6230         my $leafdir = basename $pwd;
6231         changedir "..";
6232         runcmd_ordryrun_local @cmd, $leafdir;
6233         changedir $pwd;
6234     }
6235     runcmd_ordryrun_local qw(sh -ec),
6236       'exec >$1; shift; exec "$@"','x',
6237       "../$sourcechanges",
6238       @dpkggenchanges, qw(-S), changesopts();
6239 }
6240
6241 sub cmd_build_source {
6242     build_prep_early();
6243     badusage "build-source takes no additional arguments" if @ARGV;
6244     build_source();
6245     maybe_unapply_patches_again();
6246     printdone "source built, results in $dscfn and $sourcechanges";
6247 }
6248
6249 sub cmd_sbuild {
6250     build_source();
6251     midbuild_checkchanges();
6252     in_parent {
6253         if (act_local()) {
6254             stat_exists $dscfn or fail "$dscfn (in parent directory): $!";
6255             stat_exists $sourcechanges
6256                 or fail "$sourcechanges (in parent directory): $!";
6257         }
6258         runcmd_ordryrun_local @sbuild, qw(-d), $isuite, @ARGV, $dscfn;
6259     };
6260     maybe_unapply_patches_again();
6261     in_parent {
6262         postbuild_mergechanges(<<END);
6263 perhaps you need to pass -A ?  (sbuild's default is to build only
6264 arch-specific binaries; dgit 1.4 used to override that.)
6265 END
6266     };
6267 }
6268
6269 sub cmd_quilt_fixup {
6270     badusage "incorrect arguments to dgit quilt-fixup" if @ARGV;
6271     build_prep_early();
6272     clean_tree();
6273     build_maybe_quilt_fixup();
6274 }
6275
6276 sub import_dsc_result {
6277     my ($dstref, $newhash, $what_log, $what_msg) = @_;
6278     my @cmd = (@git, qw(update-ref -m), $what_log, $dstref, $newhash);
6279     runcmd @cmd;
6280     check_gitattrs($newhash, "source tree");
6281
6282     progress "dgit: import-dsc: $what_msg";
6283 }
6284
6285 sub cmd_import_dsc {
6286     my $needsig = 0;
6287
6288     while (@ARGV) {
6289         last unless $ARGV[0] =~ m/^-/;
6290         $_ = shift @ARGV;
6291         last if m/^--?$/;
6292         if (m/^--require-valid-signature$/) {
6293             $needsig = 1;
6294         } else {
6295             badusage "unknown dgit import-dsc sub-option \`$_'";
6296         }
6297     }
6298
6299     badusage "usage: dgit import-dsc .../PATH/TO/.DSC BRANCH" unless @ARGV==2;
6300     my ($dscfn, $dstbranch) = @ARGV;
6301
6302     badusage "dry run makes no sense with import-dsc" unless act_local();
6303
6304     my $force = $dstbranch =~ s/^\+//   ? +1 :
6305                 $dstbranch =~ s/^\.\.// ? -1 :
6306                                            0;
6307     my $info = $force ? " $&" : '';
6308     $info = "$dscfn$info";
6309
6310     my $specbranch = $dstbranch;
6311     $dstbranch = "refs/heads/$dstbranch" unless $dstbranch =~ m#^refs/#;
6312     $dstbranch = cmdoutput @git, qw(check-ref-format --normalize), $dstbranch;
6313
6314     my @symcmd = (@git, qw(symbolic-ref -q HEAD));
6315     my $chead = cmdoutput_errok @symcmd;
6316     defined $chead or $?==256 or failedcmd @symcmd;
6317
6318     fail "$dstbranch is checked out - will not update it"
6319         if defined $chead and $chead eq $dstbranch;
6320
6321     my $oldhash = git_get_ref $dstbranch;
6322
6323     open D, "<", $dscfn or fail "open import .dsc ($dscfn): $!";
6324     $dscdata = do { local $/ = undef; <D>; };
6325     D->error and fail "read $dscfn: $!";
6326     close C;
6327
6328     # we don't normally need this so import it here
6329     use Dpkg::Source::Package;
6330     my $dp = new Dpkg::Source::Package filename => $dscfn,
6331         require_valid_signature => $needsig;
6332     {
6333         local $SIG{__WARN__} = sub {
6334             print STDERR $_[0];
6335             return unless $needsig;
6336             fail "import-dsc signature check failed";
6337         };
6338         if (!$dp->is_signed()) {
6339             warn "$us: warning: importing unsigned .dsc\n";
6340         } else {
6341             my $r = $dp->check_signature();
6342             die "->check_signature => $r" if $needsig && $r;
6343         }
6344     }
6345
6346     parse_dscdata();
6347
6348     $package = getfield $dsc, 'Source';
6349
6350     parse_dsc_field($dsc, "Dgit metadata in .dsc")
6351         unless forceing [qw(import-dsc-with-dgit-field)];
6352     parse_dsc_field_def_dsc_distro();
6353
6354     $isuite = 'DGIT-IMPORT-DSC';
6355     $idistro //= $dsc_distro;
6356
6357     notpushing();
6358
6359     if (defined $dsc_hash) {
6360         progress "dgit: import-dsc of .dsc with Dgit field, using git hash";
6361         resolve_dsc_field_commit undef, undef;
6362     }
6363     if (defined $dsc_hash) {
6364         my @cmd = (qw(sh -ec),
6365                    "echo $dsc_hash | git cat-file --batch-check");
6366         my $objgot = cmdoutput @cmd;
6367         if ($objgot =~ m#^\w+ missing\b#) {
6368             fail <<END
6369 .dsc contains Dgit field referring to object $dsc_hash
6370 Your git tree does not have that object.  Try `git fetch' from a
6371 plausible server (browse.dgit.d.o? alioth?), and try the import-dsc again.
6372 END
6373         }
6374         if ($oldhash && !is_fast_fwd $oldhash, $dsc_hash) {
6375             if ($force > 0) {
6376                 progress "Not fast forward, forced update.";
6377             } else {
6378                 fail "Not fast forward to $dsc_hash";
6379             }
6380         }
6381         import_dsc_result $dstbranch, $dsc_hash,
6382             "dgit import-dsc (Dgit): $info",
6383             "updated git ref $dstbranch";
6384         return 0;
6385     }
6386
6387     fail <<END
6388 Branch $dstbranch already exists
6389 Specify ..$specbranch for a pseudo-merge, binding in existing history
6390 Specify  +$specbranch to overwrite, discarding existing history
6391 END
6392         if $oldhash && !$force;
6393
6394     my @dfi = dsc_files_info();
6395     foreach my $fi (@dfi) {
6396         my $f = $fi->{Filename};
6397         my $here = "../$f";
6398         if (lstat $here) {
6399             next if stat $here;
6400             fail "lstat $here works but stat gives $! !";
6401         }
6402         fail "stat $here: $!" unless $! == ENOENT;
6403         my $there = $dscfn;
6404         if ($dscfn =~ m#^(?:\./+)?\.\./+#) {
6405             $there = $';
6406         } elsif ($dscfn =~ m#^/#) {
6407             $there = $dscfn;
6408         } else {
6409             fail "cannot import $dscfn which seems to be inside working tree!";
6410         }
6411         $there =~ s#/+[^/]+$## or
6412             fail "import $dscfn requires ../$f, but it does not exist";
6413         $there .= "/$f";
6414         my $test = $there =~ m{^/} ? $there : "../$there";
6415         stat $test or fail "import $dscfn requires $test, but: $!";
6416         symlink $there, $here or fail "symlink $there to $here: $!";
6417         progress "made symlink $here -> $there";
6418 #       print STDERR Dumper($fi);
6419     }
6420     my @mergeinputs = generate_commits_from_dsc();
6421     die unless @mergeinputs == 1;
6422
6423     my $newhash = $mergeinputs[0]{Commit};
6424
6425     if ($oldhash) {
6426         if ($force > 0) {
6427             progress "Import, forced update - synthetic orphan git history.";
6428         } elsif ($force < 0) {
6429             progress "Import, merging.";
6430             my $tree = cmdoutput @git, qw(rev-parse), "$newhash:";
6431             my $version = getfield $dsc, 'Version';
6432             my $clogp = commit_getclogp $newhash;
6433             my $authline = clogp_authline $clogp;
6434             $newhash = make_commit_text <<END;
6435 tree $tree
6436 parent $newhash
6437 parent $oldhash
6438 author $authline
6439 committer $authline
6440
6441 Merge $package ($version) import into $dstbranch
6442 END
6443         } else {
6444             die; # caught earlier
6445         }
6446     }
6447
6448     import_dsc_result $dstbranch, $newhash,
6449         "dgit import-dsc: $info",
6450         "results are in in git ref $dstbranch";
6451 }
6452
6453 sub pre_archive_api_query () {
6454     not_necessarily_a_tree();
6455 }
6456 sub cmd_archive_api_query {
6457     badusage "need only 1 subpath argument" unless @ARGV==1;
6458     my ($subpath) = @ARGV;
6459     local $isuite = 'DGIT-API-QUERY-CMD';
6460     my @cmd = archive_api_query_cmd($subpath);
6461     push @cmd, qw(-f);
6462     debugcmd ">",@cmd;
6463     exec @cmd or fail "exec curl: $!\n";
6464 }
6465
6466 sub repos_server_url () {
6467     $package = '_dgit-repos-server';
6468     local $access_forpush = 1;
6469     local $isuite = 'DGIT-REPOS-SERVER';
6470     my $url = access_giturl();
6471 }
6472
6473 sub pre_clone_dgit_repos_server () {
6474     not_necessarily_a_tree();
6475 }
6476 sub cmd_clone_dgit_repos_server {
6477     badusage "need destination argument" unless @ARGV==1;
6478     my ($destdir) = @ARGV;
6479     my $url = repos_server_url();
6480     my @cmd = (@git, qw(clone), $url, $destdir);
6481     debugcmd ">",@cmd;
6482     exec @cmd or fail "exec git clone: $!\n";
6483 }
6484
6485 sub pre_print_dgit_repos_server_source_url () {
6486     not_necessarily_a_tree();
6487 }
6488 sub cmd_print_dgit_repos_server_source_url {
6489     badusage "no arguments allowed to dgit print-dgit-repos-server-source-url"
6490         if @ARGV;
6491     my $url = repos_server_url();
6492     print $url, "\n" or die $!;
6493 }
6494
6495 sub pre_print_dpkg_source_ignores {
6496     not_necessarily_a_tree();
6497 }
6498 sub cmd_print_dpkg_source_ignores {
6499     badusage "no arguments allowed to dgit print-dpkg-source-ignores"
6500         if @ARGV;
6501     print "@dpkg_source_ignores\n" or die $!;
6502 }
6503
6504 sub cmd_setup_mergechangelogs {
6505     badusage "no arguments allowed to dgit setup-mergechangelogs" if @ARGV;
6506     local $isuite = 'DGIT-SETUP-TREE';
6507     setup_mergechangelogs(1);
6508 }
6509
6510 sub cmd_setup_useremail {
6511     badusage "no arguments allowed to dgit setup-useremail" if @ARGV;
6512     local $isuite = 'DGIT-SETUP-TREE';
6513     setup_useremail(1);
6514 }
6515
6516 sub cmd_setup_gitattributes {
6517     badusage "no arguments allowed to dgit setup-useremail" if @ARGV;
6518     local $isuite = 'DGIT-SETUP-TREE';
6519     setup_gitattrs(1);
6520 }
6521
6522 sub cmd_setup_new_tree {
6523     badusage "no arguments allowed to dgit setup-tree" if @ARGV;
6524     local $isuite = 'DGIT-SETUP-TREE';
6525     setup_new_tree();
6526 }
6527
6528 #---------- argument parsing and main program ----------
6529
6530 sub cmd_version {
6531     print "dgit version $our_version\n" or die $!;
6532     exit 0;
6533 }
6534
6535 our (%valopts_long, %valopts_short);
6536 our (%funcopts_long);
6537 our @rvalopts;
6538 our (@modeopt_cfgs);
6539
6540 sub defvalopt ($$$$) {
6541     my ($long,$short,$val_re,$how) = @_;
6542     my $oi = { Long => $long, Short => $short, Re => $val_re, How => $how };
6543     $valopts_long{$long} = $oi;
6544     $valopts_short{$short} = $oi;
6545     # $how subref should:
6546     #   do whatever assignemnt or thing it likes with $_[0]
6547     #   if the option should not be passed on to remote, @rvalopts=()
6548     # or $how can be a scalar ref, meaning simply assign the value
6549 }
6550
6551 defvalopt '--since-version', '-v', '[^_]+|_', \$changes_since_version;
6552 defvalopt '--distro',        '-d', '.+',      \$idistro;
6553 defvalopt '',                '-k', '.+',      \$keyid;
6554 defvalopt '--existing-package','', '.*',      \$existing_package;
6555 defvalopt '--build-products-dir','','.*',     \$buildproductsdir;
6556 defvalopt '--clean',       '', $cleanmode_re, \$cleanmode;
6557 defvalopt '--package',   '-p',   $package_re, \$package;
6558 defvalopt '--quilt',     '', $quilt_modes_re, \$quilt_mode;
6559
6560 defvalopt '', '-C', '.+', sub {
6561     ($changesfile) = (@_);
6562     if ($changesfile =~ s#^(.*)/##) {
6563         $buildproductsdir = $1;
6564     }
6565 };
6566
6567 defvalopt '--initiator-tempdir','','.*', sub {
6568     ($initiator_tempdir) = (@_);
6569     $initiator_tempdir =~ m#^/# or
6570         badusage "--initiator-tempdir must be used specify an".
6571         " absolute, not relative, directory."
6572 };
6573
6574 sub defoptmodes ($@) {
6575     my ($varref, $cfgkey, $default, %optmap) = @_;
6576     my %permit;
6577     while (my ($opt,$val) = each %optmap) {
6578         $funcopts_long{$opt} = sub { $$varref = $val; };
6579         $permit{$val} = $val;
6580     }
6581     push @modeopt_cfgs, {
6582         Var => $varref,
6583         Key => $cfgkey,
6584         Default => $default,
6585         Vals => \%permit
6586     };
6587 }
6588
6589 defoptmodes \$dodep14tag, qw( dep14tag          want
6590                               --dep14tag        want
6591                               --no-dep14tag     no
6592                               --always-dep14tag always );
6593
6594 sub parseopts () {
6595     my $om;
6596
6597     if (defined $ENV{'DGIT_SSH'}) {
6598         @ssh = string_to_ssh $ENV{'DGIT_SSH'};
6599     } elsif (defined $ENV{'GIT_SSH'}) {
6600         @ssh = ($ENV{'GIT_SSH'});
6601     }
6602
6603     my $oi;
6604     my $val;
6605     my $valopt = sub {
6606         my ($what) = @_;
6607         @rvalopts = ($_);
6608         if (!defined $val) {
6609             badusage "$what needs a value" unless @ARGV;
6610             $val = shift @ARGV;
6611             push @rvalopts, $val;
6612         }
6613         badusage "bad value \`$val' for $what" unless
6614             $val =~ m/^$oi->{Re}$(?!\n)/s;
6615         my $how = $oi->{How};
6616         if (ref($how) eq 'SCALAR') {
6617             $$how = $val;
6618         } else {
6619             $how->($val);
6620         }
6621         push @ropts, @rvalopts;
6622     };
6623
6624     while (@ARGV) {
6625         last unless $ARGV[0] =~ m/^-/;
6626         $_ = shift @ARGV;
6627         last if m/^--?$/;
6628         if (m/^--/) {
6629             if (m/^--dry-run$/) {
6630                 push @ropts, $_;
6631                 $dryrun_level=2;
6632             } elsif (m/^--damp-run$/) {
6633                 push @ropts, $_;
6634                 $dryrun_level=1;
6635             } elsif (m/^--no-sign$/) {
6636                 push @ropts, $_;
6637                 $sign=0;
6638             } elsif (m/^--help$/) {
6639                 cmd_help();
6640             } elsif (m/^--version$/) {
6641                 cmd_version();
6642             } elsif (m/^--new$/) {
6643                 push @ropts, $_;
6644                 $new_package=1;
6645             } elsif (m/^--([-0-9a-z]+)=(.+)/s &&
6646                      ($om = $opts_opt_map{$1}) &&
6647                      length $om->[0]) {
6648                 push @ropts, $_;
6649                 $om->[0] = $2;
6650             } elsif (m/^--([-0-9a-z]+):(.*)/s &&
6651                      !$opts_opt_cmdonly{$1} &&
6652                      ($om = $opts_opt_map{$1})) {
6653                 push @ropts, $_;
6654                 push @$om, $2;
6655             } elsif (m/^--(gbp|dpm)$/s) {
6656                 push @ropts, "--quilt=$1";
6657                 $quilt_mode = $1;
6658             } elsif (m/^--ignore-dirty$/s) {
6659                 push @ropts, $_;
6660                 $ignoredirty = 1;
6661             } elsif (m/^--no-quilt-fixup$/s) {
6662                 push @ropts, $_;
6663                 $quilt_mode = 'nocheck';
6664             } elsif (m/^--no-rm-on-error$/s) {
6665                 push @ropts, $_;
6666                 $rmonerror = 0;
6667             } elsif (m/^--no-chase-dsc-distro$/s) {
6668                 push @ropts, $_;
6669                 $chase_dsc_distro = 0;
6670             } elsif (m/^--overwrite$/s) {
6671                 push @ropts, $_;
6672                 $overwrite_version = '';
6673             } elsif (m/^--overwrite=(.+)$/s) {
6674                 push @ropts, $_;
6675                 $overwrite_version = $1;
6676             } elsif (m/^--delayed=(\d+)$/s) {
6677                 push @ropts, $_;
6678                 push @dput, $_;
6679             } elsif (m/^--dgit-view-save=(.+)$/s) {
6680                 push @ropts, $_;
6681                 $split_brain_save = $1;
6682                 $split_brain_save =~ s#^(?!refs/)#refs/heads/#;
6683             } elsif (m/^--(no-)?rm-old-changes$/s) {
6684                 push @ropts, $_;
6685                 $rmchanges = !$1;
6686             } elsif (m/^--deliberately-($deliberately_re)$/s) {
6687                 push @ropts, $_;
6688                 push @deliberatelies, $&;
6689             } elsif (m/^--force-(.*)/ && defined $forceopts{$1}) {
6690                 push @ropts, $&;
6691                 $forceopts{$1} = 1;
6692                 $_='';
6693             } elsif (m/^--force-/) {
6694                 print STDERR
6695                     "$us: warning: ignoring unknown force option $_\n";
6696                 $_='';
6697             } elsif (m/^--dgit-tag-format=(old|new)$/s) {
6698                 # undocumented, for testing
6699                 push @ropts, $_;
6700                 $tagformat_want = [ $1, 'command line', 1 ];
6701                 # 1 menas overrides distro configuration
6702             } elsif (m/^--always-split-source-build$/s) {
6703                 # undocumented, for testing
6704                 push @ropts, $_;
6705                 $need_split_build_invocation = 1;
6706             } elsif (m/^--config-lookup-explode=(.+)$/s) {
6707                 # undocumented, for testing
6708                 push @ropts, $_;
6709                 $gitcfgs{cmdline}{$1} = 'CONFIG-LOOKUP-EXPLODE';
6710                 # ^ it's supposed to be an array ref
6711             } elsif (m/^(--[-0-9a-z]+)(=|$)/ && ($oi = $valopts_long{$1})) {
6712                 $val = $2 ? $' : undef; #';
6713                 $valopt->($oi->{Long});
6714             } elsif ($funcopts_long{$_}) {
6715                 push @ropts, $_;
6716                 $funcopts_long{$_}();
6717             } else {
6718                 badusage "unknown long option \`$_'";
6719             }
6720         } else {
6721             while (m/^-./s) {
6722                 if (s/^-n/-/) {
6723                     push @ropts, $&;
6724                     $dryrun_level=2;
6725                 } elsif (s/^-L/-/) {
6726                     push @ropts, $&;
6727                     $dryrun_level=1;
6728                 } elsif (s/^-h/-/) {
6729                     cmd_help();
6730                 } elsif (s/^-D/-/) {
6731                     push @ropts, $&;
6732                     $debuglevel++;
6733                     enabledebug();
6734                 } elsif (s/^-N/-/) {
6735                     push @ropts, $&;
6736                     $new_package=1;
6737                 } elsif (m/^-m/) {
6738                     push @ropts, $&;
6739                     push @changesopts, $_;
6740                     $_ = '';
6741                 } elsif (s/^-wn$//s) {
6742                     push @ropts, $&;
6743                     $cleanmode = 'none';
6744                 } elsif (s/^-wg$//s) {
6745                     push @ropts, $&;
6746                     $cleanmode = 'git';
6747                 } elsif (s/^-wgf$//s) {
6748                     push @ropts, $&;
6749                     $cleanmode = 'git-ff';
6750                 } elsif (s/^-wd$//s) {
6751                     push @ropts, $&;
6752                     $cleanmode = 'dpkg-source';
6753                 } elsif (s/^-wdd$//s) {
6754                     push @ropts, $&;
6755                     $cleanmode = 'dpkg-source-d';
6756                 } elsif (s/^-wc$//s) {
6757                     push @ropts, $&;
6758                     $cleanmode = 'check';
6759                 } elsif (s/^-c([^=]*)\=(.*)$//s) {
6760                     push @git, '-c', $&;
6761                     $gitcfgs{cmdline}{$1} = [ $2 ];
6762                 } elsif (s/^-c([^=]+)$//s) {
6763                     push @git, '-c', $&;
6764                     $gitcfgs{cmdline}{$1} = [ 'true' ];
6765                 } elsif (m/^-[a-zA-Z]/ && ($oi = $valopts_short{$&})) {
6766                     $val = $'; #';
6767                     $val = undef unless length $val;
6768                     $valopt->($oi->{Short});
6769                     $_ = '';
6770                 } else {
6771                     badusage "unknown short option \`$_'";
6772                 }
6773             }
6774         }
6775     }
6776 }
6777
6778 sub check_env_sanity () {
6779     my $blocked = new POSIX::SigSet;
6780     sigprocmask SIG_UNBLOCK, $blocked, $blocked or die $!;
6781
6782     eval {
6783         foreach my $name (qw(PIPE CHLD)) {
6784             my $signame = "SIG$name";
6785             my $signum = eval "POSIX::$signame" // die;
6786             ($SIG{$name} // 'DEFAULT') eq 'DEFAULT' or
6787                 die "$signame is set to something other than SIG_DFL\n";
6788             $blocked->ismember($signum) and
6789                 die "$signame is blocked\n";
6790         }
6791     };
6792     return unless $@;
6793     chomp $@;
6794     fail <<END;
6795 On entry to dgit, $@
6796 This is a bug produced by something in in your execution environment.
6797 Giving up.
6798 END
6799 }
6800
6801
6802 sub parseopts_late_defaults () {
6803     $isuite //= cfg("dgit-distro.$idistro.default-suite", 'RETURN-UNDEF')
6804         if defined $idistro;
6805     $isuite //= cfg('dgit.default.default-suite');
6806
6807     foreach my $k (keys %opts_opt_map) {
6808         my $om = $opts_opt_map{$k};
6809
6810         my $v = access_cfg("cmd-$k", 'RETURN-UNDEF');
6811         if (defined $v) {
6812             badcfg "cannot set command for $k"
6813                 unless length $om->[0];
6814             $om->[0] = $v;
6815         }
6816
6817         foreach my $c (access_cfg_cfgs("opts-$k")) {
6818             my @vl =
6819                 map { $_ ? @$_ : () }
6820                 map { $gitcfgs{$_}{$c} }
6821                 reverse @gitcfgsources;
6822             printdebug "CL $c ", (join " ", map { shellquote } @vl),
6823                 "\n" if $debuglevel >= 4;
6824             next unless @vl;
6825             badcfg "cannot configure options for $k"
6826                 if $opts_opt_cmdonly{$k};
6827             my $insertpos = $opts_cfg_insertpos{$k};
6828             @$om = ( @$om[0..$insertpos-1],
6829                      @vl,
6830                      @$om[$insertpos..$#$om] );
6831         }
6832     }
6833
6834     if (!defined $rmchanges) {
6835         local $access_forpush;
6836         $rmchanges = access_cfg_bool(0, 'rm-old-changes');
6837     }
6838
6839     if (!defined $quilt_mode) {
6840         local $access_forpush;
6841         $quilt_mode = cfg('dgit.force.quilt-mode', 'RETURN-UNDEF')
6842             // access_cfg('quilt-mode', 'RETURN-UNDEF')
6843             // 'linear';
6844         $quilt_mode =~ m/^($quilt_modes_re)$/
6845             or badcfg "unknown quilt-mode \`$quilt_mode'";
6846         $quilt_mode = $1;
6847     }
6848
6849     foreach my $moc (@modeopt_cfgs) {
6850         local $access_forpush;
6851         my $vr = $moc->{Var};
6852         next if defined $$vr;
6853         $$vr = access_cfg($moc->{Key}, 'RETURN-UNDEF') // $moc->{Default};
6854         my $v = $moc->{Vals}{$$vr};
6855         badcfg "unknown $moc->{Key} setting \`$$vr'" unless defined $v;
6856         $$vr = $v;
6857     }
6858
6859     $need_split_build_invocation ||= quiltmode_splitbrain();
6860
6861     if (!defined $cleanmode) {
6862         local $access_forpush;
6863         $cleanmode = access_cfg('clean-mode', 'RETURN-UNDEF');
6864         $cleanmode //= 'dpkg-source';
6865
6866         badcfg "unknown clean-mode \`$cleanmode'" unless
6867             $cleanmode =~ m/^($cleanmode_re)$(?!\n)/s;
6868     }
6869 }
6870
6871 if ($ENV{$fakeeditorenv}) {
6872     git_slurp_config();
6873     quilt_fixup_editor();
6874 }
6875
6876 parseopts();
6877 check_env_sanity();
6878
6879 print STDERR "DRY RUN ONLY\n" if $dryrun_level > 1;
6880 print STDERR "DAMP RUN - WILL MAKE LOCAL (UNSIGNED) CHANGES\n"
6881     if $dryrun_level == 1;
6882 if (!@ARGV) {
6883     print STDERR $helpmsg or die $!;
6884     exit 8;
6885 }
6886 $cmd = $subcommand = shift @ARGV;
6887 $cmd =~ y/-/_/;
6888
6889 my $pre_fn = ${*::}{"pre_$cmd"};
6890 $pre_fn->() if $pre_fn;
6891
6892 record_maindir if $invoked_in_git_tree;
6893 git_slurp_config();
6894
6895 my $fn = ${*::}{"cmd_$cmd"};
6896 $fn or badusage "unknown operation $cmd";
6897 $fn->();