Debian/Dgit.pm

   1 # -*- perl -*-
   2 # dgit
   3 # Debian::Dgit: functions common to dgit and its helpers and servers
   4 #
   5 # Copyright (C) 2015-2016  Ian Jackson
   6 #
   7 #    This program is free software; you can redistribute it and/or modify
   8 #    it under the terms of the GNU General Public License as published by
   9 #    the Free Software Foundation; either version 3 of the License, or
  10 #    (at your option) any later version.
  11 #
  12 #    This program is distributed in the hope that it will be useful,
  13 #    but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 #    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 #    GNU General Public License for more details.
  16 #
  17 #    You should have received a copy of the GNU General Public License
  18 #    along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 package Debian::Dgit;
  21
  22 use strict;
  23 use warnings;
  24
  25 use Carp;
  26 use POSIX;
  27 use IO::Handle;
  28 use Config;
  29 use Digest::SHA;
  30 use Data::Dumper;
  31 use IPC::Open2;
  32 use File::Path;
  33 use File::Basename;
  34
  35 BEGIN {
  36     use Exporter   ();
  37     our ($VERSION, @ISA, @EXPORT, @EXPORT_OK, %EXPORT_TAGS);
  38
  39     $VERSION     = 1.00;
  40     @ISA         = qw(Exporter);
  41     @EXPORT      = qw(setup_sigwarn forkcheck_setup forkcheck_mainprocess
  42                       dep14_version_mangle
  43                       debiantags debiantag_old debiantag_new
  44                       server_branch server_ref
  45                       stat_exists link_ltarget
  46                       hashfile
  47                       fail ensuredir must_getcwd executable_on_path
  48                       waitstatusmsg failedcmd_waitstatus
  49                       failedcmd_report_cmd failedcmd
  50                       runcmd cmdoutput cmdoutput_errok
  51                       git_rev_parse git_cat_file
  52                       git_get_ref git_get_symref git_for_each_ref
  53                       git_for_each_tag_referring is_fast_fwd
  54                       git_check_unmodified
  55                       $package_re $component_re $deliberately_re
  56                       $distro_re $versiontag_re $series_filename_re
  57                       $extra_orig_namepart_re
  58                       $git_null_obj
  59                       $branchprefix
  60                       $ffq_refprefix
  61                       initdebug enabledebug enabledebuglevel
  62                       printdebug debugcmd
  63                       $debugprefix *debuglevel *DEBUG
  64                       shellquote printcmd messagequote
  65                       $negate_harmful_gitattrs
  66                       changedir git_slurp_config_src
  67                       playtree_setup);
  68     # implicitly uses $main::us
  69     %EXPORT_TAGS = ( policyflags => [qw(NOFFCHECK FRESHREPO NOCOMMITCHECK)],
  70                      playground => [qw(record_maindir $maindir $local_git_cfg
  71                                        $maindir_gitdir $maindir_gitcommon
  72                                        fresh_playground
  73                                        ensure_a_playground)]);
  74     @EXPORT_OK   = ( @{ $EXPORT_TAGS{policyflags} },
  75                      @{ $EXPORT_TAGS{playground} } );
  76 }
  77
  78 our @EXPORT_OK;
  79
  80 our $package_re = '[0-9a-z][-+.0-9a-z]*';
  81 our $component_re = '[0-9a-zA-Z][-+.0-9a-zA-Z]*';
  82 our $deliberately_re = "(?:TEST-)?$package_re";
  83 our $distro_re = $component_re;
  84 our $versiontag_re = qr{[-+.\%_0-9a-zA-Z/]+};
  85 our $branchprefix = 'dgit';
  86 our $series_filename_re = qr{(?:^|\.)series(?!\n)$}s;
  87 our $extra_orig_namepart_re = qr{[-0-9a-z]+};
  88 our $git_null_obj = '0' x 40;
  89 our $ffq_refprefix = 'ffq-prev';
  90
  91 # policy hook exit status bits
  92 # see dgit-repos-server head comment for documentation
  93 # 1 is reserved in case something fails with `exit 1' and to spot
  94 # dynamic loader, runtime, etc., failures, which report 127 or 255
  95 sub NOFFCHECK () { return 0x2; }
  96 sub FRESHREPO () { return 0x4; }
  97 sub NOCOMMITCHECK () { return 0x8; }
  98
  99 our $debugprefix;
 100 our $debuglevel = 0;
 101
 102 our $negate_harmful_gitattrs = "-text -eol -crlf -ident -filter";
 103
 104 our $forkcheck_mainprocess;
 105
 106 sub forkcheck_setup () {
 107     $forkcheck_mainprocess = $$;
 108 }
 109
 110 sub forkcheck_mainprocess () {
 111     # You must have called forkcheck_setup or setup_sigwarn already
 112     getppid != $forkcheck_mainprocess;
 113 }
 114
 115 sub setup_sigwarn () {
 116     forkcheck_setup();
 117     $SIG{__WARN__} = sub {
 118         confess $_[0] if forkcheck_mainprocess;
 119     };
 120 }
 121
 122 sub initdebug ($) {
 123     ($debugprefix) = @_;
 124     open DEBUG, ">/dev/null" or die $!;
 125 }
 126
 127 sub enabledebug () {
 128     open DEBUG, ">&STDERR" or die $!;
 129     DEBUG->autoflush(1);
 130     $debuglevel ||= 1;
 131 }
 132
 133 sub enabledebuglevel ($) {
 134     my ($newlevel) = @_; # may be undef (eg from env var)
 135     die if $debuglevel;
 136     $newlevel //= 0;
 137     $newlevel += 0;
 138     return unless $newlevel;
 139     $debuglevel = $newlevel;
 140     enabledebug();
 141 }
 142
 143 sub printdebug {
 144     print DEBUG $debugprefix, @_ or die $! if $debuglevel>0;
 145 }
 146
 147 sub messagequote ($) {
 148     local ($_) = @_;
 149     s{\\}{\\\\}g;
 150     s{\n}{\\n}g;
 151     s{\x08}{\\b}g;
 152     s{\t}{\\t}g;
 153     s{[\000-\037\177]}{ sprintf "\\x%02x", ord $& }ge;
 154     $_;
 155 }
 156
 157 sub shellquote {
 158     my @out;
 159     local $_;
 160     defined or confess 'internal error' foreach @_;
 161     foreach my $a (@_) {
 162         $_ = $a;
 163         if (!length || m{[^-=_./:0-9a-z]}i) {
 164             s{['\\]}{'\\$&'}g;
 165             push @out, "'$_'";
 166         } else {
 167             push @out, $_;
 168         }
 169     }
 170     return join ' ', @out;
 171 }
 172
 173 sub printcmd {
 174     my $fh = shift @_;
 175     my $intro = shift @_;
 176     print $fh $intro," " or die $!;
 177     print $fh shellquote @_ or die $!;
 178     print $fh "\n" or die $!;
 179 }
 180
 181 sub debugcmd {
 182     my $extraprefix = shift @_;
 183     printcmd(\*DEBUG,$debugprefix.$extraprefix,@_) if $debuglevel>0;
 184 }
 185
 186 sub dep14_version_mangle ($) {
 187     my ($v) = @_;
 188     # DEP-14 patch proposed 2016-11-09  "Version Mangling"
 189     $v =~ y/~:/_%/;
 190     $v =~ s/\.(?=\.|$|lock$)/.#/g;
 191     return $v;
 192 }
 193
 194 sub debiantag_old ($$) {
 195     my ($v,$distro) = @_;
 196     return "$distro/". dep14_version_mangle $v;
 197 }
 198
 199 sub debiantag_new ($$) {
 200     my ($v,$distro) = @_;
 201     return "archive/$distro/".dep14_version_mangle $v;
 202 }
 203
 204 sub debiantags ($$) {
 205     my ($version,$distro) = @_;
 206     map { $_->($version, $distro) } (\&debiantag_new, \&debiantag_old);
 207 }
 208
 209 sub server_branch ($) { return "$branchprefix/$_[0]"; }
 210 sub server_ref ($) { return "refs/".server_branch($_[0]); }
 211
 212 sub stat_exists ($) {
 213     my ($f) = @_;
 214     return 1 if stat $f;
 215     return 0 if $!==&ENOENT;
 216     die "stat $f: $!";
 217 }
 218
 219 sub _us () {
 220     $::us // ($0 =~ m#[^/]*$#, $&);
 221 }
 222
 223 sub fail {
 224     my $s = "@_\n";
 225     $s =~ s/\n\n$/\n/;
 226     my $prefix = _us().": ";
 227     $s =~ s/^/$prefix/gm;
 228     die $s;
 229 }
 230
 231 sub ensuredir ($) {
 232     my ($dir) = @_; # does not create parents
 233     return if mkdir $dir;
 234     return if $! == EEXIST;
 235     die "mkdir $dir: $!";
 236 }
 237
 238 sub must_getcwd () {
 239     my $d = getcwd();
 240     defined $d or fail "getcwd failed: $!";
 241     return $d;
 242 }
 243
 244 sub executable_on_path ($) {
 245     my ($program) = @_;
 246     return 1 if $program =~ m{/};
 247     my @path = split /:/, ($ENV{PATH} // "/usr/local/bin:/bin:/usr/bin");
 248     foreach my $pe (@path) {
 249         my $here = "$pe/$program";
 250         return $here if stat_exists $here && -x _;
 251     }
 252     return undef;
 253 }
 254
 255 our @signames = split / /, $Config{sig_name};
 256
 257 sub waitstatusmsg () {
 258     if (!$?) {
 259         return "terminated, reporting successful completion";
 260     } elsif (!($? & 255)) {
 261         return "failed with error exit status ".WEXITSTATUS($?);
 262     } elsif (WIFSIGNALED($?)) {
 263         my $signum=WTERMSIG($?);
 264         return "died due to fatal signal ".
 265             ($signames[$signum] // "number $signum").
 266             ($? & 128 ? " (core dumped)" : ""); # POSIX(3pm) has no WCOREDUMP
 267     } else {
 268         return "failed with unknown wait status ".$?;
 269     }
 270 }
 271
 272 sub failedcmd_report_cmd {
 273     my $intro = shift @_;
 274     $intro //= "failed command";
 275     { local ($!); printcmd \*STDERR, _us().": $intro:", @_ or die $!; };
 276 }
 277
 278 sub failedcmd_waitstatus {
 279     if ($? < 0) {
 280         return "failed to fork/exec: $!";
 281     } elsif ($?) {
 282         return "subprocess ".waitstatusmsg();
 283     } else {
 284         return "subprocess produced invalid output";
 285     }
 286 }
 287
 288 sub failedcmd {
 289     # Expects $!,$? as set by close - see below.
 290     # To use with system(), set $?=-1 first.
 291     #
 292     # Actual behaviour of perl operations:
 293     #   success              $!==0       $?==0       close of piped open
 294     #   program failed       $!==0       $? >0       close of piped open
 295     #   syscall failure      $! >0       $?=-1       close of piped open
 296     #   failure              $! >0       unchanged   close of something else
 297     #   success              trashed     $?==0       system
 298     #   program failed       trashed     $? >0       system
 299     #   syscall failure      $! >0       unchanged   system
 300     failedcmd_report_cmd undef, @_;
 301     fail failedcmd_waitstatus();
 302 }
 303
 304 sub runcmd {
 305     debugcmd "+",@_;
 306     $!=0; $?=-1;
 307     failedcmd @_ if system @_;
 308 }
 309
 310 sub cmdoutput_errok {
 311     confess Dumper(\@_)." ?" if grep { !defined } @_;
 312     debugcmd "|",@_;
 313     open P, "-|", @_ or die "$_[0] $!";
 314     my $d;
 315     $!=0; $?=0;
 316     { local $/ = undef; $d = <P>; }
 317     die $! if P->error;
 318     if (!close P) { printdebug "=>!$?\n"; return undef; }
 319     chomp $d;
 320     if ($debuglevel > 0) {
 321         $d =~ m/^.*/;
 322         my $dd = $&;
 323         my $more = (length $' ? '...' : ''); #');
 324         $dd =~ s{[^\n -~]|\\}{ sprintf "\\x%02x", ord $& }ge;
 325         printdebug "=> \`$dd'",$more,"\n";
 326     }
 327     return $d;
 328 }
 329
 330 sub cmdoutput {
 331     my $d = cmdoutput_errok @_;
 332     defined $d or failedcmd @_;
 333     return $d;
 334 }
 335
 336 sub link_ltarget ($$) {
 337     my ($old,$new) = @_;
 338     lstat $old or return undef;
 339     if (-l _) {
 340         $old = cmdoutput qw(realpath  --), $old;
 341     }
 342     my $r = link $old, $new;
 343     $r = symlink $old, $new if !$r && $!==EXDEV;
 344     $r or die "(sym)link $old $new: $!";
 345 }
 346
 347 sub hashfile ($) {
 348     my ($fn) = @_;
 349     my $h = Digest::SHA->new(256);
 350     $h->addfile($fn);
 351     return $h->hexdigest();
 352 }
 353
 354 sub git_rev_parse ($) {
 355     return cmdoutput qw(git rev-parse), "$_[0]~0";
 356 }
 357
 358 sub git_cat_file ($;$) {
 359     my ($objname, $etype) = @_;
 360     # => ($type, $data) or ('missing', undef)
 361     # in scalar context, just the data
 362     # if $etype defined, dies unless type is $etype or in @$etype
 363     our ($gcf_pid, $gcf_i, $gcf_o);
 364     my $chk = sub {
 365         my ($gtype, $data) = @_;
 366         if ($etype) {
 367             $etype = [$etype] unless ref $etype;
 368             confess "$objname expected @$etype but is $gtype"
 369                 unless grep { $gtype eq $_ } @$etype;
 370         }
 371         return ($gtype, $data);
 372     };
 373     if (!$gcf_pid) {
 374         my @cmd = qw(git cat-file --batch);
 375         debugcmd "GCF|", @cmd;
 376         $gcf_pid = open2 $gcf_o, $gcf_i, @cmd or die $!;
 377     }
 378     printdebug "GCF>| ", $objname, "\n";
 379     print $gcf_i $objname, "\n" or die $!;
 380     my $x = <$gcf_o>;
 381     printdebug "GCF<| ", $x;
 382     if ($x =~ m/ (missing)$/) { return $chk->($1, undef); }
 383     my ($type, $size) = $x =~ m/^.* (\w+) (\d+)\n/ or die "$objname ?";
 384     my $data;
 385     (read $gcf_o, $data, $size) == $size or die "$objname $!";
 386     $x = <$gcf_o>;
 387     $x eq "\n" or die "$objname ($_) $!";
 388     return $chk->($type, $data);
 389 }
 390
 391 sub git_get_symref (;$) {
 392     my ($symref) = @_;  $symref //= 'HEAD';
 393     # => undef if not a symref, otherwise refs/...
 394     my @cmd = (qw(git symbolic-ref -q HEAD));
 395     my $branch = cmdoutput_errok @cmd;
 396     if (!defined $branch) {
 397         $?==256 or failedcmd @cmd;
 398     } else {
 399         chomp $branch;
 400     }
 401     return $branch;
 402 }
 403
 404 sub git_for_each_ref ($$;$) {
 405     my ($pattern,$func,$gitdir) = @_;
 406     # calls $func->($objid,$objtype,$fullrefname,$reftail);
 407     # $reftail is RHS of ref after refs/[^/]+/
 408     # breaks if $pattern matches any ref `refs/blah' where blah has no `/'
 409     # $pattern may be an array ref to mean multiple patterns
 410     $pattern = [ $pattern ] unless ref $pattern;
 411     my @cmd = (qw(git for-each-ref), @$pattern);
 412     if (defined $gitdir) {
 413         @cmd = ('sh','-ec','cd "$1"; shift; exec "$@"','x', $gitdir, @cmd);
 414     }
 415     open GFER, "-|", @cmd or die $!;
 416     debugcmd "|", @cmd;
 417     while (<GFER>) {
 418         chomp or die "$_ ?";
 419         printdebug "|> ", $_, "\n";
 420         m#^(\w+)\s+(\w+)\s+(refs/[^/]+/(\S+))$# or die "$_ ?";
 421         $func->($1,$2,$3,$4);
 422     }
 423     $!=0; $?=0; close GFER or die "$pattern $? $!";
 424 }
 425
 426 sub git_get_ref ($) {
 427     # => '' if no such ref
 428     my ($refname) = @_;
 429     local $_ = $refname;
 430     s{^refs/}{[r]efs/} or die "$refname $_ ?";
 431     return cmdoutput qw(git for-each-ref --format=%(objectname)), $_;
 432 }
 433
 434 sub git_for_each_tag_referring ($$) {
 435     my ($objreferring, $func) = @_;
 436     # calls $func->($tagobjid,$refobjid,$fullrefname,$tagname);
 437     printdebug "git_for_each_tag_referring ",
 438         ($objreferring // 'UNDEF'),"\n";
 439     git_for_each_ref('refs/tags', sub {
 440         my ($tagobjid,$objtype,$fullrefname,$tagname) = @_;
 441         return unless $objtype eq 'tag';
 442         my $refobjid = git_rev_parse $tagobjid;
 443         return unless
 444             !defined $objreferring # caller wants them all
 445             or $tagobjid eq $objreferring
 446             or $refobjid eq $objreferring;
 447         $func->($tagobjid,$refobjid,$fullrefname,$tagname);
 448     });
 449 }
 450
 451 sub git_check_unmodified () {
 452     foreach my $cached (qw(0 1)) {
 453         my @cmd = qw(git diff --quiet);
 454         push @cmd, qw(--cached) if $cached;
 455         push @cmd, qw(HEAD);
 456         debugcmd "+",@cmd;
 457         $!=0; $?=-1; system @cmd;
 458         return if !$?;
 459         if ($?==256) {
 460             fail
 461                 $cached
 462                 ? "git index contains changes (does not match HEAD)"
 463                 : "working tree is dirty (does not match HEAD)";
 464         } else {
 465             failedcmd @cmd;
 466         }
 467     }
 468 }
 469
 470 sub is_fast_fwd ($$) {
 471     my ($ancestor,$child) = @_;
 472     my @cmd = (qw(git merge-base), $ancestor, $child);
 473     my $mb = cmdoutput_errok @cmd;
 474     if (defined $mb) {
 475         return git_rev_parse($mb) eq git_rev_parse($ancestor);
 476     } else {
 477         $?==256 or failedcmd @cmd;
 478         return 0;
 479     }
 480 }
 481
 482 sub changedir ($) {
 483     my ($newdir) = @_;
 484     printdebug "CD $newdir\n";
 485     chdir $newdir or confess "chdir: $newdir: $!";
 486 }
 487
 488 sub git_slurp_config_src ($) {
 489     my ($src) = @_;
 490     # returns $r such that $r->{KEY}[] = VALUE
 491     my @cmd = (qw(git config -z --get-regexp), "--$src", qw(.*));
 492     debugcmd "|",@cmd;
 493
 494     local ($debuglevel) = $debuglevel-2;
 495     local $/="\0";
 496
 497     my $r = { };
 498     open GITS, "-|", @cmd or die $!;
 499     while (<GITS>) {
 500         chomp or die;
 501         printdebug "=> ", (messagequote $_), "\n";
 502         m/\n/ or die "$_ ?";
 503         push @{ $r->{$`} }, $'; #';
 504     }
 505     $!=0; $?=0;
 506     close GITS
 507         or ($!==0 && $?==256)
 508         or failedcmd @cmd;
 509     return $r;
 510 }
 511
 512 # ========== playground handling ==========
 513
 514 # terminology:
 515 #
 516 #   $maindir      user's git working tree
 517 #   playground    area in .git/ where we can make files, unpack, etc. etc.
 518 #   playtree      git working tree sharing object store with the user's
 519 #                 inside playground, or identical to it
 520 #
 521 # other globals
 522 #
 523 #   $local_git_cfg    hash of arrays of values: git config from $maindir
 524 #
 525 # expected calling pattern
 526 #
 527 #  firstly
 528 #
 529 #    [record_maindir]
 530 #      must be run in directory containing .git
 531 #      assigns to $maindir if not already set
 532 #      also calls git_slurp_config_src to record git config
 533 #        in $local_git_cfg, unless it's already set
 534 #
 535 #    fresh_playground SUBDIR_PATH_COMPONENTS
 536 #      e.g fresh_playground 'dgit/unpack' ('.git/' is implied)
 537 #      default SUBDIR_PATH_COMPONENTS is playground_subdir
 538 #      calls record_maindir
 539 #      sets up a new playground (destroying any old one)
 540 #      returns playground pathname
 541 #      caller may call multiple times with different subdir paths
 542 #       createing different playgrounds
 543 #
 544 #    ensure_a_playground SUBDIR_PATH_COMPONENTS
 545 #      like fresh_playground except:
 546 #      merely ensures the directory exists; does not delete an existing one
 547 #
 548 #  then can use
 549 #
 550 #    changedir playground
 551 #    changedir $maindir
 552 #
 553 #    playtree_setup $local_git_cfg
 554 #            # ^ call in some (perhaps trivial) subdir of playground
 555 #
 556 #    rmtree playground
 557
 558 # ----- maindir -----
 559
 560 # these three all go together
 561 our $maindir;
 562 our $maindir_gitdir;
 563 our $maindir_gitcommon;
 564
 565 our $local_git_cfg;
 566
 567 sub record_maindir () {
 568     if (!defined $maindir) {
 569         $maindir = must_getcwd();
 570         if (!stat "$maindir/.git") {
 571             fail "cannot stat $maindir/.git: $!";
 572         }
 573         if (-d _) {
 574             # we fall back to this in case we have a pre-worktree
 575             # git, which may not know git rev-parse --git-common-dir
 576             $maindir_gitdir    = "$maindir/.git";
 577             $maindir_gitcommon = "$maindir/.git";
 578         } else {
 579             $maindir_gitdir    = cmdoutput qw(git rev-parse --git-dir);
 580             $maindir_gitcommon = cmdoutput qw(git rev-parse --git-common-dir);
 581         }
 582     }
 583     $local_git_cfg //= git_slurp_config_src 'local';
 584 }
 585
 586 # ----- playgrounds -----
 587
 588 sub ensure_a_playground_parent ($) {
 589     my ($spc) = @_;
 590     record_maindir();
 591     $spc = "$maindir_gitdir/$spc";
 592     my $parent = dirname $spc;
 593     mkdir $parent or $!==EEXIST
 594         or fail "failed to mkdir playground parent $parent: $!";
 595     return $spc;
 596 }
 597
 598 sub ensure_a_playground ($) {
 599     my ($spc) = @_;
 600     $spc = ensure_a_playground_parent $spc;
 601     mkdir $spc or $!==EEXIST or fail "failed to mkdir a playground $spc: $!";
 602     return $spc;
 603 }
 604
 605 sub fresh_playground ($) {
 606     my ($spc) = @_;
 607     $spc = ensure_a_playground_parent $spc;
 608     rmtree $spc;
 609     mkdir $spc or fail "failed to mkdir the playground $spc: $!";
 610     return $spc;
 611 }
 612
 613 # ----- playtrees -----
 614
 615 sub playtree_setup (;$) {
 616     my ($t_local_git_cfg) = @_;
 617     $t_local_git_cfg //= $local_git_cfg;
 618     # for use in the playtree
 619     # $maindir must be set, eg by calling record_maindir or fresh_playground
 620     runcmd qw(git init -q);
 621     runcmd qw(git config gc.auto 0);
 622     foreach my $copy (qw(user.email user.name user.useConfigOnly
 623                          core.sharedRepository
 624                          core.compression core.looseCompression
 625                          core.bigFileThreshold core.fsyncObjectFiles)) {
 626         my $v = $t_local_git_cfg->{$copy};
 627         next unless $v;
 628         runcmd qw(git config), $copy, $_ foreach @$v;
 629     }
 630     # this is confusing: we have
 631     #   .                   playtree, not a worktree, has .git/, our cwd
 632     #   $maindir            might be a worktree so
 633     #   $maindir_gitdir     contains our main working "dgit", HEAD, etc.
 634     #   $maindir_gitcommon  the shared stuff, including .objects
 635     rmtree('.git/objects');
 636     symlink "$maindir_gitcommon/objects",'.git/objects' or die $!;
 637     ensuredir '.git/info';
 638     open GA, "> .git/info/attributes" or die $!;
 639     print GA "* $negate_harmful_gitattrs\n" or die $!;
 640     close GA or die $!;
 641 }
 642
 643 1;