chiark / gitweb /
1fde60bba61f663b82f931aaf454f13b193bb7b1
[dgit.git] / dgit
1 #!/usr/bin/perl -w
2 # dgit
3 # Integration between git and Debian-style archives
4 #
5 # Copyright (C)2013-2018 Ian Jackson
6 # Copyright (C)2017-2018 Sean Whitton
7 #
8 # This program is free software: you can redistribute it and/or modify
9 # it under the terms of the GNU General Public License as published by
10 # the Free Software Foundation, either version 3 of the License, or
11 # (at your option) any later version.
12 #
13 # This program is distributed in the hope that it will be useful,
14 # but WITHOUT ANY WARRANTY; without even the implied warranty of
15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
16 # GNU General Public License for more details.
17 #
18 # You should have received a copy of the GNU General Public License
19 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
20
21 END { $? = $Debian::Dgit::ExitStatus::desired // -1; };
22 use Debian::Dgit::ExitStatus;
23 use Debian::Dgit::I18n;
24
25 use strict;
26
27 use Debian::Dgit qw(:DEFAULT :playground);
28 setup_sigwarn();
29
30 use IO::Handle;
31 use Data::Dumper;
32 use LWP::UserAgent;
33 use Dpkg::Control::Hash;
34 use File::Path;
35 use File::Temp qw(tempdir);
36 use File::Basename;
37 use Dpkg::Version;
38 use Dpkg::Compression;
39 use Dpkg::Compression::Process;
40 use POSIX;
41 use Locale::gettext;
42 use IPC::Open2;
43 use Digest::SHA;
44 use Digest::MD5;
45 use List::MoreUtils qw(pairwise);
46 use Text::Glob qw(match_glob);
47 use Fcntl qw(:DEFAULT :flock);
48 use Carp;
49
50 use Debian::Dgit;
51
52 our $our_version = 'UNRELEASED'; ###substituted###
53 our $absurdity = undef; ###substituted###
54
55 our @rpushprotovsn_support = qw(4 3 2); # 4 is new tag format
56 our $protovsn;
57
58 our $cmd;
59 our $subcommand;
60 our $isuite;
61 our $idistro;
62 our $package;
63 our @ropts;
64
65 our $sign = 1;
66 our $dryrun_level = 0;
67 our $changesfile;
68 our $buildproductsdir;
69 our $bpd_glob;
70 our $new_package = 0;
71 our $includedirty = 0;
72 our $rmonerror = 1;
73 our @deliberatelies;
74 our %previously;
75 our $existing_package = 'dpkg';
76 our $cleanmode;
77 our $changes_since_version;
78 our $rmchanges;
79 our $overwrite_version; # undef: not specified; '': check changelog
80 our $quilt_mode;
81 our $quilt_modes_re = 'linear|smash|auto|nofix|nocheck|gbp|dpm|unapplied';
82 our $dodep14tag;
83 our %internal_object_save;
84 our $we_are_responder;
85 our $we_are_initiator;
86 our $initiator_tempdir;
87 our $patches_applied_dirtily = 00;
88 our $tagformat_want;
89 our $tagformat;
90 our $tagformatfn;
91 our $chase_dsc_distro=1;
92
93 our %forceopts = map { $_=>0 }
94     qw(unrepresentable unsupported-source-format
95        dsc-changes-mismatch changes-origs-exactly
96        uploading-binaries uploading-source-only
97        import-gitapply-absurd
98        import-gitapply-no-absurd
99        import-dsc-with-dgit-field);
100
101 our %format_ok = map { $_=>1 } ("1.0","3.0 (native)","3.0 (quilt)");
102
103 our $suite_re = '[-+.0-9a-z]+';
104 our $cleanmode_re = 'dpkg-source(?:-d)?|git|git-ff|check|none';
105
106 our $git_authline_re = '^([^<>]+) \<(\S+)\> (\d+ [-+]\d+)$';
107 our $splitbraincache = 'dgit-intern/quilt-cache';
108 our $rewritemap = 'dgit-rewrite/map';
109
110 our @dpkg_source_ignores = qw(-i(?:^|/)\.git(?:/|$) -I.git);
111
112 our (@git) = qw(git);
113 our (@dget) = qw(dget);
114 our (@curl) = (qw(curl --proto-redir), '-all,http,https', qw(-L));
115 our (@dput) = qw(dput);
116 our (@debsign) = qw(debsign);
117 our (@gpg) = qw(gpg);
118 our (@sbuild) = (qw(sbuild --no-source));
119 our (@ssh) = 'ssh';
120 our (@dgit) = qw(dgit);
121 our (@git_debrebase) = qw(git-debrebase);
122 our (@aptget) = qw(apt-get);
123 our (@aptcache) = qw(apt-cache);
124 our (@dpkgbuildpackage) = (qw(dpkg-buildpackage), @dpkg_source_ignores);
125 our (@dpkgsource) = (qw(dpkg-source), @dpkg_source_ignores);
126 our (@dpkggenchanges) = qw(dpkg-genchanges);
127 our (@mergechanges) = qw(mergechanges -f);
128 our (@gbp_build) = ('');
129 our (@gbp_pq) = ('gbp pq');
130 our (@changesopts) = ('');
131 our (@pbuilder) = ("sudo -E pbuilder");
132 our (@cowbuilder) = ("sudo -E cowbuilder");
133
134 our %opts_opt_map = ('dget' => \@dget, # accept for compatibility
135                      'curl' => \@curl,
136                      'dput' => \@dput,
137                      'debsign' => \@debsign,
138                      'gpg' => \@gpg,
139                      'sbuild' => \@sbuild,
140                      'ssh' => \@ssh,
141                      'dgit' => \@dgit,
142                      'git' => \@git,
143                      'git-debrebase' => \@git_debrebase,
144                      'apt-get' => \@aptget,
145                      'apt-cache' => \@aptcache,
146                      'dpkg-source' => \@dpkgsource,
147                      'dpkg-buildpackage' => \@dpkgbuildpackage,
148                      'dpkg-genchanges' => \@dpkggenchanges,
149                      'gbp-build' => \@gbp_build,
150                      'gbp-pq' => \@gbp_pq,
151                      'ch' => \@changesopts,
152                      'mergechanges' => \@mergechanges,
153                      'pbuilder' => \@pbuilder,
154                      'cowbuilder' => \@cowbuilder);
155
156 our %opts_opt_cmdonly = ('gpg' => 1, 'git' => 1);
157 our %opts_cfg_insertpos = map {
158     $_,
159     scalar @{ $opts_opt_map{$_} }
160 } keys %opts_opt_map;
161
162 sub parseopts_late_defaults();
163 sub setup_gitattrs(;$);
164 sub check_gitattrs($$);
165
166 our $playground;
167 our $keyid;
168
169 autoflush STDOUT 1;
170
171 our $supplementary_message = '';
172 our $split_brain = 0;
173
174 END {
175     local ($@, $?);
176     return unless forkcheck_mainprocess();
177     print STDERR "! $_\n" foreach $supplementary_message =~ m/^.+$/mg;
178 }
179
180 our $remotename = 'dgit';
181 our @ourdscfield = qw(Dgit Vcs-Dgit-Master);
182 our $csuite;
183 our $instead_distro;
184
185 if (!defined $absurdity) {
186     $absurdity = $0;
187     $absurdity =~ s{/[^/]+$}{/absurd} or die;
188 }
189
190 sub debiantag ($$) {
191     my ($v,$distro) = @_;
192     return $tagformatfn->($v, $distro);
193 }
194
195 sub madformat ($) { $_[0] eq '3.0 (quilt)' }
196
197 sub lbranch () { return "$branchprefix/$csuite"; }
198 my $lbranch_re = '^refs/heads/'.$branchprefix.'/([^/.]+)$';
199 sub lref () { return "refs/heads/".lbranch(); }
200 sub lrref () { return "refs/remotes/$remotename/".server_branch($csuite); }
201 sub rrref () { return server_ref($csuite); }
202
203 sub srcfn ($$) {
204     my ($vsn, $sfx) = @_;
205     return &source_file_leafname($package, $vsn, $sfx);
206 }
207 sub is_orig_file_of_vsn ($$) {
208     my ($f, $upstreamvsn) = @_;
209     return is_orig_file_of_p_v($f, $package, $upstreamvsn);
210 }
211
212 sub dscfn ($) {
213     my ($vsn) = @_;
214     return srcfn($vsn,".dsc");
215 }
216
217 sub changespat ($;$) {
218     my ($vsn, $arch) = @_;
219     return "${package}_".(stripepoch $vsn)."_".($arch//'*').".changes";
220 }
221
222 our $us = 'dgit';
223 initdebug('');
224
225 our @end;
226 END { 
227     local ($?);
228     return unless forkcheck_mainprocess();
229     foreach my $f (@end) {
230         eval { $f->(); };
231         print STDERR "$us: cleanup: $@" if length $@;
232     }
233 };
234
235 sub badcfg {
236     print STDERR f_ "%s: invalid configuration: %s\n", $us, "@_";
237     finish 12;
238 }
239
240 sub forceable_fail ($$) {
241     my ($forceoptsl, $msg) = @_;
242     fail $msg unless grep { $forceopts{$_} } @$forceoptsl;
243     print STDERR +(__ "warning: overriding problem due to --force:\n"). $msg;
244 }
245
246 sub forceing ($) {
247     my ($forceoptsl) = @_;
248     my @got = grep { $forceopts{$_} } @$forceoptsl;
249     return 0 unless @got;
250     print STDERR f_
251         "warning: skipping checks or functionality due to --force-%s\n",
252         $got[0];
253 }
254
255 sub no_such_package () {
256     print STDERR f_ "%s: package %s does not exist in suite %s\n",
257         $us, $package, $isuite;
258     finish 4;
259 }
260
261 sub deliberately ($) {
262     my ($enquiry) = @_;
263     return !!grep { $_ eq "--deliberately-$enquiry" } @deliberatelies;
264 }
265
266 sub deliberately_not_fast_forward () {
267     foreach (qw(not-fast-forward fresh-repo)) {
268         return 1 if deliberately($_) || deliberately("TEST-dgit-only-$_");
269     }
270 }
271
272 sub quiltmode_splitbrain () {
273     $quilt_mode =~ m/gbp|dpm|unapplied/;
274 }
275
276 sub opts_opt_multi_cmd {
277     my $extra = shift;
278     my @cmd;
279     push @cmd, split /\s+/, shift @_;
280     push @cmd, @$extra;
281     push @cmd, @_;
282     @cmd;
283 }
284
285 sub gbp_pq {
286     return opts_opt_multi_cmd [], @gbp_pq;
287 }
288
289 sub dgit_privdir () {
290     our $dgit_privdir_made //= ensure_a_playground 'dgit';
291 }
292
293 sub bpd_abs () {
294     my $r = $buildproductsdir;
295     $r = "$maindir/$r" unless $r =~ m{^/};
296     return $r;
297 }
298
299 sub get_tree_of_commit ($) {
300     my ($commitish) = @_;
301     my $cdata = cmdoutput @git, qw(cat-file commit), $commitish;
302     $cdata =~ m/\n\n/;  $cdata = $`;
303     $cdata =~ m/^tree (\w+)$/m or confess "cdata $cdata ?";
304     return $1;
305 }
306
307 sub branch_gdr_info ($$) {
308     my ($symref, $head) = @_;
309     my ($status, $msg, $current, $ffq_prev, $gdrlast) =
310         gdr_ffq_prev_branchinfo($symref);
311     return () unless $status eq 'branch';
312     $ffq_prev = git_get_ref $ffq_prev;
313     $gdrlast  = git_get_ref $gdrlast;
314     $gdrlast &&= is_fast_fwd $gdrlast, $head;
315     return ($ffq_prev, $gdrlast);
316 }
317
318 sub branch_is_gdr_unstitched_ff ($$$) {
319     my ($symref, $head, $ancestor) = @_;
320     my ($ffq_prev, $gdrlast) = branch_gdr_info($symref, $head);
321     return 0 unless $ffq_prev;
322     return 0 unless !defined $ancestor or is_fast_fwd $ancestor, $ffq_prev;
323     return 1;
324 }
325
326 sub branch_is_gdr ($) {
327     my ($head) = @_;
328     # This is quite like git-debrebase's keycommits.
329     # We have our own implementation because:
330     #  - our algorighm can do fewer tests so is faster
331     #  - it saves testing to see if gdr is installed
332
333     # NB we use this jsut for deciding whether to run gdr make-patches
334     # Before reusing this algorithm for somthing else, its
335     # suitability should be reconsidered.
336
337     my $walk = $head;
338     local $Debian::Dgit::debugcmd_when_debuglevel = 3;
339     printdebug "branch_is_gdr $head...\n";
340     my $get_patches = sub {
341         my $t = git_cat_file "$_[0]:debian/patches", [qw(missing tree)];
342         return $t // '';
343     };
344     my $tip_patches = $get_patches->($head);
345   WALK:
346     for (;;) {
347         my $cdata = git_cat_file $walk, 'commit';
348         my ($hdrs,$msg) = $cdata =~ m{\n\n} ? ($`,$') : ($cdata,'');
349         if ($msg =~ m{^\[git-debrebase\ (
350                           anchor | changelog | make-patches | 
351                           merged-breakwater | pseudomerge
352                       ) [: ] }mx) {
353             # no need to analyse this - it's sufficient
354             # (gdr classifications: Anchor, MergedBreakwaters)
355             # (made by gdr: Pseudomerge, Changelog)
356             printdebug "branch_is_gdr  $walk gdr $1 YES\n";
357             return 1;
358         }
359         my @parents = ($hdrs =~ m/^parent (\w+)$/gm);
360         if (@parents==2) {
361             my $walk_tree = get_tree_of_commit $walk;
362             foreach my $p (@parents) {
363                 my $p_tree = get_tree_of_commit $p;
364                 if ($p_tree eq $walk_tree) { # pseudomerge contriburor
365                     # (gdr classification: Pseudomerge; not made by gdr)
366                     printdebug "branch_is_gdr  $walk unmarked pseudomerge\n"
367                         if $debuglevel >= 2;
368                     $walk = $p;
369                     next WALK;
370                 }
371             }
372             # some other non-gdr merge
373             # (gdr classification: VanillaMerge, DgitImportUnpatched, ?)
374             printdebug "branch_is_gdr  $walk ?-2-merge NO\n";
375             return 0;
376         }
377         if (@parents>2) {
378             # (gdr classification: ?)
379             printdebug "branch_is_gdr  $walk ?-octopus NO\n";
380             return 0;
381         }
382         if ($get_patches->($walk) ne $tip_patches) {
383             # Our parent added, removed, or edited patches, and wasn't
384             # a gdr make-patches commit.  gdr make-patches probably
385             # won't do that well, then.
386             # (gdr classification of parent: AddPatches or ?)
387             printdebug "branch_is_gdr  $walk ?-patches NO\n";
388             return 0;
389         }
390         if ($tip_patches eq '' and
391             !defined git_cat_file "$walk:debian") {
392             # (gdr classification of parent: BreakwaterStart
393             printdebug "branch_is_gdr  $walk unmarked BreakwaterStart YES\n";
394             return 1;
395         }
396         # (gdr classification: Upstream Packaging Mixed Changelog)
397         printdebug "branch_is_gdr  $walk plain\n"
398             if $debuglevel >= 2;
399         $walk = $parents[0];
400     }
401 }
402
403 #---------- remote protocol support, common ----------
404
405 # remote push initiator/responder protocol:
406 #  $ dgit remote-push-build-host <n-rargs> <rargs>... <push-args>...
407 #  where <rargs> is <push-host-dir> <supported-proto-vsn>,... ...
408 #  < dgit-remote-push-ready <actual-proto-vsn>
409 #
410 # occasionally:
411 #
412 #  > progress NBYTES
413 #  [NBYTES message]
414 #
415 #  > supplementary-message NBYTES          # $protovsn >= 3
416 #  [NBYTES message]
417 #
418 # main sequence:
419 #
420 #  > file parsed-changelog
421 #  [indicates that output of dpkg-parsechangelog follows]
422 #  > data-block NBYTES
423 #  > [NBYTES bytes of data (no newline)]
424 #  [maybe some more blocks]
425 #  > data-end
426 #
427 #  > file dsc
428 #  [etc]
429 #
430 #  > file changes
431 #  [etc]
432 #
433 #  > param head DGIT-VIEW-HEAD
434 #  > param csuite SUITE
435 #  > param tagformat old|new
436 #  > param maint-view MAINT-VIEW-HEAD
437 #
438 #  > param buildinfo-filename P_V_X.buildinfo   # zero or more times
439 #  > file buildinfo                             # for buildinfos to sign
440 #
441 #  > previously REFNAME=OBJNAME       # if --deliberately-not-fast-forward
442 #                                     # goes into tag, for replay prevention
443 #
444 #  > want signed-tag
445 #  [indicates that signed tag is wanted]
446 #  < data-block NBYTES
447 #  < [NBYTES bytes of data (no newline)]
448 #  [maybe some more blocks]
449 #  < data-end
450 #  < files-end
451 #
452 #  > want signed-dsc-changes
453 #  < data-block NBYTES    [transfer of signed dsc]
454 #  [etc]
455 #  < data-block NBYTES    [transfer of signed changes]
456 #  [etc]
457 #  < data-block NBYTES    [transfer of each signed buildinfo
458 #  [etc]                   same number and order as "file buildinfo"]
459 #  ...
460 #  < files-end
461 #
462 #  > complete
463
464 our $i_child_pid;
465
466 sub i_child_report () {
467     # Sees if our child has died, and reap it if so.  Returns a string
468     # describing how it died if it failed, or undef otherwise.
469     return undef unless $i_child_pid;
470     my $got = waitpid $i_child_pid, WNOHANG;
471     return undef if $got <= 0;
472     die unless $got == $i_child_pid;
473     $i_child_pid = undef;
474     return undef unless $?;
475     return f_ "build host child %s", waitstatusmsg();
476 }
477
478 sub badproto ($$) {
479     my ($fh, $m) = @_;
480     fail f_ "connection lost: %s", $! if $fh->error;
481     fail f_ "protocol violation; %s not expected", $m;
482 }
483
484 sub badproto_badread ($$) {
485     my ($fh, $wh) = @_;
486     fail f_ "connection lost: %s", $! if $!;
487     my $report = i_child_report();
488     fail $report if defined $report;
489     badproto $fh, f_ "eof (reading %s)", $wh;
490 }
491
492 sub protocol_expect (&$) {
493     my ($match, $fh) = @_;
494     local $_;
495     $_ = <$fh>;
496     defined && chomp or badproto_badread $fh, __ "protocol message";
497     if (wantarray) {
498         my @r = &$match;
499         return @r if @r;
500     } else {
501         my $r = &$match;
502         return $r if $r;
503     }
504     badproto $fh, f_ "\`%s'", $_;
505 }
506
507 sub protocol_send_file ($$) {
508     my ($fh, $ourfn) = @_;
509     open PF, "<", $ourfn or die "$ourfn: $!";
510     for (;;) {
511         my $d;
512         my $got = read PF, $d, 65536;
513         die "$ourfn: $!" unless defined $got;
514         last if !$got;
515         print $fh "data-block ".length($d)."\n" or die $!;
516         print $fh $d or die $!;
517     }
518     PF->error and die "$ourfn $!";
519     print $fh "data-end\n" or die $!;
520     close PF;
521 }
522
523 sub protocol_read_bytes ($$) {
524     my ($fh, $nbytes) = @_;
525     $nbytes =~ m/^[1-9]\d{0,5}$|^0$/ or badproto \*RO, __ "bad byte count";
526     my $d;
527     my $got = read $fh, $d, $nbytes;
528     $got==$nbytes or badproto_badread $fh, __ "data block";
529     return $d;
530 }
531
532 sub protocol_receive_file ($$) {
533     my ($fh, $ourfn) = @_;
534     printdebug "() $ourfn\n";
535     open PF, ">", $ourfn or die "$ourfn: $!";
536     for (;;) {
537         my ($y,$l) = protocol_expect {
538             m/^data-block (.*)$/ ? (1,$1) :
539             m/^data-end$/ ? (0,) :
540             ();
541         } $fh;
542         last unless $y;
543         my $d = protocol_read_bytes $fh, $l;
544         print PF $d or die $!;
545     }
546     close PF or die $!;
547 }
548
549 #---------- remote protocol support, responder ----------
550
551 sub responder_send_command ($) {
552     my ($command) = @_;
553     return unless $we_are_responder;
554     # called even without $we_are_responder
555     printdebug ">> $command\n";
556     print PO $command, "\n" or die $!;
557 }    
558
559 sub responder_send_file ($$) {
560     my ($keyword, $ourfn) = @_;
561     return unless $we_are_responder;
562     printdebug "]] $keyword $ourfn\n";
563     responder_send_command "file $keyword";
564     protocol_send_file \*PO, $ourfn;
565 }
566
567 sub responder_receive_files ($@) {
568     my ($keyword, @ourfns) = @_;
569     die unless $we_are_responder;
570     printdebug "[[ $keyword @ourfns\n";
571     responder_send_command "want $keyword";
572     foreach my $fn (@ourfns) {
573         protocol_receive_file \*PI, $fn;
574     }
575     printdebug "[[\$\n";
576     protocol_expect { m/^files-end$/ } \*PI;
577 }
578
579 #---------- remote protocol support, initiator ----------
580
581 sub initiator_expect (&) {
582     my ($match) = @_;
583     protocol_expect { &$match } \*RO;
584 }
585
586 #---------- end remote code ----------
587
588 sub progress {
589     if ($we_are_responder) {
590         my $m = join '', @_;
591         responder_send_command "progress ".length($m) or die $!;
592         print PO $m or die $!;
593     } else {
594         print @_, "\n";
595     }
596 }
597
598 our $ua;
599
600 sub url_get {
601     if (!$ua) {
602         $ua = LWP::UserAgent->new();
603         $ua->env_proxy;
604     }
605     my $what = $_[$#_];
606     progress "downloading $what...";
607     my $r = $ua->get(@_) or die $!;
608     return undef if $r->code == 404;
609     $r->is_success or fail f_ "failed to fetch %s: %s",
610         $what, $r->status_line;
611     return $r->decoded_content(charset => 'none');
612 }
613
614 our ($dscdata,$dscurl,$dsc,$dsc_checked,$skew_warning_vsn);
615
616 sub act_local () { return $dryrun_level <= 1; }
617 sub act_scary () { return !$dryrun_level; }
618
619 sub printdone {
620     if (!$dryrun_level) {
621         progress f_ "%s ok: %s", $us, "@_";
622     } else {
623         progress f_ "would be ok: %s (but dry run only)", "@_";
624     }
625 }
626
627 sub dryrun_report {
628     printcmd(\*STDERR,$debugprefix."#",@_);
629 }
630
631 sub runcmd_ordryrun {
632     if (act_scary()) {
633         runcmd @_;
634     } else {
635         dryrun_report @_;
636     }
637 }
638
639 sub runcmd_ordryrun_local {
640     if (act_local()) {
641         runcmd @_;
642     } else {
643         dryrun_report @_;
644     }
645 }
646
647 our $helpmsg = i_ <<END;
648 main usages:
649   dgit [dgit-opts] clone [dgit-opts] package [suite] [./dir|/dir]
650   dgit [dgit-opts] fetch|pull [dgit-opts] [suite]
651   dgit [dgit-opts] build [dpkg-buildpackage-opts]
652   dgit [dgit-opts] sbuild [sbuild-opts]
653   dgit [dgit-opts] pbuilder|cowbuilder [debbuildopts]
654   dgit [dgit-opts] push [dgit-opts] [suite]
655   dgit [dgit-opts] push-source [dgit-opts] [suite]
656   dgit [dgit-opts] rpush build-host:build-dir ...
657 important dgit options:
658   -k<keyid>           sign tag and package with <keyid> instead of default
659   --dry-run -n        do not change anything, but go through the motions
660   --damp-run -L       like --dry-run but make local changes, without signing
661   --new -N            allow introducing a new package
662   --debug -D          increase debug level
663   -c<name>=<value>    set git config option (used directly by dgit too)
664 END
665
666 our $later_warning_msg = i_ <<END;
667 Perhaps the upload is stuck in incoming.  Using the version from git.
668 END
669
670 sub badusage {
671     print STDERR f_ "%s: %s\n%s", $us, "@_", __ $helpmsg or die $!;
672     finish 8;
673 }
674
675 sub nextarg {
676     @ARGV or badusage __ "too few arguments";
677     return scalar shift @ARGV;
678 }
679
680 sub pre_help () {
681     not_necessarily_a_tree();
682 }
683 sub cmd_help () {
684     print __ $helpmsg or die $!;
685     finish 0;
686 }
687
688 our $td = $ENV{DGIT_TEST_DUMMY_DIR} || "DGIT_TEST_DUMMY_DIR-unset";
689
690 our %defcfg = ('dgit.default.distro' => 'debian',
691                'dgit.default.default-suite' => 'unstable',
692                'dgit.default.old-dsc-distro' => 'debian',
693                'dgit-suite.*-security.distro' => 'debian-security',
694                'dgit.default.username' => '',
695                'dgit.default.archive-query-default-component' => 'main',
696                'dgit.default.ssh' => 'ssh',
697                'dgit.default.archive-query' => 'madison:',
698                'dgit.default.sshpsql-dbname' => 'service=projectb',
699                'dgit.default.aptget-components' => 'main',
700                'dgit.default.dgit-tag-format' => 'new,old,maint',
701                'dgit.default.source-only-uploads' => 'ok',
702                'dgit.dsc-url-proto-ok.http'    => 'true',
703                'dgit.dsc-url-proto-ok.https'   => 'true',
704                'dgit.dsc-url-proto-ok.git'     => 'true',
705                'dgit.vcs-git.suites',          => 'sid', # ;-separated
706                'dgit.default.dsc-url-proto-ok' => 'false',
707                # old means "repo server accepts pushes with old dgit tags"
708                # new means "repo server accepts pushes with new dgit tags"
709                # maint means "repo server accepts split brain pushes"
710                # hist means "repo server may have old pushes without new tag"
711                #   ("hist" is implied by "old")
712                'dgit-distro.debian.archive-query' => 'ftpmasterapi:',
713                'dgit-distro.debian.git-check' => 'url',
714                'dgit-distro.debian.git-check-suffix' => '/info/refs',
715                'dgit-distro.debian.new-private-pushers' => 't',
716                'dgit-distro.debian.source-only-uploads' => 'not-wholly-new',
717                'dgit-distro.debian/push.git-url' => '',
718                'dgit-distro.debian/push.git-host' => 'push.dgit.debian.org',
719                'dgit-distro.debian/push.git-user-force' => 'dgit',
720                'dgit-distro.debian/push.git-proto' => 'git+ssh://',
721                'dgit-distro.debian/push.git-path' => '/dgit/debian/repos',
722                'dgit-distro.debian/push.git-create' => 'true',
723                'dgit-distro.debian/push.git-check' => 'ssh-cmd',
724  'dgit-distro.debian.archive-query-url', 'https://api.ftp-master.debian.org/',
725 # 'dgit-distro.debian.archive-query-tls-key',
726 #    '/etc/ssl/certs/%HOST%.pem:/etc/dgit/%HOST%.pem',
727 # ^ this does not work because curl is broken nowadays
728 # Fixing #790093 properly will involve providing providing the key
729 # in some pacagke and maybe updating these paths.
730 #
731 # 'dgit-distro.debian.archive-query-tls-curl-args',
732 #   '--ca-path=/etc/ssl/ca-debian',
733 # ^ this is a workaround but works (only) on DSA-administered machines
734                'dgit-distro.debian.git-url' => 'https://git.dgit.debian.org',
735                'dgit-distro.debian.git-url-suffix' => '',
736                'dgit-distro.debian.upload-host' => 'ftp-master', # for dput
737                'dgit-distro.debian.mirror' => 'http://ftp.debian.org/debian/',
738  'dgit-distro.debian-security.archive-query' => 'aptget:',
739  'dgit-distro.debian-security.mirror' => 'http://security.debian.org/debian-security/',
740  'dgit-distro.debian-security.aptget-suite-map' => 's#-security$#/updates#',
741  'dgit-distro.debian-security.aptget-suite-rmap' => 's#$#-security#',
742  'dgit-distro.debian-security.nominal-distro' => 'debian',
743  'dgit-distro.debian.backports-quirk' => '(squeeze)-backports*',
744  'dgit-distro.debian-backports.mirror' => 'http://backports.debian.org/debian-backports/',
745                'dgit-distro.ubuntu.git-check' => 'false',
746  'dgit-distro.ubuntu.mirror' => 'http://archive.ubuntu.com/ubuntu',
747                'dgit-distro.test-dummy.ssh' => "$td/ssh",
748                'dgit-distro.test-dummy.username' => "alice",
749                'dgit-distro.test-dummy.git-check' => "ssh-cmd",
750                'dgit-distro.test-dummy.git-create' => "ssh-cmd",
751                'dgit-distro.test-dummy.git-url' => "$td/git",
752                'dgit-distro.test-dummy.git-host' => "git",
753                'dgit-distro.test-dummy.git-path' => "$td/git",
754                'dgit-distro.test-dummy.archive-query' => "dummycatapi:",
755                'dgit-distro.test-dummy.archive-query-url' => "file://$td/aq/",
756                'dgit-distro.test-dummy.mirror' => "file://$td/mirror/",
757                'dgit-distro.test-dummy.upload-host' => 'test-dummy',
758                );
759
760 our %gitcfgs;
761 our @gitcfgsources = qw(cmdline local global system);
762 our $invoked_in_git_tree = 1;
763
764 sub git_slurp_config () {
765     # This algoritm is a bit subtle, but this is needed so that for
766     # options which we want to be single-valued, we allow the
767     # different config sources to override properly.  See #835858.
768     foreach my $src (@gitcfgsources) {
769         next if $src eq 'cmdline';
770         # we do this ourselves since git doesn't handle it
771
772         $gitcfgs{$src} = git_slurp_config_src $src;
773     }
774 }
775
776 sub git_get_config ($) {
777     my ($c) = @_;
778     foreach my $src (@gitcfgsources) {
779         my $l = $gitcfgs{$src}{$c};
780         confess "internal error ($l $c)" if $l && !ref $l;
781         printdebug"C $c ".(defined $l ?
782                            join " ", map { messagequote "'$_'" } @$l :
783                            "undef")."\n"
784             if $debuglevel >= 4;
785         $l or next;
786         @$l==1 or badcfg
787             f_ "multiple values for %s (in %s git config)", $c, $src
788             if @$l > 1;
789         return $l->[0];
790     }
791     return undef;
792 }
793
794 sub cfg {
795     foreach my $c (@_) {
796         return undef if $c =~ /RETURN-UNDEF/;
797         printdebug "C? $c\n" if $debuglevel >= 5;
798         my $v = git_get_config($c);
799         return $v if defined $v;
800         my $dv = $defcfg{$c};
801         if (defined $dv) {
802             printdebug "CD $c $dv\n" if $debuglevel >= 4;
803             return $dv;
804         }
805     }
806     badcfg f_
807         "need value for one of: %s\n".
808         "%s: distro or suite appears not to be (properly) supported",
809         "@_", $us;
810 }
811
812 sub not_necessarily_a_tree () {
813     # needs to be called from pre_*
814     @gitcfgsources = grep { $_ ne 'local' } @gitcfgsources;
815     $invoked_in_git_tree = 0;
816 }
817
818 sub access_basedistro__noalias () {
819     if (defined $idistro) {
820         return $idistro;
821     } else {    
822         my $def = cfg("dgit-suite.$isuite.distro", 'RETURN-UNDEF');
823         return $def if defined $def;
824         foreach my $src (@gitcfgsources, 'internal') {
825             my $kl = $src eq 'internal' ? \%defcfg : $gitcfgs{$src};
826             next unless $kl;
827             foreach my $k (keys %$kl) {
828                 next unless $k =~ m#^dgit-suite\.(.*)\.distro$#;
829                 my $dpat = $1;
830                 next unless match_glob $dpat, $isuite;
831                 return $kl->{$k};
832             }
833         }
834         return cfg("dgit.default.distro");
835     }
836 }
837
838 sub access_basedistro () {
839     my $noalias = access_basedistro__noalias();
840     my $canon = cfg("dgit-distro.$noalias.alias-canon",'RETURN-UNDEF');
841     return $canon // $noalias;
842 }
843
844 sub access_nomdistro () {
845     my $base = access_basedistro();
846     my $r = cfg("dgit-distro.$base.nominal-distro",'RETURN-UNDEF') // $base;
847     $r =~ m/^$distro_re$/ or badcfg
848         f_ "bad syntax for (nominal) distro \`%s' (does not match %s)",
849         $r, "/^$distro_re$/";
850     return $r;
851 }
852
853 sub access_quirk () {
854     # returns (quirk name, distro to use instead or undef, quirk-specific info)
855     my $basedistro = access_basedistro();
856     my $backports_quirk = cfg("dgit-distro.$basedistro.backports-quirk",
857                               'RETURN-UNDEF');
858     if (defined $backports_quirk) {
859         my $re = $backports_quirk;
860         $re =~ s/[^-0-9a-z_\%*()]/\\$&/ig;
861         $re =~ s/\*/.*/g;
862         $re =~ s/\%/([-0-9a-z_]+)/
863             or $re =~ m/[()]/ or badcfg __ "backports-quirk needs \% or ( )";
864         if ($isuite =~ m/^$re$/) {
865             return ('backports',"$basedistro-backports",$1);
866         }
867     }
868     return ('none',undef);
869 }
870
871 our $access_forpush;
872
873 sub parse_cfg_bool ($$$) {
874     my ($what,$def,$v) = @_;
875     $v //= $def;
876     return
877         $v =~ m/^[ty1]/ ? 1 :
878         $v =~ m/^[fn0]/ ? 0 :
879         badcfg f_ "%s needs t (true, y, 1) or f (false, n, 0) not \`%s'",
880             $what, $v;
881 }       
882
883 sub access_forpush_config () {
884     my $d = access_basedistro();
885
886     return 1 if
887         $new_package &&
888         parse_cfg_bool('new-private-pushers', 0,
889                        cfg("dgit-distro.$d.new-private-pushers",
890                            'RETURN-UNDEF'));
891
892     my $v = cfg("dgit-distro.$d.readonly", 'RETURN-UNDEF');
893     $v //= 'a';
894     return
895         $v =~ m/^[ty1]/ ? 0 : # force readonly,    forpush = 0
896         $v =~ m/^[fn0]/ ? 1 : # force nonreadonly, forpush = 1
897         $v =~ m/^[a]/  ? '' : # auto,              forpush = ''
898         badcfg __
899             "readonly needs t (true, y, 1) or f (false, n, 0) or a (auto)";
900 }
901
902 sub access_forpush () {
903     $access_forpush //= access_forpush_config();
904     return $access_forpush;
905 }
906
907 sub pushing () {
908     confess +(__ 'internal error').' '.Dumper($access_forpush)," ?" if
909         defined $access_forpush and !$access_forpush;
910     badcfg __ "pushing but distro is configured readonly"
911         if access_forpush_config() eq '0';
912     $access_forpush = 1;
913     $supplementary_message = __ <<'END' unless $we_are_responder;
914 Push failed, before we got started.
915 You can retry the push, after fixing the problem, if you like.
916 END
917     parseopts_late_defaults();
918 }
919
920 sub notpushing () {
921     parseopts_late_defaults();
922 }
923
924 sub supplementary_message ($) {
925     my ($msg) = @_;
926     if (!$we_are_responder) {
927         $supplementary_message = $msg;
928         return;
929     } elsif ($protovsn >= 3) {
930         responder_send_command "supplementary-message ".length($msg)
931             or die $!;
932         print PO $msg or die $!;
933     }
934 }
935
936 sub access_distros () {
937     # Returns list of distros to try, in order
938     #
939     # We want to try:
940     #    0. `instead of' distro name(s) we have been pointed to
941     #    1. the access_quirk distro, if any
942     #    2a. the user's specified distro, or failing that  } basedistro
943     #    2b. the distro calculated from the suite          }
944     my @l = access_basedistro();
945
946     my (undef,$quirkdistro) = access_quirk();
947     unshift @l, $quirkdistro;
948     unshift @l, $instead_distro;
949     @l = grep { defined } @l;
950
951     push @l, access_nomdistro();
952
953     if (access_forpush()) {
954         @l = map { ("$_/push", $_) } @l;
955     }
956     @l;
957 }
958
959 sub access_cfg_cfgs (@) {
960     my (@keys) = @_;
961     my @cfgs;
962     # The nesting of these loops determines the search order.  We put
963     # the key loop on the outside so that we search all the distros
964     # for each key, before going on to the next key.  That means that
965     # if access_cfg is called with a more specific, and then a less
966     # specific, key, an earlier distro can override the less specific
967     # without necessarily overriding any more specific keys.  (If the
968     # distro wants to override the more specific keys it can simply do
969     # so; whereas if we did the loop the other way around, it would be
970     # impossible to for an earlier distro to override a less specific
971     # key but not the more specific ones without restating the unknown
972     # values of the more specific keys.
973     my @realkeys;
974     my @rundef;
975     # We have to deal with RETURN-UNDEF specially, so that we don't
976     # terminate the search prematurely.
977     foreach (@keys) {
978         if (m/RETURN-UNDEF/) { push @rundef, $_; last; }
979         push @realkeys, $_
980     }
981     foreach my $d (access_distros()) {
982         push @cfgs, map { "dgit-distro.$d.$_" } @realkeys;
983     }
984     push @cfgs, map { "dgit.default.$_" } @realkeys;
985     push @cfgs, @rundef;
986     return @cfgs;
987 }
988
989 sub access_cfg (@) {
990     my (@keys) = @_;
991     my (@cfgs) = access_cfg_cfgs(@keys);
992     my $value = cfg(@cfgs);
993     return $value;
994 }
995
996 sub access_cfg_bool ($$) {
997     my ($def, @keys) = @_;
998     parse_cfg_bool($keys[0], $def, access_cfg(@keys, 'RETURN-UNDEF'));
999 }
1000
1001 sub string_to_ssh ($) {
1002     my ($spec) = @_;
1003     if ($spec =~ m/\s/) {
1004         return qw(sh -ec), 'exec '.$spec.' "$@"', 'x';
1005     } else {
1006         return ($spec);
1007     }
1008 }
1009
1010 sub access_cfg_ssh () {
1011     my $gitssh = access_cfg('ssh', 'RETURN-UNDEF');
1012     if (!defined $gitssh) {
1013         return @ssh;
1014     } else {
1015         return string_to_ssh $gitssh;
1016     }
1017 }
1018
1019 sub access_runeinfo ($) {
1020     my ($info) = @_;
1021     return ": dgit ".access_basedistro()." $info ;";
1022 }
1023
1024 sub access_someuserhost ($) {
1025     my ($some) = @_;
1026     my $user = access_cfg("$some-user-force", 'RETURN-UNDEF');
1027     defined($user) && length($user) or
1028         $user = access_cfg("$some-user",'username');
1029     my $host = access_cfg("$some-host");
1030     return length($user) ? "$user\@$host" : $host;
1031 }
1032
1033 sub access_gituserhost () {
1034     return access_someuserhost('git');
1035 }
1036
1037 sub access_giturl (;$) {
1038     my ($optional) = @_;
1039     my $url = access_cfg('git-url','RETURN-UNDEF');
1040     my $suffix;
1041     if (!length $url) {
1042         my $proto = access_cfg('git-proto', 'RETURN-UNDEF');
1043         return undef unless defined $proto;
1044         $url =
1045             $proto.
1046             access_gituserhost().
1047             access_cfg('git-path');
1048     } else {
1049         $suffix = access_cfg('git-url-suffix','RETURN-UNDEF');
1050     }
1051     $suffix //= '.git';
1052     return "$url/$package$suffix";
1053 }              
1054
1055 sub commit_getclogp ($) {
1056     # Returns the parsed changelog hashref for a particular commit
1057     my ($objid) = @_;
1058     our %commit_getclogp_memo;
1059     my $memo = $commit_getclogp_memo{$objid};
1060     return $memo if $memo;
1061
1062     my $mclog = dgit_privdir()."clog";
1063     runcmd shell_cmd "exec >$mclog", @git, qw(cat-file blob),
1064         "$objid:debian/changelog";
1065     $commit_getclogp_memo{$objid} = parsechangelog("-l$mclog");
1066 }
1067
1068 sub parse_dscdata () {
1069     my $dscfh = new IO::File \$dscdata, '<' or die $!;
1070     printdebug Dumper($dscdata) if $debuglevel>1;
1071     $dsc = parsecontrolfh($dscfh,$dscurl,1);
1072     printdebug Dumper($dsc) if $debuglevel>1;
1073 }
1074
1075 our %rmad;
1076
1077 sub archive_query ($;@) {
1078     my ($method) = shift @_;
1079     fail __ "this operation does not support multiple comma-separated suites"
1080         if $isuite =~ m/,/;
1081     my $query = access_cfg('archive-query','RETURN-UNDEF');
1082     $query =~ s/^(\w+):// or badcfg "invalid archive-query method \`$query'";
1083     my $proto = $1;
1084     my $data = $'; #';
1085     { no strict qw(refs); &{"${method}_${proto}"}($proto,$data,@_); }
1086 }
1087
1088 sub archive_query_prepend_mirror {
1089     my $m = access_cfg('mirror');
1090     return map { [ $_->[0], $m.$_->[1], @$_[2..$#$_] ] } @_;
1091 }
1092
1093 sub pool_dsc_subpath ($$) {
1094     my ($vsn,$component) = @_; # $package is implict arg
1095     my $prefix = substr($package, 0, $package =~ m/^l/ ? 4 : 1);
1096     return "/pool/$component/$prefix/$package/".dscfn($vsn);
1097 }
1098
1099 sub cfg_apply_map ($$$) {
1100     my ($varref, $what, $mapspec) = @_;
1101     return unless $mapspec;
1102
1103     printdebug "config $what EVAL{ $mapspec; }\n";
1104     $_ = $$varref;
1105     eval "package Dgit::Config; $mapspec;";
1106     die $@ if $@;
1107     $$varref = $_;
1108 }
1109
1110 #---------- `ftpmasterapi' archive query method (nascent) ----------
1111
1112 sub archive_api_query_cmd ($) {
1113     my ($subpath) = @_;
1114     my @cmd = (@curl, qw(-sS));
1115     my $url = access_cfg('archive-query-url');
1116     if ($url =~ m#^https://([-.0-9a-z]+)/#) {
1117         my $host = $1;
1118         my $keys = access_cfg('archive-query-tls-key','RETURN-UNDEF') //'';
1119         foreach my $key (split /\:/, $keys) {
1120             $key =~ s/\%HOST\%/$host/g;
1121             if (!stat $key) {
1122                 fail "for $url: stat $key: $!" unless $!==ENOENT;
1123                 next;
1124             }
1125             fail f_ "config requested specific TLS key but do not know".
1126                     " how to get curl to use exactly that EE key (%s)",
1127                     $key;
1128 #           push @cmd, "--cacert", $key, "--capath", "/dev/enoent";
1129 #           # Sadly the above line does not work because of changes
1130 #           # to gnutls.   The real fix for #790093 may involve
1131 #           # new curl options.
1132             last;
1133         }
1134         # Fixing #790093 properly will involve providing a value
1135         # for this on clients.
1136         my $kargs = access_cfg('archive-query-tls-curl-ca-args','RETURN-UNDEF');
1137         push @cmd, split / /, $kargs if defined $kargs;
1138     }
1139     push @cmd, $url.$subpath;
1140     return @cmd;
1141 }
1142
1143 sub api_query ($$;$) {
1144     use JSON;
1145     my ($data, $subpath, $ok404) = @_;
1146     badcfg __ "ftpmasterapi archive query method takes no data part"
1147         if length $data;
1148     my @cmd = archive_api_query_cmd($subpath);
1149     my $url = $cmd[$#cmd];
1150     push @cmd, qw(-w %{http_code});
1151     my $json = cmdoutput @cmd;
1152     unless ($json =~ s/\d+\d+\d$//) {
1153         failedcmd_report_cmd undef, @cmd;
1154         fail __ "curl failed to print 3-digit HTTP code";
1155     }
1156     my $code = $&;
1157     return undef if $code eq '404' && $ok404;
1158     fail f_ "fetch of %s gave HTTP code %s", $url, $code
1159         unless $url =~ m#^file://# or $code =~ m/^2/;
1160     return decode_json($json);
1161 }
1162
1163 sub canonicalise_suite_ftpmasterapi {
1164     my ($proto,$data) = @_;
1165     my $suites = api_query($data, 'suites');
1166     my @matched;
1167     foreach my $entry (@$suites) {
1168         next unless grep { 
1169             my $v = $entry->{$_};
1170             defined $v && $v eq $isuite;
1171         } qw(codename name);
1172         push @matched, $entry;
1173     }
1174     fail f_ "unknown suite %s, maybe -d would help", $isuite
1175         unless @matched;
1176     my $cn;
1177     eval {
1178         @matched==1 or die f_ "multiple matches for suite %s\n", $isuite;
1179         $cn = "$matched[0]{codename}";
1180         defined $cn or die f_ "suite %s info has no codename\n", $isuite;
1181         $cn =~ m/^$suite_re$/
1182             or die f_ "suite %s maps to bad codename\n", $isuite;
1183     };
1184     die +(__ "bad ftpmaster api response: ")."$@\n".Dumper(\@matched)
1185         if length $@;
1186     return $cn;
1187 }
1188
1189 sub archive_query_ftpmasterapi {
1190     my ($proto,$data) = @_;
1191     my $info = api_query($data, "dsc_in_suite/$isuite/$package");
1192     my @rows;
1193     my $digester = Digest::SHA->new(256);
1194     foreach my $entry (@$info) {
1195         eval {
1196             my $vsn = "$entry->{version}";
1197             my ($ok,$msg) = version_check $vsn;
1198             die f_ "bad version: %s\n", $msg unless $ok;
1199             my $component = "$entry->{component}";
1200             $component =~ m/^$component_re$/ or die __ "bad component";
1201             my $filename = "$entry->{filename}";
1202             $filename && $filename !~ m#[^-+:._~0-9a-zA-Z/]|^[/.]|/[/.]#
1203                 or die __ "bad filename";
1204             my $sha256sum = "$entry->{sha256sum}";
1205             $sha256sum =~ m/^[0-9a-f]+$/ or die __ "bad sha256sum";
1206             push @rows, [ $vsn, "/pool/$component/$filename",
1207                           $digester, $sha256sum ];
1208         };
1209         die +(__ "bad ftpmaster api response: ")."$@\n".Dumper($entry)
1210             if length $@;
1211     }
1212     @rows = sort { -version_compare($a->[0],$b->[0]) } @rows;
1213     return archive_query_prepend_mirror @rows;
1214 }
1215
1216 sub file_in_archive_ftpmasterapi {
1217     my ($proto,$data,$filename) = @_;
1218     my $pat = $filename;
1219     $pat =~ s/_/\\_/g;
1220     $pat = "%/$pat";
1221     $pat =~ s#[^-+_.0-9a-z/]# sprintf '%%%02x', ord $& #ge;
1222     my $info = api_query($data, "file_in_archive/$pat", 1);
1223 }
1224
1225 sub package_not_wholly_new_ftpmasterapi {
1226     my ($proto,$data,$pkg) = @_;
1227     my $info = api_query($data,"madison?package=${pkg}&f=json");
1228     return !!@$info;
1229 }
1230
1231 #---------- `aptget' archive query method ----------
1232
1233 our $aptget_base;
1234 our $aptget_releasefile;
1235 our $aptget_configpath;
1236
1237 sub aptget_aptget   () { return @aptget,   qw(-c), $aptget_configpath; }
1238 sub aptget_aptcache () { return @aptcache, qw(-c), $aptget_configpath; }
1239
1240 sub aptget_cache_clean {
1241     runcmd_ordryrun_local qw(sh -ec),
1242         'cd "$1"; find -atime +30 -type f -print0 | xargs -0r rm --',
1243         'x', $aptget_base;
1244 }
1245
1246 sub aptget_lock_acquire () {
1247     my $lockfile = "$aptget_base/lock";
1248     open APTGET_LOCK, '>', $lockfile or confess "open $lockfile: $!";
1249     flock APTGET_LOCK, LOCK_EX or confess "lock $lockfile: $!";
1250 }
1251
1252 sub aptget_prep ($) {
1253     my ($data) = @_;
1254     return if defined $aptget_base;
1255
1256     badcfg __ "aptget archive query method takes no data part"
1257         if length $data;
1258
1259     my $cache = $ENV{XDG_CACHE_DIR} // "$ENV{HOME}/.cache";
1260
1261     ensuredir $cache;
1262     ensuredir "$cache/dgit";
1263     my $cachekey =
1264         access_cfg('aptget-cachekey','RETURN-UNDEF')
1265         // access_nomdistro();
1266
1267     $aptget_base = "$cache/dgit/aptget";
1268     ensuredir $aptget_base;
1269
1270     my $quoted_base = $aptget_base;
1271     confess "$quoted_base contains bad chars, cannot continue"
1272         if $quoted_base =~ m/["\\]/; # apt.conf(5) says no escaping :-/
1273
1274     ensuredir $aptget_base;
1275
1276     aptget_lock_acquire();
1277
1278     aptget_cache_clean();
1279
1280     $aptget_configpath = "$aptget_base/apt.conf#$cachekey";
1281     my $sourceslist = "source.list#$cachekey";
1282
1283     my $aptsuites = $isuite;
1284     cfg_apply_map(\$aptsuites, 'suite map',
1285                   access_cfg('aptget-suite-map', 'RETURN-UNDEF'));
1286
1287     open SRCS, ">", "$aptget_base/$sourceslist" or confess $!;
1288     printf SRCS "deb-src %s %s %s\n",
1289         access_cfg('mirror'),
1290         $aptsuites,
1291         access_cfg('aptget-components')
1292         or die $!;
1293
1294     ensuredir "$aptget_base/cache";
1295     ensuredir "$aptget_base/lists";
1296
1297     open CONF, ">", $aptget_configpath or die $!;
1298     print CONF <<END;
1299 Debug::NoLocking "true";
1300 APT::Get::List-Cleanup "false";
1301 #clear APT::Update::Post-Invoke-Success;
1302 Dir::Etc::SourceList "$quoted_base/$sourceslist";
1303 Dir::State::Lists "$quoted_base/lists";
1304 Dir::Etc::preferences "$quoted_base/preferences";
1305 Dir::Cache::srcpkgcache "$quoted_base/cache/srcs#$cachekey";
1306 Dir::Cache::pkgcache "$quoted_base/cache/pkgs#$cachekey";
1307 END
1308
1309     foreach my $key (qw(
1310                         Dir::Cache
1311                         Dir::State
1312                         Dir::Cache::Archives
1313                         Dir::Etc::SourceParts
1314                         Dir::Etc::preferencesparts
1315                       )) {
1316         ensuredir "$aptget_base/$key";
1317         print CONF "$key \"$quoted_base/$key\";\n" or die $!;
1318     };
1319
1320     my $oldatime = (time // die $!) - 1;
1321     foreach my $oldlist (<$aptget_base/lists/*Release>) {
1322         next unless stat_exists $oldlist;
1323         my ($mtime) = (stat _)[9];
1324         utime $oldatime, $mtime, $oldlist or die "$oldlist $!";
1325     }
1326
1327     runcmd_ordryrun_local aptget_aptget(), qw(update);
1328
1329     my @releasefiles;
1330     foreach my $oldlist (<$aptget_base/lists/*Release>) {
1331         next unless stat_exists $oldlist;
1332         my ($atime) = (stat _)[8];
1333         next if $atime == $oldatime;
1334         push @releasefiles, $oldlist;
1335     }
1336     my @inreleasefiles = grep { m#/InRelease$# } @releasefiles;
1337     @releasefiles = @inreleasefiles if @inreleasefiles;
1338     if (!@releasefiles) {
1339         fail f_ <<END, $isuite, $cache;
1340 apt seemed to not to update dgit's cached Release files for %s.
1341 (Perhaps %s
1342  is on a filesystem mounted `noatime'; if so, please use `relatime'.)
1343 END
1344     }
1345     confess "apt updated too many Release files (@releasefiles), erk"
1346         unless @releasefiles == 1;
1347
1348     ($aptget_releasefile) = @releasefiles;
1349 }
1350
1351 sub canonicalise_suite_aptget {
1352     my ($proto,$data) = @_;
1353     aptget_prep($data);
1354
1355     my $release = parsecontrol $aptget_releasefile, "Release file", 1;
1356
1357     foreach my $name (qw(Codename Suite)) {
1358         my $val = $release->{$name};
1359         if (defined $val) {
1360             printdebug "release file $name: $val\n";
1361             $val =~ m/^$suite_re$/o or fail f_
1362                 "Release file (%s) specifies intolerable %s",
1363                 $aptget_releasefile, $name;
1364             cfg_apply_map(\$val, 'suite rmap',
1365                           access_cfg('aptget-suite-rmap', 'RETURN-UNDEF'));
1366             return $val
1367         }
1368     }
1369     return $isuite;
1370 }
1371
1372 sub archive_query_aptget {
1373     my ($proto,$data) = @_;
1374     aptget_prep($data);
1375
1376     ensuredir "$aptget_base/source";
1377     foreach my $old (<$aptget_base/source/*.dsc>) {
1378         unlink $old or die "$old: $!";
1379     }
1380
1381     my $showsrc = cmdoutput aptget_aptcache(), qw(showsrc), $package;
1382     return () unless $showsrc =~ m/^package:\s*\Q$package\E\s*$/mi;
1383     # avoids apt-get source failing with ambiguous error code
1384
1385     runcmd_ordryrun_local
1386         shell_cmd 'cd "$1"/source; shift', $aptget_base,
1387         aptget_aptget(), qw(--download-only --only-source source), $package;
1388
1389     my @dscs = <$aptget_base/source/*.dsc>;
1390     fail __ "apt-get source did not produce a .dsc" unless @dscs;
1391     fail f_ "apt-get source produced several .dscs (%s)", "@dscs"
1392         unless @dscs==1;
1393
1394     my $pre_dsc = parsecontrol $dscs[0], $dscs[0], 1;
1395
1396     use URI::Escape;
1397     my $uri = "file://". uri_escape $dscs[0];
1398     $uri =~ s{\%2f}{/}gi;
1399     return [ (getfield $pre_dsc, 'Version'), $uri ];
1400 }
1401
1402 sub file_in_archive_aptget () { return undef; }
1403 sub package_not_wholly_new_aptget () { return undef; }
1404
1405 #---------- `dummyapicat' archive query method ----------
1406 # (untranslated, because this is for testing purposes etc.)
1407
1408 sub archive_query_dummycatapi { archive_query_ftpmasterapi @_; }
1409 sub canonicalise_suite_dummycatapi { canonicalise_suite_ftpmasterapi @_; }
1410
1411 sub dummycatapi_run_in_mirror ($@) {
1412     # runs $fn with FIA open onto rune
1413     my ($rune, $argl, $fn) = @_;
1414
1415     my $mirror = access_cfg('mirror');
1416     $mirror =~ s#^file://#/# or die "$mirror ?";
1417     my @cmd = (qw(sh -ec), 'cd "$1"; shift'."\n".$rune,
1418                qw(x), $mirror, @$argl);
1419     debugcmd "-|", @cmd;
1420     open FIA, "-|", @cmd or die $!;
1421     my $r = $fn->();
1422     close FIA or ($!==0 && $?==141) or die failedcmd @cmd;
1423     return $r;
1424 }
1425
1426 sub file_in_archive_dummycatapi ($$$) {
1427     my ($proto,$data,$filename) = @_;
1428     my @out;
1429     dummycatapi_run_in_mirror '
1430             find -name "$1" -print0 |
1431             xargs -0r sha256sum
1432     ', [$filename], sub {
1433         while (<FIA>) {
1434             chomp or die;
1435             printdebug "| $_\n";
1436             m/^(\w+)  (\S+)$/ or die "$_ ?";
1437             push @out, { sha256sum => $1, filename => $2 };
1438         }
1439     };
1440     return \@out;
1441 }
1442
1443 sub package_not_wholly_new_dummycatapi {
1444     my ($proto,$data,$pkg) = @_;
1445     dummycatapi_run_in_mirror "
1446             find -name ${pkg}_*.dsc
1447     ", [], sub {
1448         local $/ = undef;
1449         !!<FIA>;
1450     };
1451 }
1452
1453 #---------- `madison' archive query method ----------
1454
1455 sub archive_query_madison {
1456     return archive_query_prepend_mirror
1457         map { [ @$_[0..1] ] } madison_get_parse(@_);
1458 }
1459
1460 sub madison_get_parse {
1461     my ($proto,$data) = @_;
1462     die unless $proto eq 'madison';
1463     if (!length $data) {
1464         $data= access_cfg('madison-distro','RETURN-UNDEF');
1465         $data //= access_basedistro();
1466     }
1467     $rmad{$proto,$data,$package} ||= cmdoutput
1468         qw(rmadison -asource),"-s$isuite","-u$data",$package;
1469     my $rmad = $rmad{$proto,$data,$package};
1470
1471     my @out;
1472     foreach my $l (split /\n/, $rmad) {
1473         $l =~ m{^ \s*( [^ \t|]+ )\s* \|
1474                   \s*( [^ \t|]+ )\s* \|
1475                   \s*( [^ \t|/]+ )(?:/([^ \t|/]+))? \s* \|
1476                   \s*( [^ \t|]+ )\s* }x or die "$rmad ?";
1477         $1 eq $package or die "$rmad $package ?";
1478         my $vsn = $2;
1479         my $newsuite = $3;
1480         my $component;
1481         if (defined $4) {
1482             $component = $4;
1483         } else {
1484             $component = access_cfg('archive-query-default-component');
1485         }
1486         $5 eq 'source' or die "$rmad ?";
1487         push @out, [$vsn,pool_dsc_subpath($vsn,$component),$newsuite];
1488     }
1489     return sort { -version_compare($a->[0],$b->[0]); } @out;
1490 }
1491
1492 sub canonicalise_suite_madison {
1493     # madison canonicalises for us
1494     my @r = madison_get_parse(@_);
1495     @r or fail f_
1496         "unable to canonicalise suite using package %s".
1497         " which does not appear to exist in suite %s;".
1498         " --existing-package may help",
1499         $package, $isuite;
1500     return $r[0][2];
1501 }
1502
1503 sub file_in_archive_madison { return undef; }
1504 sub package_not_wholly_new_madison { return undef; }
1505
1506 #---------- `sshpsql' archive query method ----------
1507 # (untranslated, because this is obsolete)
1508
1509 sub sshpsql ($$$) {
1510     my ($data,$runeinfo,$sql) = @_;
1511     if (!length $data) {
1512         $data= access_someuserhost('sshpsql').':'.
1513             access_cfg('sshpsql-dbname');
1514     }
1515     $data =~ m/:/ or badcfg "invalid sshpsql method string \`$data'";
1516     my ($userhost,$dbname) = ($`,$'); #';
1517     my @rows;
1518     my @cmd = (access_cfg_ssh, $userhost,
1519                access_runeinfo("ssh-psql $runeinfo").
1520                " export LC_MESSAGES=C; export LC_CTYPE=C;".
1521                " ".shellquote qw(psql -A), $dbname, qw(-c), $sql);
1522     debugcmd "|",@cmd;
1523     open P, "-|", @cmd or die $!;
1524     while (<P>) {
1525         chomp or die;
1526         printdebug(">|$_|\n");
1527         push @rows, $_;
1528     }
1529     $!=0; $?=0; close P or failedcmd @cmd;
1530     @rows or die;
1531     my $nrows = pop @rows;
1532     $nrows =~ s/^\((\d+) rows?\)$/$1/ or die "$nrows ?";
1533     @rows == $nrows+1 or die "$nrows ".(scalar @rows)." ?";
1534     @rows = map { [ split /\|/, $_ ] } @rows;
1535     my $ncols = scalar @{ shift @rows };
1536     die if grep { scalar @$_ != $ncols } @rows;
1537     return @rows;
1538 }
1539
1540 sub sql_injection_check {
1541     foreach (@_) { die "$_ $& ?" if m{[^-+=:_.,/0-9a-zA-Z]}; }
1542 }
1543
1544 sub archive_query_sshpsql ($$) {
1545     my ($proto,$data) = @_;
1546     sql_injection_check $isuite, $package;
1547     my @rows = sshpsql($data, "archive-query $isuite $package", <<END);
1548         SELECT source.version, component.name, files.filename, files.sha256sum
1549           FROM source
1550           JOIN src_associations ON source.id = src_associations.source
1551           JOIN suite ON suite.id = src_associations.suite
1552           JOIN dsc_files ON dsc_files.source = source.id
1553           JOIN files_archive_map ON files_archive_map.file_id = dsc_files.file
1554           JOIN component ON component.id = files_archive_map.component_id
1555           JOIN files ON files.id = dsc_files.file
1556          WHERE ( suite.suite_name='$isuite' OR suite.codename='$isuite' )
1557            AND source.source='$package'
1558            AND files.filename LIKE '%.dsc';
1559 END
1560     @rows = sort { -version_compare($a->[0],$b->[0]) } @rows;
1561     my $digester = Digest::SHA->new(256);
1562     @rows = map {
1563         my ($vsn,$component,$filename,$sha256sum) = @$_;
1564         [ $vsn, "/pool/$component/$filename",$digester,$sha256sum ];
1565     } @rows;
1566     return archive_query_prepend_mirror @rows;
1567 }
1568
1569 sub canonicalise_suite_sshpsql ($$) {
1570     my ($proto,$data) = @_;
1571     sql_injection_check $isuite;
1572     my @rows = sshpsql($data, "canonicalise-suite $isuite", <<END);
1573         SELECT suite.codename
1574           FROM suite where suite_name='$isuite' or codename='$isuite';
1575 END
1576     @rows = map { $_->[0] } @rows;
1577     fail "unknown suite $isuite" unless @rows;
1578     die "ambiguous $isuite: @rows ?" if @rows>1;
1579     return $rows[0];
1580 }
1581
1582 sub file_in_archive_sshpsql ($$$) { return undef; }
1583 sub package_not_wholly_new_sshpsql ($$$) { return undef; }
1584
1585 #---------- `dummycat' archive query method ----------
1586 # (untranslated, because this is for testing purposes etc.)
1587
1588 sub canonicalise_suite_dummycat ($$) {
1589     my ($proto,$data) = @_;
1590     my $dpath = "$data/suite.$isuite";
1591     if (!open C, "<", $dpath) {
1592         $!==ENOENT or die "$dpath: $!";
1593         printdebug "dummycat canonicalise_suite $isuite $dpath ENOENT\n";
1594         return $isuite;
1595     }
1596     $!=0; $_ = <C>;
1597     chomp or die "$dpath: $!";
1598     close C;
1599     printdebug "dummycat canonicalise_suite $isuite $dpath = $_\n";
1600     return $_;
1601 }
1602
1603 sub archive_query_dummycat ($$) {
1604     my ($proto,$data) = @_;
1605     canonicalise_suite();
1606     my $dpath = "$data/package.$csuite.$package";
1607     if (!open C, "<", $dpath) {
1608         $!==ENOENT or die "$dpath: $!";
1609         printdebug "dummycat query $csuite $package $dpath ENOENT\n";
1610         return ();
1611     }
1612     my @rows;
1613     while (<C>) {
1614         next if m/^\#/;
1615         next unless m/\S/;
1616         die unless chomp;
1617         printdebug "dummycat query $csuite $package $dpath | $_\n";
1618         my @row = split /\s+/, $_;
1619         @row==2 or die "$dpath: $_ ?";
1620         push @rows, \@row;
1621     }
1622     C->error and die "$dpath: $!";
1623     close C;
1624     return archive_query_prepend_mirror
1625         sort { -version_compare($a->[0],$b->[0]); } @rows;
1626 }
1627
1628 sub file_in_archive_dummycat () { return undef; }
1629 sub package_not_wholly_new_dummycat () { return undef; }
1630
1631 #---------- tag format handling ----------
1632 # (untranslated, because everything should be new tag format by now)
1633
1634 sub access_cfg_tagformats () {
1635     split /\,/, access_cfg('dgit-tag-format');
1636 }
1637
1638 sub access_cfg_tagformats_can_splitbrain () {
1639     my %y = map { $_ => 1 } access_cfg_tagformats;
1640     foreach my $needtf (qw(new maint)) {
1641         next if $y{$needtf};
1642         return 0;
1643     }
1644     return 1;
1645 }
1646
1647 sub need_tagformat ($$) {
1648     my ($fmt, $why) = @_;
1649     fail "need to use tag format $fmt ($why) but also need".
1650         " to use tag format $tagformat_want->[0] ($tagformat_want->[1])".
1651         " - no way to proceed"
1652         if $tagformat_want && $tagformat_want->[0] ne $fmt;
1653     $tagformat_want = [$fmt, $why, $tagformat_want->[2] // 0];
1654 }
1655
1656 sub select_tagformat () {
1657     # sets $tagformatfn
1658     return if $tagformatfn && !$tagformat_want;
1659     die 'bug' if $tagformatfn && $tagformat_want;
1660     # ... $tagformat_want assigned after previous select_tagformat
1661
1662     my (@supported) = grep { $_ =~ m/^(?:old|new)$/ } access_cfg_tagformats();
1663     printdebug "select_tagformat supported @supported\n";
1664
1665     $tagformat_want //= [ $supported[0], "distro access configuration", 0 ];
1666     printdebug "select_tagformat specified @$tagformat_want\n";
1667
1668     my ($fmt,$why,$override) = @$tagformat_want;
1669
1670     fail "target distro supports tag formats @supported".
1671         " but have to use $fmt ($why)"
1672         unless $override
1673             or grep { $_ eq $fmt } @supported;
1674
1675     $tagformat_want = undef;
1676     $tagformat = $fmt;
1677     $tagformatfn = ${*::}{"debiantag_$fmt"};
1678
1679     fail "trying to use unknown tag format \`$fmt' ($why) !"
1680         unless $tagformatfn;
1681 }
1682
1683 #---------- archive query entrypoints and rest of program ----------
1684
1685 sub canonicalise_suite () {
1686     return if defined $csuite;
1687     fail f_ "cannot operate on %s suite", $isuite if $isuite eq 'UNRELEASED';
1688     $csuite = archive_query('canonicalise_suite');
1689     if ($isuite ne $csuite) {
1690         progress f_ "canonical suite name for %s is %s", $isuite, $csuite;
1691     } else {
1692         progress f_ "canonical suite name is %s", $csuite;
1693     }
1694 }
1695
1696 sub get_archive_dsc () {
1697     canonicalise_suite();
1698     my @vsns = archive_query('archive_query');
1699     foreach my $vinfo (@vsns) {
1700         my ($vsn,$vsn_dscurl,$digester,$digest) = @$vinfo;
1701         $dscurl = $vsn_dscurl;
1702         $dscdata = url_get($dscurl);
1703         if (!$dscdata) {
1704             $skew_warning_vsn = $vsn if !defined $skew_warning_vsn;
1705             next;
1706         }
1707         if ($digester) {
1708             $digester->reset();
1709             $digester->add($dscdata);
1710             my $got = $digester->hexdigest();
1711             $got eq $digest or
1712                 fail f_ "%s has hash %s but archive told us to expect %s",
1713                         $dscurl, $got, $digest;
1714         }
1715         parse_dscdata();
1716         my $fmt = getfield $dsc, 'Format';
1717         $format_ok{$fmt} or forceable_fail [qw(unsupported-source-format)],
1718             f_ "unsupported source format %s, sorry", $fmt;
1719             
1720         $dsc_checked = !!$digester;
1721         printdebug "get_archive_dsc: Version ".(getfield $dsc, 'Version')."\n";
1722         return;
1723     }
1724     $dsc = undef;
1725     printdebug "get_archive_dsc: nothing in archive, returning undef\n";
1726 }
1727
1728 sub check_for_git ();
1729 sub check_for_git () {
1730     # returns 0 or 1
1731     my $how = access_cfg('git-check');
1732     if ($how eq 'ssh-cmd') {
1733         my @cmd =
1734             (access_cfg_ssh, access_gituserhost(),
1735              access_runeinfo("git-check $package").
1736              " set -e; cd ".access_cfg('git-path').";".
1737              " if test -d $package.git; then echo 1; else echo 0; fi");
1738         my $r= cmdoutput @cmd;
1739         if (defined $r and $r =~ m/^divert (\w+)$/) {
1740             my $divert=$1;
1741             my ($usedistro,) = access_distros();
1742             # NB that if we are pushing, $usedistro will be $distro/push
1743             $instead_distro= cfg("dgit-distro.$usedistro.diverts.$divert");
1744             $instead_distro =~ s{^/}{ access_basedistro()."/" }e;
1745             progress f_ "diverting to %s (using config for %s)",
1746                         $divert, $instead_distro;
1747             return check_for_git();
1748         }
1749         failedcmd @cmd unless defined $r and $r =~ m/^[01]$/;
1750         return $r+0;
1751     } elsif ($how eq 'url') {
1752         my $prefix = access_cfg('git-check-url','git-url');
1753         my $suffix = access_cfg('git-check-suffix','git-suffix',
1754                                 'RETURN-UNDEF') // '.git';
1755         my $url = "$prefix/$package$suffix";
1756         my @cmd = (@curl, qw(-sS -I), $url);
1757         my $result = cmdoutput @cmd;
1758         $result =~ s/^\S+ 200 .*\n\r?\n//;
1759         # curl -sS -I with https_proxy prints
1760         # HTTP/1.0 200 Connection established
1761         $result =~ m/^\S+ (404|200) /s or
1762             fail +(__ "unexpected results from git check query - ").
1763                 Dumper($prefix, $result);
1764         my $code = $1;
1765         if ($code eq '404') {
1766             return 0;
1767         } elsif ($code eq '200') {
1768             return 1;
1769         } else {
1770             die;
1771         }
1772     } elsif ($how eq 'true') {
1773         return 1;
1774     } elsif ($how eq 'false') {
1775         return 0;
1776     } else {
1777         badcfg f_ "unknown git-check \`%s'", $how;
1778     }
1779 }
1780
1781 sub create_remote_git_repo () {
1782     my $how = access_cfg('git-create');
1783     if ($how eq 'ssh-cmd') {
1784         runcmd_ordryrun
1785             (access_cfg_ssh, access_gituserhost(),
1786              access_runeinfo("git-create $package").
1787              "set -e; cd ".access_cfg('git-path').";".
1788              " cp -a _template $package.git");
1789     } elsif ($how eq 'true') {
1790         # nothing to do
1791     } else {
1792         badcfg f_ "unknown git-create \`%s'", $how;
1793     }
1794 }
1795
1796 our ($dsc_hash,$lastpush_mergeinput);
1797 our ($dsc_distro, $dsc_hint_tag, $dsc_hint_url);
1798
1799
1800 sub prep_ud () {
1801     dgit_privdir(); # ensures that $dgit_privdir_made is based on $maindir
1802     $playground = fresh_playground 'dgit/unpack';
1803 }
1804
1805 sub mktree_in_ud_here () {
1806     playtree_setup $gitcfgs{local};
1807 }
1808
1809 sub git_write_tree () {
1810     my $tree = cmdoutput @git, qw(write-tree);
1811     $tree =~ m/^\w+$/ or die "$tree ?";
1812     return $tree;
1813 }
1814
1815 sub git_add_write_tree () {
1816     runcmd @git, qw(add -Af .);
1817     return git_write_tree();
1818 }
1819
1820 sub remove_stray_gits ($) {
1821     my ($what) = @_;
1822     my @gitscmd = qw(find -name .git -prune -print0);
1823     debugcmd "|",@gitscmd;
1824     open GITS, "-|", @gitscmd or die $!;
1825     {
1826         local $/="\0";
1827         while (<GITS>) {
1828             chomp or die;
1829             print STDERR f_ "%s: warning: removing from %s: %s\n",
1830                 $us, $what, (messagequote $_);
1831             rmtree $_;
1832         }
1833     }
1834     $!=0; $?=0; close GITS or failedcmd @gitscmd;
1835 }
1836
1837 sub mktree_in_ud_from_only_subdir ($;$) {
1838     my ($what,$raw) = @_;
1839     # changes into the subdir
1840
1841     my (@dirs) = <*/.>;
1842     confess "expected one subdir but found @dirs ?" unless @dirs==1;
1843     $dirs[0] =~ m#^([^/]+)/\.$# or die;
1844     my $dir = $1;
1845     changedir $dir;
1846
1847     remove_stray_gits($what);
1848     mktree_in_ud_here();
1849     if (!$raw) {
1850         my ($format, $fopts) = get_source_format();
1851         if (madformat($format)) {
1852             rmtree '.pc';
1853         }
1854     }
1855
1856     my $tree=git_add_write_tree();
1857     return ($tree,$dir);
1858 }
1859
1860 our @files_csum_info_fields = 
1861     (['Checksums-Sha256','Digest::SHA', 'new(256)', 'sha256sum'],
1862      ['Checksums-Sha1',  'Digest::SHA', 'new(1)',   'sha1sum'],
1863      ['Files',           'Digest::MD5', 'new()',    'md5sum']);
1864
1865 sub dsc_files_info () {
1866     foreach my $csumi (@files_csum_info_fields) {
1867         my ($fname, $module, $method) = @$csumi;
1868         my $field = $dsc->{$fname};
1869         next unless defined $field;
1870         eval "use $module; 1;" or die $@;
1871         my @out;
1872         foreach (split /\n/, $field) {
1873             next unless m/\S/;
1874             m/^(\w+) (\d+) (\S+)$/ or
1875                 fail f_ "could not parse .dsc %s line \`%s'", $fname, $_;
1876             my $digester = eval "$module"."->$method;" or die $@;
1877             push @out, {
1878                 Hash => $1,
1879                 Bytes => $2,
1880                 Filename => $3,
1881                 Digester => $digester,
1882             };
1883         }
1884         return @out;
1885     }
1886     fail f_ "missing any supported Checksums-* or Files field in %s",
1887             $dsc->get_option('name');
1888 }
1889
1890 sub dsc_files () {
1891     map { $_->{Filename} } dsc_files_info();
1892 }
1893
1894 sub files_compare_inputs (@) {
1895     my $inputs = \@_;
1896     my %record;
1897     my %fchecked;
1898
1899     my $showinputs = sub {
1900         return join "; ", map { $_->get_option('name') } @$inputs;
1901     };
1902
1903     foreach my $in (@$inputs) {
1904         my $expected_files;
1905         my $in_name = $in->get_option('name');
1906
1907         printdebug "files_compare_inputs $in_name\n";
1908
1909         foreach my $csumi (@files_csum_info_fields) {
1910             my ($fname) = @$csumi;
1911             printdebug "files_compare_inputs $in_name $fname\n";
1912
1913             my $field = $in->{$fname};
1914             next unless defined $field;
1915
1916             my @files;
1917             foreach (split /\n/, $field) {
1918                 next unless m/\S/;
1919
1920                 my ($info, $f) = m/^(\w+ \d+) (?:\S+ \S+ )?(\S+)$/ or
1921                     fail "could not parse $in_name $fname line \`$_'";
1922
1923                 printdebug "files_compare_inputs $in_name $fname $f\n";
1924
1925                 push @files, $f;
1926
1927                 my $re = \ $record{$f}{$fname};
1928                 if (defined $$re) {
1929                     $fchecked{$f}{$in_name} = 1;
1930                     $$re eq $info or
1931                         fail f_
1932               "hash or size of %s varies in %s fields (between: %s)",
1933                                  $f, $fname, $showinputs->();
1934                 } else {
1935                     $$re = $info;
1936                 }
1937             }
1938             @files = sort @files;
1939             $expected_files //= \@files;
1940             "@$expected_files" eq "@files" or
1941                 fail f_ "file list in %s varies between hash fields!",
1942                         $in_name;
1943         }
1944         $expected_files or
1945             fail f_ "%s has no files list field(s)", $in_name;
1946     }
1947     printdebug "files_compare_inputs ".Dumper(\%fchecked, \%record)
1948         if $debuglevel>=2;
1949
1950     grep { keys %$_ == @$inputs-1 } values %fchecked
1951         or fail f_ "no file appears in all file lists (looked in: %s)",
1952                    $showinputs->();
1953 }
1954
1955 sub is_orig_file_in_dsc ($$) {
1956     my ($f, $dsc_files_info) = @_;
1957     return 0 if @$dsc_files_info <= 1;
1958     # One file means no origs, and the filename doesn't have a "what
1959     # part of dsc" component.  (Consider versions ending `.orig'.)
1960     return 0 unless $f =~ m/\.$orig_f_tail_re$/o;
1961     return 1;
1962 }
1963
1964 # This function determines whether a .changes file is source-only from
1965 # the point of view of dak.  Thus, it permits *_source.buildinfo
1966 # files.
1967 #
1968 # It does not, however, permit any other buildinfo files.  After a
1969 # source-only upload, the buildds will try to upload files like
1970 # foo_1.2.3_amd64.buildinfo.  If the package maintainer included files
1971 # named like this in their (otherwise) source-only upload, the uploads
1972 # of the buildd can be rejected by dak.  Fixing the resultant
1973 # situation can require manual intervention.  So we block such
1974 # .buildinfo files when the user tells us to perform a source-only
1975 # upload (such as when using the push-source subcommand with the -C
1976 # option, which calls this function).
1977 #
1978 # Note, though, that when dgit is told to prepare a source-only
1979 # upload, such as when subcommands like build-source and push-source
1980 # without -C are used, dgit has a more restrictive notion of
1981 # source-only .changes than dak: such uploads will never include
1982 # *_source.buildinfo files.  This is because there is no use for such
1983 # files when using a tool like dgit to produce the source package, as
1984 # dgit ensures the source is identical to git HEAD.
1985 sub test_source_only_changes ($) {
1986     my ($changes) = @_;
1987     foreach my $l (split /\n/, getfield $changes, 'Files') {
1988         $l =~ m/\S+$/ or next;
1989         # \.tar\.[a-z0-9]+ covers orig.tar and the tarballs in native packages
1990         unless ($& =~ m/(?:\.dsc|\.diff\.gz|\.tar\.[a-z0-9]+|_source\.buildinfo)$/) {
1991             print f_ "purportedly source-only changes polluted by %s\n", $&;
1992             return 0;
1993         }
1994     }
1995     return 1;
1996 }
1997
1998 sub changes_update_origs_from_dsc ($$$$) {
1999     my ($dsc, $changes, $upstreamvsn, $changesfile) = @_;
2000     my %changes_f;
2001     printdebug "checking origs needed ($upstreamvsn)...\n";
2002     $_ = getfield $changes, 'Files';
2003     m/^\w+ \d+ (\S+ \S+) \S+$/m or
2004         fail __ "cannot find section/priority from .changes Files field";
2005     my $placementinfo = $1;
2006     my %changed;
2007     printdebug "checking origs needed placement '$placementinfo'...\n";
2008     foreach my $l (split /\n/, getfield $dsc, 'Files') {
2009         $l =~ m/\S+$/ or next;
2010         my $file = $&;
2011         printdebug "origs $file | $l\n";
2012         next unless is_orig_file_of_vsn $file, $upstreamvsn;
2013         printdebug "origs $file is_orig\n";
2014         my $have = archive_query('file_in_archive', $file);
2015         if (!defined $have) {
2016             print STDERR __ <<END;
2017 archive does not support .orig check; hope you used --ch:--sa/-sd if needed
2018 END
2019             return;
2020         }
2021         my $found_same = 0;
2022         my @found_differ;
2023         printdebug "origs $file \$#\$have=$#$have\n";
2024         foreach my $h (@$have) {
2025             my $same = 0;
2026             my @differ;
2027             foreach my $csumi (@files_csum_info_fields) {
2028                 my ($fname, $module, $method, $archivefield) = @$csumi;
2029                 next unless defined $h->{$archivefield};
2030                 $_ = $dsc->{$fname};
2031                 next unless defined;
2032                 m/^(\w+) .* \Q$file\E$/m or
2033                     fail f_ ".dsc %s missing entry for %s", $fname, $file;
2034                 if ($h->{$archivefield} eq $1) {
2035                     $same++;
2036                 } else {
2037                     push @differ, f_
2038                         "%s: %s (archive) != %s (local .dsc)",
2039                         $archivefield, $h->{$archivefield}, $1;
2040                 }
2041             }
2042             confess "$file ".Dumper($h)." ?!" if $same && @differ;
2043             $found_same++
2044                 if $same;
2045             push @found_differ,
2046                 f_ "archive %s: %s", $h->{filename}, join "; ", @differ
2047                 if @differ;
2048         }
2049         printdebug "origs $file f.same=$found_same".
2050             " #f._differ=$#found_differ\n";
2051         if (@found_differ && !$found_same) {
2052             fail join "\n",
2053                 (f_ "archive contains %s with different checksum", $file),
2054                 @found_differ;
2055         }
2056         # Now we edit the changes file to add or remove it
2057         foreach my $csumi (@files_csum_info_fields) {
2058             my ($fname, $module, $method, $archivefield) = @$csumi;
2059             next unless defined $changes->{$fname};
2060             if ($found_same) {
2061                 # in archive, delete from .changes if it's there
2062                 $changed{$file} = "removed" if
2063                     $changes->{$fname} =~ s/\n.* \Q$file\E$(?:)$//m;
2064             } elsif ($changes->{$fname} =~ m/^.* \Q$file\E$(?:)$/m) {
2065                 # not in archive, but it's here in the .changes
2066             } else {
2067                 my $dsc_data = getfield $dsc, $fname;
2068                 $dsc_data =~ m/^(.* \Q$file\E$)$/m or die "$dsc_data $file ?";
2069                 my $extra = $1;
2070                 $extra =~ s/ \d+ /$&$placementinfo /
2071                     or confess "$fname $extra >$dsc_data< ?"
2072                     if $fname eq 'Files';
2073                 $changes->{$fname} .= "\n". $extra;
2074                 $changed{$file} = "added";
2075             }
2076         }
2077     }
2078     if (%changed) {
2079         foreach my $file (keys %changed) {
2080             progress f_
2081                 "edited .changes for archive .orig contents: %s %s",
2082                 $changed{$file}, $file;
2083         }
2084         my $chtmp = "$changesfile.tmp";
2085         $changes->save($chtmp);
2086         if (act_local()) {
2087             rename $chtmp,$changesfile or die "$changesfile $!";
2088         } else {
2089             progress f_ "[new .changes left in %s]", $changesfile;
2090         }
2091     } else {
2092         progress f_ "%s already has appropriate .orig(s) (if any)",
2093                     $changesfile;
2094     }
2095 }
2096
2097 sub make_commit ($) {
2098     my ($file) = @_;
2099     return cmdoutput @git, qw(hash-object -w -t commit), $file;
2100 }
2101
2102 sub clogp_authline ($) {
2103     my ($clogp) = @_;
2104     my $author = getfield $clogp, 'Maintainer';
2105     if ($author =~ m/^[^"\@]+\,/) {
2106         # single entry Maintainer field with unquoted comma
2107         $author = ($& =~ y/,//rd).$'; # strip the comma
2108     }
2109     # git wants a single author; any remaining commas in $author
2110     # are by now preceded by @ (or ").  It seems safer to punt on
2111     # "..." for now rather than attempting to dequote or something.
2112     $author =~ s#,.*##ms unless $author =~ m/"/;
2113     my $date = cmdoutput qw(date), '+%s %z', qw(-d), getfield($clogp,'Date');
2114     my $authline = "$author $date";
2115     $authline =~ m/$git_authline_re/o or
2116         fail f_ "unexpected commit author line format \`%s'".
2117                 " (was generated from changelog Maintainer field)",
2118                 $authline;
2119     return ($1,$2,$3) if wantarray;
2120     return $authline;
2121 }
2122
2123 sub vendor_patches_distro ($$) {
2124     my ($checkdistro, $what) = @_;
2125     return unless defined $checkdistro;
2126
2127     my $series = "debian/patches/\L$checkdistro\E.series";
2128     printdebug "checking for vendor-specific $series ($what)\n";
2129
2130     if (!open SERIES, "<", $series) {
2131         confess "$series $!" unless $!==ENOENT;
2132         return;
2133     }
2134     while (<SERIES>) {
2135         next unless m/\S/;
2136         next if m/^\s+\#/;
2137
2138         print STDERR __ <<END;
2139
2140 Unfortunately, this source package uses a feature of dpkg-source where
2141 the same source package unpacks to different source code on different
2142 distros.  dgit cannot safely operate on such packages on affected
2143 distros, because the meaning of source packages is not stable.
2144
2145 Please ask the distro/maintainer to remove the distro-specific series
2146 files and use a different technique (if necessary, uploading actually
2147 different packages, if different distros are supposed to have
2148 different code).
2149
2150 END
2151         fail f_ "Found active distro-specific series file for".
2152                 " %s (%s): %s, cannot continue",
2153                 $checkdistro, $what, $series;
2154     }
2155     die "$series $!" if SERIES->error;
2156     close SERIES;
2157 }
2158
2159 sub check_for_vendor_patches () {
2160     # This dpkg-source feature doesn't seem to be documented anywhere!
2161     # But it can be found in the changelog (reformatted):
2162
2163     #   commit  4fa01b70df1dc4458daee306cfa1f987b69da58c
2164     #   Author: Raphael Hertzog <hertzog@debian.org>
2165     #   Date: Sun  Oct  3  09:36:48  2010 +0200
2166
2167     #   dpkg-source: correctly create .pc/.quilt_series with alternate
2168     #   series files
2169     #   
2170     #   If you have debian/patches/ubuntu.series and you were
2171     #   unpacking the source package on ubuntu, quilt was still
2172     #   directed to debian/patches/series instead of
2173     #   debian/patches/ubuntu.series.
2174     #   
2175     #   debian/changelog                        |    3 +++
2176     #   scripts/Dpkg/Source/Package/V3/quilt.pm |    4 +++-
2177     #   2 files changed, 6 insertions(+), 1 deletion(-)
2178
2179     use Dpkg::Vendor;
2180     vendor_patches_distro($ENV{DEB_VENDOR}, "DEB_VENDOR");
2181     vendor_patches_distro(Dpkg::Vendor::get_current_vendor(),
2182                           __ "Dpkg::Vendor \`current vendor'");
2183     vendor_patches_distro(access_basedistro(),
2184                           __ "(base) distro being accessed");
2185     vendor_patches_distro(access_nomdistro(),
2186                           __ "(nominal) distro being accessed");
2187 }
2188
2189 sub generate_commits_from_dsc () {
2190     # See big comment in fetch_from_archive, below.
2191     # See also README.dsc-import.
2192     prep_ud();
2193     changedir $playground;
2194
2195     my @dfi = dsc_files_info();
2196     foreach my $fi (@dfi) {
2197         my $f = $fi->{Filename};
2198         die "$f ?" if $f =~ m#/|^\.|\.dsc$|\.tmp$#;
2199         my $upper_f = (bpd_abs()."/$f");
2200
2201         printdebug "considering reusing $f: ";
2202
2203         if (link_ltarget "$upper_f,fetch", $f) {
2204             printdebug "linked (using ...,fetch).\n";
2205         } elsif ((printdebug "($!) "),
2206                  $! != ENOENT) {
2207             fail f_ "accessing %s: %s", "$buildproductsdir/$f,fetch", $!;
2208         } elsif (link_ltarget $upper_f, $f) {
2209             printdebug "linked.\n";
2210         } elsif ((printdebug "($!) "),
2211                  $! != ENOENT) {
2212             fail f_ "accessing %s: %s", "$buildproductsdir/$f", $!;
2213         } else {
2214             printdebug "absent.\n";
2215         }
2216
2217         my $refetched;
2218         complete_file_from_dsc('.', $fi, \$refetched)
2219             or next;
2220
2221         printdebug "considering saving $f: ";
2222
2223         if (link $f, $upper_f) {
2224             printdebug "linked.\n";
2225         } elsif ((printdebug "($!) "),
2226                  $! != EEXIST) {
2227             fail f_ "saving %s: %s", "$buildproductsdir/$f", $!;
2228         } elsif (!$refetched) {
2229             printdebug "no need.\n";
2230         } elsif (link $f, "$upper_f,fetch") {
2231             printdebug "linked (using ...,fetch).\n";
2232         } elsif ((printdebug "($!) "),
2233                  $! != EEXIST) {
2234             fail f_ "saving %s: %s", "$buildproductsdir/$f,fetch", $!;
2235         } else {
2236             printdebug "cannot.\n";
2237         }
2238     }
2239
2240     # We unpack and record the orig tarballs first, so that we only
2241     # need disk space for one private copy of the unpacked source.
2242     # But we can't make them into commits until we have the metadata
2243     # from the debian/changelog, so we record the tree objects now and
2244     # make them into commits later.
2245     my @tartrees;
2246     my $upstreamv = upstreamversion $dsc->{version};
2247     my $orig_f_base = srcfn $upstreamv, '';
2248
2249     foreach my $fi (@dfi) {
2250         # We actually import, and record as a commit, every tarball
2251         # (unless there is only one file, in which case there seems
2252         # little point.
2253
2254         my $f = $fi->{Filename};
2255         printdebug "import considering $f ";
2256         (printdebug "only one dfi\n"), next if @dfi == 1;
2257         (printdebug "not tar\n"), next unless $f =~ m/\.tar(\.\w+)?$/;
2258         (printdebug "signature\n"), next if $f =~ m/$orig_f_sig_re$/o;
2259         my $compr_ext = $1;
2260
2261         my ($orig_f_part) =
2262             $f =~ m/^\Q$orig_f_base\E\.([^._]+)?\.tar(?:\.\w+)?$/;
2263
2264         printdebug "Y ", (join ' ', map { $_//"(none)" }
2265                           $compr_ext, $orig_f_part
2266                          ), "\n";
2267
2268         my $input = new IO::File $f, '<' or die "$f $!";
2269         my $compr_pid;
2270         my @compr_cmd;
2271
2272         if (defined $compr_ext) {
2273             my $cname =
2274                 Dpkg::Compression::compression_guess_from_filename $f;
2275             fail "Dpkg::Compression cannot handle file $f in source package"
2276                 if defined $compr_ext && !defined $cname;
2277             my $compr_proc =
2278                 new Dpkg::Compression::Process compression => $cname;
2279             @compr_cmd = $compr_proc->get_uncompress_cmdline();
2280             my $compr_fh = new IO::Handle;
2281             my $compr_pid = open $compr_fh, "-|" // die $!;
2282             if (!$compr_pid) {
2283                 open STDIN, "<&", $input or die $!;
2284                 exec @compr_cmd;
2285                 die "dgit (child): exec $compr_cmd[0]: $!\n";
2286             }
2287             $input = $compr_fh;
2288         }
2289
2290         rmtree "_unpack-tar";
2291         mkdir "_unpack-tar" or die $!;
2292         my @tarcmd = qw(tar -x -f -
2293                         --no-same-owner --no-same-permissions
2294                         --no-acls --no-xattrs --no-selinux);
2295         my $tar_pid = fork // die $!;
2296         if (!$tar_pid) {
2297             chdir "_unpack-tar" or die $!;
2298             open STDIN, "<&", $input or die $!;
2299             exec @tarcmd;
2300             die f_ "dgit (child): exec %s: %s", $tarcmd[0], $!;
2301         }
2302         $!=0; (waitpid $tar_pid, 0) == $tar_pid or die $!;
2303         !$? or failedcmd @tarcmd;
2304
2305         close $input or
2306             (@compr_cmd ? ($?==SIGPIPE || failedcmd @compr_cmd)
2307              : die $!);
2308         # finally, we have the results in "tarball", but maybe
2309         # with the wrong permissions
2310
2311         runcmd qw(chmod -R +rwX _unpack-tar);
2312         changedir "_unpack-tar";
2313         remove_stray_gits($f);
2314         mktree_in_ud_here();
2315         
2316         my ($tree) = git_add_write_tree();
2317         my $tentries = cmdoutput @git, qw(ls-tree -z), $tree;
2318         if ($tentries =~ m/^\d+ tree (\w+)\t[^\000]+\000$/s) {
2319             $tree = $1;
2320             printdebug "one subtree $1\n";
2321         } else {
2322             printdebug "multiple subtrees\n";
2323         }
2324         changedir "..";
2325         rmtree "_unpack-tar";
2326
2327         my $ent = [ $f, $tree ];
2328         push @tartrees, {
2329             Orig => !!$orig_f_part,
2330             Sort => (!$orig_f_part         ? 2 :
2331                      $orig_f_part =~ m/-/g ? 1 :
2332                                              0),
2333             F => $f,
2334             Tree => $tree,
2335         };
2336     }
2337
2338     @tartrees = sort {
2339         # put any without "_" first (spec is not clear whether files
2340         # are always in the usual order).  Tarballs without "_" are
2341         # the main orig or the debian tarball.
2342         $a->{Sort} <=> $b->{Sort} or
2343         $a->{F}    cmp $b->{F}
2344     } @tartrees;
2345
2346     my $any_orig = grep { $_->{Orig} } @tartrees;
2347
2348     my $dscfn = "$package.dsc";
2349
2350     my $treeimporthow = 'package';
2351
2352     open D, ">", $dscfn or die "$dscfn: $!";
2353     print D $dscdata or die "$dscfn: $!";
2354     close D or die "$dscfn: $!";
2355     my @cmd = qw(dpkg-source);
2356     push @cmd, '--no-check' if $dsc_checked;
2357     if (madformat $dsc->{format}) {
2358         push @cmd, '--skip-patches';
2359         $treeimporthow = 'unpatched';
2360     }
2361     push @cmd, qw(-x --), $dscfn;
2362     runcmd @cmd;
2363
2364     my ($tree,$dir) = mktree_in_ud_from_only_subdir(__ "source package");
2365     if (madformat $dsc->{format}) { 
2366         check_for_vendor_patches();
2367     }
2368
2369     my $dappliedtree;
2370     if (madformat $dsc->{format}) {
2371         my @pcmd = qw(dpkg-source --before-build .);
2372         runcmd shell_cmd 'exec >/dev/null', @pcmd;
2373         rmtree '.pc';
2374         $dappliedtree = git_add_write_tree();
2375     }
2376
2377     my @clogcmd = qw(dpkg-parsechangelog --format rfc822 --all);
2378     my $clogp;
2379     my $r1clogp;
2380
2381     printdebug "import clog search...\n";
2382     parsechangelog_loop \@clogcmd, (__ "package changelog"), sub {
2383         my ($thisstanza, $desc) = @_;
2384         no warnings qw(exiting);
2385
2386         $clogp //= $thisstanza;
2387
2388         printdebug "import clog $thisstanza->{version} $desc...\n";
2389
2390         last if !$any_orig; # we don't need $r1clogp
2391
2392         # We look for the first (most recent) changelog entry whose
2393         # version number is lower than the upstream version of this
2394         # package.  Then the last (least recent) previous changelog
2395         # entry is treated as the one which introduced this upstream
2396         # version and used for the synthetic commits for the upstream
2397         # tarballs.
2398
2399         # One might think that a more sophisticated algorithm would be
2400         # necessary.  But: we do not want to scan the whole changelog
2401         # file.  Stopping when we see an earlier version, which
2402         # necessarily then is an earlier upstream version, is the only
2403         # realistic way to do that.  Then, either the earliest
2404         # changelog entry we have seen so far is indeed the earliest
2405         # upload of this upstream version; or there are only changelog
2406         # entries relating to later upstream versions (which is not
2407         # possible unless the changelog and .dsc disagree about the
2408         # version).  Then it remains to choose between the physically
2409         # last entry in the file, and the one with the lowest version
2410         # number.  If these are not the same, we guess that the
2411         # versions were created in a non-monotonic order rather than
2412         # that the changelog entries have been misordered.
2413
2414         printdebug "import clog $thisstanza->{version} vs $upstreamv...\n";
2415
2416         last if version_compare($thisstanza->{version}, $upstreamv) < 0;
2417         $r1clogp = $thisstanza;
2418
2419         printdebug "import clog $r1clogp->{version} becomes r1\n";
2420     };
2421
2422     $clogp or fail __ "package changelog has no entries!";
2423
2424     my $authline = clogp_authline $clogp;
2425     my $changes = getfield $clogp, 'Changes';
2426     $changes =~ s/^\n//; # Changes: \n
2427     my $cversion = getfield $clogp, 'Version';
2428
2429     if (@tartrees) {
2430         $r1clogp //= $clogp; # maybe there's only one entry;
2431         my $r1authline = clogp_authline $r1clogp;
2432         # Strictly, r1authline might now be wrong if it's going to be
2433         # unused because !$any_orig.  Whatever.
2434
2435         printdebug "import tartrees authline   $authline\n";
2436         printdebug "import tartrees r1authline $r1authline\n";
2437
2438         foreach my $tt (@tartrees) {
2439             printdebug "import tartree $tt->{F} $tt->{Tree}\n";
2440
2441             my $mbody = f_ "Import %s", $tt->{F};
2442             $tt->{Commit} = make_commit_text($tt->{Orig} ? <<END_O : <<END_T);
2443 tree $tt->{Tree}
2444 author $r1authline
2445 committer $r1authline
2446
2447 $mbody
2448
2449 [dgit import orig $tt->{F}]
2450 END_O
2451 tree $tt->{Tree}
2452 author $authline
2453 committer $authline
2454
2455 $mbody
2456
2457 [dgit import tarball $package $cversion $tt->{F}]
2458 END_T
2459         }
2460     }
2461
2462     printdebug "import main commit\n";
2463
2464     open C, ">../commit.tmp" or die $!;
2465     print C <<END or die $!;
2466 tree $tree
2467 END
2468     print C <<END or die $! foreach @tartrees;
2469 parent $_->{Commit}
2470 END
2471     print C <<END or die $!;
2472 author $authline
2473 committer $authline
2474
2475 $changes
2476
2477 [dgit import $treeimporthow $package $cversion]
2478 END
2479
2480     close C or die $!;
2481     my $rawimport_hash = make_commit qw(../commit.tmp);
2482
2483     if (madformat $dsc->{format}) {
2484         printdebug "import apply patches...\n";
2485
2486         # regularise the state of the working tree so that
2487         # the checkout of $rawimport_hash works nicely.
2488         my $dappliedcommit = make_commit_text(<<END);
2489 tree $dappliedtree
2490 author $authline
2491 committer $authline
2492
2493 [dgit dummy commit]
2494 END
2495         runcmd @git, qw(checkout -q -b dapplied), $dappliedcommit;
2496
2497         runcmd @git, qw(checkout -q -b unpa), $rawimport_hash;
2498
2499         # We need the answers to be reproducible
2500         my @authline = clogp_authline($clogp);
2501         local $ENV{GIT_COMMITTER_NAME} =  $authline[0];
2502         local $ENV{GIT_COMMITTER_EMAIL} = $authline[1];
2503         local $ENV{GIT_COMMITTER_DATE} =  $authline[2];
2504         local $ENV{GIT_AUTHOR_NAME} =  $authline[0];
2505         local $ENV{GIT_AUTHOR_EMAIL} = $authline[1];
2506         local $ENV{GIT_AUTHOR_DATE} =  $authline[2];
2507
2508         my $path = $ENV{PATH} or die;
2509
2510         # we use ../../gbp-pq-output, which (given that we are in
2511         # $playground/PLAYTREE, and $playground is .git/dgit/unpack,
2512         # is .git/dgit.
2513
2514         foreach my $use_absurd (qw(0 1)) {
2515             runcmd @git, qw(checkout -q unpa);
2516             runcmd @git, qw(update-ref -d refs/heads/patch-queue/unpa);
2517             local $ENV{PATH} = $path;
2518             if ($use_absurd) {
2519                 chomp $@;
2520                 progress "warning: $@";
2521                 $path = "$absurdity:$path";
2522                 progress f_ "%s: trying slow absurd-git-apply...", $us;
2523                 rename "../../gbp-pq-output","../../gbp-pq-output.0"
2524                     or $!==ENOENT
2525                     or die $!;
2526             }
2527             eval {
2528                 die "forbid absurd git-apply\n" if $use_absurd
2529                     && forceing [qw(import-gitapply-no-absurd)];
2530                 die "only absurd git-apply!\n" if !$use_absurd
2531                     && forceing [qw(import-gitapply-absurd)];
2532
2533                 local $ENV{DGIT_ABSURD_DEBUG} = $debuglevel if $use_absurd;
2534                 local $ENV{PATH} = $path                    if $use_absurd;
2535
2536                 my @showcmd = (gbp_pq, qw(import));
2537                 my @realcmd = shell_cmd
2538                     'exec >/dev/null 2>>../../gbp-pq-output', @showcmd;
2539                 debugcmd "+",@realcmd;
2540                 if (system @realcmd) {
2541                     die f_ "%s failed: %s\n",
2542                         +(shellquote @showcmd),
2543                         failedcmd_waitstatus();
2544                 }
2545
2546                 my $gapplied = git_rev_parse('HEAD');
2547                 my $gappliedtree = cmdoutput @git, qw(rev-parse HEAD:);
2548                 $gappliedtree eq $dappliedtree or
2549                     fail f_ <<END, $gapplied, $gappliedtree, $dappliedtree;
2550 gbp-pq import and dpkg-source disagree!
2551  gbp-pq import gave commit %s
2552  gbp-pq import gave tree %s
2553  dpkg-source --before-build gave tree %s
2554 END
2555                 $rawimport_hash = $gapplied;
2556             };
2557             last unless $@;
2558         }
2559         if ($@) {
2560             { local $@; eval { runcmd qw(cat ../../gbp-pq-output); }; }
2561             die $@;
2562         }
2563     }
2564
2565     progress f_ "synthesised git commit from .dsc %s", $cversion;
2566
2567     my $rawimport_mergeinput = {
2568         Commit => $rawimport_hash,
2569         Info => __ "Import of source package",
2570     };
2571     my @output = ($rawimport_mergeinput);
2572
2573     if ($lastpush_mergeinput) {
2574         my $oldclogp = mergeinfo_getclogp($lastpush_mergeinput);
2575         my $oversion = getfield $oldclogp, 'Version';
2576         my $vcmp =
2577             version_compare($oversion, $cversion);
2578         if ($vcmp < 0) {
2579             @output = ($rawimport_mergeinput, $lastpush_mergeinput,
2580                 { ReverseParents => 1,
2581                   Message => (f_ <<END, $package, $cversion, $csuite) });
2582 Record %s (%s) in archive suite %s
2583 END
2584         } elsif ($vcmp > 0) {
2585             print STDERR f_ <<END, $cversion, $oversion,
2586
2587 Version actually in archive:   %s (older)
2588 Last version pushed with dgit: %s (newer or same)
2589 %s
2590 END
2591                 __ $later_warning_msg or die $!;
2592             @output = $lastpush_mergeinput;
2593         } else {
2594             # Same version.  Use what's in the server git branch,
2595             # discarding our own import.  (This could happen if the
2596             # server automatically imports all packages into git.)
2597             @output = $lastpush_mergeinput;
2598         }
2599     }
2600     changedir $maindir;
2601     rmtree $playground;
2602     return @output;
2603 }
2604
2605 sub complete_file_from_dsc ($$;$) {
2606     our ($dstdir, $fi, $refetched) = @_;
2607     # Ensures that we have, in $dstdir, the file $fi, with the correct
2608     # contents.  (Downloading it from alongside $dscurl if necessary.)
2609     # If $refetched is defined, can overwrite "$dstdir/$fi->{Filename}"
2610     # and will set $$refetched=1 if it did so (or tried to).
2611
2612     my $f = $fi->{Filename};
2613     my $tf = "$dstdir/$f";
2614     my $downloaded = 0;
2615
2616     my $got;
2617     my $checkhash = sub {
2618         open F, "<", "$tf" or die "$tf: $!";
2619         $fi->{Digester}->reset();
2620         $fi->{Digester}->addfile(*F);
2621         F->error and die $!;
2622         $got = $fi->{Digester}->hexdigest();
2623         return $got eq $fi->{Hash};
2624     };
2625
2626     if (stat_exists $tf) {
2627         if ($checkhash->()) {
2628             progress f_ "using existing %s", $f;
2629             return 1;
2630         }
2631         if (!$refetched) {
2632             fail f_ "file %s has hash %s but .dsc demands hash %s".
2633                     " (perhaps you should delete this file?)",
2634                     $f, $got, $fi->{Hash};
2635         }
2636         progress f_ "need to fetch correct version of %s", $f;
2637         unlink $tf or die "$tf $!";
2638         $$refetched = 1;
2639     } else {
2640         printdebug "$tf does not exist, need to fetch\n";
2641     }
2642
2643     my $furl = $dscurl;
2644     $furl =~ s{/[^/]+$}{};
2645     $furl .= "/$f";
2646     die "$f ?" unless $f =~ m/^\Q${package}\E_/;
2647     die "$f ?" if $f =~ m#/#;
2648     runcmd_ordryrun_local @curl,qw(-f -o),$tf,'--',"$furl";
2649     return 0 if !act_local();
2650
2651     $checkhash->() or
2652         fail f_ "file %s has hash %s but .dsc demands hash %s".
2653                 " (got wrong file from archive!)",
2654                 $f, $got, $fi->{Hash};
2655
2656     return 1;
2657 }
2658
2659 sub ensure_we_have_orig () {
2660     my @dfi = dsc_files_info();
2661     foreach my $fi (@dfi) {
2662         my $f = $fi->{Filename};
2663         next unless is_orig_file_in_dsc($f, \@dfi);
2664         complete_file_from_dsc($buildproductsdir, $fi)
2665             or next;
2666     }
2667 }
2668
2669 #---------- git fetch ----------
2670
2671 sub lrfetchrefs () { return "refs/dgit-fetch/".access_basedistro(); }
2672 sub lrfetchref () { return lrfetchrefs.'/'.server_branch($csuite); }
2673
2674 # We fetch some parts of lrfetchrefs/*.  Ideally we delete these
2675 # locally fetched refs because they have unhelpful names and clutter
2676 # up gitk etc.  So we track whether we have "used up" head ref (ie,
2677 # whether we have made another local ref which refers to this object).
2678 #
2679 # (If we deleted them unconditionally, then we might end up
2680 # re-fetching the same git objects each time dgit fetch was run.)
2681 #
2682 # So, each use of lrfetchrefs needs to be accompanied by arrangements
2683 # in git_fetch_us to fetch the refs in question, and possibly a call
2684 # to lrfetchref_used.
2685
2686 our (%lrfetchrefs_f, %lrfetchrefs_d);
2687 # $lrfetchrefs_X{lrfetchrefs."/heads/whatever"} = $objid
2688
2689 sub lrfetchref_used ($) {
2690     my ($fullrefname) = @_;
2691     my $objid = $lrfetchrefs_f{$fullrefname};
2692     $lrfetchrefs_d{$fullrefname} = $objid if defined $objid;
2693 }
2694
2695 sub git_lrfetch_sane {
2696     my ($url, $supplementary, @specs) = @_;
2697     # Make a 'refs/'.lrfetchrefs.'/*' be just like on server,
2698     # at least as regards @specs.  Also leave the results in
2699     # %lrfetchrefs_f, and arrange for lrfetchref_used to be
2700     # able to clean these up.
2701     #
2702     # With $supplementary==1, @specs must not contain wildcards
2703     # and we add to our previous fetches (non-atomically).
2704
2705     # This is rather miserable:
2706     # When git fetch --prune is passed a fetchspec ending with a *,
2707     # it does a plausible thing.  If there is no * then:
2708     # - it matches subpaths too, even if the supplied refspec
2709     #   starts refs, and behaves completely madly if the source
2710     #   has refs/refs/something.  (See, for example, Debian #NNNN.)
2711     # - if there is no matching remote ref, it bombs out the whole
2712     #   fetch.
2713     # We want to fetch a fixed ref, and we don't know in advance
2714     # if it exists, so this is not suitable.
2715     #
2716     # Our workaround is to use git ls-remote.  git ls-remote has its
2717     # own qairks.  Notably, it has the absurd multi-tail-matching
2718     # behaviour: git ls-remote R refs/foo can report refs/foo AND
2719     # refs/refs/foo etc.
2720     #
2721     # Also, we want an idempotent snapshot, but we have to make two
2722     # calls to the remote: one to git ls-remote and to git fetch.  The
2723     # solution is use git ls-remote to obtain a target state, and
2724     # git fetch to try to generate it.  If we don't manage to generate
2725     # the target state, we try again.
2726
2727     printdebug "git_lrfetch_sane suppl=$supplementary specs @specs\n";
2728
2729     my $specre = join '|', map {
2730         my $x = $_;
2731         $x =~ s/\W/\\$&/g;
2732         my $wildcard = $x =~ s/\\\*$/.*/;
2733         die if $wildcard && $supplementary;
2734         "(?:refs/$x)";
2735     } @specs;
2736     printdebug "git_lrfetch_sane specre=$specre\n";
2737     my $wanted_rref = sub {
2738         local ($_) = @_;
2739         return m/^(?:$specre)$/;
2740     };
2741
2742     my $fetch_iteration = 0;
2743     FETCH_ITERATION:
2744     for (;;) {
2745         printdebug "git_lrfetch_sane iteration $fetch_iteration\n";
2746         if (++$fetch_iteration > 10) {
2747             fail __ "too many iterations trying to get sane fetch!";
2748         }
2749
2750         my @look = map { "refs/$_" } @specs;
2751         my @lcmd = (@git, qw(ls-remote -q --refs), $url, @look);
2752         debugcmd "|",@lcmd;
2753
2754         my %wantr;
2755         open GITLS, "-|", @lcmd or die $!;
2756         while (<GITLS>) {
2757             printdebug "=> ", $_;
2758             m/^(\w+)\s+(\S+)\n/ or die "ls-remote $_ ?";
2759             my ($objid,$rrefname) = ($1,$2);
2760             if (!$wanted_rref->($rrefname)) {
2761                 print STDERR f_ <<END, "@look", $rrefname;
2762 warning: git ls-remote %s reported %s; this is silly, ignoring it.
2763 END
2764                 next;
2765             }
2766             $wantr{$rrefname} = $objid;
2767         }
2768         $!=0; $?=0;
2769         close GITLS or failedcmd @lcmd;
2770
2771         # OK, now %want is exactly what we want for refs in @specs
2772         my @fspecs = map {
2773             !m/\*$/ && !exists $wantr{"refs/$_"} ? () :
2774             "+refs/$_:".lrfetchrefs."/$_";
2775         } @specs;
2776
2777         printdebug "git_lrfetch_sane fspecs @fspecs\n";
2778
2779         my @fcmd = (@git, qw(fetch -p -n -q), $url, @fspecs);
2780         runcmd_ordryrun_local @fcmd if @fspecs;
2781
2782         if (!$supplementary) {
2783             %lrfetchrefs_f = ();
2784         }
2785         my %objgot;
2786
2787         git_for_each_ref(lrfetchrefs, sub {
2788             my ($objid,$objtype,$lrefname,$reftail) = @_;
2789             $lrfetchrefs_f{$lrefname} = $objid;
2790             $objgot{$objid} = 1;
2791         });
2792
2793         if ($supplementary) {
2794             last;
2795         }
2796
2797         foreach my $lrefname (sort keys %lrfetchrefs_f) {
2798             my $rrefname = 'refs'.substr($lrefname, length lrfetchrefs);
2799             if (!exists $wantr{$rrefname}) {
2800                 if ($wanted_rref->($rrefname)) {
2801                     printdebug <<END;
2802 git-fetch @fspecs created $lrefname which git ls-remote @look didn't list.
2803 END
2804                 } else {
2805                     print STDERR f_ <<END, "@fspecs", $lrefname
2806 warning: git fetch %s created %s; this is silly, deleting it.
2807 END
2808                 }
2809                 runcmd_ordryrun_local @git, qw(update-ref -d), $lrefname;
2810                 delete $lrfetchrefs_f{$lrefname};
2811                 next;
2812             }
2813         }
2814         foreach my $rrefname (sort keys %wantr) {
2815             my $lrefname = lrfetchrefs.substr($rrefname, 4);
2816             my $got = $lrfetchrefs_f{$lrefname} // '<none>';
2817             my $want = $wantr{$rrefname};
2818             next if $got eq $want;
2819             if (!defined $objgot{$want}) {
2820                 fail __ <<END unless act_local();
2821 --dry-run specified but we actually wanted the results of git fetch,
2822 so this is not going to work.  Try running dgit fetch first,
2823 or using --damp-run instead of --dry-run.
2824 END
2825                 print STDERR f_ <<END, $lrefname, $want;
2826 warning: git ls-remote suggests we want %s
2827 warning:  and it should refer to %s
2828 warning:  but git fetch didn't fetch that object to any relevant ref.
2829 warning:  This may be due to a race with someone updating the server.
2830 warning:  Will try again...
2831 END
2832                 next FETCH_ITERATION;
2833             }
2834             printdebug <<END;
2835 git-fetch @fspecs made $lrefname=$got but want git ls-remote @look says $want
2836 END
2837             runcmd_ordryrun_local @git, qw(update-ref -m),
2838                 "dgit fetch git fetch fixup", $lrefname, $want;
2839             $lrfetchrefs_f{$lrefname} = $want;
2840         }
2841         last;
2842     }
2843
2844     if (defined $csuite) {
2845         printdebug "git_lrfetch_sane: tidying any old suite lrfetchrefs\n";
2846         git_for_each_ref("refs/dgit-fetch/$csuite", sub {
2847             my ($objid,$objtype,$lrefname,$reftail) = @_;
2848             next if $lrfetchrefs_f{$lrefname}; # $csuite eq $distro ?
2849             runcmd_ordryrun_local @git, qw(update-ref -d), $lrefname;
2850         });
2851     }
2852
2853     printdebug "git_lrfetch_sane: git fetch --no-insane emulation complete\n",
2854         Dumper(\%lrfetchrefs_f);
2855 }
2856
2857 sub git_fetch_us () {
2858     # Want to fetch only what we are going to use, unless
2859     # deliberately-not-ff, in which case we must fetch everything.
2860
2861     my @specs = deliberately_not_fast_forward ? qw(tags/*) :
2862         map { "tags/$_" }
2863         (quiltmode_splitbrain
2864          ? (map { $_->('*',access_nomdistro) }
2865             \&debiantag_new, \&debiantag_maintview)
2866          : debiantags('*',access_nomdistro));
2867     push @specs, server_branch($csuite);
2868     push @specs, $rewritemap;
2869     push @specs, qw(heads/*) if deliberately_not_fast_forward;
2870
2871     my $url = access_giturl();
2872     git_lrfetch_sane $url, 0, @specs;
2873
2874     my %here;
2875     my @tagpats = debiantags('*',access_nomdistro);
2876
2877     git_for_each_ref([map { "refs/tags/$_" } @tagpats], sub {
2878         my ($objid,$objtype,$fullrefname,$reftail) = @_;
2879         printdebug "currently $fullrefname=$objid\n";
2880         $here{$fullrefname} = $objid;
2881     });
2882     git_for_each_ref([map { lrfetchrefs."/tags/".$_ } @tagpats], sub {
2883         my ($objid,$objtype,$fullrefname,$reftail) = @_;
2884         my $lref = "refs".substr($fullrefname, length(lrfetchrefs));
2885         printdebug "offered $lref=$objid\n";
2886         if (!defined $here{$lref}) {
2887             my @upd = (@git, qw(update-ref), $lref, $objid, '');
2888             runcmd_ordryrun_local @upd;
2889             lrfetchref_used $fullrefname;
2890         } elsif ($here{$lref} eq $objid) {
2891             lrfetchref_used $fullrefname;
2892         } else {
2893             print STDERR
2894                 "Not updating $lref from $here{$lref} to $objid.\n";
2895         }
2896     });
2897 }
2898
2899 #---------- dsc and archive handling ----------
2900
2901 sub mergeinfo_getclogp ($) {
2902     # Ensures thit $mi->{Clogp} exists and returns it
2903     my ($mi) = @_;
2904     $mi->{Clogp} = commit_getclogp($mi->{Commit});
2905 }
2906
2907 sub mergeinfo_version ($) {
2908     return getfield( (mergeinfo_getclogp $_[0]), 'Version' );
2909 }
2910
2911 sub fetch_from_archive_record_1 ($) {
2912     my ($hash) = @_;
2913     runcmd git_update_ref_cmd "dgit fetch $csuite", 'DGIT_ARCHIVE', $hash;
2914     cmdoutput @git, qw(log -n2), $hash;
2915     # ... gives git a chance to complain if our commit is malformed
2916 }
2917
2918 sub fetch_from_archive_record_2 ($) {
2919     my ($hash) = @_;
2920     my @upd_cmd = (git_update_ref_cmd 'dgit fetch', lrref(), $hash);
2921     if (act_local()) {
2922         cmdoutput @upd_cmd;
2923     } else {
2924         dryrun_report @upd_cmd;
2925     }
2926 }
2927
2928 sub parse_dsc_field_def_dsc_distro () {
2929     $dsc_distro //= cfg qw(dgit.default.old-dsc-distro
2930                            dgit.default.distro);
2931 }
2932
2933 sub parse_dsc_field ($$) {
2934     my ($dsc, $what) = @_;
2935     my $f;
2936     foreach my $field (@ourdscfield) {
2937         $f = $dsc->{$field};
2938         last if defined $f;
2939     }
2940
2941     if (!defined $f) {
2942         progress "$what: NO git hash";
2943         parse_dsc_field_def_dsc_distro();
2944     } elsif (($dsc_hash, $dsc_distro, $dsc_hint_tag, $dsc_hint_url)
2945              = $f =~ m/^(\w+)\s+($distro_re)\s+($versiontag_re)\s+(\S+)(?:\s|$)/) {
2946         progress "$what: specified git info ($dsc_distro)";
2947         $dsc_hint_tag = [ $dsc_hint_tag ];
2948     } elsif ($f =~ m/^\w+\s*$/) {
2949         $dsc_hash = $&;
2950         parse_dsc_field_def_dsc_distro();
2951         $dsc_hint_tag = [ debiantags +(getfield $dsc, 'Version'),
2952                           $dsc_distro ];
2953         progress "$what: specified git hash";
2954     } else {
2955         fail "$what: invalid Dgit info";
2956     }
2957 }
2958
2959 sub resolve_dsc_field_commit ($$) {
2960     my ($already_distro, $already_mapref) = @_;
2961
2962     return unless defined $dsc_hash;
2963
2964     my $mapref =
2965         defined $already_mapref &&
2966         ($already_distro eq $dsc_distro || !$chase_dsc_distro)
2967         ? $already_mapref : undef;
2968
2969     my $do_fetch;
2970     $do_fetch = sub {
2971         my ($what, @fetch) = @_;
2972
2973         local $idistro = $dsc_distro;
2974         my $lrf = lrfetchrefs;
2975
2976         if (!$chase_dsc_distro) {
2977             progress
2978                 "not chasing .dsc distro $dsc_distro: not fetching $what";
2979             return 0;
2980         }
2981
2982         progress
2983             ".dsc names distro $dsc_distro: fetching $what";
2984
2985         my $url = access_giturl();
2986         if (!defined $url) {
2987             defined $dsc_hint_url or fail <<END;
2988 .dsc Dgit metadata is in context of distro $dsc_distro
2989 for which we have no configured url and .dsc provides no hint
2990 END
2991             my $proto =
2992                 $dsc_hint_url =~ m#^([-+0-9a-zA-Z]+):# ? $1 :
2993                 $dsc_hint_url =~ m#^/# ? 'file' : 'bad-syntax';
2994             parse_cfg_bool "dsc-url-proto-ok", 'false',
2995                 cfg("dgit.dsc-url-proto-ok.$proto",
2996                     "dgit.default.dsc-url-proto-ok")
2997                 or fail <<END;
2998 .dsc Dgit metadata is in context of distro $dsc_distro
2999 for which we have no configured url;
3000 .dsc provides hinted url with protocol $proto which is unsafe.
3001 (can be overridden by config - consult documentation)
3002 END
3003             $url = $dsc_hint_url;
3004         }
3005
3006         git_lrfetch_sane $url, 1, @fetch;
3007
3008         return $lrf;
3009     };
3010
3011     my $rewrite_enable = do {
3012         local $idistro = $dsc_distro;
3013         access_cfg('rewrite-map-enable', 'RETURN-UNDEF');
3014     };
3015
3016     if (parse_cfg_bool 'rewrite-map-enable', 'true', $rewrite_enable) {
3017         if (!defined $mapref) {
3018             my $lrf = $do_fetch->("rewrite map", $rewritemap) or return;
3019             $mapref = $lrf.'/'.$rewritemap;
3020         }
3021         my $rewritemapdata = git_cat_file $mapref.':map';
3022         if (defined $rewritemapdata
3023             && $rewritemapdata =~ m/^$dsc_hash(?:[ \t](\w+))/m) {
3024             progress
3025                 "server's git history rewrite map contains a relevant entry!";
3026
3027             $dsc_hash = $1;
3028             if (defined $dsc_hash) {
3029                 progress "using rewritten git hash in place of .dsc value";
3030             } else {
3031                 progress "server data says .dsc hash is to be disregarded";
3032             }
3033         }
3034     }
3035
3036     if (!defined git_cat_file $dsc_hash) {
3037         my @tags = map { "tags/".$_ } @$dsc_hint_tag;
3038         my $lrf = $do_fetch->("additional commits", @tags) &&
3039             defined git_cat_file $dsc_hash
3040             or fail <<END;
3041 .dsc Dgit metadata requires commit $dsc_hash
3042 but we could not obtain that object anywhere.
3043 END
3044         foreach my $t (@tags) {
3045             my $fullrefname = $lrf.'/'.$t;
3046 #           print STDERR "CHK $t $fullrefname ".Dumper(\%lrfetchrefs_f);
3047             next unless $lrfetchrefs_f{$fullrefname};
3048             next unless is_fast_fwd "$fullrefname~0", $dsc_hash;
3049             lrfetchref_used $fullrefname;
3050         }
3051     }
3052 }
3053
3054 sub fetch_from_archive () {
3055     ensure_setup_existing_tree();
3056
3057     # Ensures that lrref() is what is actually in the archive, one way
3058     # or another, according to us - ie this client's
3059     # appropritaely-updated archive view.  Also returns the commit id.
3060     # If there is nothing in the archive, leaves lrref alone and
3061     # returns undef.  git_fetch_us must have already been called.
3062     get_archive_dsc();
3063
3064     if ($dsc) {
3065         parse_dsc_field($dsc, 'last upload to archive');
3066         resolve_dsc_field_commit access_basedistro,
3067             lrfetchrefs."/".$rewritemap
3068     } else {
3069         progress "no version available from the archive";
3070     }
3071
3072     # If the archive's .dsc has a Dgit field, there are three
3073     # relevant git commitids we need to choose between and/or merge
3074     # together:
3075     #   1. $dsc_hash: the Dgit field from the archive
3076     #   2. $lastpush_hash: the suite branch on the dgit git server
3077     #   3. $lastfetch_hash: our local tracking brach for the suite
3078     #
3079     # These may all be distinct and need not be in any fast forward
3080     # relationship:
3081     #
3082     # If the dsc was pushed to this suite, then the server suite
3083     # branch will have been updated; but it might have been pushed to
3084     # a different suite and copied by the archive.  Conversely a more
3085     # recent version may have been pushed with dgit but not appeared
3086     # in the archive (yet).
3087     #
3088     # $lastfetch_hash may be awkward because archive imports
3089     # (particularly, imports of Dgit-less .dscs) are performed only as
3090     # needed on individual clients, so different clients may perform a
3091     # different subset of them - and these imports are only made
3092     # public during push.  So $lastfetch_hash may represent a set of
3093     # imports different to a subsequent upload by a different dgit
3094     # client.
3095     #
3096     # Our approach is as follows:
3097     #
3098     # As between $dsc_hash and $lastpush_hash: if $lastpush_hash is a
3099     # descendant of $dsc_hash, then it was pushed by a dgit user who
3100     # had based their work on $dsc_hash, so we should prefer it.
3101     # Otherwise, $dsc_hash was installed into this suite in the
3102     # archive other than by a dgit push, and (necessarily) after the
3103     # last dgit push into that suite (since a dgit push would have
3104     # been descended from the dgit server git branch); thus, in that
3105     # case, we prefer the archive's version (and produce a
3106     # pseudo-merge to overwrite the dgit server git branch).
3107     #
3108     # (If there is no Dgit field in the archive's .dsc then
3109     # generate_commit_from_dsc uses the version numbers to decide
3110     # whether the suite branch or the archive is newer.  If the suite
3111     # branch is newer it ignores the archive's .dsc; otherwise it
3112     # generates an import of the .dsc, and produces a pseudo-merge to
3113     # overwrite the suite branch with the archive contents.)
3114     #
3115     # The outcome of that part of the algorithm is the `public view',
3116     # and is same for all dgit clients: it does not depend on any
3117     # unpublished history in the local tracking branch.
3118     #
3119     # As between the public view and the local tracking branch: The
3120     # local tracking branch is only updated by dgit fetch, and
3121     # whenever dgit fetch runs it includes the public view in the
3122     # local tracking branch.  Therefore if the public view is not
3123     # descended from the local tracking branch, the local tracking
3124     # branch must contain history which was imported from the archive
3125     # but never pushed; and, its tip is now out of date.  So, we make
3126     # a pseudo-merge to overwrite the old imports and stitch the old
3127     # history in.
3128     #
3129     # Finally: we do not necessarily reify the public view (as
3130     # described above).  This is so that we do not end up stacking two
3131     # pseudo-merges.  So what we actually do is figure out the inputs
3132     # to any public view pseudo-merge and put them in @mergeinputs.
3133
3134     my @mergeinputs;
3135     # $mergeinputs[]{Commit}
3136     # $mergeinputs[]{Info}
3137     # $mergeinputs[0] is the one whose tree we use
3138     # @mergeinputs is in the order we use in the actual commit)
3139     #
3140     # Also:
3141     # $mergeinputs[]{Message} is a commit message to use
3142     # $mergeinputs[]{ReverseParents} if def specifies that parent
3143     #                                list should be in opposite order
3144     # Such an entry has no Commit or Info.  It applies only when found
3145     # in the last entry.  (This ugliness is to support making
3146     # identical imports to previous dgit versions.)
3147
3148     my $lastpush_hash = git_get_ref(lrfetchref());
3149     printdebug "previous reference hash=$lastpush_hash\n";
3150     $lastpush_mergeinput = $lastpush_hash && {
3151         Commit => $lastpush_hash,
3152         Info => "dgit suite branch on dgit git server",
3153     };
3154
3155     my $lastfetch_hash = git_get_ref(lrref());
3156     printdebug "fetch_from_archive: lastfetch=$lastfetch_hash\n";
3157     my $lastfetch_mergeinput = $lastfetch_hash && {
3158         Commit => $lastfetch_hash,
3159         Info => "dgit client's archive history view",
3160     };
3161
3162     my $dsc_mergeinput = $dsc_hash && {
3163         Commit => $dsc_hash,
3164         Info => "Dgit field in .dsc from archive",
3165     };
3166
3167     my $cwd = getcwd();
3168     my $del_lrfetchrefs = sub {
3169         changedir $cwd;
3170         my $gur;
3171         printdebug "del_lrfetchrefs...\n";
3172         foreach my $fullrefname (sort keys %lrfetchrefs_d) {
3173             my $objid = $lrfetchrefs_d{$fullrefname};
3174             printdebug "del_lrfetchrefs: $objid $fullrefname\n";
3175             if (!$gur) {
3176                 $gur ||= new IO::Handle;
3177                 open $gur, "|-", qw(git update-ref --stdin) or die $!;
3178             }
3179             printf $gur "delete %s %s\n", $fullrefname, $objid;
3180         }
3181         if ($gur) {
3182             close $gur or failedcmd "git update-ref delete lrfetchrefs";
3183         }
3184     };
3185
3186     if (defined $dsc_hash) {
3187         ensure_we_have_orig();
3188         if (!$lastpush_hash || $dsc_hash eq $lastpush_hash) {
3189             @mergeinputs = $dsc_mergeinput
3190         } elsif (is_fast_fwd($dsc_hash,$lastpush_hash)) {
3191             print STDERR f_ <<END, $dsc_hash, $lastpush_hash,
3192
3193 Git commit in archive is behind the last version allegedly pushed/uploaded.
3194 Commit referred to by archive: %s
3195 Last version pushed with dgit: %s
3196 %s
3197 END
3198                 __ $later_warning_msg or die $!;
3199             @mergeinputs = ($lastpush_mergeinput);
3200         } else {
3201             # Archive has .dsc which is not a descendant of the last dgit
3202             # push.  This can happen if the archive moves .dscs about.
3203             # Just follow its lead.
3204             if (is_fast_fwd($lastpush_hash,$dsc_hash)) {
3205                 progress "archive .dsc names newer git commit";
3206                 @mergeinputs = ($dsc_mergeinput);
3207             } else {
3208                 progress "archive .dsc names other git commit, fixing up";
3209                 @mergeinputs = ($dsc_mergeinput, $lastpush_mergeinput);
3210             }
3211         }
3212     } elsif ($dsc) {
3213         @mergeinputs = generate_commits_from_dsc();
3214         # We have just done an import.  Now, our import algorithm might
3215         # have been improved.  But even so we do not want to generate
3216         # a new different import of the same package.  So if the
3217         # version numbers are the same, just use our existing version.
3218         # If the version numbers are different, the archive has changed
3219         # (perhaps, rewound).
3220         if ($lastfetch_mergeinput &&
3221             !version_compare( (mergeinfo_version $lastfetch_mergeinput),
3222                               (mergeinfo_version $mergeinputs[0]) )) {
3223             @mergeinputs = ($lastfetch_mergeinput);
3224         }
3225     } elsif ($lastpush_hash) {
3226         # only in git, not in the archive yet
3227         @mergeinputs = ($lastpush_mergeinput);
3228         print STDERR f_ <<END,
3229
3230 Package not found in the archive, but has allegedly been pushed using dgit.
3231 %s
3232 END
3233             __ $later_warning_msg or die $!;
3234     } else {
3235         printdebug "nothing found!\n";
3236         if (defined $skew_warning_vsn) {
3237             print STDERR <<END or die $!;
3238
3239 Warning: relevant archive skew detected.
3240 Archive allegedly contains $skew_warning_vsn
3241 But we were not able to obtain any version from the archive or git.
3242
3243 END
3244         }
3245         unshift @end, $del_lrfetchrefs;
3246         return undef;
3247     }
3248
3249     if ($lastfetch_hash &&
3250         !grep {
3251             my $h = $_->{Commit};
3252             $h and is_fast_fwd($lastfetch_hash, $h);
3253             # If true, one of the existing parents of this commit
3254             # is a descendant of the $lastfetch_hash, so we'll
3255             # be ff from that automatically.
3256         } @mergeinputs
3257         ) {
3258         # Otherwise:
3259         push @mergeinputs, $lastfetch_mergeinput;
3260     }
3261
3262     printdebug "fetch mergeinfos:\n";
3263     foreach my $mi (@mergeinputs) {
3264         if ($mi->{Info}) {
3265             printdebug " commit $mi->{Commit} $mi->{Info}\n";
3266         } else {
3267             printdebug sprintf " ReverseParents=%d Message=%s",
3268                 $mi->{ReverseParents}, $mi->{Message};
3269         }
3270     }
3271
3272     my $compat_info= pop @mergeinputs
3273         if $mergeinputs[$#mergeinputs]{Message};
3274
3275     @mergeinputs = grep { defined $_->{Commit} } @mergeinputs;
3276
3277     my $hash;
3278     if (@mergeinputs > 1) {
3279         # here we go, then:
3280         my $tree_commit = $mergeinputs[0]{Commit};
3281
3282         my $tree = get_tree_of_commit $tree_commit;;
3283
3284         # We use the changelog author of the package in question the
3285         # author of this pseudo-merge.  This is (roughly) correct if
3286         # this commit is simply representing aa non-dgit upload.
3287         # (Roughly because it does not record sponsorship - but we
3288         # don't have sponsorship info because that's in the .changes,
3289         # which isn't in the archivw.)
3290         #
3291         # But, it might be that we are representing archive history
3292         # updates (including in-archive copies).  These are not really
3293         # the responsibility of the person who created the .dsc, but
3294         # there is no-one whose name we should better use.  (The
3295         # author of the .dsc-named commit is clearly worse.)
3296
3297         my $useclogp = mergeinfo_getclogp $mergeinputs[0];
3298         my $author = clogp_authline $useclogp;
3299         my $cversion = getfield $useclogp, 'Version';
3300
3301         my $mcf = dgit_privdir()."/mergecommit";
3302         open MC, ">", $mcf or die "$mcf $!";
3303         print MC <<END or die $!;
3304 tree $tree
3305 END
3306
3307         my @parents = grep { $_->{Commit} } @mergeinputs;
3308         @parents = reverse @parents if $compat_info->{ReverseParents};
3309         print MC <<END or die $! foreach @parents;
3310 parent $_->{Commit}
3311 END
3312
3313         print MC <<END or die $!;
3314 author $author
3315 committer $author
3316
3317 END
3318
3319         if (defined $compat_info->{Message}) {
3320             print MC $compat_info->{Message} or die $!;
3321         } else {
3322             print MC <<END or die $!;
3323 Record $package ($cversion) in archive suite $csuite
3324
3325 Record that
3326 END
3327             my $message_add_info = sub {
3328                 my ($mi) = (@_);
3329                 my $mversion = mergeinfo_version $mi;
3330                 printf MC "  %-20s %s\n", $mversion, $mi->{Info}
3331                     or die $!;
3332             };
3333
3334             $message_add_info->($mergeinputs[0]);
3335             print MC <<END or die $!;
3336 should be treated as descended from
3337 END
3338             $message_add_info->($_) foreach @mergeinputs[1..$#mergeinputs];
3339         }
3340
3341         close MC or die $!;
3342         $hash = make_commit $mcf;
3343     } else {
3344         $hash = $mergeinputs[0]{Commit};
3345     }
3346     printdebug "fetch hash=$hash\n";
3347
3348     my $chkff = sub {
3349         my ($lasth, $what) = @_;
3350         return unless $lasth;
3351         die "$lasth $hash $what ?" unless is_fast_fwd($lasth, $hash);
3352     };
3353
3354     $chkff->($lastpush_hash, 'dgit repo server tip (last push)')
3355         if $lastpush_hash;
3356     $chkff->($lastfetch_hash, 'local tracking tip (last fetch)');
3357
3358     fetch_from_archive_record_1($hash);
3359
3360     if (defined $skew_warning_vsn) {
3361         printdebug "SKEW CHECK WANT $skew_warning_vsn\n";
3362         my $gotclogp = commit_getclogp($hash);
3363         my $got_vsn = getfield $gotclogp, 'Version';
3364         printdebug "SKEW CHECK GOT $got_vsn\n";
3365         if (version_compare($got_vsn, $skew_warning_vsn) < 0) {
3366             print STDERR <<END or die $!;
3367
3368 Warning: archive skew detected.  Using the available version:
3369 Archive allegedly contains    $skew_warning_vsn
3370 We were able to obtain only   $got_vsn
3371
3372 END
3373         }
3374     }
3375
3376     if ($lastfetch_hash ne $hash) {
3377         fetch_from_archive_record_2($hash);
3378     }
3379
3380     lrfetchref_used lrfetchref();
3381
3382     check_gitattrs($hash, "fetched source tree");
3383
3384     unshift @end, $del_lrfetchrefs;
3385     return $hash;
3386 }
3387
3388 sub set_local_git_config ($$) {
3389     my ($k, $v) = @_;
3390     runcmd @git, qw(config), $k, $v;
3391 }
3392
3393 sub setup_mergechangelogs (;$) {
3394     my ($always) = @_;
3395     return unless $always || access_cfg_bool(1, 'setup-mergechangelogs');
3396
3397     my $driver = 'dpkg-mergechangelogs';
3398     my $cb = "merge.$driver";
3399     confess unless defined $maindir;
3400     my $attrs = "$maindir_gitcommon/info/attributes";
3401     ensuredir "$maindir_gitcommon/info";
3402
3403     open NATTRS, ">", "$attrs.new" or die "$attrs.new $!";
3404     if (!open ATTRS, "<", $attrs) {
3405         $!==ENOENT or die "$attrs: $!";
3406     } else {
3407         while (<ATTRS>) {
3408             chomp;
3409             next if m{^debian/changelog\s};
3410             print NATTRS $_, "\n" or die $!;
3411         }
3412         ATTRS->error and die $!;
3413         close ATTRS;
3414     }
3415     print NATTRS "debian/changelog merge=$driver\n" or die $!;
3416     close NATTRS;
3417
3418     set_local_git_config "$cb.name", 'debian/changelog merge driver';
3419     set_local_git_config "$cb.driver", 'dpkg-mergechangelogs -m %O %A %B %A';
3420
3421     rename "$attrs.new", "$attrs" or die "$attrs: $!";
3422 }
3423
3424 sub setup_useremail (;$) {
3425     my ($always) = @_;
3426     return unless $always || access_cfg_bool(1, 'setup-useremail');
3427
3428     my $setup = sub {
3429         my ($k, $envvar) = @_;
3430         my $v = access_cfg("user-$k", 'RETURN-UNDEF') // $ENV{$envvar};
3431         return unless defined $v;
3432         set_local_git_config "user.$k", $v;
3433     };
3434
3435     $setup->('email', 'DEBEMAIL');
3436     $setup->('name', 'DEBFULLNAME');
3437 }
3438
3439 sub ensure_setup_existing_tree () {
3440     my $k = "remote.$remotename.skipdefaultupdate";
3441     my $c = git_get_config $k;
3442     return if defined $c;
3443     set_local_git_config $k, 'true';
3444 }
3445
3446 sub open_main_gitattrs () {
3447     confess 'internal error no maindir' unless defined $maindir;
3448     my $gai = new IO::File "$maindir_gitcommon/info/attributes"
3449         or $!==ENOENT
3450         or die "open $maindir_gitcommon/info/attributes: $!";
3451     return $gai;
3452 }
3453
3454 our $gitattrs_ourmacro_re = qr{^\[attr\]dgit-defuse-attrs\s};
3455
3456 sub is_gitattrs_setup () {
3457     # return values:
3458     #  trueish
3459     #     1: gitattributes set up and should be left alone
3460     #  falseish
3461     #     0: there is a dgit-defuse-attrs but it needs fixing
3462     #     undef: there is none
3463     my $gai = open_main_gitattrs();
3464     return 0 unless $gai;
3465     while (<$gai>) {
3466         next unless m{$gitattrs_ourmacro_re};
3467         return 1 if m{\s-working-tree-encoding\s};
3468         printdebug "is_gitattrs_setup: found old macro\n";
3469         return 0;
3470     }
3471     $gai->error and die $!;
3472     printdebug "is_gitattrs_setup: found nothing\n";
3473     return undef;
3474 }    
3475
3476 sub setup_gitattrs (;$) {
3477     my ($always) = @_;
3478     return unless $always || access_cfg_bool(1, 'setup-gitattributes');
3479
3480     my $already = is_gitattrs_setup();
3481     if ($already) {
3482         progress <<END;
3483 [attr]dgit-defuse-attrs already found, and proper, in .git/info/attributes
3484  not doing further gitattributes setup
3485 END
3486         return;
3487     }
3488     my $new = "[attr]dgit-defuse-attrs  $negate_harmful_gitattrs";
3489     my $af = "$maindir_gitcommon/info/attributes";
3490     ensuredir "$maindir_gitcommon/info";
3491
3492     open GAO, "> $af.new" or die $!;
3493     print GAO <<END or die $! unless defined $already;
3494 *       dgit-defuse-attrs
3495 $new
3496 # ^ see GITATTRIBUTES in dgit(7) and dgit setup-new-tree in dgit(1)
3497 END
3498     my $gai = open_main_gitattrs();
3499     if ($gai) {
3500         while (<$gai>) {
3501             if (m{$gitattrs_ourmacro_re}) {
3502                 die unless defined $already;
3503                 $_ = $new;
3504             }
3505             chomp;
3506             print GAO $_, "\n" or die $!;
3507         }
3508         $gai->error and die $!;
3509     }
3510     close GAO or die $!;
3511     rename "$af.new", "$af" or die "install $af: $!";
3512 }
3513
3514 sub setup_new_tree () {
3515     setup_mergechangelogs();
3516     setup_useremail();
3517     setup_gitattrs();
3518 }
3519
3520 sub check_gitattrs ($$) {
3521     my ($treeish, $what) = @_;
3522
3523     return if is_gitattrs_setup;
3524
3525     local $/="\0";
3526     my @cmd = (@git, qw(ls-tree -lrz --), "${treeish}:");
3527     debugcmd "|",@cmd;
3528     my $gafl = new IO::File;
3529     open $gafl, "-|", @cmd or die $!;
3530     while (<$gafl>) {
3531         chomp or die;
3532         s/^\d+\s+\w+\s+\w+\s+(\d+)\t// or die;
3533         next if $1 == 0;
3534         next unless m{(?:^|/)\.gitattributes$};
3535
3536         # oh dear, found one
3537         print STDERR <<END;
3538 dgit: warning: $what contains .gitattributes
3539 dgit: .gitattributes not (fully) defused.  Recommended: dgit setup-new-tree.
3540 END
3541         close $gafl;
3542         return;
3543     }
3544     # tree contains no .gitattributes files
3545     $?=0; $!=0; close $gafl or failedcmd @cmd;
3546 }
3547
3548
3549 sub multisuite_suite_child ($$$) {
3550     my ($tsuite, $mergeinputs, $fn) = @_;
3551     # in child, sets things up, calls $fn->(), and returns undef
3552     # in parent, returns canonical suite name for $tsuite
3553     my $canonsuitefh = IO::File::new_tmpfile;
3554     my $pid = fork // die $!;
3555     if (!$pid) {
3556         forkcheck_setup();
3557         $isuite = $tsuite;
3558         $us .= " [$isuite]";
3559         $debugprefix .= " ";
3560         progress "fetching $tsuite...";
3561         canonicalise_suite();
3562         print $canonsuitefh $csuite, "\n" or die $!;
3563         close $canonsuitefh or die $!;
3564         $fn->();
3565         return undef;
3566     }
3567     waitpid $pid,0 == $pid or die $!;
3568     fail "failed to obtain $tsuite: ".waitstatusmsg() if $? && $?!=256*4;
3569     seek $canonsuitefh,0,0 or die $!;
3570     local $csuite = <$canonsuitefh>;
3571     die $! unless defined $csuite && chomp $csuite;
3572     if ($? == 256*4) {
3573         printdebug "multisuite $tsuite missing\n";
3574         return $csuite;
3575     }
3576     printdebug "multisuite $tsuite ok (canon=$csuite)\n";
3577     push @$mergeinputs, {
3578         Ref => lrref,
3579         Info => $csuite,
3580     };
3581     return $csuite;
3582 }
3583
3584 sub fork_for_multisuite ($) {
3585     my ($before_fetch_merge) = @_;
3586     # if nothing unusual, just returns ''
3587     #
3588     # if multisuite:
3589     # returns 0 to caller in child, to do first of the specified suites
3590     # in child, $csuite is not yet set
3591     #
3592     # returns 1 to caller in parent, to finish up anything needed after
3593     # in parent, $csuite is set to canonicalised portmanteau
3594
3595     my $org_isuite = $isuite;
3596     my @suites = split /\,/, $isuite;
3597     return '' unless @suites > 1;
3598     printdebug "fork_for_multisuite: @suites\n";
3599
3600     my @mergeinputs;
3601
3602     my $cbasesuite = multisuite_suite_child($suites[0], \@mergeinputs,
3603                                             sub { });
3604     return 0 unless defined $cbasesuite;
3605
3606     fail "package $package missing in (base suite) $cbasesuite"
3607         unless @mergeinputs;
3608
3609     my @csuites = ($cbasesuite);
3610
3611     $before_fetch_merge->();
3612
3613     foreach my $tsuite (@suites[1..$#suites]) {
3614         $tsuite =~ s/^-/$cbasesuite-/;
3615         my $csubsuite = multisuite_suite_child($tsuite, \@mergeinputs,
3616                                                sub {
3617             @end = ();
3618             fetch_one();
3619             finish 0;
3620         });
3621
3622         $csubsuite =~ s/^\Q$cbasesuite\E-/-/;
3623         push @csuites, $csubsuite;
3624     }
3625
3626     foreach my $mi (@mergeinputs) {
3627         my $ref = git_get_ref $mi->{Ref};
3628         die "$mi->{Ref} ?" unless length $ref;
3629         $mi->{Commit} = $ref;
3630     }
3631
3632     $csuite = join ",", @csuites;
3633
3634     my $previous = git_get_ref lrref;
3635     if ($previous) {
3636         unshift @mergeinputs, {
3637             Commit => $previous,
3638             Info => "local combined tracking branch",
3639             Warning =>
3640  "archive seems to have rewound: local tracking branch is ahead!",
3641         };
3642     }
3643
3644     foreach my $ix (0..$#mergeinputs) {
3645         $mergeinputs[$ix]{Index} = $ix;
3646     }
3647
3648     @mergeinputs = sort {
3649         -version_compare(mergeinfo_version $a,
3650                          mergeinfo_version $b) # highest version first
3651             or
3652         $a->{Index} <=> $b->{Index}; # earliest in spec first
3653     } @mergeinputs;
3654
3655     my @needed;
3656
3657   NEEDED:
3658     foreach my $mi (@mergeinputs) {
3659         printdebug "multisuite merge check $mi->{Info}\n";
3660         foreach my $previous (@needed) {
3661             next unless is_fast_fwd $mi->{Commit}, $previous->{Commit};
3662             printdebug "multisuite merge un-needed $previous->{Info}\n";
3663             next NEEDED;
3664         }
3665         push @needed, $mi;
3666         printdebug "multisuite merge this-needed\n";
3667         $mi->{Character} = '+';
3668     }
3669
3670     $needed[0]{Character} = '*';
3671
3672     my $output = $needed[0]{Commit};
3673
3674     if (@needed > 1) {
3675         printdebug "multisuite merge nontrivial\n";
3676         my $tree = cmdoutput qw(git rev-parse), $needed[0]{Commit}.':';
3677
3678         my $commit = "tree $tree\n";
3679         my $msg = "Combine archive branches $csuite [dgit]\n\n".
3680             "Input branches:\n";
3681
3682         foreach my $mi (sort { $a->{Index} <=> $b->{Index} } @mergeinputs) {
3683             printdebug "multisuite merge include $mi->{Info}\n";
3684             $mi->{Character} //= ' ';
3685             $commit .= "parent $mi->{Commit}\n";
3686             $msg .= sprintf " %s  %-25s %s\n",
3687                 $mi->{Character},
3688                 (mergeinfo_version $mi),
3689                 $mi->{Info};
3690         }
3691         my $authline = clogp_authline mergeinfo_getclogp $needed[0];
3692         $msg .= "\nKey\n".