chiark / gitweb /
135abe5fd1b69291af30d5b2740840c01bbe797c
[dgit.git] / dgit
1 #!/usr/bin/perl -w
2 # dgit
3 # Integration between git and Debian-style archives
4 #
5 # Copyright (C)2013-2016 Ian Jackson
6 #
7 # This program is free software: you can redistribute it and/or modify
8 # it under the terms of the GNU General Public License as published by
9 # the Free Software Foundation, either version 3 of the License, or
10 # (at your option) any later version.
11 #
12 # This program is distributed in the hope that it will be useful,
13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
15 # GNU General Public License for more details.
16 #
17 # You should have received a copy of the GNU General Public License
18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
19
20 use strict;
21
22 use Debian::Dgit;
23 setup_sigwarn();
24
25 use IO::Handle;
26 use Data::Dumper;
27 use LWP::UserAgent;
28 use Dpkg::Control::Hash;
29 use File::Path;
30 use File::Temp qw(tempdir);
31 use File::Basename;
32 use Dpkg::Version;
33 use POSIX;
34 use IPC::Open2;
35 use Digest::SHA;
36 use Digest::MD5;
37 use List::Util qw(any);
38 use List::MoreUtils qw(pairwise);
39 use Text::Glob qw(match_glob);
40 use Fcntl qw(:DEFAULT :flock);
41 use Carp;
42
43 use Debian::Dgit;
44
45 our $our_version = 'UNRELEASED'; ###substituted###
46 our $absurdity = undef; ###substituted###
47
48 our @rpushprotovsn_support = qw(4 3 2); # 4 is new tag format
49 our $protovsn;
50
51 our $isuite;
52 our $idistro;
53 our $package;
54 our @ropts;
55
56 our $sign = 1;
57 our $dryrun_level = 0;
58 our $changesfile;
59 our $buildproductsdir = '..';
60 our $new_package = 0;
61 our $ignoredirty = 0;
62 our $rmonerror = 1;
63 our @deliberatelies;
64 our %previously;
65 our $existing_package = 'dpkg';
66 our $cleanmode;
67 our $changes_since_version;
68 our $rmchanges;
69 our $overwrite_version; # undef: not specified; '': check changelog
70 our $quilt_mode;
71 our $quilt_modes_re = 'linear|smash|auto|nofix|nocheck|gbp|dpm|unapplied';
72 our $dodep14tag;
73 our $dodep14tag_re = 'want|no|always';
74 our $split_brain_save;
75 our $we_are_responder;
76 our $we_are_initiator;
77 our $initiator_tempdir;
78 our $patches_applied_dirtily = 00;
79 our $tagformat_want;
80 our $tagformat;
81 our $tagformatfn;
82 our $chase_dsc_distro=1;
83
84 our %forceopts = map { $_=>0 }
85     qw(unrepresentable unsupported-source-format
86        dsc-changes-mismatch changes-origs-exactly
87        import-gitapply-absurd
88        import-gitapply-no-absurd
89        import-dsc-with-dgit-field);
90
91 our %format_ok = map { $_=>1 } ("1.0","3.0 (native)","3.0 (quilt)");
92
93 our $suite_re = '[-+.0-9a-z]+';
94 our $cleanmode_re = 'dpkg-source(?:-d)?|git|git-ff|check|none';
95 our $orig_f_comp_re = 'orig(?:-[-0-9a-z]+)?';
96 our $orig_f_sig_re = '\\.(?:asc|gpg|pgp)';
97 our $orig_f_tail_re = "$orig_f_comp_re\\.tar(?:\\.\\w+)?(?:$orig_f_sig_re)?";
98
99 our $git_authline_re = '^([^<>]+) \<(\S+)\> (\d+ [-+]\d+)$';
100 our $splitbraincache = 'dgit-intern/quilt-cache';
101 our $rewritemap = 'dgit-rewrite/map';
102
103 our (@git) = qw(git);
104 our (@dget) = qw(dget);
105 our (@curl) = qw(curl);
106 our (@dput) = qw(dput);
107 our (@debsign) = qw(debsign);
108 our (@gpg) = qw(gpg);
109 our (@sbuild) = qw(sbuild);
110 our (@ssh) = 'ssh';
111 our (@dgit) = qw(dgit);
112 our (@aptget) = qw(apt-get);
113 our (@aptcache) = qw(apt-cache);
114 our (@dpkgbuildpackage) = qw(dpkg-buildpackage -i\.git/ -I.git);
115 our (@dpkgsource) = qw(dpkg-source -i\.git/ -I.git);
116 our (@dpkggenchanges) = qw(dpkg-genchanges);
117 our (@mergechanges) = qw(mergechanges -f);
118 our (@gbp_build) = ('');
119 our (@gbp_pq) = ('gbp pq');
120 our (@changesopts) = ('');
121
122 our %opts_opt_map = ('dget' => \@dget, # accept for compatibility
123                      'curl' => \@curl,
124                      'dput' => \@dput,
125                      'debsign' => \@debsign,
126                      'gpg' => \@gpg,
127                      'sbuild' => \@sbuild,
128                      'ssh' => \@ssh,
129                      'dgit' => \@dgit,
130                      'git' => \@git,
131                      'apt-get' => \@aptget,
132                      'apt-cache' => \@aptcache,
133                      'dpkg-source' => \@dpkgsource,
134                      'dpkg-buildpackage' => \@dpkgbuildpackage,
135                      'dpkg-genchanges' => \@dpkggenchanges,
136                      'gbp-build' => \@gbp_build,
137                      'gbp-pq' => \@gbp_pq,
138                      'ch' => \@changesopts,
139                      'mergechanges' => \@mergechanges);
140
141 our %opts_opt_cmdonly = ('gpg' => 1, 'git' => 1);
142 our %opts_cfg_insertpos = map {
143     $_,
144     scalar @{ $opts_opt_map{$_} }
145 } keys %opts_opt_map;
146
147 sub parseopts_late_defaults();
148
149 our $keyid;
150
151 autoflush STDOUT 1;
152
153 our $supplementary_message = '';
154 our $need_split_build_invocation = 0;
155 our $split_brain = 0;
156
157 END {
158     local ($@, $?);
159     print STDERR "! $_\n" foreach $supplementary_message =~ m/^.+$/mg;
160 }
161
162 our $remotename = 'dgit';
163 our @ourdscfield = qw(Dgit Vcs-Dgit-Master);
164 our $csuite;
165 our $instead_distro;
166
167 if (!defined $absurdity) {
168     $absurdity = $0;
169     $absurdity =~ s{/[^/]+$}{/absurd} or die;
170 }
171
172 sub debiantag ($$) {
173     my ($v,$distro) = @_;
174     return $tagformatfn->($v, $distro);
175 }
176
177 sub debiantag_maintview ($$) { 
178     my ($v,$distro) = @_;
179     return "$distro/".dep14_version_mangle $v;
180 }
181
182 sub madformat ($) { $_[0] eq '3.0 (quilt)' }
183
184 sub lbranch () { return "$branchprefix/$csuite"; }
185 my $lbranch_re = '^refs/heads/'.$branchprefix.'/([^/.]+)$';
186 sub lref () { return "refs/heads/".lbranch(); }
187 sub lrref () { return "refs/remotes/$remotename/".server_branch($csuite); }
188 sub rrref () { return server_ref($csuite); }
189
190 sub stripepoch ($) {
191     my ($vsn) = @_;
192     $vsn =~ s/^\d+\://;
193     return $vsn;
194 }
195
196 sub srcfn ($$) {
197     my ($vsn,$sfx) = @_;
198     return "${package}_".(stripepoch $vsn).$sfx
199 }
200
201 sub dscfn ($) {
202     my ($vsn) = @_;
203     return srcfn($vsn,".dsc");
204 }
205
206 sub changespat ($;$) {
207     my ($vsn, $arch) = @_;
208     return "${package}_".(stripepoch $vsn)."_".($arch//'*').".changes";
209 }
210
211 sub upstreamversion ($) {
212     my ($vsn) = @_;
213     $vsn =~ s/-[^-]+$//;
214     return $vsn;
215 }
216
217 our $us = 'dgit';
218 initdebug('');
219
220 our @end;
221 END { 
222     local ($?);
223     foreach my $f (@end) {
224         eval { $f->(); };
225         print STDERR "$us: cleanup: $@" if length $@;
226     }
227 };
228
229 sub badcfg { print STDERR "$us: invalid configuration: @_\n"; exit 12; }
230
231 sub forceable_fail ($$) {
232     my ($forceoptsl, $msg) = @_;
233     fail $msg unless grep { $forceopts{$_} } @$forceoptsl;
234     print STDERR "warning: overriding problem due to --force:\n". $msg;
235 }
236
237 sub forceing ($) {
238     my ($forceoptsl) = @_;
239     my @got = grep { $forceopts{$_} } @$forceoptsl;
240     return 0 unless @got;
241     print STDERR
242  "warning: skipping checks or functionality due to --force-$got[0]\n";
243 }
244
245 sub no_such_package () {
246     print STDERR "$us: package $package does not exist in suite $isuite\n";
247     exit 4;
248 }
249
250 sub changedir ($) {
251     my ($newdir) = @_;
252     printdebug "CD $newdir\n";
253     chdir $newdir or confess "chdir: $newdir: $!";
254 }
255
256 sub deliberately ($) {
257     my ($enquiry) = @_;
258     return !!grep { $_ eq "--deliberately-$enquiry" } @deliberatelies;
259 }
260
261 sub deliberately_not_fast_forward () {
262     foreach (qw(not-fast-forward fresh-repo)) {
263         return 1 if deliberately($_) || deliberately("TEST-dgit-only-$_");
264     }
265 }
266
267 sub quiltmode_splitbrain () {
268     $quilt_mode =~ m/gbp|dpm|unapplied/;
269 }
270
271 sub opts_opt_multi_cmd {
272     my @cmd;
273     push @cmd, split /\s+/, shift @_;
274     push @cmd, @_;
275     @cmd;
276 }
277
278 sub gbp_pq {
279     return opts_opt_multi_cmd @gbp_pq;
280 }
281
282 #---------- remote protocol support, common ----------
283
284 # remote push initiator/responder protocol:
285 #  $ dgit remote-push-build-host <n-rargs> <rargs>... <push-args>...
286 #  where <rargs> is <push-host-dir> <supported-proto-vsn>,... ...
287 #  < dgit-remote-push-ready <actual-proto-vsn>
288 #
289 # occasionally:
290 #
291 #  > progress NBYTES
292 #  [NBYTES message]
293 #
294 #  > supplementary-message NBYTES          # $protovsn >= 3
295 #  [NBYTES message]
296 #
297 # main sequence:
298 #
299 #  > file parsed-changelog
300 #  [indicates that output of dpkg-parsechangelog follows]
301 #  > data-block NBYTES
302 #  > [NBYTES bytes of data (no newline)]
303 #  [maybe some more blocks]
304 #  > data-end
305 #
306 #  > file dsc
307 #  [etc]
308 #
309 #  > file changes
310 #  [etc]
311 #
312 #  > param head DGIT-VIEW-HEAD
313 #  > param csuite SUITE
314 #  > param tagformat old|new
315 #  > param maint-view MAINT-VIEW-HEAD
316 #
317 #  > previously REFNAME=OBJNAME       # if --deliberately-not-fast-forward
318 #                                     # goes into tag, for replay prevention
319 #
320 #  > want signed-tag
321 #  [indicates that signed tag is wanted]
322 #  < data-block NBYTES
323 #  < [NBYTES bytes of data (no newline)]
324 #  [maybe some more blocks]
325 #  < data-end
326 #  < files-end
327 #
328 #  > want signed-dsc-changes
329 #  < data-block NBYTES    [transfer of signed dsc]
330 #  [etc]
331 #  < data-block NBYTES    [transfer of signed changes]
332 #  [etc]
333 #  < files-end
334 #
335 #  > complete
336
337 our $i_child_pid;
338
339 sub i_child_report () {
340     # Sees if our child has died, and reap it if so.  Returns a string
341     # describing how it died if it failed, or undef otherwise.
342     return undef unless $i_child_pid;
343     my $got = waitpid $i_child_pid, WNOHANG;
344     return undef if $got <= 0;
345     die unless $got == $i_child_pid;
346     $i_child_pid = undef;
347     return undef unless $?;
348     return "build host child ".waitstatusmsg();
349 }
350
351 sub badproto ($$) {
352     my ($fh, $m) = @_;
353     fail "connection lost: $!" if $fh->error;
354     fail "protocol violation; $m not expected";
355 }
356
357 sub badproto_badread ($$) {
358     my ($fh, $wh) = @_;
359     fail "connection lost: $!" if $!;
360     my $report = i_child_report();
361     fail $report if defined $report;
362     badproto $fh, "eof (reading $wh)";
363 }
364
365 sub protocol_expect (&$) {
366     my ($match, $fh) = @_;
367     local $_;
368     $_ = <$fh>;
369     defined && chomp or badproto_badread $fh, "protocol message";
370     if (wantarray) {
371         my @r = &$match;
372         return @r if @r;
373     } else {
374         my $r = &$match;
375         return $r if $r;
376     }
377     badproto $fh, "\`$_'";
378 }
379
380 sub protocol_send_file ($$) {
381     my ($fh, $ourfn) = @_;
382     open PF, "<", $ourfn or die "$ourfn: $!";
383     for (;;) {
384         my $d;
385         my $got = read PF, $d, 65536;
386         die "$ourfn: $!" unless defined $got;
387         last if !$got;
388         print $fh "data-block ".length($d)."\n" or die $!;
389         print $fh $d or die $!;
390     }
391     PF->error and die "$ourfn $!";
392     print $fh "data-end\n" or die $!;
393     close PF;
394 }
395
396 sub protocol_read_bytes ($$) {
397     my ($fh, $nbytes) = @_;
398     $nbytes =~ m/^[1-9]\d{0,5}$|^0$/ or badproto \*RO, "bad byte count";
399     my $d;
400     my $got = read $fh, $d, $nbytes;
401     $got==$nbytes or badproto_badread $fh, "data block";
402     return $d;
403 }
404
405 sub protocol_receive_file ($$) {
406     my ($fh, $ourfn) = @_;
407     printdebug "() $ourfn\n";
408     open PF, ">", $ourfn or die "$ourfn: $!";
409     for (;;) {
410         my ($y,$l) = protocol_expect {
411             m/^data-block (.*)$/ ? (1,$1) :
412             m/^data-end$/ ? (0,) :
413             ();
414         } $fh;
415         last unless $y;
416         my $d = protocol_read_bytes $fh, $l;
417         print PF $d or die $!;
418     }
419     close PF or die $!;
420 }
421
422 #---------- remote protocol support, responder ----------
423
424 sub responder_send_command ($) {
425     my ($command) = @_;
426     return unless $we_are_responder;
427     # called even without $we_are_responder
428     printdebug ">> $command\n";
429     print PO $command, "\n" or die $!;
430 }    
431
432 sub responder_send_file ($$) {
433     my ($keyword, $ourfn) = @_;
434     return unless $we_are_responder;
435     printdebug "]] $keyword $ourfn\n";
436     responder_send_command "file $keyword";
437     protocol_send_file \*PO, $ourfn;
438 }
439
440 sub responder_receive_files ($@) {
441     my ($keyword, @ourfns) = @_;
442     die unless $we_are_responder;
443     printdebug "[[ $keyword @ourfns\n";
444     responder_send_command "want $keyword";
445     foreach my $fn (@ourfns) {
446         protocol_receive_file \*PI, $fn;
447     }
448     printdebug "[[\$\n";
449     protocol_expect { m/^files-end$/ } \*PI;
450 }
451
452 #---------- remote protocol support, initiator ----------
453
454 sub initiator_expect (&) {
455     my ($match) = @_;
456     protocol_expect { &$match } \*RO;
457 }
458
459 #---------- end remote code ----------
460
461 sub progress {
462     if ($we_are_responder) {
463         my $m = join '', @_;
464         responder_send_command "progress ".length($m) or die $!;
465         print PO $m or die $!;
466     } else {
467         print @_, "\n";
468     }
469 }
470
471 our $ua;
472
473 sub url_get {
474     if (!$ua) {
475         $ua = LWP::UserAgent->new();
476         $ua->env_proxy;
477     }
478     my $what = $_[$#_];
479     progress "downloading $what...";
480     my $r = $ua->get(@_) or die $!;
481     return undef if $r->code == 404;
482     $r->is_success or fail "failed to fetch $what: ".$r->status_line;
483     return $r->decoded_content(charset => 'none');
484 }
485
486 our ($dscdata,$dscurl,$dsc,$dsc_checked,$skew_warning_vsn);
487
488 sub runcmd {
489     debugcmd "+",@_;
490     $!=0; $?=-1;
491     failedcmd @_ if system @_;
492 }
493
494 sub act_local () { return $dryrun_level <= 1; }
495 sub act_scary () { return !$dryrun_level; }
496
497 sub printdone {
498     if (!$dryrun_level) {
499         progress "$us ok: @_";
500     } else {
501         progress "would be ok: @_ (but dry run only)";
502     }
503 }
504
505 sub dryrun_report {
506     printcmd(\*STDERR,$debugprefix."#",@_);
507 }
508
509 sub runcmd_ordryrun {
510     if (act_scary()) {
511         runcmd @_;
512     } else {
513         dryrun_report @_;
514     }
515 }
516
517 sub runcmd_ordryrun_local {
518     if (act_local()) {
519         runcmd @_;
520     } else {
521         dryrun_report @_;
522     }
523 }
524
525 sub shell_cmd {
526     my ($first_shell, @cmd) = @_;
527     return qw(sh -ec), $first_shell.'; exec "$@"', 'x', @cmd;
528 }
529
530 our $helpmsg = <<END;
531 main usages:
532   dgit [dgit-opts] clone [dgit-opts] package [suite] [./dir|/dir]
533   dgit [dgit-opts] fetch|pull [dgit-opts] [suite]
534   dgit [dgit-opts] build [dpkg-buildpackage-opts]
535   dgit [dgit-opts] sbuild [sbuild-opts]
536   dgit [dgit-opts] push [dgit-opts] [suite]
537   dgit [dgit-opts] rpush build-host:build-dir ...
538 important dgit options:
539   -k<keyid>           sign tag and package with <keyid> instead of default
540   --dry-run -n        do not change anything, but go through the motions
541   --damp-run -L       like --dry-run but make local changes, without signing
542   --new -N            allow introducing a new package
543   --debug -D          increase debug level
544   -c<name>=<value>    set git config option (used directly by dgit too)
545 END
546
547 our $later_warning_msg = <<END;
548 Perhaps the upload is stuck in incoming.  Using the version from git.
549 END
550
551 sub badusage {
552     print STDERR "$us: @_\n", $helpmsg or die $!;
553     exit 8;
554 }
555
556 sub nextarg {
557     @ARGV or badusage "too few arguments";
558     return scalar shift @ARGV;
559 }
560
561 sub cmd_help () {
562     print $helpmsg or die $!;
563     exit 0;
564 }
565
566 our $td = $ENV{DGIT_TEST_DUMMY_DIR} || "DGIT_TEST_DUMMY_DIR-unset";
567
568 our %defcfg = ('dgit.default.distro' => 'debian',
569                'dgit.default.default-suite' => 'unstable',
570                'dgit.default.old-dsc-distro' => 'debian',
571                'dgit-suite.*-security.distro' => 'debian-security',
572                'dgit.default.username' => '',
573                'dgit.default.archive-query-default-component' => 'main',
574                'dgit.default.ssh' => 'ssh',
575                'dgit.default.archive-query' => 'madison:',
576                'dgit.default.sshpsql-dbname' => 'service=projectb',
577                'dgit.default.aptget-components' => 'main',
578                'dgit.default.dgit-tag-format' => 'new,old,maint',
579                'dgit.dsc-url-proto-ok.http'    => 'true',
580                'dgit.dsc-url-proto-ok.https'   => 'true',
581                'dgit.dsc-url-proto-ok.git'     => 'true',
582                'dgit.default.dsc-url-proto-ok' => 'false',
583                # old means "repo server accepts pushes with old dgit tags"
584                # new means "repo server accepts pushes with new dgit tags"
585                # maint means "repo server accepts split brain pushes"
586                # hist means "repo server may have old pushes without new tag"
587                #   ("hist" is implied by "old")
588                'dgit-distro.debian.archive-query' => 'ftpmasterapi:',
589                'dgit-distro.debian.git-check' => 'url',
590                'dgit-distro.debian.git-check-suffix' => '/info/refs',
591                'dgit-distro.debian.new-private-pushers' => 't',
592                'dgit-distro.debian/push.git-url' => '',
593                'dgit-distro.debian/push.git-host' => 'push.dgit.debian.org',
594                'dgit-distro.debian/push.git-user-force' => 'dgit',
595                'dgit-distro.debian/push.git-proto' => 'git+ssh://',
596                'dgit-distro.debian/push.git-path' => '/dgit/debian/repos',
597                'dgit-distro.debian/push.git-create' => 'true',
598                'dgit-distro.debian/push.git-check' => 'ssh-cmd',
599  'dgit-distro.debian.archive-query-url', 'https://api.ftp-master.debian.org/',
600 # 'dgit-distro.debian.archive-query-tls-key',
601 #    '/etc/ssl/certs/%HOST%.pem:/etc/dgit/%HOST%.pem',
602 # ^ this does not work because curl is broken nowadays
603 # Fixing #790093 properly will involve providing providing the key
604 # in some pacagke and maybe updating these paths.
605 #
606 # 'dgit-distro.debian.archive-query-tls-curl-args',
607 #   '--ca-path=/etc/ssl/ca-debian',
608 # ^ this is a workaround but works (only) on DSA-administered machines
609                'dgit-distro.debian.git-url' => 'https://git.dgit.debian.org',
610                'dgit-distro.debian.git-url-suffix' => '',
611                'dgit-distro.debian.upload-host' => 'ftp-master', # for dput
612                'dgit-distro.debian.mirror' => 'http://ftp.debian.org/debian/',
613  'dgit-distro.debian-security.archive-query' => 'aptget:',
614  'dgit-distro.debian-security.mirror' => 'http://security.debian.org/debian-security/',
615  'dgit-distro.debian-security.aptget-suite-map' => 's#-security$#/updates#',
616  'dgit-distro.debian-security.aptget-suite-rmap' => 's#$#-security#',
617  'dgit-distro.debian-security.nominal-distro' => 'debian',
618  'dgit-distro.debian.backports-quirk' => '(squeeze)-backports*',
619  'dgit-distro.debian-backports.mirror' => 'http://backports.debian.org/debian-backports/',
620                'dgit-distro.ubuntu.git-check' => 'false',
621  'dgit-distro.ubuntu.mirror' => 'http://archive.ubuntu.com/ubuntu',
622                'dgit-distro.test-dummy.ssh' => "$td/ssh",
623                'dgit-distro.test-dummy.username' => "alice",
624                'dgit-distro.test-dummy.git-check' => "ssh-cmd",
625                'dgit-distro.test-dummy.git-create' => "ssh-cmd",
626                'dgit-distro.test-dummy.git-url' => "$td/git",
627                'dgit-distro.test-dummy.git-host' => "git",
628                'dgit-distro.test-dummy.git-path' => "$td/git",
629                'dgit-distro.test-dummy.archive-query' => "dummycatapi:",
630                'dgit-distro.test-dummy.archive-query-url' => "file://$td/aq/",
631                'dgit-distro.test-dummy.mirror' => "file://$td/mirror/",
632                'dgit-distro.test-dummy.upload-host' => 'test-dummy',
633                );
634
635 our %gitcfgs;
636 our @gitcfgsources = qw(cmdline local global system);
637
638 sub git_slurp_config () {
639     local ($debuglevel) = $debuglevel-2;
640     local $/="\0";
641
642     # This algoritm is a bit subtle, but this is needed so that for
643     # options which we want to be single-valued, we allow the
644     # different config sources to override properly.  See #835858.
645     foreach my $src (@gitcfgsources) {
646         next if $src eq 'cmdline';
647         # we do this ourselves since git doesn't handle it
648         
649         my @cmd = (@git, qw(config -z --get-regexp), "--$src", qw(.*));
650         debugcmd "|",@cmd;
651
652         open GITS, "-|", @cmd or die $!;
653         while (<GITS>) {
654             chomp or die;
655             printdebug "=> ", (messagequote $_), "\n";
656             m/\n/ or die "$_ ?";
657             push @{ $gitcfgs{$src}{$`} }, $'; #';
658         }
659         $!=0; $?=0;
660         close GITS
661             or ($!==0 && $?==256)
662             or failedcmd @cmd;
663     }
664 }
665
666 sub git_get_config ($) {
667     my ($c) = @_;
668     foreach my $src (@gitcfgsources) {
669         my $l = $gitcfgs{$src}{$c};
670         croak "$l $c" if $l && !ref $l;
671         printdebug"C $c ".(defined $l ?
672                            join " ", map { messagequote "'$_'" } @$l :
673                            "undef")."\n"
674             if $debuglevel >= 4;
675         $l or next;
676         @$l==1 or badcfg "multiple values for $c".
677             " (in $src git config)" if @$l > 1;
678         return $l->[0];
679     }
680     return undef;
681 }
682
683 sub cfg {
684     foreach my $c (@_) {
685         return undef if $c =~ /RETURN-UNDEF/;
686         printdebug "C? $c\n" if $debuglevel >= 5;
687         my $v = git_get_config($c);
688         return $v if defined $v;
689         my $dv = $defcfg{$c};
690         if (defined $dv) {
691             printdebug "CD $c $dv\n" if $debuglevel >= 4;
692             return $dv;
693         }
694     }
695     badcfg "need value for one of: @_\n".
696         "$us: distro or suite appears not to be (properly) supported";
697 }
698
699 sub access_basedistro__noalias () {
700     if (defined $idistro) {
701         return $idistro;
702     } else {    
703         my $def = cfg("dgit-suite.$isuite.distro", 'RETURN-UNDEF');
704         return $def if defined $def;
705         foreach my $src (@gitcfgsources, 'internal') {
706             my $kl = $src eq 'internal' ? \%defcfg : $gitcfgs{$src};
707             next unless $kl;
708             foreach my $k (keys %$kl) {
709                 next unless $k =~ m#^dgit-suite\.(.*)\.distro$#;
710                 my $dpat = $1;
711                 next unless match_glob $dpat, $isuite;
712                 return $kl->{$k};
713             }
714         }
715         return cfg("dgit.default.distro");
716     }
717 }
718
719 sub access_basedistro () {
720     my $noalias = access_basedistro__noalias();
721     my $canon = cfg("dgit-distro.$noalias.alias-canon",'RETURN-UNDEF');
722     return $canon // $noalias;
723 }
724
725 sub access_nomdistro () {
726     my $base = access_basedistro();
727     my $r = cfg("dgit-distro.$base.nominal-distro",'RETURN-UNDEF') // $base;
728     $r =~ m/^$distro_re$/ or badcfg
729  "bad syntax for (nominal) distro \`$r' (does not match /^$distro_re$/)";
730     return $r;
731 }
732
733 sub access_quirk () {
734     # returns (quirk name, distro to use instead or undef, quirk-specific info)
735     my $basedistro = access_basedistro();
736     my $backports_quirk = cfg("dgit-distro.$basedistro.backports-quirk",
737                               'RETURN-UNDEF');
738     if (defined $backports_quirk) {
739         my $re = $backports_quirk;
740         $re =~ s/[^-0-9a-z_\%*()]/\\$&/ig;
741         $re =~ s/\*/.*/g;
742         $re =~ s/\%/([-0-9a-z_]+)/
743             or $re =~ m/[()]/ or badcfg "backports-quirk needs \% or ( )";
744         if ($isuite =~ m/^$re$/) {
745             return ('backports',"$basedistro-backports",$1);
746         }
747     }
748     return ('none',undef);
749 }
750
751 our $access_forpush;
752
753 sub parse_cfg_bool ($$$) {
754     my ($what,$def,$v) = @_;
755     $v //= $def;
756     return
757         $v =~ m/^[ty1]/ ? 1 :
758         $v =~ m/^[fn0]/ ? 0 :
759         badcfg "$what needs t (true, y, 1) or f (false, n, 0) not \`$v'";
760 }       
761
762 sub access_forpush_config () {
763     my $d = access_basedistro();
764
765     return 1 if
766         $new_package &&
767         parse_cfg_bool('new-private-pushers', 0,
768                        cfg("dgit-distro.$d.new-private-pushers",
769                            'RETURN-UNDEF'));
770
771     my $v = cfg("dgit-distro.$d.readonly", 'RETURN-UNDEF');
772     $v //= 'a';
773     return
774         $v =~ m/^[ty1]/ ? 0 : # force readonly,    forpush = 0
775         $v =~ m/^[fn0]/ ? 1 : # force nonreadonly, forpush = 1
776         $v =~ m/^[a]/  ? '' : # auto,              forpush = ''
777         badcfg "readonly needs t (true, y, 1) or f (false, n, 0) or a (auto)";
778 }
779
780 sub access_forpush () {
781     $access_forpush //= access_forpush_config();
782     return $access_forpush;
783 }
784
785 sub pushing () {
786     die "$access_forpush ?" if ($access_forpush // 1) ne 1;
787     badcfg "pushing but distro is configured readonly"
788         if access_forpush_config() eq '0';
789     $access_forpush = 1;
790     $supplementary_message = <<'END' unless $we_are_responder;
791 Push failed, before we got started.
792 You can retry the push, after fixing the problem, if you like.
793 END
794     parseopts_late_defaults();
795 }
796
797 sub notpushing () {
798     parseopts_late_defaults();
799 }
800
801 sub supplementary_message ($) {
802     my ($msg) = @_;
803     if (!$we_are_responder) {
804         $supplementary_message = $msg;
805         return;
806     } elsif ($protovsn >= 3) {
807         responder_send_command "supplementary-message ".length($msg)
808             or die $!;
809         print PO $msg or die $!;
810     }
811 }
812
813 sub access_distros () {
814     # Returns list of distros to try, in order
815     #
816     # We want to try:
817     #    0. `instead of' distro name(s) we have been pointed to
818     #    1. the access_quirk distro, if any
819     #    2a. the user's specified distro, or failing that  } basedistro
820     #    2b. the distro calculated from the suite          }
821     my @l = access_basedistro();
822
823     my (undef,$quirkdistro) = access_quirk();
824     unshift @l, $quirkdistro;
825     unshift @l, $instead_distro;
826     @l = grep { defined } @l;
827
828     push @l, access_nomdistro();
829
830     if (access_forpush()) {
831         @l = map { ("$_/push", $_) } @l;
832     }
833     @l;
834 }
835
836 sub access_cfg_cfgs (@) {
837     my (@keys) = @_;
838     my @cfgs;
839     # The nesting of these loops determines the search order.  We put
840     # the key loop on the outside so that we search all the distros
841     # for each key, before going on to the next key.  That means that
842     # if access_cfg is called with a more specific, and then a less
843     # specific, key, an earlier distro can override the less specific
844     # without necessarily overriding any more specific keys.  (If the
845     # distro wants to override the more specific keys it can simply do
846     # so; whereas if we did the loop the other way around, it would be
847     # impossible to for an earlier distro to override a less specific
848     # key but not the more specific ones without restating the unknown
849     # values of the more specific keys.
850     my @realkeys;
851     my @rundef;
852     # We have to deal with RETURN-UNDEF specially, so that we don't
853     # terminate the search prematurely.
854     foreach (@keys) {
855         if (m/RETURN-UNDEF/) { push @rundef, $_; last; }
856         push @realkeys, $_
857     }
858     foreach my $d (access_distros()) {
859         push @cfgs, map { "dgit-distro.$d.$_" } @realkeys;
860     }
861     push @cfgs, map { "dgit.default.$_" } @realkeys;
862     push @cfgs, @rundef;
863     return @cfgs;
864 }
865
866 sub access_cfg (@) {
867     my (@keys) = @_;
868     my (@cfgs) = access_cfg_cfgs(@keys);
869     my $value = cfg(@cfgs);
870     return $value;
871 }
872
873 sub access_cfg_bool ($$) {
874     my ($def, @keys) = @_;
875     parse_cfg_bool($keys[0], $def, access_cfg(@keys, 'RETURN-UNDEF'));
876 }
877
878 sub string_to_ssh ($) {
879     my ($spec) = @_;
880     if ($spec =~ m/\s/) {
881         return qw(sh -ec), 'exec '.$spec.' "$@"', 'x';
882     } else {
883         return ($spec);
884     }
885 }
886
887 sub access_cfg_ssh () {
888     my $gitssh = access_cfg('ssh', 'RETURN-UNDEF');
889     if (!defined $gitssh) {
890         return @ssh;
891     } else {
892         return string_to_ssh $gitssh;
893     }
894 }
895
896 sub access_runeinfo ($) {
897     my ($info) = @_;
898     return ": dgit ".access_basedistro()." $info ;";
899 }
900
901 sub access_someuserhost ($) {
902     my ($some) = @_;
903     my $user = access_cfg("$some-user-force", 'RETURN-UNDEF');
904     defined($user) && length($user) or
905         $user = access_cfg("$some-user",'username');
906     my $host = access_cfg("$some-host");
907     return length($user) ? "$user\@$host" : $host;
908 }
909
910 sub access_gituserhost () {
911     return access_someuserhost('git');
912 }
913
914 sub access_giturl (;$) {
915     my ($optional) = @_;
916     my $url = access_cfg('git-url','RETURN-UNDEF');
917     my $suffix;
918     if (!length $url) {
919         my $proto = access_cfg('git-proto', 'RETURN-UNDEF');
920         return undef unless defined $proto;
921         $url =
922             $proto.
923             access_gituserhost().
924             access_cfg('git-path');
925     } else {
926         $suffix = access_cfg('git-url-suffix','RETURN-UNDEF');
927     }
928     $suffix //= '.git';
929     return "$url/$package$suffix";
930 }              
931
932 sub parsecontrolfh ($$;$) {
933     my ($fh, $desc, $allowsigned) = @_;
934     our $dpkgcontrolhash_noissigned;
935     my $c;
936     for (;;) {
937         my %opts = ('name' => $desc);
938         $opts{allow_pgp}= $allowsigned || !$dpkgcontrolhash_noissigned;
939         $c = Dpkg::Control::Hash->new(%opts);
940         $c->parse($fh,$desc) or die "parsing of $desc failed";
941         last if $allowsigned;
942         last if $dpkgcontrolhash_noissigned;
943         my $issigned= $c->get_option('is_pgp_signed');
944         if (!defined $issigned) {
945             $dpkgcontrolhash_noissigned= 1;
946             seek $fh, 0,0 or die "seek $desc: $!";
947         } elsif ($issigned) {
948             fail "control file $desc is (already) PGP-signed. ".
949                 " Note that dgit push needs to modify the .dsc and then".
950                 " do the signature itself";
951         } else {
952             last;
953         }
954     }
955     return $c;
956 }
957
958 sub parsecontrol {
959     my ($file, $desc, $allowsigned) = @_;
960     my $fh = new IO::Handle;
961     open $fh, '<', $file or die "$file: $!";
962     my $c = parsecontrolfh($fh,$desc,$allowsigned);
963     $fh->error and die $!;
964     close $fh;
965     return $c;
966 }
967
968 sub getfield ($$) {
969     my ($dctrl,$field) = @_;
970     my $v = $dctrl->{$field};
971     return $v if defined $v;
972     fail "missing field $field in ".$dctrl->get_option('name');
973 }
974
975 sub parsechangelog {
976     my $c = Dpkg::Control::Hash->new(name => 'parsed changelog');
977     my $p = new IO::Handle;
978     my @cmd = (qw(dpkg-parsechangelog), @_);
979     open $p, '-|', @cmd or die $!;
980     $c->parse($p);
981     $?=0; $!=0; close $p or failedcmd @cmd;
982     return $c;
983 }
984
985 sub commit_getclogp ($) {
986     # Returns the parsed changelog hashref for a particular commit
987     my ($objid) = @_;
988     our %commit_getclogp_memo;
989     my $memo = $commit_getclogp_memo{$objid};
990     return $memo if $memo;
991     mkpath '.git/dgit';
992     my $mclog = ".git/dgit/clog-$objid";
993     runcmd shell_cmd "exec >$mclog", @git, qw(cat-file blob),
994         "$objid:debian/changelog";
995     $commit_getclogp_memo{$objid} = parsechangelog("-l$mclog");
996 }
997
998 sub must_getcwd () {
999     my $d = getcwd();
1000     defined $d or fail "getcwd failed: $!";
1001     return $d;
1002 }
1003
1004 sub parse_dscdata () {
1005     my $dscfh = new IO::File \$dscdata, '<' or die $!;
1006     printdebug Dumper($dscdata) if $debuglevel>1;
1007     $dsc = parsecontrolfh($dscfh,$dscurl,1);
1008     printdebug Dumper($dsc) if $debuglevel>1;
1009 }
1010
1011 our %rmad;
1012
1013 sub archive_query ($;@) {
1014     my ($method) = shift @_;
1015     fail "this operation does not support multiple comma-separated suites"
1016         if $isuite =~ m/,/;
1017     my $query = access_cfg('archive-query','RETURN-UNDEF');
1018     $query =~ s/^(\w+):// or badcfg "invalid archive-query method \`$query'";
1019     my $proto = $1;
1020     my $data = $'; #';
1021     { no strict qw(refs); &{"${method}_${proto}"}($proto,$data,@_); }
1022 }
1023
1024 sub archive_query_prepend_mirror {
1025     my $m = access_cfg('mirror');
1026     return map { [ $_->[0], $m.$_->[1], @$_[2..$#$_] ] } @_;
1027 }
1028
1029 sub pool_dsc_subpath ($$) {
1030     my ($vsn,$component) = @_; # $package is implict arg
1031     my $prefix = substr($package, 0, $package =~ m/^l/ ? 4 : 1);
1032     return "/pool/$component/$prefix/$package/".dscfn($vsn);
1033 }
1034
1035 sub cfg_apply_map ($$$) {
1036     my ($varref, $what, $mapspec) = @_;
1037     return unless $mapspec;
1038
1039     printdebug "config $what EVAL{ $mapspec; }\n";
1040     $_ = $$varref;
1041     eval "package Dgit::Config; $mapspec;";
1042     die $@ if $@;
1043     $$varref = $_;
1044 }
1045
1046 #---------- `ftpmasterapi' archive query method (nascent) ----------
1047
1048 sub archive_api_query_cmd ($) {
1049     my ($subpath) = @_;
1050     my @cmd = (@curl, qw(-sS));
1051     my $url = access_cfg('archive-query-url');
1052     if ($url =~ m#^https://([-.0-9a-z]+)/#) {
1053         my $host = $1;
1054         my $keys = access_cfg('archive-query-tls-key','RETURN-UNDEF') //'';
1055         foreach my $key (split /\:/, $keys) {
1056             $key =~ s/\%HOST\%/$host/g;
1057             if (!stat $key) {
1058                 fail "for $url: stat $key: $!" unless $!==ENOENT;
1059                 next;
1060             }
1061             fail "config requested specific TLS key but do not know".
1062                 " how to get curl to use exactly that EE key ($key)";
1063 #           push @cmd, "--cacert", $key, "--capath", "/dev/enoent";
1064 #           # Sadly the above line does not work because of changes
1065 #           # to gnutls.   The real fix for #790093 may involve
1066 #           # new curl options.
1067             last;
1068         }
1069         # Fixing #790093 properly will involve providing a value
1070         # for this on clients.
1071         my $kargs = access_cfg('archive-query-tls-curl-ca-args','RETURN-UNDEF');
1072         push @cmd, split / /, $kargs if defined $kargs;
1073     }
1074     push @cmd, $url.$subpath;
1075     return @cmd;
1076 }
1077
1078 sub api_query ($$;$) {
1079     use JSON;
1080     my ($data, $subpath, $ok404) = @_;
1081     badcfg "ftpmasterapi archive query method takes no data part"
1082         if length $data;
1083     my @cmd = archive_api_query_cmd($subpath);
1084     my $url = $cmd[$#cmd];
1085     push @cmd, qw(-w %{http_code});
1086     my $json = cmdoutput @cmd;
1087     unless ($json =~ s/\d+\d+\d$//) {
1088         failedcmd_report_cmd undef, @cmd;
1089         fail "curl failed to print 3-digit HTTP code";
1090     }
1091     my $code = $&;
1092     return undef if $code eq '404' && $ok404;
1093     fail "fetch of $url gave HTTP code $code"
1094         unless $url =~ m#^file://# or $code =~ m/^2/;
1095     return decode_json($json);
1096 }
1097
1098 sub canonicalise_suite_ftpmasterapi {
1099     my ($proto,$data) = @_;
1100     my $suites = api_query($data, 'suites');
1101     my @matched;
1102     foreach my $entry (@$suites) {
1103         next unless grep { 
1104             my $v = $entry->{$_};
1105             defined $v && $v eq $isuite;
1106         } qw(codename name);
1107         push @matched, $entry;
1108     }
1109     fail "unknown suite $isuite" unless @matched;
1110     my $cn;
1111     eval {
1112         @matched==1 or die "multiple matches for suite $isuite\n";
1113         $cn = "$matched[0]{codename}";
1114         defined $cn or die "suite $isuite info has no codename\n";
1115         $cn =~ m/^$suite_re$/ or die "suite $isuite maps to bad codename\n";
1116     };
1117     die "bad ftpmaster api response: $@\n".Dumper(\@matched)
1118         if length $@;
1119     return $cn;
1120 }
1121
1122 sub archive_query_ftpmasterapi {
1123     my ($proto,$data) = @_;
1124     my $info = api_query($data, "dsc_in_suite/$isuite/$package");
1125     my @rows;
1126     my $digester = Digest::SHA->new(256);
1127     foreach my $entry (@$info) {
1128         eval {
1129             my $vsn = "$entry->{version}";
1130             my ($ok,$msg) = version_check $vsn;
1131             die "bad version: $msg\n" unless $ok;
1132             my $component = "$entry->{component}";
1133             $component =~ m/^$component_re$/ or die "bad component";
1134             my $filename = "$entry->{filename}";
1135             $filename && $filename !~ m#[^-+:._~0-9a-zA-Z/]|^[/.]|/[/.]#
1136                 or die "bad filename";
1137             my $sha256sum = "$entry->{sha256sum}";
1138             $sha256sum =~ m/^[0-9a-f]+$/ or die "bad sha256sum";
1139             push @rows, [ $vsn, "/pool/$component/$filename",
1140                           $digester, $sha256sum ];
1141         };
1142         die "bad ftpmaster api response: $@\n".Dumper($entry)
1143             if length $@;
1144     }
1145     @rows = sort { -version_compare($a->[0],$b->[0]) } @rows;
1146     return archive_query_prepend_mirror @rows;
1147 }
1148
1149 sub file_in_archive_ftpmasterapi {
1150     my ($proto,$data,$filename) = @_;
1151     my $pat = $filename;
1152     $pat =~ s/_/\\_/g;
1153     $pat = "%/$pat";
1154     $pat =~ s#[^-+_.0-9a-z/]# sprintf '%%%02x', ord $& #ge;
1155     my $info = api_query($data, "file_in_archive/$pat", 1);
1156 }
1157
1158 #---------- `aptget' archive query method ----------
1159
1160 our $aptget_base;
1161 our $aptget_releasefile;
1162 our $aptget_configpath;
1163
1164 sub aptget_aptget   () { return @aptget,   qw(-c), $aptget_configpath; }
1165 sub aptget_aptcache () { return @aptcache, qw(-c), $aptget_configpath; }
1166
1167 sub aptget_cache_clean {
1168     runcmd_ordryrun_local qw(sh -ec),
1169         'cd "$1"; find -atime +30 -type f -print0 | xargs -0r rm --',
1170         'x', $aptget_base;
1171 }
1172
1173 sub aptget_lock_acquire () {
1174     my $lockfile = "$aptget_base/lock";
1175     open APTGET_LOCK, '>', $lockfile or die "open $lockfile: $!";
1176     flock APTGET_LOCK, LOCK_EX or die "lock $lockfile: $!";
1177 }
1178
1179 sub aptget_prep ($) {
1180     my ($data) = @_;
1181     return if defined $aptget_base;
1182
1183     badcfg "aptget archive query method takes no data part"
1184         if length $data;
1185
1186     my $cache = $ENV{XDG_CACHE_DIR} // "$ENV{HOME}/.cache";
1187
1188     ensuredir $cache;
1189     ensuredir "$cache/dgit";
1190     my $cachekey =
1191         access_cfg('aptget-cachekey','RETURN-UNDEF')
1192         // access_nomdistro();
1193
1194     $aptget_base = "$cache/dgit/aptget";
1195     ensuredir $aptget_base;
1196
1197     my $quoted_base = $aptget_base;
1198     die "$quoted_base contains bad chars, cannot continue"
1199         if $quoted_base =~ m/["\\]/; # apt.conf(5) says no escaping :-/
1200
1201     ensuredir $aptget_base;
1202
1203     aptget_lock_acquire();
1204
1205     aptget_cache_clean();
1206
1207     $aptget_configpath = "$aptget_base/apt.conf#$cachekey";
1208     my $sourceslist = "source.list#$cachekey";
1209
1210     my $aptsuites = $isuite;
1211     cfg_apply_map(\$aptsuites, 'suite map',
1212                   access_cfg('aptget-suite-map', 'RETURN-UNDEF'));
1213
1214     open SRCS, ">", "$aptget_base/$sourceslist" or die $!;
1215     printf SRCS "deb-src %s %s %s\n",
1216         access_cfg('mirror'),
1217         $aptsuites,
1218         access_cfg('aptget-components')
1219         or die $!;
1220
1221     ensuredir "$aptget_base/cache";
1222     ensuredir "$aptget_base/lists";
1223
1224     open CONF, ">", $aptget_configpath or die $!;
1225     print CONF <<END;
1226 Debug::NoLocking "true";
1227 APT::Get::List-Cleanup "false";
1228 #clear APT::Update::Post-Invoke-Success;
1229 Dir::Etc::SourceList "$quoted_base/$sourceslist";
1230 Dir::State::Lists "$quoted_base/lists";
1231 Dir::Etc::preferences "$quoted_base/preferences";
1232 Dir::Cache::srcpkgcache "$quoted_base/cache/srcs#$cachekey";
1233 Dir::Cache::pkgcache "$quoted_base/cache/pkgs#$cachekey";
1234 END
1235
1236     foreach my $key (qw(
1237                         Dir::Cache
1238                         Dir::State
1239                         Dir::Cache::Archives
1240                         Dir::Etc::SourceParts
1241                         Dir::Etc::preferencesparts
1242                       )) {
1243         ensuredir "$aptget_base/$key";
1244         print CONF "$key \"$quoted_base/$key\";\n" or die $!;
1245     };
1246
1247     my $oldatime = (time // die $!) - 1;
1248     foreach my $oldlist (<$aptget_base/lists/*Release>) {
1249         next unless stat_exists $oldlist;
1250         my ($mtime) = (stat _)[9];
1251         utime $oldatime, $mtime, $oldlist or die "$oldlist $!";
1252     }
1253
1254     runcmd_ordryrun_local aptget_aptget(), qw(update);
1255
1256     my @releasefiles;
1257     foreach my $oldlist (<$aptget_base/lists/*Release>) {
1258         next unless stat_exists $oldlist;
1259         my ($atime) = (stat _)[8];
1260         next if $atime == $oldatime;
1261         push @releasefiles, $oldlist;
1262     }
1263     my @inreleasefiles = grep { m#/InRelease$# } @releasefiles;
1264     @releasefiles = @inreleasefiles if @inreleasefiles;
1265     die "apt updated wrong number of Release files (@releasefiles), erk"
1266         unless @releasefiles == 1;
1267
1268     ($aptget_releasefile) = @releasefiles;
1269 }
1270
1271 sub canonicalise_suite_aptget {
1272     my ($proto,$data) = @_;
1273     aptget_prep($data);
1274
1275     my $release = parsecontrol $aptget_releasefile, "Release file", 1;
1276
1277     foreach my $name (qw(Codename Suite)) {
1278         my $val = $release->{$name};
1279         if (defined $val) {
1280             printdebug "release file $name: $val\n";
1281             $val =~ m/^$suite_re$/o or fail
1282  "Release file ($aptget_releasefile) specifies intolerable $name";
1283             cfg_apply_map(\$val, 'suite rmap',
1284                           access_cfg('aptget-suite-rmap', 'RETURN-UNDEF'));
1285             return $val
1286         }
1287     }
1288     return $isuite;
1289 }
1290
1291 sub archive_query_aptget {
1292     my ($proto,$data) = @_;
1293     aptget_prep($data);
1294
1295     ensuredir "$aptget_base/source";
1296     foreach my $old (<$aptget_base/source/*.dsc>) {
1297         unlink $old or die "$old: $!";
1298     }
1299
1300     my $showsrc = cmdoutput aptget_aptcache(), qw(showsrc), $package;
1301     return () unless $showsrc =~ m/^package:\s*\Q$package\E\s*$/mi;
1302     # avoids apt-get source failing with ambiguous error code
1303
1304     runcmd_ordryrun_local
1305         shell_cmd 'cd "$1"/source; shift', $aptget_base,
1306         aptget_aptget(), qw(--download-only --only-source source), $package;
1307
1308     my @dscs = <$aptget_base/source/*.dsc>;
1309     fail "apt-get source did not produce a .dsc" unless @dscs;
1310     fail "apt-get source produced several .dscs (@dscs)" unless @dscs==1;
1311
1312     my $pre_dsc = parsecontrol $dscs[0], $dscs[0], 1;
1313
1314     use URI::Escape;
1315     my $uri = "file://". uri_escape $dscs[0];
1316     $uri =~ s{\%2f}{/}gi;
1317     return [ (getfield $pre_dsc, 'Version'), $uri ];
1318 }
1319
1320 #---------- `dummyapicat' archive query method ----------
1321
1322 sub archive_query_dummycatapi { archive_query_ftpmasterapi @_; }
1323 sub canonicalise_suite_dummycatapi { canonicalise_suite_ftpmasterapi @_; }
1324
1325 sub file_in_archive_dummycatapi ($$$) {
1326     my ($proto,$data,$filename) = @_;
1327     my $mirror = access_cfg('mirror');
1328     $mirror =~ s#^file://#/# or die "$mirror ?";
1329     my @out;
1330     my @cmd = (qw(sh -ec), '
1331             cd "$1"
1332             find -name "$2" -print0 |
1333             xargs -0r sha256sum
1334         ', qw(x), $mirror, $filename);
1335     debugcmd "-|", @cmd;
1336     open FIA, "-|", @cmd or die $!;
1337     while (<FIA>) {
1338         chomp or die;
1339         printdebug "| $_\n";
1340         m/^(\w+)  (\S+)$/ or die "$_ ?";
1341         push @out, { sha256sum => $1, filename => $2 };
1342     }
1343     close FIA or die failedcmd @cmd;
1344     return \@out;
1345 }
1346
1347 #---------- `madison' archive query method ----------
1348
1349 sub archive_query_madison {
1350     return archive_query_prepend_mirror
1351         map { [ @$_[0..1] ] } madison_get_parse(@_);
1352 }
1353
1354 sub madison_get_parse {
1355     my ($proto,$data) = @_;
1356     die unless $proto eq 'madison';
1357     if (!length $data) {
1358         $data= access_cfg('madison-distro','RETURN-UNDEF');
1359         $data //= access_basedistro();
1360     }
1361     $rmad{$proto,$data,$package} ||= cmdoutput
1362         qw(rmadison -asource),"-s$isuite","-u$data",$package;
1363     my $rmad = $rmad{$proto,$data,$package};
1364
1365     my @out;
1366     foreach my $l (split /\n/, $rmad) {
1367         $l =~ m{^ \s*( [^ \t|]+ )\s* \|
1368                   \s*( [^ \t|]+ )\s* \|
1369                   \s*( [^ \t|/]+ )(?:/([^ \t|/]+))? \s* \|
1370                   \s*( [^ \t|]+ )\s* }x or die "$rmad ?";
1371         $1 eq $package or die "$rmad $package ?";
1372         my $vsn = $2;
1373         my $newsuite = $3;
1374         my $component;
1375         if (defined $4) {
1376             $component = $4;
1377         } else {
1378             $component = access_cfg('archive-query-default-component');
1379         }
1380         $5 eq 'source' or die "$rmad ?";
1381         push @out, [$vsn,pool_dsc_subpath($vsn,$component),$newsuite];
1382     }
1383     return sort { -version_compare($a->[0],$b->[0]); } @out;
1384 }
1385
1386 sub canonicalise_suite_madison {
1387     # madison canonicalises for us
1388     my @r = madison_get_parse(@_);
1389     @r or fail
1390         "unable to canonicalise suite using package $package".
1391         " which does not appear to exist in suite $isuite;".
1392         " --existing-package may help";
1393     return $r[0][2];
1394 }
1395
1396 sub file_in_archive_madison { return undef; }
1397
1398 #---------- `sshpsql' archive query method ----------
1399
1400 sub sshpsql ($$$) {
1401     my ($data,$runeinfo,$sql) = @_;
1402     if (!length $data) {
1403         $data= access_someuserhost('sshpsql').':'.
1404             access_cfg('sshpsql-dbname');
1405     }
1406     $data =~ m/:/ or badcfg "invalid sshpsql method string \`$data'";
1407     my ($userhost,$dbname) = ($`,$'); #';
1408     my @rows;
1409     my @cmd = (access_cfg_ssh, $userhost,
1410                access_runeinfo("ssh-psql $runeinfo").
1411                " export LC_MESSAGES=C; export LC_CTYPE=C;".
1412                " ".shellquote qw(psql -A), $dbname, qw(-c), $sql);
1413     debugcmd "|",@cmd;
1414     open P, "-|", @cmd or die $!;
1415     while (<P>) {
1416         chomp or die;
1417         printdebug(">|$_|\n");
1418         push @rows, $_;
1419     }
1420     $!=0; $?=0; close P or failedcmd @cmd;
1421     @rows or die;
1422     my $nrows = pop @rows;
1423     $nrows =~ s/^\((\d+) rows?\)$/$1/ or die "$nrows ?";
1424     @rows == $nrows+1 or die "$nrows ".(scalar @rows)." ?";
1425     @rows = map { [ split /\|/, $_ ] } @rows;
1426     my $ncols = scalar @{ shift @rows };
1427     die if grep { scalar @$_ != $ncols } @rows;
1428     return @rows;
1429 }
1430
1431 sub sql_injection_check {
1432     foreach (@_) { die "$_ $& ?" if m{[^-+=:_.,/0-9a-zA-Z]}; }
1433 }
1434
1435 sub archive_query_sshpsql ($$) {
1436     my ($proto,$data) = @_;
1437     sql_injection_check $isuite, $package;
1438     my @rows = sshpsql($data, "archive-query $isuite $package", <<END);
1439         SELECT source.version, component.name, files.filename, files.sha256sum
1440           FROM source
1441           JOIN src_associations ON source.id = src_associations.source
1442           JOIN suite ON suite.id = src_associations.suite
1443           JOIN dsc_files ON dsc_files.source = source.id
1444           JOIN files_archive_map ON files_archive_map.file_id = dsc_files.file
1445           JOIN component ON component.id = files_archive_map.component_id
1446           JOIN files ON files.id = dsc_files.file
1447          WHERE ( suite.suite_name='$isuite' OR suite.codename='$isuite' )
1448            AND source.source='$package'
1449            AND files.filename LIKE '%.dsc';
1450 END
1451     @rows = sort { -version_compare($a->[0],$b->[0]) } @rows;
1452     my $digester = Digest::SHA->new(256);
1453     @rows = map {
1454         my ($vsn,$component,$filename,$sha256sum) = @$_;
1455         [ $vsn, "/pool/$component/$filename",$digester,$sha256sum ];
1456     } @rows;
1457     return archive_query_prepend_mirror @rows;
1458 }
1459
1460 sub canonicalise_suite_sshpsql ($$) {
1461     my ($proto,$data) = @_;
1462     sql_injection_check $isuite;
1463     my @rows = sshpsql($data, "canonicalise-suite $isuite", <<END);
1464         SELECT suite.codename
1465           FROM suite where suite_name='$isuite' or codename='$isuite';
1466 END
1467     @rows = map { $_->[0] } @rows;
1468     fail "unknown suite $isuite" unless @rows;
1469     die "ambiguous $isuite: @rows ?" if @rows>1;
1470     return $rows[0];
1471 }
1472
1473 sub file_in_archive_sshpsql ($$$) { return undef; }
1474
1475 #---------- `dummycat' archive query method ----------
1476
1477 sub canonicalise_suite_dummycat ($$) {
1478     my ($proto,$data) = @_;
1479     my $dpath = "$data/suite.$isuite";
1480     if (!open C, "<", $dpath) {
1481         $!==ENOENT or die "$dpath: $!";
1482         printdebug "dummycat canonicalise_suite $isuite $dpath ENOENT\n";
1483         return $isuite;
1484     }
1485     $!=0; $_ = <C>;
1486     chomp or die "$dpath: $!";
1487     close C;
1488     printdebug "dummycat canonicalise_suite $isuite $dpath = $_\n";
1489     return $_;
1490 }
1491
1492 sub archive_query_dummycat ($$) {
1493     my ($proto,$data) = @_;
1494     canonicalise_suite();
1495     my $dpath = "$data/package.$csuite.$package";
1496     if (!open C, "<", $dpath) {
1497         $!==ENOENT or die "$dpath: $!";
1498         printdebug "dummycat query $csuite $package $dpath ENOENT\n";
1499         return ();
1500     }
1501     my @rows;
1502     while (<C>) {
1503         next if m/^\#/;
1504         next unless m/\S/;
1505         die unless chomp;
1506         printdebug "dummycat query $csuite $package $dpath | $_\n";
1507         my @row = split /\s+/, $_;
1508         @row==2 or die "$dpath: $_ ?";
1509         push @rows, \@row;
1510     }
1511     C->error and die "$dpath: $!";
1512     close C;
1513     return archive_query_prepend_mirror
1514         sort { -version_compare($a->[0],$b->[0]); } @rows;
1515 }
1516
1517 sub file_in_archive_dummycat () { return undef; }
1518
1519 #---------- tag format handling ----------
1520
1521 sub access_cfg_tagformats () {
1522     split /\,/, access_cfg('dgit-tag-format');
1523 }
1524
1525 sub access_cfg_tagformats_can_splitbrain () {
1526     my %y = map { $_ => 1 } access_cfg_tagformats;
1527     foreach my $needtf (qw(new maint)) {
1528         next if $y{$needtf};
1529         return 0;
1530     }
1531     return 1;
1532 }
1533
1534 sub need_tagformat ($$) {
1535     my ($fmt, $why) = @_;
1536     fail "need to use tag format $fmt ($why) but also need".
1537         " to use tag format $tagformat_want->[0] ($tagformat_want->[1])".
1538         " - no way to proceed"
1539         if $tagformat_want && $tagformat_want->[0] ne $fmt;
1540     $tagformat_want = [$fmt, $why, $tagformat_want->[2] // 0];
1541 }
1542
1543 sub select_tagformat () {
1544     # sets $tagformatfn
1545     return if $tagformatfn && !$tagformat_want;
1546     die 'bug' if $tagformatfn && $tagformat_want;
1547     # ... $tagformat_want assigned after previous select_tagformat
1548
1549     my (@supported) = grep { $_ =~ m/^(?:old|new)$/ } access_cfg_tagformats();
1550     printdebug "select_tagformat supported @supported\n";
1551
1552     $tagformat_want //= [ $supported[0], "distro access configuration", 0 ];
1553     printdebug "select_tagformat specified @$tagformat_want\n";
1554
1555     my ($fmt,$why,$override) = @$tagformat_want;
1556
1557     fail "target distro supports tag formats @supported".
1558         " but have to use $fmt ($why)"
1559         unless $override
1560             or grep { $_ eq $fmt } @supported;
1561
1562     $tagformat_want = undef;
1563     $tagformat = $fmt;
1564     $tagformatfn = ${*::}{"debiantag_$fmt"};
1565
1566     fail "trying to use unknown tag format \`$fmt' ($why) !"
1567         unless $tagformatfn;
1568 }
1569
1570 #---------- archive query entrypoints and rest of program ----------
1571
1572 sub canonicalise_suite () {
1573     return if defined $csuite;
1574     fail "cannot operate on $isuite suite" if $isuite eq 'UNRELEASED';
1575     $csuite = archive_query('canonicalise_suite');
1576     if ($isuite ne $csuite) {
1577         progress "canonical suite name for $isuite is $csuite";
1578     } else {
1579         progress "canonical suite name is $csuite";
1580     }
1581 }
1582
1583 sub get_archive_dsc () {
1584     canonicalise_suite();
1585     my @vsns = archive_query('archive_query');
1586     foreach my $vinfo (@vsns) {
1587         my ($vsn,$vsn_dscurl,$digester,$digest) = @$vinfo;
1588         $dscurl = $vsn_dscurl;
1589         $dscdata = url_get($dscurl);
1590         if (!$dscdata) {
1591             $skew_warning_vsn = $vsn if !defined $skew_warning_vsn;
1592             next;
1593         }
1594         if ($digester) {
1595             $digester->reset();
1596             $digester->add($dscdata);
1597             my $got = $digester->hexdigest();
1598             $got eq $digest or
1599                 fail "$dscurl has hash $got but".
1600                     " archive told us to expect $digest";
1601         }
1602         parse_dscdata();
1603         my $fmt = getfield $dsc, 'Format';
1604         $format_ok{$fmt} or forceable_fail [qw(unsupported-source-format)],
1605             "unsupported source format $fmt, sorry";
1606             
1607         $dsc_checked = !!$digester;
1608         printdebug "get_archive_dsc: Version ".(getfield $dsc, 'Version')."\n";
1609         return;
1610     }
1611     $dsc = undef;
1612     printdebug "get_archive_dsc: nothing in archive, returning undef\n";
1613 }
1614
1615 sub check_for_git ();
1616 sub check_for_git () {
1617     # returns 0 or 1
1618     my $how = access_cfg('git-check');
1619     if ($how eq 'ssh-cmd') {
1620         my @cmd =
1621             (access_cfg_ssh, access_gituserhost(),
1622              access_runeinfo("git-check $package").
1623              " set -e; cd ".access_cfg('git-path').";".
1624              " if test -d $package.git; then echo 1; else echo 0; fi");
1625         my $r= cmdoutput @cmd;
1626         if (defined $r and $r =~ m/^divert (\w+)$/) {
1627             my $divert=$1;
1628             my ($usedistro,) = access_distros();
1629             # NB that if we are pushing, $usedistro will be $distro/push
1630             $instead_distro= cfg("dgit-distro.$usedistro.diverts.$divert");
1631             $instead_distro =~ s{^/}{ access_basedistro()."/" }e;
1632             progress "diverting to $divert (using config for $instead_distro)";
1633             return check_for_git();
1634         }
1635         failedcmd @cmd unless defined $r and $r =~ m/^[01]$/;
1636         return $r+0;
1637     } elsif ($how eq 'url') {
1638         my $prefix = access_cfg('git-check-url','git-url');
1639         my $suffix = access_cfg('git-check-suffix','git-suffix',
1640                                 'RETURN-UNDEF') // '.git';
1641         my $url = "$prefix/$package$suffix";
1642         my @cmd = (@curl, qw(-sS -I), $url);
1643         my $result = cmdoutput @cmd;
1644         $result =~ s/^\S+ 200 .*\n\r?\n//;
1645         # curl -sS -I with https_proxy prints
1646         # HTTP/1.0 200 Connection established
1647         $result =~ m/^\S+ (404|200) /s or
1648             fail "unexpected results from git check query - ".
1649                 Dumper($prefix, $result);
1650         my $code = $1;
1651         if ($code eq '404') {
1652             return 0;
1653         } elsif ($code eq '200') {
1654             return 1;
1655         } else {
1656             die;
1657         }
1658     } elsif ($how eq 'true') {
1659         return 1;
1660     } elsif ($how eq 'false') {
1661         return 0;
1662     } else {
1663         badcfg "unknown git-check \`$how'";
1664     }
1665 }
1666
1667 sub create_remote_git_repo () {
1668     my $how = access_cfg('git-create');
1669     if ($how eq 'ssh-cmd') {
1670         runcmd_ordryrun
1671             (access_cfg_ssh, access_gituserhost(),
1672              access_runeinfo("git-create $package").
1673              "set -e; cd ".access_cfg('git-path').";".
1674              " cp -a _template $package.git");
1675     } elsif ($how eq 'true') {
1676         # nothing to do
1677     } else {
1678         badcfg "unknown git-create \`$how'";
1679     }
1680 }
1681
1682 our ($dsc_hash,$lastpush_mergeinput);
1683 our ($dsc_distro, $dsc_hint_tag, $dsc_hint_url);
1684
1685 our $ud = '.git/dgit/unpack';
1686
1687 sub prep_ud (;$) {
1688     my ($d) = @_;
1689     $d //= $ud;
1690     rmtree($d);
1691     mkpath '.git/dgit';
1692     mkdir $d or die $!;
1693 }
1694
1695 sub mktree_in_ud_here () {
1696     runcmd qw(git init -q);
1697     runcmd qw(git config gc.auto 0);
1698     rmtree('.git/objects');
1699     symlink '../../../../objects','.git/objects' or die $!;
1700 }
1701
1702 sub git_write_tree () {
1703     my $tree = cmdoutput @git, qw(write-tree);
1704     $tree =~ m/^\w+$/ or die "$tree ?";
1705     return $tree;
1706 }
1707
1708 sub git_add_write_tree () {
1709     runcmd @git, qw(add -Af .);
1710     return git_write_tree();
1711 }
1712
1713 sub remove_stray_gits ($) {
1714     my ($what) = @_;
1715     my @gitscmd = qw(find -name .git -prune -print0);
1716     debugcmd "|",@gitscmd;
1717     open GITS, "-|", @gitscmd or die $!;
1718     {
1719         local $/="\0";
1720         while (<GITS>) {
1721             chomp or die;
1722             print STDERR "$us: warning: removing from $what: ",
1723                 (messagequote $_), "\n";
1724             rmtree $_;
1725         }
1726     }
1727     $!=0; $?=0; close GITS or failedcmd @gitscmd;
1728 }
1729
1730 sub mktree_in_ud_from_only_subdir ($;$) {
1731     my ($what,$raw) = @_;
1732
1733     # changes into the subdir
1734     my (@dirs) = <*/.>;
1735     die "expected one subdir but found @dirs ?" unless @dirs==1;
1736     $dirs[0] =~ m#^([^/]+)/\.$# or die;
1737     my $dir = $1;
1738     changedir $dir;
1739
1740     remove_stray_gits($what);
1741     mktree_in_ud_here();
1742     if (!$raw) {
1743         my ($format, $fopts) = get_source_format();
1744         if (madformat($format)) {
1745             rmtree '.pc';
1746         }
1747     }
1748
1749     my $tree=git_add_write_tree();
1750     return ($tree,$dir);
1751 }
1752
1753 our @files_csum_info_fields = 
1754     (['Checksums-Sha256','Digest::SHA', 'new(256)', 'sha256sum'],
1755      ['Checksums-Sha1',  'Digest::SHA', 'new(1)',   'sha1sum'],
1756      ['Files',           'Digest::MD5', 'new()',    'md5sum']);
1757
1758 sub dsc_files_info () {
1759     foreach my $csumi (@files_csum_info_fields) {
1760         my ($fname, $module, $method) = @$csumi;
1761         my $field = $dsc->{$fname};
1762         next unless defined $field;
1763         eval "use $module; 1;" or die $@;
1764         my @out;
1765         foreach (split /\n/, $field) {
1766             next unless m/\S/;
1767             m/^(\w+) (\d+) (\S+)$/ or
1768                 fail "could not parse .dsc $fname line \`$_'";
1769             my $digester = eval "$module"."->$method;" or die $@;
1770             push @out, {
1771                 Hash => $1,
1772                 Bytes => $2,
1773                 Filename => $3,
1774                 Digester => $digester,
1775             };
1776         }
1777         return @out;
1778     }
1779     fail "missing any supported Checksums-* or Files field in ".
1780         $dsc->get_option('name');
1781 }
1782
1783 sub dsc_files () {
1784     map { $_->{Filename} } dsc_files_info();
1785 }
1786
1787 sub files_compare_inputs (@) {
1788     my $inputs = \@_;
1789     my %record;
1790     my %fchecked;
1791
1792     my $showinputs = sub {
1793         return join "; ", map { $_->get_option('name') } @$inputs;
1794     };
1795
1796     foreach my $in (@$inputs) {
1797         my $expected_files;
1798         my $in_name = $in->get_option('name');
1799
1800         printdebug "files_compare_inputs $in_name\n";
1801
1802         foreach my $csumi (@files_csum_info_fields) {
1803             my ($fname) = @$csumi;
1804             printdebug "files_compare_inputs $in_name $fname\n";
1805
1806             my $field = $in->{$fname};
1807             next unless defined $field;
1808
1809             my @files;
1810             foreach (split /\n/, $field) {
1811                 next unless m/\S/;
1812
1813                 my ($info, $f) = m/^(\w+ \d+) (?:\S+ \S+ )?(\S+)$/ or
1814                     fail "could not parse $in_name $fname line \`$_'";
1815
1816                 printdebug "files_compare_inputs $in_name $fname $f\n";
1817
1818                 push @files, $f;
1819
1820                 my $re = \ $record{$f}{$fname};
1821                 if (defined $$re) {
1822                     $fchecked{$f}{$in_name} = 1;
1823                     $$re eq $info or
1824                         fail "hash or size of $f varies in $fname fields".
1825                         " (between: ".$showinputs->().")";
1826                 } else {
1827                     $$re = $info;
1828                 }
1829             }
1830             @files = sort @files;
1831             $expected_files //= \@files;
1832             "@$expected_files" eq "@files" or
1833                 fail "file list in $in_name varies between hash fields!";
1834         }
1835         $expected_files or
1836             fail "$in_name has no files list field(s)";
1837     }
1838     printdebug "files_compare_inputs ".Dumper(\%fchecked, \%record)
1839         if $debuglevel>=2;
1840
1841     grep { keys %$_ == @$inputs-1 } values %fchecked
1842         or fail "no file appears in all file lists".
1843         " (looked in: ".$showinputs->().")";
1844 }
1845
1846 sub is_orig_file_in_dsc ($$) {
1847     my ($f, $dsc_files_info) = @_;
1848     return 0 if @$dsc_files_info <= 1;
1849     # One file means no origs, and the filename doesn't have a "what
1850     # part of dsc" component.  (Consider versions ending `.orig'.)
1851     return 0 unless $f =~ m/\.$orig_f_tail_re$/o;
1852     return 1;
1853 }
1854
1855 sub is_orig_file_of_vsn ($$) {
1856     my ($f, $upstreamvsn) = @_;
1857     my $base = srcfn $upstreamvsn, '';
1858     return 0 unless $f =~ m/^\Q$base\E\.$orig_f_tail_re$/;
1859     return 1;
1860 }
1861
1862 sub changes_update_origs_from_dsc ($$$$) {
1863     my ($dsc, $changes, $upstreamvsn, $changesfile) = @_;
1864     my %changes_f;
1865     printdebug "checking origs needed ($upstreamvsn)...\n";
1866     $_ = getfield $changes, 'Files';
1867     m/^\w+ \d+ (\S+ \S+) \S+$/m or
1868         fail "cannot find section/priority from .changes Files field";
1869     my $placementinfo = $1;
1870     my %changed;
1871     printdebug "checking origs needed placement '$placementinfo'...\n";
1872     foreach my $l (split /\n/, getfield $dsc, 'Files') {
1873         $l =~ m/\S+$/ or next;
1874         my $file = $&;
1875         printdebug "origs $file | $l\n";
1876         next unless is_orig_file_of_vsn $file, $upstreamvsn;
1877         printdebug "origs $file is_orig\n";
1878         my $have = archive_query('file_in_archive', $file);
1879         if (!defined $have) {
1880             print STDERR <<END;
1881 archive does not support .orig check; hope you used --ch:--sa/-sd if needed
1882 END
1883             return;
1884         }
1885         my $found_same = 0;
1886         my @found_differ;
1887         printdebug "origs $file \$#\$have=$#$have\n";
1888         foreach my $h (@$have) {
1889             my $same = 0;
1890             my @differ;
1891             foreach my $csumi (@files_csum_info_fields) {
1892                 my ($fname, $module, $method, $archivefield) = @$csumi;
1893                 next unless defined $h->{$archivefield};
1894                 $_ = $dsc->{$fname};
1895                 next unless defined;
1896                 m/^(\w+) .* \Q$file\E$/m or
1897                     fail ".dsc $fname missing entry for $file";
1898                 if ($h->{$archivefield} eq $1) {
1899                     $same++;
1900                 } else {
1901                     push @differ,
1902  "$archivefield: $h->{$archivefield} (archive) != $1 (local .dsc)";
1903                 }
1904             }
1905             die "$file ".Dumper($h)." ?!" if $same && @differ;
1906             $found_same++
1907                 if $same;
1908             push @found_differ, "archive $h->{filename}: ".join "; ", @differ
1909                 if @differ;
1910         }
1911         printdebug "origs $file f.same=$found_same".
1912             " #f._differ=$#found_differ\n";
1913         if (@found_differ && !$found_same) {
1914             fail join "\n",
1915                 "archive contains $file with different checksum",
1916                 @found_differ;
1917         }
1918         # Now we edit the changes file to add or remove it
1919         foreach my $csumi (@files_csum_info_fields) {
1920             my ($fname, $module, $method, $archivefield) = @$csumi;
1921             next unless defined $changes->{$fname};
1922             if ($found_same) {
1923                 # in archive, delete from .changes if it's there
1924                 $changed{$file} = "removed" if
1925                     $changes->{$fname} =~ s/^.* \Q$file\E$(?:)\n//m;
1926             } elsif ($changes->{$fname} =~ m/^.* \Q$file\E$(?:)\n/m) {
1927                 # not in archive, but it's here in the .changes
1928             } else {
1929                 my $dsc_data = getfield $dsc, $fname;
1930                 $dsc_data =~ m/^(.* \Q$file\E$)\n/m or die "$dsc_data $file ?";
1931                 my $extra = $1;
1932                 $extra =~ s/ \d+ /$&$placementinfo /
1933                     or die "$fname $extra >$dsc_data< ?"
1934                     if $fname eq 'Files';
1935                 $changes->{$fname} .= "\n". $extra;
1936                 $changed{$file} = "added";
1937             }
1938         }
1939     }
1940     if (%changed) {
1941         foreach my $file (keys %changed) {
1942             progress sprintf
1943                 "edited .changes for archive .orig contents: %s %s",
1944                 $changed{$file}, $file;
1945         }
1946         my $chtmp = "$changesfile.tmp";
1947         $changes->save($chtmp);
1948         if (act_local()) {
1949             rename $chtmp,$changesfile or die "$changesfile $!";
1950         } else {
1951             progress "[new .changes left in $changesfile]";
1952         }
1953     } else {
1954         progress "$changesfile already has appropriate .orig(s) (if any)";
1955     }
1956 }
1957
1958 sub make_commit ($) {
1959     my ($file) = @_;
1960     return cmdoutput @git, qw(hash-object -w -t commit), $file;
1961 }
1962
1963 sub make_commit_text ($) {
1964     my ($text) = @_;
1965     my ($out, $in);
1966     my @cmd = (@git, qw(hash-object -w -t commit --stdin));
1967     debugcmd "|",@cmd;
1968     print Dumper($text) if $debuglevel > 1;
1969     my $child = open2($out, $in, @cmd) or die $!;
1970     my $h;
1971     eval {
1972         print $in $text or die $!;
1973         close $in or die $!;
1974         $h = <$out>;
1975         $h =~ m/^\w+$/ or die;
1976         $h = $&;
1977         printdebug "=> $h\n";
1978     };
1979     close $out;
1980     waitpid $child, 0 == $child or die "$child $!";
1981     $? and failedcmd @cmd;
1982     return $h;
1983 }
1984
1985 sub clogp_authline ($) {
1986     my ($clogp) = @_;
1987     my $author = getfield $clogp, 'Maintainer';
1988     $author =~ s#,.*##ms;
1989     my $date = cmdoutput qw(date), '+%s %z', qw(-d), getfield($clogp,'Date');
1990     my $authline = "$author $date";
1991     $authline =~ m/$git_authline_re/o or
1992         fail "unexpected commit author line format \`$authline'".
1993         " (was generated from changelog Maintainer field)";
1994     return ($1,$2,$3) if wantarray;
1995     return $authline;
1996 }
1997
1998 sub vendor_patches_distro ($$) {
1999     my ($checkdistro, $what) = @_;
2000     return unless defined $checkdistro;
2001
2002     my $series = "debian/patches/\L$checkdistro\E.series";
2003     printdebug "checking for vendor-specific $series ($what)\n";
2004
2005     if (!open SERIES, "<", $series) {
2006         die "$series $!" unless $!==ENOENT;
2007         return;
2008     }
2009     while (<SERIES>) {
2010         next unless m/\S/;
2011         next if m/^\s+\#/;
2012
2013         print STDERR <<END;
2014
2015 Unfortunately, this source package uses a feature of dpkg-source where
2016 the same source package unpacks to different source code on different
2017 distros.  dgit cannot safely operate on such packages on affected
2018 distros, because the meaning of source packages is not stable.
2019
2020 Please ask the distro/maintainer to remove the distro-specific series
2021 files and use a different technique (if necessary, uploading actually
2022 different packages, if different distros are supposed to have
2023 different code).
2024
2025 END
2026         fail "Found active distro-specific series file for".
2027             " $checkdistro ($what): $series, cannot continue";
2028     }
2029     die "$series $!" if SERIES->error;
2030     close SERIES;
2031 }
2032
2033 sub check_for_vendor_patches () {
2034     # This dpkg-source feature doesn't seem to be documented anywhere!
2035     # But it can be found in the changelog (reformatted):
2036
2037     #   commit  4fa01b70df1dc4458daee306cfa1f987b69da58c
2038     #   Author: Raphael Hertzog <hertzog@debian.org>
2039     #   Date: Sun  Oct  3  09:36:48  2010 +0200
2040
2041     #   dpkg-source: correctly create .pc/.quilt_series with alternate
2042     #   series files
2043     #   
2044     #   If you have debian/patches/ubuntu.series and you were
2045     #   unpacking the source package on ubuntu, quilt was still
2046     #   directed to debian/patches/series instead of
2047     #   debian/patches/ubuntu.series.
2048     #   
2049     #   debian/changelog                        |    3 +++
2050     #   scripts/Dpkg/Source/Package/V3/quilt.pm |    4 +++-
2051     #   2 files changed, 6 insertions(+), 1 deletion(-)
2052
2053     use Dpkg::Vendor;
2054     vendor_patches_distro($ENV{DEB_VENDOR}, "DEB_VENDOR");
2055     vendor_patches_distro(Dpkg::Vendor::get_current_vendor(),
2056                          "Dpkg::Vendor \`current vendor'");
2057     vendor_patches_distro(access_basedistro(),
2058                           "(base) distro being accessed");
2059     vendor_patches_distro(access_nomdistro(),
2060                           "(nominal) distro being accessed");
2061 }
2062
2063 sub generate_commits_from_dsc () {
2064     # See big comment in fetch_from_archive, below.
2065     # See also README.dsc-import.
2066     prep_ud();
2067     changedir $ud;
2068
2069     my @dfi = dsc_files_info();
2070     foreach my $fi (@dfi) {
2071         my $f = $fi->{Filename};
2072         die "$f ?" if $f =~ m#/|^\.|\.dsc$|\.tmp$#;
2073         my $upper_f = "../../../../$f";
2074
2075         printdebug "considering linking $f: ";
2076
2077         link_ltarget $upper_f, $f
2078             or ((printdebug "($!) "), 0)
2079             or $!==&ENOENT
2080             or die "$f $!";
2081
2082         printdebug "linked.\n";
2083
2084         complete_file_from_dsc('.', $fi)
2085             or next;
2086
2087         link $f, $upper_f
2088             or $!==&EEXIST
2089             or die "$f $!";
2090     }
2091
2092     # We unpack and record the orig tarballs first, so that we only
2093     # need disk space for one private copy of the unpacked source.
2094     # But we can't make them into commits until we have the metadata
2095     # from the debian/changelog, so we record the tree objects now and
2096     # make them into commits later.
2097     my @tartrees;
2098     my $upstreamv = upstreamversion $dsc->{version};
2099     my $orig_f_base = srcfn $upstreamv, '';
2100
2101     foreach my $fi (@dfi) {
2102         # We actually import, and record as a commit, every tarball
2103         # (unless there is only one file, in which case there seems
2104         # little point.
2105
2106         my $f = $fi->{Filename};
2107         printdebug "import considering $f ";
2108         (printdebug "only one dfi\n"), next if @dfi == 1;
2109         (printdebug "not tar\n"), next unless $f =~ m/\.tar(\.\w+)?$/;
2110         (printdebug "signature\n"), next if $f =~ m/$orig_f_sig_re$/o;
2111         my $compr_ext = $1;
2112
2113         my ($orig_f_part) =
2114             $f =~ m/^\Q$orig_f_base\E\.([^._]+)?\.tar(?:\.\w+)?$/;
2115
2116         printdebug "Y ", (join ' ', map { $_//"(none)" }
2117                           $compr_ext, $orig_f_part
2118                          ), "\n";
2119
2120         my $input = new IO::File $f, '<' or die "$f $!";
2121         my $compr_pid;
2122         my @compr_cmd;
2123
2124         if (defined $compr_ext) {
2125             my $cname =
2126                 Dpkg::Compression::compression_guess_from_filename $f;
2127             fail "Dpkg::Compression cannot handle file $f in source package"
2128                 if defined $compr_ext && !defined $cname;
2129             my $compr_proc =
2130                 new Dpkg::Compression::Process compression => $cname;
2131             my @compr_cmd = $compr_proc->get_uncompress_cmdline();
2132             my $compr_fh = new IO::Handle;
2133             my $compr_pid = open $compr_fh, "-|" // die $!;
2134             if (!$compr_pid) {
2135                 open STDIN, "<&", $input or die $!;
2136                 exec @compr_cmd;
2137                 die "dgit (child): exec $compr_cmd[0]: $!\n";
2138             }
2139             $input = $compr_fh;
2140         }
2141
2142         rmtree "_unpack-tar";
2143         mkdir "_unpack-tar" or die $!;
2144         my @tarcmd = qw(tar -x -f -
2145                         --no-same-owner --no-same-permissions
2146                         --no-acls --no-xattrs --no-selinux);
2147         my $tar_pid = fork // die $!;
2148         if (!$tar_pid) {
2149             chdir "_unpack-tar" or die $!;
2150             open STDIN, "<&", $input or die $!;
2151             exec @tarcmd;
2152             die "dgit (child): exec $tarcmd[0]: $!";
2153         }
2154         $!=0; (waitpid $tar_pid, 0) == $tar_pid or die $!;
2155         !$? or failedcmd @tarcmd;
2156
2157         close $input or
2158             (@compr_cmd ? failedcmd @compr_cmd
2159              : die $!);
2160         # finally, we have the results in "tarball", but maybe
2161         # with the wrong permissions
2162
2163         runcmd qw(chmod -R +rwX _unpack-tar);
2164         changedir "_unpack-tar";
2165         remove_stray_gits($f);
2166         mktree_in_ud_here();
2167         
2168         my ($tree) = git_add_write_tree();
2169         my $tentries = cmdoutput @git, qw(ls-tree -z), $tree;
2170         if ($tentries =~ m/^\d+ tree (\w+)\t[^\000]+\000$/s) {
2171             $tree = $1;
2172             printdebug "one subtree $1\n";
2173         } else {
2174             printdebug "multiple subtrees\n";
2175         }
2176         changedir "..";
2177         rmtree "_unpack-tar";
2178
2179         my $ent = [ $f, $tree ];
2180         push @tartrees, {
2181             Orig => !!$orig_f_part,
2182             Sort => (!$orig_f_part         ? 2 :
2183                      $orig_f_part =~ m/-/g ? 1 :
2184                                              0),
2185             F => $f,
2186             Tree => $tree,
2187         };
2188     }
2189
2190     @tartrees = sort {
2191         # put any without "_" first (spec is not clear whether files
2192         # are always in the usual order).  Tarballs without "_" are
2193         # the main orig or the debian tarball.
2194         $a->{Sort} <=> $b->{Sort} or
2195         $a->{F}    cmp $b->{F}
2196     } @tartrees;
2197
2198     my $any_orig = grep { $_->{Orig} } @tartrees;
2199
2200     my $dscfn = "$package.dsc";
2201
2202     my $treeimporthow = 'package';
2203
2204     open D, ">", $dscfn or die "$dscfn: $!";
2205     print D $dscdata or die "$dscfn: $!";
2206     close D or die "$dscfn: $!";
2207     my @cmd = qw(dpkg-source);
2208     push @cmd, '--no-check' if $dsc_checked;
2209     if (madformat $dsc->{format}) {
2210         push @cmd, '--skip-patches';
2211         $treeimporthow = 'unpatched';
2212     }
2213     push @cmd, qw(-x --), $dscfn;
2214     runcmd @cmd;
2215
2216     my ($tree,$dir) = mktree_in_ud_from_only_subdir("source package");
2217     if (madformat $dsc->{format}) { 
2218         check_for_vendor_patches();
2219     }
2220
2221     my $dappliedtree;
2222     if (madformat $dsc->{format}) {
2223         my @pcmd = qw(dpkg-source --before-build .);
2224         runcmd shell_cmd 'exec >/dev/null', @pcmd;
2225         rmtree '.pc';
2226         $dappliedtree = git_add_write_tree();
2227     }
2228
2229     my @clogcmd = qw(dpkg-parsechangelog --format rfc822 --all);
2230     debugcmd "|",@clogcmd;
2231     open CLOGS, "-|", @clogcmd or die $!;
2232
2233     my $clogp;
2234     my $r1clogp;
2235
2236     printdebug "import clog search...\n";
2237
2238     for (;;) {
2239         my $stanzatext = do { local $/=""; <CLOGS>; };
2240         printdebug "import clogp ".Dumper($stanzatext) if $debuglevel>1;
2241         last if !defined $stanzatext;
2242
2243         my $desc = "package changelog, entry no.$.";
2244         open my $stanzafh, "<", \$stanzatext or die;
2245         my $thisstanza = parsecontrolfh $stanzafh, $desc, 1;
2246         $clogp //= $thisstanza;
2247
2248         printdebug "import clog $thisstanza->{version} $desc...\n";
2249
2250         last if !$any_orig; # we don't need $r1clogp
2251
2252         # We look for the first (most recent) changelog entry whose
2253         # version number is lower than the upstream version of this
2254         # package.  Then the last (least recent) previous changelog
2255         # entry is treated as the one which introduced this upstream
2256         # version and used for the synthetic commits for the upstream
2257         # tarballs.
2258
2259         # One might think that a more sophisticated algorithm would be
2260         # necessary.  But: we do not want to scan the whole changelog
2261         # file.  Stopping when we see an earlier version, which
2262         # necessarily then is an earlier upstream version, is the only
2263         # realistic way to do that.  Then, either the earliest
2264         # changelog entry we have seen so far is indeed the earliest
2265         # upload of this upstream version; or there are only changelog
2266         # entries relating to later upstream versions (which is not
2267         # possible unless the changelog and .dsc disagree about the
2268         # version).  Then it remains to choose between the physically
2269         # last entry in the file, and the one with the lowest version
2270         # number.  If these are not the same, we guess that the
2271         # versions were created in a non-monotic order rather than
2272         # that the changelog entries have been misordered.
2273
2274         printdebug "import clog $thisstanza->{version} vs $upstreamv...\n";
2275
2276         last if version_compare($thisstanza->{version}, $upstreamv) < 0;
2277         $r1clogp = $thisstanza;
2278
2279         printdebug "import clog $r1clogp->{version} becomes r1\n";
2280     }
2281     die $! if CLOGS->error;
2282     close CLOGS or $?==SIGPIPE or failedcmd @clogcmd;
2283
2284     $clogp or fail "package changelog has no entries!";
2285
2286     my $authline = clogp_authline $clogp;
2287     my $changes = getfield $clogp, 'Changes';
2288     my $cversion = getfield $clogp, 'Version';
2289
2290     if (@tartrees) {
2291         $r1clogp //= $clogp; # maybe there's only one entry;
2292         my $r1authline = clogp_authline $r1clogp;
2293         # Strictly, r1authline might now be wrong if it's going to be
2294         # unused because !$any_orig.  Whatever.
2295
2296         printdebug "import tartrees authline   $authline\n";
2297         printdebug "import tartrees r1authline $r1authline\n";
2298
2299         foreach my $tt (@tartrees) {
2300             printdebug "import tartree $tt->{F} $tt->{Tree}\n";
2301
2302             $tt->{Commit} = make_commit_text($tt->{Orig} ? <<END_O : <<END_T);
2303 tree $tt->{Tree}
2304 author $r1authline
2305 committer $r1authline
2306
2307 Import $tt->{F}
2308
2309 [dgit import orig $tt->{F}]
2310 END_O
2311 tree $tt->{Tree}
2312 author $authline
2313 committer $authline
2314
2315 Import $tt->{F}
2316
2317 [dgit import tarball $package $cversion $tt->{F}]
2318 END_T
2319         }
2320     }
2321
2322     printdebug "import main commit\n";
2323
2324     open C, ">../commit.tmp" or die $!;
2325     print C <<END or die $!;
2326 tree $tree
2327 END
2328     print C <<END or die $! foreach @tartrees;
2329 parent $_->{Commit}
2330 END
2331     print C <<END or die $!;
2332 author $authline
2333 committer $authline
2334
2335 $changes
2336
2337 [dgit import $treeimporthow $package $cversion]
2338 END
2339
2340     close C or die $!;
2341     my $rawimport_hash = make_commit qw(../commit.tmp);
2342
2343     if (madformat $dsc->{format}) {
2344         printdebug "import apply patches...\n";
2345
2346         # regularise the state of the working tree so that
2347         # the checkout of $rawimport_hash works nicely.
2348         my $dappliedcommit = make_commit_text(<<END);
2349 tree $dappliedtree
2350 author $authline
2351 committer $authline
2352
2353 [dgit dummy commit]
2354 END
2355         runcmd @git, qw(checkout -q -b dapplied), $dappliedcommit;
2356
2357         runcmd @git, qw(checkout -q -b unpa), $rawimport_hash;
2358
2359         # We need the answers to be reproducible
2360         my @authline = clogp_authline($clogp);
2361         local $ENV{GIT_COMMITTER_NAME} =  $authline[0];
2362         local $ENV{GIT_COMMITTER_EMAIL} = $authline[1];
2363         local $ENV{GIT_COMMITTER_DATE} =  $authline[2];
2364         local $ENV{GIT_AUTHOR_NAME} =  $authline[0];
2365         local $ENV{GIT_AUTHOR_EMAIL} = $authline[1];
2366         local $ENV{GIT_AUTHOR_DATE} =  $authline[2];
2367
2368         my $path = $ENV{PATH} or die;
2369
2370         foreach my $use_absurd (qw(0 1)) {
2371             runcmd @git, qw(checkout -q unpa);
2372             runcmd @git, qw(update-ref -d refs/heads/patch-queue/unpa);
2373             local $ENV{PATH} = $path;
2374             if ($use_absurd) {
2375                 chomp $@;
2376                 progress "warning: $@";
2377                 $path = "$absurdity:$path";
2378                 progress "$us: trying slow absurd-git-apply...";
2379                 rename "../../gbp-pq-output","../../gbp-pq-output.0"
2380                     or $!==ENOENT
2381                     or die $!;
2382             }
2383             eval {
2384                 die "forbid absurd git-apply\n" if $use_absurd
2385                     && forceing [qw(import-gitapply-no-absurd)];
2386                 die "only absurd git-apply!\n" if !$use_absurd
2387                     && forceing [qw(import-gitapply-absurd)];
2388
2389                 local $ENV{DGIT_ABSURD_DEBUG} = $debuglevel if $use_absurd;
2390                 local $ENV{PATH} = $path                    if $use_absurd;
2391
2392                 my @showcmd = (gbp_pq, qw(import));
2393                 my @realcmd = shell_cmd
2394                     'exec >/dev/null 2>>../../gbp-pq-output', @showcmd;
2395                 debugcmd "+",@realcmd;
2396                 if (system @realcmd) {
2397                     die +(shellquote @showcmd).
2398                         " failed: ".
2399                         failedcmd_waitstatus()."\n";
2400                 }
2401
2402                 my $gapplied = git_rev_parse('HEAD');
2403                 my $gappliedtree = cmdoutput @git, qw(rev-parse HEAD:);
2404                 $gappliedtree eq $dappliedtree or
2405                     fail <<END;
2406 gbp-pq import and dpkg-source disagree!
2407  gbp-pq import gave commit $gapplied
2408  gbp-pq import gave tree $gappliedtree
2409  dpkg-source --before-build gave tree $dappliedtree
2410 END
2411                 $rawimport_hash = $gapplied;
2412             };
2413             last unless $@;
2414         }
2415         if ($@) {
2416             { local $@; eval { runcmd qw(cat ../../gbp-pq-output); }; }
2417             die $@;
2418         }
2419     }
2420
2421     progress "synthesised git commit from .dsc $cversion";
2422
2423     my $rawimport_mergeinput = {
2424         Commit => $rawimport_hash,
2425         Info => "Import of source package",
2426     };
2427     my @output = ($rawimport_mergeinput);
2428
2429     if ($lastpush_mergeinput) {
2430         my $oldclogp = mergeinfo_getclogp($lastpush_mergeinput);
2431         my $oversion = getfield $oldclogp, 'Version';
2432         my $vcmp =
2433             version_compare($oversion, $cversion);
2434         if ($vcmp < 0) {
2435             @output = ($rawimport_mergeinput, $lastpush_mergeinput,
2436                 { Message => <<END, ReverseParents => 1 });
2437 Record $package ($cversion) in archive suite $csuite
2438 END
2439         } elsif ($vcmp > 0) {
2440             print STDERR <<END or die $!;
2441
2442 Version actually in archive:   $cversion (older)
2443 Last version pushed with dgit: $oversion (newer or same)
2444 $later_warning_msg
2445 END
2446             @output = $lastpush_mergeinput;
2447         } else {
2448             # Same version.  Use what's in the server git branch,
2449             # discarding our own import.  (This could happen if the
2450             # server automatically imports all packages into git.)
2451             @output = $lastpush_mergeinput;
2452         }
2453     }
2454     changedir '../../../..';
2455     rmtree($ud);
2456     return @output;
2457 }
2458
2459 sub complete_file_from_dsc ($$) {
2460     our ($dstdir, $fi) = @_;
2461     # Ensures that we have, in $dir, the file $fi, with the correct
2462     # contents.  (Downloading it from alongside $dscurl if necessary.)
2463
2464     my $f = $fi->{Filename};
2465     my $tf = "$dstdir/$f";
2466     my $downloaded = 0;
2467
2468     if (stat_exists $tf) {
2469         progress "using existing $f";
2470     } else {
2471         printdebug "$tf does not exist, need to fetch\n";
2472         my $furl = $dscurl;
2473         $furl =~ s{/[^/]+$}{};
2474         $furl .= "/$f";
2475         die "$f ?" unless $f =~ m/^\Q${package}\E_/;
2476         die "$f ?" if $f =~ m#/#;
2477         runcmd_ordryrun_local @curl,qw(-f -o),$tf,'--',"$furl";
2478         return 0 if !act_local();
2479         $downloaded = 1;
2480     }
2481
2482     open F, "<", "$tf" or die "$tf: $!";
2483     $fi->{Digester}->reset();
2484     $fi->{Digester}->addfile(*F);
2485     F->error and die $!;
2486     my $got = $fi->{Digester}->hexdigest();
2487     $got eq $fi->{Hash} or
2488         fail "file $f has hash $got but .dsc".
2489             " demands hash $fi->{Hash} ".
2490             ($downloaded ? "(got wrong file from archive!)"
2491              : "(perhaps you should delete this file?)");
2492
2493     return 1;
2494 }
2495
2496 sub ensure_we_have_orig () {
2497     my @dfi = dsc_files_info();
2498     foreach my $fi (@dfi) {
2499         my $f = $fi->{Filename};
2500         next unless is_orig_file_in_dsc($f, \@dfi);
2501         complete_file_from_dsc('..', $fi)
2502             or next;
2503     }
2504 }
2505
2506 #---------- git fetch ----------
2507
2508 sub lrfetchrefs () { return "refs/dgit-fetch/".access_basedistro(); }
2509 sub lrfetchref () { return lrfetchrefs.'/'.server_branch($csuite); }
2510
2511 # We fetch some parts of lrfetchrefs/*.  Ideally we delete these
2512 # locally fetched refs because they have unhelpful names and clutter
2513 # up gitk etc.  So we track whether we have "used up" head ref (ie,
2514 # whether we have made another local ref which refers to this object).
2515 #
2516 # (If we deleted them unconditionally, then we might end up
2517 # re-fetching the same git objects each time dgit fetch was run.)
2518 #
2519 # So, leach use of lrfetchrefs needs to be accompanied by arrangements
2520 # in git_fetch_us to fetch the refs in question, and possibly a call
2521 # to lrfetchref_used.
2522
2523 our (%lrfetchrefs_f, %lrfetchrefs_d);
2524 # $lrfetchrefs_X{lrfetchrefs."/heads/whatever"} = $objid
2525
2526 sub lrfetchref_used ($) {
2527     my ($fullrefname) = @_;
2528     my $objid = $lrfetchrefs_f{$fullrefname};
2529     $lrfetchrefs_d{$fullrefname} = $objid if defined $objid;
2530 }
2531
2532 sub git_lrfetch_sane {
2533     my ($supplementary, @specs) = @_;
2534     # Make a 'refs/'.lrfetchrefs.'/*' be just like on server,
2535     # at least as regards @specs.  Also leave the results in
2536     # %lrfetchrefs_f, and arrange for lrfetchref_used to be
2537     # able to clean these up.
2538     #
2539     # With $supplementary==1, @specs must not contain wildcards
2540     # and we add to our previous fetches (non-atomically).
2541
2542     # This is rather miserable:
2543     # When git fetch --prune is passed a fetchspec ending with a *,
2544     # it does a plausible thing.  If there is no * then:
2545     # - it matches subpaths too, even if the supplied refspec
2546     #   starts refs, and behaves completely madly if the source
2547     #   has refs/refs/something.  (See, for example, Debian #NNNN.)
2548     # - if there is no matching remote ref, it bombs out the whole
2549     #   fetch.
2550     # We want to fetch a fixed ref, and we don't know in advance
2551     # if it exists, so this is not suitable.
2552     #
2553     # Our workaround is to use git ls-remote.  git ls-remote has its
2554     # own qairks.  Notably, it has the absurd multi-tail-matching
2555     # behaviour: git ls-remote R refs/foo can report refs/foo AND
2556     # refs/refs/foo etc.
2557     #
2558     # Also, we want an idempotent snapshot, but we have to make two
2559     # calls to the remote: one to git ls-remote and to git fetch.  The
2560     # solution is use git ls-remote to obtain a target state, and
2561     # git fetch to try to generate it.  If we don't manage to generate
2562     # the target state, we try again.
2563
2564     my $url = access_giturl();
2565
2566     printdebug "git_lrfetch_sane suppl=$supplementary specs @specs\n";
2567
2568     my $specre = join '|', map {
2569         my $x = $_;
2570         $x =~ s/\W/\\$&/g;
2571         my $wildcard = $x =~ s/\\\*$/.*/;
2572         die if $wildcard && $supplementary;
2573         "(?:refs/$x)";
2574     } @specs;
2575     printdebug "git_lrfetch_sane specre=$specre\n";
2576     my $wanted_rref = sub {
2577         local ($_) = @_;
2578         return m/^(?:$specre)$/;
2579     };
2580
2581     my $fetch_iteration = 0;
2582     FETCH_ITERATION:
2583     for (;;) {
2584         printdebug "git_lrfetch_sane iteration $fetch_iteration\n";
2585         if (++$fetch_iteration > 10) {
2586             fail "too many iterations trying to get sane fetch!";
2587         }
2588
2589         my @look = map { "refs/$_" } @specs;
2590         my @lcmd = (@git, qw(ls-remote -q --refs), $url, @look);
2591         debugcmd "|",@lcmd;
2592
2593         my %wantr;
2594         open GITLS, "-|", @lcmd or die $!;
2595         while (<GITLS>) {
2596             printdebug "=> ", $_;
2597             m/^(\w+)\s+(\S+)\n/ or die "ls-remote $_ ?";
2598             my ($objid,$rrefname) = ($1,$2);
2599             if (!$wanted_rref->($rrefname)) {
2600                 print STDERR <<END;
2601 warning: git ls-remote @look reported $rrefname; this is silly, ignoring it.
2602 END
2603                 next;
2604             }
2605             $wantr{$rrefname} = $objid;
2606         }
2607         $!=0; $?=0;
2608         close GITLS or failedcmd @lcmd;
2609
2610         # OK, now %want is exactly what we want for refs in @specs
2611         my @fspecs = map {
2612             !m/\*$/ && !exists $wantr{"refs/$_"} ? () :
2613             "+refs/$_:".lrfetchrefs."/$_";
2614         } @specs;
2615
2616         printdebug "git_lrfetch_sane fspecs @fspecs\n";
2617
2618         my @fcmd = (@git, qw(fetch -p -n -q), $url, @fspecs);
2619         runcmd_ordryrun_local @fcmd if @fspecs;
2620
2621         if (!$supplementary) {
2622             %lrfetchrefs_f = ();
2623         }
2624         my %objgot;
2625
2626         git_for_each_ref(lrfetchrefs, sub {
2627             my ($objid,$objtype,$lrefname,$reftail) = @_;
2628             $lrfetchrefs_f{$lrefname} = $objid;
2629             $objgot{$objid} = 1;
2630         });
2631
2632         if ($supplementary) {
2633             last;
2634         }
2635
2636         foreach my $lrefname (sort keys %lrfetchrefs_f) {
2637             my $rrefname = 'refs'.substr($lrefname, length lrfetchrefs);
2638             if (!exists $wantr{$rrefname}) {
2639                 if ($wanted_rref->($rrefname)) {
2640                     printdebug <<END;
2641 git-fetch @fspecs created $lrefname which git ls-remote @look didn't list.
2642 END
2643                 } else {
2644                     print STDERR <<END
2645 warning: git fetch @fspecs created $lrefname; this is silly, deleting it.
2646 END
2647                 }
2648                 runcmd_ordryrun_local @git, qw(update-ref -d), $lrefname;
2649                 delete $lrfetchrefs_f{$lrefname};
2650                 next;
2651             }
2652         }
2653         foreach my $rrefname (sort keys %wantr) {
2654             my $lrefname = lrfetchrefs.substr($rrefname, 4);
2655             my $got = $lrfetchrefs_f{$lrefname} // '<none>';
2656             my $want = $wantr{$rrefname};
2657             next if $got eq $want;
2658             if (!defined $objgot{$want}) {
2659                 print STDERR <<END;
2660 warning: git ls-remote suggests we want $lrefname
2661 warning:  and it should refer to $want
2662 warning:  but git fetch didn't fetch that object to any relevant ref.
2663 warning:  This may be due to a race with someone updating the server.
2664 warning:  Will try again...
2665 END
2666                 next FETCH_ITERATION;
2667             }
2668             printdebug <<END;
2669 git-fetch @fspecs made $lrefname=$got but want git ls-remote @look says $want
2670 END
2671             runcmd_ordryrun_local @git, qw(update-ref -m),
2672                 "dgit fetch git fetch fixup", $lrefname, $want;
2673             $lrfetchrefs_f{$lrefname} = $want;
2674         }
2675         last;
2676     }
2677
2678     if (defined $csuite) {
2679         printdebug "git_lrfetch_sane: tidying any old suite lrfetchrefs\n";
2680         git_for_each_ref("refs/dgit-fetch/$csuite", sub {
2681             my ($objid,$objtype,$lrefname,$reftail) = @_;
2682             next if $lrfetchrefs_f{$lrefname}; # $csuite eq $distro ?
2683             runcmd_ordryrun_local @git, qw(update-ref -d), $lrefname;
2684         });
2685     }
2686
2687     printdebug "git_lrfetch_sane: git fetch --no-insane emulation complete\n",
2688         Dumper(\%lrfetchrefs_f);
2689 }
2690
2691 sub git_fetch_us () {
2692     # Want to fetch only what we are going to use, unless
2693     # deliberately-not-ff, in which case we must fetch everything.
2694
2695     my @specs = deliberately_not_fast_forward ? qw(tags/*) :
2696         map { "tags/$_" }
2697         (quiltmode_splitbrain
2698          ? (map { $_->('*',access_nomdistro) }
2699             \&debiantag_new, \&debiantag_maintview)
2700          : debiantags('*',access_nomdistro));
2701     push @specs, server_branch($csuite);
2702     push @specs, $rewritemap;
2703     push @specs, qw(heads/*) if deliberately_not_fast_forward;
2704
2705     git_lrfetch_sane 0, @specs;
2706
2707     my %here;
2708     my @tagpats = debiantags('*',access_nomdistro);
2709
2710     git_for_each_ref([map { "refs/tags/$_" } @tagpats], sub {
2711         my ($objid,$objtype,$fullrefname,$reftail) = @_;
2712         printdebug "currently $fullrefname=$objid\n";
2713         $here{$fullrefname} = $objid;
2714     });
2715     git_for_each_ref([map { lrfetchrefs."/tags/".$_ } @tagpats], sub {
2716         my ($objid,$objtype,$fullrefname,$reftail) = @_;
2717         my $lref = "refs".substr($fullrefname, length(lrfetchrefs));
2718         printdebug "offered $lref=$objid\n";
2719         if (!defined $here{$lref}) {
2720             my @upd = (@git, qw(update-ref), $lref, $objid, '');
2721             runcmd_ordryrun_local @upd;
2722             lrfetchref_used $fullrefname;
2723         } elsif ($here{$lref} eq $objid) {
2724             lrfetchref_used $fullrefname;
2725         } else {
2726             print STDERR \
2727                 "Not updateting $lref from $here{$lref} to $objid.\n";
2728         }
2729     });
2730 }
2731
2732 #---------- dsc and archive handling ----------
2733
2734 sub mergeinfo_getclogp ($) {
2735     # Ensures thit $mi->{Clogp} exists and returns it
2736     my ($mi) = @_;
2737     $mi->{Clogp} = commit_getclogp($mi->{Commit});
2738 }
2739
2740 sub mergeinfo_version ($) {
2741     return getfield( (mergeinfo_getclogp $_[0]), 'Version' );
2742 }
2743
2744 sub fetch_from_archive_record_1 ($) {
2745     my ($hash) = @_;
2746     runcmd @git, qw(update-ref -m), "dgit fetch $csuite",
2747             'DGIT_ARCHIVE', $hash;
2748     cmdoutput @git, qw(log -n2), $hash;
2749     # ... gives git a chance to complain if our commit is malformed
2750 }
2751
2752 sub fetch_from_archive_record_2 ($) {
2753     my ($hash) = @_;
2754     my @upd_cmd = (@git, qw(update-ref -m), 'dgit fetch', lrref(), $hash);
2755     if (act_local()) {
2756         cmdoutput @upd_cmd;
2757     } else {
2758         dryrun_report @upd_cmd;
2759     }
2760 }
2761
2762 sub parse_dsc_field ($$) {
2763     my ($dsc, $what) = @_;
2764     my $f;
2765     foreach my $field (@ourdscfield) {
2766         $f = $dsc->{$field};
2767         last if defined $f;
2768     }
2769     if (!defined $f) {
2770         progress "$what: NO git hash";
2771     } elsif (($dsc_hash, $dsc_distro, $dsc_hint_tag, $dsc_hint_url)
2772              = $f =~ m/^(\w+)\s+($distro_re)\s+($versiontag_re)\s+(\S+)(?:\s|$)/) {
2773         progress "$what: specified git info ($dsc_distro)";
2774         $dsc_hint_tag = [ $dsc_hint_tag ];
2775     } elsif ($f =~ m/^\w+\s*$/) {
2776         $dsc_hash = $&;
2777         $dsc_distro //= cfg qw(dgit.default.old-dsc-distro
2778                                dgit.default.distro);
2779         $dsc_hint_tag = [ debiantags +(getfield $dsc, 'Version'),
2780                           $dsc_distro ];
2781         progress "$what: specified git hash";
2782     } else {
2783         fail "$what: invalid Dgit info";
2784     }
2785 }
2786
2787 sub resolve_dsc_field_commit ($$) {
2788     my ($already_distro, $already_mapref) = @_;
2789
2790     return unless defined $dsc_hash;
2791
2792     my $mapref =
2793         defined $already_mapref &&
2794         ($already_distro eq $dsc_distro || !$chase_dsc_distro)
2795         ? $already_mapref : undef;
2796
2797     my $do_fetch;
2798     $do_fetch = sub {
2799         my ($what, @fetch) = @_;
2800
2801         local $idistro = $dsc_distro;
2802         my $lrf = lrfetchrefs;
2803
2804         if (!$chase_dsc_distro) {
2805             progress
2806                 "not chasing .dsc distro $dsc_distro: not fetching $what";
2807             return 0;
2808         }
2809
2810         progress
2811             ".dsc names distro $dsc_distro: fetching $what";
2812
2813         my $url = access_giturl();
2814         if (!defined $url) {
2815             defined $dsc_hint_url or fail <<END;
2816 .dsc Dgit metadata is in context of distro $dsc_distro
2817 for which we have no configured url and .dsc provides no hint
2818 END
2819             my $proto =
2820                 $dsc_hint_url =~ m#^([-+0-9a-zA-Z]+):# ? $1 :
2821                 $dsc_hint_url =~ m#^/# ? 'file' : 'bad-syntax';
2822             parse_cfg_bool "dsc-url-proto-ok", 'false',
2823                 cfg("dgit.dsc-url-proto-ok.$proto",
2824                     "dgit.default.dsc-url-proto-ok")
2825                 or fail <<END;
2826 .dsc Dgit metadata is in context of distro $dsc_distro
2827 for which we have no configured url;
2828 .dsc provices hinted url with protocol $proto which is unsafe.
2829 (can be overridden by config - consult documentation)
2830 END
2831             $url = $dsc_hint_url;
2832         }
2833
2834         git_lrfetch_sane 1, @fetch;
2835
2836         return $lrf;
2837     };
2838
2839     my $rewrite_enable = do {
2840         local $idistro = $dsc_distro;
2841         access_cfg('rewrite-map-enable', 'RETURN-UNDEF');
2842     };
2843
2844     if (parse_cfg_bool 'rewrite-map-enable', 'true', $rewrite_enable) {
2845         if (!defined $mapref) {
2846             my $lrf = $do_fetch->("rewrite map", $rewritemap) or return;
2847             $mapref = $lrf.'/'.$rewritemap;
2848         }
2849         my $rewritemapdata = git_cat_file $mapref.':map';
2850         if (defined $rewritemapdata
2851             && $rewritemapdata =~ m/^$dsc_hash(?:[ \t](\w+))/m) {
2852             progress
2853                 "server's git history rewrite map contains a relevant entry!";
2854
2855             $dsc_hash = $1;
2856             if (defined $dsc_hash) {
2857                 progress "using rewritten git hash in place of .dsc value";
2858             } else {
2859                 progress "server data says .dsc hash is to be disregarded";
2860             }
2861         }
2862     }
2863
2864     if (!defined git_cat_file $dsc_hash) {
2865         my @tags = map { "tags/".$_ } @$dsc_hint_tag;
2866         my $lrf = $do_fetch->("additional commits", @tags) &&
2867             defined git_cat_file $dsc_hash
2868             or fail <<END;
2869 .dsc Dgit metadata requires commit $dsc_hash
2870 but we could not obtain that object anywhere.
2871 END
2872         foreach my $t (@tags) {
2873             my $fullrefname = $lrf.'/'.$t;
2874             print STDERR "CHK $t $fullrefname ".Dumper(\%lrfetchrefs_f);
2875             next unless $lrfetchrefs_f{$fullrefname};
2876             next unless is_fast_fwd "$fullrefname~0", $dsc_hash;
2877             lrfetchref_used $fullrefname;
2878         }
2879     }
2880 }
2881
2882 sub fetch_from_archive () {
2883     ensure_setup_existing_tree();
2884
2885     # Ensures that lrref() is what is actually in the archive, one way
2886     # or another, according to us - ie this client's
2887     # appropritaely-updated archive view.  Also returns the commit id.
2888     # If there is nothing in the archive, leaves lrref alone and
2889     # returns undef.  git_fetch_us must have already been called.
2890     get_archive_dsc();
2891
2892     if ($dsc) {
2893         parse_dsc_field($dsc, 'last upload to archive');
2894         resolve_dsc_field_commit access_basedistro,
2895             lrfetchrefs."/".$rewritemap
2896     } else {
2897         progress "no version available from the archive";
2898     }
2899
2900     # If the archive's .dsc has a Dgit field, there are three
2901     # relevant git commitids we need to choose between and/or merge
2902     # together:
2903     #   1. $dsc_hash: the Dgit field from the archive
2904     #   2. $lastpush_hash: the suite branch on the dgit git server
2905     #   3. $lastfetch_hash: our local tracking brach for the suite
2906     #
2907     # These may all be distinct and need not be in any fast forward
2908     # relationship:
2909     #
2910     # If the dsc was pushed to this suite, then the server suite
2911     # branch will have been updated; but it might have been pushed to
2912     # a different suite and copied by the archive.  Conversely a more
2913     # recent version may have been pushed with dgit but not appeared
2914     # in the archive (yet).
2915     #
2916     # $lastfetch_hash may be awkward because archive imports
2917     # (particularly, imports of Dgit-less .dscs) are performed only as
2918     # needed on individual clients, so different clients may perform a
2919     # different subset of them - and these imports are only made
2920     # public during push.  So $lastfetch_hash may represent a set of
2921     # imports different to a subsequent upload by a different dgit
2922     # client.
2923     #
2924     # Our approach is as follows:
2925     #
2926     # As between $dsc_hash and $lastpush_hash: if $lastpush_hash is a
2927     # descendant of $dsc_hash, then it was pushed by a dgit user who
2928     # had based their work on $dsc_hash, so we should prefer it.
2929     # Otherwise, $dsc_hash was installed into this suite in the
2930     # archive other than by a dgit push, and (necessarily) after the
2931     # last dgit push into that suite (since a dgit push would have
2932     # been descended from the dgit server git branch); thus, in that
2933     # case, we prefer the archive's version (and produce a
2934     # pseudo-merge to overwrite the dgit server git branch).
2935     #
2936     # (If there is no Dgit field in the archive's .dsc then
2937     # generate_commit_from_dsc uses the version numbers to decide
2938     # whether the suite branch or the archive is newer.  If the suite
2939     # branch is newer it ignores the archive's .dsc; otherwise it
2940     # generates an import of the .dsc, and produces a pseudo-merge to
2941     # overwrite the suite branch with the archive contents.)
2942     #
2943     # The outcome of that part of the algorithm is the `public view',
2944     # and is same for all dgit clients: it does not depend on any
2945     # unpublished history in the local tracking branch.
2946     #
2947     # As between the public view and the local tracking branch: The
2948     # local tracking branch is only updated by dgit fetch, and
2949     # whenever dgit fetch runs it includes the public view in the
2950     # local tracking branch.  Therefore if the public view is not
2951     # descended from the local tracking branch, the local tracking
2952     # branch must contain history which was imported from the archive
2953     # but never pushed; and, its tip is now out of date.  So, we make
2954     # a pseudo-merge to overwrite the old imports and stitch the old
2955     # history in.
2956     #
2957     # Finally: we do not necessarily reify the public view (as
2958     # described above).  This is so that we do not end up stacking two
2959     # pseudo-merges.  So what we actually do is figure out the inputs
2960     # to any public view pseudo-merge and put them in @mergeinputs.
2961
2962     my @mergeinputs;
2963     # $mergeinputs[]{Commit}
2964     # $mergeinputs[]{Info}
2965     # $mergeinputs[0] is the one whose tree we use
2966     # @mergeinputs is in the order we use in the actual commit)
2967     #
2968     # Also:
2969     # $mergeinputs[]{Message} is a commit message to use
2970     # $mergeinputs[]{ReverseParents} if def specifies that parent
2971     #                                list should be in opposite order
2972     # Such an entry has no Commit or Info.  It applies only when found
2973     # in the last entry.  (This ugliness is to support making
2974     # identical imports to previous dgit versions.)
2975
2976     my $lastpush_hash = git_get_ref(lrfetchref());
2977     printdebug "previous reference hash=$lastpush_hash\n";
2978     $lastpush_mergeinput = $lastpush_hash && {
2979         Commit => $lastpush_hash,
2980         Info => "dgit suite branch on dgit git server",
2981     };
2982
2983     my $lastfetch_hash = git_get_ref(lrref());
2984     printdebug "fetch_from_archive: lastfetch=$lastfetch_hash\n";
2985     my $lastfetch_mergeinput = $lastfetch_hash && {
2986         Commit => $lastfetch_hash,
2987         Info => "dgit client's archive history view",
2988     };
2989
2990     my $dsc_mergeinput = $dsc_hash && {
2991         Commit => $dsc_hash,
2992         Info => "Dgit field in .dsc from archive",
2993     };
2994
2995     my $cwd = getcwd();
2996     my $del_lrfetchrefs = sub {
2997         changedir $cwd;
2998         my $gur;
2999         printdebug "del_lrfetchrefs...\n";
3000         foreach my $fullrefname (sort keys %lrfetchrefs_d) {
3001             my $objid = $lrfetchrefs_d{$fullrefname};
3002             printdebug "del_lrfetchrefs: $objid $fullrefname\n";
3003             if (!$gur) {
3004                 $gur ||= new IO::Handle;
3005                 open $gur, "|-", qw(git update-ref --stdin) or die $!;
3006             }
3007             printf $gur "delete %s %s\n", $fullrefname, $objid;
3008         }
3009         if ($gur) {
3010             close $gur or failedcmd "git update-ref delete lrfetchrefs";
3011         }
3012     };
3013
3014     if (defined $dsc_hash) {
3015         ensure_we_have_orig();
3016         if (!$lastpush_hash || $dsc_hash eq $lastpush_hash) {
3017             @mergeinputs = $dsc_mergeinput
3018         } elsif (is_fast_fwd($dsc_hash,$lastpush_hash)) {
3019             print STDERR <<END or die $!;
3020
3021 Git commit in archive is behind the last version allegedly pushed/uploaded.
3022 Commit referred to by archive: $dsc_hash
3023 Last version pushed with dgit: $lastpush_hash
3024 $later_warning_msg
3025 END
3026             @mergeinputs = ($lastpush_mergeinput);
3027         } else {
3028             # Archive has .dsc which is not a descendant of the last dgit
3029             # push.  This can happen if the archive moves .dscs about.
3030             # Just follow its lead.
3031             if (is_fast_fwd($lastpush_hash,$dsc_hash)) {
3032                 progress "archive .dsc names newer git commit";
3033                 @mergeinputs = ($dsc_mergeinput);
3034             } else {
3035                 progress "archive .dsc names other git commit, fixing up";
3036                 @mergeinputs = ($dsc_mergeinput, $lastpush_mergeinput);
3037             }
3038         }
3039     } elsif ($dsc) {
3040         @mergeinputs = generate_commits_from_dsc();
3041         # We have just done an import.  Now, our import algorithm might
3042         # have been improved.  But even so we do not want to generate
3043         # a new different import of the same package.  So if the
3044         # version numbers are the same, just use our existing version.
3045         # If the version numbers are different, the archive has changed
3046         # (perhaps, rewound).
3047         if ($lastfetch_mergeinput &&
3048             !version_compare( (mergeinfo_version $lastfetch_mergeinput),
3049                               (mergeinfo_version $mergeinputs[0]) )) {
3050             @mergeinputs = ($lastfetch_mergeinput);
3051         }
3052     } elsif ($lastpush_hash) {
3053         # only in git, not in the archive yet
3054         @mergeinputs = ($lastpush_mergeinput);
3055         print STDERR <<END or die $!;
3056
3057 Package not found in the archive, but has allegedly been pushed using dgit.
3058 $later_warning_msg
3059 END
3060     } else {
3061         printdebug "nothing found!\n";
3062         if (defined $skew_warning_vsn) {
3063             print STDERR <<END or die $!;
3064
3065 Warning: relevant archive skew detected.
3066 Archive allegedly contains $skew_warning_vsn
3067 But we were not able to obtain any version from the archive or git.
3068
3069 END
3070         }
3071         unshift @end, $del_lrfetchrefs;
3072         return undef;
3073     }
3074
3075     if ($lastfetch_hash &&
3076         !grep {
3077             my $h = $_->{Commit};
3078             $h and is_fast_fwd($lastfetch_hash, $h);
3079             # If true, one of the existing parents of this commit
3080             # is a descendant of the $lastfetch_hash, so we'll
3081             # be ff from that automatically.
3082         } @mergeinputs
3083         ) {
3084         # Otherwise:
3085         push @mergeinputs, $lastfetch_mergeinput;
3086     }
3087
3088     printdebug "fetch mergeinfos:\n";
3089     foreach my $mi (@mergeinputs) {
3090         if ($mi->{Info}) {
3091             printdebug " commit $mi->{Commit} $mi->{Info}\n";
3092         } else {
3093             printdebug sprintf " ReverseParents=%d Message=%s",
3094                 $mi->{ReverseParents}, $mi->{Message};
3095         }
3096     }
3097
3098     my $compat_info= pop @mergeinputs
3099         if $mergeinputs[$#mergeinputs]{Message};
3100
3101     @mergeinputs = grep { defined $_->{Commit} } @mergeinputs;
3102
3103     my $hash;
3104     if (@mergeinputs > 1) {
3105         # here we go, then:
3106         my $tree_commit = $mergeinputs[0]{Commit};
3107
3108         my $tree = cmdoutput @git, qw(cat-file commit), $tree_commit;
3109         $tree =~ m/\n\n/;  $tree = $`;
3110         $tree =~ m/^tree (\w+)$/m or die "$dsc_hash tree ?";
3111         $tree = $1;
3112
3113         # We use the changelog author of the package in question the
3114         # author of this pseudo-merge.  This is (roughly) correct if
3115         # this commit is simply representing aa non-dgit upload.
3116         # (Roughly because it does not record sponsorship - but we
3117         # don't have sponsorship info because that's in the .changes,
3118         # which isn't in the archivw.)
3119         #
3120         # But, it might be that we are representing archive history
3121         # updates (including in-archive copies).  These are not really
3122         # the responsibility of the person who created the .dsc, but
3123         # there is no-one whose name we should better use.  (The
3124         # author of the .dsc-named commit is clearly worse.)
3125
3126         my $useclogp = mergeinfo_getclogp $mergeinputs[0];
3127         my $author = clogp_authline $useclogp;
3128         my $cversion = getfield $useclogp, 'Version';
3129
3130         my $mcf = ".git/dgit/mergecommit";
3131         open MC, ">", $mcf or die "$mcf $!";
3132         print MC <<END or die $!;
3133 tree $tree
3134 END
3135
3136         my @parents = grep { $_->{Commit} } @mergeinputs;
3137         @parents = reverse @parents if $compat_info->{ReverseParents};
3138         print MC <<END or die $! foreach @parents;
3139 parent $_->{Commit}
3140 END
3141
3142         print MC <<END or die $!;
3143 author $author
3144 committer $author
3145
3146 END
3147
3148         if (defined $compat_info->{Message}) {
3149             print MC $compat_info->{Message} or die $!;
3150         } else {
3151             print MC <<END or die $!;
3152 Record $package ($cversion) in archive suite $csuite
3153
3154 Record that
3155 END
3156             my $message_add_info = sub {
3157                 my ($mi) = (@_);
3158                 my $mversion = mergeinfo_version $mi;
3159                 printf MC "  %-20s %s\n", $mversion, $mi->{Info}
3160                     or die $!;
3161             };
3162
3163             $message_add_info->($mergeinputs[0]);
3164             print MC <<END or die $!;
3165 should be treated as descended from
3166 END
3167             $message_add_info->($_) foreach @mergeinputs[1..$#mergeinputs];
3168         }
3169
3170         close MC or die $!;
3171         $hash = make_commit $mcf;
3172     } else {
3173         $hash = $mergeinputs[0]{Commit};
3174     }
3175     printdebug "fetch hash=$hash\n";
3176
3177     my $chkff = sub {
3178         my ($lasth, $what) = @_;
3179         return unless $lasth;
3180         die "$lasth $hash $what ?" unless is_fast_fwd($lasth, $hash);
3181     };
3182
3183     $chkff->($lastpush_hash, 'dgit repo server tip (last push)')
3184         if $lastpush_hash;
3185     $chkff->($lastfetch_hash, 'local tracking tip (last fetch)');
3186
3187     fetch_from_archive_record_1($hash);
3188
3189     if (defined $skew_warning_vsn) {
3190         mkpath '.git/dgit';
3191         printdebug "SKEW CHECK WANT $skew_warning_vsn\n";
3192         my $gotclogp = commit_getclogp($hash);
3193         my $got_vsn = getfield $gotclogp, 'Version';
3194         printdebug "SKEW CHECK GOT $got_vsn\n";
3195         if (version_compare($got_vsn, $skew_warning_vsn) < 0) {
3196             print STDERR <<END or die $!;
3197
3198 Warning: archive skew detected.  Using the available version:
3199 Archive allegedly contains    $skew_warning_vsn
3200 We were able to obtain only   $got_vsn
3201
3202 END
3203         }
3204     }
3205
3206     if ($lastfetch_hash ne $hash) {
3207         fetch_from_archive_record_2($hash);
3208     }
3209
3210     lrfetchref_used lrfetchref();
3211
3212     unshift @end, $del_lrfetchrefs;
3213     return $hash;
3214 }
3215
3216 sub set_local_git_config ($$) {
3217     my ($k, $v) = @_;
3218     runcmd @git, qw(config), $k, $v;
3219 }
3220
3221 sub setup_mergechangelogs (;$) {
3222     my ($always) = @_;
3223     return unless $always || access_cfg_bool(1, 'setup-mergechangelogs');
3224
3225     my $driver = 'dpkg-mergechangelogs';
3226     my $cb = "merge.$driver";
3227     my $attrs = '.git/info/attributes';
3228     ensuredir '.git/info';
3229
3230     open NATTRS, ">", "$attrs.new" or die "$attrs.new $!";
3231     if (!open ATTRS, "<", $attrs) {
3232         $!==ENOENT or die "$attrs: $!";
3233     } else {
3234         while (<ATTRS>) {
3235             chomp;
3236             next if m{^debian/changelog\s};
3237             print NATTRS $_, "\n" or die $!;
3238         }
3239         ATTRS->error and die $!;
3240         close ATTRS;
3241     }
3242     print NATTRS "debian/changelog merge=$driver\n" or die $!;
3243     close NATTRS;
3244
3245     set_local_git_config "$cb.name", 'debian/changelog merge driver';
3246     set_local_git_config "$cb.driver", 'dpkg-mergechangelogs -m %O %A %B %A';
3247
3248     rename "$attrs.new", "$attrs" or die "$attrs: $!";
3249 }
3250
3251 sub setup_useremail (;$) {
3252     my ($always) = @_;
3253     return unless $always || access_cfg_bool(1, 'setup-useremail');
3254
3255     my $setup = sub {
3256         my ($k, $envvar) = @_;
3257         my $v = access_cfg("user-$k", 'RETURN-UNDEF') // $ENV{$envvar};
3258         return unless defined $v;
3259         set_local_git_config "user.$k", $v;
3260     };
3261
3262     $setup->('email', 'DEBEMAIL');
3263     $setup->('name', 'DEBFULLNAME');
3264 }
3265
3266 sub ensure_setup_existing_tree () {
3267     my $k = "remote.$remotename.skipdefaultupdate";
3268     my $c = git_get_config $k;
3269     return if defined $c;
3270     set_local_git_config $k, 'true';
3271 }
3272
3273 sub setup_new_tree () {
3274     setup_mergechangelogs();
3275     setup_useremail();
3276 }
3277
3278 sub multisuite_suite_child ($$$) {
3279     my ($tsuite, $merginputs, $fn) = @_;
3280     # in child, sets things up, calls $fn->(), and returns undef
3281     # in parent, returns canonical suite name for $tsuite
3282     my $canonsuitefh = IO::File::new_tmpfile;
3283     my $pid = fork // die $!;
3284     if (!$pid) {
3285         $isuite = $tsuite;
3286         $us .= " [$isuite]";
3287         $debugprefix .= " ";
3288         progress "fetching $tsuite...";
3289         canonicalise_suite();
3290         print $canonsuitefh $csuite, "\n" or die $!;
3291         close $canonsuitefh or die $!;
3292         $fn->();
3293         return undef;
3294     }
3295     waitpid $pid,0 == $pid or die $!;
3296     fail "failed to obtain $tsuite: ".waitstatusmsg() if $? && $?!=256*4;
3297     seek $canonsuitefh,0,0 or die $!;
3298     local $csuite = <$canonsuitefh>;
3299     die $! unless defined $csuite && chomp $csuite;
3300     if ($? == 256*4) {
3301         printdebug "multisuite $tsuite missing\n";
3302         return $csuite;
3303     }
3304     printdebug "multisuite $tsuite ok (canon=$csuite)\n";
3305     push @$merginputs, {
3306         Ref => lrref,
3307         Info => $csuite,
3308     };
3309     return $csuite;
3310 }
3311
3312 sub fork_for_multisuite ($) {
3313     my ($before_fetch_merge) = @_;
3314     # if nothing unusual, just returns ''
3315     #
3316     # if multisuite:
3317     # returns 0 to caller in child, to do first of the specified suites
3318     # in child, $csuite is not yet set
3319     #
3320     # returns 1 to caller in parent, to finish up anything needed after
3321     # in parent, $csuite is set to canonicalised portmanteau
3322
3323     my $org_isuite = $isuite;
3324     my @suites = split /\,/, $isuite;
3325     return '' unless @suites > 1;
3326     printdebug "fork_for_multisuite: @suites\n";
3327
3328     my @mergeinputs;
3329
3330     my $cbasesuite = multisuite_suite_child($suites[0], \@mergeinputs,
3331                                             sub { });
3332     return 0 unless defined $cbasesuite;
3333
3334     fail "package $package missing in (base suite) $cbasesuite"
3335         unless @mergeinputs;
3336
3337     my @csuites = ($cbasesuite);
3338
3339     $before_fetch_merge->();
3340
3341     foreach my $tsuite (@suites[1..$#suites]) {
3342         my $csubsuite = multisuite_suite_child($tsuite, \@mergeinputs,
3343                                                sub {
3344             @end = ();
3345             fetch();
3346             exit 0;
3347         });
3348         # xxx collecte the ref here
3349
3350         $csubsuite =~ s/^\Q$cbasesuite\E-/-/;
3351         push @csuites, $csubsuite;
3352     }
3353
3354     foreach my $mi (@mergeinputs) {
3355         my $ref = git_get_ref $mi->{Ref};
3356         die "$mi->{Ref} ?" unless length $ref;
3357         $mi->{Commit} = $ref;
3358     }
3359
3360     $csuite = join ",", @csuites;
3361
3362     my $previous = git_get_ref lrref;
3363     if ($previous) {
3364         unshift @mergeinputs, {
3365             Commit => $previous,
3366             Info => "local combined tracking branch",
3367             Warning =>
3368  "archive seems to have rewound: local tracking branch is ahead!",
3369         };
3370     }
3371
3372     foreach my $ix (0..$#mergeinputs) {
3373         $mergeinputs[$ix]{Index} = $ix;
3374     }
3375
3376     @mergeinputs = sort {
3377         -version_compare(mergeinfo_version $a,
3378                          mergeinfo_version $b) # highest version first
3379             or
3380         $a->{Index} <=> $b->{Index}; # earliest in spec first
3381     } @mergeinputs;
3382
3383     my @needed;
3384
3385   NEEDED:
3386     foreach my $mi (@mergeinputs) {
3387         printdebug "multisuite merge check $mi->{Info}\n";
3388         foreach my $previous (@needed) {
3389             next unless is_fast_fwd $mi->{Commit}, $previous->{Commit};
3390             printdebug "multisuite merge un-needed $previous->{Info}\n";
3391             next NEEDED;
3392         }
3393         push @needed, $mi;
3394         printdebug "multisuite merge this-needed\n";
3395         $mi->{Character} = '+';
3396     }
3397
3398     $needed[0]{Character} = '*';
3399
3400     my $output = $needed[0]{Commit};
3401
3402     if (@needed > 1) {
3403         printdebug "multisuite merge nontrivial\n";
3404         my $tree = cmdoutput qw(git rev-parse), $needed[0]{Commit}.':';
3405
3406         my $commit = "tree $tree\n";
3407         my $msg = "Combine archive branches $csuite [dgit]\n\n".
3408             "Input branches:\n";
3409
3410         foreach my $mi (sort { $a->{Index} <=> $b->{Index} } @mergeinputs) {
3411             printdebug "multisuite merge include $mi->{Info}\n";
3412             $mi->{Character} //= ' ';
3413             $commit .= "parent $mi->{Commit}\n";
3414             $msg .= sprintf " %s  %-25s %s\n",
3415                 $mi->{Character},
3416                 (mergeinfo_version $mi),
3417                 $mi->{Info};
3418         }
3419         my $authline = clogp_authline mergeinfo_getclogp $needed[0];
3420         $msg .= "\nKey\n".
3421             " * marks the highest version branch, which choose to use\n".
3422             " + marks each branch which was not already an ancestor\n\n".
3423             "[dgit multi-suite $csuite]\n";
3424         $commit .=
3425             "author $authline\n".
3426             "committer $authline\n\n";
3427         $output = make_commit_text $commit.$msg;
3428         printdebug "multisuite merge generated $output\n";
3429     }
3430
3431     fetch_from_archive_record_1($output);
3432     fetch_from_archive_record_2($output);
3433
3434     progress "calculated combined tracking suite $csuite";
3435
3436     return 1;
3437 }
3438
3439 sub clone_set_head () {
3440     open H, "> .git/HEAD" or die $!;
3441     print H "ref: ".lref()."\n" or die $!;
3442     close H or die $!;
3443 }
3444 sub clone_finish ($) {
3445     my ($dstdir) = @_;
3446     runcmd @git, qw(reset --hard), lrref();
3447     runcmd qw(bash -ec), <<'END';
3448         set -o pipefail
3449         git ls-tree -r --name-only -z HEAD | \
3450         xargs -0r touch -h -r . --
3451 END
3452     printdone "ready for work in $dstdir";
3453 }
3454
3455 sub clone ($) {
3456     my ($dstdir) = @_;
3457     badusage "dry run makes no sense with clone" unless act_local();
3458
3459     my $multi_fetched = fork_for_multisuite(sub {
3460         printdebug "multi clone before fetch merge\n";
3461         changedir $dstdir;
3462     });
3463     if ($multi_fetched) {
3464         printdebug "multi clone after fetch merge\n";
3465         clone_set_head();
3466         clone_finish($dstdir);
3467         exit 0;
3468     }
3469     printdebug "clone main body\n";
3470
3471     canonicalise_suite();
3472     my $hasgit = check_for_git();
3473     mkdir $dstdir or fail "create \`$dstdir': $!";
3474     changedir $dstdir;
3475     runcmd @git, qw(init -q);
3476     clone_set_head();
3477     my $giturl = access_giturl(1);
3478     if (defined $giturl) {
3479         runcmd @git, qw(remote add), 'origin', $giturl;
3480     }
3481     if ($hasgit) {
3482         progress "fetching existing git history";
3483         git_fetch_us();
3484         runcmd_ordryrun_local @git, qw(fetch origin);
3485     } else {
3486         progress "starting new git history";
3487     }
3488     fetch_from_archive() or no_such_package;
3489     my $vcsgiturl = $dsc->{'Vcs-Git'};
3490     if (length $vcsgiturl) {
3491         $vcsgiturl =~ s/\s+-b\s+\S+//g;
3492         runcmd @git, qw(remote add vcs-git), $vcsgiturl;
3493     }
3494     setup_new_tree();
3495     clone_finish($dstdir);
3496 }
3497
3498 sub fetch () {
3499     canonicalise_suite();
3500     if (check_for_git()) {
3501         git_fetch_us();
3502     }
3503     fetch_from_archive() or no_such_package();
3504     printdone "fetched into ".lrref();
3505 }
3506
3507 sub pull () {
3508     my $multi_fetched = fork_for_multisuite(sub { });
3509     fetch() unless $multi_fetched; # parent
3510     return if $multi_fetched eq '0'; # child
3511     runcmd_ordryrun_local @git, qw(merge -m),"Merge from $csuite [dgit]",
3512         lrref();
3513     printdone "fetched to ".lrref()." and merged into HEAD";
3514 }
3515
3516 sub check_not_dirty () {
3517     foreach my $f (qw(local-options local-patch-header)) {
3518         if (stat_exists "debian/source/$f") {
3519             fail "git tree contains debian/source/$f";
3520         }
3521     }
3522
3523     return if $ignoredirty;
3524
3525     my @cmd = (@git, qw(diff --quiet HEAD));
3526     debugcmd "+",@cmd;
3527     $!=0; $?=-1; system @cmd;
3528     return if !$?;
3529     if ($?==256) {
3530         fail "working tree is dirty (does not match HEAD)";
3531     } else {
3532         failedcmd @cmd;
3533     }
3534 }
3535
3536 sub commit_admin ($) {
3537     my ($m) = @_;
3538     progress "$m";
3539     runcmd_ordryrun_local @git, qw(commit -m), $m;
3540 }
3541
3542 sub commit_quilty_patch () {
3543     my $output = cmdoutput @git, qw(status --porcelain);
3544     my %adds;
3545     foreach my $l (split /\n/, $output) {
3546         next unless $l =~ m/\S/;
3547         if ($l =~ m{^(?:\?\?| M) (.pc|debian/patches)}) {
3548             $adds{$1}++;
3549         }
3550     }
3551     delete $adds{'.pc'}; # if there wasn't one before, don't add it
3552     if (!%adds) {
3553         progress "nothing quilty to commit, ok.";
3554         return;
3555     }
3556     my @adds = map { s/[][*?\\]/\\$&/g; $_; } sort keys %adds;
3557     runcmd_ordryrun_local @git, qw(add -f), @adds;
3558     commit_admin <<END
3559 Commit Debian 3.0 (quilt) metadata
3560
3561 [dgit ($our_version) quilt-fixup]
3562 END
3563 }
3564
3565 sub get_source_format () {
3566     my %options;
3567     if (open F, "debian/source/options") {
3568         while (<F>) {
3569             next if m/^\s*\#/;
3570             next unless m/\S/;
3571             s/\s+$//; # ignore missing final newline
3572             if (m/\s*\#\s*/) {
3573                 my ($k, $v) = ($`, $'); #');
3574                 $v =~ s/^"(.*)"$/$1/;
3575                 $options{$k} = $v;
3576             } else {
3577                 $options{$_} = 1;
3578             }
3579         }
3580         F->error and die $!;
3581         close F;
3582     } else {
3583         die $! unless $!==&ENOENT;
3584     }
3585
3586     if (!open F, "debian/source/format") {
3587         die $! unless $!==&ENOENT;
3588         return '';
3589     }
3590     $_ = <F>;
3591     F->error and die $!;
3592     chomp;
3593     return ($_, \%options);
3594 }
3595
3596 sub madformat_wantfixup ($) {
3597     my ($format) = @_;
3598     return 0 unless $format eq '3.0 (quilt)';
3599     our $quilt_mode_warned;
3600     if ($quilt_mode eq 'nocheck') {
3601         progress "Not doing any fixup of \`$format' due to".
3602             " ----no-quilt-fixup or --quilt=nocheck"
3603             unless $quilt_mode_warned++;
3604         return 0;
3605     }
3606     progress "Format \`$format', need to check/update patch stack"
3607         unless $quilt_mode_warned++;
3608     return 1;
3609 }
3610
3611 sub maybe_split_brain_save ($$$) {
3612     my ($headref, $dgitview, $msg) = @_;
3613     # => message fragment "$saved" describing disposition of $dgitview
3614     return "commit id $dgitview" unless defined $split_brain_save;
3615     my @cmd = (shell_cmd "cd ../../../..",
3616                @git, qw(update-ref -m),
3617                "dgit --dgit-view-save $msg HEAD=$headref",
3618                $split_brain_save, $dgitview);
3619     runcmd @cmd;
3620     return "and left in $split_brain_save";
3621 }
3622
3623 # An "infopair" is a tuple [ $thing, $what ]
3624 # (often $thing is a commit hash; $what is a description)
3625
3626 sub infopair_cond_equal ($$) {
3627     my ($x,$y) = @_;
3628     $x->[0] eq $y->[0] or fail <<END;
3629 $x->[1] ($x->[0]) not equal to $y->[1] ($y->[0])
3630 END
3631 };
3632
3633 sub infopair_lrf_tag_lookup ($$) {
3634     my ($tagnames, $what) = @_;
3635     # $tagname may be an array ref
3636     my @tagnames = ref $tagnames ? @$tagnames : ($tagnames);
3637     printdebug "infopair_lrfetchref_tag_lookup $what @tagnames\n";
3638     foreach my $tagname (@tagnames) {
3639         my $lrefname = lrfetchrefs."/tags/$tagname";
3640         my $tagobj = $lrfetchrefs_f{$lrefname};
3641         next unless defined $tagobj;
3642         printdebug "infopair_lrfetchref_tag_lookup $tagobj $tagname $what\n";
3643         return [ git_rev_parse($tagobj), $what ];
3644     }
3645     fail @tagnames==1 ? <<END : <<END;
3646 Wanted tag $what (@tagnames) on dgit server, but not found
3647 END
3648 Wanted tag $what (one of: @tagnames) on dgit server, but not found
3649 END
3650 }
3651
3652 sub infopair_cond_ff ($$) {
3653     my ($anc,$desc) = @_;
3654     is_fast_fwd($anc->[0], $desc->[0]) or fail <<END;
3655 $anc->[1] ($anc->[0]) .. $desc->[1] ($desc->[0]) is not fast forward
3656 END
3657 };
3658
3659 sub pseudomerge_version_check ($$) {
3660     my ($clogp, $archive_hash) = @_;
3661
3662     my $arch_clogp = commit_getclogp $archive_hash;
3663     my $i_arch_v = [ (getfield $arch_clogp, 'Version'),
3664                      'version currently in archive' ];
3665     if (defined $overwrite_version) {
3666         if (length $overwrite_version) {
3667             infopair_cond_equal([ $overwrite_version,
3668                                   '--overwrite= version' ],
3669                                 $i_arch_v);
3670         } else {
3671             my $v = $i_arch_v->[0];
3672             progress "Checking package changelog for archive version $v ...";
3673             eval {
3674                 my @xa = ("-f$v", "-t$v");
3675                 my $vclogp = parsechangelog @xa;
3676                 my $cv = [ (getfield $vclogp, 'Version'),
3677                            "Version field from dpkg-parsechangelog @xa" ];
3678                 infopair_cond_equal($i_arch_v, $cv);
3679             };
3680             if ($@) {
3681                 $@ =~ s/^dgit: //gm;
3682                 fail "$@".
3683                     "Perhaps debian/changelog does not mention $v ?";
3684             }
3685         }
3686     }
3687     
3688     printdebug "pseudomerge_version_check i_arch_v @$i_arch_v\n";
3689     return $i_arch_v;
3690 }
3691
3692 sub pseudomerge_make_commit ($$$$ $$) {
3693     my ($clogp, $dgitview, $archive_hash, $i_arch_v,
3694         $msg_cmd, $msg_msg) = @_;
3695     progress "Declaring that HEAD inciudes all changes in $i_arch_v->[0]...";
3696
3697     my $tree = cmdoutput qw(git rev-parse), "${dgitview}:";
3698     my $authline = clogp_authline $clogp;
3699
3700     chomp $msg_msg;
3701     $msg_cmd .=
3702         !defined $overwrite_version ? ""
3703         : !length  $overwrite_version ? " --overwrite"
3704         : " --overwrite=".$overwrite_version;
3705
3706     mkpath '.git/dgit';
3707     my $pmf = ".git/dgit/pseudomerge";
3708     open MC, ">", $pmf or die "$pmf $!";
3709     print MC <<END or die $!;
3710 tree $tree
3711 parent $dgitview
3712 parent $archive_hash
3713 author $authline
3714 committer $authline
3715
3716 $msg_msg
3717
3718 [$msg_cmd]
3719 END
3720     close MC or die $!;
3721
3722     return make_commit($pmf);
3723 }
3724