Debian/Dgit.pm

   1 # -*- perl -*-
   2
   3 package Debian::Dgit;
   4
   5 use strict;
   6 use warnings;
   7
   8 use POSIX;
   9 use IO::Handle;
  10
  11 BEGIN {
  12     use Exporter   ();
  13     our ($VERSION, @ISA, @EXPORT, @EXPORT_OK, %EXPORT_TAGS);
  14
  15     $VERSION     = 1.00;
  16     @ISA         = qw(Exporter);
  17     @EXPORT      = qw(debiantag server_branch server_ref
  18                       stat_exists git_for_each_ref
  19                       git_for_each_tag_referring
  20                       $package_re $component_re $deliberately_re
  21                       $branchprefix
  22                       initdebug enabledebug enabledebuglevel
  23                       printdebug debugcmd
  24                       $debugprefix *debuglevel *DEBUG
  25                       shellquote printcmd);
  26     %EXPORT_TAGS = ( policyflags => [qw(NOFFCHECK FRESHREPO)] );
  27     @EXPORT_OK   = @{ $EXPORT_TAGS{policyflags} };
  28 }
  29
  30 our @EXPORT_OK;
  31
  32 our $package_re = '[0-9a-z][-+.0-9a-z]*';
  33 our $component_re = '[0-9a-zA-Z][-+.0-9a-zA-Z]*';
  34 our $deliberately_re = "(?:TEST-)?$package_re";
  35 our $branchprefix = 'dgit';
  36
  37 # policy hook exit status bits
  38 # see dgit-repos-server head comment for documentation
  39 # 1 is reserved in case something fails with `exit 1'
  40 sub NOFFCHECK () { return 0x2; }
  41 sub FRESHREPO () { return 0x4; }
  42 # 0x80 is reserved
  43
  44 sub debiantag ($) {
  45     my ($v) = @_;
  46     $v =~ y/~:/_%/;
  47     return "debian/$v";
  48 }
  49
  50 sub server_branch ($) { return "$branchprefix/$_[0]"; }
  51 sub server_ref ($) { return "refs/".server_branch($_[0]); }
  52
  53 sub stat_exists ($) {
  54     my ($f) = @_;
  55     return 1 if stat $f;
  56     return 0 if $!==&ENOENT;
  57     die "stat $f: $!";
  58 }
  59
  60 sub git_for_each_ref ($$) {
  61     my ($pattern,$func) = @_;
  62     # calls $func->($objid,$objtype,$fullrefname,$reftail);
  63     # $reftail is RHS of ref after refs/\w+/
  64     # breaks if $pattern matches any ref `refs/blah' where blah has no `/'
  65     open GFER, "-|", qw(git for-each-ref), $pattern or die $!;
  66     while (<GFER>) {
  67         m#^(\w+)\s+(\w+)\s+(refs/\w+/(\S+))\s# or die "$_ ?";
  68         $func->($1,$2,$3,$4);
  69     }
  70     $!=0; $?=0; close GFER or die "$pattern $? $!";
  71 }
  72
  73 sub git_for_each_tag_referring ($$) {
  74     my ($objreferring, $func) = @_;
  75     # calls $func->($objid,$fullrefname,$tagname);
  76     git_for_each_ref('refs/tags', sub {
  77         my ($objid,$objtype,$fullrefname,$tagname) = @_;
  78         next unless $objtype eq 'tag';
  79         next if defined $objreferring and $objid ne $objreferring;
  80         $func->($objid,$fullrefname,$tagname);
  81     });
  82 }
  83
  84 our $debugprefix;
  85 our $debuglevel = 0;
  86
  87 sub initdebug ($) {
  88     ($debugprefix) = @_;
  89     open DEBUG, ">/dev/null" or die $!;
  90 }
  91
  92 sub enabledebug () {
  93     open DEBUG, ">&STDERR" or die $!;
  94     DEBUG->autoflush(1);
  95     $debuglevel ||= 1;
  96 }
  97
  98 sub enabledebuglevel ($) {
  99     my ($newlevel) = @_; # may be undef (eg from env var)
 100     die if $debuglevel;
 101     $newlevel //= 0;
 102     $newlevel += 0;
 103     return unless $newlevel;
 104     $debuglevel = $newlevel;
 105     enabledebug();
 106 }
 107
 108 sub printdebug {
 109     print DEBUG $debugprefix, @_ or die $! if $debuglevel>0;
 110 }
 111
 112 sub shellquote {
 113     my @out;
 114     local $_;
 115     foreach my $a (@_) {
 116         $_ = $a;
 117         if (!length || m{[^-=_./0-9a-z]}i) {
 118             s{['\\]}{'\\$&'}g;
 119             push @out, "'$_'";
 120         } else {
 121             push @out, $_;
 122         }
 123     }
 124     return join ' ', @out;
 125 }
 126
 127 sub printcmd {
 128     my $fh = shift @_;
 129     my $intro = shift @_;
 130     print $fh $intro," " or die $!;
 131     print $fh shellquote @_ or die $!;
 132     print $fh "\n" or die $!;
 133 }
 134
 135 sub debugcmd {
 136     my $extraprefix = shift @_;
 137     printcmd(\*DEBUG,$debugprefix.$extraprefix,@_) if $debuglevel>0;
 138 }
 139
 140 1;