Debian/Dgit.pm

   1 # -*- perl -*-
   2
   3 package Debian::Dgit;
   4
   5 use strict;
   6 use warnings;
   7
   8 use POSIX;
   9 use IO::Handle;
  10
  11 BEGIN {
  12     use Exporter   ();
  13     our ($VERSION, @ISA, @EXPORT, @EXPORT_OK, %EXPORT_TAGS);
  14
  15     $VERSION     = 1.00;
  16     @ISA         = qw(Exporter);
  17     @EXPORT      = qw(debiantag server_branch server_ref
  18                       stat_exists git_for_each_ref
  19                       git_for_each_tag_referring
  20                       $package_re $component_re $deliberately_re
  21                       $branchprefix
  22                       initdebug enabledebug enabledebuglevel
  23                       printdebug debugcmd
  24                       $debugprefix *debuglevel *DEBUG
  25                       shellquote printcmd);
  26     %EXPORT_TAGS = ( policyflags => [qw(NOFFCHECK FRESHREPO)] );
  27     @EXPORT_OK   = @{ $EXPORT_TAGS{policyflags} };
  28 }
  29
  30 our @EXPORT_OK;
  31
  32 our $package_re = '[0-9a-z][-+.0-9a-z]*';
  33 our $component_re = '[0-9a-zA-Z][-+.0-9a-zA-Z]*';
  34 our $deliberately_re = "(?:TEST-)?$package_re";
  35 our $branchprefix = 'dgit';
  36
  37 # policy hook exit status bits
  38 # see dgit-repos-server head comment for documentation
  39 # 1 is reserved in case something fails with `exit 1' and to spot
  40 # dynamic loader, runtime, etc., failures, which report 127 or 255
  41 sub NOFFCHECK () { return 0x2; }
  42 sub FRESHREPO () { return 0x4; }
  43
  44 sub printdebug;
  45 sub shellquote;
  46 sub printcmd;
  47 sub debugcmd;
  48
  49 sub debiantag ($) {
  50     my ($v) = @_;
  51     $v =~ y/~:/_%/;
  52     return "debian/$v";
  53 }
  54
  55 sub server_branch ($) { return "$branchprefix/$_[0]"; }
  56 sub server_ref ($) { return "refs/".server_branch($_[0]); }
  57
  58 sub stat_exists ($) {
  59     my ($f) = @_;
  60     return 1 if stat $f;
  61     return 0 if $!==&ENOENT;
  62     die "stat $f: $!";
  63 }
  64
  65 sub git_for_each_ref ($$) {
  66     my ($pattern,$func) = @_;
  67     # calls $func->($objid,$objtype,$fullrefname,$reftail);
  68     # $reftail is RHS of ref after refs/\w+/
  69     # breaks if $pattern matches any ref `refs/blah' where blah has no `/'
  70     my @cmd = (qw(git for-each-ref), $pattern);
  71     open GFER, "-|", @cmd or die $!;
  72     debugcmd "|", @cmd;
  73     while (<GFER>) {
  74         chomp or die "$_ ?";
  75         printdebug "|> ", $_, "\n";
  76         m#^(\w+)\s+(\w+)\s+(refs/\w+/(\S+))$# or die "$_ ?";
  77         $func->($1,$2,$3,$4);
  78     }
  79     $!=0; $?=0; close GFER or die "$pattern $? $!";
  80 }
  81
  82 sub git_for_each_tag_referring ($$) {
  83     my ($objreferring, $func) = @_;
  84     # calls $func->($objid,$fullrefname,$tagname);
  85     printdebug "git_for_each_tag_referring ",
  86         ($objreferring // 'UNDEF'),"\n";
  87     git_for_each_ref('refs/tags', sub {
  88         my ($objid,$objtype,$fullrefname,$tagname) = @_;
  89         next unless $objtype eq 'tag';
  90         next if defined $objreferring and $objid ne $objreferring;
  91         $func->($objid,$fullrefname,$tagname);
  92     });
  93 }
  94
  95 our $debugprefix;
  96 our $debuglevel = 0;
  97
  98 sub initdebug ($) {
  99     ($debugprefix) = @_;
 100     open DEBUG, ">/dev/null" or die $!;
 101 }
 102
 103 sub enabledebug () {
 104     open DEBUG, ">&STDERR" or die $!;
 105     DEBUG->autoflush(1);
 106     $debuglevel ||= 1;
 107 }
 108
 109 sub enabledebuglevel ($) {
 110     my ($newlevel) = @_; # may be undef (eg from env var)
 111     die if $debuglevel;
 112     $newlevel //= 0;
 113     $newlevel += 0;
 114     return unless $newlevel;
 115     $debuglevel = $newlevel;
 116     enabledebug();
 117 }
 118
 119 sub printdebug {
 120     print DEBUG $debugprefix, @_ or die $! if $debuglevel>0;
 121 }
 122
 123 sub shellquote {
 124     my @out;
 125     local $_;
 126     foreach my $a (@_) {
 127         $_ = $a;
 128         if (!length || m{[^-=_./0-9a-z]}i) {
 129             s{['\\]}{'\\$&'}g;
 130             push @out, "'$_'";
 131         } else {
 132             push @out, $_;
 133         }
 134     }
 135     return join ' ', @out;
 136 }
 137
 138 sub printcmd {
 139     my $fh = shift @_;
 140     my $intro = shift @_;
 141     print $fh $intro," " or die $!;
 142     print $fh shellquote @_ or die $!;
 143     print $fh "\n" or die $!;
 144 }
 145
 146 sub debugcmd {
 147     my $extraprefix = shift @_;
 148     printcmd(\*DEBUG,$debugprefix.$extraprefix,@_) if $debuglevel>0;
 149 }
 150
 151 1;